configure.ac

   1 AC_PREREQ([2.69])
   2
   3 m4_define([lxc_devel], 1)
   4 m4_define([lxc_version_major], 4)
   5 m4_define([lxc_version_minor], 0)
   6 m4_define([lxc_version_micro], 0)
   7 m4_define([lxc_version_beta], [])
   8
   9 m4_define([lxc_abi_major], 1)
  10 m4_define([lxc_abi_minor], 7)
  11 m4_define([lxc_abi_micro], 0)
  12 m4_define([lxc_abi], [lxc_abi_major.lxc_abi_minor.lxc_abi_micro])
  13
  14 m4_define([lxc_version_base], [lxc_version_major.lxc_version_minor.lxc_version_micro])
  15 m4_define([lxc_version],
  16        [ifelse(lxc_devel, 1,
  17         ifelse(lxc_version_beta, [], [lxc_version_base], [lxc_version_base.lxc_version_beta])-devel,
  18         ifelse(lxc_version_beta, [], [lxc_version_base], [lxc_version_base.lxc_version_beta]))])
  19
  20 AC_INIT([lxc],[lxc_version])
  21
  22 # We need pkg-config
  23 PKG_PROG_PKG_CONFIG
  24
  25 AC_SUBST(LXC_VERSION_BASE, lxc_version_base)
  26 AC_SUBST(LXC_VERSION_BETA, lxc_version_beta)
  27
  28 AC_SUBST([LXC_VERSION_MAJOR], [lxc_version_major])
  29 AC_SUBST([LXC_VERSION_MINOR], [lxc_version_minor])
  30 AC_SUBST([LXC_VERSION_MICRO], [lxc_version_micro])
  31 AC_SUBST([LXC_VERSION], [lxc_version])
  32 AC_SUBST([LXC_DEVEL], [lxc_devel])
  33
  34 AC_SUBST([LXC_ABI_MAJOR], [lxc_abi_major])
  35 AC_SUBST([LXC_ABI_MINOR], [lxc_abi_minor])
  36 AC_SUBST([LXC_ABI_MICRO], [lxc_abi_micro])
  37 AC_SUBST([LXC_ABI], [lxc_abi])
  38
  39 AC_CONFIG_SRCDIR([configure.ac])
  40 AC_CONFIG_AUX_DIR([config])
  41 AC_CONFIG_HEADERS([src/config.h])
  42 AM_INIT_AUTOMAKE([-Wall -Werror -Wno-portability subdir-objects])
  43 AC_CANONICAL_HOST
  44 AM_PROG_CC_C_O
  45 AC_USE_SYSTEM_EXTENSIONS
  46 AC_SYS_LARGEFILE
  47
  48 # Test if we have a new enough compiler.
  49 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
  50 #define GCC_VERSION \
  51         (__GNUC__ * 10000 + __GNUC_MINOR__ * 100 + __GNUC_PATCHLEVEL__)
  52
  53 #define CLANG_VERSION \
  54         (__clang_major__ * 10000 + __clang_minor__ * 100 + __clang_patchlevel__)
  55
  56 #if GCC_VERSION < 40700 && CLANG_VERSION < 10000
  57 #error Sorry, your compiler is too old - please upgrade it
  58 #endif
  59         ]])], [valid_compiler=yes], [valid_compiler=no])
  60 if test "x$valid_compiler" = "xno"; then
  61         AC_MSG_ERROR([Sorry, your compiler is too old - please upgrade it])
  62 fi
  63
  64 AC_PROG_GCC_TRADITIONAL
  65 AC_ENABLE_SHARED
  66 AC_ENABLE_STATIC
  67 # Check binaries
  68 AC_PROG_SED
  69 case $CC in clang*)
  70         AC_CHECK_TOOL([AR], llvm-ar)
  71         AC_CHECK_TOOL([NM], llvm-nm)
  72         AC_CHECK_TOOL([OBJCOPY], llvm-objcopy)
  73         AC_CHECK_TOOL([RANLIB], llvm-ranlib)
  74 esac
  75
  76 # libtool
  77 LT_INIT
  78 AC_SUBST([LIBTOOL_DEPS])
  79
  80 # Detect the distribution. This is used for the default configuration and
  81 # for some distro-specific build options.
  82 AC_MSG_CHECKING([host distribution])
  83 AC_ARG_WITH(distro, AS_HELP_STRING([--with-distro=DISTRO], [Specify the Linux distribution to target: One of redhat, redhatenterpriseserver, oracle, centos, fedora, suse, gentoo, debian, arch, slackware, plamo, paldo, openmandriva, pardus, sparclinux, altlinux.]))
  84 if type lsb_release >/dev/null 2>&1 && test "z$with_distro" = "z"; then
  85         with_distro=`lsb_release -is`
  86 fi
  87 if test "z$with_distro" = "z"; then
  88         AC_CHECK_FILE(/etc/redhat-release,with_distro="redhat")
  89         AC_CHECK_FILE(/etc/oracle-release,with_distro="oracle")
  90         AC_CHECK_FILE(/etc/sparclinux-release,with_distro="sparclinux")
  91         AC_CHECK_FILE(/etc/centos-release,with_distro="centos")
  92         AC_CHECK_FILE(/etc/fedora-release,with_distro="fedora")
  93         AC_CHECK_FILE(/etc/SuSE-release,with_distro="suse")
  94         AC_CHECK_FILE(/etc/gentoo-release,with_distro="gentoo")
  95         AC_CHECK_FILE(/etc/debian_version,with_distro="debian")
  96         AC_CHECK_FILE(/etc/arch-release,with_distro="arch")
  97         AC_CHECK_FILE(/etc/slackware-version,with_distro="slackware")
  98         AC_CHECK_FILE(/etc/plamo-version,with_distro="plamo")
  99         AC_CHECK_FILE(/etc/frugalware-release,with_distro="frugalware")
 100         AC_CHECK_FILE(/etc/mandrakelinux-release, with_distro="openmandriva")
 101         AC_CHECK_FILE(/etc/mandriva-release,with_distro="openmandriva")
 102         AC_CHECK_FILE(/etc/pardus-release,with_distro="pardus")
 103         AC_CHECK_FILE(/etc/altlinux-release,with_distro="altlinux")
 104         AC_CHECK_FILE(/etc/pld-release,with_distro="pld")
 105 fi
 106 with_distro=`echo ${with_distro} | tr '[[:upper:]]' '[[:lower:]]'`
 107
 108 if test "z$with_distro" = "zforsparc"; then
 109         with_distro="sparclinux"
 110 fi
 111
 112 if test "z$with_distro" = "z"; then
 113         with_distro="unknown"
 114 fi
 115 case $with_distro in
 116         ubuntu|raspbian)
 117                 distroconf=default.conf.lxcbr
 118                 distrosysconf="$sysconfdir/default"
 119                 ;;
 120         redhat|redhatenterpriseserver|centos|fedora|oracle|oracleserver|sparclinux|altlinux|suse|opensuse*|plamo|pld)
 121                 distroconf=default.conf.lxcbr
 122                 distrosysconf="$sysconfdir/sysconfig"
 123                 ;;
 124         *)
 125                 distroconf=default.conf.unknown
 126                 distrosysconf="$sysconfdir/default"
 127                 ;;
 128 esac
 129 AC_MSG_RESULT([$with_distro])
 130 AM_CONDITIONAL([HAVE_DEBIAN], [test x"$with_distro" = "xdebian" -o x"$with_distro" = "xubuntu" -o x"$with_distro" = "xraspbian"])
 131 AM_CONDITIONAL([DISTRO_UBUNTU], [test "x$with_distro" = "xubuntu"])
 132
 133 AC_CONFIG_LINKS([config/etc/default.conf:config/etc/${distroconf}])
 134
 135 # Check for init system type
 136 AC_MSG_CHECKING([for init system type])
 137 AC_ARG_WITH([init-script],
 138             [AS_HELP_STRING([--with-init-script@<:@=TYPE@<:@,TYPE,...@:>@@:>@],
 139                             [Type(s) of init script to install: sysvinit, systemd, upstart,
 140                              distro @<:@default=distro@:>@])],[],[with_init_script=distro])
 141 case "$with_init_script" in
 142         distro)
 143                 case $with_distro in
 144                         fedora|altlinux|opensuse*)
 145                                 init_script=systemd
 146                                 ;;
 147                         redhat|redhatenterpriseserver|oracle|oracleserver|sparclinux|plamo)
 148                                 init_script=sysvinit
 149                                 ;;
 150                         centos)
 151                                 init_script=sysvinit,systemd
 152                                 ;;
 153                         debian|raspbian|ubuntu)
 154                                 init_script=upstart,systemd
 155                                 ;;
 156                         pld)
 157                                 init_script=sysvinit,upstart,systemd
 158                                 ;;
 159                         *)
 160                                 echo -n "Linux distribution init system unknown."
 161                                 init_script=
 162                                 ;;
 163                 esac
 164                 ;;
 165         *)
 166                 init_script=$with_init_script
 167                 ;;
 168 esac
 169
 170 # Check valid init systems were given, run in subshell so we don't mess up IFS
 171 (IFS="," ; for init_sys in $init_script;
 172 do
 173         case "$init_sys" in
 174                 none|sysvinit|systemd|upstart)
 175                         ;;
 176                 *)
 177                         exit 1
 178                         ;;
 179         esac
 180 done) || AC_MSG_ERROR([Unknown init system type in $init_script])
 181
 182 AM_CONDITIONAL([INIT_SCRIPT_SYSV], [echo "$init_script" |grep -q "sysvinit"])
 183 AM_CONDITIONAL([INIT_SCRIPT_SYSTEMD], [echo "$init_script" |grep -q "systemd"])
 184 AM_CONDITIONAL([INIT_SCRIPT_UPSTART], [echo "$init_script" |grep -q "upstart"])
 185 AC_MSG_RESULT($init_script)
 186
 187 # systemd unit dir
 188 AC_ARG_WITH([systemdsystemunitdir],
 189         AS_HELP_STRING([--with-systemdsystemunitdir=DIR], [Directory for systemd service files]),
 190         [with_systemdsystemunitdir=$withval],
 191         [with_systemdsystemunitdir=$($PKG_CONFIG --variable=systemdsystemunitdir systemd)])
 192 if test -z "$with_systemdsystemunitdir"; then
 193   with_systemdsystemunitdir=/lib/systemd/system
 194 fi
 195 if test "x$with_systemdsystemunitdir" != "xno"; then
 196   AC_SUBST([SYSTEMD_UNIT_DIR], [$with_systemdsystemunitdir])
 197 fi
 198
 199 AC_ARG_ENABLE([werror],
 200         [AS_HELP_STRING([--disable-werror], [do not treat warnings as errors])],
 201         [enable_werror=$enableval], [enable_werror=yes])
 202
 203 # Allow disabling rpath
 204 AC_ARG_ENABLE([rpath],
 205         [AS_HELP_STRING([--enable-rpath], [set rpath in executables [default=no]])],
 206         [enable_rpath=$enableval], [enable_rpath=no])
 207 AM_CONDITIONAL([ENABLE_RPATH], [test "x$enable_rpath" = "xyes"])
 208
 209 # Documentation (manpages)
 210 AC_ARG_ENABLE([doc],
 211         [AS_HELP_STRING([--enable-doc], [make man pages [default=auto]])],
 212         [enable_doc=$enableval], [enable_doc=auto])
 213
 214 if test "x$enable_doc" = "xyes" -o "x$enable_doc" = "xauto"; then
 215         db2xman=""
 216         dbparsers="docbook2X2man docbook2x-man db2x_docbook2man docbook2man docbook-to-man"
 217
 218         AC_MSG_CHECKING(for docbook2x-man)
 219         for name in ${dbparsers}; do
 220                 if "$name" --help >/dev/null 2>&1; then
 221                         db2xman="$name"
 222                         break;
 223                 fi
 224         done
 225
 226         if test -n "${db2xman}"; then
 227                 AC_MSG_RESULT([${db2xman}])
 228                 enable_doc="yes"
 229         else
 230                 AC_MSG_RESULT([no])
 231                 if test "x$enable_doc" = "xyes"; then
 232                         AC_MSG_ERROR([docbook2x-man is required, but could not be found])
 233                 fi
 234                 enable_doc="no"
 235         fi
 236
 237         AC_SUBST(db2xman)
 238 fi
 239 AM_CONDITIONAL([ENABLE_DOCBOOK], [test "x$db2xman" != "x"])
 240 AM_CONDITIONAL([USE_DOCBOOK2X], [test "x$db2xman" != "xdocbook2man"])
 241
 242 if test "x$db2xman" = "xdocbook2man"; then
 243         docdtd="\"-//Davenport//DTD DocBook V3.0//EN\""
 244 else
 245         docdtd="\"-//OASIS//DTD DocBook XML\" \"http://www.oasis-open.org/docbook/xml/4.5/docbookx.dtd\""
 246 fi
 247 AC_SUBST(docdtd)
 248
 249 # Documentation (API)
 250 AC_ARG_ENABLE([api-docs],
 251         [AS_HELP_STRING([--enable-api-docs], [make API documentation [default=auto]])],
 252         [enable_api_docs=$enableval], [enable_api_docs=auto])
 253
 254 if test "x$enable_api_docs" = "xyes" -o "x$enable_api_docs" = "xauto"; then
 255         AC_CHECK_PROGS([HAVE_DOXYGEN],[doxygen])
 256         AC_SUBST([HAVE_DOXYGEN])
 257
 258         if test "x$HAVE_DOXYGEN" != "x"; then
 259                 enable_api_docs="yes"
 260         else
 261                 if test "x$enable_api_docs" = "xyes"; then
 262                         AC_MSG_ERROR([doxygen is required, but could not be found])
 263                 fi
 264                 enable_api_docs="no"
 265         fi
 266 fi
 267
 268 AM_CONDITIONAL([ENABLE_API_DOCS], [test "x$HAVE_DOXYGEN" != "x"])
 269
 270 AC_CONFIG_MACRO_DIRS([config])
 271
 272 # Apparmor
 273 AC_ARG_ENABLE([apparmor],
 274         [AS_HELP_STRING([--enable-apparmor], [enable apparmor support [default=auto]])],
 275         [enable_apparmor=$enableval], [enable_apparmor=auto])
 276
 277 if test "$enable_apparmor" = "auto" ; then
 278         AC_CHECK_LIB([apparmor],[aa_change_profile],[enable_apparmor=yes], [enable_apparmor=no])
 279 fi
 280 AM_CONDITIONAL([ENABLE_APPARMOR], [test "x$enable_apparmor" = "xyes"])
 281
 282 # OpenSSL
 283 # libssl-dev
 284 AC_ARG_ENABLE([openssl],
 285         [AS_HELP_STRING([--enable-openssl], [enable OpenSSL support [default=auto]])],
 286         [enable_openssl=$enableval], [enable_openssl=auto])
 287
 288 if test "$enable_openssl" = "auto" ; then
 289         AC_CHECK_LIB([ssl], [OPENSSL_init_ssl], [enable_openssl=yes], [enable_openssl=no])
 290
 291 fi
 292 AM_CONDITIONAL([ENABLE_OPENSSL], [test "x$enable_openssl" = "xyes"])
 293
 294 AC_ARG_ENABLE([static-binaries],
 295         [AS_HELP_STRING([--enable-static-binaries], [build all binaries statically [default=no]])],
 296         [enable_static_binaries=$enableval], [enable_static_binaries=no])
 297 AM_CONDITIONAL([ENABLE_STATIC_BINARIES], [test "x$enable_static_binaries" = "xyes"])
 298
 299 AM_COND_IF([ENABLE_OPENSSL],
 300         [AC_CHECK_HEADER([openssl/engine.h],[],[AC_MSG_ERROR([You must install the OpenSSL development package in order to compile lxc])])
 301         AM_COND_IF([ENABLE_STATIC_BINARIES], [AC_SUBST([OPENSSL_LIBS], '-lssl -lcrypto -ldl')], [AC_SUBST([OPENSSL_LIBS], '-lssl -lcrypto')])])
 302
 303 # SELinux
 304 AC_ARG_ENABLE([selinux],
 305         [AS_HELP_STRING([--enable-selinux], [enable SELinux support [default=auto]])],
 306         [enable_selinux=$enableval], [enable_selinux=auto])
 307
 308 if test "x$enable_selinux" = xauto; then
 309         AC_CHECK_LIB([selinux],[setexeccon_raw],[enable_selinux=yes],[enable_selinux=no])
 310 fi
 311 AM_CONDITIONAL([ENABLE_SELINUX], [test "x$enable_selinux" = "xyes"])
 312 AM_COND_IF([ENABLE_SELINUX],
 313         [AC_CHECK_HEADER([selinux/selinux.h],[],[AC_MSG_ERROR([You must install the SELinux development package in order to compile lxc])])
 314         AC_CHECK_LIB([selinux], [setexeccon_raw],[true],[AC_MSG_ERROR([You must install the SELinux development package in order to compile lxc])])
 315         AC_SUBST([SELINUX_LIBS], [-lselinux])])
 316
 317 # Seccomp syscall filter
 318 AC_ARG_ENABLE([seccomp],
 319         [AS_HELP_STRING([--enable-seccomp], [enable seccomp support [default=auto]])],
 320         [enable_seccomp=$enableval], [enable_seccomp=auto])
 321
 322 if test "x$enable_seccomp" = "xauto" ; then
 323         AC_CHECK_LIB([seccomp],[seccomp_init],[enable_seccomp=yes],[enable_seccomp=no])
 324 fi
 325 AM_CONDITIONAL([ENABLE_SECCOMP], [test "x$enable_seccomp" = "xyes"])
 326
 327 AM_COND_IF([ENABLE_SECCOMP],
 328         [PKG_CHECK_MODULES([SECCOMP],[libseccomp],[],[
 329                 AC_CHECK_HEADER([seccomp.h],[],[AC_MSG_ERROR([You must install the seccomp development package in order to compile lxc])])
 330                 AC_CHECK_LIB([seccomp], [seccomp_init],[],[AC_MSG_ERROR([You must install the seccomp development package in order to compile lxc])])
 331                 AC_SUBST([SECCOMP_LIBS], [-lseccomp])
 332                 ])
 333         # HAVE_SCMP_FILTER_CTX=1 will tell us we have libseccomp api >= 1.0.0
 334         OLD_CFLAGS="$CFLAGS"
 335         CFLAGS="$CFLAGS $SECCOMP_CFLAGS"
 336         AC_CHECK_TYPES([scmp_filter_ctx], [], [], [[#include <seccomp.h>]])
 337         AC_CHECK_DECLS([seccomp_notify_fd], [], [], [[#include <seccomp.h>]])
 338         AC_CHECK_TYPES([struct seccomp_notif_sizes], [], [], [[#include <seccomp.h>]])
 339         AC_CHECK_DECLS([seccomp_syscall_resolve_name_arch], [], [], [[#include <seccomp.h>]])
 340         CFLAGS="$OLD_CFLAGS"
 341         ])
 342
 343 AC_MSG_CHECKING(for static libcap)
 344 # Check for static libcap, make sure the function checked for differs from the
 345 # the one checked below so the cache doesn't give a wrong answer
 346 OLD_CFLAGS="$CFLAGS"
 347 OLD_CPPFLAGS="$CPPFLAGS"
 348 OLD_LDFLAGS="$LDFLAGS"
 349 OLD_LIBS="$LIBS"
 350 CFLAGS=""
 351 CPPFLAGS=""
 352 LDFLAGS="-static"
 353 LIBS="-lcap"
 354 AC_LINK_IFELSE([
 355   AC_LANG_SOURCE(
 356     [[int main() { return 0; }]]
 357   )],[have_static_libcap=yes],[have_static_libcap=no])
 358 AM_CONDITIONAL([HAVE_STATIC_LIBCAP], [test "x$have_static_libcap" = "xyes"])
 359 if test "x$have_static_libcap" = "xyes"; then
 360         AC_DEFINE([HAVE_STATIC_LIBCAP], 1, [Have static libcap])
 361         AC_MSG_RESULT([yes])
 362 else
 363         AC_MSG_RESULT([no])
 364 fi
 365 CPPFLAGS="$OLD_CPPFLAGS"
 366 CFLAGS="$OLD_CFLAGS"
 367 LDFLAGS="$OLD_LDFLAGS"
 368 LIBS="$OLD_LIBS"
 369
 370
 371 # Linux capabilities
 372 AC_ARG_ENABLE([capabilities],
 373         [AS_HELP_STRING([--enable-capabilities], [enable kernel capabilities support [default=auto]])],
 374         [enable_capabilities=$enableval], [enable_capabilities=auto])
 375
 376 if test "x$enable_capabilities" = "xauto"; then
 377         AC_CHECK_LIB([cap],[cap_set_proc],[enable_capabilities=yes],[enable_capabilities=no])
 378 fi
 379 AM_CONDITIONAL([ENABLE_CAP], [test "x$enable_capabilities" = "xyes"])
 380
 381 AM_COND_IF([ENABLE_CAP],
 382         [AC_CHECK_HEADER([sys/capability.h],[],[AC_MSG_ERROR([You must install the libcap development package in order to compile lxc])])
 383         AC_CHECK_LIB(cap,cap_set_proc,[],[AC_MSG_ERROR([You must install the libcap development package in order to compile lxc])])
 384         # Test whether we support getting file capabilities via cap_get_file().
 385         AC_CHECK_LIB(cap,cap_get_file, AC_DEFINE(LIBCAP_SUPPORTS_FILE_CAPABILITIES,1,[Have cap_get_file]),[],[])
 386         AC_SUBST([CAP_LIBS], [-lcap])])
 387
 388 # Configuration examples
 389 AC_ARG_ENABLE([examples],
 390         [AS_HELP_STRING([--enable-examples], [install examples [default=yes]])],
 391         [enable_examples=$enableval], [enable_examples=yes])
 392 AM_CONDITIONAL([ENABLE_EXAMPLES], [test "x$enable_examples" = "xyes"])
 393
 394 # Enable dumping stack traces
 395 AC_ARG_ENABLE([mutex-debugging],
 396         [AS_HELP_STRING([--enable-mutex-debugging], [Makes mutexes to report error and provide stack trace [default=no]])],
 397         [enable_mutex_debugging=$enableval], [enable_mutex_debugging=no])
 398 AM_CONDITIONAL([MUTEX_DEBUGGING], [test "x$enable_mutex_debugging" = "xyes"])
 399
 400 AM_COND_IF([MUTEX_DEBUGGING],
 401         AC_DEFINE_UNQUOTED([MUTEX_DEBUGGING], 1, [Enabling mutex debugging]))
 402
 403 # Not in older autoconf versions
 404 # AS_VAR_COPY(DEST, SOURCE)
 405 # -------------------------
 406 # Set the polymorphic shell variable DEST to the contents of the polymorphic
 407 # shell variable SOURCE.
 408 m4_ifdef([AS_VAR_COPY], [],
 409 [AC_DEFUN([AS_VAR_COPY],
 410     [AS_LITERAL_IF([$1[]$2], [$1=$$2], [eval $1=\$$2])])
 411 ])
 412
 413 dnl PKG_CHECK_VAR was introduced with pkg-config 0.28
 414 m4_ifdef([PKG_CHECK_VAR], [],
 415 [AC_DEFUN([PKG_CHECK_VAR],
 416     [AC_REQUIRE([PKG_PROG_PKG_CONFIG])dnl
 417      AC_ARG_VAR([$1], [value of $3 for $2, overriding pkg-config])dnl
 418      _PKG_CONFIG([$1], [variable="][$3]["], [$2])
 419      AS_VAR_COPY([$1], [pkg_cv_][$1])
 420      AS_VAR_IF([$1], [""], [$5], [$4])dnl
 421     ])# PKG_CHECK_VAR
 422 ])
 423
 424 # Optional bash integration
 425 AC_ARG_ENABLE([bash],
 426         [AS_HELP_STRING([--enable-bash], [build bash integration [default=yes]])],
 427         [enable_bash=$enableval], [enable_bash=yes])
 428 AM_CONDITIONAL([ENABLE_BASH], [test "x$enable_bash" = "xyes"])
 429
 430 AM_COND_IF([ENABLE_BASH],
 431         [AC_MSG_CHECKING([bash completion directory])
 432         PKG_CHECK_VAR(bashcompdir, [bash-completion], [completionsdir], ,
 433                 bashcompdir="${sysconfdir}/bash_completion.d")
 434         AC_MSG_RESULT([$bashcompdir])
 435         AC_SUBST(bashcompdir)
 436         ])
 437
 438 # Build the command line tools
 439 AC_ARG_ENABLE([tools],
 440         [AS_HELP_STRING([--enable-tools], [build the command line tools [default=yes]])],
 441         [enable_tools=$enableval], [enable_tools=yes])
 442 AM_CONDITIONAL([ENABLE_TOOLS], [test "x$enable_tools" = "xyes"])
 443
 444 # Build the liblxc commands
 445 AC_ARG_ENABLE([commands],
 446         [AS_HELP_STRING([--enable-commands], [build the liblxc commands [default=yes]])],
 447         [enable_commands=$enableval], [enable_commands=yes])
 448 AM_CONDITIONAL([ENABLE_COMMANDS], [test "x$enable_commands" = "xyes"])
 449
 450 AC_ARG_ENABLE([static-binaries],
 451         [AS_HELP_STRING([--enable-static-binaries], [build all binaries statically [default=no]])],
 452         [enable_static_binaries=$enableval], [enable_static_binaries=no])
 453 AM_CONDITIONAL([ENABLE_STATIC_BINARIES], [test "x$enable_static_binaries" = "xyes"])
 454
 455 AC_ARG_ENABLE([sanitizers],
 456         [AS_HELP_STRING([--enable-sanitizers], [build with sanitizers enabled [default=no]])],
 457         [enable_sanitizers=$enableval], [enable_sanitizers=no])
 458 AM_CONDITIONAL([ENABLE_SANITIZERS], [test "x$enable_sanitizers" = "xyes"])
 459 if test "x$enable_sanitizers" = "xyes"; then
 460         AC_DEFINE([ENABLE_SANITIZERS], 1, [build with sanitizers enabled])
 461
 462         CC_CHECK_FLAGS_APPEND([AM_CFLAGS],[CFLAGS],[ \
 463                 -fsanitize=address \
 464                 -fsanitize=undefined \
 465                 -fsanitize=memory \
 466                 -fno-omit-frame-pointer])
 467         AC_SUBST(AM_CFLAGS)
 468
 469         AC_MSG_RESULT([yes])
 470 else
 471         AC_MSG_RESULT([no])
 472 fi
 473
 474 # Optional test binaries
 475 AC_ARG_ENABLE([tests],
 476         [AS_HELP_STRING([--enable-tests], [build test/example binaries [default=no]])],
 477         [enable_tests=$enableval], [enable_tests=no])
 478 AM_CONDITIONAL([ENABLE_TESTS], [test "x$enable_tests" = "xyes"])
 479
 480 # Allow overriding the default runtime dir (/run)
 481 AC_ARG_WITH([runtime-path],
 482         [AS_HELP_STRING([--with-runtime-path=dir], [runtime directory (default: /run)])],
 483         [with_runtime_path=$withval], [with_runtime_path=['/run']])
 484
 485 # LXC container path, where the containers are actually stored
 486 # This is overridden by an entry in the file called LXCCONF
 487 # (i.e. /etc/lxc/lxc.conf)
 488 AC_ARG_WITH([config-path],
 489         [AS_HELP_STRING([--with-config-path=dir], [lxc configuration repository path])],
 490         [with_config_path=$withval], [with_config_path=['${localstatedir}/lib/lxc']])
 491
 492 # The path of the global lxc configuration file.
 493 AC_ARG_WITH([global-conf],
 494         [AS_HELP_STRING([--with-global-conf=dir], [global lxc configuration file])],
 495         [with_global_conf=$withval], [with_global_conf=['${sysconfdir}/lxc/lxc.conf']])
 496
 497 # The path of the userns network configuration file
 498 AC_ARG_WITH([usernic-conf],
 499         [AS_HELP_STRING([--with-usernic-conf], [user network interface configuration file])],
 500         [with_usernic_conf=$withval], [with_usernic_conf=['${sysconfdir}/lxc/lxc-usernet']])
 501
 502 # The path of the runtime usernic database
 503 AC_ARG_WITH([usernic-db],
 504         [AS_HELP_STRING([--with-usernic-db], [lxc user nic database])],
 505         [with_usernic_db=$withval], [with_usernic_db=['${with_runtime_path}/lxc/nics']])
 506
 507 # Rootfs path, where the container mount structure is assembled
 508 AC_ARG_WITH([rootfs-path],
 509         [AS_HELP_STRING([--with-rootfs-path=dir], [lxc rootfs mount point])],
 510         [with_rootfs_path=$withval], [with_rootfs_path=['${libdir}/lxc/rootfs']])
 511
 512 # cgroup pattern specification
 513 AC_ARG_WITH([cgroup-pattern],
 514         [AS_HELP_STRING([--with-cgroup-pattern=pattern], [pattern for container cgroups])],
 515         [with_cgroup_pattern=$withval], [with_cgroup_pattern=['']])
 516
 517 # The path for the apparmor_parser's cache for generated apparmor profiles
 518 AC_ARG_WITH([apparmor-cache-dir],
 519         [AS_HELP_STRING([--with-apparmor-cache-dir=dir],[path for apparmor_parser cache])],
 520         [with_apparmor_cache_dir=$withval], [with_apparmor_cache_dir=['${localstatedir}/cache/lxc/apparmor']])
 521
 522 # Container log path.  By default, use $lxcpath.
 523 AC_MSG_CHECKING([Whether to place logfiles in container config path])
 524 AC_ARG_ENABLE([configpath-log],
 525         [AS_HELP_STRING([--enable-configpath-log], [use logfiles in config path [default=no]])],
 526         [enable_configpath_log=$enableval], [enable_configpath_log=no])
 527 AC_MSG_RESULT([$enable_configpath_log])
 528 AM_CONDITIONAL([USE_CONFIGPATH_LOGS], [test "$enable_configpath_log" = "yes"])
 529
 530 if test "$enable_configpath_log" = "yes"; then
 531         default_log_path="${with_config_path}"
 532 else
 533         default_log_path="${localstatedir}/log/lxc"
 534 fi
 535
 536 AC_ARG_WITH([log-path],
 537         [AS_HELP_STRING([--with-log-path=dir],[per container log path])],
 538         [with_log_path=$withval], [with_log_path=['${default_log_path}']])
 539
 540 # Expand some useful variables
 541 AS_AC_EXPAND(PREFIX, "$prefix")
 542 AS_AC_EXPAND(LIBDIR, "$libdir")
 543 AS_AC_EXPAND(BINDIR, "$bindir")
 544 AS_AC_EXPAND(SBINDIR, "$sbindir")
 545 AS_AC_EXPAND(LIBEXECDIR, "$libexecdir")
 546 AS_AC_EXPAND(INCLUDEDIR, "$includedir")
 547 AS_AC_EXPAND(SYSCONFDIR, "$sysconfdir")
 548 AS_AC_EXPAND(LXC_DEFAULT_CONFIG, "$sysconfdir/lxc/default.conf")
 549 AS_AC_EXPAND(DATADIR, "$datadir")
 550 AS_AC_EXPAND(LOCALSTATEDIR, "$localstatedir")
 551 AS_AC_EXPAND(DOCDIR, "$docdir")
 552 AS_AC_EXPAND(LXC_GENERATE_DATE, "$(date --utc --date=@${SOURCE_DATE_EPOCH:-$(date +%s)} '+%Y-%m-%d')")
 553 AS_AC_EXPAND(LXCPATH, "$with_config_path")
 554 AS_AC_EXPAND(LXC_GLOBAL_CONF, "$with_global_conf")
 555 AS_AC_EXPAND(LXC_USERNIC_CONF, "$with_usernic_conf")
 556 AS_AC_EXPAND(LXC_USERNIC_DB, "$with_usernic_db")
 557 AS_AC_EXPAND(LXC_DISTRO_SYSCONF, "$distrosysconf")
 558 AS_AC_EXPAND(LXCROOTFSMOUNT, "$with_rootfs_path")
 559 AS_AC_EXPAND(LXCTEMPLATEDIR, "$datadir/lxc/templates")
 560 AS_AC_EXPAND(LXCTEMPLATECONFIG, "$datadir/lxc/config")
 561 AS_AC_EXPAND(LXCHOOKDIR, "$datadir/lxc/hooks")
 562 AS_AC_EXPAND(LXCBINHOOKDIR, "$libexecdir/lxc/hooks")
 563 AS_AC_EXPAND(LXCINITDIR, "$libexecdir")
 564 AS_AC_EXPAND(LOGPATH, "$with_log_path")
 565 AS_AC_EXPAND(RUNTIME_PATH, "$with_runtime_path")
 566 AS_AC_EXPAND(APPARMOR_CACHE_DIR, "$with_apparmor_cache_dir")
 567 AC_SUBST(DEFAULT_CGROUP_PATTERN, ["$with_cgroup_pattern"])
 568
 569 # We need the install path so criu knows where to reference the hook scripts.
 570 AC_DEFINE_UNQUOTED([DATADIR], "$DATADIR", ["Prefix for shared files."])
 571
 572 # Check for some standard kernel headers
 573 AC_CHECK_HEADERS([linux/unistd.h linux/netlink.h linux/genetlink.h],
 574                                 [],
 575                                 AC_MSG_ERROR([Please install the Linux kernel headers.]),
 576                                 [#include <sys/socket.h>])
 577
 578 # Check for alternate C libraries
 579 AC_MSG_CHECKING(for bionic libc)
 580 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 581         [[#ifndef __ANDROID__
 582 error: Not bionic!
 583 #endif]])],
 584         [is_bionic=yes],
 585         [is_bionic=no])
 586 if test "x$is_bionic" = "xyes"; then
 587         AC_DEFINE([IS_BIONIC], 1, [bionic libc])
 588         AC_MSG_RESULT([yes])
 589 else
 590         AC_MSG_RESULT([no])
 591 fi
 592 AM_CONDITIONAL([IS_BIONIC], [test "x$is_bionic" = "xyes"])
 593
 594 # Configuration examples
 595 AC_ARG_ENABLE([pam],
 596         [AS_HELP_STRING([--enable-pam], [enable pam module [default=no]])],
 597         [enable_pam=$enableval], [enable_pam=no])
 598 AM_CONDITIONAL([ENABLE_PAM], [test "x$enable_pam" = "xyes"])
 599
 600 AM_COND_IF([ENABLE_PAM],
 601         [AC_ARG_WITH(
 602                 [pamdir],
 603                 [AS_HELP_STRING([--with-pamdir=PATH],[Specify the directory where PAM modules are stored,
 604                                                         or "none" if PAM modules are not to be built])],
 605                 [pamdir=$withval],
 606                 [
 607                         if test "${prefix}" = "/usr"; then
 608                                 pamdir="/lib${libdir##*/lib}/security"
 609                         else
 610                                 pamdir="\$(libdir)/security"
 611                         fi
 612                 ]
 613         )])
 614
 615 AM_CONDITIONAL([HAVE_PAM], [test x"$pamdir" != "xnone"])
 616 AM_COND_IF([ENABLE_PAM],
 617         [if test "z$pamdir" != "znone"; then
 618                 AC_ARG_VAR([PAM_CFLAGS], [C compiler flags for pam])
 619                 AC_ARG_VAR([PAM_LIBS], [linker flags for pam])
 620                 AC_CHECK_LIB(
 621                         [pam],
 622                         [pam_authenticate],
 623                         [PAM_LIBS="-lpam"],
 624                         [AC_MSG_ERROR([*** libpam not found.])
 625                         ])
 626
 627                 AC_SUBST(PAM_LIBS)
 628                 AC_SUBST([pamdir])
 629         fi])
 630
 631 # Some systems lack PR_CAPBSET_DROP definition => HAVE_DECL_PR_CAPBSET_DROP
 632 AC_CHECK_DECLS([PR_CAPBSET_DROP], [], [], [#include <sys/prctl.h>])
 633
 634 # Some systems lack PR_{G,S}ET_NO_NEW_PRIVS definition => HAVE_DECL_PR_{G,S}ET_NO_NEW_PRIVS
 635 AC_CHECK_DECLS([PR_SET_NO_NEW_PRIVS], [], [], [#include <sys/prctl.h>])
 636 AC_CHECK_DECLS([PR_GET_NO_NEW_PRIVS], [], [], [#include <sys/prctl.h>])
 637
 638 # Check for some headers
 639 AC_CHECK_HEADERS([pty.h sys/memfd.h sys/personality.h sys/resource.h sys/signalfd.h sys/timerfd.h utmpx.h])
 640
 641 AC_CHECK_HEADER([ifaddrs.h],
 642         AM_CONDITIONAL(HAVE_IFADDRS_H, true)
 643         AC_DEFINE(HAVE_IFADDRS_H, 1, [Have ifaddrs.h]),
 644         AM_CONDITIONAL(HAVE_IFADDRS_H, false))
 645
 646 # lookup major()/minor()/makedev()
 647 AC_HEADER_MAJOR
 648
 649 # Check for some syscalls functions
 650 AC_CHECK_FUNCS([setns pivot_root sethostname unshare rand_r confstr faccessat gettid memfd_create move_mount open_tree execveat clone3 fsopen fspick fsconfig fsmount, openat2, close_range, statvfs])
 651 AC_CHECK_TYPES([__aligned_u64], [], [], [[#include <linux/types.h>]])
 652 AC_CHECK_TYPES([struct open_how], [], [], [[#include <linux/openat2.h>]])
 653 AC_CHECK_TYPES([struct clone_args], [], [], [[#include <linux/sched.h>]])
 654 AC_CHECK_MEMBERS([struct clone_args.set_tid],[],[],[[#include <linux/sched.h>]])
 655 AC_CHECK_MEMBERS([struct clone_args.cgroup],[],[],[[#include <linux/sched.h>]])
 656
 657 # Check for strerror_r() support. Defines:
 658 # - HAVE_STRERROR_R if available
 659 # - HAVE_DECL_STRERROR_R if defined
 660 # - STRERROR_R_CHAR_P if it returns char *
 661 AC_FUNC_STRERROR_R
 662
 663 # Check if "%m" is supported by printf and Co
 664 AC_MSG_CHECKING([%m format])
 665 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 666 #include <stdio.h>
 667 int main(void)
 668 {
 669   char msg[256];
 670   int rc;
 671
 672   rc = snprintf(msg, sizeof(msg), "%m\n");
 673   if ((rc > 1) && (msg[0] != '%'))
 674   {
 675     return 0;
 676   }
 677   else
 678   {
 679     return 1;
 680   }
 681 }]])],[fmt_m=yes],[fmt_m=no],[fmt_m=no])
 682 if test "x$fmt_m" = "xyes"; then
 683         AC_DEFINE([HAVE_M_FORMAT], 1, [Have %m format])
 684         AC_MSG_RESULT([yes])
 685 else
 686         AC_MSG_RESULT([no])
 687 fi
 688
 689 # Check for some functions
 690 AC_CHECK_LIB(pthread, main)
 691 AC_CHECK_LIB(util, openpty)
 692 AC_CHECK_FUNCS([hasmntopt setmntent endmntent utmpxname])
 693 AC_CHECK_FUNCS([getgrgid_r],
 694         AM_CONDITIONAL(HAVE_GETGRGID_R, true)
 695         AC_DEFINE(HAVE_GETGRGID_R,1,[Have getgrgid_r]),
 696         AM_CONDITIONAL(HAVE_GETGRGID_R, false))
 697 AC_CHECK_FUNCS([getline],
 698         AM_CONDITIONAL(HAVE_GETLINE, true)
 699         AC_DEFINE(HAVE_GETLINE,1,[Have getline]),
 700         AM_CONDITIONAL(HAVE_GETLINE, false))
 701 AC_CHECK_FUNCS([getsubopt],
 702         AM_CONDITIONAL(HAVE_GETSUBOPT, true)
 703         AC_DEFINE(HAVE_GETSUBOPT,1,[Have getsubopt]),
 704         AM_CONDITIONAL(HAVE_GETSUBOPT, false))
 705 AC_CHECK_FUNCS([fgetln],
 706         AM_CONDITIONAL(HAVE_FGETLN, true)
 707         AC_DEFINE(HAVE_FGETLN,1,[Have fgetln]),
 708         AM_CONDITIONAL(HAVE_FGETLN, false))
 709 AC_CHECK_FUNCS([keyctl],
 710         AM_CONDITIONAL(HAVE_KEYCTL, true)
 711         AC_DEFINE(HAVE_KEYCTL,1,[Have keyctl]),
 712         AM_CONDITIONAL(HAVE_KEYCTL, false))
 713 AC_CHECK_FUNCS([openpty],
 714         AM_CONDITIONAL(HAVE_OPENPTY, true)
 715         AC_DEFINE(HAVE_OPENPTY,1,[Have openpty]),
 716         AM_CONDITIONAL(HAVE_OPENPTY, false))
 717 AC_CHECK_FUNCS([prlimit],
 718         AM_CONDITIONAL(HAVE_PRLIMIT, true)
 719         AC_DEFINE(HAVE_PRLIMIT,1,[Have prlimit]),
 720         AM_CONDITIONAL(HAVE_PRLIMIT, false))
 721 AC_CHECK_FUNCS([prlimit64],
 722         AM_CONDITIONAL(HAVE_PRLIMIT64, true)
 723         AC_DEFINE(HAVE_PRLIMIT64,1,[Have prlimit64]),
 724         AM_CONDITIONAL(HAVE_PRLIMIT64, false))
 725 AC_CHECK_FUNCS([pthread_setcancelstate],
 726         AM_CONDITIONAL(HAVE_PTHREAD_SETCANCELSTATE, true)
 727         AC_DEFINE(HAVE_PTHREAD_SETCANCELSTATE,1,[Have pthread_setcancelstate]),
 728         AM_CONDITIONAL(HAVE_PTHREAD_SETCANCELSTATE, false))
 729 AC_CHECK_FUNCS([strlcpy],
 730         AM_CONDITIONAL(HAVE_STRLCPY, true)
 731         AC_DEFINE(HAVE_STRLCPY,1,[Have strlcpy]),
 732         AM_CONDITIONAL(HAVE_STRLCPY, false))
 733 AC_CHECK_FUNCS([strlcat],
 734         AM_CONDITIONAL(HAVE_STRLCAT, true)
 735         AC_DEFINE(HAVE_STRLCAT,1,[Have strlcat]),
 736         AM_CONDITIONAL(HAVE_STRLCAT, false))
 737 AC_CHECK_FUNCS([strchrnul],
 738         AM_CONDITIONAL(HAVE_STRCHRNUL, true)
 739         AC_DEFINE(HAVE_STRCHRNUL,1,[Have strchnul]),
 740         AM_CONDITIONAL(HAVE_STRCHRNUL, false))
 741 AC_CHECK_FUNCS([fmemopen],
 742         AM_CONDITIONAL(HAVE_FMEMOPEN, true)
 743         AC_DEFINE(HAVE_FMEMOPEN,1,[Have fmemopen]),
 744         AM_CONDITIONAL(HAVE_FMEMOPEN, false))
 745
 746 # HAVE_STRUCT_RTNL_LINK_STATS64={0,1}
 747 AC_CHECK_TYPES([struct rtnl_link_stats64], [], [], [[#include <linux/if_link.h>]])
 748
 749 # Check for some libraries
 750 AX_PTHREAD
 751 AC_SEARCH_LIBS(clock_gettime, [rt])
 752
 753 # See if we support thread-local storage.
 754 LXC_CHECK_TLS
 755
 756 # Hardening flags
 757 CC_CHECK_FLAGS_APPEND([AM_CFLAGS],[CFLAGS],[ \
 758         -fPIE \
 759         -Wvla \
 760         -std=gnu11 \
 761         -fms-extensions \
 762         -fdiagnostics-color \
 763         -Wimplicit-fallthrough=5 \
 764         -Wcast-align \
 765         -Wstrict-prototypes \
 766         -fno-strict-aliasing \
 767         -fstack-clash-protection \
 768         -fstack-protector-strong \
 769         --param=ssp-buffer-size=4 \
 770         -g \
 771         --mcet -fcf-protection \
 772         -Werror=implicit-function-declaration \
 773         -Wlogical-op \
 774         -Wmissing-include-dirs \
 775         -Wold-style-definition \
 776         -Winit-self \
 777         -Wunused-but-set-variable \
 778         -Wfloat-equal \
 779         -Wsuggest-attribute=noreturn \
 780         -Werror=return-type \
 781         -Werror=incompatible-pointer-types \
 782         -Wformat=2 \
 783         -Wshadow \
 784         -Wendif-labels \
 785         -Werror=overflow \
 786         -fdiagnostics-show-option \
 787         -Werror=shift-count-overflow \
 788         -Werror=shift-overflow=2 \
 789         -Wdate-time \
 790         -Wnested-externs \
 791         -fasynchronous-unwind-tables \
 792         -pipe \
 793         -fexceptions \
 794         -Warray-bounds \
 795         -Wrestrict \
 796         -Wreturn-local-addr \
 797         -flto=thin \
 798         -fsanitize=cfi \
 799         -Wstringop-overflow])
 800 AC_SUBST(AM_CFLAGS)
 801
 802 CC_CHECK_FLAGS_APPEND([AM_LDFLAGS],[LDFLAGS],[ \
 803         -Wl,--as-needed \
 804         -Wl,--no-undefined \
 805         -Wl,--gc-sections \
 806         -Wl,-z,relro \
 807         -Wl,-z,now \
 808         -pie \
 809         -Wl,-fuse-ld=gold])
 810 AC_SUBST(AM_LDFLAGS)
 811
 812 CFLAGS="$CFLAGS -Wvla -std=gnu11 -fms-extensions"
 813 if test "x$enable_werror" = "xyes"; then
 814         CFLAGS="$CFLAGS -Werror"
 815 fi
 816
 817 AC_ARG_ENABLE([thread-safety],
 818         [AS_HELP_STRING([--enable-thread-safety], [enforce thread-safety otherwise fail the build [default=yes]])],
 819         [enable_thread_safety=$enableval], [enable_thread_safety=yes])
 820 AM_CONDITIONAL([ENFORCE_THREAD_SAFETY], [test "x$enable_thread_safety" = "xyes"])
 821 if test "x$enable_thread_safety" = "xyes"; then
 822         AC_DEFINE([ENFORCE_THREAD_SAFETY], 1, [enforce thread-safety otherwise fail the build])
 823         AC_MSG_RESULT([yes])
 824 else
 825         AC_MSG_RESULT([no])
 826 fi
 827
 828 AC_ARG_ENABLE([coverity-build],
 829         [AS_HELP_STRING([--enable-coverity-build], [build for use with Coverity [default=no]])],
 830         [enable_coverity_build=$enableval], [enable_coverity_build=no])
 831 AM_CONDITIONAL([ENABLE_COVERITY_BUILD], [test "x$enable_coverity_build" = "xyes"])
 832 if test "x$enable_coverity_build" = "xyes"; then
 833         AC_DEFINE([ENABLE_COVERITY_BUILD], 1, [build for use with Coverity])
 834         AC_MSG_RESULT([yes])
 835 else
 836         AC_MSG_RESULT([no])
 837 fi
 838
 839 AC_ARG_ENABLE([dlog],
 840         [AS_HELP_STRING([--enable-dlog], [enable dlog support [default=no]])],
 841         [enable_dlog=$enableval], [enable_dlog=no])
 842 AM_CONDITIONAL([ENABLE_DLOG], [test "x$enable_dlog" = "xyes"])
 843
 844 AM_COND_IF([ENABLE_DLOG],
 845         [PKG_CHECK_MODULES([DLOG],[dlog],[],[
 846                 AC_CHECK_HEADER([dlog.h],[],[AC_MSG_ERROR([You must install the dlog development package in order to compile lxc])])
 847                 AC_CHECK_LIB([dlog], [dlog_print],[],[AC_MSG_ERROR([You must install the dlog development package in order to compile lxc])])
 848                 AC_SUBST([DLOG_LIBS], [-ldlog])
 849                 ])
 850         ])
 851
 852 AC_ARG_ENABLE([memfd-rexec],
 853         [AS_HELP_STRING([--enable-memfd-rexec], [enforce liblxc as a memfd to protect against certain symlink attacks [default=yes]])],
 854         [enable_memfd_rexec=$enableval], [enable_memfd_rexec=yes])
 855 AM_CONDITIONAL([ENFORCE_MEMFD_REXEC], [test "x$enable_memfd_rexec" = "xyes"])
 856 if test "x$enable_memfd_rexec" = "xyes"; then
 857         AC_DEFINE([ENFORCE_MEMFD_REXEC], 1, [Rexec liblxc as memfd])
 858         AC_MSG_RESULT([yes])
 859 else
 860         AC_MSG_RESULT([no])
 861 fi
 862
 863 # Files requiring some variable expansion
 864 AC_CONFIG_FILES([
 865         Makefile
 866         lxc.pc
 867         lxc.spec
 868
 869         coccinelle/Makefile
 870
 871         config/Makefile
 872         config/apparmor/Makefile
 873         config/apparmor/abstractions/start-container
 874         config/selinux/Makefile
 875         config/bash/Makefile
 876         config/bash/lxc
 877         config/init/Makefile
 878         config/init/common/Makefile
 879         config/init/common/lxc-containers
 880         config/init/common/lxc-net
 881         config/init/systemd/Makefile
 882         config/init/systemd/lxc.service
 883         config/init/systemd/lxc@.service
 884         config/init/systemd/lxc-net.service
 885         config/init/systemd/lxc-monitord.service
 886         config/init/sysvinit/Makefile
 887         config/init/sysvinit/lxc-containers
 888         config/init/sysvinit/lxc-net
 889         config/init/upstart/lxc.conf
 890         config/init/upstart/lxc-net.conf
 891         config/init/upstart/Makefile
 892         config/etc/Makefile
 893         config/templates/Makefile
 894         config/templates/common.conf
 895         config/templates/common.conf.d/Makefile
 896         config/templates/nesting.conf
 897         config/templates/oci.common.conf
 898         config/templates/userns.conf
 899         config/yum/Makefile
 900         config/sysconfig/Makefile
 901         config/sysconfig/lxc
 902
 903         doc/Makefile
 904         doc/api/Makefile
 905         doc/lxc-attach.sgml
 906         doc/lxc-autostart.sgml
 907         doc/lxc-cgroup.sgml
 908         doc/lxc-checkconfig.sgml
 909         doc/lxc-checkpoint.sgml
 910         doc/lxc-config.sgml
 911         doc/lxc-console.sgml
 912         doc/lxc-copy.sgml
 913         doc/lxc-create.sgml
 914         doc/lxc-destroy.sgml
 915         doc/lxc-device.sgml
 916         doc/lxc-execute.sgml
 917         doc/lxc-freeze.sgml
 918         doc/lxc-info.sgml
 919         doc/lxc-ls.sgml
 920         doc/lxc-monitor.sgml
 921         doc/lxc-snapshot.sgml
 922         doc/lxc-start.sgml
 923         doc/lxc-stop.sgml
 924         doc/lxc-top.sgml
 925         doc/lxc-unfreeze.sgml
 926         doc/lxc-unshare.sgml
 927         doc/lxc-update-config.sgml
 928         doc/lxc-user-nic.sgml
 929         doc/lxc-usernsexec.sgml
 930         doc/lxc-wait.sgml
 931
 932         doc/pam_cgfs.sgml
 933
 934         doc/lxc.conf.sgml
 935         doc/lxc.container.conf.sgml
 936         doc/lxc.system.conf.sgml
 937         doc/lxc-usernet.sgml
 938         doc/lxc.sgml
 939         doc/common_options.sgml
 940         doc/see_also.sgml
 941
 942         doc/rootfs/Makefile
 943
 944         doc/examples/Makefile
 945         doc/examples/lxc-macvlan.conf
 946         doc/examples/lxc-vlan.conf
 947         doc/examples/lxc-no-netns.conf
 948         doc/examples/lxc-empty-netns.conf
 949         doc/examples/lxc-phys.conf
 950         doc/examples/lxc-veth.conf
 951         doc/examples/lxc-complex.conf
 952
 953         doc/ja/Makefile
 954         doc/ja/lxc-attach.sgml
 955         doc/ja/lxc-autostart.sgml
 956         doc/ja/lxc-cgroup.sgml
 957         doc/ja/lxc-checkconfig.sgml
 958         doc/ja/lxc-checkpoint.sgml
 959         doc/ja/lxc-config.sgml
 960         doc/ja/lxc-console.sgml
 961         doc/ja/lxc-copy.sgml
 962         doc/ja/lxc-create.sgml
 963         doc/ja/lxc-destroy.sgml
 964         doc/ja/lxc-device.sgml
 965         doc/ja/lxc-execute.sgml
 966         doc/ja/lxc-freeze.sgml
 967         doc/ja/lxc-info.sgml
 968         doc/ja/lxc-ls.sgml
 969         doc/ja/lxc-monitor.sgml
 970         doc/ja/lxc-snapshot.sgml
 971         doc/ja/lxc-start.sgml
 972         doc/ja/lxc-stop.sgml
 973         doc/ja/lxc-top.sgml
 974         doc/ja/lxc-unfreeze.sgml
 975         doc/ja/lxc-unshare.sgml
 976         doc/ja/lxc-update-config.sgml
 977         doc/ja/lxc-user-nic.sgml
 978         doc/ja/lxc-usernsexec.sgml
 979         doc/ja/lxc-wait.sgml
 980
 981         doc/ja/pam_cgfs.sgml
 982
 983         doc/ja/lxc.conf.sgml
 984         doc/ja/lxc.container.conf.sgml
 985         doc/ja/lxc.system.conf.sgml
 986         doc/ja/lxc-usernet.sgml
 987         doc/ja/lxc.sgml
 988         doc/ja/common_options.sgml
 989         doc/ja/see_also.sgml
 990
 991         doc/ko/Makefile
 992         doc/ko/lxc-attach.sgml
 993         doc/ko/lxc-autostart.sgml
 994         doc/ko/lxc-cgroup.sgml
 995         doc/ko/lxc-checkconfig.sgml
 996         doc/ko/lxc-checkpoint.sgml
 997         doc/ko/lxc-config.sgml
 998         doc/ko/lxc-console.sgml
 999         doc/ko/lxc-copy.sgml
1000         doc/ko/lxc-create.sgml
1001         doc/ko/lxc-destroy.sgml
1002         doc/ko/lxc-device.sgml
1003         doc/ko/lxc-execute.sgml
1004         doc/ko/lxc-freeze.sgml
1005         doc/ko/lxc-info.sgml
1006         doc/ko/lxc-ls.sgml
1007         doc/ko/lxc-monitor.sgml
1008         doc/ko/lxc-snapshot.sgml
1009         doc/ko/lxc-start.sgml
1010         doc/ko/lxc-stop.sgml
1011         doc/ko/lxc-top.sgml
1012         doc/ko/lxc-unfreeze.sgml
1013         doc/ko/lxc-unshare.sgml
1014         doc/ko/lxc-user-nic.sgml
1015         doc/ko/lxc-usernsexec.sgml
1016         doc/ko/lxc-wait.sgml
1017
1018         doc/ko/lxc.conf.sgml
1019         doc/ko/lxc.container.conf.sgml
1020         doc/ko/lxc.system.conf.sgml
1021         doc/ko/lxc-usernet.sgml
1022         doc/ko/lxc.sgml
1023         doc/ko/common_options.sgml
1024         doc/ko/see_also.sgml
1025
1026         hooks/Makefile
1027         hooks/dhclient
1028
1029         templates/Makefile
1030         templates/lxc-busybox
1031         templates/lxc-download
1032         templates/lxc-local
1033         templates/lxc-oci
1034
1035         src/Makefile
1036         src/lxc/Makefile
1037         src/lxc/lxc.functions
1038         src/lxc/cmd/lxc-checkconfig
1039         src/lxc/cmd/lxc-update-config
1040         src/lxc/version.h
1041
1042         src/tests/Makefile
1043         src/tests/lxc-test-usernic
1044 ])
1045 AC_CONFIG_COMMANDS([default],[[]],[[]])
1046 AC_OUTPUT
1047
1048 # Configuration overview
1049 cat << EOF
1050
1051 ----------------------------
1052 Binaries
1053  - Command Line Tools:
1054    - lxc-attach:     $enable_tools
1055    - lxc-autostart:  $enable_tools
1056    - lxc-cgroup:     $enable_tools
1057    - lxc-checkpoint: $enable_tools
1058    - lxc-config:     $enable_tools
1059    - lxc-console:    $enable_tools
1060    - lxc-copy:       $enable_tools
1061    - lxc-create:     $enable_tools
1062    - lxc-destroy:    $enable_tools
1063    - lxc-device:     $enable_tools
1064    - lxc-execute:    $enable_tools
1065    - lxc-freeze:     $enable_tools
1066    - lxc-info:       $enable_tools
1067    - lxc-ls:         $enable_tools
1068    - lxc-monitor:    $enable_tools
1069    - lxc-snapshot:   $enable_tools
1070    - lxc-start:      $enable_tools
1071    - lxc-stop:       $enable_tools
1072    - lxc-top:        $enable_tools
1073    - lxc-unfreeze:   $enable_tools
1074    - lxc-unshare:    $enable_tools
1075    - lxc-wait:       $enable_tools
1076
1077  - liblxc Commands:
1078    - lxc-checkconfig:   $enable_commands
1079    - lxc-update-config: $enable_commands
1080    - lxc-init:          $enable_commands
1081    - lxc-monitord:      $enable_commands
1082    - lxc-user-nic:      $enable_commands
1083    - lxc-usernsexec:    $enable_commands
1084
1085  - static binaries: $enable_static_binaries
1086
1087 Environment:
1088  - compiler: $CC
1089  - cflags: ${AM_CFLAGS} ${PTHREAD_CFLAGS}
1090  - ldflags: ${AM_LDFLAGS} ${PTHREAD_LIBS}
1091  - distribution: $with_distro
1092  - init script type(s): $init_script
1093  - rpath: $enable_rpath
1094  - OpenSSL: $enable_openssl
1095  - Bash integration: $enable_bash
1096
1097 Security features:
1098  - Apparmor: $enable_apparmor
1099  - Linux capabilities: $enable_capabilities
1100  - seccomp: $enable_seccomp
1101  - SELinux: $enable_selinux
1102  - memfd rexec: $enable_memfd_rexec
1103
1104 PAM:
1105  - PAM module: $enable_pam
1106  - cgroup PAM module: $pamdir
1107
1108 Documentation:
1109  - examples: $enable_examples
1110  - API documentation: $enable_api_docs
1111  - user documentation: $enable_doc
1112
1113 Debugging:
1114  - Sanitizers: $enable_sanitizers
1115  - Coverity: $enable_coverity_build
1116  - mutex debugging: $enable_mutex_debugging
1117  - tests: $enable_tests
1118
1119 Paths:
1120  - Logs in configpath: $enable_configpath_log
1121
1122 Thread-safety:
1123  - enforce: $enable_thread_safety
1124
1125 Dlog:
1126  - enable: $enable_dlog
1127 EOF