configure.ac

   1 ##
   2 ## Configure template file for FRRouting.
   3 ## autoconf will generate configure script.
   4 ##
   5 ##  Copyright (c) 1996, 97, 98, 99, 2000 Kunihiro Ishiguro <kunihiro@zebra.org>
   6 ##  Portions Copyright (c) 2003 Paul Jakma <paul@dishone.st>
   7 ##
   8 AC_PREREQ(2.60)
   9
  10 AC_INIT(frr, 5.1-dev, [https://github.com/frrouting/frr/issues])
  11 PACKAGE_URL="https://frrouting.org/"
  12 AC_SUBST(PACKAGE_URL)
  13 PACKAGE_FULLNAME="FRRouting"
  14 AC_SUBST(PACKAGE_FULLNAME)
  15
  16 CONFIG_ARGS="$ac_configure_args"
  17 AC_SUBST(CONFIG_ARGS)
  18
  19 AC_CONFIG_SRCDIR(lib/zebra.h)
  20 AC_CONFIG_MACRO_DIR([m4])
  21
  22 dnl -----------------------------------
  23 dnl Get hostname and other information.
  24 dnl -----------------------------------
  25 AC_CANONICAL_BUILD()
  26 AC_CANONICAL_HOST()
  27
  28 AS_IF([test "$host" != "$build"], [
  29   if test "$srcdir" = "."; then
  30     AC_MSG_ERROR([cross-compilation is only possible with builddir separate from srcdir.  create a separate directory and run as .../path-to-frr/configure.])
  31   fi
  32   test -d hosttools || mkdir hosttools
  33   abssrc="`cd \"${srcdir}\"; pwd`"
  34
  35   AC_MSG_NOTICE([...])
  36   AC_MSG_NOTICE([... cross-compilation: creating hosttools directory and self-configuring for build platform tools])
  37   AC_MSG_NOTICE([... use HOST_CPPFLAGS / HOST_CFLAGS / HOST_LDFLAGS if neccessary])
  38   AC_MSG_NOTICE([...])
  39
  40   ( CPPFLAGS="$HOST_CPPFLAGS"; \
  41     CFLAGS="$HOST_CFLAGS"; \
  42     LDFLAGS="$HOST_LDFLAGS"; \
  43     cd hosttools; "${abssrc}/configure" "--host=$build" "--build=$build" "--enable-clippy-only" "--disable-nhrpd" "--disable-vtysh"; )
  44
  45   AC_MSG_NOTICE([...])
  46   AC_MSG_NOTICE([... cross-compilation: finished self-configuring for build platform tools])
  47   AC_MSG_NOTICE([...])
  48
  49   build_clippy="false"
  50   HOSTTOOLS="hosttools/"
  51 ], [
  52   build_clippy="true"
  53   HOSTTOOLS=""
  54 ])
  55 AC_SUBST(HOSTTOOLS)
  56 AM_CONDITIONAL([BUILD_CLIPPY], [$build_clippy])
  57
  58 # Disable portability warnings -- our automake code (in particular
  59 # common.am) uses some constructs specific to gmake.
  60 AM_INIT_AUTOMAKE([1.12 -Wno-portability])
  61 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
  62 AM_SILENT_RULES([yes])
  63 AC_CONFIG_HEADERS(config.h)
  64
  65 AC_PATH_PROG(PERL, perl)
  66 PKG_PROG_PKG_CONFIG
  67
  68 dnl default is to match previous behavior
  69 exampledir=${sysconfdir}
  70 AC_ARG_ENABLE([exampledir],
  71           AS_HELP_STRING([--enable-exampledir],
  72                          [specify alternate directory for examples]),
  73                          exampledir="$enableval",)
  74 dnl XXX add --exampledir to autoconf standard directory list somehow
  75 AC_SUBST(exampledir)
  76
  77 dnl default is to match previous behavior
  78 pkgsrcrcdir=""
  79 AC_ARG_ENABLE([pkgsrcrcdir],
  80           AS_HELP_STRING([--enable-pkgsrcrcdir],
  81                          [specify directory for rc.d scripts]),
  82                          pkgsrcrcdir="$enableval",)
  83 dnl XXX add --pkgsrcrcdir to autoconf standard directory list somehow
  84 AC_SUBST(pkgsrcrcdir)
  85 AM_CONDITIONAL([PKGSRC], [test "x$pkgsrcrcdir" != "x"])
  86
  87 AC_ARG_WITH([moduledir], [AS_HELP_STRING([--with-moduledir=DIR], [module directory (${libdir}/frr/modules)])], [
  88         moduledir="$withval"
  89 ], [
  90         moduledir="\${libdir}/frr/modules"
  91 ])
  92 AC_SUBST([moduledir], [$moduledir])
  93
  94 AC_ARG_ENABLE(tcmalloc,
  95         AS_HELP_STRING([--enable-tcmalloc], [Turn on tcmalloc]),
  96 [case "${enableval}" in
  97   yes) tcmalloc_enabled=true
  98 LIBS="$LIBS -ltcmalloc_minimal"
  99  ;;
 100   no)  tcmalloc_enabled=false ;;
 101   *) AC_MSG_ERROR(bad value ${enableval} for --enable-tcmalloc) ;;
 102 esac],[tcmalloc_enabled=false])
 103
 104
 105 dnl Thanks autoconf, but we don't want a default -g -O2.  We have our own
 106 dnl flag determination logic.
 107 CFLAGS="${CFLAGS:-}"
 108
 109 dnl --------------------
 110 dnl Check CC and friends
 111 dnl --------------------
 112 dnl note orig_cflags is also used further down
 113 orig_cflags="$CFLAGS"
 114 AC_LANG([C])
 115 AC_PROG_CC
 116 AC_PROG_CPP
 117 AM_PROG_CC_C_O
 118 dnl remove autoconf default "-g -O2"
 119 CFLAGS="$orig_cflags"
 120 AC_PROG_CC_C99
 121 dnl NB: see C11 below
 122
 123 AC_PROG_EGREP
 124 PKG_PROG_PKG_CONFIG
 125
 126 dnl autoconf 2.59 appears not to support AC_PROG_SED
 127 dnl AC_PROG_SED
 128 AC_CHECK_PROG([SED],[sed],[sed],[/bin/false])
 129
 130 dnl try and enable CFLAGS that are useful for FRR
 131 dnl - specifically, options to control warnings
 132
 133 AC_USE_SYSTEM_EXTENSIONS
 134 AC_DEFUN([AC_C_FLAG], [{
 135         AC_LANG_PUSH(C)
 136         ac_c_flag_save="$CFLAGS"
 137         CFLAGS="$CFLAGS $1"
 138         AC_MSG_CHECKING([[whether $CC supports $1]])
 139         AC_COMPILE_IFELSE(
 140                 [AC_LANG_PROGRAM([[]])],
 141                 [
 142                         AC_MSG_RESULT([yes])
 143                         m4_if([$3], [], [], [
 144                                 CFLAGS="$ac_c_flag_save"
 145                                 $3
 146                         ])
 147                 ], [
 148                         CFLAGS="$ac_c_flag_save"
 149                         AC_MSG_RESULT([no])
 150                         $2
 151                 ])
 152         AC_LANG_POP(C)
 153         }])
 154
 155 AC_DEFUN([AC_LINK_IFELSE_FLAGS], [{
 156         AC_LANG_PUSH(C)
 157         ac_cflags_save="$CFLAGS"
 158         ac_libs_save="$LIBS"
 159         CFLAGS="$CFLAGS $1"
 160         LIBS="$LIBS $2"
 161         AC_LINK_IFELSE(
 162                 [$3],
 163                 [
 164                         AC_MSG_RESULT([yes])
 165                         CFLAGS="$ac_cflags_save"
 166                         LIBS="$ac_libs_save"
 167                         $5
 168                 ], [
 169                         AC_MSG_RESULT([no])
 170                         CFLAGS="$ac_cflags_save"
 171                         LIBS="$ac_libs_save"
 172                         $4
 173                 ])
 174         AC_LANG_POP(C)
 175         }])
 176
 177 dnl ICC won't bail on unknown options without -diag-error 10006
 178 dnl need to do this first so we get useful results for the other options
 179 AC_C_FLAG([-diag-error 10006])
 180
 181 dnl AC_PROG_CC_C99 may change CC to include -std=gnu99 or something
 182 ac_cc="$CC"
 183 CC="${CC% -std=gnu99}"
 184 CC="${CC% -std=c99}"
 185
 186 AC_C_FLAG([-std=gnu11], [CC="$ac_cc"], [CC="$CC -std=gnu11"])
 187
 188 dnl AddressSanitizer support
 189 AC_ARG_ENABLE([address-sanitizer], AS_HELP_STRING([--enable-address-sanitizer], \
 190               [enabled AddressSanitizer support for detecting a wide variety of \
 191                memory allocation and deallocation errors]), \
 192               [AC_DEFINE(HAVE_ADDRESS_SANITIZER, 1, [enable AddressSanitizer])
 193               ASAN_FLAGS="-fsanitize=address"
 194               SAN_CLIPPY_FLAGS="-fno-sanitize=all"
 195               AC_SUBST([ASAN_FLAGS])
 196               AC_SUBST([SAN_CLIPPY_FLAGS])
 197               LIBS="-ldl $LIBS"
 198               AC_TRY_COMPILE([],[const int i=0;],[AC_MSG_NOTICE([Address Sanitizer Enabled])],
 199                                                  [AC_MSG_ERROR([Address Sanitizer not available])])
 200               ])
 201
 202 dnl ThreadSanitizer support
 203 AC_ARG_ENABLE([thread-sanitizer], AS_HELP_STRING([--enable-thread-sanitizer], \
 204               [enabled ThreadSanitizer support for detecting data races]), \
 205               [AC_DEFINE(HAVE_THREAD_SANITIZER, 1, [enable ThreadSanitizer])
 206               TSAN_FLAGS="-fsanitize=thread"
 207               SAN_CLIPPY_FLAGS="-fno-sanitize=all"
 208               AC_SUBST([TSAN_FLAGS])
 209               AC_SUBST([SAN_CLIPPY_FLAGS])
 210               LIBS="-ldl $LIBS"
 211               AC_TRY_COMPILE([],[const int i=0;],[AC_MSG_NOTICE([Thread Sanitizer Enabled])],
 212                                                  [AC_MSG_ERROR([Thread Sanitizer not available])])
 213               ])
 214
 215 dnl MemorySanitizer support
 216 AC_ARG_ENABLE([memory-sanitizer], AS_HELP_STRING([--enable-memory-sanitizer], \
 217               [enabled MemorySanitizer support for detecting uninitialized memory reads]), \
 218               [AC_DEFINE(HAVE_THREAD_SANITIZER, 1, [enable MemorySanitizer])
 219               MSAN_FLAGS="-fsanitize=memory -fPIE -pie"
 220               SAN_CLIPPY_FLAGS="-fno-sanitize=all"
 221               AC_SUBST([MSAN_FLAGS])
 222               AC_SUBST([SAN_CLIPPY_FLAGS])
 223               LIBS="-ldl $LIBS"
 224               AC_TRY_COMPILE([],[const int i=0;],[AC_MSG_NOTICE([Memory Sanitizer Enabled])],
 225                                                  [AC_MSG_ERROR([Memory Sanitizer not available])])
 226               ])
 227
 228 dnl if the user has specified any CFLAGS, override our settings
 229 if test "x${enable_gcov}" = "xyes"; then
 230    if test "z$orig_cflags" = "z"; then
 231       AC_C_FLAG([-coverage])
 232       AC_C_FLAG([-O0])
 233    fi
 234
 235    LDFLAGS="${LDFLAGS} -lgcov"
 236 elif test "x${enable_dev_build}" = "xyes"; then
 237    AC_DEFINE(DEV_BUILD,,Build for development)
 238    if test "z$orig_cflags" = "z"; then
 239       AC_C_FLAG([-g3])
 240       AC_C_FLAG([-O0])
 241    fi
 242 else
 243    if test "z$orig_cflags" = "z"; then
 244       AC_C_FLAG([-g])
 245       AC_C_FLAG([-Os], [
 246         AC_C_FLAG([-O2])
 247       ])
 248    fi
 249 fi
 250 AM_CONDITIONAL([DEV_BUILD], [test "x$enable_dev_build" = "xyes"])
 251
 252 dnl always want these CFLAGS
 253 AC_C_FLAG([-fno-omit-frame-pointer])
 254 AC_C_FLAG([-funwind-tables])
 255 AC_C_FLAG([-Wall])
 256 AC_C_FLAG([-Wextra])
 257 AC_C_FLAG([-Wmissing-prototypes])
 258 AC_C_FLAG([-Wmissing-declarations])
 259 AC_C_FLAG([-Wpointer-arith])
 260 AC_C_FLAG([-Wbad-function-cast])
 261 AC_C_FLAG([-Wwrite-strings])
 262 if test x"${enable_gcc_ultra_verbose}" = x"yes" ; then
 263   AC_C_FLAG([-Wcast-qual])
 264   AC_C_FLAG([-Wstrict-prototypes])
 265   AC_C_FLAG([-Wmissing-noreturn])
 266   AC_C_FLAG([-Wmissing-format-attribute])
 267   AC_C_FLAG([-Wunreachable-code])
 268   AC_C_FLAG([-Wpacked])
 269   AC_C_FLAG([-Wpadded])
 270 else
 271   AC_C_FLAG([-Wno-unused-result])
 272 fi
 273 AC_C_FLAG([-Wno-unused-parameter])
 274 AC_C_FLAG([-Wno-missing-field-initializers])
 275
 276 dnl ICC emits a broken warning for const char *x = a ? "b" : "c";
 277 dnl for some reason the string consts get 'promoted' to char *,
 278 dnl triggering a const to non-const conversion warning.
 279 AC_C_FLAG([-diag-disable 3179])
 280
 281 if test x"${enable_werror}" = x"yes" ; then
 282   WERROR="-Werror"
 283 fi
 284 AC_SUBST(WERROR)
 285
 286 dnl need link on this one, not compile
 287 AC_LANG_PUSH(C)
 288 ac_ld_flag_save="$LDFLAGS"
 289 LDFLAGS="$LDFLAGS -rdynamic"
 290 AC_MSG_CHECKING([[whether linker supports -rdynamic]])
 291 AC_LINK_IFELSE(
 292         [AC_LANG_PROGRAM([[]])],
 293         [AC_MSG_RESULT([yes])],
 294         [
 295                 LDFLAGS="$ac_ld_flag_save"
 296                 AC_MSG_RESULT([no])
 297         ])
 298 AC_LANG_POP(C)
 299
 300 dnl ----------
 301 dnl Essentials
 302 dnl ----------
 303
 304 AX_PTHREAD([
 305   CC="$PTHREAD_CC"
 306   CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 307   LIBS="$PTHREAD_LIBS $LIBS"
 308 ], [
 309   AC_MSG_FAILURE([This FRR version needs pthreads])
 310 ])
 311
 312 dnl --------------
 313 dnl Check programs
 314 dnl --------------
 315 AC_PROG_INSTALL
 316 AC_PROG_LN_S
 317 AC_PROG_MAKE_SET
 318 AC_CHECK_TOOL(AR, ar)
 319
 320 dnl -----------------
 321 dnl System extensions
 322 dnl -----------------
 323 AC_GNU_SOURCE
 324
 325 dnl -------
 326 dnl libtool
 327 dnl -------
 328 LT_INIT
 329
 330 dnl ----------------------
 331 dnl Packages configuration
 332 dnl ----------------------
 333 AC_ARG_WITH(pkg-extra-version,
 334         AS_HELP_STRING([--with-pkg-extra-version=VER], [add extra version field, for packagers/distributions]),
 335         [EXTRAVERSION=$withval],)
 336 AC_ARG_WITH(pkg-git-version,
 337         AS_HELP_STRING([--with-pkg-git-version], [add git information to MOTD and build version string]),
 338         [ test "x$withval" != "xno" && with_pkg_git_version="yes" ])
 339 AC_ARG_WITH(vtysh_pager,
 340         AS_HELP_STRING([--with-vtysh-pager=PAGER], [control what pager is compiled in as default]),
 341         VTYSH_PAGER=$withval, VTYSH_PAGER="more")
 342 AC_ARG_ENABLE(vtysh,
 343   AS_HELP_STRING([--disable-vtysh], [do not build integrated vty shell for FRR]))
 344 AC_ARG_ENABLE(doc,
 345   AS_HELP_STRING([--disable-doc], [do not build docs]))
 346 AC_ARG_ENABLE(zebra,
 347   AS_HELP_STRING([--disable-zebra], [do not build zebra daemon]))
 348 AC_ARG_ENABLE(bgpd,
 349   AS_HELP_STRING([--disable-bgpd], [do not build bgpd]))
 350 AC_ARG_ENABLE(ripd,
 351   AS_HELP_STRING([--disable-ripd], [do not build ripd]))
 352 AC_ARG_ENABLE(ripngd,
 353   AS_HELP_STRING([--disable-ripngd], [do not build ripngd]))
 354 AC_ARG_ENABLE(ospfd,
 355   AS_HELP_STRING([--disable-ospfd], [do not build ospfd]))
 356 AC_ARG_ENABLE(ospf6d,
 357   AS_HELP_STRING([--disable-ospf6d], [do not build ospf6d]))
 358 AC_ARG_ENABLE(ldpd,
 359   AS_HELP_STRING([--enable-ldpd], [build ldpd]))
 360 AC_ARG_ENABLE(nhrpd,
 361   AS_HELP_STRING([--disable-nhrpd], [do not build nhrpd]))
 362 AC_ARG_ENABLE(eigrpd,
 363   AS_HELP_STRING([--disable-eigrpd], [do not build eigrpd]))
 364 AC_ARG_ENABLE(babeld,
 365   AS_HELP_STRING([--disable-babeld], [do not build babeld]))
 366 AC_ARG_ENABLE(watchfrr,
 367   AS_HELP_STRING([--disable-watchfrr], [do not build watchfrr]))
 368 AC_ARG_ENABLE(isisd,
 369   AS_HELP_STRING([--disable-isisd], [do not build isisd]))
 370 AC_ARG_ENABLE(pimd,
 371   AS_HELP_STRING([--disable-pimd], [do not build pimd]))
 372 AC_ARG_ENABLE(pbrd,
 373   AS_HELP_STRING([--disable-pbrd], [do not build pbrd]))
 374 AC_ARG_ENABLE(sharpd,
 375   AS_HELP_STRING([--enable-sharpd], [do not build sharpd]))
 376 AC_ARG_ENABLE(bgp-announce,
 377   AS_HELP_STRING([--disable-bgp-announce,], [turn off BGP route announcement]))
 378 AC_ARG_ENABLE(bgp-vnc,
 379   AS_HELP_STRING([--disable-bgp-vnc],[turn off BGP VNC support]))
 380 AC_ARG_WITH(rfp-path,
 381   AS_HELP_STRING([--with-rfp-path[=DIR]],[path to replaced stub RFP used with BGP VNC]))
 382 AC_ARG_ENABLE(snmp,
 383   AS_HELP_STRING([--enable-snmp=ARG], [enable SNMP support (smux or agentx)]))
 384 AC_ARG_ENABLE(zeromq,
 385   AS_HELP_STRING([--enable-zeromq], [enable ZeroMQ handler (libfrrzmq)]))
 386 AC_ARG_WITH(libpam,
 387   AS_HELP_STRING([--with-libpam], [use libpam for PAM support in vtysh]))
 388 AC_ARG_ENABLE(ospfapi,
 389   AS_HELP_STRING([--disable-ospfapi], [do not build OSPFAPI to access the OSPF LSA Database]))
 390 AC_ARG_ENABLE(ospfclient,
 391   AS_HELP_STRING([--disable-ospfclient], [do not build OSPFAPI client for OSPFAPI,
 392                           (this is the default if --disable-ospfapi is set)]))
 393 AC_ARG_ENABLE(multipath,
 394   AS_HELP_STRING([--enable-multipath=ARG], [enable multipath function, ARG must be digit]))
 395 AC_ARG_ENABLE(user,
 396   AS_HELP_STRING([--enable-user=USER], [user to run FRR suite as (default frr)]))
 397 AC_ARG_ENABLE(group,
 398   AS_HELP_STRING([--enable-group=GROUP], [group to run FRR suite as (default frr)]))
 399 AC_ARG_ENABLE(vty_group,
 400   AS_HELP_STRING([--enable-vty-group=ARG], [set vty sockets to have specified group as owner]))
 401 AC_ARG_ENABLE(configfile_mask,
 402   AS_HELP_STRING([--enable-configfile-mask=ARG], [set mask for config files]))
 403 AC_ARG_ENABLE(logfile_mask,
 404   AS_HELP_STRING([--enable-logfile-mask=ARG], [set mask for log files]))
 405 AC_ARG_ENABLE(shell_access,
 406   AS_HELP_STRING([--enable-shell-access], [Allow users to access shell/telnet/ssh]))
 407 AC_ARG_ENABLE(realms,
 408   AS_HELP_STRING([--enable-realms], [enable REALMS support under Linux]))
 409 AC_ARG_ENABLE(rtadv,
 410   AS_HELP_STRING([--disable-rtadv], [disable IPV6 router advertisement feature]))
 411 AC_ARG_ENABLE(irdp,
 412   AS_HELP_STRING([--disable-irdp], [enable IRDP server support in zebra (default if supported)]))
 413 AC_ARG_ENABLE(capabilities,
 414   AS_HELP_STRING([--disable-capabilities], [disable using POSIX capabilities]))
 415 AC_ARG_ENABLE(rusage,
 416   AS_HELP_STRING([--disable-rusage], [disable using getrusage]))
 417 AC_ARG_ENABLE(gcc_ultra_verbose,
 418   AS_HELP_STRING([--enable-gcc-ultra-verbose], [enable ultra verbose GCC warnings]))
 419 AC_ARG_ENABLE(linux24_tcp_md5,
 420   AS_HELP_STRING([--enable-linux24-tcp-md5], [enable support for old, Linux-2.4 RFC2385 patch]))
 421 AC_ARG_ENABLE(backtrace,
 422   AS_HELP_STRING([--disable-backtrace,], [disable crash backtraces (default autodetect)]))
 423 AC_ARG_ENABLE(time-check,
 424   AS_HELP_STRING([--disable-time-check], [disable slow thread warning messages]))
 425 AC_ARG_ENABLE(pcreposix,
 426   AS_HELP_STRING([--enable-pcreposix], [enable using PCRE Posix libs for regex functions]))
 427 AC_ARG_ENABLE(fpm,
 428   AS_HELP_STRING([--enable-fpm], [enable Forwarding Plane Manager support]))
 429 AC_ARG_ENABLE(systemd,
 430   AS_HELP_STRING([--enable-systemd], [enable Systemd support]))
 431 AC_ARG_ENABLE(werror,
 432   AS_HELP_STRING([--enable-werror], [enable -Werror (recommended for developers only)]))
 433 AC_ARG_ENABLE(cumulus,
 434   AS_HELP_STRING([--enable-cumulus], [enable Cumulus Switch Special Extensions]))
 435 AC_ARG_ENABLE(datacenter,
 436   AS_HELP_STRING([--enable-datacenter], [enable Compilation for Data Center Extensions]))
 437 AC_ARG_ENABLE(fuzzing,
 438   AS_HELP_STRING([--enable-fuzzing], [enable ability to fuzz various parts of FRR]))
 439 AC_ARG_ENABLE(rr-semantics,
 440   AS_HELP_STRING([--disable-rr-semantics], [disable the v6 Route Replace semantics]))
 441 AC_ARG_ENABLE([protobuf],
 442   AS_HELP_STRING([--enable-protobuf], [Enable experimental protobuf support]))
 443 AC_ARG_ENABLE([oldvpn_commands],
 444   AS_HELP_STRING([--enable-oldvpn-commands], [Keep old vpn commands]))
 445 AC_ARG_ENABLE(rpki,
 446   AS_HELP_STRING([--enable-rpki], [enable RPKI prefix validation support]))
 447 AC_ARG_ENABLE([clippy-only],
 448   AS_HELP_STRING([--enable-clippy-only], [Only build clippy]))
 449 AC_ARG_ENABLE([numeric_version],
 450   AS_HELP_STRING([--enable-numeric-version], [Only numeric digits allowed in version (for Alpine)]))
 451 AC_ARG_ENABLE([gcov],
 452   AS_HELP_STRING([--enable-gcov], [Add code coverage information]))
 453
 454 AS_IF([test "${enable_clippy_only}" != "yes"], [
 455 AC_CHECK_HEADERS(json-c/json.h)
 456 AC_CHECK_LIB(json-c, json_object_get, LIBS="$LIBS -ljson-c", [], [-lm])
 457 if test $ac_cv_lib_json_c_json_object_get = no; then
 458   AC_CHECK_LIB(json, json_object_get, LIBS="$LIBS -ljson")
 459   if test $ac_cv_lib_json_json_object_get = no; then
 460       AC_MSG_ERROR([lib json is needed to compile])
 461   fi
 462 fi
 463 ])
 464
 465 AC_ARG_ENABLE([dev_build],
 466     AS_HELP_STRING([--enable-dev-build], [build for development]))
 467
 468 if test x"${enable_time_check}" != x"no" ; then
 469   if test x"${enable_time_check}" = x"yes" -o x"${enable_time_check}" = x ; then
 470     AC_DEFINE(CONSUMED_TIME_CHECK,5000000,Consumed Time Check)
 471   else
 472     AC_DEFINE_UNQUOTED(CONSUMED_TIME_CHECK,$enable_time_check,Consumed Time Check)
 473   fi
 474 fi
 475
 476 case "${enable_systemd}" in
 477   "no") ;;
 478   "yes")
 479   AC_CHECK_LIB(systemd, sd_notify, LIBS="$LIBS -lsystemd")
 480   if test $ac_cv_lib_systemd_sd_notify = no; then
 481     AC_MSG_ERROR([enable systemd has been specified but systemd development env not found on your system])
 482   else
 483     AC_DEFINE(HAVE_SYSTEMD,,Compile systemd support in)
 484   fi
 485   ;;
 486   "*") ;;
 487 esac
 488
 489 if test "${enable_rr_semantics}" != "no" ; then
 490   AC_DEFINE(HAVE_V6_RR_SEMANTICS,, Compile in v6 Route Replacement Semantics)
 491 fi
 492
 493 if test "${enable_datacenter}" = "yes" ; then
 494   AC_DEFINE(HAVE_DATACENTER,,Compile extensions for a DataCenter)
 495   DFLT_NAME="datacenter"
 496 else
 497   DFLT_NAME="traditional"
 498 fi
 499
 500 if test "${enable_fuzzing}" = "yes" ; then
 501   AC_DEFINE(HANDLE_ZAPI_FUZZING,,Compile extensions to use with a fuzzer)
 502 fi
 503
 504 if test "${enable_cumulus}" = "yes" ; then
 505   AC_DEFINE(HAVE_CUMULUS,,Compile Special Cumulus Code in)
 506 fi
 507
 508 AC_SUBST(DFLT_NAME)
 509 AC_DEFINE_UNQUOTED(DFLT_NAME,["$DFLT_NAME"], Name of the configuration default set)
 510
 511 if test "${enable_shell_access}" = "yes"; then
 512    AC_DEFINE(HAVE_SHELL_ACCESS,,Allow user to use ssh/telnet/bash)
 513 fi
 514
 515 AM_CONDITIONAL([FPM], [test "x$enable_fpm" = "xyes"])
 516
 517 #
 518 # Python for clippy
 519 #
 520 AS_IF([test "$host" = "$build"], [
 521   PYTHONCONFIG=""
 522
 523   # ordering:
 524   # 1.  try python3, but respect the user's preference on which minor ver
 525   # 2.  try python, which might be py3 or py2 again on the user's preference
 526   # 3.  try python2 (can really only be 2.7 but eh)
 527   # 4.  try 3.5 > 3.4 > 3.3 > 3.2 > 2.7 through pkg-config (no user pref)
 528   #
 529   # (AX_PYTHON_DEVEL has no clue about py3 vs py2)
 530   # (AX_PYTHON does not do what we need)
 531
 532   AC_CHECK_TOOLS([PYTHONCONFIG], [python3-config python-config python2-config])
 533   if test -n "$PYTHONCONFIG"; then
 534     PYTHON_CFLAGS="`\"${PYTHONCONFIG}\" --includes`"
 535     PYTHON_LIBS="`\"${PYTHONCONFIG}\" --libs`"
 536
 537     AC_MSG_CHECKING([whether we found a working Python version])
 538     AC_LINK_IFELSE_FLAGS([$PYTHON_CFLAGS], [$PYTHON_LIBS], [AC_LANG_PROGRAM([
 539 #include <Python.h>
 540 #if PY_VERSION_HEX < 0x02070000
 541 #error python too old
 542 #endif
 543 int main(void);
 544 ],
 545 [
 546 {
 547   Py_Initialize();
 548   return 0;
 549 }
 550 ])], [
 551       PYTHONCONFIG=""
 552       unset PYTHON_LIBS
 553       unset PYTHON_CFLAGS
 554     ])
 555   fi
 556
 557   if test -z "$PYTHONCONFIG"; then
 558     PKG_CHECK_MODULES([PYTHON], python-3.5, [], [
 559       PKG_CHECK_MODULES([PYTHON], python-3.4, [], [
 560         PKG_CHECK_MODULES([PYTHON], python-3.3, [], [
 561           PKG_CHECK_MODULES([PYTHON], python-3.2, [], [
 562             PKG_CHECK_MODULES([PYTHON], python-2.7, [], [
 563               AC_MSG_FAILURE([could not find python-config or pkg-config python, please install Python development files from libpython-dev or similar])
 564               ])])])])])
 565
 566
 567     AC_MSG_CHECKING([whether we found a working Python version])
 568     AC_LINK_IFELSE_FLAGS([$PYTHON_CFLAGS], [$PYTHON_LIBS], [AC_LANG_PROGRAM([
 569 #include <Python.h>
 570 #if PY_VERSION_HEX < 0x02070000
 571 #error python too old
 572 #endif
 573 int main(void);
 574 ],
 575 [
 576 {
 577   Py_Initialize();
 578   return 0;
 579 }
 580 ])], [
 581       AC_MSG_FAILURE([could not find python-config or pkg-config python, please install Python development files from libpython-dev or similar])
 582     ])
 583   fi
 584 ])
 585 AC_SUBST(PYTHON_CFLAGS)
 586 AC_SUBST(PYTHON_LIBS)
 587
 588 #
 589 # Logic for protobuf support.
 590 #
 591 if test "$enable_protobuf" = "yes"; then
 592    have_protobuf=yes
 593
 594    # Check for protoc-c
 595    AC_CHECK_PROG([PROTOC_C], [protoc-c], [protoc-c], [/bin/false])
 596    if test "x$PROTOC_C" = "x/bin/false"; then
 597       have_protobuf=no
 598    else
 599       found_protobuf_c=no
 600       PKG_CHECK_MODULES([PROTOBUF_C], libprotobuf-c >= 0.14,
 601                      [found_protobuf_c=yes],
 602                      [AC_MSG_RESULT([pkg-config did not find libprotobuf-c])])
 603
 604       if test "x$found_protobuf_c" = "xyes"; then
 605          LDFLAGS="$LDFLAGS $PROTOBUF_C_LIBS"
 606          CFLAGS="$CFLAGS $PROTOBUF_C_CFLAGS"
 607       else
 608         AC_CHECK_HEADER([google/protobuf-c/protobuf-c.h], [],
 609                         [have_protobuf=no; AC_MSG_RESULT([Couldn't find google/protobuf-c.h])])
 610       fi
 611    fi
 612 fi
 613
 614 #
 615 # Logic for old vpn commans support.
 616 #
 617 if test "$enable_oldvpn_commands" = "yes"; then
 618    AC_DEFINE(KEEP_OLD_VPN_COMMANDS,, [Define for compiling with old vpn commands])
 619 fi
 620
 621 # Fail if the user explicity enabled protobuf support and we couldn't
 622 # find the compiler or libraries.
 623 if test "x$have_protobuf" = "xno" && test "x$enable_protobuf" = "xyes"; then
 624    AC_MSG_ERROR([Protobuf enabled explicitly but can't find libraries/tools])
 625 fi
 626
 627 if test "x$have_protobuf" = "xyes"; then
 628    AC_DEFINE(HAVE_PROTOBUF,, protobuf)
 629 fi
 630
 631 AM_CONDITIONAL([HAVE_PROTOBUF], [test "x$have_protobuf" = "xyes"])
 632
 633 #
 634 # End of logic for protobuf support.
 635 #
 636
 637 if test "${enable_linux24_tcp_md5}" = "yes"; then
 638   AC_DEFINE(HAVE_TCP_MD5_LINUX24,,Old Linux 2.4 TCP MD5 Signature Patch)
 639 fi
 640
 641 AC_MSG_CHECKING(if zebra should be configurable to send Route Advertisements)
 642 if test "${enable_rtadv}" != "no"; then
 643   AC_MSG_RESULT(yes)
 644   AC_DEFINE(HAVE_RTADV,,Enable IPv6 Routing Advertisement support)
 645 else
 646   AC_MSG_RESULT(no)
 647 fi
 648
 649 if test x"${enable_user}" = x"no"; then
 650   enable_user=""
 651 else
 652   if test x"${enable_user}" = x"yes" || test x"${enable_user}" = x""; then
 653     enable_user="frr"
 654   fi
 655   AC_DEFINE_UNQUOTED(FRR_USER, "${enable_user}", frr User)
 656 fi
 657
 658 if test x"${enable_group}" = x"no"; then
 659   enable_group=""
 660 else
 661   if test x"${enable_group}" = x"yes" || test x"${enable_group}" = x""; then
 662     enable_group="frr"
 663   fi
 664   AC_DEFINE_UNQUOTED(FRR_GROUP, "${enable_group}", frr Group)
 665 fi
 666
 667 if test x"${enable_vty_group}" = x"yes" ; then
 668   AC_MSG_ERROR([--enable-vty-group requires a group as argument, not yes])
 669 elif test x"${enable_vty_group}" != x""; then
 670   if test x"${enable_vty_group}" != x"no"; then
 671     AC_DEFINE_UNQUOTED(VTY_GROUP, "${enable_vty_group}", VTY Sockets Group)
 672   fi
 673 fi
 674 AC_SUBST([enable_user])
 675 AC_SUBST([enable_group])
 676 AC_SUBST([enable_vty_group])
 677
 678 enable_configfile_mask=${enable_configfile_mask:-0600}
 679 AC_DEFINE_UNQUOTED(CONFIGFILE_MASK, ${enable_configfile_mask}, Mask for config files)
 680
 681 enable_logfile_mask=${enable_logfile_mask:-0600}
 682 AC_DEFINE_UNQUOTED(LOGFILE_MASK, ${enable_logfile_mask}, Mask for log files)
 683
 684 MPATH_NUM=1
 685
 686 case "${enable_multipath}" in
 687   0)
 688     MPATH_NUM=64
 689     ;;
 690   [[1-9]|[1-9][0-9]|[1-9][0-9][0-9]])
 691     MPATH_NUM="${enable_multipath}"
 692     ;;
 693   "")
 694     ;;
 695   *)
 696     AC_MSG_FAILURE([Please specify digit to enable multipath ARG])
 697     ;;
 698 esac
 699
 700 AC_DEFINE_UNQUOTED(MULTIPATH_NUM, $MPATH_NUM, Maximum number of paths for a route)
 701
 702 AC_DEFINE_UNQUOTED(VTYSH_PAGER, "$VTYSH_PAGER", [What pager to use])
 703
 704 dnl --------------------
 705 dnl Enable code coverage
 706 dnl --------------------
 707 AM_CONDITIONAL([HAVE_GCOV],[test '!' "$enable_gcov" = no])
 708
 709 dnl ------------------------------------
 710 dnl Alpine only accepts numeric versions
 711 dnl ------------------------------------
 712 if test "x${enable_numeric_version}" != "x" ; then
 713   VERSION="`echo ${VERSION} | tr -c -d '[[.0-9]]'`"
 714   PACKAGE_VERSION="`echo ${PACKAGE_VERSION} | tr -c -d '[[.0-9]]'`"
 715 fi
 716
 717 dnl -----------------------------------
 718 dnl Add extra version string to package
 719 dnl name, string and version fields.
 720 dnl -----------------------------------
 721 if test "x${EXTRAVERSION}" != "x" ; then
 722   VERSION="${VERSION}${EXTRAVERSION}"
 723   PACKAGE_VERSION="${PACKAGE_VERSION}${EXTRAVERSION}"
 724   AC_SUBST(PACKAGE_EXTRAVERSION, ["${EXTRAVERSION}"])
 725   PACKAGE_STRING="${PACKAGE_STRING}${EXTRAVERSION}"
 726 fi
 727
 728 if test "x$with_pkg_git_version" = "xyes"; then
 729         if test -d "${srcdir}/.git"; then
 730                 AC_DEFINE(GIT_VERSION, [1], [include git version info])
 731         else    with_pkg_git_version="no"
 732                 AC_MSG_WARN([--with-pkg-git-version given, but this is not a git checkout])
 733         fi
 734 fi
 735 AM_CONDITIONAL([GIT_VERSION], [test "x$with_pkg_git_version" = "xyes"])
 736
 737 dnl ------------------------------------
 738 dnl Check C keywords and standard  types
 739 dnl ------------------------------------
 740 AC_C_CONST
 741 AC_C_INLINE
 742 AC_C_VOLATILE
 743 AC_HEADER_STDC
 744 dnl AC_TYPE_PID_T
 745 AC_TYPE_UID_T
 746 AC_TYPE_MODE_T
 747 AC_TYPE_SIZE_T
 748 AC_STRUCT_TM
 749
 750 dnl -------------------------
 751 dnl Check other header files.
 752 dnl -------------------------
 753 AC_CHECK_HEADERS([stropts.h sys/ksym.h \
 754         linux/version.h asm/types.h \
 755         sys/cdefs.h])
 756
 757 ac_stdatomic_ok=false
 758 AC_DEFINE(FRR_AUTOCONF_ATOMIC, 1, [did autoconf checks for atomic funcs])
 759 AC_CHECK_HEADER([stdatomic.h],[
 760
 761   AC_MSG_CHECKING([whether _Atomic qualifier works])
 762   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 763 #include <stdatomic.h>
 764 int main(int argc, char **argv) {
 765   _Atomic int i = 0;
 766   return i;
 767 }
 768 ]])], [
 769     AC_DEFINE(HAVE_STDATOMIC_H, 1, [found stdatomic.h])
 770     AC_MSG_RESULT([yes])
 771     ac_stdatomic_ok=true
 772   ], [
 773     AC_MSG_RESULT([no])
 774   ])
 775 ])
 776
 777 AS_IF([$ac_stdatomic_ok], [true], [
 778   AC_MSG_CHECKING([for __atomic_* builtins])
 779   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 780 int main(int argc, char **argv) {
 781   volatile int i = 1;
 782   __atomic_store_n (&i, 0, __ATOMIC_RELEASE);
 783   return __atomic_load_n (&i, __ATOMIC_ACQUIRE);
 784 }
 785 ]])], [
 786     AC_DEFINE(HAVE___ATOMIC, 1, [found __atomic builtins])
 787     AC_MSG_RESULT([yes])
 788   ], [
 789     AC_MSG_RESULT([no])
 790
 791     dnl FreeBSD 9 has a broken stdatomic.h where _Atomic doesn't work
 792     AC_MSG_CHECKING([for __sync_* builtins])
 793     AC_LINK_IFELSE([AC_LANG_SOURCE([[
 794 int main(int argc, char **argv) {
 795   volatile int i = 1;
 796   __sync_fetch_and_sub (&i, 1);
 797   return __sync_val_compare_and_swap (&i, 0, 1);
 798 }
 799 ]])], [
 800       AC_DEFINE(HAVE___SYNC, 1, [found __sync builtins])
 801       AC_MSG_RESULT([yes])
 802
 803       AC_MSG_CHECKING([for __sync_swap builtin])
 804       AC_LINK_IFELSE([AC_LANG_SOURCE([[
 805 int main(int argc, char **argv) {
 806   volatile int i = 1;
 807   return __sync_swap (&i, 2);
 808 }
 809 ]])], [
 810         AC_DEFINE(HAVE___SYNC_SWAP, 1, [found __sync_swap builtin])
 811         AC_MSG_RESULT([yes])
 812       ], [
 813         AC_MSG_RESULT([no])
 814       ])
 815
 816     ], [
 817       AC_MSG_RESULT([no])
 818       AC_MSG_FAILURE([stdatomic.h unavailable and $CC has neither __atomic nor __sync builtins])
 819     ])
 820   ])
 821 ])
 822
 823 dnl Utility macro to avoid retyping includes all the time
 824 m4_define([FRR_INCLUDES],
 825 [#ifdef SUNOS_5
 826 #define _XPG4_2
 827 #define __EXTENSIONS__
 828 #endif
 829 #include <stdio.h>
 830 #include <stdlib.h>
 831 #include <stddef.h>
 832 #include <sys/types.h>
 833 /* sys/conf.h depends on param.h on FBSD at least */
 834 #include <sys/param.h>
 835 /* Required for MAXSIG */
 836 #include <signal.h>
 837 #include <sys/socket.h>
 838 #ifdef __APPLE__
 839 # define __APPLE_USE_RFC_3542
 840 #endif
 841 #include <netinet/in.h>
 842 #include <sys/time.h>
 843 #include <time.h>
 844 #include <net/if.h>
 845 ])dnl
 846
 847 dnl Same applies for HAVE_NET_IF_VAR_H, which HAVE_NETINET6_ND6_H and
 848 dnl HAVE_NETINET_IN_VAR_H depend upon. But if_var.h depends on if.h, hence
 849 dnl an additional round for it.
 850
 851 AC_CHECK_HEADERS([net/if_var.h], [], [], FRR_INCLUDES)
 852
 853 m4_define([FRR_INCLUDES],
 854 FRR_INCLUDES
 855 [#if HAVE_NET_IF_VAR_H
 856 # include <net/if_var.h>
 857 #endif
 858 ])dnl
 859
 860 AC_CHECK_HEADERS([netinet/in_var.h \
 861         net/if_dl.h net/netopt.h \
 862         inet/nd.h netinet/ip_icmp.h \
 863         sys/sysctl.h sys/sockio.h kvm.h sys/conf.h],
 864         [], [], FRR_INCLUDES)
 865
 866 AC_CHECK_HEADERS([ucontext.h], [], [],
 867 [#ifndef __USE_GNU
 868 #define __USE_GNU
 869 #endif /* __USE_GNU */
 870 FRR_INCLUDES
 871 ])
 872
 873 m4_define([UCONTEXT_INCLUDES],
 874 [#include <ucontext.h>])dnl
 875
 876 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.uc_regs],
 877   [], [], [UCONTEXT_INCLUDES])
 878 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs],
 879   [AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs.nip],
 880    [], [], [UCONTEXT_INCLUDES])],
 881   [], [UCONTEXT_INCLUDES])
 882 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.gregs],
 883   [], [], [UCONTEXT_INCLUDES])
 884
 885 m4_define([FRR_INCLUDES],
 886 FRR_INCLUDES
 887 [
 888 #include <sys/un.h>
 889 #include <netinet/in_systm.h>
 890 #if HAVE_NETINET_IN_VAR_H
 891 # include <netinet/in_var.h>
 892 #endif
 893 #if HAVE_NET_IF_DL_H
 894 # include <net/if_dl.h>
 895 #endif
 896 #if HAVE_NET_NETOPT_H
 897 # include <net/netopt.h>
 898 #endif
 899 #include <net/route.h>
 900 #if HAVE_INET_ND_H
 901 # include <inet/nd.h>
 902 #endif
 903 #include <arpa/inet.h>
 904 /* Required for IDRP */
 905 #if HAVE_NETINET_IP_ICMP_H
 906 # include <netinet/ip_icmp.h>
 907 #endif
 908 ])dnl
 909
 910 dnl V6 headers are checked below, after we check for v6
 911
 912 AC_MSG_CHECKING([which operating system interface to use])
 913 case "$host_os" in
 914   sunos* | solaris2*)
 915     AC_MSG_RESULT([Solaris])
 916
 917     AC_DEFINE(SUNOS_5, 1, [SunOS 5])
 918     AC_DEFINE(SOLARIS_IPV6, 1, Solaris IPv6)
 919
 920     AC_CHECK_LIB(socket, main)
 921     AC_CHECK_LIB(nsl, main)
 922     AC_CHECK_LIB(umem, main)
 923     AC_CHECK_FUNCS([printstack], [
 924       AC_DEFINE([HAVE_PRINTSTACK],1,[Solaris printstack])
 925       AC_DEFINE([HAVE_STACK_TRACE],1,[Stack symbols decode functionality])
 926     ])
 927     CURSES=-lcurses
 928     SOLARIS="solaris"
 929     ;;
 930   linux*)
 931     AC_MSG_RESULT([Linux])
 932
 933     AC_DEFINE(GNU_LINUX,,GNU Linux)
 934     AC_DEFINE(HAVE_NETLINK,,netlink)
 935     AC_DEFINE(LINUX_IPV6,1,Linux IPv6 stack)
 936
 937     dnl Linux has a compilation problem with mixing
 938     dnl netinet/in.h and linux/in6.h they are not
 939     dnl compatible.  There has been discussion on
 940     dnl how to fix it but no real progress on implementation
 941     dnl when they fix it, remove this
 942     AC_DEFINE(IPV6_MINHOPCOUNT, 73, Linux ipv6 Min Hop Count)
 943     ;;
 944   openbsd*)
 945     AC_MSG_RESULT([OpenBSD])
 946
 947     AC_DEFINE(OPEN_BSD,,OpenBSD)
 948     AC_DEFINE(KAME,1,KAME IPv6)
 949     AC_DEFINE(BSD_V6_SYSCTL,1,BSD v6 sysctl to turn on and off forwarding)
 950
 951     if test "x${enable_pimd}" != "xno"; then
 952       case "$host_os" in
 953       openbsd6.0)
 954         ;;
 955       openbsd[6-9]*)
 956         AC_MSG_FAILURE([pimd cannot be enabled as PIM support has been removed from OpenBSD 6.1])
 957         ;;
 958       esac
 959     fi
 960     ;;
 961   *)
 962     AC_MSG_RESULT([BSD])
 963
 964     AC_DEFINE(HAVE_NET_RT_IFLIST,,NET_RT_IFLIST)
 965     AC_DEFINE(KAME,1,KAME IPv6)
 966     AC_DEFINE(BSD_V6_SYSCTL,1,BSD v6 sysctl to turn on and off forwarding)
 967     ;;
 968 esac
 969 AM_CONDITIONAL(SOLARIS, test "${SOLARIS}" = "solaris")
 970
 971 AC_SYS_LARGEFILE
 972
 973 dnl ------------------------
 974 dnl Integrated REALMS option
 975 dnl ------------------------
 976 if test "${enable_realms}" = "yes"; then
 977     case "$host_os" in
 978       linux*)
 979        AC_DEFINE(SUPPORT_REALMS,, Realms support)
 980        ;;
 981       *)
 982        echo "Sorry, only Linux has REALMS support"
 983        exit 1
 984        ;;
 985     esac
 986 fi
 987 AM_CONDITIONAL([SUPPORT_REALMS], [test "${enable_realms}" = "yes"])
 988
 989 dnl ---------------------
 990 dnl Integrated VTY option
 991 dnl ---------------------
 992 case "${enable_vtysh}" in
 993   "no") VTYSH="";;
 994   *)    VTYSH="vtysh";
 995          AC_DEFINE(VTYSH,,VTY shell)
 996 dnl      Vtysh uses libreadline, which looks for termcap functions at
 997 dnl      configure time.  We follow readlines search order.
 998 dnl      The required procedures are in libtermcap on NetBSD, in
 999 dnl      [TODO] on Linux, and in [TODO] on Solaris.
1000          AC_CHECK_LIB(termcap, tputs, LIBREADLINE="$LIBREADLINE -ltermcap",
1001            [AC_CHECK_LIB(tinfo, tputs, LIBREADLINE="$LIBREADLINE -ltinfo",
1002              [AC_CHECK_LIB(curses, tputs, LIBREADLINE="$LIBREADLINE -lcurses",
1003                [AC_CHECK_LIB(ncurses, tputs,
1004                              LIBREADLINE="$LIBREADLINE -lncurses")]
1005               )]
1006             )]
1007           )
1008          AC_CHECK_LIB(readline, main, LIBREADLINE="-lreadline $LIBREADLINE",,
1009                       "$LIBREADLINE")
1010          if test $ac_cv_lib_readline_main = no; then
1011            AC_MSG_ERROR([vtysh needs libreadline but was not found and usable on your system.])
1012          fi
1013          AC_CHECK_HEADER(readline/history.h)
1014          if test $ac_cv_header_readline_history_h = no;then
1015            AC_MSG_ERROR([readline is too old to have readline/history.h, please update to the latest readline library.])
1016          fi
1017          AC_CHECK_LIB(readline, rl_completion_matches,
1018                       LIBREADLINE="$LIBREADLINE",, "$LIBREADLINE")
1019          if test $ac_cv_lib_readline_rl_completion_matches = no; then
1020            AC_DEFINE(rl_completion_matches,completion_matches,Old readline)
1021          fi
1022          ;;
1023 esac
1024 AC_SUBST(LIBREADLINE)
1025 AM_CONDITIONAL(VTYSH, test "x$VTYSH" = "xvtysh")
1026
1027 dnl ----------
1028 dnl PAM module
1029 dnl
1030 dnl FRR detects the PAM library it is built against by checking for a
1031 dnl functional pam_misc.h (Linux-PAM) or openpam.h (OpenPAM) header. pam_misc.h
1032 dnl is known to #include pam_appl.h, the standard header of a PAM library, and
1033 dnl openpam.h doesn't do that, although depends on the header too. Hence a
1034 dnl little assistance to AC_CHECK_HEADER is necessary for the proper detection
1035 dnl of OpenPAM.
1036 dnl ----------
1037 if test "$with_libpam" = "yes"; then
1038   AC_CHECK_HEADER([security/pam_misc.h],
1039     [AC_DEFINE(HAVE_PAM_MISC_H,,Have pam_misc.h)
1040      AC_DEFINE(PAM_CONV_FUNC,misc_conv,Have misc_conv)
1041      pam_conv_func="misc_conv"
1042     ],
1043     [], FRR_INCLUDES)
1044   AC_CHECK_HEADER([security/openpam.h],
1045     [AC_DEFINE(HAVE_OPENPAM_H,,Have openpam.h)
1046      AC_DEFINE(PAM_CONV_FUNC,openpam_ttyconv,Have openpam_ttyconv)
1047      pam_conv_func="openpam_ttyconv"
1048     ],
1049     [], FRR_INCLUDES[#include <security/pam_appl.h>])
1050   if test -z "$ac_cv_header_security_pam_misc_h$ac_cv_header_security_openpam_h" ; then
1051     AC_MSG_WARN([*** pam support will not be built ***])
1052     with_libpam="no"
1053   fi
1054 fi
1055
1056 if test "$with_libpam" = "yes"; then
1057 dnl took this test from proftpds configure.in and suited to our needs
1058 dnl -------------------------------------------------------------------------
1059 dnl
1060 dnl This next check looks funky due to a linker problem with some versions
1061 dnl of the PAM library.  Prior to 0.72 release, the Linux PAM shared library
1062 dnl omitted requiring libdl linking information. PAM-0.72 or better ships
1063 dnl with RedHat 6.2 and Debian 2.2 or better.
1064 AC_CHECK_LIB(pam, pam_start,
1065   [AC_CHECK_LIB(pam, $pam_conv_func,
1066     [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1067      LIBPAM="-lpam"],
1068     [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1069      LIBPAM="-lpam -lpam_misc"]
1070     )
1071   ],
1072
1073   [AC_CHECK_LIB(pam, pam_end,
1074     [AC_CHECK_LIB(pam, $pam_conv_func,
1075       [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1076        LIBPAM="-lpam -ldl"],
1077       [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1078        LIBPAM="-lpam -ldl -lpam_misc"]
1079      )
1080   ],AC_MSG_WARN([*** pam support will not be built ***]),
1081   [-ldl])
1082   ]
1083 )
1084 fi
1085 AC_SUBST(LIBPAM)
1086
1087 dnl -------------------------------
1088 dnl Endian-ness check
1089 dnl -------------------------------
1090 AC_WORDS_BIGENDIAN
1091
1092 dnl -------------------------------
1093 dnl check the size in byte of the C
1094 dnl -------------------------------
1095 dnl AC_CHECK_SIZEOF(char)
1096 dnl AC_CHECK_SIZEOF(int)
1097 dnl AC_CHECK_SIZEOF(short)
1098 dnl AC_CHECK_SIZEOF(long)
1099
1100 dnl ----------------------------
1101 dnl check existance of functions
1102 dnl ----------------------------
1103 AC_FUNC_FNMATCH
1104 AC_FUNC_FORK
1105 AC_FUNC_MKTIME
1106 AC_FUNC_STAT
1107
1108 dnl -------------------------------
1109 dnl bgpd needs pow() and hence libm
1110 dnl -------------------------------
1111 TMPLIBS="$LIBS"
1112 AC_CHECK_HEADER([math.h],
1113   [AC_CHECK_LIB([m], [pow],
1114     [LIBM="-lm"
1115      LIBS="$LIBS $LIBM"
1116      AC_CHECK_FUNCS(pow,[],[LIBM=""])
1117     ])
1118 ])
1119 if test x"$LIBM" = x ; then
1120   AC_MSG_WARN([Unable to find working pow function - bgpd may not link])
1121 fi
1122 LIBS="$TMPLIBS"
1123 AC_SUBST(LIBM)
1124
1125 AC_CHECK_FUNCS([ppoll], [
1126   AC_DEFINE([HAVE_PPOLL], 1, [have Linux/BSD ppoll()])
1127 ])
1128 AC_CHECK_FUNCS([pollts], [
1129   AC_DEFINE([HAVE_POLLTS], 1, [have NetBSD pollts()])
1130 ])
1131
1132 dnl ---------------
1133 dnl other functions
1134 dnl ---------------
1135 AC_CHECK_FUNCS([ \
1136         strlcat strlcpy \
1137         getgrouplist])
1138
1139 AC_CHECK_HEADER([asm-generic/unistd.h],
1140                 [AC_CHECK_DECL(__NR_setns,
1141                                AC_DEFINE(HAVE_NETNS,, Have netns),,
1142                                FRR_INCLUDES [#include <asm-generic/unistd.h>
1143                                ])
1144                  AC_CHECK_FUNCS(setns)]
1145                )
1146
1147 dnl --------------------------
1148 dnl Determine IS-IS I/O method
1149 dnl --------------------------
1150 AC_DEFINE(ISIS_METHOD_PFPACKET, 1, [ constant value for isis method pfpacket ])
1151 AC_DEFINE(ISIS_METHOD_DLPI,     2, [ constant value for isis method dlpi ])
1152 AC_DEFINE(ISIS_METHOD_BPF,      3, [ constant value for isis method bpf ])
1153 AC_CHECK_HEADER(net/bpf.h)
1154 AC_CHECK_HEADER(sys/dlpi.h)
1155 AC_MSG_CHECKING(zebra IS-IS I/O method)
1156
1157 case "$host_os" in
1158   linux*)
1159     AC_MSG_RESULT(pfpacket)
1160     ISIS_METHOD_MACRO="ISIS_METHOD_PFPACKET"
1161     ;;
1162   solaris* | sunos*)
1163     AC_MSG_RESULT(DLPI)
1164     ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1165     ;;
1166   *)
1167     if test $ac_cv_header_net_bpf_h = no; then
1168       if test $ac_cv_header_sys_dlpi_h = no; then
1169         AC_MSG_RESULT(none)
1170         if test "${enable_isisd}" = yes; then
1171           AC_MSG_FAILURE([IS-IS support requested but no packet backend found])
1172         fi
1173         AC_MSG_WARN([*** IS-IS support will not be built ***])
1174         enable_isisd="no"
1175       else
1176         AC_MSG_RESULT(DLPI)
1177       fi
1178       ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1179     else
1180       AC_MSG_RESULT(BPF)
1181       ISIS_METHOD_MACRO="ISIS_METHOD_BPF"
1182     fi
1183     ;;
1184 esac
1185 AC_DEFINE_UNQUOTED(ISIS_METHOD, $ISIS_METHOD_MACRO, [ selected method for isis, == one of the constants ])
1186
1187 dnl ------------------------------------
1188 dnl check for broken CMSG_FIRSTHDR macro
1189 dnl ------------------------------------
1190 AC_MSG_CHECKING(for broken CMSG_FIRSTHDR)
1191 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1192 #ifdef SUNOS_5
1193 #define _XPG4_2
1194 #define __EXTENSIONS__
1195 #endif
1196 #include <stdlib.h>
1197 #include <sys/types.h>
1198 #include <sys/socket.h>
1199
1200 main()
1201 {
1202   struct msghdr msg;
1203   char buf[4];
1204
1205   msg.msg_control = buf;
1206   msg.msg_controllen = 0;
1207
1208   if (CMSG_FIRSTHDR(&msg) != NULL)
1209     exit(0);
1210   exit (1);
1211 }]])],[AC_MSG_RESULT(yes - using workaround) AC_DEFINE(HAVE_BROKEN_CMSG_FIRSTHDR,,Broken CMSG_FIRSTHDR)],
1212 [AC_MSG_RESULT(no)],[AC_MSG_RESULT(no)])
1213
1214 dnl ---------------------------------------------------------------
1215 dnl figure out how to specify an interface in multicast sockets API
1216 dnl ---------------------------------------------------------------
1217 AC_CHECK_MEMBERS([struct ip_mreqn.imr_ifindex], [], [], FRR_INCLUDES)
1218
1219 AC_CHECK_HEADERS([linux/mroute.h], [], [],[
1220         #include <sys/socket.h>
1221         #include <netinet/in.h>
1222         #define _LINUX_IN_H             /* For Linux <= 2.6.25 */
1223         #include <linux/types.h>
1224 ])
1225
1226 m4_define([FRR_INCLUDES],
1227 FRR_INCLUDES
1228 [#if HAVE_LINUX_MROUTE_H
1229 # include <linux/mroute.h>
1230 #endif
1231 ])dnl
1232
1233 AC_CHECK_HEADERS([netinet/ip_mroute.h], [], [],[
1234         #include <sys/socket.h>
1235         #include <sys/types.h>
1236         #include <netinet/in.h>
1237         #include <net/route.h>
1238 ])
1239
1240 m4_define([FRR_INCLUDES],
1241 FRR_INCLUDES
1242 [#if HAVE_NETINET_IP_MROUTE_H
1243 # include <netinet/ip_mroute.h>
1244 #endif
1245 ])dnl
1246
1247 AC_MSG_CHECKING([for BSD struct ip_mreq hack])
1248 AC_TRY_COMPILE([#include <sys/param.h>],
1249 [#if (defined(__FreeBSD__) && ((__FreeBSD_version >= 500022 && __FreeBSD_version < 700000) || (__FreeBSD_version < 500000 && __FreeBSD_version >= 440000))) || (defined(__NetBSD__) && defined(__NetBSD_Version__) && __NetBSD_Version__ >= 106010000) || defined(__OpenBSD__) || defined(__APPLE__) || defined(__DragonFly__) || defined(__sun)
1250   return (0);
1251 #else
1252   #error No support for BSD struct ip_mreq hack detected
1253 #endif],[AC_MSG_RESULT(yes)
1254 AC_DEFINE(HAVE_BSD_STRUCT_IP_MREQ_HACK,,[Can pass ifindex in struct ip_mreq])],
1255 AC_MSG_RESULT(no))
1256
1257 AC_MSG_CHECKING([for RFC3678 protocol-independed API])
1258 AC_TRY_COMPILE([
1259 #include <sys/types.h>
1260 #include <netinet/in.h>
1261 ], [struct group_req gr; int sock; setsockopt(sock, IPPROTO_IP, MCAST_JOIN_GROUP, (void*)&gr, sizeof(gr));
1262 ], [AC_MSG_RESULT(yes)
1263 AC_DEFINE(HAVE_RFC3678,1,[Have RFC3678 protocol-independed API])],
1264 AC_MSG_RESULT(no))
1265
1266 dnl ---------------------------------------------------------------
1267 dnl figure out how to check link-state
1268 dnl ---------------------------------------------------------------
1269 AC_CHECK_HEADER( [net/if_media.h],
1270   [m4_define([LINK_DETECT_INCLUDES],
1271     FRR_INCLUDES
1272     [#include <net/if_media.h>
1273   ])
1274   AC_CHECK_MEMBERS( [struct ifmediareq.ifm_status],
1275     AC_DEFINE(HAVE_BSD_LINK_DETECT,,[BSD link-detect]),
1276     [], LINK_DETECT_INCLUDES)],
1277   [],
1278   FRR_INCLUDES)
1279
1280 dnl ---------------------------------------------------------------
1281 dnl Additional, newer way to check link-state using ifi_link_state.
1282 dnl Not available in all BSD's when ifmediareq available
1283 dnl ---------------------------------------------------------------
1284 AC_CHECK_MEMBERS([struct if_data.ifi_link_state],
1285   AC_DEFINE(HAVE_BSD_IFI_LINK_STATE,,[BSD ifi_link_state available]),
1286   [], FRR_INCLUDES)
1287
1288 dnl ------------------------
1289 dnl TCP_MD5SIG socket option
1290 dnl ------------------------
1291
1292 AC_CHECK_HEADER([netinet/tcp.h],
1293    [m4_define([MD5_INCLUDES],
1294       FRR_INCLUDES
1295       [#include <netinet/tcp.h>
1296     ])
1297     AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)],
1298    [],
1299    FRR_INCLUDES)
1300 if test $ac_cv_have_decl_TCP_MD5SIG = no; then
1301   AC_CHECK_HEADER([linux/tcp.h],
1302        [m4_define([MD5_INCLUDES],
1303           FRR_INCLUDES
1304           [#include <linux/tcp.h>
1305         ])
1306        AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)])
1307 fi
1308
1309 dnl ----------------------------------------------------------------------------
1310 dnl figure out if domainname is available in the utsname struct (GNU extension).
1311 dnl ----------------------------------------------------------------------------
1312 AC_CHECK_MEMBERS([struct utsname.domainname], [], [], [#include <sys/utsname.h>])
1313
1314 dnl ------------------
1315 dnl IPv6 header checks
1316 dnl ------------------
1317 AC_CHECK_HEADERS([netinet6/in6.h netinet/in6_var.h \
1318         netinet6/in6_var.h netinet6/nd6.h], [], [],
1319         FRR_INCLUDES)
1320
1321 m4_define([FRR_INCLUDES],dnl
1322 FRR_INCLUDES
1323 [#if HAVE_NETINET6_IN6_H
1324 #include <netinet6/in6.h>
1325 #endif
1326 #if HAVE_NETINET_IN6_VAR_H
1327 #include <netinet/in6_var.h>
1328 #endif
1329 #include <netinet/icmp6.h>
1330 #if HAVE_NETINET6_IN6_VAR_H
1331 # include <netinet6/in6_var.h>
1332 #endif
1333 #if HAVE_NETINET6_ND6_H
1334 # include <netinet6/nd6.h>
1335 #endif
1336 ])dnl
1337
1338 dnl disable doc check
1339 if test "${enable_doc}" = "no";then
1340   DOC=""
1341 else
1342   DOC="doc"
1343 fi
1344
1345 dnl --------------------
1346 dnl Daemon disable check
1347 dnl --------------------
1348 AM_CONDITIONAL(ZEBRA, test "${enable_zebra}" != "no")
1349
1350 if test "${enable_bgpd}" = "no";then
1351   BGPD=""
1352 else
1353   BGPD="bgpd"
1354 fi
1355 AM_CONDITIONAL(BGPD, test "x$BGPD" = "xbgpd")
1356
1357 AM_CONDITIONAL(RIPD, test "${enable_ripd}" != "no")
1358 AM_CONDITIONAL(OSPFD, test "${enable_ospfd}" != "no")
1359 AM_CONDITIONAL(LDPD, test "${enable_ldpd}" != "no")
1360
1361 AS_IF([test "${enable_ldpd}" != "no"], [
1362   AC_DEFINE(HAVE_LDPD, 1, ldpd)
1363 ])
1364
1365 NHRPD=""
1366 case "$host_os" in
1367   linux*)
1368     if test "${enable_nhrpd}" != "no"; then
1369       NHRPD="nhrpd"
1370     fi
1371     ;;
1372   *)
1373     if test "${enable_nhrpd}" = "yes"; then
1374       AC_MSG_ERROR([nhrpd requires kernel APIs that are only present on Linux.])
1375     fi
1376     ;;
1377 esac
1378 AM_CONDITIONAL(NHRPD, test "x$NHRPD" = "xnhrpd")
1379
1380 AM_CONDITIONAL(EIGRPD, test "${enable_eigrpd}" != "no")
1381
1382 if test "${enable_watchfrr}" = "no";then
1383   WATCHFRR=""
1384 else
1385   WATCHFRR="watchfrr"
1386 fi
1387 AM_CONDITIONAL(WATCHFRR, test "x$WATCHFRR" = "xwatchfrr")
1388
1389 OSPFCLIENT=""
1390 if test "${enable_ospfapi}" != "no";then
1391     AC_DEFINE(SUPPORT_OSPF_API,,OSPFAPI)
1392
1393   if test "${enable_ospfclient}" != "no";then
1394       OSPFCLIENT="ospfclient"
1395   fi
1396 fi
1397
1398 AM_CONDITIONAL(OSPFCLIENT, test "x$OSPFCLIENT" = "xospfclient")
1399 AM_CONDITIONAL(RIPNGD, test "${enable_ripngd}" != "no")
1400 AM_CONDITIONAL(BABELD, test "${enable_babeld}" != "no")
1401 AM_CONDITIONAL(OSPF6D, test "${enable_ospf6d}" != "no")
1402 AM_CONDITIONAL(ISISD, test "${enable_isisd}" != "no")
1403 AM_CONDITIONAL(PIMD, test "${enable_pimd}" != "no")
1404 AM_CONDITIONAL(PBRD, test "${enable_pbrd}" != "no")
1405 AM_CONDITIONAL(SHARPD, test "${enable_sharpd}" = "yes")
1406
1407 if test "${enable_bgp_announce}" = "no";then
1408   AC_DEFINE(DISABLE_BGP_ANNOUNCE,1,Disable BGP installation to zebra)
1409 else
1410   AC_DEFINE(DISABLE_BGP_ANNOUNCE,0,Disable BGP installation to zebra)
1411 fi
1412
1413 if test "${with_rfp_path}" = "yes" || test x"${with_rfp_path}" = x""; then
1414   with_rfp_path="bgpd/rfp-example"
1415 fi
1416 if test "${with_rfp_path}" != "no"; then
1417   VNC_RFP_PATH="${with_rfp_path}"
1418   AC_SUBST(VNC_RFP_PATH)
1419 fi
1420
1421 if test "${enable_bgp_vnc}" != "no";then
1422   AC_DEFINE(ENABLE_BGP_VNC,1,Enable BGP VNC support)
1423   RFPTEST="${with_rfp_path}/rfptest"
1424   LIBRFP="${with_rfp_path}/librfp"
1425   RFPINC="${with_rfp_path}/librfp"
1426 else
1427   RFPTEST=
1428   LIBRFP=
1429   RFPINC="bgpd/rfp-example/librfp"
1430 fi
1431 # set
1432 AM_CONDITIONAL([ENABLE_BGP_VNC], [test x${enable_bgp_vnc} != xno])
1433
1434 AC_SUBST(DOC)
1435 AC_SUBST(RFPTEST)
1436 AC_SUBST(LIBRFP)
1437 AC_SUBST(RFPINC)
1438 AC_SUBST(BGPD)
1439 AC_SUBST(SOLARIS)
1440 AC_SUBST(VTYSH)
1441 AC_SUBST(CURSES)
1442 AC_CHECK_LIB(crypt, crypt, [],
1443                     [AC_CHECK_LIB(crypto, DES_crypt)])
1444 AC_CHECK_LIB(resolv, res_init)
1445
1446 dnl ---------------------------
1447 dnl check system has PCRE regexp
1448 dnl ---------------------------
1449 if test "x$enable_pcreposix" = "xyes"; then
1450   AC_CHECK_LIB(pcreposix, regexec, [], [
1451     AC_MSG_ERROR([--enable-pcreposix given but unable to find libpcreposix])
1452   ])
1453 fi
1454 AC_SUBST(HAVE_LIBPCREPOSIX)
1455
1456 dnl ------------------
1457 dnl check C-Ares library
1458 dnl ------------------
1459 if test "${NHRPD}" != ""; then
1460   PKG_CHECK_MODULES([CARES], [libcares], , [
1461     AC_MSG_ERROR([trying to build nhrpd, but libcares not found. install c-ares and its -dev headers.])
1462   ])
1463 fi
1464
1465
1466 dnl ------------------
1467 dnl check Net-SNMP library
1468 dnl ------------------
1469 if test "${enable_snmp}" != "" -a "${enable_snmp}" != "no"; then
1470    AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], [no])
1471    if test x"$NETSNMP_CONFIG" = x"no"; then
1472       AC_MSG_ERROR([--enable-snmp given but unable to find net-snmp-config])
1473    fi
1474    SNMP_LIBS="`${NETSNMP_CONFIG} --agent-libs`"
1475    SNMP_CFLAGS="`${NETSNMP_CONFIG} --base-cflags`"
1476    AC_MSG_CHECKING([whether we can link to Net-SNMP])
1477    AC_LINK_IFELSE_FLAGS([$SNMP_CFLAGS], [$SNMP_LIBS], [AC_LANG_PROGRAM([
1478 int main(void);
1479 ],
1480 [
1481 {
1482   return 0;
1483 }
1484 ])], [
1485      AC_MSG_ERROR([--enable-snmp given but not usable])])
1486    case "${enable_snmp}" in
1487      yes)
1488       SNMP_METHOD=agentx
1489       ;;
1490      smux|agentx)
1491       SNMP_METHOD="${enable_snmp}"
1492       ;;
1493      *)
1494       AC_MSG_ERROR([--enable-snmp given with an unknown method (${enable_snmp}). Use smux or agentx])
1495       ;;
1496    esac
1497    AH_TEMPLATE([SNMP_SMUX], [Use SNMP SMUX to interface with snmpd])
1498    AH_TEMPLATE([SNMP_AGENTX], [Use SNMP AgentX to interface with snmpd])
1499    AC_DEFINE_UNQUOTED(AS_TR_CPP(SNMP_${SNMP_METHOD}),,SNMP method to interface with snmpd)
1500 fi
1501 AM_CONDITIONAL([SNMP], [test "x${SNMP_METHOD}" != "x"])
1502 AC_SUBST(SNMP_LIBS)
1503 AC_SUBST(SNMP_CFLAGS)
1504
1505 dnl ---------------
1506 dnl math
1507 dnl ---------------
1508 AC_SEARCH_LIBS([sqrt], [m])
1509
1510 dnl ---------------
1511 dnl dlopen & dlinfo
1512 dnl ---------------
1513 AC_SEARCH_LIBS(dlopen, [dl dld], [], [
1514   AC_MSG_ERROR([unable to find the dlopen()])
1515 ])
1516
1517 AC_CHECK_HEADERS([link.h])
1518
1519 AC_MSG_CHECKING([for dlinfo(RTLD_DI_ORIGIN)])
1520 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1521 #include <stdlib.h>
1522 #ifdef HAVE_LINK_H
1523 #include <link.h>
1524 #endif
1525 #include <dlfcn.h>
1526 ]], [[
1527   char origin[1];
1528   dlinfo (NULL, RTLD_DI_ORIGIN, &origin);
1529 ]])], [
1530   AC_MSG_RESULT(yes)
1531   AC_DEFINE(HAVE_DLINFO_ORIGIN, 1, [Have dlinfo RTLD_DI_ORIGIN])
1532 ], [
1533   AC_MSG_RESULT(no)
1534 ])
1535
1536 AC_MSG_CHECKING([for dlinfo(RTLD_DI_LINKMAP)])
1537 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1538 #include <stdlib.h>
1539 #ifdef HAVE_LINK_H
1540 #include <link.h>
1541 #endif
1542 #include <dlfcn.h>
1543 ]], [[
1544   struct link_map *lm = NULL;
1545   dlinfo (NULL, RTLD_DI_LINKMAP, &lm);
1546 ]])], [
1547   AC_MSG_RESULT(yes)
1548   AC_DEFINE(HAVE_DLINFO_LINKMAP, 1, [Have dlinfo RTLD_DI_LINKMAP])
1549 ], [
1550   AC_MSG_RESULT(no)
1551 ])
1552
1553
1554 AM_CONDITIONAL(SNMP, test "x$SNMP_METHOD" = "xagentx")
1555
1556 dnl ---------------------------
1557 dnl sockaddr and netinet checks
1558 dnl ---------------------------
1559 AC_CHECK_TYPES([
1560         struct sockaddr_dl,
1561         struct vifctl, struct mfcctl, struct sioc_sg_req,
1562         vifi_t, struct sioc_vif_req, struct igmpmsg,
1563         struct ifaliasreq, struct if6_aliasreq, struct in6_aliasreq,
1564         struct nd_opt_adv_interval, struct rt_addrinfo,
1565         struct nd_opt_homeagent_info, struct nd_opt_adv_interval],
1566         [], [], FRR_INCLUDES)
1567
1568 AC_CHECK_MEMBERS([struct sockaddr.sa_len,
1569         struct sockaddr_in.sin_len, struct sockaddr_un.sun_len,
1570         struct sockaddr_dl.sdl_len,
1571         struct if6_aliasreq.ifra_lifetime,
1572         struct nd_opt_adv_interval.nd_opt_ai_type],
1573         [], [], FRR_INCLUDES)
1574
1575 dnl ---------------------------
1576 dnl IRDP/pktinfo/icmphdr checks
1577 dnl ---------------------------
1578
1579 AC_CHECK_TYPES([struct in_pktinfo], [
1580   AC_CHECK_TYPES([struct icmphdr], [
1581     IRDP=true
1582   ], [
1583     IRDP=false
1584   ], [FRR_INCLUDES])
1585 ], [
1586   IRDP=false
1587 ], [FRR_INCLUDES])
1588
1589 case "${enable_irdp}" in
1590 yes)
1591   $IRDP || AC_MSG_ERROR(['IRDP requires in_pktinfo at the moment!'])
1592   ;;
1593 no)
1594   IRDP=false
1595   ;;
1596 esac
1597
1598 AM_CONDITIONAL(IRDP, $IRDP)
1599
1600 dnl -----------------------
1601 dnl checking for IP_PKTINFO
1602 dnl -----------------------
1603 AC_MSG_CHECKING(for IP_PKTINFO)
1604 AC_TRY_COMPILE([#include <netdb.h>], [
1605   int opt = IP_PKTINFO;
1606 ], [
1607   AC_MSG_RESULT(yes)
1608   AC_DEFINE(HAVE_IP_PKTINFO, 1, [Have IP_PKTINFO])
1609 ], [
1610   AC_MSG_RESULT(no)
1611 ])
1612
1613 dnl ---------------------------
1614 dnl checking for IP_RECVDSTADDR
1615 dnl ---------------------------
1616 AC_MSG_CHECKING(for IP_RECVDSTADDR)
1617 AC_TRY_COMPILE([#include <netinet/in.h>], [
1618   int opt = IP_RECVDSTADDR;
1619 ], [
1620   AC_MSG_RESULT(yes)
1621   AC_DEFINE(HAVE_IP_RECVDSTADDR, 1, [Have IP_RECVDSTADDR])
1622 ], [
1623   AC_MSG_RESULT(no)
1624 ])
1625
1626 dnl ----------------------
1627 dnl checking for IP_RECVIF
1628 dnl ----------------------
1629 AC_MSG_CHECKING(for IP_RECVIF)
1630 AC_TRY_COMPILE([#include <netinet/in.h>], [
1631   int opt = IP_RECVIF;
1632 ], [
1633   AC_MSG_RESULT(yes)
1634   AC_DEFINE(HAVE_IP_RECVIF, 1, [Have IP_RECVIF])
1635 ], [
1636   AC_MSG_RESULT(no)
1637 ])
1638
1639 dnl ----------------------
1640 dnl checking for SO_BINDANY
1641 dnl ----------------------
1642 AC_MSG_CHECKING(for SO_BINDANY)
1643 AC_TRY_COMPILE([#include <sys/socket.h>], [
1644   int opt = SO_BINDANY;
1645 ], [
1646   AC_MSG_RESULT(yes)
1647   AC_DEFINE(HAVE_SO_BINDANY, 1, [Have SO_BINDANY])
1648 ], [
1649   AC_MSG_RESULT(no)
1650 ])
1651
1652 dnl ----------------------
1653 dnl checking for IP_FREEBIND
1654 dnl ----------------------
1655 AC_MSG_CHECKING(for IP_FREEBIND)
1656 AC_TRY_COMPILE([#include <netinet/in.h>], [
1657   int opt = IP_FREEBIND;
1658 ], [
1659   AC_MSG_RESULT(yes)
1660   AC_DEFINE(HAVE_IP_FREEBIND, 1, [Have IP_FREEBIND])
1661 ], [
1662   AC_MSG_RESULT(no)
1663 ])
1664
1665 dnl --------------------------------------
1666 dnl checking for be32dec existence or not
1667 dnl --------------------------------------
1668 AC_CHECK_DECLS([be32enc, be32dec], [], [],
1669                [#include <sys/endian.h>])
1670
1671 dnl --------------------------------------
1672 dnl checking for clock_time monotonic struct and call
1673 dnl --------------------------------------
1674 AC_CHECK_DECL(CLOCK_MONOTONIC,
1675         [AC_CHECK_LIB(rt, clock_gettime, [LIBS="$LIBS -lrt"])
1676          AC_DEFINE(HAVE_CLOCK_MONOTONIC,, Have monotonic clock)
1677 ], [AC_MSG_RESULT(no)], [FRR_INCLUDES])
1678
1679 dnl --------------------------------------
1680 dnl checking for flex and bison
1681 dnl --------------------------------------
1682
1683 AM_PROG_LEX
1684 AC_MSG_CHECKING(version of flex)
1685 frr_ac_flex_version="$(eval $LEX -V | grep flex | head -n 1)"
1686 frr_ac_flex_version="${frr_ac_flex_version##* }"
1687 AC_MSG_RESULT([$frr_ac_flex_version])
1688 AX_COMPARE_VERSION([$frr_ac_flex_version], [lt], [2.5.20], [
1689   LEX="$SHELL $missing_dir/missing flex"
1690   if test -f "${srcdir}/lib/command_lex.c" -a -f "${srcdir}/lib/command_lex.h"; then
1691     AC_MSG_WARN([using pregenerated flex output files])
1692   else
1693     AC_MSG_ERROR([flex failure and pregenerated files not included (probably a git build)])
1694   fi
1695   AC_SUBST([LEX_OUTPUT_ROOT], [lex.yy])
1696   AC_SUBST([LEXLIB], [''])
1697 ])
1698
1699 AC_PROG_YACC
1700 dnl thanks GNU bison for this b*llshit...
1701 AC_MSG_CHECKING(version of bison)
1702 frr_ac_bison_version="$(eval $YACC -V | grep bison | head -n 1)"
1703 frr_ac_bison_version="${frr_ac_bison_version##* }"
1704 frr_ac_bison_missing="false"
1705 case "x${frr_ac_bison_version}" in
1706   x2.7*)
1707     BISON_OPENBRACE='"'
1708     BISON_CLOSEBRACE='"'
1709     BISON_VERBOSE=''
1710     AC_MSG_RESULT([$frr_ac_bison_version - 2.7 or older])
1711     ;;
1712   x2.*|x1.*)
1713     AC_MSG_RESULT([$frr_ac_bison_version])
1714     AC_MSG_WARN([installed bison is too old.  Please install GNU bison 2.7.x or newer.])
1715     frr_ac_bison_missing="true"
1716     ;;
1717   x)
1718     AC_MSG_RESULT([none])
1719     AC_MSG_WARN([could not determine bison version.  Please install GNU bison 2.7.x or newer.])
1720     frr_ac_bison_missing="true"
1721     ;;
1722   *)
1723     BISON_OPENBRACE='{'
1724     BISON_CLOSEBRACE='}'
1725     BISON_VERBOSE='-Dparse.error=verbose'
1726     AC_MSG_RESULT([$frr_ac_bison_version - 3.0 or newer])
1727     ;;
1728 esac
1729 AC_SUBST(BISON_OPENBRACE)
1730 AC_SUBST(BISON_CLOSEBRACE)
1731 AC_SUBST(BISON_VERBOSE)
1732
1733 if $frr_ac_bison_missing; then
1734   YACC="$SHELL $missing_dir/missing bison -y"
1735   if test -f "${srcdir}/lib/command_parse.c" -a -f "${srcdir}/lib/command_parse.h"; then
1736     AC_MSG_WARN([using pregenerated bison output files])
1737   else
1738     AC_MSG_ERROR([bison failure and pregenerated files not included (probably a git build)])
1739   fi
1740 fi
1741
1742 dnl -------------------
1743 dnl capabilities checks
1744 dnl -------------------
1745 if test "${enable_capabilities}" != "no"; then
1746   AC_MSG_CHECKING(whether prctl PR_SET_KEEPCAPS is available)
1747   AC_TRY_COMPILE([#include <sys/prctl.h>],[prctl(PR_SET_KEEPCAPS, 1, 0, 0, 0);],
1748     [AC_MSG_RESULT(yes)
1749      AC_DEFINE(HAVE_PR_SET_KEEPCAPS,,prctl)
1750      frr_ac_keepcaps="yes"],
1751      AC_MSG_RESULT(no)
1752   )
1753   if test x"${frr_ac_keepcaps}" = x"yes"; then
1754     AC_CHECK_HEADERS(sys/capability.h)
1755   fi
1756   if test x"${ac_cv_header_sys_capability_h}" = x"yes"; then
1757     AC_CHECK_LIB(cap, cap_init,
1758       [AC_DEFINE(HAVE_LCAPS,1,Capabilities)
1759        LIBCAP="-lcap"
1760        frr_ac_lcaps="yes"]
1761     )
1762   else
1763     AC_CHECK_HEADERS(priv.h,
1764      [AC_MSG_CHECKING(Solaris style privileges are available)
1765       AC_TRY_COMPILE([#include <priv.h>],[getpflags(PRIV_AWARE);],
1766           [AC_MSG_RESULT(yes)
1767            AC_DEFINE(HAVE_SOLARIS_CAPABILITIES,1,getpflags)
1768            frr_ac_scaps="yes"],
1769            AC_MSG_RESULT(no)
1770       )
1771      ]
1772    )
1773   fi
1774   if test x"${frr_ac_scaps}" = x"yes" \
1775        -o x"${frr_ac_lcaps}" = x"yes"; then
1776     AC_DEFINE(HAVE_CAPABILITIES,1,capabilities)
1777   fi
1778 fi
1779 AC_SUBST(LIBCAP)
1780
1781 dnl ---------------------------
1782 dnl check for glibc 'backtrace'
1783 dnl ---------------------------
1784 if test x"${enable_backtrace}" != x"no" ; then
1785   backtrace_ok=no
1786   AC_CHECK_HEADER([execinfo.h], [
1787     AC_SEARCH_LIBS([backtrace], [execinfo], [
1788       AC_DEFINE(HAVE_GLIBC_BACKTRACE,,[Glibc backtrace])
1789       AC_DEFINE(HAVE_STACK_TRACE,,[Stack symbol decoding])
1790       backtrace_ok=yes
1791     ],, [-lm])
1792   ])
1793
1794   if test x"${enable_backtrace}" = x"yes" -a x"${backtrace_ok}" = x"no"; then
1795     dnl user explicitly requested backtrace but we failed to find support
1796     AC_MSG_FAILURE([failed to find backtrace support])
1797   fi
1798 fi
1799
1800 dnl -----------------------------------------
1801 dnl check for malloc mallinfo struct and call
1802 dnl this must try and link using LIBS, in
1803 dnl order to check no alternative allocator
1804 dnl has been specified, which might not provide
1805 dnl mallinfo, e.g. such as Umem on Solaris.
1806 dnl -----------------------------------------
1807 AC_CHECK_HEADER([malloc.h],
1808  [AC_MSG_CHECKING(whether mallinfo is available)
1809   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <malloc.h>]],
1810                         [[struct mallinfo ac_x; ac_x = mallinfo ();]])],
1811       [AC_MSG_RESULT(yes)
1812        AC_DEFINE(HAVE_MALLINFO,,mallinfo)],
1813        AC_MSG_RESULT(no)
1814   )
1815  ], [], FRR_INCLUDES)
1816
1817 dnl ------
1818 dnl ZeroMQ
1819 dnl ------
1820 if test "x$enable_zeromq" != "xno"; then
1821   PKG_CHECK_MODULES(ZEROMQ, [libzmq >= 4.0.0], [
1822     AC_DEFINE(HAVE_ZEROMQ, 1, [Enable ZeroMQ support])
1823     ZEROMQ=true
1824   ], [
1825     if test "x$enable_zeromq" = "xyes"; then
1826       AC_MSG_ERROR([configuration specifies --enable-zeromq but libzmq was not found])
1827     fi
1828   ])
1829 fi
1830 AM_CONDITIONAL([ZEROMQ], test "x$ZEROMQ" = "xtrue")
1831
1832 dnl ----------
1833 dnl configure date
1834 dnl ----------
1835 dev_version=`echo $VERSION | grep dev`
1836 #don't expire deprecated code in non 'dev' branch
1837 if test "${dev_version}" = ""; then
1838    CONFDATE=0
1839 else
1840    CONFDATE=`date '+%Y%m%d'`
1841 fi
1842 AC_SUBST(CONFDATE)
1843
1844 dnl ------------------------------
1845 dnl set paths for state directory
1846 dnl ------------------------------
1847 AC_MSG_CHECKING(directory to use for state file)
1848 if test "${prefix}" = "NONE"; then
1849   frr_statedir_prefix="";
1850 else
1851   frr_statedir_prefix=${prefix}
1852 fi
1853 if test "${localstatedir}" = '${prefix}/var'; then
1854   for FRR_STATE_DIR in ${frr_statedir_prefix}/var/run dnl
1855                         ${frr_statedir_prefix}/var/adm dnl
1856                         ${frr_statedir_prefix}/etc dnl
1857                         /var/run        dnl
1858                         /var/adm        dnl
1859                         /etc            dnl
1860                         /dev/null;
1861   do
1862     test -d $FRR_STATE_DIR && break
1863   done
1864   frr_statedir=$FRR_STATE_DIR
1865 else
1866   frr_statedir=${localstatedir}
1867 fi
1868 if test $frr_statedir = "/dev/null"; then
1869     AC_MSG_ERROR('STATE DIRECTORY NOT FOUND! FIX OR SPECIFY --localstatedir!')
1870 fi
1871 AC_MSG_RESULT(${frr_statedir})
1872 AC_SUBST(frr_statedir)
1873
1874 AC_DEFINE_UNQUOTED(LDPD_SOCKET, "$frr_statedir/ldpd.sock",ldpd control socket)
1875 AC_DEFINE_UNQUOTED(ZEBRA_SERV_PATH, "$frr_statedir/zserv.api",zebra api socket)
1876 AC_DEFINE_UNQUOTED(DAEMON_VTY_DIR, "$frr_statedir",daemon vty directory)
1877
1878 dnl autoconf does this, but it does it too late...
1879 test "x$prefix" = xNONE && prefix=$ac_default_prefix
1880 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
1881
1882 dnl get the full path, recursing through variables...
1883 vtysh_bin="$bindir/vtysh"
1884 for I in 1 2 3 4 5 6 7 8 9 10; do
1885         eval vtysh_bin="\"$vtysh_bin\""
1886 done
1887 AC_DEFINE_UNQUOTED(VTYSH_BIN_PATH, "$vtysh_bin",path to vtysh binary)
1888
1889 CFG_SYSCONF="$sysconfdir"
1890 CFG_SBIN="$sbindir"
1891 CFG_STATE="$frr_statedir"
1892 CFG_MODULE="$moduledir"
1893 for I in 1 2 3 4 5 6 7 8 9 10; do
1894         eval CFG_SYSCONF="\"$CFG_SYSCONF\""
1895         eval CFG_SBIN="\"$CFG_SBIN\""
1896         eval CFG_STATE="\"$CFG_STATE\""
1897         eval CFG_MODULE="\"$CFG_MODULE\""
1898 done
1899 AC_SUBST(CFG_SYSCONF)
1900 AC_SUBST(CFG_SBIN)
1901 AC_SUBST(CFG_STATE)
1902 AC_SUBST(CFG_MODULE)
1903 AC_DEFINE_UNQUOTED(MODULE_PATH, "$CFG_MODULE", path to modules)
1904
1905 dnl ------------------------------------
1906 dnl Enable RPKI and add librtr to libs
1907 dnl ------------------------------------
1908 if test "${enable_rpki}" = "yes"; then
1909   PKG_CHECK_MODULES(RTRLIB,[rtrlib >= 0.5.0],
1910       [AC_DEFINE(HAVE_RPKI,1,Enable RPKI prefix validation for BGP)
1911       RPKI=true],
1912       [RPKI=false
1913       AC_MSG_ERROR([rtrlib was not found on your system or is too old.])]
1914   )
1915 fi
1916 AM_CONDITIONAL([RPKI], test "x$RPKI" = "xtrue")
1917
1918 dnl ------------------------------------------
1919 dnl Check whether rtrlib was build with ssh support
1920 dnl ------------------------------------------
1921 AC_MSG_CHECKING([whether the RTR Library is compiled with SSH])
1922 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "rtrlib/rtrlib.h"]],
1923                         [[struct tr_ssh_config config;]])],
1924         [AC_MSG_RESULT(yes)
1925         AC_DEFINE(FOUND_SSH,,found_ssh)],
1926         AC_MSG_RESULT(no)
1927 )
1928
1929 dnl ---------------------------
1930 dnl Check htonl works correctly
1931 dnl ---------------------------
1932 AC_MSG_CHECKING(for working htonl)
1933 AC_CACHE_VAL(ac_cv_htonl_works,
1934  [AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES],[htonl (0);])],
1935                 [ac_cv_htonl_works=yes], [ac_cv_htonl_works=no])
1936  ]
1937 )
1938 AC_MSG_RESULT($ac_cv_htonl_works)
1939
1940 AC_CONFIG_FILES([Makefile
1941           bgpd/Makefile
1942           vtysh/Makefile
1943           doc/Makefile
1944           doc/user/Makefile
1945           doc/manpages/Makefile
1946           doc/developer/Makefile
1947           tests/Makefile
1948           bgpd/rfp-example/rfptest/Makefile
1949           bgpd/rfp-example/librfp/Makefile
1950           redhat/frr.spec
1951           debianpkg/Makefile
1952           debianpkg/changelog
1953           alpine/APKBUILD
1954           snapcraft/snapcraft.yaml
1955           lib/version.h
1956           tests/lib/cli/test_cli.refout
1957           pkgsrc/bgpd.sh pkgsrc/ospf6d.sh pkgsrc/ospfd.sh
1958           pkgsrc/ripd.sh pkgsrc/ripngd.sh pkgsrc/zebra.sh
1959           pkgsrc/eigrpd.sh])
1960
1961 if test "${enable_bgp_vnc}" != "no"; then
1962    if test "${with_rfp_path}" != "bgpd/rfp-example" ; then
1963       AC_CONFIG_FILES([${with_rfp_path}/rfptest/Makefile ${with_rfp_path}/librfp/Makefile])
1964    fi
1965 fi
1966
1967 AC_CONFIG_FILES([solaris/Makefile])
1968
1969 AC_CONFIG_FILES([vtysh/extract.pl],[chmod +x vtysh/extract.pl])
1970
1971 AC_CONFIG_COMMANDS([lib/route_types.h], [
1972         dst="${ac_abs_top_builddir}/lib/route_types.h"
1973         ${PERL} "${ac_abs_top_srcdir}/lib/route_types.pl" \
1974                 < "${ac_abs_top_srcdir}/lib/route_types.txt" \
1975                 > "${dst}.tmp"
1976         test -f "${dst}" \
1977                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
1978                 && rm "${dst}.tmp" \
1979                 || mv "${dst}.tmp" "${dst}"
1980 ], [
1981         PERL="$PERL"
1982 ])
1983
1984 AS_IF([test "x$with_pkg_git_version" = "xyes"], [
1985     AC_CONFIG_COMMANDS([lib/gitversion.h], [
1986         dst="${ac_abs_top_builddir}/lib/gitversion.h"
1987         ${PERL} "${ac_abs_top_srcdir}/lib/gitversion.pl" \
1988                 "${ac_abs_top_srcdir}" \
1989                 > "${dst}.tmp"
1990         test -f "${dst}" \
1991                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
1992                 && rm "${dst}.tmp" \
1993                 || mv "${dst}.tmp" "${dst}"
1994     ], [
1995         PERL="$PERL"
1996     ])
1997 ])
1998
1999 ## Hack, but working solution to avoid rebuilding of frr.info.
2000 ## It's already in CVS until texinfo 4.7 is more common.
2001 AC_OUTPUT
2002
2003 echo "
2004 FRRouting configuration
2005 ------------------------------
2006 FRR version             : ${PACKAGE_VERSION}
2007 host operating system   : ${host_os}
2008 source code location    : ${srcdir}
2009 compiler                : ${CC}
2010 compiler flags          : ${CFLAGS}
2011 make                    : ${MAKE-make}
2012 linker flags            : ${LDFLAGS} ${LIBS} ${LIBCAP} ${LIBREADLINE} ${LIBM}
2013 state file directory    : ${frr_statedir}
2014 config file directory   : `eval echo \`echo ${sysconfdir}\``
2015 example directory       : `eval echo \`echo ${exampledir}\``
2016 module directory        : ${CFG_MODULE}
2017 user to run as          : ${enable_user}
2018 group to run as         : ${enable_group}
2019 group for vty sockets   : ${enable_vty_group}
2020 config file mask        : ${enable_configfile_mask}
2021 log file mask           : ${enable_logfile_mask}
2022 zebra protobuf enabled  : ${have_protobuf:-no}
2023
2024 The above user and group must have read/write access to the state file
2025 directory and to the config files in the config file directory."