configure.ac

   1 ##
   2 ## Configure template file for Quagga.
   3 ## autoconf will generate configure script.
   4 ##
   5 ##  Copyright (c) 1996, 97, 98, 99, 2000 Kunihiro Ishiguro <kunihiro@zebra.org>
   6 ##  Portions Copyright (c) 2003 Paul Jakma <paul@dishone.st>
   7 ##
   8 AC_PREREQ(2.60)
   9
  10 AC_INIT(Quagga, 0.99.24+cl3u3, [https://bugzilla.quagga.net])
  11 CONFIG_ARGS="$*"
  12 AC_SUBST(CONFIG_ARGS)
  13 AC_CONFIG_SRCDIR(lib/zebra.h)
  14 AC_CONFIG_MACRO_DIR([m4])
  15
  16 dnl -----------------------------------
  17 dnl Get hostname and other information.
  18 dnl -----------------------------------
  19 AC_CANONICAL_BUILD()
  20 AC_CANONICAL_HOST()
  21 AC_CANONICAL_TARGET()
  22
  23 AM_INIT_AUTOMAKE(1.6)
  24 AM_SILENT_RULES([yes])
  25 AC_CONFIG_HEADERS(config.h)
  26
  27 AC_PATH_PROG(PERL, perl)
  28 AC_CHECK_PROG([GAWK],[gawk],[gawk],[not-in-PATH])
  29 if test "x$GAWK" = "xnot-in-PATH" ; then
  30         AC_MSG_ERROR([GNU awk is required for lib/memtype.h made by memtypes.awk.
  31 BSD awk complains: awk: gensub doesn't support backreferences (subst "\1") ])
  32 fi
  33 AC_ARG_VAR([GAWK],[GNU AWK])
  34
  35 dnl default is to match previous behavior
  36 exampledir=${sysconfdir}
  37 AC_ARG_ENABLE([exampledir],
  38           AS_HELP_STRING([--enable-exampledir],
  39                          [specify alternate directory for examples]),
  40                          exampledir="$enableval",)
  41 dnl XXX add --exampledir to autoconf standard directory list somehow
  42 AC_SUBST(exampledir)
  43
  44 dnl default is to match previous behavior
  45 pkgsrcrcdir=""
  46 pkgsrcdir=""
  47 AC_ARG_ENABLE([pkgsrcrcdir],
  48           AS_HELP_STRING([--enable-pkgsrcrcdir],
  49                          [specify directory for rc.d scripts]),
  50                          pkgsrcrcdir="$enableval"; pkgsrcdir="pkgsrc",)
  51 dnl XXX add --pkgsrcrcdir to autoconf standard directory list somehow
  52 AC_SUBST(pkgsrcdir)
  53 AC_SUBST(pkgsrcrcdir)
  54
  55 dnl ------------
  56 dnl Check CFLAGS
  57 dnl ------------
  58 AC_ARG_WITH(cflags,
  59 [  --with-cflags           Set CFLAGS for use in compilation.])
  60 if test "x$with_cflags" != "x" ; then
  61   CFLAGS="$with_cflags" ; cflags_specified=yes ;
  62 elif test -n "$CFLAGS" ; then
  63   cflags_specified=yes ;
  64 fi
  65
  66 AC_ARG_ENABLE(tcmalloc,
  67 [  --enable-tcmalloc    Turn on tcmalloc],
  68 [case "${enableval}" in
  69   yes) tcmalloc_enabled=true
  70 LIBS="$LIBS -ltcmalloc_minimal"
  71  ;;
  72   no)  tcmalloc_enabled=false ;;
  73   *) AC_MSG_ERROR(bad value ${enableval} for --enable-tcmalloc) ;;
  74 esac],[tcmalloc_enabled=false])
  75
  76
  77 dnl --------------------
  78 dnl Check CC and friends
  79 dnl --------------------
  80 AC_LANG([C])
  81 AC_PROG_CC
  82 AC_PROG_CPP
  83 AM_PROG_CC_C_O
  84 AC_PROG_RANLIB
  85 AC_PROG_EGREP
  86
  87 dnl autoconf 2.59 appears not to support AC_PROG_SED
  88 dnl AC_PROG_SED
  89 AC_CHECK_PROG([SED],[sed],[sed],[/bin/false])
  90
  91 dnl pdflatex and latexmk are needed to build HACKING.pdf
  92 AC_CHECK_PROG([PDFLATEX],[pdflatex],[pdflatex],[/bin/false])
  93 AC_CHECK_PROG([LATEXMK],[latexmk],[latexmk],[/bin/false])
  94 if test "x$PDFLATEX" = "x/bin/false" -o "x$LATEXMK" = "x/bin/false"; then
  95         AC_MSG_WARN([Will not be able to make PDF versions of TeX documents])
  96 else
  97         HAVE_LATEX=true
  98 fi
  99 AM_CONDITIONAL([HAVE_LATEX], [test "x$HAVE_LATEX" = "xtrue"])
 100
 101 if test "x${GCC}" != "xyes" ; then
 102   AC_MSG_CHECKING([whether we are using SunPro compiler])
 103   AC_EGREP_CPP([^__SUNPRO_C.*0x5(7|8|9)], ["__SUNPRO_C" __SUNPRO_C],
 104       [AC_MSG_RESULT([no])],
 105       [COMPILER="SUNPRO"
 106        AC_MSG_RESULT([yes])]
 107   )
 108 fi
 109
 110 dnl ---------------------------------------------
 111 dnl If CLFAGS doesn\'t exist set default value
 112 dnl AC_PROG_CC will have set minimal default
 113 dnl already, eg "-O2 -g" for gcc, "-g" for others
 114 dnl (Wall is gcc specific... have to make sure
 115 dnl  gcc is being used before setting it)
 116 dnl
 117 dnl Sun Studio 10 / SunPro 5.7 is also supported,
 118 dnl so lets set some sane CFLAGS for it.
 119 dnl ---------------------------------------------
 120
 121 AC_USE_SYSTEM_EXTENSIONS()
 122 AC_DEFUN([AC_C_FLAG], [{
 123         AC_LANG_PUSH(C)
 124         ac_c_flag_save="$CFLAGS"
 125         CFLAGS="$CFLAGS $1"
 126         AC_MSG_CHECKING([[whether $CC supports $1]])
 127         AC_COMPILE_IFELSE(
 128                 [AC_LANG_PROGRAM([[]])],
 129                 [
 130                         AC_MSG_RESULT([yes])
 131                         m4_if([$3], [], [], [
 132                                 CFLAGS="$ac_c_flag_save"
 133                                 $3
 134                         ])
 135                 ], [
 136                         CFLAGS="$ac_c_flag_save"
 137                         AC_MSG_RESULT([no])
 138                         $2
 139                 ])
 140         AC_LANG_POP(C)
 141         }])
 142
 143 AC_MSG_CHECKING([whether to set a default CFLAGS])
 144 if test "x${cflags_specified}" = "x" ; then
 145   case ${COMPILER} in
 146     "SUNPRO")
 147         CFLAGS="-xO4 -v -g -xspace -xcode=pic32 -xstrconst -xc99"
 148         AC_MSG_RESULT([SunPro default])
 149         ;;
 150     *)
 151         AC_MSG_RESULT([autodetecting])
 152
 153         AC_C_FLAG([-diag-error 10006])
 154         AC_C_FLAG([-std=gnu99])
 155         AC_C_FLAG([-g])
 156         AC_C_FLAG([-Os], [
 157           AC_C_FLAG([-O2])
 158         ])
 159         AC_C_FLAG([-fno-omit-frame-pointer])
 160         AC_C_FLAG([-Wall])
 161         AC_C_FLAG([-Wextra])
 162         AC_C_FLAG([-Wmissing-prototypes])
 163         AC_C_FLAG([-Wmissing-declarations])
 164         AC_C_FLAG([-Wpointer-arith])
 165         AC_C_FLAG([-Wbad-function-cast])
 166         AC_C_FLAG([-Wwrite-strings])
 167         if test x"${enable_gcc_ultra_verbose}" = x"yes" ; then
 168           AC_C_FLAG([-Wcast-qual])
 169           AC_C_FLAG([-Wstrict-prototypes])
 170           AC_C_FLAG([-Wmissing-noreturn])
 171           AC_C_FLAG([-Wmissing-format-attribute])
 172           AC_C_FLAG([-Wunreachable-code])
 173           AC_C_FLAG([-Wpacked])
 174           AC_C_FLAG([-Wpadded])
 175         else
 176           AC_C_FLAG([-Wno-unused-result])
 177         fi
 178         AC_C_FLAG([-Wno-unused-parameter])
 179         AC_C_FLAG([-Wno-missing-field-initializers])
 180         # ICC emits a broken warning for const char *x = a ? "b" : "c";
 181         # for some reason the string consts get 'promoted' to char *,
 182         # triggering a const to non-const conversion warning.
 183         AC_C_FLAG([-diag-disable 3179])
 184         ;;
 185   esac
 186 else
 187   AC_MSG_RESULT([CFLAGS supplied by user])
 188 fi
 189
 190 if test x"${enable_werror}" = x"yes" ; then
 191   WERROR="-Werror"
 192 fi
 193 AC_SUBST(WERROR)
 194
 195 dnl --------------
 196 dnl Check programs
 197 dnl --------------
 198 AC_PROG_INSTALL
 199 AC_PROG_LN_S
 200 AC_PROG_MAKE_SET
 201 AC_CHECK_TOOL(AR, ar)
 202
 203 dnl ---------------------------
 204 dnl We, perhaps unfortunately,
 205 dnl depend on GNU Make specific
 206 dnl constructs.
 207 dnl Give the user a warning if
 208 dnl not GNU Make.
 209 dnl ---------------------------
 210 AC_CACHE_CHECK([if ${MAKE-make} is GNU make], [quagga_cv_gnu_make],
 211         [quagga_cv_gnu_make=no
 212          if ${MAKE-make} --version 2>/dev/null | \
 213                 grep '^GNU Make ' >/dev/null ; then
 214                 quagga_cv_gnu_make=yes;
 215          fi
 216         ]
 217 )
 218
 219 dnl -----------------
 220 dnl System extensions
 221 dnl -----------------
 222 AC_GNU_SOURCE
 223
 224 dnl -------
 225 dnl libtool
 226 dnl -------
 227 LT_INIT
 228
 229 dnl ----------------------
 230 dnl Packages configuration
 231 dnl ----------------------
 232 AC_ARG_WITH(pkg-extra-version,
 233         AS_HELP_STRING([--with-pkg-extra-version=VER], [add extra version field, for packagers/distributions]),
 234         [EXTRAVERSION=$withval],)
 235 AC_ARG_WITH(pkg-git-version,
 236         AS_HELP_STRING([--with-pkg-git-version], [add git information to MOTD and build version string]),
 237         [ test "x$withval" != "xno" && with_pkg_git_version="yes" ])
 238 AC_ARG_ENABLE(vtysh,
 239   AS_HELP_STRING([--disable-vtysh], [do not build integrated vty shell for Quagga]))
 240 AC_ARG_ENABLE(doc,
 241   AS_HELP_STRING([--disable-doc], [do not build docs]))
 242 AC_ARG_ENABLE(zebra,
 243   AS_HELP_STRING([--disable-zebra], [do not build zebra daemon]))
 244 AC_ARG_ENABLE(bgpd,
 245   AS_HELP_STRING([--disable-bgpd], [do not build bgpd]))
 246 AC_ARG_ENABLE(ripd,
 247   AS_HELP_STRING([--disable-ripd], [do not build ripd]))
 248 AC_ARG_ENABLE(ripngd,
 249   AS_HELP_STRING([--disable-ripngd], [do not build ripngd]))
 250 AC_ARG_ENABLE(ospfd,
 251   AS_HELP_STRING([--disable-ospfd], [do not build ospfd]))
 252 AC_ARG_ENABLE(ospf6d,
 253   AS_HELP_STRING([--disable-ospf6d], [do not build ospf6d]))
 254 AC_ARG_ENABLE(watchquagga,
 255   AS_HELP_STRING([--disable-watchquagga], [do not build watchquagga]))
 256 AC_ARG_ENABLE(isisd,
 257   AS_HELP_STRING([--disable-isisd], [do not build isisd]))
 258 AC_ARG_ENABLE(pimd,
 259   AS_HELP_STRING([--disable-pimd], [do not build pimd]))
 260 AC_ARG_ENABLE(bgp-announce,
 261   AS_HELP_STRING([--disable-bgp-announce,], [turn off BGP route announcement]))
 262 AC_ARG_ENABLE(snmp,
 263   AS_HELP_STRING([--enable-snmp=ARG], [enable SNMP support (smux or agentx)]))
 264 AC_ARG_WITH(libpam,
 265   AS_HELP_STRING([--with-libpam], [use libpam for PAM support in vtysh]))
 266 AC_ARG_ENABLE(tcp-zebra,
 267   AS_HELP_STRING([--enable-tcp-zebra], [enable TCP/IP socket connection between zebra and protocol daemon]))
 268 AC_ARG_ENABLE(opaque-lsa,
 269   AS_HELP_STRING([--disable-opaque-lsa],[do not build OSPF Opaque-LSA with OSPFAPI support (RFC2370)]))
 270 AC_ARG_ENABLE(ospfapi,
 271   AS_HELP_STRING([--disable-ospfapi], [do not build OSPFAPI to access the OSPF LSA Database]))
 272 AC_ARG_ENABLE(ospfclient,
 273   AS_HELP_STRING([--disable-ospfclient], [do not build OSPFAPI client for OSPFAPI,
 274                           (this is the default if --disable-ospfapi is set)]))
 275 AC_ARG_ENABLE(ospf-te,
 276   AS_HELP_STRING([--disable-ospf-te],[disable Traffic Engineering Extension to OSPF]))
 277 AC_ARG_ENABLE(multipath,
 278   AS_HELP_STRING([--enable-multipath=ARG], [enable multipath function, ARG must be digit]))
 279 AC_ARG_ENABLE(user,
 280   AS_HELP_STRING([--enable-user=USER], [user to run Quagga suite as (default quagga)]))
 281 AC_ARG_ENABLE(group,
 282   AS_HELP_STRING([--enable-group=GROUP], [group to run Quagga suite as (default quagga)]))
 283 AC_ARG_ENABLE(vty_group,
 284   AS_HELP_STRING([--enable-vty-group=ARG], [set vty sockets to have specified group as owner]))
 285 AC_ARG_ENABLE(configfile_mask,
 286   AS_HELP_STRING([--enable-configfile-mask=ARG], [set mask for config files]))
 287 AC_ARG_ENABLE(logfile_mask,
 288   AS_HELP_STRING([--enable-logfile-mask=ARG], [set mask for log files]))
 289 AC_ARG_ENABLE(shell_access,
 290   AS_HELP_STRING([--enable-shell-access], [Allow users to access shell/telnet/ssh]))
 291 AC_ARG_ENABLE(rtadv,
 292   AS_HELP_STRING([--disable-rtadv], [disable IPV6 router advertisement feature]))
 293 AC_ARG_ENABLE(irdp,
 294   AS_HELP_STRING([--enable-irdp], [enable IRDP server support in zebra]))
 295 AC_ARG_ENABLE(isis_topology,
 296   AS_HELP_STRING([--enable-isis-topology], [enable IS-IS topology generator]))
 297 AC_ARG_ENABLE(capabilities,
 298   AS_HELP_STRING([--disable-capabilities], [disable using POSIX capabilities]))
 299 AC_ARG_ENABLE(rusage,
 300   AS_HELP_STRING([--disable-rusage], [disable using getrusage]))
 301 AC_ARG_ENABLE(gcc_ultra_verbose,
 302   AS_HELP_STRING([--enable-gcc-ultra-verbose], [enable ultra verbose GCC warnings]))
 303 AC_ARG_ENABLE(linux24_tcp_md5,
 304   AS_HELP_STRING([--enable-linux24-tcp-md5], [enable support for old, Linux-2.4 RFC2385 patch]))
 305 AC_ARG_ENABLE(gcc-rdynamic,
 306   AS_HELP_STRING([--enable-gcc-rdynamic], [enable linking with -rdynamic for better backtraces (default if gcc)]))
 307 AC_ARG_ENABLE(backtrace,
 308   AS_HELP_STRING([--disable-backtrace,], [disable crash backtraces (default autodetect)]))
 309 AC_ARG_ENABLE(time-check,
 310   AS_HELP_STRING([--disable-time-check], [disable slow thread warning messages]))
 311 AC_ARG_ENABLE(pcreposix,
 312   AS_HELP_STRING([--enable-pcreposix], [enable using PCRE Posix libs for regex functions]))
 313 AC_ARG_ENABLE(fpm,
 314   AS_HELP_STRING([--enable-fpm], [enable Forwarding Plane Manager support]))
 315 AC_ARG_ENABLE(systemd,
 316   AS_HELP_STRING([--enable-systemd], [enable Systemd support]))
 317 AC_ARG_ENABLE(poll,
 318   AS_HELP_STRING([--enable-poll], [enable usage of Poll instead of select]))
 319 AC_ARG_ENABLE(werror,
 320   AS_HELP_STRING([--enable-werror], [enable -Werror (recommended for developers only)]))
 321 AC_ARG_ENABLE(cumulus,
 322   AS_HELP_STRING([--enable-cumulus], [enable Cumulus Switch Special Extensions]))
 323 AC_ARG_ENABLE(rr-semantics,
 324   AS_HELP_STRING([--disable-rr-semantics], [disable the v6 Route Replace semantics]))
 325
 326 AC_CHECK_HEADERS(json-c/json.h)
 327 AC_CHECK_LIB(json-c, json_object_get, LIBS="$LIBS -ljson-c")
 328 if test $ac_cv_lib_json_c_json_object_get = no; then
 329   AC_CHECK_LIB(json, json_object_get, LIBS="$LIBS -ljson")
 330   if test $ac_cv_lib_json_json_object_get = no; then
 331       AC_MSG_ERROR([lib json is needed to compile])
 332   fi
 333 fi
 334
 335 if test x"${enable_gcc_rdynamic}" != x"no" ; then
 336   if test x"${enable_gcc_rdynamic}" = x"yes" -o x"$COMPILER" = x"GCC"; then
 337     LDFLAGS="${LDFLAGS} -rdynamic"
 338   fi
 339 fi
 340
 341 if test x"${enable_time_check}" != x"no" ; then
 342   if test x"${enable_time_check}" = x"yes" -o x"${enable_time_check}" = x ; then
 343     AC_DEFINE(CONSUMED_TIME_CHECK,5000000,Consumed Time Check)
 344   else
 345     AC_DEFINE_UNQUOTED(CONSUMED_TIME_CHECK,$enable_time_check,Consumed Time Check)
 346   fi
 347 fi
 348
 349 case "${enable_systemd}" in
 350   "no") ;;
 351   "yes")
 352   AC_CHECK_LIB(systemd, sd_notify, LIBS="$LIBS -lsystemd")
 353   if test $ac_cv_lib_systemd_sd_notify = no; then
 354     AC_MSG_ERROR([enable systemd has been specified but systemd development env not found on your system])
 355   else
 356     AC_DEFINE(HAVE_SYSTEMD,,Compile systemd support in)
 357   fi
 358   ;;
 359   "*") ;;
 360 esac
 361
 362 if test "${enable_rr_semantics}" != "no" ; then
 363   AC_DEFINE(HAVE_V6_RR_SEMANTICS,, Compile in v6 Route Replacement Semantics)
 364 fi
 365
 366 if test "${enable_poll}" = "yes" ; then
 367   AC_DEFINE(HAVE_POLL,,Compile systemd support in)
 368 fi
 369
 370 if test "${enable_cumulus}" = "yes" ; then
 371   AC_DEFINE(HAVE_CUMULUS,,Compile Special Cumulus Code in)
 372 fi
 373
 374 if test "${enable_shell_access}" = "yes"; then
 375    AC_DEFINE(HAVE_SHELL_ACCESS,,Allow user to use ssh/telnet/bash)
 376 fi
 377
 378 if test "${enable_fpm}" = "yes"; then
 379    AC_DEFINE(HAVE_FPM,,Forwarding Plane Manager support)
 380 fi
 381
 382 if test "${enable_tcp_zebra}" = "yes"; then
 383   AC_DEFINE(HAVE_TCP_ZEBRA,,Use TCP for zebra communication)
 384 fi
 385
 386 if test "${enable_opaque_lsa}" != "no"; then
 387   AC_DEFINE(HAVE_OPAQUE_LSA,,OSPF Opaque LSA)
 388 fi
 389
 390 if test "${enable_ospf_te}" != "no"; then
 391   AC_DEFINE(HAVE_OPAQUE_LSA,,OSPF Opaque LSA)
 392   AC_DEFINE(HAVE_OSPF_TE,,OSPF TE)
 393 fi
 394
 395 if test "${enable_linux24_tcp_md5}" = "yes"; then
 396   AC_DEFINE(HAVE_TCP_MD5_LINUX24,,Old Linux 2.4 TCP MD5 Signature Patch)
 397 fi
 398
 399 AC_MSG_CHECKING(if zebra should be configurable to send Route Advertisements)
 400 if test "${enable_rtadv}" != "no"; then
 401   AC_MSG_RESULT(yes)
 402   AC_DEFINE(HAVE_RTADV,,Enable IPv6 Routing Advertisement support)
 403 else
 404   AC_MSG_RESULT(no)
 405 fi
 406
 407 if test "${enable_irdp}" = "yes"; then
 408   AC_DEFINE(HAVE_IRDP,, IRDP )
 409 fi
 410
 411 if test "${enable_isisd}" != "no" && test "${enable_isis_topology}" = yes; then
 412   AC_DEFINE(TOPOLOGY_GENERATE,,Enable IS-IS topology generator code)
 413   ISIS_TOPOLOGY_INCLUDES="-I\$(srcdir)/topology"
 414   ISIS_TOPOLOGY_DIR="topology"
 415   ISIS_TOPOLOGY_LIB="./topology/libtopology.a"
 416 fi
 417
 418 AC_SUBST(ISIS_TOPOLOGY_INCLUDES)
 419 AC_SUBST(ISIS_TOPOLOGY_DIR)
 420 AC_SUBST(ISIS_TOPOLOGY_LIB)
 421
 422 if test "${enable_user}" = "yes" || test x"${enable_user}" = x""; then
 423   enable_user="quagga"
 424 elif test "${enable_user}" = "no"; then
 425   enable_user="root"
 426 fi
 427
 428 if test "${enable_group}" = "yes" || test x"${enable_group}" = x""; then
 429   enable_group="quagga"
 430 elif test "${enable_group}" = "no"; then
 431   enable_group="root"
 432 fi
 433
 434 if test x"${enable_vty_group}" = x"yes" ; then
 435   AC_MSG_ERROR([--enable-vty-group requires a group as argument, not yes])
 436 elif test x"${enable_vty_group}" != x""; then
 437   if test x"${enable_vty_group}" != x"no"; then
 438     AC_DEFINE_UNQUOTED(VTY_GROUP, "${enable_vty_group}", VTY Sockets Group)
 439   fi
 440 fi
 441 AC_SUBST([enable_user])
 442 AC_SUBST([enable_group])
 443 AC_SUBST([enable_vty_group])
 444 AC_DEFINE_UNQUOTED(QUAGGA_USER, "${enable_user}", Quagga User)
 445 AC_DEFINE_UNQUOTED(QUAGGA_GROUP, "${enable_group}", Quagga Group)
 446
 447 enable_configfile_mask=${enable_configfile_mask:-0600}
 448 AC_DEFINE_UNQUOTED(CONFIGFILE_MASK, ${enable_configfile_mask}, Mask for config files)
 449
 450 enable_logfile_mask=${enable_logfile_mask:-0600}
 451 AC_DEFINE_UNQUOTED(LOGFILE_MASK, ${enable_logfile_mask}, Mask for log files)
 452
 453 MPATH_NUM=1
 454
 455 case "${enable_multipath}" in
 456   0)
 457     MPATH_NUM=64
 458     ;;
 459   [[1-9]|[1-9][0-9]|[1-9][0-9][0-9]])
 460     MPATH_NUM="${enable_multipath}"
 461     ;;
 462   "")
 463     ;;
 464   *)
 465     AC_MSG_FAILURE([Please specify digit to enable multipath ARG])
 466     ;;
 467 esac
 468
 469 AC_DEFINE_UNQUOTED(MULTIPATH_NUM, $MPATH_NUM, Maximum number of paths for a route)
 470
 471 dnl -----------------------------------
 472 dnl Add extra version string to package
 473 dnl name, string and version fields.
 474 dnl -----------------------------------
 475 if test "x${EXTRAVERSION}" != "x" ; then
 476   VERSION="${VERSION}${EXTRAVERSION}"
 477   PACKAGE_VERSION="${PACKAGE_VERSION}${EXTRAVERSION}"
 478   PACKAGE_STRING="${PACKAGE_STRING}${EXTRAVERSION}"
 479 fi
 480
 481 if test "x$with_pkg_git_version" = "xyes"; then
 482         if test -d "${srcdir}/.git"; then
 483                 AC_DEFINE(GIT_VERSION, [1], [include git version info])
 484         else    with_pkg_git_version="no"
 485                 AC_MSG_WARN([--with-pkg-git-version given, but this is not a git checkout])
 486         fi
 487 fi
 488 AM_CONDITIONAL([GIT_VERSION], [test "x$with_pkg_git_version" = "xyes"])
 489
 490 dnl ------------------------------------
 491 dnl Check C keywords and standard  types
 492 dnl ------------------------------------
 493 AC_C_CONST
 494 AC_C_INLINE
 495 AC_C_RESTRICT
 496 AC_C_VOLATILE
 497 AC_HEADER_STDC
 498 AC_HEADER_TIME
 499 AC_HEADER_SYS_WAIT
 500 AC_HEADER_STDBOOL
 501 dnl AC_TYPE_PID_T
 502 AC_TYPE_UID_T
 503 AC_TYPE_MODE_T
 504 AC_TYPE_SIZE_T
 505 AC_STRUCT_TM
 506
 507 dnl -------------------------
 508 dnl Check other header files.
 509 dnl -------------------------
 510 AC_CHECK_HEADERS([stropts.h sys/ksym.h sys/times.h sys/select.h \
 511         sys/types.h linux/version.h netdb.h asm/types.h \
 512         sys/cdefs.h sys/param.h limits.h signal.h \
 513         sys/socket.h netinet/in.h time.h sys/time.h])
 514
 515 dnl Utility macro to avoid retyping includes all the time
 516 m4_define([QUAGGA_INCLUDES],
 517 [#ifdef SUNOS_5
 518 #define _XPG4_2
 519 #define __EXTENSIONS__
 520 #endif
 521 #include <stdio.h>
 522 #if STDC_HEADERS
 523 # include <stdlib.h>
 524 # include <stddef.h>
 525 #else
 526 # if HAVE_STDLIB_H
 527 #  include <stdlib.h>
 528 # endif
 529 #endif
 530 #if HAVE_SYS_TYPES_H
 531 # include <sys/types.h>
 532 #endif
 533 /* sys/conf.h depends on param.h on FBSD at least */
 534 #if HAVE_SYS_PARAM_H
 535 # include <sys/param.h>
 536 #endif
 537 /* Required for MAXSIG */
 538 #if HAVE_SIGNAL_H
 539 # include <signal.h>
 540 #endif
 541 #if HAVE_SYS_SOCKET_H
 542 # include <sys/socket.h>
 543 #endif
 544 #ifdef __APPLE__
 545 # define __APPLE_USE_RFC_3542
 546 #endif
 547 #if HAVE_NETINET_IN_H
 548 # include <netinet/in.h>
 549 #endif
 550 #ifdef TIME_WITH_SYS_TIME
 551 # include <sys/time.h>
 552 # include <time.h>
 553 #else
 554 # ifdef HAVE_SYS_TIME_H
 555 #  include <sys/time.h>
 556 # else
 557 #  include <time.h>
 558 # endif
 559 #endif /* TIME_WITH_SYS_TIME */
 560 ])dnl
 561
 562 dnl HAVE_NET_IF_H must be discovered by the time the longer AC_CHECK_HEADERS
 563 dnl round below execution begins, otherwise it doesn't properly detect
 564 dnl HAVE_NETINET6_IN6_VAR_H, HAVE_NET_IF_VAR_H and HAVE_STRUCT_IN6_ALIASREQ
 565 dnl on FreeBSD (BZ#408).
 566
 567 AC_CHECK_HEADERS([net/if.h], [], [], QUAGGA_INCLUDES)
 568
 569 m4_define([QUAGGA_INCLUDES],
 570 QUAGGA_INCLUDES
 571 [#if HAVE_NET_IF_H
 572 # include <net/if.h>
 573 #endif
 574 ])dnl
 575
 576 dnl Same applies for HAVE_NET_IF_VAR_H, which HAVE_NETINET6_ND6_H and
 577 dnl HAVE_NETINET_IN_VAR_H depend upon. But if_var.h depends on if.h, hence
 578 dnl an additional round for it.
 579
 580 AC_CHECK_HEADERS([net/if_var.h], [], [], QUAGGA_INCLUDES)
 581
 582 m4_define([QUAGGA_INCLUDES],
 583 QUAGGA_INCLUDES
 584 [#if HAVE_NET_IF_VAR_H
 585 # include <net/if_var.h>
 586 #endif
 587 ])dnl
 588
 589 AC_CHECK_HEADERS([sys/un.h netinet/in_systm.h netinet/in_var.h \
 590         net/if_dl.h net/netopt.h net/route.h \
 591         inet/nd.h arpa/inet.h netinet/ip_icmp.h \
 592         fcntl.h stddef.h sys/ioctl.h syslog.h wchar.h wctype.h \
 593         sys/sysctl.h sys/sockio.h kvm.h sys/conf.h],
 594         [], [], QUAGGA_INCLUDES)
 595
 596 AC_CHECK_HEADERS([ucontext.h], [], [],
 597 [#ifndef __USE_GNU
 598 #define __USE_GNU
 599 #endif /* __USE_GNU */
 600 QUAGGA_INCLUDES
 601 ])
 602
 603 m4_define([UCONTEXT_INCLUDES],
 604 [#include <ucontext.h>])dnl
 605
 606 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.uc_regs],
 607   [], [], [UCONTEXT_INCLUDES])
 608 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs],
 609   [AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs.nip],
 610    [], [], [UCONTEXT_INCLUDES])],
 611   [], [UCONTEXT_INCLUDES])
 612 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.gregs],
 613   [], [], [UCONTEXT_INCLUDES])
 614
 615 m4_define([QUAGGA_INCLUDES],
 616 QUAGGA_INCLUDES
 617 [#if HAVE_SYS_UN_H
 618 # include <sys/un.h>
 619 #endif
 620 #if HAVE_NETINET_IN_SYSTM_H
 621 # include <netinet/in_systm.h>
 622 #endif
 623 #if HAVE_NETINET_IN_VAR_H
 624 # include <netinet/in_var.h>
 625 #endif
 626 #if HAVE_NET_IF_DL_H
 627 # include <net/if_dl.h>
 628 #endif
 629 #if HAVE_NET_NETOPT_H
 630 # include <net/netopt.h>
 631 #endif
 632 #if HAVE_NET_ROUTE_H
 633 # include <net/route.h>
 634 #endif
 635 #if HAVE_INET_ND_H
 636 # include <inet/nd.h>
 637 #endif
 638 #if HAVE_ARPA_INET_H
 639 # include <arpa/inet.h>
 640 #endif
 641 /* Required for IDRP */
 642 #if HAVE_NETINET_IP_ICMP_H
 643 # include <netinet/ip_icmp.h>
 644 #endif
 645 ])dnl
 646
 647 dnl V6 headers are checked below, after we check for v6
 648
 649 dnl Some systems (Solaris 2.x) require libnsl (Network Services Library)
 650 case "$host" in
 651   [*-sunos5.[6-7]*] | [*-solaris2.[6-7]*])
 652       opsys=sol2-6
 653       AC_DEFINE(SUNOS_56, 1, SunOS 5.6 to 5.7)
 654       AC_DEFINE(SUNOS_5, 1, SunOS 5)
 655       AC_CHECK_LIB(xnet, main)
 656       CURSES=-lcurses
 657       SOLARIS="solaris"
 658   ;;
 659   [*-sunos5.[8-9]] \
 660   | [*-sunos5.1[0-9]] \
 661   | [*-sunos5.1[0-9].[0-9]] \
 662   | [*-solaris2.[8-9]] \
 663   | [*-solaris2.1[0-9]] \
 664   | [*-solaris2.1[0-9].[0-9]])
 665       opsys=sol8
 666       AC_DEFINE(SUNOS_59, 1, [SunOS 5.8 up])
 667       AC_DEFINE(SUNOS_5, 1, [SunOS 5])
 668       AC_CHECK_LIB(socket, main)
 669       AC_CHECK_LIB(nsl, main)
 670       AC_CHECK_LIB(umem, main)
 671       AC_CHECK_FUNCS([printstack],
 672         [AC_DEFINE([HAVE_PRINTSTACK],1,[Solaris printstack])
 673          AC_DEFINE([HAVE_STACK_TRACE],1,[Stack symbols decode functionality])
 674         ])
 675       CURSES=-lcurses
 676       SOLARIS="solaris"
 677   ;;
 678   *-sunos5* | *-solaris2*)
 679       AC_DEFINE(SUNOS_5,,SunOS 5, Unknown SunOS)
 680       AC_CHECK_LIB(socket, main)
 681       AC_CHECK_LIB(nsl, main)
 682       CURSES=-lcurses
 683       SOLARIS="solaris"
 684   ;;
 685   *-linux*)
 686       opsys=gnu-linux
 687       AC_DEFINE(GNU_LINUX,,GNU Linux)
 688   ;;
 689   *-openbsd*)
 690       opsys=openbsd
 691       AC_DEFINE(OPEN_BSD,,OpenBSD)
 692   ;;
 693 esac
 694
 695 AC_SYS_LARGEFILE
 696
 697 dnl ---------------------
 698 dnl Integrated VTY option
 699 dnl ---------------------
 700 case "${enable_vtysh}" in
 701   "no") VTYSH="";;
 702   *)    VTYSH="vtysh";
 703          AC_DEFINE(VTYSH,,VTY shell)
 704 dnl      Vtysh uses libreadline, which looks for termcap functions at
 705 dnl      configure time.  We follow readlines search order.
 706 dnl      The required procedures are in libtermcap on NetBSD, in
 707 dnl      [TODO] on Linux, and in [TODO] on Solaris.
 708          AC_CHECK_LIB(termcap, tputs, LIBREADLINE="$LIBREADLINE -ltermcap",
 709            [AC_CHECK_LIB(tinfo, tputs, LIBREADLINE="$LIBREADLINE -ltinfo",
 710              [AC_CHECK_LIB(curses, tputs, LIBREADLINE="$LIBREADLINE -lcurses",
 711                [AC_CHECK_LIB(ncurses, tputs,
 712                              LIBREADLINE="$LIBREADLINE -lncurses")]
 713               )]
 714             )]
 715           )
 716          AC_CHECK_LIB(readline, main, LIBREADLINE="$LIBREADLINE -lreadline",,
 717                       "$LIBREADLINE")
 718          if test $ac_cv_lib_readline_main = no; then
 719            AC_MSG_ERROR([vtysh needs libreadline but was not found and usable on your system.])
 720          fi
 721          AC_CHECK_HEADER(readline/history.h)
 722          if test $ac_cv_header_readline_history_h = no;then
 723            AC_MSG_ERROR([readline is too old to have readline/history.h, please update to the latest readline library.])
 724          fi
 725          AC_CHECK_LIB(readline, rl_completion_matches,
 726                       LIBREADLINE="$LIBREADLINE",, "$LIBREADLINE")
 727          if test $ac_cv_lib_readline_rl_completion_matches = no; then
 728            AC_DEFINE(rl_completion_matches,completion_matches,Old readline)
 729          fi
 730          ;;
 731 esac
 732 AC_SUBST(LIBREADLINE)
 733 AM_CONDITIONAL(VTYSH, test "x$VTYSH" = "xvtysh")
 734
 735 dnl ----------
 736 dnl PAM module
 737 dnl
 738 dnl Quagga detects the PAM library it is built against by checking for a
 739 dnl functional pam_misc.h (Linux-PAM) or openpam.h (OpenPAM) header. pam_misc.h
 740 dnl is known to #include pam_appl.h, the standard header of a PAM library, and
 741 dnl openpam.h doesn't do that, although depends on the header too. Hence a
 742 dnl little assistance to AC_CHECK_HEADER is necessary for the proper detection
 743 dnl of OpenPAM.
 744 dnl ----------
 745 if test "$with_libpam" = "yes"; then
 746   AC_CHECK_HEADER([security/pam_misc.h],
 747     [AC_DEFINE(HAVE_PAM_MISC_H,,Have pam_misc.h)
 748      AC_DEFINE(PAM_CONV_FUNC,misc_conv,Have misc_conv)
 749      pam_conv_func="misc_conv"
 750     ],
 751     [], QUAGGA_INCLUDES)
 752   AC_CHECK_HEADER([security/openpam.h],
 753     [AC_DEFINE(HAVE_OPENPAM_H,,Have openpam.h)
 754      AC_DEFINE(PAM_CONV_FUNC,openpam_ttyconv,Have openpam_ttyconv)
 755      pam_conv_func="openpam_ttyconv"
 756     ],
 757     [], QUAGGA_INCLUDES[#include <security/pam_appl.h>])
 758   if test -z "$ac_cv_header_security_pam_misc_h$ac_cv_header_security_openpam_h" ; then
 759     AC_MSG_WARN([*** pam support will not be built ***])
 760     with_libpam="no"
 761   fi
 762 fi
 763
 764 if test "$with_libpam" = "yes"; then
 765 dnl took this test from proftpds configure.in and suited to our needs
 766 dnl -------------------------------------------------------------------------
 767 dnl
 768 dnl This next check looks funky due to a linker problem with some versions
 769 dnl of the PAM library.  Prior to 0.72 release, the Linux PAM shared library
 770 dnl omitted requiring libdl linking information. PAM-0.72 or better ships
 771 dnl with RedHat 6.2 and Debian 2.2 or better.
 772 AC_CHECK_LIB(pam, pam_start,
 773   [AC_CHECK_LIB(pam, $pam_conv_func,
 774     [AC_DEFINE(USE_PAM,,Use PAM for authentication)
 775      LIBPAM="-lpam"],
 776     [AC_DEFINE(USE_PAM,,Use PAM for authentication)
 777      LIBPAM="-lpam -lpam_misc"]
 778     )
 779   ],
 780
 781   [AC_CHECK_LIB(pam, pam_end,
 782     [AC_CHECK_LIB(pam, $pam_conv_func,
 783       [AC_DEFINE(USE_PAM,,Use PAM for authentication)
 784        LIBPAM="-lpam -ldl"],
 785       [AC_DEFINE(USE_PAM,,Use PAM for authentication)
 786        LIBPAM="-lpam -ldl -lpam_misc"]
 787      )
 788   ],AC_MSG_WARN([*** pam support will not be built ***]),
 789   [-ldl])
 790   ]
 791 )
 792 fi
 793 AC_SUBST(LIBPAM)
 794
 795 dnl -------------------------------
 796 dnl Endian-ness check
 797 dnl -------------------------------
 798 AC_WORDS_BIGENDIAN
 799
 800 dnl -------------------------------
 801 dnl check the size in byte of the C
 802 dnl -------------------------------
 803 dnl AC_CHECK_SIZEOF(char)
 804 dnl AC_CHECK_SIZEOF(int)
 805 dnl AC_CHECK_SIZEOF(short)
 806 dnl AC_CHECK_SIZEOF(long)
 807
 808 dnl ----------------------------
 809 dnl check existance of functions
 810 dnl ----------------------------
 811 AC_FUNC_CHOWN
 812 AC_FUNC_FNMATCH
 813 AC_FUNC_FORK
 814 AC_FUNC_MEMCMP
 815 AC_FUNC_MKTIME
 816 AC_FUNC_STRFTIME
 817 AC_FUNC_STAT
 818 AC_FUNC_SELECT_ARGTYPES
 819 AC_FUNC_STRFTIME
 820 dnl Avoid AC_FUNC_STRNLEN because it pulls in AC_SYSTEM_EXTENSIONS which
 821 dnl can lead to strange side effects.  So we just check for strnlen
 822 dnl directly, see below.
 823 dnl AC_FUNC_STRNLENdnl
 824 AC_FUNC_VPRINTF
 825
 826 dnl -------------------------------
 827 dnl bgpd needs pow() and hence libm
 828 dnl -------------------------------
 829 TMPLIBS="$LIBS"
 830 AC_CHECK_HEADER([math.h],
 831   [AC_CHECK_LIB([m], [pow],
 832     [LIBM="-lm"
 833      LIBS="$LIBS $LIBM"
 834      AC_DEFINE(HAVE_LIBM,, Have libm)
 835      AC_CHECK_FUNCS(pow,[],[LIBM=""])
 836     ])
 837 ])
 838 if test x"$LIBM" = x ; then
 839   AC_MSG_WARN([Unable to find working pow function - bgpd may not link])
 840 fi
 841 LIBS="$TMPLIBS"
 842 AC_SUBST(LIBM)
 843
 844 dnl ---------------
 845 dnl other functions
 846 dnl ---------------
 847 AC_CHECK_FUNCS([dup2 ftruncate getcwd gethostbyname getpagesize gettimeofday \
 848         inet_ntoa inet_aton strnlen \
 849         memchr memmove memset select socket \
 850         strcasecmp strchr strcspn strdup strerror \
 851         strncasecmp strndup strrchr strspn strstr \
 852         strtol strtoul strlcat strlcpy \
 853         daemon snprintf vsnprintf \
 854         if_nametoindex if_indextoname getifaddrs \
 855         uname fcntl getgrouplist])
 856
 857 dnl ------------------------------------
 858 dnl Determine routing get and set method
 859 dnl ------------------------------------
 860 AC_MSG_CHECKING(zebra between kernel interface method)
 861 if test x"$opsys" = x"gnu-linux"; then
 862   AC_MSG_RESULT(netlink)
 863   RT_METHOD=rt_netlink.o
 864   AC_DEFINE(HAVE_NETLINK,,netlink)
 865   netlink=yes
 866   AC_CHECK_DECLS([IFLA_INFO_SLAVE_KIND], [], [], [#include <linux/if_link.h>])
 867 else
 868   AC_MSG_RESULT(Route socket)
 869   KERNEL_METHOD="kernel_socket.o"
 870   RT_METHOD="rt_socket.o"
 871 fi
 872 AC_SUBST(RT_METHOD)
 873 AC_SUBST(KERNEL_METHOD)
 874 AM_CONDITIONAL([HAVE_NETLINK], [test "x$netlink" = "xyes"])
 875
 876 dnl --------------------------
 877 dnl Determine IS-IS I/O method
 878 dnl --------------------------
 879 AC_DEFINE(ISIS_METHOD_PFPACKET, 1, [ constant value for isis method pfpacket ])
 880 AC_DEFINE(ISIS_METHOD_DLPI,     2, [ constant value for isis method dlpi ])
 881 AC_DEFINE(ISIS_METHOD_BPF,      3, [ constant value for isis method bpf ])
 882 AC_CHECK_HEADER(net/bpf.h)
 883 AC_CHECK_HEADER(sys/dlpi.h)
 884 AC_MSG_CHECKING(zebra IS-IS I/O method)
 885 if test x"$opsys" = x"gnu-linux"; then
 886   AC_MSG_RESULT(pfpacket)
 887   ISIS_METHOD_MACRO="ISIS_METHOD_PFPACKET"
 888 elif test x"$opsys" = x"sol2-6" -o x"$opsys" = x"sol8"; then
 889   AC_MSG_RESULT(DLPI)
 890   ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
 891 else
 892   if test $ac_cv_header_net_bpf_h = no; then
 893     if test $ac_cv_header_sys_dlpi_h = no; then
 894       AC_MSG_RESULT(none)
 895       AC_MSG_WARN([*** IS-IS support will not be built ***])
 896       ISISD=""
 897     else
 898       AC_MSG_RESULT(DLPI)
 899     fi
 900     ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
 901   else
 902     AC_MSG_RESULT(BPF)
 903     ISIS_METHOD_MACRO="ISIS_METHOD_BPF"
 904   fi
 905 fi
 906 AC_DEFINE_UNQUOTED(ISIS_METHOD, $ISIS_METHOD_MACRO, [ selected method for isis, == one of the constants ])
 907
 908 dnl ------------------------------------
 909 dnl check for broken CMSG_FIRSTHDR macro
 910 dnl ------------------------------------
 911 AC_MSG_CHECKING(for broken CMSG_FIRSTHDR)
 912 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 913 #ifdef SUNOS_5
 914 #define _XPG4_2
 915 #define __EXTENSIONS__
 916 #endif
 917 #ifdef HAVE_STDLIB_H
 918 # include <stdlib.h>
 919 #endif
 920 #ifdef HAVE_SYS_TYPES_H
 921 #include <sys/types.h>
 922 #endif
 923 #ifdef HAVE_SYS_SOCKET_H
 924 #include <sys/socket.h>
 925 #endif
 926
 927 main()
 928 {
 929   struct msghdr msg;
 930   char buf[4];
 931
 932   msg.msg_control = buf;
 933   msg.msg_controllen = 0;
 934
 935   if (CMSG_FIRSTHDR(&msg) != NULL)
 936     exit(0);
 937   exit (1);
 938 }]])],[AC_MSG_RESULT(yes - using workaround) AC_DEFINE(HAVE_BROKEN_CMSG_FIRSTHDR,,Broken CMSG_FIRSTHDR)],
 939 [AC_MSG_RESULT(no)],[AC_MSG_RESULT(no)])
 940
 941 dnl ------------------------------
 942 dnl check kernel route read method
 943 dnl ------------------------------
 944 AC_CACHE_CHECK([route read method], [quagga_cv_rtread_method],
 945 [if test "x$netlink" = xyes; then
 946   quagga_cv_rtread_method="netlink"
 947 else
 948 for quagga_cv_rtread_method in /dev/ip /dev/null;
 949 do
 950   test x`ls $quagga_cv_rtread_method 2>/dev/null` = x"$quagga_cv_rtread_method" && break
 951 done
 952 case $quagga_cv_rtread_method in
 953   "/dev/ip")
 954                      case "$host" in
 955                        *-freebsd*)    quagga_cv_rtread_method="sysctl";;
 956                        *)             quagga_cv_rtread_method="getmsg";;
 957                      esac;;
 958         *)
 959                      quagga_cv_rtread_method="sysctl";;
 960 esac
 961 fi])
 962 RTREAD_METHOD=rtread_${quagga_cv_rtread_method}.o
 963 AC_SUBST(RTREAD_METHOD)
 964
 965 dnl -----------------------------
 966 dnl check interface lookup method
 967 dnl -----------------------------
 968 IOCTL_METHOD=ioctl.o
 969 AC_MSG_CHECKING(interface looking up method)
 970 if test "$netlink" = yes; then
 971   AC_MSG_RESULT(netlink)
 972   IF_METHOD=if_netlink.o
 973 elif test "$opsys" = "sol2-6";then
 974   AC_MSG_RESULT(Solaris GIF)
 975   IF_METHOD=if_ioctl.o
 976 elif test "$opsys" = "sol8";then
 977   AC_MSG_RESULT(Solaris GLIF)
 978   IF_METHOD=if_ioctl_solaris.o
 979   IOCTL_METHOD=ioctl_solaris.o
 980 elif test "$opsys" = "openbsd";then
 981   AC_MSG_RESULT(openbsd)
 982   IF_METHOD=if_ioctl.o
 983 elif grep NET_RT_IFLIST /usr/include/sys/socket.h >/dev/null 2>&1; then
 984   AC_MSG_RESULT(sysctl)
 985     IF_METHOD=if_sysctl.o
 986     AC_DEFINE(HAVE_NET_RT_IFLIST,,NET_RT_IFLIST)
 987 else
 988     AC_MSG_RESULT(ioctl)
 989     IF_METHOD=if_ioctl.o
 990 fi
 991 AC_SUBST(IF_METHOD)
 992 AC_SUBST(IOCTL_METHOD)
 993
 994 dnl ---------------------------------------------------------------
 995 dnl figure out how to specify an interface in multicast sockets API
 996 dnl ---------------------------------------------------------------
 997 AC_CHECK_MEMBERS([struct ip_mreqn.imr_ifindex], [], [], QUAGGA_INCLUDES)
 998
 999 AC_CHECK_HEADERS([linux/mroute.h], [], [],[
1000         #ifdef HAVE_SYS_SOCKET_H
1001         # include <sys/socket.h>
1002         #endif
1003         #ifdef HAVE_NETINET_IN_H
1004         # include <netinet/in.h>
1005         #endif
1006         #define _LINUX_IN_H             /* For Linux <= 2.6.25 */
1007         #include <linux/types.h>
1008 ])
1009
1010 m4_define([QUAGGA_INCLUDES],
1011 QUAGGA_INCLUDES
1012 [#if HAVE_LINUX_MROUTE_H
1013 # include <linux/mroute.h>
1014 #endif
1015 ])dnl
1016
1017 AC_CHECK_HEADERS([netinet/ip_mroute.h], [], [],[
1018         #ifdef HAVE_SYS_SOCKET_H
1019         # include <sys/socket.h>
1020         #endif
1021         #ifdef HAVE_SYS_TYPES_H
1022         # include <sys/types.h>
1023         #endif
1024         #ifdef HAVE_NETINET_IN_H
1025         # include <netinet/in.h>
1026         #endif
1027         #ifdef HAVE_NET_ROUTE_H
1028         # include <net/route.h>
1029         #endif
1030 ])
1031
1032 m4_define([QUAGGA_INCLUDES],
1033 QUAGGA_INCLUDES
1034 [#if HAVE_NETINET_IP_MROUTE_H
1035 # include <netinet/ip_mroute.h>
1036 #endif
1037 ])dnl
1038
1039 AC_MSG_CHECKING([for BSD struct ip_mreq hack])
1040 AC_TRY_COMPILE([#ifdef HAVE_SYS_PARAM_H
1041 #include <sys/param.h>
1042 #endif],[#if (defined(__FreeBSD__) && ((__FreeBSD_version >= 500022 && __FreeBSD_version < 700000) || (__FreeBSD_version < 500000 && __FreeBSD_version >= 440000))) || (defined(__NetBSD__) && defined(__NetBSD_Version__) && __NetBSD_Version__ >= 106010000) || defined(__OpenBSD__) || defined(__APPLE__) || defined(__DragonFly__) || defined(__sun)
1043   return (0);
1044 #else
1045   #error No support for BSD struct ip_mreq hack detected
1046 #endif],[AC_MSG_RESULT(yes)
1047 AC_DEFINE(HAVE_BSD_STRUCT_IP_MREQ_HACK,,[Can pass ifindex in struct ip_mreq])],
1048 AC_MSG_RESULT(no))
1049
1050 AC_MSG_CHECKING([for RFC3678 protocol-independed API])
1051 AC_TRY_COMPILE([
1052 #include <sys/types.h>
1053 #include <netinet/in.h>
1054 ], [struct group_req gr; int sock; setsockopt(sock, IPPROTO_IP, MCAST_JOIN_GROUP, (void*)&gr, sizeof(gr));
1055 ], [AC_MSG_RESULT(yes)
1056 AC_DEFINE(HAVE_RFC3678,1,[Have RFC3678 protocol-independed API])],
1057 AC_MSG_RESULT(no))
1058
1059 dnl ---------------------------------------------------------------
1060 dnl figure out how to check link-state
1061 dnl ---------------------------------------------------------------
1062 AC_CHECK_HEADER([net/if.h],
1063   [AC_CHECK_HEADER( [net/if_media.h],
1064     [m4_define([LINK_DETECT_INCLUDES],
1065       QUAGGA_INCLUDES
1066       [#include <net/if_media.h>
1067     ])
1068     AC_CHECK_MEMBERS( [struct ifmediareq.ifm_status],
1069       AC_DEFINE(HAVE_BSD_LINK_DETECT,,[BSD link-detect]),
1070       [], LINK_DETECT_INCLUDES)],
1071     [],
1072     QUAGGA_INCLUDES)],
1073   [], QUAGGA_INCLUDES )
1074
1075 dnl ---------------------------------------------------------------
1076 dnl Additional, newer way to check link-state using ifi_link_state.
1077 dnl Not available in all BSD's when ifmediareq available
1078 dnl ---------------------------------------------------------------
1079 AC_CHECK_HEADER([net/if.h],
1080     AC_CHECK_MEMBERS([struct if_data.ifi_link_state],
1081       AC_DEFINE(HAVE_BSD_IFI_LINK_STATE,,[BSD ifi_link_state available]),
1082       [], QUAGGA_INCLUDES),
1083     ,)
1084
1085 dnl ------------------------
1086 dnl TCP_MD5SIG socket option
1087 dnl ------------------------
1088
1089 AC_CHECK_HEADER([netinet/tcp.h],
1090    [m4_define([MD5_INCLUDES],
1091       QUAGGA_INCLUDES
1092       [#include <netinet/tcp.h>
1093     ])
1094     AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)],
1095    [],
1096    QUAGGA_INCLUDES)
1097 if test $ac_cv_have_decl_TCP_MD5SIG = no; then
1098   AC_CHECK_HEADER([linux/tcp.h],
1099        [m4_define([MD5_INCLUDES],
1100           QUAGGA_INCLUDES
1101           [#include <linux/tcp.h>
1102         ])
1103        AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)])
1104 fi
1105
1106 dnl -----------------------------
1107 dnl check ipforward detect method
1108 dnl -----------------------------
1109 AC_CACHE_CHECK([ipforward method], [quagga_cv_ipforward_method],
1110 [if test x$cross_compiling = xyes; then
1111   if test x"$opsys" = x"gnu-linux"; then
1112     quagga_cv_ipforward_method=/proc/net/snmp
1113   else
1114     quagga_cv_ipforward_method=/dev/ip
1115   fi
1116 else
1117   for quagga_cv_ipforward_method in /proc/net/snmp /dev/ip /dev/null;
1118   do
1119     test x`ls $quagga_cv_ipforward_method 2>/dev/null` = x"$quagga_cv_ipforward_method" && break
1120   done
1121 fi
1122 case $quagga_cv_ipforward_method in
1123   "/proc/net/snmp")  quagga_cv_ipforward_method="proc";;
1124   "/dev/ip")
1125                      case "$host" in
1126                        *-freebsd*)    quagga_cv_ipforward_method="sysctl";;
1127                        *)             quagga_cv_ipforward_method="solaris";;
1128                      esac;;
1129   *)                 quagga_cv_ipforward_method="sysctl";;
1130 esac])
1131 IPFORWARD=ipforward_${quagga_cv_ipforward_method}.o
1132 AC_SUBST(IPFORWARD)
1133
1134 AC_CHECK_FUNCS(getaddrinfo, [have_getaddrinfo=yes], [have_getaddrinfo=no])
1135
1136 dnl ----------------------------------------------------------------------------
1137 dnl figure out if domainname is available in the utsname struct (GNU extension).
1138 dnl ----------------------------------------------------------------------------
1139 AC_CHECK_MEMBERS([struct utsname.domainname], [], [], [#include <sys/utsname.h>])
1140
1141 dnl ----------
1142 dnl IPv6 check
1143 dnl ----------
1144 AC_MSG_CHECKING(whether does this OS have IPv6 stack)
1145 dnl ---------
1146 dnl KAME IPv6
1147 dnl ---------
1148   if grep WIDE /usr/include/netinet6/in6.h >/dev/null 2>&1; then
1149     AC_DEFINE(KAME,1,KAME IPv6)
1150     AC_MSG_RESULT(KAME)
1151 dnl ------------------------------------
1152 dnl Solaris 9, 10 and potentially higher
1153 dnl ------------------------------------
1154   elif test x"$opsys" = x"sol8"; then
1155     AC_DEFINE(SOLARIS_IPV6, 1, Solaris IPv6)
1156     AC_MSG_RESULT(Solaris IPv6)
1157 dnl ----------
1158 dnl Linux IPv6
1159 dnl ----------
1160   elif test x"$opsys" = x"gnu-linux"; then
1161     AC_DEFINE(LINUX_IPV6,1,Linux IPv6 stack)
1162     dnl Linux has a compilation problem with mixing
1163     dnl netinet/in.h and linux/in6.h they are not
1164     dnl compatible.  There has been discussion on
1165     dnl how to fix it but no real progress on implementation
1166     dnl when they fix it, remove this
1167     AC_DEFINE(IPV6_MINHOPCOUNT, 73, Linux ipv6 Min Hop Count)
1168     AC_MSG_RESULT(Linux IPv6)
1169   else
1170     AC_MSG_ERROR([Failed to detect IPv6 stack])
1171   fi
1172
1173 dnl this is unconditial, for compatibility
1174 AC_DEFINE(HAVE_IPV6,1,IPv6)
1175
1176 dnl ------------------
1177 dnl IPv6 header checks
1178 dnl ------------------
1179 AC_CHECK_HEADERS([netinet6/in6.h netinet/in6_var.h netinet/icmp6.h \
1180         netinet6/in6_var.h netinet6/nd6.h], [], [],
1181         QUAGGA_INCLUDES)
1182
1183 m4_define([QUAGGA_INCLUDES],dnl
1184 QUAGGA_INCLUDES
1185 [#if HAVE_NETINET6_IN6_H
1186 #include <netinet6/in6.h>
1187 #endif
1188 #if HAVE_NETINET_IN6_VAR_H
1189 #include <netinet/in6_var.h>
1190 #endif
1191 #if HAVE_NETINET_ICMP6_H
1192 # include <netinet/icmp6.h>
1193 #endif
1194 #if HAVE_NETINET6_IN6_VAR_H
1195 # include <netinet6/in6_var.h>
1196 #endif
1197 #if HAVE_NETINET6_ND6_H
1198 # include <netinet6/nd6.h>
1199 #endif
1200 ])dnl
1201
1202 dnl disable doc check
1203 if test "${enable_doc}" = "no";then
1204   DOC=""
1205 else
1206   DOC="doc"
1207 fi
1208
1209 dnl --------------------
1210 dnl Daemon disable check
1211 dnl --------------------
1212 if test "${enable_zebra}" = "no";then
1213   ZEBRA=""
1214 else
1215   ZEBRA="zebra"
1216 fi
1217 AM_CONDITIONAL(ZEBRA, test "x$ZEBRA" = "xzebra")
1218
1219 if test "${enable_bgpd}" = "no";then
1220   BGPD=""
1221 else
1222   BGPD="bgpd"
1223 fi
1224 AM_CONDITIONAL(BGPD, test "x$BGPD" = "xbgpd")
1225
1226 if test "${enable_ripd}" = "no";then
1227   RIPD=""
1228 else
1229   RIPD="ripd"
1230 fi
1231 AM_CONDITIONAL(RIPD, test "x$RIPD" = "xripd")
1232
1233 if test "${enable_ospfd}" = "no";then
1234   OSPFD=""
1235 else
1236   OSPFD="ospfd"
1237 fi
1238 AM_CONDITIONAL(OSPFD, test "x$OSPFD" = "xospfd")
1239
1240 if test "${enable_watchquagga}" = "no";then
1241   WATCHQUAGGA=""
1242 else
1243   WATCHQUAGGA="watchquagga"
1244 fi
1245 AM_CONDITIONAL(WATCHQUAGGA, test "x$WATCHQUAGGA" = "xwatchquagga")
1246
1247 OSPFCLIENT=""
1248 if test "${enable_opaque_lsa}" != "no"; then
1249   if test "${enable_ospfapi}" != "no";then
1250     AC_DEFINE(SUPPORT_OSPF_API,,OSPFAPI)
1251
1252     if test "${enable_ospfclient}" != "no";then
1253       OSPFCLIENT="ospfclient"
1254     fi
1255   fi
1256
1257 fi
1258 AM_CONDITIONAL(OSPFCLIENT, test "x$OSPFCLIENT" = "xospfclient")
1259
1260 case "${enable_ripngd}" in
1261   "no" ) RIPNGD="";;
1262   *    ) RIPNGD="ripngd";;
1263 esac
1264 AM_CONDITIONAL(RIPNGD, test "x$RIPNGD" = "xripngd")
1265
1266 case "${enable_ospf6d}" in
1267   "no" ) OSPF6D="";;
1268   *    ) OSPF6D="ospf6d";;
1269 esac
1270 AM_CONDITIONAL(OSPF6D, test "x$OSPF6D" = "xospf6d")
1271
1272 case "${enable_isisd}" in
1273   "no" ) ISISD="";;
1274   *    ) ISISD="isisd";;
1275 esac
1276 AM_CONDITIONAL(ISISD, test "x$ISISD" = "xisisd")
1277
1278 case "${enable_pimd}" in
1279   "no" ) PIMD="";;
1280   *    ) PIMD="pimd";;
1281 esac
1282 AM_CONDITIONAL(PIMD, test "x$PIMD" = "xpimd")
1283
1284 if test "${enable_bgp_announce}" = "no";then
1285   AC_DEFINE(DISABLE_BGP_ANNOUNCE,1,Disable BGP installation to zebra)
1286 else
1287   AC_DEFINE(DISABLE_BGP_ANNOUNCE,0,Disable BGP installation to zebra)
1288 fi
1289
1290 AC_SUBST(DOC)
1291 AC_SUBST(ZEBRA)
1292 AC_SUBST(BGPD)
1293 AC_SUBST(RIPD)
1294 AC_SUBST(RIPNGD)
1295 AC_SUBST(OSPFD)
1296 AC_SUBST(OSPF6D)
1297 AC_SUBST(WATCHQUAGGA)
1298 AC_SUBST(ISISD)
1299 AC_SUBST(PIMD)
1300 AC_SUBST(SOLARIS)
1301 AC_SUBST(VTYSH)
1302 AC_SUBST(CURSES)
1303 AC_SUBST(OSPFCLIENT)
1304 AC_SUBST(OSPFAPI)
1305 AC_CHECK_LIB(c, inet_ntop, [AC_DEFINE(HAVE_INET_NTOP,,inet_ntop)])
1306 AC_CHECK_LIB(c, inet_pton, [AC_DEFINE(HAVE_INET_PTON,,inet_pton)])
1307 AC_CHECK_LIB(crypt, crypt)
1308 AC_CHECK_LIB(resolv, res_init)
1309
1310 dnl ---------------------------
1311 dnl check system has PCRE regexp
1312 dnl ---------------------------
1313 if test "x$enable_pcreposix" = "xyes"; then
1314   AC_CHECK_LIB(pcreposix, pcreposix_regexec, ,[enable_pcreposix=no
1315   AC_MSG_WARN([*** falling back to other regex library ***]) ])
1316 fi
1317
1318 if test "x$enable_pcreposix" != "xyes"; then
1319 dnl ---------------------------
1320 dnl check system has GNU regexp
1321 dnl ---------------------------
1322 AC_MSG_CHECKING(whether system has GNU regex)
1323 AC_CHECK_LIB(c, regexec,
1324 [AC_DEFINE(HAVE_GNU_REGEX,,GNU regexp library)
1325  LIB_REGEX=""],
1326 [LIB_REGEX="regex.o"])
1327 fi
1328 AC_SUBST(HAVE_LIBPCREPOSIX)
1329 AC_SUBST(LIB_REGEX)
1330
1331 dnl ------------------
1332 dnl check Net-SNMP library
1333 dnl ------------------
1334 if test "${enable_snmp}" != ""; then
1335    AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], [no])
1336    if test x"$NETSNMP_CONFIG" = x"no"; then
1337       AC_MSG_ERROR([--enable-snmp given but unable to find net-snmp-config])
1338    fi
1339    LIBS="$LIBS `${NETSNMP_CONFIG} --agent-libs`"
1340    CFLAGS="`${NETSNMP_CONFIG} --base-cflags` $CFLAGS"
1341    AC_MSG_CHECKING([whether we can link to Net-SNMP])
1342    AC_LINK_IFELSE([AC_LANG_PROGRAM([
1343 int main(void);
1344 ],
1345 [
1346 {
1347   return 0;
1348 }
1349 ])],[AC_MSG_RESULT(yes)],[
1350      AC_MSG_RESULT(no)
1351      AC_MSG_ERROR([--enable-snmp given but not usable])])
1352    AC_DEFINE(HAVE_SNMP,,SNMP)
1353    case "${enable_snmp}" in
1354      yes)
1355       SNMP_METHOD=agentx
1356       ;;
1357      smux|agentx)
1358       SNMP_METHOD="${enable_snmp}"
1359       ;;
1360      *)
1361       AC_MSG_ERROR([--enable-snmp given with an unknown method (${enable_snmp}). Use smux or agentx])
1362       ;;
1363    esac
1364    AH_TEMPLATE([SNMP_SMUX], [Use SNMP SMUX to interface with snmpd])
1365    AH_TEMPLATE([SNMP_AGENTX], [Use SNMP AgentX to interface with snmpd])
1366    AC_DEFINE_UNQUOTED(AS_TR_CPP(SNMP_${SNMP_METHOD}),,SNMP method to interface with snmpd)
1367 fi
1368
1369 dnl ---------------------------
1370 dnl sockaddr and netinet checks
1371 dnl ---------------------------
1372 AC_CHECK_TYPES([struct sockaddr, struct sockaddr_in,
1373         struct sockaddr_in6, struct sockaddr_un, struct sockaddr_dl,
1374         socklen_t, struct vifctl, struct mfcctl, struct sioc_sg_req,
1375         vifi_t, struct sioc_vif_req, struct igmpmsg,
1376         struct ifaliasreq, struct if6_aliasreq, struct in6_aliasreq,
1377         struct nd_opt_adv_interval, struct rt_addrinfo,
1378         struct nd_opt_homeagent_info, struct nd_opt_adv_interval],
1379         [], [], QUAGGA_INCLUDES)
1380
1381 AC_CHECK_MEMBERS([struct sockaddr.sa_len,
1382         struct sockaddr_in.sin_len, struct sockaddr_un.sun_len,
1383         struct sockaddr_in6.sin6_scope_id,
1384         struct sockaddr_dl.sdl_len,
1385         struct if6_aliasreq.ifra_lifetime,
1386         struct nd_opt_adv_interval.nd_opt_ai_type],
1387         [], [], QUAGGA_INCLUDES)
1388
1389 dnl ---------------------------
1390 dnl IRDP/pktinfo/icmphdr checks
1391 dnl ---------------------------
1392 AC_CHECK_TYPES([struct in_pktinfo],
1393  [AC_CHECK_TYPES([struct icmphdr],
1394    [if test "${enable_irdp}" != "no"; then
1395       AC_DEFINE(HAVE_IRDP,, IRDP)
1396     fi],
1397    [if test "${enable_irdp}" = "yes"; then
1398       AC_MSG_ERROR(['IRDP requires in_pktinfo at the moment!'])
1399     fi], [QUAGGA_INCLUDES])],
1400  [if test "${enable_irdp}" = "yes"; then
1401     AC_MSG_ERROR(['IRDP requires in_pktinfo at the moment!'])
1402   fi], [QUAGGA_INCLUDES])
1403
1404 dnl -----------------------
1405 dnl checking for IP_PKTINFO
1406 dnl -----------------------
1407 AC_MSG_CHECKING(for IP_PKTINFO)
1408 AC_TRY_COMPILE([#include <netdb.h>], [
1409   int opt = IP_PKTINFO;
1410 ], [
1411   AC_MSG_RESULT(yes)
1412   AC_DEFINE(HAVE_IP_PKTINFO, 1, [Have IP_PKTINFO])
1413 ], [
1414   AC_MSG_RESULT(no)
1415 ])
1416
1417 dnl ---------------------------
1418 dnl checking for IP_RECVDSTADDR
1419 dnl ---------------------------
1420 AC_MSG_CHECKING(for IP_RECVDSTADDR)
1421 AC_TRY_COMPILE([#include <netinet/in.h>], [
1422   int opt = IP_RECVDSTADDR;
1423 ], [
1424   AC_MSG_RESULT(yes)
1425   AC_DEFINE(HAVE_IP_RECVDSTADDR, 1, [Have IP_RECVDSTADDR])
1426 ], [
1427   AC_MSG_RESULT(no)
1428 ])
1429
1430 dnl ----------------------
1431 dnl checking for IP_RECVIF
1432 dnl ----------------------
1433 AC_MSG_CHECKING(for IP_RECVIF)
1434 AC_TRY_COMPILE([#include <netinet/in.h>], [
1435   int opt = IP_RECVIF;
1436 ], [
1437   AC_MSG_RESULT(yes)
1438   AC_DEFINE(HAVE_IP_RECVIF, 1, [Have IP_RECVIF])
1439 ], [
1440   AC_MSG_RESULT(no)
1441 ])
1442
1443 dnl --------------------------------------
1444 dnl checking for getrusage struct and call
1445 dnl --------------------------------------
1446 if test "${enable_rusage}" != "no"; then
1447   AC_MSG_CHECKING(whether getrusage is available)
1448   AC_TRY_COMPILE([#include <sys/resource.h>],[struct rusage ac_x; getrusage (RUSAGE_SELF, &ac_x);],
1449     [AC_MSG_RESULT(yes)
1450      AC_DEFINE(HAVE_RUSAGE,,rusage)],
1451       AC_MSG_RESULT(no))
1452 fi
1453
1454 dnl --------------------------------------
1455 dnl checking for clock_time monotonic struct and call
1456 dnl --------------------------------------
1457 AC_CHECK_DECL(CLOCK_MONOTONIC,
1458         [AC_CHECK_LIB(rt, clock_gettime, [LIBS="$LIBS -lrt"])
1459          AC_DEFINE(HAVE_CLOCK_MONOTONIC,, Have monotonic clock)
1460 ], [AC_MSG_RESULT(no)], [QUAGGA_INCLUDES])
1461
1462 dnl -------------------
1463 dnl capabilities checks
1464 dnl -------------------
1465 if test "${enable_capabilities}" != "no"; then
1466   AC_MSG_CHECKING(whether prctl PR_SET_KEEPCAPS is available)
1467   AC_TRY_COMPILE([#include <sys/prctl.h>],[prctl(PR_SET_KEEPCAPS, 1, 0, 0, 0);],
1468     [AC_MSG_RESULT(yes)
1469      AC_DEFINE(HAVE_PR_SET_KEEPCAPS,,prctl)
1470      quagga_ac_keepcaps="yes"],
1471      AC_MSG_RESULT(no)
1472   )
1473   if test x"${quagga_ac_keepcaps}" = x"yes"; then
1474     AC_CHECK_HEADERS(sys/capability.h)
1475   fi
1476   if test x"${ac_cv_header_sys_capability_h}" = x"yes"; then
1477     AC_CHECK_LIB(cap, cap_init,
1478       [AC_DEFINE(HAVE_LCAPS,1,Capabilities)
1479        LIBCAP="-lcap"
1480        quagga_ac_lcaps="yes"]
1481     )
1482   else
1483     AC_CHECK_HEADERS(priv.h,
1484      [AC_MSG_CHECKING(Solaris style privileges are available)
1485       AC_TRY_COMPILE([#include <priv.h>],[getpflags(PRIV_AWARE);],
1486           [AC_MSG_RESULT(yes)
1487            AC_DEFINE(HAVE_SOLARIS_CAPABILITIES,1,getpflags)
1488            quagga_ac_scaps="yes"],
1489            AC_MSG_RESULT(no)
1490       )
1491      ]
1492    )
1493   fi
1494   if test x"${quagga_ac_scaps}" = x"yes" \
1495        -o x"${quagga_ac_lcaps}" = x"yes"; then
1496     AC_DEFINE(HAVE_CAPABILITIES,1,capabilities)
1497   fi
1498 fi
1499 AC_SUBST(LIBCAP)
1500
1501 dnl ---------------------------
1502 dnl check for glibc 'backtrace'
1503 dnl ---------------------------
1504 if test x"${enable_backtrace}" != x"no" ; then
1505   backtrace_ok=no
1506   AC_CHECK_HEADER([execinfo.h], [
1507     AC_SEARCH_LIBS([backtrace], [execinfo], [
1508       AC_DEFINE(HAVE_GLIBC_BACKTRACE,,[Glibc backtrace])
1509       AC_DEFINE(HAVE_STACK_TRACE,,[Stack symbol decoding])
1510       backtrace_ok=yes
1511     ],, [-lm])
1512   ])
1513
1514   if test x"${enable_backtrace}" = x"yes" -a x"${backtrace_ok}" = x"no"; then
1515     dnl user explicitly requested backtrace but we failed to find support
1516     AC_MSG_FAILURE([failed to find backtrace support])
1517   fi
1518 fi
1519
1520 dnl -----------------------------------------
1521 dnl check for malloc mallinfo struct and call
1522 dnl this must try and link using LIBS, in
1523 dnl order to check no alternative allocator
1524 dnl has been specified, which might not provide
1525 dnl mallinfo, e.g. such as Umem on Solaris.
1526 dnl -----------------------------------------
1527 AC_CHECK_HEADER([malloc.h],
1528  [AC_MSG_CHECKING(whether mallinfo is available)
1529   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <malloc.h>]],
1530                         [[struct mallinfo ac_x; ac_x = mallinfo ();]])],
1531       [AC_MSG_RESULT(yes)
1532        AC_DEFINE(HAVE_MALLINFO,,mallinfo)],
1533        AC_MSG_RESULT(no)
1534   )
1535  ], [], QUAGGA_INCLUDES)
1536
1537 dnl ----------
1538 dnl configure date
1539 dnl ----------
1540 CONFDATE=`date '+%Y%m%d'`
1541 AC_SUBST(CONFDATE)
1542
1543 dnl -------
1544 dnl DejaGNU
1545 dnl -------
1546 if test x"$DEJAGNU" = x
1547 then
1548   DEJAGNU="\$(top_srcdir)/tests/global-conf.exp"
1549 fi
1550 RUNTESTDEFAULTFLAGS="-x --tool \$\$tool"
1551
1552 AC_SUBST(DEJAGNU)
1553 AC_SUBST(RUNTESTDEFAULTFLAGS)
1554
1555 dnl ------------------------------
1556 dnl set paths for state directory
1557 dnl ------------------------------
1558 AC_MSG_CHECKING(directory to use for state file)
1559 if test "${prefix}" = "NONE"; then
1560   quagga_statedir_prefix="";
1561 else
1562   quagga_statedir_prefix=${prefix}
1563 fi
1564 if test "${localstatedir}" = '${prefix}/var'; then
1565   for QUAGGA_STATE_DIR in ${quagga_statedir_prefix}/var/run dnl
1566                         ${quagga_statedir_prefix}/var/adm dnl
1567                         ${quagga_statedir_prefix}/etc dnl
1568                         /var/run        dnl
1569                         /var/adm        dnl
1570                         /etc            dnl
1571                         /dev/null;
1572   do
1573     test -d $QUAGGA_STATE_DIR && break
1574   done
1575   quagga_statedir=$QUAGGA_STATE_DIR
1576 else
1577   quagga_statedir=${localstatedir}
1578 fi
1579 if test $quagga_statedir = "/dev/null"; then
1580     AC_MSG_ERROR('STATE DIRECTORY NOT FOUND! FIX OR SPECIFY --localstatedir!')
1581 fi
1582 AC_MSG_RESULT(${quagga_statedir})
1583 AC_SUBST(quagga_statedir)
1584
1585 AC_DEFINE_UNQUOTED(PATH_ZEBRA_PID, "$quagga_statedir/zebra.pid",zebra PID)
1586 AC_DEFINE_UNQUOTED(PATH_RIPD_PID, "$quagga_statedir/ripd.pid",ripd PID)
1587 AC_DEFINE_UNQUOTED(PATH_RIPNGD_PID, "$quagga_statedir/ripngd.pid",ripngd PID)
1588 AC_DEFINE_UNQUOTED(PATH_BGPD_PID, "$quagga_statedir/bgpd.pid",bgpd PID)
1589 AC_DEFINE_UNQUOTED(PATH_OSPFD_PID, "$quagga_statedir/ospfd.pid",ospfd PID)
1590 AC_DEFINE_UNQUOTED(PATH_OSPF6D_PID, "$quagga_statedir/ospf6d.pid",ospf6d PID)
1591 AC_DEFINE_UNQUOTED(PATH_ISISD_PID, "$quagga_statedir/isisd.pid",isisd PID)
1592 AC_DEFINE_UNQUOTED(PATH_PIMD_PID, "$quagga_statedir/pimd.pid",pimd PID)
1593 AC_DEFINE_UNQUOTED(PATH_WATCHQUAGGA_PID, "$quagga_statedir/watchquagga.pid",watchquagga PID)
1594 AC_DEFINE_UNQUOTED(ZEBRA_SERV_PATH, "$quagga_statedir/zserv.api",zebra api socket)
1595 AC_DEFINE_UNQUOTED(ZEBRA_VTYSH_PATH, "$quagga_statedir/zebra.vty",zebra vty socket)
1596 AC_DEFINE_UNQUOTED(RIP_VTYSH_PATH, "$quagga_statedir/ripd.vty",rip vty socket)
1597 AC_DEFINE_UNQUOTED(RIPNG_VTYSH_PATH, "$quagga_statedir/ripngd.vty",ripng vty socket)
1598 AC_DEFINE_UNQUOTED(BGP_VTYSH_PATH, "$quagga_statedir/bgpd.vty",bgpd vty socket)
1599 AC_DEFINE_UNQUOTED(OSPF_VTYSH_PATH, "$quagga_statedir/ospfd.vty",ospfd vty socket)
1600 AC_DEFINE_UNQUOTED(OSPF6_VTYSH_PATH, "$quagga_statedir/ospf6d.vty",ospf6d vty socket)
1601 AC_DEFINE_UNQUOTED(ISIS_VTYSH_PATH, "$quagga_statedir/isisd.vty",isisd vty socket)
1602 AC_DEFINE_UNQUOTED(PIM_VTYSH_PATH, "$quagga_statedir/pimd.vty",pimd vty socket)
1603 AC_DEFINE_UNQUOTED(DAEMON_VTY_DIR, "$quagga_statedir",daemon vty directory)
1604
1605 dnl -------------------------------
1606 dnl Quagga sources should always be
1607 dnl current wrt interfaces. Dont
1608 dnl allow deprecated interfaces to
1609 dnl be exposed.
1610 dnl -------------------------------
1611 AC_DEFINE(QUAGGA_NO_DEPRECATED_INTERFACES, 1, Hide deprecated interfaces)
1612
1613 dnl ---------------------------
1614 dnl Check htonl works correctly
1615 dnl ---------------------------
1616 AC_MSG_CHECKING(for working htonl)
1617 AC_CACHE_VAL(ac_cv_htonl_works,
1618  [AC_LINK_IFELSE([AC_LANG_PROGRAM([QUAGGA_INCLUDES],[htonl (0);])],
1619                 [ac_cv_htonl_works=yes], [ac_cv_htonl_works=no])
1620  ]
1621 )
1622 AC_MSG_RESULT($ac_cv_htonl_works)
1623
1624 AC_CONFIG_FILES([Makefile lib/Makefile zebra/Makefile ripd/Makefile
1625           ripngd/Makefile bgpd/Makefile ospfd/Makefile watchquagga/Makefile
1626           ospf6d/Makefile isisd/Makefile vtysh/Makefile
1627           doc/Makefile ospfclient/Makefile tests/Makefile m4/Makefile
1628           pimd/Makefile
1629           tests/bgpd.tests/Makefile
1630           tests/libzebra.tests/Makefile
1631           redhat/Makefile
1632           tools/Makefile
1633           cumulus/Makefile
1634           pkgsrc/Makefile
1635           redhat/quagga.spec
1636           lib/version.h
1637           doc/defines.texi
1638           isisd/topology/Makefile
1639           pkgsrc/bgpd.sh pkgsrc/ospf6d.sh pkgsrc/ospfd.sh
1640           pkgsrc/ripd.sh pkgsrc/ripngd.sh pkgsrc/zebra.sh])
1641 AC_CONFIG_FILES([solaris/Makefile])
1642
1643 AC_CONFIG_FILES([vtysh/extract.pl],[chmod +x vtysh/extract.pl])
1644 ## Hack, but working solution to avoid rebuilding of quagga.info.
1645 ## It's already in CVS until texinfo 4.7 is more common.
1646 AC_OUTPUT
1647
1648 echo "
1649 Quagga configuration
1650 --------------------
1651 quagga version          : ${PACKAGE_VERSION}
1652 host operating system   : ${host_os}
1653 source code location    : ${srcdir}
1654 compiler                : ${CC}
1655 compiler flags          : ${CFLAGS}
1656 make                    : ${MAKE-make}
1657 linker flags            : ${LDFLAGS} ${LIBS} ${LIBCAP} ${LIBREADLINE} ${LIBM}
1658 state file directory    : ${quagga_statedir}
1659 config file directory   : `eval echo \`echo ${sysconfdir}\``
1660 example directory       : `eval echo \`echo ${exampledir}\``
1661 user to run as          : ${enable_user}
1662 group to run as         : ${enable_group}
1663 group for vty sockets   : ${enable_vty_group}
1664 config file mask        : ${enable_configfile_mask}
1665 log file mask           : ${enable_logfile_mask}
1666
1667 The above user and group must have read/write access to the state file
1668 directory and to the config files in the config file directory."
1669
1670 if test x"$quagga_cv_gnu_make" = x"no"; then echo "
1671 Warning: The ${MAKE-make} programme detected, either in your path or
1672 via the MAKE variable, is not GNU Make. GNU make may be installed as
1673 gmake on some systems. and is required to complete a build of Quagga
1674 " > /dev/stderr
1675 fi