configure.ac

   1 ##
   2 ## Configure template file for FRRouting.
   3 ## autoconf will generate a configure script.
   4 ##
   5 ##  Copyright (c) 1996, 97, 98, 99, 2000 Kunihiro Ishiguro <kunihiro@zebra.org>
   6 ##  Portions Copyright (c) 2003 Paul Jakma <paul@dishone.st>
   7 ##
   8 AC_PREREQ([2.60])
   9
  10 AC_INIT([frr], [7.2-dev], [https://github.com/frrouting/frr/issues])
  11 PACKAGE_URL="https://frrouting.org/"
  12 AC_SUBST([PACKAGE_URL])
  13 PACKAGE_FULLNAME="FRRouting"
  14 AC_SUBST([PACKAGE_FULLNAME])
  15
  16 CONFIG_ARGS="`echo $ac_configure_args | sed -e \"s% '[[A-Z]]*FLAGS=[[^']]\+'%%g\"`"
  17 AC_SUBST([CONFIG_ARGS])
  18
  19 AC_CONFIG_SRCDIR([lib/zebra.h])
  20 AC_CONFIG_MACRO_DIR([m4])
  21
  22 dnl -----------------------------------
  23 dnl Get hostname and other information.
  24 dnl -----------------------------------
  25 AC_CANONICAL_BUILD()
  26 AC_CANONICAL_HOST()
  27
  28 AS_IF([test "$host" != "$build"], [
  29   if test "$srcdir" = "."; then
  30     AC_MSG_ERROR([cross-compilation is only possible with builddir separate from srcdir.  create a separate directory and run as .../path-to-frr/configure.])
  31   fi
  32   test -d hosttools || mkdir hosttools
  33   abssrc="`cd \"${srcdir}\"; pwd`"
  34
  35   AC_MSG_NOTICE([...])
  36   AC_MSG_NOTICE([... cross-compilation: creating hosttools directory and self-configuring for build platform tools])
  37   AC_MSG_NOTICE([... use HOST_CPPFLAGS / HOST_CFLAGS / HOST_LDFLAGS if neccessary])
  38   AC_MSG_NOTICE([...])
  39
  40   ( CPPFLAGS="$HOST_CPPFLAGS"; \
  41     CFLAGS="$HOST_CFLAGS"; \
  42     LDFLAGS="$HOST_LDFLAGS"; \
  43     cd hosttools; "${abssrc}/configure" "--host=$build" "--build=$build" "--enable-clippy-only" "--disable-nhrpd" "--disable-vtysh"; )
  44
  45   AC_MSG_NOTICE([...])
  46   AC_MSG_NOTICE([... cross-compilation: finished self-configuring for build platform tools])
  47   AC_MSG_NOTICE([...])
  48
  49   build_clippy="false"
  50   HOSTTOOLS="hosttools/"
  51 ], [
  52   build_clippy="true"
  53   HOSTTOOLS=""
  54 ])
  55 AC_SUBST([HOSTTOOLS])
  56 AM_CONDITIONAL([BUILD_CLIPPY], [$build_clippy])
  57
  58 # Disable portability warnings -- our automake code (in particular
  59 # common.am) uses some constructs specific to gmake.
  60 AM_INIT_AUTOMAKE([1.12 -Wno-portability foreign])
  61 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
  62 AM_SILENT_RULES([yes])
  63 AC_CONFIG_HEADERS([config.h])
  64
  65 AC_PATH_PROG([PERL], [perl])
  66 PKG_PROG_PKG_CONFIG
  67
  68 dnl default is to match previous behavior
  69 exampledir=${sysconfdir}
  70 AC_ARG_ENABLE([exampledir],
  71           AS_HELP_STRING([--enable-exampledir],
  72                          [specify alternate directory for examples]),
  73                          exampledir="$enableval",)
  74 dnl XXX add --exampledir to autoconf standard directory list somehow
  75 AC_SUBST([exampledir])
  76
  77 dnl default is to match previous behavior
  78 pkgsrcrcdir=""
  79 AC_ARG_ENABLE([pkgsrcrcdir],
  80           AS_HELP_STRING([--enable-pkgsrcrcdir],
  81                          [specify directory for rc.d scripts]),
  82                          pkgsrcrcdir="$enableval",)
  83 dnl XXX add --pkgsrcrcdir to autoconf standard directory list somehow
  84 AC_SUBST([pkgsrcrcdir])
  85 AM_CONDITIONAL([PKGSRC], [test "x$pkgsrcrcdir" != "x"])
  86
  87 AC_ARG_WITH([moduledir], [AS_HELP_STRING([--with-moduledir=DIR], [module directory (${libdir}/frr/modules)])], [
  88         moduledir="$withval"
  89 ], [
  90         moduledir="\${libdir}/frr/modules"
  91 ])
  92 AC_SUBST([moduledir], [$moduledir])
  93
  94
  95 AC_ARG_WITH([yangmodelsdir], [AS_HELP_STRING([--with-yangmodelsdir=DIR], [yang models directory (${datarootdir}/yang)])], [
  96         yangmodelsdir="$withval"
  97 ], [
  98         yangmodelsdir="\${datarootdir}/yang"
  99 ])
 100 AC_SUBST([yangmodelsdir])
 101
 102 AC_ARG_WITH([libyang_pluginsdir], [AS_HELP_STRING([--with-libyang-pluginsdir=DIR], [yangmodule plugins directory (${libdir}/frr/libyang_plugins)])], [
 103         libyang_pluginsdir="$withval"
 104 ], [
 105    libyang_pluginsdir="\${libdir}/frr/libyang_plugins"
 106 ])
 107 AC_SUBST([libyang_pluginsdir])
 108
 109 AC_ARG_ENABLE(tcmalloc,
 110         AS_HELP_STRING([--enable-tcmalloc], [Turn on tcmalloc]),
 111 [case "${enableval}" in
 112   yes) tcmalloc_enabled=true
 113 LIBS="$LIBS -ltcmalloc_minimal"
 114  ;;
 115   no)  tcmalloc_enabled=false ;;
 116   *) AC_MSG_ERROR([bad value ${enableval} for --enable-tcmalloc]) ;;
 117 esac],[tcmalloc_enabled=false])
 118
 119
 120 dnl Thanks autoconf, but we don't want a default -g -O2.  We have our own
 121 dnl flag determination logic.
 122 CFLAGS="${CFLAGS:-}"
 123
 124 dnl --------------------
 125 dnl Check CC and friends
 126 dnl --------------------
 127 dnl note orig_cflags is also used further down
 128 orig_cflags="$CFLAGS"
 129 orig_cxxflags="$CXXFLAGS"
 130 AC_LANG([C])
 131 AC_PROG_CC
 132 AC_PROG_CPP
 133 AC_PROG_CXX
 134 AM_PROG_CC_C_O
 135 dnl remove autoconf default "-g -O2"
 136 CFLAGS="$orig_cflags"
 137 CXXFLAGS="$orig_cxxflags"
 138 AC_PROG_CC_C99
 139 dnl NB: see C11 below
 140
 141 AC_PROG_EGREP
 142 PKG_PROG_PKG_CONFIG
 143
 144 dnl autoconf 2.59 appears not to support AC_PROG_SED
 145 dnl AC_PROG_SED
 146 AC_CHECK_PROG([SED],[sed],[sed],[/bin/false])
 147
 148 dnl try and enable CFLAGS that are useful for FRR
 149 dnl - specifically, options to control warnings
 150
 151 AC_USE_SYSTEM_EXTENSIONS
 152 AC_DEFUN([AC_C_FLAG], [{
 153     m4_pushdef([cachename],[m4_translit([frr_cv_$1],[ =-+],[____])])
 154     AC_CACHE_CHECK([[whether $CC supports $1]], cachename, [
 155         AC_LANG_PUSH([C])
 156         ac_c_flag_save="$CFLAGS"
 157         CFLAGS="$CFLAGS $1"
 158         AC_COMPILE_IFELSE(
 159                 [AC_LANG_PROGRAM([[]])],
 160                 [
 161                         cachename=yes
 162                 ], [
 163                         cachename=no
 164                 ])
 165         CFLAGS="$ac_c_flag_save"
 166         AC_LANG_POP([C])
 167     ])
 168     if test "${cachename}" = yes; then
 169         m4_if([$3], [], [CFLAGS="$CFLAGS $1"], [$3])
 170     else
 171         :
 172         $2
 173     fi
 174     m4_popdef([cachename])
 175 }])
 176
 177 AC_DEFUN([AC_LINK_IFELSE_FLAGS], [{
 178         AC_LANG_PUSH([C])
 179         ac_cflags_save="$CFLAGS"
 180         ac_libs_save="$LIBS"
 181         CFLAGS="$CFLAGS $1"
 182         LIBS="$LIBS $2"
 183         AC_LINK_IFELSE(
 184                 [$3],
 185                 [
 186                         AC_MSG_RESULT([yes])
 187                         CFLAGS="$ac_cflags_save"
 188                         LIBS="$ac_libs_save"
 189                         $5
 190                 ], [
 191                         AC_MSG_RESULT([no])
 192                         CFLAGS="$ac_cflags_save"
 193                         LIBS="$ac_libs_save"
 194                         $4
 195                 ])
 196         AC_LANG_POP([C])
 197         }])
 198
 199 dnl ICC won't bail on unknown options without -diag-error 10006
 200 dnl need to do this first so we get useful results for the other options
 201 AC_C_FLAG([-diag-error 10006])
 202
 203 dnl AC_PROG_CC_C99 may change CC to include -std=gnu99 or something
 204 ac_cc="$CC"
 205 CC="${CC% -std=gnu99}"
 206 CC="${CC% -std=c99}"
 207
 208 AC_C_FLAG([-std=gnu11], [CC="$ac_cc"], [CC="$CC -std=gnu11"])
 209
 210 dnl if the user has specified any CFLAGS, override our settings
 211 if test "x${enable_gcov}" = "xyes"; then
 212    if test "z$orig_cflags" = "z"; then
 213       AC_C_FLAG([-coverage])
 214       AC_C_FLAG([-O0])
 215    fi
 216
 217    LDFLAGS="${LDFLAGS} -lgcov"
 218 elif test "x${enable_dev_build}" = "xyes"; then
 219    AC_DEFINE([DEV_BUILD], [1], [Build for development])
 220    if test "z$orig_cflags" = "z"; then
 221       AC_C_FLAG([-g3])
 222       AC_C_FLAG([-O0])
 223    fi
 224    if test "x${enable_lua}" = "xyes"; then
 225       AX_PROG_LUA([5.3])
 226       AX_LUA_HEADERS
 227       AX_LUA_LIBS([
 228          AC_DEFINE([HAVE_LUA], [1], [Have support for Lua interpreter])
 229          LIBS="$LIBS $LUA_LIB"
 230       ])
 231    fi
 232 else
 233    if test "x${enable_lua}" = "xyes"; then
 234       AC_MSG_ERROR([Lua is not meant to be built/used outside of development at this time])
 235    fi
 236    if test "z$orig_cflags" = "z"; then
 237       AC_C_FLAG([-g])
 238       AC_C_FLAG([-Os], [
 239         AC_C_FLAG([-O2])
 240       ])
 241    fi
 242 fi
 243 AM_CONDITIONAL([DEV_BUILD], [test "x$enable_dev_build" = "xyes"])
 244
 245 dnl always want these CFLAGS
 246 AC_C_FLAG([-fno-omit-frame-pointer])
 247 AC_C_FLAG([-funwind-tables])
 248 AC_C_FLAG([-Wall])
 249 AC_C_FLAG([-Wextra])
 250 AC_C_FLAG([-Wmissing-prototypes])
 251 AC_C_FLAG([-Wmissing-declarations])
 252 AC_C_FLAG([-Wpointer-arith])
 253 AC_C_FLAG([-Wbad-function-cast])
 254 AC_C_FLAG([-Wwrite-strings])
 255 if test x"${enable_gcc_ultra_verbose}" = x"yes" ; then
 256   AC_C_FLAG([-Wcast-qual])
 257   AC_C_FLAG([-Wstrict-prototypes])
 258   AC_C_FLAG([-Wmissing-noreturn])
 259   AC_C_FLAG([-Wmissing-format-attribute])
 260   AC_C_FLAG([-Wunreachable-code])
 261   AC_C_FLAG([-Wpacked])
 262   AC_C_FLAG([-Wpadded])
 263   AC_C_FLAG([-Wshadow])
 264 else
 265   AC_C_FLAG([-Wno-unused-result])
 266 fi
 267 AC_C_FLAG([-Wno-unused-parameter])
 268 AC_C_FLAG([-Wno-missing-field-initializers])
 269
 270 AC_C_FLAG([-Wc++-compat], [], [CXX_COMPAT_CFLAGS="-Wc++-compat"])
 271 AC_SUBST([CXX_COMPAT_CFLAGS])
 272
 273 dnl ICC emits a broken warning for const char *x = a ? "b" : "c";
 274 dnl for some reason the string consts get 'promoted' to char *,
 275 dnl triggering a const to non-const conversion warning.
 276 AC_C_FLAG([-diag-disable 3179])
 277
 278 if test x"${enable_werror}" = x"yes" ; then
 279   WERROR="-Werror"
 280 fi
 281 AC_SUBST([WERROR])
 282
 283 SAN_FLAGS=""
 284 if test "$enable_address_sanitizer" = "yes"; then
 285   AC_C_FLAG([-fsanitize=address], [
 286     AC_MSG_ERROR([$CC does not support Address Sanitizer.])
 287   ], [
 288     SAN_FLAGS="$SAN_FLAGS -fsanitize=address"
 289   ])
 290 fi
 291 if test "$enable_thread_sanitizer" = "yes"; then
 292   AC_C_FLAG([-fsanitize=thread], [
 293     AC_MSG_ERROR([$CC does not support Thread Sanitizer.])
 294   ], [
 295     SAN_FLAGS="$SAN_FLAGS -fsanitize=thread"
 296   ])
 297 fi
 298 if test "$enable_memory_sanitizer" = "yes"; then
 299   AC_C_FLAG([-fsanitize=thread -fPIE -pie], [
 300     AC_MSG_ERROR([$CC does not support Thread Sanitizer.])
 301   ], [
 302     SAN_FLAGS="-fsanitize=memory -fPIE -pie"
 303   ])
 304 fi
 305 AC_SUBST([SAN_FLAGS])
 306
 307 dnl ----------
 308 dnl Essentials
 309 dnl ----------
 310
 311 AX_PTHREAD([
 312   CC="$PTHREAD_CC"
 313   CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 314   LIBS="$PTHREAD_LIBS $LIBS"
 315 ], [
 316   AC_MSG_FAILURE([This FRR version needs pthreads])
 317 ])
 318
 319 AC_SEARCH_LIBS([pthread_condattr_setclock], [],
 320                 [frr_cv_pthread_condattr_setclock=yes],
 321                 [frr_cv_pthread_condattr_setclock=no])
 322 if test "$frr_cv_pthread_condattr_setclock" = yes; then
 323   AC_DEFINE([HAVE_PTHREAD_CONDATTR_SETCLOCK], [1], [Have pthread.h pthread_condattr_setclock])
 324 fi
 325
 326 dnl --------------
 327 dnl Check programs
 328 dnl --------------
 329 AC_PROG_INSTALL
 330 AC_PROG_LN_S
 331 AC_PROG_MAKE_SET
 332 AC_CHECK_TOOL([AR], [ar])
 333
 334 dnl -------
 335 dnl libtool
 336 dnl -------
 337 AC_ARG_ENABLE([static-bin],
 338   AS_HELP_STRING([--enable-static-bin], [link binaries statically]))
 339 LT_INIT
 340 _LT_CONFIG_LIBTOOL([
 341   patch -N -i "${srcdir}/m4/libtool-whole-archive.patch" libtool >&AS_MESSAGE_LOG_FD || \
 342     AC_MSG_WARN([Could not patch libtool for static linking support.  Loading modules into a statically linked daemon will fail.])
 343 ])
 344 if test "$enable_static_bin" = "yes"; then
 345   AC_LDFLAGS="-static"
 346   if test "$enable_static" != "yes"; then
 347     AC_MSG_ERROR([The --enable-static-bin option must be combined with --enable-static.])
 348   fi
 349 fi
 350 if test "$enable_shared" != "yes"; then
 351   AC_MSG_ERROR([FRR cannot be built with --disable-shared.  If you want statically linked daemons, use --enable-shared --enable-static --enable-static-bin])
 352 fi
 353 AC_SUBST([AC_LDFLAGS])
 354 AM_CONDITIONAL([STATIC_BIN], [test "x$enable_static_bin" = "xyes"])
 355
 356 dnl $AR and $RANLIB are set by LT_INIT above
 357 AC_MSG_CHECKING([whether $AR supports D option])
 358 if $AR crD conftest.a >/dev/null 2>/dev/null; then
 359   AC_MSG_RESULT([yes])
 360   dnl ARFLAGS is for automake, AR_FLAGS for libtool m-(
 361   ARFLAGS="crD"
 362   AR_FLAGS="crD"
 363 else
 364   AC_MSG_RESULT([no])
 365   ARFLAGS="cru"
 366   AR_FLAGS="cru"
 367 fi
 368 AC_SUBST([ARFLAGS])
 369 AC_SUBST([AR_FLAGS])
 370
 371 AC_MSG_CHECKING([whether $RANLIB supports D option])
 372 if $RANLIB -D conftest.a >/dev/null 2>/dev/null; then
 373   AC_MSG_RESULT([yes])
 374   RANLIB="$RANLIB -D"
 375 else
 376   AC_MSG_RESULT([no])
 377 fi
 378 AC_SUBST([RANLIB])
 379
 380 test -f conftest.a && rm conftest.a
 381
 382 dnl ----------------------
 383 dnl Packages configuration
 384 dnl ----------------------
 385 if test -f config.version; then
 386   . ./config.version
 387 elif test -f "${srcdir}/config.version"; then
 388   . "${srcdir}/config.version"
 389 fi
 390 AC_ARG_WITH([pkg-extra-version],
 391   AS_HELP_STRING([--with-pkg-extra-version=VER], [add extra version field, for packagers/distributions]), [
 392   if test "$withval" = "no"; then
 393     EXTRAVERSION=
 394   else
 395     EXTRAVERSION=$withval
 396   fi
 397 ], [])
 398 AC_ARG_WITH([pkg-git-version],
 399         AS_HELP_STRING([--with-pkg-git-version], [add git information to MOTD and build version string]),
 400         [ test "x$withval" != "xno" && with_pkg_git_version="yes" ])
 401 AC_ARG_WITH([vtysh_pager],
 402         AS_HELP_STRING([--with-vtysh-pager=PAGER], [control what pager is compiled in as default]),
 403         VTYSH_PAGER=$withval, VTYSH_PAGER="more")
 404 AC_ARG_ENABLE([vtysh],
 405   AS_HELP_STRING([--disable-vtysh], [do not build integrated vty shell for FRR]))
 406 AC_ARG_ENABLE([doc],
 407   AS_HELP_STRING([--disable-doc], [do not build docs]))
 408 AC_ARG_ENABLE([doc-html],
 409   AS_HELP_STRING([--enable-doc-html], [build HTML docs]))
 410 AC_ARG_ENABLE([zebra],
 411   AS_HELP_STRING([--disable-zebra], [do not build zebra daemon]))
 412 AC_ARG_ENABLE([bgpd],
 413   AS_HELP_STRING([--disable-bgpd], [do not build bgpd]))
 414 AC_ARG_ENABLE([ripd],
 415   AS_HELP_STRING([--disable-ripd], [do not build ripd]))
 416 AC_ARG_ENABLE([ripngd],
 417   AS_HELP_STRING([--disable-ripngd], [do not build ripngd]))
 418 AC_ARG_ENABLE([ospfd],
 419   AS_HELP_STRING([--disable-ospfd], [do not build ospfd]))
 420 AC_ARG_ENABLE([ospf6d],
 421   AS_HELP_STRING([--disable-ospf6d], [do not build ospf6d]))
 422 AC_ARG_ENABLE([ldpd],
 423   AS_HELP_STRING([--disable-ldpd], [do not build ldpd]))
 424 AC_ARG_ENABLE([nhrpd],
 425   AS_HELP_STRING([--disable-nhrpd], [do not build nhrpd]))
 426 AC_ARG_ENABLE([eigrpd],
 427   AS_HELP_STRING([--disable-eigrpd], [do not build eigrpd]))
 428 AC_ARG_ENABLE([babeld],
 429   AS_HELP_STRING([--disable-babeld], [do not build babeld]))
 430 AC_ARG_ENABLE([watchfrr],
 431   AS_HELP_STRING([--disable-watchfrr], [do not build watchfrr]))
 432 AC_ARG_ENABLE([isisd],
 433   AS_HELP_STRING([--disable-isisd], [do not build isisd]))
 434 AC_ARG_ENABLE([pimd],
 435   AS_HELP_STRING([--disable-pimd], [do not build pimd]))
 436 AC_ARG_ENABLE([pbrd],
 437   AS_HELP_STRING([--disable-pbrd], [do not build pbrd]))
 438 AC_ARG_ENABLE([sharpd],
 439   AS_HELP_STRING([--enable-sharpd], [build sharpd]))
 440 AC_ARG_ENABLE([staticd],
 441   AS_HELP_STRING([--disable-staticd], [do not build staticd]))
 442 AC_ARG_ENABLE([fabricd],
 443   AS_HELP_STRING([--disable-fabricd], [do not build fabricd]))
 444 AC_ARG_ENABLE([bgp-announce],
 445   AS_HELP_STRING([--disable-bgp-announce,], [turn off BGP route announcement]))
 446 AC_ARG_ENABLE([bgp-vnc],
 447   AS_HELP_STRING([--disable-bgp-vnc],[turn off BGP VNC support]))
 448 AC_ARG_ENABLE([snmp],
 449   AS_HELP_STRING([--enable-snmp], [enable SNMP support for agentx]))
 450 AC_ARG_ENABLE([config_rollbacks],
 451   AS_HELP_STRING([--enable-config-rollbacks], [enable configuration rollbacks (requires sqlite3)]))
 452 AC_ARG_ENABLE([confd],
 453   AS_HELP_STRING([--enable-confd=ARG], [enable confd integration]))
 454 AC_ARG_ENABLE([sysrepo],
 455   AS_HELP_STRING([--enable-sysrepo], [enable sysrepo integration]))
 456 AC_ARG_ENABLE([grpc],
 457   AS_HELP_STRING([--enable-grpc], [enable the gRPC northbound plugin]))
 458 AC_ARG_ENABLE([zeromq],
 459   AS_HELP_STRING([--enable-zeromq], [enable ZeroMQ handler (libfrrzmq)]))
 460 AC_ARG_WITH([libpam],
 461   AS_HELP_STRING([--with-libpam], [use libpam for PAM support in vtysh]))
 462 AC_ARG_ENABLE([ospfapi],
 463   AS_HELP_STRING([--disable-ospfapi], [do not build OSPFAPI to access the OSPF LSA Database]))
 464 AC_ARG_ENABLE([ospfclient],
 465   AS_HELP_STRING([--disable-ospfclient], [do not build OSPFAPI client for OSPFAPI,
 466                           (this is the default if --disable-ospfapi is set)]))
 467 AC_ARG_ENABLE([multipath],
 468   AS_HELP_STRING([--enable-multipath=ARG], [enable multipath function, ARG must be digit]))
 469 AC_ARG_ENABLE([user],
 470   AS_HELP_STRING([--enable-user=USER], [user to run FRR suite as (default frr)]))
 471 AC_ARG_ENABLE([group],
 472   AS_HELP_STRING([--enable-group=GROUP], [group to run FRR suite as (default frr)]))
 473 AC_ARG_ENABLE([vty_group],
 474   AS_HELP_STRING([--enable-vty-group=ARG], [set vty sockets to have specified group as owner]))
 475 AC_ARG_ENABLE([configfile_mask],
 476   AS_HELP_STRING([--enable-configfile-mask=ARG], [set mask for config files]))
 477 AC_ARG_ENABLE([logfile_mask],
 478   AS_HELP_STRING([--enable-logfile-mask=ARG], [set mask for log files]))
 479 AC_ARG_ENABLE([shell_access],
 480   AS_HELP_STRING([--enable-shell-access], [Allow users to access shell/telnet/ssh]))
 481 AC_ARG_ENABLE([realms],
 482   AS_HELP_STRING([--enable-realms], [enable REALMS support under Linux]))
 483 AC_ARG_ENABLE([rtadv],
 484   AS_HELP_STRING([--disable-rtadv], [disable IPV6 router advertisement feature]))
 485 AC_ARG_ENABLE([irdp],
 486   AS_HELP_STRING([--disable-irdp], [enable IRDP server support in zebra (default if supported)]))
 487 AC_ARG_ENABLE([capabilities],
 488   AS_HELP_STRING([--disable-capabilities], [disable using POSIX capabilities]))
 489 AC_ARG_ENABLE([rusage],
 490   AS_HELP_STRING([--disable-rusage], [disable using getrusage]))
 491 AC_ARG_ENABLE([gcc_ultra_verbose],
 492   AS_HELP_STRING([--enable-gcc-ultra-verbose], [enable ultra verbose GCC warnings]))
 493 AC_ARG_ENABLE([backtrace],
 494   AS_HELP_STRING([--disable-backtrace,], [disable crash backtraces (default autodetect)]))
 495 AC_ARG_ENABLE([time-check],
 496   AS_HELP_STRING([--disable-time-check], [disable slow thread warning messages]))
 497 AC_ARG_ENABLE([pcreposix],
 498   AS_HELP_STRING([--enable-pcreposix], [enable using PCRE Posix libs for regex functions]))
 499 AC_ARG_ENABLE([fpm],
 500   AS_HELP_STRING([--enable-fpm], [enable Forwarding Plane Manager support]))
 501 AC_ARG_ENABLE([systemd],
 502   AS_HELP_STRING([--enable-systemd], [enable Systemd support]))
 503 AC_ARG_ENABLE([werror],
 504   AS_HELP_STRING([--enable-werror], [enable -Werror (recommended for developers only)]))
 505 AC_ARG_ENABLE([cumulus],
 506   AS_HELP_STRING([--enable-cumulus], [enable Cumulus Switch Special Extensions]))
 507 AC_ARG_ENABLE([datacenter],
 508   AS_HELP_STRING([--enable-datacenter], [enable Compilation for Data Center Extensions]))
 509 AC_ARG_ENABLE([fuzzing],
 510   AS_HELP_STRING([--enable-fuzzing], [enable ability to fuzz various parts of FRR]))
 511 AC_ARG_ENABLE([netlink_fuzzing],
 512   AS_HELP_STRING([--enable-netlink-fuzzing], [enable ability to fuzz netlink listening socket in zebra]))
 513 AC_ARG_ENABLE([rr-semantics],
 514   AS_HELP_STRING([--disable-rr-semantics], [disable the v6 Route Replace semantics]))
 515 AC_ARG_ENABLE([protobuf],
 516   AS_HELP_STRING([--enable-protobuf], [Enable experimental protobuf support]))
 517 AC_ARG_ENABLE([oldvpn_commands],
 518   AS_HELP_STRING([--enable-oldvpn-commands], [Keep old vpn commands]))
 519 AC_ARG_ENABLE([rpki],
 520   AS_HELP_STRING([--enable-rpki], [enable RPKI prefix validation support]))
 521 AC_ARG_ENABLE([clippy-only],
 522   AS_HELP_STRING([--enable-clippy-only], [Only build clippy]))
 523 AC_ARG_ENABLE([numeric_version],
 524   AS_HELP_STRING([--enable-numeric-version], [Only numeric digits allowed in version (for Alpine)]))
 525 AC_ARG_ENABLE([gcov],
 526   AS_HELP_STRING([--enable-gcov], [Add code coverage information]))
 527 AC_ARG_ENABLE([bfdd],
 528   AS_HELP_STRING([--disable-bfdd], [do not build bfdd]))
 529 AC_ARG_ENABLE([address-sanitizer],
 530   AS_HELP_STRING([--enable-address-sanitizer], [enable AddressSanitizer support for detecting a wide variety of memory allocation and deallocation errors]))
 531 AC_ARG_ENABLE([thread-sanitizer],
 532   AS_HELP_STRING([--enable-thread-sanitizer], [enable ThreadSanitizer support for detecting data races]))
 533 AC_ARG_ENABLE([memory-sanitizer],
 534   AS_HELP_STRING([--enable-memory-sanitizer], [enable MemorySanitizer support for detecting uninitialized memory reads]))
 535
 536 AS_IF([test "${enable_clippy_only}" != "yes"], [
 537 AC_CHECK_HEADERS([json-c/json.h])
 538 AC_CHECK_LIB([json-c], [json_object_get], [LIBS="$LIBS -ljson-c"], [], [-lm])
 539 if test "$ac_cv_lib_json_c_json_object_get" = no; then
 540   AC_CHECK_LIB([json], [json_object_get], [LIBS="$LIBS -ljson"])
 541   if test "$ac_cv_lib_json_json_object_get" = no; then
 542       AC_MSG_ERROR([libjson is needed to compile])
 543   fi
 544 fi
 545 ])
 546
 547 AC_ARG_ENABLE([dev_build],
 548     AS_HELP_STRING([--enable-dev-build], [build for development]))
 549
 550 AC_ARG_ENABLE([lua],
 551     AS_HELP_STRING([--enable-lua], [Build Lua scripting]))
 552
 553 if test x"${enable_time_check}" != x"no" ; then
 554   if test x"${enable_time_check}" = x"yes" -o x"${enable_time_check}" = x ; then
 555     AC_DEFINE([CONSUMED_TIME_CHECK], [5000000], [Consumed Time Check])
 556   else
 557     AC_DEFINE_UNQUOTED([CONSUMED_TIME_CHECK], [$enable_time_check], [Consumed Time Check])
 558   fi
 559 fi
 560
 561 case "${enable_systemd}" in
 562   "no") ;;
 563   "yes")
 564   AC_CHECK_LIB([systemd], [sd_notify], [LIBS="$LIBS -lsystemd"])
 565   if test $ac_cv_lib_systemd_sd_notify = no; then
 566     AC_MSG_ERROR([enable systemd has been specified but systemd development env not found on your system])
 567   else
 568     AC_DEFINE([HAVE_SYSTEMD], [1], [Compile systemd support in])
 569   fi
 570   ;;
 571   "*") ;;
 572 esac
 573
 574 if test "${enable_rr_semantics}" != "no" ; then
 575   AC_DEFINE([HAVE_V6_RR_SEMANTICS], [1], [Compile in v6 Route Replacement Semantics])
 576 fi
 577
 578 if test "${enable_datacenter}" = "yes" ; then
 579   AC_DEFINE([HAVE_DATACENTER], [1], [Compile extensions for a DataCenter])
 580   DFLT_NAME="datacenter"
 581 else
 582   DFLT_NAME="traditional"
 583 fi
 584
 585 if test "${enable_fuzzing}" = "yes" ; then
 586   AC_DEFINE([HANDLE_ZAPI_FUZZING], [1], [Compile extensions to use with a fuzzer])
 587 fi
 588
 589 if test "${enable_netlink_fuzzing}" = "yes" ; then
 590   AC_DEFINE([HANDLE_NETLINK_FUZZING], [1], [Compile extensions to use with a fuzzer for netlink])
 591 fi
 592
 593 if test "${enable_cumulus}" = "yes" ; then
 594   AC_DEFINE([HAVE_CUMULUS], [1], [Compile Special Cumulus Code in])
 595 fi
 596
 597 AC_SUBST([DFLT_NAME])
 598 AC_DEFINE_UNQUOTED([DFLT_NAME], ["$DFLT_NAME"], [Name of the configuration default set])
 599
 600 if test "${enable_shell_access}" = "yes"; then
 601    AC_DEFINE([HAVE_SHELL_ACCESS], [1], [Allow user to use ssh/telnet/bash, be aware this is considered insecure])
 602 fi
 603
 604 AM_CONDITIONAL([FPM], [test "x$enable_fpm" = "xyes"])
 605
 606 #
 607 # Python for clippy
 608 #
 609
 610 AC_DEFUN([FRR_PYTHON_CHECK_WORKING], [
 611   AC_MSG_CHECKING([whether we found a working Python version])
 612   AC_LINK_IFELSE_FLAGS([$PYTHON_CFLAGS], [$PYTHON_LIBS], [AC_LANG_PROGRAM([
 613 #include <Python.h>
 614 #if PY_VERSION_HEX < 0x02070000
 615 #error python too old
 616 #endif
 617 int main(void);
 618 ],
 619 [
 620 {
 621   Py_Initialize();
 622   return 0;
 623 }
 624 ])], [
 625     # some python installs are missing the zlib dependency...
 626     PYTHON_LIBS="${PYTHON_LIBS} -lz"
 627     AC_LINK_IFELSE_FLAGS([$PYTHON_CFLAGS], [$PYTHON_LIBS], [AC_LANG_PROGRAM([
 628 #include <Python.h>
 629 #if PY_VERSION_HEX < 0x02070000
 630 #error python too old
 631 #endif
 632 int main(void);
 633 ],
 634 [
 635 {
 636   Py_Initialize();
 637   return 0;
 638 }
 639 ])], [
 640       m4_if([$1], [], [
 641         PYTHONCONFIG=""
 642         unset PYTHON_LIBS
 643         unset PYTHON_CFLAGS
 644       ], [$1])
 645     ])
 646   ])
 647 ])
 648
 649 AS_IF([test "$host" = "$build"], [
 650   PYTHONCONFIG=""
 651
 652   # ordering:
 653   # 1.  try python3, but respect the user's preference on which minor ver
 654   # 2.  try python, which might be py3 or py2 again on the user's preference
 655   # 3.  try python2 (can really only be 2.7 but eh)
 656   # 4.  try 3.6 > 3.5 > 3.4 > 3.3 > 3.2 > 2.7 through pkg-config (no user pref)
 657   #
 658   # (AX_PYTHON_DEVEL has no clue about py3 vs py2)
 659   # (AX_PYTHON does not do what we need)
 660
 661   AC_CHECK_TOOLS([PYTHONCONFIG], [ \
 662         python3-config \
 663         python-config \
 664         python2-config \
 665         python3.6-config \
 666         python3.5-config \
 667         python3.4-config \
 668         python3.3-config \
 669         python3.2-config \
 670         python2.7-config ])
 671   if test -n "$PYTHONCONFIG"; then
 672     PYTHON_CFLAGS="`\"${PYTHONCONFIG}\" --includes`"
 673     PYTHON_LIBS="`\"${PYTHONCONFIG}\" --ldflags`"
 674
 675     FRR_PYTHON_CHECK_WORKING([])
 676   fi
 677
 678   if test -z "$PYTHONCONFIG"; then
 679     PKG_CHECK_MODULES([PYTHON], [python-3.6], [], [
 680       PKG_CHECK_MODULES([PYTHON], [python-3.5], [], [
 681         PKG_CHECK_MODULES([PYTHON], [python-3.4], [], [
 682           PKG_CHECK_MODULES([PYTHON], [python-3.3], [], [
 683             PKG_CHECK_MODULES([PYTHON], [python-3.2], [], [
 684               PKG_CHECK_MODULES([PYTHON], [python-2.7], [], [
 685                 AC_MSG_FAILURE([could not find python-config or pkg-config python, please install Python development files from libpython-dev or similar])
 686                 ])])])])])])
 687
 688
 689     FRR_PYTHON_CHECK_WORKING([
 690       AC_MSG_FAILURE([could not find python-config or pkg-config python, please install Python development files from libpython-dev or similar])
 691     ])
 692   fi
 693 ])
 694 AC_SUBST([PYTHON_CFLAGS])
 695 AC_SUBST([PYTHON_LIBS])
 696
 697 #
 698 # Logic for protobuf support.
 699 #
 700 if test "$enable_protobuf" = "yes"; then
 701   # Check for protoc & protoc-c
 702
 703   # protoc is not required, it's only for a "be nice" helper target
 704   AC_CHECK_PROGS([PROTOC], [protoc], [/bin/false])
 705
 706   AC_CHECK_PROGS([PROTOC_C], [protoc-c], [/bin/false])
 707   if test "$PROTOC_C" = "/bin/false"; then
 708     AC_MSG_FAILURE([protobuf requested but protoc-c not found.  Install protobuf-c.])
 709   fi
 710
 711   PKG_CHECK_MODULES([PROTOBUF_C], [libprotobuf-c >= 0.14],, [
 712     AC_MSG_FAILURE([protobuf requested but libprotobuf-c not found.  Install protobuf-c.])
 713   ])
 714   AC_CHECK_HEADER([google/protobuf-c/protobuf-c.h], [], [
 715     AC_MSG_FAILURE([protobuf requested but protobuf-c.h not found.  Install protobuf-c.])
 716   ])
 717
 718   AC_DEFINE([HAVE_PROTOBUF], [1], [protobuf])
 719 fi
 720 AM_CONDITIONAL([HAVE_PROTOBUF], [test "x$enable_protobuf" = "xyes"])
 721
 722 #
 723 # Logic for old vpn commands support.
 724 #
 725 if test "$enable_oldvpn_commands" = "yes"; then
 726    AC_DEFINE([KEEP_OLD_VPN_COMMANDS], [1], [Define for compiling with old vpn commands])
 727 fi
 728
 729 #
 730 # End of logic for protobuf support.
 731 #
 732
 733 AC_MSG_CHECKING([if zebra should be configurable to send Route Advertisements])
 734 if test "${enable_rtadv}" != "no"; then
 735   AC_MSG_RESULT([yes])
 736   AC_DEFINE([HAVE_RTADV], [1], [Enable IPv6 Routing Advertisement support])
 737 else
 738   AC_MSG_RESULT([no])
 739 fi
 740
 741 if test x"${enable_user}" = x"no"; then
 742   enable_user=""
 743 else
 744   if test x"${enable_user}" = x"yes" || test x"${enable_user}" = x""; then
 745     enable_user="frr"
 746   fi
 747   AC_DEFINE_UNQUOTED([FRR_USER], ["${enable_user}"], [frr User])
 748 fi
 749
 750 if test x"${enable_group}" = x"no"; then
 751   enable_group=""
 752 else
 753   if test x"${enable_group}" = x"yes" || test x"${enable_group}" = x""; then
 754     enable_group="frr"
 755   fi
 756   AC_DEFINE_UNQUOTED([FRR_GROUP], ["${enable_group}"], [frr Group])
 757 fi
 758
 759 if test x"${enable_vty_group}" = x"yes" ; then
 760   AC_MSG_ERROR([--enable-vty-group requires a group as argument, not yes])
 761 elif test x"${enable_vty_group}" != x""; then
 762   if test x"${enable_vty_group}" != x"no"; then
 763     AC_DEFINE_UNQUOTED([VTY_GROUP], ["${enable_vty_group}"], [VTY Sockets Group])
 764   fi
 765 fi
 766 AC_SUBST([enable_user])
 767 AC_SUBST([enable_group])
 768 AC_SUBST([enable_vty_group])
 769
 770 enable_configfile_mask=${enable_configfile_mask:-0600}
 771 AC_DEFINE_UNQUOTED([CONFIGFILE_MASK], [${enable_configfile_mask}], [Mask for config files])
 772
 773 enable_logfile_mask=${enable_logfile_mask:-0600}
 774 AC_DEFINE_UNQUOTED([LOGFILE_MASK], [${enable_logfile_mask}], [Mask for log files])
 775
 776 MPATH_NUM=16
 777
 778 case "${enable_multipath}" in
 779   0)
 780     MPATH_NUM=64
 781     ;;
 782   [[1-9]|[1-9][0-9]|[1-9][0-9][0-9]])
 783     MPATH_NUM="${enable_multipath}"
 784     ;;
 785   "")
 786     ;;
 787   *)
 788     AC_MSG_FAILURE([Please specify digit to enable multipath ARG])
 789     ;;
 790 esac
 791
 792 AC_DEFINE_UNQUOTED([MULTIPATH_NUM], [$MPATH_NUM], [Maximum number of paths for a route])
 793
 794 AC_DEFINE_UNQUOTED([VTYSH_PAGER], ["$VTYSH_PAGER"], [What pager to use])
 795
 796 dnl --------------------
 797 dnl Enable code coverage
 798 dnl --------------------
 799 AM_CONDITIONAL([HAVE_GCOV], [test '!' "$enable_gcov" = no])
 800
 801 dnl ------------------------------------
 802 dnl Alpine only accepts numeric versions
 803 dnl ------------------------------------
 804 if test "x${enable_numeric_version}" != "x" ; then
 805   VERSION="`echo ${VERSION} | tr -c -d '[[.0-9]]'`"
 806   PACKAGE_VERSION="`echo ${PACKAGE_VERSION} | tr -c -d '[[.0-9]]'`"
 807 fi
 808
 809 dnl -----------------------------------
 810 dnl Add extra version string to package
 811 dnl name, string and version fields.
 812 dnl -----------------------------------
 813 if test "x${EXTRAVERSION}" != "x" ; then
 814   VERSION="${VERSION}${EXTRAVERSION}"
 815   PACKAGE_VERSION="${PACKAGE_VERSION}${EXTRAVERSION}"
 816   AC_SUBST(PACKAGE_EXTRAVERSION, ["${EXTRAVERSION}"])
 817   PACKAGE_STRING="${PACKAGE_STRING}${EXTRAVERSION}"
 818 fi
 819 AC_SUBST([EXTRAVERSION])
 820
 821 if test "x$with_pkg_git_version" = "xyes"; then
 822         if test -d "${srcdir}/.git"; then
 823                 AC_DEFINE([GIT_VERSION], [1], [include git version info])
 824         else    with_pkg_git_version="no"
 825                 AC_MSG_WARN([--with-pkg-git-version given, but this is not a git checkout])
 826         fi
 827 fi
 828 AM_CONDITIONAL([GIT_VERSION], [test "x$with_pkg_git_version" = "xyes"])
 829
 830 AC_CHECK_TOOL([OBJCOPY], [objcopy], [:])
 831 if test "x${OBJCOPY}" != "x:"; then
 832   AC_CACHE_CHECK([for .interp value to use], [frr_cv_interp], [
 833     frr_cv_interp=""
 834     AC_LINK_IFELSE([AC_LANG_SOURCE([[int main() { return 0; }]])], [
 835       if $OBJCOPY -j.interp -Obinary conftest conftest.interp; then
 836         frr_cv_interp="`xargs -0 echo < conftest.interp`"
 837       fi
 838       test -f conftest.interp && rm conftest.interp
 839     ])
 840   ])
 841 fi
 842 if test -n "$frr_cv_interp"; then
 843   AC_DEFINE_UNQUOTED([INTERP], ["$frr_cv_interp"], [.interp value])
 844 fi
 845
 846 dnl ------------------------------------
 847 dnl Check C keywords and standard  types
 848 dnl ------------------------------------
 849 AC_C_CONST
 850 AC_C_INLINE
 851 AC_C_VOLATILE
 852 AC_HEADER_STDC
 853 dnl AC_TYPE_PID_T
 854 AC_TYPE_UID_T
 855 AC_TYPE_MODE_T
 856 AC_TYPE_SIZE_T
 857 AC_STRUCT_TM
 858
 859 dnl -------------------------
 860 dnl Check other header files.
 861 dnl -------------------------
 862 AC_CHECK_HEADERS([stropts.h sys/ksym.h \
 863         linux/version.h asm/types.h \
 864         sys/cdefs.h])
 865
 866 ac_stdatomic_ok=false
 867 AC_DEFINE([FRR_AUTOCONF_ATOMIC], [1], [did autoconf checks for atomic funcs])
 868 AC_CHECK_HEADER([stdatomic.h],[
 869
 870   AC_MSG_CHECKING([whether _Atomic qualifier works])
 871   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 872 #include <stdatomic.h>
 873 int main(int argc, char **argv) {
 874   _Atomic int i = 0;
 875   return i;
 876 }
 877 ]])], [
 878     AC_DEFINE([HAVE_STDATOMIC_H], [1], [found stdatomic.h])
 879     AC_MSG_RESULT([yes])
 880     ac_stdatomic_ok=true
 881   ], [
 882     AC_MSG_RESULT([no])
 883   ])
 884 ])
 885
 886 AS_IF([$ac_stdatomic_ok], [true], [
 887   AC_MSG_CHECKING([for __atomic_* builtins])
 888   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 889 int main(int argc, char **argv) {
 890   volatile int i = 1;
 891   __atomic_store_n (&i, 0, __ATOMIC_RELEASE);
 892   return __atomic_load_n (&i, __ATOMIC_ACQUIRE);
 893 }
 894 ]])], [
 895     AC_DEFINE([HAVE___ATOMIC], [1], [found __atomic builtins])
 896     AC_MSG_RESULT([yes])
 897   ], [
 898     AC_MSG_RESULT([no])
 899
 900     dnl FreeBSD 9 has a broken stdatomic.h where _Atomic doesn't work
 901     AC_MSG_CHECKING([for __sync_* builtins])
 902     AC_LINK_IFELSE([AC_LANG_SOURCE([[
 903 int main(int argc, char **argv) {
 904   volatile int i = 1;
 905   __sync_fetch_and_sub (&i, 1);
 906   return __sync_val_compare_and_swap (&i, 0, 1);
 907 }
 908 ]])], [
 909       AC_DEFINE([HAVE___SYNC], [1], [found __sync builtins])
 910       AC_MSG_RESULT([yes])
 911
 912       AC_MSG_CHECKING([for __sync_swap builtin])
 913       AC_LINK_IFELSE([AC_LANG_SOURCE([[
 914 int main(int argc, char **argv) {
 915   volatile int i = 1;
 916   return __sync_swap (&i, 2);
 917 }
 918 ]])], [
 919         AC_DEFINE([HAVE___SYNC_SWAP], 1, [found __sync_swap builtin])
 920         AC_MSG_RESULT([yes])
 921       ], [
 922         AC_MSG_RESULT([no])
 923       ])
 924
 925     ], [
 926       AC_MSG_RESULT([no])
 927       AC_MSG_FAILURE([stdatomic.h unavailable and $CC has neither __atomic nor __sync builtins])
 928     ])
 929   ])
 930 ])
 931
 932 AC_CHECK_HEADERS([pthread_np.h],,, [
 933 #include <pthread.h>
 934 ])
 935 AC_CHECK_FUNCS([pthread_setname_np pthread_set_name_np])
 936
 937 needsync=true
 938
 939 AS_IF([$needsync], [
 940   dnl Linux
 941   AC_MSG_CHECKING([for Linux futex() support])
 942   AC_LINK_IFELSE([AC_LANG_PROGRAM([
 943 #ifndef _GNU_SOURCE
 944 #define _GNU_SOURCE
 945 #endif
 946 #include <unistd.h>
 947 #include <limits.h>
 948 #include <sys/time.h>
 949 #include <sys/syscall.h>
 950 #include <linux/futex.h>
 951
 952 int main(void);
 953 ],
 954 [
 955 {
 956   return syscall(SYS_futex, NULL, FUTEX_WAIT, 0, NULL, NULL, 0);
 957 }
 958 ])], [
 959     AC_MSG_RESULT([yes])
 960     AC_DEFINE(HAVE_SYNC_LINUX_FUTEX,,Have Linux futex support)
 961     needsync=false
 962   ], [
 963     AC_MSG_RESULT([no])
 964   ])
 965 ])
 966
 967 AS_IF([$needsync], [
 968   dnl FreeBSD
 969   AC_MSG_CHECKING([for FreeBSD _umtx_op() support])
 970   AC_LINK_IFELSE([AC_LANG_PROGRAM([
 971 #include <errno.h>
 972 #include <stdlib.h>
 973 #include <sys/types.h>
 974 #include <sys/umtx.h>
 975 int main(void);
 976 ],
 977 [
 978 {
 979   return _umtx_op(NULL, UMTX_OP_WAIT_UINT, 0, NULL, NULL);
 980 }
 981 ])], [
 982     AC_MSG_RESULT([yes])
 983     AC_DEFINE(HAVE_SYNC_UMTX_OP,,Have FreeBSD _umtx_op() support)
 984     needsync=false
 985   ], [
 986     AC_MSG_RESULT([no])
 987   ])
 988 ])
 989
 990 AS_IF([$needsync], [
 991   dnl OpenBSD patch (not upstream at the time of writing this)
 992   dnl https://marc.info/?l=openbsd-tech&m=147299508409549&w=2
 993   AC_MSG_CHECKING([for OpenBSD futex() support])
 994   AC_LINK_IFELSE([AC_LANG_PROGRAM([
 995 #include <sys/futex.h>
 996 int main(void);
 997 ],
 998 [
 999 {
1000   return futex(NULL, FUTEX_WAIT, 0, NULL, NULL, 0);
1001 }
1002 ])], [
1003     AC_MSG_RESULT([yes])
1004     AC_DEFINE(HAVE_SYNC_OPENBSD_FUTEX,,Have OpenBSD futex support)
1005     needsync=false
1006   ], [
1007     AC_MSG_RESULT([no])
1008   ])
1009 ])
1010
1011 dnl Utility macro to avoid retyping includes all the time
1012 m4_define([FRR_INCLUDES],
1013 [#ifdef SUNOS_5
1014 #define _POSIX_C_SOURCE 200809L
1015 #define __EXTENSIONS__
1016 #endif
1017 #include <stdio.h>
1018 #include <stdlib.h>
1019 #include <stddef.h>
1020 #include <sys/types.h>
1021 /* sys/conf.h depends on param.h on FBSD at least */
1022 #include <sys/param.h>
1023 /* Required for MAXSIG */
1024 #include <signal.h>
1025 #include <sys/socket.h>
1026 #ifdef __APPLE__
1027 # define __APPLE_USE_RFC_3542
1028 #endif
1029 #include <netinet/in.h>
1030 #include <sys/time.h>
1031 #include <time.h>
1032 #include <net/if.h>
1033 ])dnl
1034
1035 dnl Same applies for HAVE_NET_IF_VAR_H, which HAVE_NETINET6_ND6_H and
1036 dnl HAVE_NETINET_IN_VAR_H depend upon. But if_var.h depends on if.h, hence
1037 dnl an additional round for it.
1038
1039 AC_CHECK_HEADERS([net/if_var.h], [], [], [FRR_INCLUDES])
1040
1041 m4_define([FRR_INCLUDES],
1042 FRR_INCLUDES
1043 [#if HAVE_NET_IF_VAR_H
1044 # include <net/if_var.h>
1045 #endif
1046 ])dnl
1047
1048 AC_CHECK_HEADERS([netinet/in_var.h \
1049         net/if_dl.h net/netopt.h \
1050         inet/nd.h netinet/ip_icmp.h \
1051         sys/sysctl.h sys/sockio.h kvm.h sys/conf.h],
1052         [], [], [FRR_INCLUDES])
1053
1054 AC_CHECK_HEADERS([ucontext.h], [], [],
1055 [#ifndef __USE_GNU
1056 #define __USE_GNU
1057 #endif /* __USE_GNU */
1058 FRR_INCLUDES
1059 ])
1060
1061 m4_define([UCONTEXT_INCLUDES],
1062 [#include <ucontext.h>])dnl
1063
1064 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.uc_regs],
1065   [], [], [UCONTEXT_INCLUDES])
1066 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs],
1067   [AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs.nip],
1068    [], [], [UCONTEXT_INCLUDES])],
1069   [], [UCONTEXT_INCLUDES])
1070 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.gregs],
1071   [], [], [UCONTEXT_INCLUDES])
1072
1073 m4_define([FRR_INCLUDES],
1074 FRR_INCLUDES
1075 [
1076 #include <sys/un.h>
1077 #include <netinet/in_systm.h>
1078 #if HAVE_NETINET_IN_VAR_H
1079 # include <netinet/in_var.h>
1080 #endif
1081 #if HAVE_NET_IF_DL_H
1082 # include <net/if_dl.h>
1083 #endif
1084 #if HAVE_NET_NETOPT_H
1085 # include <net/netopt.h>
1086 #endif
1087 #include <net/route.h>
1088 #if HAVE_INET_ND_H
1089 # include <inet/nd.h>
1090 #endif
1091 #include <arpa/inet.h>
1092 /* Required for IDRP */
1093 #if HAVE_NETINET_IP_ICMP_H
1094 # include <netinet/ip_icmp.h>
1095 #endif
1096 ])dnl
1097
1098 dnl V6 headers are checked below, after we check for v6
1099
1100 AC_MSG_CHECKING([which operating system interface to use])
1101 case "$host_os" in
1102   sunos* | solaris2*)
1103     AC_MSG_RESULT([Solaris])
1104
1105     AC_DEFINE([SUNOS_5], [1], [SunOS 5])
1106     AC_DEFINE([SOLARIS_IPV6], [1], Solaris IPv6)
1107     AC_DEFINE([_POSIX_C_SOURCE], [200809L], [enable POSIX.1-2008 and XPG7/SUSv4])
1108
1109     AC_CHECK_LIB([socket], [main])
1110     AC_CHECK_LIB([nsl], [main])
1111     AC_CHECK_LIB([umem], [main])
1112     SOLARIS="solaris"
1113     ;;
1114   linux*)
1115     AC_MSG_RESULT([Linux])
1116
1117     AC_DEFINE([GNU_LINUX], [1], [GNU Linux])
1118     AC_DEFINE([HAVE_NETLINK], [1], [netlink])
1119     AC_DEFINE([LINUX_IPV6], [1], [Linux IPv6 stack])
1120
1121     dnl Linux has a compilation problem with mixing
1122     dnl netinet/in.h and linux/in6.h they are not
1123     dnl compatible.  There has been discussion on
1124     dnl how to fix it but no real progress on implementation
1125     dnl when they fix it, remove this
1126     AC_DEFINE([IPV6_MINHOPCOUNT], [73], [Linux ipv6 Min Hop Count])
1127     ;;
1128   openbsd*)
1129     AC_MSG_RESULT([OpenBSD])
1130
1131     AC_DEFINE([OPEN_BSD], [1], [OpenBSD])
1132     AC_DEFINE([KAME], [1], [KAME IPv6])
1133     AC_DEFINE([BSD_V6_SYSCTL], [1], [BSD v6 sysctl to turn on and off forwarding])
1134
1135     if test "x${enable_pimd}" != "xno"; then
1136       case "$host_os" in
1137       openbsd6.0)
1138         ;;
1139       openbsd[6-9]*)
1140         AC_MSG_FAILURE([pimd cannot be enabled as PIM support has been removed from OpenBSD 6.1])
1141         ;;
1142       esac
1143     fi
1144     ;;
1145   *)
1146     AC_MSG_RESULT([BSD])
1147
1148     AC_DEFINE([HAVE_NET_RT_IFLIST], [1], [NET_RT_IFLIST])
1149     AC_DEFINE([KAME], [1], [KAME IPv6])
1150     AC_DEFINE([BSD_V6_SYSCTL], [1], [BSD v6 sysctl to turn on and off forwarding])
1151     ;;
1152 esac
1153 AM_CONDITIONAL([SOLARIS], [test "${SOLARIS}" = "solaris"])
1154
1155 AC_SYS_LARGEFILE
1156
1157 dnl ------------------------
1158 dnl Integrated REALMS option
1159 dnl ------------------------
1160 if test "${enable_realms}" = "yes"; then
1161     case "$host_os" in
1162       linux*)
1163        AC_DEFINE([SUPPORT_REALMS], [1], [Realms support])
1164        ;;
1165       *)
1166        echo "Sorry, only Linux has REALMS support"
1167        exit 1
1168        ;;
1169     esac
1170 fi
1171 AM_CONDITIONAL([SUPPORT_REALMS], [test "${enable_realms}" = "yes"])
1172
1173 dnl ---------------------
1174 dnl Integrated VTY option
1175 dnl ---------------------
1176 case "${enable_vtysh}" in
1177 "no")
1178   VTYSH="";;
1179 *)
1180   VTYSH="vtysh";
1181   AC_DEFINE([VTYSH], [1], [VTY shell])
1182
1183   prev_libs="$LIBS"
1184   AC_CHECK_LIB([readline], [main], [
1185     LIBREADLINE="-lreadline"
1186   ], [
1187     dnl readline failed - it might be incorrectly linked and missing its
1188     dnl termcap/tinfo/curses dependency.  see if we can fix that...
1189     AC_SEARCH_LIBS([tputs], [termcap tinfo curses ncurses], [
1190       LIBREADLINE="$ac_cv_search_tputs"
1191     ], [
1192       AC_MSG_ERROR([libreadline (needed for vtysh) not found and/or missing dependencies])
1193     ])
1194
1195     dnl re-try with the lib we found above
1196     unset ac_cv_lib_readline_main
1197     AC_CHECK_LIB([readline], [main], [
1198       LIBREADLINE="-lreadline $LIBREADLINE"
1199     ], [
1200       AC_MSG_ERROR([libreadline (needed for vtysh) not found and/or missing dependencies])
1201     ], [$LIBREADLINE])
1202   ], [])
1203   LIBS="$prev_libs"
1204
1205   AC_CHECK_HEADER([readline/history.h])
1206   if test $ac_cv_header_readline_history_h = no;then
1207     AC_MSG_ERROR([readline is too old to have readline/history.h, please update to the latest readline library.])
1208   fi
1209   AC_CHECK_LIB([readline], [rl_completion_matches], [true], [], [$LIBREADLINE])
1210   if test $ac_cv_lib_readline_rl_completion_matches = no; then
1211     AC_DEFINE([rl_completion_matches], [completion_matches], [Old readline])
1212   fi
1213   AC_CHECK_LIB([readline], [append_history], [frr_cv_append_history=yes], [frr_cv_append_history=no], [$LIBREADLINE])
1214   if test "$frr_cv_append_history" = yes; then
1215     AC_DEFINE([HAVE_APPEND_HISTORY], [1], [Have history.h append_history])
1216   fi
1217   ;;
1218 esac
1219 AC_SUBST([LIBREADLINE])
1220 AM_CONDITIONAL([VTYSH], test "x$VTYSH" = "xvtysh")
1221
1222 dnl ----------
1223 dnl PAM module
1224 dnl
1225 dnl FRR detects the PAM library it is built against by checking for a
1226 dnl functional pam_misc.h (Linux-PAM) or openpam.h (OpenPAM) header. pam_misc.h
1227 dnl is known to #include pam_appl.h, the standard header of a PAM library, and
1228 dnl openpam.h doesn't do that, although depends on the header too. Hence a
1229 dnl little assistance to AC_CHECK_HEADER is necessary for the proper detection
1230 dnl of OpenPAM.
1231 dnl ----------
1232 if test "$with_libpam" = "yes"; then
1233   AC_CHECK_HEADER([security/pam_misc.h],
1234     [AC_DEFINE([HAVE_PAM_MISC_H], [1], [Have pam_misc.h])
1235      AC_DEFINE([PAM_CONV_FUNC], [misc_conv], [Have misc_conv])
1236      pam_conv_func="misc_conv"
1237     ],
1238     [], FRR_INCLUDES)
1239   AC_CHECK_HEADER([security/openpam.h],
1240     [AC_DEFINE([HAVE_OPENPAM_H], [1], [Have openpam.h])
1241      AC_DEFINE([PAM_CONV_FUNC], [openpam_ttyconv], [Have openpam_ttyconv])
1242      pam_conv_func="openpam_ttyconv"
1243     ],
1244     [], FRR_INCLUDES[#include <security/pam_appl.h>])
1245   if test -z "$ac_cv_header_security_pam_misc_h$ac_cv_header_security_openpam_h" ; then
1246     AC_MSG_WARN([*** pam support will not be built ***])
1247     with_libpam="no"
1248   fi
1249 fi
1250
1251 if test "$with_libpam" = "yes"; then
1252 dnl took this test from proftpds configure.in and suited to our needs
1253 dnl -------------------------------------------------------------------------
1254 dnl
1255 dnl This next check looks funky due to a linker problem with some versions
1256 dnl of the PAM library.  Prior to 0.72 release, the Linux PAM shared library
1257 dnl omitted requiring libdl linking information. PAM-0.72 or better ships
1258 dnl with RedHat 6.2 and Debian 2.2 or better.
1259 AC_CHECK_LIB([pam], [pam_start],
1260   [AC_CHECK_LIB([pam], [$pam_conv_func],
1261     [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1262      LIBPAM="-lpam"],
1263     [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1264      LIBPAM="-lpam -lpam_misc"]
1265     )
1266   ],
1267
1268   [AC_CHECK_LIB([pam], [pam_end],
1269     [AC_CHECK_LIB([pam], [$pam_conv_func],
1270       [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1271        LIBPAM="-lpam -ldl"],
1272       [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1273        LIBPAM="-lpam -ldl -lpam_misc"]
1274      )
1275   ],AC_MSG_WARN([*** pam support will not be built ***]),
1276   [-ldl])
1277   ]
1278 )
1279 fi
1280 AC_SUBST([LIBPAM])
1281
1282 dnl -------------------------------
1283 dnl Endian-ness check
1284 dnl -------------------------------
1285 AC_WORDS_BIGENDIAN
1286
1287 dnl -------------------------------
1288 dnl check the size in byte of the C
1289 dnl -------------------------------
1290 dnl AC_CHECK_SIZEOF(char)
1291 dnl AC_CHECK_SIZEOF(int)
1292 dnl AC_CHECK_SIZEOF(short)
1293 dnl AC_CHECK_SIZEOF(long)
1294
1295 dnl ----------------------------
1296 dnl check existance of functions
1297 dnl ----------------------------
1298 AC_FUNC_FNMATCH
1299 AC_FUNC_FORK
1300 AC_FUNC_MKTIME
1301 AC_FUNC_STAT
1302
1303 dnl -------------------------------
1304 dnl bgpd needs pow() and hence libm
1305 dnl -------------------------------
1306 TMPLIBS="$LIBS"
1307 AC_CHECK_HEADER([math.h],
1308   [AC_CHECK_LIB([m], [pow],
1309     [LIBM="-lm"
1310      LIBS="$LIBS $LIBM"
1311      AC_CHECK_FUNCS(pow,[],[LIBM=""])
1312     ])
1313 ])
1314 if test x"$LIBM" = x ; then
1315   AC_MSG_WARN([Unable to find working pow function - bgpd may not link])
1316 fi
1317 LIBS="$TMPLIBS"
1318
1319 AC_SUBST([LIBM])
1320
1321 AC_CHECK_FUNCS([ppoll], [
1322   AC_DEFINE([HAVE_PPOLL], [1], [have Linux/BSD ppoll()])
1323 ])
1324 AC_CHECK_FUNCS([pollts], [
1325   AC_DEFINE([HAVE_POLLTS], [1], [have NetBSD pollts()])
1326 ])
1327
1328 dnl ---------------
1329 dnl other functions
1330 dnl ---------------
1331 AC_CHECK_FUNCS([ \
1332         strlcat strlcpy \
1333         getgrouplist])
1334
1335 AC_CHECK_HEADER([asm-generic/unistd.h],
1336                 [AC_CHECK_DECL(__NR_setns,
1337                                AC_DEFINE([HAVE_NETNS], [1], [Have netns]),,
1338                                FRR_INCLUDES [#include <asm-generic/unistd.h>
1339                                ])
1340                  AC_CHECK_FUNCS([setns])]
1341                )
1342
1343 dnl --------------------------
1344 dnl Determine IS-IS I/O method
1345 dnl --------------------------
1346 AC_DEFINE([ISIS_METHOD_PFPACKET], [1], [constant value for isis method pfpacket])
1347 AC_DEFINE([ISIS_METHOD_DLPI], [2], [constant value for isis method dlpi])
1348 AC_DEFINE([ISIS_METHOD_BPF], [3], [constant value for isis method bpf])
1349 AC_CHECK_HEADER([net/bpf.h])
1350 AC_CHECK_HEADER([sys/dlpi.h])
1351 AC_MSG_CHECKING([zebra IS-IS I/O method])
1352
1353 case "$host_os" in
1354   linux*)
1355     AC_MSG_RESULT([pfpacket])
1356     ISIS_METHOD_MACRO="ISIS_METHOD_PFPACKET"
1357     ;;
1358   solaris* | sunos*)
1359     AC_MSG_RESULT([DLPI])
1360     ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1361     ;;
1362   *)
1363     if test $ac_cv_header_net_bpf_h = no; then
1364       if test $ac_cv_header_sys_dlpi_h = no; then
1365         AC_MSG_RESULT([none])
1366         if test "${enable_isisd}" = yes -o "${enable_fabricd}" = yes; then
1367           AC_MSG_FAILURE([IS-IS support requested but no packet backend found])
1368         fi
1369         AC_MSG_WARN([*** IS-IS support will not be built ***])
1370         enable_isisd="no"
1371         enable_fabricd="no"
1372       else
1373         AC_MSG_RESULT([DLPI])
1374       fi
1375       ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1376     else
1377       AC_MSG_RESULT([BPF])
1378       ISIS_METHOD_MACRO="ISIS_METHOD_BPF"
1379     fi
1380     ;;
1381 esac
1382 AC_DEFINE_UNQUOTED([ISIS_METHOD], [$ISIS_METHOD_MACRO], [selected method for isis, == one of the constants])
1383
1384 dnl ---------------------------------------------------------------
1385 dnl figure out how to specify an interface in multicast sockets API
1386 dnl ---------------------------------------------------------------
1387 AC_CHECK_MEMBERS([struct ip_mreqn.imr_ifindex], [], [], FRR_INCLUDES)
1388
1389 AC_CHECK_HEADERS([linux/mroute.h], [], [],[
1390         #include <sys/socket.h>
1391         #include <netinet/in.h>
1392         #define _LINUX_IN_H             /* For Linux <= 2.6.25 */
1393         #include <linux/types.h>
1394 ])
1395
1396 m4_define([FRR_INCLUDES],
1397 FRR_INCLUDES
1398 [#if HAVE_LINUX_MROUTE_H
1399 # include <linux/mroute.h>
1400 #endif
1401 ])dnl
1402
1403 AC_CHECK_HEADERS([netinet/ip_mroute.h], [], [],[
1404         #include <sys/socket.h>
1405         #include <sys/types.h>
1406         #include <netinet/in.h>
1407         #include <net/route.h>
1408 ])
1409
1410 m4_define([FRR_INCLUDES],
1411 FRR_INCLUDES
1412 [#if HAVE_NETINET_IP_MROUTE_H
1413 # include <netinet/ip_mroute.h>
1414 #endif
1415 ])dnl
1416
1417 AC_MSG_CHECKING([for BSD struct ip_mreq hack])
1418 AC_TRY_COMPILE([#include <sys/param.h>],
1419 [#if (defined(__FreeBSD__) && ((__FreeBSD_version >= 500022 && __FreeBSD_version < 700000) || (__FreeBSD_version < 500000 && __FreeBSD_version >= 440000))) || (defined(__NetBSD__) && defined(__NetBSD_Version__) && __NetBSD_Version__ >= 106010000) || defined(__OpenBSD__) || defined(__APPLE__) || defined(__DragonFly__) || defined(__sun)
1420   return (0);
1421 #else
1422   #error No support for BSD struct ip_mreq hack detected
1423 #endif],[AC_MSG_RESULT([yes])
1424 AC_DEFINE([HAVE_BSD_STRUCT_IP_MREQ_HACK], [1], [Can pass ifindex in struct ip_mreq])],
1425 AC_MSG_RESULT([no]))
1426
1427 AC_MSG_CHECKING([for RFC3678 protocol-independed API])
1428 AC_TRY_COMPILE([
1429 #include <sys/types.h>
1430 #include <netinet/in.h>
1431 ], [struct group_req gr; int sock; setsockopt(sock, IPPROTO_IP, MCAST_JOIN_GROUP, (void*)&gr, sizeof(gr));
1432 ], [AC_MSG_RESULT([yes])
1433 AC_DEFINE([HAVE_RFC3678], [1], [Have RFC3678 protocol-independed API])],
1434 AC_MSG_RESULT([no]))
1435
1436 dnl ---------------------------------------------------------------
1437 dnl figure out how to check link-state
1438 dnl ---------------------------------------------------------------
1439 AC_CHECK_HEADER([net/if_media.h],
1440   [m4_define([LINK_DETECT_INCLUDES],
1441     FRR_INCLUDES
1442     [#include <net/if_media.h>
1443   ])
1444   AC_CHECK_MEMBERS([struct ifmediareq.ifm_status],
1445     AC_DEFINE([HAVE_BSD_LINK_DETECT], [1], [BSD link-detect]),
1446     [], LINK_DETECT_INCLUDES)],
1447   [],
1448   FRR_INCLUDES)
1449
1450 dnl ---------------------------------------------------------------
1451 dnl Additional, newer way to check link-state using ifi_link_state.
1452 dnl Not available in all BSD's when ifmediareq available
1453 dnl ---------------------------------------------------------------
1454 AC_CHECK_MEMBERS([struct if_data.ifi_link_state],
1455   AC_DEFINE([HAVE_BSD_IFI_LINK_STATE], [1], [BSD ifi_link_state available]),
1456   [], FRR_INCLUDES)
1457
1458 dnl ------------------------
1459 dnl TCP_MD5SIG socket option
1460 dnl ------------------------
1461
1462 AC_CHECK_HEADER([netinet/tcp.h],
1463    [m4_define([MD5_INCLUDES],
1464       FRR_INCLUDES
1465       [#include <netinet/tcp.h>
1466     ])
1467     AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)],
1468    [],
1469    FRR_INCLUDES)
1470 if test $ac_cv_have_decl_TCP_MD5SIG = no; then
1471   AC_CHECK_HEADER([linux/tcp.h],
1472        [m4_define([MD5_INCLUDES],
1473           FRR_INCLUDES
1474           [#include <linux/tcp.h>
1475         ])
1476        AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)])
1477 fi
1478
1479 dnl ----------------------------------------------------------------------------
1480 dnl figure out if domainname is available in the utsname struct (GNU extension).
1481 dnl ----------------------------------------------------------------------------
1482 AC_CHECK_MEMBERS([struct utsname.domainname], [], [], [#include <sys/utsname.h>])
1483
1484 dnl ------------------
1485 dnl IPv6 header checks
1486 dnl ------------------
1487 AC_CHECK_HEADERS([netinet6/in6.h netinet/in6_var.h \
1488         netinet6/in6_var.h netinet6/nd6.h], [], [],
1489         FRR_INCLUDES)
1490
1491 m4_define([FRR_INCLUDES],dnl
1492 FRR_INCLUDES
1493 [#if HAVE_NETINET6_IN6_H
1494 #include <netinet6/in6.h>
1495 #endif
1496 #if HAVE_NETINET_IN6_VAR_H
1497 #include <netinet/in6_var.h>
1498 #endif
1499 #include <netinet/icmp6.h>
1500 #if HAVE_NETINET6_IN6_VAR_H
1501 # include <netinet6/in6_var.h>
1502 #endif
1503 #if HAVE_NETINET6_ND6_H
1504 # include <netinet6/nd6.h>
1505 #endif
1506 ])dnl
1507
1508 dnl disable doc check
1509 AC_CHECK_PROGS([SPHINXBUILD], [sphinx-build sphinx-build3 sphinx-build2], [/bin/false])
1510 if test "$SPHINXBUILD" = "/bin/false"; then
1511   if test "${enable_doc}" = "yes"; then
1512     AC_MSG_ERROR([Documentation was explicitly requested with --enable-doc but sphinx-build is not available. Please disable docs or install sphinx.])
1513   fi
1514 fi
1515 AM_CONDITIONAL([DOC], [test "${enable_doc}" != "no" -a "$SPHINXBUILD" != "/bin/false"])
1516 AM_CONDITIONAL([DOC_HTML], [test "${enable_doc_html}" = "yes"])
1517
1518 dnl --------------------
1519 dnl Daemon disable check
1520 dnl --------------------
1521 AM_CONDITIONAL([ZEBRA], [test "${enable_zebra}" != "no"])
1522
1523 if test "${enable_bgpd}" = "no";then
1524   BGPD=""
1525 else
1526   BGPD="bgpd"
1527 fi
1528 AM_CONDITIONAL([BGPD], [test "x$BGPD" = "xbgpd"])
1529
1530 AM_CONDITIONAL([RIPD], [test "${enable_ripd}" != "no"])
1531 AM_CONDITIONAL([OSPFD], [test "${enable_ospfd}" != "no"])
1532 AM_CONDITIONAL([LDPD], [test "${enable_ldpd}" != "no"])
1533
1534 AS_IF([test "${enable_ldpd}" != "no"], [
1535   AC_DEFINE([HAVE_LDPD], [1], [ldpd])
1536 ])
1537
1538 if test "$enable_bfdd" = "no"; then
1539   AC_DEFINE([HAVE_BFDD], [0], [bfdd])
1540   BFDD=""
1541 else
1542   AC_DEFINE([HAVE_BFDD], [1], [bfdd])
1543   BFDD="bfdd"
1544
1545   case $host_os in
1546     linux*)
1547       AC_DEFINE([BFD_LINUX], [1], [bfdd])
1548       ;;
1549
1550     *)
1551       AC_DEFINE([BFD_BSD], [1], [bfdd])
1552       ;;
1553   esac
1554 fi
1555
1556 AM_CONDITIONAL([BFDD], [test "x$BFDD" = "xbfdd"])
1557
1558 if test "$ac_cv_lib_json_c_json_object_get" = no -a "x$BFDD" = "xbfdd"; then
1559   AC_MSG_ERROR(["you must use json-c library to use bfdd"])
1560 fi
1561
1562 NHRPD=""
1563 case "$host_os" in
1564   linux*)
1565     if test "${enable_nhrpd}" != "no"; then
1566       NHRPD="nhrpd"
1567     fi
1568     ;;
1569   *)
1570     if test "${enable_nhrpd}" = "yes"; then
1571       AC_MSG_ERROR([nhrpd requires kernel APIs that are only present on Linux.])
1572     fi
1573     ;;
1574 esac
1575 AM_CONDITIONAL([NHRPD], [test "x$NHRPD" = "xnhrpd"])
1576
1577 AM_CONDITIONAL([EIGRPD], [test "${enable_eigrpd}" != "no"])
1578
1579 if test "${enable_watchfrr}" = "no";then
1580   WATCHFRR=""
1581 else
1582   WATCHFRR="watchfrr"
1583 fi
1584 AM_CONDITIONAL([WATCHFRR], [test "x$WATCHFRR" = "xwatchfrr"])
1585
1586 OSPFCLIENT=""
1587 if test "${enable_ospfapi}" != "no";then
1588     AC_DEFINE([SUPPORT_OSPF_API], [1], [OSPFAPI])
1589
1590   if test "${enable_ospfclient}" != "no";then
1591       OSPFCLIENT="ospfclient"
1592   fi
1593 fi
1594
1595 AM_CONDITIONAL([OSPFCLIENT], [test "x$OSPFCLIENT" = "xospfclient"])
1596 AM_CONDITIONAL([RIPNGD], [test "${enable_ripngd}" != "no"])
1597 AM_CONDITIONAL([BABELD], [test "${enable_babeld}" != "no"])
1598 AM_CONDITIONAL([OSPF6D], [test "${enable_ospf6d}" != "no"])
1599 AM_CONDITIONAL([ISISD], [test "${enable_isisd}" != "no"])
1600 AM_CONDITIONAL([PIMD], [test "${enable_pimd}" != "no"])
1601 AM_CONDITIONAL([PBRD], [test "${enable_pbrd}" != "no"])
1602 AM_CONDITIONAL([SHARPD], [test "${enable_sharpd}" = "yes"])
1603 AM_CONDITIONAL([STATICD], [test "${enable_staticd}" != "no"])
1604 AM_CONDITIONAL([FABRICD], [test "${enable_fabricd}" != "no"])
1605 AM_CONDITIONAL([VRRPD], [test "${enable_vrrpd}" != "no"])
1606
1607 if test "${enable_bgp_announce}" = "no";then
1608   AC_DEFINE([DISABLE_BGP_ANNOUNCE], [1], [Disable BGP installation to zebra])
1609 else
1610   AC_DEFINE([DISABLE_BGP_ANNOUNCE], [0], [Disable BGP installation to zebra])
1611 fi
1612
1613 if test "${enable_bgp_vnc}" != "no";then
1614   AC_DEFINE([ENABLE_BGP_VNC], [1], [Enable BGP VNC support])
1615 fi
1616 AM_CONDITIONAL([ENABLE_BGP_VNC], [test x${enable_bgp_vnc} != xno])
1617
1618 AC_SUBST([SOLARIS])
1619 AC_CHECK_LIB([crypt], [crypt], [],
1620                     [AC_CHECK_LIB([crypto], [DES_crypt])])
1621 AC_CHECK_LIB([resolv], [res_init])
1622
1623 dnl ---------------------------
1624 dnl check system has PCRE regexp
1625 dnl ---------------------------
1626 if test "x$enable_pcreposix" = "xyes"; then
1627   AC_CHECK_LIB([pcreposix], [regexec], [], [
1628     AC_MSG_ERROR([--enable-pcreposix given but unable to find libpcreposix])
1629   ])
1630 fi
1631 AC_SUBST([HAVE_LIBPCREPOSIX])
1632
1633 dnl ------------------
1634 dnl check C-Ares library
1635 dnl ------------------
1636 if test "${NHRPD}" != ""; then
1637   PKG_CHECK_MODULES([CARES], [libcares], ,[
1638     AC_MSG_ERROR([trying to build nhrpd, but libcares not found. install c-ares and its -dev headers.])
1639   ])
1640 fi
1641
1642
1643 dnl ------------------
1644 dnl check Net-SNMP library
1645 dnl ------------------
1646 if test "${enable_snmp}" != "" -a "${enable_snmp}" != "no"; then
1647    AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], [no])
1648    if test x"$NETSNMP_CONFIG" = x"no"; then
1649       AC_MSG_ERROR([--enable-snmp given but unable to find net-snmp-config])
1650    fi
1651    SNMP_LIBS="`${NETSNMP_CONFIG} --agent-libs`"
1652    SNMP_CFLAGS="`${NETSNMP_CONFIG} --base-cflags`"
1653    # net-snmp lists all of its own dependencies.  we absolutely do not want that
1654    # among other things we avoid a GPL vs. OpenSSL license conflict here
1655    for removelib in crypto ssl sensors pci wrap; do
1656      SNMP_LIBS="`echo $SNMP_LIBS | sed -e 's/\(^\|\s\)-l'$removelib'\b/ /g' -e 's/\(^\|\s\)\([^\s]*\/\)\?lib'$removelib'\.[^\s]\+\b/ /g'`"
1657    done
1658    AC_MSG_CHECKING([whether we can link to Net-SNMP])
1659    AC_LINK_IFELSE_FLAGS([$SNMP_CFLAGS], [$SNMP_LIBS], [AC_LANG_PROGRAM([
1660 int main(void);
1661 ],
1662 [
1663 {
1664   return 0;
1665 }
1666 ])], [
1667      AC_MSG_ERROR([--enable-snmp given but not usable])])
1668    case "${enable_snmp}" in
1669      yes)
1670       SNMP_METHOD=agentx
1671       ;;
1672      agentx)
1673       SNMP_METHOD="${enable_snmp}"
1674       ;;
1675      *)
1676       AC_MSG_ERROR([--enable-snmp given with an unknown method (${enable_snmp}). Use yes or agentx])
1677       ;;
1678    esac
1679    AH_TEMPLATE([SNMP_AGENTX], [Use SNMP AgentX to interface with snmpd])
1680    AC_DEFINE_UNQUOTED(AS_TR_CPP(SNMP_${SNMP_METHOD}),,[SNMP method to interface with snmpd])
1681 fi
1682 AM_CONDITIONAL([SNMP], [test "x${SNMP_METHOD}" != "x"])
1683 AC_SUBST([SNMP_LIBS])
1684 AC_SUBST([SNMP_CFLAGS])
1685
1686 dnl ---------------
1687 dnl libyang
1688 dnl ---------------
1689 PKG_CHECK_MODULES([LIBYANG], [libyang >= 0.16.7], , [
1690   AC_MSG_ERROR([libyang (>= 0.16.7) was not found on your system.])
1691 ])
1692 ac_cflags_save="$CFLAGS"
1693 CFLAGS="$CFLAGS $LIBYANG_CFLAGS"
1694 AC_CHECK_MEMBER([struct lyd_node.priv], [], [
1695   AC_MSG_ERROR([m4_normalize([
1696     libyang needs to be compiled with ENABLE_LYD_PRIV=ON.
1697     Instructions for this are included in the build documentation for your platform at http://docs.frrouting.org/projects/dev-guide/en/latest/building.html])
1698   ])
1699 ], [[#include <libyang/libyang.h>]])
1700 CFLAGS="$ac_cflags_save"
1701
1702 dnl ---------------
1703 dnl configuration rollbacks
1704 dnl ---------------
1705 SQLITE3=false
1706 if test "$enable_config_rollbacks" = "yes"; then
1707   PKG_CHECK_MODULES([SQLITE3], [sqlite3], [
1708     AC_DEFINE([HAVE_CONFIG_ROLLBACKS], [1], [Enable configuration rollbacks])
1709     AC_DEFINE([HAVE_SQLITE3], [1], [Enable sqlite3 database])
1710     SQLITE3=true
1711   ], [
1712     AC_MSG_ERROR([--enable-config-rollbacks given but sqlite3 was not found on your system.])
1713   ])
1714 fi
1715 AM_CONDITIONAL([SQLITE3], [$SQLITE3])
1716
1717 dnl ---------------
1718 dnl confd
1719 dnl ---------------
1720 if test "$enable_confd" != "" -a "$enable_confd" != "no"; then
1721    AC_CHECK_PROG([CONFD], [confd], [confd], [/bin/false], "${enable_confd}/bin")
1722    if test "x$CONFD" = "x/bin/false"; then
1723       AC_MSG_ERROR([confd was not found on your system.])]
1724    fi
1725    CONFD_CFLAGS="-I${enable_confd}/include -L${enable_confd}/lib"
1726    AC_SUBST([CONFD_CFLAGS])
1727    CONFD_LIBS="-lconfd"
1728    AC_SUBST([CONFD_LIBS])
1729    AC_DEFINE([HAVE_CONFD], [1], [Enable confd integration])
1730 fi
1731 AM_CONDITIONAL([CONFD], [test "x$enable_confd" != "x"])
1732
1733 dnl ---------------
1734 dnl sysrepo
1735 dnl ---------------
1736 if test "$enable_sysrepo" = "yes"; then
1737   PKG_CHECK_MODULES([SYSREPO], [libsysrepo],
1738       [AC_DEFINE([HAVE_SYSREPO], [1], [Enable sysrepo integration])
1739       SYSREPO=true],
1740       [SYSREPO=false
1741       AC_MSG_ERROR([sysrepo was not found on your system.])]
1742   )
1743 fi
1744 AM_CONDITIONAL([SYSREPO], [test "x$enable_sysrepo" = "xyes"])
1745
1746 dnl ---------------
1747 dnl gRPC
1748 dnl ---------------
1749 if test "$enable_grpc" = "yes"; then
1750   PKG_CHECK_MODULES([GRPC], [grpc grpc++ protobuf], [
1751     AC_CHECK_PROGS([PROTOC], [protoc], [/bin/false])
1752     if test "$PROTOC" = "/bin/false"; then
1753       AC_MSG_FAILURE([grpc requested but protoc not found.])
1754     fi
1755
1756     AC_DEFINE([HAVE_GRPC], [1], [Enable the gRPC northbound plugin])
1757     GRPC=true
1758   ], [
1759     GRPC=false
1760     AC_MSG_ERROR([grpc/grpc++ were not found on your system.])
1761   ])
1762 fi
1763 AM_CONDITIONAL([GRPC], [test "x$enable_grpc" = "xyes"])
1764
1765 dnl ---------------
1766 dnl math
1767 dnl ---------------
1768 AC_SEARCH_LIBS([sqrt], [m])
1769
1770 dnl ---------------
1771 dnl dlopen & dlinfo
1772 dnl ---------------
1773 AC_SEARCH_LIBS([dlopen], [dl dld], [], [
1774   AC_MSG_ERROR([unable to find the dlopen()])
1775 ])
1776
1777 AC_CHECK_HEADERS([link.h])
1778
1779 AC_CACHE_CHECK([for dlinfo(RTLD_DI_ORIGIN)], [frr_cv_rtld_di_origin], [
1780   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1781 #include <stdlib.h>
1782 #ifdef HAVE_LINK_H
1783 #include <link.h>
1784 #endif
1785 #include <dlfcn.h>
1786 ]], [[
1787   char origin[1];
1788   dlinfo (NULL, RTLD_DI_ORIGIN, &origin);
1789 ]])], [
1790     frr_cv_rtld_di_origin=yes
1791   ], [
1792     frr_cv_rtld_di_origin=no
1793   ])
1794 ])
1795 if test "$frr_cv_rtld_di_origin" = yes; then
1796   AC_DEFINE([HAVE_DLINFO_ORIGIN], [1], [Have dlinfo RTLD_DI_ORIGIN])
1797 fi
1798
1799 AC_CACHE_CHECK([for dlinfo(RTLD_DI_LINKMAP)], [frr_cv_rtld_di_linkmap], [
1800   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1801 #include <stdlib.h>
1802 #ifdef HAVE_LINK_H
1803 #include <link.h>
1804 #endif
1805 #include <dlfcn.h>
1806 ]], [[
1807   struct link_map *lm = NULL;
1808   dlinfo (NULL, RTLD_DI_LINKMAP, &lm);
1809 ]])], [
1810     frr_cv_rtld_di_linkmap=yes
1811   ], [
1812     frr_cv_rtld_di_linkmap=no
1813   ])
1814 ])
1815 if test "$frr_cv_rtld_di_linkmap" = yes; then
1816   AC_DEFINE([HAVE_DLINFO_LINKMAP], [1], [Have dlinfo RTLD_DI_LINKMAP])
1817 fi
1818
1819 AM_CONDITIONAL([SNMP], [test "x$SNMP_METHOD" = "xagentx"])
1820
1821 dnl ---------------------------
1822 dnl sockaddr and netinet checks
1823 dnl ---------------------------
1824 AC_CHECK_TYPES([
1825         struct sockaddr_dl,
1826         struct vifctl, struct mfcctl, struct sioc_sg_req,
1827         vifi_t, struct sioc_vif_req, struct igmpmsg,
1828         struct ifaliasreq, struct if6_aliasreq, struct in6_aliasreq,
1829         struct nd_opt_adv_interval, struct rt_addrinfo,
1830         struct nd_opt_homeagent_info, struct nd_opt_adv_interval,
1831         struct nd_opt_rdnss, struct nd_opt_dnssl],
1832         [], [], FRR_INCLUDES)
1833
1834 AC_CHECK_MEMBERS([struct sockaddr.sa_len,
1835         struct sockaddr_in.sin_len, struct sockaddr_un.sun_len,
1836         struct sockaddr_dl.sdl_len,
1837         struct if6_aliasreq.ifra_lifetime,
1838         struct nd_opt_adv_interval.nd_opt_ai_type],
1839         [], [], FRR_INCLUDES)
1840
1841 dnl ---------------------------
1842 dnl IRDP/pktinfo/icmphdr checks
1843 dnl ---------------------------
1844
1845 AC_CHECK_TYPES([struct in_pktinfo], [
1846   AC_CHECK_TYPES([struct icmphdr], [
1847     IRDP=true
1848   ], [
1849     IRDP=false
1850   ], [FRR_INCLUDES])
1851 ], [
1852   IRDP=false
1853 ], [FRR_INCLUDES])
1854
1855 case "${enable_irdp}" in
1856 yes)
1857   $IRDP || AC_MSG_ERROR(['IRDP requires in_pktinfo at the moment!'])
1858   ;;
1859 no)
1860   IRDP=false
1861   ;;
1862 esac
1863
1864 AM_CONDITIONAL([IRDP], [$IRDP])
1865
1866 dnl -----------------------
1867 dnl checking for IP_PKTINFO
1868 dnl -----------------------
1869 AC_MSG_CHECKING([for IP_PKTINFO])
1870 AC_TRY_COMPILE([#include <netdb.h>], [
1871   int opt = IP_PKTINFO;
1872 ], [
1873   AC_MSG_RESULT([yes])
1874   AC_DEFINE([HAVE_IP_PKTINFO], [1], [Have IP_PKTINFO])
1875 ], [
1876   AC_MSG_RESULT([no])
1877 ])
1878
1879 dnl ---------------------------
1880 dnl checking for IP_RECVDSTADDR
1881 dnl ---------------------------
1882 AC_MSG_CHECKING([for IP_RECVDSTADDR])
1883 AC_TRY_COMPILE([#include <netinet/in.h>], [
1884   int opt = IP_RECVDSTADDR;
1885 ], [
1886   AC_MSG_RESULT([yes])
1887   AC_DEFINE([HAVE_IP_RECVDSTADDR], [1], [Have IP_RECVDSTADDR])
1888 ], [
1889   AC_MSG_RESULT([no])
1890 ])
1891
1892 dnl ----------------------
1893 dnl checking for IP_RECVIF
1894 dnl ----------------------
1895 AC_MSG_CHECKING([for IP_RECVIF])
1896 AC_TRY_COMPILE([#include <netinet/in.h>], [
1897   int opt = IP_RECVIF;
1898 ], [
1899   AC_MSG_RESULT([yes])
1900   AC_DEFINE([HAVE_IP_RECVIF], [1], [Have IP_RECVIF])
1901 ], [
1902   AC_MSG_RESULT([no])
1903 ])
1904
1905 dnl ----------------------
1906 dnl checking for SO_BINDANY
1907 dnl ----------------------
1908 AC_MSG_CHECKING([for SO_BINDANY])
1909 AC_TRY_COMPILE([#include <sys/socket.h>], [
1910   int opt = SO_BINDANY;
1911 ], [
1912   AC_MSG_RESULT([yes])
1913   AC_DEFINE([HAVE_SO_BINDANY], [1], [Have SO_BINDANY])
1914 ], [
1915   AC_MSG_RESULT([no])
1916 ])
1917
1918 dnl ----------------------
1919 dnl checking for IP_FREEBIND
1920 dnl ----------------------
1921 AC_MSG_CHECKING([for IP_FREEBIND])
1922 AC_TRY_COMPILE([#include <netinet/in.h>], [
1923   int opt = IP_FREEBIND;
1924 ], [
1925   AC_MSG_RESULT([yes])
1926   AC_DEFINE([HAVE_IP_FREEBIND], [1], [Have IP_FREEBIND])
1927 ], [
1928   AC_MSG_RESULT([no])
1929 ])
1930
1931 dnl --------------------------------------
1932 dnl checking for be32dec existence or not
1933 dnl --------------------------------------
1934 AC_CHECK_DECLS([be32enc, be32dec], [], [],
1935                [#include <sys/endian.h>])
1936
1937 dnl --------------------------------------
1938 dnl checking for clock_time monotonic struct and call
1939 dnl --------------------------------------
1940 AC_CHECK_DECL([CLOCK_MONOTONIC],
1941         [AC_CHECK_LIB([rt], [clock_gettime], [LIBS="$LIBS -lrt"])
1942          AC_DEFINE([HAVE_CLOCK_MONOTONIC], [1], [Have monotonic clock])
1943 ], [AC_MSG_RESULT([no])], [FRR_INCLUDES])
1944
1945 dnl --------------------------------------
1946 dnl checking for flex and bison
1947 dnl --------------------------------------
1948
1949 AM_PROG_LEX
1950 AC_MSG_CHECKING([version of flex])
1951 frr_ac_flex_version="$(eval $LEX -V | grep flex | head -n 1)"
1952 frr_ac_flex_version="${frr_ac_flex_version##* }"
1953 AC_MSG_RESULT([$frr_ac_flex_version])
1954 AX_COMPARE_VERSION([$frr_ac_flex_version], [lt], [2.5.20], [
1955   LEX="$SHELL $missing_dir/missing flex"
1956   if test -f "${srcdir}/lib/command_lex.c" -a -f "${srcdir}/lib/command_lex.h"; then
1957     AC_MSG_WARN([using pregenerated flex output files])
1958   else
1959     AC_MSG_ERROR([flex failure and pregenerated files not included (probably a git build)])
1960   fi
1961   AC_SUBST([LEX_OUTPUT_ROOT], [lex.yy])
1962   AC_SUBST([LEXLIB], [''])
1963 ])
1964
1965 AC_PROG_YACC
1966 dnl thanks GNU bison for this b*llshit...
1967 AC_MSG_CHECKING([version of bison])
1968 frr_ac_bison_version="$(eval $YACC -V | grep bison | head -n 1)"
1969 frr_ac_bison_version="${frr_ac_bison_version##* }"
1970 frr_ac_bison_missing="false"
1971 case "x${frr_ac_bison_version}" in
1972   x2.7*)
1973     BISON_OPENBRACE='"'
1974     BISON_CLOSEBRACE='"'
1975     BISON_VERBOSE=''
1976     AC_MSG_RESULT([$frr_ac_bison_version - 2.7 or older])
1977     ;;
1978   x2.*|x1.*)
1979     AC_MSG_RESULT([$frr_ac_bison_version])
1980     AC_MSG_WARN([installed bison is too old.  Please install GNU bison 2.7.x or newer.])
1981     frr_ac_bison_missing="true"
1982     ;;
1983   x)
1984     AC_MSG_RESULT([none])
1985     AC_MSG_WARN([could not determine bison version.  Please install GNU bison 2.7.x or newer.])
1986     frr_ac_bison_missing="true"
1987     ;;
1988   *)
1989     BISON_OPENBRACE='{'
1990     BISON_CLOSEBRACE='}'
1991     BISON_VERBOSE='-Dparse.error=verbose'
1992     AC_MSG_RESULT([$frr_ac_bison_version - 3.0 or newer])
1993     ;;
1994 esac
1995 AC_SUBST([BISON_OPENBRACE])
1996 AC_SUBST([BISON_CLOSEBRACE])
1997 AC_SUBST([BISON_VERBOSE])
1998
1999 if $frr_ac_bison_missing; then
2000   YACC="$SHELL $missing_dir/missing bison -y"
2001   if test -f "${srcdir}/lib/command_parse.c" -a -f "${srcdir}/lib/command_parse.h"; then
2002     AC_MSG_WARN([using pregenerated bison output files])
2003   else
2004     AC_MSG_ERROR([bison failure and pregenerated files not included (probably a git build)])
2005   fi
2006 fi
2007
2008 dnl -------------------
2009 dnl capabilities checks
2010 dnl -------------------
2011 if test "${enable_capabilities}" != "no"; then
2012   AC_MSG_CHECKING([whether prctl PR_SET_KEEPCAPS is available])
2013   AC_TRY_COMPILE([#include <sys/prctl.h>], [prctl(PR_SET_KEEPCAPS, 1, 0, 0, 0);],
2014     [AC_MSG_RESULT([yes])
2015      AC_DEFINE([HAVE_PR_SET_KEEPCAPS], [1], [prctl])
2016      frr_ac_keepcaps="yes"],
2017      AC_MSG_RESULT([no])
2018   )
2019   if test x"${frr_ac_keepcaps}" = x"yes"; then
2020     AC_CHECK_HEADERS([sys/capability.h])
2021   fi
2022   if test x"${ac_cv_header_sys_capability_h}" = x"yes"; then
2023     AC_CHECK_LIB([cap], [cap_init],
2024       [AC_DEFINE([HAVE_LCAPS], [1], [Capabilities])
2025        LIBCAP="-lcap"
2026        frr_ac_lcaps="yes"]
2027     )
2028   else
2029     AC_CHECK_HEADERS([priv.h],
2030      [AC_MSG_CHECKING([Solaris style privileges are available])
2031       AC_TRY_COMPILE([#include <priv.h>], [getpflags(PRIV_AWARE);],
2032           [AC_MSG_RESULT([yes])
2033            AC_DEFINE([HAVE_SOLARIS_CAPABILITIES], [1], [getpflags])
2034            frr_ac_scaps="yes"],
2035            AC_MSG_RESULT(no)
2036       )
2037      ]
2038    )
2039   fi
2040   if test x"${frr_ac_scaps}" = x"yes" \
2041        -o x"${frr_ac_lcaps}" = x"yes"; then
2042     AC_DEFINE([HAVE_CAPABILITIES], [1], [capabilities])
2043   fi
2044 fi
2045 AC_SUBST([LIBCAP])
2046
2047 dnl ---------------------------
2048 dnl check for glibc 'backtrace'
2049 dnl ---------------------------
2050 if test x"${enable_backtrace}" != x"no" ; then
2051   backtrace_ok=no
2052   PKG_CHECK_MODULES([UNWIND], [libunwind], [
2053     AC_DEFINE([HAVE_LIBUNWIND], [1], [libunwind])
2054     backtrace_ok=yes
2055   ], [
2056     case "$host_os" in
2057     sunos* | solaris2*)
2058       AC_CHECK_FUNCS([printstack], [
2059         AC_DEFINE([HAVE_PRINTSTACK], [1], [Solaris printstack])
2060         backtrace_ok=yes
2061       ])
2062       ;;
2063     esac
2064     if test "$backtrace_ok" = no; then
2065       AC_CHECK_HEADER([execinfo.h], [
2066         AC_SEARCH_LIBS([backtrace], [execinfo], [
2067           AC_DEFINE([HAVE_GLIBC_BACKTRACE], [1], [Glibc backtrace])
2068           backtrace_ok=yes
2069         ],, [-lm])
2070       ])
2071     fi
2072   ])
2073
2074   if test x"${enable_backtrace}" = x"yes" -a x"${backtrace_ok}" = x"no"; then
2075     dnl user explicitly requested backtrace but we failed to find support
2076     AC_MSG_FAILURE([failed to find backtrace or libunwind support])
2077   fi
2078 fi
2079
2080 dnl -----------------------------------------
2081 dnl check for malloc mallinfo struct and call
2082 dnl this must try and link using LIBS, in
2083 dnl order to check no alternative allocator
2084 dnl has been specified, which might not provide
2085 dnl mallinfo, e.g. such as Umem on Solaris.
2086 dnl -----------------------------------------
2087 AC_CHECK_HEADERS([malloc.h malloc_np.h malloc/malloc.h],,, [FRR_INCLUDES])
2088
2089 AC_CACHE_CHECK([whether mallinfo is available], [frr_cv_mallinfo], [
2090   AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2091 #ifdef HAVE_MALLOC_H
2092 #include <malloc.h>
2093 #endif
2094 #ifdef HAVE_MALLOC_NP_H
2095 #include <malloc_np.h>
2096 #endif
2097 #ifdef HAVE_MALLOC_MALLOC_H
2098 #include <malloc/malloc.h>
2099 #endif
2100 ]], [[
2101 struct mallinfo ac_x; ac_x = mallinfo ();
2102 ]])], [
2103     frr_cv_mallinfo=yes
2104   ], [
2105     frr_cv_mallinfo=no
2106   ])
2107 ])
2108 if test "$frr_cv_mallinfo" = yes; then
2109   AC_DEFINE([HAVE_MALLINFO], [1], [mallinfo])
2110 fi
2111
2112 AC_MSG_CHECKING([whether malloc_usable_size is available])
2113 AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2114 #ifdef HAVE_MALLOC_H
2115 #include <malloc.h>
2116 #endif
2117 #ifdef HAVE_MALLOC_MALLOC_H
2118 #include <malloc/malloc.h>
2119 #endif
2120 ]], [[
2121 size_t ac_x; ac_x = malloc_usable_size(NULL);
2122 ]])], [
2123   AC_MSG_RESULT([yes])
2124   AC_DEFINE([HAVE_MALLOC_USABLE_SIZE], [1], [malloc_usable_size])
2125 ], [
2126   AC_MSG_RESULT([no])
2127
2128   AC_MSG_CHECKING([whether malloc_size is available])
2129   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2130 #ifdef HAVE_MALLOC_H
2131 #include <malloc.h>
2132 #endif
2133 #ifdef HAVE_MALLOC_MALLOC_H
2134 #include <malloc/malloc.h>
2135 #endif
2136 ]], [[
2137 size_t ac_x; ac_x = malloc_size(NULL);
2138 ]])], [
2139     AC_MSG_RESULT([yes])
2140     AC_DEFINE([HAVE_MALLOC_SIZE], [1], [malloc_size])
2141   ], [
2142     AC_MSG_RESULT([no])
2143   ])
2144 ])
2145
2146 dnl ------
2147 dnl ZeroMQ
2148 dnl ------
2149 if test "x$enable_zeromq" != "xno"; then
2150   PKG_CHECK_MODULES([ZEROMQ], [libzmq >= 4.0.0], [
2151     AC_DEFINE([HAVE_ZEROMQ], [1], [Enable ZeroMQ support])
2152     ZEROMQ=true
2153   ], [
2154     if test "x$enable_zeromq" = "xyes"; then
2155       AC_MSG_ERROR([configuration specifies --enable-zeromq but libzmq was not found])
2156     fi
2157   ])
2158 fi
2159 AM_CONDITIONAL([ZEROMQ], [test "x$ZEROMQ" = "xtrue"])
2160
2161 dnl ----------
2162 dnl configure date
2163 dnl ----------
2164 dev_version=`echo $VERSION | grep dev`
2165 #don't expire deprecated code in non 'dev' branch
2166 if test "${dev_version}" = ""; then
2167    CONFDATE=0
2168 else
2169    CONFDATE=`date '+%Y%m%d'`
2170 fi
2171 AC_SUBST([CONFDATE])
2172
2173 dnl ------------------------------
2174 dnl set paths for state directory
2175 dnl ------------------------------
2176 AC_MSG_CHECKING([directory to use for state file])
2177 if test "${prefix}" = "NONE"; then
2178   frr_statedir_prefix="";
2179 else
2180   frr_statedir_prefix=${prefix}
2181 fi
2182 if test "${localstatedir}" = '${prefix}/var'; then
2183   for FRR_STATE_DIR in ${frr_statedir_prefix}/var/run dnl
2184                         ${frr_statedir_prefix}/var/adm dnl
2185                         ${frr_statedir_prefix}/etc dnl
2186                         /var/run        dnl
2187                         /var/adm        dnl
2188                         /etc            dnl
2189                         /dev/null;
2190   do
2191     test -d $FRR_STATE_DIR && break
2192   done
2193   frr_statedir=$FRR_STATE_DIR
2194 else
2195   frr_statedir=${localstatedir}
2196 fi
2197 if test $frr_statedir = "/dev/null"; then
2198     AC_MSG_ERROR([STATE DIRECTORY NOT FOUND! FIX OR SPECIFY --localstatedir!])
2199 fi
2200 AC_MSG_RESULT([${frr_statedir}])
2201 AC_SUBST([frr_statedir])
2202
2203 AC_DEFINE_UNQUOTED([LDPD_SOCKET], ["$frr_statedir/ldpd.sock"], [ldpd control socket])
2204 AC_DEFINE_UNQUOTED([ZEBRA_SERV_PATH], ["$frr_statedir/zserv.api"], [zebra api socket])
2205 AC_DEFINE_UNQUOTED([BFDD_CONTROL_SOCKET], ["$frr_statedir/bfdd.sock"], [bfdd control socket])
2206 AC_DEFINE_UNQUOTED([DAEMON_VTY_DIR], ["$frr_statedir"], [daemon vty directory])
2207 AC_DEFINE_UNQUOTED([DAEMON_DB_DIR], ["$frr_statedir"], [daemon database directory])
2208
2209 dnl autoconf does this, but it does it too late...
2210 test "x$prefix" = xNONE && prefix=$ac_default_prefix
2211 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
2212
2213 dnl get the full path, recursing through variables...
2214 vtysh_bin="$bindir/vtysh"
2215 for I in 1 2 3 4 5 6 7 8 9 10; do
2216         eval vtysh_bin="\"$vtysh_bin\""
2217 done
2218 AC_DEFINE_UNQUOTED([VTYSH_BIN_PATH], ["$vtysh_bin"], [path to vtysh binary])
2219 AC_SUBST([vtysh_bin])
2220
2221 CFG_SYSCONF="$sysconfdir"
2222 CFG_SBIN="$sbindir"
2223 CFG_STATE="$frr_statedir"
2224 CFG_MODULE="$moduledir"
2225 CFG_YANGMODELS="$yangmodelsdir"
2226 CFG_LIBYANG_PLUGINS="$libyang_pluginsdir"
2227 for I in 1 2 3 4 5 6 7 8 9 10; do
2228         eval CFG_SYSCONF="\"$CFG_SYSCONF\""
2229         eval CFG_SBIN="\"$CFG_SBIN\""
2230         eval CFG_STATE="\"$CFG_STATE\""
2231         eval CFG_MODULE="\"$CFG_MODULE\""
2232         eval CFG_YANGMODELS="\"$CFG_YANGMODELS\""
2233         eval CFG_LIBYANG_PLUGINS="\"$CFG_LIBYANG_PLUGINS\""
2234 done
2235 AC_SUBST([CFG_SYSCONF])
2236 AC_SUBST([CFG_SBIN])
2237 AC_SUBST([CFG_STATE])
2238 AC_SUBST([CFG_MODULE])
2239 AC_SUBST([CFG_YANGMODELS])
2240 AC_SUBST([CFG_LIBYANG_PLUGINS])
2241 AC_DEFINE_UNQUOTED([MODULE_PATH], ["$CFG_MODULE"], [path to modules])
2242 AC_DEFINE_UNQUOTED([YANG_MODELS_PATH], ["$CFG_YANGMODELS"], [path to YANG data models])
2243 AC_DEFINE_UNQUOTED([LIBYANG_PLUGINS_PATH], ["$CFG_LIBYANG_PLUGINS"], [path to libyang plugins])
2244 AC_DEFINE_UNQUOTED([WATCHFRR_SH_PATH], ["${CFG_SBIN%/}/watchfrr.sh"], [path to watchfrr.sh])
2245
2246 dnl ------------------------------------
2247 dnl Enable RPKI and add librtr to libs
2248 dnl ------------------------------------
2249 if test "${enable_rpki}" = "yes"; then
2250   PKG_CHECK_MODULES([RTRLIB], [rtrlib >= 0.5.0],
2251       [RPKI=true],
2252       [RPKI=false
2253       AC_MSG_ERROR([rtrlib was not found on your system or is too old.])]
2254   )
2255 fi
2256 AM_CONDITIONAL([RPKI], [test "x$RPKI" = "xtrue"])
2257
2258 dnl ------------------------------------------
2259 dnl Check whether rtrlib was build with ssh support
2260 dnl ------------------------------------------
2261 AC_MSG_CHECKING([whether the RTR Library is compiled with SSH])
2262 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "rtrlib/rtrlib.h"]],
2263                         [[struct tr_ssh_config config;]])],
2264         [AC_MSG_RESULT([yes])
2265         AC_DEFINE([FOUND_SSH], [1], [found_ssh])],
2266         AC_MSG_RESULT([no])
2267 )
2268
2269 dnl ---------------------------
2270 dnl Check htonl works correctly
2271 dnl ---------------------------
2272 AC_MSG_CHECKING([for working htonl])
2273 AC_CACHE_VAL(ac_cv_htonl_works,
2274  [AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES],[htonl (0);])],
2275                 [ac_cv_htonl_works=yes], [ac_cv_htonl_works=no])
2276  ]
2277 )
2278 AC_MSG_RESULT([$ac_cv_htonl_works])
2279
2280 AC_CONFIG_FILES([Makefile],[sed -e 's/^#AUTODERP# //' -i Makefile])
2281
2282 AC_CONFIG_FILES([
2283           config.version
2284           changelog-auto
2285           redhat/frr.spec
2286           solaris/Makefile
2287           alpine/APKBUILD
2288           snapcraft/snapcraft.yaml
2289           lib/version.h
2290           tests/lib/cli/test_cli.refout
2291           pkgsrc/bgpd.sh pkgsrc/ospf6d.sh pkgsrc/ospfd.sh
2292           pkgsrc/ripd.sh pkgsrc/ripngd.sh pkgsrc/zebra.sh
2293           pkgsrc/eigrpd.sh])
2294
2295 AC_CONFIG_FILES([vtysh/extract.pl], [chmod +x vtysh/extract.pl])
2296 AC_CONFIG_FILES([tools/frr], [chmod +x tools/frr])
2297 AC_CONFIG_FILES([tools/watchfrr.sh], [chmod +x tools/watchfrr.sh])
2298 AC_CONFIG_FILES([tools/frrinit.sh], [chmod +x tools/frrinit.sh])
2299 AC_CONFIG_FILES([tools/frrcommon.sh])
2300
2301 AC_CONFIG_COMMANDS([lib/route_types.h], [
2302         dst="${ac_abs_top_builddir}/lib/route_types.h"
2303         ${PERL} "${ac_abs_top_srcdir}/lib/route_types.pl" \
2304                 < "${ac_abs_top_srcdir}/lib/route_types.txt" \
2305                 > "${dst}.tmp"
2306         test -f "${dst}" \
2307                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
2308                 && rm "${dst}.tmp" \
2309                 || mv "${dst}.tmp" "${dst}"
2310 ], [
2311         PERL="$PERL"
2312 ])
2313
2314 AS_IF([test "x$with_pkg_git_version" = "xyes"], [
2315     AC_CONFIG_COMMANDS([lib/gitversion.h], [
2316         dst="${ac_abs_top_builddir}/lib/gitversion.h"
2317         ${PERL} "${ac_abs_top_srcdir}/lib/gitversion.pl" \
2318                 "${ac_abs_top_srcdir}" \
2319                 > "${dst}.tmp"
2320         test -f "${dst}" \
2321                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
2322                 && rm "${dst}.tmp" \
2323                 || mv "${dst}.tmp" "${dst}"
2324     ], [
2325         PERL="$PERL"
2326     ])
2327 ])
2328
2329 ## Hack, but working solution to avoid rebuilding of frr.info.
2330 ## It's already in CVS until texinfo 4.7 is more common.
2331 AC_OUTPUT
2332
2333 echo "
2334 FRRouting configuration
2335 ------------------------------
2336 FRR version             : ${PACKAGE_VERSION}
2337 host operating system   : ${host_os}
2338 source code location    : ${srcdir}
2339 compiler                : ${CC}
2340 compiler flags          : ${CFLAGS} ${SAN_FLAGS}
2341 make                    : ${MAKE-make}
2342 linker flags            : ${LDFLAGS} ${SAN_FLAGS} ${LIBS} ${LIBCAP} ${LIBREADLINE} ${LIBM}
2343 state file directory    : ${frr_statedir}
2344 config file directory   : `eval echo \`echo ${sysconfdir}\``
2345 example directory       : `eval echo \`echo ${exampledir}\``
2346 module directory        : ${CFG_MODULE}
2347 user to run as          : ${enable_user}
2348 group to run as         : ${enable_group}
2349 group for vty sockets   : ${enable_vty_group}
2350 config file mask        : ${enable_configfile_mask}
2351 log file mask           : ${enable_logfile_mask}
2352 zebra protobuf enabled  : ${enable_protobuf:-no}
2353
2354 The above user and group must have read/write access to the state file
2355 directory and to the config files in the config file directory."
2356
2357 if test "${enable_doc}" != "no";then
2358   AS_IF([test "$SPHINXBUILD" = /bin/false],
2359      AC_MSG_WARN([sphinx-build is missing but required to build documentation]))
2360 fi