configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 m4_define([lxc_version_major], 2)
   5 m4_define([lxc_version_minor], 0)
   6 m4_define([lxc_version_micro], 0)
   7 m4_define([lxc_version_beta], rc1)
   8 m4_define([lxc_version_abi], 1.2.0)
   9
  10 m4_define([lxc_version_base], [lxc_version_major.lxc_version_minor.lxc_version_micro])
  11 m4_define([lxc_version],
  12           [ifelse(lxc_version_beta, [], [lxc_version_base], [lxc_version_base.lxc_version_beta])])
  13
  14 AC_INIT([lxc], [lxc_version])
  15
  16 # We need pkg-config
  17 PKG_PROG_PKG_CONFIG
  18
  19 AC_SUBST(LXC_VERSION_BASE, lxc_version_base)
  20 AC_SUBST(LXC_VERSION_BETA, lxc_version_beta)
  21
  22 AC_SUBST([LXC_VERSION_MAJOR], [lxc_version_major])
  23 AC_SUBST([LXC_VERSION_MINOR], [lxc_version_minor])
  24 AC_SUBST([LXC_VERSION_MICRO], [lxc_version_micro])
  25 AC_SUBST([LXC_VERSION_ABI], [lxc_version_abi])
  26 AC_SUBST([LXC_VERSION], [lxc_version])
  27
  28 AC_CONFIG_SRCDIR([configure.ac])
  29 AC_CONFIG_AUX_DIR([config])
  30 AC_CONFIG_HEADERS([src/config.h])
  31 AM_INIT_AUTOMAKE([-Wall -Werror -Wno-portability subdir-objects])
  32 AC_CANONICAL_HOST
  33 AM_PROG_CC_C_O
  34 AC_GNU_SOURCE
  35
  36 # Detect the distribution. This is used for the default configuration and
  37 # for some distro-specific build options.
  38 AC_MSG_CHECKING([host distribution])
  39 AC_ARG_WITH(distro, AS_HELP_STRING([--with-distro=DISTRO], [Specify the Linux distribution to target: One of redhat, oracle, centos, fedora, suse, gentoo, debian, arch, slackware, plamo, paldo, openmandriva, pardus, sparclinux.]))
  40 if type lsb_release >/dev/null 2>&1 && test "z$with_distro" = "z"; then
  41         with_distro=`lsb_release -is`
  42 fi
  43 if test "z$with_distro" = "z"; then
  44         AC_CHECK_FILE(/etc/redhat-release,with_distro="redhat")
  45         AC_CHECK_FILE(/etc/oracle-release,with_distro="oracle")
  46         AC_CHECK_FILE(/etc/sparclinux-release,with_distro="sparclinux")
  47         AC_CHECK_FILE(/etc/centos-release,with_distro="centos")
  48         AC_CHECK_FILE(/etc/fedora-release,with_distro="fedora")
  49         AC_CHECK_FILE(/etc/SuSE-release,with_distro="suse")
  50         AC_CHECK_FILE(/etc/gentoo-release,with_distro="gentoo")
  51         AC_CHECK_FILE(/etc/debian_version,with_distro="debian")
  52         AC_CHECK_FILE(/etc/arch-release,with_distro="arch")
  53         AC_CHECK_FILE(/etc/slackware-version,with_distro="slackware")
  54         AC_CHECK_FILE(/etc/plamo-version,with_distro="plamo")
  55         AC_CHECK_FILE(/etc/frugalware-release,with_distro="frugalware")
  56         AC_CHECK_FILE(/etc/mandrakelinux-release, with_distro="openmandriva")
  57         AC_CHECK_FILE(/etc/mandriva-release,with_distro="openmandriva")
  58         AC_CHECK_FILE(/etc/pardus-release,with_distro="pardus")
  59 fi
  60 with_distro=`echo ${with_distro} | tr '[[:upper:]]' '[[:lower:]]'`
  61
  62 if test "z$with_distro" = "zforsparc"; then
  63         with_distro="sparclinux"
  64 fi
  65
  66 if test "z$with_distro" = "z"; then
  67         with_distro="unknown"
  68 fi
  69 case $with_distro in
  70         ubuntu|raspbian)
  71                 distroconf=default.conf.lxcbr
  72                 distrosysconf="$sysconfdir/default"
  73                 ;;
  74         redhat|centos|fedora|oracle|oracleserver|sparclinux|suse|opensuse*|plamo)
  75                 distroconf=default.conf.lxcbr
  76                 distrosysconf="$sysconfdir/sysconfig"
  77                 ;;
  78         *)
  79                 distroconf=default.conf.unknown
  80                 distrosysconf="$sysconfdir/default"
  81                 ;;
  82 esac
  83 AC_MSG_RESULT([$with_distro])
  84 AM_CONDITIONAL([HAVE_DEBIAN], [test x"$with_distro" = "xdebian" -o x"$with_distro" = "xubuntu" -o x"$with_distro" = "xraspbian"])
  85 AM_CONDITIONAL([DISTRO_UBUNTU], [test "x$with_distro" = "xubuntu"])
  86
  87 AC_CONFIG_LINKS([config/etc/default.conf:config/etc/${distroconf}])
  88
  89 # Check for init system type
  90 AC_MSG_CHECKING([for init system type])
  91 AC_ARG_WITH([init-script],
  92             [AC_HELP_STRING([--with-init-script@<:@=TYPE@<:@,TYPE,...@:>@@:>@],
  93                             [Type(s) of init script to install: sysvinit, systemd, upstart,
  94                              distro @<:@default=distro@:>@])],[],[with_init_script=distro])
  95 case "$with_init_script" in
  96         distro)
  97                 case $with_distro in
  98                         fedora|opensuse*)
  99                                 init_script=systemd
 100                                 ;;
 101                         redhat|centos|oracle|oracleserver|sparclinux|plamo)
 102                                 init_script=sysvinit
 103                                 ;;
 104                         debian|raspbian)
 105                                 init_script=upstart,systemd
 106                                 ;;
 107                         ubuntu)
 108                                 init_script=upstart,systemd
 109                                 ;;
 110                         *)
 111                                 echo -n "Linux distribution init system unknown."
 112                                 init_script=
 113                                 ;;
 114                 esac
 115                 ;;
 116         *)
 117                 init_script=$with_init_script
 118                 ;;
 119 esac
 120
 121 # Check valid init systems were given, run in subshell so we don't mess up IFS
 122 (IFS="," ; for init_sys in $init_script;
 123 do
 124         case "$init_sys" in
 125                 none|sysvinit|systemd|upstart)
 126                         ;;
 127                 *)
 128                         exit 1
 129                         ;;
 130         esac
 131 done) || AC_MSG_ERROR([Unknown init system type in $init_script])
 132
 133 AM_CONDITIONAL([INIT_SCRIPT_SYSV], [echo "$init_script" |grep -q "sysvinit"])
 134 AM_CONDITIONAL([INIT_SCRIPT_SYSTEMD], [echo "$init_script" |grep -q "systemd"])
 135 AM_CONDITIONAL([INIT_SCRIPT_UPSTART], [echo "$init_script" |grep -q "upstart"])
 136 AC_MSG_RESULT($init_script)
 137
 138 # systemd unit dir
 139 AC_ARG_WITH([systemdsystemunitdir],
 140             AS_HELP_STRING([--with-systemdsystemunitdir=DIR], [Directory for systemd service files]),
 141             [],
 142             [with_systemdsystemunitdir=$($PKG_CONFIG --variable=systemdsystemunitdir systemd)])
 143 if test -z "$with_systemdsystemunitdir"; then
 144   with_systemdsystemunitdir=/lib/systemd/system
 145 fi
 146 if test "x$with_systemdsystemunitdir" != "xno"; then
 147   AC_SUBST([SYSTEMD_UNIT_DIR], [$with_systemdsystemunitdir])
 148 fi
 149
 150 # Allow disabling rpath
 151 AC_ARG_ENABLE([rpath],
 152         [AC_HELP_STRING([--enable-rpath], [set rpath in executables [default=no]])],
 153         [], [enable_rpath=no])
 154 AM_CONDITIONAL([ENABLE_RPATH], [test "x$enable_rpath" = "xyes"])
 155
 156 # Documentation (manpages)
 157 AC_ARG_ENABLE([doc],
 158         [AC_HELP_STRING([--enable-doc], [make man pages [default=auto]])],
 159         [], [enable_doc=auto])
 160
 161 if test "x$enable_doc" = "xyes" -o "x$enable_doc" = "xauto"; then
 162         db2xman=""
 163         dbparsers="docbook2x-man db2x_docbook2man docbook2man docbook-to-man"
 164
 165         AC_MSG_CHECKING(for docbook2x-man)
 166         for name in ${dbparsers}; do
 167                 if "$name" --help >/dev/null 2>&1; then
 168                         db2xman="$name"
 169                         break;
 170                 fi
 171         done
 172
 173         if test -n "${db2xman}"; then
 174                 AC_MSG_RESULT([${db2xman}])
 175                 enable_doc="yes"
 176         else
 177                 AC_MSG_RESULT([no])
 178                 if test "x$enable_doc" = "xyes"; then
 179                         AC_MSG_ERROR([docbook2x-man is required, but could not be found])
 180                 fi
 181                 enable_doc="no"
 182         fi
 183
 184         AC_SUBST(db2xman)
 185 fi
 186 AM_CONDITIONAL([ENABLE_DOCBOOK], [test "x$db2xman" != "x"])
 187 AM_CONDITIONAL([USE_DOCBOOK2X], [test "x$db2xman" != "xdocbook2man"])
 188
 189 if test "x$db2xman" = "xdocbook2man"; then
 190         docdtd="\"-//Davenport//DTD DocBook V3.0//EN\""
 191 else
 192         docdtd="\"-//OASIS//DTD DocBook XML\" \"http://www.oasis-open.org/docbook/xml/4.5/docbookx.dtd\""
 193 fi
 194 AC_SUBST(docdtd)
 195
 196 # Documentation (API)
 197 AC_ARG_ENABLE([api-docs],
 198         [AC_HELP_STRING([--enable-api-docs],
 199         [make API documentation [default=auto]])],
 200         [], [enable_api_docs=auto])
 201
 202 if test "x$enable_api_docs" = "xyes" -o "x$enable_api_docs" = "xauto"; then
 203         AC_CHECK_PROGS([HAVE_DOXYGEN],[doxygen])
 204         AC_SUBST([HAVE_DOXYGEN])
 205
 206         if test "x$HAVE_DOXYGEN" != "x"; then
 207                 enable_api_docs="yes"
 208         else
 209                 if test "x$enable_api_docs" = "xyes"; then
 210                         AC_MSG_ERROR([doxygen is required, but could not be found])
 211                 fi
 212                 enable_api_docs="no"
 213         fi
 214 fi
 215
 216 AM_CONDITIONAL([ENABLE_API_DOCS], [test "x$HAVE_DOXYGEN" != "x"])
 217
 218 # Apparmor
 219 AC_ARG_ENABLE([apparmor],
 220         [AC_HELP_STRING([--enable-apparmor], [enable apparmor support [default=auto]])],
 221         [], [enable_apparmor=auto])
 222
 223 if test "$enable_apparmor" = "auto" ; then
 224         AC_CHECK_LIB([apparmor],[aa_change_profile],[enable_apparmor=yes], [enable_apparmor=no])
 225 fi
 226 AM_CONDITIONAL([ENABLE_APPARMOR], [test "x$enable_apparmor" = "xyes"])
 227
 228 AC_CHECK_LIB([gnutls], [gnutls_hash_fast], [enable_gnutls=yes], [enable_gnutls=no])
 229
 230 AM_COND_IF([ENABLE_APPARMOR],
 231         [AC_CHECK_HEADER([sys/apparmor.h],[],[AC_MSG_ERROR([You must install the AppArmor development package in order to compile lxc])])
 232         AC_CHECK_LIB([apparmor], [aa_change_profile],[],[AC_MSG_ERROR([You must install the AppArmor development package in order to compile lxc])])
 233         AC_SUBST([APPARMOR_LIBS], [-lapparmor])])
 234
 235 # SELinux
 236 AC_ARG_ENABLE([selinux],
 237         [AC_HELP_STRING([--enable-selinux], [enable SELinux support [default=auto]])],
 238         [], [enable_selinux=auto])
 239
 240 if test "x$enable_selinux" = xauto; then
 241         AC_CHECK_LIB([selinux],[setexeccon_raw],[enable_selinux=yes],[enable_selinux=no])
 242 fi
 243 AM_CONDITIONAL([ENABLE_SELINUX], [test "x$enable_selinux" = "xyes"])
 244 AM_COND_IF([ENABLE_SELINUX],
 245         [AC_CHECK_HEADER([selinux/selinux.h],[],[AC_MSG_ERROR([You must install the SELinux development package in order to compile lxc])])
 246         AC_CHECK_LIB([selinux], [setexeccon_raw],[true],[AC_MSG_ERROR([You must install the SELinux development package in order to compile lxc])])
 247         AC_SUBST([SELINUX_LIBS], [-lselinux])])
 248
 249 # Seccomp syscall filter
 250 AC_ARG_ENABLE([seccomp],
 251         [AC_HELP_STRING([--enable-seccomp], [enable seccomp support [default=auto]])],
 252         [], [enable_seccomp=auto])
 253
 254 if test "x$enable_seccomp" = "xauto" ; then
 255         AC_CHECK_LIB([seccomp],[seccomp_init],[enable_seccomp=yes],[enable_seccomp=no])
 256 fi
 257 AM_CONDITIONAL([ENABLE_SECCOMP], [test "x$enable_seccomp" = "xyes"])
 258
 259 AM_COND_IF([ENABLE_SECCOMP],
 260         [PKG_CHECK_MODULES([SECCOMP],[libseccomp],[],[
 261                 AC_CHECK_HEADER([seccomp.h],[],[AC_MSG_ERROR([You must install the seccomp development package in order to compile lxc])])
 262                 AC_CHECK_LIB([seccomp], [seccomp_init],[],[AC_MSG_ERROR([You must install the seccomp development package in order to compile lxc])])
 263                 AC_SUBST([SECCOMP_LIBS], [-lseccomp])
 264                 ])
 265         ])
 266
 267 # cgmanager
 268 AC_ARG_ENABLE([cgmanager],
 269         [AC_HELP_STRING([--enable-cgmanager], [enable cgmanager support [default=auto]])],
 270         [], [enable_cgmanager=auto])
 271
 272 if test "x$enable_cgmanager" = "xauto" ; then
 273         AC_CHECK_LIB([cgmanager],[cgmanager_create],[enable_cgmanager=yes],[enable_cgmanager=no],[-lnih -lnih-dbus -ldbus-1])
 274 fi
 275 AM_CONDITIONAL([ENABLE_CGMANAGER], [test "x$enable_cgmanager" = "xyes"])
 276
 277 AM_COND_IF([ENABLE_CGMANAGER],
 278         [PKG_CHECK_MODULES([CGMANAGER], [libcgmanager])
 279         PKG_CHECK_MODULES([NIH], [libnih >= 1.0.2])
 280         PKG_CHECK_MODULES([NIH_DBUS], [libnih-dbus >= 1.0.0])
 281         PKG_CHECK_MODULES([DBUS], [dbus-1 >= 1.2.16])
 282         ])
 283
 284 AC_MSG_CHECKING(for get_pid_cgroup_abs_sync)
 285 save_LIBS=$LIBS
 286 AC_SEARCH_LIBS([cgmanager_get_pid_cgroup_abs_sync], [cgmanager], [have_abs_cgroups=yes], [have_abs_cgroups=no], [-lnih -lnih-dbus -ldbus-1])
 287 LIBS=$save_LIBS
 288 if test "x$have_abs_cgroups" = "xyes"; then
 289         AC_DEFINE([HAVE_CGMANAGER_GET_PID_CGROUP_ABS_SYNC], 1, [Have cgmanager_get_pid_cgroup_abs_sync])
 290         AC_MSG_RESULT([yes])
 291 else
 292         AC_MSG_RESULT([no])
 293 fi
 294
 295 AC_MSG_CHECKING(for cgmanager_list_controllers)
 296 save_LIBS=$LIBS
 297 AC_SEARCH_LIBS([cgmanager_list_controllers_sync], [cgmanager], [have_list_controllers=yes], [have_list_controllers=no], [-lnih -lnih-dbus -ldbus-1])
 298 LIBS=$save_LIBS
 299 if test "x$have_list_controllers" = "xyes"; then
 300         AC_DEFINE([HAVE_CGMANAGER_LIST_CONTROLLERS], 1, [Have cgmanager_list_controllers])
 301         AC_MSG_RESULT([yes])
 302 else
 303         AC_MSG_RESULT([no])
 304 fi
 305
 306 # Check for static libcap, make sure the function checked for differs from the
 307 # the one checked below so the cache doesn't give a wrong answer
 308 OLD_CFLAGS="$CFLAGS"
 309 CFLAGS="$CFLAGS -static"
 310 AC_CHECK_LIB([cap],[cap_init],[have_static_libcap=yes],[have_static_libcap=no])
 311 AM_CONDITIONAL([HAVE_STATIC_LIBCAP], [test "x$have_static_libcap" = "xyes"])
 312 if test "x$have_static_libcap" = "xyes"; then
 313         AC_DEFINE([HAVE_STATIC_LIBCAP], 1, [Have static libcap])
 314 fi
 315 CFLAGS="$OLD_CFLAGS"
 316
 317
 318 # Linux capabilities
 319 AC_ARG_ENABLE([capabilities],
 320         [AC_HELP_STRING([--enable-capabilities], [enable kernel capabilities support [default=auto]])],
 321         [], [enable_capabilities=auto])
 322
 323 if test "x$enable_capabilities" = "xauto"; then
 324         AC_CHECK_LIB([cap],[cap_set_proc],[enable_capabilities=yes],[enable_capabilities=no])
 325 fi
 326 AM_CONDITIONAL([ENABLE_CAP], [test "x$enable_capabilities" = "xyes"])
 327
 328 AM_COND_IF([ENABLE_CAP],
 329         [AC_CHECK_LIB(cap,cap_set_proc,[true],[AC_MSG_ERROR([You are missing libcap support.])])
 330         AC_SUBST([CAP_LIBS], [-lcap])])
 331
 332 # HAVE_SCMP_FILTER_CTX=1 will tell us we have libseccomp api >= 1.0.0
 333 OLD_CFLAGS="$CFLAGS"
 334 CFLAGS="$CFLAGS $SECCOMP_CFLAGS"
 335 AC_CHECK_TYPES([scmp_filter_ctx], [], [], [[#include <seccomp.h>]])
 336 AC_CHECK_DECLS([seccomp_syscall_resolve_name_arch], [], [], [[#include <seccomp.h>]])
 337 CFLAGS="$OLD_CFLAGS"
 338
 339 # Configuration examples
 340 AC_ARG_ENABLE([examples],
 341         [AC_HELP_STRING([--enable-examples], [install examples [default=yes]])],
 342         [], [enable_examples=yes])
 343 AM_CONDITIONAL([ENABLE_EXAMPLES], [test "x$enable_examples" = "xyes"])
 344
 345 # Python3 module and scripts
 346 AC_ARG_ENABLE([python],
 347         [AC_HELP_STRING([--enable-python], [enable python binding [default=auto]])],
 348         [], [enable_python=auto])
 349
 350 if test "x$enable_python" = "xauto"; then
 351         PKG_CHECK_MODULES([PYTHONDEV], [python3 >= 3.2],[enable_python=yes],[enable_python=no])
 352         if test "$CC" = "clang"; then
 353                 enable_python=no
 354         fi
 355 fi
 356
 357 if test "x$enable_python" = "xyes" && test "$CC" = "clang"; then
 358         AC_MSG_ERROR([Python3 is incompatible with the clang compiler])
 359 fi
 360
 361 AM_CONDITIONAL([ENABLE_PYTHON], [test "x$enable_python" = "xyes"])
 362
 363 AM_COND_IF([ENABLE_PYTHON],
 364         [AM_PATH_PYTHON([3.2], [], [AC_MSG_ERROR([You must install python3])])
 365         PKG_CHECK_MODULES([PYTHONDEV], [python3 >= 3.2],[],[AC_MSG_ERROR([You must install python3-dev])])
 366         AC_DEFINE_UNQUOTED([ENABLE_PYTHON], 1, [Python3 is available])])
 367
 368 # Enable dumping stack traces
 369 AC_ARG_ENABLE([mutex-debugging],
 370         [AC_HELP_STRING([--enable-mutex-debugging], [Makes mutexes to report error and provide stack trace [default=no]])],
 371         [], [enable_mutex_debugging=no])
 372 AM_CONDITIONAL([MUTEX_DEBUGGING], [test "x$enable_mutex_debugging" = "xyes"])
 373
 374 AM_COND_IF([MUTEX_DEBUGGING],
 375         AC_DEFINE_UNQUOTED([MUTEX_DEBUGGING], 1, [Enabling mutex debugging]))
 376
 377 # Not in older autoconf versions
 378 # AS_VAR_COPY(DEST, SOURCE)
 379 # -------------------------
 380 # Set the polymorphic shell variable DEST to the contents of the polymorphic
 381 # shell variable SOURCE.
 382 m4_ifdef([AS_VAR_COPY], [],
 383 [AC_DEFUN([AS_VAR_COPY],
 384     [AS_LITERAL_IF([$1[]$2], [$1=$$2], [eval $1=\$$2])])
 385 ])
 386
 387 dnl PKG_CHECK_VAR was introduced with pkg-config 0.28
 388 m4_ifdef([PKG_CHECK_VAR], [],
 389 [AC_DEFUN([PKG_CHECK_VAR],
 390     [AC_REQUIRE([PKG_PROG_PKG_CONFIG])dnl
 391      AC_ARG_VAR([$1], [value of $3 for $2, overriding pkg-config])dnl
 392      _PKG_CONFIG([$1], [variable="][$3]["], [$2])
 393      AS_VAR_COPY([$1], [pkg_cv_][$1])
 394      AS_VAR_IF([$1], [""], [$5], [$4])dnl
 395     ])# PKG_CHECK_VAR
 396 ])
 397
 398 # Lua module and scripts
 399 AC_ARG_ENABLE([lua],
 400         [AC_HELP_STRING([--enable-lua], [enable lua binding [default=auto]])],
 401         [], [enable_lua=auto])
 402
 403 AC_ARG_WITH([lua-pc],
 404         [AS_HELP_STRING(
 405                 [--with-lua-pc=PKG],
 406                 [Specify pkg-config package name for lua]
 407         )], [], [with_lua_pc=no])
 408
 409 if test "x$enable_lua" = "xyes" -a "x$with_lua_pc" != "xno"; then
 410         # exit with error if not found
 411         PKG_CHECK_MODULES([LUA], [$with_lua_pc], [LUAPKGCONFIG=$with_lua_pc])
 412 fi
 413
 414 if test "x$enable_lua" = "xauto" -a "x$with_lua_pc" != "xno"; then
 415         PKG_CHECK_MODULES([LUA], [$with_lua_pc],
 416                 [LUAPKGCONFIG=$with_lua_pc
 417                 enable_lua=yes],
 418                 [enable_lua=no])
 419 fi
 420
 421 if test "x$enable_lua" != "xno"; then
 422         PKG_CHECK_MODULES([LUA], [lua], [LUAPKGCONFIG=lua],
 423                 [PKG_CHECK_MODULES([LUA], [lua5.2], [LUAPKGCONFIG=lua5.2],
 424                         [PKG_CHECK_MODULES([LUA], [lua5.1], [LUAPKGCONFIG=lua5.1],
 425                                 [AS_IF([test "x$enable_lua" = "xyes"],
 426                                         [AC_MSG_ERROR([Lua not found. Please use --with-lua-pc=PKG])],
 427                                         [enable_lua=no])]
 428                         )]
 429                 )])
 430         AS_IF([test "x$LUAPKGCONFIG" != "x"], [enable_lua=yes])
 431 fi
 432
 433 AM_CONDITIONAL([ENABLE_LUA],
 434         [test "x$enable_lua" = "xyes"])
 435
 436 AM_COND_IF([ENABLE_LUA],
 437         [AC_MSG_CHECKING([Lua version])
 438         PKG_CHECK_VAR([LUA_VERSION], [$LUAPKGCONFIG], [V],,
 439                 [PKG_CHECK_VAR([LUA_VERSION], [$LUAPKGCONFIG], [major_version])])
 440         AC_MSG_RESULT([$LUA_VERSION])
 441         AC_SUBST([LUA_LIBDIR], [$libdir/lua/$LUA_VERSION])
 442         AC_SUBST([LUA_SHAREDIR], [$datadir/lua/$LUA_VERSION])
 443         ])
 444
 445 # Optional bash integration
 446 AC_ARG_ENABLE([bash],
 447         [AC_HELP_STRING([--enable-bash], [build bash integration [default=yes]])],
 448         [], [enable_bash=yes])
 449 AM_CONDITIONAL([ENABLE_BASH], [test "x$enable_bash" = "xyes"])
 450
 451 # Optional test binaries
 452 AC_ARG_ENABLE([tests],
 453         [AC_HELP_STRING([--enable-tests], [build test/example binaries [default=no]])],
 454         [], [enable_tests=no])
 455 AM_CONDITIONAL([ENABLE_TESTS], [test "x$enable_tests" = "xyes"])
 456
 457 # Allow overriding the default runtime dir (/run)
 458 AC_ARG_WITH([runtime-path],
 459         [AC_HELP_STRING(
 460                 [--with-runtime-path=dir],
 461                 [runtime directory (default: /run)]
 462         )], [], [with_runtime_path=['/run']])
 463
 464 # LXC container path, where the containers are actually stored
 465 # This is overridden by an entry in the file called LXCCONF
 466 # (i.e. /etc/lxc/lxc.conf)
 467 AC_ARG_WITH([config-path],
 468         [AC_HELP_STRING(
 469                 [--with-config-path=dir],
 470                 [lxc configuration repository path]
 471         )], [], [with_config_path=['${localstatedir}/lib/lxc']])
 472
 473 # The path of the global lxc configuration file.
 474 AC_ARG_WITH([global-conf],
 475         [AC_HELP_STRING(
 476                 [--with-global-conf=dir],
 477                 [global lxc configuration file]
 478         )], [], [with_global_conf=['${sysconfdir}/lxc/lxc.conf']])
 479
 480 # The path of the userns network configuration file
 481 AC_ARG_WITH([usernic-conf],
 482         [AC_HELP_STRING(
 483                 [--with-usernic-conf],
 484                 [user network interface configuration file]
 485         )], [], [with_usernic_conf=['${sysconfdir}/lxc/lxc-usernet']])
 486
 487 # The path of the runtime usernic database
 488 AC_ARG_WITH([usernic-db],
 489         [AC_HELP_STRING(
 490                 [--with-usernic-db],
 491                 [lxc user nic database]
 492         )], [], [with_usernic_db=['${with_runtime_path}/lxc/nics']])
 493
 494 # Rootfs path, where the container mount structure is assembled
 495 AC_ARG_WITH([rootfs-path],
 496         [AC_HELP_STRING(
 497                 [--with-rootfs-path=dir],
 498                 [lxc rootfs mount point]
 499         )], [], [with_rootfs_path=['${libdir}/lxc/rootfs']])
 500
 501 # cgroup pattern specification
 502 AC_ARG_WITH([cgroup-pattern],
 503         [AC_HELP_STRING(
 504                 [--with-cgroup-pattern=pattern],
 505                 [pattern for container cgroups]
 506         )], [], [with_cgroup_pattern=['/lxc/%n']])
 507
 508 # Container log path.  By default, use $lxcpath.
 509 AC_MSG_CHECKING([Whether to place logfiles in container config path])
 510 AC_ARG_ENABLE([configpath-log],
 511         [AC_HELP_STRING([--enable-configpath-log], [use logfiles in config path [default=no]])],
 512         [], [enable_configpath_log=no])
 513 AC_MSG_RESULT([$enable_configpath_log])
 514 AM_CONDITIONAL([USE_CONFIGPATH_LOGS], [test "$enable_configpath_log" = "yes"])
 515
 516 if test "$enable_configpath_log" = "yes"; then
 517         default_log_path="${with_config_path}"
 518 else
 519         default_log_path="${localstatedir}/log/lxc"
 520 fi
 521
 522 AC_ARG_WITH([log-path],
 523         [AC_HELP_STRING(
 524                 [--with-log-path=dir],
 525                 [per container log path]
 526         )], [], [with_log_path=['${default_log_path}']])
 527
 528 # Expand some useful variables
 529 AS_AC_EXPAND(PREFIX, "$prefix")
 530 AS_AC_EXPAND(LIBDIR, "$libdir")
 531 AS_AC_EXPAND(BINDIR, "$bindir")
 532 AS_AC_EXPAND(SBINDIR, "$sbindir")
 533 AS_AC_EXPAND(LIBEXECDIR, "$libexecdir")
 534 AS_AC_EXPAND(INCLUDEDIR, "$includedir")
 535 AS_AC_EXPAND(SYSCONFDIR, "$sysconfdir")
 536 AS_AC_EXPAND(LXC_DEFAULT_CONFIG, "$sysconfdir/lxc/default.conf")
 537 AS_AC_EXPAND(DATADIR, "$datadir")
 538 AS_AC_EXPAND(LOCALSTATEDIR, "$localstatedir")
 539 AS_AC_EXPAND(DOCDIR, "$docdir")
 540 AS_AC_EXPAND(LXC_GENERATE_DATE, "$(date)")
 541 AS_AC_EXPAND(LXCPATH, "$with_config_path")
 542 AS_AC_EXPAND(LXC_GLOBAL_CONF, "$with_global_conf")
 543 AS_AC_EXPAND(LXC_USERNIC_CONF, "$with_usernic_conf")
 544 AS_AC_EXPAND(LXC_USERNIC_DB, "$with_usernic_db")
 545 AS_AC_EXPAND(LXC_DISTRO_SYSCONF, "$distrosysconf")
 546 AS_AC_EXPAND(LXCROOTFSMOUNT, "$with_rootfs_path")
 547 AS_AC_EXPAND(LXCTEMPLATEDIR, "$datadir/lxc/templates")
 548 AS_AC_EXPAND(LXCTEMPLATECONFIG, "$datadir/lxc/config")
 549 AS_AC_EXPAND(LXCHOOKDIR, "$datadir/lxc/hooks")
 550 AS_AC_EXPAND(LXCBINHOOKDIR, "$libexecdir/lxc/hooks")
 551 AS_AC_EXPAND(LXCINITDIR, "$libexecdir")
 552 AS_AC_EXPAND(LOGPATH, "$with_log_path")
 553 AS_AC_EXPAND(RUNTIME_PATH, "$with_runtime_path")
 554 AC_SUBST(DEFAULT_CGROUP_PATTERN, ["$with_cgroup_pattern"])
 555
 556 # We need the install path so criu knows where to reference the hook scripts.
 557 AC_DEFINE_UNQUOTED([DATADIR], "$DATADIR", ["Prefix for shared files."])
 558
 559 # Check for some standard kernel headers
 560 AC_CHECK_HEADERS([linux/unistd.h linux/netlink.h linux/genetlink.h],
 561                                 [],
 562                                 AC_MSG_ERROR([Please install the Linux kernel headers.]),
 563                                 [#include <sys/socket.h>])
 564
 565 # Check for alternate C libraries
 566 AC_MSG_CHECKING(for bionic libc)
 567 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 568         [[#ifndef __ANDROID__
 569 error: Not bionic!
 570 #endif]])],
 571         [is_bionic=yes],
 572         [is_bionic=no])
 573 if test "x$is_bionic" = "xyes"; then
 574         AC_DEFINE([IS_BIONIC], 1, [bionic libc])
 575         AC_MSG_RESULT([yes])
 576 else
 577         AC_MSG_RESULT([no])
 578 fi
 579 AM_CONDITIONAL([IS_BIONIC], [test "x$is_bionic" = "xyes"])
 580
 581 # Some systems lack PR_CAPBSET_DROP definition => HAVE_DECL_PR_CAPBSET_DROP
 582 AC_CHECK_DECLS([PR_CAPBSET_DROP], [], [], [#include <sys/prctl.h>])
 583
 584 # Check for some headers
 585 AC_CHECK_HEADERS([sys/signalfd.h pty.h ifaddrs.h sys/capability.h sys/personality.h utmpx.h sys/timerfd.h])
 586
 587 # Check for some syscalls functions
 588 AC_CHECK_FUNCS([setns pivot_root sethostname unshare rand_r confstr faccessat])
 589
 590 # Check for some functions
 591 AC_CHECK_LIB(pthread, main)
 592 AC_CHECK_FUNCS(pthread_atfork)
 593 AC_CHECK_FUNCS(statvfs)
 594 AC_CHECK_LIB(util, openpty)
 595 AC_CHECK_FUNCS([openpty hasmntopt setmntent endmntent utmpxname])
 596 AC_CHECK_FUNCS([getline],
 597         AM_CONDITIONAL(HAVE_GETLINE, true)
 598         AC_DEFINE(HAVE_GETLINE,1,[Have getline]),
 599         AM_CONDITIONAL(HAVE_GETLINE, false))
 600 AC_CHECK_FUNCS([getsubopt],
 601         AM_CONDITIONAL(HAVE_GETSUBOPT, true)
 602         AC_DEFINE(HAVE_GETSUBOPT,1,[Have getsubopt]),
 603         AM_CONDITIONAL(HAVE_GETSUBOPT, false))
 604 AC_CHECK_FUNCS([fgetln],
 605         AM_CONDITIONAL(HAVE_FGETLN, true)
 606         AC_DEFINE(HAVE_FGETLN,1,[Have fgetln]),
 607         AM_CONDITIONAL(HAVE_FGETLN, false))
 608
 609 # Check for some libraries
 610 AC_SEARCH_LIBS(sem_open, [rt pthread])
 611 AC_SEARCH_LIBS(clock_gettime, [rt])
 612
 613 # Check for some standard binaries
 614 AC_PROG_GCC_TRADITIONAL
 615 AC_PROG_SED
 616
 617 # See if we support thread-local storage.
 618 LXC_CHECK_TLS
 619
 620 if test "x$GCC" = "xyes"; then
 621         CFLAGS="$CFLAGS -Wall -Werror"
 622 fi
 623
 624 # Files requiring some variable expansion
 625 AC_CONFIG_FILES([
 626         Makefile
 627         lxc.pc
 628         lxc.spec
 629
 630         config/Makefile
 631         config/apparmor/Makefile
 632         config/selinux/Makefile
 633         config/bash/Makefile
 634         config/bash/lxc
 635         config/init/Makefile
 636         config/init/common/Makefile
 637         config/init/common/lxc-containers
 638         config/init/common/lxc-net
 639         config/init/systemd/Makefile
 640         config/init/systemd/lxc.service
 641         config/init/systemd/lxc@.service
 642         config/init/systemd/lxc-net.service
 643         config/init/sysvinit/Makefile
 644         config/init/sysvinit/lxc-containers
 645         config/init/sysvinit/lxc-net
 646         config/init/upstart/lxc-net.conf
 647         config/init/upstart/Makefile
 648         config/etc/Makefile
 649         config/templates/Makefile
 650         config/templates/alpine.common.conf
 651         config/templates/alpine.userns.conf
 652         config/templates/archlinux.common.conf
 653         config/templates/archlinux.userns.conf
 654         config/templates/centos.common.conf
 655         config/templates/centos.userns.conf
 656         config/templates/common.conf
 657         config/templates/common.conf.d/Makefile
 658         config/templates/debian.common.conf
 659         config/templates/debian.userns.conf
 660         config/templates/fedora.common.conf
 661         config/templates/fedora.userns.conf
 662         config/templates/gentoo.common.conf
 663         config/templates/gentoo.moresecure.conf
 664         config/templates/gentoo.userns.conf
 665         config/templates/nesting.conf
 666         config/templates/opensuse.common.conf
 667         config/templates/opensuse.userns.conf
 668         config/templates/oracle.common.conf
 669         config/templates/oracle.userns.conf
 670         config/templates/plamo.common.conf
 671         config/templates/plamo.userns.conf
 672         config/templates/slackware.common.conf
 673         config/templates/slackware.userns.conf
 674         config/templates/ubuntu-cloud.common.conf
 675         config/templates/ubuntu-cloud.lucid.conf
 676         config/templates/ubuntu-cloud.userns.conf
 677         config/templates/ubuntu.common.conf
 678         config/templates/ubuntu.lucid.conf
 679         config/templates/ubuntu.userns.conf
 680         config/templates/openwrt.common.conf
 681         config/templates/sparclinux.common.conf
 682         config/templates/sparclinux.userns.conf
 683         config/templates/userns.conf
 684         config/yum/Makefile
 685         config/sysconfig/Makefile
 686         config/sysconfig/lxc
 687
 688         doc/Makefile
 689         doc/api/Makefile
 690         doc/lxc-attach.sgml
 691         doc/lxc-autostart.sgml
 692         doc/lxc-cgroup.sgml
 693         doc/lxc-checkconfig.sgml
 694         doc/lxc-checkpoint.sgml
 695         doc/lxc-clone.sgml
 696         doc/lxc-config.sgml
 697         doc/lxc-console.sgml
 698         doc/lxc-copy.sgml
 699         doc/lxc-create.sgml
 700         doc/lxc-destroy.sgml
 701         doc/lxc-device.sgml
 702         doc/lxc-execute.sgml
 703         doc/lxc-freeze.sgml
 704         doc/lxc-info.sgml
 705         doc/lxc-ls.sgml
 706         doc/lxc-monitor.sgml
 707         doc/lxc-snapshot.sgml
 708         doc/lxc-start-ephemeral.sgml
 709         doc/lxc-start.sgml
 710         doc/lxc-stop.sgml
 711         doc/lxc-top.sgml
 712         doc/lxc-unfreeze.sgml
 713         doc/lxc-unshare.sgml
 714         doc/lxc-user-nic.sgml
 715         doc/lxc-usernsexec.sgml
 716         doc/lxc-wait.sgml
 717
 718         doc/lxc.conf.sgml
 719         doc/lxc.container.conf.sgml
 720         doc/lxc.system.conf.sgml
 721         doc/lxc-usernet.sgml
 722         doc/lxc.sgml
 723         doc/common_options.sgml
 724         doc/see_also.sgml
 725
 726         doc/rootfs/Makefile
 727
 728         doc/examples/Makefile
 729         doc/examples/lxc-macvlan.conf
 730         doc/examples/lxc-vlan.conf
 731         doc/examples/lxc-no-netns.conf
 732         doc/examples/lxc-empty-netns.conf
 733         doc/examples/lxc-phys.conf
 734         doc/examples/lxc-veth.conf
 735         doc/examples/lxc-complex.conf
 736
 737         doc/ja/Makefile
 738         doc/ja/lxc-attach.sgml
 739         doc/ja/lxc-autostart.sgml
 740         doc/ja/lxc-cgroup.sgml
 741         doc/ja/lxc-checkconfig.sgml
 742         doc/ja/lxc-checkpoint.sgml
 743         doc/ja/lxc-clone.sgml
 744         doc/ja/lxc-config.sgml
 745         doc/ja/lxc-console.sgml
 746         doc/ja/lxc-copy.sgml
 747         doc/ja/lxc-create.sgml
 748         doc/ja/lxc-destroy.sgml
 749         doc/ja/lxc-device.sgml
 750         doc/ja/lxc-execute.sgml
 751         doc/ja/lxc-freeze.sgml
 752         doc/ja/lxc-info.sgml
 753         doc/ja/lxc-ls.sgml
 754         doc/ja/lxc-monitor.sgml
 755         doc/ja/lxc-snapshot.sgml
 756         doc/ja/lxc-start-ephemeral.sgml
 757         doc/ja/lxc-start.sgml
 758         doc/ja/lxc-stop.sgml
 759         doc/ja/lxc-top.sgml
 760         doc/ja/lxc-unfreeze.sgml
 761         doc/ja/lxc-unshare.sgml
 762         doc/ja/lxc-user-nic.sgml
 763         doc/ja/lxc-usernsexec.sgml
 764         doc/ja/lxc-wait.sgml
 765
 766         doc/ja/lxc.conf.sgml
 767         doc/ja/lxc.container.conf.sgml
 768         doc/ja/lxc.system.conf.sgml
 769         doc/ja/lxc-usernet.sgml
 770         doc/ja/lxc.sgml
 771         doc/ja/common_options.sgml
 772         doc/ja/see_also.sgml
 773
 774         doc/ko/Makefile
 775         doc/ko/lxc-attach.sgml
 776         doc/ko/lxc-autostart.sgml
 777         doc/ko/lxc-cgroup.sgml
 778         doc/ko/lxc-checkconfig.sgml
 779         doc/ko/lxc-checkpoint.sgml
 780         doc/ko/lxc-clone.sgml
 781         doc/ko/lxc-config.sgml
 782         doc/ko/lxc-console.sgml
 783         doc/ko/lxc-copy.sgml
 784         doc/ko/lxc-create.sgml
 785         doc/ko/lxc-destroy.sgml
 786         doc/ko/lxc-device.sgml
 787         doc/ko/lxc-execute.sgml
 788         doc/ko/lxc-freeze.sgml
 789         doc/ko/lxc-info.sgml
 790         doc/ko/lxc-ls.sgml
 791         doc/ko/lxc-monitor.sgml
 792         doc/ko/lxc-snapshot.sgml
 793         doc/ko/lxc-start-ephemeral.sgml
 794         doc/ko/lxc-start.sgml
 795         doc/ko/lxc-stop.sgml
 796         doc/ko/lxc-top.sgml
 797         doc/ko/lxc-unfreeze.sgml
 798         doc/ko/lxc-unshare.sgml
 799         doc/ko/lxc-user-nic.sgml
 800         doc/ko/lxc-usernsexec.sgml
 801         doc/ko/lxc-wait.sgml
 802
 803         doc/ko/lxc.conf.sgml
 804         doc/ko/lxc.container.conf.sgml
 805         doc/ko/lxc.system.conf.sgml
 806         doc/ko/lxc-usernet.sgml
 807         doc/ko/lxc.sgml
 808         doc/ko/common_options.sgml
 809         doc/ko/see_also.sgml
 810
 811         hooks/Makefile
 812
 813         templates/Makefile
 814         templates/lxc-alpine
 815         templates/lxc-altlinux
 816         templates/lxc-archlinux
 817         templates/lxc-busybox
 818         templates/lxc-centos
 819         templates/lxc-cirros
 820         templates/lxc-debian
 821         templates/lxc-download
 822         templates/lxc-fedora
 823         templates/lxc-gentoo
 824         templates/lxc-openmandriva
 825         templates/lxc-opensuse
 826         templates/lxc-oracle
 827         templates/lxc-plamo
 828         templates/lxc-slackware
 829         templates/lxc-sshd
 830         templates/lxc-ubuntu
 831         templates/lxc-ubuntu-cloud
 832         templates/lxc-sparclinux
 833
 834         src/Makefile
 835         src/lxc/Makefile
 836         src/lxc/lxc-checkconfig
 837         src/lxc/lxc-start-ephemeral
 838         src/lxc/lxc.functions
 839         src/lxc/version.h
 840         src/python-lxc/Makefile
 841         src/python-lxc/setup.py
 842
 843         src/lua-lxc/Makefile
 844
 845         src/tests/Makefile
 846         src/tests/lxc-test-usernic
 847 ])
 848 AC_CONFIG_COMMANDS([default],[[]],[[]])
 849 AC_OUTPUT
 850
 851 # Configuration overview
 852 cat << EOF
 853
 854 ----------------------------
 855 Environment:
 856  - compiler: $CC
 857  - distribution: $with_distro
 858  - init script type(s): $init_script
 859  - rpath: $enable_rpath
 860  - GnuTLS: $enable_gnutls
 861  - Bash integration: $enable_bash
 862
 863 Security features:
 864  - Apparmor: $enable_apparmor
 865  - Linux capabilities: $enable_capabilities
 866  - seccomp: $enable_seccomp
 867  - SELinux: $enable_selinux
 868  - cgmanager: $enable_cgmanager
 869
 870 Bindings:
 871  - lua: $enable_lua
 872  - python3: $enable_python
 873
 874 Documentation:
 875  - examples: $enable_examples
 876  - API documentation: $enable_api_docs
 877  - user documentation: $enable_doc
 878
 879 Debugging:
 880  - tests: $enable_tests
 881  - mutex debugging: $enable_mutex_debugging
 882
 883 Paths:
 884  - Logs in configpath: $enable_configpath_log
 885 EOF
 886
 887 if test "x$ac_cv_func_pthread_atfork" = "xno" ; then
 888 cat << EOF
 889
 890 WARNING: Threading not supported on your platform
 891
 892         You are compiling LXC for bionic target which lacks certain threading related functionality used by LXC API (like pthread_atfork).
 893         Please note that, because of the missing functionality, multithreaded usage of LXC API cause some problems.
 894 EOF
 895 fi