configure.ac

   1 ##
   2 ## Configure template file for FRRouting.
   3 ## autoconf will generate a configure script.
   4 ##
   5 ##  Copyright (c) 1996, 97, 98, 99, 2000 Kunihiro Ishiguro <kunihiro@zebra.org>
   6 ##  Portions Copyright (c) 2003 Paul Jakma <paul@dishone.st>
   7 ##
   8 AC_PREREQ([2.60])
   9
  10 AC_INIT([frr], [7.4-dev], [https://github.com/frrouting/frr/issues])
  11 PACKAGE_URL="https://frrouting.org/"
  12 AC_SUBST([PACKAGE_URL])
  13 PACKAGE_FULLNAME="FRRouting"
  14 AC_SUBST([PACKAGE_FULLNAME])
  15
  16 CONFIG_ARGS="`echo $ac_configure_args | sed -e \"s% '[[A-Z]]*FLAGS=[[^']]\+'%%g\"`"
  17 AC_SUBST([CONFIG_ARGS])
  18
  19 AC_CONFIG_SRCDIR([lib/zebra.h])
  20 AC_CONFIG_MACRO_DIR([m4])
  21
  22 dnl -----------------------------------
  23 dnl Get hostname and other information.
  24 dnl -----------------------------------
  25 AC_CANONICAL_BUILD()
  26 AC_CANONICAL_HOST()
  27
  28 hosttools_clippy="false"
  29 build_clippy="true"
  30
  31 dnl case 1: external clippy
  32 if test -n "$with_clippy" -a "$with_clippy" != "no" -a "$with_clippy" != "yes"; then
  33   if test "$enable_clippy_only" = "yes"; then
  34     AC_MSG_ERROR([--enable-clippy-only does not make sense with --with-clippy])
  35   fi
  36
  37   CLIPPY="$with_clippy"
  38   build_clippy="false"
  39   if test ! -x "$with_clippy"; then
  40     AC_MSG_ERROR([clippy tool ($with_clippy) is not executable])
  41   fi
  42
  43 dnl case 2: cross-compiling internal clippy
  44 elif test "$host" != "$build"; then
  45   if test "$srcdir" = "."; then
  46     AC_MSG_ERROR([cross-compilation is only possible with builddir separate from srcdir or by building clippy separately and using the --with-clippy option.  create a separate directory and run as .../path-to-frr/configure.])
  47   fi
  48   test -d hosttools || mkdir hosttools
  49   abssrc="`cd \"${srcdir}\"; pwd`"
  50
  51   AC_MSG_NOTICE([...])
  52   AC_MSG_NOTICE([... cross-compilation: creating hosttools directory and self-configuring for build platform tools])
  53   AC_MSG_NOTICE([... use HOST_CPPFLAGS / HOST_CFLAGS / HOST_LDFLAGS if neccessary])
  54   AC_MSG_NOTICE([...])
  55
  56   (
  57     for var in $ac_precious_vars; do
  58       dnl special cases
  59       case "$var" in
  60       YACC|YFLAGS) continue;;
  61       PYTHON*)     retain=true;;
  62       *)           retain=false;
  63       esac
  64
  65       eval "hostvar=\"\${HOST_$var}\""
  66       eval "targetvar=\"\${$var}\""
  67       if test -n "$hostvar"; then
  68         eval "$var='$hostvar'"
  69         _AS_ECHO_LOG([host $var='$hostvar'])
  70       elif $retain; then
  71         _AS_ECHO_LOG([host retain $var='$targetvar'])
  72       else
  73         eval "unset $var"
  74         _AS_ECHO_LOG([host unset $var])
  75       fi
  76     done
  77     cd hosttools
  78     "${abssrc}/configure" "--host=$build" "--build=$build" "--enable-clippy-only" "--disable-nhrpd" "--disable-vtysh"
  79   ) || exit 1
  80
  81   AC_MSG_NOTICE([...])
  82   AC_MSG_NOTICE([... cross-compilation: finished self-configuring for build platform tools])
  83   AC_MSG_NOTICE([...])
  84
  85   build_clippy="false"
  86   hosttools_clippy="true"
  87   CLIPPY="hosttools/lib/clippy"
  88
  89 dnl case 3: normal build internal clippy
  90 else
  91   CLIPPY="lib/clippy\$(EXEEXT)"
  92 fi
  93 AC_SUBST([CLIPPY])
  94 AM_CONDITIONAL([BUILD_CLIPPY], [$build_clippy])
  95 AM_CONDITIONAL([HOSTTOOLS_CLIPPY], [$hosttools_clippy])
  96 AM_CONDITIONAL([ONLY_CLIPPY], [test "$enable_clippy_only" = "yes"])
  97
  98 # Disable portability warnings -- our automake code (in particular
  99 # common.am) uses some constructs specific to gmake.
 100 AM_INIT_AUTOMAKE([1.12 -Wno-portability foreign])
 101 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
 102 AM_SILENT_RULES([yes])
 103 AC_CONFIG_HEADERS([config.h])
 104
 105 AC_PATH_PROG([PERL], [perl])
 106 PKG_PROG_PKG_CONFIG
 107
 108 dnl default is to match previous behavior
 109 exampledir=${sysconfdir}
 110 AC_ARG_ENABLE([exampledir],
 111           AS_HELP_STRING([--enable-exampledir],
 112                          [specify alternate directory for examples]),
 113                          exampledir="$enableval",)
 114 dnl XXX add --exampledir to autoconf standard directory list somehow
 115 AC_SUBST([exampledir])
 116
 117 dnl default is to match previous behavior
 118 pkgsrcrcdir=""
 119 AC_ARG_ENABLE([pkgsrcrcdir],
 120           AS_HELP_STRING([--enable-pkgsrcrcdir],
 121                          [specify directory for rc.d scripts]),
 122                          pkgsrcrcdir="$enableval",)
 123 dnl XXX add --pkgsrcrcdir to autoconf standard directory list somehow
 124 AC_SUBST([pkgsrcrcdir])
 125 AM_CONDITIONAL([PKGSRC], [test "$pkgsrcrcdir" != ""])
 126
 127 AC_ARG_WITH([moduledir], [AS_HELP_STRING([--with-moduledir=DIR], [module directory (${libdir}/frr/modules)])], [
 128         moduledir="$withval"
 129 ], [
 130         moduledir="\${libdir}/frr/modules"
 131 ])
 132 AC_SUBST([moduledir], [$moduledir])
 133
 134
 135 AC_ARG_WITH([yangmodelsdir], [AS_HELP_STRING([--with-yangmodelsdir=DIR], [yang models directory (${datarootdir}/yang)])], [
 136         yangmodelsdir="$withval"
 137 ], [
 138         yangmodelsdir="\${datarootdir}/yang"
 139 ])
 140 AC_SUBST([yangmodelsdir])
 141
 142 AC_ARG_ENABLE(tcmalloc,
 143         AS_HELP_STRING([--enable-tcmalloc], [Turn on tcmalloc]),
 144 [case "${enableval}" in
 145   yes) tcmalloc_enabled=true
 146 LIBS="$LIBS -ltcmalloc_minimal"
 147  ;;
 148   no)  tcmalloc_enabled=false ;;
 149   *) AC_MSG_ERROR([bad value ${enableval} for --enable-tcmalloc]) ;;
 150 esac],[tcmalloc_enabled=false])
 151
 152
 153 dnl Thanks autoconf, but we don't want a default -g -O2.  We have our own
 154 dnl flag determination logic.
 155 CFLAGS="${CFLAGS:-}"
 156
 157 dnl --------------------
 158 dnl Check CC and friends
 159 dnl --------------------
 160 dnl note orig_cflags is also used further down
 161 orig_cflags="$CFLAGS"
 162 orig_cxxflags="$CXXFLAGS"
 163 AC_LANG([C])
 164 AC_PROG_CC
 165 AC_PROG_CPP
 166 AC_PROG_CXX
 167 AM_PROG_CC_C_O
 168 dnl remove autoconf default "-g -O2"
 169 CFLAGS="$orig_cflags"
 170 CXXFLAGS="$orig_cxxflags"
 171 AC_PROG_CC_C99
 172 dnl NB: see C11 below
 173
 174 PKG_PROG_PKG_CONFIG
 175
 176 dnl it's 2019, sed is sed.
 177 SED=sed
 178 AC_SUBST([SED])
 179
 180 dnl try and enable CFLAGS that are useful for FRR
 181 dnl - specifically, options to control warnings
 182
 183 AC_USE_SYSTEM_EXTENSIONS
 184 AC_DEFUN([AC_C_FLAG], [{
 185     m4_pushdef([cachename],[m4_translit([frr_cv_$1],[ =-+/{}$],[________])])
 186     AC_CACHE_CHECK([[whether $CC supports $1]], cachename, [
 187         AC_LANG_PUSH([C])
 188         ac_c_flag_save="$CFLAGS"
 189         CFLAGS="$CFLAGS $1"
 190         AC_COMPILE_IFELSE(
 191                 [AC_LANG_PROGRAM([[$4]])],
 192                 [
 193                         cachename=yes
 194                 ], [
 195                         cachename=no
 196                 ])
 197         CFLAGS="$ac_c_flag_save"
 198         AC_LANG_POP([C])
 199     ])
 200     if test "$cachename" = "yes"; then
 201         m4_if([$3], [], [CFLAGS="$CFLAGS $1"], [$3])
 202     else
 203         :
 204         $2
 205     fi
 206     m4_popdef([cachename])
 207 }])
 208
 209 AC_DEFUN([AC_LINK_IFELSE_FLAGS], [{
 210         AC_LANG_PUSH([C])
 211         ac_cflags_save="$CFLAGS"
 212         ac_libs_save="$LIBS"
 213         CFLAGS="$CFLAGS $1"
 214         LIBS="$LIBS $2"
 215         AC_LINK_IFELSE(
 216                 [$3],
 217                 [
 218                         CFLAGS="$ac_cflags_save"
 219                         LIBS="$ac_libs_save"
 220                         m4_default([$5], [
 221                                 AC_MSG_RESULT([yes])
 222                         ])
 223                 ], [
 224                         CFLAGS="$ac_cflags_save"
 225                         LIBS="$ac_libs_save"
 226                         m4_default([$4], [
 227                                 AC_MSG_RESULT([no])
 228                         ])
 229                 ])
 230         AC_LANG_POP([C])
 231         }])
 232
 233 dnl ICC won't bail on unknown options without -diag-error 10006
 234 dnl need to do this first so we get useful results for the other options
 235 AC_C_FLAG([-diag-error 10006])
 236
 237 dnl AC_PROG_CC_C99 may change CC to include -std=gnu99 or something
 238 ac_cc="$CC"
 239 CC="${CC% -std=gnu99}"
 240 CC="${CC% -std=c99}"
 241
 242 AC_C_FLAG([-std=gnu11], [CC="$ac_cc"], [CC="$CC -std=gnu11"])
 243
 244 dnl if the user has specified any CFLAGS, override our settings
 245 if test "$enable_gcov" = "yes"; then
 246    if test "$orig_cflags" = ""; then
 247       AC_C_FLAG([-coverage])
 248       AC_C_FLAG([-O0])
 249    fi
 250
 251    LDFLAGS="${LDFLAGS} -lgcov"
 252 fi
 253
 254 if test "$enable_clang_coverage" = "yes"; then
 255    AC_C_FLAG([-fprofile-instr-generate], [
 256      AC_MSG_ERROR([$CC does not support -fprofile-instr-generate.])
 257    ])
 258    AC_C_FLAG([-fcoverage-mapping], [
 259      AC_MSG_ERROR([$CC does not support -fcoverage-mapping.])
 260    ])
 261 fi
 262
 263 if test "$enable_dev_build" = "yes"; then
 264    AC_DEFINE([DEV_BUILD], [1], [Build for development])
 265    if test "$orig_cflags" = ""; then
 266       AC_C_FLAG([-g3])
 267       AC_C_FLAG([-O0])
 268    fi
 269    if test "$enable_lua" = "yes"; then
 270       AX_PROG_LUA([5.3])
 271       AX_LUA_HEADERS
 272       AX_LUA_LIBS([
 273          AC_DEFINE([HAVE_LUA], [1], [Have support for Lua interpreter])
 274          LIBS="$LIBS $LUA_LIB"
 275       ])
 276    fi
 277 else
 278    if test "$enable_lua" = "yes"; then
 279       AC_MSG_ERROR([Lua is not meant to be built/used outside of development at this time])
 280    fi
 281    if test "$orig_cflags" = ""; then
 282       AC_C_FLAG([-g])
 283       AC_C_FLAG([-O2])
 284    fi
 285 fi
 286 AM_CONDITIONAL([DEV_BUILD], [test "$enable_dev_build" = "yes"])
 287
 288 dnl always want these CFLAGS
 289 AC_C_FLAG([-fno-omit-frame-pointer])
 290 AC_C_FLAG([-funwind-tables])
 291 AC_C_FLAG([-Wall])
 292 AC_C_FLAG([-Wextra])
 293 AC_C_FLAG([-Wmissing-prototypes])
 294 AC_C_FLAG([-Wmissing-declarations])
 295 AC_C_FLAG([-Wpointer-arith])
 296 AC_C_FLAG([-Wbad-function-cast])
 297 AC_C_FLAG([-Wwrite-strings])
 298 AC_C_FLAG([-Wundef])
 299 if test "$enable_gcc_ultra_verbose" = "yes" ; then
 300   AC_C_FLAG([-Wcast-qual])
 301   AC_C_FLAG([-Wstrict-prototypes])
 302   AC_C_FLAG([-Wmissing-noreturn])
 303   AC_C_FLAG([-Wmissing-format-attribute])
 304   AC_C_FLAG([-Wunreachable-code])
 305   AC_C_FLAG([-Wpacked])
 306   AC_C_FLAG([-Wpadded])
 307   AC_C_FLAG([-Wshadow])
 308 else
 309   AC_C_FLAG([-Wno-unused-result])
 310 fi
 311 AC_C_FLAG([-Wno-unused-parameter])
 312 AC_C_FLAG([-Wno-missing-field-initializers])
 313
 314 AC_C_FLAG([-Wc++-compat], [], [CXX_COMPAT_CFLAGS="-Wc++-compat"])
 315 AC_SUBST([CXX_COMPAT_CFLAGS])
 316
 317 dnl ICC emits a broken warning for const char *x = a ? "b" : "c";
 318 dnl for some reason the string consts get 'promoted' to char *,
 319 dnl triggering a const to non-const conversion warning.
 320 AC_C_FLAG([-diag-disable 3179])
 321
 322 if test "$enable_werror" = "yes" ; then
 323   WERROR="-Werror"
 324 fi
 325 AC_SUBST([WERROR])
 326
 327 SAN_FLAGS=""
 328 if test "$enable_address_sanitizer" = "yes"; then
 329   AC_C_FLAG([-fsanitize=address], [
 330     AC_MSG_ERROR([$CC does not support Address Sanitizer.])
 331   ], [
 332     SAN_FLAGS="$SAN_FLAGS -fsanitize=address"
 333   ])
 334 fi
 335 if test "$enable_thread_sanitizer" = "yes"; then
 336   AC_C_FLAG([-fsanitize=thread], [
 337     AC_MSG_ERROR([$CC does not support Thread Sanitizer.])
 338   ], [
 339     SAN_FLAGS="$SAN_FLAGS -fsanitize=thread"
 340   ])
 341 fi
 342 if test "$enable_memory_sanitizer" = "yes"; then
 343   AC_C_FLAG([-fsanitize=memory -fPIE -pie], [
 344     AC_MSG_ERROR([$CC does not support Memory Sanitizer.])
 345   ], [
 346     SAN_FLAGS="$SAN_FLAGS -fsanitize=memory -fPIE -pie"
 347   ])
 348 fi
 349 if test "$enable_undefined_sanitizer" = "yes"; then
 350   AC_C_FLAG([-fsanitize=undefined], [
 351     AC_MSG_ERROR([$CC does not support UndefinedBehaviorSanitizer.])
 352   ], [
 353     SAN_FLAGS="$SAN_FLAGS -fsanitize=undefined"
 354   ])
 355 fi
 356 AC_SUBST([SAN_FLAGS])
 357
 358 dnl frr-format.so
 359 if test "$with_frr_format" != "no" -a "$with_frr_format" != "yes" -a -n "$with_frr_format"; then
 360   AC_C_FLAG([-fplugin=${with_frr_format}], [
 361     AC_MSG_ERROR([specified frr-format plugin ($with_frr_format) does not work])
 362   ],,[
 363 #ifndef _FRR_ATTRIBUTE_PRINTFRR
 364 #error plugin not loaded
 365 #endif
 366 #if _FRR_ATTRIBUTE_PRINTFRR < 0x10000
 367 #error plugin too old
 368 #endif
 369   ])
 370 elif test "$with_frr_format" = "no"; then
 371   : #nothing
 372 else
 373   AC_C_FLAG([-fplugin=tools/gcc-plugins/frr-format.so],[
 374     AC_C_FLAG([-fplugin=frr-format],[
 375       if test "$with_frr_format" = "yes"; then
 376         AC_MSG_ERROR([frr-format plugin requested but not found])
 377       fi
 378     ],,[
 379 #ifndef _FRR_ATTRIBUTE_PRINTFRR
 380 #error plugin not loaded
 381 #endif
 382 #if _FRR_ATTRIBUTE_PRINTFRR < 0x10000
 383 #error plugin too old
 384 #endif
 385     ])
 386   ],,[
 387 #ifndef _FRR_ATTRIBUTE_PRINTFRR
 388 #error plugin not loaded
 389 #endif
 390 #if _FRR_ATTRIBUTE_PRINTFRR < 0x10000
 391 #error plugin too old
 392 #endif
 393   ])
 394 fi
 395
 396 dnl ----------
 397 dnl Essentials
 398 dnl ----------
 399
 400 AX_PTHREAD([
 401   CC="$PTHREAD_CC"
 402   CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 403   LIBS="$PTHREAD_LIBS $LIBS"
 404 ], [
 405   AC_MSG_FAILURE([This FRR version needs pthreads])
 406 ])
 407
 408 AC_SEARCH_LIBS([pthread_condattr_setclock], [],
 409                 [frr_cv_pthread_condattr_setclock=yes],
 410                 [frr_cv_pthread_condattr_setclock=no])
 411 if test "$frr_cv_pthread_condattr_setclock" = "yes"; then
 412   AC_DEFINE([HAVE_PTHREAD_CONDATTR_SETCLOCK], [1], [Have pthread.h pthread_condattr_setclock])
 413 fi
 414
 415 dnl --------------
 416 dnl Check programs
 417 dnl --------------
 418 AC_PROG_INSTALL
 419 AC_PROG_LN_S
 420 AC_CHECK_TOOL([AR], [ar])
 421
 422 dnl -------
 423 dnl libtool
 424 dnl -------
 425 AC_ARG_ENABLE([static-bin],
 426   AS_HELP_STRING([--enable-static-bin], [link binaries statically]))
 427 LT_INIT
 428 _LT_CONFIG_LIBTOOL([
 429   patch -N -i "${srcdir}/m4/libtool-whole-archive.patch" libtool >&AS_MESSAGE_LOG_FD || \
 430     AC_MSG_WARN([Could not patch libtool for static linking support.  Loading modules into a statically linked daemon will fail.])
 431   sed -e 's%func_warning "relinking%true #\0%' -i libtool || true
 432   sed -e 's%func_warning "remember to run%true #\0%' -i libtool || true
 433   sed -e 's%func_warning ".*has not been installed in%true #\0%' -i libtool || true
 434 ])
 435 if test "$enable_static_bin" = "yes"; then
 436   AC_LDFLAGS="-static"
 437   if test "$enable_static" != "yes"; then
 438     AC_MSG_ERROR([The --enable-static-bin option must be combined with --enable-static.])
 439   fi
 440 fi
 441 if test "$enable_shared" != "yes"; then
 442   AC_MSG_ERROR([FRR cannot be built with --disable-shared.  If you want statically linked daemons, use --enable-shared --enable-static --enable-static-bin])
 443 fi
 444 AC_SUBST([AC_LDFLAGS])
 445 AM_CONDITIONAL([STATIC_BIN], [test "$enable_static_bin" = "yes"])
 446
 447 dnl $AR and $RANLIB are set by LT_INIT above
 448 AC_MSG_CHECKING([whether $AR supports D option])
 449 if $AR crD conftest.a >/dev/null 2>/dev/null; then
 450   AC_MSG_RESULT([yes])
 451   dnl ARFLAGS is for automake, AR_FLAGS for libtool m-(
 452   ARFLAGS="crD"
 453   AR_FLAGS="crD"
 454 else
 455   AC_MSG_RESULT([no])
 456   ARFLAGS="cru"
 457   AR_FLAGS="cru"
 458 fi
 459 AC_SUBST([ARFLAGS])
 460 AC_SUBST([AR_FLAGS])
 461
 462 AC_MSG_CHECKING([whether $RANLIB supports D option])
 463 if $RANLIB -D conftest.a >conftest.err 2>&1; then
 464   if grep -q -- '-D' conftest.err; then
 465     AC_MSG_RESULT([no])
 466   else
 467     AC_MSG_RESULT([yes])
 468     RANLIB="$RANLIB -D"
 469   fi
 470 else
 471   AC_MSG_RESULT([no])
 472 fi
 473 AC_SUBST([RANLIB])
 474
 475 test -f conftest.err && rm conftest.err
 476 test -f conftest.a && rm conftest.a
 477
 478 dnl ----------------------
 479 dnl Packages configuration
 480 dnl ----------------------
 481 if test -f config.version; then
 482   . ./config.version
 483 elif test -f "${srcdir}/config.version"; then
 484   . "${srcdir}/config.version"
 485 fi
 486 AC_ARG_WITH([pkg-extra-version],
 487   AS_HELP_STRING([--with-pkg-extra-version=VER], [add extra version field, for packagers/distributions]), [
 488   if test "$withval" = "no"; then
 489     EXTRAVERSION=
 490   else
 491     EXTRAVERSION=$withval
 492   fi
 493 ], [])
 494 AC_ARG_WITH([pkg-git-version],
 495         AS_HELP_STRING([--with-pkg-git-version], [add git information to MOTD and build version string]),
 496         [ test "$withval" != "no" && with_pkg_git_version="yes" ])
 497 AC_ARG_WITH([clippy],
 498   AS_HELP_STRING([--with-clippy=PATH], [use external clippy helper program]))
 499 AC_ARG_WITH([vtysh_pager],
 500         AS_HELP_STRING([--with-vtysh-pager=PAGER], [control what pager is compiled in as default]),
 501         VTYSH_PAGER=$withval, VTYSH_PAGER="more")
 502 AC_ARG_ENABLE([vtysh],
 503   AS_HELP_STRING([--disable-vtysh], [do not build integrated vty shell for FRR]))
 504 AC_ARG_ENABLE([doc],
 505   AS_HELP_STRING([--disable-doc], [do not build docs]))
 506 AC_ARG_ENABLE([doc-html],
 507   AS_HELP_STRING([--enable-doc-html], [build HTML docs]))
 508 AC_ARG_ENABLE([zebra],
 509   AS_HELP_STRING([--disable-zebra], [do not build zebra daemon]))
 510 AC_ARG_ENABLE([bgpd],
 511   AS_HELP_STRING([--disable-bgpd], [do not build bgpd]))
 512 AC_ARG_ENABLE([ripd],
 513   AS_HELP_STRING([--disable-ripd], [do not build ripd]))
 514 AC_ARG_ENABLE([ripngd],
 515   AS_HELP_STRING([--disable-ripngd], [do not build ripngd]))
 516 AC_ARG_ENABLE([ospfd],
 517   AS_HELP_STRING([--disable-ospfd], [do not build ospfd]))
 518 AC_ARG_ENABLE([ospf6d],
 519   AS_HELP_STRING([--disable-ospf6d], [do not build ospf6d]))
 520 AC_ARG_ENABLE([ldpd],
 521   AS_HELP_STRING([--disable-ldpd], [do not build ldpd]))
 522 AC_ARG_ENABLE([nhrpd],
 523   AS_HELP_STRING([--disable-nhrpd], [do not build nhrpd]))
 524 AC_ARG_ENABLE([eigrpd],
 525   AS_HELP_STRING([--disable-eigrpd], [do not build eigrpd]))
 526 AC_ARG_ENABLE([babeld],
 527   AS_HELP_STRING([--disable-babeld], [do not build babeld]))
 528 AC_ARG_ENABLE([watchfrr],
 529   AS_HELP_STRING([--disable-watchfrr], [do not build watchfrr]))
 530 AC_ARG_ENABLE([isisd],
 531   AS_HELP_STRING([--disable-isisd], [do not build isisd]))
 532 AC_ARG_ENABLE([pimd],
 533   AS_HELP_STRING([--disable-pimd], [do not build pimd]))
 534 AC_ARG_ENABLE([pbrd],
 535   AS_HELP_STRING([--disable-pbrd], [do not build pbrd]))
 536 AC_ARG_ENABLE([sharpd],
 537   AS_HELP_STRING([--enable-sharpd], [build sharpd]))
 538 AC_ARG_ENABLE([staticd],
 539   AS_HELP_STRING([--disable-staticd], [do not build staticd]))
 540 AC_ARG_ENABLE([fabricd],
 541   AS_HELP_STRING([--disable-fabricd], [do not build fabricd]))
 542 AC_ARG_ENABLE([vrrpd],
 543   AS_HELP_STRING([--disable-vrrpd], [do not build vrrpd]))
 544 AC_ARG_ENABLE([bgp-announce],
 545   AS_HELP_STRING([--disable-bgp-announce,], [turn off BGP route announcement]))
 546 AC_ARG_ENABLE([bgp-vnc],
 547   AS_HELP_STRING([--disable-bgp-vnc],[turn off BGP VNC support]))
 548 AC_ARG_ENABLE([bgp-bmp],
 549   AS_HELP_STRING([--disable-bgp-bmp],[turn off BGP BMP support]))
 550 AC_ARG_ENABLE([snmp],
 551   AS_HELP_STRING([--enable-snmp], [enable SNMP support for agentx]))
 552 AC_ARG_ENABLE([config_rollbacks],
 553   AS_HELP_STRING([--enable-config-rollbacks], [enable configuration rollbacks (requires sqlite3)]))
 554 AC_ARG_ENABLE([confd],
 555   AS_HELP_STRING([--enable-confd=ARG], [enable confd integration]))
 556 AC_ARG_ENABLE([sysrepo],
 557   AS_HELP_STRING([--enable-sysrepo], [enable sysrepo integration]))
 558 AC_ARG_ENABLE([grpc],
 559   AS_HELP_STRING([--enable-grpc], [enable the gRPC northbound plugin]))
 560 AC_ARG_ENABLE([zeromq],
 561   AS_HELP_STRING([--enable-zeromq], [enable ZeroMQ handler (libfrrzmq)]))
 562 AC_ARG_WITH([libpam],
 563   AS_HELP_STRING([--with-libpam], [use libpam for PAM support in vtysh]))
 564 AC_ARG_ENABLE([ospfapi],
 565   AS_HELP_STRING([--disable-ospfapi], [do not build OSPFAPI to access the OSPF LSA Database]))
 566 AC_ARG_ENABLE([ospfclient],
 567   AS_HELP_STRING([--disable-ospfclient], [do not build OSPFAPI client for OSPFAPI,
 568                           (this is the default if --disable-ospfapi is set)]))
 569 AC_ARG_ENABLE([multipath],
 570   AS_HELP_STRING([--enable-multipath=ARG], [enable multipath function, ARG must be digit]))
 571 AC_ARG_ENABLE([user],
 572   AS_HELP_STRING([--enable-user=USER], [user to run FRR suite as (default frr)]))
 573 AC_ARG_ENABLE([group],
 574   AS_HELP_STRING([--enable-group=GROUP], [group to run FRR suite as (default frr)]))
 575 AC_ARG_ENABLE([vty_group],
 576   AS_HELP_STRING([--enable-vty-group=ARG], [set vty sockets to have specified group as owner]))
 577 AC_ARG_ENABLE([configfile_mask],
 578   AS_HELP_STRING([--enable-configfile-mask=ARG], [set mask for config files]))
 579 AC_ARG_ENABLE([logfile_mask],
 580   AS_HELP_STRING([--enable-logfile-mask=ARG], [set mask for log files]))
 581 AC_ARG_ENABLE([shell_access],
 582   AS_HELP_STRING([--enable-shell-access], [Allow users to access shell/telnet/ssh]))
 583 AC_ARG_ENABLE([realms],
 584   AS_HELP_STRING([--enable-realms], [enable REALMS support under Linux]))
 585 AC_ARG_ENABLE([rtadv],
 586   AS_HELP_STRING([--disable-rtadv], [disable IPV6 router advertisement feature]))
 587 AC_ARG_ENABLE([irdp],
 588   AS_HELP_STRING([--disable-irdp], [disable IRDP server support in zebra (enabled by default if supported)]))
 589 AC_ARG_ENABLE([capabilities],
 590   AS_HELP_STRING([--disable-capabilities], [disable using POSIX capabilities]))
 591 AC_ARG_ENABLE([rusage],
 592   AS_HELP_STRING([--disable-rusage], [disable using getrusage]))
 593 AC_ARG_ENABLE([gcc_ultra_verbose],
 594   AS_HELP_STRING([--enable-gcc-ultra-verbose], [enable ultra verbose GCC warnings]))
 595 AC_ARG_ENABLE([backtrace],
 596   AS_HELP_STRING([--disable-backtrace,], [disable crash backtraces (default autodetect)]))
 597 AC_ARG_ENABLE([time-check],
 598   AS_HELP_STRING([--disable-time-check], [disable slow thread warning messages]))
 599 AC_ARG_ENABLE([cpu-time],
 600   AS_HELP_STRING([--disable-cpu-time], [disable cpu usage data gathering]))
 601 AC_ARG_ENABLE([pcreposix],
 602   AS_HELP_STRING([--enable-pcreposix], [enable using PCRE Posix libs for regex functions]))
 603 AC_ARG_ENABLE([fpm],
 604   AS_HELP_STRING([--enable-fpm], [enable Forwarding Plane Manager support]))
 605 AC_ARG_ENABLE([systemd],
 606   AS_HELP_STRING([--enable-systemd], [enable Systemd support]))
 607 AC_ARG_ENABLE([werror],
 608   AS_HELP_STRING([--enable-werror], [enable -Werror (recommended for developers only)]))
 609 AC_ARG_ENABLE([cumulus],
 610   AS_HELP_STRING([--enable-cumulus], [enable Cumulus Switch Special Extensions]))
 611 AC_ARG_ENABLE([datacenter],
 612   AS_HELP_STRING([--enable-datacenter], [enable Compilation for Data Center Extensions]))
 613 AC_ARG_ENABLE([fuzzing],
 614   AS_HELP_STRING([--enable-fuzzing], [enable ability to fuzz various parts of FRR]))
 615 AC_ARG_ENABLE([netlink_fuzzing],
 616   AS_HELP_STRING([--enable-netlink-fuzzing], [enable ability to fuzz netlink listening socket in zebra]))
 617 AC_ARG_ENABLE([rr-semantics],
 618   AS_HELP_STRING([--disable-rr-semantics], [disable the v6 Route Replace semantics]))
 619 AC_ARG_ENABLE([protobuf],
 620   AS_HELP_STRING([--enable-protobuf], [Enable experimental protobuf support]))
 621 AC_ARG_ENABLE([oldvpn_commands],
 622   AS_HELP_STRING([--enable-oldvpn-commands], [Keep old vpn commands]))
 623 AC_ARG_ENABLE([rpki],
 624   AS_HELP_STRING([--enable-rpki], [enable RPKI prefix validation support]))
 625 AC_ARG_ENABLE([clippy-only],
 626   AS_HELP_STRING([--enable-clippy-only], [Only build clippy]))
 627 AC_ARG_ENABLE([numeric_version],
 628   AS_HELP_STRING([--enable-numeric-version], [Only numeric digits allowed in version (for Alpine)]))
 629 AC_ARG_ENABLE([gcov],
 630   AS_HELP_STRING([--enable-gcov], [Collect coverage information with gcov]))
 631 AC_ARG_ENABLE([clang_coverage],
 632   AS_HELP_STRING([--enable-clang-coverage], [Collect coverage information with Clang Coverage]))
 633 AC_ARG_ENABLE([bfdd],
 634   AS_HELP_STRING([--disable-bfdd], [do not build bfdd]))
 635 AC_ARG_ENABLE([address-sanitizer],
 636   AS_HELP_STRING([--enable-address-sanitizer], [enable AddressSanitizer support for detecting a wide variety of memory allocation and deallocation errors]))
 637 AC_ARG_ENABLE([thread-sanitizer],
 638   AS_HELP_STRING([--enable-thread-sanitizer], [enable ThreadSanitizer support for detecting data races]))
 639 AC_ARG_ENABLE([memory-sanitizer],
 640   AS_HELP_STRING([--enable-memory-sanitizer], [enable MemorySanitizer support for detecting uninitialized memory reads]))
 641 AC_ARG_ENABLE([undefined-sanitizer],
 642   AS_HELP_STRING([--undefined-sanitizer], [enable UndefinedBehaviorSanitizer support for detecting undefined behavior]))
 643 AC_ARG_WITH([crypto],
 644   AS_HELP_STRING([--with-crypto=<internal|openssl>], [choose between different implementations of cryptographic functions(default value is --with-crypto=internal)]))
 645 AC_ARG_WITH([frr-format],
 646   AS_HELP_STRING([--with-frr-format[=<.../frr-format.so>]], [use frr-format GCC plugin]))
 647
 648 #if openssl, else use the internal
 649 AS_IF([test "$with_crypto" = "openssl"], [
 650 AC_CHECK_LIB([crypto], [EVP_DigestInit], [LIBS="$LIBS -lcrypto"], [], [])
 651 if test "$ac_cv_lib_crypto_EVP_DigestInit" = "no"; then
 652   AC_MSG_ERROR([build with openssl has been specified but openssl library was not found on your system])
 653 else
 654   AC_DEFINE([CRYPTO_OPENSSL], [1], [Compile with openssl support])
 655 fi
 656 ], [test "$with_crypto" = "internal" || test "$with_crypto" = "" ], [AC_DEFINE([CRYPTO_INTERNAL], [1], [Compile with internal cryptographic implementation])
 657 ], [AC_MSG_ERROR([Unknown value for --with-crypto])]
 658 )
 659
 660 AS_IF([test "$enable_clippy_only" != "yes"], [
 661 AC_CHECK_HEADERS([json-c/json.h])
 662 AC_CHECK_LIB([json-c], [json_object_get], [LIBS="$LIBS -ljson-c"], [], [-lm])
 663 if test "$ac_cv_lib_json_c_json_object_get" = "no"; then
 664   AC_CHECK_LIB([json], [json_object_get], [LIBS="$LIBS -ljson"])
 665   if test "$ac_cv_lib_json_json_object_get" = "no"; then
 666       AC_MSG_ERROR([libjson is needed to compile])
 667   fi
 668 fi
 669 ])
 670
 671 AC_ARG_ENABLE([dev_build],
 672     AS_HELP_STRING([--enable-dev-build], [build for development]))
 673
 674 AC_ARG_ENABLE([lua],
 675     AS_HELP_STRING([--enable-lua], [Build Lua scripting]))
 676
 677 if test "$enable_time_check" != "no" ; then
 678   if test "$enable_time_check" = "yes" -o "$enable_time_check" = "" ; then
 679     AC_DEFINE([CONSUMED_TIME_CHECK], [5000000], [Consumed Time Check])
 680   else
 681     AC_DEFINE_UNQUOTED([CONSUMED_TIME_CHECK], [$enable_time_check], [Consumed Time Check])
 682   fi
 683 fi
 684
 685 case "${enable_cpu_time}" in
 686   "no")
 687   AC_DEFINE([EXCLUDE_CPU_TIME], [1], [Exclude getrusage data gathering])
 688   ;;
 689   "*")
 690   ;;
 691 esac
 692
 693 case "${enable_systemd}" in
 694   "no") ;;
 695   "yes")
 696   AC_CHECK_LIB([systemd], [sd_notify], [LIBS="$LIBS -lsystemd"])
 697   if test "$ac_cv_lib_systemd_sd_notify" = "no"; then
 698     AC_MSG_ERROR([enable systemd has been specified but systemd development env not found on your system])
 699   else
 700     AC_DEFINE([HAVE_SYSTEMD], [1], [Compile systemd support in])
 701   fi
 702   ;;
 703   "*") ;;
 704 esac
 705
 706 if test "$enable_rr_semantics" != "no" ; then
 707   AC_DEFINE([HAVE_V6_RR_SEMANTICS], [1], [Compile in v6 Route Replacement Semantics])
 708 fi
 709
 710 if test "$enable_datacenter" = "yes" ; then
 711   AC_DEFINE([HAVE_DATACENTER], [1], [Compile extensions for a DataCenter])
 712   AC_MSG_WARN([The --enable-datacenter compile time option is deprecated.  Please modify the init script to pass -F datacenter to the daemons instead.])
 713   DFLT_NAME="datacenter"
 714 else
 715   DFLT_NAME="traditional"
 716 fi
 717
 718 if test "$enable_fuzzing" = "yes" ; then
 719   AC_DEFINE([HANDLE_ZAPI_FUZZING], [1], [Compile extensions to use with a fuzzer])
 720 fi
 721
 722 if test "$enable_netlink_fuzzing" = "yes" ; then
 723   AC_DEFINE([HANDLE_NETLINK_FUZZING], [1], [Compile extensions to use with a fuzzer for netlink])
 724 fi
 725
 726 if test "$enable_cumulus" = "yes" ; then
 727   AC_DEFINE([HAVE_CUMULUS], [1], [Compile Special Cumulus Code in])
 728 fi
 729
 730 AC_SUBST([DFLT_NAME])
 731 AC_DEFINE_UNQUOTED([DFLT_NAME], ["$DFLT_NAME"], [Name of the configuration default set])
 732
 733 if test "$enable_shell_access" = "yes"; then
 734    AC_DEFINE([HAVE_SHELL_ACCESS], [1], [Allow user to use ssh/telnet/bash, be aware this is considered insecure])
 735 fi
 736
 737 #
 738 # Python for clippy
 739 #
 740
 741 AS_IF([test "$host" = "$build"], [
 742   FRR_PYTHON_DEV
 743 ], [
 744   FRR_PYTHON
 745 ])
 746
 747 FRR_PYTHON_MODULES([pytest])
 748
 749 if test "$enable_doc" != "no"; then
 750   FRR_PYTHON_MODULES([sphinx], , [
 751     if test "$enable_doc" = "yes"; then
 752       AC_MSG_ERROR([Documentation was explicitly requested with --enable-doc but sphinx is not available for $PYTHON. Please disable docs or install sphinx.])
 753     fi
 754   ])
 755 fi
 756 AM_CONDITIONAL([DOC], [test "$enable_doc" != "no" -a "$frr_py_mod_sphinx" != "false"])
 757 AM_CONDITIONAL([DOC_HTML], [test "$enable_doc_html" = "yes"])
 758
 759 FRR_PYTHON_MOD_EXEC([sphinx], [--version], [
 760   PYSPHINX="-m sphinx"
 761 ], [
 762   PYSPHINX="-c 'import sys; from sphinx import main; sys.exit(main(sys.argv))'"
 763 ])
 764 AC_SUBST([PYSPHINX])
 765
 766 #
 767 # Logic for old vpn commands support.
 768 #
 769 if test "$enable_oldvpn_commands" = "yes"; then
 770    AC_DEFINE([KEEP_OLD_VPN_COMMANDS], [1], [Define for compiling with old vpn commands])
 771 fi
 772
 773 #
 774 # End of logic for protobuf support.
 775 #
 776
 777 AC_MSG_CHECKING([if zebra should be configurable to send Route Advertisements])
 778 if test "$enable_rtadv" != "no"; then
 779   AC_MSG_RESULT([yes])
 780   AC_DEFINE([HAVE_RTADV], [1], [Enable IPv6 Routing Advertisement support])
 781 else
 782   AC_MSG_RESULT([no])
 783 fi
 784
 785 if test "$enable_user" = "no"; then
 786   enable_user=""
 787 else
 788   if test "$enable_user" = "yes" || test "$enable_user" = ""; then
 789     enable_user="frr"
 790   fi
 791   AC_DEFINE_UNQUOTED([FRR_USER], ["${enable_user}"], [frr User])
 792 fi
 793
 794 if test "$enable_group" = "no"; then
 795   enable_group=""
 796 else
 797   if test "$enable_group" = "yes" || test "$enable_group" = ""; then
 798     enable_group="frr"
 799   fi
 800   AC_DEFINE_UNQUOTED([FRR_GROUP], ["${enable_group}"], [frr Group])
 801 fi
 802
 803 if test "$enable_vty_group" = "yes" ; then
 804   AC_MSG_ERROR([--enable-vty-group requires a group as argument, not yes])
 805 elif test "$enable_vty_group" != ""; then
 806   if test "$enable_vty_group" != "no"; then
 807     AC_DEFINE_UNQUOTED([VTY_GROUP], ["${enable_vty_group}"], [VTY Sockets Group])
 808   fi
 809 fi
 810 AC_SUBST([enable_user])
 811 AC_SUBST([enable_group])
 812 AC_SUBST([enable_vty_group])
 813
 814 enable_configfile_mask=${enable_configfile_mask:-0600}
 815 AC_DEFINE_UNQUOTED([CONFIGFILE_MASK], [${enable_configfile_mask}], [Mask for config files])
 816
 817 enable_logfile_mask=${enable_logfile_mask:-0600}
 818 AC_DEFINE_UNQUOTED([LOGFILE_MASK], [${enable_logfile_mask}], [Mask for log files])
 819
 820 MPATH_NUM=16
 821
 822 case "${enable_multipath}" in
 823   0)
 824     MPATH_NUM=64
 825     ;;
 826   [[1-9]|[1-9][0-9]|[1-9][0-9][0-9]])
 827     MPATH_NUM="${enable_multipath}"
 828     ;;
 829   "")
 830     ;;
 831   *)
 832     AC_MSG_FAILURE([Please specify digit to enable multipath ARG])
 833     ;;
 834 esac
 835
 836 AC_DEFINE_UNQUOTED([MULTIPATH_NUM], [$MPATH_NUM], [Maximum number of paths for a route])
 837
 838 AC_DEFINE_UNQUOTED([VTYSH_PAGER], ["$VTYSH_PAGER"], [What pager to use])
 839
 840 dnl --------------------
 841 dnl Enable code coverage
 842 dnl --------------------
 843 AM_CONDITIONAL([HAVE_GCOV], [test "$enable_gcov" != "no"])
 844
 845 dnl ------------------------------------
 846 dnl Alpine only accepts numeric versions
 847 dnl ------------------------------------
 848 if test "$enable_numeric_version" != "" ; then
 849   VERSION="`echo ${VERSION} | tr -c -d '[[.0-9]]'`"
 850   PACKAGE_VERSION="`echo ${PACKAGE_VERSION} | tr -c -d '[[.0-9]]'`"
 851 fi
 852
 853 dnl -----------------------------------
 854 dnl Add extra version string to package
 855 dnl name, string and version fields.
 856 dnl -----------------------------------
 857 if test "$EXTRAVERSION" != "" ; then
 858   VERSION="${VERSION}${EXTRAVERSION}"
 859   PACKAGE_VERSION="${PACKAGE_VERSION}${EXTRAVERSION}"
 860   AC_SUBST(PACKAGE_EXTRAVERSION, ["${EXTRAVERSION}"])
 861   PACKAGE_STRING="${PACKAGE_STRING}${EXTRAVERSION}"
 862 fi
 863 AC_SUBST([EXTRAVERSION])
 864
 865 if test "$with_pkg_git_version" = "yes"; then
 866         if test -e "${srcdir}/.git"; then
 867                 AC_DEFINE([GIT_VERSION], [1], [include git version info])
 868         else    with_pkg_git_version="no"
 869                 AC_MSG_WARN([--with-pkg-git-version given, but this is not a git checkout])
 870         fi
 871 fi
 872 AM_CONDITIONAL([GIT_VERSION], [test "$with_pkg_git_version" = "yes"])
 873
 874 AC_CHECK_TOOL([OBJCOPY], [objcopy], [:])
 875 if test "$OBJCOPY" != ":"; then
 876   AC_CACHE_CHECK([for .interp value to use], [frr_cv_interp], [
 877     frr_cv_interp=""
 878     AC_LINK_IFELSE([AC_LANG_SOURCE([[int main() { return 0; }]])], [
 879       if $OBJCOPY -j.interp -Obinary conftest conftest.interp; then
 880         frr_cv_interp="`xargs -0 echo < conftest.interp`"
 881       fi
 882       test -f conftest.interp && rm conftest.interp
 883     ])
 884   ])
 885 fi
 886 if test -n "$frr_cv_interp"; then
 887   AC_DEFINE_UNQUOTED([INTERP], ["$frr_cv_interp"], [.interp value])
 888 fi
 889
 890 dnl -------------------------
 891 dnl Check other header files.
 892 dnl -------------------------
 893 AC_CHECK_HEADERS([stropts.h sys/ksym.h \
 894         linux/version.h asm/types.h])
 895
 896 ac_stdatomic_ok=false
 897 AC_DEFINE([FRR_AUTOCONF_ATOMIC], [1], [did autoconf checks for atomic funcs])
 898 AC_CHECK_HEADER([stdatomic.h],[
 899
 900   AC_MSG_CHECKING([whether _Atomic qualifier works])
 901   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 902 #include <stdatomic.h>
 903 int main(int argc, char **argv) {
 904   _Atomic int i = 0;
 905   return i;
 906 }
 907 ]])], [
 908     AC_DEFINE([HAVE_STDATOMIC_H], [1], [found stdatomic.h])
 909     AC_MSG_RESULT([yes])
 910     ac_stdatomic_ok=true
 911   ], [
 912     AC_MSG_RESULT([no])
 913   ])
 914 ])
 915
 916 AS_IF([$ac_stdatomic_ok], [true], [
 917   AC_MSG_CHECKING([for __atomic_* builtins])
 918   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 919 int main(int argc, char **argv) {
 920   volatile int i = 1;
 921   __atomic_store_n (&i, 0, __ATOMIC_RELEASE);
 922   return __atomic_load_n (&i, __ATOMIC_ACQUIRE);
 923 }
 924 ]])], [
 925     AC_DEFINE([HAVE___ATOMIC], [1], [found __atomic builtins])
 926     AC_MSG_RESULT([yes])
 927   ], [
 928     AC_MSG_RESULT([no])
 929
 930     dnl FreeBSD 9 has a broken stdatomic.h where _Atomic doesn't work
 931     AC_MSG_CHECKING([for __sync_* builtins])
 932     AC_LINK_IFELSE([AC_LANG_SOURCE([[
 933 int main(int argc, char **argv) {
 934   volatile int i = 1;
 935   __sync_fetch_and_sub (&i, 1);
 936   return __sync_val_compare_and_swap (&i, 0, 1);
 937 }
 938 ]])], [
 939       AC_DEFINE([HAVE___SYNC], [1], [found __sync builtins])
 940       AC_MSG_RESULT([yes])
 941
 942       AC_MSG_CHECKING([for __sync_swap builtin])
 943       AC_LINK_IFELSE([AC_LANG_SOURCE([[
 944 int main(int argc, char **argv) {
 945   volatile int i = 1;
 946   return __sync_swap (&i, 2);
 947 }
 948 ]])], [
 949         AC_DEFINE([HAVE___SYNC_SWAP], 1, [found __sync_swap builtin])
 950         AC_MSG_RESULT([yes])
 951       ], [
 952         AC_MSG_RESULT([no])
 953       ])
 954
 955     ], [
 956       AC_MSG_RESULT([no])
 957       AC_MSG_FAILURE([stdatomic.h unavailable and $CC has neither __atomic nor __sync builtins])
 958     ])
 959   ])
 960 ])
 961
 962 AC_CHECK_HEADERS([pthread_np.h],,, [
 963 #include <pthread.h>
 964 ])
 965 AC_CHECK_FUNCS([pthread_setname_np pthread_set_name_np pthread_getthreadid_np])
 966
 967 needsync=true
 968
 969 AS_IF([$needsync], [
 970   dnl Linux
 971   AC_MSG_CHECKING([for Linux futex() support])
 972   AC_LINK_IFELSE([AC_LANG_PROGRAM([
 973 #ifndef _GNU_SOURCE
 974 #define _GNU_SOURCE
 975 #endif
 976 #include <unistd.h>
 977 #include <limits.h>
 978 #include <sys/time.h>
 979 #include <sys/syscall.h>
 980 #include <linux/futex.h>
 981
 982 int main(void);
 983 ],
 984 [
 985 {
 986   return syscall(SYS_futex, NULL, FUTEX_WAIT, 0, NULL, NULL, 0);
 987 }
 988 ])], [
 989     AC_MSG_RESULT([yes])
 990     AC_DEFINE(HAVE_SYNC_LINUX_FUTEX,,Have Linux futex support)
 991     needsync=false
 992   ], [
 993     AC_MSG_RESULT([no])
 994   ])
 995 ])
 996
 997 AS_IF([$needsync], [
 998   dnl FreeBSD
 999   AC_MSG_CHECKING([for FreeBSD _umtx_op() support])
1000   AC_LINK_IFELSE([AC_LANG_PROGRAM([
1001 #include <errno.h>
1002 #include <stdlib.h>
1003 #include <sys/types.h>
1004 #include <sys/umtx.h>
1005 int main(void);
1006 ],
1007 [
1008 {
1009   return _umtx_op(NULL, UMTX_OP_WAIT_UINT, 0, NULL, NULL);
1010 }
1011 ])], [
1012     AC_MSG_RESULT([yes])
1013     AC_DEFINE(HAVE_SYNC_UMTX_OP,,Have FreeBSD _umtx_op() support)
1014     needsync=false
1015   ], [
1016     AC_MSG_RESULT([no])
1017   ])
1018 ])
1019
1020 AS_IF([$needsync], [
1021   dnl OpenBSD patch (not upstream at the time of writing this)
1022   dnl https://marc.info/?l=openbsd-tech&m=147299508409549&w=2
1023   AC_MSG_CHECKING([for OpenBSD futex() support])
1024   AC_LINK_IFELSE([AC_LANG_PROGRAM([
1025 #include <sys/futex.h>
1026 int main(void);
1027 ],
1028 [
1029 {
1030   return futex(NULL, FUTEX_WAIT, 0, NULL, NULL, 0);
1031 }
1032 ])], [
1033     AC_MSG_RESULT([yes])
1034     AC_DEFINE(HAVE_SYNC_OPENBSD_FUTEX,,Have OpenBSD futex support)
1035     needsync=false
1036   ], [
1037     AC_MSG_RESULT([no])
1038   ])
1039 ])
1040
1041 dnl Utility macro to avoid retyping includes all the time
1042 m4_define([FRR_INCLUDES],
1043 [#ifdef SUNOS_5
1044 #define _POSIX_C_SOURCE 200809L
1045 #define __EXTENSIONS__
1046 #endif
1047 #include <stdio.h>
1048 #include <stdlib.h>
1049 #include <stddef.h>
1050 #include <sys/types.h>
1051 /* sys/conf.h depends on param.h on FBSD at least */
1052 #include <sys/param.h>
1053 /* Required for MAXSIG */
1054 #include <signal.h>
1055 #include <sys/socket.h>
1056 #ifdef __APPLE__
1057 # define __APPLE_USE_RFC_3542
1058 #endif
1059 #include <netinet/in.h>
1060 #include <sys/time.h>
1061 #include <time.h>
1062 #include <net/if.h>
1063 ])dnl
1064
1065 dnl Same applies for HAVE_NET_IF_VAR_H, which HAVE_NETINET6_ND6_H and
1066 dnl HAVE_NETINET_IN_VAR_H depend upon. But if_var.h depends on if.h, hence
1067 dnl an additional round for it.
1068
1069 AC_CHECK_HEADERS([net/if_var.h], [], [], [FRR_INCLUDES])
1070
1071 m4_define([FRR_INCLUDES],
1072 FRR_INCLUDES
1073 [#ifdef HAVE_NET_IF_VAR_H
1074 # include <net/if_var.h>
1075 #endif
1076 ])dnl
1077
1078 AC_CHECK_HEADERS([netinet/in_var.h \
1079         net/if_dl.h net/netopt.h \
1080         inet/nd.h netinet/ip_icmp.h \
1081         sys/sysctl.h sys/sockio.h sys/conf.h],
1082         [], [], [FRR_INCLUDES])
1083
1084 AC_CHECK_HEADERS([ucontext.h], [], [],
1085 [#ifndef __USE_GNU
1086 #define __USE_GNU
1087 #endif /* __USE_GNU */
1088 FRR_INCLUDES
1089 ])
1090
1091 m4_define([UCONTEXT_INCLUDES],
1092 [#include <ucontext.h>])dnl
1093
1094 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.uc_regs],
1095   [], [], [UCONTEXT_INCLUDES])
1096 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs],
1097   [AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs.nip],
1098    [], [], [UCONTEXT_INCLUDES])],
1099   [], [UCONTEXT_INCLUDES])
1100 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.gregs],
1101   [], [], [UCONTEXT_INCLUDES])
1102
1103 m4_define([FRR_INCLUDES],
1104 FRR_INCLUDES
1105 [
1106 #include <sys/un.h>
1107 #include <netinet/in_systm.h>
1108 #ifdef HAVE_NETINET_IN_VAR_H
1109 # include <netinet/in_var.h>
1110 #endif
1111 #ifdef HAVE_NET_IF_DL_H
1112 # include <net/if_dl.h>
1113 #endif
1114 #ifdef HAVE_NET_NETOPT_H
1115 # include <net/netopt.h>
1116 #endif
1117 #include <net/route.h>
1118 #ifdef HAVE_INET_ND_H
1119 # include <inet/nd.h>
1120 #endif
1121 #include <arpa/inet.h>
1122 /* Required for IDRP */
1123 #ifdef HAVE_NETINET_IP_ICMP_H
1124 # include <netinet/ip_icmp.h>
1125 #endif
1126 ])dnl
1127
1128 dnl V6 headers are checked below, after we check for v6
1129
1130 is_linux=false
1131
1132 AC_MSG_CHECKING([which operating system interface to use])
1133 case "$host_os" in
1134   sunos* | solaris2*)
1135     AC_MSG_RESULT([Solaris])
1136
1137     AC_DEFINE([SUNOS_5], [1], [SunOS 5])
1138     AC_DEFINE([SOLARIS_IPV6], [1], Solaris IPv6)
1139     AC_DEFINE([_POSIX_C_SOURCE], [200809L], [enable POSIX.1-2008 and XPG7/SUSv4])
1140
1141     AC_CHECK_LIB([socket], [main])
1142     AC_CHECK_LIB([nsl], [main])
1143     AC_CHECK_LIB([umem], [main])
1144     SOLARIS="solaris"
1145     AC_MSG_WARN([--Solaris support is being considered for deprecation, please let us know if you are still using this--])
1146     ;;
1147   linux*)
1148     AC_MSG_RESULT([Linux])
1149
1150     AC_DEFINE([GNU_LINUX], [1], [GNU Linux])
1151     AC_DEFINE([HAVE_NETLINK], [1], [netlink])
1152     AC_DEFINE([LINUX_IPV6], [1], [Linux IPv6 stack])
1153
1154     dnl Linux has a compilation problem with mixing
1155     dnl netinet/in.h and linux/in6.h they are not
1156     dnl compatible.  There has been discussion on
1157     dnl how to fix it but no real progress on implementation
1158     dnl when they fix it, remove this
1159     AC_DEFINE([IPV6_MINHOPCOUNT], [73], [Linux ipv6 Min Hop Count])
1160
1161     is_linux=true
1162     ;;
1163   openbsd*)
1164     AC_MSG_RESULT([OpenBSD])
1165
1166     AC_DEFINE([OPEN_BSD], [1], [OpenBSD])
1167     AC_DEFINE([KAME], [1], [KAME IPv6])
1168     AC_DEFINE([BSD_V6_SYSCTL], [1], [BSD v6 sysctl to turn on and off forwarding])
1169     ;;
1170   *)
1171     AC_MSG_RESULT([BSD])
1172
1173     AC_DEFINE([HAVE_NET_RT_IFLIST], [1], [NET_RT_IFLIST])
1174     AC_DEFINE([KAME], [1], [KAME IPv6])
1175     AC_DEFINE([BSD_V6_SYSCTL], [1], [BSD v6 sysctl to turn on and off forwarding])
1176     ;;
1177 esac
1178 AM_CONDITIONAL([SOLARIS], [test "$SOLARIS" = "solaris"])
1179 AM_CONDITIONAL([LINUX], [${is_linux}])
1180
1181 AC_SYS_LARGEFILE
1182
1183 dnl ------------------------
1184 dnl Integrated REALMS option
1185 dnl ------------------------
1186 if test "$enable_realms" = "yes"; then
1187     case "$host_os" in
1188       linux*)
1189        AC_DEFINE([SUPPORT_REALMS], [1], [Realms support])
1190        ;;
1191       *)
1192        echo "Sorry, only Linux has REALMS support"
1193        exit 1
1194        ;;
1195     esac
1196 fi
1197
1198 dnl -------------------------------
1199 dnl Endian-ness check
1200 dnl -------------------------------
1201 AC_WORDS_BIGENDIAN
1202
1203 dnl ---------------
1204 dnl other functions
1205 dnl ---------------
1206 AC_CHECK_FUNCS([ \
1207         strlcat strlcpy \
1208         getgrouplist \
1209         openat \
1210         unlinkat \
1211         posix_fallocate \
1212         ])
1213
1214 dnl ##########################################################################
1215 dnl LARGE if block spans a lot of "configure"!
1216 if test "$enable_clippy_only" != "yes"; then
1217 dnl ##########################################################################
1218
1219 #
1220 # Logic for protobuf support.
1221 #
1222 PROTO3=false
1223 if test "$enable_protobuf" = "yes"; then
1224   # Check for protoc & protoc-c
1225
1226   # protoc is not required, it's only for a "be nice" helper target
1227   AC_CHECK_PROGS([PROTOC], [protoc], [/bin/false])
1228
1229   AC_CHECK_PROGS([PROTOC_C], [protoc-c], [/bin/false])
1230   if test "$PROTOC_C" = "/bin/false"; then
1231     AC_MSG_FAILURE([protobuf requested but protoc-c not found.  Install protobuf-c.])
1232   fi
1233
1234   PKG_CHECK_MODULES([PROTOBUF_C], [libprotobuf-c >= 0.14],, [
1235     AC_MSG_FAILURE([protobuf requested but libprotobuf-c not found.  Install protobuf-c.])
1236   ])
1237
1238   PROTO3=true
1239   AC_CHECK_HEADER([google/protobuf-c/protobuf-c.h],
1240                   [AC_CHECK_DECLS(PROTOBUF_C_LABEL_NONE,
1241                                   AC_DEFINE([HAVE_PROTOBUF_VERSION_3],
1242                                             [1], [Have Protobuf version 3]),
1243                                   [PROTO3=false],
1244                                   [#include <google/protobuf-c/protobuf-c.h>])],
1245                   [PROTO3=false && AC_MSG_FAILURE([protobuf requested but protobuf-c.h not found.  Install protobuf-c.])])
1246
1247   AC_DEFINE([HAVE_PROTOBUF], [1], [protobuf])
1248 fi
1249
1250
1251 dnl ---------------------
1252 dnl Integrated VTY option
1253 dnl ---------------------
1254 case "${enable_vtysh}" in
1255 "no")
1256   VTYSH="";;
1257 *)
1258   VTYSH="vtysh";
1259   AC_DEFINE([VTYSH], [1], [VTY shell])
1260
1261   prev_libs="$LIBS"
1262   AC_CHECK_LIB([readline], [main], [
1263     LIBREADLINE="-lreadline"
1264   ], [
1265     dnl readline failed - it might be incorrectly linked and missing its
1266     dnl termcap/tinfo/curses dependency.  see if we can fix that...
1267     AC_SEARCH_LIBS([tputs], [termcap tinfo curses ncurses], [
1268       LIBREADLINE="$ac_cv_search_tputs"
1269     ], [
1270       AC_MSG_ERROR([libreadline (needed for vtysh) not found and/or missing dependencies])
1271     ])
1272
1273     dnl re-try with the lib we found above
1274     unset ac_cv_lib_readline_main
1275     AC_CHECK_LIB([readline], [main], [
1276       LIBREADLINE="-lreadline $LIBREADLINE"
1277     ], [
1278       AC_MSG_ERROR([libreadline (needed for vtysh) not found and/or missing dependencies])
1279     ], [$LIBREADLINE])
1280   ], [])
1281   LIBS="$prev_libs"
1282
1283   AC_CHECK_HEADER([readline/history.h])
1284   if test "$ac_cv_header_readline_history_h" = "no"; then
1285     AC_MSG_ERROR([readline is too old to have readline/history.h, please update to the latest readline library.])
1286   fi
1287   AC_CHECK_LIB([readline], [rl_completion_matches], [true], [], [$LIBREADLINE])
1288   if test "$ac_cv_lib_readline_rl_completion_matches" = "no"; then
1289     AC_DEFINE([rl_completion_matches], [completion_matches], [Old readline])
1290   fi
1291   AC_CHECK_LIB([readline], [append_history], [frr_cv_append_history=yes], [frr_cv_append_history=no], [$LIBREADLINE])
1292   if test "$frr_cv_append_history" = "yes"; then
1293     AC_DEFINE([HAVE_APPEND_HISTORY], [1], [Have history.h append_history])
1294   fi
1295   ;;
1296 esac
1297 AC_SUBST([LIBREADLINE])
1298
1299 dnl ----------
1300 dnl PAM module
1301 dnl
1302 dnl FRR detects the PAM library it is built against by checking for a
1303 dnl functional pam_misc.h (Linux-PAM) or openpam.h (OpenPAM) header. pam_misc.h
1304 dnl is known to #include pam_appl.h, the standard header of a PAM library, and
1305 dnl openpam.h doesn't do that, although depends on the header too. Hence a
1306 dnl little assistance to AC_CHECK_HEADER is necessary for the proper detection
1307 dnl of OpenPAM.
1308 dnl ----------
1309 if test "$with_libpam" = "yes"; then
1310   AC_CHECK_HEADER([security/pam_misc.h],
1311     [AC_DEFINE([HAVE_PAM_MISC_H], [1], [Have pam_misc.h])
1312      AC_DEFINE([PAM_CONV_FUNC], [misc_conv], [Have misc_conv])
1313      pam_conv_func="misc_conv"
1314     ],
1315     [], FRR_INCLUDES)
1316   AC_CHECK_HEADER([security/openpam.h],
1317     [AC_DEFINE([HAVE_OPENPAM_H], [1], [Have openpam.h])
1318      AC_DEFINE([PAM_CONV_FUNC], [openpam_ttyconv], [Have openpam_ttyconv])
1319      pam_conv_func="openpam_ttyconv"
1320     ],
1321     [], FRR_INCLUDES[#include <security/pam_appl.h>])
1322   if test -z "$ac_cv_header_security_pam_misc_h$ac_cv_header_security_openpam_h" ; then
1323     AC_MSG_WARN([*** pam support will not be built ***])
1324     with_libpam="no"
1325   fi
1326 fi
1327
1328 if test "$with_libpam" = "yes"; then
1329 dnl took this test from proftpds configure.in and suited to our needs
1330 dnl -------------------------------------------------------------------------
1331 dnl
1332 dnl This next check looks funky due to a linker problem with some versions
1333 dnl of the PAM library.  Prior to 0.72 release, the Linux PAM shared library
1334 dnl omitted requiring libdl linking information. PAM-0.72 or better ships
1335 dnl with RedHat 6.2 and Debian 2.2 or better.
1336 AC_CHECK_LIB([pam], [pam_start],
1337   [AC_CHECK_LIB([pam], [$pam_conv_func],
1338     [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1339      LIBPAM="-lpam"],
1340     [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1341      LIBPAM="-lpam -lpam_misc"]
1342     )
1343   ],
1344
1345   [AC_CHECK_LIB([pam], [pam_end],
1346     [AC_CHECK_LIB([pam], [$pam_conv_func],
1347       [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1348        LIBPAM="-lpam -ldl"],
1349       [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1350        LIBPAM="-lpam -ldl -lpam_misc"]
1351      )
1352   ],AC_MSG_WARN([*** pam support will not be built ***]),
1353   [-ldl])
1354   ]
1355 )
1356 fi
1357 AC_SUBST([LIBPAM])
1358
1359 dnl -------------------------------
1360 dnl bgpd needs pow() and hence libm
1361 dnl -------------------------------
1362 TMPLIBS="$LIBS"
1363 LIBS=""
1364 AC_SEARCH_LIBS([pow], [m], [
1365   LIBM="$LIBS"
1366 ], [
1367   AC_MSG_WARN([Unable to find working pow function - bgpd may not link])
1368 ])
1369 LIBS="$TMPLIBS"
1370 AC_SUBST([LIBM])
1371
1372 AC_CHECK_FUNCS([ppoll], [
1373   AC_DEFINE([HAVE_PPOLL], [1], [have Linux/BSD ppoll()])
1374 ])
1375 AC_CHECK_FUNCS([pollts], [
1376   AC_DEFINE([HAVE_POLLTS], [1], [have NetBSD pollts()])
1377 ])
1378
1379 AC_CHECK_HEADER([asm-generic/unistd.h],
1380                 [AC_CHECK_DECL(__NR_setns,
1381                                AC_DEFINE([HAVE_NETNS], [1], [Have netns]),,
1382                                FRR_INCLUDES [#include <asm-generic/unistd.h>
1383                                ])
1384                  AC_CHECK_FUNCS([setns])]
1385                )
1386
1387 dnl --------------------------
1388 dnl Determine IS-IS I/O method
1389 dnl --------------------------
1390 AC_DEFINE([ISIS_METHOD_PFPACKET], [1], [constant value for isis method pfpacket])
1391 AC_DEFINE([ISIS_METHOD_DLPI], [2], [constant value for isis method dlpi])
1392 AC_DEFINE([ISIS_METHOD_BPF], [3], [constant value for isis method bpf])
1393 AC_CHECK_HEADER([net/bpf.h])
1394 AC_CHECK_HEADER([sys/dlpi.h])
1395 AC_MSG_CHECKING([zebra IS-IS I/O method])
1396
1397 case "$host_os" in
1398   linux*)
1399     AC_MSG_RESULT([pfpacket])
1400     ISIS_METHOD_MACRO="ISIS_METHOD_PFPACKET"
1401     ;;
1402   solaris* | sunos*)
1403     AC_MSG_RESULT([DLPI])
1404     ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1405     ;;
1406   *)
1407     if test "$ac_cv_header_net_bpf_h" = "no"; then
1408       if test "$ac_cv_header_sys_dlpi_h" = "no"; then
1409         AC_MSG_RESULT([none])
1410         if test "$enable_isisd" = "yes" -o "$enable_fabricd" = "yes"; then
1411           AC_MSG_FAILURE([IS-IS support requested but no packet backend found])
1412         fi
1413         AC_MSG_WARN([*** IS-IS support will not be built ***])
1414         enable_isisd="no"
1415         enable_fabricd="no"
1416       else
1417         AC_MSG_RESULT([DLPI])
1418       fi
1419       ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1420     else
1421       AC_MSG_RESULT([BPF])
1422       ISIS_METHOD_MACRO="ISIS_METHOD_BPF"
1423     fi
1424     ;;
1425 esac
1426 AC_DEFINE_UNQUOTED([ISIS_METHOD], [$ISIS_METHOD_MACRO], [selected method for isis, == one of the constants])
1427
1428 dnl ---------------------------------------------------------------
1429 dnl figure out how to specify an interface in multicast sockets API
1430 dnl ---------------------------------------------------------------
1431 AC_CHECK_MEMBERS([struct ip_mreqn.imr_ifindex], [], [], FRR_INCLUDES)
1432
1433 AC_CHECK_HEADERS([linux/mroute.h], [], [],[
1434         #include <sys/socket.h>
1435         #include <netinet/in.h>
1436         #define _LINUX_IN_H             /* For Linux <= 2.6.25 */
1437         #include <linux/types.h>
1438 ])
1439
1440 m4_define([FRR_INCLUDES],
1441 FRR_INCLUDES
1442 [#ifdef HAVE_LINUX_MROUTE_H
1443 # include <linux/mroute.h>
1444 #endif
1445 ])dnl
1446
1447 AC_CHECK_HEADERS([netinet/ip_mroute.h], [], [],[
1448         #include <sys/socket.h>
1449         #include <sys/types.h>
1450         #include <netinet/in.h>
1451         #include <net/route.h>
1452 ])
1453
1454 m4_define([FRR_INCLUDES],
1455 FRR_INCLUDES
1456 [#ifdef HAVE_NETINET_IP_MROUTE_H
1457 # include <netinet/ip_mroute.h>
1458 #endif
1459 ])dnl
1460
1461 AC_MSG_CHECKING([for BSD struct ip_mreq hack])
1462 AC_TRY_COMPILE([#include <sys/param.h>],
1463 [#if (defined(__FreeBSD__) && ((__FreeBSD_version >= 500022 && __FreeBSD_version < 700000) || (__FreeBSD_version < 500000 && __FreeBSD_version >= 440000))) || (defined(__NetBSD__) && defined(__NetBSD_Version__) && __NetBSD_Version__ >= 106010000) || defined(__OpenBSD__) || defined(__APPLE__) || defined(__DragonFly__) || defined(__sun)
1464   return (0);
1465 #else
1466   #error No support for BSD struct ip_mreq hack detected
1467 #endif],[AC_MSG_RESULT([yes])
1468 AC_DEFINE([HAVE_BSD_STRUCT_IP_MREQ_HACK], [1], [Can pass ifindex in struct ip_mreq])],
1469 AC_MSG_RESULT([no]))
1470
1471 AC_MSG_CHECKING([for RFC3678 protocol-independed API])
1472 AC_TRY_COMPILE([
1473 #include <sys/types.h>
1474 #include <netinet/in.h>
1475 ], [struct group_req gr; int sock; setsockopt(sock, IPPROTO_IP, MCAST_JOIN_GROUP, (void*)&gr, sizeof(gr));
1476 ], [AC_MSG_RESULT([yes])
1477 AC_DEFINE([HAVE_RFC3678], [1], [Have RFC3678 protocol-independed API])],
1478 AC_MSG_RESULT([no]))
1479
1480 dnl ---------------------------------------------------------------
1481 dnl figure out how to check link-state
1482 dnl ---------------------------------------------------------------
1483 AC_CHECK_HEADER([net/if_media.h],
1484   [m4_define([LINK_DETECT_INCLUDES],
1485     FRR_INCLUDES
1486     [#include <net/if_media.h>
1487   ])
1488   AC_CHECK_MEMBERS([struct ifmediareq.ifm_status],
1489     AC_DEFINE([HAVE_BSD_LINK_DETECT], [1], [BSD link-detect]),
1490     [], LINK_DETECT_INCLUDES)],
1491   [],
1492   FRR_INCLUDES)
1493
1494 dnl ---------------------------------------------------------------
1495 dnl Additional, newer way to check link-state using ifi_link_state.
1496 dnl Not available in all BSD's when ifmediareq available
1497 dnl ---------------------------------------------------------------
1498 AC_CHECK_MEMBERS([struct if_data.ifi_link_state],
1499   AC_DEFINE([HAVE_BSD_IFI_LINK_STATE], [1], [BSD ifi_link_state available]),
1500   [], FRR_INCLUDES)
1501
1502 dnl ------------------------
1503 dnl TCP_MD5SIG socket option
1504 dnl ------------------------
1505
1506 AC_CHECK_HEADER([netinet/tcp.h],
1507    [m4_define([MD5_INCLUDES],
1508       FRR_INCLUDES
1509       [#include <netinet/tcp.h>
1510     ])
1511     AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)],
1512    [],
1513    FRR_INCLUDES)
1514 if test "$ac_cv_have_decl_TCP_MD5SIG" = "no"; then
1515   AC_CHECK_HEADER([linux/tcp.h],
1516        [m4_define([MD5_INCLUDES],
1517           FRR_INCLUDES
1518           [#include <linux/tcp.h>
1519         ])
1520        AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)])
1521 fi
1522
1523 AC_SUBST([SOLARIS])
1524 AC_CHECK_LIB([crypt], [crypt], [],
1525                     [AC_CHECK_LIB([crypto], [DES_crypt])])
1526 AC_CHECK_LIB([resolv], [res_init])
1527
1528 dnl ---------------------------
1529 dnl check system has PCRE regexp
1530 dnl ---------------------------
1531 if test "$enable_pcreposix" = "yes"; then
1532   AC_CHECK_LIB([pcreposix], [regexec], [], [
1533     AC_MSG_ERROR([--enable-pcreposix given but unable to find libpcreposix])
1534   ])
1535 fi
1536 AC_SUBST([HAVE_LIBPCREPOSIX])
1537
1538 dnl ##########################################################################
1539 dnl test "$enable_clippy_only" != "yes"
1540 fi
1541 dnl END OF LARGE if block
1542 dnl ##########################################################################
1543
1544 dnl ------------------
1545 dnl check C-Ares library
1546 dnl ------------------
1547 PKG_CHECK_MODULES([CARES], [libcares], [
1548   c_ares_found=true
1549 ],[
1550   c_ares_found=false
1551 ])
1552 AM_CONDITIONAL([CARES], [$c_ares_found])
1553
1554
1555 dnl ----------------------------------------------------------------------------
1556 dnl figure out if domainname is available in the utsname struct (GNU extension).
1557 dnl ----------------------------------------------------------------------------
1558 AC_CHECK_MEMBERS([struct utsname.domainname], [], [], [#include <sys/utsname.h>])
1559
1560 dnl ------------------
1561 dnl IPv6 header checks
1562 dnl ------------------
1563 AC_CHECK_HEADERS([netinet6/in6.h netinet/in6_var.h \
1564         netinet6/in6_var.h netinet6/nd6.h], [], [],
1565         FRR_INCLUDES)
1566
1567 m4_define([FRR_INCLUDES],dnl
1568 FRR_INCLUDES
1569 [#ifdef HAVE_NETINET6_IN6_H
1570 #include <netinet6/in6.h>
1571 #endif
1572 #ifdef HAVE_NETINET_IN6_VAR_H
1573 #include <netinet/in6_var.h>
1574 #endif
1575 #include <netinet/icmp6.h>
1576 #ifdef HAVE_NETINET6_IN6_VAR_H
1577 # include <netinet6/in6_var.h>
1578 #endif
1579 #ifdef HAVE_NETINET6_ND6_H
1580 # include <netinet6/nd6.h>
1581 #endif
1582 ])dnl
1583
1584 dnl --------------------
1585 dnl Daemon disable check
1586 dnl --------------------
1587
1588 AS_IF([test "$enable_ldpd" != "no"], [
1589   AC_DEFINE([HAVE_LDPD], [1], [ldpd])
1590 ])
1591
1592 if test "$enable_bfdd" = "no"; then
1593   AC_DEFINE([HAVE_BFDD], [0], [bfdd])
1594   BFDD=""
1595 else
1596   AC_DEFINE([HAVE_BFDD], [1], [bfdd])
1597   BFDD="bfdd"
1598
1599   case $host_os in
1600     linux*)
1601       AC_DEFINE([BFD_LINUX], [1], [bfdd])
1602       ;;
1603
1604     *)
1605       AC_DEFINE([BFD_BSD], [1], [bfdd])
1606       ;;
1607   esac
1608 fi
1609
1610 if test "$ac_cv_lib_json_c_json_object_get" = "no" -a "$BFDD" = "bfdd"; then
1611   AC_MSG_ERROR(["you must use json-c library to use bfdd"])
1612 fi
1613
1614 NHRPD=""
1615 case "$host_os" in
1616   linux*)
1617     case "${enable_nhrpd}" in
1618       no)
1619         ;;
1620       yes)
1621         if test "$enable_clippy_only" != "yes"; then
1622         if test "$c_ares_found" != "true" ; then
1623           AC_MSG_ERROR([nhrpd requires libcares.  Please install c-ares and its -dev headers.])
1624         fi
1625         fi
1626         NHRPD="nhrpd"
1627         ;;
1628       *)
1629         if test "$c_ares_found" = "true" ; then
1630           NHRPD="nhrpd"
1631         fi
1632         ;;
1633     esac
1634     ;;
1635   *)
1636     if test "$enable_nhrpd" = "yes"; then
1637       AC_MSG_ERROR([nhrpd requires kernel APIs that are only present on Linux.])
1638     fi
1639     ;;
1640 esac
1641
1642 if test "$enable_watchfrr" = "no";then
1643   WATCHFRR=""
1644 else
1645   WATCHFRR="watchfrr"
1646 fi
1647
1648 OSPFCLIENT=""
1649 if test "$enable_ospfapi" != "no";then
1650     AC_DEFINE([SUPPORT_OSPF_API], [1], [OSPFAPI])
1651
1652   if test "$enable_ospfclient" != "no";then
1653       OSPFCLIENT="ospfclient"
1654   fi
1655 fi
1656
1657 if test "$enable_bgp_announce" = "no";then
1658   AC_DEFINE([DISABLE_BGP_ANNOUNCE], [1], [Disable BGP installation to zebra])
1659 else
1660   AC_DEFINE([DISABLE_BGP_ANNOUNCE], [0], [Disable BGP installation to zebra])
1661 fi
1662
1663 if test "$enable_bgp_vnc" != "no";then
1664   AC_DEFINE([ENABLE_BGP_VNC], [1], [Enable BGP VNC support])
1665 fi
1666
1667 bgpd_bmp=false
1668 case "${enable_bmp}" in
1669   no)
1670     ;;
1671   yes)
1672     if test "$c_ares_found" != "true" ; then
1673       AC_MSG_ERROR([BMP support requires libcares.  Please install c-ares and its -dev headers.])
1674     fi
1675     bgpd_bmp=true
1676     ;;
1677   *)
1678     if test "$c_ares_found" = "true" ; then
1679       bgpd_bmp=true
1680     fi
1681     ;;
1682 esac
1683
1684 dnl ##########################################################################
1685 dnl LARGE if block
1686 if test "$enable_clippy_only" != "yes"; then
1687 dnl ##########################################################################
1688
1689 dnl ------------------
1690 dnl check Net-SNMP library
1691 dnl ------------------
1692 if test "$enable_snmp" != "" -a "$enable_snmp" != "no"; then
1693    AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], [no])
1694    if test "$NETSNMP_CONFIG" = "no"; then
1695       AC_MSG_ERROR([--enable-snmp given but unable to find net-snmp-config])
1696    fi
1697    SNMP_LIBS="`${NETSNMP_CONFIG} --agent-libs`"
1698    SNMP_CFLAGS="`${NETSNMP_CONFIG} --base-cflags`"
1699    # net-snmp lists all of its own dependencies.  we absolutely do not want that
1700    # among other things we avoid a GPL vs. OpenSSL license conflict here
1701    for removelib in crypto ssl sensors pci wrap; do
1702      SNMP_LIBS="`echo $SNMP_LIBS | sed -e 's/\(^\|\s\)-l'$removelib'\b/ /g' -e 's/\(^\|\s\)\([^\s]*\/\)\?lib'$removelib'\.[^\s]\+\b/ /g'`"
1703    done
1704    AC_MSG_CHECKING([whether we can link to Net-SNMP])
1705    AC_LINK_IFELSE_FLAGS([$SNMP_CFLAGS], [$SNMP_LIBS], [AC_LANG_PROGRAM([
1706 int main(void);
1707 ],
1708 [
1709 {
1710   return 0;
1711 }
1712 ])], [
1713      AC_MSG_RESULT([no])
1714      AC_MSG_ERROR([--enable-snmp given but not usable])])
1715    case "${enable_snmp}" in
1716      yes)
1717       SNMP_METHOD=agentx
1718       ;;
1719      agentx)
1720       SNMP_METHOD="${enable_snmp}"
1721       ;;
1722      *)
1723       AC_MSG_ERROR([--enable-snmp given with an unknown method (${enable_snmp}). Use yes or agentx])
1724       ;;
1725    esac
1726    AH_TEMPLATE([SNMP_AGENTX], [Use SNMP AgentX to interface with snmpd])
1727    AC_DEFINE_UNQUOTED(AS_TR_CPP(SNMP_${SNMP_METHOD}),,[SNMP method to interface with snmpd])
1728 fi
1729 AC_SUBST([SNMP_LIBS])
1730 AC_SUBST([SNMP_CFLAGS])
1731
1732 dnl ---------------
1733 dnl libyang
1734 dnl ---------------
1735 PKG_CHECK_MODULES([LIBYANG], [libyang >= 0.16.105], , [
1736   AC_MSG_ERROR([libyang (>= 0.16.105) was not found on your system.])
1737 ])
1738 ac_cflags_save="$CFLAGS"
1739 CFLAGS="$CFLAGS $LIBYANG_CFLAGS"
1740 AC_CHECK_MEMBER([struct lyd_node.priv], [], [
1741   AC_MSG_ERROR([m4_normalize([
1742     libyang needs to be compiled with ENABLE_LYD_PRIV=ON.
1743     Instructions for this are included in the build documentation for your platform at http://docs.frrouting.org/projects/dev-guide/en/latest/building.html])
1744   ])
1745 ], [[#include <libyang/libyang.h>]])
1746 CFLAGS="$ac_cflags_save"
1747
1748 dnl ---------------
1749 dnl configuration rollbacks
1750 dnl ---------------
1751 SQLITE3=false
1752 if test "$enable_config_rollbacks" = "yes"; then
1753   PKG_CHECK_MODULES([SQLITE3], [sqlite3], [
1754     AC_DEFINE([HAVE_CONFIG_ROLLBACKS], [1], [Enable configuration rollbacks])
1755     AC_DEFINE([HAVE_SQLITE3], [1], [Enable sqlite3 database])
1756     SQLITE3=true
1757   ], [
1758     AC_MSG_ERROR([--enable-config-rollbacks given but sqlite3 was not found on your system.])
1759   ])
1760 fi
1761
1762 dnl ---------------
1763 dnl confd
1764 dnl ---------------
1765 if test "$enable_confd" != "" -a "$enable_confd" != "no"; then
1766    AC_CHECK_PROG([CONFD], [confd], [confd], [/bin/false], "${enable_confd}/bin")
1767    if test "$CONFD" = "/bin/false"; then
1768       AC_MSG_ERROR([confd was not found on your system.])]
1769    fi
1770    CONFD_CFLAGS="-I${enable_confd}/include -L${enable_confd}/lib"
1771    AC_SUBST([CONFD_CFLAGS])
1772    CONFD_LIBS="-lconfd"
1773    AC_SUBST([CONFD_LIBS])
1774    AC_DEFINE([HAVE_CONFD], [1], [Enable confd integration])
1775 fi
1776
1777 dnl ---------------
1778 dnl sysrepo
1779 dnl ---------------
1780 if test "$enable_sysrepo" = "yes"; then
1781   PKG_CHECK_MODULES([SYSREPO], [libsysrepo],
1782       [AC_DEFINE([HAVE_SYSREPO], [1], [Enable sysrepo integration])
1783       SYSREPO=true],
1784       [SYSREPO=false
1785       AC_MSG_ERROR([sysrepo was not found on your system.])]
1786   )
1787 fi
1788
1789 dnl ---------------
1790 dnl gRPC
1791 dnl ---------------
1792 if test "$enable_grpc" = "yes"; then
1793   PKG_CHECK_MODULES([GRPC], [grpc grpc++ protobuf], [
1794     AC_CHECK_PROGS([PROTOC], [protoc], [/bin/false])
1795     if test "$PROTOC" = "/bin/false"; then
1796       AC_MSG_FAILURE([grpc requested but protoc not found.])
1797     fi
1798
1799     AC_DEFINE([HAVE_GRPC], [1], [Enable the gRPC northbound plugin])
1800     GRPC=true
1801   ], [
1802     GRPC=false
1803     AC_MSG_ERROR([grpc/grpc++ were not found on your system.])
1804   ])
1805 fi
1806
1807 dnl ------
1808 dnl ZeroMQ
1809 dnl ------
1810 if test "$enable_zeromq" != "no"; then
1811   PKG_CHECK_MODULES([ZEROMQ], [libzmq >= 4.0.0], [
1812     AC_DEFINE([HAVE_ZEROMQ], [1], [Enable ZeroMQ support])
1813     ZEROMQ=true
1814   ], [
1815     if test "$enable_zeromq" = "yes"; then
1816       AC_MSG_ERROR([configuration specifies --enable-zeromq but libzmq was not found])
1817     fi
1818   ])
1819 fi
1820
1821 dnl ------------------------------------
1822 dnl Enable RPKI and add librtr to libs
1823 dnl ------------------------------------
1824 if test "$enable_rpki" = "yes"; then
1825   PKG_CHECK_MODULES([RTRLIB], [rtrlib >= 0.5.0],
1826       [RPKI=true],
1827       [RPKI=false
1828       AC_MSG_ERROR([rtrlib was not found on your system or is too old.])]
1829   )
1830 fi
1831
1832 dnl ------------------------------------
1833 dnl pimd is not supported on OpenBSD and MacOS
1834 dnl ------------------------------------
1835 if test "$enable_pimd" != "no"; then
1836 AC_MSG_CHECKING([for pimd OS support])
1837 case "$host_os" in
1838   darwin*)
1839     AC_MSG_RESULT([no])
1840     enable_pimd="no"
1841     ;;
1842   openbsd*)
1843     AC_MSG_RESULT([no])
1844     enable_pimd="no"
1845     ;;
1846   *)
1847     AC_MSG_RESULT([yes])
1848     ;;
1849 esac
1850 fi
1851
1852 dnl -------------------------------------
1853 dnl VRRP is only supported on linux
1854 dnl -------------------------------------
1855 if test "$enable_vrrpd" != "no"; then
1856 AC_MSG_CHECKING([for VRRP OS support])
1857 case "$host_os" in
1858   linux*)
1859     AC_MSG_RESULT([yes])
1860     ;;
1861   *)
1862     AC_MSG_RESULT([no])
1863     enable_vrrpd="no"
1864     ;;
1865 esac
1866 fi
1867
1868 dnl ------------------------------------------
1869 dnl Check whether rtrlib was build with ssh support
1870 dnl ------------------------------------------
1871 AC_MSG_CHECKING([whether the RTR Library is compiled with SSH])
1872 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "rtrlib/rtrlib.h"]],
1873                         [[struct tr_ssh_config config;]])],
1874         [AC_MSG_RESULT([yes])
1875         AC_DEFINE([FOUND_SSH], [1], [found_ssh])],
1876         AC_MSG_RESULT([no])
1877 )
1878
1879 dnl ---------------
1880 dnl dlopen & dlinfo
1881 dnl ---------------
1882 AC_SEARCH_LIBS([dlopen], [dl dld], [], [
1883   AC_MSG_ERROR([unable to find the dlopen()])
1884 ])
1885
1886 AC_CHECK_HEADERS([link.h])
1887
1888 AC_CACHE_CHECK([for dlinfo(RTLD_DI_ORIGIN)], [frr_cv_rtld_di_origin], [
1889   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1890 #include <stdlib.h>
1891 #ifdef HAVE_LINK_H
1892 #include <link.h>
1893 #endif
1894 #include <dlfcn.h>
1895 ]], [[
1896   char origin[1];
1897   dlinfo (NULL, RTLD_DI_ORIGIN, &origin);
1898 ]])], [
1899     frr_cv_rtld_di_origin=yes
1900   ], [
1901     frr_cv_rtld_di_origin=no
1902   ])
1903 ])
1904 if test "$frr_cv_rtld_di_origin" = "yes"; then
1905   AC_DEFINE([HAVE_DLINFO_ORIGIN], [1], [Have dlinfo RTLD_DI_ORIGIN])
1906 fi
1907
1908 AC_CACHE_CHECK([for dlinfo(RTLD_DI_LINKMAP)], [frr_cv_rtld_di_linkmap], [
1909   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1910 #include <stdlib.h>
1911 #ifdef HAVE_LINK_H
1912 #include <link.h>
1913 #endif
1914 #include <dlfcn.h>
1915 ]], [[
1916   struct link_map *lm = NULL;
1917   dlinfo (NULL, RTLD_DI_LINKMAP, &lm);
1918 ]])], [
1919     frr_cv_rtld_di_linkmap=yes
1920   ], [
1921     frr_cv_rtld_di_linkmap=no
1922   ])
1923 ])
1924 if test "$frr_cv_rtld_di_linkmap" = "yes"; then
1925   AC_DEFINE([HAVE_DLINFO_LINKMAP], [1], [Have dlinfo RTLD_DI_LINKMAP])
1926 fi
1927
1928 dnl ##########################################################################
1929 dnl test "$enable_clippy_only" != "yes"
1930 fi
1931 dnl END OF LARGE if block
1932 dnl ##########################################################################
1933
1934 dnl ---------------------------
1935 dnl sockaddr and netinet checks
1936 dnl ---------------------------
1937 AC_CHECK_TYPES([
1938         struct sockaddr_dl,
1939         struct vifctl, struct mfcctl, struct sioc_sg_req,
1940         vifi_t, struct sioc_vif_req, struct igmpmsg,
1941         struct ifaliasreq, struct if6_aliasreq, struct in6_aliasreq,
1942         struct nd_opt_adv_interval,
1943         struct nd_opt_homeagent_info, struct nd_opt_adv_interval,
1944         struct nd_opt_rdnss, struct nd_opt_dnssl],
1945         [], [], FRR_INCLUDES)
1946
1947 AC_CHECK_MEMBERS([struct sockaddr.sa_len,
1948         struct sockaddr_in.sin_len, struct sockaddr_un.sun_len,
1949         struct sockaddr_dl.sdl_len,
1950         struct if6_aliasreq.ifra_lifetime,
1951         struct nd_opt_adv_interval.nd_opt_ai_type],
1952         [], [], FRR_INCLUDES)
1953
1954 dnl ---------------------------
1955 dnl IRDP/pktinfo/icmphdr checks
1956 dnl ---------------------------
1957
1958 AC_CHECK_TYPES([struct in_pktinfo], [
1959   AC_CHECK_TYPES([struct icmphdr], [
1960     IRDP=true
1961   ], [
1962     IRDP=false
1963   ], [FRR_INCLUDES])
1964 ], [
1965   IRDP=false
1966 ], [FRR_INCLUDES])
1967
1968 case "${enable_irdp}" in
1969 yes)
1970   $IRDP || AC_MSG_ERROR(['IRDP requires in_pktinfo at the moment!'])
1971   ;;
1972 no)
1973   IRDP=false
1974   ;;
1975 esac
1976
1977
1978 dnl -----------------------
1979 dnl checking for IP_PKTINFO
1980 dnl -----------------------
1981 AC_MSG_CHECKING([for IP_PKTINFO])
1982 AC_TRY_COMPILE([#include <netdb.h>], [
1983   int opt = IP_PKTINFO;
1984 ], [
1985   AC_MSG_RESULT([yes])
1986   AC_DEFINE([HAVE_IP_PKTINFO], [1], [Have IP_PKTINFO])
1987 ], [
1988   AC_MSG_RESULT([no])
1989 ])
1990
1991 dnl ---------------------------
1992 dnl checking for IP_RECVDSTADDR
1993 dnl ---------------------------
1994 AC_MSG_CHECKING([for IP_RECVDSTADDR])
1995 AC_TRY_COMPILE([#include <netinet/in.h>], [
1996   int opt = IP_RECVDSTADDR;
1997 ], [
1998   AC_MSG_RESULT([yes])
1999   AC_DEFINE([HAVE_IP_RECVDSTADDR], [1], [Have IP_RECVDSTADDR])
2000 ], [
2001   AC_MSG_RESULT([no])
2002 ])
2003
2004 dnl ----------------------
2005 dnl checking for IP_RECVIF
2006 dnl ----------------------
2007 AC_MSG_CHECKING([for IP_RECVIF])
2008 AC_TRY_COMPILE([#include <netinet/in.h>], [
2009   int opt = IP_RECVIF;
2010 ], [
2011   AC_MSG_RESULT([yes])
2012   AC_DEFINE([HAVE_IP_RECVIF], [1], [Have IP_RECVIF])
2013 ], [
2014   AC_MSG_RESULT([no])
2015 ])
2016
2017 dnl ----------------------
2018 dnl checking for SO_BINDANY
2019 dnl ----------------------
2020 AC_MSG_CHECKING([for SO_BINDANY])
2021 AC_TRY_COMPILE([#include <sys/socket.h>], [
2022   int opt = SO_BINDANY;
2023 ], [
2024   AC_MSG_RESULT([yes])
2025   AC_DEFINE([HAVE_SO_BINDANY], [1], [Have SO_BINDANY])
2026 ], [
2027   AC_MSG_RESULT([no])
2028 ])
2029
2030 dnl ----------------------
2031 dnl checking for IP_FREEBIND
2032 dnl ----------------------
2033 AC_MSG_CHECKING([for IP_FREEBIND])
2034 AC_TRY_COMPILE([#include <netinet/in.h>], [
2035   int opt = IP_FREEBIND;
2036 ], [
2037   AC_MSG_RESULT([yes])
2038   AC_DEFINE([HAVE_IP_FREEBIND], [1], [Have IP_FREEBIND])
2039 ], [
2040   AC_MSG_RESULT([no])
2041 ])
2042
2043 dnl --------------------------------------
2044 dnl checking for be32dec existence or not
2045 dnl --------------------------------------
2046 AC_CHECK_DECLS([be32enc, be32dec], [], [],
2047                [#include <sys/endian.h>])
2048
2049 dnl --------------------------------------
2050 dnl checking for clock_time monotonic struct and call
2051 dnl --------------------------------------
2052 AC_CHECK_DECL([CLOCK_MONOTONIC],
2053         [AC_CHECK_LIB([rt], [clock_gettime], [LIBS="$LIBS -lrt"])
2054          AC_DEFINE([HAVE_CLOCK_MONOTONIC], [1], [Have monotonic clock])
2055 ], [AC_MSG_RESULT([no])], [FRR_INCLUDES])
2056
2057 AC_SEARCH_LIBS([clock_nanosleep], [rt], [
2058   AC_DEFINE([HAVE_CLOCK_NANOSLEEP], [1], [Have clock_nanosleep()])
2059 ])
2060
2061 dnl --------------------------------------
2062 dnl checking for flex and bison
2063 dnl --------------------------------------
2064
2065 AM_PROG_LEX
2066 AC_MSG_CHECKING([version of flex])
2067 frr_ac_flex_version="$(eval $LEX -V | grep flex | head -n 1)"
2068 frr_ac_flex_version="${frr_ac_flex_version##* }"
2069 AC_MSG_RESULT([$frr_ac_flex_version])
2070 AX_COMPARE_VERSION([$frr_ac_flex_version], [lt], [2.5.20], [
2071   LEX="$SHELL $missing_dir/missing flex"
2072   if test -f "${srcdir}/lib/command_lex.c" -a -f "${srcdir}/lib/command_lex.h"; then
2073     AC_MSG_WARN([using pregenerated flex output files])
2074   else
2075     AC_MSG_ERROR([flex failure and pregenerated files not included (probably a git build)])
2076   fi
2077   AC_SUBST([LEX_OUTPUT_ROOT], [lex.yy])
2078   AC_SUBST([LEXLIB], [''])
2079 ])
2080
2081 AC_PROG_YACC
2082 dnl thanks GNU bison for this b*llshit...
2083 AC_MSG_CHECKING([version of bison])
2084 frr_ac_bison_version="$(eval $YACC -V | grep bison | head -n 1)"
2085 frr_ac_bison_version="${frr_ac_bison_version##* }"
2086 frr_ac_bison_missing="false"
2087 case "x${frr_ac_bison_version}x" in
2088   x2.7*)
2089     BISON_OPENBRACE='"'
2090     BISON_CLOSEBRACE='"'
2091     BISON_VERBOSE=''
2092     AC_MSG_RESULT([$frr_ac_bison_version - 2.7 or older])
2093     ;;
2094   x2.*|x1.*)
2095     AC_MSG_RESULT([$frr_ac_bison_version])
2096     AC_MSG_WARN([installed bison is too old.  Please install GNU bison 2.7.x or newer.])
2097     frr_ac_bison_missing="true"
2098     ;;
2099   x)
2100     AC_MSG_RESULT([none])
2101     AC_MSG_WARN([could not determine bison version.  Please install GNU bison 2.7.x or newer.])
2102     frr_ac_bison_missing="true"
2103     ;;
2104   x3.[012][^0-9]*)
2105     BISON_OPENBRACE='{'
2106     BISON_CLOSEBRACE='}'
2107     BISON_VERBOSE='-Dparse.error=verbose'
2108     AC_MSG_RESULT([$frr_ac_bison_version - 3.0 to 3.2])
2109     ;;
2110   *)
2111     BISON_OPENBRACE='{'
2112     BISON_CLOSEBRACE='}'
2113     BISON_VERBOSE='-Dparse.error=verbose -Wno-yacc'
2114     AC_MSG_RESULT([$frr_ac_bison_version - 3.3 or newer])
2115     ;;
2116 esac
2117 AC_SUBST([BISON_OPENBRACE])
2118 AC_SUBST([BISON_CLOSEBRACE])
2119 AC_SUBST([BISON_VERBOSE])
2120
2121 if $frr_ac_bison_missing; then
2122   YACC="$SHELL $missing_dir/missing bison -y"
2123   if test -f "${srcdir}/lib/command_parse.c" -a -f "${srcdir}/lib/command_parse.h"; then
2124     AC_MSG_WARN([using pregenerated bison output files])
2125   else
2126     AC_MSG_ERROR([bison failure and pregenerated files not included (probably a git build)])
2127   fi
2128 fi
2129
2130 dnl -------------------
2131 dnl capabilities checks
2132 dnl -------------------
2133 if test "$enable_capabilities" != "no"; then
2134   AC_MSG_CHECKING([whether prctl PR_SET_KEEPCAPS is available])
2135   AC_TRY_COMPILE([#include <sys/prctl.h>], [prctl(PR_SET_KEEPCAPS, 1, 0, 0, 0);],
2136     [AC_MSG_RESULT([yes])
2137      AC_DEFINE([HAVE_PR_SET_KEEPCAPS], [1], [prctl])
2138      frr_ac_keepcaps="yes"],
2139      AC_MSG_RESULT([no])
2140   )
2141   if test "$frr_ac_keepcaps" = "yes"; then
2142     AC_CHECK_HEADERS([sys/capability.h])
2143   fi
2144   if test "$ac_cv_header_sys_capability_h" = "yes"; then
2145     AC_CHECK_LIB([cap], [cap_init],
2146       [AC_DEFINE([HAVE_LCAPS], [1], [Capabilities])
2147        LIBCAP="-lcap"
2148        frr_ac_lcaps="yes"]
2149     )
2150   else
2151     AC_CHECK_HEADERS([priv.h],
2152      [AC_MSG_CHECKING([Solaris style privileges are available])
2153       AC_TRY_COMPILE([#include <priv.h>], [getpflags(PRIV_AWARE);],
2154           [AC_MSG_RESULT([yes])
2155            AC_DEFINE([HAVE_SOLARIS_CAPABILITIES], [1], [getpflags])
2156            frr_ac_scaps="yes"],
2157            AC_MSG_RESULT(no)
2158       )
2159      ]
2160    )
2161   fi
2162   if test "$frr_ac_scaps" = "yes" \
2163        -o "$frr_ac_lcaps" = "yes"; then
2164     AC_DEFINE([HAVE_CAPABILITIES], [1], [capabilities])
2165   fi
2166
2167   case "$host_os" in
2168   linux*)
2169     if test "$enable_clippy_only" != "yes"; then
2170     if test "$frr_ac_lcaps" != "yes"; then
2171       AC_MSG_ERROR([libcap and/or its headers were not found.  Running FRR without libcap support built in causes a huge performance penalty.])
2172     fi
2173     fi
2174     ;;
2175   esac
2176 else
2177   case "$host_os" in
2178   linux*)
2179     AC_MSG_WARN([Running FRR without libcap support built in causes a huge performance penalty.])
2180     ;;
2181   esac
2182 fi
2183 AC_SUBST([LIBCAP])
2184
2185 dnl ---------------------------
2186 dnl check for glibc 'backtrace'
2187 dnl ---------------------------
2188 if test "$enable_backtrace" != "no" ; then
2189   backtrace_ok=no
2190   PKG_CHECK_MODULES([UNWIND], [libunwind], [
2191     AC_DEFINE([HAVE_LIBUNWIND], [1], [libunwind])
2192     backtrace_ok=yes
2193   ], [
2194     true
2195   ])
2196
2197   if test "$backtrace_ok" = "no"; then
2198     AC_CHECK_HEADER([unwind.h], [
2199       AC_SEARCH_LIBS([unw_getcontext], [unwind], [
2200         AC_DEFINE([HAVE_LIBUNWIND], [1], [libunwind])
2201         backtrace_ok=yes
2202       ])
2203     ])
2204   fi
2205
2206   if test "$backtrace_ok" = "no"; then
2207     AC_CHECK_HEADER([execinfo.h], [
2208       AC_SEARCH_LIBS([backtrace], [execinfo], [
2209         AC_DEFINE([HAVE_GLIBC_BACKTRACE], [1], [Glibc backtrace])
2210         backtrace_ok=yes
2211       ],, [-lm])
2212     ])
2213   fi
2214
2215   if test "$enable_backtrace" = "yes" -a "$backtrace_ok" = "no"; then
2216     dnl user explicitly requested backtrace but we failed to find support
2217     AC_MSG_FAILURE([failed to find backtrace or libunwind support])
2218   fi
2219 fi
2220
2221 dnl -----------------------------------------
2222 dnl check for malloc mallinfo struct and call
2223 dnl this must try and link using LIBS, in
2224 dnl order to check no alternative allocator
2225 dnl has been specified, which might not provide
2226 dnl mallinfo, e.g. such as Umem on Solaris.
2227 dnl -----------------------------------------
2228 AC_CHECK_HEADERS([malloc.h malloc_np.h malloc/malloc.h],,, [FRR_INCLUDES])
2229
2230 AC_CACHE_CHECK([whether mallinfo is available], [frr_cv_mallinfo], [
2231   AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2232 #ifdef HAVE_MALLOC_H
2233 #include <malloc.h>
2234 #endif
2235 #ifdef HAVE_MALLOC_NP_H
2236 #include <malloc_np.h>
2237 #endif
2238 #ifdef HAVE_MALLOC_MALLOC_H
2239 #include <malloc/malloc.h>
2240 #endif
2241 ]], [[
2242 struct mallinfo ac_x; ac_x = mallinfo ();
2243 ]])], [
2244     frr_cv_mallinfo=yes
2245   ], [
2246     frr_cv_mallinfo=no
2247   ])
2248 ])
2249 if test "$frr_cv_mallinfo" = "yes"; then
2250   AC_DEFINE([HAVE_MALLINFO], [1], [mallinfo])
2251 fi
2252
2253 AC_MSG_CHECKING([whether malloc_usable_size is available])
2254 AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2255 #ifdef HAVE_MALLOC_H
2256 #include <malloc.h>
2257 #endif
2258 #ifdef HAVE_MALLOC_MALLOC_H
2259 #include <malloc/malloc.h>
2260 #endif
2261 ]], [[
2262 size_t ac_x; ac_x = malloc_usable_size(NULL);
2263 ]])], [
2264   AC_MSG_RESULT([yes])
2265   AC_DEFINE([HAVE_MALLOC_USABLE_SIZE], [1], [malloc_usable_size])
2266 ], [
2267   AC_MSG_RESULT([no])
2268
2269   AC_MSG_CHECKING([whether malloc_size is available])
2270   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2271 #ifdef HAVE_MALLOC_H
2272 #include <malloc.h>
2273 #endif
2274 #ifdef HAVE_MALLOC_MALLOC_H
2275 #include <malloc/malloc.h>
2276 #endif
2277 ]], [[
2278 size_t ac_x; ac_x = malloc_size(NULL);
2279 ]])], [
2280     AC_MSG_RESULT([yes])
2281     AC_DEFINE([HAVE_MALLOC_SIZE], [1], [malloc_size])
2282   ], [
2283     AC_MSG_RESULT([no])
2284   ])
2285 ])
2286
2287 dnl ----------
2288 dnl configure date
2289 dnl ----------
2290 dev_version=`echo $VERSION | grep dev`
2291 #don't expire deprecated code in non 'dev' branch
2292 if test "$dev_version" = ""; then
2293    CONFDATE=0
2294 else
2295    CONFDATE=`date '+%Y%m%d'`
2296 fi
2297 AC_SUBST([CONFDATE])
2298
2299 dnl ------------------------------
2300 dnl set paths for state directory
2301 dnl ------------------------------
2302 AC_MSG_CHECKING([directory to use for state file])
2303 if test "$prefix" = "NONE"; then
2304   frr_statedir_prefix="";
2305 else
2306   frr_statedir_prefix=${prefix}
2307 fi
2308 if test "$localstatedir" = '${prefix}/var'; then
2309   for FRR_STATE_DIR in ${frr_statedir_prefix}/var/run dnl
2310                         ${frr_statedir_prefix}/var/adm dnl
2311                         ${frr_statedir_prefix}/etc dnl
2312                         /var/run        dnl
2313                         /var/adm        dnl
2314                         /etc            dnl
2315                         /dev/null;
2316   do
2317     test -d $FRR_STATE_DIR && break
2318   done
2319   frr_statedir=$FRR_STATE_DIR
2320 else
2321   frr_statedir=${localstatedir}
2322 fi
2323 if test "$frr_statedir" = "/dev/null"; then
2324     AC_MSG_ERROR([STATE DIRECTORY NOT FOUND! FIX OR SPECIFY --localstatedir!])
2325 fi
2326 AC_MSG_RESULT([${frr_statedir}])
2327 AC_SUBST([frr_statedir])
2328
2329 AC_DEFINE_UNQUOTED([LDPD_SOCKET], ["$frr_statedir%s%s/ldpd.sock"], [ldpd control socket])
2330 AC_DEFINE_UNQUOTED([ZEBRA_SERV_PATH], ["$frr_statedir%s%s/zserv.api"], [zebra api socket])
2331 AC_DEFINE_UNQUOTED([BFDD_CONTROL_SOCKET], ["$frr_statedir%s%s/bfdd.sock"], [bfdd control socket])
2332 AC_DEFINE_UNQUOTED([DAEMON_VTY_DIR], ["$frr_statedir%s%s"], [daemon vty directory])
2333 AC_DEFINE_UNQUOTED([DAEMON_DB_DIR], ["$frr_statedir"], [daemon database directory])
2334
2335 dnl autoconf does this, but it does it too late...
2336 test "$prefix" = "NONE" && prefix=$ac_default_prefix
2337 test "$exec_prefix" = "NONE" && exec_prefix='${prefix}'
2338
2339 dnl get the full path, recursing through variables...
2340 vtysh_bin="$bindir/vtysh"
2341 for I in 1 2 3 4 5 6 7 8 9 10; do
2342         eval vtysh_bin="\"$vtysh_bin\""
2343 done
2344 AC_DEFINE_UNQUOTED([VTYSH_BIN_PATH], ["$vtysh_bin"], [path to vtysh binary])
2345 AC_SUBST([vtysh_bin])
2346
2347 CFG_SYSCONF="$sysconfdir"
2348 CFG_SBIN="$sbindir"
2349 CFG_STATE="$frr_statedir"
2350 CFG_MODULE="$moduledir"
2351 CFG_YANGMODELS="$yangmodelsdir"
2352 for I in 1 2 3 4 5 6 7 8 9 10; do
2353         eval CFG_SYSCONF="\"$CFG_SYSCONF\""
2354         eval CFG_SBIN="\"$CFG_SBIN\""
2355         eval CFG_STATE="\"$CFG_STATE\""
2356         eval CFG_MODULE="\"$CFG_MODULE\""
2357         eval CFG_YANGMODELS="\"$CFG_YANGMODELS\""
2358 done
2359 AC_SUBST([CFG_SYSCONF])
2360 AC_SUBST([CFG_SBIN])
2361 AC_SUBST([CFG_STATE])
2362 AC_SUBST([CFG_MODULE])
2363 AC_SUBST([CFG_YANGMODELS])
2364 AC_DEFINE_UNQUOTED([MODULE_PATH], ["$CFG_MODULE"], [path to modules])
2365 AC_DEFINE_UNQUOTED([YANG_MODELS_PATH], ["$CFG_YANGMODELS"], [path to YANG data models])
2366 AC_DEFINE_UNQUOTED([WATCHFRR_SH_PATH], ["${CFG_SBIN%/}/watchfrr.sh"], [path to watchfrr.sh])
2367
2368 dnl various features
2369 AM_CONDITIONAL([SUPPORT_REALMS], [test "$enable_realms" = "yes"])
2370 AM_CONDITIONAL([ENABLE_BGP_VNC], [test "$enable_bgp_vnc" != "no"])
2371 AM_CONDITIONAL([BGP_BMP], [$bgpd_bmp])
2372 dnl northbound
2373 AM_CONDITIONAL([SQLITE3], [$SQLITE3])
2374 AM_CONDITIONAL([CONFD], [test "$enable_confd" != ""])
2375 AM_CONDITIONAL([SYSREPO], [test "$enable_sysrepo" = "yes"])
2376 AM_CONDITIONAL([GRPC], [test "$enable_grpc" = "yes"])
2377 AM_CONDITIONAL([ZEROMQ], [test "$ZEROMQ" = "true"])
2378 dnl plugins
2379 AM_CONDITIONAL([RPKI], [test "$RPKI" = "true"])
2380 AM_CONDITIONAL([SNMP], [test "$SNMP_METHOD" = "agentx"])
2381 AM_CONDITIONAL([IRDP], [$IRDP])
2382 AM_CONDITIONAL([FPM], [test "$enable_fpm" = "yes"])
2383 AM_CONDITIONAL([HAVE_PROTOBUF], [test "$enable_protobuf" = "yes"])
2384 AM_CONDITIONAL([HAVE_PROTOBUF3], [$PROTO3])
2385 dnl daemons
2386 AM_CONDITIONAL([VTYSH], [test "$VTYSH" = "vtysh"])
2387 AM_CONDITIONAL([ZEBRA], [test "$enable_zebra" != "no"])
2388 AM_CONDITIONAL([BGPD], [test "$enable_bgpd" != "no"])
2389 AM_CONDITIONAL([RIPD], [test "$enable_ripd" != "no"])
2390 AM_CONDITIONAL([OSPFD], [test "$enable_ospfd" != "no"])
2391 AM_CONDITIONAL([LDPD], [test "$enable_ldpd" != "no"])
2392 AM_CONDITIONAL([BFDD], [test "$BFDD" = "bfdd"])
2393 AM_CONDITIONAL([NHRPD], [test "$NHRPD" = "nhrpd"])
2394 AM_CONDITIONAL([EIGRPD], [test "$enable_eigrpd" != "no"])
2395 AM_CONDITIONAL([WATCHFRR], [test "$WATCHFRR" = "watchfrr"])
2396 AM_CONDITIONAL([OSPFCLIENT], [test "$OSPFCLIENT" = "ospfclient"])
2397 AM_CONDITIONAL([RIPNGD], [test "$enable_ripngd" != "no"])
2398 AM_CONDITIONAL([BABELD], [test "$enable_babeld" != "no"])
2399 AM_CONDITIONAL([OSPF6D], [test "$enable_ospf6d" != "no"])
2400 AM_CONDITIONAL([ISISD], [test "$enable_isisd" != "no"])
2401 AM_CONDITIONAL([PIMD], [test "$enable_pimd" != "no"])
2402 AM_CONDITIONAL([PBRD], [test "$enable_pbrd" != "no"])
2403 AM_CONDITIONAL([SHARPD], [test "$enable_sharpd" = "yes"])
2404 AM_CONDITIONAL([STATICD], [test "$enable_staticd" != "no"])
2405 AM_CONDITIONAL([FABRICD], [test "$enable_fabricd" != "no"])
2406 AM_CONDITIONAL([VRRPD], [test "$enable_vrrpd" != "no"])
2407
2408 AC_CONFIG_FILES([Makefile],[
2409         test "$enable_dev_build" = "yes" && makefile_devbuild="--dev-build"
2410         ${PYTHON} "${ac_abs_top_srcdir}/python/makefile.py" ${makefile_devbuild} || exit 1
2411 ], [
2412         PYTHON="$PYTHON"
2413         enable_dev_build="$enable_dev_build"
2414 ])
2415
2416 AC_CONFIG_FILES([
2417           config.version
2418           changelog-auto
2419           redhat/frr.spec
2420           solaris/Makefile
2421           alpine/APKBUILD
2422           snapcraft/snapcraft.yaml
2423           lib/version.h
2424           tests/lib/cli/test_cli.refout
2425           pkgsrc/bgpd.sh pkgsrc/ospf6d.sh pkgsrc/ospfd.sh
2426           pkgsrc/ripd.sh pkgsrc/ripngd.sh pkgsrc/zebra.sh
2427           pkgsrc/eigrpd.sh])
2428
2429 AC_CONFIG_FILES([vtysh/extract.pl], [chmod +x vtysh/extract.pl])
2430 AC_CONFIG_FILES([tools/frr], [chmod +x tools/frr])
2431 AC_CONFIG_FILES([tools/watchfrr.sh], [chmod +x tools/watchfrr.sh])
2432 AC_CONFIG_FILES([tools/frrinit.sh], [chmod +x tools/frrinit.sh])
2433 AC_CONFIG_FILES([tools/frrcommon.sh])
2434
2435 AC_CONFIG_COMMANDS([lib/route_types.h], [
2436         dst="${ac_abs_top_builddir}/lib/route_types.h"
2437         ${PERL} "${ac_abs_top_srcdir}/lib/route_types.pl" \
2438                 < "${ac_abs_top_srcdir}/lib/route_types.txt" \
2439                 > "${dst}.tmp"
2440         test -f "$dst" \
2441                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
2442                 && rm "${dst}.tmp" \
2443                 || mv "${dst}.tmp" "${dst}"
2444 ], [
2445         PERL="$PERL"
2446 ])
2447
2448 AS_IF([test "$with_pkg_git_version" = "yes"], [
2449     AC_CONFIG_COMMANDS([lib/gitversion.h], [
2450         dst="${ac_abs_top_builddir}/lib/gitversion.h"
2451         ${PERL} "${ac_abs_top_srcdir}/lib/gitversion.pl" \
2452                 "${ac_abs_top_srcdir}" \
2453                 > "${dst}.tmp"
2454         test -f "$dst" \
2455                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
2456                 && rm "${dst}.tmp" \
2457                 || mv "${dst}.tmp" "${dst}"
2458     ], [
2459         PERL="$PERL"
2460     ])
2461 ])
2462
2463 ## Hack, but working solution to avoid rebuilding of frr.info.
2464 ## It's already in CVS until texinfo 4.7 is more common.
2465 AC_OUTPUT
2466
2467 echo "
2468 FRRouting configuration
2469 ------------------------------
2470 FRR version             : ${PACKAGE_VERSION}
2471 host operating system   : ${host_os}
2472 source code location    : ${srcdir}
2473 compiler                : ${CC}
2474 compiler flags          : ${CFLAGS} ${SAN_FLAGS}
2475 make                    : ${MAKE-make}
2476 linker flags            : ${LDFLAGS} ${SAN_FLAGS} ${LIBS} ${LIBCAP} ${LIBREADLINE} ${LIBM}
2477 state file directory    : ${frr_statedir}
2478 config file directory   : `eval echo \`echo ${sysconfdir}\``
2479 example directory       : `eval echo \`echo ${exampledir}\``
2480 module directory        : ${CFG_MODULE}
2481 user to run as          : ${enable_user}
2482 group to run as         : ${enable_group}
2483 group for vty sockets   : ${enable_vty_group}
2484 config file mask        : ${enable_configfile_mask}
2485 log file mask           : ${enable_logfile_mask}
2486 zebra protobuf enabled  : ${enable_protobuf:-no}
2487
2488 The above user and group must have read/write access to the state file
2489 directory and to the config files in the config file directory."
2490
2491 if test "$enable_doc" != "no" -a "$frr_py_mod_sphinx" = "false"; then
2492   AC_MSG_WARN([sphinx is missing but required to build documentation])
2493 fi
2494 if test "$frr_py_mod_pytest" = "false"; then
2495   AC_MSG_WARN([pytest is missing, unit tests cannot be performed])
2496 fi