configure.ac

   1 ##
   2 ## Configure template file for FRRouting.
   3 ## autoconf will generate a configure script.
   4 ##
   5 ##  Copyright (c) 1996, 97, 98, 99, 2000 Kunihiro Ishiguro <kunihiro@zebra.org>
   6 ##  Portions Copyright (c) 2003 Paul Jakma <paul@dishone.st>
   7 ##
   8 AC_PREREQ([2.60])
   9
  10 AC_INIT([frr], [7.6-dev], [https://github.com/frrouting/frr/issues])
  11 PACKAGE_URL="https://frrouting.org/"
  12 AC_SUBST([PACKAGE_URL])
  13 PACKAGE_FULLNAME="FRRouting"
  14 AC_SUBST([PACKAGE_FULLNAME])
  15
  16 CONFIG_ARGS="`echo $ac_configure_args | sed -e \"s% '[[A-Z]]*FLAGS=[[^']]\+'%%g\"`"
  17 AC_SUBST([CONFIG_ARGS])
  18
  19 AC_CONFIG_SRCDIR([lib/zebra.h])
  20 AC_CONFIG_MACRO_DIR([m4])
  21
  22 dnl -----------------------------------
  23 dnl Get hostname and other information.
  24 dnl -----------------------------------
  25 AC_CANONICAL_BUILD()
  26 AC_CANONICAL_HOST()
  27
  28 AC_ARG_VAR([AR],[archiver command])
  29 AC_ARG_VAR([LD],[linker command])
  30 AC_ARG_VAR([OBJCOPY],[objcopy command])
  31 AC_ARG_VAR([OBJDUMP],[objdump command])
  32 AC_ARG_VAR([RANLIB],[ranlib command])
  33 AC_ARG_VAR([STRIP],[strip command])
  34
  35 hosttools_clippy="false"
  36 build_clippy="true"
  37
  38 dnl case 1: external clippy
  39 if test -n "$with_clippy" -a "$with_clippy" != "no" -a "$with_clippy" != "yes"; then
  40   if test "$enable_clippy_only" = "yes"; then
  41     AC_MSG_ERROR([--enable-clippy-only does not make sense with --with-clippy])
  42   fi
  43
  44   CLIPPY="$with_clippy"
  45   build_clippy="false"
  46   if test ! -x "$with_clippy"; then
  47     AC_MSG_ERROR([clippy tool ($with_clippy) is not executable])
  48   fi
  49
  50 dnl case 2: cross-compiling internal clippy
  51 elif test "$host" != "$build"; then
  52   if test "$srcdir" = "."; then
  53     AC_MSG_ERROR([cross-compilation is only possible with builddir separate from srcdir or by building clippy separately and using the --with-clippy option.  create a separate directory and run as .../path-to-frr/configure.])
  54   fi
  55   test -d hosttools || mkdir hosttools
  56   abssrc="`cd \"${srcdir}\"; pwd`"
  57
  58   AC_MSG_NOTICE([...])
  59   AC_MSG_NOTICE([... cross-compilation: creating hosttools directory and self-configuring for build platform tools])
  60   AC_MSG_NOTICE([... use HOST_CPPFLAGS / HOST_CFLAGS / HOST_LDFLAGS if neccessary])
  61   AC_MSG_NOTICE([...])
  62
  63   (
  64     for var in $ac_precious_vars; do
  65       dnl special cases
  66       case "$var" in
  67       YACC|YFLAGS) continue;;
  68       PYTHON*)     retain=true;;
  69       *)           retain=false;
  70       esac
  71
  72       eval "hostvar=\"\${HOST_$var}\""
  73       eval "targetvar=\"\${$var}\""
  74       if test -n "$hostvar"; then
  75         eval "$var='$hostvar'"
  76         _AS_ECHO_LOG([host $var='$hostvar'])
  77       elif $retain; then
  78         _AS_ECHO_LOG([host retain $var='$targetvar'])
  79       else
  80         eval "unset $var"
  81         _AS_ECHO_LOG([host unset $var])
  82       fi
  83     done
  84     cd hosttools
  85     "${abssrc}/configure" "--host=$build" "--build=$build" "--enable-clippy-only" "--disable-nhrpd" "--disable-vtysh"
  86   ) || exit 1
  87
  88   AC_MSG_NOTICE([...])
  89   AC_MSG_NOTICE([... cross-compilation: finished self-configuring for build platform tools])
  90   AC_MSG_NOTICE([...])
  91
  92   build_clippy="false"
  93   hosttools_clippy="true"
  94   CLIPPY="hosttools/lib/clippy"
  95
  96 dnl case 3: normal build internal clippy
  97 else
  98   CLIPPY="lib/clippy\$(EXEEXT)"
  99 fi
 100 AC_SUBST([CLIPPY])
 101 AM_CONDITIONAL([BUILD_CLIPPY], [$build_clippy])
 102 AM_CONDITIONAL([HOSTTOOLS_CLIPPY], [$hosttools_clippy])
 103 AM_CONDITIONAL([ONLY_CLIPPY], [test "$enable_clippy_only" = "yes"])
 104
 105 # Disable portability warnings -- our automake code (in particular
 106 # common.am) uses some constructs specific to gmake.
 107 AM_INIT_AUTOMAKE([1.12 -Wno-portability foreign])
 108 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
 109 AM_SILENT_RULES([yes])
 110 AC_CONFIG_HEADERS([config.h])
 111
 112 AC_PATH_PROG([PERL], [perl])
 113 PKG_PROG_PKG_CONFIG
 114
 115 dnl default is to match previous behavior
 116 exampledir=${sysconfdir}
 117 AC_ARG_ENABLE([exampledir],
 118           AS_HELP_STRING([--enable-exampledir],
 119                          [specify alternate directory for examples]),
 120                          exampledir="$enableval",)
 121 dnl XXX add --exampledir to autoconf standard directory list somehow
 122 AC_SUBST([exampledir])
 123
 124 dnl default is to match previous behavior
 125 pkgsrcrcdir=""
 126 AC_ARG_ENABLE([pkgsrcrcdir],
 127           AS_HELP_STRING([--enable-pkgsrcrcdir],
 128                          [specify directory for rc.d scripts]),
 129                          pkgsrcrcdir="$enableval",)
 130 dnl XXX add --pkgsrcrcdir to autoconf standard directory list somehow
 131 AC_SUBST([pkgsrcrcdir])
 132 AM_CONDITIONAL([PKGSRC], [test "$pkgsrcrcdir" != ""])
 133
 134 AC_ARG_WITH([moduledir], [AS_HELP_STRING([--with-moduledir=DIR], [module directory (${libdir}/frr/modules)])], [
 135         moduledir="$withval"
 136 ], [
 137         moduledir="\${libdir}/frr/modules"
 138 ])
 139 AC_SUBST([moduledir], [$moduledir])
 140
 141
 142 AC_ARG_WITH([yangmodelsdir], [AS_HELP_STRING([--with-yangmodelsdir=DIR], [yang models directory (${datarootdir}/yang)])], [
 143         yangmodelsdir="$withval"
 144 ], [
 145         yangmodelsdir="\${datarootdir}/yang"
 146 ])
 147 AC_SUBST([yangmodelsdir])
 148
 149 AC_ARG_WITH([vici-socket], [AS_HELP_STRING([--with-vici-socket=PATH], [vici-socket (/var/run/charon.vici)])], [
 150         vici_socket="$withval"
 151 ], [
 152         vici_socket="/var/run/charon.vici"
 153 ])
 154 AC_DEFINE_UNQUOTED([VICI_SOCKET], ["$vici_socket"], [StrongSWAN vici socket path])
 155
 156 AC_ARG_ENABLE(tcmalloc,
 157         AS_HELP_STRING([--enable-tcmalloc], [Turn on tcmalloc]),
 158 [case "${enableval}" in
 159   yes) tcmalloc_enabled=true
 160 LIBS="$LIBS -ltcmalloc_minimal"
 161  ;;
 162   no)  tcmalloc_enabled=false ;;
 163   *) AC_MSG_ERROR([bad value ${enableval} for --enable-tcmalloc]) ;;
 164 esac],[tcmalloc_enabled=false])
 165
 166
 167 dnl Thanks autoconf, but we don't want a default -g -O2.  We have our own
 168 dnl flag determination logic.
 169 CFLAGS="${CFLAGS:-}"
 170
 171 dnl --------------------
 172 dnl Check CC and friends
 173 dnl --------------------
 174 dnl note orig_cflags is also used further down
 175 orig_cflags="$CFLAGS"
 176 orig_cxxflags="$CXXFLAGS"
 177 AC_LANG([C])
 178 AC_PROG_CC
 179 AC_PROG_CPP
 180 AC_PROG_CXX
 181 AM_PROG_CC_C_O
 182 dnl remove autoconf default "-g -O2"
 183 CFLAGS="$orig_cflags"
 184 CXXFLAGS="$orig_cxxflags"
 185 AC_PROG_CC_C99
 186 dnl NB: see C11 below
 187
 188 PKG_PROG_PKG_CONFIG
 189
 190 dnl it's 2019, sed is sed.
 191 SED=sed
 192 AC_SUBST([SED])
 193
 194 dnl try and enable CFLAGS that are useful for FRR
 195 dnl - specifically, options to control warnings
 196
 197 AC_USE_SYSTEM_EXTENSIONS
 198 AC_DEFUN([AC_C_FLAG], [{
 199     m4_pushdef([cachename],[m4_translit([frr_cv_$1],[ =-+/{}$],[________])])
 200     AC_CACHE_CHECK([[whether $CC supports $1]], cachename, [
 201         AC_LANG_PUSH([C])
 202         ac_c_flag_save="$CFLAGS"
 203         CFLAGS="$CFLAGS $1"
 204         AC_COMPILE_IFELSE(
 205                 [AC_LANG_PROGRAM([[$4]])],
 206                 [
 207                         cachename=yes
 208                 ], [
 209                         cachename=no
 210                 ])
 211         CFLAGS="$ac_c_flag_save"
 212         AC_LANG_POP([C])
 213     ])
 214     if test "$cachename" = "yes"; then
 215         m4_if([$3], [], [CFLAGS="$CFLAGS $1"], [$3])
 216     else
 217         :
 218         $2
 219     fi
 220     m4_popdef([cachename])
 221 }])
 222
 223 AC_DEFUN([AC_LINK_IFELSE_FLAGS], [{
 224         AC_LANG_PUSH([C])
 225         ac_cflags_save="$CFLAGS"
 226         ac_libs_save="$LIBS"
 227         CFLAGS="$CFLAGS $1"
 228         LIBS="$LIBS $2"
 229         AC_LINK_IFELSE(
 230                 [$3],
 231                 [
 232                         CFLAGS="$ac_cflags_save"
 233                         LIBS="$ac_libs_save"
 234                         m4_default([$5], [
 235                                 AC_MSG_RESULT([yes])
 236                         ])
 237                 ], [
 238                         CFLAGS="$ac_cflags_save"
 239                         LIBS="$ac_libs_save"
 240                         m4_default([$4], [
 241                                 AC_MSG_RESULT([no])
 242                         ])
 243                 ])
 244         AC_LANG_POP([C])
 245         }])
 246
 247 dnl ICC won't bail on unknown options without -diag-error 10006
 248 dnl need to do this first so we get useful results for the other options
 249 AC_C_FLAG([-diag-error 10006])
 250
 251 dnl AC_PROG_CC_C99 may change CC to include -std=gnu99 or something
 252 ac_cc="$CC"
 253 CC="${CC% -std=gnu99}"
 254 CC="${CC% -std=c99}"
 255
 256 AC_C_FLAG([-std=gnu11], [CC="$ac_cc"], [CC="$CC -std=gnu11"])
 257
 258 dnl if the user has specified any CFLAGS, override our settings
 259 if test "$enable_gcov" = "yes"; then
 260    if test "$orig_cflags" = ""; then
 261       AC_C_FLAG([-coverage])
 262       AC_C_FLAG([-O0])
 263    fi
 264
 265    LDFLAGS="${LDFLAGS} -lgcov"
 266 fi
 267
 268 if test "$enable_clang_coverage" = "yes"; then
 269    AC_C_FLAG([-fprofile-instr-generate], [
 270      AC_MSG_ERROR([$CC does not support -fprofile-instr-generate.])
 271    ])
 272    AC_C_FLAG([-fcoverage-mapping], [
 273      AC_MSG_ERROR([$CC does not support -fcoverage-mapping.])
 274    ])
 275 fi
 276
 277 if test "$enable_dev_build" = "yes"; then
 278    AC_DEFINE([DEV_BUILD], [1], [Build for development])
 279    if test "$orig_cflags" = ""; then
 280       AC_C_FLAG([-g3])
 281       AC_C_FLAG([-O0])
 282    fi
 283    if test "$enable_lua" = "yes"; then
 284       AX_PROG_LUA([5.3])
 285       AX_LUA_HEADERS
 286       AX_LUA_LIBS([
 287          AC_DEFINE([HAVE_LUA], [1], [Have support for Lua interpreter])
 288          LIBS="$LIBS $LUA_LIB"
 289       ])
 290    fi
 291 else
 292    if test "$enable_lua" = "yes"; then
 293       AC_MSG_ERROR([Lua is not meant to be built/used outside of development at this time])
 294    fi
 295    if test "$orig_cflags" = ""; then
 296       AC_C_FLAG([-g])
 297       AC_C_FLAG([-O2])
 298    fi
 299 fi
 300 AM_CONDITIONAL([DEV_BUILD], [test "$enable_dev_build" = "yes"])
 301
 302 dnl always want these CFLAGS
 303 AC_C_FLAG([-fno-omit-frame-pointer])
 304 AC_C_FLAG([-funwind-tables])
 305 AC_C_FLAG([-Wall])
 306 AC_C_FLAG([-Wextra])
 307 AC_C_FLAG([-Wmissing-prototypes])
 308 AC_C_FLAG([-Wmissing-declarations])
 309 AC_C_FLAG([-Wpointer-arith])
 310 AC_C_FLAG([-Wbad-function-cast])
 311 AC_C_FLAG([-Wwrite-strings])
 312 AC_C_FLAG([-Wundef])
 313 if test "$enable_gcc_ultra_verbose" = "yes" ; then
 314   AC_C_FLAG([-Wcast-qual])
 315   AC_C_FLAG([-Wstrict-prototypes])
 316   AC_C_FLAG([-Wmissing-noreturn])
 317   AC_C_FLAG([-Wmissing-format-attribute])
 318   AC_C_FLAG([-Wunreachable-code])
 319   AC_C_FLAG([-Wpacked])
 320   AC_C_FLAG([-Wpadded])
 321   AC_C_FLAG([-Wshadow])
 322 else
 323   AC_C_FLAG([-Wno-unused-result])
 324 fi
 325 AC_C_FLAG([-Wno-unused-parameter])
 326 AC_C_FLAG([-Wno-missing-field-initializers])
 327
 328 AC_C_FLAG([-Wc++-compat], [], [CXX_COMPAT_CFLAGS="-Wc++-compat"])
 329 AC_SUBST([CXX_COMPAT_CFLAGS])
 330
 331 dnl ICC emits a broken warning for const char *x = a ? "b" : "c";
 332 dnl for some reason the string consts get 'promoted' to char *,
 333 dnl triggering a const to non-const conversion warning.
 334 AC_C_FLAG([-diag-disable 3179])
 335
 336 if test "$enable_werror" = "yes" ; then
 337   WERROR="-Werror"
 338 fi
 339 AC_SUBST([WERROR])
 340
 341 SAN_FLAGS=""
 342 if test "$enable_address_sanitizer" = "yes"; then
 343   AC_C_FLAG([-fsanitize=address], [
 344     AC_MSG_ERROR([$CC does not support Address Sanitizer.])
 345   ], [
 346     SAN_FLAGS="$SAN_FLAGS -fsanitize=address"
 347   ])
 348 fi
 349 if test "$enable_thread_sanitizer" = "yes"; then
 350   AC_C_FLAG([-fsanitize=thread], [
 351     AC_MSG_ERROR([$CC does not support Thread Sanitizer.])
 352   ], [
 353     SAN_FLAGS="$SAN_FLAGS -fsanitize=thread"
 354   ])
 355 fi
 356 if test "$enable_memory_sanitizer" = "yes"; then
 357   AC_C_FLAG([-fsanitize=memory -fPIE -pie], [
 358     AC_MSG_ERROR([$CC does not support Memory Sanitizer.])
 359   ], [
 360     SAN_FLAGS="$SAN_FLAGS -fsanitize=memory -fPIE -pie"
 361   ])
 362 fi
 363 if test "$enable_undefined_sanitizer" = "yes"; then
 364   AC_C_FLAG([-fsanitize=undefined], [
 365     AC_MSG_ERROR([$CC does not support UndefinedBehaviorSanitizer.])
 366   ], [
 367     SAN_FLAGS="$SAN_FLAGS -fsanitize=undefined"
 368   ])
 369 fi
 370 AC_SUBST([SAN_FLAGS])
 371
 372 dnl frr-format.so
 373 if test "$with_frr_format" != "no" -a "$with_frr_format" != "yes" -a -n "$with_frr_format"; then
 374   AC_C_FLAG([-fplugin=${with_frr_format}], [
 375     AC_MSG_ERROR([specified frr-format plugin ($with_frr_format) does not work])
 376   ],,[
 377 #ifndef _FRR_ATTRIBUTE_PRINTFRR
 378 #error plugin not loaded
 379 #endif
 380 #if _FRR_ATTRIBUTE_PRINTFRR < 0x10000
 381 #error plugin too old
 382 #endif
 383   ])
 384 elif test "$with_frr_format" = "no"; then
 385   : #nothing
 386 else
 387   AC_C_FLAG([-fplugin=tools/gcc-plugins/frr-format.so],[
 388     AC_C_FLAG([-fplugin=frr-format],[
 389       if test "$with_frr_format" = "yes"; then
 390         AC_MSG_ERROR([frr-format plugin requested but not found])
 391       fi
 392     ],,[
 393 #ifndef _FRR_ATTRIBUTE_PRINTFRR
 394 #error plugin not loaded
 395 #endif
 396 #if _FRR_ATTRIBUTE_PRINTFRR < 0x10000
 397 #error plugin too old
 398 #endif
 399     ])
 400   ],,[
 401 #ifndef _FRR_ATTRIBUTE_PRINTFRR
 402 #error plugin not loaded
 403 #endif
 404 #if _FRR_ATTRIBUTE_PRINTFRR < 0x10000
 405 #error plugin too old
 406 #endif
 407   ])
 408 fi
 409
 410 dnl ----------
 411 dnl Essentials
 412 dnl ----------
 413
 414 AX_PTHREAD([
 415   CC="$PTHREAD_CC"
 416   CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 417   LIBS="$PTHREAD_LIBS $LIBS"
 418 ], [
 419   AC_MSG_FAILURE([This FRR version needs pthreads])
 420 ])
 421
 422 AC_SEARCH_LIBS([pthread_condattr_setclock], [],
 423                 [frr_cv_pthread_condattr_setclock=yes],
 424                 [frr_cv_pthread_condattr_setclock=no])
 425 if test "$frr_cv_pthread_condattr_setclock" = "yes"; then
 426   AC_DEFINE([HAVE_PTHREAD_CONDATTR_SETCLOCK], [1], [Have pthread.h pthread_condattr_setclock])
 427 fi
 428
 429 dnl --------------
 430 dnl Check programs
 431 dnl --------------
 432 AC_PROG_INSTALL
 433 AC_PROG_LN_S
 434 AC_CHECK_TOOL([AR], [ar])
 435
 436 dnl -------
 437 dnl libtool
 438 dnl -------
 439 AC_ARG_ENABLE([static-bin],
 440   AS_HELP_STRING([--enable-static-bin], [link binaries statically]))
 441 LT_INIT
 442 _LT_CONFIG_LIBTOOL([
 443   patch -N -i "${srcdir}/m4/libtool-whole-archive.patch" libtool >&AS_MESSAGE_LOG_FD || \
 444     AC_MSG_WARN([Could not patch libtool for static linking support.  Loading modules into a statically linked daemon will fail.])
 445   sed -e 's%func_warning "relinking%true #\0%' -i libtool || true
 446   sed -e 's%func_warning "remember to run%true #\0%' -i libtool || true
 447   sed -e 's%func_warning ".*has not been installed in%true #\0%' -i libtool || true
 448 ])
 449 if test "$enable_static_bin" = "yes"; then
 450   AC_LDFLAGS="-static"
 451   if test "$enable_static" != "yes"; then
 452     AC_MSG_ERROR([The --enable-static-bin option must be combined with --enable-static.])
 453   fi
 454 fi
 455 if test "$enable_shared" != "yes"; then
 456   AC_MSG_ERROR([FRR cannot be built with --disable-shared.  If you want statically linked daemons, use --enable-shared --enable-static --enable-static-bin])
 457 fi
 458 AC_SUBST([AC_LDFLAGS])
 459 AM_CONDITIONAL([STATIC_BIN], [test "$enable_static_bin" = "yes"])
 460
 461 AC_ARG_ENABLE([rpath],
 462   [AS_HELP_STRING([--enable-rpath], [set hardcoded rpaths in the executable @<:@default=yes@:>@])],
 463   [],
 464   [enable_rpath=yes])
 465
 466 dnl $AR and $RANLIB are set by LT_INIT above
 467 AC_MSG_CHECKING([whether $AR supports D option])
 468 if $AR crD conftest.a >/dev/null 2>/dev/null; then
 469   AC_MSG_RESULT([yes])
 470   dnl ARFLAGS is for automake, AR_FLAGS for libtool m-(
 471   ARFLAGS="crD"
 472   AR_FLAGS="crD"
 473 else
 474   AC_MSG_RESULT([no])
 475   ARFLAGS="cru"
 476   AR_FLAGS="cru"
 477 fi
 478 AC_SUBST([ARFLAGS])
 479 AC_SUBST([AR_FLAGS])
 480
 481 AC_MSG_CHECKING([whether $RANLIB supports D option])
 482 if $RANLIB -D conftest.a >conftest.err 2>&1; then
 483   if grep -q -- '-D' conftest.err; then
 484     AC_MSG_RESULT([no])
 485   else
 486     AC_MSG_RESULT([yes])
 487     RANLIB="$RANLIB -D"
 488   fi
 489 else
 490   AC_MSG_RESULT([no])
 491 fi
 492 AC_SUBST([RANLIB])
 493
 494 test -f conftest.err && rm conftest.err
 495 test -f conftest.a && rm conftest.a
 496
 497 dnl ----------------------
 498 dnl Packages configuration
 499 dnl ----------------------
 500 if test -f config.version; then
 501   . ./config.version
 502 elif test -f "${srcdir}/config.version"; then
 503   . "${srcdir}/config.version"
 504 fi
 505 AC_ARG_WITH([pkg-extra-version],
 506   AS_HELP_STRING([--with-pkg-extra-version=VER], [add extra version field, for packagers/distributions]), [
 507   if test "$withval" = "no"; then
 508     EXTRAVERSION=
 509   else
 510     EXTRAVERSION=$withval
 511   fi
 512 ], [])
 513 AC_ARG_WITH([pkg-git-version],
 514         AS_HELP_STRING([--with-pkg-git-version], [add git information to MOTD and build version string]),
 515         [ test "$withval" != "no" && with_pkg_git_version="yes" ])
 516 AC_ARG_WITH([clippy],
 517   AS_HELP_STRING([--with-clippy=PATH], [use external clippy helper program]))
 518 AC_ARG_WITH([vtysh_pager],
 519         AS_HELP_STRING([--with-vtysh-pager=PAGER], [control what pager is compiled in as default]),
 520         VTYSH_PAGER=$withval, VTYSH_PAGER="more")
 521 AC_ARG_ENABLE([vtysh],
 522   AS_HELP_STRING([--disable-vtysh], [do not build integrated vty shell for FRR]))
 523 AC_ARG_ENABLE([doc],
 524   AS_HELP_STRING([--disable-doc], [do not build docs]))
 525 AC_ARG_ENABLE([doc-html],
 526   AS_HELP_STRING([--enable-doc-html], [build HTML docs]))
 527 AC_ARG_ENABLE([zebra],
 528   AS_HELP_STRING([--disable-zebra], [do not build zebra daemon]))
 529 AC_ARG_ENABLE([bgpd],
 530   AS_HELP_STRING([--disable-bgpd], [do not build bgpd]))
 531 AC_ARG_ENABLE([ripd],
 532   AS_HELP_STRING([--disable-ripd], [do not build ripd]))
 533 AC_ARG_ENABLE([ripngd],
 534   AS_HELP_STRING([--disable-ripngd], [do not build ripngd]))
 535 AC_ARG_ENABLE([ospfd],
 536   AS_HELP_STRING([--disable-ospfd], [do not build ospfd]))
 537 AC_ARG_ENABLE([ospf6d],
 538   AS_HELP_STRING([--disable-ospf6d], [do not build ospf6d]))
 539 AC_ARG_ENABLE([ldpd],
 540   AS_HELP_STRING([--disable-ldpd], [do not build ldpd]))
 541 AC_ARG_ENABLE([nhrpd],
 542   AS_HELP_STRING([--disable-nhrpd], [do not build nhrpd]))
 543 AC_ARG_ENABLE([eigrpd],
 544   AS_HELP_STRING([--disable-eigrpd], [do not build eigrpd]))
 545 AC_ARG_ENABLE([babeld],
 546   AS_HELP_STRING([--disable-babeld], [do not build babeld]))
 547 AC_ARG_ENABLE([watchfrr],
 548   AS_HELP_STRING([--disable-watchfrr], [do not build watchfrr]))
 549 AC_ARG_ENABLE([isisd],
 550   AS_HELP_STRING([--disable-isisd], [do not build isisd]))
 551 AC_ARG_ENABLE([pimd],
 552   AS_HELP_STRING([--disable-pimd], [do not build pimd]))
 553 AC_ARG_ENABLE([pbrd],
 554   AS_HELP_STRING([--disable-pbrd], [do not build pbrd]))
 555 AC_ARG_ENABLE([sharpd],
 556   AS_HELP_STRING([--enable-sharpd], [build sharpd]))
 557 AC_ARG_ENABLE([staticd],
 558   AS_HELP_STRING([--disable-staticd], [do not build staticd]))
 559 AC_ARG_ENABLE([fabricd],
 560   AS_HELP_STRING([--disable-fabricd], [do not build fabricd]))
 561 AC_ARG_ENABLE([vrrpd],
 562   AS_HELP_STRING([--disable-vrrpd], [do not build vrrpd]))
 563 AC_ARG_ENABLE([bgp-announce],
 564   AS_HELP_STRING([--disable-bgp-announce], [turn off BGP route announcement]))
 565 AC_ARG_ENABLE([bgp-vnc],
 566   AS_HELP_STRING([--disable-bgp-vnc],[turn off BGP VNC support]))
 567 AC_ARG_ENABLE([bgp-bmp],
 568   AS_HELP_STRING([--disable-bgp-bmp],[turn off BGP BMP support]))
 569 AC_ARG_ENABLE([snmp],
 570   AS_HELP_STRING([--enable-snmp], [enable SNMP support for agentx]))
 571 AC_ARG_ENABLE([config_rollbacks],
 572   AS_HELP_STRING([--enable-config-rollbacks], [enable configuration rollbacks (requires sqlite3)]))
 573 AC_ARG_ENABLE([confd],
 574   AS_HELP_STRING([--enable-confd=ARG], [enable confd integration]))
 575 AC_ARG_ENABLE([sysrepo],
 576   AS_HELP_STRING([--enable-sysrepo], [enable sysrepo integration]))
 577 AC_ARG_ENABLE([grpc],
 578   AS_HELP_STRING([--enable-grpc], [enable the gRPC northbound plugin]))
 579 AC_ARG_ENABLE([zeromq],
 580   AS_HELP_STRING([--enable-zeromq], [enable ZeroMQ handler (libfrrzmq)]))
 581 AC_ARG_ENABLE([lttng],
 582   AS_HELP_STRING([--enable-lttng], [enable LTTng tracing]))
 583 AC_ARG_ENABLE([usdt],
 584   AS_HELP_STRING([--enable-usdt], [enable USDT probes]))
 585 AC_ARG_WITH([libpam],
 586   AS_HELP_STRING([--with-libpam], [use libpam for PAM support in vtysh]))
 587 AC_ARG_ENABLE([ospfapi],
 588   AS_HELP_STRING([--disable-ospfapi], [do not build OSPFAPI to access the OSPF LSA Database]))
 589 AC_ARG_ENABLE([ospfclient],
 590   AS_HELP_STRING([--disable-ospfclient], [do not build OSPFAPI client for OSPFAPI,
 591                           (this is the default if --disable-ospfapi is set)]))
 592 AC_ARG_ENABLE([multipath],
 593   AS_HELP_STRING([--enable-multipath=ARG], [enable multipath function, ARG must be digit]))
 594 AC_ARG_ENABLE([user],
 595   AS_HELP_STRING([--enable-user=USER], [user to run FRR suite as (default frr)]))
 596 AC_ARG_ENABLE([group],
 597   AS_HELP_STRING([--enable-group=GROUP], [group to run FRR suite as (default frr)]))
 598 AC_ARG_ENABLE([vty_group],
 599   AS_HELP_STRING([--enable-vty-group=ARG], [set vty sockets to have specified group as owner]))
 600 AC_ARG_ENABLE([configfile_mask],
 601   AS_HELP_STRING([--enable-configfile-mask=ARG], [set mask for config files]))
 602 AC_ARG_ENABLE([logfile_mask],
 603   AS_HELP_STRING([--enable-logfile-mask=ARG], [set mask for log files]))
 604 AC_ARG_ENABLE([shell_access],
 605   AS_HELP_STRING([--enable-shell-access], [Allow users to access shell/telnet/ssh]))
 606 AC_ARG_ENABLE([realms],
 607   AS_HELP_STRING([--enable-realms], [enable REALMS support under Linux]))
 608 AC_ARG_ENABLE([rtadv],
 609   AS_HELP_STRING([--disable-rtadv], [disable IPV6 router advertisement feature]))
 610 AC_ARG_ENABLE([irdp],
 611   AS_HELP_STRING([--disable-irdp], [disable IRDP server support in zebra (enabled by default if supported)]))
 612 AC_ARG_ENABLE([capabilities],
 613   AS_HELP_STRING([--disable-capabilities], [disable using POSIX capabilities]))
 614 AC_ARG_ENABLE([rusage],
 615   AS_HELP_STRING([--disable-rusage], [disable using getrusage]))
 616 AC_ARG_ENABLE([gcc_ultra_verbose],
 617   AS_HELP_STRING([--enable-gcc-ultra-verbose], [enable ultra verbose GCC warnings]))
 618 AC_ARG_ENABLE([backtrace],
 619   AS_HELP_STRING([--disable-backtrace], [disable crash backtraces (default autodetect)]))
 620 AC_ARG_ENABLE([time-check],
 621   AS_HELP_STRING([--disable-time-check], [disable slow thread warning messages]))
 622 AC_ARG_ENABLE([cpu-time],
 623   AS_HELP_STRING([--disable-cpu-time], [disable cpu usage data gathering]))
 624 AC_ARG_ENABLE([pcreposix],
 625   AS_HELP_STRING([--enable-pcreposix], [enable using PCRE Posix libs for regex functions]))
 626 AC_ARG_ENABLE([fpm],
 627   AS_HELP_STRING([--enable-fpm], [enable Forwarding Plane Manager support]))
 628 AC_ARG_ENABLE([systemd],
 629   AS_HELP_STRING([--enable-systemd], [enable Systemd support]))
 630 AC_ARG_ENABLE([werror],
 631   AS_HELP_STRING([--enable-werror], [enable -Werror (recommended for developers only)]))
 632 AC_ARG_ENABLE([cumulus],
 633   AS_HELP_STRING([--enable-cumulus], [enable Cumulus Switch Special Extensions]))
 634 AC_ARG_ENABLE([datacenter],
 635   AS_HELP_STRING([--enable-datacenter], [enable Compilation for Data Center Extensions]))
 636 AC_ARG_ENABLE([rr-semantics],
 637   AS_HELP_STRING([--disable-rr-semantics], [disable the v6 Route Replace semantics]))
 638 AC_ARG_ENABLE([protobuf],
 639   AS_HELP_STRING([--enable-protobuf], [Enable experimental protobuf support]))
 640 AC_ARG_ENABLE([oldvpn_commands],
 641   AS_HELP_STRING([--enable-oldvpn-commands], [Keep old vpn commands]))
 642 AC_ARG_ENABLE([rpki],
 643   AS_HELP_STRING([--enable-rpki], [enable RPKI prefix validation support]))
 644 AC_ARG_ENABLE([clippy-only],
 645   AS_HELP_STRING([--enable-clippy-only], [Only build clippy]))
 646 AC_ARG_ENABLE([numeric_version],
 647   AS_HELP_STRING([--enable-numeric-version], [Only numeric digits allowed in version (for Alpine)]))
 648 AC_ARG_ENABLE([gcov],
 649   AS_HELP_STRING([--enable-gcov], [Collect coverage information with gcov]))
 650 AC_ARG_ENABLE([clang_coverage],
 651   AS_HELP_STRING([--enable-clang-coverage], [Collect coverage information with Clang Coverage]))
 652 AC_ARG_ENABLE([bfdd],
 653   AS_HELP_STRING([--disable-bfdd], [do not build bfdd]))
 654 AC_ARG_ENABLE([address-sanitizer],
 655   AS_HELP_STRING([--enable-address-sanitizer], [enable AddressSanitizer support for detecting a wide variety of memory allocation and deallocation errors]))
 656 AC_ARG_ENABLE([thread-sanitizer],
 657   AS_HELP_STRING([--enable-thread-sanitizer], [enable ThreadSanitizer support for detecting data races]))
 658 AC_ARG_ENABLE([memory-sanitizer],
 659   AS_HELP_STRING([--enable-memory-sanitizer], [enable MemorySanitizer support for detecting uninitialized memory reads]))
 660 AC_ARG_ENABLE([undefined-sanitizer],
 661   AS_HELP_STRING([--undefined-sanitizer], [enable UndefinedBehaviorSanitizer support for detecting undefined behavior]))
 662 AC_ARG_WITH([crypto],
 663   AS_HELP_STRING([--with-crypto=<internal|openssl>], [choose between different implementations of cryptographic functions(default value is --with-crypto=internal)]))
 664 AC_ARG_WITH([frr-format],
 665   AS_HELP_STRING([--with-frr-format[=<.../frr-format.so>]], [use frr-format GCC plugin]))
 666
 667 AC_ARG_ENABLE([version-build-config],
 668   AS_HELP_STRING([--disable-version-build-config], [do not include build configs in show version command]))
 669
 670 #if openssl, else use the internal
 671 AS_IF([test "$with_crypto" = "openssl"], [
 672 AC_CHECK_LIB([crypto], [EVP_DigestInit], [LIBS="$LIBS -lcrypto"], [], [])
 673 if test "$ac_cv_lib_crypto_EVP_DigestInit" = "no"; then
 674   AC_MSG_ERROR([build with openssl has been specified but openssl library was not found on your system])
 675 else
 676   AC_DEFINE([CRYPTO_OPENSSL], [1], [Compile with openssl support])
 677 fi
 678 ], [test "$with_crypto" = "internal" || test "$with_crypto" = "" ], [AC_DEFINE([CRYPTO_INTERNAL], [1], [Compile with internal cryptographic implementation])
 679 ], [AC_MSG_ERROR([Unknown value for --with-crypto])]
 680 )
 681
 682 AS_IF([test "$enable_clippy_only" != "yes"], [
 683 AC_CHECK_HEADERS([json-c/json.h])
 684 AC_CHECK_LIB([json-c], [json_object_get], [LIBS="$LIBS -ljson-c"], [], [-lm])
 685 if test "$ac_cv_lib_json_c_json_object_get" = "no"; then
 686   AC_CHECK_LIB([json], [json_object_get], [LIBS="$LIBS -ljson"])
 687   if test "$ac_cv_lib_json_json_object_get" = "no"; then
 688       AC_MSG_ERROR([libjson is needed to compile])
 689   fi
 690 fi
 691 ])
 692
 693 AC_ARG_ENABLE([dev_build],
 694     AS_HELP_STRING([--enable-dev-build], [build for development]))
 695
 696 AC_ARG_ENABLE([lua],
 697     AS_HELP_STRING([--enable-lua], [Build Lua scripting]))
 698
 699 if test "$enable_time_check" != "no" ; then
 700   if test "$enable_time_check" = "yes" -o "$enable_time_check" = "" ; then
 701     AC_DEFINE([CONSUMED_TIME_CHECK], [5000000], [Consumed Time Check])
 702   else
 703     AC_DEFINE_UNQUOTED([CONSUMED_TIME_CHECK], [$enable_time_check], [Consumed Time Check])
 704   fi
 705 fi
 706
 707 case "${enable_cpu_time}" in
 708   "no")
 709   AC_DEFINE([EXCLUDE_CPU_TIME], [1], [Exclude getrusage data gathering])
 710   ;;
 711   "*")
 712   ;;
 713 esac
 714
 715 case "${enable_systemd}" in
 716   "no") ;;
 717   "yes")
 718   AC_CHECK_LIB([systemd], [sd_notify], [LIBS="$LIBS -lsystemd"])
 719   if test "$ac_cv_lib_systemd_sd_notify" = "no"; then
 720     AC_MSG_ERROR([enable systemd has been specified but systemd development env not found on your system])
 721   else
 722     AC_DEFINE([HAVE_SYSTEMD], [1], [Compile systemd support in])
 723   fi
 724   ;;
 725   "*") ;;
 726 esac
 727
 728 if test "$enable_rr_semantics" != "no" ; then
 729   AC_DEFINE([HAVE_V6_RR_SEMANTICS], [1], [Compile in v6 Route Replacement Semantics])
 730 fi
 731
 732 if test "$enable_datacenter" = "yes" ; then
 733   AC_DEFINE([HAVE_DATACENTER], [1], [Compile extensions for a DataCenter])
 734   AC_MSG_WARN([The --enable-datacenter compile time option is deprecated.  Please modify the init script to pass -F datacenter to the daemons instead.])
 735   DFLT_NAME="datacenter"
 736 else
 737   DFLT_NAME="traditional"
 738 fi
 739
 740 if test "$enable_cumulus" = "yes" ; then
 741   AC_DEFINE([HAVE_CUMULUS], [1], [Compile Special Cumulus Code in])
 742 fi
 743
 744 AC_SUBST([DFLT_NAME])
 745 AC_DEFINE_UNQUOTED([DFLT_NAME], ["$DFLT_NAME"], [Name of the configuration default set])
 746
 747 if test "$enable_shell_access" = "yes"; then
 748    AC_DEFINE([HAVE_SHELL_ACCESS], [1], [Allow user to use ssh/telnet/bash, be aware this is considered insecure])
 749 fi
 750
 751 #
 752 # Python for clippy
 753 #
 754
 755 AS_IF([test "$host" = "$build"], [
 756   FRR_PYTHON_DEV
 757 ], [
 758   FRR_PYTHON
 759 ])
 760
 761 FRR_PYTHON_MODULES([pytest])
 762
 763 if test "$enable_doc" != "no"; then
 764   FRR_PYTHON_MODULES([sphinx], , [
 765     if test "$enable_doc" = "yes"; then
 766       AC_MSG_ERROR([Documentation was explicitly requested with --enable-doc but sphinx is not available for $PYTHON. Please disable docs or install sphinx.])
 767     fi
 768   ])
 769 fi
 770 AM_CONDITIONAL([DOC], [test "$enable_doc" != "no" -a "$frr_py_mod_sphinx" != "false"])
 771 AM_CONDITIONAL([DOC_HTML], [test "$enable_doc_html" = "yes"])
 772
 773 FRR_PYTHON_MOD_EXEC([sphinx], [--version], [
 774   PYSPHINX="-m sphinx"
 775 ], [
 776   PYSPHINX="-c 'import sys; from sphinx import main; sys.exit(main(sys.argv))'"
 777 ])
 778 AC_SUBST([PYSPHINX])
 779
 780 #
 781 # Logic for old vpn commands support.
 782 #
 783 if test "$enable_oldvpn_commands" = "yes"; then
 784    AC_DEFINE([KEEP_OLD_VPN_COMMANDS], [1], [Define for compiling with old vpn commands])
 785 fi
 786
 787 #
 788 # End of logic for protobuf support.
 789 #
 790
 791 AC_MSG_CHECKING([if zebra should be configurable to send Route Advertisements])
 792 if test "$enable_rtadv" != "no"; then
 793   AC_MSG_RESULT([yes])
 794   AC_DEFINE([HAVE_RTADV], [1], [Enable IPv6 Routing Advertisement support])
 795 else
 796   AC_MSG_RESULT([no])
 797 fi
 798
 799 if test "$enable_user" = "no"; then
 800   enable_user=""
 801 else
 802   if test "$enable_user" = "yes" || test "$enable_user" = ""; then
 803     enable_user="frr"
 804   fi
 805   AC_DEFINE_UNQUOTED([FRR_USER], ["${enable_user}"], [frr User])
 806 fi
 807
 808 if test "$enable_group" = "no"; then
 809   enable_group=""
 810 else
 811   if test "$enable_group" = "yes" || test "$enable_group" = ""; then
 812     enable_group="frr"
 813   fi
 814   AC_DEFINE_UNQUOTED([FRR_GROUP], ["${enable_group}"], [frr Group])
 815 fi
 816
 817 if test "$enable_vty_group" = "yes" ; then
 818   AC_MSG_ERROR([--enable-vty-group requires a group as argument, not yes])
 819 elif test "$enable_vty_group" != ""; then
 820   if test "$enable_vty_group" != "no"; then
 821     AC_DEFINE_UNQUOTED([VTY_GROUP], ["${enable_vty_group}"], [VTY Sockets Group])
 822   fi
 823 fi
 824 AC_SUBST([enable_user])
 825 AC_SUBST([enable_group])
 826 AC_SUBST([enable_vty_group])
 827
 828 enable_configfile_mask=${enable_configfile_mask:-0600}
 829 AC_DEFINE_UNQUOTED([CONFIGFILE_MASK], [${enable_configfile_mask}], [Mask for config files])
 830 AC_SUBST([enable_configfile_mask])
 831
 832 enable_logfile_mask=${enable_logfile_mask:-0600}
 833 AC_DEFINE_UNQUOTED([LOGFILE_MASK], [${enable_logfile_mask}], [Mask for log files])
 834
 835 MPATH_NUM=16
 836
 837 case "${enable_multipath}" in
 838   0)
 839     MPATH_NUM=64
 840     ;;
 841   [[1-9]|[1-9][0-9]|[1-9][0-9][0-9]])
 842     MPATH_NUM="${enable_multipath}"
 843     ;;
 844   "")
 845     ;;
 846   *)
 847     AC_MSG_FAILURE([Please specify digit to enable multipath ARG])
 848     ;;
 849 esac
 850
 851 AC_DEFINE_UNQUOTED([MULTIPATH_NUM], [$MPATH_NUM], [Maximum number of paths for a route])
 852
 853 AC_DEFINE_UNQUOTED([VTYSH_PAGER], ["$VTYSH_PAGER"], [What pager to use])
 854
 855 dnl --------------------
 856 dnl Enable code coverage
 857 dnl --------------------
 858 AM_CONDITIONAL([HAVE_GCOV], [test "$enable_gcov" != "no"])
 859
 860 dnl ------------------------------------
 861 dnl Alpine only accepts numeric versions
 862 dnl ------------------------------------
 863 if test "$enable_numeric_version" != "" ; then
 864   VERSION="`echo ${VERSION} | tr -c -d '[[.0-9]]'`"
 865   PACKAGE_VERSION="`echo ${PACKAGE_VERSION} | tr -c -d '[[.0-9]]'`"
 866 fi
 867
 868 dnl -----------------------------------
 869 dnl Add extra version string to package
 870 dnl name, string and version fields.
 871 dnl -----------------------------------
 872 if test "$EXTRAVERSION" != "" ; then
 873   VERSION="${VERSION}${EXTRAVERSION}"
 874   PACKAGE_VERSION="${PACKAGE_VERSION}${EXTRAVERSION}"
 875   AC_SUBST(PACKAGE_EXTRAVERSION, ["${EXTRAVERSION}"])
 876   PACKAGE_STRING="${PACKAGE_STRING}${EXTRAVERSION}"
 877 fi
 878 AC_SUBST([EXTRAVERSION])
 879
 880 if test "$with_pkg_git_version" = "yes"; then
 881         if test -e "${srcdir}/.git"; then
 882                 AC_DEFINE([GIT_VERSION], [1], [include git version info])
 883         else    with_pkg_git_version="no"
 884                 AC_MSG_WARN([--with-pkg-git-version given, but this is not a git checkout])
 885         fi
 886 fi
 887 AM_CONDITIONAL([GIT_VERSION], [test "$with_pkg_git_version" = "yes"])
 888
 889 AC_CHECK_TOOL([OBJCOPY], [objcopy], [:])
 890 if test "$OBJCOPY" != ":"; then
 891   AC_CACHE_CHECK([for .interp value to use], [frr_cv_interp], [
 892     frr_cv_interp=""
 893     AC_LINK_IFELSE([AC_LANG_SOURCE([[int main() { return 0; }]])], [
 894       if $OBJCOPY -j.interp -Obinary conftest conftest.interp; then
 895         frr_cv_interp="`xargs -0 echo < conftest.interp`"
 896       fi
 897       test -f conftest.interp && rm conftest.interp
 898     ])
 899   ])
 900 fi
 901 if test -n "$frr_cv_interp"; then
 902   AC_DEFINE_UNQUOTED([INTERP], ["$frr_cv_interp"], [.interp value])
 903 fi
 904
 905 dnl -------------------------
 906 dnl Check other header files.
 907 dnl -------------------------
 908 AC_CHECK_HEADERS([stropts.h sys/ksym.h \
 909         linux/version.h asm/types.h])
 910
 911 ac_stdatomic_ok=false
 912 AC_DEFINE([FRR_AUTOCONF_ATOMIC], [1], [did autoconf checks for atomic funcs])
 913 AC_CHECK_HEADER([stdatomic.h],[
 914
 915   AC_MSG_CHECKING([whether _Atomic qualifier works])
 916   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 917 #include <stdatomic.h>
 918 int main(int argc, char **argv) {
 919   _Atomic int i = 0;
 920   return i;
 921 }
 922 ]])], [
 923     AC_DEFINE([HAVE_STDATOMIC_H], [1], [found stdatomic.h])
 924     AC_MSG_RESULT([yes])
 925     ac_stdatomic_ok=true
 926   ], [
 927     AC_MSG_RESULT([no])
 928   ])
 929 ])
 930
 931 AS_IF([$ac_stdatomic_ok], [true], [
 932   AC_MSG_CHECKING([for __atomic_* builtins])
 933   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 934 int main(int argc, char **argv) {
 935   volatile int i = 1;
 936   __atomic_store_n (&i, 0, __ATOMIC_RELEASE);
 937   return __atomic_load_n (&i, __ATOMIC_ACQUIRE);
 938 }
 939 ]])], [
 940     AC_DEFINE([HAVE___ATOMIC], [1], [found __atomic builtins])
 941     AC_MSG_RESULT([yes])
 942   ], [
 943     AC_MSG_RESULT([no])
 944
 945     dnl FreeBSD 9 has a broken stdatomic.h where _Atomic doesn't work
 946     AC_MSG_CHECKING([for __sync_* builtins])
 947     AC_LINK_IFELSE([AC_LANG_SOURCE([[
 948 int main(int argc, char **argv) {
 949   volatile int i = 1;
 950   __sync_fetch_and_sub (&i, 1);
 951   return __sync_val_compare_and_swap (&i, 0, 1);
 952 }
 953 ]])], [
 954       AC_DEFINE([HAVE___SYNC], [1], [found __sync builtins])
 955       AC_MSG_RESULT([yes])
 956
 957       AC_MSG_CHECKING([for __sync_swap builtin])
 958       AC_LINK_IFELSE([AC_LANG_SOURCE([[
 959 int main(int argc, char **argv) {
 960   volatile int i = 1;
 961   return __sync_swap (&i, 2);
 962 }
 963 ]])], [
 964         AC_DEFINE([HAVE___SYNC_SWAP], 1, [found __sync_swap builtin])
 965         AC_MSG_RESULT([yes])
 966       ], [
 967         AC_MSG_RESULT([no])
 968       ])
 969
 970     ], [
 971       AC_MSG_RESULT([no])
 972       AC_MSG_FAILURE([stdatomic.h unavailable and $CC has neither __atomic nor __sync builtins])
 973     ])
 974   ])
 975 ])
 976
 977 AC_CHECK_HEADERS([pthread_np.h],,, [
 978 #include <pthread.h>
 979 ])
 980 AC_CHECK_FUNCS([pthread_setname_np pthread_set_name_np pthread_getthreadid_np])
 981
 982 needsync=true
 983
 984 AS_IF([$needsync], [
 985   dnl Linux
 986   AC_MSG_CHECKING([for Linux futex() support])
 987   AC_LINK_IFELSE([AC_LANG_PROGRAM([
 988 #ifndef _GNU_SOURCE
 989 #define _GNU_SOURCE
 990 #endif
 991 #include <unistd.h>
 992 #include <limits.h>
 993 #include <sys/time.h>
 994 #include <sys/syscall.h>
 995 #include <linux/futex.h>
 996
 997 int main(void);
 998 ],
 999 [
1000 {
1001   return syscall(SYS_futex, NULL, FUTEX_WAIT, 0, NULL, NULL, 0);
1002 }
1003 ])], [
1004     AC_MSG_RESULT([yes])
1005     AC_DEFINE(HAVE_SYNC_LINUX_FUTEX,,Have Linux futex support)
1006     needsync=false
1007   ], [
1008     AC_MSG_RESULT([no])
1009   ])
1010 ])
1011
1012 AS_IF([$needsync], [
1013   dnl FreeBSD
1014   AC_MSG_CHECKING([for FreeBSD _umtx_op() support])
1015   AC_LINK_IFELSE([AC_LANG_PROGRAM([
1016 #include <errno.h>
1017 #include <stdlib.h>
1018 #include <sys/types.h>
1019 #include <sys/umtx.h>
1020 int main(void);
1021 ],
1022 [
1023 {
1024   return _umtx_op(NULL, UMTX_OP_WAIT_UINT, 0, NULL, NULL);
1025 }
1026 ])], [
1027     AC_MSG_RESULT([yes])
1028     AC_DEFINE(HAVE_SYNC_UMTX_OP,,Have FreeBSD _umtx_op() support)
1029     needsync=false
1030   ], [
1031     AC_MSG_RESULT([no])
1032   ])
1033 ])
1034
1035 AS_IF([$needsync], [
1036   dnl OpenBSD patch (not upstream at the time of writing this)
1037   dnl https://marc.info/?l=openbsd-tech&m=147299508409549&w=2
1038   AC_MSG_CHECKING([for OpenBSD futex() support])
1039   AC_LINK_IFELSE([AC_LANG_PROGRAM([
1040 #include <sys/futex.h>
1041 int main(void);
1042 ],
1043 [
1044 {
1045   return futex(NULL, FUTEX_WAIT, 0, NULL, NULL, 0);
1046 }
1047 ])], [
1048     AC_MSG_RESULT([yes])
1049     AC_DEFINE(HAVE_SYNC_OPENBSD_FUTEX,,Have OpenBSD futex support)
1050     needsync=false
1051   ], [
1052     AC_MSG_RESULT([no])
1053   ])
1054 ])
1055
1056 dnl Utility macro to avoid retyping includes all the time
1057 m4_define([FRR_INCLUDES],
1058 [#ifdef SUNOS_5
1059 #define _POSIX_C_SOURCE 200809L
1060 #define __EXTENSIONS__
1061 #endif
1062 #include <stdio.h>
1063 #include <stdlib.h>
1064 #include <stddef.h>
1065 #include <sys/types.h>
1066 /* sys/conf.h depends on param.h on FBSD at least */
1067 #include <sys/param.h>
1068 /* Required for MAXSIG */
1069 #include <signal.h>
1070 #include <sys/socket.h>
1071 #ifdef __APPLE__
1072 # define __APPLE_USE_RFC_3542
1073 #endif
1074 #include <netinet/in.h>
1075 #include <sys/time.h>
1076 #include <time.h>
1077 #include <net/if.h>
1078 ])dnl
1079
1080 dnl Same applies for HAVE_NET_IF_VAR_H, which HAVE_NETINET6_ND6_H and
1081 dnl HAVE_NETINET_IN_VAR_H depend upon. But if_var.h depends on if.h, hence
1082 dnl an additional round for it.
1083
1084 AC_CHECK_HEADERS([net/if_var.h], [], [], [FRR_INCLUDES])
1085
1086 m4_define([FRR_INCLUDES],
1087 FRR_INCLUDES
1088 [#ifdef HAVE_NET_IF_VAR_H
1089 # include <net/if_var.h>
1090 #endif
1091 ])dnl
1092
1093 AC_CHECK_HEADERS([netinet/in_var.h \
1094         net/if_dl.h net/netopt.h \
1095         inet/nd.h netinet/ip_icmp.h \
1096         sys/sysctl.h sys/sockio.h sys/conf.h],
1097         [], [], [FRR_INCLUDES])
1098
1099 AC_CHECK_HEADERS([ucontext.h], [], [],
1100 [#ifndef __USE_GNU
1101 #define __USE_GNU
1102 #endif /* __USE_GNU */
1103 FRR_INCLUDES
1104 ])
1105
1106 m4_define([UCONTEXT_INCLUDES],
1107 [#include <ucontext.h>])dnl
1108
1109 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.uc_regs],
1110   [], [], [UCONTEXT_INCLUDES])
1111 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs],
1112   [AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs.nip],
1113    [], [], [UCONTEXT_INCLUDES])],
1114   [], [UCONTEXT_INCLUDES])
1115 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.gregs],
1116   [], [], [UCONTEXT_INCLUDES])
1117
1118 m4_define([FRR_INCLUDES],
1119 FRR_INCLUDES
1120 [
1121 #include <sys/un.h>
1122 #include <netinet/in_systm.h>
1123 #ifdef HAVE_NETINET_IN_VAR_H
1124 # include <netinet/in_var.h>
1125 #endif
1126 #ifdef HAVE_NET_IF_DL_H
1127 # include <net/if_dl.h>
1128 #endif
1129 #ifdef HAVE_NET_NETOPT_H
1130 # include <net/netopt.h>
1131 #endif
1132 #include <net/route.h>
1133 #ifdef HAVE_INET_ND_H
1134 # include <inet/nd.h>
1135 #endif
1136 #include <arpa/inet.h>
1137 /* Required for IDRP */
1138 #ifdef HAVE_NETINET_IP_ICMP_H
1139 # include <netinet/ip_icmp.h>
1140 #endif
1141 ])dnl
1142
1143 dnl V6 headers are checked below, after we check for v6
1144
1145 is_linux=false
1146
1147 AC_MSG_CHECKING([which operating system interface to use])
1148 case "$host_os" in
1149   sunos* | solaris2*)
1150     AC_MSG_FAILURE([Solaris support has been removed please see versions prior or equal to 7.5])
1151     ;;
1152   linux*)
1153     AC_MSG_RESULT([Linux])
1154
1155     AC_DEFINE([GNU_LINUX], [1], [GNU Linux])
1156     AC_DEFINE([HAVE_NETLINK], [1], [netlink])
1157     AC_DEFINE([LINUX_IPV6], [1], [Linux IPv6 stack])
1158
1159     dnl Linux has a compilation problem with mixing
1160     dnl netinet/in.h and linux/in6.h they are not
1161     dnl compatible.  There has been discussion on
1162     dnl how to fix it but no real progress on implementation
1163     dnl when they fix it, remove this
1164     AC_DEFINE([IPV6_MINHOPCOUNT], [73], [Linux ipv6 Min Hop Count])
1165
1166     is_linux=true
1167     ;;
1168   openbsd*)
1169     AC_MSG_RESULT([OpenBSD])
1170
1171     AC_DEFINE([OPEN_BSD], [1], [OpenBSD])
1172     AC_DEFINE([KAME], [1], [KAME IPv6])
1173     AC_DEFINE([BSD_V6_SYSCTL], [1], [BSD v6 sysctl to turn on and off forwarding])
1174     ;;
1175   *)
1176     AC_MSG_RESULT([BSD])
1177
1178     AC_DEFINE([HAVE_NET_RT_IFLIST], [1], [NET_RT_IFLIST])
1179     AC_DEFINE([KAME], [1], [KAME IPv6])
1180     AC_DEFINE([BSD_V6_SYSCTL], [1], [BSD v6 sysctl to turn on and off forwarding])
1181     ;;
1182 esac
1183 AM_CONDITIONAL([LINUX], [${is_linux}])
1184
1185 AC_SYS_LARGEFILE
1186
1187 dnl ------------------------
1188 dnl Integrated REALMS option
1189 dnl ------------------------
1190 if test "$enable_realms" = "yes"; then
1191     case "$host_os" in
1192       linux*)
1193        AC_DEFINE([SUPPORT_REALMS], [1], [Realms support])
1194        ;;
1195       *)
1196        echo "Sorry, only Linux has REALMS support"
1197        exit 1
1198        ;;
1199     esac
1200 fi
1201
1202 dnl -------------------------------
1203 dnl Endian-ness check
1204 dnl -------------------------------
1205 AC_WORDS_BIGENDIAN
1206
1207 dnl ---------------
1208 dnl other functions
1209 dnl ---------------
1210 AC_CHECK_FUNCS([ \
1211         strlcat strlcpy \
1212         getgrouplist \
1213         openat \
1214         unlinkat \
1215         posix_fallocate \
1216         ])
1217
1218 dnl ##########################################################################
1219 dnl LARGE if block spans a lot of "configure"!
1220 if test "$enable_clippy_only" != "yes"; then
1221 dnl ##########################################################################
1222
1223 #
1224 # Logic for protobuf support.
1225 #
1226 PROTO3=false
1227 if test "$enable_protobuf" = "yes"; then
1228   # Check for protoc & protoc-c
1229
1230   # protoc is not required, it's only for a "be nice" helper target
1231   AC_CHECK_PROGS([PROTOC], [protoc], [/bin/false])
1232
1233   AC_CHECK_PROGS([PROTOC_C], [protoc-c], [/bin/false])
1234   if test "$PROTOC_C" = "/bin/false"; then
1235     AC_MSG_FAILURE([protobuf requested but protoc-c not found.  Install protobuf-c.])
1236   fi
1237
1238   PKG_CHECK_MODULES([PROTOBUF_C], [libprotobuf-c >= 0.14],, [
1239     AC_MSG_FAILURE([protobuf requested but libprotobuf-c not found.  Install protobuf-c.])
1240   ])
1241
1242   PROTO3=true
1243   AC_CHECK_HEADER([google/protobuf-c/protobuf-c.h],
1244                   [AC_CHECK_DECLS(PROTOBUF_C_LABEL_NONE,
1245                                   AC_DEFINE([HAVE_PROTOBUF_VERSION_3],
1246                                             [1], [Have Protobuf version 3]),
1247                                   [PROTO3=false],
1248                                   [#include <google/protobuf-c/protobuf-c.h>])],
1249                   [PROTO3=false && AC_MSG_FAILURE([protobuf requested but protobuf-c.h not found.  Install protobuf-c.])])
1250
1251   AC_DEFINE([HAVE_PROTOBUF], [1], [protobuf])
1252 fi
1253
1254
1255 dnl ---------------------
1256 dnl Integrated VTY option
1257 dnl ---------------------
1258 case "${enable_vtysh}" in
1259 "no")
1260   VTYSH="";;
1261 *)
1262   VTYSH="vtysh";
1263   AC_DEFINE([VTYSH], [1], [VTY shell])
1264
1265   prev_libs="$LIBS"
1266   AC_CHECK_LIB([readline], [main], [
1267     LIBREADLINE="-lreadline"
1268   ], [
1269     dnl readline failed - it might be incorrectly linked and missing its
1270     dnl termcap/tinfo/curses dependency.  see if we can fix that...
1271     AC_SEARCH_LIBS([tputs], [termcap tinfo curses ncurses], [
1272       LIBREADLINE="$ac_cv_search_tputs"
1273     ], [
1274       AC_MSG_ERROR([libreadline (needed for vtysh) not found and/or missing dependencies])
1275     ])
1276
1277     dnl re-try with the lib we found above
1278     unset ac_cv_lib_readline_main
1279     AC_CHECK_LIB([readline], [main], [
1280       LIBREADLINE="-lreadline $LIBREADLINE"
1281     ], [
1282       AC_MSG_ERROR([libreadline (needed for vtysh) not found and/or missing dependencies])
1283     ], [$LIBREADLINE])
1284   ], [])
1285   LIBS="$prev_libs"
1286
1287   AC_CHECK_HEADER([readline/history.h])
1288   if test "$ac_cv_header_readline_history_h" = "no"; then
1289     AC_MSG_ERROR([readline is too old to have readline/history.h, please update to the latest readline library.])
1290   fi
1291   AC_CHECK_LIB([readline], [rl_completion_matches], [true], [], [$LIBREADLINE])
1292   if test "$ac_cv_lib_readline_rl_completion_matches" = "no"; then
1293     AC_DEFINE([rl_completion_matches], [completion_matches], [Old readline])
1294   fi
1295   AC_CHECK_LIB([readline], [append_history], [frr_cv_append_history=yes], [frr_cv_append_history=no], [$LIBREADLINE])
1296   if test "$frr_cv_append_history" = "yes"; then
1297     AC_DEFINE([HAVE_APPEND_HISTORY], [1], [Have history.h append_history])
1298   fi
1299   ;;
1300 esac
1301 AC_SUBST([LIBREADLINE])
1302
1303 dnl ----------
1304 dnl PAM module
1305 dnl
1306 dnl FRR detects the PAM library it is built against by checking for a
1307 dnl functional pam_misc.h (Linux-PAM) or openpam.h (OpenPAM) header. pam_misc.h
1308 dnl is known to #include pam_appl.h, the standard header of a PAM library, and
1309 dnl openpam.h doesn't do that, although depends on the header too. Hence a
1310 dnl little assistance to AC_CHECK_HEADER is necessary for the proper detection
1311 dnl of OpenPAM.
1312 dnl ----------
1313 if test "$with_libpam" = "yes"; then
1314   AC_CHECK_HEADER([security/pam_misc.h],
1315     [AC_DEFINE([HAVE_PAM_MISC_H], [1], [Have pam_misc.h])
1316      AC_DEFINE([PAM_CONV_FUNC], [misc_conv], [Have misc_conv])
1317      pam_conv_func="misc_conv"
1318     ],
1319     [], FRR_INCLUDES)
1320   AC_CHECK_HEADER([security/openpam.h],
1321     [AC_DEFINE([HAVE_OPENPAM_H], [1], [Have openpam.h])
1322      AC_DEFINE([PAM_CONV_FUNC], [openpam_ttyconv], [Have openpam_ttyconv])
1323      pam_conv_func="openpam_ttyconv"
1324     ],
1325     [], FRR_INCLUDES[#include <security/pam_appl.h>])
1326   if test -z "$ac_cv_header_security_pam_misc_h$ac_cv_header_security_openpam_h" ; then
1327     AC_MSG_WARN([*** pam support will not be built ***])
1328     with_libpam="no"
1329   fi
1330 fi
1331
1332 if test "$with_libpam" = "yes"; then
1333 dnl took this test from proftpds configure.in and suited to our needs
1334 dnl -------------------------------------------------------------------------
1335 dnl
1336 dnl This next check looks funky due to a linker problem with some versions
1337 dnl of the PAM library.  Prior to 0.72 release, the Linux PAM shared library
1338 dnl omitted requiring libdl linking information. PAM-0.72 or better ships
1339 dnl with RedHat 6.2 and Debian 2.2 or better.
1340 AC_CHECK_LIB([pam], [pam_start],
1341   [AC_CHECK_LIB([pam], [$pam_conv_func],
1342     [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1343      LIBPAM="-lpam"],
1344     [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1345      LIBPAM="-lpam -lpam_misc"]
1346     )
1347   ],
1348
1349   [AC_CHECK_LIB([pam], [pam_end],
1350     [AC_CHECK_LIB([pam], [$pam_conv_func],
1351       [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1352        LIBPAM="-lpam -ldl"],
1353       [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1354        LIBPAM="-lpam -ldl -lpam_misc"]
1355      )
1356   ],AC_MSG_WARN([*** pam support will not be built ***]),
1357   [-ldl])
1358   ]
1359 )
1360 fi
1361 AC_SUBST([LIBPAM])
1362
1363 dnl -------------------------------
1364 dnl bgpd needs pow() and hence libm
1365 dnl -------------------------------
1366 TMPLIBS="$LIBS"
1367 LIBS=""
1368 AC_SEARCH_LIBS([pow], [m], [
1369   LIBM="$LIBS"
1370 ], [
1371   AC_MSG_WARN([Unable to find working pow function - bgpd may not link])
1372 ])
1373 LIBS="$TMPLIBS"
1374 AC_SUBST([LIBM])
1375
1376 AC_CHECK_FUNCS([ppoll], [
1377   AC_DEFINE([HAVE_PPOLL], [1], [have Linux/BSD ppoll()])
1378 ])
1379 AC_CHECK_FUNCS([pollts], [
1380   AC_DEFINE([HAVE_POLLTS], [1], [have NetBSD pollts()])
1381 ])
1382
1383 AC_CHECK_HEADER([asm-generic/unistd.h],
1384                 [AC_CHECK_DECL(__NR_setns,
1385                                AC_DEFINE([HAVE_NETNS], [1], [Have netns]),,
1386                                FRR_INCLUDES [#include <asm-generic/unistd.h>
1387                                ])
1388                  AC_CHECK_FUNCS([setns])]
1389                )
1390
1391 dnl --------------------------
1392 dnl Determine IS-IS I/O method
1393 dnl --------------------------
1394 AC_DEFINE([ISIS_METHOD_PFPACKET], [1], [constant value for isis method pfpacket])
1395 AC_DEFINE([ISIS_METHOD_DLPI], [2], [constant value for isis method dlpi])
1396 AC_DEFINE([ISIS_METHOD_BPF], [3], [constant value for isis method bpf])
1397 AC_CHECK_HEADER([net/bpf.h])
1398 AC_CHECK_HEADER([sys/dlpi.h])
1399 AC_MSG_CHECKING([zebra IS-IS I/O method])
1400
1401 case "$host_os" in
1402   linux*)
1403     AC_MSG_RESULT([pfpacket])
1404     ISIS_METHOD_MACRO="ISIS_METHOD_PFPACKET"
1405     ;;
1406   *)
1407     if test "$ac_cv_header_net_bpf_h" = "no"; then
1408       if test "$ac_cv_header_sys_dlpi_h" = "no"; then
1409         AC_MSG_RESULT([none])
1410         if test "$enable_isisd" = "yes" -o "$enable_fabricd" = "yes"; then
1411           AC_MSG_FAILURE([IS-IS support requested but no packet backend found])
1412         fi
1413         AC_MSG_WARN([*** IS-IS support will not be built ***])
1414         enable_isisd="no"
1415         enable_fabricd="no"
1416       else
1417         AC_MSG_RESULT([DLPI])
1418       fi
1419       ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1420     else
1421       AC_MSG_RESULT([BPF])
1422       ISIS_METHOD_MACRO="ISIS_METHOD_BPF"
1423     fi
1424     ;;
1425 esac
1426 AC_DEFINE_UNQUOTED([ISIS_METHOD], [$ISIS_METHOD_MACRO], [selected method for isis, == one of the constants])
1427
1428 dnl ---------------------------------------------------------------
1429 dnl figure out how to specify an interface in multicast sockets API
1430 dnl ---------------------------------------------------------------
1431 AC_CHECK_MEMBERS([struct ip_mreqn.imr_ifindex], [], [], FRR_INCLUDES)
1432
1433 AC_CHECK_HEADERS([linux/mroute.h], [], [],[
1434         #include <sys/socket.h>
1435         #include <netinet/in.h>
1436         #define _LINUX_IN_H             /* For Linux <= 2.6.25 */
1437         #include <linux/types.h>
1438 ])
1439
1440 m4_define([FRR_INCLUDES],
1441 FRR_INCLUDES
1442 [#ifdef HAVE_LINUX_MROUTE_H
1443 # include <linux/mroute.h>
1444 #endif
1445 ])dnl
1446
1447 AC_CHECK_HEADERS([netinet/ip_mroute.h], [], [],[
1448         #include <sys/socket.h>
1449         #include <sys/types.h>
1450         #include <netinet/in.h>
1451         #include <net/route.h>
1452 ])
1453
1454 m4_define([FRR_INCLUDES],
1455 FRR_INCLUDES
1456 [#ifdef HAVE_NETINET_IP_MROUTE_H
1457 # include <netinet/ip_mroute.h>
1458 #endif
1459 ])dnl
1460
1461 AC_MSG_CHECKING([for BSD struct ip_mreq hack])
1462 AC_TRY_COMPILE([#include <sys/param.h>],
1463 [#if (defined(__FreeBSD__) && ((__FreeBSD_version >= 500022 && __FreeBSD_version < 700000) || (__FreeBSD_version < 500000 && __FreeBSD_version >= 440000))) || (defined(__NetBSD__) && defined(__NetBSD_Version__) && __NetBSD_Version__ >= 106010000) || defined(__OpenBSD__) || defined(__APPLE__) || defined(__DragonFly__) || defined(__sun)
1464   return (0);
1465 #else
1466   #error No support for BSD struct ip_mreq hack detected
1467 #endif],[AC_MSG_RESULT([yes])
1468 AC_DEFINE([HAVE_BSD_STRUCT_IP_MREQ_HACK], [1], [Can pass ifindex in struct ip_mreq])],
1469 AC_MSG_RESULT([no]))
1470
1471 AC_MSG_CHECKING([for RFC3678 protocol-independed API])
1472 AC_TRY_COMPILE([
1473 #include <sys/types.h>
1474 #include <netinet/in.h>
1475 ], [struct group_req gr; int sock; setsockopt(sock, IPPROTO_IP, MCAST_JOIN_GROUP, (void*)&gr, sizeof(gr));
1476 ], [AC_MSG_RESULT([yes])
1477 AC_DEFINE([HAVE_RFC3678], [1], [Have RFC3678 protocol-independed API])],
1478 AC_MSG_RESULT([no]))
1479
1480 dnl ---------------------------------------------------------------
1481 dnl figure out how to check link-state
1482 dnl ---------------------------------------------------------------
1483 AC_CHECK_HEADER([net/if_media.h],
1484   [m4_define([LINK_DETECT_INCLUDES],
1485     FRR_INCLUDES
1486     [#include <net/if_media.h>
1487   ])
1488   AC_CHECK_MEMBERS([struct ifmediareq.ifm_status],
1489     AC_DEFINE([HAVE_BSD_LINK_DETECT], [1], [BSD link-detect]),
1490     [], LINK_DETECT_INCLUDES)],
1491   [],
1492   FRR_INCLUDES)
1493
1494 dnl ---------------------------------------------------------------
1495 dnl Additional, newer way to check link-state using ifi_link_state.
1496 dnl Not available in all BSD's when ifmediareq available
1497 dnl ---------------------------------------------------------------
1498 AC_CHECK_MEMBERS([struct if_data.ifi_link_state],
1499   AC_DEFINE([HAVE_BSD_IFI_LINK_STATE], [1], [BSD ifi_link_state available]),
1500   [], FRR_INCLUDES)
1501
1502 dnl ------------------------
1503 dnl TCP_MD5SIG socket option
1504 dnl ------------------------
1505
1506 AC_CHECK_HEADER([netinet/tcp.h],
1507    [m4_define([MD5_INCLUDES],
1508       FRR_INCLUDES
1509       [#include <netinet/tcp.h>
1510     ])
1511     AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)],
1512    [],
1513    FRR_INCLUDES)
1514 if test "$ac_cv_have_decl_TCP_MD5SIG" = "no"; then
1515   AC_CHECK_HEADER([linux/tcp.h],
1516        [m4_define([MD5_INCLUDES],
1517           FRR_INCLUDES
1518           [#include <linux/tcp.h>
1519         ])
1520        AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)])
1521 fi
1522
1523 AC_CHECK_LIB([crypt], [crypt], [],
1524                     [AC_CHECK_LIB([crypto], [DES_crypt])])
1525 AC_CHECK_LIB([resolv], [res_init])
1526
1527 dnl ---------------------------
1528 dnl check system has PCRE regexp
1529 dnl ---------------------------
1530 if test "$enable_pcreposix" = "yes"; then
1531   AC_CHECK_LIB([pcreposix], [regexec], [], [
1532     AC_MSG_ERROR([--enable-pcreposix given but unable to find libpcreposix])
1533   ])
1534 fi
1535 AC_SUBST([HAVE_LIBPCREPOSIX])
1536
1537 dnl ##########################################################################
1538 dnl test "$enable_clippy_only" != "yes"
1539 fi
1540 dnl END OF LARGE if block
1541 dnl ##########################################################################
1542
1543 dnl ------------------
1544 dnl check C-Ares library
1545 dnl ------------------
1546 PKG_CHECK_MODULES([CARES], [libcares], [
1547   c_ares_found=true
1548 ],[
1549   c_ares_found=false
1550 ])
1551 AM_CONDITIONAL([CARES], [$c_ares_found])
1552
1553
1554 dnl ----------------------------------------------------------------------------
1555 dnl figure out if domainname is available in the utsname struct (GNU extension).
1556 dnl ----------------------------------------------------------------------------
1557 AC_CHECK_MEMBERS([struct utsname.domainname], [], [], [#include <sys/utsname.h>])
1558
1559 dnl ------------------
1560 dnl IPv6 header checks
1561 dnl ------------------
1562 AC_CHECK_HEADERS([netinet6/in6.h netinet/in6_var.h \
1563         netinet6/in6_var.h netinet6/nd6.h], [], [],
1564         FRR_INCLUDES)
1565
1566 m4_define([FRR_INCLUDES],dnl
1567 FRR_INCLUDES
1568 [#ifdef HAVE_NETINET6_IN6_H
1569 #include <netinet6/in6.h>
1570 #endif
1571 #ifdef HAVE_NETINET_IN6_VAR_H
1572 #include <netinet/in6_var.h>
1573 #endif
1574 #include <netinet/icmp6.h>
1575 #ifdef HAVE_NETINET6_IN6_VAR_H
1576 # include <netinet6/in6_var.h>
1577 #endif
1578 #ifdef HAVE_NETINET6_ND6_H
1579 # include <netinet6/nd6.h>
1580 #endif
1581 ])dnl
1582
1583 dnl --------------------
1584 dnl Daemon disable check
1585 dnl --------------------
1586
1587 AS_IF([test "$enable_bgpd" != "no"], [
1588   AC_DEFINE([HAVE_BGPD], [1], [bgpd])
1589 ])
1590
1591 AS_IF([test "$enable_ripd" != "no"], [
1592   AC_DEFINE([HAVE_RIPD], [1], [ripd])
1593 ])
1594
1595 AS_IF([test "$enable_ripngd" != "no"], [
1596   AC_DEFINE([HAVE_RIPNGD], [1], [ripngd])
1597 ])
1598
1599 AS_IF([test "$enable_ospfd" != "no"], [
1600   AC_DEFINE([HAVE_OSPFD], [1], [ospfd])
1601 ])
1602
1603 AS_IF([test "$enable_ospf6d" != "no"], [
1604   AC_DEFINE([HAVE_OSPF6D], [1], [ospf6d])
1605 ])
1606
1607 AS_IF([test "$enable_ldpd" != "no"], [
1608   AC_DEFINE([HAVE_LDPD], [1], [ldpd])
1609 ])
1610
1611 AS_IF([test "$enable_nhrpd" != "no"], [
1612   AC_DEFINE([HAVE_NHRPD], [1], [nhrpd])
1613 ])
1614
1615 AS_IF([test "$enable_eigrpd" != "no"], [
1616   AC_DEFINE([HAVE_EIGRPD], [1], [eigrpd])
1617 ])
1618
1619 AS_IF([test "$enable_babeld" != "no"], [
1620   AC_DEFINE([HAVE_BABELD], [1], [babeld])
1621 ])
1622
1623 AS_IF([test "$enable_isisd" != "no"], [
1624   AC_DEFINE([HAVE_ISISD], [1], [isisd])
1625 ])
1626
1627 AS_IF([test "$enable_pimd" != "no"], [
1628   AC_DEFINE([HAVE_PIMD], [1], [pimd])
1629 ])
1630
1631 AS_IF([test "$enable_pbrd" != "no"], [
1632   AC_DEFINE([HAVE_PBRD], [1], [pbrd])
1633 ])
1634
1635 AS_IF([test "$enable_sharpd" = "yes"], [
1636   AC_DEFINE([HAVE_SHARPD], [1], [sharpd])
1637 ])
1638
1639 AS_IF([test "$enable_staticd" != "no"], [
1640   AC_DEFINE([HAVE_STATICD], [1], [staticd])
1641 ])
1642
1643 AS_IF([test "$enable_fabricd" != "no"], [
1644   AC_DEFINE([HAVE_FABRICD], [1], [fabricd])
1645 ])
1646
1647 AS_IF([test "$enable_vrrpd" != "no"], [
1648   AC_DEFINE([HAVE_VRRPD], [1], [vrrpd])
1649 ])
1650
1651 if test "$enable_bfdd" = "no"; then
1652   AC_DEFINE([HAVE_BFDD], [0], [bfdd])
1653   BFDD=""
1654 else
1655   AC_DEFINE([HAVE_BFDD], [1], [bfdd])
1656   BFDD="bfdd"
1657
1658   case $host_os in
1659     linux*)
1660       AC_DEFINE([BFD_LINUX], [1], [bfdd])
1661       ;;
1662
1663     *)
1664       AC_DEFINE([BFD_BSD], [1], [bfdd])
1665       ;;
1666   esac
1667 fi
1668
1669 if test "$ac_cv_lib_json_c_json_object_get" = "no" -a "$BFDD" = "bfdd"; then
1670   AC_MSG_ERROR(["you must use json-c library to use bfdd"])
1671 fi
1672
1673 NHRPD=""
1674 case "$host_os" in
1675   linux*)
1676     case "${enable_nhrpd}" in
1677       no)
1678         ;;
1679       yes)
1680         if test "$enable_clippy_only" != "yes"; then
1681         if test "$c_ares_found" != "true" ; then
1682           AC_MSG_ERROR([nhrpd requires libcares.  Please install c-ares and its -dev headers.])
1683         fi
1684         fi
1685         NHRPD="nhrpd"
1686         ;;
1687       *)
1688         if test "$c_ares_found" = "true" ; then
1689           NHRPD="nhrpd"
1690         fi
1691         ;;
1692     esac
1693     ;;
1694   *)
1695     if test "$enable_nhrpd" = "yes"; then
1696       AC_MSG_ERROR([nhrpd requires kernel APIs that are only present on Linux.])
1697     fi
1698     ;;
1699 esac
1700
1701 if test "$enable_watchfrr" = "no";then
1702   WATCHFRR=""
1703 else
1704   WATCHFRR="watchfrr"
1705 fi
1706
1707 OSPFCLIENT=""
1708 if test "$enable_ospfapi" != "no";then
1709     AC_DEFINE([SUPPORT_OSPF_API], [1], [OSPFAPI])
1710
1711   if test "$enable_ospfclient" != "no";then
1712       OSPFCLIENT="ospfclient"
1713   fi
1714 fi
1715
1716 if test "$enable_bgp_announce" = "no";then
1717   AC_DEFINE([DISABLE_BGP_ANNOUNCE], [1], [Disable BGP installation to zebra])
1718 else
1719   AC_DEFINE([DISABLE_BGP_ANNOUNCE], [0], [Disable BGP installation to zebra])
1720 fi
1721
1722 if test "$enable_bgp_vnc" != "no";then
1723   AC_DEFINE([ENABLE_BGP_VNC], [1], [Enable BGP VNC support])
1724 fi
1725
1726 bgpd_bmp=false
1727 case "${enable_bmp}" in
1728   no)
1729     ;;
1730   yes)
1731     if test "$c_ares_found" != "true" ; then
1732       AC_MSG_ERROR([BMP support requires libcares.  Please install c-ares and its -dev headers.])
1733     fi
1734     bgpd_bmp=true
1735     ;;
1736   *)
1737     if test "$c_ares_found" = "true" ; then
1738       bgpd_bmp=true
1739     fi
1740     ;;
1741 esac
1742
1743 if test "$enable_version_build_config" != "no";then
1744   AC_DEFINE([ENABLE_VERSION_BUILD_CONFIG], [1], [Report build configs in show version])
1745 fi
1746
1747 dnl ##########################################################################
1748 dnl LARGE if block
1749 if test "$enable_clippy_only" != "yes"; then
1750 dnl ##########################################################################
1751
1752 dnl ------------------
1753 dnl check Net-SNMP library
1754 dnl ------------------
1755 if test "$enable_snmp" != "" -a "$enable_snmp" != "no"; then
1756    AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], [no])
1757    if test "$NETSNMP_CONFIG" = "no"; then
1758       AC_MSG_ERROR([--enable-snmp given but unable to find net-snmp-config])
1759    fi
1760    SNMP_LIBS="`${NETSNMP_CONFIG} --agent-libs`"
1761    SNMP_CFLAGS="`${NETSNMP_CONFIG} --base-cflags`"
1762    # net-snmp lists all of its own dependencies.  we absolutely do not want that
1763    # among other things we avoid a GPL vs. OpenSSL license conflict here
1764    for removelib in crypto ssl sensors pci wrap; do
1765      SNMP_LIBS="`echo $SNMP_LIBS | sed -e 's/\(^\|\s\)-l'$removelib'\b/ /g' -e 's/\(^\|\s\)\([^\s]*\/\)\?lib'$removelib'\.[^\s]\+\b/ /g'`"
1766    done
1767    AC_MSG_CHECKING([whether we can link to Net-SNMP])
1768    AC_LINK_IFELSE_FLAGS([$SNMP_CFLAGS], [$SNMP_LIBS], [AC_LANG_PROGRAM([
1769 int main(void);
1770 ],
1771 [
1772 {
1773   return 0;
1774 }
1775 ])], [
1776      AC_MSG_RESULT([no])
1777      AC_MSG_ERROR([--enable-snmp given but not usable])])
1778    case "${enable_snmp}" in
1779      yes)
1780       SNMP_METHOD=agentx
1781       ;;
1782      agentx)
1783       SNMP_METHOD="${enable_snmp}"
1784       ;;
1785      *)
1786       AC_MSG_ERROR([--enable-snmp given with an unknown method (${enable_snmp}). Use yes or agentx])
1787       ;;
1788    esac
1789    AH_TEMPLATE([SNMP_AGENTX], [Use SNMP AgentX to interface with snmpd])
1790    AC_DEFINE_UNQUOTED(AS_TR_CPP(SNMP_${SNMP_METHOD}),,[SNMP method to interface with snmpd])
1791 fi
1792 AC_SUBST([SNMP_LIBS])
1793 AC_SUBST([SNMP_CFLAGS])
1794
1795 dnl ---------------
1796 dnl libyang
1797 dnl ---------------
1798 PKG_CHECK_MODULES([LIBYANG], [libyang >= 1.0.184], , [
1799   AC_MSG_ERROR([libyang (>= 1.0.184) was not found on your system.])
1800 ])
1801 ac_cflags_save="$CFLAGS"
1802 CFLAGS="$CFLAGS $LIBYANG_CFLAGS"
1803 AC_CHECK_MEMBER([struct lyd_node.priv], [], [
1804   AC_MSG_ERROR([m4_normalize([
1805     libyang needs to be compiled with ENABLE_LYD_PRIV=ON.
1806     Instructions for this are included in the build documentation for your platform at http://docs.frrouting.org/projects/dev-guide/en/latest/building.html])
1807   ])
1808 ], [[#include <libyang/libyang.h>]])
1809 CFLAGS="$ac_cflags_save"
1810
1811 dnl ---------------
1812 dnl configuration rollbacks
1813 dnl ---------------
1814 SQLITE3=false
1815 if test "$enable_config_rollbacks" = "yes"; then
1816   PKG_CHECK_MODULES([SQLITE3], [sqlite3], [
1817     AC_DEFINE([HAVE_CONFIG_ROLLBACKS], [1], [Enable configuration rollbacks])
1818     AC_DEFINE([HAVE_SQLITE3], [1], [Enable sqlite3 database])
1819     SQLITE3=true
1820   ], [
1821     AC_MSG_ERROR([--enable-config-rollbacks given but sqlite3 was not found on your system.])
1822   ])
1823 fi
1824
1825 dnl ---------------
1826 dnl confd
1827 dnl ---------------
1828 if test "$enable_confd" != "" -a "$enable_confd" != "no"; then
1829    AC_CHECK_PROG([CONFD], [confd], [confd], [/bin/false], "${enable_confd}/bin")
1830    if test "$CONFD" = "/bin/false"; then
1831       AC_MSG_ERROR([confd was not found on your system.])]
1832    fi
1833    CONFD_CFLAGS="-I${enable_confd}/include -L${enable_confd}/lib"
1834    AC_SUBST([CONFD_CFLAGS])
1835    CONFD_LIBS="-lconfd"
1836    AC_SUBST([CONFD_LIBS])
1837    AC_DEFINE([HAVE_CONFD], [1], [Enable confd integration])
1838 fi
1839
1840 dnl ---------------
1841 dnl sysrepo
1842 dnl ---------------
1843 if test "$enable_sysrepo" = "yes"; then
1844   PKG_CHECK_MODULES([SYSREPO], [libsysrepo],
1845       [AC_DEFINE([HAVE_SYSREPO], [1], [Enable sysrepo integration])
1846       SYSREPO=true],
1847       [SYSREPO=false
1848       AC_MSG_ERROR([sysrepo was not found on your system.])]
1849   )
1850 fi
1851
1852 dnl ---------------
1853 dnl gRPC
1854 dnl ---------------
1855 if test "$enable_grpc" = "yes"; then
1856   PKG_CHECK_MODULES([GRPC], [grpc grpc++ protobuf], [
1857     AC_CHECK_PROGS([PROTOC], [protoc], [/bin/false])
1858     if test "$PROTOC" = "/bin/false"; then
1859       AC_MSG_FAILURE([grpc requested but protoc not found.])
1860     fi
1861
1862     AC_DEFINE([HAVE_GRPC], [1], [Enable the gRPC northbound plugin])
1863     GRPC=true
1864   ], [
1865     GRPC=false
1866     AC_MSG_ERROR([grpc/grpc++ were not found on your system.])
1867   ])
1868 fi
1869
1870 dnl -----
1871 dnl LTTng
1872 dnl -----
1873 if test "$enable_lttng" = "yes"; then
1874   PKG_CHECK_MODULES([UST], [lttng-ust >= 2.12.0], [
1875     AC_DEFINE([HAVE_LTTNG], [1], [Enable LTTng support])
1876     LTTNG=true
1877   ], [
1878     AC_MSG_ERROR([configuration specifies --enable-lttng but lttng-ust was not found])
1879   ])
1880 fi
1881
1882 dnl ----
1883 dnl USDT
1884 dnl ----
1885 if test "$enable_usdt" = "yes"; then
1886   AC_CHECK_HEADERS([sys/sdt.h], [
1887     AC_DEFINE([HAVE_USDT], [1], [Enable USDT probes])
1888     USDT=true
1889   ], [
1890     AC_MSG_ERROR([configuration specifies --enable-usdt but no USDT kernel headers (sys/sdt.h) found])
1891   ])
1892 fi
1893
1894 dnl ------
1895 dnl ZeroMQ
1896 dnl ------
1897 if test "$enable_zeromq" != "no"; then
1898   PKG_CHECK_MODULES([ZEROMQ], [libzmq >= 4.0.0], [
1899     AC_DEFINE([HAVE_ZEROMQ], [1], [Enable ZeroMQ support])
1900     ZEROMQ=true
1901   ], [
1902     if test "$enable_zeromq" = "yes"; then
1903       AC_MSG_ERROR([configuration specifies --enable-zeromq but libzmq was not found])
1904     fi
1905   ])
1906 fi
1907
1908 dnl ------------------------------------
1909 dnl Enable RPKI and add librtr to libs
1910 dnl ------------------------------------
1911 if test "$enable_rpki" = "yes"; then
1912   PKG_CHECK_MODULES([RTRLIB], [rtrlib >= 0.5.0],
1913       [RPKI=true],
1914       [RPKI=false
1915       AC_MSG_ERROR([rtrlib was not found on your system or is too old.])]
1916   )
1917 fi
1918
1919 dnl ------------------------------------
1920 dnl pimd is not supported on OpenBSD and MacOS
1921 dnl ------------------------------------
1922 if test "$enable_pimd" != "no"; then
1923 AC_MSG_CHECKING([for pimd OS support])
1924 case "$host_os" in
1925   darwin*)
1926     AC_MSG_RESULT([no])
1927     enable_pimd="no"
1928     ;;
1929   openbsd*)
1930     AC_MSG_RESULT([no])
1931     enable_pimd="no"
1932     ;;
1933   *)
1934     AC_MSG_RESULT([yes])
1935     ;;
1936 esac
1937 fi
1938
1939 dnl -------------------------------------
1940 dnl VRRP is only supported on linux
1941 dnl -------------------------------------
1942 if test "$enable_vrrpd" != "no"; then
1943 AC_MSG_CHECKING([for VRRP OS support])
1944 case "$host_os" in
1945   linux*)
1946     AC_MSG_RESULT([yes])
1947     ;;
1948   *)
1949     AC_MSG_RESULT([no])
1950     enable_vrrpd="no"
1951     ;;
1952 esac
1953 fi
1954
1955 dnl ------------------------------------------
1956 dnl Check whether rtrlib was build with ssh support
1957 dnl ------------------------------------------
1958 AC_MSG_CHECKING([whether the RTR Library is compiled with SSH])
1959 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "rtrlib/rtrlib.h"]],
1960                         [[struct tr_ssh_config config;]])],
1961         [AC_MSG_RESULT([yes])
1962         AC_DEFINE([FOUND_SSH], [1], [found_ssh])],
1963         AC_MSG_RESULT([no])
1964 )
1965
1966 dnl ---------------
1967 dnl dlopen & dlinfo
1968 dnl ---------------
1969 AC_SEARCH_LIBS([dlopen], [dl dld], [], [
1970   AC_MSG_ERROR([unable to find the dlopen()])
1971 ])
1972
1973 AC_CHECK_HEADERS([link.h])
1974
1975 AC_CACHE_CHECK([for dlinfo(RTLD_DI_ORIGIN)], [frr_cv_rtld_di_origin], [
1976   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1977 #include <stdlib.h>
1978 #ifdef HAVE_LINK_H
1979 #include <link.h>
1980 #endif
1981 #include <dlfcn.h>
1982 ]], [[
1983   char origin[1];
1984   dlinfo (NULL, RTLD_DI_ORIGIN, &origin);
1985 ]])], [
1986     frr_cv_rtld_di_origin=yes
1987   ], [
1988     frr_cv_rtld_di_origin=no
1989   ])
1990 ])
1991 if test "$frr_cv_rtld_di_origin" = "yes"; then
1992   AC_DEFINE([HAVE_DLINFO_ORIGIN], [1], [Have dlinfo RTLD_DI_ORIGIN])
1993 fi
1994
1995 AC_CACHE_CHECK([for dlinfo(RTLD_DI_LINKMAP)], [frr_cv_rtld_di_linkmap], [
1996   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1997 #include <stdlib.h>
1998 #ifdef HAVE_LINK_H
1999 #include <link.h>
2000 #endif
2001 #include <dlfcn.h>
2002 ]], [[
2003   struct link_map *lm = NULL;
2004   dlinfo (NULL, RTLD_DI_LINKMAP, &lm);
2005 ]])], [
2006     frr_cv_rtld_di_linkmap=yes
2007   ], [
2008     frr_cv_rtld_di_linkmap=no
2009   ])
2010 ])
2011 if test "$frr_cv_rtld_di_linkmap" = "yes"; then
2012   AC_DEFINE([HAVE_DLINFO_LINKMAP], [1], [Have dlinfo RTLD_DI_LINKMAP])
2013 fi
2014
2015 dnl ##########################################################################
2016 dnl test "$enable_clippy_only" != "yes"
2017 fi
2018 dnl END OF LARGE if block
2019 dnl ##########################################################################
2020
2021 dnl ---------------------------
2022 dnl sockaddr and netinet checks
2023 dnl ---------------------------
2024 AC_CHECK_TYPES([
2025         struct sockaddr_dl,
2026         struct vifctl, struct mfcctl, struct sioc_sg_req,
2027         vifi_t, struct sioc_vif_req, struct igmpmsg,
2028         struct ifaliasreq, struct if6_aliasreq, struct in6_aliasreq,
2029         struct nd_opt_adv_interval,
2030         struct nd_opt_homeagent_info, struct nd_opt_adv_interval,
2031         struct nd_opt_rdnss, struct nd_opt_dnssl],
2032         [], [], FRR_INCLUDES)
2033
2034 AC_CHECK_MEMBERS([struct sockaddr.sa_len,
2035         struct sockaddr_in.sin_len, struct sockaddr_un.sun_len,
2036         struct sockaddr_dl.sdl_len,
2037         struct if6_aliasreq.ifra_lifetime,
2038         struct nd_opt_adv_interval.nd_opt_ai_type],
2039         [], [], FRR_INCLUDES)
2040
2041 dnl ---------------------------
2042 dnl IRDP/pktinfo/icmphdr checks
2043 dnl ---------------------------
2044
2045 AC_CHECK_TYPES([struct in_pktinfo], [
2046   AC_CHECK_TYPES([struct icmphdr], [
2047     IRDP=true
2048   ], [
2049     IRDP=false
2050   ], [FRR_INCLUDES])
2051 ], [
2052   IRDP=false
2053 ], [FRR_INCLUDES])
2054
2055 case "${enable_irdp}" in
2056 yes)
2057   $IRDP || AC_MSG_ERROR(['IRDP requires in_pktinfo at the moment!'])
2058   ;;
2059 no)
2060   IRDP=false
2061   ;;
2062 esac
2063
2064
2065 dnl -----------------------
2066 dnl checking for IP_PKTINFO
2067 dnl -----------------------
2068 AC_MSG_CHECKING([for IP_PKTINFO])
2069 AC_TRY_COMPILE([#include <netdb.h>], [
2070   int opt = IP_PKTINFO;
2071 ], [
2072   AC_MSG_RESULT([yes])
2073   AC_DEFINE([HAVE_IP_PKTINFO], [1], [Have IP_PKTINFO])
2074 ], [
2075   AC_MSG_RESULT([no])
2076 ])
2077
2078 dnl ---------------------------
2079 dnl checking for IP_RECVDSTADDR
2080 dnl ---------------------------
2081 AC_MSG_CHECKING([for IP_RECVDSTADDR])
2082 AC_TRY_COMPILE([#include <netinet/in.h>], [
2083   int opt = IP_RECVDSTADDR;
2084 ], [
2085   AC_MSG_RESULT([yes])
2086   AC_DEFINE([HAVE_IP_RECVDSTADDR], [1], [Have IP_RECVDSTADDR])
2087 ], [
2088   AC_MSG_RESULT([no])
2089 ])
2090
2091 dnl ----------------------
2092 dnl checking for IP_RECVIF
2093 dnl ----------------------
2094 AC_MSG_CHECKING([for IP_RECVIF])
2095 AC_TRY_COMPILE([#include <netinet/in.h>], [
2096   int opt = IP_RECVIF;
2097 ], [
2098   AC_MSG_RESULT([yes])
2099   AC_DEFINE([HAVE_IP_RECVIF], [1], [Have IP_RECVIF])
2100 ], [
2101   AC_MSG_RESULT([no])
2102 ])
2103
2104 dnl ----------------------
2105 dnl checking for SO_BINDANY
2106 dnl ----------------------
2107 AC_MSG_CHECKING([for SO_BINDANY])
2108 AC_TRY_COMPILE([#include <sys/socket.h>], [
2109   int opt = SO_BINDANY;
2110 ], [
2111   AC_MSG_RESULT([yes])
2112   AC_DEFINE([HAVE_SO_BINDANY], [1], [Have SO_BINDANY])
2113 ], [
2114   AC_MSG_RESULT([no])
2115 ])
2116
2117 dnl ----------------------
2118 dnl checking for IP_FREEBIND
2119 dnl ----------------------
2120 AC_MSG_CHECKING([for IP_FREEBIND])
2121 AC_TRY_COMPILE([#include <netinet/in.h>], [
2122   int opt = IP_FREEBIND;
2123 ], [
2124   AC_MSG_RESULT([yes])
2125   AC_DEFINE([HAVE_IP_FREEBIND], [1], [Have IP_FREEBIND])
2126 ], [
2127   AC_MSG_RESULT([no])
2128 ])
2129
2130 dnl --------------------------------------
2131 dnl checking for be32dec existence or not
2132 dnl --------------------------------------
2133 AC_CHECK_DECLS([be32enc, be32dec], [], [],
2134                [#include <sys/endian.h>])
2135
2136 dnl --------------------------------------
2137 dnl checking for clock_time monotonic struct and call
2138 dnl --------------------------------------
2139 AC_CHECK_DECL([CLOCK_MONOTONIC],
2140         [AC_CHECK_LIB([rt], [clock_gettime], [LIBS="$LIBS -lrt"])
2141          AC_DEFINE([HAVE_CLOCK_MONOTONIC], [1], [Have monotonic clock])
2142 ], [AC_MSG_RESULT([no])], [FRR_INCLUDES])
2143
2144 AC_SEARCH_LIBS([clock_nanosleep], [rt], [
2145   AC_DEFINE([HAVE_CLOCK_NANOSLEEP], [1], [Have clock_nanosleep()])
2146 ])
2147
2148 dnl --------------------------------------
2149 dnl checking for flex and bison
2150 dnl --------------------------------------
2151
2152 AM_PROG_LEX
2153 AC_MSG_CHECKING([version of flex])
2154 frr_ac_flex_version="$(eval $LEX -V | grep flex | head -n 1)"
2155 frr_ac_flex_version="${frr_ac_flex_version##* }"
2156 AC_MSG_RESULT([$frr_ac_flex_version])
2157 AX_COMPARE_VERSION([$frr_ac_flex_version], [lt], [2.5.20], [
2158   LEX="$SHELL $missing_dir/missing flex"
2159   if test -f "${srcdir}/lib/command_lex.c" -a -f "${srcdir}/lib/command_lex.h"; then
2160     AC_MSG_WARN([using pregenerated flex output files])
2161   else
2162     AC_MSG_ERROR([flex failure and pregenerated files not included (probably a git build)])
2163   fi
2164   AC_SUBST([LEX_OUTPUT_ROOT], [lex.yy])
2165   AC_SUBST([LEXLIB], [''])
2166 ])
2167
2168 AC_PROG_YACC
2169 dnl thanks GNU bison for this b*llshit...
2170 AC_MSG_CHECKING([version of bison])
2171 frr_ac_bison_version="$(eval $YACC -V | grep bison | head -n 1)"
2172 frr_ac_bison_version="${frr_ac_bison_version##* }"
2173 frr_ac_bison_missing="false"
2174 case "x${frr_ac_bison_version}x" in
2175   x2.7*)
2176     BISON_OPENBRACE='"'
2177     BISON_CLOSEBRACE='"'
2178     BISON_VERBOSE=''
2179     AC_MSG_RESULT([$frr_ac_bison_version - 2.7 or older])
2180     ;;
2181   x2.*|x1.*)
2182     AC_MSG_RESULT([$frr_ac_bison_version])
2183     AC_MSG_WARN([installed bison is too old.  Please install GNU bison 2.7.x or newer.])
2184     frr_ac_bison_missing="true"
2185     ;;
2186   x)
2187     AC_MSG_RESULT([none])
2188     AC_MSG_WARN([could not determine bison version.  Please install GNU bison 2.7.x or newer.])
2189     frr_ac_bison_missing="true"
2190     ;;
2191   x3.[012][^0-9]*)
2192     BISON_OPENBRACE='{'
2193     BISON_CLOSEBRACE='}'
2194     BISON_VERBOSE='-Dparse.error=verbose'
2195     AC_MSG_RESULT([$frr_ac_bison_version - 3.0 to 3.2])
2196     ;;
2197   *)
2198     BISON_OPENBRACE='{'
2199     BISON_CLOSEBRACE='}'
2200     BISON_VERBOSE='-Dparse.error=verbose -Wno-yacc'
2201     AC_MSG_RESULT([$frr_ac_bison_version - 3.3 or newer])
2202     ;;
2203 esac
2204 AC_SUBST([BISON_OPENBRACE])
2205 AC_SUBST([BISON_CLOSEBRACE])
2206 AC_SUBST([BISON_VERBOSE])
2207
2208 if $frr_ac_bison_missing; then
2209   YACC="$SHELL $missing_dir/missing bison -y"
2210   if test -f "${srcdir}/lib/command_parse.c" -a -f "${srcdir}/lib/command_parse.h"; then
2211     AC_MSG_WARN([using pregenerated bison output files])
2212   else
2213     AC_MSG_ERROR([bison failure and pregenerated files not included (probably a git build)])
2214   fi
2215 fi
2216
2217 dnl -------------------
2218 dnl capabilities checks
2219 dnl -------------------
2220 if test "$enable_capabilities" != "no"; then
2221   AC_MSG_CHECKING([whether prctl PR_SET_KEEPCAPS is available])
2222   AC_TRY_COMPILE([#include <sys/prctl.h>], [prctl(PR_SET_KEEPCAPS, 1, 0, 0, 0);],
2223     [AC_MSG_RESULT([yes])
2224      AC_DEFINE([HAVE_PR_SET_KEEPCAPS], [1], [prctl])
2225      frr_ac_keepcaps="yes"],
2226      AC_MSG_RESULT([no])
2227   )
2228   if test "$frr_ac_keepcaps" = "yes"; then
2229     AC_CHECK_HEADERS([sys/capability.h])
2230   fi
2231   if test "$ac_cv_header_sys_capability_h" = "yes"; then
2232     AC_CHECK_LIB([cap], [cap_init],
2233       [AC_DEFINE([HAVE_LCAPS], [1], [Capabilities])
2234        LIBCAP="-lcap"
2235        frr_ac_lcaps="yes"]
2236     )
2237   fi
2238   if test "$frr_ac_scaps" = "yes" \
2239        -o "$frr_ac_lcaps" = "yes"; then
2240     AC_DEFINE([HAVE_CAPABILITIES], [1], [capabilities])
2241   fi
2242
2243   case "$host_os" in
2244   linux*)
2245     if test "$enable_clippy_only" != "yes"; then
2246     if test "$frr_ac_lcaps" != "yes"; then
2247       AC_MSG_ERROR([libcap and/or its headers were not found.  Running FRR without libcap support built in causes a huge performance penalty.])
2248     fi
2249     fi
2250     ;;
2251   esac
2252 else
2253   case "$host_os" in
2254   linux*)
2255     AC_MSG_WARN([Running FRR without libcap support built in causes a huge performance penalty.])
2256     ;;
2257   esac
2258 fi
2259 AC_SUBST([LIBCAP])
2260
2261 dnl ---------------------------
2262 dnl check for glibc 'backtrace'
2263 dnl ---------------------------
2264 if test "$enable_backtrace" != "no" ; then
2265   backtrace_ok=no
2266   PKG_CHECK_MODULES([UNWIND], [libunwind], [
2267     AC_DEFINE([HAVE_LIBUNWIND], [1], [libunwind])
2268     backtrace_ok=yes
2269   ], [
2270     true
2271   ])
2272
2273   if test "$backtrace_ok" = "no"; then
2274     AC_CHECK_HEADER([unwind.h], [
2275       AC_SEARCH_LIBS([unw_getcontext], [unwind], [
2276         AC_DEFINE([HAVE_LIBUNWIND], [1], [libunwind])
2277         backtrace_ok=yes
2278       ])
2279     ])
2280   fi
2281
2282   if test "$backtrace_ok" = "no"; then
2283     AC_CHECK_HEADER([execinfo.h], [
2284       AC_SEARCH_LIBS([backtrace], [execinfo], [
2285         AC_DEFINE([HAVE_GLIBC_BACKTRACE], [1], [Glibc backtrace])
2286         backtrace_ok=yes
2287       ],, [-lm])
2288     ])
2289   fi
2290
2291   if test "$enable_backtrace" = "yes" -a "$backtrace_ok" = "no"; then
2292     dnl user explicitly requested backtrace but we failed to find support
2293     AC_MSG_FAILURE([failed to find backtrace or libunwind support])
2294   fi
2295 fi
2296
2297 dnl -----------------------------------------
2298 dnl check for malloc mallinfo struct and call
2299 dnl this must try and link using LIBS, in
2300 dnl order to check no alternative allocator
2301 dnl has been specified, which might not provide
2302 dnl mallinfo
2303 dnl -----------------------------------------
2304 AC_CHECK_HEADERS([malloc.h malloc_np.h malloc/malloc.h],,, [FRR_INCLUDES])
2305
2306 AC_CACHE_CHECK([whether mallinfo is available], [frr_cv_mallinfo], [
2307   AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2308 #ifdef HAVE_MALLOC_H
2309 #include <malloc.h>
2310 #endif
2311 #ifdef HAVE_MALLOC_NP_H
2312 #include <malloc_np.h>
2313 #endif
2314 #ifdef HAVE_MALLOC_MALLOC_H
2315 #include <malloc/malloc.h>
2316 #endif
2317 ]], [[
2318 struct mallinfo ac_x; ac_x = mallinfo ();
2319 ]])], [
2320     frr_cv_mallinfo=yes
2321   ], [
2322     frr_cv_mallinfo=no
2323   ])
2324 ])
2325 if test "$frr_cv_mallinfo" = "yes"; then
2326   AC_DEFINE([HAVE_MALLINFO], [1], [mallinfo])
2327 fi
2328
2329 AC_MSG_CHECKING([whether malloc_usable_size is available])
2330 AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2331 #ifdef HAVE_MALLOC_H
2332 #include <malloc.h>
2333 #endif
2334 #ifdef HAVE_MALLOC_MALLOC_H
2335 #include <malloc/malloc.h>
2336 #endif
2337 ]], [[
2338 size_t ac_x; ac_x = malloc_usable_size(NULL);
2339 ]])], [
2340   AC_MSG_RESULT([yes])
2341   AC_DEFINE([HAVE_MALLOC_USABLE_SIZE], [1], [malloc_usable_size])
2342 ], [
2343   AC_MSG_RESULT([no])
2344
2345   AC_MSG_CHECKING([whether malloc_size is available])
2346   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2347 #ifdef HAVE_MALLOC_H
2348 #include <malloc.h>
2349 #endif
2350 #ifdef HAVE_MALLOC_MALLOC_H
2351 #include <malloc/malloc.h>
2352 #endif
2353 ]], [[
2354 size_t ac_x; ac_x = malloc_size(NULL);
2355 ]])], [
2356     AC_MSG_RESULT([yes])
2357     AC_DEFINE([HAVE_MALLOC_SIZE], [1], [malloc_size])
2358   ], [
2359     AC_MSG_RESULT([no])
2360   ])
2361 ])
2362
2363 dnl ----------
2364 dnl configure date
2365 dnl ----------
2366 dev_version=`echo $VERSION | grep dev`
2367 #don't expire deprecated code in non 'dev' branch
2368 if test "$dev_version" = ""; then
2369    CONFDATE=0
2370 else
2371    CONFDATE=`date '+%Y%m%d'`
2372 fi
2373 AC_SUBST([CONFDATE])
2374
2375 dnl ------------------------------
2376 dnl set paths for state directory
2377 dnl ------------------------------
2378 AC_MSG_CHECKING([directory to use for state file])
2379 if test "$prefix" = "NONE"; then
2380   frr_statedir_prefix="";
2381 else
2382   frr_statedir_prefix=${prefix}
2383 fi
2384 if test "$localstatedir" = '${prefix}/var'; then
2385   for FRR_STATE_DIR in ${frr_statedir_prefix}/var/run dnl
2386                         ${frr_statedir_prefix}/var/adm dnl
2387                         ${frr_statedir_prefix}/etc dnl
2388                         /var/run        dnl
2389                         /var/adm        dnl
2390                         /etc            dnl
2391                         /dev/null;
2392   do
2393     test -d $FRR_STATE_DIR && break
2394   done
2395   frr_statedir=$FRR_STATE_DIR
2396 else
2397   frr_statedir=${localstatedir}
2398 fi
2399 if test "$frr_statedir" = "/dev/null"; then
2400     AC_MSG_ERROR([STATE DIRECTORY NOT FOUND! FIX OR SPECIFY --localstatedir!])
2401 fi
2402 AC_MSG_RESULT([${frr_statedir}])
2403 AC_SUBST([frr_statedir])
2404
2405 AC_DEFINE_UNQUOTED([LDPD_SOCKET], ["$frr_statedir%s%s/ldpd.sock"], [ldpd control socket])
2406 AC_DEFINE_UNQUOTED([ZEBRA_SERV_PATH], ["$frr_statedir%s%s/zserv.api"], [zebra api socket])
2407 AC_DEFINE_UNQUOTED([BFDD_CONTROL_SOCKET], ["$frr_statedir%s%s/bfdd.sock"], [bfdd control socket])
2408 AC_DEFINE_UNQUOTED([DAEMON_VTY_DIR], ["$frr_statedir%s%s"], [daemon vty directory])
2409 AC_DEFINE_UNQUOTED([DAEMON_DB_DIR], ["$frr_statedir"], [daemon database directory])
2410
2411 dnl autoconf does this, but it does it too late...
2412 test "$prefix" = "NONE" && prefix=$ac_default_prefix
2413 test "$exec_prefix" = "NONE" && exec_prefix='${prefix}'
2414
2415 dnl get the full path, recursing through variables...
2416 vtysh_bin="$bindir/vtysh"
2417 for I in 1 2 3 4 5 6 7 8 9 10; do
2418         eval vtysh_bin="\"$vtysh_bin\""
2419 done
2420 AC_DEFINE_UNQUOTED([VTYSH_BIN_PATH], ["$vtysh_bin"], [path to vtysh binary])
2421 AC_SUBST([vtysh_bin])
2422
2423 CFG_SYSCONF="$sysconfdir"
2424 CFG_SBIN="$sbindir"
2425 CFG_STATE="$frr_statedir"
2426 CFG_MODULE="$moduledir"
2427 CFG_YANGMODELS="$yangmodelsdir"
2428 for I in 1 2 3 4 5 6 7 8 9 10; do
2429         eval CFG_SYSCONF="\"$CFG_SYSCONF\""
2430         eval CFG_SBIN="\"$CFG_SBIN\""
2431         eval CFG_STATE="\"$CFG_STATE\""
2432         eval CFG_MODULE="\"$CFG_MODULE\""
2433         eval CFG_YANGMODELS="\"$CFG_YANGMODELS\""
2434 done
2435 AC_SUBST([CFG_SYSCONF])
2436 AC_SUBST([CFG_SBIN])
2437 AC_SUBST([CFG_STATE])
2438 AC_SUBST([CFG_MODULE])
2439 AC_SUBST([CFG_YANGMODELS])
2440 AC_DEFINE_UNQUOTED([MODULE_PATH], ["$CFG_MODULE"], [path to modules])
2441 AC_DEFINE_UNQUOTED([YANG_MODELS_PATH], ["$CFG_YANGMODELS"], [path to YANG data models])
2442 AC_DEFINE_UNQUOTED([WATCHFRR_SH_PATH], ["${CFG_SBIN%/}/watchfrr.sh"], [path to watchfrr.sh])
2443
2444 dnl various features
2445 AM_CONDITIONAL([SUPPORT_REALMS], [test "$enable_realms" = "yes"])
2446 AM_CONDITIONAL([ENABLE_BGP_VNC], [test "$enable_bgp_vnc" != "no"])
2447 AM_CONDITIONAL([BGP_BMP], [$bgpd_bmp])
2448 dnl northbound
2449 AM_CONDITIONAL([SQLITE3], [$SQLITE3])
2450 AM_CONDITIONAL([CONFD], [test "$enable_confd" != ""])
2451 AM_CONDITIONAL([SYSREPO], [test "$enable_sysrepo" = "yes"])
2452 AM_CONDITIONAL([GRPC], [test "$enable_grpc" = "yes"])
2453 AM_CONDITIONAL([ZEROMQ], [test "$ZEROMQ" = "true"])
2454 dnl plugins
2455 AM_CONDITIONAL([RPKI], [test "$RPKI" = "true"])
2456 AM_CONDITIONAL([SNMP], [test "$SNMP_METHOD" = "agentx"])
2457 AM_CONDITIONAL([IRDP], [$IRDP])
2458 AM_CONDITIONAL([FPM], [test "$enable_fpm" = "yes"])
2459 AM_CONDITIONAL([HAVE_PROTOBUF], [test "$enable_protobuf" = "yes"])
2460 AM_CONDITIONAL([HAVE_PROTOBUF3], [$PROTO3])
2461 dnl daemons
2462 AM_CONDITIONAL([VTYSH], [test "$VTYSH" = "vtysh"])
2463 AM_CONDITIONAL([ZEBRA], [test "$enable_zebra" != "no"])
2464 AM_CONDITIONAL([BGPD], [test "$enable_bgpd" != "no"])
2465 AM_CONDITIONAL([RIPD], [test "$enable_ripd" != "no"])
2466 AM_CONDITIONAL([OSPFD], [test "$enable_ospfd" != "no"])
2467 AM_CONDITIONAL([LDPD], [test "$enable_ldpd" != "no"])
2468 AM_CONDITIONAL([BFDD], [test "$BFDD" = "bfdd"])
2469 AM_CONDITIONAL([NHRPD], [test "$NHRPD" = "nhrpd"])
2470 AM_CONDITIONAL([EIGRPD], [test "$enable_eigrpd" != "no"])
2471 AM_CONDITIONAL([WATCHFRR], [test "$WATCHFRR" = "watchfrr"])
2472 AM_CONDITIONAL([OSPFCLIENT], [test "$OSPFCLIENT" = "ospfclient"])
2473 AM_CONDITIONAL([RIPNGD], [test "$enable_ripngd" != "no"])
2474 AM_CONDITIONAL([BABELD], [test "$enable_babeld" != "no"])
2475 AM_CONDITIONAL([OSPF6D], [test "$enable_ospf6d" != "no"])
2476 AM_CONDITIONAL([ISISD], [test "$enable_isisd" != "no"])
2477 AM_CONDITIONAL([PIMD], [test "$enable_pimd" != "no"])
2478 AM_CONDITIONAL([PBRD], [test "$enable_pbrd" != "no"])
2479 AM_CONDITIONAL([SHARPD], [test "$enable_sharpd" = "yes"])
2480 AM_CONDITIONAL([STATICD], [test "$enable_staticd" != "no"])
2481 AM_CONDITIONAL([FABRICD], [test "$enable_fabricd" != "no"])
2482 AM_CONDITIONAL([VRRPD], [test "$enable_vrrpd" != "no"])
2483
2484 AC_CONFIG_FILES([Makefile],[
2485         test "$enable_dev_build" = "yes" && makefile_devbuild="--dev-build"
2486         ${PYTHON} "${ac_abs_top_srcdir}/python/makefile.py" ${makefile_devbuild} || exit 1
2487 ], [
2488         PYTHON="$PYTHON"
2489         enable_dev_build="$enable_dev_build"
2490 ])
2491
2492 AC_CONFIG_FILES([
2493           config.version
2494           changelog-auto
2495           redhat/frr.spec
2496           alpine/APKBUILD
2497           snapcraft/snapcraft.yaml
2498           lib/version.h
2499           tests/lib/cli/test_cli.refout
2500           pkgsrc/bgpd.sh pkgsrc/ospf6d.sh pkgsrc/ospfd.sh
2501           pkgsrc/ripd.sh pkgsrc/ripngd.sh pkgsrc/zebra.sh
2502           pkgsrc/eigrpd.sh])
2503
2504 AC_CONFIG_FILES([vtysh/extract.pl], [chmod +x vtysh/extract.pl])
2505 AC_CONFIG_FILES([tools/frr], [chmod +x tools/frr])
2506 AC_CONFIG_FILES([tools/watchfrr.sh], [chmod +x tools/watchfrr.sh])
2507 AC_CONFIG_FILES([tools/frrinit.sh], [chmod +x tools/frrinit.sh])
2508 AC_CONFIG_FILES([tools/frrcommon.sh])
2509
2510 AS_IF([test "$with_pkg_git_version" = "yes"], [
2511     AC_CONFIG_COMMANDS([lib/gitversion.h], [
2512         dst="${ac_abs_top_builddir}/lib/gitversion.h"
2513         ${PERL} "${ac_abs_top_srcdir}/lib/gitversion.pl" \
2514                 "${ac_abs_top_srcdir}" \
2515                 > "${dst}.tmp"
2516         test -f "$dst" \
2517                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
2518                 && rm "${dst}.tmp" \
2519                 || mv "${dst}.tmp" "${dst}"
2520     ], [
2521         PERL="$PERL"
2522     ])
2523 ])
2524
2525 ## Hack, but working solution to avoid rebuilding of frr.info.
2526 ## It's already in CVS until texinfo 4.7 is more common.
2527 AC_OUTPUT
2528
2529 if test "$enable_rpath" = "yes" ; then
2530         true
2531 else
2532         # See https://old-en.opensuse.org/openSUSE:Packaging_Guidelines#Removing_Rpath
2533         sed -i 's|^hardcode_libdir_flag_spec=.*|hardcode_libdir_flag_spec=""|g' libtool
2534         sed -i 's|^runpath_var=LD_RUN_PATH|runpath_var=DIE_RPATH_DIE|g' libtool
2535 fi
2536
2537 echo "
2538 FRRouting configuration
2539 ------------------------------
2540 FRR version             : ${PACKAGE_VERSION}
2541 host operating system   : ${host_os}
2542 source code location    : ${srcdir}
2543 compiler                : ${CC}
2544 compiler flags          : ${CFLAGS} ${SAN_FLAGS}
2545 make                    : ${MAKE-make}
2546 linker flags            : ${LDFLAGS} ${SAN_FLAGS} ${LIBS} ${LIBCAP} ${LIBREADLINE} ${LIBM}
2547 state file directory    : ${frr_statedir}
2548 config file directory   : `eval echo \`echo ${sysconfdir}\``
2549 example directory       : `eval echo \`echo ${exampledir}\``
2550 module directory        : ${CFG_MODULE}
2551 user to run as          : ${enable_user}
2552 group to run as         : ${enable_group}
2553 group for vty sockets   : ${enable_vty_group}
2554 config file mask        : ${enable_configfile_mask}
2555 log file mask           : ${enable_logfile_mask}
2556 zebra protobuf enabled  : ${enable_protobuf:-no}
2557 vici socket path        : ${vici_socket}
2558
2559 The above user and group must have read/write access to the state file
2560 directory and to the config files in the config file directory."
2561
2562 if test "$enable_doc" != "no" -a "$frr_py_mod_sphinx" = "false"; then
2563   AC_MSG_WARN([sphinx is missing but required to build documentation])
2564 fi
2565 if test "$frr_py_mod_pytest" = "false"; then
2566   AC_MSG_WARN([pytest is missing, unit tests cannot be performed])
2567 fi