configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 m4_define([lxc_version_major], 1)
   5 m4_define([lxc_version_minor], 1)
   6 m4_define([lxc_version_micro], 0)
   7 m4_define([lxc_version_beta], [])
   8
   9 m4_define([lxc_version_base], [lxc_version_major.lxc_version_minor.lxc_version_micro])
  10 m4_define([lxc_version],
  11           [ifelse(lxc_version_beta, [], [lxc_version_base], [lxc_version_base.lxc_version_beta])])
  12
  13 AC_INIT([lxc], [lxc_version])
  14
  15 # We need pkg-config
  16 PKG_PROG_PKG_CONFIG
  17
  18 AC_SUBST(LXC_VERSION_BASE, lxc_version_base)
  19 AC_SUBST(LXC_VERSION_BETA, lxc_version_beta)
  20
  21 AC_SUBST([LXC_VERSION_MAJOR], [lxc_version_major])
  22 AC_SUBST([LXC_VERSION_MINOR], [lxc_version_minor])
  23 AC_SUBST([LXC_VERSION_MICRO], [lxc_version_micro])
  24 AC_SUBST([LXC_VERSION], [lxc_version])
  25
  26 AC_CONFIG_SRCDIR([configure.ac])
  27 AC_CONFIG_AUX_DIR([config])
  28 AC_CONFIG_HEADERS([src/config.h])
  29 AM_INIT_AUTOMAKE([-Wall -Werror -Wno-portability subdir-objects])
  30 AC_CANONICAL_HOST
  31 AM_PROG_CC_C_O
  32 AC_GNU_SOURCE
  33
  34 # Detect the distribution. This is used for the default configuration and
  35 # for some distro-specific build options.
  36 AC_MSG_CHECKING([host distribution])
  37 AC_ARG_WITH(distro, AS_HELP_STRING([--with-distro=DISTRO], [Specify the Linux distribution to target: One of redhat, oracle, centos, fedora, suse, gentoo, debian, arch, slackware, plamo, paldo, openmandriva or pardus.]))
  38 if type lsb_release >/dev/null 2>&1 && test "z$with_distro" = "z"; then
  39         with_distro=`lsb_release -is`
  40 fi
  41 if test "z$with_distro" = "z"; then
  42         AC_CHECK_FILE(/etc/redhat-release,with_distro="redhat")
  43         AC_CHECK_FILE(/etc/oracle-release,with_distro="oracle")
  44         AC_CHECK_FILE(/etc/centos-release,with_distro="centos")
  45         AC_CHECK_FILE(/etc/fedora-release,with_distro="fedora")
  46         AC_CHECK_FILE(/etc/SuSE-release,with_distro="suse")
  47         AC_CHECK_FILE(/etc/gentoo-release,with_distro="gentoo")
  48         AC_CHECK_FILE(/etc/debian_version,with_distro="debian")
  49         AC_CHECK_FILE(/etc/arch-release,with_distro="arch")
  50         AC_CHECK_FILE(/etc/slackware-version,with_distro="slackware")
  51         AC_CHECK_FILE(/etc/plamo-version,with_distro="plamo")
  52         AC_CHECK_FILE(/etc/frugalware-release,with_distro="frugalware")
  53         AC_CHECK_FILE(/etc/mandrakelinux-release, with_distro="openmandriva")
  54         AC_CHECK_FILE(/etc/mandriva-release,with_distro="openmandriva")
  55         AC_CHECK_FILE(/etc/pardus-release,with_distro="pardus")
  56 fi
  57 with_distro=`echo ${with_distro} | tr '[[:upper:]]' '[[:lower:]]'`
  58
  59 if test "z$with_distro" = "z"; then
  60         with_distro="unknown"
  61 fi
  62 case $with_distro in
  63         ubuntu|raspbian)
  64                 distroconf=default.conf.lxcbr
  65                 distrosysconf="$sysconfdir/default"
  66                 ;;
  67         redhat|centos|fedora|oracle|oracleserver|suse|opensuse*|plamo)
  68                 distroconf=default.conf.lxcbr
  69                 distrosysconf="$sysconfdir/sysconfig"
  70                 ;;
  71         *)
  72                 distroconf=default.conf.unknown
  73                 distrosysconf="$sysconfdir/default"
  74                 ;;
  75 esac
  76 AC_MSG_RESULT([$with_distro])
  77 AM_CONDITIONAL([HAVE_DEBIAN], [test x"$with_distro" = "xdebian" -o x"$with_distro" = "xubuntu" -o x"$with_distro" = "xraspbian"])
  78 AM_CONDITIONAL([DISTRO_UBUNTU], [test "x$with_distro" = "xubuntu"])
  79
  80 AC_CONFIG_LINKS([config/etc/default.conf:config/etc/${distroconf}])
  81
  82 # Check for init system type
  83 AC_MSG_CHECKING([for init system type])
  84 AC_ARG_WITH([init-script],
  85             [AC_HELP_STRING([--with-init-script@<:@=TYPE@<:@,TYPE,...@:>@@:>@],
  86                             [Type(s) of init script to install: sysvinit, systemd, upstart,
  87                              distro @<:@default=distro@:>@])],[],[with_init_script=distro])
  88 case "$with_init_script" in
  89         distro)
  90                 case $with_distro in
  91                         fedora|opensuse*)
  92                                 init_script=systemd
  93                                 ;;
  94                         redhat|centos|oracle|oracleserver|plamo)
  95                                 init_script=sysvinit
  96                                 ;;
  97                         debian|raspbian)
  98                                 init_script=upstart,systemd
  99                                 ;;
 100                         ubuntu)
 101                                 init_script=upstart,systemd
 102                                 ;;
 103                         *)
 104                                 echo -n "Linux distribution init system unknown."
 105                                 init_script=
 106                                 ;;
 107                 esac
 108                 ;;
 109         *)
 110                 init_script=$with_init_script
 111                 ;;
 112 esac
 113
 114 # Check valid init systems were given, run in subshell so we don't mess up IFS
 115 (IFS="," ; for init_sys in $init_script;
 116 do
 117         case "$init_sys" in
 118                 none|sysvinit|systemd|upstart)
 119                         ;;
 120                 *)
 121                         exit 1
 122                         ;;
 123         esac
 124 done) || AC_MSG_ERROR([Unknown init system type in $init_script])
 125
 126 AM_CONDITIONAL([INIT_SCRIPT_SYSV], [echo "$init_script" |grep -q "sysvinit"])
 127 AM_CONDITIONAL([INIT_SCRIPT_SYSTEMD], [echo "$init_script" |grep -q "systemd"])
 128 AM_CONDITIONAL([INIT_SCRIPT_UPSTART], [echo "$init_script" |grep -q "upstart"])
 129 AC_MSG_RESULT($init_script)
 130
 131 # systemd unit dir
 132 AC_ARG_WITH([systemdsystemunitdir],
 133             AS_HELP_STRING([--with-systemdsystemunitdir=DIR], [Directory for systemd service files]),
 134             [],
 135             [with_systemdsystemunitdir=$($PKG_CONFIG --variable=systemdsystemunitdir systemd)])
 136 if test -z "$with_systemdsystemunitdir"; then
 137   with_systemdsystemunitdir=/lib/systemd/system
 138 fi
 139 if test "x$with_systemdsystemunitdir" != "xno"; then
 140   AC_SUBST([SYSTEMD_UNIT_DIR], [$with_systemdsystemunitdir])
 141 fi
 142
 143 # Allow disabling rpath
 144 AC_ARG_ENABLE([rpath],
 145         [AC_HELP_STRING([--enable-rpath], [set rpath in executables [default=no]])],
 146         [], [enable_rpath=no])
 147 AM_CONDITIONAL([ENABLE_RPATH], [test "x$enable_rpath" = "xyes"])
 148
 149 # Documentation (manpages)
 150 AC_ARG_ENABLE([doc],
 151         [AC_HELP_STRING([--enable-doc], [make man pages [default=auto]])],
 152         [], [enable_doc=auto])
 153
 154 if test "x$enable_doc" = "xyes" -o "x$enable_doc" = "xauto"; then
 155         db2xman=""
 156         dbparsers="docbook2x-man db2x_docbook2man docbook2man docbook-to-man"
 157
 158         AC_MSG_CHECKING(for docbook2x-man)
 159         for name in ${dbparsers}; do
 160                 if "$name" --help >/dev/null 2>&1; then
 161                         db2xman="$name"
 162                         break;
 163                 fi
 164         done
 165
 166         if test -n "${db2xman}"; then
 167                 AC_MSG_RESULT([${db2xman}])
 168                 enable_doc="yes"
 169         else
 170                 AC_MSG_RESULT([no])
 171                 if test "x$enable_doc" = "xyes"; then
 172                         AC_MSG_ERROR([docbook2x-man is required, but could not be found])
 173                 fi
 174                 enable_doc="no"
 175         fi
 176
 177         AC_SUBST(db2xman)
 178 fi
 179 AM_CONDITIONAL([ENABLE_DOCBOOK], [test "x$db2xman" != "x"])
 180 AM_CONDITIONAL([USE_DOCBOOK2X], [test "x$db2xman" != "xdocbook2man"])
 181
 182 if test "x$db2xman" = "xdocbook2man"; then
 183         docdtd="\"-//Davenport//DTD DocBook V3.0//EN\""
 184 else
 185         docdtd="\"-//OASIS//DTD DocBook XML\" \"http://www.oasis-open.org/docbook/xml/4.5/docbookx.dtd\""
 186 fi
 187 AC_SUBST(docdtd)
 188
 189 # Documentation (API)
 190 AC_ARG_ENABLE([api-docs],
 191         [AC_HELP_STRING([--enable-api-docs],
 192         [make API documentation [default=auto]])],
 193         [], [enable_api_docs=auto])
 194
 195 if test "x$enable_api_docs" = "xyes" -o "x$enable_api_docs" = "xauto"; then
 196         AC_CHECK_PROGS([HAVE_DOXYGEN],[doxygen])
 197         AC_SUBST([HAVE_DOXYGEN])
 198
 199         if test "x$HAVE_DOXYGEN" != "x"; then
 200                 enable_api_docs="yes"
 201         else
 202                 if test "x$enable_api_docs" = "xyes"; then
 203                         AC_MSG_ERROR([doxygen is required, but could not be found])
 204                 fi
 205                 enable_api_docs="no"
 206         fi
 207 fi
 208
 209 AM_CONDITIONAL([ENABLE_API_DOCS], [test "x$HAVE_DOXYGEN" != "x"])
 210
 211 # Apparmor
 212 AC_ARG_ENABLE([apparmor],
 213         [AC_HELP_STRING([--enable-apparmor], [enable apparmor support [default=auto]])],
 214         [], [enable_apparmor=auto])
 215
 216 if test "$enable_apparmor" = "auto" ; then
 217         AC_CHECK_LIB([apparmor],[aa_change_profile],[enable_apparmor=yes], [enable_apparmor=no])
 218 fi
 219 AM_CONDITIONAL([ENABLE_APPARMOR], [test "x$enable_apparmor" = "xyes"])
 220
 221 AC_CHECK_LIB([gnutls], [gnutls_hash_fast], [enable_gnutls=yes], [enable_gnutls=no])
 222
 223 AM_COND_IF([ENABLE_APPARMOR],
 224         [AC_CHECK_HEADER([sys/apparmor.h],[],[AC_MSG_ERROR([You must install the AppArmor development package in order to compile lxc])])
 225         AC_CHECK_LIB([apparmor], [aa_change_profile],[],[AC_MSG_ERROR([You must install the AppArmor development package in order to compile lxc])])
 226         AC_SUBST([APPARMOR_LIBS], [-lapparmor])])
 227
 228 # SELinux
 229 AC_ARG_ENABLE([selinux],
 230         [AC_HELP_STRING([--enable-selinux], [enable SELinux support [default=auto]])],
 231         [], [enable_selinux=auto])
 232
 233 if test "x$enable_selinux" = xauto; then
 234         AC_CHECK_LIB([selinux],[setexeccon_raw],[enable_selinux=yes],[enable_selinux=no])
 235 fi
 236 AM_CONDITIONAL([ENABLE_SELINUX], [test "x$enable_selinux" = "xyes"])
 237 AM_COND_IF([ENABLE_SELINUX],
 238         [AC_CHECK_HEADER([selinux/selinux.h],[],[AC_MSG_ERROR([You must install the SELinux development package in order to compile lxc])])
 239         AC_CHECK_LIB([selinux], [setexeccon_raw],[true],[AC_MSG_ERROR([You must install the SELinux development package in order to compile lxc])])
 240         AC_SUBST([SELINUX_LIBS], [-lselinux])])
 241
 242 # Seccomp syscall filter
 243 AC_ARG_ENABLE([seccomp],
 244         [AC_HELP_STRING([--enable-seccomp], [enable seccomp support [default=auto]])],
 245         [], [enable_seccomp=auto])
 246
 247 if test "x$enable_seccomp" = "xauto" ; then
 248         AC_CHECK_LIB([seccomp],[seccomp_init],[enable_seccomp=yes],[enable_seccomp=no])
 249 fi
 250 AM_CONDITIONAL([ENABLE_SECCOMP], [test "x$enable_seccomp" = "xyes"])
 251
 252 AM_COND_IF([ENABLE_SECCOMP],
 253         [PKG_CHECK_MODULES([SECCOMP],[libseccomp],[],[
 254                 AC_CHECK_HEADER([seccomp.h],[],[AC_MSG_ERROR([You must install the seccomp development package in order to compile lxc])])
 255                 AC_CHECK_LIB([seccomp], [seccomp_init],[],[AC_MSG_ERROR([You must install the seccomp development package in order to compile lxc])])
 256                 AC_SUBST([SECCOMP_LIBS], [-lseccomp])
 257                 ])
 258         ])
 259
 260 # cgmanager
 261 AC_ARG_ENABLE([cgmanager],
 262         [AC_HELP_STRING([--enable-cgmanager], [enable cgmanager support [default=auto]])],
 263         [], [enable_cgmanager=auto])
 264
 265 if test "x$enable_cgmanager" = "xauto" ; then
 266         AC_CHECK_LIB([cgmanager],[cgmanager_create],[enable_cgmanager=yes],[enable_cgmanager=no],[-lnih -lnih-dbus -ldbus-1])
 267 fi
 268 AM_CONDITIONAL([ENABLE_CGMANAGER], [test "x$enable_cgmanager" = "xyes"])
 269
 270 AM_COND_IF([ENABLE_CGMANAGER],
 271         [PKG_CHECK_MODULES([CGMANAGER], [libcgmanager])
 272         PKG_CHECK_MODULES([NIH], [libnih >= 1.0.2])
 273         PKG_CHECK_MODULES([NIH_DBUS], [libnih-dbus >= 1.0.0])
 274         PKG_CHECK_MODULES([DBUS], [dbus-1 >= 1.2.16])
 275         ])
 276
 277 AC_MSG_CHECKING(for get_pid_cgroup_abs_sync)
 278 save_LIBS=$LIBS
 279 AC_SEARCH_LIBS([cgmanager_get_pid_cgroup_abs_sync], [cgmanager], [have_abs_cgroups=yes], [have_abs_cgroups=no], [-lnih -lnih-dbus -ldbus-1])
 280 LIBS=$save_LIBS
 281 if test "x$have_abs_cgroups" = "xyes"; then
 282         AC_DEFINE([HAVE_CGMANAGER_GET_PID_CGROUP_ABS_SYNC], 1, [Have cgmanager_get_pid_cgroup_abs_sync])
 283         AC_MSG_RESULT([yes])
 284 else
 285         AC_MSG_RESULT([no])
 286 fi
 287
 288 AC_MSG_CHECKING(for cgmanager_list_controllers)
 289 save_LIBS=$LIBS
 290 AC_SEARCH_LIBS([cgmanager_list_controllers_sync], [cgmanager], [have_list_controllers=yes], [have_list_controllers=no], [-lnih -lnih-dbus -ldbus-1])
 291 LIBS=$save_LIBS
 292 if test "x$have_list_controllers" = "xyes"; then
 293         AC_DEFINE([HAVE_CGMANAGER_LIST_CONTROLLERS], 1, [Have cgmanager_list_controllers])
 294         AC_MSG_RESULT([yes])
 295 else
 296         AC_MSG_RESULT([no])
 297 fi
 298
 299 # Check for static libcap, make sure the function checked for differs from the
 300 # the one checked below so the cache doesn't give a wrong answer
 301 OLD_CFLAGS="$CFLAGS"
 302 CFLAGS="$CFLAGS -static"
 303 AC_CHECK_LIB([cap],[cap_init],[have_static_libcap=yes],[have_static_libcap=no])
 304 AM_CONDITIONAL([HAVE_STATIC_LIBCAP], [test "x$have_static_libcap" = "xyes"])
 305 if test "x$have_static_libcap" = "xyes"; then
 306         AC_DEFINE([HAVE_STATIC_LIBCAP], 1, [Have static libcap])
 307 fi
 308 CFLAGS="$OLD_CFLAGS"
 309
 310
 311 # Linux capabilities
 312 AC_ARG_ENABLE([capabilities],
 313         [AC_HELP_STRING([--enable-capabilities], [enable kernel capabilities support [default=auto]])],
 314         [], [enable_capabilities=auto])
 315
 316 if test "x$enable_capabilities" = "xauto"; then
 317         AC_CHECK_LIB([cap],[cap_set_proc],[enable_capabilities=yes],[enable_capabilities=no])
 318 fi
 319 AM_CONDITIONAL([ENABLE_CAP], [test "x$enable_capabilities" = "xyes"])
 320
 321 AM_COND_IF([ENABLE_CAP],
 322         [AC_CHECK_LIB(cap,cap_set_proc,[true],[AC_MSG_ERROR([You are missing libcap support.])])
 323         AC_SUBST([CAP_LIBS], [-lcap])])
 324
 325 # HAVE_SCMP_FILTER_CTX=1 will tell us we have libseccomp api >= 1.0.0
 326 OLD_CFLAGS="$CFLAGS"
 327 CFLAGS="$CFLAGS $SECCOMP_CFLAGS"
 328 AC_CHECK_TYPES([scmp_filter_ctx], [], [], [[#include <seccomp.h>]])
 329 AC_CHECK_DECLS([seccomp_syscall_resolve_name_arch], [], [], [[#include <seccomp.h>]])
 330 CFLAGS="$OLD_CFLAGS"
 331
 332 # Configuration examples
 333 AC_ARG_ENABLE([examples],
 334         [AC_HELP_STRING([--enable-examples], [install examples [default=yes]])],
 335         [], [enable_examples=yes])
 336 AM_CONDITIONAL([ENABLE_EXAMPLES], [test "x$enable_examples" = "xyes"])
 337
 338 # Python3 module and scripts
 339 AC_ARG_ENABLE([python],
 340         [AC_HELP_STRING([--enable-python], [enable python binding [default=auto]])],
 341         [], [enable_python=auto])
 342
 343 if test "x$enable_python" = "xauto"; then
 344         PKG_CHECK_MODULES([PYTHONDEV], [python3 >= 3.2],[enable_python=yes],[enable_python=no])
 345         if test "$CC" = "clang"; then
 346                 enable_python=no
 347         fi
 348 fi
 349
 350 if test "x$enable_python" = "xyes" && test "$CC" = "clang"; then
 351         AC_MSG_ERROR([Python3 is incompatible with the clang compiler])
 352 fi
 353
 354 AM_CONDITIONAL([ENABLE_PYTHON], [test "x$enable_python" = "xyes"])
 355
 356 AM_COND_IF([ENABLE_PYTHON],
 357         [AM_PATH_PYTHON([3.2], [], [AC_MSG_ERROR([You must install python3])])
 358         PKG_CHECK_MODULES([PYTHONDEV], [python3 >= 3.2],[],[AC_MSG_ERROR([You must install python3-dev])])
 359         AC_DEFINE_UNQUOTED([ENABLE_PYTHON], 1, [Python3 is available])])
 360
 361 # Enable dumping stack traces
 362 AC_ARG_ENABLE([mutex-debugging],
 363         [AC_HELP_STRING([--enable-mutex-debugging], [Makes mutexes to report error and provide stack trace [default=no]])],
 364         [], [enable_mutex_debugging=no])
 365 AM_CONDITIONAL([MUTEX_DEBUGGING], [test "x$enable_mutex_debugging" = "xyes"])
 366
 367 AM_COND_IF([MUTEX_DEBUGGING],
 368         AC_DEFINE_UNQUOTED([MUTEX_DEBUGGING], 1, [Enabling mutex debugging]))
 369
 370 # Not in older autoconf versions
 371 # AS_VAR_COPY(DEST, SOURCE)
 372 # -------------------------
 373 # Set the polymorphic shell variable DEST to the contents of the polymorphic
 374 # shell variable SOURCE.
 375 m4_ifdef([AS_VAR_COPY], [],
 376 [AC_DEFUN([AS_VAR_COPY],
 377     [AS_LITERAL_IF([$1[]$2], [$1=$$2], [eval $1=\$$2])])
 378 ])
 379
 380 dnl PKG_CHECK_VAR was introduced with pkg-config 0.28
 381 m4_ifdef([PKG_CHECK_VAR], [],
 382 [AC_DEFUN([PKG_CHECK_VAR],
 383     [AC_REQUIRE([PKG_PROG_PKG_CONFIG])dnl
 384      AC_ARG_VAR([$1], [value of $3 for $2, overriding pkg-config])dnl
 385      _PKG_CONFIG([$1], [variable="][$3]["], [$2])
 386      AS_VAR_COPY([$1], [pkg_cv_][$1])
 387      AS_VAR_IF([$1], [""], [$5], [$4])dnl
 388     ])# PKG_CHECK_VAR
 389 ])
 390
 391 # Lua module and scripts
 392 AC_ARG_ENABLE([lua],
 393         [AC_HELP_STRING([--enable-lua], [enable lua binding [default=auto]])],
 394         [], [enable_lua=auto])
 395
 396 AC_ARG_WITH([lua-pc],
 397         [AS_HELP_STRING(
 398                 [--with-lua-pc=PKG],
 399                 [Specify pkg-config package name for lua]
 400         )], [], [with_lua_pc=no])
 401
 402 if test "x$enable_lua" = "xyes" -a "x$with_lua_pc" != "xno"; then
 403         # exit with error if not found
 404         PKG_CHECK_MODULES([LUA], [$with_lua_pc], [LUAPKGCONFIG=$with_lua_pc])
 405 fi
 406
 407 if test "x$enable_lua" = "xauto" -a "x$with_lua_pc" != "xno"; then
 408         PKG_CHECK_MODULES([LUA], [$with_lua_pc],
 409                 [LUAPKGCONFIG=$with_lua_pc
 410                 enable_lua=yes],
 411                 [enable_lua=no])
 412 fi
 413
 414 if test "x$enable_lua" != "xno"; then
 415         PKG_CHECK_MODULES([LUA], [lua], [LUAPKGCONFIG=lua],
 416                 [PKG_CHECK_MODULES([LUA], [lua5.2], [LUAPKGCONFIG=lua5.2],
 417                         [PKG_CHECK_MODULES([LUA], [lua5.1], [LUAPKGCONFIG=lua5.1],
 418                                 [AS_IF([test "x$enable_lua" = "xyes"],
 419                                         [AC_MSG_ERROR([Lua not found. Please use --with-lua-pc=PKG])],
 420                                         [enable_lua=no])]
 421                         )]
 422                 )])
 423         AS_IF([test "x$LUAPKGCONFIG" != "x"], [enable_lua=yes])
 424 fi
 425
 426 AM_CONDITIONAL([ENABLE_LUA],
 427         [test "x$enable_lua" = "xyes"])
 428
 429 AM_COND_IF([ENABLE_LUA],
 430         [AC_MSG_CHECKING([Lua version])
 431         PKG_CHECK_VAR([LUA_VERSION], [$LUAPKGCONFIG], [V],,
 432                 [PKG_CHECK_VAR([LUA_VERSION], [$LUAPKGCONFIG], [major_version])])
 433         AC_MSG_RESULT([$LUA_VERSION])
 434         AC_SUBST([LUA_LIBDIR], [$libdir/lua/$LUA_VERSION])
 435         AC_SUBST([LUA_SHAREDIR], [$datadir/lua/$LUA_VERSION])
 436         ])
 437
 438 # Optional bash integration
 439 AC_ARG_ENABLE([bash],
 440         [AC_HELP_STRING([--enable-bash], [build bash integration [default=yes]])],
 441         [], [enable_bash=yes])
 442 AM_CONDITIONAL([ENABLE_BASH], [test "x$enable_bash" = "xyes"])
 443
 444 # Optional test binaries
 445 AC_ARG_ENABLE([tests],
 446         [AC_HELP_STRING([--enable-tests], [build test/example binaries [default=no]])],
 447         [], [enable_tests=no])
 448 AM_CONDITIONAL([ENABLE_TESTS], [test "x$enable_tests" = "xyes"])
 449
 450 # Allow overriding the default runtime dir (/run)
 451 AC_ARG_WITH([runtime-path],
 452         [AC_HELP_STRING(
 453                 [--with-runtime-path=dir],
 454                 [runtime directory (default: /run)]
 455         )], [], [with_runtime_path=['/run']])
 456
 457 # LXC container path, where the containers are actually stored
 458 # This is overridden by an entry in the file called LXCCONF
 459 # (i.e. /etc/lxc/lxc.conf)
 460 AC_ARG_WITH([config-path],
 461         [AC_HELP_STRING(
 462                 [--with-config-path=dir],
 463                 [lxc configuration repository path]
 464         )], [], [with_config_path=['${localstatedir}/lib/lxc']])
 465
 466 # The path of the global lxc configuration file.
 467 AC_ARG_WITH([global-conf],
 468         [AC_HELP_STRING(
 469                 [--with-global-conf=dir],
 470                 [global lxc configuration file]
 471         )], [], [with_global_conf=['${sysconfdir}/lxc/lxc.conf']])
 472
 473 # The path of the userns network configuration file
 474 AC_ARG_WITH([usernic-conf],
 475         [AC_HELP_STRING(
 476                 [--with-usernic-conf],
 477                 [user network interface configuration file]
 478         )], [], [with_usernic_conf=['${sysconfdir}/lxc/lxc-usernet']])
 479
 480 # The path of the runtime usernic database
 481 AC_ARG_WITH([usernic-db],
 482         [AC_HELP_STRING(
 483                 [--with-usernic-db],
 484                 [lxc user nic database]
 485         )], [], [with_usernic_db=['${with_runtime_path}/lxc/nics']])
 486
 487 # Rootfs path, where the container mount structure is assembled
 488 AC_ARG_WITH([rootfs-path],
 489         [AC_HELP_STRING(
 490                 [--with-rootfs-path=dir],
 491                 [lxc rootfs mount point]
 492         )], [], [with_rootfs_path=['${libdir}/lxc/rootfs']])
 493
 494 # cgroup pattern specification
 495 AC_ARG_WITH([cgroup-pattern],
 496         [AC_HELP_STRING(
 497                 [--with-cgroup-pattern=pattern],
 498                 [pattern for container cgroups]
 499         )], [], [with_cgroup_pattern=['/lxc/%n']])
 500
 501 # Container log path.  By default, use $lxcpath.
 502 AC_MSG_CHECKING([Whether to place logfiles in container config path])
 503 AC_ARG_ENABLE([configpath-log],
 504         [AC_HELP_STRING([--enable-configpath-log], [use logfiles in config path [default=no]])],
 505         [], [enable_configpath_log=no])
 506 AC_MSG_RESULT([$enable_configpath_log])
 507 AM_CONDITIONAL([USE_CONFIGPATH_LOGS], [test "$enable_configpath_log" = "yes"])
 508
 509 if test "$enable_configpath_log" = "yes"; then
 510         default_log_path="${with_config_path}"
 511 else
 512         default_log_path="${localstatedir}/log/lxc"
 513 fi
 514
 515 AC_ARG_WITH([log-path],
 516         [AC_HELP_STRING(
 517                 [--with-log-path=dir],
 518                 [per container log path]
 519         )], [], [with_log_path=['${default_log_path}']])
 520
 521 # Expand some useful variables
 522 AS_AC_EXPAND(PREFIX, "$prefix")
 523 AS_AC_EXPAND(LIBDIR, "$libdir")
 524 AS_AC_EXPAND(BINDIR, "$bindir")
 525 AS_AC_EXPAND(SBINDIR, "$sbindir")
 526 AS_AC_EXPAND(LIBEXECDIR, "$libexecdir")
 527 AS_AC_EXPAND(INCLUDEDIR, "$includedir")
 528 AS_AC_EXPAND(SYSCONFDIR, "$sysconfdir")
 529 AS_AC_EXPAND(LXC_DEFAULT_CONFIG, "$sysconfdir/lxc/default.conf")
 530 AS_AC_EXPAND(DATADIR, "$datadir")
 531 AS_AC_EXPAND(LOCALSTATEDIR, "$localstatedir")
 532 AS_AC_EXPAND(DOCDIR, "$docdir")
 533 AS_AC_EXPAND(LXC_GENERATE_DATE, "$(date)")
 534 AS_AC_EXPAND(LXCPATH, "$with_config_path")
 535 AS_AC_EXPAND(LXC_GLOBAL_CONF, "$with_global_conf")
 536 AS_AC_EXPAND(LXC_USERNIC_CONF, "$with_usernic_conf")
 537 AS_AC_EXPAND(LXC_USERNIC_DB, "$with_usernic_db")
 538 AS_AC_EXPAND(LXC_DISTRO_SYSCONF, "$distrosysconf")
 539 AS_AC_EXPAND(LXCROOTFSMOUNT, "$with_rootfs_path")
 540 AS_AC_EXPAND(LXCTEMPLATEDIR, "$datadir/lxc/templates")
 541 AS_AC_EXPAND(LXCTEMPLATECONFIG, "$datadir/lxc/config")
 542 AS_AC_EXPAND(LXCHOOKDIR, "$datadir/lxc/hooks")
 543 AS_AC_EXPAND(LXCBINHOOKDIR, "$libexecdir/lxc/hooks")
 544 AS_AC_EXPAND(LXCINITDIR, "$libexecdir")
 545 AS_AC_EXPAND(LOGPATH, "$with_log_path")
 546 AS_AC_EXPAND(RUNTIME_PATH, "$with_runtime_path")
 547 AC_SUBST(DEFAULT_CGROUP_PATTERN, ["$with_cgroup_pattern"])
 548
 549 # We need the install path so criu knows where to reference the hook scripts.
 550 AC_DEFINE_UNQUOTED([DATADIR], "$DATADIR", ["Prefix for shared files."])
 551
 552 # Check for some standard kernel headers
 553 AC_CHECK_HEADERS([linux/unistd.h linux/netlink.h linux/genetlink.h],
 554                                 [],
 555                                 AC_MSG_ERROR([Please install the Linux kernel headers.]),
 556                                 [#include <sys/socket.h>])
 557
 558 # Check for alternate C libraries
 559 AC_MSG_CHECKING(for bionic libc)
 560 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 561         [[#ifndef __ANDROID__
 562 error: Not bionic!
 563 #endif]])],
 564         [is_bionic=yes],
 565         [is_bionic=no])
 566 if test "x$is_bionic" = "xyes"; then
 567         AC_DEFINE([IS_BIONIC], 1, [bionic libc])
 568         AC_MSG_RESULT([yes])
 569 else
 570         AC_MSG_RESULT([no])
 571 fi
 572 AM_CONDITIONAL([IS_BIONIC], [test "x$is_bionic" = "xyes"])
 573
 574 # Some systems lack PR_CAPBSET_DROP definition => HAVE_DECL_PR_CAPBSET_DROP
 575 AC_CHECK_DECLS([PR_CAPBSET_DROP], [], [], [#include <sys/prctl.h>])
 576
 577 # Check for some headers
 578 AC_CHECK_HEADERS([sys/signalfd.h pty.h ifaddrs.h sys/capability.h sys/personality.h utmpx.h sys/timerfd.h])
 579
 580 # Check for some syscalls functions
 581 AC_CHECK_FUNCS([setns pivot_root sethostname unshare rand_r confstr faccessat])
 582
 583 # Check for some functions
 584 AC_CHECK_LIB(pthread, main)
 585 AC_CHECK_FUNCS(pthread_atfork)
 586 AC_CHECK_FUNCS(statvfs)
 587 AC_CHECK_LIB(util, openpty)
 588 AC_CHECK_FUNCS([openpty hasmntopt setmntent endmntent utmpxname])
 589 AC_CHECK_FUNCS([getline],
 590         AM_CONDITIONAL(HAVE_GETLINE, true)
 591         AC_DEFINE(HAVE_GETLINE,1,[Have getline]),
 592         AM_CONDITIONAL(HAVE_GETLINE, false))
 593 AC_CHECK_FUNCS([getsubopt],
 594         AM_CONDITIONAL(HAVE_GETSUBOPT, true)
 595         AC_DEFINE(HAVE_GETSUBOPT,1,[Have getsubopt]),
 596         AM_CONDITIONAL(HAVE_GETSUBOPT, false))
 597 AC_CHECK_FUNCS([fgetln],
 598         AM_CONDITIONAL(HAVE_FGETLN, true)
 599         AC_DEFINE(HAVE_FGETLN,1,[Have fgetln]),
 600         AM_CONDITIONAL(HAVE_FGETLN, false))
 601
 602 # Check for some libraries
 603 AC_SEARCH_LIBS(sem_open, [rt pthread])
 604 AC_SEARCH_LIBS(clock_gettime, [rt])
 605
 606 # Check for some standard binaries
 607 AC_PROG_GCC_TRADITIONAL
 608 AC_PROG_SED
 609
 610 # See if we support thread-local storage.
 611 LXC_CHECK_TLS
 612
 613 if test "x$GCC" = "xyes"; then
 614         CFLAGS="$CFLAGS -Wall -Werror"
 615 fi
 616
 617 # Files requiring some variable expansion
 618 AC_CONFIG_FILES([
 619         Makefile
 620         lxc.pc
 621         lxc.spec
 622
 623         config/Makefile
 624         config/apparmor/Makefile
 625         config/selinux/Makefile
 626         config/bash/Makefile
 627         config/bash/lxc
 628         config/init/Makefile
 629         config/init/common/Makefile
 630         config/init/common/lxc-containers
 631         config/init/common/lxc-net
 632         config/init/systemd/Makefile
 633         config/init/systemd/lxc.service
 634         config/init/systemd/lxc@.service
 635         config/init/systemd/lxc-net.service
 636         config/init/sysvinit/Makefile
 637         config/init/sysvinit/lxc-containers
 638         config/init/sysvinit/lxc-net
 639         config/init/upstart/lxc-net.conf
 640         config/init/upstart/Makefile
 641         config/etc/Makefile
 642         config/templates/Makefile
 643         config/templates/archlinux.common.conf
 644         config/templates/archlinux.userns.conf
 645         config/templates/centos.common.conf
 646         config/templates/centos.userns.conf
 647         config/templates/common.conf
 648         config/templates/common.conf.d/Makefile
 649         config/templates/debian.common.conf
 650         config/templates/debian.userns.conf
 651         config/templates/fedora.common.conf
 652         config/templates/fedora.userns.conf
 653         config/templates/gentoo.common.conf
 654         config/templates/gentoo.moresecure.conf
 655         config/templates/gentoo.userns.conf
 656         config/templates/nesting.conf
 657         config/templates/opensuse.common.conf
 658         config/templates/opensuse.userns.conf
 659         config/templates/oracle.common.conf
 660         config/templates/oracle.userns.conf
 661         config/templates/plamo.common.conf
 662         config/templates/plamo.userns.conf
 663         config/templates/slackware.common.conf
 664         config/templates/slackware.userns.conf
 665         config/templates/ubuntu-cloud.common.conf
 666         config/templates/ubuntu-cloud.lucid.conf
 667         config/templates/ubuntu-cloud.userns.conf
 668         config/templates/ubuntu.common.conf
 669         config/templates/ubuntu.lucid.conf
 670         config/templates/ubuntu.userns.conf
 671         config/templates/openwrt.common.conf
 672         config/templates/userns.conf
 673         config/yum/Makefile
 674         config/sysconfig/Makefile
 675         config/sysconfig/lxc
 676
 677         doc/Makefile
 678         doc/api/Makefile
 679         doc/legacy/lxc-ls.sgml
 680         doc/lxc-attach.sgml
 681         doc/lxc-autostart.sgml
 682         doc/lxc-cgroup.sgml
 683         doc/lxc-checkconfig.sgml
 684         doc/lxc-checkpoint.sgml
 685         doc/lxc-clone.sgml
 686         doc/lxc-config.sgml
 687         doc/lxc-console.sgml
 688         doc/lxc-copy.sgml
 689         doc/lxc-create.sgml
 690         doc/lxc-destroy.sgml
 691         doc/lxc-device.sgml
 692         doc/lxc-execute.sgml
 693         doc/lxc-freeze.sgml
 694         doc/lxc-info.sgml
 695         doc/lxc-ls.sgml
 696         doc/lxc-monitor.sgml
 697         doc/lxc-snapshot.sgml
 698         doc/lxc-start-ephemeral.sgml
 699         doc/lxc-start.sgml
 700         doc/lxc-stop.sgml
 701         doc/lxc-top.sgml
 702         doc/lxc-unfreeze.sgml
 703         doc/lxc-unshare.sgml
 704         doc/lxc-user-nic.sgml
 705         doc/lxc-usernsexec.sgml
 706         doc/lxc-wait.sgml
 707
 708         doc/lxc.conf.sgml
 709         doc/lxc.container.conf.sgml
 710         doc/lxc.system.conf.sgml
 711         doc/lxc-usernet.sgml
 712         doc/lxc.sgml
 713         doc/common_options.sgml
 714         doc/see_also.sgml
 715
 716         doc/rootfs/Makefile
 717
 718         doc/examples/Makefile
 719         doc/examples/lxc-macvlan.conf
 720         doc/examples/lxc-vlan.conf
 721         doc/examples/lxc-no-netns.conf
 722         doc/examples/lxc-empty-netns.conf
 723         doc/examples/lxc-phys.conf
 724         doc/examples/lxc-veth.conf
 725         doc/examples/lxc-complex.conf
 726
 727         doc/ja/Makefile
 728         doc/ja/legacy/lxc-ls.sgml
 729         doc/ja/lxc-attach.sgml
 730         doc/ja/lxc-autostart.sgml
 731         doc/ja/lxc-cgroup.sgml
 732         doc/ja/lxc-checkconfig.sgml
 733         doc/ja/lxc-checkpoint.sgml
 734         doc/ja/lxc-clone.sgml
 735         doc/ja/lxc-config.sgml
 736         doc/ja/lxc-console.sgml
 737         doc/ja/lxc-copy.sgml
 738         doc/ja/lxc-create.sgml
 739         doc/ja/lxc-destroy.sgml
 740         doc/ja/lxc-device.sgml
 741         doc/ja/lxc-execute.sgml
 742         doc/ja/lxc-freeze.sgml
 743         doc/ja/lxc-info.sgml
 744         doc/ja/lxc-ls.sgml
 745         doc/ja/lxc-monitor.sgml
 746         doc/ja/lxc-snapshot.sgml
 747         doc/ja/lxc-start-ephemeral.sgml
 748         doc/ja/lxc-start.sgml
 749         doc/ja/lxc-stop.sgml
 750         doc/ja/lxc-top.sgml
 751         doc/ja/lxc-unfreeze.sgml
 752         doc/ja/lxc-unshare.sgml
 753         doc/ja/lxc-user-nic.sgml
 754         doc/ja/lxc-usernsexec.sgml
 755         doc/ja/lxc-wait.sgml
 756
 757         doc/ja/lxc.conf.sgml
 758         doc/ja/lxc.container.conf.sgml
 759         doc/ja/lxc.system.conf.sgml
 760         doc/ja/lxc-usernet.sgml
 761         doc/ja/lxc.sgml
 762         doc/ja/common_options.sgml
 763         doc/ja/see_also.sgml
 764
 765         doc/ko/Makefile
 766         doc/ko/legacy/lxc-ls.sgml
 767         doc/ko/lxc-attach.sgml
 768         doc/ko/lxc-autostart.sgml
 769         doc/ko/lxc-cgroup.sgml
 770         doc/ko/lxc-checkconfig.sgml
 771         doc/ko/lxc-checkpoint.sgml
 772         doc/ko/lxc-clone.sgml
 773         doc/ko/lxc-config.sgml
 774         doc/ko/lxc-console.sgml
 775         doc/ko/lxc-copy.sgml
 776         doc/ko/lxc-create.sgml
 777         doc/ko/lxc-destroy.sgml
 778         doc/ko/lxc-device.sgml
 779         doc/ko/lxc-execute.sgml
 780         doc/ko/lxc-freeze.sgml
 781         doc/ko/lxc-info.sgml
 782         doc/ko/lxc-ls.sgml
 783         doc/ko/lxc-monitor.sgml
 784         doc/ko/lxc-snapshot.sgml
 785         doc/ko/lxc-start-ephemeral.sgml
 786         doc/ko/lxc-start.sgml
 787         doc/ko/lxc-stop.sgml
 788         doc/ko/lxc-top.sgml
 789         doc/ko/lxc-unfreeze.sgml
 790         doc/ko/lxc-unshare.sgml
 791         doc/ko/lxc-user-nic.sgml
 792         doc/ko/lxc-usernsexec.sgml
 793         doc/ko/lxc-wait.sgml
 794
 795         doc/ko/lxc.conf.sgml
 796         doc/ko/lxc.container.conf.sgml
 797         doc/ko/lxc.system.conf.sgml
 798         doc/ko/lxc-usernet.sgml
 799         doc/ko/lxc.sgml
 800         doc/ko/common_options.sgml
 801         doc/ko/see_also.sgml
 802
 803         hooks/Makefile
 804
 805         templates/Makefile
 806         templates/lxc-alpine
 807         templates/lxc-altlinux
 808         templates/lxc-archlinux
 809         templates/lxc-busybox
 810         templates/lxc-centos
 811         templates/lxc-cirros
 812         templates/lxc-debian
 813         templates/lxc-download
 814         templates/lxc-fedora
 815         templates/lxc-gentoo
 816         templates/lxc-openmandriva
 817         templates/lxc-opensuse
 818         templates/lxc-oracle
 819         templates/lxc-plamo
 820         templates/lxc-slackware
 821         templates/lxc-sshd
 822         templates/lxc-ubuntu
 823         templates/lxc-ubuntu-cloud
 824
 825         src/Makefile
 826         src/lxc/Makefile
 827         src/lxc/lxc-checkconfig
 828         src/lxc/lxc-ls
 829         src/lxc/lxc-start-ephemeral
 830         src/lxc/legacy/lxc-ls
 831         src/lxc/lxc.functions
 832         src/lxc/version.h
 833         src/python-lxc/Makefile
 834         src/python-lxc/setup.py
 835
 836         src/lua-lxc/Makefile
 837
 838         src/tests/Makefile
 839         src/tests/lxc-test-usernic
 840 ])
 841 AC_CONFIG_COMMANDS([default],[[]],[[]])
 842 AC_OUTPUT
 843
 844 # Configuration overview
 845 cat << EOF
 846
 847 ----------------------------
 848 Environment:
 849  - compiler: $CC
 850  - distribution: $with_distro
 851  - init script type(s): $init_script
 852  - rpath: $enable_rpath
 853  - GnuTLS: $enable_gnutls
 854  - Bash integration: $enable_bash
 855
 856 Security features:
 857  - Apparmor: $enable_apparmor
 858  - Linux capabilities: $enable_capabilities
 859  - seccomp: $enable_seccomp
 860  - SELinux: $enable_selinux
 861  - cgmanager: $enable_cgmanager
 862
 863 Bindings:
 864  - lua: $enable_lua
 865  - python3: $enable_python
 866
 867 Documentation:
 868  - examples: $enable_examples
 869  - API documentation: $enable_api_docs
 870  - user documentation: $enable_doc
 871
 872 Debugging:
 873  - tests: $enable_tests
 874  - mutex debugging: $enable_mutex_debugging
 875
 876 Paths:
 877  - Logs in configpath: $enable_configpath_log
 878 EOF
 879
 880 if test "x$ac_cv_func_pthread_atfork" = "xno" ; then
 881 cat << EOF
 882
 883 WARNING: Threading not supported on your platform
 884
 885         You are compiling LXC for bionic target which lacks certain threading related functionality used by LXC API (like pthread_atfork).
 886         Please note that, because of the missing functionality, multithreaded usage of LXC API cause some problems.
 887 EOF
 888 fi