configure.ac

   1 ##
   2 ## Configure template file for FRRouting.
   3 ## autoconf will generate a configure script.
   4 ##
   5 ##  Copyright (c) 1996, 97, 98, 99, 2000 Kunihiro Ishiguro <kunihiro@zebra.org>
   6 ##  Portions Copyright (c) 2003 Paul Jakma <paul@dishone.st>
   7 ##
   8 AC_PREREQ([2.69])
   9
  10 AC_INIT([frr], [8.3-dev], [https://github.com/frrouting/frr/issues])
  11 PACKAGE_URL="https://frrouting.org/"
  12 AC_SUBST([PACKAGE_URL])
  13 PACKAGE_FULLNAME="FRRouting"
  14 AC_SUBST([PACKAGE_FULLNAME])
  15
  16 CONFIG_ARGS="`echo $ac_configure_args | sed -e \"s% '[[A-Z]]*FLAGS=[[^']]\+'%%g\"`"
  17 AC_SUBST([CONFIG_ARGS])
  18
  19 AC_CONFIG_SRCDIR([lib/zebra.h])
  20 AC_CONFIG_MACRO_DIR([m4])
  21 AC_CONFIG_AUX_DIR([m4/ac])
  22
  23 dnl -----------------------------------
  24 dnl Get hostname and other information.
  25 dnl -----------------------------------
  26 AC_CANONICAL_BUILD()
  27 AC_CANONICAL_HOST()
  28
  29 AC_ARG_VAR([AR],[archiver command])
  30 AC_ARG_VAR([LD],[linker command])
  31 AC_ARG_VAR([OBJCOPY],[objcopy command])
  32 AC_ARG_VAR([OBJDUMP],[objdump command])
  33 AC_ARG_VAR([RANLIB],[ranlib command])
  34 AC_ARG_VAR([STRIP],[strip command])
  35
  36 hosttools_clippy="false"
  37 build_clippy="true"
  38
  39 dnl case 1: external clippy
  40 if test -n "$with_clippy" -a "$with_clippy" != "no" -a "$with_clippy" != "yes"; then
  41   if test "$enable_clippy_only" = "yes"; then
  42     AC_MSG_ERROR([--enable-clippy-only does not make sense with --with-clippy])
  43   fi
  44
  45   CLIPPY="$with_clippy"
  46   build_clippy="false"
  47   if test ! -x "$with_clippy"; then
  48     AC_MSG_ERROR([clippy tool ($with_clippy) is not executable])
  49   fi
  50
  51 dnl case 2: cross-compiling internal clippy
  52 elif test "$host" != "$build"; then
  53   if test "$srcdir" = "."; then
  54     AC_MSG_ERROR([cross-compilation is only possible with builddir separate from srcdir or by building clippy separately and using the --with-clippy option.  create a separate directory and run as .../path-to-frr/configure.])
  55   fi
  56   test -d hosttools || mkdir hosttools
  57   abssrc="`cd \"${srcdir}\"; pwd`"
  58
  59   AC_MSG_NOTICE([...])
  60   AC_MSG_NOTICE([... cross-compilation: creating hosttools directory and self-configuring for build platform tools])
  61   AC_MSG_NOTICE([... use HOST_CPPFLAGS / HOST_CFLAGS / HOST_LDFLAGS if neccessary])
  62   AC_MSG_NOTICE([...])
  63
  64   (
  65     for var in $ac_precious_vars; do
  66       dnl special cases
  67       case "$var" in
  68       YACC|YFLAGS) continue;;
  69       PYTHON*)     retain=true;;
  70       *)           retain=false;
  71       esac
  72
  73       eval "hostvar=\"\${HOST_$var}\""
  74       eval "targetvar=\"\${$var}\""
  75       if test -n "$hostvar"; then
  76         eval "$var='$hostvar'"
  77         _AS_ECHO_LOG([host $var='$hostvar'])
  78       elif $retain; then
  79         _AS_ECHO_LOG([host retain $var='$targetvar'])
  80       else
  81         eval "unset $var"
  82         _AS_ECHO_LOG([host unset $var])
  83       fi
  84     done
  85     cd hosttools
  86     "${abssrc}/configure" "--host=$build" "--build=$build" "--enable-clippy-only" "--disable-nhrpd" "--disable-vtysh"
  87   ) || exit 1
  88
  89   AC_MSG_NOTICE([...])
  90   AC_MSG_NOTICE([... cross-compilation: finished self-configuring for build platform tools])
  91   AC_MSG_NOTICE([...])
  92
  93   build_clippy="false"
  94   hosttools_clippy="true"
  95   CLIPPY="hosttools/lib/clippy"
  96
  97 dnl case 3: normal build internal clippy
  98 else
  99   CLIPPY="lib/clippy\$(EXEEXT)"
 100 fi
 101 AC_SUBST([CLIPPY])
 102 AM_CONDITIONAL([BUILD_CLIPPY], [$build_clippy])
 103 AM_CONDITIONAL([HOSTTOOLS_CLIPPY], [$hosttools_clippy])
 104 AM_CONDITIONAL([ONLY_CLIPPY], [test "$enable_clippy_only" = "yes"])
 105
 106 # Disable portability warnings -- our automake code (in particular
 107 # common.am) uses some constructs specific to gmake.
 108 AM_INIT_AUTOMAKE([1.12 -Wno-portability foreign])
 109 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
 110 AM_SILENT_RULES([yes])
 111 AC_CONFIG_HEADERS([config.h])
 112
 113 AC_PATH_PROG([PERL], [perl])
 114 PKG_PROG_PKG_CONFIG
 115
 116 dnl default is to match previous behavior
 117 pkgsrcrcdir=""
 118 AC_ARG_ENABLE([pkgsrcrcdir],
 119           AS_HELP_STRING([--enable-pkgsrcrcdir],
 120                          [specify directory for rc.d scripts]),
 121                          pkgsrcrcdir="$enableval",)
 122 dnl XXX add --pkgsrcrcdir to autoconf standard directory list somehow
 123 AC_SUBST([pkgsrcrcdir])
 124 AM_CONDITIONAL([PKGSRC], [test "$pkgsrcrcdir" != ""])
 125
 126 AC_ARG_WITH([moduledir], [AS_HELP_STRING([--with-moduledir=DIR], [module directory (${libdir}/frr/modules)])], [
 127         moduledir="$withval"
 128 ], [
 129         moduledir="\${libdir}/frr/modules"
 130 ])
 131 AC_SUBST([moduledir], [$moduledir])
 132
 133 AC_ARG_WITH([scriptdir], [AS_HELP_STRING([--with-scriptdir=DIR], [script directory (${sysconfdir}/scripts)])], [
 134         scriptdir="$withval"
 135 ], [
 136         scriptdir="\${sysconfdir}/scripts"
 137 ])
 138 AC_SUBST([scriptdir], [$scriptdir])
 139
 140 AC_ARG_WITH([yangmodelsdir], [AS_HELP_STRING([--with-yangmodelsdir=DIR], [yang models directory (${datarootdir}/yang)])], [
 141         yangmodelsdir="$withval"
 142 ], [
 143         yangmodelsdir="\${datarootdir}/yang"
 144 ])
 145 AC_SUBST([yangmodelsdir])
 146
 147 AC_ARG_WITH([vici-socket], [AS_HELP_STRING([--with-vici-socket=PATH], [vici-socket (/var/run/charon.vici)])], [
 148         vici_socket="$withval"
 149 ], [
 150         vici_socket="/var/run/charon.vici"
 151 ])
 152 AC_DEFINE_UNQUOTED([VICI_SOCKET], ["$vici_socket"], [StrongSWAN vici socket path])
 153
 154 AC_ARG_ENABLE(tcmalloc,
 155         AS_HELP_STRING([--enable-tcmalloc], [Turn on tcmalloc]),
 156 [case "${enableval}" in
 157   yes) tcmalloc_enabled=true
 158 LIBS="$LIBS -ltcmalloc_minimal"
 159  ;;
 160   no)  tcmalloc_enabled=false ;;
 161   *) AC_MSG_ERROR([bad value ${enableval} for --enable-tcmalloc]) ;;
 162 esac],[tcmalloc_enabled=false])
 163
 164
 165 dnl Thanks autoconf, but we don't want a default -g -O2.  We have our own
 166 dnl flag determination logic.
 167 CFLAGS="${CFLAGS:-}"
 168
 169 dnl --------------------
 170 dnl Check CC and friends
 171 dnl --------------------
 172 dnl note orig_cflags is also used further down
 173 orig_cflags="$CFLAGS"
 174 orig_cxxflags="$CXXFLAGS"
 175 AC_LANG([C])
 176 AC_PROG_CC
 177 AC_PROG_CPP
 178 AC_PROG_CXX
 179 AM_PROG_CC_C_O
 180 dnl remove autoconf default "-g -O2"
 181 CFLAGS="$orig_cflags"
 182 CXXFLAGS="$orig_cxxflags"
 183
 184 dnl Some special handling for ICC later on
 185 if test "$CC" = "icc"; then
 186     cc_is_icc="yes"
 187 fi
 188
 189 PKG_PROG_PKG_CONFIG
 190
 191 dnl it's 2019, sed is sed.
 192 SED=sed
 193 AC_SUBST([SED])
 194
 195 dnl try and enable CFLAGS that are useful for FRR
 196 dnl - specifically, options to control warnings
 197
 198 AC_SUBST([AC_CFLAGS])
 199 AC_USE_SYSTEM_EXTENSIONS
 200 AC_DEFUN([AC_C_FLAG], [{
 201     m4_pushdef([cachename],[m4_translit([frr_cv_$1],[ =-+/{}$],[________])])
 202     AC_CACHE_CHECK([[whether $CC supports $1]], cachename, [
 203         AC_LANG_PUSH([C])
 204         ac_c_flag_save="$CFLAGS"
 205         CFLAGS="$CFLAGS $1"
 206         AC_COMPILE_IFELSE(
 207                 [AC_LANG_PROGRAM([[$4]])],
 208                 [
 209                         cachename=yes
 210                 ], [
 211                         cachename=no
 212                 ])
 213         CFLAGS="$ac_c_flag_save"
 214         AC_LANG_POP([C])
 215     ])
 216     if test "$cachename" = "yes"; then
 217         m4_if([$3], [], [AC_CFLAGS="$AC_CFLAGS $1"], [$3])
 218     else
 219         :
 220         $2
 221     fi
 222     m4_popdef([cachename])
 223 }])
 224
 225 AC_DEFUN([AC_LINK_IFELSE_FLAGS], [{
 226         AC_LANG_PUSH([C])
 227         ac_cflags_save="$CFLAGS"
 228         ac_libs_save="$LIBS"
 229         CFLAGS="$CFLAGS $1"
 230         LIBS="$LIBS $2"
 231         AC_LINK_IFELSE(
 232                 [$3],
 233                 [
 234                         CFLAGS="$ac_cflags_save"
 235                         LIBS="$ac_libs_save"
 236                         m4_default([$5], [
 237                                 AC_MSG_RESULT([yes])
 238                         ])
 239                 ], [
 240                         CFLAGS="$ac_cflags_save"
 241                         LIBS="$ac_libs_save"
 242                         m4_default([$4], [
 243                                 AC_MSG_RESULT([no])
 244                         ])
 245                 ])
 246         AC_LANG_POP([C])
 247         }])
 248
 249 dnl ICC won't bail on unknown options without -diag-error 10006
 250 dnl need to do this first so we get useful results for the other options
 251 if test "$cc_is_icc" = "yes"; then
 252     AC_C_FLAG([-diag-error 10006])
 253 fi
 254
 255 dnl autoconf 2.69 AC_PROG_CC_C99 is "state of the art"
 256 dnl autoconf 2.70 AC_PROG_CC_C99 is deprecated and AC_PROC_CC tries to do C11
 257 m4_if(m4_version_compare(m4_defn([AC_AUTOCONF_VERSION]), [2.70]), [-1], [dnl
 258   dnl autoconf < 2.70
 259   AC_PROG_CC_C99
 260
 261   dnl AC_PROG_CC_C99 may change CC to include -std=gnu99 or something
 262   ac_cc="$CC"
 263   CC="${CC% -std=gnu99}"
 264   CC="${CC% -std=c99}"
 265
 266   AC_C_FLAG([-std=gnu11], [CC="$ac_cc"], [CC="$CC -std=gnu11"])
 267 ], [
 268   dnl autoconf >= 2.70
 269   if test "$ac_cv_prog_cc_c11" = "no"; then
 270     AC_MSG_ERROR([ISO C11 compiler support (with GNU extensions) is required.])
 271   fi
 272 ])
 273
 274 dnl if the user has specified any CFLAGS, override our settings
 275 if test "$enable_gcov" = "yes"; then
 276    if test "$orig_cflags" = ""; then
 277       AC_C_FLAG([--coverage])
 278       AC_C_FLAG([-O0])
 279    fi
 280
 281    AC_LDFLAGS="${AC_LDFLAGS} --coverage"
 282 fi
 283
 284 if test "$enable_clang_coverage" = "yes"; then
 285    AC_C_FLAG([-fprofile-instr-generate], [
 286      AC_MSG_ERROR([$CC does not support -fprofile-instr-generate.])
 287    ])
 288    AC_C_FLAG([-fcoverage-mapping], [
 289      AC_MSG_ERROR([$CC does not support -fcoverage-mapping.])
 290    ])
 291 fi
 292
 293 AM_CONDITIONAL([SCRIPTING], [test "$enable_scripting" = "yes"])
 294
 295 if test "$enable_scripting" = "yes"; then
 296    AX_PROG_LUA([5.3], [5.4], [], [
 297      AC_MSG_ERROR([Lua 5.3 is required to build with Lua support. No other version is supported.])
 298    ])
 299    AX_LUA_HEADERS([], [
 300      AC_MSG_ERROR([Lua 5.3 headers are required to build with Lua support. No other version is supported.])
 301    ])
 302    AX_LUA_LIBS([
 303      AC_DEFINE([HAVE_SCRIPTING], [1], [Have support for scripting])
 304      LIBS="$LIBS $LUA_LIB"
 305      SCRIPTING=true
 306    ], [
 307      SCRIPTING=false
 308      AC_MSG_ERROR([Lua 5.3 libraries are required to build with Lua support. No other version is supported.])
 309    ])
 310 fi
 311
 312 dnl the following flags go in CFLAGS rather than AC_CFLAGS since they make
 313 dnl sense to be overridden by the user
 314 if test "$enable_dev_build" = "yes"; then
 315    AC_DEFINE([DEV_BUILD], [1], [Build for development])
 316    if test "$orig_cflags" = ""; then
 317       AC_C_FLAG([-O0],,[CFLAGS="$CFLAGS -O0"])
 318       AC_C_FLAG([-g3],,[CFLAGS="$CFLAGS -g3"])
 319       AC_C_FLAG([-ggdb3],,[CFLAGS="$CFLAGS -ggdb3"])
 320    fi
 321 else
 322    if test "$orig_cflags" = ""; then
 323       AC_C_FLAG([-g],,[CFLAGS="$CFLAGS -g"])
 324       AC_C_FLAG([-O2],,[CFLAGS="$CFLAGS -O2"])
 325    fi
 326 fi
 327
 328 AM_CONDITIONAL([DEV_BUILD], [test "$enable_dev_build" = "yes"])
 329
 330 dnl always want these CFLAGS
 331 AC_C_FLAG([-fno-omit-frame-pointer])
 332 AC_C_FLAG([-funwind-tables])
 333 AC_C_FLAG([-Wall])
 334 AC_C_FLAG([-Wextra])
 335 AC_C_FLAG([-Wstrict-prototypes])
 336 AC_C_FLAG([-Wmissing-prototypes])
 337 AC_C_FLAG([-Wmissing-declarations])
 338 AC_C_FLAG([-Wpointer-arith])
 339 AC_C_FLAG([-Wbad-function-cast])
 340 AC_C_FLAG([-Wwrite-strings])
 341 AC_C_FLAG([-Wundef])
 342 if test "$enable_gcc_ultra_verbose" = "yes" ; then
 343   AC_C_FLAG([-Wcast-qual])
 344   AC_C_FLAG([-Wmissing-noreturn])
 345   AC_C_FLAG([-Wmissing-format-attribute])
 346   AC_C_FLAG([-Wunreachable-code])
 347   AC_C_FLAG([-Wpacked])
 348   AC_C_FLAG([-Wpadded])
 349   AC_C_FLAG([-Wshadow])
 350 else
 351   AC_C_FLAG([-Wno-unused-result])
 352 fi
 353 AC_C_FLAG([-Wno-unused-parameter])
 354 AC_C_FLAG([-Wno-missing-field-initializers])
 355
 356 AC_C_FLAG([-Wc++-compat], [], [CXX_COMPAT_CFLAGS="-Wc++-compat"])
 357 AC_SUBST([CXX_COMPAT_CFLAGS])
 358
 359 dnl ICC emits a broken warning for const char *x = a ? "b" : "c";
 360 dnl for some reason the string consts get 'promoted' to char *,
 361 dnl triggering a const to non-const conversion warning.
 362 if test "$cc_is_icc" = "yes"; then
 363     AC_C_FLAG([-diag-disable 3179])
 364 fi
 365
 366 if test "$enable_werror" = "yes" ; then
 367   WERROR="-Werror"
 368 fi
 369 AC_SUBST([WERROR])
 370
 371 SAN_FLAGS=""
 372 if test "$enable_address_sanitizer" = "yes"; then
 373   AC_C_FLAG([-fsanitize=address], [
 374     AC_MSG_ERROR([$CC does not support Address Sanitizer.])
 375   ], [
 376     SAN_FLAGS="$SAN_FLAGS -fsanitize=address"
 377   ])
 378 fi
 379 if test "$enable_thread_sanitizer" = "yes"; then
 380   AC_C_FLAG([-fsanitize=thread], [
 381     AC_MSG_ERROR([$CC does not support Thread Sanitizer.])
 382   ], [
 383     SAN_FLAGS="$SAN_FLAGS -fsanitize=thread"
 384   ])
 385 fi
 386 if test "$enable_memory_sanitizer" = "yes"; then
 387   AC_C_FLAG([-fsanitize=memory -fPIE -pie], [
 388     AC_MSG_ERROR([$CC does not support Memory Sanitizer.])
 389   ], [
 390     SAN_FLAGS="$SAN_FLAGS -fsanitize=memory -fPIE -pie"
 391   ])
 392 fi
 393 if test "$enable_undefined_sanitizer" = "yes"; then
 394   AC_C_FLAG([-fsanitize=undefined], [
 395     AC_MSG_ERROR([$CC does not support UndefinedBehaviorSanitizer.])
 396   ], [
 397     SAN_FLAGS="$SAN_FLAGS -fsanitize=undefined"
 398   ])
 399 fi
 400 AC_SUBST([SAN_FLAGS])
 401
 402 dnl frr-format.so
 403 if test "$with_frr_format" != "no" -a "$with_frr_format" != "yes" -a -n "$with_frr_format"; then
 404   AC_C_FLAG([-fplugin=${with_frr_format}], [
 405     AC_MSG_ERROR([specified frr-format plugin ($with_frr_format) does not work])
 406   ],,[
 407 #ifndef _FRR_ATTRIBUTE_PRINTFRR
 408 #error plugin not loaded
 409 #endif
 410 #if _FRR_ATTRIBUTE_PRINTFRR < 0x10000
 411 #error plugin too old
 412 #endif
 413   ])
 414 elif test "$with_frr_format" = "no"; then
 415   : #nothing
 416 else
 417   AC_C_FLAG([-fplugin=tools/gcc-plugins/frr-format.so],[
 418     AC_C_FLAG([-fplugin=frr-format],[
 419       if test "$with_frr_format" = "yes"; then
 420         AC_MSG_ERROR([frr-format plugin requested but not found])
 421       fi
 422     ],,[
 423 #ifndef _FRR_ATTRIBUTE_PRINTFRR
 424 #error plugin not loaded
 425 #endif
 426 #if _FRR_ATTRIBUTE_PRINTFRR < 0x10000
 427 #error plugin too old
 428 #endif
 429     ])
 430   ],,[
 431 #ifndef _FRR_ATTRIBUTE_PRINTFRR
 432 #error plugin not loaded
 433 #endif
 434 #if _FRR_ATTRIBUTE_PRINTFRR < 0x10000
 435 #error plugin too old
 436 #endif
 437   ])
 438 fi
 439
 440 AC_MSG_CHECKING([whether linker supports __start/stop_section symbols])
 441 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 442 #include <stdio.h>
 443 int __attribute__((section("secttest"))) var = 1;
 444 extern int __start_secttest, __stop_secttest;
 445 ]], [[
 446   void *a = &var, *b = &__start_secttest, *c = &__stop_secttest;
 447   printf("%p %p %p\n", a, b, c);
 448 ]])], [
 449   AC_MSG_RESULT(yes)
 450   AC_DEFINE(HAVE_SECTION_SYMS, 1, [have __start/stop_section symbols])
 451 ], [
 452   AC_MSG_RESULT(no)
 453 ])
 454
 455 dnl ----------
 456 dnl Essentials
 457 dnl ----------
 458
 459 AX_PTHREAD([
 460   CC="$PTHREAD_CC"
 461   AC_CFLAGS="$AC_CFLAGS $PTHREAD_CFLAGS"
 462   LIBS="$PTHREAD_LIBS $LIBS"
 463 ], [
 464   AC_MSG_FAILURE([This FRR version needs pthreads])
 465 ])
 466
 467 orig_cflags="$CFLAGS"
 468 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 469
 470 AC_SEARCH_LIBS([pthread_condattr_setclock], [],
 471                 [frr_cv_pthread_condattr_setclock=yes],
 472                 [frr_cv_pthread_condattr_setclock=no])
 473 if test "$frr_cv_pthread_condattr_setclock" = "yes"; then
 474   AC_DEFINE([HAVE_PTHREAD_CONDATTR_SETCLOCK], [1], [Have pthread.h pthread_condattr_setclock])
 475 fi
 476
 477 AC_CHECK_HEADERS([pthread_np.h],,, [
 478 #include <pthread.h>
 479 ])
 480 AC_CHECK_FUNCS([pthread_setname_np pthread_set_name_np pthread_getthreadid_np])
 481
 482 CFLAGS="$orig_cflags"
 483
 484 dnl --------------
 485 dnl Check programs
 486 dnl --------------
 487 AC_PROG_INSTALL
 488 AC_PROG_LN_S
 489 AC_CHECK_TOOL([AR], [ar])
 490
 491 dnl -------
 492 dnl libtool
 493 dnl -------
 494 AC_ARG_ENABLE([static-bin],
 495   AS_HELP_STRING([--enable-static-bin], [link binaries statically]))
 496 LT_INIT
 497 _LT_CONFIG_LIBTOOL([
 498   patch -N -i "${srcdir}/m4/libtool-whole-archive.patch" libtool >&AS_MESSAGE_LOG_FD || \
 499     AC_MSG_WARN([Could not patch libtool for static linking support.  Loading modules into a statically linked daemon will fail.])
 500 dnl the -i option is not POSIX sed and the BSDs implement it differently
 501 dnl cat'ing the output back instead of mv/cp keeps permissions on libtool intact
 502   sed -e 's%func_warning "relinking%true #\0%'                   libtool > libtool.sed && cat libtool.sed > libtool
 503   sed -e 's%func_warning "remember to run%true #\0%'             libtool > libtool.sed && cat libtool.sed > libtool
 504   sed -e 's%func_warning ".*has not been installed in%true #\0%' libtool > libtool.sed && cat libtool.sed > libtool
 505   test -f libtool.sed && rm libtool.sed
 506 ])
 507 if test "$enable_static_bin" = "yes"; then
 508   AC_LDFLAGS_EXEC="-static"
 509   if test "$enable_static" != "yes"; then
 510     AC_MSG_ERROR([The --enable-static-bin option must be combined with --enable-static.])
 511   fi
 512 fi
 513 if test "$enable_shared" != "yes"; then
 514   AC_MSG_ERROR([FRR cannot be built with --disable-shared.  If you want statically linked daemons, use --enable-shared --enable-static --enable-static-bin])
 515 fi
 516 AC_SUBST([AC_LDFLAGS])
 517 AC_SUBST([AC_LDFLAGS_EXEC])
 518 AM_CONDITIONAL([STATIC_BIN], [test "$enable_static_bin" = "yes"])
 519
 520 dnl libtool, the repository of all knowledge related linkers, is too stupid to
 521 dnl correctly tell the linker how to build modules.
 522 if test -z "$module_cmds"; then
 523   module_cmds="`echo \"$archive_cmds\" | sed -e 's%$wl-soname $wl$soname%%'`"
 524 fi
 525 if test -z "$module_expsym_cmds"; then
 526   module_expsym_cmds="`echo \"$archive_expsym_cmds\" | sed -e 's%$wl-soname $wl$soname%%'`"
 527 fi
 528
 529 AC_ARG_ENABLE([rpath],
 530   [AS_HELP_STRING([--enable-rpath], [set hardcoded rpaths in the executable @<:@default=yes@:>@])],
 531   [],
 532   [enable_rpath=yes])
 533
 534 dnl $AR and $RANLIB are set by LT_INIT above
 535 AC_MSG_CHECKING([whether $AR supports D option])
 536 if $AR crD conftest.a >/dev/null 2>/dev/null; then
 537   AC_MSG_RESULT([yes])
 538   dnl ARFLAGS is for automake, AR_FLAGS for libtool m-(
 539   ARFLAGS="crD"
 540   AR_FLAGS="crD"
 541 else
 542   AC_MSG_RESULT([no])
 543   ARFLAGS="cru"
 544   AR_FLAGS="cru"
 545 fi
 546 AC_SUBST([ARFLAGS])
 547 AC_SUBST([AR_FLAGS])
 548
 549 AC_MSG_CHECKING([whether $RANLIB supports D option])
 550 if $RANLIB -D conftest.a >conftest.err 2>&1; then
 551   if grep -q -- '-D' conftest.err; then
 552     AC_MSG_RESULT([no])
 553   else
 554     AC_MSG_RESULT([yes])
 555     RANLIB="$RANLIB -D"
 556   fi
 557 else
 558   AC_MSG_RESULT([no])
 559 fi
 560 AC_SUBST([RANLIB])
 561
 562 test -f conftest.err && rm conftest.err
 563 test -f conftest.a && rm conftest.a
 564
 565 dnl ----------------------
 566 dnl Packages configuration
 567 dnl ----------------------
 568 if test -f config.version; then
 569   . ./config.version
 570 elif test -f "${srcdir}/config.version"; then
 571   . "${srcdir}/config.version"
 572 fi
 573 AC_ARG_WITH([pkg-extra-version],
 574   AS_HELP_STRING([--with-pkg-extra-version=VER], [add extra version field, for packagers/distributions]), [
 575   if test "$withval" = "no"; then
 576     EXTRAVERSION=
 577   else
 578     EXTRAVERSION=$withval
 579   fi
 580 ], [])
 581 AC_ARG_WITH([pkg-git-version],
 582         AS_HELP_STRING([--with-pkg-git-version], [add git information to MOTD and build version string]),
 583         [ test "$withval" != "no" && with_pkg_git_version="yes" ])
 584 AC_ARG_WITH([clippy],
 585   AS_HELP_STRING([--with-clippy=PATH], [use external clippy helper program]))
 586 AC_ARG_WITH([vtysh_pager],
 587         AS_HELP_STRING([--with-vtysh-pager=PAGER], [control what pager is compiled in as default]),
 588         VTYSH_PAGER=$withval, VTYSH_PAGER="more")
 589 AC_ARG_ENABLE([vtysh],
 590   AS_HELP_STRING([--disable-vtysh], [do not build integrated vty shell for FRR]))
 591 AC_ARG_ENABLE([doc],
 592   AS_HELP_STRING([--disable-doc], [do not build docs]))
 593 AC_ARG_ENABLE([doc-html],
 594   AS_HELP_STRING([--enable-doc-html], [build HTML docs]))
 595 AC_ARG_ENABLE([zebra],
 596   AS_HELP_STRING([--disable-zebra], [do not build zebra daemon]))
 597 AC_ARG_ENABLE([bgpd],
 598   AS_HELP_STRING([--disable-bgpd], [do not build bgpd]))
 599 AC_ARG_ENABLE([ripd],
 600   AS_HELP_STRING([--disable-ripd], [do not build ripd]))
 601 AC_ARG_ENABLE([ripngd],
 602   AS_HELP_STRING([--disable-ripngd], [do not build ripngd]))
 603 AC_ARG_ENABLE([ospfd],
 604   AS_HELP_STRING([--disable-ospfd], [do not build ospfd]))
 605 AC_ARG_ENABLE([ospf6d],
 606   AS_HELP_STRING([--disable-ospf6d], [do not build ospf6d]))
 607 AC_ARG_ENABLE([ldpd],
 608   AS_HELP_STRING([--disable-ldpd], [do not build ldpd]))
 609 AC_ARG_ENABLE([nhrpd],
 610   AS_HELP_STRING([--disable-nhrpd], [do not build nhrpd]))
 611 AC_ARG_ENABLE([eigrpd],
 612   AS_HELP_STRING([--disable-eigrpd], [do not build eigrpd]))
 613 AC_ARG_ENABLE([babeld],
 614   AS_HELP_STRING([--disable-babeld], [do not build babeld]))
 615 AC_ARG_ENABLE([watchfrr],
 616   AS_HELP_STRING([--disable-watchfrr], [do not build watchfrr]))
 617 AC_ARG_ENABLE([isisd],
 618   AS_HELP_STRING([--disable-isisd], [do not build isisd]))
 619 AC_ARG_ENABLE([pimd],
 620   AS_HELP_STRING([--disable-pimd], [do not build pimd]))
 621 AC_ARG_ENABLE([pbrd],
 622   AS_HELP_STRING([--disable-pbrd], [do not build pbrd]))
 623 AC_ARG_ENABLE([sharpd],
 624   AS_HELP_STRING([--enable-sharpd], [build sharpd]))
 625 AC_ARG_ENABLE([staticd],
 626   AS_HELP_STRING([--disable-staticd], [do not build staticd]))
 627 AC_ARG_ENABLE([fabricd],
 628   AS_HELP_STRING([--disable-fabricd], [do not build fabricd]))
 629 AC_ARG_ENABLE([vrrpd],
 630   AS_HELP_STRING([--disable-vrrpd], [do not build vrrpd]))
 631 AC_ARG_ENABLE([pathd],
 632   AS_HELP_STRING([--disable-pathd], [do not build pathd]))
 633 AC_ARG_ENABLE([bgp-announce],
 634   AS_HELP_STRING([--disable-bgp-announce], [turn off BGP route announcement]))
 635 AC_ARG_ENABLE([bgp-vnc],
 636   AS_HELP_STRING([--disable-bgp-vnc],[turn off BGP VNC support]))
 637 AC_ARG_ENABLE([bgp-bmp],
 638   AS_HELP_STRING([--disable-bgp-bmp],[turn off BGP BMP support]))
 639 AC_ARG_ENABLE([snmp],
 640   AS_HELP_STRING([--enable-snmp], [enable SNMP support for agentx]))
 641 AC_ARG_ENABLE([config_rollbacks],
 642   AS_HELP_STRING([--enable-config-rollbacks], [enable configuration rollbacks (requires sqlite3)]))
 643 AC_ARG_ENABLE([confd],
 644   AS_HELP_STRING([--enable-confd=ARG], [enable confd integration]))
 645 AC_ARG_ENABLE([sysrepo],
 646   AS_HELP_STRING([--enable-sysrepo], [enable sysrepo integration]))
 647 AC_ARG_ENABLE([grpc],
 648   AS_HELP_STRING([--enable-grpc], [enable the gRPC northbound plugin]))
 649 AC_ARG_ENABLE([zeromq],
 650   AS_HELP_STRING([--enable-zeromq], [enable ZeroMQ handler (libfrrzmq)]))
 651 AC_ARG_ENABLE([lttng],
 652   AS_HELP_STRING([--enable-lttng], [enable LTTng tracing]))
 653 AC_ARG_ENABLE([usdt],
 654   AS_HELP_STRING([--enable-usdt], [enable USDT probes]))
 655 AC_ARG_WITH([libpam],
 656   AS_HELP_STRING([--with-libpam], [use libpam for PAM support in vtysh]))
 657 AC_ARG_ENABLE([ospfapi],
 658   AS_HELP_STRING([--disable-ospfapi], [do not build OSPFAPI to access the OSPF LSA Database]))
 659 AC_ARG_ENABLE([ospfclient],
 660   AS_HELP_STRING([--disable-ospfclient], [do not build OSPFAPI client for OSPFAPI,
 661                           (this is the default if --disable-ospfapi is set)]))
 662 AC_ARG_ENABLE([multipath],
 663   AS_HELP_STRING([--enable-multipath=ARG], [enable multipath function, ARG must be digit]))
 664 AC_ARG_WITH([service_timeout],
 665   AS_HELP_STRING([--with-service-timeout=ARG], [set service timeout value (2 minutes by default), ARG must be digit]))
 666 AC_ARG_ENABLE([user],
 667   AS_HELP_STRING([--enable-user=USER], [user to run FRR suite as (default frr)]))
 668 AC_ARG_ENABLE([group],
 669   AS_HELP_STRING([--enable-group=GROUP], [group to run FRR suite as (default frr)]))
 670 AC_ARG_ENABLE([vty_group],
 671   AS_HELP_STRING([--enable-vty-group=ARG], [set vty sockets to have specified group as owner]))
 672 AC_ARG_ENABLE([configfile_mask],
 673   AS_HELP_STRING([--enable-configfile-mask=ARG], [set mask for config files]))
 674 AC_ARG_ENABLE([logfile_mask],
 675   AS_HELP_STRING([--enable-logfile-mask=ARG], [set mask for log files]))
 676 AC_ARG_ENABLE([shell_access],
 677   AS_HELP_STRING([--enable-shell-access], [Allow users to access shell/telnet/ssh]))
 678 AC_ARG_ENABLE([realms],
 679   AS_HELP_STRING([--enable-realms], [enable REALMS support under Linux]))
 680 AC_ARG_ENABLE([rtadv],
 681   AS_HELP_STRING([--disable-rtadv], [disable IPV6 router advertisement feature]))
 682 AC_ARG_ENABLE([irdp],
 683   AS_HELP_STRING([--disable-irdp], [disable IRDP server support in zebra (enabled by default if supported)]))
 684 AC_ARG_ENABLE([capabilities],
 685   AS_HELP_STRING([--disable-capabilities], [disable using POSIX capabilities]))
 686 AC_ARG_ENABLE([gcc_ultra_verbose],
 687   AS_HELP_STRING([--enable-gcc-ultra-verbose], [enable ultra verbose GCC warnings]))
 688 AC_ARG_ENABLE([backtrace],
 689   AS_HELP_STRING([--disable-backtrace], [disable crash backtraces (default autodetect)]))
 690 AC_ARG_ENABLE([time-check],
 691   AS_HELP_STRING([--disable-time-check], [disable slow thread warning messages]))
 692 AC_ARG_ENABLE([cpu-time],
 693   AS_HELP_STRING([--disable-cpu-time], [disable cpu usage data gathering]))
 694 AC_ARG_ENABLE([pcreposix],
 695   AS_HELP_STRING([--enable-pcreposix], [enable using PCRE Posix libs for regex functions]))
 696 AC_ARG_ENABLE([fpm],
 697   AS_HELP_STRING([--enable-fpm], [enable Forwarding Plane Manager support]))
 698 AC_ARG_ENABLE([werror],
 699   AS_HELP_STRING([--enable-werror], [enable -Werror (recommended for developers only)]))
 700 AC_ARG_ENABLE([cumulus],
 701   AS_HELP_STRING([--enable-cumulus], [enable Cumulus Switch Special Extensions]))
 702 AC_ARG_ENABLE([datacenter],
 703   AS_HELP_STRING([--enable-datacenter], [enable Compilation for Data Center Extensions]))
 704 AC_ARG_ENABLE([rr-semantics],
 705   AS_HELP_STRING([--disable-rr-semantics], [disable the v6 Route Replace semantics]))
 706 AC_ARG_ENABLE([protobuf],
 707   AS_HELP_STRING([--enable-protobuf], [Enable experimental protobuf support]))
 708 AC_ARG_ENABLE([oldvpn_commands],
 709   AS_HELP_STRING([--enable-oldvpn-commands], [Keep old vpn commands]))
 710 AC_ARG_ENABLE([rpki],
 711   AS_HELP_STRING([--enable-rpki], [enable RPKI prefix validation support]))
 712 AC_ARG_ENABLE([clippy-only],
 713   AS_HELP_STRING([--enable-clippy-only], [Only build clippy]))
 714 AC_ARG_ENABLE([numeric_version],
 715   AS_HELP_STRING([--enable-numeric-version], [Only numeric digits allowed in version (for Alpine)]))
 716 AC_ARG_ENABLE([gcov],
 717   AS_HELP_STRING([--enable-gcov], [Collect coverage information with gcov]))
 718 AC_ARG_ENABLE([clang_coverage],
 719   AS_HELP_STRING([--enable-clang-coverage], [Collect coverage information with Clang Coverage]))
 720 AC_ARG_ENABLE([bfdd],
 721   AS_HELP_STRING([--disable-bfdd], [do not build bfdd]))
 722 AC_ARG_ENABLE([address-sanitizer],
 723   AS_HELP_STRING([--enable-address-sanitizer], [enable AddressSanitizer support for detecting a wide variety of memory allocation and deallocation errors]))
 724 AC_ARG_ENABLE([thread-sanitizer],
 725   AS_HELP_STRING([--enable-thread-sanitizer], [enable ThreadSanitizer support for detecting data races]))
 726 AC_ARG_ENABLE([memory-sanitizer],
 727   AS_HELP_STRING([--enable-memory-sanitizer], [enable MemorySanitizer support for detecting uninitialized memory reads]))
 728 AC_ARG_ENABLE([undefined-sanitizer],
 729   AS_HELP_STRING([--enable-undefined-sanitizer], [enable UndefinedBehaviorSanitizer support for detecting undefined behavior]))
 730 AC_ARG_WITH([crypto],
 731   AS_HELP_STRING([--with-crypto=<internal|openssl>], [choose between different implementations of cryptographic functions(default value is --with-crypto=internal)]))
 732 AC_ARG_WITH([frr-format],
 733   AS_HELP_STRING([--with-frr-format[=<.../frr-format.so>]], [use frr-format GCC plugin]))
 734
 735 AC_ARG_ENABLE([version-build-config],
 736   AS_HELP_STRING([--disable-version-build-config], [do not include build configs in show version command]))
 737
 738 #if openssl, else use the internal
 739 AS_IF([test "$with_crypto" = "openssl"], [
 740 AC_CHECK_LIB([crypto], [EVP_DigestInit], [LIBS="$LIBS -lcrypto"], [], [])
 741 if test "$ac_cv_lib_crypto_EVP_DigestInit" = "no"; then
 742   AC_MSG_ERROR([build with openssl has been specified but openssl library was not found on your system])
 743 else
 744   AC_DEFINE([CRYPTO_OPENSSL], [1], [Compile with openssl support])
 745 fi
 746 ], [test "$with_crypto" = "internal" || test "$with_crypto" = "" ], [AC_DEFINE([CRYPTO_INTERNAL], [1], [Compile with internal cryptographic implementation])
 747 ], [AC_MSG_ERROR([Unknown value for --with-crypto])]
 748 )
 749
 750 AS_IF([test "$enable_clippy_only" != "yes"], [
 751 AC_CHECK_HEADERS([json-c/json.h])
 752 AC_CHECK_LIB([json-c], [json_object_get], [LIBS="$LIBS -ljson-c"], [], [-lm])
 753 if test "$ac_cv_lib_json_c_json_object_get" = "no"; then
 754   AC_CHECK_LIB([json], [json_object_get], [LIBS="$LIBS -ljson"])
 755   if test "$ac_cv_lib_json_json_object_get" = "no"; then
 756       AC_MSG_ERROR([libjson is needed to compile])
 757   fi
 758 fi
 759 ])
 760
 761 AC_ARG_ENABLE([dev_build],
 762     AS_HELP_STRING([--enable-dev-build], [build for development]))
 763
 764 AC_ARG_ENABLE([scripting],
 765     AS_HELP_STRING([--enable-scripting], [Build with scripting support]))
 766
 767 AC_ARG_ENABLE([netlink-debug],
 768   AS_HELP_STRING([--disable-netlink-debug], [pretty print netlink debug messages]))
 769
 770 if test "$enable_netlink_debug" != "no" ; then
 771   AC_DEFINE([NETLINK_DEBUG], [1], [Netlink extra debugging code])
 772 fi
 773
 774 AM_CONDITIONAL([NETLINK_DEBUG], [test "$enable_netlink_debug" != "no"])
 775
 776 if test "$enable_time_check" != "no" ; then
 777   if test "$enable_time_check" = "yes" -o "$enable_time_check" = "" ; then
 778     AC_DEFINE([CONSUMED_TIME_CHECK], [5000000], [Consumed Time Check])
 779   else
 780     AC_DEFINE_UNQUOTED([CONSUMED_TIME_CHECK], [$enable_time_check], [Consumed Time Check])
 781   fi
 782 fi
 783
 784 case "${enable_cpu_time}" in
 785   "no")
 786   AC_DEFINE([EXCLUDE_CPU_TIME], [1], [Exclude getrusage data gathering])
 787   ;;
 788   "*")
 789   ;;
 790 esac
 791
 792 if test "$enable_rr_semantics" != "no" ; then
 793   AC_DEFINE([HAVE_V6_RR_SEMANTICS], [1], [Compile in v6 Route Replacement Semantics])
 794 fi
 795
 796 if test "$enable_datacenter" = "yes" ; then
 797   AC_DEFINE([HAVE_DATACENTER], [1], [Compile extensions for a DataCenter])
 798   DFLT_NAME="datacenter"
 799 else
 800   DFLT_NAME="traditional"
 801 fi
 802
 803 if test "$enable_cumulus" = "yes" ; then
 804   AC_DEFINE([HAVE_CUMULUS], [1], [Compile Special Cumulus Code in])
 805 fi
 806
 807 AC_SUBST([DFLT_NAME])
 808 AC_DEFINE_UNQUOTED([DFLT_NAME], ["$DFLT_NAME"], [Name of the configuration default set])
 809
 810 if test "$enable_shell_access" = "yes"; then
 811    AC_DEFINE([HAVE_SHELL_ACCESS], [1], [Allow user to use ssh/telnet/bash, be aware this is considered insecure])
 812 fi
 813
 814 #
 815 # Python for clippy
 816 #
 817
 818 AS_IF([test "$host" = "$build"], [
 819   AM_PATH_PYTHON([3])
 820   AC_CHECK_HEADER([gelf.h], [], [
 821     AC_MSG_ERROR([libelf headers are required for building clippy.  (Host only when cross-compiling.)])
 822   ])
 823
 824   LIBS_save="$LIBS"
 825   AC_CHECK_LIB([elf], [elf_memory], [], [
 826     AC_MSG_ERROR([libelf is required for building clippy.  (Host only when cross-compiling.)])
 827   ])
 828
 829   AC_CHECK_LIB([elf], [elf_getdata_rawchunk], [
 830     AC_DEFINE([HAVE_ELF_GETDATA_RAWCHUNK], [1], [Have elf_getdata_rawchunk()])
 831   ])
 832   AC_CHECK_LIB([elf], [gelf_getnote], [
 833     AC_DEFINE([HAVE_GELF_GETNOTE], [1], [Have gelf_getnote()])
 834   ])
 835   LIBS="$LIBS_save"
 836   unset LIBS_save
 837
 838   FRR_PYTHON_DEV
 839 ], [
 840   FRR_PYTHON
 841 ])
 842
 843 FRR_PYTHON_MODULES([pytest])
 844
 845 if test "$enable_doc" != "no"; then
 846   FRR_PYTHON_MODULES([sphinx], , [
 847     if test "$enable_doc" = "yes"; then
 848       AC_MSG_ERROR([Documentation was explicitly requested with --enable-doc but sphinx is not available for $PYTHON. Please disable docs or install sphinx.])
 849     fi
 850   ])
 851 fi
 852 AM_CONDITIONAL([DOC], [test "$enable_doc" != "no" -a "$frr_py_mod_sphinx" != "false"])
 853 AM_CONDITIONAL([DOC_HTML], [test "$enable_doc_html" = "yes"])
 854
 855 FRR_PYTHON_MOD_EXEC([sphinx], [--version], [
 856   PYSPHINX="-m sphinx"
 857 ], [
 858   PYSPHINX="-c 'import sys; from sphinx import main; sys.exit(main(sys.argv))'"
 859 ])
 860 AC_SUBST([PYSPHINX])
 861
 862 #
 863 # Logic for old vpn commands support.
 864 #
 865 if test "$enable_oldvpn_commands" = "yes"; then
 866    AC_DEFINE([KEEP_OLD_VPN_COMMANDS], [1], [Define for compiling with old vpn commands])
 867 fi
 868
 869 #
 870 # End of logic for protobuf support.
 871 #
 872
 873 AC_MSG_CHECKING([if zebra should be configurable to send Route Advertisements])
 874 if test "$enable_rtadv" != "no"; then
 875   AC_MSG_RESULT([yes])
 876   AC_DEFINE([HAVE_RTADV], [1], [Enable IPv6 Routing Advertisement support])
 877 else
 878   AC_MSG_RESULT([no])
 879 fi
 880
 881 if test "$enable_user" = "no"; then
 882   enable_user=""
 883 else
 884   if test "$enable_user" = "yes" || test "$enable_user" = ""; then
 885     enable_user="frr"
 886   fi
 887   AC_DEFINE_UNQUOTED([FRR_USER], ["${enable_user}"], [frr User])
 888 fi
 889
 890 if test "$enable_group" = "no"; then
 891   enable_group=""
 892 else
 893   if test "$enable_group" = "yes" || test "$enable_group" = ""; then
 894     enable_group="frr"
 895   fi
 896   AC_DEFINE_UNQUOTED([FRR_GROUP], ["${enable_group}"], [frr Group])
 897 fi
 898
 899 if test "$enable_vty_group" = "yes" ; then
 900   AC_MSG_ERROR([--enable-vty-group requires a group as argument, not yes])
 901 elif test "$enable_vty_group" != ""; then
 902   if test "$enable_vty_group" != "no"; then
 903     AC_DEFINE_UNQUOTED([VTY_GROUP], ["${enable_vty_group}"], [VTY Sockets Group])
 904   fi
 905 fi
 906 AC_SUBST([enable_user])
 907 AC_SUBST([enable_group])
 908 AC_SUBST([enable_vty_group])
 909
 910 enable_configfile_mask=${enable_configfile_mask:-0600}
 911 AC_DEFINE_UNQUOTED([CONFIGFILE_MASK], [${enable_configfile_mask}], [Mask for config files])
 912 AC_SUBST([enable_configfile_mask])
 913
 914 enable_logfile_mask=${enable_logfile_mask:-0600}
 915 AC_DEFINE_UNQUOTED([LOGFILE_MASK], [${enable_logfile_mask}], [Mask for log files])
 916
 917 MPATH_NUM=16
 918
 919 case "${enable_multipath}" in
 920   0)
 921     MPATH_NUM=64
 922     ;;
 923   [[1-9]|[1-9][0-9]|[1-9][0-9][0-9]])
 924     MPATH_NUM="${enable_multipath}"
 925     ;;
 926   "")
 927     ;;
 928   *)
 929     AC_MSG_FAILURE([Please specify digit to enable multipath ARG])
 930     ;;
 931 esac
 932
 933 AC_DEFINE_UNQUOTED([MULTIPATH_NUM], [$MPATH_NUM], [Maximum number of paths for a route])
 934
 935 AC_DEFINE_UNQUOTED([VTYSH_PAGER], ["$VTYSH_PAGER"], [What pager to use])
 936
 937
 938 TIMEOUT_MIN=2
 939 case "${with_service_timeout}" in
 940   [[1-9]|[1-9][0-9]|[1-9][0-9][0-9]])
 941     TIMEOUT_MIN="${with_service_timeout}"
 942     ;;
 943   0|"")
 944     ;;
 945   *)
 946     AC_MSG_FAILURE([Please specify digit for timeout ARG])
 947     ;;
 948 esac
 949 AC_SUBST([TIMEOUT_MIN])
 950
 951 dnl --------------------
 952 dnl Enable code coverage
 953 dnl --------------------
 954 AM_CONDITIONAL([HAVE_GCOV], [test "$enable_gcov" != "no"])
 955
 956 dnl ------------------------------------
 957 dnl Alpine only accepts numeric versions
 958 dnl ------------------------------------
 959 if test "$enable_numeric_version" != "" ; then
 960   VERSION="`echo ${VERSION} | tr -c -d '[[.0-9]]'`"
 961   PACKAGE_VERSION="`echo ${PACKAGE_VERSION} | tr -c -d '[[.0-9]]'`"
 962 fi
 963
 964 dnl -----------------------------------
 965 dnl Add extra version string to package
 966 dnl name, string and version fields.
 967 dnl -----------------------------------
 968 if test "$EXTRAVERSION" != "" ; then
 969   VERSION="${VERSION}${EXTRAVERSION}"
 970   PACKAGE_VERSION="${PACKAGE_VERSION}${EXTRAVERSION}"
 971   AC_SUBST(PACKAGE_EXTRAVERSION, ["${EXTRAVERSION}"])
 972   PACKAGE_STRING="${PACKAGE_STRING}${EXTRAVERSION}"
 973 fi
 974 AC_SUBST([EXTRAVERSION])
 975
 976 if test "$with_pkg_git_version" = "yes"; then
 977         if test -e "${srcdir}/.git"; then
 978                 AC_DEFINE([GIT_VERSION], [1], [include git version info])
 979         else    with_pkg_git_version="no"
 980                 AC_MSG_WARN([--with-pkg-git-version given, but this is not a git checkout])
 981         fi
 982 fi
 983 AM_CONDITIONAL([GIT_VERSION], [test "$with_pkg_git_version" = "yes"])
 984
 985 AC_CHECK_TOOL([OBJCOPY], [objcopy], [:])
 986 if test "$OBJCOPY" != ":"; then
 987   AC_CACHE_CHECK([for .interp value to use], [frr_cv_interp], [
 988     frr_cv_interp=""
 989     AC_LINK_IFELSE([AC_LANG_SOURCE([[int main() { return 0; }]])], [
 990       if $OBJCOPY -j.interp -Obinary conftest conftest.interp; then
 991         frr_cv_interp="`xargs -0 echo < conftest.interp`"
 992       fi
 993       test -f conftest.interp && rm conftest.interp
 994     ])
 995   ])
 996 fi
 997 if test -n "$frr_cv_interp"; then
 998   AC_DEFINE_UNQUOTED([INTERP], ["$frr_cv_interp"], [.interp value])
 999 fi
1000
1001 dnl -------------------------
1002 dnl Check other header files.
1003 dnl -------------------------
1004 AC_CHECK_HEADERS([stropts.h sys/ksym.h \
1005         linux/version.h asm/types.h endian.h sys/endian.h])
1006
1007 ac_stdatomic_ok=false
1008 AC_DEFINE([FRR_AUTOCONF_ATOMIC], [1], [did autoconf checks for atomic funcs])
1009 AC_CHECK_HEADER([stdatomic.h],[
1010
1011   AC_MSG_CHECKING([whether _Atomic qualifier works])
1012   AC_LINK_IFELSE([AC_LANG_SOURCE([[
1013 #include <stdatomic.h>
1014 int main(int argc, char **argv) {
1015   _Atomic int i = 0;
1016   return i;
1017 }
1018 ]])], [
1019     AC_DEFINE([HAVE_STDATOMIC_H], [1], [found stdatomic.h])
1020     AC_MSG_RESULT([yes])
1021     ac_stdatomic_ok=true
1022   ], [
1023     AC_MSG_RESULT([no])
1024   ])
1025 ])
1026
1027 AS_IF([$ac_stdatomic_ok], [true], [
1028   AC_MSG_CHECKING([for __atomic_* builtins])
1029   AC_LINK_IFELSE([AC_LANG_SOURCE([[
1030 int main(int argc, char **argv) {
1031   volatile int i = 1;
1032   __atomic_store_n (&i, 0, __ATOMIC_RELEASE);
1033   return __atomic_load_n (&i, __ATOMIC_ACQUIRE);
1034 }
1035 ]])], [
1036     AC_DEFINE([HAVE___ATOMIC], [1], [found __atomic builtins])
1037     AC_MSG_RESULT([yes])
1038   ], [
1039     AC_MSG_RESULT([no])
1040
1041     dnl FreeBSD 9 has a broken stdatomic.h where _Atomic doesn't work
1042     AC_MSG_CHECKING([for __sync_* builtins])
1043     AC_LINK_IFELSE([AC_LANG_SOURCE([[
1044 int main(int argc, char **argv) {
1045   volatile int i = 1;
1046   __sync_fetch_and_sub (&i, 1);
1047   return __sync_val_compare_and_swap (&i, 0, 1);
1048 }
1049 ]])], [
1050       AC_DEFINE([HAVE___SYNC], [1], [found __sync builtins])
1051       AC_MSG_RESULT([yes])
1052
1053       AC_MSG_CHECKING([for __sync_swap builtin])
1054       AC_LINK_IFELSE([AC_LANG_SOURCE([[
1055 int main(int argc, char **argv) {
1056   volatile int i = 1;
1057   return __sync_swap (&i, 2);
1058 }
1059 ]])], [
1060         AC_DEFINE([HAVE___SYNC_SWAP], 1, [found __sync_swap builtin])
1061         AC_MSG_RESULT([yes])
1062       ], [
1063         AC_MSG_RESULT([no])
1064       ])
1065
1066     ], [
1067       AC_MSG_RESULT([no])
1068       AC_MSG_FAILURE([stdatomic.h unavailable and $CC has neither __atomic nor __sync builtins])
1069     ])
1070   ])
1071 ])
1072
1073 needsync=true
1074
1075 AS_IF([$needsync], [
1076   dnl Linux
1077   AC_MSG_CHECKING([for Linux futex() support])
1078   AC_LINK_IFELSE([AC_LANG_PROGRAM([
1079 #ifndef _GNU_SOURCE
1080 #define _GNU_SOURCE
1081 #endif
1082 #include <unistd.h>
1083 #include <limits.h>
1084 #include <sys/time.h>
1085 #include <sys/syscall.h>
1086 #include <linux/futex.h>
1087
1088 int main(void);
1089 ],
1090 [
1091 {
1092   return syscall(SYS_futex, NULL, FUTEX_WAIT, 0, NULL, NULL, 0);
1093 }
1094 ])], [
1095     AC_MSG_RESULT([yes])
1096     AC_DEFINE(HAVE_SYNC_LINUX_FUTEX,,Have Linux futex support)
1097     needsync=false
1098   ], [
1099     AC_MSG_RESULT([no])
1100   ])
1101 ])
1102
1103 AS_IF([$needsync], [
1104   dnl FreeBSD
1105   AC_MSG_CHECKING([for FreeBSD _umtx_op() support])
1106   AC_LINK_IFELSE([AC_LANG_PROGRAM([
1107 #include <errno.h>
1108 #include <stdlib.h>
1109 #include <sys/types.h>
1110 #include <sys/umtx.h>
1111 int main(void);
1112 ],
1113 [
1114 {
1115   return _umtx_op(NULL, UMTX_OP_WAIT_UINT, 0, NULL, NULL);
1116 }
1117 ])], [
1118     AC_MSG_RESULT([yes])
1119     AC_DEFINE(HAVE_SYNC_UMTX_OP,,Have FreeBSD _umtx_op() support)
1120     needsync=false
1121   ], [
1122     AC_MSG_RESULT([no])
1123   ])
1124 ])
1125
1126 AS_IF([$needsync], [
1127   dnl OpenBSD patch (not upstream at the time of writing this)
1128   dnl https://marc.info/?l=openbsd-tech&m=147299508409549&w=2
1129   AC_MSG_CHECKING([for OpenBSD futex() support])
1130   AC_LINK_IFELSE([AC_LANG_PROGRAM([
1131 #include <sys/futex.h>
1132 int main(void);
1133 ],
1134 [
1135 {
1136   return futex(NULL, FUTEX_WAIT, 0, NULL, NULL, 0);
1137 }
1138 ])], [
1139     AC_MSG_RESULT([yes])
1140     AC_DEFINE(HAVE_SYNC_OPENBSD_FUTEX,,Have OpenBSD futex support)
1141     needsync=false
1142   ], [
1143     AC_MSG_RESULT([no])
1144   ])
1145 ])
1146
1147 dnl Utility macro to avoid retyping includes all the time
1148 m4_define([FRR_INCLUDES],
1149 [#ifdef SUNOS_5
1150 #define _POSIX_C_SOURCE 200809L
1151 #define __EXTENSIONS__
1152 #endif
1153 #include <stdio.h>
1154 #include <stdlib.h>
1155 #include <stddef.h>
1156 #include <sys/types.h>
1157 /* sys/conf.h depends on param.h on FBSD at least */
1158 #include <sys/param.h>
1159 /* Required for MAXSIG */
1160 #include <signal.h>
1161 #include <sys/socket.h>
1162 #ifdef __APPLE__
1163 # define __APPLE_USE_RFC_3542
1164 #endif
1165 #include <netinet/in.h>
1166 #include <sys/time.h>
1167 #include <time.h>
1168 #include <net/if.h>
1169 ])dnl
1170
1171 dnl Same applies for HAVE_NET_IF_VAR_H, which HAVE_NETINET6_ND6_H and
1172 dnl HAVE_NETINET_IN_VAR_H depend upon. But if_var.h depends on if.h, hence
1173 dnl an additional round for it.
1174
1175 AC_CHECK_HEADERS([net/if_var.h], [], [], [FRR_INCLUDES])
1176
1177 m4_define([FRR_INCLUDES],
1178 FRR_INCLUDES
1179 [#ifdef HAVE_NET_IF_VAR_H
1180 # include <net/if_var.h>
1181 #endif
1182 ])dnl
1183
1184 AC_CHECK_HEADERS([netinet/in_var.h \
1185         net/if_dl.h net/netopt.h \
1186         inet/nd.h netinet/ip_icmp.h \
1187         sys/sysctl.h sys/sockio.h sys/conf.h],
1188         [], [], [FRR_INCLUDES])
1189
1190 AC_CHECK_HEADERS([ucontext.h], [], [],
1191 [#ifndef __USE_GNU
1192 #define __USE_GNU
1193 #endif /* __USE_GNU */
1194 FRR_INCLUDES
1195 ])
1196
1197 m4_define([UCONTEXT_INCLUDES],
1198 [#include <ucontext.h>])dnl
1199
1200 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.uc_regs],
1201   [], [], [UCONTEXT_INCLUDES])
1202 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs],
1203   [AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs.nip],
1204    [], [], [UCONTEXT_INCLUDES])],
1205   [], [UCONTEXT_INCLUDES])
1206 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.gregs],
1207   [], [], [UCONTEXT_INCLUDES])
1208
1209 m4_define([FRR_INCLUDES],
1210 FRR_INCLUDES
1211 [
1212 #include <sys/un.h>
1213 #include <netinet/in_systm.h>
1214 #ifdef HAVE_NETINET_IN_VAR_H
1215 # include <netinet/in_var.h>
1216 #endif
1217 #ifdef HAVE_NET_IF_DL_H
1218 # include <net/if_dl.h>
1219 #endif
1220 #ifdef HAVE_NET_NETOPT_H
1221 # include <net/netopt.h>
1222 #endif
1223 #include <net/route.h>
1224 #ifdef HAVE_INET_ND_H
1225 # include <inet/nd.h>
1226 #endif
1227 #include <arpa/inet.h>
1228 /* Required for IDRP */
1229 #ifdef HAVE_NETINET_IP_ICMP_H
1230 # include <netinet/ip_icmp.h>
1231 #endif
1232 ])dnl
1233
1234 dnl V6 headers are checked below, after we check for v6
1235
1236 is_linux=false
1237
1238 AC_MSG_CHECKING([which operating system interface to use])
1239 case "$host_os" in
1240   sunos* | solaris2*)
1241     AC_MSG_FAILURE([Solaris support has been removed please see versions prior or equal to 7.5])
1242     ;;
1243   linux*)
1244     AC_MSG_RESULT([Linux])
1245
1246     AC_DEFINE([GNU_LINUX], [1], [GNU Linux])
1247     AC_DEFINE([HAVE_NETLINK], [1], [netlink])
1248     AC_DEFINE([LINUX_IPV6], [1], [Linux IPv6 stack])
1249
1250     dnl Linux has a compilation problem with mixing
1251     dnl netinet/in.h and linux/in6.h they are not
1252     dnl compatible.  There has been discussion on
1253     dnl how to fix it but no real progress on implementation
1254     dnl when they fix it, remove this
1255     AC_DEFINE([IPV6_MINHOPCOUNT], [73], [Linux ipv6 Min Hop Count])
1256
1257     is_linux=true
1258     ;;
1259   openbsd*)
1260     AC_MSG_RESULT([OpenBSD])
1261
1262     AC_DEFINE([OPEN_BSD], [1], [OpenBSD])
1263     AC_DEFINE([KAME], [1], [KAME IPv6])
1264     AC_DEFINE([BSD_V6_SYSCTL], [1], [BSD v6 sysctl to turn on and off forwarding])
1265     ;;
1266   *)
1267     AC_MSG_RESULT([BSD])
1268
1269     AC_DEFINE([HAVE_NET_RT_IFLIST], [1], [NET_RT_IFLIST])
1270     AC_DEFINE([KAME], [1], [KAME IPv6])
1271     AC_DEFINE([BSD_V6_SYSCTL], [1], [BSD v6 sysctl to turn on and off forwarding])
1272     ;;
1273 esac
1274 AM_CONDITIONAL([LINUX], [${is_linux}])
1275
1276 AC_SYS_LARGEFILE
1277
1278 dnl ------------------------
1279 dnl Integrated REALMS option
1280 dnl ------------------------
1281 if test "$enable_realms" = "yes"; then
1282     case "$host_os" in
1283       linux*)
1284        AC_DEFINE([SUPPORT_REALMS], [1], [Realms support])
1285        ;;
1286       *)
1287        echo "Sorry, only Linux has REALMS support"
1288        exit 1
1289        ;;
1290     esac
1291 fi
1292
1293 dnl ---------------
1294 dnl other functions
1295 dnl ---------------
1296 AC_CHECK_FUNCS([ \
1297         strlcat strlcpy \
1298         getgrouplist \
1299         openat \
1300         unlinkat \
1301         posix_fallocate \
1302         ])
1303
1304 dnl ##########################################################################
1305 dnl LARGE if block spans a lot of "configure"!
1306 if test "$enable_clippy_only" != "yes"; then
1307 dnl ##########################################################################
1308
1309 #
1310 # Logic for protobuf support.
1311 #
1312 PROTO3=false
1313 if test "$enable_protobuf" = "yes"; then
1314   # Check for protoc & protoc-c
1315
1316   # protoc is not required, it's only for a "be nice" helper target
1317   AC_CHECK_PROGS([PROTOC], [protoc], [/bin/false])
1318
1319   AC_CHECK_PROGS([PROTOC_C], [protoc-c], [/bin/false])
1320   if test "$PROTOC_C" = "/bin/false"; then
1321     AC_MSG_FAILURE([protobuf requested but protoc-c not found.  Install protobuf-c.])
1322   fi
1323
1324   PKG_CHECK_MODULES([PROTOBUF_C], [libprotobuf-c >= 0.14],, [
1325     AC_MSG_FAILURE([protobuf requested but libprotobuf-c not found.  Install protobuf-c.])
1326   ])
1327
1328   PROTO3=true
1329   AC_CHECK_HEADER([google/protobuf-c/protobuf-c.h],
1330                   [AC_CHECK_DECLS(PROTOBUF_C_LABEL_NONE,
1331                                   AC_DEFINE([HAVE_PROTOBUF_VERSION_3],
1332                                             [1], [Have Protobuf version 3]),
1333                                   [PROTO3=false],
1334                                   [#include <google/protobuf-c/protobuf-c.h>])],
1335                   [PROTO3=false && AC_MSG_FAILURE([protobuf requested but protobuf-c.h not found.  Install protobuf-c.])])
1336
1337   AC_DEFINE([HAVE_PROTOBUF], [1], [protobuf])
1338 fi
1339
1340
1341 dnl ---------------------
1342 dnl Integrated VTY option
1343 dnl ---------------------
1344 case "${enable_vtysh}" in
1345 "no")
1346   VTYSH="";;
1347 *)
1348   VTYSH="vtysh";
1349   AC_DEFINE([VTYSH], [1], [VTY shell])
1350
1351   prev_libs="$LIBS"
1352   AC_CHECK_LIB([readline], [main], [
1353     LIBREADLINE="-lreadline"
1354   ], [
1355     dnl readline failed - it might be incorrectly linked and missing its
1356     dnl termcap/tinfo/curses dependency.  see if we can fix that...
1357     AC_SEARCH_LIBS([tputs], [termcap tinfo curses ncurses], [
1358       LIBREADLINE="$ac_cv_search_tputs"
1359     ], [
1360       AC_MSG_ERROR([libreadline (needed for vtysh) not found and/or missing dependencies])
1361     ])
1362
1363     dnl re-try with the lib we found above
1364     unset ac_cv_lib_readline_main
1365     AC_CHECK_LIB([readline], [main], [
1366       LIBREADLINE="-lreadline $LIBREADLINE"
1367     ], [
1368       AC_MSG_ERROR([libreadline (needed for vtysh) not found and/or missing dependencies])
1369     ], [$LIBREADLINE])
1370   ], [])
1371   LIBS="$prev_libs"
1372
1373   AC_CHECK_HEADER([readline/history.h])
1374   if test "$ac_cv_header_readline_history_h" = "no"; then
1375     AC_MSG_ERROR([readline is too old to have readline/history.h, please update to the latest readline library.])
1376   fi
1377   AC_CHECK_LIB([readline], [rl_completion_matches], [true], [], [$LIBREADLINE])
1378   if test "$ac_cv_lib_readline_rl_completion_matches" = "no"; then
1379     AC_DEFINE([rl_completion_matches], [completion_matches], [Old readline])
1380   fi
1381   AC_CHECK_LIB([readline], [append_history], [frr_cv_append_history=yes], [frr_cv_append_history=no], [$LIBREADLINE])
1382   if test "$frr_cv_append_history" = "yes"; then
1383     AC_DEFINE([HAVE_APPEND_HISTORY], [1], [Have history.h append_history])
1384   fi
1385   ;;
1386 esac
1387 AC_SUBST([LIBREADLINE])
1388
1389 dnl ----------
1390 dnl PAM module
1391 dnl
1392 dnl FRR detects the PAM library it is built against by checking for a
1393 dnl functional pam_misc.h (Linux-PAM) or openpam.h (OpenPAM) header. pam_misc.h
1394 dnl is known to #include pam_appl.h, the standard header of a PAM library, and
1395 dnl openpam.h doesn't do that, although depends on the header too. Hence a
1396 dnl little assistance to AC_CHECK_HEADER is necessary for the proper detection
1397 dnl of OpenPAM.
1398 dnl ----------
1399 if test "$with_libpam" = "yes"; then
1400   AC_CHECK_HEADER([security/pam_misc.h],
1401     [AC_DEFINE([HAVE_PAM_MISC_H], [1], [Have pam_misc.h])
1402      AC_DEFINE([PAM_CONV_FUNC], [misc_conv], [Have misc_conv])
1403      pam_conv_func="misc_conv"
1404     ],
1405     [], FRR_INCLUDES)
1406   AC_CHECK_HEADER([security/openpam.h],
1407     [AC_DEFINE([HAVE_OPENPAM_H], [1], [Have openpam.h])
1408      AC_DEFINE([PAM_CONV_FUNC], [openpam_ttyconv], [Have openpam_ttyconv])
1409      pam_conv_func="openpam_ttyconv"
1410     ],
1411     [], FRR_INCLUDES[#include <security/pam_appl.h>])
1412   if test -z "$ac_cv_header_security_pam_misc_h$ac_cv_header_security_openpam_h" ; then
1413     AC_MSG_WARN([*** pam support will not be built ***])
1414     with_libpam="no"
1415   fi
1416 fi
1417
1418 if test "$with_libpam" = "yes"; then
1419 dnl took this test from proftpds configure.in and suited to our needs
1420 dnl -------------------------------------------------------------------------
1421 dnl
1422 dnl This next check looks funky due to a linker problem with some versions
1423 dnl of the PAM library.  Prior to 0.72 release, the Linux PAM shared library
1424 dnl omitted requiring libdl linking information. PAM-0.72 or better ships
1425 dnl with RedHat 6.2 and Debian 2.2 or better.
1426 AC_CHECK_LIB([pam], [pam_start],
1427   [AC_CHECK_LIB([pam], [$pam_conv_func],
1428     [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1429      LIBPAM="-lpam"],
1430     [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1431      LIBPAM="-lpam -lpam_misc"]
1432     )
1433   ],
1434
1435   [AC_CHECK_LIB([pam], [pam_end],
1436     [AC_CHECK_LIB([pam], [$pam_conv_func],
1437       [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1438        LIBPAM="-lpam -ldl"],
1439       [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1440        LIBPAM="-lpam -ldl -lpam_misc"]
1441      )
1442   ],AC_MSG_WARN([*** pam support will not be built ***]),
1443   [-ldl])
1444   ]
1445 )
1446 fi
1447 AC_SUBST([LIBPAM])
1448
1449 dnl -------------------------------
1450 dnl bgpd needs pow() and hence libm
1451 dnl -------------------------------
1452 TMPLIBS="$LIBS"
1453 LIBS=""
1454 AC_SEARCH_LIBS([pow], [m], [
1455   LIBM="$LIBS"
1456 ], [
1457   AC_MSG_WARN([Unable to find working pow function - bgpd may not link])
1458 ])
1459 LIBS="$TMPLIBS"
1460 AC_SUBST([LIBM])
1461
1462 AC_CHECK_FUNCS([ppoll], [
1463   AC_DEFINE([HAVE_PPOLL], [1], [have Linux/BSD ppoll()])
1464 ])
1465 AC_CHECK_FUNCS([pollts], [
1466   AC_DEFINE([HAVE_POLLTS], [1], [have NetBSD pollts()])
1467 ])
1468
1469 AC_CHECK_HEADER([asm-generic/unistd.h],
1470                 [AC_CHECK_DECL(__NR_setns,
1471                                AC_DEFINE([HAVE_NETNS], [1], [Have netns]),,
1472                                FRR_INCLUDES [#include <asm-generic/unistd.h>
1473                                ])
1474                  AC_CHECK_FUNCS([setns])]
1475                )
1476
1477 dnl --------------------------
1478 dnl Determine IS-IS I/O method
1479 dnl --------------------------
1480 AC_DEFINE([ISIS_METHOD_PFPACKET], [1], [constant value for isis method pfpacket])
1481 AC_DEFINE([ISIS_METHOD_DLPI], [2], [constant value for isis method dlpi])
1482 AC_DEFINE([ISIS_METHOD_BPF], [3], [constant value for isis method bpf])
1483 AC_CHECK_HEADER([net/bpf.h])
1484 AC_CHECK_HEADER([sys/dlpi.h])
1485 AC_MSG_CHECKING([zebra IS-IS I/O method])
1486
1487 case "$host_os" in
1488   linux*)
1489     AC_MSG_RESULT([pfpacket])
1490     ISIS_METHOD_MACRO="ISIS_METHOD_PFPACKET"
1491     ;;
1492   *)
1493     if test "$ac_cv_header_net_bpf_h" = "no"; then
1494       if test "$ac_cv_header_sys_dlpi_h" = "no"; then
1495         AC_MSG_RESULT([none])
1496         if test "$enable_isisd" = "yes" -o "$enable_fabricd" = "yes"; then
1497           AC_MSG_FAILURE([IS-IS support requested but no packet backend found])
1498         fi
1499         AC_MSG_WARN([*** IS-IS support will not be built ***])
1500         enable_isisd="no"
1501         enable_fabricd="no"
1502       else
1503         AC_MSG_RESULT([DLPI])
1504       fi
1505       ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1506     else
1507       AC_MSG_RESULT([BPF])
1508       ISIS_METHOD_MACRO="ISIS_METHOD_BPF"
1509     fi
1510     ;;
1511 esac
1512 AC_DEFINE_UNQUOTED([ISIS_METHOD], [$ISIS_METHOD_MACRO], [selected method for isis, == one of the constants])
1513
1514 dnl ---------------------------------------------------------------
1515 dnl figure out how to specify an interface in multicast sockets API
1516 dnl ---------------------------------------------------------------
1517 AC_CHECK_MEMBERS([struct ip_mreqn.imr_ifindex], [], [], FRR_INCLUDES)
1518
1519 AC_CHECK_HEADERS([linux/mroute.h], [], [],[
1520         #include <sys/socket.h>
1521         #include <netinet/in.h>
1522         #define _LINUX_IN_H             /* For Linux <= 2.6.25 */
1523         #include <linux/types.h>
1524 ])
1525
1526 m4_define([FRR_INCLUDES],
1527 FRR_INCLUDES
1528 [#ifdef HAVE_LINUX_MROUTE_H
1529 # include <linux/mroute.h>
1530 #endif
1531 ])dnl
1532
1533 AC_CHECK_HEADERS([netinet/ip_mroute.h], [], [],[
1534         #include <sys/socket.h>
1535         #include <sys/types.h>
1536         #include <netinet/in.h>
1537         #include <net/route.h>
1538 ])
1539
1540 m4_define([FRR_INCLUDES],
1541 FRR_INCLUDES
1542 [#ifdef HAVE_NETINET_IP_MROUTE_H
1543 # include <netinet/ip_mroute.h>
1544 #endif
1545 ])dnl
1546
1547 AC_MSG_CHECKING([for RFC3678 protocol-independed API])
1548 AC_COMPILE_IFELSE(
1549 [ AC_LANG_PROGRAM([[
1550       #include <sys/types.h>
1551       #include <netinet/in.h>
1552   ]], [[
1553       struct group_req gr;
1554       int sock;
1555       setsockopt(sock, IPPROTO_IP, MCAST_JOIN_GROUP, (void*)&gr, sizeof(gr));
1556   ]])
1557 ],[
1558   AC_MSG_RESULT([yes])
1559   AC_DEFINE([HAVE_RFC3678], [1], [Have RFC3678 protocol-independed API])
1560 ],[
1561   AC_MSG_RESULT(no)
1562 ])
1563
1564 dnl ---------------------------------------------------------------
1565 dnl figure out how to check link-state
1566 dnl ---------------------------------------------------------------
1567 AC_CHECK_HEADER([net/if_media.h],
1568   [m4_define([LINK_DETECT_INCLUDES],
1569     FRR_INCLUDES
1570     [#include <net/if_media.h>
1571   ])
1572   AC_CHECK_MEMBERS([struct ifmediareq.ifm_status],
1573     AC_DEFINE([HAVE_BSD_LINK_DETECT], [1], [BSD link-detect]),
1574     [], LINK_DETECT_INCLUDES)],
1575   [],
1576   FRR_INCLUDES)
1577
1578 dnl ---------------------------------------------------------------
1579 dnl Additional, newer way to check link-state using ifi_link_state.
1580 dnl Not available in all BSD's when ifmediareq available
1581 dnl ---------------------------------------------------------------
1582 AC_CHECK_MEMBERS([struct if_data.ifi_link_state],
1583   AC_DEFINE([HAVE_BSD_IFI_LINK_STATE], [1], [BSD ifi_link_state available]),
1584   [], FRR_INCLUDES)
1585
1586 dnl ------------------------
1587 dnl TCP_MD5SIG socket option
1588 dnl ------------------------
1589
1590 AC_CHECK_HEADER([netinet/tcp.h],
1591    [m4_define([MD5_INCLUDES],
1592       FRR_INCLUDES
1593       [#include <netinet/tcp.h>
1594     ])
1595     AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)],
1596    [],
1597    FRR_INCLUDES)
1598 if test "$ac_cv_have_decl_TCP_MD5SIG" = "no"; then
1599   AC_CHECK_HEADER([linux/tcp.h],
1600        [m4_define([MD5_INCLUDES],
1601           FRR_INCLUDES
1602           [#include <linux/tcp.h>
1603         ])
1604        AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)])
1605 fi
1606
1607 LIBS_save="$LIBS"
1608 AC_CHECK_LIB([crypt], [crypt], [], [
1609   AC_CHECK_LIB([crypto], [DES_crypt])
1610 ])
1611 LIBCRYPT="$LIBS"
1612 LIBCRYPT="${LIBCRYPT%$LIBS_save}"
1613 LIBCRYPT="${LIBCRYPT#$LIBS_save}"
1614 AC_SUBST([LIBCRYPT])
1615 LIBS="$LIBS_save"
1616 unset LIBS_save
1617
1618 AC_CHECK_LIB([resolv], [res_init])
1619
1620 dnl ---------------------------
1621 dnl check system has PCRE regexp
1622 dnl ---------------------------
1623 if test "$enable_pcreposix" = "yes"; then
1624   AC_CHECK_LIB([pcreposix], [regexec], [], [
1625     AC_MSG_ERROR([--enable-pcreposix given but unable to find libpcreposix])
1626   ])
1627 fi
1628 AC_SUBST([HAVE_LIBPCREPOSIX])
1629
1630 dnl ##########################################################################
1631 dnl test "$enable_clippy_only" != "yes"
1632 fi
1633 dnl END OF LARGE if block
1634 dnl ##########################################################################
1635
1636 dnl ------------------
1637 dnl check C-Ares library
1638 dnl ------------------
1639 PKG_CHECK_MODULES([CARES], [libcares], [
1640   c_ares_found=true
1641 ],[
1642   c_ares_found=false
1643 ])
1644 AM_CONDITIONAL([CARES], [$c_ares_found])
1645
1646
1647 dnl ----------------------------------------------------------------------------
1648 dnl figure out if domainname is available in the utsname struct (GNU extension).
1649 dnl ----------------------------------------------------------------------------
1650 AC_CHECK_MEMBERS([struct utsname.domainname], [], [], [#include <sys/utsname.h>])
1651
1652 dnl ------------------
1653 dnl IPv6 header checks
1654 dnl ------------------
1655 AC_CHECK_HEADERS([netinet6/in6.h netinet/in6_var.h \
1656         netinet6/in6_var.h netinet6/nd6.h], [], [],
1657         FRR_INCLUDES)
1658
1659 m4_define([FRR_INCLUDES],dnl
1660 FRR_INCLUDES
1661 [#ifdef HAVE_NETINET6_IN6_H
1662 #include <netinet6/in6.h>
1663 #endif
1664 #ifdef HAVE_NETINET_IN6_VAR_H
1665 #include <netinet/in6_var.h>
1666 #endif
1667 #include <netinet/icmp6.h>
1668 #ifdef HAVE_NETINET6_IN6_VAR_H
1669 # include <netinet6/in6_var.h>
1670 #endif
1671 #ifdef HAVE_NETINET6_ND6_H
1672 # include <netinet6/nd6.h>
1673 #endif
1674 ])dnl
1675
1676 dnl --------------------
1677 dnl Daemon disable check
1678 dnl --------------------
1679
1680 AS_IF([test "$enable_bgpd" != "no"], [
1681   AC_DEFINE([HAVE_BGPD], [1], [bgpd])
1682 ])
1683
1684 AS_IF([test "$enable_ripd" != "no"], [
1685   AC_DEFINE([HAVE_RIPD], [1], [ripd])
1686 ])
1687
1688 AS_IF([test "$enable_ripngd" != "no"], [
1689   AC_DEFINE([HAVE_RIPNGD], [1], [ripngd])
1690 ])
1691
1692 AS_IF([test "$enable_ospfd" != "no"], [
1693   AC_DEFINE([HAVE_OSPFD], [1], [ospfd])
1694 ])
1695
1696 AS_IF([test "$enable_ospf6d" != "no"], [
1697   AC_DEFINE([HAVE_OSPF6D], [1], [ospf6d])
1698 ])
1699
1700 AS_IF([test "$enable_ldpd" != "no"], [
1701   AC_DEFINE([HAVE_LDPD], [1], [ldpd])
1702 ])
1703
1704 AS_IF([test "$enable_nhrpd" != "no"], [
1705   AC_DEFINE([HAVE_NHRPD], [1], [nhrpd])
1706 ])
1707
1708 AS_IF([test "$enable_eigrpd" != "no"], [
1709   AC_DEFINE([HAVE_EIGRPD], [1], [eigrpd])
1710 ])
1711
1712 AS_IF([test "$enable_babeld" != "no"], [
1713   AC_DEFINE([HAVE_BABELD], [1], [babeld])
1714 ])
1715
1716 AS_IF([test "$enable_isisd" != "no"], [
1717   AC_DEFINE([HAVE_ISISD], [1], [isisd])
1718 ])
1719
1720 AS_IF([test "$enable_pimd" != "no"], [
1721   AC_DEFINE([HAVE_PIMD], [1], [pimd])
1722 ])
1723
1724 AS_IF([test "$enable_pbrd" != "no"], [
1725   AC_DEFINE([HAVE_PBRD], [1], [pbrd])
1726 ])
1727
1728 AS_IF([test "$enable_sharpd" = "yes"], [
1729   AC_DEFINE([HAVE_SHARPD], [1], [sharpd])
1730 ])
1731
1732 AS_IF([test "$enable_staticd" != "no"], [
1733   AC_DEFINE([HAVE_STATICD], [1], [staticd])
1734 ])
1735
1736 AS_IF([test "$enable_fabricd" != "no"], [
1737   AC_DEFINE([HAVE_FABRICD], [1], [fabricd])
1738 ])
1739
1740 AS_IF([test "$enable_vrrpd" != "no"], [
1741   AC_DEFINE([HAVE_VRRPD], [1], [vrrpd])
1742 ])
1743
1744 if test "$enable_bfdd" = "no"; then
1745   AC_DEFINE([HAVE_BFDD], [0], [bfdd])
1746   BFDD=""
1747 else
1748   AC_DEFINE([HAVE_BFDD], [1], [bfdd])
1749   BFDD="bfdd"
1750
1751   case $host_os in
1752     linux*)
1753       AC_DEFINE([BFD_LINUX], [1], [bfdd])
1754       ;;
1755
1756     *)
1757       AC_DEFINE([BFD_BSD], [1], [bfdd])
1758       ;;
1759   esac
1760 fi
1761
1762 AS_IF([test "$enable_pathd" != "no"], [
1763   AC_DEFINE([HAVE_PATHD], [1], [pathd])
1764 ])
1765
1766
1767 if test "$ac_cv_lib_json_c_json_object_get" = "no" -a "$BFDD" = "bfdd"; then
1768   AC_MSG_ERROR(["you must use json-c library to use bfdd"])
1769 fi
1770
1771 NHRPD=""
1772 case "$host_os" in
1773   linux*)
1774     case "${enable_nhrpd}" in
1775       no)
1776         ;;
1777       yes)
1778         if test "$enable_clippy_only" != "yes"; then
1779         if test "$c_ares_found" != "true" ; then
1780           AC_MSG_ERROR([nhrpd requires libcares.  Please install c-ares and its -dev headers.])
1781         fi
1782         fi
1783         NHRPD="nhrpd"
1784         ;;
1785       *)
1786         if test "$c_ares_found" = "true" ; then
1787           NHRPD="nhrpd"
1788         fi
1789         ;;
1790     esac
1791     ;;
1792   *)
1793     if test "$enable_nhrpd" = "yes"; then
1794       AC_MSG_ERROR([nhrpd requires kernel APIs that are only present on Linux.])
1795     fi
1796     ;;
1797 esac
1798
1799 if test "$enable_watchfrr" = "no";then
1800   WATCHFRR=""
1801 else
1802   WATCHFRR="watchfrr"
1803 fi
1804
1805 OSPFCLIENT=""
1806 if test "$enable_ospfapi" != "no";then
1807     AC_DEFINE([SUPPORT_OSPF_API], [1], [OSPFAPI])
1808
1809   if test "$enable_ospfclient" != "no";then
1810       OSPFCLIENT="ospfclient"
1811   fi
1812 fi
1813
1814 if test "$enable_bgp_announce" = "no";then
1815   AC_DEFINE([DISABLE_BGP_ANNOUNCE], [1], [Disable BGP installation to zebra])
1816 else
1817   AC_DEFINE([DISABLE_BGP_ANNOUNCE], [0], [Disable BGP installation to zebra])
1818 fi
1819
1820 if test "$enable_bgp_vnc" != "no";then
1821   AC_DEFINE([ENABLE_BGP_VNC], [1], [Enable BGP VNC support])
1822 fi
1823
1824 bgpd_bmp=false
1825 case "${enable_bgp_bmp}" in
1826   no)
1827     ;;
1828   yes)
1829     if test "$c_ares_found" != "true" ; then
1830       AC_MSG_ERROR([BMP support requires libcares.  Please install c-ares and its -dev headers.])
1831     fi
1832     bgpd_bmp=true
1833     ;;
1834   *)
1835     if test "$c_ares_found" = "true" ; then
1836       bgpd_bmp=true
1837     fi
1838     ;;
1839 esac
1840
1841 if test "$enable_version_build_config" != "no";then
1842   AC_DEFINE([ENABLE_VERSION_BUILD_CONFIG], [1], [Report build configs in show version])
1843 fi
1844
1845 dnl ##########################################################################
1846 dnl LARGE if block
1847 if test "$enable_clippy_only" != "yes"; then
1848 dnl ##########################################################################
1849
1850 dnl ------------------
1851 dnl check Net-SNMP library
1852 dnl ------------------
1853 if test "$enable_snmp" != "" -a "$enable_snmp" != "no"; then
1854    AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], [no])
1855    if test "$NETSNMP_CONFIG" = "no"; then
1856       AC_MSG_ERROR([--enable-snmp given but unable to find net-snmp-config])
1857    fi
1858    SNMP_LIBS="`${NETSNMP_CONFIG} --agent-libs`"
1859    SNMP_CFLAGS="`${NETSNMP_CONFIG} --base-cflags`"
1860    # net-snmp lists all of its own dependencies.  we absolutely do not want that
1861    # among other things we avoid a GPL vs. OpenSSL license conflict here
1862    for removelib in crypto ssl sensors pci wrap; do
1863      SNMP_LIBS="`echo $SNMP_LIBS | sed -e 's/\(^\|\s\)-l'$removelib'\b/ /g' -e 's/\(^\|\s\)\([^\s]*\/\)\?lib'$removelib'\.[^\s]\+\b/ /g'`"
1864    done
1865    AC_MSG_CHECKING([whether we can link to Net-SNMP])
1866    AC_LINK_IFELSE_FLAGS([$SNMP_CFLAGS], [$SNMP_LIBS], [AC_LANG_PROGRAM([
1867 int main(void);
1868 ],
1869 [
1870 {
1871   return 0;
1872 }
1873 ])], [
1874      AC_MSG_RESULT([no])
1875      AC_MSG_ERROR([--enable-snmp given but not usable])])
1876    case "${enable_snmp}" in
1877      yes)
1878       SNMP_METHOD=agentx
1879       ;;
1880      agentx)
1881       SNMP_METHOD="${enable_snmp}"
1882       ;;
1883      *)
1884       AC_MSG_ERROR([--enable-snmp given with an unknown method (${enable_snmp}). Use yes or agentx])
1885       ;;
1886    esac
1887    AH_TEMPLATE([SNMP_AGENTX], [Use SNMP AgentX to interface with snmpd])
1888    AC_DEFINE_UNQUOTED(AS_TR_CPP(SNMP_${SNMP_METHOD}),,[SNMP method to interface with snmpd])
1889 fi
1890 AC_SUBST([SNMP_LIBS])
1891 AC_SUBST([SNMP_CFLAGS])
1892
1893 dnl ---------------
1894 dnl libyang
1895 dnl ---------------
1896 PKG_CHECK_MODULES([LIBYANG], [libyang >= 2.0.0], , [
1897   AC_MSG_ERROR([libyang (>= 2.0.0) was not found on your system.])
1898 ])
1899 ac_cflags_save="$CFLAGS"
1900 CFLAGS="$CFLAGS $LIBYANG_CFLAGS"
1901 AC_CHECK_MEMBER([struct lyd_node.priv], [], [
1902   AC_MSG_ERROR([m4_normalize([
1903     libyang needs to be compiled with ENABLE_LYD_PRIV=ON.
1904     Instructions for this are included in the build documentation for your platform at http://docs.frrouting.org/projects/dev-guide/en/latest/building.html])
1905   ])
1906 ], [[#include <libyang/libyang.h>]])
1907 CFLAGS="$ac_cflags_save"
1908
1909 dnl ---------------
1910 dnl configuration rollbacks
1911 dnl ---------------
1912 SQLITE3=false
1913 if test "$enable_config_rollbacks" = "yes"; then
1914   PKG_CHECK_MODULES([SQLITE3], [sqlite3], [
1915     AC_DEFINE([HAVE_CONFIG_ROLLBACKS], [1], [Enable configuration rollbacks])
1916     AC_DEFINE([HAVE_SQLITE3], [1], [Enable sqlite3 database])
1917     SQLITE3=true
1918   ], [
1919     AC_MSG_ERROR([--enable-config-rollbacks given but sqlite3 was not found on your system.])
1920   ])
1921 fi
1922
1923 dnl ---------------
1924 dnl confd
1925 dnl ---------------
1926 if test "$enable_confd" != "" -a "$enable_confd" != "no"; then
1927    AC_CHECK_PROG([CONFD], [confd], [confd], [/bin/false], "${enable_confd}/bin")
1928    if test "$CONFD" = "/bin/false"; then
1929       AC_MSG_ERROR([confd was not found on your system.])]
1930    fi
1931    AC_CHECK_PROG([CONFDC], [confdc], [confdc], [/bin/false], "${enable_confd}/bin")
1932    CONFD_CFLAGS="-I${enable_confd}/include -L${enable_confd}/lib"
1933    AC_SUBST([CONFD_CFLAGS])
1934    CONFD_LIBS="-lconfd"
1935    AC_SUBST([CONFD_LIBS])
1936    AC_DEFINE([HAVE_CONFD], [1], [Enable confd integration])
1937 fi
1938
1939 dnl ---------------
1940 dnl sysrepo
1941 dnl ---------------
1942 if test "$enable_sysrepo" = "yes"; then
1943   PKG_CHECK_MODULES([SYSREPO], [sysrepo],
1944       [AC_DEFINE([HAVE_SYSREPO], [1], [Enable sysrepo integration])
1945       SYSREPO=true],
1946       [SYSREPO=false
1947       AC_MSG_ERROR([sysrepo was not found on your system.])]
1948   )
1949 fi
1950
1951 dnl ---------------
1952 dnl gRPC
1953 dnl ---------------
1954 if test "$enable_grpc" = "yes"; then
1955   AC_LANG_PUSH([C++])
1956   AX_CXX_COMPILE_STDCXX([11], [ext])
1957   PKG_CHECK_MODULES([GRPC], [grpc >= 6.0.0 grpc++ >= 1.16.1 protobuf >= 3.6.1 ], [
1958     AC_CHECK_PROGS([PROTOC], [protoc], [/bin/false])
1959     if test "$PROTOC" = "/bin/false"; then
1960       AC_MSG_FAILURE([grpc requested but protoc not found.])
1961     fi
1962
1963     AC_DEFINE([HAVE_GRPC], [1], [Enable the gRPC northbound plugin])
1964     GRPC=true
1965   ], [
1966     GRPC=false
1967     AC_MSG_ERROR([grpc/grpc++ were not found on your system.])
1968   ])
1969   AC_LANG_POP([C++])
1970 fi
1971
1972 dnl -----
1973 dnl LTTng
1974 dnl -----
1975 if test "$enable_lttng" = "yes"; then
1976   PKG_CHECK_MODULES([UST], [lttng-ust >= 2.9.0], [
1977     AC_DEFINE([HAVE_LTTNG], [1], [Enable LTTng support])
1978     LTTNG=true
1979   ], [
1980     AC_MSG_ERROR([configuration specifies --enable-lttng but lttng-ust was not found])
1981   ])
1982 fi
1983
1984 dnl ----
1985 dnl USDT
1986 dnl ----
1987 if test "$enable_usdt" = "yes"; then
1988   AC_CHECK_HEADERS([sys/sdt.h], [
1989     AC_DEFINE([HAVE_USDT], [1], [Enable USDT probes])
1990     USDT=true
1991   ], [
1992     AC_MSG_ERROR([configuration specifies --enable-usdt but no USDT kernel headers (sys/sdt.h) found])
1993   ])
1994 fi
1995
1996 dnl ------
1997 dnl ZeroMQ
1998 dnl ------
1999 if test "$enable_zeromq" != "no"; then
2000   PKG_CHECK_MODULES([ZEROMQ], [libzmq >= 4.0.0], [
2001     AC_DEFINE([HAVE_ZEROMQ], [1], [Enable ZeroMQ support])
2002     ZEROMQ=true
2003   ], [
2004     if test "$enable_zeromq" = "yes"; then
2005       AC_MSG_ERROR([configuration specifies --enable-zeromq but libzmq was not found])
2006     fi
2007   ])
2008 fi
2009
2010 dnl ------------------------------------
2011 dnl Enable RPKI and add librtr to libs
2012 dnl ------------------------------------
2013 if test "$enable_rpki" = "yes"; then
2014   PKG_CHECK_MODULES([RTRLIB], [rtrlib >= 0.5.0],
2015       [RPKI=true],
2016       [RPKI=false
2017       AC_MSG_ERROR([rtrlib was not found on your system or is too old.])]
2018   )
2019 fi
2020
2021 dnl ------------------------------------
2022 dnl pimd is not supported on OpenBSD and MacOS
2023 dnl ------------------------------------
2024 if test "$enable_pimd" != "no"; then
2025 AC_MSG_CHECKING([for pimd OS support])
2026 case "$host_os" in
2027   darwin*)
2028     AC_MSG_RESULT([no])
2029     enable_pimd="no"
2030     ;;
2031   openbsd*)
2032     AC_MSG_RESULT([no])
2033     enable_pimd="no"
2034     ;;
2035   *)
2036     AC_MSG_RESULT([yes])
2037     ;;
2038 esac
2039 fi
2040
2041 dnl -------------------------------------
2042 dnl VRRP is only supported on linux
2043 dnl -------------------------------------
2044 if test "$enable_vrrpd" != "no"; then
2045 AC_MSG_CHECKING([for VRRP OS support])
2046 case "$host_os" in
2047   linux*)
2048     AC_MSG_RESULT([yes])
2049     ;;
2050   *)
2051     AC_MSG_RESULT([no])
2052     enable_vrrpd="no"
2053     ;;
2054 esac
2055 fi
2056
2057 dnl ------------------------------------------
2058 dnl Check whether rtrlib was build with ssh support
2059 dnl ------------------------------------------
2060 AC_MSG_CHECKING([whether the RTR Library is compiled with SSH])
2061 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "rtrlib/rtrlib.h"]],
2062                         [[struct tr_ssh_config config;]])],
2063         [AC_MSG_RESULT([yes])
2064         AC_DEFINE([FOUND_SSH], [1], [found_ssh])],
2065         AC_MSG_RESULT([no])
2066 )
2067
2068 dnl ---------------
2069 dnl dlopen & dlinfo
2070 dnl ---------------
2071 LIBS_save="$LIBS"
2072 AC_SEARCH_LIBS([dlopen], [dl dld], [], [
2073   AC_MSG_ERROR([unable to find the dlopen()])
2074 ])
2075
2076 AC_CHECK_HEADERS([link.h])
2077
2078 AC_CACHE_CHECK([for dlinfo(RTLD_DI_ORIGIN)], [frr_cv_rtld_di_origin], [
2079   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2080 #include <stdlib.h>
2081 #ifdef HAVE_LINK_H
2082 #include <link.h>
2083 #endif
2084 #include <dlfcn.h>
2085 ]], [[
2086   char origin[1];
2087   dlinfo (NULL, RTLD_DI_ORIGIN, &origin);
2088 ]])], [
2089     frr_cv_rtld_di_origin=yes
2090   ], [
2091     frr_cv_rtld_di_origin=no
2092   ])
2093 ])
2094 if test "$frr_cv_rtld_di_origin" = "yes"; then
2095   AC_DEFINE([HAVE_DLINFO_ORIGIN], [1], [Have dlinfo RTLD_DI_ORIGIN])
2096 fi
2097
2098 AC_CACHE_CHECK([for dlinfo(RTLD_DI_LINKMAP)], [frr_cv_rtld_di_linkmap], [
2099   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2100 #include <stdlib.h>
2101 #ifdef HAVE_LINK_H
2102 #include <link.h>
2103 #endif
2104 #include <dlfcn.h>
2105 ]], [[
2106   struct link_map *lm = NULL;
2107   dlinfo (NULL, RTLD_DI_LINKMAP, &lm);
2108 ]])], [
2109     frr_cv_rtld_di_linkmap=yes
2110   ], [
2111     frr_cv_rtld_di_linkmap=no
2112   ])
2113 ])
2114 if test "$frr_cv_rtld_di_linkmap" = "yes"; then
2115   AC_DEFINE([HAVE_DLINFO_LINKMAP], [1], [Have dlinfo RTLD_DI_LINKMAP])
2116 fi
2117
2118 LIBDL="$LIBS"
2119 LIBDL="${LIBDL%$LIBS_save}"
2120 LIBDL="${LIBDL#$LIBS_save}"
2121 AC_SUBST([LIBDL])
2122 LIBS="$LIBS_save"
2123 unset LIBS_save
2124
2125 dnl ##########################################################################
2126 dnl test "$enable_clippy_only" != "yes"
2127 fi
2128 dnl END OF LARGE if block
2129 dnl ##########################################################################
2130
2131 dnl ---------------------------
2132 dnl sockaddr and netinet checks
2133 dnl ---------------------------
2134 AC_CHECK_TYPES([
2135         struct sockaddr_dl,
2136         struct vifctl, struct mfcctl, struct sioc_sg_req,
2137         vifi_t, struct sioc_vif_req, struct igmpmsg,
2138         struct ifaliasreq, struct if6_aliasreq, struct in6_aliasreq,
2139         struct nd_opt_adv_interval,
2140         struct nd_opt_homeagent_info, struct nd_opt_adv_interval,
2141         struct nd_opt_rdnss, struct nd_opt_dnssl],
2142         [], [], FRR_INCLUDES)
2143
2144 AC_CHECK_MEMBERS([struct sockaddr.sa_len,
2145         struct sockaddr_in.sin_len, struct sockaddr_un.sun_len,
2146         struct sockaddr_dl.sdl_len,
2147         struct if6_aliasreq.ifra_lifetime,
2148         struct nd_opt_adv_interval.nd_opt_ai_type],
2149         [], [], FRR_INCLUDES)
2150
2151 dnl ---------------------------
2152 dnl IRDP/pktinfo/icmphdr checks
2153 dnl ---------------------------
2154
2155 AC_CHECK_TYPES([struct in_pktinfo], [
2156   AC_CHECK_TYPES([struct icmphdr], [
2157     IRDP=true
2158   ], [
2159     IRDP=false
2160   ], [FRR_INCLUDES])
2161 ], [
2162   IRDP=false
2163 ], [FRR_INCLUDES])
2164
2165 case "${enable_irdp}" in
2166 yes)
2167   $IRDP || AC_MSG_ERROR(['IRDP requires in_pktinfo at the moment!'])
2168   ;;
2169 no)
2170   IRDP=false
2171   ;;
2172 esac
2173
2174
2175 dnl -----------------------
2176 dnl checking for IP_PKTINFO
2177 dnl -----------------------
2178 AC_MSG_CHECKING([for IP_PKTINFO])
2179 AC_COMPILE_IFELSE(
2180 [ AC_LANG_PROGRAM([[
2181         #include <netdb.h>
2182    ]], [[
2183         int opt = IP_PKTINFO;
2184    ]])
2185 ],[
2186   AC_MSG_RESULT([yes])
2187   AC_DEFINE([HAVE_IP_PKTINFO], [1], [Have IP_PKTINFO])
2188 ],[
2189   AC_MSG_RESULT([no])
2190 ])
2191
2192 dnl ---------------------------
2193 dnl checking for IP_RECVDSTADDR
2194 dnl ---------------------------
2195 AC_MSG_CHECKING([for IP_RECVDSTADDR])
2196 AC_COMPILE_IFELSE(
2197 [ AC_LANG_PROGRAM([[
2198         #include <netinet/in.h>
2199   ]], [[
2200         int opt = IP_RECVDSTADDR;
2201   ]])
2202 ],[
2203   AC_MSG_RESULT([yes])
2204   AC_DEFINE([HAVE_IP_RECVDSTADDR], [1], [Have IP_RECVDSTADDR])
2205 ],[
2206   AC_MSG_RESULT([no])
2207 ])
2208
2209 dnl ----------------------
2210 dnl checking for IP_RECVIF
2211 dnl ----------------------
2212 AC_MSG_CHECKING([for IP_RECVIF])
2213 AC_COMPILE_IFELSE(
2214 [ AC_LANG_PROGRAM([[
2215         #include <netinet/in.h>
2216   ]], [[
2217         int opt = IP_RECVIF;
2218   ]])
2219 ],[
2220   AC_MSG_RESULT([yes])
2221   AC_DEFINE([HAVE_IP_RECVIF], [1], [Have IP_RECVIF])
2222 ],[
2223   AC_MSG_RESULT([no])
2224 ])
2225
2226 dnl ----------------------
2227 dnl checking for SO_BINDANY
2228 dnl ----------------------
2229 AC_MSG_CHECKING([for SO_BINDANY])
2230 AC_COMPILE_IFELSE(
2231 [ AC_LANG_PROGRAM([[
2232         #include <sys/socket.h>
2233   ]], [[
2234         int opt = SO_BINDANY;
2235   ]])
2236 ],[
2237   AC_MSG_RESULT([yes])
2238   AC_DEFINE([HAVE_SO_BINDANY], [1], [Have SO_BINDANY])
2239 ],[
2240   AC_MSG_RESULT([no])
2241 ])
2242
2243 dnl ----------------------
2244 dnl checking for IP_FREEBIND
2245 dnl ----------------------
2246 AC_MSG_CHECKING([for IP_FREEBIND])
2247 AC_COMPILE_IFELSE(
2248 [ AC_LANG_PROGRAM([[
2249         #include <netinet/in.h>
2250   ]], [[
2251         int opt = IP_FREEBIND;
2252   ]])
2253 ],[
2254   AC_MSG_RESULT([yes])
2255   AC_DEFINE([HAVE_IP_FREEBIND], [1], [Have IP_FREEBIND])
2256 ],[
2257   AC_MSG_RESULT([no])
2258 ])
2259
2260 dnl --------------------------------------
2261 dnl checking for be32dec existence or not
2262 dnl --------------------------------------
2263 AC_CHECK_DECLS([be32enc, be32dec], [], [], [
2264         #ifdef HAVE_SYS_ENDIAN_H
2265         #include <sys/endian.h>
2266         #endif
2267         #ifdef HAVE_ENDIAN_H
2268         #include <endian.h>
2269         #endif
2270 ])
2271
2272 dnl --------------------------------------
2273 dnl checking for clock_time monotonic struct and call
2274 dnl --------------------------------------
2275 AC_CHECK_DECL([CLOCK_MONOTONIC],
2276         [AC_CHECK_LIB([rt], [clock_gettime], [LIBS="$LIBS -lrt"])
2277          AC_DEFINE([HAVE_CLOCK_MONOTONIC], [1], [Have monotonic clock])
2278 ], [AC_MSG_RESULT([no])], [FRR_INCLUDES])
2279
2280 AC_CHECK_DECL([CLOCK_THREAD_CPUTIME_ID], [
2281          AC_DEFINE([HAVE_CLOCK_THREAD_CPUTIME_ID], [1], [Have cpu-time clock])
2282 ], [AC_MSG_RESULT([no])], [FRR_INCLUDES])
2283
2284 AC_SEARCH_LIBS([clock_nanosleep], [rt], [
2285   AC_DEFINE([HAVE_CLOCK_NANOSLEEP], [1], [Have clock_nanosleep()])
2286 ])
2287
2288 dnl --------------------------------------
2289 dnl checking for flex and bison
2290 dnl --------------------------------------
2291
2292 dnl autoconf 2.69 AC_PROG_LEX has no parameters
2293 dnl autoconf 2.70 AC_PROG_LEX prints a deprecation warning without params
2294 m4_if(m4_version_compare(m4_defn([AC_AUTOCONF_VERSION]), [2.70]), [-1], [dnl
2295   dnl autoconf < 2.70
2296   AC_PROG_LEX
2297 ], [
2298   dnl autoconf >= 2.70
2299   AC_PROG_LEX([noyywrap])
2300 ])
2301
2302 AC_MSG_CHECKING([version of flex])
2303 frr_ac_flex_version="$(eval $LEX -V | grep flex | head -n 1)"
2304 frr_ac_flex_version="${frr_ac_flex_version##* }"
2305 AC_MSG_RESULT([$frr_ac_flex_version])
2306 AX_COMPARE_VERSION([$frr_ac_flex_version], [lt], [2.5.20], [
2307   LEX="$SHELL $missing_dir/missing flex"
2308   if test -f "${srcdir}/lib/command_lex.c" -a -f "${srcdir}/lib/command_lex.h"; then
2309     AC_MSG_WARN([using pregenerated flex output files])
2310   else
2311     AC_MSG_ERROR([flex failure and pregenerated files not included (probably a git build)])
2312   fi
2313   AC_SUBST([LEX_OUTPUT_ROOT], [lex.yy])
2314   AC_SUBST([LEXLIB], [''])
2315 ])
2316
2317 AC_PROG_YACC
2318 dnl thanks GNU bison for this b*llshit...
2319 AC_MSG_CHECKING([version of bison])
2320 frr_ac_bison_version="$(eval $YACC -V | grep bison | head -n 1)"
2321 frr_ac_bison_version="${frr_ac_bison_version##* }"
2322 frr_ac_bison_missing="false"
2323 case "x${frr_ac_bison_version}x" in
2324   x2.7*)
2325     BISON_OPENBRACE='"'
2326     BISON_CLOSEBRACE='"'
2327     BISON_VERBOSE=''
2328     AC_MSG_RESULT([$frr_ac_bison_version - 2.7 or older])
2329     ;;
2330   x2.*|x1.*)
2331     AC_MSG_RESULT([$frr_ac_bison_version])
2332     AC_MSG_WARN([installed bison is too old.  Please install GNU bison 2.7.x or newer.])
2333     frr_ac_bison_missing="true"
2334     ;;
2335   x)
2336     AC_MSG_RESULT([none])
2337     AC_MSG_WARN([could not determine bison version.  Please install GNU bison 2.7.x or newer.])
2338     frr_ac_bison_missing="true"
2339     ;;
2340   x3.[012][^0-9]*)
2341     BISON_OPENBRACE='{'
2342     BISON_CLOSEBRACE='}'
2343     BISON_VERBOSE='-Dparse.error=verbose'
2344     AC_MSG_RESULT([$frr_ac_bison_version - 3.0 to 3.2])
2345     ;;
2346   *)
2347     BISON_OPENBRACE='{'
2348     BISON_CLOSEBRACE='}'
2349     BISON_VERBOSE='-Dparse.error=verbose -Wno-yacc'
2350     AC_MSG_RESULT([$frr_ac_bison_version - 3.3 or newer])
2351     ;;
2352 esac
2353 AC_SUBST([BISON_OPENBRACE])
2354 AC_SUBST([BISON_CLOSEBRACE])
2355 AC_SUBST([BISON_VERBOSE])
2356
2357 if $frr_ac_bison_missing; then
2358   YACC="$SHELL $missing_dir/missing bison -y"
2359   if test -f "${srcdir}/lib/command_parse.c" -a -f "${srcdir}/lib/command_parse.h"; then
2360     AC_MSG_WARN([using pregenerated bison output files])
2361   else
2362     AC_MSG_ERROR([bison failure and pregenerated files not included (probably a git build)])
2363   fi
2364 fi
2365
2366 dnl -------------------
2367 dnl capabilities checks
2368 dnl -------------------
2369 if test "$enable_capabilities" != "no"; then
2370   AC_MSG_CHECKING([whether prctl PR_SET_KEEPCAPS is available])
2371   AC_COMPILE_IFELSE(
2372   [ AC_LANG_PROGRAM([[
2373         #include <sys/prctl.h>
2374     ]], [[
2375         prctl(PR_SET_KEEPCAPS, 1, 0, 0, 0);
2376     ]])
2377   ],[AC_MSG_RESULT([yes])
2378      AC_DEFINE([HAVE_PR_SET_KEEPCAPS], [1], [prctl])
2379      frr_ac_keepcaps="yes"
2380   ],[AC_MSG_RESULT(no)
2381   ])
2382   if test "$frr_ac_keepcaps" = "yes"; then
2383     AC_CHECK_HEADERS([sys/capability.h])
2384   fi
2385   if test "$ac_cv_header_sys_capability_h" = "yes"; then
2386     AC_CHECK_LIB([cap], [cap_init],
2387       [AC_DEFINE([HAVE_LCAPS], [1], [Capabilities])
2388        LIBCAP="-lcap"
2389        frr_ac_lcaps="yes"]
2390     )
2391   fi
2392   if test "$frr_ac_scaps" = "yes" \
2393        -o "$frr_ac_lcaps" = "yes"; then
2394     AC_DEFINE([HAVE_CAPABILITIES], [1], [capabilities])
2395   fi
2396
2397   case "$host_os" in
2398   linux*)
2399     if test "$enable_clippy_only" != "yes"; then
2400     if test "$frr_ac_lcaps" != "yes"; then
2401       AC_MSG_ERROR([libcap and/or its headers were not found.  Running FRR without libcap support built in causes a huge performance penalty.])
2402     fi
2403     fi
2404     ;;
2405   esac
2406 else
2407   case "$host_os" in
2408   linux*)
2409     AC_MSG_WARN([Running FRR without libcap support built in causes a huge performance penalty.])
2410     ;;
2411   esac
2412 fi
2413 AC_SUBST([LIBCAP])
2414
2415 dnl ---------------------------
2416 dnl check for glibc 'backtrace'
2417 dnl ---------------------------
2418 if test "$enable_backtrace" != "no" ; then
2419   backtrace_ok=no
2420   PKG_CHECK_MODULES([UNWIND], [libunwind], [
2421     AC_DEFINE([HAVE_LIBUNWIND], [1], [libunwind])
2422     backtrace_ok=yes
2423   ], [
2424     true
2425   ])
2426
2427   if test "$backtrace_ok" = "no"; then
2428     AC_CHECK_HEADER([unwind.h], [
2429       AC_SEARCH_LIBS([unw_getcontext], [unwind], [
2430         AC_DEFINE([HAVE_LIBUNWIND], [1], [libunwind])
2431         backtrace_ok=yes
2432       ])
2433     ])
2434   fi
2435
2436   if test "$backtrace_ok" = "no"; then
2437     AC_CHECK_HEADER([execinfo.h], [
2438       AC_SEARCH_LIBS([backtrace], [execinfo], [
2439         AC_DEFINE([HAVE_GLIBC_BACKTRACE], [1], [Glibc backtrace])
2440         backtrace_ok=yes
2441       ],, [-lm])
2442     ])
2443   fi
2444
2445   if test "$enable_backtrace" = "yes" -a "$backtrace_ok" = "no"; then
2446     dnl user explicitly requested backtrace but we failed to find support
2447     AC_MSG_FAILURE([failed to find backtrace or libunwind support])
2448   fi
2449 fi
2450
2451 dnl -----------------------------------------
2452 dnl check for malloc mallinfo struct and call
2453 dnl this must try and link using LIBS, in
2454 dnl order to check no alternative allocator
2455 dnl has been specified, which might not provide
2456 dnl mallinfo
2457 dnl -----------------------------------------
2458 AC_CHECK_HEADERS([malloc.h malloc_np.h malloc/malloc.h],,, [FRR_INCLUDES])
2459
2460 AC_CACHE_CHECK([whether mallinfo is available], [frr_cv_mallinfo], [
2461   AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2462 #ifdef HAVE_MALLOC_H
2463 #include <malloc.h>
2464 #endif
2465 #ifdef HAVE_MALLOC_NP_H
2466 #include <malloc_np.h>
2467 #endif
2468 #ifdef HAVE_MALLOC_MALLOC_H
2469 #include <malloc/malloc.h>
2470 #endif
2471 ]], [[
2472 struct mallinfo ac_x; ac_x = mallinfo ();
2473 ]])], [
2474     frr_cv_mallinfo=yes
2475   ], [
2476     frr_cv_mallinfo=no
2477   ])
2478 ])
2479 if test "$frr_cv_mallinfo" = "yes"; then
2480   AC_DEFINE([HAVE_MALLINFO], [1], [mallinfo])
2481 fi
2482
2483 AC_CACHE_CHECK([whether mallinfo2 is available], [frr_cv_mallinfo2], [
2484   AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2485 #ifdef HAVE_MALLOC_H
2486 #include <malloc.h>
2487 #endif
2488 #ifdef HAVE_MALLOC_NP_H
2489 #include <malloc_np.h>
2490 #endif
2491 #ifdef HAVE_MALLOC_MALLOC_H
2492 #include <malloc/malloc.h>
2493 #endif
2494 ]], [[
2495 struct mallinfo2 ac_x; ac_x = mallinfo2 ();
2496 ]])], [
2497     frr_cv_mallinfo2=yes
2498   ], [
2499     frr_cv_mallinfo2=no
2500   ])
2501 ])
2502 if test "$frr_cv_mallinfo2" = "yes"; then
2503   AC_DEFINE([HAVE_MALLINFO2], [1], [mallinfo2])
2504 fi
2505
2506 AC_MSG_CHECKING([whether malloc_usable_size is available])
2507 AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2508 #ifdef HAVE_MALLOC_H
2509 #include <malloc.h>
2510 #endif
2511 #ifdef HAVE_MALLOC_MALLOC_H
2512 #include <malloc/malloc.h>
2513 #endif
2514 ]], [[
2515 size_t ac_x; ac_x = malloc_usable_size(NULL);
2516 ]])], [
2517   AC_MSG_RESULT([yes])
2518   AC_DEFINE([HAVE_MALLOC_USABLE_SIZE], [1], [malloc_usable_size])
2519 ], [
2520   AC_MSG_RESULT([no])
2521
2522   AC_MSG_CHECKING([whether malloc_size is available])
2523   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2524 #ifdef HAVE_MALLOC_H
2525 #include <malloc.h>
2526 #endif
2527 #ifdef HAVE_MALLOC_MALLOC_H
2528 #include <malloc/malloc.h>
2529 #endif
2530 ]], [[
2531 size_t ac_x; ac_x = malloc_size(NULL);
2532 ]])], [
2533     AC_MSG_RESULT([yes])
2534     AC_DEFINE([HAVE_MALLOC_SIZE], [1], [malloc_size])
2535   ], [
2536     AC_MSG_RESULT([no])
2537   ])
2538 ])
2539
2540 dnl ----------
2541 dnl configure date
2542 dnl ----------
2543 dev_version=`echo $VERSION | grep dev`
2544 #don't expire deprecated code in non 'dev' branch
2545 if test "$dev_version" = ""; then
2546    CONFDATE=0
2547 else
2548    CONFDATE=`date '+%Y%m%d'`
2549 fi
2550 AC_SUBST([CONFDATE])
2551
2552 dnl ------------------------------
2553 dnl set paths for state directory
2554 dnl ------------------------------
2555 AC_MSG_CHECKING([directory to use for state file])
2556 if test "$prefix" = "NONE"; then
2557   frr_statedir_prefix="";
2558 else
2559   frr_statedir_prefix=${prefix}
2560 fi
2561 if test "$localstatedir" = '${prefix}/var'; then
2562   for FRR_STATE_DIR in ${frr_statedir_prefix}/var/run dnl
2563                         ${frr_statedir_prefix}/var/adm dnl
2564                         ${frr_statedir_prefix}/etc dnl
2565                         /var/run        dnl
2566                         /var/adm        dnl
2567                         /etc            dnl
2568                         /dev/null;
2569   do
2570     test -d $FRR_STATE_DIR && break
2571   done
2572   frr_statedir=$FRR_STATE_DIR
2573 else
2574   frr_statedir=${localstatedir}
2575 fi
2576 if test "$frr_statedir" = "/dev/null"; then
2577     AC_MSG_ERROR([STATE DIRECTORY NOT FOUND! FIX OR SPECIFY --localstatedir!])
2578 fi
2579 AC_MSG_RESULT([${frr_statedir}])
2580 AC_SUBST([frr_statedir])
2581
2582 AC_DEFINE_UNQUOTED([LDPD_SOCKET], ["$frr_statedir%s%s/ldpd.sock"], [ldpd control socket])
2583 AC_DEFINE_UNQUOTED([ZEBRA_SERV_PATH], ["$frr_statedir%s%s/zserv.api"], [zebra api socket])
2584 AC_DEFINE_UNQUOTED([BFDD_CONTROL_SOCKET], ["$frr_statedir%s%s/bfdd.sock"], [bfdd control socket])
2585 AC_DEFINE_UNQUOTED([OSPFD_GR_STATE], ["$frr_statedir%s/ospfd-gr.json"], [ospfd GR state information])
2586 AC_DEFINE_UNQUOTED([OSPF6D_GR_STATE], ["$frr_statedir/ospf6d-gr.json"], [ospf6d GR state information])
2587 AC_DEFINE_UNQUOTED([DAEMON_VTY_DIR], ["$frr_statedir%s%s"], [daemon vty directory])
2588 AC_DEFINE_UNQUOTED([DAEMON_DB_DIR], ["$frr_statedir"], [daemon database directory])
2589
2590 dnl autoconf does this, but it does it too late...
2591 test "$prefix" = "NONE" && prefix=$ac_default_prefix
2592 test "$exec_prefix" = "NONE" && exec_prefix='${prefix}'
2593
2594 dnl get the full path, recursing through variables...
2595 vtysh_bin="$bindir/vtysh"
2596 for I in 1 2 3 4 5 6 7 8 9 10; do
2597         eval vtysh_bin="\"$vtysh_bin\""
2598 done
2599 AC_DEFINE_UNQUOTED([VTYSH_BIN_PATH], ["$vtysh_bin"], [path to vtysh binary])
2600 AC_SUBST([vtysh_bin])
2601
2602 CFG_SYSCONF="$sysconfdir"
2603 CFG_SBIN="$sbindir"
2604 CFG_STATE="$frr_statedir"
2605 CFG_MODULE="$moduledir"
2606 CFG_YANGMODELS="$yangmodelsdir"
2607 CFG_SCRIPT="$scriptdir"
2608 for I in 1 2 3 4 5 6 7 8 9 10; do
2609         eval CFG_SYSCONF="\"$CFG_SYSCONF\""
2610         eval CFG_SBIN="\"$CFG_SBIN\""
2611         eval CFG_STATE="\"$CFG_STATE\""
2612         eval CFG_MODULE="\"$CFG_MODULE\""
2613         eval CFG_YANGMODELS="\"$CFG_YANGMODELS\""
2614         eval CFG_SCRIPT="\"$CFG_SCRIPT\""
2615 done
2616 AC_SUBST([CFG_SYSCONF])
2617 AC_SUBST([CFG_SBIN])
2618 AC_SUBST([CFG_STATE])
2619 AC_SUBST([CFG_MODULE])
2620 AC_SUBST([CFG_SCRIPT])
2621 AC_SUBST([CFG_YANGMODELS])
2622 AC_DEFINE_UNQUOTED([MODULE_PATH], ["$CFG_MODULE"], [path to modules])
2623 AC_DEFINE_UNQUOTED([SCRIPT_PATH], ["$CFG_SCRIPT"], [path to scripts])
2624 AC_DEFINE_UNQUOTED([YANG_MODELS_PATH], ["$CFG_YANGMODELS"], [path to YANG data models])
2625 AC_DEFINE_UNQUOTED([WATCHFRR_SH_PATH], ["${CFG_SBIN%/}/watchfrr.sh"], [path to watchfrr.sh])
2626
2627 dnl various features
2628 AM_CONDITIONAL([SUPPORT_REALMS], [test "$enable_realms" = "yes"])
2629 AM_CONDITIONAL([ENABLE_BGP_VNC], [test "$enable_bgp_vnc" != "no"])
2630 AM_CONDITIONAL([BGP_BMP], [$bgpd_bmp])
2631 dnl northbound
2632 AM_CONDITIONAL([SQLITE3], [$SQLITE3])
2633 AM_CONDITIONAL([CONFD], [test "$enable_confd" != ""])
2634 AM_CONDITIONAL([SYSREPO], [test "$enable_sysrepo" = "yes"])
2635 AM_CONDITIONAL([GRPC], [test "$enable_grpc" = "yes"])
2636 AM_CONDITIONAL([ZEROMQ], [test "$ZEROMQ" = "true"])
2637 dnl plugins
2638 AM_CONDITIONAL([RPKI], [test "$RPKI" = "true"])
2639 AM_CONDITIONAL([SNMP], [test "$SNMP_METHOD" = "agentx"])
2640 AM_CONDITIONAL([IRDP], [$IRDP])
2641 AM_CONDITIONAL([FPM], [test "$enable_fpm" = "yes"])
2642 AM_CONDITIONAL([HAVE_PROTOBUF], [test "$enable_protobuf" = "yes"])
2643 AM_CONDITIONAL([HAVE_PROTOBUF3], [$PROTO3])
2644
2645 dnl PCEP plugin
2646 AS_IF([test "$enable_pathd" != "no"], [
2647        AC_SUBST([PATHD_PCEP_LIBS], ["pceplib/libpcep_pcc.la"])
2648        AC_SUBST([PATHD_PCEP_INCL], ["-I./pceplib "])
2649        ])
2650 AC_CHECK_LIB([cunit], [CU_initialize_registry], [pcep_cunit=yes],[pcep_cunit=no])
2651 AM_CONDITIONAL([PATHD_PCEP_TEST], [test "x${pcep_cunit}" = xyes])
2652 AC_CHECK_PROG(VALGRIND_CHECK, valgrind, yes)
2653 AM_CONDITIONAL([HAVE_VALGRIND_PCEP], [test "$VALGRIND_CHECK" = "yes"])
2654
2655 dnl daemons
2656 AM_CONDITIONAL([VTYSH], [test "$VTYSH" = "vtysh"])
2657 AM_CONDITIONAL([ZEBRA], [test "$enable_zebra" != "no"])
2658 AM_CONDITIONAL([BGPD], [test "$enable_bgpd" != "no"])
2659 AM_CONDITIONAL([RIPD], [test "$enable_ripd" != "no"])
2660 AM_CONDITIONAL([OSPFD], [test "$enable_ospfd" != "no"])
2661 AM_CONDITIONAL([LDPD], [test "$enable_ldpd" != "no"])
2662 AM_CONDITIONAL([BFDD], [test "$BFDD" = "bfdd"])
2663 AM_CONDITIONAL([NHRPD], [test "$NHRPD" = "nhrpd"])
2664 AM_CONDITIONAL([EIGRPD], [test "$enable_eigrpd" != "no"])
2665 AM_CONDITIONAL([WATCHFRR], [test "$WATCHFRR" = "watchfrr"])
2666 AM_CONDITIONAL([OSPFCLIENT], [test "$OSPFCLIENT" = "ospfclient"])
2667 AM_CONDITIONAL([RIPNGD], [test "$enable_ripngd" != "no"])
2668 AM_CONDITIONAL([BABELD], [test "$enable_babeld" != "no"])
2669 AM_CONDITIONAL([OSPF6D], [test "$enable_ospf6d" != "no"])
2670 AM_CONDITIONAL([ISISD], [test "$enable_isisd" != "no"])
2671 AM_CONDITIONAL([PIMD], [test "$enable_pimd" != "no"])
2672 AM_CONDITIONAL([PBRD], [test "$enable_pbrd" != "no"])
2673 AM_CONDITIONAL([SHARPD], [test "$enable_sharpd" = "yes"])
2674 AM_CONDITIONAL([STATICD], [test "$enable_staticd" != "no"])
2675 AM_CONDITIONAL([FABRICD], [test "$enable_fabricd" != "no"])
2676 AM_CONDITIONAL([VRRPD], [test "$enable_vrrpd" != "no"])
2677 AM_CONDITIONAL([PATHD], [test "$enable_pathd" != "no"])
2678 AM_CONDITIONAL([PATHD_PCEP], [test "$enable_pathd" != "no"])
2679
2680 AC_CONFIG_FILES([Makefile],[
2681         test "$enable_dev_build" = "yes" && makefile_devbuild="--dev-build"
2682         ${PYTHON} "${ac_abs_top_srcdir}/python/makefile.py" ${makefile_devbuild} || exit 1
2683 ], [
2684         PYTHON="$PYTHON"
2685         enable_dev_build="$enable_dev_build"
2686 ])
2687
2688 AC_CONFIG_FILES([
2689           config.version
2690           redhat/frr.spec
2691           alpine/APKBUILD
2692           snapcraft/snapcraft.yaml
2693           lib/version.h
2694           tests/lib/cli/test_cli.refout
2695           pkgsrc/bgpd.sh pkgsrc/ospf6d.sh pkgsrc/ospfd.sh
2696           pkgsrc/ripd.sh pkgsrc/ripngd.sh pkgsrc/zebra.sh
2697           pkgsrc/eigrpd.sh])
2698
2699 AC_CONFIG_FILES([vtysh/extract.pl], [chmod +x vtysh/extract.pl])
2700 AC_CONFIG_FILES([tools/frr], [chmod +x tools/frr])
2701 AC_CONFIG_FILES([tools/watchfrr.sh], [chmod +x tools/watchfrr.sh])
2702 AC_CONFIG_FILES([tools/frrinit.sh], [chmod +x tools/frrinit.sh])
2703 AC_CONFIG_FILES([tools/frrcommon.sh])
2704 AC_CONFIG_FILES([tools/frr.service])
2705 AC_CONFIG_FILES([tools/frr@.service])
2706
2707 AS_IF([test "$with_pkg_git_version" = "yes"], [
2708     AC_CONFIG_COMMANDS([lib/gitversion.h], [
2709         dst="${ac_abs_top_builddir}/lib/gitversion.h"
2710         ${PERL} "${ac_abs_top_srcdir}/lib/gitversion.pl" \
2711                 "${ac_abs_top_srcdir}" \
2712                 > "${dst}.tmp"
2713         test -f "$dst" \
2714                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
2715                 && rm "${dst}.tmp" \
2716                 || mv "${dst}.tmp" "${dst}"
2717     ], [
2718         PERL="$PERL"
2719     ])
2720 ])
2721
2722 ## Hack, but working solution to avoid rebuilding of frr.info.
2723 ## It's already in CVS until texinfo 4.7 is more common.
2724 AC_OUTPUT
2725
2726 if test "$enable_rpath" = "yes" ; then
2727         true
2728 else
2729         # See https://old-en.opensuse.org/openSUSE:Packaging_Guidelines#Removing_Rpath
2730         sed -e 's|^hardcode_libdir_flag_spec=.*|hardcode_libdir_flag_spec=""|g' libtool > libtool.sed && cat libtool.sed > libtool
2731         sed -e 's|^runpath_var=LD_RUN_PATH|runpath_var=DIE_RPATH_DIE|g'         libtool > libtool.sed && cat libtool.sed > libtool
2732         test -f libtool.sed && rm libtool.sed
2733 fi
2734
2735 echo "
2736 FRRouting configuration
2737 ------------------------------
2738 FRR version             : ${PACKAGE_VERSION}
2739 host operating system   : ${host_os}
2740 source code location    : ${srcdir}
2741 compiler                : ${CC}
2742 compiler flags          : ${CFLAGS} ${WERROR} ${AC_CFLAGS} ${SAN_FLAGS}
2743 make                    : ${MAKE-make}
2744 linker flags            : ${LDFLAGS} ${SAN_FLAGS} ${LIBS} ${LIBCAP} ${LIBREADLINE} ${LIBM}
2745 state file directory    : ${frr_statedir}
2746 config file directory   : `eval echo \`echo ${sysconfdir}\``
2747 module directory        : ${CFG_MODULE}
2748 script directory        : ${CFG_SCRIPT}
2749 user to run as          : ${enable_user}
2750 group to run as         : ${enable_group}
2751 group for vty sockets   : ${enable_vty_group}
2752 config file mask        : ${enable_configfile_mask}
2753 log file mask           : ${enable_logfile_mask}
2754 zebra protobuf enabled  : ${enable_protobuf:-no}
2755 vici socket path        : ${vici_socket}
2756
2757 The above user and group must have read/write access to the state file
2758 directory and to the config files in the config file directory."
2759
2760 if test -n "$enable_datacenter"; then
2761   AC_MSG_WARN([The --enable-datacenter compile time option is deprecated.  Please modify the init script to pass -F datacenter to the daemons instead.])
2762 fi
2763 if test -n "$enable_time_check"; then
2764   AC_MSG_WARN([The --enable-time-check compile time option is deprecated.  Please use the service cputime-stats configuration option instead.])
2765 fi
2766 if test -n "$enable_cpu_time"; then
2767   AC_MSG_WARN([The --enable-cpu-time compile time option is deprecated.  Please use the service cputime-warning NNN configuration option instead.])
2768 fi
2769
2770 if test "$enable_doc" != "no" -a "$frr_py_mod_sphinx" = "false"; then
2771   AC_MSG_WARN([sphinx is missing but required to build documentation])
2772 fi
2773 if test "$frr_py_mod_pytest" = "false"; then
2774   AC_MSG_WARN([pytest is missing, unit tests cannot be performed])
2775 fi