configure.ac

   1 ##
   2 ## Configure template file for FRRouting.
   3 ## autoconf will generate a configure script.
   4 ##
   5 ##  Copyright (c) 1996, 97, 98, 99, 2000 Kunihiro Ishiguro <kunihiro@zebra.org>
   6 ##  Portions Copyright (c) 2003 Paul Jakma <paul@dishone.st>
   7 ##
   8 AC_PREREQ([2.60])
   9
  10 AC_INIT([frr], [7.6-dev], [https://github.com/frrouting/frr/issues])
  11 PACKAGE_URL="https://frrouting.org/"
  12 AC_SUBST([PACKAGE_URL])
  13 PACKAGE_FULLNAME="FRRouting"
  14 AC_SUBST([PACKAGE_FULLNAME])
  15
  16 CONFIG_ARGS="`echo $ac_configure_args | sed -e \"s% '[[A-Z]]*FLAGS=[[^']]\+'%%g\"`"
  17 AC_SUBST([CONFIG_ARGS])
  18
  19 AC_CONFIG_SRCDIR([lib/zebra.h])
  20 AC_CONFIG_MACRO_DIR([m4])
  21
  22 dnl -----------------------------------
  23 dnl Get hostname and other information.
  24 dnl -----------------------------------
  25 AC_CANONICAL_BUILD()
  26 AC_CANONICAL_HOST()
  27
  28 hosttools_clippy="false"
  29 build_clippy="true"
  30
  31 dnl case 1: external clippy
  32 if test -n "$with_clippy" -a "$with_clippy" != "no" -a "$with_clippy" != "yes"; then
  33   if test "$enable_clippy_only" = "yes"; then
  34     AC_MSG_ERROR([--enable-clippy-only does not make sense with --with-clippy])
  35   fi
  36
  37   CLIPPY="$with_clippy"
  38   build_clippy="false"
  39   if test ! -x "$with_clippy"; then
  40     AC_MSG_ERROR([clippy tool ($with_clippy) is not executable])
  41   fi
  42
  43 dnl case 2: cross-compiling internal clippy
  44 elif test "$host" != "$build"; then
  45   if test "$srcdir" = "."; then
  46     AC_MSG_ERROR([cross-compilation is only possible with builddir separate from srcdir or by building clippy separately and using the --with-clippy option.  create a separate directory and run as .../path-to-frr/configure.])
  47   fi
  48   test -d hosttools || mkdir hosttools
  49   abssrc="`cd \"${srcdir}\"; pwd`"
  50
  51   AC_MSG_NOTICE([...])
  52   AC_MSG_NOTICE([... cross-compilation: creating hosttools directory and self-configuring for build platform tools])
  53   AC_MSG_NOTICE([... use HOST_CPPFLAGS / HOST_CFLAGS / HOST_LDFLAGS if neccessary])
  54   AC_MSG_NOTICE([...])
  55
  56   (
  57     for var in $ac_precious_vars; do
  58       dnl special cases
  59       case "$var" in
  60       YACC|YFLAGS) continue;;
  61       PYTHON*)     retain=true;;
  62       *)           retain=false;
  63       esac
  64
  65       eval "hostvar=\"\${HOST_$var}\""
  66       eval "targetvar=\"\${$var}\""
  67       if test -n "$hostvar"; then
  68         eval "$var='$hostvar'"
  69         _AS_ECHO_LOG([host $var='$hostvar'])
  70       elif $retain; then
  71         _AS_ECHO_LOG([host retain $var='$targetvar'])
  72       else
  73         eval "unset $var"
  74         _AS_ECHO_LOG([host unset $var])
  75       fi
  76     done
  77     cd hosttools
  78     "${abssrc}/configure" "--host=$build" "--build=$build" "--enable-clippy-only" "--disable-nhrpd" "--disable-vtysh"
  79   ) || exit 1
  80
  81   AC_MSG_NOTICE([...])
  82   AC_MSG_NOTICE([... cross-compilation: finished self-configuring for build platform tools])
  83   AC_MSG_NOTICE([...])
  84
  85   build_clippy="false"
  86   hosttools_clippy="true"
  87   CLIPPY="hosttools/lib/clippy"
  88
  89 dnl case 3: normal build internal clippy
  90 else
  91   CLIPPY="lib/clippy\$(EXEEXT)"
  92 fi
  93 AC_SUBST([CLIPPY])
  94 AM_CONDITIONAL([BUILD_CLIPPY], [$build_clippy])
  95 AM_CONDITIONAL([HOSTTOOLS_CLIPPY], [$hosttools_clippy])
  96 AM_CONDITIONAL([ONLY_CLIPPY], [test "$enable_clippy_only" = "yes"])
  97
  98 # Disable portability warnings -- our automake code (in particular
  99 # common.am) uses some constructs specific to gmake.
 100 AM_INIT_AUTOMAKE([1.12 -Wno-portability foreign])
 101 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
 102 AM_SILENT_RULES([yes])
 103 AC_CONFIG_HEADERS([config.h])
 104
 105 AC_PATH_PROG([PERL], [perl])
 106 PKG_PROG_PKG_CONFIG
 107
 108 dnl default is to match previous behavior
 109 exampledir=${sysconfdir}
 110 AC_ARG_ENABLE([exampledir],
 111           AS_HELP_STRING([--enable-exampledir],
 112                          [specify alternate directory for examples]),
 113                          exampledir="$enableval",)
 114 dnl XXX add --exampledir to autoconf standard directory list somehow
 115 AC_SUBST([exampledir])
 116
 117 dnl default is to match previous behavior
 118 pkgsrcrcdir=""
 119 AC_ARG_ENABLE([pkgsrcrcdir],
 120           AS_HELP_STRING([--enable-pkgsrcrcdir],
 121                          [specify directory for rc.d scripts]),
 122                          pkgsrcrcdir="$enableval",)
 123 dnl XXX add --pkgsrcrcdir to autoconf standard directory list somehow
 124 AC_SUBST([pkgsrcrcdir])
 125 AM_CONDITIONAL([PKGSRC], [test "$pkgsrcrcdir" != ""])
 126
 127 AC_ARG_WITH([moduledir], [AS_HELP_STRING([--with-moduledir=DIR], [module directory (${libdir}/frr/modules)])], [
 128         moduledir="$withval"
 129 ], [
 130         moduledir="\${libdir}/frr/modules"
 131 ])
 132 AC_SUBST([moduledir], [$moduledir])
 133
 134
 135 AC_ARG_WITH([yangmodelsdir], [AS_HELP_STRING([--with-yangmodelsdir=DIR], [yang models directory (${datarootdir}/yang)])], [
 136         yangmodelsdir="$withval"
 137 ], [
 138         yangmodelsdir="\${datarootdir}/yang"
 139 ])
 140 AC_SUBST([yangmodelsdir])
 141
 142 AC_ARG_ENABLE(tcmalloc,
 143         AS_HELP_STRING([--enable-tcmalloc], [Turn on tcmalloc]),
 144 [case "${enableval}" in
 145   yes) tcmalloc_enabled=true
 146 LIBS="$LIBS -ltcmalloc_minimal"
 147  ;;
 148   no)  tcmalloc_enabled=false ;;
 149   *) AC_MSG_ERROR([bad value ${enableval} for --enable-tcmalloc]) ;;
 150 esac],[tcmalloc_enabled=false])
 151
 152
 153 dnl Thanks autoconf, but we don't want a default -g -O2.  We have our own
 154 dnl flag determination logic.
 155 CFLAGS="${CFLAGS:-}"
 156
 157 dnl --------------------
 158 dnl Check CC and friends
 159 dnl --------------------
 160 dnl note orig_cflags is also used further down
 161 orig_cflags="$CFLAGS"
 162 orig_cxxflags="$CXXFLAGS"
 163 AC_LANG([C])
 164 AC_PROG_CC
 165 AC_PROG_CPP
 166 AC_PROG_CXX
 167 AM_PROG_CC_C_O
 168 dnl remove autoconf default "-g -O2"
 169 CFLAGS="$orig_cflags"
 170 CXXFLAGS="$orig_cxxflags"
 171 AC_PROG_CC_C99
 172 dnl NB: see C11 below
 173
 174 PKG_PROG_PKG_CONFIG
 175
 176 dnl it's 2019, sed is sed.
 177 SED=sed
 178 AC_SUBST([SED])
 179
 180 dnl try and enable CFLAGS that are useful for FRR
 181 dnl - specifically, options to control warnings
 182
 183 AC_USE_SYSTEM_EXTENSIONS
 184 AC_DEFUN([AC_C_FLAG], [{
 185     m4_pushdef([cachename],[m4_translit([frr_cv_$1],[ =-+/{}$],[________])])
 186     AC_CACHE_CHECK([[whether $CC supports $1]], cachename, [
 187         AC_LANG_PUSH([C])
 188         ac_c_flag_save="$CFLAGS"
 189         CFLAGS="$CFLAGS $1"
 190         AC_COMPILE_IFELSE(
 191                 [AC_LANG_PROGRAM([[$4]])],
 192                 [
 193                         cachename=yes
 194                 ], [
 195                         cachename=no
 196                 ])
 197         CFLAGS="$ac_c_flag_save"
 198         AC_LANG_POP([C])
 199     ])
 200     if test "$cachename" = "yes"; then
 201         m4_if([$3], [], [CFLAGS="$CFLAGS $1"], [$3])
 202     else
 203         :
 204         $2
 205     fi
 206     m4_popdef([cachename])
 207 }])
 208
 209 AC_DEFUN([AC_LINK_IFELSE_FLAGS], [{
 210         AC_LANG_PUSH([C])
 211         ac_cflags_save="$CFLAGS"
 212         ac_libs_save="$LIBS"
 213         CFLAGS="$CFLAGS $1"
 214         LIBS="$LIBS $2"
 215         AC_LINK_IFELSE(
 216                 [$3],
 217                 [
 218                         CFLAGS="$ac_cflags_save"
 219                         LIBS="$ac_libs_save"
 220                         m4_default([$5], [
 221                                 AC_MSG_RESULT([yes])
 222                         ])
 223                 ], [
 224                         CFLAGS="$ac_cflags_save"
 225                         LIBS="$ac_libs_save"
 226                         m4_default([$4], [
 227                                 AC_MSG_RESULT([no])
 228                         ])
 229                 ])
 230         AC_LANG_POP([C])
 231         }])
 232
 233 dnl ICC won't bail on unknown options without -diag-error 10006
 234 dnl need to do this first so we get useful results for the other options
 235 AC_C_FLAG([-diag-error 10006])
 236
 237 dnl AC_PROG_CC_C99 may change CC to include -std=gnu99 or something
 238 ac_cc="$CC"
 239 CC="${CC% -std=gnu99}"
 240 CC="${CC% -std=c99}"
 241
 242 AC_C_FLAG([-std=gnu11], [CC="$ac_cc"], [CC="$CC -std=gnu11"])
 243
 244 dnl if the user has specified any CFLAGS, override our settings
 245 if test "$enable_gcov" = "yes"; then
 246    if test "$orig_cflags" = ""; then
 247       AC_C_FLAG([-coverage])
 248       AC_C_FLAG([-O0])
 249    fi
 250
 251    LDFLAGS="${LDFLAGS} -lgcov"
 252 fi
 253
 254 if test "$enable_clang_coverage" = "yes"; then
 255    AC_C_FLAG([-fprofile-instr-generate], [
 256      AC_MSG_ERROR([$CC does not support -fprofile-instr-generate.])
 257    ])
 258    AC_C_FLAG([-fcoverage-mapping], [
 259      AC_MSG_ERROR([$CC does not support -fcoverage-mapping.])
 260    ])
 261 fi
 262
 263 if test "$enable_dev_build" = "yes"; then
 264    AC_DEFINE([DEV_BUILD], [1], [Build for development])
 265    if test "$orig_cflags" = ""; then
 266       AC_C_FLAG([-g3])
 267       AC_C_FLAG([-O0])
 268    fi
 269    if test "$enable_lua" = "yes"; then
 270       AX_PROG_LUA([5.3])
 271       AX_LUA_HEADERS
 272       AX_LUA_LIBS([
 273          AC_DEFINE([HAVE_LUA], [1], [Have support for Lua interpreter])
 274          LIBS="$LIBS $LUA_LIB"
 275       ])
 276    fi
 277 else
 278    if test "$enable_lua" = "yes"; then
 279       AC_MSG_ERROR([Lua is not meant to be built/used outside of development at this time])
 280    fi
 281    if test "$orig_cflags" = ""; then
 282       AC_C_FLAG([-g])
 283       AC_C_FLAG([-O2])
 284    fi
 285 fi
 286 AM_CONDITIONAL([DEV_BUILD], [test "$enable_dev_build" = "yes"])
 287
 288 dnl always want these CFLAGS
 289 AC_C_FLAG([-fno-omit-frame-pointer])
 290 AC_C_FLAG([-funwind-tables])
 291 AC_C_FLAG([-Wall])
 292 AC_C_FLAG([-Wextra])
 293 AC_C_FLAG([-Wmissing-prototypes])
 294 AC_C_FLAG([-Wmissing-declarations])
 295 AC_C_FLAG([-Wpointer-arith])
 296 AC_C_FLAG([-Wbad-function-cast])
 297 AC_C_FLAG([-Wwrite-strings])
 298 AC_C_FLAG([-Wundef])
 299 if test "$enable_gcc_ultra_verbose" = "yes" ; then
 300   AC_C_FLAG([-Wcast-qual])
 301   AC_C_FLAG([-Wstrict-prototypes])
 302   AC_C_FLAG([-Wmissing-noreturn])
 303   AC_C_FLAG([-Wmissing-format-attribute])
 304   AC_C_FLAG([-Wunreachable-code])
 305   AC_C_FLAG([-Wpacked])
 306   AC_C_FLAG([-Wpadded])
 307   AC_C_FLAG([-Wshadow])
 308 else
 309   AC_C_FLAG([-Wno-unused-result])
 310 fi
 311 AC_C_FLAG([-Wno-unused-parameter])
 312 AC_C_FLAG([-Wno-missing-field-initializers])
 313
 314 AC_C_FLAG([-Wc++-compat], [], [CXX_COMPAT_CFLAGS="-Wc++-compat"])
 315 AC_SUBST([CXX_COMPAT_CFLAGS])
 316
 317 dnl ICC emits a broken warning for const char *x = a ? "b" : "c";
 318 dnl for some reason the string consts get 'promoted' to char *,
 319 dnl triggering a const to non-const conversion warning.
 320 AC_C_FLAG([-diag-disable 3179])
 321
 322 if test "$enable_werror" = "yes" ; then
 323   WERROR="-Werror"
 324 fi
 325 AC_SUBST([WERROR])
 326
 327 SAN_FLAGS=""
 328 if test "$enable_address_sanitizer" = "yes"; then
 329   AC_C_FLAG([-fsanitize=address], [
 330     AC_MSG_ERROR([$CC does not support Address Sanitizer.])
 331   ], [
 332     SAN_FLAGS="$SAN_FLAGS -fsanitize=address"
 333   ])
 334 fi
 335 if test "$enable_thread_sanitizer" = "yes"; then
 336   AC_C_FLAG([-fsanitize=thread], [
 337     AC_MSG_ERROR([$CC does not support Thread Sanitizer.])
 338   ], [
 339     SAN_FLAGS="$SAN_FLAGS -fsanitize=thread"
 340   ])
 341 fi
 342 if test "$enable_memory_sanitizer" = "yes"; then
 343   AC_C_FLAG([-fsanitize=memory -fPIE -pie], [
 344     AC_MSG_ERROR([$CC does not support Memory Sanitizer.])
 345   ], [
 346     SAN_FLAGS="$SAN_FLAGS -fsanitize=memory -fPIE -pie"
 347   ])
 348 fi
 349 if test "$enable_undefined_sanitizer" = "yes"; then
 350   AC_C_FLAG([-fsanitize=undefined], [
 351     AC_MSG_ERROR([$CC does not support UndefinedBehaviorSanitizer.])
 352   ], [
 353     SAN_FLAGS="$SAN_FLAGS -fsanitize=undefined"
 354   ])
 355 fi
 356 AC_SUBST([SAN_FLAGS])
 357
 358 dnl frr-format.so
 359 if test "$with_frr_format" != "no" -a "$with_frr_format" != "yes" -a -n "$with_frr_format"; then
 360   AC_C_FLAG([-fplugin=${with_frr_format}], [
 361     AC_MSG_ERROR([specified frr-format plugin ($with_frr_format) does not work])
 362   ],,[
 363 #ifndef _FRR_ATTRIBUTE_PRINTFRR
 364 #error plugin not loaded
 365 #endif
 366 #if _FRR_ATTRIBUTE_PRINTFRR < 0x10000
 367 #error plugin too old
 368 #endif
 369   ])
 370 elif test "$with_frr_format" = "no"; then
 371   : #nothing
 372 else
 373   AC_C_FLAG([-fplugin=tools/gcc-plugins/frr-format.so],[
 374     AC_C_FLAG([-fplugin=frr-format],[
 375       if test "$with_frr_format" = "yes"; then
 376         AC_MSG_ERROR([frr-format plugin requested but not found])
 377       fi
 378     ],,[
 379 #ifndef _FRR_ATTRIBUTE_PRINTFRR
 380 #error plugin not loaded
 381 #endif
 382 #if _FRR_ATTRIBUTE_PRINTFRR < 0x10000
 383 #error plugin too old
 384 #endif
 385     ])
 386   ],,[
 387 #ifndef _FRR_ATTRIBUTE_PRINTFRR
 388 #error plugin not loaded
 389 #endif
 390 #if _FRR_ATTRIBUTE_PRINTFRR < 0x10000
 391 #error plugin too old
 392 #endif
 393   ])
 394 fi
 395
 396 dnl ----------
 397 dnl Essentials
 398 dnl ----------
 399
 400 AX_PTHREAD([
 401   CC="$PTHREAD_CC"
 402   CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 403   LIBS="$PTHREAD_LIBS $LIBS"
 404 ], [
 405   AC_MSG_FAILURE([This FRR version needs pthreads])
 406 ])
 407
 408 AC_SEARCH_LIBS([pthread_condattr_setclock], [],
 409                 [frr_cv_pthread_condattr_setclock=yes],
 410                 [frr_cv_pthread_condattr_setclock=no])
 411 if test "$frr_cv_pthread_condattr_setclock" = "yes"; then
 412   AC_DEFINE([HAVE_PTHREAD_CONDATTR_SETCLOCK], [1], [Have pthread.h pthread_condattr_setclock])
 413 fi
 414
 415 dnl --------------
 416 dnl Check programs
 417 dnl --------------
 418 AC_PROG_INSTALL
 419 AC_PROG_LN_S
 420 AC_CHECK_TOOL([AR], [ar])
 421
 422 dnl -------
 423 dnl libtool
 424 dnl -------
 425 AC_ARG_ENABLE([static-bin],
 426   AS_HELP_STRING([--enable-static-bin], [link binaries statically]))
 427 LT_INIT
 428 _LT_CONFIG_LIBTOOL([
 429   patch -N -i "${srcdir}/m4/libtool-whole-archive.patch" libtool >&AS_MESSAGE_LOG_FD || \
 430     AC_MSG_WARN([Could not patch libtool for static linking support.  Loading modules into a statically linked daemon will fail.])
 431   sed -e 's%func_warning "relinking%true #\0%' -i libtool || true
 432   sed -e 's%func_warning "remember to run%true #\0%' -i libtool || true
 433   sed -e 's%func_warning ".*has not been installed in%true #\0%' -i libtool || true
 434 ])
 435 if test "$enable_static_bin" = "yes"; then
 436   AC_LDFLAGS="-static"
 437   if test "$enable_static" != "yes"; then
 438     AC_MSG_ERROR([The --enable-static-bin option must be combined with --enable-static.])
 439   fi
 440 fi
 441 if test "$enable_shared" != "yes"; then
 442   AC_MSG_ERROR([FRR cannot be built with --disable-shared.  If you want statically linked daemons, use --enable-shared --enable-static --enable-static-bin])
 443 fi
 444 AC_SUBST([AC_LDFLAGS])
 445 AM_CONDITIONAL([STATIC_BIN], [test "$enable_static_bin" = "yes"])
 446
 447 dnl $AR and $RANLIB are set by LT_INIT above
 448 AC_MSG_CHECKING([whether $AR supports D option])
 449 if $AR crD conftest.a >/dev/null 2>/dev/null; then
 450   AC_MSG_RESULT([yes])
 451   dnl ARFLAGS is for automake, AR_FLAGS for libtool m-(
 452   ARFLAGS="crD"
 453   AR_FLAGS="crD"
 454 else
 455   AC_MSG_RESULT([no])
 456   ARFLAGS="cru"
 457   AR_FLAGS="cru"
 458 fi
 459 AC_SUBST([ARFLAGS])
 460 AC_SUBST([AR_FLAGS])
 461
 462 AC_MSG_CHECKING([whether $RANLIB supports D option])
 463 if $RANLIB -D conftest.a >conftest.err 2>&1; then
 464   if grep -q -- '-D' conftest.err; then
 465     AC_MSG_RESULT([no])
 466   else
 467     AC_MSG_RESULT([yes])
 468     RANLIB="$RANLIB -D"
 469   fi
 470 else
 471   AC_MSG_RESULT([no])
 472 fi
 473 AC_SUBST([RANLIB])
 474
 475 test -f conftest.err && rm conftest.err
 476 test -f conftest.a && rm conftest.a
 477
 478 dnl ----------------------
 479 dnl Packages configuration
 480 dnl ----------------------
 481 if test -f config.version; then
 482   . ./config.version
 483 elif test -f "${srcdir}/config.version"; then
 484   . "${srcdir}/config.version"
 485 fi
 486 AC_ARG_WITH([pkg-extra-version],
 487   AS_HELP_STRING([--with-pkg-extra-version=VER], [add extra version field, for packagers/distributions]), [
 488   if test "$withval" = "no"; then
 489     EXTRAVERSION=
 490   else
 491     EXTRAVERSION=$withval
 492   fi
 493 ], [])
 494 AC_ARG_WITH([pkg-git-version],
 495         AS_HELP_STRING([--with-pkg-git-version], [add git information to MOTD and build version string]),
 496         [ test "$withval" != "no" && with_pkg_git_version="yes" ])
 497 AC_ARG_WITH([clippy],
 498   AS_HELP_STRING([--with-clippy=PATH], [use external clippy helper program]))
 499 AC_ARG_WITH([vtysh_pager],
 500         AS_HELP_STRING([--with-vtysh-pager=PAGER], [control what pager is compiled in as default]),
 501         VTYSH_PAGER=$withval, VTYSH_PAGER="more")
 502 AC_ARG_ENABLE([vtysh],
 503   AS_HELP_STRING([--disable-vtysh], [do not build integrated vty shell for FRR]))
 504 AC_ARG_ENABLE([doc],
 505   AS_HELP_STRING([--disable-doc], [do not build docs]))
 506 AC_ARG_ENABLE([doc-html],
 507   AS_HELP_STRING([--enable-doc-html], [build HTML docs]))
 508 AC_ARG_ENABLE([zebra],
 509   AS_HELP_STRING([--disable-zebra], [do not build zebra daemon]))
 510 AC_ARG_ENABLE([bgpd],
 511   AS_HELP_STRING([--disable-bgpd], [do not build bgpd]))
 512 AC_ARG_ENABLE([ripd],
 513   AS_HELP_STRING([--disable-ripd], [do not build ripd]))
 514 AC_ARG_ENABLE([ripngd],
 515   AS_HELP_STRING([--disable-ripngd], [do not build ripngd]))
 516 AC_ARG_ENABLE([ospfd],
 517   AS_HELP_STRING([--disable-ospfd], [do not build ospfd]))
 518 AC_ARG_ENABLE([ospf6d],
 519   AS_HELP_STRING([--disable-ospf6d], [do not build ospf6d]))
 520 AC_ARG_ENABLE([ldpd],
 521   AS_HELP_STRING([--disable-ldpd], [do not build ldpd]))
 522 AC_ARG_ENABLE([nhrpd],
 523   AS_HELP_STRING([--disable-nhrpd], [do not build nhrpd]))
 524 AC_ARG_ENABLE([eigrpd],
 525   AS_HELP_STRING([--disable-eigrpd], [do not build eigrpd]))
 526 AC_ARG_ENABLE([babeld],
 527   AS_HELP_STRING([--disable-babeld], [do not build babeld]))
 528 AC_ARG_ENABLE([watchfrr],
 529   AS_HELP_STRING([--disable-watchfrr], [do not build watchfrr]))
 530 AC_ARG_ENABLE([isisd],
 531   AS_HELP_STRING([--disable-isisd], [do not build isisd]))
 532 AC_ARG_ENABLE([pimd],
 533   AS_HELP_STRING([--disable-pimd], [do not build pimd]))
 534 AC_ARG_ENABLE([pbrd],
 535   AS_HELP_STRING([--disable-pbrd], [do not build pbrd]))
 536 AC_ARG_ENABLE([sharpd],
 537   AS_HELP_STRING([--enable-sharpd], [build sharpd]))
 538 AC_ARG_ENABLE([staticd],
 539   AS_HELP_STRING([--disable-staticd], [do not build staticd]))
 540 AC_ARG_ENABLE([fabricd],
 541   AS_HELP_STRING([--disable-fabricd], [do not build fabricd]))
 542 AC_ARG_ENABLE([vrrpd],
 543   AS_HELP_STRING([--disable-vrrpd], [do not build vrrpd]))
 544 AC_ARG_ENABLE([bgp-announce],
 545   AS_HELP_STRING([--disable-bgp-announce], [turn off BGP route announcement]))
 546 AC_ARG_ENABLE([bgp-vnc],
 547   AS_HELP_STRING([--disable-bgp-vnc],[turn off BGP VNC support]))
 548 AC_ARG_ENABLE([bgp-bmp],
 549   AS_HELP_STRING([--disable-bgp-bmp],[turn off BGP BMP support]))
 550 AC_ARG_ENABLE([snmp],
 551   AS_HELP_STRING([--enable-snmp], [enable SNMP support for agentx]))
 552 AC_ARG_ENABLE([config_rollbacks],
 553   AS_HELP_STRING([--enable-config-rollbacks], [enable configuration rollbacks (requires sqlite3)]))
 554 AC_ARG_ENABLE([confd],
 555   AS_HELP_STRING([--enable-confd=ARG], [enable confd integration]))
 556 AC_ARG_ENABLE([sysrepo],
 557   AS_HELP_STRING([--enable-sysrepo], [enable sysrepo integration]))
 558 AC_ARG_ENABLE([grpc],
 559   AS_HELP_STRING([--enable-grpc], [enable the gRPC northbound plugin]))
 560 AC_ARG_ENABLE([zeromq],
 561   AS_HELP_STRING([--enable-zeromq], [enable ZeroMQ handler (libfrrzmq)]))
 562 AC_ARG_WITH([libpam],
 563   AS_HELP_STRING([--with-libpam], [use libpam for PAM support in vtysh]))
 564 AC_ARG_ENABLE([ospfapi],
 565   AS_HELP_STRING([--disable-ospfapi], [do not build OSPFAPI to access the OSPF LSA Database]))
 566 AC_ARG_ENABLE([ospfclient],
 567   AS_HELP_STRING([--disable-ospfclient], [do not build OSPFAPI client for OSPFAPI,
 568                           (this is the default if --disable-ospfapi is set)]))
 569 AC_ARG_ENABLE([multipath],
 570   AS_HELP_STRING([--enable-multipath=ARG], [enable multipath function, ARG must be digit]))
 571 AC_ARG_ENABLE([user],
 572   AS_HELP_STRING([--enable-user=USER], [user to run FRR suite as (default frr)]))
 573 AC_ARG_ENABLE([group],
 574   AS_HELP_STRING([--enable-group=GROUP], [group to run FRR suite as (default frr)]))
 575 AC_ARG_ENABLE([vty_group],
 576   AS_HELP_STRING([--enable-vty-group=ARG], [set vty sockets to have specified group as owner]))
 577 AC_ARG_ENABLE([configfile_mask],
 578   AS_HELP_STRING([--enable-configfile-mask=ARG], [set mask for config files]))
 579 AC_ARG_ENABLE([logfile_mask],
 580   AS_HELP_STRING([--enable-logfile-mask=ARG], [set mask for log files]))
 581 AC_ARG_ENABLE([shell_access],
 582   AS_HELP_STRING([--enable-shell-access], [Allow users to access shell/telnet/ssh]))
 583 AC_ARG_ENABLE([realms],
 584   AS_HELP_STRING([--enable-realms], [enable REALMS support under Linux]))
 585 AC_ARG_ENABLE([rtadv],
 586   AS_HELP_STRING([--disable-rtadv], [disable IPV6 router advertisement feature]))
 587 AC_ARG_ENABLE([irdp],
 588   AS_HELP_STRING([--disable-irdp], [disable IRDP server support in zebra (enabled by default if supported)]))
 589 AC_ARG_ENABLE([capabilities],
 590   AS_HELP_STRING([--disable-capabilities], [disable using POSIX capabilities]))
 591 AC_ARG_ENABLE([rusage],
 592   AS_HELP_STRING([--disable-rusage], [disable using getrusage]))
 593 AC_ARG_ENABLE([gcc_ultra_verbose],
 594   AS_HELP_STRING([--enable-gcc-ultra-verbose], [enable ultra verbose GCC warnings]))
 595 AC_ARG_ENABLE([backtrace],
 596   AS_HELP_STRING([--disable-backtrace], [disable crash backtraces (default autodetect)]))
 597 AC_ARG_ENABLE([time-check],
 598   AS_HELP_STRING([--disable-time-check], [disable slow thread warning messages]))
 599 AC_ARG_ENABLE([cpu-time],
 600   AS_HELP_STRING([--disable-cpu-time], [disable cpu usage data gathering]))
 601 AC_ARG_ENABLE([pcreposix],
 602   AS_HELP_STRING([--enable-pcreposix], [enable using PCRE Posix libs for regex functions]))
 603 AC_ARG_ENABLE([fpm],
 604   AS_HELP_STRING([--enable-fpm], [enable Forwarding Plane Manager support]))
 605 AC_ARG_ENABLE([systemd],
 606   AS_HELP_STRING([--enable-systemd], [enable Systemd support]))
 607 AC_ARG_ENABLE([werror],
 608   AS_HELP_STRING([--enable-werror], [enable -Werror (recommended for developers only)]))
 609 AC_ARG_ENABLE([cumulus],
 610   AS_HELP_STRING([--enable-cumulus], [enable Cumulus Switch Special Extensions]))
 611 AC_ARG_ENABLE([datacenter],
 612   AS_HELP_STRING([--enable-datacenter], [enable Compilation for Data Center Extensions]))
 613 AC_ARG_ENABLE([rr-semantics],
 614   AS_HELP_STRING([--disable-rr-semantics], [disable the v6 Route Replace semantics]))
 615 AC_ARG_ENABLE([protobuf],
 616   AS_HELP_STRING([--enable-protobuf], [Enable experimental protobuf support]))
 617 AC_ARG_ENABLE([oldvpn_commands],
 618   AS_HELP_STRING([--enable-oldvpn-commands], [Keep old vpn commands]))
 619 AC_ARG_ENABLE([rpki],
 620   AS_HELP_STRING([--enable-rpki], [enable RPKI prefix validation support]))
 621 AC_ARG_ENABLE([clippy-only],
 622   AS_HELP_STRING([--enable-clippy-only], [Only build clippy]))
 623 AC_ARG_ENABLE([numeric_version],
 624   AS_HELP_STRING([--enable-numeric-version], [Only numeric digits allowed in version (for Alpine)]))
 625 AC_ARG_ENABLE([gcov],
 626   AS_HELP_STRING([--enable-gcov], [Collect coverage information with gcov]))
 627 AC_ARG_ENABLE([clang_coverage],
 628   AS_HELP_STRING([--enable-clang-coverage], [Collect coverage information with Clang Coverage]))
 629 AC_ARG_ENABLE([bfdd],
 630   AS_HELP_STRING([--disable-bfdd], [do not build bfdd]))
 631 AC_ARG_ENABLE([address-sanitizer],
 632   AS_HELP_STRING([--enable-address-sanitizer], [enable AddressSanitizer support for detecting a wide variety of memory allocation and deallocation errors]))
 633 AC_ARG_ENABLE([thread-sanitizer],
 634   AS_HELP_STRING([--enable-thread-sanitizer], [enable ThreadSanitizer support for detecting data races]))
 635 AC_ARG_ENABLE([memory-sanitizer],
 636   AS_HELP_STRING([--enable-memory-sanitizer], [enable MemorySanitizer support for detecting uninitialized memory reads]))
 637 AC_ARG_ENABLE([undefined-sanitizer],
 638   AS_HELP_STRING([--undefined-sanitizer], [enable UndefinedBehaviorSanitizer support for detecting undefined behavior]))
 639 AC_ARG_WITH([crypto],
 640   AS_HELP_STRING([--with-crypto=<internal|openssl>], [choose between different implementations of cryptographic functions(default value is --with-crypto=internal)]))
 641 AC_ARG_WITH([frr-format],
 642   AS_HELP_STRING([--with-frr-format[=<.../frr-format.so>]], [use frr-format GCC plugin]))
 643
 644 AC_ARG_ENABLE([version-build-config],
 645   AS_HELP_STRING([--disable-version-build-config], [do not include build configs in show version command]))
 646
 647 #if openssl, else use the internal
 648 AS_IF([test "$with_crypto" = "openssl"], [
 649 AC_CHECK_LIB([crypto], [EVP_DigestInit], [LIBS="$LIBS -lcrypto"], [], [])
 650 if test "$ac_cv_lib_crypto_EVP_DigestInit" = "no"; then
 651   AC_MSG_ERROR([build with openssl has been specified but openssl library was not found on your system])
 652 else
 653   AC_DEFINE([CRYPTO_OPENSSL], [1], [Compile with openssl support])
 654 fi
 655 ], [test "$with_crypto" = "internal" || test "$with_crypto" = "" ], [AC_DEFINE([CRYPTO_INTERNAL], [1], [Compile with internal cryptographic implementation])
 656 ], [AC_MSG_ERROR([Unknown value for --with-crypto])]
 657 )
 658
 659 AS_IF([test "$enable_clippy_only" != "yes"], [
 660 AC_CHECK_HEADERS([json-c/json.h])
 661 AC_CHECK_LIB([json-c], [json_object_get], [LIBS="$LIBS -ljson-c"], [], [-lm])
 662 if test "$ac_cv_lib_json_c_json_object_get" = "no"; then
 663   AC_CHECK_LIB([json], [json_object_get], [LIBS="$LIBS -ljson"])
 664   if test "$ac_cv_lib_json_json_object_get" = "no"; then
 665       AC_MSG_ERROR([libjson is needed to compile])
 666   fi
 667 fi
 668 ])
 669
 670 AC_ARG_ENABLE([dev_build],
 671     AS_HELP_STRING([--enable-dev-build], [build for development]))
 672
 673 AC_ARG_ENABLE([lua],
 674     AS_HELP_STRING([--enable-lua], [Build Lua scripting]))
 675
 676 if test "$enable_time_check" != "no" ; then
 677   if test "$enable_time_check" = "yes" -o "$enable_time_check" = "" ; then
 678     AC_DEFINE([CONSUMED_TIME_CHECK], [5000000], [Consumed Time Check])
 679   else
 680     AC_DEFINE_UNQUOTED([CONSUMED_TIME_CHECK], [$enable_time_check], [Consumed Time Check])
 681   fi
 682 fi
 683
 684 case "${enable_cpu_time}" in
 685   "no")
 686   AC_DEFINE([EXCLUDE_CPU_TIME], [1], [Exclude getrusage data gathering])
 687   ;;
 688   "*")
 689   ;;
 690 esac
 691
 692 case "${enable_systemd}" in
 693   "no") ;;
 694   "yes")
 695   AC_CHECK_LIB([systemd], [sd_notify], [LIBS="$LIBS -lsystemd"])
 696   if test "$ac_cv_lib_systemd_sd_notify" = "no"; then
 697     AC_MSG_ERROR([enable systemd has been specified but systemd development env not found on your system])
 698   else
 699     AC_DEFINE([HAVE_SYSTEMD], [1], [Compile systemd support in])
 700   fi
 701   ;;
 702   "*") ;;
 703 esac
 704
 705 if test "$enable_rr_semantics" != "no" ; then
 706   AC_DEFINE([HAVE_V6_RR_SEMANTICS], [1], [Compile in v6 Route Replacement Semantics])
 707 fi
 708
 709 if test "$enable_datacenter" = "yes" ; then
 710   AC_DEFINE([HAVE_DATACENTER], [1], [Compile extensions for a DataCenter])
 711   AC_MSG_WARN([The --enable-datacenter compile time option is deprecated.  Please modify the init script to pass -F datacenter to the daemons instead.])
 712   DFLT_NAME="datacenter"
 713 else
 714   DFLT_NAME="traditional"
 715 fi
 716
 717 if test "$enable_cumulus" = "yes" ; then
 718   AC_DEFINE([HAVE_CUMULUS], [1], [Compile Special Cumulus Code in])
 719 fi
 720
 721 AC_SUBST([DFLT_NAME])
 722 AC_DEFINE_UNQUOTED([DFLT_NAME], ["$DFLT_NAME"], [Name of the configuration default set])
 723
 724 if test "$enable_shell_access" = "yes"; then
 725    AC_DEFINE([HAVE_SHELL_ACCESS], [1], [Allow user to use ssh/telnet/bash, be aware this is considered insecure])
 726 fi
 727
 728 #
 729 # Python for clippy
 730 #
 731
 732 AS_IF([test "$host" = "$build"], [
 733   FRR_PYTHON_DEV
 734 ], [
 735   FRR_PYTHON
 736 ])
 737
 738 FRR_PYTHON_MODULES([pytest])
 739
 740 if test "$enable_doc" != "no"; then
 741   FRR_PYTHON_MODULES([sphinx], , [
 742     if test "$enable_doc" = "yes"; then
 743       AC_MSG_ERROR([Documentation was explicitly requested with --enable-doc but sphinx is not available for $PYTHON. Please disable docs or install sphinx.])
 744     fi
 745   ])
 746 fi
 747 AM_CONDITIONAL([DOC], [test "$enable_doc" != "no" -a "$frr_py_mod_sphinx" != "false"])
 748 AM_CONDITIONAL([DOC_HTML], [test "$enable_doc_html" = "yes"])
 749
 750 FRR_PYTHON_MOD_EXEC([sphinx], [--version], [
 751   PYSPHINX="-m sphinx"
 752 ], [
 753   PYSPHINX="-c 'import sys; from sphinx import main; sys.exit(main(sys.argv))'"
 754 ])
 755 AC_SUBST([PYSPHINX])
 756
 757 #
 758 # Logic for old vpn commands support.
 759 #
 760 if test "$enable_oldvpn_commands" = "yes"; then
 761    AC_DEFINE([KEEP_OLD_VPN_COMMANDS], [1], [Define for compiling with old vpn commands])
 762 fi
 763
 764 #
 765 # End of logic for protobuf support.
 766 #
 767
 768 AC_MSG_CHECKING([if zebra should be configurable to send Route Advertisements])
 769 if test "$enable_rtadv" != "no"; then
 770   AC_MSG_RESULT([yes])
 771   AC_DEFINE([HAVE_RTADV], [1], [Enable IPv6 Routing Advertisement support])
 772 else
 773   AC_MSG_RESULT([no])
 774 fi
 775
 776 if test "$enable_user" = "no"; then
 777   enable_user=""
 778 else
 779   if test "$enable_user" = "yes" || test "$enable_user" = ""; then
 780     enable_user="frr"
 781   fi
 782   AC_DEFINE_UNQUOTED([FRR_USER], ["${enable_user}"], [frr User])
 783 fi
 784
 785 if test "$enable_group" = "no"; then
 786   enable_group=""
 787 else
 788   if test "$enable_group" = "yes" || test "$enable_group" = ""; then
 789     enable_group="frr"
 790   fi
 791   AC_DEFINE_UNQUOTED([FRR_GROUP], ["${enable_group}"], [frr Group])
 792 fi
 793
 794 if test "$enable_vty_group" = "yes" ; then
 795   AC_MSG_ERROR([--enable-vty-group requires a group as argument, not yes])
 796 elif test "$enable_vty_group" != ""; then
 797   if test "$enable_vty_group" != "no"; then
 798     AC_DEFINE_UNQUOTED([VTY_GROUP], ["${enable_vty_group}"], [VTY Sockets Group])
 799   fi
 800 fi
 801 AC_SUBST([enable_user])
 802 AC_SUBST([enable_group])
 803 AC_SUBST([enable_vty_group])
 804
 805 enable_configfile_mask=${enable_configfile_mask:-0600}
 806 AC_DEFINE_UNQUOTED([CONFIGFILE_MASK], [${enable_configfile_mask}], [Mask for config files])
 807 AC_SUBST([enable_configfile_mask])
 808
 809 enable_logfile_mask=${enable_logfile_mask:-0600}
 810 AC_DEFINE_UNQUOTED([LOGFILE_MASK], [${enable_logfile_mask}], [Mask for log files])
 811
 812 MPATH_NUM=16
 813
 814 case "${enable_multipath}" in
 815   0)
 816     MPATH_NUM=64
 817     ;;
 818   [[1-9]|[1-9][0-9]|[1-9][0-9][0-9]])
 819     MPATH_NUM="${enable_multipath}"
 820     ;;
 821   "")
 822     ;;
 823   *)
 824     AC_MSG_FAILURE([Please specify digit to enable multipath ARG])
 825     ;;
 826 esac
 827
 828 AC_DEFINE_UNQUOTED([MULTIPATH_NUM], [$MPATH_NUM], [Maximum number of paths for a route])
 829
 830 AC_DEFINE_UNQUOTED([VTYSH_PAGER], ["$VTYSH_PAGER"], [What pager to use])
 831
 832 dnl --------------------
 833 dnl Enable code coverage
 834 dnl --------------------
 835 AM_CONDITIONAL([HAVE_GCOV], [test "$enable_gcov" != "no"])
 836
 837 dnl ------------------------------------
 838 dnl Alpine only accepts numeric versions
 839 dnl ------------------------------------
 840 if test "$enable_numeric_version" != "" ; then
 841   VERSION="`echo ${VERSION} | tr -c -d '[[.0-9]]'`"
 842   PACKAGE_VERSION="`echo ${PACKAGE_VERSION} | tr -c -d '[[.0-9]]'`"
 843 fi
 844
 845 dnl -----------------------------------
 846 dnl Add extra version string to package
 847 dnl name, string and version fields.
 848 dnl -----------------------------------
 849 if test "$EXTRAVERSION" != "" ; then
 850   VERSION="${VERSION}${EXTRAVERSION}"
 851   PACKAGE_VERSION="${PACKAGE_VERSION}${EXTRAVERSION}"
 852   AC_SUBST(PACKAGE_EXTRAVERSION, ["${EXTRAVERSION}"])
 853   PACKAGE_STRING="${PACKAGE_STRING}${EXTRAVERSION}"
 854 fi
 855 AC_SUBST([EXTRAVERSION])
 856
 857 if test "$with_pkg_git_version" = "yes"; then
 858         if test -e "${srcdir}/.git"; then
 859                 AC_DEFINE([GIT_VERSION], [1], [include git version info])
 860         else    with_pkg_git_version="no"
 861                 AC_MSG_WARN([--with-pkg-git-version given, but this is not a git checkout])
 862         fi
 863 fi
 864 AM_CONDITIONAL([GIT_VERSION], [test "$with_pkg_git_version" = "yes"])
 865
 866 AC_CHECK_TOOL([OBJCOPY], [objcopy], [:])
 867 if test "$OBJCOPY" != ":"; then
 868   AC_CACHE_CHECK([for .interp value to use], [frr_cv_interp], [
 869     frr_cv_interp=""
 870     AC_LINK_IFELSE([AC_LANG_SOURCE([[int main() { return 0; }]])], [
 871       if $OBJCOPY -j.interp -Obinary conftest conftest.interp; then
 872         frr_cv_interp="`xargs -0 echo < conftest.interp`"
 873       fi
 874       test -f conftest.interp && rm conftest.interp
 875     ])
 876   ])
 877 fi
 878 if test -n "$frr_cv_interp"; then
 879   AC_DEFINE_UNQUOTED([INTERP], ["$frr_cv_interp"], [.interp value])
 880 fi
 881
 882 dnl -------------------------
 883 dnl Check other header files.
 884 dnl -------------------------
 885 AC_CHECK_HEADERS([stropts.h sys/ksym.h \
 886         linux/version.h asm/types.h])
 887
 888 ac_stdatomic_ok=false
 889 AC_DEFINE([FRR_AUTOCONF_ATOMIC], [1], [did autoconf checks for atomic funcs])
 890 AC_CHECK_HEADER([stdatomic.h],[
 891
 892   AC_MSG_CHECKING([whether _Atomic qualifier works])
 893   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 894 #include <stdatomic.h>
 895 int main(int argc, char **argv) {
 896   _Atomic int i = 0;
 897   return i;
 898 }
 899 ]])], [
 900     AC_DEFINE([HAVE_STDATOMIC_H], [1], [found stdatomic.h])
 901     AC_MSG_RESULT([yes])
 902     ac_stdatomic_ok=true
 903   ], [
 904     AC_MSG_RESULT([no])
 905   ])
 906 ])
 907
 908 AS_IF([$ac_stdatomic_ok], [true], [
 909   AC_MSG_CHECKING([for __atomic_* builtins])
 910   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 911 int main(int argc, char **argv) {
 912   volatile int i = 1;
 913   __atomic_store_n (&i, 0, __ATOMIC_RELEASE);
 914   return __atomic_load_n (&i, __ATOMIC_ACQUIRE);
 915 }
 916 ]])], [
 917     AC_DEFINE([HAVE___ATOMIC], [1], [found __atomic builtins])
 918     AC_MSG_RESULT([yes])
 919   ], [
 920     AC_MSG_RESULT([no])
 921
 922     dnl FreeBSD 9 has a broken stdatomic.h where _Atomic doesn't work
 923     AC_MSG_CHECKING([for __sync_* builtins])
 924     AC_LINK_IFELSE([AC_LANG_SOURCE([[
 925 int main(int argc, char **argv) {
 926   volatile int i = 1;
 927   __sync_fetch_and_sub (&i, 1);
 928   return __sync_val_compare_and_swap (&i, 0, 1);
 929 }
 930 ]])], [
 931       AC_DEFINE([HAVE___SYNC], [1], [found __sync builtins])
 932       AC_MSG_RESULT([yes])
 933
 934       AC_MSG_CHECKING([for __sync_swap builtin])
 935       AC_LINK_IFELSE([AC_LANG_SOURCE([[
 936 int main(int argc, char **argv) {
 937   volatile int i = 1;
 938   return __sync_swap (&i, 2);
 939 }
 940 ]])], [
 941         AC_DEFINE([HAVE___SYNC_SWAP], 1, [found __sync_swap builtin])
 942         AC_MSG_RESULT([yes])
 943       ], [
 944         AC_MSG_RESULT([no])
 945       ])
 946
 947     ], [
 948       AC_MSG_RESULT([no])
 949       AC_MSG_FAILURE([stdatomic.h unavailable and $CC has neither __atomic nor __sync builtins])
 950     ])
 951   ])
 952 ])
 953
 954 AC_CHECK_HEADERS([pthread_np.h],,, [
 955 #include <pthread.h>
 956 ])
 957 AC_CHECK_FUNCS([pthread_setname_np pthread_set_name_np pthread_getthreadid_np])
 958
 959 needsync=true
 960
 961 AS_IF([$needsync], [
 962   dnl Linux
 963   AC_MSG_CHECKING([for Linux futex() support])
 964   AC_LINK_IFELSE([AC_LANG_PROGRAM([
 965 #ifndef _GNU_SOURCE
 966 #define _GNU_SOURCE
 967 #endif
 968 #include <unistd.h>
 969 #include <limits.h>
 970 #include <sys/time.h>
 971 #include <sys/syscall.h>
 972 #include <linux/futex.h>
 973
 974 int main(void);
 975 ],
 976 [
 977 {
 978   return syscall(SYS_futex, NULL, FUTEX_WAIT, 0, NULL, NULL, 0);
 979 }
 980 ])], [
 981     AC_MSG_RESULT([yes])
 982     AC_DEFINE(HAVE_SYNC_LINUX_FUTEX,,Have Linux futex support)
 983     needsync=false
 984   ], [
 985     AC_MSG_RESULT([no])
 986   ])
 987 ])
 988
 989 AS_IF([$needsync], [
 990   dnl FreeBSD
 991   AC_MSG_CHECKING([for FreeBSD _umtx_op() support])
 992   AC_LINK_IFELSE([AC_LANG_PROGRAM([
 993 #include <errno.h>
 994 #include <stdlib.h>
 995 #include <sys/types.h>
 996 #include <sys/umtx.h>
 997 int main(void);
 998 ],
 999 [
1000 {
1001   return _umtx_op(NULL, UMTX_OP_WAIT_UINT, 0, NULL, NULL);
1002 }
1003 ])], [
1004     AC_MSG_RESULT([yes])
1005     AC_DEFINE(HAVE_SYNC_UMTX_OP,,Have FreeBSD _umtx_op() support)
1006     needsync=false
1007   ], [
1008     AC_MSG_RESULT([no])
1009   ])
1010 ])
1011
1012 AS_IF([$needsync], [
1013   dnl OpenBSD patch (not upstream at the time of writing this)
1014   dnl https://marc.info/?l=openbsd-tech&m=147299508409549&w=2
1015   AC_MSG_CHECKING([for OpenBSD futex() support])
1016   AC_LINK_IFELSE([AC_LANG_PROGRAM([
1017 #include <sys/futex.h>
1018 int main(void);
1019 ],
1020 [
1021 {
1022   return futex(NULL, FUTEX_WAIT, 0, NULL, NULL, 0);
1023 }
1024 ])], [
1025     AC_MSG_RESULT([yes])
1026     AC_DEFINE(HAVE_SYNC_OPENBSD_FUTEX,,Have OpenBSD futex support)
1027     needsync=false
1028   ], [
1029     AC_MSG_RESULT([no])
1030   ])
1031 ])
1032
1033 dnl Utility macro to avoid retyping includes all the time
1034 m4_define([FRR_INCLUDES],
1035 [#ifdef SUNOS_5
1036 #define _POSIX_C_SOURCE 200809L
1037 #define __EXTENSIONS__
1038 #endif
1039 #include <stdio.h>
1040 #include <stdlib.h>
1041 #include <stddef.h>
1042 #include <sys/types.h>
1043 /* sys/conf.h depends on param.h on FBSD at least */
1044 #include <sys/param.h>
1045 /* Required for MAXSIG */
1046 #include <signal.h>
1047 #include <sys/socket.h>
1048 #ifdef __APPLE__
1049 # define __APPLE_USE_RFC_3542
1050 #endif
1051 #include <netinet/in.h>
1052 #include <sys/time.h>
1053 #include <time.h>
1054 #include <net/if.h>
1055 ])dnl
1056
1057 dnl Same applies for HAVE_NET_IF_VAR_H, which HAVE_NETINET6_ND6_H and
1058 dnl HAVE_NETINET_IN_VAR_H depend upon. But if_var.h depends on if.h, hence
1059 dnl an additional round for it.
1060
1061 AC_CHECK_HEADERS([net/if_var.h], [], [], [FRR_INCLUDES])
1062
1063 m4_define([FRR_INCLUDES],
1064 FRR_INCLUDES
1065 [#ifdef HAVE_NET_IF_VAR_H
1066 # include <net/if_var.h>
1067 #endif
1068 ])dnl
1069
1070 AC_CHECK_HEADERS([netinet/in_var.h \
1071         net/if_dl.h net/netopt.h \
1072         inet/nd.h netinet/ip_icmp.h \
1073         sys/sysctl.h sys/sockio.h sys/conf.h],
1074         [], [], [FRR_INCLUDES])
1075
1076 AC_CHECK_HEADERS([ucontext.h], [], [],
1077 [#ifndef __USE_GNU
1078 #define __USE_GNU
1079 #endif /* __USE_GNU */
1080 FRR_INCLUDES
1081 ])
1082
1083 m4_define([UCONTEXT_INCLUDES],
1084 [#include <ucontext.h>])dnl
1085
1086 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.uc_regs],
1087   [], [], [UCONTEXT_INCLUDES])
1088 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs],
1089   [AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs.nip],
1090    [], [], [UCONTEXT_INCLUDES])],
1091   [], [UCONTEXT_INCLUDES])
1092 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.gregs],
1093   [], [], [UCONTEXT_INCLUDES])
1094
1095 m4_define([FRR_INCLUDES],
1096 FRR_INCLUDES
1097 [
1098 #include <sys/un.h>
1099 #include <netinet/in_systm.h>
1100 #ifdef HAVE_NETINET_IN_VAR_H
1101 # include <netinet/in_var.h>
1102 #endif
1103 #ifdef HAVE_NET_IF_DL_H
1104 # include <net/if_dl.h>
1105 #endif
1106 #ifdef HAVE_NET_NETOPT_H
1107 # include <net/netopt.h>
1108 #endif
1109 #include <net/route.h>
1110 #ifdef HAVE_INET_ND_H
1111 # include <inet/nd.h>
1112 #endif
1113 #include <arpa/inet.h>
1114 /* Required for IDRP */
1115 #ifdef HAVE_NETINET_IP_ICMP_H
1116 # include <netinet/ip_icmp.h>
1117 #endif
1118 ])dnl
1119
1120 dnl V6 headers are checked below, after we check for v6
1121
1122 is_linux=false
1123
1124 AC_MSG_CHECKING([which operating system interface to use])
1125 case "$host_os" in
1126   sunos* | solaris2*)
1127     AC_MSG_FAILURE([Solaris support has been removed please see versions prior or equal to 7.5])
1128     ;;
1129   linux*)
1130     AC_MSG_RESULT([Linux])
1131
1132     AC_DEFINE([GNU_LINUX], [1], [GNU Linux])
1133     AC_DEFINE([HAVE_NETLINK], [1], [netlink])
1134     AC_DEFINE([LINUX_IPV6], [1], [Linux IPv6 stack])
1135
1136     dnl Linux has a compilation problem with mixing
1137     dnl netinet/in.h and linux/in6.h they are not
1138     dnl compatible.  There has been discussion on
1139     dnl how to fix it but no real progress on implementation
1140     dnl when they fix it, remove this
1141     AC_DEFINE([IPV6_MINHOPCOUNT], [73], [Linux ipv6 Min Hop Count])
1142
1143     is_linux=true
1144     ;;
1145   openbsd*)
1146     AC_MSG_RESULT([OpenBSD])
1147
1148     AC_DEFINE([OPEN_BSD], [1], [OpenBSD])
1149     AC_DEFINE([KAME], [1], [KAME IPv6])
1150     AC_DEFINE([BSD_V6_SYSCTL], [1], [BSD v6 sysctl to turn on and off forwarding])
1151     ;;
1152   *)
1153     AC_MSG_RESULT([BSD])
1154
1155     AC_DEFINE([HAVE_NET_RT_IFLIST], [1], [NET_RT_IFLIST])
1156     AC_DEFINE([KAME], [1], [KAME IPv6])
1157     AC_DEFINE([BSD_V6_SYSCTL], [1], [BSD v6 sysctl to turn on and off forwarding])
1158     ;;
1159 esac
1160 AM_CONDITIONAL([LINUX], [${is_linux}])
1161
1162 AC_SYS_LARGEFILE
1163
1164 dnl ------------------------
1165 dnl Integrated REALMS option
1166 dnl ------------------------
1167 if test "$enable_realms" = "yes"; then
1168     case "$host_os" in
1169       linux*)
1170        AC_DEFINE([SUPPORT_REALMS], [1], [Realms support])
1171        ;;
1172       *)
1173        echo "Sorry, only Linux has REALMS support"
1174        exit 1
1175        ;;
1176     esac
1177 fi
1178
1179 dnl -------------------------------
1180 dnl Endian-ness check
1181 dnl -------------------------------
1182 AC_WORDS_BIGENDIAN
1183
1184 dnl ---------------
1185 dnl other functions
1186 dnl ---------------
1187 AC_CHECK_FUNCS([ \
1188         strlcat strlcpy \
1189         getgrouplist \
1190         openat \
1191         unlinkat \
1192         posix_fallocate \
1193         ])
1194
1195 dnl ##########################################################################
1196 dnl LARGE if block spans a lot of "configure"!
1197 if test "$enable_clippy_only" != "yes"; then
1198 dnl ##########################################################################
1199
1200 #
1201 # Logic for protobuf support.
1202 #
1203 PROTO3=false
1204 if test "$enable_protobuf" = "yes"; then
1205   # Check for protoc & protoc-c
1206
1207   # protoc is not required, it's only for a "be nice" helper target
1208   AC_CHECK_PROGS([PROTOC], [protoc], [/bin/false])
1209
1210   AC_CHECK_PROGS([PROTOC_C], [protoc-c], [/bin/false])
1211   if test "$PROTOC_C" = "/bin/false"; then
1212     AC_MSG_FAILURE([protobuf requested but protoc-c not found.  Install protobuf-c.])
1213   fi
1214
1215   PKG_CHECK_MODULES([PROTOBUF_C], [libprotobuf-c >= 0.14],, [
1216     AC_MSG_FAILURE([protobuf requested but libprotobuf-c not found.  Install protobuf-c.])
1217   ])
1218
1219   PROTO3=true
1220   AC_CHECK_HEADER([google/protobuf-c/protobuf-c.h],
1221                   [AC_CHECK_DECLS(PROTOBUF_C_LABEL_NONE,
1222                                   AC_DEFINE([HAVE_PROTOBUF_VERSION_3],
1223                                             [1], [Have Protobuf version 3]),
1224                                   [PROTO3=false],
1225                                   [#include <google/protobuf-c/protobuf-c.h>])],
1226                   [PROTO3=false && AC_MSG_FAILURE([protobuf requested but protobuf-c.h not found.  Install protobuf-c.])])
1227
1228   AC_DEFINE([HAVE_PROTOBUF], [1], [protobuf])
1229 fi
1230
1231
1232 dnl ---------------------
1233 dnl Integrated VTY option
1234 dnl ---------------------
1235 case "${enable_vtysh}" in
1236 "no")
1237   VTYSH="";;
1238 *)
1239   VTYSH="vtysh";
1240   AC_DEFINE([VTYSH], [1], [VTY shell])
1241
1242   prev_libs="$LIBS"
1243   AC_CHECK_LIB([readline], [main], [
1244     LIBREADLINE="-lreadline"
1245   ], [
1246     dnl readline failed - it might be incorrectly linked and missing its
1247     dnl termcap/tinfo/curses dependency.  see if we can fix that...
1248     AC_SEARCH_LIBS([tputs], [termcap tinfo curses ncurses], [
1249       LIBREADLINE="$ac_cv_search_tputs"
1250     ], [
1251       AC_MSG_ERROR([libreadline (needed for vtysh) not found and/or missing dependencies])
1252     ])
1253
1254     dnl re-try with the lib we found above
1255     unset ac_cv_lib_readline_main
1256     AC_CHECK_LIB([readline], [main], [
1257       LIBREADLINE="-lreadline $LIBREADLINE"
1258     ], [
1259       AC_MSG_ERROR([libreadline (needed for vtysh) not found and/or missing dependencies])
1260     ], [$LIBREADLINE])
1261   ], [])
1262   LIBS="$prev_libs"
1263
1264   AC_CHECK_HEADER([readline/history.h])
1265   if test "$ac_cv_header_readline_history_h" = "no"; then
1266     AC_MSG_ERROR([readline is too old to have readline/history.h, please update to the latest readline library.])
1267   fi
1268   AC_CHECK_LIB([readline], [rl_completion_matches], [true], [], [$LIBREADLINE])
1269   if test "$ac_cv_lib_readline_rl_completion_matches" = "no"; then
1270     AC_DEFINE([rl_completion_matches], [completion_matches], [Old readline])
1271   fi
1272   AC_CHECK_LIB([readline], [append_history], [frr_cv_append_history=yes], [frr_cv_append_history=no], [$LIBREADLINE])
1273   if test "$frr_cv_append_history" = "yes"; then
1274     AC_DEFINE([HAVE_APPEND_HISTORY], [1], [Have history.h append_history])
1275   fi
1276   ;;
1277 esac
1278 AC_SUBST([LIBREADLINE])
1279
1280 dnl ----------
1281 dnl PAM module
1282 dnl
1283 dnl FRR detects the PAM library it is built against by checking for a
1284 dnl functional pam_misc.h (Linux-PAM) or openpam.h (OpenPAM) header. pam_misc.h
1285 dnl is known to #include pam_appl.h, the standard header of a PAM library, and
1286 dnl openpam.h doesn't do that, although depends on the header too. Hence a
1287 dnl little assistance to AC_CHECK_HEADER is necessary for the proper detection
1288 dnl of OpenPAM.
1289 dnl ----------
1290 if test "$with_libpam" = "yes"; then
1291   AC_CHECK_HEADER([security/pam_misc.h],
1292     [AC_DEFINE([HAVE_PAM_MISC_H], [1], [Have pam_misc.h])
1293      AC_DEFINE([PAM_CONV_FUNC], [misc_conv], [Have misc_conv])
1294      pam_conv_func="misc_conv"
1295     ],
1296     [], FRR_INCLUDES)
1297   AC_CHECK_HEADER([security/openpam.h],
1298     [AC_DEFINE([HAVE_OPENPAM_H], [1], [Have openpam.h])
1299      AC_DEFINE([PAM_CONV_FUNC], [openpam_ttyconv], [Have openpam_ttyconv])
1300      pam_conv_func="openpam_ttyconv"
1301     ],
1302     [], FRR_INCLUDES[#include <security/pam_appl.h>])
1303   if test -z "$ac_cv_header_security_pam_misc_h$ac_cv_header_security_openpam_h" ; then
1304     AC_MSG_WARN([*** pam support will not be built ***])
1305     with_libpam="no"
1306   fi
1307 fi
1308
1309 if test "$with_libpam" = "yes"; then
1310 dnl took this test from proftpds configure.in and suited to our needs
1311 dnl -------------------------------------------------------------------------
1312 dnl
1313 dnl This next check looks funky due to a linker problem with some versions
1314 dnl of the PAM library.  Prior to 0.72 release, the Linux PAM shared library
1315 dnl omitted requiring libdl linking information. PAM-0.72 or better ships
1316 dnl with RedHat 6.2 and Debian 2.2 or better.
1317 AC_CHECK_LIB([pam], [pam_start],
1318   [AC_CHECK_LIB([pam], [$pam_conv_func],
1319     [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1320      LIBPAM="-lpam"],
1321     [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1322      LIBPAM="-lpam -lpam_misc"]
1323     )
1324   ],
1325
1326   [AC_CHECK_LIB([pam], [pam_end],
1327     [AC_CHECK_LIB([pam], [$pam_conv_func],
1328       [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1329        LIBPAM="-lpam -ldl"],
1330       [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1331        LIBPAM="-lpam -ldl -lpam_misc"]
1332      )
1333   ],AC_MSG_WARN([*** pam support will not be built ***]),
1334   [-ldl])
1335   ]
1336 )
1337 fi
1338 AC_SUBST([LIBPAM])
1339
1340 dnl -------------------------------
1341 dnl bgpd needs pow() and hence libm
1342 dnl -------------------------------
1343 TMPLIBS="$LIBS"
1344 LIBS=""
1345 AC_SEARCH_LIBS([pow], [m], [
1346   LIBM="$LIBS"
1347 ], [
1348   AC_MSG_WARN([Unable to find working pow function - bgpd may not link])
1349 ])
1350 LIBS="$TMPLIBS"
1351 AC_SUBST([LIBM])
1352
1353 AC_CHECK_FUNCS([ppoll], [
1354   AC_DEFINE([HAVE_PPOLL], [1], [have Linux/BSD ppoll()])
1355 ])
1356 AC_CHECK_FUNCS([pollts], [
1357   AC_DEFINE([HAVE_POLLTS], [1], [have NetBSD pollts()])
1358 ])
1359
1360 AC_CHECK_HEADER([asm-generic/unistd.h],
1361                 [AC_CHECK_DECL(__NR_setns,
1362                                AC_DEFINE([HAVE_NETNS], [1], [Have netns]),,
1363                                FRR_INCLUDES [#include <asm-generic/unistd.h>
1364                                ])
1365                  AC_CHECK_FUNCS([setns])]
1366                )
1367
1368 dnl --------------------------
1369 dnl Determine IS-IS I/O method
1370 dnl --------------------------
1371 AC_DEFINE([ISIS_METHOD_PFPACKET], [1], [constant value for isis method pfpacket])
1372 AC_DEFINE([ISIS_METHOD_DLPI], [2], [constant value for isis method dlpi])
1373 AC_DEFINE([ISIS_METHOD_BPF], [3], [constant value for isis method bpf])
1374 AC_CHECK_HEADER([net/bpf.h])
1375 AC_CHECK_HEADER([sys/dlpi.h])
1376 AC_MSG_CHECKING([zebra IS-IS I/O method])
1377
1378 case "$host_os" in
1379   linux*)
1380     AC_MSG_RESULT([pfpacket])
1381     ISIS_METHOD_MACRO="ISIS_METHOD_PFPACKET"
1382     ;;
1383   *)
1384     if test "$ac_cv_header_net_bpf_h" = "no"; then
1385       if test "$ac_cv_header_sys_dlpi_h" = "no"; then
1386         AC_MSG_RESULT([none])
1387         if test "$enable_isisd" = "yes" -o "$enable_fabricd" = "yes"; then
1388           AC_MSG_FAILURE([IS-IS support requested but no packet backend found])
1389         fi
1390         AC_MSG_WARN([*** IS-IS support will not be built ***])
1391         enable_isisd="no"
1392         enable_fabricd="no"
1393       else
1394         AC_MSG_RESULT([DLPI])
1395       fi
1396       ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1397     else
1398       AC_MSG_RESULT([BPF])
1399       ISIS_METHOD_MACRO="ISIS_METHOD_BPF"
1400     fi
1401     ;;
1402 esac
1403 AC_DEFINE_UNQUOTED([ISIS_METHOD], [$ISIS_METHOD_MACRO], [selected method for isis, == one of the constants])
1404
1405 dnl ---------------------------------------------------------------
1406 dnl figure out how to specify an interface in multicast sockets API
1407 dnl ---------------------------------------------------------------
1408 AC_CHECK_MEMBERS([struct ip_mreqn.imr_ifindex], [], [], FRR_INCLUDES)
1409
1410 AC_CHECK_HEADERS([linux/mroute.h], [], [],[
1411         #include <sys/socket.h>
1412         #include <netinet/in.h>
1413         #define _LINUX_IN_H             /* For Linux <= 2.6.25 */
1414         #include <linux/types.h>
1415 ])
1416
1417 m4_define([FRR_INCLUDES],
1418 FRR_INCLUDES
1419 [#ifdef HAVE_LINUX_MROUTE_H
1420 # include <linux/mroute.h>
1421 #endif
1422 ])dnl
1423
1424 AC_CHECK_HEADERS([netinet/ip_mroute.h], [], [],[
1425         #include <sys/socket.h>
1426         #include <sys/types.h>
1427         #include <netinet/in.h>
1428         #include <net/route.h>
1429 ])
1430
1431 m4_define([FRR_INCLUDES],
1432 FRR_INCLUDES
1433 [#ifdef HAVE_NETINET_IP_MROUTE_H
1434 # include <netinet/ip_mroute.h>
1435 #endif
1436 ])dnl
1437
1438 AC_MSG_CHECKING([for BSD struct ip_mreq hack])
1439 AC_TRY_COMPILE([#include <sys/param.h>],
1440 [#if (defined(__FreeBSD__) && ((__FreeBSD_version >= 500022 && __FreeBSD_version < 700000) || (__FreeBSD_version < 500000 && __FreeBSD_version >= 440000))) || (defined(__NetBSD__) && defined(__NetBSD_Version__) && __NetBSD_Version__ >= 106010000) || defined(__OpenBSD__) || defined(__APPLE__) || defined(__DragonFly__) || defined(__sun)
1441   return (0);
1442 #else
1443   #error No support for BSD struct ip_mreq hack detected
1444 #endif],[AC_MSG_RESULT([yes])
1445 AC_DEFINE([HAVE_BSD_STRUCT_IP_MREQ_HACK], [1], [Can pass ifindex in struct ip_mreq])],
1446 AC_MSG_RESULT([no]))
1447
1448 AC_MSG_CHECKING([for RFC3678 protocol-independed API])
1449 AC_TRY_COMPILE([
1450 #include <sys/types.h>
1451 #include <netinet/in.h>
1452 ], [struct group_req gr; int sock; setsockopt(sock, IPPROTO_IP, MCAST_JOIN_GROUP, (void*)&gr, sizeof(gr));
1453 ], [AC_MSG_RESULT([yes])
1454 AC_DEFINE([HAVE_RFC3678], [1], [Have RFC3678 protocol-independed API])],
1455 AC_MSG_RESULT([no]))
1456
1457 dnl ---------------------------------------------------------------
1458 dnl figure out how to check link-state
1459 dnl ---------------------------------------------------------------
1460 AC_CHECK_HEADER([net/if_media.h],
1461   [m4_define([LINK_DETECT_INCLUDES],
1462     FRR_INCLUDES
1463     [#include <net/if_media.h>
1464   ])
1465   AC_CHECK_MEMBERS([struct ifmediareq.ifm_status],
1466     AC_DEFINE([HAVE_BSD_LINK_DETECT], [1], [BSD link-detect]),
1467     [], LINK_DETECT_INCLUDES)],
1468   [],
1469   FRR_INCLUDES)
1470
1471 dnl ---------------------------------------------------------------
1472 dnl Additional, newer way to check link-state using ifi_link_state.
1473 dnl Not available in all BSD's when ifmediareq available
1474 dnl ---------------------------------------------------------------
1475 AC_CHECK_MEMBERS([struct if_data.ifi_link_state],
1476   AC_DEFINE([HAVE_BSD_IFI_LINK_STATE], [1], [BSD ifi_link_state available]),
1477   [], FRR_INCLUDES)
1478
1479 dnl ------------------------
1480 dnl TCP_MD5SIG socket option
1481 dnl ------------------------
1482
1483 AC_CHECK_HEADER([netinet/tcp.h],
1484    [m4_define([MD5_INCLUDES],
1485       FRR_INCLUDES
1486       [#include <netinet/tcp.h>
1487     ])
1488     AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)],
1489    [],
1490    FRR_INCLUDES)
1491 if test "$ac_cv_have_decl_TCP_MD5SIG" = "no"; then
1492   AC_CHECK_HEADER([linux/tcp.h],
1493        [m4_define([MD5_INCLUDES],
1494           FRR_INCLUDES
1495           [#include <linux/tcp.h>
1496         ])
1497        AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)])
1498 fi
1499
1500 AC_CHECK_LIB([crypt], [crypt], [],
1501                     [AC_CHECK_LIB([crypto], [DES_crypt])])
1502 AC_CHECK_LIB([resolv], [res_init])
1503
1504 dnl ---------------------------
1505 dnl check system has PCRE regexp
1506 dnl ---------------------------
1507 if test "$enable_pcreposix" = "yes"; then
1508   AC_CHECK_LIB([pcreposix], [regexec], [], [
1509     AC_MSG_ERROR([--enable-pcreposix given but unable to find libpcreposix])
1510   ])
1511 fi
1512 AC_SUBST([HAVE_LIBPCREPOSIX])
1513
1514 dnl ##########################################################################
1515 dnl test "$enable_clippy_only" != "yes"
1516 fi
1517 dnl END OF LARGE if block
1518 dnl ##########################################################################
1519
1520 dnl ------------------
1521 dnl check C-Ares library
1522 dnl ------------------
1523 PKG_CHECK_MODULES([CARES], [libcares], [
1524   c_ares_found=true
1525 ],[
1526   c_ares_found=false
1527 ])
1528 AM_CONDITIONAL([CARES], [$c_ares_found])
1529
1530
1531 dnl ----------------------------------------------------------------------------
1532 dnl figure out if domainname is available in the utsname struct (GNU extension).
1533 dnl ----------------------------------------------------------------------------
1534 AC_CHECK_MEMBERS([struct utsname.domainname], [], [], [#include <sys/utsname.h>])
1535
1536 dnl ------------------
1537 dnl IPv6 header checks
1538 dnl ------------------
1539 AC_CHECK_HEADERS([netinet6/in6.h netinet/in6_var.h \
1540         netinet6/in6_var.h netinet6/nd6.h], [], [],
1541         FRR_INCLUDES)
1542
1543 m4_define([FRR_INCLUDES],dnl
1544 FRR_INCLUDES
1545 [#ifdef HAVE_NETINET6_IN6_H
1546 #include <netinet6/in6.h>
1547 #endif
1548 #ifdef HAVE_NETINET_IN6_VAR_H
1549 #include <netinet/in6_var.h>
1550 #endif
1551 #include <netinet/icmp6.h>
1552 #ifdef HAVE_NETINET6_IN6_VAR_H
1553 # include <netinet6/in6_var.h>
1554 #endif
1555 #ifdef HAVE_NETINET6_ND6_H
1556 # include <netinet6/nd6.h>
1557 #endif
1558 ])dnl
1559
1560 dnl --------------------
1561 dnl Daemon disable check
1562 dnl --------------------
1563
1564 AS_IF([test "$enable_bgpd" != "no"], [
1565   AC_DEFINE([HAVE_BGPD], [1], [bgpd])
1566 ])
1567
1568 AS_IF([test "$enable_ripd" != "no"], [
1569   AC_DEFINE([HAVE_RIPD], [1], [ripd])
1570 ])
1571
1572 AS_IF([test "$enable_ripngd" != "no"], [
1573   AC_DEFINE([HAVE_RIPNGD], [1], [ripngd])
1574 ])
1575
1576 AS_IF([test "$enable_ospfd" != "no"], [
1577   AC_DEFINE([HAVE_OSPFD], [1], [ospfd])
1578 ])
1579
1580 AS_IF([test "$enable_ospf6d" != "no"], [
1581   AC_DEFINE([HAVE_OSPF6D], [1], [ospf6d])
1582 ])
1583
1584 AS_IF([test "$enable_ldpd" != "no"], [
1585   AC_DEFINE([HAVE_LDPD], [1], [ldpd])
1586 ])
1587
1588 AS_IF([test "$enable_nhrpd" != "no"], [
1589   AC_DEFINE([HAVE_NHRPD], [1], [nhrpd])
1590 ])
1591
1592 AS_IF([test "$enable_eigrpd" != "no"], [
1593   AC_DEFINE([HAVE_EIGRPD], [1], [eigrpd])
1594 ])
1595
1596 AS_IF([test "$enable_babeld" != "no"], [
1597   AC_DEFINE([HAVE_BABELD], [1], [babeld])
1598 ])
1599
1600 AS_IF([test "$enable_isisd" != "no"], [
1601   AC_DEFINE([HAVE_ISISD], [1], [isisd])
1602 ])
1603
1604 AS_IF([test "$enable_pimd" != "no"], [
1605   AC_DEFINE([HAVE_PIMD], [1], [pimd])
1606 ])
1607
1608 AS_IF([test "$enable_pbrd" != "no"], [
1609   AC_DEFINE([HAVE_PBRD], [1], [pbrd])
1610 ])
1611
1612 AS_IF([test "$enable_sharpd" = "yes"], [
1613   AC_DEFINE([HAVE_SHARPD], [1], [sharpd])
1614 ])
1615
1616 AS_IF([test "$enable_staticd" != "no"], [
1617   AC_DEFINE([HAVE_STATICD], [1], [staticd])
1618 ])
1619
1620 AS_IF([test "$enable_fabricd" != "no"], [
1621   AC_DEFINE([HAVE_FABRICD], [1], [fabricd])
1622 ])
1623
1624 AS_IF([test "$enable_vrrpd" != "no"], [
1625   AC_DEFINE([HAVE_VRRPD], [1], [vrrpd])
1626 ])
1627
1628 if test "$enable_bfdd" = "no"; then
1629   AC_DEFINE([HAVE_BFDD], [0], [bfdd])
1630   BFDD=""
1631 else
1632   AC_DEFINE([HAVE_BFDD], [1], [bfdd])
1633   BFDD="bfdd"
1634
1635   case $host_os in
1636     linux*)
1637       AC_DEFINE([BFD_LINUX], [1], [bfdd])
1638       ;;
1639
1640     *)
1641       AC_DEFINE([BFD_BSD], [1], [bfdd])
1642       ;;
1643   esac
1644 fi
1645
1646 if test "$ac_cv_lib_json_c_json_object_get" = "no" -a "$BFDD" = "bfdd"; then
1647   AC_MSG_ERROR(["you must use json-c library to use bfdd"])
1648 fi
1649
1650 NHRPD=""
1651 case "$host_os" in
1652   linux*)
1653     case "${enable_nhrpd}" in
1654       no)
1655         ;;
1656       yes)
1657         if test "$enable_clippy_only" != "yes"; then
1658         if test "$c_ares_found" != "true" ; then
1659           AC_MSG_ERROR([nhrpd requires libcares.  Please install c-ares and its -dev headers.])
1660         fi
1661         fi
1662         NHRPD="nhrpd"
1663         ;;
1664       *)
1665         if test "$c_ares_found" = "true" ; then
1666           NHRPD="nhrpd"
1667         fi
1668         ;;
1669     esac
1670     ;;
1671   *)
1672     if test "$enable_nhrpd" = "yes"; then
1673       AC_MSG_ERROR([nhrpd requires kernel APIs that are only present on Linux.])
1674     fi
1675     ;;
1676 esac
1677
1678 if test "$enable_watchfrr" = "no";then
1679   WATCHFRR=""
1680 else
1681   WATCHFRR="watchfrr"
1682 fi
1683
1684 OSPFCLIENT=""
1685 if test "$enable_ospfapi" != "no";then
1686     AC_DEFINE([SUPPORT_OSPF_API], [1], [OSPFAPI])
1687
1688   if test "$enable_ospfclient" != "no";then
1689       OSPFCLIENT="ospfclient"
1690   fi
1691 fi
1692
1693 if test "$enable_bgp_announce" = "no";then
1694   AC_DEFINE([DISABLE_BGP_ANNOUNCE], [1], [Disable BGP installation to zebra])
1695 else
1696   AC_DEFINE([DISABLE_BGP_ANNOUNCE], [0], [Disable BGP installation to zebra])
1697 fi
1698
1699 if test "$enable_bgp_vnc" != "no";then
1700   AC_DEFINE([ENABLE_BGP_VNC], [1], [Enable BGP VNC support])
1701 fi
1702
1703 bgpd_bmp=false
1704 case "${enable_bmp}" in
1705   no)
1706     ;;
1707   yes)
1708     if test "$c_ares_found" != "true" ; then
1709       AC_MSG_ERROR([BMP support requires libcares.  Please install c-ares and its -dev headers.])
1710     fi
1711     bgpd_bmp=true
1712     ;;
1713   *)
1714     if test "$c_ares_found" = "true" ; then
1715       bgpd_bmp=true
1716     fi
1717     ;;
1718 esac
1719
1720 if test "$enable_version_build_config" != "no";then
1721   AC_DEFINE([ENABLE_VERSION_BUILD_CONFIG], [1], [Report build configs in show version])
1722 fi
1723
1724 dnl ##########################################################################
1725 dnl LARGE if block
1726 if test "$enable_clippy_only" != "yes"; then
1727 dnl ##########################################################################
1728
1729 dnl ------------------
1730 dnl check Net-SNMP library
1731 dnl ------------------
1732 if test "$enable_snmp" != "" -a "$enable_snmp" != "no"; then
1733    AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], [no])
1734    if test "$NETSNMP_CONFIG" = "no"; then
1735       AC_MSG_ERROR([--enable-snmp given but unable to find net-snmp-config])
1736    fi
1737    SNMP_LIBS="`${NETSNMP_CONFIG} --agent-libs`"
1738    SNMP_CFLAGS="`${NETSNMP_CONFIG} --base-cflags`"
1739    # net-snmp lists all of its own dependencies.  we absolutely do not want that
1740    # among other things we avoid a GPL vs. OpenSSL license conflict here
1741    for removelib in crypto ssl sensors pci wrap; do
1742      SNMP_LIBS="`echo $SNMP_LIBS | sed -e 's/\(^\|\s\)-l'$removelib'\b/ /g' -e 's/\(^\|\s\)\([^\s]*\/\)\?lib'$removelib'\.[^\s]\+\b/ /g'`"
1743    done
1744    AC_MSG_CHECKING([whether we can link to Net-SNMP])
1745    AC_LINK_IFELSE_FLAGS([$SNMP_CFLAGS], [$SNMP_LIBS], [AC_LANG_PROGRAM([
1746 int main(void);
1747 ],
1748 [
1749 {
1750   return 0;
1751 }
1752 ])], [
1753      AC_MSG_RESULT([no])
1754      AC_MSG_ERROR([--enable-snmp given but not usable])])
1755    case "${enable_snmp}" in
1756      yes)
1757       SNMP_METHOD=agentx
1758       ;;
1759      agentx)
1760       SNMP_METHOD="${enable_snmp}"
1761       ;;
1762      *)
1763       AC_MSG_ERROR([--enable-snmp given with an unknown method (${enable_snmp}). Use yes or agentx])
1764       ;;
1765    esac
1766    AH_TEMPLATE([SNMP_AGENTX], [Use SNMP AgentX to interface with snmpd])
1767    AC_DEFINE_UNQUOTED(AS_TR_CPP(SNMP_${SNMP_METHOD}),,[SNMP method to interface with snmpd])
1768 fi
1769 AC_SUBST([SNMP_LIBS])
1770 AC_SUBST([SNMP_CFLAGS])
1771
1772 dnl ---------------
1773 dnl libyang
1774 dnl ---------------
1775 PKG_CHECK_MODULES([LIBYANG], [libyang >= 1.0.184], , [
1776   AC_MSG_ERROR([libyang (>= 1.0.184) was not found on your system.])
1777 ])
1778 ac_cflags_save="$CFLAGS"
1779 CFLAGS="$CFLAGS $LIBYANG_CFLAGS"
1780 AC_CHECK_MEMBER([struct lyd_node.priv], [], [
1781   AC_MSG_ERROR([m4_normalize([
1782     libyang needs to be compiled with ENABLE_LYD_PRIV=ON.
1783     Instructions for this are included in the build documentation for your platform at http://docs.frrouting.org/projects/dev-guide/en/latest/building.html])
1784   ])
1785 ], [[#include <libyang/libyang.h>]])
1786 CFLAGS="$ac_cflags_save"
1787
1788 dnl ---------------
1789 dnl configuration rollbacks
1790 dnl ---------------
1791 SQLITE3=false
1792 if test "$enable_config_rollbacks" = "yes"; then
1793   PKG_CHECK_MODULES([SQLITE3], [sqlite3], [
1794     AC_DEFINE([HAVE_CONFIG_ROLLBACKS], [1], [Enable configuration rollbacks])
1795     AC_DEFINE([HAVE_SQLITE3], [1], [Enable sqlite3 database])
1796     SQLITE3=true
1797   ], [
1798     AC_MSG_ERROR([--enable-config-rollbacks given but sqlite3 was not found on your system.])
1799   ])
1800 fi
1801
1802 dnl ---------------
1803 dnl confd
1804 dnl ---------------
1805 if test "$enable_confd" != "" -a "$enable_confd" != "no"; then
1806    AC_CHECK_PROG([CONFD], [confd], [confd], [/bin/false], "${enable_confd}/bin")
1807    if test "$CONFD" = "/bin/false"; then
1808       AC_MSG_ERROR([confd was not found on your system.])]
1809    fi
1810    CONFD_CFLAGS="-I${enable_confd}/include -L${enable_confd}/lib"
1811    AC_SUBST([CONFD_CFLAGS])
1812    CONFD_LIBS="-lconfd"
1813    AC_SUBST([CONFD_LIBS])
1814    AC_DEFINE([HAVE_CONFD], [1], [Enable confd integration])
1815 fi
1816
1817 dnl ---------------
1818 dnl sysrepo
1819 dnl ---------------
1820 if test "$enable_sysrepo" = "yes"; then
1821   PKG_CHECK_MODULES([SYSREPO], [libsysrepo],
1822       [AC_DEFINE([HAVE_SYSREPO], [1], [Enable sysrepo integration])
1823       SYSREPO=true],
1824       [SYSREPO=false
1825       AC_MSG_ERROR([sysrepo was not found on your system.])]
1826   )
1827 fi
1828
1829 dnl ---------------
1830 dnl gRPC
1831 dnl ---------------
1832 if test "$enable_grpc" = "yes"; then
1833   PKG_CHECK_MODULES([GRPC], [grpc grpc++ protobuf], [
1834     AC_CHECK_PROGS([PROTOC], [protoc], [/bin/false])
1835     if test "$PROTOC" = "/bin/false"; then
1836       AC_MSG_FAILURE([grpc requested but protoc not found.])
1837     fi
1838
1839     AC_DEFINE([HAVE_GRPC], [1], [Enable the gRPC northbound plugin])
1840     GRPC=true
1841   ], [
1842     GRPC=false
1843     AC_MSG_ERROR([grpc/grpc++ were not found on your system.])
1844   ])
1845 fi
1846
1847 dnl ------
1848 dnl ZeroMQ
1849 dnl ------
1850 if test "$enable_zeromq" != "no"; then
1851   PKG_CHECK_MODULES([ZEROMQ], [libzmq >= 4.0.0], [
1852     AC_DEFINE([HAVE_ZEROMQ], [1], [Enable ZeroMQ support])
1853     ZEROMQ=true
1854   ], [
1855     if test "$enable_zeromq" = "yes"; then
1856       AC_MSG_ERROR([configuration specifies --enable-zeromq but libzmq was not found])
1857     fi
1858   ])
1859 fi
1860
1861 dnl ------------------------------------
1862 dnl Enable RPKI and add librtr to libs
1863 dnl ------------------------------------
1864 if test "$enable_rpki" = "yes"; then
1865   PKG_CHECK_MODULES([RTRLIB], [rtrlib >= 0.5.0],
1866       [RPKI=true],
1867       [RPKI=false
1868       AC_MSG_ERROR([rtrlib was not found on your system or is too old.])]
1869   )
1870 fi
1871
1872 dnl ------------------------------------
1873 dnl pimd is not supported on OpenBSD and MacOS
1874 dnl ------------------------------------
1875 if test "$enable_pimd" != "no"; then
1876 AC_MSG_CHECKING([for pimd OS support])
1877 case "$host_os" in
1878   darwin*)
1879     AC_MSG_RESULT([no])
1880     enable_pimd="no"
1881     ;;
1882   openbsd*)
1883     AC_MSG_RESULT([no])
1884     enable_pimd="no"
1885     ;;
1886   *)
1887     AC_MSG_RESULT([yes])
1888     ;;
1889 esac
1890 fi
1891
1892 dnl -------------------------------------
1893 dnl VRRP is only supported on linux
1894 dnl -------------------------------------
1895 if test "$enable_vrrpd" != "no"; then
1896 AC_MSG_CHECKING([for VRRP OS support])
1897 case "$host_os" in
1898   linux*)
1899     AC_MSG_RESULT([yes])
1900     ;;
1901   *)
1902     AC_MSG_RESULT([no])
1903     enable_vrrpd="no"
1904     ;;
1905 esac
1906 fi
1907
1908 dnl ------------------------------------------
1909 dnl Check whether rtrlib was build with ssh support
1910 dnl ------------------------------------------
1911 AC_MSG_CHECKING([whether the RTR Library is compiled with SSH])
1912 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "rtrlib/rtrlib.h"]],
1913                         [[struct tr_ssh_config config;]])],
1914         [AC_MSG_RESULT([yes])
1915         AC_DEFINE([FOUND_SSH], [1], [found_ssh])],
1916         AC_MSG_RESULT([no])
1917 )
1918
1919 dnl ---------------
1920 dnl dlopen & dlinfo
1921 dnl ---------------
1922 AC_SEARCH_LIBS([dlopen], [dl dld], [], [
1923   AC_MSG_ERROR([unable to find the dlopen()])
1924 ])
1925
1926 AC_CHECK_HEADERS([link.h])
1927
1928 AC_CACHE_CHECK([for dlinfo(RTLD_DI_ORIGIN)], [frr_cv_rtld_di_origin], [
1929   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1930 #include <stdlib.h>
1931 #ifdef HAVE_LINK_H
1932 #include <link.h>
1933 #endif
1934 #include <dlfcn.h>
1935 ]], [[
1936   char origin[1];
1937   dlinfo (NULL, RTLD_DI_ORIGIN, &origin);
1938 ]])], [
1939     frr_cv_rtld_di_origin=yes
1940   ], [
1941     frr_cv_rtld_di_origin=no
1942   ])
1943 ])
1944 if test "$frr_cv_rtld_di_origin" = "yes"; then
1945   AC_DEFINE([HAVE_DLINFO_ORIGIN], [1], [Have dlinfo RTLD_DI_ORIGIN])
1946 fi
1947
1948 AC_CACHE_CHECK([for dlinfo(RTLD_DI_LINKMAP)], [frr_cv_rtld_di_linkmap], [
1949   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1950 #include <stdlib.h>
1951 #ifdef HAVE_LINK_H
1952 #include <link.h>
1953 #endif
1954 #include <dlfcn.h>
1955 ]], [[
1956   struct link_map *lm = NULL;
1957   dlinfo (NULL, RTLD_DI_LINKMAP, &lm);
1958 ]])], [
1959     frr_cv_rtld_di_linkmap=yes
1960   ], [
1961     frr_cv_rtld_di_linkmap=no
1962   ])
1963 ])
1964 if test "$frr_cv_rtld_di_linkmap" = "yes"; then
1965   AC_DEFINE([HAVE_DLINFO_LINKMAP], [1], [Have dlinfo RTLD_DI_LINKMAP])
1966 fi
1967
1968 dnl ##########################################################################
1969 dnl test "$enable_clippy_only" != "yes"
1970 fi
1971 dnl END OF LARGE if block
1972 dnl ##########################################################################
1973
1974 dnl ---------------------------
1975 dnl sockaddr and netinet checks
1976 dnl ---------------------------
1977 AC_CHECK_TYPES([
1978         struct sockaddr_dl,
1979         struct vifctl, struct mfcctl, struct sioc_sg_req,
1980         vifi_t, struct sioc_vif_req, struct igmpmsg,
1981         struct ifaliasreq, struct if6_aliasreq, struct in6_aliasreq,
1982         struct nd_opt_adv_interval,
1983         struct nd_opt_homeagent_info, struct nd_opt_adv_interval,
1984         struct nd_opt_rdnss, struct nd_opt_dnssl],
1985         [], [], FRR_INCLUDES)
1986
1987 AC_CHECK_MEMBERS([struct sockaddr.sa_len,
1988         struct sockaddr_in.sin_len, struct sockaddr_un.sun_len,
1989         struct sockaddr_dl.sdl_len,
1990         struct if6_aliasreq.ifra_lifetime,
1991         struct nd_opt_adv_interval.nd_opt_ai_type],
1992         [], [], FRR_INCLUDES)
1993
1994 dnl ---------------------------
1995 dnl IRDP/pktinfo/icmphdr checks
1996 dnl ---------------------------
1997
1998 AC_CHECK_TYPES([struct in_pktinfo], [
1999   AC_CHECK_TYPES([struct icmphdr], [
2000     IRDP=true
2001   ], [
2002     IRDP=false
2003   ], [FRR_INCLUDES])
2004 ], [
2005   IRDP=false
2006 ], [FRR_INCLUDES])
2007
2008 case "${enable_irdp}" in
2009 yes)
2010   $IRDP || AC_MSG_ERROR(['IRDP requires in_pktinfo at the moment!'])
2011   ;;
2012 no)
2013   IRDP=false
2014   ;;
2015 esac
2016
2017
2018 dnl -----------------------
2019 dnl checking for IP_PKTINFO
2020 dnl -----------------------
2021 AC_MSG_CHECKING([for IP_PKTINFO])
2022 AC_TRY_COMPILE([#include <netdb.h>], [
2023   int opt = IP_PKTINFO;
2024 ], [
2025   AC_MSG_RESULT([yes])
2026   AC_DEFINE([HAVE_IP_PKTINFO], [1], [Have IP_PKTINFO])
2027 ], [
2028   AC_MSG_RESULT([no])
2029 ])
2030
2031 dnl ---------------------------
2032 dnl checking for IP_RECVDSTADDR
2033 dnl ---------------------------
2034 AC_MSG_CHECKING([for IP_RECVDSTADDR])
2035 AC_TRY_COMPILE([#include <netinet/in.h>], [
2036   int opt = IP_RECVDSTADDR;
2037 ], [
2038   AC_MSG_RESULT([yes])
2039   AC_DEFINE([HAVE_IP_RECVDSTADDR], [1], [Have IP_RECVDSTADDR])
2040 ], [
2041   AC_MSG_RESULT([no])
2042 ])
2043
2044 dnl ----------------------
2045 dnl checking for IP_RECVIF
2046 dnl ----------------------
2047 AC_MSG_CHECKING([for IP_RECVIF])
2048 AC_TRY_COMPILE([#include <netinet/in.h>], [
2049   int opt = IP_RECVIF;
2050 ], [
2051   AC_MSG_RESULT([yes])
2052   AC_DEFINE([HAVE_IP_RECVIF], [1], [Have IP_RECVIF])
2053 ], [
2054   AC_MSG_RESULT([no])
2055 ])
2056
2057 dnl ----------------------
2058 dnl checking for SO_BINDANY
2059 dnl ----------------------
2060 AC_MSG_CHECKING([for SO_BINDANY])
2061 AC_TRY_COMPILE([#include <sys/socket.h>], [
2062   int opt = SO_BINDANY;
2063 ], [
2064   AC_MSG_RESULT([yes])
2065   AC_DEFINE([HAVE_SO_BINDANY], [1], [Have SO_BINDANY])
2066 ], [
2067   AC_MSG_RESULT([no])
2068 ])
2069
2070 dnl ----------------------
2071 dnl checking for IP_FREEBIND
2072 dnl ----------------------
2073 AC_MSG_CHECKING([for IP_FREEBIND])
2074 AC_TRY_COMPILE([#include <netinet/in.h>], [
2075   int opt = IP_FREEBIND;
2076 ], [
2077   AC_MSG_RESULT([yes])
2078   AC_DEFINE([HAVE_IP_FREEBIND], [1], [Have IP_FREEBIND])
2079 ], [
2080   AC_MSG_RESULT([no])
2081 ])
2082
2083 dnl --------------------------------------
2084 dnl checking for be32dec existence or not
2085 dnl --------------------------------------
2086 AC_CHECK_DECLS([be32enc, be32dec], [], [],
2087                [#include <sys/endian.h>])
2088
2089 dnl --------------------------------------
2090 dnl checking for clock_time monotonic struct and call
2091 dnl --------------------------------------
2092 AC_CHECK_DECL([CLOCK_MONOTONIC],
2093         [AC_CHECK_LIB([rt], [clock_gettime], [LIBS="$LIBS -lrt"])
2094          AC_DEFINE([HAVE_CLOCK_MONOTONIC], [1], [Have monotonic clock])
2095 ], [AC_MSG_RESULT([no])], [FRR_INCLUDES])
2096
2097 AC_SEARCH_LIBS([clock_nanosleep], [rt], [
2098   AC_DEFINE([HAVE_CLOCK_NANOSLEEP], [1], [Have clock_nanosleep()])
2099 ])
2100
2101 dnl --------------------------------------
2102 dnl checking for flex and bison
2103 dnl --------------------------------------
2104
2105 AM_PROG_LEX
2106 AC_MSG_CHECKING([version of flex])
2107 frr_ac_flex_version="$(eval $LEX -V | grep flex | head -n 1)"
2108 frr_ac_flex_version="${frr_ac_flex_version##* }"
2109 AC_MSG_RESULT([$frr_ac_flex_version])
2110 AX_COMPARE_VERSION([$frr_ac_flex_version], [lt], [2.5.20], [
2111   LEX="$SHELL $missing_dir/missing flex"
2112   if test -f "${srcdir}/lib/command_lex.c" -a -f "${srcdir}/lib/command_lex.h"; then
2113     AC_MSG_WARN([using pregenerated flex output files])
2114   else
2115     AC_MSG_ERROR([flex failure and pregenerated files not included (probably a git build)])
2116   fi
2117   AC_SUBST([LEX_OUTPUT_ROOT], [lex.yy])
2118   AC_SUBST([LEXLIB], [''])
2119 ])
2120
2121 AC_PROG_YACC
2122 dnl thanks GNU bison for this b*llshit...
2123 AC_MSG_CHECKING([version of bison])
2124 frr_ac_bison_version="$(eval $YACC -V | grep bison | head -n 1)"
2125 frr_ac_bison_version="${frr_ac_bison_version##* }"
2126 frr_ac_bison_missing="false"
2127 case "x${frr_ac_bison_version}x" in
2128   x2.7*)
2129     BISON_OPENBRACE='"'
2130     BISON_CLOSEBRACE='"'
2131     BISON_VERBOSE=''
2132     AC_MSG_RESULT([$frr_ac_bison_version - 2.7 or older])
2133     ;;
2134   x2.*|x1.*)
2135     AC_MSG_RESULT([$frr_ac_bison_version])
2136     AC_MSG_WARN([installed bison is too old.  Please install GNU bison 2.7.x or newer.])
2137     frr_ac_bison_missing="true"
2138     ;;
2139   x)
2140     AC_MSG_RESULT([none])
2141     AC_MSG_WARN([could not determine bison version.  Please install GNU bison 2.7.x or newer.])
2142     frr_ac_bison_missing="true"
2143     ;;
2144   x3.[012][^0-9]*)
2145     BISON_OPENBRACE='{'
2146     BISON_CLOSEBRACE='}'
2147     BISON_VERBOSE='-Dparse.error=verbose'
2148     AC_MSG_RESULT([$frr_ac_bison_version - 3.0 to 3.2])
2149     ;;
2150   *)
2151     BISON_OPENBRACE='{'
2152     BISON_CLOSEBRACE='}'
2153     BISON_VERBOSE='-Dparse.error=verbose -Wno-yacc'
2154     AC_MSG_RESULT([$frr_ac_bison_version - 3.3 or newer])
2155     ;;
2156 esac
2157 AC_SUBST([BISON_OPENBRACE])
2158 AC_SUBST([BISON_CLOSEBRACE])
2159 AC_SUBST([BISON_VERBOSE])
2160
2161 if $frr_ac_bison_missing; then
2162   YACC="$SHELL $missing_dir/missing bison -y"
2163   if test -f "${srcdir}/lib/command_parse.c" -a -f "${srcdir}/lib/command_parse.h"; then
2164     AC_MSG_WARN([using pregenerated bison output files])
2165   else
2166     AC_MSG_ERROR([bison failure and pregenerated files not included (probably a git build)])
2167   fi
2168 fi
2169
2170 dnl -------------------
2171 dnl capabilities checks
2172 dnl -------------------
2173 if test "$enable_capabilities" != "no"; then
2174   AC_MSG_CHECKING([whether prctl PR_SET_KEEPCAPS is available])
2175   AC_TRY_COMPILE([#include <sys/prctl.h>], [prctl(PR_SET_KEEPCAPS, 1, 0, 0, 0);],
2176     [AC_MSG_RESULT([yes])
2177      AC_DEFINE([HAVE_PR_SET_KEEPCAPS], [1], [prctl])
2178      frr_ac_keepcaps="yes"],
2179      AC_MSG_RESULT([no])
2180   )
2181   if test "$frr_ac_keepcaps" = "yes"; then
2182     AC_CHECK_HEADERS([sys/capability.h])
2183   fi
2184   if test "$ac_cv_header_sys_capability_h" = "yes"; then
2185     AC_CHECK_LIB([cap], [cap_init],
2186       [AC_DEFINE([HAVE_LCAPS], [1], [Capabilities])
2187        LIBCAP="-lcap"
2188        frr_ac_lcaps="yes"]
2189     )
2190   fi
2191   if test "$frr_ac_scaps" = "yes" \
2192        -o "$frr_ac_lcaps" = "yes"; then
2193     AC_DEFINE([HAVE_CAPABILITIES], [1], [capabilities])
2194   fi
2195
2196   case "$host_os" in
2197   linux*)
2198     if test "$enable_clippy_only" != "yes"; then
2199     if test "$frr_ac_lcaps" != "yes"; then
2200       AC_MSG_ERROR([libcap and/or its headers were not found.  Running FRR without libcap support built in causes a huge performance penalty.])
2201     fi
2202     fi
2203     ;;
2204   esac
2205 else
2206   case "$host_os" in
2207   linux*)
2208     AC_MSG_WARN([Running FRR without libcap support built in causes a huge performance penalty.])
2209     ;;
2210   esac
2211 fi
2212 AC_SUBST([LIBCAP])
2213
2214 dnl ---------------------------
2215 dnl check for glibc 'backtrace'
2216 dnl ---------------------------
2217 if test "$enable_backtrace" != "no" ; then
2218   backtrace_ok=no
2219   PKG_CHECK_MODULES([UNWIND], [libunwind], [
2220     AC_DEFINE([HAVE_LIBUNWIND], [1], [libunwind])
2221     backtrace_ok=yes
2222   ], [
2223     true
2224   ])
2225
2226   if test "$backtrace_ok" = "no"; then
2227     AC_CHECK_HEADER([unwind.h], [
2228       AC_SEARCH_LIBS([unw_getcontext], [unwind], [
2229         AC_DEFINE([HAVE_LIBUNWIND], [1], [libunwind])
2230         backtrace_ok=yes
2231       ])
2232     ])
2233   fi
2234
2235   if test "$backtrace_ok" = "no"; then
2236     AC_CHECK_HEADER([execinfo.h], [
2237       AC_SEARCH_LIBS([backtrace], [execinfo], [
2238         AC_DEFINE([HAVE_GLIBC_BACKTRACE], [1], [Glibc backtrace])
2239         backtrace_ok=yes
2240       ],, [-lm])
2241     ])
2242   fi
2243
2244   if test "$enable_backtrace" = "yes" -a "$backtrace_ok" = "no"; then
2245     dnl user explicitly requested backtrace but we failed to find support
2246     AC_MSG_FAILURE([failed to find backtrace or libunwind support])
2247   fi
2248 fi
2249
2250 dnl -----------------------------------------
2251 dnl check for malloc mallinfo struct and call
2252 dnl this must try and link using LIBS, in
2253 dnl order to check no alternative allocator
2254 dnl has been specified, which might not provide
2255 dnl mallinfo
2256 dnl -----------------------------------------
2257 AC_CHECK_HEADERS([malloc.h malloc_np.h malloc/malloc.h],,, [FRR_INCLUDES])
2258
2259 AC_CACHE_CHECK([whether mallinfo is available], [frr_cv_mallinfo], [
2260   AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2261 #ifdef HAVE_MALLOC_H
2262 #include <malloc.h>
2263 #endif
2264 #ifdef HAVE_MALLOC_NP_H
2265 #include <malloc_np.h>
2266 #endif
2267 #ifdef HAVE_MALLOC_MALLOC_H
2268 #include <malloc/malloc.h>
2269 #endif
2270 ]], [[
2271 struct mallinfo ac_x; ac_x = mallinfo ();
2272 ]])], [
2273     frr_cv_mallinfo=yes
2274   ], [
2275     frr_cv_mallinfo=no
2276   ])
2277 ])
2278 if test "$frr_cv_mallinfo" = "yes"; then
2279   AC_DEFINE([HAVE_MALLINFO], [1], [mallinfo])
2280 fi
2281
2282 AC_MSG_CHECKING([whether malloc_usable_size is available])
2283 AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2284 #ifdef HAVE_MALLOC_H
2285 #include <malloc.h>
2286 #endif
2287 #ifdef HAVE_MALLOC_MALLOC_H
2288 #include <malloc/malloc.h>
2289 #endif
2290 ]], [[
2291 size_t ac_x; ac_x = malloc_usable_size(NULL);
2292 ]])], [
2293   AC_MSG_RESULT([yes])
2294   AC_DEFINE([HAVE_MALLOC_USABLE_SIZE], [1], [malloc_usable_size])
2295 ], [
2296   AC_MSG_RESULT([no])
2297
2298   AC_MSG_CHECKING([whether malloc_size is available])
2299   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2300 #ifdef HAVE_MALLOC_H
2301 #include <malloc.h>
2302 #endif
2303 #ifdef HAVE_MALLOC_MALLOC_H
2304 #include <malloc/malloc.h>
2305 #endif
2306 ]], [[
2307 size_t ac_x; ac_x = malloc_size(NULL);
2308 ]])], [
2309     AC_MSG_RESULT([yes])
2310     AC_DEFINE([HAVE_MALLOC_SIZE], [1], [malloc_size])
2311   ], [
2312     AC_MSG_RESULT([no])
2313   ])
2314 ])
2315
2316 dnl ----------
2317 dnl configure date
2318 dnl ----------
2319 dev_version=`echo $VERSION | grep dev`
2320 #don't expire deprecated code in non 'dev' branch
2321 if test "$dev_version" = ""; then
2322    CONFDATE=0
2323 else
2324    CONFDATE=`date '+%Y%m%d'`
2325 fi
2326 AC_SUBST([CONFDATE])
2327
2328 dnl ------------------------------
2329 dnl set paths for state directory
2330 dnl ------------------------------
2331 AC_MSG_CHECKING([directory to use for state file])
2332 if test "$prefix" = "NONE"; then
2333   frr_statedir_prefix="";
2334 else
2335   frr_statedir_prefix=${prefix}
2336 fi
2337 if test "$localstatedir" = '${prefix}/var'; then
2338   for FRR_STATE_DIR in ${frr_statedir_prefix}/var/run dnl
2339                         ${frr_statedir_prefix}/var/adm dnl
2340                         ${frr_statedir_prefix}/etc dnl
2341                         /var/run        dnl
2342                         /var/adm        dnl
2343                         /etc            dnl
2344                         /dev/null;
2345   do
2346     test -d $FRR_STATE_DIR && break
2347   done
2348   frr_statedir=$FRR_STATE_DIR
2349 else
2350   frr_statedir=${localstatedir}
2351 fi
2352 if test "$frr_statedir" = "/dev/null"; then
2353     AC_MSG_ERROR([STATE DIRECTORY NOT FOUND! FIX OR SPECIFY --localstatedir!])
2354 fi
2355 AC_MSG_RESULT([${frr_statedir}])
2356 AC_SUBST([frr_statedir])
2357
2358 AC_DEFINE_UNQUOTED([LDPD_SOCKET], ["$frr_statedir%s%s/ldpd.sock"], [ldpd control socket])
2359 AC_DEFINE_UNQUOTED([ZEBRA_SERV_PATH], ["$frr_statedir%s%s/zserv.api"], [zebra api socket])
2360 AC_DEFINE_UNQUOTED([BFDD_CONTROL_SOCKET], ["$frr_statedir%s%s/bfdd.sock"], [bfdd control socket])
2361 AC_DEFINE_UNQUOTED([DAEMON_VTY_DIR], ["$frr_statedir%s%s"], [daemon vty directory])
2362 AC_DEFINE_UNQUOTED([DAEMON_DB_DIR], ["$frr_statedir"], [daemon database directory])
2363
2364 dnl autoconf does this, but it does it too late...
2365 test "$prefix" = "NONE" && prefix=$ac_default_prefix
2366 test "$exec_prefix" = "NONE" && exec_prefix='${prefix}'
2367
2368 dnl get the full path, recursing through variables...
2369 vtysh_bin="$bindir/vtysh"
2370 for I in 1 2 3 4 5 6 7 8 9 10; do
2371         eval vtysh_bin="\"$vtysh_bin\""
2372 done
2373 AC_DEFINE_UNQUOTED([VTYSH_BIN_PATH], ["$vtysh_bin"], [path to vtysh binary])
2374 AC_SUBST([vtysh_bin])
2375
2376 CFG_SYSCONF="$sysconfdir"
2377 CFG_SBIN="$sbindir"
2378 CFG_STATE="$frr_statedir"
2379 CFG_MODULE="$moduledir"
2380 CFG_YANGMODELS="$yangmodelsdir"
2381 for I in 1 2 3 4 5 6 7 8 9 10; do
2382         eval CFG_SYSCONF="\"$CFG_SYSCONF\""
2383         eval CFG_SBIN="\"$CFG_SBIN\""
2384         eval CFG_STATE="\"$CFG_STATE\""
2385         eval CFG_MODULE="\"$CFG_MODULE\""
2386         eval CFG_YANGMODELS="\"$CFG_YANGMODELS\""
2387 done
2388 AC_SUBST([CFG_SYSCONF])
2389 AC_SUBST([CFG_SBIN])
2390 AC_SUBST([CFG_STATE])
2391 AC_SUBST([CFG_MODULE])
2392 AC_SUBST([CFG_YANGMODELS])
2393 AC_DEFINE_UNQUOTED([MODULE_PATH], ["$CFG_MODULE"], [path to modules])
2394 AC_DEFINE_UNQUOTED([YANG_MODELS_PATH], ["$CFG_YANGMODELS"], [path to YANG data models])
2395 AC_DEFINE_UNQUOTED([WATCHFRR_SH_PATH], ["${CFG_SBIN%/}/watchfrr.sh"], [path to watchfrr.sh])
2396
2397 dnl various features
2398 AM_CONDITIONAL([SUPPORT_REALMS], [test "$enable_realms" = "yes"])
2399 AM_CONDITIONAL([ENABLE_BGP_VNC], [test "$enable_bgp_vnc" != "no"])
2400 AM_CONDITIONAL([BGP_BMP], [$bgpd_bmp])
2401 dnl northbound
2402 AM_CONDITIONAL([SQLITE3], [$SQLITE3])
2403 AM_CONDITIONAL([CONFD], [test "$enable_confd" != ""])
2404 AM_CONDITIONAL([SYSREPO], [test "$enable_sysrepo" = "yes"])
2405 AM_CONDITIONAL([GRPC], [test "$enable_grpc" = "yes"])
2406 AM_CONDITIONAL([ZEROMQ], [test "$ZEROMQ" = "true"])
2407 dnl plugins
2408 AM_CONDITIONAL([RPKI], [test "$RPKI" = "true"])
2409 AM_CONDITIONAL([SNMP], [test "$SNMP_METHOD" = "agentx"])
2410 AM_CONDITIONAL([IRDP], [$IRDP])
2411 AM_CONDITIONAL([FPM], [test "$enable_fpm" = "yes"])
2412 AM_CONDITIONAL([HAVE_PROTOBUF], [test "$enable_protobuf" = "yes"])
2413 AM_CONDITIONAL([HAVE_PROTOBUF3], [$PROTO3])
2414 dnl daemons
2415 AM_CONDITIONAL([VTYSH], [test "$VTYSH" = "vtysh"])
2416 AM_CONDITIONAL([ZEBRA], [test "$enable_zebra" != "no"])
2417 AM_CONDITIONAL([BGPD], [test "$enable_bgpd" != "no"])
2418 AM_CONDITIONAL([RIPD], [test "$enable_ripd" != "no"])
2419 AM_CONDITIONAL([OSPFD], [test "$enable_ospfd" != "no"])
2420 AM_CONDITIONAL([LDPD], [test "$enable_ldpd" != "no"])
2421 AM_CONDITIONAL([BFDD], [test "$BFDD" = "bfdd"])
2422 AM_CONDITIONAL([NHRPD], [test "$NHRPD" = "nhrpd"])
2423 AM_CONDITIONAL([EIGRPD], [test "$enable_eigrpd" != "no"])
2424 AM_CONDITIONAL([WATCHFRR], [test "$WATCHFRR" = "watchfrr"])
2425 AM_CONDITIONAL([OSPFCLIENT], [test "$OSPFCLIENT" = "ospfclient"])
2426 AM_CONDITIONAL([RIPNGD], [test "$enable_ripngd" != "no"])
2427 AM_CONDITIONAL([BABELD], [test "$enable_babeld" != "no"])
2428 AM_CONDITIONAL([OSPF6D], [test "$enable_ospf6d" != "no"])
2429 AM_CONDITIONAL([ISISD], [test "$enable_isisd" != "no"])
2430 AM_CONDITIONAL([PIMD], [test "$enable_pimd" != "no"])
2431 AM_CONDITIONAL([PBRD], [test "$enable_pbrd" != "no"])
2432 AM_CONDITIONAL([SHARPD], [test "$enable_sharpd" = "yes"])
2433 AM_CONDITIONAL([STATICD], [test "$enable_staticd" != "no"])
2434 AM_CONDITIONAL([FABRICD], [test "$enable_fabricd" != "no"])
2435 AM_CONDITIONAL([VRRPD], [test "$enable_vrrpd" != "no"])
2436
2437 AC_CONFIG_FILES([Makefile],[
2438         test "$enable_dev_build" = "yes" && makefile_devbuild="--dev-build"
2439         ${PYTHON} "${ac_abs_top_srcdir}/python/makefile.py" ${makefile_devbuild} || exit 1
2440 ], [
2441         PYTHON="$PYTHON"
2442         enable_dev_build="$enable_dev_build"
2443 ])
2444
2445 AC_CONFIG_FILES([
2446           config.version
2447           changelog-auto
2448           redhat/frr.spec
2449           alpine/APKBUILD
2450           snapcraft/snapcraft.yaml
2451           lib/version.h
2452           tests/lib/cli/test_cli.refout
2453           pkgsrc/bgpd.sh pkgsrc/ospf6d.sh pkgsrc/ospfd.sh
2454           pkgsrc/ripd.sh pkgsrc/ripngd.sh pkgsrc/zebra.sh
2455           pkgsrc/eigrpd.sh])
2456
2457 AC_CONFIG_FILES([vtysh/extract.pl], [chmod +x vtysh/extract.pl])
2458 AC_CONFIG_FILES([tools/frr], [chmod +x tools/frr])
2459 AC_CONFIG_FILES([tools/watchfrr.sh], [chmod +x tools/watchfrr.sh])
2460 AC_CONFIG_FILES([tools/frrinit.sh], [chmod +x tools/frrinit.sh])
2461 AC_CONFIG_FILES([tools/frrcommon.sh])
2462
2463 AC_CONFIG_COMMANDS([lib/route_types.h], [
2464         dst="${ac_abs_top_builddir}/lib/route_types.h"
2465         ${PERL} "${ac_abs_top_srcdir}/lib/route_types.pl" \
2466                 < "${ac_abs_top_srcdir}/lib/route_types.txt" \
2467                 > "${dst}.tmp"
2468         test -f "$dst" \
2469                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
2470                 && rm "${dst}.tmp" \
2471                 || mv "${dst}.tmp" "${dst}"
2472 ], [
2473         PERL="$PERL"
2474 ])
2475
2476 AS_IF([test "$with_pkg_git_version" = "yes"], [
2477     AC_CONFIG_COMMANDS([lib/gitversion.h], [
2478         dst="${ac_abs_top_builddir}/lib/gitversion.h"
2479         ${PERL} "${ac_abs_top_srcdir}/lib/gitversion.pl" \
2480                 "${ac_abs_top_srcdir}" \
2481                 > "${dst}.tmp"
2482         test -f "$dst" \
2483                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
2484                 && rm "${dst}.tmp" \
2485                 || mv "${dst}.tmp" "${dst}"
2486     ], [
2487         PERL="$PERL"
2488     ])
2489 ])
2490
2491 ## Hack, but working solution to avoid rebuilding of frr.info.
2492 ## It's already in CVS until texinfo 4.7 is more common.
2493 AC_OUTPUT
2494
2495 echo "
2496 FRRouting configuration
2497 ------------------------------
2498 FRR version             : ${PACKAGE_VERSION}
2499 host operating system   : ${host_os}
2500 source code location    : ${srcdir}
2501 compiler                : ${CC}
2502 compiler flags          : ${CFLAGS} ${SAN_FLAGS}
2503 make                    : ${MAKE-make}
2504 linker flags            : ${LDFLAGS} ${SAN_FLAGS} ${LIBS} ${LIBCAP} ${LIBREADLINE} ${LIBM}
2505 state file directory    : ${frr_statedir}
2506 config file directory   : `eval echo \`echo ${sysconfdir}\``
2507 example directory       : `eval echo \`echo ${exampledir}\``
2508 module directory        : ${CFG_MODULE}
2509 user to run as          : ${enable_user}
2510 group to run as         : ${enable_group}
2511 group for vty sockets   : ${enable_vty_group}
2512 config file mask        : ${enable_configfile_mask}
2513 log file mask           : ${enable_logfile_mask}
2514 zebra protobuf enabled  : ${enable_protobuf:-no}
2515
2516 The above user and group must have read/write access to the state file
2517 directory and to the config files in the config file directory."
2518
2519 if test "$enable_doc" != "no" -a "$frr_py_mod_sphinx" = "false"; then
2520   AC_MSG_WARN([sphinx is missing but required to build documentation])
2521 fi
2522 if test "$frr_py_mod_pytest" = "false"; then
2523   AC_MSG_WARN([pytest is missing, unit tests cannot be performed])
2524 fi