configure.ac

   1 ##
   2 ## Configure template file for FRRouting.
   3 ## autoconf will generate configure script.
   4 ##
   5 ##  Copyright (c) 1996, 97, 98, 99, 2000 Kunihiro Ishiguro <kunihiro@zebra.org>
   6 ##  Portions Copyright (c) 2003 Paul Jakma <paul@dishone.st>
   7 ##
   8 AC_PREREQ(2.60)
   9
  10 AC_INIT(frr, 5.1-dev, [https://github.com/frrouting/frr/issues])
  11 PACKAGE_URL="https://frrouting.org/"
  12 AC_SUBST(PACKAGE_URL)
  13 PACKAGE_FULLNAME="FRRouting"
  14 AC_SUBST(PACKAGE_FULLNAME)
  15
  16 CONFIG_ARGS="$ac_configure_args"
  17 AC_SUBST(CONFIG_ARGS)
  18
  19 AC_CONFIG_SRCDIR(lib/zebra.h)
  20 AC_CONFIG_MACRO_DIR([m4])
  21
  22 dnl -----------------------------------
  23 dnl Get hostname and other information.
  24 dnl -----------------------------------
  25 AC_CANONICAL_BUILD()
  26 AC_CANONICAL_HOST()
  27
  28 AS_IF([test "$host" != "$build"], [
  29   if test "$srcdir" = "."; then
  30     AC_MSG_ERROR([cross-compilation is only possible with builddir separate from srcdir.  create a separate directory and run as .../path-to-frr/configure.])
  31   fi
  32   test -d hosttools || mkdir hosttools
  33   abssrc="`cd \"${srcdir}\"; pwd`"
  34
  35   AC_MSG_NOTICE([...])
  36   AC_MSG_NOTICE([... cross-compilation: creating hosttools directory and self-configuring for build platform tools])
  37   AC_MSG_NOTICE([... use HOST_CPPFLAGS / HOST_CFLAGS / HOST_LDFLAGS if neccessary])
  38   AC_MSG_NOTICE([...])
  39
  40   ( CPPFLAGS="$HOST_CPPFLAGS"; \
  41     CFLAGS="$HOST_CFLAGS"; \
  42     LDFLAGS="$HOST_LDFLAGS"; \
  43     cd hosttools; "${abssrc}/configure" "--host=$build" "--build=$build" "--enable-clippy-only" "--disable-nhrpd" "--disable-vtysh"; )
  44
  45   AC_MSG_NOTICE([...])
  46   AC_MSG_NOTICE([... cross-compilation: finished self-configuring for build platform tools])
  47   AC_MSG_NOTICE([...])
  48
  49   build_clippy="false"
  50   HOSTTOOLS="hosttools/"
  51 ], [
  52   build_clippy="true"
  53   HOSTTOOLS=""
  54 ])
  55 AC_SUBST(HOSTTOOLS)
  56 AM_CONDITIONAL([BUILD_CLIPPY], [$build_clippy])
  57
  58 # Disable portability warnings -- our automake code (in particular
  59 # common.am) uses some constructs specific to gmake.
  60 AM_INIT_AUTOMAKE([1.12 -Wno-portability])
  61 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
  62 AM_SILENT_RULES([yes])
  63 AC_CONFIG_HEADERS(config.h)
  64
  65 AC_PATH_PROG(PERL, perl)
  66 PKG_PROG_PKG_CONFIG
  67
  68 dnl default is to match previous behavior
  69 exampledir=${sysconfdir}
  70 AC_ARG_ENABLE([exampledir],
  71           AS_HELP_STRING([--enable-exampledir],
  72                          [specify alternate directory for examples]),
  73                          exampledir="$enableval",)
  74 dnl XXX add --exampledir to autoconf standard directory list somehow
  75 AC_SUBST(exampledir)
  76
  77 dnl default is to match previous behavior
  78 pkgsrcrcdir=""
  79 AC_ARG_ENABLE([pkgsrcrcdir],
  80           AS_HELP_STRING([--enable-pkgsrcrcdir],
  81                          [specify directory for rc.d scripts]),
  82                          pkgsrcrcdir="$enableval",)
  83 dnl XXX add --pkgsrcrcdir to autoconf standard directory list somehow
  84 AC_SUBST(pkgsrcrcdir)
  85 AM_CONDITIONAL([PKGSRC], [test "x$pkgsrcrcdir" != "x"])
  86
  87 AC_ARG_WITH([moduledir], [AS_HELP_STRING([--with-moduledir=DIR], [module directory (${libdir}/frr/modules)])], [
  88         moduledir="$withval"
  89 ], [
  90         moduledir="\${libdir}/frr/modules"
  91 ])
  92 AC_SUBST([moduledir], [$moduledir])
  93
  94 AC_ARG_ENABLE(tcmalloc,
  95         AS_HELP_STRING([--enable-tcmalloc], [Turn on tcmalloc]),
  96 [case "${enableval}" in
  97   yes) tcmalloc_enabled=true
  98 LIBS="$LIBS -ltcmalloc_minimal"
  99  ;;
 100   no)  tcmalloc_enabled=false ;;
 101   *) AC_MSG_ERROR(bad value ${enableval} for --enable-tcmalloc) ;;
 102 esac],[tcmalloc_enabled=false])
 103
 104
 105 dnl Thanks autoconf, but we don't want a default -g -O2.  We have our own
 106 dnl flag determination logic.
 107 CFLAGS="${CFLAGS:-}"
 108
 109 dnl --------------------
 110 dnl Check CC and friends
 111 dnl --------------------
 112 dnl note orig_cflags is also used further down
 113 orig_cflags="$CFLAGS"
 114 AC_LANG([C])
 115 AC_PROG_CC
 116 AC_PROG_CPP
 117 AM_PROG_CC_C_O
 118 dnl remove autoconf default "-g -O2"
 119 CFLAGS="$orig_cflags"
 120 AC_PROG_CC_C99
 121 dnl NB: see C11 below
 122
 123 AC_PROG_EGREP
 124 PKG_PROG_PKG_CONFIG
 125
 126 dnl autoconf 2.59 appears not to support AC_PROG_SED
 127 dnl AC_PROG_SED
 128 AC_CHECK_PROG([SED],[sed],[sed],[/bin/false])
 129
 130 dnl try and enable CFLAGS that are useful for FRR
 131 dnl - specifically, options to control warnings
 132
 133 AC_USE_SYSTEM_EXTENSIONS
 134 AC_DEFUN([AC_C_FLAG], [{
 135         AC_LANG_PUSH(C)
 136         ac_c_flag_save="$CFLAGS"
 137         CFLAGS="$CFLAGS $1"
 138         AC_MSG_CHECKING([[whether $CC supports $1]])
 139         AC_COMPILE_IFELSE(
 140                 [AC_LANG_PROGRAM([[]])],
 141                 [
 142                         AC_MSG_RESULT([yes])
 143                         m4_if([$3], [], [], [
 144                                 CFLAGS="$ac_c_flag_save"
 145                                 $3
 146                         ])
 147                 ], [
 148                         CFLAGS="$ac_c_flag_save"
 149                         AC_MSG_RESULT([no])
 150                         $2
 151                 ])
 152         AC_LANG_POP(C)
 153         }])
 154
 155 AC_DEFUN([AC_LINK_IFELSE_FLAGS], [{
 156         AC_LANG_PUSH(C)
 157         ac_cflags_save="$CFLAGS"
 158         ac_libs_save="$LIBS"
 159         CFLAGS="$CFLAGS $1"
 160         LIBS="$LIBS $2"
 161         AC_LINK_IFELSE(
 162                 [$3],
 163                 [
 164                         AC_MSG_RESULT([yes])
 165                         CFLAGS="$ac_cflags_save"
 166                         LIBS="$ac_libs_save"
 167                         $5
 168                 ], [
 169                         AC_MSG_RESULT([no])
 170                         CFLAGS="$ac_cflags_save"
 171                         LIBS="$ac_libs_save"
 172                         $4
 173                 ])
 174         AC_LANG_POP(C)
 175         }])
 176
 177 dnl ICC won't bail on unknown options without -diag-error 10006
 178 dnl need to do this first so we get useful results for the other options
 179 AC_C_FLAG([-diag-error 10006])
 180
 181 dnl AC_PROG_CC_C99 may change CC to include -std=gnu99 or something
 182 ac_cc="$CC"
 183 CC="${CC% -std=gnu99}"
 184 CC="${CC% -std=c99}"
 185
 186 AC_C_FLAG([-std=gnu11], [CC="$ac_cc"], [CC="$CC -std=gnu11"])
 187
 188 dnl AddressSanitizer support
 189 AC_ARG_ENABLE([address-sanitizer], AS_HELP_STRING([--enable-address-sanitizer], \
 190               [enabled AddressSanitizer support for detecting a wide variety of \
 191                memory allocation and deallocation errors]), \
 192               [AC_DEFINE(HAVE_ADDRESS_SANITIZER, 1, [enable AddressSanitizer])
 193               ASAN_FLAGS="-fsanitize=address"
 194               SAN_CLIPPY_FLAGS="-fno-sanitize=all"
 195               AC_SUBST([ASAN_FLAGS])
 196               AC_SUBST([SAN_CLIPPY_FLAGS])
 197               LIBS="-ldl $LIBS"
 198               AC_TRY_COMPILE([],[const int i=0;],[AC_MSG_NOTICE([Address Sanitizer Enabled])],
 199                                                  [AC_MSG_ERROR([Address Sanitizer not available])])
 200               ])
 201
 202 dnl ThreadSanitizer support
 203 AC_ARG_ENABLE([thread-sanitizer], AS_HELP_STRING([--enable-thread-sanitizer], \
 204               [enabled ThreadSanitizer support for detecting data races]), \
 205               [AC_DEFINE(HAVE_THREAD_SANITIZER, 1, [enable ThreadSanitizer])
 206               TSAN_FLAGS="-fsanitize=thread"
 207               SAN_CLIPPY_FLAGS="-fno-sanitize=all"
 208               AC_SUBST([TSAN_FLAGS])
 209               AC_SUBST([SAN_CLIPPY_FLAGS])
 210               LIBS="-ldl $LIBS"
 211               AC_TRY_COMPILE([],[const int i=0;],[AC_MSG_NOTICE([Thread Sanitizer Enabled])],
 212                                                  [AC_MSG_ERROR([Thread Sanitizer not available])])
 213               ])
 214
 215 dnl MemorySanitizer support
 216 AC_ARG_ENABLE([memory-sanitizer], AS_HELP_STRING([--enable-memory-sanitizer], \
 217               [enabled MemorySanitizer support for detecting uninitialized memory reads]), \
 218               [AC_DEFINE(HAVE_THREAD_SANITIZER, 1, [enable MemorySanitizer])
 219               MSAN_FLAGS="-fsanitize=memory -fPIE -pie"
 220               SAN_CLIPPY_FLAGS="-fno-sanitize=all"
 221               AC_SUBST([MSAN_FLAGS])
 222               AC_SUBST([SAN_CLIPPY_FLAGS])
 223               LIBS="-ldl $LIBS"
 224               AC_TRY_COMPILE([],[const int i=0;],[AC_MSG_NOTICE([Memory Sanitizer Enabled])],
 225                                                  [AC_MSG_ERROR([Memory Sanitizer not available])])
 226               ])
 227
 228 dnl if the user has specified any CFLAGS, override our settings
 229 if test "x${enable_gcov}" = "xyes"; then
 230    if test "z$orig_cflags" = "z"; then
 231       AC_C_FLAG([-coverage])
 232       AC_C_FLAG([-O0])
 233    fi
 234
 235    LDFLAGS="${LDFLAGS} -lgcov"
 236 elif test "x${enable_dev_build}" = "xyes"; then
 237    AC_DEFINE(DEV_BUILD,,Build for development)
 238    if test "z$orig_cflags" = "z"; then
 239       AC_C_FLAG([-g3])
 240       AC_C_FLAG([-O0])
 241    fi
 242 else
 243    if test "z$orig_cflags" = "z"; then
 244       AC_C_FLAG([-g])
 245       AC_C_FLAG([-Os], [
 246         AC_C_FLAG([-O2])
 247       ])
 248    fi
 249 fi
 250 AM_CONDITIONAL([DEV_BUILD], [test "x$enable_dev_build" = "xyes"])
 251
 252 dnl always want these CFLAGS
 253 AC_C_FLAG([-fno-omit-frame-pointer])
 254 AC_C_FLAG([-funwind-tables])
 255 AC_C_FLAG([-Wall])
 256 AC_C_FLAG([-Wextra])
 257 AC_C_FLAG([-Wmissing-prototypes])
 258 AC_C_FLAG([-Wmissing-declarations])
 259 AC_C_FLAG([-Wpointer-arith])
 260 AC_C_FLAG([-Wbad-function-cast])
 261 AC_C_FLAG([-Wwrite-strings])
 262 if test x"${enable_gcc_ultra_verbose}" = x"yes" ; then
 263   AC_C_FLAG([-Wcast-qual])
 264   AC_C_FLAG([-Wstrict-prototypes])
 265   AC_C_FLAG([-Wmissing-noreturn])
 266   AC_C_FLAG([-Wmissing-format-attribute])
 267   AC_C_FLAG([-Wunreachable-code])
 268   AC_C_FLAG([-Wpacked])
 269   AC_C_FLAG([-Wpadded])
 270 else
 271   AC_C_FLAG([-Wno-unused-result])
 272 fi
 273 AC_C_FLAG([-Wno-unused-parameter])
 274 AC_C_FLAG([-Wno-missing-field-initializers])
 275
 276 dnl ICC emits a broken warning for const char *x = a ? "b" : "c";
 277 dnl for some reason the string consts get 'promoted' to char *,
 278 dnl triggering a const to non-const conversion warning.
 279 AC_C_FLAG([-diag-disable 3179])
 280
 281 if test x"${enable_werror}" = x"yes" ; then
 282   WERROR="-Werror"
 283 fi
 284 AC_SUBST(WERROR)
 285
 286 dnl need link on this one, not compile
 287 AC_LANG_PUSH(C)
 288 ac_ld_flag_save="$LDFLAGS"
 289 LDFLAGS="$LDFLAGS -rdynamic"
 290 AC_MSG_CHECKING([[whether linker supports -rdynamic]])
 291 AC_LINK_IFELSE(
 292         [AC_LANG_PROGRAM([[]])],
 293         [AC_MSG_RESULT([yes])],
 294         [
 295                 LDFLAGS="$ac_ld_flag_save"
 296                 AC_MSG_RESULT([no])
 297         ])
 298 AC_LANG_POP(C)
 299
 300 dnl ----------
 301 dnl Essentials
 302 dnl ----------
 303
 304 AX_PTHREAD([
 305   CC="$PTHREAD_CC"
 306   CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 307   LIBS="$PTHREAD_LIBS $LIBS"
 308 ], [
 309   AC_MSG_FAILURE([This FRR version needs pthreads])
 310 ])
 311
 312 dnl --------------
 313 dnl Check programs
 314 dnl --------------
 315 AC_PROG_INSTALL
 316 AC_PROG_LN_S
 317 AC_PROG_MAKE_SET
 318 AC_CHECK_TOOL(AR, ar)
 319
 320 dnl -----------------
 321 dnl System extensions
 322 dnl -----------------
 323 AC_GNU_SOURCE
 324
 325 dnl -------
 326 dnl libtool
 327 dnl -------
 328 LT_INIT
 329
 330 dnl ----------------------
 331 dnl Packages configuration
 332 dnl ----------------------
 333 AC_ARG_WITH(pkg-extra-version,
 334         AS_HELP_STRING([--with-pkg-extra-version=VER], [add extra version field, for packagers/distributions]),
 335         [EXTRAVERSION=$withval],)
 336 AC_ARG_WITH(pkg-git-version,
 337         AS_HELP_STRING([--with-pkg-git-version], [add git information to MOTD and build version string]),
 338         [ test "x$withval" != "xno" && with_pkg_git_version="yes" ])
 339 AC_ARG_WITH(vtysh_pager,
 340         AS_HELP_STRING([--with-vtysh-pager=PAGER], [control what pager is compiled in as default]),
 341         VTYSH_PAGER=$withval, VTYSH_PAGER="more")
 342 AC_ARG_ENABLE(vtysh,
 343   AS_HELP_STRING([--disable-vtysh], [do not build integrated vty shell for FRR]))
 344 AC_ARG_ENABLE(doc,
 345   AS_HELP_STRING([--disable-doc], [do not build docs]))
 346 AC_ARG_ENABLE(zebra,
 347   AS_HELP_STRING([--disable-zebra], [do not build zebra daemon]))
 348 AC_ARG_ENABLE(bgpd,
 349   AS_HELP_STRING([--disable-bgpd], [do not build bgpd]))
 350 AC_ARG_ENABLE(ripd,
 351   AS_HELP_STRING([--disable-ripd], [do not build ripd]))
 352 AC_ARG_ENABLE(ripngd,
 353   AS_HELP_STRING([--disable-ripngd], [do not build ripngd]))
 354 AC_ARG_ENABLE(ospfd,
 355   AS_HELP_STRING([--disable-ospfd], [do not build ospfd]))
 356 AC_ARG_ENABLE(ospf6d,
 357   AS_HELP_STRING([--disable-ospf6d], [do not build ospf6d]))
 358 AC_ARG_ENABLE(ldpd,
 359   AS_HELP_STRING([--enable-ldpd], [build ldpd]))
 360 AC_ARG_ENABLE(nhrpd,
 361   AS_HELP_STRING([--disable-nhrpd], [do not build nhrpd]))
 362 AC_ARG_ENABLE(eigrpd,
 363   AS_HELP_STRING([--disable-eigrpd], [do not build eigrpd]))
 364 AC_ARG_ENABLE(babeld,
 365   AS_HELP_STRING([--disable-babeld], [do not build babeld]))
 366 AC_ARG_ENABLE(watchfrr,
 367   AS_HELP_STRING([--disable-watchfrr], [do not build watchfrr]))
 368 AC_ARG_ENABLE(isisd,
 369   AS_HELP_STRING([--disable-isisd], [do not build isisd]))
 370 AC_ARG_ENABLE(pimd,
 371   AS_HELP_STRING([--disable-pimd], [do not build pimd]))
 372 AC_ARG_ENABLE(pbrd,
 373   AS_HELP_STRING([--disable-pbrd], [do not build pbrd]))
 374 AC_ARG_ENABLE(sharpd,
 375   AS_HELP_STRING([--enable-sharpd], [do not build sharpd]))
 376 AC_ARG_ENABLE(bgp-announce,
 377   AS_HELP_STRING([--disable-bgp-announce,], [turn off BGP route announcement]))
 378 AC_ARG_ENABLE(bgp-vnc,
 379   AS_HELP_STRING([--disable-bgp-vnc],[turn off BGP VNC support]))
 380 AC_ARG_WITH(rfp-path,
 381   AS_HELP_STRING([--with-rfp-path[=DIR]],[path to replaced stub RFP used with BGP VNC]))
 382 AC_ARG_ENABLE(snmp,
 383   AS_HELP_STRING([--enable-snmp=ARG], [enable SNMP support (smux or agentx)]))
 384 AC_ARG_ENABLE(zeromq,
 385   AS_HELP_STRING([--enable-zeromq], [enable ZeroMQ handler (libfrrzmq)]))
 386 AC_ARG_WITH(libpam,
 387   AS_HELP_STRING([--with-libpam], [use libpam for PAM support in vtysh]))
 388 AC_ARG_ENABLE(ospfapi,
 389   AS_HELP_STRING([--disable-ospfapi], [do not build OSPFAPI to access the OSPF LSA Database]))
 390 AC_ARG_ENABLE(ospfclient,
 391   AS_HELP_STRING([--disable-ospfclient], [do not build OSPFAPI client for OSPFAPI,
 392                           (this is the default if --disable-ospfapi is set)]))
 393 AC_ARG_ENABLE(multipath,
 394   AS_HELP_STRING([--enable-multipath=ARG], [enable multipath function, ARG must be digit]))
 395 AC_ARG_ENABLE(user,
 396   AS_HELP_STRING([--enable-user=USER], [user to run FRR suite as (default frr)]))
 397 AC_ARG_ENABLE(group,
 398   AS_HELP_STRING([--enable-group=GROUP], [group to run FRR suite as (default frr)]))
 399 AC_ARG_ENABLE(vty_group,
 400   AS_HELP_STRING([--enable-vty-group=ARG], [set vty sockets to have specified group as owner]))
 401 AC_ARG_ENABLE(configfile_mask,
 402   AS_HELP_STRING([--enable-configfile-mask=ARG], [set mask for config files]))
 403 AC_ARG_ENABLE(logfile_mask,
 404   AS_HELP_STRING([--enable-logfile-mask=ARG], [set mask for log files]))
 405 AC_ARG_ENABLE(shell_access,
 406   AS_HELP_STRING([--enable-shell-access], [Allow users to access shell/telnet/ssh]))
 407 AC_ARG_ENABLE(realms,
 408   AS_HELP_STRING([--enable-realms], [enable REALMS support under Linux]))
 409 AC_ARG_ENABLE(rtadv,
 410   AS_HELP_STRING([--disable-rtadv], [disable IPV6 router advertisement feature]))
 411 AC_ARG_ENABLE(irdp,
 412   AS_HELP_STRING([--disable-irdp], [enable IRDP server support in zebra (default if supported)]))
 413 AC_ARG_ENABLE(capabilities,
 414   AS_HELP_STRING([--disable-capabilities], [disable using POSIX capabilities]))
 415 AC_ARG_ENABLE(rusage,
 416   AS_HELP_STRING([--disable-rusage], [disable using getrusage]))
 417 AC_ARG_ENABLE(gcc_ultra_verbose,
 418   AS_HELP_STRING([--enable-gcc-ultra-verbose], [enable ultra verbose GCC warnings]))
 419 AC_ARG_ENABLE(linux24_tcp_md5,
 420   AS_HELP_STRING([--enable-linux24-tcp-md5], [enable support for old, Linux-2.4 RFC2385 patch]))
 421 AC_ARG_ENABLE(backtrace,
 422   AS_HELP_STRING([--disable-backtrace,], [disable crash backtraces (default autodetect)]))
 423 AC_ARG_ENABLE(time-check,
 424   AS_HELP_STRING([--disable-time-check], [disable slow thread warning messages]))
 425 AC_ARG_ENABLE(pcreposix,
 426   AS_HELP_STRING([--enable-pcreposix], [enable using PCRE Posix libs for regex functions]))
 427 AC_ARG_ENABLE(fpm,
 428   AS_HELP_STRING([--enable-fpm], [enable Forwarding Plane Manager support]))
 429 AC_ARG_ENABLE(systemd,
 430   AS_HELP_STRING([--enable-systemd], [enable Systemd support]))
 431 AC_ARG_ENABLE(werror,
 432   AS_HELP_STRING([--enable-werror], [enable -Werror (recommended for developers only)]))
 433 AC_ARG_ENABLE(cumulus,
 434   AS_HELP_STRING([--enable-cumulus], [enable Cumulus Switch Special Extensions]))
 435 AC_ARG_ENABLE(datacenter,
 436   AS_HELP_STRING([--enable-datacenter], [enable Compilation for Data Center Extensions]))
 437 AC_ARG_ENABLE(fuzzing,
 438   AS_HELP_STRING([--enable-fuzzing], [enable ability to fuzz various parts of FRR]))
 439 AC_ARG_ENABLE(netlink_fuzzing,
 440   AS_HELP_STRING([--enable-netlink-fuzzing], [enable ability to fuzz netlink listening socket in zebra]))
 441 AC_ARG_ENABLE(rr-semantics,
 442   AS_HELP_STRING([--disable-rr-semantics], [disable the v6 Route Replace semantics]))
 443 AC_ARG_ENABLE([protobuf],
 444   AS_HELP_STRING([--enable-protobuf], [Enable experimental protobuf support]))
 445 AC_ARG_ENABLE([oldvpn_commands],
 446   AS_HELP_STRING([--enable-oldvpn-commands], [Keep old vpn commands]))
 447 AC_ARG_ENABLE(rpki,
 448   AS_HELP_STRING([--enable-rpki], [enable RPKI prefix validation support]))
 449 AC_ARG_ENABLE([clippy-only],
 450   AS_HELP_STRING([--enable-clippy-only], [Only build clippy]))
 451 AC_ARG_ENABLE([numeric_version],
 452   AS_HELP_STRING([--enable-numeric-version], [Only numeric digits allowed in version (for Alpine)]))
 453 AC_ARG_ENABLE([gcov],
 454   AS_HELP_STRING([--enable-gcov], [Add code coverage information]))
 455
 456 AS_IF([test "${enable_clippy_only}" != "yes"], [
 457 AC_CHECK_HEADERS(json-c/json.h)
 458 AC_CHECK_LIB(json-c, json_object_get, LIBS="$LIBS -ljson-c", [], [-lm])
 459 if test $ac_cv_lib_json_c_json_object_get = no; then
 460   AC_CHECK_LIB(json, json_object_get, LIBS="$LIBS -ljson")
 461   if test $ac_cv_lib_json_json_object_get = no; then
 462       AC_MSG_ERROR([lib json is needed to compile])
 463   fi
 464 fi
 465 ])
 466
 467 AC_ARG_ENABLE([dev_build],
 468     AS_HELP_STRING([--enable-dev-build], [build for development]))
 469
 470 if test x"${enable_time_check}" != x"no" ; then
 471   if test x"${enable_time_check}" = x"yes" -o x"${enable_time_check}" = x ; then
 472     AC_DEFINE(CONSUMED_TIME_CHECK,5000000,Consumed Time Check)
 473   else
 474     AC_DEFINE_UNQUOTED(CONSUMED_TIME_CHECK,$enable_time_check,Consumed Time Check)
 475   fi
 476 fi
 477
 478 case "${enable_systemd}" in
 479   "no") ;;
 480   "yes")
 481   AC_CHECK_LIB(systemd, sd_notify, LIBS="$LIBS -lsystemd")
 482   if test $ac_cv_lib_systemd_sd_notify = no; then
 483     AC_MSG_ERROR([enable systemd has been specified but systemd development env not found on your system])
 484   else
 485     AC_DEFINE(HAVE_SYSTEMD,,Compile systemd support in)
 486   fi
 487   ;;
 488   "*") ;;
 489 esac
 490
 491 if test "${enable_rr_semantics}" != "no" ; then
 492   AC_DEFINE(HAVE_V6_RR_SEMANTICS,, Compile in v6 Route Replacement Semantics)
 493 fi
 494
 495 if test "${enable_datacenter}" = "yes" ; then
 496   AC_DEFINE(HAVE_DATACENTER,,Compile extensions for a DataCenter)
 497   DFLT_NAME="datacenter"
 498 else
 499   DFLT_NAME="traditional"
 500 fi
 501
 502 if test "${enable_fuzzing}" = "yes" ; then
 503   AC_DEFINE(HANDLE_ZAPI_FUZZING,,Compile extensions to use with a fuzzer)
 504 fi
 505
 506 if test "${enable_netlink_fuzzing}" = "yes" ; then
 507   AC_DEFINE(HANDLE_NETLINK_FUZZING,,Compile extensions to use with a fuzzer for netlink)
 508 fi
 509
 510 if test "${enable_cumulus}" = "yes" ; then
 511   AC_DEFINE(HAVE_CUMULUS,,Compile Special Cumulus Code in)
 512 fi
 513
 514 AC_SUBST(DFLT_NAME)
 515 AC_DEFINE_UNQUOTED(DFLT_NAME,["$DFLT_NAME"], Name of the configuration default set)
 516
 517 if test "${enable_shell_access}" = "yes"; then
 518    AC_DEFINE(HAVE_SHELL_ACCESS,,Allow user to use ssh/telnet/bash)
 519 fi
 520
 521 AM_CONDITIONAL([FPM], [test "x$enable_fpm" = "xyes"])
 522
 523 #
 524 # Python for clippy
 525 #
 526 AS_IF([test "$host" = "$build"], [
 527   PYTHONCONFIG=""
 528
 529   # ordering:
 530   # 1.  try python3, but respect the user's preference on which minor ver
 531   # 2.  try python, which might be py3 or py2 again on the user's preference
 532   # 3.  try python2 (can really only be 2.7 but eh)
 533   # 4.  try 3.5 > 3.4 > 3.3 > 3.2 > 2.7 through pkg-config (no user pref)
 534   #
 535   # (AX_PYTHON_DEVEL has no clue about py3 vs py2)
 536   # (AX_PYTHON does not do what we need)
 537
 538   AC_CHECK_TOOLS([PYTHONCONFIG], [python3-config python-config python2-config])
 539   if test -n "$PYTHONCONFIG"; then
 540     PYTHON_CFLAGS="`\"${PYTHONCONFIG}\" --includes`"
 541     PYTHON_LIBS="`\"${PYTHONCONFIG}\" --libs`"
 542
 543     AC_MSG_CHECKING([whether we found a working Python version])
 544     AC_LINK_IFELSE_FLAGS([$PYTHON_CFLAGS], [$PYTHON_LIBS], [AC_LANG_PROGRAM([
 545 #include <Python.h>
 546 #if PY_VERSION_HEX < 0x02070000
 547 #error python too old
 548 #endif
 549 int main(void);
 550 ],
 551 [
 552 {
 553   Py_Initialize();
 554   return 0;
 555 }
 556 ])], [
 557       PYTHONCONFIG=""
 558       unset PYTHON_LIBS
 559       unset PYTHON_CFLAGS
 560     ])
 561   fi
 562
 563   if test -z "$PYTHONCONFIG"; then
 564     PKG_CHECK_MODULES([PYTHON], python-3.5, [], [
 565       PKG_CHECK_MODULES([PYTHON], python-3.4, [], [
 566         PKG_CHECK_MODULES([PYTHON], python-3.3, [], [
 567           PKG_CHECK_MODULES([PYTHON], python-3.2, [], [
 568             PKG_CHECK_MODULES([PYTHON], python-2.7, [], [
 569               AC_MSG_FAILURE([could not find python-config or pkg-config python, please install Python development files from libpython-dev or similar])
 570               ])])])])])
 571
 572
 573     AC_MSG_CHECKING([whether we found a working Python version])
 574     AC_LINK_IFELSE_FLAGS([$PYTHON_CFLAGS], [$PYTHON_LIBS], [AC_LANG_PROGRAM([
 575 #include <Python.h>
 576 #if PY_VERSION_HEX < 0x02070000
 577 #error python too old
 578 #endif
 579 int main(void);
 580 ],
 581 [
 582 {
 583   Py_Initialize();
 584   return 0;
 585 }
 586 ])], [
 587       AC_MSG_FAILURE([could not find python-config or pkg-config python, please install Python development files from libpython-dev or similar])
 588     ])
 589   fi
 590 ])
 591 AC_SUBST(PYTHON_CFLAGS)
 592 AC_SUBST(PYTHON_LIBS)
 593
 594 #
 595 # Logic for protobuf support.
 596 #
 597 if test "$enable_protobuf" = "yes"; then
 598    have_protobuf=yes
 599
 600    # Check for protoc-c
 601    AC_CHECK_PROG([PROTOC_C], [protoc-c], [protoc-c], [/bin/false])
 602    if test "x$PROTOC_C" = "x/bin/false"; then
 603       have_protobuf=no
 604    else
 605       found_protobuf_c=no
 606       PKG_CHECK_MODULES([PROTOBUF_C], libprotobuf-c >= 0.14,
 607                      [found_protobuf_c=yes],
 608                      [AC_MSG_RESULT([pkg-config did not find libprotobuf-c])])
 609
 610       if test "x$found_protobuf_c" = "xyes"; then
 611          LDFLAGS="$LDFLAGS $PROTOBUF_C_LIBS"
 612          CFLAGS="$CFLAGS $PROTOBUF_C_CFLAGS"
 613       else
 614         AC_CHECK_HEADER([google/protobuf-c/protobuf-c.h], [],
 615                         [have_protobuf=no; AC_MSG_RESULT([Couldn't find google/protobuf-c.h])])
 616       fi
 617    fi
 618 fi
 619
 620 #
 621 # Logic for old vpn commans support.
 622 #
 623 if test "$enable_oldvpn_commands" = "yes"; then
 624    AC_DEFINE(KEEP_OLD_VPN_COMMANDS,, [Define for compiling with old vpn commands])
 625 fi
 626
 627 # Fail if the user explicity enabled protobuf support and we couldn't
 628 # find the compiler or libraries.
 629 if test "x$have_protobuf" = "xno" && test "x$enable_protobuf" = "xyes"; then
 630    AC_MSG_ERROR([Protobuf enabled explicitly but can't find libraries/tools])
 631 fi
 632
 633 if test "x$have_protobuf" = "xyes"; then
 634    AC_DEFINE(HAVE_PROTOBUF,, protobuf)
 635 fi
 636
 637 AM_CONDITIONAL([HAVE_PROTOBUF], [test "x$have_protobuf" = "xyes"])
 638
 639 #
 640 # End of logic for protobuf support.
 641 #
 642
 643 if test "${enable_linux24_tcp_md5}" = "yes"; then
 644   AC_DEFINE(HAVE_TCP_MD5_LINUX24,,Old Linux 2.4 TCP MD5 Signature Patch)
 645 fi
 646
 647 AC_MSG_CHECKING(if zebra should be configurable to send Route Advertisements)
 648 if test "${enable_rtadv}" != "no"; then
 649   AC_MSG_RESULT(yes)
 650   AC_DEFINE(HAVE_RTADV,,Enable IPv6 Routing Advertisement support)
 651 else
 652   AC_MSG_RESULT(no)
 653 fi
 654
 655 if test x"${enable_user}" = x"no"; then
 656   enable_user=""
 657 else
 658   if test x"${enable_user}" = x"yes" || test x"${enable_user}" = x""; then
 659     enable_user="frr"
 660   fi
 661   AC_DEFINE_UNQUOTED(FRR_USER, "${enable_user}", frr User)
 662 fi
 663
 664 if test x"${enable_group}" = x"no"; then
 665   enable_group=""
 666 else
 667   if test x"${enable_group}" = x"yes" || test x"${enable_group}" = x""; then
 668     enable_group="frr"
 669   fi
 670   AC_DEFINE_UNQUOTED(FRR_GROUP, "${enable_group}", frr Group)
 671 fi
 672
 673 if test x"${enable_vty_group}" = x"yes" ; then
 674   AC_MSG_ERROR([--enable-vty-group requires a group as argument, not yes])
 675 elif test x"${enable_vty_group}" != x""; then
 676   if test x"${enable_vty_group}" != x"no"; then
 677     AC_DEFINE_UNQUOTED(VTY_GROUP, "${enable_vty_group}", VTY Sockets Group)
 678   fi
 679 fi
 680 AC_SUBST([enable_user])
 681 AC_SUBST([enable_group])
 682 AC_SUBST([enable_vty_group])
 683
 684 enable_configfile_mask=${enable_configfile_mask:-0600}
 685 AC_DEFINE_UNQUOTED(CONFIGFILE_MASK, ${enable_configfile_mask}, Mask for config files)
 686
 687 enable_logfile_mask=${enable_logfile_mask:-0600}
 688 AC_DEFINE_UNQUOTED(LOGFILE_MASK, ${enable_logfile_mask}, Mask for log files)
 689
 690 MPATH_NUM=1
 691
 692 case "${enable_multipath}" in
 693   0)
 694     MPATH_NUM=64
 695     ;;
 696   [[1-9]|[1-9][0-9]|[1-9][0-9][0-9]])
 697     MPATH_NUM="${enable_multipath}"
 698     ;;
 699   "")
 700     ;;
 701   *)
 702     AC_MSG_FAILURE([Please specify digit to enable multipath ARG])
 703     ;;
 704 esac
 705
 706 AC_DEFINE_UNQUOTED(MULTIPATH_NUM, $MPATH_NUM, Maximum number of paths for a route)
 707
 708 AC_DEFINE_UNQUOTED(VTYSH_PAGER, "$VTYSH_PAGER", [What pager to use])
 709
 710 dnl --------------------
 711 dnl Enable code coverage
 712 dnl --------------------
 713 AM_CONDITIONAL([HAVE_GCOV],[test '!' "$enable_gcov" = no])
 714
 715 dnl ------------------------------------
 716 dnl Alpine only accepts numeric versions
 717 dnl ------------------------------------
 718 if test "x${enable_numeric_version}" != "x" ; then
 719   VERSION="`echo ${VERSION} | tr -c -d '[[.0-9]]'`"
 720   PACKAGE_VERSION="`echo ${PACKAGE_VERSION} | tr -c -d '[[.0-9]]'`"
 721 fi
 722
 723 dnl -----------------------------------
 724 dnl Add extra version string to package
 725 dnl name, string and version fields.
 726 dnl -----------------------------------
 727 if test "x${EXTRAVERSION}" != "x" ; then
 728   VERSION="${VERSION}${EXTRAVERSION}"
 729   PACKAGE_VERSION="${PACKAGE_VERSION}${EXTRAVERSION}"
 730   AC_SUBST(PACKAGE_EXTRAVERSION, ["${EXTRAVERSION}"])
 731   PACKAGE_STRING="${PACKAGE_STRING}${EXTRAVERSION}"
 732 fi
 733
 734 if test "x$with_pkg_git_version" = "xyes"; then
 735         if test -d "${srcdir}/.git"; then
 736                 AC_DEFINE(GIT_VERSION, [1], [include git version info])
 737         else    with_pkg_git_version="no"
 738                 AC_MSG_WARN([--with-pkg-git-version given, but this is not a git checkout])
 739         fi
 740 fi
 741 AM_CONDITIONAL([GIT_VERSION], [test "x$with_pkg_git_version" = "xyes"])
 742
 743 dnl ------------------------------------
 744 dnl Check C keywords and standard  types
 745 dnl ------------------------------------
 746 AC_C_CONST
 747 AC_C_INLINE
 748 AC_C_VOLATILE
 749 AC_HEADER_STDC
 750 dnl AC_TYPE_PID_T
 751 AC_TYPE_UID_T
 752 AC_TYPE_MODE_T
 753 AC_TYPE_SIZE_T
 754 AC_STRUCT_TM
 755
 756 dnl -------------------------
 757 dnl Check other header files.
 758 dnl -------------------------
 759 AC_CHECK_HEADERS([stropts.h sys/ksym.h \
 760         linux/version.h asm/types.h \
 761         sys/cdefs.h])
 762
 763 ac_stdatomic_ok=false
 764 AC_DEFINE(FRR_AUTOCONF_ATOMIC, 1, [did autoconf checks for atomic funcs])
 765 AC_CHECK_HEADER([stdatomic.h],[
 766
 767   AC_MSG_CHECKING([whether _Atomic qualifier works])
 768   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 769 #include <stdatomic.h>
 770 int main(int argc, char **argv) {
 771   _Atomic int i = 0;
 772   return i;
 773 }
 774 ]])], [
 775     AC_DEFINE(HAVE_STDATOMIC_H, 1, [found stdatomic.h])
 776     AC_MSG_RESULT([yes])
 777     ac_stdatomic_ok=true
 778   ], [
 779     AC_MSG_RESULT([no])
 780   ])
 781 ])
 782
 783 AS_IF([$ac_stdatomic_ok], [true], [
 784   AC_MSG_CHECKING([for __atomic_* builtins])
 785   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 786 int main(int argc, char **argv) {
 787   volatile int i = 1;
 788   __atomic_store_n (&i, 0, __ATOMIC_RELEASE);
 789   return __atomic_load_n (&i, __ATOMIC_ACQUIRE);
 790 }
 791 ]])], [
 792     AC_DEFINE(HAVE___ATOMIC, 1, [found __atomic builtins])
 793     AC_MSG_RESULT([yes])
 794   ], [
 795     AC_MSG_RESULT([no])
 796
 797     dnl FreeBSD 9 has a broken stdatomic.h where _Atomic doesn't work
 798     AC_MSG_CHECKING([for __sync_* builtins])
 799     AC_LINK_IFELSE([AC_LANG_SOURCE([[
 800 int main(int argc, char **argv) {
 801   volatile int i = 1;
 802   __sync_fetch_and_sub (&i, 1);
 803   return __sync_val_compare_and_swap (&i, 0, 1);
 804 }
 805 ]])], [
 806       AC_DEFINE(HAVE___SYNC, 1, [found __sync builtins])
 807       AC_MSG_RESULT([yes])
 808
 809       AC_MSG_CHECKING([for __sync_swap builtin])
 810       AC_LINK_IFELSE([AC_LANG_SOURCE([[
 811 int main(int argc, char **argv) {
 812   volatile int i = 1;
 813   return __sync_swap (&i, 2);
 814 }
 815 ]])], [
 816         AC_DEFINE(HAVE___SYNC_SWAP, 1, [found __sync_swap builtin])
 817         AC_MSG_RESULT([yes])
 818       ], [
 819         AC_MSG_RESULT([no])
 820       ])
 821
 822     ], [
 823       AC_MSG_RESULT([no])
 824       AC_MSG_FAILURE([stdatomic.h unavailable and $CC has neither __atomic nor __sync builtins])
 825     ])
 826   ])
 827 ])
 828
 829 dnl Utility macro to avoid retyping includes all the time
 830 m4_define([FRR_INCLUDES],
 831 [#ifdef SUNOS_5
 832 #define _XPG4_2
 833 #define __EXTENSIONS__
 834 #endif
 835 #include <stdio.h>
 836 #include <stdlib.h>
 837 #include <stddef.h>
 838 #include <sys/types.h>
 839 /* sys/conf.h depends on param.h on FBSD at least */
 840 #include <sys/param.h>
 841 /* Required for MAXSIG */
 842 #include <signal.h>
 843 #include <sys/socket.h>
 844 #ifdef __APPLE__
 845 # define __APPLE_USE_RFC_3542
 846 #endif
 847 #include <netinet/in.h>
 848 #include <sys/time.h>
 849 #include <time.h>
 850 #include <net/if.h>
 851 ])dnl
 852
 853 dnl Same applies for HAVE_NET_IF_VAR_H, which HAVE_NETINET6_ND6_H and
 854 dnl HAVE_NETINET_IN_VAR_H depend upon. But if_var.h depends on if.h, hence
 855 dnl an additional round for it.
 856
 857 AC_CHECK_HEADERS([net/if_var.h], [], [], FRR_INCLUDES)
 858
 859 m4_define([FRR_INCLUDES],
 860 FRR_INCLUDES
 861 [#if HAVE_NET_IF_VAR_H
 862 # include <net/if_var.h>
 863 #endif
 864 ])dnl
 865
 866 AC_CHECK_HEADERS([netinet/in_var.h \
 867         net/if_dl.h net/netopt.h \
 868         inet/nd.h netinet/ip_icmp.h \
 869         sys/sysctl.h sys/sockio.h kvm.h sys/conf.h],
 870         [], [], FRR_INCLUDES)
 871
 872 AC_CHECK_HEADERS([ucontext.h], [], [],
 873 [#ifndef __USE_GNU
 874 #define __USE_GNU
 875 #endif /* __USE_GNU */
 876 FRR_INCLUDES
 877 ])
 878
 879 m4_define([UCONTEXT_INCLUDES],
 880 [#include <ucontext.h>])dnl
 881
 882 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.uc_regs],
 883   [], [], [UCONTEXT_INCLUDES])
 884 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs],
 885   [AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs.nip],
 886    [], [], [UCONTEXT_INCLUDES])],
 887   [], [UCONTEXT_INCLUDES])
 888 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.gregs],
 889   [], [], [UCONTEXT_INCLUDES])
 890
 891 m4_define([FRR_INCLUDES],
 892 FRR_INCLUDES
 893 [
 894 #include <sys/un.h>
 895 #include <netinet/in_systm.h>
 896 #if HAVE_NETINET_IN_VAR_H
 897 # include <netinet/in_var.h>
 898 #endif
 899 #if HAVE_NET_IF_DL_H
 900 # include <net/if_dl.h>
 901 #endif
 902 #if HAVE_NET_NETOPT_H
 903 # include <net/netopt.h>
 904 #endif
 905 #include <net/route.h>
 906 #if HAVE_INET_ND_H
 907 # include <inet/nd.h>
 908 #endif
 909 #include <arpa/inet.h>
 910 /* Required for IDRP */
 911 #if HAVE_NETINET_IP_ICMP_H
 912 # include <netinet/ip_icmp.h>
 913 #endif
 914 ])dnl
 915
 916 dnl V6 headers are checked below, after we check for v6
 917
 918 AC_MSG_CHECKING([which operating system interface to use])
 919 case "$host_os" in
 920   sunos* | solaris2*)
 921     AC_MSG_RESULT([Solaris])
 922
 923     AC_DEFINE(SUNOS_5, 1, [SunOS 5])
 924     AC_DEFINE(SOLARIS_IPV6, 1, Solaris IPv6)
 925
 926     AC_CHECK_LIB(socket, main)
 927     AC_CHECK_LIB(nsl, main)
 928     AC_CHECK_LIB(umem, main)
 929     AC_CHECK_FUNCS([printstack], [
 930       AC_DEFINE([HAVE_PRINTSTACK],1,[Solaris printstack])
 931       AC_DEFINE([HAVE_STACK_TRACE],1,[Stack symbols decode functionality])
 932     ])
 933     CURSES=-lcurses
 934     SOLARIS="solaris"
 935     ;;
 936   linux*)
 937     AC_MSG_RESULT([Linux])
 938
 939     AC_DEFINE(GNU_LINUX,,GNU Linux)
 940     AC_DEFINE(HAVE_NETLINK,,netlink)
 941     AC_DEFINE(LINUX_IPV6,1,Linux IPv6 stack)
 942
 943     dnl Linux has a compilation problem with mixing
 944     dnl netinet/in.h and linux/in6.h they are not
 945     dnl compatible.  There has been discussion on
 946     dnl how to fix it but no real progress on implementation
 947     dnl when they fix it, remove this
 948     AC_DEFINE(IPV6_MINHOPCOUNT, 73, Linux ipv6 Min Hop Count)
 949     ;;
 950   openbsd*)
 951     AC_MSG_RESULT([OpenBSD])
 952
 953     AC_DEFINE(OPEN_BSD,,OpenBSD)
 954     AC_DEFINE(KAME,1,KAME IPv6)
 955     AC_DEFINE(BSD_V6_SYSCTL,1,BSD v6 sysctl to turn on and off forwarding)
 956
 957     if test "x${enable_pimd}" != "xno"; then
 958       case "$host_os" in
 959       openbsd6.0)
 960         ;;
 961       openbsd[6-9]*)
 962         AC_MSG_FAILURE([pimd cannot be enabled as PIM support has been removed from OpenBSD 6.1])
 963         ;;
 964       esac
 965     fi
 966     ;;
 967   *)
 968     AC_MSG_RESULT([BSD])
 969
 970     AC_DEFINE(HAVE_NET_RT_IFLIST,,NET_RT_IFLIST)
 971     AC_DEFINE(KAME,1,KAME IPv6)
 972     AC_DEFINE(BSD_V6_SYSCTL,1,BSD v6 sysctl to turn on and off forwarding)
 973     ;;
 974 esac
 975 AM_CONDITIONAL(SOLARIS, test "${SOLARIS}" = "solaris")
 976
 977 AC_SYS_LARGEFILE
 978
 979 dnl ------------------------
 980 dnl Integrated REALMS option
 981 dnl ------------------------
 982 if test "${enable_realms}" = "yes"; then
 983     case "$host_os" in
 984       linux*)
 985        AC_DEFINE(SUPPORT_REALMS,, Realms support)
 986        ;;
 987       *)
 988        echo "Sorry, only Linux has REALMS support"
 989        exit 1
 990        ;;
 991     esac
 992 fi
 993 AM_CONDITIONAL([SUPPORT_REALMS], [test "${enable_realms}" = "yes"])
 994
 995 dnl ---------------------
 996 dnl Integrated VTY option
 997 dnl ---------------------
 998 case "${enable_vtysh}" in
 999   "no") VTYSH="";;
1000   *)    VTYSH="vtysh";
1001          AC_DEFINE(VTYSH,,VTY shell)
1002 dnl      Vtysh uses libreadline, which looks for termcap functions at
1003 dnl      configure time.  We follow readlines search order.
1004 dnl      The required procedures are in libtermcap on NetBSD, in
1005 dnl      [TODO] on Linux, and in [TODO] on Solaris.
1006          AC_CHECK_LIB(termcap, tputs, LIBREADLINE="$LIBREADLINE -ltermcap",
1007            [AC_CHECK_LIB(tinfo, tputs, LIBREADLINE="$LIBREADLINE -ltinfo",
1008              [AC_CHECK_LIB(curses, tputs, LIBREADLINE="$LIBREADLINE -lcurses",
1009                [AC_CHECK_LIB(ncurses, tputs,
1010                              LIBREADLINE="$LIBREADLINE -lncurses")]
1011               )]
1012             )]
1013           )
1014          AC_CHECK_LIB(readline, main, LIBREADLINE="-lreadline $LIBREADLINE",,
1015                       "$LIBREADLINE")
1016          if test $ac_cv_lib_readline_main = no; then
1017            AC_MSG_ERROR([vtysh needs libreadline but was not found and usable on your system.])
1018          fi
1019          AC_CHECK_HEADER(readline/history.h)
1020          if test $ac_cv_header_readline_history_h = no;then
1021            AC_MSG_ERROR([readline is too old to have readline/history.h, please update to the latest readline library.])
1022          fi
1023          AC_CHECK_LIB(readline, rl_completion_matches,
1024                       LIBREADLINE="$LIBREADLINE",, "$LIBREADLINE")
1025          if test $ac_cv_lib_readline_rl_completion_matches = no; then
1026            AC_DEFINE(rl_completion_matches,completion_matches,Old readline)
1027          fi
1028          ;;
1029 esac
1030 AC_SUBST(LIBREADLINE)
1031 AM_CONDITIONAL(VTYSH, test "x$VTYSH" = "xvtysh")
1032
1033 dnl ----------
1034 dnl PAM module
1035 dnl
1036 dnl FRR detects the PAM library it is built against by checking for a
1037 dnl functional pam_misc.h (Linux-PAM) or openpam.h (OpenPAM) header. pam_misc.h
1038 dnl is known to #include pam_appl.h, the standard header of a PAM library, and
1039 dnl openpam.h doesn't do that, although depends on the header too. Hence a
1040 dnl little assistance to AC_CHECK_HEADER is necessary for the proper detection
1041 dnl of OpenPAM.
1042 dnl ----------
1043 if test "$with_libpam" = "yes"; then
1044   AC_CHECK_HEADER([security/pam_misc.h],
1045     [AC_DEFINE(HAVE_PAM_MISC_H,,Have pam_misc.h)
1046      AC_DEFINE(PAM_CONV_FUNC,misc_conv,Have misc_conv)
1047      pam_conv_func="misc_conv"
1048     ],
1049     [], FRR_INCLUDES)
1050   AC_CHECK_HEADER([security/openpam.h],
1051     [AC_DEFINE(HAVE_OPENPAM_H,,Have openpam.h)
1052      AC_DEFINE(PAM_CONV_FUNC,openpam_ttyconv,Have openpam_ttyconv)
1053      pam_conv_func="openpam_ttyconv"
1054     ],
1055     [], FRR_INCLUDES[#include <security/pam_appl.h>])
1056   if test -z "$ac_cv_header_security_pam_misc_h$ac_cv_header_security_openpam_h" ; then
1057     AC_MSG_WARN([*** pam support will not be built ***])
1058     with_libpam="no"
1059   fi
1060 fi
1061
1062 if test "$with_libpam" = "yes"; then
1063 dnl took this test from proftpds configure.in and suited to our needs
1064 dnl -------------------------------------------------------------------------
1065 dnl
1066 dnl This next check looks funky due to a linker problem with some versions
1067 dnl of the PAM library.  Prior to 0.72 release, the Linux PAM shared library
1068 dnl omitted requiring libdl linking information. PAM-0.72 or better ships
1069 dnl with RedHat 6.2 and Debian 2.2 or better.
1070 AC_CHECK_LIB(pam, pam_start,
1071   [AC_CHECK_LIB(pam, $pam_conv_func,
1072     [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1073      LIBPAM="-lpam"],
1074     [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1075      LIBPAM="-lpam -lpam_misc"]
1076     )
1077   ],
1078
1079   [AC_CHECK_LIB(pam, pam_end,
1080     [AC_CHECK_LIB(pam, $pam_conv_func,
1081       [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1082        LIBPAM="-lpam -ldl"],
1083       [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1084        LIBPAM="-lpam -ldl -lpam_misc"]
1085      )
1086   ],AC_MSG_WARN([*** pam support will not be built ***]),
1087   [-ldl])
1088   ]
1089 )
1090 fi
1091 AC_SUBST(LIBPAM)
1092
1093 dnl -------------------------------
1094 dnl Endian-ness check
1095 dnl -------------------------------
1096 AC_WORDS_BIGENDIAN
1097
1098 dnl -------------------------------
1099 dnl check the size in byte of the C
1100 dnl -------------------------------
1101 dnl AC_CHECK_SIZEOF(char)
1102 dnl AC_CHECK_SIZEOF(int)
1103 dnl AC_CHECK_SIZEOF(short)
1104 dnl AC_CHECK_SIZEOF(long)
1105
1106 dnl ----------------------------
1107 dnl check existance of functions
1108 dnl ----------------------------
1109 AC_FUNC_FNMATCH
1110 AC_FUNC_FORK
1111 AC_FUNC_MKTIME
1112 AC_FUNC_STAT
1113
1114 dnl -------------------------------
1115 dnl bgpd needs pow() and hence libm
1116 dnl -------------------------------
1117 TMPLIBS="$LIBS"
1118 AC_CHECK_HEADER([math.h],
1119   [AC_CHECK_LIB([m], [pow],
1120     [LIBM="-lm"
1121      LIBS="$LIBS $LIBM"
1122      AC_CHECK_FUNCS(pow,[],[LIBM=""])
1123     ])
1124 ])
1125 if test x"$LIBM" = x ; then
1126   AC_MSG_WARN([Unable to find working pow function - bgpd may not link])
1127 fi
1128 LIBS="$TMPLIBS"
1129 AC_SUBST(LIBM)
1130
1131 AC_CHECK_FUNCS([ppoll], [
1132   AC_DEFINE([HAVE_PPOLL], 1, [have Linux/BSD ppoll()])
1133 ])
1134 AC_CHECK_FUNCS([pollts], [
1135   AC_DEFINE([HAVE_POLLTS], 1, [have NetBSD pollts()])
1136 ])
1137
1138 dnl ---------------
1139 dnl other functions
1140 dnl ---------------
1141 AC_CHECK_FUNCS([ \
1142         strlcat strlcpy \
1143         getgrouplist])
1144
1145 AC_CHECK_HEADER([asm-generic/unistd.h],
1146                 [AC_CHECK_DECL(__NR_setns,
1147                                AC_DEFINE(HAVE_NETNS,, Have netns),,
1148                                FRR_INCLUDES [#include <asm-generic/unistd.h>
1149                                ])
1150                  AC_CHECK_FUNCS(setns)]
1151                )
1152
1153 dnl --------------------------
1154 dnl Determine IS-IS I/O method
1155 dnl --------------------------
1156 AC_DEFINE(ISIS_METHOD_PFPACKET, 1, [ constant value for isis method pfpacket ])
1157 AC_DEFINE(ISIS_METHOD_DLPI,     2, [ constant value for isis method dlpi ])
1158 AC_DEFINE(ISIS_METHOD_BPF,      3, [ constant value for isis method bpf ])
1159 AC_CHECK_HEADER(net/bpf.h)
1160 AC_CHECK_HEADER(sys/dlpi.h)
1161 AC_MSG_CHECKING(zebra IS-IS I/O method)
1162
1163 case "$host_os" in
1164   linux*)
1165     AC_MSG_RESULT(pfpacket)
1166     ISIS_METHOD_MACRO="ISIS_METHOD_PFPACKET"
1167     ;;
1168   solaris* | sunos*)
1169     AC_MSG_RESULT(DLPI)
1170     ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1171     ;;
1172   *)
1173     if test $ac_cv_header_net_bpf_h = no; then
1174       if test $ac_cv_header_sys_dlpi_h = no; then
1175         AC_MSG_RESULT(none)
1176         if test "${enable_isisd}" = yes; then
1177           AC_MSG_FAILURE([IS-IS support requested but no packet backend found])
1178         fi
1179         AC_MSG_WARN([*** IS-IS support will not be built ***])
1180         enable_isisd="no"
1181       else
1182         AC_MSG_RESULT(DLPI)
1183       fi
1184       ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1185     else
1186       AC_MSG_RESULT(BPF)
1187       ISIS_METHOD_MACRO="ISIS_METHOD_BPF"
1188     fi
1189     ;;
1190 esac
1191 AC_DEFINE_UNQUOTED(ISIS_METHOD, $ISIS_METHOD_MACRO, [ selected method for isis, == one of the constants ])
1192
1193 dnl ------------------------------------
1194 dnl check for broken CMSG_FIRSTHDR macro
1195 dnl ------------------------------------
1196 AC_MSG_CHECKING(for broken CMSG_FIRSTHDR)
1197 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1198 #ifdef SUNOS_5
1199 #define _XPG4_2
1200 #define __EXTENSIONS__
1201 #endif
1202 #include <stdlib.h>
1203 #include <sys/types.h>
1204 #include <sys/socket.h>
1205
1206 main()
1207 {
1208   struct msghdr msg;
1209   char buf[4];
1210
1211   msg.msg_control = buf;
1212   msg.msg_controllen = 0;
1213
1214   if (CMSG_FIRSTHDR(&msg) != NULL)
1215     exit(0);
1216   exit (1);
1217 }]])],[AC_MSG_RESULT(yes - using workaround) AC_DEFINE(HAVE_BROKEN_CMSG_FIRSTHDR,,Broken CMSG_FIRSTHDR)],
1218 [AC_MSG_RESULT(no)],[AC_MSG_RESULT(no)])
1219
1220 dnl ---------------------------------------------------------------
1221 dnl figure out how to specify an interface in multicast sockets API
1222 dnl ---------------------------------------------------------------
1223 AC_CHECK_MEMBERS([struct ip_mreqn.imr_ifindex], [], [], FRR_INCLUDES)
1224
1225 AC_CHECK_HEADERS([linux/mroute.h], [], [],[
1226         #include <sys/socket.h>
1227         #include <netinet/in.h>
1228         #define _LINUX_IN_H             /* For Linux <= 2.6.25 */
1229         #include <linux/types.h>
1230 ])
1231
1232 m4_define([FRR_INCLUDES],
1233 FRR_INCLUDES
1234 [#if HAVE_LINUX_MROUTE_H
1235 # include <linux/mroute.h>
1236 #endif
1237 ])dnl
1238
1239 AC_CHECK_HEADERS([netinet/ip_mroute.h], [], [],[
1240         #include <sys/socket.h>
1241         #include <sys/types.h>
1242         #include <netinet/in.h>
1243         #include <net/route.h>
1244 ])
1245
1246 m4_define([FRR_INCLUDES],
1247 FRR_INCLUDES
1248 [#if HAVE_NETINET_IP_MROUTE_H
1249 # include <netinet/ip_mroute.h>
1250 #endif
1251 ])dnl
1252
1253 AC_MSG_CHECKING([for BSD struct ip_mreq hack])
1254 AC_TRY_COMPILE([#include <sys/param.h>],
1255 [#if (defined(__FreeBSD__) && ((__FreeBSD_version >= 500022 && __FreeBSD_version < 700000) || (__FreeBSD_version < 500000 && __FreeBSD_version >= 440000))) || (defined(__NetBSD__) && defined(__NetBSD_Version__) && __NetBSD_Version__ >= 106010000) || defined(__OpenBSD__) || defined(__APPLE__) || defined(__DragonFly__) || defined(__sun)
1256   return (0);
1257 #else
1258   #error No support for BSD struct ip_mreq hack detected
1259 #endif],[AC_MSG_RESULT(yes)
1260 AC_DEFINE(HAVE_BSD_STRUCT_IP_MREQ_HACK,,[Can pass ifindex in struct ip_mreq])],
1261 AC_MSG_RESULT(no))
1262
1263 AC_MSG_CHECKING([for RFC3678 protocol-independed API])
1264 AC_TRY_COMPILE([
1265 #include <sys/types.h>
1266 #include <netinet/in.h>
1267 ], [struct group_req gr; int sock; setsockopt(sock, IPPROTO_IP, MCAST_JOIN_GROUP, (void*)&gr, sizeof(gr));
1268 ], [AC_MSG_RESULT(yes)
1269 AC_DEFINE(HAVE_RFC3678,1,[Have RFC3678 protocol-independed API])],
1270 AC_MSG_RESULT(no))
1271
1272 dnl ---------------------------------------------------------------
1273 dnl figure out how to check link-state
1274 dnl ---------------------------------------------------------------
1275 AC_CHECK_HEADER( [net/if_media.h],
1276   [m4_define([LINK_DETECT_INCLUDES],
1277     FRR_INCLUDES
1278     [#include <net/if_media.h>
1279   ])
1280   AC_CHECK_MEMBERS( [struct ifmediareq.ifm_status],
1281     AC_DEFINE(HAVE_BSD_LINK_DETECT,,[BSD link-detect]),
1282     [], LINK_DETECT_INCLUDES)],
1283   [],
1284   FRR_INCLUDES)
1285
1286 dnl ---------------------------------------------------------------
1287 dnl Additional, newer way to check link-state using ifi_link_state.
1288 dnl Not available in all BSD's when ifmediareq available
1289 dnl ---------------------------------------------------------------
1290 AC_CHECK_MEMBERS([struct if_data.ifi_link_state],
1291   AC_DEFINE(HAVE_BSD_IFI_LINK_STATE,,[BSD ifi_link_state available]),
1292   [], FRR_INCLUDES)
1293
1294 dnl ------------------------
1295 dnl TCP_MD5SIG socket option
1296 dnl ------------------------
1297
1298 AC_CHECK_HEADER([netinet/tcp.h],
1299    [m4_define([MD5_INCLUDES],
1300       FRR_INCLUDES
1301       [#include <netinet/tcp.h>
1302     ])
1303     AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)],
1304    [],
1305    FRR_INCLUDES)
1306 if test $ac_cv_have_decl_TCP_MD5SIG = no; then
1307   AC_CHECK_HEADER([linux/tcp.h],
1308        [m4_define([MD5_INCLUDES],
1309           FRR_INCLUDES
1310           [#include <linux/tcp.h>
1311         ])
1312        AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)])
1313 fi
1314
1315 dnl ----------------------------------------------------------------------------
1316 dnl figure out if domainname is available in the utsname struct (GNU extension).
1317 dnl ----------------------------------------------------------------------------
1318 AC_CHECK_MEMBERS([struct utsname.domainname], [], [], [#include <sys/utsname.h>])
1319
1320 dnl ------------------
1321 dnl IPv6 header checks
1322 dnl ------------------
1323 AC_CHECK_HEADERS([netinet6/in6.h netinet/in6_var.h \
1324         netinet6/in6_var.h netinet6/nd6.h], [], [],
1325         FRR_INCLUDES)
1326
1327 m4_define([FRR_INCLUDES],dnl
1328 FRR_INCLUDES
1329 [#if HAVE_NETINET6_IN6_H
1330 #include <netinet6/in6.h>
1331 #endif
1332 #if HAVE_NETINET_IN6_VAR_H
1333 #include <netinet/in6_var.h>
1334 #endif
1335 #include <netinet/icmp6.h>
1336 #if HAVE_NETINET6_IN6_VAR_H
1337 # include <netinet6/in6_var.h>
1338 #endif
1339 #if HAVE_NETINET6_ND6_H
1340 # include <netinet6/nd6.h>
1341 #endif
1342 ])dnl
1343
1344 dnl disable doc check
1345 if test "${enable_doc}" = "no";then
1346   DOC=""
1347 else
1348   DOC="doc"
1349 fi
1350
1351 dnl --------------------
1352 dnl Daemon disable check
1353 dnl --------------------
1354 AM_CONDITIONAL(ZEBRA, test "${enable_zebra}" != "no")
1355
1356 if test "${enable_bgpd}" = "no";then
1357   BGPD=""
1358 else
1359   BGPD="bgpd"
1360 fi
1361 AM_CONDITIONAL(BGPD, test "x$BGPD" = "xbgpd")
1362
1363 AM_CONDITIONAL(RIPD, test "${enable_ripd}" != "no")
1364 AM_CONDITIONAL(OSPFD, test "${enable_ospfd}" != "no")
1365 AM_CONDITIONAL(LDPD, test "${enable_ldpd}" != "no")
1366
1367 AS_IF([test "${enable_ldpd}" != "no"], [
1368   AC_DEFINE(HAVE_LDPD, 1, ldpd)
1369 ])
1370
1371 NHRPD=""
1372 case "$host_os" in
1373   linux*)
1374     if test "${enable_nhrpd}" != "no"; then
1375       NHRPD="nhrpd"
1376     fi
1377     ;;
1378   *)
1379     if test "${enable_nhrpd}" = "yes"; then
1380       AC_MSG_ERROR([nhrpd requires kernel APIs that are only present on Linux.])
1381     fi
1382     ;;
1383 esac
1384 AM_CONDITIONAL(NHRPD, test "x$NHRPD" = "xnhrpd")
1385
1386 AM_CONDITIONAL(EIGRPD, test "${enable_eigrpd}" != "no")
1387
1388 if test "${enable_watchfrr}" = "no";then
1389   WATCHFRR=""
1390 else
1391   WATCHFRR="watchfrr"
1392 fi
1393 AM_CONDITIONAL(WATCHFRR, test "x$WATCHFRR" = "xwatchfrr")
1394
1395 OSPFCLIENT=""
1396 if test "${enable_ospfapi}" != "no";then
1397     AC_DEFINE(SUPPORT_OSPF_API,,OSPFAPI)
1398
1399   if test "${enable_ospfclient}" != "no";then
1400       OSPFCLIENT="ospfclient"
1401   fi
1402 fi
1403
1404 AM_CONDITIONAL(OSPFCLIENT, test "x$OSPFCLIENT" = "xospfclient")
1405 AM_CONDITIONAL(RIPNGD, test "${enable_ripngd}" != "no")
1406 AM_CONDITIONAL(BABELD, test "${enable_babeld}" != "no")
1407 AM_CONDITIONAL(OSPF6D, test "${enable_ospf6d}" != "no")
1408 AM_CONDITIONAL(ISISD, test "${enable_isisd}" != "no")
1409 AM_CONDITIONAL(PIMD, test "${enable_pimd}" != "no")
1410 AM_CONDITIONAL(PBRD, test "${enable_pbrd}" != "no")
1411 AM_CONDITIONAL(SHARPD, test "${enable_sharpd}" = "yes")
1412
1413 if test "${enable_bgp_announce}" = "no";then
1414   AC_DEFINE(DISABLE_BGP_ANNOUNCE,1,Disable BGP installation to zebra)
1415 else
1416   AC_DEFINE(DISABLE_BGP_ANNOUNCE,0,Disable BGP installation to zebra)
1417 fi
1418
1419 if test "${with_rfp_path}" = "yes" || test x"${with_rfp_path}" = x""; then
1420   with_rfp_path="bgpd/rfp-example"
1421 fi
1422 if test "${with_rfp_path}" != "no"; then
1423   VNC_RFP_PATH="${with_rfp_path}"
1424   AC_SUBST(VNC_RFP_PATH)
1425 fi
1426
1427 if test "${enable_bgp_vnc}" != "no";then
1428   AC_DEFINE(ENABLE_BGP_VNC,1,Enable BGP VNC support)
1429   RFPTEST="${with_rfp_path}/rfptest"
1430   LIBRFP="${with_rfp_path}/librfp"
1431   RFPINC="${with_rfp_path}/librfp"
1432 else
1433   RFPTEST=
1434   LIBRFP=
1435   RFPINC="bgpd/rfp-example/librfp"
1436 fi
1437 # set
1438 AM_CONDITIONAL([ENABLE_BGP_VNC], [test x${enable_bgp_vnc} != xno])
1439
1440 AC_SUBST(DOC)
1441 AC_SUBST(RFPTEST)
1442 AC_SUBST(LIBRFP)
1443 AC_SUBST(RFPINC)
1444 AC_SUBST(BGPD)
1445 AC_SUBST(SOLARIS)
1446 AC_SUBST(VTYSH)
1447 AC_SUBST(CURSES)
1448 AC_CHECK_LIB(crypt, crypt, [],
1449                     [AC_CHECK_LIB(crypto, DES_crypt)])
1450 AC_CHECK_LIB(resolv, res_init)
1451
1452 dnl ---------------------------
1453 dnl check system has PCRE regexp
1454 dnl ---------------------------
1455 if test "x$enable_pcreposix" = "xyes"; then
1456   AC_CHECK_LIB(pcreposix, regexec, [], [
1457     AC_MSG_ERROR([--enable-pcreposix given but unable to find libpcreposix])
1458   ])
1459 fi
1460 AC_SUBST(HAVE_LIBPCREPOSIX)
1461
1462 dnl ------------------
1463 dnl check C-Ares library
1464 dnl ------------------
1465 if test "${NHRPD}" != ""; then
1466   PKG_CHECK_MODULES([CARES], [libcares], , [
1467     AC_MSG_ERROR([trying to build nhrpd, but libcares not found. install c-ares and its -dev headers.])
1468   ])
1469 fi
1470
1471
1472 dnl ------------------
1473 dnl check Net-SNMP library
1474 dnl ------------------
1475 if test "${enable_snmp}" != "" -a "${enable_snmp}" != "no"; then
1476    AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], [no])
1477    if test x"$NETSNMP_CONFIG" = x"no"; then
1478       AC_MSG_ERROR([--enable-snmp given but unable to find net-snmp-config])
1479    fi
1480    SNMP_LIBS="`${NETSNMP_CONFIG} --agent-libs`"
1481    SNMP_CFLAGS="`${NETSNMP_CONFIG} --base-cflags`"
1482    AC_MSG_CHECKING([whether we can link to Net-SNMP])
1483    AC_LINK_IFELSE_FLAGS([$SNMP_CFLAGS], [$SNMP_LIBS], [AC_LANG_PROGRAM([
1484 int main(void);
1485 ],
1486 [
1487 {
1488   return 0;
1489 }
1490 ])], [
1491      AC_MSG_ERROR([--enable-snmp given but not usable])])
1492    case "${enable_snmp}" in
1493      yes)
1494       SNMP_METHOD=agentx
1495       ;;
1496      smux|agentx)
1497       SNMP_METHOD="${enable_snmp}"
1498       ;;
1499      *)
1500       AC_MSG_ERROR([--enable-snmp given with an unknown method (${enable_snmp}). Use smux or agentx])
1501       ;;
1502    esac
1503    AH_TEMPLATE([SNMP_SMUX], [Use SNMP SMUX to interface with snmpd])
1504    AH_TEMPLATE([SNMP_AGENTX], [Use SNMP AgentX to interface with snmpd])
1505    AC_DEFINE_UNQUOTED(AS_TR_CPP(SNMP_${SNMP_METHOD}),,SNMP method to interface with snmpd)
1506 fi
1507 AM_CONDITIONAL([SNMP], [test "x${SNMP_METHOD}" != "x"])
1508 AC_SUBST(SNMP_LIBS)
1509 AC_SUBST(SNMP_CFLAGS)
1510
1511 dnl ---------------
1512 dnl math
1513 dnl ---------------
1514 AC_SEARCH_LIBS([sqrt], [m])
1515
1516 dnl ---------------
1517 dnl dlopen & dlinfo
1518 dnl ---------------
1519 AC_SEARCH_LIBS(dlopen, [dl dld], [], [
1520   AC_MSG_ERROR([unable to find the dlopen()])
1521 ])
1522
1523 AC_CHECK_HEADERS([link.h])
1524
1525 AC_MSG_CHECKING([for dlinfo(RTLD_DI_ORIGIN)])
1526 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1527 #include <stdlib.h>
1528 #ifdef HAVE_LINK_H
1529 #include <link.h>
1530 #endif
1531 #include <dlfcn.h>
1532 ]], [[
1533   char origin[1];
1534   dlinfo (NULL, RTLD_DI_ORIGIN, &origin);
1535 ]])], [
1536   AC_MSG_RESULT(yes)
1537   AC_DEFINE(HAVE_DLINFO_ORIGIN, 1, [Have dlinfo RTLD_DI_ORIGIN])
1538 ], [
1539   AC_MSG_RESULT(no)
1540 ])
1541
1542 AC_MSG_CHECKING([for dlinfo(RTLD_DI_LINKMAP)])
1543 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1544 #include <stdlib.h>
1545 #ifdef HAVE_LINK_H
1546 #include <link.h>
1547 #endif
1548 #include <dlfcn.h>
1549 ]], [[
1550   struct link_map *lm = NULL;
1551   dlinfo (NULL, RTLD_DI_LINKMAP, &lm);
1552 ]])], [
1553   AC_MSG_RESULT(yes)
1554   AC_DEFINE(HAVE_DLINFO_LINKMAP, 1, [Have dlinfo RTLD_DI_LINKMAP])
1555 ], [
1556   AC_MSG_RESULT(no)
1557 ])
1558
1559
1560 AM_CONDITIONAL(SNMP, test "x$SNMP_METHOD" = "xagentx")
1561
1562 dnl ---------------------------
1563 dnl sockaddr and netinet checks
1564 dnl ---------------------------
1565 AC_CHECK_TYPES([
1566         struct sockaddr_dl,
1567         struct vifctl, struct mfcctl, struct sioc_sg_req,
1568         vifi_t, struct sioc_vif_req, struct igmpmsg,
1569         struct ifaliasreq, struct if6_aliasreq, struct in6_aliasreq,
1570         struct nd_opt_adv_interval, struct rt_addrinfo,
1571         struct nd_opt_homeagent_info, struct nd_opt_adv_interval],
1572         [], [], FRR_INCLUDES)
1573
1574 AC_CHECK_MEMBERS([struct sockaddr.sa_len,
1575         struct sockaddr_in.sin_len, struct sockaddr_un.sun_len,
1576         struct sockaddr_dl.sdl_len,
1577         struct if6_aliasreq.ifra_lifetime,
1578         struct nd_opt_adv_interval.nd_opt_ai_type],
1579         [], [], FRR_INCLUDES)
1580
1581 dnl ---------------------------
1582 dnl IRDP/pktinfo/icmphdr checks
1583 dnl ---------------------------
1584
1585 AC_CHECK_TYPES([struct in_pktinfo], [
1586   AC_CHECK_TYPES([struct icmphdr], [
1587     IRDP=true
1588   ], [
1589     IRDP=false
1590   ], [FRR_INCLUDES])
1591 ], [
1592   IRDP=false
1593 ], [FRR_INCLUDES])
1594
1595 case "${enable_irdp}" in
1596 yes)
1597   $IRDP || AC_MSG_ERROR(['IRDP requires in_pktinfo at the moment!'])
1598   ;;
1599 no)
1600   IRDP=false
1601   ;;
1602 esac
1603
1604 AM_CONDITIONAL(IRDP, $IRDP)
1605
1606 dnl -----------------------
1607 dnl checking for IP_PKTINFO
1608 dnl -----------------------
1609 AC_MSG_CHECKING(for IP_PKTINFO)
1610 AC_TRY_COMPILE([#include <netdb.h>], [
1611   int opt = IP_PKTINFO;
1612 ], [
1613   AC_MSG_RESULT(yes)
1614   AC_DEFINE(HAVE_IP_PKTINFO, 1, [Have IP_PKTINFO])
1615 ], [
1616   AC_MSG_RESULT(no)
1617 ])
1618
1619 dnl ---------------------------
1620 dnl checking for IP_RECVDSTADDR
1621 dnl ---------------------------
1622 AC_MSG_CHECKING(for IP_RECVDSTADDR)
1623 AC_TRY_COMPILE([#include <netinet/in.h>], [
1624   int opt = IP_RECVDSTADDR;
1625 ], [
1626   AC_MSG_RESULT(yes)
1627   AC_DEFINE(HAVE_IP_RECVDSTADDR, 1, [Have IP_RECVDSTADDR])
1628 ], [
1629   AC_MSG_RESULT(no)
1630 ])
1631
1632 dnl ----------------------
1633 dnl checking for IP_RECVIF
1634 dnl ----------------------
1635 AC_MSG_CHECKING(for IP_RECVIF)
1636 AC_TRY_COMPILE([#include <netinet/in.h>], [
1637   int opt = IP_RECVIF;
1638 ], [
1639   AC_MSG_RESULT(yes)
1640   AC_DEFINE(HAVE_IP_RECVIF, 1, [Have IP_RECVIF])
1641 ], [
1642   AC_MSG_RESULT(no)
1643 ])
1644
1645 dnl ----------------------
1646 dnl checking for SO_BINDANY
1647 dnl ----------------------
1648 AC_MSG_CHECKING(for SO_BINDANY)
1649 AC_TRY_COMPILE([#include <sys/socket.h>], [
1650   int opt = SO_BINDANY;
1651 ], [
1652   AC_MSG_RESULT(yes)
1653   AC_DEFINE(HAVE_SO_BINDANY, 1, [Have SO_BINDANY])
1654 ], [
1655   AC_MSG_RESULT(no)
1656 ])
1657
1658 dnl ----------------------
1659 dnl checking for IP_FREEBIND
1660 dnl ----------------------
1661 AC_MSG_CHECKING(for IP_FREEBIND)
1662 AC_TRY_COMPILE([#include <netinet/in.h>], [
1663   int opt = IP_FREEBIND;
1664 ], [
1665   AC_MSG_RESULT(yes)
1666   AC_DEFINE(HAVE_IP_FREEBIND, 1, [Have IP_FREEBIND])
1667 ], [
1668   AC_MSG_RESULT(no)
1669 ])
1670
1671 dnl --------------------------------------
1672 dnl checking for be32dec existence or not
1673 dnl --------------------------------------
1674 AC_CHECK_DECLS([be32enc, be32dec], [], [],
1675                [#include <sys/endian.h>])
1676
1677 dnl --------------------------------------
1678 dnl checking for clock_time monotonic struct and call
1679 dnl --------------------------------------
1680 AC_CHECK_DECL(CLOCK_MONOTONIC,
1681         [AC_CHECK_LIB(rt, clock_gettime, [LIBS="$LIBS -lrt"])
1682          AC_DEFINE(HAVE_CLOCK_MONOTONIC,, Have monotonic clock)
1683 ], [AC_MSG_RESULT(no)], [FRR_INCLUDES])
1684
1685 dnl --------------------------------------
1686 dnl checking for flex and bison
1687 dnl --------------------------------------
1688
1689 AM_PROG_LEX
1690 AC_MSG_CHECKING(version of flex)
1691 frr_ac_flex_version="$(eval $LEX -V | grep flex | head -n 1)"
1692 frr_ac_flex_version="${frr_ac_flex_version##* }"
1693 AC_MSG_RESULT([$frr_ac_flex_version])
1694 AX_COMPARE_VERSION([$frr_ac_flex_version], [lt], [2.5.20], [
1695   LEX="$SHELL $missing_dir/missing flex"
1696   if test -f "${srcdir}/lib/command_lex.c" -a -f "${srcdir}/lib/command_lex.h"; then
1697     AC_MSG_WARN([using pregenerated flex output files])
1698   else
1699     AC_MSG_ERROR([flex failure and pregenerated files not included (probably a git build)])
1700   fi
1701   AC_SUBST([LEX_OUTPUT_ROOT], [lex.yy])
1702   AC_SUBST([LEXLIB], [''])
1703 ])
1704
1705 AC_PROG_YACC
1706 dnl thanks GNU bison for this b*llshit...
1707 AC_MSG_CHECKING(version of bison)
1708 frr_ac_bison_version="$(eval $YACC -V | grep bison | head -n 1)"
1709 frr_ac_bison_version="${frr_ac_bison_version##* }"
1710 frr_ac_bison_missing="false"
1711 case "x${frr_ac_bison_version}" in
1712   x2.7*)
1713     BISON_OPENBRACE='"'
1714     BISON_CLOSEBRACE='"'
1715     BISON_VERBOSE=''
1716     AC_MSG_RESULT([$frr_ac_bison_version - 2.7 or older])
1717     ;;
1718   x2.*|x1.*)
1719     AC_MSG_RESULT([$frr_ac_bison_version])
1720     AC_MSG_WARN([installed bison is too old.  Please install GNU bison 2.7.x or newer.])
1721     frr_ac_bison_missing="true"
1722     ;;
1723   x)
1724     AC_MSG_RESULT([none])
1725     AC_MSG_WARN([could not determine bison version.  Please install GNU bison 2.7.x or newer.])
1726     frr_ac_bison_missing="true"
1727     ;;
1728   *)
1729     BISON_OPENBRACE='{'
1730     BISON_CLOSEBRACE='}'
1731     BISON_VERBOSE='-Dparse.error=verbose'
1732     AC_MSG_RESULT([$frr_ac_bison_version - 3.0 or newer])
1733     ;;
1734 esac
1735 AC_SUBST(BISON_OPENBRACE)
1736 AC_SUBST(BISON_CLOSEBRACE)
1737 AC_SUBST(BISON_VERBOSE)
1738
1739 if $frr_ac_bison_missing; then
1740   YACC="$SHELL $missing_dir/missing bison -y"
1741   if test -f "${srcdir}/lib/command_parse.c" -a -f "${srcdir}/lib/command_parse.h"; then
1742     AC_MSG_WARN([using pregenerated bison output files])
1743   else
1744     AC_MSG_ERROR([bison failure and pregenerated files not included (probably a git build)])
1745   fi
1746 fi
1747
1748 dnl -------------------
1749 dnl capabilities checks
1750 dnl -------------------
1751 if test "${enable_capabilities}" != "no"; then
1752   AC_MSG_CHECKING(whether prctl PR_SET_KEEPCAPS is available)
1753   AC_TRY_COMPILE([#include <sys/prctl.h>],[prctl(PR_SET_KEEPCAPS, 1, 0, 0, 0);],
1754     [AC_MSG_RESULT(yes)
1755      AC_DEFINE(HAVE_PR_SET_KEEPCAPS,,prctl)
1756      frr_ac_keepcaps="yes"],
1757      AC_MSG_RESULT(no)
1758   )
1759   if test x"${frr_ac_keepcaps}" = x"yes"; then
1760     AC_CHECK_HEADERS(sys/capability.h)
1761   fi
1762   if test x"${ac_cv_header_sys_capability_h}" = x"yes"; then
1763     AC_CHECK_LIB(cap, cap_init,
1764       [AC_DEFINE(HAVE_LCAPS,1,Capabilities)
1765        LIBCAP="-lcap"
1766        frr_ac_lcaps="yes"]
1767     )
1768   else
1769     AC_CHECK_HEADERS(priv.h,
1770      [AC_MSG_CHECKING(Solaris style privileges are available)
1771       AC_TRY_COMPILE([#include <priv.h>],[getpflags(PRIV_AWARE);],
1772           [AC_MSG_RESULT(yes)
1773            AC_DEFINE(HAVE_SOLARIS_CAPABILITIES,1,getpflags)
1774            frr_ac_scaps="yes"],
1775            AC_MSG_RESULT(no)
1776       )
1777      ]
1778    )
1779   fi
1780   if test x"${frr_ac_scaps}" = x"yes" \
1781        -o x"${frr_ac_lcaps}" = x"yes"; then
1782     AC_DEFINE(HAVE_CAPABILITIES,1,capabilities)
1783   fi
1784 fi
1785 AC_SUBST(LIBCAP)
1786
1787 dnl ---------------------------
1788 dnl check for glibc 'backtrace'
1789 dnl ---------------------------
1790 if test x"${enable_backtrace}" != x"no" ; then
1791   backtrace_ok=no
1792   AC_CHECK_HEADER([execinfo.h], [
1793     AC_SEARCH_LIBS([backtrace], [execinfo], [
1794       AC_DEFINE(HAVE_GLIBC_BACKTRACE,,[Glibc backtrace])
1795       AC_DEFINE(HAVE_STACK_TRACE,,[Stack symbol decoding])
1796       backtrace_ok=yes
1797     ],, [-lm])
1798   ])
1799
1800   if test x"${enable_backtrace}" = x"yes" -a x"${backtrace_ok}" = x"no"; then
1801     dnl user explicitly requested backtrace but we failed to find support
1802     AC_MSG_FAILURE([failed to find backtrace support])
1803   fi
1804 fi
1805
1806 dnl -----------------------------------------
1807 dnl check for malloc mallinfo struct and call
1808 dnl this must try and link using LIBS, in
1809 dnl order to check no alternative allocator
1810 dnl has been specified, which might not provide
1811 dnl mallinfo, e.g. such as Umem on Solaris.
1812 dnl -----------------------------------------
1813 AC_CHECK_HEADER([malloc.h],
1814  [AC_MSG_CHECKING(whether mallinfo is available)
1815   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <malloc.h>]],
1816                         [[struct mallinfo ac_x; ac_x = mallinfo ();]])],
1817       [AC_MSG_RESULT(yes)
1818        AC_DEFINE(HAVE_MALLINFO,,mallinfo)],
1819        AC_MSG_RESULT(no)
1820   )
1821  ], [], FRR_INCLUDES)
1822
1823 dnl ------
1824 dnl ZeroMQ
1825 dnl ------
1826 if test "x$enable_zeromq" != "xno"; then
1827   PKG_CHECK_MODULES(ZEROMQ, [libzmq >= 4.0.0], [
1828     AC_DEFINE(HAVE_ZEROMQ, 1, [Enable ZeroMQ support])
1829     ZEROMQ=true
1830   ], [
1831     if test "x$enable_zeromq" = "xyes"; then
1832       AC_MSG_ERROR([configuration specifies --enable-zeromq but libzmq was not found])
1833     fi
1834   ])
1835 fi
1836 AM_CONDITIONAL([ZEROMQ], test "x$ZEROMQ" = "xtrue")
1837
1838 dnl ----------
1839 dnl configure date
1840 dnl ----------
1841 dev_version=`echo $VERSION | grep dev`
1842 #don't expire deprecated code in non 'dev' branch
1843 if test "${dev_version}" = ""; then
1844    CONFDATE=0
1845 else
1846    CONFDATE=`date '+%Y%m%d'`
1847 fi
1848 AC_SUBST(CONFDATE)
1849
1850 dnl ------------------------------
1851 dnl set paths for state directory
1852 dnl ------------------------------
1853 AC_MSG_CHECKING(directory to use for state file)
1854 if test "${prefix}" = "NONE"; then
1855   frr_statedir_prefix="";
1856 else
1857   frr_statedir_prefix=${prefix}
1858 fi
1859 if test "${localstatedir}" = '${prefix}/var'; then
1860   for FRR_STATE_DIR in ${frr_statedir_prefix}/var/run dnl
1861                         ${frr_statedir_prefix}/var/adm dnl
1862                         ${frr_statedir_prefix}/etc dnl
1863                         /var/run        dnl
1864                         /var/adm        dnl
1865                         /etc            dnl
1866                         /dev/null;
1867   do
1868     test -d $FRR_STATE_DIR && break
1869   done
1870   frr_statedir=$FRR_STATE_DIR
1871 else
1872   frr_statedir=${localstatedir}
1873 fi
1874 if test $frr_statedir = "/dev/null"; then
1875     AC_MSG_ERROR('STATE DIRECTORY NOT FOUND! FIX OR SPECIFY --localstatedir!')
1876 fi
1877 AC_MSG_RESULT(${frr_statedir})
1878 AC_SUBST(frr_statedir)
1879
1880 AC_DEFINE_UNQUOTED(LDPD_SOCKET, "$frr_statedir/ldpd.sock",ldpd control socket)
1881 AC_DEFINE_UNQUOTED(ZEBRA_SERV_PATH, "$frr_statedir/zserv.api",zebra api socket)
1882 AC_DEFINE_UNQUOTED(DAEMON_VTY_DIR, "$frr_statedir",daemon vty directory)
1883
1884 dnl autoconf does this, but it does it too late...
1885 test "x$prefix" = xNONE && prefix=$ac_default_prefix
1886 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
1887
1888 dnl get the full path, recursing through variables...
1889 vtysh_bin="$bindir/vtysh"
1890 for I in 1 2 3 4 5 6 7 8 9 10; do
1891         eval vtysh_bin="\"$vtysh_bin\""
1892 done
1893 AC_DEFINE_UNQUOTED(VTYSH_BIN_PATH, "$vtysh_bin",path to vtysh binary)
1894
1895 CFG_SYSCONF="$sysconfdir"
1896 CFG_SBIN="$sbindir"
1897 CFG_STATE="$frr_statedir"
1898 CFG_MODULE="$moduledir"
1899 for I in 1 2 3 4 5 6 7 8 9 10; do
1900         eval CFG_SYSCONF="\"$CFG_SYSCONF\""
1901         eval CFG_SBIN="\"$CFG_SBIN\""
1902         eval CFG_STATE="\"$CFG_STATE\""
1903         eval CFG_MODULE="\"$CFG_MODULE\""
1904 done
1905 AC_SUBST(CFG_SYSCONF)
1906 AC_SUBST(CFG_SBIN)
1907 AC_SUBST(CFG_STATE)
1908 AC_SUBST(CFG_MODULE)
1909 AC_DEFINE_UNQUOTED(MODULE_PATH, "$CFG_MODULE", path to modules)
1910
1911 dnl ------------------------------------
1912 dnl Enable RPKI and add librtr to libs
1913 dnl ------------------------------------
1914 if test "${enable_rpki}" = "yes"; then
1915   PKG_CHECK_MODULES(RTRLIB,[rtrlib >= 0.5.0],
1916       [AC_DEFINE(HAVE_RPKI,1,Enable RPKI prefix validation for BGP)
1917       RPKI=true],
1918       [RPKI=false
1919       AC_MSG_ERROR([rtrlib was not found on your system or is too old.])]
1920   )
1921 fi
1922 AM_CONDITIONAL([RPKI], test "x$RPKI" = "xtrue")
1923
1924 dnl ------------------------------------------
1925 dnl Check whether rtrlib was build with ssh support
1926 dnl ------------------------------------------
1927 AC_MSG_CHECKING([whether the RTR Library is compiled with SSH])
1928 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "rtrlib/rtrlib.h"]],
1929                         [[struct tr_ssh_config config;]])],
1930         [AC_MSG_RESULT(yes)
1931         AC_DEFINE(FOUND_SSH,,found_ssh)],
1932         AC_MSG_RESULT(no)
1933 )
1934
1935 dnl ---------------------------
1936 dnl Check htonl works correctly
1937 dnl ---------------------------
1938 AC_MSG_CHECKING(for working htonl)
1939 AC_CACHE_VAL(ac_cv_htonl_works,
1940  [AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES],[htonl (0);])],
1941                 [ac_cv_htonl_works=yes], [ac_cv_htonl_works=no])
1942  ]
1943 )
1944 AC_MSG_RESULT($ac_cv_htonl_works)
1945
1946 AC_CONFIG_FILES([Makefile
1947           bgpd/Makefile
1948           vtysh/Makefile
1949           doc/Makefile
1950           doc/user/Makefile
1951           doc/manpages/Makefile
1952           doc/developer/Makefile
1953           tests/Makefile
1954           bgpd/rfp-example/rfptest/Makefile
1955           bgpd/rfp-example/librfp/Makefile
1956           redhat/frr.spec
1957           debianpkg/Makefile
1958           debianpkg/changelog
1959           alpine/APKBUILD
1960           snapcraft/snapcraft.yaml
1961           lib/version.h
1962           tests/lib/cli/test_cli.refout
1963           pkgsrc/bgpd.sh pkgsrc/ospf6d.sh pkgsrc/ospfd.sh
1964           pkgsrc/ripd.sh pkgsrc/ripngd.sh pkgsrc/zebra.sh
1965           pkgsrc/eigrpd.sh])
1966
1967 if test "${enable_bgp_vnc}" != "no"; then
1968    if test "${with_rfp_path}" != "bgpd/rfp-example" ; then
1969       AC_CONFIG_FILES([${with_rfp_path}/rfptest/Makefile ${with_rfp_path}/librfp/Makefile])
1970    fi
1971 fi
1972
1973 AC_CONFIG_FILES([solaris/Makefile])
1974
1975 AC_CONFIG_FILES([vtysh/extract.pl],[chmod +x vtysh/extract.pl])
1976
1977 AC_CONFIG_COMMANDS([lib/route_types.h], [
1978         dst="${ac_abs_top_builddir}/lib/route_types.h"
1979         ${PERL} "${ac_abs_top_srcdir}/lib/route_types.pl" \
1980                 < "${ac_abs_top_srcdir}/lib/route_types.txt" \
1981                 > "${dst}.tmp"
1982         test -f "${dst}" \
1983                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
1984                 && rm "${dst}.tmp" \
1985                 || mv "${dst}.tmp" "${dst}"
1986 ], [
1987         PERL="$PERL"
1988 ])
1989
1990 AS_IF([test "x$with_pkg_git_version" = "xyes"], [
1991     AC_CONFIG_COMMANDS([lib/gitversion.h], [
1992         dst="${ac_abs_top_builddir}/lib/gitversion.h"
1993         ${PERL} "${ac_abs_top_srcdir}/lib/gitversion.pl" \
1994                 "${ac_abs_top_srcdir}" \
1995                 > "${dst}.tmp"
1996         test -f "${dst}" \
1997                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
1998                 && rm "${dst}.tmp" \
1999                 || mv "${dst}.tmp" "${dst}"
2000     ], [
2001         PERL="$PERL"
2002     ])
2003 ])
2004
2005 ## Hack, but working solution to avoid rebuilding of frr.info.
2006 ## It's already in CVS until texinfo 4.7 is more common.
2007 AC_OUTPUT
2008
2009 echo "
2010 FRRouting configuration
2011 ------------------------------
2012 FRR version             : ${PACKAGE_VERSION}
2013 host operating system   : ${host_os}
2014 source code location    : ${srcdir}
2015 compiler                : ${CC}
2016 compiler flags          : ${CFLAGS}
2017 make                    : ${MAKE-make}
2018 linker flags            : ${LDFLAGS} ${LIBS} ${LIBCAP} ${LIBREADLINE} ${LIBM}
2019 state file directory    : ${frr_statedir}
2020 config file directory   : `eval echo \`echo ${sysconfdir}\``
2021 example directory       : `eval echo \`echo ${exampledir}\``
2022 module directory        : ${CFG_MODULE}
2023 user to run as          : ${enable_user}
2024 group to run as         : ${enable_group}
2025 group for vty sockets   : ${enable_vty_group}
2026 config file mask        : ${enable_configfile_mask}
2027 log file mask           : ${enable_logfile_mask}
2028 zebra protobuf enabled  : ${have_protobuf:-no}
2029
2030 The above user and group must have read/write access to the state file
2031 directory and to the config files in the config file directory."