configure.ac

   1 #
   2 # Copyright (C) 2010-2019 Red Hat, Inc.  All rights reserved.
   3 #
   4 # Authors: Fabio M. Di Nitto <fabbione@kronosnet.org>
   5 #          Federico Simoncelli <fsimon@kronosnet.org>
   6 #
   7 # This software licensed under GPL-2.0+
   8 #
   9
  10 #                                               -*- Autoconf -*-
  11 # Process this file with autoconf to produce a configure script.
  12 #
  13
  14 AC_PREREQ([2.63])
  15 AC_INIT([kronosnet],
  16         m4_esyscmd([build-aux/git-version-gen .tarball-version .gitarchivever]),
  17         [devel@lists.kronosnet.org])
  18 # Don't let AC_PROC_CC (invoked by AC_USE_SYSTEM_EXTENSIONS) replace
  19 # undefined CFLAGS with -g -O2, overriding our special OPT_CFLAGS.
  20 : ${CFLAGS=""}
  21 AC_USE_SYSTEM_EXTENSIONS
  22 AM_INIT_AUTOMAKE([1.13 dist-bzip2 dist-xz color-tests -Wno-portability subdir-objects])
  23
  24 LT_PREREQ([2.2.6])
  25 # --enable-new-dtags: Use RUNPATH instead of RPATH.
  26 # It is necessary to have this done before libtool does linker detection.
  27 # See also: https://github.com/kronosnet/kronosnet/issues/107
  28 # --as-needed: Modern systems have builtin ceil() making -lm superfluous but
  29 # AC_SEARCH_LIBS can't detect this because it tests with a false prototype
  30 AX_CHECK_LINK_FLAG([-Wl,--enable-new-dtags],
  31                    [AM_LDFLAGS=-Wl,--enable-new-dtags],
  32                    [AC_MSG_ERROR(["Linker support for --enable-new-dtags is required"])])
  33 AX_CHECK_LINK_FLAG([-Wl,--as-needed], [AM_LDFLAGS="$AM_LDFLAGS -Wl,--as-needed"])
  34
  35 AC_SUBST([AM_LDFLAGS])
  36 saved_LDFLAGS="$LDFLAGS"
  37 LDFLAGS="$AM_LDFLAGS $LDFLAGS"
  38 LT_INIT
  39 LDFLAGS="$saved_LDFLAGS"
  40
  41 AC_CONFIG_MACRO_DIR([m4])
  42 AC_CONFIG_SRCDIR([kronosnetd/main.c])
  43 AC_CONFIG_HEADERS([config.h])
  44
  45 AC_CANONICAL_HOST
  46
  47 AC_LANG([C])
  48
  49 systemddir=${prefix}/lib/systemd/system
  50
  51 if test "$prefix" = "NONE"; then
  52         prefix="/usr"
  53         if test "$localstatedir" = "\${prefix}/var"; then
  54                 localstatedir="/var"
  55         fi
  56         if test "$sysconfdir" = "\${prefix}/etc"; then
  57                 sysconfdir="/etc"
  58         fi
  59         if test "$systemddir" = "NONE/lib/systemd/system"; then
  60                 systemddir=/lib/systemd/system
  61         fi
  62         if test "$libdir" = "\${exec_prefix}/lib"; then
  63                 if test -e /usr/lib64; then
  64                         libdir="/usr/lib64"
  65                 else
  66                         libdir="/usr/lib"
  67                 fi
  68         fi
  69 fi
  70
  71 AC_PROG_AWK
  72 AC_PROG_GREP
  73 AC_PROG_SED
  74 AC_PROG_CPP
  75 AC_PROG_CC
  76 AC_PROG_CC_C99
  77 if test "x$ac_cv_prog_cc_c99" = "xno"; then
  78         AC_MSG_ERROR(["C99 support is required"])
  79 fi
  80 AC_PROG_LN_S
  81 AC_PROG_INSTALL
  82 AC_PROG_MAKE_SET
  83 PKG_PROG_PKG_CONFIG
  84
  85 AC_CHECK_PROGS([VALGRIND_EXEC], [valgrind])
  86 AM_CONDITIONAL([HAS_VALGRIND], [test x$VALGRIND_EXEC != "x"])
  87
  88 AC_CHECK_PROGS([COVBUILD_EXEC], [cov-build])
  89 AM_CONDITIONAL([HAS_COVBUILD], [test x$COVBUILD_EXEC != "x"])
  90
  91 AC_CHECK_PROGS([COVANALYZE_EXEC], [cov-analyze])
  92 AM_CONDITIONAL([HAS_COVANALYZE], [test x$COVANALYZE_EXEC != "x"])
  93
  94 AC_CHECK_PROGS([COVFORMATERRORS_EXEC], [cov-format-errors])
  95 AM_CONDITIONAL([HAS_COVFORMATERRORS], [test x$COVFORMATERRORS_EXEC != "x"])
  96
  97 # KNET_OPTION_DEFINES(stem,type,detection code)
  98 # stem: enters name of option, Automake conditional and preprocessor define
  99 # type: compress or crypto, determines where the default comes from
 100 AC_DEFUN([KNET_OPTION_DEFINES],[
 101 AC_ARG_ENABLE([$2-$1],[AS_HELP_STRING([--disable-$2-$1],[disable libknet $1 support])],,
 102         [enable_$2_$1="$enable_$2_all"])
 103 AM_CONDITIONAL([BUILD_]m4_toupper([$2_$1]),[test "x$enable_$2_$1" = xyes])
 104 if test "x$enable_$2_$1" = xyes; then
 105         $3
 106 fi
 107 AC_DEFINE_UNQUOTED([WITH_]m4_toupper([$2_$1]), [`test "x$enable_$2_$1" != xyes; echo $?`], $1 $2 [built in])
 108 ])
 109
 110 AC_ARG_ENABLE([man],
 111         [AS_HELP_STRING([--disable-man],[disable man page creation])],,
 112         [ enable_man="yes" ])
 113 AM_CONDITIONAL([BUILD_MAN], [test x$enable_man = xyes])
 114
 115 AC_ARG_ENABLE([libknet-sctp],
 116         [AS_HELP_STRING([--disable-libknet-sctp],[disable libknet SCTP support])],,
 117         [ enable_libknet_sctp="yes" ])
 118 AM_CONDITIONAL([BUILD_SCTP], [test x$enable_libknet_sctp = xyes])
 119
 120 AC_ARG_ENABLE([crypto-all],
 121         [AS_HELP_STRING([--disable-crypto-all],[disable libknet all crypto modules support])],,
 122         [ enable_crypto_all="yes" ])
 123
 124 KNET_OPTION_DEFINES([nss],[crypto],[PKG_CHECK_MODULES([nss], [nss])])
 125 KNET_OPTION_DEFINES([openssl],[crypto],[
 126         PKG_CHECK_MODULES([openssl],[libcrypto < 1.1],
 127                           [AC_DEFINE_UNQUOTED([BUILDCRYPTOOPENSSL10], [1], [openssl 1.0 crypto])],
 128                           [PKG_CHECK_MODULES([openssl],[libcrypto >= 1.1],
 129                                              [AC_DEFINE_UNQUOTED([BUILDCRYPTOOPENSSL11], [1], [openssl 1.1 crypto])])])
 130 ])
 131
 132 AC_ARG_ENABLE([compress-all],
 133         [AS_HELP_STRING([--disable-compress-all],[disable libknet all compress modules support])],,
 134         [ enable_compress_all="yes" ])
 135
 136 KNET_OPTION_DEFINES([zstd],[compress],[PKG_CHECK_MODULES([libzstd], [libzstd])])
 137
 138 KNET_OPTION_DEFINES([zlib],[compress],[PKG_CHECK_MODULES([zlib], [zlib])])
 139 KNET_OPTION_DEFINES([lz4],[compress],[PKG_CHECK_MODULES([liblz4], [liblz4])])
 140 KNET_OPTION_DEFINES([lzo2],[compress],[
 141         PKG_CHECK_MODULES([lzo2], [lzo2],
 142                 [# work around broken pkg-config file in v2.10
 143                  AC_SUBST([lzo2_CFLAGS],[`echo $lzo2_CFLAGS | sed 's,/lzo *, ,'`])],
 144                 [AC_CHECK_HEADERS([lzo/lzo1x.h],
 145                         [AC_CHECK_LIB([lzo2], [lzo1x_decompress_safe],
 146                                 [AC_SUBST([lzo2_LIBS], [-llzo2])])],
 147                                 [AC_MSG_ERROR(["missing required lzo/lzo1x.h header"])])])
 148 ])
 149 KNET_OPTION_DEFINES([lzma],[compress],[PKG_CHECK_MODULES([liblzma], [liblzma])])
 150 KNET_OPTION_DEFINES([bzip2],[compress],[
 151         PKG_CHECK_MODULES([bzip2], [bzip2],,
 152                 [AC_CHECK_HEADERS([bzlib.h],
 153                         [AC_CHECK_LIB([bz2], [BZ2_bzBuffToBuffCompress],
 154                                 [AC_SUBST([bzip2_LIBS], [-lbz2])])],
 155                                 [AC_MSG_ERROR(["missing required bzlib.h"])])])
 156 ])
 157
 158 AC_ARG_ENABLE([install-tests],
 159         [AS_HELP_STRING([--enable-install-tests],[install tests])],,
 160         [ enable_install_tests="no" ])
 161 AM_CONDITIONAL([INSTALL_TESTS], [test x$enable_install_tests = xyes])
 162
 163 AC_ARG_ENABLE([poc],
 164         [AS_HELP_STRING([--enable-poc],[enable building poc code])],,
 165         [ enable_poc="no" ])
 166 AM_CONDITIONAL([BUILD_POC], [test x$enable_poc = xyes])
 167
 168 AC_ARG_ENABLE([kronosnetd],
 169         [AS_HELP_STRING([--enable-kronosnetd],[Kronosnetd support])],,
 170         [ enable_kronosnetd="no" ])
 171 AM_CONDITIONAL([BUILD_KRONOSNETD], [test x$enable_kronosnetd = xyes])
 172
 173 AC_ARG_ENABLE([runautogen],
 174         [AS_HELP_STRING([--enable-runautogen],[run autogen.sh])],,
 175         [ enable_runautogen="no" ])
 176 AM_CONDITIONAL([BUILD_RUNAUTOGEN], [test x$enable_runautogen = xyes])
 177
 178 override_rpm_debuginfo_option="yes"
 179 AC_ARG_ENABLE([rpm-debuginfo],
 180         [AS_HELP_STRING([--enable-rpm-debuginfo],[build debuginfo packages])],,
 181         [ enable_rpm_debuginfo="no", override_rpm_debuginfo_option="no" ])
 182 AM_CONDITIONAL([BUILD_RPM_DEBUGINFO], [test x$enable_rpm_debuginfo = xyes])
 183 AM_CONDITIONAL([OVERRIDE_RPM_DEBUGINFO], [test x$override_rpm_debuginfo_option = xyes])
 184
 185 AC_ARG_ENABLE([libnozzle],
 186         [AS_HELP_STRING([--enable-libnozzle],[libnozzle support])],,
 187         [ enable_libnozzle="yes" ])
 188
 189 if test "x$enable_kronosnetd" = xyes; then
 190         enable_libnozzle=yes
 191 fi
 192 AM_CONDITIONAL([BUILD_LIBNOZZLE], [test x$enable_libnozzle = xyes])
 193
 194 # Checks for libraries.
 195 AX_PTHREAD(,[AC_MSG_ERROR([POSIX threads support is required])])
 196 saved_LIBS="$LIBS"
 197 LIBS=
 198 AC_SEARCH_LIBS([ceil], [m], , [AC_MSG_ERROR([ceil not found])])
 199 AC_SUBST([m_LIBS], [$LIBS])
 200 LIBS=
 201 AC_SEARCH_LIBS([clock_gettime], [rt], , [AC_MSG_ERROR([clock_gettime not found])])
 202 AC_SUBST([rt_LIBS], [$LIBS])
 203 LIBS=
 204 AC_SEARCH_LIBS([dlopen], [dl dld], , [AC_MSG_ERROR([dlopen not found])])
 205 AC_SUBST([dl_LIBS], [$LIBS])
 206 LIBS="$saved_LIBS"
 207
 208 # Check RTLD_DI_ORIGIN (not decalred by musl. glibc has it as an enum so cannot use ifdef)
 209 AC_CHECK_DECL([RTLD_DI_ORIGIN], [AC_DEFINE([HAVE_RTLD_DI_ORIGIN], 1,
 210     [define when RTLD_DI_ORIGIN is declared])], ,[[#include <dlfcn.h>]])
 211
 212 # OS detection
 213
 214 AC_MSG_CHECKING([for os in ${host_os}])
 215 case "$host_os" in
 216         *linux*)
 217                 AC_DEFINE_UNQUOTED([KNET_LINUX], [1], [Compiling for Linux platform])
 218                 AC_MSG_RESULT([Linux])
 219                 ;;
 220         *bsd*)
 221                 AC_DEFINE_UNQUOTED([KNET_BSD], [1], [Compiling for BSD platform])
 222                 AC_MSG_RESULT([BSD])
 223                 ;;
 224         *)
 225                 AC_MSG_ERROR([Unsupported OS? hmmmm])
 226                 ;;
 227 esac
 228
 229 # Checks for header files.
 230 AC_CHECK_HEADERS([sys/epoll.h])
 231 AC_CHECK_FUNCS([kevent])
 232 # if neither sys/epoll.h nor kevent are present, we should fail.
 233
 234 if test "x$ac_cv_header_sys_epoll_h" = xno && test "x$ac_cv_func_kevent" = xno; then
 235         AC_MSG_ERROR([Both epoll and kevent unavailable on this OS])
 236 fi
 237
 238 if test "x$ac_cv_header_sys_epoll_h" = xyes && test "x$ac_cv_func_kevent" = xyes; then
 239         AC_MSG_ERROR([Both epoll and kevent available on this OS, please contact the maintainers to fix the code])
 240 fi
 241
 242 if test "x$enable_libknet_sctp" = xyes; then
 243         AC_CHECK_HEADERS([netinet/sctp.h],, [AC_MSG_ERROR(["missing required SCTP headers"])])
 244 fi
 245
 246 # Checks for typedefs, structures, and compiler characteristics.
 247 AC_C_INLINE
 248 AC_TYPE_PID_T
 249 AC_TYPE_SIZE_T
 250 AC_TYPE_SSIZE_T
 251 AC_TYPE_UINT8_T
 252 AC_TYPE_UINT16_T
 253 AC_TYPE_UINT32_T
 254 AC_TYPE_UINT64_T
 255 AC_TYPE_INT8_T
 256 AC_TYPE_INT16_T
 257 AC_TYPE_INT32_T
 258 AC_TYPE_INT64_T
 259
 260 if test "x$enable_man" = "xyes"; then
 261         AC_ARG_VAR([DOXYGEN], [override doxygen executable])
 262         AC_CHECK_PROGS([DOXYGEN], [doxygen], [no])
 263         if test "x$DOXYGEN" = xno; then
 264                 AC_MSG_ERROR(["Doxygen command not found"])
 265         fi
 266         # required by doxyxml to build man pages dynamically
 267         # Don't let AC_PROC_CC (invoked by AX_PROG_CC_FOR_BUILD) replace
 268         # undefined CFLAGS_FOR_BUILD with -g -O2, overriding our special OPT_CFLAGS.
 269         : ${CFLAGS_FOR_BUILD=""}
 270         AX_PROG_CC_FOR_BUILD
 271         saved_PKG_CONFIG="$PKG_CONFIG"
 272         saved_ac_cv_path_PKG_CONFIG="$ac_cv_path_PKG_CONFIG"
 273         unset PKG_CONFIG ac_cv_path_PKG_CONFIG
 274         AC_PATH_PROG([PKG_CONFIG], [pkg-config])
 275         PKG_CHECK_MODULES([libqb_BUILD], [libqb])
 276         PKG_CHECK_MODULES([libxml_BUILD], [libxml-2.0])
 277         PKG_CONFIG="$saved_PKG_CONFIG"
 278         ac_cv_path_PKG_CONFIG="$saved_ac_cv_path_PKG_CONFIG"
 279 fi
 280
 281 # checks for libnozzle
 282 if test "x$enable_libnozzle" = xyes; then
 283         if `echo $host_os | grep -q linux`; then
 284                 PKG_CHECK_MODULES([libnl], [libnl-3.0])
 285                 PKG_CHECK_MODULES([libnlroute], [libnl-route-3.0 >= 3.3], [],
 286                         [PKG_CHECK_MODULES([libnlroute], [libnl-route-3.0 < 3.3],
 287                                            [AC_DEFINE_UNQUOTED([LIBNL3_WORKAROUND], [1], [Enable libnl < 3.3 build workaround])], [])])
 288         fi
 289 fi
 290
 291 # checks for kronosnetd
 292 if test "x$enable_kronosnetd" = xyes; then
 293         AC_CHECK_HEADERS([security/pam_appl.h],
 294                          [AC_CHECK_LIB([pam], [pam_start],
 295                                        [AC_SUBST([pam_LIBS], [-lpam])],
 296                                        [AC_MSG_ERROR([Unable to find LinuxPAM devel files])])])
 297
 298         AC_CHECK_HEADERS([security/pam_misc.h],
 299                          [AC_CHECK_LIB([pam_misc], [misc_conv],
 300                                        [AC_SUBST([pam_misc_LIBS], [-lpam_misc])],
 301                                        [AC_MSG_ERROR([Unable to find LinuxPAM MISC devel files])])])
 302
 303         PKG_CHECK_MODULES([libqb], [libqb])
 304
 305         AC_CHECK_LIB([qb], [qb_log_thread_priority_set],
 306                      [have_qb_log_thread_priority_set="yes"],
 307                      [have_qb_log_thread_priority_set="no"])
 308         if test "x${have_qb_log_thread_priority_set}" = xyes; then
 309                 AC_DEFINE_UNQUOTED([HAVE_QB_LOG_THREAD_PRIORITY_SET], [1], [have qb_log_thread_priority_set])
 310         fi
 311 fi
 312
 313 # local options
 314 AC_ARG_ENABLE([debug],
 315         [AS_HELP_STRING([--enable-debug],[enable debug build])])
 316
 317 AC_ARG_WITH([testdir],
 318         [AS_HELP_STRING([--with-testdir=DIR],[path to /usr/lib../kronosnet/tests/ dir where to install the test suite])],
 319         [ TESTDIR="$withval" ],
 320         [ TESTDIR="$libdir/kronosnet/tests" ])
 321
 322 AC_ARG_WITH([initdefaultdir],
 323         [AS_HELP_STRING([--with-initdefaultdir=DIR],[path to /etc/sysconfig or /etc/default dir])],
 324         [ INITDEFAULTDIR="$withval" ],
 325         [ INITDEFAULTDIR="$sysconfdir/default" ])
 326
 327 AC_ARG_WITH([initddir],
 328         [AS_HELP_STRING([--with-initddir=DIR],[path to init script directory])],
 329         [ INITDDIR="$withval" ],
 330         [ INITDDIR="$sysconfdir/init.d" ])
 331
 332 AC_ARG_WITH([systemddir],
 333         [AS_HELP_STRING([--with-systemddir=DIR],[path to systemd unit files directory])],
 334         [ SYSTEMDDIR="$withval" ],
 335         [ SYSTEMDDIR="$systemddir" ])
 336
 337 AC_ARG_WITH([syslogfacility],
 338         [AS_HELP_STRING([--with-syslogfacility=FACILITY],[default syslog facility])],
 339         [ SYSLOGFACILITY="$withval" ],
 340         [ SYSLOGFACILITY="LOG_DAEMON" ])
 341
 342 AC_ARG_WITH([sysloglevel],
 343         [AS_HELP_STRING([--with-sysloglevel=LEVEL],[default syslog level])],
 344         [ SYSLOGLEVEL="$withval" ],
 345         [ SYSLOGLEVEL="LOG_INFO" ])
 346
 347 AC_ARG_WITH([defaultadmgroup],
 348         [AS_HELP_STRING([--with-defaultadmgroup=GROUP],
 349                 [define PAM group. Users part of this group will be allowed to configure
 350                  kronosnet. Others will only receive read-only rights.])],
 351         [ DEFAULTADMGROUP="$withval" ],
 352         [ DEFAULTADMGROUP="kronosnetadm" ])
 353
 354 ## random vars
 355 LOGDIR=${localstatedir}/log/
 356 RUNDIR=${localstatedir}/run/
 357 DEFAULT_CONFIG_DIR=${sysconfdir}/kronosnet
 358
 359 ## do subst
 360
 361 AC_SUBST([TESTDIR])
 362 AC_SUBST([DEFAULT_CONFIG_DIR])
 363 AC_SUBST([INITDEFAULTDIR])
 364 AC_SUBST([INITDDIR])
 365 AC_SUBST([SYSTEMDDIR])
 366 AC_SUBST([LOGDIR])
 367 AC_SUBST([DEFAULTADMGROUP])
 368
 369 AC_DEFINE_UNQUOTED([DEFAULT_CONFIG_DIR],
 370                    ["$(eval echo ${DEFAULT_CONFIG_DIR})"],
 371                    [Default config directory])
 372
 373 AC_DEFINE_UNQUOTED([DEFAULT_CONFIG_FILE],
 374                    ["$(eval echo ${DEFAULT_CONFIG_DIR}/kronosnetd.conf)"],
 375                    [Default config file])
 376
 377 AC_DEFINE_UNQUOTED([LOGDIR],
 378                    ["$(eval echo ${LOGDIR})"],
 379                    [Default logging directory])
 380
 381 AC_DEFINE_UNQUOTED([DEFAULT_LOG_FILE],
 382                    ["$(eval echo ${LOGDIR}/kronosnetd.log)"],
 383                    [Default log file])
 384
 385 AC_DEFINE_UNQUOTED([RUNDIR],
 386                    ["$(eval echo ${RUNDIR})"],
 387                    [Default run directory])
 388
 389 AC_DEFINE_UNQUOTED([SYSLOGFACILITY],
 390                    [$(eval echo ${SYSLOGFACILITY})],
 391                    [Default syslog facility])
 392
 393 AC_DEFINE_UNQUOTED([SYSLOGLEVEL],
 394                    [$(eval echo ${SYSLOGLEVEL})],
 395                    [Default syslog level])
 396
 397 AC_DEFINE_UNQUOTED([DEFAULTADMGROUP],
 398                    ["$(eval echo ${DEFAULTADMGROUP})"],
 399                    [Default admin group])
 400
 401 # debug build stuff
 402 if test "x${enable_debug}" = xyes; then
 403         AC_DEFINE_UNQUOTED([DEBUG], [1], [Compiling Debugging code])
 404         OPT_CFLAGS="-O0"
 405 else
 406         OPT_CFLAGS="-O3"
 407 fi
 408
 409 # gdb flags
 410 if test "x${GCC}" = xyes; then
 411         GDB_FLAGS="-ggdb3"
 412 else
 413         GDB_FLAGS="-g"
 414 fi
 415
 416 DEFAULT_CFLAGS="-Werror -Wall -Wextra"
 417
 418 # manual overrides
 419 # generates too much noise for stub APIs
 420 UNWANTED_CFLAGS="-Wno-unused-parameter"
 421
 422 AC_SUBST([AM_CFLAGS],["$OPT_CFLAGS $GDB_FLAGS $DEFAULT_CFLAGS $UNWANTED_CFLAGS"])
 423
 424 AX_PROG_DATE
 425 AS_IF([test "$ax_cv_prog_date_gnu_date:$ax_cv_prog_date_gnu_utc" = yes:yes],
 426         [UTC_DATE_AT="date -u -d@"],
 427         [AS_IF([test "x$ax_cv_prog_date_bsd_date" = xyes],
 428                 [UTC_DATE_AT="date -u -r"],
 429                 [AC_MSG_ERROR([date utility unable to convert epoch to UTC])])])
 430 AC_SUBST([UTC_DATE_AT])
 431
 432 AC_ARG_VAR([SOURCE_EPOCH],[last modification date of the source])
 433 AC_MSG_NOTICE([trying to determine source epoch])
 434 AC_MSG_CHECKING([for source epoch in \$SOURCE_EPOCH])
 435 AS_IF([test -n "$SOURCE_EPOCH"],
 436         [AC_MSG_RESULT([yes])],
 437         [AC_MSG_RESULT([no])
 438          AC_MSG_CHECKING([for source epoch in source_epoch file])
 439          AS_IF([test -e "$srcdir/source_epoch"],
 440                 [read SOURCE_EPOCH <"$srcdir/source_epoch"
 441                  AC_MSG_RESULT([yes])],
 442                 [AC_MSG_RESULT([no])
 443                  AC_MSG_CHECKING([for source epoch baked in by gitattributes export-subst])
 444                  SOURCE_EPOCH='$Format:%at$' # template for rewriting by git-archive
 445                  AS_CASE([$SOURCE_EPOCH],
 446                         [?Format:*], # was not rewritten
 447                                 [AC_MSG_RESULT([no])
 448                                  AC_MSG_CHECKING([for source epoch in \$SOURCE_DATE_EPOCH])
 449                                  AS_IF([test "x$SOURCE_DATE_EPOCH" != x],
 450                                         [SOURCE_EPOCH="$SOURCE_DATE_EPOCH"
 451                                          AC_MSG_RESULT([yes])],
 452                                         [AC_MSG_RESULT([no])
 453                                          AC_MSG_CHECKING([whether git log can provide a source epoch])
 454                                          SOURCE_EPOCH=f${SOURCE_EPOCH#\$F} # convert into git log --pretty format
 455                                          SOURCE_EPOCH=$(cd "$srcdir" && git log -1 --pretty=${SOURCE_EPOCH%$} 2>/dev/null)
 456                                          AS_IF([test -n "$SOURCE_EPOCH"],
 457                                                 [AC_MSG_RESULT([yes])],
 458                                                 [AC_MSG_RESULT([no, using current time and breaking reproducibility])
 459                                                  SOURCE_EPOCH=$(date +%s)])])],
 460                         [AC_MSG_RESULT([yes])]
 461                  )])
 462         ])
 463 AC_MSG_NOTICE([using source epoch $($UTC_DATE_AT$SOURCE_EPOCH +'%F %T %Z')])
 464
 465 AC_CONFIG_FILES([
 466                 Makefile
 467                 init/Makefile
 468                 libnozzle/Makefile
 469                 libnozzle/libnozzle.pc
 470                 libnozzle/tests/Makefile
 471                 kronosnetd/Makefile
 472                 kronosnetd/kronosnetd.logrotate
 473                 libknet/Makefile
 474                 libknet/libknet.pc
 475                 libknet/tests/Makefile
 476                 man/Makefile
 477                 man/Doxyfile-knet
 478                 man/Doxyfile-nozzle
 479                 poc-code/Makefile
 480                 poc-code/iov-hash/Makefile
 481                 ])
 482
 483 if test "x$VERSION" = "xUNKNOWN"; then
 484         AC_MSG_ERROR([m4_text_wrap([
 485   configure was unable to determine the source tree's current version. This
 486   generally happens when using git archive (or the github download button)
 487   generated tarball/zip file. In order to workaround this issue, either use git
 488   clone https://github.com/kronosnet/kronosnet.git or use an official release
 489   tarball, available at https://kronosnet.org/releases/.  Alternatively you
 490   can add a compatible version in a .tarball-version file at the top of the
 491   source tree, wipe your autom4te.cache dir and generated configure, and rerun
 492   autogen.sh.
 493   ], [  ], [   ], [76])])
 494 fi
 495
 496 AC_OUTPUT