configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 m4_define([lxc_devel], 1)
   5 m4_define([lxc_version_major], 2)
   6 m4_define([lxc_version_minor], 0)
   7 m4_define([lxc_version_micro], 0)
   8 m4_define([lxc_version_beta], [])
   9 m4_define([lxc_version_abi], 1.2.0)
  10
  11 m4_define([lxc_version_base], [lxc_version_major.lxc_version_minor.lxc_version_micro])
  12 m4_define([lxc_version],
  13           [ifelse(lxc_version_beta, [], [lxc_version_base], [lxc_version_base.lxc_version_beta])])
  14
  15 AC_INIT([lxc], [lxc_version])
  16
  17 # We need pkg-config
  18 PKG_PROG_PKG_CONFIG
  19
  20 AC_SUBST(LXC_VERSION_BASE, lxc_version_base)
  21 AC_SUBST(LXC_VERSION_BETA, lxc_version_beta)
  22
  23 AC_SUBST([LXC_VERSION_MAJOR], [lxc_version_major])
  24 AC_SUBST([LXC_VERSION_MINOR], [lxc_version_minor])
  25 AC_SUBST([LXC_VERSION_MICRO], [lxc_version_micro])
  26 AC_SUBST([LXC_VERSION_ABI], [lxc_version_abi])
  27 AC_SUBST([LXC_VERSION], [lxc_version])
  28 AC_SUBST([LXC_DEVEL], [lxc_devel])
  29
  30 AC_CONFIG_SRCDIR([configure.ac])
  31 AC_CONFIG_AUX_DIR([config])
  32 AC_CONFIG_HEADERS([src/config.h])
  33 AM_INIT_AUTOMAKE([-Wall -Werror -Wno-portability subdir-objects])
  34 AC_CANONICAL_HOST
  35 AM_PROG_CC_C_O
  36 AC_GNU_SOURCE
  37
  38 # Detect the distribution. This is used for the default configuration and
  39 # for some distro-specific build options.
  40 AC_MSG_CHECKING([host distribution])
  41 AC_ARG_WITH(distro, AS_HELP_STRING([--with-distro=DISTRO], [Specify the Linux distribution to target: One of redhat, oracle, centos, fedora, suse, gentoo, debian, arch, slackware, plamo, paldo, openmandriva, pardus, sparclinux, altlinux.]))
  42 if type lsb_release >/dev/null 2>&1 && test "z$with_distro" = "z"; then
  43         with_distro=`lsb_release -is`
  44 fi
  45 if test "z$with_distro" = "z"; then
  46         AC_CHECK_FILE(/etc/redhat-release,with_distro="redhat")
  47         AC_CHECK_FILE(/etc/oracle-release,with_distro="oracle")
  48         AC_CHECK_FILE(/etc/sparclinux-release,with_distro="sparclinux")
  49         AC_CHECK_FILE(/etc/centos-release,with_distro="centos")
  50         AC_CHECK_FILE(/etc/fedora-release,with_distro="fedora")
  51         AC_CHECK_FILE(/etc/SuSE-release,with_distro="suse")
  52         AC_CHECK_FILE(/etc/gentoo-release,with_distro="gentoo")
  53         AC_CHECK_FILE(/etc/debian_version,with_distro="debian")
  54         AC_CHECK_FILE(/etc/arch-release,with_distro="arch")
  55         AC_CHECK_FILE(/etc/slackware-version,with_distro="slackware")
  56         AC_CHECK_FILE(/etc/plamo-version,with_distro="plamo")
  57         AC_CHECK_FILE(/etc/frugalware-release,with_distro="frugalware")
  58         AC_CHECK_FILE(/etc/mandrakelinux-release, with_distro="openmandriva")
  59         AC_CHECK_FILE(/etc/mandriva-release,with_distro="openmandriva")
  60         AC_CHECK_FILE(/etc/pardus-release,with_distro="pardus")
  61         AC_CHECK_FILE(/etc/altlinux-release,with_distro="altlinux")
  62         AC_CHECK_FILE(/etc/pld-release,with_distro="pld")
  63 fi
  64 with_distro=`echo ${with_distro} | tr '[[:upper:]]' '[[:lower:]]'`
  65
  66 if test "z$with_distro" = "zforsparc"; then
  67         with_distro="sparclinux"
  68 fi
  69
  70 if test "z$with_distro" = "z"; then
  71         with_distro="unknown"
  72 fi
  73 case $with_distro in
  74         ubuntu|raspbian)
  75                 distroconf=default.conf.lxcbr
  76                 distrosysconf="$sysconfdir/default"
  77                 ;;
  78         redhat|centos|fedora|oracle|oracleserver|sparclinux|altlinux|suse|opensuse*|plamo|pld)
  79                 distroconf=default.conf.lxcbr
  80                 distrosysconf="$sysconfdir/sysconfig"
  81                 ;;
  82         *)
  83                 distroconf=default.conf.unknown
  84                 distrosysconf="$sysconfdir/default"
  85                 ;;
  86 esac
  87 AC_MSG_RESULT([$with_distro])
  88 AM_CONDITIONAL([HAVE_DEBIAN], [test x"$with_distro" = "xdebian" -o x"$with_distro" = "xubuntu" -o x"$with_distro" = "xraspbian"])
  89 AM_CONDITIONAL([DISTRO_UBUNTU], [test "x$with_distro" = "xubuntu"])
  90
  91 AC_CONFIG_LINKS([config/etc/default.conf:config/etc/${distroconf}])
  92
  93 # Check for init system type
  94 AC_MSG_CHECKING([for init system type])
  95 AC_ARG_WITH([init-script],
  96             [AC_HELP_STRING([--with-init-script@<:@=TYPE@<:@,TYPE,...@:>@@:>@],
  97                             [Type(s) of init script to install: sysvinit, systemd, upstart,
  98                              distro @<:@default=distro@:>@])],[],[with_init_script=distro])
  99 case "$with_init_script" in
 100         distro)
 101                 case $with_distro in
 102                         fedora|altlinux|opensuse*)
 103                                 init_script=systemd
 104                                 ;;
 105                         redhat|centos|oracle|oracleserver|sparclinux|plamo)
 106                                 init_script=sysvinit
 107                                 ;;
 108                         debian|raspbian)
 109                                 init_script=upstart,systemd
 110                                 ;;
 111                         ubuntu)
 112                                 init_script=upstart,systemd
 113                                 ;;
 114                         pld)
 115                                 init_script=sysvinit,upstart,systemd
 116                                 ;;
 117                         *)
 118                                 echo -n "Linux distribution init system unknown."
 119                                 init_script=
 120                                 ;;
 121                 esac
 122                 ;;
 123         *)
 124                 init_script=$with_init_script
 125                 ;;
 126 esac
 127
 128 # Check valid init systems were given, run in subshell so we don't mess up IFS
 129 (IFS="," ; for init_sys in $init_script;
 130 do
 131         case "$init_sys" in
 132                 none|sysvinit|systemd|upstart)
 133                         ;;
 134                 *)
 135                         exit 1
 136                         ;;
 137         esac
 138 done) || AC_MSG_ERROR([Unknown init system type in $init_script])
 139
 140 AM_CONDITIONAL([INIT_SCRIPT_SYSV], [echo "$init_script" |grep -q "sysvinit"])
 141 AM_CONDITIONAL([INIT_SCRIPT_SYSTEMD], [echo "$init_script" |grep -q "systemd"])
 142 AM_CONDITIONAL([INIT_SCRIPT_UPSTART], [echo "$init_script" |grep -q "upstart"])
 143 AC_MSG_RESULT($init_script)
 144
 145 # systemd unit dir
 146 AC_ARG_WITH([systemdsystemunitdir],
 147             AS_HELP_STRING([--with-systemdsystemunitdir=DIR], [Directory for systemd service files]),
 148             [],
 149             [with_systemdsystemunitdir=$($PKG_CONFIG --variable=systemdsystemunitdir systemd)])
 150 if test -z "$with_systemdsystemunitdir"; then
 151   with_systemdsystemunitdir=/lib/systemd/system
 152 fi
 153 if test "x$with_systemdsystemunitdir" != "xno"; then
 154   AC_SUBST([SYSTEMD_UNIT_DIR], [$with_systemdsystemunitdir])
 155 fi
 156
 157 AC_ARG_ENABLE([werror],
 158         [AC_HELP_STRING([--disable-werror],
 159         [do not treat warnings as errors])],
 160         [], [enable_werror=yes])
 161
 162 # Allow enabling deprecated executables
 163 AC_ARG_ENABLE([deprecated],
 164         [AC_HELP_STRING([--enable-deprecated],
 165         [enable deprecated executables [default=no]])],
 166         [], [enable_deprecated=false])
 167 AM_CONDITIONAL([ENABLE_DEPRECATED], [test "x$enable_deprecated" = "xyes"])
 168
 169 # Allow disabling rpath
 170 AC_ARG_ENABLE([rpath],
 171         [AC_HELP_STRING([--enable-rpath], [set rpath in executables [default=no]])],
 172         [], [enable_rpath=no])
 173 AM_CONDITIONAL([ENABLE_RPATH], [test "x$enable_rpath" = "xyes"])
 174
 175 # Documentation (manpages)
 176 AC_ARG_ENABLE([doc],
 177         [AC_HELP_STRING([--enable-doc], [make man pages [default=auto]])],
 178         [], [enable_doc=auto])
 179
 180 if test "x$enable_doc" = "xyes" -o "x$enable_doc" = "xauto"; then
 181         db2xman=""
 182         dbparsers="docbook2X2man docbook2x-man db2x_docbook2man docbook2man docbook-to-man"
 183
 184         AC_MSG_CHECKING(for docbook2x-man)
 185         for name in ${dbparsers}; do
 186                 if "$name" --help >/dev/null 2>&1; then
 187                         db2xman="$name"
 188                         break;
 189                 fi
 190         done
 191
 192         if test -n "${db2xman}"; then
 193                 AC_MSG_RESULT([${db2xman}])
 194                 enable_doc="yes"
 195         else
 196                 AC_MSG_RESULT([no])
 197                 if test "x$enable_doc" = "xyes"; then
 198                         AC_MSG_ERROR([docbook2x-man is required, but could not be found])
 199                 fi
 200                 enable_doc="no"
 201         fi
 202
 203         AC_SUBST(db2xman)
 204 fi
 205 AM_CONDITIONAL([ENABLE_DOCBOOK], [test "x$db2xman" != "x"])
 206 AM_CONDITIONAL([USE_DOCBOOK2X], [test "x$db2xman" != "xdocbook2man"])
 207
 208 if test "x$db2xman" = "xdocbook2man"; then
 209         docdtd="\"-//Davenport//DTD DocBook V3.0//EN\""
 210 else
 211         docdtd="\"-//OASIS//DTD DocBook XML\" \"http://www.oasis-open.org/docbook/xml/4.5/docbookx.dtd\""
 212 fi
 213 AC_SUBST(docdtd)
 214
 215 # Documentation (API)
 216 AC_ARG_ENABLE([api-docs],
 217         [AC_HELP_STRING([--enable-api-docs],
 218         [make API documentation [default=auto]])],
 219         [], [enable_api_docs=auto])
 220
 221 if test "x$enable_api_docs" = "xyes" -o "x$enable_api_docs" = "xauto"; then
 222         AC_CHECK_PROGS([HAVE_DOXYGEN],[doxygen])
 223         AC_SUBST([HAVE_DOXYGEN])
 224
 225         if test "x$HAVE_DOXYGEN" != "x"; then
 226                 enable_api_docs="yes"
 227         else
 228                 if test "x$enable_api_docs" = "xyes"; then
 229                         AC_MSG_ERROR([doxygen is required, but could not be found])
 230                 fi
 231                 enable_api_docs="no"
 232         fi
 233 fi
 234
 235 AM_CONDITIONAL([ENABLE_API_DOCS], [test "x$HAVE_DOXYGEN" != "x"])
 236
 237 # Apparmor
 238 AC_ARG_ENABLE([apparmor],
 239         [AC_HELP_STRING([--enable-apparmor], [enable apparmor support [default=auto]])],
 240         [], [enable_apparmor=auto])
 241
 242 if test "$enable_apparmor" = "auto" ; then
 243         AC_CHECK_LIB([apparmor],[aa_change_profile],[enable_apparmor=yes], [enable_apparmor=no])
 244 fi
 245 AM_CONDITIONAL([ENABLE_APPARMOR], [test "x$enable_apparmor" = "xyes"])
 246
 247 AC_CHECK_LIB([gnutls], [gnutls_hash_fast], [enable_gnutls=yes], [enable_gnutls=no])
 248
 249 AM_COND_IF([ENABLE_APPARMOR],
 250         [AC_CHECK_HEADER([sys/apparmor.h],[],[AC_MSG_ERROR([You must install the AppArmor development package in order to compile lxc])])
 251         AC_CHECK_LIB([apparmor], [aa_change_profile],[],[AC_MSG_ERROR([You must install the AppArmor development package in order to compile lxc])])
 252         AC_SUBST([APPARMOR_LIBS], [-lapparmor])])
 253
 254 # SELinux
 255 AC_ARG_ENABLE([selinux],
 256         [AC_HELP_STRING([--enable-selinux], [enable SELinux support [default=auto]])],
 257         [], [enable_selinux=auto])
 258
 259 if test "x$enable_selinux" = xauto; then
 260         AC_CHECK_LIB([selinux],[setexeccon_raw],[enable_selinux=yes],[enable_selinux=no])
 261 fi
 262 AM_CONDITIONAL([ENABLE_SELINUX], [test "x$enable_selinux" = "xyes"])
 263 AM_COND_IF([ENABLE_SELINUX],
 264         [AC_CHECK_HEADER([selinux/selinux.h],[],[AC_MSG_ERROR([You must install the SELinux development package in order to compile lxc])])
 265         AC_CHECK_LIB([selinux], [setexeccon_raw],[true],[AC_MSG_ERROR([You must install the SELinux development package in order to compile lxc])])
 266         AC_SUBST([SELINUX_LIBS], [-lselinux])])
 267
 268 # Seccomp syscall filter
 269 AC_ARG_ENABLE([seccomp],
 270         [AC_HELP_STRING([--enable-seccomp], [enable seccomp support [default=auto]])],
 271         [], [enable_seccomp=auto])
 272
 273 if test "x$enable_seccomp" = "xauto" ; then
 274         AC_CHECK_LIB([seccomp],[seccomp_init],[enable_seccomp=yes],[enable_seccomp=no])
 275 fi
 276 AM_CONDITIONAL([ENABLE_SECCOMP], [test "x$enable_seccomp" = "xyes"])
 277
 278 AM_COND_IF([ENABLE_SECCOMP],
 279         [PKG_CHECK_MODULES([SECCOMP],[libseccomp],[],[
 280                 AC_CHECK_HEADER([seccomp.h],[],[AC_MSG_ERROR([You must install the seccomp development package in order to compile lxc])])
 281                 AC_CHECK_LIB([seccomp], [seccomp_init],[],[AC_MSG_ERROR([You must install the seccomp development package in order to compile lxc])])
 282                 AC_SUBST([SECCOMP_LIBS], [-lseccomp])
 283                 ])
 284         ])
 285
 286 # cgmanager
 287 AC_ARG_ENABLE([cgmanager],
 288         [AC_HELP_STRING([--enable-cgmanager], [enable cgmanager support [default=auto]])],
 289         [], [enable_cgmanager=auto])
 290
 291 if test "x$enable_cgmanager" = "xauto" ; then
 292         AC_CHECK_LIB([cgmanager],[cgmanager_create],[enable_cgmanager=yes],[enable_cgmanager=no],[-lnih -lnih-dbus -ldbus-1])
 293 fi
 294 AM_CONDITIONAL([ENABLE_CGMANAGER], [test "x$enable_cgmanager" = "xyes"])
 295
 296 AM_COND_IF([ENABLE_CGMANAGER],
 297         [PKG_CHECK_MODULES([CGMANAGER], [libcgmanager])
 298         PKG_CHECK_MODULES([NIH], [libnih >= 1.0.2])
 299         PKG_CHECK_MODULES([NIH_DBUS], [libnih-dbus >= 1.0.0])
 300         PKG_CHECK_MODULES([DBUS], [dbus-1 >= 1.2.16])
 301         ])
 302
 303 AC_MSG_CHECKING(for get_pid_cgroup_abs_sync)
 304 save_LIBS=$LIBS
 305 AC_SEARCH_LIBS([cgmanager_get_pid_cgroup_abs_sync], [cgmanager], [have_abs_cgroups=yes], [have_abs_cgroups=no], [-lnih -lnih-dbus -ldbus-1])
 306 LIBS=$save_LIBS
 307 if test "x$have_abs_cgroups" = "xyes"; then
 308         AC_DEFINE([HAVE_CGMANAGER_GET_PID_CGROUP_ABS_SYNC], 1, [Have cgmanager_get_pid_cgroup_abs_sync])
 309         AC_MSG_RESULT([yes])
 310 else
 311         AC_MSG_RESULT([no])
 312 fi
 313
 314 AC_MSG_CHECKING(for cgmanager_list_controllers)
 315 save_LIBS=$LIBS
 316 AC_SEARCH_LIBS([cgmanager_list_controllers_sync], [cgmanager], [have_list_controllers=yes], [have_list_controllers=no], [-lnih -lnih-dbus -ldbus-1])
 317 LIBS=$save_LIBS
 318 if test "x$have_list_controllers" = "xyes"; then
 319         AC_DEFINE([HAVE_CGMANAGER_LIST_CONTROLLERS], 1, [Have cgmanager_list_controllers])
 320         AC_MSG_RESULT([yes])
 321 else
 322         AC_MSG_RESULT([no])
 323 fi
 324
 325 # Check for static libcap, make sure the function checked for differs from the
 326 # the one checked below so the cache doesn't give a wrong answer
 327 OLD_CFLAGS="$CFLAGS"
 328 CFLAGS="$CFLAGS -static"
 329 AC_CHECK_LIB([cap],[cap_init],[have_static_libcap=yes],[have_static_libcap=no])
 330 AM_CONDITIONAL([HAVE_STATIC_LIBCAP], [test "x$have_static_libcap" = "xyes"])
 331 if test "x$have_static_libcap" = "xyes"; then
 332         AC_DEFINE([HAVE_STATIC_LIBCAP], 1, [Have static libcap])
 333 fi
 334 CFLAGS="$OLD_CFLAGS"
 335
 336
 337 # Linux capabilities
 338 AC_ARG_ENABLE([capabilities],
 339         [AC_HELP_STRING([--enable-capabilities], [enable kernel capabilities support [default=auto]])],
 340         [], [enable_capabilities=auto])
 341
 342 if test "x$enable_capabilities" = "xauto"; then
 343         AC_CHECK_LIB([cap],[cap_set_proc],[enable_capabilities=yes],[enable_capabilities=no])
 344 fi
 345 AM_CONDITIONAL([ENABLE_CAP], [test "x$enable_capabilities" = "xyes"])
 346
 347 AM_COND_IF([ENABLE_CAP],
 348         [AC_CHECK_LIB(cap,cap_set_proc,[true],[AC_MSG_ERROR([You are missing libcap support.])])
 349         AC_SUBST([CAP_LIBS], [-lcap])])
 350
 351 # HAVE_SCMP_FILTER_CTX=1 will tell us we have libseccomp api >= 1.0.0
 352 OLD_CFLAGS="$CFLAGS"
 353 CFLAGS="$CFLAGS $SECCOMP_CFLAGS"
 354 AC_CHECK_TYPES([scmp_filter_ctx], [], [], [[#include <seccomp.h>]])
 355 AC_CHECK_DECLS([seccomp_syscall_resolve_name_arch], [], [], [[#include <seccomp.h>]])
 356 CFLAGS="$OLD_CFLAGS"
 357
 358 # Configuration examples
 359 AC_ARG_ENABLE([examples],
 360         [AC_HELP_STRING([--enable-examples], [install examples [default=yes]])],
 361         [], [enable_examples=yes])
 362 AM_CONDITIONAL([ENABLE_EXAMPLES], [test "x$enable_examples" = "xyes"])
 363
 364 # Python3 module and scripts
 365 AC_ARG_ENABLE([python],
 366         [AC_HELP_STRING([--enable-python], [enable python binding [default=auto]])],
 367         [], [enable_python=auto])
 368
 369 if test "x$enable_python" = "xauto"; then
 370         PKG_CHECK_MODULES([PYTHONDEV], [python3 >= 3.2],[enable_python=yes],[enable_python=no])
 371         if test "$CC" = "clang"; then
 372                 enable_python=no
 373         fi
 374 fi
 375
 376 if test "x$enable_python" = "xyes" && test "$CC" = "clang"; then
 377         AC_MSG_ERROR([Python3 is incompatible with the clang compiler])
 378 fi
 379
 380 AM_CONDITIONAL([ENABLE_PYTHON], [test "x$enable_python" = "xyes"])
 381
 382 AM_COND_IF([ENABLE_PYTHON],
 383         [AM_PATH_PYTHON([3.2], [], [AC_MSG_ERROR([You must install python3])])
 384         PKG_CHECK_MODULES([PYTHONDEV], [python3 >= 3.2],[],[AC_MSG_ERROR([You must install python3-dev])])
 385         AC_DEFINE_UNQUOTED([ENABLE_PYTHON], 1, [Python3 is available])])
 386
 387 # Enable dumping stack traces
 388 AC_ARG_ENABLE([mutex-debugging],
 389         [AC_HELP_STRING([--enable-mutex-debugging], [Makes mutexes to report error and provide stack trace [default=no]])],
 390         [], [enable_mutex_debugging=no])
 391 AM_CONDITIONAL([MUTEX_DEBUGGING], [test "x$enable_mutex_debugging" = "xyes"])
 392
 393 AM_COND_IF([MUTEX_DEBUGGING],
 394         AC_DEFINE_UNQUOTED([MUTEX_DEBUGGING], 1, [Enabling mutex debugging]))
 395
 396 # Not in older autoconf versions
 397 # AS_VAR_COPY(DEST, SOURCE)
 398 # -------------------------
 399 # Set the polymorphic shell variable DEST to the contents of the polymorphic
 400 # shell variable SOURCE.
 401 m4_ifdef([AS_VAR_COPY], [],
 402 [AC_DEFUN([AS_VAR_COPY],
 403     [AS_LITERAL_IF([$1[]$2], [$1=$$2], [eval $1=\$$2])])
 404 ])
 405
 406 dnl PKG_CHECK_VAR was introduced with pkg-config 0.28
 407 m4_ifdef([PKG_CHECK_VAR], [],
 408 [AC_DEFUN([PKG_CHECK_VAR],
 409     [AC_REQUIRE([PKG_PROG_PKG_CONFIG])dnl
 410      AC_ARG_VAR([$1], [value of $3 for $2, overriding pkg-config])dnl
 411      _PKG_CONFIG([$1], [variable="][$3]["], [$2])
 412      AS_VAR_COPY([$1], [pkg_cv_][$1])
 413      AS_VAR_IF([$1], [""], [$5], [$4])dnl
 414     ])# PKG_CHECK_VAR
 415 ])
 416
 417 # Lua module and scripts
 418 AC_ARG_ENABLE([lua],
 419         [AC_HELP_STRING([--enable-lua], [enable lua binding [default=auto]])],
 420         [], [enable_lua=auto])
 421
 422 AC_ARG_WITH([lua-pc],
 423         [AS_HELP_STRING(
 424                 [--with-lua-pc=PKG],
 425                 [Specify pkg-config package name for lua]
 426         )], [], [with_lua_pc=no])
 427
 428 if test "x$enable_lua" = "xyes" -a "x$with_lua_pc" != "xno"; then
 429         # exit with error if not found
 430         PKG_CHECK_MODULES([LUA], [$with_lua_pc], [LUAPKGCONFIG=$with_lua_pc])
 431 fi
 432
 433 if test "x$enable_lua" = "xauto" -a "x$with_lua_pc" != "xno"; then
 434         PKG_CHECK_MODULES([LUA], [$with_lua_pc],
 435                 [LUAPKGCONFIG=$with_lua_pc
 436                 enable_lua=yes],
 437                 [enable_lua=no])
 438 fi
 439
 440 if test "x$enable_lua" != "xno"; then
 441         PKG_CHECK_MODULES([LUA], [lua], [LUAPKGCONFIG=lua],
 442                 [PKG_CHECK_MODULES([LUA], [lua5.2], [LUAPKGCONFIG=lua5.2],
 443                         [PKG_CHECK_MODULES([LUA], [lua5.1], [LUAPKGCONFIG=lua5.1],
 444                                 [AS_IF([test "x$enable_lua" = "xyes"],
 445                                         [AC_MSG_ERROR([Lua not found. Please use --with-lua-pc=PKG])],
 446                                         [enable_lua=no])]
 447                         )]
 448                 )])
 449         AS_IF([test "x$LUAPKGCONFIG" != "x"], [enable_lua=yes])
 450 fi
 451
 452 AM_CONDITIONAL([ENABLE_LUA],
 453         [test "x$enable_lua" = "xyes"])
 454
 455 AM_COND_IF([ENABLE_LUA],
 456         [AC_MSG_CHECKING([Lua version])
 457         PKG_CHECK_VAR([LUA_VERSION], [$LUAPKGCONFIG], [V],,
 458                 [PKG_CHECK_VAR([LUA_VERSION], [$LUAPKGCONFIG], [major_version])])
 459         AC_MSG_RESULT([$LUA_VERSION])
 460         AC_SUBST([LUA_LIBDIR], [$libdir/lua/$LUA_VERSION])
 461         AC_SUBST([LUA_SHAREDIR], [$datadir/lua/$LUA_VERSION])
 462         ])
 463
 464 # Optional bash integration
 465 AC_ARG_ENABLE([bash],
 466         [AC_HELP_STRING([--enable-bash], [build bash integration [default=yes]])],
 467         [], [enable_bash=yes])
 468 AM_CONDITIONAL([ENABLE_BASH], [test "x$enable_bash" = "xyes"])
 469
 470 # Optional test binaries
 471 AC_ARG_ENABLE([tests],
 472         [AC_HELP_STRING([--enable-tests], [build test/example binaries [default=no]])],
 473         [], [enable_tests=no])
 474 AM_CONDITIONAL([ENABLE_TESTS], [test "x$enable_tests" = "xyes"])
 475
 476 # Allow overriding the default runtime dir (/run)
 477 AC_ARG_WITH([runtime-path],
 478         [AC_HELP_STRING(
 479                 [--with-runtime-path=dir],
 480                 [runtime directory (default: /run)]
 481         )], [], [with_runtime_path=['/run']])
 482
 483 # LXC container path, where the containers are actually stored
 484 # This is overridden by an entry in the file called LXCCONF
 485 # (i.e. /etc/lxc/lxc.conf)
 486 AC_ARG_WITH([config-path],
 487         [AC_HELP_STRING(
 488                 [--with-config-path=dir],
 489                 [lxc configuration repository path]
 490         )], [], [with_config_path=['${localstatedir}/lib/lxc']])
 491
 492 # The path of the global lxc configuration file.
 493 AC_ARG_WITH([global-conf],
 494         [AC_HELP_STRING(
 495                 [--with-global-conf=dir],
 496                 [global lxc configuration file]
 497         )], [], [with_global_conf=['${sysconfdir}/lxc/lxc.conf']])
 498
 499 # The path of the userns network configuration file
 500 AC_ARG_WITH([usernic-conf],
 501         [AC_HELP_STRING(
 502                 [--with-usernic-conf],
 503                 [user network interface configuration file]
 504         )], [], [with_usernic_conf=['${sysconfdir}/lxc/lxc-usernet']])
 505
 506 # The path of the runtime usernic database
 507 AC_ARG_WITH([usernic-db],
 508         [AC_HELP_STRING(
 509                 [--with-usernic-db],
 510                 [lxc user nic database]
 511         )], [], [with_usernic_db=['${with_runtime_path}/lxc/nics']])
 512
 513 # Rootfs path, where the container mount structure is assembled
 514 AC_ARG_WITH([rootfs-path],
 515         [AC_HELP_STRING(
 516                 [--with-rootfs-path=dir],
 517                 [lxc rootfs mount point]
 518         )], [], [with_rootfs_path=['${libdir}/lxc/rootfs']])
 519
 520 # cgroup pattern specification
 521 AC_ARG_WITH([cgroup-pattern],
 522         [AC_HELP_STRING(
 523                 [--with-cgroup-pattern=pattern],
 524                 [pattern for container cgroups]
 525         )], [], [with_cgroup_pattern=['/lxc/%n']])
 526
 527 # Container log path.  By default, use $lxcpath.
 528 AC_MSG_CHECKING([Whether to place logfiles in container config path])
 529 AC_ARG_ENABLE([configpath-log],
 530         [AC_HELP_STRING([--enable-configpath-log], [use logfiles in config path [default=no]])],
 531         [], [enable_configpath_log=no])
 532 AC_MSG_RESULT([$enable_configpath_log])
 533 AM_CONDITIONAL([USE_CONFIGPATH_LOGS], [test "$enable_configpath_log" = "yes"])
 534
 535 if test "$enable_configpath_log" = "yes"; then
 536         default_log_path="${with_config_path}"
 537 else
 538         default_log_path="${localstatedir}/log/lxc"
 539 fi
 540
 541 AC_ARG_WITH([log-path],
 542         [AC_HELP_STRING(
 543                 [--with-log-path=dir],
 544                 [per container log path]
 545         )], [], [with_log_path=['${default_log_path}']])
 546
 547 # Expand some useful variables
 548 AS_AC_EXPAND(PREFIX, "$prefix")
 549 AS_AC_EXPAND(LIBDIR, "$libdir")
 550 AS_AC_EXPAND(BINDIR, "$bindir")
 551 AS_AC_EXPAND(SBINDIR, "$sbindir")
 552 AS_AC_EXPAND(LIBEXECDIR, "$libexecdir")
 553 AS_AC_EXPAND(INCLUDEDIR, "$includedir")
 554 AS_AC_EXPAND(SYSCONFDIR, "$sysconfdir")
 555 AS_AC_EXPAND(LXC_DEFAULT_CONFIG, "$sysconfdir/lxc/default.conf")
 556 AS_AC_EXPAND(DATADIR, "$datadir")
 557 AS_AC_EXPAND(LOCALSTATEDIR, "$localstatedir")
 558 AS_AC_EXPAND(DOCDIR, "$docdir")
 559 AS_AC_EXPAND(LXC_GENERATE_DATE, "$(date --utc --date=@${SOURCE_DATE_EPOCH:-$(date +%s)} '+%Y-%m-%d')")
 560 AS_AC_EXPAND(LXCPATH, "$with_config_path")
 561 AS_AC_EXPAND(LXC_GLOBAL_CONF, "$with_global_conf")
 562 AS_AC_EXPAND(LXC_USERNIC_CONF, "$with_usernic_conf")
 563 AS_AC_EXPAND(LXC_USERNIC_DB, "$with_usernic_db")
 564 AS_AC_EXPAND(LXC_DISTRO_SYSCONF, "$distrosysconf")
 565 AS_AC_EXPAND(LXCROOTFSMOUNT, "$with_rootfs_path")
 566 AS_AC_EXPAND(LXCTEMPLATEDIR, "$datadir/lxc/templates")
 567 AS_AC_EXPAND(LXCTEMPLATECONFIG, "$datadir/lxc/config")
 568 AS_AC_EXPAND(LXCHOOKDIR, "$datadir/lxc/hooks")
 569 AS_AC_EXPAND(LXCBINHOOKDIR, "$libexecdir/lxc/hooks")
 570 AS_AC_EXPAND(LXCINITDIR, "$libexecdir")
 571 AS_AC_EXPAND(LOGPATH, "$with_log_path")
 572 AS_AC_EXPAND(RUNTIME_PATH, "$with_runtime_path")
 573 AC_SUBST(DEFAULT_CGROUP_PATTERN, ["$with_cgroup_pattern"])
 574
 575 # We need the install path so criu knows where to reference the hook scripts.
 576 AC_DEFINE_UNQUOTED([DATADIR], "$DATADIR", ["Prefix for shared files."])
 577
 578 # Check for some standard kernel headers
 579 AC_CHECK_HEADERS([linux/unistd.h linux/netlink.h linux/genetlink.h],
 580                                 [],
 581                                 AC_MSG_ERROR([Please install the Linux kernel headers.]),
 582                                 [#include <sys/socket.h>])
 583
 584 # Check for alternate C libraries
 585 AC_MSG_CHECKING(for bionic libc)
 586 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 587         [[#ifndef __ANDROID__
 588 error: Not bionic!
 589 #endif]])],
 590         [is_bionic=yes],
 591         [is_bionic=no])
 592 if test "x$is_bionic" = "xyes"; then
 593         AC_DEFINE([IS_BIONIC], 1, [bionic libc])
 594         AC_MSG_RESULT([yes])
 595 else
 596         AC_MSG_RESULT([no])
 597 fi
 598 AM_CONDITIONAL([IS_BIONIC], [test "x$is_bionic" = "xyes"])
 599
 600 # Some systems lack PR_CAPBSET_DROP definition => HAVE_DECL_PR_CAPBSET_DROP
 601 AC_CHECK_DECLS([PR_CAPBSET_DROP], [], [], [#include <sys/prctl.h>])
 602
 603 # Some systems lack PR_{G,S}ET_NO_NEW_PRIVS definition => HAVE_DECL_PR_{G,S}ET_NO_NEW_PRIVS
 604 AC_CHECK_DECLS([PR_SET_NO_NEW_PRIVS], [], [], [#include <sys/prctl.h>])
 605 AC_CHECK_DECLS([PR_GET_NO_NEW_PRIVS], [], [], [#include <sys/prctl.h>])
 606
 607 # Check for some headers
 608 AC_CHECK_HEADERS([sys/signalfd.h pty.h ifaddrs.h sys/capability.h sys/personality.h utmpx.h sys/timerfd.h])
 609
 610 # Check for some syscalls functions
 611 AC_CHECK_FUNCS([setns pivot_root sethostname unshare rand_r confstr faccessat])
 612
 613 # Check for some functions
 614 AC_CHECK_LIB(pthread, main)
 615 AC_CHECK_FUNCS(pthread_atfork)
 616 AC_CHECK_FUNCS(statvfs)
 617 AC_CHECK_LIB(util, openpty)
 618 AC_CHECK_FUNCS([openpty hasmntopt setmntent endmntent utmpxname])
 619 AC_CHECK_FUNCS([getline],
 620         AM_CONDITIONAL(HAVE_GETLINE, true)
 621         AC_DEFINE(HAVE_GETLINE,1,[Have getline]),
 622         AM_CONDITIONAL(HAVE_GETLINE, false))
 623 AC_CHECK_FUNCS([getsubopt],
 624         AM_CONDITIONAL(HAVE_GETSUBOPT, true)
 625         AC_DEFINE(HAVE_GETSUBOPT,1,[Have getsubopt]),
 626         AM_CONDITIONAL(HAVE_GETSUBOPT, false))
 627 AC_CHECK_FUNCS([fgetln],
 628         AM_CONDITIONAL(HAVE_FGETLN, true)
 629         AC_DEFINE(HAVE_FGETLN,1,[Have fgetln]),
 630         AM_CONDITIONAL(HAVE_FGETLN, false))
 631
 632 # Check for some libraries
 633 AC_SEARCH_LIBS(sem_open, [rt pthread])
 634 AC_SEARCH_LIBS(clock_gettime, [rt])
 635
 636 # Check for some standard binaries
 637 AC_PROG_GCC_TRADITIONAL
 638 AC_PROG_SED
 639
 640 # See if we support thread-local storage.
 641 LXC_CHECK_TLS
 642
 643 if test "x$GCC" = "xyes"; then
 644         CFLAGS="$CFLAGS -Wall"
 645         if test "x$enable_werror" = "xyes"; then
 646                 CFLAGS="$CFLAGS -Werror"
 647         fi
 648 fi
 649
 650 # Files requiring some variable expansion
 651 AC_CONFIG_FILES([
 652         Makefile
 653         lxc.pc
 654         lxc.spec
 655
 656         config/Makefile
 657         config/apparmor/Makefile
 658         config/selinux/Makefile
 659         config/bash/Makefile
 660         config/bash/lxc
 661         config/init/Makefile
 662         config/init/common/Makefile
 663         config/init/common/lxc-containers
 664         config/init/common/lxc-net
 665         config/init/systemd/Makefile
 666         config/init/systemd/lxc.service
 667         config/init/systemd/lxc@.service
 668         config/init/systemd/lxc-net.service
 669         config/init/sysvinit/Makefile
 670         config/init/sysvinit/lxc-containers
 671         config/init/sysvinit/lxc-net
 672         config/init/upstart/lxc.conf
 673         config/init/upstart/lxc-net.conf
 674         config/init/upstart/Makefile
 675         config/etc/Makefile
 676         config/templates/Makefile
 677         config/templates/alpine.common.conf
 678         config/templates/alpine.userns.conf
 679         config/templates/archlinux.common.conf
 680         config/templates/archlinux.userns.conf
 681         config/templates/centos.common.conf
 682         config/templates/centos.userns.conf
 683         config/templates/common.conf
 684         config/templates/common.conf.d/Makefile
 685         config/templates/debian.common.conf
 686         config/templates/debian.userns.conf
 687         config/templates/fedora.common.conf
 688         config/templates/fedora.userns.conf
 689         config/templates/gentoo.common.conf
 690         config/templates/gentoo.moresecure.conf
 691         config/templates/gentoo.userns.conf
 692         config/templates/nesting.conf
 693         config/templates/opensuse.common.conf
 694         config/templates/opensuse.userns.conf
 695         config/templates/oracle.common.conf
 696         config/templates/oracle.userns.conf
 697         config/templates/plamo.common.conf
 698         config/templates/plamo.userns.conf
 699         config/templates/slackware.common.conf
 700         config/templates/slackware.userns.conf
 701         config/templates/ubuntu-cloud.common.conf
 702         config/templates/ubuntu-cloud.lucid.conf
 703         config/templates/ubuntu-cloud.userns.conf
 704         config/templates/ubuntu.common.conf
 705         config/templates/ubuntu.lucid.conf
 706         config/templates/ubuntu.userns.conf
 707         config/templates/openwrt.common.conf
 708         config/templates/sparclinux.common.conf
 709         config/templates/sparclinux.userns.conf
 710         config/templates/userns.conf
 711         config/yum/Makefile
 712         config/sysconfig/Makefile
 713         config/sysconfig/lxc
 714
 715         doc/Makefile
 716         doc/api/Makefile
 717         doc/lxc-attach.sgml
 718         doc/lxc-autostart.sgml
 719         doc/lxc-cgroup.sgml
 720         doc/lxc-checkconfig.sgml
 721         doc/lxc-checkpoint.sgml
 722         doc/lxc-clone.sgml
 723         doc/lxc-config.sgml
 724         doc/lxc-console.sgml
 725         doc/lxc-copy.sgml
 726         doc/lxc-create.sgml
 727         doc/lxc-destroy.sgml
 728         doc/lxc-device.sgml
 729         doc/lxc-execute.sgml
 730         doc/lxc-freeze.sgml
 731         doc/lxc-info.sgml
 732         doc/lxc-ls.sgml
 733         doc/lxc-monitor.sgml
 734         doc/lxc-snapshot.sgml
 735         doc/lxc-start-ephemeral.sgml
 736         doc/lxc-start.sgml
 737         doc/lxc-stop.sgml
 738         doc/lxc-top.sgml
 739         doc/lxc-unfreeze.sgml
 740         doc/lxc-unshare.sgml
 741         doc/lxc-user-nic.sgml
 742         doc/lxc-usernsexec.sgml
 743         doc/lxc-wait.sgml
 744
 745         doc/lxc.conf.sgml
 746         doc/lxc.container.conf.sgml
 747         doc/lxc.system.conf.sgml
 748         doc/lxc-usernet.sgml
 749         doc/lxc.sgml
 750         doc/common_options.sgml
 751         doc/see_also.sgml
 752
 753         doc/rootfs/Makefile
 754
 755         doc/examples/Makefile
 756         doc/examples/lxc-macvlan.conf
 757         doc/examples/lxc-vlan.conf
 758         doc/examples/lxc-no-netns.conf
 759         doc/examples/lxc-empty-netns.conf
 760         doc/examples/lxc-phys.conf
 761         doc/examples/lxc-veth.conf
 762         doc/examples/lxc-complex.conf
 763
 764         doc/ja/Makefile
 765         doc/ja/lxc-attach.sgml
 766         doc/ja/lxc-autostart.sgml
 767         doc/ja/lxc-cgroup.sgml
 768         doc/ja/lxc-checkconfig.sgml
 769         doc/ja/lxc-checkpoint.sgml
 770         doc/ja/lxc-clone.sgml
 771         doc/ja/lxc-config.sgml
 772         doc/ja/lxc-console.sgml
 773         doc/ja/lxc-copy.sgml
 774         doc/ja/lxc-create.sgml
 775         doc/ja/lxc-destroy.sgml
 776         doc/ja/lxc-device.sgml
 777         doc/ja/lxc-execute.sgml
 778         doc/ja/lxc-freeze.sgml
 779         doc/ja/lxc-info.sgml
 780         doc/ja/lxc-ls.sgml
 781         doc/ja/lxc-monitor.sgml
 782         doc/ja/lxc-snapshot.sgml
 783         doc/ja/lxc-start-ephemeral.sgml
 784         doc/ja/lxc-start.sgml
 785         doc/ja/lxc-stop.sgml
 786         doc/ja/lxc-top.sgml
 787         doc/ja/lxc-unfreeze.sgml
 788         doc/ja/lxc-unshare.sgml
 789         doc/ja/lxc-user-nic.sgml
 790         doc/ja/lxc-usernsexec.sgml
 791         doc/ja/lxc-wait.sgml
 792
 793         doc/ja/lxc.conf.sgml
 794         doc/ja/lxc.container.conf.sgml
 795         doc/ja/lxc.system.conf.sgml
 796         doc/ja/lxc-usernet.sgml
 797         doc/ja/lxc.sgml
 798         doc/ja/common_options.sgml
 799         doc/ja/see_also.sgml
 800
 801         doc/ko/Makefile
 802         doc/ko/lxc-attach.sgml
 803         doc/ko/lxc-autostart.sgml
 804         doc/ko/lxc-cgroup.sgml
 805         doc/ko/lxc-checkconfig.sgml
 806         doc/ko/lxc-checkpoint.sgml
 807         doc/ko/lxc-clone.sgml
 808         doc/ko/lxc-config.sgml
 809         doc/ko/lxc-console.sgml
 810         doc/ko/lxc-copy.sgml
 811         doc/ko/lxc-create.sgml
 812         doc/ko/lxc-destroy.sgml
 813         doc/ko/lxc-device.sgml
 814         doc/ko/lxc-execute.sgml
 815         doc/ko/lxc-freeze.sgml
 816         doc/ko/lxc-info.sgml
 817         doc/ko/lxc-ls.sgml
 818         doc/ko/lxc-monitor.sgml
 819         doc/ko/lxc-snapshot.sgml
 820         doc/ko/lxc-start-ephemeral.sgml
 821         doc/ko/lxc-start.sgml
 822         doc/ko/lxc-stop.sgml
 823         doc/ko/lxc-top.sgml
 824         doc/ko/lxc-unfreeze.sgml
 825         doc/ko/lxc-unshare.sgml
 826         doc/ko/lxc-user-nic.sgml
 827         doc/ko/lxc-usernsexec.sgml
 828         doc/ko/lxc-wait.sgml
 829
 830         doc/ko/lxc.conf.sgml
 831         doc/ko/lxc.container.conf.sgml
 832         doc/ko/lxc.system.conf.sgml
 833         doc/ko/lxc-usernet.sgml
 834         doc/ko/lxc.sgml
 835         doc/ko/common_options.sgml
 836         doc/ko/see_also.sgml
 837
 838         hooks/Makefile
 839
 840         templates/Makefile
 841         templates/lxc-alpine
 842         templates/lxc-altlinux
 843         templates/lxc-archlinux
 844         templates/lxc-busybox
 845         templates/lxc-centos
 846         templates/lxc-cirros
 847         templates/lxc-debian
 848         templates/lxc-download
 849         templates/lxc-fedora
 850         templates/lxc-gentoo
 851         templates/lxc-openmandriva
 852         templates/lxc-opensuse
 853         templates/lxc-oracle
 854         templates/lxc-plamo
 855         templates/lxc-pld
 856         templates/lxc-slackware
 857         templates/lxc-sshd
 858         templates/lxc-ubuntu
 859         templates/lxc-ubuntu-cloud
 860         templates/lxc-sparclinux
 861
 862         src/Makefile
 863         src/lxc/Makefile
 864         src/lxc/lxc.functions
 865         src/lxc/tools/lxc-checkconfig
 866         src/lxc/tools/lxc-start-ephemeral
 867         src/lxc/version.h
 868         src/python-lxc/Makefile
 869
 870         src/lua-lxc/Makefile
 871
 872         src/tests/Makefile
 873         src/tests/lxc-test-usernic
 874 ])
 875 AC_CONFIG_COMMANDS([default],[[]],[[]])
 876 AC_OUTPUT
 877
 878 # Configuration overview
 879 cat << EOF
 880
 881 ----------------------------
 882 Environment:
 883  - compiler: $CC
 884  - distribution: $with_distro
 885  - init script type(s): $init_script
 886  - rpath: $enable_rpath
 887  - GnuTLS: $enable_gnutls
 888  - Bash integration: $enable_bash
 889
 890 Security features:
 891  - Apparmor: $enable_apparmor
 892  - Linux capabilities: $enable_capabilities
 893  - seccomp: $enable_seccomp
 894  - SELinux: $enable_selinux
 895  - cgmanager: $enable_cgmanager
 896
 897 Bindings:
 898  - lua: $enable_lua
 899  - python3: $enable_python
 900
 901 Documentation:
 902  - examples: $enable_examples
 903  - API documentation: $enable_api_docs
 904  - user documentation: $enable_doc
 905
 906 Debugging:
 907  - tests: $enable_tests
 908  - mutex debugging: $enable_mutex_debugging
 909
 910 Paths:
 911  - Logs in configpath: $enable_configpath_log
 912 EOF
 913
 914 if test "x$ac_cv_func_pthread_atfork" = "xno" ; then
 915 cat << EOF
 916
 917 WARNING: Threading not supported on your platform
 918
 919         You are compiling LXC for bionic target which lacks certain threading related functionality used by LXC API (like pthread_atfork).
 920         Please note that, because of the missing functionality, multithreaded usage of LXC API cause some problems.
 921 EOF
 922 fi