configure.ac

   1 ##
   2 ## Configure template file for FRRouting.
   3 ## autoconf will generate configure script.
   4 ##
   5 ##  Copyright (c) 1996, 97, 98, 99, 2000 Kunihiro Ishiguro <kunihiro@zebra.org>
   6 ##  Portions Copyright (c) 2003 Paul Jakma <paul@dishone.st>
   7 ##
   8 AC_PREREQ(2.60)
   9
  10 AC_INIT(frr, 5.1-dev, [https://github.com/frrouting/frr/issues])
  11 PACKAGE_URL="https://frrouting.org/"
  12 AC_SUBST(PACKAGE_URL)
  13 PACKAGE_FULLNAME="FRRouting"
  14 AC_SUBST(PACKAGE_FULLNAME)
  15
  16 CONFIG_ARGS="$ac_configure_args"
  17 AC_SUBST(CONFIG_ARGS)
  18
  19 AC_CONFIG_SRCDIR(lib/zebra.h)
  20 AC_CONFIG_MACRO_DIR([m4])
  21
  22 dnl -----------------------------------
  23 dnl Get hostname and other information.
  24 dnl -----------------------------------
  25 AC_CANONICAL_BUILD()
  26 AC_CANONICAL_HOST()
  27
  28 AS_IF([test "$host" != "$build"], [
  29   if test "$srcdir" = "."; then
  30     AC_MSG_ERROR([cross-compilation is only possible with builddir separate from srcdir.  create a separate directory and run as .../path-to-frr/configure.])
  31   fi
  32   test -d hosttools || mkdir hosttools
  33   abssrc="`cd \"${srcdir}\"; pwd`"
  34
  35   AC_MSG_NOTICE([...])
  36   AC_MSG_NOTICE([... cross-compilation: creating hosttools directory and self-configuring for build platform tools])
  37   AC_MSG_NOTICE([... use HOST_CPPFLAGS / HOST_CFLAGS / HOST_LDFLAGS if neccessary])
  38   AC_MSG_NOTICE([...])
  39
  40   ( CPPFLAGS="$HOST_CPPFLAGS"; \
  41     CFLAGS="$HOST_CFLAGS"; \
  42     LDFLAGS="$HOST_LDFLAGS"; \
  43     cd hosttools; "${abssrc}/configure" "--host=$build" "--build=$build" "--enable-clippy-only" "--disable-nhrpd" "--disable-vtysh"; )
  44
  45   AC_MSG_NOTICE([...])
  46   AC_MSG_NOTICE([... cross-compilation: finished self-configuring for build platform tools])
  47   AC_MSG_NOTICE([...])
  48
  49   build_clippy="false"
  50   HOSTTOOLS="hosttools/"
  51 ], [
  52   build_clippy="true"
  53   HOSTTOOLS=""
  54 ])
  55 AC_SUBST(HOSTTOOLS)
  56 AM_CONDITIONAL([BUILD_CLIPPY], [$build_clippy])
  57
  58 # Disable portability warnings -- our automake code (in particular
  59 # common.am) uses some constructs specific to gmake.
  60 AM_INIT_AUTOMAKE([1.12 -Wno-portability])
  61 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
  62 AM_SILENT_RULES([yes])
  63 AC_CONFIG_HEADERS(config.h)
  64
  65 AC_PATH_PROG(PERL, perl)
  66 PKG_PROG_PKG_CONFIG
  67
  68 dnl default is to match previous behavior
  69 exampledir=${sysconfdir}
  70 AC_ARG_ENABLE([exampledir],
  71           AS_HELP_STRING([--enable-exampledir],
  72                          [specify alternate directory for examples]),
  73                          exampledir="$enableval",)
  74 dnl XXX add --exampledir to autoconf standard directory list somehow
  75 AC_SUBST(exampledir)
  76
  77 dnl default is to match previous behavior
  78 pkgsrcrcdir=""
  79 AC_ARG_ENABLE([pkgsrcrcdir],
  80           AS_HELP_STRING([--enable-pkgsrcrcdir],
  81                          [specify directory for rc.d scripts]),
  82                          pkgsrcrcdir="$enableval",)
  83 dnl XXX add --pkgsrcrcdir to autoconf standard directory list somehow
  84 AC_SUBST(pkgsrcrcdir)
  85 AM_CONDITIONAL([PKGSRC], [test "x$pkgsrcrcdir" != "x"])
  86
  87 AC_ARG_WITH([moduledir], [AS_HELP_STRING([--with-moduledir=DIR], [module directory (${libdir}/frr/modules)])], [
  88         moduledir="$withval"
  89 ], [
  90         moduledir="\${libdir}/frr/modules"
  91 ])
  92 AC_SUBST([moduledir], [$moduledir])
  93
  94 AC_ARG_ENABLE(tcmalloc,
  95         AS_HELP_STRING([--enable-tcmalloc], [Turn on tcmalloc]),
  96 [case "${enableval}" in
  97   yes) tcmalloc_enabled=true
  98 LIBS="$LIBS -ltcmalloc_minimal"
  99  ;;
 100   no)  tcmalloc_enabled=false ;;
 101   *) AC_MSG_ERROR(bad value ${enableval} for --enable-tcmalloc) ;;
 102 esac],[tcmalloc_enabled=false])
 103
 104
 105 dnl Thanks autoconf, but we don't want a default -g -O2.  We have our own
 106 dnl flag determination logic.
 107 CFLAGS="${CFLAGS:-}"
 108
 109 dnl --------------------
 110 dnl Check CC and friends
 111 dnl --------------------
 112 dnl note orig_cflags is also used further down
 113 orig_cflags="$CFLAGS"
 114 AC_LANG([C])
 115 AC_PROG_CC
 116 AC_PROG_CPP
 117 AM_PROG_CC_C_O
 118 dnl remove autoconf default "-g -O2"
 119 CFLAGS="$orig_cflags"
 120 AC_PROG_CC_C99
 121 dnl NB: see C11 below
 122
 123 AC_PROG_EGREP
 124 PKG_PROG_PKG_CONFIG
 125
 126 dnl autoconf 2.59 appears not to support AC_PROG_SED
 127 dnl AC_PROG_SED
 128 AC_CHECK_PROG([SED],[sed],[sed],[/bin/false])
 129
 130 dnl try and enable CFLAGS that are useful for FRR
 131 dnl - specifically, options to control warnings
 132
 133 AC_USE_SYSTEM_EXTENSIONS
 134 AC_DEFUN([AC_C_FLAG], [{
 135         AC_LANG_PUSH(C)
 136         ac_c_flag_save="$CFLAGS"
 137         CFLAGS="$CFLAGS $1"
 138         AC_MSG_CHECKING([[whether $CC supports $1]])
 139         AC_COMPILE_IFELSE(
 140                 [AC_LANG_PROGRAM([[]])],
 141                 [
 142                         AC_MSG_RESULT([yes])
 143                         m4_if([$3], [], [], [
 144                                 CFLAGS="$ac_c_flag_save"
 145                                 $3
 146                         ])
 147                 ], [
 148                         CFLAGS="$ac_c_flag_save"
 149                         AC_MSG_RESULT([no])
 150                         $2
 151                 ])
 152         AC_LANG_POP(C)
 153         }])
 154
 155 AC_DEFUN([AC_LINK_IFELSE_FLAGS], [{
 156         AC_LANG_PUSH(C)
 157         ac_cflags_save="$CFLAGS"
 158         ac_libs_save="$LIBS"
 159         CFLAGS="$CFLAGS $1"
 160         LIBS="$LIBS $2"
 161         AC_LINK_IFELSE(
 162                 [$3],
 163                 [
 164                         AC_MSG_RESULT([yes])
 165                         CFLAGS="$ac_cflags_save"
 166                         LIBS="$ac_libs_save"
 167                         $5
 168                 ], [
 169                         AC_MSG_RESULT([no])
 170                         CFLAGS="$ac_cflags_save"
 171                         LIBS="$ac_libs_save"
 172                         $4
 173                 ])
 174         AC_LANG_POP(C)
 175         }])
 176
 177 dnl ICC won't bail on unknown options without -diag-error 10006
 178 dnl need to do this first so we get useful results for the other options
 179 AC_C_FLAG([-diag-error 10006])
 180
 181 dnl AC_PROG_CC_C99 may change CC to include -std=gnu99 or something
 182 ac_cc="$CC"
 183 CC="${CC% -std=gnu99}"
 184 CC="${CC% -std=c99}"
 185
 186 AC_C_FLAG([-std=gnu11], [CC="$ac_cc"], [CC="$CC -std=gnu11"])
 187
 188 dnl AddressSanitizer support
 189 AC_ARG_ENABLE([address-sanitizer], AS_HELP_STRING([--enable-address-sanitizer], \
 190               [enabled AddressSanitizer support for detecting a wide variety of \
 191                memory allocation and deallocation errors]), \
 192               [AC_DEFINE(HAVE_ADDRESS_SANITIZER, 1, [enable AddressSanitizer])
 193               CFLAGS="$CFLAGS -fsanitize=address"
 194               CXXFLAGS="$CXXFLAGS -fsanitize=address"
 195               AC_TRY_COMPILE([],[const int i=0;],[AC_MSG_NOTICE([Address Sanitizer Enabled])],
 196                                                  [AC_MSG_ERROR([Address Sanitizer not available])])
 197               ])
 198
 199 dnl ThreadSanitizer support
 200 AC_ARG_ENABLE([thread-sanitizer], AS_HELP_STRING([--enable-thread-sanitizer], \
 201               [enabled ThreadSanitizer support for detecting data races]), \
 202               [AC_DEFINE(HAVE_THREAD_SANITIZER, 1, [enable ThreadSanitizer])
 203               CFLAGS="$CFLAGS -fsanitize=thread"
 204               CXXFLAGS="$CXXFLAGS -fsanitize=thread"
 205               AC_TRY_COMPILE([],[const int i=0;],[AC_MSG_NOTICE([Thread Sanitizer Enabled])],
 206                                                  [AC_MSG_ERROR([Thread Sanitizer not available])])
 207               ])
 208
 209 dnl MemorySanitizer support
 210 AC_ARG_ENABLE([memory-sanitizer], AS_HELP_STRING([--enable-memory-sanitizer], \
 211               [enabled MemorySanitizer support for detecting uninitialized memory reads]), \
 212               [AC_DEFINE(HAVE_THREAD_SANITIZER, 1, [enable MemorySanitizer])
 213               CFLAGS="$CFLAGS -fsanitize=memory -fPIE -pie"
 214               CXXFLAGS="$CXXFLAGS -fsanitize=memory -fPIE -pie"
 215               AC_TRY_COMPILE([],[const int i=0;],[AC_MSG_NOTICE([Memory Sanitizer Enabled])],
 216                                                  [AC_MSG_ERROR([Memory Sanitizer not available])])
 217               ])
 218
 219 dnl if the user has specified any CFLAGS, override our settings
 220 if test "x${enable_dev_build}" = "xyes"; then
 221    AC_DEFINE(DEV_BUILD,,Build for development)
 222    if test "z$orig_cflags" = "z"; then
 223       AC_C_FLAG([-g3])
 224       AC_C_FLAG([-O0])
 225    fi
 226 else
 227    if test "z$orig_cflags" = "z"; then
 228       AC_C_FLAG([-g])
 229       AC_C_FLAG([-Os], [
 230         AC_C_FLAG([-O2])
 231       ])
 232    fi
 233 fi
 234 AM_CONDITIONAL([DEV_BUILD], [test "x$enable_dev_build" = "xyes"])
 235
 236 dnl always want these CFLAGS
 237 AC_C_FLAG([-fno-omit-frame-pointer])
 238 AC_C_FLAG([-funwind-tables])
 239 AC_C_FLAG([-Wall])
 240 AC_C_FLAG([-Wextra])
 241 AC_C_FLAG([-Wmissing-prototypes])
 242 AC_C_FLAG([-Wmissing-declarations])
 243 AC_C_FLAG([-Wpointer-arith])
 244 AC_C_FLAG([-Wbad-function-cast])
 245 AC_C_FLAG([-Wwrite-strings])
 246 if test x"${enable_gcc_ultra_verbose}" = x"yes" ; then
 247   AC_C_FLAG([-Wcast-qual])
 248   AC_C_FLAG([-Wstrict-prototypes])
 249   AC_C_FLAG([-Wmissing-noreturn])
 250   AC_C_FLAG([-Wmissing-format-attribute])
 251   AC_C_FLAG([-Wunreachable-code])
 252   AC_C_FLAG([-Wpacked])
 253   AC_C_FLAG([-Wpadded])
 254 else
 255   AC_C_FLAG([-Wno-unused-result])
 256 fi
 257 AC_C_FLAG([-Wno-unused-parameter])
 258 AC_C_FLAG([-Wno-missing-field-initializers])
 259
 260 dnl ICC emits a broken warning for const char *x = a ? "b" : "c";
 261 dnl for some reason the string consts get 'promoted' to char *,
 262 dnl triggering a const to non-const conversion warning.
 263 AC_C_FLAG([-diag-disable 3179])
 264
 265 if test x"${enable_werror}" = x"yes" ; then
 266   WERROR="-Werror"
 267 fi
 268 AC_SUBST(WERROR)
 269
 270 dnl need link on this one, not compile
 271 AC_LANG_PUSH(C)
 272 ac_ld_flag_save="$LDFLAGS"
 273 LDFLAGS="$LDFLAGS -rdynamic"
 274 AC_MSG_CHECKING([[whether linker supports -rdynamic]])
 275 AC_LINK_IFELSE(
 276         [AC_LANG_PROGRAM([[]])],
 277         [AC_MSG_RESULT([yes])],
 278         [
 279                 LDFLAGS="$ac_ld_flag_save"
 280                 AC_MSG_RESULT([no])
 281         ])
 282 AC_LANG_POP(C)
 283
 284 dnl ----------
 285 dnl Essentials
 286 dnl ----------
 287
 288 AX_PTHREAD([
 289   CC="$PTHREAD_CC"
 290   CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 291   LIBS="$PTHREAD_LIBS $LIBS"
 292 ], [
 293   AC_MSG_FAILURE([This FRR version needs pthreads])
 294 ])
 295
 296 dnl --------------
 297 dnl Check programs
 298 dnl --------------
 299 AC_PROG_INSTALL
 300 AC_PROG_LN_S
 301 AC_PROG_MAKE_SET
 302 AC_CHECK_TOOL(AR, ar)
 303
 304 dnl -----------------
 305 dnl System extensions
 306 dnl -----------------
 307 AC_GNU_SOURCE
 308
 309 dnl -------
 310 dnl libtool
 311 dnl -------
 312 LT_INIT
 313
 314 dnl ----------------------
 315 dnl Packages configuration
 316 dnl ----------------------
 317 AC_ARG_WITH(pkg-extra-version,
 318         AS_HELP_STRING([--with-pkg-extra-version=VER], [add extra version field, for packagers/distributions]),
 319         [EXTRAVERSION=$withval],)
 320 AC_ARG_WITH(pkg-git-version,
 321         AS_HELP_STRING([--with-pkg-git-version], [add git information to MOTD and build version string]),
 322         [ test "x$withval" != "xno" && with_pkg_git_version="yes" ])
 323 AC_ARG_WITH(vtysh_pager,
 324         AS_HELP_STRING([--with-vtysh-pager=PAGER], [control what pager is compiled in as default]),
 325         VTYSH_PAGER=$withval, VTYSH_PAGER="more")
 326 AC_ARG_ENABLE(vtysh,
 327   AS_HELP_STRING([--disable-vtysh], [do not build integrated vty shell for FRR]))
 328 AC_ARG_ENABLE(doc,
 329   AS_HELP_STRING([--disable-doc], [do not build docs]))
 330 AC_ARG_ENABLE(zebra,
 331   AS_HELP_STRING([--disable-zebra], [do not build zebra daemon]))
 332 AC_ARG_ENABLE(bgpd,
 333   AS_HELP_STRING([--disable-bgpd], [do not build bgpd]))
 334 AC_ARG_ENABLE(ripd,
 335   AS_HELP_STRING([--disable-ripd], [do not build ripd]))
 336 AC_ARG_ENABLE(ripngd,
 337   AS_HELP_STRING([--disable-ripngd], [do not build ripngd]))
 338 AC_ARG_ENABLE(ospfd,
 339   AS_HELP_STRING([--disable-ospfd], [do not build ospfd]))
 340 AC_ARG_ENABLE(ospf6d,
 341   AS_HELP_STRING([--disable-ospf6d], [do not build ospf6d]))
 342 AC_ARG_ENABLE(ldpd,
 343   AS_HELP_STRING([--enable-ldpd], [build ldpd]))
 344 AC_ARG_ENABLE(nhrpd,
 345   AS_HELP_STRING([--disable-nhrpd], [do not build nhrpd]))
 346 AC_ARG_ENABLE(eigrpd,
 347   AS_HELP_STRING([--disable-eigrpd], [do not build eigrpd]))
 348 AC_ARG_ENABLE(babeld,
 349   AS_HELP_STRING([--disable-babeld], [do not build babeld]))
 350 AC_ARG_ENABLE(watchfrr,
 351   AS_HELP_STRING([--disable-watchfrr], [do not build watchfrr]))
 352 AC_ARG_ENABLE(isisd,
 353   AS_HELP_STRING([--disable-isisd], [do not build isisd]))
 354 AC_ARG_ENABLE(pimd,
 355   AS_HELP_STRING([--disable-pimd], [do not build pimd]))
 356 AC_ARG_ENABLE(pbrd,
 357   AS_HELP_STRING([--disable-pbrd], [do not build pbrd]))
 358 AC_ARG_ENABLE(sharpd,
 359   AS_HELP_STRING([--enable-sharpd], [do not build sharpd]))
 360 AC_ARG_ENABLE(bgp-announce,
 361   AS_HELP_STRING([--disable-bgp-announce,], [turn off BGP route announcement]))
 362 AC_ARG_ENABLE(bgp-vnc,
 363   AS_HELP_STRING([--disable-bgp-vnc],[turn off BGP VNC support]))
 364 AC_ARG_WITH(rfp-path,
 365   AS_HELP_STRING([--with-rfp-path[=DIR]],[path to replaced stub RFP used with BGP VNC]))
 366 AC_ARG_ENABLE(snmp,
 367   AS_HELP_STRING([--enable-snmp=ARG], [enable SNMP support (smux or agentx)]))
 368 AC_ARG_ENABLE(zeromq,
 369   AS_HELP_STRING([--enable-zeromq], [enable ZeroMQ handler (libfrrzmq)]))
 370 AC_ARG_WITH(libpam,
 371   AS_HELP_STRING([--with-libpam], [use libpam for PAM support in vtysh]))
 372 AC_ARG_ENABLE(ospfapi,
 373   AS_HELP_STRING([--disable-ospfapi], [do not build OSPFAPI to access the OSPF LSA Database]))
 374 AC_ARG_ENABLE(ospfclient,
 375   AS_HELP_STRING([--disable-ospfclient], [do not build OSPFAPI client for OSPFAPI,
 376                           (this is the default if --disable-ospfapi is set)]))
 377 AC_ARG_ENABLE(multipath,
 378   AS_HELP_STRING([--enable-multipath=ARG], [enable multipath function, ARG must be digit]))
 379 AC_ARG_ENABLE(user,
 380   AS_HELP_STRING([--enable-user=USER], [user to run FRR suite as (default frr)]))
 381 AC_ARG_ENABLE(group,
 382   AS_HELP_STRING([--enable-group=GROUP], [group to run FRR suite as (default frr)]))
 383 AC_ARG_ENABLE(vty_group,
 384   AS_HELP_STRING([--enable-vty-group=ARG], [set vty sockets to have specified group as owner]))
 385 AC_ARG_ENABLE(configfile_mask,
 386   AS_HELP_STRING([--enable-configfile-mask=ARG], [set mask for config files]))
 387 AC_ARG_ENABLE(logfile_mask,
 388   AS_HELP_STRING([--enable-logfile-mask=ARG], [set mask for log files]))
 389 AC_ARG_ENABLE(shell_access,
 390   AS_HELP_STRING([--enable-shell-access], [Allow users to access shell/telnet/ssh]))
 391 AC_ARG_ENABLE(realms,
 392   AS_HELP_STRING([--enable-realms], [enable REALMS support under Linux]))
 393 AC_ARG_ENABLE(rtadv,
 394   AS_HELP_STRING([--disable-rtadv], [disable IPV6 router advertisement feature]))
 395 AC_ARG_ENABLE(irdp,
 396   AS_HELP_STRING([--disable-irdp], [enable IRDP server support in zebra (default if supported)]))
 397 AC_ARG_ENABLE(capabilities,
 398   AS_HELP_STRING([--disable-capabilities], [disable using POSIX capabilities]))
 399 AC_ARG_ENABLE(rusage,
 400   AS_HELP_STRING([--disable-rusage], [disable using getrusage]))
 401 AC_ARG_ENABLE(gcc_ultra_verbose,
 402   AS_HELP_STRING([--enable-gcc-ultra-verbose], [enable ultra verbose GCC warnings]))
 403 AC_ARG_ENABLE(linux24_tcp_md5,
 404   AS_HELP_STRING([--enable-linux24-tcp-md5], [enable support for old, Linux-2.4 RFC2385 patch]))
 405 AC_ARG_ENABLE(backtrace,
 406   AS_HELP_STRING([--disable-backtrace,], [disable crash backtraces (default autodetect)]))
 407 AC_ARG_ENABLE(time-check,
 408   AS_HELP_STRING([--disable-time-check], [disable slow thread warning messages]))
 409 AC_ARG_ENABLE(pcreposix,
 410   AS_HELP_STRING([--enable-pcreposix], [enable using PCRE Posix libs for regex functions]))
 411 AC_ARG_ENABLE(fpm,
 412   AS_HELP_STRING([--enable-fpm], [enable Forwarding Plane Manager support]))
 413 AC_ARG_ENABLE(systemd,
 414   AS_HELP_STRING([--enable-systemd], [enable Systemd support]))
 415 AC_ARG_ENABLE(werror,
 416   AS_HELP_STRING([--enable-werror], [enable -Werror (recommended for developers only)]))
 417 AC_ARG_ENABLE(cumulus,
 418   AS_HELP_STRING([--enable-cumulus], [enable Cumulus Switch Special Extensions]))
 419 AC_ARG_ENABLE(datacenter,
 420   AS_HELP_STRING([--enable-datacenter], [enable Compilation for Data Center Extensions]))
 421 AC_ARG_ENABLE(fuzzing,
 422   AS_HELP_STRING([--enable-fuzzing], [enable ability to fuzz various parts of FRR]))
 423 AC_ARG_ENABLE(rr-semantics,
 424   AS_HELP_STRING([--disable-rr-semantics], [disable the v6 Route Replace semantics]))
 425 AC_ARG_ENABLE([protobuf],
 426   AS_HELP_STRING([--enable-protobuf], [Enable experimental protobuf support]))
 427 AC_ARG_ENABLE([oldvpn_commands],
 428   AS_HELP_STRING([--enable-oldvpn-commands], [Keep old vpn commands]))
 429 AC_ARG_ENABLE(rpki,
 430   AS_HELP_STRING([--enable-rpki], [enable RPKI prefix validation support]))
 431 AC_ARG_ENABLE([clippy-only],
 432   AS_HELP_STRING([--enable-clippy-only], [Only build clippy]))
 433 AC_ARG_ENABLE([numeric_version],
 434   AS_HELP_STRING([--enable-numeric-version], [Only numeric digits allowed in version (for Alpine)]))
 435
 436 AS_IF([test "${enable_clippy_only}" != "yes"], [
 437 AC_CHECK_HEADERS(json-c/json.h)
 438 AC_CHECK_LIB(json-c, json_object_get, LIBS="$LIBS -ljson-c", [], [-lm])
 439 if test $ac_cv_lib_json_c_json_object_get = no; then
 440   AC_CHECK_LIB(json, json_object_get, LIBS="$LIBS -ljson")
 441   if test $ac_cv_lib_json_json_object_get = no; then
 442       AC_MSG_ERROR([lib json is needed to compile])
 443   fi
 444 fi
 445 ])
 446
 447 AC_ARG_ENABLE([dev_build],
 448     AS_HELP_STRING([--enable-dev-build], [build for development]))
 449
 450 if test x"${enable_time_check}" != x"no" ; then
 451   if test x"${enable_time_check}" = x"yes" -o x"${enable_time_check}" = x ; then
 452     AC_DEFINE(CONSUMED_TIME_CHECK,5000000,Consumed Time Check)
 453   else
 454     AC_DEFINE_UNQUOTED(CONSUMED_TIME_CHECK,$enable_time_check,Consumed Time Check)
 455   fi
 456 fi
 457
 458 case "${enable_systemd}" in
 459   "no") ;;
 460   "yes")
 461   AC_CHECK_LIB(systemd, sd_notify, LIBS="$LIBS -lsystemd")
 462   if test $ac_cv_lib_systemd_sd_notify = no; then
 463     AC_MSG_ERROR([enable systemd has been specified but systemd development env not found on your system])
 464   else
 465     AC_DEFINE(HAVE_SYSTEMD,,Compile systemd support in)
 466   fi
 467   ;;
 468   "*") ;;
 469 esac
 470
 471 if test "${enable_rr_semantics}" != "no" ; then
 472   AC_DEFINE(HAVE_V6_RR_SEMANTICS,, Compile in v6 Route Replacement Semantics)
 473 fi
 474
 475 if test "${enable_datacenter}" = "yes" ; then
 476   AC_DEFINE(HAVE_DATACENTER,,Compile extensions for a DataCenter)
 477   DFLT_NAME="datacenter"
 478 else
 479   DFLT_NAME="traditional"
 480 fi
 481
 482 if test "${enable_fuzzing}" = "yes" ; then
 483   AC_DEFINE(HANDLE_ZAPI_FUZZING,,Compile extensions to use with a fuzzer)
 484 fi
 485
 486 if test "${enable_cumulus}" = "yes" ; then
 487   AC_DEFINE(HAVE_CUMULUS,,Compile Special Cumulus Code in)
 488 fi
 489
 490 AC_SUBST(DFLT_NAME)
 491 AC_DEFINE_UNQUOTED(DFLT_NAME,["$DFLT_NAME"], Name of the configuration default set)
 492
 493 if test "${enable_shell_access}" = "yes"; then
 494    AC_DEFINE(HAVE_SHELL_ACCESS,,Allow user to use ssh/telnet/bash)
 495 fi
 496
 497 AM_CONDITIONAL([FPM], [test "x$enable_fpm" = "xyes"])
 498
 499 #
 500 # Python for clippy
 501 #
 502 AS_IF([test "$host" = "$build"], [
 503   PYTHONCONFIG=""
 504
 505   # ordering:
 506   # 1.  try python3, but respect the user's preference on which minor ver
 507   # 2.  try python, which might be py3 or py2 again on the user's preference
 508   # 3.  try python2 (can really only be 2.7 but eh)
 509   # 4.  try 3.5 > 3.4 > 3.3 > 3.2 > 2.7 through pkg-config (no user pref)
 510   #
 511   # (AX_PYTHON_DEVEL has no clue about py3 vs py2)
 512   # (AX_PYTHON does not do what we need)
 513
 514   AC_CHECK_TOOLS([PYTHONCONFIG], [python3-config python-config python2-config])
 515   if test -n "$PYTHONCONFIG"; then
 516     PYTHON_CFLAGS="`\"${PYTHONCONFIG}\" --includes`"
 517     PYTHON_LIBS="`\"${PYTHONCONFIG}\" --libs`"
 518
 519     AC_MSG_CHECKING([whether we found a working Python version])
 520     AC_LINK_IFELSE_FLAGS([$PYTHON_CFLAGS], [$PYTHON_LIBS], [AC_LANG_PROGRAM([
 521 #include <Python.h>
 522 #if PY_VERSION_HEX < 0x02070000
 523 #error python too old
 524 #endif
 525 int main(void);
 526 ],
 527 [
 528 {
 529   Py_Initialize();
 530   return 0;
 531 }
 532 ])], [
 533       PYTHONCONFIG=""
 534       unset PYTHON_LIBS
 535       unset PYTHON_CFLAGS
 536     ])
 537   fi
 538
 539   if test -z "$PYTHONCONFIG"; then
 540     PKG_CHECK_MODULES([PYTHON], python-3.5, [], [
 541       PKG_CHECK_MODULES([PYTHON], python-3.4, [], [
 542         PKG_CHECK_MODULES([PYTHON], python-3.3, [], [
 543           PKG_CHECK_MODULES([PYTHON], python-3.2, [], [
 544             PKG_CHECK_MODULES([PYTHON], python-2.7, [], [
 545               AC_MSG_FAILURE([could not find python-config or pkg-config python, please install Python development files from libpython-dev or similar])
 546               ])])])])])
 547
 548
 549     AC_MSG_CHECKING([whether we found a working Python version])
 550     AC_LINK_IFELSE_FLAGS([$PYTHON_CFLAGS], [$PYTHON_LIBS], [AC_LANG_PROGRAM([
 551 #include <Python.h>
 552 #if PY_VERSION_HEX < 0x02070000
 553 #error python too old
 554 #endif
 555 int main(void);
 556 ],
 557 [
 558 {
 559   Py_Initialize();
 560   return 0;
 561 }
 562 ])], [
 563       AC_MSG_FAILURE([could not find python-config or pkg-config python, please install Python development files from libpython-dev or similar])
 564     ])
 565   fi
 566 ])
 567 AC_SUBST(PYTHON_CFLAGS)
 568 AC_SUBST(PYTHON_LIBS)
 569
 570 #
 571 # Logic for protobuf support.
 572 #
 573 if test "$enable_protobuf" = "yes"; then
 574    have_protobuf=yes
 575
 576    # Check for protoc-c
 577    AC_CHECK_PROG([PROTOC_C], [protoc-c], [protoc-c], [/bin/false])
 578    if test "x$PROTOC_C" = "x/bin/false"; then
 579       have_protobuf=no
 580    else
 581       found_protobuf_c=no
 582       PKG_CHECK_MODULES([PROTOBUF_C], libprotobuf-c >= 0.14,
 583                      [found_protobuf_c=yes],
 584                      [AC_MSG_RESULT([pkg-config did not find libprotobuf-c])])
 585
 586       if test "x$found_protobuf_c" = "xyes"; then
 587          LDFLAGS="$LDFLAGS $PROTOBUF_C_LIBS"
 588          CFLAGS="$CFLAGS $PROTOBUF_C_CFLAGS"
 589       else
 590         AC_CHECK_HEADER([google/protobuf-c/protobuf-c.h], [],
 591                         [have_protobuf=no; AC_MSG_RESULT([Couldn't find google/protobuf-c.h])])
 592       fi
 593    fi
 594 fi
 595
 596 #
 597 # Logic for old vpn commans support.
 598 #
 599 if test "$enable_oldvpn_commands" = "yes"; then
 600    AC_DEFINE(KEEP_OLD_VPN_COMMANDS,, [Define for compiling with old vpn commands])
 601 fi
 602
 603 # Fail if the user explicity enabled protobuf support and we couldn't
 604 # find the compiler or libraries.
 605 if test "x$have_protobuf" = "xno" && test "x$enable_protobuf" = "xyes"; then
 606    AC_MSG_ERROR([Protobuf enabled explicitly but can't find libraries/tools])
 607 fi
 608
 609 if test "x$have_protobuf" = "xyes"; then
 610    AC_DEFINE(HAVE_PROTOBUF,, protobuf)
 611 fi
 612
 613 AM_CONDITIONAL([HAVE_PROTOBUF], [test "x$have_protobuf" = "xyes"])
 614
 615 #
 616 # End of logic for protobuf support.
 617 #
 618
 619 if test "${enable_linux24_tcp_md5}" = "yes"; then
 620   AC_DEFINE(HAVE_TCP_MD5_LINUX24,,Old Linux 2.4 TCP MD5 Signature Patch)
 621 fi
 622
 623 AC_MSG_CHECKING(if zebra should be configurable to send Route Advertisements)
 624 if test "${enable_rtadv}" != "no"; then
 625   AC_MSG_RESULT(yes)
 626   AC_DEFINE(HAVE_RTADV,,Enable IPv6 Routing Advertisement support)
 627 else
 628   AC_MSG_RESULT(no)
 629 fi
 630
 631 if test x"${enable_user}" = x"no"; then
 632   enable_user=""
 633 else
 634   if test x"${enable_user}" = x"yes" || test x"${enable_user}" = x""; then
 635     enable_user="frr"
 636   fi
 637   AC_DEFINE_UNQUOTED(FRR_USER, "${enable_user}", frr User)
 638 fi
 639
 640 if test x"${enable_group}" = x"no"; then
 641   enable_group=""
 642 else
 643   if test x"${enable_group}" = x"yes" || test x"${enable_group}" = x""; then
 644     enable_group="frr"
 645   fi
 646   AC_DEFINE_UNQUOTED(FRR_GROUP, "${enable_group}", frr Group)
 647 fi
 648
 649 if test x"${enable_vty_group}" = x"yes" ; then
 650   AC_MSG_ERROR([--enable-vty-group requires a group as argument, not yes])
 651 elif test x"${enable_vty_group}" != x""; then
 652   if test x"${enable_vty_group}" != x"no"; then
 653     AC_DEFINE_UNQUOTED(VTY_GROUP, "${enable_vty_group}", VTY Sockets Group)
 654   fi
 655 fi
 656 AC_SUBST([enable_user])
 657 AC_SUBST([enable_group])
 658 AC_SUBST([enable_vty_group])
 659
 660 enable_configfile_mask=${enable_configfile_mask:-0600}
 661 AC_DEFINE_UNQUOTED(CONFIGFILE_MASK, ${enable_configfile_mask}, Mask for config files)
 662
 663 enable_logfile_mask=${enable_logfile_mask:-0600}
 664 AC_DEFINE_UNQUOTED(LOGFILE_MASK, ${enable_logfile_mask}, Mask for log files)
 665
 666 MPATH_NUM=1
 667
 668 case "${enable_multipath}" in
 669   0)
 670     MPATH_NUM=64
 671     ;;
 672   [[1-9]|[1-9][0-9]|[1-9][0-9][0-9]])
 673     MPATH_NUM="${enable_multipath}"
 674     ;;
 675   "")
 676     ;;
 677   *)
 678     AC_MSG_FAILURE([Please specify digit to enable multipath ARG])
 679     ;;
 680 esac
 681
 682 AC_DEFINE_UNQUOTED(MULTIPATH_NUM, $MPATH_NUM, Maximum number of paths for a route)
 683
 684 AC_DEFINE_UNQUOTED(VTYSH_PAGER, "$VTYSH_PAGER", [What pager to use])
 685
 686 dnl ------------------------------------
 687 dnl Alpine only accepts numeric versions
 688 dnl ------------------------------------
 689 if test "x${enable_numeric_version}" != "x" ; then
 690   VERSION="`echo ${VERSION} | tr -c -d '[[.0-9]]'`"
 691   PACKAGE_VERSION="`echo ${PACKAGE_VERSION} | tr -c -d '[[.0-9]]'`"
 692 fi
 693
 694 dnl -----------------------------------
 695 dnl Add extra version string to package
 696 dnl name, string and version fields.
 697 dnl -----------------------------------
 698 if test "x${EXTRAVERSION}" != "x" ; then
 699   VERSION="${VERSION}${EXTRAVERSION}"
 700   PACKAGE_VERSION="${PACKAGE_VERSION}${EXTRAVERSION}"
 701   AC_SUBST(PACKAGE_EXTRAVERSION, ["${EXTRAVERSION}"])
 702   PACKAGE_STRING="${PACKAGE_STRING}${EXTRAVERSION}"
 703 fi
 704
 705 if test "x$with_pkg_git_version" = "xyes"; then
 706         if test -d "${srcdir}/.git"; then
 707                 AC_DEFINE(GIT_VERSION, [1], [include git version info])
 708         else    with_pkg_git_version="no"
 709                 AC_MSG_WARN([--with-pkg-git-version given, but this is not a git checkout])
 710         fi
 711 fi
 712 AM_CONDITIONAL([GIT_VERSION], [test "x$with_pkg_git_version" = "xyes"])
 713
 714 dnl ------------------------------------
 715 dnl Check C keywords and standard  types
 716 dnl ------------------------------------
 717 AC_C_CONST
 718 AC_C_INLINE
 719 AC_C_VOLATILE
 720 AC_HEADER_STDC
 721 dnl AC_TYPE_PID_T
 722 AC_TYPE_UID_T
 723 AC_TYPE_MODE_T
 724 AC_TYPE_SIZE_T
 725 AC_STRUCT_TM
 726
 727 dnl -------------------------
 728 dnl Check other header files.
 729 dnl -------------------------
 730 AC_CHECK_HEADERS([stropts.h sys/ksym.h \
 731         linux/version.h asm/types.h \
 732         sys/cdefs.h])
 733
 734 ac_stdatomic_ok=false
 735 AC_DEFINE(FRR_AUTOCONF_ATOMIC, 1, [did autoconf checks for atomic funcs])
 736 AC_CHECK_HEADER([stdatomic.h],[
 737
 738   AC_MSG_CHECKING([whether _Atomic qualifier works])
 739   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 740 #include <stdatomic.h>
 741 int main(int argc, char **argv) {
 742   _Atomic int i = 0;
 743   return i;
 744 }
 745 ]])], [
 746     AC_DEFINE(HAVE_STDATOMIC_H, 1, [found stdatomic.h])
 747     AC_MSG_RESULT([yes])
 748     ac_stdatomic_ok=true
 749   ], [
 750     AC_MSG_RESULT([no])
 751   ])
 752 ])
 753
 754 AS_IF([$ac_stdatomic_ok], [true], [
 755   AC_MSG_CHECKING([for __atomic_* builtins])
 756   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 757 int main(int argc, char **argv) {
 758   volatile int i = 1;
 759   __atomic_store_n (&i, 0, __ATOMIC_RELEASE);
 760   return __atomic_load_n (&i, __ATOMIC_ACQUIRE);
 761 }
 762 ]])], [
 763     AC_DEFINE(HAVE___ATOMIC, 1, [found __atomic builtins])
 764     AC_MSG_RESULT([yes])
 765   ], [
 766     AC_MSG_RESULT([no])
 767
 768     dnl FreeBSD 9 has a broken stdatomic.h where _Atomic doesn't work
 769     AC_MSG_CHECKING([for __sync_* builtins])
 770     AC_LINK_IFELSE([AC_LANG_SOURCE([[
 771 int main(int argc, char **argv) {
 772   volatile int i = 1;
 773   __sync_fetch_and_sub (&i, 1);
 774   return __sync_val_compare_and_swap (&i, 0, 1);
 775 }
 776 ]])], [
 777       AC_DEFINE(HAVE___SYNC, 1, [found __sync builtins])
 778       AC_MSG_RESULT([yes])
 779
 780       AC_MSG_CHECKING([for __sync_swap builtin])
 781       AC_LINK_IFELSE([AC_LANG_SOURCE([[
 782 int main(int argc, char **argv) {
 783   volatile int i = 1;
 784   return __sync_swap (&i, 2);
 785 }
 786 ]])], [
 787         AC_DEFINE(HAVE___SYNC_SWAP, 1, [found __sync_swap builtin])
 788         AC_MSG_RESULT([yes])
 789       ], [
 790         AC_MSG_RESULT([no])
 791       ])
 792
 793     ], [
 794       AC_MSG_RESULT([no])
 795       AC_MSG_FAILURE([stdatomic.h unavailable and $CC has neither __atomic nor __sync builtins])
 796     ])
 797   ])
 798 ])
 799
 800 dnl Utility macro to avoid retyping includes all the time
 801 m4_define([FRR_INCLUDES],
 802 [#ifdef SUNOS_5
 803 #define _XPG4_2
 804 #define __EXTENSIONS__
 805 #endif
 806 #include <stdio.h>
 807 #include <stdlib.h>
 808 #include <stddef.h>
 809 #include <sys/types.h>
 810 /* sys/conf.h depends on param.h on FBSD at least */
 811 #include <sys/param.h>
 812 /* Required for MAXSIG */
 813 #include <signal.h>
 814 #include <sys/socket.h>
 815 #ifdef __APPLE__
 816 # define __APPLE_USE_RFC_3542
 817 #endif
 818 #include <netinet/in.h>
 819 #include <sys/time.h>
 820 #include <time.h>
 821 #include <net/if.h>
 822 ])dnl
 823
 824 dnl Same applies for HAVE_NET_IF_VAR_H, which HAVE_NETINET6_ND6_H and
 825 dnl HAVE_NETINET_IN_VAR_H depend upon. But if_var.h depends on if.h, hence
 826 dnl an additional round for it.
 827
 828 AC_CHECK_HEADERS([net/if_var.h], [], [], FRR_INCLUDES)
 829
 830 m4_define([FRR_INCLUDES],
 831 FRR_INCLUDES
 832 [#if HAVE_NET_IF_VAR_H
 833 # include <net/if_var.h>
 834 #endif
 835 ])dnl
 836
 837 AC_CHECK_HEADERS([netinet/in_var.h \
 838         net/if_dl.h net/netopt.h \
 839         inet/nd.h netinet/ip_icmp.h \
 840         sys/sysctl.h sys/sockio.h kvm.h sys/conf.h],
 841         [], [], FRR_INCLUDES)
 842
 843 AC_CHECK_HEADERS([ucontext.h], [], [],
 844 [#ifndef __USE_GNU
 845 #define __USE_GNU
 846 #endif /* __USE_GNU */
 847 FRR_INCLUDES
 848 ])
 849
 850 m4_define([UCONTEXT_INCLUDES],
 851 [#include <ucontext.h>])dnl
 852
 853 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.uc_regs],
 854   [], [], [UCONTEXT_INCLUDES])
 855 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs],
 856   [AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs.nip],
 857    [], [], [UCONTEXT_INCLUDES])],
 858   [], [UCONTEXT_INCLUDES])
 859 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.gregs],
 860   [], [], [UCONTEXT_INCLUDES])
 861
 862 m4_define([FRR_INCLUDES],
 863 FRR_INCLUDES
 864 [
 865 #include <sys/un.h>
 866 #include <netinet/in_systm.h>
 867 #if HAVE_NETINET_IN_VAR_H
 868 # include <netinet/in_var.h>
 869 #endif
 870 #if HAVE_NET_IF_DL_H
 871 # include <net/if_dl.h>
 872 #endif
 873 #if HAVE_NET_NETOPT_H
 874 # include <net/netopt.h>
 875 #endif
 876 #include <net/route.h>
 877 #if HAVE_INET_ND_H
 878 # include <inet/nd.h>
 879 #endif
 880 #include <arpa/inet.h>
 881 /* Required for IDRP */
 882 #if HAVE_NETINET_IP_ICMP_H
 883 # include <netinet/ip_icmp.h>
 884 #endif
 885 ])dnl
 886
 887 dnl V6 headers are checked below, after we check for v6
 888
 889 AC_MSG_CHECKING([which operating system interface to use])
 890 case "$host_os" in
 891   sunos* | solaris2*)
 892     AC_MSG_RESULT([Solaris])
 893
 894     AC_DEFINE(SUNOS_5, 1, [SunOS 5])
 895     AC_DEFINE(SOLARIS_IPV6, 1, Solaris IPv6)
 896
 897     AC_CHECK_LIB(socket, main)
 898     AC_CHECK_LIB(nsl, main)
 899     AC_CHECK_LIB(umem, main)
 900     AC_CHECK_FUNCS([printstack], [
 901       AC_DEFINE([HAVE_PRINTSTACK],1,[Solaris printstack])
 902       AC_DEFINE([HAVE_STACK_TRACE],1,[Stack symbols decode functionality])
 903     ])
 904     CURSES=-lcurses
 905     SOLARIS="solaris"
 906     ;;
 907   linux*)
 908     AC_MSG_RESULT([Linux])
 909
 910     AC_DEFINE(GNU_LINUX,,GNU Linux)
 911     AC_DEFINE(HAVE_NETLINK,,netlink)
 912     AC_DEFINE(LINUX_IPV6,1,Linux IPv6 stack)
 913
 914     dnl Linux has a compilation problem with mixing
 915     dnl netinet/in.h and linux/in6.h they are not
 916     dnl compatible.  There has been discussion on
 917     dnl how to fix it but no real progress on implementation
 918     dnl when they fix it, remove this
 919     AC_DEFINE(IPV6_MINHOPCOUNT, 73, Linux ipv6 Min Hop Count)
 920
 921     AC_CHECK_DECLS([IFLA_INFO_SLAVE_KIND], [], [], [#include <linux/if_link.h>])
 922     ;;
 923   openbsd*)
 924     AC_MSG_RESULT([OpenBSD])
 925
 926     AC_DEFINE(OPEN_BSD,,OpenBSD)
 927     AC_DEFINE(KAME,1,KAME IPv6)
 928     AC_DEFINE(BSD_V6_SYSCTL,1,BSD v6 sysctl to turn on and off forwarding)
 929
 930     if test "x${enable_pimd}" != "xno"; then
 931       case "$host_os" in
 932       openbsd6.0)
 933         ;;
 934       openbsd[6-9]*)
 935         AC_MSG_FAILURE([pimd cannot be enabled as PIM support has been removed from OpenBSD 6.1])
 936         ;;
 937       esac
 938     fi
 939     ;;
 940   *)
 941     AC_MSG_RESULT([BSD])
 942
 943     AC_DEFINE(HAVE_NET_RT_IFLIST,,NET_RT_IFLIST)
 944     AC_DEFINE(KAME,1,KAME IPv6)
 945     AC_DEFINE(BSD_V6_SYSCTL,1,BSD v6 sysctl to turn on and off forwarding)
 946     ;;
 947 esac
 948 AM_CONDITIONAL(SOLARIS, test "${SOLARIS}" = "solaris")
 949
 950 AC_SYS_LARGEFILE
 951
 952 dnl ------------------------
 953 dnl Integrated REALMS option
 954 dnl ------------------------
 955 if test "${enable_realms}" = "yes"; then
 956     case "$host_os" in
 957       linux*)
 958        AC_DEFINE(SUPPORT_REALMS,, Realms support)
 959        ;;
 960       *)
 961        echo "Sorry, only Linux has REALMS support"
 962        exit 1
 963        ;;
 964     esac
 965 fi
 966 AM_CONDITIONAL([SUPPORT_REALMS], [test "${enable_realms}" = "yes"])
 967
 968 dnl ---------------------
 969 dnl Integrated VTY option
 970 dnl ---------------------
 971 case "${enable_vtysh}" in
 972   "no") VTYSH="";;
 973   *)    VTYSH="vtysh";
 974          AC_DEFINE(VTYSH,,VTY shell)
 975 dnl      Vtysh uses libreadline, which looks for termcap functions at
 976 dnl      configure time.  We follow readlines search order.
 977 dnl      The required procedures are in libtermcap on NetBSD, in
 978 dnl      [TODO] on Linux, and in [TODO] on Solaris.
 979          AC_CHECK_LIB(termcap, tputs, LIBREADLINE="$LIBREADLINE -ltermcap",
 980            [AC_CHECK_LIB(tinfo, tputs, LIBREADLINE="$LIBREADLINE -ltinfo",
 981              [AC_CHECK_LIB(curses, tputs, LIBREADLINE="$LIBREADLINE -lcurses",
 982                [AC_CHECK_LIB(ncurses, tputs,
 983                              LIBREADLINE="$LIBREADLINE -lncurses")]
 984               )]
 985             )]
 986           )
 987          AC_CHECK_LIB(readline, main, LIBREADLINE="-lreadline $LIBREADLINE",,
 988                       "$LIBREADLINE")
 989          if test $ac_cv_lib_readline_main = no; then
 990            AC_MSG_ERROR([vtysh needs libreadline but was not found and usable on your system.])
 991          fi
 992          AC_CHECK_HEADER(readline/history.h)
 993          if test $ac_cv_header_readline_history_h = no;then
 994            AC_MSG_ERROR([readline is too old to have readline/history.h, please update to the latest readline library.])
 995          fi
 996          AC_CHECK_LIB(readline, rl_completion_matches,
 997                       LIBREADLINE="$LIBREADLINE",, "$LIBREADLINE")
 998          if test $ac_cv_lib_readline_rl_completion_matches = no; then
 999            AC_DEFINE(rl_completion_matches,completion_matches,Old readline)
1000          fi
1001          ;;
1002 esac
1003 AC_SUBST(LIBREADLINE)
1004 AM_CONDITIONAL(VTYSH, test "x$VTYSH" = "xvtysh")
1005
1006 dnl ----------
1007 dnl PAM module
1008 dnl
1009 dnl FRR detects the PAM library it is built against by checking for a
1010 dnl functional pam_misc.h (Linux-PAM) or openpam.h (OpenPAM) header. pam_misc.h
1011 dnl is known to #include pam_appl.h, the standard header of a PAM library, and
1012 dnl openpam.h doesn't do that, although depends on the header too. Hence a
1013 dnl little assistance to AC_CHECK_HEADER is necessary for the proper detection
1014 dnl of OpenPAM.
1015 dnl ----------
1016 if test "$with_libpam" = "yes"; then
1017   AC_CHECK_HEADER([security/pam_misc.h],
1018     [AC_DEFINE(HAVE_PAM_MISC_H,,Have pam_misc.h)
1019      AC_DEFINE(PAM_CONV_FUNC,misc_conv,Have misc_conv)
1020      pam_conv_func="misc_conv"
1021     ],
1022     [], FRR_INCLUDES)
1023   AC_CHECK_HEADER([security/openpam.h],
1024     [AC_DEFINE(HAVE_OPENPAM_H,,Have openpam.h)
1025      AC_DEFINE(PAM_CONV_FUNC,openpam_ttyconv,Have openpam_ttyconv)
1026      pam_conv_func="openpam_ttyconv"
1027     ],
1028     [], FRR_INCLUDES[#include <security/pam_appl.h>])
1029   if test -z "$ac_cv_header_security_pam_misc_h$ac_cv_header_security_openpam_h" ; then
1030     AC_MSG_WARN([*** pam support will not be built ***])
1031     with_libpam="no"
1032   fi
1033 fi
1034
1035 if test "$with_libpam" = "yes"; then
1036 dnl took this test from proftpds configure.in and suited to our needs
1037 dnl -------------------------------------------------------------------------
1038 dnl
1039 dnl This next check looks funky due to a linker problem with some versions
1040 dnl of the PAM library.  Prior to 0.72 release, the Linux PAM shared library
1041 dnl omitted requiring libdl linking information. PAM-0.72 or better ships
1042 dnl with RedHat 6.2 and Debian 2.2 or better.
1043 AC_CHECK_LIB(pam, pam_start,
1044   [AC_CHECK_LIB(pam, $pam_conv_func,
1045     [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1046      LIBPAM="-lpam"],
1047     [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1048      LIBPAM="-lpam -lpam_misc"]
1049     )
1050   ],
1051
1052   [AC_CHECK_LIB(pam, pam_end,
1053     [AC_CHECK_LIB(pam, $pam_conv_func,
1054       [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1055        LIBPAM="-lpam -ldl"],
1056       [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1057        LIBPAM="-lpam -ldl -lpam_misc"]
1058      )
1059   ],AC_MSG_WARN([*** pam support will not be built ***]),
1060   [-ldl])
1061   ]
1062 )
1063 fi
1064 AC_SUBST(LIBPAM)
1065
1066 dnl -------------------------------
1067 dnl Endian-ness check
1068 dnl -------------------------------
1069 AC_WORDS_BIGENDIAN
1070
1071 dnl -------------------------------
1072 dnl check the size in byte of the C
1073 dnl -------------------------------
1074 dnl AC_CHECK_SIZEOF(char)
1075 dnl AC_CHECK_SIZEOF(int)
1076 dnl AC_CHECK_SIZEOF(short)
1077 dnl AC_CHECK_SIZEOF(long)
1078
1079 dnl ----------------------------
1080 dnl check existance of functions
1081 dnl ----------------------------
1082 AC_FUNC_FNMATCH
1083 AC_FUNC_FORK
1084 AC_FUNC_MKTIME
1085 AC_FUNC_STAT
1086
1087 dnl -------------------------------
1088 dnl bgpd needs pow() and hence libm
1089 dnl -------------------------------
1090 TMPLIBS="$LIBS"
1091 AC_CHECK_HEADER([math.h],
1092   [AC_CHECK_LIB([m], [pow],
1093     [LIBM="-lm"
1094      LIBS="$LIBS $LIBM"
1095      AC_CHECK_FUNCS(pow,[],[LIBM=""])
1096     ])
1097 ])
1098 if test x"$LIBM" = x ; then
1099   AC_MSG_WARN([Unable to find working pow function - bgpd may not link])
1100 fi
1101 LIBS="$TMPLIBS"
1102 AC_SUBST(LIBM)
1103
1104 AC_CHECK_FUNCS([ppoll], [
1105   AC_DEFINE([HAVE_PPOLL], 1, [have Linux/BSD ppoll()])
1106 ])
1107 AC_CHECK_FUNCS([pollts], [
1108   AC_DEFINE([HAVE_POLLTS], 1, [have NetBSD pollts()])
1109 ])
1110
1111 dnl ---------------
1112 dnl other functions
1113 dnl ---------------
1114 AC_CHECK_FUNCS([ \
1115         strlcat strlcpy \
1116         getgrouplist])
1117
1118 AC_CHECK_HEADER([asm-generic/unistd.h],
1119                 [AC_CHECK_DECL(__NR_setns,
1120                                AC_DEFINE(HAVE_NETNS,, Have netns),,
1121                                FRR_INCLUDES [#include <asm-generic/unistd.h>
1122                                ])
1123                  AC_CHECK_FUNCS(setns)]
1124                )
1125
1126 dnl --------------------------
1127 dnl Determine IS-IS I/O method
1128 dnl --------------------------
1129 AC_DEFINE(ISIS_METHOD_PFPACKET, 1, [ constant value for isis method pfpacket ])
1130 AC_DEFINE(ISIS_METHOD_DLPI,     2, [ constant value for isis method dlpi ])
1131 AC_DEFINE(ISIS_METHOD_BPF,      3, [ constant value for isis method bpf ])
1132 AC_CHECK_HEADER(net/bpf.h)
1133 AC_CHECK_HEADER(sys/dlpi.h)
1134 AC_MSG_CHECKING(zebra IS-IS I/O method)
1135
1136 case "$host_os" in
1137   linux*)
1138     AC_MSG_RESULT(pfpacket)
1139     ISIS_METHOD_MACRO="ISIS_METHOD_PFPACKET"
1140     ;;
1141   solaris* | sunos*)
1142     AC_MSG_RESULT(DLPI)
1143     ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1144     ;;
1145   *)
1146     if test $ac_cv_header_net_bpf_h = no; then
1147       if test $ac_cv_header_sys_dlpi_h = no; then
1148         AC_MSG_RESULT(none)
1149         if test "${enable_isisd}" = yes; then
1150           AC_MSG_FAILURE([IS-IS support requested but no packet backend found])
1151         fi
1152         AC_MSG_WARN([*** IS-IS support will not be built ***])
1153         enable_isisd="no"
1154       else
1155         AC_MSG_RESULT(DLPI)
1156       fi
1157       ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1158     else
1159       AC_MSG_RESULT(BPF)
1160       ISIS_METHOD_MACRO="ISIS_METHOD_BPF"
1161     fi
1162     ;;
1163 esac
1164 AC_DEFINE_UNQUOTED(ISIS_METHOD, $ISIS_METHOD_MACRO, [ selected method for isis, == one of the constants ])
1165
1166 dnl ------------------------------------
1167 dnl check for broken CMSG_FIRSTHDR macro
1168 dnl ------------------------------------
1169 AC_MSG_CHECKING(for broken CMSG_FIRSTHDR)
1170 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1171 #ifdef SUNOS_5
1172 #define _XPG4_2
1173 #define __EXTENSIONS__
1174 #endif
1175 #include <stdlib.h>
1176 #include <sys/types.h>
1177 #include <sys/socket.h>
1178
1179 main()
1180 {
1181   struct msghdr msg;
1182   char buf[4];
1183
1184   msg.msg_control = buf;
1185   msg.msg_controllen = 0;
1186
1187   if (CMSG_FIRSTHDR(&msg) != NULL)
1188     exit(0);
1189   exit (1);
1190 }]])],[AC_MSG_RESULT(yes - using workaround) AC_DEFINE(HAVE_BROKEN_CMSG_FIRSTHDR,,Broken CMSG_FIRSTHDR)],
1191 [AC_MSG_RESULT(no)],[AC_MSG_RESULT(no)])
1192
1193 dnl ---------------------------------------------------------------
1194 dnl figure out how to specify an interface in multicast sockets API
1195 dnl ---------------------------------------------------------------
1196 AC_CHECK_MEMBERS([struct ip_mreqn.imr_ifindex], [], [], FRR_INCLUDES)
1197
1198 AC_CHECK_HEADERS([linux/mroute.h], [], [],[
1199         #include <sys/socket.h>
1200         #include <netinet/in.h>
1201         #define _LINUX_IN_H             /* For Linux <= 2.6.25 */
1202         #include <linux/types.h>
1203 ])
1204
1205 m4_define([FRR_INCLUDES],
1206 FRR_INCLUDES
1207 [#if HAVE_LINUX_MROUTE_H
1208 # include <linux/mroute.h>
1209 #endif
1210 ])dnl
1211
1212 AC_CHECK_HEADERS([netinet/ip_mroute.h], [], [],[
1213         #include <sys/socket.h>
1214         #include <sys/types.h>
1215         #include <netinet/in.h>
1216         #include <net/route.h>
1217 ])
1218
1219 m4_define([FRR_INCLUDES],
1220 FRR_INCLUDES
1221 [#if HAVE_NETINET_IP_MROUTE_H
1222 # include <netinet/ip_mroute.h>
1223 #endif
1224 ])dnl
1225
1226 AC_MSG_CHECKING([for BSD struct ip_mreq hack])
1227 AC_TRY_COMPILE([#include <sys/param.h>],
1228 [#if (defined(__FreeBSD__) && ((__FreeBSD_version >= 500022 && __FreeBSD_version < 700000) || (__FreeBSD_version < 500000 && __FreeBSD_version >= 440000))) || (defined(__NetBSD__) && defined(__NetBSD_Version__) && __NetBSD_Version__ >= 106010000) || defined(__OpenBSD__) || defined(__APPLE__) || defined(__DragonFly__) || defined(__sun)
1229   return (0);
1230 #else
1231   #error No support for BSD struct ip_mreq hack detected
1232 #endif],[AC_MSG_RESULT(yes)
1233 AC_DEFINE(HAVE_BSD_STRUCT_IP_MREQ_HACK,,[Can pass ifindex in struct ip_mreq])],
1234 AC_MSG_RESULT(no))
1235
1236 AC_MSG_CHECKING([for RFC3678 protocol-independed API])
1237 AC_TRY_COMPILE([
1238 #include <sys/types.h>
1239 #include <netinet/in.h>
1240 ], [struct group_req gr; int sock; setsockopt(sock, IPPROTO_IP, MCAST_JOIN_GROUP, (void*)&gr, sizeof(gr));
1241 ], [AC_MSG_RESULT(yes)
1242 AC_DEFINE(HAVE_RFC3678,1,[Have RFC3678 protocol-independed API])],
1243 AC_MSG_RESULT(no))
1244
1245 dnl ---------------------------------------------------------------
1246 dnl figure out how to check link-state
1247 dnl ---------------------------------------------------------------
1248 AC_CHECK_HEADER( [net/if_media.h],
1249   [m4_define([LINK_DETECT_INCLUDES],
1250     FRR_INCLUDES
1251     [#include <net/if_media.h>
1252   ])
1253   AC_CHECK_MEMBERS( [struct ifmediareq.ifm_status],
1254     AC_DEFINE(HAVE_BSD_LINK_DETECT,,[BSD link-detect]),
1255     [], LINK_DETECT_INCLUDES)],
1256   [],
1257   FRR_INCLUDES)
1258
1259 dnl ---------------------------------------------------------------
1260 dnl Additional, newer way to check link-state using ifi_link_state.
1261 dnl Not available in all BSD's when ifmediareq available
1262 dnl ---------------------------------------------------------------
1263 AC_CHECK_MEMBERS([struct if_data.ifi_link_state],
1264   AC_DEFINE(HAVE_BSD_IFI_LINK_STATE,,[BSD ifi_link_state available]),
1265   [], FRR_INCLUDES)
1266
1267 dnl ------------------------
1268 dnl TCP_MD5SIG socket option
1269 dnl ------------------------
1270
1271 AC_CHECK_HEADER([netinet/tcp.h],
1272    [m4_define([MD5_INCLUDES],
1273       FRR_INCLUDES
1274       [#include <netinet/tcp.h>
1275     ])
1276     AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)],
1277    [],
1278    FRR_INCLUDES)
1279 if test $ac_cv_have_decl_TCP_MD5SIG = no; then
1280   AC_CHECK_HEADER([linux/tcp.h],
1281        [m4_define([MD5_INCLUDES],
1282           FRR_INCLUDES
1283           [#include <linux/tcp.h>
1284         ])
1285        AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)])
1286 fi
1287
1288 dnl ----------------------------------------------------------------------------
1289 dnl figure out if domainname is available in the utsname struct (GNU extension).
1290 dnl ----------------------------------------------------------------------------
1291 AC_CHECK_MEMBERS([struct utsname.domainname], [], [], [#include <sys/utsname.h>])
1292
1293 dnl ------------------
1294 dnl IPv6 header checks
1295 dnl ------------------
1296 AC_CHECK_HEADERS([netinet6/in6.h netinet/in6_var.h \
1297         netinet6/in6_var.h netinet6/nd6.h], [], [],
1298         FRR_INCLUDES)
1299
1300 m4_define([FRR_INCLUDES],dnl
1301 FRR_INCLUDES
1302 [#if HAVE_NETINET6_IN6_H
1303 #include <netinet6/in6.h>
1304 #endif
1305 #if HAVE_NETINET_IN6_VAR_H
1306 #include <netinet/in6_var.h>
1307 #endif
1308 #include <netinet/icmp6.h>
1309 #if HAVE_NETINET6_IN6_VAR_H
1310 # include <netinet6/in6_var.h>
1311 #endif
1312 #if HAVE_NETINET6_ND6_H
1313 # include <netinet6/nd6.h>
1314 #endif
1315 ])dnl
1316
1317 dnl disable doc check
1318 if test "${enable_doc}" = "no";then
1319   DOC=""
1320 else
1321   DOC="doc"
1322 fi
1323
1324 dnl --------------------
1325 dnl Daemon disable check
1326 dnl --------------------
1327 AM_CONDITIONAL(ZEBRA, test "${enable_zebra}" != "no")
1328
1329 if test "${enable_bgpd}" = "no";then
1330   BGPD=""
1331 else
1332   BGPD="bgpd"
1333 fi
1334 AM_CONDITIONAL(BGPD, test "x$BGPD" = "xbgpd")
1335
1336 AM_CONDITIONAL(RIPD, test "${enable_ripd}" != "no")
1337 AM_CONDITIONAL(OSPFD, test "${enable_ospfd}" != "no")
1338 AM_CONDITIONAL(LDPD, test "${enable_ldpd}" != "no")
1339
1340 AS_IF([test "${enable_ldpd}" != "no"], [
1341   AC_DEFINE(HAVE_LDPD, 1, ldpd)
1342 ])
1343
1344 NHRPD=""
1345 case "$host_os" in
1346   linux*)
1347     if test "${enable_nhrpd}" != "no"; then
1348       NHRPD="nhrpd"
1349     fi
1350     ;;
1351   *)
1352     if test "${enable_nhrpd}" = "yes"; then
1353       AC_MSG_ERROR([nhrpd requires kernel APIs that are only present on Linux.])
1354     fi
1355     ;;
1356 esac
1357 AM_CONDITIONAL(NHRPD, test "x$NHRPD" = "xnhrpd")
1358
1359 AM_CONDITIONAL(EIGRPD, test "${enable_eigrpd}" != "no")
1360
1361 if test "${enable_watchfrr}" = "no";then
1362   WATCHFRR=""
1363 else
1364   WATCHFRR="watchfrr"
1365 fi
1366 AM_CONDITIONAL(WATCHFRR, test "x$WATCHFRR" = "xwatchfrr")
1367
1368 OSPFCLIENT=""
1369 if test "${enable_ospfapi}" != "no";then
1370     AC_DEFINE(SUPPORT_OSPF_API,,OSPFAPI)
1371
1372   if test "${enable_ospfclient}" != "no";then
1373       OSPFCLIENT="ospfclient"
1374   fi
1375 fi
1376
1377 AM_CONDITIONAL(OSPFCLIENT, test "x$OSPFCLIENT" = "xospfclient")
1378 AM_CONDITIONAL(RIPNGD, test "${enable_ripngd}" != "no")
1379 AM_CONDITIONAL(BABELD, test "${enable_babeld}" != "no")
1380 AM_CONDITIONAL(OSPF6D, test "${enable_ospf6d}" != "no")
1381 AM_CONDITIONAL(ISISD, test "${enable_isisd}" != "no")
1382 AM_CONDITIONAL(PIMD, test "${enable_pimd}" != "no")
1383 AM_CONDITIONAL(PBRD, test "${enable_pbrd}" != "no")
1384 AM_CONDITIONAL(SHARPD, test "${enable_sharpd}" = "yes")
1385
1386 if test "${enable_bgp_announce}" = "no";then
1387   AC_DEFINE(DISABLE_BGP_ANNOUNCE,1,Disable BGP installation to zebra)
1388 else
1389   AC_DEFINE(DISABLE_BGP_ANNOUNCE,0,Disable BGP installation to zebra)
1390 fi
1391
1392 if test "${with_rfp_path}" = "yes" || test x"${with_rfp_path}" = x""; then
1393   with_rfp_path="bgpd/rfp-example"
1394 fi
1395 if test "${with_rfp_path}" != "no"; then
1396   VNC_RFP_PATH="${with_rfp_path}"
1397   AC_SUBST(VNC_RFP_PATH)
1398 fi
1399
1400 if test "${enable_bgp_vnc}" != "no";then
1401   AC_DEFINE(ENABLE_BGP_VNC,1,Enable BGP VNC support)
1402   RFPTEST="${with_rfp_path}/rfptest"
1403   LIBRFP="${with_rfp_path}/librfp"
1404   RFPINC="${with_rfp_path}/librfp"
1405 else
1406   RFPTEST=
1407   LIBRFP=
1408   RFPINC="bgpd/rfp-example/librfp"
1409 fi
1410 # set
1411 AM_CONDITIONAL([ENABLE_BGP_VNC], [test x${enable_bgp_vnc} != xno])
1412
1413 AC_SUBST(DOC)
1414 AC_SUBST(RFPTEST)
1415 AC_SUBST(LIBRFP)
1416 AC_SUBST(RFPINC)
1417 AC_SUBST(BGPD)
1418 AC_SUBST(SOLARIS)
1419 AC_SUBST(VTYSH)
1420 AC_SUBST(CURSES)
1421 AC_CHECK_LIB(crypt, crypt, [],
1422                     [AC_CHECK_LIB(crypto, DES_crypt)])
1423 AC_CHECK_LIB(resolv, res_init)
1424
1425 dnl ---------------------------
1426 dnl check system has PCRE regexp
1427 dnl ---------------------------
1428 if test "x$enable_pcreposix" = "xyes"; then
1429   AC_CHECK_LIB(pcreposix, regexec, [], [
1430     AC_MSG_ERROR([--enable-pcreposix given but unable to find libpcreposix])
1431   ])
1432 fi
1433 AC_SUBST(HAVE_LIBPCREPOSIX)
1434
1435 dnl ------------------
1436 dnl check C-Ares library
1437 dnl ------------------
1438 if test "${NHRPD}" != ""; then
1439   PKG_CHECK_MODULES([CARES], [libcares], , [
1440     AC_MSG_ERROR([trying to build nhrpd, but libcares not found. install c-ares and its -dev headers.])
1441   ])
1442 fi
1443
1444
1445 dnl ------------------
1446 dnl check Net-SNMP library
1447 dnl ------------------
1448 if test "${enable_snmp}" != "" -a "${enable_snmp}" != "no"; then
1449    AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], [no])
1450    if test x"$NETSNMP_CONFIG" = x"no"; then
1451       AC_MSG_ERROR([--enable-snmp given but unable to find net-snmp-config])
1452    fi
1453    SNMP_LIBS="`${NETSNMP_CONFIG} --agent-libs`"
1454    SNMP_CFLAGS="`${NETSNMP_CONFIG} --base-cflags`"
1455    AC_MSG_CHECKING([whether we can link to Net-SNMP])
1456    AC_LINK_IFELSE_FLAGS([$SNMP_CFLAGS], [$SNMP_LIBS], [AC_LANG_PROGRAM([
1457 int main(void);
1458 ],
1459 [
1460 {
1461   return 0;
1462 }
1463 ])], [
1464      AC_MSG_ERROR([--enable-snmp given but not usable])])
1465    case "${enable_snmp}" in
1466      yes)
1467       SNMP_METHOD=agentx
1468       ;;
1469      smux|agentx)
1470       SNMP_METHOD="${enable_snmp}"
1471       ;;
1472      *)
1473       AC_MSG_ERROR([--enable-snmp given with an unknown method (${enable_snmp}). Use smux or agentx])
1474       ;;
1475    esac
1476    AH_TEMPLATE([SNMP_SMUX], [Use SNMP SMUX to interface with snmpd])
1477    AH_TEMPLATE([SNMP_AGENTX], [Use SNMP AgentX to interface with snmpd])
1478    AC_DEFINE_UNQUOTED(AS_TR_CPP(SNMP_${SNMP_METHOD}),,SNMP method to interface with snmpd)
1479 fi
1480 AM_CONDITIONAL([SNMP], [test "x${SNMP_METHOD}" != "x"])
1481 AC_SUBST(SNMP_LIBS)
1482 AC_SUBST(SNMP_CFLAGS)
1483
1484 dnl ---------------
1485 dnl math
1486 dnl ---------------
1487 AC_SEARCH_LIBS([sqrt], [m])
1488
1489 dnl ---------------
1490 dnl dlopen & dlinfo
1491 dnl ---------------
1492 AC_SEARCH_LIBS(dlopen, [dl dld], [], [
1493   AC_MSG_ERROR([unable to find the dlopen()])
1494 ])
1495
1496 AC_CHECK_HEADERS([link.h])
1497
1498 AC_MSG_CHECKING([for dlinfo(RTLD_DI_ORIGIN)])
1499 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1500 #include <stdlib.h>
1501 #ifdef HAVE_LINK_H
1502 #include <link.h>
1503 #endif
1504 #include <dlfcn.h>
1505 ]], [[
1506   char origin[1];
1507   dlinfo (NULL, RTLD_DI_ORIGIN, &origin);
1508 ]])], [
1509   AC_MSG_RESULT(yes)
1510   AC_DEFINE(HAVE_DLINFO_ORIGIN, 1, [Have dlinfo RTLD_DI_ORIGIN])
1511 ], [
1512   AC_MSG_RESULT(no)
1513 ])
1514
1515 AC_MSG_CHECKING([for dlinfo(RTLD_DI_LINKMAP)])
1516 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1517 #include <stdlib.h>
1518 #ifdef HAVE_LINK_H
1519 #include <link.h>
1520 #endif
1521 #include <dlfcn.h>
1522 ]], [[
1523   struct link_map *lm = NULL;
1524   dlinfo (NULL, RTLD_DI_LINKMAP, &lm);
1525 ]])], [
1526   AC_MSG_RESULT(yes)
1527   AC_DEFINE(HAVE_DLINFO_LINKMAP, 1, [Have dlinfo RTLD_DI_LINKMAP])
1528 ], [
1529   AC_MSG_RESULT(no)
1530 ])
1531
1532
1533 AM_CONDITIONAL(SNMP, test "x$SNMP_METHOD" = "xagentx")
1534
1535 dnl ---------------------------
1536 dnl sockaddr and netinet checks
1537 dnl ---------------------------
1538 AC_CHECK_TYPES([
1539         struct sockaddr_dl,
1540         struct vifctl, struct mfcctl, struct sioc_sg_req,
1541         vifi_t, struct sioc_vif_req, struct igmpmsg,
1542         struct ifaliasreq, struct if6_aliasreq, struct in6_aliasreq,
1543         struct nd_opt_adv_interval, struct rt_addrinfo,
1544         struct nd_opt_homeagent_info, struct nd_opt_adv_interval],
1545         [], [], FRR_INCLUDES)
1546
1547 AC_CHECK_MEMBERS([struct sockaddr.sa_len,
1548         struct sockaddr_in.sin_len, struct sockaddr_un.sun_len,
1549         struct sockaddr_dl.sdl_len,
1550         struct if6_aliasreq.ifra_lifetime,
1551         struct nd_opt_adv_interval.nd_opt_ai_type],
1552         [], [], FRR_INCLUDES)
1553
1554 dnl ---------------------------
1555 dnl IRDP/pktinfo/icmphdr checks
1556 dnl ---------------------------
1557
1558 AC_CHECK_TYPES([struct in_pktinfo], [
1559   AC_CHECK_TYPES([struct icmphdr], [
1560     IRDP=true
1561   ], [
1562     IRDP=false
1563   ], [FRR_INCLUDES])
1564 ], [
1565   IRDP=false
1566 ], [FRR_INCLUDES])
1567
1568 case "${enable_irdp}" in
1569 yes)
1570   $IRDP || AC_MSG_ERROR(['IRDP requires in_pktinfo at the moment!'])
1571   ;;
1572 no)
1573   IRDP=false
1574   ;;
1575 esac
1576
1577 AM_CONDITIONAL(IRDP, $IRDP)
1578
1579 dnl -----------------------
1580 dnl checking for IP_PKTINFO
1581 dnl -----------------------
1582 AC_MSG_CHECKING(for IP_PKTINFO)
1583 AC_TRY_COMPILE([#include <netdb.h>], [
1584   int opt = IP_PKTINFO;
1585 ], [
1586   AC_MSG_RESULT(yes)
1587   AC_DEFINE(HAVE_IP_PKTINFO, 1, [Have IP_PKTINFO])
1588 ], [
1589   AC_MSG_RESULT(no)
1590 ])
1591
1592 dnl ---------------------------
1593 dnl checking for IP_RECVDSTADDR
1594 dnl ---------------------------
1595 AC_MSG_CHECKING(for IP_RECVDSTADDR)
1596 AC_TRY_COMPILE([#include <netinet/in.h>], [
1597   int opt = IP_RECVDSTADDR;
1598 ], [
1599   AC_MSG_RESULT(yes)
1600   AC_DEFINE(HAVE_IP_RECVDSTADDR, 1, [Have IP_RECVDSTADDR])
1601 ], [
1602   AC_MSG_RESULT(no)
1603 ])
1604
1605 dnl ----------------------
1606 dnl checking for IP_RECVIF
1607 dnl ----------------------
1608 AC_MSG_CHECKING(for IP_RECVIF)
1609 AC_TRY_COMPILE([#include <netinet/in.h>], [
1610   int opt = IP_RECVIF;
1611 ], [
1612   AC_MSG_RESULT(yes)
1613   AC_DEFINE(HAVE_IP_RECVIF, 1, [Have IP_RECVIF])
1614 ], [
1615   AC_MSG_RESULT(no)
1616 ])
1617
1618 dnl ----------------------
1619 dnl checking for SO_BINDANY
1620 dnl ----------------------
1621 AC_MSG_CHECKING(for SO_BINDANY)
1622 AC_TRY_COMPILE([#include <sys/socket.h>], [
1623   int opt = SO_BINDANY;
1624 ], [
1625   AC_MSG_RESULT(yes)
1626   AC_DEFINE(HAVE_SO_BINDANY, 1, [Have SO_BINDANY])
1627 ], [
1628   AC_MSG_RESULT(no)
1629 ])
1630
1631 dnl ----------------------
1632 dnl checking for IP_FREEBIND
1633 dnl ----------------------
1634 AC_MSG_CHECKING(for IP_FREEBIND)
1635 AC_TRY_COMPILE([#include <netinet/in.h>], [
1636   int opt = IP_FREEBIND;
1637 ], [
1638   AC_MSG_RESULT(yes)
1639   AC_DEFINE(HAVE_IP_FREEBIND, 1, [Have IP_FREEBIND])
1640 ], [
1641   AC_MSG_RESULT(no)
1642 ])
1643
1644 dnl --------------------------------------
1645 dnl checking for be32dec existence or not
1646 dnl --------------------------------------
1647 AC_CHECK_DECLS([be32enc, be32dec], [], [],
1648                [#include <sys/endian.h>])
1649
1650 dnl --------------------------------------
1651 dnl checking for clock_time monotonic struct and call
1652 dnl --------------------------------------
1653 AC_CHECK_DECL(CLOCK_MONOTONIC,
1654         [AC_CHECK_LIB(rt, clock_gettime, [LIBS="$LIBS -lrt"])
1655          AC_DEFINE(HAVE_CLOCK_MONOTONIC,, Have monotonic clock)
1656 ], [AC_MSG_RESULT(no)], [FRR_INCLUDES])
1657
1658 dnl --------------------------------------
1659 dnl checking for flex and bison
1660 dnl --------------------------------------
1661
1662 AM_PROG_LEX
1663 AC_MSG_CHECKING(version of flex)
1664 frr_ac_flex_version="$(eval $LEX -V | grep flex | head -n 1)"
1665 frr_ac_flex_version="${frr_ac_flex_version##* }"
1666 AC_MSG_RESULT([$frr_ac_flex_version])
1667 AX_COMPARE_VERSION([$frr_ac_flex_version], [lt], [2.5.20], [
1668   LEX="$SHELL $missing_dir/missing flex"
1669   if test -f "${srcdir}/lib/command_lex.c" -a -f "${srcdir}/lib/command_lex.h"; then
1670     AC_MSG_WARN([using pregenerated flex output files])
1671   else
1672     AC_MSG_ERROR([flex failure and pregenerated files not included (probably a git build)])
1673   fi
1674   AC_SUBST([LEX_OUTPUT_ROOT], [lex.yy])
1675   AC_SUBST([LEXLIB], [''])
1676 ])
1677
1678 AC_PROG_YACC
1679 dnl thanks GNU bison for this b*llshit...
1680 AC_MSG_CHECKING(version of bison)
1681 frr_ac_bison_version="$(eval $YACC -V | grep bison | head -n 1)"
1682 frr_ac_bison_version="${frr_ac_bison_version##* }"
1683 frr_ac_bison_missing="false"
1684 case "x${frr_ac_bison_version}" in
1685   x2.7*)
1686     BISON_OPENBRACE='"'
1687     BISON_CLOSEBRACE='"'
1688     BISON_VERBOSE=''
1689     AC_MSG_RESULT([$frr_ac_bison_version - 2.7 or older])
1690     ;;
1691   x2.*|x1.*)
1692     AC_MSG_RESULT([$frr_ac_bison_version])
1693     AC_MSG_WARN([installed bison is too old.  Please install GNU bison 2.7.x or newer.])
1694     frr_ac_bison_missing="true"
1695     ;;
1696   x)
1697     AC_MSG_RESULT([none])
1698     AC_MSG_WARN([could not determine bison version.  Please install GNU bison 2.7.x or newer.])
1699     frr_ac_bison_missing="true"
1700     ;;
1701   *)
1702     BISON_OPENBRACE='{'
1703     BISON_CLOSEBRACE='}'
1704     BISON_VERBOSE='-Dparse.error=verbose'
1705     AC_MSG_RESULT([$frr_ac_bison_version - 3.0 or newer])
1706     ;;
1707 esac
1708 AC_SUBST(BISON_OPENBRACE)
1709 AC_SUBST(BISON_CLOSEBRACE)
1710 AC_SUBST(BISON_VERBOSE)
1711
1712 if $frr_ac_bison_missing; then
1713   YACC="$SHELL $missing_dir/missing bison -y"
1714   if test -f "${srcdir}/lib/command_parse.c" -a -f "${srcdir}/lib/command_parse.h"; then
1715     AC_MSG_WARN([using pregenerated bison output files])
1716   else
1717     AC_MSG_ERROR([bison failure and pregenerated files not included (probably a git build)])
1718   fi
1719 fi
1720
1721 dnl -------------------
1722 dnl capabilities checks
1723 dnl -------------------
1724 if test "${enable_capabilities}" != "no"; then
1725   AC_MSG_CHECKING(whether prctl PR_SET_KEEPCAPS is available)
1726   AC_TRY_COMPILE([#include <sys/prctl.h>],[prctl(PR_SET_KEEPCAPS, 1, 0, 0, 0);],
1727     [AC_MSG_RESULT(yes)
1728      AC_DEFINE(HAVE_PR_SET_KEEPCAPS,,prctl)
1729      frr_ac_keepcaps="yes"],
1730      AC_MSG_RESULT(no)
1731   )
1732   if test x"${frr_ac_keepcaps}" = x"yes"; then
1733     AC_CHECK_HEADERS(sys/capability.h)
1734   fi
1735   if test x"${ac_cv_header_sys_capability_h}" = x"yes"; then
1736     AC_CHECK_LIB(cap, cap_init,
1737       [AC_DEFINE(HAVE_LCAPS,1,Capabilities)
1738        LIBCAP="-lcap"
1739        frr_ac_lcaps="yes"]
1740     )
1741   else
1742     AC_CHECK_HEADERS(priv.h,
1743      [AC_MSG_CHECKING(Solaris style privileges are available)
1744       AC_TRY_COMPILE([#include <priv.h>],[getpflags(PRIV_AWARE);],
1745           [AC_MSG_RESULT(yes)
1746            AC_DEFINE(HAVE_SOLARIS_CAPABILITIES,1,getpflags)
1747            frr_ac_scaps="yes"],
1748            AC_MSG_RESULT(no)
1749       )
1750      ]
1751    )
1752   fi
1753   if test x"${frr_ac_scaps}" = x"yes" \
1754        -o x"${frr_ac_lcaps}" = x"yes"; then
1755     AC_DEFINE(HAVE_CAPABILITIES,1,capabilities)
1756   fi
1757 fi
1758 AC_SUBST(LIBCAP)
1759
1760 dnl ---------------------------
1761 dnl check for glibc 'backtrace'
1762 dnl ---------------------------
1763 if test x"${enable_backtrace}" != x"no" ; then
1764   backtrace_ok=no
1765   AC_CHECK_HEADER([execinfo.h], [
1766     AC_SEARCH_LIBS([backtrace], [execinfo], [
1767       AC_DEFINE(HAVE_GLIBC_BACKTRACE,,[Glibc backtrace])
1768       AC_DEFINE(HAVE_STACK_TRACE,,[Stack symbol decoding])
1769       backtrace_ok=yes
1770     ],, [-lm])
1771   ])
1772
1773   if test x"${enable_backtrace}" = x"yes" -a x"${backtrace_ok}" = x"no"; then
1774     dnl user explicitly requested backtrace but we failed to find support
1775     AC_MSG_FAILURE([failed to find backtrace support])
1776   fi
1777 fi
1778
1779 dnl -----------------------------------------
1780 dnl check for malloc mallinfo struct and call
1781 dnl this must try and link using LIBS, in
1782 dnl order to check no alternative allocator
1783 dnl has been specified, which might not provide
1784 dnl mallinfo, e.g. such as Umem on Solaris.
1785 dnl -----------------------------------------
1786 AC_CHECK_HEADER([malloc.h],
1787  [AC_MSG_CHECKING(whether mallinfo is available)
1788   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <malloc.h>]],
1789                         [[struct mallinfo ac_x; ac_x = mallinfo ();]])],
1790       [AC_MSG_RESULT(yes)
1791        AC_DEFINE(HAVE_MALLINFO,,mallinfo)],
1792        AC_MSG_RESULT(no)
1793   )
1794  ], [], FRR_INCLUDES)
1795
1796 dnl ------
1797 dnl ZeroMQ
1798 dnl ------
1799 if test "x$enable_zeromq" != "xno"; then
1800   PKG_CHECK_MODULES(ZEROMQ, [libzmq >= 4.0.0], [
1801     AC_DEFINE(HAVE_ZEROMQ, 1, [Enable ZeroMQ support])
1802     ZEROMQ=true
1803   ], [
1804     if test "x$enable_zeromq" = "xyes"; then
1805       AC_MSG_ERROR([configuration specifies --enable-zeromq but libzmq was not found])
1806     fi
1807   ])
1808 fi
1809 AM_CONDITIONAL([ZEROMQ], test "x$ZEROMQ" = "xtrue")
1810
1811 dnl ----------
1812 dnl configure date
1813 dnl ----------
1814 CONFDATE=`date '+%Y%m%d'`
1815 AC_SUBST(CONFDATE)
1816
1817 dnl ------------------------------
1818 dnl set paths for state directory
1819 dnl ------------------------------
1820 AC_MSG_CHECKING(directory to use for state file)
1821 if test "${prefix}" = "NONE"; then
1822   frr_statedir_prefix="";
1823 else
1824   frr_statedir_prefix=${prefix}
1825 fi
1826 if test "${localstatedir}" = '${prefix}/var'; then
1827   for FRR_STATE_DIR in ${frr_statedir_prefix}/var/run dnl
1828                         ${frr_statedir_prefix}/var/adm dnl
1829                         ${frr_statedir_prefix}/etc dnl
1830                         /var/run        dnl
1831                         /var/adm        dnl
1832                         /etc            dnl
1833                         /dev/null;
1834   do
1835     test -d $FRR_STATE_DIR && break
1836   done
1837   frr_statedir=$FRR_STATE_DIR
1838 else
1839   frr_statedir=${localstatedir}
1840 fi
1841 if test $frr_statedir = "/dev/null"; then
1842     AC_MSG_ERROR('STATE DIRECTORY NOT FOUND! FIX OR SPECIFY --localstatedir!')
1843 fi
1844 AC_MSG_RESULT(${frr_statedir})
1845 AC_SUBST(frr_statedir)
1846
1847 AC_DEFINE_UNQUOTED(LDPD_SOCKET, "$frr_statedir/ldpd.sock",ldpd control socket)
1848 AC_DEFINE_UNQUOTED(ZEBRA_SERV_PATH, "$frr_statedir/zserv.api",zebra api socket)
1849 AC_DEFINE_UNQUOTED(DAEMON_VTY_DIR, "$frr_statedir",daemon vty directory)
1850
1851 dnl autoconf does this, but it does it too late...
1852 test "x$prefix" = xNONE && prefix=$ac_default_prefix
1853 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
1854
1855 dnl get the full path, recursing through variables...
1856 vtysh_bin="$bindir/vtysh"
1857 for I in 1 2 3 4 5 6 7 8 9 10; do
1858         eval vtysh_bin="\"$vtysh_bin\""
1859 done
1860 AC_DEFINE_UNQUOTED(VTYSH_BIN_PATH, "$vtysh_bin",path to vtysh binary)
1861
1862 CFG_SYSCONF="$sysconfdir"
1863 CFG_SBIN="$sbindir"
1864 CFG_STATE="$frr_statedir"
1865 CFG_MODULE="$moduledir"
1866 for I in 1 2 3 4 5 6 7 8 9 10; do
1867         eval CFG_SYSCONF="\"$CFG_SYSCONF\""
1868         eval CFG_SBIN="\"$CFG_SBIN\""
1869         eval CFG_STATE="\"$CFG_STATE\""
1870         eval CFG_MODULE="\"$CFG_MODULE\""
1871 done
1872 AC_SUBST(CFG_SYSCONF)
1873 AC_SUBST(CFG_SBIN)
1874 AC_SUBST(CFG_STATE)
1875 AC_SUBST(CFG_MODULE)
1876 AC_DEFINE_UNQUOTED(MODULE_PATH, "$CFG_MODULE", path to modules)
1877
1878 dnl ------------------------------------
1879 dnl Enable RPKI and add librtr to libs
1880 dnl ------------------------------------
1881 if test "${enable_rpki}" = "yes"; then
1882   PKG_CHECK_MODULES(RTRLIB,[rtrlib >= 0.5.0],
1883       [AC_DEFINE(HAVE_RPKI,1,Enable RPKI prefix validation for BGP)
1884       RPKI=true],
1885       [RPKI=false
1886       AC_MSG_ERROR([rtrlib was not found on your system or is too old.])]
1887   )
1888 fi
1889 AM_CONDITIONAL([RPKI], test "x$RPKI" = "xtrue")
1890
1891 dnl ------------------------------------------
1892 dnl Check whether rtrlib was build with ssh support
1893 dnl ------------------------------------------
1894 AC_MSG_CHECKING([whether the RTR Library is compiled with SSH])
1895 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "rtrlib/rtrlib.h"]],
1896                         [[struct tr_ssh_config config;]])],
1897         [AC_MSG_RESULT(yes)
1898         AC_DEFINE(FOUND_SSH,,found_ssh)],
1899         AC_MSG_RESULT(no)
1900 )
1901
1902 dnl ---------------------------
1903 dnl Check htonl works correctly
1904 dnl ---------------------------
1905 AC_MSG_CHECKING(for working htonl)
1906 AC_CACHE_VAL(ac_cv_htonl_works,
1907  [AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES],[htonl (0);])],
1908                 [ac_cv_htonl_works=yes], [ac_cv_htonl_works=no])
1909  ]
1910 )
1911 AC_MSG_RESULT($ac_cv_htonl_works)
1912
1913 AC_CONFIG_FILES([Makefile
1914           bgpd/Makefile
1915           vtysh/Makefile
1916           doc/Makefile
1917           doc/user/Makefile
1918           doc/manpages/Makefile
1919           doc/developer/Makefile
1920           tests/Makefile
1921           bgpd/rfp-example/rfptest/Makefile
1922           bgpd/rfp-example/librfp/Makefile
1923           redhat/frr.spec
1924           debianpkg/Makefile
1925           debianpkg/changelog
1926           alpine/APKBUILD
1927           snapcraft/snapcraft.yaml
1928           lib/version.h
1929           tests/lib/cli/test_cli.refout
1930           pkgsrc/bgpd.sh pkgsrc/ospf6d.sh pkgsrc/ospfd.sh
1931           pkgsrc/ripd.sh pkgsrc/ripngd.sh pkgsrc/zebra.sh
1932           pkgsrc/eigrpd.sh])
1933
1934 if test "${enable_bgp_vnc}" != "no"; then
1935    if test "${with_rfp_path}" != "bgpd/rfp-example" ; then
1936       AC_CONFIG_FILES([${with_rfp_path}/rfptest/Makefile ${with_rfp_path}/librfp/Makefile])
1937    fi
1938 fi
1939
1940 AC_CONFIG_FILES([solaris/Makefile])
1941
1942 AC_CONFIG_FILES([vtysh/extract.pl],[chmod +x vtysh/extract.pl])
1943
1944 AC_CONFIG_COMMANDS([lib/route_types.h], [
1945         dst="${ac_abs_top_builddir}/lib/route_types.h"
1946         ${PERL} "${ac_abs_top_srcdir}/lib/route_types.pl" \
1947                 < "${ac_abs_top_srcdir}/lib/route_types.txt" \
1948                 > "${dst}.tmp"
1949         test -f "${dst}" \
1950                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
1951                 && rm "${dst}.tmp" \
1952                 || mv "${dst}.tmp" "${dst}"
1953 ], [
1954         PERL="$PERL"
1955 ])
1956
1957 AS_IF([test "x$with_pkg_git_version" = "xyes"], [
1958     AC_CONFIG_COMMANDS([lib/gitversion.h], [
1959         dst="${ac_abs_top_builddir}/lib/gitversion.h"
1960         ${PERL} "${ac_abs_top_srcdir}/lib/gitversion.pl" \
1961                 "${ac_abs_top_srcdir}" \
1962                 > "${dst}.tmp"
1963         test -f "${dst}" \
1964                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
1965                 && rm "${dst}.tmp" \
1966                 || mv "${dst}.tmp" "${dst}"
1967     ], [
1968         PERL="$PERL"
1969     ])
1970 ])
1971
1972 ## Hack, but working solution to avoid rebuilding of frr.info.
1973 ## It's already in CVS until texinfo 4.7 is more common.
1974 AC_OUTPUT
1975
1976 echo "
1977 FRRouting configuration
1978 ------------------------------
1979 FRR version             : ${PACKAGE_VERSION}
1980 host operating system   : ${host_os}
1981 source code location    : ${srcdir}
1982 compiler                : ${CC}
1983 compiler flags          : ${CFLAGS}
1984 make                    : ${MAKE-make}
1985 linker flags            : ${LDFLAGS} ${LIBS} ${LIBCAP} ${LIBREADLINE} ${LIBM}
1986 state file directory    : ${frr_statedir}
1987 config file directory   : `eval echo \`echo ${sysconfdir}\``
1988 example directory       : `eval echo \`echo ${exampledir}\``
1989 module directory        : ${CFG_MODULE}
1990 user to run as          : ${enable_user}
1991 group to run as         : ${enable_group}
1992 group for vty sockets   : ${enable_vty_group}
1993 config file mask        : ${enable_configfile_mask}
1994 log file mask           : ${enable_logfile_mask}
1995 zebra protobuf enabled  : ${have_protobuf:-no}
1996
1997 The above user and group must have read/write access to the state file
1998 directory and to the config files in the config file directory."