configure.ac

   1 ##
   2 ## Configure template file for FRRouting.
   3 ## autoconf will generate configure script.
   4 ##
   5 ##  Copyright (c) 1996, 97, 98, 99, 2000 Kunihiro Ishiguro <kunihiro@zebra.org>
   6 ##  Portions Copyright (c) 2003 Paul Jakma <paul@dishone.st>
   7 ##
   8 AC_PREREQ(2.60)
   9
  10 AC_INIT(frr, 5.1-dev, [https://github.com/frrouting/frr/issues])
  11 PACKAGE_URL="https://frrouting.org/"
  12 AC_SUBST(PACKAGE_URL)
  13 PACKAGE_FULLNAME="FRRouting"
  14 AC_SUBST(PACKAGE_FULLNAME)
  15
  16 CONFIG_ARGS="$ac_configure_args"
  17 AC_SUBST(CONFIG_ARGS)
  18
  19 AC_CONFIG_SRCDIR(lib/zebra.h)
  20 AC_CONFIG_MACRO_DIR([m4])
  21
  22 dnl -----------------------------------
  23 dnl Get hostname and other information.
  24 dnl -----------------------------------
  25 AC_CANONICAL_BUILD()
  26 AC_CANONICAL_HOST()
  27
  28 AS_IF([test "$host" != "$build"], [
  29   if test "$srcdir" = "."; then
  30     AC_MSG_ERROR([cross-compilation is only possible with builddir separate from srcdir.  create a separate directory and run as .../path-to-frr/configure.])
  31   fi
  32   test -d hosttools || mkdir hosttools
  33   abssrc="`cd \"${srcdir}\"; pwd`"
  34
  35   AC_MSG_NOTICE([...])
  36   AC_MSG_NOTICE([... cross-compilation: creating hosttools directory and self-configuring for build platform tools])
  37   AC_MSG_NOTICE([... use HOST_CPPFLAGS / HOST_CFLAGS / HOST_LDFLAGS if neccessary])
  38   AC_MSG_NOTICE([...])
  39
  40   ( CPPFLAGS="$HOST_CPPFLAGS"; \
  41     CFLAGS="$HOST_CFLAGS"; \
  42     LDFLAGS="$HOST_LDFLAGS"; \
  43     cd hosttools; "${abssrc}/configure" "--host=$build" "--build=$build" "--enable-clippy-only" "--disable-nhrpd" "--disable-vtysh"; )
  44
  45   AC_MSG_NOTICE([...])
  46   AC_MSG_NOTICE([... cross-compilation: finished self-configuring for build platform tools])
  47   AC_MSG_NOTICE([...])
  48
  49   build_clippy="false"
  50   HOSTTOOLS="hosttools/"
  51 ], [
  52   build_clippy="true"
  53   HOSTTOOLS=""
  54 ])
  55 AC_SUBST(HOSTTOOLS)
  56 AM_CONDITIONAL([BUILD_CLIPPY], [$build_clippy])
  57
  58 # Disable portability warnings -- our automake code (in particular
  59 # common.am) uses some constructs specific to gmake.
  60 AM_INIT_AUTOMAKE([1.12 -Wno-portability])
  61 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
  62 AM_SILENT_RULES([yes])
  63 AC_CONFIG_HEADERS(config.h)
  64
  65 AC_PATH_PROG(PERL, perl)
  66 PKG_PROG_PKG_CONFIG
  67
  68 dnl default is to match previous behavior
  69 exampledir=${sysconfdir}
  70 AC_ARG_ENABLE([exampledir],
  71           AS_HELP_STRING([--enable-exampledir],
  72                          [specify alternate directory for examples]),
  73                          exampledir="$enableval",)
  74 dnl XXX add --exampledir to autoconf standard directory list somehow
  75 AC_SUBST(exampledir)
  76
  77 dnl default is to match previous behavior
  78 pkgsrcrcdir=""
  79 AC_ARG_ENABLE([pkgsrcrcdir],
  80           AS_HELP_STRING([--enable-pkgsrcrcdir],
  81                          [specify directory for rc.d scripts]),
  82                          pkgsrcrcdir="$enableval",)
  83 dnl XXX add --pkgsrcrcdir to autoconf standard directory list somehow
  84 AC_SUBST(pkgsrcrcdir)
  85 AM_CONDITIONAL([PKGSRC], [test "x$pkgsrcrcdir" != "x"])
  86
  87 AC_ARG_WITH([moduledir], [AS_HELP_STRING([--with-moduledir=DIR], [module directory (${libdir}/frr/modules)])], [
  88         moduledir="$withval"
  89 ], [
  90         moduledir="\${libdir}/frr/modules"
  91 ])
  92 AC_SUBST([moduledir], [$moduledir])
  93
  94 AC_ARG_ENABLE(tcmalloc,
  95         AS_HELP_STRING([--enable-tcmalloc], [Turn on tcmalloc]),
  96 [case "${enableval}" in
  97   yes) tcmalloc_enabled=true
  98 LIBS="$LIBS -ltcmalloc_minimal"
  99  ;;
 100   no)  tcmalloc_enabled=false ;;
 101   *) AC_MSG_ERROR(bad value ${enableval} for --enable-tcmalloc) ;;
 102 esac],[tcmalloc_enabled=false])
 103
 104
 105 dnl Thanks autoconf, but we don't want a default -g -O2.  We have our own
 106 dnl flag determination logic.
 107 CFLAGS="${CFLAGS:-}"
 108
 109 dnl --------------------
 110 dnl Check CC and friends
 111 dnl --------------------
 112 dnl note orig_cflags is also used further down
 113 orig_cflags="$CFLAGS"
 114 AC_LANG([C])
 115 AC_PROG_CC
 116 AC_PROG_CPP
 117 AM_PROG_CC_C_O
 118 dnl remove autoconf default "-g -O2"
 119 CFLAGS="$orig_cflags"
 120 AC_PROG_CC_C99
 121 dnl NB: see C11 below
 122
 123 AC_PROG_EGREP
 124 PKG_PROG_PKG_CONFIG
 125
 126 dnl autoconf 2.59 appears not to support AC_PROG_SED
 127 dnl AC_PROG_SED
 128 AC_CHECK_PROG([SED],[sed],[sed],[/bin/false])
 129
 130 dnl try and enable CFLAGS that are useful for FRR
 131 dnl - specifically, options to control warnings
 132
 133 AC_USE_SYSTEM_EXTENSIONS
 134 AC_DEFUN([AC_C_FLAG], [{
 135         AC_LANG_PUSH(C)
 136         ac_c_flag_save="$CFLAGS"
 137         CFLAGS="$CFLAGS $1"
 138         AC_MSG_CHECKING([[whether $CC supports $1]])
 139         AC_COMPILE_IFELSE(
 140                 [AC_LANG_PROGRAM([[]])],
 141                 [
 142                         AC_MSG_RESULT([yes])
 143                         m4_if([$3], [], [], [
 144                                 CFLAGS="$ac_c_flag_save"
 145                                 $3
 146                         ])
 147                 ], [
 148                         CFLAGS="$ac_c_flag_save"
 149                         AC_MSG_RESULT([no])
 150                         $2
 151                 ])
 152         AC_LANG_POP(C)
 153         }])
 154
 155 AC_DEFUN([AC_LINK_IFELSE_FLAGS], [{
 156         AC_LANG_PUSH(C)
 157         ac_cflags_save="$CFLAGS"
 158         ac_libs_save="$LIBS"
 159         CFLAGS="$CFLAGS $1"
 160         LIBS="$LIBS $2"
 161         AC_LINK_IFELSE(
 162                 [$3],
 163                 [
 164                         AC_MSG_RESULT([yes])
 165                         CFLAGS="$ac_cflags_save"
 166                         LIBS="$ac_libs_save"
 167                         $5
 168                 ], [
 169                         AC_MSG_RESULT([no])
 170                         CFLAGS="$ac_cflags_save"
 171                         LIBS="$ac_libs_save"
 172                         $4
 173                 ])
 174         AC_LANG_POP(C)
 175         }])
 176
 177 dnl ICC won't bail on unknown options without -diag-error 10006
 178 dnl need to do this first so we get useful results for the other options
 179 AC_C_FLAG([-diag-error 10006])
 180
 181 dnl AC_PROG_CC_C99 may change CC to include -std=gnu99 or something
 182 ac_cc="$CC"
 183 CC="${CC% -std=gnu99}"
 184 CC="${CC% -std=c99}"
 185
 186 AC_C_FLAG([-std=gnu11], [CC="$ac_cc"], [CC="$CC -std=gnu11"])
 187
 188 dnl AddressSanitizer support
 189 AC_ARG_ENABLE([address-sanitizer], AS_HELP_STRING([--enable-address-sanitizer], \
 190               [enabled AddressSanitizer support for detecting a wide variety of \
 191                memory allocation and deallocation errors]), \
 192               [AC_DEFINE(HAVE_ADDRESS_SANITIZER, 1, [enable AddressSanitizer])
 193               CFLAGS="$CFLAGS -fsanitize=address"
 194               CXXFLAGS="$CXXFLAGS -fsanitize=address"
 195               LIBS="-ldl $LIBS"
 196               AC_TRY_COMPILE([],[const int i=0;],[AC_MSG_NOTICE([Address Sanitizer Enabled])],
 197                                                  [AC_MSG_ERROR([Address Sanitizer not available])])
 198               ])
 199
 200 dnl ThreadSanitizer support
 201 AC_ARG_ENABLE([thread-sanitizer], AS_HELP_STRING([--enable-thread-sanitizer], \
 202               [enabled ThreadSanitizer support for detecting data races]), \
 203               [AC_DEFINE(HAVE_THREAD_SANITIZER, 1, [enable ThreadSanitizer])
 204               CFLAGS="$CFLAGS -fsanitize=thread"
 205               CXXFLAGS="$CXXFLAGS -fsanitize=thread"
 206               LIBS="-ldl $LIBS"
 207               AC_TRY_COMPILE([],[const int i=0;],[AC_MSG_NOTICE([Thread Sanitizer Enabled])],
 208                                                  [AC_MSG_ERROR([Thread Sanitizer not available])])
 209               ])
 210
 211 dnl MemorySanitizer support
 212 AC_ARG_ENABLE([memory-sanitizer], AS_HELP_STRING([--enable-memory-sanitizer], \
 213               [enabled MemorySanitizer support for detecting uninitialized memory reads]), \
 214               [AC_DEFINE(HAVE_THREAD_SANITIZER, 1, [enable MemorySanitizer])
 215               CFLAGS="$CFLAGS -fsanitize=memory -fPIE -pie"
 216               CXXFLAGS="$CXXFLAGS -fsanitize=memory -fPIE -pie"
 217               LIBS="-ldl $LIBS"
 218               AC_TRY_COMPILE([],[const int i=0;],[AC_MSG_NOTICE([Memory Sanitizer Enabled])],
 219                                                  [AC_MSG_ERROR([Memory Sanitizer not available])])
 220               ])
 221
 222 dnl if the user has specified any CFLAGS, override our settings
 223 if test "x${enable_dev_build}" = "xyes"; then
 224    AC_DEFINE(DEV_BUILD,,Build for development)
 225    if test "z$orig_cflags" = "z"; then
 226       AC_C_FLAG([-g3])
 227       AC_C_FLAG([-O0])
 228    fi
 229 else
 230    if test "z$orig_cflags" = "z"; then
 231       AC_C_FLAG([-g])
 232       AC_C_FLAG([-Os], [
 233         AC_C_FLAG([-O2])
 234       ])
 235    fi
 236 fi
 237 AM_CONDITIONAL([DEV_BUILD], [test "x$enable_dev_build" = "xyes"])
 238
 239 dnl always want these CFLAGS
 240 AC_C_FLAG([-fno-omit-frame-pointer])
 241 AC_C_FLAG([-funwind-tables])
 242 AC_C_FLAG([-Wall])
 243 AC_C_FLAG([-Wextra])
 244 AC_C_FLAG([-Wmissing-prototypes])
 245 AC_C_FLAG([-Wmissing-declarations])
 246 AC_C_FLAG([-Wpointer-arith])
 247 AC_C_FLAG([-Wbad-function-cast])
 248 AC_C_FLAG([-Wwrite-strings])
 249 if test x"${enable_gcc_ultra_verbose}" = x"yes" ; then
 250   AC_C_FLAG([-Wcast-qual])
 251   AC_C_FLAG([-Wstrict-prototypes])
 252   AC_C_FLAG([-Wmissing-noreturn])
 253   AC_C_FLAG([-Wmissing-format-attribute])
 254   AC_C_FLAG([-Wunreachable-code])
 255   AC_C_FLAG([-Wpacked])
 256   AC_C_FLAG([-Wpadded])
 257 else
 258   AC_C_FLAG([-Wno-unused-result])
 259 fi
 260 AC_C_FLAG([-Wno-unused-parameter])
 261 AC_C_FLAG([-Wno-missing-field-initializers])
 262
 263 dnl ICC emits a broken warning for const char *x = a ? "b" : "c";
 264 dnl for some reason the string consts get 'promoted' to char *,
 265 dnl triggering a const to non-const conversion warning.
 266 AC_C_FLAG([-diag-disable 3179])
 267
 268 if test x"${enable_werror}" = x"yes" ; then
 269   WERROR="-Werror"
 270 fi
 271 AC_SUBST(WERROR)
 272
 273 dnl need link on this one, not compile
 274 AC_LANG_PUSH(C)
 275 ac_ld_flag_save="$LDFLAGS"
 276 LDFLAGS="$LDFLAGS -rdynamic"
 277 AC_MSG_CHECKING([[whether linker supports -rdynamic]])
 278 AC_LINK_IFELSE(
 279         [AC_LANG_PROGRAM([[]])],
 280         [AC_MSG_RESULT([yes])],
 281         [
 282                 LDFLAGS="$ac_ld_flag_save"
 283                 AC_MSG_RESULT([no])
 284         ])
 285 AC_LANG_POP(C)
 286
 287 dnl ----------
 288 dnl Essentials
 289 dnl ----------
 290
 291 AX_PTHREAD([
 292   CC="$PTHREAD_CC"
 293   CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 294   LIBS="$PTHREAD_LIBS $LIBS"
 295 ], [
 296   AC_MSG_FAILURE([This FRR version needs pthreads])
 297 ])
 298
 299 dnl --------------
 300 dnl Check programs
 301 dnl --------------
 302 AC_PROG_INSTALL
 303 AC_PROG_LN_S
 304 AC_PROG_MAKE_SET
 305 AC_CHECK_TOOL(AR, ar)
 306
 307 dnl -----------------
 308 dnl System extensions
 309 dnl -----------------
 310 AC_GNU_SOURCE
 311
 312 dnl -------
 313 dnl libtool
 314 dnl -------
 315 LT_INIT
 316
 317 dnl ----------------------
 318 dnl Packages configuration
 319 dnl ----------------------
 320 AC_ARG_WITH(pkg-extra-version,
 321         AS_HELP_STRING([--with-pkg-extra-version=VER], [add extra version field, for packagers/distributions]),
 322         [EXTRAVERSION=$withval],)
 323 AC_ARG_WITH(pkg-git-version,
 324         AS_HELP_STRING([--with-pkg-git-version], [add git information to MOTD and build version string]),
 325         [ test "x$withval" != "xno" && with_pkg_git_version="yes" ])
 326 AC_ARG_WITH(vtysh_pager,
 327         AS_HELP_STRING([--with-vtysh-pager=PAGER], [control what pager is compiled in as default]),
 328         VTYSH_PAGER=$withval, VTYSH_PAGER="more")
 329 AC_ARG_ENABLE(vtysh,
 330   AS_HELP_STRING([--disable-vtysh], [do not build integrated vty shell for FRR]))
 331 AC_ARG_ENABLE(doc,
 332   AS_HELP_STRING([--disable-doc], [do not build docs]))
 333 AC_ARG_ENABLE(zebra,
 334   AS_HELP_STRING([--disable-zebra], [do not build zebra daemon]))
 335 AC_ARG_ENABLE(bgpd,
 336   AS_HELP_STRING([--disable-bgpd], [do not build bgpd]))
 337 AC_ARG_ENABLE(ripd,
 338   AS_HELP_STRING([--disable-ripd], [do not build ripd]))
 339 AC_ARG_ENABLE(ripngd,
 340   AS_HELP_STRING([--disable-ripngd], [do not build ripngd]))
 341 AC_ARG_ENABLE(ospfd,
 342   AS_HELP_STRING([--disable-ospfd], [do not build ospfd]))
 343 AC_ARG_ENABLE(ospf6d,
 344   AS_HELP_STRING([--disable-ospf6d], [do not build ospf6d]))
 345 AC_ARG_ENABLE(ldpd,
 346   AS_HELP_STRING([--enable-ldpd], [build ldpd]))
 347 AC_ARG_ENABLE(nhrpd,
 348   AS_HELP_STRING([--disable-nhrpd], [do not build nhrpd]))
 349 AC_ARG_ENABLE(eigrpd,
 350   AS_HELP_STRING([--disable-eigrpd], [do not build eigrpd]))
 351 AC_ARG_ENABLE(babeld,
 352   AS_HELP_STRING([--disable-babeld], [do not build babeld]))
 353 AC_ARG_ENABLE(watchfrr,
 354   AS_HELP_STRING([--disable-watchfrr], [do not build watchfrr]))
 355 AC_ARG_ENABLE(isisd,
 356   AS_HELP_STRING([--disable-isisd], [do not build isisd]))
 357 AC_ARG_ENABLE(pimd,
 358   AS_HELP_STRING([--disable-pimd], [do not build pimd]))
 359 AC_ARG_ENABLE(pbrd,
 360   AS_HELP_STRING([--disable-pbrd], [do not build pbrd]))
 361 AC_ARG_ENABLE(sharpd,
 362   AS_HELP_STRING([--enable-sharpd], [do not build sharpd]))
 363 AC_ARG_ENABLE(bgp-announce,
 364   AS_HELP_STRING([--disable-bgp-announce,], [turn off BGP route announcement]))
 365 AC_ARG_ENABLE(bgp-vnc,
 366   AS_HELP_STRING([--disable-bgp-vnc],[turn off BGP VNC support]))
 367 AC_ARG_WITH(rfp-path,
 368   AS_HELP_STRING([--with-rfp-path[=DIR]],[path to replaced stub RFP used with BGP VNC]))
 369 AC_ARG_ENABLE(snmp,
 370   AS_HELP_STRING([--enable-snmp=ARG], [enable SNMP support (smux or agentx)]))
 371 AC_ARG_ENABLE(zeromq,
 372   AS_HELP_STRING([--enable-zeromq], [enable ZeroMQ handler (libfrrzmq)]))
 373 AC_ARG_WITH(libpam,
 374   AS_HELP_STRING([--with-libpam], [use libpam for PAM support in vtysh]))
 375 AC_ARG_ENABLE(ospfapi,
 376   AS_HELP_STRING([--disable-ospfapi], [do not build OSPFAPI to access the OSPF LSA Database]))
 377 AC_ARG_ENABLE(ospfclient,
 378   AS_HELP_STRING([--disable-ospfclient], [do not build OSPFAPI client for OSPFAPI,
 379                           (this is the default if --disable-ospfapi is set)]))
 380 AC_ARG_ENABLE(multipath,
 381   AS_HELP_STRING([--enable-multipath=ARG], [enable multipath function, ARG must be digit]))
 382 AC_ARG_ENABLE(user,
 383   AS_HELP_STRING([--enable-user=USER], [user to run FRR suite as (default frr)]))
 384 AC_ARG_ENABLE(group,
 385   AS_HELP_STRING([--enable-group=GROUP], [group to run FRR suite as (default frr)]))
 386 AC_ARG_ENABLE(vty_group,
 387   AS_HELP_STRING([--enable-vty-group=ARG], [set vty sockets to have specified group as owner]))
 388 AC_ARG_ENABLE(configfile_mask,
 389   AS_HELP_STRING([--enable-configfile-mask=ARG], [set mask for config files]))
 390 AC_ARG_ENABLE(logfile_mask,
 391   AS_HELP_STRING([--enable-logfile-mask=ARG], [set mask for log files]))
 392 AC_ARG_ENABLE(shell_access,
 393   AS_HELP_STRING([--enable-shell-access], [Allow users to access shell/telnet/ssh]))
 394 AC_ARG_ENABLE(realms,
 395   AS_HELP_STRING([--enable-realms], [enable REALMS support under Linux]))
 396 AC_ARG_ENABLE(rtadv,
 397   AS_HELP_STRING([--disable-rtadv], [disable IPV6 router advertisement feature]))
 398 AC_ARG_ENABLE(irdp,
 399   AS_HELP_STRING([--disable-irdp], [enable IRDP server support in zebra (default if supported)]))
 400 AC_ARG_ENABLE(capabilities,
 401   AS_HELP_STRING([--disable-capabilities], [disable using POSIX capabilities]))
 402 AC_ARG_ENABLE(rusage,
 403   AS_HELP_STRING([--disable-rusage], [disable using getrusage]))
 404 AC_ARG_ENABLE(gcc_ultra_verbose,
 405   AS_HELP_STRING([--enable-gcc-ultra-verbose], [enable ultra verbose GCC warnings]))
 406 AC_ARG_ENABLE(linux24_tcp_md5,
 407   AS_HELP_STRING([--enable-linux24-tcp-md5], [enable support for old, Linux-2.4 RFC2385 patch]))
 408 AC_ARG_ENABLE(backtrace,
 409   AS_HELP_STRING([--disable-backtrace,], [disable crash backtraces (default autodetect)]))
 410 AC_ARG_ENABLE(time-check,
 411   AS_HELP_STRING([--disable-time-check], [disable slow thread warning messages]))
 412 AC_ARG_ENABLE(pcreposix,
 413   AS_HELP_STRING([--enable-pcreposix], [enable using PCRE Posix libs for regex functions]))
 414 AC_ARG_ENABLE(fpm,
 415   AS_HELP_STRING([--enable-fpm], [enable Forwarding Plane Manager support]))
 416 AC_ARG_ENABLE(systemd,
 417   AS_HELP_STRING([--enable-systemd], [enable Systemd support]))
 418 AC_ARG_ENABLE(werror,
 419   AS_HELP_STRING([--enable-werror], [enable -Werror (recommended for developers only)]))
 420 AC_ARG_ENABLE(cumulus,
 421   AS_HELP_STRING([--enable-cumulus], [enable Cumulus Switch Special Extensions]))
 422 AC_ARG_ENABLE(datacenter,
 423   AS_HELP_STRING([--enable-datacenter], [enable Compilation for Data Center Extensions]))
 424 AC_ARG_ENABLE(fuzzing,
 425   AS_HELP_STRING([--enable-fuzzing], [enable ability to fuzz various parts of FRR]))
 426 AC_ARG_ENABLE(rr-semantics,
 427   AS_HELP_STRING([--disable-rr-semantics], [disable the v6 Route Replace semantics]))
 428 AC_ARG_ENABLE([protobuf],
 429   AS_HELP_STRING([--enable-protobuf], [Enable experimental protobuf support]))
 430 AC_ARG_ENABLE([oldvpn_commands],
 431   AS_HELP_STRING([--enable-oldvpn-commands], [Keep old vpn commands]))
 432 AC_ARG_ENABLE(rpki,
 433   AS_HELP_STRING([--enable-rpki], [enable RPKI prefix validation support]))
 434 AC_ARG_ENABLE([clippy-only],
 435   AS_HELP_STRING([--enable-clippy-only], [Only build clippy]))
 436 AC_ARG_ENABLE([numeric_version],
 437   AS_HELP_STRING([--enable-numeric-version], [Only numeric digits allowed in version (for Alpine)]))
 438
 439 AS_IF([test "${enable_clippy_only}" != "yes"], [
 440 AC_CHECK_HEADERS(json-c/json.h)
 441 AC_CHECK_LIB(json-c, json_object_get, LIBS="$LIBS -ljson-c", [], [-lm])
 442 if test $ac_cv_lib_json_c_json_object_get = no; then
 443   AC_CHECK_LIB(json, json_object_get, LIBS="$LIBS -ljson")
 444   if test $ac_cv_lib_json_json_object_get = no; then
 445       AC_MSG_ERROR([lib json is needed to compile])
 446   fi
 447 fi
 448 ])
 449
 450 AC_ARG_ENABLE([dev_build],
 451     AS_HELP_STRING([--enable-dev-build], [build for development]))
 452
 453 if test x"${enable_time_check}" != x"no" ; then
 454   if test x"${enable_time_check}" = x"yes" -o x"${enable_time_check}" = x ; then
 455     AC_DEFINE(CONSUMED_TIME_CHECK,5000000,Consumed Time Check)
 456   else
 457     AC_DEFINE_UNQUOTED(CONSUMED_TIME_CHECK,$enable_time_check,Consumed Time Check)
 458   fi
 459 fi
 460
 461 case "${enable_systemd}" in
 462   "no") ;;
 463   "yes")
 464   AC_CHECK_LIB(systemd, sd_notify, LIBS="$LIBS -lsystemd")
 465   if test $ac_cv_lib_systemd_sd_notify = no; then
 466     AC_MSG_ERROR([enable systemd has been specified but systemd development env not found on your system])
 467   else
 468     AC_DEFINE(HAVE_SYSTEMD,,Compile systemd support in)
 469   fi
 470   ;;
 471   "*") ;;
 472 esac
 473
 474 if test "${enable_rr_semantics}" != "no" ; then
 475   AC_DEFINE(HAVE_V6_RR_SEMANTICS,, Compile in v6 Route Replacement Semantics)
 476 fi
 477
 478 if test "${enable_datacenter}" = "yes" ; then
 479   AC_DEFINE(HAVE_DATACENTER,,Compile extensions for a DataCenter)
 480   DFLT_NAME="datacenter"
 481 else
 482   DFLT_NAME="traditional"
 483 fi
 484
 485 if test "${enable_fuzzing}" = "yes" ; then
 486   AC_DEFINE(HANDLE_ZAPI_FUZZING,,Compile extensions to use with a fuzzer)
 487 fi
 488
 489 if test "${enable_cumulus}" = "yes" ; then
 490   AC_DEFINE(HAVE_CUMULUS,,Compile Special Cumulus Code in)
 491 fi
 492
 493 AC_SUBST(DFLT_NAME)
 494 AC_DEFINE_UNQUOTED(DFLT_NAME,["$DFLT_NAME"], Name of the configuration default set)
 495
 496 if test "${enable_shell_access}" = "yes"; then
 497    AC_DEFINE(HAVE_SHELL_ACCESS,,Allow user to use ssh/telnet/bash)
 498 fi
 499
 500 AM_CONDITIONAL([FPM], [test "x$enable_fpm" = "xyes"])
 501
 502 #
 503 # Python for clippy
 504 #
 505 AS_IF([test "$host" = "$build"], [
 506   PYTHONCONFIG=""
 507
 508   # ordering:
 509   # 1.  try python3, but respect the user's preference on which minor ver
 510   # 2.  try python, which might be py3 or py2 again on the user's preference
 511   # 3.  try python2 (can really only be 2.7 but eh)
 512   # 4.  try 3.5 > 3.4 > 3.3 > 3.2 > 2.7 through pkg-config (no user pref)
 513   #
 514   # (AX_PYTHON_DEVEL has no clue about py3 vs py2)
 515   # (AX_PYTHON does not do what we need)
 516
 517   AC_CHECK_TOOLS([PYTHONCONFIG], [python3-config python-config python2-config])
 518   if test -n "$PYTHONCONFIG"; then
 519     PYTHON_CFLAGS="`\"${PYTHONCONFIG}\" --includes`"
 520     PYTHON_LIBS="`\"${PYTHONCONFIG}\" --libs`"
 521
 522     AC_MSG_CHECKING([whether we found a working Python version])
 523     AC_LINK_IFELSE_FLAGS([$PYTHON_CFLAGS], [$PYTHON_LIBS], [AC_LANG_PROGRAM([
 524 #include <Python.h>
 525 #if PY_VERSION_HEX < 0x02070000
 526 #error python too old
 527 #endif
 528 int main(void);
 529 ],
 530 [
 531 {
 532   Py_Initialize();
 533   return 0;
 534 }
 535 ])], [
 536       PYTHONCONFIG=""
 537       unset PYTHON_LIBS
 538       unset PYTHON_CFLAGS
 539     ])
 540   fi
 541
 542   if test -z "$PYTHONCONFIG"; then
 543     PKG_CHECK_MODULES([PYTHON], python-3.5, [], [
 544       PKG_CHECK_MODULES([PYTHON], python-3.4, [], [
 545         PKG_CHECK_MODULES([PYTHON], python-3.3, [], [
 546           PKG_CHECK_MODULES([PYTHON], python-3.2, [], [
 547             PKG_CHECK_MODULES([PYTHON], python-2.7, [], [
 548               AC_MSG_FAILURE([could not find python-config or pkg-config python, please install Python development files from libpython-dev or similar])
 549               ])])])])])
 550
 551
 552     AC_MSG_CHECKING([whether we found a working Python version])
 553     AC_LINK_IFELSE_FLAGS([$PYTHON_CFLAGS], [$PYTHON_LIBS], [AC_LANG_PROGRAM([
 554 #include <Python.h>
 555 #if PY_VERSION_HEX < 0x02070000
 556 #error python too old
 557 #endif
 558 int main(void);
 559 ],
 560 [
 561 {
 562   Py_Initialize();
 563   return 0;
 564 }
 565 ])], [
 566       AC_MSG_FAILURE([could not find python-config or pkg-config python, please install Python development files from libpython-dev or similar])
 567     ])
 568   fi
 569 ])
 570 AC_SUBST(PYTHON_CFLAGS)
 571 AC_SUBST(PYTHON_LIBS)
 572
 573 #
 574 # Logic for protobuf support.
 575 #
 576 if test "$enable_protobuf" = "yes"; then
 577    have_protobuf=yes
 578
 579    # Check for protoc-c
 580    AC_CHECK_PROG([PROTOC_C], [protoc-c], [protoc-c], [/bin/false])
 581    if test "x$PROTOC_C" = "x/bin/false"; then
 582       have_protobuf=no
 583    else
 584       found_protobuf_c=no
 585       PKG_CHECK_MODULES([PROTOBUF_C], libprotobuf-c >= 0.14,
 586                      [found_protobuf_c=yes],
 587                      [AC_MSG_RESULT([pkg-config did not find libprotobuf-c])])
 588
 589       if test "x$found_protobuf_c" = "xyes"; then
 590          LDFLAGS="$LDFLAGS $PROTOBUF_C_LIBS"
 591          CFLAGS="$CFLAGS $PROTOBUF_C_CFLAGS"
 592       else
 593         AC_CHECK_HEADER([google/protobuf-c/protobuf-c.h], [],
 594                         [have_protobuf=no; AC_MSG_RESULT([Couldn't find google/protobuf-c.h])])
 595       fi
 596    fi
 597 fi
 598
 599 #
 600 # Logic for old vpn commans support.
 601 #
 602 if test "$enable_oldvpn_commands" = "yes"; then
 603    AC_DEFINE(KEEP_OLD_VPN_COMMANDS,, [Define for compiling with old vpn commands])
 604 fi
 605
 606 # Fail if the user explicity enabled protobuf support and we couldn't
 607 # find the compiler or libraries.
 608 if test "x$have_protobuf" = "xno" && test "x$enable_protobuf" = "xyes"; then
 609    AC_MSG_ERROR([Protobuf enabled explicitly but can't find libraries/tools])
 610 fi
 611
 612 if test "x$have_protobuf" = "xyes"; then
 613    AC_DEFINE(HAVE_PROTOBUF,, protobuf)
 614 fi
 615
 616 AM_CONDITIONAL([HAVE_PROTOBUF], [test "x$have_protobuf" = "xyes"])
 617
 618 #
 619 # End of logic for protobuf support.
 620 #
 621
 622 if test "${enable_linux24_tcp_md5}" = "yes"; then
 623   AC_DEFINE(HAVE_TCP_MD5_LINUX24,,Old Linux 2.4 TCP MD5 Signature Patch)
 624 fi
 625
 626 AC_MSG_CHECKING(if zebra should be configurable to send Route Advertisements)
 627 if test "${enable_rtadv}" != "no"; then
 628   AC_MSG_RESULT(yes)
 629   AC_DEFINE(HAVE_RTADV,,Enable IPv6 Routing Advertisement support)
 630 else
 631   AC_MSG_RESULT(no)
 632 fi
 633
 634 if test x"${enable_user}" = x"no"; then
 635   enable_user=""
 636 else
 637   if test x"${enable_user}" = x"yes" || test x"${enable_user}" = x""; then
 638     enable_user="frr"
 639   fi
 640   AC_DEFINE_UNQUOTED(FRR_USER, "${enable_user}", frr User)
 641 fi
 642
 643 if test x"${enable_group}" = x"no"; then
 644   enable_group=""
 645 else
 646   if test x"${enable_group}" = x"yes" || test x"${enable_group}" = x""; then
 647     enable_group="frr"
 648   fi
 649   AC_DEFINE_UNQUOTED(FRR_GROUP, "${enable_group}", frr Group)
 650 fi
 651
 652 if test x"${enable_vty_group}" = x"yes" ; then
 653   AC_MSG_ERROR([--enable-vty-group requires a group as argument, not yes])
 654 elif test x"${enable_vty_group}" != x""; then
 655   if test x"${enable_vty_group}" != x"no"; then
 656     AC_DEFINE_UNQUOTED(VTY_GROUP, "${enable_vty_group}", VTY Sockets Group)
 657   fi
 658 fi
 659 AC_SUBST([enable_user])
 660 AC_SUBST([enable_group])
 661 AC_SUBST([enable_vty_group])
 662
 663 enable_configfile_mask=${enable_configfile_mask:-0600}
 664 AC_DEFINE_UNQUOTED(CONFIGFILE_MASK, ${enable_configfile_mask}, Mask for config files)
 665
 666 enable_logfile_mask=${enable_logfile_mask:-0600}
 667 AC_DEFINE_UNQUOTED(LOGFILE_MASK, ${enable_logfile_mask}, Mask for log files)
 668
 669 MPATH_NUM=1
 670
 671 case "${enable_multipath}" in
 672   0)
 673     MPATH_NUM=64
 674     ;;
 675   [[1-9]|[1-9][0-9]|[1-9][0-9][0-9]])
 676     MPATH_NUM="${enable_multipath}"
 677     ;;
 678   "")
 679     ;;
 680   *)
 681     AC_MSG_FAILURE([Please specify digit to enable multipath ARG])
 682     ;;
 683 esac
 684
 685 AC_DEFINE_UNQUOTED(MULTIPATH_NUM, $MPATH_NUM, Maximum number of paths for a route)
 686
 687 AC_DEFINE_UNQUOTED(VTYSH_PAGER, "$VTYSH_PAGER", [What pager to use])
 688
 689 dnl ------------------------------------
 690 dnl Alpine only accepts numeric versions
 691 dnl ------------------------------------
 692 if test "x${enable_numeric_version}" != "x" ; then
 693   VERSION="`echo ${VERSION} | tr -c -d '[[.0-9]]'`"
 694   PACKAGE_VERSION="`echo ${PACKAGE_VERSION} | tr -c -d '[[.0-9]]'`"
 695 fi
 696
 697 dnl -----------------------------------
 698 dnl Add extra version string to package
 699 dnl name, string and version fields.
 700 dnl -----------------------------------
 701 if test "x${EXTRAVERSION}" != "x" ; then
 702   VERSION="${VERSION}${EXTRAVERSION}"
 703   PACKAGE_VERSION="${PACKAGE_VERSION}${EXTRAVERSION}"
 704   AC_SUBST(PACKAGE_EXTRAVERSION, ["${EXTRAVERSION}"])
 705   PACKAGE_STRING="${PACKAGE_STRING}${EXTRAVERSION}"
 706 fi
 707
 708 if test "x$with_pkg_git_version" = "xyes"; then
 709         if test -d "${srcdir}/.git"; then
 710                 AC_DEFINE(GIT_VERSION, [1], [include git version info])
 711         else    with_pkg_git_version="no"
 712                 AC_MSG_WARN([--with-pkg-git-version given, but this is not a git checkout])
 713         fi
 714 fi
 715 AM_CONDITIONAL([GIT_VERSION], [test "x$with_pkg_git_version" = "xyes"])
 716
 717 dnl ------------------------------------
 718 dnl Check C keywords and standard  types
 719 dnl ------------------------------------
 720 AC_C_CONST
 721 AC_C_INLINE
 722 AC_C_VOLATILE
 723 AC_HEADER_STDC
 724 dnl AC_TYPE_PID_T
 725 AC_TYPE_UID_T
 726 AC_TYPE_MODE_T
 727 AC_TYPE_SIZE_T
 728 AC_STRUCT_TM
 729
 730 dnl -------------------------
 731 dnl Check other header files.
 732 dnl -------------------------
 733 AC_CHECK_HEADERS([stropts.h sys/ksym.h \
 734         linux/version.h asm/types.h \
 735         sys/cdefs.h])
 736
 737 ac_stdatomic_ok=false
 738 AC_DEFINE(FRR_AUTOCONF_ATOMIC, 1, [did autoconf checks for atomic funcs])
 739 AC_CHECK_HEADER([stdatomic.h],[
 740
 741   AC_MSG_CHECKING([whether _Atomic qualifier works])
 742   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 743 #include <stdatomic.h>
 744 int main(int argc, char **argv) {
 745   _Atomic int i = 0;
 746   return i;
 747 }
 748 ]])], [
 749     AC_DEFINE(HAVE_STDATOMIC_H, 1, [found stdatomic.h])
 750     AC_MSG_RESULT([yes])
 751     ac_stdatomic_ok=true
 752   ], [
 753     AC_MSG_RESULT([no])
 754   ])
 755 ])
 756
 757 AS_IF([$ac_stdatomic_ok], [true], [
 758   AC_MSG_CHECKING([for __atomic_* builtins])
 759   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 760 int main(int argc, char **argv) {
 761   volatile int i = 1;
 762   __atomic_store_n (&i, 0, __ATOMIC_RELEASE);
 763   return __atomic_load_n (&i, __ATOMIC_ACQUIRE);
 764 }
 765 ]])], [
 766     AC_DEFINE(HAVE___ATOMIC, 1, [found __atomic builtins])
 767     AC_MSG_RESULT([yes])
 768   ], [
 769     AC_MSG_RESULT([no])
 770
 771     dnl FreeBSD 9 has a broken stdatomic.h where _Atomic doesn't work
 772     AC_MSG_CHECKING([for __sync_* builtins])
 773     AC_LINK_IFELSE([AC_LANG_SOURCE([[
 774 int main(int argc, char **argv) {
 775   volatile int i = 1;
 776   __sync_fetch_and_sub (&i, 1);
 777   return __sync_val_compare_and_swap (&i, 0, 1);
 778 }
 779 ]])], [
 780       AC_DEFINE(HAVE___SYNC, 1, [found __sync builtins])
 781       AC_MSG_RESULT([yes])
 782
 783       AC_MSG_CHECKING([for __sync_swap builtin])
 784       AC_LINK_IFELSE([AC_LANG_SOURCE([[
 785 int main(int argc, char **argv) {
 786   volatile int i = 1;
 787   return __sync_swap (&i, 2);
 788 }
 789 ]])], [
 790         AC_DEFINE(HAVE___SYNC_SWAP, 1, [found __sync_swap builtin])
 791         AC_MSG_RESULT([yes])
 792       ], [
 793         AC_MSG_RESULT([no])
 794       ])
 795
 796     ], [
 797       AC_MSG_RESULT([no])
 798       AC_MSG_FAILURE([stdatomic.h unavailable and $CC has neither __atomic nor __sync builtins])
 799     ])
 800   ])
 801 ])
 802
 803 dnl Utility macro to avoid retyping includes all the time
 804 m4_define([FRR_INCLUDES],
 805 [#ifdef SUNOS_5
 806 #define _XPG4_2
 807 #define __EXTENSIONS__
 808 #endif
 809 #include <stdio.h>
 810 #include <stdlib.h>
 811 #include <stddef.h>
 812 #include <sys/types.h>
 813 /* sys/conf.h depends on param.h on FBSD at least */
 814 #include <sys/param.h>
 815 /* Required for MAXSIG */
 816 #include <signal.h>
 817 #include <sys/socket.h>
 818 #ifdef __APPLE__
 819 # define __APPLE_USE_RFC_3542
 820 #endif
 821 #include <netinet/in.h>
 822 #include <sys/time.h>
 823 #include <time.h>
 824 #include <net/if.h>
 825 ])dnl
 826
 827 dnl Same applies for HAVE_NET_IF_VAR_H, which HAVE_NETINET6_ND6_H and
 828 dnl HAVE_NETINET_IN_VAR_H depend upon. But if_var.h depends on if.h, hence
 829 dnl an additional round for it.
 830
 831 AC_CHECK_HEADERS([net/if_var.h], [], [], FRR_INCLUDES)
 832
 833 m4_define([FRR_INCLUDES],
 834 FRR_INCLUDES
 835 [#if HAVE_NET_IF_VAR_H
 836 # include <net/if_var.h>
 837 #endif
 838 ])dnl
 839
 840 AC_CHECK_HEADERS([netinet/in_var.h \
 841         net/if_dl.h net/netopt.h \
 842         inet/nd.h netinet/ip_icmp.h \
 843         sys/sysctl.h sys/sockio.h kvm.h sys/conf.h],
 844         [], [], FRR_INCLUDES)
 845
 846 AC_CHECK_HEADERS([ucontext.h], [], [],
 847 [#ifndef __USE_GNU
 848 #define __USE_GNU
 849 #endif /* __USE_GNU */
 850 FRR_INCLUDES
 851 ])
 852
 853 m4_define([UCONTEXT_INCLUDES],
 854 [#include <ucontext.h>])dnl
 855
 856 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.uc_regs],
 857   [], [], [UCONTEXT_INCLUDES])
 858 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs],
 859   [AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs.nip],
 860    [], [], [UCONTEXT_INCLUDES])],
 861   [], [UCONTEXT_INCLUDES])
 862 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.gregs],
 863   [], [], [UCONTEXT_INCLUDES])
 864
 865 m4_define([FRR_INCLUDES],
 866 FRR_INCLUDES
 867 [
 868 #include <sys/un.h>
 869 #include <netinet/in_systm.h>
 870 #if HAVE_NETINET_IN_VAR_H
 871 # include <netinet/in_var.h>
 872 #endif
 873 #if HAVE_NET_IF_DL_H
 874 # include <net/if_dl.h>
 875 #endif
 876 #if HAVE_NET_NETOPT_H
 877 # include <net/netopt.h>
 878 #endif
 879 #include <net/route.h>
 880 #if HAVE_INET_ND_H
 881 # include <inet/nd.h>
 882 #endif
 883 #include <arpa/inet.h>
 884 /* Required for IDRP */
 885 #if HAVE_NETINET_IP_ICMP_H
 886 # include <netinet/ip_icmp.h>
 887 #endif
 888 ])dnl
 889
 890 dnl V6 headers are checked below, after we check for v6
 891
 892 AC_MSG_CHECKING([which operating system interface to use])
 893 case "$host_os" in
 894   sunos* | solaris2*)
 895     AC_MSG_RESULT([Solaris])
 896
 897     AC_DEFINE(SUNOS_5, 1, [SunOS 5])
 898     AC_DEFINE(SOLARIS_IPV6, 1, Solaris IPv6)
 899
 900     AC_CHECK_LIB(socket, main)
 901     AC_CHECK_LIB(nsl, main)
 902     AC_CHECK_LIB(umem, main)
 903     AC_CHECK_FUNCS([printstack], [
 904       AC_DEFINE([HAVE_PRINTSTACK],1,[Solaris printstack])
 905       AC_DEFINE([HAVE_STACK_TRACE],1,[Stack symbols decode functionality])
 906     ])
 907     CURSES=-lcurses
 908     SOLARIS="solaris"
 909     ;;
 910   linux*)
 911     AC_MSG_RESULT([Linux])
 912
 913     AC_DEFINE(GNU_LINUX,,GNU Linux)
 914     AC_DEFINE(HAVE_NETLINK,,netlink)
 915     AC_DEFINE(LINUX_IPV6,1,Linux IPv6 stack)
 916
 917     dnl Linux has a compilation problem with mixing
 918     dnl netinet/in.h and linux/in6.h they are not
 919     dnl compatible.  There has been discussion on
 920     dnl how to fix it but no real progress on implementation
 921     dnl when they fix it, remove this
 922     AC_DEFINE(IPV6_MINHOPCOUNT, 73, Linux ipv6 Min Hop Count)
 923
 924     AC_CHECK_DECLS([IFLA_INFO_SLAVE_KIND], [], [], [#include <linux/if_link.h>])
 925     ;;
 926   openbsd*)
 927     AC_MSG_RESULT([OpenBSD])
 928
 929     AC_DEFINE(OPEN_BSD,,OpenBSD)
 930     AC_DEFINE(KAME,1,KAME IPv6)
 931     AC_DEFINE(BSD_V6_SYSCTL,1,BSD v6 sysctl to turn on and off forwarding)
 932
 933     if test "x${enable_pimd}" != "xno"; then
 934       case "$host_os" in
 935       openbsd6.0)
 936         ;;
 937       openbsd[6-9]*)
 938         AC_MSG_FAILURE([pimd cannot be enabled as PIM support has been removed from OpenBSD 6.1])
 939         ;;
 940       esac
 941     fi
 942     ;;
 943   *)
 944     AC_MSG_RESULT([BSD])
 945
 946     AC_DEFINE(HAVE_NET_RT_IFLIST,,NET_RT_IFLIST)
 947     AC_DEFINE(KAME,1,KAME IPv6)
 948     AC_DEFINE(BSD_V6_SYSCTL,1,BSD v6 sysctl to turn on and off forwarding)
 949     ;;
 950 esac
 951 AM_CONDITIONAL(SOLARIS, test "${SOLARIS}" = "solaris")
 952
 953 AC_SYS_LARGEFILE
 954
 955 dnl ------------------------
 956 dnl Integrated REALMS option
 957 dnl ------------------------
 958 if test "${enable_realms}" = "yes"; then
 959     case "$host_os" in
 960       linux*)
 961        AC_DEFINE(SUPPORT_REALMS,, Realms support)
 962        ;;
 963       *)
 964        echo "Sorry, only Linux has REALMS support"
 965        exit 1
 966        ;;
 967     esac
 968 fi
 969 AM_CONDITIONAL([SUPPORT_REALMS], [test "${enable_realms}" = "yes"])
 970
 971 dnl ---------------------
 972 dnl Integrated VTY option
 973 dnl ---------------------
 974 case "${enable_vtysh}" in
 975   "no") VTYSH="";;
 976   *)    VTYSH="vtysh";
 977          AC_DEFINE(VTYSH,,VTY shell)
 978 dnl      Vtysh uses libreadline, which looks for termcap functions at
 979 dnl      configure time.  We follow readlines search order.
 980 dnl      The required procedures are in libtermcap on NetBSD, in
 981 dnl      [TODO] on Linux, and in [TODO] on Solaris.
 982          AC_CHECK_LIB(termcap, tputs, LIBREADLINE="$LIBREADLINE -ltermcap",
 983            [AC_CHECK_LIB(tinfo, tputs, LIBREADLINE="$LIBREADLINE -ltinfo",
 984              [AC_CHECK_LIB(curses, tputs, LIBREADLINE="$LIBREADLINE -lcurses",
 985                [AC_CHECK_LIB(ncurses, tputs,
 986                              LIBREADLINE="$LIBREADLINE -lncurses")]
 987               )]
 988             )]
 989           )
 990          AC_CHECK_LIB(readline, main, LIBREADLINE="-lreadline $LIBREADLINE",,
 991                       "$LIBREADLINE")
 992          if test $ac_cv_lib_readline_main = no; then
 993            AC_MSG_ERROR([vtysh needs libreadline but was not found and usable on your system.])
 994          fi
 995          AC_CHECK_HEADER(readline/history.h)
 996          if test $ac_cv_header_readline_history_h = no;then
 997            AC_MSG_ERROR([readline is too old to have readline/history.h, please update to the latest readline library.])
 998          fi
 999          AC_CHECK_LIB(readline, rl_completion_matches,
1000                       LIBREADLINE="$LIBREADLINE",, "$LIBREADLINE")
1001          if test $ac_cv_lib_readline_rl_completion_matches = no; then
1002            AC_DEFINE(rl_completion_matches,completion_matches,Old readline)
1003          fi
1004          ;;
1005 esac
1006 AC_SUBST(LIBREADLINE)
1007 AM_CONDITIONAL(VTYSH, test "x$VTYSH" = "xvtysh")
1008
1009 dnl ----------
1010 dnl PAM module
1011 dnl
1012 dnl FRR detects the PAM library it is built against by checking for a
1013 dnl functional pam_misc.h (Linux-PAM) or openpam.h (OpenPAM) header. pam_misc.h
1014 dnl is known to #include pam_appl.h, the standard header of a PAM library, and
1015 dnl openpam.h doesn't do that, although depends on the header too. Hence a
1016 dnl little assistance to AC_CHECK_HEADER is necessary for the proper detection
1017 dnl of OpenPAM.
1018 dnl ----------
1019 if test "$with_libpam" = "yes"; then
1020   AC_CHECK_HEADER([security/pam_misc.h],
1021     [AC_DEFINE(HAVE_PAM_MISC_H,,Have pam_misc.h)
1022      AC_DEFINE(PAM_CONV_FUNC,misc_conv,Have misc_conv)
1023      pam_conv_func="misc_conv"
1024     ],
1025     [], FRR_INCLUDES)
1026   AC_CHECK_HEADER([security/openpam.h],
1027     [AC_DEFINE(HAVE_OPENPAM_H,,Have openpam.h)
1028      AC_DEFINE(PAM_CONV_FUNC,openpam_ttyconv,Have openpam_ttyconv)
1029      pam_conv_func="openpam_ttyconv"
1030     ],
1031     [], FRR_INCLUDES[#include <security/pam_appl.h>])
1032   if test -z "$ac_cv_header_security_pam_misc_h$ac_cv_header_security_openpam_h" ; then
1033     AC_MSG_WARN([*** pam support will not be built ***])
1034     with_libpam="no"
1035   fi
1036 fi
1037
1038 if test "$with_libpam" = "yes"; then
1039 dnl took this test from proftpds configure.in and suited to our needs
1040 dnl -------------------------------------------------------------------------
1041 dnl
1042 dnl This next check looks funky due to a linker problem with some versions
1043 dnl of the PAM library.  Prior to 0.72 release, the Linux PAM shared library
1044 dnl omitted requiring libdl linking information. PAM-0.72 or better ships
1045 dnl with RedHat 6.2 and Debian 2.2 or better.
1046 AC_CHECK_LIB(pam, pam_start,
1047   [AC_CHECK_LIB(pam, $pam_conv_func,
1048     [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1049      LIBPAM="-lpam"],
1050     [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1051      LIBPAM="-lpam -lpam_misc"]
1052     )
1053   ],
1054
1055   [AC_CHECK_LIB(pam, pam_end,
1056     [AC_CHECK_LIB(pam, $pam_conv_func,
1057       [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1058        LIBPAM="-lpam -ldl"],
1059       [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1060        LIBPAM="-lpam -ldl -lpam_misc"]
1061      )
1062   ],AC_MSG_WARN([*** pam support will not be built ***]),
1063   [-ldl])
1064   ]
1065 )
1066 fi
1067 AC_SUBST(LIBPAM)
1068
1069 dnl -------------------------------
1070 dnl Endian-ness check
1071 dnl -------------------------------
1072 AC_WORDS_BIGENDIAN
1073
1074 dnl -------------------------------
1075 dnl check the size in byte of the C
1076 dnl -------------------------------
1077 dnl AC_CHECK_SIZEOF(char)
1078 dnl AC_CHECK_SIZEOF(int)
1079 dnl AC_CHECK_SIZEOF(short)
1080 dnl AC_CHECK_SIZEOF(long)
1081
1082 dnl ----------------------------
1083 dnl check existance of functions
1084 dnl ----------------------------
1085 AC_FUNC_FNMATCH
1086 AC_FUNC_FORK
1087 AC_FUNC_MKTIME
1088 AC_FUNC_STAT
1089
1090 dnl -------------------------------
1091 dnl bgpd needs pow() and hence libm
1092 dnl -------------------------------
1093 TMPLIBS="$LIBS"
1094 AC_CHECK_HEADER([math.h],
1095   [AC_CHECK_LIB([m], [pow],
1096     [LIBM="-lm"
1097      LIBS="$LIBS $LIBM"
1098      AC_CHECK_FUNCS(pow,[],[LIBM=""])
1099     ])
1100 ])
1101 if test x"$LIBM" = x ; then
1102   AC_MSG_WARN([Unable to find working pow function - bgpd may not link])
1103 fi
1104 LIBS="$TMPLIBS"
1105 AC_SUBST(LIBM)
1106
1107 AC_CHECK_FUNCS([ppoll], [
1108   AC_DEFINE([HAVE_PPOLL], 1, [have Linux/BSD ppoll()])
1109 ])
1110 AC_CHECK_FUNCS([pollts], [
1111   AC_DEFINE([HAVE_POLLTS], 1, [have NetBSD pollts()])
1112 ])
1113
1114 dnl ---------------
1115 dnl other functions
1116 dnl ---------------
1117 AC_CHECK_FUNCS([ \
1118         strlcat strlcpy \
1119         getgrouplist])
1120
1121 AC_CHECK_HEADER([asm-generic/unistd.h],
1122                 [AC_CHECK_DECL(__NR_setns,
1123                                AC_DEFINE(HAVE_NETNS,, Have netns),,
1124                                FRR_INCLUDES [#include <asm-generic/unistd.h>
1125                                ])
1126                  AC_CHECK_FUNCS(setns)]
1127                )
1128
1129 dnl --------------------------
1130 dnl Determine IS-IS I/O method
1131 dnl --------------------------
1132 AC_DEFINE(ISIS_METHOD_PFPACKET, 1, [ constant value for isis method pfpacket ])
1133 AC_DEFINE(ISIS_METHOD_DLPI,     2, [ constant value for isis method dlpi ])
1134 AC_DEFINE(ISIS_METHOD_BPF,      3, [ constant value for isis method bpf ])
1135 AC_CHECK_HEADER(net/bpf.h)
1136 AC_CHECK_HEADER(sys/dlpi.h)
1137 AC_MSG_CHECKING(zebra IS-IS I/O method)
1138
1139 case "$host_os" in
1140   linux*)
1141     AC_MSG_RESULT(pfpacket)
1142     ISIS_METHOD_MACRO="ISIS_METHOD_PFPACKET"
1143     ;;
1144   solaris* | sunos*)
1145     AC_MSG_RESULT(DLPI)
1146     ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1147     ;;
1148   *)
1149     if test $ac_cv_header_net_bpf_h = no; then
1150       if test $ac_cv_header_sys_dlpi_h = no; then
1151         AC_MSG_RESULT(none)
1152         if test "${enable_isisd}" = yes; then
1153           AC_MSG_FAILURE([IS-IS support requested but no packet backend found])
1154         fi
1155         AC_MSG_WARN([*** IS-IS support will not be built ***])
1156         enable_isisd="no"
1157       else
1158         AC_MSG_RESULT(DLPI)
1159       fi
1160       ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1161     else
1162       AC_MSG_RESULT(BPF)
1163       ISIS_METHOD_MACRO="ISIS_METHOD_BPF"
1164     fi
1165     ;;
1166 esac
1167 AC_DEFINE_UNQUOTED(ISIS_METHOD, $ISIS_METHOD_MACRO, [ selected method for isis, == one of the constants ])
1168
1169 dnl ------------------------------------
1170 dnl check for broken CMSG_FIRSTHDR macro
1171 dnl ------------------------------------
1172 AC_MSG_CHECKING(for broken CMSG_FIRSTHDR)
1173 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1174 #ifdef SUNOS_5
1175 #define _XPG4_2
1176 #define __EXTENSIONS__
1177 #endif
1178 #include <stdlib.h>
1179 #include <sys/types.h>
1180 #include <sys/socket.h>
1181
1182 main()
1183 {
1184   struct msghdr msg;
1185   char buf[4];
1186
1187   msg.msg_control = buf;
1188   msg.msg_controllen = 0;
1189
1190   if (CMSG_FIRSTHDR(&msg) != NULL)
1191     exit(0);
1192   exit (1);
1193 }]])],[AC_MSG_RESULT(yes - using workaround) AC_DEFINE(HAVE_BROKEN_CMSG_FIRSTHDR,,Broken CMSG_FIRSTHDR)],
1194 [AC_MSG_RESULT(no)],[AC_MSG_RESULT(no)])
1195
1196 dnl ---------------------------------------------------------------
1197 dnl figure out how to specify an interface in multicast sockets API
1198 dnl ---------------------------------------------------------------
1199 AC_CHECK_MEMBERS([struct ip_mreqn.imr_ifindex], [], [], FRR_INCLUDES)
1200
1201 AC_CHECK_HEADERS([linux/mroute.h], [], [],[
1202         #include <sys/socket.h>
1203         #include <netinet/in.h>
1204         #define _LINUX_IN_H             /* For Linux <= 2.6.25 */
1205         #include <linux/types.h>
1206 ])
1207
1208 m4_define([FRR_INCLUDES],
1209 FRR_INCLUDES
1210 [#if HAVE_LINUX_MROUTE_H
1211 # include <linux/mroute.h>
1212 #endif
1213 ])dnl
1214
1215 AC_CHECK_HEADERS([netinet/ip_mroute.h], [], [],[
1216         #include <sys/socket.h>
1217         #include <sys/types.h>
1218         #include <netinet/in.h>
1219         #include <net/route.h>
1220 ])
1221
1222 m4_define([FRR_INCLUDES],
1223 FRR_INCLUDES
1224 [#if HAVE_NETINET_IP_MROUTE_H
1225 # include <netinet/ip_mroute.h>
1226 #endif
1227 ])dnl
1228
1229 AC_MSG_CHECKING([for BSD struct ip_mreq hack])
1230 AC_TRY_COMPILE([#include <sys/param.h>],
1231 [#if (defined(__FreeBSD__) && ((__FreeBSD_version >= 500022 && __FreeBSD_version < 700000) || (__FreeBSD_version < 500000 && __FreeBSD_version >= 440000))) || (defined(__NetBSD__) && defined(__NetBSD_Version__) && __NetBSD_Version__ >= 106010000) || defined(__OpenBSD__) || defined(__APPLE__) || defined(__DragonFly__) || defined(__sun)
1232   return (0);
1233 #else
1234   #error No support for BSD struct ip_mreq hack detected
1235 #endif],[AC_MSG_RESULT(yes)
1236 AC_DEFINE(HAVE_BSD_STRUCT_IP_MREQ_HACK,,[Can pass ifindex in struct ip_mreq])],
1237 AC_MSG_RESULT(no))
1238
1239 AC_MSG_CHECKING([for RFC3678 protocol-independed API])
1240 AC_TRY_COMPILE([
1241 #include <sys/types.h>
1242 #include <netinet/in.h>
1243 ], [struct group_req gr; int sock; setsockopt(sock, IPPROTO_IP, MCAST_JOIN_GROUP, (void*)&gr, sizeof(gr));
1244 ], [AC_MSG_RESULT(yes)
1245 AC_DEFINE(HAVE_RFC3678,1,[Have RFC3678 protocol-independed API])],
1246 AC_MSG_RESULT(no))
1247
1248 dnl ---------------------------------------------------------------
1249 dnl figure out how to check link-state
1250 dnl ---------------------------------------------------------------
1251 AC_CHECK_HEADER( [net/if_media.h],
1252   [m4_define([LINK_DETECT_INCLUDES],
1253     FRR_INCLUDES
1254     [#include <net/if_media.h>
1255   ])
1256   AC_CHECK_MEMBERS( [struct ifmediareq.ifm_status],
1257     AC_DEFINE(HAVE_BSD_LINK_DETECT,,[BSD link-detect]),
1258     [], LINK_DETECT_INCLUDES)],
1259   [],
1260   FRR_INCLUDES)
1261
1262 dnl ---------------------------------------------------------------
1263 dnl Additional, newer way to check link-state using ifi_link_state.
1264 dnl Not available in all BSD's when ifmediareq available
1265 dnl ---------------------------------------------------------------
1266 AC_CHECK_MEMBERS([struct if_data.ifi_link_state],
1267   AC_DEFINE(HAVE_BSD_IFI_LINK_STATE,,[BSD ifi_link_state available]),
1268   [], FRR_INCLUDES)
1269
1270 dnl ------------------------
1271 dnl TCP_MD5SIG socket option
1272 dnl ------------------------
1273
1274 AC_CHECK_HEADER([netinet/tcp.h],
1275    [m4_define([MD5_INCLUDES],
1276       FRR_INCLUDES
1277       [#include <netinet/tcp.h>
1278     ])
1279     AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)],
1280    [],
1281    FRR_INCLUDES)
1282 if test $ac_cv_have_decl_TCP_MD5SIG = no; then
1283   AC_CHECK_HEADER([linux/tcp.h],
1284        [m4_define([MD5_INCLUDES],
1285           FRR_INCLUDES
1286           [#include <linux/tcp.h>
1287         ])
1288        AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)])
1289 fi
1290
1291 dnl ----------------------------------------------------------------------------
1292 dnl figure out if domainname is available in the utsname struct (GNU extension).
1293 dnl ----------------------------------------------------------------------------
1294 AC_CHECK_MEMBERS([struct utsname.domainname], [], [], [#include <sys/utsname.h>])
1295
1296 dnl ------------------
1297 dnl IPv6 header checks
1298 dnl ------------------
1299 AC_CHECK_HEADERS([netinet6/in6.h netinet/in6_var.h \
1300         netinet6/in6_var.h netinet6/nd6.h], [], [],
1301         FRR_INCLUDES)
1302
1303 m4_define([FRR_INCLUDES],dnl
1304 FRR_INCLUDES
1305 [#if HAVE_NETINET6_IN6_H
1306 #include <netinet6/in6.h>
1307 #endif
1308 #if HAVE_NETINET_IN6_VAR_H
1309 #include <netinet/in6_var.h>
1310 #endif
1311 #include <netinet/icmp6.h>
1312 #if HAVE_NETINET6_IN6_VAR_H
1313 # include <netinet6/in6_var.h>
1314 #endif
1315 #if HAVE_NETINET6_ND6_H
1316 # include <netinet6/nd6.h>
1317 #endif
1318 ])dnl
1319
1320 dnl disable doc check
1321 if test "${enable_doc}" = "no";then
1322   DOC=""
1323 else
1324   DOC="doc"
1325 fi
1326
1327 dnl --------------------
1328 dnl Daemon disable check
1329 dnl --------------------
1330 AM_CONDITIONAL(ZEBRA, test "${enable_zebra}" != "no")
1331
1332 if test "${enable_bgpd}" = "no";then
1333   BGPD=""
1334 else
1335   BGPD="bgpd"
1336 fi
1337 AM_CONDITIONAL(BGPD, test "x$BGPD" = "xbgpd")
1338
1339 AM_CONDITIONAL(RIPD, test "${enable_ripd}" != "no")
1340 AM_CONDITIONAL(OSPFD, test "${enable_ospfd}" != "no")
1341 AM_CONDITIONAL(LDPD, test "${enable_ldpd}" != "no")
1342
1343 AS_IF([test "${enable_ldpd}" != "no"], [
1344   AC_DEFINE(HAVE_LDPD, 1, ldpd)
1345 ])
1346
1347 NHRPD=""
1348 case "$host_os" in
1349   linux*)
1350     if test "${enable_nhrpd}" != "no"; then
1351       NHRPD="nhrpd"
1352     fi
1353     ;;
1354   *)
1355     if test "${enable_nhrpd}" = "yes"; then
1356       AC_MSG_ERROR([nhrpd requires kernel APIs that are only present on Linux.])
1357     fi
1358     ;;
1359 esac
1360 AM_CONDITIONAL(NHRPD, test "x$NHRPD" = "xnhrpd")
1361
1362 AM_CONDITIONAL(EIGRPD, test "${enable_eigrpd}" != "no")
1363
1364 if test "${enable_watchfrr}" = "no";then
1365   WATCHFRR=""
1366 else
1367   WATCHFRR="watchfrr"
1368 fi
1369 AM_CONDITIONAL(WATCHFRR, test "x$WATCHFRR" = "xwatchfrr")
1370
1371 OSPFCLIENT=""
1372 if test "${enable_ospfapi}" != "no";then
1373     AC_DEFINE(SUPPORT_OSPF_API,,OSPFAPI)
1374
1375   if test "${enable_ospfclient}" != "no";then
1376       OSPFCLIENT="ospfclient"
1377   fi
1378 fi
1379
1380 AM_CONDITIONAL(OSPFCLIENT, test "x$OSPFCLIENT" = "xospfclient")
1381 AM_CONDITIONAL(RIPNGD, test "${enable_ripngd}" != "no")
1382 AM_CONDITIONAL(BABELD, test "${enable_babeld}" != "no")
1383 AM_CONDITIONAL(OSPF6D, test "${enable_ospf6d}" != "no")
1384 AM_CONDITIONAL(ISISD, test "${enable_isisd}" != "no")
1385 AM_CONDITIONAL(PIMD, test "${enable_pimd}" != "no")
1386 AM_CONDITIONAL(PBRD, test "${enable_pbrd}" != "no")
1387 AM_CONDITIONAL(SHARPD, test "${enable_sharpd}" = "yes")
1388
1389 if test "${enable_bgp_announce}" = "no";then
1390   AC_DEFINE(DISABLE_BGP_ANNOUNCE,1,Disable BGP installation to zebra)
1391 else
1392   AC_DEFINE(DISABLE_BGP_ANNOUNCE,0,Disable BGP installation to zebra)
1393 fi
1394
1395 if test "${with_rfp_path}" = "yes" || test x"${with_rfp_path}" = x""; then
1396   with_rfp_path="bgpd/rfp-example"
1397 fi
1398 if test "${with_rfp_path}" != "no"; then
1399   VNC_RFP_PATH="${with_rfp_path}"
1400   AC_SUBST(VNC_RFP_PATH)
1401 fi
1402
1403 if test "${enable_bgp_vnc}" != "no";then
1404   AC_DEFINE(ENABLE_BGP_VNC,1,Enable BGP VNC support)
1405   RFPTEST="${with_rfp_path}/rfptest"
1406   LIBRFP="${with_rfp_path}/librfp"
1407   RFPINC="${with_rfp_path}/librfp"
1408 else
1409   RFPTEST=
1410   LIBRFP=
1411   RFPINC="bgpd/rfp-example/librfp"
1412 fi
1413 # set
1414 AM_CONDITIONAL([ENABLE_BGP_VNC], [test x${enable_bgp_vnc} != xno])
1415
1416 AC_SUBST(DOC)
1417 AC_SUBST(RFPTEST)
1418 AC_SUBST(LIBRFP)
1419 AC_SUBST(RFPINC)
1420 AC_SUBST(BGPD)
1421 AC_SUBST(SOLARIS)
1422 AC_SUBST(VTYSH)
1423 AC_SUBST(CURSES)
1424 AC_CHECK_LIB(crypt, crypt, [],
1425                     [AC_CHECK_LIB(crypto, DES_crypt)])
1426 AC_CHECK_LIB(resolv, res_init)
1427
1428 dnl ---------------------------
1429 dnl check system has PCRE regexp
1430 dnl ---------------------------
1431 if test "x$enable_pcreposix" = "xyes"; then
1432   AC_CHECK_LIB(pcreposix, regexec, [], [
1433     AC_MSG_ERROR([--enable-pcreposix given but unable to find libpcreposix])
1434   ])
1435 fi
1436 AC_SUBST(HAVE_LIBPCREPOSIX)
1437
1438 dnl ------------------
1439 dnl check C-Ares library
1440 dnl ------------------
1441 if test "${NHRPD}" != ""; then
1442   PKG_CHECK_MODULES([CARES], [libcares], , [
1443     AC_MSG_ERROR([trying to build nhrpd, but libcares not found. install c-ares and its -dev headers.])
1444   ])
1445 fi
1446
1447
1448 dnl ------------------
1449 dnl check Net-SNMP library
1450 dnl ------------------
1451 if test "${enable_snmp}" != "" -a "${enable_snmp}" != "no"; then
1452    AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], [no])
1453    if test x"$NETSNMP_CONFIG" = x"no"; then
1454       AC_MSG_ERROR([--enable-snmp given but unable to find net-snmp-config])
1455    fi
1456    SNMP_LIBS="`${NETSNMP_CONFIG} --agent-libs`"
1457    SNMP_CFLAGS="`${NETSNMP_CONFIG} --base-cflags`"
1458    AC_MSG_CHECKING([whether we can link to Net-SNMP])
1459    AC_LINK_IFELSE_FLAGS([$SNMP_CFLAGS], [$SNMP_LIBS], [AC_LANG_PROGRAM([
1460 int main(void);
1461 ],
1462 [
1463 {
1464   return 0;
1465 }
1466 ])], [
1467      AC_MSG_ERROR([--enable-snmp given but not usable])])
1468    case "${enable_snmp}" in
1469      yes)
1470       SNMP_METHOD=agentx
1471       ;;
1472      smux|agentx)
1473       SNMP_METHOD="${enable_snmp}"
1474       ;;
1475      *)
1476       AC_MSG_ERROR([--enable-snmp given with an unknown method (${enable_snmp}). Use smux or agentx])
1477       ;;
1478    esac
1479    AH_TEMPLATE([SNMP_SMUX], [Use SNMP SMUX to interface with snmpd])
1480    AH_TEMPLATE([SNMP_AGENTX], [Use SNMP AgentX to interface with snmpd])
1481    AC_DEFINE_UNQUOTED(AS_TR_CPP(SNMP_${SNMP_METHOD}),,SNMP method to interface with snmpd)
1482 fi
1483 AM_CONDITIONAL([SNMP], [test "x${SNMP_METHOD}" != "x"])
1484 AC_SUBST(SNMP_LIBS)
1485 AC_SUBST(SNMP_CFLAGS)
1486
1487 dnl ---------------
1488 dnl math
1489 dnl ---------------
1490 AC_SEARCH_LIBS([sqrt], [m])
1491
1492 dnl ---------------
1493 dnl dlopen & dlinfo
1494 dnl ---------------
1495 AC_SEARCH_LIBS(dlopen, [dl dld], [], [
1496   AC_MSG_ERROR([unable to find the dlopen()])
1497 ])
1498
1499 AC_CHECK_HEADERS([link.h])
1500
1501 AC_MSG_CHECKING([for dlinfo(RTLD_DI_ORIGIN)])
1502 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1503 #include <stdlib.h>
1504 #ifdef HAVE_LINK_H
1505 #include <link.h>
1506 #endif
1507 #include <dlfcn.h>
1508 ]], [[
1509   char origin[1];
1510   dlinfo (NULL, RTLD_DI_ORIGIN, &origin);
1511 ]])], [
1512   AC_MSG_RESULT(yes)
1513   AC_DEFINE(HAVE_DLINFO_ORIGIN, 1, [Have dlinfo RTLD_DI_ORIGIN])
1514 ], [
1515   AC_MSG_RESULT(no)
1516 ])
1517
1518 AC_MSG_CHECKING([for dlinfo(RTLD_DI_LINKMAP)])
1519 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1520 #include <stdlib.h>
1521 #ifdef HAVE_LINK_H
1522 #include <link.h>
1523 #endif
1524 #include <dlfcn.h>
1525 ]], [[
1526   struct link_map *lm = NULL;
1527   dlinfo (NULL, RTLD_DI_LINKMAP, &lm);
1528 ]])], [
1529   AC_MSG_RESULT(yes)
1530   AC_DEFINE(HAVE_DLINFO_LINKMAP, 1, [Have dlinfo RTLD_DI_LINKMAP])
1531 ], [
1532   AC_MSG_RESULT(no)
1533 ])
1534
1535
1536 AM_CONDITIONAL(SNMP, test "x$SNMP_METHOD" = "xagentx")
1537
1538 dnl ---------------------------
1539 dnl sockaddr and netinet checks
1540 dnl ---------------------------
1541 AC_CHECK_TYPES([
1542         struct sockaddr_dl,
1543         struct vifctl, struct mfcctl, struct sioc_sg_req,
1544         vifi_t, struct sioc_vif_req, struct igmpmsg,
1545         struct ifaliasreq, struct if6_aliasreq, struct in6_aliasreq,
1546         struct nd_opt_adv_interval, struct rt_addrinfo,
1547         struct nd_opt_homeagent_info, struct nd_opt_adv_interval],
1548         [], [], FRR_INCLUDES)
1549
1550 AC_CHECK_MEMBERS([struct sockaddr.sa_len,
1551         struct sockaddr_in.sin_len, struct sockaddr_un.sun_len,
1552         struct sockaddr_dl.sdl_len,
1553         struct if6_aliasreq.ifra_lifetime,
1554         struct nd_opt_adv_interval.nd_opt_ai_type],
1555         [], [], FRR_INCLUDES)
1556
1557 dnl ---------------------------
1558 dnl IRDP/pktinfo/icmphdr checks
1559 dnl ---------------------------
1560
1561 AC_CHECK_TYPES([struct in_pktinfo], [
1562   AC_CHECK_TYPES([struct icmphdr], [
1563     IRDP=true
1564   ], [
1565     IRDP=false
1566   ], [FRR_INCLUDES])
1567 ], [
1568   IRDP=false
1569 ], [FRR_INCLUDES])
1570
1571 case "${enable_irdp}" in
1572 yes)
1573   $IRDP || AC_MSG_ERROR(['IRDP requires in_pktinfo at the moment!'])
1574   ;;
1575 no)
1576   IRDP=false
1577   ;;
1578 esac
1579
1580 AM_CONDITIONAL(IRDP, $IRDP)
1581
1582 dnl -----------------------
1583 dnl checking for IP_PKTINFO
1584 dnl -----------------------
1585 AC_MSG_CHECKING(for IP_PKTINFO)
1586 AC_TRY_COMPILE([#include <netdb.h>], [
1587   int opt = IP_PKTINFO;
1588 ], [
1589   AC_MSG_RESULT(yes)
1590   AC_DEFINE(HAVE_IP_PKTINFO, 1, [Have IP_PKTINFO])
1591 ], [
1592   AC_MSG_RESULT(no)
1593 ])
1594
1595 dnl ---------------------------
1596 dnl checking for IP_RECVDSTADDR
1597 dnl ---------------------------
1598 AC_MSG_CHECKING(for IP_RECVDSTADDR)
1599 AC_TRY_COMPILE([#include <netinet/in.h>], [
1600   int opt = IP_RECVDSTADDR;
1601 ], [
1602   AC_MSG_RESULT(yes)
1603   AC_DEFINE(HAVE_IP_RECVDSTADDR, 1, [Have IP_RECVDSTADDR])
1604 ], [
1605   AC_MSG_RESULT(no)
1606 ])
1607
1608 dnl ----------------------
1609 dnl checking for IP_RECVIF
1610 dnl ----------------------
1611 AC_MSG_CHECKING(for IP_RECVIF)
1612 AC_TRY_COMPILE([#include <netinet/in.h>], [
1613   int opt = IP_RECVIF;
1614 ], [
1615   AC_MSG_RESULT(yes)
1616   AC_DEFINE(HAVE_IP_RECVIF, 1, [Have IP_RECVIF])
1617 ], [
1618   AC_MSG_RESULT(no)
1619 ])
1620
1621 dnl ----------------------
1622 dnl checking for SO_BINDANY
1623 dnl ----------------------
1624 AC_MSG_CHECKING(for SO_BINDANY)
1625 AC_TRY_COMPILE([#include <sys/socket.h>], [
1626   int opt = SO_BINDANY;
1627 ], [
1628   AC_MSG_RESULT(yes)
1629   AC_DEFINE(HAVE_SO_BINDANY, 1, [Have SO_BINDANY])
1630 ], [
1631   AC_MSG_RESULT(no)
1632 ])
1633
1634 dnl ----------------------
1635 dnl checking for IP_FREEBIND
1636 dnl ----------------------
1637 AC_MSG_CHECKING(for IP_FREEBIND)
1638 AC_TRY_COMPILE([#include <netinet/in.h>], [
1639   int opt = IP_FREEBIND;
1640 ], [
1641   AC_MSG_RESULT(yes)
1642   AC_DEFINE(HAVE_IP_FREEBIND, 1, [Have IP_FREEBIND])
1643 ], [
1644   AC_MSG_RESULT(no)
1645 ])
1646
1647 dnl --------------------------------------
1648 dnl checking for be32dec existence or not
1649 dnl --------------------------------------
1650 AC_CHECK_DECLS([be32enc, be32dec], [], [],
1651                [#include <sys/endian.h>])
1652
1653 dnl --------------------------------------
1654 dnl checking for clock_time monotonic struct and call
1655 dnl --------------------------------------
1656 AC_CHECK_DECL(CLOCK_MONOTONIC,
1657         [AC_CHECK_LIB(rt, clock_gettime, [LIBS="$LIBS -lrt"])
1658          AC_DEFINE(HAVE_CLOCK_MONOTONIC,, Have monotonic clock)
1659 ], [AC_MSG_RESULT(no)], [FRR_INCLUDES])
1660
1661 dnl --------------------------------------
1662 dnl checking for flex and bison
1663 dnl --------------------------------------
1664
1665 AM_PROG_LEX
1666 AC_MSG_CHECKING(version of flex)
1667 frr_ac_flex_version="$(eval $LEX -V | grep flex | head -n 1)"
1668 frr_ac_flex_version="${frr_ac_flex_version##* }"
1669 AC_MSG_RESULT([$frr_ac_flex_version])
1670 AX_COMPARE_VERSION([$frr_ac_flex_version], [lt], [2.5.20], [
1671   LEX="$SHELL $missing_dir/missing flex"
1672   if test -f "${srcdir}/lib/command_lex.c" -a -f "${srcdir}/lib/command_lex.h"; then
1673     AC_MSG_WARN([using pregenerated flex output files])
1674   else
1675     AC_MSG_ERROR([flex failure and pregenerated files not included (probably a git build)])
1676   fi
1677   AC_SUBST([LEX_OUTPUT_ROOT], [lex.yy])
1678   AC_SUBST([LEXLIB], [''])
1679 ])
1680
1681 AC_PROG_YACC
1682 dnl thanks GNU bison for this b*llshit...
1683 AC_MSG_CHECKING(version of bison)
1684 frr_ac_bison_version="$(eval $YACC -V | grep bison | head -n 1)"
1685 frr_ac_bison_version="${frr_ac_bison_version##* }"
1686 frr_ac_bison_missing="false"
1687 case "x${frr_ac_bison_version}" in
1688   x2.7*)
1689     BISON_OPENBRACE='"'
1690     BISON_CLOSEBRACE='"'
1691     BISON_VERBOSE=''
1692     AC_MSG_RESULT([$frr_ac_bison_version - 2.7 or older])
1693     ;;
1694   x2.*|x1.*)
1695     AC_MSG_RESULT([$frr_ac_bison_version])
1696     AC_MSG_WARN([installed bison is too old.  Please install GNU bison 2.7.x or newer.])
1697     frr_ac_bison_missing="true"
1698     ;;
1699   x)
1700     AC_MSG_RESULT([none])
1701     AC_MSG_WARN([could not determine bison version.  Please install GNU bison 2.7.x or newer.])
1702     frr_ac_bison_missing="true"
1703     ;;
1704   *)
1705     BISON_OPENBRACE='{'
1706     BISON_CLOSEBRACE='}'
1707     BISON_VERBOSE='-Dparse.error=verbose'
1708     AC_MSG_RESULT([$frr_ac_bison_version - 3.0 or newer])
1709     ;;
1710 esac
1711 AC_SUBST(BISON_OPENBRACE)
1712 AC_SUBST(BISON_CLOSEBRACE)
1713 AC_SUBST(BISON_VERBOSE)
1714
1715 if $frr_ac_bison_missing; then
1716   YACC="$SHELL $missing_dir/missing bison -y"
1717   if test -f "${srcdir}/lib/command_parse.c" -a -f "${srcdir}/lib/command_parse.h"; then
1718     AC_MSG_WARN([using pregenerated bison output files])
1719   else
1720     AC_MSG_ERROR([bison failure and pregenerated files not included (probably a git build)])
1721   fi
1722 fi
1723
1724 dnl -------------------
1725 dnl capabilities checks
1726 dnl -------------------
1727 if test "${enable_capabilities}" != "no"; then
1728   AC_MSG_CHECKING(whether prctl PR_SET_KEEPCAPS is available)
1729   AC_TRY_COMPILE([#include <sys/prctl.h>],[prctl(PR_SET_KEEPCAPS, 1, 0, 0, 0);],
1730     [AC_MSG_RESULT(yes)
1731      AC_DEFINE(HAVE_PR_SET_KEEPCAPS,,prctl)
1732      frr_ac_keepcaps="yes"],
1733      AC_MSG_RESULT(no)
1734   )
1735   if test x"${frr_ac_keepcaps}" = x"yes"; then
1736     AC_CHECK_HEADERS(sys/capability.h)
1737   fi
1738   if test x"${ac_cv_header_sys_capability_h}" = x"yes"; then
1739     AC_CHECK_LIB(cap, cap_init,
1740       [AC_DEFINE(HAVE_LCAPS,1,Capabilities)
1741        LIBCAP="-lcap"
1742        frr_ac_lcaps="yes"]
1743     )
1744   else
1745     AC_CHECK_HEADERS(priv.h,
1746      [AC_MSG_CHECKING(Solaris style privileges are available)
1747       AC_TRY_COMPILE([#include <priv.h>],[getpflags(PRIV_AWARE);],
1748           [AC_MSG_RESULT(yes)
1749            AC_DEFINE(HAVE_SOLARIS_CAPABILITIES,1,getpflags)
1750            frr_ac_scaps="yes"],
1751            AC_MSG_RESULT(no)
1752       )
1753      ]
1754    )
1755   fi
1756   if test x"${frr_ac_scaps}" = x"yes" \
1757        -o x"${frr_ac_lcaps}" = x"yes"; then
1758     AC_DEFINE(HAVE_CAPABILITIES,1,capabilities)
1759   fi
1760 fi
1761 AC_SUBST(LIBCAP)
1762
1763 dnl ---------------------------
1764 dnl check for glibc 'backtrace'
1765 dnl ---------------------------
1766 if test x"${enable_backtrace}" != x"no" ; then
1767   backtrace_ok=no
1768   AC_CHECK_HEADER([execinfo.h], [
1769     AC_SEARCH_LIBS([backtrace], [execinfo], [
1770       AC_DEFINE(HAVE_GLIBC_BACKTRACE,,[Glibc backtrace])
1771       AC_DEFINE(HAVE_STACK_TRACE,,[Stack symbol decoding])
1772       backtrace_ok=yes
1773     ],, [-lm])
1774   ])
1775
1776   if test x"${enable_backtrace}" = x"yes" -a x"${backtrace_ok}" = x"no"; then
1777     dnl user explicitly requested backtrace but we failed to find support
1778     AC_MSG_FAILURE([failed to find backtrace support])
1779   fi
1780 fi
1781
1782 dnl -----------------------------------------
1783 dnl check for malloc mallinfo struct and call
1784 dnl this must try and link using LIBS, in
1785 dnl order to check no alternative allocator
1786 dnl has been specified, which might not provide
1787 dnl mallinfo, e.g. such as Umem on Solaris.
1788 dnl -----------------------------------------
1789 AC_CHECK_HEADER([malloc.h],
1790  [AC_MSG_CHECKING(whether mallinfo is available)
1791   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <malloc.h>]],
1792                         [[struct mallinfo ac_x; ac_x = mallinfo ();]])],
1793       [AC_MSG_RESULT(yes)
1794        AC_DEFINE(HAVE_MALLINFO,,mallinfo)],
1795        AC_MSG_RESULT(no)
1796   )
1797  ], [], FRR_INCLUDES)
1798
1799 dnl ------
1800 dnl ZeroMQ
1801 dnl ------
1802 if test "x$enable_zeromq" != "xno"; then
1803   PKG_CHECK_MODULES(ZEROMQ, [libzmq >= 4.0.0], [
1804     AC_DEFINE(HAVE_ZEROMQ, 1, [Enable ZeroMQ support])
1805     ZEROMQ=true
1806   ], [
1807     if test "x$enable_zeromq" = "xyes"; then
1808       AC_MSG_ERROR([configuration specifies --enable-zeromq but libzmq was not found])
1809     fi
1810   ])
1811 fi
1812 AM_CONDITIONAL([ZEROMQ], test "x$ZEROMQ" = "xtrue")
1813
1814 dnl ----------
1815 dnl configure date
1816 dnl ----------
1817 CONFDATE=`date '+%Y%m%d'`
1818 AC_SUBST(CONFDATE)
1819
1820 dnl ------------------------------
1821 dnl set paths for state directory
1822 dnl ------------------------------
1823 AC_MSG_CHECKING(directory to use for state file)
1824 if test "${prefix}" = "NONE"; then
1825   frr_statedir_prefix="";
1826 else
1827   frr_statedir_prefix=${prefix}
1828 fi
1829 if test "${localstatedir}" = '${prefix}/var'; then
1830   for FRR_STATE_DIR in ${frr_statedir_prefix}/var/run dnl
1831                         ${frr_statedir_prefix}/var/adm dnl
1832                         ${frr_statedir_prefix}/etc dnl
1833                         /var/run        dnl
1834                         /var/adm        dnl
1835                         /etc            dnl
1836                         /dev/null;
1837   do
1838     test -d $FRR_STATE_DIR && break
1839   done
1840   frr_statedir=$FRR_STATE_DIR
1841 else
1842   frr_statedir=${localstatedir}
1843 fi
1844 if test $frr_statedir = "/dev/null"; then
1845     AC_MSG_ERROR('STATE DIRECTORY NOT FOUND! FIX OR SPECIFY --localstatedir!')
1846 fi
1847 AC_MSG_RESULT(${frr_statedir})
1848 AC_SUBST(frr_statedir)
1849
1850 AC_DEFINE_UNQUOTED(LDPD_SOCKET, "$frr_statedir/ldpd.sock",ldpd control socket)
1851 AC_DEFINE_UNQUOTED(ZEBRA_SERV_PATH, "$frr_statedir/zserv.api",zebra api socket)
1852 AC_DEFINE_UNQUOTED(DAEMON_VTY_DIR, "$frr_statedir",daemon vty directory)
1853
1854 dnl autoconf does this, but it does it too late...
1855 test "x$prefix" = xNONE && prefix=$ac_default_prefix
1856 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
1857
1858 dnl get the full path, recursing through variables...
1859 vtysh_bin="$bindir/vtysh"
1860 for I in 1 2 3 4 5 6 7 8 9 10; do
1861         eval vtysh_bin="\"$vtysh_bin\""
1862 done
1863 AC_DEFINE_UNQUOTED(VTYSH_BIN_PATH, "$vtysh_bin",path to vtysh binary)
1864
1865 CFG_SYSCONF="$sysconfdir"
1866 CFG_SBIN="$sbindir"
1867 CFG_STATE="$frr_statedir"
1868 CFG_MODULE="$moduledir"
1869 for I in 1 2 3 4 5 6 7 8 9 10; do
1870         eval CFG_SYSCONF="\"$CFG_SYSCONF\""
1871         eval CFG_SBIN="\"$CFG_SBIN\""
1872         eval CFG_STATE="\"$CFG_STATE\""
1873         eval CFG_MODULE="\"$CFG_MODULE\""
1874 done
1875 AC_SUBST(CFG_SYSCONF)
1876 AC_SUBST(CFG_SBIN)
1877 AC_SUBST(CFG_STATE)
1878 AC_SUBST(CFG_MODULE)
1879 AC_DEFINE_UNQUOTED(MODULE_PATH, "$CFG_MODULE", path to modules)
1880
1881 dnl ------------------------------------
1882 dnl Enable RPKI and add librtr to libs
1883 dnl ------------------------------------
1884 if test "${enable_rpki}" = "yes"; then
1885   PKG_CHECK_MODULES(RTRLIB,[rtrlib >= 0.5.0],
1886       [AC_DEFINE(HAVE_RPKI,1,Enable RPKI prefix validation for BGP)
1887       RPKI=true],
1888       [RPKI=false
1889       AC_MSG_ERROR([rtrlib was not found on your system or is too old.])]
1890   )
1891 fi
1892 AM_CONDITIONAL([RPKI], test "x$RPKI" = "xtrue")
1893
1894 dnl ------------------------------------------
1895 dnl Check whether rtrlib was build with ssh support
1896 dnl ------------------------------------------
1897 AC_MSG_CHECKING([whether the RTR Library is compiled with SSH])
1898 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "rtrlib/rtrlib.h"]],
1899                         [[struct tr_ssh_config config;]])],
1900         [AC_MSG_RESULT(yes)
1901         AC_DEFINE(FOUND_SSH,,found_ssh)],
1902         AC_MSG_RESULT(no)
1903 )
1904
1905 dnl ---------------------------
1906 dnl Check htonl works correctly
1907 dnl ---------------------------
1908 AC_MSG_CHECKING(for working htonl)
1909 AC_CACHE_VAL(ac_cv_htonl_works,
1910  [AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES],[htonl (0);])],
1911                 [ac_cv_htonl_works=yes], [ac_cv_htonl_works=no])
1912  ]
1913 )
1914 AC_MSG_RESULT($ac_cv_htonl_works)
1915
1916 AC_CONFIG_FILES([Makefile
1917           bgpd/Makefile
1918           vtysh/Makefile
1919           doc/Makefile
1920           doc/user/Makefile
1921           doc/manpages/Makefile
1922           doc/developer/Makefile
1923           tests/Makefile
1924           bgpd/rfp-example/rfptest/Makefile
1925           bgpd/rfp-example/librfp/Makefile
1926           redhat/frr.spec
1927           debianpkg/Makefile
1928           debianpkg/changelog
1929           alpine/APKBUILD
1930           snapcraft/snapcraft.yaml
1931           lib/version.h
1932           tests/lib/cli/test_cli.refout
1933           pkgsrc/bgpd.sh pkgsrc/ospf6d.sh pkgsrc/ospfd.sh
1934           pkgsrc/ripd.sh pkgsrc/ripngd.sh pkgsrc/zebra.sh
1935           pkgsrc/eigrpd.sh])
1936
1937 if test "${enable_bgp_vnc}" != "no"; then
1938    if test "${with_rfp_path}" != "bgpd/rfp-example" ; then
1939       AC_CONFIG_FILES([${with_rfp_path}/rfptest/Makefile ${with_rfp_path}/librfp/Makefile])
1940    fi
1941 fi
1942
1943 AC_CONFIG_FILES([solaris/Makefile])
1944
1945 AC_CONFIG_FILES([vtysh/extract.pl],[chmod +x vtysh/extract.pl])
1946
1947 AC_CONFIG_COMMANDS([lib/route_types.h], [
1948         dst="${ac_abs_top_builddir}/lib/route_types.h"
1949         ${PERL} "${ac_abs_top_srcdir}/lib/route_types.pl" \
1950                 < "${ac_abs_top_srcdir}/lib/route_types.txt" \
1951                 > "${dst}.tmp"
1952         test -f "${dst}" \
1953                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
1954                 && rm "${dst}.tmp" \
1955                 || mv "${dst}.tmp" "${dst}"
1956 ], [
1957         PERL="$PERL"
1958 ])
1959
1960 AS_IF([test "x$with_pkg_git_version" = "xyes"], [
1961     AC_CONFIG_COMMANDS([lib/gitversion.h], [
1962         dst="${ac_abs_top_builddir}/lib/gitversion.h"
1963         ${PERL} "${ac_abs_top_srcdir}/lib/gitversion.pl" \
1964                 "${ac_abs_top_srcdir}" \
1965                 > "${dst}.tmp"
1966         test -f "${dst}" \
1967                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
1968                 && rm "${dst}.tmp" \
1969                 || mv "${dst}.tmp" "${dst}"
1970     ], [
1971         PERL="$PERL"
1972     ])
1973 ])
1974
1975 ## Hack, but working solution to avoid rebuilding of frr.info.
1976 ## It's already in CVS until texinfo 4.7 is more common.
1977 AC_OUTPUT
1978
1979 echo "
1980 FRRouting configuration
1981 ------------------------------
1982 FRR version             : ${PACKAGE_VERSION}
1983 host operating system   : ${host_os}
1984 source code location    : ${srcdir}
1985 compiler                : ${CC}
1986 compiler flags          : ${CFLAGS}
1987 make                    : ${MAKE-make}
1988 linker flags            : ${LDFLAGS} ${LIBS} ${LIBCAP} ${LIBREADLINE} ${LIBM}
1989 state file directory    : ${frr_statedir}
1990 config file directory   : `eval echo \`echo ${sysconfdir}\``
1991 example directory       : `eval echo \`echo ${exampledir}\``
1992 module directory        : ${CFG_MODULE}
1993 user to run as          : ${enable_user}
1994 group to run as         : ${enable_group}
1995 group for vty sockets   : ${enable_vty_group}
1996 config file mask        : ${enable_configfile_mask}
1997 log file mask           : ${enable_logfile_mask}
1998 zebra protobuf enabled  : ${have_protobuf:-no}
1999
2000 The above user and group must have read/write access to the state file
2001 directory and to the config files in the config file directory."