configure.ac

   1 ##
   2 ## Configure template file for FRRouting.
   3 ## autoconf will generate a configure script.
   4 ##
   5 ##  Copyright (c) 1996, 97, 98, 99, 2000 Kunihiro Ishiguro <kunihiro@zebra.org>
   6 ##  Portions Copyright (c) 2003 Paul Jakma <paul@dishone.st>
   7 ##
   8 AC_PREREQ([2.69])
   9
  10 AC_INIT([frr], [8.1-dev], [https://github.com/frrouting/frr/issues])
  11 PACKAGE_URL="https://frrouting.org/"
  12 AC_SUBST([PACKAGE_URL])
  13 PACKAGE_FULLNAME="FRRouting"
  14 AC_SUBST([PACKAGE_FULLNAME])
  15
  16 CONFIG_ARGS="`echo $ac_configure_args | sed -e \"s% '[[A-Z]]*FLAGS=[[^']]\+'%%g\"`"
  17 AC_SUBST([CONFIG_ARGS])
  18
  19 AC_CONFIG_SRCDIR([lib/zebra.h])
  20 AC_CONFIG_MACRO_DIR([m4])
  21 AC_CONFIG_AUX_DIR([m4/ac])
  22
  23 dnl -----------------------------------
  24 dnl Get hostname and other information.
  25 dnl -----------------------------------
  26 AC_CANONICAL_BUILD()
  27 AC_CANONICAL_HOST()
  28
  29 AC_ARG_VAR([AR],[archiver command])
  30 AC_ARG_VAR([LD],[linker command])
  31 AC_ARG_VAR([OBJCOPY],[objcopy command])
  32 AC_ARG_VAR([OBJDUMP],[objdump command])
  33 AC_ARG_VAR([RANLIB],[ranlib command])
  34 AC_ARG_VAR([STRIP],[strip command])
  35
  36 hosttools_clippy="false"
  37 build_clippy="true"
  38
  39 dnl case 1: external clippy
  40 if test -n "$with_clippy" -a "$with_clippy" != "no" -a "$with_clippy" != "yes"; then
  41   if test "$enable_clippy_only" = "yes"; then
  42     AC_MSG_ERROR([--enable-clippy-only does not make sense with --with-clippy])
  43   fi
  44
  45   CLIPPY="$with_clippy"
  46   build_clippy="false"
  47   if test ! -x "$with_clippy"; then
  48     AC_MSG_ERROR([clippy tool ($with_clippy) is not executable])
  49   fi
  50
  51 dnl case 2: cross-compiling internal clippy
  52 elif test "$host" != "$build"; then
  53   if test "$srcdir" = "."; then
  54     AC_MSG_ERROR([cross-compilation is only possible with builddir separate from srcdir or by building clippy separately and using the --with-clippy option.  create a separate directory and run as .../path-to-frr/configure.])
  55   fi
  56   test -d hosttools || mkdir hosttools
  57   abssrc="`cd \"${srcdir}\"; pwd`"
  58
  59   AC_MSG_NOTICE([...])
  60   AC_MSG_NOTICE([... cross-compilation: creating hosttools directory and self-configuring for build platform tools])
  61   AC_MSG_NOTICE([... use HOST_CPPFLAGS / HOST_CFLAGS / HOST_LDFLAGS if neccessary])
  62   AC_MSG_NOTICE([...])
  63
  64   (
  65     for var in $ac_precious_vars; do
  66       dnl special cases
  67       case "$var" in
  68       YACC|YFLAGS) continue;;
  69       PYTHON*)     retain=true;;
  70       *)           retain=false;
  71       esac
  72
  73       eval "hostvar=\"\${HOST_$var}\""
  74       eval "targetvar=\"\${$var}\""
  75       if test -n "$hostvar"; then
  76         eval "$var='$hostvar'"
  77         _AS_ECHO_LOG([host $var='$hostvar'])
  78       elif $retain; then
  79         _AS_ECHO_LOG([host retain $var='$targetvar'])
  80       else
  81         eval "unset $var"
  82         _AS_ECHO_LOG([host unset $var])
  83       fi
  84     done
  85     cd hosttools
  86     "${abssrc}/configure" "--host=$build" "--build=$build" "--enable-clippy-only" "--disable-nhrpd" "--disable-vtysh"
  87   ) || exit 1
  88
  89   AC_MSG_NOTICE([...])
  90   AC_MSG_NOTICE([... cross-compilation: finished self-configuring for build platform tools])
  91   AC_MSG_NOTICE([...])
  92
  93   build_clippy="false"
  94   hosttools_clippy="true"
  95   CLIPPY="hosttools/lib/clippy"
  96
  97 dnl case 3: normal build internal clippy
  98 else
  99   CLIPPY="lib/clippy\$(EXEEXT)"
 100 fi
 101 AC_SUBST([CLIPPY])
 102 AM_CONDITIONAL([BUILD_CLIPPY], [$build_clippy])
 103 AM_CONDITIONAL([HOSTTOOLS_CLIPPY], [$hosttools_clippy])
 104 AM_CONDITIONAL([ONLY_CLIPPY], [test "$enable_clippy_only" = "yes"])
 105
 106 # Disable portability warnings -- our automake code (in particular
 107 # common.am) uses some constructs specific to gmake.
 108 AM_INIT_AUTOMAKE([1.12 -Wno-portability foreign])
 109 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
 110 AM_SILENT_RULES([yes])
 111 AC_CONFIG_HEADERS([config.h])
 112
 113 AC_PATH_PROG([PERL], [perl])
 114 PKG_PROG_PKG_CONFIG
 115
 116 dnl default is to match previous behavior
 117 pkgsrcrcdir=""
 118 AC_ARG_ENABLE([pkgsrcrcdir],
 119           AS_HELP_STRING([--enable-pkgsrcrcdir],
 120                          [specify directory for rc.d scripts]),
 121                          pkgsrcrcdir="$enableval",)
 122 dnl XXX add --pkgsrcrcdir to autoconf standard directory list somehow
 123 AC_SUBST([pkgsrcrcdir])
 124 AM_CONDITIONAL([PKGSRC], [test "$pkgsrcrcdir" != ""])
 125
 126 AC_ARG_WITH([moduledir], [AS_HELP_STRING([--with-moduledir=DIR], [module directory (${libdir}/frr/modules)])], [
 127         moduledir="$withval"
 128 ], [
 129         moduledir="\${libdir}/frr/modules"
 130 ])
 131 AC_SUBST([moduledir], [$moduledir])
 132
 133 AC_ARG_WITH([scriptdir], [AS_HELP_STRING([--with-scriptdir=DIR], [script directory (${sysconfdir}/scripts)])], [
 134         scriptdir="$withval"
 135 ], [
 136         scriptdir="\${sysconfdir}/scripts"
 137 ])
 138 AC_SUBST([scriptdir], [$scriptdir])
 139
 140 AC_ARG_WITH([yangmodelsdir], [AS_HELP_STRING([--with-yangmodelsdir=DIR], [yang models directory (${datarootdir}/yang)])], [
 141         yangmodelsdir="$withval"
 142 ], [
 143         yangmodelsdir="\${datarootdir}/yang"
 144 ])
 145 AC_SUBST([yangmodelsdir])
 146
 147 AC_ARG_WITH([vici-socket], [AS_HELP_STRING([--with-vici-socket=PATH], [vici-socket (/var/run/charon.vici)])], [
 148         vici_socket="$withval"
 149 ], [
 150         vici_socket="/var/run/charon.vici"
 151 ])
 152 AC_DEFINE_UNQUOTED([VICI_SOCKET], ["$vici_socket"], [StrongSWAN vici socket path])
 153
 154 AC_ARG_ENABLE(tcmalloc,
 155         AS_HELP_STRING([--enable-tcmalloc], [Turn on tcmalloc]),
 156 [case "${enableval}" in
 157   yes) tcmalloc_enabled=true
 158 LIBS="$LIBS -ltcmalloc_minimal"
 159  ;;
 160   no)  tcmalloc_enabled=false ;;
 161   *) AC_MSG_ERROR([bad value ${enableval} for --enable-tcmalloc]) ;;
 162 esac],[tcmalloc_enabled=false])
 163
 164
 165 dnl Thanks autoconf, but we don't want a default -g -O2.  We have our own
 166 dnl flag determination logic.
 167 CFLAGS="${CFLAGS:-}"
 168
 169 dnl --------------------
 170 dnl Check CC and friends
 171 dnl --------------------
 172 dnl note orig_cflags is also used further down
 173 orig_cflags="$CFLAGS"
 174 orig_cxxflags="$CXXFLAGS"
 175 AC_LANG([C])
 176 AC_PROG_CC
 177 AC_PROG_CPP
 178 AC_PROG_CXX
 179 AM_PROG_CC_C_O
 180 dnl remove autoconf default "-g -O2"
 181 CFLAGS="$orig_cflags"
 182 CXXFLAGS="$orig_cxxflags"
 183 AC_PROG_CC_C99
 184 dnl NB: see C11 below
 185
 186 dnl Some special handling for ICC later on
 187 if test "$CC" = "icc"; then
 188     cc_is_icc="yes"
 189 fi
 190
 191 PKG_PROG_PKG_CONFIG
 192
 193 dnl it's 2019, sed is sed.
 194 SED=sed
 195 AC_SUBST([SED])
 196
 197 dnl try and enable CFLAGS that are useful for FRR
 198 dnl - specifically, options to control warnings
 199
 200 AC_SUBST([AC_CFLAGS])
 201 AC_USE_SYSTEM_EXTENSIONS
 202 AC_DEFUN([AC_C_FLAG], [{
 203     m4_pushdef([cachename],[m4_translit([frr_cv_$1],[ =-+/{}$],[________])])
 204     AC_CACHE_CHECK([[whether $CC supports $1]], cachename, [
 205         AC_LANG_PUSH([C])
 206         ac_c_flag_save="$CFLAGS"
 207         CFLAGS="$CFLAGS $1"
 208         AC_COMPILE_IFELSE(
 209                 [AC_LANG_PROGRAM([[$4]])],
 210                 [
 211                         cachename=yes
 212                 ], [
 213                         cachename=no
 214                 ])
 215         CFLAGS="$ac_c_flag_save"
 216         AC_LANG_POP([C])
 217     ])
 218     if test "$cachename" = "yes"; then
 219         m4_if([$3], [], [AC_CFLAGS="$AC_CFLAGS $1"], [$3])
 220     else
 221         :
 222         $2
 223     fi
 224     m4_popdef([cachename])
 225 }])
 226
 227 AC_DEFUN([AC_LINK_IFELSE_FLAGS], [{
 228         AC_LANG_PUSH([C])
 229         ac_cflags_save="$CFLAGS"
 230         ac_libs_save="$LIBS"
 231         CFLAGS="$CFLAGS $1"
 232         LIBS="$LIBS $2"
 233         AC_LINK_IFELSE(
 234                 [$3],
 235                 [
 236                         CFLAGS="$ac_cflags_save"
 237                         LIBS="$ac_libs_save"
 238                         m4_default([$5], [
 239                                 AC_MSG_RESULT([yes])
 240                         ])
 241                 ], [
 242                         CFLAGS="$ac_cflags_save"
 243                         LIBS="$ac_libs_save"
 244                         m4_default([$4], [
 245                                 AC_MSG_RESULT([no])
 246                         ])
 247                 ])
 248         AC_LANG_POP([C])
 249         }])
 250
 251 dnl ICC won't bail on unknown options without -diag-error 10006
 252 dnl need to do this first so we get useful results for the other options
 253 if test "$cc_is_icc" = "yes"; then
 254     AC_C_FLAG([-diag-error 10006])
 255 fi
 256
 257 dnl AC_PROG_CC_C99 may change CC to include -std=gnu99 or something
 258 ac_cc="$CC"
 259 CC="${CC% -std=gnu99}"
 260 CC="${CC% -std=c99}"
 261
 262 AC_C_FLAG([-std=gnu11], [CC="$ac_cc"], [CC="$CC -std=gnu11"])
 263
 264 dnl if the user has specified any CFLAGS, override our settings
 265 if test "$enable_gcov" = "yes"; then
 266    if test "$orig_cflags" = ""; then
 267       AC_C_FLAG([-coverage])
 268       AC_C_FLAG([-O0])
 269    fi
 270
 271    AC_LDFLAGS="${AC_LDFLAGS} -lgcov"
 272 fi
 273
 274 if test "$enable_clang_coverage" = "yes"; then
 275    AC_C_FLAG([-fprofile-instr-generate], [
 276      AC_MSG_ERROR([$CC does not support -fprofile-instr-generate.])
 277    ])
 278    AC_C_FLAG([-fcoverage-mapping], [
 279      AC_MSG_ERROR([$CC does not support -fcoverage-mapping.])
 280    ])
 281 fi
 282
 283 if test "$enable_scripting" = "yes"; then
 284    AX_PROG_LUA([5.3], [5.4], [], [
 285      AC_MSG_ERROR([Lua 5.3 is required to build with Lua support. No other version is supported.])
 286    ])
 287    AX_LUA_HEADERS([], [
 288      AC_MSG_ERROR([Lua 5.3 headers are required to build with Lua support. No other version is supported.])
 289    ])
 290    AX_LUA_LIBS([
 291      AC_DEFINE([HAVE_SCRIPTING], [1], [Have support for scripting])
 292      LIBS="$LIBS $LUA_LIB"
 293    ], [
 294      AC_MSG_ERROR([Lua 5.3 libraries are required to build with Lua support. No other version is supported.])
 295    ])
 296 fi
 297
 298 dnl the following flags go in CFLAGS rather than AC_CFLAGS since they make
 299 dnl sense to be overridden by the user
 300 if test "$enable_dev_build" = "yes"; then
 301    AC_DEFINE([DEV_BUILD], [1], [Build for development])
 302    if test "$orig_cflags" = ""; then
 303       AC_C_FLAG([-O0],,[CFLAGS="$CFLAGS -O0"])
 304       AC_C_FLAG([-g3],,[CFLAGS="$CFLAGS -g3"])
 305       AC_C_FLAG([-ggdb3],,[CFLAGS="$CFLAGS -ggdb3"])
 306    fi
 307 else
 308    if test "$orig_cflags" = ""; then
 309       AC_C_FLAG([-g],,[CFLAGS="$CFLAGS -g"])
 310       AC_C_FLAG([-O2],,[CFLAGS="$CFLAGS -O2"])
 311    fi
 312 fi
 313
 314 AM_CONDITIONAL([DEV_BUILD], [test "$enable_dev_build" = "yes"])
 315
 316 dnl always want these CFLAGS
 317 AC_C_FLAG([-fno-omit-frame-pointer])
 318 AC_C_FLAG([-funwind-tables])
 319 AC_C_FLAG([-Wall])
 320 AC_C_FLAG([-Wextra])
 321 AC_C_FLAG([-Wmissing-prototypes])
 322 AC_C_FLAG([-Wmissing-declarations])
 323 AC_C_FLAG([-Wpointer-arith])
 324 AC_C_FLAG([-Wbad-function-cast])
 325 AC_C_FLAG([-Wwrite-strings])
 326 AC_C_FLAG([-Wundef])
 327 if test "$enable_gcc_ultra_verbose" = "yes" ; then
 328   AC_C_FLAG([-Wcast-qual])
 329   AC_C_FLAG([-Wstrict-prototypes])
 330   AC_C_FLAG([-Wmissing-noreturn])
 331   AC_C_FLAG([-Wmissing-format-attribute])
 332   AC_C_FLAG([-Wunreachable-code])
 333   AC_C_FLAG([-Wpacked])
 334   AC_C_FLAG([-Wpadded])
 335   AC_C_FLAG([-Wshadow])
 336 else
 337   AC_C_FLAG([-Wno-unused-result])
 338 fi
 339 AC_C_FLAG([-Wno-unused-parameter])
 340 AC_C_FLAG([-Wno-missing-field-initializers])
 341
 342 AC_C_FLAG([-Wc++-compat], [], [CXX_COMPAT_CFLAGS="-Wc++-compat"])
 343 AC_SUBST([CXX_COMPAT_CFLAGS])
 344
 345 dnl ICC emits a broken warning for const char *x = a ? "b" : "c";
 346 dnl for some reason the string consts get 'promoted' to char *,
 347 dnl triggering a const to non-const conversion warning.
 348 if test "$cc_is_icc" = "yes"; then
 349     AC_C_FLAG([-diag-disable 3179])
 350 fi
 351
 352 if test "$enable_werror" = "yes" ; then
 353   WERROR="-Werror"
 354 fi
 355 AC_SUBST([WERROR])
 356
 357 SAN_FLAGS=""
 358 if test "$enable_address_sanitizer" = "yes"; then
 359   AC_C_FLAG([-fsanitize=address], [
 360     AC_MSG_ERROR([$CC does not support Address Sanitizer.])
 361   ], [
 362     SAN_FLAGS="$SAN_FLAGS -fsanitize=address"
 363   ])
 364 fi
 365 if test "$enable_thread_sanitizer" = "yes"; then
 366   AC_C_FLAG([-fsanitize=thread], [
 367     AC_MSG_ERROR([$CC does not support Thread Sanitizer.])
 368   ], [
 369     SAN_FLAGS="$SAN_FLAGS -fsanitize=thread"
 370   ])
 371 fi
 372 if test "$enable_memory_sanitizer" = "yes"; then
 373   AC_C_FLAG([-fsanitize=memory -fPIE -pie], [
 374     AC_MSG_ERROR([$CC does not support Memory Sanitizer.])
 375   ], [
 376     SAN_FLAGS="$SAN_FLAGS -fsanitize=memory -fPIE -pie"
 377   ])
 378 fi
 379 if test "$enable_undefined_sanitizer" = "yes"; then
 380   AC_C_FLAG([-fsanitize=undefined], [
 381     AC_MSG_ERROR([$CC does not support UndefinedBehaviorSanitizer.])
 382   ], [
 383     SAN_FLAGS="$SAN_FLAGS -fsanitize=undefined"
 384   ])
 385 fi
 386 AC_SUBST([SAN_FLAGS])
 387
 388 dnl frr-format.so
 389 if test "$with_frr_format" != "no" -a "$with_frr_format" != "yes" -a -n "$with_frr_format"; then
 390   AC_C_FLAG([-fplugin=${with_frr_format}], [
 391     AC_MSG_ERROR([specified frr-format plugin ($with_frr_format) does not work])
 392   ],,[
 393 #ifndef _FRR_ATTRIBUTE_PRINTFRR
 394 #error plugin not loaded
 395 #endif
 396 #if _FRR_ATTRIBUTE_PRINTFRR < 0x10000
 397 #error plugin too old
 398 #endif
 399   ])
 400 elif test "$with_frr_format" = "no"; then
 401   : #nothing
 402 else
 403   AC_C_FLAG([-fplugin=tools/gcc-plugins/frr-format.so],[
 404     AC_C_FLAG([-fplugin=frr-format],[
 405       if test "$with_frr_format" = "yes"; then
 406         AC_MSG_ERROR([frr-format plugin requested but not found])
 407       fi
 408     ],,[
 409 #ifndef _FRR_ATTRIBUTE_PRINTFRR
 410 #error plugin not loaded
 411 #endif
 412 #if _FRR_ATTRIBUTE_PRINTFRR < 0x10000
 413 #error plugin too old
 414 #endif
 415     ])
 416   ],,[
 417 #ifndef _FRR_ATTRIBUTE_PRINTFRR
 418 #error plugin not loaded
 419 #endif
 420 #if _FRR_ATTRIBUTE_PRINTFRR < 0x10000
 421 #error plugin too old
 422 #endif
 423   ])
 424 fi
 425
 426 AC_MSG_CHECKING([whether linker supports __start/stop_section symbols])
 427 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 428 #include <stdio.h>
 429 int __attribute__((section("secttest"))) var = 1;
 430 extern int __start_secttest, __stop_secttest;
 431 ]], [[
 432   void *a = &var, *b = &__start_secttest, *c = &__stop_secttest;
 433   printf("%p %p %p\n", a, b, c);
 434 ]])], [
 435   AC_MSG_RESULT(yes)
 436   AC_DEFINE(HAVE_SECTION_SYMS, 1, [have __start/stop_section symbols])
 437 ], [
 438   AC_MSG_RESULT(no)
 439 ])
 440
 441 dnl ----------
 442 dnl Essentials
 443 dnl ----------
 444
 445 AX_PTHREAD([
 446   CC="$PTHREAD_CC"
 447   AC_CFLAGS="$AC_CFLAGS $PTHREAD_CFLAGS"
 448   LIBS="$PTHREAD_LIBS $LIBS"
 449 ], [
 450   AC_MSG_FAILURE([This FRR version needs pthreads])
 451 ])
 452
 453 orig_cflags="$CFLAGS"
 454 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 455
 456 AC_SEARCH_LIBS([pthread_condattr_setclock], [],
 457                 [frr_cv_pthread_condattr_setclock=yes],
 458                 [frr_cv_pthread_condattr_setclock=no])
 459 if test "$frr_cv_pthread_condattr_setclock" = "yes"; then
 460   AC_DEFINE([HAVE_PTHREAD_CONDATTR_SETCLOCK], [1], [Have pthread.h pthread_condattr_setclock])
 461 fi
 462
 463 AC_CHECK_HEADERS([pthread_np.h],,, [
 464 #include <pthread.h>
 465 ])
 466 AC_CHECK_FUNCS([pthread_setname_np pthread_set_name_np pthread_getthreadid_np])
 467
 468 CFLAGS="$orig_cflags"
 469
 470 dnl --------------
 471 dnl Check programs
 472 dnl --------------
 473 AC_PROG_INSTALL
 474 AC_PROG_LN_S
 475 AC_CHECK_TOOL([AR], [ar])
 476
 477 dnl -------
 478 dnl libtool
 479 dnl -------
 480 AC_ARG_ENABLE([static-bin],
 481   AS_HELP_STRING([--enable-static-bin], [link binaries statically]))
 482 LT_INIT
 483 _LT_CONFIG_LIBTOOL([
 484   patch -N -i "${srcdir}/m4/libtool-whole-archive.patch" libtool >&AS_MESSAGE_LOG_FD || \
 485     AC_MSG_WARN([Could not patch libtool for static linking support.  Loading modules into a statically linked daemon will fail.])
 486   sed -e 's%func_warning "relinking%true #\0%' -i libtool || true
 487   sed -e 's%func_warning "remember to run%true #\0%' -i libtool || true
 488   sed -e 's%func_warning ".*has not been installed in%true #\0%' -i libtool || true
 489 ])
 490 if test "$enable_static_bin" = "yes"; then
 491   AC_LDFLAGS="-static"
 492   if test "$enable_static" != "yes"; then
 493     AC_MSG_ERROR([The --enable-static-bin option must be combined with --enable-static.])
 494   fi
 495 fi
 496 if test "$enable_shared" != "yes"; then
 497   AC_MSG_ERROR([FRR cannot be built with --disable-shared.  If you want statically linked daemons, use --enable-shared --enable-static --enable-static-bin])
 498 fi
 499 AC_SUBST([AC_LDFLAGS])
 500 AM_CONDITIONAL([STATIC_BIN], [test "$enable_static_bin" = "yes"])
 501
 502 AC_ARG_ENABLE([rpath],
 503   [AS_HELP_STRING([--enable-rpath], [set hardcoded rpaths in the executable @<:@default=yes@:>@])],
 504   [],
 505   [enable_rpath=yes])
 506
 507 dnl $AR and $RANLIB are set by LT_INIT above
 508 AC_MSG_CHECKING([whether $AR supports D option])
 509 if $AR crD conftest.a >/dev/null 2>/dev/null; then
 510   AC_MSG_RESULT([yes])
 511   dnl ARFLAGS is for automake, AR_FLAGS for libtool m-(
 512   ARFLAGS="crD"
 513   AR_FLAGS="crD"
 514 else
 515   AC_MSG_RESULT([no])
 516   ARFLAGS="cru"
 517   AR_FLAGS="cru"
 518 fi
 519 AC_SUBST([ARFLAGS])
 520 AC_SUBST([AR_FLAGS])
 521
 522 AC_MSG_CHECKING([whether $RANLIB supports D option])
 523 if $RANLIB -D conftest.a >conftest.err 2>&1; then
 524   if grep -q -- '-D' conftest.err; then
 525     AC_MSG_RESULT([no])
 526   else
 527     AC_MSG_RESULT([yes])
 528     RANLIB="$RANLIB -D"
 529   fi
 530 else
 531   AC_MSG_RESULT([no])
 532 fi
 533 AC_SUBST([RANLIB])
 534
 535 test -f conftest.err && rm conftest.err
 536 test -f conftest.a && rm conftest.a
 537
 538 dnl ----------------------
 539 dnl Packages configuration
 540 dnl ----------------------
 541 if test -f config.version; then
 542   . ./config.version
 543 elif test -f "${srcdir}/config.version"; then
 544   . "${srcdir}/config.version"
 545 fi
 546 AC_ARG_WITH([pkg-extra-version],
 547   AS_HELP_STRING([--with-pkg-extra-version=VER], [add extra version field, for packagers/distributions]), [
 548   if test "$withval" = "no"; then
 549     EXTRAVERSION=
 550   else
 551     EXTRAVERSION=$withval
 552   fi
 553 ], [])
 554 AC_ARG_WITH([pkg-git-version],
 555         AS_HELP_STRING([--with-pkg-git-version], [add git information to MOTD and build version string]),
 556         [ test "$withval" != "no" && with_pkg_git_version="yes" ])
 557 AC_ARG_WITH([clippy],
 558   AS_HELP_STRING([--with-clippy=PATH], [use external clippy helper program]))
 559 AC_ARG_WITH([vtysh_pager],
 560         AS_HELP_STRING([--with-vtysh-pager=PAGER], [control what pager is compiled in as default]),
 561         VTYSH_PAGER=$withval, VTYSH_PAGER="more")
 562 AC_ARG_ENABLE([vtysh],
 563   AS_HELP_STRING([--disable-vtysh], [do not build integrated vty shell for FRR]))
 564 AC_ARG_ENABLE([doc],
 565   AS_HELP_STRING([--disable-doc], [do not build docs]))
 566 AC_ARG_ENABLE([doc-html],
 567   AS_HELP_STRING([--enable-doc-html], [build HTML docs]))
 568 AC_ARG_ENABLE([zebra],
 569   AS_HELP_STRING([--disable-zebra], [do not build zebra daemon]))
 570 AC_ARG_ENABLE([bgpd],
 571   AS_HELP_STRING([--disable-bgpd], [do not build bgpd]))
 572 AC_ARG_ENABLE([ripd],
 573   AS_HELP_STRING([--disable-ripd], [do not build ripd]))
 574 AC_ARG_ENABLE([ripngd],
 575   AS_HELP_STRING([--disable-ripngd], [do not build ripngd]))
 576 AC_ARG_ENABLE([ospfd],
 577   AS_HELP_STRING([--disable-ospfd], [do not build ospfd]))
 578 AC_ARG_ENABLE([ospf6d],
 579   AS_HELP_STRING([--disable-ospf6d], [do not build ospf6d]))
 580 AC_ARG_ENABLE([ldpd],
 581   AS_HELP_STRING([--disable-ldpd], [do not build ldpd]))
 582 AC_ARG_ENABLE([nhrpd],
 583   AS_HELP_STRING([--disable-nhrpd], [do not build nhrpd]))
 584 AC_ARG_ENABLE([eigrpd],
 585   AS_HELP_STRING([--disable-eigrpd], [do not build eigrpd]))
 586 AC_ARG_ENABLE([babeld],
 587   AS_HELP_STRING([--disable-babeld], [do not build babeld]))
 588 AC_ARG_ENABLE([watchfrr],
 589   AS_HELP_STRING([--disable-watchfrr], [do not build watchfrr]))
 590 AC_ARG_ENABLE([isisd],
 591   AS_HELP_STRING([--disable-isisd], [do not build isisd]))
 592 AC_ARG_ENABLE([pimd],
 593   AS_HELP_STRING([--disable-pimd], [do not build pimd]))
 594 AC_ARG_ENABLE([pbrd],
 595   AS_HELP_STRING([--disable-pbrd], [do not build pbrd]))
 596 AC_ARG_ENABLE([sharpd],
 597   AS_HELP_STRING([--enable-sharpd], [build sharpd]))
 598 AC_ARG_ENABLE([staticd],
 599   AS_HELP_STRING([--disable-staticd], [do not build staticd]))
 600 AC_ARG_ENABLE([fabricd],
 601   AS_HELP_STRING([--disable-fabricd], [do not build fabricd]))
 602 AC_ARG_ENABLE([vrrpd],
 603   AS_HELP_STRING([--disable-vrrpd], [do not build vrrpd]))
 604 AC_ARG_ENABLE([pathd],
 605   AS_HELP_STRING([--disable-pathd], [do not build pathd]))
 606 AC_ARG_ENABLE([bgp-announce],
 607   AS_HELP_STRING([--disable-bgp-announce], [turn off BGP route announcement]))
 608 AC_ARG_ENABLE([bgp-vnc],
 609   AS_HELP_STRING([--disable-bgp-vnc],[turn off BGP VNC support]))
 610 AC_ARG_ENABLE([bgp-bmp],
 611   AS_HELP_STRING([--disable-bgp-bmp],[turn off BGP BMP support]))
 612 AC_ARG_ENABLE([snmp],
 613   AS_HELP_STRING([--enable-snmp], [enable SNMP support for agentx]))
 614 AC_ARG_ENABLE([config_rollbacks],
 615   AS_HELP_STRING([--enable-config-rollbacks], [enable configuration rollbacks (requires sqlite3)]))
 616 AC_ARG_ENABLE([confd],
 617   AS_HELP_STRING([--enable-confd=ARG], [enable confd integration]))
 618 AC_ARG_ENABLE([sysrepo],
 619   AS_HELP_STRING([--enable-sysrepo], [enable sysrepo integration]))
 620 AC_ARG_ENABLE([grpc],
 621   AS_HELP_STRING([--enable-grpc], [enable the gRPC northbound plugin]))
 622 AC_ARG_ENABLE([zeromq],
 623   AS_HELP_STRING([--enable-zeromq], [enable ZeroMQ handler (libfrrzmq)]))
 624 AC_ARG_ENABLE([lttng],
 625   AS_HELP_STRING([--enable-lttng], [enable LTTng tracing]))
 626 AC_ARG_ENABLE([usdt],
 627   AS_HELP_STRING([--enable-usdt], [enable USDT probes]))
 628 AC_ARG_WITH([libpam],
 629   AS_HELP_STRING([--with-libpam], [use libpam for PAM support in vtysh]))
 630 AC_ARG_ENABLE([ospfapi],
 631   AS_HELP_STRING([--disable-ospfapi], [do not build OSPFAPI to access the OSPF LSA Database]))
 632 AC_ARG_ENABLE([ospfclient],
 633   AS_HELP_STRING([--disable-ospfclient], [do not build OSPFAPI client for OSPFAPI,
 634                           (this is the default if --disable-ospfapi is set)]))
 635 AC_ARG_ENABLE([multipath],
 636   AS_HELP_STRING([--enable-multipath=ARG], [enable multipath function, ARG must be digit]))
 637 AC_ARG_ENABLE([user],
 638   AS_HELP_STRING([--enable-user=USER], [user to run FRR suite as (default frr)]))
 639 AC_ARG_ENABLE([group],
 640   AS_HELP_STRING([--enable-group=GROUP], [group to run FRR suite as (default frr)]))
 641 AC_ARG_ENABLE([vty_group],
 642   AS_HELP_STRING([--enable-vty-group=ARG], [set vty sockets to have specified group as owner]))
 643 AC_ARG_ENABLE([configfile_mask],
 644   AS_HELP_STRING([--enable-configfile-mask=ARG], [set mask for config files]))
 645 AC_ARG_ENABLE([logfile_mask],
 646   AS_HELP_STRING([--enable-logfile-mask=ARG], [set mask for log files]))
 647 AC_ARG_ENABLE([shell_access],
 648   AS_HELP_STRING([--enable-shell-access], [Allow users to access shell/telnet/ssh]))
 649 AC_ARG_ENABLE([realms],
 650   AS_HELP_STRING([--enable-realms], [enable REALMS support under Linux]))
 651 AC_ARG_ENABLE([rtadv],
 652   AS_HELP_STRING([--disable-rtadv], [disable IPV6 router advertisement feature]))
 653 AC_ARG_ENABLE([irdp],
 654   AS_HELP_STRING([--disable-irdp], [disable IRDP server support in zebra (enabled by default if supported)]))
 655 AC_ARG_ENABLE([capabilities],
 656   AS_HELP_STRING([--disable-capabilities], [disable using POSIX capabilities]))
 657 AC_ARG_ENABLE([gcc_ultra_verbose],
 658   AS_HELP_STRING([--enable-gcc-ultra-verbose], [enable ultra verbose GCC warnings]))
 659 AC_ARG_ENABLE([backtrace],
 660   AS_HELP_STRING([--disable-backtrace], [disable crash backtraces (default autodetect)]))
 661 AC_ARG_ENABLE([time-check],
 662   AS_HELP_STRING([--disable-time-check], [disable slow thread warning messages]))
 663 AC_ARG_ENABLE([cpu-time],
 664   AS_HELP_STRING([--disable-cpu-time], [disable cpu usage data gathering]))
 665 AC_ARG_ENABLE([pcreposix],
 666   AS_HELP_STRING([--enable-pcreposix], [enable using PCRE Posix libs for regex functions]))
 667 AC_ARG_ENABLE([fpm],
 668   AS_HELP_STRING([--enable-fpm], [enable Forwarding Plane Manager support]))
 669 AC_ARG_ENABLE([pcep],
 670   AS_HELP_STRING([--enable-pcep], [enable PCEP support for pathd]))
 671 AC_ARG_ENABLE([systemd],
 672   AS_HELP_STRING([--enable-systemd], [enable Systemd support]))
 673 AC_ARG_ENABLE([werror],
 674   AS_HELP_STRING([--enable-werror], [enable -Werror (recommended for developers only)]))
 675 AC_ARG_ENABLE([cumulus],
 676   AS_HELP_STRING([--enable-cumulus], [enable Cumulus Switch Special Extensions]))
 677 AC_ARG_ENABLE([datacenter],
 678   AS_HELP_STRING([--enable-datacenter], [enable Compilation for Data Center Extensions]))
 679 AC_ARG_ENABLE([rr-semantics],
 680   AS_HELP_STRING([--disable-rr-semantics], [disable the v6 Route Replace semantics]))
 681 AC_ARG_ENABLE([protobuf],
 682   AS_HELP_STRING([--enable-protobuf], [Enable experimental protobuf support]))
 683 AC_ARG_ENABLE([oldvpn_commands],
 684   AS_HELP_STRING([--enable-oldvpn-commands], [Keep old vpn commands]))
 685 AC_ARG_ENABLE([rpki],
 686   AS_HELP_STRING([--enable-rpki], [enable RPKI prefix validation support]))
 687 AC_ARG_ENABLE([clippy-only],
 688   AS_HELP_STRING([--enable-clippy-only], [Only build clippy]))
 689 AC_ARG_ENABLE([numeric_version],
 690   AS_HELP_STRING([--enable-numeric-version], [Only numeric digits allowed in version (for Alpine)]))
 691 AC_ARG_ENABLE([gcov],
 692   AS_HELP_STRING([--enable-gcov], [Collect coverage information with gcov]))
 693 AC_ARG_ENABLE([clang_coverage],
 694   AS_HELP_STRING([--enable-clang-coverage], [Collect coverage information with Clang Coverage]))
 695 AC_ARG_ENABLE([bfdd],
 696   AS_HELP_STRING([--disable-bfdd], [do not build bfdd]))
 697 AC_ARG_ENABLE([address-sanitizer],
 698   AS_HELP_STRING([--enable-address-sanitizer], [enable AddressSanitizer support for detecting a wide variety of memory allocation and deallocation errors]))
 699 AC_ARG_ENABLE([thread-sanitizer],
 700   AS_HELP_STRING([--enable-thread-sanitizer], [enable ThreadSanitizer support for detecting data races]))
 701 AC_ARG_ENABLE([memory-sanitizer],
 702   AS_HELP_STRING([--enable-memory-sanitizer], [enable MemorySanitizer support for detecting uninitialized memory reads]))
 703 AC_ARG_ENABLE([undefined-sanitizer],
 704   AS_HELP_STRING([--undefined-sanitizer], [enable UndefinedBehaviorSanitizer support for detecting undefined behavior]))
 705 AC_ARG_WITH([crypto],
 706   AS_HELP_STRING([--with-crypto=<internal|openssl>], [choose between different implementations of cryptographic functions(default value is --with-crypto=internal)]))
 707 AC_ARG_WITH([frr-format],
 708   AS_HELP_STRING([--with-frr-format[=<.../frr-format.so>]], [use frr-format GCC plugin]))
 709
 710 AC_ARG_ENABLE([version-build-config],
 711   AS_HELP_STRING([--disable-version-build-config], [do not include build configs in show version command]))
 712
 713 #if openssl, else use the internal
 714 AS_IF([test "$with_crypto" = "openssl"], [
 715 AC_CHECK_LIB([crypto], [EVP_DigestInit], [LIBS="$LIBS -lcrypto"], [], [])
 716 if test "$ac_cv_lib_crypto_EVP_DigestInit" = "no"; then
 717   AC_MSG_ERROR([build with openssl has been specified but openssl library was not found on your system])
 718 else
 719   AC_DEFINE([CRYPTO_OPENSSL], [1], [Compile with openssl support])
 720 fi
 721 ], [test "$with_crypto" = "internal" || test "$with_crypto" = "" ], [AC_DEFINE([CRYPTO_INTERNAL], [1], [Compile with internal cryptographic implementation])
 722 ], [AC_MSG_ERROR([Unknown value for --with-crypto])]
 723 )
 724
 725 AS_IF([test "$enable_clippy_only" != "yes"], [
 726 AC_CHECK_HEADERS([json-c/json.h])
 727 AC_CHECK_LIB([json-c], [json_object_get], [LIBS="$LIBS -ljson-c"], [], [-lm])
 728 if test "$ac_cv_lib_json_c_json_object_get" = "no"; then
 729   AC_CHECK_LIB([json], [json_object_get], [LIBS="$LIBS -ljson"])
 730   if test "$ac_cv_lib_json_json_object_get" = "no"; then
 731       AC_MSG_ERROR([libjson is needed to compile])
 732   fi
 733 fi
 734 ])
 735
 736 AC_ARG_ENABLE([dev_build],
 737     AS_HELP_STRING([--enable-dev-build], [build for development]))
 738
 739 AC_ARG_ENABLE([scripting],
 740     AS_HELP_STRING([--enable-scripting], [Build with scripting support]))
 741
 742 AC_ARG_ENABLE([netlink-debug],
 743   AS_HELP_STRING([--disable-netlink-debug], [pretty print netlink debug messages]))
 744
 745 if test "$enable_netlink_debug" != "no" ; then
 746   AC_DEFINE([NETLINK_DEBUG], [1], [Netlink extra debugging code])
 747 fi
 748
 749 AM_CONDITIONAL([NETLINK_DEBUG], [test "$enable_netlink_debug" != "no"])
 750
 751 if test "$enable_time_check" != "no" ; then
 752   if test "$enable_time_check" = "yes" -o "$enable_time_check" = "" ; then
 753     AC_DEFINE([CONSUMED_TIME_CHECK], [5000000], [Consumed Time Check])
 754   else
 755     AC_DEFINE_UNQUOTED([CONSUMED_TIME_CHECK], [$enable_time_check], [Consumed Time Check])
 756   fi
 757 fi
 758
 759 case "${enable_cpu_time}" in
 760   "no")
 761   AC_DEFINE([EXCLUDE_CPU_TIME], [1], [Exclude getrusage data gathering])
 762   ;;
 763   "*")
 764   ;;
 765 esac
 766
 767 case "${enable_systemd}" in
 768   "no") ;;
 769   "yes")
 770   AC_CHECK_LIB([systemd], [sd_notify], [LIBS="$LIBS -lsystemd"])
 771   if test "$ac_cv_lib_systemd_sd_notify" = "no"; then
 772     AC_MSG_ERROR([enable systemd has been specified but systemd development env not found on your system])
 773   else
 774     AC_DEFINE([HAVE_SYSTEMD], [1], [Compile systemd support in])
 775   fi
 776   ;;
 777   "*") ;;
 778 esac
 779
 780 if test "$enable_rr_semantics" != "no" ; then
 781   AC_DEFINE([HAVE_V6_RR_SEMANTICS], [1], [Compile in v6 Route Replacement Semantics])
 782 fi
 783
 784 if test "$enable_datacenter" = "yes" ; then
 785   AC_DEFINE([HAVE_DATACENTER], [1], [Compile extensions for a DataCenter])
 786   DFLT_NAME="datacenter"
 787 else
 788   DFLT_NAME="traditional"
 789 fi
 790
 791 if test "$enable_cumulus" = "yes" ; then
 792   AC_DEFINE([HAVE_CUMULUS], [1], [Compile Special Cumulus Code in])
 793 fi
 794
 795 AC_SUBST([DFLT_NAME])
 796 AC_DEFINE_UNQUOTED([DFLT_NAME], ["$DFLT_NAME"], [Name of the configuration default set])
 797
 798 if test "$enable_shell_access" = "yes"; then
 799    AC_DEFINE([HAVE_SHELL_ACCESS], [1], [Allow user to use ssh/telnet/bash, be aware this is considered insecure])
 800 fi
 801
 802 #
 803 # Python for clippy
 804 #
 805
 806 AS_IF([test "$host" = "$build"], [
 807   AC_CHECK_HEADER([gelf.h], [], [
 808     AC_MSG_ERROR([libelf headers are required for building clippy.  (Host only when cross-compiling.)])
 809   ])
 810   AC_CHECK_LIB([elf], [elf_memory], [], [
 811     AC_MSG_ERROR([libelf is required for building clippy.  (Host only when cross-compiling.)])
 812   ])
 813
 814   AC_CHECK_LIB([elf], [elf_getdata_rawchunk], [
 815     AC_DEFINE([HAVE_ELF_GETDATA_RAWCHUNK], [1], [Have elf_getdata_rawchunk()])
 816   ])
 817   AC_CHECK_LIB([elf], [gelf_getnote], [
 818     AC_DEFINE([HAVE_GELF_GETNOTE], [1], [Have gelf_getnote()])
 819   ])
 820
 821   FRR_PYTHON_DEV
 822 ], [
 823   FRR_PYTHON
 824 ])
 825
 826 FRR_PYTHON_MODULES([pytest])
 827
 828 if test "$enable_doc" != "no"; then
 829   FRR_PYTHON_MODULES([sphinx], , [
 830     if test "$enable_doc" = "yes"; then
 831       AC_MSG_ERROR([Documentation was explicitly requested with --enable-doc but sphinx is not available for $PYTHON. Please disable docs or install sphinx.])
 832     fi
 833   ])
 834 fi
 835 AM_CONDITIONAL([DOC], [test "$enable_doc" != "no" -a "$frr_py_mod_sphinx" != "false"])
 836 AM_CONDITIONAL([DOC_HTML], [test "$enable_doc_html" = "yes"])
 837
 838 FRR_PYTHON_MOD_EXEC([sphinx], [--version], [
 839   PYSPHINX="-m sphinx"
 840 ], [
 841   PYSPHINX="-c 'import sys; from sphinx import main; sys.exit(main(sys.argv))'"
 842 ])
 843 AC_SUBST([PYSPHINX])
 844
 845 #
 846 # Logic for old vpn commands support.
 847 #
 848 if test "$enable_oldvpn_commands" = "yes"; then
 849    AC_DEFINE([KEEP_OLD_VPN_COMMANDS], [1], [Define for compiling with old vpn commands])
 850 fi
 851
 852 #
 853 # End of logic for protobuf support.
 854 #
 855
 856 AC_MSG_CHECKING([if zebra should be configurable to send Route Advertisements])
 857 if test "$enable_rtadv" != "no"; then
 858   AC_MSG_RESULT([yes])
 859   AC_DEFINE([HAVE_RTADV], [1], [Enable IPv6 Routing Advertisement support])
 860 else
 861   AC_MSG_RESULT([no])
 862 fi
 863
 864 if test "$enable_user" = "no"; then
 865   enable_user=""
 866 else
 867   if test "$enable_user" = "yes" || test "$enable_user" = ""; then
 868     enable_user="frr"
 869   fi
 870   AC_DEFINE_UNQUOTED([FRR_USER], ["${enable_user}"], [frr User])
 871 fi
 872
 873 if test "$enable_group" = "no"; then
 874   enable_group=""
 875 else
 876   if test "$enable_group" = "yes" || test "$enable_group" = ""; then
 877     enable_group="frr"
 878   fi
 879   AC_DEFINE_UNQUOTED([FRR_GROUP], ["${enable_group}"], [frr Group])
 880 fi
 881
 882 if test "$enable_vty_group" = "yes" ; then
 883   AC_MSG_ERROR([--enable-vty-group requires a group as argument, not yes])
 884 elif test "$enable_vty_group" != ""; then
 885   if test "$enable_vty_group" != "no"; then
 886     AC_DEFINE_UNQUOTED([VTY_GROUP], ["${enable_vty_group}"], [VTY Sockets Group])
 887   fi
 888 fi
 889 AC_SUBST([enable_user])
 890 AC_SUBST([enable_group])
 891 AC_SUBST([enable_vty_group])
 892
 893 enable_configfile_mask=${enable_configfile_mask:-0600}
 894 AC_DEFINE_UNQUOTED([CONFIGFILE_MASK], [${enable_configfile_mask}], [Mask for config files])
 895 AC_SUBST([enable_configfile_mask])
 896
 897 enable_logfile_mask=${enable_logfile_mask:-0600}
 898 AC_DEFINE_UNQUOTED([LOGFILE_MASK], [${enable_logfile_mask}], [Mask for log files])
 899
 900 MPATH_NUM=16
 901
 902 case "${enable_multipath}" in
 903   0)
 904     MPATH_NUM=64
 905     ;;
 906   [[1-9]|[1-9][0-9]|[1-9][0-9][0-9]])
 907     MPATH_NUM="${enable_multipath}"
 908     ;;
 909   "")
 910     ;;
 911   *)
 912     AC_MSG_FAILURE([Please specify digit to enable multipath ARG])
 913     ;;
 914 esac
 915
 916 AC_DEFINE_UNQUOTED([MULTIPATH_NUM], [$MPATH_NUM], [Maximum number of paths for a route])
 917
 918 AC_DEFINE_UNQUOTED([VTYSH_PAGER], ["$VTYSH_PAGER"], [What pager to use])
 919
 920 dnl --------------------
 921 dnl Enable code coverage
 922 dnl --------------------
 923 AM_CONDITIONAL([HAVE_GCOV], [test "$enable_gcov" != "no"])
 924
 925 dnl ------------------------------------
 926 dnl Alpine only accepts numeric versions
 927 dnl ------------------------------------
 928 if test "$enable_numeric_version" != "" ; then
 929   VERSION="`echo ${VERSION} | tr -c -d '[[.0-9]]'`"
 930   PACKAGE_VERSION="`echo ${PACKAGE_VERSION} | tr -c -d '[[.0-9]]'`"
 931 fi
 932
 933 dnl -----------------------------------
 934 dnl Add extra version string to package
 935 dnl name, string and version fields.
 936 dnl -----------------------------------
 937 if test "$EXTRAVERSION" != "" ; then
 938   VERSION="${VERSION}${EXTRAVERSION}"
 939   PACKAGE_VERSION="${PACKAGE_VERSION}${EXTRAVERSION}"
 940   AC_SUBST(PACKAGE_EXTRAVERSION, ["${EXTRAVERSION}"])
 941   PACKAGE_STRING="${PACKAGE_STRING}${EXTRAVERSION}"
 942 fi
 943 AC_SUBST([EXTRAVERSION])
 944
 945 if test "$with_pkg_git_version" = "yes"; then
 946         if test -e "${srcdir}/.git"; then
 947                 AC_DEFINE([GIT_VERSION], [1], [include git version info])
 948         else    with_pkg_git_version="no"
 949                 AC_MSG_WARN([--with-pkg-git-version given, but this is not a git checkout])
 950         fi
 951 fi
 952 AM_CONDITIONAL([GIT_VERSION], [test "$with_pkg_git_version" = "yes"])
 953
 954 AC_CHECK_TOOL([OBJCOPY], [objcopy], [:])
 955 if test "$OBJCOPY" != ":"; then
 956   AC_CACHE_CHECK([for .interp value to use], [frr_cv_interp], [
 957     frr_cv_interp=""
 958     AC_LINK_IFELSE([AC_LANG_SOURCE([[int main() { return 0; }]])], [
 959       if $OBJCOPY -j.interp -Obinary conftest conftest.interp; then
 960         frr_cv_interp="`xargs -0 echo < conftest.interp`"
 961       fi
 962       test -f conftest.interp && rm conftest.interp
 963     ])
 964   ])
 965 fi
 966 if test -n "$frr_cv_interp"; then
 967   AC_DEFINE_UNQUOTED([INTERP], ["$frr_cv_interp"], [.interp value])
 968 fi
 969
 970 dnl -------------------------
 971 dnl Check other header files.
 972 dnl -------------------------
 973 AC_CHECK_HEADERS([stropts.h sys/ksym.h \
 974         linux/version.h asm/types.h endian.h sys/endian.h])
 975
 976 ac_stdatomic_ok=false
 977 AC_DEFINE([FRR_AUTOCONF_ATOMIC], [1], [did autoconf checks for atomic funcs])
 978 AC_CHECK_HEADER([stdatomic.h],[
 979
 980   AC_MSG_CHECKING([whether _Atomic qualifier works])
 981   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 982 #include <stdatomic.h>
 983 int main(int argc, char **argv) {
 984   _Atomic int i = 0;
 985   return i;
 986 }
 987 ]])], [
 988     AC_DEFINE([HAVE_STDATOMIC_H], [1], [found stdatomic.h])
 989     AC_MSG_RESULT([yes])
 990     ac_stdatomic_ok=true
 991   ], [
 992     AC_MSG_RESULT([no])
 993   ])
 994 ])
 995
 996 AS_IF([$ac_stdatomic_ok], [true], [
 997   AC_MSG_CHECKING([for __atomic_* builtins])
 998   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 999 int main(int argc, char **argv) {
1000   volatile int i = 1;
1001   __atomic_store_n (&i, 0, __ATOMIC_RELEASE);
1002   return __atomic_load_n (&i, __ATOMIC_ACQUIRE);
1003 }
1004 ]])], [
1005     AC_DEFINE([HAVE___ATOMIC], [1], [found __atomic builtins])
1006     AC_MSG_RESULT([yes])
1007   ], [
1008     AC_MSG_RESULT([no])
1009
1010     dnl FreeBSD 9 has a broken stdatomic.h where _Atomic doesn't work
1011     AC_MSG_CHECKING([for __sync_* builtins])
1012     AC_LINK_IFELSE([AC_LANG_SOURCE([[
1013 int main(int argc, char **argv) {
1014   volatile int i = 1;
1015   __sync_fetch_and_sub (&i, 1);
1016   return __sync_val_compare_and_swap (&i, 0, 1);
1017 }
1018 ]])], [
1019       AC_DEFINE([HAVE___SYNC], [1], [found __sync builtins])
1020       AC_MSG_RESULT([yes])
1021
1022       AC_MSG_CHECKING([for __sync_swap builtin])
1023       AC_LINK_IFELSE([AC_LANG_SOURCE([[
1024 int main(int argc, char **argv) {
1025   volatile int i = 1;
1026   return __sync_swap (&i, 2);
1027 }
1028 ]])], [
1029         AC_DEFINE([HAVE___SYNC_SWAP], 1, [found __sync_swap builtin])
1030         AC_MSG_RESULT([yes])
1031       ], [
1032         AC_MSG_RESULT([no])
1033       ])
1034
1035     ], [
1036       AC_MSG_RESULT([no])
1037       AC_MSG_FAILURE([stdatomic.h unavailable and $CC has neither __atomic nor __sync builtins])
1038     ])
1039   ])
1040 ])
1041
1042 needsync=true
1043
1044 AS_IF([$needsync], [
1045   dnl Linux
1046   AC_MSG_CHECKING([for Linux futex() support])
1047   AC_LINK_IFELSE([AC_LANG_PROGRAM([
1048 #ifndef _GNU_SOURCE
1049 #define _GNU_SOURCE
1050 #endif
1051 #include <unistd.h>
1052 #include <limits.h>
1053 #include <sys/time.h>
1054 #include <sys/syscall.h>
1055 #include <linux/futex.h>
1056
1057 int main(void);
1058 ],
1059 [
1060 {
1061   return syscall(SYS_futex, NULL, FUTEX_WAIT, 0, NULL, NULL, 0);
1062 }
1063 ])], [
1064     AC_MSG_RESULT([yes])
1065     AC_DEFINE(HAVE_SYNC_LINUX_FUTEX,,Have Linux futex support)
1066     needsync=false
1067   ], [
1068     AC_MSG_RESULT([no])
1069   ])
1070 ])
1071
1072 AS_IF([$needsync], [
1073   dnl FreeBSD
1074   AC_MSG_CHECKING([for FreeBSD _umtx_op() support])
1075   AC_LINK_IFELSE([AC_LANG_PROGRAM([
1076 #include <errno.h>
1077 #include <stdlib.h>
1078 #include <sys/types.h>
1079 #include <sys/umtx.h>
1080 int main(void);
1081 ],
1082 [
1083 {
1084   return _umtx_op(NULL, UMTX_OP_WAIT_UINT, 0, NULL, NULL);
1085 }
1086 ])], [
1087     AC_MSG_RESULT([yes])
1088     AC_DEFINE(HAVE_SYNC_UMTX_OP,,Have FreeBSD _umtx_op() support)
1089     needsync=false
1090   ], [
1091     AC_MSG_RESULT([no])
1092   ])
1093 ])
1094
1095 AS_IF([$needsync], [
1096   dnl OpenBSD patch (not upstream at the time of writing this)
1097   dnl https://marc.info/?l=openbsd-tech&m=147299508409549&w=2
1098   AC_MSG_CHECKING([for OpenBSD futex() support])
1099   AC_LINK_IFELSE([AC_LANG_PROGRAM([
1100 #include <sys/futex.h>
1101 int main(void);
1102 ],
1103 [
1104 {
1105   return futex(NULL, FUTEX_WAIT, 0, NULL, NULL, 0);
1106 }
1107 ])], [
1108     AC_MSG_RESULT([yes])
1109     AC_DEFINE(HAVE_SYNC_OPENBSD_FUTEX,,Have OpenBSD futex support)
1110     needsync=false
1111   ], [
1112     AC_MSG_RESULT([no])
1113   ])
1114 ])
1115
1116 dnl Utility macro to avoid retyping includes all the time
1117 m4_define([FRR_INCLUDES],
1118 [#ifdef SUNOS_5
1119 #define _POSIX_C_SOURCE 200809L
1120 #define __EXTENSIONS__
1121 #endif
1122 #include <stdio.h>
1123 #include <stdlib.h>
1124 #include <stddef.h>
1125 #include <sys/types.h>
1126 /* sys/conf.h depends on param.h on FBSD at least */
1127 #include <sys/param.h>
1128 /* Required for MAXSIG */
1129 #include <signal.h>
1130 #include <sys/socket.h>
1131 #ifdef __APPLE__
1132 # define __APPLE_USE_RFC_3542
1133 #endif
1134 #include <netinet/in.h>
1135 #include <sys/time.h>
1136 #include <time.h>
1137 #include <net/if.h>
1138 ])dnl
1139
1140 dnl Same applies for HAVE_NET_IF_VAR_H, which HAVE_NETINET6_ND6_H and
1141 dnl HAVE_NETINET_IN_VAR_H depend upon. But if_var.h depends on if.h, hence
1142 dnl an additional round for it.
1143
1144 AC_CHECK_HEADERS([net/if_var.h], [], [], [FRR_INCLUDES])
1145
1146 m4_define([FRR_INCLUDES],
1147 FRR_INCLUDES
1148 [#ifdef HAVE_NET_IF_VAR_H
1149 # include <net/if_var.h>
1150 #endif
1151 ])dnl
1152
1153 AC_CHECK_HEADERS([netinet/in_var.h \
1154         net/if_dl.h net/netopt.h \
1155         inet/nd.h netinet/ip_icmp.h \
1156         sys/sysctl.h sys/sockio.h sys/conf.h],
1157         [], [], [FRR_INCLUDES])
1158
1159 AC_CHECK_HEADERS([ucontext.h], [], [],
1160 [#ifndef __USE_GNU
1161 #define __USE_GNU
1162 #endif /* __USE_GNU */
1163 FRR_INCLUDES
1164 ])
1165
1166 m4_define([UCONTEXT_INCLUDES],
1167 [#include <ucontext.h>])dnl
1168
1169 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.uc_regs],
1170   [], [], [UCONTEXT_INCLUDES])
1171 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs],
1172   [AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs.nip],
1173    [], [], [UCONTEXT_INCLUDES])],
1174   [], [UCONTEXT_INCLUDES])
1175 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.gregs],
1176   [], [], [UCONTEXT_INCLUDES])
1177
1178 m4_define([FRR_INCLUDES],
1179 FRR_INCLUDES
1180 [
1181 #include <sys/un.h>
1182 #include <netinet/in_systm.h>
1183 #ifdef HAVE_NETINET_IN_VAR_H
1184 # include <netinet/in_var.h>
1185 #endif
1186 #ifdef HAVE_NET_IF_DL_H
1187 # include <net/if_dl.h>
1188 #endif
1189 #ifdef HAVE_NET_NETOPT_H
1190 # include <net/netopt.h>
1191 #endif
1192 #include <net/route.h>
1193 #ifdef HAVE_INET_ND_H
1194 # include <inet/nd.h>
1195 #endif
1196 #include <arpa/inet.h>
1197 /* Required for IDRP */
1198 #ifdef HAVE_NETINET_IP_ICMP_H
1199 # include <netinet/ip_icmp.h>
1200 #endif
1201 ])dnl
1202
1203 dnl V6 headers are checked below, after we check for v6
1204
1205 is_linux=false
1206
1207 AC_MSG_CHECKING([which operating system interface to use])
1208 case "$host_os" in
1209   sunos* | solaris2*)
1210     AC_MSG_FAILURE([Solaris support has been removed please see versions prior or equal to 7.5])
1211     ;;
1212   linux*)
1213     AC_MSG_RESULT([Linux])
1214
1215     AC_DEFINE([GNU_LINUX], [1], [GNU Linux])
1216     AC_DEFINE([HAVE_NETLINK], [1], [netlink])
1217     AC_DEFINE([LINUX_IPV6], [1], [Linux IPv6 stack])
1218
1219     dnl Linux has a compilation problem with mixing
1220     dnl netinet/in.h and linux/in6.h they are not
1221     dnl compatible.  There has been discussion on
1222     dnl how to fix it but no real progress on implementation
1223     dnl when they fix it, remove this
1224     AC_DEFINE([IPV6_MINHOPCOUNT], [73], [Linux ipv6 Min Hop Count])
1225
1226     is_linux=true
1227     ;;
1228   openbsd*)
1229     AC_MSG_RESULT([OpenBSD])
1230
1231     AC_DEFINE([OPEN_BSD], [1], [OpenBSD])
1232     AC_DEFINE([KAME], [1], [KAME IPv6])
1233     AC_DEFINE([BSD_V6_SYSCTL], [1], [BSD v6 sysctl to turn on and off forwarding])
1234     ;;
1235   *)
1236     AC_MSG_RESULT([BSD])
1237
1238     AC_DEFINE([HAVE_NET_RT_IFLIST], [1], [NET_RT_IFLIST])
1239     AC_DEFINE([KAME], [1], [KAME IPv6])
1240     AC_DEFINE([BSD_V6_SYSCTL], [1], [BSD v6 sysctl to turn on and off forwarding])
1241     ;;
1242 esac
1243 AM_CONDITIONAL([LINUX], [${is_linux}])
1244
1245 AC_SYS_LARGEFILE
1246
1247 dnl ------------------------
1248 dnl Integrated REALMS option
1249 dnl ------------------------
1250 if test "$enable_realms" = "yes"; then
1251     case "$host_os" in
1252       linux*)
1253        AC_DEFINE([SUPPORT_REALMS], [1], [Realms support])
1254        ;;
1255       *)
1256        echo "Sorry, only Linux has REALMS support"
1257        exit 1
1258        ;;
1259     esac
1260 fi
1261
1262 dnl ---------------
1263 dnl other functions
1264 dnl ---------------
1265 AC_CHECK_FUNCS([ \
1266         strlcat strlcpy \
1267         getgrouplist \
1268         openat \
1269         unlinkat \
1270         posix_fallocate \
1271         ])
1272
1273 dnl ##########################################################################
1274 dnl LARGE if block spans a lot of "configure"!
1275 if test "$enable_clippy_only" != "yes"; then
1276 dnl ##########################################################################
1277
1278 #
1279 # Logic for protobuf support.
1280 #
1281 PROTO3=false
1282 if test "$enable_protobuf" = "yes"; then
1283   # Check for protoc & protoc-c
1284
1285   # protoc is not required, it's only for a "be nice" helper target
1286   AC_CHECK_PROGS([PROTOC], [protoc], [/bin/false])
1287
1288   AC_CHECK_PROGS([PROTOC_C], [protoc-c], [/bin/false])
1289   if test "$PROTOC_C" = "/bin/false"; then
1290     AC_MSG_FAILURE([protobuf requested but protoc-c not found.  Install protobuf-c.])
1291   fi
1292
1293   PKG_CHECK_MODULES([PROTOBUF_C], [libprotobuf-c >= 0.14],, [
1294     AC_MSG_FAILURE([protobuf requested but libprotobuf-c not found.  Install protobuf-c.])
1295   ])
1296
1297   PROTO3=true
1298   AC_CHECK_HEADER([google/protobuf-c/protobuf-c.h],
1299                   [AC_CHECK_DECLS(PROTOBUF_C_LABEL_NONE,
1300                                   AC_DEFINE([HAVE_PROTOBUF_VERSION_3],
1301                                             [1], [Have Protobuf version 3]),
1302                                   [PROTO3=false],
1303                                   [#include <google/protobuf-c/protobuf-c.h>])],
1304                   [PROTO3=false && AC_MSG_FAILURE([protobuf requested but protobuf-c.h not found.  Install protobuf-c.])])
1305
1306   AC_DEFINE([HAVE_PROTOBUF], [1], [protobuf])
1307 fi
1308
1309
1310 dnl ---------------------
1311 dnl Integrated VTY option
1312 dnl ---------------------
1313 case "${enable_vtysh}" in
1314 "no")
1315   VTYSH="";;
1316 *)
1317   VTYSH="vtysh";
1318   AC_DEFINE([VTYSH], [1], [VTY shell])
1319
1320   prev_libs="$LIBS"
1321   AC_CHECK_LIB([readline], [main], [
1322     LIBREADLINE="-lreadline"
1323   ], [
1324     dnl readline failed - it might be incorrectly linked and missing its
1325     dnl termcap/tinfo/curses dependency.  see if we can fix that...
1326     AC_SEARCH_LIBS([tputs], [termcap tinfo curses ncurses], [
1327       LIBREADLINE="$ac_cv_search_tputs"
1328     ], [
1329       AC_MSG_ERROR([libreadline (needed for vtysh) not found and/or missing dependencies])
1330     ])
1331
1332     dnl re-try with the lib we found above
1333     unset ac_cv_lib_readline_main
1334     AC_CHECK_LIB([readline], [main], [
1335       LIBREADLINE="-lreadline $LIBREADLINE"
1336     ], [
1337       AC_MSG_ERROR([libreadline (needed for vtysh) not found and/or missing dependencies])
1338     ], [$LIBREADLINE])
1339   ], [])
1340   LIBS="$prev_libs"
1341
1342   AC_CHECK_HEADER([readline/history.h])
1343   if test "$ac_cv_header_readline_history_h" = "no"; then
1344     AC_MSG_ERROR([readline is too old to have readline/history.h, please update to the latest readline library.])
1345   fi
1346   AC_CHECK_LIB([readline], [rl_completion_matches], [true], [], [$LIBREADLINE])
1347   if test "$ac_cv_lib_readline_rl_completion_matches" = "no"; then
1348     AC_DEFINE([rl_completion_matches], [completion_matches], [Old readline])
1349   fi
1350   AC_CHECK_LIB([readline], [append_history], [frr_cv_append_history=yes], [frr_cv_append_history=no], [$LIBREADLINE])
1351   if test "$frr_cv_append_history" = "yes"; then
1352     AC_DEFINE([HAVE_APPEND_HISTORY], [1], [Have history.h append_history])
1353   fi
1354   ;;
1355 esac
1356 AC_SUBST([LIBREADLINE])
1357
1358 dnl ----------
1359 dnl PAM module
1360 dnl
1361 dnl FRR detects the PAM library it is built against by checking for a
1362 dnl functional pam_misc.h (Linux-PAM) or openpam.h (OpenPAM) header. pam_misc.h
1363 dnl is known to #include pam_appl.h, the standard header of a PAM library, and
1364 dnl openpam.h doesn't do that, although depends on the header too. Hence a
1365 dnl little assistance to AC_CHECK_HEADER is necessary for the proper detection
1366 dnl of OpenPAM.
1367 dnl ----------
1368 if test "$with_libpam" = "yes"; then
1369   AC_CHECK_HEADER([security/pam_misc.h],
1370     [AC_DEFINE([HAVE_PAM_MISC_H], [1], [Have pam_misc.h])
1371      AC_DEFINE([PAM_CONV_FUNC], [misc_conv], [Have misc_conv])
1372      pam_conv_func="misc_conv"
1373     ],
1374     [], FRR_INCLUDES)
1375   AC_CHECK_HEADER([security/openpam.h],
1376     [AC_DEFINE([HAVE_OPENPAM_H], [1], [Have openpam.h])
1377      AC_DEFINE([PAM_CONV_FUNC], [openpam_ttyconv], [Have openpam_ttyconv])
1378      pam_conv_func="openpam_ttyconv"
1379     ],
1380     [], FRR_INCLUDES[#include <security/pam_appl.h>])
1381   if test -z "$ac_cv_header_security_pam_misc_h$ac_cv_header_security_openpam_h" ; then
1382     AC_MSG_WARN([*** pam support will not be built ***])
1383     with_libpam="no"
1384   fi
1385 fi
1386
1387 if test "$with_libpam" = "yes"; then
1388 dnl took this test from proftpds configure.in and suited to our needs
1389 dnl -------------------------------------------------------------------------
1390 dnl
1391 dnl This next check looks funky due to a linker problem with some versions
1392 dnl of the PAM library.  Prior to 0.72 release, the Linux PAM shared library
1393 dnl omitted requiring libdl linking information. PAM-0.72 or better ships
1394 dnl with RedHat 6.2 and Debian 2.2 or better.
1395 AC_CHECK_LIB([pam], [pam_start],
1396   [AC_CHECK_LIB([pam], [$pam_conv_func],
1397     [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1398      LIBPAM="-lpam"],
1399     [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1400      LIBPAM="-lpam -lpam_misc"]
1401     )
1402   ],
1403
1404   [AC_CHECK_LIB([pam], [pam_end],
1405     [AC_CHECK_LIB([pam], [$pam_conv_func],
1406       [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1407        LIBPAM="-lpam -ldl"],
1408       [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1409        LIBPAM="-lpam -ldl -lpam_misc"]
1410      )
1411   ],AC_MSG_WARN([*** pam support will not be built ***]),
1412   [-ldl])
1413   ]
1414 )
1415 fi
1416 AC_SUBST([LIBPAM])
1417
1418 dnl -------------------------------
1419 dnl bgpd needs pow() and hence libm
1420 dnl -------------------------------
1421 TMPLIBS="$LIBS"
1422 LIBS=""
1423 AC_SEARCH_LIBS([pow], [m], [
1424   LIBM="$LIBS"
1425 ], [
1426   AC_MSG_WARN([Unable to find working pow function - bgpd may not link])
1427 ])
1428 LIBS="$TMPLIBS"
1429 AC_SUBST([LIBM])
1430
1431 AC_CHECK_FUNCS([ppoll], [
1432   AC_DEFINE([HAVE_PPOLL], [1], [have Linux/BSD ppoll()])
1433 ])
1434 AC_CHECK_FUNCS([pollts], [
1435   AC_DEFINE([HAVE_POLLTS], [1], [have NetBSD pollts()])
1436 ])
1437
1438 AC_CHECK_HEADER([asm-generic/unistd.h],
1439                 [AC_CHECK_DECL(__NR_setns,
1440                                AC_DEFINE([HAVE_NETNS], [1], [Have netns]),,
1441                                FRR_INCLUDES [#include <asm-generic/unistd.h>
1442                                ])
1443                  AC_CHECK_FUNCS([setns])]
1444                )
1445
1446 dnl --------------------------
1447 dnl Determine IS-IS I/O method
1448 dnl --------------------------
1449 AC_DEFINE([ISIS_METHOD_PFPACKET], [1], [constant value for isis method pfpacket])
1450 AC_DEFINE([ISIS_METHOD_DLPI], [2], [constant value for isis method dlpi])
1451 AC_DEFINE([ISIS_METHOD_BPF], [3], [constant value for isis method bpf])
1452 AC_CHECK_HEADER([net/bpf.h])
1453 AC_CHECK_HEADER([sys/dlpi.h])
1454 AC_MSG_CHECKING([zebra IS-IS I/O method])
1455
1456 case "$host_os" in
1457   linux*)
1458     AC_MSG_RESULT([pfpacket])
1459     ISIS_METHOD_MACRO="ISIS_METHOD_PFPACKET"
1460     ;;
1461   *)
1462     if test "$ac_cv_header_net_bpf_h" = "no"; then
1463       if test "$ac_cv_header_sys_dlpi_h" = "no"; then
1464         AC_MSG_RESULT([none])
1465         if test "$enable_isisd" = "yes" -o "$enable_fabricd" = "yes"; then
1466           AC_MSG_FAILURE([IS-IS support requested but no packet backend found])
1467         fi
1468         AC_MSG_WARN([*** IS-IS support will not be built ***])
1469         enable_isisd="no"
1470         enable_fabricd="no"
1471       else
1472         AC_MSG_RESULT([DLPI])
1473       fi
1474       ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1475     else
1476       AC_MSG_RESULT([BPF])
1477       ISIS_METHOD_MACRO="ISIS_METHOD_BPF"
1478     fi
1479     ;;
1480 esac
1481 AC_DEFINE_UNQUOTED([ISIS_METHOD], [$ISIS_METHOD_MACRO], [selected method for isis, == one of the constants])
1482
1483 dnl ---------------------------------------------------------------
1484 dnl figure out how to specify an interface in multicast sockets API
1485 dnl ---------------------------------------------------------------
1486 AC_CHECK_MEMBERS([struct ip_mreqn.imr_ifindex], [], [], FRR_INCLUDES)
1487
1488 AC_CHECK_HEADERS([linux/mroute.h], [], [],[
1489         #include <sys/socket.h>
1490         #include <netinet/in.h>
1491         #define _LINUX_IN_H             /* For Linux <= 2.6.25 */
1492         #include <linux/types.h>
1493 ])
1494
1495 m4_define([FRR_INCLUDES],
1496 FRR_INCLUDES
1497 [#ifdef HAVE_LINUX_MROUTE_H
1498 # include <linux/mroute.h>
1499 #endif
1500 ])dnl
1501
1502 AC_CHECK_HEADERS([netinet/ip_mroute.h], [], [],[
1503         #include <sys/socket.h>
1504         #include <sys/types.h>
1505         #include <netinet/in.h>
1506         #include <net/route.h>
1507 ])
1508
1509 m4_define([FRR_INCLUDES],
1510 FRR_INCLUDES
1511 [#ifdef HAVE_NETINET_IP_MROUTE_H
1512 # include <netinet/ip_mroute.h>
1513 #endif
1514 ])dnl
1515
1516 AC_MSG_CHECKING([for RFC3678 protocol-independed API])
1517 AC_COMPILE_IFELSE(
1518 [ AC_LANG_PROGRAM([[
1519       #include <sys/types.h>
1520       #include <netinet/in.h>
1521   ]], [[
1522       struct group_req gr;
1523       int sock;
1524       setsockopt(sock, IPPROTO_IP, MCAST_JOIN_GROUP, (void*)&gr, sizeof(gr));
1525   ]])
1526 ],[
1527   AC_MSG_RESULT([yes])
1528   AC_DEFINE([HAVE_RFC3678], [1], [Have RFC3678 protocol-independed API])
1529 ],[
1530   AC_MSG_RESULT(no)
1531 ])
1532
1533 dnl ---------------------------------------------------------------
1534 dnl figure out how to check link-state
1535 dnl ---------------------------------------------------------------
1536 AC_CHECK_HEADER([net/if_media.h],
1537   [m4_define([LINK_DETECT_INCLUDES],
1538     FRR_INCLUDES
1539     [#include <net/if_media.h>
1540   ])
1541   AC_CHECK_MEMBERS([struct ifmediareq.ifm_status],
1542     AC_DEFINE([HAVE_BSD_LINK_DETECT], [1], [BSD link-detect]),
1543     [], LINK_DETECT_INCLUDES)],
1544   [],
1545   FRR_INCLUDES)
1546
1547 dnl ---------------------------------------------------------------
1548 dnl Additional, newer way to check link-state using ifi_link_state.
1549 dnl Not available in all BSD's when ifmediareq available
1550 dnl ---------------------------------------------------------------
1551 AC_CHECK_MEMBERS([struct if_data.ifi_link_state],
1552   AC_DEFINE([HAVE_BSD_IFI_LINK_STATE], [1], [BSD ifi_link_state available]),
1553   [], FRR_INCLUDES)
1554
1555 dnl ------------------------
1556 dnl TCP_MD5SIG socket option
1557 dnl ------------------------
1558
1559 AC_CHECK_HEADER([netinet/tcp.h],
1560    [m4_define([MD5_INCLUDES],
1561       FRR_INCLUDES
1562       [#include <netinet/tcp.h>
1563     ])
1564     AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)],
1565    [],
1566    FRR_INCLUDES)
1567 if test "$ac_cv_have_decl_TCP_MD5SIG" = "no"; then
1568   AC_CHECK_HEADER([linux/tcp.h],
1569        [m4_define([MD5_INCLUDES],
1570           FRR_INCLUDES
1571           [#include <linux/tcp.h>
1572         ])
1573        AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)])
1574 fi
1575
1576 AC_CHECK_LIB([crypt], [crypt], [],
1577                     [AC_CHECK_LIB([crypto], [DES_crypt])])
1578 AC_CHECK_LIB([resolv], [res_init])
1579
1580 dnl ---------------------------
1581 dnl check system has PCRE regexp
1582 dnl ---------------------------
1583 if test "$enable_pcreposix" = "yes"; then
1584   AC_CHECK_LIB([pcreposix], [regexec], [], [
1585     AC_MSG_ERROR([--enable-pcreposix given but unable to find libpcreposix])
1586   ])
1587 fi
1588 AC_SUBST([HAVE_LIBPCREPOSIX])
1589
1590 dnl ##########################################################################
1591 dnl test "$enable_clippy_only" != "yes"
1592 fi
1593 dnl END OF LARGE if block
1594 dnl ##########################################################################
1595
1596 dnl ------------------
1597 dnl check C-Ares library
1598 dnl ------------------
1599 PKG_CHECK_MODULES([CARES], [libcares], [
1600   c_ares_found=true
1601 ],[
1602   c_ares_found=false
1603 ])
1604 AM_CONDITIONAL([CARES], [$c_ares_found])
1605
1606
1607 dnl ----------------------------------------------------------------------------
1608 dnl figure out if domainname is available in the utsname struct (GNU extension).
1609 dnl ----------------------------------------------------------------------------
1610 AC_CHECK_MEMBERS([struct utsname.domainname], [], [], [#include <sys/utsname.h>])
1611
1612 dnl ------------------
1613 dnl IPv6 header checks
1614 dnl ------------------
1615 AC_CHECK_HEADERS([netinet6/in6.h netinet/in6_var.h \
1616         netinet6/in6_var.h netinet6/nd6.h], [], [],
1617         FRR_INCLUDES)
1618
1619 m4_define([FRR_INCLUDES],dnl
1620 FRR_INCLUDES
1621 [#ifdef HAVE_NETINET6_IN6_H
1622 #include <netinet6/in6.h>
1623 #endif
1624 #ifdef HAVE_NETINET_IN6_VAR_H
1625 #include <netinet/in6_var.h>
1626 #endif
1627 #include <netinet/icmp6.h>
1628 #ifdef HAVE_NETINET6_IN6_VAR_H
1629 # include <netinet6/in6_var.h>
1630 #endif
1631 #ifdef HAVE_NETINET6_ND6_H
1632 # include <netinet6/nd6.h>
1633 #endif
1634 ])dnl
1635
1636 dnl --------------------
1637 dnl Daemon disable check
1638 dnl --------------------
1639
1640 AS_IF([test "$enable_bgpd" != "no"], [
1641   AC_DEFINE([HAVE_BGPD], [1], [bgpd])
1642 ])
1643
1644 AS_IF([test "$enable_ripd" != "no"], [
1645   AC_DEFINE([HAVE_RIPD], [1], [ripd])
1646 ])
1647
1648 AS_IF([test "$enable_ripngd" != "no"], [
1649   AC_DEFINE([HAVE_RIPNGD], [1], [ripngd])
1650 ])
1651
1652 AS_IF([test "$enable_ospfd" != "no"], [
1653   AC_DEFINE([HAVE_OSPFD], [1], [ospfd])
1654 ])
1655
1656 AS_IF([test "$enable_ospf6d" != "no"], [
1657   AC_DEFINE([HAVE_OSPF6D], [1], [ospf6d])
1658 ])
1659
1660 AS_IF([test "$enable_ldpd" != "no"], [
1661   AC_DEFINE([HAVE_LDPD], [1], [ldpd])
1662 ])
1663
1664 AS_IF([test "$enable_nhrpd" != "no"], [
1665   AC_DEFINE([HAVE_NHRPD], [1], [nhrpd])
1666 ])
1667
1668 AS_IF([test "$enable_eigrpd" != "no"], [
1669   AC_DEFINE([HAVE_EIGRPD], [1], [eigrpd])
1670 ])
1671
1672 AS_IF([test "$enable_babeld" != "no"], [
1673   AC_DEFINE([HAVE_BABELD], [1], [babeld])
1674 ])
1675
1676 AS_IF([test "$enable_isisd" != "no"], [
1677   AC_DEFINE([HAVE_ISISD], [1], [isisd])
1678 ])
1679
1680 AS_IF([test "$enable_pimd" != "no"], [
1681   AC_DEFINE([HAVE_PIMD], [1], [pimd])
1682 ])
1683
1684 AS_IF([test "$enable_pbrd" != "no"], [
1685   AC_DEFINE([HAVE_PBRD], [1], [pbrd])
1686 ])
1687
1688 AS_IF([test "$enable_sharpd" = "yes"], [
1689   AC_DEFINE([HAVE_SHARPD], [1], [sharpd])
1690 ])
1691
1692 AS_IF([test "$enable_staticd" != "no"], [
1693   AC_DEFINE([HAVE_STATICD], [1], [staticd])
1694 ])
1695
1696 AS_IF([test "$enable_fabricd" != "no"], [
1697   AC_DEFINE([HAVE_FABRICD], [1], [fabricd])
1698 ])
1699
1700 AS_IF([test "$enable_vrrpd" != "no"], [
1701   AC_DEFINE([HAVE_VRRPD], [1], [vrrpd])
1702 ])
1703
1704 if test "$enable_bfdd" = "no"; then
1705   AC_DEFINE([HAVE_BFDD], [0], [bfdd])
1706   BFDD=""
1707 else
1708   AC_DEFINE([HAVE_BFDD], [1], [bfdd])
1709   BFDD="bfdd"
1710
1711   case $host_os in
1712     linux*)
1713       AC_DEFINE([BFD_LINUX], [1], [bfdd])
1714       ;;
1715
1716     *)
1717       AC_DEFINE([BFD_BSD], [1], [bfdd])
1718       ;;
1719   esac
1720 fi
1721
1722 AS_IF([test "$enable_pathd" != "no"], [
1723   AC_DEFINE([HAVE_PATHD], [1], [pathd])
1724   AC_DEFINE([HAVE_PATHD_PCEP], [1], [pathd-pcep])
1725 ])
1726
1727
1728 if test "$ac_cv_lib_json_c_json_object_get" = "no" -a "$BFDD" = "bfdd"; then
1729   AC_MSG_ERROR(["you must use json-c library to use bfdd"])
1730 fi
1731
1732 NHRPD=""
1733 case "$host_os" in
1734   linux*)
1735     case "${enable_nhrpd}" in
1736       no)
1737         ;;
1738       yes)
1739         if test "$enable_clippy_only" != "yes"; then
1740         if test "$c_ares_found" != "true" ; then
1741           AC_MSG_ERROR([nhrpd requires libcares.  Please install c-ares and its -dev headers.])
1742         fi
1743         fi
1744         NHRPD="nhrpd"
1745         ;;
1746       *)
1747         if test "$c_ares_found" = "true" ; then
1748           NHRPD="nhrpd"
1749         fi
1750         ;;
1751     esac
1752     ;;
1753   *)
1754     if test "$enable_nhrpd" = "yes"; then
1755       AC_MSG_ERROR([nhrpd requires kernel APIs that are only present on Linux.])
1756     fi
1757     ;;
1758 esac
1759
1760 if test "$enable_watchfrr" = "no";then
1761   WATCHFRR=""
1762 else
1763   WATCHFRR="watchfrr"
1764 fi
1765
1766 OSPFCLIENT=""
1767 if test "$enable_ospfapi" != "no";then
1768     AC_DEFINE([SUPPORT_OSPF_API], [1], [OSPFAPI])
1769
1770   if test "$enable_ospfclient" != "no";then
1771       OSPFCLIENT="ospfclient"
1772   fi
1773 fi
1774
1775 if test "$enable_bgp_announce" = "no";then
1776   AC_DEFINE([DISABLE_BGP_ANNOUNCE], [1], [Disable BGP installation to zebra])
1777 else
1778   AC_DEFINE([DISABLE_BGP_ANNOUNCE], [0], [Disable BGP installation to zebra])
1779 fi
1780
1781 if test "$enable_bgp_vnc" != "no";then
1782   AC_DEFINE([ENABLE_BGP_VNC], [1], [Enable BGP VNC support])
1783 fi
1784
1785 bgpd_bmp=false
1786 case "${enable_bmp}" in
1787   no)
1788     ;;
1789   yes)
1790     if test "$c_ares_found" != "true" ; then
1791       AC_MSG_ERROR([BMP support requires libcares.  Please install c-ares and its -dev headers.])
1792     fi
1793     bgpd_bmp=true
1794     ;;
1795   *)
1796     if test "$c_ares_found" = "true" ; then
1797       bgpd_bmp=true
1798     fi
1799     ;;
1800 esac
1801
1802 if test "$enable_version_build_config" != "no";then
1803   AC_DEFINE([ENABLE_VERSION_BUILD_CONFIG], [1], [Report build configs in show version])
1804 fi
1805
1806 dnl ##########################################################################
1807 dnl LARGE if block
1808 if test "$enable_clippy_only" != "yes"; then
1809 dnl ##########################################################################
1810
1811 dnl ------------------
1812 dnl check Net-SNMP library
1813 dnl ------------------
1814 if test "$enable_snmp" != "" -a "$enable_snmp" != "no"; then
1815    AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], [no])
1816    if test "$NETSNMP_CONFIG" = "no"; then
1817       AC_MSG_ERROR([--enable-snmp given but unable to find net-snmp-config])
1818    fi
1819    SNMP_LIBS="`${NETSNMP_CONFIG} --agent-libs`"
1820    SNMP_CFLAGS="`${NETSNMP_CONFIG} --base-cflags`"
1821    # net-snmp lists all of its own dependencies.  we absolutely do not want that
1822    # among other things we avoid a GPL vs. OpenSSL license conflict here
1823    for removelib in crypto ssl sensors pci wrap; do
1824      SNMP_LIBS="`echo $SNMP_LIBS | sed -e 's/\(^\|\s\)-l'$removelib'\b/ /g' -e 's/\(^\|\s\)\([^\s]*\/\)\?lib'$removelib'\.[^\s]\+\b/ /g'`"
1825    done
1826    AC_MSG_CHECKING([whether we can link to Net-SNMP])
1827    AC_LINK_IFELSE_FLAGS([$SNMP_CFLAGS], [$SNMP_LIBS], [AC_LANG_PROGRAM([
1828 int main(void);
1829 ],
1830 [
1831 {
1832   return 0;
1833 }
1834 ])], [
1835      AC_MSG_RESULT([no])
1836      AC_MSG_ERROR([--enable-snmp given but not usable])])
1837    case "${enable_snmp}" in
1838      yes)
1839       SNMP_METHOD=agentx
1840       ;;
1841      agentx)
1842       SNMP_METHOD="${enable_snmp}"
1843       ;;
1844      *)
1845       AC_MSG_ERROR([--enable-snmp given with an unknown method (${enable_snmp}). Use yes or agentx])
1846       ;;
1847    esac
1848    AH_TEMPLATE([SNMP_AGENTX], [Use SNMP AgentX to interface with snmpd])
1849    AC_DEFINE_UNQUOTED(AS_TR_CPP(SNMP_${SNMP_METHOD}),,[SNMP method to interface with snmpd])
1850 fi
1851 AC_SUBST([SNMP_LIBS])
1852 AC_SUBST([SNMP_CFLAGS])
1853
1854 dnl ---------------
1855 dnl libyang
1856 dnl ---------------
1857 PKG_CHECK_MODULES([LIBYANG], [libyang >= 2.0.0], , [
1858   AC_MSG_ERROR([libyang (>= 2.0.0) was not found on your system.])
1859 ])
1860 ac_cflags_save="$CFLAGS"
1861 CFLAGS="$CFLAGS $LIBYANG_CFLAGS"
1862 AC_CHECK_MEMBER([struct lyd_node.priv], [], [
1863   AC_MSG_ERROR([m4_normalize([
1864     libyang needs to be compiled with ENABLE_LYD_PRIV=ON.
1865     Instructions for this are included in the build documentation for your platform at http://docs.frrouting.org/projects/dev-guide/en/latest/building.html])
1866   ])
1867 ], [[#include <libyang/libyang.h>]])
1868 CFLAGS="$ac_cflags_save"
1869
1870 dnl ---------------
1871 dnl configuration rollbacks
1872 dnl ---------------
1873 SQLITE3=false
1874 if test "$enable_config_rollbacks" = "yes"; then
1875   PKG_CHECK_MODULES([SQLITE3], [sqlite3], [
1876     AC_DEFINE([HAVE_CONFIG_ROLLBACKS], [1], [Enable configuration rollbacks])
1877     AC_DEFINE([HAVE_SQLITE3], [1], [Enable sqlite3 database])
1878     SQLITE3=true
1879   ], [
1880     AC_MSG_ERROR([--enable-config-rollbacks given but sqlite3 was not found on your system.])
1881   ])
1882 fi
1883
1884 dnl ---------------
1885 dnl confd
1886 dnl ---------------
1887 if test "$enable_confd" != "" -a "$enable_confd" != "no"; then
1888    AC_CHECK_PROG([CONFD], [confd], [confd], [/bin/false], "${enable_confd}/bin")
1889    if test "$CONFD" = "/bin/false"; then
1890       AC_MSG_ERROR([confd was not found on your system.])]
1891    fi
1892    CONFD_CFLAGS="-I${enable_confd}/include -L${enable_confd}/lib"
1893    AC_SUBST([CONFD_CFLAGS])
1894    CONFD_LIBS="-lconfd"
1895    AC_SUBST([CONFD_LIBS])
1896    AC_DEFINE([HAVE_CONFD], [1], [Enable confd integration])
1897 fi
1898
1899 dnl ---------------
1900 dnl sysrepo
1901 dnl ---------------
1902 if test "$enable_sysrepo" = "yes"; then
1903   PKG_CHECK_MODULES([SYSREPO], [sysrepo],
1904       [AC_DEFINE([HAVE_SYSREPO], [1], [Enable sysrepo integration])
1905       SYSREPO=true],
1906       [SYSREPO=false
1907       AC_MSG_ERROR([sysrepo was not found on your system.])]
1908   )
1909 fi
1910
1911 dnl ---------------
1912 dnl gRPC
1913 dnl ---------------
1914 if test "$enable_grpc" = "yes"; then
1915   AC_LANG_PUSH([C++])
1916   AX_CXX_COMPILE_STDCXX([11], [ext])
1917   PKG_CHECK_MODULES([GRPC], [grpc >= 6.0.0 grpc++ >= 1.16.1 protobuf >= 3.6.1 ], [
1918     AC_CHECK_PROGS([PROTOC], [protoc], [/bin/false])
1919     if test "$PROTOC" = "/bin/false"; then
1920       AC_MSG_FAILURE([grpc requested but protoc not found.])
1921     fi
1922
1923     AC_DEFINE([HAVE_GRPC], [1], [Enable the gRPC northbound plugin])
1924     GRPC=true
1925   ], [
1926     GRPC=false
1927     AC_MSG_ERROR([grpc/grpc++ were not found on your system.])
1928   ])
1929   AC_LANG_POP([C++])
1930 fi
1931
1932 dnl -----
1933 dnl LTTng
1934 dnl -----
1935 if test "$enable_lttng" = "yes"; then
1936   PKG_CHECK_MODULES([UST], [lttng-ust >= 2.12.0], [
1937     AC_DEFINE([HAVE_LTTNG], [1], [Enable LTTng support])
1938     LTTNG=true
1939   ], [
1940     AC_MSG_ERROR([configuration specifies --enable-lttng but lttng-ust was not found])
1941   ])
1942 fi
1943
1944 dnl ----
1945 dnl USDT
1946 dnl ----
1947 if test "$enable_usdt" = "yes"; then
1948   AC_CHECK_HEADERS([sys/sdt.h], [
1949     AC_DEFINE([HAVE_USDT], [1], [Enable USDT probes])
1950     USDT=true
1951   ], [
1952     AC_MSG_ERROR([configuration specifies --enable-usdt but no USDT kernel headers (sys/sdt.h) found])
1953   ])
1954 fi
1955
1956 dnl ------
1957 dnl ZeroMQ
1958 dnl ------
1959 if test "$enable_zeromq" != "no"; then
1960   PKG_CHECK_MODULES([ZEROMQ], [libzmq >= 4.0.0], [
1961     AC_DEFINE([HAVE_ZEROMQ], [1], [Enable ZeroMQ support])
1962     ZEROMQ=true
1963   ], [
1964     if test "$enable_zeromq" = "yes"; then
1965       AC_MSG_ERROR([configuration specifies --enable-zeromq but libzmq was not found])
1966     fi
1967   ])
1968 fi
1969
1970 dnl ------------------------------------
1971 dnl Enable RPKI and add librtr to libs
1972 dnl ------------------------------------
1973 if test "$enable_rpki" = "yes"; then
1974   PKG_CHECK_MODULES([RTRLIB], [rtrlib >= 0.5.0],
1975       [RPKI=true],
1976       [RPKI=false
1977       AC_MSG_ERROR([rtrlib was not found on your system or is too old.])]
1978   )
1979 fi
1980
1981 dnl ------------------------------------
1982 dnl pimd is not supported on OpenBSD and MacOS
1983 dnl ------------------------------------
1984 if test "$enable_pimd" != "no"; then
1985 AC_MSG_CHECKING([for pimd OS support])
1986 case "$host_os" in
1987   darwin*)
1988     AC_MSG_RESULT([no])
1989     enable_pimd="no"
1990     ;;
1991   openbsd*)
1992     AC_MSG_RESULT([no])
1993     enable_pimd="no"
1994     ;;
1995   *)
1996     AC_MSG_RESULT([yes])
1997     ;;
1998 esac
1999 fi
2000
2001 dnl -------------------------------------
2002 dnl VRRP is only supported on linux
2003 dnl -------------------------------------
2004 if test "$enable_vrrpd" != "no"; then
2005 AC_MSG_CHECKING([for VRRP OS support])
2006 case "$host_os" in
2007   linux*)
2008     AC_MSG_RESULT([yes])
2009     ;;
2010   *)
2011     AC_MSG_RESULT([no])
2012     enable_vrrpd="no"
2013     ;;
2014 esac
2015 fi
2016
2017 dnl ------------------------------------------
2018 dnl Check whether rtrlib was build with ssh support
2019 dnl ------------------------------------------
2020 AC_MSG_CHECKING([whether the RTR Library is compiled with SSH])
2021 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "rtrlib/rtrlib.h"]],
2022                         [[struct tr_ssh_config config;]])],
2023         [AC_MSG_RESULT([yes])
2024         AC_DEFINE([FOUND_SSH], [1], [found_ssh])],
2025         AC_MSG_RESULT([no])
2026 )
2027
2028 dnl ---------------
2029 dnl dlopen & dlinfo
2030 dnl ---------------
2031 AC_SEARCH_LIBS([dlopen], [dl dld], [], [
2032   AC_MSG_ERROR([unable to find the dlopen()])
2033 ])
2034
2035 AC_CHECK_HEADERS([link.h])
2036
2037 AC_CACHE_CHECK([for dlinfo(RTLD_DI_ORIGIN)], [frr_cv_rtld_di_origin], [
2038   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2039 #include <stdlib.h>
2040 #ifdef HAVE_LINK_H
2041 #include <link.h>
2042 #endif
2043 #include <dlfcn.h>
2044 ]], [[
2045   char origin[1];
2046   dlinfo (NULL, RTLD_DI_ORIGIN, &origin);
2047 ]])], [
2048     frr_cv_rtld_di_origin=yes
2049   ], [
2050     frr_cv_rtld_di_origin=no
2051   ])
2052 ])
2053 if test "$frr_cv_rtld_di_origin" = "yes"; then
2054   AC_DEFINE([HAVE_DLINFO_ORIGIN], [1], [Have dlinfo RTLD_DI_ORIGIN])
2055 fi
2056
2057 AC_CACHE_CHECK([for dlinfo(RTLD_DI_LINKMAP)], [frr_cv_rtld_di_linkmap], [
2058   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2059 #include <stdlib.h>
2060 #ifdef HAVE_LINK_H
2061 #include <link.h>
2062 #endif
2063 #include <dlfcn.h>
2064 ]], [[
2065   struct link_map *lm = NULL;
2066   dlinfo (NULL, RTLD_DI_LINKMAP, &lm);
2067 ]])], [
2068     frr_cv_rtld_di_linkmap=yes
2069   ], [
2070     frr_cv_rtld_di_linkmap=no
2071   ])
2072 ])
2073 if test "$frr_cv_rtld_di_linkmap" = "yes"; then
2074   AC_DEFINE([HAVE_DLINFO_LINKMAP], [1], [Have dlinfo RTLD_DI_LINKMAP])
2075 fi
2076
2077 dnl ##########################################################################
2078 dnl test "$enable_clippy_only" != "yes"
2079 fi
2080 dnl END OF LARGE if block
2081 dnl ##########################################################################
2082
2083 dnl ---------------------------
2084 dnl sockaddr and netinet checks
2085 dnl ---------------------------
2086 AC_CHECK_TYPES([
2087         struct sockaddr_dl,
2088         struct vifctl, struct mfcctl, struct sioc_sg_req,
2089         vifi_t, struct sioc_vif_req, struct igmpmsg,
2090         struct ifaliasreq, struct if6_aliasreq, struct in6_aliasreq,
2091         struct nd_opt_adv_interval,
2092         struct nd_opt_homeagent_info, struct nd_opt_adv_interval,
2093         struct nd_opt_rdnss, struct nd_opt_dnssl],
2094         [], [], FRR_INCLUDES)
2095
2096 AC_CHECK_MEMBERS([struct sockaddr.sa_len,
2097         struct sockaddr_in.sin_len, struct sockaddr_un.sun_len,
2098         struct sockaddr_dl.sdl_len,
2099         struct if6_aliasreq.ifra_lifetime,
2100         struct nd_opt_adv_interval.nd_opt_ai_type],
2101         [], [], FRR_INCLUDES)
2102
2103 dnl ---------------------------
2104 dnl IRDP/pktinfo/icmphdr checks
2105 dnl ---------------------------
2106
2107 AC_CHECK_TYPES([struct in_pktinfo], [
2108   AC_CHECK_TYPES([struct icmphdr], [
2109     IRDP=true
2110   ], [
2111     IRDP=false
2112   ], [FRR_INCLUDES])
2113 ], [
2114   IRDP=false
2115 ], [FRR_INCLUDES])
2116
2117 case "${enable_irdp}" in
2118 yes)
2119   $IRDP || AC_MSG_ERROR(['IRDP requires in_pktinfo at the moment!'])
2120   ;;
2121 no)
2122   IRDP=false
2123   ;;
2124 esac
2125
2126
2127 dnl -----------------------
2128 dnl checking for IP_PKTINFO
2129 dnl -----------------------
2130 AC_MSG_CHECKING([for IP_PKTINFO])
2131 AC_COMPILE_IFELSE(
2132 [ AC_LANG_PROGRAM([[
2133         #include <netdb.h>
2134    ]], [[
2135         int opt = IP_PKTINFO;
2136    ]])
2137 ],[
2138   AC_MSG_RESULT([yes])
2139   AC_DEFINE([HAVE_IP_PKTINFO], [1], [Have IP_PKTINFO])
2140 ],[
2141   AC_MSG_RESULT([no])
2142 ])
2143
2144 dnl ---------------------------
2145 dnl checking for IP_RECVDSTADDR
2146 dnl ---------------------------
2147 AC_MSG_CHECKING([for IP_RECVDSTADDR])
2148 AC_COMPILE_IFELSE(
2149 [ AC_LANG_PROGRAM([[
2150         #include <netinet/in.h>
2151   ]], [[
2152         int opt = IP_RECVDSTADDR;
2153   ]])
2154 ],[
2155   AC_MSG_RESULT([yes])
2156   AC_DEFINE([HAVE_IP_RECVDSTADDR], [1], [Have IP_RECVDSTADDR])
2157 ],[
2158   AC_MSG_RESULT([no])
2159 ])
2160
2161 dnl ----------------------
2162 dnl checking for IP_RECVIF
2163 dnl ----------------------
2164 AC_MSG_CHECKING([for IP_RECVIF])
2165 AC_COMPILE_IFELSE(
2166 [ AC_LANG_PROGRAM([[
2167         #include <netinet/in.h>
2168   ]], [[
2169         int opt = IP_RECVIF;
2170   ]])
2171 ],[
2172   AC_MSG_RESULT([yes])
2173   AC_DEFINE([HAVE_IP_RECVIF], [1], [Have IP_RECVIF])
2174 ],[
2175   AC_MSG_RESULT([no])
2176 ])
2177
2178 dnl ----------------------
2179 dnl checking for SO_BINDANY
2180 dnl ----------------------
2181 AC_MSG_CHECKING([for SO_BINDANY])
2182 AC_COMPILE_IFELSE(
2183 [ AC_LANG_PROGRAM([[
2184         #include <sys/socket.h>
2185   ]], [[
2186         int opt = SO_BINDANY;
2187   ]])
2188 ],[
2189   AC_MSG_RESULT([yes])
2190   AC_DEFINE([HAVE_SO_BINDANY], [1], [Have SO_BINDANY])
2191 ],[
2192   AC_MSG_RESULT([no])
2193 ])
2194
2195 dnl ----------------------
2196 dnl checking for IP_FREEBIND
2197 dnl ----------------------
2198 AC_MSG_CHECKING([for IP_FREEBIND])
2199 AC_COMPILE_IFELSE(
2200 [ AC_LANG_PROGRAM([[
2201         #include <netinet/in.h>
2202   ]], [[
2203         int opt = IP_FREEBIND;
2204   ]])
2205 ],[
2206   AC_MSG_RESULT([yes])
2207   AC_DEFINE([HAVE_IP_FREEBIND], [1], [Have IP_FREEBIND])
2208 ],[
2209   AC_MSG_RESULT([no])
2210 ])
2211
2212 dnl --------------------------------------
2213 dnl checking for be32dec existence or not
2214 dnl --------------------------------------
2215 AC_CHECK_DECLS([be32enc, be32dec], [], [], [
2216         #ifdef HAVE_SYS_ENDIAN_H
2217         #include <sys/endian.h>
2218         #endif
2219         #ifdef HAVE_ENDIAN_H
2220         #include <endian.h>
2221         #endif
2222 ])
2223
2224 dnl --------------------------------------
2225 dnl checking for clock_time monotonic struct and call
2226 dnl --------------------------------------
2227 AC_CHECK_DECL([CLOCK_MONOTONIC],
2228         [AC_CHECK_LIB([rt], [clock_gettime], [LIBS="$LIBS -lrt"])
2229          AC_DEFINE([HAVE_CLOCK_MONOTONIC], [1], [Have monotonic clock])
2230 ], [AC_MSG_RESULT([no])], [FRR_INCLUDES])
2231
2232 AC_CHECK_DECL([CLOCK_THREAD_CPUTIME_ID], [
2233          AC_DEFINE([HAVE_CLOCK_THREAD_CPUTIME_ID], [1], [Have cpu-time clock])
2234 ], [AC_MSG_RESULT([no])], [FRR_INCLUDES])
2235
2236 AC_SEARCH_LIBS([clock_nanosleep], [rt], [
2237   AC_DEFINE([HAVE_CLOCK_NANOSLEEP], [1], [Have clock_nanosleep()])
2238 ])
2239
2240 dnl --------------------------------------
2241 dnl checking for flex and bison
2242 dnl --------------------------------------
2243
2244 AM_PROG_LEX
2245 AC_MSG_CHECKING([version of flex])
2246 frr_ac_flex_version="$(eval $LEX -V | grep flex | head -n 1)"
2247 frr_ac_flex_version="${frr_ac_flex_version##* }"
2248 AC_MSG_RESULT([$frr_ac_flex_version])
2249 AX_COMPARE_VERSION([$frr_ac_flex_version], [lt], [2.5.20], [
2250   LEX="$SHELL $missing_dir/missing flex"
2251   if test -f "${srcdir}/lib/command_lex.c" -a -f "${srcdir}/lib/command_lex.h"; then
2252     AC_MSG_WARN([using pregenerated flex output files])
2253   else
2254     AC_MSG_ERROR([flex failure and pregenerated files not included (probably a git build)])
2255   fi
2256   AC_SUBST([LEX_OUTPUT_ROOT], [lex.yy])
2257   AC_SUBST([LEXLIB], [''])
2258 ])
2259
2260 AC_PROG_YACC
2261 dnl thanks GNU bison for this b*llshit...
2262 AC_MSG_CHECKING([version of bison])
2263 frr_ac_bison_version="$(eval $YACC -V | grep bison | head -n 1)"
2264 frr_ac_bison_version="${frr_ac_bison_version##* }"
2265 frr_ac_bison_missing="false"
2266 case "x${frr_ac_bison_version}x" in
2267   x2.7*)
2268     BISON_OPENBRACE='"'
2269     BISON_CLOSEBRACE='"'
2270     BISON_VERBOSE=''
2271     AC_MSG_RESULT([$frr_ac_bison_version - 2.7 or older])
2272     ;;
2273   x2.*|x1.*)
2274     AC_MSG_RESULT([$frr_ac_bison_version])
2275     AC_MSG_WARN([installed bison is too old.  Please install GNU bison 2.7.x or newer.])
2276     frr_ac_bison_missing="true"
2277     ;;
2278   x)
2279     AC_MSG_RESULT([none])
2280     AC_MSG_WARN([could not determine bison version.  Please install GNU bison 2.7.x or newer.])
2281     frr_ac_bison_missing="true"
2282     ;;
2283   x3.[012][^0-9]*)
2284     BISON_OPENBRACE='{'
2285     BISON_CLOSEBRACE='}'
2286     BISON_VERBOSE='-Dparse.error=verbose'
2287     AC_MSG_RESULT([$frr_ac_bison_version - 3.0 to 3.2])
2288     ;;
2289   *)
2290     BISON_OPENBRACE='{'
2291     BISON_CLOSEBRACE='}'
2292     BISON_VERBOSE='-Dparse.error=verbose -Wno-yacc'
2293     AC_MSG_RESULT([$frr_ac_bison_version - 3.3 or newer])
2294     ;;
2295 esac
2296 AC_SUBST([BISON_OPENBRACE])
2297 AC_SUBST([BISON_CLOSEBRACE])
2298 AC_SUBST([BISON_VERBOSE])
2299
2300 if $frr_ac_bison_missing; then
2301   YACC="$SHELL $missing_dir/missing bison -y"
2302   if test -f "${srcdir}/lib/command_parse.c" -a -f "${srcdir}/lib/command_parse.h"; then
2303     AC_MSG_WARN([using pregenerated bison output files])
2304   else
2305     AC_MSG_ERROR([bison failure and pregenerated files not included (probably a git build)])
2306   fi
2307 fi
2308
2309 dnl -------------------
2310 dnl capabilities checks
2311 dnl -------------------
2312 if test "$enable_capabilities" != "no"; then
2313   AC_MSG_CHECKING([whether prctl PR_SET_KEEPCAPS is available])
2314   AC_COMPILE_IFELSE(
2315   [ AC_LANG_PROGRAM([[
2316         #include <sys/prctl.h>
2317     ]], [[
2318         prctl(PR_SET_KEEPCAPS, 1, 0, 0, 0);
2319     ]])
2320   ],[AC_MSG_RESULT([yes])
2321      AC_DEFINE([HAVE_PR_SET_KEEPCAPS], [1], [prctl])
2322      frr_ac_keepcaps="yes"
2323   ],[AC_MSG_RESULT(no)
2324   ])
2325   if test "$frr_ac_keepcaps" = "yes"; then
2326     AC_CHECK_HEADERS([sys/capability.h])
2327   fi
2328   if test "$ac_cv_header_sys_capability_h" = "yes"; then
2329     AC_CHECK_LIB([cap], [cap_init],
2330       [AC_DEFINE([HAVE_LCAPS], [1], [Capabilities])
2331        LIBCAP="-lcap"
2332        frr_ac_lcaps="yes"]
2333     )
2334   fi
2335   if test "$frr_ac_scaps" = "yes" \
2336        -o "$frr_ac_lcaps" = "yes"; then
2337     AC_DEFINE([HAVE_CAPABILITIES], [1], [capabilities])
2338   fi
2339
2340   case "$host_os" in
2341   linux*)
2342     if test "$enable_clippy_only" != "yes"; then
2343     if test "$frr_ac_lcaps" != "yes"; then
2344       AC_MSG_ERROR([libcap and/or its headers were not found.  Running FRR without libcap support built in causes a huge performance penalty.])
2345     fi
2346     fi
2347     ;;
2348   esac
2349 else
2350   case "$host_os" in
2351   linux*)
2352     AC_MSG_WARN([Running FRR without libcap support built in causes a huge performance penalty.])
2353     ;;
2354   esac
2355 fi
2356 AC_SUBST([LIBCAP])
2357
2358 dnl ---------------------------
2359 dnl check for glibc 'backtrace'
2360 dnl ---------------------------
2361 if test "$enable_backtrace" != "no" ; then
2362   backtrace_ok=no
2363   PKG_CHECK_MODULES([UNWIND], [libunwind], [
2364     AC_DEFINE([HAVE_LIBUNWIND], [1], [libunwind])
2365     backtrace_ok=yes
2366   ], [
2367     true
2368   ])
2369
2370   if test "$backtrace_ok" = "no"; then
2371     AC_CHECK_HEADER([unwind.h], [
2372       AC_SEARCH_LIBS([unw_getcontext], [unwind], [
2373         AC_DEFINE([HAVE_LIBUNWIND], [1], [libunwind])
2374         backtrace_ok=yes
2375       ])
2376     ])
2377   fi
2378
2379   if test "$backtrace_ok" = "no"; then
2380     AC_CHECK_HEADER([execinfo.h], [
2381       AC_SEARCH_LIBS([backtrace], [execinfo], [
2382         AC_DEFINE([HAVE_GLIBC_BACKTRACE], [1], [Glibc backtrace])
2383         backtrace_ok=yes
2384       ],, [-lm])
2385     ])
2386   fi
2387
2388   if test "$enable_backtrace" = "yes" -a "$backtrace_ok" = "no"; then
2389     dnl user explicitly requested backtrace but we failed to find support
2390     AC_MSG_FAILURE([failed to find backtrace or libunwind support])
2391   fi
2392 fi
2393
2394 dnl -----------------------------------------
2395 dnl check for malloc mallinfo struct and call
2396 dnl this must try and link using LIBS, in
2397 dnl order to check no alternative allocator
2398 dnl has been specified, which might not provide
2399 dnl mallinfo
2400 dnl -----------------------------------------
2401 AC_CHECK_HEADERS([malloc.h malloc_np.h malloc/malloc.h],,, [FRR_INCLUDES])
2402
2403 AC_CACHE_CHECK([whether mallinfo is available], [frr_cv_mallinfo], [
2404   AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2405 #ifdef HAVE_MALLOC_H
2406 #include <malloc.h>
2407 #endif
2408 #ifdef HAVE_MALLOC_NP_H
2409 #include <malloc_np.h>
2410 #endif
2411 #ifdef HAVE_MALLOC_MALLOC_H
2412 #include <malloc/malloc.h>
2413 #endif
2414 ]], [[
2415 struct mallinfo ac_x; ac_x = mallinfo ();
2416 ]])], [
2417     frr_cv_mallinfo=yes
2418   ], [
2419     frr_cv_mallinfo=no
2420   ])
2421 ])
2422 if test "$frr_cv_mallinfo" = "yes"; then
2423   AC_DEFINE([HAVE_MALLINFO], [1], [mallinfo])
2424 fi
2425
2426 AC_CACHE_CHECK([whether mallinfo2 is available], [frr_cv_mallinfo2], [
2427   AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2428 #ifdef HAVE_MALLOC_H
2429 #include <malloc.h>
2430 #endif
2431 #ifdef HAVE_MALLOC_NP_H
2432 #include <malloc_np.h>
2433 #endif
2434 #ifdef HAVE_MALLOC_MALLOC_H
2435 #include <malloc/malloc.h>
2436 #endif
2437 ]], [[
2438 struct mallinfo2 ac_x; ac_x = mallinfo2 ();
2439 ]])], [
2440     frr_cv_mallinfo2=yes
2441   ], [
2442     frr_cv_mallinfo2=no
2443   ])
2444 ])
2445 if test "$frr_cv_mallinfo2" = "yes"; then
2446   AC_DEFINE([HAVE_MALLINFO2], [1], [mallinfo2])
2447 fi
2448
2449 AC_MSG_CHECKING([whether malloc_usable_size is available])
2450 AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2451 #ifdef HAVE_MALLOC_H
2452 #include <malloc.h>
2453 #endif
2454 #ifdef HAVE_MALLOC_MALLOC_H
2455 #include <malloc/malloc.h>
2456 #endif
2457 ]], [[
2458 size_t ac_x; ac_x = malloc_usable_size(NULL);
2459 ]])], [
2460   AC_MSG_RESULT([yes])
2461   AC_DEFINE([HAVE_MALLOC_USABLE_SIZE], [1], [malloc_usable_size])
2462 ], [
2463   AC_MSG_RESULT([no])
2464
2465   AC_MSG_CHECKING([whether malloc_size is available])
2466   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2467 #ifdef HAVE_MALLOC_H
2468 #include <malloc.h>
2469 #endif
2470 #ifdef HAVE_MALLOC_MALLOC_H
2471 #include <malloc/malloc.h>
2472 #endif
2473 ]], [[
2474 size_t ac_x; ac_x = malloc_size(NULL);
2475 ]])], [
2476     AC_MSG_RESULT([yes])
2477     AC_DEFINE([HAVE_MALLOC_SIZE], [1], [malloc_size])
2478   ], [
2479     AC_MSG_RESULT([no])
2480   ])
2481 ])
2482
2483 dnl ----------
2484 dnl configure date
2485 dnl ----------
2486 dev_version=`echo $VERSION | grep dev`
2487 #don't expire deprecated code in non 'dev' branch
2488 if test "$dev_version" = ""; then
2489    CONFDATE=0
2490 else
2491    CONFDATE=`date '+%Y%m%d'`
2492 fi
2493 AC_SUBST([CONFDATE])
2494
2495 dnl ------------------------------
2496 dnl set paths for state directory
2497 dnl ------------------------------
2498 AC_MSG_CHECKING([directory to use for state file])
2499 if test "$prefix" = "NONE"; then
2500   frr_statedir_prefix="";
2501 else
2502   frr_statedir_prefix=${prefix}
2503 fi
2504 if test "$localstatedir" = '${prefix}/var'; then
2505   for FRR_STATE_DIR in ${frr_statedir_prefix}/var/run dnl
2506                         ${frr_statedir_prefix}/var/adm dnl
2507                         ${frr_statedir_prefix}/etc dnl
2508                         /var/run        dnl
2509                         /var/adm        dnl
2510                         /etc            dnl
2511                         /dev/null;
2512   do
2513     test -d $FRR_STATE_DIR && break
2514   done
2515   frr_statedir=$FRR_STATE_DIR
2516 else
2517   frr_statedir=${localstatedir}
2518 fi
2519 if test "$frr_statedir" = "/dev/null"; then
2520     AC_MSG_ERROR([STATE DIRECTORY NOT FOUND! FIX OR SPECIFY --localstatedir!])
2521 fi
2522 AC_MSG_RESULT([${frr_statedir}])
2523 AC_SUBST([frr_statedir])
2524
2525 AC_DEFINE_UNQUOTED([LDPD_SOCKET], ["$frr_statedir%s%s/ldpd.sock"], [ldpd control socket])
2526 AC_DEFINE_UNQUOTED([ZEBRA_SERV_PATH], ["$frr_statedir%s%s/zserv.api"], [zebra api socket])
2527 AC_DEFINE_UNQUOTED([BFDD_CONTROL_SOCKET], ["$frr_statedir%s%s/bfdd.sock"], [bfdd control socket])
2528 AC_DEFINE_UNQUOTED([DAEMON_VTY_DIR], ["$frr_statedir%s%s"], [daemon vty directory])
2529 AC_DEFINE_UNQUOTED([DAEMON_DB_DIR], ["$frr_statedir"], [daemon database directory])
2530
2531 dnl autoconf does this, but it does it too late...
2532 test "$prefix" = "NONE" && prefix=$ac_default_prefix
2533 test "$exec_prefix" = "NONE" && exec_prefix='${prefix}'
2534
2535 dnl get the full path, recursing through variables...
2536 vtysh_bin="$bindir/vtysh"
2537 for I in 1 2 3 4 5 6 7 8 9 10; do
2538         eval vtysh_bin="\"$vtysh_bin\""
2539 done
2540 AC_DEFINE_UNQUOTED([VTYSH_BIN_PATH], ["$vtysh_bin"], [path to vtysh binary])
2541 AC_SUBST([vtysh_bin])
2542
2543 CFG_SYSCONF="$sysconfdir"
2544 CFG_SBIN="$sbindir"
2545 CFG_STATE="$frr_statedir"
2546 CFG_MODULE="$moduledir"
2547 CFG_YANGMODELS="$yangmodelsdir"
2548 CFG_SCRIPT="$scriptdir"
2549 for I in 1 2 3 4 5 6 7 8 9 10; do
2550         eval CFG_SYSCONF="\"$CFG_SYSCONF\""
2551         eval CFG_SBIN="\"$CFG_SBIN\""
2552         eval CFG_STATE="\"$CFG_STATE\""
2553         eval CFG_MODULE="\"$CFG_MODULE\""
2554         eval CFG_YANGMODELS="\"$CFG_YANGMODELS\""
2555         eval CFG_SCRIPT="\"$CFG_SCRIPT\""
2556 done
2557 AC_SUBST([CFG_SYSCONF])
2558 AC_SUBST([CFG_SBIN])
2559 AC_SUBST([CFG_STATE])
2560 AC_SUBST([CFG_MODULE])
2561 AC_SUBST([CFG_SCRIPT])
2562 AC_SUBST([CFG_YANGMODELS])
2563 AC_DEFINE_UNQUOTED([MODULE_PATH], ["$CFG_MODULE"], [path to modules])
2564 AC_DEFINE_UNQUOTED([SCRIPT_PATH], ["$CFG_SCRIPT"], [path to scripts])
2565 AC_DEFINE_UNQUOTED([YANG_MODELS_PATH], ["$CFG_YANGMODELS"], [path to YANG data models])
2566 AC_DEFINE_UNQUOTED([WATCHFRR_SH_PATH], ["${CFG_SBIN%/}/watchfrr.sh"], [path to watchfrr.sh])
2567
2568 dnl various features
2569 AM_CONDITIONAL([SUPPORT_REALMS], [test "$enable_realms" = "yes"])
2570 AM_CONDITIONAL([ENABLE_BGP_VNC], [test "$enable_bgp_vnc" != "no"])
2571 AM_CONDITIONAL([BGP_BMP], [$bgpd_bmp])
2572 dnl northbound
2573 AM_CONDITIONAL([SQLITE3], [$SQLITE3])
2574 AM_CONDITIONAL([CONFD], [test "$enable_confd" != ""])
2575 AM_CONDITIONAL([SYSREPO], [test "$enable_sysrepo" = "yes"])
2576 AM_CONDITIONAL([GRPC], [test "$enable_grpc" = "yes"])
2577 AM_CONDITIONAL([ZEROMQ], [test "$ZEROMQ" = "true"])
2578 dnl plugins
2579 AM_CONDITIONAL([RPKI], [test "$RPKI" = "true"])
2580 AM_CONDITIONAL([SNMP], [test "$SNMP_METHOD" = "agentx"])
2581 AM_CONDITIONAL([IRDP], [$IRDP])
2582 AM_CONDITIONAL([FPM], [test "$enable_fpm" = "yes"])
2583 AM_CONDITIONAL([HAVE_PROTOBUF], [test "$enable_protobuf" = "yes"])
2584 AM_CONDITIONAL([HAVE_PROTOBUF3], [$PROTO3])
2585
2586 dnl PCEP plugin
2587 AS_IF([test "$enable_pathd" != "no"], [
2588        AC_SUBST([PATHD_PCEP_LIBS], ["pceplib/libpcep_pcc.la"])
2589        AC_SUBST([PATHD_PCEP_INCL], ["-I./pceplib "])
2590        ])
2591 AC_CHECK_LIB([cunit], [CU_initialize_registry], [pcep_cunit=yes],[pcep_cunit=no])
2592 AM_CONDITIONAL([PATHD_PCEP_TEST], [test "x${pcep_cunit}" = xyes])
2593 AC_CHECK_PROG(VALGRIND_CHECK, valgrind, yes)
2594 AM_CONDITIONAL([HAVE_VALGRIND_PCEP], [test "$VALGRIND_CHECK" = "yes"])
2595
2596 dnl daemons
2597 AM_CONDITIONAL([VTYSH], [test "$VTYSH" = "vtysh"])
2598 AM_CONDITIONAL([ZEBRA], [test "$enable_zebra" != "no"])
2599 AM_CONDITIONAL([BGPD], [test "$enable_bgpd" != "no"])
2600 AM_CONDITIONAL([RIPD], [test "$enable_ripd" != "no"])
2601 AM_CONDITIONAL([OSPFD], [test "$enable_ospfd" != "no"])
2602 AM_CONDITIONAL([LDPD], [test "$enable_ldpd" != "no"])
2603 AM_CONDITIONAL([BFDD], [test "$BFDD" = "bfdd"])
2604 AM_CONDITIONAL([NHRPD], [test "$NHRPD" = "nhrpd"])
2605 AM_CONDITIONAL([EIGRPD], [test "$enable_eigrpd" != "no"])
2606 AM_CONDITIONAL([WATCHFRR], [test "$WATCHFRR" = "watchfrr"])
2607 AM_CONDITIONAL([OSPFCLIENT], [test "$OSPFCLIENT" = "ospfclient"])
2608 AM_CONDITIONAL([RIPNGD], [test "$enable_ripngd" != "no"])
2609 AM_CONDITIONAL([BABELD], [test "$enable_babeld" != "no"])
2610 AM_CONDITIONAL([OSPF6D], [test "$enable_ospf6d" != "no"])
2611 AM_CONDITIONAL([ISISD], [test "$enable_isisd" != "no"])
2612 AM_CONDITIONAL([PIMD], [test "$enable_pimd" != "no"])
2613 AM_CONDITIONAL([PBRD], [test "$enable_pbrd" != "no"])
2614 AM_CONDITIONAL([SHARPD], [test "$enable_sharpd" = "yes"])
2615 AM_CONDITIONAL([STATICD], [test "$enable_staticd" != "no"])
2616 AM_CONDITIONAL([FABRICD], [test "$enable_fabricd" != "no"])
2617 AM_CONDITIONAL([VRRPD], [test "$enable_vrrpd" != "no"])
2618 AM_CONDITIONAL([PATHD], [test "$enable_pathd" != "no"])
2619 AM_CONDITIONAL([PATHD_PCEP], [test "$enable_pathd" != "no"])
2620
2621 AC_CONFIG_FILES([Makefile],[
2622         test "$enable_dev_build" = "yes" && makefile_devbuild="--dev-build"
2623         ${PYTHON} "${ac_abs_top_srcdir}/python/makefile.py" ${makefile_devbuild} || exit 1
2624 ], [
2625         PYTHON="$PYTHON"
2626         enable_dev_build="$enable_dev_build"
2627 ])
2628
2629 AC_CONFIG_FILES([
2630           config.version
2631           redhat/frr.spec
2632           alpine/APKBUILD
2633           snapcraft/snapcraft.yaml
2634           lib/version.h
2635           tests/lib/cli/test_cli.refout
2636           pkgsrc/bgpd.sh pkgsrc/ospf6d.sh pkgsrc/ospfd.sh
2637           pkgsrc/ripd.sh pkgsrc/ripngd.sh pkgsrc/zebra.sh
2638           pkgsrc/eigrpd.sh])
2639
2640 AC_CONFIG_FILES([vtysh/extract.pl], [chmod +x vtysh/extract.pl])
2641 AC_CONFIG_FILES([tools/frr], [chmod +x tools/frr])
2642 AC_CONFIG_FILES([tools/watchfrr.sh], [chmod +x tools/watchfrr.sh])
2643 AC_CONFIG_FILES([tools/frrinit.sh], [chmod +x tools/frrinit.sh])
2644 AC_CONFIG_FILES([tools/frrcommon.sh])
2645 AC_CONFIG_FILES([tools/frr.service])
2646 AC_CONFIG_FILES([tools/frr@.service])
2647
2648 AS_IF([test "$with_pkg_git_version" = "yes"], [
2649     AC_CONFIG_COMMANDS([lib/gitversion.h], [
2650         dst="${ac_abs_top_builddir}/lib/gitversion.h"
2651         ${PERL} "${ac_abs_top_srcdir}/lib/gitversion.pl" \
2652                 "${ac_abs_top_srcdir}" \
2653                 > "${dst}.tmp"
2654         test -f "$dst" \
2655                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
2656                 && rm "${dst}.tmp" \
2657                 || mv "${dst}.tmp" "${dst}"
2658     ], [
2659         PERL="$PERL"
2660     ])
2661 ])
2662
2663 ## Hack, but working solution to avoid rebuilding of frr.info.
2664 ## It's already in CVS until texinfo 4.7 is more common.
2665 AC_OUTPUT
2666
2667 if test "$enable_rpath" = "yes" ; then
2668         true
2669 else
2670         # See https://old-en.opensuse.org/openSUSE:Packaging_Guidelines#Removing_Rpath
2671         sed -i 's|^hardcode_libdir_flag_spec=.*|hardcode_libdir_flag_spec=""|g' libtool
2672         sed -i 's|^runpath_var=LD_RUN_PATH|runpath_var=DIE_RPATH_DIE|g' libtool
2673 fi
2674
2675 echo "
2676 FRRouting configuration
2677 ------------------------------
2678 FRR version             : ${PACKAGE_VERSION}
2679 host operating system   : ${host_os}
2680 source code location    : ${srcdir}
2681 compiler                : ${CC}
2682 compiler flags          : ${CFLAGS} ${WERROR} ${AC_CFLAGS} ${SAN_FLAGS}
2683 make                    : ${MAKE-make}
2684 linker flags            : ${LDFLAGS} ${SAN_FLAGS} ${LIBS} ${LIBCAP} ${LIBREADLINE} ${LIBM}
2685 state file directory    : ${frr_statedir}
2686 config file directory   : `eval echo \`echo ${sysconfdir}\``
2687 module directory        : ${CFG_MODULE}
2688 script directory        : ${CFG_SCRIPT}
2689 user to run as          : ${enable_user}
2690 group to run as         : ${enable_group}
2691 group for vty sockets   : ${enable_vty_group}
2692 config file mask        : ${enable_configfile_mask}
2693 log file mask           : ${enable_logfile_mask}
2694 zebra protobuf enabled  : ${enable_protobuf:-no}
2695 vici socket path        : ${vici_socket}
2696
2697 The above user and group must have read/write access to the state file
2698 directory and to the config files in the config file directory."
2699
2700 if test -n "$enable_datacenter"; then
2701   AC_MSG_WARN([The --enable-datacenter compile time option is deprecated.  Please modify the init script to pass -F datacenter to the daemons instead.])
2702 fi
2703 if test -n "$enable_time_check"; then
2704   AC_MSG_WARN([The --enable-time-check compile time option is deprecated.  Please use the service cputime-stats configuration option instead.])
2705 fi
2706 if test -n "$enable_cpu_time"; then
2707   AC_MSG_WARN([The --enable-cpu-time compile time option is deprecated.  Please use the service cputime-warning NNN configuration option instead.])
2708 fi
2709
2710 if test "$enable_doc" != "no" -a "$frr_py_mod_sphinx" = "false"; then
2711   AC_MSG_WARN([sphinx is missing but required to build documentation])
2712 fi
2713 if test "$frr_py_mod_pytest" = "false"; then
2714   AC_MSG_WARN([pytest is missing, unit tests cannot be performed])
2715 fi