configure.ac

   1 ##
   2 ## Configure template file for FRRouting.
   3 ## autoconf will generate a configure script.
   4 ##
   5 ##  Copyright (c) 1996, 97, 98, 99, 2000 Kunihiro Ishiguro <kunihiro@zebra.org>
   6 ##  Portions Copyright (c) 2003 Paul Jakma <paul@dishone.st>
   7 ##
   8 AC_PREREQ([2.69])
   9
  10 AC_INIT([frr], [8.2-dev], [https://github.com/frrouting/frr/issues])
  11 PACKAGE_URL="https://frrouting.org/"
  12 AC_SUBST([PACKAGE_URL])
  13 PACKAGE_FULLNAME="FRRouting"
  14 AC_SUBST([PACKAGE_FULLNAME])
  15
  16 CONFIG_ARGS="`echo $ac_configure_args | sed -e \"s% '[[A-Z]]*FLAGS=[[^']]\+'%%g\"`"
  17 AC_SUBST([CONFIG_ARGS])
  18
  19 AC_CONFIG_SRCDIR([lib/zebra.h])
  20 AC_CONFIG_MACRO_DIR([m4])
  21 AC_CONFIG_AUX_DIR([m4/ac])
  22
  23 dnl -----------------------------------
  24 dnl Get hostname and other information.
  25 dnl -----------------------------------
  26 AC_CANONICAL_BUILD()
  27 AC_CANONICAL_HOST()
  28
  29 AC_ARG_VAR([AR],[archiver command])
  30 AC_ARG_VAR([LD],[linker command])
  31 AC_ARG_VAR([OBJCOPY],[objcopy command])
  32 AC_ARG_VAR([OBJDUMP],[objdump command])
  33 AC_ARG_VAR([RANLIB],[ranlib command])
  34 AC_ARG_VAR([STRIP],[strip command])
  35
  36 hosttools_clippy="false"
  37 build_clippy="true"
  38
  39 dnl case 1: external clippy
  40 if test -n "$with_clippy" -a "$with_clippy" != "no" -a "$with_clippy" != "yes"; then
  41   if test "$enable_clippy_only" = "yes"; then
  42     AC_MSG_ERROR([--enable-clippy-only does not make sense with --with-clippy])
  43   fi
  44
  45   CLIPPY="$with_clippy"
  46   build_clippy="false"
  47   if test ! -x "$with_clippy"; then
  48     AC_MSG_ERROR([clippy tool ($with_clippy) is not executable])
  49   fi
  50
  51 dnl case 2: cross-compiling internal clippy
  52 elif test "$host" != "$build"; then
  53   if test "$srcdir" = "."; then
  54     AC_MSG_ERROR([cross-compilation is only possible with builddir separate from srcdir or by building clippy separately and using the --with-clippy option.  create a separate directory and run as .../path-to-frr/configure.])
  55   fi
  56   test -d hosttools || mkdir hosttools
  57   abssrc="`cd \"${srcdir}\"; pwd`"
  58
  59   AC_MSG_NOTICE([...])
  60   AC_MSG_NOTICE([... cross-compilation: creating hosttools directory and self-configuring for build platform tools])
  61   AC_MSG_NOTICE([... use HOST_CPPFLAGS / HOST_CFLAGS / HOST_LDFLAGS if neccessary])
  62   AC_MSG_NOTICE([...])
  63
  64   (
  65     for var in $ac_precious_vars; do
  66       dnl special cases
  67       case "$var" in
  68       YACC|YFLAGS) continue;;
  69       PYTHON*)     retain=true;;
  70       *)           retain=false;
  71       esac
  72
  73       eval "hostvar=\"\${HOST_$var}\""
  74       eval "targetvar=\"\${$var}\""
  75       if test -n "$hostvar"; then
  76         eval "$var='$hostvar'"
  77         _AS_ECHO_LOG([host $var='$hostvar'])
  78       elif $retain; then
  79         _AS_ECHO_LOG([host retain $var='$targetvar'])
  80       else
  81         eval "unset $var"
  82         _AS_ECHO_LOG([host unset $var])
  83       fi
  84     done
  85     cd hosttools
  86     "${abssrc}/configure" "--host=$build" "--build=$build" "--enable-clippy-only" "--disable-nhrpd" "--disable-vtysh"
  87   ) || exit 1
  88
  89   AC_MSG_NOTICE([...])
  90   AC_MSG_NOTICE([... cross-compilation: finished self-configuring for build platform tools])
  91   AC_MSG_NOTICE([...])
  92
  93   build_clippy="false"
  94   hosttools_clippy="true"
  95   CLIPPY="hosttools/lib/clippy"
  96
  97 dnl case 3: normal build internal clippy
  98 else
  99   CLIPPY="lib/clippy\$(EXEEXT)"
 100 fi
 101 AC_SUBST([CLIPPY])
 102 AM_CONDITIONAL([BUILD_CLIPPY], [$build_clippy])
 103 AM_CONDITIONAL([HOSTTOOLS_CLIPPY], [$hosttools_clippy])
 104 AM_CONDITIONAL([ONLY_CLIPPY], [test "$enable_clippy_only" = "yes"])
 105
 106 # Disable portability warnings -- our automake code (in particular
 107 # common.am) uses some constructs specific to gmake.
 108 AM_INIT_AUTOMAKE([1.12 -Wno-portability foreign])
 109 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
 110 AM_SILENT_RULES([yes])
 111 AC_CONFIG_HEADERS([config.h])
 112
 113 AC_PATH_PROG([PERL], [perl])
 114 PKG_PROG_PKG_CONFIG
 115
 116 dnl default is to match previous behavior
 117 pkgsrcrcdir=""
 118 AC_ARG_ENABLE([pkgsrcrcdir],
 119           AS_HELP_STRING([--enable-pkgsrcrcdir],
 120                          [specify directory for rc.d scripts]),
 121                          pkgsrcrcdir="$enableval",)
 122 dnl XXX add --pkgsrcrcdir to autoconf standard directory list somehow
 123 AC_SUBST([pkgsrcrcdir])
 124 AM_CONDITIONAL([PKGSRC], [test "$pkgsrcrcdir" != ""])
 125
 126 AC_ARG_WITH([moduledir], [AS_HELP_STRING([--with-moduledir=DIR], [module directory (${libdir}/frr/modules)])], [
 127         moduledir="$withval"
 128 ], [
 129         moduledir="\${libdir}/frr/modules"
 130 ])
 131 AC_SUBST([moduledir], [$moduledir])
 132
 133 AC_ARG_WITH([scriptdir], [AS_HELP_STRING([--with-scriptdir=DIR], [script directory (${sysconfdir}/scripts)])], [
 134         scriptdir="$withval"
 135 ], [
 136         scriptdir="\${sysconfdir}/scripts"
 137 ])
 138 AC_SUBST([scriptdir], [$scriptdir])
 139
 140 AC_ARG_WITH([yangmodelsdir], [AS_HELP_STRING([--with-yangmodelsdir=DIR], [yang models directory (${datarootdir}/yang)])], [
 141         yangmodelsdir="$withval"
 142 ], [
 143         yangmodelsdir="\${datarootdir}/yang"
 144 ])
 145 AC_SUBST([yangmodelsdir])
 146
 147 AC_ARG_WITH([vici-socket], [AS_HELP_STRING([--with-vici-socket=PATH], [vici-socket (/var/run/charon.vici)])], [
 148         vici_socket="$withval"
 149 ], [
 150         vici_socket="/var/run/charon.vici"
 151 ])
 152 AC_DEFINE_UNQUOTED([VICI_SOCKET], ["$vici_socket"], [StrongSWAN vici socket path])
 153
 154 AC_ARG_ENABLE(tcmalloc,
 155         AS_HELP_STRING([--enable-tcmalloc], [Turn on tcmalloc]),
 156 [case "${enableval}" in
 157   yes) tcmalloc_enabled=true
 158 LIBS="$LIBS -ltcmalloc_minimal"
 159  ;;
 160   no)  tcmalloc_enabled=false ;;
 161   *) AC_MSG_ERROR([bad value ${enableval} for --enable-tcmalloc]) ;;
 162 esac],[tcmalloc_enabled=false])
 163
 164
 165 dnl Thanks autoconf, but we don't want a default -g -O2.  We have our own
 166 dnl flag determination logic.
 167 CFLAGS="${CFLAGS:-}"
 168
 169 dnl --------------------
 170 dnl Check CC and friends
 171 dnl --------------------
 172 dnl note orig_cflags is also used further down
 173 orig_cflags="$CFLAGS"
 174 orig_cxxflags="$CXXFLAGS"
 175 AC_LANG([C])
 176 AC_PROG_CC
 177 AC_PROG_CPP
 178 AC_PROG_CXX
 179 AM_PROG_CC_C_O
 180 dnl remove autoconf default "-g -O2"
 181 CFLAGS="$orig_cflags"
 182 CXXFLAGS="$orig_cxxflags"
 183
 184 dnl Some special handling for ICC later on
 185 if test "$CC" = "icc"; then
 186     cc_is_icc="yes"
 187 fi
 188
 189 PKG_PROG_PKG_CONFIG
 190
 191 dnl it's 2019, sed is sed.
 192 SED=sed
 193 AC_SUBST([SED])
 194
 195 dnl try and enable CFLAGS that are useful for FRR
 196 dnl - specifically, options to control warnings
 197
 198 AC_SUBST([AC_CFLAGS])
 199 AC_USE_SYSTEM_EXTENSIONS
 200 AC_DEFUN([AC_C_FLAG], [{
 201     m4_pushdef([cachename],[m4_translit([frr_cv_$1],[ =-+/{}$],[________])])
 202     AC_CACHE_CHECK([[whether $CC supports $1]], cachename, [
 203         AC_LANG_PUSH([C])
 204         ac_c_flag_save="$CFLAGS"
 205         CFLAGS="$CFLAGS $1"
 206         AC_COMPILE_IFELSE(
 207                 [AC_LANG_PROGRAM([[$4]])],
 208                 [
 209                         cachename=yes
 210                 ], [
 211                         cachename=no
 212                 ])
 213         CFLAGS="$ac_c_flag_save"
 214         AC_LANG_POP([C])
 215     ])
 216     if test "$cachename" = "yes"; then
 217         m4_if([$3], [], [AC_CFLAGS="$AC_CFLAGS $1"], [$3])
 218     else
 219         :
 220         $2
 221     fi
 222     m4_popdef([cachename])
 223 }])
 224
 225 AC_DEFUN([AC_LINK_IFELSE_FLAGS], [{
 226         AC_LANG_PUSH([C])
 227         ac_cflags_save="$CFLAGS"
 228         ac_libs_save="$LIBS"
 229         CFLAGS="$CFLAGS $1"
 230         LIBS="$LIBS $2"
 231         AC_LINK_IFELSE(
 232                 [$3],
 233                 [
 234                         CFLAGS="$ac_cflags_save"
 235                         LIBS="$ac_libs_save"
 236                         m4_default([$5], [
 237                                 AC_MSG_RESULT([yes])
 238                         ])
 239                 ], [
 240                         CFLAGS="$ac_cflags_save"
 241                         LIBS="$ac_libs_save"
 242                         m4_default([$4], [
 243                                 AC_MSG_RESULT([no])
 244                         ])
 245                 ])
 246         AC_LANG_POP([C])
 247         }])
 248
 249 dnl ICC won't bail on unknown options without -diag-error 10006
 250 dnl need to do this first so we get useful results for the other options
 251 if test "$cc_is_icc" = "yes"; then
 252     AC_C_FLAG([-diag-error 10006])
 253 fi
 254
 255 dnl autoconf 2.69 AC_PROG_CC_C99 is "state of the art"
 256 dnl autoconf 2.70 AC_PROG_CC_C99 is deprecated and AC_PROC_CC tries to do C11
 257 m4_if(m4_version_compare(m4_defn([AC_AUTOCONF_VERSION]), [2.70]), [-1], [dnl
 258   dnl autoconf < 2.70
 259   AC_PROG_CC_C99
 260
 261   dnl AC_PROG_CC_C99 may change CC to include -std=gnu99 or something
 262   ac_cc="$CC"
 263   CC="${CC% -std=gnu99}"
 264   CC="${CC% -std=c99}"
 265
 266   AC_C_FLAG([-std=gnu11], [CC="$ac_cc"], [CC="$CC -std=gnu11"])
 267 ], [
 268   dnl autoconf >= 2.70
 269   if test "$ac_cv_prog_cc_c11" = "no"; then
 270     AC_MSG_ERROR([ISO C11 compiler support (with GNU extensions) is required.])
 271   fi
 272 ])
 273
 274 dnl if the user has specified any CFLAGS, override our settings
 275 if test "$enable_gcov" = "yes"; then
 276    if test "$orig_cflags" = ""; then
 277       AC_C_FLAG([--coverage])
 278       AC_C_FLAG([-O0])
 279    fi
 280
 281    AC_LDFLAGS="${AC_LDFLAGS} --coverage"
 282 fi
 283
 284 if test "$enable_clang_coverage" = "yes"; then
 285    AC_C_FLAG([-fprofile-instr-generate], [
 286      AC_MSG_ERROR([$CC does not support -fprofile-instr-generate.])
 287    ])
 288    AC_C_FLAG([-fcoverage-mapping], [
 289      AC_MSG_ERROR([$CC does not support -fcoverage-mapping.])
 290    ])
 291 fi
 292
 293 AM_CONDITIONAL([SCRIPTING], [test "$enable_scripting" = "yes"])
 294
 295 if test "$enable_scripting" = "yes"; then
 296    AX_PROG_LUA([5.3], [5.4], [], [
 297      AC_MSG_ERROR([Lua 5.3 is required to build with Lua support. No other version is supported.])
 298    ])
 299    AX_LUA_HEADERS([], [
 300      AC_MSG_ERROR([Lua 5.3 headers are required to build with Lua support. No other version is supported.])
 301    ])
 302    AX_LUA_LIBS([
 303      AC_DEFINE([HAVE_SCRIPTING], [1], [Have support for scripting])
 304      LIBS="$LIBS $LUA_LIB"
 305      SCRIPTING=true
 306    ], [
 307      SCRIPTING=false
 308      AC_MSG_ERROR([Lua 5.3 libraries are required to build with Lua support. No other version is supported.])
 309    ])
 310 fi
 311
 312 dnl the following flags go in CFLAGS rather than AC_CFLAGS since they make
 313 dnl sense to be overridden by the user
 314 if test "$enable_dev_build" = "yes"; then
 315    AC_DEFINE([DEV_BUILD], [1], [Build for development])
 316    if test "$orig_cflags" = ""; then
 317       AC_C_FLAG([-O0],,[CFLAGS="$CFLAGS -O0"])
 318       AC_C_FLAG([-g3],,[CFLAGS="$CFLAGS -g3"])
 319       AC_C_FLAG([-ggdb3],,[CFLAGS="$CFLAGS -ggdb3"])
 320    fi
 321 else
 322    if test "$orig_cflags" = ""; then
 323       AC_C_FLAG([-g],,[CFLAGS="$CFLAGS -g"])
 324       AC_C_FLAG([-O2],,[CFLAGS="$CFLAGS -O2"])
 325    fi
 326 fi
 327
 328 AM_CONDITIONAL([DEV_BUILD], [test "$enable_dev_build" = "yes"])
 329
 330 dnl always want these CFLAGS
 331 AC_C_FLAG([-fno-omit-frame-pointer])
 332 AC_C_FLAG([-funwind-tables])
 333 AC_C_FLAG([-Wall])
 334 AC_C_FLAG([-Wextra])
 335 AC_C_FLAG([-Wstrict-prototypes])
 336 AC_C_FLAG([-Wmissing-prototypes])
 337 AC_C_FLAG([-Wmissing-declarations])
 338 AC_C_FLAG([-Wpointer-arith])
 339 AC_C_FLAG([-Wbad-function-cast])
 340 AC_C_FLAG([-Wwrite-strings])
 341 AC_C_FLAG([-Wundef])
 342 if test "$enable_gcc_ultra_verbose" = "yes" ; then
 343   AC_C_FLAG([-Wcast-qual])
 344   AC_C_FLAG([-Wmissing-noreturn])
 345   AC_C_FLAG([-Wmissing-format-attribute])
 346   AC_C_FLAG([-Wunreachable-code])
 347   AC_C_FLAG([-Wpacked])
 348   AC_C_FLAG([-Wpadded])
 349   AC_C_FLAG([-Wshadow])
 350 else
 351   AC_C_FLAG([-Wno-unused-result])
 352 fi
 353 AC_C_FLAG([-Wno-unused-parameter])
 354 AC_C_FLAG([-Wno-missing-field-initializers])
 355
 356 AC_C_FLAG([-Wc++-compat], [], [CXX_COMPAT_CFLAGS="-Wc++-compat"])
 357 AC_SUBST([CXX_COMPAT_CFLAGS])
 358
 359 dnl ICC emits a broken warning for const char *x = a ? "b" : "c";
 360 dnl for some reason the string consts get 'promoted' to char *,
 361 dnl triggering a const to non-const conversion warning.
 362 if test "$cc_is_icc" = "yes"; then
 363     AC_C_FLAG([-diag-disable 3179])
 364 fi
 365
 366 if test "$enable_werror" = "yes" ; then
 367   WERROR="-Werror"
 368 fi
 369 AC_SUBST([WERROR])
 370
 371 SAN_FLAGS=""
 372 if test "$enable_address_sanitizer" = "yes"; then
 373   AC_C_FLAG([-fsanitize=address], [
 374     AC_MSG_ERROR([$CC does not support Address Sanitizer.])
 375   ], [
 376     SAN_FLAGS="$SAN_FLAGS -fsanitize=address"
 377   ])
 378 fi
 379 if test "$enable_thread_sanitizer" = "yes"; then
 380   AC_C_FLAG([-fsanitize=thread], [
 381     AC_MSG_ERROR([$CC does not support Thread Sanitizer.])
 382   ], [
 383     SAN_FLAGS="$SAN_FLAGS -fsanitize=thread"
 384   ])
 385 fi
 386 if test "$enable_memory_sanitizer" = "yes"; then
 387   AC_C_FLAG([-fsanitize=memory -fPIE -pie], [
 388     AC_MSG_ERROR([$CC does not support Memory Sanitizer.])
 389   ], [
 390     SAN_FLAGS="$SAN_FLAGS -fsanitize=memory -fPIE -pie"
 391   ])
 392 fi
 393 if test "$enable_undefined_sanitizer" = "yes"; then
 394   AC_C_FLAG([-fsanitize=undefined], [
 395     AC_MSG_ERROR([$CC does not support UndefinedBehaviorSanitizer.])
 396   ], [
 397     SAN_FLAGS="$SAN_FLAGS -fsanitize=undefined"
 398   ])
 399 fi
 400 AC_SUBST([SAN_FLAGS])
 401
 402 dnl frr-format.so
 403 if test "$with_frr_format" != "no" -a "$with_frr_format" != "yes" -a -n "$with_frr_format"; then
 404   AC_C_FLAG([-fplugin=${with_frr_format}], [
 405     AC_MSG_ERROR([specified frr-format plugin ($with_frr_format) does not work])
 406   ],,[
 407 #ifndef _FRR_ATTRIBUTE_PRINTFRR
 408 #error plugin not loaded
 409 #endif
 410 #if _FRR_ATTRIBUTE_PRINTFRR < 0x10000
 411 #error plugin too old
 412 #endif
 413   ])
 414 elif test "$with_frr_format" = "no"; then
 415   : #nothing
 416 else
 417   AC_C_FLAG([-fplugin=tools/gcc-plugins/frr-format.so],[
 418     AC_C_FLAG([-fplugin=frr-format],[
 419       if test "$with_frr_format" = "yes"; then
 420         AC_MSG_ERROR([frr-format plugin requested but not found])
 421       fi
 422     ],,[
 423 #ifndef _FRR_ATTRIBUTE_PRINTFRR
 424 #error plugin not loaded
 425 #endif
 426 #if _FRR_ATTRIBUTE_PRINTFRR < 0x10000
 427 #error plugin too old
 428 #endif
 429     ])
 430   ],,[
 431 #ifndef _FRR_ATTRIBUTE_PRINTFRR
 432 #error plugin not loaded
 433 #endif
 434 #if _FRR_ATTRIBUTE_PRINTFRR < 0x10000
 435 #error plugin too old
 436 #endif
 437   ])
 438 fi
 439
 440 AC_MSG_CHECKING([whether linker supports __start/stop_section symbols])
 441 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 442 #include <stdio.h>
 443 int __attribute__((section("secttest"))) var = 1;
 444 extern int __start_secttest, __stop_secttest;
 445 ]], [[
 446   void *a = &var, *b = &__start_secttest, *c = &__stop_secttest;
 447   printf("%p %p %p\n", a, b, c);
 448 ]])], [
 449   AC_MSG_RESULT(yes)
 450   AC_DEFINE(HAVE_SECTION_SYMS, 1, [have __start/stop_section symbols])
 451 ], [
 452   AC_MSG_RESULT(no)
 453 ])
 454
 455 dnl ----------
 456 dnl Essentials
 457 dnl ----------
 458
 459 AX_PTHREAD([
 460   CC="$PTHREAD_CC"
 461   AC_CFLAGS="$AC_CFLAGS $PTHREAD_CFLAGS"
 462   LIBS="$PTHREAD_LIBS $LIBS"
 463 ], [
 464   AC_MSG_FAILURE([This FRR version needs pthreads])
 465 ])
 466
 467 orig_cflags="$CFLAGS"
 468 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 469
 470 AC_SEARCH_LIBS([pthread_condattr_setclock], [],
 471                 [frr_cv_pthread_condattr_setclock=yes],
 472                 [frr_cv_pthread_condattr_setclock=no])
 473 if test "$frr_cv_pthread_condattr_setclock" = "yes"; then
 474   AC_DEFINE([HAVE_PTHREAD_CONDATTR_SETCLOCK], [1], [Have pthread.h pthread_condattr_setclock])
 475 fi
 476
 477 AC_CHECK_HEADERS([pthread_np.h],,, [
 478 #include <pthread.h>
 479 ])
 480 AC_CHECK_FUNCS([pthread_setname_np pthread_set_name_np pthread_getthreadid_np])
 481
 482 CFLAGS="$orig_cflags"
 483
 484 dnl --------------
 485 dnl Check programs
 486 dnl --------------
 487 AC_PROG_INSTALL
 488 AC_PROG_LN_S
 489 AC_CHECK_TOOL([AR], [ar])
 490
 491 dnl -------
 492 dnl libtool
 493 dnl -------
 494 AC_ARG_ENABLE([static-bin],
 495   AS_HELP_STRING([--enable-static-bin], [link binaries statically]))
 496 LT_INIT
 497 _LT_CONFIG_LIBTOOL([
 498   patch -N -i "${srcdir}/m4/libtool-whole-archive.patch" libtool >&AS_MESSAGE_LOG_FD || \
 499     AC_MSG_WARN([Could not patch libtool for static linking support.  Loading modules into a statically linked daemon will fail.])
 500 dnl the -i option is not POSIX sed and the BSDs implement it differently
 501 dnl cat'ing the output back instead of mv/cp keeps permissions on libtool intact
 502   sed -e 's%func_warning "relinking%true #\0%'                   libtool > libtool.sed && cat libtool.sed > libtool
 503   sed -e 's%func_warning "remember to run%true #\0%'             libtool > libtool.sed && cat libtool.sed > libtool
 504   sed -e 's%func_warning ".*has not been installed in%true #\0%' libtool > libtool.sed && cat libtool.sed > libtool
 505   test -f libtool.sed && rm libtool.sed
 506 ])
 507 if test "$enable_static_bin" = "yes"; then
 508   AC_LDFLAGS_EXEC="-static"
 509   if test "$enable_static" != "yes"; then
 510     AC_MSG_ERROR([The --enable-static-bin option must be combined with --enable-static.])
 511   fi
 512 fi
 513 if test "$enable_shared" != "yes"; then
 514   AC_MSG_ERROR([FRR cannot be built with --disable-shared.  If you want statically linked daemons, use --enable-shared --enable-static --enable-static-bin])
 515 fi
 516 AC_SUBST([AC_LDFLAGS])
 517 AC_SUBST([AC_LDFLAGS_EXEC])
 518 AM_CONDITIONAL([STATIC_BIN], [test "$enable_static_bin" = "yes"])
 519
 520 dnl libtool, the repository of all knowledge related linkers, is too stupid to
 521 dnl correctly tell the linker how to build modules.
 522 if test -z "$module_cmds"; then
 523   module_cmds="`echo \"$archive_cmds\" | sed -e 's%$wl-soname $wl$soname%%'`"
 524 fi
 525 if test -z "$module_expsym_cmds"; then
 526   module_expsym_cmds="`echo \"$archive_expsym_cmds\" | sed -e 's%$wl-soname $wl$soname%%'`"
 527 fi
 528
 529 AC_ARG_ENABLE([rpath],
 530   [AS_HELP_STRING([--enable-rpath], [set hardcoded rpaths in the executable @<:@default=yes@:>@])],
 531   [],
 532   [enable_rpath=yes])
 533
 534 dnl $AR and $RANLIB are set by LT_INIT above
 535 AC_MSG_CHECKING([whether $AR supports D option])
 536 if $AR crD conftest.a >/dev/null 2>/dev/null; then
 537   AC_MSG_RESULT([yes])
 538   dnl ARFLAGS is for automake, AR_FLAGS for libtool m-(
 539   ARFLAGS="crD"
 540   AR_FLAGS="crD"
 541 else
 542   AC_MSG_RESULT([no])
 543   ARFLAGS="cru"
 544   AR_FLAGS="cru"
 545 fi
 546 AC_SUBST([ARFLAGS])
 547 AC_SUBST([AR_FLAGS])
 548
 549 AC_MSG_CHECKING([whether $RANLIB supports D option])
 550 if $RANLIB -D conftest.a >conftest.err 2>&1; then
 551   if grep -q -- '-D' conftest.err; then
 552     AC_MSG_RESULT([no])
 553   else
 554     AC_MSG_RESULT([yes])
 555     RANLIB="$RANLIB -D"
 556   fi
 557 else
 558   AC_MSG_RESULT([no])
 559 fi
 560 AC_SUBST([RANLIB])
 561
 562 test -f conftest.err && rm conftest.err
 563 test -f conftest.a && rm conftest.a
 564
 565 dnl ----------------------
 566 dnl Packages configuration
 567 dnl ----------------------
 568 if test -f config.version; then
 569   . ./config.version
 570 elif test -f "${srcdir}/config.version"; then
 571   . "${srcdir}/config.version"
 572 fi
 573 AC_ARG_WITH([pkg-extra-version],
 574   AS_HELP_STRING([--with-pkg-extra-version=VER], [add extra version field, for packagers/distributions]), [
 575   if test "$withval" = "no"; then
 576     EXTRAVERSION=
 577   else
 578     EXTRAVERSION=$withval
 579   fi
 580 ], [])
 581 AC_ARG_WITH([pkg-git-version],
 582         AS_HELP_STRING([--with-pkg-git-version], [add git information to MOTD and build version string]),
 583         [ test "$withval" != "no" && with_pkg_git_version="yes" ])
 584 AC_ARG_WITH([clippy],
 585   AS_HELP_STRING([--with-clippy=PATH], [use external clippy helper program]))
 586 AC_ARG_WITH([vtysh_pager],
 587         AS_HELP_STRING([--with-vtysh-pager=PAGER], [control what pager is compiled in as default]),
 588         VTYSH_PAGER=$withval, VTYSH_PAGER="more")
 589 AC_ARG_ENABLE([vtysh],
 590   AS_HELP_STRING([--disable-vtysh], [do not build integrated vty shell for FRR]))
 591 AC_ARG_ENABLE([doc],
 592   AS_HELP_STRING([--disable-doc], [do not build docs]))
 593 AC_ARG_ENABLE([doc-html],
 594   AS_HELP_STRING([--enable-doc-html], [build HTML docs]))
 595 AC_ARG_ENABLE([zebra],
 596   AS_HELP_STRING([--disable-zebra], [do not build zebra daemon]))
 597 AC_ARG_ENABLE([bgpd],
 598   AS_HELP_STRING([--disable-bgpd], [do not build bgpd]))
 599 AC_ARG_ENABLE([ripd],
 600   AS_HELP_STRING([--disable-ripd], [do not build ripd]))
 601 AC_ARG_ENABLE([ripngd],
 602   AS_HELP_STRING([--disable-ripngd], [do not build ripngd]))
 603 AC_ARG_ENABLE([ospfd],
 604   AS_HELP_STRING([--disable-ospfd], [do not build ospfd]))
 605 AC_ARG_ENABLE([ospf6d],
 606   AS_HELP_STRING([--disable-ospf6d], [do not build ospf6d]))
 607 AC_ARG_ENABLE([ldpd],
 608   AS_HELP_STRING([--disable-ldpd], [do not build ldpd]))
 609 AC_ARG_ENABLE([nhrpd],
 610   AS_HELP_STRING([--disable-nhrpd], [do not build nhrpd]))
 611 AC_ARG_ENABLE([eigrpd],
 612   AS_HELP_STRING([--disable-eigrpd], [do not build eigrpd]))
 613 AC_ARG_ENABLE([babeld],
 614   AS_HELP_STRING([--disable-babeld], [do not build babeld]))
 615 AC_ARG_ENABLE([watchfrr],
 616   AS_HELP_STRING([--disable-watchfrr], [do not build watchfrr]))
 617 AC_ARG_ENABLE([isisd],
 618   AS_HELP_STRING([--disable-isisd], [do not build isisd]))
 619 AC_ARG_ENABLE([pimd],
 620   AS_HELP_STRING([--disable-pimd], [do not build pimd]))
 621 AC_ARG_ENABLE([pbrd],
 622   AS_HELP_STRING([--disable-pbrd], [do not build pbrd]))
 623 AC_ARG_ENABLE([sharpd],
 624   AS_HELP_STRING([--enable-sharpd], [build sharpd]))
 625 AC_ARG_ENABLE([staticd],
 626   AS_HELP_STRING([--disable-staticd], [do not build staticd]))
 627 AC_ARG_ENABLE([fabricd],
 628   AS_HELP_STRING([--disable-fabricd], [do not build fabricd]))
 629 AC_ARG_ENABLE([vrrpd],
 630   AS_HELP_STRING([--disable-vrrpd], [do not build vrrpd]))
 631 AC_ARG_ENABLE([pathd],
 632   AS_HELP_STRING([--disable-pathd], [do not build pathd]))
 633 AC_ARG_ENABLE([bgp-announce],
 634   AS_HELP_STRING([--disable-bgp-announce], [turn off BGP route announcement]))
 635 AC_ARG_ENABLE([bgp-vnc],
 636   AS_HELP_STRING([--disable-bgp-vnc],[turn off BGP VNC support]))
 637 AC_ARG_ENABLE([bgp-bmp],
 638   AS_HELP_STRING([--disable-bgp-bmp],[turn off BGP BMP support]))
 639 AC_ARG_ENABLE([snmp],
 640   AS_HELP_STRING([--enable-snmp], [enable SNMP support for agentx]))
 641 AC_ARG_ENABLE([config_rollbacks],
 642   AS_HELP_STRING([--enable-config-rollbacks], [enable configuration rollbacks (requires sqlite3)]))
 643 AC_ARG_ENABLE([confd],
 644   AS_HELP_STRING([--enable-confd=ARG], [enable confd integration]))
 645 AC_ARG_ENABLE([sysrepo],
 646   AS_HELP_STRING([--enable-sysrepo], [enable sysrepo integration]))
 647 AC_ARG_ENABLE([grpc],
 648   AS_HELP_STRING([--enable-grpc], [enable the gRPC northbound plugin]))
 649 AC_ARG_ENABLE([zeromq],
 650   AS_HELP_STRING([--enable-zeromq], [enable ZeroMQ handler (libfrrzmq)]))
 651 AC_ARG_ENABLE([lttng],
 652   AS_HELP_STRING([--enable-lttng], [enable LTTng tracing]))
 653 AC_ARG_ENABLE([usdt],
 654   AS_HELP_STRING([--enable-usdt], [enable USDT probes]))
 655 AC_ARG_WITH([libpam],
 656   AS_HELP_STRING([--with-libpam], [use libpam for PAM support in vtysh]))
 657 AC_ARG_ENABLE([ospfapi],
 658   AS_HELP_STRING([--disable-ospfapi], [do not build OSPFAPI to access the OSPF LSA Database]))
 659 AC_ARG_ENABLE([ospfclient],
 660   AS_HELP_STRING([--disable-ospfclient], [do not build OSPFAPI client for OSPFAPI,
 661                           (this is the default if --disable-ospfapi is set)]))
 662 AC_ARG_ENABLE([multipath],
 663   AS_HELP_STRING([--enable-multipath=ARG], [enable multipath function, ARG must be digit]))
 664 AC_ARG_ENABLE([user],
 665   AS_HELP_STRING([--enable-user=USER], [user to run FRR suite as (default frr)]))
 666 AC_ARG_ENABLE([group],
 667   AS_HELP_STRING([--enable-group=GROUP], [group to run FRR suite as (default frr)]))
 668 AC_ARG_ENABLE([vty_group],
 669   AS_HELP_STRING([--enable-vty-group=ARG], [set vty sockets to have specified group as owner]))
 670 AC_ARG_ENABLE([configfile_mask],
 671   AS_HELP_STRING([--enable-configfile-mask=ARG], [set mask for config files]))
 672 AC_ARG_ENABLE([logfile_mask],
 673   AS_HELP_STRING([--enable-logfile-mask=ARG], [set mask for log files]))
 674 AC_ARG_ENABLE([shell_access],
 675   AS_HELP_STRING([--enable-shell-access], [Allow users to access shell/telnet/ssh]))
 676 AC_ARG_ENABLE([realms],
 677   AS_HELP_STRING([--enable-realms], [enable REALMS support under Linux]))
 678 AC_ARG_ENABLE([rtadv],
 679   AS_HELP_STRING([--disable-rtadv], [disable IPV6 router advertisement feature]))
 680 AC_ARG_ENABLE([irdp],
 681   AS_HELP_STRING([--disable-irdp], [disable IRDP server support in zebra (enabled by default if supported)]))
 682 AC_ARG_ENABLE([capabilities],
 683   AS_HELP_STRING([--disable-capabilities], [disable using POSIX capabilities]))
 684 AC_ARG_ENABLE([gcc_ultra_verbose],
 685   AS_HELP_STRING([--enable-gcc-ultra-verbose], [enable ultra verbose GCC warnings]))
 686 AC_ARG_ENABLE([backtrace],
 687   AS_HELP_STRING([--disable-backtrace], [disable crash backtraces (default autodetect)]))
 688 AC_ARG_ENABLE([time-check],
 689   AS_HELP_STRING([--disable-time-check], [disable slow thread warning messages]))
 690 AC_ARG_ENABLE([cpu-time],
 691   AS_HELP_STRING([--disable-cpu-time], [disable cpu usage data gathering]))
 692 AC_ARG_ENABLE([pcreposix],
 693   AS_HELP_STRING([--enable-pcreposix], [enable using PCRE Posix libs for regex functions]))
 694 AC_ARG_ENABLE([fpm],
 695   AS_HELP_STRING([--enable-fpm], [enable Forwarding Plane Manager support]))
 696 AC_ARG_ENABLE([pcep],
 697   AS_HELP_STRING([--enable-pcep], [enable PCEP support for pathd]))
 698 AC_ARG_ENABLE([werror],
 699   AS_HELP_STRING([--enable-werror], [enable -Werror (recommended for developers only)]))
 700 AC_ARG_ENABLE([cumulus],
 701   AS_HELP_STRING([--enable-cumulus], [enable Cumulus Switch Special Extensions]))
 702 AC_ARG_ENABLE([datacenter],
 703   AS_HELP_STRING([--enable-datacenter], [enable Compilation for Data Center Extensions]))
 704 AC_ARG_ENABLE([rr-semantics],
 705   AS_HELP_STRING([--disable-rr-semantics], [disable the v6 Route Replace semantics]))
 706 AC_ARG_ENABLE([protobuf],
 707   AS_HELP_STRING([--enable-protobuf], [Enable experimental protobuf support]))
 708 AC_ARG_ENABLE([oldvpn_commands],
 709   AS_HELP_STRING([--enable-oldvpn-commands], [Keep old vpn commands]))
 710 AC_ARG_ENABLE([rpki],
 711   AS_HELP_STRING([--enable-rpki], [enable RPKI prefix validation support]))
 712 AC_ARG_ENABLE([clippy-only],
 713   AS_HELP_STRING([--enable-clippy-only], [Only build clippy]))
 714 AC_ARG_ENABLE([numeric_version],
 715   AS_HELP_STRING([--enable-numeric-version], [Only numeric digits allowed in version (for Alpine)]))
 716 AC_ARG_ENABLE([gcov],
 717   AS_HELP_STRING([--enable-gcov], [Collect coverage information with gcov]))
 718 AC_ARG_ENABLE([clang_coverage],
 719   AS_HELP_STRING([--enable-clang-coverage], [Collect coverage information with Clang Coverage]))
 720 AC_ARG_ENABLE([bfdd],
 721   AS_HELP_STRING([--disable-bfdd], [do not build bfdd]))
 722 AC_ARG_ENABLE([address-sanitizer],
 723   AS_HELP_STRING([--enable-address-sanitizer], [enable AddressSanitizer support for detecting a wide variety of memory allocation and deallocation errors]))
 724 AC_ARG_ENABLE([thread-sanitizer],
 725   AS_HELP_STRING([--enable-thread-sanitizer], [enable ThreadSanitizer support for detecting data races]))
 726 AC_ARG_ENABLE([memory-sanitizer],
 727   AS_HELP_STRING([--enable-memory-sanitizer], [enable MemorySanitizer support for detecting uninitialized memory reads]))
 728 AC_ARG_ENABLE([undefined-sanitizer],
 729   AS_HELP_STRING([--enable-undefined-sanitizer], [enable UndefinedBehaviorSanitizer support for detecting undefined behavior]))
 730 AC_ARG_WITH([crypto],
 731   AS_HELP_STRING([--with-crypto=<internal|openssl>], [choose between different implementations of cryptographic functions(default value is --with-crypto=internal)]))
 732 AC_ARG_WITH([frr-format],
 733   AS_HELP_STRING([--with-frr-format[=<.../frr-format.so>]], [use frr-format GCC plugin]))
 734
 735 AC_ARG_ENABLE([version-build-config],
 736   AS_HELP_STRING([--disable-version-build-config], [do not include build configs in show version command]))
 737
 738 #if openssl, else use the internal
 739 AS_IF([test "$with_crypto" = "openssl"], [
 740 AC_CHECK_LIB([crypto], [EVP_DigestInit], [LIBS="$LIBS -lcrypto"], [], [])
 741 if test "$ac_cv_lib_crypto_EVP_DigestInit" = "no"; then
 742   AC_MSG_ERROR([build with openssl has been specified but openssl library was not found on your system])
 743 else
 744   AC_DEFINE([CRYPTO_OPENSSL], [1], [Compile with openssl support])
 745 fi
 746 ], [test "$with_crypto" = "internal" || test "$with_crypto" = "" ], [AC_DEFINE([CRYPTO_INTERNAL], [1], [Compile with internal cryptographic implementation])
 747 ], [AC_MSG_ERROR([Unknown value for --with-crypto])]
 748 )
 749
 750 AS_IF([test "$enable_clippy_only" != "yes"], [
 751 AC_CHECK_HEADERS([json-c/json.h])
 752 AC_CHECK_LIB([json-c], [json_object_get], [LIBS="$LIBS -ljson-c"], [], [-lm])
 753 if test "$ac_cv_lib_json_c_json_object_get" = "no"; then
 754   AC_CHECK_LIB([json], [json_object_get], [LIBS="$LIBS -ljson"])
 755   if test "$ac_cv_lib_json_json_object_get" = "no"; then
 756       AC_MSG_ERROR([libjson is needed to compile])
 757   fi
 758 fi
 759 ])
 760
 761 AC_ARG_ENABLE([dev_build],
 762     AS_HELP_STRING([--enable-dev-build], [build for development]))
 763
 764 AC_ARG_ENABLE([scripting],
 765     AS_HELP_STRING([--enable-scripting], [Build with scripting support]))
 766
 767 AC_ARG_ENABLE([netlink-debug],
 768   AS_HELP_STRING([--disable-netlink-debug], [pretty print netlink debug messages]))
 769
 770 if test "$enable_netlink_debug" != "no" ; then
 771   AC_DEFINE([NETLINK_DEBUG], [1], [Netlink extra debugging code])
 772 fi
 773
 774 AM_CONDITIONAL([NETLINK_DEBUG], [test "$enable_netlink_debug" != "no"])
 775
 776 if test "$enable_time_check" != "no" ; then
 777   if test "$enable_time_check" = "yes" -o "$enable_time_check" = "" ; then
 778     AC_DEFINE([CONSUMED_TIME_CHECK], [5000000], [Consumed Time Check])
 779   else
 780     AC_DEFINE_UNQUOTED([CONSUMED_TIME_CHECK], [$enable_time_check], [Consumed Time Check])
 781   fi
 782 fi
 783
 784 case "${enable_cpu_time}" in
 785   "no")
 786   AC_DEFINE([EXCLUDE_CPU_TIME], [1], [Exclude getrusage data gathering])
 787   ;;
 788   "*")
 789   ;;
 790 esac
 791
 792 if test "$enable_rr_semantics" != "no" ; then
 793   AC_DEFINE([HAVE_V6_RR_SEMANTICS], [1], [Compile in v6 Route Replacement Semantics])
 794 fi
 795
 796 if test "$enable_datacenter" = "yes" ; then
 797   AC_DEFINE([HAVE_DATACENTER], [1], [Compile extensions for a DataCenter])
 798   DFLT_NAME="datacenter"
 799 else
 800   DFLT_NAME="traditional"
 801 fi
 802
 803 if test "$enable_cumulus" = "yes" ; then
 804   AC_DEFINE([HAVE_CUMULUS], [1], [Compile Special Cumulus Code in])
 805 fi
 806
 807 AC_SUBST([DFLT_NAME])
 808 AC_DEFINE_UNQUOTED([DFLT_NAME], ["$DFLT_NAME"], [Name of the configuration default set])
 809
 810 if test "$enable_shell_access" = "yes"; then
 811    AC_DEFINE([HAVE_SHELL_ACCESS], [1], [Allow user to use ssh/telnet/bash, be aware this is considered insecure])
 812 fi
 813
 814 #
 815 # Python for clippy
 816 #
 817
 818 AS_IF([test "$host" = "$build"], [
 819   AM_PATH_PYTHON([3])
 820   AC_CHECK_HEADER([gelf.h], [], [
 821     AC_MSG_ERROR([libelf headers are required for building clippy.  (Host only when cross-compiling.)])
 822   ])
 823
 824   LIBS_save="$LIBS"
 825   AC_CHECK_LIB([elf], [elf_memory], [], [
 826     AC_MSG_ERROR([libelf is required for building clippy.  (Host only when cross-compiling.)])
 827   ])
 828
 829   AC_CHECK_LIB([elf], [elf_getdata_rawchunk], [
 830     AC_DEFINE([HAVE_ELF_GETDATA_RAWCHUNK], [1], [Have elf_getdata_rawchunk()])
 831   ])
 832   AC_CHECK_LIB([elf], [gelf_getnote], [
 833     AC_DEFINE([HAVE_GELF_GETNOTE], [1], [Have gelf_getnote()])
 834   ])
 835   LIBS="$LIBS_save"
 836   unset LIBS_save
 837
 838   FRR_PYTHON_DEV
 839 ], [
 840   FRR_PYTHON
 841 ])
 842
 843 FRR_PYTHON_MODULES([pytest])
 844
 845 if test "$enable_doc" != "no"; then
 846   FRR_PYTHON_MODULES([sphinx], , [
 847     if test "$enable_doc" = "yes"; then
 848       AC_MSG_ERROR([Documentation was explicitly requested with --enable-doc but sphinx is not available for $PYTHON. Please disable docs or install sphinx.])
 849     fi
 850   ])
 851 fi
 852 AM_CONDITIONAL([DOC], [test "$enable_doc" != "no" -a "$frr_py_mod_sphinx" != "false"])
 853 AM_CONDITIONAL([DOC_HTML], [test "$enable_doc_html" = "yes"])
 854
 855 FRR_PYTHON_MOD_EXEC([sphinx], [--version], [
 856   PYSPHINX="-m sphinx"
 857 ], [
 858   PYSPHINX="-c 'import sys; from sphinx import main; sys.exit(main(sys.argv))'"
 859 ])
 860 AC_SUBST([PYSPHINX])
 861
 862 #
 863 # Logic for old vpn commands support.
 864 #
 865 if test "$enable_oldvpn_commands" = "yes"; then
 866    AC_DEFINE([KEEP_OLD_VPN_COMMANDS], [1], [Define for compiling with old vpn commands])
 867 fi
 868
 869 #
 870 # End of logic for protobuf support.
 871 #
 872
 873 AC_MSG_CHECKING([if zebra should be configurable to send Route Advertisements])
 874 if test "$enable_rtadv" != "no"; then
 875   AC_MSG_RESULT([yes])
 876   AC_DEFINE([HAVE_RTADV], [1], [Enable IPv6 Routing Advertisement support])
 877 else
 878   AC_MSG_RESULT([no])
 879 fi
 880
 881 if test "$enable_user" = "no"; then
 882   enable_user=""
 883 else
 884   if test "$enable_user" = "yes" || test "$enable_user" = ""; then
 885     enable_user="frr"
 886   fi
 887   AC_DEFINE_UNQUOTED([FRR_USER], ["${enable_user}"], [frr User])
 888 fi
 889
 890 if test "$enable_group" = "no"; then
 891   enable_group=""
 892 else
 893   if test "$enable_group" = "yes" || test "$enable_group" = ""; then
 894     enable_group="frr"
 895   fi
 896   AC_DEFINE_UNQUOTED([FRR_GROUP], ["${enable_group}"], [frr Group])
 897 fi
 898
 899 if test "$enable_vty_group" = "yes" ; then
 900   AC_MSG_ERROR([--enable-vty-group requires a group as argument, not yes])
 901 elif test "$enable_vty_group" != ""; then
 902   if test "$enable_vty_group" != "no"; then
 903     AC_DEFINE_UNQUOTED([VTY_GROUP], ["${enable_vty_group}"], [VTY Sockets Group])
 904   fi
 905 fi
 906 AC_SUBST([enable_user])
 907 AC_SUBST([enable_group])
 908 AC_SUBST([enable_vty_group])
 909
 910 enable_configfile_mask=${enable_configfile_mask:-0600}
 911 AC_DEFINE_UNQUOTED([CONFIGFILE_MASK], [${enable_configfile_mask}], [Mask for config files])
 912 AC_SUBST([enable_configfile_mask])
 913
 914 enable_logfile_mask=${enable_logfile_mask:-0600}
 915 AC_DEFINE_UNQUOTED([LOGFILE_MASK], [${enable_logfile_mask}], [Mask for log files])
 916
 917 MPATH_NUM=16
 918
 919 case "${enable_multipath}" in
 920   0)
 921     MPATH_NUM=64
 922     ;;
 923   [[1-9]|[1-9][0-9]|[1-9][0-9][0-9]])
 924     MPATH_NUM="${enable_multipath}"
 925     ;;
 926   "")
 927     ;;
 928   *)
 929     AC_MSG_FAILURE([Please specify digit to enable multipath ARG])
 930     ;;
 931 esac
 932
 933 AC_DEFINE_UNQUOTED([MULTIPATH_NUM], [$MPATH_NUM], [Maximum number of paths for a route])
 934
 935 AC_DEFINE_UNQUOTED([VTYSH_PAGER], ["$VTYSH_PAGER"], [What pager to use])
 936
 937 dnl --------------------
 938 dnl Enable code coverage
 939 dnl --------------------
 940 AM_CONDITIONAL([HAVE_GCOV], [test "$enable_gcov" != "no"])
 941
 942 dnl ------------------------------------
 943 dnl Alpine only accepts numeric versions
 944 dnl ------------------------------------
 945 if test "$enable_numeric_version" != "" ; then
 946   VERSION="`echo ${VERSION} | tr -c -d '[[.0-9]]'`"
 947   PACKAGE_VERSION="`echo ${PACKAGE_VERSION} | tr -c -d '[[.0-9]]'`"
 948 fi
 949
 950 dnl -----------------------------------
 951 dnl Add extra version string to package
 952 dnl name, string and version fields.
 953 dnl -----------------------------------
 954 if test "$EXTRAVERSION" != "" ; then
 955   VERSION="${VERSION}${EXTRAVERSION}"
 956   PACKAGE_VERSION="${PACKAGE_VERSION}${EXTRAVERSION}"
 957   AC_SUBST(PACKAGE_EXTRAVERSION, ["${EXTRAVERSION}"])
 958   PACKAGE_STRING="${PACKAGE_STRING}${EXTRAVERSION}"
 959 fi
 960 AC_SUBST([EXTRAVERSION])
 961
 962 if test "$with_pkg_git_version" = "yes"; then
 963         if test -e "${srcdir}/.git"; then
 964                 AC_DEFINE([GIT_VERSION], [1], [include git version info])
 965         else    with_pkg_git_version="no"
 966                 AC_MSG_WARN([--with-pkg-git-version given, but this is not a git checkout])
 967         fi
 968 fi
 969 AM_CONDITIONAL([GIT_VERSION], [test "$with_pkg_git_version" = "yes"])
 970
 971 AC_CHECK_TOOL([OBJCOPY], [objcopy], [:])
 972 if test "$OBJCOPY" != ":"; then
 973   AC_CACHE_CHECK([for .interp value to use], [frr_cv_interp], [
 974     frr_cv_interp=""
 975     AC_LINK_IFELSE([AC_LANG_SOURCE([[int main() { return 0; }]])], [
 976       if $OBJCOPY -j.interp -Obinary conftest conftest.interp; then
 977         frr_cv_interp="`xargs -0 echo < conftest.interp`"
 978       fi
 979       test -f conftest.interp && rm conftest.interp
 980     ])
 981   ])
 982 fi
 983 if test -n "$frr_cv_interp"; then
 984   AC_DEFINE_UNQUOTED([INTERP], ["$frr_cv_interp"], [.interp value])
 985 fi
 986
 987 dnl -------------------------
 988 dnl Check other header files.
 989 dnl -------------------------
 990 AC_CHECK_HEADERS([stropts.h sys/ksym.h \
 991         linux/version.h asm/types.h endian.h sys/endian.h])
 992
 993 ac_stdatomic_ok=false
 994 AC_DEFINE([FRR_AUTOCONF_ATOMIC], [1], [did autoconf checks for atomic funcs])
 995 AC_CHECK_HEADER([stdatomic.h],[
 996
 997   AC_MSG_CHECKING([whether _Atomic qualifier works])
 998   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 999 #include <stdatomic.h>
1000 int main(int argc, char **argv) {
1001   _Atomic int i = 0;
1002   return i;
1003 }
1004 ]])], [
1005     AC_DEFINE([HAVE_STDATOMIC_H], [1], [found stdatomic.h])
1006     AC_MSG_RESULT([yes])
1007     ac_stdatomic_ok=true
1008   ], [
1009     AC_MSG_RESULT([no])
1010   ])
1011 ])
1012
1013 AS_IF([$ac_stdatomic_ok], [true], [
1014   AC_MSG_CHECKING([for __atomic_* builtins])
1015   AC_LINK_IFELSE([AC_LANG_SOURCE([[
1016 int main(int argc, char **argv) {
1017   volatile int i = 1;
1018   __atomic_store_n (&i, 0, __ATOMIC_RELEASE);
1019   return __atomic_load_n (&i, __ATOMIC_ACQUIRE);
1020 }
1021 ]])], [
1022     AC_DEFINE([HAVE___ATOMIC], [1], [found __atomic builtins])
1023     AC_MSG_RESULT([yes])
1024   ], [
1025     AC_MSG_RESULT([no])
1026
1027     dnl FreeBSD 9 has a broken stdatomic.h where _Atomic doesn't work
1028     AC_MSG_CHECKING([for __sync_* builtins])
1029     AC_LINK_IFELSE([AC_LANG_SOURCE([[
1030 int main(int argc, char **argv) {
1031   volatile int i = 1;
1032   __sync_fetch_and_sub (&i, 1);
1033   return __sync_val_compare_and_swap (&i, 0, 1);
1034 }
1035 ]])], [
1036       AC_DEFINE([HAVE___SYNC], [1], [found __sync builtins])
1037       AC_MSG_RESULT([yes])
1038
1039       AC_MSG_CHECKING([for __sync_swap builtin])
1040       AC_LINK_IFELSE([AC_LANG_SOURCE([[
1041 int main(int argc, char **argv) {
1042   volatile int i = 1;
1043   return __sync_swap (&i, 2);
1044 }
1045 ]])], [
1046         AC_DEFINE([HAVE___SYNC_SWAP], 1, [found __sync_swap builtin])
1047         AC_MSG_RESULT([yes])
1048       ], [
1049         AC_MSG_RESULT([no])
1050       ])
1051
1052     ], [
1053       AC_MSG_RESULT([no])
1054       AC_MSG_FAILURE([stdatomic.h unavailable and $CC has neither __atomic nor __sync builtins])
1055     ])
1056   ])
1057 ])
1058
1059 needsync=true
1060
1061 AS_IF([$needsync], [
1062   dnl Linux
1063   AC_MSG_CHECKING([for Linux futex() support])
1064   AC_LINK_IFELSE([AC_LANG_PROGRAM([
1065 #ifndef _GNU_SOURCE
1066 #define _GNU_SOURCE
1067 #endif
1068 #include <unistd.h>
1069 #include <limits.h>
1070 #include <sys/time.h>
1071 #include <sys/syscall.h>
1072 #include <linux/futex.h>
1073
1074 int main(void);
1075 ],
1076 [
1077 {
1078   return syscall(SYS_futex, NULL, FUTEX_WAIT, 0, NULL, NULL, 0);
1079 }
1080 ])], [
1081     AC_MSG_RESULT([yes])
1082     AC_DEFINE(HAVE_SYNC_LINUX_FUTEX,,Have Linux futex support)
1083     needsync=false
1084   ], [
1085     AC_MSG_RESULT([no])
1086   ])
1087 ])
1088
1089 AS_IF([$needsync], [
1090   dnl FreeBSD
1091   AC_MSG_CHECKING([for FreeBSD _umtx_op() support])
1092   AC_LINK_IFELSE([AC_LANG_PROGRAM([
1093 #include <errno.h>
1094 #include <stdlib.h>
1095 #include <sys/types.h>
1096 #include <sys/umtx.h>
1097 int main(void);
1098 ],
1099 [
1100 {
1101   return _umtx_op(NULL, UMTX_OP_WAIT_UINT, 0, NULL, NULL);
1102 }
1103 ])], [
1104     AC_MSG_RESULT([yes])
1105     AC_DEFINE(HAVE_SYNC_UMTX_OP,,Have FreeBSD _umtx_op() support)
1106     needsync=false
1107   ], [
1108     AC_MSG_RESULT([no])
1109   ])
1110 ])
1111
1112 AS_IF([$needsync], [
1113   dnl OpenBSD patch (not upstream at the time of writing this)
1114   dnl https://marc.info/?l=openbsd-tech&m=147299508409549&w=2
1115   AC_MSG_CHECKING([for OpenBSD futex() support])
1116   AC_LINK_IFELSE([AC_LANG_PROGRAM([
1117 #include <sys/futex.h>
1118 int main(void);
1119 ],
1120 [
1121 {
1122   return futex(NULL, FUTEX_WAIT, 0, NULL, NULL, 0);
1123 }
1124 ])], [
1125     AC_MSG_RESULT([yes])
1126     AC_DEFINE(HAVE_SYNC_OPENBSD_FUTEX,,Have OpenBSD futex support)
1127     needsync=false
1128   ], [
1129     AC_MSG_RESULT([no])
1130   ])
1131 ])
1132
1133 dnl Utility macro to avoid retyping includes all the time
1134 m4_define([FRR_INCLUDES],
1135 [#ifdef SUNOS_5
1136 #define _POSIX_C_SOURCE 200809L
1137 #define __EXTENSIONS__
1138 #endif
1139 #include <stdio.h>
1140 #include <stdlib.h>
1141 #include <stddef.h>
1142 #include <sys/types.h>
1143 /* sys/conf.h depends on param.h on FBSD at least */
1144 #include <sys/param.h>
1145 /* Required for MAXSIG */
1146 #include <signal.h>
1147 #include <sys/socket.h>
1148 #ifdef __APPLE__
1149 # define __APPLE_USE_RFC_3542
1150 #endif
1151 #include <netinet/in.h>
1152 #include <sys/time.h>
1153 #include <time.h>
1154 #include <net/if.h>
1155 ])dnl
1156
1157 dnl Same applies for HAVE_NET_IF_VAR_H, which HAVE_NETINET6_ND6_H and
1158 dnl HAVE_NETINET_IN_VAR_H depend upon. But if_var.h depends on if.h, hence
1159 dnl an additional round for it.
1160
1161 AC_CHECK_HEADERS([net/if_var.h], [], [], [FRR_INCLUDES])
1162
1163 m4_define([FRR_INCLUDES],
1164 FRR_INCLUDES
1165 [#ifdef HAVE_NET_IF_VAR_H
1166 # include <net/if_var.h>
1167 #endif
1168 ])dnl
1169
1170 AC_CHECK_HEADERS([netinet/in_var.h \
1171         net/if_dl.h net/netopt.h \
1172         inet/nd.h netinet/ip_icmp.h \
1173         sys/sysctl.h sys/sockio.h sys/conf.h],
1174         [], [], [FRR_INCLUDES])
1175
1176 AC_CHECK_HEADERS([ucontext.h], [], [],
1177 [#ifndef __USE_GNU
1178 #define __USE_GNU
1179 #endif /* __USE_GNU */
1180 FRR_INCLUDES
1181 ])
1182
1183 m4_define([UCONTEXT_INCLUDES],
1184 [#include <ucontext.h>])dnl
1185
1186 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.uc_regs],
1187   [], [], [UCONTEXT_INCLUDES])
1188 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs],
1189   [AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs.nip],
1190    [], [], [UCONTEXT_INCLUDES])],
1191   [], [UCONTEXT_INCLUDES])
1192 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.gregs],
1193   [], [], [UCONTEXT_INCLUDES])
1194
1195 m4_define([FRR_INCLUDES],
1196 FRR_INCLUDES
1197 [
1198 #include <sys/un.h>
1199 #include <netinet/in_systm.h>
1200 #ifdef HAVE_NETINET_IN_VAR_H
1201 # include <netinet/in_var.h>
1202 #endif
1203 #ifdef HAVE_NET_IF_DL_H
1204 # include <net/if_dl.h>
1205 #endif
1206 #ifdef HAVE_NET_NETOPT_H
1207 # include <net/netopt.h>
1208 #endif
1209 #include <net/route.h>
1210 #ifdef HAVE_INET_ND_H
1211 # include <inet/nd.h>
1212 #endif
1213 #include <arpa/inet.h>
1214 /* Required for IDRP */
1215 #ifdef HAVE_NETINET_IP_ICMP_H
1216 # include <netinet/ip_icmp.h>
1217 #endif
1218 ])dnl
1219
1220 dnl V6 headers are checked below, after we check for v6
1221
1222 is_linux=false
1223
1224 AC_MSG_CHECKING([which operating system interface to use])
1225 case "$host_os" in
1226   sunos* | solaris2*)
1227     AC_MSG_FAILURE([Solaris support has been removed please see versions prior or equal to 7.5])
1228     ;;
1229   linux*)
1230     AC_MSG_RESULT([Linux])
1231
1232     AC_DEFINE([GNU_LINUX], [1], [GNU Linux])
1233     AC_DEFINE([HAVE_NETLINK], [1], [netlink])
1234     AC_DEFINE([LINUX_IPV6], [1], [Linux IPv6 stack])
1235
1236     dnl Linux has a compilation problem with mixing
1237     dnl netinet/in.h and linux/in6.h they are not
1238     dnl compatible.  There has been discussion on
1239     dnl how to fix it but no real progress on implementation
1240     dnl when they fix it, remove this
1241     AC_DEFINE([IPV6_MINHOPCOUNT], [73], [Linux ipv6 Min Hop Count])
1242
1243     is_linux=true
1244     ;;
1245   openbsd*)
1246     AC_MSG_RESULT([OpenBSD])
1247
1248     AC_DEFINE([OPEN_BSD], [1], [OpenBSD])
1249     AC_DEFINE([KAME], [1], [KAME IPv6])
1250     AC_DEFINE([BSD_V6_SYSCTL], [1], [BSD v6 sysctl to turn on and off forwarding])
1251     ;;
1252   *)
1253     AC_MSG_RESULT([BSD])
1254
1255     AC_DEFINE([HAVE_NET_RT_IFLIST], [1], [NET_RT_IFLIST])
1256     AC_DEFINE([KAME], [1], [KAME IPv6])
1257     AC_DEFINE([BSD_V6_SYSCTL], [1], [BSD v6 sysctl to turn on and off forwarding])
1258     ;;
1259 esac
1260 AM_CONDITIONAL([LINUX], [${is_linux}])
1261
1262 AC_SYS_LARGEFILE
1263
1264 dnl ------------------------
1265 dnl Integrated REALMS option
1266 dnl ------------------------
1267 if test "$enable_realms" = "yes"; then
1268     case "$host_os" in
1269       linux*)
1270        AC_DEFINE([SUPPORT_REALMS], [1], [Realms support])
1271        ;;
1272       *)
1273        echo "Sorry, only Linux has REALMS support"
1274        exit 1
1275        ;;
1276     esac
1277 fi
1278
1279 dnl ---------------
1280 dnl other functions
1281 dnl ---------------
1282 AC_CHECK_FUNCS([ \
1283         strlcat strlcpy \
1284         getgrouplist \
1285         openat \
1286         unlinkat \
1287         posix_fallocate \
1288         ])
1289
1290 dnl ##########################################################################
1291 dnl LARGE if block spans a lot of "configure"!
1292 if test "$enable_clippy_only" != "yes"; then
1293 dnl ##########################################################################
1294
1295 #
1296 # Logic for protobuf support.
1297 #
1298 PROTO3=false
1299 if test "$enable_protobuf" = "yes"; then
1300   # Check for protoc & protoc-c
1301
1302   # protoc is not required, it's only for a "be nice" helper target
1303   AC_CHECK_PROGS([PROTOC], [protoc], [/bin/false])
1304
1305   AC_CHECK_PROGS([PROTOC_C], [protoc-c], [/bin/false])
1306   if test "$PROTOC_C" = "/bin/false"; then
1307     AC_MSG_FAILURE([protobuf requested but protoc-c not found.  Install protobuf-c.])
1308   fi
1309
1310   PKG_CHECK_MODULES([PROTOBUF_C], [libprotobuf-c >= 0.14],, [
1311     AC_MSG_FAILURE([protobuf requested but libprotobuf-c not found.  Install protobuf-c.])
1312   ])
1313
1314   PROTO3=true
1315   AC_CHECK_HEADER([google/protobuf-c/protobuf-c.h],
1316                   [AC_CHECK_DECLS(PROTOBUF_C_LABEL_NONE,
1317                                   AC_DEFINE([HAVE_PROTOBUF_VERSION_3],
1318                                             [1], [Have Protobuf version 3]),
1319                                   [PROTO3=false],
1320                                   [#include <google/protobuf-c/protobuf-c.h>])],
1321                   [PROTO3=false && AC_MSG_FAILURE([protobuf requested but protobuf-c.h not found.  Install protobuf-c.])])
1322
1323   AC_DEFINE([HAVE_PROTOBUF], [1], [protobuf])
1324 fi
1325
1326
1327 dnl ---------------------
1328 dnl Integrated VTY option
1329 dnl ---------------------
1330 case "${enable_vtysh}" in
1331 "no")
1332   VTYSH="";;
1333 *)
1334   VTYSH="vtysh";
1335   AC_DEFINE([VTYSH], [1], [VTY shell])
1336
1337   prev_libs="$LIBS"
1338   AC_CHECK_LIB([readline], [main], [
1339     LIBREADLINE="-lreadline"
1340   ], [
1341     dnl readline failed - it might be incorrectly linked and missing its
1342     dnl termcap/tinfo/curses dependency.  see if we can fix that...
1343     AC_SEARCH_LIBS([tputs], [termcap tinfo curses ncurses], [
1344       LIBREADLINE="$ac_cv_search_tputs"
1345     ], [
1346       AC_MSG_ERROR([libreadline (needed for vtysh) not found and/or missing dependencies])
1347     ])
1348
1349     dnl re-try with the lib we found above
1350     unset ac_cv_lib_readline_main
1351     AC_CHECK_LIB([readline], [main], [
1352       LIBREADLINE="-lreadline $LIBREADLINE"
1353     ], [
1354       AC_MSG_ERROR([libreadline (needed for vtysh) not found and/or missing dependencies])
1355     ], [$LIBREADLINE])
1356   ], [])
1357   LIBS="$prev_libs"
1358
1359   AC_CHECK_HEADER([readline/history.h])
1360   if test "$ac_cv_header_readline_history_h" = "no"; then
1361     AC_MSG_ERROR([readline is too old to have readline/history.h, please update to the latest readline library.])
1362   fi
1363   AC_CHECK_LIB([readline], [rl_completion_matches], [true], [], [$LIBREADLINE])
1364   if test "$ac_cv_lib_readline_rl_completion_matches" = "no"; then
1365     AC_DEFINE([rl_completion_matches], [completion_matches], [Old readline])
1366   fi
1367   AC_CHECK_LIB([readline], [append_history], [frr_cv_append_history=yes], [frr_cv_append_history=no], [$LIBREADLINE])
1368   if test "$frr_cv_append_history" = "yes"; then
1369     AC_DEFINE([HAVE_APPEND_HISTORY], [1], [Have history.h append_history])
1370   fi
1371   ;;
1372 esac
1373 AC_SUBST([LIBREADLINE])
1374
1375 dnl ----------
1376 dnl PAM module
1377 dnl
1378 dnl FRR detects the PAM library it is built against by checking for a
1379 dnl functional pam_misc.h (Linux-PAM) or openpam.h (OpenPAM) header. pam_misc.h
1380 dnl is known to #include pam_appl.h, the standard header of a PAM library, and
1381 dnl openpam.h doesn't do that, although depends on the header too. Hence a
1382 dnl little assistance to AC_CHECK_HEADER is necessary for the proper detection
1383 dnl of OpenPAM.
1384 dnl ----------
1385 if test "$with_libpam" = "yes"; then
1386   AC_CHECK_HEADER([security/pam_misc.h],
1387     [AC_DEFINE([HAVE_PAM_MISC_H], [1], [Have pam_misc.h])
1388      AC_DEFINE([PAM_CONV_FUNC], [misc_conv], [Have misc_conv])
1389      pam_conv_func="misc_conv"
1390     ],
1391     [], FRR_INCLUDES)
1392   AC_CHECK_HEADER([security/openpam.h],
1393     [AC_DEFINE([HAVE_OPENPAM_H], [1], [Have openpam.h])
1394      AC_DEFINE([PAM_CONV_FUNC], [openpam_ttyconv], [Have openpam_ttyconv])
1395      pam_conv_func="openpam_ttyconv"
1396     ],
1397     [], FRR_INCLUDES[#include <security/pam_appl.h>])
1398   if test -z "$ac_cv_header_security_pam_misc_h$ac_cv_header_security_openpam_h" ; then
1399     AC_MSG_WARN([*** pam support will not be built ***])
1400     with_libpam="no"
1401   fi
1402 fi
1403
1404 if test "$with_libpam" = "yes"; then
1405 dnl took this test from proftpds configure.in and suited to our needs
1406 dnl -------------------------------------------------------------------------
1407 dnl
1408 dnl This next check looks funky due to a linker problem with some versions
1409 dnl of the PAM library.  Prior to 0.72 release, the Linux PAM shared library
1410 dnl omitted requiring libdl linking information. PAM-0.72 or better ships
1411 dnl with RedHat 6.2 and Debian 2.2 or better.
1412 AC_CHECK_LIB([pam], [pam_start],
1413   [AC_CHECK_LIB([pam], [$pam_conv_func],
1414     [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1415      LIBPAM="-lpam"],
1416     [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1417      LIBPAM="-lpam -lpam_misc"]
1418     )
1419   ],
1420
1421   [AC_CHECK_LIB([pam], [pam_end],
1422     [AC_CHECK_LIB([pam], [$pam_conv_func],
1423       [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1424        LIBPAM="-lpam -ldl"],
1425       [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1426        LIBPAM="-lpam -ldl -lpam_misc"]
1427      )
1428   ],AC_MSG_WARN([*** pam support will not be built ***]),
1429   [-ldl])
1430   ]
1431 )
1432 fi
1433 AC_SUBST([LIBPAM])
1434
1435 dnl -------------------------------
1436 dnl bgpd needs pow() and hence libm
1437 dnl -------------------------------
1438 TMPLIBS="$LIBS"
1439 LIBS=""
1440 AC_SEARCH_LIBS([pow], [m], [
1441   LIBM="$LIBS"
1442 ], [
1443   AC_MSG_WARN([Unable to find working pow function - bgpd may not link])
1444 ])
1445 LIBS="$TMPLIBS"
1446 AC_SUBST([LIBM])
1447
1448 AC_CHECK_FUNCS([ppoll], [
1449   AC_DEFINE([HAVE_PPOLL], [1], [have Linux/BSD ppoll()])
1450 ])
1451 AC_CHECK_FUNCS([pollts], [
1452   AC_DEFINE([HAVE_POLLTS], [1], [have NetBSD pollts()])
1453 ])
1454
1455 AC_CHECK_HEADER([asm-generic/unistd.h],
1456                 [AC_CHECK_DECL(__NR_setns,
1457                                AC_DEFINE([HAVE_NETNS], [1], [Have netns]),,
1458                                FRR_INCLUDES [#include <asm-generic/unistd.h>
1459                                ])
1460                  AC_CHECK_FUNCS([setns])]
1461                )
1462
1463 dnl --------------------------
1464 dnl Determine IS-IS I/O method
1465 dnl --------------------------
1466 AC_DEFINE([ISIS_METHOD_PFPACKET], [1], [constant value for isis method pfpacket])
1467 AC_DEFINE([ISIS_METHOD_DLPI], [2], [constant value for isis method dlpi])
1468 AC_DEFINE([ISIS_METHOD_BPF], [3], [constant value for isis method bpf])
1469 AC_CHECK_HEADER([net/bpf.h])
1470 AC_CHECK_HEADER([sys/dlpi.h])
1471 AC_MSG_CHECKING([zebra IS-IS I/O method])
1472
1473 case "$host_os" in
1474   linux*)
1475     AC_MSG_RESULT([pfpacket])
1476     ISIS_METHOD_MACRO="ISIS_METHOD_PFPACKET"
1477     ;;
1478   *)
1479     if test "$ac_cv_header_net_bpf_h" = "no"; then
1480       if test "$ac_cv_header_sys_dlpi_h" = "no"; then
1481         AC_MSG_RESULT([none])
1482         if test "$enable_isisd" = "yes" -o "$enable_fabricd" = "yes"; then
1483           AC_MSG_FAILURE([IS-IS support requested but no packet backend found])
1484         fi
1485         AC_MSG_WARN([*** IS-IS support will not be built ***])
1486         enable_isisd="no"
1487         enable_fabricd="no"
1488       else
1489         AC_MSG_RESULT([DLPI])
1490       fi
1491       ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1492     else
1493       AC_MSG_RESULT([BPF])
1494       ISIS_METHOD_MACRO="ISIS_METHOD_BPF"
1495     fi
1496     ;;
1497 esac
1498 AC_DEFINE_UNQUOTED([ISIS_METHOD], [$ISIS_METHOD_MACRO], [selected method for isis, == one of the constants])
1499
1500 dnl ---------------------------------------------------------------
1501 dnl figure out how to specify an interface in multicast sockets API
1502 dnl ---------------------------------------------------------------
1503 AC_CHECK_MEMBERS([struct ip_mreqn.imr_ifindex], [], [], FRR_INCLUDES)
1504
1505 AC_CHECK_HEADERS([linux/mroute.h], [], [],[
1506         #include <sys/socket.h>
1507         #include <netinet/in.h>
1508         #define _LINUX_IN_H             /* For Linux <= 2.6.25 */
1509         #include <linux/types.h>
1510 ])
1511
1512 m4_define([FRR_INCLUDES],
1513 FRR_INCLUDES
1514 [#ifdef HAVE_LINUX_MROUTE_H
1515 # include <linux/mroute.h>
1516 #endif
1517 ])dnl
1518
1519 AC_CHECK_HEADERS([netinet/ip_mroute.h], [], [],[
1520         #include <sys/socket.h>
1521         #include <sys/types.h>
1522         #include <netinet/in.h>
1523         #include <net/route.h>
1524 ])
1525
1526 m4_define([FRR_INCLUDES],
1527 FRR_INCLUDES
1528 [#ifdef HAVE_NETINET_IP_MROUTE_H
1529 # include <netinet/ip_mroute.h>
1530 #endif
1531 ])dnl
1532
1533 AC_MSG_CHECKING([for RFC3678 protocol-independed API])
1534 AC_COMPILE_IFELSE(
1535 [ AC_LANG_PROGRAM([[
1536       #include <sys/types.h>
1537       #include <netinet/in.h>
1538   ]], [[
1539       struct group_req gr;
1540       int sock;
1541       setsockopt(sock, IPPROTO_IP, MCAST_JOIN_GROUP, (void*)&gr, sizeof(gr));
1542   ]])
1543 ],[
1544   AC_MSG_RESULT([yes])
1545   AC_DEFINE([HAVE_RFC3678], [1], [Have RFC3678 protocol-independed API])
1546 ],[
1547   AC_MSG_RESULT(no)
1548 ])
1549
1550 dnl ---------------------------------------------------------------
1551 dnl figure out how to check link-state
1552 dnl ---------------------------------------------------------------
1553 AC_CHECK_HEADER([net/if_media.h],
1554   [m4_define([LINK_DETECT_INCLUDES],
1555     FRR_INCLUDES
1556     [#include <net/if_media.h>
1557   ])
1558   AC_CHECK_MEMBERS([struct ifmediareq.ifm_status],
1559     AC_DEFINE([HAVE_BSD_LINK_DETECT], [1], [BSD link-detect]),
1560     [], LINK_DETECT_INCLUDES)],
1561   [],
1562   FRR_INCLUDES)
1563
1564 dnl ---------------------------------------------------------------
1565 dnl Additional, newer way to check link-state using ifi_link_state.
1566 dnl Not available in all BSD's when ifmediareq available
1567 dnl ---------------------------------------------------------------
1568 AC_CHECK_MEMBERS([struct if_data.ifi_link_state],
1569   AC_DEFINE([HAVE_BSD_IFI_LINK_STATE], [1], [BSD ifi_link_state available]),
1570   [], FRR_INCLUDES)
1571
1572 dnl ------------------------
1573 dnl TCP_MD5SIG socket option
1574 dnl ------------------------
1575
1576 AC_CHECK_HEADER([netinet/tcp.h],
1577    [m4_define([MD5_INCLUDES],
1578       FRR_INCLUDES
1579       [#include <netinet/tcp.h>
1580     ])
1581     AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)],
1582    [],
1583    FRR_INCLUDES)
1584 if test "$ac_cv_have_decl_TCP_MD5SIG" = "no"; then
1585   AC_CHECK_HEADER([linux/tcp.h],
1586        [m4_define([MD5_INCLUDES],
1587           FRR_INCLUDES
1588           [#include <linux/tcp.h>
1589         ])
1590        AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)])
1591 fi
1592
1593 LIBS_save="$LIBS"
1594 AC_CHECK_LIB([crypt], [crypt], [], [
1595   AC_CHECK_LIB([crypto], [DES_crypt])
1596 ])
1597 LIBCRYPT="$LIBS"
1598 LIBCRYPT="${LIBCRYPT%$LIBS_save}"
1599 LIBCRYPT="${LIBCRYPT#$LIBS_save}"
1600 AC_SUBST([LIBCRYPT])
1601 LIBS="$LIBS_save"
1602 unset LIBS_save
1603
1604 AC_CHECK_LIB([resolv], [res_init])
1605
1606 dnl ---------------------------
1607 dnl check system has PCRE regexp
1608 dnl ---------------------------
1609 if test "$enable_pcreposix" = "yes"; then
1610   AC_CHECK_LIB([pcreposix], [regexec], [], [
1611     AC_MSG_ERROR([--enable-pcreposix given but unable to find libpcreposix])
1612   ])
1613 fi
1614 AC_SUBST([HAVE_LIBPCREPOSIX])
1615
1616 dnl ##########################################################################
1617 dnl test "$enable_clippy_only" != "yes"
1618 fi
1619 dnl END OF LARGE if block
1620 dnl ##########################################################################
1621
1622 dnl ------------------
1623 dnl check C-Ares library
1624 dnl ------------------
1625 PKG_CHECK_MODULES([CARES], [libcares], [
1626   c_ares_found=true
1627 ],[
1628   c_ares_found=false
1629 ])
1630 AM_CONDITIONAL([CARES], [$c_ares_found])
1631
1632
1633 dnl ----------------------------------------------------------------------------
1634 dnl figure out if domainname is available in the utsname struct (GNU extension).
1635 dnl ----------------------------------------------------------------------------
1636 AC_CHECK_MEMBERS([struct utsname.domainname], [], [], [#include <sys/utsname.h>])
1637
1638 dnl ------------------
1639 dnl IPv6 header checks
1640 dnl ------------------
1641 AC_CHECK_HEADERS([netinet6/in6.h netinet/in6_var.h \
1642         netinet6/in6_var.h netinet6/nd6.h], [], [],
1643         FRR_INCLUDES)
1644
1645 m4_define([FRR_INCLUDES],dnl
1646 FRR_INCLUDES
1647 [#ifdef HAVE_NETINET6_IN6_H
1648 #include <netinet6/in6.h>
1649 #endif
1650 #ifdef HAVE_NETINET_IN6_VAR_H
1651 #include <netinet/in6_var.h>
1652 #endif
1653 #include <netinet/icmp6.h>
1654 #ifdef HAVE_NETINET6_IN6_VAR_H
1655 # include <netinet6/in6_var.h>
1656 #endif
1657 #ifdef HAVE_NETINET6_ND6_H
1658 # include <netinet6/nd6.h>
1659 #endif
1660 ])dnl
1661
1662 dnl --------------------
1663 dnl Daemon disable check
1664 dnl --------------------
1665
1666 AS_IF([test "$enable_bgpd" != "no"], [
1667   AC_DEFINE([HAVE_BGPD], [1], [bgpd])
1668 ])
1669
1670 AS_IF([test "$enable_ripd" != "no"], [
1671   AC_DEFINE([HAVE_RIPD], [1], [ripd])
1672 ])
1673
1674 AS_IF([test "$enable_ripngd" != "no"], [
1675   AC_DEFINE([HAVE_RIPNGD], [1], [ripngd])
1676 ])
1677
1678 AS_IF([test "$enable_ospfd" != "no"], [
1679   AC_DEFINE([HAVE_OSPFD], [1], [ospfd])
1680 ])
1681
1682 AS_IF([test "$enable_ospf6d" != "no"], [
1683   AC_DEFINE([HAVE_OSPF6D], [1], [ospf6d])
1684 ])
1685
1686 AS_IF([test "$enable_ldpd" != "no"], [
1687   AC_DEFINE([HAVE_LDPD], [1], [ldpd])
1688 ])
1689
1690 AS_IF([test "$enable_nhrpd" != "no"], [
1691   AC_DEFINE([HAVE_NHRPD], [1], [nhrpd])
1692 ])
1693
1694 AS_IF([test "$enable_eigrpd" != "no"], [
1695   AC_DEFINE([HAVE_EIGRPD], [1], [eigrpd])
1696 ])
1697
1698 AS_IF([test "$enable_babeld" != "no"], [
1699   AC_DEFINE([HAVE_BABELD], [1], [babeld])
1700 ])
1701
1702 AS_IF([test "$enable_isisd" != "no"], [
1703   AC_DEFINE([HAVE_ISISD], [1], [isisd])
1704 ])
1705
1706 AS_IF([test "$enable_pimd" != "no"], [
1707   AC_DEFINE([HAVE_PIMD], [1], [pimd])
1708 ])
1709
1710 AS_IF([test "$enable_pbrd" != "no"], [
1711   AC_DEFINE([HAVE_PBRD], [1], [pbrd])
1712 ])
1713
1714 AS_IF([test "$enable_sharpd" = "yes"], [
1715   AC_DEFINE([HAVE_SHARPD], [1], [sharpd])
1716 ])
1717
1718 AS_IF([test "$enable_staticd" != "no"], [
1719   AC_DEFINE([HAVE_STATICD], [1], [staticd])
1720 ])
1721
1722 AS_IF([test "$enable_fabricd" != "no"], [
1723   AC_DEFINE([HAVE_FABRICD], [1], [fabricd])
1724 ])
1725
1726 AS_IF([test "$enable_vrrpd" != "no"], [
1727   AC_DEFINE([HAVE_VRRPD], [1], [vrrpd])
1728 ])
1729
1730 if test "$enable_bfdd" = "no"; then
1731   AC_DEFINE([HAVE_BFDD], [0], [bfdd])
1732   BFDD=""
1733 else
1734   AC_DEFINE([HAVE_BFDD], [1], [bfdd])
1735   BFDD="bfdd"
1736
1737   case $host_os in
1738     linux*)
1739       AC_DEFINE([BFD_LINUX], [1], [bfdd])
1740       ;;
1741
1742     *)
1743       AC_DEFINE([BFD_BSD], [1], [bfdd])
1744       ;;
1745   esac
1746 fi
1747
1748 AS_IF([test "$enable_pathd" != "no"], [
1749   AC_DEFINE([HAVE_PATHD], [1], [pathd])
1750   AC_DEFINE([HAVE_PATHD_PCEP], [1], [pathd-pcep])
1751 ])
1752
1753
1754 if test "$ac_cv_lib_json_c_json_object_get" = "no" -a "$BFDD" = "bfdd"; then
1755   AC_MSG_ERROR(["you must use json-c library to use bfdd"])
1756 fi
1757
1758 NHRPD=""
1759 case "$host_os" in
1760   linux*)
1761     case "${enable_nhrpd}" in
1762       no)
1763         ;;
1764       yes)
1765         if test "$enable_clippy_only" != "yes"; then
1766         if test "$c_ares_found" != "true" ; then
1767           AC_MSG_ERROR([nhrpd requires libcares.  Please install c-ares and its -dev headers.])
1768         fi
1769         fi
1770         NHRPD="nhrpd"
1771         ;;
1772       *)
1773         if test "$c_ares_found" = "true" ; then
1774           NHRPD="nhrpd"
1775         fi
1776         ;;
1777     esac
1778     ;;
1779   *)
1780     if test "$enable_nhrpd" = "yes"; then
1781       AC_MSG_ERROR([nhrpd requires kernel APIs that are only present on Linux.])
1782     fi
1783     ;;
1784 esac
1785
1786 if test "$enable_watchfrr" = "no";then
1787   WATCHFRR=""
1788 else
1789   WATCHFRR="watchfrr"
1790 fi
1791
1792 OSPFCLIENT=""
1793 if test "$enable_ospfapi" != "no";then
1794     AC_DEFINE([SUPPORT_OSPF_API], [1], [OSPFAPI])
1795
1796   if test "$enable_ospfclient" != "no";then
1797       OSPFCLIENT="ospfclient"
1798   fi
1799 fi
1800
1801 if test "$enable_bgp_announce" = "no";then
1802   AC_DEFINE([DISABLE_BGP_ANNOUNCE], [1], [Disable BGP installation to zebra])
1803 else
1804   AC_DEFINE([DISABLE_BGP_ANNOUNCE], [0], [Disable BGP installation to zebra])
1805 fi
1806
1807 if test "$enable_bgp_vnc" != "no";then
1808   AC_DEFINE([ENABLE_BGP_VNC], [1], [Enable BGP VNC support])
1809 fi
1810
1811 bgpd_bmp=false
1812 case "${enable_bmp}" in
1813   no)
1814     ;;
1815   yes)
1816     if test "$c_ares_found" != "true" ; then
1817       AC_MSG_ERROR([BMP support requires libcares.  Please install c-ares and its -dev headers.])
1818     fi
1819     bgpd_bmp=true
1820     ;;
1821   *)
1822     if test "$c_ares_found" = "true" ; then
1823       bgpd_bmp=true
1824     fi
1825     ;;
1826 esac
1827
1828 if test "$enable_version_build_config" != "no";then
1829   AC_DEFINE([ENABLE_VERSION_BUILD_CONFIG], [1], [Report build configs in show version])
1830 fi
1831
1832 dnl ##########################################################################
1833 dnl LARGE if block
1834 if test "$enable_clippy_only" != "yes"; then
1835 dnl ##########################################################################
1836
1837 dnl ------------------
1838 dnl check Net-SNMP library
1839 dnl ------------------
1840 if test "$enable_snmp" != "" -a "$enable_snmp" != "no"; then
1841    AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], [no])
1842    if test "$NETSNMP_CONFIG" = "no"; then
1843       AC_MSG_ERROR([--enable-snmp given but unable to find net-snmp-config])
1844    fi
1845    SNMP_LIBS="`${NETSNMP_CONFIG} --agent-libs`"
1846    SNMP_CFLAGS="`${NETSNMP_CONFIG} --base-cflags`"
1847    # net-snmp lists all of its own dependencies.  we absolutely do not want that
1848    # among other things we avoid a GPL vs. OpenSSL license conflict here
1849    for removelib in crypto ssl sensors pci wrap; do
1850      SNMP_LIBS="`echo $SNMP_LIBS | sed -e 's/\(^\|\s\)-l'$removelib'\b/ /g' -e 's/\(^\|\s\)\([^\s]*\/\)\?lib'$removelib'\.[^\s]\+\b/ /g'`"
1851    done
1852    AC_MSG_CHECKING([whether we can link to Net-SNMP])
1853    AC_LINK_IFELSE_FLAGS([$SNMP_CFLAGS], [$SNMP_LIBS], [AC_LANG_PROGRAM([
1854 int main(void);
1855 ],
1856 [
1857 {
1858   return 0;
1859 }
1860 ])], [
1861      AC_MSG_RESULT([no])
1862      AC_MSG_ERROR([--enable-snmp given but not usable])])
1863    case "${enable_snmp}" in
1864      yes)
1865       SNMP_METHOD=agentx
1866       ;;
1867      agentx)
1868       SNMP_METHOD="${enable_snmp}"
1869       ;;
1870      *)
1871       AC_MSG_ERROR([--enable-snmp given with an unknown method (${enable_snmp}). Use yes or agentx])
1872       ;;
1873    esac
1874    AH_TEMPLATE([SNMP_AGENTX], [Use SNMP AgentX to interface with snmpd])
1875    AC_DEFINE_UNQUOTED(AS_TR_CPP(SNMP_${SNMP_METHOD}),,[SNMP method to interface with snmpd])
1876 fi
1877 AC_SUBST([SNMP_LIBS])
1878 AC_SUBST([SNMP_CFLAGS])
1879
1880 dnl ---------------
1881 dnl libyang
1882 dnl ---------------
1883 PKG_CHECK_MODULES([LIBYANG], [libyang >= 2.0.0], , [
1884   AC_MSG_ERROR([libyang (>= 2.0.0) was not found on your system.])
1885 ])
1886 ac_cflags_save="$CFLAGS"
1887 CFLAGS="$CFLAGS $LIBYANG_CFLAGS"
1888 AC_CHECK_MEMBER([struct lyd_node.priv], [], [
1889   AC_MSG_ERROR([m4_normalize([
1890     libyang needs to be compiled with ENABLE_LYD_PRIV=ON.
1891     Instructions for this are included in the build documentation for your platform at http://docs.frrouting.org/projects/dev-guide/en/latest/building.html])
1892   ])
1893 ], [[#include <libyang/libyang.h>]])
1894 CFLAGS="$ac_cflags_save"
1895
1896 dnl ---------------
1897 dnl configuration rollbacks
1898 dnl ---------------
1899 SQLITE3=false
1900 if test "$enable_config_rollbacks" = "yes"; then
1901   PKG_CHECK_MODULES([SQLITE3], [sqlite3], [
1902     AC_DEFINE([HAVE_CONFIG_ROLLBACKS], [1], [Enable configuration rollbacks])
1903     AC_DEFINE([HAVE_SQLITE3], [1], [Enable sqlite3 database])
1904     SQLITE3=true
1905   ], [
1906     AC_MSG_ERROR([--enable-config-rollbacks given but sqlite3 was not found on your system.])
1907   ])
1908 fi
1909
1910 dnl ---------------
1911 dnl confd
1912 dnl ---------------
1913 if test "$enable_confd" != "" -a "$enable_confd" != "no"; then
1914    AC_CHECK_PROG([CONFD], [confd], [confd], [/bin/false], "${enable_confd}/bin")
1915    if test "$CONFD" = "/bin/false"; then
1916       AC_MSG_ERROR([confd was not found on your system.])]
1917    fi
1918    CONFD_CFLAGS="-I${enable_confd}/include -L${enable_confd}/lib"
1919    AC_SUBST([CONFD_CFLAGS])
1920    CONFD_LIBS="-lconfd"
1921    AC_SUBST([CONFD_LIBS])
1922    AC_DEFINE([HAVE_CONFD], [1], [Enable confd integration])
1923 fi
1924
1925 dnl ---------------
1926 dnl sysrepo
1927 dnl ---------------
1928 if test "$enable_sysrepo" = "yes"; then
1929   PKG_CHECK_MODULES([SYSREPO], [sysrepo],
1930       [AC_DEFINE([HAVE_SYSREPO], [1], [Enable sysrepo integration])
1931       SYSREPO=true],
1932       [SYSREPO=false
1933       AC_MSG_ERROR([sysrepo was not found on your system.])]
1934   )
1935 fi
1936
1937 dnl ---------------
1938 dnl gRPC
1939 dnl ---------------
1940 if test "$enable_grpc" = "yes"; then
1941   AC_LANG_PUSH([C++])
1942   AX_CXX_COMPILE_STDCXX([11], [ext])
1943   PKG_CHECK_MODULES([GRPC], [grpc >= 6.0.0 grpc++ >= 1.16.1 protobuf >= 3.6.1 ], [
1944     AC_CHECK_PROGS([PROTOC], [protoc], [/bin/false])
1945     if test "$PROTOC" = "/bin/false"; then
1946       AC_MSG_FAILURE([grpc requested but protoc not found.])
1947     fi
1948
1949     AC_DEFINE([HAVE_GRPC], [1], [Enable the gRPC northbound plugin])
1950     GRPC=true
1951   ], [
1952     GRPC=false
1953     AC_MSG_ERROR([grpc/grpc++ were not found on your system.])
1954   ])
1955   AC_LANG_POP([C++])
1956 fi
1957
1958 dnl -----
1959 dnl LTTng
1960 dnl -----
1961 if test "$enable_lttng" = "yes"; then
1962   PKG_CHECK_MODULES([UST], [lttng-ust >= 2.9.0], [
1963     AC_DEFINE([HAVE_LTTNG], [1], [Enable LTTng support])
1964     LTTNG=true
1965   ], [
1966     AC_MSG_ERROR([configuration specifies --enable-lttng but lttng-ust was not found])
1967   ])
1968 fi
1969
1970 dnl ----
1971 dnl USDT
1972 dnl ----
1973 if test "$enable_usdt" = "yes"; then
1974   AC_CHECK_HEADERS([sys/sdt.h], [
1975     AC_DEFINE([HAVE_USDT], [1], [Enable USDT probes])
1976     USDT=true
1977   ], [
1978     AC_MSG_ERROR([configuration specifies --enable-usdt but no USDT kernel headers (sys/sdt.h) found])
1979   ])
1980 fi
1981
1982 dnl ------
1983 dnl ZeroMQ
1984 dnl ------
1985 if test "$enable_zeromq" != "no"; then
1986   PKG_CHECK_MODULES([ZEROMQ], [libzmq >= 4.0.0], [
1987     AC_DEFINE([HAVE_ZEROMQ], [1], [Enable ZeroMQ support])
1988     ZEROMQ=true
1989   ], [
1990     if test "$enable_zeromq" = "yes"; then
1991       AC_MSG_ERROR([configuration specifies --enable-zeromq but libzmq was not found])
1992     fi
1993   ])
1994 fi
1995
1996 dnl ------------------------------------
1997 dnl Enable RPKI and add librtr to libs
1998 dnl ------------------------------------
1999 if test "$enable_rpki" = "yes"; then
2000   PKG_CHECK_MODULES([RTRLIB], [rtrlib >= 0.5.0],
2001       [RPKI=true],
2002       [RPKI=false
2003       AC_MSG_ERROR([rtrlib was not found on your system or is too old.])]
2004   )
2005 fi
2006
2007 dnl ------------------------------------
2008 dnl pimd is not supported on OpenBSD and MacOS
2009 dnl ------------------------------------
2010 if test "$enable_pimd" != "no"; then
2011 AC_MSG_CHECKING([for pimd OS support])
2012 case "$host_os" in
2013   darwin*)
2014     AC_MSG_RESULT([no])
2015     enable_pimd="no"
2016     ;;
2017   openbsd*)
2018     AC_MSG_RESULT([no])
2019     enable_pimd="no"
2020     ;;
2021   *)
2022     AC_MSG_RESULT([yes])
2023     ;;
2024 esac
2025 fi
2026
2027 dnl -------------------------------------
2028 dnl VRRP is only supported on linux
2029 dnl -------------------------------------
2030 if test "$enable_vrrpd" != "no"; then
2031 AC_MSG_CHECKING([for VRRP OS support])
2032 case "$host_os" in
2033   linux*)
2034     AC_MSG_RESULT([yes])
2035     ;;
2036   *)
2037     AC_MSG_RESULT([no])
2038     enable_vrrpd="no"
2039     ;;
2040 esac
2041 fi
2042
2043 dnl ------------------------------------------
2044 dnl Check whether rtrlib was build with ssh support
2045 dnl ------------------------------------------
2046 AC_MSG_CHECKING([whether the RTR Library is compiled with SSH])
2047 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "rtrlib/rtrlib.h"]],
2048                         [[struct tr_ssh_config config;]])],
2049         [AC_MSG_RESULT([yes])
2050         AC_DEFINE([FOUND_SSH], [1], [found_ssh])],
2051         AC_MSG_RESULT([no])
2052 )
2053
2054 dnl ---------------
2055 dnl dlopen & dlinfo
2056 dnl ---------------
2057 LIBS_save="$LIBS"
2058 AC_SEARCH_LIBS([dlopen], [dl dld], [], [
2059   AC_MSG_ERROR([unable to find the dlopen()])
2060 ])
2061
2062 AC_CHECK_HEADERS([link.h])
2063
2064 AC_CACHE_CHECK([for dlinfo(RTLD_DI_ORIGIN)], [frr_cv_rtld_di_origin], [
2065   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2066 #include <stdlib.h>
2067 #ifdef HAVE_LINK_H
2068 #include <link.h>
2069 #endif
2070 #include <dlfcn.h>
2071 ]], [[
2072   char origin[1];
2073   dlinfo (NULL, RTLD_DI_ORIGIN, &origin);
2074 ]])], [
2075     frr_cv_rtld_di_origin=yes
2076   ], [
2077     frr_cv_rtld_di_origin=no
2078   ])
2079 ])
2080 if test "$frr_cv_rtld_di_origin" = "yes"; then
2081   AC_DEFINE([HAVE_DLINFO_ORIGIN], [1], [Have dlinfo RTLD_DI_ORIGIN])
2082 fi
2083
2084 AC_CACHE_CHECK([for dlinfo(RTLD_DI_LINKMAP)], [frr_cv_rtld_di_linkmap], [
2085   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2086 #include <stdlib.h>
2087 #ifdef HAVE_LINK_H
2088 #include <link.h>
2089 #endif
2090 #include <dlfcn.h>
2091 ]], [[
2092   struct link_map *lm = NULL;
2093   dlinfo (NULL, RTLD_DI_LINKMAP, &lm);
2094 ]])], [
2095     frr_cv_rtld_di_linkmap=yes
2096   ], [
2097     frr_cv_rtld_di_linkmap=no
2098   ])
2099 ])
2100 if test "$frr_cv_rtld_di_linkmap" = "yes"; then
2101   AC_DEFINE([HAVE_DLINFO_LINKMAP], [1], [Have dlinfo RTLD_DI_LINKMAP])
2102 fi
2103
2104 LIBDL="$LIBS"
2105 LIBDL="${LIBDL%$LIBS_save}"
2106 LIBDL="${LIBDL#$LIBS_save}"
2107 AC_SUBST([LIBDL])
2108 LIBS="$LIBS_save"
2109 unset LIBS_save
2110
2111 dnl ##########################################################################
2112 dnl test "$enable_clippy_only" != "yes"
2113 fi
2114 dnl END OF LARGE if block
2115 dnl ##########################################################################
2116
2117 dnl ---------------------------
2118 dnl sockaddr and netinet checks
2119 dnl ---------------------------
2120 AC_CHECK_TYPES([
2121         struct sockaddr_dl,
2122         struct vifctl, struct mfcctl, struct sioc_sg_req,
2123         vifi_t, struct sioc_vif_req, struct igmpmsg,
2124         struct ifaliasreq, struct if6_aliasreq, struct in6_aliasreq,
2125         struct nd_opt_adv_interval,
2126         struct nd_opt_homeagent_info, struct nd_opt_adv_interval,
2127         struct nd_opt_rdnss, struct nd_opt_dnssl],
2128         [], [], FRR_INCLUDES)
2129
2130 AC_CHECK_MEMBERS([struct sockaddr.sa_len,
2131         struct sockaddr_in.sin_len, struct sockaddr_un.sun_len,
2132         struct sockaddr_dl.sdl_len,
2133         struct if6_aliasreq.ifra_lifetime,
2134         struct nd_opt_adv_interval.nd_opt_ai_type],
2135         [], [], FRR_INCLUDES)
2136
2137 dnl ---------------------------
2138 dnl IRDP/pktinfo/icmphdr checks
2139 dnl ---------------------------
2140
2141 AC_CHECK_TYPES([struct in_pktinfo], [
2142   AC_CHECK_TYPES([struct icmphdr], [
2143     IRDP=true
2144   ], [
2145     IRDP=false
2146   ], [FRR_INCLUDES])
2147 ], [
2148   IRDP=false
2149 ], [FRR_INCLUDES])
2150
2151 case "${enable_irdp}" in
2152 yes)
2153   $IRDP || AC_MSG_ERROR(['IRDP requires in_pktinfo at the moment!'])
2154   ;;
2155 no)
2156   IRDP=false
2157   ;;
2158 esac
2159
2160
2161 dnl -----------------------
2162 dnl checking for IP_PKTINFO
2163 dnl -----------------------
2164 AC_MSG_CHECKING([for IP_PKTINFO])
2165 AC_COMPILE_IFELSE(
2166 [ AC_LANG_PROGRAM([[
2167         #include <netdb.h>
2168    ]], [[
2169         int opt = IP_PKTINFO;
2170    ]])
2171 ],[
2172   AC_MSG_RESULT([yes])
2173   AC_DEFINE([HAVE_IP_PKTINFO], [1], [Have IP_PKTINFO])
2174 ],[
2175   AC_MSG_RESULT([no])
2176 ])
2177
2178 dnl ---------------------------
2179 dnl checking for IP_RECVDSTADDR
2180 dnl ---------------------------
2181 AC_MSG_CHECKING([for IP_RECVDSTADDR])
2182 AC_COMPILE_IFELSE(
2183 [ AC_LANG_PROGRAM([[
2184         #include <netinet/in.h>
2185   ]], [[
2186         int opt = IP_RECVDSTADDR;
2187   ]])
2188 ],[
2189   AC_MSG_RESULT([yes])
2190   AC_DEFINE([HAVE_IP_RECVDSTADDR], [1], [Have IP_RECVDSTADDR])
2191 ],[
2192   AC_MSG_RESULT([no])
2193 ])
2194
2195 dnl ----------------------
2196 dnl checking for IP_RECVIF
2197 dnl ----------------------
2198 AC_MSG_CHECKING([for IP_RECVIF])
2199 AC_COMPILE_IFELSE(
2200 [ AC_LANG_PROGRAM([[
2201         #include <netinet/in.h>
2202   ]], [[
2203         int opt = IP_RECVIF;
2204   ]])
2205 ],[
2206   AC_MSG_RESULT([yes])
2207   AC_DEFINE([HAVE_IP_RECVIF], [1], [Have IP_RECVIF])
2208 ],[
2209   AC_MSG_RESULT([no])
2210 ])
2211
2212 dnl ----------------------
2213 dnl checking for SO_BINDANY
2214 dnl ----------------------
2215 AC_MSG_CHECKING([for SO_BINDANY])
2216 AC_COMPILE_IFELSE(
2217 [ AC_LANG_PROGRAM([[
2218         #include <sys/socket.h>
2219   ]], [[
2220         int opt = SO_BINDANY;
2221   ]])
2222 ],[
2223   AC_MSG_RESULT([yes])
2224   AC_DEFINE([HAVE_SO_BINDANY], [1], [Have SO_BINDANY])
2225 ],[
2226   AC_MSG_RESULT([no])
2227 ])
2228
2229 dnl ----------------------
2230 dnl checking for IP_FREEBIND
2231 dnl ----------------------
2232 AC_MSG_CHECKING([for IP_FREEBIND])
2233 AC_COMPILE_IFELSE(
2234 [ AC_LANG_PROGRAM([[
2235         #include <netinet/in.h>
2236   ]], [[
2237         int opt = IP_FREEBIND;
2238   ]])
2239 ],[
2240   AC_MSG_RESULT([yes])
2241   AC_DEFINE([HAVE_IP_FREEBIND], [1], [Have IP_FREEBIND])
2242 ],[
2243   AC_MSG_RESULT([no])
2244 ])
2245
2246 dnl --------------------------------------
2247 dnl checking for be32dec existence or not
2248 dnl --------------------------------------
2249 AC_CHECK_DECLS([be32enc, be32dec], [], [], [
2250         #ifdef HAVE_SYS_ENDIAN_H
2251         #include <sys/endian.h>
2252         #endif
2253         #ifdef HAVE_ENDIAN_H
2254         #include <endian.h>
2255         #endif
2256 ])
2257
2258 dnl --------------------------------------
2259 dnl checking for clock_time monotonic struct and call
2260 dnl --------------------------------------
2261 AC_CHECK_DECL([CLOCK_MONOTONIC],
2262         [AC_CHECK_LIB([rt], [clock_gettime], [LIBS="$LIBS -lrt"])
2263          AC_DEFINE([HAVE_CLOCK_MONOTONIC], [1], [Have monotonic clock])
2264 ], [AC_MSG_RESULT([no])], [FRR_INCLUDES])
2265
2266 AC_CHECK_DECL([CLOCK_THREAD_CPUTIME_ID], [
2267          AC_DEFINE([HAVE_CLOCK_THREAD_CPUTIME_ID], [1], [Have cpu-time clock])
2268 ], [AC_MSG_RESULT([no])], [FRR_INCLUDES])
2269
2270 AC_SEARCH_LIBS([clock_nanosleep], [rt], [
2271   AC_DEFINE([HAVE_CLOCK_NANOSLEEP], [1], [Have clock_nanosleep()])
2272 ])
2273
2274 dnl --------------------------------------
2275 dnl checking for flex and bison
2276 dnl --------------------------------------
2277
2278 dnl autoconf 2.69 AC_PROG_LEX has no parameters
2279 dnl autoconf 2.70 AC_PROG_LEX prints a deprecation warning without params
2280 m4_if(m4_version_compare(m4_defn([AC_AUTOCONF_VERSION]), [2.70]), [-1], [dnl
2281   dnl autoconf < 2.70
2282   AC_PROG_LEX
2283 ], [
2284   dnl autoconf >= 2.70
2285   AC_PROG_LEX([noyywrap])
2286 ])
2287
2288 AC_MSG_CHECKING([version of flex])
2289 frr_ac_flex_version="$(eval $LEX -V | grep flex | head -n 1)"
2290 frr_ac_flex_version="${frr_ac_flex_version##* }"
2291 AC_MSG_RESULT([$frr_ac_flex_version])
2292 AX_COMPARE_VERSION([$frr_ac_flex_version], [lt], [2.5.20], [
2293   LEX="$SHELL $missing_dir/missing flex"
2294   if test -f "${srcdir}/lib/command_lex.c" -a -f "${srcdir}/lib/command_lex.h"; then
2295     AC_MSG_WARN([using pregenerated flex output files])
2296   else
2297     AC_MSG_ERROR([flex failure and pregenerated files not included (probably a git build)])
2298   fi
2299   AC_SUBST([LEX_OUTPUT_ROOT], [lex.yy])
2300   AC_SUBST([LEXLIB], [''])
2301 ])
2302
2303 AC_PROG_YACC
2304 dnl thanks GNU bison for this b*llshit...
2305 AC_MSG_CHECKING([version of bison])
2306 frr_ac_bison_version="$(eval $YACC -V | grep bison | head -n 1)"
2307 frr_ac_bison_version="${frr_ac_bison_version##* }"
2308 frr_ac_bison_missing="false"
2309 case "x${frr_ac_bison_version}x" in
2310   x2.7*)
2311     BISON_OPENBRACE='"'
2312     BISON_CLOSEBRACE='"'
2313     BISON_VERBOSE=''
2314     AC_MSG_RESULT([$frr_ac_bison_version - 2.7 or older])
2315     ;;
2316   x2.*|x1.*)
2317     AC_MSG_RESULT([$frr_ac_bison_version])
2318     AC_MSG_WARN([installed bison is too old.  Please install GNU bison 2.7.x or newer.])
2319     frr_ac_bison_missing="true"
2320     ;;
2321   x)
2322     AC_MSG_RESULT([none])
2323     AC_MSG_WARN([could not determine bison version.  Please install GNU bison 2.7.x or newer.])
2324     frr_ac_bison_missing="true"
2325     ;;
2326   x3.[012][^0-9]*)
2327     BISON_OPENBRACE='{'
2328     BISON_CLOSEBRACE='}'
2329     BISON_VERBOSE='-Dparse.error=verbose'
2330     AC_MSG_RESULT([$frr_ac_bison_version - 3.0 to 3.2])
2331     ;;
2332   *)
2333     BISON_OPENBRACE='{'
2334     BISON_CLOSEBRACE='}'
2335     BISON_VERBOSE='-Dparse.error=verbose -Wno-yacc'
2336     AC_MSG_RESULT([$frr_ac_bison_version - 3.3 or newer])
2337     ;;
2338 esac
2339 AC_SUBST([BISON_OPENBRACE])
2340 AC_SUBST([BISON_CLOSEBRACE])
2341 AC_SUBST([BISON_VERBOSE])
2342
2343 if $frr_ac_bison_missing; then
2344   YACC="$SHELL $missing_dir/missing bison -y"
2345   if test -f "${srcdir}/lib/command_parse.c" -a -f "${srcdir}/lib/command_parse.h"; then
2346     AC_MSG_WARN([using pregenerated bison output files])
2347   else
2348     AC_MSG_ERROR([bison failure and pregenerated files not included (probably a git build)])
2349   fi
2350 fi
2351
2352 dnl -------------------
2353 dnl capabilities checks
2354 dnl -------------------
2355 if test "$enable_capabilities" != "no"; then
2356   AC_MSG_CHECKING([whether prctl PR_SET_KEEPCAPS is available])
2357   AC_COMPILE_IFELSE(
2358   [ AC_LANG_PROGRAM([[
2359         #include <sys/prctl.h>
2360     ]], [[
2361         prctl(PR_SET_KEEPCAPS, 1, 0, 0, 0);
2362     ]])
2363   ],[AC_MSG_RESULT([yes])
2364      AC_DEFINE([HAVE_PR_SET_KEEPCAPS], [1], [prctl])
2365      frr_ac_keepcaps="yes"
2366   ],[AC_MSG_RESULT(no)
2367   ])
2368   if test "$frr_ac_keepcaps" = "yes"; then
2369     AC_CHECK_HEADERS([sys/capability.h])
2370   fi
2371   if test "$ac_cv_header_sys_capability_h" = "yes"; then
2372     AC_CHECK_LIB([cap], [cap_init],
2373       [AC_DEFINE([HAVE_LCAPS], [1], [Capabilities])
2374        LIBCAP="-lcap"
2375        frr_ac_lcaps="yes"]
2376     )
2377   fi
2378   if test "$frr_ac_scaps" = "yes" \
2379        -o "$frr_ac_lcaps" = "yes"; then
2380     AC_DEFINE([HAVE_CAPABILITIES], [1], [capabilities])
2381   fi
2382
2383   case "$host_os" in
2384   linux*)
2385     if test "$enable_clippy_only" != "yes"; then
2386     if test "$frr_ac_lcaps" != "yes"; then
2387       AC_MSG_ERROR([libcap and/or its headers were not found.  Running FRR without libcap support built in causes a huge performance penalty.])
2388     fi
2389     fi
2390     ;;
2391   esac
2392 else
2393   case "$host_os" in
2394   linux*)
2395     AC_MSG_WARN([Running FRR without libcap support built in causes a huge performance penalty.])
2396     ;;
2397   esac
2398 fi
2399 AC_SUBST([LIBCAP])
2400
2401 dnl ---------------------------
2402 dnl check for glibc 'backtrace'
2403 dnl ---------------------------
2404 if test "$enable_backtrace" != "no" ; then
2405   backtrace_ok=no
2406   PKG_CHECK_MODULES([UNWIND], [libunwind], [
2407     AC_DEFINE([HAVE_LIBUNWIND], [1], [libunwind])
2408     backtrace_ok=yes
2409   ], [
2410     true
2411   ])
2412
2413   if test "$backtrace_ok" = "no"; then
2414     AC_CHECK_HEADER([unwind.h], [
2415       AC_SEARCH_LIBS([unw_getcontext], [unwind], [
2416         AC_DEFINE([HAVE_LIBUNWIND], [1], [libunwind])
2417         backtrace_ok=yes
2418       ])
2419     ])
2420   fi
2421
2422   if test "$backtrace_ok" = "no"; then
2423     AC_CHECK_HEADER([execinfo.h], [
2424       AC_SEARCH_LIBS([backtrace], [execinfo], [
2425         AC_DEFINE([HAVE_GLIBC_BACKTRACE], [1], [Glibc backtrace])
2426         backtrace_ok=yes
2427       ],, [-lm])
2428     ])
2429   fi
2430
2431   if test "$enable_backtrace" = "yes" -a "$backtrace_ok" = "no"; then
2432     dnl user explicitly requested backtrace but we failed to find support
2433     AC_MSG_FAILURE([failed to find backtrace or libunwind support])
2434   fi
2435 fi
2436
2437 dnl -----------------------------------------
2438 dnl check for malloc mallinfo struct and call
2439 dnl this must try and link using LIBS, in
2440 dnl order to check no alternative allocator
2441 dnl has been specified, which might not provide
2442 dnl mallinfo
2443 dnl -----------------------------------------
2444 AC_CHECK_HEADERS([malloc.h malloc_np.h malloc/malloc.h],,, [FRR_INCLUDES])
2445
2446 AC_CACHE_CHECK([whether mallinfo is available], [frr_cv_mallinfo], [
2447   AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2448 #ifdef HAVE_MALLOC_H
2449 #include <malloc.h>
2450 #endif
2451 #ifdef HAVE_MALLOC_NP_H
2452 #include <malloc_np.h>
2453 #endif
2454 #ifdef HAVE_MALLOC_MALLOC_H
2455 #include <malloc/malloc.h>
2456 #endif
2457 ]], [[
2458 struct mallinfo ac_x; ac_x = mallinfo ();
2459 ]])], [
2460     frr_cv_mallinfo=yes
2461   ], [
2462     frr_cv_mallinfo=no
2463   ])
2464 ])
2465 if test "$frr_cv_mallinfo" = "yes"; then
2466   AC_DEFINE([HAVE_MALLINFO], [1], [mallinfo])
2467 fi
2468
2469 AC_CACHE_CHECK([whether mallinfo2 is available], [frr_cv_mallinfo2], [
2470   AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2471 #ifdef HAVE_MALLOC_H
2472 #include <malloc.h>
2473 #endif
2474 #ifdef HAVE_MALLOC_NP_H
2475 #include <malloc_np.h>
2476 #endif
2477 #ifdef HAVE_MALLOC_MALLOC_H
2478 #include <malloc/malloc.h>
2479 #endif
2480 ]], [[
2481 struct mallinfo2 ac_x; ac_x = mallinfo2 ();
2482 ]])], [
2483     frr_cv_mallinfo2=yes
2484   ], [
2485     frr_cv_mallinfo2=no
2486   ])
2487 ])
2488 if test "$frr_cv_mallinfo2" = "yes"; then
2489   AC_DEFINE([HAVE_MALLINFO2], [1], [mallinfo2])
2490 fi
2491
2492 AC_MSG_CHECKING([whether malloc_usable_size is available])
2493 AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2494 #ifdef HAVE_MALLOC_H
2495 #include <malloc.h>
2496 #endif
2497 #ifdef HAVE_MALLOC_MALLOC_H
2498 #include <malloc/malloc.h>
2499 #endif
2500 ]], [[
2501 size_t ac_x; ac_x = malloc_usable_size(NULL);
2502 ]])], [
2503   AC_MSG_RESULT([yes])
2504   AC_DEFINE([HAVE_MALLOC_USABLE_SIZE], [1], [malloc_usable_size])
2505 ], [
2506   AC_MSG_RESULT([no])
2507
2508   AC_MSG_CHECKING([whether malloc_size is available])
2509   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2510 #ifdef HAVE_MALLOC_H
2511 #include <malloc.h>
2512 #endif
2513 #ifdef HAVE_MALLOC_MALLOC_H
2514 #include <malloc/malloc.h>
2515 #endif
2516 ]], [[
2517 size_t ac_x; ac_x = malloc_size(NULL);
2518 ]])], [
2519     AC_MSG_RESULT([yes])
2520     AC_DEFINE([HAVE_MALLOC_SIZE], [1], [malloc_size])
2521   ], [
2522     AC_MSG_RESULT([no])
2523   ])
2524 ])
2525
2526 dnl ----------
2527 dnl configure date
2528 dnl ----------
2529 dev_version=`echo $VERSION | grep dev`
2530 #don't expire deprecated code in non 'dev' branch
2531 if test "$dev_version" = ""; then
2532    CONFDATE=0
2533 else
2534    CONFDATE=`date '+%Y%m%d'`
2535 fi
2536 AC_SUBST([CONFDATE])
2537
2538 dnl ------------------------------
2539 dnl set paths for state directory
2540 dnl ------------------------------
2541 AC_MSG_CHECKING([directory to use for state file])
2542 if test "$prefix" = "NONE"; then
2543   frr_statedir_prefix="";
2544 else
2545   frr_statedir_prefix=${prefix}
2546 fi
2547 if test "$localstatedir" = '${prefix}/var'; then
2548   for FRR_STATE_DIR in ${frr_statedir_prefix}/var/run dnl
2549                         ${frr_statedir_prefix}/var/adm dnl
2550                         ${frr_statedir_prefix}/etc dnl
2551                         /var/run        dnl
2552                         /var/adm        dnl
2553                         /etc            dnl
2554                         /dev/null;
2555   do
2556     test -d $FRR_STATE_DIR && break
2557   done
2558   frr_statedir=$FRR_STATE_DIR
2559 else
2560   frr_statedir=${localstatedir}
2561 fi
2562 if test "$frr_statedir" = "/dev/null"; then
2563     AC_MSG_ERROR([STATE DIRECTORY NOT FOUND! FIX OR SPECIFY --localstatedir!])
2564 fi
2565 AC_MSG_RESULT([${frr_statedir}])
2566 AC_SUBST([frr_statedir])
2567
2568 AC_DEFINE_UNQUOTED([LDPD_SOCKET], ["$frr_statedir%s%s/ldpd.sock"], [ldpd control socket])
2569 AC_DEFINE_UNQUOTED([ZEBRA_SERV_PATH], ["$frr_statedir%s%s/zserv.api"], [zebra api socket])
2570 AC_DEFINE_UNQUOTED([BFDD_CONTROL_SOCKET], ["$frr_statedir%s%s/bfdd.sock"], [bfdd control socket])
2571 AC_DEFINE_UNQUOTED([OSPFD_GR_STATE], ["$frr_statedir%s/ospfd-gr.json"], [ospfd GR state information])
2572 AC_DEFINE_UNQUOTED([OSPF6D_GR_STATE], ["$frr_statedir/ospf6d-gr.json"], [ospf6d GR state information])
2573 AC_DEFINE_UNQUOTED([DAEMON_VTY_DIR], ["$frr_statedir%s%s"], [daemon vty directory])
2574 AC_DEFINE_UNQUOTED([DAEMON_DB_DIR], ["$frr_statedir"], [daemon database directory])
2575
2576 dnl autoconf does this, but it does it too late...
2577 test "$prefix" = "NONE" && prefix=$ac_default_prefix
2578 test "$exec_prefix" = "NONE" && exec_prefix='${prefix}'
2579
2580 dnl get the full path, recursing through variables...
2581 vtysh_bin="$bindir/vtysh"
2582 for I in 1 2 3 4 5 6 7 8 9 10; do
2583         eval vtysh_bin="\"$vtysh_bin\""
2584 done
2585 AC_DEFINE_UNQUOTED([VTYSH_BIN_PATH], ["$vtysh_bin"], [path to vtysh binary])
2586 AC_SUBST([vtysh_bin])
2587
2588 CFG_SYSCONF="$sysconfdir"
2589 CFG_SBIN="$sbindir"
2590 CFG_STATE="$frr_statedir"
2591 CFG_MODULE="$moduledir"
2592 CFG_YANGMODELS="$yangmodelsdir"
2593 CFG_SCRIPT="$scriptdir"
2594 for I in 1 2 3 4 5 6 7 8 9 10; do
2595         eval CFG_SYSCONF="\"$CFG_SYSCONF\""
2596         eval CFG_SBIN="\"$CFG_SBIN\""
2597         eval CFG_STATE="\"$CFG_STATE\""
2598         eval CFG_MODULE="\"$CFG_MODULE\""
2599         eval CFG_YANGMODELS="\"$CFG_YANGMODELS\""
2600         eval CFG_SCRIPT="\"$CFG_SCRIPT\""
2601 done
2602 AC_SUBST([CFG_SYSCONF])
2603 AC_SUBST([CFG_SBIN])
2604 AC_SUBST([CFG_STATE])
2605 AC_SUBST([CFG_MODULE])
2606 AC_SUBST([CFG_SCRIPT])
2607 AC_SUBST([CFG_YANGMODELS])
2608 AC_DEFINE_UNQUOTED([MODULE_PATH], ["$CFG_MODULE"], [path to modules])
2609 AC_DEFINE_UNQUOTED([SCRIPT_PATH], ["$CFG_SCRIPT"], [path to scripts])
2610 AC_DEFINE_UNQUOTED([YANG_MODELS_PATH], ["$CFG_YANGMODELS"], [path to YANG data models])
2611 AC_DEFINE_UNQUOTED([WATCHFRR_SH_PATH], ["${CFG_SBIN%/}/watchfrr.sh"], [path to watchfrr.sh])
2612
2613 dnl various features
2614 AM_CONDITIONAL([SUPPORT_REALMS], [test "$enable_realms" = "yes"])
2615 AM_CONDITIONAL([ENABLE_BGP_VNC], [test "$enable_bgp_vnc" != "no"])
2616 AM_CONDITIONAL([BGP_BMP], [$bgpd_bmp])
2617 dnl northbound
2618 AM_CONDITIONAL([SQLITE3], [$SQLITE3])
2619 AM_CONDITIONAL([CONFD], [test "$enable_confd" != ""])
2620 AM_CONDITIONAL([SYSREPO], [test "$enable_sysrepo" = "yes"])
2621 AM_CONDITIONAL([GRPC], [test "$enable_grpc" = "yes"])
2622 AM_CONDITIONAL([ZEROMQ], [test "$ZEROMQ" = "true"])
2623 dnl plugins
2624 AM_CONDITIONAL([RPKI], [test "$RPKI" = "true"])
2625 AM_CONDITIONAL([SNMP], [test "$SNMP_METHOD" = "agentx"])
2626 AM_CONDITIONAL([IRDP], [$IRDP])
2627 AM_CONDITIONAL([FPM], [test "$enable_fpm" = "yes"])
2628 AM_CONDITIONAL([HAVE_PROTOBUF], [test "$enable_protobuf" = "yes"])
2629 AM_CONDITIONAL([HAVE_PROTOBUF3], [$PROTO3])
2630
2631 dnl PCEP plugin
2632 AS_IF([test "$enable_pathd" != "no"], [
2633        AC_SUBST([PATHD_PCEP_LIBS], ["pceplib/libpcep_pcc.la"])
2634        AC_SUBST([PATHD_PCEP_INCL], ["-I./pceplib "])
2635        ])
2636 AC_CHECK_LIB([cunit], [CU_initialize_registry], [pcep_cunit=yes],[pcep_cunit=no])
2637 AM_CONDITIONAL([PATHD_PCEP_TEST], [test "x${pcep_cunit}" = xyes])
2638 AC_CHECK_PROG(VALGRIND_CHECK, valgrind, yes)
2639 AM_CONDITIONAL([HAVE_VALGRIND_PCEP], [test "$VALGRIND_CHECK" = "yes"])
2640
2641 dnl daemons
2642 AM_CONDITIONAL([VTYSH], [test "$VTYSH" = "vtysh"])
2643 AM_CONDITIONAL([ZEBRA], [test "$enable_zebra" != "no"])
2644 AM_CONDITIONAL([BGPD], [test "$enable_bgpd" != "no"])
2645 AM_CONDITIONAL([RIPD], [test "$enable_ripd" != "no"])
2646 AM_CONDITIONAL([OSPFD], [test "$enable_ospfd" != "no"])
2647 AM_CONDITIONAL([LDPD], [test "$enable_ldpd" != "no"])
2648 AM_CONDITIONAL([BFDD], [test "$BFDD" = "bfdd"])
2649 AM_CONDITIONAL([NHRPD], [test "$NHRPD" = "nhrpd"])
2650 AM_CONDITIONAL([EIGRPD], [test "$enable_eigrpd" != "no"])
2651 AM_CONDITIONAL([WATCHFRR], [test "$WATCHFRR" = "watchfrr"])
2652 AM_CONDITIONAL([OSPFCLIENT], [test "$OSPFCLIENT" = "ospfclient"])
2653 AM_CONDITIONAL([RIPNGD], [test "$enable_ripngd" != "no"])
2654 AM_CONDITIONAL([BABELD], [test "$enable_babeld" != "no"])
2655 AM_CONDITIONAL([OSPF6D], [test "$enable_ospf6d" != "no"])
2656 AM_CONDITIONAL([ISISD], [test "$enable_isisd" != "no"])
2657 AM_CONDITIONAL([PIMD], [test "$enable_pimd" != "no"])
2658 AM_CONDITIONAL([PBRD], [test "$enable_pbrd" != "no"])
2659 AM_CONDITIONAL([SHARPD], [test "$enable_sharpd" = "yes"])
2660 AM_CONDITIONAL([STATICD], [test "$enable_staticd" != "no"])
2661 AM_CONDITIONAL([FABRICD], [test "$enable_fabricd" != "no"])
2662 AM_CONDITIONAL([VRRPD], [test "$enable_vrrpd" != "no"])
2663 AM_CONDITIONAL([PATHD], [test "$enable_pathd" != "no"])
2664 AM_CONDITIONAL([PATHD_PCEP], [test "$enable_pathd" != "no"])
2665
2666 AC_CONFIG_FILES([Makefile],[
2667         test "$enable_dev_build" = "yes" && makefile_devbuild="--dev-build"
2668         ${PYTHON} "${ac_abs_top_srcdir}/python/makefile.py" ${makefile_devbuild} || exit 1
2669 ], [
2670         PYTHON="$PYTHON"
2671         enable_dev_build="$enable_dev_build"
2672 ])
2673
2674 AC_CONFIG_FILES([
2675           config.version
2676           redhat/frr.spec
2677           alpine/APKBUILD
2678           snapcraft/snapcraft.yaml
2679           lib/version.h
2680           tests/lib/cli/test_cli.refout
2681           pkgsrc/bgpd.sh pkgsrc/ospf6d.sh pkgsrc/ospfd.sh
2682           pkgsrc/ripd.sh pkgsrc/ripngd.sh pkgsrc/zebra.sh
2683           pkgsrc/eigrpd.sh])
2684
2685 AC_CONFIG_FILES([vtysh/extract.pl], [chmod +x vtysh/extract.pl])
2686 AC_CONFIG_FILES([tools/frr], [chmod +x tools/frr])
2687 AC_CONFIG_FILES([tools/watchfrr.sh], [chmod +x tools/watchfrr.sh])
2688 AC_CONFIG_FILES([tools/frrinit.sh], [chmod +x tools/frrinit.sh])
2689 AC_CONFIG_FILES([tools/frrcommon.sh])
2690 AC_CONFIG_FILES([tools/frr.service])
2691 AC_CONFIG_FILES([tools/frr@.service])
2692
2693 AS_IF([test "$with_pkg_git_version" = "yes"], [
2694     AC_CONFIG_COMMANDS([lib/gitversion.h], [
2695         dst="${ac_abs_top_builddir}/lib/gitversion.h"
2696         ${PERL} "${ac_abs_top_srcdir}/lib/gitversion.pl" \
2697                 "${ac_abs_top_srcdir}" \
2698                 > "${dst}.tmp"
2699         test -f "$dst" \
2700                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
2701                 && rm "${dst}.tmp" \
2702                 || mv "${dst}.tmp" "${dst}"
2703     ], [
2704         PERL="$PERL"
2705     ])
2706 ])
2707
2708 ## Hack, but working solution to avoid rebuilding of frr.info.
2709 ## It's already in CVS until texinfo 4.7 is more common.
2710 AC_OUTPUT
2711
2712 if test "$enable_rpath" = "yes" ; then
2713         true
2714 else
2715         # See https://old-en.opensuse.org/openSUSE:Packaging_Guidelines#Removing_Rpath
2716         sed -e 's|^hardcode_libdir_flag_spec=.*|hardcode_libdir_flag_spec=""|g' libtool > libtool.sed && cat libtool.sed > libtool
2717         sed -e 's|^runpath_var=LD_RUN_PATH|runpath_var=DIE_RPATH_DIE|g'         libtool > libtool.sed && cat libtool.sed > libtool
2718         test -f libtool.sed && rm libtool.sed
2719 fi
2720
2721 echo "
2722 FRRouting configuration
2723 ------------------------------
2724 FRR version             : ${PACKAGE_VERSION}
2725 host operating system   : ${host_os}
2726 source code location    : ${srcdir}
2727 compiler                : ${CC}
2728 compiler flags          : ${CFLAGS} ${WERROR} ${AC_CFLAGS} ${SAN_FLAGS}
2729 make                    : ${MAKE-make}
2730 linker flags            : ${LDFLAGS} ${SAN_FLAGS} ${LIBS} ${LIBCAP} ${LIBREADLINE} ${LIBM}
2731 state file directory    : ${frr_statedir}
2732 config file directory   : `eval echo \`echo ${sysconfdir}\``
2733 module directory        : ${CFG_MODULE}
2734 script directory        : ${CFG_SCRIPT}
2735 user to run as          : ${enable_user}
2736 group to run as         : ${enable_group}
2737 group for vty sockets   : ${enable_vty_group}
2738 config file mask        : ${enable_configfile_mask}
2739 log file mask           : ${enable_logfile_mask}
2740 zebra protobuf enabled  : ${enable_protobuf:-no}
2741 vici socket path        : ${vici_socket}
2742
2743 The above user and group must have read/write access to the state file
2744 directory and to the config files in the config file directory."
2745
2746 if test -n "$enable_datacenter"; then
2747   AC_MSG_WARN([The --enable-datacenter compile time option is deprecated.  Please modify the init script to pass -F datacenter to the daemons instead.])
2748 fi
2749 if test -n "$enable_time_check"; then
2750   AC_MSG_WARN([The --enable-time-check compile time option is deprecated.  Please use the service cputime-stats configuration option instead.])
2751 fi
2752 if test -n "$enable_cpu_time"; then
2753   AC_MSG_WARN([The --enable-cpu-time compile time option is deprecated.  Please use the service cputime-warning NNN configuration option instead.])
2754 fi
2755
2756 if test "$enable_doc" != "no" -a "$frr_py_mod_sphinx" = "false"; then
2757   AC_MSG_WARN([sphinx is missing but required to build documentation])
2758 fi
2759 if test "$frr_py_mod_pytest" = "false"; then
2760   AC_MSG_WARN([pytest is missing, unit tests cannot be performed])
2761 fi