configure.ac

   1 ##
   2 ## Configure template file for FRRouting.
   3 ## autoconf will generate configure script.
   4 ##
   5 ##  Copyright (c) 1996, 97, 98, 99, 2000 Kunihiro Ishiguro <kunihiro@zebra.org>
   6 ##  Portions Copyright (c) 2003 Paul Jakma <paul@dishone.st>
   7 ##
   8 AC_PREREQ(2.60)
   9
  10 AC_INIT(frr, 6.1-dev, [https://github.com/frrouting/frr/issues])
  11 PACKAGE_URL="https://frrouting.org/"
  12 AC_SUBST(PACKAGE_URL)
  13 PACKAGE_FULLNAME="FRRouting"
  14 AC_SUBST(PACKAGE_FULLNAME)
  15
  16 CONFIG_ARGS="$ac_configure_args"
  17 AC_SUBST(CONFIG_ARGS)
  18
  19 AC_CONFIG_SRCDIR(lib/zebra.h)
  20 AC_CONFIG_MACRO_DIR([m4])
  21
  22 dnl -----------------------------------
  23 dnl Get hostname and other information.
  24 dnl -----------------------------------
  25 AC_CANONICAL_BUILD()
  26 AC_CANONICAL_HOST()
  27
  28 AS_IF([test "$host" != "$build"], [
  29   if test "$srcdir" = "."; then
  30     AC_MSG_ERROR([cross-compilation is only possible with builddir separate from srcdir.  create a separate directory and run as .../path-to-frr/configure.])
  31   fi
  32   test -d hosttools || mkdir hosttools
  33   abssrc="`cd \"${srcdir}\"; pwd`"
  34
  35   AC_MSG_NOTICE([...])
  36   AC_MSG_NOTICE([... cross-compilation: creating hosttools directory and self-configuring for build platform tools])
  37   AC_MSG_NOTICE([... use HOST_CPPFLAGS / HOST_CFLAGS / HOST_LDFLAGS if neccessary])
  38   AC_MSG_NOTICE([...])
  39
  40   ( CPPFLAGS="$HOST_CPPFLAGS"; \
  41     CFLAGS="$HOST_CFLAGS"; \
  42     LDFLAGS="$HOST_LDFLAGS"; \
  43     cd hosttools; "${abssrc}/configure" "--host=$build" "--build=$build" "--enable-clippy-only" "--disable-nhrpd" "--disable-vtysh"; )
  44
  45   AC_MSG_NOTICE([...])
  46   AC_MSG_NOTICE([... cross-compilation: finished self-configuring for build platform tools])
  47   AC_MSG_NOTICE([...])
  48
  49   build_clippy="false"
  50   HOSTTOOLS="hosttools/"
  51 ], [
  52   build_clippy="true"
  53   HOSTTOOLS=""
  54 ])
  55 AC_SUBST(HOSTTOOLS)
  56 AM_CONDITIONAL([BUILD_CLIPPY], [$build_clippy])
  57
  58 # Disable portability warnings -- our automake code (in particular
  59 # common.am) uses some constructs specific to gmake.
  60 AM_INIT_AUTOMAKE([1.12 -Wno-portability])
  61 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
  62 AM_SILENT_RULES([yes])
  63 AC_CONFIG_HEADERS(config.h)
  64
  65 AC_PATH_PROG(PERL, perl)
  66 PKG_PROG_PKG_CONFIG
  67
  68 dnl default is to match previous behavior
  69 exampledir=${sysconfdir}
  70 AC_ARG_ENABLE([exampledir],
  71           AS_HELP_STRING([--enable-exampledir],
  72                          [specify alternate directory for examples]),
  73                          exampledir="$enableval",)
  74 dnl XXX add --exampledir to autoconf standard directory list somehow
  75 AC_SUBST(exampledir)
  76
  77 dnl default is to match previous behavior
  78 pkgsrcrcdir=""
  79 AC_ARG_ENABLE([pkgsrcrcdir],
  80           AS_HELP_STRING([--enable-pkgsrcrcdir],
  81                          [specify directory for rc.d scripts]),
  82                          pkgsrcrcdir="$enableval",)
  83 dnl XXX add --pkgsrcrcdir to autoconf standard directory list somehow
  84 AC_SUBST(pkgsrcrcdir)
  85 AM_CONDITIONAL([PKGSRC], [test "x$pkgsrcrcdir" != "x"])
  86
  87 AC_ARG_WITH([moduledir], [AS_HELP_STRING([--with-moduledir=DIR], [module directory (${libdir}/frr/modules)])], [
  88         moduledir="$withval"
  89 ], [
  90         moduledir="\${libdir}/frr/modules"
  91 ])
  92 AC_SUBST([moduledir], [$moduledir])
  93
  94 AC_ARG_ENABLE(tcmalloc,
  95         AS_HELP_STRING([--enable-tcmalloc], [Turn on tcmalloc]),
  96 [case "${enableval}" in
  97   yes) tcmalloc_enabled=true
  98 LIBS="$LIBS -ltcmalloc_minimal"
  99  ;;
 100   no)  tcmalloc_enabled=false ;;
 101   *) AC_MSG_ERROR(bad value ${enableval} for --enable-tcmalloc) ;;
 102 esac],[tcmalloc_enabled=false])
 103
 104
 105 dnl Thanks autoconf, but we don't want a default -g -O2.  We have our own
 106 dnl flag determination logic.
 107 CFLAGS="${CFLAGS:-}"
 108
 109 dnl --------------------
 110 dnl Check CC and friends
 111 dnl --------------------
 112 dnl note orig_cflags is also used further down
 113 orig_cflags="$CFLAGS"
 114 AC_LANG([C])
 115 AC_PROG_CC
 116 AC_PROG_CPP
 117 AM_PROG_CC_C_O
 118 dnl remove autoconf default "-g -O2"
 119 CFLAGS="$orig_cflags"
 120 AC_PROG_CC_C99
 121 dnl NB: see C11 below
 122
 123 AC_PROG_EGREP
 124 PKG_PROG_PKG_CONFIG
 125
 126 dnl autoconf 2.59 appears not to support AC_PROG_SED
 127 dnl AC_PROG_SED
 128 AC_CHECK_PROG([SED],[sed],[sed],[/bin/false])
 129
 130 dnl try and enable CFLAGS that are useful for FRR
 131 dnl - specifically, options to control warnings
 132
 133 AC_USE_SYSTEM_EXTENSIONS
 134 AC_DEFUN([AC_C_FLAG], [{
 135     m4_pushdef([cachename],[m4_translit([frr_cv_$1],[ =-],[___])])
 136     AC_CACHE_CHECK([[whether $CC supports $1]], cachename, [
 137         AC_LANG_PUSH(C)
 138         ac_c_flag_save="$CFLAGS"
 139         CFLAGS="$CFLAGS $1"
 140         AC_COMPILE_IFELSE(
 141                 [AC_LANG_PROGRAM([[]])],
 142                 [
 143                         cachename=yes
 144                 ], [
 145                         cachename=no
 146                 ])
 147         CFLAGS="$ac_c_flag_save"
 148         AC_LANG_POP(C)
 149     ])
 150     if test "${cachename}" = yes; then
 151         m4_if([$3], [], [CFLAGS="$CFLAGS $1"], [$3])
 152     else
 153         :
 154         $2
 155     fi
 156     m4_popdef([cachename])
 157 }])
 158
 159 AC_DEFUN([AC_LINK_IFELSE_FLAGS], [{
 160         AC_LANG_PUSH(C)
 161         ac_cflags_save="$CFLAGS"
 162         ac_libs_save="$LIBS"
 163         CFLAGS="$CFLAGS $1"
 164         LIBS="$LIBS $2"
 165         AC_LINK_IFELSE(
 166                 [$3],
 167                 [
 168                         AC_MSG_RESULT([yes])
 169                         CFLAGS="$ac_cflags_save"
 170                         LIBS="$ac_libs_save"
 171                         $5
 172                 ], [
 173                         AC_MSG_RESULT([no])
 174                         CFLAGS="$ac_cflags_save"
 175                         LIBS="$ac_libs_save"
 176                         $4
 177                 ])
 178         AC_LANG_POP(C)
 179         }])
 180
 181 dnl ICC won't bail on unknown options without -diag-error 10006
 182 dnl need to do this first so we get useful results for the other options
 183 AC_C_FLAG([-diag-error 10006])
 184
 185 dnl AC_PROG_CC_C99 may change CC to include -std=gnu99 or something
 186 ac_cc="$CC"
 187 CC="${CC% -std=gnu99}"
 188 CC="${CC% -std=c99}"
 189
 190 AC_C_FLAG([-std=gnu11], [CC="$ac_cc"], [CC="$CC -std=gnu11"])
 191
 192 dnl AddressSanitizer support
 193 AC_ARG_ENABLE([address-sanitizer], AS_HELP_STRING([--enable-address-sanitizer], \
 194               [enabled AddressSanitizer support for detecting a wide variety of \
 195                memory allocation and deallocation errors]), \
 196               [AC_DEFINE(HAVE_ADDRESS_SANITIZER, 1, [enable AddressSanitizer])
 197               ASAN_FLAGS="-fsanitize=address"
 198               SAN_CLIPPY_FLAGS="-fno-sanitize=all"
 199               AC_SUBST([ASAN_FLAGS])
 200               AC_SUBST([SAN_CLIPPY_FLAGS])
 201               LIBS="-ldl $LIBS"
 202               AC_TRY_COMPILE([],[const int i=0;],[AC_MSG_NOTICE([Address Sanitizer Enabled])],
 203                                                  [AC_MSG_ERROR([Address Sanitizer not available])])
 204               ])
 205
 206 dnl ThreadSanitizer support
 207 AC_ARG_ENABLE([thread-sanitizer], AS_HELP_STRING([--enable-thread-sanitizer], \
 208               [enabled ThreadSanitizer support for detecting data races]), \
 209               [AC_DEFINE(HAVE_THREAD_SANITIZER, 1, [enable ThreadSanitizer])
 210               TSAN_FLAGS="-fsanitize=thread"
 211               SAN_CLIPPY_FLAGS="-fno-sanitize=all"
 212               AC_SUBST([TSAN_FLAGS])
 213               AC_SUBST([SAN_CLIPPY_FLAGS])
 214               LIBS="-ldl $LIBS"
 215               AC_TRY_COMPILE([],[const int i=0;],[AC_MSG_NOTICE([Thread Sanitizer Enabled])],
 216                                                  [AC_MSG_ERROR([Thread Sanitizer not available])])
 217               ])
 218
 219 dnl MemorySanitizer support
 220 AC_ARG_ENABLE([memory-sanitizer], AS_HELP_STRING([--enable-memory-sanitizer], \
 221               [enabled MemorySanitizer support for detecting uninitialized memory reads]), \
 222               [AC_DEFINE(HAVE_THREAD_SANITIZER, 1, [enable MemorySanitizer])
 223               MSAN_FLAGS="-fsanitize=memory -fPIE -pie"
 224               SAN_CLIPPY_FLAGS="-fno-sanitize=all"
 225               AC_SUBST([MSAN_FLAGS])
 226               AC_SUBST([SAN_CLIPPY_FLAGS])
 227               LIBS="-ldl $LIBS"
 228               AC_TRY_COMPILE([],[const int i=0;],[AC_MSG_NOTICE([Memory Sanitizer Enabled])],
 229                                                  [AC_MSG_ERROR([Memory Sanitizer not available])])
 230               ])
 231
 232 dnl if the user has specified any CFLAGS, override our settings
 233 if test "x${enable_gcov}" = "xyes"; then
 234    if test "z$orig_cflags" = "z"; then
 235       AC_C_FLAG([-coverage])
 236       AC_C_FLAG([-O0])
 237    fi
 238
 239    LDFLAGS="${LDFLAGS} -lgcov"
 240 elif test "x${enable_dev_build}" = "xyes"; then
 241    AC_DEFINE(DEV_BUILD,,Build for development)
 242    if test "z$orig_cflags" = "z"; then
 243       AC_C_FLAG([-g3])
 244       AC_C_FLAG([-O0])
 245    fi
 246 else
 247    if test "z$orig_cflags" = "z"; then
 248       AC_C_FLAG([-g])
 249       AC_C_FLAG([-Os], [
 250         AC_C_FLAG([-O2])
 251       ])
 252    fi
 253 fi
 254 AM_CONDITIONAL([DEV_BUILD], [test "x$enable_dev_build" = "xyes"])
 255
 256 dnl always want these CFLAGS
 257 AC_C_FLAG([-fno-omit-frame-pointer])
 258 AC_C_FLAG([-funwind-tables])
 259 AC_C_FLAG([-Wall])
 260 AC_C_FLAG([-Wextra])
 261 AC_C_FLAG([-Wmissing-prototypes])
 262 AC_C_FLAG([-Wmissing-declarations])
 263 AC_C_FLAG([-Wpointer-arith])
 264 AC_C_FLAG([-Wbad-function-cast])
 265 AC_C_FLAG([-Wwrite-strings])
 266 if test x"${enable_gcc_ultra_verbose}" = x"yes" ; then
 267   AC_C_FLAG([-Wcast-qual])
 268   AC_C_FLAG([-Wstrict-prototypes])
 269   AC_C_FLAG([-Wmissing-noreturn])
 270   AC_C_FLAG([-Wmissing-format-attribute])
 271   AC_C_FLAG([-Wunreachable-code])
 272   AC_C_FLAG([-Wpacked])
 273   AC_C_FLAG([-Wpadded])
 274 else
 275   AC_C_FLAG([-Wno-unused-result])
 276 fi
 277 AC_C_FLAG([-Wno-unused-parameter])
 278 AC_C_FLAG([-Wno-missing-field-initializers])
 279
 280 dnl ICC emits a broken warning for const char *x = a ? "b" : "c";
 281 dnl for some reason the string consts get 'promoted' to char *,
 282 dnl triggering a const to non-const conversion warning.
 283 AC_C_FLAG([-diag-disable 3179])
 284
 285 if test x"${enable_werror}" = x"yes" ; then
 286   WERROR="-Werror"
 287 fi
 288 AC_SUBST(WERROR)
 289
 290 dnl need link on this one, not compile
 291 AC_LANG_PUSH(C)
 292 ac_ld_flag_save="$LDFLAGS"
 293 LDFLAGS="$LDFLAGS -rdynamic"
 294 AC_MSG_CHECKING([[whether linker supports -rdynamic]])
 295 AC_LINK_IFELSE(
 296         [AC_LANG_PROGRAM([[]])],
 297         [AC_MSG_RESULT([yes])],
 298         [
 299                 LDFLAGS="$ac_ld_flag_save"
 300                 AC_MSG_RESULT([no])
 301         ])
 302 AC_LANG_POP(C)
 303
 304 dnl ----------
 305 dnl Essentials
 306 dnl ----------
 307
 308 AX_PTHREAD([
 309   CC="$PTHREAD_CC"
 310   CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 311   LIBS="$PTHREAD_LIBS $LIBS"
 312 ], [
 313   AC_MSG_FAILURE([This FRR version needs pthreads])
 314 ])
 315
 316 dnl --------------
 317 dnl Check programs
 318 dnl --------------
 319 AC_PROG_INSTALL
 320 AC_PROG_LN_S
 321 AC_PROG_MAKE_SET
 322 AC_CHECK_TOOL(AR, ar)
 323
 324 dnl -----------------
 325 dnl System extensions
 326 dnl -----------------
 327 AC_GNU_SOURCE
 328
 329 dnl -------
 330 dnl libtool
 331 dnl -------
 332 LT_INIT
 333
 334 dnl ----------------------
 335 dnl Packages configuration
 336 dnl ----------------------
 337 AC_ARG_WITH(pkg-extra-version,
 338         AS_HELP_STRING([--with-pkg-extra-version=VER], [add extra version field, for packagers/distributions]),
 339         [EXTRAVERSION=$withval],)
 340 AC_ARG_WITH(pkg-git-version,
 341         AS_HELP_STRING([--with-pkg-git-version], [add git information to MOTD and build version string]),
 342         [ test "x$withval" != "xno" && with_pkg_git_version="yes" ])
 343 AC_ARG_WITH(vtysh_pager,
 344         AS_HELP_STRING([--with-vtysh-pager=PAGER], [control what pager is compiled in as default]),
 345         VTYSH_PAGER=$withval, VTYSH_PAGER="more")
 346 AC_ARG_ENABLE(vtysh,
 347   AS_HELP_STRING([--disable-vtysh], [do not build integrated vty shell for FRR]))
 348 AC_ARG_ENABLE(doc,
 349   AS_HELP_STRING([--disable-doc], [do not build docs]))
 350 AC_ARG_ENABLE(doc-html,
 351   AS_HELP_STRING([--enable-doc-html], [build HTML docs]))
 352 AC_ARG_ENABLE(zebra,
 353   AS_HELP_STRING([--disable-zebra], [do not build zebra daemon]))
 354 AC_ARG_ENABLE(bgpd,
 355   AS_HELP_STRING([--disable-bgpd], [do not build bgpd]))
 356 AC_ARG_ENABLE(ripd,
 357   AS_HELP_STRING([--disable-ripd], [do not build ripd]))
 358 AC_ARG_ENABLE(ripngd,
 359   AS_HELP_STRING([--disable-ripngd], [do not build ripngd]))
 360 AC_ARG_ENABLE(ospfd,
 361   AS_HELP_STRING([--disable-ospfd], [do not build ospfd]))
 362 AC_ARG_ENABLE(ospf6d,
 363   AS_HELP_STRING([--disable-ospf6d], [do not build ospf6d]))
 364 AC_ARG_ENABLE(ldpd,
 365   AS_HELP_STRING([--disable-ldpd], [do not build ldpd]))
 366 AC_ARG_ENABLE(nhrpd,
 367   AS_HELP_STRING([--disable-nhrpd], [do not build nhrpd]))
 368 AC_ARG_ENABLE(eigrpd,
 369   AS_HELP_STRING([--disable-eigrpd], [do not build eigrpd]))
 370 AC_ARG_ENABLE(babeld,
 371   AS_HELP_STRING([--disable-babeld], [do not build babeld]))
 372 AC_ARG_ENABLE(watchfrr,
 373   AS_HELP_STRING([--disable-watchfrr], [do not build watchfrr]))
 374 AC_ARG_ENABLE(isisd,
 375   AS_HELP_STRING([--disable-isisd], [do not build isisd]))
 376 AC_ARG_ENABLE(pimd,
 377   AS_HELP_STRING([--disable-pimd], [do not build pimd]))
 378 AC_ARG_ENABLE(pbrd,
 379   AS_HELP_STRING([--disable-pbrd], [do not build pbrd]))
 380 AC_ARG_ENABLE(sharpd,
 381   AS_HELP_STRING([--enable-sharpd], [build sharpd]))
 382 AC_ARG_ENABLE(staticd,
 383   AS_HELP_STRING([--disable-staticd], [do not build staticd]))
 384 AC_ARG_ENABLE(bgp-announce,
 385   AS_HELP_STRING([--disable-bgp-announce,], [turn off BGP route announcement]))
 386 AC_ARG_ENABLE(bgp-vnc,
 387   AS_HELP_STRING([--disable-bgp-vnc],[turn off BGP VNC support]))
 388 AC_ARG_WITH(rfp-path,
 389   AS_HELP_STRING([--with-rfp-path[=DIR]],[path to replaced stub RFP used with BGP VNC]))
 390 AC_ARG_ENABLE(snmp,
 391   AS_HELP_STRING([--enable-snmp], [enable SNMP support for agentx]))
 392 AC_ARG_ENABLE(zeromq,
 393   AS_HELP_STRING([--enable-zeromq], [enable ZeroMQ handler (libfrrzmq)]))
 394 AC_ARG_WITH(libpam,
 395   AS_HELP_STRING([--with-libpam], [use libpam for PAM support in vtysh]))
 396 AC_ARG_ENABLE(ospfapi,
 397   AS_HELP_STRING([--disable-ospfapi], [do not build OSPFAPI to access the OSPF LSA Database]))
 398 AC_ARG_ENABLE(ospfclient,
 399   AS_HELP_STRING([--disable-ospfclient], [do not build OSPFAPI client for OSPFAPI,
 400                           (this is the default if --disable-ospfapi is set)]))
 401 AC_ARG_ENABLE(multipath,
 402   AS_HELP_STRING([--enable-multipath=ARG], [enable multipath function, ARG must be digit]))
 403 AC_ARG_ENABLE(user,
 404   AS_HELP_STRING([--enable-user=USER], [user to run FRR suite as (default frr)]))
 405 AC_ARG_ENABLE(group,
 406   AS_HELP_STRING([--enable-group=GROUP], [group to run FRR suite as (default frr)]))
 407 AC_ARG_ENABLE(vty_group,
 408   AS_HELP_STRING([--enable-vty-group=ARG], [set vty sockets to have specified group as owner]))
 409 AC_ARG_ENABLE(configfile_mask,
 410   AS_HELP_STRING([--enable-configfile-mask=ARG], [set mask for config files]))
 411 AC_ARG_ENABLE(logfile_mask,
 412   AS_HELP_STRING([--enable-logfile-mask=ARG], [set mask for log files]))
 413 AC_ARG_ENABLE(shell_access,
 414   AS_HELP_STRING([--enable-shell-access], [Allow users to access shell/telnet/ssh]))
 415 AC_ARG_ENABLE(realms,
 416   AS_HELP_STRING([--enable-realms], [enable REALMS support under Linux]))
 417 AC_ARG_ENABLE(rtadv,
 418   AS_HELP_STRING([--disable-rtadv], [disable IPV6 router advertisement feature]))
 419 AC_ARG_ENABLE(irdp,
 420   AS_HELP_STRING([--disable-irdp], [enable IRDP server support in zebra (default if supported)]))
 421 AC_ARG_ENABLE(capabilities,
 422   AS_HELP_STRING([--disable-capabilities], [disable using POSIX capabilities]))
 423 AC_ARG_ENABLE(rusage,
 424   AS_HELP_STRING([--disable-rusage], [disable using getrusage]))
 425 AC_ARG_ENABLE(gcc_ultra_verbose,
 426   AS_HELP_STRING([--enable-gcc-ultra-verbose], [enable ultra verbose GCC warnings]))
 427 AC_ARG_ENABLE(backtrace,
 428   AS_HELP_STRING([--disable-backtrace,], [disable crash backtraces (default autodetect)]))
 429 AC_ARG_ENABLE(time-check,
 430   AS_HELP_STRING([--disable-time-check], [disable slow thread warning messages]))
 431 AC_ARG_ENABLE(pcreposix,
 432   AS_HELP_STRING([--enable-pcreposix], [enable using PCRE Posix libs for regex functions]))
 433 AC_ARG_ENABLE(fpm,
 434   AS_HELP_STRING([--enable-fpm], [enable Forwarding Plane Manager support]))
 435 AC_ARG_ENABLE(systemd,
 436   AS_HELP_STRING([--enable-systemd], [enable Systemd support]))
 437 AC_ARG_ENABLE(werror,
 438   AS_HELP_STRING([--enable-werror], [enable -Werror (recommended for developers only)]))
 439 AC_ARG_ENABLE(cumulus,
 440   AS_HELP_STRING([--enable-cumulus], [enable Cumulus Switch Special Extensions]))
 441 AC_ARG_ENABLE(datacenter,
 442   AS_HELP_STRING([--enable-datacenter], [enable Compilation for Data Center Extensions]))
 443 AC_ARG_ENABLE(fuzzing,
 444   AS_HELP_STRING([--enable-fuzzing], [enable ability to fuzz various parts of FRR]))
 445 AC_ARG_ENABLE(netlink_fuzzing,
 446   AS_HELP_STRING([--enable-netlink-fuzzing], [enable ability to fuzz netlink listening socket in zebra]))
 447 AC_ARG_ENABLE(rr-semantics,
 448   AS_HELP_STRING([--disable-rr-semantics], [disable the v6 Route Replace semantics]))
 449 AC_ARG_ENABLE([protobuf],
 450   AS_HELP_STRING([--enable-protobuf], [Enable experimental protobuf support]))
 451 AC_ARG_ENABLE([oldvpn_commands],
 452   AS_HELP_STRING([--enable-oldvpn-commands], [Keep old vpn commands]))
 453 AC_ARG_ENABLE(rpki,
 454   AS_HELP_STRING([--enable-rpki], [enable RPKI prefix validation support]))
 455 AC_ARG_ENABLE([clippy-only],
 456   AS_HELP_STRING([--enable-clippy-only], [Only build clippy]))
 457 AC_ARG_ENABLE([numeric_version],
 458   AS_HELP_STRING([--enable-numeric-version], [Only numeric digits allowed in version (for Alpine)]))
 459 AC_ARG_ENABLE([gcov],
 460   AS_HELP_STRING([--enable-gcov], [Add code coverage information]))
 461 AC_ARG_ENABLE(bfdd,
 462   AS_HELP_STRING([--disable-bfdd], [do not build bfdd]))
 463
 464 AS_IF([test "${enable_clippy_only}" != "yes"], [
 465 AC_CHECK_HEADERS(json-c/json.h)
 466 AC_CHECK_LIB(json-c, json_object_get, LIBS="$LIBS -ljson-c", [], [-lm])
 467 if test $ac_cv_lib_json_c_json_object_get = no; then
 468   AC_CHECK_LIB(json, json_object_get, LIBS="$LIBS -ljson")
 469   if test $ac_cv_lib_json_json_object_get = no; then
 470       AC_MSG_ERROR([lib json is needed to compile])
 471   fi
 472 fi
 473 ])
 474
 475 AC_ARG_ENABLE([dev_build],
 476     AS_HELP_STRING([--enable-dev-build], [build for development]))
 477
 478 if test x"${enable_time_check}" != x"no" ; then
 479   if test x"${enable_time_check}" = x"yes" -o x"${enable_time_check}" = x ; then
 480     AC_DEFINE(CONSUMED_TIME_CHECK,5000000,Consumed Time Check)
 481   else
 482     AC_DEFINE_UNQUOTED(CONSUMED_TIME_CHECK,$enable_time_check,Consumed Time Check)
 483   fi
 484 fi
 485
 486 case "${enable_systemd}" in
 487   "no") ;;
 488   "yes")
 489   AC_CHECK_LIB(systemd, sd_notify, LIBS="$LIBS -lsystemd")
 490   if test $ac_cv_lib_systemd_sd_notify = no; then
 491     AC_MSG_ERROR([enable systemd has been specified but systemd development env not found on your system])
 492   else
 493     AC_DEFINE(HAVE_SYSTEMD,,Compile systemd support in)
 494   fi
 495   ;;
 496   "*") ;;
 497 esac
 498
 499 if test "${enable_rr_semantics}" != "no" ; then
 500   AC_DEFINE(HAVE_V6_RR_SEMANTICS,, Compile in v6 Route Replacement Semantics)
 501 fi
 502
 503 if test "${enable_datacenter}" = "yes" ; then
 504   AC_DEFINE(HAVE_DATACENTER,,Compile extensions for a DataCenter)
 505   DFLT_NAME="datacenter"
 506 else
 507   DFLT_NAME="traditional"
 508 fi
 509
 510 if test "${enable_fuzzing}" = "yes" ; then
 511   AC_DEFINE(HANDLE_ZAPI_FUZZING,,Compile extensions to use with a fuzzer)
 512 fi
 513
 514 if test "${enable_netlink_fuzzing}" = "yes" ; then
 515   AC_DEFINE(HANDLE_NETLINK_FUZZING,,Compile extensions to use with a fuzzer for netlink)
 516 fi
 517
 518 if test "${enable_cumulus}" = "yes" ; then
 519   AC_DEFINE(HAVE_CUMULUS,,Compile Special Cumulus Code in)
 520 fi
 521
 522 AC_SUBST(DFLT_NAME)
 523 AC_DEFINE_UNQUOTED(DFLT_NAME,["$DFLT_NAME"], Name of the configuration default set)
 524
 525 if test "${enable_shell_access}" = "yes"; then
 526    AC_DEFINE(HAVE_SHELL_ACCESS,,Allow user to use ssh/telnet/bash)
 527 fi
 528
 529 AM_CONDITIONAL([FPM], [test "x$enable_fpm" = "xyes"])
 530
 531 #
 532 # Python for clippy
 533 #
 534
 535 AC_DEFUN([FRR_PYTHON_CHECK_WORKING], [
 536   AC_MSG_CHECKING([whether we found a working Python version])
 537   AC_LINK_IFELSE_FLAGS([$PYTHON_CFLAGS], [$PYTHON_LIBS], [AC_LANG_PROGRAM([
 538 #include <Python.h>
 539 #if PY_VERSION_HEX < 0x02070000
 540 #error python too old
 541 #endif
 542 int main(void);
 543 ],
 544 [
 545 {
 546   Py_Initialize();
 547   return 0;
 548 }
 549 ])], [
 550     # some python installs are missing the zlib dependency...
 551     PYTHON_LIBS="${PYTHON_LIBS} -lz"
 552     AC_LINK_IFELSE_FLAGS([$PYTHON_CFLAGS], [$PYTHON_LIBS], [AC_LANG_PROGRAM([
 553 #include <Python.h>
 554 #if PY_VERSION_HEX < 0x02070000
 555 #error python too old
 556 #endif
 557 int main(void);
 558 ],
 559 [
 560 {
 561   Py_Initialize();
 562   return 0;
 563 }
 564 ])], [
 565       m4_if([$1], [], [
 566         PYTHONCONFIG=""
 567         unset PYTHON_LIBS
 568         unset PYTHON_CFLAGS
 569       ], [$1])
 570     ])
 571   ])
 572 ])
 573
 574 AS_IF([test "$host" = "$build"], [
 575   PYTHONCONFIG=""
 576
 577   # ordering:
 578   # 1.  try python3, but respect the user's preference on which minor ver
 579   # 2.  try python, which might be py3 or py2 again on the user's preference
 580   # 3.  try python2 (can really only be 2.7 but eh)
 581   # 4.  try 3.6 > 3.5 > 3.4 > 3.3 > 3.2 > 2.7 through pkg-config (no user pref)
 582   #
 583   # (AX_PYTHON_DEVEL has no clue about py3 vs py2)
 584   # (AX_PYTHON does not do what we need)
 585
 586   AC_CHECK_TOOLS([PYTHONCONFIG], [ \
 587         python3-config \
 588         python-config \
 589         python2-config \
 590         python3.6-config \
 591         python3.5-config \
 592         python3.4-config \
 593         python3.3-config \
 594         python3.2-config \
 595         python2.7-config ])
 596   if test -n "$PYTHONCONFIG"; then
 597     PYTHON_CFLAGS="`\"${PYTHONCONFIG}\" --includes`"
 598     PYTHON_LIBS="`\"${PYTHONCONFIG}\" --ldflags`"
 599
 600     FRR_PYTHON_CHECK_WORKING([])
 601   fi
 602
 603   if test -z "$PYTHONCONFIG"; then
 604     PKG_CHECK_MODULES([PYTHON], python-3.6, [], [
 605       PKG_CHECK_MODULES([PYTHON], python-3.5, [], [
 606         PKG_CHECK_MODULES([PYTHON], python-3.4, [], [
 607           PKG_CHECK_MODULES([PYTHON], python-3.3, [], [
 608             PKG_CHECK_MODULES([PYTHON], python-3.2, [], [
 609               PKG_CHECK_MODULES([PYTHON], python-2.7, [], [
 610                 AC_MSG_FAILURE([could not find python-config or pkg-config python, please install Python development files from libpython-dev or similar])
 611                 ])])])])])])
 612
 613
 614     FRR_PYTHON_CHECK_WORKING([
 615       AC_MSG_FAILURE([could not find python-config or pkg-config python, please install Python development files from libpython-dev or similar])
 616     ])
 617   fi
 618 ])
 619 AC_SUBST(PYTHON_CFLAGS)
 620 AC_SUBST(PYTHON_LIBS)
 621
 622 #
 623 # Logic for protobuf support.
 624 #
 625 if test "$enable_protobuf" = "yes"; then
 626    have_protobuf=yes
 627
 628    # Check for protoc-c
 629    AC_CHECK_PROG([PROTOC_C], [protoc-c], [protoc-c], [/bin/false])
 630    if test "x$PROTOC_C" = "x/bin/false"; then
 631       have_protobuf=no
 632    else
 633       found_protobuf_c=no
 634       PKG_CHECK_MODULES([PROTOBUF_C], libprotobuf-c >= 0.14,
 635                      [found_protobuf_c=yes],
 636                      [AC_MSG_RESULT([pkg-config did not find libprotobuf-c])])
 637
 638       if test "x$found_protobuf_c" = "xyes"; then
 639          LDFLAGS="$LDFLAGS $PROTOBUF_C_LIBS"
 640          CFLAGS="$CFLAGS $PROTOBUF_C_CFLAGS"
 641       else
 642         AC_CHECK_HEADER([google/protobuf-c/protobuf-c.h], [],
 643                         [have_protobuf=no; AC_MSG_RESULT([Couldn't find google/protobuf-c.h])])
 644       fi
 645    fi
 646 fi
 647
 648 #
 649 # Logic for old vpn commans support.
 650 #
 651 if test "$enable_oldvpn_commands" = "yes"; then
 652    AC_DEFINE(KEEP_OLD_VPN_COMMANDS,, [Define for compiling with old vpn commands])
 653 fi
 654
 655 # Fail if the user explicity enabled protobuf support and we couldn't
 656 # find the compiler or libraries.
 657 if test "x$have_protobuf" = "xno" && test "x$enable_protobuf" = "xyes"; then
 658    AC_MSG_ERROR([Protobuf enabled explicitly but can't find libraries/tools])
 659 fi
 660
 661 if test "x$have_protobuf" = "xyes"; then
 662    AC_DEFINE(HAVE_PROTOBUF,, protobuf)
 663 fi
 664
 665 AM_CONDITIONAL([HAVE_PROTOBUF], [test "x$have_protobuf" = "xyes"])
 666
 667 #
 668 # End of logic for protobuf support.
 669 #
 670
 671 AC_MSG_CHECKING(if zebra should be configurable to send Route Advertisements)
 672 if test "${enable_rtadv}" != "no"; then
 673   AC_MSG_RESULT(yes)
 674   AC_DEFINE(HAVE_RTADV,,Enable IPv6 Routing Advertisement support)
 675 else
 676   AC_MSG_RESULT(no)
 677 fi
 678
 679 if test x"${enable_user}" = x"no"; then
 680   enable_user=""
 681 else
 682   if test x"${enable_user}" = x"yes" || test x"${enable_user}" = x""; then
 683     enable_user="frr"
 684   fi
 685   AC_DEFINE_UNQUOTED(FRR_USER, "${enable_user}", frr User)
 686 fi
 687
 688 if test x"${enable_group}" = x"no"; then
 689   enable_group=""
 690 else
 691   if test x"${enable_group}" = x"yes" || test x"${enable_group}" = x""; then
 692     enable_group="frr"
 693   fi
 694   AC_DEFINE_UNQUOTED(FRR_GROUP, "${enable_group}", frr Group)
 695 fi
 696
 697 if test x"${enable_vty_group}" = x"yes" ; then
 698   AC_MSG_ERROR([--enable-vty-group requires a group as argument, not yes])
 699 elif test x"${enable_vty_group}" != x""; then
 700   if test x"${enable_vty_group}" != x"no"; then
 701     AC_DEFINE_UNQUOTED(VTY_GROUP, "${enable_vty_group}", VTY Sockets Group)
 702   fi
 703 fi
 704 AC_SUBST([enable_user])
 705 AC_SUBST([enable_group])
 706 AC_SUBST([enable_vty_group])
 707
 708 enable_configfile_mask=${enable_configfile_mask:-0600}
 709 AC_DEFINE_UNQUOTED(CONFIGFILE_MASK, ${enable_configfile_mask}, Mask for config files)
 710
 711 enable_logfile_mask=${enable_logfile_mask:-0600}
 712 AC_DEFINE_UNQUOTED(LOGFILE_MASK, ${enable_logfile_mask}, Mask for log files)
 713
 714 MPATH_NUM=1
 715
 716 case "${enable_multipath}" in
 717   0)
 718     MPATH_NUM=64
 719     ;;
 720   [[1-9]|[1-9][0-9]|[1-9][0-9][0-9]])
 721     MPATH_NUM="${enable_multipath}"
 722     ;;
 723   "")
 724     ;;
 725   *)
 726     AC_MSG_FAILURE([Please specify digit to enable multipath ARG])
 727     ;;
 728 esac
 729
 730 AC_DEFINE_UNQUOTED(MULTIPATH_NUM, $MPATH_NUM, Maximum number of paths for a route)
 731
 732 AC_DEFINE_UNQUOTED(VTYSH_PAGER, "$VTYSH_PAGER", [What pager to use])
 733
 734 dnl --------------------
 735 dnl Enable code coverage
 736 dnl --------------------
 737 AM_CONDITIONAL([HAVE_GCOV],[test '!' "$enable_gcov" = no])
 738
 739 dnl ------------------------------------
 740 dnl Alpine only accepts numeric versions
 741 dnl ------------------------------------
 742 if test "x${enable_numeric_version}" != "x" ; then
 743   VERSION="`echo ${VERSION} | tr -c -d '[[.0-9]]'`"
 744   PACKAGE_VERSION="`echo ${PACKAGE_VERSION} | tr -c -d '[[.0-9]]'`"
 745 fi
 746
 747 dnl -----------------------------------
 748 dnl Add extra version string to package
 749 dnl name, string and version fields.
 750 dnl -----------------------------------
 751 if test "x${EXTRAVERSION}" != "x" ; then
 752   VERSION="${VERSION}${EXTRAVERSION}"
 753   PACKAGE_VERSION="${PACKAGE_VERSION}${EXTRAVERSION}"
 754   AC_SUBST(PACKAGE_EXTRAVERSION, ["${EXTRAVERSION}"])
 755   PACKAGE_STRING="${PACKAGE_STRING}${EXTRAVERSION}"
 756 fi
 757
 758 if test "x$with_pkg_git_version" = "xyes"; then
 759         if test -d "${srcdir}/.git"; then
 760                 AC_DEFINE(GIT_VERSION, [1], [include git version info])
 761         else    with_pkg_git_version="no"
 762                 AC_MSG_WARN([--with-pkg-git-version given, but this is not a git checkout])
 763         fi
 764 fi
 765 AM_CONDITIONAL([GIT_VERSION], [test "x$with_pkg_git_version" = "xyes"])
 766
 767 dnl ------------------------------------
 768 dnl Check C keywords and standard  types
 769 dnl ------------------------------------
 770 AC_C_CONST
 771 AC_C_INLINE
 772 AC_C_VOLATILE
 773 AC_HEADER_STDC
 774 dnl AC_TYPE_PID_T
 775 AC_TYPE_UID_T
 776 AC_TYPE_MODE_T
 777 AC_TYPE_SIZE_T
 778 AC_STRUCT_TM
 779
 780 dnl -------------------------
 781 dnl Check other header files.
 782 dnl -------------------------
 783 AC_CHECK_HEADERS([stropts.h sys/ksym.h \
 784         linux/version.h asm/types.h \
 785         sys/cdefs.h])
 786
 787 ac_stdatomic_ok=false
 788 AC_DEFINE(FRR_AUTOCONF_ATOMIC, 1, [did autoconf checks for atomic funcs])
 789 AC_CHECK_HEADER([stdatomic.h],[
 790
 791   AC_MSG_CHECKING([whether _Atomic qualifier works])
 792   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 793 #include <stdatomic.h>
 794 int main(int argc, char **argv) {
 795   _Atomic int i = 0;
 796   return i;
 797 }
 798 ]])], [
 799     AC_DEFINE(HAVE_STDATOMIC_H, 1, [found stdatomic.h])
 800     AC_MSG_RESULT([yes])
 801     ac_stdatomic_ok=true
 802   ], [
 803     AC_MSG_RESULT([no])
 804   ])
 805 ])
 806
 807 AS_IF([$ac_stdatomic_ok], [true], [
 808   AC_MSG_CHECKING([for __atomic_* builtins])
 809   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 810 int main(int argc, char **argv) {
 811   volatile int i = 1;
 812   __atomic_store_n (&i, 0, __ATOMIC_RELEASE);
 813   return __atomic_load_n (&i, __ATOMIC_ACQUIRE);
 814 }
 815 ]])], [
 816     AC_DEFINE(HAVE___ATOMIC, 1, [found __atomic builtins])
 817     AC_MSG_RESULT([yes])
 818   ], [
 819     AC_MSG_RESULT([no])
 820
 821     dnl FreeBSD 9 has a broken stdatomic.h where _Atomic doesn't work
 822     AC_MSG_CHECKING([for __sync_* builtins])
 823     AC_LINK_IFELSE([AC_LANG_SOURCE([[
 824 int main(int argc, char **argv) {
 825   volatile int i = 1;
 826   __sync_fetch_and_sub (&i, 1);
 827   return __sync_val_compare_and_swap (&i, 0, 1);
 828 }
 829 ]])], [
 830       AC_DEFINE(HAVE___SYNC, 1, [found __sync builtins])
 831       AC_MSG_RESULT([yes])
 832
 833       AC_MSG_CHECKING([for __sync_swap builtin])
 834       AC_LINK_IFELSE([AC_LANG_SOURCE([[
 835 int main(int argc, char **argv) {
 836   volatile int i = 1;
 837   return __sync_swap (&i, 2);
 838 }
 839 ]])], [
 840         AC_DEFINE(HAVE___SYNC_SWAP, 1, [found __sync_swap builtin])
 841         AC_MSG_RESULT([yes])
 842       ], [
 843         AC_MSG_RESULT([no])
 844       ])
 845
 846     ], [
 847       AC_MSG_RESULT([no])
 848       AC_MSG_FAILURE([stdatomic.h unavailable and $CC has neither __atomic nor __sync builtins])
 849     ])
 850   ])
 851 ])
 852
 853 dnl Utility macro to avoid retyping includes all the time
 854 m4_define([FRR_INCLUDES],
 855 [#ifdef SUNOS_5
 856 #define _XPG4_2
 857 #define __EXTENSIONS__
 858 #endif
 859 #include <stdio.h>
 860 #include <stdlib.h>
 861 #include <stddef.h>
 862 #include <sys/types.h>
 863 /* sys/conf.h depends on param.h on FBSD at least */
 864 #include <sys/param.h>
 865 /* Required for MAXSIG */
 866 #include <signal.h>
 867 #include <sys/socket.h>
 868 #ifdef __APPLE__
 869 # define __APPLE_USE_RFC_3542
 870 #endif
 871 #include <netinet/in.h>
 872 #include <sys/time.h>
 873 #include <time.h>
 874 #include <net/if.h>
 875 ])dnl
 876
 877 dnl Same applies for HAVE_NET_IF_VAR_H, which HAVE_NETINET6_ND6_H and
 878 dnl HAVE_NETINET_IN_VAR_H depend upon. But if_var.h depends on if.h, hence
 879 dnl an additional round for it.
 880
 881 AC_CHECK_HEADERS([net/if_var.h], [], [], FRR_INCLUDES)
 882
 883 m4_define([FRR_INCLUDES],
 884 FRR_INCLUDES
 885 [#if HAVE_NET_IF_VAR_H
 886 # include <net/if_var.h>
 887 #endif
 888 ])dnl
 889
 890 AC_CHECK_HEADERS([netinet/in_var.h \
 891         net/if_dl.h net/netopt.h \
 892         inet/nd.h netinet/ip_icmp.h \
 893         sys/sysctl.h sys/sockio.h kvm.h sys/conf.h],
 894         [], [], FRR_INCLUDES)
 895
 896 AC_CHECK_HEADERS([ucontext.h], [], [],
 897 [#ifndef __USE_GNU
 898 #define __USE_GNU
 899 #endif /* __USE_GNU */
 900 FRR_INCLUDES
 901 ])
 902
 903 m4_define([UCONTEXT_INCLUDES],
 904 [#include <ucontext.h>])dnl
 905
 906 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.uc_regs],
 907   [], [], [UCONTEXT_INCLUDES])
 908 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs],
 909   [AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs.nip],
 910    [], [], [UCONTEXT_INCLUDES])],
 911   [], [UCONTEXT_INCLUDES])
 912 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.gregs],
 913   [], [], [UCONTEXT_INCLUDES])
 914
 915 m4_define([FRR_INCLUDES],
 916 FRR_INCLUDES
 917 [
 918 #include <sys/un.h>
 919 #include <netinet/in_systm.h>
 920 #if HAVE_NETINET_IN_VAR_H
 921 # include <netinet/in_var.h>
 922 #endif
 923 #if HAVE_NET_IF_DL_H
 924 # include <net/if_dl.h>
 925 #endif
 926 #if HAVE_NET_NETOPT_H
 927 # include <net/netopt.h>
 928 #endif
 929 #include <net/route.h>
 930 #if HAVE_INET_ND_H
 931 # include <inet/nd.h>
 932 #endif
 933 #include <arpa/inet.h>
 934 /* Required for IDRP */
 935 #if HAVE_NETINET_IP_ICMP_H
 936 # include <netinet/ip_icmp.h>
 937 #endif
 938 ])dnl
 939
 940 dnl V6 headers are checked below, after we check for v6
 941
 942 AC_MSG_CHECKING([which operating system interface to use])
 943 case "$host_os" in
 944   sunos* | solaris2*)
 945     AC_MSG_RESULT([Solaris])
 946
 947     AC_DEFINE(SUNOS_5, 1, [SunOS 5])
 948     AC_DEFINE(SOLARIS_IPV6, 1, Solaris IPv6)
 949
 950     AC_CHECK_LIB(socket, main)
 951     AC_CHECK_LIB(nsl, main)
 952     AC_CHECK_LIB(umem, main)
 953     AC_CHECK_FUNCS([printstack], [
 954       AC_DEFINE([HAVE_PRINTSTACK],1,[Solaris printstack])
 955       AC_DEFINE([HAVE_STACK_TRACE],1,[Stack symbols decode functionality])
 956     ])
 957     CURSES=-lcurses
 958     SOLARIS="solaris"
 959     ;;
 960   linux*)
 961     AC_MSG_RESULT([Linux])
 962
 963     AC_DEFINE(GNU_LINUX,,GNU Linux)
 964     AC_DEFINE(HAVE_NETLINK,,netlink)
 965     AC_DEFINE(LINUX_IPV6,1,Linux IPv6 stack)
 966
 967     dnl Linux has a compilation problem with mixing
 968     dnl netinet/in.h and linux/in6.h they are not
 969     dnl compatible.  There has been discussion on
 970     dnl how to fix it but no real progress on implementation
 971     dnl when they fix it, remove this
 972     AC_DEFINE(IPV6_MINHOPCOUNT, 73, Linux ipv6 Min Hop Count)
 973     ;;
 974   openbsd*)
 975     AC_MSG_RESULT([OpenBSD])
 976
 977     AC_DEFINE(OPEN_BSD,,OpenBSD)
 978     AC_DEFINE(KAME,1,KAME IPv6)
 979     AC_DEFINE(BSD_V6_SYSCTL,1,BSD v6 sysctl to turn on and off forwarding)
 980
 981     if test "x${enable_pimd}" != "xno"; then
 982       case "$host_os" in
 983       openbsd6.0)
 984         ;;
 985       openbsd[6-9]*)
 986         AC_MSG_FAILURE([pimd cannot be enabled as PIM support has been removed from OpenBSD 6.1])
 987         ;;
 988       esac
 989     fi
 990     ;;
 991   *)
 992     AC_MSG_RESULT([BSD])
 993
 994     AC_DEFINE(HAVE_NET_RT_IFLIST,,NET_RT_IFLIST)
 995     AC_DEFINE(KAME,1,KAME IPv6)
 996     AC_DEFINE(BSD_V6_SYSCTL,1,BSD v6 sysctl to turn on and off forwarding)
 997     ;;
 998 esac
 999 AM_CONDITIONAL(SOLARIS, test "${SOLARIS}" = "solaris")
1000
1001 AC_SYS_LARGEFILE
1002
1003 dnl ------------------------
1004 dnl Integrated REALMS option
1005 dnl ------------------------
1006 if test "${enable_realms}" = "yes"; then
1007     case "$host_os" in
1008       linux*)
1009        AC_DEFINE(SUPPORT_REALMS,, Realms support)
1010        ;;
1011       *)
1012        echo "Sorry, only Linux has REALMS support"
1013        exit 1
1014        ;;
1015     esac
1016 fi
1017 AM_CONDITIONAL([SUPPORT_REALMS], [test "${enable_realms}" = "yes"])
1018
1019 dnl ---------------------
1020 dnl Integrated VTY option
1021 dnl ---------------------
1022 case "${enable_vtysh}" in
1023   "no") VTYSH="";;
1024   *)    VTYSH="vtysh";
1025          AC_DEFINE(VTYSH,,VTY shell)
1026 dnl      Vtysh uses libreadline, which looks for termcap functions at
1027 dnl      configure time.  We follow readlines search order.
1028 dnl      The required procedures are in libtermcap on NetBSD, in
1029 dnl      [TODO] on Linux, and in [TODO] on Solaris.
1030          AC_CHECK_LIB(termcap, tputs, LIBREADLINE="$LIBREADLINE -ltermcap",
1031            [AC_CHECK_LIB(tinfo, tputs, LIBREADLINE="$LIBREADLINE -ltinfo",
1032              [AC_CHECK_LIB(curses, tputs, LIBREADLINE="$LIBREADLINE -lcurses",
1033                [AC_CHECK_LIB(ncurses, tputs,
1034                              LIBREADLINE="$LIBREADLINE -lncurses")]
1035               )]
1036             )]
1037           )
1038          AC_CHECK_LIB(readline, main, LIBREADLINE="-lreadline $LIBREADLINE",,
1039                       "$LIBREADLINE")
1040          if test $ac_cv_lib_readline_main = no; then
1041            AC_MSG_ERROR([vtysh needs libreadline but was not found and usable on your system.])
1042          fi
1043          AC_CHECK_HEADER(readline/history.h)
1044          if test $ac_cv_header_readline_history_h = no;then
1045            AC_MSG_ERROR([readline is too old to have readline/history.h, please update to the latest readline library.])
1046          fi
1047          AC_CHECK_LIB(readline, rl_completion_matches,
1048                       LIBREADLINE="$LIBREADLINE",, "$LIBREADLINE")
1049          if test $ac_cv_lib_readline_rl_completion_matches = no; then
1050            AC_DEFINE(rl_completion_matches,completion_matches,Old readline)
1051          fi
1052          ;;
1053 esac
1054 AC_SUBST(LIBREADLINE)
1055 AM_CONDITIONAL(VTYSH, test "x$VTYSH" = "xvtysh")
1056
1057 dnl ----------
1058 dnl PAM module
1059 dnl
1060 dnl FRR detects the PAM library it is built against by checking for a
1061 dnl functional pam_misc.h (Linux-PAM) or openpam.h (OpenPAM) header. pam_misc.h
1062 dnl is known to #include pam_appl.h, the standard header of a PAM library, and
1063 dnl openpam.h doesn't do that, although depends on the header too. Hence a
1064 dnl little assistance to AC_CHECK_HEADER is necessary for the proper detection
1065 dnl of OpenPAM.
1066 dnl ----------
1067 if test "$with_libpam" = "yes"; then
1068   AC_CHECK_HEADER([security/pam_misc.h],
1069     [AC_DEFINE(HAVE_PAM_MISC_H,,Have pam_misc.h)
1070      AC_DEFINE(PAM_CONV_FUNC,misc_conv,Have misc_conv)
1071      pam_conv_func="misc_conv"
1072     ],
1073     [], FRR_INCLUDES)
1074   AC_CHECK_HEADER([security/openpam.h],
1075     [AC_DEFINE(HAVE_OPENPAM_H,,Have openpam.h)
1076      AC_DEFINE(PAM_CONV_FUNC,openpam_ttyconv,Have openpam_ttyconv)
1077      pam_conv_func="openpam_ttyconv"
1078     ],
1079     [], FRR_INCLUDES[#include <security/pam_appl.h>])
1080   if test -z "$ac_cv_header_security_pam_misc_h$ac_cv_header_security_openpam_h" ; then
1081     AC_MSG_WARN([*** pam support will not be built ***])
1082     with_libpam="no"
1083   fi
1084 fi
1085
1086 if test "$with_libpam" = "yes"; then
1087 dnl took this test from proftpds configure.in and suited to our needs
1088 dnl -------------------------------------------------------------------------
1089 dnl
1090 dnl This next check looks funky due to a linker problem with some versions
1091 dnl of the PAM library.  Prior to 0.72 release, the Linux PAM shared library
1092 dnl omitted requiring libdl linking information. PAM-0.72 or better ships
1093 dnl with RedHat 6.2 and Debian 2.2 or better.
1094 AC_CHECK_LIB(pam, pam_start,
1095   [AC_CHECK_LIB(pam, $pam_conv_func,
1096     [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1097      LIBPAM="-lpam"],
1098     [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1099      LIBPAM="-lpam -lpam_misc"]
1100     )
1101   ],
1102
1103   [AC_CHECK_LIB(pam, pam_end,
1104     [AC_CHECK_LIB(pam, $pam_conv_func,
1105       [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1106        LIBPAM="-lpam -ldl"],
1107       [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1108        LIBPAM="-lpam -ldl -lpam_misc"]
1109      )
1110   ],AC_MSG_WARN([*** pam support will not be built ***]),
1111   [-ldl])
1112   ]
1113 )
1114 fi
1115 AC_SUBST(LIBPAM)
1116
1117 dnl -------------------------------
1118 dnl Endian-ness check
1119 dnl -------------------------------
1120 AC_WORDS_BIGENDIAN
1121
1122 dnl -------------------------------
1123 dnl check the size in byte of the C
1124 dnl -------------------------------
1125 dnl AC_CHECK_SIZEOF(char)
1126 dnl AC_CHECK_SIZEOF(int)
1127 dnl AC_CHECK_SIZEOF(short)
1128 dnl AC_CHECK_SIZEOF(long)
1129
1130 dnl ----------------------------
1131 dnl check existance of functions
1132 dnl ----------------------------
1133 AC_FUNC_FNMATCH
1134 AC_FUNC_FORK
1135 AC_FUNC_MKTIME
1136 AC_FUNC_STAT
1137
1138 dnl -------------------------------
1139 dnl bgpd needs pow() and hence libm
1140 dnl -------------------------------
1141 TMPLIBS="$LIBS"
1142 AC_CHECK_HEADER([math.h],
1143   [AC_CHECK_LIB([m], [pow],
1144     [LIBM="-lm"
1145      LIBS="$LIBS $LIBM"
1146      AC_CHECK_FUNCS(pow,[],[LIBM=""])
1147     ])
1148 ])
1149 if test x"$LIBM" = x ; then
1150   AC_MSG_WARN([Unable to find working pow function - bgpd may not link])
1151 fi
1152 LIBS="$TMPLIBS"
1153 AC_SUBST(LIBM)
1154
1155 AC_CHECK_FUNCS([ppoll], [
1156   AC_DEFINE([HAVE_PPOLL], 1, [have Linux/BSD ppoll()])
1157 ])
1158 AC_CHECK_FUNCS([pollts], [
1159   AC_DEFINE([HAVE_POLLTS], 1, [have NetBSD pollts()])
1160 ])
1161
1162 dnl ---------------
1163 dnl other functions
1164 dnl ---------------
1165 AC_CHECK_FUNCS([ \
1166         strlcat strlcpy \
1167         getgrouplist])
1168
1169 AC_CHECK_HEADER([asm-generic/unistd.h],
1170                 [AC_CHECK_DECL(__NR_setns,
1171                                AC_DEFINE(HAVE_NETNS,, Have netns),,
1172                                FRR_INCLUDES [#include <asm-generic/unistd.h>
1173                                ])
1174                  AC_CHECK_FUNCS(setns)]
1175                )
1176
1177 dnl --------------------------
1178 dnl Determine IS-IS I/O method
1179 dnl --------------------------
1180 AC_DEFINE(ISIS_METHOD_PFPACKET, 1, [ constant value for isis method pfpacket ])
1181 AC_DEFINE(ISIS_METHOD_DLPI,     2, [ constant value for isis method dlpi ])
1182 AC_DEFINE(ISIS_METHOD_BPF,      3, [ constant value for isis method bpf ])
1183 AC_CHECK_HEADER(net/bpf.h)
1184 AC_CHECK_HEADER(sys/dlpi.h)
1185 AC_MSG_CHECKING(zebra IS-IS I/O method)
1186
1187 case "$host_os" in
1188   linux*)
1189     AC_MSG_RESULT(pfpacket)
1190     ISIS_METHOD_MACRO="ISIS_METHOD_PFPACKET"
1191     ;;
1192   solaris* | sunos*)
1193     AC_MSG_RESULT(DLPI)
1194     ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1195     ;;
1196   *)
1197     if test $ac_cv_header_net_bpf_h = no; then
1198       if test $ac_cv_header_sys_dlpi_h = no; then
1199         AC_MSG_RESULT(none)
1200         if test "${enable_isisd}" = yes; then
1201           AC_MSG_FAILURE([IS-IS support requested but no packet backend found])
1202         fi
1203         AC_MSG_WARN([*** IS-IS support will not be built ***])
1204         enable_isisd="no"
1205       else
1206         AC_MSG_RESULT(DLPI)
1207       fi
1208       ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1209     else
1210       AC_MSG_RESULT(BPF)
1211       ISIS_METHOD_MACRO="ISIS_METHOD_BPF"
1212     fi
1213     ;;
1214 esac
1215 AC_DEFINE_UNQUOTED(ISIS_METHOD, $ISIS_METHOD_MACRO, [ selected method for isis, == one of the constants ])
1216
1217 dnl ---------------------------------------------------------------
1218 dnl figure out how to specify an interface in multicast sockets API
1219 dnl ---------------------------------------------------------------
1220 AC_CHECK_MEMBERS([struct ip_mreqn.imr_ifindex], [], [], FRR_INCLUDES)
1221
1222 AC_CHECK_HEADERS([linux/mroute.h], [], [],[
1223         #include <sys/socket.h>
1224         #include <netinet/in.h>
1225         #define _LINUX_IN_H             /* For Linux <= 2.6.25 */
1226         #include <linux/types.h>
1227 ])
1228
1229 m4_define([FRR_INCLUDES],
1230 FRR_INCLUDES
1231 [#if HAVE_LINUX_MROUTE_H
1232 # include <linux/mroute.h>
1233 #endif
1234 ])dnl
1235
1236 AC_CHECK_HEADERS([netinet/ip_mroute.h], [], [],[
1237         #include <sys/socket.h>
1238         #include <sys/types.h>
1239         #include <netinet/in.h>
1240         #include <net/route.h>
1241 ])
1242
1243 m4_define([FRR_INCLUDES],
1244 FRR_INCLUDES
1245 [#if HAVE_NETINET_IP_MROUTE_H
1246 # include <netinet/ip_mroute.h>
1247 #endif
1248 ])dnl
1249
1250 AC_MSG_CHECKING([for BSD struct ip_mreq hack])
1251 AC_TRY_COMPILE([#include <sys/param.h>],
1252 [#if (defined(__FreeBSD__) && ((__FreeBSD_version >= 500022 && __FreeBSD_version < 700000) || (__FreeBSD_version < 500000 && __FreeBSD_version >= 440000))) || (defined(__NetBSD__) && defined(__NetBSD_Version__) && __NetBSD_Version__ >= 106010000) || defined(__OpenBSD__) || defined(__APPLE__) || defined(__DragonFly__) || defined(__sun)
1253   return (0);
1254 #else
1255   #error No support for BSD struct ip_mreq hack detected
1256 #endif],[AC_MSG_RESULT(yes)
1257 AC_DEFINE(HAVE_BSD_STRUCT_IP_MREQ_HACK,,[Can pass ifindex in struct ip_mreq])],
1258 AC_MSG_RESULT(no))
1259
1260 AC_MSG_CHECKING([for RFC3678 protocol-independed API])
1261 AC_TRY_COMPILE([
1262 #include <sys/types.h>
1263 #include <netinet/in.h>
1264 ], [struct group_req gr; int sock; setsockopt(sock, IPPROTO_IP, MCAST_JOIN_GROUP, (void*)&gr, sizeof(gr));
1265 ], [AC_MSG_RESULT(yes)
1266 AC_DEFINE(HAVE_RFC3678,1,[Have RFC3678 protocol-independed API])],
1267 AC_MSG_RESULT(no))
1268
1269 dnl ---------------------------------------------------------------
1270 dnl figure out how to check link-state
1271 dnl ---------------------------------------------------------------
1272 AC_CHECK_HEADER( [net/if_media.h],
1273   [m4_define([LINK_DETECT_INCLUDES],
1274     FRR_INCLUDES
1275     [#include <net/if_media.h>
1276   ])
1277   AC_CHECK_MEMBERS( [struct ifmediareq.ifm_status],
1278     AC_DEFINE(HAVE_BSD_LINK_DETECT,,[BSD link-detect]),
1279     [], LINK_DETECT_INCLUDES)],
1280   [],
1281   FRR_INCLUDES)
1282
1283 dnl ---------------------------------------------------------------
1284 dnl Additional, newer way to check link-state using ifi_link_state.
1285 dnl Not available in all BSD's when ifmediareq available
1286 dnl ---------------------------------------------------------------
1287 AC_CHECK_MEMBERS([struct if_data.ifi_link_state],
1288   AC_DEFINE(HAVE_BSD_IFI_LINK_STATE,,[BSD ifi_link_state available]),
1289   [], FRR_INCLUDES)
1290
1291 dnl ------------------------
1292 dnl TCP_MD5SIG socket option
1293 dnl ------------------------
1294
1295 AC_CHECK_HEADER([netinet/tcp.h],
1296    [m4_define([MD5_INCLUDES],
1297       FRR_INCLUDES
1298       [#include <netinet/tcp.h>
1299     ])
1300     AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)],
1301    [],
1302    FRR_INCLUDES)
1303 if test $ac_cv_have_decl_TCP_MD5SIG = no; then
1304   AC_CHECK_HEADER([linux/tcp.h],
1305        [m4_define([MD5_INCLUDES],
1306           FRR_INCLUDES
1307           [#include <linux/tcp.h>
1308         ])
1309        AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)])
1310 fi
1311
1312 dnl ----------------------------------------------------------------------------
1313 dnl figure out if domainname is available in the utsname struct (GNU extension).
1314 dnl ----------------------------------------------------------------------------
1315 AC_CHECK_MEMBERS([struct utsname.domainname], [], [], [#include <sys/utsname.h>])
1316
1317 dnl ------------------
1318 dnl IPv6 header checks
1319 dnl ------------------
1320 AC_CHECK_HEADERS([netinet6/in6.h netinet/in6_var.h \
1321         netinet6/in6_var.h netinet6/nd6.h], [], [],
1322         FRR_INCLUDES)
1323
1324 m4_define([FRR_INCLUDES],dnl
1325 FRR_INCLUDES
1326 [#if HAVE_NETINET6_IN6_H
1327 #include <netinet6/in6.h>
1328 #endif
1329 #if HAVE_NETINET_IN6_VAR_H
1330 #include <netinet/in6_var.h>
1331 #endif
1332 #include <netinet/icmp6.h>
1333 #if HAVE_NETINET6_IN6_VAR_H
1334 # include <netinet6/in6_var.h>
1335 #endif
1336 #if HAVE_NETINET6_ND6_H
1337 # include <netinet6/nd6.h>
1338 #endif
1339 ])dnl
1340
1341 dnl disable doc check
1342 AC_CHECK_PROGS([SPHINXBUILD], [sphinx-build sphinx-build3 sphinx-build2], [no])
1343 AM_CONDITIONAL(DOC, test "${enable_doc}" != "no")
1344 AM_CONDITIONAL(DOC_HTML, test "${enable_doc_html}" = "yes")
1345
1346 dnl --------------------
1347 dnl Daemon disable check
1348 dnl --------------------
1349 AM_CONDITIONAL(ZEBRA, test "${enable_zebra}" != "no")
1350
1351 if test "${enable_bgpd}" = "no";then
1352   BGPD=""
1353 else
1354   BGPD="bgpd"
1355 fi
1356 AM_CONDITIONAL(BGPD, test "x$BGPD" = "xbgpd")
1357
1358 AM_CONDITIONAL(RIPD, test "${enable_ripd}" != "no")
1359 AM_CONDITIONAL(OSPFD, test "${enable_ospfd}" != "no")
1360 AM_CONDITIONAL(LDPD, test "${enable_ldpd}" != "no")
1361
1362 AS_IF([test "${enable_ldpd}" != "no"], [
1363   AC_DEFINE(HAVE_LDPD, 1, ldpd)
1364 ])
1365
1366 if test "$enable_bfdd" = "no"; then
1367   AC_DEFINE(HAVE_BFDD, 0, bfdd)
1368   BFDD=""
1369 else
1370   AC_DEFINE(HAVE_BFDD, 1, bfdd)
1371   BFDD="bfdd"
1372
1373   case $host_os in
1374     linux*)
1375       AC_DEFINE(BFD_LINUX, 1, bfdd)
1376       ;;
1377
1378     *)
1379       AC_DEFINE(BFD_BSD, 1, bfdd)
1380       ;;
1381   esac
1382 fi
1383
1384 AM_CONDITIONAL(BFDD, [test "x$BFDD" = "xbfdd"])
1385
1386 if test $ac_cv_lib_json_c_json_object_get = no -a "x$BFDD" = "xbfdd"; then
1387   AC_MSG_ERROR(["you must use json-c library to use bfdd"])
1388 fi
1389
1390 NHRPD=""
1391 case "$host_os" in
1392   linux*)
1393     if test "${enable_nhrpd}" != "no"; then
1394       NHRPD="nhrpd"
1395     fi
1396     ;;
1397   *)
1398     if test "${enable_nhrpd}" = "yes"; then
1399       AC_MSG_ERROR([nhrpd requires kernel APIs that are only present on Linux.])
1400     fi
1401     ;;
1402 esac
1403 AM_CONDITIONAL(NHRPD, test "x$NHRPD" = "xnhrpd")
1404
1405 AM_CONDITIONAL(EIGRPD, test "${enable_eigrpd}" != "no")
1406
1407 if test "${enable_watchfrr}" = "no";then
1408   WATCHFRR=""
1409 else
1410   WATCHFRR="watchfrr"
1411 fi
1412 AM_CONDITIONAL(WATCHFRR, test "x$WATCHFRR" = "xwatchfrr")
1413
1414 OSPFCLIENT=""
1415 if test "${enable_ospfapi}" != "no";then
1416     AC_DEFINE(SUPPORT_OSPF_API,,OSPFAPI)
1417
1418   if test "${enable_ospfclient}" != "no";then
1419       OSPFCLIENT="ospfclient"
1420   fi
1421 fi
1422
1423 AM_CONDITIONAL(OSPFCLIENT, test "x$OSPFCLIENT" = "xospfclient")
1424 AM_CONDITIONAL(RIPNGD, test "${enable_ripngd}" != "no")
1425 AM_CONDITIONAL(BABELD, test "${enable_babeld}" != "no")
1426 AM_CONDITIONAL(OSPF6D, test "${enable_ospf6d}" != "no")
1427 AM_CONDITIONAL(ISISD, test "${enable_isisd}" != "no")
1428 AM_CONDITIONAL(PIMD, test "${enable_pimd}" != "no")
1429 AM_CONDITIONAL(PBRD, test "${enable_pbrd}" != "no")
1430 AM_CONDITIONAL(SHARPD, test "${enable_sharpd}" = "yes")
1431 AM_CONDITIONAL(STATICD, test "${enable_staticd}" != "no")
1432
1433 if test "${enable_bgp_announce}" = "no";then
1434   AC_DEFINE(DISABLE_BGP_ANNOUNCE,1,Disable BGP installation to zebra)
1435 else
1436   AC_DEFINE(DISABLE_BGP_ANNOUNCE,0,Disable BGP installation to zebra)
1437 fi
1438
1439 if test "${with_rfp_path}" = "yes" || test x"${with_rfp_path}" = x""; then
1440   with_rfp_path="bgpd/rfp-example"
1441 fi
1442 if test "${with_rfp_path}" != "no"; then
1443   VNC_RFP_PATH="${with_rfp_path}"
1444   AC_SUBST(VNC_RFP_PATH)
1445 fi
1446
1447 if test "${enable_bgp_vnc}" != "no";then
1448   AC_DEFINE(ENABLE_BGP_VNC,1,Enable BGP VNC support)
1449   RFPTEST="${with_rfp_path}/rfptest"
1450   LIBRFP="${with_rfp_path}/librfp"
1451   RFPINC="${with_rfp_path}/librfp"
1452 else
1453   RFPTEST=
1454   LIBRFP=
1455   RFPINC="bgpd/rfp-example/librfp"
1456 fi
1457 # set
1458 AM_CONDITIONAL([ENABLE_BGP_VNC], [test x${enable_bgp_vnc} != xno])
1459
1460 AC_SUBST(RFPTEST)
1461 AC_SUBST(LIBRFP)
1462 AC_SUBST(RFPINC)
1463 AC_SUBST(BGPD)
1464 AC_SUBST(SOLARIS)
1465 AC_SUBST(VTYSH)
1466 AC_SUBST(CURSES)
1467 AC_CHECK_LIB(crypt, crypt, [],
1468                     [AC_CHECK_LIB(crypto, DES_crypt)])
1469 AC_CHECK_LIB(resolv, res_init)
1470
1471 dnl ---------------------------
1472 dnl check system has PCRE regexp
1473 dnl ---------------------------
1474 if test "x$enable_pcreposix" = "xyes"; then
1475   AC_CHECK_LIB(pcreposix, regexec, [], [
1476     AC_MSG_ERROR([--enable-pcreposix given but unable to find libpcreposix])
1477   ])
1478 fi
1479 AC_SUBST(HAVE_LIBPCREPOSIX)
1480
1481 dnl ------------------
1482 dnl check C-Ares library
1483 dnl ------------------
1484 if test "${NHRPD}" != ""; then
1485   PKG_CHECK_MODULES([CARES], [libcares], , [
1486     AC_MSG_ERROR([trying to build nhrpd, but libcares not found. install c-ares and its -dev headers.])
1487   ])
1488 fi
1489
1490
1491 dnl ------------------
1492 dnl check Net-SNMP library
1493 dnl ------------------
1494 if test "${enable_snmp}" != "" -a "${enable_snmp}" != "no"; then
1495    AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], [no])
1496    if test x"$NETSNMP_CONFIG" = x"no"; then
1497       AC_MSG_ERROR([--enable-snmp given but unable to find net-snmp-config])
1498    fi
1499    SNMP_LIBS="`${NETSNMP_CONFIG} --agent-libs`"
1500    SNMP_CFLAGS="`${NETSNMP_CONFIG} --base-cflags`"
1501    AC_MSG_CHECKING([whether we can link to Net-SNMP])
1502    AC_LINK_IFELSE_FLAGS([$SNMP_CFLAGS], [$SNMP_LIBS], [AC_LANG_PROGRAM([
1503 int main(void);
1504 ],
1505 [
1506 {
1507   return 0;
1508 }
1509 ])], [
1510      AC_MSG_ERROR([--enable-snmp given but not usable])])
1511    case "${enable_snmp}" in
1512      yes)
1513       SNMP_METHOD=agentx
1514       ;;
1515      agentx)
1516       SNMP_METHOD="${enable_snmp}"
1517       ;;
1518      *)
1519       AC_MSG_ERROR([--enable-snmp given with an unknown method (${enable_snmp}). Use yes or agentx])
1520       ;;
1521    esac
1522    AH_TEMPLATE([SNMP_AGENTX], [Use SNMP AgentX to interface with snmpd])
1523    AC_DEFINE_UNQUOTED(AS_TR_CPP(SNMP_${SNMP_METHOD}),,SNMP method to interface with snmpd)
1524 fi
1525 AM_CONDITIONAL([SNMP], [test "x${SNMP_METHOD}" != "x"])
1526 AC_SUBST(SNMP_LIBS)
1527 AC_SUBST(SNMP_CFLAGS)
1528
1529 dnl ---------------
1530 dnl math
1531 dnl ---------------
1532 AC_SEARCH_LIBS([sqrt], [m])
1533
1534 dnl ---------------
1535 dnl dlopen & dlinfo
1536 dnl ---------------
1537 AC_SEARCH_LIBS(dlopen, [dl dld], [], [
1538   AC_MSG_ERROR([unable to find the dlopen()])
1539 ])
1540
1541 AC_CHECK_HEADERS([link.h])
1542
1543 AC_CACHE_CHECK([for dlinfo(RTLD_DI_ORIGIN)], [frr_cv_rtld_di_origin], [
1544   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1545 #include <stdlib.h>
1546 #ifdef HAVE_LINK_H
1547 #include <link.h>
1548 #endif
1549 #include <dlfcn.h>
1550 ]], [[
1551   char origin[1];
1552   dlinfo (NULL, RTLD_DI_ORIGIN, &origin);
1553 ]])], [
1554     frr_cv_rtld_di_origin=yes
1555   ], [
1556     frr_cv_rtld_di_origin=no
1557   ])
1558 ])
1559 if test "$frr_cv_rtld_di_origin" = yes; then
1560   AC_DEFINE(HAVE_DLINFO_ORIGIN, 1, [Have dlinfo RTLD_DI_ORIGIN])
1561 fi
1562
1563 AC_CACHE_CHECK([for dlinfo(RTLD_DI_LINKMAP)], [frr_cv_rtld_di_linkmap], [
1564   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1565 #include <stdlib.h>
1566 #ifdef HAVE_LINK_H
1567 #include <link.h>
1568 #endif
1569 #include <dlfcn.h>
1570 ]], [[
1571   struct link_map *lm = NULL;
1572   dlinfo (NULL, RTLD_DI_LINKMAP, &lm);
1573 ]])], [
1574     frr_cv_rtld_di_linkmap=yes
1575   ], [
1576     frr_cv_rtld_di_linkmap=no
1577   ])
1578 ])
1579 if test "$frr_cv_rtld_di_linkmap" = yes; then
1580   AC_DEFINE(HAVE_DLINFO_LINKMAP, 1, [Have dlinfo RTLD_DI_LINKMAP])
1581 fi
1582
1583 AM_CONDITIONAL(SNMP, test "x$SNMP_METHOD" = "xagentx")
1584
1585 dnl ---------------------------
1586 dnl sockaddr and netinet checks
1587 dnl ---------------------------
1588 AC_CHECK_TYPES([
1589         struct sockaddr_dl,
1590         struct vifctl, struct mfcctl, struct sioc_sg_req,
1591         vifi_t, struct sioc_vif_req, struct igmpmsg,
1592         struct ifaliasreq, struct if6_aliasreq, struct in6_aliasreq,
1593         struct nd_opt_adv_interval, struct rt_addrinfo,
1594         struct nd_opt_homeagent_info, struct nd_opt_adv_interval],
1595         [], [], FRR_INCLUDES)
1596
1597 AC_CHECK_MEMBERS([struct sockaddr.sa_len,
1598         struct sockaddr_in.sin_len, struct sockaddr_un.sun_len,
1599         struct sockaddr_dl.sdl_len,
1600         struct if6_aliasreq.ifra_lifetime,
1601         struct nd_opt_adv_interval.nd_opt_ai_type],
1602         [], [], FRR_INCLUDES)
1603
1604 dnl ---------------------------
1605 dnl IRDP/pktinfo/icmphdr checks
1606 dnl ---------------------------
1607
1608 AC_CHECK_TYPES([struct in_pktinfo], [
1609   AC_CHECK_TYPES([struct icmphdr], [
1610     IRDP=true
1611   ], [
1612     IRDP=false
1613   ], [FRR_INCLUDES])
1614 ], [
1615   IRDP=false
1616 ], [FRR_INCLUDES])
1617
1618 case "${enable_irdp}" in
1619 yes)
1620   $IRDP || AC_MSG_ERROR(['IRDP requires in_pktinfo at the moment!'])
1621   ;;
1622 no)
1623   IRDP=false
1624   ;;
1625 esac
1626
1627 AM_CONDITIONAL(IRDP, $IRDP)
1628
1629 dnl -----------------------
1630 dnl checking for IP_PKTINFO
1631 dnl -----------------------
1632 AC_MSG_CHECKING(for IP_PKTINFO)
1633 AC_TRY_COMPILE([#include <netdb.h>], [
1634   int opt = IP_PKTINFO;
1635 ], [
1636   AC_MSG_RESULT(yes)
1637   AC_DEFINE(HAVE_IP_PKTINFO, 1, [Have IP_PKTINFO])
1638 ], [
1639   AC_MSG_RESULT(no)
1640 ])
1641
1642 dnl ---------------------------
1643 dnl checking for IP_RECVDSTADDR
1644 dnl ---------------------------
1645 AC_MSG_CHECKING(for IP_RECVDSTADDR)
1646 AC_TRY_COMPILE([#include <netinet/in.h>], [
1647   int opt = IP_RECVDSTADDR;
1648 ], [
1649   AC_MSG_RESULT(yes)
1650   AC_DEFINE(HAVE_IP_RECVDSTADDR, 1, [Have IP_RECVDSTADDR])
1651 ], [
1652   AC_MSG_RESULT(no)
1653 ])
1654
1655 dnl ----------------------
1656 dnl checking for IP_RECVIF
1657 dnl ----------------------
1658 AC_MSG_CHECKING(for IP_RECVIF)
1659 AC_TRY_COMPILE([#include <netinet/in.h>], [
1660   int opt = IP_RECVIF;
1661 ], [
1662   AC_MSG_RESULT(yes)
1663   AC_DEFINE(HAVE_IP_RECVIF, 1, [Have IP_RECVIF])
1664 ], [
1665   AC_MSG_RESULT(no)
1666 ])
1667
1668 dnl ----------------------
1669 dnl checking for SO_BINDANY
1670 dnl ----------------------
1671 AC_MSG_CHECKING(for SO_BINDANY)
1672 AC_TRY_COMPILE([#include <sys/socket.h>], [
1673   int opt = SO_BINDANY;
1674 ], [
1675   AC_MSG_RESULT(yes)
1676   AC_DEFINE(HAVE_SO_BINDANY, 1, [Have SO_BINDANY])
1677 ], [
1678   AC_MSG_RESULT(no)
1679 ])
1680
1681 dnl ----------------------
1682 dnl checking for IP_FREEBIND
1683 dnl ----------------------
1684 AC_MSG_CHECKING(for IP_FREEBIND)
1685 AC_TRY_COMPILE([#include <netinet/in.h>], [
1686   int opt = IP_FREEBIND;
1687 ], [
1688   AC_MSG_RESULT(yes)
1689   AC_DEFINE(HAVE_IP_FREEBIND, 1, [Have IP_FREEBIND])
1690 ], [
1691   AC_MSG_RESULT(no)
1692 ])
1693
1694 dnl --------------------------------------
1695 dnl checking for be32dec existence or not
1696 dnl --------------------------------------
1697 AC_CHECK_DECLS([be32enc, be32dec], [], [],
1698                [#include <sys/endian.h>])
1699
1700 dnl --------------------------------------
1701 dnl checking for clock_time monotonic struct and call
1702 dnl --------------------------------------
1703 AC_CHECK_DECL(CLOCK_MONOTONIC,
1704         [AC_CHECK_LIB(rt, clock_gettime, [LIBS="$LIBS -lrt"])
1705          AC_DEFINE(HAVE_CLOCK_MONOTONIC,, Have monotonic clock)
1706 ], [AC_MSG_RESULT(no)], [FRR_INCLUDES])
1707
1708 dnl --------------------------------------
1709 dnl checking for flex and bison
1710 dnl --------------------------------------
1711
1712 AM_PROG_LEX
1713 AC_MSG_CHECKING(version of flex)
1714 frr_ac_flex_version="$(eval $LEX -V | grep flex | head -n 1)"
1715 frr_ac_flex_version="${frr_ac_flex_version##* }"
1716 AC_MSG_RESULT([$frr_ac_flex_version])
1717 AX_COMPARE_VERSION([$frr_ac_flex_version], [lt], [2.5.20], [
1718   LEX="$SHELL $missing_dir/missing flex"
1719   if test -f "${srcdir}/lib/command_lex.c" -a -f "${srcdir}/lib/command_lex.h"; then
1720     AC_MSG_WARN([using pregenerated flex output files])
1721   else
1722     AC_MSG_ERROR([flex failure and pregenerated files not included (probably a git build)])
1723   fi
1724   AC_SUBST([LEX_OUTPUT_ROOT], [lex.yy])
1725   AC_SUBST([LEXLIB], [''])
1726 ])
1727
1728 AC_PROG_YACC
1729 dnl thanks GNU bison for this b*llshit...
1730 AC_MSG_CHECKING(version of bison)
1731 frr_ac_bison_version="$(eval $YACC -V | grep bison | head -n 1)"
1732 frr_ac_bison_version="${frr_ac_bison_version##* }"
1733 frr_ac_bison_missing="false"
1734 case "x${frr_ac_bison_version}" in
1735   x2.7*)
1736     BISON_OPENBRACE='"'
1737     BISON_CLOSEBRACE='"'
1738     BISON_VERBOSE=''
1739     AC_MSG_RESULT([$frr_ac_bison_version - 2.7 or older])
1740     ;;
1741   x2.*|x1.*)
1742     AC_MSG_RESULT([$frr_ac_bison_version])
1743     AC_MSG_WARN([installed bison is too old.  Please install GNU bison 2.7.x or newer.])
1744     frr_ac_bison_missing="true"
1745     ;;
1746   x)
1747     AC_MSG_RESULT([none])
1748     AC_MSG_WARN([could not determine bison version.  Please install GNU bison 2.7.x or newer.])
1749     frr_ac_bison_missing="true"
1750     ;;
1751   *)
1752     BISON_OPENBRACE='{'
1753     BISON_CLOSEBRACE='}'
1754     BISON_VERBOSE='-Dparse.error=verbose'
1755     AC_MSG_RESULT([$frr_ac_bison_version - 3.0 or newer])
1756     ;;
1757 esac
1758 AC_SUBST(BISON_OPENBRACE)
1759 AC_SUBST(BISON_CLOSEBRACE)
1760 AC_SUBST(BISON_VERBOSE)
1761
1762 if $frr_ac_bison_missing; then
1763   YACC="$SHELL $missing_dir/missing bison -y"
1764   if test -f "${srcdir}/lib/command_parse.c" -a -f "${srcdir}/lib/command_parse.h"; then
1765     AC_MSG_WARN([using pregenerated bison output files])
1766   else
1767     AC_MSG_ERROR([bison failure and pregenerated files not included (probably a git build)])
1768   fi
1769 fi
1770
1771 dnl -------------------
1772 dnl capabilities checks
1773 dnl -------------------
1774 if test "${enable_capabilities}" != "no"; then
1775   AC_MSG_CHECKING(whether prctl PR_SET_KEEPCAPS is available)
1776   AC_TRY_COMPILE([#include <sys/prctl.h>],[prctl(PR_SET_KEEPCAPS, 1, 0, 0, 0);],
1777     [AC_MSG_RESULT(yes)
1778      AC_DEFINE(HAVE_PR_SET_KEEPCAPS,,prctl)
1779      frr_ac_keepcaps="yes"],
1780      AC_MSG_RESULT(no)
1781   )
1782   if test x"${frr_ac_keepcaps}" = x"yes"; then
1783     AC_CHECK_HEADERS(sys/capability.h)
1784   fi
1785   if test x"${ac_cv_header_sys_capability_h}" = x"yes"; then
1786     AC_CHECK_LIB(cap, cap_init,
1787       [AC_DEFINE(HAVE_LCAPS,1,Capabilities)
1788        LIBCAP="-lcap"
1789        frr_ac_lcaps="yes"]
1790     )
1791   else
1792     AC_CHECK_HEADERS(priv.h,
1793      [AC_MSG_CHECKING(Solaris style privileges are available)
1794       AC_TRY_COMPILE([#include <priv.h>],[getpflags(PRIV_AWARE);],
1795           [AC_MSG_RESULT(yes)
1796            AC_DEFINE(HAVE_SOLARIS_CAPABILITIES,1,getpflags)
1797            frr_ac_scaps="yes"],
1798            AC_MSG_RESULT(no)
1799       )
1800      ]
1801    )
1802   fi
1803   if test x"${frr_ac_scaps}" = x"yes" \
1804        -o x"${frr_ac_lcaps}" = x"yes"; then
1805     AC_DEFINE(HAVE_CAPABILITIES,1,capabilities)
1806   fi
1807 fi
1808 AC_SUBST(LIBCAP)
1809
1810 dnl ---------------------------
1811 dnl check for glibc 'backtrace'
1812 dnl ---------------------------
1813 if test x"${enable_backtrace}" != x"no" ; then
1814   backtrace_ok=no
1815   AC_CHECK_HEADER([execinfo.h], [
1816     AC_SEARCH_LIBS([backtrace], [execinfo], [
1817       AC_DEFINE(HAVE_GLIBC_BACKTRACE,,[Glibc backtrace])
1818       AC_DEFINE(HAVE_STACK_TRACE,,[Stack symbol decoding])
1819       backtrace_ok=yes
1820     ],, [-lm])
1821   ])
1822
1823   if test x"${enable_backtrace}" = x"yes" -a x"${backtrace_ok}" = x"no"; then
1824     dnl user explicitly requested backtrace but we failed to find support
1825     AC_MSG_FAILURE([failed to find backtrace support])
1826   fi
1827 fi
1828
1829 dnl -----------------------------------------
1830 dnl check for malloc mallinfo struct and call
1831 dnl this must try and link using LIBS, in
1832 dnl order to check no alternative allocator
1833 dnl has been specified, which might not provide
1834 dnl mallinfo, e.g. such as Umem on Solaris.
1835 dnl -----------------------------------------
1836 AC_CHECK_HEADERS([malloc.h malloc/malloc.h],,, [FRR_INCLUDES])
1837
1838 AC_CACHE_CHECK([whether mallinfo is available], [frr_cv_mallinfo], [
1839   AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
1840 #ifdef HAVE_MALLOC_H
1841 #include <malloc.h>
1842 #endif
1843 #ifdef HAVE_MALLOC_MALLOC_H
1844 #include <malloc/malloc.h>
1845 #endif
1846 ]], [[
1847 struct mallinfo ac_x; ac_x = mallinfo ();
1848 ]])], [
1849     frr_cv_mallinfo=yes
1850   ], [
1851     frr_cv_mallinfo=no
1852   ])
1853 ])
1854 if test "$frr_cv_mallinfo" = yes; then
1855   AC_DEFINE(HAVE_MALLINFO,,mallinfo)
1856 fi
1857
1858 AC_MSG_CHECKING(whether malloc_usable_size is available)
1859 AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
1860 #ifdef HAVE_MALLOC_H
1861 #include <malloc.h>
1862 #endif
1863 #ifdef HAVE_MALLOC_MALLOC_H
1864 #include <malloc/malloc.h>
1865 #endif
1866 ]], [[
1867 size_t ac_x; ac_x = malloc_usable_size(NULL);
1868 ]])], [
1869   AC_MSG_RESULT(yes)
1870   AC_DEFINE(HAVE_MALLOC_USABLE_SIZE,,malloc_usable_size)
1871 ], [
1872   AC_MSG_RESULT(no)
1873
1874   AC_MSG_CHECKING(whether malloc_size is available)
1875   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1876 #ifdef HAVE_MALLOC_H
1877 #include <malloc.h>
1878 #endif
1879 #ifdef HAVE_MALLOC_MALLOC_H
1880 #include <malloc/malloc.h>
1881 #endif
1882 ]], [[
1883 size_t ac_x; ac_x = malloc_size(NULL);
1884 ]])], [
1885     AC_MSG_RESULT(yes)
1886     AC_DEFINE(HAVE_MALLOC_SIZE,,malloc_size)
1887   ], [
1888     AC_MSG_RESULT(no)
1889   ])
1890 ])
1891
1892 dnl ------
1893 dnl ZeroMQ
1894 dnl ------
1895 if test "x$enable_zeromq" != "xno"; then
1896   PKG_CHECK_MODULES(ZEROMQ, [libzmq >= 4.0.0], [
1897     AC_DEFINE(HAVE_ZEROMQ, 1, [Enable ZeroMQ support])
1898     ZEROMQ=true
1899   ], [
1900     if test "x$enable_zeromq" = "xyes"; then
1901       AC_MSG_ERROR([configuration specifies --enable-zeromq but libzmq was not found])
1902     fi
1903   ])
1904 fi
1905 AM_CONDITIONAL([ZEROMQ], test "x$ZEROMQ" = "xtrue")
1906
1907 dnl ----------
1908 dnl configure date
1909 dnl ----------
1910 dev_version=`echo $VERSION | grep dev`
1911 #don't expire deprecated code in non 'dev' branch
1912 if test "${dev_version}" = ""; then
1913    CONFDATE=0
1914 else
1915    CONFDATE=`date '+%Y%m%d'`
1916 fi
1917 AC_SUBST(CONFDATE)
1918
1919 dnl ------------------------------
1920 dnl set paths for state directory
1921 dnl ------------------------------
1922 AC_MSG_CHECKING(directory to use for state file)
1923 if test "${prefix}" = "NONE"; then
1924   frr_statedir_prefix="";
1925 else
1926   frr_statedir_prefix=${prefix}
1927 fi
1928 if test "${localstatedir}" = '${prefix}/var'; then
1929   for FRR_STATE_DIR in ${frr_statedir_prefix}/var/run dnl
1930                         ${frr_statedir_prefix}/var/adm dnl
1931                         ${frr_statedir_prefix}/etc dnl
1932                         /var/run        dnl
1933                         /var/adm        dnl
1934                         /etc            dnl
1935                         /dev/null;
1936   do
1937     test -d $FRR_STATE_DIR && break
1938   done
1939   frr_statedir=$FRR_STATE_DIR
1940 else
1941   frr_statedir=${localstatedir}
1942 fi
1943 if test $frr_statedir = "/dev/null"; then
1944     AC_MSG_ERROR('STATE DIRECTORY NOT FOUND! FIX OR SPECIFY --localstatedir!')
1945 fi
1946 AC_MSG_RESULT(${frr_statedir})
1947 AC_SUBST(frr_statedir)
1948
1949 AC_DEFINE_UNQUOTED(LDPD_SOCKET, "$frr_statedir/ldpd.sock",ldpd control socket)
1950 AC_DEFINE_UNQUOTED(ZEBRA_SERV_PATH, "$frr_statedir/zserv.api",zebra api socket)
1951 AC_DEFINE_UNQUOTED(BFDD_CONTROL_SOCKET, "$frr_statedir/bfdd.sock", bfdd control socket)
1952 AC_DEFINE_UNQUOTED(DAEMON_VTY_DIR, "$frr_statedir",daemon vty directory)
1953
1954 dnl autoconf does this, but it does it too late...
1955 test "x$prefix" = xNONE && prefix=$ac_default_prefix
1956 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
1957
1958 dnl get the full path, recursing through variables...
1959 vtysh_bin="$bindir/vtysh"
1960 for I in 1 2 3 4 5 6 7 8 9 10; do
1961         eval vtysh_bin="\"$vtysh_bin\""
1962 done
1963 AC_DEFINE_UNQUOTED(VTYSH_BIN_PATH, "$vtysh_bin",path to vtysh binary)
1964
1965 CFG_SYSCONF="$sysconfdir"
1966 CFG_SBIN="$sbindir"
1967 CFG_STATE="$frr_statedir"
1968 CFG_MODULE="$moduledir"
1969 for I in 1 2 3 4 5 6 7 8 9 10; do
1970         eval CFG_SYSCONF="\"$CFG_SYSCONF\""
1971         eval CFG_SBIN="\"$CFG_SBIN\""
1972         eval CFG_STATE="\"$CFG_STATE\""
1973         eval CFG_MODULE="\"$CFG_MODULE\""
1974 done
1975 AC_SUBST(CFG_SYSCONF)
1976 AC_SUBST(CFG_SBIN)
1977 AC_SUBST(CFG_STATE)
1978 AC_SUBST(CFG_MODULE)
1979 AC_DEFINE_UNQUOTED(MODULE_PATH, "$CFG_MODULE", path to modules)
1980
1981 dnl ------------------------------------
1982 dnl Enable RPKI and add librtr to libs
1983 dnl ------------------------------------
1984 if test "${enable_rpki}" = "yes"; then
1985   PKG_CHECK_MODULES(RTRLIB,[rtrlib >= 0.5.0],
1986       [AC_DEFINE(HAVE_RPKI,1,Enable RPKI prefix validation for BGP)
1987       RPKI=true],
1988       [RPKI=false
1989       AC_MSG_ERROR([rtrlib was not found on your system or is too old.])]
1990   )
1991 fi
1992 AM_CONDITIONAL([RPKI], test "x$RPKI" = "xtrue")
1993
1994 dnl ------------------------------------------
1995 dnl Check whether rtrlib was build with ssh support
1996 dnl ------------------------------------------
1997 AC_MSG_CHECKING([whether the RTR Library is compiled with SSH])
1998 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "rtrlib/rtrlib.h"]],
1999                         [[struct tr_ssh_config config;]])],
2000         [AC_MSG_RESULT(yes)
2001         AC_DEFINE(FOUND_SSH,,found_ssh)],
2002         AC_MSG_RESULT(no)
2003 )
2004
2005 dnl ---------------------------
2006 dnl Check htonl works correctly
2007 dnl ---------------------------
2008 AC_MSG_CHECKING(for working htonl)
2009 AC_CACHE_VAL(ac_cv_htonl_works,
2010  [AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES],[htonl (0);])],
2011                 [ac_cv_htonl_works=yes], [ac_cv_htonl_works=no])
2012  ]
2013 )
2014 AC_MSG_RESULT($ac_cv_htonl_works)
2015
2016 AC_CONFIG_FILES([Makefile],[sed -e 's/^#AUTODERP# //' -i Makefile])
2017
2018 AC_CONFIG_FILES([
2019           bgpd/Makefile
2020           vtysh/Makefile
2021           tests/Makefile
2022           bgpd/rfp-example/rfptest/Makefile
2023           bgpd/rfp-example/librfp/Makefile
2024           redhat/frr.spec
2025           solaris/Makefile
2026           debianpkg/changelog
2027           alpine/APKBUILD
2028           snapcraft/snapcraft.yaml
2029           lib/version.h
2030           tests/lib/cli/test_cli.refout
2031           pkgsrc/bgpd.sh pkgsrc/ospf6d.sh pkgsrc/ospfd.sh
2032           pkgsrc/ripd.sh pkgsrc/ripngd.sh pkgsrc/zebra.sh
2033           pkgsrc/eigrpd.sh])
2034
2035 if test "${enable_bgp_vnc}" != "no"; then
2036    if test "${with_rfp_path}" != "bgpd/rfp-example" ; then
2037       AC_CONFIG_FILES([${with_rfp_path}/rfptest/Makefile ${with_rfp_path}/librfp/Makefile])
2038    fi
2039 fi
2040
2041 AC_CONFIG_FILES([vtysh/extract.pl],[chmod +x vtysh/extract.pl])
2042
2043 AC_CONFIG_COMMANDS([lib/route_types.h], [
2044         dst="${ac_abs_top_builddir}/lib/route_types.h"
2045         ${PERL} "${ac_abs_top_srcdir}/lib/route_types.pl" \
2046                 < "${ac_abs_top_srcdir}/lib/route_types.txt" \
2047                 > "${dst}.tmp"
2048         test -f "${dst}" \
2049                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
2050                 && rm "${dst}.tmp" \
2051                 || mv "${dst}.tmp" "${dst}"
2052 ], [
2053         PERL="$PERL"
2054 ])
2055
2056 AS_IF([test "x$with_pkg_git_version" = "xyes"], [
2057     AC_CONFIG_COMMANDS([lib/gitversion.h], [
2058         dst="${ac_abs_top_builddir}/lib/gitversion.h"
2059         ${PERL} "${ac_abs_top_srcdir}/lib/gitversion.pl" \
2060                 "${ac_abs_top_srcdir}" \
2061                 > "${dst}.tmp"
2062         test -f "${dst}" \
2063                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
2064                 && rm "${dst}.tmp" \
2065                 || mv "${dst}.tmp" "${dst}"
2066     ], [
2067         PERL="$PERL"
2068     ])
2069 ])
2070
2071 ## Hack, but working solution to avoid rebuilding of frr.info.
2072 ## It's already in CVS until texinfo 4.7 is more common.
2073 AC_OUTPUT
2074
2075 echo "
2076 FRRouting configuration
2077 ------------------------------
2078 FRR version             : ${PACKAGE_VERSION}
2079 host operating system   : ${host_os}
2080 source code location    : ${srcdir}
2081 compiler                : ${CC}
2082 compiler flags          : ${CFLAGS}
2083 make                    : ${MAKE-make}
2084 linker flags            : ${LDFLAGS} ${LIBS} ${LIBCAP} ${LIBREADLINE} ${LIBM}
2085 state file directory    : ${frr_statedir}
2086 config file directory   : `eval echo \`echo ${sysconfdir}\``
2087 example directory       : `eval echo \`echo ${exampledir}\``
2088 module directory        : ${CFG_MODULE}
2089 user to run as          : ${enable_user}
2090 group to run as         : ${enable_group}
2091 group for vty sockets   : ${enable_vty_group}
2092 config file mask        : ${enable_configfile_mask}
2093 log file mask           : ${enable_logfile_mask}
2094 zebra protobuf enabled  : ${have_protobuf:-no}
2095
2096 The above user and group must have read/write access to the state file
2097 directory and to the config files in the config file directory."
2098
2099 if test "${enable_doc}" != "no";then
2100   AS_IF([test "x$SPHINXBUILD" = xno],
2101      AC_MSG_WARN(sphinx-build is missing but required to build documentation))
2102 fi