configure.ac

   1 ##
   2 ## Configure template file for Quagga.
   3 ## autoconf will generate configure script.
   4 ##
   5 ##  Copyright (c) 1996, 97, 98, 99, 2000 Kunihiro Ishiguro <kunihiro@zebra.org>
   6 ##  Portions Copyright (c) 2003 Paul Jakma <paul@dishone.st>
   7 ##
   8 AC_PREREQ(2.60)
   9
  10 AC_INIT(Quagga, 0.99.24+cl3u3, [https://bugzilla.quagga.net])
  11 CONFIG_ARGS="$*"
  12 AC_SUBST(CONFIG_ARGS)
  13 AC_CONFIG_SRCDIR(lib/zebra.h)
  14 AC_CONFIG_MACRO_DIR([m4])
  15
  16 dnl -----------------------------------
  17 dnl Get hostname and other information.
  18 dnl -----------------------------------
  19 AC_CANONICAL_BUILD()
  20 AC_CANONICAL_HOST()
  21 AC_CANONICAL_TARGET()
  22
  23 AM_INIT_AUTOMAKE(1.6)
  24 AM_SILENT_RULES([yes])
  25 AC_CONFIG_HEADERS(config.h)
  26
  27 AC_PATH_PROG(PERL, perl)
  28 AC_CHECK_PROG([GAWK],[gawk],[gawk],[not-in-PATH])
  29 if test "x$GAWK" = "xnot-in-PATH" ; then
  30         AC_MSG_ERROR([GNU awk is required for lib/memtype.h made by memtypes.awk.
  31 BSD awk complains: awk: gensub doesn't support backreferences (subst "\1") ])
  32 fi
  33 AC_ARG_VAR([GAWK],[GNU AWK])
  34
  35 dnl default is to match previous behavior
  36 exampledir=${sysconfdir}
  37 AC_ARG_ENABLE([exampledir],
  38           AS_HELP_STRING([--enable-exampledir],
  39                          [specify alternate directory for examples]),
  40                          exampledir="$enableval",)
  41 dnl XXX add --exampledir to autoconf standard directory list somehow
  42 AC_SUBST(exampledir)
  43
  44 dnl default is to match previous behavior
  45 pkgsrcrcdir=""
  46 pkgsrcdir=""
  47 AC_ARG_ENABLE([pkgsrcrcdir],
  48           AS_HELP_STRING([--enable-pkgsrcrcdir],
  49                          [specify directory for rc.d scripts]),
  50                          pkgsrcrcdir="$enableval"; pkgsrcdir="pkgsrc",)
  51 dnl XXX add --pkgsrcrcdir to autoconf standard directory list somehow
  52 AC_SUBST(pkgsrcdir)
  53 AC_SUBST(pkgsrcrcdir)
  54
  55 dnl ------------
  56 dnl Check CFLAGS
  57 dnl ------------
  58 AC_ARG_WITH(cflags,
  59 [  --with-cflags           Set CFLAGS for use in compilation.])
  60 if test "x$with_cflags" != "x" ; then
  61   CFLAGS="$with_cflags" ; cflags_specified=yes ;
  62 elif test -n "$CFLAGS" ; then
  63   cflags_specified=yes ;
  64 fi
  65
  66 AC_ARG_ENABLE(tcmalloc,
  67 [  --enable-tcmalloc    Turn on tcmalloc],
  68 [case "${enableval}" in
  69   yes) tcmalloc_enabled=true
  70 LIBS="$LIBS -ltcmalloc_minimal"
  71  ;;
  72   no)  tcmalloc_enabled=false ;;
  73   *) AC_MSG_ERROR(bad value ${enableval} for --enable-tcmalloc) ;;
  74 esac],[tcmalloc_enabled=false])
  75
  76
  77 dnl --------------------
  78 dnl Check CC and friends
  79 dnl --------------------
  80 AC_LANG([C])
  81 AC_PROG_CC
  82 AC_PROG_CPP
  83 AM_PROG_CC_C_O
  84 AC_PROG_RANLIB
  85 AC_PROG_EGREP
  86
  87 dnl autoconf 2.59 appears not to support AC_PROG_SED
  88 dnl AC_PROG_SED
  89 AC_CHECK_PROG([SED],[sed],[sed],[/bin/false])
  90
  91 dnl pdflatex and latexmk are needed to build HACKING.pdf
  92 AC_CHECK_PROG([PDFLATEX],[pdflatex],[pdflatex],[/bin/false])
  93 AC_CHECK_PROG([LATEXMK],[latexmk],[latexmk],[/bin/false])
  94 if test "x$PDFLATEX" = "x/bin/false" -o "x$LATEXMK" = "x/bin/false"; then
  95         AC_MSG_WARN([Will not be able to make PDF versions of TeX documents])
  96 else
  97         HAVE_LATEX=true
  98 fi
  99 AM_CONDITIONAL([HAVE_LATEX], [test "x$HAVE_LATEX" = "xtrue"])
 100
 101 if test "x${GCC}" != "xyes" ; then
 102   AC_MSG_CHECKING([whether we are using SunPro compiler])
 103   AC_EGREP_CPP([^__SUNPRO_C.*0x5(7|8|9)], ["__SUNPRO_C" __SUNPRO_C],
 104       [AC_MSG_RESULT([no])],
 105       [COMPILER="SUNPRO"
 106        AC_MSG_RESULT([yes])]
 107   )
 108 fi
 109
 110 dnl ---------------------------------------------
 111 dnl If CLFAGS doesn\'t exist set default value
 112 dnl AC_PROG_CC will have set minimal default
 113 dnl already, eg "-O2 -g" for gcc, "-g" for others
 114 dnl (Wall is gcc specific... have to make sure
 115 dnl  gcc is being used before setting it)
 116 dnl
 117 dnl Sun Studio 10 / SunPro 5.7 is also supported,
 118 dnl so lets set some sane CFLAGS for it.
 119 dnl ---------------------------------------------
 120
 121 AC_USE_SYSTEM_EXTENSIONS()
 122 AC_DEFUN([AC_C_FLAG], [{
 123         AC_LANG_PUSH(C)
 124         ac_c_flag_save="$CFLAGS"
 125         CFLAGS="$CFLAGS $1"
 126         AC_MSG_CHECKING([[whether $CC supports $1]])
 127         AC_COMPILE_IFELSE(
 128                 [AC_LANG_PROGRAM([[]])],
 129                 [
 130                         AC_MSG_RESULT([yes])
 131                         m4_if([$3], [], [], [
 132                                 CFLAGS="$ac_c_flag_save"
 133                                 $3
 134                         ])
 135                 ], [
 136                         CFLAGS="$ac_c_flag_save"
 137                         AC_MSG_RESULT([no])
 138                         $2
 139                 ])
 140         AC_LANG_POP(C)
 141         }])
 142
 143 AC_MSG_CHECKING([whether to set a default CFLAGS])
 144 if test "x${cflags_specified}" = "x" ; then
 145   case ${COMPILER} in
 146     "SUNPRO")
 147         CFLAGS="-xO4 -v -g -xspace -xcode=pic32 -xstrconst -xc99"
 148         AC_MSG_RESULT([SunPro default])
 149         ;;
 150     *)
 151         AC_MSG_RESULT([autodetecting])
 152
 153         AC_C_FLAG([-diag-error 10006])
 154         AC_C_FLAG([-std=gnu99])
 155         AC_C_FLAG([-g])
 156         AC_C_FLAG([-Os], [
 157           AC_C_FLAG([-O2])
 158         ])
 159         AC_C_FLAG([-fno-omit-frame-pointer])
 160         AC_C_FLAG([-Wall])
 161         AC_C_FLAG([-Wextra])
 162         AC_C_FLAG([-Wmissing-prototypes])
 163         AC_C_FLAG([-Wmissing-declarations])
 164         AC_C_FLAG([-Wpointer-arith])
 165         AC_C_FLAG([-Wbad-function-cast])
 166         AC_C_FLAG([-Wwrite-strings])
 167         if test x"${enable_gcc_ultra_verbose}" = x"yes" ; then
 168           AC_C_FLAG([-Wcast-qual])
 169           AC_C_FLAG([-Wstrict-prototypes])
 170           AC_C_FLAG([-Wmissing-noreturn])
 171           AC_C_FLAG([-Wmissing-format-attribute])
 172           AC_C_FLAG([-Wunreachable-code])
 173           AC_C_FLAG([-Wpacked])
 174           AC_C_FLAG([-Wpadded])
 175         else
 176           AC_C_FLAG([-Wno-unused-result])
 177         fi
 178         AC_C_FLAG([-Wno-unused-parameter])
 179         AC_C_FLAG([-Wno-missing-field-initializers])
 180         # ICC emits a broken warning for const char *x = a ? "b" : "c";
 181         # for some reason the string consts get 'promoted' to char *,
 182         # triggering a const to non-const conversion warning.
 183         AC_C_FLAG([-diag-disable 3179])
 184         ;;
 185   esac
 186 else
 187   AC_MSG_RESULT([CFLAGS supplied by user])
 188 fi
 189
 190 if test x"${enable_werror}" = x"yes" ; then
 191   WERROR="-Werror"
 192 fi
 193 AC_SUBST(WERROR)
 194
 195 dnl --------------
 196 dnl Check programs
 197 dnl --------------
 198 AC_PROG_INSTALL
 199 AC_PROG_LN_S
 200 AC_PROG_MAKE_SET
 201 AC_CHECK_TOOL(AR, ar)
 202
 203 dnl ---------------------------
 204 dnl We, perhaps unfortunately,
 205 dnl depend on GNU Make specific
 206 dnl constructs.
 207 dnl Give the user a warning if
 208 dnl not GNU Make.
 209 dnl ---------------------------
 210 AC_CACHE_CHECK([if ${MAKE-make} is GNU make], [quagga_cv_gnu_make],
 211         [quagga_cv_gnu_make=no
 212          if ${MAKE-make} --version 2>/dev/null | \
 213                 grep '^GNU Make ' >/dev/null ; then
 214                 quagga_cv_gnu_make=yes;
 215          fi
 216         ]
 217 )
 218
 219 dnl -----------------
 220 dnl System extensions
 221 dnl -----------------
 222 AC_GNU_SOURCE
 223
 224 dnl -------
 225 dnl libtool
 226 dnl -------
 227 LT_INIT
 228
 229 dnl ----------------------
 230 dnl Packages configuration
 231 dnl ----------------------
 232 AC_ARG_WITH(pkg-extra-version,
 233         AS_HELP_STRING([--with-pkg-extra-version=VER], [add extra version field, for packagers/distributions]),
 234         [EXTRAVERSION=$withval],)
 235 AC_ARG_WITH(pkg-git-version,
 236         AS_HELP_STRING([--with-pkg-git-version], [add git information to MOTD and build version string]),
 237         [ test "x$withval" != "xno" && with_pkg_git_version="yes" ])
 238 AC_ARG_ENABLE(vtysh,
 239   AS_HELP_STRING([--disable-vtysh], [do not build integrated vty shell for Quagga]))
 240 AC_ARG_ENABLE(doc,
 241   AS_HELP_STRING([--disable-doc], [do not build docs]))
 242 AC_ARG_ENABLE(zebra,
 243   AS_HELP_STRING([--disable-zebra], [do not build zebra daemon]))
 244 AC_ARG_ENABLE(bgpd,
 245   AS_HELP_STRING([--disable-bgpd], [do not build bgpd]))
 246 AC_ARG_ENABLE(ripd,
 247   AS_HELP_STRING([--disable-ripd], [do not build ripd]))
 248 AC_ARG_ENABLE(ripngd,
 249   AS_HELP_STRING([--disable-ripngd], [do not build ripngd]))
 250 AC_ARG_ENABLE(ospfd,
 251   AS_HELP_STRING([--disable-ospfd], [do not build ospfd]))
 252 AC_ARG_ENABLE(ospf6d,
 253   AS_HELP_STRING([--disable-ospf6d], [do not build ospf6d]))
 254 AC_ARG_ENABLE(watchquagga,
 255   AS_HELP_STRING([--disable-watchquagga], [do not build watchquagga]))
 256 AC_ARG_ENABLE(isisd,
 257   AS_HELP_STRING([--disable-isisd], [do not build isisd]))
 258 AC_ARG_ENABLE(pimd,
 259   AS_HELP_STRING([--disable-pimd], [do not build pimd]))
 260 AC_ARG_ENABLE(bgp-announce,
 261   AS_HELP_STRING([--disable-bgp-announce,], [turn off BGP route announcement]))
 262 AC_ARG_ENABLE(snmp,
 263   AS_HELP_STRING([--enable-snmp=ARG], [enable SNMP support (smux or agentx)]))
 264 AC_ARG_WITH(libpam,
 265   AS_HELP_STRING([--with-libpam], [use libpam for PAM support in vtysh]))
 266 AC_ARG_ENABLE(tcp-zebra,
 267   AS_HELP_STRING([--enable-tcp-zebra], [enable TCP/IP socket connection between zebra and protocol daemon]))
 268 AC_ARG_ENABLE(ospfapi,
 269   AS_HELP_STRING([--disable-ospfapi], [do not build OSPFAPI to access the OSPF LSA Database]))
 270 AC_ARG_ENABLE(ospfclient,
 271   AS_HELP_STRING([--disable-ospfclient], [do not build OSPFAPI client for OSPFAPI,
 272                           (this is the default if --disable-ospfapi is set)]))
 273 AC_ARG_ENABLE(multipath,
 274   AS_HELP_STRING([--enable-multipath=ARG], [enable multipath function, ARG must be digit]))
 275 AC_ARG_ENABLE(user,
 276   AS_HELP_STRING([--enable-user=USER], [user to run Quagga suite as (default quagga)]))
 277 AC_ARG_ENABLE(group,
 278   AS_HELP_STRING([--enable-group=GROUP], [group to run Quagga suite as (default quagga)]))
 279 AC_ARG_ENABLE(vty_group,
 280   AS_HELP_STRING([--enable-vty-group=ARG], [set vty sockets to have specified group as owner]))
 281 AC_ARG_ENABLE(configfile_mask,
 282   AS_HELP_STRING([--enable-configfile-mask=ARG], [set mask for config files]))
 283 AC_ARG_ENABLE(logfile_mask,
 284   AS_HELP_STRING([--enable-logfile-mask=ARG], [set mask for log files]))
 285 AC_ARG_ENABLE(shell_access,
 286   AS_HELP_STRING([--enable-shell-access], [Allow users to access shell/telnet/ssh]))
 287 AC_ARG_ENABLE(rtadv,
 288   AS_HELP_STRING([--disable-rtadv], [disable IPV6 router advertisement feature]))
 289 AC_ARG_ENABLE(irdp,
 290   AS_HELP_STRING([--enable-irdp], [enable IRDP server support in zebra]))
 291 AC_ARG_ENABLE(isis_topology,
 292   AS_HELP_STRING([--enable-isis-topology], [enable IS-IS topology generator]))
 293 AC_ARG_ENABLE(capabilities,
 294   AS_HELP_STRING([--disable-capabilities], [disable using POSIX capabilities]))
 295 AC_ARG_ENABLE(rusage,
 296   AS_HELP_STRING([--disable-rusage], [disable using getrusage]))
 297 AC_ARG_ENABLE(gcc_ultra_verbose,
 298   AS_HELP_STRING([--enable-gcc-ultra-verbose], [enable ultra verbose GCC warnings]))
 299 AC_ARG_ENABLE(linux24_tcp_md5,
 300   AS_HELP_STRING([--enable-linux24-tcp-md5], [enable support for old, Linux-2.4 RFC2385 patch]))
 301 AC_ARG_ENABLE(gcc-rdynamic,
 302   AS_HELP_STRING([--enable-gcc-rdynamic], [enable linking with -rdynamic for better backtraces (default if gcc)]))
 303 AC_ARG_ENABLE(backtrace,
 304   AS_HELP_STRING([--disable-backtrace,], [disable crash backtraces (default autodetect)]))
 305 AC_ARG_ENABLE(time-check,
 306   AS_HELP_STRING([--disable-time-check], [disable slow thread warning messages]))
 307 AC_ARG_ENABLE(pcreposix,
 308   AS_HELP_STRING([--enable-pcreposix], [enable using PCRE Posix libs for regex functions]))
 309 AC_ARG_ENABLE(fpm,
 310   AS_HELP_STRING([--enable-fpm], [enable Forwarding Plane Manager support]))
 311 AC_ARG_ENABLE(systemd,
 312   AS_HELP_STRING([--enable-systemd], [enable Systemd support]))
 313 AC_ARG_ENABLE(poll,
 314   AS_HELP_STRING([--enable-poll], [enable usage of Poll instead of select]))
 315 AC_ARG_ENABLE(werror,
 316   AS_HELP_STRING([--enable-werror], [enable -Werror (recommended for developers only)]))
 317 AC_ARG_ENABLE(cumulus,
 318   AS_HELP_STRING([--enable-cumulus], [enable Cumulus Switch Special Extensions]))
 319 AC_ARG_ENABLE(rr-semantics,
 320   AS_HELP_STRING([--disable-rr-semantics], [disable the v6 Route Replace semantics]))
 321
 322 AC_CHECK_HEADERS(json-c/json.h)
 323 AC_CHECK_LIB(json-c, json_object_get, LIBS="$LIBS -ljson-c")
 324 if test $ac_cv_lib_json_c_json_object_get = no; then
 325   AC_CHECK_LIB(json, json_object_get, LIBS="$LIBS -ljson")
 326   if test $ac_cv_lib_json_json_object_get = no; then
 327       AC_MSG_ERROR([lib json is needed to compile])
 328   fi
 329 fi
 330
 331 if test x"${enable_gcc_rdynamic}" != x"no" ; then
 332   if test x"${enable_gcc_rdynamic}" = x"yes" -o x"$COMPILER" = x"GCC"; then
 333     LDFLAGS="${LDFLAGS} -rdynamic"
 334   fi
 335 fi
 336
 337 if test x"${enable_time_check}" != x"no" ; then
 338   if test x"${enable_time_check}" = x"yes" -o x"${enable_time_check}" = x ; then
 339     AC_DEFINE(CONSUMED_TIME_CHECK,5000000,Consumed Time Check)
 340   else
 341     AC_DEFINE_UNQUOTED(CONSUMED_TIME_CHECK,$enable_time_check,Consumed Time Check)
 342   fi
 343 fi
 344
 345 case "${enable_systemd}" in
 346   "no") ;;
 347   "yes")
 348   AC_CHECK_LIB(systemd, sd_notify, LIBS="$LIBS -lsystemd")
 349   if test $ac_cv_lib_systemd_sd_notify = no; then
 350     AC_MSG_ERROR([enable systemd has been specified but systemd development env not found on your system])
 351   else
 352     AC_DEFINE(HAVE_SYSTEMD,,Compile systemd support in)
 353   fi
 354   ;;
 355   "*") ;;
 356 esac
 357
 358 if test "${enable_rr_semantics}" != "no" ; then
 359   AC_DEFINE(HAVE_V6_RR_SEMANTICS,, Compile in v6 Route Replacement Semantics)
 360 fi
 361
 362 if test "${enable_poll}" = "yes" ; then
 363   AC_DEFINE(HAVE_POLL,,Compile systemd support in)
 364 fi
 365
 366 if test "${enable_cumulus}" = "yes" ; then
 367   AC_DEFINE(HAVE_CUMULUS,,Compile Special Cumulus Code in)
 368 fi
 369
 370 if test "${enable_shell_access}" = "yes"; then
 371    AC_DEFINE(HAVE_SHELL_ACCESS,,Allow user to use ssh/telnet/bash)
 372 fi
 373
 374 if test "${enable_fpm}" = "yes"; then
 375    AC_DEFINE(HAVE_FPM,,Forwarding Plane Manager support)
 376 fi
 377
 378 if test "${enable_tcp_zebra}" = "yes"; then
 379   AC_DEFINE(HAVE_TCP_ZEBRA,,Use TCP for zebra communication)
 380 fi
 381
 382 if test "${enable_linux24_tcp_md5}" = "yes"; then
 383   AC_DEFINE(HAVE_TCP_MD5_LINUX24,,Old Linux 2.4 TCP MD5 Signature Patch)
 384 fi
 385
 386 AC_MSG_CHECKING(if zebra should be configurable to send Route Advertisements)
 387 if test "${enable_rtadv}" != "no"; then
 388   AC_MSG_RESULT(yes)
 389   AC_DEFINE(HAVE_RTADV,,Enable IPv6 Routing Advertisement support)
 390 else
 391   AC_MSG_RESULT(no)
 392 fi
 393
 394 if test "${enable_irdp}" = "yes"; then
 395   AC_DEFINE(HAVE_IRDP,, IRDP )
 396 fi
 397
 398 if test "${enable_isisd}" != "no" && test "${enable_isis_topology}" = yes; then
 399   AC_DEFINE(TOPOLOGY_GENERATE,,Enable IS-IS topology generator code)
 400   ISIS_TOPOLOGY_INCLUDES="-I\$(srcdir)/topology"
 401   ISIS_TOPOLOGY_DIR="topology"
 402   ISIS_TOPOLOGY_LIB="./topology/libtopology.a"
 403 fi
 404
 405 AC_SUBST(ISIS_TOPOLOGY_INCLUDES)
 406 AC_SUBST(ISIS_TOPOLOGY_DIR)
 407 AC_SUBST(ISIS_TOPOLOGY_LIB)
 408
 409 if test x"${enable_user}" = x"no"; then
 410   enable_user=""
 411 else
 412   if test x"${enable_user}" = x"yes" || test x"${enable_user}" = x""; then
 413     enable_user="quagga"
 414   fi
 415   AC_DEFINE_UNQUOTED(QUAGGA_USER, "${enable_user}", Quagga User)
 416 fi
 417
 418 if test x"${enable_group}" = x"no"; then
 419   enable_group=""
 420 else
 421   if test x"${enable_group}" = x"yes" || test x"${enable_group}" = x""; then
 422     enable_group="quagga"
 423   fi
 424   AC_DEFINE_UNQUOTED(QUAGGA_GROUP, "${enable_group}", Quagga Group)
 425 fi
 426
 427 if test x"${enable_vty_group}" = x"yes" ; then
 428   AC_MSG_ERROR([--enable-vty-group requires a group as argument, not yes])
 429 elif test x"${enable_vty_group}" != x""; then
 430   if test x"${enable_vty_group}" != x"no"; then
 431     AC_DEFINE_UNQUOTED(VTY_GROUP, "${enable_vty_group}", VTY Sockets Group)
 432   fi
 433 fi
 434 AC_SUBST([enable_user])
 435 AC_SUBST([enable_group])
 436 AC_SUBST([enable_vty_group])
 437
 438 enable_configfile_mask=${enable_configfile_mask:-0600}
 439 AC_DEFINE_UNQUOTED(CONFIGFILE_MASK, ${enable_configfile_mask}, Mask for config files)
 440
 441 enable_logfile_mask=${enable_logfile_mask:-0600}
 442 AC_DEFINE_UNQUOTED(LOGFILE_MASK, ${enable_logfile_mask}, Mask for log files)
 443
 444 MPATH_NUM=1
 445
 446 case "${enable_multipath}" in
 447   0)
 448     MPATH_NUM=64
 449     ;;
 450   [[1-9]|[1-9][0-9]|[1-9][0-9][0-9]])
 451     MPATH_NUM="${enable_multipath}"
 452     ;;
 453   "")
 454     ;;
 455   *)
 456     AC_MSG_FAILURE([Please specify digit to enable multipath ARG])
 457     ;;
 458 esac
 459
 460 AC_DEFINE_UNQUOTED(MULTIPATH_NUM, $MPATH_NUM, Maximum number of paths for a route)
 461
 462 dnl -----------------------------------
 463 dnl Add extra version string to package
 464 dnl name, string and version fields.
 465 dnl -----------------------------------
 466 if test "x${EXTRAVERSION}" != "x" ; then
 467   VERSION="${VERSION}${EXTRAVERSION}"
 468   PACKAGE_VERSION="${PACKAGE_VERSION}${EXTRAVERSION}"
 469   PACKAGE_STRING="${PACKAGE_STRING}${EXTRAVERSION}"
 470 fi
 471
 472 if test "x$with_pkg_git_version" = "xyes"; then
 473         if test -d "${srcdir}/.git"; then
 474                 AC_DEFINE(GIT_VERSION, [1], [include git version info])
 475         else    with_pkg_git_version="no"
 476                 AC_MSG_WARN([--with-pkg-git-version given, but this is not a git checkout])
 477         fi
 478 fi
 479 AM_CONDITIONAL([GIT_VERSION], [test "x$with_pkg_git_version" = "xyes"])
 480
 481 dnl ------------------------------------
 482 dnl Check C keywords and standard  types
 483 dnl ------------------------------------
 484 AC_C_CONST
 485 AC_C_INLINE
 486 AC_C_RESTRICT
 487 AC_C_VOLATILE
 488 AC_HEADER_STDC
 489 AC_HEADER_TIME
 490 AC_HEADER_SYS_WAIT
 491 AC_HEADER_STDBOOL
 492 dnl AC_TYPE_PID_T
 493 AC_TYPE_UID_T
 494 AC_TYPE_MODE_T
 495 AC_TYPE_SIZE_T
 496 AC_STRUCT_TM
 497
 498 dnl -------------------------
 499 dnl Check other header files.
 500 dnl -------------------------
 501 AC_CHECK_HEADERS([stropts.h sys/ksym.h sys/times.h sys/select.h \
 502         sys/types.h linux/version.h netdb.h asm/types.h \
 503         sys/cdefs.h sys/param.h limits.h signal.h \
 504         sys/socket.h netinet/in.h time.h sys/time.h])
 505
 506 dnl Utility macro to avoid retyping includes all the time
 507 m4_define([QUAGGA_INCLUDES],
 508 [#ifdef SUNOS_5
 509 #define _XPG4_2
 510 #define __EXTENSIONS__
 511 #endif
 512 #include <stdio.h>
 513 #if STDC_HEADERS
 514 # include <stdlib.h>
 515 # include <stddef.h>
 516 #else
 517 # if HAVE_STDLIB_H
 518 #  include <stdlib.h>
 519 # endif
 520 #endif
 521 #if HAVE_SYS_TYPES_H
 522 # include <sys/types.h>
 523 #endif
 524 /* sys/conf.h depends on param.h on FBSD at least */
 525 #if HAVE_SYS_PARAM_H
 526 # include <sys/param.h>
 527 #endif
 528 /* Required for MAXSIG */
 529 #if HAVE_SIGNAL_H
 530 # include <signal.h>
 531 #endif
 532 #if HAVE_SYS_SOCKET_H
 533 # include <sys/socket.h>
 534 #endif
 535 #ifdef __APPLE__
 536 # define __APPLE_USE_RFC_3542
 537 #endif
 538 #if HAVE_NETINET_IN_H
 539 # include <netinet/in.h>
 540 #endif
 541 #ifdef TIME_WITH_SYS_TIME
 542 # include <sys/time.h>
 543 # include <time.h>
 544 #else
 545 # ifdef HAVE_SYS_TIME_H
 546 #  include <sys/time.h>
 547 # else
 548 #  include <time.h>
 549 # endif
 550 #endif /* TIME_WITH_SYS_TIME */
 551 ])dnl
 552
 553 dnl HAVE_NET_IF_H must be discovered by the time the longer AC_CHECK_HEADERS
 554 dnl round below execution begins, otherwise it doesn't properly detect
 555 dnl HAVE_NETINET6_IN6_VAR_H, HAVE_NET_IF_VAR_H and HAVE_STRUCT_IN6_ALIASREQ
 556 dnl on FreeBSD (BZ#408).
 557
 558 AC_CHECK_HEADERS([net/if.h], [], [], QUAGGA_INCLUDES)
 559
 560 m4_define([QUAGGA_INCLUDES],
 561 QUAGGA_INCLUDES
 562 [#if HAVE_NET_IF_H
 563 # include <net/if.h>
 564 #endif
 565 ])dnl
 566
 567 dnl Same applies for HAVE_NET_IF_VAR_H, which HAVE_NETINET6_ND6_H and
 568 dnl HAVE_NETINET_IN_VAR_H depend upon. But if_var.h depends on if.h, hence
 569 dnl an additional round for it.
 570
 571 AC_CHECK_HEADERS([net/if_var.h], [], [], QUAGGA_INCLUDES)
 572
 573 m4_define([QUAGGA_INCLUDES],
 574 QUAGGA_INCLUDES
 575 [#if HAVE_NET_IF_VAR_H
 576 # include <net/if_var.h>
 577 #endif
 578 ])dnl
 579
 580 AC_CHECK_HEADERS([sys/un.h netinet/in_systm.h netinet/in_var.h \
 581         net/if_dl.h net/netopt.h net/route.h \
 582         inet/nd.h arpa/inet.h netinet/ip_icmp.h \
 583         fcntl.h stddef.h sys/ioctl.h syslog.h wchar.h wctype.h \
 584         sys/sysctl.h sys/sockio.h kvm.h sys/conf.h],
 585         [], [], QUAGGA_INCLUDES)
 586
 587 AC_CHECK_HEADERS([ucontext.h], [], [],
 588 [#ifndef __USE_GNU
 589 #define __USE_GNU
 590 #endif /* __USE_GNU */
 591 QUAGGA_INCLUDES
 592 ])
 593
 594 m4_define([UCONTEXT_INCLUDES],
 595 [#include <ucontext.h>])dnl
 596
 597 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.uc_regs],
 598   [], [], [UCONTEXT_INCLUDES])
 599 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs],
 600   [AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs.nip],
 601    [], [], [UCONTEXT_INCLUDES])],
 602   [], [UCONTEXT_INCLUDES])
 603 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.gregs],
 604   [], [], [UCONTEXT_INCLUDES])
 605
 606 m4_define([QUAGGA_INCLUDES],
 607 QUAGGA_INCLUDES
 608 [#if HAVE_SYS_UN_H
 609 # include <sys/un.h>
 610 #endif
 611 #if HAVE_NETINET_IN_SYSTM_H
 612 # include <netinet/in_systm.h>
 613 #endif
 614 #if HAVE_NETINET_IN_VAR_H
 615 # include <netinet/in_var.h>
 616 #endif
 617 #if HAVE_NET_IF_DL_H
 618 # include <net/if_dl.h>
 619 #endif
 620 #if HAVE_NET_NETOPT_H
 621 # include <net/netopt.h>
 622 #endif
 623 #if HAVE_NET_ROUTE_H
 624 # include <net/route.h>
 625 #endif
 626 #if HAVE_INET_ND_H
 627 # include <inet/nd.h>
 628 #endif
 629 #if HAVE_ARPA_INET_H
 630 # include <arpa/inet.h>
 631 #endif
 632 /* Required for IDRP */
 633 #if HAVE_NETINET_IP_ICMP_H
 634 # include <netinet/ip_icmp.h>
 635 #endif
 636 ])dnl
 637
 638 dnl V6 headers are checked below, after we check for v6
 639
 640 dnl Some systems (Solaris 2.x) require libnsl (Network Services Library)
 641 case "$host" in
 642   [*-sunos5.[6-7]*] | [*-solaris2.[6-7]*])
 643       opsys=sol2-6
 644       AC_DEFINE(SUNOS_56, 1, SunOS 5.6 to 5.7)
 645       AC_DEFINE(SUNOS_5, 1, SunOS 5)
 646       AC_CHECK_LIB(xnet, main)
 647       CURSES=-lcurses
 648       SOLARIS="solaris"
 649   ;;
 650   [*-sunos5.[8-9]] \
 651   | [*-sunos5.1[0-9]] \
 652   | [*-sunos5.1[0-9].[0-9]] \
 653   | [*-solaris2.[8-9]] \
 654   | [*-solaris2.1[0-9]] \
 655   | [*-solaris2.1[0-9].[0-9]])
 656       opsys=sol8
 657       AC_DEFINE(SUNOS_59, 1, [SunOS 5.8 up])
 658       AC_DEFINE(SUNOS_5, 1, [SunOS 5])
 659       AC_CHECK_LIB(socket, main)
 660       AC_CHECK_LIB(nsl, main)
 661       AC_CHECK_LIB(umem, main)
 662       AC_CHECK_FUNCS([printstack],
 663         [AC_DEFINE([HAVE_PRINTSTACK],1,[Solaris printstack])
 664          AC_DEFINE([HAVE_STACK_TRACE],1,[Stack symbols decode functionality])
 665         ])
 666       CURSES=-lcurses
 667       SOLARIS="solaris"
 668   ;;
 669   *-sunos5* | *-solaris2*)
 670       AC_DEFINE(SUNOS_5,,SunOS 5, Unknown SunOS)
 671       AC_CHECK_LIB(socket, main)
 672       AC_CHECK_LIB(nsl, main)
 673       CURSES=-lcurses
 674       SOLARIS="solaris"
 675   ;;
 676   *-linux*)
 677       opsys=gnu-linux
 678       AC_DEFINE(GNU_LINUX,,GNU Linux)
 679   ;;
 680   *-openbsd*)
 681       opsys=openbsd
 682       AC_DEFINE(OPEN_BSD,,OpenBSD)
 683   ;;
 684 esac
 685
 686 AC_SYS_LARGEFILE
 687
 688 dnl ---------------------
 689 dnl Integrated VTY option
 690 dnl ---------------------
 691 case "${enable_vtysh}" in
 692   "no") VTYSH="";;
 693   *)    VTYSH="vtysh";
 694          AC_DEFINE(VTYSH,,VTY shell)
 695 dnl      Vtysh uses libreadline, which looks for termcap functions at
 696 dnl      configure time.  We follow readlines search order.
 697 dnl      The required procedures are in libtermcap on NetBSD, in
 698 dnl      [TODO] on Linux, and in [TODO] on Solaris.
 699          AC_CHECK_LIB(termcap, tputs, LIBREADLINE="$LIBREADLINE -ltermcap",
 700            [AC_CHECK_LIB(tinfo, tputs, LIBREADLINE="$LIBREADLINE -ltinfo",
 701              [AC_CHECK_LIB(curses, tputs, LIBREADLINE="$LIBREADLINE -lcurses",
 702                [AC_CHECK_LIB(ncurses, tputs,
 703                              LIBREADLINE="$LIBREADLINE -lncurses")]
 704               )]
 705             )]
 706           )
 707          AC_CHECK_LIB(readline, main, LIBREADLINE="-lreadline $LIBREADLINE",,
 708                       "$LIBREADLINE")
 709          if test $ac_cv_lib_readline_main = no; then
 710            AC_MSG_ERROR([vtysh needs libreadline but was not found and usable on your system.])
 711          fi
 712          AC_CHECK_HEADER(readline/history.h)
 713          if test $ac_cv_header_readline_history_h = no;then
 714            AC_MSG_ERROR([readline is too old to have readline/history.h, please update to the latest readline library.])
 715          fi
 716          AC_CHECK_LIB(readline, rl_completion_matches,
 717                       LIBREADLINE="$LIBREADLINE",, "$LIBREADLINE")
 718          if test $ac_cv_lib_readline_rl_completion_matches = no; then
 719            AC_DEFINE(rl_completion_matches,completion_matches,Old readline)
 720          fi
 721          ;;
 722 esac
 723 AC_SUBST(LIBREADLINE)
 724 AM_CONDITIONAL(VTYSH, test "x$VTYSH" = "xvtysh")
 725
 726 dnl ----------
 727 dnl PAM module
 728 dnl
 729 dnl Quagga detects the PAM library it is built against by checking for a
 730 dnl functional pam_misc.h (Linux-PAM) or openpam.h (OpenPAM) header. pam_misc.h
 731 dnl is known to #include pam_appl.h, the standard header of a PAM library, and
 732 dnl openpam.h doesn't do that, although depends on the header too. Hence a
 733 dnl little assistance to AC_CHECK_HEADER is necessary for the proper detection
 734 dnl of OpenPAM.
 735 dnl ----------
 736 if test "$with_libpam" = "yes"; then
 737   AC_CHECK_HEADER([security/pam_misc.h],
 738     [AC_DEFINE(HAVE_PAM_MISC_H,,Have pam_misc.h)
 739      AC_DEFINE(PAM_CONV_FUNC,misc_conv,Have misc_conv)
 740      pam_conv_func="misc_conv"
 741     ],
 742     [], QUAGGA_INCLUDES)
 743   AC_CHECK_HEADER([security/openpam.h],
 744     [AC_DEFINE(HAVE_OPENPAM_H,,Have openpam.h)
 745      AC_DEFINE(PAM_CONV_FUNC,openpam_ttyconv,Have openpam_ttyconv)
 746      pam_conv_func="openpam_ttyconv"
 747     ],
 748     [], QUAGGA_INCLUDES[#include <security/pam_appl.h>])
 749   if test -z "$ac_cv_header_security_pam_misc_h$ac_cv_header_security_openpam_h" ; then
 750     AC_MSG_WARN([*** pam support will not be built ***])
 751     with_libpam="no"
 752   fi
 753 fi
 754
 755 if test "$with_libpam" = "yes"; then
 756 dnl took this test from proftpds configure.in and suited to our needs
 757 dnl -------------------------------------------------------------------------
 758 dnl
 759 dnl This next check looks funky due to a linker problem with some versions
 760 dnl of the PAM library.  Prior to 0.72 release, the Linux PAM shared library
 761 dnl omitted requiring libdl linking information. PAM-0.72 or better ships
 762 dnl with RedHat 6.2 and Debian 2.2 or better.
 763 AC_CHECK_LIB(pam, pam_start,
 764   [AC_CHECK_LIB(pam, $pam_conv_func,
 765     [AC_DEFINE(USE_PAM,,Use PAM for authentication)
 766      LIBPAM="-lpam"],
 767     [AC_DEFINE(USE_PAM,,Use PAM for authentication)
 768      LIBPAM="-lpam -lpam_misc"]
 769     )
 770   ],
 771
 772   [AC_CHECK_LIB(pam, pam_end,
 773     [AC_CHECK_LIB(pam, $pam_conv_func,
 774       [AC_DEFINE(USE_PAM,,Use PAM for authentication)
 775        LIBPAM="-lpam -ldl"],
 776       [AC_DEFINE(USE_PAM,,Use PAM for authentication)
 777        LIBPAM="-lpam -ldl -lpam_misc"]
 778      )
 779   ],AC_MSG_WARN([*** pam support will not be built ***]),
 780   [-ldl])
 781   ]
 782 )
 783 fi
 784 AC_SUBST(LIBPAM)
 785
 786 dnl -------------------------------
 787 dnl Endian-ness check
 788 dnl -------------------------------
 789 AC_WORDS_BIGENDIAN
 790
 791 dnl -------------------------------
 792 dnl check the size in byte of the C
 793 dnl -------------------------------
 794 dnl AC_CHECK_SIZEOF(char)
 795 dnl AC_CHECK_SIZEOF(int)
 796 dnl AC_CHECK_SIZEOF(short)
 797 dnl AC_CHECK_SIZEOF(long)
 798
 799 dnl ----------------------------
 800 dnl check existance of functions
 801 dnl ----------------------------
 802 AC_FUNC_CHOWN
 803 AC_FUNC_FNMATCH
 804 AC_FUNC_FORK
 805 AC_FUNC_MEMCMP
 806 AC_FUNC_MKTIME
 807 AC_FUNC_STRFTIME
 808 AC_FUNC_STAT
 809 AC_FUNC_SELECT_ARGTYPES
 810 AC_FUNC_STRFTIME
 811 dnl Avoid AC_FUNC_STRNLEN because it pulls in AC_SYSTEM_EXTENSIONS which
 812 dnl can lead to strange side effects.  So we just check for strnlen
 813 dnl directly, see below.
 814 dnl AC_FUNC_STRNLENdnl
 815 AC_FUNC_VPRINTF
 816
 817 dnl -------------------------------
 818 dnl bgpd needs pow() and hence libm
 819 dnl -------------------------------
 820 TMPLIBS="$LIBS"
 821 AC_CHECK_HEADER([math.h],
 822   [AC_CHECK_LIB([m], [pow],
 823     [LIBM="-lm"
 824      LIBS="$LIBS $LIBM"
 825      AC_DEFINE(HAVE_LIBM,, Have libm)
 826      AC_CHECK_FUNCS(pow,[],[LIBM=""])
 827     ])
 828 ])
 829 if test x"$LIBM" = x ; then
 830   AC_MSG_WARN([Unable to find working pow function - bgpd may not link])
 831 fi
 832 LIBS="$TMPLIBS"
 833 AC_SUBST(LIBM)
 834
 835 dnl ---------------
 836 dnl other functions
 837 dnl ---------------
 838 AC_CHECK_FUNCS([dup2 ftruncate getcwd gethostbyname getpagesize gettimeofday \
 839         inet_ntoa inet_aton strnlen \
 840         memchr memmove memset select socket \
 841         strcasecmp strchr strcspn strdup strerror \
 842         strncasecmp strndup strrchr strspn strstr \
 843         strtol strtoul strlcat strlcpy \
 844         daemon snprintf vsnprintf \
 845         if_nametoindex if_indextoname getifaddrs \
 846         uname fcntl getgrouplist])
 847
 848 dnl ------------------------------------
 849 dnl Determine routing get and set method
 850 dnl ------------------------------------
 851 AC_MSG_CHECKING(zebra between kernel interface method)
 852 if test x"$opsys" = x"gnu-linux"; then
 853   AC_MSG_RESULT(netlink)
 854   RT_METHOD=rt_netlink.o
 855   AC_DEFINE(HAVE_NETLINK,,netlink)
 856   netlink=yes
 857   AC_CHECK_DECLS([IFLA_INFO_SLAVE_KIND], [], [], [#include <linux/if_link.h>])
 858 else
 859   AC_MSG_RESULT(Route socket)
 860   KERNEL_METHOD="kernel_socket.o"
 861   RT_METHOD="rt_socket.o"
 862 fi
 863 AC_SUBST(RT_METHOD)
 864 AC_SUBST(KERNEL_METHOD)
 865 AM_CONDITIONAL([HAVE_NETLINK], [test "x$netlink" = "xyes"])
 866
 867 dnl --------------------------
 868 dnl Determine IS-IS I/O method
 869 dnl --------------------------
 870 AC_DEFINE(ISIS_METHOD_PFPACKET, 1, [ constant value for isis method pfpacket ])
 871 AC_DEFINE(ISIS_METHOD_DLPI,     2, [ constant value for isis method dlpi ])
 872 AC_DEFINE(ISIS_METHOD_BPF,      3, [ constant value for isis method bpf ])
 873 AC_CHECK_HEADER(net/bpf.h)
 874 AC_CHECK_HEADER(sys/dlpi.h)
 875 AC_MSG_CHECKING(zebra IS-IS I/O method)
 876 if test x"$opsys" = x"gnu-linux"; then
 877   AC_MSG_RESULT(pfpacket)
 878   ISIS_METHOD_MACRO="ISIS_METHOD_PFPACKET"
 879 elif test x"$opsys" = x"sol2-6" -o x"$opsys" = x"sol8"; then
 880   AC_MSG_RESULT(DLPI)
 881   ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
 882 else
 883   if test $ac_cv_header_net_bpf_h = no; then
 884     if test $ac_cv_header_sys_dlpi_h = no; then
 885       AC_MSG_RESULT(none)
 886       AC_MSG_WARN([*** IS-IS support will not be built ***])
 887       ISISD=""
 888     else
 889       AC_MSG_RESULT(DLPI)
 890     fi
 891     ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
 892   else
 893     AC_MSG_RESULT(BPF)
 894     ISIS_METHOD_MACRO="ISIS_METHOD_BPF"
 895   fi
 896 fi
 897 AC_DEFINE_UNQUOTED(ISIS_METHOD, $ISIS_METHOD_MACRO, [ selected method for isis, == one of the constants ])
 898
 899 dnl ------------------------------------
 900 dnl check for broken CMSG_FIRSTHDR macro
 901 dnl ------------------------------------
 902 AC_MSG_CHECKING(for broken CMSG_FIRSTHDR)
 903 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 904 #ifdef SUNOS_5
 905 #define _XPG4_2
 906 #define __EXTENSIONS__
 907 #endif
 908 #ifdef HAVE_STDLIB_H
 909 # include <stdlib.h>
 910 #endif
 911 #ifdef HAVE_SYS_TYPES_H
 912 #include <sys/types.h>
 913 #endif
 914 #ifdef HAVE_SYS_SOCKET_H
 915 #include <sys/socket.h>
 916 #endif
 917
 918 main()
 919 {
 920   struct msghdr msg;
 921   char buf[4];
 922
 923   msg.msg_control = buf;
 924   msg.msg_controllen = 0;
 925
 926   if (CMSG_FIRSTHDR(&msg) != NULL)
 927     exit(0);
 928   exit (1);
 929 }]])],[AC_MSG_RESULT(yes - using workaround) AC_DEFINE(HAVE_BROKEN_CMSG_FIRSTHDR,,Broken CMSG_FIRSTHDR)],
 930 [AC_MSG_RESULT(no)],[AC_MSG_RESULT(no)])
 931
 932 dnl ------------------------------
 933 dnl check kernel route read method
 934 dnl ------------------------------
 935 AC_CACHE_CHECK([route read method], [quagga_cv_rtread_method],
 936 [if test "x$netlink" = xyes; then
 937   quagga_cv_rtread_method="netlink"
 938 else
 939 for quagga_cv_rtread_method in /dev/ip /dev/null;
 940 do
 941   test x`ls $quagga_cv_rtread_method 2>/dev/null` = x"$quagga_cv_rtread_method" && break
 942 done
 943 case $quagga_cv_rtread_method in
 944   "/dev/ip")
 945                      case "$host" in
 946                        *-freebsd*)    quagga_cv_rtread_method="sysctl";;
 947                        *)             quagga_cv_rtread_method="getmsg";;
 948                      esac;;
 949         *)
 950                      quagga_cv_rtread_method="sysctl";;
 951 esac
 952 fi])
 953 RTREAD_METHOD=rtread_${quagga_cv_rtread_method}.o
 954 AC_SUBST(RTREAD_METHOD)
 955
 956 dnl -----------------------------
 957 dnl check interface lookup method
 958 dnl -----------------------------
 959 IOCTL_METHOD=ioctl.o
 960 AC_MSG_CHECKING(interface looking up method)
 961 if test "$netlink" = yes; then
 962   AC_MSG_RESULT(netlink)
 963   IF_METHOD=if_netlink.o
 964 elif test "$opsys" = "sol2-6";then
 965   AC_MSG_RESULT(Solaris GIF)
 966   IF_METHOD=if_ioctl.o
 967 elif test "$opsys" = "sol8";then
 968   AC_MSG_RESULT(Solaris GLIF)
 969   IF_METHOD=if_ioctl_solaris.o
 970   IOCTL_METHOD=ioctl_solaris.o
 971 elif test "$opsys" = "openbsd";then
 972   AC_MSG_RESULT(openbsd)
 973   IF_METHOD=if_ioctl.o
 974 elif grep NET_RT_IFLIST /usr/include/sys/socket.h >/dev/null 2>&1; then
 975   AC_MSG_RESULT(sysctl)
 976     IF_METHOD=if_sysctl.o
 977     AC_DEFINE(HAVE_NET_RT_IFLIST,,NET_RT_IFLIST)
 978 else
 979     AC_MSG_RESULT(ioctl)
 980     IF_METHOD=if_ioctl.o
 981 fi
 982 AC_SUBST(IF_METHOD)
 983 AC_SUBST(IOCTL_METHOD)
 984
 985 dnl ---------------------------------------------------------------
 986 dnl figure out how to specify an interface in multicast sockets API
 987 dnl ---------------------------------------------------------------
 988 AC_CHECK_MEMBERS([struct ip_mreqn.imr_ifindex], [], [], QUAGGA_INCLUDES)
 989
 990 AC_CHECK_HEADERS([linux/mroute.h], [], [],[
 991         #ifdef HAVE_SYS_SOCKET_H
 992         # include <sys/socket.h>
 993         #endif
 994         #ifdef HAVE_NETINET_IN_H
 995         # include <netinet/in.h>
 996         #endif
 997         #define _LINUX_IN_H             /* For Linux <= 2.6.25 */
 998         #include <linux/types.h>
 999 ])
1000
1001 m4_define([QUAGGA_INCLUDES],
1002 QUAGGA_INCLUDES
1003 [#if HAVE_LINUX_MROUTE_H
1004 # include <linux/mroute.h>
1005 #endif
1006 ])dnl
1007
1008 AC_CHECK_HEADERS([netinet/ip_mroute.h], [], [],[
1009         #ifdef HAVE_SYS_SOCKET_H
1010         # include <sys/socket.h>
1011         #endif
1012         #ifdef HAVE_SYS_TYPES_H
1013         # include <sys/types.h>
1014         #endif
1015         #ifdef HAVE_NETINET_IN_H
1016         # include <netinet/in.h>
1017         #endif
1018         #ifdef HAVE_NET_ROUTE_H
1019         # include <net/route.h>
1020         #endif
1021 ])
1022
1023 m4_define([QUAGGA_INCLUDES],
1024 QUAGGA_INCLUDES
1025 [#if HAVE_NETINET_IP_MROUTE_H
1026 # include <netinet/ip_mroute.h>
1027 #endif
1028 ])dnl
1029
1030 AC_MSG_CHECKING([for BSD struct ip_mreq hack])
1031 AC_TRY_COMPILE([#ifdef HAVE_SYS_PARAM_H
1032 #include <sys/param.h>
1033 #endif],[#if (defined(__FreeBSD__) && ((__FreeBSD_version >= 500022 && __FreeBSD_version < 700000) || (__FreeBSD_version < 500000 && __FreeBSD_version >= 440000))) || (defined(__NetBSD__) && defined(__NetBSD_Version__) && __NetBSD_Version__ >= 106010000) || defined(__OpenBSD__) || defined(__APPLE__) || defined(__DragonFly__) || defined(__sun)
1034   return (0);
1035 #else
1036   #error No support for BSD struct ip_mreq hack detected
1037 #endif],[AC_MSG_RESULT(yes)
1038 AC_DEFINE(HAVE_BSD_STRUCT_IP_MREQ_HACK,,[Can pass ifindex in struct ip_mreq])],
1039 AC_MSG_RESULT(no))
1040
1041 AC_MSG_CHECKING([for RFC3678 protocol-independed API])
1042 AC_TRY_COMPILE([
1043 #include <sys/types.h>
1044 #include <netinet/in.h>
1045 ], [struct group_req gr; int sock; setsockopt(sock, IPPROTO_IP, MCAST_JOIN_GROUP, (void*)&gr, sizeof(gr));
1046 ], [AC_MSG_RESULT(yes)
1047 AC_DEFINE(HAVE_RFC3678,1,[Have RFC3678 protocol-independed API])],
1048 AC_MSG_RESULT(no))
1049
1050 dnl ---------------------------------------------------------------
1051 dnl figure out how to check link-state
1052 dnl ---------------------------------------------------------------
1053 AC_CHECK_HEADER([net/if.h],
1054   [AC_CHECK_HEADER( [net/if_media.h],
1055     [m4_define([LINK_DETECT_INCLUDES],
1056       QUAGGA_INCLUDES
1057       [#include <net/if_media.h>
1058     ])
1059     AC_CHECK_MEMBERS( [struct ifmediareq.ifm_status],
1060       AC_DEFINE(HAVE_BSD_LINK_DETECT,,[BSD link-detect]),
1061       [], LINK_DETECT_INCLUDES)],
1062     [],
1063     QUAGGA_INCLUDES)],
1064   [], QUAGGA_INCLUDES )
1065
1066 dnl ---------------------------------------------------------------
1067 dnl Additional, newer way to check link-state using ifi_link_state.
1068 dnl Not available in all BSD's when ifmediareq available
1069 dnl ---------------------------------------------------------------
1070 AC_CHECK_HEADER([net/if.h],
1071     AC_CHECK_MEMBERS([struct if_data.ifi_link_state],
1072       AC_DEFINE(HAVE_BSD_IFI_LINK_STATE,,[BSD ifi_link_state available]),
1073       [], QUAGGA_INCLUDES),
1074     ,)
1075
1076 dnl ------------------------
1077 dnl TCP_MD5SIG socket option
1078 dnl ------------------------
1079
1080 AC_CHECK_HEADER([netinet/tcp.h],
1081    [m4_define([MD5_INCLUDES],
1082       QUAGGA_INCLUDES
1083       [#include <netinet/tcp.h>
1084     ])
1085     AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)],
1086    [],
1087    QUAGGA_INCLUDES)
1088 if test $ac_cv_have_decl_TCP_MD5SIG = no; then
1089   AC_CHECK_HEADER([linux/tcp.h],
1090        [m4_define([MD5_INCLUDES],
1091           QUAGGA_INCLUDES
1092           [#include <linux/tcp.h>
1093         ])
1094        AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)])
1095 fi
1096
1097 dnl -----------------------------
1098 dnl check ipforward detect method
1099 dnl -----------------------------
1100 AC_CACHE_CHECK([ipforward method], [quagga_cv_ipforward_method],
1101 [if test x$cross_compiling = xyes; then
1102   if test x"$opsys" = x"gnu-linux"; then
1103     quagga_cv_ipforward_method=/proc/net/snmp
1104   else
1105     quagga_cv_ipforward_method=/dev/ip
1106   fi
1107 else
1108   for quagga_cv_ipforward_method in /proc/net/snmp /dev/ip /dev/null;
1109   do
1110     test x`ls $quagga_cv_ipforward_method 2>/dev/null` = x"$quagga_cv_ipforward_method" && break
1111   done
1112 fi
1113 case $quagga_cv_ipforward_method in
1114   "/proc/net/snmp")  quagga_cv_ipforward_method="proc";;
1115   "/dev/ip")
1116                      case "$host" in
1117                        *-freebsd*)    quagga_cv_ipforward_method="sysctl";;
1118                        *)             quagga_cv_ipforward_method="solaris";;
1119                      esac;;
1120   *)                 quagga_cv_ipforward_method="sysctl";;
1121 esac])
1122 IPFORWARD=ipforward_${quagga_cv_ipforward_method}.o
1123 AC_SUBST(IPFORWARD)
1124
1125 AC_CHECK_FUNCS(getaddrinfo, [have_getaddrinfo=yes], [have_getaddrinfo=no])
1126
1127 dnl ----------------------------------------------------------------------------
1128 dnl figure out if domainname is available in the utsname struct (GNU extension).
1129 dnl ----------------------------------------------------------------------------
1130 AC_CHECK_MEMBERS([struct utsname.domainname], [], [], [#include <sys/utsname.h>])
1131
1132 dnl ----------
1133 dnl IPv6 check
1134 dnl ----------
1135 AC_MSG_CHECKING(whether does this OS have IPv6 stack)
1136 dnl ---------
1137 dnl KAME IPv6
1138 dnl ---------
1139   if grep WIDE /usr/include/netinet6/in6.h >/dev/null 2>&1; then
1140     AC_DEFINE(KAME,1,KAME IPv6)
1141     AC_MSG_RESULT(KAME)
1142 dnl ------------------------------------
1143 dnl Solaris 9, 10 and potentially higher
1144 dnl ------------------------------------
1145   elif test x"$opsys" = x"sol8"; then
1146     AC_DEFINE(SOLARIS_IPV6, 1, Solaris IPv6)
1147     AC_MSG_RESULT(Solaris IPv6)
1148 dnl ----------
1149 dnl Linux IPv6
1150 dnl ----------
1151   elif test x"$opsys" = x"gnu-linux"; then
1152     AC_DEFINE(LINUX_IPV6,1,Linux IPv6 stack)
1153     dnl Linux has a compilation problem with mixing
1154     dnl netinet/in.h and linux/in6.h they are not
1155     dnl compatible.  There has been discussion on
1156     dnl how to fix it but no real progress on implementation
1157     dnl when they fix it, remove this
1158     AC_DEFINE(IPV6_MINHOPCOUNT, 73, Linux ipv6 Min Hop Count)
1159     AC_MSG_RESULT(Linux IPv6)
1160   else
1161     AC_MSG_ERROR([Failed to detect IPv6 stack])
1162   fi
1163
1164 dnl this is unconditial, for compatibility
1165 AC_DEFINE(HAVE_IPV6,1,IPv6)
1166
1167 dnl ------------------
1168 dnl IPv6 header checks
1169 dnl ------------------
1170 AC_CHECK_HEADERS([netinet6/in6.h netinet/in6_var.h netinet/icmp6.h \
1171         netinet6/in6_var.h netinet6/nd6.h], [], [],
1172         QUAGGA_INCLUDES)
1173
1174 m4_define([QUAGGA_INCLUDES],dnl
1175 QUAGGA_INCLUDES
1176 [#if HAVE_NETINET6_IN6_H
1177 #include <netinet6/in6.h>
1178 #endif
1179 #if HAVE_NETINET_IN6_VAR_H
1180 #include <netinet/in6_var.h>
1181 #endif
1182 #if HAVE_NETINET_ICMP6_H
1183 # include <netinet/icmp6.h>
1184 #endif
1185 #if HAVE_NETINET6_IN6_VAR_H
1186 # include <netinet6/in6_var.h>
1187 #endif
1188 #if HAVE_NETINET6_ND6_H
1189 # include <netinet6/nd6.h>
1190 #endif
1191 ])dnl
1192
1193 dnl disable doc check
1194 if test "${enable_doc}" = "no";then
1195   DOC=""
1196 else
1197   DOC="doc"
1198 fi
1199
1200 dnl --------------------
1201 dnl Daemon disable check
1202 dnl --------------------
1203 if test "${enable_zebra}" = "no";then
1204   ZEBRA=""
1205 else
1206   ZEBRA="zebra"
1207 fi
1208 AM_CONDITIONAL(ZEBRA, test "x$ZEBRA" = "xzebra")
1209
1210 if test "${enable_bgpd}" = "no";then
1211   BGPD=""
1212 else
1213   BGPD="bgpd"
1214 fi
1215 AM_CONDITIONAL(BGPD, test "x$BGPD" = "xbgpd")
1216
1217 if test "${enable_ripd}" = "no";then
1218   RIPD=""
1219 else
1220   RIPD="ripd"
1221 fi
1222 AM_CONDITIONAL(RIPD, test "x$RIPD" = "xripd")
1223
1224 if test "${enable_ospfd}" = "no";then
1225   OSPFD=""
1226 else
1227   OSPFD="ospfd"
1228 fi
1229 AM_CONDITIONAL(OSPFD, test "x$OSPFD" = "xospfd")
1230
1231 if test "${enable_watchquagga}" = "no";then
1232   WATCHQUAGGA=""
1233 else
1234   WATCHQUAGGA="watchquagga"
1235 fi
1236 AM_CONDITIONAL(WATCHQUAGGA, test "x$WATCHQUAGGA" = "xwatchquagga")
1237
1238 OSPFCLIENT=""
1239 if test "${enable_ospfapi}" != "no";then
1240     AC_DEFINE(SUPPORT_OSPF_API,,OSPFAPI)
1241
1242   if test "${enable_ospfclient}" != "no";then
1243       OSPFCLIENT="ospfclient"
1244   fi
1245 fi
1246
1247 AM_CONDITIONAL(OSPFCLIENT, test "x$OSPFCLIENT" = "xospfclient")
1248
1249 case "${enable_ripngd}" in
1250   "no" ) RIPNGD="";;
1251   *    ) RIPNGD="ripngd";;
1252 esac
1253 AM_CONDITIONAL(RIPNGD, test "x$RIPNGD" = "xripngd")
1254
1255 case "${enable_ospf6d}" in
1256   "no" ) OSPF6D="";;
1257   *    ) OSPF6D="ospf6d";;
1258 esac
1259 AM_CONDITIONAL(OSPF6D, test "x$OSPF6D" = "xospf6d")
1260
1261 case "${enable_isisd}" in
1262   "no" ) ISISD="";;
1263   *    ) ISISD="isisd";;
1264 esac
1265 AM_CONDITIONAL(ISISD, test "x$ISISD" = "xisisd")
1266
1267 case "${enable_pimd}" in
1268   "no" ) PIMD="";;
1269   *    ) PIMD="pimd";;
1270 esac
1271 AM_CONDITIONAL(PIMD, test "x$PIMD" = "xpimd")
1272
1273 if test "${enable_bgp_announce}" = "no";then
1274   AC_DEFINE(DISABLE_BGP_ANNOUNCE,1,Disable BGP installation to zebra)
1275 else
1276   AC_DEFINE(DISABLE_BGP_ANNOUNCE,0,Disable BGP installation to zebra)
1277 fi
1278
1279 AC_SUBST(DOC)
1280 AC_SUBST(ZEBRA)
1281 AC_SUBST(BGPD)
1282 AC_SUBST(RIPD)
1283 AC_SUBST(RIPNGD)
1284 AC_SUBST(OSPFD)
1285 AC_SUBST(OSPF6D)
1286 AC_SUBST(WATCHQUAGGA)
1287 AC_SUBST(ISISD)
1288 AC_SUBST(PIMD)
1289 AC_SUBST(SOLARIS)
1290 AC_SUBST(VTYSH)
1291 AC_SUBST(CURSES)
1292 AC_SUBST(OSPFCLIENT)
1293 AC_SUBST(OSPFAPI)
1294 AC_CHECK_LIB(c, inet_ntop, [AC_DEFINE(HAVE_INET_NTOP,,inet_ntop)])
1295 AC_CHECK_LIB(c, inet_pton, [AC_DEFINE(HAVE_INET_PTON,,inet_pton)])
1296 AC_CHECK_LIB(crypt, crypt)
1297 AC_CHECK_LIB(resolv, res_init)
1298
1299 dnl ---------------------------
1300 dnl check system has PCRE regexp
1301 dnl ---------------------------
1302 if test "x$enable_pcreposix" = "xyes"; then
1303   AC_CHECK_LIB(pcreposix, pcreposix_regexec, ,[enable_pcreposix=no
1304   AC_MSG_WARN([*** falling back to other regex library ***]) ])
1305 fi
1306
1307 if test "x$enable_pcreposix" != "xyes"; then
1308 dnl ---------------------------
1309 dnl check system has GNU regexp
1310 dnl ---------------------------
1311 AC_MSG_CHECKING(whether system has GNU regex)
1312 AC_CHECK_LIB(c, regexec,
1313 [AC_DEFINE(HAVE_GNU_REGEX,,GNU regexp library)
1314  LIB_REGEX=""],
1315 [LIB_REGEX="regex.o"])
1316 fi
1317 AC_SUBST(HAVE_LIBPCREPOSIX)
1318 AC_SUBST(LIB_REGEX)
1319
1320 dnl ------------------
1321 dnl check Net-SNMP library
1322 dnl ------------------
1323 if test "${enable_snmp}" != ""; then
1324    AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], [no])
1325    if test x"$NETSNMP_CONFIG" = x"no"; then
1326       AC_MSG_ERROR([--enable-snmp given but unable to find net-snmp-config])
1327    fi
1328    LIBS="$LIBS `${NETSNMP_CONFIG} --agent-libs`"
1329    CFLAGS="`${NETSNMP_CONFIG} --base-cflags` $CFLAGS"
1330    AC_MSG_CHECKING([whether we can link to Net-SNMP])
1331    AC_LINK_IFELSE([AC_LANG_PROGRAM([
1332 int main(void);
1333 ],
1334 [
1335 {
1336   return 0;
1337 }
1338 ])],[AC_MSG_RESULT(yes)],[
1339      AC_MSG_RESULT(no)
1340      AC_MSG_ERROR([--enable-snmp given but not usable])])
1341    AC_DEFINE(HAVE_SNMP,,SNMP)
1342    case "${enable_snmp}" in
1343      yes)
1344       SNMP_METHOD=agentx
1345       ;;
1346      smux|agentx)
1347       SNMP_METHOD="${enable_snmp}"
1348       ;;
1349      *)
1350       AC_MSG_ERROR([--enable-snmp given with an unknown method (${enable_snmp}). Use smux or agentx])
1351       ;;
1352    esac
1353    AH_TEMPLATE([SNMP_SMUX], [Use SNMP SMUX to interface with snmpd])
1354    AH_TEMPLATE([SNMP_AGENTX], [Use SNMP AgentX to interface with snmpd])
1355    AC_DEFINE_UNQUOTED(AS_TR_CPP(SNMP_${SNMP_METHOD}),,SNMP method to interface with snmpd)
1356 fi
1357
1358 dnl ---------------------------
1359 dnl sockaddr and netinet checks
1360 dnl ---------------------------
1361 AC_CHECK_TYPES([struct sockaddr, struct sockaddr_in,
1362         struct sockaddr_in6, struct sockaddr_un, struct sockaddr_dl,
1363         socklen_t, struct vifctl, struct mfcctl, struct sioc_sg_req,
1364         vifi_t, struct sioc_vif_req, struct igmpmsg,
1365         struct ifaliasreq, struct if6_aliasreq, struct in6_aliasreq,
1366         struct nd_opt_adv_interval, struct rt_addrinfo,
1367         struct nd_opt_homeagent_info, struct nd_opt_adv_interval],
1368         [], [], QUAGGA_INCLUDES)
1369
1370 AC_CHECK_MEMBERS([struct sockaddr.sa_len,
1371         struct sockaddr_in.sin_len, struct sockaddr_un.sun_len,
1372         struct sockaddr_in6.sin6_scope_id,
1373         struct sockaddr_dl.sdl_len,
1374         struct if6_aliasreq.ifra_lifetime,
1375         struct nd_opt_adv_interval.nd_opt_ai_type],
1376         [], [], QUAGGA_INCLUDES)
1377
1378 dnl ---------------------------
1379 dnl IRDP/pktinfo/icmphdr checks
1380 dnl ---------------------------
1381 AC_CHECK_TYPES([struct in_pktinfo],
1382  [AC_CHECK_TYPES([struct icmphdr],
1383    [if test "${enable_irdp}" != "no"; then
1384       AC_DEFINE(HAVE_IRDP,, IRDP)
1385     fi],
1386    [if test "${enable_irdp}" = "yes"; then
1387       AC_MSG_ERROR(['IRDP requires in_pktinfo at the moment!'])
1388     fi], [QUAGGA_INCLUDES])],
1389  [if test "${enable_irdp}" = "yes"; then
1390     AC_MSG_ERROR(['IRDP requires in_pktinfo at the moment!'])
1391   fi], [QUAGGA_INCLUDES])
1392
1393 dnl -----------------------
1394 dnl checking for IP_PKTINFO
1395 dnl -----------------------
1396 AC_MSG_CHECKING(for IP_PKTINFO)
1397 AC_TRY_COMPILE([#include <netdb.h>], [
1398   int opt = IP_PKTINFO;
1399 ], [
1400   AC_MSG_RESULT(yes)
1401   AC_DEFINE(HAVE_IP_PKTINFO, 1, [Have IP_PKTINFO])
1402 ], [
1403   AC_MSG_RESULT(no)
1404 ])
1405
1406 dnl ---------------------------
1407 dnl checking for IP_RECVDSTADDR
1408 dnl ---------------------------
1409 AC_MSG_CHECKING(for IP_RECVDSTADDR)
1410 AC_TRY_COMPILE([#include <netinet/in.h>], [
1411   int opt = IP_RECVDSTADDR;
1412 ], [
1413   AC_MSG_RESULT(yes)
1414   AC_DEFINE(HAVE_IP_RECVDSTADDR, 1, [Have IP_RECVDSTADDR])
1415 ], [
1416   AC_MSG_RESULT(no)
1417 ])
1418
1419 dnl ----------------------
1420 dnl checking for IP_RECVIF
1421 dnl ----------------------
1422 AC_MSG_CHECKING(for IP_RECVIF)
1423 AC_TRY_COMPILE([#include <netinet/in.h>], [
1424   int opt = IP_RECVIF;
1425 ], [
1426   AC_MSG_RESULT(yes)
1427   AC_DEFINE(HAVE_IP_RECVIF, 1, [Have IP_RECVIF])
1428 ], [
1429   AC_MSG_RESULT(no)
1430 ])
1431
1432 dnl --------------------------------------
1433 dnl checking for getrusage struct and call
1434 dnl --------------------------------------
1435 if test "${enable_rusage}" != "no"; then
1436   AC_MSG_CHECKING(whether getrusage is available)
1437   AC_TRY_COMPILE([#include <sys/resource.h>],[struct rusage ac_x; getrusage (RUSAGE_SELF, &ac_x);],
1438     [AC_MSG_RESULT(yes)
1439      AC_DEFINE(HAVE_RUSAGE,,rusage)],
1440       AC_MSG_RESULT(no))
1441 fi
1442
1443 dnl --------------------------------------
1444 dnl checking for clock_time monotonic struct and call
1445 dnl --------------------------------------
1446 AC_CHECK_DECL(CLOCK_MONOTONIC,
1447         [AC_CHECK_LIB(rt, clock_gettime, [LIBS="$LIBS -lrt"])
1448          AC_DEFINE(HAVE_CLOCK_MONOTONIC,, Have monotonic clock)
1449 ], [AC_MSG_RESULT(no)], [QUAGGA_INCLUDES])
1450
1451 dnl -------------------
1452 dnl capabilities checks
1453 dnl -------------------
1454 if test "${enable_capabilities}" != "no"; then
1455   AC_MSG_CHECKING(whether prctl PR_SET_KEEPCAPS is available)
1456   AC_TRY_COMPILE([#include <sys/prctl.h>],[prctl(PR_SET_KEEPCAPS, 1, 0, 0, 0);],
1457     [AC_MSG_RESULT(yes)
1458      AC_DEFINE(HAVE_PR_SET_KEEPCAPS,,prctl)
1459      quagga_ac_keepcaps="yes"],
1460      AC_MSG_RESULT(no)
1461   )
1462   if test x"${quagga_ac_keepcaps}" = x"yes"; then
1463     AC_CHECK_HEADERS(sys/capability.h)
1464   fi
1465   if test x"${ac_cv_header_sys_capability_h}" = x"yes"; then
1466     AC_CHECK_LIB(cap, cap_init,
1467       [AC_DEFINE(HAVE_LCAPS,1,Capabilities)
1468        LIBCAP="-lcap"
1469        quagga_ac_lcaps="yes"]
1470     )
1471   else
1472     AC_CHECK_HEADERS(priv.h,
1473      [AC_MSG_CHECKING(Solaris style privileges are available)
1474       AC_TRY_COMPILE([#include <priv.h>],[getpflags(PRIV_AWARE);],
1475           [AC_MSG_RESULT(yes)
1476            AC_DEFINE(HAVE_SOLARIS_CAPABILITIES,1,getpflags)
1477            quagga_ac_scaps="yes"],
1478            AC_MSG_RESULT(no)
1479       )
1480      ]
1481    )
1482   fi
1483   if test x"${quagga_ac_scaps}" = x"yes" \
1484        -o x"${quagga_ac_lcaps}" = x"yes"; then
1485     AC_DEFINE(HAVE_CAPABILITIES,1,capabilities)
1486   fi
1487 fi
1488 AC_SUBST(LIBCAP)
1489
1490 dnl ---------------------------
1491 dnl check for glibc 'backtrace'
1492 dnl ---------------------------
1493 if test x"${enable_backtrace}" != x"no" ; then
1494   backtrace_ok=no
1495   AC_CHECK_HEADER([execinfo.h], [
1496     AC_SEARCH_LIBS([backtrace], [execinfo], [
1497       AC_DEFINE(HAVE_GLIBC_BACKTRACE,,[Glibc backtrace])
1498       AC_DEFINE(HAVE_STACK_TRACE,,[Stack symbol decoding])
1499       backtrace_ok=yes
1500     ],, [-lm])
1501   ])
1502
1503   if test x"${enable_backtrace}" = x"yes" -a x"${backtrace_ok}" = x"no"; then
1504     dnl user explicitly requested backtrace but we failed to find support
1505     AC_MSG_FAILURE([failed to find backtrace support])
1506   fi
1507 fi
1508
1509 dnl -----------------------------------------
1510 dnl check for malloc mallinfo struct and call
1511 dnl this must try and link using LIBS, in
1512 dnl order to check no alternative allocator
1513 dnl has been specified, which might not provide
1514 dnl mallinfo, e.g. such as Umem on Solaris.
1515 dnl -----------------------------------------
1516 AC_CHECK_HEADER([malloc.h],
1517  [AC_MSG_CHECKING(whether mallinfo is available)
1518   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <malloc.h>]],
1519                         [[struct mallinfo ac_x; ac_x = mallinfo ();]])],
1520       [AC_MSG_RESULT(yes)
1521        AC_DEFINE(HAVE_MALLINFO,,mallinfo)],
1522        AC_MSG_RESULT(no)
1523   )
1524  ], [], QUAGGA_INCLUDES)
1525
1526 dnl ----------
1527 dnl configure date
1528 dnl ----------
1529 CONFDATE=`date '+%Y%m%d'`
1530 AC_SUBST(CONFDATE)
1531
1532 dnl -------
1533 dnl DejaGNU
1534 dnl -------
1535 if test x"$DEJAGNU" = x
1536 then
1537   DEJAGNU="\$(top_srcdir)/tests/global-conf.exp"
1538 fi
1539 RUNTESTDEFAULTFLAGS="-x --tool \$\$tool"
1540
1541 AC_SUBST(DEJAGNU)
1542 AC_SUBST(RUNTESTDEFAULTFLAGS)
1543
1544 dnl ------------------------------
1545 dnl set paths for state directory
1546 dnl ------------------------------
1547 AC_MSG_CHECKING(directory to use for state file)
1548 if test "${prefix}" = "NONE"; then
1549   quagga_statedir_prefix="";
1550 else
1551   quagga_statedir_prefix=${prefix}
1552 fi
1553 if test "${localstatedir}" = '${prefix}/var'; then
1554   for QUAGGA_STATE_DIR in ${quagga_statedir_prefix}/var/run dnl
1555                         ${quagga_statedir_prefix}/var/adm dnl
1556                         ${quagga_statedir_prefix}/etc dnl
1557                         /var/run        dnl
1558                         /var/adm        dnl
1559                         /etc            dnl
1560                         /dev/null;
1561   do
1562     test -d $QUAGGA_STATE_DIR && break
1563   done
1564   quagga_statedir=$QUAGGA_STATE_DIR
1565 else
1566   quagga_statedir=${localstatedir}
1567 fi
1568 if test $quagga_statedir = "/dev/null"; then
1569     AC_MSG_ERROR('STATE DIRECTORY NOT FOUND! FIX OR SPECIFY --localstatedir!')
1570 fi
1571 AC_MSG_RESULT(${quagga_statedir})
1572 AC_SUBST(quagga_statedir)
1573
1574 AC_DEFINE_UNQUOTED(PATH_ZEBRA_PID, "$quagga_statedir/zebra.pid",zebra PID)
1575 AC_DEFINE_UNQUOTED(PATH_RIPD_PID, "$quagga_statedir/ripd.pid",ripd PID)
1576 AC_DEFINE_UNQUOTED(PATH_RIPNGD_PID, "$quagga_statedir/ripngd.pid",ripngd PID)
1577 AC_DEFINE_UNQUOTED(PATH_BGPD_PID, "$quagga_statedir/bgpd.pid",bgpd PID)
1578 AC_DEFINE_UNQUOTED(PATH_OSPFD_PID, "$quagga_statedir/ospfd.pid",ospfd PID)
1579 AC_DEFINE_UNQUOTED(PATH_OSPF6D_PID, "$quagga_statedir/ospf6d.pid",ospf6d PID)
1580 AC_DEFINE_UNQUOTED(PATH_ISISD_PID, "$quagga_statedir/isisd.pid",isisd PID)
1581 AC_DEFINE_UNQUOTED(PATH_PIMD_PID, "$quagga_statedir/pimd.pid",pimd PID)
1582 AC_DEFINE_UNQUOTED(PATH_WATCHQUAGGA_PID, "$quagga_statedir/watchquagga.pid",watchquagga PID)
1583 AC_DEFINE_UNQUOTED(ZEBRA_SERV_PATH, "$quagga_statedir/zserv.api",zebra api socket)
1584 AC_DEFINE_UNQUOTED(ZEBRA_VTYSH_PATH, "$quagga_statedir/zebra.vty",zebra vty socket)
1585 AC_DEFINE_UNQUOTED(RIP_VTYSH_PATH, "$quagga_statedir/ripd.vty",rip vty socket)
1586 AC_DEFINE_UNQUOTED(RIPNG_VTYSH_PATH, "$quagga_statedir/ripngd.vty",ripng vty socket)
1587 AC_DEFINE_UNQUOTED(BGP_VTYSH_PATH, "$quagga_statedir/bgpd.vty",bgpd vty socket)
1588 AC_DEFINE_UNQUOTED(OSPF_VTYSH_PATH, "$quagga_statedir/ospfd.vty",ospfd vty socket)
1589 AC_DEFINE_UNQUOTED(OSPF6_VTYSH_PATH, "$quagga_statedir/ospf6d.vty",ospf6d vty socket)
1590 AC_DEFINE_UNQUOTED(ISIS_VTYSH_PATH, "$quagga_statedir/isisd.vty",isisd vty socket)
1591 AC_DEFINE_UNQUOTED(PIM_VTYSH_PATH, "$quagga_statedir/pimd.vty",pimd vty socket)
1592 AC_DEFINE_UNQUOTED(DAEMON_VTY_DIR, "$quagga_statedir",daemon vty directory)
1593
1594 dnl -------------------------------
1595 dnl Quagga sources should always be
1596 dnl current wrt interfaces. Dont
1597 dnl allow deprecated interfaces to
1598 dnl be exposed.
1599 dnl -------------------------------
1600 AC_DEFINE(QUAGGA_NO_DEPRECATED_INTERFACES, 1, Hide deprecated interfaces)
1601
1602 dnl ---------------------------
1603 dnl Check htonl works correctly
1604 dnl ---------------------------
1605 AC_MSG_CHECKING(for working htonl)
1606 AC_CACHE_VAL(ac_cv_htonl_works,
1607  [AC_LINK_IFELSE([AC_LANG_PROGRAM([QUAGGA_INCLUDES],[htonl (0);])],
1608                 [ac_cv_htonl_works=yes], [ac_cv_htonl_works=no])
1609  ]
1610 )
1611 AC_MSG_RESULT($ac_cv_htonl_works)
1612
1613 AC_CONFIG_FILES([Makefile lib/Makefile zebra/Makefile ripd/Makefile
1614           ripngd/Makefile bgpd/Makefile ospfd/Makefile watchquagga/Makefile
1615           ospf6d/Makefile isisd/Makefile vtysh/Makefile
1616           doc/Makefile ospfclient/Makefile tests/Makefile m4/Makefile
1617           pimd/Makefile
1618           tests/bgpd.tests/Makefile
1619           tests/libzebra.tests/Makefile
1620           redhat/Makefile
1621           tools/Makefile
1622           cumulus/Makefile
1623           pkgsrc/Makefile
1624           redhat/quagga.spec
1625           lib/version.h
1626           doc/defines.texi
1627           isisd/topology/Makefile
1628           pkgsrc/bgpd.sh pkgsrc/ospf6d.sh pkgsrc/ospfd.sh
1629           pkgsrc/ripd.sh pkgsrc/ripngd.sh pkgsrc/zebra.sh])
1630 AC_CONFIG_FILES([solaris/Makefile])
1631
1632 AC_CONFIG_FILES([vtysh/extract.pl],[chmod +x vtysh/extract.pl])
1633 ## Hack, but working solution to avoid rebuilding of quagga.info.
1634 ## It's already in CVS until texinfo 4.7 is more common.
1635 AC_OUTPUT
1636
1637 echo "
1638 Quagga configuration
1639 --------------------
1640 quagga version          : ${PACKAGE_VERSION}
1641 host operating system   : ${host_os}
1642 source code location    : ${srcdir}
1643 compiler                : ${CC}
1644 compiler flags          : ${CFLAGS}
1645 make                    : ${MAKE-make}
1646 linker flags            : ${LDFLAGS} ${LIBS} ${LIBCAP} ${LIBREADLINE} ${LIBM}
1647 state file directory    : ${quagga_statedir}
1648 config file directory   : `eval echo \`echo ${sysconfdir}\``
1649 example directory       : `eval echo \`echo ${exampledir}\``
1650 user to run as          : ${enable_user}
1651 group to run as         : ${enable_group}
1652 group for vty sockets   : ${enable_vty_group}
1653 config file mask        : ${enable_configfile_mask}
1654 log file mask           : ${enable_logfile_mask}
1655
1656 The above user and group must have read/write access to the state file
1657 directory and to the config files in the config file directory."
1658
1659 if test x"$quagga_cv_gnu_make" = x"no"; then echo "
1660 Warning: The ${MAKE-make} programme detected, either in your path or
1661 via the MAKE variable, is not GNU Make. GNU make may be installed as
1662 gmake on some systems. and is required to complete a build of Quagga
1663 " > /dev/stderr
1664 fi