configure.ac

   1 ##
   2 ## Configure template file for FRRouting.
   3 ## autoconf will generate a configure script.
   4 ##
   5 ##  Copyright (c) 1996, 97, 98, 99, 2000 Kunihiro Ishiguro <kunihiro@zebra.org>
   6 ##  Portions Copyright (c) 2003 Paul Jakma <paul@dishone.st>
   7 ##
   8 AC_PREREQ([2.60])
   9
  10 AC_INIT([frr], [7.7-dev], [https://github.com/frrouting/frr/issues])
  11 PACKAGE_URL="https://frrouting.org/"
  12 AC_SUBST([PACKAGE_URL])
  13 PACKAGE_FULLNAME="FRRouting"
  14 AC_SUBST([PACKAGE_FULLNAME])
  15
  16 CONFIG_ARGS="`echo $ac_configure_args | sed -e \"s% '[[A-Z]]*FLAGS=[[^']]\+'%%g\"`"
  17 AC_SUBST([CONFIG_ARGS])
  18
  19 AC_CONFIG_SRCDIR([lib/zebra.h])
  20 AC_CONFIG_MACRO_DIR([m4])
  21 AC_CONFIG_AUX_DIR([m4/ac])
  22
  23 dnl -----------------------------------
  24 dnl Get hostname and other information.
  25 dnl -----------------------------------
  26 AC_CANONICAL_BUILD()
  27 AC_CANONICAL_HOST()
  28
  29 AC_ARG_VAR([AR],[archiver command])
  30 AC_ARG_VAR([LD],[linker command])
  31 AC_ARG_VAR([OBJCOPY],[objcopy command])
  32 AC_ARG_VAR([OBJDUMP],[objdump command])
  33 AC_ARG_VAR([RANLIB],[ranlib command])
  34 AC_ARG_VAR([STRIP],[strip command])
  35
  36 hosttools_clippy="false"
  37 build_clippy="true"
  38
  39 dnl case 1: external clippy
  40 if test -n "$with_clippy" -a "$with_clippy" != "no" -a "$with_clippy" != "yes"; then
  41   if test "$enable_clippy_only" = "yes"; then
  42     AC_MSG_ERROR([--enable-clippy-only does not make sense with --with-clippy])
  43   fi
  44
  45   CLIPPY="$with_clippy"
  46   build_clippy="false"
  47   if test ! -x "$with_clippy"; then
  48     AC_MSG_ERROR([clippy tool ($with_clippy) is not executable])
  49   fi
  50
  51 dnl case 2: cross-compiling internal clippy
  52 elif test "$host" != "$build"; then
  53   if test "$srcdir" = "."; then
  54     AC_MSG_ERROR([cross-compilation is only possible with builddir separate from srcdir or by building clippy separately and using the --with-clippy option.  create a separate directory and run as .../path-to-frr/configure.])
  55   fi
  56   test -d hosttools || mkdir hosttools
  57   abssrc="`cd \"${srcdir}\"; pwd`"
  58
  59   AC_MSG_NOTICE([...])
  60   AC_MSG_NOTICE([... cross-compilation: creating hosttools directory and self-configuring for build platform tools])
  61   AC_MSG_NOTICE([... use HOST_CPPFLAGS / HOST_CFLAGS / HOST_LDFLAGS if neccessary])
  62   AC_MSG_NOTICE([...])
  63
  64   (
  65     for var in $ac_precious_vars; do
  66       dnl special cases
  67       case "$var" in
  68       YACC|YFLAGS) continue;;
  69       PYTHON*)     retain=true;;
  70       *)           retain=false;
  71       esac
  72
  73       eval "hostvar=\"\${HOST_$var}\""
  74       eval "targetvar=\"\${$var}\""
  75       if test -n "$hostvar"; then
  76         eval "$var='$hostvar'"
  77         _AS_ECHO_LOG([host $var='$hostvar'])
  78       elif $retain; then
  79         _AS_ECHO_LOG([host retain $var='$targetvar'])
  80       else
  81         eval "unset $var"
  82         _AS_ECHO_LOG([host unset $var])
  83       fi
  84     done
  85     cd hosttools
  86     "${abssrc}/configure" "--host=$build" "--build=$build" "--enable-clippy-only" "--disable-nhrpd" "--disable-vtysh"
  87   ) || exit 1
  88
  89   AC_MSG_NOTICE([...])
  90   AC_MSG_NOTICE([... cross-compilation: finished self-configuring for build platform tools])
  91   AC_MSG_NOTICE([...])
  92
  93   build_clippy="false"
  94   hosttools_clippy="true"
  95   CLIPPY="hosttools/lib/clippy"
  96
  97 dnl case 3: normal build internal clippy
  98 else
  99   CLIPPY="lib/clippy\$(EXEEXT)"
 100 fi
 101 AC_SUBST([CLIPPY])
 102 AM_CONDITIONAL([BUILD_CLIPPY], [$build_clippy])
 103 AM_CONDITIONAL([HOSTTOOLS_CLIPPY], [$hosttools_clippy])
 104 AM_CONDITIONAL([ONLY_CLIPPY], [test "$enable_clippy_only" = "yes"])
 105
 106 # Disable portability warnings -- our automake code (in particular
 107 # common.am) uses some constructs specific to gmake.
 108 AM_INIT_AUTOMAKE([1.12 -Wno-portability foreign])
 109 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
 110 AM_SILENT_RULES([yes])
 111 AC_CONFIG_HEADERS([config.h])
 112
 113 AC_PATH_PROG([PERL], [perl])
 114 PKG_PROG_PKG_CONFIG
 115
 116 dnl default is to match previous behavior
 117 exampledir=${sysconfdir}
 118 AC_ARG_ENABLE([exampledir],
 119           AS_HELP_STRING([--enable-exampledir],
 120                          [specify alternate directory for examples]),
 121                          exampledir="$enableval",)
 122 dnl XXX add --exampledir to autoconf standard directory list somehow
 123 AC_SUBST([exampledir])
 124
 125 dnl default is to match previous behavior
 126 pkgsrcrcdir=""
 127 AC_ARG_ENABLE([pkgsrcrcdir],
 128           AS_HELP_STRING([--enable-pkgsrcrcdir],
 129                          [specify directory for rc.d scripts]),
 130                          pkgsrcrcdir="$enableval",)
 131 dnl XXX add --pkgsrcrcdir to autoconf standard directory list somehow
 132 AC_SUBST([pkgsrcrcdir])
 133 AM_CONDITIONAL([PKGSRC], [test "$pkgsrcrcdir" != ""])
 134
 135 AC_ARG_WITH([moduledir], [AS_HELP_STRING([--with-moduledir=DIR], [module directory (${libdir}/frr/modules)])], [
 136         moduledir="$withval"
 137 ], [
 138         moduledir="\${libdir}/frr/modules"
 139 ])
 140 AC_SUBST([moduledir], [$moduledir])
 141
 142 AC_ARG_WITH([scriptdir], [AS_HELP_STRING([--with-scriptdir=DIR], [script directory (${sysconfdir}/scripts)])], [
 143         scriptdir="$withval"
 144 ], [
 145         scriptdir="\${sysconfdir}/scripts"
 146 ])
 147 AC_SUBST([scriptdir], [$scriptdir])
 148
 149 AC_ARG_WITH([yangmodelsdir], [AS_HELP_STRING([--with-yangmodelsdir=DIR], [yang models directory (${datarootdir}/yang)])], [
 150         yangmodelsdir="$withval"
 151 ], [
 152         yangmodelsdir="\${datarootdir}/yang"
 153 ])
 154 AC_SUBST([yangmodelsdir])
 155
 156 AC_ARG_WITH([vici-socket], [AS_HELP_STRING([--with-vici-socket=PATH], [vici-socket (/var/run/charon.vici)])], [
 157         vici_socket="$withval"
 158 ], [
 159         vici_socket="/var/run/charon.vici"
 160 ])
 161 AC_DEFINE_UNQUOTED([VICI_SOCKET], ["$vici_socket"], [StrongSWAN vici socket path])
 162
 163 AC_ARG_ENABLE(tcmalloc,
 164         AS_HELP_STRING([--enable-tcmalloc], [Turn on tcmalloc]),
 165 [case "${enableval}" in
 166   yes) tcmalloc_enabled=true
 167 LIBS="$LIBS -ltcmalloc_minimal"
 168  ;;
 169   no)  tcmalloc_enabled=false ;;
 170   *) AC_MSG_ERROR([bad value ${enableval} for --enable-tcmalloc]) ;;
 171 esac],[tcmalloc_enabled=false])
 172
 173
 174 dnl Thanks autoconf, but we don't want a default -g -O2.  We have our own
 175 dnl flag determination logic.
 176 CFLAGS="${CFLAGS:-}"
 177
 178 dnl --------------------
 179 dnl Check CC and friends
 180 dnl --------------------
 181 dnl note orig_cflags is also used further down
 182 orig_cflags="$CFLAGS"
 183 orig_cxxflags="$CXXFLAGS"
 184 AC_LANG([C])
 185 AC_PROG_CC
 186 AC_PROG_CPP
 187 AC_PROG_CXX
 188 AM_PROG_CC_C_O
 189 dnl remove autoconf default "-g -O2"
 190 CFLAGS="$orig_cflags"
 191 CXXFLAGS="$orig_cxxflags"
 192 AC_PROG_CC_C99
 193 dnl NB: see C11 below
 194
 195 dnl Some special handling for ICC later on
 196 if test "$CC" = "icc"; then
 197     cc_is_icc="yes"
 198 fi
 199
 200 PKG_PROG_PKG_CONFIG
 201
 202 dnl it's 2019, sed is sed.
 203 SED=sed
 204 AC_SUBST([SED])
 205
 206 dnl try and enable CFLAGS that are useful for FRR
 207 dnl - specifically, options to control warnings
 208
 209 AC_SUBST([AC_CFLAGS])
 210 AC_USE_SYSTEM_EXTENSIONS
 211 AC_DEFUN([AC_C_FLAG], [{
 212     m4_pushdef([cachename],[m4_translit([frr_cv_$1],[ =-+/{}$],[________])])
 213     AC_CACHE_CHECK([[whether $CC supports $1]], cachename, [
 214         AC_LANG_PUSH([C])
 215         ac_c_flag_save="$CFLAGS"
 216         CFLAGS="$CFLAGS $1"
 217         AC_COMPILE_IFELSE(
 218                 [AC_LANG_PROGRAM([[$4]])],
 219                 [
 220                         cachename=yes
 221                 ], [
 222                         cachename=no
 223                 ])
 224         CFLAGS="$ac_c_flag_save"
 225         AC_LANG_POP([C])
 226     ])
 227     if test "$cachename" = "yes"; then
 228         m4_if([$3], [], [AC_CFLAGS="$AC_CFLAGS $1"], [$3])
 229     else
 230         :
 231         $2
 232     fi
 233     m4_popdef([cachename])
 234 }])
 235
 236 AC_DEFUN([AC_LINK_IFELSE_FLAGS], [{
 237         AC_LANG_PUSH([C])
 238         ac_cflags_save="$CFLAGS"
 239         ac_libs_save="$LIBS"
 240         CFLAGS="$CFLAGS $1"
 241         LIBS="$LIBS $2"
 242         AC_LINK_IFELSE(
 243                 [$3],
 244                 [
 245                         CFLAGS="$ac_cflags_save"
 246                         LIBS="$ac_libs_save"
 247                         m4_default([$5], [
 248                                 AC_MSG_RESULT([yes])
 249                         ])
 250                 ], [
 251                         CFLAGS="$ac_cflags_save"
 252                         LIBS="$ac_libs_save"
 253                         m4_default([$4], [
 254                                 AC_MSG_RESULT([no])
 255                         ])
 256                 ])
 257         AC_LANG_POP([C])
 258         }])
 259
 260 dnl ICC won't bail on unknown options without -diag-error 10006
 261 dnl need to do this first so we get useful results for the other options
 262 if test "$cc_is_icc" = "yes"; then
 263     AC_C_FLAG([-diag-error 10006])
 264 fi
 265
 266 dnl AC_PROG_CC_C99 may change CC to include -std=gnu99 or something
 267 ac_cc="$CC"
 268 CC="${CC% -std=gnu99}"
 269 CC="${CC% -std=c99}"
 270
 271 AC_C_FLAG([-std=gnu11], [CC="$ac_cc"], [CC="$CC -std=gnu11"])
 272
 273 dnl if the user has specified any CFLAGS, override our settings
 274 if test "$enable_gcov" = "yes"; then
 275    if test "$orig_cflags" = ""; then
 276       AC_C_FLAG([-coverage])
 277       AC_C_FLAG([-O0])
 278    fi
 279
 280    AC_LDFLAGS="${AC_LDFLAGS} -lgcov"
 281 fi
 282
 283 if test "$enable_clang_coverage" = "yes"; then
 284    AC_C_FLAG([-fprofile-instr-generate], [
 285      AC_MSG_ERROR([$CC does not support -fprofile-instr-generate.])
 286    ])
 287    AC_C_FLAG([-fcoverage-mapping], [
 288      AC_MSG_ERROR([$CC does not support -fcoverage-mapping.])
 289    ])
 290 fi
 291
 292 if test "$enable_scripting" = "yes"; then
 293    AX_PROG_LUA([5.3], [5.4], [], [
 294      AC_MSG_ERROR([Lua 5.3 is required to build with Lua support. No other version is supported.])
 295    ])
 296    AX_LUA_HEADERS([], [
 297      AC_MSG_ERROR([Lua 5.3 headers are required to build with Lua support. No other version is supported.])
 298    ])
 299    AX_LUA_LIBS([
 300      AC_DEFINE([HAVE_SCRIPTING], [1], [Have support for scripting])
 301      LIBS="$LIBS $LUA_LIB"
 302    ], [
 303      AC_MSG_ERROR([Lua 5.3 libraries are required to build with Lua support. No other version is supported.])
 304    ])
 305 fi
 306
 307 dnl the following flags go in CFLAGS rather than AC_CFLAGS since they make
 308 dnl sense to be overridden by the user
 309 if test "$enable_dev_build" = "yes"; then
 310    AC_DEFINE([DEV_BUILD], [1], [Build for development])
 311    if test "$orig_cflags" = ""; then
 312       AC_C_FLAG([-O0],,[CFLAGS="$CFLAGS -O0"])
 313       AC_C_FLAG([-g3],,[CFLAGS="$CFLAGS -g3"])
 314       AC_C_FLAG([-ggdb3],,[CFLAGS="$CFLAGS -ggdb3"])
 315    fi
 316 else
 317    if test "$orig_cflags" = ""; then
 318       AC_C_FLAG([-g],,[CFLAGS="$CFLAGS -g"])
 319       AC_C_FLAG([-O2],,[CFLAGS="$CFLAGS -O2"])
 320    fi
 321 fi
 322
 323 AM_CONDITIONAL([DEV_BUILD], [test "$enable_dev_build" = "yes"])
 324
 325 dnl always want these CFLAGS
 326 AC_C_FLAG([-fno-omit-frame-pointer])
 327 AC_C_FLAG([-funwind-tables])
 328 AC_C_FLAG([-Wall])
 329 AC_C_FLAG([-Wextra])
 330 AC_C_FLAG([-Wmissing-prototypes])
 331 AC_C_FLAG([-Wmissing-declarations])
 332 AC_C_FLAG([-Wpointer-arith])
 333 AC_C_FLAG([-Wbad-function-cast])
 334 AC_C_FLAG([-Wwrite-strings])
 335 AC_C_FLAG([-Wundef])
 336 if test "$enable_gcc_ultra_verbose" = "yes" ; then
 337   AC_C_FLAG([-Wcast-qual])
 338   AC_C_FLAG([-Wstrict-prototypes])
 339   AC_C_FLAG([-Wmissing-noreturn])
 340   AC_C_FLAG([-Wmissing-format-attribute])
 341   AC_C_FLAG([-Wunreachable-code])
 342   AC_C_FLAG([-Wpacked])
 343   AC_C_FLAG([-Wpadded])
 344   AC_C_FLAG([-Wshadow])
 345 else
 346   AC_C_FLAG([-Wno-unused-result])
 347 fi
 348 AC_C_FLAG([-Wno-unused-parameter])
 349 AC_C_FLAG([-Wno-missing-field-initializers])
 350
 351 AC_C_FLAG([-Wc++-compat], [], [CXX_COMPAT_CFLAGS="-Wc++-compat"])
 352 AC_SUBST([CXX_COMPAT_CFLAGS])
 353
 354 dnl ICC emits a broken warning for const char *x = a ? "b" : "c";
 355 dnl for some reason the string consts get 'promoted' to char *,
 356 dnl triggering a const to non-const conversion warning.
 357 if test "$cc_is_icc" = "yes"; then
 358     AC_C_FLAG([-diag-disable 3179])
 359 fi
 360
 361 if test "$enable_werror" = "yes" ; then
 362   WERROR="-Werror"
 363 fi
 364 AC_SUBST([WERROR])
 365
 366 SAN_FLAGS=""
 367 if test "$enable_address_sanitizer" = "yes"; then
 368   AC_C_FLAG([-fsanitize=address], [
 369     AC_MSG_ERROR([$CC does not support Address Sanitizer.])
 370   ], [
 371     SAN_FLAGS="$SAN_FLAGS -fsanitize=address"
 372   ])
 373 fi
 374 if test "$enable_thread_sanitizer" = "yes"; then
 375   AC_C_FLAG([-fsanitize=thread], [
 376     AC_MSG_ERROR([$CC does not support Thread Sanitizer.])
 377   ], [
 378     SAN_FLAGS="$SAN_FLAGS -fsanitize=thread"
 379   ])
 380 fi
 381 if test "$enable_memory_sanitizer" = "yes"; then
 382   AC_C_FLAG([-fsanitize=memory -fPIE -pie], [
 383     AC_MSG_ERROR([$CC does not support Memory Sanitizer.])
 384   ], [
 385     SAN_FLAGS="$SAN_FLAGS -fsanitize=memory -fPIE -pie"
 386   ])
 387 fi
 388 if test "$enable_undefined_sanitizer" = "yes"; then
 389   AC_C_FLAG([-fsanitize=undefined], [
 390     AC_MSG_ERROR([$CC does not support UndefinedBehaviorSanitizer.])
 391   ], [
 392     SAN_FLAGS="$SAN_FLAGS -fsanitize=undefined"
 393   ])
 394 fi
 395 AC_SUBST([SAN_FLAGS])
 396
 397 dnl frr-format.so
 398 if test "$with_frr_format" != "no" -a "$with_frr_format" != "yes" -a -n "$with_frr_format"; then
 399   AC_C_FLAG([-fplugin=${with_frr_format}], [
 400     AC_MSG_ERROR([specified frr-format plugin ($with_frr_format) does not work])
 401   ],,[
 402 #ifndef _FRR_ATTRIBUTE_PRINTFRR
 403 #error plugin not loaded
 404 #endif
 405 #if _FRR_ATTRIBUTE_PRINTFRR < 0x10000
 406 #error plugin too old
 407 #endif
 408   ])
 409 elif test "$with_frr_format" = "no"; then
 410   : #nothing
 411 else
 412   AC_C_FLAG([-fplugin=tools/gcc-plugins/frr-format.so],[
 413     AC_C_FLAG([-fplugin=frr-format],[
 414       if test "$with_frr_format" = "yes"; then
 415         AC_MSG_ERROR([frr-format plugin requested but not found])
 416       fi
 417     ],,[
 418 #ifndef _FRR_ATTRIBUTE_PRINTFRR
 419 #error plugin not loaded
 420 #endif
 421 #if _FRR_ATTRIBUTE_PRINTFRR < 0x10000
 422 #error plugin too old
 423 #endif
 424     ])
 425   ],,[
 426 #ifndef _FRR_ATTRIBUTE_PRINTFRR
 427 #error plugin not loaded
 428 #endif
 429 #if _FRR_ATTRIBUTE_PRINTFRR < 0x10000
 430 #error plugin too old
 431 #endif
 432   ])
 433 fi
 434
 435 AC_MSG_CHECKING([whether linker supports __start/stop_section symbols])
 436 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 437 #include <stdio.h>
 438 int __attribute__((section("secttest"))) var = 1;
 439 extern int __start_secttest, __stop_secttest;
 440 ]], [[
 441   void *a = &var, *b = &__start_secttest, *c = &__stop_secttest;
 442   printf("%p %p %p\n", a, b, c);
 443 ]])], [
 444   AC_MSG_RESULT(yes)
 445   AC_DEFINE(HAVE_SECTION_SYMS, 1, [have __start/stop_section symbols])
 446 ], [
 447   AC_MSG_RESULT(no)
 448 ])
 449
 450 dnl ----------
 451 dnl Essentials
 452 dnl ----------
 453
 454 AX_PTHREAD([
 455   CC="$PTHREAD_CC"
 456   AC_CFLAGS="$AC_CFLAGS $PTHREAD_CFLAGS"
 457   LIBS="$PTHREAD_LIBS $LIBS"
 458 ], [
 459   AC_MSG_FAILURE([This FRR version needs pthreads])
 460 ])
 461
 462 AC_SEARCH_LIBS([pthread_condattr_setclock], [],
 463                 [frr_cv_pthread_condattr_setclock=yes],
 464                 [frr_cv_pthread_condattr_setclock=no])
 465 if test "$frr_cv_pthread_condattr_setclock" = "yes"; then
 466   AC_DEFINE([HAVE_PTHREAD_CONDATTR_SETCLOCK], [1], [Have pthread.h pthread_condattr_setclock])
 467 fi
 468
 469 dnl --------------
 470 dnl Check programs
 471 dnl --------------
 472 AC_PROG_INSTALL
 473 AC_PROG_LN_S
 474 AC_CHECK_TOOL([AR], [ar])
 475
 476 dnl -------
 477 dnl libtool
 478 dnl -------
 479 AC_ARG_ENABLE([static-bin],
 480   AS_HELP_STRING([--enable-static-bin], [link binaries statically]))
 481 LT_INIT
 482 _LT_CONFIG_LIBTOOL([
 483   patch -N -i "${srcdir}/m4/libtool-whole-archive.patch" libtool >&AS_MESSAGE_LOG_FD || \
 484     AC_MSG_WARN([Could not patch libtool for static linking support.  Loading modules into a statically linked daemon will fail.])
 485   sed -e 's%func_warning "relinking%true #\0%' -i libtool || true
 486   sed -e 's%func_warning "remember to run%true #\0%' -i libtool || true
 487   sed -e 's%func_warning ".*has not been installed in%true #\0%' -i libtool || true
 488 ])
 489 if test "$enable_static_bin" = "yes"; then
 490   AC_LDFLAGS="-static"
 491   if test "$enable_static" != "yes"; then
 492     AC_MSG_ERROR([The --enable-static-bin option must be combined with --enable-static.])
 493   fi
 494 fi
 495 if test "$enable_shared" != "yes"; then
 496   AC_MSG_ERROR([FRR cannot be built with --disable-shared.  If you want statically linked daemons, use --enable-shared --enable-static --enable-static-bin])
 497 fi
 498 AC_SUBST([AC_LDFLAGS])
 499 AM_CONDITIONAL([STATIC_BIN], [test "$enable_static_bin" = "yes"])
 500
 501 AC_ARG_ENABLE([rpath],
 502   [AS_HELP_STRING([--enable-rpath], [set hardcoded rpaths in the executable @<:@default=yes@:>@])],
 503   [],
 504   [enable_rpath=yes])
 505
 506 dnl $AR and $RANLIB are set by LT_INIT above
 507 AC_MSG_CHECKING([whether $AR supports D option])
 508 if $AR crD conftest.a >/dev/null 2>/dev/null; then
 509   AC_MSG_RESULT([yes])
 510   dnl ARFLAGS is for automake, AR_FLAGS for libtool m-(
 511   ARFLAGS="crD"
 512   AR_FLAGS="crD"
 513 else
 514   AC_MSG_RESULT([no])
 515   ARFLAGS="cru"
 516   AR_FLAGS="cru"
 517 fi
 518 AC_SUBST([ARFLAGS])
 519 AC_SUBST([AR_FLAGS])
 520
 521 AC_MSG_CHECKING([whether $RANLIB supports D option])
 522 if $RANLIB -D conftest.a >conftest.err 2>&1; then
 523   if grep -q -- '-D' conftest.err; then
 524     AC_MSG_RESULT([no])
 525   else
 526     AC_MSG_RESULT([yes])
 527     RANLIB="$RANLIB -D"
 528   fi
 529 else
 530   AC_MSG_RESULT([no])
 531 fi
 532 AC_SUBST([RANLIB])
 533
 534 test -f conftest.err && rm conftest.err
 535 test -f conftest.a && rm conftest.a
 536
 537 dnl ----------------------
 538 dnl Packages configuration
 539 dnl ----------------------
 540 if test -f config.version; then
 541   . ./config.version
 542 elif test -f "${srcdir}/config.version"; then
 543   . "${srcdir}/config.version"
 544 fi
 545 AC_ARG_WITH([pkg-extra-version],
 546   AS_HELP_STRING([--with-pkg-extra-version=VER], [add extra version field, for packagers/distributions]), [
 547   if test "$withval" = "no"; then
 548     EXTRAVERSION=
 549   else
 550     EXTRAVERSION=$withval
 551   fi
 552 ], [])
 553 AC_ARG_WITH([pkg-git-version],
 554         AS_HELP_STRING([--with-pkg-git-version], [add git information to MOTD and build version string]),
 555         [ test "$withval" != "no" && with_pkg_git_version="yes" ])
 556 AC_ARG_WITH([clippy],
 557   AS_HELP_STRING([--with-clippy=PATH], [use external clippy helper program]))
 558 AC_ARG_WITH([vtysh_pager],
 559         AS_HELP_STRING([--with-vtysh-pager=PAGER], [control what pager is compiled in as default]),
 560         VTYSH_PAGER=$withval, VTYSH_PAGER="more")
 561 AC_ARG_ENABLE([vtysh],
 562   AS_HELP_STRING([--disable-vtysh], [do not build integrated vty shell for FRR]))
 563 AC_ARG_ENABLE([doc],
 564   AS_HELP_STRING([--disable-doc], [do not build docs]))
 565 AC_ARG_ENABLE([doc-html],
 566   AS_HELP_STRING([--enable-doc-html], [build HTML docs]))
 567 AC_ARG_ENABLE([zebra],
 568   AS_HELP_STRING([--disable-zebra], [do not build zebra daemon]))
 569 AC_ARG_ENABLE([bgpd],
 570   AS_HELP_STRING([--disable-bgpd], [do not build bgpd]))
 571 AC_ARG_ENABLE([ripd],
 572   AS_HELP_STRING([--disable-ripd], [do not build ripd]))
 573 AC_ARG_ENABLE([ripngd],
 574   AS_HELP_STRING([--disable-ripngd], [do not build ripngd]))
 575 AC_ARG_ENABLE([ospfd],
 576   AS_HELP_STRING([--disable-ospfd], [do not build ospfd]))
 577 AC_ARG_ENABLE([ospf6d],
 578   AS_HELP_STRING([--disable-ospf6d], [do not build ospf6d]))
 579 AC_ARG_ENABLE([ldpd],
 580   AS_HELP_STRING([--disable-ldpd], [do not build ldpd]))
 581 AC_ARG_ENABLE([nhrpd],
 582   AS_HELP_STRING([--disable-nhrpd], [do not build nhrpd]))
 583 AC_ARG_ENABLE([eigrpd],
 584   AS_HELP_STRING([--disable-eigrpd], [do not build eigrpd]))
 585 AC_ARG_ENABLE([babeld],
 586   AS_HELP_STRING([--disable-babeld], [do not build babeld]))
 587 AC_ARG_ENABLE([watchfrr],
 588   AS_HELP_STRING([--disable-watchfrr], [do not build watchfrr]))
 589 AC_ARG_ENABLE([isisd],
 590   AS_HELP_STRING([--disable-isisd], [do not build isisd]))
 591 AC_ARG_ENABLE([pimd],
 592   AS_HELP_STRING([--disable-pimd], [do not build pimd]))
 593 AC_ARG_ENABLE([pbrd],
 594   AS_HELP_STRING([--disable-pbrd], [do not build pbrd]))
 595 AC_ARG_ENABLE([sharpd],
 596   AS_HELP_STRING([--enable-sharpd], [build sharpd]))
 597 AC_ARG_ENABLE([staticd],
 598   AS_HELP_STRING([--disable-staticd], [do not build staticd]))
 599 AC_ARG_ENABLE([fabricd],
 600   AS_HELP_STRING([--disable-fabricd], [do not build fabricd]))
 601 AC_ARG_ENABLE([vrrpd],
 602   AS_HELP_STRING([--disable-vrrpd], [do not build vrrpd]))
 603 AC_ARG_ENABLE([pathd],
 604   AS_HELP_STRING([--disable-pathd], [do not build pathd]))
 605 AC_ARG_ENABLE([bgp-announce],
 606   AS_HELP_STRING([--disable-bgp-announce], [turn off BGP route announcement]))
 607 AC_ARG_ENABLE([bgp-vnc],
 608   AS_HELP_STRING([--disable-bgp-vnc],[turn off BGP VNC support]))
 609 AC_ARG_ENABLE([bgp-bmp],
 610   AS_HELP_STRING([--disable-bgp-bmp],[turn off BGP BMP support]))
 611 AC_ARG_ENABLE([snmp],
 612   AS_HELP_STRING([--enable-snmp], [enable SNMP support for agentx]))
 613 AC_ARG_ENABLE([config_rollbacks],
 614   AS_HELP_STRING([--enable-config-rollbacks], [enable configuration rollbacks (requires sqlite3)]))
 615 AC_ARG_ENABLE([confd],
 616   AS_HELP_STRING([--enable-confd=ARG], [enable confd integration]))
 617 AC_ARG_ENABLE([sysrepo],
 618   AS_HELP_STRING([--enable-sysrepo], [enable sysrepo integration]))
 619 AC_ARG_ENABLE([grpc],
 620   AS_HELP_STRING([--enable-grpc], [enable the gRPC northbound plugin]))
 621 AC_ARG_ENABLE([zeromq],
 622   AS_HELP_STRING([--enable-zeromq], [enable ZeroMQ handler (libfrrzmq)]))
 623 AC_ARG_ENABLE([lttng],
 624   AS_HELP_STRING([--enable-lttng], [enable LTTng tracing]))
 625 AC_ARG_ENABLE([usdt],
 626   AS_HELP_STRING([--enable-usdt], [enable USDT probes]))
 627 AC_ARG_WITH([libpam],
 628   AS_HELP_STRING([--with-libpam], [use libpam for PAM support in vtysh]))
 629 AC_ARG_ENABLE([ospfapi],
 630   AS_HELP_STRING([--disable-ospfapi], [do not build OSPFAPI to access the OSPF LSA Database]))
 631 AC_ARG_ENABLE([ospfclient],
 632   AS_HELP_STRING([--disable-ospfclient], [do not build OSPFAPI client for OSPFAPI,
 633                           (this is the default if --disable-ospfapi is set)]))
 634 AC_ARG_ENABLE([multipath],
 635   AS_HELP_STRING([--enable-multipath=ARG], [enable multipath function, ARG must be digit]))
 636 AC_ARG_ENABLE([user],
 637   AS_HELP_STRING([--enable-user=USER], [user to run FRR suite as (default frr)]))
 638 AC_ARG_ENABLE([group],
 639   AS_HELP_STRING([--enable-group=GROUP], [group to run FRR suite as (default frr)]))
 640 AC_ARG_ENABLE([vty_group],
 641   AS_HELP_STRING([--enable-vty-group=ARG], [set vty sockets to have specified group as owner]))
 642 AC_ARG_ENABLE([configfile_mask],
 643   AS_HELP_STRING([--enable-configfile-mask=ARG], [set mask for config files]))
 644 AC_ARG_ENABLE([logfile_mask],
 645   AS_HELP_STRING([--enable-logfile-mask=ARG], [set mask for log files]))
 646 AC_ARG_ENABLE([shell_access],
 647   AS_HELP_STRING([--enable-shell-access], [Allow users to access shell/telnet/ssh]))
 648 AC_ARG_ENABLE([realms],
 649   AS_HELP_STRING([--enable-realms], [enable REALMS support under Linux]))
 650 AC_ARG_ENABLE([rtadv],
 651   AS_HELP_STRING([--disable-rtadv], [disable IPV6 router advertisement feature]))
 652 AC_ARG_ENABLE([irdp],
 653   AS_HELP_STRING([--disable-irdp], [disable IRDP server support in zebra (enabled by default if supported)]))
 654 AC_ARG_ENABLE([capabilities],
 655   AS_HELP_STRING([--disable-capabilities], [disable using POSIX capabilities]))
 656 AC_ARG_ENABLE([rusage],
 657   AS_HELP_STRING([--disable-rusage], [disable using getrusage]))
 658 AC_ARG_ENABLE([gcc_ultra_verbose],
 659   AS_HELP_STRING([--enable-gcc-ultra-verbose], [enable ultra verbose GCC warnings]))
 660 AC_ARG_ENABLE([backtrace],
 661   AS_HELP_STRING([--disable-backtrace], [disable crash backtraces (default autodetect)]))
 662 AC_ARG_ENABLE([time-check],
 663   AS_HELP_STRING([--disable-time-check], [disable slow thread warning messages]))
 664 AC_ARG_ENABLE([cpu-time],
 665   AS_HELP_STRING([--disable-cpu-time], [disable cpu usage data gathering]))
 666 AC_ARG_ENABLE([pcreposix],
 667   AS_HELP_STRING([--enable-pcreposix], [enable using PCRE Posix libs for regex functions]))
 668 AC_ARG_ENABLE([fpm],
 669   AS_HELP_STRING([--enable-fpm], [enable Forwarding Plane Manager support]))
 670 AC_ARG_ENABLE([pcep],
 671   AS_HELP_STRING([--enable-pcep], [enable PCEP support for pathd]))
 672 AC_ARG_ENABLE([systemd],
 673   AS_HELP_STRING([--enable-systemd], [enable Systemd support]))
 674 AC_ARG_ENABLE([werror],
 675   AS_HELP_STRING([--enable-werror], [enable -Werror (recommended for developers only)]))
 676 AC_ARG_ENABLE([cumulus],
 677   AS_HELP_STRING([--enable-cumulus], [enable Cumulus Switch Special Extensions]))
 678 AC_ARG_ENABLE([datacenter],
 679   AS_HELP_STRING([--enable-datacenter], [enable Compilation for Data Center Extensions]))
 680 AC_ARG_ENABLE([rr-semantics],
 681   AS_HELP_STRING([--disable-rr-semantics], [disable the v6 Route Replace semantics]))
 682 AC_ARG_ENABLE([protobuf],
 683   AS_HELP_STRING([--enable-protobuf], [Enable experimental protobuf support]))
 684 AC_ARG_ENABLE([oldvpn_commands],
 685   AS_HELP_STRING([--enable-oldvpn-commands], [Keep old vpn commands]))
 686 AC_ARG_ENABLE([rpki],
 687   AS_HELP_STRING([--enable-rpki], [enable RPKI prefix validation support]))
 688 AC_ARG_ENABLE([clippy-only],
 689   AS_HELP_STRING([--enable-clippy-only], [Only build clippy]))
 690 AC_ARG_ENABLE([numeric_version],
 691   AS_HELP_STRING([--enable-numeric-version], [Only numeric digits allowed in version (for Alpine)]))
 692 AC_ARG_ENABLE([gcov],
 693   AS_HELP_STRING([--enable-gcov], [Collect coverage information with gcov]))
 694 AC_ARG_ENABLE([clang_coverage],
 695   AS_HELP_STRING([--enable-clang-coverage], [Collect coverage information with Clang Coverage]))
 696 AC_ARG_ENABLE([bfdd],
 697   AS_HELP_STRING([--disable-bfdd], [do not build bfdd]))
 698 AC_ARG_ENABLE([address-sanitizer],
 699   AS_HELP_STRING([--enable-address-sanitizer], [enable AddressSanitizer support for detecting a wide variety of memory allocation and deallocation errors]))
 700 AC_ARG_ENABLE([thread-sanitizer],
 701   AS_HELP_STRING([--enable-thread-sanitizer], [enable ThreadSanitizer support for detecting data races]))
 702 AC_ARG_ENABLE([memory-sanitizer],
 703   AS_HELP_STRING([--enable-memory-sanitizer], [enable MemorySanitizer support for detecting uninitialized memory reads]))
 704 AC_ARG_ENABLE([undefined-sanitizer],
 705   AS_HELP_STRING([--undefined-sanitizer], [enable UndefinedBehaviorSanitizer support for detecting undefined behavior]))
 706 AC_ARG_WITH([crypto],
 707   AS_HELP_STRING([--with-crypto=<internal|openssl>], [choose between different implementations of cryptographic functions(default value is --with-crypto=internal)]))
 708 AC_ARG_WITH([frr-format],
 709   AS_HELP_STRING([--with-frr-format[=<.../frr-format.so>]], [use frr-format GCC plugin]))
 710
 711 AC_ARG_ENABLE([version-build-config],
 712   AS_HELP_STRING([--disable-version-build-config], [do not include build configs in show version command]))
 713
 714 #if openssl, else use the internal
 715 AS_IF([test "$with_crypto" = "openssl"], [
 716 AC_CHECK_LIB([crypto], [EVP_DigestInit], [LIBS="$LIBS -lcrypto"], [], [])
 717 if test "$ac_cv_lib_crypto_EVP_DigestInit" = "no"; then
 718   AC_MSG_ERROR([build with openssl has been specified but openssl library was not found on your system])
 719 else
 720   AC_DEFINE([CRYPTO_OPENSSL], [1], [Compile with openssl support])
 721 fi
 722 ], [test "$with_crypto" = "internal" || test "$with_crypto" = "" ], [AC_DEFINE([CRYPTO_INTERNAL], [1], [Compile with internal cryptographic implementation])
 723 ], [AC_MSG_ERROR([Unknown value for --with-crypto])]
 724 )
 725
 726 AS_IF([test "$enable_clippy_only" != "yes"], [
 727 AC_CHECK_HEADERS([json-c/json.h])
 728 AC_CHECK_LIB([json-c], [json_object_get], [LIBS="$LIBS -ljson-c"], [], [-lm])
 729 if test "$ac_cv_lib_json_c_json_object_get" = "no"; then
 730   AC_CHECK_LIB([json], [json_object_get], [LIBS="$LIBS -ljson"])
 731   if test "$ac_cv_lib_json_json_object_get" = "no"; then
 732       AC_MSG_ERROR([libjson is needed to compile])
 733   fi
 734 fi
 735 ])
 736
 737 AC_ARG_ENABLE([dev_build],
 738     AS_HELP_STRING([--enable-dev-build], [build for development]))
 739
 740 AC_ARG_ENABLE([scripting],
 741     AS_HELP_STRING([--enable-scripting], [Build with scripting support]))
 742
 743 AC_ARG_ENABLE([netlink-debug],
 744   AS_HELP_STRING([--disable-netlink-debug], [pretty print netlink debug messages]))
 745
 746 if test "$enable_netlink_debug" != "no" ; then
 747   AC_DEFINE([NETLINK_DEBUG], [1], [Netlink extra debugging code])
 748 fi
 749
 750 AM_CONDITIONAL([NETLINK_DEBUG], [test "$enable_netlink_debug" != "no"])
 751
 752 if test "$enable_time_check" != "no" ; then
 753   if test "$enable_time_check" = "yes" -o "$enable_time_check" = "" ; then
 754     AC_DEFINE([CONSUMED_TIME_CHECK], [5000000], [Consumed Time Check])
 755   else
 756     AC_DEFINE_UNQUOTED([CONSUMED_TIME_CHECK], [$enable_time_check], [Consumed Time Check])
 757   fi
 758 fi
 759
 760 case "${enable_cpu_time}" in
 761   "no")
 762   AC_DEFINE([EXCLUDE_CPU_TIME], [1], [Exclude getrusage data gathering])
 763   ;;
 764   "*")
 765   ;;
 766 esac
 767
 768 case "${enable_systemd}" in
 769   "no") ;;
 770   "yes")
 771   AC_CHECK_LIB([systemd], [sd_notify], [LIBS="$LIBS -lsystemd"])
 772   if test "$ac_cv_lib_systemd_sd_notify" = "no"; then
 773     AC_MSG_ERROR([enable systemd has been specified but systemd development env not found on your system])
 774   else
 775     AC_DEFINE([HAVE_SYSTEMD], [1], [Compile systemd support in])
 776   fi
 777   ;;
 778   "*") ;;
 779 esac
 780
 781 if test "$enable_rr_semantics" != "no" ; then
 782   AC_DEFINE([HAVE_V6_RR_SEMANTICS], [1], [Compile in v6 Route Replacement Semantics])
 783 fi
 784
 785 if test "$enable_datacenter" = "yes" ; then
 786   AC_DEFINE([HAVE_DATACENTER], [1], [Compile extensions for a DataCenter])
 787   AC_MSG_WARN([The --enable-datacenter compile time option is deprecated.  Please modify the init script to pass -F datacenter to the daemons instead.])
 788   DFLT_NAME="datacenter"
 789 else
 790   DFLT_NAME="traditional"
 791 fi
 792
 793 if test "$enable_cumulus" = "yes" ; then
 794   AC_DEFINE([HAVE_CUMULUS], [1], [Compile Special Cumulus Code in])
 795 fi
 796
 797 AC_SUBST([DFLT_NAME])
 798 AC_DEFINE_UNQUOTED([DFLT_NAME], ["$DFLT_NAME"], [Name of the configuration default set])
 799
 800 if test "$enable_shell_access" = "yes"; then
 801    AC_DEFINE([HAVE_SHELL_ACCESS], [1], [Allow user to use ssh/telnet/bash, be aware this is considered insecure])
 802 fi
 803
 804 #
 805 # Python for clippy
 806 #
 807
 808 AS_IF([test "$host" = "$build"], [
 809   AC_CHECK_HEADER([gelf.h], [], [
 810     AC_MSG_ERROR([libelf headers are required for building clippy.  (Host only when cross-compiling.)])
 811   ])
 812   AC_CHECK_LIB([elf], [elf_memory], [], [
 813     AC_MSG_ERROR([libelf is required for building clippy.  (Host only when cross-compiling.)])
 814   ])
 815
 816   AC_CHECK_LIB([elf], [elf_getdata_rawchunk], [
 817     AC_DEFINE([HAVE_ELF_GETDATA_RAWCHUNK], [1], [Have elf_getdata_rawchunk()])
 818   ])
 819   AC_CHECK_LIB([elf], [gelf_getnote], [
 820     AC_DEFINE([HAVE_GELF_GETNOTE], [1], [Have gelf_getnote()])
 821   ])
 822
 823   FRR_PYTHON_DEV
 824 ], [
 825   FRR_PYTHON
 826 ])
 827
 828 FRR_PYTHON_MODULES([pytest])
 829
 830 if test "$enable_doc" != "no"; then
 831   FRR_PYTHON_MODULES([sphinx], , [
 832     if test "$enable_doc" = "yes"; then
 833       AC_MSG_ERROR([Documentation was explicitly requested with --enable-doc but sphinx is not available for $PYTHON. Please disable docs or install sphinx.])
 834     fi
 835   ])
 836 fi
 837 AM_CONDITIONAL([DOC], [test "$enable_doc" != "no" -a "$frr_py_mod_sphinx" != "false"])
 838 AM_CONDITIONAL([DOC_HTML], [test "$enable_doc_html" = "yes"])
 839
 840 FRR_PYTHON_MOD_EXEC([sphinx], [--version], [
 841   PYSPHINX="-m sphinx"
 842 ], [
 843   PYSPHINX="-c 'import sys; from sphinx import main; sys.exit(main(sys.argv))'"
 844 ])
 845 AC_SUBST([PYSPHINX])
 846
 847 #
 848 # Logic for old vpn commands support.
 849 #
 850 if test "$enable_oldvpn_commands" = "yes"; then
 851    AC_DEFINE([KEEP_OLD_VPN_COMMANDS], [1], [Define for compiling with old vpn commands])
 852 fi
 853
 854 #
 855 # End of logic for protobuf support.
 856 #
 857
 858 AC_MSG_CHECKING([if zebra should be configurable to send Route Advertisements])
 859 if test "$enable_rtadv" != "no"; then
 860   AC_MSG_RESULT([yes])
 861   AC_DEFINE([HAVE_RTADV], [1], [Enable IPv6 Routing Advertisement support])
 862 else
 863   AC_MSG_RESULT([no])
 864 fi
 865
 866 if test "$enable_user" = "no"; then
 867   enable_user=""
 868 else
 869   if test "$enable_user" = "yes" || test "$enable_user" = ""; then
 870     enable_user="frr"
 871   fi
 872   AC_DEFINE_UNQUOTED([FRR_USER], ["${enable_user}"], [frr User])
 873 fi
 874
 875 if test "$enable_group" = "no"; then
 876   enable_group=""
 877 else
 878   if test "$enable_group" = "yes" || test "$enable_group" = ""; then
 879     enable_group="frr"
 880   fi
 881   AC_DEFINE_UNQUOTED([FRR_GROUP], ["${enable_group}"], [frr Group])
 882 fi
 883
 884 if test "$enable_vty_group" = "yes" ; then
 885   AC_MSG_ERROR([--enable-vty-group requires a group as argument, not yes])
 886 elif test "$enable_vty_group" != ""; then
 887   if test "$enable_vty_group" != "no"; then
 888     AC_DEFINE_UNQUOTED([VTY_GROUP], ["${enable_vty_group}"], [VTY Sockets Group])
 889   fi
 890 fi
 891 AC_SUBST([enable_user])
 892 AC_SUBST([enable_group])
 893 AC_SUBST([enable_vty_group])
 894
 895 enable_configfile_mask=${enable_configfile_mask:-0600}
 896 AC_DEFINE_UNQUOTED([CONFIGFILE_MASK], [${enable_configfile_mask}], [Mask for config files])
 897 AC_SUBST([enable_configfile_mask])
 898
 899 enable_logfile_mask=${enable_logfile_mask:-0600}
 900 AC_DEFINE_UNQUOTED([LOGFILE_MASK], [${enable_logfile_mask}], [Mask for log files])
 901
 902 MPATH_NUM=16
 903
 904 case "${enable_multipath}" in
 905   0)
 906     MPATH_NUM=64
 907     ;;
 908   [[1-9]|[1-9][0-9]|[1-9][0-9][0-9]])
 909     MPATH_NUM="${enable_multipath}"
 910     ;;
 911   "")
 912     ;;
 913   *)
 914     AC_MSG_FAILURE([Please specify digit to enable multipath ARG])
 915     ;;
 916 esac
 917
 918 AC_DEFINE_UNQUOTED([MULTIPATH_NUM], [$MPATH_NUM], [Maximum number of paths for a route])
 919
 920 AC_DEFINE_UNQUOTED([VTYSH_PAGER], ["$VTYSH_PAGER"], [What pager to use])
 921
 922 dnl --------------------
 923 dnl Enable code coverage
 924 dnl --------------------
 925 AM_CONDITIONAL([HAVE_GCOV], [test "$enable_gcov" != "no"])
 926
 927 dnl ------------------------------------
 928 dnl Alpine only accepts numeric versions
 929 dnl ------------------------------------
 930 if test "$enable_numeric_version" != "" ; then
 931   VERSION="`echo ${VERSION} | tr -c -d '[[.0-9]]'`"
 932   PACKAGE_VERSION="`echo ${PACKAGE_VERSION} | tr -c -d '[[.0-9]]'`"
 933 fi
 934
 935 dnl -----------------------------------
 936 dnl Add extra version string to package
 937 dnl name, string and version fields.
 938 dnl -----------------------------------
 939 if test "$EXTRAVERSION" != "" ; then
 940   VERSION="${VERSION}${EXTRAVERSION}"
 941   PACKAGE_VERSION="${PACKAGE_VERSION}${EXTRAVERSION}"
 942   AC_SUBST(PACKAGE_EXTRAVERSION, ["${EXTRAVERSION}"])
 943   PACKAGE_STRING="${PACKAGE_STRING}${EXTRAVERSION}"
 944 fi
 945 AC_SUBST([EXTRAVERSION])
 946
 947 if test "$with_pkg_git_version" = "yes"; then
 948         if test -e "${srcdir}/.git"; then
 949                 AC_DEFINE([GIT_VERSION], [1], [include git version info])
 950         else    with_pkg_git_version="no"
 951                 AC_MSG_WARN([--with-pkg-git-version given, but this is not a git checkout])
 952         fi
 953 fi
 954 AM_CONDITIONAL([GIT_VERSION], [test "$with_pkg_git_version" = "yes"])
 955
 956 AC_CHECK_TOOL([OBJCOPY], [objcopy], [:])
 957 if test "$OBJCOPY" != ":"; then
 958   AC_CACHE_CHECK([for .interp value to use], [frr_cv_interp], [
 959     frr_cv_interp=""
 960     AC_LINK_IFELSE([AC_LANG_SOURCE([[int main() { return 0; }]])], [
 961       if $OBJCOPY -j.interp -Obinary conftest conftest.interp; then
 962         frr_cv_interp="`xargs -0 echo < conftest.interp`"
 963       fi
 964       test -f conftest.interp && rm conftest.interp
 965     ])
 966   ])
 967 fi
 968 if test -n "$frr_cv_interp"; then
 969   AC_DEFINE_UNQUOTED([INTERP], ["$frr_cv_interp"], [.interp value])
 970 fi
 971
 972 dnl -------------------------
 973 dnl Check other header files.
 974 dnl -------------------------
 975 AC_CHECK_HEADERS([stropts.h sys/ksym.h \
 976         linux/version.h asm/types.h])
 977
 978 ac_stdatomic_ok=false
 979 AC_DEFINE([FRR_AUTOCONF_ATOMIC], [1], [did autoconf checks for atomic funcs])
 980 AC_CHECK_HEADER([stdatomic.h],[
 981
 982   AC_MSG_CHECKING([whether _Atomic qualifier works])
 983   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 984 #include <stdatomic.h>
 985 int main(int argc, char **argv) {
 986   _Atomic int i = 0;
 987   return i;
 988 }
 989 ]])], [
 990     AC_DEFINE([HAVE_STDATOMIC_H], [1], [found stdatomic.h])
 991     AC_MSG_RESULT([yes])
 992     ac_stdatomic_ok=true
 993   ], [
 994     AC_MSG_RESULT([no])
 995   ])
 996 ])
 997
 998 AS_IF([$ac_stdatomic_ok], [true], [
 999   AC_MSG_CHECKING([for __atomic_* builtins])
1000   AC_LINK_IFELSE([AC_LANG_SOURCE([[
1001 int main(int argc, char **argv) {
1002   volatile int i = 1;
1003   __atomic_store_n (&i, 0, __ATOMIC_RELEASE);
1004   return __atomic_load_n (&i, __ATOMIC_ACQUIRE);
1005 }
1006 ]])], [
1007     AC_DEFINE([HAVE___ATOMIC], [1], [found __atomic builtins])
1008     AC_MSG_RESULT([yes])
1009   ], [
1010     AC_MSG_RESULT([no])
1011
1012     dnl FreeBSD 9 has a broken stdatomic.h where _Atomic doesn't work
1013     AC_MSG_CHECKING([for __sync_* builtins])
1014     AC_LINK_IFELSE([AC_LANG_SOURCE([[
1015 int main(int argc, char **argv) {
1016   volatile int i = 1;
1017   __sync_fetch_and_sub (&i, 1);
1018   return __sync_val_compare_and_swap (&i, 0, 1);
1019 }
1020 ]])], [
1021       AC_DEFINE([HAVE___SYNC], [1], [found __sync builtins])
1022       AC_MSG_RESULT([yes])
1023
1024       AC_MSG_CHECKING([for __sync_swap builtin])
1025       AC_LINK_IFELSE([AC_LANG_SOURCE([[
1026 int main(int argc, char **argv) {
1027   volatile int i = 1;
1028   return __sync_swap (&i, 2);
1029 }
1030 ]])], [
1031         AC_DEFINE([HAVE___SYNC_SWAP], 1, [found __sync_swap builtin])
1032         AC_MSG_RESULT([yes])
1033       ], [
1034         AC_MSG_RESULT([no])
1035       ])
1036
1037     ], [
1038       AC_MSG_RESULT([no])
1039       AC_MSG_FAILURE([stdatomic.h unavailable and $CC has neither __atomic nor __sync builtins])
1040     ])
1041   ])
1042 ])
1043
1044 AC_CHECK_HEADERS([pthread_np.h],,, [
1045 #include <pthread.h>
1046 ])
1047 AC_CHECK_FUNCS([pthread_setname_np pthread_set_name_np pthread_getthreadid_np])
1048
1049 needsync=true
1050
1051 AS_IF([$needsync], [
1052   dnl Linux
1053   AC_MSG_CHECKING([for Linux futex() support])
1054   AC_LINK_IFELSE([AC_LANG_PROGRAM([
1055 #ifndef _GNU_SOURCE
1056 #define _GNU_SOURCE
1057 #endif
1058 #include <unistd.h>
1059 #include <limits.h>
1060 #include <sys/time.h>
1061 #include <sys/syscall.h>
1062 #include <linux/futex.h>
1063
1064 int main(void);
1065 ],
1066 [
1067 {
1068   return syscall(SYS_futex, NULL, FUTEX_WAIT, 0, NULL, NULL, 0);
1069 }
1070 ])], [
1071     AC_MSG_RESULT([yes])
1072     AC_DEFINE(HAVE_SYNC_LINUX_FUTEX,,Have Linux futex support)
1073     needsync=false
1074   ], [
1075     AC_MSG_RESULT([no])
1076   ])
1077 ])
1078
1079 AS_IF([$needsync], [
1080   dnl FreeBSD
1081   AC_MSG_CHECKING([for FreeBSD _umtx_op() support])
1082   AC_LINK_IFELSE([AC_LANG_PROGRAM([
1083 #include <errno.h>
1084 #include <stdlib.h>
1085 #include <sys/types.h>
1086 #include <sys/umtx.h>
1087 int main(void);
1088 ],
1089 [
1090 {
1091   return _umtx_op(NULL, UMTX_OP_WAIT_UINT, 0, NULL, NULL);
1092 }
1093 ])], [
1094     AC_MSG_RESULT([yes])
1095     AC_DEFINE(HAVE_SYNC_UMTX_OP,,Have FreeBSD _umtx_op() support)
1096     needsync=false
1097   ], [
1098     AC_MSG_RESULT([no])
1099   ])
1100 ])
1101
1102 AS_IF([$needsync], [
1103   dnl OpenBSD patch (not upstream at the time of writing this)
1104   dnl https://marc.info/?l=openbsd-tech&m=147299508409549&w=2
1105   AC_MSG_CHECKING([for OpenBSD futex() support])
1106   AC_LINK_IFELSE([AC_LANG_PROGRAM([
1107 #include <sys/futex.h>
1108 int main(void);
1109 ],
1110 [
1111 {
1112   return futex(NULL, FUTEX_WAIT, 0, NULL, NULL, 0);
1113 }
1114 ])], [
1115     AC_MSG_RESULT([yes])
1116     AC_DEFINE(HAVE_SYNC_OPENBSD_FUTEX,,Have OpenBSD futex support)
1117     needsync=false
1118   ], [
1119     AC_MSG_RESULT([no])
1120   ])
1121 ])
1122
1123 dnl Utility macro to avoid retyping includes all the time
1124 m4_define([FRR_INCLUDES],
1125 [#ifdef SUNOS_5
1126 #define _POSIX_C_SOURCE 200809L
1127 #define __EXTENSIONS__
1128 #endif
1129 #include <stdio.h>
1130 #include <stdlib.h>
1131 #include <stddef.h>
1132 #include <sys/types.h>
1133 /* sys/conf.h depends on param.h on FBSD at least */
1134 #include <sys/param.h>
1135 /* Required for MAXSIG */
1136 #include <signal.h>
1137 #include <sys/socket.h>
1138 #ifdef __APPLE__
1139 # define __APPLE_USE_RFC_3542
1140 #endif
1141 #include <netinet/in.h>
1142 #include <sys/time.h>
1143 #include <time.h>
1144 #include <net/if.h>
1145 ])dnl
1146
1147 dnl Same applies for HAVE_NET_IF_VAR_H, which HAVE_NETINET6_ND6_H and
1148 dnl HAVE_NETINET_IN_VAR_H depend upon. But if_var.h depends on if.h, hence
1149 dnl an additional round for it.
1150
1151 AC_CHECK_HEADERS([net/if_var.h], [], [], [FRR_INCLUDES])
1152
1153 m4_define([FRR_INCLUDES],
1154 FRR_INCLUDES
1155 [#ifdef HAVE_NET_IF_VAR_H
1156 # include <net/if_var.h>
1157 #endif
1158 ])dnl
1159
1160 AC_CHECK_HEADERS([netinet/in_var.h \
1161         net/if_dl.h net/netopt.h \
1162         inet/nd.h netinet/ip_icmp.h \
1163         sys/sysctl.h sys/sockio.h sys/conf.h],
1164         [], [], [FRR_INCLUDES])
1165
1166 AC_CHECK_HEADERS([ucontext.h], [], [],
1167 [#ifndef __USE_GNU
1168 #define __USE_GNU
1169 #endif /* __USE_GNU */
1170 FRR_INCLUDES
1171 ])
1172
1173 m4_define([UCONTEXT_INCLUDES],
1174 [#include <ucontext.h>])dnl
1175
1176 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.uc_regs],
1177   [], [], [UCONTEXT_INCLUDES])
1178 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs],
1179   [AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs.nip],
1180    [], [], [UCONTEXT_INCLUDES])],
1181   [], [UCONTEXT_INCLUDES])
1182 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.gregs],
1183   [], [], [UCONTEXT_INCLUDES])
1184
1185 m4_define([FRR_INCLUDES],
1186 FRR_INCLUDES
1187 [
1188 #include <sys/un.h>
1189 #include <netinet/in_systm.h>
1190 #ifdef HAVE_NETINET_IN_VAR_H
1191 # include <netinet/in_var.h>
1192 #endif
1193 #ifdef HAVE_NET_IF_DL_H
1194 # include <net/if_dl.h>
1195 #endif
1196 #ifdef HAVE_NET_NETOPT_H
1197 # include <net/netopt.h>
1198 #endif
1199 #include <net/route.h>
1200 #ifdef HAVE_INET_ND_H
1201 # include <inet/nd.h>
1202 #endif
1203 #include <arpa/inet.h>
1204 /* Required for IDRP */
1205 #ifdef HAVE_NETINET_IP_ICMP_H
1206 # include <netinet/ip_icmp.h>
1207 #endif
1208 ])dnl
1209
1210 dnl V6 headers are checked below, after we check for v6
1211
1212 is_linux=false
1213
1214 AC_MSG_CHECKING([which operating system interface to use])
1215 case "$host_os" in
1216   sunos* | solaris2*)
1217     AC_MSG_FAILURE([Solaris support has been removed please see versions prior or equal to 7.5])
1218     ;;
1219   linux*)
1220     AC_MSG_RESULT([Linux])
1221
1222     AC_DEFINE([GNU_LINUX], [1], [GNU Linux])
1223     AC_DEFINE([HAVE_NETLINK], [1], [netlink])
1224     AC_DEFINE([LINUX_IPV6], [1], [Linux IPv6 stack])
1225
1226     dnl Linux has a compilation problem with mixing
1227     dnl netinet/in.h and linux/in6.h they are not
1228     dnl compatible.  There has been discussion on
1229     dnl how to fix it but no real progress on implementation
1230     dnl when they fix it, remove this
1231     AC_DEFINE([IPV6_MINHOPCOUNT], [73], [Linux ipv6 Min Hop Count])
1232
1233     is_linux=true
1234     ;;
1235   openbsd*)
1236     AC_MSG_RESULT([OpenBSD])
1237
1238     AC_DEFINE([OPEN_BSD], [1], [OpenBSD])
1239     AC_DEFINE([KAME], [1], [KAME IPv6])
1240     AC_DEFINE([BSD_V6_SYSCTL], [1], [BSD v6 sysctl to turn on and off forwarding])
1241     ;;
1242   *)
1243     AC_MSG_RESULT([BSD])
1244
1245     AC_DEFINE([HAVE_NET_RT_IFLIST], [1], [NET_RT_IFLIST])
1246     AC_DEFINE([KAME], [1], [KAME IPv6])
1247     AC_DEFINE([BSD_V6_SYSCTL], [1], [BSD v6 sysctl to turn on and off forwarding])
1248     ;;
1249 esac
1250 AM_CONDITIONAL([LINUX], [${is_linux}])
1251
1252 AC_SYS_LARGEFILE
1253
1254 dnl ------------------------
1255 dnl Integrated REALMS option
1256 dnl ------------------------
1257 if test "$enable_realms" = "yes"; then
1258     case "$host_os" in
1259       linux*)
1260        AC_DEFINE([SUPPORT_REALMS], [1], [Realms support])
1261        ;;
1262       *)
1263        echo "Sorry, only Linux has REALMS support"
1264        exit 1
1265        ;;
1266     esac
1267 fi
1268
1269 dnl -------------------------------
1270 dnl Endian-ness check
1271 dnl -------------------------------
1272 AC_WORDS_BIGENDIAN
1273
1274 dnl ---------------
1275 dnl other functions
1276 dnl ---------------
1277 AC_CHECK_FUNCS([ \
1278         strlcat strlcpy \
1279         getgrouplist \
1280         openat \
1281         unlinkat \
1282         posix_fallocate \
1283         ])
1284
1285 dnl ##########################################################################
1286 dnl LARGE if block spans a lot of "configure"!
1287 if test "$enable_clippy_only" != "yes"; then
1288 dnl ##########################################################################
1289
1290 #
1291 # Logic for protobuf support.
1292 #
1293 PROTO3=false
1294 if test "$enable_protobuf" = "yes"; then
1295   # Check for protoc & protoc-c
1296
1297   # protoc is not required, it's only for a "be nice" helper target
1298   AC_CHECK_PROGS([PROTOC], [protoc], [/bin/false])
1299
1300   AC_CHECK_PROGS([PROTOC_C], [protoc-c], [/bin/false])
1301   if test "$PROTOC_C" = "/bin/false"; then
1302     AC_MSG_FAILURE([protobuf requested but protoc-c not found.  Install protobuf-c.])
1303   fi
1304
1305   PKG_CHECK_MODULES([PROTOBUF_C], [libprotobuf-c >= 0.14],, [
1306     AC_MSG_FAILURE([protobuf requested but libprotobuf-c not found.  Install protobuf-c.])
1307   ])
1308
1309   PROTO3=true
1310   AC_CHECK_HEADER([google/protobuf-c/protobuf-c.h],
1311                   [AC_CHECK_DECLS(PROTOBUF_C_LABEL_NONE,
1312                                   AC_DEFINE([HAVE_PROTOBUF_VERSION_3],
1313                                             [1], [Have Protobuf version 3]),
1314                                   [PROTO3=false],
1315                                   [#include <google/protobuf-c/protobuf-c.h>])],
1316                   [PROTO3=false && AC_MSG_FAILURE([protobuf requested but protobuf-c.h not found.  Install protobuf-c.])])
1317
1318   AC_DEFINE([HAVE_PROTOBUF], [1], [protobuf])
1319 fi
1320
1321
1322 dnl ---------------------
1323 dnl Integrated VTY option
1324 dnl ---------------------
1325 case "${enable_vtysh}" in
1326 "no")
1327   VTYSH="";;
1328 *)
1329   VTYSH="vtysh";
1330   AC_DEFINE([VTYSH], [1], [VTY shell])
1331
1332   prev_libs="$LIBS"
1333   AC_CHECK_LIB([readline], [main], [
1334     LIBREADLINE="-lreadline"
1335   ], [
1336     dnl readline failed - it might be incorrectly linked and missing its
1337     dnl termcap/tinfo/curses dependency.  see if we can fix that...
1338     AC_SEARCH_LIBS([tputs], [termcap tinfo curses ncurses], [
1339       LIBREADLINE="$ac_cv_search_tputs"
1340     ], [
1341       AC_MSG_ERROR([libreadline (needed for vtysh) not found and/or missing dependencies])
1342     ])
1343
1344     dnl re-try with the lib we found above
1345     unset ac_cv_lib_readline_main
1346     AC_CHECK_LIB([readline], [main], [
1347       LIBREADLINE="-lreadline $LIBREADLINE"
1348     ], [
1349       AC_MSG_ERROR([libreadline (needed for vtysh) not found and/or missing dependencies])
1350     ], [$LIBREADLINE])
1351   ], [])
1352   LIBS="$prev_libs"
1353
1354   AC_CHECK_HEADER([readline/history.h])
1355   if test "$ac_cv_header_readline_history_h" = "no"; then
1356     AC_MSG_ERROR([readline is too old to have readline/history.h, please update to the latest readline library.])
1357   fi
1358   AC_CHECK_LIB([readline], [rl_completion_matches], [true], [], [$LIBREADLINE])
1359   if test "$ac_cv_lib_readline_rl_completion_matches" = "no"; then
1360     AC_DEFINE([rl_completion_matches], [completion_matches], [Old readline])
1361   fi
1362   AC_CHECK_LIB([readline], [append_history], [frr_cv_append_history=yes], [frr_cv_append_history=no], [$LIBREADLINE])
1363   if test "$frr_cv_append_history" = "yes"; then
1364     AC_DEFINE([HAVE_APPEND_HISTORY], [1], [Have history.h append_history])
1365   fi
1366   ;;
1367 esac
1368 AC_SUBST([LIBREADLINE])
1369
1370 dnl ----------
1371 dnl PAM module
1372 dnl
1373 dnl FRR detects the PAM library it is built against by checking for a
1374 dnl functional pam_misc.h (Linux-PAM) or openpam.h (OpenPAM) header. pam_misc.h
1375 dnl is known to #include pam_appl.h, the standard header of a PAM library, and
1376 dnl openpam.h doesn't do that, although depends on the header too. Hence a
1377 dnl little assistance to AC_CHECK_HEADER is necessary for the proper detection
1378 dnl of OpenPAM.
1379 dnl ----------
1380 if test "$with_libpam" = "yes"; then
1381   AC_CHECK_HEADER([security/pam_misc.h],
1382     [AC_DEFINE([HAVE_PAM_MISC_H], [1], [Have pam_misc.h])
1383      AC_DEFINE([PAM_CONV_FUNC], [misc_conv], [Have misc_conv])
1384      pam_conv_func="misc_conv"
1385     ],
1386     [], FRR_INCLUDES)
1387   AC_CHECK_HEADER([security/openpam.h],
1388     [AC_DEFINE([HAVE_OPENPAM_H], [1], [Have openpam.h])
1389      AC_DEFINE([PAM_CONV_FUNC], [openpam_ttyconv], [Have openpam_ttyconv])
1390      pam_conv_func="openpam_ttyconv"
1391     ],
1392     [], FRR_INCLUDES[#include <security/pam_appl.h>])
1393   if test -z "$ac_cv_header_security_pam_misc_h$ac_cv_header_security_openpam_h" ; then
1394     AC_MSG_WARN([*** pam support will not be built ***])
1395     with_libpam="no"
1396   fi
1397 fi
1398
1399 if test "$with_libpam" = "yes"; then
1400 dnl took this test from proftpds configure.in and suited to our needs
1401 dnl -------------------------------------------------------------------------
1402 dnl
1403 dnl This next check looks funky due to a linker problem with some versions
1404 dnl of the PAM library.  Prior to 0.72 release, the Linux PAM shared library
1405 dnl omitted requiring libdl linking information. PAM-0.72 or better ships
1406 dnl with RedHat 6.2 and Debian 2.2 or better.
1407 AC_CHECK_LIB([pam], [pam_start],
1408   [AC_CHECK_LIB([pam], [$pam_conv_func],
1409     [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1410      LIBPAM="-lpam"],
1411     [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1412      LIBPAM="-lpam -lpam_misc"]
1413     )
1414   ],
1415
1416   [AC_CHECK_LIB([pam], [pam_end],
1417     [AC_CHECK_LIB([pam], [$pam_conv_func],
1418       [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1419        LIBPAM="-lpam -ldl"],
1420       [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1421        LIBPAM="-lpam -ldl -lpam_misc"]
1422      )
1423   ],AC_MSG_WARN([*** pam support will not be built ***]),
1424   [-ldl])
1425   ]
1426 )
1427 fi
1428 AC_SUBST([LIBPAM])
1429
1430 dnl -------------------------------
1431 dnl bgpd needs pow() and hence libm
1432 dnl -------------------------------
1433 TMPLIBS="$LIBS"
1434 LIBS=""
1435 AC_SEARCH_LIBS([pow], [m], [
1436   LIBM="$LIBS"
1437 ], [
1438   AC_MSG_WARN([Unable to find working pow function - bgpd may not link])
1439 ])
1440 LIBS="$TMPLIBS"
1441 AC_SUBST([LIBM])
1442
1443 AC_CHECK_FUNCS([ppoll], [
1444   AC_DEFINE([HAVE_PPOLL], [1], [have Linux/BSD ppoll()])
1445 ])
1446 AC_CHECK_FUNCS([pollts], [
1447   AC_DEFINE([HAVE_POLLTS], [1], [have NetBSD pollts()])
1448 ])
1449
1450 AC_CHECK_HEADER([asm-generic/unistd.h],
1451                 [AC_CHECK_DECL(__NR_setns,
1452                                AC_DEFINE([HAVE_NETNS], [1], [Have netns]),,
1453                                FRR_INCLUDES [#include <asm-generic/unistd.h>
1454                                ])
1455                  AC_CHECK_FUNCS([setns])]
1456                )
1457
1458 dnl --------------------------
1459 dnl Determine IS-IS I/O method
1460 dnl --------------------------
1461 AC_DEFINE([ISIS_METHOD_PFPACKET], [1], [constant value for isis method pfpacket])
1462 AC_DEFINE([ISIS_METHOD_DLPI], [2], [constant value for isis method dlpi])
1463 AC_DEFINE([ISIS_METHOD_BPF], [3], [constant value for isis method bpf])
1464 AC_CHECK_HEADER([net/bpf.h])
1465 AC_CHECK_HEADER([sys/dlpi.h])
1466 AC_MSG_CHECKING([zebra IS-IS I/O method])
1467
1468 case "$host_os" in
1469   linux*)
1470     AC_MSG_RESULT([pfpacket])
1471     ISIS_METHOD_MACRO="ISIS_METHOD_PFPACKET"
1472     ;;
1473   *)
1474     if test "$ac_cv_header_net_bpf_h" = "no"; then
1475       if test "$ac_cv_header_sys_dlpi_h" = "no"; then
1476         AC_MSG_RESULT([none])
1477         if test "$enable_isisd" = "yes" -o "$enable_fabricd" = "yes"; then
1478           AC_MSG_FAILURE([IS-IS support requested but no packet backend found])
1479         fi
1480         AC_MSG_WARN([*** IS-IS support will not be built ***])
1481         enable_isisd="no"
1482         enable_fabricd="no"
1483       else
1484         AC_MSG_RESULT([DLPI])
1485       fi
1486       ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1487     else
1488       AC_MSG_RESULT([BPF])
1489       ISIS_METHOD_MACRO="ISIS_METHOD_BPF"
1490     fi
1491     ;;
1492 esac
1493 AC_DEFINE_UNQUOTED([ISIS_METHOD], [$ISIS_METHOD_MACRO], [selected method for isis, == one of the constants])
1494
1495 dnl ---------------------------------------------------------------
1496 dnl figure out how to specify an interface in multicast sockets API
1497 dnl ---------------------------------------------------------------
1498 AC_CHECK_MEMBERS([struct ip_mreqn.imr_ifindex], [], [], FRR_INCLUDES)
1499
1500 AC_CHECK_HEADERS([linux/mroute.h], [], [],[
1501         #include <sys/socket.h>
1502         #include <netinet/in.h>
1503         #define _LINUX_IN_H             /* For Linux <= 2.6.25 */
1504         #include <linux/types.h>
1505 ])
1506
1507 m4_define([FRR_INCLUDES],
1508 FRR_INCLUDES
1509 [#ifdef HAVE_LINUX_MROUTE_H
1510 # include <linux/mroute.h>
1511 #endif
1512 ])dnl
1513
1514 AC_CHECK_HEADERS([netinet/ip_mroute.h], [], [],[
1515         #include <sys/socket.h>
1516         #include <sys/types.h>
1517         #include <netinet/in.h>
1518         #include <net/route.h>
1519 ])
1520
1521 m4_define([FRR_INCLUDES],
1522 FRR_INCLUDES
1523 [#ifdef HAVE_NETINET_IP_MROUTE_H
1524 # include <netinet/ip_mroute.h>
1525 #endif
1526 ])dnl
1527
1528 AC_MSG_CHECKING([for BSD struct ip_mreq hack])
1529 AC_TRY_COMPILE([#include <sys/param.h>],
1530 [#if (defined(__FreeBSD__) && ((__FreeBSD_version >= 500022 && __FreeBSD_version < 700000) || (__FreeBSD_version < 500000 && __FreeBSD_version >= 440000))) || (defined(__NetBSD__) && defined(__NetBSD_Version__) && __NetBSD_Version__ >= 106010000) || defined(__OpenBSD__) || defined(__APPLE__) || defined(__DragonFly__) || defined(__sun)
1531   return (0);
1532 #else
1533   #error No support for BSD struct ip_mreq hack detected
1534 #endif],[AC_MSG_RESULT([yes])
1535 AC_DEFINE([HAVE_BSD_STRUCT_IP_MREQ_HACK], [1], [Can pass ifindex in struct ip_mreq])],
1536 AC_MSG_RESULT([no]))
1537
1538 AC_MSG_CHECKING([for RFC3678 protocol-independed API])
1539 AC_TRY_COMPILE([
1540 #include <sys/types.h>
1541 #include <netinet/in.h>
1542 ], [struct group_req gr; int sock; setsockopt(sock, IPPROTO_IP, MCAST_JOIN_GROUP, (void*)&gr, sizeof(gr));
1543 ], [AC_MSG_RESULT([yes])
1544 AC_DEFINE([HAVE_RFC3678], [1], [Have RFC3678 protocol-independed API])],
1545 AC_MSG_RESULT([no]))
1546
1547 dnl ---------------------------------------------------------------
1548 dnl figure out how to check link-state
1549 dnl ---------------------------------------------------------------
1550 AC_CHECK_HEADER([net/if_media.h],
1551   [m4_define([LINK_DETECT_INCLUDES],
1552     FRR_INCLUDES
1553     [#include <net/if_media.h>
1554   ])
1555   AC_CHECK_MEMBERS([struct ifmediareq.ifm_status],
1556     AC_DEFINE([HAVE_BSD_LINK_DETECT], [1], [BSD link-detect]),
1557     [], LINK_DETECT_INCLUDES)],
1558   [],
1559   FRR_INCLUDES)
1560
1561 dnl ---------------------------------------------------------------
1562 dnl Additional, newer way to check link-state using ifi_link_state.
1563 dnl Not available in all BSD's when ifmediareq available
1564 dnl ---------------------------------------------------------------
1565 AC_CHECK_MEMBERS([struct if_data.ifi_link_state],
1566   AC_DEFINE([HAVE_BSD_IFI_LINK_STATE], [1], [BSD ifi_link_state available]),
1567   [], FRR_INCLUDES)
1568
1569 dnl ------------------------
1570 dnl TCP_MD5SIG socket option
1571 dnl ------------------------
1572
1573 AC_CHECK_HEADER([netinet/tcp.h],
1574    [m4_define([MD5_INCLUDES],
1575       FRR_INCLUDES
1576       [#include <netinet/tcp.h>
1577     ])
1578     AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)],
1579    [],
1580    FRR_INCLUDES)
1581 if test "$ac_cv_have_decl_TCP_MD5SIG" = "no"; then
1582   AC_CHECK_HEADER([linux/tcp.h],
1583        [m4_define([MD5_INCLUDES],
1584           FRR_INCLUDES
1585           [#include <linux/tcp.h>
1586         ])
1587        AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)])
1588 fi
1589
1590 AC_CHECK_LIB([crypt], [crypt], [],
1591                     [AC_CHECK_LIB([crypto], [DES_crypt])])
1592 AC_CHECK_LIB([resolv], [res_init])
1593
1594 dnl ---------------------------
1595 dnl check system has PCRE regexp
1596 dnl ---------------------------
1597 if test "$enable_pcreposix" = "yes"; then
1598   AC_CHECK_LIB([pcreposix], [regexec], [], [
1599     AC_MSG_ERROR([--enable-pcreposix given but unable to find libpcreposix])
1600   ])
1601 fi
1602 AC_SUBST([HAVE_LIBPCREPOSIX])
1603
1604 dnl ##########################################################################
1605 dnl test "$enable_clippy_only" != "yes"
1606 fi
1607 dnl END OF LARGE if block
1608 dnl ##########################################################################
1609
1610 dnl ------------------
1611 dnl check C-Ares library
1612 dnl ------------------
1613 PKG_CHECK_MODULES([CARES], [libcares], [
1614   c_ares_found=true
1615 ],[
1616   c_ares_found=false
1617 ])
1618 AM_CONDITIONAL([CARES], [$c_ares_found])
1619
1620
1621 dnl ----------------------------------------------------------------------------
1622 dnl figure out if domainname is available in the utsname struct (GNU extension).
1623 dnl ----------------------------------------------------------------------------
1624 AC_CHECK_MEMBERS([struct utsname.domainname], [], [], [#include <sys/utsname.h>])
1625
1626 dnl ------------------
1627 dnl IPv6 header checks
1628 dnl ------------------
1629 AC_CHECK_HEADERS([netinet6/in6.h netinet/in6_var.h \
1630         netinet6/in6_var.h netinet6/nd6.h], [], [],
1631         FRR_INCLUDES)
1632
1633 m4_define([FRR_INCLUDES],dnl
1634 FRR_INCLUDES
1635 [#ifdef HAVE_NETINET6_IN6_H
1636 #include <netinet6/in6.h>
1637 #endif
1638 #ifdef HAVE_NETINET_IN6_VAR_H
1639 #include <netinet/in6_var.h>
1640 #endif
1641 #include <netinet/icmp6.h>
1642 #ifdef HAVE_NETINET6_IN6_VAR_H
1643 # include <netinet6/in6_var.h>
1644 #endif
1645 #ifdef HAVE_NETINET6_ND6_H
1646 # include <netinet6/nd6.h>
1647 #endif
1648 ])dnl
1649
1650 dnl --------------------
1651 dnl Daemon disable check
1652 dnl --------------------
1653
1654 AS_IF([test "$enable_bgpd" != "no"], [
1655   AC_DEFINE([HAVE_BGPD], [1], [bgpd])
1656 ])
1657
1658 AS_IF([test "$enable_ripd" != "no"], [
1659   AC_DEFINE([HAVE_RIPD], [1], [ripd])
1660 ])
1661
1662 AS_IF([test "$enable_ripngd" != "no"], [
1663   AC_DEFINE([HAVE_RIPNGD], [1], [ripngd])
1664 ])
1665
1666 AS_IF([test "$enable_ospfd" != "no"], [
1667   AC_DEFINE([HAVE_OSPFD], [1], [ospfd])
1668 ])
1669
1670 AS_IF([test "$enable_ospf6d" != "no"], [
1671   AC_DEFINE([HAVE_OSPF6D], [1], [ospf6d])
1672 ])
1673
1674 AS_IF([test "$enable_ldpd" != "no"], [
1675   AC_DEFINE([HAVE_LDPD], [1], [ldpd])
1676 ])
1677
1678 AS_IF([test "$enable_nhrpd" != "no"], [
1679   AC_DEFINE([HAVE_NHRPD], [1], [nhrpd])
1680 ])
1681
1682 AS_IF([test "$enable_eigrpd" != "no"], [
1683   AC_DEFINE([HAVE_EIGRPD], [1], [eigrpd])
1684 ])
1685
1686 AS_IF([test "$enable_babeld" != "no"], [
1687   AC_DEFINE([HAVE_BABELD], [1], [babeld])
1688 ])
1689
1690 AS_IF([test "$enable_isisd" != "no"], [
1691   AC_DEFINE([HAVE_ISISD], [1], [isisd])
1692 ])
1693
1694 AS_IF([test "$enable_pimd" != "no"], [
1695   AC_DEFINE([HAVE_PIMD], [1], [pimd])
1696 ])
1697
1698 AS_IF([test "$enable_pbrd" != "no"], [
1699   AC_DEFINE([HAVE_PBRD], [1], [pbrd])
1700 ])
1701
1702 AS_IF([test "$enable_sharpd" = "yes"], [
1703   AC_DEFINE([HAVE_SHARPD], [1], [sharpd])
1704 ])
1705
1706 AS_IF([test "$enable_staticd" != "no"], [
1707   AC_DEFINE([HAVE_STATICD], [1], [staticd])
1708 ])
1709
1710 AS_IF([test "$enable_fabricd" != "no"], [
1711   AC_DEFINE([HAVE_FABRICD], [1], [fabricd])
1712 ])
1713
1714 AS_IF([test "$enable_vrrpd" != "no"], [
1715   AC_DEFINE([HAVE_VRRPD], [1], [vrrpd])
1716 ])
1717
1718 if test "$enable_bfdd" = "no"; then
1719   AC_DEFINE([HAVE_BFDD], [0], [bfdd])
1720   BFDD=""
1721 else
1722   AC_DEFINE([HAVE_BFDD], [1], [bfdd])
1723   BFDD="bfdd"
1724
1725   case $host_os in
1726     linux*)
1727       AC_DEFINE([BFD_LINUX], [1], [bfdd])
1728       ;;
1729
1730     *)
1731       AC_DEFINE([BFD_BSD], [1], [bfdd])
1732       ;;
1733   esac
1734 fi
1735
1736 AS_IF([test "$enable_pathd" != "no"], [
1737   AC_DEFINE([HAVE_PATHD], [1], [pathd])
1738   AC_DEFINE([HAVE_PATHD_PCEP], [1], [pathd-pcep])
1739 ])
1740
1741
1742 if test "$ac_cv_lib_json_c_json_object_get" = "no" -a "$BFDD" = "bfdd"; then
1743   AC_MSG_ERROR(["you must use json-c library to use bfdd"])
1744 fi
1745
1746 NHRPD=""
1747 case "$host_os" in
1748   linux*)
1749     case "${enable_nhrpd}" in
1750       no)
1751         ;;
1752       yes)
1753         if test "$enable_clippy_only" != "yes"; then
1754         if test "$c_ares_found" != "true" ; then
1755           AC_MSG_ERROR([nhrpd requires libcares.  Please install c-ares and its -dev headers.])
1756         fi
1757         fi
1758         NHRPD="nhrpd"
1759         ;;
1760       *)
1761         if test "$c_ares_found" = "true" ; then
1762           NHRPD="nhrpd"
1763         fi
1764         ;;
1765     esac
1766     ;;
1767   *)
1768     if test "$enable_nhrpd" = "yes"; then
1769       AC_MSG_ERROR([nhrpd requires kernel APIs that are only present on Linux.])
1770     fi
1771     ;;
1772 esac
1773
1774 if test "$enable_watchfrr" = "no";then
1775   WATCHFRR=""
1776 else
1777   WATCHFRR="watchfrr"
1778 fi
1779
1780 OSPFCLIENT=""
1781 if test "$enable_ospfapi" != "no";then
1782     AC_DEFINE([SUPPORT_OSPF_API], [1], [OSPFAPI])
1783
1784   if test "$enable_ospfclient" != "no";then
1785       OSPFCLIENT="ospfclient"
1786   fi
1787 fi
1788
1789 if test "$enable_bgp_announce" = "no";then
1790   AC_DEFINE([DISABLE_BGP_ANNOUNCE], [1], [Disable BGP installation to zebra])
1791 else
1792   AC_DEFINE([DISABLE_BGP_ANNOUNCE], [0], [Disable BGP installation to zebra])
1793 fi
1794
1795 if test "$enable_bgp_vnc" != "no";then
1796   AC_DEFINE([ENABLE_BGP_VNC], [1], [Enable BGP VNC support])
1797 fi
1798
1799 bgpd_bmp=false
1800 case "${enable_bmp}" in
1801   no)
1802     ;;
1803   yes)
1804     if test "$c_ares_found" != "true" ; then
1805       AC_MSG_ERROR([BMP support requires libcares.  Please install c-ares and its -dev headers.])
1806     fi
1807     bgpd_bmp=true
1808     ;;
1809   *)
1810     if test "$c_ares_found" = "true" ; then
1811       bgpd_bmp=true
1812     fi
1813     ;;
1814 esac
1815
1816 if test "$enable_version_build_config" != "no";then
1817   AC_DEFINE([ENABLE_VERSION_BUILD_CONFIG], [1], [Report build configs in show version])
1818 fi
1819
1820 dnl ##########################################################################
1821 dnl LARGE if block
1822 if test "$enable_clippy_only" != "yes"; then
1823 dnl ##########################################################################
1824
1825 dnl ------------------
1826 dnl check Net-SNMP library
1827 dnl ------------------
1828 if test "$enable_snmp" != "" -a "$enable_snmp" != "no"; then
1829    AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], [no])
1830    if test "$NETSNMP_CONFIG" = "no"; then
1831       AC_MSG_ERROR([--enable-snmp given but unable to find net-snmp-config])
1832    fi
1833    SNMP_LIBS="`${NETSNMP_CONFIG} --agent-libs`"
1834    SNMP_CFLAGS="`${NETSNMP_CONFIG} --base-cflags`"
1835    # net-snmp lists all of its own dependencies.  we absolutely do not want that
1836    # among other things we avoid a GPL vs. OpenSSL license conflict here
1837    for removelib in crypto ssl sensors pci wrap; do
1838      SNMP_LIBS="`echo $SNMP_LIBS | sed -e 's/\(^\|\s\)-l'$removelib'\b/ /g' -e 's/\(^\|\s\)\([^\s]*\/\)\?lib'$removelib'\.[^\s]\+\b/ /g'`"
1839    done
1840    AC_MSG_CHECKING([whether we can link to Net-SNMP])
1841    AC_LINK_IFELSE_FLAGS([$SNMP_CFLAGS], [$SNMP_LIBS], [AC_LANG_PROGRAM([
1842 int main(void);
1843 ],
1844 [
1845 {
1846   return 0;
1847 }
1848 ])], [
1849      AC_MSG_RESULT([no])
1850      AC_MSG_ERROR([--enable-snmp given but not usable])])
1851    case "${enable_snmp}" in
1852      yes)
1853       SNMP_METHOD=agentx
1854       ;;
1855      agentx)
1856       SNMP_METHOD="${enable_snmp}"
1857       ;;
1858      *)
1859       AC_MSG_ERROR([--enable-snmp given with an unknown method (${enable_snmp}). Use yes or agentx])
1860       ;;
1861    esac
1862    AH_TEMPLATE([SNMP_AGENTX], [Use SNMP AgentX to interface with snmpd])
1863    AC_DEFINE_UNQUOTED(AS_TR_CPP(SNMP_${SNMP_METHOD}),,[SNMP method to interface with snmpd])
1864 fi
1865 AC_SUBST([SNMP_LIBS])
1866 AC_SUBST([SNMP_CFLAGS])
1867
1868 dnl ---------------
1869 dnl libyang
1870 dnl ---------------
1871 PKG_CHECK_MODULES([LIBYANG], [libyang >= 1.0.184], , [
1872   AC_MSG_ERROR([libyang (>= 1.0.184) was not found on your system.])
1873 ])
1874 ac_cflags_save="$CFLAGS"
1875 CFLAGS="$CFLAGS $LIBYANG_CFLAGS"
1876 AC_CHECK_MEMBER([struct lyd_node.priv], [], [
1877   AC_MSG_ERROR([m4_normalize([
1878     libyang needs to be compiled with ENABLE_LYD_PRIV=ON.
1879     Instructions for this are included in the build documentation for your platform at http://docs.frrouting.org/projects/dev-guide/en/latest/building.html])
1880   ])
1881 ], [[#include <libyang/libyang.h>]])
1882 CFLAGS="$ac_cflags_save"
1883
1884 dnl ---------------
1885 dnl configuration rollbacks
1886 dnl ---------------
1887 SQLITE3=false
1888 if test "$enable_config_rollbacks" = "yes"; then
1889   PKG_CHECK_MODULES([SQLITE3], [sqlite3], [
1890     AC_DEFINE([HAVE_CONFIG_ROLLBACKS], [1], [Enable configuration rollbacks])
1891     AC_DEFINE([HAVE_SQLITE3], [1], [Enable sqlite3 database])
1892     SQLITE3=true
1893   ], [
1894     AC_MSG_ERROR([--enable-config-rollbacks given but sqlite3 was not found on your system.])
1895   ])
1896 fi
1897
1898 dnl ---------------
1899 dnl confd
1900 dnl ---------------
1901 if test "$enable_confd" != "" -a "$enable_confd" != "no"; then
1902    AC_CHECK_PROG([CONFD], [confd], [confd], [/bin/false], "${enable_confd}/bin")
1903    if test "$CONFD" = "/bin/false"; then
1904       AC_MSG_ERROR([confd was not found on your system.])]
1905    fi
1906    CONFD_CFLAGS="-I${enable_confd}/include -L${enable_confd}/lib"
1907    AC_SUBST([CONFD_CFLAGS])
1908    CONFD_LIBS="-lconfd"
1909    AC_SUBST([CONFD_LIBS])
1910    AC_DEFINE([HAVE_CONFD], [1], [Enable confd integration])
1911 fi
1912
1913 dnl ---------------
1914 dnl sysrepo
1915 dnl ---------------
1916 if test "$enable_sysrepo" = "yes"; then
1917   PKG_CHECK_MODULES([SYSREPO], [sysrepo],
1918       [AC_DEFINE([HAVE_SYSREPO], [1], [Enable sysrepo integration])
1919       SYSREPO=true],
1920       [SYSREPO=false
1921       AC_MSG_ERROR([sysrepo was not found on your system.])]
1922   )
1923 fi
1924
1925 dnl ---------------
1926 dnl gRPC
1927 dnl ---------------
1928 if test "$enable_grpc" = "yes"; then
1929   PKG_CHECK_MODULES([GRPC], [grpc grpc++ protobuf], [
1930     AC_CHECK_PROGS([PROTOC], [protoc], [/bin/false])
1931     if test "$PROTOC" = "/bin/false"; then
1932       AC_MSG_FAILURE([grpc requested but protoc not found.])
1933     fi
1934
1935     AC_DEFINE([HAVE_GRPC], [1], [Enable the gRPC northbound plugin])
1936     GRPC=true
1937   ], [
1938     GRPC=false
1939     AC_MSG_ERROR([grpc/grpc++ were not found on your system.])
1940   ])
1941 fi
1942
1943 dnl -----
1944 dnl LTTng
1945 dnl -----
1946 if test "$enable_lttng" = "yes"; then
1947   PKG_CHECK_MODULES([UST], [lttng-ust >= 2.12.0], [
1948     AC_DEFINE([HAVE_LTTNG], [1], [Enable LTTng support])
1949     LTTNG=true
1950   ], [
1951     AC_MSG_ERROR([configuration specifies --enable-lttng but lttng-ust was not found])
1952   ])
1953 fi
1954
1955 dnl ----
1956 dnl USDT
1957 dnl ----
1958 if test "$enable_usdt" = "yes"; then
1959   AC_CHECK_HEADERS([sys/sdt.h], [
1960     AC_DEFINE([HAVE_USDT], [1], [Enable USDT probes])
1961     USDT=true
1962   ], [
1963     AC_MSG_ERROR([configuration specifies --enable-usdt but no USDT kernel headers (sys/sdt.h) found])
1964   ])
1965 fi
1966
1967 dnl ------
1968 dnl ZeroMQ
1969 dnl ------
1970 if test "$enable_zeromq" != "no"; then
1971   PKG_CHECK_MODULES([ZEROMQ], [libzmq >= 4.0.0], [
1972     AC_DEFINE([HAVE_ZEROMQ], [1], [Enable ZeroMQ support])
1973     ZEROMQ=true
1974   ], [
1975     if test "$enable_zeromq" = "yes"; then
1976       AC_MSG_ERROR([configuration specifies --enable-zeromq but libzmq was not found])
1977     fi
1978   ])
1979 fi
1980
1981 dnl ------------------------------------
1982 dnl Enable RPKI and add librtr to libs
1983 dnl ------------------------------------
1984 if test "$enable_rpki" = "yes"; then
1985   PKG_CHECK_MODULES([RTRLIB], [rtrlib >= 0.5.0],
1986       [RPKI=true],
1987       [RPKI=false
1988       AC_MSG_ERROR([rtrlib was not found on your system or is too old.])]
1989   )
1990 fi
1991
1992 dnl ------------------------------------
1993 dnl pimd is not supported on OpenBSD and MacOS
1994 dnl ------------------------------------
1995 if test "$enable_pimd" != "no"; then
1996 AC_MSG_CHECKING([for pimd OS support])
1997 case "$host_os" in
1998   darwin*)
1999     AC_MSG_RESULT([no])
2000     enable_pimd="no"
2001     ;;
2002   openbsd*)
2003     AC_MSG_RESULT([no])
2004     enable_pimd="no"
2005     ;;
2006   *)
2007     AC_MSG_RESULT([yes])
2008     ;;
2009 esac
2010 fi
2011
2012 dnl -------------------------------------
2013 dnl VRRP is only supported on linux
2014 dnl -------------------------------------
2015 if test "$enable_vrrpd" != "no"; then
2016 AC_MSG_CHECKING([for VRRP OS support])
2017 case "$host_os" in
2018   linux*)
2019     AC_MSG_RESULT([yes])
2020     ;;
2021   *)
2022     AC_MSG_RESULT([no])
2023     enable_vrrpd="no"
2024     ;;
2025 esac
2026 fi
2027
2028 dnl ------------------------------------------
2029 dnl Check whether rtrlib was build with ssh support
2030 dnl ------------------------------------------
2031 AC_MSG_CHECKING([whether the RTR Library is compiled with SSH])
2032 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "rtrlib/rtrlib.h"]],
2033                         [[struct tr_ssh_config config;]])],
2034         [AC_MSG_RESULT([yes])
2035         AC_DEFINE([FOUND_SSH], [1], [found_ssh])],
2036         AC_MSG_RESULT([no])
2037 )
2038
2039 dnl ---------------
2040 dnl dlopen & dlinfo
2041 dnl ---------------
2042 AC_SEARCH_LIBS([dlopen], [dl dld], [], [
2043   AC_MSG_ERROR([unable to find the dlopen()])
2044 ])
2045
2046 AC_CHECK_HEADERS([link.h])
2047
2048 AC_CACHE_CHECK([for dlinfo(RTLD_DI_ORIGIN)], [frr_cv_rtld_di_origin], [
2049   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2050 #include <stdlib.h>
2051 #ifdef HAVE_LINK_H
2052 #include <link.h>
2053 #endif
2054 #include <dlfcn.h>
2055 ]], [[
2056   char origin[1];
2057   dlinfo (NULL, RTLD_DI_ORIGIN, &origin);
2058 ]])], [
2059     frr_cv_rtld_di_origin=yes
2060   ], [
2061     frr_cv_rtld_di_origin=no
2062   ])
2063 ])
2064 if test "$frr_cv_rtld_di_origin" = "yes"; then
2065   AC_DEFINE([HAVE_DLINFO_ORIGIN], [1], [Have dlinfo RTLD_DI_ORIGIN])
2066 fi
2067
2068 AC_CACHE_CHECK([for dlinfo(RTLD_DI_LINKMAP)], [frr_cv_rtld_di_linkmap], [
2069   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2070 #include <stdlib.h>
2071 #ifdef HAVE_LINK_H
2072 #include <link.h>
2073 #endif
2074 #include <dlfcn.h>
2075 ]], [[
2076   struct link_map *lm = NULL;
2077   dlinfo (NULL, RTLD_DI_LINKMAP, &lm);
2078 ]])], [
2079     frr_cv_rtld_di_linkmap=yes
2080   ], [
2081     frr_cv_rtld_di_linkmap=no
2082   ])
2083 ])
2084 if test "$frr_cv_rtld_di_linkmap" = "yes"; then
2085   AC_DEFINE([HAVE_DLINFO_LINKMAP], [1], [Have dlinfo RTLD_DI_LINKMAP])
2086 fi
2087
2088 dnl ##########################################################################
2089 dnl test "$enable_clippy_only" != "yes"
2090 fi
2091 dnl END OF LARGE if block
2092 dnl ##########################################################################
2093
2094 dnl ---------------------------
2095 dnl sockaddr and netinet checks
2096 dnl ---------------------------
2097 AC_CHECK_TYPES([
2098         struct sockaddr_dl,
2099         struct vifctl, struct mfcctl, struct sioc_sg_req,
2100         vifi_t, struct sioc_vif_req, struct igmpmsg,
2101         struct ifaliasreq, struct if6_aliasreq, struct in6_aliasreq,
2102         struct nd_opt_adv_interval,
2103         struct nd_opt_homeagent_info, struct nd_opt_adv_interval,
2104         struct nd_opt_rdnss, struct nd_opt_dnssl],
2105         [], [], FRR_INCLUDES)
2106
2107 AC_CHECK_MEMBERS([struct sockaddr.sa_len,
2108         struct sockaddr_in.sin_len, struct sockaddr_un.sun_len,
2109         struct sockaddr_dl.sdl_len,
2110         struct if6_aliasreq.ifra_lifetime,
2111         struct nd_opt_adv_interval.nd_opt_ai_type],
2112         [], [], FRR_INCLUDES)
2113
2114 dnl ---------------------------
2115 dnl IRDP/pktinfo/icmphdr checks
2116 dnl ---------------------------
2117
2118 AC_CHECK_TYPES([struct in_pktinfo], [
2119   AC_CHECK_TYPES([struct icmphdr], [
2120     IRDP=true
2121   ], [
2122     IRDP=false
2123   ], [FRR_INCLUDES])
2124 ], [
2125   IRDP=false
2126 ], [FRR_INCLUDES])
2127
2128 case "${enable_irdp}" in
2129 yes)
2130   $IRDP || AC_MSG_ERROR(['IRDP requires in_pktinfo at the moment!'])
2131   ;;
2132 no)
2133   IRDP=false
2134   ;;
2135 esac
2136
2137
2138 dnl -----------------------
2139 dnl checking for IP_PKTINFO
2140 dnl -----------------------
2141 AC_MSG_CHECKING([for IP_PKTINFO])
2142 AC_TRY_COMPILE([#include <netdb.h>], [
2143   int opt = IP_PKTINFO;
2144 ], [
2145   AC_MSG_RESULT([yes])
2146   AC_DEFINE([HAVE_IP_PKTINFO], [1], [Have IP_PKTINFO])
2147 ], [
2148   AC_MSG_RESULT([no])
2149 ])
2150
2151 dnl ---------------------------
2152 dnl checking for IP_RECVDSTADDR
2153 dnl ---------------------------
2154 AC_MSG_CHECKING([for IP_RECVDSTADDR])
2155 AC_TRY_COMPILE([#include <netinet/in.h>], [
2156   int opt = IP_RECVDSTADDR;
2157 ], [
2158   AC_MSG_RESULT([yes])
2159   AC_DEFINE([HAVE_IP_RECVDSTADDR], [1], [Have IP_RECVDSTADDR])
2160 ], [
2161   AC_MSG_RESULT([no])
2162 ])
2163
2164 dnl ----------------------
2165 dnl checking for IP_RECVIF
2166 dnl ----------------------
2167 AC_MSG_CHECKING([for IP_RECVIF])
2168 AC_TRY_COMPILE([#include <netinet/in.h>], [
2169   int opt = IP_RECVIF;
2170 ], [
2171   AC_MSG_RESULT([yes])
2172   AC_DEFINE([HAVE_IP_RECVIF], [1], [Have IP_RECVIF])
2173 ], [
2174   AC_MSG_RESULT([no])
2175 ])
2176
2177 dnl ----------------------
2178 dnl checking for SO_BINDANY
2179 dnl ----------------------
2180 AC_MSG_CHECKING([for SO_BINDANY])
2181 AC_TRY_COMPILE([#include <sys/socket.h>], [
2182   int opt = SO_BINDANY;
2183 ], [
2184   AC_MSG_RESULT([yes])
2185   AC_DEFINE([HAVE_SO_BINDANY], [1], [Have SO_BINDANY])
2186 ], [
2187   AC_MSG_RESULT([no])
2188 ])
2189
2190 dnl ----------------------
2191 dnl checking for IP_FREEBIND
2192 dnl ----------------------
2193 AC_MSG_CHECKING([for IP_FREEBIND])
2194 AC_TRY_COMPILE([#include <netinet/in.h>], [
2195   int opt = IP_FREEBIND;
2196 ], [
2197   AC_MSG_RESULT([yes])
2198   AC_DEFINE([HAVE_IP_FREEBIND], [1], [Have IP_FREEBIND])
2199 ], [
2200   AC_MSG_RESULT([no])
2201 ])
2202
2203 dnl --------------------------------------
2204 dnl checking for be32dec existence or not
2205 dnl --------------------------------------
2206 AC_CHECK_DECLS([be32enc, be32dec], [], [],
2207                [#include <sys/endian.h>])
2208
2209 dnl --------------------------------------
2210 dnl checking for clock_time monotonic struct and call
2211 dnl --------------------------------------
2212 AC_CHECK_DECL([CLOCK_MONOTONIC],
2213         [AC_CHECK_LIB([rt], [clock_gettime], [LIBS="$LIBS -lrt"])
2214          AC_DEFINE([HAVE_CLOCK_MONOTONIC], [1], [Have monotonic clock])
2215 ], [AC_MSG_RESULT([no])], [FRR_INCLUDES])
2216
2217 AC_SEARCH_LIBS([clock_nanosleep], [rt], [
2218   AC_DEFINE([HAVE_CLOCK_NANOSLEEP], [1], [Have clock_nanosleep()])
2219 ])
2220
2221 dnl --------------------------------------
2222 dnl checking for flex and bison
2223 dnl --------------------------------------
2224
2225 AM_PROG_LEX
2226 AC_MSG_CHECKING([version of flex])
2227 frr_ac_flex_version="$(eval $LEX -V | grep flex | head -n 1)"
2228 frr_ac_flex_version="${frr_ac_flex_version##* }"
2229 AC_MSG_RESULT([$frr_ac_flex_version])
2230 AX_COMPARE_VERSION([$frr_ac_flex_version], [lt], [2.5.20], [
2231   LEX="$SHELL $missing_dir/missing flex"
2232   if test -f "${srcdir}/lib/command_lex.c" -a -f "${srcdir}/lib/command_lex.h"; then
2233     AC_MSG_WARN([using pregenerated flex output files])
2234   else
2235     AC_MSG_ERROR([flex failure and pregenerated files not included (probably a git build)])
2236   fi
2237   AC_SUBST([LEX_OUTPUT_ROOT], [lex.yy])
2238   AC_SUBST([LEXLIB], [''])
2239 ])
2240
2241 AC_PROG_YACC
2242 dnl thanks GNU bison for this b*llshit...
2243 AC_MSG_CHECKING([version of bison])
2244 frr_ac_bison_version="$(eval $YACC -V | grep bison | head -n 1)"
2245 frr_ac_bison_version="${frr_ac_bison_version##* }"
2246 frr_ac_bison_missing="false"
2247 case "x${frr_ac_bison_version}x" in
2248   x2.7*)
2249     BISON_OPENBRACE='"'
2250     BISON_CLOSEBRACE='"'
2251     BISON_VERBOSE=''
2252     AC_MSG_RESULT([$frr_ac_bison_version - 2.7 or older])
2253     ;;
2254   x2.*|x1.*)
2255     AC_MSG_RESULT([$frr_ac_bison_version])
2256     AC_MSG_WARN([installed bison is too old.  Please install GNU bison 2.7.x or newer.])
2257     frr_ac_bison_missing="true"
2258     ;;
2259   x)
2260     AC_MSG_RESULT([none])
2261     AC_MSG_WARN([could not determine bison version.  Please install GNU bison 2.7.x or newer.])
2262     frr_ac_bison_missing="true"
2263     ;;
2264   x3.[012][^0-9]*)
2265     BISON_OPENBRACE='{'
2266     BISON_CLOSEBRACE='}'
2267     BISON_VERBOSE='-Dparse.error=verbose'
2268     AC_MSG_RESULT([$frr_ac_bison_version - 3.0 to 3.2])
2269     ;;
2270   *)
2271     BISON_OPENBRACE='{'
2272     BISON_CLOSEBRACE='}'
2273     BISON_VERBOSE='-Dparse.error=verbose -Wno-yacc'
2274     AC_MSG_RESULT([$frr_ac_bison_version - 3.3 or newer])
2275     ;;
2276 esac
2277 AC_SUBST([BISON_OPENBRACE])
2278 AC_SUBST([BISON_CLOSEBRACE])
2279 AC_SUBST([BISON_VERBOSE])
2280
2281 if $frr_ac_bison_missing; then
2282   YACC="$SHELL $missing_dir/missing bison -y"
2283   if test -f "${srcdir}/lib/command_parse.c" -a -f "${srcdir}/lib/command_parse.h"; then
2284     AC_MSG_WARN([using pregenerated bison output files])
2285   else
2286     AC_MSG_ERROR([bison failure and pregenerated files not included (probably a git build)])
2287   fi
2288 fi
2289
2290 dnl -------------------
2291 dnl capabilities checks
2292 dnl -------------------
2293 if test "$enable_capabilities" != "no"; then
2294   AC_MSG_CHECKING([whether prctl PR_SET_KEEPCAPS is available])
2295   AC_TRY_COMPILE([#include <sys/prctl.h>], [prctl(PR_SET_KEEPCAPS, 1, 0, 0, 0);],
2296     [AC_MSG_RESULT([yes])
2297      AC_DEFINE([HAVE_PR_SET_KEEPCAPS], [1], [prctl])
2298      frr_ac_keepcaps="yes"],
2299      AC_MSG_RESULT([no])
2300   )
2301   if test "$frr_ac_keepcaps" = "yes"; then
2302     AC_CHECK_HEADERS([sys/capability.h])
2303   fi
2304   if test "$ac_cv_header_sys_capability_h" = "yes"; then
2305     AC_CHECK_LIB([cap], [cap_init],
2306       [AC_DEFINE([HAVE_LCAPS], [1], [Capabilities])
2307        LIBCAP="-lcap"
2308        frr_ac_lcaps="yes"]
2309     )
2310   fi
2311   if test "$frr_ac_scaps" = "yes" \
2312        -o "$frr_ac_lcaps" = "yes"; then
2313     AC_DEFINE([HAVE_CAPABILITIES], [1], [capabilities])
2314   fi
2315
2316   case "$host_os" in
2317   linux*)
2318     if test "$enable_clippy_only" != "yes"; then
2319     if test "$frr_ac_lcaps" != "yes"; then
2320       AC_MSG_ERROR([libcap and/or its headers were not found.  Running FRR without libcap support built in causes a huge performance penalty.])
2321     fi
2322     fi
2323     ;;
2324   esac
2325 else
2326   case "$host_os" in
2327   linux*)
2328     AC_MSG_WARN([Running FRR without libcap support built in causes a huge performance penalty.])
2329     ;;
2330   esac
2331 fi
2332 AC_SUBST([LIBCAP])
2333
2334 dnl ---------------------------
2335 dnl check for glibc 'backtrace'
2336 dnl ---------------------------
2337 if test "$enable_backtrace" != "no" ; then
2338   backtrace_ok=no
2339   PKG_CHECK_MODULES([UNWIND], [libunwind], [
2340     AC_DEFINE([HAVE_LIBUNWIND], [1], [libunwind])
2341     backtrace_ok=yes
2342   ], [
2343     true
2344   ])
2345
2346   if test "$backtrace_ok" = "no"; then
2347     AC_CHECK_HEADER([unwind.h], [
2348       AC_SEARCH_LIBS([unw_getcontext], [unwind], [
2349         AC_DEFINE([HAVE_LIBUNWIND], [1], [libunwind])
2350         backtrace_ok=yes
2351       ])
2352     ])
2353   fi
2354
2355   if test "$backtrace_ok" = "no"; then
2356     AC_CHECK_HEADER([execinfo.h], [
2357       AC_SEARCH_LIBS([backtrace], [execinfo], [
2358         AC_DEFINE([HAVE_GLIBC_BACKTRACE], [1], [Glibc backtrace])
2359         backtrace_ok=yes
2360       ],, [-lm])
2361     ])
2362   fi
2363
2364   if test "$enable_backtrace" = "yes" -a "$backtrace_ok" = "no"; then
2365     dnl user explicitly requested backtrace but we failed to find support
2366     AC_MSG_FAILURE([failed to find backtrace or libunwind support])
2367   fi
2368 fi
2369
2370 dnl -----------------------------------------
2371 dnl check for malloc mallinfo struct and call
2372 dnl this must try and link using LIBS, in
2373 dnl order to check no alternative allocator
2374 dnl has been specified, which might not provide
2375 dnl mallinfo
2376 dnl -----------------------------------------
2377 AC_CHECK_HEADERS([malloc.h malloc_np.h malloc/malloc.h],,, [FRR_INCLUDES])
2378
2379 AC_CACHE_CHECK([whether mallinfo is available], [frr_cv_mallinfo], [
2380   AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2381 #ifdef HAVE_MALLOC_H
2382 #include <malloc.h>
2383 #endif
2384 #ifdef HAVE_MALLOC_NP_H
2385 #include <malloc_np.h>
2386 #endif
2387 #ifdef HAVE_MALLOC_MALLOC_H
2388 #include <malloc/malloc.h>
2389 #endif
2390 ]], [[
2391 struct mallinfo ac_x; ac_x = mallinfo ();
2392 ]])], [
2393     frr_cv_mallinfo=yes
2394   ], [
2395     frr_cv_mallinfo=no
2396   ])
2397 ])
2398 if test "$frr_cv_mallinfo" = "yes"; then
2399   AC_DEFINE([HAVE_MALLINFO], [1], [mallinfo])
2400 fi
2401
2402 AC_CACHE_CHECK([whether mallinfo2 is available], [frr_cv_mallinfo2], [
2403   AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2404 #ifdef HAVE_MALLOC_H
2405 #include <malloc.h>
2406 #endif
2407 #ifdef HAVE_MALLOC_NP_H
2408 #include <malloc_np.h>
2409 #endif
2410 #ifdef HAVE_MALLOC_MALLOC_H
2411 #include <malloc/malloc.h>
2412 #endif
2413 ]], [[
2414 struct mallinfo2 ac_x; ac_x = mallinfo2 ();
2415 ]])], [
2416     frr_cv_mallinfo2=yes
2417   ], [
2418     frr_cv_mallinfo2=no
2419   ])
2420 ])
2421 if test "$frr_cv_mallinfo2" = "yes"; then
2422   AC_DEFINE([HAVE_MALLINFO2], [1], [mallinfo2])
2423 fi
2424
2425 AC_MSG_CHECKING([whether malloc_usable_size is available])
2426 AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2427 #ifdef HAVE_MALLOC_H
2428 #include <malloc.h>
2429 #endif
2430 #ifdef HAVE_MALLOC_MALLOC_H
2431 #include <malloc/malloc.h>
2432 #endif
2433 ]], [[
2434 size_t ac_x; ac_x = malloc_usable_size(NULL);
2435 ]])], [
2436   AC_MSG_RESULT([yes])
2437   AC_DEFINE([HAVE_MALLOC_USABLE_SIZE], [1], [malloc_usable_size])
2438 ], [
2439   AC_MSG_RESULT([no])
2440
2441   AC_MSG_CHECKING([whether malloc_size is available])
2442   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2443 #ifdef HAVE_MALLOC_H
2444 #include <malloc.h>
2445 #endif
2446 #ifdef HAVE_MALLOC_MALLOC_H
2447 #include <malloc/malloc.h>
2448 #endif
2449 ]], [[
2450 size_t ac_x; ac_x = malloc_size(NULL);
2451 ]])], [
2452     AC_MSG_RESULT([yes])
2453     AC_DEFINE([HAVE_MALLOC_SIZE], [1], [malloc_size])
2454   ], [
2455     AC_MSG_RESULT([no])
2456   ])
2457 ])
2458
2459 dnl ----------
2460 dnl configure date
2461 dnl ----------
2462 dev_version=`echo $VERSION | grep dev`
2463 #don't expire deprecated code in non 'dev' branch
2464 if test "$dev_version" = ""; then
2465    CONFDATE=0
2466 else
2467    CONFDATE=`date '+%Y%m%d'`
2468 fi
2469 AC_SUBST([CONFDATE])
2470
2471 dnl ------------------------------
2472 dnl set paths for state directory
2473 dnl ------------------------------
2474 AC_MSG_CHECKING([directory to use for state file])
2475 if test "$prefix" = "NONE"; then
2476   frr_statedir_prefix="";
2477 else
2478   frr_statedir_prefix=${prefix}
2479 fi
2480 if test "$localstatedir" = '${prefix}/var'; then
2481   for FRR_STATE_DIR in ${frr_statedir_prefix}/var/run dnl
2482                         ${frr_statedir_prefix}/var/adm dnl
2483                         ${frr_statedir_prefix}/etc dnl
2484                         /var/run        dnl
2485                         /var/adm        dnl
2486                         /etc            dnl
2487                         /dev/null;
2488   do
2489     test -d $FRR_STATE_DIR && break
2490   done
2491   frr_statedir=$FRR_STATE_DIR
2492 else
2493   frr_statedir=${localstatedir}
2494 fi
2495 if test "$frr_statedir" = "/dev/null"; then
2496     AC_MSG_ERROR([STATE DIRECTORY NOT FOUND! FIX OR SPECIFY --localstatedir!])
2497 fi
2498 AC_MSG_RESULT([${frr_statedir}])
2499 AC_SUBST([frr_statedir])
2500
2501 AC_DEFINE_UNQUOTED([LDPD_SOCKET], ["$frr_statedir%s%s/ldpd.sock"], [ldpd control socket])
2502 AC_DEFINE_UNQUOTED([ZEBRA_SERV_PATH], ["$frr_statedir%s%s/zserv.api"], [zebra api socket])
2503 AC_DEFINE_UNQUOTED([BFDD_CONTROL_SOCKET], ["$frr_statedir%s%s/bfdd.sock"], [bfdd control socket])
2504 AC_DEFINE_UNQUOTED([DAEMON_VTY_DIR], ["$frr_statedir%s%s"], [daemon vty directory])
2505 AC_DEFINE_UNQUOTED([DAEMON_DB_DIR], ["$frr_statedir"], [daemon database directory])
2506
2507 dnl autoconf does this, but it does it too late...
2508 test "$prefix" = "NONE" && prefix=$ac_default_prefix
2509 test "$exec_prefix" = "NONE" && exec_prefix='${prefix}'
2510
2511 dnl get the full path, recursing through variables...
2512 vtysh_bin="$bindir/vtysh"
2513 for I in 1 2 3 4 5 6 7 8 9 10; do
2514         eval vtysh_bin="\"$vtysh_bin\""
2515 done
2516 AC_DEFINE_UNQUOTED([VTYSH_BIN_PATH], ["$vtysh_bin"], [path to vtysh binary])
2517 AC_SUBST([vtysh_bin])
2518
2519 CFG_SYSCONF="$sysconfdir"
2520 CFG_SBIN="$sbindir"
2521 CFG_STATE="$frr_statedir"
2522 CFG_MODULE="$moduledir"
2523 CFG_YANGMODELS="$yangmodelsdir"
2524 CFG_SCRIPT="$scriptdir"
2525 for I in 1 2 3 4 5 6 7 8 9 10; do
2526         eval CFG_SYSCONF="\"$CFG_SYSCONF\""
2527         eval CFG_SBIN="\"$CFG_SBIN\""
2528         eval CFG_STATE="\"$CFG_STATE\""
2529         eval CFG_MODULE="\"$CFG_MODULE\""
2530         eval CFG_YANGMODELS="\"$CFG_YANGMODELS\""
2531         eval CFG_SCRIPT="\"$CFG_SCRIPT\""
2532 done
2533 AC_SUBST([CFG_SYSCONF])
2534 AC_SUBST([CFG_SBIN])
2535 AC_SUBST([CFG_STATE])
2536 AC_SUBST([CFG_MODULE])
2537 AC_SUBST([CFG_SCRIPT])
2538 AC_SUBST([CFG_YANGMODELS])
2539 AC_DEFINE_UNQUOTED([MODULE_PATH], ["$CFG_MODULE"], [path to modules])
2540 AC_DEFINE_UNQUOTED([SCRIPT_PATH], ["$CFG_SCRIPT"], [path to scripts])
2541 AC_DEFINE_UNQUOTED([YANG_MODELS_PATH], ["$CFG_YANGMODELS"], [path to YANG data models])
2542 AC_DEFINE_UNQUOTED([WATCHFRR_SH_PATH], ["${CFG_SBIN%/}/watchfrr.sh"], [path to watchfrr.sh])
2543
2544 dnl various features
2545 AM_CONDITIONAL([SUPPORT_REALMS], [test "$enable_realms" = "yes"])
2546 AM_CONDITIONAL([ENABLE_BGP_VNC], [test "$enable_bgp_vnc" != "no"])
2547 AM_CONDITIONAL([BGP_BMP], [$bgpd_bmp])
2548 dnl northbound
2549 AM_CONDITIONAL([SQLITE3], [$SQLITE3])
2550 AM_CONDITIONAL([CONFD], [test "$enable_confd" != ""])
2551 AM_CONDITIONAL([SYSREPO], [test "$enable_sysrepo" = "yes"])
2552 AM_CONDITIONAL([GRPC], [test "$enable_grpc" = "yes"])
2553 AM_CONDITIONAL([ZEROMQ], [test "$ZEROMQ" = "true"])
2554 dnl plugins
2555 AM_CONDITIONAL([RPKI], [test "$RPKI" = "true"])
2556 AM_CONDITIONAL([SNMP], [test "$SNMP_METHOD" = "agentx"])
2557 AM_CONDITIONAL([IRDP], [$IRDP])
2558 AM_CONDITIONAL([FPM], [test "$enable_fpm" = "yes"])
2559 AM_CONDITIONAL([HAVE_PROTOBUF], [test "$enable_protobuf" = "yes"])
2560 AM_CONDITIONAL([HAVE_PROTOBUF3], [$PROTO3])
2561
2562 dnl PCEP plugin
2563 AS_IF([test "$enable_pathd" != "no"], [
2564        AC_SUBST([PATHD_PCEP_LIBS], ["pceplib/libpcep_pcc.la"])
2565        AC_SUBST([PATHD_PCEP_INCL], ["-I./pceplib "])
2566        ])
2567 AC_CHECK_LIB([cunit], [CU_initialize_registry], [pcep_cunit=yes],[pcep_cunit=no])
2568 AM_CONDITIONAL([PATHD_PCEP_TEST], [test "x${pcep_cunit}" = xyes])
2569 AC_CHECK_PROG(VALGRIND_CHECK, valgrind, yes)
2570 AM_CONDITIONAL([HAVE_VALGRIND_PCEP], [test "$VALGRIND_CHECK" = "yes"])
2571
2572 dnl daemons
2573 AM_CONDITIONAL([VTYSH], [test "$VTYSH" = "vtysh"])
2574 AM_CONDITIONAL([ZEBRA], [test "$enable_zebra" != "no"])
2575 AM_CONDITIONAL([BGPD], [test "$enable_bgpd" != "no"])
2576 AM_CONDITIONAL([RIPD], [test "$enable_ripd" != "no"])
2577 AM_CONDITIONAL([OSPFD], [test "$enable_ospfd" != "no"])
2578 AM_CONDITIONAL([LDPD], [test "$enable_ldpd" != "no"])
2579 AM_CONDITIONAL([BFDD], [test "$BFDD" = "bfdd"])
2580 AM_CONDITIONAL([NHRPD], [test "$NHRPD" = "nhrpd"])
2581 AM_CONDITIONAL([EIGRPD], [test "$enable_eigrpd" != "no"])
2582 AM_CONDITIONAL([WATCHFRR], [test "$WATCHFRR" = "watchfrr"])
2583 AM_CONDITIONAL([OSPFCLIENT], [test "$OSPFCLIENT" = "ospfclient"])
2584 AM_CONDITIONAL([RIPNGD], [test "$enable_ripngd" != "no"])
2585 AM_CONDITIONAL([BABELD], [test "$enable_babeld" != "no"])
2586 AM_CONDITIONAL([OSPF6D], [test "$enable_ospf6d" != "no"])
2587 AM_CONDITIONAL([ISISD], [test "$enable_isisd" != "no"])
2588 AM_CONDITIONAL([PIMD], [test "$enable_pimd" != "no"])
2589 AM_CONDITIONAL([PBRD], [test "$enable_pbrd" != "no"])
2590 AM_CONDITIONAL([SHARPD], [test "$enable_sharpd" = "yes"])
2591 AM_CONDITIONAL([STATICD], [test "$enable_staticd" != "no"])
2592 AM_CONDITIONAL([FABRICD], [test "$enable_fabricd" != "no"])
2593 AM_CONDITIONAL([VRRPD], [test "$enable_vrrpd" != "no"])
2594 AM_CONDITIONAL([PATHD], [test "$enable_pathd" != "no"])
2595 AM_CONDITIONAL([PATHD_PCEP], [test "$enable_pathd" != "no"])
2596
2597 AC_CONFIG_FILES([Makefile],[
2598         test "$enable_dev_build" = "yes" && makefile_devbuild="--dev-build"
2599         ${PYTHON} "${ac_abs_top_srcdir}/python/makefile.py" ${makefile_devbuild} || exit 1
2600 ], [
2601         PYTHON="$PYTHON"
2602         enable_dev_build="$enable_dev_build"
2603 ])
2604
2605 AC_CONFIG_FILES([
2606           config.version
2607           changelog-auto
2608           redhat/frr.spec
2609           alpine/APKBUILD
2610           snapcraft/snapcraft.yaml
2611           lib/version.h
2612           tests/lib/cli/test_cli.refout
2613           pkgsrc/bgpd.sh pkgsrc/ospf6d.sh pkgsrc/ospfd.sh
2614           pkgsrc/ripd.sh pkgsrc/ripngd.sh pkgsrc/zebra.sh
2615           pkgsrc/eigrpd.sh])
2616
2617 AC_CONFIG_FILES([vtysh/extract.pl], [chmod +x vtysh/extract.pl])
2618 AC_CONFIG_FILES([tools/frr], [chmod +x tools/frr])
2619 AC_CONFIG_FILES([tools/watchfrr.sh], [chmod +x tools/watchfrr.sh])
2620 AC_CONFIG_FILES([tools/frrinit.sh], [chmod +x tools/frrinit.sh])
2621 AC_CONFIG_FILES([tools/frrcommon.sh])
2622 AC_CONFIG_FILES([tools/frr.service])
2623 AC_CONFIG_FILES([tools/frr@.service])
2624
2625 AS_IF([test "$with_pkg_git_version" = "yes"], [
2626     AC_CONFIG_COMMANDS([lib/gitversion.h], [
2627         dst="${ac_abs_top_builddir}/lib/gitversion.h"
2628         ${PERL} "${ac_abs_top_srcdir}/lib/gitversion.pl" \
2629                 "${ac_abs_top_srcdir}" \
2630                 > "${dst}.tmp"
2631         test -f "$dst" \
2632                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
2633                 && rm "${dst}.tmp" \
2634                 || mv "${dst}.tmp" "${dst}"
2635     ], [
2636         PERL="$PERL"
2637     ])
2638 ])
2639
2640 ## Hack, but working solution to avoid rebuilding of frr.info.
2641 ## It's already in CVS until texinfo 4.7 is more common.
2642 AC_OUTPUT
2643
2644 if test "$enable_rpath" = "yes" ; then
2645         true
2646 else
2647         # See https://old-en.opensuse.org/openSUSE:Packaging_Guidelines#Removing_Rpath
2648         sed -i 's|^hardcode_libdir_flag_spec=.*|hardcode_libdir_flag_spec=""|g' libtool
2649         sed -i 's|^runpath_var=LD_RUN_PATH|runpath_var=DIE_RPATH_DIE|g' libtool
2650 fi
2651
2652 echo "
2653 FRRouting configuration
2654 ------------------------------
2655 FRR version             : ${PACKAGE_VERSION}
2656 host operating system   : ${host_os}
2657 source code location    : ${srcdir}
2658 compiler                : ${CC}
2659 compiler flags          : ${CFLAGS} ${AC_CFLAGS} ${SAN_FLAGS}
2660 make                    : ${MAKE-make}
2661 linker flags            : ${LDFLAGS} ${SAN_FLAGS} ${LIBS} ${LIBCAP} ${LIBREADLINE} ${LIBM}
2662 state file directory    : ${frr_statedir}
2663 config file directory   : `eval echo \`echo ${sysconfdir}\``
2664 example directory       : `eval echo \`echo ${exampledir}\``
2665 module directory        : ${CFG_MODULE}
2666 script directory        : ${CFG_SCRIPT}
2667 user to run as          : ${enable_user}
2668 group to run as         : ${enable_group}
2669 group for vty sockets   : ${enable_vty_group}
2670 config file mask        : ${enable_configfile_mask}
2671 log file mask           : ${enable_logfile_mask}
2672 zebra protobuf enabled  : ${enable_protobuf:-no}
2673 vici socket path        : ${vici_socket}
2674
2675 The above user and group must have read/write access to the state file
2676 directory and to the config files in the config file directory."
2677
2678 if test "$enable_doc" != "no" -a "$frr_py_mod_sphinx" = "false"; then
2679   AC_MSG_WARN([sphinx is missing but required to build documentation])
2680 fi
2681 if test "$frr_py_mod_pytest" = "false"; then
2682   AC_MSG_WARN([pytest is missing, unit tests cannot be performed])
2683 fi