configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 m4_define([lxc_version_major], 2)
   5 m4_define([lxc_version_minor], 0)
   6 m4_define([lxc_version_micro], 0)
   7 m4_define([lxc_version_beta], rc8)
   8 m4_define([lxc_version_abi], 1.2.0)
   9
  10 m4_define([lxc_version_base], [lxc_version_major.lxc_version_minor.lxc_version_micro])
  11 m4_define([lxc_version],
  12           [ifelse(lxc_version_beta, [], [lxc_version_base], [lxc_version_base.lxc_version_beta])])
  13
  14 AC_INIT([lxc], [lxc_version])
  15
  16 # We need pkg-config
  17 PKG_PROG_PKG_CONFIG
  18
  19 AC_SUBST(LXC_VERSION_BASE, lxc_version_base)
  20 AC_SUBST(LXC_VERSION_BETA, lxc_version_beta)
  21
  22 AC_SUBST([LXC_VERSION_MAJOR], [lxc_version_major])
  23 AC_SUBST([LXC_VERSION_MINOR], [lxc_version_minor])
  24 AC_SUBST([LXC_VERSION_MICRO], [lxc_version_micro])
  25 AC_SUBST([LXC_VERSION_ABI], [lxc_version_abi])
  26 AC_SUBST([LXC_VERSION], [lxc_version])
  27
  28 AC_CONFIG_SRCDIR([configure.ac])
  29 AC_CONFIG_AUX_DIR([config])
  30 AC_CONFIG_HEADERS([src/config.h])
  31 AM_INIT_AUTOMAKE([-Wall -Werror -Wno-portability subdir-objects])
  32 AC_CANONICAL_HOST
  33 AM_PROG_CC_C_O
  34 AC_GNU_SOURCE
  35
  36 # Detect the distribution. This is used for the default configuration and
  37 # for some distro-specific build options.
  38 AC_MSG_CHECKING([host distribution])
  39 AC_ARG_WITH(distro, AS_HELP_STRING([--with-distro=DISTRO], [Specify the Linux distribution to target: One of redhat, oracle, centos, fedora, suse, gentoo, debian, arch, slackware, plamo, paldo, openmandriva, pardus, sparclinux, altlinux.]))
  40 if type lsb_release >/dev/null 2>&1 && test "z$with_distro" = "z"; then
  41         with_distro=`lsb_release -is`
  42 fi
  43 if test "z$with_distro" = "z"; then
  44         AC_CHECK_FILE(/etc/redhat-release,with_distro="redhat")
  45         AC_CHECK_FILE(/etc/oracle-release,with_distro="oracle")
  46         AC_CHECK_FILE(/etc/sparclinux-release,with_distro="sparclinux")
  47         AC_CHECK_FILE(/etc/centos-release,with_distro="centos")
  48         AC_CHECK_FILE(/etc/fedora-release,with_distro="fedora")
  49         AC_CHECK_FILE(/etc/SuSE-release,with_distro="suse")
  50         AC_CHECK_FILE(/etc/gentoo-release,with_distro="gentoo")
  51         AC_CHECK_FILE(/etc/debian_version,with_distro="debian")
  52         AC_CHECK_FILE(/etc/arch-release,with_distro="arch")
  53         AC_CHECK_FILE(/etc/slackware-version,with_distro="slackware")
  54         AC_CHECK_FILE(/etc/plamo-version,with_distro="plamo")
  55         AC_CHECK_FILE(/etc/frugalware-release,with_distro="frugalware")
  56         AC_CHECK_FILE(/etc/mandrakelinux-release, with_distro="openmandriva")
  57         AC_CHECK_FILE(/etc/mandriva-release,with_distro="openmandriva")
  58         AC_CHECK_FILE(/etc/pardus-release,with_distro="pardus")
  59         AC_CHECK_FILE(/etc/altlinux-release,with_distro="altlinux")
  60 fi
  61 with_distro=`echo ${with_distro} | tr '[[:upper:]]' '[[:lower:]]'`
  62
  63 if test "z$with_distro" = "zforsparc"; then
  64         with_distro="sparclinux"
  65 fi
  66
  67 if test "z$with_distro" = "z"; then
  68         with_distro="unknown"
  69 fi
  70 case $with_distro in
  71         ubuntu|raspbian)
  72                 distroconf=default.conf.lxcbr
  73                 distrosysconf="$sysconfdir/default"
  74                 ;;
  75         redhat|centos|fedora|oracle|oracleserver|sparclinux|altlinux|suse|opensuse*|plamo)
  76                 distroconf=default.conf.lxcbr
  77                 distrosysconf="$sysconfdir/sysconfig"
  78                 ;;
  79         *)
  80                 distroconf=default.conf.unknown
  81                 distrosysconf="$sysconfdir/default"
  82                 ;;
  83 esac
  84 AC_MSG_RESULT([$with_distro])
  85 AM_CONDITIONAL([HAVE_DEBIAN], [test x"$with_distro" = "xdebian" -o x"$with_distro" = "xubuntu" -o x"$with_distro" = "xraspbian"])
  86 AM_CONDITIONAL([DISTRO_UBUNTU], [test "x$with_distro" = "xubuntu"])
  87
  88 AC_CONFIG_LINKS([config/etc/default.conf:config/etc/${distroconf}])
  89
  90 # Check for init system type
  91 AC_MSG_CHECKING([for init system type])
  92 AC_ARG_WITH([init-script],
  93             [AC_HELP_STRING([--with-init-script@<:@=TYPE@<:@,TYPE,...@:>@@:>@],
  94                             [Type(s) of init script to install: sysvinit, systemd, upstart,
  95                              distro @<:@default=distro@:>@])],[],[with_init_script=distro])
  96 case "$with_init_script" in
  97         distro)
  98                 case $with_distro in
  99                         fedora|altlinux|opensuse*)
 100                                 init_script=systemd
 101                                 ;;
 102                         redhat|centos|oracle|oracleserver|sparclinux|plamo)
 103                                 init_script=sysvinit
 104                                 ;;
 105                         debian|raspbian)
 106                                 init_script=upstart,systemd
 107                                 ;;
 108                         ubuntu)
 109                                 init_script=upstart,systemd
 110                                 ;;
 111                         *)
 112                                 echo -n "Linux distribution init system unknown."
 113                                 init_script=
 114                                 ;;
 115                 esac
 116                 ;;
 117         *)
 118                 init_script=$with_init_script
 119                 ;;
 120 esac
 121
 122 # Check valid init systems were given, run in subshell so we don't mess up IFS
 123 (IFS="," ; for init_sys in $init_script;
 124 do
 125         case "$init_sys" in
 126                 none|sysvinit|systemd|upstart)
 127                         ;;
 128                 *)
 129                         exit 1
 130                         ;;
 131         esac
 132 done) || AC_MSG_ERROR([Unknown init system type in $init_script])
 133
 134 AM_CONDITIONAL([INIT_SCRIPT_SYSV], [echo "$init_script" |grep -q "sysvinit"])
 135 AM_CONDITIONAL([INIT_SCRIPT_SYSTEMD], [echo "$init_script" |grep -q "systemd"])
 136 AM_CONDITIONAL([INIT_SCRIPT_UPSTART], [echo "$init_script" |grep -q "upstart"])
 137 AC_MSG_RESULT($init_script)
 138
 139 # systemd unit dir
 140 AC_ARG_WITH([systemdsystemunitdir],
 141             AS_HELP_STRING([--with-systemdsystemunitdir=DIR], [Directory for systemd service files]),
 142             [],
 143             [with_systemdsystemunitdir=$($PKG_CONFIG --variable=systemdsystemunitdir systemd)])
 144 if test -z "$with_systemdsystemunitdir"; then
 145   with_systemdsystemunitdir=/lib/systemd/system
 146 fi
 147 if test "x$with_systemdsystemunitdir" != "xno"; then
 148   AC_SUBST([SYSTEMD_UNIT_DIR], [$with_systemdsystemunitdir])
 149 fi
 150
 151 # Allow enabling deprecated executables
 152 AC_ARG_ENABLE([deprecated],
 153         [AC_HELP_STRING([--enable-deprecated],
 154         [enable deprecated executables [default=no]])],
 155         [], [enable_deprecated=false])
 156 AM_CONDITIONAL([ENABLE_DEPRECATED], [test "x$enable_deprecated" = "xyes"])
 157
 158 # Allow disabling rpath
 159 AC_ARG_ENABLE([rpath],
 160         [AC_HELP_STRING([--enable-rpath], [set rpath in executables [default=no]])],
 161         [], [enable_rpath=no])
 162 AM_CONDITIONAL([ENABLE_RPATH], [test "x$enable_rpath" = "xyes"])
 163
 164 # Documentation (manpages)
 165 AC_ARG_ENABLE([doc],
 166         [AC_HELP_STRING([--enable-doc], [make man pages [default=auto]])],
 167         [], [enable_doc=auto])
 168
 169 if test "x$enable_doc" = "xyes" -o "x$enable_doc" = "xauto"; then
 170         db2xman=""
 171         dbparsers="docbook2x-man db2x_docbook2man docbook2man docbook-to-man"
 172
 173         AC_MSG_CHECKING(for docbook2x-man)
 174         for name in ${dbparsers}; do
 175                 if "$name" --help >/dev/null 2>&1; then
 176                         db2xman="$name"
 177                         break;
 178                 fi
 179         done
 180
 181         if test -n "${db2xman}"; then
 182                 AC_MSG_RESULT([${db2xman}])
 183                 enable_doc="yes"
 184         else
 185                 AC_MSG_RESULT([no])
 186                 if test "x$enable_doc" = "xyes"; then
 187                         AC_MSG_ERROR([docbook2x-man is required, but could not be found])
 188                 fi
 189                 enable_doc="no"
 190         fi
 191
 192         AC_SUBST(db2xman)
 193 fi
 194 AM_CONDITIONAL([ENABLE_DOCBOOK], [test "x$db2xman" != "x"])
 195 AM_CONDITIONAL([USE_DOCBOOK2X], [test "x$db2xman" != "xdocbook2man"])
 196
 197 if test "x$db2xman" = "xdocbook2man"; then
 198         docdtd="\"-//Davenport//DTD DocBook V3.0//EN\""
 199 else
 200         docdtd="\"-//OASIS//DTD DocBook XML\" \"http://www.oasis-open.org/docbook/xml/4.5/docbookx.dtd\""
 201 fi
 202 AC_SUBST(docdtd)
 203
 204 # Documentation (API)
 205 AC_ARG_ENABLE([api-docs],
 206         [AC_HELP_STRING([--enable-api-docs],
 207         [make API documentation [default=auto]])],
 208         [], [enable_api_docs=auto])
 209
 210 if test "x$enable_api_docs" = "xyes" -o "x$enable_api_docs" = "xauto"; then
 211         AC_CHECK_PROGS([HAVE_DOXYGEN],[doxygen])
 212         AC_SUBST([HAVE_DOXYGEN])
 213
 214         if test "x$HAVE_DOXYGEN" != "x"; then
 215                 enable_api_docs="yes"
 216         else
 217                 if test "x$enable_api_docs" = "xyes"; then
 218                         AC_MSG_ERROR([doxygen is required, but could not be found])
 219                 fi
 220                 enable_api_docs="no"
 221         fi
 222 fi
 223
 224 AM_CONDITIONAL([ENABLE_API_DOCS], [test "x$HAVE_DOXYGEN" != "x"])
 225
 226 # Apparmor
 227 AC_ARG_ENABLE([apparmor],
 228         [AC_HELP_STRING([--enable-apparmor], [enable apparmor support [default=auto]])],
 229         [], [enable_apparmor=auto])
 230
 231 if test "$enable_apparmor" = "auto" ; then
 232         AC_CHECK_LIB([apparmor],[aa_change_profile],[enable_apparmor=yes], [enable_apparmor=no])
 233 fi
 234 AM_CONDITIONAL([ENABLE_APPARMOR], [test "x$enable_apparmor" = "xyes"])
 235
 236 AC_CHECK_LIB([gnutls], [gnutls_hash_fast], [enable_gnutls=yes], [enable_gnutls=no])
 237
 238 AM_COND_IF([ENABLE_APPARMOR],
 239         [AC_CHECK_HEADER([sys/apparmor.h],[],[AC_MSG_ERROR([You must install the AppArmor development package in order to compile lxc])])
 240         AC_CHECK_LIB([apparmor], [aa_change_profile],[],[AC_MSG_ERROR([You must install the AppArmor development package in order to compile lxc])])
 241         AC_SUBST([APPARMOR_LIBS], [-lapparmor])])
 242
 243 # SELinux
 244 AC_ARG_ENABLE([selinux],
 245         [AC_HELP_STRING([--enable-selinux], [enable SELinux support [default=auto]])],
 246         [], [enable_selinux=auto])
 247
 248 if test "x$enable_selinux" = xauto; then
 249         AC_CHECK_LIB([selinux],[setexeccon_raw],[enable_selinux=yes],[enable_selinux=no])
 250 fi
 251 AM_CONDITIONAL([ENABLE_SELINUX], [test "x$enable_selinux" = "xyes"])
 252 AM_COND_IF([ENABLE_SELINUX],
 253         [AC_CHECK_HEADER([selinux/selinux.h],[],[AC_MSG_ERROR([You must install the SELinux development package in order to compile lxc])])
 254         AC_CHECK_LIB([selinux], [setexeccon_raw],[true],[AC_MSG_ERROR([You must install the SELinux development package in order to compile lxc])])
 255         AC_SUBST([SELINUX_LIBS], [-lselinux])])
 256
 257 # Seccomp syscall filter
 258 AC_ARG_ENABLE([seccomp],
 259         [AC_HELP_STRING([--enable-seccomp], [enable seccomp support [default=auto]])],
 260         [], [enable_seccomp=auto])
 261
 262 if test "x$enable_seccomp" = "xauto" ; then
 263         AC_CHECK_LIB([seccomp],[seccomp_init],[enable_seccomp=yes],[enable_seccomp=no])
 264 fi
 265 AM_CONDITIONAL([ENABLE_SECCOMP], [test "x$enable_seccomp" = "xyes"])
 266
 267 AM_COND_IF([ENABLE_SECCOMP],
 268         [PKG_CHECK_MODULES([SECCOMP],[libseccomp],[],[
 269                 AC_CHECK_HEADER([seccomp.h],[],[AC_MSG_ERROR([You must install the seccomp development package in order to compile lxc])])
 270                 AC_CHECK_LIB([seccomp], [seccomp_init],[],[AC_MSG_ERROR([You must install the seccomp development package in order to compile lxc])])
 271                 AC_SUBST([SECCOMP_LIBS], [-lseccomp])
 272                 ])
 273         ])
 274
 275 # cgmanager
 276 AC_ARG_ENABLE([cgmanager],
 277         [AC_HELP_STRING([--enable-cgmanager], [enable cgmanager support [default=auto]])],
 278         [], [enable_cgmanager=auto])
 279
 280 if test "x$enable_cgmanager" = "xauto" ; then
 281         AC_CHECK_LIB([cgmanager],[cgmanager_create],[enable_cgmanager=yes],[enable_cgmanager=no],[-lnih -lnih-dbus -ldbus-1])
 282 fi
 283 AM_CONDITIONAL([ENABLE_CGMANAGER], [test "x$enable_cgmanager" = "xyes"])
 284
 285 AM_COND_IF([ENABLE_CGMANAGER],
 286         [PKG_CHECK_MODULES([CGMANAGER], [libcgmanager])
 287         PKG_CHECK_MODULES([NIH], [libnih >= 1.0.2])
 288         PKG_CHECK_MODULES([NIH_DBUS], [libnih-dbus >= 1.0.0])
 289         PKG_CHECK_MODULES([DBUS], [dbus-1 >= 1.2.16])
 290         ])
 291
 292 AC_MSG_CHECKING(for get_pid_cgroup_abs_sync)
 293 save_LIBS=$LIBS
 294 AC_SEARCH_LIBS([cgmanager_get_pid_cgroup_abs_sync], [cgmanager], [have_abs_cgroups=yes], [have_abs_cgroups=no], [-lnih -lnih-dbus -ldbus-1])
 295 LIBS=$save_LIBS
 296 if test "x$have_abs_cgroups" = "xyes"; then
 297         AC_DEFINE([HAVE_CGMANAGER_GET_PID_CGROUP_ABS_SYNC], 1, [Have cgmanager_get_pid_cgroup_abs_sync])
 298         AC_MSG_RESULT([yes])
 299 else
 300         AC_MSG_RESULT([no])
 301 fi
 302
 303 AC_MSG_CHECKING(for cgmanager_list_controllers)
 304 save_LIBS=$LIBS
 305 AC_SEARCH_LIBS([cgmanager_list_controllers_sync], [cgmanager], [have_list_controllers=yes], [have_list_controllers=no], [-lnih -lnih-dbus -ldbus-1])
 306 LIBS=$save_LIBS
 307 if test "x$have_list_controllers" = "xyes"; then
 308         AC_DEFINE([HAVE_CGMANAGER_LIST_CONTROLLERS], 1, [Have cgmanager_list_controllers])
 309         AC_MSG_RESULT([yes])
 310 else
 311         AC_MSG_RESULT([no])
 312 fi
 313
 314 # Check for static libcap, make sure the function checked for differs from the
 315 # the one checked below so the cache doesn't give a wrong answer
 316 OLD_CFLAGS="$CFLAGS"
 317 CFLAGS="$CFLAGS -static"
 318 AC_CHECK_LIB([cap],[cap_init],[have_static_libcap=yes],[have_static_libcap=no])
 319 AM_CONDITIONAL([HAVE_STATIC_LIBCAP], [test "x$have_static_libcap" = "xyes"])
 320 if test "x$have_static_libcap" = "xyes"; then
 321         AC_DEFINE([HAVE_STATIC_LIBCAP], 1, [Have static libcap])
 322 fi
 323 CFLAGS="$OLD_CFLAGS"
 324
 325
 326 # Linux capabilities
 327 AC_ARG_ENABLE([capabilities],
 328         [AC_HELP_STRING([--enable-capabilities], [enable kernel capabilities support [default=auto]])],
 329         [], [enable_capabilities=auto])
 330
 331 if test "x$enable_capabilities" = "xauto"; then
 332         AC_CHECK_LIB([cap],[cap_set_proc],[enable_capabilities=yes],[enable_capabilities=no])
 333 fi
 334 AM_CONDITIONAL([ENABLE_CAP], [test "x$enable_capabilities" = "xyes"])
 335
 336 AM_COND_IF([ENABLE_CAP],
 337         [AC_CHECK_LIB(cap,cap_set_proc,[true],[AC_MSG_ERROR([You are missing libcap support.])])
 338         AC_SUBST([CAP_LIBS], [-lcap])])
 339
 340 # HAVE_SCMP_FILTER_CTX=1 will tell us we have libseccomp api >= 1.0.0
 341 OLD_CFLAGS="$CFLAGS"
 342 CFLAGS="$CFLAGS $SECCOMP_CFLAGS"
 343 AC_CHECK_TYPES([scmp_filter_ctx], [], [], [[#include <seccomp.h>]])
 344 AC_CHECK_DECLS([seccomp_syscall_resolve_name_arch], [], [], [[#include <seccomp.h>]])
 345 CFLAGS="$OLD_CFLAGS"
 346
 347 # Configuration examples
 348 AC_ARG_ENABLE([examples],
 349         [AC_HELP_STRING([--enable-examples], [install examples [default=yes]])],
 350         [], [enable_examples=yes])
 351 AM_CONDITIONAL([ENABLE_EXAMPLES], [test "x$enable_examples" = "xyes"])
 352
 353 # Python3 module and scripts
 354 AC_ARG_ENABLE([python],
 355         [AC_HELP_STRING([--enable-python], [enable python binding [default=auto]])],
 356         [], [enable_python=auto])
 357
 358 if test "x$enable_python" = "xauto"; then
 359         PKG_CHECK_MODULES([PYTHONDEV], [python3 >= 3.2],[enable_python=yes],[enable_python=no])
 360         if test "$CC" = "clang"; then
 361                 enable_python=no
 362         fi
 363 fi
 364
 365 if test "x$enable_python" = "xyes" && test "$CC" = "clang"; then
 366         AC_MSG_ERROR([Python3 is incompatible with the clang compiler])
 367 fi
 368
 369 AM_CONDITIONAL([ENABLE_PYTHON], [test "x$enable_python" = "xyes"])
 370
 371 AM_COND_IF([ENABLE_PYTHON],
 372         [AM_PATH_PYTHON([3.2], [], [AC_MSG_ERROR([You must install python3])])
 373         PKG_CHECK_MODULES([PYTHONDEV], [python3 >= 3.2],[],[AC_MSG_ERROR([You must install python3-dev])])
 374         AC_DEFINE_UNQUOTED([ENABLE_PYTHON], 1, [Python3 is available])])
 375
 376 # Enable dumping stack traces
 377 AC_ARG_ENABLE([mutex-debugging],
 378         [AC_HELP_STRING([--enable-mutex-debugging], [Makes mutexes to report error and provide stack trace [default=no]])],
 379         [], [enable_mutex_debugging=no])
 380 AM_CONDITIONAL([MUTEX_DEBUGGING], [test "x$enable_mutex_debugging" = "xyes"])
 381
 382 AM_COND_IF([MUTEX_DEBUGGING],
 383         AC_DEFINE_UNQUOTED([MUTEX_DEBUGGING], 1, [Enabling mutex debugging]))
 384
 385 # Not in older autoconf versions
 386 # AS_VAR_COPY(DEST, SOURCE)
 387 # -------------------------
 388 # Set the polymorphic shell variable DEST to the contents of the polymorphic
 389 # shell variable SOURCE.
 390 m4_ifdef([AS_VAR_COPY], [],
 391 [AC_DEFUN([AS_VAR_COPY],
 392     [AS_LITERAL_IF([$1[]$2], [$1=$$2], [eval $1=\$$2])])
 393 ])
 394
 395 dnl PKG_CHECK_VAR was introduced with pkg-config 0.28
 396 m4_ifdef([PKG_CHECK_VAR], [],
 397 [AC_DEFUN([PKG_CHECK_VAR],
 398     [AC_REQUIRE([PKG_PROG_PKG_CONFIG])dnl
 399      AC_ARG_VAR([$1], [value of $3 for $2, overriding pkg-config])dnl
 400      _PKG_CONFIG([$1], [variable="][$3]["], [$2])
 401      AS_VAR_COPY([$1], [pkg_cv_][$1])
 402      AS_VAR_IF([$1], [""], [$5], [$4])dnl
 403     ])# PKG_CHECK_VAR
 404 ])
 405
 406 # Lua module and scripts
 407 AC_ARG_ENABLE([lua],
 408         [AC_HELP_STRING([--enable-lua], [enable lua binding [default=auto]])],
 409         [], [enable_lua=auto])
 410
 411 AC_ARG_WITH([lua-pc],
 412         [AS_HELP_STRING(
 413                 [--with-lua-pc=PKG],
 414                 [Specify pkg-config package name for lua]
 415         )], [], [with_lua_pc=no])
 416
 417 if test "x$enable_lua" = "xyes" -a "x$with_lua_pc" != "xno"; then
 418         # exit with error if not found
 419         PKG_CHECK_MODULES([LUA], [$with_lua_pc], [LUAPKGCONFIG=$with_lua_pc])
 420 fi
 421
 422 if test "x$enable_lua" = "xauto" -a "x$with_lua_pc" != "xno"; then
 423         PKG_CHECK_MODULES([LUA], [$with_lua_pc],
 424                 [LUAPKGCONFIG=$with_lua_pc
 425                 enable_lua=yes],
 426                 [enable_lua=no])
 427 fi
 428
 429 if test "x$enable_lua" != "xno"; then
 430         PKG_CHECK_MODULES([LUA], [lua], [LUAPKGCONFIG=lua],
 431                 [PKG_CHECK_MODULES([LUA], [lua5.2], [LUAPKGCONFIG=lua5.2],
 432                         [PKG_CHECK_MODULES([LUA], [lua5.1], [LUAPKGCONFIG=lua5.1],
 433                                 [AS_IF([test "x$enable_lua" = "xyes"],
 434                                         [AC_MSG_ERROR([Lua not found. Please use --with-lua-pc=PKG])],
 435                                         [enable_lua=no])]
 436                         )]
 437                 )])
 438         AS_IF([test "x$LUAPKGCONFIG" != "x"], [enable_lua=yes])
 439 fi
 440
 441 AM_CONDITIONAL([ENABLE_LUA],
 442         [test "x$enable_lua" = "xyes"])
 443
 444 AM_COND_IF([ENABLE_LUA],
 445         [AC_MSG_CHECKING([Lua version])
 446         PKG_CHECK_VAR([LUA_VERSION], [$LUAPKGCONFIG], [V],,
 447                 [PKG_CHECK_VAR([LUA_VERSION], [$LUAPKGCONFIG], [major_version])])
 448         AC_MSG_RESULT([$LUA_VERSION])
 449         AC_SUBST([LUA_LIBDIR], [$libdir/lua/$LUA_VERSION])
 450         AC_SUBST([LUA_SHAREDIR], [$datadir/lua/$LUA_VERSION])
 451         ])
 452
 453 # Optional bash integration
 454 AC_ARG_ENABLE([bash],
 455         [AC_HELP_STRING([--enable-bash], [build bash integration [default=yes]])],
 456         [], [enable_bash=yes])
 457 AM_CONDITIONAL([ENABLE_BASH], [test "x$enable_bash" = "xyes"])
 458
 459 # Optional test binaries
 460 AC_ARG_ENABLE([tests],
 461         [AC_HELP_STRING([--enable-tests], [build test/example binaries [default=no]])],
 462         [], [enable_tests=no])
 463 AM_CONDITIONAL([ENABLE_TESTS], [test "x$enable_tests" = "xyes"])
 464
 465 # Allow overriding the default runtime dir (/run)
 466 AC_ARG_WITH([runtime-path],
 467         [AC_HELP_STRING(
 468                 [--with-runtime-path=dir],
 469                 [runtime directory (default: /run)]
 470         )], [], [with_runtime_path=['/run']])
 471
 472 # LXC container path, where the containers are actually stored
 473 # This is overridden by an entry in the file called LXCCONF
 474 # (i.e. /etc/lxc/lxc.conf)
 475 AC_ARG_WITH([config-path],
 476         [AC_HELP_STRING(
 477                 [--with-config-path=dir],
 478                 [lxc configuration repository path]
 479         )], [], [with_config_path=['${localstatedir}/lib/lxc']])
 480
 481 # The path of the global lxc configuration file.
 482 AC_ARG_WITH([global-conf],
 483         [AC_HELP_STRING(
 484                 [--with-global-conf=dir],
 485                 [global lxc configuration file]
 486         )], [], [with_global_conf=['${sysconfdir}/lxc/lxc.conf']])
 487
 488 # The path of the userns network configuration file
 489 AC_ARG_WITH([usernic-conf],
 490         [AC_HELP_STRING(
 491                 [--with-usernic-conf],
 492                 [user network interface configuration file]
 493         )], [], [with_usernic_conf=['${sysconfdir}/lxc/lxc-usernet']])
 494
 495 # The path of the runtime usernic database
 496 AC_ARG_WITH([usernic-db],
 497         [AC_HELP_STRING(
 498                 [--with-usernic-db],
 499                 [lxc user nic database]
 500         )], [], [with_usernic_db=['${with_runtime_path}/lxc/nics']])
 501
 502 # Rootfs path, where the container mount structure is assembled
 503 AC_ARG_WITH([rootfs-path],
 504         [AC_HELP_STRING(
 505                 [--with-rootfs-path=dir],
 506                 [lxc rootfs mount point]
 507         )], [], [with_rootfs_path=['${libdir}/lxc/rootfs']])
 508
 509 # cgroup pattern specification
 510 AC_ARG_WITH([cgroup-pattern],
 511         [AC_HELP_STRING(
 512                 [--with-cgroup-pattern=pattern],
 513                 [pattern for container cgroups]
 514         )], [], [with_cgroup_pattern=['/lxc/%n']])
 515
 516 # Container log path.  By default, use $lxcpath.
 517 AC_MSG_CHECKING([Whether to place logfiles in container config path])
 518 AC_ARG_ENABLE([configpath-log],
 519         [AC_HELP_STRING([--enable-configpath-log], [use logfiles in config path [default=no]])],
 520         [], [enable_configpath_log=no])
 521 AC_MSG_RESULT([$enable_configpath_log])
 522 AM_CONDITIONAL([USE_CONFIGPATH_LOGS], [test "$enable_configpath_log" = "yes"])
 523
 524 if test "$enable_configpath_log" = "yes"; then
 525         default_log_path="${with_config_path}"
 526 else
 527         default_log_path="${localstatedir}/log/lxc"
 528 fi
 529
 530 AC_ARG_WITH([log-path],
 531         [AC_HELP_STRING(
 532                 [--with-log-path=dir],
 533                 [per container log path]
 534         )], [], [with_log_path=['${default_log_path}']])
 535
 536 # Expand some useful variables
 537 AS_AC_EXPAND(PREFIX, "$prefix")
 538 AS_AC_EXPAND(LIBDIR, "$libdir")
 539 AS_AC_EXPAND(BINDIR, "$bindir")
 540 AS_AC_EXPAND(SBINDIR, "$sbindir")
 541 AS_AC_EXPAND(LIBEXECDIR, "$libexecdir")
 542 AS_AC_EXPAND(INCLUDEDIR, "$includedir")
 543 AS_AC_EXPAND(SYSCONFDIR, "$sysconfdir")
 544 AS_AC_EXPAND(LXC_DEFAULT_CONFIG, "$sysconfdir/lxc/default.conf")
 545 AS_AC_EXPAND(DATADIR, "$datadir")
 546 AS_AC_EXPAND(LOCALSTATEDIR, "$localstatedir")
 547 AS_AC_EXPAND(DOCDIR, "$docdir")
 548 AS_AC_EXPAND(LXC_GENERATE_DATE, "$(date)")
 549 AS_AC_EXPAND(LXCPATH, "$with_config_path")
 550 AS_AC_EXPAND(LXC_GLOBAL_CONF, "$with_global_conf")
 551 AS_AC_EXPAND(LXC_USERNIC_CONF, "$with_usernic_conf")
 552 AS_AC_EXPAND(LXC_USERNIC_DB, "$with_usernic_db")
 553 AS_AC_EXPAND(LXC_DISTRO_SYSCONF, "$distrosysconf")
 554 AS_AC_EXPAND(LXCROOTFSMOUNT, "$with_rootfs_path")
 555 AS_AC_EXPAND(LXCTEMPLATEDIR, "$datadir/lxc/templates")
 556 AS_AC_EXPAND(LXCTEMPLATECONFIG, "$datadir/lxc/config")
 557 AS_AC_EXPAND(LXCHOOKDIR, "$datadir/lxc/hooks")
 558 AS_AC_EXPAND(LXCBINHOOKDIR, "$libexecdir/lxc/hooks")
 559 AS_AC_EXPAND(LXCINITDIR, "$libexecdir")
 560 AS_AC_EXPAND(LOGPATH, "$with_log_path")
 561 AS_AC_EXPAND(RUNTIME_PATH, "$with_runtime_path")
 562 AC_SUBST(DEFAULT_CGROUP_PATTERN, ["$with_cgroup_pattern"])
 563
 564 # We need the install path so criu knows where to reference the hook scripts.
 565 AC_DEFINE_UNQUOTED([DATADIR], "$DATADIR", ["Prefix for shared files."])
 566
 567 # Check for some standard kernel headers
 568 AC_CHECK_HEADERS([linux/unistd.h linux/netlink.h linux/genetlink.h],
 569                                 [],
 570                                 AC_MSG_ERROR([Please install the Linux kernel headers.]),
 571                                 [#include <sys/socket.h>])
 572
 573 # Check for alternate C libraries
 574 AC_MSG_CHECKING(for bionic libc)
 575 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 576         [[#ifndef __ANDROID__
 577 error: Not bionic!
 578 #endif]])],
 579         [is_bionic=yes],
 580         [is_bionic=no])
 581 if test "x$is_bionic" = "xyes"; then
 582         AC_DEFINE([IS_BIONIC], 1, [bionic libc])
 583         AC_MSG_RESULT([yes])
 584 else
 585         AC_MSG_RESULT([no])
 586 fi
 587 AM_CONDITIONAL([IS_BIONIC], [test "x$is_bionic" = "xyes"])
 588
 589 # Some systems lack PR_CAPBSET_DROP definition => HAVE_DECL_PR_CAPBSET_DROP
 590 AC_CHECK_DECLS([PR_CAPBSET_DROP], [], [], [#include <sys/prctl.h>])
 591
 592 # Check for some headers
 593 AC_CHECK_HEADERS([sys/signalfd.h pty.h ifaddrs.h sys/capability.h sys/personality.h utmpx.h sys/timerfd.h])
 594
 595 # Check for some syscalls functions
 596 AC_CHECK_FUNCS([setns pivot_root sethostname unshare rand_r confstr faccessat])
 597
 598 # Check for some functions
 599 AC_CHECK_LIB(pthread, main)
 600 AC_CHECK_FUNCS(pthread_atfork)
 601 AC_CHECK_FUNCS(statvfs)
 602 AC_CHECK_LIB(util, openpty)
 603 AC_CHECK_FUNCS([openpty hasmntopt setmntent endmntent utmpxname])
 604 AC_CHECK_FUNCS([getline],
 605         AM_CONDITIONAL(HAVE_GETLINE, true)
 606         AC_DEFINE(HAVE_GETLINE,1,[Have getline]),
 607         AM_CONDITIONAL(HAVE_GETLINE, false))
 608 AC_CHECK_FUNCS([getsubopt],
 609         AM_CONDITIONAL(HAVE_GETSUBOPT, true)
 610         AC_DEFINE(HAVE_GETSUBOPT,1,[Have getsubopt]),
 611         AM_CONDITIONAL(HAVE_GETSUBOPT, false))
 612 AC_CHECK_FUNCS([fgetln],
 613         AM_CONDITIONAL(HAVE_FGETLN, true)
 614         AC_DEFINE(HAVE_FGETLN,1,[Have fgetln]),
 615         AM_CONDITIONAL(HAVE_FGETLN, false))
 616
 617 # Check for some libraries
 618 AC_SEARCH_LIBS(sem_open, [rt pthread])
 619 AC_SEARCH_LIBS(clock_gettime, [rt])
 620
 621 # Check for some standard binaries
 622 AC_PROG_GCC_TRADITIONAL
 623 AC_PROG_SED
 624
 625 # See if we support thread-local storage.
 626 LXC_CHECK_TLS
 627
 628 if test "x$GCC" = "xyes"; then
 629         CFLAGS="$CFLAGS -Wall -Werror"
 630 fi
 631
 632 # Files requiring some variable expansion
 633 AC_CONFIG_FILES([
 634         Makefile
 635         lxc.pc
 636         lxc.spec
 637
 638         config/Makefile
 639         config/apparmor/Makefile
 640         config/selinux/Makefile
 641         config/bash/Makefile
 642         config/bash/lxc
 643         config/init/Makefile
 644         config/init/common/Makefile
 645         config/init/common/lxc-containers
 646         config/init/common/lxc-net
 647         config/init/systemd/Makefile
 648         config/init/systemd/lxc.service
 649         config/init/systemd/lxc@.service
 650         config/init/systemd/lxc-net.service
 651         config/init/sysvinit/Makefile
 652         config/init/sysvinit/lxc-containers
 653         config/init/sysvinit/lxc-net
 654         config/init/upstart/lxc.conf
 655         config/init/upstart/lxc-net.conf
 656         config/init/upstart/Makefile
 657         config/etc/Makefile
 658         config/templates/Makefile
 659         config/templates/alpine.common.conf
 660         config/templates/alpine.userns.conf
 661         config/templates/archlinux.common.conf
 662         config/templates/archlinux.userns.conf
 663         config/templates/centos.common.conf
 664         config/templates/centos.userns.conf
 665         config/templates/common.conf
 666         config/templates/common.conf.d/Makefile
 667         config/templates/debian.common.conf
 668         config/templates/debian.userns.conf
 669         config/templates/fedora.common.conf
 670         config/templates/fedora.userns.conf
 671         config/templates/gentoo.common.conf
 672         config/templates/gentoo.moresecure.conf
 673         config/templates/gentoo.userns.conf
 674         config/templates/nesting.conf
 675         config/templates/opensuse.common.conf
 676         config/templates/opensuse.userns.conf
 677         config/templates/oracle.common.conf
 678         config/templates/oracle.userns.conf
 679         config/templates/plamo.common.conf
 680         config/templates/plamo.userns.conf
 681         config/templates/slackware.common.conf
 682         config/templates/slackware.userns.conf
 683         config/templates/ubuntu-cloud.common.conf
 684         config/templates/ubuntu-cloud.lucid.conf
 685         config/templates/ubuntu-cloud.userns.conf
 686         config/templates/ubuntu.common.conf
 687         config/templates/ubuntu.lucid.conf
 688         config/templates/ubuntu.userns.conf
 689         config/templates/openwrt.common.conf
 690         config/templates/sparclinux.common.conf
 691         config/templates/sparclinux.userns.conf
 692         config/templates/userns.conf
 693         config/yum/Makefile
 694         config/sysconfig/Makefile
 695         config/sysconfig/lxc
 696
 697         doc/Makefile
 698         doc/api/Makefile
 699         doc/lxc-attach.sgml
 700         doc/lxc-autostart.sgml
 701         doc/lxc-cgroup.sgml
 702         doc/lxc-checkconfig.sgml
 703         doc/lxc-checkpoint.sgml
 704         doc/lxc-clone.sgml
 705         doc/lxc-config.sgml
 706         doc/lxc-console.sgml
 707         doc/lxc-copy.sgml
 708         doc/lxc-create.sgml
 709         doc/lxc-destroy.sgml
 710         doc/lxc-device.sgml
 711         doc/lxc-execute.sgml
 712         doc/lxc-freeze.sgml
 713         doc/lxc-info.sgml
 714         doc/lxc-ls.sgml
 715         doc/lxc-monitor.sgml
 716         doc/lxc-snapshot.sgml
 717         doc/lxc-start-ephemeral.sgml
 718         doc/lxc-start.sgml
 719         doc/lxc-stop.sgml
 720         doc/lxc-top.sgml
 721         doc/lxc-unfreeze.sgml
 722         doc/lxc-unshare.sgml
 723         doc/lxc-user-nic.sgml
 724         doc/lxc-usernsexec.sgml
 725         doc/lxc-wait.sgml
 726
 727         doc/lxc.conf.sgml
 728         doc/lxc.container.conf.sgml
 729         doc/lxc.system.conf.sgml
 730         doc/lxc-usernet.sgml
 731         doc/lxc.sgml
 732         doc/common_options.sgml
 733         doc/see_also.sgml
 734
 735         doc/rootfs/Makefile
 736
 737         doc/examples/Makefile
 738         doc/examples/lxc-macvlan.conf
 739         doc/examples/lxc-vlan.conf
 740         doc/examples/lxc-no-netns.conf
 741         doc/examples/lxc-empty-netns.conf
 742         doc/examples/lxc-phys.conf
 743         doc/examples/lxc-veth.conf
 744         doc/examples/lxc-complex.conf
 745
 746         doc/ja/Makefile
 747         doc/ja/lxc-attach.sgml
 748         doc/ja/lxc-autostart.sgml
 749         doc/ja/lxc-cgroup.sgml
 750         doc/ja/lxc-checkconfig.sgml
 751         doc/ja/lxc-checkpoint.sgml
 752         doc/ja/lxc-clone.sgml
 753         doc/ja/lxc-config.sgml
 754         doc/ja/lxc-console.sgml
 755         doc/ja/lxc-copy.sgml
 756         doc/ja/lxc-create.sgml
 757         doc/ja/lxc-destroy.sgml
 758         doc/ja/lxc-device.sgml
 759         doc/ja/lxc-execute.sgml
 760         doc/ja/lxc-freeze.sgml
 761         doc/ja/lxc-info.sgml
 762         doc/ja/lxc-ls.sgml
 763         doc/ja/lxc-monitor.sgml
 764         doc/ja/lxc-snapshot.sgml
 765         doc/ja/lxc-start-ephemeral.sgml
 766         doc/ja/lxc-start.sgml
 767         doc/ja/lxc-stop.sgml
 768         doc/ja/lxc-top.sgml
 769         doc/ja/lxc-unfreeze.sgml
 770         doc/ja/lxc-unshare.sgml
 771         doc/ja/lxc-user-nic.sgml
 772         doc/ja/lxc-usernsexec.sgml
 773         doc/ja/lxc-wait.sgml
 774
 775         doc/ja/lxc.conf.sgml
 776         doc/ja/lxc.container.conf.sgml
 777         doc/ja/lxc.system.conf.sgml
 778         doc/ja/lxc-usernet.sgml
 779         doc/ja/lxc.sgml
 780         doc/ja/common_options.sgml
 781         doc/ja/see_also.sgml
 782
 783         doc/ko/Makefile
 784         doc/ko/lxc-attach.sgml
 785         doc/ko/lxc-autostart.sgml
 786         doc/ko/lxc-cgroup.sgml
 787         doc/ko/lxc-checkconfig.sgml
 788         doc/ko/lxc-checkpoint.sgml
 789         doc/ko/lxc-clone.sgml
 790         doc/ko/lxc-config.sgml
 791         doc/ko/lxc-console.sgml
 792         doc/ko/lxc-copy.sgml
 793         doc/ko/lxc-create.sgml
 794         doc/ko/lxc-destroy.sgml
 795         doc/ko/lxc-device.sgml
 796         doc/ko/lxc-execute.sgml
 797         doc/ko/lxc-freeze.sgml
 798         doc/ko/lxc-info.sgml
 799         doc/ko/lxc-ls.sgml
 800         doc/ko/lxc-monitor.sgml
 801         doc/ko/lxc-snapshot.sgml
 802         doc/ko/lxc-start-ephemeral.sgml
 803         doc/ko/lxc-start.sgml
 804         doc/ko/lxc-stop.sgml
 805         doc/ko/lxc-top.sgml
 806         doc/ko/lxc-unfreeze.sgml
 807         doc/ko/lxc-unshare.sgml
 808         doc/ko/lxc-user-nic.sgml
 809         doc/ko/lxc-usernsexec.sgml
 810         doc/ko/lxc-wait.sgml
 811
 812         doc/ko/lxc.conf.sgml
 813         doc/ko/lxc.container.conf.sgml
 814         doc/ko/lxc.system.conf.sgml
 815         doc/ko/lxc-usernet.sgml
 816         doc/ko/lxc.sgml
 817         doc/ko/common_options.sgml
 818         doc/ko/see_also.sgml
 819
 820         hooks/Makefile
 821
 822         templates/Makefile
 823         templates/lxc-alpine
 824         templates/lxc-altlinux
 825         templates/lxc-archlinux
 826         templates/lxc-busybox
 827         templates/lxc-centos
 828         templates/lxc-cirros
 829         templates/lxc-debian
 830         templates/lxc-download
 831         templates/lxc-fedora
 832         templates/lxc-gentoo
 833         templates/lxc-openmandriva
 834         templates/lxc-opensuse
 835         templates/lxc-oracle
 836         templates/lxc-plamo
 837         templates/lxc-slackware
 838         templates/lxc-sshd
 839         templates/lxc-ubuntu
 840         templates/lxc-ubuntu-cloud
 841         templates/lxc-sparclinux
 842
 843         src/Makefile
 844         src/lxc/Makefile
 845         src/lxc/lxc-checkconfig
 846         src/lxc/lxc-start-ephemeral
 847         src/lxc/lxc.functions
 848         src/lxc/version.h
 849         src/python-lxc/Makefile
 850         src/python-lxc/setup.py
 851
 852         src/lua-lxc/Makefile
 853
 854         src/tests/Makefile
 855         src/tests/lxc-test-usernic
 856 ])
 857 AC_CONFIG_COMMANDS([default],[[]],[[]])
 858 AC_OUTPUT
 859
 860 # Configuration overview
 861 cat << EOF
 862
 863 ----------------------------
 864 Environment:
 865  - compiler: $CC
 866  - distribution: $with_distro
 867  - init script type(s): $init_script
 868  - rpath: $enable_rpath
 869  - GnuTLS: $enable_gnutls
 870  - Bash integration: $enable_bash
 871
 872 Security features:
 873  - Apparmor: $enable_apparmor
 874  - Linux capabilities: $enable_capabilities
 875  - seccomp: $enable_seccomp
 876  - SELinux: $enable_selinux
 877  - cgmanager: $enable_cgmanager
 878
 879 Bindings:
 880  - lua: $enable_lua
 881  - python3: $enable_python
 882
 883 Documentation:
 884  - examples: $enable_examples
 885  - API documentation: $enable_api_docs
 886  - user documentation: $enable_doc
 887
 888 Debugging:
 889  - tests: $enable_tests
 890  - mutex debugging: $enable_mutex_debugging
 891
 892 Paths:
 893  - Logs in configpath: $enable_configpath_log
 894 EOF
 895
 896 if test "x$ac_cv_func_pthread_atfork" = "xno" ; then
 897 cat << EOF
 898
 899 WARNING: Threading not supported on your platform
 900
 901         You are compiling LXC for bionic target which lacks certain threading related functionality used by LXC API (like pthread_atfork).
 902         Please note that, because of the missing functionality, multithreaded usage of LXC API cause some problems.
 903 EOF
 904 fi