configure.ac

   1 ##
   2 ## Configure template file for FRRouting.
   3 ## autoconf will generate a configure script.
   4 ##
   5 ##  Copyright (c) 1996, 97, 98, 99, 2000 Kunihiro Ishiguro <kunihiro@zebra.org>
   6 ##  Portions Copyright (c) 2003 Paul Jakma <paul@dishone.st>
   7 ##
   8 AC_PREREQ([2.60])
   9
  10 AC_INIT([frr], [7.7-dev], [https://github.com/frrouting/frr/issues])
  11 PACKAGE_URL="https://frrouting.org/"
  12 AC_SUBST([PACKAGE_URL])
  13 PACKAGE_FULLNAME="FRRouting"
  14 AC_SUBST([PACKAGE_FULLNAME])
  15
  16 CONFIG_ARGS="`echo $ac_configure_args | sed -e \"s% '[[A-Z]]*FLAGS=[[^']]\+'%%g\"`"
  17 AC_SUBST([CONFIG_ARGS])
  18
  19 AC_CONFIG_SRCDIR([lib/zebra.h])
  20 AC_CONFIG_MACRO_DIR([m4])
  21
  22 dnl -----------------------------------
  23 dnl Get hostname and other information.
  24 dnl -----------------------------------
  25 AC_CANONICAL_BUILD()
  26 AC_CANONICAL_HOST()
  27
  28 AC_ARG_VAR([AR],[archiver command])
  29 AC_ARG_VAR([LD],[linker command])
  30 AC_ARG_VAR([OBJCOPY],[objcopy command])
  31 AC_ARG_VAR([OBJDUMP],[objdump command])
  32 AC_ARG_VAR([RANLIB],[ranlib command])
  33 AC_ARG_VAR([STRIP],[strip command])
  34
  35 hosttools_clippy="false"
  36 build_clippy="true"
  37
  38 dnl case 1: external clippy
  39 if test -n "$with_clippy" -a "$with_clippy" != "no" -a "$with_clippy" != "yes"; then
  40   if test "$enable_clippy_only" = "yes"; then
  41     AC_MSG_ERROR([--enable-clippy-only does not make sense with --with-clippy])
  42   fi
  43
  44   CLIPPY="$with_clippy"
  45   build_clippy="false"
  46   if test ! -x "$with_clippy"; then
  47     AC_MSG_ERROR([clippy tool ($with_clippy) is not executable])
  48   fi
  49
  50 dnl case 2: cross-compiling internal clippy
  51 elif test "$host" != "$build"; then
  52   if test "$srcdir" = "."; then
  53     AC_MSG_ERROR([cross-compilation is only possible with builddir separate from srcdir or by building clippy separately and using the --with-clippy option.  create a separate directory and run as .../path-to-frr/configure.])
  54   fi
  55   test -d hosttools || mkdir hosttools
  56   abssrc="`cd \"${srcdir}\"; pwd`"
  57
  58   AC_MSG_NOTICE([...])
  59   AC_MSG_NOTICE([... cross-compilation: creating hosttools directory and self-configuring for build platform tools])
  60   AC_MSG_NOTICE([... use HOST_CPPFLAGS / HOST_CFLAGS / HOST_LDFLAGS if neccessary])
  61   AC_MSG_NOTICE([...])
  62
  63   (
  64     for var in $ac_precious_vars; do
  65       dnl special cases
  66       case "$var" in
  67       YACC|YFLAGS) continue;;
  68       PYTHON*)     retain=true;;
  69       *)           retain=false;
  70       esac
  71
  72       eval "hostvar=\"\${HOST_$var}\""
  73       eval "targetvar=\"\${$var}\""
  74       if test -n "$hostvar"; then
  75         eval "$var='$hostvar'"
  76         _AS_ECHO_LOG([host $var='$hostvar'])
  77       elif $retain; then
  78         _AS_ECHO_LOG([host retain $var='$targetvar'])
  79       else
  80         eval "unset $var"
  81         _AS_ECHO_LOG([host unset $var])
  82       fi
  83     done
  84     cd hosttools
  85     "${abssrc}/configure" "--host=$build" "--build=$build" "--enable-clippy-only" "--disable-nhrpd" "--disable-vtysh"
  86   ) || exit 1
  87
  88   AC_MSG_NOTICE([...])
  89   AC_MSG_NOTICE([... cross-compilation: finished self-configuring for build platform tools])
  90   AC_MSG_NOTICE([...])
  91
  92   build_clippy="false"
  93   hosttools_clippy="true"
  94   CLIPPY="hosttools/lib/clippy"
  95
  96 dnl case 3: normal build internal clippy
  97 else
  98   CLIPPY="lib/clippy\$(EXEEXT)"
  99 fi
 100 AC_SUBST([CLIPPY])
 101 AM_CONDITIONAL([BUILD_CLIPPY], [$build_clippy])
 102 AM_CONDITIONAL([HOSTTOOLS_CLIPPY], [$hosttools_clippy])
 103 AM_CONDITIONAL([ONLY_CLIPPY], [test "$enable_clippy_only" = "yes"])
 104
 105 # Disable portability warnings -- our automake code (in particular
 106 # common.am) uses some constructs specific to gmake.
 107 AM_INIT_AUTOMAKE([1.12 -Wno-portability foreign])
 108 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
 109 AM_SILENT_RULES([yes])
 110 AC_CONFIG_HEADERS([config.h])
 111
 112 AC_PATH_PROG([PERL], [perl])
 113 PKG_PROG_PKG_CONFIG
 114
 115 dnl default is to match previous behavior
 116 exampledir=${sysconfdir}
 117 AC_ARG_ENABLE([exampledir],
 118           AS_HELP_STRING([--enable-exampledir],
 119                          [specify alternate directory for examples]),
 120                          exampledir="$enableval",)
 121 dnl XXX add --exampledir to autoconf standard directory list somehow
 122 AC_SUBST([exampledir])
 123
 124 dnl default is to match previous behavior
 125 pkgsrcrcdir=""
 126 AC_ARG_ENABLE([pkgsrcrcdir],
 127           AS_HELP_STRING([--enable-pkgsrcrcdir],
 128                          [specify directory for rc.d scripts]),
 129                          pkgsrcrcdir="$enableval",)
 130 dnl XXX add --pkgsrcrcdir to autoconf standard directory list somehow
 131 AC_SUBST([pkgsrcrcdir])
 132 AM_CONDITIONAL([PKGSRC], [test "$pkgsrcrcdir" != ""])
 133
 134 AC_ARG_WITH([moduledir], [AS_HELP_STRING([--with-moduledir=DIR], [module directory (${libdir}/frr/modules)])], [
 135         moduledir="$withval"
 136 ], [
 137         moduledir="\${libdir}/frr/modules"
 138 ])
 139 AC_SUBST([moduledir], [$moduledir])
 140
 141 AC_ARG_WITH([scriptdir], [AS_HELP_STRING([--with-scriptdir=DIR], [script directory (${sysconfdir}/scripts)])], [
 142         scriptdir="$withval"
 143 ], [
 144         scriptdir="\${sysconfdir}/scripts"
 145 ])
 146 AC_SUBST([scriptdir], [$scriptdir])
 147
 148 AC_ARG_WITH([yangmodelsdir], [AS_HELP_STRING([--with-yangmodelsdir=DIR], [yang models directory (${datarootdir}/yang)])], [
 149         yangmodelsdir="$withval"
 150 ], [
 151         yangmodelsdir="\${datarootdir}/yang"
 152 ])
 153 AC_SUBST([yangmodelsdir])
 154
 155 AC_ARG_WITH([vici-socket], [AS_HELP_STRING([--with-vici-socket=PATH], [vici-socket (/var/run/charon.vici)])], [
 156         vici_socket="$withval"
 157 ], [
 158         vici_socket="/var/run/charon.vici"
 159 ])
 160 AC_DEFINE_UNQUOTED([VICI_SOCKET], ["$vici_socket"], [StrongSWAN vici socket path])
 161
 162 AC_ARG_ENABLE(tcmalloc,
 163         AS_HELP_STRING([--enable-tcmalloc], [Turn on tcmalloc]),
 164 [case "${enableval}" in
 165   yes) tcmalloc_enabled=true
 166 LIBS="$LIBS -ltcmalloc_minimal"
 167  ;;
 168   no)  tcmalloc_enabled=false ;;
 169   *) AC_MSG_ERROR([bad value ${enableval} for --enable-tcmalloc]) ;;
 170 esac],[tcmalloc_enabled=false])
 171
 172
 173 dnl Thanks autoconf, but we don't want a default -g -O2.  We have our own
 174 dnl flag determination logic.
 175 CFLAGS="${CFLAGS:-}"
 176
 177 dnl --------------------
 178 dnl Check CC and friends
 179 dnl --------------------
 180 dnl note orig_cflags is also used further down
 181 orig_cflags="$CFLAGS"
 182 orig_cxxflags="$CXXFLAGS"
 183 AC_LANG([C])
 184 AC_PROG_CC
 185 AC_PROG_CPP
 186 AC_PROG_CXX
 187 AM_PROG_CC_C_O
 188 dnl remove autoconf default "-g -O2"
 189 CFLAGS="$orig_cflags"
 190 CXXFLAGS="$orig_cxxflags"
 191 AC_PROG_CC_C99
 192 dnl NB: see C11 below
 193
 194 dnl Some special handling for ICC later on
 195 if test "$CC" = "icc"; then
 196     cc_is_icc="yes"
 197 fi
 198
 199 PKG_PROG_PKG_CONFIG
 200
 201 dnl it's 2019, sed is sed.
 202 SED=sed
 203 AC_SUBST([SED])
 204
 205 dnl try and enable CFLAGS that are useful for FRR
 206 dnl - specifically, options to control warnings
 207
 208 AC_USE_SYSTEM_EXTENSIONS
 209 AC_DEFUN([AC_C_FLAG], [{
 210     m4_pushdef([cachename],[m4_translit([frr_cv_$1],[ =-+/{}$],[________])])
 211     AC_CACHE_CHECK([[whether $CC supports $1]], cachename, [
 212         AC_LANG_PUSH([C])
 213         ac_c_flag_save="$CFLAGS"
 214         CFLAGS="$CFLAGS $1"
 215         AC_COMPILE_IFELSE(
 216                 [AC_LANG_PROGRAM([[$4]])],
 217                 [
 218                         cachename=yes
 219                 ], [
 220                         cachename=no
 221                 ])
 222         CFLAGS="$ac_c_flag_save"
 223         AC_LANG_POP([C])
 224     ])
 225     if test "$cachename" = "yes"; then
 226         m4_if([$3], [], [CFLAGS="$CFLAGS $1"], [$3])
 227     else
 228         :
 229         $2
 230     fi
 231     m4_popdef([cachename])
 232 }])
 233
 234 AC_DEFUN([AC_LINK_IFELSE_FLAGS], [{
 235         AC_LANG_PUSH([C])
 236         ac_cflags_save="$CFLAGS"
 237         ac_libs_save="$LIBS"
 238         CFLAGS="$CFLAGS $1"
 239         LIBS="$LIBS $2"
 240         AC_LINK_IFELSE(
 241                 [$3],
 242                 [
 243                         CFLAGS="$ac_cflags_save"
 244                         LIBS="$ac_libs_save"
 245                         m4_default([$5], [
 246                                 AC_MSG_RESULT([yes])
 247                         ])
 248                 ], [
 249                         CFLAGS="$ac_cflags_save"
 250                         LIBS="$ac_libs_save"
 251                         m4_default([$4], [
 252                                 AC_MSG_RESULT([no])
 253                         ])
 254                 ])
 255         AC_LANG_POP([C])
 256         }])
 257
 258 dnl ICC won't bail on unknown options without -diag-error 10006
 259 dnl need to do this first so we get useful results for the other options
 260 if test "$cc_is_icc" = "yes"; then
 261     AC_C_FLAG([-diag-error 10006])
 262 fi
 263
 264 dnl AC_PROG_CC_C99 may change CC to include -std=gnu99 or something
 265 ac_cc="$CC"
 266 CC="${CC% -std=gnu99}"
 267 CC="${CC% -std=c99}"
 268
 269 AC_C_FLAG([-std=gnu11], [CC="$ac_cc"], [CC="$CC -std=gnu11"])
 270
 271 dnl if the user has specified any CFLAGS, override our settings
 272 if test "$enable_gcov" = "yes"; then
 273    if test "$orig_cflags" = ""; then
 274       AC_C_FLAG([-coverage])
 275       AC_C_FLAG([-O0])
 276    fi
 277
 278    LDFLAGS="${LDFLAGS} -lgcov"
 279 fi
 280
 281 if test "$enable_clang_coverage" = "yes"; then
 282    AC_C_FLAG([-fprofile-instr-generate], [
 283      AC_MSG_ERROR([$CC does not support -fprofile-instr-generate.])
 284    ])
 285    AC_C_FLAG([-fcoverage-mapping], [
 286      AC_MSG_ERROR([$CC does not support -fcoverage-mapping.])
 287    ])
 288 fi
 289
 290 if test "$enable_scripting" = "yes"; then
 291    AX_PROG_LUA([5.3])
 292    AX_LUA_HEADERS
 293    AX_LUA_LIBS([
 294       AC_DEFINE([HAVE_SCRIPTING], [1], [Have support for scripting])
 295       LIBS="$LIBS $LUA_LIB"
 296    ])
 297 fi
 298
 299 if test "$enable_dev_build" = "yes"; then
 300    AC_DEFINE([DEV_BUILD], [1], [Build for development])
 301    if test "$orig_cflags" = ""; then
 302       AC_C_FLAG([-g3])
 303       AC_C_FLAG([-O0])
 304       AC_C_FLAG([-ggdb3])
 305    fi
 306 else
 307    if test "$orig_cflags" = ""; then
 308       AC_C_FLAG([-g])
 309       AC_C_FLAG([-O2])
 310    fi
 311 fi
 312
 313 AM_CONDITIONAL([DEV_BUILD], [test "$enable_dev_build" = "yes"])
 314
 315 dnl always want these CFLAGS
 316 AC_C_FLAG([-fno-omit-frame-pointer])
 317 AC_C_FLAG([-funwind-tables])
 318 AC_C_FLAG([-Wall])
 319 AC_C_FLAG([-Wextra])
 320 AC_C_FLAG([-Wmissing-prototypes])
 321 AC_C_FLAG([-Wmissing-declarations])
 322 AC_C_FLAG([-Wpointer-arith])
 323 AC_C_FLAG([-Wbad-function-cast])
 324 AC_C_FLAG([-Wwrite-strings])
 325 AC_C_FLAG([-Wundef])
 326 if test "$enable_gcc_ultra_verbose" = "yes" ; then
 327   AC_C_FLAG([-Wcast-qual])
 328   AC_C_FLAG([-Wstrict-prototypes])
 329   AC_C_FLAG([-Wmissing-noreturn])
 330   AC_C_FLAG([-Wmissing-format-attribute])
 331   AC_C_FLAG([-Wunreachable-code])
 332   AC_C_FLAG([-Wpacked])
 333   AC_C_FLAG([-Wpadded])
 334   AC_C_FLAG([-Wshadow])
 335 else
 336   AC_C_FLAG([-Wno-unused-result])
 337 fi
 338 AC_C_FLAG([-Wno-unused-parameter])
 339 AC_C_FLAG([-Wno-missing-field-initializers])
 340
 341 AC_C_FLAG([-Wc++-compat], [], [CXX_COMPAT_CFLAGS="-Wc++-compat"])
 342 AC_SUBST([CXX_COMPAT_CFLAGS])
 343
 344 dnl ICC emits a broken warning for const char *x = a ? "b" : "c";
 345 dnl for some reason the string consts get 'promoted' to char *,
 346 dnl triggering a const to non-const conversion warning.
 347 if test "$cc_is_icc" = "yes"; then
 348     AC_C_FLAG([-diag-disable 3179])
 349 fi
 350
 351 if test "$enable_werror" = "yes" ; then
 352   WERROR="-Werror"
 353 fi
 354 AC_SUBST([WERROR])
 355
 356 SAN_FLAGS=""
 357 if test "$enable_address_sanitizer" = "yes"; then
 358   AC_C_FLAG([-fsanitize=address], [
 359     AC_MSG_ERROR([$CC does not support Address Sanitizer.])
 360   ], [
 361     SAN_FLAGS="$SAN_FLAGS -fsanitize=address"
 362   ])
 363 fi
 364 if test "$enable_thread_sanitizer" = "yes"; then
 365   AC_C_FLAG([-fsanitize=thread], [
 366     AC_MSG_ERROR([$CC does not support Thread Sanitizer.])
 367   ], [
 368     SAN_FLAGS="$SAN_FLAGS -fsanitize=thread"
 369   ])
 370 fi
 371 if test "$enable_memory_sanitizer" = "yes"; then
 372   AC_C_FLAG([-fsanitize=memory -fPIE -pie], [
 373     AC_MSG_ERROR([$CC does not support Memory Sanitizer.])
 374   ], [
 375     SAN_FLAGS="$SAN_FLAGS -fsanitize=memory -fPIE -pie"
 376   ])
 377 fi
 378 if test "$enable_undefined_sanitizer" = "yes"; then
 379   AC_C_FLAG([-fsanitize=undefined], [
 380     AC_MSG_ERROR([$CC does not support UndefinedBehaviorSanitizer.])
 381   ], [
 382     SAN_FLAGS="$SAN_FLAGS -fsanitize=undefined"
 383   ])
 384 fi
 385 AC_SUBST([SAN_FLAGS])
 386
 387 dnl frr-format.so
 388 if test "$with_frr_format" != "no" -a "$with_frr_format" != "yes" -a -n "$with_frr_format"; then
 389   AC_C_FLAG([-fplugin=${with_frr_format}], [
 390     AC_MSG_ERROR([specified frr-format plugin ($with_frr_format) does not work])
 391   ],,[
 392 #ifndef _FRR_ATTRIBUTE_PRINTFRR
 393 #error plugin not loaded
 394 #endif
 395 #if _FRR_ATTRIBUTE_PRINTFRR < 0x10000
 396 #error plugin too old
 397 #endif
 398   ])
 399 elif test "$with_frr_format" = "no"; then
 400   : #nothing
 401 else
 402   AC_C_FLAG([-fplugin=tools/gcc-plugins/frr-format.so],[
 403     AC_C_FLAG([-fplugin=frr-format],[
 404       if test "$with_frr_format" = "yes"; then
 405         AC_MSG_ERROR([frr-format plugin requested but not found])
 406       fi
 407     ],,[
 408 #ifndef _FRR_ATTRIBUTE_PRINTFRR
 409 #error plugin not loaded
 410 #endif
 411 #if _FRR_ATTRIBUTE_PRINTFRR < 0x10000
 412 #error plugin too old
 413 #endif
 414     ])
 415   ],,[
 416 #ifndef _FRR_ATTRIBUTE_PRINTFRR
 417 #error plugin not loaded
 418 #endif
 419 #if _FRR_ATTRIBUTE_PRINTFRR < 0x10000
 420 #error plugin too old
 421 #endif
 422   ])
 423 fi
 424
 425 AC_MSG_CHECKING([whether linker supports __start/stop_section symbols])
 426 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 427 #include <stdio.h>
 428 int __attribute__((section("secttest"))) var = 1;
 429 extern int __start_secttest, __stop_secttest;
 430 ]], [[
 431   void *a = &var, *b = &__start_secttest, *c = &__stop_secttest;
 432   printf("%p %p %p\n", a, b, c);
 433 ]])], [
 434   AC_MSG_RESULT(yes)
 435   AC_DEFINE(HAVE_SECTION_SYMS, 1, [have __start/stop_section symbols])
 436 ], [
 437   AC_MSG_RESULT(no)
 438 ])
 439
 440 dnl ----------
 441 dnl Essentials
 442 dnl ----------
 443
 444 AX_PTHREAD([
 445   CC="$PTHREAD_CC"
 446   CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 447   LIBS="$PTHREAD_LIBS $LIBS"
 448 ], [
 449   AC_MSG_FAILURE([This FRR version needs pthreads])
 450 ])
 451
 452 AC_SEARCH_LIBS([pthread_condattr_setclock], [],
 453                 [frr_cv_pthread_condattr_setclock=yes],
 454                 [frr_cv_pthread_condattr_setclock=no])
 455 if test "$frr_cv_pthread_condattr_setclock" = "yes"; then
 456   AC_DEFINE([HAVE_PTHREAD_CONDATTR_SETCLOCK], [1], [Have pthread.h pthread_condattr_setclock])
 457 fi
 458
 459 dnl --------------
 460 dnl Check programs
 461 dnl --------------
 462 AC_PROG_INSTALL
 463 AC_PROG_LN_S
 464 AC_CHECK_TOOL([AR], [ar])
 465
 466 dnl -------
 467 dnl libtool
 468 dnl -------
 469 AC_ARG_ENABLE([static-bin],
 470   AS_HELP_STRING([--enable-static-bin], [link binaries statically]))
 471 LT_INIT
 472 _LT_CONFIG_LIBTOOL([
 473   patch -N -i "${srcdir}/m4/libtool-whole-archive.patch" libtool >&AS_MESSAGE_LOG_FD || \
 474     AC_MSG_WARN([Could not patch libtool for static linking support.  Loading modules into a statically linked daemon will fail.])
 475   sed -e 's%func_warning "relinking%true #\0%' -i libtool || true
 476   sed -e 's%func_warning "remember to run%true #\0%' -i libtool || true
 477   sed -e 's%func_warning ".*has not been installed in%true #\0%' -i libtool || true
 478 ])
 479 if test "$enable_static_bin" = "yes"; then
 480   AC_LDFLAGS="-static"
 481   if test "$enable_static" != "yes"; then
 482     AC_MSG_ERROR([The --enable-static-bin option must be combined with --enable-static.])
 483   fi
 484 fi
 485 if test "$enable_shared" != "yes"; then
 486   AC_MSG_ERROR([FRR cannot be built with --disable-shared.  If you want statically linked daemons, use --enable-shared --enable-static --enable-static-bin])
 487 fi
 488 AC_SUBST([AC_LDFLAGS])
 489 AM_CONDITIONAL([STATIC_BIN], [test "$enable_static_bin" = "yes"])
 490
 491 AC_ARG_ENABLE([rpath],
 492   [AS_HELP_STRING([--enable-rpath], [set hardcoded rpaths in the executable @<:@default=yes@:>@])],
 493   [],
 494   [enable_rpath=yes])
 495
 496 dnl $AR and $RANLIB are set by LT_INIT above
 497 AC_MSG_CHECKING([whether $AR supports D option])
 498 if $AR crD conftest.a >/dev/null 2>/dev/null; then
 499   AC_MSG_RESULT([yes])
 500   dnl ARFLAGS is for automake, AR_FLAGS for libtool m-(
 501   ARFLAGS="crD"
 502   AR_FLAGS="crD"
 503 else
 504   AC_MSG_RESULT([no])
 505   ARFLAGS="cru"
 506   AR_FLAGS="cru"
 507 fi
 508 AC_SUBST([ARFLAGS])
 509 AC_SUBST([AR_FLAGS])
 510
 511 AC_MSG_CHECKING([whether $RANLIB supports D option])
 512 if $RANLIB -D conftest.a >conftest.err 2>&1; then
 513   if grep -q -- '-D' conftest.err; then
 514     AC_MSG_RESULT([no])
 515   else
 516     AC_MSG_RESULT([yes])
 517     RANLIB="$RANLIB -D"
 518   fi
 519 else
 520   AC_MSG_RESULT([no])
 521 fi
 522 AC_SUBST([RANLIB])
 523
 524 test -f conftest.err && rm conftest.err
 525 test -f conftest.a && rm conftest.a
 526
 527 dnl ----------------------
 528 dnl Packages configuration
 529 dnl ----------------------
 530 if test -f config.version; then
 531   . ./config.version
 532 elif test -f "${srcdir}/config.version"; then
 533   . "${srcdir}/config.version"
 534 fi
 535 AC_ARG_WITH([pkg-extra-version],
 536   AS_HELP_STRING([--with-pkg-extra-version=VER], [add extra version field, for packagers/distributions]), [
 537   if test "$withval" = "no"; then
 538     EXTRAVERSION=
 539   else
 540     EXTRAVERSION=$withval
 541   fi
 542 ], [])
 543 AC_ARG_WITH([pkg-git-version],
 544         AS_HELP_STRING([--with-pkg-git-version], [add git information to MOTD and build version string]),
 545         [ test "$withval" != "no" && with_pkg_git_version="yes" ])
 546 AC_ARG_WITH([clippy],
 547   AS_HELP_STRING([--with-clippy=PATH], [use external clippy helper program]))
 548 AC_ARG_WITH([vtysh_pager],
 549         AS_HELP_STRING([--with-vtysh-pager=PAGER], [control what pager is compiled in as default]),
 550         VTYSH_PAGER=$withval, VTYSH_PAGER="more")
 551 AC_ARG_ENABLE([vtysh],
 552   AS_HELP_STRING([--disable-vtysh], [do not build integrated vty shell for FRR]))
 553 AC_ARG_ENABLE([doc],
 554   AS_HELP_STRING([--disable-doc], [do not build docs]))
 555 AC_ARG_ENABLE([doc-html],
 556   AS_HELP_STRING([--enable-doc-html], [build HTML docs]))
 557 AC_ARG_ENABLE([zebra],
 558   AS_HELP_STRING([--disable-zebra], [do not build zebra daemon]))
 559 AC_ARG_ENABLE([bgpd],
 560   AS_HELP_STRING([--disable-bgpd], [do not build bgpd]))
 561 AC_ARG_ENABLE([ripd],
 562   AS_HELP_STRING([--disable-ripd], [do not build ripd]))
 563 AC_ARG_ENABLE([ripngd],
 564   AS_HELP_STRING([--disable-ripngd], [do not build ripngd]))
 565 AC_ARG_ENABLE([ospfd],
 566   AS_HELP_STRING([--disable-ospfd], [do not build ospfd]))
 567 AC_ARG_ENABLE([ospf6d],
 568   AS_HELP_STRING([--disable-ospf6d], [do not build ospf6d]))
 569 AC_ARG_ENABLE([ldpd],
 570   AS_HELP_STRING([--disable-ldpd], [do not build ldpd]))
 571 AC_ARG_ENABLE([nhrpd],
 572   AS_HELP_STRING([--disable-nhrpd], [do not build nhrpd]))
 573 AC_ARG_ENABLE([eigrpd],
 574   AS_HELP_STRING([--disable-eigrpd], [do not build eigrpd]))
 575 AC_ARG_ENABLE([babeld],
 576   AS_HELP_STRING([--disable-babeld], [do not build babeld]))
 577 AC_ARG_ENABLE([watchfrr],
 578   AS_HELP_STRING([--disable-watchfrr], [do not build watchfrr]))
 579 AC_ARG_ENABLE([isisd],
 580   AS_HELP_STRING([--disable-isisd], [do not build isisd]))
 581 AC_ARG_ENABLE([pimd],
 582   AS_HELP_STRING([--disable-pimd], [do not build pimd]))
 583 AC_ARG_ENABLE([pbrd],
 584   AS_HELP_STRING([--disable-pbrd], [do not build pbrd]))
 585 AC_ARG_ENABLE([sharpd],
 586   AS_HELP_STRING([--enable-sharpd], [build sharpd]))
 587 AC_ARG_ENABLE([staticd],
 588   AS_HELP_STRING([--disable-staticd], [do not build staticd]))
 589 AC_ARG_ENABLE([fabricd],
 590   AS_HELP_STRING([--disable-fabricd], [do not build fabricd]))
 591 AC_ARG_ENABLE([vrrpd],
 592   AS_HELP_STRING([--disable-vrrpd], [do not build vrrpd]))
 593 AC_ARG_ENABLE([pathd],
 594   AS_HELP_STRING([--disable-pathd], [do not build pathd]))
 595 AC_ARG_ENABLE([bgp-announce],
 596   AS_HELP_STRING([--disable-bgp-announce], [turn off BGP route announcement]))
 597 AC_ARG_ENABLE([bgp-vnc],
 598   AS_HELP_STRING([--disable-bgp-vnc],[turn off BGP VNC support]))
 599 AC_ARG_ENABLE([bgp-bmp],
 600   AS_HELP_STRING([--disable-bgp-bmp],[turn off BGP BMP support]))
 601 AC_ARG_ENABLE([snmp],
 602   AS_HELP_STRING([--enable-snmp], [enable SNMP support for agentx]))
 603 AC_ARG_ENABLE([config_rollbacks],
 604   AS_HELP_STRING([--enable-config-rollbacks], [enable configuration rollbacks (requires sqlite3)]))
 605 AC_ARG_ENABLE([confd],
 606   AS_HELP_STRING([--enable-confd=ARG], [enable confd integration]))
 607 AC_ARG_ENABLE([sysrepo],
 608   AS_HELP_STRING([--enable-sysrepo], [enable sysrepo integration]))
 609 AC_ARG_ENABLE([grpc],
 610   AS_HELP_STRING([--enable-grpc], [enable the gRPC northbound plugin]))
 611 AC_ARG_ENABLE([zeromq],
 612   AS_HELP_STRING([--enable-zeromq], [enable ZeroMQ handler (libfrrzmq)]))
 613 AC_ARG_ENABLE([lttng],
 614   AS_HELP_STRING([--enable-lttng], [enable LTTng tracing]))
 615 AC_ARG_ENABLE([usdt],
 616   AS_HELP_STRING([--enable-usdt], [enable USDT probes]))
 617 AC_ARG_WITH([libpam],
 618   AS_HELP_STRING([--with-libpam], [use libpam for PAM support in vtysh]))
 619 AC_ARG_ENABLE([ospfapi],
 620   AS_HELP_STRING([--disable-ospfapi], [do not build OSPFAPI to access the OSPF LSA Database]))
 621 AC_ARG_ENABLE([ospfclient],
 622   AS_HELP_STRING([--disable-ospfclient], [do not build OSPFAPI client for OSPFAPI,
 623                           (this is the default if --disable-ospfapi is set)]))
 624 AC_ARG_ENABLE([multipath],
 625   AS_HELP_STRING([--enable-multipath=ARG], [enable multipath function, ARG must be digit]))
 626 AC_ARG_ENABLE([user],
 627   AS_HELP_STRING([--enable-user=USER], [user to run FRR suite as (default frr)]))
 628 AC_ARG_ENABLE([group],
 629   AS_HELP_STRING([--enable-group=GROUP], [group to run FRR suite as (default frr)]))
 630 AC_ARG_ENABLE([vty_group],
 631   AS_HELP_STRING([--enable-vty-group=ARG], [set vty sockets to have specified group as owner]))
 632 AC_ARG_ENABLE([configfile_mask],
 633   AS_HELP_STRING([--enable-configfile-mask=ARG], [set mask for config files]))
 634 AC_ARG_ENABLE([logfile_mask],
 635   AS_HELP_STRING([--enable-logfile-mask=ARG], [set mask for log files]))
 636 AC_ARG_ENABLE([shell_access],
 637   AS_HELP_STRING([--enable-shell-access], [Allow users to access shell/telnet/ssh]))
 638 AC_ARG_ENABLE([realms],
 639   AS_HELP_STRING([--enable-realms], [enable REALMS support under Linux]))
 640 AC_ARG_ENABLE([rtadv],
 641   AS_HELP_STRING([--disable-rtadv], [disable IPV6 router advertisement feature]))
 642 AC_ARG_ENABLE([irdp],
 643   AS_HELP_STRING([--disable-irdp], [disable IRDP server support in zebra (enabled by default if supported)]))
 644 AC_ARG_ENABLE([capabilities],
 645   AS_HELP_STRING([--disable-capabilities], [disable using POSIX capabilities]))
 646 AC_ARG_ENABLE([rusage],
 647   AS_HELP_STRING([--disable-rusage], [disable using getrusage]))
 648 AC_ARG_ENABLE([gcc_ultra_verbose],
 649   AS_HELP_STRING([--enable-gcc-ultra-verbose], [enable ultra verbose GCC warnings]))
 650 AC_ARG_ENABLE([backtrace],
 651   AS_HELP_STRING([--disable-backtrace], [disable crash backtraces (default autodetect)]))
 652 AC_ARG_ENABLE([time-check],
 653   AS_HELP_STRING([--disable-time-check], [disable slow thread warning messages]))
 654 AC_ARG_ENABLE([cpu-time],
 655   AS_HELP_STRING([--disable-cpu-time], [disable cpu usage data gathering]))
 656 AC_ARG_ENABLE([pcreposix],
 657   AS_HELP_STRING([--enable-pcreposix], [enable using PCRE Posix libs for regex functions]))
 658 AC_ARG_ENABLE([fpm],
 659   AS_HELP_STRING([--enable-fpm], [enable Forwarding Plane Manager support]))
 660 AC_ARG_ENABLE([pcep],
 661   AS_HELP_STRING([--enable-pcep], [enable PCEP support for pathd]))
 662 AC_ARG_ENABLE([systemd],
 663   AS_HELP_STRING([--enable-systemd], [enable Systemd support]))
 664 AC_ARG_ENABLE([werror],
 665   AS_HELP_STRING([--enable-werror], [enable -Werror (recommended for developers only)]))
 666 AC_ARG_ENABLE([cumulus],
 667   AS_HELP_STRING([--enable-cumulus], [enable Cumulus Switch Special Extensions]))
 668 AC_ARG_ENABLE([datacenter],
 669   AS_HELP_STRING([--enable-datacenter], [enable Compilation for Data Center Extensions]))
 670 AC_ARG_ENABLE([rr-semantics],
 671   AS_HELP_STRING([--disable-rr-semantics], [disable the v6 Route Replace semantics]))
 672 AC_ARG_ENABLE([protobuf],
 673   AS_HELP_STRING([--enable-protobuf], [Enable experimental protobuf support]))
 674 AC_ARG_ENABLE([oldvpn_commands],
 675   AS_HELP_STRING([--enable-oldvpn-commands], [Keep old vpn commands]))
 676 AC_ARG_ENABLE([rpki],
 677   AS_HELP_STRING([--enable-rpki], [enable RPKI prefix validation support]))
 678 AC_ARG_ENABLE([clippy-only],
 679   AS_HELP_STRING([--enable-clippy-only], [Only build clippy]))
 680 AC_ARG_ENABLE([numeric_version],
 681   AS_HELP_STRING([--enable-numeric-version], [Only numeric digits allowed in version (for Alpine)]))
 682 AC_ARG_ENABLE([gcov],
 683   AS_HELP_STRING([--enable-gcov], [Collect coverage information with gcov]))
 684 AC_ARG_ENABLE([clang_coverage],
 685   AS_HELP_STRING([--enable-clang-coverage], [Collect coverage information with Clang Coverage]))
 686 AC_ARG_ENABLE([bfdd],
 687   AS_HELP_STRING([--disable-bfdd], [do not build bfdd]))
 688 AC_ARG_ENABLE([address-sanitizer],
 689   AS_HELP_STRING([--enable-address-sanitizer], [enable AddressSanitizer support for detecting a wide variety of memory allocation and deallocation errors]))
 690 AC_ARG_ENABLE([thread-sanitizer],
 691   AS_HELP_STRING([--enable-thread-sanitizer], [enable ThreadSanitizer support for detecting data races]))
 692 AC_ARG_ENABLE([memory-sanitizer],
 693   AS_HELP_STRING([--enable-memory-sanitizer], [enable MemorySanitizer support for detecting uninitialized memory reads]))
 694 AC_ARG_ENABLE([undefined-sanitizer],
 695   AS_HELP_STRING([--undefined-sanitizer], [enable UndefinedBehaviorSanitizer support for detecting undefined behavior]))
 696 AC_ARG_WITH([crypto],
 697   AS_HELP_STRING([--with-crypto=<internal|openssl>], [choose between different implementations of cryptographic functions(default value is --with-crypto=internal)]))
 698 AC_ARG_WITH([frr-format],
 699   AS_HELP_STRING([--with-frr-format[=<.../frr-format.so>]], [use frr-format GCC plugin]))
 700
 701 AC_ARG_ENABLE([version-build-config],
 702   AS_HELP_STRING([--disable-version-build-config], [do not include build configs in show version command]))
 703
 704 #if openssl, else use the internal
 705 AS_IF([test "$with_crypto" = "openssl"], [
 706 AC_CHECK_LIB([crypto], [EVP_DigestInit], [LIBS="$LIBS -lcrypto"], [], [])
 707 if test "$ac_cv_lib_crypto_EVP_DigestInit" = "no"; then
 708   AC_MSG_ERROR([build with openssl has been specified but openssl library was not found on your system])
 709 else
 710   AC_DEFINE([CRYPTO_OPENSSL], [1], [Compile with openssl support])
 711 fi
 712 ], [test "$with_crypto" = "internal" || test "$with_crypto" = "" ], [AC_DEFINE([CRYPTO_INTERNAL], [1], [Compile with internal cryptographic implementation])
 713 ], [AC_MSG_ERROR([Unknown value for --with-crypto])]
 714 )
 715
 716 AS_IF([test "$enable_clippy_only" != "yes"], [
 717 AC_CHECK_HEADERS([json-c/json.h])
 718 AC_CHECK_LIB([json-c], [json_object_get], [LIBS="$LIBS -ljson-c"], [], [-lm])
 719 if test "$ac_cv_lib_json_c_json_object_get" = "no"; then
 720   AC_CHECK_LIB([json], [json_object_get], [LIBS="$LIBS -ljson"])
 721   if test "$ac_cv_lib_json_json_object_get" = "no"; then
 722       AC_MSG_ERROR([libjson is needed to compile])
 723   fi
 724 fi
 725 ])
 726
 727 AC_ARG_ENABLE([dev_build],
 728     AS_HELP_STRING([--enable-dev-build], [build for development]))
 729
 730 AC_ARG_ENABLE([scripting],
 731     AS_HELP_STRING([--enable-scripting], [Build with scripting support]))
 732
 733 AC_ARG_ENABLE([netlink-debug],
 734   AS_HELP_STRING([--disable-netlink-debug], [pretty print netlink debug messages]))
 735
 736 if test "$enable_netlink_debug" != "no" ; then
 737   AC_DEFINE([NETLINK_DEBUG], [1], [Netlink extra debugging code])
 738 fi
 739
 740 AM_CONDITIONAL([NETLINK_DEBUG], [test "$enable_netlink_debug" != "no"])
 741
 742 if test "$enable_time_check" != "no" ; then
 743   if test "$enable_time_check" = "yes" -o "$enable_time_check" = "" ; then
 744     AC_DEFINE([CONSUMED_TIME_CHECK], [5000000], [Consumed Time Check])
 745   else
 746     AC_DEFINE_UNQUOTED([CONSUMED_TIME_CHECK], [$enable_time_check], [Consumed Time Check])
 747   fi
 748 fi
 749
 750 case "${enable_cpu_time}" in
 751   "no")
 752   AC_DEFINE([EXCLUDE_CPU_TIME], [1], [Exclude getrusage data gathering])
 753   ;;
 754   "*")
 755   ;;
 756 esac
 757
 758 case "${enable_systemd}" in
 759   "no") ;;
 760   "yes")
 761   AC_CHECK_LIB([systemd], [sd_notify], [LIBS="$LIBS -lsystemd"])
 762   if test "$ac_cv_lib_systemd_sd_notify" = "no"; then
 763     AC_MSG_ERROR([enable systemd has been specified but systemd development env not found on your system])
 764   else
 765     AC_DEFINE([HAVE_SYSTEMD], [1], [Compile systemd support in])
 766   fi
 767   ;;
 768   "*") ;;
 769 esac
 770
 771 if test "$enable_rr_semantics" != "no" ; then
 772   AC_DEFINE([HAVE_V6_RR_SEMANTICS], [1], [Compile in v6 Route Replacement Semantics])
 773 fi
 774
 775 if test "$enable_datacenter" = "yes" ; then
 776   AC_DEFINE([HAVE_DATACENTER], [1], [Compile extensions for a DataCenter])
 777   AC_MSG_WARN([The --enable-datacenter compile time option is deprecated.  Please modify the init script to pass -F datacenter to the daemons instead.])
 778   DFLT_NAME="datacenter"
 779 else
 780   DFLT_NAME="traditional"
 781 fi
 782
 783 if test "$enable_cumulus" = "yes" ; then
 784   AC_DEFINE([HAVE_CUMULUS], [1], [Compile Special Cumulus Code in])
 785 fi
 786
 787 AC_SUBST([DFLT_NAME])
 788 AC_DEFINE_UNQUOTED([DFLT_NAME], ["$DFLT_NAME"], [Name of the configuration default set])
 789
 790 if test "$enable_shell_access" = "yes"; then
 791    AC_DEFINE([HAVE_SHELL_ACCESS], [1], [Allow user to use ssh/telnet/bash, be aware this is considered insecure])
 792 fi
 793
 794 #
 795 # Python for clippy
 796 #
 797
 798 AS_IF([test "$host" = "$build"], [
 799   AC_CHECK_HEADER([gelf.h], [], [
 800     AC_MSG_ERROR([libelf headers are required for building clippy.  (Host only when cross-compiling.)])
 801   ])
 802   AC_CHECK_LIB([elf], [elf_memory], [], [
 803     AC_MSG_ERROR([libelf is required for building clippy.  (Host only when cross-compiling.)])
 804   ])
 805
 806   AC_CHECK_LIB([elf], [elf_getdata_rawchunk], [
 807     AC_DEFINE([HAVE_ELF_GETDATA_RAWCHUNK], [1], [Have elf_getdata_rawchunk()])
 808   ])
 809   AC_CHECK_LIB([elf], [gelf_getnote], [
 810     AC_DEFINE([HAVE_GELF_GETNOTE], [1], [Have gelf_getnote()])
 811   ])
 812
 813   FRR_PYTHON_DEV
 814 ], [
 815   FRR_PYTHON
 816 ])
 817
 818 FRR_PYTHON_MODULES([pytest])
 819
 820 if test "$enable_doc" != "no"; then
 821   FRR_PYTHON_MODULES([sphinx], , [
 822     if test "$enable_doc" = "yes"; then
 823       AC_MSG_ERROR([Documentation was explicitly requested with --enable-doc but sphinx is not available for $PYTHON. Please disable docs or install sphinx.])
 824     fi
 825   ])
 826 fi
 827 AM_CONDITIONAL([DOC], [test "$enable_doc" != "no" -a "$frr_py_mod_sphinx" != "false"])
 828 AM_CONDITIONAL([DOC_HTML], [test "$enable_doc_html" = "yes"])
 829
 830 FRR_PYTHON_MOD_EXEC([sphinx], [--version], [
 831   PYSPHINX="-m sphinx"
 832 ], [
 833   PYSPHINX="-c 'import sys; from sphinx import main; sys.exit(main(sys.argv))'"
 834 ])
 835 AC_SUBST([PYSPHINX])
 836
 837 #
 838 # Logic for old vpn commands support.
 839 #
 840 if test "$enable_oldvpn_commands" = "yes"; then
 841    AC_DEFINE([KEEP_OLD_VPN_COMMANDS], [1], [Define for compiling with old vpn commands])
 842 fi
 843
 844 #
 845 # End of logic for protobuf support.
 846 #
 847
 848 AC_MSG_CHECKING([if zebra should be configurable to send Route Advertisements])
 849 if test "$enable_rtadv" != "no"; then
 850   AC_MSG_RESULT([yes])
 851   AC_DEFINE([HAVE_RTADV], [1], [Enable IPv6 Routing Advertisement support])
 852 else
 853   AC_MSG_RESULT([no])
 854 fi
 855
 856 if test "$enable_user" = "no"; then
 857   enable_user=""
 858 else
 859   if test "$enable_user" = "yes" || test "$enable_user" = ""; then
 860     enable_user="frr"
 861   fi
 862   AC_DEFINE_UNQUOTED([FRR_USER], ["${enable_user}"], [frr User])
 863 fi
 864
 865 if test "$enable_group" = "no"; then
 866   enable_group=""
 867 else
 868   if test "$enable_group" = "yes" || test "$enable_group" = ""; then
 869     enable_group="frr"
 870   fi
 871   AC_DEFINE_UNQUOTED([FRR_GROUP], ["${enable_group}"], [frr Group])
 872 fi
 873
 874 if test "$enable_vty_group" = "yes" ; then
 875   AC_MSG_ERROR([--enable-vty-group requires a group as argument, not yes])
 876 elif test "$enable_vty_group" != ""; then
 877   if test "$enable_vty_group" != "no"; then
 878     AC_DEFINE_UNQUOTED([VTY_GROUP], ["${enable_vty_group}"], [VTY Sockets Group])
 879   fi
 880 fi
 881 AC_SUBST([enable_user])
 882 AC_SUBST([enable_group])
 883 AC_SUBST([enable_vty_group])
 884
 885 enable_configfile_mask=${enable_configfile_mask:-0600}
 886 AC_DEFINE_UNQUOTED([CONFIGFILE_MASK], [${enable_configfile_mask}], [Mask for config files])
 887 AC_SUBST([enable_configfile_mask])
 888
 889 enable_logfile_mask=${enable_logfile_mask:-0600}
 890 AC_DEFINE_UNQUOTED([LOGFILE_MASK], [${enable_logfile_mask}], [Mask for log files])
 891
 892 MPATH_NUM=16
 893
 894 case "${enable_multipath}" in
 895   0)
 896     MPATH_NUM=64
 897     ;;
 898   [[1-9]|[1-9][0-9]|[1-9][0-9][0-9]])
 899     MPATH_NUM="${enable_multipath}"
 900     ;;
 901   "")
 902     ;;
 903   *)
 904     AC_MSG_FAILURE([Please specify digit to enable multipath ARG])
 905     ;;
 906 esac
 907
 908 AC_DEFINE_UNQUOTED([MULTIPATH_NUM], [$MPATH_NUM], [Maximum number of paths for a route])
 909
 910 AC_DEFINE_UNQUOTED([VTYSH_PAGER], ["$VTYSH_PAGER"], [What pager to use])
 911
 912 dnl --------------------
 913 dnl Enable code coverage
 914 dnl --------------------
 915 AM_CONDITIONAL([HAVE_GCOV], [test "$enable_gcov" != "no"])
 916
 917 dnl ------------------------------------
 918 dnl Alpine only accepts numeric versions
 919 dnl ------------------------------------
 920 if test "$enable_numeric_version" != "" ; then
 921   VERSION="`echo ${VERSION} | tr -c -d '[[.0-9]]'`"
 922   PACKAGE_VERSION="`echo ${PACKAGE_VERSION} | tr -c -d '[[.0-9]]'`"
 923 fi
 924
 925 dnl -----------------------------------
 926 dnl Add extra version string to package
 927 dnl name, string and version fields.
 928 dnl -----------------------------------
 929 if test "$EXTRAVERSION" != "" ; then
 930   VERSION="${VERSION}${EXTRAVERSION}"
 931   PACKAGE_VERSION="${PACKAGE_VERSION}${EXTRAVERSION}"
 932   AC_SUBST(PACKAGE_EXTRAVERSION, ["${EXTRAVERSION}"])
 933   PACKAGE_STRING="${PACKAGE_STRING}${EXTRAVERSION}"
 934 fi
 935 AC_SUBST([EXTRAVERSION])
 936
 937 if test "$with_pkg_git_version" = "yes"; then
 938         if test -e "${srcdir}/.git"; then
 939                 AC_DEFINE([GIT_VERSION], [1], [include git version info])
 940         else    with_pkg_git_version="no"
 941                 AC_MSG_WARN([--with-pkg-git-version given, but this is not a git checkout])
 942         fi
 943 fi
 944 AM_CONDITIONAL([GIT_VERSION], [test "$with_pkg_git_version" = "yes"])
 945
 946 AC_CHECK_TOOL([OBJCOPY], [objcopy], [:])
 947 if test "$OBJCOPY" != ":"; then
 948   AC_CACHE_CHECK([for .interp value to use], [frr_cv_interp], [
 949     frr_cv_interp=""
 950     AC_LINK_IFELSE([AC_LANG_SOURCE([[int main() { return 0; }]])], [
 951       if $OBJCOPY -j.interp -Obinary conftest conftest.interp; then
 952         frr_cv_interp="`xargs -0 echo < conftest.interp`"
 953       fi
 954       test -f conftest.interp && rm conftest.interp
 955     ])
 956   ])
 957 fi
 958 if test -n "$frr_cv_interp"; then
 959   AC_DEFINE_UNQUOTED([INTERP], ["$frr_cv_interp"], [.interp value])
 960 fi
 961
 962 dnl -------------------------
 963 dnl Check other header files.
 964 dnl -------------------------
 965 AC_CHECK_HEADERS([stropts.h sys/ksym.h \
 966         linux/version.h asm/types.h])
 967
 968 ac_stdatomic_ok=false
 969 AC_DEFINE([FRR_AUTOCONF_ATOMIC], [1], [did autoconf checks for atomic funcs])
 970 AC_CHECK_HEADER([stdatomic.h],[
 971
 972   AC_MSG_CHECKING([whether _Atomic qualifier works])
 973   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 974 #include <stdatomic.h>
 975 int main(int argc, char **argv) {
 976   _Atomic int i = 0;
 977   return i;
 978 }
 979 ]])], [
 980     AC_DEFINE([HAVE_STDATOMIC_H], [1], [found stdatomic.h])
 981     AC_MSG_RESULT([yes])
 982     ac_stdatomic_ok=true
 983   ], [
 984     AC_MSG_RESULT([no])
 985   ])
 986 ])
 987
 988 AS_IF([$ac_stdatomic_ok], [true], [
 989   AC_MSG_CHECKING([for __atomic_* builtins])
 990   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 991 int main(int argc, char **argv) {
 992   volatile int i = 1;
 993   __atomic_store_n (&i, 0, __ATOMIC_RELEASE);
 994   return __atomic_load_n (&i, __ATOMIC_ACQUIRE);
 995 }
 996 ]])], [
 997     AC_DEFINE([HAVE___ATOMIC], [1], [found __atomic builtins])
 998     AC_MSG_RESULT([yes])
 999   ], [
1000     AC_MSG_RESULT([no])
1001
1002     dnl FreeBSD 9 has a broken stdatomic.h where _Atomic doesn't work
1003     AC_MSG_CHECKING([for __sync_* builtins])
1004     AC_LINK_IFELSE([AC_LANG_SOURCE([[
1005 int main(int argc, char **argv) {
1006   volatile int i = 1;
1007   __sync_fetch_and_sub (&i, 1);
1008   return __sync_val_compare_and_swap (&i, 0, 1);
1009 }
1010 ]])], [
1011       AC_DEFINE([HAVE___SYNC], [1], [found __sync builtins])
1012       AC_MSG_RESULT([yes])
1013
1014       AC_MSG_CHECKING([for __sync_swap builtin])
1015       AC_LINK_IFELSE([AC_LANG_SOURCE([[
1016 int main(int argc, char **argv) {
1017   volatile int i = 1;
1018   return __sync_swap (&i, 2);
1019 }
1020 ]])], [
1021         AC_DEFINE([HAVE___SYNC_SWAP], 1, [found __sync_swap builtin])
1022         AC_MSG_RESULT([yes])
1023       ], [
1024         AC_MSG_RESULT([no])
1025       ])
1026
1027     ], [
1028       AC_MSG_RESULT([no])
1029       AC_MSG_FAILURE([stdatomic.h unavailable and $CC has neither __atomic nor __sync builtins])
1030     ])
1031   ])
1032 ])
1033
1034 AC_CHECK_HEADERS([pthread_np.h],,, [
1035 #include <pthread.h>
1036 ])
1037 AC_CHECK_FUNCS([pthread_setname_np pthread_set_name_np pthread_getthreadid_np])
1038
1039 needsync=true
1040
1041 AS_IF([$needsync], [
1042   dnl Linux
1043   AC_MSG_CHECKING([for Linux futex() support])
1044   AC_LINK_IFELSE([AC_LANG_PROGRAM([
1045 #ifndef _GNU_SOURCE
1046 #define _GNU_SOURCE
1047 #endif
1048 #include <unistd.h>
1049 #include <limits.h>
1050 #include <sys/time.h>
1051 #include <sys/syscall.h>
1052 #include <linux/futex.h>
1053
1054 int main(void);
1055 ],
1056 [
1057 {
1058   return syscall(SYS_futex, NULL, FUTEX_WAIT, 0, NULL, NULL, 0);
1059 }
1060 ])], [
1061     AC_MSG_RESULT([yes])
1062     AC_DEFINE(HAVE_SYNC_LINUX_FUTEX,,Have Linux futex support)
1063     needsync=false
1064   ], [
1065     AC_MSG_RESULT([no])
1066   ])
1067 ])
1068
1069 AS_IF([$needsync], [
1070   dnl FreeBSD
1071   AC_MSG_CHECKING([for FreeBSD _umtx_op() support])
1072   AC_LINK_IFELSE([AC_LANG_PROGRAM([
1073 #include <errno.h>
1074 #include <stdlib.h>
1075 #include <sys/types.h>
1076 #include <sys/umtx.h>
1077 int main(void);
1078 ],
1079 [
1080 {
1081   return _umtx_op(NULL, UMTX_OP_WAIT_UINT, 0, NULL, NULL);
1082 }
1083 ])], [
1084     AC_MSG_RESULT([yes])
1085     AC_DEFINE(HAVE_SYNC_UMTX_OP,,Have FreeBSD _umtx_op() support)
1086     needsync=false
1087   ], [
1088     AC_MSG_RESULT([no])
1089   ])
1090 ])
1091
1092 AS_IF([$needsync], [
1093   dnl OpenBSD patch (not upstream at the time of writing this)
1094   dnl https://marc.info/?l=openbsd-tech&m=147299508409549&w=2
1095   AC_MSG_CHECKING([for OpenBSD futex() support])
1096   AC_LINK_IFELSE([AC_LANG_PROGRAM([
1097 #include <sys/futex.h>
1098 int main(void);
1099 ],
1100 [
1101 {
1102   return futex(NULL, FUTEX_WAIT, 0, NULL, NULL, 0);
1103 }
1104 ])], [
1105     AC_MSG_RESULT([yes])
1106     AC_DEFINE(HAVE_SYNC_OPENBSD_FUTEX,,Have OpenBSD futex support)
1107     needsync=false
1108   ], [
1109     AC_MSG_RESULT([no])
1110   ])
1111 ])
1112
1113 dnl Utility macro to avoid retyping includes all the time
1114 m4_define([FRR_INCLUDES],
1115 [#ifdef SUNOS_5
1116 #define _POSIX_C_SOURCE 200809L
1117 #define __EXTENSIONS__
1118 #endif
1119 #include <stdio.h>
1120 #include <stdlib.h>
1121 #include <stddef.h>
1122 #include <sys/types.h>
1123 /* sys/conf.h depends on param.h on FBSD at least */
1124 #include <sys/param.h>
1125 /* Required for MAXSIG */
1126 #include <signal.h>
1127 #include <sys/socket.h>
1128 #ifdef __APPLE__
1129 # define __APPLE_USE_RFC_3542
1130 #endif
1131 #include <netinet/in.h>
1132 #include <sys/time.h>
1133 #include <time.h>
1134 #include <net/if.h>
1135 ])dnl
1136
1137 dnl Same applies for HAVE_NET_IF_VAR_H, which HAVE_NETINET6_ND6_H and
1138 dnl HAVE_NETINET_IN_VAR_H depend upon. But if_var.h depends on if.h, hence
1139 dnl an additional round for it.
1140
1141 AC_CHECK_HEADERS([net/if_var.h], [], [], [FRR_INCLUDES])
1142
1143 m4_define([FRR_INCLUDES],
1144 FRR_INCLUDES
1145 [#ifdef HAVE_NET_IF_VAR_H
1146 # include <net/if_var.h>
1147 #endif
1148 ])dnl
1149
1150 AC_CHECK_HEADERS([netinet/in_var.h \
1151         net/if_dl.h net/netopt.h \
1152         inet/nd.h netinet/ip_icmp.h \
1153         sys/sysctl.h sys/sockio.h sys/conf.h],
1154         [], [], [FRR_INCLUDES])
1155
1156 AC_CHECK_HEADERS([ucontext.h], [], [],
1157 [#ifndef __USE_GNU
1158 #define __USE_GNU
1159 #endif /* __USE_GNU */
1160 FRR_INCLUDES
1161 ])
1162
1163 m4_define([UCONTEXT_INCLUDES],
1164 [#include <ucontext.h>])dnl
1165
1166 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.uc_regs],
1167   [], [], [UCONTEXT_INCLUDES])
1168 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs],
1169   [AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs.nip],
1170    [], [], [UCONTEXT_INCLUDES])],
1171   [], [UCONTEXT_INCLUDES])
1172 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.gregs],
1173   [], [], [UCONTEXT_INCLUDES])
1174
1175 m4_define([FRR_INCLUDES],
1176 FRR_INCLUDES
1177 [
1178 #include <sys/un.h>
1179 #include <netinet/in_systm.h>
1180 #ifdef HAVE_NETINET_IN_VAR_H
1181 # include <netinet/in_var.h>
1182 #endif
1183 #ifdef HAVE_NET_IF_DL_H
1184 # include <net/if_dl.h>
1185 #endif
1186 #ifdef HAVE_NET_NETOPT_H
1187 # include <net/netopt.h>
1188 #endif
1189 #include <net/route.h>
1190 #ifdef HAVE_INET_ND_H
1191 # include <inet/nd.h>
1192 #endif
1193 #include <arpa/inet.h>
1194 /* Required for IDRP */
1195 #ifdef HAVE_NETINET_IP_ICMP_H
1196 # include <netinet/ip_icmp.h>
1197 #endif
1198 ])dnl
1199
1200 dnl V6 headers are checked below, after we check for v6
1201
1202 is_linux=false
1203
1204 AC_MSG_CHECKING([which operating system interface to use])
1205 case "$host_os" in
1206   sunos* | solaris2*)
1207     AC_MSG_FAILURE([Solaris support has been removed please see versions prior or equal to 7.5])
1208     ;;
1209   linux*)
1210     AC_MSG_RESULT([Linux])
1211
1212     AC_DEFINE([GNU_LINUX], [1], [GNU Linux])
1213     AC_DEFINE([HAVE_NETLINK], [1], [netlink])
1214     AC_DEFINE([LINUX_IPV6], [1], [Linux IPv6 stack])
1215
1216     dnl Linux has a compilation problem with mixing
1217     dnl netinet/in.h and linux/in6.h they are not
1218     dnl compatible.  There has been discussion on
1219     dnl how to fix it but no real progress on implementation
1220     dnl when they fix it, remove this
1221     AC_DEFINE([IPV6_MINHOPCOUNT], [73], [Linux ipv6 Min Hop Count])
1222
1223     is_linux=true
1224     ;;
1225   openbsd*)
1226     AC_MSG_RESULT([OpenBSD])
1227
1228     AC_DEFINE([OPEN_BSD], [1], [OpenBSD])
1229     AC_DEFINE([KAME], [1], [KAME IPv6])
1230     AC_DEFINE([BSD_V6_SYSCTL], [1], [BSD v6 sysctl to turn on and off forwarding])
1231     ;;
1232   *)
1233     AC_MSG_RESULT([BSD])
1234
1235     AC_DEFINE([HAVE_NET_RT_IFLIST], [1], [NET_RT_IFLIST])
1236     AC_DEFINE([KAME], [1], [KAME IPv6])
1237     AC_DEFINE([BSD_V6_SYSCTL], [1], [BSD v6 sysctl to turn on and off forwarding])
1238     ;;
1239 esac
1240 AM_CONDITIONAL([LINUX], [${is_linux}])
1241
1242 AC_SYS_LARGEFILE
1243
1244 dnl ------------------------
1245 dnl Integrated REALMS option
1246 dnl ------------------------
1247 if test "$enable_realms" = "yes"; then
1248     case "$host_os" in
1249       linux*)
1250        AC_DEFINE([SUPPORT_REALMS], [1], [Realms support])
1251        ;;
1252       *)
1253        echo "Sorry, only Linux has REALMS support"
1254        exit 1
1255        ;;
1256     esac
1257 fi
1258
1259 dnl -------------------------------
1260 dnl Endian-ness check
1261 dnl -------------------------------
1262 AC_WORDS_BIGENDIAN
1263
1264 dnl ---------------
1265 dnl other functions
1266 dnl ---------------
1267 AC_CHECK_FUNCS([ \
1268         strlcat strlcpy \
1269         getgrouplist \
1270         openat \
1271         unlinkat \
1272         posix_fallocate \
1273         ])
1274
1275 dnl ##########################################################################
1276 dnl LARGE if block spans a lot of "configure"!
1277 if test "$enable_clippy_only" != "yes"; then
1278 dnl ##########################################################################
1279
1280 #
1281 # Logic for protobuf support.
1282 #
1283 PROTO3=false
1284 if test "$enable_protobuf" = "yes"; then
1285   # Check for protoc & protoc-c
1286
1287   # protoc is not required, it's only for a "be nice" helper target
1288   AC_CHECK_PROGS([PROTOC], [protoc], [/bin/false])
1289
1290   AC_CHECK_PROGS([PROTOC_C], [protoc-c], [/bin/false])
1291   if test "$PROTOC_C" = "/bin/false"; then
1292     AC_MSG_FAILURE([protobuf requested but protoc-c not found.  Install protobuf-c.])
1293   fi
1294
1295   PKG_CHECK_MODULES([PROTOBUF_C], [libprotobuf-c >= 0.14],, [
1296     AC_MSG_FAILURE([protobuf requested but libprotobuf-c not found.  Install protobuf-c.])
1297   ])
1298
1299   PROTO3=true
1300   AC_CHECK_HEADER([google/protobuf-c/protobuf-c.h],
1301                   [AC_CHECK_DECLS(PROTOBUF_C_LABEL_NONE,
1302                                   AC_DEFINE([HAVE_PROTOBUF_VERSION_3],
1303                                             [1], [Have Protobuf version 3]),
1304                                   [PROTO3=false],
1305                                   [#include <google/protobuf-c/protobuf-c.h>])],
1306                   [PROTO3=false && AC_MSG_FAILURE([protobuf requested but protobuf-c.h not found.  Install protobuf-c.])])
1307
1308   AC_DEFINE([HAVE_PROTOBUF], [1], [protobuf])
1309 fi
1310
1311
1312 dnl ---------------------
1313 dnl Integrated VTY option
1314 dnl ---------------------
1315 case "${enable_vtysh}" in
1316 "no")
1317   VTYSH="";;
1318 *)
1319   VTYSH="vtysh";
1320   AC_DEFINE([VTYSH], [1], [VTY shell])
1321
1322   prev_libs="$LIBS"
1323   AC_CHECK_LIB([readline], [main], [
1324     LIBREADLINE="-lreadline"
1325   ], [
1326     dnl readline failed - it might be incorrectly linked and missing its
1327     dnl termcap/tinfo/curses dependency.  see if we can fix that...
1328     AC_SEARCH_LIBS([tputs], [termcap tinfo curses ncurses], [
1329       LIBREADLINE="$ac_cv_search_tputs"
1330     ], [
1331       AC_MSG_ERROR([libreadline (needed for vtysh) not found and/or missing dependencies])
1332     ])
1333
1334     dnl re-try with the lib we found above
1335     unset ac_cv_lib_readline_main
1336     AC_CHECK_LIB([readline], [main], [
1337       LIBREADLINE="-lreadline $LIBREADLINE"
1338     ], [
1339       AC_MSG_ERROR([libreadline (needed for vtysh) not found and/or missing dependencies])
1340     ], [$LIBREADLINE])
1341   ], [])
1342   LIBS="$prev_libs"
1343
1344   AC_CHECK_HEADER([readline/history.h])
1345   if test "$ac_cv_header_readline_history_h" = "no"; then
1346     AC_MSG_ERROR([readline is too old to have readline/history.h, please update to the latest readline library.])
1347   fi
1348   AC_CHECK_LIB([readline], [rl_completion_matches], [true], [], [$LIBREADLINE])
1349   if test "$ac_cv_lib_readline_rl_completion_matches" = "no"; then
1350     AC_DEFINE([rl_completion_matches], [completion_matches], [Old readline])
1351   fi
1352   AC_CHECK_LIB([readline], [append_history], [frr_cv_append_history=yes], [frr_cv_append_history=no], [$LIBREADLINE])
1353   if test "$frr_cv_append_history" = "yes"; then
1354     AC_DEFINE([HAVE_APPEND_HISTORY], [1], [Have history.h append_history])
1355   fi
1356   ;;
1357 esac
1358 AC_SUBST([LIBREADLINE])
1359
1360 dnl ----------
1361 dnl PAM module
1362 dnl
1363 dnl FRR detects the PAM library it is built against by checking for a
1364 dnl functional pam_misc.h (Linux-PAM) or openpam.h (OpenPAM) header. pam_misc.h
1365 dnl is known to #include pam_appl.h, the standard header of a PAM library, and
1366 dnl openpam.h doesn't do that, although depends on the header too. Hence a
1367 dnl little assistance to AC_CHECK_HEADER is necessary for the proper detection
1368 dnl of OpenPAM.
1369 dnl ----------
1370 if test "$with_libpam" = "yes"; then
1371   AC_CHECK_HEADER([security/pam_misc.h],
1372     [AC_DEFINE([HAVE_PAM_MISC_H], [1], [Have pam_misc.h])
1373      AC_DEFINE([PAM_CONV_FUNC], [misc_conv], [Have misc_conv])
1374      pam_conv_func="misc_conv"
1375     ],
1376     [], FRR_INCLUDES)
1377   AC_CHECK_HEADER([security/openpam.h],
1378     [AC_DEFINE([HAVE_OPENPAM_H], [1], [Have openpam.h])
1379      AC_DEFINE([PAM_CONV_FUNC], [openpam_ttyconv], [Have openpam_ttyconv])
1380      pam_conv_func="openpam_ttyconv"
1381     ],
1382     [], FRR_INCLUDES[#include <security/pam_appl.h>])
1383   if test -z "$ac_cv_header_security_pam_misc_h$ac_cv_header_security_openpam_h" ; then
1384     AC_MSG_WARN([*** pam support will not be built ***])
1385     with_libpam="no"
1386   fi
1387 fi
1388
1389 if test "$with_libpam" = "yes"; then
1390 dnl took this test from proftpds configure.in and suited to our needs
1391 dnl -------------------------------------------------------------------------
1392 dnl
1393 dnl This next check looks funky due to a linker problem with some versions
1394 dnl of the PAM library.  Prior to 0.72 release, the Linux PAM shared library
1395 dnl omitted requiring libdl linking information. PAM-0.72 or better ships
1396 dnl with RedHat 6.2 and Debian 2.2 or better.
1397 AC_CHECK_LIB([pam], [pam_start],
1398   [AC_CHECK_LIB([pam], [$pam_conv_func],
1399     [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1400      LIBPAM="-lpam"],
1401     [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1402      LIBPAM="-lpam -lpam_misc"]
1403     )
1404   ],
1405
1406   [AC_CHECK_LIB([pam], [pam_end],
1407     [AC_CHECK_LIB([pam], [$pam_conv_func],
1408       [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1409        LIBPAM="-lpam -ldl"],
1410       [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1411        LIBPAM="-lpam -ldl -lpam_misc"]
1412      )
1413   ],AC_MSG_WARN([*** pam support will not be built ***]),
1414   [-ldl])
1415   ]
1416 )
1417 fi
1418 AC_SUBST([LIBPAM])
1419
1420 dnl -------------------------------
1421 dnl bgpd needs pow() and hence libm
1422 dnl -------------------------------
1423 TMPLIBS="$LIBS"
1424 LIBS=""
1425 AC_SEARCH_LIBS([pow], [m], [
1426   LIBM="$LIBS"
1427 ], [
1428   AC_MSG_WARN([Unable to find working pow function - bgpd may not link])
1429 ])
1430 LIBS="$TMPLIBS"
1431 AC_SUBST([LIBM])
1432
1433 AC_CHECK_FUNCS([ppoll], [
1434   AC_DEFINE([HAVE_PPOLL], [1], [have Linux/BSD ppoll()])
1435 ])
1436 AC_CHECK_FUNCS([pollts], [
1437   AC_DEFINE([HAVE_POLLTS], [1], [have NetBSD pollts()])
1438 ])
1439
1440 AC_CHECK_HEADER([asm-generic/unistd.h],
1441                 [AC_CHECK_DECL(__NR_setns,
1442                                AC_DEFINE([HAVE_NETNS], [1], [Have netns]),,
1443                                FRR_INCLUDES [#include <asm-generic/unistd.h>
1444                                ])
1445                  AC_CHECK_FUNCS([setns])]
1446                )
1447
1448 dnl --------------------------
1449 dnl Determine IS-IS I/O method
1450 dnl --------------------------
1451 AC_DEFINE([ISIS_METHOD_PFPACKET], [1], [constant value for isis method pfpacket])
1452 AC_DEFINE([ISIS_METHOD_DLPI], [2], [constant value for isis method dlpi])
1453 AC_DEFINE([ISIS_METHOD_BPF], [3], [constant value for isis method bpf])
1454 AC_CHECK_HEADER([net/bpf.h])
1455 AC_CHECK_HEADER([sys/dlpi.h])
1456 AC_MSG_CHECKING([zebra IS-IS I/O method])
1457
1458 case "$host_os" in
1459   linux*)
1460     AC_MSG_RESULT([pfpacket])
1461     ISIS_METHOD_MACRO="ISIS_METHOD_PFPACKET"
1462     ;;
1463   *)
1464     if test "$ac_cv_header_net_bpf_h" = "no"; then
1465       if test "$ac_cv_header_sys_dlpi_h" = "no"; then
1466         AC_MSG_RESULT([none])
1467         if test "$enable_isisd" = "yes" -o "$enable_fabricd" = "yes"; then
1468           AC_MSG_FAILURE([IS-IS support requested but no packet backend found])
1469         fi
1470         AC_MSG_WARN([*** IS-IS support will not be built ***])
1471         enable_isisd="no"
1472         enable_fabricd="no"
1473       else
1474         AC_MSG_RESULT([DLPI])
1475       fi
1476       ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1477     else
1478       AC_MSG_RESULT([BPF])
1479       ISIS_METHOD_MACRO="ISIS_METHOD_BPF"
1480     fi
1481     ;;
1482 esac
1483 AC_DEFINE_UNQUOTED([ISIS_METHOD], [$ISIS_METHOD_MACRO], [selected method for isis, == one of the constants])
1484
1485 dnl ---------------------------------------------------------------
1486 dnl figure out how to specify an interface in multicast sockets API
1487 dnl ---------------------------------------------------------------
1488 AC_CHECK_MEMBERS([struct ip_mreqn.imr_ifindex], [], [], FRR_INCLUDES)
1489
1490 AC_CHECK_HEADERS([linux/mroute.h], [], [],[
1491         #include <sys/socket.h>
1492         #include <netinet/in.h>
1493         #define _LINUX_IN_H             /* For Linux <= 2.6.25 */
1494         #include <linux/types.h>
1495 ])
1496
1497 m4_define([FRR_INCLUDES],
1498 FRR_INCLUDES
1499 [#ifdef HAVE_LINUX_MROUTE_H
1500 # include <linux/mroute.h>
1501 #endif
1502 ])dnl
1503
1504 AC_CHECK_HEADERS([netinet/ip_mroute.h], [], [],[
1505         #include <sys/socket.h>
1506         #include <sys/types.h>
1507         #include <netinet/in.h>
1508         #include <net/route.h>
1509 ])
1510
1511 m4_define([FRR_INCLUDES],
1512 FRR_INCLUDES
1513 [#ifdef HAVE_NETINET_IP_MROUTE_H
1514 # include <netinet/ip_mroute.h>
1515 #endif
1516 ])dnl
1517
1518 AC_MSG_CHECKING([for BSD struct ip_mreq hack])
1519 AC_TRY_COMPILE([#include <sys/param.h>],
1520 [#if (defined(__FreeBSD__) && ((__FreeBSD_version >= 500022 && __FreeBSD_version < 700000) || (__FreeBSD_version < 500000 && __FreeBSD_version >= 440000))) || (defined(__NetBSD__) && defined(__NetBSD_Version__) && __NetBSD_Version__ >= 106010000) || defined(__OpenBSD__) || defined(__APPLE__) || defined(__DragonFly__) || defined(__sun)
1521   return (0);
1522 #else
1523   #error No support for BSD struct ip_mreq hack detected
1524 #endif],[AC_MSG_RESULT([yes])
1525 AC_DEFINE([HAVE_BSD_STRUCT_IP_MREQ_HACK], [1], [Can pass ifindex in struct ip_mreq])],
1526 AC_MSG_RESULT([no]))
1527
1528 AC_MSG_CHECKING([for RFC3678 protocol-independed API])
1529 AC_TRY_COMPILE([
1530 #include <sys/types.h>
1531 #include <netinet/in.h>
1532 ], [struct group_req gr; int sock; setsockopt(sock, IPPROTO_IP, MCAST_JOIN_GROUP, (void*)&gr, sizeof(gr));
1533 ], [AC_MSG_RESULT([yes])
1534 AC_DEFINE([HAVE_RFC3678], [1], [Have RFC3678 protocol-independed API])],
1535 AC_MSG_RESULT([no]))
1536
1537 dnl ---------------------------------------------------------------
1538 dnl figure out how to check link-state
1539 dnl ---------------------------------------------------------------
1540 AC_CHECK_HEADER([net/if_media.h],
1541   [m4_define([LINK_DETECT_INCLUDES],
1542     FRR_INCLUDES
1543     [#include <net/if_media.h>
1544   ])
1545   AC_CHECK_MEMBERS([struct ifmediareq.ifm_status],
1546     AC_DEFINE([HAVE_BSD_LINK_DETECT], [1], [BSD link-detect]),
1547     [], LINK_DETECT_INCLUDES)],
1548   [],
1549   FRR_INCLUDES)
1550
1551 dnl ---------------------------------------------------------------
1552 dnl Additional, newer way to check link-state using ifi_link_state.
1553 dnl Not available in all BSD's when ifmediareq available
1554 dnl ---------------------------------------------------------------
1555 AC_CHECK_MEMBERS([struct if_data.ifi_link_state],
1556   AC_DEFINE([HAVE_BSD_IFI_LINK_STATE], [1], [BSD ifi_link_state available]),
1557   [], FRR_INCLUDES)
1558
1559 dnl ------------------------
1560 dnl TCP_MD5SIG socket option
1561 dnl ------------------------
1562
1563 AC_CHECK_HEADER([netinet/tcp.h],
1564    [m4_define([MD5_INCLUDES],
1565       FRR_INCLUDES
1566       [#include <netinet/tcp.h>
1567     ])
1568     AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)],
1569    [],
1570    FRR_INCLUDES)
1571 if test "$ac_cv_have_decl_TCP_MD5SIG" = "no"; then
1572   AC_CHECK_HEADER([linux/tcp.h],
1573        [m4_define([MD5_INCLUDES],
1574           FRR_INCLUDES
1575           [#include <linux/tcp.h>
1576         ])
1577        AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)])
1578 fi
1579
1580 AC_CHECK_LIB([crypt], [crypt], [],
1581                     [AC_CHECK_LIB([crypto], [DES_crypt])])
1582 AC_CHECK_LIB([resolv], [res_init])
1583
1584 dnl ---------------------------
1585 dnl check system has PCRE regexp
1586 dnl ---------------------------
1587 if test "$enable_pcreposix" = "yes"; then
1588   AC_CHECK_LIB([pcreposix], [regexec], [], [
1589     AC_MSG_ERROR([--enable-pcreposix given but unable to find libpcreposix])
1590   ])
1591 fi
1592 AC_SUBST([HAVE_LIBPCREPOSIX])
1593
1594 dnl ##########################################################################
1595 dnl test "$enable_clippy_only" != "yes"
1596 fi
1597 dnl END OF LARGE if block
1598 dnl ##########################################################################
1599
1600 dnl ------------------
1601 dnl check C-Ares library
1602 dnl ------------------
1603 PKG_CHECK_MODULES([CARES], [libcares], [
1604   c_ares_found=true
1605 ],[
1606   c_ares_found=false
1607 ])
1608 AM_CONDITIONAL([CARES], [$c_ares_found])
1609
1610
1611 dnl ----------------------------------------------------------------------------
1612 dnl figure out if domainname is available in the utsname struct (GNU extension).
1613 dnl ----------------------------------------------------------------------------
1614 AC_CHECK_MEMBERS([struct utsname.domainname], [], [], [#include <sys/utsname.h>])
1615
1616 dnl ------------------
1617 dnl IPv6 header checks
1618 dnl ------------------
1619 AC_CHECK_HEADERS([netinet6/in6.h netinet/in6_var.h \
1620         netinet6/in6_var.h netinet6/nd6.h], [], [],
1621         FRR_INCLUDES)
1622
1623 m4_define([FRR_INCLUDES],dnl
1624 FRR_INCLUDES
1625 [#ifdef HAVE_NETINET6_IN6_H
1626 #include <netinet6/in6.h>
1627 #endif
1628 #ifdef HAVE_NETINET_IN6_VAR_H
1629 #include <netinet/in6_var.h>
1630 #endif
1631 #include <netinet/icmp6.h>
1632 #ifdef HAVE_NETINET6_IN6_VAR_H
1633 # include <netinet6/in6_var.h>
1634 #endif
1635 #ifdef HAVE_NETINET6_ND6_H
1636 # include <netinet6/nd6.h>
1637 #endif
1638 ])dnl
1639
1640 dnl --------------------
1641 dnl Daemon disable check
1642 dnl --------------------
1643
1644 AS_IF([test "$enable_bgpd" != "no"], [
1645   AC_DEFINE([HAVE_BGPD], [1], [bgpd])
1646 ])
1647
1648 AS_IF([test "$enable_ripd" != "no"], [
1649   AC_DEFINE([HAVE_RIPD], [1], [ripd])
1650 ])
1651
1652 AS_IF([test "$enable_ripngd" != "no"], [
1653   AC_DEFINE([HAVE_RIPNGD], [1], [ripngd])
1654 ])
1655
1656 AS_IF([test "$enable_ospfd" != "no"], [
1657   AC_DEFINE([HAVE_OSPFD], [1], [ospfd])
1658 ])
1659
1660 AS_IF([test "$enable_ospf6d" != "no"], [
1661   AC_DEFINE([HAVE_OSPF6D], [1], [ospf6d])
1662 ])
1663
1664 AS_IF([test "$enable_ldpd" != "no"], [
1665   AC_DEFINE([HAVE_LDPD], [1], [ldpd])
1666 ])
1667
1668 AS_IF([test "$enable_nhrpd" != "no"], [
1669   AC_DEFINE([HAVE_NHRPD], [1], [nhrpd])
1670 ])
1671
1672 AS_IF([test "$enable_eigrpd" != "no"], [
1673   AC_DEFINE([HAVE_EIGRPD], [1], [eigrpd])
1674 ])
1675
1676 AS_IF([test "$enable_babeld" != "no"], [
1677   AC_DEFINE([HAVE_BABELD], [1], [babeld])
1678 ])
1679
1680 AS_IF([test "$enable_isisd" != "no"], [
1681   AC_DEFINE([HAVE_ISISD], [1], [isisd])
1682 ])
1683
1684 AS_IF([test "$enable_pimd" != "no"], [
1685   AC_DEFINE([HAVE_PIMD], [1], [pimd])
1686 ])
1687
1688 AS_IF([test "$enable_pbrd" != "no"], [
1689   AC_DEFINE([HAVE_PBRD], [1], [pbrd])
1690 ])
1691
1692 AS_IF([test "$enable_sharpd" = "yes"], [
1693   AC_DEFINE([HAVE_SHARPD], [1], [sharpd])
1694 ])
1695
1696 AS_IF([test "$enable_staticd" != "no"], [
1697   AC_DEFINE([HAVE_STATICD], [1], [staticd])
1698 ])
1699
1700 AS_IF([test "$enable_fabricd" != "no"], [
1701   AC_DEFINE([HAVE_FABRICD], [1], [fabricd])
1702 ])
1703
1704 AS_IF([test "$enable_vrrpd" != "no"], [
1705   AC_DEFINE([HAVE_VRRPD], [1], [vrrpd])
1706 ])
1707
1708 if test "$enable_bfdd" = "no"; then
1709   AC_DEFINE([HAVE_BFDD], [0], [bfdd])
1710   BFDD=""
1711 else
1712   AC_DEFINE([HAVE_BFDD], [1], [bfdd])
1713   BFDD="bfdd"
1714
1715   case $host_os in
1716     linux*)
1717       AC_DEFINE([BFD_LINUX], [1], [bfdd])
1718       ;;
1719
1720     *)
1721       AC_DEFINE([BFD_BSD], [1], [bfdd])
1722       ;;
1723   esac
1724 fi
1725
1726 AS_IF([test "$enable_pathd" != "no"], [
1727   AC_DEFINE([HAVE_PATHD], [1], [pathd])
1728   AC_DEFINE([HAVE_PATHD_PCEP], [1], [pathd-pcep])
1729 ])
1730
1731
1732 if test "$ac_cv_lib_json_c_json_object_get" = "no" -a "$BFDD" = "bfdd"; then
1733   AC_MSG_ERROR(["you must use json-c library to use bfdd"])
1734 fi
1735
1736 NHRPD=""
1737 case "$host_os" in
1738   linux*)
1739     case "${enable_nhrpd}" in
1740       no)
1741         ;;
1742       yes)
1743         if test "$enable_clippy_only" != "yes"; then
1744         if test "$c_ares_found" != "true" ; then
1745           AC_MSG_ERROR([nhrpd requires libcares.  Please install c-ares and its -dev headers.])
1746         fi
1747         fi
1748         NHRPD="nhrpd"
1749         ;;
1750       *)
1751         if test "$c_ares_found" = "true" ; then
1752           NHRPD="nhrpd"
1753         fi
1754         ;;
1755     esac
1756     ;;
1757   *)
1758     if test "$enable_nhrpd" = "yes"; then
1759       AC_MSG_ERROR([nhrpd requires kernel APIs that are only present on Linux.])
1760     fi
1761     ;;
1762 esac
1763
1764 if test "$enable_watchfrr" = "no";then
1765   WATCHFRR=""
1766 else
1767   WATCHFRR="watchfrr"
1768 fi
1769
1770 OSPFCLIENT=""
1771 if test "$enable_ospfapi" != "no";then
1772     AC_DEFINE([SUPPORT_OSPF_API], [1], [OSPFAPI])
1773
1774   if test "$enable_ospfclient" != "no";then
1775       OSPFCLIENT="ospfclient"
1776   fi
1777 fi
1778
1779 if test "$enable_bgp_announce" = "no";then
1780   AC_DEFINE([DISABLE_BGP_ANNOUNCE], [1], [Disable BGP installation to zebra])
1781 else
1782   AC_DEFINE([DISABLE_BGP_ANNOUNCE], [0], [Disable BGP installation to zebra])
1783 fi
1784
1785 if test "$enable_bgp_vnc" != "no";then
1786   AC_DEFINE([ENABLE_BGP_VNC], [1], [Enable BGP VNC support])
1787 fi
1788
1789 bgpd_bmp=false
1790 case "${enable_bmp}" in
1791   no)
1792     ;;
1793   yes)
1794     if test "$c_ares_found" != "true" ; then
1795       AC_MSG_ERROR([BMP support requires libcares.  Please install c-ares and its -dev headers.])
1796     fi
1797     bgpd_bmp=true
1798     ;;
1799   *)
1800     if test "$c_ares_found" = "true" ; then
1801       bgpd_bmp=true
1802     fi
1803     ;;
1804 esac
1805
1806 if test "$enable_version_build_config" != "no";then
1807   AC_DEFINE([ENABLE_VERSION_BUILD_CONFIG], [1], [Report build configs in show version])
1808 fi
1809
1810 dnl ##########################################################################
1811 dnl LARGE if block
1812 if test "$enable_clippy_only" != "yes"; then
1813 dnl ##########################################################################
1814
1815 dnl ------------------
1816 dnl check Net-SNMP library
1817 dnl ------------------
1818 if test "$enable_snmp" != "" -a "$enable_snmp" != "no"; then
1819    AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], [no])
1820    if test "$NETSNMP_CONFIG" = "no"; then
1821       AC_MSG_ERROR([--enable-snmp given but unable to find net-snmp-config])
1822    fi
1823    SNMP_LIBS="`${NETSNMP_CONFIG} --agent-libs`"
1824    SNMP_CFLAGS="`${NETSNMP_CONFIG} --base-cflags`"
1825    # net-snmp lists all of its own dependencies.  we absolutely do not want that
1826    # among other things we avoid a GPL vs. OpenSSL license conflict here
1827    for removelib in crypto ssl sensors pci wrap; do
1828      SNMP_LIBS="`echo $SNMP_LIBS | sed -e 's/\(^\|\s\)-l'$removelib'\b/ /g' -e 's/\(^\|\s\)\([^\s]*\/\)\?lib'$removelib'\.[^\s]\+\b/ /g'`"
1829    done
1830    AC_MSG_CHECKING([whether we can link to Net-SNMP])
1831    AC_LINK_IFELSE_FLAGS([$SNMP_CFLAGS], [$SNMP_LIBS], [AC_LANG_PROGRAM([
1832 int main(void);
1833 ],
1834 [
1835 {
1836   return 0;
1837 }
1838 ])], [
1839      AC_MSG_RESULT([no])
1840      AC_MSG_ERROR([--enable-snmp given but not usable])])
1841    case "${enable_snmp}" in
1842      yes)
1843       SNMP_METHOD=agentx
1844       ;;
1845      agentx)
1846       SNMP_METHOD="${enable_snmp}"
1847       ;;
1848      *)
1849       AC_MSG_ERROR([--enable-snmp given with an unknown method (${enable_snmp}). Use yes or agentx])
1850       ;;
1851    esac
1852    AH_TEMPLATE([SNMP_AGENTX], [Use SNMP AgentX to interface with snmpd])
1853    AC_DEFINE_UNQUOTED(AS_TR_CPP(SNMP_${SNMP_METHOD}),,[SNMP method to interface with snmpd])
1854 fi
1855 AC_SUBST([SNMP_LIBS])
1856 AC_SUBST([SNMP_CFLAGS])
1857
1858 dnl ---------------
1859 dnl libyang
1860 dnl ---------------
1861 PKG_CHECK_MODULES([LIBYANG], [libyang >= 1.0.184], , [
1862   AC_MSG_ERROR([libyang (>= 1.0.184) was not found on your system.])
1863 ])
1864 ac_cflags_save="$CFLAGS"
1865 CFLAGS="$CFLAGS $LIBYANG_CFLAGS"
1866 AC_CHECK_MEMBER([struct lyd_node.priv], [], [
1867   AC_MSG_ERROR([m4_normalize([
1868     libyang needs to be compiled with ENABLE_LYD_PRIV=ON.
1869     Instructions for this are included in the build documentation for your platform at http://docs.frrouting.org/projects/dev-guide/en/latest/building.html])
1870   ])
1871 ], [[#include <libyang/libyang.h>]])
1872 CFLAGS="$ac_cflags_save"
1873
1874 dnl ---------------
1875 dnl configuration rollbacks
1876 dnl ---------------
1877 SQLITE3=false
1878 if test "$enable_config_rollbacks" = "yes"; then
1879   PKG_CHECK_MODULES([SQLITE3], [sqlite3], [
1880     AC_DEFINE([HAVE_CONFIG_ROLLBACKS], [1], [Enable configuration rollbacks])
1881     AC_DEFINE([HAVE_SQLITE3], [1], [Enable sqlite3 database])
1882     SQLITE3=true
1883   ], [
1884     AC_MSG_ERROR([--enable-config-rollbacks given but sqlite3 was not found on your system.])
1885   ])
1886 fi
1887
1888 dnl ---------------
1889 dnl confd
1890 dnl ---------------
1891 if test "$enable_confd" != "" -a "$enable_confd" != "no"; then
1892    AC_CHECK_PROG([CONFD], [confd], [confd], [/bin/false], "${enable_confd}/bin")
1893    if test "$CONFD" = "/bin/false"; then
1894       AC_MSG_ERROR([confd was not found on your system.])]
1895    fi
1896    CONFD_CFLAGS="-I${enable_confd}/include -L${enable_confd}/lib"
1897    AC_SUBST([CONFD_CFLAGS])
1898    CONFD_LIBS="-lconfd"
1899    AC_SUBST([CONFD_LIBS])
1900    AC_DEFINE([HAVE_CONFD], [1], [Enable confd integration])
1901 fi
1902
1903 dnl ---------------
1904 dnl sysrepo
1905 dnl ---------------
1906 if test "$enable_sysrepo" = "yes"; then
1907   PKG_CHECK_MODULES([SYSREPO], [sysrepo],
1908       [AC_DEFINE([HAVE_SYSREPO], [1], [Enable sysrepo integration])
1909       SYSREPO=true],
1910       [SYSREPO=false
1911       AC_MSG_ERROR([sysrepo was not found on your system.])]
1912   )
1913 fi
1914
1915 dnl ---------------
1916 dnl gRPC
1917 dnl ---------------
1918 if test "$enable_grpc" = "yes"; then
1919   PKG_CHECK_MODULES([GRPC], [grpc grpc++ protobuf], [
1920     AC_CHECK_PROGS([PROTOC], [protoc], [/bin/false])
1921     if test "$PROTOC" = "/bin/false"; then
1922       AC_MSG_FAILURE([grpc requested but protoc not found.])
1923     fi
1924
1925     AC_DEFINE([HAVE_GRPC], [1], [Enable the gRPC northbound plugin])
1926     GRPC=true
1927   ], [
1928     GRPC=false
1929     AC_MSG_ERROR([grpc/grpc++ were not found on your system.])
1930   ])
1931 fi
1932
1933 dnl -----
1934 dnl LTTng
1935 dnl -----
1936 if test "$enable_lttng" = "yes"; then
1937   PKG_CHECK_MODULES([UST], [lttng-ust >= 2.12.0], [
1938     AC_DEFINE([HAVE_LTTNG], [1], [Enable LTTng support])
1939     LTTNG=true
1940   ], [
1941     AC_MSG_ERROR([configuration specifies --enable-lttng but lttng-ust was not found])
1942   ])
1943 fi
1944
1945 dnl ----
1946 dnl USDT
1947 dnl ----
1948 if test "$enable_usdt" = "yes"; then
1949   AC_CHECK_HEADERS([sys/sdt.h], [
1950     AC_DEFINE([HAVE_USDT], [1], [Enable USDT probes])
1951     USDT=true
1952   ], [
1953     AC_MSG_ERROR([configuration specifies --enable-usdt but no USDT kernel headers (sys/sdt.h) found])
1954   ])
1955 fi
1956
1957 dnl ------
1958 dnl ZeroMQ
1959 dnl ------
1960 if test "$enable_zeromq" != "no"; then
1961   PKG_CHECK_MODULES([ZEROMQ], [libzmq >= 4.0.0], [
1962     AC_DEFINE([HAVE_ZEROMQ], [1], [Enable ZeroMQ support])
1963     ZEROMQ=true
1964   ], [
1965     if test "$enable_zeromq" = "yes"; then
1966       AC_MSG_ERROR([configuration specifies --enable-zeromq but libzmq was not found])
1967     fi
1968   ])
1969 fi
1970
1971 dnl ------------------------------------
1972 dnl Enable RPKI and add librtr to libs
1973 dnl ------------------------------------
1974 if test "$enable_rpki" = "yes"; then
1975   PKG_CHECK_MODULES([RTRLIB], [rtrlib >= 0.5.0],
1976       [RPKI=true],
1977       [RPKI=false
1978       AC_MSG_ERROR([rtrlib was not found on your system or is too old.])]
1979   )
1980 fi
1981
1982 dnl ------------------------------------
1983 dnl pimd is not supported on OpenBSD and MacOS
1984 dnl ------------------------------------
1985 if test "$enable_pimd" != "no"; then
1986 AC_MSG_CHECKING([for pimd OS support])
1987 case "$host_os" in
1988   darwin*)
1989     AC_MSG_RESULT([no])
1990     enable_pimd="no"
1991     ;;
1992   openbsd*)
1993     AC_MSG_RESULT([no])
1994     enable_pimd="no"
1995     ;;
1996   *)
1997     AC_MSG_RESULT([yes])
1998     ;;
1999 esac
2000 fi
2001
2002 dnl -------------------------------------
2003 dnl VRRP is only supported on linux
2004 dnl -------------------------------------
2005 if test "$enable_vrrpd" != "no"; then
2006 AC_MSG_CHECKING([for VRRP OS support])
2007 case "$host_os" in
2008   linux*)
2009     AC_MSG_RESULT([yes])
2010     ;;
2011   *)
2012     AC_MSG_RESULT([no])
2013     enable_vrrpd="no"
2014     ;;
2015 esac
2016 fi
2017
2018 dnl ------------------------------------------
2019 dnl Check whether rtrlib was build with ssh support
2020 dnl ------------------------------------------
2021 AC_MSG_CHECKING([whether the RTR Library is compiled with SSH])
2022 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "rtrlib/rtrlib.h"]],
2023                         [[struct tr_ssh_config config;]])],
2024         [AC_MSG_RESULT([yes])
2025         AC_DEFINE([FOUND_SSH], [1], [found_ssh])],
2026         AC_MSG_RESULT([no])
2027 )
2028
2029 dnl ---------------
2030 dnl dlopen & dlinfo
2031 dnl ---------------
2032 AC_SEARCH_LIBS([dlopen], [dl dld], [], [
2033   AC_MSG_ERROR([unable to find the dlopen()])
2034 ])
2035
2036 AC_CHECK_HEADERS([link.h])
2037
2038 AC_CACHE_CHECK([for dlinfo(RTLD_DI_ORIGIN)], [frr_cv_rtld_di_origin], [
2039   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2040 #include <stdlib.h>
2041 #ifdef HAVE_LINK_H
2042 #include <link.h>
2043 #endif
2044 #include <dlfcn.h>
2045 ]], [[
2046   char origin[1];
2047   dlinfo (NULL, RTLD_DI_ORIGIN, &origin);
2048 ]])], [
2049     frr_cv_rtld_di_origin=yes
2050   ], [
2051     frr_cv_rtld_di_origin=no
2052   ])
2053 ])
2054 if test "$frr_cv_rtld_di_origin" = "yes"; then
2055   AC_DEFINE([HAVE_DLINFO_ORIGIN], [1], [Have dlinfo RTLD_DI_ORIGIN])
2056 fi
2057
2058 AC_CACHE_CHECK([for dlinfo(RTLD_DI_LINKMAP)], [frr_cv_rtld_di_linkmap], [
2059   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2060 #include <stdlib.h>
2061 #ifdef HAVE_LINK_H
2062 #include <link.h>
2063 #endif
2064 #include <dlfcn.h>
2065 ]], [[
2066   struct link_map *lm = NULL;
2067   dlinfo (NULL, RTLD_DI_LINKMAP, &lm);
2068 ]])], [
2069     frr_cv_rtld_di_linkmap=yes
2070   ], [
2071     frr_cv_rtld_di_linkmap=no
2072   ])
2073 ])
2074 if test "$frr_cv_rtld_di_linkmap" = "yes"; then
2075   AC_DEFINE([HAVE_DLINFO_LINKMAP], [1], [Have dlinfo RTLD_DI_LINKMAP])
2076 fi
2077
2078 dnl ##########################################################################
2079 dnl test "$enable_clippy_only" != "yes"
2080 fi
2081 dnl END OF LARGE if block
2082 dnl ##########################################################################
2083
2084 dnl ---------------------------
2085 dnl sockaddr and netinet checks
2086 dnl ---------------------------
2087 AC_CHECK_TYPES([
2088         struct sockaddr_dl,
2089         struct vifctl, struct mfcctl, struct sioc_sg_req,
2090         vifi_t, struct sioc_vif_req, struct igmpmsg,
2091         struct ifaliasreq, struct if6_aliasreq, struct in6_aliasreq,
2092         struct nd_opt_adv_interval,
2093         struct nd_opt_homeagent_info, struct nd_opt_adv_interval,
2094         struct nd_opt_rdnss, struct nd_opt_dnssl],
2095         [], [], FRR_INCLUDES)
2096
2097 AC_CHECK_MEMBERS([struct sockaddr.sa_len,
2098         struct sockaddr_in.sin_len, struct sockaddr_un.sun_len,
2099         struct sockaddr_dl.sdl_len,
2100         struct if6_aliasreq.ifra_lifetime,
2101         struct nd_opt_adv_interval.nd_opt_ai_type],
2102         [], [], FRR_INCLUDES)
2103
2104 dnl ---------------------------
2105 dnl IRDP/pktinfo/icmphdr checks
2106 dnl ---------------------------
2107
2108 AC_CHECK_TYPES([struct in_pktinfo], [
2109   AC_CHECK_TYPES([struct icmphdr], [
2110     IRDP=true
2111   ], [
2112     IRDP=false
2113   ], [FRR_INCLUDES])
2114 ], [
2115   IRDP=false
2116 ], [FRR_INCLUDES])
2117
2118 case "${enable_irdp}" in
2119 yes)
2120   $IRDP || AC_MSG_ERROR(['IRDP requires in_pktinfo at the moment!'])
2121   ;;
2122 no)
2123   IRDP=false
2124   ;;
2125 esac
2126
2127
2128 dnl -----------------------
2129 dnl checking for IP_PKTINFO
2130 dnl -----------------------
2131 AC_MSG_CHECKING([for IP_PKTINFO])
2132 AC_TRY_COMPILE([#include <netdb.h>], [
2133   int opt = IP_PKTINFO;
2134 ], [
2135   AC_MSG_RESULT([yes])
2136   AC_DEFINE([HAVE_IP_PKTINFO], [1], [Have IP_PKTINFO])
2137 ], [
2138   AC_MSG_RESULT([no])
2139 ])
2140
2141 dnl ---------------------------
2142 dnl checking for IP_RECVDSTADDR
2143 dnl ---------------------------
2144 AC_MSG_CHECKING([for IP_RECVDSTADDR])
2145 AC_TRY_COMPILE([#include <netinet/in.h>], [
2146   int opt = IP_RECVDSTADDR;
2147 ], [
2148   AC_MSG_RESULT([yes])
2149   AC_DEFINE([HAVE_IP_RECVDSTADDR], [1], [Have IP_RECVDSTADDR])
2150 ], [
2151   AC_MSG_RESULT([no])
2152 ])
2153
2154 dnl ----------------------
2155 dnl checking for IP_RECVIF
2156 dnl ----------------------
2157 AC_MSG_CHECKING([for IP_RECVIF])
2158 AC_TRY_COMPILE([#include <netinet/in.h>], [
2159   int opt = IP_RECVIF;
2160 ], [
2161   AC_MSG_RESULT([yes])
2162   AC_DEFINE([HAVE_IP_RECVIF], [1], [Have IP_RECVIF])
2163 ], [
2164   AC_MSG_RESULT([no])
2165 ])
2166
2167 dnl ----------------------
2168 dnl checking for SO_BINDANY
2169 dnl ----------------------
2170 AC_MSG_CHECKING([for SO_BINDANY])
2171 AC_TRY_COMPILE([#include <sys/socket.h>], [
2172   int opt = SO_BINDANY;
2173 ], [
2174   AC_MSG_RESULT([yes])
2175   AC_DEFINE([HAVE_SO_BINDANY], [1], [Have SO_BINDANY])
2176 ], [
2177   AC_MSG_RESULT([no])
2178 ])
2179
2180 dnl ----------------------
2181 dnl checking for IP_FREEBIND
2182 dnl ----------------------
2183 AC_MSG_CHECKING([for IP_FREEBIND])
2184 AC_TRY_COMPILE([#include <netinet/in.h>], [
2185   int opt = IP_FREEBIND;
2186 ], [
2187   AC_MSG_RESULT([yes])
2188   AC_DEFINE([HAVE_IP_FREEBIND], [1], [Have IP_FREEBIND])
2189 ], [
2190   AC_MSG_RESULT([no])
2191 ])
2192
2193 dnl --------------------------------------
2194 dnl checking for be32dec existence or not
2195 dnl --------------------------------------
2196 AC_CHECK_DECLS([be32enc, be32dec], [], [],
2197                [#include <sys/endian.h>])
2198
2199 dnl --------------------------------------
2200 dnl checking for clock_time monotonic struct and call
2201 dnl --------------------------------------
2202 AC_CHECK_DECL([CLOCK_MONOTONIC],
2203         [AC_CHECK_LIB([rt], [clock_gettime], [LIBS="$LIBS -lrt"])
2204          AC_DEFINE([HAVE_CLOCK_MONOTONIC], [1], [Have monotonic clock])
2205 ], [AC_MSG_RESULT([no])], [FRR_INCLUDES])
2206
2207 AC_SEARCH_LIBS([clock_nanosleep], [rt], [
2208   AC_DEFINE([HAVE_CLOCK_NANOSLEEP], [1], [Have clock_nanosleep()])
2209 ])
2210
2211 dnl --------------------------------------
2212 dnl checking for flex and bison
2213 dnl --------------------------------------
2214
2215 AM_PROG_LEX
2216 AC_MSG_CHECKING([version of flex])
2217 frr_ac_flex_version="$(eval $LEX -V | grep flex | head -n 1)"
2218 frr_ac_flex_version="${frr_ac_flex_version##* }"
2219 AC_MSG_RESULT([$frr_ac_flex_version])
2220 AX_COMPARE_VERSION([$frr_ac_flex_version], [lt], [2.5.20], [
2221   LEX="$SHELL $missing_dir/missing flex"
2222   if test -f "${srcdir}/lib/command_lex.c" -a -f "${srcdir}/lib/command_lex.h"; then
2223     AC_MSG_WARN([using pregenerated flex output files])
2224   else
2225     AC_MSG_ERROR([flex failure and pregenerated files not included (probably a git build)])
2226   fi
2227   AC_SUBST([LEX_OUTPUT_ROOT], [lex.yy])
2228   AC_SUBST([LEXLIB], [''])
2229 ])
2230
2231 AC_PROG_YACC
2232 dnl thanks GNU bison for this b*llshit...
2233 AC_MSG_CHECKING([version of bison])
2234 frr_ac_bison_version="$(eval $YACC -V | grep bison | head -n 1)"
2235 frr_ac_bison_version="${frr_ac_bison_version##* }"
2236 frr_ac_bison_missing="false"
2237 case "x${frr_ac_bison_version}x" in
2238   x2.7*)
2239     BISON_OPENBRACE='"'
2240     BISON_CLOSEBRACE='"'
2241     BISON_VERBOSE=''
2242     AC_MSG_RESULT([$frr_ac_bison_version - 2.7 or older])
2243     ;;
2244   x2.*|x1.*)
2245     AC_MSG_RESULT([$frr_ac_bison_version])
2246     AC_MSG_WARN([installed bison is too old.  Please install GNU bison 2.7.x or newer.])
2247     frr_ac_bison_missing="true"
2248     ;;
2249   x)
2250     AC_MSG_RESULT([none])
2251     AC_MSG_WARN([could not determine bison version.  Please install GNU bison 2.7.x or newer.])
2252     frr_ac_bison_missing="true"
2253     ;;
2254   x3.[012][^0-9]*)
2255     BISON_OPENBRACE='{'
2256     BISON_CLOSEBRACE='}'
2257     BISON_VERBOSE='-Dparse.error=verbose'
2258     AC_MSG_RESULT([$frr_ac_bison_version - 3.0 to 3.2])
2259     ;;
2260   *)
2261     BISON_OPENBRACE='{'
2262     BISON_CLOSEBRACE='}'
2263     BISON_VERBOSE='-Dparse.error=verbose -Wno-yacc'
2264     AC_MSG_RESULT([$frr_ac_bison_version - 3.3 or newer])
2265     ;;
2266 esac
2267 AC_SUBST([BISON_OPENBRACE])
2268 AC_SUBST([BISON_CLOSEBRACE])
2269 AC_SUBST([BISON_VERBOSE])
2270
2271 if $frr_ac_bison_missing; then
2272   YACC="$SHELL $missing_dir/missing bison -y"
2273   if test -f "${srcdir}/lib/command_parse.c" -a -f "${srcdir}/lib/command_parse.h"; then
2274     AC_MSG_WARN([using pregenerated bison output files])
2275   else
2276     AC_MSG_ERROR([bison failure and pregenerated files not included (probably a git build)])
2277   fi
2278 fi
2279
2280 dnl -------------------
2281 dnl capabilities checks
2282 dnl -------------------
2283 if test "$enable_capabilities" != "no"; then
2284   AC_MSG_CHECKING([whether prctl PR_SET_KEEPCAPS is available])
2285   AC_TRY_COMPILE([#include <sys/prctl.h>], [prctl(PR_SET_KEEPCAPS, 1, 0, 0, 0);],
2286     [AC_MSG_RESULT([yes])
2287      AC_DEFINE([HAVE_PR_SET_KEEPCAPS], [1], [prctl])
2288      frr_ac_keepcaps="yes"],
2289      AC_MSG_RESULT([no])
2290   )
2291   if test "$frr_ac_keepcaps" = "yes"; then
2292     AC_CHECK_HEADERS([sys/capability.h])
2293   fi
2294   if test "$ac_cv_header_sys_capability_h" = "yes"; then
2295     AC_CHECK_LIB([cap], [cap_init],
2296       [AC_DEFINE([HAVE_LCAPS], [1], [Capabilities])
2297        LIBCAP="-lcap"
2298        frr_ac_lcaps="yes"]
2299     )
2300   fi
2301   if test "$frr_ac_scaps" = "yes" \
2302        -o "$frr_ac_lcaps" = "yes"; then
2303     AC_DEFINE([HAVE_CAPABILITIES], [1], [capabilities])
2304   fi
2305
2306   case "$host_os" in
2307   linux*)
2308     if test "$enable_clippy_only" != "yes"; then
2309     if test "$frr_ac_lcaps" != "yes"; then
2310       AC_MSG_ERROR([libcap and/or its headers were not found.  Running FRR without libcap support built in causes a huge performance penalty.])
2311     fi
2312     fi
2313     ;;
2314   esac
2315 else
2316   case "$host_os" in
2317   linux*)
2318     AC_MSG_WARN([Running FRR without libcap support built in causes a huge performance penalty.])
2319     ;;
2320   esac
2321 fi
2322 AC_SUBST([LIBCAP])
2323
2324 dnl ---------------------------
2325 dnl check for glibc 'backtrace'
2326 dnl ---------------------------
2327 if test "$enable_backtrace" != "no" ; then
2328   backtrace_ok=no
2329   PKG_CHECK_MODULES([UNWIND], [libunwind], [
2330     AC_DEFINE([HAVE_LIBUNWIND], [1], [libunwind])
2331     backtrace_ok=yes
2332   ], [
2333     true
2334   ])
2335
2336   if test "$backtrace_ok" = "no"; then
2337     AC_CHECK_HEADER([unwind.h], [
2338       AC_SEARCH_LIBS([unw_getcontext], [unwind], [
2339         AC_DEFINE([HAVE_LIBUNWIND], [1], [libunwind])
2340         backtrace_ok=yes
2341       ])
2342     ])
2343   fi
2344
2345   if test "$backtrace_ok" = "no"; then
2346     AC_CHECK_HEADER([execinfo.h], [
2347       AC_SEARCH_LIBS([backtrace], [execinfo], [
2348         AC_DEFINE([HAVE_GLIBC_BACKTRACE], [1], [Glibc backtrace])
2349         backtrace_ok=yes
2350       ],, [-lm])
2351     ])
2352   fi
2353
2354   if test "$enable_backtrace" = "yes" -a "$backtrace_ok" = "no"; then
2355     dnl user explicitly requested backtrace but we failed to find support
2356     AC_MSG_FAILURE([failed to find backtrace or libunwind support])
2357   fi
2358 fi
2359
2360 dnl -----------------------------------------
2361 dnl check for malloc mallinfo struct and call
2362 dnl this must try and link using LIBS, in
2363 dnl order to check no alternative allocator
2364 dnl has been specified, which might not provide
2365 dnl mallinfo
2366 dnl -----------------------------------------
2367 AC_CHECK_HEADERS([malloc.h malloc_np.h malloc/malloc.h],,, [FRR_INCLUDES])
2368
2369 AC_CACHE_CHECK([whether mallinfo is available], [frr_cv_mallinfo], [
2370   AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2371 #ifdef HAVE_MALLOC_H
2372 #include <malloc.h>
2373 #endif
2374 #ifdef HAVE_MALLOC_NP_H
2375 #include <malloc_np.h>
2376 #endif
2377 #ifdef HAVE_MALLOC_MALLOC_H
2378 #include <malloc/malloc.h>
2379 #endif
2380 ]], [[
2381 struct mallinfo ac_x; ac_x = mallinfo ();
2382 ]])], [
2383     frr_cv_mallinfo=yes
2384   ], [
2385     frr_cv_mallinfo=no
2386   ])
2387 ])
2388 if test "$frr_cv_mallinfo" = "yes"; then
2389   AC_DEFINE([HAVE_MALLINFO], [1], [mallinfo])
2390 fi
2391
2392 AC_CACHE_CHECK([whether mallinfo2 is available], [frr_cv_mallinfo2], [
2393   AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2394 #ifdef HAVE_MALLOC_H
2395 #include <malloc.h>
2396 #endif
2397 #ifdef HAVE_MALLOC_NP_H
2398 #include <malloc_np.h>
2399 #endif
2400 #ifdef HAVE_MALLOC_MALLOC_H
2401 #include <malloc/malloc.h>
2402 #endif
2403 ]], [[
2404 struct mallinfo2 ac_x; ac_x = mallinfo2 ();
2405 ]])], [
2406     frr_cv_mallinfo2=yes
2407   ], [
2408     frr_cv_mallinfo2=no
2409   ])
2410 ])
2411 if test "$frr_cv_mallinfo2" = "yes"; then
2412   AC_DEFINE([HAVE_MALLINFO2], [1], [mallinfo2])
2413 fi
2414
2415 AC_MSG_CHECKING([whether malloc_usable_size is available])
2416 AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2417 #ifdef HAVE_MALLOC_H
2418 #include <malloc.h>
2419 #endif
2420 #ifdef HAVE_MALLOC_MALLOC_H
2421 #include <malloc/malloc.h>
2422 #endif
2423 ]], [[
2424 size_t ac_x; ac_x = malloc_usable_size(NULL);
2425 ]])], [
2426   AC_MSG_RESULT([yes])
2427   AC_DEFINE([HAVE_MALLOC_USABLE_SIZE], [1], [malloc_usable_size])
2428 ], [
2429   AC_MSG_RESULT([no])
2430
2431   AC_MSG_CHECKING([whether malloc_size is available])
2432   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2433 #ifdef HAVE_MALLOC_H
2434 #include <malloc.h>
2435 #endif
2436 #ifdef HAVE_MALLOC_MALLOC_H
2437 #include <malloc/malloc.h>
2438 #endif
2439 ]], [[
2440 size_t ac_x; ac_x = malloc_size(NULL);
2441 ]])], [
2442     AC_MSG_RESULT([yes])
2443     AC_DEFINE([HAVE_MALLOC_SIZE], [1], [malloc_size])
2444   ], [
2445     AC_MSG_RESULT([no])
2446   ])
2447 ])
2448
2449 dnl ----------
2450 dnl configure date
2451 dnl ----------
2452 dev_version=`echo $VERSION | grep dev`
2453 #don't expire deprecated code in non 'dev' branch
2454 if test "$dev_version" = ""; then
2455    CONFDATE=0
2456 else
2457    CONFDATE=`date '+%Y%m%d'`
2458 fi
2459 AC_SUBST([CONFDATE])
2460
2461 dnl ------------------------------
2462 dnl set paths for state directory
2463 dnl ------------------------------
2464 AC_MSG_CHECKING([directory to use for state file])
2465 if test "$prefix" = "NONE"; then
2466   frr_statedir_prefix="";
2467 else
2468   frr_statedir_prefix=${prefix}
2469 fi
2470 if test "$localstatedir" = '${prefix}/var'; then
2471   for FRR_STATE_DIR in ${frr_statedir_prefix}/var/run dnl
2472                         ${frr_statedir_prefix}/var/adm dnl
2473                         ${frr_statedir_prefix}/etc dnl
2474                         /var/run        dnl
2475                         /var/adm        dnl
2476                         /etc            dnl
2477                         /dev/null;
2478   do
2479     test -d $FRR_STATE_DIR && break
2480   done
2481   frr_statedir=$FRR_STATE_DIR
2482 else
2483   frr_statedir=${localstatedir}
2484 fi
2485 if test "$frr_statedir" = "/dev/null"; then
2486     AC_MSG_ERROR([STATE DIRECTORY NOT FOUND! FIX OR SPECIFY --localstatedir!])
2487 fi
2488 AC_MSG_RESULT([${frr_statedir}])
2489 AC_SUBST([frr_statedir])
2490
2491 AC_DEFINE_UNQUOTED([LDPD_SOCKET], ["$frr_statedir%s%s/ldpd.sock"], [ldpd control socket])
2492 AC_DEFINE_UNQUOTED([ZEBRA_SERV_PATH], ["$frr_statedir%s%s/zserv.api"], [zebra api socket])
2493 AC_DEFINE_UNQUOTED([BFDD_CONTROL_SOCKET], ["$frr_statedir%s%s/bfdd.sock"], [bfdd control socket])
2494 AC_DEFINE_UNQUOTED([DAEMON_VTY_DIR], ["$frr_statedir%s%s"], [daemon vty directory])
2495 AC_DEFINE_UNQUOTED([DAEMON_DB_DIR], ["$frr_statedir"], [daemon database directory])
2496
2497 dnl autoconf does this, but it does it too late...
2498 test "$prefix" = "NONE" && prefix=$ac_default_prefix
2499 test "$exec_prefix" = "NONE" && exec_prefix='${prefix}'
2500
2501 dnl get the full path, recursing through variables...
2502 vtysh_bin="$bindir/vtysh"
2503 for I in 1 2 3 4 5 6 7 8 9 10; do
2504         eval vtysh_bin="\"$vtysh_bin\""
2505 done
2506 AC_DEFINE_UNQUOTED([VTYSH_BIN_PATH], ["$vtysh_bin"], [path to vtysh binary])
2507 AC_SUBST([vtysh_bin])
2508
2509 CFG_SYSCONF="$sysconfdir"
2510 CFG_SBIN="$sbindir"
2511 CFG_STATE="$frr_statedir"
2512 CFG_MODULE="$moduledir"
2513 CFG_YANGMODELS="$yangmodelsdir"
2514 CFG_SCRIPT="$scriptdir"
2515 for I in 1 2 3 4 5 6 7 8 9 10; do
2516         eval CFG_SYSCONF="\"$CFG_SYSCONF\""
2517         eval CFG_SBIN="\"$CFG_SBIN\""
2518         eval CFG_STATE="\"$CFG_STATE\""
2519         eval CFG_MODULE="\"$CFG_MODULE\""
2520         eval CFG_YANGMODELS="\"$CFG_YANGMODELS\""
2521         eval CFG_SCRIPT="\"$CFG_SCRIPT\""
2522 done
2523 AC_SUBST([CFG_SYSCONF])
2524 AC_SUBST([CFG_SBIN])
2525 AC_SUBST([CFG_STATE])
2526 AC_SUBST([CFG_MODULE])
2527 AC_SUBST([CFG_SCRIPT])
2528 AC_SUBST([CFG_YANGMODELS])
2529 AC_DEFINE_UNQUOTED([MODULE_PATH], ["$CFG_MODULE"], [path to modules])
2530 AC_DEFINE_UNQUOTED([SCRIPT_PATH], ["$CFG_SCRIPT"], [path to scripts])
2531 AC_DEFINE_UNQUOTED([YANG_MODELS_PATH], ["$CFG_YANGMODELS"], [path to YANG data models])
2532 AC_DEFINE_UNQUOTED([WATCHFRR_SH_PATH], ["${CFG_SBIN%/}/watchfrr.sh"], [path to watchfrr.sh])
2533
2534 dnl various features
2535 AM_CONDITIONAL([SUPPORT_REALMS], [test "$enable_realms" = "yes"])
2536 AM_CONDITIONAL([ENABLE_BGP_VNC], [test "$enable_bgp_vnc" != "no"])
2537 AM_CONDITIONAL([BGP_BMP], [$bgpd_bmp])
2538 dnl northbound
2539 AM_CONDITIONAL([SQLITE3], [$SQLITE3])
2540 AM_CONDITIONAL([CONFD], [test "$enable_confd" != ""])
2541 AM_CONDITIONAL([SYSREPO], [test "$enable_sysrepo" = "yes"])
2542 AM_CONDITIONAL([GRPC], [test "$enable_grpc" = "yes"])
2543 AM_CONDITIONAL([ZEROMQ], [test "$ZEROMQ" = "true"])
2544 dnl plugins
2545 AM_CONDITIONAL([RPKI], [test "$RPKI" = "true"])
2546 AM_CONDITIONAL([SNMP], [test "$SNMP_METHOD" = "agentx"])
2547 AM_CONDITIONAL([IRDP], [$IRDP])
2548 AM_CONDITIONAL([FPM], [test "$enable_fpm" = "yes"])
2549 AM_CONDITIONAL([HAVE_PROTOBUF], [test "$enable_protobuf" = "yes"])
2550 AM_CONDITIONAL([HAVE_PROTOBUF3], [$PROTO3])
2551
2552 dnl PCEP plugin
2553 AS_IF([test "$enable_pathd" != "no"], [
2554        AC_SUBST([PATHD_PCEP_LIBS], ["pceplib/libpcep_pcc.la"])
2555        AC_SUBST([PATHD_PCEP_INCL], ["-I./pceplib "])
2556        ])
2557 AC_CHECK_LIB([cunit], [CU_initialize_registry], [pcep_cunit=yes],[pcep_cunit=no])
2558 AM_CONDITIONAL([PATHD_PCEP_TEST], [test "x${pcep_cunit}" = xyes])
2559 AC_CHECK_PROG(VALGRIND_CHECK, valgrind, yes)
2560 AM_CONDITIONAL([HAVE_VALGRIND_PCEP], [test "$VALGRIND_CHECK" = "yes"])
2561
2562 dnl daemons
2563 AM_CONDITIONAL([VTYSH], [test "$VTYSH" = "vtysh"])
2564 AM_CONDITIONAL([ZEBRA], [test "$enable_zebra" != "no"])
2565 AM_CONDITIONAL([BGPD], [test "$enable_bgpd" != "no"])
2566 AM_CONDITIONAL([RIPD], [test "$enable_ripd" != "no"])
2567 AM_CONDITIONAL([OSPFD], [test "$enable_ospfd" != "no"])
2568 AM_CONDITIONAL([LDPD], [test "$enable_ldpd" != "no"])
2569 AM_CONDITIONAL([BFDD], [test "$BFDD" = "bfdd"])
2570 AM_CONDITIONAL([NHRPD], [test "$NHRPD" = "nhrpd"])
2571 AM_CONDITIONAL([EIGRPD], [test "$enable_eigrpd" != "no"])
2572 AM_CONDITIONAL([WATCHFRR], [test "$WATCHFRR" = "watchfrr"])
2573 AM_CONDITIONAL([OSPFCLIENT], [test "$OSPFCLIENT" = "ospfclient"])
2574 AM_CONDITIONAL([RIPNGD], [test "$enable_ripngd" != "no"])
2575 AM_CONDITIONAL([BABELD], [test "$enable_babeld" != "no"])
2576 AM_CONDITIONAL([OSPF6D], [test "$enable_ospf6d" != "no"])
2577 AM_CONDITIONAL([ISISD], [test "$enable_isisd" != "no"])
2578 AM_CONDITIONAL([PIMD], [test "$enable_pimd" != "no"])
2579 AM_CONDITIONAL([PBRD], [test "$enable_pbrd" != "no"])
2580 AM_CONDITIONAL([SHARPD], [test "$enable_sharpd" = "yes"])
2581 AM_CONDITIONAL([STATICD], [test "$enable_staticd" != "no"])
2582 AM_CONDITIONAL([FABRICD], [test "$enable_fabricd" != "no"])
2583 AM_CONDITIONAL([VRRPD], [test "$enable_vrrpd" != "no"])
2584 AM_CONDITIONAL([PATHD], [test "$enable_pathd" != "no"])
2585 AM_CONDITIONAL([PATHD_PCEP], [test "$enable_pathd" != "no"])
2586
2587 AC_CONFIG_FILES([Makefile],[
2588         test "$enable_dev_build" = "yes" && makefile_devbuild="--dev-build"
2589         ${PYTHON} "${ac_abs_top_srcdir}/python/makefile.py" ${makefile_devbuild} || exit 1
2590 ], [
2591         PYTHON="$PYTHON"
2592         enable_dev_build="$enable_dev_build"
2593 ])
2594
2595 AC_CONFIG_FILES([
2596           config.version
2597           changelog-auto
2598           redhat/frr.spec
2599           alpine/APKBUILD
2600           snapcraft/snapcraft.yaml
2601           lib/version.h
2602           tests/lib/cli/test_cli.refout
2603           pkgsrc/bgpd.sh pkgsrc/ospf6d.sh pkgsrc/ospfd.sh
2604           pkgsrc/ripd.sh pkgsrc/ripngd.sh pkgsrc/zebra.sh
2605           pkgsrc/eigrpd.sh])
2606
2607 AC_CONFIG_FILES([vtysh/extract.pl], [chmod +x vtysh/extract.pl])
2608 AC_CONFIG_FILES([tools/frr], [chmod +x tools/frr])
2609 AC_CONFIG_FILES([tools/watchfrr.sh], [chmod +x tools/watchfrr.sh])
2610 AC_CONFIG_FILES([tools/frrinit.sh], [chmod +x tools/frrinit.sh])
2611 AC_CONFIG_FILES([tools/frrcommon.sh])
2612 AC_CONFIG_FILES([tools/frr.service])
2613 AC_CONFIG_FILES([tools/frr@.service])
2614
2615 AS_IF([test "$with_pkg_git_version" = "yes"], [
2616     AC_CONFIG_COMMANDS([lib/gitversion.h], [
2617         dst="${ac_abs_top_builddir}/lib/gitversion.h"
2618         ${PERL} "${ac_abs_top_srcdir}/lib/gitversion.pl" \
2619                 "${ac_abs_top_srcdir}" \
2620                 > "${dst}.tmp"
2621         test -f "$dst" \
2622                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
2623                 && rm "${dst}.tmp" \
2624                 || mv "${dst}.tmp" "${dst}"
2625     ], [
2626         PERL="$PERL"
2627     ])
2628 ])
2629
2630 ## Hack, but working solution to avoid rebuilding of frr.info.
2631 ## It's already in CVS until texinfo 4.7 is more common.
2632 AC_OUTPUT
2633
2634 if test "$enable_rpath" = "yes" ; then
2635         true
2636 else
2637         # See https://old-en.opensuse.org/openSUSE:Packaging_Guidelines#Removing_Rpath
2638         sed -i 's|^hardcode_libdir_flag_spec=.*|hardcode_libdir_flag_spec=""|g' libtool
2639         sed -i 's|^runpath_var=LD_RUN_PATH|runpath_var=DIE_RPATH_DIE|g' libtool
2640 fi
2641
2642 echo "
2643 FRRouting configuration
2644 ------------------------------
2645 FRR version             : ${PACKAGE_VERSION}
2646 host operating system   : ${host_os}
2647 source code location    : ${srcdir}
2648 compiler                : ${CC}
2649 compiler flags          : ${CFLAGS} ${SAN_FLAGS}
2650 make                    : ${MAKE-make}
2651 linker flags            : ${LDFLAGS} ${SAN_FLAGS} ${LIBS} ${LIBCAP} ${LIBREADLINE} ${LIBM}
2652 state file directory    : ${frr_statedir}
2653 config file directory   : `eval echo \`echo ${sysconfdir}\``
2654 example directory       : `eval echo \`echo ${exampledir}\``
2655 module directory        : ${CFG_MODULE}
2656 script directory        : ${CFG_SCRIPT}
2657 user to run as          : ${enable_user}
2658 group to run as         : ${enable_group}
2659 group for vty sockets   : ${enable_vty_group}
2660 config file mask        : ${enable_configfile_mask}
2661 log file mask           : ${enable_logfile_mask}
2662 zebra protobuf enabled  : ${enable_protobuf:-no}
2663 vici socket path        : ${vici_socket}
2664
2665 The above user and group must have read/write access to the state file
2666 directory and to the config files in the config file directory."
2667
2668 if test "$enable_doc" != "no" -a "$frr_py_mod_sphinx" = "false"; then
2669   AC_MSG_WARN([sphinx is missing but required to build documentation])
2670 fi
2671 if test "$frr_py_mod_pytest" = "false"; then
2672   AC_MSG_WARN([pytest is missing, unit tests cannot be performed])
2673 fi