configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 m4_define([lxc_version_major], 1)
   5 m4_define([lxc_version_minor], 0)
   6 m4_define([lxc_version_micro], 0)
   7 m4_define([lxc_version_beta], [])
   8
   9 m4_define([lxc_version_base], [lxc_version_major.lxc_version_minor.lxc_version_micro])
  10 m4_define([lxc_version],
  11           [ifelse(lxc_version_beta, [], [lxc_version_base], [lxc_version_base.lxc_version_beta])])
  12
  13 AC_INIT([lxc], [lxc_version])
  14
  15 # We need pkg-config
  16 PKG_PROG_PKG_CONFIG
  17
  18 AC_SUBST(LXC_VERSION_BASE, lxc_version_base)
  19 AC_SUBST(LXC_VERSION_BETA, lxc_version_beta)
  20
  21 AC_SUBST([LXC_VERSION_MAJOR], [lxc_version_major])
  22 AC_SUBST([LXC_VERSION_MINOR], [lxc_version_minor])
  23 AC_SUBST([LXC_VERSION_MICRO], [lxc_version_micro])
  24 AC_SUBST([LXC_VERSION], [lxc_version])
  25
  26 AC_CONFIG_SRCDIR([configure.ac])
  27 AC_CONFIG_AUX_DIR([config])
  28 AC_CONFIG_HEADERS([src/config.h])
  29 AM_INIT_AUTOMAKE([-Wall -Werror -Wno-portability subdir-objects])
  30 AC_CANONICAL_HOST
  31 AM_PROG_CC_C_O
  32 AC_GNU_SOURCE
  33
  34 # Detect the distribution. This is used for the default configuration and
  35 # for some distro-specific build options.
  36 AC_MSG_CHECKING([host distribution])
  37 AC_ARG_WITH(distro, AS_HELP_STRING([--with-distro=DISTRO], [Specify the Linux distribution to target: One of redhat, oracle, centos, fedora, suse, gentoo, debian, arch, slackware, paldo, openmandriva or pardus.]))
  38 if type lsb_release >/dev/null 2>&1 && test "z$with_distro" = "z"; then
  39         with_distro=`lsb_release -is`
  40 fi
  41 if test "z$with_distro" = "z"; then
  42         AC_CHECK_FILE(/etc/redhat-release,with_distro="redhat")
  43         AC_CHECK_FILE(/etc/oracle-release,with_distro="oracle")
  44         AC_CHECK_FILE(/etc/centos-release,with_distro="centos")
  45         AC_CHECK_FILE(/etc/fedora-release,with_distro="fedora")
  46         AC_CHECK_FILE(/etc/SuSE-release,with_distro="suse")
  47         AC_CHECK_FILE(/etc/gentoo-release,with_distro="gentoo")
  48         AC_CHECK_FILE(/etc/debian_version,with_distro="debian")
  49         AC_CHECK_FILE(/etc/arch-release,with_distro="arch")
  50         AC_CHECK_FILE(/etc/slackware-version,with_distro="slackware")
  51         AC_CHECK_FILE(/etc/frugalware-release,with_distro="frugalware")
  52         AC_CHECK_FILE(/etc/mandrakelinux-release, with_distro="openmandriva")
  53         AC_CHECK_FILE(/etc/mandriva-release,with_distro="openmandriva")
  54         AC_CHECK_FILE(/etc/pardus-release,with_distro="pardus")
  55 fi
  56 with_distro=`echo ${with_distro} | tr '[[:upper:]]' '[[:lower:]]'`
  57
  58 if test "z$with_distro" = "z"; then
  59         with_distro="unknown"
  60 fi
  61 case $with_distro in
  62         ubuntu)
  63                 distroconf=default.conf.ubuntu
  64                 ;;
  65         redhat|centos|fedora|oracle|oracleserver)
  66                 distroconf=default.conf.libvirt
  67                 ;;
  68         *)
  69                 distroconf=default.conf.unknown
  70                 ;;
  71 esac
  72 AC_MSG_RESULT([$with_distro])
  73 AM_CONDITIONAL([HAVE_DEBIAN], [test x"$with_distro" = "xdebian" -o x"$with_distro" = "xubuntu"])
  74 AM_CONDITIONAL([DISTRO_UBUNTU], [test "x$with_distro" = "xubuntu"])
  75
  76 # Check for init system type
  77 AC_MSG_CHECKING([for init system type])
  78 AC_ARG_WITH([init-script],
  79             [AC_HELP_STRING([--with-init-script@<:@=TYPE@<:@,TYPE,...@:>@@:>@],
  80                             [Type(s) of init script to install: sysvinit, systemd, upstart,
  81                              distro @<:@default=distro@:>@])],[],[with_init_script=distro])
  82 case "$with_init_script" in
  83         distro)
  84                 case $with_distro in
  85                         fedora)
  86                                 init_script=systemd
  87                                 ;;
  88                         redhat|centos|oracle|oracleserver)
  89                                 init_script=sysvinit
  90                                 ;;
  91                         debian)
  92                                 init_script=upstart,systemd
  93                                 ;;
  94                         ubuntu)
  95                                 init_script=upstart
  96                                 ;;
  97                         *)
  98                                 echo -n "Linux distribution init system unknown."
  99                                 init_script=
 100                                 ;;
 101                 esac
 102                 ;;
 103         *)
 104                 init_script=$with_init_script
 105                 ;;
 106 esac
 107
 108 # Check valid init systems were given, run in subshell so we don't mess up IFS
 109 (IFS="," ; for init_sys in $init_script;
 110 do
 111         case "$init_sys" in
 112                 none|sysvinit|systemd|upstart)
 113                         ;;
 114                 *)
 115                         exit 1
 116                         ;;
 117         esac
 118 done) || AC_MSG_ERROR([Unknown init system type in $init_script])
 119
 120 AM_CONDITIONAL([INIT_SCRIPT_SYSV], [echo "$init_script" |grep -q "sysvinit"])
 121 AM_CONDITIONAL([INIT_SCRIPT_SYSTEMD], [echo "$init_script" |grep -q "systemd"])
 122 AM_CONDITIONAL([INIT_SCRIPT_UPSTART], [echo "$init_script" |grep -q "upstart"])
 123 AC_MSG_RESULT($init_script)
 124
 125 # Allow disabling rpath
 126 AC_ARG_ENABLE([rpath],
 127         [AC_HELP_STRING([--enable-rpath], [set rpath in executables [default=no]])],
 128         [], [enable_rpath=no])
 129 AM_CONDITIONAL([ENABLE_RPATH], [test "x$enable_rpath" = "xyes"])
 130
 131 # Documentation (manpages)
 132 AC_ARG_ENABLE([doc],
 133         [AC_HELP_STRING([--enable-doc], [make man pages [default=auto]])],
 134         [], [enable_doc=auto])
 135
 136 if test "x$enable_doc" = "xyes" -o "x$enable_doc" = "xauto"; then
 137         db2xman=""
 138         dbparsers="docbook2x-man db2x_docbook2man docbook2man docbook-to-man"
 139
 140         AC_MSG_CHECKING(for docbook2x-man)
 141         for name in ${dbparsers}; do
 142                 if "$name" --help >/dev/null 2>&1; then
 143                         db2xman="$name"
 144                         break;
 145                 fi
 146         done
 147
 148         if test -n "${db2xman}"; then
 149                 AC_MSG_RESULT([${db2xman}])
 150                 enable_doc="yes"
 151         else
 152                 AC_MSG_RESULT([no])
 153                 if test "x$enable_doc" = "xyes"; then
 154                         AC_MSG_ERROR([docbook2x-man is required, but could not be found])
 155                 fi
 156                 enable_doc="no"
 157         fi
 158
 159         AC_SUBST(db2xman)
 160 fi
 161 AM_CONDITIONAL([ENABLE_DOCBOOK], [test "x$db2xman" != "x"])
 162 AM_CONDITIONAL([USE_DOCBOOK2X], [test "x$db2xman" != "xdocbook2man"])
 163
 164 if test "x$db2xman" = "xdocbook2man"; then
 165         docdtd="\"-//Davenport//DTD DocBook V3.0//EN\""
 166 else
 167         docdtd="\"-//OASIS//DTD DocBook XML\" \"http://www.oasis-open.org/docbook/xml/4.5/docbookx.dtd\""
 168 fi
 169 AC_SUBST(docdtd)
 170
 171 # Documentation (API)
 172 AC_ARG_ENABLE([api-docs],
 173         [AC_HELP_STRING([--enable-api-docs],
 174         [make API documentation [default=auto]])],
 175         [], [enable_api_docs=auto])
 176
 177 if test "x$enable_api_docs" = "xyes" -o "x$enable_api_docs" = "xauto"; then
 178         AC_CHECK_PROGS([HAVE_DOXYGEN],[doxygen])
 179         AC_SUBST([HAVE_DOXYGEN])
 180
 181         if test "x$HAVE_DOXYGEN" != "x"; then
 182                 enable_api_docs="yes"
 183         else
 184                 if test "x$enable_api_docs" = "xyes"; then
 185                         AC_MSG_ERROR([doxygen is required, but could not be found])
 186                 fi
 187                 enable_api_docs="no"
 188         fi
 189 fi
 190
 191 AM_CONDITIONAL([ENABLE_API_DOCS], [test "x$HAVE_DOXYGEN" != "x"])
 192
 193 # Apparmor
 194 AC_ARG_ENABLE([apparmor],
 195         [AC_HELP_STRING([--enable-apparmor], [enable apparmor support [default=auto]])],
 196         [], [enable_apparmor=auto])
 197
 198 if test "$enable_apparmor" = "auto" ; then
 199         AC_CHECK_LIB([apparmor],[aa_change_profile],[enable_apparmor=yes], [enable_apparmor=no])
 200 fi
 201 AM_CONDITIONAL([ENABLE_APPARMOR], [test "x$enable_apparmor" = "xyes"])
 202
 203 AC_CHECK_LIB([gnutls], [gnutls_hash_fast], [enable_gnutls=yes], [enable_gnutls=no])
 204
 205 AM_COND_IF([ENABLE_APPARMOR],
 206         [AC_CHECK_HEADER([sys/apparmor.h],[],[AC_MSG_ERROR([You must install the AppArmor development package in order to compile lxc])])
 207         AC_CHECK_LIB([apparmor], [aa_change_profile],[],[AC_MSG_ERROR([You must install the AppArmor development package in order to compile lxc])])
 208         AC_SUBST([APPARMOR_LIBS], [-lapparmor])])
 209
 210 # SELinux
 211 AC_ARG_ENABLE([selinux],
 212         [AC_HELP_STRING([--enable-selinux], [enable SELinux support [default=auto]])],
 213         [], [enable_selinux=auto])
 214
 215 if test "x$enable_selinux" = xauto; then
 216         AC_CHECK_LIB([selinux],[setexeccon_raw],[enable_selinux=yes],[enable_selinux=no])
 217 fi
 218 AM_CONDITIONAL([ENABLE_SELINUX], [test "x$enable_selinux" = "xyes"])
 219 AM_COND_IF([ENABLE_SELINUX],
 220         [AC_CHECK_HEADER([selinux/selinux.h],[],[AC_MSG_ERROR([You must install the SELinux development package in order to compile lxc])])
 221         AC_CHECK_LIB([selinux], [setexeccon_raw],[],[AC_MSG_ERROR([You must install the SELinux development package in order to compile lxc])])
 222         AC_SUBST([SELINUX_LIBS])])
 223
 224 # Seccomp syscall filter
 225 AC_ARG_ENABLE([seccomp],
 226         [AC_HELP_STRING([--enable-seccomp], [enable seccomp support [default=auto]])],
 227         [], [enable_seccomp=auto])
 228
 229 if test "x$enable_seccomp" = "xauto" ; then
 230         AC_CHECK_LIB([seccomp],[seccomp_init],[enable_seccomp=yes],[enable_seccomp=no])
 231 fi
 232 AM_CONDITIONAL([ENABLE_SECCOMP], [test "x$enable_seccomp" = "xyes"])
 233
 234 AM_COND_IF([ENABLE_SECCOMP],
 235         [PKG_CHECK_MODULES([SECCOMP],[libseccomp],[],[
 236                 AC_CHECK_HEADER([seccomp.h],[],[AC_MSG_ERROR([You must install the seccomp development package in order to compile lxc])])
 237                 AC_CHECK_LIB([seccomp], [seccomp_init],[],[AC_MSG_ERROR([You must install the seccomp development package in order to compile lxc])])
 238                 AC_SUBST([SECCOMP_LIBS], [-lseccomp])
 239                 ])
 240         ])
 241
 242 # cgmanager
 243 AC_ARG_ENABLE([cgmanager],
 244         [AC_HELP_STRING([--enable-cgmanager], [enable cgmanager support [default=auto]])],
 245         [], [enable_cgmanager=auto])
 246
 247 if test "x$enable_cgmanager" = "xauto" ; then
 248         AC_CHECK_LIB([cgmanager],[cgmanager_create],[enable_cgmanager=yes],[enable_cgmanager=no],[-lnih -lnih-dbus -ldbus-1])
 249 fi
 250 AM_CONDITIONAL([ENABLE_CGMANAGER], [test "x$enable_cgmanager" = "xyes"])
 251
 252 AM_COND_IF([ENABLE_CGMANAGER],
 253         [PKG_CHECK_MODULES([CGMANAGER], [libcgmanager])
 254         PKG_CHECK_MODULES([NIH], [libnih >= 1.0.2])
 255         PKG_CHECK_MODULES([NIH_DBUS], [libnih-dbus >= 1.0.0])
 256         PKG_CHECK_MODULES([DBUS], [dbus-1 >= 1.2.16])
 257         ])
 258
 259 AC_MSG_CHECKING(for get_pid_cgroup_abs_sync)
 260 save_LIBS=$LIBS
 261 AC_SEARCH_LIBS([cgmanager_get_pid_cgroup_abs_sync], [cgmanager], [have_abs_cgroups=yes], [have_abs_cgroups=no], [-lnih -lnih-dbus -ldbus-1])
 262 LIBS=$save_LIBS
 263 if test "x$have_abs_cgroups" = "xyes"; then
 264         AC_DEFINE([HAVE_CGMANAGER_GET_PID_CGROUP_ABS_SYNC], 1, [Have cgmanager_get_pid_cgroup_abs_sync])
 265         AC_MSG_RESULT([yes])
 266 else
 267         AC_MSG_RESULT([no])
 268 fi
 269 # Linux capabilities
 270 AC_ARG_ENABLE([capabilities],
 271         [AC_HELP_STRING([--enable-capabilities], [enable kernel capabilities support [default=auto]])],
 272         [], [enable_capabilities=auto])
 273
 274 if test "x$enable_capabilities" = "xauto"; then
 275         AC_CHECK_LIB([cap],[cap_set_proc],[enable_capabilities=yes],[enable_capabilities=no])
 276 fi
 277 AM_CONDITIONAL([ENABLE_CAP], [test "x$enable_capabilities" = "xyes"])
 278
 279 AM_COND_IF([ENABLE_CAP],
 280         [AC_CHECK_LIB(cap,cap_set_proc,[],[AC_MSG_ERROR([You are missing libcap support.])])
 281         AC_SUBST([CAP_LIBS], [-lcap])])
 282
 283 # HAVE_SCMP_FILTER_CTX=1 will tell us we have libseccomp api >= 1.0.0
 284 OLD_CFLAGS="$CFLAGS"
 285 CFLAGS="$CFLAGS $SECCOMP_CFLAGS"
 286 AC_CHECK_TYPES([scmp_filter_ctx], [], [], [[#include <seccomp.h>]])
 287 AC_CHECK_DECLS([seccomp_syscall_resolve_name_arch], [], [], [[#include <seccomp.h>]])
 288 CFLAGS="$OLD_CFLAGS"
 289
 290 # Configuration examples
 291 AC_ARG_ENABLE([examples],
 292         [AC_HELP_STRING([--enable-examples], [install examples [default=yes]])],
 293         [], [enable_examples=yes])
 294 AM_CONDITIONAL([ENABLE_EXAMPLES], [test "x$enable_examples" = "xyes"])
 295
 296 # Python3 module and scripts
 297 AC_ARG_ENABLE([python],
 298         [AC_HELP_STRING([--enable-python], [enable python binding [default=auto]])],
 299         [], [enable_python=auto])
 300
 301 if test "x$enable_python" = "xauto"; then
 302         PKG_CHECK_MODULES([PYTHONDEV], [python3 >= 3.2],[enable_python=yes],[enable_python=no])
 303         if test "$CC" = "clang"; then
 304                 enable_python=no
 305         fi
 306 fi
 307
 308 if test "x$enable_python" = "xyes" && test "$CC" = "clang"; then
 309         AC_MSG_ERROR([Python3 is incompatible with the clang compiler])
 310 fi
 311
 312 AM_CONDITIONAL([ENABLE_PYTHON], [test "x$enable_python" = "xyes"])
 313
 314 AM_COND_IF([ENABLE_PYTHON],
 315         [AM_PATH_PYTHON([3.2], [], [AC_MSG_ERROR([You must install python3])])
 316         PKG_CHECK_MODULES([PYTHONDEV], [python3 >= 3.2],[],[AC_MSG_ERROR([You must install python3-dev])])
 317         AC_DEFINE_UNQUOTED([ENABLE_PYTHON], 1, [Python3 is available])])
 318
 319 # Enable dumping stack traces
 320 AC_ARG_ENABLE([mutex-debugging],
 321         [AC_HELP_STRING([--enable-mutex-debugging], [Makes mutexes to report error and provide stack trace [default=no]])],
 322         [], [enable_mutex_debugging=no])
 323 AM_CONDITIONAL([MUTEX_DEBUGGING], [test "x$enable_mutex_debugging" = "xyes"])
 324
 325 AM_COND_IF([MUTEX_DEBUGGING],
 326         AC_DEFINE_UNQUOTED([MUTEX_DEBUGGING], 1, [Enabling mutex debugging]))
 327
 328 # Not in older autoconf versions
 329 # AS_VAR_COPY(DEST, SOURCE)
 330 # -------------------------
 331 # Set the polymorphic shell variable DEST to the contents of the polymorphic
 332 # shell variable SOURCE.
 333 m4_ifdef([AS_VAR_COPY], [],
 334 [AC_DEFUN([AS_VAR_COPY],
 335     [AS_LITERAL_IF([$1[]$2], [$1=$$2], [eval $1=\$$2])])
 336 ])
 337
 338 dnl PKG_CHECK_VAR was introduced with pkg-config 0.28
 339 m4_ifdef([PKG_CHECK_VAR], [],
 340 [AC_DEFUN([PKG_CHECK_VAR],
 341     [AC_REQUIRE([PKG_PROG_PKG_CONFIG])dnl
 342      AC_ARG_VAR([$1], [value of $3 for $2, overriding pkg-config])dnl
 343      _PKG_CONFIG([$1], [variable="][$3]["], [$2])
 344      AS_VAR_COPY([$1], [pkg_cv_][$1])
 345      AS_VAR_IF([$1], [""], [$5], [$4])dnl
 346     ])# PKG_CHECK_VAR
 347 ])
 348
 349 # Lua module and scripts
 350 AC_ARG_ENABLE([lua],
 351         [AC_HELP_STRING([--enable-lua], [enable lua binding [default=auto]])],
 352         [], [enable_lua=auto])
 353
 354 AC_ARG_WITH([lua-pc],
 355         [AS_HELP_STRING(
 356                 [--with-lua-pc=PKG],
 357                 [Specify pkg-config package name for lua]
 358         )], [], [with_lua_pc=no])
 359
 360 if test "x$enable_lua" = "xyes" -a "x$with_lua_pc" != "xno"; then
 361         # exit with error if not found
 362         PKG_CHECK_MODULES([LUA], [$with_lua_pc], [LUAPKGCONFIG=$with_lua_pc])
 363 fi
 364
 365 if test "x$enable_lua" = "xauto" -a "x$with_lua_pc" != "xno"; then
 366         PKG_CHECK_MODULES([LUA], [$with_lua_pc],
 367                 [LUAPKGCONFIG=$with_lua_pc
 368                 enable_lua=yes],
 369                 [enable_lua=no])
 370 fi
 371
 372 if test "x$enable_lua" != "xno"; then
 373         PKG_CHECK_MODULES([LUA], [lua], [LUAPKGCONFIG=lua],
 374                 [PKG_CHECK_MODULES([LUA], [lua5.2], [LUAPKGCONFIG=lua5.2],
 375                         [PKG_CHECK_MODULES([LUA], [lua5.1], [LUAPKGCONFIG=lua5.1],
 376                                 [AS_IF([test "x$enable_lua" = "xyes"],
 377                                         [AC_MSG_ERROR([Lua not found. Please use --with-lua-pc=PKG])],
 378                                         [enable_lua=no])]
 379                         )]
 380                 )])
 381         AS_IF([test "x$LUAPKGCONFIG" != "x"], [enable_lua=yes])
 382 fi
 383
 384 AM_CONDITIONAL([ENABLE_LUA],
 385         [test "x$enable_lua" = "xyes"])
 386
 387 AM_COND_IF([ENABLE_LUA],
 388         [AC_MSG_CHECKING([Lua version])
 389         PKG_CHECK_VAR([LUA_VERSION], [$LUAPKGCONFIG], [V],,
 390                 [PKG_CHECK_VAR([LUA_VERSION], [$LUAPKGCONFIG], [major_version])])
 391         AC_MSG_RESULT([$LUA_VERSION])
 392         AC_SUBST([LUA_LIBDIR], [$libdir/lua/$LUA_VERSION])
 393         AC_SUBST([LUA_SHAREDIR], [$datadir/lua/$LUA_VERSION])
 394         ])
 395
 396 # Optional bash integration
 397 AC_ARG_ENABLE([bash],
 398         [AC_HELP_STRING([--enable-bash], [build bash integration [default=yes]])],
 399         [], [enable_bash=yes])
 400 AM_CONDITIONAL([ENABLE_BASH], [test "x$enable_bash" = "xyes"])
 401
 402 # Optional test binaries
 403 AC_ARG_ENABLE([tests],
 404         [AC_HELP_STRING([--enable-tests], [build test/example binaries [default=no]])],
 405         [], [enable_tests=no])
 406 AM_CONDITIONAL([ENABLE_TESTS], [test "x$enable_tests" = "xyes"])
 407
 408 # Allow overriding the default runtime dir (/run)
 409 AC_ARG_WITH([runtime-path],
 410         [AC_HELP_STRING(
 411                 [--with-runtime-path=dir],
 412                 [runtime directory (default: /run)]
 413         )], [], [with_runtime_path=['/run']])
 414
 415 # LXC container path, where the containers are actually stored
 416 # This is overridden by an entry in the file called LXCCONF
 417 # (i.e. /etc/lxc/lxc.conf)
 418 AC_ARG_WITH([config-path],
 419         [AC_HELP_STRING(
 420                 [--with-config-path=dir],
 421                 [lxc configuration repository path]
 422         )], [], [with_config_path=['${localstatedir}/lib/lxc']])
 423
 424 # The path of the global lxc configuration file.
 425 AC_ARG_WITH([global-conf],
 426         [AC_HELP_STRING(
 427                 [--with-global-conf=dir],
 428                 [global lxc configuration file]
 429         )], [], [with_global_conf=['${sysconfdir}/lxc/lxc.conf']])
 430
 431 # The path of the userns network configuration file
 432 AC_ARG_WITH([usernic-conf],
 433         [AC_HELP_STRING(
 434                 [--with-usernic-conf],
 435                 [user network interface configuration file]
 436         )], [], [with_usernic_conf=['${sysconfdir}/lxc/lxc-usernet']])
 437
 438 # The path of the runtime usernic database
 439 AC_ARG_WITH([usernic-db],
 440         [AC_HELP_STRING(
 441                 [--with-usernic-db],
 442                 [lxc user nic database]
 443         )], [], [with_usernic_db=['${with_runtime_path}/lxc/nics']])
 444
 445 # Rootfs path, where the container mount structure is assembled
 446 AC_ARG_WITH([rootfs-path],
 447         [AC_HELP_STRING(
 448                 [--with-rootfs-path=dir],
 449                 [lxc rootfs mount point]
 450         )], [], [with_rootfs_path=['${libdir}/lxc/rootfs']])
 451
 452 # cgroup pattern specification
 453 AC_ARG_WITH([cgroup-pattern],
 454         [AC_HELP_STRING(
 455                 [--with-cgroup-pattern=pattern],
 456                 [pattern for container cgroups]
 457         )], [], [with_cgroup_pattern=['/lxc/%n']])
 458
 459 # Container log path.  By default, use $lxcpath.
 460 AC_MSG_CHECKING([Whether to place logfiles in container config path])
 461 AC_ARG_ENABLE([configpath-log],
 462         [AC_HELP_STRING([--enable-configpath-log], [use logfiles in config path [default=no]])],
 463         [], [enable_configpath_log=no])
 464 AC_MSG_RESULT([$enable_configpath_log])
 465 AM_CONDITIONAL([USE_CONFIGPATH_LOGS], [test "$enable_configpath_log" = "yes"])
 466
 467 if test "$enable_configpath_log" = "yes"; then
 468         default_log_path="${with_config_path}"
 469 else
 470         default_log_path="${localstatedir}/log/lxc"
 471 fi
 472
 473 AC_ARG_WITH([log-path],
 474         [AC_HELP_STRING(
 475                 [--with-log-path=dir],
 476                 [per container log path]
 477         )], [], [with_log_path=['${default_log_path}']])
 478
 479 # Expand some useful variables
 480 AS_AC_EXPAND(PREFIX, "$prefix")
 481 AS_AC_EXPAND(LIBDIR, "$libdir")
 482 AS_AC_EXPAND(BINDIR, "$bindir")
 483 AS_AC_EXPAND(SBINDIR, "$sbindir")
 484 AS_AC_EXPAND(LIBEXECDIR, "$libexecdir")
 485 AS_AC_EXPAND(INCLUDEDIR, "$includedir")
 486 AS_AC_EXPAND(SYSCONFDIR, "$sysconfdir")
 487 AS_AC_EXPAND(LXC_DEFAULT_CONFIG, "$sysconfdir/lxc/default.conf")
 488 AS_AC_EXPAND(DATADIR, "$datadir")
 489 AS_AC_EXPAND(LOCALSTATEDIR, "$localstatedir")
 490 AS_AC_EXPAND(DOCDIR, "$docdir")
 491 AS_AC_EXPAND(LXC_DISTRO_CONF, "$distroconf")
 492 AS_AC_EXPAND(LXC_GENERATE_DATE, "$(date)")
 493 AS_AC_EXPAND(LXCPATH, "$with_config_path")
 494 AS_AC_EXPAND(LXC_GLOBAL_CONF, "$with_global_conf")
 495 AS_AC_EXPAND(LXC_USERNIC_CONF, "$with_usernic_conf")
 496 AS_AC_EXPAND(LXC_USERNIC_DB, "$with_usernic_db")
 497 AS_AC_EXPAND(LXCROOTFSMOUNT, "$with_rootfs_path")
 498 AS_AC_EXPAND(LXCTEMPLATEDIR, "$datadir/lxc/templates")
 499 AS_AC_EXPAND(LXCTEMPLATECONFIG, "$datadir/lxc/config")
 500 AS_AC_EXPAND(LXCHOOKDIR, "$datadir/lxc/hooks")
 501 AS_AC_EXPAND(LXCINITDIR, "$libexecdir")
 502 AS_AC_EXPAND(LOGPATH, "$with_log_path")
 503 AS_AC_EXPAND(RUNTIME_PATH, "$with_runtime_path")
 504 AC_SUBST(DEFAULT_CGROUP_PATTERN, ["$with_cgroup_pattern"])
 505
 506 # Check for some standard kernel headers
 507 AC_CHECK_HEADERS([linux/unistd.h linux/netlink.h linux/genetlink.h],
 508                                 [],
 509                                 AC_MSG_ERROR([Please install the Linux kernel headers.]),
 510                                 [#include <sys/socket.h>])
 511
 512 # Check for alternate C libraries
 513 AC_MSG_CHECKING(for bionic libc)
 514 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 515         [[#ifndef __ANDROID__
 516 error: Not bionic!
 517 #endif]])],
 518         [is_bionic=yes],
 519         [is_bionic=no])
 520 if test "x$is_bionic" = "xyes"; then
 521         AC_DEFINE([IS_BIONIC], 1, [bionic libc])
 522         AC_MSG_RESULT([yes])
 523 else
 524         AC_MSG_RESULT([no])
 525 fi
 526 AM_CONDITIONAL([IS_BIONIC], [test "x$is_bionic" = "xyes"])
 527
 528 # Some systems lack PR_CAPBSET_DROP definition => HAVE_DECL_PR_CAPBSET_DROP
 529 AC_CHECK_DECLS([PR_CAPBSET_DROP], [], [], [#include <sys/prctl.h>])
 530
 531 # Check for some headers
 532 AC_CHECK_HEADERS([sys/signalfd.h pty.h ifaddrs.h sys/capability.h sys/personality.h utmpx.h sys/timerfd.h])
 533
 534 # Check for some syscalls functions
 535 AC_CHECK_FUNCS([setns pivot_root sethostname unshare rand_r confstr faccessat])
 536
 537 # Check for some functions
 538 AC_CHECK_LIB(pthread, main)
 539 AC_CHECK_FUNCS(pthread_atfork)
 540 AC_CHECK_LIB(util, openpty)
 541 AC_CHECK_FUNCS([openpty hasmntopt setmntent endmntent utmpxname])
 542 AC_CHECK_FUNCS([getline],
 543         AM_CONDITIONAL(HAVE_GETLINE, true)
 544         AC_DEFINE(HAVE_GETLINE,1,[Have getline]),
 545         AM_CONDITIONAL(HAVE_GETLINE, false))
 546 AC_CHECK_FUNCS([fgetln],
 547         AM_CONDITIONAL(HAVE_FGETLN, true)
 548         AC_DEFINE(HAVE_FGETLN,1,[Have fgetln]),
 549         AM_CONDITIONAL(HAVE_FGETLN, false))
 550
 551 # Check for some libraries
 552 AC_SEARCH_LIBS(sem_open, [rt pthread])
 553 AC_SEARCH_LIBS(clock_gettime, [rt])
 554
 555 # Check for some standard binaries
 556 AC_PROG_GCC_TRADITIONAL
 557 AC_PROG_SED
 558
 559 # See if we support thread-local storage.
 560 LXC_CHECK_TLS
 561
 562 if test "x$GCC" = "xyes"; then
 563         CFLAGS="$CFLAGS -Wall -Werror"
 564 fi
 565
 566 # Files requiring some variable expansion
 567 AC_CONFIG_FILES([
 568         Makefile
 569         lxc.pc
 570         lxc.spec
 571
 572         config/Makefile
 573         config/apparmor/Makefile
 574         config/bash/Makefile
 575         config/bash/lxc
 576         config/init/Makefile
 577         config/init/sysvinit/Makefile
 578         config/init/sysvinit/lxc
 579         config/init/systemd/Makefile
 580         config/init/systemd/lxc.service
 581         config/init/upstart/Makefile
 582         config/etc/Makefile
 583         config/templates/Makefile
 584         config/templates/centos.common.conf
 585         config/templates/centos.userns.conf
 586         config/templates/debian.common.conf
 587         config/templates/debian.userns.conf
 588         config/templates/fedora.common.conf
 589         config/templates/fedora.userns.conf
 590         config/templates/gentoo.common.conf
 591         config/templates/gentoo.moresecure.conf
 592         config/templates/gentoo.userns.conf
 593         config/templates/oracle.common.conf
 594         config/templates/oracle.userns.conf
 595         config/templates/plamo.common.conf
 596         config/templates/plamo.userns.conf
 597         config/templates/ubuntu-cloud.common.conf
 598         config/templates/ubuntu-cloud.lucid.conf
 599         config/templates/ubuntu-cloud.userns.conf
 600         config/templates/ubuntu.common.conf
 601         config/templates/ubuntu.lucid.conf
 602         config/templates/ubuntu.userns.conf
 603         config/yum/Makefile
 604
 605         doc/Makefile
 606         doc/api/Makefile
 607         doc/legacy/lxc-ls.sgml
 608         doc/lxc-attach.sgml
 609         doc/lxc-autostart.sgml
 610         doc/lxc-cgroup.sgml
 611         doc/lxc-checkconfig.sgml
 612         doc/lxc-clone.sgml
 613         doc/lxc-config.sgml
 614         doc/lxc-console.sgml
 615         doc/lxc-create.sgml
 616         doc/lxc-destroy.sgml
 617         doc/lxc-device.sgml
 618         doc/lxc-execute.sgml
 619         doc/lxc-freeze.sgml
 620         doc/lxc-info.sgml
 621         doc/lxc-ls.sgml
 622         doc/lxc-monitor.sgml
 623         doc/lxc-snapshot.sgml
 624         doc/lxc-start-ephemeral.sgml
 625         doc/lxc-start.sgml
 626         doc/lxc-stop.sgml
 627         doc/lxc-top.sgml
 628         doc/lxc-unfreeze.sgml
 629         doc/lxc-unshare.sgml
 630         doc/lxc-user-nic.sgml
 631         doc/lxc-usernsexec.sgml
 632         doc/lxc-wait.sgml
 633
 634         doc/lxc.conf.sgml
 635         doc/lxc.container.conf.sgml
 636         doc/lxc.system.conf.sgml
 637         doc/lxc-usernet.sgml
 638         doc/lxc.sgml
 639         doc/common_options.sgml
 640         doc/see_also.sgml
 641
 642         doc/rootfs/Makefile
 643
 644         doc/examples/Makefile
 645         doc/examples/lxc-macvlan.conf
 646         doc/examples/lxc-vlan.conf
 647         doc/examples/lxc-no-netns.conf
 648         doc/examples/lxc-empty-netns.conf
 649         doc/examples/lxc-phys.conf
 650         doc/examples/lxc-veth.conf
 651         doc/examples/lxc-complex.conf
 652
 653         doc/ja/Makefile
 654         doc/ja/legacy/lxc-ls.sgml
 655         doc/ja/lxc-attach.sgml
 656         doc/ja/lxc-autostart.sgml
 657         doc/ja/lxc-cgroup.sgml
 658         doc/ja/lxc-checkconfig.sgml
 659         doc/ja/lxc-clone.sgml
 660         doc/ja/lxc-config.sgml
 661         doc/ja/lxc-console.sgml
 662         doc/ja/lxc-create.sgml
 663         doc/ja/lxc-destroy.sgml
 664         doc/ja/lxc-device.sgml
 665         doc/ja/lxc-execute.sgml
 666         doc/ja/lxc-freeze.sgml
 667         doc/ja/lxc-info.sgml
 668         doc/ja/lxc-ls.sgml
 669         doc/ja/lxc-monitor.sgml
 670         doc/ja/lxc-snapshot.sgml
 671         doc/ja/lxc-start-ephemeral.sgml
 672         doc/ja/lxc-start.sgml
 673         doc/ja/lxc-stop.sgml
 674         doc/ja/lxc-top.sgml
 675         doc/ja/lxc-unfreeze.sgml
 676         doc/ja/lxc-unshare.sgml
 677         doc/ja/lxc-user-nic.sgml
 678         doc/ja/lxc-usernsexec.sgml
 679         doc/ja/lxc-wait.sgml
 680
 681         doc/ja/lxc.conf.sgml
 682         doc/ja/lxc.container.conf.sgml
 683         doc/ja/lxc.system.conf.sgml
 684         doc/ja/lxc-usernet.sgml
 685         doc/ja/lxc.sgml
 686         doc/ja/common_options.sgml
 687         doc/ja/see_also.sgml
 688
 689         hooks/Makefile
 690
 691         templates/Makefile
 692         templates/lxc-alpine
 693         templates/lxc-altlinux
 694         templates/lxc-archlinux
 695         templates/lxc-busybox
 696         templates/lxc-centos
 697         templates/lxc-cirros
 698         templates/lxc-debian
 699         templates/lxc-download
 700         templates/lxc-fedora
 701         templates/lxc-gentoo
 702         templates/lxc-openmandriva
 703         templates/lxc-opensuse
 704         templates/lxc-oracle
 705         templates/lxc-plamo
 706         templates/lxc-sshd
 707         templates/lxc-ubuntu
 708         templates/lxc-ubuntu-cloud
 709
 710         src/Makefile
 711         src/lxc/Makefile
 712         src/lxc/lxc-checkconfig
 713         src/lxc/lxc-ls
 714         src/lxc/lxc-start-ephemeral
 715         src/lxc/legacy/lxc-ls
 716         src/lxc/lxc.functions
 717         src/lxc/version.h
 718         src/python-lxc/Makefile
 719
 720         src/lua-lxc/Makefile
 721
 722         src/tests/Makefile
 723         src/tests/lxc-test-usernic
 724 ])
 725 AC_CONFIG_COMMANDS([default],[[]],[[]])
 726 AC_OUTPUT
 727
 728 # Configuration overview
 729 cat << EOF
 730
 731 ----------------------------
 732 Environment:
 733  - compiler: $CC
 734  - distribution: $with_distro
 735  - init script type(s): $init_script
 736  - rpath: $enable_rpath
 737  - GnuTLS: $enable_gnutls
 738  - Bash integration: $enable_bash
 739
 740 Security features:
 741  - Apparmor: $enable_apparmor
 742  - Linux capabilities: $enable_capabilities
 743  - seccomp: $enable_seccomp
 744  - SELinux: $enable_selinux
 745  - cgmanager: $enable_cgmanager
 746
 747 Bindings:
 748  - lua: $enable_lua
 749  - python3: $enable_python
 750
 751 Documentation:
 752  - examples: $enable_examples
 753  - API documentation: $enable_api_docs
 754  - user documentation: $enable_doc
 755
 756 Debugging:
 757  - tests: $enable_tests
 758  - mutex debugging: $enable_mutex_debugging
 759
 760 Paths:
 761  - Logs in configpath: $enable_configpath_log
 762 EOF
 763
 764 if test "x$ac_cv_func_pthread_atfork" = "xno" ; then
 765 cat << EOF
 766
 767 WARNING: Threading not supported on your platform
 768
 769         You are compiling LXC for bionic target which lacks certain threading related functionality used by LXC API (like pthread_atfork).
 770         Please note that, because of the missing functionality, multithreaded usage of LXC API cause some problems.
 771 EOF
 772 fi