configure.ac

   1 ##
   2 ## Configure template file for FRRouting.
   3 ## autoconf will generate a configure script.
   4 ##
   5 ##  Copyright (c) 1996, 97, 98, 99, 2000 Kunihiro Ishiguro <kunihiro@zebra.org>
   6 ##  Portions Copyright (c) 2003 Paul Jakma <paul@dishone.st>
   7 ##
   8 AC_PREREQ([2.69])
   9
  10 AC_INIT([frr], [8.1-dev], [https://github.com/frrouting/frr/issues])
  11 PACKAGE_URL="https://frrouting.org/"
  12 AC_SUBST([PACKAGE_URL])
  13 PACKAGE_FULLNAME="FRRouting"
  14 AC_SUBST([PACKAGE_FULLNAME])
  15
  16 CONFIG_ARGS="`echo $ac_configure_args | sed -e \"s% '[[A-Z]]*FLAGS=[[^']]\+'%%g\"`"
  17 AC_SUBST([CONFIG_ARGS])
  18
  19 AC_CONFIG_SRCDIR([lib/zebra.h])
  20 AC_CONFIG_MACRO_DIR([m4])
  21 AC_CONFIG_AUX_DIR([m4/ac])
  22
  23 dnl -----------------------------------
  24 dnl Get hostname and other information.
  25 dnl -----------------------------------
  26 AC_CANONICAL_BUILD()
  27 AC_CANONICAL_HOST()
  28
  29 AC_ARG_VAR([AR],[archiver command])
  30 AC_ARG_VAR([LD],[linker command])
  31 AC_ARG_VAR([OBJCOPY],[objcopy command])
  32 AC_ARG_VAR([OBJDUMP],[objdump command])
  33 AC_ARG_VAR([RANLIB],[ranlib command])
  34 AC_ARG_VAR([STRIP],[strip command])
  35
  36 hosttools_clippy="false"
  37 build_clippy="true"
  38
  39 dnl case 1: external clippy
  40 if test -n "$with_clippy" -a "$with_clippy" != "no" -a "$with_clippy" != "yes"; then
  41   if test "$enable_clippy_only" = "yes"; then
  42     AC_MSG_ERROR([--enable-clippy-only does not make sense with --with-clippy])
  43   fi
  44
  45   CLIPPY="$with_clippy"
  46   build_clippy="false"
  47   if test ! -x "$with_clippy"; then
  48     AC_MSG_ERROR([clippy tool ($with_clippy) is not executable])
  49   fi
  50
  51 dnl case 2: cross-compiling internal clippy
  52 elif test "$host" != "$build"; then
  53   if test "$srcdir" = "."; then
  54     AC_MSG_ERROR([cross-compilation is only possible with builddir separate from srcdir or by building clippy separately and using the --with-clippy option.  create a separate directory and run as .../path-to-frr/configure.])
  55   fi
  56   test -d hosttools || mkdir hosttools
  57   abssrc="`cd \"${srcdir}\"; pwd`"
  58
  59   AC_MSG_NOTICE([...])
  60   AC_MSG_NOTICE([... cross-compilation: creating hosttools directory and self-configuring for build platform tools])
  61   AC_MSG_NOTICE([... use HOST_CPPFLAGS / HOST_CFLAGS / HOST_LDFLAGS if neccessary])
  62   AC_MSG_NOTICE([...])
  63
  64   (
  65     for var in $ac_precious_vars; do
  66       dnl special cases
  67       case "$var" in
  68       YACC|YFLAGS) continue;;
  69       PYTHON*)     retain=true;;
  70       *)           retain=false;
  71       esac
  72
  73       eval "hostvar=\"\${HOST_$var}\""
  74       eval "targetvar=\"\${$var}\""
  75       if test -n "$hostvar"; then
  76         eval "$var='$hostvar'"
  77         _AS_ECHO_LOG([host $var='$hostvar'])
  78       elif $retain; then
  79         _AS_ECHO_LOG([host retain $var='$targetvar'])
  80       else
  81         eval "unset $var"
  82         _AS_ECHO_LOG([host unset $var])
  83       fi
  84     done
  85     cd hosttools
  86     "${abssrc}/configure" "--host=$build" "--build=$build" "--enable-clippy-only" "--disable-nhrpd" "--disable-vtysh"
  87   ) || exit 1
  88
  89   AC_MSG_NOTICE([...])
  90   AC_MSG_NOTICE([... cross-compilation: finished self-configuring for build platform tools])
  91   AC_MSG_NOTICE([...])
  92
  93   build_clippy="false"
  94   hosttools_clippy="true"
  95   CLIPPY="hosttools/lib/clippy"
  96
  97 dnl case 3: normal build internal clippy
  98 else
  99   CLIPPY="lib/clippy\$(EXEEXT)"
 100 fi
 101 AC_SUBST([CLIPPY])
 102 AM_CONDITIONAL([BUILD_CLIPPY], [$build_clippy])
 103 AM_CONDITIONAL([HOSTTOOLS_CLIPPY], [$hosttools_clippy])
 104 AM_CONDITIONAL([ONLY_CLIPPY], [test "$enable_clippy_only" = "yes"])
 105
 106 # Disable portability warnings -- our automake code (in particular
 107 # common.am) uses some constructs specific to gmake.
 108 AM_INIT_AUTOMAKE([1.12 -Wno-portability foreign])
 109 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
 110 AM_SILENT_RULES([yes])
 111 AC_CONFIG_HEADERS([config.h])
 112
 113 AC_PATH_PROG([PERL], [perl])
 114 PKG_PROG_PKG_CONFIG
 115
 116 dnl default is to match previous behavior
 117 pkgsrcrcdir=""
 118 AC_ARG_ENABLE([pkgsrcrcdir],
 119           AS_HELP_STRING([--enable-pkgsrcrcdir],
 120                          [specify directory for rc.d scripts]),
 121                          pkgsrcrcdir="$enableval",)
 122 dnl XXX add --pkgsrcrcdir to autoconf standard directory list somehow
 123 AC_SUBST([pkgsrcrcdir])
 124 AM_CONDITIONAL([PKGSRC], [test "$pkgsrcrcdir" != ""])
 125
 126 AC_ARG_WITH([moduledir], [AS_HELP_STRING([--with-moduledir=DIR], [module directory (${libdir}/frr/modules)])], [
 127         moduledir="$withval"
 128 ], [
 129         moduledir="\${libdir}/frr/modules"
 130 ])
 131 AC_SUBST([moduledir], [$moduledir])
 132
 133 AC_ARG_WITH([scriptdir], [AS_HELP_STRING([--with-scriptdir=DIR], [script directory (${sysconfdir}/scripts)])], [
 134         scriptdir="$withval"
 135 ], [
 136         scriptdir="\${sysconfdir}/scripts"
 137 ])
 138 AC_SUBST([scriptdir], [$scriptdir])
 139
 140 AC_ARG_WITH([yangmodelsdir], [AS_HELP_STRING([--with-yangmodelsdir=DIR], [yang models directory (${datarootdir}/yang)])], [
 141         yangmodelsdir="$withval"
 142 ], [
 143         yangmodelsdir="\${datarootdir}/yang"
 144 ])
 145 AC_SUBST([yangmodelsdir])
 146
 147 AC_ARG_WITH([vici-socket], [AS_HELP_STRING([--with-vici-socket=PATH], [vici-socket (/var/run/charon.vici)])], [
 148         vici_socket="$withval"
 149 ], [
 150         vici_socket="/var/run/charon.vici"
 151 ])
 152 AC_DEFINE_UNQUOTED([VICI_SOCKET], ["$vici_socket"], [StrongSWAN vici socket path])
 153
 154 AC_ARG_ENABLE(tcmalloc,
 155         AS_HELP_STRING([--enable-tcmalloc], [Turn on tcmalloc]),
 156 [case "${enableval}" in
 157   yes) tcmalloc_enabled=true
 158 LIBS="$LIBS -ltcmalloc_minimal"
 159  ;;
 160   no)  tcmalloc_enabled=false ;;
 161   *) AC_MSG_ERROR([bad value ${enableval} for --enable-tcmalloc]) ;;
 162 esac],[tcmalloc_enabled=false])
 163
 164
 165 dnl Thanks autoconf, but we don't want a default -g -O2.  We have our own
 166 dnl flag determination logic.
 167 CFLAGS="${CFLAGS:-}"
 168
 169 dnl --------------------
 170 dnl Check CC and friends
 171 dnl --------------------
 172 dnl note orig_cflags is also used further down
 173 orig_cflags="$CFLAGS"
 174 orig_cxxflags="$CXXFLAGS"
 175 AC_LANG([C])
 176 AC_PROG_CC
 177 AC_PROG_CPP
 178 AC_PROG_CXX
 179 AM_PROG_CC_C_O
 180 dnl remove autoconf default "-g -O2"
 181 CFLAGS="$orig_cflags"
 182 CXXFLAGS="$orig_cxxflags"
 183 AC_PROG_CC_C99
 184 dnl NB: see C11 below
 185
 186 dnl Some special handling for ICC later on
 187 if test "$CC" = "icc"; then
 188     cc_is_icc="yes"
 189 fi
 190
 191 PKG_PROG_PKG_CONFIG
 192
 193 dnl it's 2019, sed is sed.
 194 SED=sed
 195 AC_SUBST([SED])
 196
 197 dnl try and enable CFLAGS that are useful for FRR
 198 dnl - specifically, options to control warnings
 199
 200 AC_SUBST([AC_CFLAGS])
 201 AC_USE_SYSTEM_EXTENSIONS
 202 AC_DEFUN([AC_C_FLAG], [{
 203     m4_pushdef([cachename],[m4_translit([frr_cv_$1],[ =-+/{}$],[________])])
 204     AC_CACHE_CHECK([[whether $CC supports $1]], cachename, [
 205         AC_LANG_PUSH([C])
 206         ac_c_flag_save="$CFLAGS"
 207         CFLAGS="$CFLAGS $1"
 208         AC_COMPILE_IFELSE(
 209                 [AC_LANG_PROGRAM([[$4]])],
 210                 [
 211                         cachename=yes
 212                 ], [
 213                         cachename=no
 214                 ])
 215         CFLAGS="$ac_c_flag_save"
 216         AC_LANG_POP([C])
 217     ])
 218     if test "$cachename" = "yes"; then
 219         m4_if([$3], [], [AC_CFLAGS="$AC_CFLAGS $1"], [$3])
 220     else
 221         :
 222         $2
 223     fi
 224     m4_popdef([cachename])
 225 }])
 226
 227 AC_DEFUN([AC_LINK_IFELSE_FLAGS], [{
 228         AC_LANG_PUSH([C])
 229         ac_cflags_save="$CFLAGS"
 230         ac_libs_save="$LIBS"
 231         CFLAGS="$CFLAGS $1"
 232         LIBS="$LIBS $2"
 233         AC_LINK_IFELSE(
 234                 [$3],
 235                 [
 236                         CFLAGS="$ac_cflags_save"
 237                         LIBS="$ac_libs_save"
 238                         m4_default([$5], [
 239                                 AC_MSG_RESULT([yes])
 240                         ])
 241                 ], [
 242                         CFLAGS="$ac_cflags_save"
 243                         LIBS="$ac_libs_save"
 244                         m4_default([$4], [
 245                                 AC_MSG_RESULT([no])
 246                         ])
 247                 ])
 248         AC_LANG_POP([C])
 249         }])
 250
 251 dnl ICC won't bail on unknown options without -diag-error 10006
 252 dnl need to do this first so we get useful results for the other options
 253 if test "$cc_is_icc" = "yes"; then
 254     AC_C_FLAG([-diag-error 10006])
 255 fi
 256
 257 dnl AC_PROG_CC_C99 may change CC to include -std=gnu99 or something
 258 ac_cc="$CC"
 259 CC="${CC% -std=gnu99}"
 260 CC="${CC% -std=c99}"
 261
 262 AC_C_FLAG([-std=gnu11], [CC="$ac_cc"], [CC="$CC -std=gnu11"])
 263
 264 dnl if the user has specified any CFLAGS, override our settings
 265 if test "$enable_gcov" = "yes"; then
 266    if test "$orig_cflags" = ""; then
 267       AC_C_FLAG([--coverage])
 268       AC_C_FLAG([-O0])
 269    fi
 270
 271    AC_LDFLAGS="${AC_LDFLAGS} --coverage"
 272 fi
 273
 274 if test "$enable_clang_coverage" = "yes"; then
 275    AC_C_FLAG([-fprofile-instr-generate], [
 276      AC_MSG_ERROR([$CC does not support -fprofile-instr-generate.])
 277    ])
 278    AC_C_FLAG([-fcoverage-mapping], [
 279      AC_MSG_ERROR([$CC does not support -fcoverage-mapping.])
 280    ])
 281 fi
 282
 283 AM_CONDITIONAL([SCRIPTING], [test "$enable_scripting" = "yes"])
 284
 285 if test "$enable_scripting" = "yes"; then
 286    AX_PROG_LUA([5.3], [5.4], [], [
 287      AC_MSG_ERROR([Lua 5.3 is required to build with Lua support. No other version is supported.])
 288    ])
 289    AX_LUA_HEADERS([], [
 290      AC_MSG_ERROR([Lua 5.3 headers are required to build with Lua support. No other version is supported.])
 291    ])
 292    AX_LUA_LIBS([
 293      AC_DEFINE([HAVE_SCRIPTING], [1], [Have support for scripting])
 294      LIBS="$LIBS $LUA_LIB"
 295      SCRIPTING=true
 296    ], [
 297      SCRIPTING=false
 298      AC_MSG_ERROR([Lua 5.3 libraries are required to build with Lua support. No other version is supported.])
 299    ])
 300 fi
 301
 302 dnl the following flags go in CFLAGS rather than AC_CFLAGS since they make
 303 dnl sense to be overridden by the user
 304 if test "$enable_dev_build" = "yes"; then
 305    AC_DEFINE([DEV_BUILD], [1], [Build for development])
 306    if test "$orig_cflags" = ""; then
 307       AC_C_FLAG([-O0],,[CFLAGS="$CFLAGS -O0"])
 308       AC_C_FLAG([-g3],,[CFLAGS="$CFLAGS -g3"])
 309       AC_C_FLAG([-ggdb3],,[CFLAGS="$CFLAGS -ggdb3"])
 310    fi
 311 else
 312    if test "$orig_cflags" = ""; then
 313       AC_C_FLAG([-g],,[CFLAGS="$CFLAGS -g"])
 314       AC_C_FLAG([-O2],,[CFLAGS="$CFLAGS -O2"])
 315    fi
 316 fi
 317
 318 AM_CONDITIONAL([DEV_BUILD], [test "$enable_dev_build" = "yes"])
 319
 320 dnl always want these CFLAGS
 321 AC_C_FLAG([-fno-omit-frame-pointer])
 322 AC_C_FLAG([-funwind-tables])
 323 AC_C_FLAG([-Wall])
 324 AC_C_FLAG([-Wextra])
 325 AC_C_FLAG([-Wstrict-prototypes])
 326 AC_C_FLAG([-Wmissing-prototypes])
 327 AC_C_FLAG([-Wmissing-declarations])
 328 AC_C_FLAG([-Wpointer-arith])
 329 AC_C_FLAG([-Wbad-function-cast])
 330 AC_C_FLAG([-Wwrite-strings])
 331 AC_C_FLAG([-Wundef])
 332 if test "$enable_gcc_ultra_verbose" = "yes" ; then
 333   AC_C_FLAG([-Wcast-qual])
 334   AC_C_FLAG([-Wmissing-noreturn])
 335   AC_C_FLAG([-Wmissing-format-attribute])
 336   AC_C_FLAG([-Wunreachable-code])
 337   AC_C_FLAG([-Wpacked])
 338   AC_C_FLAG([-Wpadded])
 339   AC_C_FLAG([-Wshadow])
 340 else
 341   AC_C_FLAG([-Wno-unused-result])
 342 fi
 343 AC_C_FLAG([-Wno-unused-parameter])
 344 AC_C_FLAG([-Wno-missing-field-initializers])
 345
 346 AC_C_FLAG([-Wc++-compat], [], [CXX_COMPAT_CFLAGS="-Wc++-compat"])
 347 AC_SUBST([CXX_COMPAT_CFLAGS])
 348
 349 dnl ICC emits a broken warning for const char *x = a ? "b" : "c";
 350 dnl for some reason the string consts get 'promoted' to char *,
 351 dnl triggering a const to non-const conversion warning.
 352 if test "$cc_is_icc" = "yes"; then
 353     AC_C_FLAG([-diag-disable 3179])
 354 fi
 355
 356 if test "$enable_werror" = "yes" ; then
 357   WERROR="-Werror"
 358 fi
 359 AC_SUBST([WERROR])
 360
 361 SAN_FLAGS=""
 362 if test "$enable_address_sanitizer" = "yes"; then
 363   AC_C_FLAG([-fsanitize=address], [
 364     AC_MSG_ERROR([$CC does not support Address Sanitizer.])
 365   ], [
 366     SAN_FLAGS="$SAN_FLAGS -fsanitize=address"
 367   ])
 368 fi
 369 if test "$enable_thread_sanitizer" = "yes"; then
 370   AC_C_FLAG([-fsanitize=thread], [
 371     AC_MSG_ERROR([$CC does not support Thread Sanitizer.])
 372   ], [
 373     SAN_FLAGS="$SAN_FLAGS -fsanitize=thread"
 374   ])
 375 fi
 376 if test "$enable_memory_sanitizer" = "yes"; then
 377   AC_C_FLAG([-fsanitize=memory -fPIE -pie], [
 378     AC_MSG_ERROR([$CC does not support Memory Sanitizer.])
 379   ], [
 380     SAN_FLAGS="$SAN_FLAGS -fsanitize=memory -fPIE -pie"
 381   ])
 382 fi
 383 if test "$enable_undefined_sanitizer" = "yes"; then
 384   AC_C_FLAG([-fsanitize=undefined], [
 385     AC_MSG_ERROR([$CC does not support UndefinedBehaviorSanitizer.])
 386   ], [
 387     SAN_FLAGS="$SAN_FLAGS -fsanitize=undefined"
 388   ])
 389 fi
 390 AC_SUBST([SAN_FLAGS])
 391
 392 dnl frr-format.so
 393 if test "$with_frr_format" != "no" -a "$with_frr_format" != "yes" -a -n "$with_frr_format"; then
 394   AC_C_FLAG([-fplugin=${with_frr_format}], [
 395     AC_MSG_ERROR([specified frr-format plugin ($with_frr_format) does not work])
 396   ],,[
 397 #ifndef _FRR_ATTRIBUTE_PRINTFRR
 398 #error plugin not loaded
 399 #endif
 400 #if _FRR_ATTRIBUTE_PRINTFRR < 0x10000
 401 #error plugin too old
 402 #endif
 403   ])
 404 elif test "$with_frr_format" = "no"; then
 405   : #nothing
 406 else
 407   AC_C_FLAG([-fplugin=tools/gcc-plugins/frr-format.so],[
 408     AC_C_FLAG([-fplugin=frr-format],[
 409       if test "$with_frr_format" = "yes"; then
 410         AC_MSG_ERROR([frr-format plugin requested but not found])
 411       fi
 412     ],,[
 413 #ifndef _FRR_ATTRIBUTE_PRINTFRR
 414 #error plugin not loaded
 415 #endif
 416 #if _FRR_ATTRIBUTE_PRINTFRR < 0x10000
 417 #error plugin too old
 418 #endif
 419     ])
 420   ],,[
 421 #ifndef _FRR_ATTRIBUTE_PRINTFRR
 422 #error plugin not loaded
 423 #endif
 424 #if _FRR_ATTRIBUTE_PRINTFRR < 0x10000
 425 #error plugin too old
 426 #endif
 427   ])
 428 fi
 429
 430 AC_MSG_CHECKING([whether linker supports __start/stop_section symbols])
 431 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 432 #include <stdio.h>
 433 int __attribute__((section("secttest"))) var = 1;
 434 extern int __start_secttest, __stop_secttest;
 435 ]], [[
 436   void *a = &var, *b = &__start_secttest, *c = &__stop_secttest;
 437   printf("%p %p %p\n", a, b, c);
 438 ]])], [
 439   AC_MSG_RESULT(yes)
 440   AC_DEFINE(HAVE_SECTION_SYMS, 1, [have __start/stop_section symbols])
 441 ], [
 442   AC_MSG_RESULT(no)
 443 ])
 444
 445 dnl ----------
 446 dnl Essentials
 447 dnl ----------
 448
 449 AX_PTHREAD([
 450   CC="$PTHREAD_CC"
 451   AC_CFLAGS="$AC_CFLAGS $PTHREAD_CFLAGS"
 452   LIBS="$PTHREAD_LIBS $LIBS"
 453 ], [
 454   AC_MSG_FAILURE([This FRR version needs pthreads])
 455 ])
 456
 457 orig_cflags="$CFLAGS"
 458 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 459
 460 AC_SEARCH_LIBS([pthread_condattr_setclock], [],
 461                 [frr_cv_pthread_condattr_setclock=yes],
 462                 [frr_cv_pthread_condattr_setclock=no])
 463 if test "$frr_cv_pthread_condattr_setclock" = "yes"; then
 464   AC_DEFINE([HAVE_PTHREAD_CONDATTR_SETCLOCK], [1], [Have pthread.h pthread_condattr_setclock])
 465 fi
 466
 467 AC_CHECK_HEADERS([pthread_np.h],,, [
 468 #include <pthread.h>
 469 ])
 470 AC_CHECK_FUNCS([pthread_setname_np pthread_set_name_np pthread_getthreadid_np])
 471
 472 CFLAGS="$orig_cflags"
 473
 474 dnl --------------
 475 dnl Check programs
 476 dnl --------------
 477 AC_PROG_INSTALL
 478 AC_PROG_LN_S
 479 AC_CHECK_TOOL([AR], [ar])
 480
 481 dnl -------
 482 dnl libtool
 483 dnl -------
 484 AC_ARG_ENABLE([static-bin],
 485   AS_HELP_STRING([--enable-static-bin], [link binaries statically]))
 486 LT_INIT
 487 _LT_CONFIG_LIBTOOL([
 488   patch -N -i "${srcdir}/m4/libtool-whole-archive.patch" libtool >&AS_MESSAGE_LOG_FD || \
 489     AC_MSG_WARN([Could not patch libtool for static linking support.  Loading modules into a statically linked daemon will fail.])
 490 dnl the -i option is not POSIX sed and the BSDs implement it differently
 491 dnl cat'ing the output back instead of mv/cp keeps permissions on libtool intact
 492   sed -e 's%func_warning "relinking%true #\0%'                   libtool > libtool.sed && cat libtool.sed > libtool
 493   sed -e 's%func_warning "remember to run%true #\0%'             libtool > libtool.sed && cat libtool.sed > libtool
 494   sed -e 's%func_warning ".*has not been installed in%true #\0%' libtool > libtool.sed && cat libtool.sed > libtool
 495   test -f libtool.sed && rm libtool.sed
 496 ])
 497 if test "$enable_static_bin" = "yes"; then
 498   AC_LDFLAGS_EXEC="-static"
 499   if test "$enable_static" != "yes"; then
 500     AC_MSG_ERROR([The --enable-static-bin option must be combined with --enable-static.])
 501   fi
 502 fi
 503 if test "$enable_shared" != "yes"; then
 504   AC_MSG_ERROR([FRR cannot be built with --disable-shared.  If you want statically linked daemons, use --enable-shared --enable-static --enable-static-bin])
 505 fi
 506 AC_SUBST([AC_LDFLAGS])
 507 AC_SUBST([AC_LDFLAGS_EXEC])
 508 AM_CONDITIONAL([STATIC_BIN], [test "$enable_static_bin" = "yes"])
 509
 510 AC_ARG_ENABLE([rpath],
 511   [AS_HELP_STRING([--enable-rpath], [set hardcoded rpaths in the executable @<:@default=yes@:>@])],
 512   [],
 513   [enable_rpath=yes])
 514
 515 dnl $AR and $RANLIB are set by LT_INIT above
 516 AC_MSG_CHECKING([whether $AR supports D option])
 517 if $AR crD conftest.a >/dev/null 2>/dev/null; then
 518   AC_MSG_RESULT([yes])
 519   dnl ARFLAGS is for automake, AR_FLAGS for libtool m-(
 520   ARFLAGS="crD"
 521   AR_FLAGS="crD"
 522 else
 523   AC_MSG_RESULT([no])
 524   ARFLAGS="cru"
 525   AR_FLAGS="cru"
 526 fi
 527 AC_SUBST([ARFLAGS])
 528 AC_SUBST([AR_FLAGS])
 529
 530 AC_MSG_CHECKING([whether $RANLIB supports D option])
 531 if $RANLIB -D conftest.a >conftest.err 2>&1; then
 532   if grep -q -- '-D' conftest.err; then
 533     AC_MSG_RESULT([no])
 534   else
 535     AC_MSG_RESULT([yes])
 536     RANLIB="$RANLIB -D"
 537   fi
 538 else
 539   AC_MSG_RESULT([no])
 540 fi
 541 AC_SUBST([RANLIB])
 542
 543 test -f conftest.err && rm conftest.err
 544 test -f conftest.a && rm conftest.a
 545
 546 dnl ----------------------
 547 dnl Packages configuration
 548 dnl ----------------------
 549 if test -f config.version; then
 550   . ./config.version
 551 elif test -f "${srcdir}/config.version"; then
 552   . "${srcdir}/config.version"
 553 fi
 554 AC_ARG_WITH([pkg-extra-version],
 555   AS_HELP_STRING([--with-pkg-extra-version=VER], [add extra version field, for packagers/distributions]), [
 556   if test "$withval" = "no"; then
 557     EXTRAVERSION=
 558   else
 559     EXTRAVERSION=$withval
 560   fi
 561 ], [])
 562 AC_ARG_WITH([pkg-git-version],
 563         AS_HELP_STRING([--with-pkg-git-version], [add git information to MOTD and build version string]),
 564         [ test "$withval" != "no" && with_pkg_git_version="yes" ])
 565 AC_ARG_WITH([clippy],
 566   AS_HELP_STRING([--with-clippy=PATH], [use external clippy helper program]))
 567 AC_ARG_WITH([vtysh_pager],
 568         AS_HELP_STRING([--with-vtysh-pager=PAGER], [control what pager is compiled in as default]),
 569         VTYSH_PAGER=$withval, VTYSH_PAGER="more")
 570 AC_ARG_ENABLE([vtysh],
 571   AS_HELP_STRING([--disable-vtysh], [do not build integrated vty shell for FRR]))
 572 AC_ARG_ENABLE([doc],
 573   AS_HELP_STRING([--disable-doc], [do not build docs]))
 574 AC_ARG_ENABLE([doc-html],
 575   AS_HELP_STRING([--enable-doc-html], [build HTML docs]))
 576 AC_ARG_ENABLE([zebra],
 577   AS_HELP_STRING([--disable-zebra], [do not build zebra daemon]))
 578 AC_ARG_ENABLE([bgpd],
 579   AS_HELP_STRING([--disable-bgpd], [do not build bgpd]))
 580 AC_ARG_ENABLE([ripd],
 581   AS_HELP_STRING([--disable-ripd], [do not build ripd]))
 582 AC_ARG_ENABLE([ripngd],
 583   AS_HELP_STRING([--disable-ripngd], [do not build ripngd]))
 584 AC_ARG_ENABLE([ospfd],
 585   AS_HELP_STRING([--disable-ospfd], [do not build ospfd]))
 586 AC_ARG_ENABLE([ospf6d],
 587   AS_HELP_STRING([--disable-ospf6d], [do not build ospf6d]))
 588 AC_ARG_ENABLE([ldpd],
 589   AS_HELP_STRING([--disable-ldpd], [do not build ldpd]))
 590 AC_ARG_ENABLE([nhrpd],
 591   AS_HELP_STRING([--disable-nhrpd], [do not build nhrpd]))
 592 AC_ARG_ENABLE([eigrpd],
 593   AS_HELP_STRING([--disable-eigrpd], [do not build eigrpd]))
 594 AC_ARG_ENABLE([babeld],
 595   AS_HELP_STRING([--disable-babeld], [do not build babeld]))
 596 AC_ARG_ENABLE([watchfrr],
 597   AS_HELP_STRING([--disable-watchfrr], [do not build watchfrr]))
 598 AC_ARG_ENABLE([isisd],
 599   AS_HELP_STRING([--disable-isisd], [do not build isisd]))
 600 AC_ARG_ENABLE([pimd],
 601   AS_HELP_STRING([--disable-pimd], [do not build pimd]))
 602 AC_ARG_ENABLE([pbrd],
 603   AS_HELP_STRING([--disable-pbrd], [do not build pbrd]))
 604 AC_ARG_ENABLE([sharpd],
 605   AS_HELP_STRING([--enable-sharpd], [build sharpd]))
 606 AC_ARG_ENABLE([staticd],
 607   AS_HELP_STRING([--disable-staticd], [do not build staticd]))
 608 AC_ARG_ENABLE([fabricd],
 609   AS_HELP_STRING([--disable-fabricd], [do not build fabricd]))
 610 AC_ARG_ENABLE([vrrpd],
 611   AS_HELP_STRING([--disable-vrrpd], [do not build vrrpd]))
 612 AC_ARG_ENABLE([pathd],
 613   AS_HELP_STRING([--disable-pathd], [do not build pathd]))
 614 AC_ARG_ENABLE([bgp-announce],
 615   AS_HELP_STRING([--disable-bgp-announce], [turn off BGP route announcement]))
 616 AC_ARG_ENABLE([bgp-vnc],
 617   AS_HELP_STRING([--disable-bgp-vnc],[turn off BGP VNC support]))
 618 AC_ARG_ENABLE([bgp-bmp],
 619   AS_HELP_STRING([--disable-bgp-bmp],[turn off BGP BMP support]))
 620 AC_ARG_ENABLE([snmp],
 621   AS_HELP_STRING([--enable-snmp], [enable SNMP support for agentx]))
 622 AC_ARG_ENABLE([config_rollbacks],
 623   AS_HELP_STRING([--enable-config-rollbacks], [enable configuration rollbacks (requires sqlite3)]))
 624 AC_ARG_ENABLE([confd],
 625   AS_HELP_STRING([--enable-confd=ARG], [enable confd integration]))
 626 AC_ARG_ENABLE([sysrepo],
 627   AS_HELP_STRING([--enable-sysrepo], [enable sysrepo integration]))
 628 AC_ARG_ENABLE([grpc],
 629   AS_HELP_STRING([--enable-grpc], [enable the gRPC northbound plugin]))
 630 AC_ARG_ENABLE([zeromq],
 631   AS_HELP_STRING([--enable-zeromq], [enable ZeroMQ handler (libfrrzmq)]))
 632 AC_ARG_ENABLE([lttng],
 633   AS_HELP_STRING([--enable-lttng], [enable LTTng tracing]))
 634 AC_ARG_ENABLE([usdt],
 635   AS_HELP_STRING([--enable-usdt], [enable USDT probes]))
 636 AC_ARG_WITH([libpam],
 637   AS_HELP_STRING([--with-libpam], [use libpam for PAM support in vtysh]))
 638 AC_ARG_ENABLE([ospfapi],
 639   AS_HELP_STRING([--disable-ospfapi], [do not build OSPFAPI to access the OSPF LSA Database]))
 640 AC_ARG_ENABLE([ospfclient],
 641   AS_HELP_STRING([--disable-ospfclient], [do not build OSPFAPI client for OSPFAPI,
 642                           (this is the default if --disable-ospfapi is set)]))
 643 AC_ARG_ENABLE([multipath],
 644   AS_HELP_STRING([--enable-multipath=ARG], [enable multipath function, ARG must be digit]))
 645 AC_ARG_ENABLE([user],
 646   AS_HELP_STRING([--enable-user=USER], [user to run FRR suite as (default frr)]))
 647 AC_ARG_ENABLE([group],
 648   AS_HELP_STRING([--enable-group=GROUP], [group to run FRR suite as (default frr)]))
 649 AC_ARG_ENABLE([vty_group],
 650   AS_HELP_STRING([--enable-vty-group=ARG], [set vty sockets to have specified group as owner]))
 651 AC_ARG_ENABLE([configfile_mask],
 652   AS_HELP_STRING([--enable-configfile-mask=ARG], [set mask for config files]))
 653 AC_ARG_ENABLE([logfile_mask],
 654   AS_HELP_STRING([--enable-logfile-mask=ARG], [set mask for log files]))
 655 AC_ARG_ENABLE([shell_access],
 656   AS_HELP_STRING([--enable-shell-access], [Allow users to access shell/telnet/ssh]))
 657 AC_ARG_ENABLE([realms],
 658   AS_HELP_STRING([--enable-realms], [enable REALMS support under Linux]))
 659 AC_ARG_ENABLE([rtadv],
 660   AS_HELP_STRING([--disable-rtadv], [disable IPV6 router advertisement feature]))
 661 AC_ARG_ENABLE([irdp],
 662   AS_HELP_STRING([--disable-irdp], [disable IRDP server support in zebra (enabled by default if supported)]))
 663 AC_ARG_ENABLE([capabilities],
 664   AS_HELP_STRING([--disable-capabilities], [disable using POSIX capabilities]))
 665 AC_ARG_ENABLE([gcc_ultra_verbose],
 666   AS_HELP_STRING([--enable-gcc-ultra-verbose], [enable ultra verbose GCC warnings]))
 667 AC_ARG_ENABLE([backtrace],
 668   AS_HELP_STRING([--disable-backtrace], [disable crash backtraces (default autodetect)]))
 669 AC_ARG_ENABLE([time-check],
 670   AS_HELP_STRING([--disable-time-check], [disable slow thread warning messages]))
 671 AC_ARG_ENABLE([cpu-time],
 672   AS_HELP_STRING([--disable-cpu-time], [disable cpu usage data gathering]))
 673 AC_ARG_ENABLE([pcreposix],
 674   AS_HELP_STRING([--enable-pcreposix], [enable using PCRE Posix libs for regex functions]))
 675 AC_ARG_ENABLE([fpm],
 676   AS_HELP_STRING([--enable-fpm], [enable Forwarding Plane Manager support]))
 677 AC_ARG_ENABLE([pcep],
 678   AS_HELP_STRING([--enable-pcep], [enable PCEP support for pathd]))
 679 AC_ARG_ENABLE([werror],
 680   AS_HELP_STRING([--enable-werror], [enable -Werror (recommended for developers only)]))
 681 AC_ARG_ENABLE([cumulus],
 682   AS_HELP_STRING([--enable-cumulus], [enable Cumulus Switch Special Extensions]))
 683 AC_ARG_ENABLE([datacenter],
 684   AS_HELP_STRING([--enable-datacenter], [enable Compilation for Data Center Extensions]))
 685 AC_ARG_ENABLE([rr-semantics],
 686   AS_HELP_STRING([--disable-rr-semantics], [disable the v6 Route Replace semantics]))
 687 AC_ARG_ENABLE([protobuf],
 688   AS_HELP_STRING([--enable-protobuf], [Enable experimental protobuf support]))
 689 AC_ARG_ENABLE([oldvpn_commands],
 690   AS_HELP_STRING([--enable-oldvpn-commands], [Keep old vpn commands]))
 691 AC_ARG_ENABLE([rpki],
 692   AS_HELP_STRING([--enable-rpki], [enable RPKI prefix validation support]))
 693 AC_ARG_ENABLE([clippy-only],
 694   AS_HELP_STRING([--enable-clippy-only], [Only build clippy]))
 695 AC_ARG_ENABLE([numeric_version],
 696   AS_HELP_STRING([--enable-numeric-version], [Only numeric digits allowed in version (for Alpine)]))
 697 AC_ARG_ENABLE([gcov],
 698   AS_HELP_STRING([--enable-gcov], [Collect coverage information with gcov]))
 699 AC_ARG_ENABLE([clang_coverage],
 700   AS_HELP_STRING([--enable-clang-coverage], [Collect coverage information with Clang Coverage]))
 701 AC_ARG_ENABLE([bfdd],
 702   AS_HELP_STRING([--disable-bfdd], [do not build bfdd]))
 703 AC_ARG_ENABLE([address-sanitizer],
 704   AS_HELP_STRING([--enable-address-sanitizer], [enable AddressSanitizer support for detecting a wide variety of memory allocation and deallocation errors]))
 705 AC_ARG_ENABLE([thread-sanitizer],
 706   AS_HELP_STRING([--enable-thread-sanitizer], [enable ThreadSanitizer support for detecting data races]))
 707 AC_ARG_ENABLE([memory-sanitizer],
 708   AS_HELP_STRING([--enable-memory-sanitizer], [enable MemorySanitizer support for detecting uninitialized memory reads]))
 709 AC_ARG_ENABLE([undefined-sanitizer],
 710   AS_HELP_STRING([--enable-undefined-sanitizer], [enable UndefinedBehaviorSanitizer support for detecting undefined behavior]))
 711 AC_ARG_WITH([crypto],
 712   AS_HELP_STRING([--with-crypto=<internal|openssl>], [choose between different implementations of cryptographic functions(default value is --with-crypto=internal)]))
 713 AC_ARG_WITH([frr-format],
 714   AS_HELP_STRING([--with-frr-format[=<.../frr-format.so>]], [use frr-format GCC plugin]))
 715
 716 AC_ARG_ENABLE([version-build-config],
 717   AS_HELP_STRING([--disable-version-build-config], [do not include build configs in show version command]))
 718
 719 #if openssl, else use the internal
 720 AS_IF([test "$with_crypto" = "openssl"], [
 721 AC_CHECK_LIB([crypto], [EVP_DigestInit], [LIBS="$LIBS -lcrypto"], [], [])
 722 if test "$ac_cv_lib_crypto_EVP_DigestInit" = "no"; then
 723   AC_MSG_ERROR([build with openssl has been specified but openssl library was not found on your system])
 724 else
 725   AC_DEFINE([CRYPTO_OPENSSL], [1], [Compile with openssl support])
 726 fi
 727 ], [test "$with_crypto" = "internal" || test "$with_crypto" = "" ], [AC_DEFINE([CRYPTO_INTERNAL], [1], [Compile with internal cryptographic implementation])
 728 ], [AC_MSG_ERROR([Unknown value for --with-crypto])]
 729 )
 730
 731 AS_IF([test "$enable_clippy_only" != "yes"], [
 732 AC_CHECK_HEADERS([json-c/json.h])
 733 AC_CHECK_LIB([json-c], [json_object_get], [LIBS="$LIBS -ljson-c"], [], [-lm])
 734 if test "$ac_cv_lib_json_c_json_object_get" = "no"; then
 735   AC_CHECK_LIB([json], [json_object_get], [LIBS="$LIBS -ljson"])
 736   if test "$ac_cv_lib_json_json_object_get" = "no"; then
 737       AC_MSG_ERROR([libjson is needed to compile])
 738   fi
 739 fi
 740 ])
 741
 742 AC_ARG_ENABLE([dev_build],
 743     AS_HELP_STRING([--enable-dev-build], [build for development]))
 744
 745 AC_ARG_ENABLE([scripting],
 746     AS_HELP_STRING([--enable-scripting], [Build with scripting support]))
 747
 748 AC_ARG_ENABLE([netlink-debug],
 749   AS_HELP_STRING([--disable-netlink-debug], [pretty print netlink debug messages]))
 750
 751 if test "$enable_netlink_debug" != "no" ; then
 752   AC_DEFINE([NETLINK_DEBUG], [1], [Netlink extra debugging code])
 753 fi
 754
 755 AM_CONDITIONAL([NETLINK_DEBUG], [test "$enable_netlink_debug" != "no"])
 756
 757 if test "$enable_time_check" != "no" ; then
 758   if test "$enable_time_check" = "yes" -o "$enable_time_check" = "" ; then
 759     AC_DEFINE([CONSUMED_TIME_CHECK], [5000000], [Consumed Time Check])
 760   else
 761     AC_DEFINE_UNQUOTED([CONSUMED_TIME_CHECK], [$enable_time_check], [Consumed Time Check])
 762   fi
 763 fi
 764
 765 case "${enable_cpu_time}" in
 766   "no")
 767   AC_DEFINE([EXCLUDE_CPU_TIME], [1], [Exclude getrusage data gathering])
 768   ;;
 769   "*")
 770   ;;
 771 esac
 772
 773 if test "$enable_rr_semantics" != "no" ; then
 774   AC_DEFINE([HAVE_V6_RR_SEMANTICS], [1], [Compile in v6 Route Replacement Semantics])
 775 fi
 776
 777 if test "$enable_datacenter" = "yes" ; then
 778   AC_DEFINE([HAVE_DATACENTER], [1], [Compile extensions for a DataCenter])
 779   DFLT_NAME="datacenter"
 780 else
 781   DFLT_NAME="traditional"
 782 fi
 783
 784 if test "$enable_cumulus" = "yes" ; then
 785   AC_DEFINE([HAVE_CUMULUS], [1], [Compile Special Cumulus Code in])
 786 fi
 787
 788 AC_SUBST([DFLT_NAME])
 789 AC_DEFINE_UNQUOTED([DFLT_NAME], ["$DFLT_NAME"], [Name of the configuration default set])
 790
 791 if test "$enable_shell_access" = "yes"; then
 792    AC_DEFINE([HAVE_SHELL_ACCESS], [1], [Allow user to use ssh/telnet/bash, be aware this is considered insecure])
 793 fi
 794
 795 #
 796 # Python for clippy
 797 #
 798
 799 AS_IF([test "$host" = "$build"], [
 800   AC_CHECK_HEADER([gelf.h], [], [
 801     AC_MSG_ERROR([libelf headers are required for building clippy.  (Host only when cross-compiling.)])
 802   ])
 803   AC_CHECK_LIB([elf], [elf_memory], [], [
 804     AC_MSG_ERROR([libelf is required for building clippy.  (Host only when cross-compiling.)])
 805   ])
 806
 807   AC_CHECK_LIB([elf], [elf_getdata_rawchunk], [
 808     AC_DEFINE([HAVE_ELF_GETDATA_RAWCHUNK], [1], [Have elf_getdata_rawchunk()])
 809   ])
 810   AC_CHECK_LIB([elf], [gelf_getnote], [
 811     AC_DEFINE([HAVE_GELF_GETNOTE], [1], [Have gelf_getnote()])
 812   ])
 813
 814   FRR_PYTHON_DEV
 815 ], [
 816   FRR_PYTHON
 817 ])
 818
 819 FRR_PYTHON_MODULES([pytest])
 820
 821 if test "$enable_doc" != "no"; then
 822   FRR_PYTHON_MODULES([sphinx], , [
 823     if test "$enable_doc" = "yes"; then
 824       AC_MSG_ERROR([Documentation was explicitly requested with --enable-doc but sphinx is not available for $PYTHON. Please disable docs or install sphinx.])
 825     fi
 826   ])
 827 fi
 828 AM_CONDITIONAL([DOC], [test "$enable_doc" != "no" -a "$frr_py_mod_sphinx" != "false"])
 829 AM_CONDITIONAL([DOC_HTML], [test "$enable_doc_html" = "yes"])
 830
 831 FRR_PYTHON_MOD_EXEC([sphinx], [--version], [
 832   PYSPHINX="-m sphinx"
 833 ], [
 834   PYSPHINX="-c 'import sys; from sphinx import main; sys.exit(main(sys.argv))'"
 835 ])
 836 AC_SUBST([PYSPHINX])
 837
 838 #
 839 # Logic for old vpn commands support.
 840 #
 841 if test "$enable_oldvpn_commands" = "yes"; then
 842    AC_DEFINE([KEEP_OLD_VPN_COMMANDS], [1], [Define for compiling with old vpn commands])
 843 fi
 844
 845 #
 846 # End of logic for protobuf support.
 847 #
 848
 849 AC_MSG_CHECKING([if zebra should be configurable to send Route Advertisements])
 850 if test "$enable_rtadv" != "no"; then
 851   AC_MSG_RESULT([yes])
 852   AC_DEFINE([HAVE_RTADV], [1], [Enable IPv6 Routing Advertisement support])
 853 else
 854   AC_MSG_RESULT([no])
 855 fi
 856
 857 if test "$enable_user" = "no"; then
 858   enable_user=""
 859 else
 860   if test "$enable_user" = "yes" || test "$enable_user" = ""; then
 861     enable_user="frr"
 862   fi
 863   AC_DEFINE_UNQUOTED([FRR_USER], ["${enable_user}"], [frr User])
 864 fi
 865
 866 if test "$enable_group" = "no"; then
 867   enable_group=""
 868 else
 869   if test "$enable_group" = "yes" || test "$enable_group" = ""; then
 870     enable_group="frr"
 871   fi
 872   AC_DEFINE_UNQUOTED([FRR_GROUP], ["${enable_group}"], [frr Group])
 873 fi
 874
 875 if test "$enable_vty_group" = "yes" ; then
 876   AC_MSG_ERROR([--enable-vty-group requires a group as argument, not yes])
 877 elif test "$enable_vty_group" != ""; then
 878   if test "$enable_vty_group" != "no"; then
 879     AC_DEFINE_UNQUOTED([VTY_GROUP], ["${enable_vty_group}"], [VTY Sockets Group])
 880   fi
 881 fi
 882 AC_SUBST([enable_user])
 883 AC_SUBST([enable_group])
 884 AC_SUBST([enable_vty_group])
 885
 886 enable_configfile_mask=${enable_configfile_mask:-0600}
 887 AC_DEFINE_UNQUOTED([CONFIGFILE_MASK], [${enable_configfile_mask}], [Mask for config files])
 888 AC_SUBST([enable_configfile_mask])
 889
 890 enable_logfile_mask=${enable_logfile_mask:-0600}
 891 AC_DEFINE_UNQUOTED([LOGFILE_MASK], [${enable_logfile_mask}], [Mask for log files])
 892
 893 MPATH_NUM=16
 894
 895 case "${enable_multipath}" in
 896   0)
 897     MPATH_NUM=64
 898     ;;
 899   [[1-9]|[1-9][0-9]|[1-9][0-9][0-9]])
 900     MPATH_NUM="${enable_multipath}"
 901     ;;
 902   "")
 903     ;;
 904   *)
 905     AC_MSG_FAILURE([Please specify digit to enable multipath ARG])
 906     ;;
 907 esac
 908
 909 AC_DEFINE_UNQUOTED([MULTIPATH_NUM], [$MPATH_NUM], [Maximum number of paths for a route])
 910
 911 AC_DEFINE_UNQUOTED([VTYSH_PAGER], ["$VTYSH_PAGER"], [What pager to use])
 912
 913 dnl --------------------
 914 dnl Enable code coverage
 915 dnl --------------------
 916 AM_CONDITIONAL([HAVE_GCOV], [test "$enable_gcov" != "no"])
 917
 918 dnl ------------------------------------
 919 dnl Alpine only accepts numeric versions
 920 dnl ------------------------------------
 921 if test "$enable_numeric_version" != "" ; then
 922   VERSION="`echo ${VERSION} | tr -c -d '[[.0-9]]'`"
 923   PACKAGE_VERSION="`echo ${PACKAGE_VERSION} | tr -c -d '[[.0-9]]'`"
 924 fi
 925
 926 dnl -----------------------------------
 927 dnl Add extra version string to package
 928 dnl name, string and version fields.
 929 dnl -----------------------------------
 930 if test "$EXTRAVERSION" != "" ; then
 931   VERSION="${VERSION}${EXTRAVERSION}"
 932   PACKAGE_VERSION="${PACKAGE_VERSION}${EXTRAVERSION}"
 933   AC_SUBST(PACKAGE_EXTRAVERSION, ["${EXTRAVERSION}"])
 934   PACKAGE_STRING="${PACKAGE_STRING}${EXTRAVERSION}"
 935 fi
 936 AC_SUBST([EXTRAVERSION])
 937
 938 if test "$with_pkg_git_version" = "yes"; then
 939         if test -e "${srcdir}/.git"; then
 940                 AC_DEFINE([GIT_VERSION], [1], [include git version info])
 941         else    with_pkg_git_version="no"
 942                 AC_MSG_WARN([--with-pkg-git-version given, but this is not a git checkout])
 943         fi
 944 fi
 945 AM_CONDITIONAL([GIT_VERSION], [test "$with_pkg_git_version" = "yes"])
 946
 947 AC_CHECK_TOOL([OBJCOPY], [objcopy], [:])
 948 if test "$OBJCOPY" != ":"; then
 949   AC_CACHE_CHECK([for .interp value to use], [frr_cv_interp], [
 950     frr_cv_interp=""
 951     AC_LINK_IFELSE([AC_LANG_SOURCE([[int main() { return 0; }]])], [
 952       if $OBJCOPY -j.interp -Obinary conftest conftest.interp; then
 953         frr_cv_interp="`xargs -0 echo < conftest.interp`"
 954       fi
 955       test -f conftest.interp && rm conftest.interp
 956     ])
 957   ])
 958 fi
 959 if test -n "$frr_cv_interp"; then
 960   AC_DEFINE_UNQUOTED([INTERP], ["$frr_cv_interp"], [.interp value])
 961 fi
 962
 963 dnl -------------------------
 964 dnl Check other header files.
 965 dnl -------------------------
 966 AC_CHECK_HEADERS([stropts.h sys/ksym.h \
 967         linux/version.h asm/types.h endian.h sys/endian.h])
 968
 969 ac_stdatomic_ok=false
 970 AC_DEFINE([FRR_AUTOCONF_ATOMIC], [1], [did autoconf checks for atomic funcs])
 971 AC_CHECK_HEADER([stdatomic.h],[
 972
 973   AC_MSG_CHECKING([whether _Atomic qualifier works])
 974   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 975 #include <stdatomic.h>
 976 int main(int argc, char **argv) {
 977   _Atomic int i = 0;
 978   return i;
 979 }
 980 ]])], [
 981     AC_DEFINE([HAVE_STDATOMIC_H], [1], [found stdatomic.h])
 982     AC_MSG_RESULT([yes])
 983     ac_stdatomic_ok=true
 984   ], [
 985     AC_MSG_RESULT([no])
 986   ])
 987 ])
 988
 989 AS_IF([$ac_stdatomic_ok], [true], [
 990   AC_MSG_CHECKING([for __atomic_* builtins])
 991   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 992 int main(int argc, char **argv) {
 993   volatile int i = 1;
 994   __atomic_store_n (&i, 0, __ATOMIC_RELEASE);
 995   return __atomic_load_n (&i, __ATOMIC_ACQUIRE);
 996 }
 997 ]])], [
 998     AC_DEFINE([HAVE___ATOMIC], [1], [found __atomic builtins])
 999     AC_MSG_RESULT([yes])
1000   ], [
1001     AC_MSG_RESULT([no])
1002
1003     dnl FreeBSD 9 has a broken stdatomic.h where _Atomic doesn't work
1004     AC_MSG_CHECKING([for __sync_* builtins])
1005     AC_LINK_IFELSE([AC_LANG_SOURCE([[
1006 int main(int argc, char **argv) {
1007   volatile int i = 1;
1008   __sync_fetch_and_sub (&i, 1);
1009   return __sync_val_compare_and_swap (&i, 0, 1);
1010 }
1011 ]])], [
1012       AC_DEFINE([HAVE___SYNC], [1], [found __sync builtins])
1013       AC_MSG_RESULT([yes])
1014
1015       AC_MSG_CHECKING([for __sync_swap builtin])
1016       AC_LINK_IFELSE([AC_LANG_SOURCE([[
1017 int main(int argc, char **argv) {
1018   volatile int i = 1;
1019   return __sync_swap (&i, 2);
1020 }
1021 ]])], [
1022         AC_DEFINE([HAVE___SYNC_SWAP], 1, [found __sync_swap builtin])
1023         AC_MSG_RESULT([yes])
1024       ], [
1025         AC_MSG_RESULT([no])
1026       ])
1027
1028     ], [
1029       AC_MSG_RESULT([no])
1030       AC_MSG_FAILURE([stdatomic.h unavailable and $CC has neither __atomic nor __sync builtins])
1031     ])
1032   ])
1033 ])
1034
1035 needsync=true
1036
1037 AS_IF([$needsync], [
1038   dnl Linux
1039   AC_MSG_CHECKING([for Linux futex() support])
1040   AC_LINK_IFELSE([AC_LANG_PROGRAM([
1041 #ifndef _GNU_SOURCE
1042 #define _GNU_SOURCE
1043 #endif
1044 #include <unistd.h>
1045 #include <limits.h>
1046 #include <sys/time.h>
1047 #include <sys/syscall.h>
1048 #include <linux/futex.h>
1049
1050 int main(void);
1051 ],
1052 [
1053 {
1054   return syscall(SYS_futex, NULL, FUTEX_WAIT, 0, NULL, NULL, 0);
1055 }
1056 ])], [
1057     AC_MSG_RESULT([yes])
1058     AC_DEFINE(HAVE_SYNC_LINUX_FUTEX,,Have Linux futex support)
1059     needsync=false
1060   ], [
1061     AC_MSG_RESULT([no])
1062   ])
1063 ])
1064
1065 AS_IF([$needsync], [
1066   dnl FreeBSD
1067   AC_MSG_CHECKING([for FreeBSD _umtx_op() support])
1068   AC_LINK_IFELSE([AC_LANG_PROGRAM([
1069 #include <errno.h>
1070 #include <stdlib.h>
1071 #include <sys/types.h>
1072 #include <sys/umtx.h>
1073 int main(void);
1074 ],
1075 [
1076 {
1077   return _umtx_op(NULL, UMTX_OP_WAIT_UINT, 0, NULL, NULL);
1078 }
1079 ])], [
1080     AC_MSG_RESULT([yes])
1081     AC_DEFINE(HAVE_SYNC_UMTX_OP,,Have FreeBSD _umtx_op() support)
1082     needsync=false
1083   ], [
1084     AC_MSG_RESULT([no])
1085   ])
1086 ])
1087
1088 AS_IF([$needsync], [
1089   dnl OpenBSD patch (not upstream at the time of writing this)
1090   dnl https://marc.info/?l=openbsd-tech&m=147299508409549&w=2
1091   AC_MSG_CHECKING([for OpenBSD futex() support])
1092   AC_LINK_IFELSE([AC_LANG_PROGRAM([
1093 #include <sys/futex.h>
1094 int main(void);
1095 ],
1096 [
1097 {
1098   return futex(NULL, FUTEX_WAIT, 0, NULL, NULL, 0);
1099 }
1100 ])], [
1101     AC_MSG_RESULT([yes])
1102     AC_DEFINE(HAVE_SYNC_OPENBSD_FUTEX,,Have OpenBSD futex support)
1103     needsync=false
1104   ], [
1105     AC_MSG_RESULT([no])
1106   ])
1107 ])
1108
1109 dnl Utility macro to avoid retyping includes all the time
1110 m4_define([FRR_INCLUDES],
1111 [#ifdef SUNOS_5
1112 #define _POSIX_C_SOURCE 200809L
1113 #define __EXTENSIONS__
1114 #endif
1115 #include <stdio.h>
1116 #include <stdlib.h>
1117 #include <stddef.h>
1118 #include <sys/types.h>
1119 /* sys/conf.h depends on param.h on FBSD at least */
1120 #include <sys/param.h>
1121 /* Required for MAXSIG */
1122 #include <signal.h>
1123 #include <sys/socket.h>
1124 #ifdef __APPLE__
1125 # define __APPLE_USE_RFC_3542
1126 #endif
1127 #include <netinet/in.h>
1128 #include <sys/time.h>
1129 #include <time.h>
1130 #include <net/if.h>
1131 ])dnl
1132
1133 dnl Same applies for HAVE_NET_IF_VAR_H, which HAVE_NETINET6_ND6_H and
1134 dnl HAVE_NETINET_IN_VAR_H depend upon. But if_var.h depends on if.h, hence
1135 dnl an additional round for it.
1136
1137 AC_CHECK_HEADERS([net/if_var.h], [], [], [FRR_INCLUDES])
1138
1139 m4_define([FRR_INCLUDES],
1140 FRR_INCLUDES
1141 [#ifdef HAVE_NET_IF_VAR_H
1142 # include <net/if_var.h>
1143 #endif
1144 ])dnl
1145
1146 AC_CHECK_HEADERS([netinet/in_var.h \
1147         net/if_dl.h net/netopt.h \
1148         inet/nd.h netinet/ip_icmp.h \
1149         sys/sysctl.h sys/sockio.h sys/conf.h],
1150         [], [], [FRR_INCLUDES])
1151
1152 AC_CHECK_HEADERS([ucontext.h], [], [],
1153 [#ifndef __USE_GNU
1154 #define __USE_GNU
1155 #endif /* __USE_GNU */
1156 FRR_INCLUDES
1157 ])
1158
1159 m4_define([UCONTEXT_INCLUDES],
1160 [#include <ucontext.h>])dnl
1161
1162 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.uc_regs],
1163   [], [], [UCONTEXT_INCLUDES])
1164 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs],
1165   [AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs.nip],
1166    [], [], [UCONTEXT_INCLUDES])],
1167   [], [UCONTEXT_INCLUDES])
1168 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.gregs],
1169   [], [], [UCONTEXT_INCLUDES])
1170
1171 m4_define([FRR_INCLUDES],
1172 FRR_INCLUDES
1173 [
1174 #include <sys/un.h>
1175 #include <netinet/in_systm.h>
1176 #ifdef HAVE_NETINET_IN_VAR_H
1177 # include <netinet/in_var.h>
1178 #endif
1179 #ifdef HAVE_NET_IF_DL_H
1180 # include <net/if_dl.h>
1181 #endif
1182 #ifdef HAVE_NET_NETOPT_H
1183 # include <net/netopt.h>
1184 #endif
1185 #include <net/route.h>
1186 #ifdef HAVE_INET_ND_H
1187 # include <inet/nd.h>
1188 #endif
1189 #include <arpa/inet.h>
1190 /* Required for IDRP */
1191 #ifdef HAVE_NETINET_IP_ICMP_H
1192 # include <netinet/ip_icmp.h>
1193 #endif
1194 ])dnl
1195
1196 dnl V6 headers are checked below, after we check for v6
1197
1198 is_linux=false
1199
1200 AC_MSG_CHECKING([which operating system interface to use])
1201 case "$host_os" in
1202   sunos* | solaris2*)
1203     AC_MSG_FAILURE([Solaris support has been removed please see versions prior or equal to 7.5])
1204     ;;
1205   linux*)
1206     AC_MSG_RESULT([Linux])
1207
1208     AC_DEFINE([GNU_LINUX], [1], [GNU Linux])
1209     AC_DEFINE([HAVE_NETLINK], [1], [netlink])
1210     AC_DEFINE([LINUX_IPV6], [1], [Linux IPv6 stack])
1211
1212     dnl Linux has a compilation problem with mixing
1213     dnl netinet/in.h and linux/in6.h they are not
1214     dnl compatible.  There has been discussion on
1215     dnl how to fix it but no real progress on implementation
1216     dnl when they fix it, remove this
1217     AC_DEFINE([IPV6_MINHOPCOUNT], [73], [Linux ipv6 Min Hop Count])
1218
1219     is_linux=true
1220     ;;
1221   openbsd*)
1222     AC_MSG_RESULT([OpenBSD])
1223
1224     AC_DEFINE([OPEN_BSD], [1], [OpenBSD])
1225     AC_DEFINE([KAME], [1], [KAME IPv6])
1226     AC_DEFINE([BSD_V6_SYSCTL], [1], [BSD v6 sysctl to turn on and off forwarding])
1227     ;;
1228   *)
1229     AC_MSG_RESULT([BSD])
1230
1231     AC_DEFINE([HAVE_NET_RT_IFLIST], [1], [NET_RT_IFLIST])
1232     AC_DEFINE([KAME], [1], [KAME IPv6])
1233     AC_DEFINE([BSD_V6_SYSCTL], [1], [BSD v6 sysctl to turn on and off forwarding])
1234     ;;
1235 esac
1236 AM_CONDITIONAL([LINUX], [${is_linux}])
1237
1238 AC_SYS_LARGEFILE
1239
1240 dnl ------------------------
1241 dnl Integrated REALMS option
1242 dnl ------------------------
1243 if test "$enable_realms" = "yes"; then
1244     case "$host_os" in
1245       linux*)
1246        AC_DEFINE([SUPPORT_REALMS], [1], [Realms support])
1247        ;;
1248       *)
1249        echo "Sorry, only Linux has REALMS support"
1250        exit 1
1251        ;;
1252     esac
1253 fi
1254
1255 dnl ---------------
1256 dnl other functions
1257 dnl ---------------
1258 AC_CHECK_FUNCS([ \
1259         strlcat strlcpy \
1260         getgrouplist \
1261         openat \
1262         unlinkat \
1263         posix_fallocate \
1264         ])
1265
1266 dnl ##########################################################################
1267 dnl LARGE if block spans a lot of "configure"!
1268 if test "$enable_clippy_only" != "yes"; then
1269 dnl ##########################################################################
1270
1271 #
1272 # Logic for protobuf support.
1273 #
1274 PROTO3=false
1275 if test "$enable_protobuf" = "yes"; then
1276   # Check for protoc & protoc-c
1277
1278   # protoc is not required, it's only for a "be nice" helper target
1279   AC_CHECK_PROGS([PROTOC], [protoc], [/bin/false])
1280
1281   AC_CHECK_PROGS([PROTOC_C], [protoc-c], [/bin/false])
1282   if test "$PROTOC_C" = "/bin/false"; then
1283     AC_MSG_FAILURE([protobuf requested but protoc-c not found.  Install protobuf-c.])
1284   fi
1285
1286   PKG_CHECK_MODULES([PROTOBUF_C], [libprotobuf-c >= 0.14],, [
1287     AC_MSG_FAILURE([protobuf requested but libprotobuf-c not found.  Install protobuf-c.])
1288   ])
1289
1290   PROTO3=true
1291   AC_CHECK_HEADER([google/protobuf-c/protobuf-c.h],
1292                   [AC_CHECK_DECLS(PROTOBUF_C_LABEL_NONE,
1293                                   AC_DEFINE([HAVE_PROTOBUF_VERSION_3],
1294                                             [1], [Have Protobuf version 3]),
1295                                   [PROTO3=false],
1296                                   [#include <google/protobuf-c/protobuf-c.h>])],
1297                   [PROTO3=false && AC_MSG_FAILURE([protobuf requested but protobuf-c.h not found.  Install protobuf-c.])])
1298
1299   AC_DEFINE([HAVE_PROTOBUF], [1], [protobuf])
1300 fi
1301
1302
1303 dnl ---------------------
1304 dnl Integrated VTY option
1305 dnl ---------------------
1306 case "${enable_vtysh}" in
1307 "no")
1308   VTYSH="";;
1309 *)
1310   VTYSH="vtysh";
1311   AC_DEFINE([VTYSH], [1], [VTY shell])
1312
1313   prev_libs="$LIBS"
1314   AC_CHECK_LIB([readline], [main], [
1315     LIBREADLINE="-lreadline"
1316   ], [
1317     dnl readline failed - it might be incorrectly linked and missing its
1318     dnl termcap/tinfo/curses dependency.  see if we can fix that...
1319     AC_SEARCH_LIBS([tputs], [termcap tinfo curses ncurses], [
1320       LIBREADLINE="$ac_cv_search_tputs"
1321     ], [
1322       AC_MSG_ERROR([libreadline (needed for vtysh) not found and/or missing dependencies])
1323     ])
1324
1325     dnl re-try with the lib we found above
1326     unset ac_cv_lib_readline_main
1327     AC_CHECK_LIB([readline], [main], [
1328       LIBREADLINE="-lreadline $LIBREADLINE"
1329     ], [
1330       AC_MSG_ERROR([libreadline (needed for vtysh) not found and/or missing dependencies])
1331     ], [$LIBREADLINE])
1332   ], [])
1333   LIBS="$prev_libs"
1334
1335   AC_CHECK_HEADER([readline/history.h])
1336   if test "$ac_cv_header_readline_history_h" = "no"; then
1337     AC_MSG_ERROR([readline is too old to have readline/history.h, please update to the latest readline library.])
1338   fi
1339   AC_CHECK_LIB([readline], [rl_completion_matches], [true], [], [$LIBREADLINE])
1340   if test "$ac_cv_lib_readline_rl_completion_matches" = "no"; then
1341     AC_DEFINE([rl_completion_matches], [completion_matches], [Old readline])
1342   fi
1343   AC_CHECK_LIB([readline], [append_history], [frr_cv_append_history=yes], [frr_cv_append_history=no], [$LIBREADLINE])
1344   if test "$frr_cv_append_history" = "yes"; then
1345     AC_DEFINE([HAVE_APPEND_HISTORY], [1], [Have history.h append_history])
1346   fi
1347   ;;
1348 esac
1349 AC_SUBST([LIBREADLINE])
1350
1351 dnl ----------
1352 dnl PAM module
1353 dnl
1354 dnl FRR detects the PAM library it is built against by checking for a
1355 dnl functional pam_misc.h (Linux-PAM) or openpam.h (OpenPAM) header. pam_misc.h
1356 dnl is known to #include pam_appl.h, the standard header of a PAM library, and
1357 dnl openpam.h doesn't do that, although depends on the header too. Hence a
1358 dnl little assistance to AC_CHECK_HEADER is necessary for the proper detection
1359 dnl of OpenPAM.
1360 dnl ----------
1361 if test "$with_libpam" = "yes"; then
1362   AC_CHECK_HEADER([security/pam_misc.h],
1363     [AC_DEFINE([HAVE_PAM_MISC_H], [1], [Have pam_misc.h])
1364      AC_DEFINE([PAM_CONV_FUNC], [misc_conv], [Have misc_conv])
1365      pam_conv_func="misc_conv"
1366     ],
1367     [], FRR_INCLUDES)
1368   AC_CHECK_HEADER([security/openpam.h],
1369     [AC_DEFINE([HAVE_OPENPAM_H], [1], [Have openpam.h])
1370      AC_DEFINE([PAM_CONV_FUNC], [openpam_ttyconv], [Have openpam_ttyconv])
1371      pam_conv_func="openpam_ttyconv"
1372     ],
1373     [], FRR_INCLUDES[#include <security/pam_appl.h>])
1374   if test -z "$ac_cv_header_security_pam_misc_h$ac_cv_header_security_openpam_h" ; then
1375     AC_MSG_WARN([*** pam support will not be built ***])
1376     with_libpam="no"
1377   fi
1378 fi
1379
1380 if test "$with_libpam" = "yes"; then
1381 dnl took this test from proftpds configure.in and suited to our needs
1382 dnl -------------------------------------------------------------------------
1383 dnl
1384 dnl This next check looks funky due to a linker problem with some versions
1385 dnl of the PAM library.  Prior to 0.72 release, the Linux PAM shared library
1386 dnl omitted requiring libdl linking information. PAM-0.72 or better ships
1387 dnl with RedHat 6.2 and Debian 2.2 or better.
1388 AC_CHECK_LIB([pam], [pam_start],
1389   [AC_CHECK_LIB([pam], [$pam_conv_func],
1390     [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1391      LIBPAM="-lpam"],
1392     [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1393      LIBPAM="-lpam -lpam_misc"]
1394     )
1395   ],
1396
1397   [AC_CHECK_LIB([pam], [pam_end],
1398     [AC_CHECK_LIB([pam], [$pam_conv_func],
1399       [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1400        LIBPAM="-lpam -ldl"],
1401       [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1402        LIBPAM="-lpam -ldl -lpam_misc"]
1403      )
1404   ],AC_MSG_WARN([*** pam support will not be built ***]),
1405   [-ldl])
1406   ]
1407 )
1408 fi
1409 AC_SUBST([LIBPAM])
1410
1411 dnl -------------------------------
1412 dnl bgpd needs pow() and hence libm
1413 dnl -------------------------------
1414 TMPLIBS="$LIBS"
1415 LIBS=""
1416 AC_SEARCH_LIBS([pow], [m], [
1417   LIBM="$LIBS"
1418 ], [
1419   AC_MSG_WARN([Unable to find working pow function - bgpd may not link])
1420 ])
1421 LIBS="$TMPLIBS"
1422 AC_SUBST([LIBM])
1423
1424 AC_CHECK_FUNCS([ppoll], [
1425   AC_DEFINE([HAVE_PPOLL], [1], [have Linux/BSD ppoll()])
1426 ])
1427 AC_CHECK_FUNCS([pollts], [
1428   AC_DEFINE([HAVE_POLLTS], [1], [have NetBSD pollts()])
1429 ])
1430
1431 AC_CHECK_HEADER([asm-generic/unistd.h],
1432                 [AC_CHECK_DECL(__NR_setns,
1433                                AC_DEFINE([HAVE_NETNS], [1], [Have netns]),,
1434                                FRR_INCLUDES [#include <asm-generic/unistd.h>
1435                                ])
1436                  AC_CHECK_FUNCS([setns])]
1437                )
1438
1439 dnl --------------------------
1440 dnl Determine IS-IS I/O method
1441 dnl --------------------------
1442 AC_DEFINE([ISIS_METHOD_PFPACKET], [1], [constant value for isis method pfpacket])
1443 AC_DEFINE([ISIS_METHOD_DLPI], [2], [constant value for isis method dlpi])
1444 AC_DEFINE([ISIS_METHOD_BPF], [3], [constant value for isis method bpf])
1445 AC_CHECK_HEADER([net/bpf.h])
1446 AC_CHECK_HEADER([sys/dlpi.h])
1447 AC_MSG_CHECKING([zebra IS-IS I/O method])
1448
1449 case "$host_os" in
1450   linux*)
1451     AC_MSG_RESULT([pfpacket])
1452     ISIS_METHOD_MACRO="ISIS_METHOD_PFPACKET"
1453     ;;
1454   *)
1455     if test "$ac_cv_header_net_bpf_h" = "no"; then
1456       if test "$ac_cv_header_sys_dlpi_h" = "no"; then
1457         AC_MSG_RESULT([none])
1458         if test "$enable_isisd" = "yes" -o "$enable_fabricd" = "yes"; then
1459           AC_MSG_FAILURE([IS-IS support requested but no packet backend found])
1460         fi
1461         AC_MSG_WARN([*** IS-IS support will not be built ***])
1462         enable_isisd="no"
1463         enable_fabricd="no"
1464       else
1465         AC_MSG_RESULT([DLPI])
1466       fi
1467       ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1468     else
1469       AC_MSG_RESULT([BPF])
1470       ISIS_METHOD_MACRO="ISIS_METHOD_BPF"
1471     fi
1472     ;;
1473 esac
1474 AC_DEFINE_UNQUOTED([ISIS_METHOD], [$ISIS_METHOD_MACRO], [selected method for isis, == one of the constants])
1475
1476 dnl ---------------------------------------------------------------
1477 dnl figure out how to specify an interface in multicast sockets API
1478 dnl ---------------------------------------------------------------
1479 AC_CHECK_MEMBERS([struct ip_mreqn.imr_ifindex], [], [], FRR_INCLUDES)
1480
1481 AC_CHECK_HEADERS([linux/mroute.h], [], [],[
1482         #include <sys/socket.h>
1483         #include <netinet/in.h>
1484         #define _LINUX_IN_H             /* For Linux <= 2.6.25 */
1485         #include <linux/types.h>
1486 ])
1487
1488 m4_define([FRR_INCLUDES],
1489 FRR_INCLUDES
1490 [#ifdef HAVE_LINUX_MROUTE_H
1491 # include <linux/mroute.h>
1492 #endif
1493 ])dnl
1494
1495 AC_CHECK_HEADERS([netinet/ip_mroute.h], [], [],[
1496         #include <sys/socket.h>
1497         #include <sys/types.h>
1498         #include <netinet/in.h>
1499         #include <net/route.h>
1500 ])
1501
1502 m4_define([FRR_INCLUDES],
1503 FRR_INCLUDES
1504 [#ifdef HAVE_NETINET_IP_MROUTE_H
1505 # include <netinet/ip_mroute.h>
1506 #endif
1507 ])dnl
1508
1509 AC_MSG_CHECKING([for RFC3678 protocol-independed API])
1510 AC_COMPILE_IFELSE(
1511 [ AC_LANG_PROGRAM([[
1512       #include <sys/types.h>
1513       #include <netinet/in.h>
1514   ]], [[
1515       struct group_req gr;
1516       int sock;
1517       setsockopt(sock, IPPROTO_IP, MCAST_JOIN_GROUP, (void*)&gr, sizeof(gr));
1518   ]])
1519 ],[
1520   AC_MSG_RESULT([yes])
1521   AC_DEFINE([HAVE_RFC3678], [1], [Have RFC3678 protocol-independed API])
1522 ],[
1523   AC_MSG_RESULT(no)
1524 ])
1525
1526 dnl ---------------------------------------------------------------
1527 dnl figure out how to check link-state
1528 dnl ---------------------------------------------------------------
1529 AC_CHECK_HEADER([net/if_media.h],
1530   [m4_define([LINK_DETECT_INCLUDES],
1531     FRR_INCLUDES
1532     [#include <net/if_media.h>
1533   ])
1534   AC_CHECK_MEMBERS([struct ifmediareq.ifm_status],
1535     AC_DEFINE([HAVE_BSD_LINK_DETECT], [1], [BSD link-detect]),
1536     [], LINK_DETECT_INCLUDES)],
1537   [],
1538   FRR_INCLUDES)
1539
1540 dnl ---------------------------------------------------------------
1541 dnl Additional, newer way to check link-state using ifi_link_state.
1542 dnl Not available in all BSD's when ifmediareq available
1543 dnl ---------------------------------------------------------------
1544 AC_CHECK_MEMBERS([struct if_data.ifi_link_state],
1545   AC_DEFINE([HAVE_BSD_IFI_LINK_STATE], [1], [BSD ifi_link_state available]),
1546   [], FRR_INCLUDES)
1547
1548 dnl ------------------------
1549 dnl TCP_MD5SIG socket option
1550 dnl ------------------------
1551
1552 AC_CHECK_HEADER([netinet/tcp.h],
1553    [m4_define([MD5_INCLUDES],
1554       FRR_INCLUDES
1555       [#include <netinet/tcp.h>
1556     ])
1557     AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)],
1558    [],
1559    FRR_INCLUDES)
1560 if test "$ac_cv_have_decl_TCP_MD5SIG" = "no"; then
1561   AC_CHECK_HEADER([linux/tcp.h],
1562        [m4_define([MD5_INCLUDES],
1563           FRR_INCLUDES
1564           [#include <linux/tcp.h>
1565         ])
1566        AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)])
1567 fi
1568
1569 AC_CHECK_LIB([crypt], [crypt], [],
1570                     [AC_CHECK_LIB([crypto], [DES_crypt])])
1571 AC_CHECK_LIB([resolv], [res_init])
1572
1573 dnl ---------------------------
1574 dnl check system has PCRE regexp
1575 dnl ---------------------------
1576 if test "$enable_pcreposix" = "yes"; then
1577   AC_CHECK_LIB([pcreposix], [regexec], [], [
1578     AC_MSG_ERROR([--enable-pcreposix given but unable to find libpcreposix])
1579   ])
1580 fi
1581 AC_SUBST([HAVE_LIBPCREPOSIX])
1582
1583 dnl ##########################################################################
1584 dnl test "$enable_clippy_only" != "yes"
1585 fi
1586 dnl END OF LARGE if block
1587 dnl ##########################################################################
1588
1589 dnl ------------------
1590 dnl check C-Ares library
1591 dnl ------------------
1592 PKG_CHECK_MODULES([CARES], [libcares], [
1593   c_ares_found=true
1594 ],[
1595   c_ares_found=false
1596 ])
1597 AM_CONDITIONAL([CARES], [$c_ares_found])
1598
1599
1600 dnl ----------------------------------------------------------------------------
1601 dnl figure out if domainname is available in the utsname struct (GNU extension).
1602 dnl ----------------------------------------------------------------------------
1603 AC_CHECK_MEMBERS([struct utsname.domainname], [], [], [#include <sys/utsname.h>])
1604
1605 dnl ------------------
1606 dnl IPv6 header checks
1607 dnl ------------------
1608 AC_CHECK_HEADERS([netinet6/in6.h netinet/in6_var.h \
1609         netinet6/in6_var.h netinet6/nd6.h], [], [],
1610         FRR_INCLUDES)
1611
1612 m4_define([FRR_INCLUDES],dnl
1613 FRR_INCLUDES
1614 [#ifdef HAVE_NETINET6_IN6_H
1615 #include <netinet6/in6.h>
1616 #endif
1617 #ifdef HAVE_NETINET_IN6_VAR_H
1618 #include <netinet/in6_var.h>
1619 #endif
1620 #include <netinet/icmp6.h>
1621 #ifdef HAVE_NETINET6_IN6_VAR_H
1622 # include <netinet6/in6_var.h>
1623 #endif
1624 #ifdef HAVE_NETINET6_ND6_H
1625 # include <netinet6/nd6.h>
1626 #endif
1627 ])dnl
1628
1629 dnl --------------------
1630 dnl Daemon disable check
1631 dnl --------------------
1632
1633 AS_IF([test "$enable_bgpd" != "no"], [
1634   AC_DEFINE([HAVE_BGPD], [1], [bgpd])
1635 ])
1636
1637 AS_IF([test "$enable_ripd" != "no"], [
1638   AC_DEFINE([HAVE_RIPD], [1], [ripd])
1639 ])
1640
1641 AS_IF([test "$enable_ripngd" != "no"], [
1642   AC_DEFINE([HAVE_RIPNGD], [1], [ripngd])
1643 ])
1644
1645 AS_IF([test "$enable_ospfd" != "no"], [
1646   AC_DEFINE([HAVE_OSPFD], [1], [ospfd])
1647 ])
1648
1649 AS_IF([test "$enable_ospf6d" != "no"], [
1650   AC_DEFINE([HAVE_OSPF6D], [1], [ospf6d])
1651 ])
1652
1653 AS_IF([test "$enable_ldpd" != "no"], [
1654   AC_DEFINE([HAVE_LDPD], [1], [ldpd])
1655 ])
1656
1657 AS_IF([test "$enable_nhrpd" != "no"], [
1658   AC_DEFINE([HAVE_NHRPD], [1], [nhrpd])
1659 ])
1660
1661 AS_IF([test "$enable_eigrpd" != "no"], [
1662   AC_DEFINE([HAVE_EIGRPD], [1], [eigrpd])
1663 ])
1664
1665 AS_IF([test "$enable_babeld" != "no"], [
1666   AC_DEFINE([HAVE_BABELD], [1], [babeld])
1667 ])
1668
1669 AS_IF([test "$enable_isisd" != "no"], [
1670   AC_DEFINE([HAVE_ISISD], [1], [isisd])
1671 ])
1672
1673 AS_IF([test "$enable_pimd" != "no"], [
1674   AC_DEFINE([HAVE_PIMD], [1], [pimd])
1675 ])
1676
1677 AS_IF([test "$enable_pbrd" != "no"], [
1678   AC_DEFINE([HAVE_PBRD], [1], [pbrd])
1679 ])
1680
1681 AS_IF([test "$enable_sharpd" = "yes"], [
1682   AC_DEFINE([HAVE_SHARPD], [1], [sharpd])
1683 ])
1684
1685 AS_IF([test "$enable_staticd" != "no"], [
1686   AC_DEFINE([HAVE_STATICD], [1], [staticd])
1687 ])
1688
1689 AS_IF([test "$enable_fabricd" != "no"], [
1690   AC_DEFINE([HAVE_FABRICD], [1], [fabricd])
1691 ])
1692
1693 AS_IF([test "$enable_vrrpd" != "no"], [
1694   AC_DEFINE([HAVE_VRRPD], [1], [vrrpd])
1695 ])
1696
1697 if test "$enable_bfdd" = "no"; then
1698   AC_DEFINE([HAVE_BFDD], [0], [bfdd])
1699   BFDD=""
1700 else
1701   AC_DEFINE([HAVE_BFDD], [1], [bfdd])
1702   BFDD="bfdd"
1703
1704   case $host_os in
1705     linux*)
1706       AC_DEFINE([BFD_LINUX], [1], [bfdd])
1707       ;;
1708
1709     *)
1710       AC_DEFINE([BFD_BSD], [1], [bfdd])
1711       ;;
1712   esac
1713 fi
1714
1715 AS_IF([test "$enable_pathd" != "no"], [
1716   AC_DEFINE([HAVE_PATHD], [1], [pathd])
1717   AC_DEFINE([HAVE_PATHD_PCEP], [1], [pathd-pcep])
1718 ])
1719
1720
1721 if test "$ac_cv_lib_json_c_json_object_get" = "no" -a "$BFDD" = "bfdd"; then
1722   AC_MSG_ERROR(["you must use json-c library to use bfdd"])
1723 fi
1724
1725 NHRPD=""
1726 case "$host_os" in
1727   linux*)
1728     case "${enable_nhrpd}" in
1729       no)
1730         ;;
1731       yes)
1732         if test "$enable_clippy_only" != "yes"; then
1733         if test "$c_ares_found" != "true" ; then
1734           AC_MSG_ERROR([nhrpd requires libcares.  Please install c-ares and its -dev headers.])
1735         fi
1736         fi
1737         NHRPD="nhrpd"
1738         ;;
1739       *)
1740         if test "$c_ares_found" = "true" ; then
1741           NHRPD="nhrpd"
1742         fi
1743         ;;
1744     esac
1745     ;;
1746   *)
1747     if test "$enable_nhrpd" = "yes"; then
1748       AC_MSG_ERROR([nhrpd requires kernel APIs that are only present on Linux.])
1749     fi
1750     ;;
1751 esac
1752
1753 if test "$enable_watchfrr" = "no";then
1754   WATCHFRR=""
1755 else
1756   WATCHFRR="watchfrr"
1757 fi
1758
1759 OSPFCLIENT=""
1760 if test "$enable_ospfapi" != "no";then
1761     AC_DEFINE([SUPPORT_OSPF_API], [1], [OSPFAPI])
1762
1763   if test "$enable_ospfclient" != "no";then
1764       OSPFCLIENT="ospfclient"
1765   fi
1766 fi
1767
1768 if test "$enable_bgp_announce" = "no";then
1769   AC_DEFINE([DISABLE_BGP_ANNOUNCE], [1], [Disable BGP installation to zebra])
1770 else
1771   AC_DEFINE([DISABLE_BGP_ANNOUNCE], [0], [Disable BGP installation to zebra])
1772 fi
1773
1774 if test "$enable_bgp_vnc" != "no";then
1775   AC_DEFINE([ENABLE_BGP_VNC], [1], [Enable BGP VNC support])
1776 fi
1777
1778 bgpd_bmp=false
1779 case "${enable_bmp}" in
1780   no)
1781     ;;
1782   yes)
1783     if test "$c_ares_found" != "true" ; then
1784       AC_MSG_ERROR([BMP support requires libcares.  Please install c-ares and its -dev headers.])
1785     fi
1786     bgpd_bmp=true
1787     ;;
1788   *)
1789     if test "$c_ares_found" = "true" ; then
1790       bgpd_bmp=true
1791     fi
1792     ;;
1793 esac
1794
1795 if test "$enable_version_build_config" != "no";then
1796   AC_DEFINE([ENABLE_VERSION_BUILD_CONFIG], [1], [Report build configs in show version])
1797 fi
1798
1799 dnl ##########################################################################
1800 dnl LARGE if block
1801 if test "$enable_clippy_only" != "yes"; then
1802 dnl ##########################################################################
1803
1804 dnl ------------------
1805 dnl check Net-SNMP library
1806 dnl ------------------
1807 if test "$enable_snmp" != "" -a "$enable_snmp" != "no"; then
1808    AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], [no])
1809    if test "$NETSNMP_CONFIG" = "no"; then
1810       AC_MSG_ERROR([--enable-snmp given but unable to find net-snmp-config])
1811    fi
1812    SNMP_LIBS="`${NETSNMP_CONFIG} --agent-libs`"
1813    SNMP_CFLAGS="`${NETSNMP_CONFIG} --base-cflags`"
1814    # net-snmp lists all of its own dependencies.  we absolutely do not want that
1815    # among other things we avoid a GPL vs. OpenSSL license conflict here
1816    for removelib in crypto ssl sensors pci wrap; do
1817      SNMP_LIBS="`echo $SNMP_LIBS | sed -e 's/\(^\|\s\)-l'$removelib'\b/ /g' -e 's/\(^\|\s\)\([^\s]*\/\)\?lib'$removelib'\.[^\s]\+\b/ /g'`"
1818    done
1819    AC_MSG_CHECKING([whether we can link to Net-SNMP])
1820    AC_LINK_IFELSE_FLAGS([$SNMP_CFLAGS], [$SNMP_LIBS], [AC_LANG_PROGRAM([
1821 int main(void);
1822 ],
1823 [
1824 {
1825   return 0;
1826 }
1827 ])], [
1828      AC_MSG_RESULT([no])
1829      AC_MSG_ERROR([--enable-snmp given but not usable])])
1830    case "${enable_snmp}" in
1831      yes)
1832       SNMP_METHOD=agentx
1833       ;;
1834      agentx)
1835       SNMP_METHOD="${enable_snmp}"
1836       ;;
1837      *)
1838       AC_MSG_ERROR([--enable-snmp given with an unknown method (${enable_snmp}). Use yes or agentx])
1839       ;;
1840    esac
1841    AH_TEMPLATE([SNMP_AGENTX], [Use SNMP AgentX to interface with snmpd])
1842    AC_DEFINE_UNQUOTED(AS_TR_CPP(SNMP_${SNMP_METHOD}),,[SNMP method to interface with snmpd])
1843 fi
1844 AC_SUBST([SNMP_LIBS])
1845 AC_SUBST([SNMP_CFLAGS])
1846
1847 dnl ---------------
1848 dnl libyang
1849 dnl ---------------
1850 PKG_CHECK_MODULES([LIBYANG], [libyang >= 2.0.0], , [
1851   AC_MSG_ERROR([libyang (>= 2.0.0) was not found on your system.])
1852 ])
1853 ac_cflags_save="$CFLAGS"
1854 CFLAGS="$CFLAGS $LIBYANG_CFLAGS"
1855 AC_CHECK_MEMBER([struct lyd_node.priv], [], [
1856   AC_MSG_ERROR([m4_normalize([
1857     libyang needs to be compiled with ENABLE_LYD_PRIV=ON.
1858     Instructions for this are included in the build documentation for your platform at http://docs.frrouting.org/projects/dev-guide/en/latest/building.html])
1859   ])
1860 ], [[#include <libyang/libyang.h>]])
1861 CFLAGS="$ac_cflags_save"
1862
1863 dnl ---------------
1864 dnl configuration rollbacks
1865 dnl ---------------
1866 SQLITE3=false
1867 if test "$enable_config_rollbacks" = "yes"; then
1868   PKG_CHECK_MODULES([SQLITE3], [sqlite3], [
1869     AC_DEFINE([HAVE_CONFIG_ROLLBACKS], [1], [Enable configuration rollbacks])
1870     AC_DEFINE([HAVE_SQLITE3], [1], [Enable sqlite3 database])
1871     SQLITE3=true
1872   ], [
1873     AC_MSG_ERROR([--enable-config-rollbacks given but sqlite3 was not found on your system.])
1874   ])
1875 fi
1876
1877 dnl ---------------
1878 dnl confd
1879 dnl ---------------
1880 if test "$enable_confd" != "" -a "$enable_confd" != "no"; then
1881    AC_CHECK_PROG([CONFD], [confd], [confd], [/bin/false], "${enable_confd}/bin")
1882    if test "$CONFD" = "/bin/false"; then
1883       AC_MSG_ERROR([confd was not found on your system.])]
1884    fi
1885    CONFD_CFLAGS="-I${enable_confd}/include -L${enable_confd}/lib"
1886    AC_SUBST([CONFD_CFLAGS])
1887    CONFD_LIBS="-lconfd"
1888    AC_SUBST([CONFD_LIBS])
1889    AC_DEFINE([HAVE_CONFD], [1], [Enable confd integration])
1890 fi
1891
1892 dnl ---------------
1893 dnl sysrepo
1894 dnl ---------------
1895 if test "$enable_sysrepo" = "yes"; then
1896   PKG_CHECK_MODULES([SYSREPO], [sysrepo],
1897       [AC_DEFINE([HAVE_SYSREPO], [1], [Enable sysrepo integration])
1898       SYSREPO=true],
1899       [SYSREPO=false
1900       AC_MSG_ERROR([sysrepo was not found on your system.])]
1901   )
1902 fi
1903
1904 dnl ---------------
1905 dnl gRPC
1906 dnl ---------------
1907 if test "$enable_grpc" = "yes"; then
1908   AC_LANG_PUSH([C++])
1909   AX_CXX_COMPILE_STDCXX([11], [ext])
1910   PKG_CHECK_MODULES([GRPC], [grpc >= 6.0.0 grpc++ >= 1.16.1 protobuf >= 3.6.1 ], [
1911     AC_CHECK_PROGS([PROTOC], [protoc], [/bin/false])
1912     if test "$PROTOC" = "/bin/false"; then
1913       AC_MSG_FAILURE([grpc requested but protoc not found.])
1914     fi
1915
1916     AC_DEFINE([HAVE_GRPC], [1], [Enable the gRPC northbound plugin])
1917     GRPC=true
1918   ], [
1919     GRPC=false
1920     AC_MSG_ERROR([grpc/grpc++ were not found on your system.])
1921   ])
1922   AC_LANG_POP([C++])
1923 fi
1924
1925 dnl -----
1926 dnl LTTng
1927 dnl -----
1928 if test "$enable_lttng" = "yes"; then
1929   PKG_CHECK_MODULES([UST], [lttng-ust >= 2.12.0], [
1930     AC_DEFINE([HAVE_LTTNG], [1], [Enable LTTng support])
1931     LTTNG=true
1932   ], [
1933     AC_MSG_ERROR([configuration specifies --enable-lttng but lttng-ust was not found])
1934   ])
1935 fi
1936
1937 dnl ----
1938 dnl USDT
1939 dnl ----
1940 if test "$enable_usdt" = "yes"; then
1941   AC_CHECK_HEADERS([sys/sdt.h], [
1942     AC_DEFINE([HAVE_USDT], [1], [Enable USDT probes])
1943     USDT=true
1944   ], [
1945     AC_MSG_ERROR([configuration specifies --enable-usdt but no USDT kernel headers (sys/sdt.h) found])
1946   ])
1947 fi
1948
1949 dnl ------
1950 dnl ZeroMQ
1951 dnl ------
1952 if test "$enable_zeromq" != "no"; then
1953   PKG_CHECK_MODULES([ZEROMQ], [libzmq >= 4.0.0], [
1954     AC_DEFINE([HAVE_ZEROMQ], [1], [Enable ZeroMQ support])
1955     ZEROMQ=true
1956   ], [
1957     if test "$enable_zeromq" = "yes"; then
1958       AC_MSG_ERROR([configuration specifies --enable-zeromq but libzmq was not found])
1959     fi
1960   ])
1961 fi
1962
1963 dnl ------------------------------------
1964 dnl Enable RPKI and add librtr to libs
1965 dnl ------------------------------------
1966 if test "$enable_rpki" = "yes"; then
1967   PKG_CHECK_MODULES([RTRLIB], [rtrlib >= 0.5.0],
1968       [RPKI=true],
1969       [RPKI=false
1970       AC_MSG_ERROR([rtrlib was not found on your system or is too old.])]
1971   )
1972 fi
1973
1974 dnl ------------------------------------
1975 dnl pimd is not supported on OpenBSD and MacOS
1976 dnl ------------------------------------
1977 if test "$enable_pimd" != "no"; then
1978 AC_MSG_CHECKING([for pimd OS support])
1979 case "$host_os" in
1980   darwin*)
1981     AC_MSG_RESULT([no])
1982     enable_pimd="no"
1983     ;;
1984   openbsd*)
1985     AC_MSG_RESULT([no])
1986     enable_pimd="no"
1987     ;;
1988   *)
1989     AC_MSG_RESULT([yes])
1990     ;;
1991 esac
1992 fi
1993
1994 dnl -------------------------------------
1995 dnl VRRP is only supported on linux
1996 dnl -------------------------------------
1997 if test "$enable_vrrpd" != "no"; then
1998 AC_MSG_CHECKING([for VRRP OS support])
1999 case "$host_os" in
2000   linux*)
2001     AC_MSG_RESULT([yes])
2002     ;;
2003   *)
2004     AC_MSG_RESULT([no])
2005     enable_vrrpd="no"
2006     ;;
2007 esac
2008 fi
2009
2010 dnl ------------------------------------------
2011 dnl Check whether rtrlib was build with ssh support
2012 dnl ------------------------------------------
2013 AC_MSG_CHECKING([whether the RTR Library is compiled with SSH])
2014 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "rtrlib/rtrlib.h"]],
2015                         [[struct tr_ssh_config config;]])],
2016         [AC_MSG_RESULT([yes])
2017         AC_DEFINE([FOUND_SSH], [1], [found_ssh])],
2018         AC_MSG_RESULT([no])
2019 )
2020
2021 dnl ---------------
2022 dnl dlopen & dlinfo
2023 dnl ---------------
2024 AC_SEARCH_LIBS([dlopen], [dl dld], [], [
2025   AC_MSG_ERROR([unable to find the dlopen()])
2026 ])
2027
2028 AC_CHECK_HEADERS([link.h])
2029
2030 AC_CACHE_CHECK([for dlinfo(RTLD_DI_ORIGIN)], [frr_cv_rtld_di_origin], [
2031   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2032 #include <stdlib.h>
2033 #ifdef HAVE_LINK_H
2034 #include <link.h>
2035 #endif
2036 #include <dlfcn.h>
2037 ]], [[
2038   char origin[1];
2039   dlinfo (NULL, RTLD_DI_ORIGIN, &origin);
2040 ]])], [
2041     frr_cv_rtld_di_origin=yes
2042   ], [
2043     frr_cv_rtld_di_origin=no
2044   ])
2045 ])
2046 if test "$frr_cv_rtld_di_origin" = "yes"; then
2047   AC_DEFINE([HAVE_DLINFO_ORIGIN], [1], [Have dlinfo RTLD_DI_ORIGIN])
2048 fi
2049
2050 AC_CACHE_CHECK([for dlinfo(RTLD_DI_LINKMAP)], [frr_cv_rtld_di_linkmap], [
2051   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2052 #include <stdlib.h>
2053 #ifdef HAVE_LINK_H
2054 #include <link.h>
2055 #endif
2056 #include <dlfcn.h>
2057 ]], [[
2058   struct link_map *lm = NULL;
2059   dlinfo (NULL, RTLD_DI_LINKMAP, &lm);
2060 ]])], [
2061     frr_cv_rtld_di_linkmap=yes
2062   ], [
2063     frr_cv_rtld_di_linkmap=no
2064   ])
2065 ])
2066 if test "$frr_cv_rtld_di_linkmap" = "yes"; then
2067   AC_DEFINE([HAVE_DLINFO_LINKMAP], [1], [Have dlinfo RTLD_DI_LINKMAP])
2068 fi
2069
2070 dnl ##########################################################################
2071 dnl test "$enable_clippy_only" != "yes"
2072 fi
2073 dnl END OF LARGE if block
2074 dnl ##########################################################################
2075
2076 dnl ---------------------------
2077 dnl sockaddr and netinet checks
2078 dnl ---------------------------
2079 AC_CHECK_TYPES([
2080         struct sockaddr_dl,
2081         struct vifctl, struct mfcctl, struct sioc_sg_req,
2082         vifi_t, struct sioc_vif_req, struct igmpmsg,
2083         struct ifaliasreq, struct if6_aliasreq, struct in6_aliasreq,
2084         struct nd_opt_adv_interval,
2085         struct nd_opt_homeagent_info, struct nd_opt_adv_interval,
2086         struct nd_opt_rdnss, struct nd_opt_dnssl],
2087         [], [], FRR_INCLUDES)
2088
2089 AC_CHECK_MEMBERS([struct sockaddr.sa_len,
2090         struct sockaddr_in.sin_len, struct sockaddr_un.sun_len,
2091         struct sockaddr_dl.sdl_len,
2092         struct if6_aliasreq.ifra_lifetime,
2093         struct nd_opt_adv_interval.nd_opt_ai_type],
2094         [], [], FRR_INCLUDES)
2095
2096 dnl ---------------------------
2097 dnl IRDP/pktinfo/icmphdr checks
2098 dnl ---------------------------
2099
2100 AC_CHECK_TYPES([struct in_pktinfo], [
2101   AC_CHECK_TYPES([struct icmphdr], [
2102     IRDP=true
2103   ], [
2104     IRDP=false
2105   ], [FRR_INCLUDES])
2106 ], [
2107   IRDP=false
2108 ], [FRR_INCLUDES])
2109
2110 case "${enable_irdp}" in
2111 yes)
2112   $IRDP || AC_MSG_ERROR(['IRDP requires in_pktinfo at the moment!'])
2113   ;;
2114 no)
2115   IRDP=false
2116   ;;
2117 esac
2118
2119
2120 dnl -----------------------
2121 dnl checking for IP_PKTINFO
2122 dnl -----------------------
2123 AC_MSG_CHECKING([for IP_PKTINFO])
2124 AC_COMPILE_IFELSE(
2125 [ AC_LANG_PROGRAM([[
2126         #include <netdb.h>
2127    ]], [[
2128         int opt = IP_PKTINFO;
2129    ]])
2130 ],[
2131   AC_MSG_RESULT([yes])
2132   AC_DEFINE([HAVE_IP_PKTINFO], [1], [Have IP_PKTINFO])
2133 ],[
2134   AC_MSG_RESULT([no])
2135 ])
2136
2137 dnl ---------------------------
2138 dnl checking for IP_RECVDSTADDR
2139 dnl ---------------------------
2140 AC_MSG_CHECKING([for IP_RECVDSTADDR])
2141 AC_COMPILE_IFELSE(
2142 [ AC_LANG_PROGRAM([[
2143         #include <netinet/in.h>
2144   ]], [[
2145         int opt = IP_RECVDSTADDR;
2146   ]])
2147 ],[
2148   AC_MSG_RESULT([yes])
2149   AC_DEFINE([HAVE_IP_RECVDSTADDR], [1], [Have IP_RECVDSTADDR])
2150 ],[
2151   AC_MSG_RESULT([no])
2152 ])
2153
2154 dnl ----------------------
2155 dnl checking for IP_RECVIF
2156 dnl ----------------------
2157 AC_MSG_CHECKING([for IP_RECVIF])
2158 AC_COMPILE_IFELSE(
2159 [ AC_LANG_PROGRAM([[
2160         #include <netinet/in.h>
2161   ]], [[
2162         int opt = IP_RECVIF;
2163   ]])
2164 ],[
2165   AC_MSG_RESULT([yes])
2166   AC_DEFINE([HAVE_IP_RECVIF], [1], [Have IP_RECVIF])
2167 ],[
2168   AC_MSG_RESULT([no])
2169 ])
2170
2171 dnl ----------------------
2172 dnl checking for SO_BINDANY
2173 dnl ----------------------
2174 AC_MSG_CHECKING([for SO_BINDANY])
2175 AC_COMPILE_IFELSE(
2176 [ AC_LANG_PROGRAM([[
2177         #include <sys/socket.h>
2178   ]], [[
2179         int opt = SO_BINDANY;
2180   ]])
2181 ],[
2182   AC_MSG_RESULT([yes])
2183   AC_DEFINE([HAVE_SO_BINDANY], [1], [Have SO_BINDANY])
2184 ],[
2185   AC_MSG_RESULT([no])
2186 ])
2187
2188 dnl ----------------------
2189 dnl checking for IP_FREEBIND
2190 dnl ----------------------
2191 AC_MSG_CHECKING([for IP_FREEBIND])
2192 AC_COMPILE_IFELSE(
2193 [ AC_LANG_PROGRAM([[
2194         #include <netinet/in.h>
2195   ]], [[
2196         int opt = IP_FREEBIND;
2197   ]])
2198 ],[
2199   AC_MSG_RESULT([yes])
2200   AC_DEFINE([HAVE_IP_FREEBIND], [1], [Have IP_FREEBIND])
2201 ],[
2202   AC_MSG_RESULT([no])
2203 ])
2204
2205 dnl --------------------------------------
2206 dnl checking for be32dec existence or not
2207 dnl --------------------------------------
2208 AC_CHECK_DECLS([be32enc, be32dec], [], [], [
2209         #ifdef HAVE_SYS_ENDIAN_H
2210         #include <sys/endian.h>
2211         #endif
2212         #ifdef HAVE_ENDIAN_H
2213         #include <endian.h>
2214         #endif
2215 ])
2216
2217 dnl --------------------------------------
2218 dnl checking for clock_time monotonic struct and call
2219 dnl --------------------------------------
2220 AC_CHECK_DECL([CLOCK_MONOTONIC],
2221         [AC_CHECK_LIB([rt], [clock_gettime], [LIBS="$LIBS -lrt"])
2222          AC_DEFINE([HAVE_CLOCK_MONOTONIC], [1], [Have monotonic clock])
2223 ], [AC_MSG_RESULT([no])], [FRR_INCLUDES])
2224
2225 AC_CHECK_DECL([CLOCK_THREAD_CPUTIME_ID], [
2226          AC_DEFINE([HAVE_CLOCK_THREAD_CPUTIME_ID], [1], [Have cpu-time clock])
2227 ], [AC_MSG_RESULT([no])], [FRR_INCLUDES])
2228
2229 AC_SEARCH_LIBS([clock_nanosleep], [rt], [
2230   AC_DEFINE([HAVE_CLOCK_NANOSLEEP], [1], [Have clock_nanosleep()])
2231 ])
2232
2233 dnl --------------------------------------
2234 dnl checking for flex and bison
2235 dnl --------------------------------------
2236
2237 AM_PROG_LEX
2238 AC_MSG_CHECKING([version of flex])
2239 frr_ac_flex_version="$(eval $LEX -V | grep flex | head -n 1)"
2240 frr_ac_flex_version="${frr_ac_flex_version##* }"
2241 AC_MSG_RESULT([$frr_ac_flex_version])
2242 AX_COMPARE_VERSION([$frr_ac_flex_version], [lt], [2.5.20], [
2243   LEX="$SHELL $missing_dir/missing flex"
2244   if test -f "${srcdir}/lib/command_lex.c" -a -f "${srcdir}/lib/command_lex.h"; then
2245     AC_MSG_WARN([using pregenerated flex output files])
2246   else
2247     AC_MSG_ERROR([flex failure and pregenerated files not included (probably a git build)])
2248   fi
2249   AC_SUBST([LEX_OUTPUT_ROOT], [lex.yy])
2250   AC_SUBST([LEXLIB], [''])
2251 ])
2252
2253 AC_PROG_YACC
2254 dnl thanks GNU bison for this b*llshit...
2255 AC_MSG_CHECKING([version of bison])
2256 frr_ac_bison_version="$(eval $YACC -V | grep bison | head -n 1)"
2257 frr_ac_bison_version="${frr_ac_bison_version##* }"
2258 frr_ac_bison_missing="false"
2259 case "x${frr_ac_bison_version}x" in
2260   x2.7*)
2261     BISON_OPENBRACE='"'
2262     BISON_CLOSEBRACE='"'
2263     BISON_VERBOSE=''
2264     AC_MSG_RESULT([$frr_ac_bison_version - 2.7 or older])
2265     ;;
2266   x2.*|x1.*)
2267     AC_MSG_RESULT([$frr_ac_bison_version])
2268     AC_MSG_WARN([installed bison is too old.  Please install GNU bison 2.7.x or newer.])
2269     frr_ac_bison_missing="true"
2270     ;;
2271   x)
2272     AC_MSG_RESULT([none])
2273     AC_MSG_WARN([could not determine bison version.  Please install GNU bison 2.7.x or newer.])
2274     frr_ac_bison_missing="true"
2275     ;;
2276   x3.[012][^0-9]*)
2277     BISON_OPENBRACE='{'
2278     BISON_CLOSEBRACE='}'
2279     BISON_VERBOSE='-Dparse.error=verbose'
2280     AC_MSG_RESULT([$frr_ac_bison_version - 3.0 to 3.2])
2281     ;;
2282   *)
2283     BISON_OPENBRACE='{'
2284     BISON_CLOSEBRACE='}'
2285     BISON_VERBOSE='-Dparse.error=verbose -Wno-yacc'
2286     AC_MSG_RESULT([$frr_ac_bison_version - 3.3 or newer])
2287     ;;
2288 esac
2289 AC_SUBST([BISON_OPENBRACE])
2290 AC_SUBST([BISON_CLOSEBRACE])
2291 AC_SUBST([BISON_VERBOSE])
2292
2293 if $frr_ac_bison_missing; then
2294   YACC="$SHELL $missing_dir/missing bison -y"
2295   if test -f "${srcdir}/lib/command_parse.c" -a -f "${srcdir}/lib/command_parse.h"; then
2296     AC_MSG_WARN([using pregenerated bison output files])
2297   else
2298     AC_MSG_ERROR([bison failure and pregenerated files not included (probably a git build)])
2299   fi
2300 fi
2301
2302 dnl -------------------
2303 dnl capabilities checks
2304 dnl -------------------
2305 if test "$enable_capabilities" != "no"; then
2306   AC_MSG_CHECKING([whether prctl PR_SET_KEEPCAPS is available])
2307   AC_COMPILE_IFELSE(
2308   [ AC_LANG_PROGRAM([[
2309         #include <sys/prctl.h>
2310     ]], [[
2311         prctl(PR_SET_KEEPCAPS, 1, 0, 0, 0);
2312     ]])
2313   ],[AC_MSG_RESULT([yes])
2314      AC_DEFINE([HAVE_PR_SET_KEEPCAPS], [1], [prctl])
2315      frr_ac_keepcaps="yes"
2316   ],[AC_MSG_RESULT(no)
2317   ])
2318   if test "$frr_ac_keepcaps" = "yes"; then
2319     AC_CHECK_HEADERS([sys/capability.h])
2320   fi
2321   if test "$ac_cv_header_sys_capability_h" = "yes"; then
2322     AC_CHECK_LIB([cap], [cap_init],
2323       [AC_DEFINE([HAVE_LCAPS], [1], [Capabilities])
2324        LIBCAP="-lcap"
2325        frr_ac_lcaps="yes"]
2326     )
2327   fi
2328   if test "$frr_ac_scaps" = "yes" \
2329        -o "$frr_ac_lcaps" = "yes"; then
2330     AC_DEFINE([HAVE_CAPABILITIES], [1], [capabilities])
2331   fi
2332
2333   case "$host_os" in
2334   linux*)
2335     if test "$enable_clippy_only" != "yes"; then
2336     if test "$frr_ac_lcaps" != "yes"; then
2337       AC_MSG_ERROR([libcap and/or its headers were not found.  Running FRR without libcap support built in causes a huge performance penalty.])
2338     fi
2339     fi
2340     ;;
2341   esac
2342 else
2343   case "$host_os" in
2344   linux*)
2345     AC_MSG_WARN([Running FRR without libcap support built in causes a huge performance penalty.])
2346     ;;
2347   esac
2348 fi
2349 AC_SUBST([LIBCAP])
2350
2351 dnl ---------------------------
2352 dnl check for glibc 'backtrace'
2353 dnl ---------------------------
2354 if test "$enable_backtrace" != "no" ; then
2355   backtrace_ok=no
2356   PKG_CHECK_MODULES([UNWIND], [libunwind], [
2357     AC_DEFINE([HAVE_LIBUNWIND], [1], [libunwind])
2358     backtrace_ok=yes
2359   ], [
2360     true
2361   ])
2362
2363   if test "$backtrace_ok" = "no"; then
2364     AC_CHECK_HEADER([unwind.h], [
2365       AC_SEARCH_LIBS([unw_getcontext], [unwind], [
2366         AC_DEFINE([HAVE_LIBUNWIND], [1], [libunwind])
2367         backtrace_ok=yes
2368       ])
2369     ])
2370   fi
2371
2372   if test "$backtrace_ok" = "no"; then
2373     AC_CHECK_HEADER([execinfo.h], [
2374       AC_SEARCH_LIBS([backtrace], [execinfo], [
2375         AC_DEFINE([HAVE_GLIBC_BACKTRACE], [1], [Glibc backtrace])
2376         backtrace_ok=yes
2377       ],, [-lm])
2378     ])
2379   fi
2380
2381   if test "$enable_backtrace" = "yes" -a "$backtrace_ok" = "no"; then
2382     dnl user explicitly requested backtrace but we failed to find support
2383     AC_MSG_FAILURE([failed to find backtrace or libunwind support])
2384   fi
2385 fi
2386
2387 dnl -----------------------------------------
2388 dnl check for malloc mallinfo struct and call
2389 dnl this must try and link using LIBS, in
2390 dnl order to check no alternative allocator
2391 dnl has been specified, which might not provide
2392 dnl mallinfo
2393 dnl -----------------------------------------
2394 AC_CHECK_HEADERS([malloc.h malloc_np.h malloc/malloc.h],,, [FRR_INCLUDES])
2395
2396 AC_CACHE_CHECK([whether mallinfo is available], [frr_cv_mallinfo], [
2397   AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2398 #ifdef HAVE_MALLOC_H
2399 #include <malloc.h>
2400 #endif
2401 #ifdef HAVE_MALLOC_NP_H
2402 #include <malloc_np.h>
2403 #endif
2404 #ifdef HAVE_MALLOC_MALLOC_H
2405 #include <malloc/malloc.h>
2406 #endif
2407 ]], [[
2408 struct mallinfo ac_x; ac_x = mallinfo ();
2409 ]])], [
2410     frr_cv_mallinfo=yes
2411   ], [
2412     frr_cv_mallinfo=no
2413   ])
2414 ])
2415 if test "$frr_cv_mallinfo" = "yes"; then
2416   AC_DEFINE([HAVE_MALLINFO], [1], [mallinfo])
2417 fi
2418
2419 AC_CACHE_CHECK([whether mallinfo2 is available], [frr_cv_mallinfo2], [
2420   AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2421 #ifdef HAVE_MALLOC_H
2422 #include <malloc.h>
2423 #endif
2424 #ifdef HAVE_MALLOC_NP_H
2425 #include <malloc_np.h>
2426 #endif
2427 #ifdef HAVE_MALLOC_MALLOC_H
2428 #include <malloc/malloc.h>
2429 #endif
2430 ]], [[
2431 struct mallinfo2 ac_x; ac_x = mallinfo2 ();
2432 ]])], [
2433     frr_cv_mallinfo2=yes
2434   ], [
2435     frr_cv_mallinfo2=no
2436   ])
2437 ])
2438 if test "$frr_cv_mallinfo2" = "yes"; then
2439   AC_DEFINE([HAVE_MALLINFO2], [1], [mallinfo2])
2440 fi
2441
2442 AC_MSG_CHECKING([whether malloc_usable_size is available])
2443 AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2444 #ifdef HAVE_MALLOC_H
2445 #include <malloc.h>
2446 #endif
2447 #ifdef HAVE_MALLOC_MALLOC_H
2448 #include <malloc/malloc.h>
2449 #endif
2450 ]], [[
2451 size_t ac_x; ac_x = malloc_usable_size(NULL);
2452 ]])], [
2453   AC_MSG_RESULT([yes])
2454   AC_DEFINE([HAVE_MALLOC_USABLE_SIZE], [1], [malloc_usable_size])
2455 ], [
2456   AC_MSG_RESULT([no])
2457
2458   AC_MSG_CHECKING([whether malloc_size is available])
2459   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2460 #ifdef HAVE_MALLOC_H
2461 #include <malloc.h>
2462 #endif
2463 #ifdef HAVE_MALLOC_MALLOC_H
2464 #include <malloc/malloc.h>
2465 #endif
2466 ]], [[
2467 size_t ac_x; ac_x = malloc_size(NULL);
2468 ]])], [
2469     AC_MSG_RESULT([yes])
2470     AC_DEFINE([HAVE_MALLOC_SIZE], [1], [malloc_size])
2471   ], [
2472     AC_MSG_RESULT([no])
2473   ])
2474 ])
2475
2476 dnl ----------
2477 dnl configure date
2478 dnl ----------
2479 dev_version=`echo $VERSION | grep dev`
2480 #don't expire deprecated code in non 'dev' branch
2481 if test "$dev_version" = ""; then
2482    CONFDATE=0
2483 else
2484    CONFDATE=`date '+%Y%m%d'`
2485 fi
2486 AC_SUBST([CONFDATE])
2487
2488 dnl ------------------------------
2489 dnl set paths for state directory
2490 dnl ------------------------------
2491 AC_MSG_CHECKING([directory to use for state file])
2492 if test "$prefix" = "NONE"; then
2493   frr_statedir_prefix="";
2494 else
2495   frr_statedir_prefix=${prefix}
2496 fi
2497 if test "$localstatedir" = '${prefix}/var'; then
2498   for FRR_STATE_DIR in ${frr_statedir_prefix}/var/run dnl
2499                         ${frr_statedir_prefix}/var/adm dnl
2500                         ${frr_statedir_prefix}/etc dnl
2501                         /var/run        dnl
2502                         /var/adm        dnl
2503                         /etc            dnl
2504                         /dev/null;
2505   do
2506     test -d $FRR_STATE_DIR && break
2507   done
2508   frr_statedir=$FRR_STATE_DIR
2509 else
2510   frr_statedir=${localstatedir}
2511 fi
2512 if test "$frr_statedir" = "/dev/null"; then
2513     AC_MSG_ERROR([STATE DIRECTORY NOT FOUND! FIX OR SPECIFY --localstatedir!])
2514 fi
2515 AC_MSG_RESULT([${frr_statedir}])
2516 AC_SUBST([frr_statedir])
2517
2518 AC_DEFINE_UNQUOTED([LDPD_SOCKET], ["$frr_statedir%s%s/ldpd.sock"], [ldpd control socket])
2519 AC_DEFINE_UNQUOTED([ZEBRA_SERV_PATH], ["$frr_statedir%s%s/zserv.api"], [zebra api socket])
2520 AC_DEFINE_UNQUOTED([BFDD_CONTROL_SOCKET], ["$frr_statedir%s%s/bfdd.sock"], [bfdd control socket])
2521 AC_DEFINE_UNQUOTED([OSPFD_GR_STATE], ["$frr_statedir%s/ospfd-gr.json"], [ospfd GR state information])
2522 AC_DEFINE_UNQUOTED([OSPF6D_GR_STATE], ["$frr_statedir/ospf6d-gr.json"], [ospf6d GR state information])
2523 AC_DEFINE_UNQUOTED([DAEMON_VTY_DIR], ["$frr_statedir%s%s"], [daemon vty directory])
2524 AC_DEFINE_UNQUOTED([DAEMON_DB_DIR], ["$frr_statedir"], [daemon database directory])
2525
2526 dnl autoconf does this, but it does it too late...
2527 test "$prefix" = "NONE" && prefix=$ac_default_prefix
2528 test "$exec_prefix" = "NONE" && exec_prefix='${prefix}'
2529
2530 dnl get the full path, recursing through variables...
2531 vtysh_bin="$bindir/vtysh"
2532 for I in 1 2 3 4 5 6 7 8 9 10; do
2533         eval vtysh_bin="\"$vtysh_bin\""
2534 done
2535 AC_DEFINE_UNQUOTED([VTYSH_BIN_PATH], ["$vtysh_bin"], [path to vtysh binary])
2536 AC_SUBST([vtysh_bin])
2537
2538 CFG_SYSCONF="$sysconfdir"
2539 CFG_SBIN="$sbindir"
2540 CFG_STATE="$frr_statedir"
2541 CFG_MODULE="$moduledir"
2542 CFG_YANGMODELS="$yangmodelsdir"
2543 CFG_SCRIPT="$scriptdir"
2544 for I in 1 2 3 4 5 6 7 8 9 10; do
2545         eval CFG_SYSCONF="\"$CFG_SYSCONF\""
2546         eval CFG_SBIN="\"$CFG_SBIN\""
2547         eval CFG_STATE="\"$CFG_STATE\""
2548         eval CFG_MODULE="\"$CFG_MODULE\""
2549         eval CFG_YANGMODELS="\"$CFG_YANGMODELS\""
2550         eval CFG_SCRIPT="\"$CFG_SCRIPT\""
2551 done
2552 AC_SUBST([CFG_SYSCONF])
2553 AC_SUBST([CFG_SBIN])
2554 AC_SUBST([CFG_STATE])
2555 AC_SUBST([CFG_MODULE])
2556 AC_SUBST([CFG_SCRIPT])
2557 AC_SUBST([CFG_YANGMODELS])
2558 AC_DEFINE_UNQUOTED([MODULE_PATH], ["$CFG_MODULE"], [path to modules])
2559 AC_DEFINE_UNQUOTED([SCRIPT_PATH], ["$CFG_SCRIPT"], [path to scripts])
2560 AC_DEFINE_UNQUOTED([YANG_MODELS_PATH], ["$CFG_YANGMODELS"], [path to YANG data models])
2561 AC_DEFINE_UNQUOTED([WATCHFRR_SH_PATH], ["${CFG_SBIN%/}/watchfrr.sh"], [path to watchfrr.sh])
2562
2563 dnl various features
2564 AM_CONDITIONAL([SUPPORT_REALMS], [test "$enable_realms" = "yes"])
2565 AM_CONDITIONAL([ENABLE_BGP_VNC], [test "$enable_bgp_vnc" != "no"])
2566 AM_CONDITIONAL([BGP_BMP], [$bgpd_bmp])
2567 dnl northbound
2568 AM_CONDITIONAL([SQLITE3], [$SQLITE3])
2569 AM_CONDITIONAL([CONFD], [test "$enable_confd" != ""])
2570 AM_CONDITIONAL([SYSREPO], [test "$enable_sysrepo" = "yes"])
2571 AM_CONDITIONAL([GRPC], [test "$enable_grpc" = "yes"])
2572 AM_CONDITIONAL([ZEROMQ], [test "$ZEROMQ" = "true"])
2573 dnl plugins
2574 AM_CONDITIONAL([RPKI], [test "$RPKI" = "true"])
2575 AM_CONDITIONAL([SNMP], [test "$SNMP_METHOD" = "agentx"])
2576 AM_CONDITIONAL([IRDP], [$IRDP])
2577 AM_CONDITIONAL([FPM], [test "$enable_fpm" = "yes"])
2578 AM_CONDITIONAL([HAVE_PROTOBUF], [test "$enable_protobuf" = "yes"])
2579 AM_CONDITIONAL([HAVE_PROTOBUF3], [$PROTO3])
2580
2581 dnl PCEP plugin
2582 AS_IF([test "$enable_pathd" != "no"], [
2583        AC_SUBST([PATHD_PCEP_LIBS], ["pceplib/libpcep_pcc.la"])
2584        AC_SUBST([PATHD_PCEP_INCL], ["-I./pceplib "])
2585        ])
2586 AC_CHECK_LIB([cunit], [CU_initialize_registry], [pcep_cunit=yes],[pcep_cunit=no])
2587 AM_CONDITIONAL([PATHD_PCEP_TEST], [test "x${pcep_cunit}" = xyes])
2588 AC_CHECK_PROG(VALGRIND_CHECK, valgrind, yes)
2589 AM_CONDITIONAL([HAVE_VALGRIND_PCEP], [test "$VALGRIND_CHECK" = "yes"])
2590
2591 dnl daemons
2592 AM_CONDITIONAL([VTYSH], [test "$VTYSH" = "vtysh"])
2593 AM_CONDITIONAL([ZEBRA], [test "$enable_zebra" != "no"])
2594 AM_CONDITIONAL([BGPD], [test "$enable_bgpd" != "no"])
2595 AM_CONDITIONAL([RIPD], [test "$enable_ripd" != "no"])
2596 AM_CONDITIONAL([OSPFD], [test "$enable_ospfd" != "no"])
2597 AM_CONDITIONAL([LDPD], [test "$enable_ldpd" != "no"])
2598 AM_CONDITIONAL([BFDD], [test "$BFDD" = "bfdd"])
2599 AM_CONDITIONAL([NHRPD], [test "$NHRPD" = "nhrpd"])
2600 AM_CONDITIONAL([EIGRPD], [test "$enable_eigrpd" != "no"])
2601 AM_CONDITIONAL([WATCHFRR], [test "$WATCHFRR" = "watchfrr"])
2602 AM_CONDITIONAL([OSPFCLIENT], [test "$OSPFCLIENT" = "ospfclient"])
2603 AM_CONDITIONAL([RIPNGD], [test "$enable_ripngd" != "no"])
2604 AM_CONDITIONAL([BABELD], [test "$enable_babeld" != "no"])
2605 AM_CONDITIONAL([OSPF6D], [test "$enable_ospf6d" != "no"])
2606 AM_CONDITIONAL([ISISD], [test "$enable_isisd" != "no"])
2607 AM_CONDITIONAL([PIMD], [test "$enable_pimd" != "no"])
2608 AM_CONDITIONAL([PBRD], [test "$enable_pbrd" != "no"])
2609 AM_CONDITIONAL([SHARPD], [test "$enable_sharpd" = "yes"])
2610 AM_CONDITIONAL([STATICD], [test "$enable_staticd" != "no"])
2611 AM_CONDITIONAL([FABRICD], [test "$enable_fabricd" != "no"])
2612 AM_CONDITIONAL([VRRPD], [test "$enable_vrrpd" != "no"])
2613 AM_CONDITIONAL([PATHD], [test "$enable_pathd" != "no"])
2614 AM_CONDITIONAL([PATHD_PCEP], [test "$enable_pathd" != "no"])
2615
2616 AC_CONFIG_FILES([Makefile],[
2617         test "$enable_dev_build" = "yes" && makefile_devbuild="--dev-build"
2618         ${PYTHON} "${ac_abs_top_srcdir}/python/makefile.py" ${makefile_devbuild} || exit 1
2619 ], [
2620         PYTHON="$PYTHON"
2621         enable_dev_build="$enable_dev_build"
2622 ])
2623
2624 AC_CONFIG_FILES([
2625           config.version
2626           redhat/frr.spec
2627           alpine/APKBUILD
2628           snapcraft/snapcraft.yaml
2629           lib/version.h
2630           tests/lib/cli/test_cli.refout
2631           pkgsrc/bgpd.sh pkgsrc/ospf6d.sh pkgsrc/ospfd.sh
2632           pkgsrc/ripd.sh pkgsrc/ripngd.sh pkgsrc/zebra.sh
2633           pkgsrc/eigrpd.sh])
2634
2635 AC_CONFIG_FILES([vtysh/extract.pl], [chmod +x vtysh/extract.pl])
2636 AC_CONFIG_FILES([tools/frr], [chmod +x tools/frr])
2637 AC_CONFIG_FILES([tools/watchfrr.sh], [chmod +x tools/watchfrr.sh])
2638 AC_CONFIG_FILES([tools/frrinit.sh], [chmod +x tools/frrinit.sh])
2639 AC_CONFIG_FILES([tools/frrcommon.sh])
2640 AC_CONFIG_FILES([tools/frr.service])
2641 AC_CONFIG_FILES([tools/frr@.service])
2642
2643 AS_IF([test "$with_pkg_git_version" = "yes"], [
2644     AC_CONFIG_COMMANDS([lib/gitversion.h], [
2645         dst="${ac_abs_top_builddir}/lib/gitversion.h"
2646         ${PERL} "${ac_abs_top_srcdir}/lib/gitversion.pl" \
2647                 "${ac_abs_top_srcdir}" \
2648                 > "${dst}.tmp"
2649         test -f "$dst" \
2650                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
2651                 && rm "${dst}.tmp" \
2652                 || mv "${dst}.tmp" "${dst}"
2653     ], [
2654         PERL="$PERL"
2655     ])
2656 ])
2657
2658 ## Hack, but working solution to avoid rebuilding of frr.info.
2659 ## It's already in CVS until texinfo 4.7 is more common.
2660 AC_OUTPUT
2661
2662 if test "$enable_rpath" = "yes" ; then
2663         true
2664 else
2665         # See https://old-en.opensuse.org/openSUSE:Packaging_Guidelines#Removing_Rpath
2666         sed -e 's|^hardcode_libdir_flag_spec=.*|hardcode_libdir_flag_spec=""|g' libtool > libtool.sed && cat libtool.sed > libtool
2667         sed -e 's|^runpath_var=LD_RUN_PATH|runpath_var=DIE_RPATH_DIE|g'         libtool > libtool.sed && cat libtool.sed > libtool
2668         test -f libtool.sed && rm libtool.sed
2669 fi
2670
2671 echo "
2672 FRRouting configuration
2673 ------------------------------
2674 FRR version             : ${PACKAGE_VERSION}
2675 host operating system   : ${host_os}
2676 source code location    : ${srcdir}
2677 compiler                : ${CC}
2678 compiler flags          : ${CFLAGS} ${WERROR} ${AC_CFLAGS} ${SAN_FLAGS}
2679 make                    : ${MAKE-make}
2680 linker flags            : ${LDFLAGS} ${SAN_FLAGS} ${LIBS} ${LIBCAP} ${LIBREADLINE} ${LIBM}
2681 state file directory    : ${frr_statedir}
2682 config file directory   : `eval echo \`echo ${sysconfdir}\``
2683 module directory        : ${CFG_MODULE}
2684 script directory        : ${CFG_SCRIPT}
2685 user to run as          : ${enable_user}
2686 group to run as         : ${enable_group}
2687 group for vty sockets   : ${enable_vty_group}
2688 config file mask        : ${enable_configfile_mask}
2689 log file mask           : ${enable_logfile_mask}
2690 zebra protobuf enabled  : ${enable_protobuf:-no}
2691 vici socket path        : ${vici_socket}
2692
2693 The above user and group must have read/write access to the state file
2694 directory and to the config files in the config file directory."
2695
2696 if test -n "$enable_datacenter"; then
2697   AC_MSG_WARN([The --enable-datacenter compile time option is deprecated.  Please modify the init script to pass -F datacenter to the daemons instead.])
2698 fi
2699 if test -n "$enable_time_check"; then
2700   AC_MSG_WARN([The --enable-time-check compile time option is deprecated.  Please use the service cputime-stats configuration option instead.])
2701 fi
2702 if test -n "$enable_cpu_time"; then
2703   AC_MSG_WARN([The --enable-cpu-time compile time option is deprecated.  Please use the service cputime-warning NNN configuration option instead.])
2704 fi
2705
2706 if test "$enable_doc" != "no" -a "$frr_py_mod_sphinx" = "false"; then
2707   AC_MSG_WARN([sphinx is missing but required to build documentation])
2708 fi
2709 if test "$frr_py_mod_pytest" = "false"; then
2710   AC_MSG_WARN([pytest is missing, unit tests cannot be performed])
2711 fi