configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 m4_define([lxc_version_major], 1)
   5 m4_define([lxc_version_minor], 0)
   6 m4_define([lxc_version_micro], 0)
   7 m4_define([lxc_version_beta], [beta4])
   8
   9 m4_define([lxc_version_base], [lxc_version_major.lxc_version_minor.lxc_version_micro])
  10 m4_define([lxc_version],
  11           [ifelse(lxc_version_beta, [], [lxc_version_base], [lxc_version_base.lxc_version_beta])])
  12
  13 AC_INIT([lxc], [lxc_version])
  14
  15 # We need pkg-config
  16 PKG_PROG_PKG_CONFIG
  17
  18 AC_SUBST(LXC_VERSION_BASE, lxc_version_base)
  19 AC_SUBST(LXC_VERSION_BETA, lxc_version_beta)
  20
  21 AC_SUBST([LXC_VERSION_MAJOR], [lxc_version_major])
  22 AC_SUBST([LXC_VERSION_MINOR], [lxc_version_minor])
  23 AC_SUBST([LXC_VERSION_MICRO], [lxc_version_micro])
  24 AC_SUBST([LXC_VERSION], [lxc_version])
  25
  26 AC_CONFIG_SRCDIR([configure.ac])
  27 AC_CONFIG_AUX_DIR([config])
  28 AC_CONFIG_HEADERS([src/config.h])
  29 AM_INIT_AUTOMAKE([-Wall -Werror -Wno-portability subdir-objects])
  30 AC_CANONICAL_HOST
  31 AM_PROG_CC_C_O
  32 AC_GNU_SOURCE
  33
  34 # Detect the distribution. This is used for the default configuration and
  35 # for some distro-specific build options.
  36 AC_MSG_CHECKING([host distribution])
  37 AC_ARG_WITH(distro, AS_HELP_STRING([--with-distro=DISTRO], [Specify the Linux distribution to target: One of redhat, oracle, centos, fedora, suse, gentoo, debian, arch, slackware, paldo, openmandriva or pardus.]))
  38 if type lsb_release >/dev/null 2>&1 && test "z$with_distro" = "z"; then
  39         with_distro=`lsb_release -is`
  40 fi
  41 if test "z$with_distro" = "z"; then
  42         AC_CHECK_FILE(/etc/redhat-release,with_distro="redhat")
  43         AC_CHECK_FILE(/etc/oracle-release,with_distro="oracle")
  44         AC_CHECK_FILE(/etc/centos-release,with_distro="centos")
  45         AC_CHECK_FILE(/etc/fedora-release,with_distro="fedora")
  46         AC_CHECK_FILE(/etc/SuSE-release,with_distro="suse")
  47         AC_CHECK_FILE(/etc/gentoo-release,with_distro="gentoo")
  48         AC_CHECK_FILE(/etc/debian_version,with_distro="debian")
  49         AC_CHECK_FILE(/etc/arch-release,with_distro="arch")
  50         AC_CHECK_FILE(/etc/slackware-version,with_distro="slackware")
  51         AC_CHECK_FILE(/etc/frugalware-release,with_distro="frugalware")
  52         AC_CHECK_FILE(/etc/mandrakelinux-release, with_distro="openmandriva")
  53         AC_CHECK_FILE(/etc/mandriva-release,with_distro="openmandriva")
  54         AC_CHECK_FILE(/etc/pardus-release,with_distro="pardus")
  55 fi
  56 with_distro=`echo ${with_distro} | tr '[[:upper:]]' '[[:lower:]]'`
  57
  58 if test "z$with_distro" = "z"; then
  59         with_distro="unknown"
  60 fi
  61 case $with_distro in
  62         ubuntu)
  63                 distroconf=default.conf.ubuntu
  64                 ;;
  65         redhat|centos|fedora|oracle|oracleserver)
  66                 distroconf=default.conf.libvirt
  67                 ;;
  68         *)
  69                 distroconf=default.conf.unknown
  70                 ;;
  71 esac
  72 AC_MSG_RESULT([$with_distro])
  73 AM_CONDITIONAL([HAVE_DEBIAN], [test x"$with_distro" = "xdebian" -o x"$with_distro" = "xubuntu"])
  74 AM_CONDITIONAL([DISTRO_UBUNTU], [test "x$with_distro" = "xubuntu"])
  75
  76 # Check for init system type
  77 AC_MSG_CHECKING([for init system type])
  78 AC_ARG_WITH([init-script],
  79             [AC_HELP_STRING([--with-init-script@<:@=TYPE@<:@,TYPE,...@:>@@:>@],
  80                             [Type(s) of init script to install: sysvinit, systemd, upstart,
  81                              distro @<:@default=distro@:>@])],[],[with_init_script=distro])
  82 case "$with_init_script" in
  83         distro)
  84                 case $with_distro in
  85                         fedora)
  86                                 init_script=systemd
  87                                 ;;
  88                         redhat|centos|oracle|oracleserver)
  89                                 init_script=sysvinit
  90                                 ;;
  91                         debian)
  92                                 init_script=upstart,systemd
  93                                 ;;
  94                         ubuntu)
  95                                 init_script=upstart
  96                                 ;;
  97                         *)
  98                                 echo -n "Linux distribution init system unknown."
  99                                 init_script=
 100                                 ;;
 101                 esac
 102                 ;;
 103         *)
 104                 init_script=$with_init_script
 105                 ;;
 106 esac
 107
 108 # Check valid init systems were given, run in subshell so we don't mess up IFS
 109 (IFS="," ; for init_sys in $init_script;
 110 do
 111         case "$init_sys" in
 112                 none|sysvinit|systemd|upstart)
 113                         ;;
 114                 *)
 115                         exit 1
 116                         ;;
 117         esac
 118 done) || AC_MSG_ERROR([Unknown init system type in $init_script])
 119
 120 AM_CONDITIONAL([INIT_SCRIPT_SYSV], [echo "$init_script" |grep -q "sysvinit"])
 121 AM_CONDITIONAL([INIT_SCRIPT_SYSTEMD], [echo "$init_script" |grep -q "systemd"])
 122 AM_CONDITIONAL([INIT_SCRIPT_UPSTART], [echo "$init_script" |grep -q "upstart"])
 123 AC_MSG_RESULT($init_script)
 124
 125 # Allow disabling rpath
 126 AC_ARG_ENABLE([rpath],
 127         [AC_HELP_STRING([--enable-rpath], [set rpath in executables [default=no]])],
 128         [], [enable_rpath=no])
 129 AM_CONDITIONAL([ENABLE_RPATH], [test "x$enable_rpath" = "xyes"])
 130
 131 # Documentation (manpages)
 132 AC_ARG_ENABLE([doc],
 133         [AC_HELP_STRING([--enable-doc], [make man pages [default=auto]])],
 134         [], [enable_doc=auto])
 135
 136 if test "x$enable_doc" = "xyes" -o "x$enable_doc" = "xauto"; then
 137         db2xman=""
 138         dbparsers="docbook2x-man db2x_docbook2man docbook2man docbook-to-man"
 139
 140         AC_MSG_CHECKING(for docbook2x-man)
 141         for name in ${dbparsers}; do
 142                 if "$name" --help >/dev/null 2>&1; then
 143                         db2xman="$name"
 144                         break;
 145                 fi
 146         done
 147
 148         if test -n "${db2xman}"; then
 149                 AC_MSG_RESULT([${db2xman}])
 150                 enable_doc="yes"
 151         else
 152                 AC_MSG_RESULT([no])
 153                 if test "x$enable_doc" = "xyes"; then
 154                         AC_MSG_ERROR([docbook2x-man is required, but could not be found])
 155                 fi
 156                 enable_doc="no"
 157         fi
 158
 159         AC_SUBST(db2xman)
 160 fi
 161 AM_CONDITIONAL([ENABLE_DOCBOOK], [test "x$db2xman" != "x"])
 162 AM_CONDITIONAL([USE_DOCBOOK2X], [test "x$db2xman" != "xdocbook2man"])
 163
 164 if test "x$db2xman" = "xdocbook2man"; then
 165         docdtd="\"-//Davenport//DTD DocBook V3.0//EN\""
 166 else
 167         docdtd="\"-//OASIS//DTD DocBook XML\" \"http://www.oasis-open.org/docbook/xml/4.5/docbookx.dtd\""
 168 fi
 169 AC_SUBST(docdtd)
 170
 171 # Documentation (API)
 172 AC_ARG_ENABLE([api-docs],
 173         [AC_HELP_STRING([--enable-api-docs],
 174         [make API documentation [default=auto]])],
 175         [], [enable_api_docs=auto])
 176
 177 if test "x$enable_api_docs" = "xyes" -o "x$enable_api_docs" = "xauto"; then
 178         AC_CHECK_PROGS([HAVE_DOXYGEN],[doxygen])
 179         AC_SUBST([HAVE_DOXYGEN])
 180
 181         if test "x$HAVE_DOXYGEN" != "x"; then
 182                 enable_api_docs="yes"
 183         else
 184                 if test "x$enable_api_docs" = "xyes"; then
 185                         AC_MSG_ERROR([doxygen is required, but could not be found])
 186                 fi
 187                 enable_api_docs="no"
 188         fi
 189 fi
 190
 191 AM_CONDITIONAL([ENABLE_API_DOCS], [test "x$HAVE_DOXYGEN" != "x"])
 192
 193 # Apparmor
 194 AC_ARG_ENABLE([apparmor],
 195         [AC_HELP_STRING([--enable-apparmor], [enable apparmor support [default=auto]])],
 196         [], [enable_apparmor=auto])
 197
 198 if test "$enable_apparmor" = "auto" ; then
 199         AC_CHECK_LIB([apparmor],[aa_change_profile],[enable_apparmor=yes], [enable_apparmor=no])
 200 fi
 201 AM_CONDITIONAL([ENABLE_APPARMOR], [test "x$enable_apparmor" = "xyes"])
 202
 203 AC_CHECK_LIB([gnutls], [gnutls_hash_fast], [enable_gnutls=yes], [enable_gnutls=no])
 204
 205 AM_COND_IF([ENABLE_APPARMOR],
 206         [AC_CHECK_HEADER([sys/apparmor.h],[],[AC_MSG_ERROR([You must install the AppArmor development package in order to compile lxc])])
 207         AC_CHECK_LIB([apparmor], [aa_change_profile],[],[AC_MSG_ERROR([You must install the AppArmor development package in order to compile lxc])])
 208         AC_SUBST([APPARMOR_LIBS], [-lapparmor])])
 209
 210 # SELinux
 211 AC_ARG_ENABLE([selinux],
 212         [AC_HELP_STRING([--enable-selinux], [enable SELinux support [default=auto]])],
 213         [], [enable_selinux=auto])
 214
 215 if test "x$enable_selinux" = xauto; then
 216         AC_CHECK_LIB([selinux],[setexeccon_raw],[enable_selinux=yes],[enable_selinux=no])
 217 fi
 218 AM_CONDITIONAL([ENABLE_SELINUX], [test "x$enable_selinux" = "xyes"])
 219 AM_COND_IF([ENABLE_SELINUX],
 220         [AC_CHECK_HEADER([selinux/selinux.h],[],[AC_MSG_ERROR([You must install the SELinux development package in order to compile lxc])])
 221         AC_CHECK_LIB([selinux], [setexeccon_raw],[],[AC_MSG_ERROR([You must install the SELinux development package in order to compile lxc])])
 222         AC_SUBST([SELINUX_LIBS])])
 223
 224 # Seccomp syscall filter
 225 AC_ARG_ENABLE([seccomp],
 226         [AC_HELP_STRING([--enable-seccomp], [enable seccomp support [default=auto]])],
 227         [], [enable_seccomp=auto])
 228
 229 if test "x$enable_seccomp" = "xauto" ; then
 230         AC_CHECK_LIB([seccomp],[seccomp_init],[enable_seccomp=yes],[enable_seccomp=no])
 231 fi
 232 AM_CONDITIONAL([ENABLE_SECCOMP], [test "x$enable_seccomp" = "xyes"])
 233
 234 AM_COND_IF([ENABLE_SECCOMP],
 235         [PKG_CHECK_MODULES([SECCOMP],[libseccomp],[],[
 236                 AC_CHECK_HEADER([seccomp.h],[],[AC_MSG_ERROR([You must install the seccomp development package in order to compile lxc])])
 237                 AC_CHECK_LIB([seccomp], [seccomp_init],[],[AC_MSG_ERROR([You must install the seccomp development package in order to compile lxc])])
 238                 AC_SUBST([SECCOMP_LIBS], [-lseccomp])
 239                 ])
 240         ])
 241
 242 # cgmanager
 243 AC_ARG_ENABLE([cgmanager],
 244         [AC_HELP_STRING([--enable-cgmanager], [enable cgmanager support [default=auto]])],
 245         [], [enable_cgmanager=auto])
 246
 247 if test "x$enable_cgmanager" = "xauto" ; then
 248         AC_CHECK_LIB([cgmanager],[cgmanager_create],[enable_cgmanager=yes],[enable_cgmanager=no],[-lnih -lnih-dbus])
 249 fi
 250 AM_CONDITIONAL([ENABLE_CGMANAGER], [test "x$enable_cgmanager" = "xyes"])
 251
 252 AM_COND_IF([ENABLE_CGMANAGER],
 253         [PKG_CHECK_MODULES([CGMANAGER], [libcgmanager])
 254         PKG_CHECK_MODULES([NIH], [libnih >= 1.0.2])
 255         PKG_CHECK_MODULES([NIH_DBUS], [libnih-dbus >= 1.0.0])
 256         PKG_CHECK_MODULES([DBUS], [dbus-1 >= 1.2.16])
 257         ])
 258
 259 # Linux capabilities
 260 AC_ARG_ENABLE([capabilities],
 261         [AC_HELP_STRING([--enable-capabilities], [enable kernel capabilities support [default=auto]])],
 262         [], [enable_capabilities=auto])
 263
 264 if test "x$enable_capabilities" = "xauto"; then
 265         AC_CHECK_LIB([cap],[cap_set_proc],[enable_capabilities=yes],[enable_capabilities=no])
 266 fi
 267 AM_CONDITIONAL([ENABLE_CAP], [test "x$enable_capabilities" = "xyes"])
 268
 269 AM_COND_IF([ENABLE_CAP],
 270         [AC_CHECK_LIB(cap,cap_set_proc,[],[AC_MSG_ERROR([You are missing libcap support.])])
 271         AC_SUBST([CAP_LIBS], [-lcap])])
 272
 273 # HAVE_SCMP_FILTER_CTX=1 will tell us we have libseccomp api >= 1.0.0
 274 OLD_CFLAGS="$CFLAGS"
 275 CFLAGS="$CFLAGS $SECCOMP_CFLAGS"
 276 AC_CHECK_TYPES([scmp_filter_ctx], [], [], [[#include <seccomp.h>]])
 277 CFLAGS="$OLD_CFLAGS"
 278
 279 # Configuration examples
 280 AC_ARG_ENABLE([examples],
 281         [AC_HELP_STRING([--enable-examples], [install examples [default=yes]])],
 282         [], [enable_examples=yes])
 283 AM_CONDITIONAL([ENABLE_EXAMPLES], [test "x$enable_examples" = "xyes"])
 284
 285 # Python3 module and scripts
 286 AC_ARG_ENABLE([python],
 287         [AC_HELP_STRING([--enable-python], [enable python binding [default=auto]])],
 288         [], [enable_python=auto])
 289
 290 if test "x$enable_python" = "xauto"; then
 291         PKG_CHECK_MODULES([PYTHONDEV], [python3 >= 3.2],[enable_python=yes],[enable_python=no])
 292         if test "$CC" = "clang"; then
 293                 enable_python=no
 294         fi
 295 fi
 296
 297 if test "x$enable_python" = "xyes" && test "$CC" = "clang"; then
 298         AC_MSG_ERROR([Python3 is incompatible with the clang compiler])
 299 fi
 300
 301 AM_CONDITIONAL([ENABLE_PYTHON], [test "x$enable_python" = "xyes"])
 302
 303 AM_COND_IF([ENABLE_PYTHON],
 304         [AM_PATH_PYTHON([3.2], [], [AC_MSG_ERROR([You must install python3])])
 305         PKG_CHECK_MODULES([PYTHONDEV], [python3 >= 3.2],[],[AC_MSG_ERROR([You must install python3-dev])])
 306         AC_DEFINE_UNQUOTED([ENABLE_PYTHON], 1, [Python3 is available])])
 307
 308 # Enable dumping stack traces
 309 AC_ARG_ENABLE([mutex-debugging],
 310         [AC_HELP_STRING([--enable-mutex-debugging], [Makes mutexes to report error and provide stack trace [default=no]])],
 311         [], [enable_mutex_debugging=no])
 312 AM_CONDITIONAL([MUTEX_DEBUGGING], [test "x$enable_mutex_debugging" = "xyes"])
 313
 314 AM_COND_IF([MUTEX_DEBUGGING],
 315         AC_DEFINE_UNQUOTED([MUTEX_DEBUGGING], 1, [Enabling mutex debugging]))
 316
 317 # Not in older autoconf versions
 318 # AS_VAR_COPY(DEST, SOURCE)
 319 # -------------------------
 320 # Set the polymorphic shell variable DEST to the contents of the polymorphic
 321 # shell variable SOURCE.
 322 m4_ifdef([AS_VAR_COPY], [],
 323 [AC_DEFUN([AS_VAR_COPY],
 324     [AS_LITERAL_IF([$1[]$2], [$1=$$2], [eval $1=\$$2])])
 325 ])
 326
 327 dnl PKG_CHECK_VAR was introduced with pkg-config 0.28
 328 m4_ifdef([PKG_CHECK_VAR], [],
 329 [AC_DEFUN([PKG_CHECK_VAR],
 330     [AC_REQUIRE([PKG_PROG_PKG_CONFIG])dnl
 331      AC_ARG_VAR([$1], [value of $3 for $2, overriding pkg-config])dnl
 332      _PKG_CONFIG([$1], [variable="][$3]["], [$2])
 333      AS_VAR_COPY([$1], [pkg_cv_][$1])
 334      AS_VAR_IF([$1], [""], [$5], [$4])dnl
 335     ])# PKG_CHECK_VAR
 336 ])
 337
 338 # Lua module and scripts
 339 AC_ARG_ENABLE([lua],
 340         [AC_HELP_STRING([--enable-lua], [enable lua binding [default=auto]])],
 341         [], [enable_lua=auto])
 342
 343 AC_ARG_WITH([lua-pc],
 344         [AS_HELP_STRING(
 345                 [--with-lua-pc=PKG],
 346                 [Specify pkg-config package name for lua]
 347         )], [], [with_lua_pc=no])
 348
 349 if test "x$enable_lua" = "xyes" -a "x$with_lua_pc" != "xno"; then
 350         # exit with error if not found
 351         PKG_CHECK_MODULES([LUA], [$with_lua_pc], [LUAPKGCONFIG=$with_lua_pc])
 352 fi
 353
 354 if test "x$enable_lua" = "xauto" -a "x$with_lua_pc" != "xno"; then
 355         PKG_CHECK_MODULES([LUA], [$with_lua_pc],
 356                 [LUAPKGCONFIG=$with_lua_pc
 357                 enable_lua=yes],
 358                 [enable_lua=no])
 359 fi
 360
 361 if test "x$enable_lua" != "xno"; then
 362         PKG_CHECK_MODULES([LUA], [lua], [LUAPKGCONFIG=lua],
 363                 [PKG_CHECK_MODULES([LUA], [lua5.2], [LUAPKGCONFIG=lua5.2],
 364                         [PKG_CHECK_MODULES([LUA], [lua5.1], [LUAPKGCONFIG=lua5.1],
 365                                 [AS_IF([test "x$enable_lua" = "xyes"],
 366                                         [AC_MSG_ERROR([Lua not found. Please use --with-lua-pc=PKG])],
 367                                         [enable_lua=no])]
 368                         )]
 369                 )])
 370         AS_IF([test "x$LUAPKGCONFIG" != "x"], [enable_lua=yes])
 371 fi
 372
 373 AM_CONDITIONAL([ENABLE_LUA],
 374         [test "x$enable_lua" = "xyes"])
 375
 376 AM_COND_IF([ENABLE_LUA],
 377         [AC_MSG_CHECKING([Lua version])
 378         PKG_CHECK_VAR([LUA_VERSION], [$LUAPKGCONFIG], [V],,
 379                 [PKG_CHECK_VAR([LUA_VERSION], [$LUAPKGCONFIG], [major_version])])
 380         AC_MSG_RESULT([$LUA_VERSION])
 381         PKG_CHECK_VAR([LUA_INSTALL_CMOD], [$LUAPKGCONFIG], [INSTALL_CMOD],,
 382                 [LUA_INSTALL_CMOD=$libdir/lua/$LUA_VERSION])
 383         PKG_CHECK_VAR([LUA_INSTALL_LMOD], [$LUAPKGCONFIG], [INSTALL_LMOD],,
 384                 [LUA_INSTALL_LMOD=$datadir/lua/$LUA_VERSION])
 385         ])
 386
 387 # Optional bash integration
 388 AC_ARG_ENABLE([bash],
 389         [AC_HELP_STRING([--enable-bash], [build bash integration [default=yes]])],
 390         [], [enable_bash=yes])
 391 AM_CONDITIONAL([ENABLE_BASH], [test "x$enable_bash" = "xyes"])
 392
 393 # Optional test binaries
 394 AC_ARG_ENABLE([tests],
 395         [AC_HELP_STRING([--enable-tests], [build test/example binaries [default=no]])],
 396         [], [enable_tests=no])
 397 AM_CONDITIONAL([ENABLE_TESTS], [test "x$enable_tests" = "xyes"])
 398
 399 # Allow overriding the default runtime dir (/run)
 400 AC_ARG_WITH([runtime-path],
 401         [AC_HELP_STRING(
 402                 [--with-runtime-path=dir],
 403                 [runtime directory (default: /run)]
 404         )], [], [with_runtime_path=['/run']])
 405
 406 # LXC container path, where the containers are actually stored
 407 # This is overridden by an entry in the file called LXCCONF
 408 # (i.e. /etc/lxc/lxc.conf)
 409 AC_ARG_WITH([config-path],
 410         [AC_HELP_STRING(
 411                 [--with-config-path=dir],
 412                 [lxc configuration repository path]
 413         )], [], [with_config_path=['${localstatedir}/lib/lxc']])
 414
 415 # The path of the global lxc configuration file.
 416 AC_ARG_WITH([global-conf],
 417         [AC_HELP_STRING(
 418                 [--with-global-conf=dir],
 419                 [global lxc configuration file]
 420         )], [], [with_global_conf=['${sysconfdir}/lxc/lxc.conf']])
 421
 422 # The path of the userns network configuration file
 423 AC_ARG_WITH([usernic-conf],
 424         [AC_HELP_STRING(
 425                 [--with-usernic-conf],
 426                 [user network interface configuration file]
 427         )], [], [with_usernic_conf=['${sysconfdir}/lxc/lxc-usernet']])
 428
 429 # The path of the runtime usernic database
 430 AC_ARG_WITH([usernic-db],
 431         [AC_HELP_STRING(
 432                 [--with-usernic-db],
 433                 [lxc user nic database]
 434         )], [], [with_usernic_db=['${with_runtime_path}/lxc/nics']])
 435
 436 # Rootfs path, where the container mount structure is assembled
 437 AC_ARG_WITH([rootfs-path],
 438         [AC_HELP_STRING(
 439                 [--with-rootfs-path=dir],
 440                 [lxc rootfs mount point]
 441         )], [], [with_rootfs_path=['${libdir}/lxc/rootfs']])
 442
 443 # cgroup pattern specification
 444 AC_ARG_WITH([cgroup-pattern],
 445         [AC_HELP_STRING(
 446                 [--with-cgroup-pattern=pattern],
 447                 [pattern for container cgroups]
 448         )], [], [with_cgroup_pattern=['/lxc/%n']])
 449
 450 # Container log path.  By default, use $lxcpath.
 451 AC_MSG_CHECKING([Whether to place logfiles in container config path])
 452 AC_ARG_ENABLE([configpath-log],
 453         [AC_HELP_STRING([--enable-configpath-log], [use logfiles in config path [default=no]])],
 454         [], [enable_configpath_log=no])
 455 AC_MSG_RESULT([$enable_configpath_log])
 456 AM_CONDITIONAL([USE_CONFIGPATH_LOGS], [test "$enable_configpath_log" = "yes"])
 457
 458 if test "$enable_configpath_log" = "yes"; then
 459         default_log_path="${with_config_path}"
 460 else
 461         default_log_path="${localstatedir}/log/lxc"
 462 fi
 463
 464 AC_ARG_WITH([log-path],
 465         [AC_HELP_STRING(
 466                 [--with-log-path=dir],
 467                 [per container log path]
 468         )], [], [with_log_path=['${default_log_path}']])
 469
 470 # Expand some useful variables
 471 AS_AC_EXPAND(PREFIX, "$prefix")
 472 AS_AC_EXPAND(LIBDIR, "$libdir")
 473 AS_AC_EXPAND(BINDIR, "$bindir")
 474 AS_AC_EXPAND(LIBEXECDIR, "$libexecdir")
 475 AS_AC_EXPAND(INCLUDEDIR, "$includedir")
 476 AS_AC_EXPAND(SYSCONFDIR, "$sysconfdir")
 477 AS_AC_EXPAND(LXC_DEFAULT_CONFIG, "$sysconfdir/lxc/default.conf")
 478 AS_AC_EXPAND(DATADIR, "$datadir")
 479 AS_AC_EXPAND(LOCALSTATEDIR, "$localstatedir")
 480 AS_AC_EXPAND(DOCDIR, "$docdir")
 481 AS_AC_EXPAND(LXC_DISTRO_CONF, "$distroconf")
 482 AS_AC_EXPAND(LXC_GENERATE_DATE, "$(date)")
 483 AS_AC_EXPAND(LXCPATH, "$with_config_path")
 484 AS_AC_EXPAND(LXC_GLOBAL_CONF, "$with_global_conf")
 485 AS_AC_EXPAND(LXC_USERNIC_CONF, "$with_usernic_conf")
 486 AS_AC_EXPAND(LXC_USERNIC_DB, "$with_usernic_db")
 487 AS_AC_EXPAND(LXCROOTFSMOUNT, "$with_rootfs_path")
 488 AS_AC_EXPAND(LXCTEMPLATEDIR, "$datadir/lxc/templates")
 489 AS_AC_EXPAND(LXCTEMPLATECONFIG, "$datadir/lxc/config")
 490 AS_AC_EXPAND(LXCHOOKDIR, "$datadir/lxc/hooks")
 491 AS_AC_EXPAND(LXCINITDIR, "$libexecdir")
 492 AS_AC_EXPAND(LOGPATH, "$with_log_path")
 493 AS_AC_EXPAND(RUNTIME_PATH, "$with_runtime_path")
 494 AC_SUBST(DEFAULT_CGROUP_PATTERN, ["$with_cgroup_pattern"])
 495
 496 # Check for some standard kernel headers
 497 AC_CHECK_HEADERS([linux/unistd.h linux/netlink.h linux/genetlink.h],
 498                                 [],
 499                                 AC_MSG_ERROR([Please install the Linux kernel headers.]),
 500                                 [#include <sys/socket.h>])
 501
 502 # Check for alternate C libraries
 503 AC_MSG_CHECKING(for bionic libc)
 504 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 505         [[#ifndef __ANDROID__
 506 error: Not bionic!
 507 #endif]])],
 508         [is_bionic=yes],
 509         [is_bionic=no])
 510 if test "x$is_bionic" = "xyes"; then
 511         AC_DEFINE([IS_BIONIC], 1, [bionic libc])
 512         AC_MSG_RESULT([yes])
 513 else
 514         AC_MSG_RESULT([no])
 515 fi
 516 AM_CONDITIONAL([IS_BIONIC], [test "x$is_bionic" = "xyes"])
 517
 518 # Some systems lack PR_CAPBSET_DROP definition => HAVE_DECL_PR_CAPBSET_DROP
 519 AC_CHECK_DECLS([PR_CAPBSET_DROP], [], [], [#include <sys/prctl.h>])
 520
 521 # Check for some headers
 522 AC_CHECK_HEADERS([sys/signalfd.h pty.h ifaddrs.h sys/capability.h sys/personality.h utmpx.h sys/timerfd.h])
 523
 524 # Check for some syscalls functions
 525 AC_CHECK_FUNCS([setns pivot_root sethostname unshare rand_r confstr faccessat])
 526
 527 # Check for some functions
 528 AC_CHECK_LIB(pthread, main)
 529 AC_CHECK_FUNCS(pthread_atfork)
 530 AC_CHECK_LIB(util, openpty)
 531 AC_CHECK_FUNCS([openpty hasmntopt setmntent endmntent utmpxname])
 532 AC_CHECK_FUNCS([getline],
 533         AM_CONDITIONAL(HAVE_GETLINE, true)
 534         AC_DEFINE(HAVE_GETLINE,1,[Have getline]),
 535         AM_CONDITIONAL(HAVE_GETLINE, false))
 536 AC_CHECK_FUNCS([fgetln],
 537         AM_CONDITIONAL(HAVE_FGETLN, true)
 538         AC_DEFINE(HAVE_FGETLN,1,[Have fgetln]),
 539         AM_CONDITIONAL(HAVE_FGETLN, false))
 540
 541 # Check for some libraries
 542 AC_SEARCH_LIBS(sem_open, [rt pthread])
 543 AC_SEARCH_LIBS(clock_gettime, [rt])
 544
 545 # Check for some standard binaries
 546 AC_PROG_GCC_TRADITIONAL
 547 AC_PROG_SED
 548
 549 # See if we support thread-local storage.
 550 LXC_CHECK_TLS
 551
 552 if test "x$GCC" = "xyes"; then
 553         CFLAGS="$CFLAGS -Wall -Werror"
 554 fi
 555
 556 # Files requiring some variable expansion
 557 AC_CONFIG_FILES([
 558         Makefile
 559         lxc.pc
 560         lxc.spec
 561
 562         config/Makefile
 563         config/apparmor/Makefile
 564         config/bash/Makefile
 565         config/bash/lxc
 566         config/init/Makefile
 567         config/init/sysvinit/Makefile
 568         config/init/systemd/Makefile
 569         config/init/upstart/Makefile
 570         config/etc/Makefile
 571         config/templates/Makefile
 572         config/templates/centos.common.conf
 573         config/templates/centos.userns.conf
 574         config/templates/debian.common.conf
 575         config/templates/debian.userns.conf
 576         config/templates/fedora.common.conf
 577         config/templates/fedora.userns.conf
 578         config/templates/gentoo.common.conf
 579         config/templates/gentoo.moresecure.conf
 580         config/templates/gentoo.userns.conf
 581         config/templates/oracle.common.conf
 582         config/templates/oracle.userns.conf
 583         config/templates/plamo.common.conf
 584         config/templates/plamo.userns.conf
 585         config/templates/ubuntu-cloud.common.conf
 586         config/templates/ubuntu-cloud.lucid.conf
 587         config/templates/ubuntu-cloud.userns.conf
 588         config/templates/ubuntu.common.conf
 589         config/templates/ubuntu.lucid.conf
 590         config/templates/ubuntu.userns.conf
 591
 592         doc/Makefile
 593         doc/api/Makefile
 594         doc/legacy/lxc-ls.sgml
 595         doc/lxc-attach.sgml
 596         doc/lxc-autostart.sgml
 597         doc/lxc-cgroup.sgml
 598         doc/lxc-checkconfig.sgml
 599         doc/lxc-clone.sgml
 600         doc/lxc-config.sgml
 601         doc/lxc-console.sgml
 602         doc/lxc-create.sgml
 603         doc/lxc-destroy.sgml
 604         doc/lxc-device.sgml
 605         doc/lxc-execute.sgml
 606         doc/lxc-freeze.sgml
 607         doc/lxc-info.sgml
 608         doc/lxc-ls.sgml
 609         doc/lxc-monitor.sgml
 610         doc/lxc-snapshot.sgml
 611         doc/lxc-start-ephemeral.sgml
 612         doc/lxc-start.sgml
 613         doc/lxc-stop.sgml
 614         doc/lxc-top.sgml
 615         doc/lxc-unfreeze.sgml
 616         doc/lxc-unshare.sgml
 617         doc/lxc-user-nic.sgml
 618         doc/lxc-usernsexec.sgml
 619         doc/lxc-wait.sgml
 620
 621         doc/lxc.conf.sgml
 622         doc/lxc.container.conf.sgml
 623         doc/lxc.system.conf.sgml
 624         doc/lxc-usernet.sgml
 625         doc/lxc.sgml
 626         doc/common_options.sgml
 627         doc/see_also.sgml
 628
 629         doc/rootfs/Makefile
 630
 631         doc/examples/Makefile
 632         doc/examples/lxc-macvlan.conf
 633         doc/examples/lxc-vlan.conf
 634         doc/examples/lxc-no-netns.conf
 635         doc/examples/lxc-empty-netns.conf
 636         doc/examples/lxc-phys.conf
 637         doc/examples/lxc-veth.conf
 638         doc/examples/lxc-complex.conf
 639
 640         doc/ja/Makefile
 641         doc/ja/legacy/lxc-ls.sgml
 642         doc/ja/lxc-attach.sgml
 643         doc/ja/lxc-autostart.sgml
 644         doc/ja/lxc-cgroup.sgml
 645         doc/ja/lxc-checkconfig.sgml
 646         doc/ja/lxc-clone.sgml
 647         doc/ja/lxc-config.sgml
 648         doc/ja/lxc-console.sgml
 649         doc/ja/lxc-create.sgml
 650         doc/ja/lxc-destroy.sgml
 651         doc/ja/lxc-device.sgml
 652         doc/ja/lxc-execute.sgml
 653         doc/ja/lxc-freeze.sgml
 654         doc/ja/lxc-info.sgml
 655         doc/ja/lxc-ls.sgml
 656         doc/ja/lxc-monitor.sgml
 657         doc/ja/lxc-snapshot.sgml
 658         doc/ja/lxc-start-ephemeral.sgml
 659         doc/ja/lxc-start.sgml
 660         doc/ja/lxc-stop.sgml
 661         doc/ja/lxc-top.sgml
 662         doc/ja/lxc-unfreeze.sgml
 663         doc/ja/lxc-unshare.sgml
 664         doc/ja/lxc-user-nic.sgml
 665         doc/ja/lxc-usernsexec.sgml
 666         doc/ja/lxc-wait.sgml
 667
 668         doc/ja/lxc.conf.sgml
 669         doc/ja/lxc.container.conf.sgml
 670         doc/ja/lxc.system.conf.sgml
 671         doc/ja/lxc-usernet.sgml
 672         doc/ja/lxc.sgml
 673         doc/ja/common_options.sgml
 674         doc/ja/see_also.sgml
 675
 676         hooks/Makefile
 677
 678         templates/Makefile
 679         templates/lxc-alpine
 680         templates/lxc-altlinux
 681         templates/lxc-archlinux
 682         templates/lxc-busybox
 683         templates/lxc-centos
 684         templates/lxc-cirros
 685         templates/lxc-debian
 686         templates/lxc-download
 687         templates/lxc-fedora
 688         templates/lxc-gentoo
 689         templates/lxc-openmandriva
 690         templates/lxc-opensuse
 691         templates/lxc-oracle
 692         templates/lxc-plamo
 693         templates/lxc-sshd
 694         templates/lxc-ubuntu
 695         templates/lxc-ubuntu-cloud
 696
 697         src/Makefile
 698         src/lxc/Makefile
 699         src/lxc/lxc-checkconfig
 700         src/lxc/lxc-start-ephemeral
 701         src/lxc/legacy/lxc-ls
 702         src/lxc/lxc.functions
 703         src/lxc/version.h
 704         src/python-lxc/Makefile
 705
 706         src/lua-lxc/Makefile
 707
 708         src/tests/Makefile
 709         src/tests/lxc-test-usernic
 710 ])
 711 AC_CONFIG_COMMANDS([default],[[]],[[]])
 712 AC_OUTPUT
 713
 714 # Configuration overview
 715 cat << EOF
 716
 717 ----------------------------
 718 Environment:
 719  - compiler: $CC
 720  - distribution: $with_distro
 721  - init script type(s): $init_script
 722  - rpath: $enable_rpath
 723  - GnuTLS: $enable_gnutls
 724  - Bash integration: $enable_bash
 725
 726 Security features:
 727  - Apparmor: $enable_apparmor
 728  - Linux capabilities: $enable_capabilities
 729  - seccomp: $enable_seccomp
 730  - SELinux: $enable_selinux
 731  - cgmanager: $enable_cgmanager
 732
 733 Bindings:
 734  - lua: $enable_lua
 735  - python3: $enable_python
 736
 737 Documentation:
 738  - examples: $enable_examples
 739  - API documentation: $enable_api_docs
 740  - user documentation: $enable_doc
 741
 742 Debugging:
 743  - tests: $enable_tests
 744  - mutex debugging: $enable_mutex_debugging
 745
 746 Paths:
 747  - Logs in configpath: $enable_configpath_log
 748 EOF
 749
 750 if test "x$ac_cv_func_pthread_atfork" = "xno" ; then
 751 cat << EOF
 752
 753 WARNING: Threading not supported on your platform
 754
 755         You are compiling LXC for bionic target which lacks certain threading related functionality used by LXC API (like pthread_atfork).
 756         Please note that, because of the missing functionality, multithreaded usage of LXC API cause some problems.
 757 EOF
 758 fi