configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_INIT([lxc], [1.0.0.alpha1])
   5
   6 AC_CONFIG_SRCDIR([configure.ac])
   7 AC_CONFIG_AUX_DIR([config])
   8 AC_CONFIG_HEADERS([src/config.h])
   9 AM_INIT_AUTOMAKE([-Wall -Werror -Wno-portability subdir-objects])
  10 AC_CANONICAL_HOST
  11 AM_PROG_CC_C_O
  12 AC_GNU_SOURCE
  13
  14 # Detect the distribution. This is used for the default configuration and
  15 # for some distro-specific build options.
  16 AC_MSG_CHECKING([host distribution])
  17 AC_ARG_WITH(distro, AS_HELP_STRING([--with-distro=DISTRO], [Specify the Linux distribution to target: One of redhat, oracle, fedora, suse, gentoo, debian, arch, slackware, paldo, mandriva or pardus.]))
  18 if test "z$with_distro" = "z"; then
  19         with_distro=`lsb_release -is`
  20 fi
  21 if test "z$with_distro" = "z"; then
  22         AC_CHECK_FILE(/etc/redhat-release,with_distro="redhat")
  23         AC_CHECK_FILE(/etc/oracle-release,with_distro="oracle")
  24         AC_CHECK_FILE(/etc/fedora-release,with_distro="fedora")
  25         AC_CHECK_FILE(/etc/SuSE-release,with_distro="suse")
  26         AC_CHECK_FILE(/etc/gentoo-release,with_distro="gentoo")
  27         AC_CHECK_FILE(/etc/debian_version,with_distro="debian")
  28         AC_CHECK_FILE(/etc/arch-release,with_distro="arch")
  29         AC_CHECK_FILE(/etc/slackware-version,with_distro="slackware")
  30         AC_CHECK_FILE(/etc/frugalware-release,with_distro="frugalware")
  31         AC_CHECK_FILE(/etc/mandrakelinux-release, with_distro="mandriva")
  32         AC_CHECK_FILE(/etc/mandriva-release,with_distro="mandriva")
  33         AC_CHECK_FILE(/etc/pardus-release,with_distro="pardus")
  34 fi
  35 with_distro=`echo ${with_distro} | tr '[[:upper:]]' '[[:lower:]]'`
  36
  37 if test "z$with_distro" = "z"; then
  38         with_distro="unknown"
  39 fi
  40 case $with_distro in
  41         ubuntu)
  42                 distroconf=default.conf.ubuntu
  43                 ;;
  44         redhat|fedora|oracle|oracleserver)
  45                 distroconf=default.conf.libvirt
  46                 ;;
  47         *)
  48                 echo -n "Linux distribution network config unknown, defaulting to lxc.network.type = empty"
  49                 distroconf=default.conf.unknown
  50                 ;;
  51 esac
  52 AC_MSG_RESULT([$with_distro])
  53 AM_CONDITIONAL([HAVE_DEBIAN], [test x"$with_distro" = "xdebian" -o x"$with_distro" = "xubuntu"])
  54
  55 # Detect the newuidmap tool (required for userns)
  56 AC_CHECK_PROG([NEWUIDMAP], [newuidmap], [newuidmap])
  57 AM_CONDITIONAL([HAVE_NEWUIDMAP], [test -n "$NEWUIDMAP"])
  58
  59 # Allow disabling rpath
  60 AC_ARG_ENABLE([rpath],
  61         [AC_HELP_STRING([--disable-rpath], [do not set rpath in executables])],
  62         [], [enable_rpath=yes])
  63 AM_CONDITIONAL([ENABLE_RPATH], [test "x$enable_rpath" = "xyes"])
  64
  65 # Documentation (manpages)
  66 AC_ARG_ENABLE([doc],
  67         [AC_HELP_STRING([--enable-doc], [make mans (requires docbook2man or docbook2x-man to be installed) [default=auto]])],
  68         [], [enable_doc=auto])
  69
  70 if test "x$enable_doc" = "xyes" -o "x$enable_doc" = "xauto"; then
  71         db2xman=""
  72         dbparsers="docbook2x-man db2x_docbook2man docbook2man"
  73
  74         AC_MSG_CHECKING(for docbook2x-man)
  75         for name in ${dbparsers}; do
  76                 if "$name" --help >/dev/null 2>&1; then
  77                         db2xman="$name"
  78                         break;
  79                 fi
  80         done
  81
  82         if test -n "${db2xman}"; then
  83                 AC_MSG_RESULT([${db2xman}])
  84         else
  85                 AC_MSG_RESULT([no])
  86                 if test "x$enable_doc" = "xyes"; then
  87                         AC_MSG_ERROR([docbook2x-man required by man request, but not found])
  88                 fi
  89         fi
  90
  91         AC_SUBST(db2xman)
  92 fi
  93 AM_CONDITIONAL([ENABLE_DOCBOOK], [test "x$db2xman" != "x"])
  94 AM_CONDITIONAL([USE_DOCBOOK2X], [test "x$db2xman" != "xdocbook2man"])
  95
  96 if test "x$db2xman" = "xdocbook2man"; then
  97         docdtd="\"-//Davenport//DTD DocBook V3.0//EN\""
  98 else
  99         docdtd="\"-//OASIS//DTD DocBook XML\" \"http://www.oasis-open.org/docbook/xml/4.5/docbookx.dtd\""
 100 fi
 101 AC_SUBST(docdtd)
 102
 103 # Apparmor
 104 AC_ARG_ENABLE([apparmor],
 105         [AC_HELP_STRING([--enable-apparmor], [enable apparmor])],
 106         [], [enable_apparmor=check])
 107
 108 if test "$enable_apparmor" = "check" ; then
 109         AC_CHECK_LIB([apparmor],[aa_change_profile],[enable_apparmor=yes], [enable_apparmor=no])
 110 fi
 111 AM_CONDITIONAL([ENABLE_APPARMOR], [test "x$enable_apparmor" = "xyes"])
 112
 113 AC_CHECK_LIB([gnutls], [gnutls_hash_fast])
 114
 115 AM_COND_IF([ENABLE_APPARMOR],
 116         [AC_CHECK_HEADER([sys/apparmor.h],[],[AC_MSG_ERROR([You must install the AppArmor development package in order to compile lxc])])
 117         AC_CHECK_LIB([apparmor], [aa_change_profile],[],[AC_MSG_ERROR([You must install the AppArmor development package in order to compile lxc])])
 118         AC_SUBST([APPARMOR_LIBS], [-lapparmor])])
 119
 120 # Seccomp syscall filter
 121 AC_ARG_ENABLE([seccomp],
 122         [AC_HELP_STRING([--enable-seccomp], [enable seccomp])],
 123         [], [enable_seccomp=check])
 124
 125 if test "$enable_seccomp" = "check" ; then
 126         AC_CHECK_LIB([seccomp],[seccomp_init],[enable_seccomp=yes],[enable_seccomp=no])
 127 fi
 128 AM_CONDITIONAL([ENABLE_SECCOMP], [test "x$enable_seccomp" = "xyes"])
 129
 130 AM_COND_IF([ENABLE_SECCOMP],
 131         [AC_CHECK_HEADER([seccomp.h],[],[AC_MSG_ERROR([You must install the seccomp development package in order to compile lxc])])
 132         AC_CHECK_LIB([seccomp], [seccomp_init],[],[AC_MSG_ERROR([You must install the seccomp development package in order to compile lxc])])
 133         AC_SUBST([SECCOMP_LIBS], [-lseccomp])])
 134
 135 # HAVE_SCMP_FILTER_CTX=1 will tell us we have libseccomp api >= 1.0.0
 136 AC_CHECK_TYPES([scmp_filter_ctx], [], [], [#include <seccomp.h>])
 137
 138 # Configuration examples
 139 AC_ARG_ENABLE([examples],
 140         [AC_HELP_STRING([--disable-examples], [do not install configuration examples])],
 141         [], [enable_examples=yes])
 142 AM_CONDITIONAL([ENABLE_EXAMPLES], [test "x$enable_examples" = "xyes"])
 143
 144 # Python3 module and scripts
 145 AC_ARG_ENABLE([python],
 146         [AC_HELP_STRING([--enable-python], [enable python binding])],
 147         [enable_python=yes], [enable_python=no])
 148 AM_CONDITIONAL([ENABLE_PYTHON], [test "x$enable_python" = "xyes"])
 149
 150 AM_COND_IF([ENABLE_PYTHON],
 151         [AM_PATH_PYTHON([3.2], [], [AC_MSG_ERROR([You must install python3])])
 152         PKG_CHECK_MODULES([PYTHONDEV], [python3 >= 3.2],[],[AC_MSG_ERROR([You must install python3-dev])])
 153         AC_DEFINE_UNQUOTED([ENABLE_PYTHON], 1, [Python3 is available])])
 154
 155 # Not in older autoconf versions
 156 # AS_VAR_COPY(DEST, SOURCE)
 157 # -------------------------
 158 # Set the polymorphic shell variable DEST to the contents of the polymorphic
 159 # shell variable SOURCE.
 160 m4_ifdef([AS_VAR_COPY], [],
 161 [AC_DEFUN([AS_VAR_COPY],
 162     [AS_LITERAL_IF([$1[]$2], [$1=$$2], [eval $1=\$$2])])
 163 ])
 164
 165 dnl PKG_CHECK_VAR was introduced with pkg-config 0.28
 166 m4_ifdef([PKG_CHECK_VAR], [],
 167 [AC_DEFUN([PKG_CHECK_VAR],
 168     [AC_REQUIRE([PKG_PROG_PKG_CONFIG])dnl
 169      AC_ARG_VAR([$1], [value of $3 for $2, overriding pkg-config])dnl
 170      _PKG_CONFIG([$1], [variable="][$3]["], [$2])
 171      AS_VAR_COPY([$1], [pkg_cv_][$1])
 172      AS_VAR_IF([$1], [""], [$5], [$4])dnl
 173     ])# PKG_CHECK_VAR
 174 ])
 175
 176 # Lua module and scripts
 177 AC_ARG_ENABLE([lua],
 178         [AC_HELP_STRING([--enable-lua], [enable lua binding])],
 179         [], [enable_lua=check])
 180
 181 AC_ARG_WITH([lua-pc],
 182         [AS_HELP_STRING(
 183                 [--with-lua-pc=PKG],
 184                 [Specify pkg-config package name for lua]
 185         )], [], [with_lua_pc=no])
 186
 187 if test "x$enable_lua" = "xyes" -a "x$with_lua_pc" != "xno"; then
 188         # exit with error if not found
 189         PKG_CHECK_MODULES([LUA], [$with_lua_pc], [LUAPKGCONFIG=$with_lua_pc])
 190 fi
 191
 192 if test "x$enable_lua" = "xcheck" -a "x$with_lua_pc" != "xno"; then
 193         PKG_CHECK_MODULES([LUA], [$with_lua_pc],
 194                 [LUAPKGCONFIG=$with_lua_pc
 195                 enable_lua=yes],
 196                 [enable_lua=no])
 197 fi
 198
 199 if test "x$enable_lua" != "xno"; then
 200         PKG_CHECK_MODULES([LUA], [lua], [LUAPKGCONFIG=lua],
 201                 [PKG_CHECK_MODULES([LUA], [lua5.2], [LUAPKGCONFIG=lua5.2],
 202                         [PKG_CHECK_MODULES([LUA], [lua5.1], [LUAPKGCONFIG=lua5.1],
 203                                 [AS_IF([test "x$enable_lua" = "xyes"],
 204                                         [AC_MSG_ERROR([Lua not found. Please use --with-lua-pc=PKG])],
 205                                         [enable_lua=no])]
 206                         )]
 207                 )])
 208         AS_IF([test "x$LUAPKGCONFIG" != "x"], [enable_lua=yes])
 209 fi
 210
 211 AM_CONDITIONAL([ENABLE_LUA],
 212         [test "x$enable_lua" = "xyes"])
 213
 214 AM_COND_IF([ENABLE_LUA],
 215         [AC_MSG_CHECKING([Lua version])
 216         PKG_CHECK_VAR([LUA_VERSION], [$LUAPKGCONFIG], [V],,
 217                 [PKG_CHECK_VAR([LUA_VERSION], [$LUAPKGCONFIG], [major_version])])
 218         AC_MSG_RESULT([$LUA_VERSION])
 219         PKG_CHECK_VAR([LUA_INSTALL_CMOD], [$LUAPKGCONFIG], [INSTALL_CMOD],,
 220                 [LUA_INSTALL_CMOD=$libdir/lua/$LUA_VERSION])
 221         PKG_CHECK_VAR([LUA_INSTALL_LMOD], [$LUAPKGCONFIG], [INSTALL_LMOD],,
 222                 [LUA_INSTALL_LMOD=$datadir/lua/$LUA_VERSION])
 223         ])
 224
 225 # Optional test binaries
 226 AC_ARG_ENABLE([tests],
 227         [AC_HELP_STRING([--enable-tests], [build test/example binaries])],
 228         [enable_tests=yes], [enable_tests=no])
 229 AM_CONDITIONAL([ENABLE_TESTS], [test "x$enable_tests" = "xyes"])
 230
 231 # LXC container path, where the containers are actually stored
 232 # This is overridden by an entry in the file called LXCCONF
 233 # (i.e. /etc/lxc/lxc.conf)
 234 AC_ARG_WITH([config-path],
 235         [AC_HELP_STRING(
 236                 [--with-config-path=dir],
 237                 [lxc configuration repository path]
 238         )], [], [with_config_path=['${localstatedir}/lib/lxc']])
 239
 240 # The path of the global lxc configuration file.
 241 AC_ARG_WITH([global-conf],
 242         [AC_HELP_STRING(
 243                 [--with-global-conf=dir],
 244                 [global lxc configuration file]
 245         )], [], [with_global_conf=['${sysconfdir}/lxc/lxc.conf']])
 246
 247 # The path of the userns network configuration file
 248 AC_ARG_WITH([usernic-conf],
 249         [AC_HELP_STRING(
 250                 [--with-usernic-conf],
 251                 [user network interface configuration file]
 252         )], [], [with_usernic_conf=['${sysconfdir}/lxc/lxc-usernet']])
 253
 254 # The path of the runtime usernic database
 255 AC_ARG_WITH([usernic-db],
 256         [AC_HELP_STRING(
 257                 [--with-usernic-db],
 258                 [lxc user nic database]
 259         )], [], [with_usernic_db=['/run/lxc/nics']])
 260
 261 # Rootfs path, where the container mount structure is assembled
 262 AC_ARG_WITH([rootfs-path],
 263         [AC_HELP_STRING(
 264                 [--with-rootfs-path=dir],
 265                 [lxc rootfs mount point]
 266         )], [], [with_rootfs_path=['${libdir}/lxc/rootfs']])
 267
 268 # cgroup pattern specification
 269 AC_ARG_WITH([cgroup-pattern],
 270         [AC_HELP_STRING(
 271                 [--with-cgroup-pattern=pattern],
 272                 [pattern for container cgroups]
 273         )], [], [with_cgroup_pattern=['/lxc/%n']])
 274
 275 # Container log path.  By default, use $lxcpath.
 276 AC_MSG_CHECKING([Whether to place logfiles in container config path])
 277 AC_ARG_ENABLE([configpath-log],
 278         [AC_HELP_STRING([--enable-configpath-log], [use logfiles in config path])],
 279         [use_configpath_logs=yes], [use_configpath_logs=no])
 280 AC_MSG_RESULT([$use_configpath_logs])
 281 AM_CONDITIONAL([USE_CONFIGPATH_LOGS], [test "$use_configpath_logs" = "yes"])
 282
 283 if test "$use_configpath_logs" = "yes"; then
 284         default_log_path="${with_config_path}"
 285 else
 286         default_log_path="${localstatedir}/log/lxc"
 287 fi
 288
 289 AC_ARG_WITH([log-path],
 290         [AC_HELP_STRING(
 291                 [--with-log-path=dir],
 292                 [per container log path]
 293         )], [], [with_log_path=['${default_log_path}']])
 294
 295 # Expand some useful variables
 296 AS_AC_EXPAND(PREFIX, "$prefix")
 297 AS_AC_EXPAND(LIBDIR, "$libdir")
 298 AS_AC_EXPAND(BINDIR, "$bindir")
 299 AS_AC_EXPAND(LIBEXECDIR, "$libexecdir")
 300 AS_AC_EXPAND(INCLUDEDIR, "$includedir")
 301 AS_AC_EXPAND(SYSCONFDIR, "$sysconfdir")
 302 AS_AC_EXPAND(LXC_DEFAULT_CONFIG, "$sysconfdir/lxc/default.conf")
 303 AS_AC_EXPAND(DATADIR, "$datadir")
 304 AS_AC_EXPAND(LOCALSTATEDIR, "$localstatedir")
 305 AS_AC_EXPAND(DOCDIR, "$docdir")
 306 AS_AC_EXPAND(LXC_DISTRO_CONF, "$distroconf")
 307 AS_AC_EXPAND(LXC_GENERATE_DATE, "$(date)")
 308 AS_AC_EXPAND(LXCPATH, "$with_config_path")
 309 AS_AC_EXPAND(LXC_GLOBAL_CONF, "$with_global_conf")
 310 AS_AC_EXPAND(LXC_USERNIC_CONF, "$with_usernic_conf")
 311 AS_AC_EXPAND(LXC_USERNIC_DB, "$with_usernic_db")
 312 AS_AC_EXPAND(LXCROOTFSMOUNT, "$with_rootfs_path")
 313 AS_AC_EXPAND(LXCTEMPLATEDIR, "$datadir/lxc/templates")
 314 AS_AC_EXPAND(LXCHOOKDIR, "$datadir/lxc/hooks")
 315 AS_AC_EXPAND(LXCINITDIR, "$libexecdir")
 316 AS_AC_EXPAND(LOGPATH, "$with_log_path")
 317 AC_SUBST(DEFAULT_CGROUP_PATTERN, ["$with_cgroup_pattern"])
 318
 319 # Check for some standard kernel headers
 320 AC_CHECK_HEADERS([linux/unistd.h linux/netlink.h linux/genetlink.h],
 321                                 [],
 322                                 AC_MSG_ERROR([Please install the Linux kernel headers.]),
 323                                 [#include <sys/socket.h>])
 324
 325 # Allow disabling libcap support
 326 AC_ARG_ENABLE([capabilities],
 327         [AC_HELP_STRING([--disable-capabilities], [disable kernel capabilities])],
 328         [], [enable_capabilities=yes])
 329
 330 # Check for libcap support
 331 if test "x$enable_capabilities" = "xyes"; then
 332         AC_CHECK_LIB(cap,cap_set_proc,caplib=yes,caplib=no)
 333         AC_MSG_CHECKING([linux capabilities])
 334         if test "x$caplib" = "xyes" ; then
 335                 CAP_LIBS="-lcap"
 336                 AC_MSG_RESULT([$CAP_LIBS])
 337         else
 338                 AC_MSG_RESULT([no])
 339                 AC_MSG_ERROR([You are missing libcap support. If you really want to build without kernel capabilities, use --disable-capabilities])
 340         fi
 341 else
 342         CAP_LIBS=""
 343 fi
 344 AC_SUBST([CAP_LIBS])
 345
 346 # Check for alternate C libraries
 347 AC_MSG_CHECKING(for bionic libc)
 348 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 349         [[#ifndef __ANDROID__
 350 error: Not bionic!
 351 #endif]])],
 352         [is_bionic=yes],
 353         [is_bionic=no])
 354 if test "x$is_bionic" = "xyes"; then
 355         AC_DEFINE([IS_BIONIC], 1, [bionic libc])
 356         AC_MSG_RESULT([yes])
 357 else
 358         AC_MSG_RESULT([no])
 359 fi
 360 AM_CONDITIONAL([IS_BIONIC], [test "x$is_bionic" = "xyes"])
 361
 362 # Some systems lack PR_CAPBSET_DROP definition => HAVE_DECL_PR_CAPBSET_DROP
 363 AC_CHECK_DECLS([PR_CAPBSET_DROP], [], [], [#include <sys/prctl.h>])
 364
 365 # Check for some headers
 366 AC_CHECK_HEADERS([sys/signalfd.h pty.h ifaddrs.h sys/capability.h sys/personality.h utmpx.h sys/timerfd.h])
 367
 368 # Check for some syscalls functions
 369 AC_CHECK_FUNCS([setns pivot_root sethostname unshare rand_r confstr])
 370
 371 # Check for some functions
 372 AC_CHECK_LIB(util, openpty)
 373 AC_CHECK_FUNCS([openpty hasmntopt setmntent endmntent])
 374 AC_CHECK_FUNCS([getline],
 375         AM_CONDITIONAL(HAVE_GETLINE, true)
 376         AC_DEFINE(HAVE_GETLINE,1,[Have getline]),
 377         AM_CONDITIONAL(HAVE_GETLINE, false))
 378 AC_CHECK_FUNCS([fgetln],
 379         AM_CONDITIONAL(HAVE_FGETLN, true)
 380         AC_DEFINE(HAVE_FGETLN,1,[Have fgetln]),
 381         AM_CONDITIONAL(HAVE_FGETLN, false))
 382
 383 # Check for some libraries
 384 AC_SEARCH_LIBS(sem_open, [rt pthread])
 385 AC_SEARCH_LIBS(clock_gettime, [rt])
 386
 387 # Check for some standard binaries
 388 AC_PROG_GCC_TRADITIONAL
 389 AC_PROG_SED
 390
 391 if test "x$GCC" = "xyes"; then
 392         CFLAGS="$CFLAGS -Wall -Werror"
 393 fi
 394
 395 # Files requiring some variable expansion
 396 AC_CONFIG_FILES([
 397         Makefile
 398         lxc.pc
 399         lxc.spec
 400         config/Makefile
 401
 402         doc/Makefile
 403         doc/legacy/lxc-ls.sgml
 404         doc/lxc-attach.sgml
 405         doc/lxc-cgroup.sgml
 406         doc/lxc-checkconfig.sgml
 407         doc/lxc-checkpoint.sgml
 408         doc/lxc-clone.sgml
 409         doc/lxc-console.sgml
 410         doc/lxc-create.sgml
 411         doc/lxc-destroy.sgml
 412         doc/lxc-device.sgml
 413         doc/lxc-execute.sgml
 414         doc/lxc-freeze.sgml
 415         doc/lxc-info.sgml
 416         doc/lxc-kill.sgml
 417         doc/lxc-ls.sgml
 418         doc/lxc-monitor.sgml
 419         doc/lxc-netstat.sgml
 420         doc/lxc-ps.sgml
 421         doc/lxc-restart.sgml
 422         doc/lxc-snapshot.sgml
 423         doc/lxc-start-ephemeral.sgml
 424         doc/lxc-start.sgml
 425         doc/lxc-stop.sgml
 426         doc/lxc-top.sgml
 427         doc/lxc-unfreeze.sgml
 428         doc/lxc-unshare.sgml
 429         doc/lxc-version.sgml
 430         doc/lxc-wait.sgml
 431
 432         doc/lxc.conf.sgml
 433         doc/lxc.sgml
 434         doc/common_options.sgml
 435         doc/see_also.sgml
 436
 437         doc/rootfs/Makefile
 438
 439         doc/examples/Makefile
 440         doc/examples/lxc-macvlan.conf
 441         doc/examples/lxc-vlan.conf
 442         doc/examples/lxc-no-netns.conf
 443         doc/examples/lxc-empty-netns.conf
 444         doc/examples/lxc-phys.conf
 445         doc/examples/lxc-veth.conf
 446         doc/examples/lxc-complex.conf
 447
 448         doc/ja/Makefile
 449         doc/ja/legacy/lxc-ls.sgml
 450         doc/ja/lxc-attach.sgml
 451         doc/ja/lxc-cgroup.sgml
 452         doc/ja/lxc-checkconfig.sgml
 453         doc/ja/lxc-checkpoint.sgml
 454         doc/ja/lxc-clone.sgml
 455         doc/ja/lxc-console.sgml
 456         doc/ja/lxc-create.sgml
 457         doc/ja/lxc-destroy.sgml
 458         doc/ja/lxc-device.sgml
 459         doc/ja/lxc-execute.sgml
 460         doc/ja/lxc-freeze.sgml
 461         doc/ja/lxc-info.sgml
 462         doc/ja/lxc-kill.sgml
 463         doc/ja/lxc-ls.sgml
 464         doc/ja/lxc-monitor.sgml
 465         doc/ja/lxc-netstat.sgml
 466         doc/ja/lxc-ps.sgml
 467         doc/ja/lxc-restart.sgml
 468         doc/ja/lxc-start-ephemeral.sgml
 469         doc/ja/lxc-start.sgml
 470         doc/ja/lxc-stop.sgml
 471         doc/ja/lxc-top.sgml
 472         doc/ja/lxc-unfreeze.sgml
 473         doc/ja/lxc-unshare.sgml
 474         doc/ja/lxc-version.sgml
 475         doc/ja/lxc-wait.sgml
 476
 477         doc/ja/lxc.conf.sgml
 478         doc/ja/lxc.sgml
 479         doc/ja/common_options.sgml
 480         doc/ja/see_also.sgml
 481
 482         hooks/Makefile
 483
 484         templates/Makefile
 485         templates/lxc-cirros
 486         templates/lxc-debian
 487         templates/lxc-ubuntu
 488         templates/lxc-ubuntu-cloud
 489         templates/lxc-opensuse
 490         templates/lxc-busybox
 491         templates/lxc-fedora
 492         templates/lxc-oracle
 493         templates/lxc-altlinux
 494         templates/lxc-sshd
 495         templates/lxc-archlinux
 496         templates/lxc-alpine
 497
 498         src/Makefile
 499         src/lxc/Makefile
 500         src/lxc/lxc-ps
 501         src/lxc/lxc-netstat
 502         src/lxc/lxc-checkconfig
 503         src/lxc/lxc-version
 504         src/lxc/lxc-start-ephemeral
 505         src/lxc/legacy/lxc-ls
 506         src/lxc/lxc.functions
 507
 508         src/python-lxc/Makefile
 509
 510         src/lua-lxc/Makefile
 511
 512         src/tests/Makefile
 513 ])
 514 AC_CONFIG_COMMANDS([default],[[]],[[]])
 515 AC_OUTPUT