configure.ac

   1 ##
   2 ## Configure template file for FRRouting.
   3 ## autoconf will generate configure script.
   4 ##
   5 ##  Copyright (c) 1996, 97, 98, 99, 2000 Kunihiro Ishiguro <kunihiro@zebra.org>
   6 ##  Portions Copyright (c) 2003 Paul Jakma <paul@dishone.st>
   7 ##
   8 AC_PREREQ(2.60)
   9
  10 AC_INIT(frr, 3.1-dev, [https://github.com/frrouting/frr/issues])
  11 PACKAGE_URL="https://frrouting.org/"
  12 PACKAGE_FULLNAME="FRRouting"
  13 AC_SUBST(PACKAGE_FULLNAME)
  14
  15 CONFIG_ARGS="$ac_configure_args"
  16 AC_SUBST(CONFIG_ARGS)
  17
  18 AC_CONFIG_SRCDIR(lib/zebra.h)
  19 AC_CONFIG_MACRO_DIR([m4])
  20
  21 dnl -----------------------------------
  22 dnl Get hostname and other information.
  23 dnl -----------------------------------
  24 AC_CANONICAL_BUILD()
  25 AC_CANONICAL_HOST()
  26
  27 AS_IF([test "$host" != "$build"], [
  28   if test "$srcdir" = "."; then
  29     AC_MSG_ERROR([cross-compilation is only possible with builddir separate from srcdir.  create a separate directory and run as .../path-to-frr/configure.])
  30   fi
  31   test -d hosttools || mkdir hosttools
  32   abssrc="`cd \"${srcdir}\"; pwd`"
  33
  34   AC_MSG_NOTICE([...])
  35   AC_MSG_NOTICE([... cross-compilation: creating hosttools directory and self-configuring for build platform tools])
  36   AC_MSG_NOTICE([... use HOST_CPPFLAGS / HOST_CFLAGS / HOST_LDFLAGS if neccessary])
  37   AC_MSG_NOTICE([...])
  38
  39   ( CPPFLAGS="$HOST_CPPFLAGS"; \
  40     CFLAGS="$HOST_CFLAGS"; \
  41     LDFLAGS="$HOST_LDFLAGS"; \
  42     cd hosttools; "${abssrc}/configure" "--host=$build" "--build=$build"; )
  43
  44   AC_MSG_NOTICE([...])
  45   AC_MSG_NOTICE([... cross-compilation: finished self-configuring for build platform tools])
  46   AC_MSG_NOTICE([...])
  47
  48   build_clippy="false"
  49   HOSTTOOLS="hosttools/"
  50 ], [
  51   build_clippy="true"
  52   HOSTTOOLS=""
  53 ])
  54 AC_SUBST(HOSTTOOLS)
  55 AM_CONDITIONAL([BUILD_CLIPPY], [$build_clippy])
  56
  57 # Disable portability warnings -- our automake code (in particular
  58 # common.am) uses some constructs specific to gmake.
  59 AM_INIT_AUTOMAKE([1.12 -Wno-portability])
  60 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
  61 AM_SILENT_RULES([yes])
  62 AC_CONFIG_HEADERS(config.h)
  63
  64 AC_PATH_PROG(PERL, perl)
  65 PKG_PROG_PKG_CONFIG
  66
  67 dnl default is to match previous behavior
  68 exampledir=${sysconfdir}
  69 AC_ARG_ENABLE([exampledir],
  70           AS_HELP_STRING([--enable-exampledir],
  71                          [specify alternate directory for examples]),
  72                          exampledir="$enableval",)
  73 dnl XXX add --exampledir to autoconf standard directory list somehow
  74 AC_SUBST(exampledir)
  75
  76 dnl default is to match previous behavior
  77 pkgsrcrcdir=""
  78 pkgsrcdir=""
  79 AC_ARG_ENABLE([pkgsrcrcdir],
  80           AS_HELP_STRING([--enable-pkgsrcrcdir],
  81                          [specify directory for rc.d scripts]),
  82                          pkgsrcrcdir="$enableval"; pkgsrcdir="pkgsrc",)
  83 dnl XXX add --pkgsrcrcdir to autoconf standard directory list somehow
  84 AC_SUBST(pkgsrcdir)
  85 AC_SUBST(pkgsrcrcdir)
  86
  87 AC_ARG_WITH([moduledir], [AS_HELP_STRING([--with-moduledir=DIR], [module directory (${libdir}/frr/modules)])], [
  88         moduledir="$withval"
  89 ], [
  90         moduledir="\${libdir}/frr/modules"
  91 ])
  92 AC_SUBST([moduledir], [$moduledir])
  93
  94 AC_ARG_ENABLE(tcmalloc,
  95         AS_HELP_STRING([--enable-tcmalloc], [Turn on tcmalloc]),
  96 [case "${enableval}" in
  97   yes) tcmalloc_enabled=true
  98 LIBS="$LIBS -ltcmalloc_minimal"
  99  ;;
 100   no)  tcmalloc_enabled=false ;;
 101   *) AC_MSG_ERROR(bad value ${enableval} for --enable-tcmalloc) ;;
 102 esac],[tcmalloc_enabled=false])
 103
 104
 105 dnl Thanks autoconf, but we don't want a default -g -O2.  We have our own
 106 dnl flag determination logic.
 107 CFLAGS="${CFLAGS:-}"
 108
 109 dnl --------------------
 110 dnl Check CC and friends
 111 dnl --------------------
 112 dnl note orig_cflags is also used further down
 113 orig_cflags="$CFLAGS"
 114 AC_LANG([C])
 115 AC_PROG_CC
 116 AC_PROG_CPP
 117 AM_PROG_CC_C_O
 118 dnl remove autoconf default "-g -O2"
 119 CFLAGS="$orig_cflags"
 120 AC_PROG_CC_C99
 121 dnl NB: see C11 below
 122
 123 AC_PROG_EGREP
 124 PKG_PROG_PKG_CONFIG
 125
 126 dnl autoconf 2.59 appears not to support AC_PROG_SED
 127 dnl AC_PROG_SED
 128 AC_CHECK_PROG([SED],[sed],[sed],[/bin/false])
 129
 130 dnl try and enable CFLAGS that are useful for FRR
 131 dnl - specifically, options to control warnings
 132
 133 AC_USE_SYSTEM_EXTENSIONS
 134 AC_DEFUN([AC_C_FLAG], [{
 135         AC_LANG_PUSH(C)
 136         ac_c_flag_save="$CFLAGS"
 137         CFLAGS="$CFLAGS $1"
 138         AC_MSG_CHECKING([[whether $CC supports $1]])
 139         AC_COMPILE_IFELSE(
 140                 [AC_LANG_PROGRAM([[]])],
 141                 [
 142                         AC_MSG_RESULT([yes])
 143                         m4_if([$3], [], [], [
 144                                 CFLAGS="$ac_c_flag_save"
 145                                 $3
 146                         ])
 147                 ], [
 148                         CFLAGS="$ac_c_flag_save"
 149                         AC_MSG_RESULT([no])
 150                         $2
 151                 ])
 152         AC_LANG_POP(C)
 153         }])
 154
 155 AC_DEFUN([AC_LINK_IFELSE_FLAGS], [{
 156         AC_LANG_PUSH(C)
 157         ac_cflags_save="$CFLAGS"
 158         ac_libs_save="$LIBS"
 159         CFLAGS="$CFLAGS $1"
 160         LIBS="$LIBS $2"
 161         AC_LINK_IFELSE(
 162                 [$3],
 163                 [
 164                         AC_MSG_RESULT([yes])
 165                         CFLAGS="$ac_cflags_save"
 166                         LIBS="$ac_libs_save"
 167                         $5
 168                 ], [
 169                         AC_MSG_RESULT([no])
 170                         CFLAGS="$ac_cflags_save"
 171                         LIBS="$ac_libs_save"
 172                         $4
 173                 ])
 174         AC_LANG_POP(C)
 175         }])
 176
 177 dnl ICC won't bail on unknown options without -diag-error 10006
 178 dnl need to do this first so we get useful results for the other options
 179 AC_C_FLAG([-diag-error 10006])
 180
 181 dnl AC_PROG_CC_C99 may change CC to include -std=gnu99 or something
 182 ac_cc="$CC"
 183 CC="${CC% -std=gnu99}"
 184 CC="${CC% -std=c99}"
 185
 186 AC_C_FLAG([-std=gnu11], [CC="$ac_cc"], [CC="$CC -std=gnu11"])
 187
 188 dnl if the user specified any CFLAGS, we don't add "-g -Os/-O2" here
 189 if test "z$orig_cflags" = "z"; then
 190   AC_C_FLAG([-g])
 191   AC_C_FLAG([-Os], [
 192     AC_C_FLAG([-O2])
 193   ])
 194 fi
 195
 196 dnl always want these CFLAGS
 197 AC_C_FLAG([-fno-omit-frame-pointer])
 198 AC_C_FLAG([-Wall])
 199 AC_C_FLAG([-Wextra])
 200 AC_C_FLAG([-Wmissing-prototypes])
 201 AC_C_FLAG([-Wmissing-declarations])
 202 AC_C_FLAG([-Wpointer-arith])
 203 AC_C_FLAG([-Wbad-function-cast])
 204 AC_C_FLAG([-Wwrite-strings])
 205 if test x"${enable_gcc_ultra_verbose}" = x"yes" ; then
 206   AC_C_FLAG([-Wcast-qual])
 207   AC_C_FLAG([-Wstrict-prototypes])
 208   AC_C_FLAG([-Wmissing-noreturn])
 209   AC_C_FLAG([-Wmissing-format-attribute])
 210   AC_C_FLAG([-Wunreachable-code])
 211   AC_C_FLAG([-Wpacked])
 212   AC_C_FLAG([-Wpadded])
 213 else
 214   AC_C_FLAG([-Wno-unused-result])
 215 fi
 216 AC_C_FLAG([-Wno-unused-parameter])
 217 AC_C_FLAG([-Wno-missing-field-initializers])
 218
 219 dnl ICC emits a broken warning for const char *x = a ? "b" : "c";
 220 dnl for some reason the string consts get 'promoted' to char *,
 221 dnl triggering a const to non-const conversion warning.
 222 AC_C_FLAG([-diag-disable 3179])
 223
 224 if test x"${enable_werror}" = x"yes" ; then
 225   WERROR="-Werror"
 226 fi
 227 AC_SUBST(WERROR)
 228
 229 dnl need link on this one, not compile
 230 AC_LANG_PUSH(C)
 231 ac_ld_flag_save="$LDFLAGS"
 232 LDFLAGS="$LDFLAGS -rdynamic"
 233 AC_MSG_CHECKING([[whether linker supports -rdynamic]])
 234 AC_LINK_IFELSE(
 235         [AC_LANG_PROGRAM([[]])],
 236         [AC_MSG_RESULT([yes])],
 237         [
 238                 LDFLAGS="$ac_ld_flag_save"
 239                 AC_MSG_RESULT([no])
 240         ])
 241 AC_LANG_POP(C)
 242
 243 dnl ----------
 244 dnl Essentials
 245 dnl ----------
 246
 247 AX_PTHREAD([
 248   CC="$PTHREAD_CC"
 249   CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 250   LIBS="$PTHREAD_LIBS $LIBS"
 251 ], [
 252   AC_MSG_FAILURE([This FRR version needs pthreads])
 253 ])
 254
 255 dnl --------------
 256 dnl Check programs
 257 dnl --------------
 258 AC_PROG_INSTALL
 259 AC_PROG_LN_S
 260 AC_PROG_MAKE_SET
 261 AC_CHECK_TOOL(AR, ar)
 262
 263 dnl -----------------
 264 dnl System extensions
 265 dnl -----------------
 266 AC_GNU_SOURCE
 267
 268 dnl -------
 269 dnl libtool
 270 dnl -------
 271 LT_INIT
 272
 273 dnl ----------------------
 274 dnl Packages configuration
 275 dnl ----------------------
 276 AC_ARG_WITH(pkg-extra-version,
 277         AS_HELP_STRING([--with-pkg-extra-version=VER], [add extra version field, for packagers/distributions]),
 278         [EXTRAVERSION=$withval],)
 279 AC_ARG_WITH(pkg-git-version,
 280         AS_HELP_STRING([--with-pkg-git-version], [add git information to MOTD and build version string]),
 281         [ test "x$withval" != "xno" && with_pkg_git_version="yes" ])
 282 AC_ARG_WITH(vtysh_pager,
 283         AS_HELP_STRING([--with-vtysh-pager=PAGER], [control what pager is compiled in as default]),
 284         VTYSH_PAGER=$withval, VTYSH_PAGER="more")
 285 AC_ARG_ENABLE(vtysh,
 286   AS_HELP_STRING([--disable-vtysh], [do not build integrated vty shell for FRR]))
 287 AC_ARG_ENABLE(doc,
 288   AS_HELP_STRING([--disable-doc], [do not build docs]))
 289 AC_ARG_ENABLE(zebra,
 290   AS_HELP_STRING([--disable-zebra], [do not build zebra daemon]))
 291 AC_ARG_ENABLE(bgpd,
 292   AS_HELP_STRING([--disable-bgpd], [do not build bgpd]))
 293 AC_ARG_ENABLE(ripd,
 294   AS_HELP_STRING([--disable-ripd], [do not build ripd]))
 295 AC_ARG_ENABLE(ripngd,
 296   AS_HELP_STRING([--disable-ripngd], [do not build ripngd]))
 297 AC_ARG_ENABLE(ospfd,
 298   AS_HELP_STRING([--disable-ospfd], [do not build ospfd]))
 299 AC_ARG_ENABLE(ospf6d,
 300   AS_HELP_STRING([--disable-ospf6d], [do not build ospf6d]))
 301 AC_ARG_ENABLE(ldpd,
 302   AS_HELP_STRING([--enable-ldpd], [build ldpd]))
 303 AC_ARG_ENABLE(nhrpd,
 304   AS_HELP_STRING([--disable-nhrpd], [do not build nhrpd]))
 305 AC_ARG_ENABLE(eigrpd,
 306   AS_HELP_STRING([--disable-eigrpd], [do not build eigrpd]))
 307 AC_ARG_ENABLE(babeld,
 308   AS_HELP_STRING([--disable-babeld], [do not build babeld]))
 309 AC_ARG_ENABLE(watchfrr,
 310   AS_HELP_STRING([--disable-watchfrr], [do not build watchfrr]))
 311 AC_ARG_ENABLE(isisd,
 312   AS_HELP_STRING([--disable-isisd], [do not build isisd]))
 313 AC_ARG_ENABLE(pimd,
 314   AS_HELP_STRING([--disable-pimd], [do not build pimd]))
 315 AC_ARG_ENABLE(bgp-announce,
 316   AS_HELP_STRING([--disable-bgp-announce,], [turn off BGP route announcement]))
 317 AC_ARG_ENABLE(bgp-vnc,
 318   AS_HELP_STRING([--disable-bgp-vnc],[turn off BGP VNC support]))
 319 AC_ARG_WITH(rfp-path,
 320   AS_HELP_STRING([--with-rfp-path[=DIR]],[path to replaced stub RFP used with BGP VNC]))
 321 AC_ARG_ENABLE(snmp,
 322   AS_HELP_STRING([--enable-snmp=ARG], [enable SNMP support (smux or agentx)]))
 323 AC_ARG_WITH(libpam,
 324   AS_HELP_STRING([--with-libpam], [use libpam for PAM support in vtysh]))
 325 AC_ARG_ENABLE(tcp-zebra,
 326   AS_HELP_STRING([--enable-tcp-zebra], [enable TCP/IP socket connection between zebra and protocol daemon]))
 327 AC_ARG_ENABLE(ospfapi,
 328   AS_HELP_STRING([--disable-ospfapi], [do not build OSPFAPI to access the OSPF LSA Database]))
 329 AC_ARG_ENABLE(ospfclient,
 330   AS_HELP_STRING([--disable-ospfclient], [do not build OSPFAPI client for OSPFAPI,
 331                           (this is the default if --disable-ospfapi is set)]))
 332 AC_ARG_ENABLE(multipath,
 333   AS_HELP_STRING([--enable-multipath=ARG], [enable multipath function, ARG must be digit]))
 334 AC_ARG_ENABLE(user,
 335   AS_HELP_STRING([--enable-user=USER], [user to run FRR suite as (default frr)]))
 336 AC_ARG_ENABLE(group,
 337   AS_HELP_STRING([--enable-group=GROUP], [group to run FRR suite as (default frr)]))
 338 AC_ARG_ENABLE(vty_group,
 339   AS_HELP_STRING([--enable-vty-group=ARG], [set vty sockets to have specified group as owner]))
 340 AC_ARG_ENABLE(configfile_mask,
 341   AS_HELP_STRING([--enable-configfile-mask=ARG], [set mask for config files]))
 342 AC_ARG_ENABLE(logfile_mask,
 343   AS_HELP_STRING([--enable-logfile-mask=ARG], [set mask for log files]))
 344 AC_ARG_ENABLE(shell_access,
 345   AS_HELP_STRING([--enable-shell-access], [Allow users to access shell/telnet/ssh]))
 346 AC_ARG_ENABLE(rtadv,
 347   AS_HELP_STRING([--disable-rtadv], [disable IPV6 router advertisement feature]))
 348 AC_ARG_ENABLE(irdp,
 349   AS_HELP_STRING([--enable-irdp], [enable IRDP server support in zebra]))
 350 AC_ARG_ENABLE(capabilities,
 351   AS_HELP_STRING([--disable-capabilities], [disable using POSIX capabilities]))
 352 AC_ARG_ENABLE(rusage,
 353   AS_HELP_STRING([--disable-rusage], [disable using getrusage]))
 354 AC_ARG_ENABLE(gcc_ultra_verbose,
 355   AS_HELP_STRING([--enable-gcc-ultra-verbose], [enable ultra verbose GCC warnings]))
 356 AC_ARG_ENABLE(linux24_tcp_md5,
 357   AS_HELP_STRING([--enable-linux24-tcp-md5], [enable support for old, Linux-2.4 RFC2385 patch]))
 358 AC_ARG_ENABLE(backtrace,
 359   AS_HELP_STRING([--disable-backtrace,], [disable crash backtraces (default autodetect)]))
 360 AC_ARG_ENABLE(time-check,
 361   AS_HELP_STRING([--disable-time-check], [disable slow thread warning messages]))
 362 AC_ARG_ENABLE(pcreposix,
 363   AS_HELP_STRING([--enable-pcreposix], [enable using PCRE Posix libs for regex functions]))
 364 AC_ARG_ENABLE(fpm,
 365   AS_HELP_STRING([--enable-fpm], [enable Forwarding Plane Manager support]))
 366 AC_ARG_ENABLE(systemd,
 367   AS_HELP_STRING([--enable-systemd], [enable Systemd support]))
 368 AC_ARG_ENABLE(werror,
 369   AS_HELP_STRING([--enable-werror], [enable -Werror (recommended for developers only)]))
 370 AC_ARG_ENABLE(cumulus,
 371   AS_HELP_STRING([--enable-cumulus], [enable Cumulus Switch Special Extensions]))
 372 AC_ARG_ENABLE(datacenter,
 373   AS_HELP_STRING([--enable-datacenter], [enable Compilation for Data Center Extensions]))
 374 AC_ARG_ENABLE(rr-semantics,
 375   AS_HELP_STRING([--disable-rr-semantics], [disable the v6 Route Replace semantics]))
 376 AC_ARG_ENABLE([protobuf],
 377   AS_HELP_STRING([--enable-protobuf], [Enable experimental protobuf support]))
 378 AC_ARG_ENABLE([oldvpn_commands],
 379   AS_HELP_STRING([--enable-oldvpn-commands], [Keep old vpn commands]))
 380
 381 AC_CHECK_HEADERS(json-c/json.h)
 382 AC_CHECK_LIB(json-c, json_object_get, LIBS="$LIBS -ljson-c")
 383 if test $ac_cv_lib_json_c_json_object_get = no; then
 384   AC_CHECK_LIB(json, json_object_get, LIBS="$LIBS -ljson")
 385   if test $ac_cv_lib_json_json_object_get = no; then
 386       AC_MSG_ERROR([lib json is needed to compile])
 387   fi
 388 fi
 389
 390 AC_ARG_ENABLE([dev_build],
 391     AS_HELP_STRING([--enable-dev-build], [build for development]))
 392
 393 if test x"${enable_time_check}" != x"no" ; then
 394   if test x"${enable_time_check}" = x"yes" -o x"${enable_time_check}" = x ; then
 395     AC_DEFINE(CONSUMED_TIME_CHECK,5000000,Consumed Time Check)
 396   else
 397     AC_DEFINE_UNQUOTED(CONSUMED_TIME_CHECK,$enable_time_check,Consumed Time Check)
 398   fi
 399 fi
 400
 401 case "${enable_systemd}" in
 402   "no") ;;
 403   "yes")
 404   AC_CHECK_LIB(systemd, sd_notify, LIBS="$LIBS -lsystemd")
 405   if test $ac_cv_lib_systemd_sd_notify = no; then
 406     AC_MSG_ERROR([enable systemd has been specified but systemd development env not found on your system])
 407   else
 408     AC_DEFINE(HAVE_SYSTEMD,,Compile systemd support in)
 409   fi
 410   ;;
 411   "*") ;;
 412 esac
 413
 414 if test "${enable_rr_semantics}" != "no" ; then
 415   AC_DEFINE(HAVE_V6_RR_SEMANTICS,, Compile in v6 Route Replacement Semantics)
 416 fi
 417
 418 if test "${enable_datacenter}" = "yes" ; then
 419   AC_DEFINE(HAVE_DATACENTER,,Compile extensions for a DataCenter)
 420   DFLT_NAME="datacenter"
 421 else
 422   DFLT_NAME="traditional"
 423 fi
 424
 425 if test "${enable_cumulus}" = "yes" ; then
 426   AC_DEFINE(HAVE_CUMULUS,,Compile Special Cumulus Code in)
 427 fi
 428
 429 AC_SUBST(DFLT_NAME)
 430 AC_DEFINE_UNQUOTED(DFLT_NAME,["$DFLT_NAME"], Name of the configuration default set)
 431
 432 if test "${enable_shell_access}" = "yes"; then
 433    AC_DEFINE(HAVE_SHELL_ACCESS,,Allow user to use ssh/telnet/bash)
 434 fi
 435
 436 AM_CONDITIONAL([FPM], [test "x$enable_fpm" = "xyes"])
 437
 438 if test "x${enable_dev_build}" = "xyes"; then
 439    AC_DEFINE(DEV_BUILD,,Build for development)
 440 fi
 441 AM_CONDITIONAL([DEV_BUILD], [test "x$enable_dev_build" = "xyes"])
 442
 443 #
 444 # Python for clippy
 445 #
 446 AS_IF([test "$host" = "$build"], [
 447   PYTHONCONFIG=""
 448
 449   # ordering:
 450   # 1.  try python3, but respect the user's preference on which minor ver
 451   # 2.  try python, which might be py3 or py2 again on the user's preference
 452   # 3.  try python2 (can really only be 2.7 but eh)
 453   # 4.  try 3.5 > 3.4 > 3.3 > 3.2 > 2.7 through pkg-config (no user pref)
 454   #
 455   # (AX_PYTHON_DEVEL has no clue about py3 vs py2)
 456   # (AX_PYTHON does not do what we need)
 457
 458   AC_CHECK_TOOLS([PYTHONCONFIG], [python3-config python-config python2-config])
 459   if test -n "$PYTHONCONFIG"; then
 460     PYTHON_CFLAGS="`\"${PYTHONCONFIG}\" --includes`"
 461     PYTHON_LIBS="`\"${PYTHONCONFIG}\" --libs`"
 462
 463     AC_MSG_CHECKING([whether we found a working Python version])
 464     AC_LINK_IFELSE_FLAGS([$PYTHON_CFLAGS], [$PYTHON_LIBS], [AC_LANG_PROGRAM([
 465 #include <Python.h>
 466 #if PY_VERSION_HEX < 0x02070000
 467 #error python too old
 468 #endif
 469 int main(void);
 470 ],
 471 [
 472 {
 473   Py_Initialize();
 474   return 0;
 475 }
 476 ])], [
 477       PYTHONCONFIG=""
 478       unset PYTHON_LIBS
 479       unset PYTHON_CFLAGS
 480     ])
 481   fi
 482
 483   if test -z "$PYTHONCONFIG"; then
 484     PKG_CHECK_MODULES([PYTHON], python-3.5, [], [
 485       PKG_CHECK_MODULES([PYTHON], python-3.4, [], [
 486         PKG_CHECK_MODULES([PYTHON], python-3.3, [], [
 487           PKG_CHECK_MODULES([PYTHON], python-3.2, [], [
 488             PKG_CHECK_MODULES([PYTHON], python-2.7, [], [
 489               AC_MSG_FAILURE([could not find python-config or pkg-config python, please install Python development files from libpython-dev or similar])
 490               ])])])])])
 491
 492
 493     AC_MSG_CHECKING([whether we found a working Python version])
 494     AC_LINK_IFELSE_FLAGS([$PYTHON_CFLAGS], [$PYTHON_LIBS], [AC_LANG_PROGRAM([
 495 #include <Python.h>
 496 #if PY_VERSION_HEX < 0x02070000
 497 #error python too old
 498 #endif
 499 int main(void);
 500 ],
 501 [
 502 {
 503   Py_Initialize();
 504   return 0;
 505 }
 506 ])], [
 507       AC_MSG_FAILURE([could not find python-config or pkg-config python, please install Python development files from libpython-dev or similar])
 508     ])
 509   fi
 510 ])
 511 AC_SUBST(PYTHON_CFLAGS)
 512 AC_SUBST(PYTHON_LIBS)
 513
 514 #
 515 # Logic for protobuf support.
 516 #
 517 if test "$enable_protobuf" = "yes"; then
 518    have_protobuf=yes
 519
 520    # Check for protoc-c
 521    AC_CHECK_PROG([PROTOC_C], [protoc-c], [protoc-c], [/bin/false])
 522    if test "x$PROTOC_C" = "x/bin/false"; then
 523       have_protobuf=no
 524    else
 525       found_protobuf_c=no
 526       PKG_CHECK_MODULES([PROTOBUF_C], libprotobuf-c >= 0.14,
 527                      [found_protobuf_c=yes],
 528                      [AC_MSG_RESULT([pkg-config did not find libprotobuf-c])])
 529
 530       if test "x$found_protobuf_c" = "xyes"; then
 531          LDFLAGS="$LDFLAGS $PROTOBUF_C_LIBS"
 532          CFLAGS="$CFLAGS $PROTOBUF_C_CFLAGS"
 533       else
 534         AC_CHECK_HEADER([google/protobuf-c/protobuf-c.h], [],
 535                         [have_protobuf=no; AC_MSG_RESULT([Couldn't find google/protobuf-c.h])])
 536       fi
 537    fi
 538 fi
 539
 540 #
 541 # Logic for old vpn commans support.
 542 #
 543 if test "$enable_oldvpn_commands" = "yes"; then
 544    AC_DEFINE(KEEP_OLD_VPN_COMMANDS,, [Define for compiling with old vpn commands])
 545 fi
 546
 547 # Fail if the user explicity enabled protobuf support and we couldn't
 548 # find the compiler or libraries.
 549 if test "x$have_protobuf" = "xno" && test "x$enable_protobuf" = "xyes"; then
 550    AC_MSG_ERROR([Protobuf enabled explicitly but can't find libraries/tools])
 551 fi
 552
 553 if test "x$have_protobuf" = "xyes"; then
 554    AC_DEFINE(HAVE_PROTOBUF,, protobuf)
 555 fi
 556
 557 AM_CONDITIONAL([HAVE_PROTOBUF], [test "x$have_protobuf" = "xyes"])
 558
 559 #
 560 # End of logic for protobuf support.
 561 #
 562
 563 if test "${enable_tcp_zebra}" = "yes"; then
 564   AC_DEFINE(HAVE_TCP_ZEBRA,,Use TCP for zebra communication)
 565 fi
 566
 567 if test "${enable_linux24_tcp_md5}" = "yes"; then
 568   AC_DEFINE(HAVE_TCP_MD5_LINUX24,,Old Linux 2.4 TCP MD5 Signature Patch)
 569 fi
 570
 571 AC_MSG_CHECKING(if zebra should be configurable to send Route Advertisements)
 572 if test "${enable_rtadv}" != "no"; then
 573   AC_MSG_RESULT(yes)
 574   AC_DEFINE(HAVE_RTADV,,Enable IPv6 Routing Advertisement support)
 575 else
 576   AC_MSG_RESULT(no)
 577 fi
 578
 579 if test "${enable_irdp}" = "yes"; then
 580   AC_DEFINE(HAVE_IRDP,, IRDP )
 581 fi
 582
 583 if test x"${enable_user}" = x"no"; then
 584   enable_user=""
 585 else
 586   if test x"${enable_user}" = x"yes" || test x"${enable_user}" = x""; then
 587     enable_user="frr"
 588   fi
 589   AC_DEFINE_UNQUOTED(FRR_USER, "${enable_user}", frr User)
 590 fi
 591
 592 if test x"${enable_group}" = x"no"; then
 593   enable_group=""
 594 else
 595   if test x"${enable_group}" = x"yes" || test x"${enable_group}" = x""; then
 596     enable_group="frr"
 597   fi
 598   AC_DEFINE_UNQUOTED(FRR_GROUP, "${enable_group}", frr Group)
 599 fi
 600
 601 if test x"${enable_vty_group}" = x"yes" ; then
 602   AC_MSG_ERROR([--enable-vty-group requires a group as argument, not yes])
 603 elif test x"${enable_vty_group}" != x""; then
 604   if test x"${enable_vty_group}" != x"no"; then
 605     AC_DEFINE_UNQUOTED(VTY_GROUP, "${enable_vty_group}", VTY Sockets Group)
 606   fi
 607 fi
 608 AC_SUBST([enable_user])
 609 AC_SUBST([enable_group])
 610 AC_SUBST([enable_vty_group])
 611
 612 enable_configfile_mask=${enable_configfile_mask:-0600}
 613 AC_DEFINE_UNQUOTED(CONFIGFILE_MASK, ${enable_configfile_mask}, Mask for config files)
 614
 615 enable_logfile_mask=${enable_logfile_mask:-0600}
 616 AC_DEFINE_UNQUOTED(LOGFILE_MASK, ${enable_logfile_mask}, Mask for log files)
 617
 618 MPATH_NUM=1
 619
 620 case "${enable_multipath}" in
 621   0)
 622     MPATH_NUM=64
 623     ;;
 624   [[1-9]|[1-9][0-9]|[1-9][0-9][0-9]])
 625     MPATH_NUM="${enable_multipath}"
 626     ;;
 627   "")
 628     ;;
 629   *)
 630     AC_MSG_FAILURE([Please specify digit to enable multipath ARG])
 631     ;;
 632 esac
 633
 634 AC_DEFINE_UNQUOTED(MULTIPATH_NUM, $MPATH_NUM, Maximum number of paths for a route)
 635
 636 AC_DEFINE_UNQUOTED(VTYSH_PAGER, "$VTYSH_PAGER", [What pager to use])
 637
 638 dnl -----------------------------------
 639 dnl Add extra version string to package
 640 dnl name, string and version fields.
 641 dnl -----------------------------------
 642 if test "x${EXTRAVERSION}" != "x" ; then
 643   VERSION="${VERSION}${EXTRAVERSION}"
 644   PACKAGE_VERSION="${PACKAGE_VERSION}${EXTRAVERSION}"
 645   AC_SUBST(PACKAGE_EXTRAVERSION, ["${EXTRAVERSION}"])
 646   PACKAGE_STRING="${PACKAGE_STRING}${EXTRAVERSION}"
 647 fi
 648
 649 if test "x$with_pkg_git_version" = "xyes"; then
 650         if test -d "${srcdir}/.git"; then
 651                 AC_DEFINE(GIT_VERSION, [1], [include git version info])
 652         else    with_pkg_git_version="no"
 653                 AC_MSG_WARN([--with-pkg-git-version given, but this is not a git checkout])
 654         fi
 655 fi
 656 AM_CONDITIONAL([GIT_VERSION], [test "x$with_pkg_git_version" = "xyes"])
 657
 658 dnl ------------------------------------
 659 dnl Check C keywords and standard  types
 660 dnl ------------------------------------
 661 AC_C_CONST
 662 AC_C_INLINE
 663 AC_C_VOLATILE
 664 AC_HEADER_STDC
 665 dnl AC_TYPE_PID_T
 666 AC_TYPE_UID_T
 667 AC_TYPE_MODE_T
 668 AC_TYPE_SIZE_T
 669 AC_STRUCT_TM
 670
 671 dnl -------------------------
 672 dnl Check other header files.
 673 dnl -------------------------
 674 AC_CHECK_HEADERS([stropts.h sys/ksym.h \
 675         linux/version.h asm/types.h \
 676         sys/cdefs.h])
 677
 678 ac_stdatomic_ok=false
 679 AC_DEFINE(FRR_AUTOCONF_ATOMIC, 1, [did autoconf checks for atomic funcs])
 680 AC_CHECK_HEADER([stdatomic.h],[
 681
 682   AC_MSG_CHECKING([whether _Atomic qualifier works])
 683   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 684 #include <stdatomic.h>
 685 int main(int argc, char **argv) {
 686   _Atomic int i = 0;
 687   return i;
 688 }
 689 ]])], [
 690     AC_DEFINE(HAVE_STDATOMIC_H, 1, [found stdatomic.h])
 691     AC_MSG_RESULT([yes])
 692     ac_stdatomic_ok=true
 693   ], [
 694     AC_MSG_RESULT([no])
 695   ])
 696 ])
 697
 698 AS_IF([$ac_stdatomic_ok], [true], [
 699   AC_MSG_CHECKING([for __atomic_* builtins])
 700   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 701 int main(int argc, char **argv) {
 702   volatile int i = 1;
 703   __atomic_store_n (&i, 0, __ATOMIC_RELEASE);
 704   return __atomic_load_n (&i, __ATOMIC_ACQUIRE);
 705 }
 706 ]])], [
 707     AC_DEFINE(HAVE___ATOMIC, 1, [found __atomic builtins])
 708     AC_MSG_RESULT([yes])
 709   ], [
 710     AC_MSG_RESULT([no])
 711
 712     dnl FreeBSD 9 has a broken stdatomic.h where _Atomic doesn't work
 713     AC_MSG_CHECKING([for __sync_* builtins])
 714     AC_LINK_IFELSE([AC_LANG_SOURCE([[
 715 int main(int argc, char **argv) {
 716   volatile int i = 1;
 717   __sync_fetch_and_sub (&i, 1);
 718   return __sync_val_compare_and_swap (&i, 0, 1);
 719 }
 720 ]])], [
 721       AC_DEFINE(HAVE___SYNC, 1, [found __sync builtins])
 722       AC_MSG_RESULT([yes])
 723
 724       AC_MSG_CHECKING([for __sync_swap builtin])
 725       AC_LINK_IFELSE([AC_LANG_SOURCE([[
 726 int main(int argc, char **argv) {
 727   volatile int i = 1;
 728   return __sync_swap (&i, 2);
 729 }
 730 ]])], [
 731         AC_DEFINE(HAVE___SYNC_SWAP, 1, [found __sync_swap builtin])
 732         AC_MSG_RESULT([yes])
 733       ], [
 734         AC_MSG_RESULT([no])
 735       ])
 736
 737     ], [
 738       AC_MSG_RESULT([no])
 739       AC_MSG_FAILURE([stdatomic.h unavailable and $CC has neither __atomic nor __sync builtins])
 740     ])
 741   ])
 742 ])
 743
 744 dnl Utility macro to avoid retyping includes all the time
 745 m4_define([FRR_INCLUDES],
 746 [#ifdef SUNOS_5
 747 #define _XPG4_2
 748 #define __EXTENSIONS__
 749 #endif
 750 #include <stdio.h>
 751 #include <stdlib.h>
 752 #include <stddef.h>
 753 #include <sys/types.h>
 754 /* sys/conf.h depends on param.h on FBSD at least */
 755 #include <sys/param.h>
 756 /* Required for MAXSIG */
 757 #include <signal.h>
 758 #include <sys/socket.h>
 759 #ifdef __APPLE__
 760 # define __APPLE_USE_RFC_3542
 761 #endif
 762 #include <netinet/in.h>
 763 #include <sys/time.h>
 764 #include <time.h>
 765 #include <net/if.h>
 766 ])dnl
 767
 768 dnl Same applies for HAVE_NET_IF_VAR_H, which HAVE_NETINET6_ND6_H and
 769 dnl HAVE_NETINET_IN_VAR_H depend upon. But if_var.h depends on if.h, hence
 770 dnl an additional round for it.
 771
 772 AC_CHECK_HEADERS([net/if_var.h], [], [], FRR_INCLUDES)
 773
 774 m4_define([FRR_INCLUDES],
 775 FRR_INCLUDES
 776 [#if HAVE_NET_IF_VAR_H
 777 # include <net/if_var.h>
 778 #endif
 779 ])dnl
 780
 781 AC_CHECK_HEADERS([netinet/in_var.h \
 782         net/if_dl.h net/netopt.h \
 783         inet/nd.h netinet/ip_icmp.h \
 784         sys/sysctl.h sys/sockio.h kvm.h sys/conf.h],
 785         [], [], FRR_INCLUDES)
 786
 787 AC_CHECK_HEADERS([ucontext.h], [], [],
 788 [#ifndef __USE_GNU
 789 #define __USE_GNU
 790 #endif /* __USE_GNU */
 791 FRR_INCLUDES
 792 ])
 793
 794 m4_define([UCONTEXT_INCLUDES],
 795 [#include <ucontext.h>])dnl
 796
 797 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.uc_regs],
 798   [], [], [UCONTEXT_INCLUDES])
 799 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs],
 800   [AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs.nip],
 801    [], [], [UCONTEXT_INCLUDES])],
 802   [], [UCONTEXT_INCLUDES])
 803 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.gregs],
 804   [], [], [UCONTEXT_INCLUDES])
 805
 806 m4_define([FRR_INCLUDES],
 807 FRR_INCLUDES
 808 [
 809 #include <sys/un.h>
 810 #include <netinet/in_systm.h>
 811 #if HAVE_NETINET_IN_VAR_H
 812 # include <netinet/in_var.h>
 813 #endif
 814 #if HAVE_NET_IF_DL_H
 815 # include <net/if_dl.h>
 816 #endif
 817 #if HAVE_NET_NETOPT_H
 818 # include <net/netopt.h>
 819 #endif
 820 #include <net/route.h>
 821 #if HAVE_INET_ND_H
 822 # include <inet/nd.h>
 823 #endif
 824 #include <arpa/inet.h>
 825 /* Required for IDRP */
 826 #if HAVE_NETINET_IP_ICMP_H
 827 # include <netinet/ip_icmp.h>
 828 #endif
 829 ])dnl
 830
 831 dnl V6 headers are checked below, after we check for v6
 832
 833 AC_MSG_CHECKING([which operating system interface to use])
 834 case "$host_os" in
 835   sunos* | solaris2*)
 836     AC_MSG_RESULT([Solaris])
 837
 838     AC_DEFINE(SUNOS_5, 1, [SunOS 5])
 839     AC_DEFINE(SOLARIS_IPV6, 1, Solaris IPv6)
 840
 841     AC_CHECK_LIB(socket, main)
 842     AC_CHECK_LIB(nsl, main)
 843     AC_CHECK_LIB(umem, main)
 844     AC_CHECK_FUNCS([printstack], [
 845       AC_DEFINE([HAVE_PRINTSTACK],1,[Solaris printstack])
 846       AC_DEFINE([HAVE_STACK_TRACE],1,[Stack symbols decode functionality])
 847     ])
 848     CURSES=-lcurses
 849     SOLARIS="solaris"
 850     ;;
 851   linux*)
 852     AC_MSG_RESULT([Linux])
 853
 854     AC_DEFINE(GNU_LINUX,,GNU Linux)
 855     AC_DEFINE(HAVE_NETLINK,,netlink)
 856     AC_DEFINE(LINUX_IPV6,1,Linux IPv6 stack)
 857
 858     dnl Linux has a compilation problem with mixing
 859     dnl netinet/in.h and linux/in6.h they are not
 860     dnl compatible.  There has been discussion on
 861     dnl how to fix it but no real progress on implementation
 862     dnl when they fix it, remove this
 863     AC_DEFINE(IPV6_MINHOPCOUNT, 73, Linux ipv6 Min Hop Count)
 864
 865     AC_CHECK_DECLS([IFLA_INFO_SLAVE_KIND], [], [], [#include <linux/if_link.h>])
 866     ;;
 867   openbsd*)
 868     AC_MSG_RESULT([OpenBSD])
 869
 870     AC_DEFINE(OPEN_BSD,,OpenBSD)
 871     AC_DEFINE(KAME,1,KAME IPv6)
 872     ;;
 873   *)
 874     AC_MSG_RESULT([BSD])
 875
 876     AC_DEFINE(HAVE_NET_RT_IFLIST,,NET_RT_IFLIST)
 877     AC_DEFINE(KAME,1,KAME IPv6)
 878     ;;
 879 esac
 880
 881 AC_SYS_LARGEFILE
 882
 883 dnl ---------------------
 884 dnl Integrated VTY option
 885 dnl ---------------------
 886 case "${enable_vtysh}" in
 887   "no") VTYSH="";;
 888   *)    VTYSH="vtysh";
 889          AC_DEFINE(VTYSH,,VTY shell)
 890 dnl      Vtysh uses libreadline, which looks for termcap functions at
 891 dnl      configure time.  We follow readlines search order.
 892 dnl      The required procedures are in libtermcap on NetBSD, in
 893 dnl      [TODO] on Linux, and in [TODO] on Solaris.
 894          AC_CHECK_LIB(termcap, tputs, LIBREADLINE="$LIBREADLINE -ltermcap",
 895            [AC_CHECK_LIB(tinfo, tputs, LIBREADLINE="$LIBREADLINE -ltinfo",
 896              [AC_CHECK_LIB(curses, tputs, LIBREADLINE="$LIBREADLINE -lcurses",
 897                [AC_CHECK_LIB(ncurses, tputs,
 898                              LIBREADLINE="$LIBREADLINE -lncurses")]
 899               )]
 900             )]
 901           )
 902          AC_CHECK_LIB(readline, main, LIBREADLINE="-lreadline $LIBREADLINE",,
 903                       "$LIBREADLINE")
 904          if test $ac_cv_lib_readline_main = no; then
 905            AC_MSG_ERROR([vtysh needs libreadline but was not found and usable on your system.])
 906          fi
 907          AC_CHECK_HEADER(readline/history.h)
 908          if test $ac_cv_header_readline_history_h = no;then
 909            AC_MSG_ERROR([readline is too old to have readline/history.h, please update to the latest readline library.])
 910          fi
 911          AC_CHECK_LIB(readline, rl_completion_matches,
 912                       LIBREADLINE="$LIBREADLINE",, "$LIBREADLINE")
 913          if test $ac_cv_lib_readline_rl_completion_matches = no; then
 914            AC_DEFINE(rl_completion_matches,completion_matches,Old readline)
 915          fi
 916          ;;
 917 esac
 918 AC_SUBST(LIBREADLINE)
 919 AM_CONDITIONAL(VTYSH, test "x$VTYSH" = "xvtysh")
 920
 921 dnl ----------
 922 dnl PAM module
 923 dnl
 924 dnl FRR detects the PAM library it is built against by checking for a
 925 dnl functional pam_misc.h (Linux-PAM) or openpam.h (OpenPAM) header. pam_misc.h
 926 dnl is known to #include pam_appl.h, the standard header of a PAM library, and
 927 dnl openpam.h doesn't do that, although depends on the header too. Hence a
 928 dnl little assistance to AC_CHECK_HEADER is necessary for the proper detection
 929 dnl of OpenPAM.
 930 dnl ----------
 931 if test "$with_libpam" = "yes"; then
 932   AC_CHECK_HEADER([security/pam_misc.h],
 933     [AC_DEFINE(HAVE_PAM_MISC_H,,Have pam_misc.h)
 934      AC_DEFINE(PAM_CONV_FUNC,misc_conv,Have misc_conv)
 935      pam_conv_func="misc_conv"
 936     ],
 937     [], FRR_INCLUDES)
 938   AC_CHECK_HEADER([security/openpam.h],
 939     [AC_DEFINE(HAVE_OPENPAM_H,,Have openpam.h)
 940      AC_DEFINE(PAM_CONV_FUNC,openpam_ttyconv,Have openpam_ttyconv)
 941      pam_conv_func="openpam_ttyconv"
 942     ],
 943     [], FRR_INCLUDES[#include <security/pam_appl.h>])
 944   if test -z "$ac_cv_header_security_pam_misc_h$ac_cv_header_security_openpam_h" ; then
 945     AC_MSG_WARN([*** pam support will not be built ***])
 946     with_libpam="no"
 947   fi
 948 fi
 949
 950 if test "$with_libpam" = "yes"; then
 951 dnl took this test from proftpds configure.in and suited to our needs
 952 dnl -------------------------------------------------------------------------
 953 dnl
 954 dnl This next check looks funky due to a linker problem with some versions
 955 dnl of the PAM library.  Prior to 0.72 release, the Linux PAM shared library
 956 dnl omitted requiring libdl linking information. PAM-0.72 or better ships
 957 dnl with RedHat 6.2 and Debian 2.2 or better.
 958 AC_CHECK_LIB(pam, pam_start,
 959   [AC_CHECK_LIB(pam, $pam_conv_func,
 960     [AC_DEFINE(USE_PAM,,Use PAM for authentication)
 961      LIBPAM="-lpam"],
 962     [AC_DEFINE(USE_PAM,,Use PAM for authentication)
 963      LIBPAM="-lpam -lpam_misc"]
 964     )
 965   ],
 966
 967   [AC_CHECK_LIB(pam, pam_end,
 968     [AC_CHECK_LIB(pam, $pam_conv_func,
 969       [AC_DEFINE(USE_PAM,,Use PAM for authentication)
 970        LIBPAM="-lpam -ldl"],
 971       [AC_DEFINE(USE_PAM,,Use PAM for authentication)
 972        LIBPAM="-lpam -ldl -lpam_misc"]
 973      )
 974   ],AC_MSG_WARN([*** pam support will not be built ***]),
 975   [-ldl])
 976   ]
 977 )
 978 fi
 979 AC_SUBST(LIBPAM)
 980
 981 dnl -------------------------------
 982 dnl Endian-ness check
 983 dnl -------------------------------
 984 AC_WORDS_BIGENDIAN
 985
 986 dnl -------------------------------
 987 dnl check the size in byte of the C
 988 dnl -------------------------------
 989 dnl AC_CHECK_SIZEOF(char)
 990 dnl AC_CHECK_SIZEOF(int)
 991 dnl AC_CHECK_SIZEOF(short)
 992 dnl AC_CHECK_SIZEOF(long)
 993
 994 dnl ----------------------------
 995 dnl check existance of functions
 996 dnl ----------------------------
 997 AC_FUNC_FNMATCH
 998 AC_FUNC_FORK
 999 AC_FUNC_MKTIME
1000 AC_FUNC_STAT
1001
1002 dnl -------------------------------
1003 dnl bgpd needs pow() and hence libm
1004 dnl -------------------------------
1005 TMPLIBS="$LIBS"
1006 AC_CHECK_HEADER([math.h],
1007   [AC_CHECK_LIB([m], [pow],
1008     [LIBM="-lm"
1009      LIBS="$LIBS $LIBM"
1010      AC_CHECK_FUNCS(pow,[],[LIBM=""])
1011     ])
1012 ])
1013 if test x"$LIBM" = x ; then
1014   AC_MSG_WARN([Unable to find working pow function - bgpd may not link])
1015 fi
1016 LIBS="$TMPLIBS"
1017 AC_SUBST(LIBM)
1018
1019 dnl ---------------
1020 dnl other functions
1021 dnl ---------------
1022 AC_CHECK_FUNCS([ \
1023         strlcat strlcpy \
1024         getgrouplist])
1025
1026 AC_CHECK_HEADER([asm-generic/unistd.h],
1027                 [AC_CHECK_DECL(__NR_setns,
1028                                AC_DEFINE(HAVE_NETNS,, Have netns),,
1029                                FRR_INCLUDES [#include <asm-generic/unistd.h>
1030                                ])
1031                  AC_CHECK_FUNCS(setns)]
1032                )
1033
1034 dnl --------------------------
1035 dnl Determine IS-IS I/O method
1036 dnl --------------------------
1037 AC_DEFINE(ISIS_METHOD_PFPACKET, 1, [ constant value for isis method pfpacket ])
1038 AC_DEFINE(ISIS_METHOD_DLPI,     2, [ constant value for isis method dlpi ])
1039 AC_DEFINE(ISIS_METHOD_BPF,      3, [ constant value for isis method bpf ])
1040 AC_CHECK_HEADER(net/bpf.h)
1041 AC_CHECK_HEADER(sys/dlpi.h)
1042 AC_MSG_CHECKING(zebra IS-IS I/O method)
1043
1044 case "$host_os" in
1045   linux*)
1046     AC_MSG_RESULT(pfpacket)
1047     ISIS_METHOD_MACRO="ISIS_METHOD_PFPACKET"
1048     ;;
1049   solaris* | sunos*)
1050     AC_MSG_RESULT(DLPI)
1051     ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1052     ;;
1053   *)
1054     if test $ac_cv_header_net_bpf_h = no; then
1055       if test $ac_cv_header_sys_dlpi_h = no; then
1056         AC_MSG_RESULT(none)
1057         AC_MSG_WARN([*** IS-IS support will not be built ***])
1058         ISISD=""
1059       else
1060         AC_MSG_RESULT(DLPI)
1061       fi
1062       ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1063     else
1064       AC_MSG_RESULT(BPF)
1065       ISIS_METHOD_MACRO="ISIS_METHOD_BPF"
1066     fi
1067     ;;
1068 esac
1069 AC_DEFINE_UNQUOTED(ISIS_METHOD, $ISIS_METHOD_MACRO, [ selected method for isis, == one of the constants ])
1070
1071 dnl ------------------------------------
1072 dnl check for broken CMSG_FIRSTHDR macro
1073 dnl ------------------------------------
1074 AC_MSG_CHECKING(for broken CMSG_FIRSTHDR)
1075 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1076 #ifdef SUNOS_5
1077 #define _XPG4_2
1078 #define __EXTENSIONS__
1079 #endif
1080 #include <stdlib.h>
1081 #include <sys/types.h>
1082 #include <sys/socket.h>
1083
1084 main()
1085 {
1086   struct msghdr msg;
1087   char buf[4];
1088
1089   msg.msg_control = buf;
1090   msg.msg_controllen = 0;
1091
1092   if (CMSG_FIRSTHDR(&msg) != NULL)
1093     exit(0);
1094   exit (1);
1095 }]])],[AC_MSG_RESULT(yes - using workaround) AC_DEFINE(HAVE_BROKEN_CMSG_FIRSTHDR,,Broken CMSG_FIRSTHDR)],
1096 [AC_MSG_RESULT(no)],[AC_MSG_RESULT(no)])
1097
1098 dnl ---------------------------------------------------------------
1099 dnl figure out how to specify an interface in multicast sockets API
1100 dnl ---------------------------------------------------------------
1101 AC_CHECK_MEMBERS([struct ip_mreqn.imr_ifindex], [], [], FRR_INCLUDES)
1102
1103 AC_CHECK_HEADERS([linux/mroute.h], [], [],[
1104         #include <sys/socket.h>
1105         #include <netinet/in.h>
1106         #define _LINUX_IN_H             /* For Linux <= 2.6.25 */
1107         #include <linux/types.h>
1108 ])
1109
1110 m4_define([FRR_INCLUDES],
1111 FRR_INCLUDES
1112 [#if HAVE_LINUX_MROUTE_H
1113 # include <linux/mroute.h>
1114 #endif
1115 ])dnl
1116
1117 AC_CHECK_HEADERS([netinet/ip_mroute.h], [], [],[
1118         #include <sys/socket.h>
1119         #include <sys/types.h>
1120         #include <netinet/in.h>
1121         #include <net/route.h>
1122 ])
1123
1124 m4_define([FRR_INCLUDES],
1125 FRR_INCLUDES
1126 [#if HAVE_NETINET_IP_MROUTE_H
1127 # include <netinet/ip_mroute.h>
1128 #endif
1129 ])dnl
1130
1131 AC_MSG_CHECKING([for BSD struct ip_mreq hack])
1132 AC_TRY_COMPILE([#include <sys/param.h>],
1133 [#if (defined(__FreeBSD__) && ((__FreeBSD_version >= 500022 && __FreeBSD_version < 700000) || (__FreeBSD_version < 500000 && __FreeBSD_version >= 440000))) || (defined(__NetBSD__) && defined(__NetBSD_Version__) && __NetBSD_Version__ >= 106010000) || defined(__OpenBSD__) || defined(__APPLE__) || defined(__DragonFly__) || defined(__sun)
1134   return (0);
1135 #else
1136   #error No support for BSD struct ip_mreq hack detected
1137 #endif],[AC_MSG_RESULT(yes)
1138 AC_DEFINE(HAVE_BSD_STRUCT_IP_MREQ_HACK,,[Can pass ifindex in struct ip_mreq])],
1139 AC_MSG_RESULT(no))
1140
1141 AC_MSG_CHECKING([for RFC3678 protocol-independed API])
1142 AC_TRY_COMPILE([
1143 #include <sys/types.h>
1144 #include <netinet/in.h>
1145 ], [struct group_req gr; int sock; setsockopt(sock, IPPROTO_IP, MCAST_JOIN_GROUP, (void*)&gr, sizeof(gr));
1146 ], [AC_MSG_RESULT(yes)
1147 AC_DEFINE(HAVE_RFC3678,1,[Have RFC3678 protocol-independed API])],
1148 AC_MSG_RESULT(no))
1149
1150 dnl ---------------------------------------------------------------
1151 dnl figure out how to check link-state
1152 dnl ---------------------------------------------------------------
1153 AC_CHECK_HEADER( [net/if_media.h],
1154   [m4_define([LINK_DETECT_INCLUDES],
1155     FRR_INCLUDES
1156     [#include <net/if_media.h>
1157   ])
1158   AC_CHECK_MEMBERS( [struct ifmediareq.ifm_status],
1159     AC_DEFINE(HAVE_BSD_LINK_DETECT,,[BSD link-detect]),
1160     [], LINK_DETECT_INCLUDES)],
1161   [],
1162   FRR_INCLUDES)
1163
1164 dnl ---------------------------------------------------------------
1165 dnl Additional, newer way to check link-state using ifi_link_state.
1166 dnl Not available in all BSD's when ifmediareq available
1167 dnl ---------------------------------------------------------------
1168 AC_CHECK_MEMBERS([struct if_data.ifi_link_state],
1169   AC_DEFINE(HAVE_BSD_IFI_LINK_STATE,,[BSD ifi_link_state available]),
1170   [], FRR_INCLUDES)
1171
1172 dnl ------------------------
1173 dnl TCP_MD5SIG socket option
1174 dnl ------------------------
1175
1176 AC_CHECK_HEADER([netinet/tcp.h],
1177    [m4_define([MD5_INCLUDES],
1178       FRR_INCLUDES
1179       [#include <netinet/tcp.h>
1180     ])
1181     AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)],
1182    [],
1183    FRR_INCLUDES)
1184 if test $ac_cv_have_decl_TCP_MD5SIG = no; then
1185   AC_CHECK_HEADER([linux/tcp.h],
1186        [m4_define([MD5_INCLUDES],
1187           FRR_INCLUDES
1188           [#include <linux/tcp.h>
1189         ])
1190        AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)])
1191 fi
1192
1193 dnl ----------------------------------------------------------------------------
1194 dnl figure out if domainname is available in the utsname struct (GNU extension).
1195 dnl ----------------------------------------------------------------------------
1196 AC_CHECK_MEMBERS([struct utsname.domainname], [], [], [#include <sys/utsname.h>])
1197
1198 dnl ------------------
1199 dnl IPv6 header checks
1200 dnl ------------------
1201 AC_CHECK_HEADERS([netinet6/in6.h netinet/in6_var.h \
1202         netinet6/in6_var.h netinet6/nd6.h], [], [],
1203         FRR_INCLUDES)
1204
1205 m4_define([FRR_INCLUDES],dnl
1206 FRR_INCLUDES
1207 [#if HAVE_NETINET6_IN6_H
1208 #include <netinet6/in6.h>
1209 #endif
1210 #if HAVE_NETINET_IN6_VAR_H
1211 #include <netinet/in6_var.h>
1212 #endif
1213 #include <netinet/icmp6.h>
1214 #if HAVE_NETINET6_IN6_VAR_H
1215 # include <netinet6/in6_var.h>
1216 #endif
1217 #if HAVE_NETINET6_ND6_H
1218 # include <netinet6/nd6.h>
1219 #endif
1220 ])dnl
1221
1222 dnl disable doc check
1223 if test "${enable_doc}" = "no";then
1224   DOC=""
1225 else
1226   DOC="doc"
1227 fi
1228
1229 dnl --------------------
1230 dnl Daemon disable check
1231 dnl --------------------
1232 AM_CONDITIONAL(ZEBRA, test "${enable_zebra}" != "no")
1233
1234 if test "${enable_bgpd}" = "no";then
1235   BGPD=""
1236 else
1237   BGPD="bgpd"
1238 fi
1239 AM_CONDITIONAL(BGPD, test "x$BGPD" = "xbgpd")
1240
1241 if test "${enable_ripd}" = "no";then
1242   RIPD=""
1243 else
1244   RIPD="ripd"
1245 fi
1246 AM_CONDITIONAL(RIPD, test "x$RIPD" = "xripd")
1247
1248 if test "${enable_ospfd}" = "no";then
1249   OSPFD=""
1250 else
1251   OSPFD="ospfd"
1252 fi
1253 AM_CONDITIONAL(OSPFD, test "x$OSPFD" = "xospfd")
1254
1255 if test "${enable_ldpd}" = "no";then
1256   LDPD=""
1257 else
1258   LDPD="ldpd"
1259   AC_DEFINE(HAVE_LDPD, 1, ldpd)
1260 fi
1261 AM_CONDITIONAL(LDPD, test "x$LDPD" = "xldpd")
1262
1263 NHRPD=""
1264 case "$host_os" in
1265   linux*)
1266     if test "${enable_nhrpd}" != "no"; then
1267       NHRPD="nhrpd"
1268     fi
1269     ;;
1270   *)
1271     if test "${enable_nhrpd}" = "yes"; then
1272       AC_MSG_ERROR([nhrpd requires kernel APIs that are only present on Linux.])
1273     fi
1274     ;;
1275 esac
1276 AM_CONDITIONAL(NHRPD, test "x$NHRPD" = "xnhrpd")
1277
1278 if test "${enable_eigrpd}" = "no";then
1279   EIGRPD=""
1280 else
1281   EIGRPD="eigrpd"
1282 fi
1283 AM_CONDITIONAL(EIGRPD, test "x$EIGRPD" = "xeigrpd")
1284
1285 if test "${enable_watchfrr}" = "no";then
1286   WATCHFRR=""
1287 else
1288   WATCHFRR="watchfrr"
1289 fi
1290 AM_CONDITIONAL(WATCHFRR, test "x$WATCHFRR" = "xwatchfrr")
1291
1292 OSPFCLIENT=""
1293 if test "${enable_ospfapi}" != "no";then
1294     AC_DEFINE(SUPPORT_OSPF_API,,OSPFAPI)
1295
1296   if test "${enable_ospfclient}" != "no";then
1297       OSPFCLIENT="ospfclient"
1298   fi
1299 fi
1300
1301 AM_CONDITIONAL(OSPFCLIENT, test "x$OSPFCLIENT" = "xospfclient")
1302
1303 case "${enable_ripngd}" in
1304   "no" ) RIPNGD="";;
1305   *    ) RIPNGD="ripngd";;
1306 esac
1307 AM_CONDITIONAL(RIPNGD, test "x$RIPNGD" = "xripngd")
1308
1309 case "${enable_babeld}" in
1310   "no" ) BABELD="";;
1311   *    ) BABELD="babeld";;
1312 esac
1313 AM_CONDITIONAL(BABELD, test "x$BABELD" = "xbabeld")
1314
1315 case "${enable_ospf6d}" in
1316   "no" ) OSPF6D="";;
1317   *    ) OSPF6D="ospf6d";;
1318 esac
1319 AM_CONDITIONAL(OSPF6D, test "x$OSPF6D" = "xospf6d")
1320
1321 case "${enable_isisd}" in
1322   "no" ) ISISD="";;
1323   *    ) ISISD="isisd";;
1324 esac
1325 AM_CONDITIONAL(ISISD, test "x$ISISD" = "xisisd")
1326
1327 case "${enable_pimd}" in
1328   "no" ) PIMD="";;
1329   *    ) PIMD="pimd";;
1330 esac
1331 AM_CONDITIONAL(PIMD, test "x$PIMD" = "xpimd")
1332
1333 if test "${enable_bgp_announce}" = "no";then
1334   AC_DEFINE(DISABLE_BGP_ANNOUNCE,1,Disable BGP installation to zebra)
1335 else
1336   AC_DEFINE(DISABLE_BGP_ANNOUNCE,0,Disable BGP installation to zebra)
1337 fi
1338
1339 if test "${with_rfp_path}" = "yes" || test x"${with_rfp_path}" = x""; then
1340   with_rfp_path="bgpd/rfp-example"
1341 fi
1342 if test "${with_rfp_path}" != "no"; then
1343   VNC_RFP_PATH="${with_rfp_path}"
1344   AC_SUBST(VNC_RFP_PATH)
1345 fi
1346
1347 if test "${enable_bgp_vnc}" != "no";then
1348   AC_DEFINE(ENABLE_BGP_VNC,1,Enable BGP VNC support)
1349   RFPTEST="${with_rfp_path}/rfptest"
1350   LIBRFP="${with_rfp_path}/librfp"
1351   RFPINC="${with_rfp_path}/librfp"
1352 else
1353   RFPTEST=
1354   LIBRFP=
1355   RFPINC="bgpd/rfp-example/librfp"
1356 fi
1357 # set
1358 AM_CONDITIONAL([ENABLE_BGP_VNC], [test x${enable_bgp_vnc} != xno])
1359
1360 AC_SUBST(DOC)
1361 AC_SUBST(RFPTEST)
1362 AC_SUBST(LIBRFP)
1363 AC_SUBST(RFPINC)
1364 AC_SUBST(BABELD)
1365 AC_SUBST(BGPD)
1366 AC_SUBST(RIPD)
1367 AC_SUBST(RIPNGD)
1368 AC_SUBST(OSPFD)
1369 AC_SUBST(OSPF6D)
1370 AC_SUBST(LDPD)
1371 AC_SUBST(NHRPD)
1372 AC_SUBST(EIGRPD)
1373 AC_SUBST(WATCHFRR)
1374 AC_SUBST(ISISD)
1375 AC_SUBST(PIMD)
1376 AC_SUBST(SOLARIS)
1377 AC_SUBST(VTYSH)
1378 AC_SUBST(CURSES)
1379 AC_SUBST(OSPFCLIENT)
1380 AC_SUBST(OSPFAPI)
1381 AC_CHECK_LIB(crypt, crypt)
1382 AC_CHECK_LIB(resolv, res_init)
1383
1384 dnl ---------------------------
1385 dnl check system has PCRE regexp
1386 dnl ---------------------------
1387 if test "x$enable_pcreposix" = "xyes"; then
1388   AC_CHECK_LIB(pcreposix, regexec, [], [
1389     AC_MSG_ERROR([--enable-pcreposix given but unable to find libpcreposix])
1390   ])
1391 fi
1392 AC_SUBST(HAVE_LIBPCREPOSIX)
1393
1394 dnl ------------------
1395 dnl check C-Ares library
1396 dnl ------------------
1397 if test "${NHRPD}" != ""; then
1398   PKG_CHECK_MODULES([CARES], [libcares], , [
1399     AC_MSG_ERROR([trying to build nhrpd, but libcares not found. install c-ares and its -dev headers.])
1400   ])
1401 fi
1402
1403
1404 dnl ------------------
1405 dnl check Net-SNMP library
1406 dnl ------------------
1407 if test "${enable_snmp}" != ""; then
1408    AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], [no])
1409    if test x"$NETSNMP_CONFIG" = x"no"; then
1410       AC_MSG_ERROR([--enable-snmp given but unable to find net-snmp-config])
1411    fi
1412    SNMP_LIBS="`${NETSNMP_CONFIG} --agent-libs`"
1413    SNMP_CFLAGS="`${NETSNMP_CONFIG} --base-cflags`"
1414    AC_MSG_CHECKING([whether we can link to Net-SNMP])
1415    AC_LINK_IFELSE_FLAGS([$SNMP_CFLAGS], [$SNMP_LIBS], [AC_LANG_PROGRAM([
1416 int main(void);
1417 ],
1418 [
1419 {
1420   return 0;
1421 }
1422 ])], [
1423      AC_MSG_ERROR([--enable-snmp given but not usable])])
1424    case "${enable_snmp}" in
1425      yes)
1426       SNMP_METHOD=agentx
1427       ;;
1428      smux|agentx)
1429       SNMP_METHOD="${enable_snmp}"
1430       ;;
1431      *)
1432       AC_MSG_ERROR([--enable-snmp given with an unknown method (${enable_snmp}). Use smux or agentx])
1433       ;;
1434    esac
1435    AH_TEMPLATE([SNMP_SMUX], [Use SNMP SMUX to interface with snmpd])
1436    AH_TEMPLATE([SNMP_AGENTX], [Use SNMP AgentX to interface with snmpd])
1437    AC_DEFINE_UNQUOTED(AS_TR_CPP(SNMP_${SNMP_METHOD}),,SNMP method to interface with snmpd)
1438 fi
1439 AM_CONDITIONAL([SNMP], [test "x${SNMP_METHOD}" != "x"])
1440 AC_SUBST(SNMP_LIBS)
1441 AC_SUBST(SNMP_CFLAGS)
1442
1443 dnl ---------------
1444 dnl math
1445 dnl ---------------
1446 AC_SEARCH_LIBS([sqrt], [m])
1447
1448 dnl ---------------
1449 dnl dlopen & dlinfo
1450 dnl ---------------
1451 AC_SEARCH_LIBS(dlopen, [dl dld], [], [
1452   AC_MSG_ERROR([unable to find the dlopen()])
1453 ])
1454
1455 AC_CHECK_HEADERS([link.h])
1456
1457 AC_MSG_CHECKING([for dlinfo(RTLD_DI_ORIGIN)])
1458 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1459 #include <stdlib.h>
1460 #ifdef HAVE_LINK_H
1461 #include <link.h>
1462 #endif
1463 #include <dlfcn.h>
1464 ]], [[
1465   char origin[1];
1466   dlinfo (NULL, RTLD_DI_ORIGIN, &origin);
1467 ]])], [
1468   AC_MSG_RESULT(yes)
1469   AC_DEFINE(HAVE_DLINFO_ORIGIN, 1, [Have dlinfo RTLD_DI_ORIGIN])
1470 ], [
1471   AC_MSG_RESULT(no)
1472 ])
1473
1474 AC_MSG_CHECKING([for dlinfo(RTLD_DI_LINKMAP)])
1475 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1476 #include <stdlib.h>
1477 #ifdef HAVE_LINK_H
1478 #include <link.h>
1479 #endif
1480 #include <dlfcn.h>
1481 ]], [[
1482   struct link_map *lm = NULL;
1483   dlinfo (NULL, RTLD_DI_LINKMAP, &lm);
1484 ]])], [
1485   AC_MSG_RESULT(yes)
1486   AC_DEFINE(HAVE_DLINFO_LINKMAP, 1, [Have dlinfo RTLD_DI_LINKMAP])
1487 ], [
1488   AC_MSG_RESULT(no)
1489 ])
1490
1491
1492 AM_CONDITIONAL(SNMP, test "x$SNMP_METHOD" = "xagentx")
1493
1494 dnl ---------------------------
1495 dnl sockaddr and netinet checks
1496 dnl ---------------------------
1497 AC_CHECK_TYPES([
1498         struct sockaddr_dl,
1499         struct vifctl, struct mfcctl, struct sioc_sg_req,
1500         vifi_t, struct sioc_vif_req, struct igmpmsg,
1501         struct ifaliasreq, struct if6_aliasreq, struct in6_aliasreq,
1502         struct nd_opt_adv_interval, struct rt_addrinfo,
1503         struct nd_opt_homeagent_info, struct nd_opt_adv_interval],
1504         [], [], FRR_INCLUDES)
1505
1506 AC_CHECK_MEMBERS([struct sockaddr.sa_len,
1507         struct sockaddr_in.sin_len, struct sockaddr_un.sun_len,
1508         struct sockaddr_dl.sdl_len,
1509         struct if6_aliasreq.ifra_lifetime,
1510         struct nd_opt_adv_interval.nd_opt_ai_type],
1511         [], [], FRR_INCLUDES)
1512
1513 dnl ---------------------------
1514 dnl IRDP/pktinfo/icmphdr checks
1515 dnl ---------------------------
1516 AC_CHECK_TYPES([struct in_pktinfo],
1517  [AC_CHECK_TYPES([struct icmphdr],
1518    [if test "${enable_irdp}" != "no"; then
1519       AC_DEFINE(HAVE_IRDP,, IRDP)
1520     fi],
1521    [if test "${enable_irdp}" = "yes"; then
1522       AC_MSG_ERROR(['IRDP requires in_pktinfo at the moment!'])
1523     fi], [FRR_INCLUDES])],
1524  [if test "${enable_irdp}" = "yes"; then
1525     AC_MSG_ERROR(['IRDP requires in_pktinfo at the moment!'])
1526   fi], [FRR_INCLUDES])
1527
1528 dnl -----------------------
1529 dnl checking for IP_PKTINFO
1530 dnl -----------------------
1531 AC_MSG_CHECKING(for IP_PKTINFO)
1532 AC_TRY_COMPILE([#include <netdb.h>], [
1533   int opt = IP_PKTINFO;
1534 ], [
1535   AC_MSG_RESULT(yes)
1536   AC_DEFINE(HAVE_IP_PKTINFO, 1, [Have IP_PKTINFO])
1537 ], [
1538   AC_MSG_RESULT(no)
1539 ])
1540
1541 dnl ---------------------------
1542 dnl checking for IP_RECVDSTADDR
1543 dnl ---------------------------
1544 AC_MSG_CHECKING(for IP_RECVDSTADDR)
1545 AC_TRY_COMPILE([#include <netinet/in.h>], [
1546   int opt = IP_RECVDSTADDR;
1547 ], [
1548   AC_MSG_RESULT(yes)
1549   AC_DEFINE(HAVE_IP_RECVDSTADDR, 1, [Have IP_RECVDSTADDR])
1550 ], [
1551   AC_MSG_RESULT(no)
1552 ])
1553
1554 dnl ----------------------
1555 dnl checking for IP_RECVIF
1556 dnl ----------------------
1557 AC_MSG_CHECKING(for IP_RECVIF)
1558 AC_TRY_COMPILE([#include <netinet/in.h>], [
1559   int opt = IP_RECVIF;
1560 ], [
1561   AC_MSG_RESULT(yes)
1562   AC_DEFINE(HAVE_IP_RECVIF, 1, [Have IP_RECVIF])
1563 ], [
1564   AC_MSG_RESULT(no)
1565 ])
1566
1567 dnl ----------------------
1568 dnl checking for SO_BINDANY
1569 dnl ----------------------
1570 AC_MSG_CHECKING(for SO_BINDANY)
1571 AC_TRY_COMPILE([#include <sys/socket.h>], [
1572   int opt = SO_BINDANY;
1573 ], [
1574   AC_MSG_RESULT(yes)
1575   AC_DEFINE(HAVE_SO_BINDANY, 1, [Have SO_BINDANY])
1576 ], [
1577   AC_MSG_RESULT(no)
1578 ])
1579
1580 dnl ----------------------
1581 dnl checking for IP_FREEBIND
1582 dnl ----------------------
1583 AC_MSG_CHECKING(for IP_FREEBIND)
1584 AC_TRY_COMPILE([#include <netinet/in.h>], [
1585   int opt = IP_FREEBIND;
1586 ], [
1587   AC_MSG_RESULT(yes)
1588   AC_DEFINE(HAVE_IP_FREEBIND, 1, [Have IP_FREEBIND])
1589 ], [
1590   AC_MSG_RESULT(no)
1591 ])
1592
1593 dnl --------------------------------------
1594 dnl checking for be32dec existence or not
1595 dnl --------------------------------------
1596 AC_CHECK_DECLS([be32enc, be32dec], [], [],
1597                [#include <sys/endian.h>])
1598
1599 dnl --------------------------------------
1600 dnl checking for clock_time monotonic struct and call
1601 dnl --------------------------------------
1602 AC_CHECK_DECL(CLOCK_MONOTONIC,
1603         [AC_CHECK_LIB(rt, clock_gettime, [LIBS="$LIBS -lrt"])
1604          AC_DEFINE(HAVE_CLOCK_MONOTONIC,, Have monotonic clock)
1605 ], [AC_MSG_RESULT(no)], [FRR_INCLUDES])
1606
1607 dnl --------------------------------------
1608 dnl checking for flex and bison
1609 dnl --------------------------------------
1610
1611 AM_PROG_LEX
1612 AC_MSG_CHECKING(version of flex)
1613 frr_ac_flex_version="$(eval $LEX -V | grep flex | head -n 1)"
1614 frr_ac_flex_version="${frr_ac_flex_version##* }"
1615 AC_MSG_RESULT([$frr_ac_flex_version])
1616 AX_COMPARE_VERSION([$frr_ac_flex_version], [lt], [2.5.20], [
1617   LEX="$SHELL $missing_dir/missing flex"
1618   if test -f "${srcdir}/lib/command_lex.c" -a -f "${srcdir}/lib/command_lex.h"; then
1619     AC_MSG_WARN([using pregenerated flex output files])
1620   else
1621     AC_MSG_ERROR([flex failure and pregenerated files not included (probably a git build)])
1622   fi
1623   AC_SUBST([LEX_OUTPUT_ROOT], [lex.yy])
1624   AC_SUBST([LEXLIB], [''])
1625 ])
1626
1627 AC_PROG_YACC
1628 dnl thanks GNU bison for this b*llshit...
1629 AC_MSG_CHECKING(version of bison)
1630 frr_ac_bison_version="$(eval $YACC -V | grep bison | head -n 1)"
1631 frr_ac_bison_version="${frr_ac_bison_version##* }"
1632 frr_ac_bison_missing="false"
1633 case "x${frr_ac_bison_version}" in
1634   x2.7*)
1635     BISON_OPENBRACE='"'
1636     BISON_CLOSEBRACE='"'
1637     BISON_VERBOSE=''
1638     AC_MSG_RESULT([$frr_ac_bison_version - 2.7 or older])
1639     ;;
1640   x2.*|x1.*)
1641     AC_MSG_RESULT([$frr_ac_bison_version])
1642     AC_MSG_WARN([installed bison is too old.  Please install GNU bison 2.7.x or newer.])
1643     frr_ac_bison_missing="true"
1644     ;;
1645   x)
1646     AC_MSG_RESULT([none])
1647     AC_MSG_WARN([could not determine bison version.  Please install GNU bison 2.7.x or newer.])
1648     frr_ac_bison_missing="true"
1649     ;;
1650   *)
1651     BISON_OPENBRACE='{'
1652     BISON_CLOSEBRACE='}'
1653     BISON_VERBOSE='-Dparse.error=verbose'
1654     AC_MSG_RESULT([$frr_ac_bison_version - 3.0 or newer])
1655     ;;
1656 esac
1657 AC_SUBST(BISON_OPENBRACE)
1658 AC_SUBST(BISON_CLOSEBRACE)
1659 AC_SUBST(BISON_VERBOSE)
1660
1661 if $frr_ac_bison_missing; then
1662   YACC="$SHELL $missing_dir/missing bison -y"
1663   if test -f "${srcdir}/lib/command_parse.c" -a -f "${srcdir}/lib/command_parse.h"; then
1664     AC_MSG_WARN([using pregenerated bison output files])
1665   else
1666     AC_MSG_ERROR([bison failure and pregenerated files not included (probably a git build)])
1667   fi
1668 fi
1669
1670 dnl -------------------
1671 dnl capabilities checks
1672 dnl -------------------
1673 if test "${enable_capabilities}" != "no"; then
1674   AC_MSG_CHECKING(whether prctl PR_SET_KEEPCAPS is available)
1675   AC_TRY_COMPILE([#include <sys/prctl.h>],[prctl(PR_SET_KEEPCAPS, 1, 0, 0, 0);],
1676     [AC_MSG_RESULT(yes)
1677      AC_DEFINE(HAVE_PR_SET_KEEPCAPS,,prctl)
1678      frr_ac_keepcaps="yes"],
1679      AC_MSG_RESULT(no)
1680   )
1681   if test x"${frr_ac_keepcaps}" = x"yes"; then
1682     AC_CHECK_HEADERS(sys/capability.h)
1683   fi
1684   if test x"${ac_cv_header_sys_capability_h}" = x"yes"; then
1685     AC_CHECK_LIB(cap, cap_init,
1686       [AC_DEFINE(HAVE_LCAPS,1,Capabilities)
1687        LIBCAP="-lcap"
1688        frr_ac_lcaps="yes"]
1689     )
1690   else
1691     AC_CHECK_HEADERS(priv.h,
1692      [AC_MSG_CHECKING(Solaris style privileges are available)
1693       AC_TRY_COMPILE([#include <priv.h>],[getpflags(PRIV_AWARE);],
1694           [AC_MSG_RESULT(yes)
1695            AC_DEFINE(HAVE_SOLARIS_CAPABILITIES,1,getpflags)
1696            frr_ac_scaps="yes"],
1697            AC_MSG_RESULT(no)
1698       )
1699      ]
1700    )
1701   fi
1702   if test x"${frr_ac_scaps}" = x"yes" \
1703        -o x"${frr_ac_lcaps}" = x"yes"; then
1704     AC_DEFINE(HAVE_CAPABILITIES,1,capabilities)
1705   fi
1706 fi
1707 AC_SUBST(LIBCAP)
1708
1709 dnl ---------------------------
1710 dnl check for glibc 'backtrace'
1711 dnl ---------------------------
1712 if test x"${enable_backtrace}" != x"no" ; then
1713   backtrace_ok=no
1714   AC_CHECK_HEADER([execinfo.h], [
1715     AC_SEARCH_LIBS([backtrace], [execinfo], [
1716       AC_DEFINE(HAVE_GLIBC_BACKTRACE,,[Glibc backtrace])
1717       AC_DEFINE(HAVE_STACK_TRACE,,[Stack symbol decoding])
1718       backtrace_ok=yes
1719     ],, [-lm])
1720   ])
1721
1722   if test x"${enable_backtrace}" = x"yes" -a x"${backtrace_ok}" = x"no"; then
1723     dnl user explicitly requested backtrace but we failed to find support
1724     AC_MSG_FAILURE([failed to find backtrace support])
1725   fi
1726 fi
1727
1728 dnl -----------------------------------------
1729 dnl check for malloc mallinfo struct and call
1730 dnl this must try and link using LIBS, in
1731 dnl order to check no alternative allocator
1732 dnl has been specified, which might not provide
1733 dnl mallinfo, e.g. such as Umem on Solaris.
1734 dnl -----------------------------------------
1735 AC_CHECK_HEADER([malloc.h],
1736  [AC_MSG_CHECKING(whether mallinfo is available)
1737   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <malloc.h>]],
1738                         [[struct mallinfo ac_x; ac_x = mallinfo ();]])],
1739       [AC_MSG_RESULT(yes)
1740        AC_DEFINE(HAVE_MALLINFO,,mallinfo)],
1741        AC_MSG_RESULT(no)
1742   )
1743  ], [], FRR_INCLUDES)
1744
1745 dnl ----------
1746 dnl configure date
1747 dnl ----------
1748 CONFDATE=`date '+%Y%m%d'`
1749 AC_SUBST(CONFDATE)
1750
1751 dnl ------------------------------
1752 dnl set paths for state directory
1753 dnl ------------------------------
1754 AC_MSG_CHECKING(directory to use for state file)
1755 if test "${prefix}" = "NONE"; then
1756   frr_statedir_prefix="";
1757 else
1758   frr_statedir_prefix=${prefix}
1759 fi
1760 if test "${localstatedir}" = '${prefix}/var'; then
1761   for FRR_STATE_DIR in ${frr_statedir_prefix}/var/run dnl
1762                         ${frr_statedir_prefix}/var/adm dnl
1763                         ${frr_statedir_prefix}/etc dnl
1764                         /var/run        dnl
1765                         /var/adm        dnl
1766                         /etc            dnl
1767                         /dev/null;
1768   do
1769     test -d $FRR_STATE_DIR && break
1770   done
1771   frr_statedir=$FRR_STATE_DIR
1772 else
1773   frr_statedir=${localstatedir}
1774 fi
1775 if test $frr_statedir = "/dev/null"; then
1776     AC_MSG_ERROR('STATE DIRECTORY NOT FOUND! FIX OR SPECIFY --localstatedir!')
1777 fi
1778 AC_MSG_RESULT(${frr_statedir})
1779 AC_SUBST(frr_statedir)
1780
1781 AC_DEFINE_UNQUOTED(LDPD_SOCKET, "$frr_statedir/ldpd.sock",ldpd control socket)
1782 AC_DEFINE_UNQUOTED(ZEBRA_SERV_PATH, "$frr_statedir/zserv.api",zebra api socket)
1783 AC_DEFINE_UNQUOTED(DAEMON_VTY_DIR, "$frr_statedir",daemon vty directory)
1784
1785 dnl autoconf does this, but it does it too late...
1786 test "x$prefix" = xNONE && prefix=$ac_default_prefix
1787 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
1788
1789 dnl get the full path, recursing through variables...
1790 vtysh_bin="$bindir/vtysh"
1791 for I in 1 2 3 4 5 6 7 8 9 10; do
1792         eval vtysh_bin="\"$vtysh_bin\""
1793 done
1794 AC_DEFINE_UNQUOTED(VTYSH_BIN_PATH, "$vtysh_bin",path to vtysh binary)
1795
1796 CFG_SYSCONF="$sysconfdir"
1797 CFG_SBIN="$sbindir"
1798 CFG_STATE="$frr_statedir"
1799 CFG_MODULE="$moduledir"
1800 for I in 1 2 3 4 5 6 7 8 9 10; do
1801         eval CFG_SYSCONF="\"$CFG_SYSCONF\""
1802         eval CFG_SBIN="\"$CFG_SBIN\""
1803         eval CFG_STATE="\"$CFG_STATE\""
1804         eval CFG_MODULE="\"$CFG_MODULE\""
1805 done
1806 AC_SUBST(CFG_SYSCONF)
1807 AC_SUBST(CFG_SBIN)
1808 AC_SUBST(CFG_STATE)
1809 AC_SUBST(CFG_MODULE)
1810 AC_DEFINE_UNQUOTED(MODULE_PATH, "$CFG_MODULE", path to modules)
1811
1812 dnl ---------------------------
1813 dnl Check htonl works correctly
1814 dnl ---------------------------
1815 AC_MSG_CHECKING(for working htonl)
1816 AC_CACHE_VAL(ac_cv_htonl_works,
1817  [AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES],[htonl (0);])],
1818                 [ac_cv_htonl_works=yes], [ac_cv_htonl_works=no])
1819  ]
1820 )
1821 AC_MSG_RESULT($ac_cv_htonl_works)
1822
1823 AC_CONFIG_FILES([Makefile qpb/Makefile ripd/Makefile
1824           ripngd/Makefile bgpd/Makefile ospfd/Makefile watchfrr/Makefile
1825           ospf6d/Makefile ldpd/Makefile isisd/Makefile vtysh/Makefile
1826           doc/Makefile ospfclient/Makefile tests/Makefile m4/Makefile
1827           bgpd/rfp-example/rfptest/Makefile bgpd/rfp-example/librfp/Makefile
1828           babeld/Makefile
1829           pimd/Makefile
1830           eigrpd/Makefile
1831           nhrpd/Makefile
1832           redhat/Makefile
1833           tools/Makefile
1834           pkgsrc/Makefile
1835           python/Makefile
1836           fpm/Makefile
1837           redhat/frr.spec
1838           snapcraft/Makefile
1839           snapcraft/snapcraft.yaml
1840           lib/version.h
1841           tests/lib/cli/test_cli.refout
1842           doc/defines.texi
1843           doc/bgpd.8
1844           doc/isisd.8
1845           doc/ospf6d.8
1846           doc/ospfclient.8
1847           doc/ospfd.8
1848           doc/ldpd.8
1849           doc/ripd.8
1850           doc/eigrpd.8
1851           doc/ripngd.8
1852           doc/pimd.8
1853           doc/nhrpd.8
1854           doc/vtysh.1
1855           doc/watchfrr.8
1856           doc/zebra.8
1857           doc/frr.1
1858           pkgsrc/bgpd.sh pkgsrc/ospf6d.sh pkgsrc/ospfd.sh
1859           pkgsrc/ripd.sh pkgsrc/ripngd.sh pkgsrc/zebra.sh
1860           pkgsrc/eigrpd.sh])
1861
1862
1863 AC_CONFIG_FILES([solaris/Makefile])
1864
1865 AC_CONFIG_FILES([vtysh/extract.pl],[chmod +x vtysh/extract.pl])
1866
1867 ## Hack, but working solution to avoid rebuilding of frr.info.
1868 ## It's already in CVS until texinfo 4.7 is more common.
1869 AC_OUTPUT
1870
1871 echo "
1872 FRRouting configuration
1873 ------------------------------
1874 FRR version             : ${PACKAGE_VERSION}
1875 host operating system   : ${host_os}
1876 source code location    : ${srcdir}
1877 compiler                : ${CC}
1878 compiler flags          : ${CFLAGS}
1879 make                    : ${MAKE-make}
1880 linker flags            : ${LDFLAGS} ${LIBS} ${LIBCAP} ${LIBREADLINE} ${LIBM}
1881 state file directory    : ${frr_statedir}
1882 config file directory   : `eval echo \`echo ${sysconfdir}\``
1883 example directory       : `eval echo \`echo ${exampledir}\``
1884 module directory        : ${CFG_MODULE}
1885 user to run as          : ${enable_user}
1886 group to run as         : ${enable_group}
1887 group for vty sockets   : ${enable_vty_group}
1888 config file mask        : ${enable_configfile_mask}
1889 log file mask           : ${enable_logfile_mask}
1890 zebra protobuf enabled  : ${have_protobuf:-no}
1891
1892 The above user and group must have read/write access to the state file
1893 directory and to the config files in the config file directory."