configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 m4_define([lxc_version_major], 1)
   5 m4_define([lxc_version_minor], 0)
   6 m4_define([lxc_version_micro], 0)
   7 m4_define([lxc_version_beta], [])
   8
   9 m4_define([lxc_version_base], [lxc_version_major.lxc_version_minor.lxc_version_micro])
  10 m4_define([lxc_version],
  11           [ifelse(lxc_version_beta, [], [lxc_version_base], [lxc_version_base.lxc_version_beta])])
  12
  13 AC_INIT([lxc], [lxc_version])
  14
  15 # We need pkg-config
  16 PKG_PROG_PKG_CONFIG
  17
  18 AC_SUBST(LXC_VERSION_BASE, lxc_version_base)
  19 AC_SUBST(LXC_VERSION_BETA, lxc_version_beta)
  20
  21 AC_SUBST([LXC_VERSION_MAJOR], [lxc_version_major])
  22 AC_SUBST([LXC_VERSION_MINOR], [lxc_version_minor])
  23 AC_SUBST([LXC_VERSION_MICRO], [lxc_version_micro])
  24 AC_SUBST([LXC_VERSION], [lxc_version])
  25
  26 AC_CONFIG_SRCDIR([configure.ac])
  27 AC_CONFIG_AUX_DIR([config])
  28 AC_CONFIG_HEADERS([src/config.h])
  29 AM_INIT_AUTOMAKE([-Wall -Werror -Wno-portability subdir-objects])
  30 AC_CANONICAL_HOST
  31 AM_PROG_CC_C_O
  32 AC_GNU_SOURCE
  33
  34 # Detect the distribution. This is used for the default configuration and
  35 # for some distro-specific build options.
  36 AC_MSG_CHECKING([host distribution])
  37 AC_ARG_WITH(distro, AS_HELP_STRING([--with-distro=DISTRO], [Specify the Linux distribution to target: One of redhat, oracle, centos, fedora, suse, gentoo, debian, arch, slackware, paldo, openmandriva or pardus.]))
  38 if type lsb_release >/dev/null 2>&1 && test "z$with_distro" = "z"; then
  39         with_distro=`lsb_release -is`
  40 fi
  41 if test "z$with_distro" = "z"; then
  42         AC_CHECK_FILE(/etc/redhat-release,with_distro="redhat")
  43         AC_CHECK_FILE(/etc/oracle-release,with_distro="oracle")
  44         AC_CHECK_FILE(/etc/centos-release,with_distro="centos")
  45         AC_CHECK_FILE(/etc/fedora-release,with_distro="fedora")
  46         AC_CHECK_FILE(/etc/SuSE-release,with_distro="suse")
  47         AC_CHECK_FILE(/etc/gentoo-release,with_distro="gentoo")
  48         AC_CHECK_FILE(/etc/debian_version,with_distro="debian")
  49         AC_CHECK_FILE(/etc/arch-release,with_distro="arch")
  50         AC_CHECK_FILE(/etc/slackware-version,with_distro="slackware")
  51         AC_CHECK_FILE(/etc/frugalware-release,with_distro="frugalware")
  52         AC_CHECK_FILE(/etc/mandrakelinux-release, with_distro="openmandriva")
  53         AC_CHECK_FILE(/etc/mandriva-release,with_distro="openmandriva")
  54         AC_CHECK_FILE(/etc/pardus-release,with_distro="pardus")
  55 fi
  56 with_distro=`echo ${with_distro} | tr '[[:upper:]]' '[[:lower:]]'`
  57
  58 if test "z$with_distro" = "z"; then
  59         with_distro="unknown"
  60 fi
  61 case $with_distro in
  62         ubuntu)
  63                 distroconf=default.conf.ubuntu
  64                 ;;
  65         redhat|centos|fedora|oracle|oracleserver)
  66                 distroconf=default.conf.libvirt
  67                 ;;
  68         *)
  69                 distroconf=default.conf.unknown
  70                 ;;
  71 esac
  72 AC_MSG_RESULT([$with_distro])
  73 AM_CONDITIONAL([HAVE_DEBIAN], [test x"$with_distro" = "xdebian" -o x"$with_distro" = "xubuntu"])
  74 AM_CONDITIONAL([DISTRO_UBUNTU], [test "x$with_distro" = "xubuntu"])
  75
  76 # Check for init system type
  77 AC_MSG_CHECKING([for init system type])
  78 AC_ARG_WITH([init-script],
  79             [AC_HELP_STRING([--with-init-script@<:@=TYPE@<:@,TYPE,...@:>@@:>@],
  80                             [Type(s) of init script to install: sysvinit, systemd, upstart,
  81                              distro @<:@default=distro@:>@])],[],[with_init_script=distro])
  82 case "$with_init_script" in
  83         distro)
  84                 case $with_distro in
  85                         fedora)
  86                                 init_script=systemd
  87                                 ;;
  88                         redhat|centos|oracle|oracleserver)
  89                                 init_script=sysvinit
  90                                 ;;
  91                         debian)
  92                                 init_script=upstart,systemd
  93                                 ;;
  94                         ubuntu)
  95                                 init_script=upstart
  96                                 ;;
  97                         *)
  98                                 echo -n "Linux distribution init system unknown."
  99                                 init_script=
 100                                 ;;
 101                 esac
 102                 ;;
 103         *)
 104                 init_script=$with_init_script
 105                 ;;
 106 esac
 107
 108 # Check valid init systems were given, run in subshell so we don't mess up IFS
 109 (IFS="," ; for init_sys in $init_script;
 110 do
 111         case "$init_sys" in
 112                 none|sysvinit|systemd|upstart)
 113                         ;;
 114                 *)
 115                         exit 1
 116                         ;;
 117         esac
 118 done) || AC_MSG_ERROR([Unknown init system type in $init_script])
 119
 120 AM_CONDITIONAL([INIT_SCRIPT_SYSV], [echo "$init_script" |grep -q "sysvinit"])
 121 AM_CONDITIONAL([INIT_SCRIPT_SYSTEMD], [echo "$init_script" |grep -q "systemd"])
 122 AM_CONDITIONAL([INIT_SCRIPT_UPSTART], [echo "$init_script" |grep -q "upstart"])
 123 AC_MSG_RESULT($init_script)
 124
 125 # Allow disabling rpath
 126 AC_ARG_ENABLE([rpath],
 127         [AC_HELP_STRING([--enable-rpath], [set rpath in executables [default=no]])],
 128         [], [enable_rpath=no])
 129 AM_CONDITIONAL([ENABLE_RPATH], [test "x$enable_rpath" = "xyes"])
 130
 131 # Documentation (manpages)
 132 AC_ARG_ENABLE([doc],
 133         [AC_HELP_STRING([--enable-doc], [make man pages [default=auto]])],
 134         [], [enable_doc=auto])
 135
 136 if test "x$enable_doc" = "xyes" -o "x$enable_doc" = "xauto"; then
 137         db2xman=""
 138         dbparsers="docbook2x-man db2x_docbook2man docbook2man docbook-to-man"
 139
 140         AC_MSG_CHECKING(for docbook2x-man)
 141         for name in ${dbparsers}; do
 142                 if "$name" --help >/dev/null 2>&1; then
 143                         db2xman="$name"
 144                         break;
 145                 fi
 146         done
 147
 148         if test -n "${db2xman}"; then
 149                 AC_MSG_RESULT([${db2xman}])
 150                 enable_doc="yes"
 151         else
 152                 AC_MSG_RESULT([no])
 153                 if test "x$enable_doc" = "xyes"; then
 154                         AC_MSG_ERROR([docbook2x-man is required, but could not be found])
 155                 fi
 156                 enable_doc="no"
 157         fi
 158
 159         AC_SUBST(db2xman)
 160 fi
 161 AM_CONDITIONAL([ENABLE_DOCBOOK], [test "x$db2xman" != "x"])
 162 AM_CONDITIONAL([USE_DOCBOOK2X], [test "x$db2xman" != "xdocbook2man"])
 163
 164 if test "x$db2xman" = "xdocbook2man"; then
 165         docdtd="\"-//Davenport//DTD DocBook V3.0//EN\""
 166 else
 167         docdtd="\"-//OASIS//DTD DocBook XML\" \"http://www.oasis-open.org/docbook/xml/4.5/docbookx.dtd\""
 168 fi
 169 AC_SUBST(docdtd)
 170
 171 # Documentation (API)
 172 AC_ARG_ENABLE([api-docs],
 173         [AC_HELP_STRING([--enable-api-docs],
 174         [make API documentation [default=auto]])],
 175         [], [enable_api_docs=auto])
 176
 177 if test "x$enable_api_docs" = "xyes" -o "x$enable_api_docs" = "xauto"; then
 178         AC_CHECK_PROGS([HAVE_DOXYGEN],[doxygen])
 179         AC_SUBST([HAVE_DOXYGEN])
 180
 181         if test "x$HAVE_DOXYGEN" != "x"; then
 182                 enable_api_docs="yes"
 183         else
 184                 if test "x$enable_api_docs" = "xyes"; then
 185                         AC_MSG_ERROR([doxygen is required, but could not be found])
 186                 fi
 187                 enable_api_docs="no"
 188         fi
 189 fi
 190
 191 AM_CONDITIONAL([ENABLE_API_DOCS], [test "x$HAVE_DOXYGEN" != "x"])
 192
 193 # Apparmor
 194 AC_ARG_ENABLE([apparmor],
 195         [AC_HELP_STRING([--enable-apparmor], [enable apparmor support [default=auto]])],
 196         [], [enable_apparmor=auto])
 197
 198 if test "$enable_apparmor" = "auto" ; then
 199         AC_CHECK_LIB([apparmor],[aa_change_profile],[enable_apparmor=yes], [enable_apparmor=no])
 200 fi
 201 AM_CONDITIONAL([ENABLE_APPARMOR], [test "x$enable_apparmor" = "xyes"])
 202
 203 AC_CHECK_LIB([gnutls], [gnutls_hash_fast], [enable_gnutls=yes], [enable_gnutls=no])
 204
 205 AM_COND_IF([ENABLE_APPARMOR],
 206         [AC_CHECK_HEADER([sys/apparmor.h],[],[AC_MSG_ERROR([You must install the AppArmor development package in order to compile lxc])])
 207         AC_CHECK_LIB([apparmor], [aa_change_profile],[],[AC_MSG_ERROR([You must install the AppArmor development package in order to compile lxc])])
 208         AC_SUBST([APPARMOR_LIBS], [-lapparmor])])
 209
 210 # SELinux
 211 AC_ARG_ENABLE([selinux],
 212         [AC_HELP_STRING([--enable-selinux], [enable SELinux support [default=auto]])],
 213         [], [enable_selinux=auto])
 214
 215 if test "x$enable_selinux" = xauto; then
 216         AC_CHECK_LIB([selinux],[setexeccon_raw],[enable_selinux=yes],[enable_selinux=no])
 217 fi
 218 AM_CONDITIONAL([ENABLE_SELINUX], [test "x$enable_selinux" = "xyes"])
 219 AM_COND_IF([ENABLE_SELINUX],
 220         [AC_CHECK_HEADER([selinux/selinux.h],[],[AC_MSG_ERROR([You must install the SELinux development package in order to compile lxc])])
 221         AC_CHECK_LIB([selinux], [setexeccon_raw],[],[AC_MSG_ERROR([You must install the SELinux development package in order to compile lxc])])
 222         AC_SUBST([SELINUX_LIBS])])
 223
 224 # Seccomp syscall filter
 225 AC_ARG_ENABLE([seccomp],
 226         [AC_HELP_STRING([--enable-seccomp], [enable seccomp support [default=auto]])],
 227         [], [enable_seccomp=auto])
 228
 229 if test "x$enable_seccomp" = "xauto" ; then
 230         AC_CHECK_LIB([seccomp],[seccomp_init],[enable_seccomp=yes],[enable_seccomp=no])
 231 fi
 232 AM_CONDITIONAL([ENABLE_SECCOMP], [test "x$enable_seccomp" = "xyes"])
 233
 234 AM_COND_IF([ENABLE_SECCOMP],
 235         [PKG_CHECK_MODULES([SECCOMP],[libseccomp],[],[
 236                 AC_CHECK_HEADER([seccomp.h],[],[AC_MSG_ERROR([You must install the seccomp development package in order to compile lxc])])
 237                 AC_CHECK_LIB([seccomp], [seccomp_init],[],[AC_MSG_ERROR([You must install the seccomp development package in order to compile lxc])])
 238                 AC_SUBST([SECCOMP_LIBS], [-lseccomp])
 239                 ])
 240         ])
 241
 242 # cgmanager
 243 AC_ARG_ENABLE([cgmanager],
 244         [AC_HELP_STRING([--enable-cgmanager], [enable cgmanager support [default=auto]])],
 245         [], [enable_cgmanager=auto])
 246
 247 if test "x$enable_cgmanager" = "xauto" ; then
 248         AC_CHECK_LIB([cgmanager],[cgmanager_create],[enable_cgmanager=yes],[enable_cgmanager=no],[-lnih -lnih-dbus -ldbus-1])
 249 fi
 250 AM_CONDITIONAL([ENABLE_CGMANAGER], [test "x$enable_cgmanager" = "xyes"])
 251
 252 AM_COND_IF([ENABLE_CGMANAGER],
 253         [PKG_CHECK_MODULES([CGMANAGER], [libcgmanager])
 254         PKG_CHECK_MODULES([NIH], [libnih >= 1.0.2])
 255         PKG_CHECK_MODULES([NIH_DBUS], [libnih-dbus >= 1.0.0])
 256         PKG_CHECK_MODULES([DBUS], [dbus-1 >= 1.2.16])
 257         ])
 258
 259 AC_MSG_CHECKING(for get_pid_cgroup_abs_sync)
 260 AC_SEARCH_LIBS([cgmanager_get_pid_cgroup_abs_sync], [cgmanager], [have_abs_cgroups=yes], [have_abs_cgroups=no], [-lnih -lnih-dbus -ldbus-1])
 261 if test "x$have_abs_cgroups" = "xyes"; then
 262         AC_DEFINE([HAVE_CGMANAGER_GET_PID_CGROUP_ABS_SYNC], 1, [Have cgmanager_get_pid_cgroup_abs_sync])
 263         AC_MSG_RESULT([yes])
 264 else
 265         AC_MSG_RESULT([no])
 266 fi
 267 # Linux capabilities
 268 AC_ARG_ENABLE([capabilities],
 269         [AC_HELP_STRING([--enable-capabilities], [enable kernel capabilities support [default=auto]])],
 270         [], [enable_capabilities=auto])
 271
 272 if test "x$enable_capabilities" = "xauto"; then
 273         AC_CHECK_LIB([cap],[cap_set_proc],[enable_capabilities=yes],[enable_capabilities=no])
 274 fi
 275 AM_CONDITIONAL([ENABLE_CAP], [test "x$enable_capabilities" = "xyes"])
 276
 277 AM_COND_IF([ENABLE_CAP],
 278         [AC_CHECK_LIB(cap,cap_set_proc,[],[AC_MSG_ERROR([You are missing libcap support.])])
 279         AC_SUBST([CAP_LIBS], [-lcap])])
 280
 281 # HAVE_SCMP_FILTER_CTX=1 will tell us we have libseccomp api >= 1.0.0
 282 OLD_CFLAGS="$CFLAGS"
 283 CFLAGS="$CFLAGS $SECCOMP_CFLAGS"
 284 AC_CHECK_TYPES([scmp_filter_ctx], [], [], [[#include <seccomp.h>]])
 285 AC_CHECK_DECLS([seccomp_syscall_resolve_name_arch], [], [], [[#include <seccomp.h>]])
 286 CFLAGS="$OLD_CFLAGS"
 287
 288 # Configuration examples
 289 AC_ARG_ENABLE([examples],
 290         [AC_HELP_STRING([--enable-examples], [install examples [default=yes]])],
 291         [], [enable_examples=yes])
 292 AM_CONDITIONAL([ENABLE_EXAMPLES], [test "x$enable_examples" = "xyes"])
 293
 294 # Python3 module and scripts
 295 AC_ARG_ENABLE([python],
 296         [AC_HELP_STRING([--enable-python], [enable python binding [default=auto]])],
 297         [], [enable_python=auto])
 298
 299 if test "x$enable_python" = "xauto"; then
 300         PKG_CHECK_MODULES([PYTHONDEV], [python3 >= 3.2],[enable_python=yes],[enable_python=no])
 301         if test "$CC" = "clang"; then
 302                 enable_python=no
 303         fi
 304 fi
 305
 306 if test "x$enable_python" = "xyes" && test "$CC" = "clang"; then
 307         AC_MSG_ERROR([Python3 is incompatible with the clang compiler])
 308 fi
 309
 310 AM_CONDITIONAL([ENABLE_PYTHON], [test "x$enable_python" = "xyes"])
 311
 312 AM_COND_IF([ENABLE_PYTHON],
 313         [AM_PATH_PYTHON([3.2], [], [AC_MSG_ERROR([You must install python3])])
 314         PKG_CHECK_MODULES([PYTHONDEV], [python3 >= 3.2],[],[AC_MSG_ERROR([You must install python3-dev])])
 315         AC_DEFINE_UNQUOTED([ENABLE_PYTHON], 1, [Python3 is available])])
 316
 317 # Enable dumping stack traces
 318 AC_ARG_ENABLE([mutex-debugging],
 319         [AC_HELP_STRING([--enable-mutex-debugging], [Makes mutexes to report error and provide stack trace [default=no]])],
 320         [], [enable_mutex_debugging=no])
 321 AM_CONDITIONAL([MUTEX_DEBUGGING], [test "x$enable_mutex_debugging" = "xyes"])
 322
 323 AM_COND_IF([MUTEX_DEBUGGING],
 324         AC_DEFINE_UNQUOTED([MUTEX_DEBUGGING], 1, [Enabling mutex debugging]))
 325
 326 # Not in older autoconf versions
 327 # AS_VAR_COPY(DEST, SOURCE)
 328 # -------------------------
 329 # Set the polymorphic shell variable DEST to the contents of the polymorphic
 330 # shell variable SOURCE.
 331 m4_ifdef([AS_VAR_COPY], [],
 332 [AC_DEFUN([AS_VAR_COPY],
 333     [AS_LITERAL_IF([$1[]$2], [$1=$$2], [eval $1=\$$2])])
 334 ])
 335
 336 dnl PKG_CHECK_VAR was introduced with pkg-config 0.28
 337 m4_ifdef([PKG_CHECK_VAR], [],
 338 [AC_DEFUN([PKG_CHECK_VAR],
 339     [AC_REQUIRE([PKG_PROG_PKG_CONFIG])dnl
 340      AC_ARG_VAR([$1], [value of $3 for $2, overriding pkg-config])dnl
 341      _PKG_CONFIG([$1], [variable="][$3]["], [$2])
 342      AS_VAR_COPY([$1], [pkg_cv_][$1])
 343      AS_VAR_IF([$1], [""], [$5], [$4])dnl
 344     ])# PKG_CHECK_VAR
 345 ])
 346
 347 # Lua module and scripts
 348 AC_ARG_ENABLE([lua],
 349         [AC_HELP_STRING([--enable-lua], [enable lua binding [default=auto]])],
 350         [], [enable_lua=auto])
 351
 352 AC_ARG_WITH([lua-pc],
 353         [AS_HELP_STRING(
 354                 [--with-lua-pc=PKG],
 355                 [Specify pkg-config package name for lua]
 356         )], [], [with_lua_pc=no])
 357
 358 if test "x$enable_lua" = "xyes" -a "x$with_lua_pc" != "xno"; then
 359         # exit with error if not found
 360         PKG_CHECK_MODULES([LUA], [$with_lua_pc], [LUAPKGCONFIG=$with_lua_pc])
 361 fi
 362
 363 if test "x$enable_lua" = "xauto" -a "x$with_lua_pc" != "xno"; then
 364         PKG_CHECK_MODULES([LUA], [$with_lua_pc],
 365                 [LUAPKGCONFIG=$with_lua_pc
 366                 enable_lua=yes],
 367                 [enable_lua=no])
 368 fi
 369
 370 if test "x$enable_lua" != "xno"; then
 371         PKG_CHECK_MODULES([LUA], [lua], [LUAPKGCONFIG=lua],
 372                 [PKG_CHECK_MODULES([LUA], [lua5.2], [LUAPKGCONFIG=lua5.2],
 373                         [PKG_CHECK_MODULES([LUA], [lua5.1], [LUAPKGCONFIG=lua5.1],
 374                                 [AS_IF([test "x$enable_lua" = "xyes"],
 375                                         [AC_MSG_ERROR([Lua not found. Please use --with-lua-pc=PKG])],
 376                                         [enable_lua=no])]
 377                         )]
 378                 )])
 379         AS_IF([test "x$LUAPKGCONFIG" != "x"], [enable_lua=yes])
 380 fi
 381
 382 AM_CONDITIONAL([ENABLE_LUA],
 383         [test "x$enable_lua" = "xyes"])
 384
 385 AM_COND_IF([ENABLE_LUA],
 386         [AC_MSG_CHECKING([Lua version])
 387         PKG_CHECK_VAR([LUA_VERSION], [$LUAPKGCONFIG], [V],,
 388                 [PKG_CHECK_VAR([LUA_VERSION], [$LUAPKGCONFIG], [major_version])])
 389         AC_MSG_RESULT([$LUA_VERSION])
 390         AC_SUBST([LUA_LIBDIR], [$libdir/lua/$LUA_VERSION])
 391         AC_SUBST([LUA_SHAREDIR], [$datadir/lua/$LUA_VERSION])
 392         ])
 393
 394 # Optional bash integration
 395 AC_ARG_ENABLE([bash],
 396         [AC_HELP_STRING([--enable-bash], [build bash integration [default=yes]])],
 397         [], [enable_bash=yes])
 398 AM_CONDITIONAL([ENABLE_BASH], [test "x$enable_bash" = "xyes"])
 399
 400 # Optional test binaries
 401 AC_ARG_ENABLE([tests],
 402         [AC_HELP_STRING([--enable-tests], [build test/example binaries [default=no]])],
 403         [], [enable_tests=no])
 404 AM_CONDITIONAL([ENABLE_TESTS], [test "x$enable_tests" = "xyes"])
 405
 406 # Allow overriding the default runtime dir (/run)
 407 AC_ARG_WITH([runtime-path],
 408         [AC_HELP_STRING(
 409                 [--with-runtime-path=dir],
 410                 [runtime directory (default: /run)]
 411         )], [], [with_runtime_path=['/run']])
 412
 413 # LXC container path, where the containers are actually stored
 414 # This is overridden by an entry in the file called LXCCONF
 415 # (i.e. /etc/lxc/lxc.conf)
 416 AC_ARG_WITH([config-path],
 417         [AC_HELP_STRING(
 418                 [--with-config-path=dir],
 419                 [lxc configuration repository path]
 420         )], [], [with_config_path=['${localstatedir}/lib/lxc']])
 421
 422 # The path of the global lxc configuration file.
 423 AC_ARG_WITH([global-conf],
 424         [AC_HELP_STRING(
 425                 [--with-global-conf=dir],
 426                 [global lxc configuration file]
 427         )], [], [with_global_conf=['${sysconfdir}/lxc/lxc.conf']])
 428
 429 # The path of the userns network configuration file
 430 AC_ARG_WITH([usernic-conf],
 431         [AC_HELP_STRING(
 432                 [--with-usernic-conf],
 433                 [user network interface configuration file]
 434         )], [], [with_usernic_conf=['${sysconfdir}/lxc/lxc-usernet']])
 435
 436 # The path of the runtime usernic database
 437 AC_ARG_WITH([usernic-db],
 438         [AC_HELP_STRING(
 439                 [--with-usernic-db],
 440                 [lxc user nic database]
 441         )], [], [with_usernic_db=['${with_runtime_path}/lxc/nics']])
 442
 443 # Rootfs path, where the container mount structure is assembled
 444 AC_ARG_WITH([rootfs-path],
 445         [AC_HELP_STRING(
 446                 [--with-rootfs-path=dir],
 447                 [lxc rootfs mount point]
 448         )], [], [with_rootfs_path=['${libdir}/lxc/rootfs']])
 449
 450 # cgroup pattern specification
 451 AC_ARG_WITH([cgroup-pattern],
 452         [AC_HELP_STRING(
 453                 [--with-cgroup-pattern=pattern],
 454                 [pattern for container cgroups]
 455         )], [], [with_cgroup_pattern=['/lxc/%n']])
 456
 457 # Container log path.  By default, use $lxcpath.
 458 AC_MSG_CHECKING([Whether to place logfiles in container config path])
 459 AC_ARG_ENABLE([configpath-log],
 460         [AC_HELP_STRING([--enable-configpath-log], [use logfiles in config path [default=no]])],
 461         [], [enable_configpath_log=no])
 462 AC_MSG_RESULT([$enable_configpath_log])
 463 AM_CONDITIONAL([USE_CONFIGPATH_LOGS], [test "$enable_configpath_log" = "yes"])
 464
 465 if test "$enable_configpath_log" = "yes"; then
 466         default_log_path="${with_config_path}"
 467 else
 468         default_log_path="${localstatedir}/log/lxc"
 469 fi
 470
 471 AC_ARG_WITH([log-path],
 472         [AC_HELP_STRING(
 473                 [--with-log-path=dir],
 474                 [per container log path]
 475         )], [], [with_log_path=['${default_log_path}']])
 476
 477 # Expand some useful variables
 478 AS_AC_EXPAND(PREFIX, "$prefix")
 479 AS_AC_EXPAND(LIBDIR, "$libdir")
 480 AS_AC_EXPAND(BINDIR, "$bindir")
 481 AS_AC_EXPAND(SBINDIR, "$sbindir")
 482 AS_AC_EXPAND(LIBEXECDIR, "$libexecdir")
 483 AS_AC_EXPAND(INCLUDEDIR, "$includedir")
 484 AS_AC_EXPAND(SYSCONFDIR, "$sysconfdir")
 485 AS_AC_EXPAND(LXC_DEFAULT_CONFIG, "$sysconfdir/lxc/default.conf")
 486 AS_AC_EXPAND(DATADIR, "$datadir")
 487 AS_AC_EXPAND(LOCALSTATEDIR, "$localstatedir")
 488 AS_AC_EXPAND(DOCDIR, "$docdir")
 489 AS_AC_EXPAND(LXC_DISTRO_CONF, "$distroconf")
 490 AS_AC_EXPAND(LXC_GENERATE_DATE, "$(date)")
 491 AS_AC_EXPAND(LXCPATH, "$with_config_path")
 492 AS_AC_EXPAND(LXC_GLOBAL_CONF, "$with_global_conf")
 493 AS_AC_EXPAND(LXC_USERNIC_CONF, "$with_usernic_conf")
 494 AS_AC_EXPAND(LXC_USERNIC_DB, "$with_usernic_db")
 495 AS_AC_EXPAND(LXCROOTFSMOUNT, "$with_rootfs_path")
 496 AS_AC_EXPAND(LXCTEMPLATEDIR, "$datadir/lxc/templates")
 497 AS_AC_EXPAND(LXCTEMPLATECONFIG, "$datadir/lxc/config")
 498 AS_AC_EXPAND(LXCHOOKDIR, "$datadir/lxc/hooks")
 499 AS_AC_EXPAND(LXCINITDIR, "$libexecdir")
 500 AS_AC_EXPAND(LOGPATH, "$with_log_path")
 501 AS_AC_EXPAND(RUNTIME_PATH, "$with_runtime_path")
 502 AC_SUBST(DEFAULT_CGROUP_PATTERN, ["$with_cgroup_pattern"])
 503
 504 # Check for some standard kernel headers
 505 AC_CHECK_HEADERS([linux/unistd.h linux/netlink.h linux/genetlink.h],
 506                                 [],
 507                                 AC_MSG_ERROR([Please install the Linux kernel headers.]),
 508                                 [#include <sys/socket.h>])
 509
 510 # Check for alternate C libraries
 511 AC_MSG_CHECKING(for bionic libc)
 512 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 513         [[#ifndef __ANDROID__
 514 error: Not bionic!
 515 #endif]])],
 516         [is_bionic=yes],
 517         [is_bionic=no])
 518 if test "x$is_bionic" = "xyes"; then
 519         AC_DEFINE([IS_BIONIC], 1, [bionic libc])
 520         AC_MSG_RESULT([yes])
 521 else
 522         AC_MSG_RESULT([no])
 523 fi
 524 AM_CONDITIONAL([IS_BIONIC], [test "x$is_bionic" = "xyes"])
 525
 526 # Some systems lack PR_CAPBSET_DROP definition => HAVE_DECL_PR_CAPBSET_DROP
 527 AC_CHECK_DECLS([PR_CAPBSET_DROP], [], [], [#include <sys/prctl.h>])
 528
 529 # Check for some headers
 530 AC_CHECK_HEADERS([sys/signalfd.h pty.h ifaddrs.h sys/capability.h sys/personality.h utmpx.h sys/timerfd.h])
 531
 532 # Check for some syscalls functions
 533 AC_CHECK_FUNCS([setns pivot_root sethostname unshare rand_r confstr faccessat])
 534
 535 # Check for some functions
 536 AC_CHECK_LIB(pthread, main)
 537 AC_CHECK_FUNCS(pthread_atfork)
 538 AC_CHECK_LIB(util, openpty)
 539 AC_CHECK_FUNCS([openpty hasmntopt setmntent endmntent utmpxname])
 540 AC_CHECK_FUNCS([getline],
 541         AM_CONDITIONAL(HAVE_GETLINE, true)
 542         AC_DEFINE(HAVE_GETLINE,1,[Have getline]),
 543         AM_CONDITIONAL(HAVE_GETLINE, false))
 544 AC_CHECK_FUNCS([fgetln],
 545         AM_CONDITIONAL(HAVE_FGETLN, true)
 546         AC_DEFINE(HAVE_FGETLN,1,[Have fgetln]),
 547         AM_CONDITIONAL(HAVE_FGETLN, false))
 548
 549 # Check for some libraries
 550 AC_SEARCH_LIBS(sem_open, [rt pthread])
 551 AC_SEARCH_LIBS(clock_gettime, [rt])
 552
 553 # Check for some standard binaries
 554 AC_PROG_GCC_TRADITIONAL
 555 AC_PROG_SED
 556
 557 # See if we support thread-local storage.
 558 LXC_CHECK_TLS
 559
 560 if test "x$GCC" = "xyes"; then
 561         CFLAGS="$CFLAGS -Wall -Werror"
 562 fi
 563
 564 # Files requiring some variable expansion
 565 AC_CONFIG_FILES([
 566         Makefile
 567         lxc.pc
 568         lxc.spec
 569
 570         config/Makefile
 571         config/apparmor/Makefile
 572         config/bash/Makefile
 573         config/bash/lxc
 574         config/init/Makefile
 575         config/init/sysvinit/Makefile
 576         config/init/systemd/Makefile
 577         config/init/upstart/Makefile
 578         config/etc/Makefile
 579         config/templates/Makefile
 580         config/templates/centos.common.conf
 581         config/templates/centos.userns.conf
 582         config/templates/debian.common.conf
 583         config/templates/debian.userns.conf
 584         config/templates/fedora.common.conf
 585         config/templates/fedora.userns.conf
 586         config/templates/gentoo.common.conf
 587         config/templates/gentoo.moresecure.conf
 588         config/templates/gentoo.userns.conf
 589         config/templates/oracle.common.conf
 590         config/templates/oracle.userns.conf
 591         config/templates/plamo.common.conf
 592         config/templates/plamo.userns.conf
 593         config/templates/ubuntu-cloud.common.conf
 594         config/templates/ubuntu-cloud.lucid.conf
 595         config/templates/ubuntu-cloud.userns.conf
 596         config/templates/ubuntu.common.conf
 597         config/templates/ubuntu.lucid.conf
 598         config/templates/ubuntu.userns.conf
 599         config/yum/Makefile
 600
 601         doc/Makefile
 602         doc/api/Makefile
 603         doc/legacy/lxc-ls.sgml
 604         doc/lxc-attach.sgml
 605         doc/lxc-autostart.sgml
 606         doc/lxc-cgroup.sgml
 607         doc/lxc-checkconfig.sgml
 608         doc/lxc-clone.sgml
 609         doc/lxc-config.sgml
 610         doc/lxc-console.sgml
 611         doc/lxc-create.sgml
 612         doc/lxc-destroy.sgml
 613         doc/lxc-device.sgml
 614         doc/lxc-execute.sgml
 615         doc/lxc-freeze.sgml
 616         doc/lxc-info.sgml
 617         doc/lxc-ls.sgml
 618         doc/lxc-monitor.sgml
 619         doc/lxc-snapshot.sgml
 620         doc/lxc-start-ephemeral.sgml
 621         doc/lxc-start.sgml
 622         doc/lxc-stop.sgml
 623         doc/lxc-top.sgml
 624         doc/lxc-unfreeze.sgml
 625         doc/lxc-unshare.sgml
 626         doc/lxc-user-nic.sgml
 627         doc/lxc-usernsexec.sgml
 628         doc/lxc-wait.sgml
 629
 630         doc/lxc.conf.sgml
 631         doc/lxc.container.conf.sgml
 632         doc/lxc.system.conf.sgml
 633         doc/lxc-usernet.sgml
 634         doc/lxc.sgml
 635         doc/common_options.sgml
 636         doc/see_also.sgml
 637
 638         doc/rootfs/Makefile
 639
 640         doc/examples/Makefile
 641         doc/examples/lxc-macvlan.conf
 642         doc/examples/lxc-vlan.conf
 643         doc/examples/lxc-no-netns.conf
 644         doc/examples/lxc-empty-netns.conf
 645         doc/examples/lxc-phys.conf
 646         doc/examples/lxc-veth.conf
 647         doc/examples/lxc-complex.conf
 648
 649         doc/ja/Makefile
 650         doc/ja/legacy/lxc-ls.sgml
 651         doc/ja/lxc-attach.sgml
 652         doc/ja/lxc-autostart.sgml
 653         doc/ja/lxc-cgroup.sgml
 654         doc/ja/lxc-checkconfig.sgml
 655         doc/ja/lxc-clone.sgml
 656         doc/ja/lxc-config.sgml
 657         doc/ja/lxc-console.sgml
 658         doc/ja/lxc-create.sgml
 659         doc/ja/lxc-destroy.sgml
 660         doc/ja/lxc-device.sgml
 661         doc/ja/lxc-execute.sgml
 662         doc/ja/lxc-freeze.sgml
 663         doc/ja/lxc-info.sgml
 664         doc/ja/lxc-ls.sgml
 665         doc/ja/lxc-monitor.sgml
 666         doc/ja/lxc-snapshot.sgml
 667         doc/ja/lxc-start-ephemeral.sgml
 668         doc/ja/lxc-start.sgml
 669         doc/ja/lxc-stop.sgml
 670         doc/ja/lxc-top.sgml
 671         doc/ja/lxc-unfreeze.sgml
 672         doc/ja/lxc-unshare.sgml
 673         doc/ja/lxc-user-nic.sgml
 674         doc/ja/lxc-usernsexec.sgml
 675         doc/ja/lxc-wait.sgml
 676
 677         doc/ja/lxc.conf.sgml
 678         doc/ja/lxc.container.conf.sgml
 679         doc/ja/lxc.system.conf.sgml
 680         doc/ja/lxc-usernet.sgml
 681         doc/ja/lxc.sgml
 682         doc/ja/common_options.sgml
 683         doc/ja/see_also.sgml
 684
 685         hooks/Makefile
 686
 687         templates/Makefile
 688         templates/lxc-alpine
 689         templates/lxc-altlinux
 690         templates/lxc-archlinux
 691         templates/lxc-busybox
 692         templates/lxc-centos
 693         templates/lxc-cirros
 694         templates/lxc-debian
 695         templates/lxc-download
 696         templates/lxc-fedora
 697         templates/lxc-gentoo
 698         templates/lxc-openmandriva
 699         templates/lxc-opensuse
 700         templates/lxc-oracle
 701         templates/lxc-plamo
 702         templates/lxc-sshd
 703         templates/lxc-ubuntu
 704         templates/lxc-ubuntu-cloud
 705
 706         src/Makefile
 707         src/lxc/Makefile
 708         src/lxc/lxc-checkconfig
 709         src/lxc/lxc-ls
 710         src/lxc/lxc-start-ephemeral
 711         src/lxc/legacy/lxc-ls
 712         src/lxc/lxc.functions
 713         src/lxc/version.h
 714         src/python-lxc/Makefile
 715
 716         src/lua-lxc/Makefile
 717
 718         src/tests/Makefile
 719         src/tests/lxc-test-usernic
 720 ])
 721 AC_CONFIG_COMMANDS([default],[[]],[[]])
 722 AC_OUTPUT
 723
 724 # Configuration overview
 725 cat << EOF
 726
 727 ----------------------------
 728 Environment:
 729  - compiler: $CC
 730  - distribution: $with_distro
 731  - init script type(s): $init_script
 732  - rpath: $enable_rpath
 733  - GnuTLS: $enable_gnutls
 734  - Bash integration: $enable_bash
 735
 736 Security features:
 737  - Apparmor: $enable_apparmor
 738  - Linux capabilities: $enable_capabilities
 739  - seccomp: $enable_seccomp
 740  - SELinux: $enable_selinux
 741  - cgmanager: $enable_cgmanager
 742
 743 Bindings:
 744  - lua: $enable_lua
 745  - python3: $enable_python
 746
 747 Documentation:
 748  - examples: $enable_examples
 749  - API documentation: $enable_api_docs
 750  - user documentation: $enable_doc
 751
 752 Debugging:
 753  - tests: $enable_tests
 754  - mutex debugging: $enable_mutex_debugging
 755
 756 Paths:
 757  - Logs in configpath: $enable_configpath_log
 758 EOF
 759
 760 if test "x$ac_cv_func_pthread_atfork" = "xno" ; then
 761 cat << EOF
 762
 763 WARNING: Threading not supported on your platform
 764
 765         You are compiling LXC for bionic target which lacks certain threading related functionality used by LXC API (like pthread_atfork).
 766         Please note that, because of the missing functionality, multithreaded usage of LXC API cause some problems.
 767 EOF
 768 fi