configure.ac

   1 ##
   2 ## Configure template file for FRRouting.
   3 ## autoconf will generate configure script.
   4 ##
   5 ##  Copyright (c) 1996, 97, 98, 99, 2000 Kunihiro Ishiguro <kunihiro@zebra.org>
   6 ##  Portions Copyright (c) 2003 Paul Jakma <paul@dishone.st>
   7 ##
   8 AC_PREREQ(2.60)
   9
  10 AC_INIT(frr, 5.1-dev, [https://github.com/frrouting/frr/issues])
  11 PACKAGE_URL="https://frrouting.org/"
  12 AC_SUBST(PACKAGE_URL)
  13 PACKAGE_FULLNAME="FRRouting"
  14 AC_SUBST(PACKAGE_FULLNAME)
  15
  16 CONFIG_ARGS="$ac_configure_args"
  17 AC_SUBST(CONFIG_ARGS)
  18
  19 AC_CONFIG_SRCDIR(lib/zebra.h)
  20 AC_CONFIG_MACRO_DIR([m4])
  21
  22 dnl -----------------------------------
  23 dnl Get hostname and other information.
  24 dnl -----------------------------------
  25 AC_CANONICAL_BUILD()
  26 AC_CANONICAL_HOST()
  27
  28 AS_IF([test "$host" != "$build"], [
  29   if test "$srcdir" = "."; then
  30     AC_MSG_ERROR([cross-compilation is only possible with builddir separate from srcdir.  create a separate directory and run as .../path-to-frr/configure.])
  31   fi
  32   test -d hosttools || mkdir hosttools
  33   abssrc="`cd \"${srcdir}\"; pwd`"
  34
  35   AC_MSG_NOTICE([...])
  36   AC_MSG_NOTICE([... cross-compilation: creating hosttools directory and self-configuring for build platform tools])
  37   AC_MSG_NOTICE([... use HOST_CPPFLAGS / HOST_CFLAGS / HOST_LDFLAGS if neccessary])
  38   AC_MSG_NOTICE([...])
  39
  40   ( CPPFLAGS="$HOST_CPPFLAGS"; \
  41     CFLAGS="$HOST_CFLAGS"; \
  42     LDFLAGS="$HOST_LDFLAGS"; \
  43     cd hosttools; "${abssrc}/configure" "--host=$build" "--build=$build" "--enable-clippy-only" "--disable-nhrpd" "--disable-vtysh"; )
  44
  45   AC_MSG_NOTICE([...])
  46   AC_MSG_NOTICE([... cross-compilation: finished self-configuring for build platform tools])
  47   AC_MSG_NOTICE([...])
  48
  49   build_clippy="false"
  50   HOSTTOOLS="hosttools/"
  51 ], [
  52   build_clippy="true"
  53   HOSTTOOLS=""
  54 ])
  55 AC_SUBST(HOSTTOOLS)
  56 AM_CONDITIONAL([BUILD_CLIPPY], [$build_clippy])
  57
  58 # Disable portability warnings -- our automake code (in particular
  59 # common.am) uses some constructs specific to gmake.
  60 AM_INIT_AUTOMAKE([1.12 -Wno-portability])
  61 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
  62 AM_SILENT_RULES([yes])
  63 AC_CONFIG_HEADERS(config.h)
  64
  65 AC_PATH_PROG(PERL, perl)
  66 PKG_PROG_PKG_CONFIG
  67
  68 dnl default is to match previous behavior
  69 exampledir=${sysconfdir}
  70 AC_ARG_ENABLE([exampledir],
  71           AS_HELP_STRING([--enable-exampledir],
  72                          [specify alternate directory for examples]),
  73                          exampledir="$enableval",)
  74 dnl XXX add --exampledir to autoconf standard directory list somehow
  75 AC_SUBST(exampledir)
  76
  77 dnl default is to match previous behavior
  78 pkgsrcrcdir=""
  79 AC_ARG_ENABLE([pkgsrcrcdir],
  80           AS_HELP_STRING([--enable-pkgsrcrcdir],
  81                          [specify directory for rc.d scripts]),
  82                          pkgsrcrcdir="$enableval",)
  83 dnl XXX add --pkgsrcrcdir to autoconf standard directory list somehow
  84 AC_SUBST(pkgsrcrcdir)
  85 AM_CONDITIONAL([PKGSRC], [test "x$pkgsrcrcdir" != "x"])
  86
  87 AC_ARG_WITH([moduledir], [AS_HELP_STRING([--with-moduledir=DIR], [module directory (${libdir}/frr/modules)])], [
  88         moduledir="$withval"
  89 ], [
  90         moduledir="\${libdir}/frr/modules"
  91 ])
  92 AC_SUBST([moduledir], [$moduledir])
  93
  94 AC_ARG_ENABLE(tcmalloc,
  95         AS_HELP_STRING([--enable-tcmalloc], [Turn on tcmalloc]),
  96 [case "${enableval}" in
  97   yes) tcmalloc_enabled=true
  98 LIBS="$LIBS -ltcmalloc_minimal"
  99  ;;
 100   no)  tcmalloc_enabled=false ;;
 101   *) AC_MSG_ERROR(bad value ${enableval} for --enable-tcmalloc) ;;
 102 esac],[tcmalloc_enabled=false])
 103
 104
 105 dnl Thanks autoconf, but we don't want a default -g -O2.  We have our own
 106 dnl flag determination logic.
 107 CFLAGS="${CFLAGS:-}"
 108
 109 dnl --------------------
 110 dnl Check CC and friends
 111 dnl --------------------
 112 dnl note orig_cflags is also used further down
 113 orig_cflags="$CFLAGS"
 114 AC_LANG([C])
 115 AC_PROG_CC
 116 AC_PROG_CPP
 117 AM_PROG_CC_C_O
 118 dnl remove autoconf default "-g -O2"
 119 CFLAGS="$orig_cflags"
 120 AC_PROG_CC_C99
 121 dnl NB: see C11 below
 122
 123 AC_PROG_EGREP
 124 PKG_PROG_PKG_CONFIG
 125
 126 dnl autoconf 2.59 appears not to support AC_PROG_SED
 127 dnl AC_PROG_SED
 128 AC_CHECK_PROG([SED],[sed],[sed],[/bin/false])
 129
 130 dnl try and enable CFLAGS that are useful for FRR
 131 dnl - specifically, options to control warnings
 132
 133 AC_USE_SYSTEM_EXTENSIONS
 134 AC_DEFUN([AC_C_FLAG], [{
 135         AC_LANG_PUSH(C)
 136         ac_c_flag_save="$CFLAGS"
 137         CFLAGS="$CFLAGS $1"
 138         AC_MSG_CHECKING([[whether $CC supports $1]])
 139         AC_COMPILE_IFELSE(
 140                 [AC_LANG_PROGRAM([[]])],
 141                 [
 142                         AC_MSG_RESULT([yes])
 143                         m4_if([$3], [], [], [
 144                                 CFLAGS="$ac_c_flag_save"
 145                                 $3
 146                         ])
 147                 ], [
 148                         CFLAGS="$ac_c_flag_save"
 149                         AC_MSG_RESULT([no])
 150                         $2
 151                 ])
 152         AC_LANG_POP(C)
 153         }])
 154
 155 AC_DEFUN([AC_LINK_IFELSE_FLAGS], [{
 156         AC_LANG_PUSH(C)
 157         ac_cflags_save="$CFLAGS"
 158         ac_libs_save="$LIBS"
 159         CFLAGS="$CFLAGS $1"
 160         LIBS="$LIBS $2"
 161         AC_LINK_IFELSE(
 162                 [$3],
 163                 [
 164                         AC_MSG_RESULT([yes])
 165                         CFLAGS="$ac_cflags_save"
 166                         LIBS="$ac_libs_save"
 167                         $5
 168                 ], [
 169                         AC_MSG_RESULT([no])
 170                         CFLAGS="$ac_cflags_save"
 171                         LIBS="$ac_libs_save"
 172                         $4
 173                 ])
 174         AC_LANG_POP(C)
 175         }])
 176
 177 dnl ICC won't bail on unknown options without -diag-error 10006
 178 dnl need to do this first so we get useful results for the other options
 179 AC_C_FLAG([-diag-error 10006])
 180
 181 dnl AC_PROG_CC_C99 may change CC to include -std=gnu99 or something
 182 ac_cc="$CC"
 183 CC="${CC% -std=gnu99}"
 184 CC="${CC% -std=c99}"
 185
 186 AC_C_FLAG([-std=gnu11], [CC="$ac_cc"], [CC="$CC -std=gnu11"])
 187
 188 dnl AddressSanitizer support
 189 AC_ARG_ENABLE([address-sanitizer], AS_HELP_STRING([--enable-address-sanitizer], \
 190               [enabled AddressSanitizer support for detecting a wide variety of \
 191                memory allocation and deallocation errors]), \
 192               [AC_DEFINE(HAVE_ADDRESS_SANITIZER, 1, [enable AddressSanitizer])
 193               CFLAGS="$CFLAGS -fsanitize=address"
 194               CXXFLAGS="$CXXFLAGS -fsanitize=address"
 195               LIBS="-ldl $LIBS"
 196               AC_TRY_COMPILE([],[const int i=0;],[AC_MSG_NOTICE([Address Sanitizer Enabled])],
 197                                                  [AC_MSG_ERROR([Address Sanitizer not available])])
 198               ])
 199
 200 dnl ThreadSanitizer support
 201 AC_ARG_ENABLE([thread-sanitizer], AS_HELP_STRING([--enable-thread-sanitizer], \
 202               [enabled ThreadSanitizer support for detecting data races]), \
 203               [AC_DEFINE(HAVE_THREAD_SANITIZER, 1, [enable ThreadSanitizer])
 204               CFLAGS="$CFLAGS -fsanitize=thread"
 205               CXXFLAGS="$CXXFLAGS -fsanitize=thread"
 206               LIBS="-ldl $LIBS"
 207               AC_TRY_COMPILE([],[const int i=0;],[AC_MSG_NOTICE([Thread Sanitizer Enabled])],
 208                                                  [AC_MSG_ERROR([Thread Sanitizer not available])])
 209               ])
 210
 211 dnl MemorySanitizer support
 212 AC_ARG_ENABLE([memory-sanitizer], AS_HELP_STRING([--enable-memory-sanitizer], \
 213               [enabled MemorySanitizer support for detecting uninitialized memory reads]), \
 214               [AC_DEFINE(HAVE_THREAD_SANITIZER, 1, [enable MemorySanitizer])
 215               CFLAGS="$CFLAGS -fsanitize=memory -fPIE -pie"
 216               CXXFLAGS="$CXXFLAGS -fsanitize=memory -fPIE -pie"
 217               LIBS="-ldl $LIBS"
 218               AC_TRY_COMPILE([],[const int i=0;],[AC_MSG_NOTICE([Memory Sanitizer Enabled])],
 219                                                  [AC_MSG_ERROR([Memory Sanitizer not available])])
 220               ])
 221
 222 dnl if the user has specified any CFLAGS, override our settings
 223 if test "x${enable_dev_build}" = "xyes"; then
 224    AC_DEFINE(DEV_BUILD,,Build for development)
 225    if test "z$orig_cflags" = "z"; then
 226       AC_C_FLAG([-g3])
 227       AC_C_FLAG([-O0])
 228    fi
 229 else
 230    if test "z$orig_cflags" = "z"; then
 231       AC_C_FLAG([-g])
 232       AC_C_FLAG([-Os], [
 233         AC_C_FLAG([-O2])
 234       ])
 235    fi
 236 fi
 237 AM_CONDITIONAL([DEV_BUILD], [test "x$enable_dev_build" = "xyes"])
 238
 239 dnl always want these CFLAGS
 240 AC_C_FLAG([-fno-omit-frame-pointer])
 241 AC_C_FLAG([-funwind-tables])
 242 AC_C_FLAG([-Wall])
 243 AC_C_FLAG([-Wextra])
 244 AC_C_FLAG([-Wmissing-prototypes])
 245 AC_C_FLAG([-Wmissing-declarations])
 246 AC_C_FLAG([-Wpointer-arith])
 247 AC_C_FLAG([-Wbad-function-cast])
 248 AC_C_FLAG([-Wwrite-strings])
 249 if test x"${enable_gcc_ultra_verbose}" = x"yes" ; then
 250   AC_C_FLAG([-Wcast-qual])
 251   AC_C_FLAG([-Wstrict-prototypes])
 252   AC_C_FLAG([-Wmissing-noreturn])
 253   AC_C_FLAG([-Wmissing-format-attribute])
 254   AC_C_FLAG([-Wunreachable-code])
 255   AC_C_FLAG([-Wpacked])
 256   AC_C_FLAG([-Wpadded])
 257 else
 258   AC_C_FLAG([-Wno-unused-result])
 259 fi
 260 AC_C_FLAG([-Wno-unused-parameter])
 261 AC_C_FLAG([-Wno-missing-field-initializers])
 262
 263 dnl ICC emits a broken warning for const char *x = a ? "b" : "c";
 264 dnl for some reason the string consts get 'promoted' to char *,
 265 dnl triggering a const to non-const conversion warning.
 266 AC_C_FLAG([-diag-disable 3179])
 267
 268 if test x"${enable_werror}" = x"yes" ; then
 269   WERROR="-Werror"
 270 fi
 271 AC_SUBST(WERROR)
 272
 273 dnl need link on this one, not compile
 274 AC_LANG_PUSH(C)
 275 ac_ld_flag_save="$LDFLAGS"
 276 LDFLAGS="$LDFLAGS -rdynamic"
 277 AC_MSG_CHECKING([[whether linker supports -rdynamic]])
 278 AC_LINK_IFELSE(
 279         [AC_LANG_PROGRAM([[]])],
 280         [AC_MSG_RESULT([yes])],
 281         [
 282                 LDFLAGS="$ac_ld_flag_save"
 283                 AC_MSG_RESULT([no])
 284         ])
 285 AC_LANG_POP(C)
 286
 287 dnl ----------
 288 dnl Essentials
 289 dnl ----------
 290
 291 AX_PTHREAD([
 292   CC="$PTHREAD_CC"
 293   CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 294   LIBS="$PTHREAD_LIBS $LIBS"
 295 ], [
 296   AC_MSG_FAILURE([This FRR version needs pthreads])
 297 ])
 298
 299 dnl --------------
 300 dnl Check programs
 301 dnl --------------
 302 AC_PROG_INSTALL
 303 AC_PROG_LN_S
 304 AC_PROG_MAKE_SET
 305 AC_CHECK_TOOL(AR, ar)
 306
 307 dnl -----------------
 308 dnl System extensions
 309 dnl -----------------
 310 AC_GNU_SOURCE
 311
 312 dnl -------
 313 dnl libtool
 314 dnl -------
 315 LT_INIT
 316
 317 dnl ----------------------
 318 dnl Packages configuration
 319 dnl ----------------------
 320 AC_ARG_WITH(pkg-extra-version,
 321         AS_HELP_STRING([--with-pkg-extra-version=VER], [add extra version field, for packagers/distributions]),
 322         [EXTRAVERSION=$withval],)
 323 AC_ARG_WITH(pkg-git-version,
 324         AS_HELP_STRING([--with-pkg-git-version], [add git information to MOTD and build version string]),
 325         [ test "x$withval" != "xno" && with_pkg_git_version="yes" ])
 326 AC_ARG_WITH(vtysh_pager,
 327         AS_HELP_STRING([--with-vtysh-pager=PAGER], [control what pager is compiled in as default]),
 328         VTYSH_PAGER=$withval, VTYSH_PAGER="more")
 329 AC_ARG_ENABLE(vtysh,
 330   AS_HELP_STRING([--disable-vtysh], [do not build integrated vty shell for FRR]))
 331 AC_ARG_ENABLE(doc,
 332   AS_HELP_STRING([--disable-doc], [do not build docs]))
 333 AC_ARG_ENABLE(zebra,
 334   AS_HELP_STRING([--disable-zebra], [do not build zebra daemon]))
 335 AC_ARG_ENABLE(bgpd,
 336   AS_HELP_STRING([--disable-bgpd], [do not build bgpd]))
 337 AC_ARG_ENABLE(ripd,
 338   AS_HELP_STRING([--disable-ripd], [do not build ripd]))
 339 AC_ARG_ENABLE(ripngd,
 340   AS_HELP_STRING([--disable-ripngd], [do not build ripngd]))
 341 AC_ARG_ENABLE(ospfd,
 342   AS_HELP_STRING([--disable-ospfd], [do not build ospfd]))
 343 AC_ARG_ENABLE(ospf6d,
 344   AS_HELP_STRING([--disable-ospf6d], [do not build ospf6d]))
 345 AC_ARG_ENABLE(ldpd,
 346   AS_HELP_STRING([--enable-ldpd], [build ldpd]))
 347 AC_ARG_ENABLE(nhrpd,
 348   AS_HELP_STRING([--disable-nhrpd], [do not build nhrpd]))
 349 AC_ARG_ENABLE(eigrpd,
 350   AS_HELP_STRING([--disable-eigrpd], [do not build eigrpd]))
 351 AC_ARG_ENABLE(babeld,
 352   AS_HELP_STRING([--disable-babeld], [do not build babeld]))
 353 AC_ARG_ENABLE(watchfrr,
 354   AS_HELP_STRING([--disable-watchfrr], [do not build watchfrr]))
 355 AC_ARG_ENABLE(isisd,
 356   AS_HELP_STRING([--disable-isisd], [do not build isisd]))
 357 AC_ARG_ENABLE(pimd,
 358   AS_HELP_STRING([--disable-pimd], [do not build pimd]))
 359 AC_ARG_ENABLE(pbrd,
 360   AS_HELP_STRING([--disable-pbrd], [do not build pbrd]))
 361 AC_ARG_ENABLE(sharpd,
 362   AS_HELP_STRING([--enable-sharpd], [do not build sharpd]))
 363 AC_ARG_ENABLE(bgp-announce,
 364   AS_HELP_STRING([--disable-bgp-announce,], [turn off BGP route announcement]))
 365 AC_ARG_ENABLE(bgp-vnc,
 366   AS_HELP_STRING([--disable-bgp-vnc],[turn off BGP VNC support]))
 367 AC_ARG_WITH(rfp-path,
 368   AS_HELP_STRING([--with-rfp-path[=DIR]],[path to replaced stub RFP used with BGP VNC]))
 369 AC_ARG_ENABLE(snmp,
 370   AS_HELP_STRING([--enable-snmp=ARG], [enable SNMP support (smux or agentx)]))
 371 AC_ARG_ENABLE(zeromq,
 372   AS_HELP_STRING([--enable-zeromq], [enable ZeroMQ handler (libfrrzmq)]))
 373 AC_ARG_WITH(libpam,
 374   AS_HELP_STRING([--with-libpam], [use libpam for PAM support in vtysh]))
 375 AC_ARG_ENABLE(ospfapi,
 376   AS_HELP_STRING([--disable-ospfapi], [do not build OSPFAPI to access the OSPF LSA Database]))
 377 AC_ARG_ENABLE(ospfclient,
 378   AS_HELP_STRING([--disable-ospfclient], [do not build OSPFAPI client for OSPFAPI,
 379                           (this is the default if --disable-ospfapi is set)]))
 380 AC_ARG_ENABLE(multipath,
 381   AS_HELP_STRING([--enable-multipath=ARG], [enable multipath function, ARG must be digit]))
 382 AC_ARG_ENABLE(user,
 383   AS_HELP_STRING([--enable-user=USER], [user to run FRR suite as (default frr)]))
 384 AC_ARG_ENABLE(group,
 385   AS_HELP_STRING([--enable-group=GROUP], [group to run FRR suite as (default frr)]))
 386 AC_ARG_ENABLE(vty_group,
 387   AS_HELP_STRING([--enable-vty-group=ARG], [set vty sockets to have specified group as owner]))
 388 AC_ARG_ENABLE(configfile_mask,
 389   AS_HELP_STRING([--enable-configfile-mask=ARG], [set mask for config files]))
 390 AC_ARG_ENABLE(logfile_mask,
 391   AS_HELP_STRING([--enable-logfile-mask=ARG], [set mask for log files]))
 392 AC_ARG_ENABLE(shell_access,
 393   AS_HELP_STRING([--enable-shell-access], [Allow users to access shell/telnet/ssh]))
 394 AC_ARG_ENABLE(realms,
 395   AS_HELP_STRING([--enable-realms], [enable REALMS support under Linux]))
 396 AC_ARG_ENABLE(rtadv,
 397   AS_HELP_STRING([--disable-rtadv], [disable IPV6 router advertisement feature]))
 398 AC_ARG_ENABLE(irdp,
 399   AS_HELP_STRING([--disable-irdp], [enable IRDP server support in zebra (default if supported)]))
 400 AC_ARG_ENABLE(capabilities,
 401   AS_HELP_STRING([--disable-capabilities], [disable using POSIX capabilities]))
 402 AC_ARG_ENABLE(rusage,
 403   AS_HELP_STRING([--disable-rusage], [disable using getrusage]))
 404 AC_ARG_ENABLE(gcc_ultra_verbose,
 405   AS_HELP_STRING([--enable-gcc-ultra-verbose], [enable ultra verbose GCC warnings]))
 406 AC_ARG_ENABLE(linux24_tcp_md5,
 407   AS_HELP_STRING([--enable-linux24-tcp-md5], [enable support for old, Linux-2.4 RFC2385 patch]))
 408 AC_ARG_ENABLE(backtrace,
 409   AS_HELP_STRING([--disable-backtrace,], [disable crash backtraces (default autodetect)]))
 410 AC_ARG_ENABLE(time-check,
 411   AS_HELP_STRING([--disable-time-check], [disable slow thread warning messages]))
 412 AC_ARG_ENABLE(pcreposix,
 413   AS_HELP_STRING([--enable-pcreposix], [enable using PCRE Posix libs for regex functions]))
 414 AC_ARG_ENABLE(fpm,
 415   AS_HELP_STRING([--enable-fpm], [enable Forwarding Plane Manager support]))
 416 AC_ARG_ENABLE(systemd,
 417   AS_HELP_STRING([--enable-systemd], [enable Systemd support]))
 418 AC_ARG_ENABLE(werror,
 419   AS_HELP_STRING([--enable-werror], [enable -Werror (recommended for developers only)]))
 420 AC_ARG_ENABLE(cumulus,
 421   AS_HELP_STRING([--enable-cumulus], [enable Cumulus Switch Special Extensions]))
 422 AC_ARG_ENABLE(datacenter,
 423   AS_HELP_STRING([--enable-datacenter], [enable Compilation for Data Center Extensions]))
 424 AC_ARG_ENABLE(fuzzing,
 425   AS_HELP_STRING([--enable-fuzzing], [enable ability to fuzz various parts of FRR]))
 426 AC_ARG_ENABLE(rr-semantics,
 427   AS_HELP_STRING([--disable-rr-semantics], [disable the v6 Route Replace semantics]))
 428 AC_ARG_ENABLE([protobuf],
 429   AS_HELP_STRING([--enable-protobuf], [Enable experimental protobuf support]))
 430 AC_ARG_ENABLE([oldvpn_commands],
 431   AS_HELP_STRING([--enable-oldvpn-commands], [Keep old vpn commands]))
 432 AC_ARG_ENABLE(rpki,
 433   AS_HELP_STRING([--enable-rpki], [enable RPKI prefix validation support]))
 434 AC_ARG_ENABLE([clippy-only],
 435   AS_HELP_STRING([--enable-clippy-only], [Only build clippy]))
 436 AC_ARG_ENABLE([numeric_version],
 437   AS_HELP_STRING([--enable-numeric-version], [Only numeric digits allowed in version (for Alpine)]))
 438
 439 AS_IF([test "${enable_clippy_only}" != "yes"], [
 440 AC_CHECK_HEADERS(json-c/json.h)
 441 AC_CHECK_LIB(json-c, json_object_get, LIBS="$LIBS -ljson-c", [], [-lm])
 442 if test $ac_cv_lib_json_c_json_object_get = no; then
 443   AC_CHECK_LIB(json, json_object_get, LIBS="$LIBS -ljson")
 444   if test $ac_cv_lib_json_json_object_get = no; then
 445       AC_MSG_ERROR([lib json is needed to compile])
 446   fi
 447 fi
 448 ])
 449
 450 AC_ARG_ENABLE([dev_build],
 451     AS_HELP_STRING([--enable-dev-build], [build for development]))
 452
 453 if test x"${enable_time_check}" != x"no" ; then
 454   if test x"${enable_time_check}" = x"yes" -o x"${enable_time_check}" = x ; then
 455     AC_DEFINE(CONSUMED_TIME_CHECK,5000000,Consumed Time Check)
 456   else
 457     AC_DEFINE_UNQUOTED(CONSUMED_TIME_CHECK,$enable_time_check,Consumed Time Check)
 458   fi
 459 fi
 460
 461 case "${enable_systemd}" in
 462   "no") ;;
 463   "yes")
 464   AC_CHECK_LIB(systemd, sd_notify, LIBS="$LIBS -lsystemd")
 465   if test $ac_cv_lib_systemd_sd_notify = no; then
 466     AC_MSG_ERROR([enable systemd has been specified but systemd development env not found on your system])
 467   else
 468     AC_DEFINE(HAVE_SYSTEMD,,Compile systemd support in)
 469   fi
 470   ;;
 471   "*") ;;
 472 esac
 473
 474 if test "${enable_rr_semantics}" != "no" ; then
 475   AC_DEFINE(HAVE_V6_RR_SEMANTICS,, Compile in v6 Route Replacement Semantics)
 476 fi
 477
 478 if test "${enable_datacenter}" = "yes" ; then
 479   AC_DEFINE(HAVE_DATACENTER,,Compile extensions for a DataCenter)
 480   DFLT_NAME="datacenter"
 481 else
 482   DFLT_NAME="traditional"
 483 fi
 484
 485 if test "${enable_fuzzing}" = "yes" ; then
 486   AC_DEFINE(HANDLE_ZAPI_FUZZING,,Compile extensions to use with a fuzzer)
 487 fi
 488
 489 if test "${enable_cumulus}" = "yes" ; then
 490   AC_DEFINE(HAVE_CUMULUS,,Compile Special Cumulus Code in)
 491 fi
 492
 493 AC_SUBST(DFLT_NAME)
 494 AC_DEFINE_UNQUOTED(DFLT_NAME,["$DFLT_NAME"], Name of the configuration default set)
 495
 496 if test "${enable_shell_access}" = "yes"; then
 497    AC_DEFINE(HAVE_SHELL_ACCESS,,Allow user to use ssh/telnet/bash)
 498 fi
 499
 500 AM_CONDITIONAL([FPM], [test "x$enable_fpm" = "xyes"])
 501
 502 #
 503 # Python for clippy
 504 #
 505 AS_IF([test "$host" = "$build"], [
 506   PYTHONCONFIG=""
 507
 508   # ordering:
 509   # 1.  try python3, but respect the user's preference on which minor ver
 510   # 2.  try python, which might be py3 or py2 again on the user's preference
 511   # 3.  try python2 (can really only be 2.7 but eh)
 512   # 4.  try 3.5 > 3.4 > 3.3 > 3.2 > 2.7 through pkg-config (no user pref)
 513   #
 514   # (AX_PYTHON_DEVEL has no clue about py3 vs py2)
 515   # (AX_PYTHON does not do what we need)
 516
 517   AC_CHECK_TOOLS([PYTHONCONFIG], [python3-config python-config python2-config])
 518   if test -n "$PYTHONCONFIG"; then
 519     PYTHON_CFLAGS="`\"${PYTHONCONFIG}\" --includes`"
 520     PYTHON_LIBS="`\"${PYTHONCONFIG}\" --libs`"
 521
 522     AC_MSG_CHECKING([whether we found a working Python version])
 523     AC_LINK_IFELSE_FLAGS([$PYTHON_CFLAGS], [$PYTHON_LIBS], [AC_LANG_PROGRAM([
 524 #include <Python.h>
 525 #if PY_VERSION_HEX < 0x02070000
 526 #error python too old
 527 #endif
 528 int main(void);
 529 ],
 530 [
 531 {
 532   Py_Initialize();
 533   return 0;
 534 }
 535 ])], [
 536       PYTHONCONFIG=""
 537       unset PYTHON_LIBS
 538       unset PYTHON_CFLAGS
 539     ])
 540   fi
 541
 542   if test -z "$PYTHONCONFIG"; then
 543     PKG_CHECK_MODULES([PYTHON], python-3.5, [], [
 544       PKG_CHECK_MODULES([PYTHON], python-3.4, [], [
 545         PKG_CHECK_MODULES([PYTHON], python-3.3, [], [
 546           PKG_CHECK_MODULES([PYTHON], python-3.2, [], [
 547             PKG_CHECK_MODULES([PYTHON], python-2.7, [], [
 548               AC_MSG_FAILURE([could not find python-config or pkg-config python, please install Python development files from libpython-dev or similar])
 549               ])])])])])
 550
 551
 552     AC_MSG_CHECKING([whether we found a working Python version])
 553     AC_LINK_IFELSE_FLAGS([$PYTHON_CFLAGS], [$PYTHON_LIBS], [AC_LANG_PROGRAM([
 554 #include <Python.h>
 555 #if PY_VERSION_HEX < 0x02070000
 556 #error python too old
 557 #endif
 558 int main(void);
 559 ],
 560 [
 561 {
 562   Py_Initialize();
 563   return 0;
 564 }
 565 ])], [
 566       AC_MSG_FAILURE([could not find python-config or pkg-config python, please install Python development files from libpython-dev or similar])
 567     ])
 568   fi
 569 ])
 570 AC_SUBST(PYTHON_CFLAGS)
 571 AC_SUBST(PYTHON_LIBS)
 572
 573 #
 574 # Logic for protobuf support.
 575 #
 576 if test "$enable_protobuf" = "yes"; then
 577    have_protobuf=yes
 578
 579    # Check for protoc-c
 580    AC_CHECK_PROG([PROTOC_C], [protoc-c], [protoc-c], [/bin/false])
 581    if test "x$PROTOC_C" = "x/bin/false"; then
 582       have_protobuf=no
 583    else
 584       found_protobuf_c=no
 585       PKG_CHECK_MODULES([PROTOBUF_C], libprotobuf-c >= 0.14,
 586                      [found_protobuf_c=yes],
 587                      [AC_MSG_RESULT([pkg-config did not find libprotobuf-c])])
 588
 589       if test "x$found_protobuf_c" = "xyes"; then
 590          LDFLAGS="$LDFLAGS $PROTOBUF_C_LIBS"
 591          CFLAGS="$CFLAGS $PROTOBUF_C_CFLAGS"
 592       else
 593         AC_CHECK_HEADER([google/protobuf-c/protobuf-c.h], [],
 594                         [have_protobuf=no; AC_MSG_RESULT([Couldn't find google/protobuf-c.h])])
 595       fi
 596    fi
 597 fi
 598
 599 #
 600 # Logic for old vpn commans support.
 601 #
 602 if test "$enable_oldvpn_commands" = "yes"; then
 603    AC_DEFINE(KEEP_OLD_VPN_COMMANDS,, [Define for compiling with old vpn commands])
 604 fi
 605
 606 # Fail if the user explicity enabled protobuf support and we couldn't
 607 # find the compiler or libraries.
 608 if test "x$have_protobuf" = "xno" && test "x$enable_protobuf" = "xyes"; then
 609    AC_MSG_ERROR([Protobuf enabled explicitly but can't find libraries/tools])
 610 fi
 611
 612 if test "x$have_protobuf" = "xyes"; then
 613    AC_DEFINE(HAVE_PROTOBUF,, protobuf)
 614 fi
 615
 616 AM_CONDITIONAL([HAVE_PROTOBUF], [test "x$have_protobuf" = "xyes"])
 617
 618 #
 619 # End of logic for protobuf support.
 620 #
 621
 622 if test "${enable_linux24_tcp_md5}" = "yes"; then
 623   AC_DEFINE(HAVE_TCP_MD5_LINUX24,,Old Linux 2.4 TCP MD5 Signature Patch)
 624 fi
 625
 626 AC_MSG_CHECKING(if zebra should be configurable to send Route Advertisements)
 627 if test "${enable_rtadv}" != "no"; then
 628   AC_MSG_RESULT(yes)
 629   AC_DEFINE(HAVE_RTADV,,Enable IPv6 Routing Advertisement support)
 630 else
 631   AC_MSG_RESULT(no)
 632 fi
 633
 634 if test x"${enable_user}" = x"no"; then
 635   enable_user=""
 636 else
 637   if test x"${enable_user}" = x"yes" || test x"${enable_user}" = x""; then
 638     enable_user="frr"
 639   fi
 640   AC_DEFINE_UNQUOTED(FRR_USER, "${enable_user}", frr User)
 641 fi
 642
 643 if test x"${enable_group}" = x"no"; then
 644   enable_group=""
 645 else
 646   if test x"${enable_group}" = x"yes" || test x"${enable_group}" = x""; then
 647     enable_group="frr"
 648   fi
 649   AC_DEFINE_UNQUOTED(FRR_GROUP, "${enable_group}", frr Group)
 650 fi
 651
 652 if test x"${enable_vty_group}" = x"yes" ; then
 653   AC_MSG_ERROR([--enable-vty-group requires a group as argument, not yes])
 654 elif test x"${enable_vty_group}" != x""; then
 655   if test x"${enable_vty_group}" != x"no"; then
 656     AC_DEFINE_UNQUOTED(VTY_GROUP, "${enable_vty_group}", VTY Sockets Group)
 657   fi
 658 fi
 659 AC_SUBST([enable_user])
 660 AC_SUBST([enable_group])
 661 AC_SUBST([enable_vty_group])
 662
 663 enable_configfile_mask=${enable_configfile_mask:-0600}
 664 AC_DEFINE_UNQUOTED(CONFIGFILE_MASK, ${enable_configfile_mask}, Mask for config files)
 665
 666 enable_logfile_mask=${enable_logfile_mask:-0600}
 667 AC_DEFINE_UNQUOTED(LOGFILE_MASK, ${enable_logfile_mask}, Mask for log files)
 668
 669 MPATH_NUM=1
 670
 671 case "${enable_multipath}" in
 672   0)
 673     MPATH_NUM=64
 674     ;;
 675   [[1-9]|[1-9][0-9]|[1-9][0-9][0-9]])
 676     MPATH_NUM="${enable_multipath}"
 677     ;;
 678   "")
 679     ;;
 680   *)
 681     AC_MSG_FAILURE([Please specify digit to enable multipath ARG])
 682     ;;
 683 esac
 684
 685 AC_DEFINE_UNQUOTED(MULTIPATH_NUM, $MPATH_NUM, Maximum number of paths for a route)
 686
 687 AC_DEFINE_UNQUOTED(VTYSH_PAGER, "$VTYSH_PAGER", [What pager to use])
 688
 689 dnl ------------------------------------
 690 dnl Alpine only accepts numeric versions
 691 dnl ------------------------------------
 692 if test "x${enable_numeric_version}" != "x" ; then
 693   VERSION="`echo ${VERSION} | tr -c -d '[[.0-9]]'`"
 694   PACKAGE_VERSION="`echo ${PACKAGE_VERSION} | tr -c -d '[[.0-9]]'`"
 695 fi
 696
 697 dnl -----------------------------------
 698 dnl Add extra version string to package
 699 dnl name, string and version fields.
 700 dnl -----------------------------------
 701 if test "x${EXTRAVERSION}" != "x" ; then
 702   VERSION="${VERSION}${EXTRAVERSION}"
 703   PACKAGE_VERSION="${PACKAGE_VERSION}${EXTRAVERSION}"
 704   AC_SUBST(PACKAGE_EXTRAVERSION, ["${EXTRAVERSION}"])
 705   PACKAGE_STRING="${PACKAGE_STRING}${EXTRAVERSION}"
 706 fi
 707
 708 if test "x$with_pkg_git_version" = "xyes"; then
 709         if test -d "${srcdir}/.git"; then
 710                 AC_DEFINE(GIT_VERSION, [1], [include git version info])
 711         else    with_pkg_git_version="no"
 712                 AC_MSG_WARN([--with-pkg-git-version given, but this is not a git checkout])
 713         fi
 714 fi
 715 AM_CONDITIONAL([GIT_VERSION], [test "x$with_pkg_git_version" = "xyes"])
 716
 717 dnl ------------------------------------
 718 dnl Check C keywords and standard  types
 719 dnl ------------------------------------
 720 AC_C_CONST
 721 AC_C_INLINE
 722 AC_C_VOLATILE
 723 AC_HEADER_STDC
 724 dnl AC_TYPE_PID_T
 725 AC_TYPE_UID_T
 726 AC_TYPE_MODE_T
 727 AC_TYPE_SIZE_T
 728 AC_STRUCT_TM
 729
 730 dnl -------------------------
 731 dnl Check other header files.
 732 dnl -------------------------
 733 AC_CHECK_HEADERS([stropts.h sys/ksym.h \
 734         linux/version.h asm/types.h \
 735         sys/cdefs.h])
 736
 737 ac_stdatomic_ok=false
 738 AC_DEFINE(FRR_AUTOCONF_ATOMIC, 1, [did autoconf checks for atomic funcs])
 739 AC_CHECK_HEADER([stdatomic.h],[
 740
 741   AC_MSG_CHECKING([whether _Atomic qualifier works])
 742   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 743 #include <stdatomic.h>
 744 int main(int argc, char **argv) {
 745   _Atomic int i = 0;
 746   return i;
 747 }
 748 ]])], [
 749     AC_DEFINE(HAVE_STDATOMIC_H, 1, [found stdatomic.h])
 750     AC_MSG_RESULT([yes])
 751     ac_stdatomic_ok=true
 752   ], [
 753     AC_MSG_RESULT([no])
 754   ])
 755 ])
 756
 757 AS_IF([$ac_stdatomic_ok], [true], [
 758   AC_MSG_CHECKING([for __atomic_* builtins])
 759   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 760 int main(int argc, char **argv) {
 761   volatile int i = 1;
 762   __atomic_store_n (&i, 0, __ATOMIC_RELEASE);
 763   return __atomic_load_n (&i, __ATOMIC_ACQUIRE);
 764 }
 765 ]])], [
 766     AC_DEFINE(HAVE___ATOMIC, 1, [found __atomic builtins])
 767     AC_MSG_RESULT([yes])
 768   ], [
 769     AC_MSG_RESULT([no])
 770
 771     dnl FreeBSD 9 has a broken stdatomic.h where _Atomic doesn't work
 772     AC_MSG_CHECKING([for __sync_* builtins])
 773     AC_LINK_IFELSE([AC_LANG_SOURCE([[
 774 int main(int argc, char **argv) {
 775   volatile int i = 1;
 776   __sync_fetch_and_sub (&i, 1);
 777   return __sync_val_compare_and_swap (&i, 0, 1);
 778 }
 779 ]])], [
 780       AC_DEFINE(HAVE___SYNC, 1, [found __sync builtins])
 781       AC_MSG_RESULT([yes])
 782
 783       AC_MSG_CHECKING([for __sync_swap builtin])
 784       AC_LINK_IFELSE([AC_LANG_SOURCE([[
 785 int main(int argc, char **argv) {
 786   volatile int i = 1;
 787   return __sync_swap (&i, 2);
 788 }
 789 ]])], [
 790         AC_DEFINE(HAVE___SYNC_SWAP, 1, [found __sync_swap builtin])
 791         AC_MSG_RESULT([yes])
 792       ], [
 793         AC_MSG_RESULT([no])
 794       ])
 795
 796     ], [
 797       AC_MSG_RESULT([no])
 798       AC_MSG_FAILURE([stdatomic.h unavailable and $CC has neither __atomic nor __sync builtins])
 799     ])
 800   ])
 801 ])
 802
 803 dnl Utility macro to avoid retyping includes all the time
 804 m4_define([FRR_INCLUDES],
 805 [#ifdef SUNOS_5
 806 #define _XPG4_2
 807 #define __EXTENSIONS__
 808 #endif
 809 #include <stdio.h>
 810 #include <stdlib.h>
 811 #include <stddef.h>
 812 #include <sys/types.h>
 813 /* sys/conf.h depends on param.h on FBSD at least */
 814 #include <sys/param.h>
 815 /* Required for MAXSIG */
 816 #include <signal.h>
 817 #include <sys/socket.h>
 818 #ifdef __APPLE__
 819 # define __APPLE_USE_RFC_3542
 820 #endif
 821 #include <netinet/in.h>
 822 #include <sys/time.h>
 823 #include <time.h>
 824 #include <net/if.h>
 825 ])dnl
 826
 827 dnl Same applies for HAVE_NET_IF_VAR_H, which HAVE_NETINET6_ND6_H and
 828 dnl HAVE_NETINET_IN_VAR_H depend upon. But if_var.h depends on if.h, hence
 829 dnl an additional round for it.
 830
 831 AC_CHECK_HEADERS([net/if_var.h], [], [], FRR_INCLUDES)
 832
 833 m4_define([FRR_INCLUDES],
 834 FRR_INCLUDES
 835 [#if HAVE_NET_IF_VAR_H
 836 # include <net/if_var.h>
 837 #endif
 838 ])dnl
 839
 840 AC_CHECK_HEADERS([netinet/in_var.h \
 841         net/if_dl.h net/netopt.h \
 842         inet/nd.h netinet/ip_icmp.h \
 843         sys/sysctl.h sys/sockio.h kvm.h sys/conf.h],
 844         [], [], FRR_INCLUDES)
 845
 846 AC_CHECK_HEADERS([ucontext.h], [], [],
 847 [#ifndef __USE_GNU
 848 #define __USE_GNU
 849 #endif /* __USE_GNU */
 850 FRR_INCLUDES
 851 ])
 852
 853 m4_define([UCONTEXT_INCLUDES],
 854 [#include <ucontext.h>])dnl
 855
 856 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.uc_regs],
 857   [], [], [UCONTEXT_INCLUDES])
 858 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs],
 859   [AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs.nip],
 860    [], [], [UCONTEXT_INCLUDES])],
 861   [], [UCONTEXT_INCLUDES])
 862 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.gregs],
 863   [], [], [UCONTEXT_INCLUDES])
 864
 865 m4_define([FRR_INCLUDES],
 866 FRR_INCLUDES
 867 [
 868 #include <sys/un.h>
 869 #include <netinet/in_systm.h>
 870 #if HAVE_NETINET_IN_VAR_H
 871 # include <netinet/in_var.h>
 872 #endif
 873 #if HAVE_NET_IF_DL_H
 874 # include <net/if_dl.h>
 875 #endif
 876 #if HAVE_NET_NETOPT_H
 877 # include <net/netopt.h>
 878 #endif
 879 #include <net/route.h>
 880 #if HAVE_INET_ND_H
 881 # include <inet/nd.h>
 882 #endif
 883 #include <arpa/inet.h>
 884 /* Required for IDRP */
 885 #if HAVE_NETINET_IP_ICMP_H
 886 # include <netinet/ip_icmp.h>
 887 #endif
 888 ])dnl
 889
 890 dnl V6 headers are checked below, after we check for v6
 891
 892 AC_MSG_CHECKING([which operating system interface to use])
 893 case "$host_os" in
 894   sunos* | solaris2*)
 895     AC_MSG_RESULT([Solaris])
 896
 897     AC_DEFINE(SUNOS_5, 1, [SunOS 5])
 898     AC_DEFINE(SOLARIS_IPV6, 1, Solaris IPv6)
 899
 900     AC_CHECK_LIB(socket, main)
 901     AC_CHECK_LIB(nsl, main)
 902     AC_CHECK_LIB(umem, main)
 903     AC_CHECK_FUNCS([printstack], [
 904       AC_DEFINE([HAVE_PRINTSTACK],1,[Solaris printstack])
 905       AC_DEFINE([HAVE_STACK_TRACE],1,[Stack symbols decode functionality])
 906     ])
 907     CURSES=-lcurses
 908     SOLARIS="solaris"
 909     ;;
 910   linux*)
 911     AC_MSG_RESULT([Linux])
 912
 913     AC_DEFINE(GNU_LINUX,,GNU Linux)
 914     AC_DEFINE(HAVE_NETLINK,,netlink)
 915     AC_DEFINE(LINUX_IPV6,1,Linux IPv6 stack)
 916
 917     dnl Linux has a compilation problem with mixing
 918     dnl netinet/in.h and linux/in6.h they are not
 919     dnl compatible.  There has been discussion on
 920     dnl how to fix it but no real progress on implementation
 921     dnl when they fix it, remove this
 922     AC_DEFINE(IPV6_MINHOPCOUNT, 73, Linux ipv6 Min Hop Count)
 923     ;;
 924   openbsd*)
 925     AC_MSG_RESULT([OpenBSD])
 926
 927     AC_DEFINE(OPEN_BSD,,OpenBSD)
 928     AC_DEFINE(KAME,1,KAME IPv6)
 929     AC_DEFINE(BSD_V6_SYSCTL,1,BSD v6 sysctl to turn on and off forwarding)
 930
 931     if test "x${enable_pimd}" != "xno"; then
 932       case "$host_os" in
 933       openbsd6.0)
 934         ;;
 935       openbsd[6-9]*)
 936         AC_MSG_FAILURE([pimd cannot be enabled as PIM support has been removed from OpenBSD 6.1])
 937         ;;
 938       esac
 939     fi
 940     ;;
 941   *)
 942     AC_MSG_RESULT([BSD])
 943
 944     AC_DEFINE(HAVE_NET_RT_IFLIST,,NET_RT_IFLIST)
 945     AC_DEFINE(KAME,1,KAME IPv6)
 946     AC_DEFINE(BSD_V6_SYSCTL,1,BSD v6 sysctl to turn on and off forwarding)
 947     ;;
 948 esac
 949 AM_CONDITIONAL(SOLARIS, test "${SOLARIS}" = "solaris")
 950
 951 AC_SYS_LARGEFILE
 952
 953 dnl ------------------------
 954 dnl Integrated REALMS option
 955 dnl ------------------------
 956 if test "${enable_realms}" = "yes"; then
 957     case "$host_os" in
 958       linux*)
 959        AC_DEFINE(SUPPORT_REALMS,, Realms support)
 960        ;;
 961       *)
 962        echo "Sorry, only Linux has REALMS support"
 963        exit 1
 964        ;;
 965     esac
 966 fi
 967 AM_CONDITIONAL([SUPPORT_REALMS], [test "${enable_realms}" = "yes"])
 968
 969 dnl ---------------------
 970 dnl Integrated VTY option
 971 dnl ---------------------
 972 case "${enable_vtysh}" in
 973   "no") VTYSH="";;
 974   *)    VTYSH="vtysh";
 975          AC_DEFINE(VTYSH,,VTY shell)
 976 dnl      Vtysh uses libreadline, which looks for termcap functions at
 977 dnl      configure time.  We follow readlines search order.
 978 dnl      The required procedures are in libtermcap on NetBSD, in
 979 dnl      [TODO] on Linux, and in [TODO] on Solaris.
 980          AC_CHECK_LIB(termcap, tputs, LIBREADLINE="$LIBREADLINE -ltermcap",
 981            [AC_CHECK_LIB(tinfo, tputs, LIBREADLINE="$LIBREADLINE -ltinfo",
 982              [AC_CHECK_LIB(curses, tputs, LIBREADLINE="$LIBREADLINE -lcurses",
 983                [AC_CHECK_LIB(ncurses, tputs,
 984                              LIBREADLINE="$LIBREADLINE -lncurses")]
 985               )]
 986             )]
 987           )
 988          AC_CHECK_LIB(readline, main, LIBREADLINE="-lreadline $LIBREADLINE",,
 989                       "$LIBREADLINE")
 990          if test $ac_cv_lib_readline_main = no; then
 991            AC_MSG_ERROR([vtysh needs libreadline but was not found and usable on your system.])
 992          fi
 993          AC_CHECK_HEADER(readline/history.h)
 994          if test $ac_cv_header_readline_history_h = no;then
 995            AC_MSG_ERROR([readline is too old to have readline/history.h, please update to the latest readline library.])
 996          fi
 997          AC_CHECK_LIB(readline, rl_completion_matches,
 998                       LIBREADLINE="$LIBREADLINE",, "$LIBREADLINE")
 999          if test $ac_cv_lib_readline_rl_completion_matches = no; then
1000            AC_DEFINE(rl_completion_matches,completion_matches,Old readline)
1001          fi
1002          ;;
1003 esac
1004 AC_SUBST(LIBREADLINE)
1005 AM_CONDITIONAL(VTYSH, test "x$VTYSH" = "xvtysh")
1006
1007 dnl ----------
1008 dnl PAM module
1009 dnl
1010 dnl FRR detects the PAM library it is built against by checking for a
1011 dnl functional pam_misc.h (Linux-PAM) or openpam.h (OpenPAM) header. pam_misc.h
1012 dnl is known to #include pam_appl.h, the standard header of a PAM library, and
1013 dnl openpam.h doesn't do that, although depends on the header too. Hence a
1014 dnl little assistance to AC_CHECK_HEADER is necessary for the proper detection
1015 dnl of OpenPAM.
1016 dnl ----------
1017 if test "$with_libpam" = "yes"; then
1018   AC_CHECK_HEADER([security/pam_misc.h],
1019     [AC_DEFINE(HAVE_PAM_MISC_H,,Have pam_misc.h)
1020      AC_DEFINE(PAM_CONV_FUNC,misc_conv,Have misc_conv)
1021      pam_conv_func="misc_conv"
1022     ],
1023     [], FRR_INCLUDES)
1024   AC_CHECK_HEADER([security/openpam.h],
1025     [AC_DEFINE(HAVE_OPENPAM_H,,Have openpam.h)
1026      AC_DEFINE(PAM_CONV_FUNC,openpam_ttyconv,Have openpam_ttyconv)
1027      pam_conv_func="openpam_ttyconv"
1028     ],
1029     [], FRR_INCLUDES[#include <security/pam_appl.h>])
1030   if test -z "$ac_cv_header_security_pam_misc_h$ac_cv_header_security_openpam_h" ; then
1031     AC_MSG_WARN([*** pam support will not be built ***])
1032     with_libpam="no"
1033   fi
1034 fi
1035
1036 if test "$with_libpam" = "yes"; then
1037 dnl took this test from proftpds configure.in and suited to our needs
1038 dnl -------------------------------------------------------------------------
1039 dnl
1040 dnl This next check looks funky due to a linker problem with some versions
1041 dnl of the PAM library.  Prior to 0.72 release, the Linux PAM shared library
1042 dnl omitted requiring libdl linking information. PAM-0.72 or better ships
1043 dnl with RedHat 6.2 and Debian 2.2 or better.
1044 AC_CHECK_LIB(pam, pam_start,
1045   [AC_CHECK_LIB(pam, $pam_conv_func,
1046     [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1047      LIBPAM="-lpam"],
1048     [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1049      LIBPAM="-lpam -lpam_misc"]
1050     )
1051   ],
1052
1053   [AC_CHECK_LIB(pam, pam_end,
1054     [AC_CHECK_LIB(pam, $pam_conv_func,
1055       [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1056        LIBPAM="-lpam -ldl"],
1057       [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1058        LIBPAM="-lpam -ldl -lpam_misc"]
1059      )
1060   ],AC_MSG_WARN([*** pam support will not be built ***]),
1061   [-ldl])
1062   ]
1063 )
1064 fi
1065 AC_SUBST(LIBPAM)
1066
1067 dnl -------------------------------
1068 dnl Endian-ness check
1069 dnl -------------------------------
1070 AC_WORDS_BIGENDIAN
1071
1072 dnl -------------------------------
1073 dnl check the size in byte of the C
1074 dnl -------------------------------
1075 dnl AC_CHECK_SIZEOF(char)
1076 dnl AC_CHECK_SIZEOF(int)
1077 dnl AC_CHECK_SIZEOF(short)
1078 dnl AC_CHECK_SIZEOF(long)
1079
1080 dnl ----------------------------
1081 dnl check existance of functions
1082 dnl ----------------------------
1083 AC_FUNC_FNMATCH
1084 AC_FUNC_FORK
1085 AC_FUNC_MKTIME
1086 AC_FUNC_STAT
1087
1088 dnl -------------------------------
1089 dnl bgpd needs pow() and hence libm
1090 dnl -------------------------------
1091 TMPLIBS="$LIBS"
1092 AC_CHECK_HEADER([math.h],
1093   [AC_CHECK_LIB([m], [pow],
1094     [LIBM="-lm"
1095      LIBS="$LIBS $LIBM"
1096      AC_CHECK_FUNCS(pow,[],[LIBM=""])
1097     ])
1098 ])
1099 if test x"$LIBM" = x ; then
1100   AC_MSG_WARN([Unable to find working pow function - bgpd may not link])
1101 fi
1102 LIBS="$TMPLIBS"
1103 AC_SUBST(LIBM)
1104
1105 AC_CHECK_FUNCS([ppoll], [
1106   AC_DEFINE([HAVE_PPOLL], 1, [have Linux/BSD ppoll()])
1107 ])
1108 AC_CHECK_FUNCS([pollts], [
1109   AC_DEFINE([HAVE_POLLTS], 1, [have NetBSD pollts()])
1110 ])
1111
1112 dnl ---------------
1113 dnl other functions
1114 dnl ---------------
1115 AC_CHECK_FUNCS([ \
1116         strlcat strlcpy \
1117         getgrouplist])
1118
1119 AC_CHECK_HEADER([asm-generic/unistd.h],
1120                 [AC_CHECK_DECL(__NR_setns,
1121                                AC_DEFINE(HAVE_NETNS,, Have netns),,
1122                                FRR_INCLUDES [#include <asm-generic/unistd.h>
1123                                ])
1124                  AC_CHECK_FUNCS(setns)]
1125                )
1126
1127 dnl --------------------------
1128 dnl Determine IS-IS I/O method
1129 dnl --------------------------
1130 AC_DEFINE(ISIS_METHOD_PFPACKET, 1, [ constant value for isis method pfpacket ])
1131 AC_DEFINE(ISIS_METHOD_DLPI,     2, [ constant value for isis method dlpi ])
1132 AC_DEFINE(ISIS_METHOD_BPF,      3, [ constant value for isis method bpf ])
1133 AC_CHECK_HEADER(net/bpf.h)
1134 AC_CHECK_HEADER(sys/dlpi.h)
1135 AC_MSG_CHECKING(zebra IS-IS I/O method)
1136
1137 case "$host_os" in
1138   linux*)
1139     AC_MSG_RESULT(pfpacket)
1140     ISIS_METHOD_MACRO="ISIS_METHOD_PFPACKET"
1141     ;;
1142   solaris* | sunos*)
1143     AC_MSG_RESULT(DLPI)
1144     ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1145     ;;
1146   *)
1147     if test $ac_cv_header_net_bpf_h = no; then
1148       if test $ac_cv_header_sys_dlpi_h = no; then
1149         AC_MSG_RESULT(none)
1150         if test "${enable_isisd}" = yes; then
1151           AC_MSG_FAILURE([IS-IS support requested but no packet backend found])
1152         fi
1153         AC_MSG_WARN([*** IS-IS support will not be built ***])
1154         enable_isisd="no"
1155       else
1156         AC_MSG_RESULT(DLPI)
1157       fi
1158       ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1159     else
1160       AC_MSG_RESULT(BPF)
1161       ISIS_METHOD_MACRO="ISIS_METHOD_BPF"
1162     fi
1163     ;;
1164 esac
1165 AC_DEFINE_UNQUOTED(ISIS_METHOD, $ISIS_METHOD_MACRO, [ selected method for isis, == one of the constants ])
1166
1167 dnl ------------------------------------
1168 dnl check for broken CMSG_FIRSTHDR macro
1169 dnl ------------------------------------
1170 AC_MSG_CHECKING(for broken CMSG_FIRSTHDR)
1171 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1172 #ifdef SUNOS_5
1173 #define _XPG4_2
1174 #define __EXTENSIONS__
1175 #endif
1176 #include <stdlib.h>
1177 #include <sys/types.h>
1178 #include <sys/socket.h>
1179
1180 main()
1181 {
1182   struct msghdr msg;
1183   char buf[4];
1184
1185   msg.msg_control = buf;
1186   msg.msg_controllen = 0;
1187
1188   if (CMSG_FIRSTHDR(&msg) != NULL)
1189     exit(0);
1190   exit (1);
1191 }]])],[AC_MSG_RESULT(yes - using workaround) AC_DEFINE(HAVE_BROKEN_CMSG_FIRSTHDR,,Broken CMSG_FIRSTHDR)],
1192 [AC_MSG_RESULT(no)],[AC_MSG_RESULT(no)])
1193
1194 dnl ---------------------------------------------------------------
1195 dnl figure out how to specify an interface in multicast sockets API
1196 dnl ---------------------------------------------------------------
1197 AC_CHECK_MEMBERS([struct ip_mreqn.imr_ifindex], [], [], FRR_INCLUDES)
1198
1199 AC_CHECK_HEADERS([linux/mroute.h], [], [],[
1200         #include <sys/socket.h>
1201         #include <netinet/in.h>
1202         #define _LINUX_IN_H             /* For Linux <= 2.6.25 */
1203         #include <linux/types.h>
1204 ])
1205
1206 m4_define([FRR_INCLUDES],
1207 FRR_INCLUDES
1208 [#if HAVE_LINUX_MROUTE_H
1209 # include <linux/mroute.h>
1210 #endif
1211 ])dnl
1212
1213 AC_CHECK_HEADERS([netinet/ip_mroute.h], [], [],[
1214         #include <sys/socket.h>
1215         #include <sys/types.h>
1216         #include <netinet/in.h>
1217         #include <net/route.h>
1218 ])
1219
1220 m4_define([FRR_INCLUDES],
1221 FRR_INCLUDES
1222 [#if HAVE_NETINET_IP_MROUTE_H
1223 # include <netinet/ip_mroute.h>
1224 #endif
1225 ])dnl
1226
1227 AC_MSG_CHECKING([for BSD struct ip_mreq hack])
1228 AC_TRY_COMPILE([#include <sys/param.h>],
1229 [#if (defined(__FreeBSD__) && ((__FreeBSD_version >= 500022 && __FreeBSD_version < 700000) || (__FreeBSD_version < 500000 && __FreeBSD_version >= 440000))) || (defined(__NetBSD__) && defined(__NetBSD_Version__) && __NetBSD_Version__ >= 106010000) || defined(__OpenBSD__) || defined(__APPLE__) || defined(__DragonFly__) || defined(__sun)
1230   return (0);
1231 #else
1232   #error No support for BSD struct ip_mreq hack detected
1233 #endif],[AC_MSG_RESULT(yes)
1234 AC_DEFINE(HAVE_BSD_STRUCT_IP_MREQ_HACK,,[Can pass ifindex in struct ip_mreq])],
1235 AC_MSG_RESULT(no))
1236
1237 AC_MSG_CHECKING([for RFC3678 protocol-independed API])
1238 AC_TRY_COMPILE([
1239 #include <sys/types.h>
1240 #include <netinet/in.h>
1241 ], [struct group_req gr; int sock; setsockopt(sock, IPPROTO_IP, MCAST_JOIN_GROUP, (void*)&gr, sizeof(gr));
1242 ], [AC_MSG_RESULT(yes)
1243 AC_DEFINE(HAVE_RFC3678,1,[Have RFC3678 protocol-independed API])],
1244 AC_MSG_RESULT(no))
1245
1246 dnl ---------------------------------------------------------------
1247 dnl figure out how to check link-state
1248 dnl ---------------------------------------------------------------
1249 AC_CHECK_HEADER( [net/if_media.h],
1250   [m4_define([LINK_DETECT_INCLUDES],
1251     FRR_INCLUDES
1252     [#include <net/if_media.h>
1253   ])
1254   AC_CHECK_MEMBERS( [struct ifmediareq.ifm_status],
1255     AC_DEFINE(HAVE_BSD_LINK_DETECT,,[BSD link-detect]),
1256     [], LINK_DETECT_INCLUDES)],
1257   [],
1258   FRR_INCLUDES)
1259
1260 dnl ---------------------------------------------------------------
1261 dnl Additional, newer way to check link-state using ifi_link_state.
1262 dnl Not available in all BSD's when ifmediareq available
1263 dnl ---------------------------------------------------------------
1264 AC_CHECK_MEMBERS([struct if_data.ifi_link_state],
1265   AC_DEFINE(HAVE_BSD_IFI_LINK_STATE,,[BSD ifi_link_state available]),
1266   [], FRR_INCLUDES)
1267
1268 dnl ------------------------
1269 dnl TCP_MD5SIG socket option
1270 dnl ------------------------
1271
1272 AC_CHECK_HEADER([netinet/tcp.h],
1273    [m4_define([MD5_INCLUDES],
1274       FRR_INCLUDES
1275       [#include <netinet/tcp.h>
1276     ])
1277     AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)],
1278    [],
1279    FRR_INCLUDES)
1280 if test $ac_cv_have_decl_TCP_MD5SIG = no; then
1281   AC_CHECK_HEADER([linux/tcp.h],
1282        [m4_define([MD5_INCLUDES],
1283           FRR_INCLUDES
1284           [#include <linux/tcp.h>
1285         ])
1286        AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)])
1287 fi
1288
1289 dnl ----------------------------------------------------------------------------
1290 dnl figure out if domainname is available in the utsname struct (GNU extension).
1291 dnl ----------------------------------------------------------------------------
1292 AC_CHECK_MEMBERS([struct utsname.domainname], [], [], [#include <sys/utsname.h>])
1293
1294 dnl ------------------
1295 dnl IPv6 header checks
1296 dnl ------------------
1297 AC_CHECK_HEADERS([netinet6/in6.h netinet/in6_var.h \
1298         netinet6/in6_var.h netinet6/nd6.h], [], [],
1299         FRR_INCLUDES)
1300
1301 m4_define([FRR_INCLUDES],dnl
1302 FRR_INCLUDES
1303 [#if HAVE_NETINET6_IN6_H
1304 #include <netinet6/in6.h>
1305 #endif
1306 #if HAVE_NETINET_IN6_VAR_H
1307 #include <netinet/in6_var.h>
1308 #endif
1309 #include <netinet/icmp6.h>
1310 #if HAVE_NETINET6_IN6_VAR_H
1311 # include <netinet6/in6_var.h>
1312 #endif
1313 #if HAVE_NETINET6_ND6_H
1314 # include <netinet6/nd6.h>
1315 #endif
1316 ])dnl
1317
1318 dnl disable doc check
1319 if test "${enable_doc}" = "no";then
1320   DOC=""
1321 else
1322   DOC="doc"
1323 fi
1324
1325 dnl --------------------
1326 dnl Daemon disable check
1327 dnl --------------------
1328 AM_CONDITIONAL(ZEBRA, test "${enable_zebra}" != "no")
1329
1330 if test "${enable_bgpd}" = "no";then
1331   BGPD=""
1332 else
1333   BGPD="bgpd"
1334 fi
1335 AM_CONDITIONAL(BGPD, test "x$BGPD" = "xbgpd")
1336
1337 AM_CONDITIONAL(RIPD, test "${enable_ripd}" != "no")
1338 AM_CONDITIONAL(OSPFD, test "${enable_ospfd}" != "no")
1339 AM_CONDITIONAL(LDPD, test "${enable_ldpd}" != "no")
1340
1341 AS_IF([test "${enable_ldpd}" != "no"], [
1342   AC_DEFINE(HAVE_LDPD, 1, ldpd)
1343 ])
1344
1345 NHRPD=""
1346 case "$host_os" in
1347   linux*)
1348     if test "${enable_nhrpd}" != "no"; then
1349       NHRPD="nhrpd"
1350     fi
1351     ;;
1352   *)
1353     if test "${enable_nhrpd}" = "yes"; then
1354       AC_MSG_ERROR([nhrpd requires kernel APIs that are only present on Linux.])
1355     fi
1356     ;;
1357 esac
1358 AM_CONDITIONAL(NHRPD, test "x$NHRPD" = "xnhrpd")
1359
1360 AM_CONDITIONAL(EIGRPD, test "${enable_eigrpd}" != "no")
1361
1362 if test "${enable_watchfrr}" = "no";then
1363   WATCHFRR=""
1364 else
1365   WATCHFRR="watchfrr"
1366 fi
1367 AM_CONDITIONAL(WATCHFRR, test "x$WATCHFRR" = "xwatchfrr")
1368
1369 OSPFCLIENT=""
1370 if test "${enable_ospfapi}" != "no";then
1371     AC_DEFINE(SUPPORT_OSPF_API,,OSPFAPI)
1372
1373   if test "${enable_ospfclient}" != "no";then
1374       OSPFCLIENT="ospfclient"
1375   fi
1376 fi
1377
1378 AM_CONDITIONAL(OSPFCLIENT, test "x$OSPFCLIENT" = "xospfclient")
1379 AM_CONDITIONAL(RIPNGD, test "${enable_ripngd}" != "no")
1380 AM_CONDITIONAL(BABELD, test "${enable_babeld}" != "no")
1381 AM_CONDITIONAL(OSPF6D, test "${enable_ospf6d}" != "no")
1382 AM_CONDITIONAL(ISISD, test "${enable_isisd}" != "no")
1383 AM_CONDITIONAL(PIMD, test "${enable_pimd}" != "no")
1384 AM_CONDITIONAL(PBRD, test "${enable_pbrd}" != "no")
1385 AM_CONDITIONAL(SHARPD, test "${enable_sharpd}" = "yes")
1386
1387 if test "${enable_bgp_announce}" = "no";then
1388   AC_DEFINE(DISABLE_BGP_ANNOUNCE,1,Disable BGP installation to zebra)
1389 else
1390   AC_DEFINE(DISABLE_BGP_ANNOUNCE,0,Disable BGP installation to zebra)
1391 fi
1392
1393 if test "${with_rfp_path}" = "yes" || test x"${with_rfp_path}" = x""; then
1394   with_rfp_path="bgpd/rfp-example"
1395 fi
1396 if test "${with_rfp_path}" != "no"; then
1397   VNC_RFP_PATH="${with_rfp_path}"
1398   AC_SUBST(VNC_RFP_PATH)
1399 fi
1400
1401 if test "${enable_bgp_vnc}" != "no";then
1402   AC_DEFINE(ENABLE_BGP_VNC,1,Enable BGP VNC support)
1403   RFPTEST="${with_rfp_path}/rfptest"
1404   LIBRFP="${with_rfp_path}/librfp"
1405   RFPINC="${with_rfp_path}/librfp"
1406 else
1407   RFPTEST=
1408   LIBRFP=
1409   RFPINC="bgpd/rfp-example/librfp"
1410 fi
1411 # set
1412 AM_CONDITIONAL([ENABLE_BGP_VNC], [test x${enable_bgp_vnc} != xno])
1413
1414 AC_SUBST(DOC)
1415 AC_SUBST(RFPTEST)
1416 AC_SUBST(LIBRFP)
1417 AC_SUBST(RFPINC)
1418 AC_SUBST(BGPD)
1419 AC_SUBST(SOLARIS)
1420 AC_SUBST(VTYSH)
1421 AC_SUBST(CURSES)
1422 AC_CHECK_LIB(crypt, crypt, [],
1423                     [AC_CHECK_LIB(crypto, DES_crypt)])
1424 AC_CHECK_LIB(resolv, res_init)
1425
1426 dnl ---------------------------
1427 dnl check system has PCRE regexp
1428 dnl ---------------------------
1429 if test "x$enable_pcreposix" = "xyes"; then
1430   AC_CHECK_LIB(pcreposix, regexec, [], [
1431     AC_MSG_ERROR([--enable-pcreposix given but unable to find libpcreposix])
1432   ])
1433 fi
1434 AC_SUBST(HAVE_LIBPCREPOSIX)
1435
1436 dnl ------------------
1437 dnl check C-Ares library
1438 dnl ------------------
1439 if test "${NHRPD}" != ""; then
1440   PKG_CHECK_MODULES([CARES], [libcares], , [
1441     AC_MSG_ERROR([trying to build nhrpd, but libcares not found. install c-ares and its -dev headers.])
1442   ])
1443 fi
1444
1445
1446 dnl ------------------
1447 dnl check Net-SNMP library
1448 dnl ------------------
1449 if test "${enable_snmp}" != "" -a "${enable_snmp}" != "no"; then
1450    AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], [no])
1451    if test x"$NETSNMP_CONFIG" = x"no"; then
1452       AC_MSG_ERROR([--enable-snmp given but unable to find net-snmp-config])
1453    fi
1454    SNMP_LIBS="`${NETSNMP_CONFIG} --agent-libs`"
1455    SNMP_CFLAGS="`${NETSNMP_CONFIG} --base-cflags`"
1456    AC_MSG_CHECKING([whether we can link to Net-SNMP])
1457    AC_LINK_IFELSE_FLAGS([$SNMP_CFLAGS], [$SNMP_LIBS], [AC_LANG_PROGRAM([
1458 int main(void);
1459 ],
1460 [
1461 {
1462   return 0;
1463 }
1464 ])], [
1465      AC_MSG_ERROR([--enable-snmp given but not usable])])
1466    case "${enable_snmp}" in
1467      yes)
1468       SNMP_METHOD=agentx
1469       ;;
1470      smux|agentx)
1471       SNMP_METHOD="${enable_snmp}"
1472       ;;
1473      *)
1474       AC_MSG_ERROR([--enable-snmp given with an unknown method (${enable_snmp}). Use smux or agentx])
1475       ;;
1476    esac
1477    AH_TEMPLATE([SNMP_SMUX], [Use SNMP SMUX to interface with snmpd])
1478    AH_TEMPLATE([SNMP_AGENTX], [Use SNMP AgentX to interface with snmpd])
1479    AC_DEFINE_UNQUOTED(AS_TR_CPP(SNMP_${SNMP_METHOD}),,SNMP method to interface with snmpd)
1480 fi
1481 AM_CONDITIONAL([SNMP], [test "x${SNMP_METHOD}" != "x"])
1482 AC_SUBST(SNMP_LIBS)
1483 AC_SUBST(SNMP_CFLAGS)
1484
1485 dnl ---------------
1486 dnl math
1487 dnl ---------------
1488 AC_SEARCH_LIBS([sqrt], [m])
1489
1490 dnl ---------------
1491 dnl dlopen & dlinfo
1492 dnl ---------------
1493 AC_SEARCH_LIBS(dlopen, [dl dld], [], [
1494   AC_MSG_ERROR([unable to find the dlopen()])
1495 ])
1496
1497 AC_CHECK_HEADERS([link.h])
1498
1499 AC_MSG_CHECKING([for dlinfo(RTLD_DI_ORIGIN)])
1500 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1501 #include <stdlib.h>
1502 #ifdef HAVE_LINK_H
1503 #include <link.h>
1504 #endif
1505 #include <dlfcn.h>
1506 ]], [[
1507   char origin[1];
1508   dlinfo (NULL, RTLD_DI_ORIGIN, &origin);
1509 ]])], [
1510   AC_MSG_RESULT(yes)
1511   AC_DEFINE(HAVE_DLINFO_ORIGIN, 1, [Have dlinfo RTLD_DI_ORIGIN])
1512 ], [
1513   AC_MSG_RESULT(no)
1514 ])
1515
1516 AC_MSG_CHECKING([for dlinfo(RTLD_DI_LINKMAP)])
1517 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1518 #include <stdlib.h>
1519 #ifdef HAVE_LINK_H
1520 #include <link.h>
1521 #endif
1522 #include <dlfcn.h>
1523 ]], [[
1524   struct link_map *lm = NULL;
1525   dlinfo (NULL, RTLD_DI_LINKMAP, &lm);
1526 ]])], [
1527   AC_MSG_RESULT(yes)
1528   AC_DEFINE(HAVE_DLINFO_LINKMAP, 1, [Have dlinfo RTLD_DI_LINKMAP])
1529 ], [
1530   AC_MSG_RESULT(no)
1531 ])
1532
1533
1534 AM_CONDITIONAL(SNMP, test "x$SNMP_METHOD" = "xagentx")
1535
1536 dnl ---------------------------
1537 dnl sockaddr and netinet checks
1538 dnl ---------------------------
1539 AC_CHECK_TYPES([
1540         struct sockaddr_dl,
1541         struct vifctl, struct mfcctl, struct sioc_sg_req,
1542         vifi_t, struct sioc_vif_req, struct igmpmsg,
1543         struct ifaliasreq, struct if6_aliasreq, struct in6_aliasreq,
1544         struct nd_opt_adv_interval, struct rt_addrinfo,
1545         struct nd_opt_homeagent_info, struct nd_opt_adv_interval],
1546         [], [], FRR_INCLUDES)
1547
1548 AC_CHECK_MEMBERS([struct sockaddr.sa_len,
1549         struct sockaddr_in.sin_len, struct sockaddr_un.sun_len,
1550         struct sockaddr_dl.sdl_len,
1551         struct if6_aliasreq.ifra_lifetime,
1552         struct nd_opt_adv_interval.nd_opt_ai_type],
1553         [], [], FRR_INCLUDES)
1554
1555 dnl ---------------------------
1556 dnl IRDP/pktinfo/icmphdr checks
1557 dnl ---------------------------
1558
1559 AC_CHECK_TYPES([struct in_pktinfo], [
1560   AC_CHECK_TYPES([struct icmphdr], [
1561     IRDP=true
1562   ], [
1563     IRDP=false
1564   ], [FRR_INCLUDES])
1565 ], [
1566   IRDP=false
1567 ], [FRR_INCLUDES])
1568
1569 case "${enable_irdp}" in
1570 yes)
1571   $IRDP || AC_MSG_ERROR(['IRDP requires in_pktinfo at the moment!'])
1572   ;;
1573 no)
1574   IRDP=false
1575   ;;
1576 esac
1577
1578 AM_CONDITIONAL(IRDP, $IRDP)
1579
1580 dnl -----------------------
1581 dnl checking for IP_PKTINFO
1582 dnl -----------------------
1583 AC_MSG_CHECKING(for IP_PKTINFO)
1584 AC_TRY_COMPILE([#include <netdb.h>], [
1585   int opt = IP_PKTINFO;
1586 ], [
1587   AC_MSG_RESULT(yes)
1588   AC_DEFINE(HAVE_IP_PKTINFO, 1, [Have IP_PKTINFO])
1589 ], [
1590   AC_MSG_RESULT(no)
1591 ])
1592
1593 dnl ---------------------------
1594 dnl checking for IP_RECVDSTADDR
1595 dnl ---------------------------
1596 AC_MSG_CHECKING(for IP_RECVDSTADDR)
1597 AC_TRY_COMPILE([#include <netinet/in.h>], [
1598   int opt = IP_RECVDSTADDR;
1599 ], [
1600   AC_MSG_RESULT(yes)
1601   AC_DEFINE(HAVE_IP_RECVDSTADDR, 1, [Have IP_RECVDSTADDR])
1602 ], [
1603   AC_MSG_RESULT(no)
1604 ])
1605
1606 dnl ----------------------
1607 dnl checking for IP_RECVIF
1608 dnl ----------------------
1609 AC_MSG_CHECKING(for IP_RECVIF)
1610 AC_TRY_COMPILE([#include <netinet/in.h>], [
1611   int opt = IP_RECVIF;
1612 ], [
1613   AC_MSG_RESULT(yes)
1614   AC_DEFINE(HAVE_IP_RECVIF, 1, [Have IP_RECVIF])
1615 ], [
1616   AC_MSG_RESULT(no)
1617 ])
1618
1619 dnl ----------------------
1620 dnl checking for SO_BINDANY
1621 dnl ----------------------
1622 AC_MSG_CHECKING(for SO_BINDANY)
1623 AC_TRY_COMPILE([#include <sys/socket.h>], [
1624   int opt = SO_BINDANY;
1625 ], [
1626   AC_MSG_RESULT(yes)
1627   AC_DEFINE(HAVE_SO_BINDANY, 1, [Have SO_BINDANY])
1628 ], [
1629   AC_MSG_RESULT(no)
1630 ])
1631
1632 dnl ----------------------
1633 dnl checking for IP_FREEBIND
1634 dnl ----------------------
1635 AC_MSG_CHECKING(for IP_FREEBIND)
1636 AC_TRY_COMPILE([#include <netinet/in.h>], [
1637   int opt = IP_FREEBIND;
1638 ], [
1639   AC_MSG_RESULT(yes)
1640   AC_DEFINE(HAVE_IP_FREEBIND, 1, [Have IP_FREEBIND])
1641 ], [
1642   AC_MSG_RESULT(no)
1643 ])
1644
1645 dnl --------------------------------------
1646 dnl checking for be32dec existence or not
1647 dnl --------------------------------------
1648 AC_CHECK_DECLS([be32enc, be32dec], [], [],
1649                [#include <sys/endian.h>])
1650
1651 dnl --------------------------------------
1652 dnl checking for clock_time monotonic struct and call
1653 dnl --------------------------------------
1654 AC_CHECK_DECL(CLOCK_MONOTONIC,
1655         [AC_CHECK_LIB(rt, clock_gettime, [LIBS="$LIBS -lrt"])
1656          AC_DEFINE(HAVE_CLOCK_MONOTONIC,, Have monotonic clock)
1657 ], [AC_MSG_RESULT(no)], [FRR_INCLUDES])
1658
1659 dnl --------------------------------------
1660 dnl checking for flex and bison
1661 dnl --------------------------------------
1662
1663 AM_PROG_LEX
1664 AC_MSG_CHECKING(version of flex)
1665 frr_ac_flex_version="$(eval $LEX -V | grep flex | head -n 1)"
1666 frr_ac_flex_version="${frr_ac_flex_version##* }"
1667 AC_MSG_RESULT([$frr_ac_flex_version])
1668 AX_COMPARE_VERSION([$frr_ac_flex_version], [lt], [2.5.20], [
1669   LEX="$SHELL $missing_dir/missing flex"
1670   if test -f "${srcdir}/lib/command_lex.c" -a -f "${srcdir}/lib/command_lex.h"; then
1671     AC_MSG_WARN([using pregenerated flex output files])
1672   else
1673     AC_MSG_ERROR([flex failure and pregenerated files not included (probably a git build)])
1674   fi
1675   AC_SUBST([LEX_OUTPUT_ROOT], [lex.yy])
1676   AC_SUBST([LEXLIB], [''])
1677 ])
1678
1679 AC_PROG_YACC
1680 dnl thanks GNU bison for this b*llshit...
1681 AC_MSG_CHECKING(version of bison)
1682 frr_ac_bison_version="$(eval $YACC -V | grep bison | head -n 1)"
1683 frr_ac_bison_version="${frr_ac_bison_version##* }"
1684 frr_ac_bison_missing="false"
1685 case "x${frr_ac_bison_version}" in
1686   x2.7*)
1687     BISON_OPENBRACE='"'
1688     BISON_CLOSEBRACE='"'
1689     BISON_VERBOSE=''
1690     AC_MSG_RESULT([$frr_ac_bison_version - 2.7 or older])
1691     ;;
1692   x2.*|x1.*)
1693     AC_MSG_RESULT([$frr_ac_bison_version])
1694     AC_MSG_WARN([installed bison is too old.  Please install GNU bison 2.7.x or newer.])
1695     frr_ac_bison_missing="true"
1696     ;;
1697   x)
1698     AC_MSG_RESULT([none])
1699     AC_MSG_WARN([could not determine bison version.  Please install GNU bison 2.7.x or newer.])
1700     frr_ac_bison_missing="true"
1701     ;;
1702   *)
1703     BISON_OPENBRACE='{'
1704     BISON_CLOSEBRACE='}'
1705     BISON_VERBOSE='-Dparse.error=verbose'
1706     AC_MSG_RESULT([$frr_ac_bison_version - 3.0 or newer])
1707     ;;
1708 esac
1709 AC_SUBST(BISON_OPENBRACE)
1710 AC_SUBST(BISON_CLOSEBRACE)
1711 AC_SUBST(BISON_VERBOSE)
1712
1713 if $frr_ac_bison_missing; then
1714   YACC="$SHELL $missing_dir/missing bison -y"
1715   if test -f "${srcdir}/lib/command_parse.c" -a -f "${srcdir}/lib/command_parse.h"; then
1716     AC_MSG_WARN([using pregenerated bison output files])
1717   else
1718     AC_MSG_ERROR([bison failure and pregenerated files not included (probably a git build)])
1719   fi
1720 fi
1721
1722 dnl -------------------
1723 dnl capabilities checks
1724 dnl -------------------
1725 if test "${enable_capabilities}" != "no"; then
1726   AC_MSG_CHECKING(whether prctl PR_SET_KEEPCAPS is available)
1727   AC_TRY_COMPILE([#include <sys/prctl.h>],[prctl(PR_SET_KEEPCAPS, 1, 0, 0, 0);],
1728     [AC_MSG_RESULT(yes)
1729      AC_DEFINE(HAVE_PR_SET_KEEPCAPS,,prctl)
1730      frr_ac_keepcaps="yes"],
1731      AC_MSG_RESULT(no)
1732   )
1733   if test x"${frr_ac_keepcaps}" = x"yes"; then
1734     AC_CHECK_HEADERS(sys/capability.h)
1735   fi
1736   if test x"${ac_cv_header_sys_capability_h}" = x"yes"; then
1737     AC_CHECK_LIB(cap, cap_init,
1738       [AC_DEFINE(HAVE_LCAPS,1,Capabilities)
1739        LIBCAP="-lcap"
1740        frr_ac_lcaps="yes"]
1741     )
1742   else
1743     AC_CHECK_HEADERS(priv.h,
1744      [AC_MSG_CHECKING(Solaris style privileges are available)
1745       AC_TRY_COMPILE([#include <priv.h>],[getpflags(PRIV_AWARE);],
1746           [AC_MSG_RESULT(yes)
1747            AC_DEFINE(HAVE_SOLARIS_CAPABILITIES,1,getpflags)
1748            frr_ac_scaps="yes"],
1749            AC_MSG_RESULT(no)
1750       )
1751      ]
1752    )
1753   fi
1754   if test x"${frr_ac_scaps}" = x"yes" \
1755        -o x"${frr_ac_lcaps}" = x"yes"; then
1756     AC_DEFINE(HAVE_CAPABILITIES,1,capabilities)
1757   fi
1758 fi
1759 AC_SUBST(LIBCAP)
1760
1761 dnl ---------------------------
1762 dnl check for glibc 'backtrace'
1763 dnl ---------------------------
1764 if test x"${enable_backtrace}" != x"no" ; then
1765   backtrace_ok=no
1766   AC_CHECK_HEADER([execinfo.h], [
1767     AC_SEARCH_LIBS([backtrace], [execinfo], [
1768       AC_DEFINE(HAVE_GLIBC_BACKTRACE,,[Glibc backtrace])
1769       AC_DEFINE(HAVE_STACK_TRACE,,[Stack symbol decoding])
1770       backtrace_ok=yes
1771     ],, [-lm])
1772   ])
1773
1774   if test x"${enable_backtrace}" = x"yes" -a x"${backtrace_ok}" = x"no"; then
1775     dnl user explicitly requested backtrace but we failed to find support
1776     AC_MSG_FAILURE([failed to find backtrace support])
1777   fi
1778 fi
1779
1780 dnl -----------------------------------------
1781 dnl check for malloc mallinfo struct and call
1782 dnl this must try and link using LIBS, in
1783 dnl order to check no alternative allocator
1784 dnl has been specified, which might not provide
1785 dnl mallinfo, e.g. such as Umem on Solaris.
1786 dnl -----------------------------------------
1787 AC_CHECK_HEADER([malloc.h],
1788  [AC_MSG_CHECKING(whether mallinfo is available)
1789   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <malloc.h>]],
1790                         [[struct mallinfo ac_x; ac_x = mallinfo ();]])],
1791       [AC_MSG_RESULT(yes)
1792        AC_DEFINE(HAVE_MALLINFO,,mallinfo)],
1793        AC_MSG_RESULT(no)
1794   )
1795  ], [], FRR_INCLUDES)
1796
1797 dnl ------
1798 dnl ZeroMQ
1799 dnl ------
1800 if test "x$enable_zeromq" != "xno"; then
1801   PKG_CHECK_MODULES(ZEROMQ, [libzmq >= 4.0.0], [
1802     AC_DEFINE(HAVE_ZEROMQ, 1, [Enable ZeroMQ support])
1803     ZEROMQ=true
1804   ], [
1805     if test "x$enable_zeromq" = "xyes"; then
1806       AC_MSG_ERROR([configuration specifies --enable-zeromq but libzmq was not found])
1807     fi
1808   ])
1809 fi
1810 AM_CONDITIONAL([ZEROMQ], test "x$ZEROMQ" = "xtrue")
1811
1812 dnl ----------
1813 dnl configure date
1814 dnl ----------
1815 CONFDATE=`date '+%Y%m%d'`
1816 AC_SUBST(CONFDATE)
1817
1818 dnl ------------------------------
1819 dnl set paths for state directory
1820 dnl ------------------------------
1821 AC_MSG_CHECKING(directory to use for state file)
1822 if test "${prefix}" = "NONE"; then
1823   frr_statedir_prefix="";
1824 else
1825   frr_statedir_prefix=${prefix}
1826 fi
1827 if test "${localstatedir}" = '${prefix}/var'; then
1828   for FRR_STATE_DIR in ${frr_statedir_prefix}/var/run dnl
1829                         ${frr_statedir_prefix}/var/adm dnl
1830                         ${frr_statedir_prefix}/etc dnl
1831                         /var/run        dnl
1832                         /var/adm        dnl
1833                         /etc            dnl
1834                         /dev/null;
1835   do
1836     test -d $FRR_STATE_DIR && break
1837   done
1838   frr_statedir=$FRR_STATE_DIR
1839 else
1840   frr_statedir=${localstatedir}
1841 fi
1842 if test $frr_statedir = "/dev/null"; then
1843     AC_MSG_ERROR('STATE DIRECTORY NOT FOUND! FIX OR SPECIFY --localstatedir!')
1844 fi
1845 AC_MSG_RESULT(${frr_statedir})
1846 AC_SUBST(frr_statedir)
1847
1848 AC_DEFINE_UNQUOTED(LDPD_SOCKET, "$frr_statedir/ldpd.sock",ldpd control socket)
1849 AC_DEFINE_UNQUOTED(ZEBRA_SERV_PATH, "$frr_statedir/zserv.api",zebra api socket)
1850 AC_DEFINE_UNQUOTED(DAEMON_VTY_DIR, "$frr_statedir",daemon vty directory)
1851
1852 dnl autoconf does this, but it does it too late...
1853 test "x$prefix" = xNONE && prefix=$ac_default_prefix
1854 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
1855
1856 dnl get the full path, recursing through variables...
1857 vtysh_bin="$bindir/vtysh"
1858 for I in 1 2 3 4 5 6 7 8 9 10; do
1859         eval vtysh_bin="\"$vtysh_bin\""
1860 done
1861 AC_DEFINE_UNQUOTED(VTYSH_BIN_PATH, "$vtysh_bin",path to vtysh binary)
1862
1863 CFG_SYSCONF="$sysconfdir"
1864 CFG_SBIN="$sbindir"
1865 CFG_STATE="$frr_statedir"
1866 CFG_MODULE="$moduledir"
1867 for I in 1 2 3 4 5 6 7 8 9 10; do
1868         eval CFG_SYSCONF="\"$CFG_SYSCONF\""
1869         eval CFG_SBIN="\"$CFG_SBIN\""
1870         eval CFG_STATE="\"$CFG_STATE\""
1871         eval CFG_MODULE="\"$CFG_MODULE\""
1872 done
1873 AC_SUBST(CFG_SYSCONF)
1874 AC_SUBST(CFG_SBIN)
1875 AC_SUBST(CFG_STATE)
1876 AC_SUBST(CFG_MODULE)
1877 AC_DEFINE_UNQUOTED(MODULE_PATH, "$CFG_MODULE", path to modules)
1878
1879 dnl ------------------------------------
1880 dnl Enable RPKI and add librtr to libs
1881 dnl ------------------------------------
1882 if test "${enable_rpki}" = "yes"; then
1883   PKG_CHECK_MODULES(RTRLIB,[rtrlib >= 0.5.0],
1884       [AC_DEFINE(HAVE_RPKI,1,Enable RPKI prefix validation for BGP)
1885       RPKI=true],
1886       [RPKI=false
1887       AC_MSG_ERROR([rtrlib was not found on your system or is too old.])]
1888   )
1889 fi
1890 AM_CONDITIONAL([RPKI], test "x$RPKI" = "xtrue")
1891
1892 dnl ------------------------------------------
1893 dnl Check whether rtrlib was build with ssh support
1894 dnl ------------------------------------------
1895 AC_MSG_CHECKING([whether the RTR Library is compiled with SSH])
1896 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "rtrlib/rtrlib.h"]],
1897                         [[struct tr_ssh_config config;]])],
1898         [AC_MSG_RESULT(yes)
1899         AC_DEFINE(FOUND_SSH,,found_ssh)],
1900         AC_MSG_RESULT(no)
1901 )
1902
1903 dnl ---------------------------
1904 dnl Check htonl works correctly
1905 dnl ---------------------------
1906 AC_MSG_CHECKING(for working htonl)
1907 AC_CACHE_VAL(ac_cv_htonl_works,
1908  [AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES],[htonl (0);])],
1909                 [ac_cv_htonl_works=yes], [ac_cv_htonl_works=no])
1910  ]
1911 )
1912 AC_MSG_RESULT($ac_cv_htonl_works)
1913
1914 AC_CONFIG_FILES([Makefile
1915           bgpd/Makefile
1916           vtysh/Makefile
1917           doc/Makefile
1918           doc/user/Makefile
1919           doc/manpages/Makefile
1920           doc/developer/Makefile
1921           tests/Makefile
1922           bgpd/rfp-example/rfptest/Makefile
1923           bgpd/rfp-example/librfp/Makefile
1924           redhat/frr.spec
1925           debianpkg/Makefile
1926           debianpkg/changelog
1927           alpine/APKBUILD
1928           snapcraft/snapcraft.yaml
1929           lib/version.h
1930           tests/lib/cli/test_cli.refout
1931           pkgsrc/bgpd.sh pkgsrc/ospf6d.sh pkgsrc/ospfd.sh
1932           pkgsrc/ripd.sh pkgsrc/ripngd.sh pkgsrc/zebra.sh
1933           pkgsrc/eigrpd.sh])
1934
1935 if test "${enable_bgp_vnc}" != "no"; then
1936    if test "${with_rfp_path}" != "bgpd/rfp-example" ; then
1937       AC_CONFIG_FILES([${with_rfp_path}/rfptest/Makefile ${with_rfp_path}/librfp/Makefile])
1938    fi
1939 fi
1940
1941 AC_CONFIG_FILES([solaris/Makefile])
1942
1943 AC_CONFIG_FILES([vtysh/extract.pl],[chmod +x vtysh/extract.pl])
1944
1945 AC_CONFIG_COMMANDS([lib/route_types.h], [
1946         dst="${ac_abs_top_builddir}/lib/route_types.h"
1947         ${PERL} "${ac_abs_top_srcdir}/lib/route_types.pl" \
1948                 < "${ac_abs_top_srcdir}/lib/route_types.txt" \
1949                 > "${dst}.tmp"
1950         test -f "${dst}" \
1951                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
1952                 && rm "${dst}.tmp" \
1953                 || mv "${dst}.tmp" "${dst}"
1954 ], [
1955         PERL="$PERL"
1956 ])
1957
1958 AS_IF([test "x$with_pkg_git_version" = "xyes"], [
1959     AC_CONFIG_COMMANDS([lib/gitversion.h], [
1960         dst="${ac_abs_top_builddir}/lib/gitversion.h"
1961         ${PERL} "${ac_abs_top_srcdir}/lib/gitversion.pl" \
1962                 "${ac_abs_top_srcdir}" \
1963                 > "${dst}.tmp"
1964         test -f "${dst}" \
1965                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
1966                 && rm "${dst}.tmp" \
1967                 || mv "${dst}.tmp" "${dst}"
1968     ], [
1969         PERL="$PERL"
1970     ])
1971 ])
1972
1973 ## Hack, but working solution to avoid rebuilding of frr.info.
1974 ## It's already in CVS until texinfo 4.7 is more common.
1975 AC_OUTPUT
1976
1977 echo "
1978 FRRouting configuration
1979 ------------------------------
1980 FRR version             : ${PACKAGE_VERSION}
1981 host operating system   : ${host_os}
1982 source code location    : ${srcdir}
1983 compiler                : ${CC}
1984 compiler flags          : ${CFLAGS}
1985 make                    : ${MAKE-make}
1986 linker flags            : ${LDFLAGS} ${LIBS} ${LIBCAP} ${LIBREADLINE} ${LIBM}
1987 state file directory    : ${frr_statedir}
1988 config file directory   : `eval echo \`echo ${sysconfdir}\``
1989 example directory       : `eval echo \`echo ${exampledir}\``
1990 module directory        : ${CFG_MODULE}
1991 user to run as          : ${enable_user}
1992 group to run as         : ${enable_group}
1993 group for vty sockets   : ${enable_vty_group}
1994 config file mask        : ${enable_configfile_mask}
1995 log file mask           : ${enable_logfile_mask}
1996 zebra protobuf enabled  : ${have_protobuf:-no}
1997
1998 The above user and group must have read/write access to the state file
1999 directory and to the config files in the config file directory."