configure.ac

   1 ##
   2 ## Configure template file for FRRouting.
   3 ## autoconf will generate a configure script.
   4 ##
   5 ##  Copyright (c) 1996, 97, 98, 99, 2000 Kunihiro Ishiguro <kunihiro@zebra.org>
   6 ##  Portions Copyright (c) 2003 Paul Jakma <paul@dishone.st>
   7 ##
   8 AC_PREREQ([2.60])
   9
  10 AC_INIT([frr], [7.2-dev], [https://github.com/frrouting/frr/issues])
  11 PACKAGE_URL="https://frrouting.org/"
  12 AC_SUBST([PACKAGE_URL])
  13 PACKAGE_FULLNAME="FRRouting"
  14 AC_SUBST([PACKAGE_FULLNAME])
  15
  16 CONFIG_ARGS="`echo $ac_configure_args | sed -e \"s% '[[A-Z]]*FLAGS=[[^']]\+'%%g\"`"
  17 AC_SUBST([CONFIG_ARGS])
  18
  19 AC_CONFIG_SRCDIR([lib/zebra.h])
  20 AC_CONFIG_MACRO_DIR([m4])
  21
  22 dnl -----------------------------------
  23 dnl Get hostname and other information.
  24 dnl -----------------------------------
  25 AC_CANONICAL_BUILD()
  26 AC_CANONICAL_HOST()
  27
  28 hosttools_clippy="false"
  29 build_clippy="true"
  30
  31 dnl case 1: external clippy
  32 if test -n "$with_clippy" -a "$with_clippy" != "no" -a "$with_clippy" != "yes"; then
  33   if test "$enable_clippy_only" == "yes"; then
  34     AC_MSG_ERROR([--enable-clippy-only does not make sense with --with-clippy])
  35   fi
  36
  37   CLIPPY="$with_clippy"
  38   build_clippy="false"
  39   if test ! -x "$with_clippy"; then
  40     AC_MSG_ERROR([clippy tool ($with_clippy) is not executable])
  41   fi
  42
  43 dnl case 2: cross-compiling internal clippy
  44 elif test "$host" != "$build"; then
  45   if test "$srcdir" = "."; then
  46     AC_MSG_ERROR([cross-compilation is only possible with builddir separate from srcdir or by building clippy separately and using the --with-clippy option.  create a separate directory and run as .../path-to-frr/configure.])
  47   fi
  48   test -d hosttools || mkdir hosttools
  49   abssrc="`cd \"${srcdir}\"; pwd`"
  50
  51   AC_MSG_NOTICE([...])
  52   AC_MSG_NOTICE([... cross-compilation: creating hosttools directory and self-configuring for build platform tools])
  53   AC_MSG_NOTICE([... use HOST_CPPFLAGS / HOST_CFLAGS / HOST_LDFLAGS if neccessary])
  54   AC_MSG_NOTICE([...])
  55
  56   (
  57     for var in $ac_precious_vars; do
  58       dnl special cases
  59       case "$var" in
  60       YACC|YFLAGS) continue;;
  61       PYTHON*)     retain=true;;
  62       *)           retain=false;
  63       esac
  64
  65       eval "hostvar=\"\${HOST_$var}\""
  66       eval "targetvar=\"\${$var}\""
  67       if test -n "$hostvar"; then
  68         eval "$var='$hostvar'"
  69         _AS_ECHO_LOG([host $var='$hostvar'])
  70       elif $retain; then
  71         _AS_ECHO_LOG([host retain $var='$targetvar'])
  72       else
  73         eval "unset $var"
  74         _AS_ECHO_LOG([host unset $var])
  75       fi
  76     done
  77     cd hosttools
  78     "${abssrc}/configure" "--host=$build" "--build=$build" "--enable-clippy-only" "--disable-nhrpd" "--disable-vtysh"
  79   ) || exit 1
  80
  81   AC_MSG_NOTICE([...])
  82   AC_MSG_NOTICE([... cross-compilation: finished self-configuring for build platform tools])
  83   AC_MSG_NOTICE([...])
  84
  85   build_clippy="false"
  86   hosttools_clippy="true"
  87   CLIPPY="hosttools/lib/clippy"
  88
  89 dnl case 3: normal build internal clippy
  90 else
  91   CLIPPY="lib/clippy\$(EXEEXT)"
  92 fi
  93 AC_SUBST([CLIPPY])
  94 AM_CONDITIONAL([BUILD_CLIPPY], [$build_clippy])
  95 AM_CONDITIONAL([HOSTTOOLS_CLIPPY], [$hosttools_clippy])
  96 AM_CONDITIONAL([ONLY_CLIPPY], [test "$enable_clippy_only" = "yes"])
  97
  98 # Disable portability warnings -- our automake code (in particular
  99 # common.am) uses some constructs specific to gmake.
 100 AM_INIT_AUTOMAKE([1.12 -Wno-portability foreign])
 101 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
 102 AM_SILENT_RULES([yes])
 103 AC_CONFIG_HEADERS([config.h])
 104
 105 AC_PATH_PROG([PERL], [perl])
 106 PKG_PROG_PKG_CONFIG
 107
 108 dnl default is to match previous behavior
 109 exampledir=${sysconfdir}
 110 AC_ARG_ENABLE([exampledir],
 111           AS_HELP_STRING([--enable-exampledir],
 112                          [specify alternate directory for examples]),
 113                          exampledir="$enableval",)
 114 dnl XXX add --exampledir to autoconf standard directory list somehow
 115 AC_SUBST([exampledir])
 116
 117 dnl default is to match previous behavior
 118 pkgsrcrcdir=""
 119 AC_ARG_ENABLE([pkgsrcrcdir],
 120           AS_HELP_STRING([--enable-pkgsrcrcdir],
 121                          [specify directory for rc.d scripts]),
 122                          pkgsrcrcdir="$enableval",)
 123 dnl XXX add --pkgsrcrcdir to autoconf standard directory list somehow
 124 AC_SUBST([pkgsrcrcdir])
 125 AM_CONDITIONAL([PKGSRC], [test "x$pkgsrcrcdir" != "x"])
 126
 127 AC_ARG_WITH([moduledir], [AS_HELP_STRING([--with-moduledir=DIR], [module directory (${libdir}/frr/modules)])], [
 128         moduledir="$withval"
 129 ], [
 130         moduledir="\${libdir}/frr/modules"
 131 ])
 132 AC_SUBST([moduledir], [$moduledir])
 133
 134
 135 AC_ARG_WITH([yangmodelsdir], [AS_HELP_STRING([--with-yangmodelsdir=DIR], [yang models directory (${datarootdir}/yang)])], [
 136         yangmodelsdir="$withval"
 137 ], [
 138         yangmodelsdir="\${datarootdir}/yang"
 139 ])
 140 AC_SUBST([yangmodelsdir])
 141
 142 AC_ARG_WITH([libyang_pluginsdir], [AS_HELP_STRING([--with-libyang-pluginsdir=DIR], [yangmodule plugins directory (${libdir}/frr/libyang_plugins)])], [
 143         libyang_pluginsdir="$withval"
 144 ], [
 145    libyang_pluginsdir="\${libdir}/frr/libyang_plugins"
 146 ])
 147 AC_SUBST([libyang_pluginsdir])
 148
 149 AC_ARG_ENABLE(tcmalloc,
 150         AS_HELP_STRING([--enable-tcmalloc], [Turn on tcmalloc]),
 151 [case "${enableval}" in
 152   yes) tcmalloc_enabled=true
 153 LIBS="$LIBS -ltcmalloc_minimal"
 154  ;;
 155   no)  tcmalloc_enabled=false ;;
 156   *) AC_MSG_ERROR([bad value ${enableval} for --enable-tcmalloc]) ;;
 157 esac],[tcmalloc_enabled=false])
 158
 159
 160 dnl Thanks autoconf, but we don't want a default -g -O2.  We have our own
 161 dnl flag determination logic.
 162 CFLAGS="${CFLAGS:-}"
 163
 164 dnl --------------------
 165 dnl Check CC and friends
 166 dnl --------------------
 167 dnl note orig_cflags is also used further down
 168 orig_cflags="$CFLAGS"
 169 orig_cxxflags="$CXXFLAGS"
 170 AC_LANG([C])
 171 AC_PROG_CC
 172 AC_PROG_CPP
 173 AC_PROG_CXX
 174 AM_PROG_CC_C_O
 175 dnl remove autoconf default "-g -O2"
 176 CFLAGS="$orig_cflags"
 177 CXXFLAGS="$orig_cxxflags"
 178 AC_PROG_CC_C99
 179 dnl NB: see C11 below
 180
 181 PKG_PROG_PKG_CONFIG
 182
 183 dnl it's 2019, sed is sed.
 184 SED=sed
 185 AC_SUBST([SED])
 186
 187 dnl try and enable CFLAGS that are useful for FRR
 188 dnl - specifically, options to control warnings
 189
 190 AC_USE_SYSTEM_EXTENSIONS
 191 AC_DEFUN([AC_C_FLAG], [{
 192     m4_pushdef([cachename],[m4_translit([frr_cv_$1],[ =-+],[____])])
 193     AC_CACHE_CHECK([[whether $CC supports $1]], cachename, [
 194         AC_LANG_PUSH([C])
 195         ac_c_flag_save="$CFLAGS"
 196         CFLAGS="$CFLAGS $1"
 197         AC_COMPILE_IFELSE(
 198                 [AC_LANG_PROGRAM([[]])],
 199                 [
 200                         cachename=yes
 201                 ], [
 202                         cachename=no
 203                 ])
 204         CFLAGS="$ac_c_flag_save"
 205         AC_LANG_POP([C])
 206     ])
 207     if test "${cachename}" = yes; then
 208         m4_if([$3], [], [CFLAGS="$CFLAGS $1"], [$3])
 209     else
 210         :
 211         $2
 212     fi
 213     m4_popdef([cachename])
 214 }])
 215
 216 AC_DEFUN([AC_LINK_IFELSE_FLAGS], [{
 217         AC_LANG_PUSH([C])
 218         ac_cflags_save="$CFLAGS"
 219         ac_libs_save="$LIBS"
 220         CFLAGS="$CFLAGS $1"
 221         LIBS="$LIBS $2"
 222         AC_LINK_IFELSE(
 223                 [$3],
 224                 [
 225                         CFLAGS="$ac_cflags_save"
 226                         LIBS="$ac_libs_save"
 227                         m4_default([$5], [
 228                                 AC_MSG_RESULT([yes])
 229                         ])
 230                 ], [
 231                         CFLAGS="$ac_cflags_save"
 232                         LIBS="$ac_libs_save"
 233                         m4_default([$4], [
 234                                 AC_MSG_RESULT([no])
 235                         ])
 236                 ])
 237         AC_LANG_POP([C])
 238         }])
 239
 240 dnl ICC won't bail on unknown options without -diag-error 10006
 241 dnl need to do this first so we get useful results for the other options
 242 AC_C_FLAG([-diag-error 10006])
 243
 244 dnl AC_PROG_CC_C99 may change CC to include -std=gnu99 or something
 245 ac_cc="$CC"
 246 CC="${CC% -std=gnu99}"
 247 CC="${CC% -std=c99}"
 248
 249 AC_C_FLAG([-std=gnu11], [CC="$ac_cc"], [CC="$CC -std=gnu11"])
 250
 251 dnl if the user has specified any CFLAGS, override our settings
 252 if test "x${enable_gcov}" = "xyes"; then
 253    if test "z$orig_cflags" = "z"; then
 254       AC_C_FLAG([-coverage])
 255       AC_C_FLAG([-O0])
 256    fi
 257
 258    LDFLAGS="${LDFLAGS} -lgcov"
 259 elif test "x${enable_dev_build}" = "xyes"; then
 260    AC_DEFINE([DEV_BUILD], [1], [Build for development])
 261    if test "z$orig_cflags" = "z"; then
 262       AC_C_FLAG([-g3])
 263       AC_C_FLAG([-O0])
 264    fi
 265    if test "x${enable_lua}" = "xyes"; then
 266       AX_PROG_LUA([5.3])
 267       AX_LUA_HEADERS
 268       AX_LUA_LIBS([
 269          AC_DEFINE([HAVE_LUA], [1], [Have support for Lua interpreter])
 270          LIBS="$LIBS $LUA_LIB"
 271       ])
 272    fi
 273 else
 274    if test "x${enable_lua}" = "xyes"; then
 275       AC_MSG_ERROR([Lua is not meant to be built/used outside of development at this time])
 276    fi
 277    if test "z$orig_cflags" = "z"; then
 278       AC_C_FLAG([-g])
 279       AC_C_FLAG([-O2])
 280    fi
 281 fi
 282 AM_CONDITIONAL([DEV_BUILD], [test "x$enable_dev_build" = "xyes"])
 283
 284 dnl always want these CFLAGS
 285 AC_C_FLAG([-fno-omit-frame-pointer])
 286 AC_C_FLAG([-funwind-tables])
 287 AC_C_FLAG([-Wall])
 288 AC_C_FLAG([-Wextra])
 289 AC_C_FLAG([-Wmissing-prototypes])
 290 AC_C_FLAG([-Wmissing-declarations])
 291 AC_C_FLAG([-Wpointer-arith])
 292 AC_C_FLAG([-Wbad-function-cast])
 293 AC_C_FLAG([-Wwrite-strings])
 294 if test x"${enable_gcc_ultra_verbose}" = x"yes" ; then
 295   AC_C_FLAG([-Wcast-qual])
 296   AC_C_FLAG([-Wstrict-prototypes])
 297   AC_C_FLAG([-Wmissing-noreturn])
 298   AC_C_FLAG([-Wmissing-format-attribute])
 299   AC_C_FLAG([-Wunreachable-code])
 300   AC_C_FLAG([-Wpacked])
 301   AC_C_FLAG([-Wpadded])
 302   AC_C_FLAG([-Wshadow])
 303 else
 304   AC_C_FLAG([-Wno-unused-result])
 305 fi
 306 AC_C_FLAG([-Wno-unused-parameter])
 307 AC_C_FLAG([-Wno-missing-field-initializers])
 308
 309 AC_C_FLAG([-Wc++-compat], [], [CXX_COMPAT_CFLAGS="-Wc++-compat"])
 310 AC_SUBST([CXX_COMPAT_CFLAGS])
 311
 312 dnl ICC emits a broken warning for const char *x = a ? "b" : "c";
 313 dnl for some reason the string consts get 'promoted' to char *,
 314 dnl triggering a const to non-const conversion warning.
 315 AC_C_FLAG([-diag-disable 3179])
 316
 317 if test x"${enable_werror}" = x"yes" ; then
 318   WERROR="-Werror"
 319 fi
 320 AC_SUBST([WERROR])
 321
 322 SAN_FLAGS=""
 323 if test "$enable_address_sanitizer" = "yes"; then
 324   AC_C_FLAG([-fsanitize=address], [
 325     AC_MSG_ERROR([$CC does not support Address Sanitizer.])
 326   ], [
 327     SAN_FLAGS="$SAN_FLAGS -fsanitize=address"
 328   ])
 329 fi
 330 if test "$enable_thread_sanitizer" = "yes"; then
 331   AC_C_FLAG([-fsanitize=thread], [
 332     AC_MSG_ERROR([$CC does not support Thread Sanitizer.])
 333   ], [
 334     SAN_FLAGS="$SAN_FLAGS -fsanitize=thread"
 335   ])
 336 fi
 337 if test "$enable_memory_sanitizer" = "yes"; then
 338   AC_C_FLAG([-fsanitize=thread -fPIE -pie], [
 339     AC_MSG_ERROR([$CC does not support Thread Sanitizer.])
 340   ], [
 341     SAN_FLAGS="-fsanitize=memory -fPIE -pie"
 342   ])
 343 fi
 344 AC_SUBST([SAN_FLAGS])
 345
 346 dnl ----------
 347 dnl Essentials
 348 dnl ----------
 349
 350 AX_PTHREAD([
 351   CC="$PTHREAD_CC"
 352   CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 353   LIBS="$PTHREAD_LIBS $LIBS"
 354 ], [
 355   AC_MSG_FAILURE([This FRR version needs pthreads])
 356 ])
 357
 358 AC_SEARCH_LIBS([pthread_condattr_setclock], [],
 359                 [frr_cv_pthread_condattr_setclock=yes],
 360                 [frr_cv_pthread_condattr_setclock=no])
 361 if test "$frr_cv_pthread_condattr_setclock" = yes; then
 362   AC_DEFINE([HAVE_PTHREAD_CONDATTR_SETCLOCK], [1], [Have pthread.h pthread_condattr_setclock])
 363 fi
 364
 365 dnl --------------
 366 dnl Check programs
 367 dnl --------------
 368 AC_PROG_INSTALL
 369 AC_PROG_LN_S
 370 AC_CHECK_TOOL([AR], [ar])
 371
 372 dnl -------
 373 dnl libtool
 374 dnl -------
 375 AC_ARG_ENABLE([static-bin],
 376   AS_HELP_STRING([--enable-static-bin], [link binaries statically]))
 377 LT_INIT
 378 _LT_CONFIG_LIBTOOL([
 379   patch -N -i "${srcdir}/m4/libtool-whole-archive.patch" libtool >&AS_MESSAGE_LOG_FD || \
 380     AC_MSG_WARN([Could not patch libtool for static linking support.  Loading modules into a statically linked daemon will fail.])
 381 ])
 382 if test "$enable_static_bin" = "yes"; then
 383   AC_LDFLAGS="-static"
 384   if test "$enable_static" != "yes"; then
 385     AC_MSG_ERROR([The --enable-static-bin option must be combined with --enable-static.])
 386   fi
 387 fi
 388 if test "$enable_shared" != "yes"; then
 389   AC_MSG_ERROR([FRR cannot be built with --disable-shared.  If you want statically linked daemons, use --enable-shared --enable-static --enable-static-bin])
 390 fi
 391 AC_SUBST([AC_LDFLAGS])
 392 AM_CONDITIONAL([STATIC_BIN], [test "x$enable_static_bin" = "xyes"])
 393
 394 dnl $AR and $RANLIB are set by LT_INIT above
 395 AC_MSG_CHECKING([whether $AR supports D option])
 396 if $AR crD conftest.a >/dev/null 2>/dev/null; then
 397   AC_MSG_RESULT([yes])
 398   dnl ARFLAGS is for automake, AR_FLAGS for libtool m-(
 399   ARFLAGS="crD"
 400   AR_FLAGS="crD"
 401 else
 402   AC_MSG_RESULT([no])
 403   ARFLAGS="cru"
 404   AR_FLAGS="cru"
 405 fi
 406 AC_SUBST([ARFLAGS])
 407 AC_SUBST([AR_FLAGS])
 408
 409 AC_MSG_CHECKING([whether $RANLIB supports D option])
 410 if $RANLIB -D conftest.a >/dev/null 2>/dev/null; then
 411   AC_MSG_RESULT([yes])
 412   RANLIB="$RANLIB -D"
 413 else
 414   AC_MSG_RESULT([no])
 415 fi
 416 AC_SUBST([RANLIB])
 417
 418 test -f conftest.a && rm conftest.a
 419
 420 dnl ----------------------
 421 dnl Packages configuration
 422 dnl ----------------------
 423 if test -f config.version; then
 424   . ./config.version
 425 elif test -f "${srcdir}/config.version"; then
 426   . "${srcdir}/config.version"
 427 fi
 428 AC_ARG_WITH([pkg-extra-version],
 429   AS_HELP_STRING([--with-pkg-extra-version=VER], [add extra version field, for packagers/distributions]), [
 430   if test "$withval" = "no"; then
 431     EXTRAVERSION=
 432   else
 433     EXTRAVERSION=$withval
 434   fi
 435 ], [])
 436 AC_ARG_WITH([pkg-git-version],
 437         AS_HELP_STRING([--with-pkg-git-version], [add git information to MOTD and build version string]),
 438         [ test "x$withval" != "xno" && with_pkg_git_version="yes" ])
 439 AC_ARG_WITH([clippy],
 440   AS_HELP_STRING([--with-clippy=PATH], [use external clippy helper program]))
 441 AC_ARG_WITH([vtysh_pager],
 442         AS_HELP_STRING([--with-vtysh-pager=PAGER], [control what pager is compiled in as default]),
 443         VTYSH_PAGER=$withval, VTYSH_PAGER="more")
 444 AC_ARG_ENABLE([vtysh],
 445   AS_HELP_STRING([--disable-vtysh], [do not build integrated vty shell for FRR]))
 446 AC_ARG_ENABLE([doc],
 447   AS_HELP_STRING([--disable-doc], [do not build docs]))
 448 AC_ARG_ENABLE([doc-html],
 449   AS_HELP_STRING([--enable-doc-html], [build HTML docs]))
 450 AC_ARG_ENABLE([zebra],
 451   AS_HELP_STRING([--disable-zebra], [do not build zebra daemon]))
 452 AC_ARG_ENABLE([bgpd],
 453   AS_HELP_STRING([--disable-bgpd], [do not build bgpd]))
 454 AC_ARG_ENABLE([ripd],
 455   AS_HELP_STRING([--disable-ripd], [do not build ripd]))
 456 AC_ARG_ENABLE([ripngd],
 457   AS_HELP_STRING([--disable-ripngd], [do not build ripngd]))
 458 AC_ARG_ENABLE([ospfd],
 459   AS_HELP_STRING([--disable-ospfd], [do not build ospfd]))
 460 AC_ARG_ENABLE([ospf6d],
 461   AS_HELP_STRING([--disable-ospf6d], [do not build ospf6d]))
 462 AC_ARG_ENABLE([ldpd],
 463   AS_HELP_STRING([--disable-ldpd], [do not build ldpd]))
 464 AC_ARG_ENABLE([nhrpd],
 465   AS_HELP_STRING([--disable-nhrpd], [do not build nhrpd]))
 466 AC_ARG_ENABLE([eigrpd],
 467   AS_HELP_STRING([--disable-eigrpd], [do not build eigrpd]))
 468 AC_ARG_ENABLE([babeld],
 469   AS_HELP_STRING([--disable-babeld], [do not build babeld]))
 470 AC_ARG_ENABLE([watchfrr],
 471   AS_HELP_STRING([--disable-watchfrr], [do not build watchfrr]))
 472 AC_ARG_ENABLE([isisd],
 473   AS_HELP_STRING([--disable-isisd], [do not build isisd]))
 474 AC_ARG_ENABLE([pimd],
 475   AS_HELP_STRING([--disable-pimd], [do not build pimd]))
 476 AC_ARG_ENABLE([pbrd],
 477   AS_HELP_STRING([--disable-pbrd], [do not build pbrd]))
 478 AC_ARG_ENABLE([sharpd],
 479   AS_HELP_STRING([--enable-sharpd], [build sharpd]))
 480 AC_ARG_ENABLE([staticd],
 481   AS_HELP_STRING([--disable-staticd], [do not build staticd]))
 482 AC_ARG_ENABLE([fabricd],
 483   AS_HELP_STRING([--disable-fabricd], [do not build fabricd]))
 484 AC_ARG_ENABLE([bgp-announce],
 485   AS_HELP_STRING([--disable-bgp-announce,], [turn off BGP route announcement]))
 486 AC_ARG_ENABLE([vrrpd],
 487   AS_HELP_STRING([--disable-vrrpd], [do not build vrrpd]))
 488 AC_ARG_ENABLE([bgp-vnc],
 489   AS_HELP_STRING([--disable-bgp-vnc],[turn off BGP VNC support]))
 490 AC_ARG_ENABLE([snmp],
 491   AS_HELP_STRING([--enable-snmp], [enable SNMP support for agentx]))
 492 AC_ARG_ENABLE([config_rollbacks],
 493   AS_HELP_STRING([--enable-config-rollbacks], [enable configuration rollbacks (requires sqlite3)]))
 494 AC_ARG_ENABLE([confd],
 495   AS_HELP_STRING([--enable-confd=ARG], [enable confd integration]))
 496 AC_ARG_ENABLE([sysrepo],
 497   AS_HELP_STRING([--enable-sysrepo], [enable sysrepo integration]))
 498 AC_ARG_ENABLE([grpc],
 499   AS_HELP_STRING([--enable-grpc], [enable the gRPC northbound plugin]))
 500 AC_ARG_ENABLE([zeromq],
 501   AS_HELP_STRING([--enable-zeromq], [enable ZeroMQ handler (libfrrzmq)]))
 502 AC_ARG_WITH([libpam],
 503   AS_HELP_STRING([--with-libpam], [use libpam for PAM support in vtysh]))
 504 AC_ARG_ENABLE([ospfapi],
 505   AS_HELP_STRING([--disable-ospfapi], [do not build OSPFAPI to access the OSPF LSA Database]))
 506 AC_ARG_ENABLE([ospfclient],
 507   AS_HELP_STRING([--disable-ospfclient], [do not build OSPFAPI client for OSPFAPI,
 508                           (this is the default if --disable-ospfapi is set)]))
 509 AC_ARG_ENABLE([multipath],
 510   AS_HELP_STRING([--enable-multipath=ARG], [enable multipath function, ARG must be digit]))
 511 AC_ARG_ENABLE([user],
 512   AS_HELP_STRING([--enable-user=USER], [user to run FRR suite as (default frr)]))
 513 AC_ARG_ENABLE([group],
 514   AS_HELP_STRING([--enable-group=GROUP], [group to run FRR suite as (default frr)]))
 515 AC_ARG_ENABLE([vty_group],
 516   AS_HELP_STRING([--enable-vty-group=ARG], [set vty sockets to have specified group as owner]))
 517 AC_ARG_ENABLE([configfile_mask],
 518   AS_HELP_STRING([--enable-configfile-mask=ARG], [set mask for config files]))
 519 AC_ARG_ENABLE([logfile_mask],
 520   AS_HELP_STRING([--enable-logfile-mask=ARG], [set mask for log files]))
 521 AC_ARG_ENABLE([shell_access],
 522   AS_HELP_STRING([--enable-shell-access], [Allow users to access shell/telnet/ssh]))
 523 AC_ARG_ENABLE([realms],
 524   AS_HELP_STRING([--enable-realms], [enable REALMS support under Linux]))
 525 AC_ARG_ENABLE([rtadv],
 526   AS_HELP_STRING([--disable-rtadv], [disable IPV6 router advertisement feature]))
 527 AC_ARG_ENABLE([irdp],
 528   AS_HELP_STRING([--disable-irdp], [enable IRDP server support in zebra (default if supported)]))
 529 AC_ARG_ENABLE([capabilities],
 530   AS_HELP_STRING([--disable-capabilities], [disable using POSIX capabilities]))
 531 AC_ARG_ENABLE([rusage],
 532   AS_HELP_STRING([--disable-rusage], [disable using getrusage]))
 533 AC_ARG_ENABLE([gcc_ultra_verbose],
 534   AS_HELP_STRING([--enable-gcc-ultra-verbose], [enable ultra verbose GCC warnings]))
 535 AC_ARG_ENABLE([backtrace],
 536   AS_HELP_STRING([--disable-backtrace,], [disable crash backtraces (default autodetect)]))
 537 AC_ARG_ENABLE([time-check],
 538   AS_HELP_STRING([--disable-time-check], [disable slow thread warning messages]))
 539 AC_ARG_ENABLE([pcreposix],
 540   AS_HELP_STRING([--enable-pcreposix], [enable using PCRE Posix libs for regex functions]))
 541 AC_ARG_ENABLE([fpm],
 542   AS_HELP_STRING([--enable-fpm], [enable Forwarding Plane Manager support]))
 543 AC_ARG_ENABLE([systemd],
 544   AS_HELP_STRING([--enable-systemd], [enable Systemd support]))
 545 AC_ARG_ENABLE([werror],
 546   AS_HELP_STRING([--enable-werror], [enable -Werror (recommended for developers only)]))
 547 AC_ARG_ENABLE([cumulus],
 548   AS_HELP_STRING([--enable-cumulus], [enable Cumulus Switch Special Extensions]))
 549 AC_ARG_ENABLE([datacenter],
 550   AS_HELP_STRING([--enable-datacenter], [enable Compilation for Data Center Extensions]))
 551 AC_ARG_ENABLE([fuzzing],
 552   AS_HELP_STRING([--enable-fuzzing], [enable ability to fuzz various parts of FRR]))
 553 AC_ARG_ENABLE([netlink_fuzzing],
 554   AS_HELP_STRING([--enable-netlink-fuzzing], [enable ability to fuzz netlink listening socket in zebra]))
 555 AC_ARG_ENABLE([rr-semantics],
 556   AS_HELP_STRING([--disable-rr-semantics], [disable the v6 Route Replace semantics]))
 557 AC_ARG_ENABLE([protobuf],
 558   AS_HELP_STRING([--enable-protobuf], [Enable experimental protobuf support]))
 559 AC_ARG_ENABLE([oldvpn_commands],
 560   AS_HELP_STRING([--enable-oldvpn-commands], [Keep old vpn commands]))
 561 AC_ARG_ENABLE([rpki],
 562   AS_HELP_STRING([--enable-rpki], [enable RPKI prefix validation support]))
 563 AC_ARG_ENABLE([clippy-only],
 564   AS_HELP_STRING([--enable-clippy-only], [Only build clippy]))
 565 AC_ARG_ENABLE([numeric_version],
 566   AS_HELP_STRING([--enable-numeric-version], [Only numeric digits allowed in version (for Alpine)]))
 567 AC_ARG_ENABLE([gcov],
 568   AS_HELP_STRING([--enable-gcov], [Add code coverage information]))
 569 AC_ARG_ENABLE([bfdd],
 570   AS_HELP_STRING([--disable-bfdd], [do not build bfdd]))
 571 AC_ARG_ENABLE([address-sanitizer],
 572   AS_HELP_STRING([--enable-address-sanitizer], [enable AddressSanitizer support for detecting a wide variety of memory allocation and deallocation errors]))
 573 AC_ARG_ENABLE([thread-sanitizer],
 574   AS_HELP_STRING([--enable-thread-sanitizer], [enable ThreadSanitizer support for detecting data races]))
 575 AC_ARG_ENABLE([memory-sanitizer],
 576   AS_HELP_STRING([--enable-memory-sanitizer], [enable MemorySanitizer support for detecting uninitialized memory reads]))
 577
 578 AS_IF([test "${enable_clippy_only}" != "yes"], [
 579 AC_CHECK_HEADERS([json-c/json.h])
 580 AC_CHECK_LIB([json-c], [json_object_get], [LIBS="$LIBS -ljson-c"], [], [-lm])
 581 if test "$ac_cv_lib_json_c_json_object_get" = no; then
 582   AC_CHECK_LIB([json], [json_object_get], [LIBS="$LIBS -ljson"])
 583   if test "$ac_cv_lib_json_json_object_get" = no; then
 584       AC_MSG_ERROR([libjson is needed to compile])
 585   fi
 586 fi
 587 ])
 588
 589 AC_ARG_ENABLE([dev_build],
 590     AS_HELP_STRING([--enable-dev-build], [build for development]))
 591
 592 AC_ARG_ENABLE([lua],
 593     AS_HELP_STRING([--enable-lua], [Build Lua scripting]))
 594
 595 if test x"${enable_time_check}" != x"no" ; then
 596   if test x"${enable_time_check}" = x"yes" -o x"${enable_time_check}" = x ; then
 597     AC_DEFINE([CONSUMED_TIME_CHECK], [5000000], [Consumed Time Check])
 598   else
 599     AC_DEFINE_UNQUOTED([CONSUMED_TIME_CHECK], [$enable_time_check], [Consumed Time Check])
 600   fi
 601 fi
 602
 603 case "${enable_systemd}" in
 604   "no") ;;
 605   "yes")
 606   AC_CHECK_LIB([systemd], [sd_notify], [LIBS="$LIBS -lsystemd"])
 607   if test $ac_cv_lib_systemd_sd_notify = no; then
 608     AC_MSG_ERROR([enable systemd has been specified but systemd development env not found on your system])
 609   else
 610     AC_DEFINE([HAVE_SYSTEMD], [1], [Compile systemd support in])
 611   fi
 612   ;;
 613   "*") ;;
 614 esac
 615
 616 if test "${enable_rr_semantics}" != "no" ; then
 617   AC_DEFINE([HAVE_V6_RR_SEMANTICS], [1], [Compile in v6 Route Replacement Semantics])
 618 fi
 619
 620 if test "${enable_datacenter}" = "yes" ; then
 621   AC_DEFINE([HAVE_DATACENTER], [1], [Compile extensions for a DataCenter])
 622   DFLT_NAME="datacenter"
 623 else
 624   DFLT_NAME="traditional"
 625 fi
 626
 627 if test "${enable_fuzzing}" = "yes" ; then
 628   AC_DEFINE([HANDLE_ZAPI_FUZZING], [1], [Compile extensions to use with a fuzzer])
 629 fi
 630
 631 if test "${enable_netlink_fuzzing}" = "yes" ; then
 632   AC_DEFINE([HANDLE_NETLINK_FUZZING], [1], [Compile extensions to use with a fuzzer for netlink])
 633 fi
 634
 635 if test "${enable_cumulus}" = "yes" ; then
 636   AC_DEFINE([HAVE_CUMULUS], [1], [Compile Special Cumulus Code in])
 637 fi
 638
 639 AC_SUBST([DFLT_NAME])
 640 AC_DEFINE_UNQUOTED([DFLT_NAME], ["$DFLT_NAME"], [Name of the configuration default set])
 641
 642 if test "${enable_shell_access}" = "yes"; then
 643    AC_DEFINE([HAVE_SHELL_ACCESS], [1], [Allow user to use ssh/telnet/bash, be aware this is considered insecure])
 644 fi
 645
 646 #
 647 # Python for clippy
 648 #
 649
 650 AS_IF([test "$host" = "$build"], [
 651   FRR_PYTHON_DEV
 652 ], [
 653   FRR_PYTHON
 654 ])
 655
 656 FRR_PYTHON_MODULES([pytest])
 657
 658 if test "${enable_doc}" != "no"; then
 659   FRR_PYTHON_MODULES([sphinx], , [
 660     if test "${enable_doc}" = "yes"; then
 661       AC_MSG_ERROR([Documentation was explicitly requested with --enable-doc but sphinx is not available for $PYTHON. Please disable docs or install sphinx.])
 662     fi
 663   ])
 664 fi
 665 AM_CONDITIONAL([DOC], [test "${enable_doc}" != "no" -a "$frr_py_mod_sphinx" != "false"])
 666 AM_CONDITIONAL([DOC_HTML], [test "${enable_doc_html}" = "yes"])
 667
 668 FRR_PYTHON_MOD_EXEC([sphinx], [--version], [
 669   PYSPHINX="-m sphinx"
 670 ], [
 671   PYSPHINX="-c 'import sys; from sphinx import main; sys.exit(main(sys.argv))'"
 672 ])
 673 AC_SUBST([PYSPHINX])
 674
 675 #
 676 # Logic for old vpn commands support.
 677 #
 678 if test "$enable_oldvpn_commands" = "yes"; then
 679    AC_DEFINE([KEEP_OLD_VPN_COMMANDS], [1], [Define for compiling with old vpn commands])
 680 fi
 681
 682 #
 683 # End of logic for protobuf support.
 684 #
 685
 686 AC_MSG_CHECKING([if zebra should be configurable to send Route Advertisements])
 687 if test "${enable_rtadv}" != "no"; then
 688   AC_MSG_RESULT([yes])
 689   AC_DEFINE([HAVE_RTADV], [1], [Enable IPv6 Routing Advertisement support])
 690 else
 691   AC_MSG_RESULT([no])
 692 fi
 693
 694 if test x"${enable_user}" = x"no"; then
 695   enable_user=""
 696 else
 697   if test x"${enable_user}" = x"yes" || test x"${enable_user}" = x""; then
 698     enable_user="frr"
 699   fi
 700   AC_DEFINE_UNQUOTED([FRR_USER], ["${enable_user}"], [frr User])
 701 fi
 702
 703 if test x"${enable_group}" = x"no"; then
 704   enable_group=""
 705 else
 706   if test x"${enable_group}" = x"yes" || test x"${enable_group}" = x""; then
 707     enable_group="frr"
 708   fi
 709   AC_DEFINE_UNQUOTED([FRR_GROUP], ["${enable_group}"], [frr Group])
 710 fi
 711
 712 if test x"${enable_vty_group}" = x"yes" ; then
 713   AC_MSG_ERROR([--enable-vty-group requires a group as argument, not yes])
 714 elif test x"${enable_vty_group}" != x""; then
 715   if test x"${enable_vty_group}" != x"no"; then
 716     AC_DEFINE_UNQUOTED([VTY_GROUP], ["${enable_vty_group}"], [VTY Sockets Group])
 717   fi
 718 fi
 719 AC_SUBST([enable_user])
 720 AC_SUBST([enable_group])
 721 AC_SUBST([enable_vty_group])
 722
 723 enable_configfile_mask=${enable_configfile_mask:-0600}
 724 AC_DEFINE_UNQUOTED([CONFIGFILE_MASK], [${enable_configfile_mask}], [Mask for config files])
 725
 726 enable_logfile_mask=${enable_logfile_mask:-0600}
 727 AC_DEFINE_UNQUOTED([LOGFILE_MASK], [${enable_logfile_mask}], [Mask for log files])
 728
 729 MPATH_NUM=16
 730
 731 case "${enable_multipath}" in
 732   0)
 733     MPATH_NUM=64
 734     ;;
 735   [[1-9]|[1-9][0-9]|[1-9][0-9][0-9]])
 736     MPATH_NUM="${enable_multipath}"
 737     ;;
 738   "")
 739     ;;
 740   *)
 741     AC_MSG_FAILURE([Please specify digit to enable multipath ARG])
 742     ;;
 743 esac
 744
 745 AC_DEFINE_UNQUOTED([MULTIPATH_NUM], [$MPATH_NUM], [Maximum number of paths for a route])
 746
 747 AC_DEFINE_UNQUOTED([VTYSH_PAGER], ["$VTYSH_PAGER"], [What pager to use])
 748
 749 dnl --------------------
 750 dnl Enable code coverage
 751 dnl --------------------
 752 AM_CONDITIONAL([HAVE_GCOV], [test '!' "$enable_gcov" = no])
 753
 754 dnl ------------------------------------
 755 dnl Alpine only accepts numeric versions
 756 dnl ------------------------------------
 757 if test "x${enable_numeric_version}" != "x" ; then
 758   VERSION="`echo ${VERSION} | tr -c -d '[[.0-9]]'`"
 759   PACKAGE_VERSION="`echo ${PACKAGE_VERSION} | tr -c -d '[[.0-9]]'`"
 760 fi
 761
 762 dnl -----------------------------------
 763 dnl Add extra version string to package
 764 dnl name, string and version fields.
 765 dnl -----------------------------------
 766 if test "x${EXTRAVERSION}" != "x" ; then
 767   VERSION="${VERSION}${EXTRAVERSION}"
 768   PACKAGE_VERSION="${PACKAGE_VERSION}${EXTRAVERSION}"
 769   AC_SUBST(PACKAGE_EXTRAVERSION, ["${EXTRAVERSION}"])
 770   PACKAGE_STRING="${PACKAGE_STRING}${EXTRAVERSION}"
 771 fi
 772 AC_SUBST([EXTRAVERSION])
 773
 774 if test "x$with_pkg_git_version" = "xyes"; then
 775         if test -d "${srcdir}/.git"; then
 776                 AC_DEFINE([GIT_VERSION], [1], [include git version info])
 777         else    with_pkg_git_version="no"
 778                 AC_MSG_WARN([--with-pkg-git-version given, but this is not a git checkout])
 779         fi
 780 fi
 781 AM_CONDITIONAL([GIT_VERSION], [test "x$with_pkg_git_version" = "xyes"])
 782
 783 AC_CHECK_TOOL([OBJCOPY], [objcopy], [:])
 784 if test "x${OBJCOPY}" != "x:"; then
 785   AC_CACHE_CHECK([for .interp value to use], [frr_cv_interp], [
 786     frr_cv_interp=""
 787     AC_LINK_IFELSE([AC_LANG_SOURCE([[int main() { return 0; }]])], [
 788       if $OBJCOPY -j.interp -Obinary conftest conftest.interp; then
 789         frr_cv_interp="`xargs -0 echo < conftest.interp`"
 790       fi
 791       test -f conftest.interp && rm conftest.interp
 792     ])
 793   ])
 794 fi
 795 if test -n "$frr_cv_interp"; then
 796   AC_DEFINE_UNQUOTED([INTERP], ["$frr_cv_interp"], [.interp value])
 797 fi
 798
 799 dnl -------------------------
 800 dnl Check other header files.
 801 dnl -------------------------
 802 AC_CHECK_HEADERS([stropts.h sys/ksym.h \
 803         linux/version.h asm/types.h])
 804
 805 ac_stdatomic_ok=false
 806 AC_DEFINE([FRR_AUTOCONF_ATOMIC], [1], [did autoconf checks for atomic funcs])
 807 AC_CHECK_HEADER([stdatomic.h],[
 808
 809   AC_MSG_CHECKING([whether _Atomic qualifier works])
 810   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 811 #include <stdatomic.h>
 812 int main(int argc, char **argv) {
 813   _Atomic int i = 0;
 814   return i;
 815 }
 816 ]])], [
 817     AC_DEFINE([HAVE_STDATOMIC_H], [1], [found stdatomic.h])
 818     AC_MSG_RESULT([yes])
 819     ac_stdatomic_ok=true
 820   ], [
 821     AC_MSG_RESULT([no])
 822   ])
 823 ])
 824
 825 AS_IF([$ac_stdatomic_ok], [true], [
 826   AC_MSG_CHECKING([for __atomic_* builtins])
 827   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 828 int main(int argc, char **argv) {
 829   volatile int i = 1;
 830   __atomic_store_n (&i, 0, __ATOMIC_RELEASE);
 831   return __atomic_load_n (&i, __ATOMIC_ACQUIRE);
 832 }
 833 ]])], [
 834     AC_DEFINE([HAVE___ATOMIC], [1], [found __atomic builtins])
 835     AC_MSG_RESULT([yes])
 836   ], [
 837     AC_MSG_RESULT([no])
 838
 839     dnl FreeBSD 9 has a broken stdatomic.h where _Atomic doesn't work
 840     AC_MSG_CHECKING([for __sync_* builtins])
 841     AC_LINK_IFELSE([AC_LANG_SOURCE([[
 842 int main(int argc, char **argv) {
 843   volatile int i = 1;
 844   __sync_fetch_and_sub (&i, 1);
 845   return __sync_val_compare_and_swap (&i, 0, 1);
 846 }
 847 ]])], [
 848       AC_DEFINE([HAVE___SYNC], [1], [found __sync builtins])
 849       AC_MSG_RESULT([yes])
 850
 851       AC_MSG_CHECKING([for __sync_swap builtin])
 852       AC_LINK_IFELSE([AC_LANG_SOURCE([[
 853 int main(int argc, char **argv) {
 854   volatile int i = 1;
 855   return __sync_swap (&i, 2);
 856 }
 857 ]])], [
 858         AC_DEFINE([HAVE___SYNC_SWAP], 1, [found __sync_swap builtin])
 859         AC_MSG_RESULT([yes])
 860       ], [
 861         AC_MSG_RESULT([no])
 862       ])
 863
 864     ], [
 865       AC_MSG_RESULT([no])
 866       AC_MSG_FAILURE([stdatomic.h unavailable and $CC has neither __atomic nor __sync builtins])
 867     ])
 868   ])
 869 ])
 870
 871 AC_CHECK_HEADERS([pthread_np.h],,, [
 872 #include <pthread.h>
 873 ])
 874 AC_CHECK_FUNCS([pthread_setname_np pthread_set_name_np])
 875
 876 needsync=true
 877
 878 AS_IF([$needsync], [
 879   dnl Linux
 880   AC_MSG_CHECKING([for Linux futex() support])
 881   AC_LINK_IFELSE([AC_LANG_PROGRAM([
 882 #ifndef _GNU_SOURCE
 883 #define _GNU_SOURCE
 884 #endif
 885 #include <unistd.h>
 886 #include <limits.h>
 887 #include <sys/time.h>
 888 #include <sys/syscall.h>
 889 #include <linux/futex.h>
 890
 891 int main(void);
 892 ],
 893 [
 894 {
 895   return syscall(SYS_futex, NULL, FUTEX_WAIT, 0, NULL, NULL, 0);
 896 }
 897 ])], [
 898     AC_MSG_RESULT([yes])
 899     AC_DEFINE(HAVE_SYNC_LINUX_FUTEX,,Have Linux futex support)
 900     needsync=false
 901   ], [
 902     AC_MSG_RESULT([no])
 903   ])
 904 ])
 905
 906 AS_IF([$needsync], [
 907   dnl FreeBSD
 908   AC_MSG_CHECKING([for FreeBSD _umtx_op() support])
 909   AC_LINK_IFELSE([AC_LANG_PROGRAM([
 910 #include <errno.h>
 911 #include <stdlib.h>
 912 #include <sys/types.h>
 913 #include <sys/umtx.h>
 914 int main(void);
 915 ],
 916 [
 917 {
 918   return _umtx_op(NULL, UMTX_OP_WAIT_UINT, 0, NULL, NULL);
 919 }
 920 ])], [
 921     AC_MSG_RESULT([yes])
 922     AC_DEFINE(HAVE_SYNC_UMTX_OP,,Have FreeBSD _umtx_op() support)
 923     needsync=false
 924   ], [
 925     AC_MSG_RESULT([no])
 926   ])
 927 ])
 928
 929 AS_IF([$needsync], [
 930   dnl OpenBSD patch (not upstream at the time of writing this)
 931   dnl https://marc.info/?l=openbsd-tech&m=147299508409549&w=2
 932   AC_MSG_CHECKING([for OpenBSD futex() support])
 933   AC_LINK_IFELSE([AC_LANG_PROGRAM([
 934 #include <sys/futex.h>
 935 int main(void);
 936 ],
 937 [
 938 {
 939   return futex(NULL, FUTEX_WAIT, 0, NULL, NULL, 0);
 940 }
 941 ])], [
 942     AC_MSG_RESULT([yes])
 943     AC_DEFINE(HAVE_SYNC_OPENBSD_FUTEX,,Have OpenBSD futex support)
 944     needsync=false
 945   ], [
 946     AC_MSG_RESULT([no])
 947   ])
 948 ])
 949
 950 dnl Utility macro to avoid retyping includes all the time
 951 m4_define([FRR_INCLUDES],
 952 [#ifdef SUNOS_5
 953 #define _POSIX_C_SOURCE 200809L
 954 #define __EXTENSIONS__
 955 #endif
 956 #include <stdio.h>
 957 #include <stdlib.h>
 958 #include <stddef.h>
 959 #include <sys/types.h>
 960 /* sys/conf.h depends on param.h on FBSD at least */
 961 #include <sys/param.h>
 962 /* Required for MAXSIG */
 963 #include <signal.h>
 964 #include <sys/socket.h>
 965 #ifdef __APPLE__
 966 # define __APPLE_USE_RFC_3542
 967 #endif
 968 #include <netinet/in.h>
 969 #include <sys/time.h>
 970 #include <time.h>
 971 #include <net/if.h>
 972 ])dnl
 973
 974 dnl Same applies for HAVE_NET_IF_VAR_H, which HAVE_NETINET6_ND6_H and
 975 dnl HAVE_NETINET_IN_VAR_H depend upon. But if_var.h depends on if.h, hence
 976 dnl an additional round for it.
 977
 978 AC_CHECK_HEADERS([net/if_var.h], [], [], [FRR_INCLUDES])
 979
 980 m4_define([FRR_INCLUDES],
 981 FRR_INCLUDES
 982 [#if HAVE_NET_IF_VAR_H
 983 # include <net/if_var.h>
 984 #endif
 985 ])dnl
 986
 987 AC_CHECK_HEADERS([netinet/in_var.h \
 988         net/if_dl.h net/netopt.h \
 989         inet/nd.h netinet/ip_icmp.h \
 990         sys/sysctl.h sys/sockio.h sys/conf.h],
 991         [], [], [FRR_INCLUDES])
 992
 993 AC_CHECK_HEADERS([ucontext.h], [], [],
 994 [#ifndef __USE_GNU
 995 #define __USE_GNU
 996 #endif /* __USE_GNU */
 997 FRR_INCLUDES
 998 ])
 999
1000 m4_define([UCONTEXT_INCLUDES],
1001 [#include <ucontext.h>])dnl
1002
1003 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.uc_regs],
1004   [], [], [UCONTEXT_INCLUDES])
1005 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs],
1006   [AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs.nip],
1007    [], [], [UCONTEXT_INCLUDES])],
1008   [], [UCONTEXT_INCLUDES])
1009 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.gregs],
1010   [], [], [UCONTEXT_INCLUDES])
1011
1012 m4_define([FRR_INCLUDES],
1013 FRR_INCLUDES
1014 [
1015 #include <sys/un.h>
1016 #include <netinet/in_systm.h>
1017 #if HAVE_NETINET_IN_VAR_H
1018 # include <netinet/in_var.h>
1019 #endif
1020 #if HAVE_NET_IF_DL_H
1021 # include <net/if_dl.h>
1022 #endif
1023 #if HAVE_NET_NETOPT_H
1024 # include <net/netopt.h>
1025 #endif
1026 #include <net/route.h>
1027 #if HAVE_INET_ND_H
1028 # include <inet/nd.h>
1029 #endif
1030 #include <arpa/inet.h>
1031 /* Required for IDRP */
1032 #if HAVE_NETINET_IP_ICMP_H
1033 # include <netinet/ip_icmp.h>
1034 #endif
1035 ])dnl
1036
1037 dnl V6 headers are checked below, after we check for v6
1038
1039 AC_MSG_CHECKING([which operating system interface to use])
1040 case "$host_os" in
1041   sunos* | solaris2*)
1042     AC_MSG_RESULT([Solaris])
1043
1044     AC_DEFINE([SUNOS_5], [1], [SunOS 5])
1045     AC_DEFINE([SOLARIS_IPV6], [1], Solaris IPv6)
1046     AC_DEFINE([_POSIX_C_SOURCE], [200809L], [enable POSIX.1-2008 and XPG7/SUSv4])
1047
1048     AC_CHECK_LIB([socket], [main])
1049     AC_CHECK_LIB([nsl], [main])
1050     AC_CHECK_LIB([umem], [main])
1051     SOLARIS="solaris"
1052     ;;
1053   linux*)
1054     AC_MSG_RESULT([Linux])
1055
1056     AC_DEFINE([GNU_LINUX], [1], [GNU Linux])
1057     AC_DEFINE([HAVE_NETLINK], [1], [netlink])
1058     AC_DEFINE([LINUX_IPV6], [1], [Linux IPv6 stack])
1059
1060     dnl Linux has a compilation problem with mixing
1061     dnl netinet/in.h and linux/in6.h they are not
1062     dnl compatible.  There has been discussion on
1063     dnl how to fix it but no real progress on implementation
1064     dnl when they fix it, remove this
1065     AC_DEFINE([IPV6_MINHOPCOUNT], [73], [Linux ipv6 Min Hop Count])
1066     ;;
1067   openbsd*)
1068     AC_MSG_RESULT([OpenBSD])
1069
1070     AC_DEFINE([OPEN_BSD], [1], [OpenBSD])
1071     AC_DEFINE([KAME], [1], [KAME IPv6])
1072     AC_DEFINE([BSD_V6_SYSCTL], [1], [BSD v6 sysctl to turn on and off forwarding])
1073
1074     if test "x${enable_pimd}" != "xno"; then
1075       case "$host_os" in
1076       openbsd6.0)
1077         ;;
1078       openbsd[6-9]*)
1079         AC_MSG_FAILURE([pimd cannot be enabled as PIM support has been removed from OpenBSD 6.1])
1080         ;;
1081       esac
1082     fi
1083     ;;
1084   *)
1085     AC_MSG_RESULT([BSD])
1086
1087     AC_DEFINE([HAVE_NET_RT_IFLIST], [1], [NET_RT_IFLIST])
1088     AC_DEFINE([KAME], [1], [KAME IPv6])
1089     AC_DEFINE([BSD_V6_SYSCTL], [1], [BSD v6 sysctl to turn on and off forwarding])
1090     ;;
1091 esac
1092 AM_CONDITIONAL([SOLARIS], [test "${SOLARIS}" = "solaris"])
1093
1094 AC_SYS_LARGEFILE
1095
1096 dnl ------------------------
1097 dnl Integrated REALMS option
1098 dnl ------------------------
1099 if test "${enable_realms}" = "yes"; then
1100     case "$host_os" in
1101       linux*)
1102        AC_DEFINE([SUPPORT_REALMS], [1], [Realms support])
1103        ;;
1104       *)
1105        echo "Sorry, only Linux has REALMS support"
1106        exit 1
1107        ;;
1108     esac
1109 fi
1110
1111 dnl -------------------------------
1112 dnl Endian-ness check
1113 dnl -------------------------------
1114 AC_WORDS_BIGENDIAN
1115
1116 dnl ---------------
1117 dnl other functions
1118 dnl ---------------
1119 AC_CHECK_FUNCS([ \
1120         strlcat strlcpy \
1121         getgrouplist])
1122
1123 dnl ##########################################################################
1124 dnl LARGE if block spans a lot of "configure"!
1125 if test "${enable_clippy_only}" != "yes"; then
1126 dnl ##########################################################################
1127
1128 #
1129 # Logic for protobuf support.
1130 #
1131 if test "$enable_protobuf" = "yes"; then
1132   # Check for protoc & protoc-c
1133
1134   # protoc is not required, it's only for a "be nice" helper target
1135   AC_CHECK_PROGS([PROTOC], [protoc], [/bin/false])
1136
1137   AC_CHECK_PROGS([PROTOC_C], [protoc-c], [/bin/false])
1138   if test "$PROTOC_C" = "/bin/false"; then
1139     AC_MSG_FAILURE([protobuf requested but protoc-c not found.  Install protobuf-c.])
1140   fi
1141
1142   PKG_CHECK_MODULES([PROTOBUF_C], [libprotobuf-c >= 0.14],, [
1143     AC_MSG_FAILURE([protobuf requested but libprotobuf-c not found.  Install protobuf-c.])
1144   ])
1145   AC_CHECK_HEADER([google/protobuf-c/protobuf-c.h], [], [
1146     AC_MSG_FAILURE([protobuf requested but protobuf-c.h not found.  Install protobuf-c.])
1147   ])
1148
1149   AC_DEFINE([HAVE_PROTOBUF], [1], [protobuf])
1150 fi
1151
1152
1153 dnl ---------------------
1154 dnl Integrated VTY option
1155 dnl ---------------------
1156 case "${enable_vtysh}" in
1157 "no")
1158   VTYSH="";;
1159 *)
1160   VTYSH="vtysh";
1161   AC_DEFINE([VTYSH], [1], [VTY shell])
1162
1163   prev_libs="$LIBS"
1164   AC_CHECK_LIB([readline], [main], [
1165     LIBREADLINE="-lreadline"
1166   ], [
1167     dnl readline failed - it might be incorrectly linked and missing its
1168     dnl termcap/tinfo/curses dependency.  see if we can fix that...
1169     AC_SEARCH_LIBS([tputs], [termcap tinfo curses ncurses], [
1170       LIBREADLINE="$ac_cv_search_tputs"
1171     ], [
1172       AC_MSG_ERROR([libreadline (needed for vtysh) not found and/or missing dependencies])
1173     ])
1174
1175     dnl re-try with the lib we found above
1176     unset ac_cv_lib_readline_main
1177     AC_CHECK_LIB([readline], [main], [
1178       LIBREADLINE="-lreadline $LIBREADLINE"
1179     ], [
1180       AC_MSG_ERROR([libreadline (needed for vtysh) not found and/or missing dependencies])
1181     ], [$LIBREADLINE])
1182   ], [])
1183   LIBS="$prev_libs"
1184
1185   AC_CHECK_HEADER([readline/history.h])
1186   if test $ac_cv_header_readline_history_h = no;then
1187     AC_MSG_ERROR([readline is too old to have readline/history.h, please update to the latest readline library.])
1188   fi
1189   AC_CHECK_LIB([readline], [rl_completion_matches], [true], [], [$LIBREADLINE])
1190   if test $ac_cv_lib_readline_rl_completion_matches = no; then
1191     AC_DEFINE([rl_completion_matches], [completion_matches], [Old readline])
1192   fi
1193   AC_CHECK_LIB([readline], [append_history], [frr_cv_append_history=yes], [frr_cv_append_history=no], [$LIBREADLINE])
1194   if test "$frr_cv_append_history" = yes; then
1195     AC_DEFINE([HAVE_APPEND_HISTORY], [1], [Have history.h append_history])
1196   fi
1197   ;;
1198 esac
1199 AC_SUBST([LIBREADLINE])
1200
1201 dnl ----------
1202 dnl PAM module
1203 dnl
1204 dnl FRR detects the PAM library it is built against by checking for a
1205 dnl functional pam_misc.h (Linux-PAM) or openpam.h (OpenPAM) header. pam_misc.h
1206 dnl is known to #include pam_appl.h, the standard header of a PAM library, and
1207 dnl openpam.h doesn't do that, although depends on the header too. Hence a
1208 dnl little assistance to AC_CHECK_HEADER is necessary for the proper detection
1209 dnl of OpenPAM.
1210 dnl ----------
1211 if test "$with_libpam" = "yes"; then
1212   AC_CHECK_HEADER([security/pam_misc.h],
1213     [AC_DEFINE([HAVE_PAM_MISC_H], [1], [Have pam_misc.h])
1214      AC_DEFINE([PAM_CONV_FUNC], [misc_conv], [Have misc_conv])
1215      pam_conv_func="misc_conv"
1216     ],
1217     [], FRR_INCLUDES)
1218   AC_CHECK_HEADER([security/openpam.h],
1219     [AC_DEFINE([HAVE_OPENPAM_H], [1], [Have openpam.h])
1220      AC_DEFINE([PAM_CONV_FUNC], [openpam_ttyconv], [Have openpam_ttyconv])
1221      pam_conv_func="openpam_ttyconv"
1222     ],
1223     [], FRR_INCLUDES[#include <security/pam_appl.h>])
1224   if test -z "$ac_cv_header_security_pam_misc_h$ac_cv_header_security_openpam_h" ; then
1225     AC_MSG_WARN([*** pam support will not be built ***])
1226     with_libpam="no"
1227   fi
1228 fi
1229
1230 if test "$with_libpam" = "yes"; then
1231 dnl took this test from proftpds configure.in and suited to our needs
1232 dnl -------------------------------------------------------------------------
1233 dnl
1234 dnl This next check looks funky due to a linker problem with some versions
1235 dnl of the PAM library.  Prior to 0.72 release, the Linux PAM shared library
1236 dnl omitted requiring libdl linking information. PAM-0.72 or better ships
1237 dnl with RedHat 6.2 and Debian 2.2 or better.
1238 AC_CHECK_LIB([pam], [pam_start],
1239   [AC_CHECK_LIB([pam], [$pam_conv_func],
1240     [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1241      LIBPAM="-lpam"],
1242     [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1243      LIBPAM="-lpam -lpam_misc"]
1244     )
1245   ],
1246
1247   [AC_CHECK_LIB([pam], [pam_end],
1248     [AC_CHECK_LIB([pam], [$pam_conv_func],
1249       [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1250        LIBPAM="-lpam -ldl"],
1251       [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1252        LIBPAM="-lpam -ldl -lpam_misc"]
1253      )
1254   ],AC_MSG_WARN([*** pam support will not be built ***]),
1255   [-ldl])
1256   ]
1257 )
1258 fi
1259 AC_SUBST([LIBPAM])
1260
1261 dnl -------------------------------
1262 dnl bgpd needs pow() and hence libm
1263 dnl -------------------------------
1264 TMPLIBS="$LIBS"
1265 LIBS=""
1266 AC_SEARCH_LIBS([pow], [m], [
1267   LIBM="$LIBS"
1268 ], [
1269   AC_MSG_WARN([Unable to find working pow function - bgpd may not link])
1270 ])
1271 LIBS="$TMPLIBS"
1272 AC_SUBST([LIBM])
1273
1274 AC_CHECK_FUNCS([ppoll], [
1275   AC_DEFINE([HAVE_PPOLL], [1], [have Linux/BSD ppoll()])
1276 ])
1277 AC_CHECK_FUNCS([pollts], [
1278   AC_DEFINE([HAVE_POLLTS], [1], [have NetBSD pollts()])
1279 ])
1280
1281 AC_CHECK_HEADER([asm-generic/unistd.h],
1282                 [AC_CHECK_DECL(__NR_setns,
1283                                AC_DEFINE([HAVE_NETNS], [1], [Have netns]),,
1284                                FRR_INCLUDES [#include <asm-generic/unistd.h>
1285                                ])
1286                  AC_CHECK_FUNCS([setns])]
1287                )
1288
1289 dnl --------------------------
1290 dnl Determine IS-IS I/O method
1291 dnl --------------------------
1292 AC_DEFINE([ISIS_METHOD_PFPACKET], [1], [constant value for isis method pfpacket])
1293 AC_DEFINE([ISIS_METHOD_DLPI], [2], [constant value for isis method dlpi])
1294 AC_DEFINE([ISIS_METHOD_BPF], [3], [constant value for isis method bpf])
1295 AC_CHECK_HEADER([net/bpf.h])
1296 AC_CHECK_HEADER([sys/dlpi.h])
1297 AC_MSG_CHECKING([zebra IS-IS I/O method])
1298
1299 case "$host_os" in
1300   linux*)
1301     AC_MSG_RESULT([pfpacket])
1302     ISIS_METHOD_MACRO="ISIS_METHOD_PFPACKET"
1303     ;;
1304   solaris* | sunos*)
1305     AC_MSG_RESULT([DLPI])
1306     ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1307     ;;
1308   *)
1309     if test $ac_cv_header_net_bpf_h = no; then
1310       if test $ac_cv_header_sys_dlpi_h = no; then
1311         AC_MSG_RESULT([none])
1312         if test "${enable_isisd}" = yes -o "${enable_fabricd}" = yes; then
1313           AC_MSG_FAILURE([IS-IS support requested but no packet backend found])
1314         fi
1315         AC_MSG_WARN([*** IS-IS support will not be built ***])
1316         enable_isisd="no"
1317         enable_fabricd="no"
1318       else
1319         AC_MSG_RESULT([DLPI])
1320       fi
1321       ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1322     else
1323       AC_MSG_RESULT([BPF])
1324       ISIS_METHOD_MACRO="ISIS_METHOD_BPF"
1325     fi
1326     ;;
1327 esac
1328 AC_DEFINE_UNQUOTED([ISIS_METHOD], [$ISIS_METHOD_MACRO], [selected method for isis, == one of the constants])
1329
1330 dnl ---------------------------------------------------------------
1331 dnl figure out how to specify an interface in multicast sockets API
1332 dnl ---------------------------------------------------------------
1333 AC_CHECK_MEMBERS([struct ip_mreqn.imr_ifindex], [], [], FRR_INCLUDES)
1334
1335 AC_CHECK_HEADERS([linux/mroute.h], [], [],[
1336         #include <sys/socket.h>
1337         #include <netinet/in.h>
1338         #define _LINUX_IN_H             /* For Linux <= 2.6.25 */
1339         #include <linux/types.h>
1340 ])
1341
1342 m4_define([FRR_INCLUDES],
1343 FRR_INCLUDES
1344 [#if HAVE_LINUX_MROUTE_H
1345 # include <linux/mroute.h>
1346 #endif
1347 ])dnl
1348
1349 AC_CHECK_HEADERS([netinet/ip_mroute.h], [], [],[
1350         #include <sys/socket.h>
1351         #include <sys/types.h>
1352         #include <netinet/in.h>
1353         #include <net/route.h>
1354 ])
1355
1356 m4_define([FRR_INCLUDES],
1357 FRR_INCLUDES
1358 [#if HAVE_NETINET_IP_MROUTE_H
1359 # include <netinet/ip_mroute.h>
1360 #endif
1361 ])dnl
1362
1363 AC_MSG_CHECKING([for BSD struct ip_mreq hack])
1364 AC_TRY_COMPILE([#include <sys/param.h>],
1365 [#if (defined(__FreeBSD__) && ((__FreeBSD_version >= 500022 && __FreeBSD_version < 700000) || (__FreeBSD_version < 500000 && __FreeBSD_version >= 440000))) || (defined(__NetBSD__) && defined(__NetBSD_Version__) && __NetBSD_Version__ >= 106010000) || defined(__OpenBSD__) || defined(__APPLE__) || defined(__DragonFly__) || defined(__sun)
1366   return (0);
1367 #else
1368   #error No support for BSD struct ip_mreq hack detected
1369 #endif],[AC_MSG_RESULT([yes])
1370 AC_DEFINE([HAVE_BSD_STRUCT_IP_MREQ_HACK], [1], [Can pass ifindex in struct ip_mreq])],
1371 AC_MSG_RESULT([no]))
1372
1373 AC_MSG_CHECKING([for RFC3678 protocol-independed API])
1374 AC_TRY_COMPILE([
1375 #include <sys/types.h>
1376 #include <netinet/in.h>
1377 ], [struct group_req gr; int sock; setsockopt(sock, IPPROTO_IP, MCAST_JOIN_GROUP, (void*)&gr, sizeof(gr));
1378 ], [AC_MSG_RESULT([yes])
1379 AC_DEFINE([HAVE_RFC3678], [1], [Have RFC3678 protocol-independed API])],
1380 AC_MSG_RESULT([no]))
1381
1382 dnl ---------------------------------------------------------------
1383 dnl figure out how to check link-state
1384 dnl ---------------------------------------------------------------
1385 AC_CHECK_HEADER([net/if_media.h],
1386   [m4_define([LINK_DETECT_INCLUDES],
1387     FRR_INCLUDES
1388     [#include <net/if_media.h>
1389   ])
1390   AC_CHECK_MEMBERS([struct ifmediareq.ifm_status],
1391     AC_DEFINE([HAVE_BSD_LINK_DETECT], [1], [BSD link-detect]),
1392     [], LINK_DETECT_INCLUDES)],
1393   [],
1394   FRR_INCLUDES)
1395
1396 dnl ---------------------------------------------------------------
1397 dnl Additional, newer way to check link-state using ifi_link_state.
1398 dnl Not available in all BSD's when ifmediareq available
1399 dnl ---------------------------------------------------------------
1400 AC_CHECK_MEMBERS([struct if_data.ifi_link_state],
1401   AC_DEFINE([HAVE_BSD_IFI_LINK_STATE], [1], [BSD ifi_link_state available]),
1402   [], FRR_INCLUDES)
1403
1404 dnl ------------------------
1405 dnl TCP_MD5SIG socket option
1406 dnl ------------------------
1407
1408 AC_CHECK_HEADER([netinet/tcp.h],
1409    [m4_define([MD5_INCLUDES],
1410       FRR_INCLUDES
1411       [#include <netinet/tcp.h>
1412     ])
1413     AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)],
1414    [],
1415    FRR_INCLUDES)
1416 if test $ac_cv_have_decl_TCP_MD5SIG = no; then
1417   AC_CHECK_HEADER([linux/tcp.h],
1418        [m4_define([MD5_INCLUDES],
1419           FRR_INCLUDES
1420           [#include <linux/tcp.h>
1421         ])
1422        AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)])
1423 fi
1424
1425 AC_SUBST([SOLARIS])
1426 AC_CHECK_LIB([crypt], [crypt], [],
1427                     [AC_CHECK_LIB([crypto], [DES_crypt])])
1428 AC_CHECK_LIB([resolv], [res_init])
1429
1430 dnl ---------------------------
1431 dnl check system has PCRE regexp
1432 dnl ---------------------------
1433 if test "x$enable_pcreposix" = "xyes"; then
1434   AC_CHECK_LIB([pcreposix], [regexec], [], [
1435     AC_MSG_ERROR([--enable-pcreposix given but unable to find libpcreposix])
1436   ])
1437 fi
1438 AC_SUBST([HAVE_LIBPCREPOSIX])
1439
1440 dnl ##########################################################################
1441 dnl test "${enable_clippy_only}" != "yes"
1442 fi
1443 dnl END OF LARGE if block
1444 dnl ##########################################################################
1445
1446
1447 dnl ----------------------------------------------------------------------------
1448 dnl figure out if domainname is available in the utsname struct (GNU extension).
1449 dnl ----------------------------------------------------------------------------
1450 AC_CHECK_MEMBERS([struct utsname.domainname], [], [], [#include <sys/utsname.h>])
1451
1452 dnl ------------------
1453 dnl IPv6 header checks
1454 dnl ------------------
1455 AC_CHECK_HEADERS([netinet6/in6.h netinet/in6_var.h \
1456         netinet6/in6_var.h netinet6/nd6.h], [], [],
1457         FRR_INCLUDES)
1458
1459 m4_define([FRR_INCLUDES],dnl
1460 FRR_INCLUDES
1461 [#if HAVE_NETINET6_IN6_H
1462 #include <netinet6/in6.h>
1463 #endif
1464 #if HAVE_NETINET_IN6_VAR_H
1465 #include <netinet/in6_var.h>
1466 #endif
1467 #include <netinet/icmp6.h>
1468 #if HAVE_NETINET6_IN6_VAR_H
1469 # include <netinet6/in6_var.h>
1470 #endif
1471 #if HAVE_NETINET6_ND6_H
1472 # include <netinet6/nd6.h>
1473 #endif
1474 ])dnl
1475
1476 dnl --------------------
1477 dnl Daemon disable check
1478 dnl --------------------
1479
1480 AS_IF([test "${enable_ldpd}" != "no"], [
1481   AC_DEFINE([HAVE_LDPD], [1], [ldpd])
1482 ])
1483
1484 if test "$enable_bfdd" = "no"; then
1485   AC_DEFINE([HAVE_BFDD], [0], [bfdd])
1486   BFDD=""
1487 else
1488   AC_DEFINE([HAVE_BFDD], [1], [bfdd])
1489   BFDD="bfdd"
1490
1491   case $host_os in
1492     linux*)
1493       AC_DEFINE([BFD_LINUX], [1], [bfdd])
1494       ;;
1495
1496     *)
1497       AC_DEFINE([BFD_BSD], [1], [bfdd])
1498       ;;
1499   esac
1500 fi
1501
1502 if test "$ac_cv_lib_json_c_json_object_get" = no -a "x$BFDD" = "xbfdd"; then
1503   AC_MSG_ERROR(["you must use json-c library to use bfdd"])
1504 fi
1505
1506 NHRPD=""
1507 case "$host_os" in
1508   linux*)
1509     if test "${enable_nhrpd}" != "no"; then
1510       NHRPD="nhrpd"
1511     fi
1512     ;;
1513   *)
1514     if test "${enable_nhrpd}" = "yes"; then
1515       AC_MSG_ERROR([nhrpd requires kernel APIs that are only present on Linux.])
1516     fi
1517     ;;
1518 esac
1519
1520 if test "${enable_watchfrr}" = "no";then
1521   WATCHFRR=""
1522 else
1523   WATCHFRR="watchfrr"
1524 fi
1525
1526 OSPFCLIENT=""
1527 if test "${enable_ospfapi}" != "no";then
1528     AC_DEFINE([SUPPORT_OSPF_API], [1], [OSPFAPI])
1529
1530   if test "${enable_ospfclient}" != "no";then
1531       OSPFCLIENT="ospfclient"
1532   fi
1533 fi
1534
1535 if test "${enable_bgp_announce}" = "no";then
1536   AC_DEFINE([DISABLE_BGP_ANNOUNCE], [1], [Disable BGP installation to zebra])
1537 else
1538   AC_DEFINE([DISABLE_BGP_ANNOUNCE], [0], [Disable BGP installation to zebra])
1539 fi
1540
1541 if test "${enable_bgp_vnc}" != "no";then
1542   AC_DEFINE([ENABLE_BGP_VNC], [1], [Enable BGP VNC support])
1543 fi
1544
1545 dnl ##########################################################################
1546 dnl LARGE if block
1547 if test "${enable_clippy_only}" != "yes"; then
1548 dnl ##########################################################################
1549
1550 dnl ------------------
1551 dnl check C-Ares library
1552 dnl ------------------
1553 if test "${NHRPD}" != ""; then
1554   PKG_CHECK_MODULES([CARES], [libcares], ,[
1555     AC_MSG_ERROR([trying to build nhrpd, but libcares not found. install c-ares and its -dev headers.])
1556   ])
1557 fi
1558
1559
1560 dnl ------------------
1561 dnl check Net-SNMP library
1562 dnl ------------------
1563 if test "${enable_snmp}" != "" -a "${enable_snmp}" != "no"; then
1564    AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], [no])
1565    if test x"$NETSNMP_CONFIG" = x"no"; then
1566       AC_MSG_ERROR([--enable-snmp given but unable to find net-snmp-config])
1567    fi
1568    SNMP_LIBS="`${NETSNMP_CONFIG} --agent-libs`"
1569    SNMP_CFLAGS="`${NETSNMP_CONFIG} --base-cflags`"
1570    # net-snmp lists all of its own dependencies.  we absolutely do not want that
1571    # among other things we avoid a GPL vs. OpenSSL license conflict here
1572    for removelib in crypto ssl sensors pci wrap; do
1573      SNMP_LIBS="`echo $SNMP_LIBS | sed -e 's/\(^\|\s\)-l'$removelib'\b/ /g' -e 's/\(^\|\s\)\([^\s]*\/\)\?lib'$removelib'\.[^\s]\+\b/ /g'`"
1574    done
1575    AC_MSG_CHECKING([whether we can link to Net-SNMP])
1576    AC_LINK_IFELSE_FLAGS([$SNMP_CFLAGS], [$SNMP_LIBS], [AC_LANG_PROGRAM([
1577 int main(void);
1578 ],
1579 [
1580 {
1581   return 0;
1582 }
1583 ])], [
1584      AC_MSG_RESULT([no])
1585      AC_MSG_ERROR([--enable-snmp given but not usable])])
1586    case "${enable_snmp}" in
1587      yes)
1588       SNMP_METHOD=agentx
1589       ;;
1590      agentx)
1591       SNMP_METHOD="${enable_snmp}"
1592       ;;
1593      *)
1594       AC_MSG_ERROR([--enable-snmp given with an unknown method (${enable_snmp}). Use yes or agentx])
1595       ;;
1596    esac
1597    AH_TEMPLATE([SNMP_AGENTX], [Use SNMP AgentX to interface with snmpd])
1598    AC_DEFINE_UNQUOTED(AS_TR_CPP(SNMP_${SNMP_METHOD}),,[SNMP method to interface with snmpd])
1599 fi
1600 AC_SUBST([SNMP_LIBS])
1601 AC_SUBST([SNMP_CFLAGS])
1602
1603 dnl ---------------
1604 dnl libyang
1605 dnl ---------------
1606 PKG_CHECK_MODULES([LIBYANG], [libyang >= 0.16.7], , [
1607   AC_MSG_ERROR([libyang (>= 0.16.7) was not found on your system.])
1608 ])
1609 ac_cflags_save="$CFLAGS"
1610 CFLAGS="$CFLAGS $LIBYANG_CFLAGS"
1611 AC_CHECK_MEMBER([struct lyd_node.priv], [], [
1612   AC_MSG_ERROR([m4_normalize([
1613     libyang needs to be compiled with ENABLE_LYD_PRIV=ON.
1614     Instructions for this are included in the build documentation for your platform at http://docs.frrouting.org/projects/dev-guide/en/latest/building.html])
1615   ])
1616 ], [[#include <libyang/libyang.h>]])
1617 CFLAGS="$ac_cflags_save"
1618
1619 dnl ---------------
1620 dnl configuration rollbacks
1621 dnl ---------------
1622 SQLITE3=false
1623 if test "$enable_config_rollbacks" = "yes"; then
1624   PKG_CHECK_MODULES([SQLITE3], [sqlite3], [
1625     AC_DEFINE([HAVE_CONFIG_ROLLBACKS], [1], [Enable configuration rollbacks])
1626     AC_DEFINE([HAVE_SQLITE3], [1], [Enable sqlite3 database])
1627     SQLITE3=true
1628   ], [
1629     AC_MSG_ERROR([--enable-config-rollbacks given but sqlite3 was not found on your system.])
1630   ])
1631 fi
1632
1633 dnl ---------------
1634 dnl confd
1635 dnl ---------------
1636 if test "$enable_confd" != "" -a "$enable_confd" != "no"; then
1637    AC_CHECK_PROG([CONFD], [confd], [confd], [/bin/false], "${enable_confd}/bin")
1638    if test "x$CONFD" = "x/bin/false"; then
1639       AC_MSG_ERROR([confd was not found on your system.])]
1640    fi
1641    CONFD_CFLAGS="-I${enable_confd}/include -L${enable_confd}/lib"
1642    AC_SUBST([CONFD_CFLAGS])
1643    CONFD_LIBS="-lconfd"
1644    AC_SUBST([CONFD_LIBS])
1645    AC_DEFINE([HAVE_CONFD], [1], [Enable confd integration])
1646 fi
1647
1648 dnl ---------------
1649 dnl sysrepo
1650 dnl ---------------
1651 if test "$enable_sysrepo" = "yes"; then
1652   PKG_CHECK_MODULES([SYSREPO], [libsysrepo],
1653       [AC_DEFINE([HAVE_SYSREPO], [1], [Enable sysrepo integration])
1654       SYSREPO=true],
1655       [SYSREPO=false
1656       AC_MSG_ERROR([sysrepo was not found on your system.])]
1657   )
1658 fi
1659
1660 dnl ---------------
1661 dnl gRPC
1662 dnl ---------------
1663 if test "$enable_grpc" = "yes"; then
1664   PKG_CHECK_MODULES([GRPC], [grpc grpc++ protobuf], [
1665     AC_CHECK_PROGS([PROTOC], [protoc], [/bin/false])
1666     if test "$PROTOC" = "/bin/false"; then
1667       AC_MSG_FAILURE([grpc requested but protoc not found.])
1668     fi
1669
1670     AC_DEFINE([HAVE_GRPC], [1], [Enable the gRPC northbound plugin])
1671     GRPC=true
1672   ], [
1673     GRPC=false
1674     AC_MSG_ERROR([grpc/grpc++ were not found on your system.])
1675   ])
1676 fi
1677
1678 dnl ------
1679 dnl ZeroMQ
1680 dnl ------
1681 if test "x$enable_zeromq" != "xno"; then
1682   PKG_CHECK_MODULES([ZEROMQ], [libzmq >= 4.0.0], [
1683     AC_DEFINE([HAVE_ZEROMQ], [1], [Enable ZeroMQ support])
1684     ZEROMQ=true
1685   ], [
1686     if test "x$enable_zeromq" = "xyes"; then
1687       AC_MSG_ERROR([configuration specifies --enable-zeromq but libzmq was not found])
1688     fi
1689   ])
1690 fi
1691
1692 dnl ------------------------------------
1693 dnl Enable RPKI and add librtr to libs
1694 dnl ------------------------------------
1695 if test "${enable_rpki}" = "yes"; then
1696   PKG_CHECK_MODULES([RTRLIB], [rtrlib >= 0.5.0],
1697       [RPKI=true],
1698       [RPKI=false
1699       AC_MSG_ERROR([rtrlib was not found on your system or is too old.])]
1700   )
1701 fi
1702
1703 dnl ------------------------------------------
1704 dnl Check whether rtrlib was build with ssh support
1705 dnl ------------------------------------------
1706 AC_MSG_CHECKING([whether the RTR Library is compiled with SSH])
1707 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "rtrlib/rtrlib.h"]],
1708                         [[struct tr_ssh_config config;]])],
1709         [AC_MSG_RESULT([yes])
1710         AC_DEFINE([FOUND_SSH], [1], [found_ssh])],
1711         AC_MSG_RESULT([no])
1712 )
1713
1714 dnl ---------------
1715 dnl dlopen & dlinfo
1716 dnl ---------------
1717 AC_SEARCH_LIBS([dlopen], [dl dld], [], [
1718   AC_MSG_ERROR([unable to find the dlopen()])
1719 ])
1720
1721 AC_CHECK_HEADERS([link.h])
1722
1723 AC_CACHE_CHECK([for dlinfo(RTLD_DI_ORIGIN)], [frr_cv_rtld_di_origin], [
1724   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1725 #include <stdlib.h>
1726 #ifdef HAVE_LINK_H
1727 #include <link.h>
1728 #endif
1729 #include <dlfcn.h>
1730 ]], [[
1731   char origin[1];
1732   dlinfo (NULL, RTLD_DI_ORIGIN, &origin);
1733 ]])], [
1734     frr_cv_rtld_di_origin=yes
1735   ], [
1736     frr_cv_rtld_di_origin=no
1737   ])
1738 ])
1739 if test "$frr_cv_rtld_di_origin" = yes; then
1740   AC_DEFINE([HAVE_DLINFO_ORIGIN], [1], [Have dlinfo RTLD_DI_ORIGIN])
1741 fi
1742
1743 AC_CACHE_CHECK([for dlinfo(RTLD_DI_LINKMAP)], [frr_cv_rtld_di_linkmap], [
1744   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1745 #include <stdlib.h>
1746 #ifdef HAVE_LINK_H
1747 #include <link.h>
1748 #endif
1749 #include <dlfcn.h>
1750 ]], [[
1751   struct link_map *lm = NULL;
1752   dlinfo (NULL, RTLD_DI_LINKMAP, &lm);
1753 ]])], [
1754     frr_cv_rtld_di_linkmap=yes
1755   ], [
1756     frr_cv_rtld_di_linkmap=no
1757   ])
1758 ])
1759 if test "$frr_cv_rtld_di_linkmap" = yes; then
1760   AC_DEFINE([HAVE_DLINFO_LINKMAP], [1], [Have dlinfo RTLD_DI_LINKMAP])
1761 fi
1762
1763 dnl ##########################################################################
1764 dnl test "${enable_clippy_only}" != "yes"
1765 fi
1766 dnl END OF LARGE if block
1767 dnl ##########################################################################
1768
1769 dnl ---------------------------
1770 dnl sockaddr and netinet checks
1771 dnl ---------------------------
1772 AC_CHECK_TYPES([
1773         struct sockaddr_dl,
1774         struct vifctl, struct mfcctl, struct sioc_sg_req,
1775         vifi_t, struct sioc_vif_req, struct igmpmsg,
1776         struct ifaliasreq, struct if6_aliasreq, struct in6_aliasreq,
1777         struct nd_opt_adv_interval,
1778         struct nd_opt_homeagent_info, struct nd_opt_adv_interval,
1779         struct nd_opt_rdnss, struct nd_opt_dnssl],
1780         [], [], FRR_INCLUDES)
1781
1782 AC_CHECK_MEMBERS([struct sockaddr.sa_len,
1783         struct sockaddr_in.sin_len, struct sockaddr_un.sun_len,
1784         struct sockaddr_dl.sdl_len,
1785         struct if6_aliasreq.ifra_lifetime,
1786         struct nd_opt_adv_interval.nd_opt_ai_type],
1787         [], [], FRR_INCLUDES)
1788
1789 dnl ---------------------------
1790 dnl IRDP/pktinfo/icmphdr checks
1791 dnl ---------------------------
1792
1793 AC_CHECK_TYPES([struct in_pktinfo], [
1794   AC_CHECK_TYPES([struct icmphdr], [
1795     IRDP=true
1796   ], [
1797     IRDP=false
1798   ], [FRR_INCLUDES])
1799 ], [
1800   IRDP=false
1801 ], [FRR_INCLUDES])
1802
1803 case "${enable_irdp}" in
1804 yes)
1805   $IRDP || AC_MSG_ERROR(['IRDP requires in_pktinfo at the moment!'])
1806   ;;
1807 no)
1808   IRDP=false
1809   ;;
1810 esac
1811
1812
1813 dnl -----------------------
1814 dnl checking for IP_PKTINFO
1815 dnl -----------------------
1816 AC_MSG_CHECKING([for IP_PKTINFO])
1817 AC_TRY_COMPILE([#include <netdb.h>], [
1818   int opt = IP_PKTINFO;
1819 ], [
1820   AC_MSG_RESULT([yes])
1821   AC_DEFINE([HAVE_IP_PKTINFO], [1], [Have IP_PKTINFO])
1822 ], [
1823   AC_MSG_RESULT([no])
1824 ])
1825
1826 dnl ---------------------------
1827 dnl checking for IP_RECVDSTADDR
1828 dnl ---------------------------
1829 AC_MSG_CHECKING([for IP_RECVDSTADDR])
1830 AC_TRY_COMPILE([#include <netinet/in.h>], [
1831   int opt = IP_RECVDSTADDR;
1832 ], [
1833   AC_MSG_RESULT([yes])
1834   AC_DEFINE([HAVE_IP_RECVDSTADDR], [1], [Have IP_RECVDSTADDR])
1835 ], [
1836   AC_MSG_RESULT([no])
1837 ])
1838
1839 dnl ----------------------
1840 dnl checking for IP_RECVIF
1841 dnl ----------------------
1842 AC_MSG_CHECKING([for IP_RECVIF])
1843 AC_TRY_COMPILE([#include <netinet/in.h>], [
1844   int opt = IP_RECVIF;
1845 ], [
1846   AC_MSG_RESULT([yes])
1847   AC_DEFINE([HAVE_IP_RECVIF], [1], [Have IP_RECVIF])
1848 ], [
1849   AC_MSG_RESULT([no])
1850 ])
1851
1852 dnl ----------------------
1853 dnl checking for SO_BINDANY
1854 dnl ----------------------
1855 AC_MSG_CHECKING([for SO_BINDANY])
1856 AC_TRY_COMPILE([#include <sys/socket.h>], [
1857   int opt = SO_BINDANY;
1858 ], [
1859   AC_MSG_RESULT([yes])
1860   AC_DEFINE([HAVE_SO_BINDANY], [1], [Have SO_BINDANY])
1861 ], [
1862   AC_MSG_RESULT([no])
1863 ])
1864
1865 dnl ----------------------
1866 dnl checking for IP_FREEBIND
1867 dnl ----------------------
1868 AC_MSG_CHECKING([for IP_FREEBIND])
1869 AC_TRY_COMPILE([#include <netinet/in.h>], [
1870   int opt = IP_FREEBIND;
1871 ], [
1872   AC_MSG_RESULT([yes])
1873   AC_DEFINE([HAVE_IP_FREEBIND], [1], [Have IP_FREEBIND])
1874 ], [
1875   AC_MSG_RESULT([no])
1876 ])
1877
1878 dnl --------------------------------------
1879 dnl checking for be32dec existence or not
1880 dnl --------------------------------------
1881 AC_CHECK_DECLS([be32enc, be32dec], [], [],
1882                [#include <sys/endian.h>])
1883
1884 dnl --------------------------------------
1885 dnl checking for clock_time monotonic struct and call
1886 dnl --------------------------------------
1887 AC_CHECK_DECL([CLOCK_MONOTONIC],
1888         [AC_CHECK_LIB([rt], [clock_gettime], [LIBS="$LIBS -lrt"])
1889          AC_DEFINE([HAVE_CLOCK_MONOTONIC], [1], [Have monotonic clock])
1890 ], [AC_MSG_RESULT([no])], [FRR_INCLUDES])
1891
1892 dnl --------------------------------------
1893 dnl checking for flex and bison
1894 dnl --------------------------------------
1895
1896 AM_PROG_LEX
1897 AC_MSG_CHECKING([version of flex])
1898 frr_ac_flex_version="$(eval $LEX -V | grep flex | head -n 1)"
1899 frr_ac_flex_version="${frr_ac_flex_version##* }"
1900 AC_MSG_RESULT([$frr_ac_flex_version])
1901 AX_COMPARE_VERSION([$frr_ac_flex_version], [lt], [2.5.20], [
1902   LEX="$SHELL $missing_dir/missing flex"
1903   if test -f "${srcdir}/lib/command_lex.c" -a -f "${srcdir}/lib/command_lex.h"; then
1904     AC_MSG_WARN([using pregenerated flex output files])
1905   else
1906     AC_MSG_ERROR([flex failure and pregenerated files not included (probably a git build)])
1907   fi
1908   AC_SUBST([LEX_OUTPUT_ROOT], [lex.yy])
1909   AC_SUBST([LEXLIB], [''])
1910 ])
1911
1912 AC_PROG_YACC
1913 dnl thanks GNU bison for this b*llshit...
1914 AC_MSG_CHECKING([version of bison])
1915 frr_ac_bison_version="$(eval $YACC -V | grep bison | head -n 1)"
1916 frr_ac_bison_version="${frr_ac_bison_version##* }"
1917 frr_ac_bison_missing="false"
1918 case "x${frr_ac_bison_version}x" in
1919   x2.7*)
1920     BISON_OPENBRACE='"'
1921     BISON_CLOSEBRACE='"'
1922     BISON_VERBOSE=''
1923     AC_MSG_RESULT([$frr_ac_bison_version - 2.7 or older])
1924     ;;
1925   x2.*|x1.*)
1926     AC_MSG_RESULT([$frr_ac_bison_version])
1927     AC_MSG_WARN([installed bison is too old.  Please install GNU bison 2.7.x or newer.])
1928     frr_ac_bison_missing="true"
1929     ;;
1930   x)
1931     AC_MSG_RESULT([none])
1932     AC_MSG_WARN([could not determine bison version.  Please install GNU bison 2.7.x or newer.])
1933     frr_ac_bison_missing="true"
1934     ;;
1935   x3.[012][^0-9]*)
1936     BISON_OPENBRACE='{'
1937     BISON_CLOSEBRACE='}'
1938     BISON_VERBOSE='-Dparse.error=verbose'
1939     AC_MSG_RESULT([$frr_ac_bison_version - 3.0 to 3.2])
1940     ;;
1941   *)
1942     BISON_OPENBRACE='{'
1943     BISON_CLOSEBRACE='}'
1944     BISON_VERBOSE='-Dparse.error=verbose -Wno-yacc'
1945     AC_MSG_RESULT([$frr_ac_bison_version - 3.3 or newer])
1946     ;;
1947 esac
1948 AC_SUBST([BISON_OPENBRACE])
1949 AC_SUBST([BISON_CLOSEBRACE])
1950 AC_SUBST([BISON_VERBOSE])
1951
1952 if $frr_ac_bison_missing; then
1953   YACC="$SHELL $missing_dir/missing bison -y"
1954   if test -f "${srcdir}/lib/command_parse.c" -a -f "${srcdir}/lib/command_parse.h"; then
1955     AC_MSG_WARN([using pregenerated bison output files])
1956   else
1957     AC_MSG_ERROR([bison failure and pregenerated files not included (probably a git build)])
1958   fi
1959 fi
1960
1961 dnl -------------------
1962 dnl capabilities checks
1963 dnl -------------------
1964 if test "${enable_capabilities}" != "no"; then
1965   AC_MSG_CHECKING([whether prctl PR_SET_KEEPCAPS is available])
1966   AC_TRY_COMPILE([#include <sys/prctl.h>], [prctl(PR_SET_KEEPCAPS, 1, 0, 0, 0);],
1967     [AC_MSG_RESULT([yes])
1968      AC_DEFINE([HAVE_PR_SET_KEEPCAPS], [1], [prctl])
1969      frr_ac_keepcaps="yes"],
1970      AC_MSG_RESULT([no])
1971   )
1972   if test x"${frr_ac_keepcaps}" = x"yes"; then
1973     AC_CHECK_HEADERS([sys/capability.h])
1974   fi
1975   if test x"${ac_cv_header_sys_capability_h}" = x"yes"; then
1976     AC_CHECK_LIB([cap], [cap_init],
1977       [AC_DEFINE([HAVE_LCAPS], [1], [Capabilities])
1978        LIBCAP="-lcap"
1979        frr_ac_lcaps="yes"]
1980     )
1981   else
1982     AC_CHECK_HEADERS([priv.h],
1983      [AC_MSG_CHECKING([Solaris style privileges are available])
1984       AC_TRY_COMPILE([#include <priv.h>], [getpflags(PRIV_AWARE);],
1985           [AC_MSG_RESULT([yes])
1986            AC_DEFINE([HAVE_SOLARIS_CAPABILITIES], [1], [getpflags])
1987            frr_ac_scaps="yes"],
1988            AC_MSG_RESULT(no)
1989       )
1990      ]
1991    )
1992   fi
1993   if test x"${frr_ac_scaps}" = x"yes" \
1994        -o x"${frr_ac_lcaps}" = x"yes"; then
1995     AC_DEFINE([HAVE_CAPABILITIES], [1], [capabilities])
1996   fi
1997 fi
1998 AC_SUBST([LIBCAP])
1999
2000 dnl ---------------------------
2001 dnl check for glibc 'backtrace'
2002 dnl ---------------------------
2003 if test x"${enable_backtrace}" != x"no" ; then
2004   backtrace_ok=no
2005   PKG_CHECK_MODULES([UNWIND], [libunwind], [
2006     AC_DEFINE([HAVE_LIBUNWIND], [1], [libunwind])
2007     backtrace_ok=yes
2008   ], [
2009     case "$host_os" in
2010     sunos* | solaris2*)
2011       AC_CHECK_FUNCS([printstack], [
2012         AC_DEFINE([HAVE_PRINTSTACK], [1], [Solaris printstack])
2013         backtrace_ok=yes
2014       ])
2015       ;;
2016     esac
2017     if test "$backtrace_ok" = no; then
2018       AC_CHECK_HEADER([execinfo.h], [
2019         AC_SEARCH_LIBS([backtrace], [execinfo], [
2020           AC_DEFINE([HAVE_GLIBC_BACKTRACE], [1], [Glibc backtrace])
2021           backtrace_ok=yes
2022         ],, [-lm])
2023       ])
2024     fi
2025   ])
2026
2027   if test x"${enable_backtrace}" = x"yes" -a x"${backtrace_ok}" = x"no"; then
2028     dnl user explicitly requested backtrace but we failed to find support
2029     AC_MSG_FAILURE([failed to find backtrace or libunwind support])
2030   fi
2031 fi
2032
2033 dnl -----------------------------------------
2034 dnl check for malloc mallinfo struct and call
2035 dnl this must try and link using LIBS, in
2036 dnl order to check no alternative allocator
2037 dnl has been specified, which might not provide
2038 dnl mallinfo, e.g. such as Umem on Solaris.
2039 dnl -----------------------------------------
2040 AC_CHECK_HEADERS([malloc.h malloc_np.h malloc/malloc.h],,, [FRR_INCLUDES])
2041
2042 AC_CACHE_CHECK([whether mallinfo is available], [frr_cv_mallinfo], [
2043   AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2044 #ifdef HAVE_MALLOC_H
2045 #include <malloc.h>
2046 #endif
2047 #ifdef HAVE_MALLOC_NP_H
2048 #include <malloc_np.h>
2049 #endif
2050 #ifdef HAVE_MALLOC_MALLOC_H
2051 #include <malloc/malloc.h>
2052 #endif
2053 ]], [[
2054 struct mallinfo ac_x; ac_x = mallinfo ();
2055 ]])], [
2056     frr_cv_mallinfo=yes
2057   ], [
2058     frr_cv_mallinfo=no
2059   ])
2060 ])
2061 if test "$frr_cv_mallinfo" = yes; then
2062   AC_DEFINE([HAVE_MALLINFO], [1], [mallinfo])
2063 fi
2064
2065 AC_MSG_CHECKING([whether malloc_usable_size is available])
2066 AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2067 #ifdef HAVE_MALLOC_H
2068 #include <malloc.h>
2069 #endif
2070 #ifdef HAVE_MALLOC_MALLOC_H
2071 #include <malloc/malloc.h>
2072 #endif
2073 ]], [[
2074 size_t ac_x; ac_x = malloc_usable_size(NULL);
2075 ]])], [
2076   AC_MSG_RESULT([yes])
2077   AC_DEFINE([HAVE_MALLOC_USABLE_SIZE], [1], [malloc_usable_size])
2078 ], [
2079   AC_MSG_RESULT([no])
2080
2081   AC_MSG_CHECKING([whether malloc_size is available])
2082   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2083 #ifdef HAVE_MALLOC_H
2084 #include <malloc.h>
2085 #endif
2086 #ifdef HAVE_MALLOC_MALLOC_H
2087 #include <malloc/malloc.h>
2088 #endif
2089 ]], [[
2090 size_t ac_x; ac_x = malloc_size(NULL);
2091 ]])], [
2092     AC_MSG_RESULT([yes])
2093     AC_DEFINE([HAVE_MALLOC_SIZE], [1], [malloc_size])
2094   ], [
2095     AC_MSG_RESULT([no])
2096   ])
2097 ])
2098
2099 dnl ----------
2100 dnl configure date
2101 dnl ----------
2102 dev_version=`echo $VERSION | grep dev`
2103 #don't expire deprecated code in non 'dev' branch
2104 if test "${dev_version}" = ""; then
2105    CONFDATE=0
2106 else
2107    CONFDATE=`date '+%Y%m%d'`
2108 fi
2109 AC_SUBST([CONFDATE])
2110
2111 dnl ------------------------------
2112 dnl set paths for state directory
2113 dnl ------------------------------
2114 AC_MSG_CHECKING([directory to use for state file])
2115 if test "${prefix}" = "NONE"; then
2116   frr_statedir_prefix="";
2117 else
2118   frr_statedir_prefix=${prefix}
2119 fi
2120 if test "${localstatedir}" = '${prefix}/var'; then
2121   for FRR_STATE_DIR in ${frr_statedir_prefix}/var/run dnl
2122                         ${frr_statedir_prefix}/var/adm dnl
2123                         ${frr_statedir_prefix}/etc dnl
2124                         /var/run        dnl
2125                         /var/adm        dnl
2126                         /etc            dnl
2127                         /dev/null;
2128   do
2129     test -d $FRR_STATE_DIR && break
2130   done
2131   frr_statedir=$FRR_STATE_DIR
2132 else
2133   frr_statedir=${localstatedir}
2134 fi
2135 if test $frr_statedir = "/dev/null"; then
2136     AC_MSG_ERROR([STATE DIRECTORY NOT FOUND! FIX OR SPECIFY --localstatedir!])
2137 fi
2138 AC_MSG_RESULT([${frr_statedir}])
2139 AC_SUBST([frr_statedir])
2140
2141 AC_DEFINE_UNQUOTED([LDPD_SOCKET], ["$frr_statedir%s%s/ldpd.sock"], [ldpd control socket])
2142 AC_DEFINE_UNQUOTED([ZEBRA_SERV_PATH], ["$frr_statedir%s%s/zserv.api"], [zebra api socket])
2143 AC_DEFINE_UNQUOTED([BFDD_CONTROL_SOCKET], ["$frr_statedir%s%s/bfdd.sock"], [bfdd control socket])
2144 AC_DEFINE_UNQUOTED([DAEMON_VTY_DIR], ["$frr_statedir%s%s"], [daemon vty directory])
2145 AC_DEFINE_UNQUOTED([DAEMON_DB_DIR], ["$frr_statedir"], [daemon database directory])
2146
2147 dnl autoconf does this, but it does it too late...
2148 test "x$prefix" = xNONE && prefix=$ac_default_prefix
2149 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
2150
2151 dnl get the full path, recursing through variables...
2152 vtysh_bin="$bindir/vtysh"
2153 for I in 1 2 3 4 5 6 7 8 9 10; do
2154         eval vtysh_bin="\"$vtysh_bin\""
2155 done
2156 AC_DEFINE_UNQUOTED([VTYSH_BIN_PATH], ["$vtysh_bin"], [path to vtysh binary])
2157 AC_SUBST([vtysh_bin])
2158
2159 CFG_SYSCONF="$sysconfdir"
2160 CFG_SBIN="$sbindir"
2161 CFG_STATE="$frr_statedir"
2162 CFG_MODULE="$moduledir"
2163 CFG_YANGMODELS="$yangmodelsdir"
2164 CFG_LIBYANG_PLUGINS="$libyang_pluginsdir"
2165 for I in 1 2 3 4 5 6 7 8 9 10; do
2166         eval CFG_SYSCONF="\"$CFG_SYSCONF\""
2167         eval CFG_SBIN="\"$CFG_SBIN\""
2168         eval CFG_STATE="\"$CFG_STATE\""
2169         eval CFG_MODULE="\"$CFG_MODULE\""
2170         eval CFG_YANGMODELS="\"$CFG_YANGMODELS\""
2171         eval CFG_LIBYANG_PLUGINS="\"$CFG_LIBYANG_PLUGINS\""
2172 done
2173 AC_SUBST([CFG_SYSCONF])
2174 AC_SUBST([CFG_SBIN])
2175 AC_SUBST([CFG_STATE])
2176 AC_SUBST([CFG_MODULE])
2177 AC_SUBST([CFG_YANGMODELS])
2178 AC_SUBST([CFG_LIBYANG_PLUGINS])
2179 AC_DEFINE_UNQUOTED([MODULE_PATH], ["$CFG_MODULE"], [path to modules])
2180 AC_DEFINE_UNQUOTED([YANG_MODELS_PATH], ["$CFG_YANGMODELS"], [path to YANG data models])
2181 AC_DEFINE_UNQUOTED([LIBYANG_PLUGINS_PATH], ["$CFG_LIBYANG_PLUGINS"], [path to libyang plugins])
2182 AC_DEFINE_UNQUOTED([WATCHFRR_SH_PATH], ["${CFG_SBIN%/}/watchfrr.sh"], [path to watchfrr.sh])
2183
2184 dnl various features
2185 AM_CONDITIONAL([SUPPORT_REALMS], [test "${enable_realms}" = "yes"])
2186 AM_CONDITIONAL([ENABLE_BGP_VNC], [test x${enable_bgp_vnc} != xno])
2187 dnl northbound
2188 AM_CONDITIONAL([SQLITE3], [$SQLITE3])
2189 AM_CONDITIONAL([CONFD], [test "x$enable_confd" != "x"])
2190 AM_CONDITIONAL([SYSREPO], [test "x$enable_sysrepo" = "xyes"])
2191 AM_CONDITIONAL([GRPC], [test "x$enable_grpc" = "xyes"])
2192 AM_CONDITIONAL([ZEROMQ], [test "x$ZEROMQ" = "xtrue"])
2193 dnl plugins
2194 AM_CONDITIONAL([RPKI], [test "x$RPKI" = "xtrue"])
2195 AM_CONDITIONAL([SNMP], [test "x$SNMP_METHOD" = "xagentx"])
2196 AM_CONDITIONAL([IRDP], [$IRDP])
2197 AM_CONDITIONAL([FPM], [test "x$enable_fpm" = "xyes"])
2198 AM_CONDITIONAL([HAVE_PROTOBUF], [test "x$enable_protobuf" = "xyes"])
2199 dnl daemons
2200 AM_CONDITIONAL([VTYSH], [test "x$VTYSH" = "xvtysh"])
2201 AM_CONDITIONAL([ZEBRA], [test "${enable_zebra}" != "no"])
2202 AM_CONDITIONAL([BGPD], [test "x${enable_bgpd}" != "no"])
2203 AM_CONDITIONAL([RIPD], [test "${enable_ripd}" != "no"])
2204 AM_CONDITIONAL([OSPFD], [test "${enable_ospfd}" != "no"])
2205 AM_CONDITIONAL([LDPD], [test "${enable_ldpd}" != "no"])
2206 AM_CONDITIONAL([BFDD], [test "x$BFDD" = "xbfdd"])
2207 AM_CONDITIONAL([NHRPD], [test "x$NHRPD" = "xnhrpd"])
2208 AM_CONDITIONAL([EIGRPD], [test "${enable_eigrpd}" != "no"])
2209 AM_CONDITIONAL([WATCHFRR], [test "x$WATCHFRR" = "xwatchfrr"])
2210 AM_CONDITIONAL([OSPFCLIENT], [test "x$OSPFCLIENT" = "xospfclient"])
2211 AM_CONDITIONAL([RIPNGD], [test "${enable_ripngd}" != "no"])
2212 AM_CONDITIONAL([BABELD], [test "${enable_babeld}" != "no"])
2213 AM_CONDITIONAL([OSPF6D], [test "${enable_ospf6d}" != "no"])
2214 AM_CONDITIONAL([ISISD], [test "${enable_isisd}" != "no"])
2215 AM_CONDITIONAL([PIMD], [test "${enable_pimd}" != "no"])
2216 AM_CONDITIONAL([PBRD], [test "${enable_pbrd}" != "no"])
2217 AM_CONDITIONAL([SHARPD], [test "${enable_sharpd}" = "yes"])
2218 AM_CONDITIONAL([STATICD], [test "${enable_staticd}" != "no"])
2219 AM_CONDITIONAL([FABRICD], [test "${enable_fabricd}" != "no"])
2220 AM_CONDITIONAL([VRRPD], [test "${enable_vrrpd}" != "no"])
2221
2222 AC_CONFIG_FILES([Makefile],[sed -e 's/^#AUTODERP# //' -i Makefile])
2223
2224 AC_CONFIG_FILES([
2225           config.version
2226           changelog-auto
2227           redhat/frr.spec
2228           solaris/Makefile
2229           alpine/APKBUILD
2230           snapcraft/snapcraft.yaml
2231           lib/version.h
2232           tests/lib/cli/test_cli.refout
2233           pkgsrc/bgpd.sh pkgsrc/ospf6d.sh pkgsrc/ospfd.sh
2234           pkgsrc/ripd.sh pkgsrc/ripngd.sh pkgsrc/zebra.sh
2235           pkgsrc/eigrpd.sh])
2236
2237 AC_CONFIG_FILES([vtysh/extract.pl], [chmod +x vtysh/extract.pl])
2238 AC_CONFIG_FILES([tools/frr], [chmod +x tools/frr])
2239 AC_CONFIG_FILES([tools/watchfrr.sh], [chmod +x tools/watchfrr.sh])
2240 AC_CONFIG_FILES([tools/frrinit.sh], [chmod +x tools/frrinit.sh])
2241 AC_CONFIG_FILES([tools/frrcommon.sh])
2242
2243 AC_CONFIG_COMMANDS([lib/route_types.h], [
2244         dst="${ac_abs_top_builddir}/lib/route_types.h"
2245         ${PERL} "${ac_abs_top_srcdir}/lib/route_types.pl" \
2246                 < "${ac_abs_top_srcdir}/lib/route_types.txt" \
2247                 > "${dst}.tmp"
2248         test -f "${dst}" \
2249                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
2250                 && rm "${dst}.tmp" \
2251                 || mv "${dst}.tmp" "${dst}"
2252 ], [
2253         PERL="$PERL"
2254 ])
2255
2256 AS_IF([test "x$with_pkg_git_version" = "xyes"], [
2257     AC_CONFIG_COMMANDS([lib/gitversion.h], [
2258         dst="${ac_abs_top_builddir}/lib/gitversion.h"
2259         ${PERL} "${ac_abs_top_srcdir}/lib/gitversion.pl" \
2260                 "${ac_abs_top_srcdir}" \
2261                 > "${dst}.tmp"
2262         test -f "${dst}" \
2263                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
2264                 && rm "${dst}.tmp" \
2265                 || mv "${dst}.tmp" "${dst}"
2266     ], [
2267         PERL="$PERL"
2268     ])
2269 ])
2270
2271 ## Hack, but working solution to avoid rebuilding of frr.info.
2272 ## It's already in CVS until texinfo 4.7 is more common.
2273 AC_OUTPUT
2274
2275 echo "
2276 FRRouting configuration
2277 ------------------------------
2278 FRR version             : ${PACKAGE_VERSION}
2279 host operating system   : ${host_os}
2280 source code location    : ${srcdir}
2281 compiler                : ${CC}
2282 compiler flags          : ${CFLAGS} ${SAN_FLAGS}
2283 make                    : ${MAKE-make}
2284 linker flags            : ${LDFLAGS} ${SAN_FLAGS} ${LIBS} ${LIBCAP} ${LIBREADLINE} ${LIBM}
2285 state file directory    : ${frr_statedir}
2286 config file directory   : `eval echo \`echo ${sysconfdir}\``
2287 example directory       : `eval echo \`echo ${exampledir}\``
2288 module directory        : ${CFG_MODULE}
2289 user to run as          : ${enable_user}
2290 group to run as         : ${enable_group}
2291 group for vty sockets   : ${enable_vty_group}
2292 config file mask        : ${enable_configfile_mask}
2293 log file mask           : ${enable_logfile_mask}
2294 zebra protobuf enabled  : ${enable_protobuf:-no}
2295
2296 The above user and group must have read/write access to the state file
2297 directory and to the config files in the config file directory."
2298
2299 if test "${enable_doc}" != "no" -a "$frr_py_mod_sphinx" = false; then
2300   AC_MSG_WARN([sphinx is missing but required to build documentation])
2301 fi
2302 if test "$frr_py_mod_pytest" = false; then
2303   AC_MSG_WARN([pytest is missing, unit tests cannot be performed])
2304 fi