configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 m4_define([lxc_version_major], 1)
   5 m4_define([lxc_version_minor], 1)
   6 m4_define([lxc_version_micro], 0)
   7 m4_define([lxc_version_beta], [alpha1])
   8
   9 m4_define([lxc_version_base], [lxc_version_major.lxc_version_minor.lxc_version_micro])
  10 m4_define([lxc_version],
  11           [ifelse(lxc_version_beta, [], [lxc_version_base], [lxc_version_base.lxc_version_beta])])
  12
  13 AC_INIT([lxc], [lxc_version])
  14
  15 # We need pkg-config
  16 PKG_PROG_PKG_CONFIG
  17
  18 AC_SUBST(LXC_VERSION_BASE, lxc_version_base)
  19 AC_SUBST(LXC_VERSION_BETA, lxc_version_beta)
  20
  21 AC_SUBST([LXC_VERSION_MAJOR], [lxc_version_major])
  22 AC_SUBST([LXC_VERSION_MINOR], [lxc_version_minor])
  23 AC_SUBST([LXC_VERSION_MICRO], [lxc_version_micro])
  24 AC_SUBST([LXC_VERSION], [lxc_version])
  25
  26 AC_CONFIG_SRCDIR([configure.ac])
  27 AC_CONFIG_AUX_DIR([config])
  28 AC_CONFIG_HEADERS([src/config.h])
  29 AM_INIT_AUTOMAKE([-Wall -Werror -Wno-portability subdir-objects])
  30 AC_CANONICAL_HOST
  31 AM_PROG_CC_C_O
  32 AC_GNU_SOURCE
  33
  34 # Detect the distribution. This is used for the default configuration and
  35 # for some distro-specific build options.
  36 AC_MSG_CHECKING([host distribution])
  37 AC_ARG_WITH(distro, AS_HELP_STRING([--with-distro=DISTRO], [Specify the Linux distribution to target: One of redhat, oracle, centos, fedora, suse, gentoo, debian, arch, slackware, paldo, openmandriva or pardus.]))
  38 if type lsb_release >/dev/null 2>&1 && test "z$with_distro" = "z"; then
  39         with_distro=`lsb_release -is`
  40 fi
  41 if test "z$with_distro" = "z"; then
  42         AC_CHECK_FILE(/etc/redhat-release,with_distro="redhat")
  43         AC_CHECK_FILE(/etc/oracle-release,with_distro="oracle")
  44         AC_CHECK_FILE(/etc/centos-release,with_distro="centos")
  45         AC_CHECK_FILE(/etc/fedora-release,with_distro="fedora")
  46         AC_CHECK_FILE(/etc/SuSE-release,with_distro="suse")
  47         AC_CHECK_FILE(/etc/gentoo-release,with_distro="gentoo")
  48         AC_CHECK_FILE(/etc/debian_version,with_distro="debian")
  49         AC_CHECK_FILE(/etc/arch-release,with_distro="arch")
  50         AC_CHECK_FILE(/etc/slackware-version,with_distro="slackware")
  51         AC_CHECK_FILE(/etc/frugalware-release,with_distro="frugalware")
  52         AC_CHECK_FILE(/etc/mandrakelinux-release, with_distro="openmandriva")
  53         AC_CHECK_FILE(/etc/mandriva-release,with_distro="openmandriva")
  54         AC_CHECK_FILE(/etc/pardus-release,with_distro="pardus")
  55 fi
  56 with_distro=`echo ${with_distro} | tr '[[:upper:]]' '[[:lower:]]'`
  57
  58 if test "z$with_distro" = "z"; then
  59         with_distro="unknown"
  60 fi
  61 case $with_distro in
  62         ubuntu)
  63                 distroconf=default.conf.ubuntu
  64                 ;;
  65         redhat|centos|fedora|oracle|oracleserver)
  66                 distroconf=default.conf.libvirt
  67                 ;;
  68         *)
  69                 distroconf=default.conf.unknown
  70                 ;;
  71 esac
  72 AC_MSG_RESULT([$with_distro])
  73 AM_CONDITIONAL([HAVE_DEBIAN], [test x"$with_distro" = "xdebian" -o x"$with_distro" = "xubuntu"])
  74 AM_CONDITIONAL([DISTRO_UBUNTU], [test "x$with_distro" = "xubuntu"])
  75
  76 # Check for init system type
  77 AC_MSG_CHECKING([for init system type])
  78 AC_ARG_WITH([init-script],
  79             [AC_HELP_STRING([--with-init-script@<:@=TYPE@<:@,TYPE,...@:>@@:>@],
  80                             [Type(s) of init script to install: sysvinit, systemd, upstart,
  81                              distro @<:@default=distro@:>@])],[],[with_init_script=distro])
  82 case "$with_init_script" in
  83         distro)
  84                 case $with_distro in
  85                         fedora)
  86                                 init_script=systemd
  87                                 ;;
  88                         redhat|centos|oracle|oracleserver)
  89                                 init_script=sysvinit
  90                                 ;;
  91                         debian)
  92                                 init_script=upstart,systemd
  93                                 ;;
  94                         ubuntu)
  95                                 init_script=upstart
  96                                 ;;
  97                         *)
  98                                 echo -n "Linux distribution init system unknown."
  99                                 init_script=
 100                                 ;;
 101                 esac
 102                 ;;
 103         *)
 104                 init_script=$with_init_script
 105                 ;;
 106 esac
 107
 108 # Check valid init systems were given, run in subshell so we don't mess up IFS
 109 (IFS="," ; for init_sys in $init_script;
 110 do
 111         case "$init_sys" in
 112                 none|sysvinit|systemd|upstart)
 113                         ;;
 114                 *)
 115                         exit 1
 116                         ;;
 117         esac
 118 done) || AC_MSG_ERROR([Unknown init system type in $init_script])
 119
 120 AM_CONDITIONAL([INIT_SCRIPT_SYSV], [echo "$init_script" |grep -q "sysvinit"])
 121 AM_CONDITIONAL([INIT_SCRIPT_SYSTEMD], [echo "$init_script" |grep -q "systemd"])
 122 AM_CONDITIONAL([INIT_SCRIPT_UPSTART], [echo "$init_script" |grep -q "upstart"])
 123 AC_MSG_RESULT($init_script)
 124
 125 # Allow disabling rpath
 126 AC_ARG_ENABLE([rpath],
 127         [AC_HELP_STRING([--enable-rpath], [set rpath in executables [default=no]])],
 128         [], [enable_rpath=no])
 129 AM_CONDITIONAL([ENABLE_RPATH], [test "x$enable_rpath" = "xyes"])
 130
 131 # Documentation (manpages)
 132 AC_ARG_ENABLE([doc],
 133         [AC_HELP_STRING([--enable-doc], [make man pages [default=auto]])],
 134         [], [enable_doc=auto])
 135
 136 if test "x$enable_doc" = "xyes" -o "x$enable_doc" = "xauto"; then
 137         db2xman=""
 138         dbparsers="docbook2x-man db2x_docbook2man docbook2man docbook-to-man"
 139
 140         AC_MSG_CHECKING(for docbook2x-man)
 141         for name in ${dbparsers}; do
 142                 if "$name" --help >/dev/null 2>&1; then
 143                         db2xman="$name"
 144                         break;
 145                 fi
 146         done
 147
 148         if test -n "${db2xman}"; then
 149                 AC_MSG_RESULT([${db2xman}])
 150                 enable_doc="yes"
 151         else
 152                 AC_MSG_RESULT([no])
 153                 if test "x$enable_doc" = "xyes"; then
 154                         AC_MSG_ERROR([docbook2x-man is required, but could not be found])
 155                 fi
 156                 enable_doc="no"
 157         fi
 158
 159         AC_SUBST(db2xman)
 160 fi
 161 AM_CONDITIONAL([ENABLE_DOCBOOK], [test "x$db2xman" != "x"])
 162 AM_CONDITIONAL([USE_DOCBOOK2X], [test "x$db2xman" != "xdocbook2man"])
 163
 164 if test "x$db2xman" = "xdocbook2man"; then
 165         docdtd="\"-//Davenport//DTD DocBook V3.0//EN\""
 166 else
 167         docdtd="\"-//OASIS//DTD DocBook XML\" \"http://www.oasis-open.org/docbook/xml/4.5/docbookx.dtd\""
 168 fi
 169 AC_SUBST(docdtd)
 170
 171 # Documentation (API)
 172 AC_ARG_ENABLE([api-docs],
 173         [AC_HELP_STRING([--enable-api-docs],
 174         [make API documentation [default=auto]])],
 175         [], [enable_api_docs=auto])
 176
 177 if test "x$enable_api_docs" = "xyes" -o "x$enable_api_docs" = "xauto"; then
 178         AC_CHECK_PROGS([HAVE_DOXYGEN],[doxygen])
 179         AC_SUBST([HAVE_DOXYGEN])
 180
 181         if test "x$HAVE_DOXYGEN" != "x"; then
 182                 enable_api_docs="yes"
 183         else
 184                 if test "x$enable_api_docs" = "xyes"; then
 185                         AC_MSG_ERROR([doxygen is required, but could not be found])
 186                 fi
 187                 enable_api_docs="no"
 188         fi
 189 fi
 190
 191 AM_CONDITIONAL([ENABLE_API_DOCS], [test "x$HAVE_DOXYGEN" != "x"])
 192
 193 # Openvswitch
 194 AC_PATH_PROG([OVS_CTL_PATH],[ovs-vsctl])
 195 if test "x$OVS_CTL_PATH" != "x"; then
 196         enable_ovs="yes"
 197         AS_AC_EXPAND(OVS_CTL_PATH, "$OVS_CTL_PATH")
 198 else
 199         enable_ovs="no"
 200 fi
 201 AM_CONDITIONAL([HAVE_OVS], [test "x$enable_ovs" = "xyes"])
 202
 203 # Apparmor
 204 AC_ARG_ENABLE([apparmor],
 205         [AC_HELP_STRING([--enable-apparmor], [enable apparmor support [default=auto]])],
 206         [], [enable_apparmor=auto])
 207
 208 if test "$enable_apparmor" = "auto" ; then
 209         AC_CHECK_LIB([apparmor],[aa_change_profile],[enable_apparmor=yes], [enable_apparmor=no])
 210 fi
 211 AM_CONDITIONAL([ENABLE_APPARMOR], [test "x$enable_apparmor" = "xyes"])
 212
 213 AC_CHECK_LIB([gnutls], [gnutls_hash_fast], [enable_gnutls=yes], [enable_gnutls=no])
 214
 215 AM_COND_IF([ENABLE_APPARMOR],
 216         [AC_CHECK_HEADER([sys/apparmor.h],[],[AC_MSG_ERROR([You must install the AppArmor development package in order to compile lxc])])
 217         AC_CHECK_LIB([apparmor], [aa_change_profile],[],[AC_MSG_ERROR([You must install the AppArmor development package in order to compile lxc])])
 218         AC_SUBST([APPARMOR_LIBS], [-lapparmor])])
 219
 220 # SELinux
 221 AC_ARG_ENABLE([selinux],
 222         [AC_HELP_STRING([--enable-selinux], [enable SELinux support [default=auto]])],
 223         [], [enable_selinux=auto])
 224
 225 if test "x$enable_selinux" = xauto; then
 226         AC_CHECK_LIB([selinux],[setexeccon_raw],[enable_selinux=yes],[enable_selinux=no])
 227 fi
 228 AM_CONDITIONAL([ENABLE_SELINUX], [test "x$enable_selinux" = "xyes"])
 229 AM_COND_IF([ENABLE_SELINUX],
 230         [AC_CHECK_HEADER([selinux/selinux.h],[],[AC_MSG_ERROR([You must install the SELinux development package in order to compile lxc])])
 231         AC_CHECK_LIB([selinux], [setexeccon_raw],[true],[AC_MSG_ERROR([You must install the SELinux development package in order to compile lxc])])
 232         AC_SUBST([SELINUX_LIBS], [-lselinux])])
 233
 234 # Seccomp syscall filter
 235 AC_ARG_ENABLE([seccomp],
 236         [AC_HELP_STRING([--enable-seccomp], [enable seccomp support [default=auto]])],
 237         [], [enable_seccomp=auto])
 238
 239 if test "x$enable_seccomp" = "xauto" ; then
 240         AC_CHECK_LIB([seccomp],[seccomp_init],[enable_seccomp=yes],[enable_seccomp=no])
 241 fi
 242 AM_CONDITIONAL([ENABLE_SECCOMP], [test "x$enable_seccomp" = "xyes"])
 243
 244 AM_COND_IF([ENABLE_SECCOMP],
 245         [PKG_CHECK_MODULES([SECCOMP],[libseccomp],[],[
 246                 AC_CHECK_HEADER([seccomp.h],[],[AC_MSG_ERROR([You must install the seccomp development package in order to compile lxc])])
 247                 AC_CHECK_LIB([seccomp], [seccomp_init],[],[AC_MSG_ERROR([You must install the seccomp development package in order to compile lxc])])
 248                 AC_SUBST([SECCOMP_LIBS], [-lseccomp])
 249                 ])
 250         ])
 251
 252 # cgmanager
 253 AC_ARG_ENABLE([cgmanager],
 254         [AC_HELP_STRING([--enable-cgmanager], [enable cgmanager support [default=auto]])],
 255         [], [enable_cgmanager=auto])
 256
 257 if test "x$enable_cgmanager" = "xauto" ; then
 258         AC_CHECK_LIB([cgmanager],[cgmanager_create],[enable_cgmanager=yes],[enable_cgmanager=no],[-lnih -lnih-dbus -ldbus-1])
 259 fi
 260 AM_CONDITIONAL([ENABLE_CGMANAGER], [test "x$enable_cgmanager" = "xyes"])
 261
 262 AM_COND_IF([ENABLE_CGMANAGER],
 263         [PKG_CHECK_MODULES([CGMANAGER], [libcgmanager])
 264         PKG_CHECK_MODULES([NIH], [libnih >= 1.0.2])
 265         PKG_CHECK_MODULES([NIH_DBUS], [libnih-dbus >= 1.0.0])
 266         PKG_CHECK_MODULES([DBUS], [dbus-1 >= 1.2.16])
 267         ])
 268
 269 AC_MSG_CHECKING(for get_pid_cgroup_abs_sync)
 270 save_LIBS=$LIBS
 271 AC_SEARCH_LIBS([cgmanager_get_pid_cgroup_abs_sync], [cgmanager], [have_abs_cgroups=yes], [have_abs_cgroups=no], [-lnih -lnih-dbus -ldbus-1])
 272 LIBS=$save_LIBS
 273 if test "x$have_abs_cgroups" = "xyes"; then
 274         AC_DEFINE([HAVE_CGMANAGER_GET_PID_CGROUP_ABS_SYNC], 1, [Have cgmanager_get_pid_cgroup_abs_sync])
 275         AC_MSG_RESULT([yes])
 276 else
 277         AC_MSG_RESULT([no])
 278 fi
 279
 280 # Check for static libcap, make sure the function checked for differs from the
 281 # the one checked below so the cache doesn't give a wrong answer
 282 OLD_CFLAGS="$CFLAGS"
 283 CFLAGS="$CFLAGS -static"
 284 AC_CHECK_LIB([cap],[cap_init],[have_static_libcap=yes],[have_static_libcap=no])
 285 AM_CONDITIONAL([HAVE_STATIC_LIBCAP], [test "x$have_static_libcap" = "xyes"])
 286 if test "x$have_static_libcap" = "xyes"; then
 287         AC_DEFINE([HAVE_STATIC_LIBCAP], 1, [Have static libcap])
 288 fi
 289 CFLAGS="$OLD_CFLAGS"
 290
 291
 292 # Linux capabilities
 293 AC_ARG_ENABLE([capabilities],
 294         [AC_HELP_STRING([--enable-capabilities], [enable kernel capabilities support [default=auto]])],
 295         [], [enable_capabilities=auto])
 296
 297 if test "x$enable_capabilities" = "xauto"; then
 298         AC_CHECK_LIB([cap],[cap_set_proc],[enable_capabilities=yes],[enable_capabilities=no])
 299 fi
 300 AM_CONDITIONAL([ENABLE_CAP], [test "x$enable_capabilities" = "xyes"])
 301
 302 AM_COND_IF([ENABLE_CAP],
 303         [AC_CHECK_LIB(cap,cap_set_proc,[true],[AC_MSG_ERROR([You are missing libcap support.])])
 304         AC_SUBST([CAP_LIBS], [-lcap])])
 305
 306 # HAVE_SCMP_FILTER_CTX=1 will tell us we have libseccomp api >= 1.0.0
 307 OLD_CFLAGS="$CFLAGS"
 308 CFLAGS="$CFLAGS $SECCOMP_CFLAGS"
 309 AC_CHECK_TYPES([scmp_filter_ctx], [], [], [[#include <seccomp.h>]])
 310 AC_CHECK_DECLS([seccomp_syscall_resolve_name_arch], [], [], [[#include <seccomp.h>]])
 311 CFLAGS="$OLD_CFLAGS"
 312
 313 # Configuration examples
 314 AC_ARG_ENABLE([examples],
 315         [AC_HELP_STRING([--enable-examples], [install examples [default=yes]])],
 316         [], [enable_examples=yes])
 317 AM_CONDITIONAL([ENABLE_EXAMPLES], [test "x$enable_examples" = "xyes"])
 318
 319 # Python3 module and scripts
 320 AC_ARG_ENABLE([python],
 321         [AC_HELP_STRING([--enable-python], [enable python binding [default=auto]])],
 322         [], [enable_python=auto])
 323
 324 if test "x$enable_python" = "xauto"; then
 325         PKG_CHECK_MODULES([PYTHONDEV], [python3 >= 3.2],[enable_python=yes],[enable_python=no])
 326         if test "$CC" = "clang"; then
 327                 enable_python=no
 328         fi
 329 fi
 330
 331 if test "x$enable_python" = "xyes" && test "$CC" = "clang"; then
 332         AC_MSG_ERROR([Python3 is incompatible with the clang compiler])
 333 fi
 334
 335 AM_CONDITIONAL([ENABLE_PYTHON], [test "x$enable_python" = "xyes"])
 336
 337 AM_COND_IF([ENABLE_PYTHON],
 338         [AM_PATH_PYTHON([3.2], [], [AC_MSG_ERROR([You must install python3])])
 339         PKG_CHECK_MODULES([PYTHONDEV], [python3 >= 3.2],[],[AC_MSG_ERROR([You must install python3-dev])])
 340         AC_DEFINE_UNQUOTED([ENABLE_PYTHON], 1, [Python3 is available])])
 341
 342 # Enable dumping stack traces
 343 AC_ARG_ENABLE([mutex-debugging],
 344         [AC_HELP_STRING([--enable-mutex-debugging], [Makes mutexes to report error and provide stack trace [default=no]])],
 345         [], [enable_mutex_debugging=no])
 346 AM_CONDITIONAL([MUTEX_DEBUGGING], [test "x$enable_mutex_debugging" = "xyes"])
 347
 348 AM_COND_IF([MUTEX_DEBUGGING],
 349         AC_DEFINE_UNQUOTED([MUTEX_DEBUGGING], 1, [Enabling mutex debugging]))
 350
 351 # Not in older autoconf versions
 352 # AS_VAR_COPY(DEST, SOURCE)
 353 # -------------------------
 354 # Set the polymorphic shell variable DEST to the contents of the polymorphic
 355 # shell variable SOURCE.
 356 m4_ifdef([AS_VAR_COPY], [],
 357 [AC_DEFUN([AS_VAR_COPY],
 358     [AS_LITERAL_IF([$1[]$2], [$1=$$2], [eval $1=\$$2])])
 359 ])
 360
 361 dnl PKG_CHECK_VAR was introduced with pkg-config 0.28
 362 m4_ifdef([PKG_CHECK_VAR], [],
 363 [AC_DEFUN([PKG_CHECK_VAR],
 364     [AC_REQUIRE([PKG_PROG_PKG_CONFIG])dnl
 365      AC_ARG_VAR([$1], [value of $3 for $2, overriding pkg-config])dnl
 366      _PKG_CONFIG([$1], [variable="][$3]["], [$2])
 367      AS_VAR_COPY([$1], [pkg_cv_][$1])
 368      AS_VAR_IF([$1], [""], [$5], [$4])dnl
 369     ])# PKG_CHECK_VAR
 370 ])
 371
 372 # Lua module and scripts
 373 AC_ARG_ENABLE([lua],
 374         [AC_HELP_STRING([--enable-lua], [enable lua binding [default=auto]])],
 375         [], [enable_lua=auto])
 376
 377 AC_ARG_WITH([lua-pc],
 378         [AS_HELP_STRING(
 379                 [--with-lua-pc=PKG],
 380                 [Specify pkg-config package name for lua]
 381         )], [], [with_lua_pc=no])
 382
 383 if test "x$enable_lua" = "xyes" -a "x$with_lua_pc" != "xno"; then
 384         # exit with error if not found
 385         PKG_CHECK_MODULES([LUA], [$with_lua_pc], [LUAPKGCONFIG=$with_lua_pc])
 386 fi
 387
 388 if test "x$enable_lua" = "xauto" -a "x$with_lua_pc" != "xno"; then
 389         PKG_CHECK_MODULES([LUA], [$with_lua_pc],
 390                 [LUAPKGCONFIG=$with_lua_pc
 391                 enable_lua=yes],
 392                 [enable_lua=no])
 393 fi
 394
 395 if test "x$enable_lua" != "xno"; then
 396         PKG_CHECK_MODULES([LUA], [lua], [LUAPKGCONFIG=lua],
 397                 [PKG_CHECK_MODULES([LUA], [lua5.2], [LUAPKGCONFIG=lua5.2],
 398                         [PKG_CHECK_MODULES([LUA], [lua5.1], [LUAPKGCONFIG=lua5.1],
 399                                 [AS_IF([test "x$enable_lua" = "xyes"],
 400                                         [AC_MSG_ERROR([Lua not found. Please use --with-lua-pc=PKG])],
 401                                         [enable_lua=no])]
 402                         )]
 403                 )])
 404         AS_IF([test "x$LUAPKGCONFIG" != "x"], [enable_lua=yes])
 405 fi
 406
 407 AM_CONDITIONAL([ENABLE_LUA],
 408         [test "x$enable_lua" = "xyes"])
 409
 410 AM_COND_IF([ENABLE_LUA],
 411         [AC_MSG_CHECKING([Lua version])
 412         PKG_CHECK_VAR([LUA_VERSION], [$LUAPKGCONFIG], [V],,
 413                 [PKG_CHECK_VAR([LUA_VERSION], [$LUAPKGCONFIG], [major_version])])
 414         AC_MSG_RESULT([$LUA_VERSION])
 415         AC_SUBST([LUA_LIBDIR], [$libdir/lua/$LUA_VERSION])
 416         AC_SUBST([LUA_SHAREDIR], [$datadir/lua/$LUA_VERSION])
 417         ])
 418
 419 # Optional bash integration
 420 AC_ARG_ENABLE([bash],
 421         [AC_HELP_STRING([--enable-bash], [build bash integration [default=yes]])],
 422         [], [enable_bash=yes])
 423 AM_CONDITIONAL([ENABLE_BASH], [test "x$enable_bash" = "xyes"])
 424
 425 # Optional test binaries
 426 AC_ARG_ENABLE([tests],
 427         [AC_HELP_STRING([--enable-tests], [build test/example binaries [default=no]])],
 428         [], [enable_tests=no])
 429 AM_CONDITIONAL([ENABLE_TESTS], [test "x$enable_tests" = "xyes"])
 430
 431 # Allow overriding the default runtime dir (/run)
 432 AC_ARG_WITH([runtime-path],
 433         [AC_HELP_STRING(
 434                 [--with-runtime-path=dir],
 435                 [runtime directory (default: /run)]
 436         )], [], [with_runtime_path=['/run']])
 437
 438 # LXC container path, where the containers are actually stored
 439 # This is overridden by an entry in the file called LXCCONF
 440 # (i.e. /etc/lxc/lxc.conf)
 441 AC_ARG_WITH([config-path],
 442         [AC_HELP_STRING(
 443                 [--with-config-path=dir],
 444                 [lxc configuration repository path]
 445         )], [], [with_config_path=['${localstatedir}/lib/lxc']])
 446
 447 # The path of the global lxc configuration file.
 448 AC_ARG_WITH([global-conf],
 449         [AC_HELP_STRING(
 450                 [--with-global-conf=dir],
 451                 [global lxc configuration file]
 452         )], [], [with_global_conf=['${sysconfdir}/lxc/lxc.conf']])
 453
 454 # The path of the userns network configuration file
 455 AC_ARG_WITH([usernic-conf],
 456         [AC_HELP_STRING(
 457                 [--with-usernic-conf],
 458                 [user network interface configuration file]
 459         )], [], [with_usernic_conf=['${sysconfdir}/lxc/lxc-usernet']])
 460
 461 # The path of the runtime usernic database
 462 AC_ARG_WITH([usernic-db],
 463         [AC_HELP_STRING(
 464                 [--with-usernic-db],
 465                 [lxc user nic database]
 466         )], [], [with_usernic_db=['${with_runtime_path}/lxc/nics']])
 467
 468 # Rootfs path, where the container mount structure is assembled
 469 AC_ARG_WITH([rootfs-path],
 470         [AC_HELP_STRING(
 471                 [--with-rootfs-path=dir],
 472                 [lxc rootfs mount point]
 473         )], [], [with_rootfs_path=['${libdir}/lxc/rootfs']])
 474
 475 # cgroup pattern specification
 476 AC_ARG_WITH([cgroup-pattern],
 477         [AC_HELP_STRING(
 478                 [--with-cgroup-pattern=pattern],
 479                 [pattern for container cgroups]
 480         )], [], [with_cgroup_pattern=['/lxc/%n']])
 481
 482 # Container log path.  By default, use $lxcpath.
 483 AC_MSG_CHECKING([Whether to place logfiles in container config path])
 484 AC_ARG_ENABLE([configpath-log],
 485         [AC_HELP_STRING([--enable-configpath-log], [use logfiles in config path [default=no]])],
 486         [], [enable_configpath_log=no])
 487 AC_MSG_RESULT([$enable_configpath_log])
 488 AM_CONDITIONAL([USE_CONFIGPATH_LOGS], [test "$enable_configpath_log" = "yes"])
 489
 490 if test "$enable_configpath_log" = "yes"; then
 491         default_log_path="${with_config_path}"
 492 else
 493         default_log_path="${localstatedir}/log/lxc"
 494 fi
 495
 496 AC_ARG_WITH([log-path],
 497         [AC_HELP_STRING(
 498                 [--with-log-path=dir],
 499                 [per container log path]
 500         )], [], [with_log_path=['${default_log_path}']])
 501
 502 # Expand some useful variables
 503 AS_AC_EXPAND(PREFIX, "$prefix")
 504 AS_AC_EXPAND(LIBDIR, "$libdir")
 505 AS_AC_EXPAND(BINDIR, "$bindir")
 506 AS_AC_EXPAND(SBINDIR, "$sbindir")
 507 AS_AC_EXPAND(LIBEXECDIR, "$libexecdir")
 508 AS_AC_EXPAND(INCLUDEDIR, "$includedir")
 509 AS_AC_EXPAND(SYSCONFDIR, "$sysconfdir")
 510 AS_AC_EXPAND(LXC_DEFAULT_CONFIG, "$sysconfdir/lxc/default.conf")
 511 AS_AC_EXPAND(DATADIR, "$datadir")
 512 AS_AC_EXPAND(LOCALSTATEDIR, "$localstatedir")
 513 AS_AC_EXPAND(DOCDIR, "$docdir")
 514 AS_AC_EXPAND(LXC_DISTRO_CONF, "$distroconf")
 515 AS_AC_EXPAND(LXC_GENERATE_DATE, "$(date)")
 516 AS_AC_EXPAND(LXCPATH, "$with_config_path")
 517 AS_AC_EXPAND(LXC_GLOBAL_CONF, "$with_global_conf")
 518 AS_AC_EXPAND(LXC_USERNIC_CONF, "$with_usernic_conf")
 519 AS_AC_EXPAND(LXC_USERNIC_DB, "$with_usernic_db")
 520 AS_AC_EXPAND(LXCROOTFSMOUNT, "$with_rootfs_path")
 521 AS_AC_EXPAND(LXCTEMPLATEDIR, "$datadir/lxc/templates")
 522 AS_AC_EXPAND(LXCTEMPLATECONFIG, "$datadir/lxc/config")
 523 AS_AC_EXPAND(LXCHOOKDIR, "$datadir/lxc/hooks")
 524 AS_AC_EXPAND(LXCINITDIR, "$libexecdir")
 525 AS_AC_EXPAND(LOGPATH, "$with_log_path")
 526 AS_AC_EXPAND(RUNTIME_PATH, "$with_runtime_path")
 527 AC_SUBST(DEFAULT_CGROUP_PATTERN, ["$with_cgroup_pattern"])
 528
 529 # Check for some standard kernel headers
 530 AC_CHECK_HEADERS([linux/unistd.h linux/netlink.h linux/genetlink.h],
 531                                 [],
 532                                 AC_MSG_ERROR([Please install the Linux kernel headers.]),
 533                                 [#include <sys/socket.h>])
 534
 535 # Check for alternate C libraries
 536 AC_MSG_CHECKING(for bionic libc)
 537 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 538         [[#ifndef __ANDROID__
 539 error: Not bionic!
 540 #endif]])],
 541         [is_bionic=yes],
 542         [is_bionic=no])
 543 if test "x$is_bionic" = "xyes"; then
 544         AC_DEFINE([IS_BIONIC], 1, [bionic libc])
 545         AC_MSG_RESULT([yes])
 546 else
 547         AC_MSG_RESULT([no])
 548 fi
 549 AM_CONDITIONAL([IS_BIONIC], [test "x$is_bionic" = "xyes"])
 550
 551 # Some systems lack PR_CAPBSET_DROP definition => HAVE_DECL_PR_CAPBSET_DROP
 552 AC_CHECK_DECLS([PR_CAPBSET_DROP], [], [], [#include <sys/prctl.h>])
 553
 554 # Check for some headers
 555 AC_CHECK_HEADERS([sys/signalfd.h pty.h ifaddrs.h sys/capability.h sys/personality.h utmpx.h sys/timerfd.h])
 556
 557 # Check for some syscalls functions
 558 AC_CHECK_FUNCS([setns pivot_root sethostname unshare rand_r confstr faccessat])
 559
 560 # Check for some functions
 561 AC_CHECK_LIB(pthread, main)
 562 AC_CHECK_FUNCS(pthread_atfork)
 563 AC_CHECK_LIB(util, openpty)
 564 AC_CHECK_FUNCS([openpty hasmntopt setmntent endmntent utmpxname])
 565 AC_CHECK_FUNCS([getline],
 566         AM_CONDITIONAL(HAVE_GETLINE, true)
 567         AC_DEFINE(HAVE_GETLINE,1,[Have getline]),
 568         AM_CONDITIONAL(HAVE_GETLINE, false))
 569 AC_CHECK_FUNCS([fgetln],
 570         AM_CONDITIONAL(HAVE_FGETLN, true)
 571         AC_DEFINE(HAVE_FGETLN,1,[Have fgetln]),
 572         AM_CONDITIONAL(HAVE_FGETLN, false))
 573
 574 # Check for some libraries
 575 AC_SEARCH_LIBS(sem_open, [rt pthread])
 576 AC_SEARCH_LIBS(clock_gettime, [rt])
 577
 578 # Check for some standard binaries
 579 AC_PROG_GCC_TRADITIONAL
 580 AC_PROG_SED
 581
 582 # See if we support thread-local storage.
 583 LXC_CHECK_TLS
 584
 585 if test "x$GCC" = "xyes"; then
 586         CFLAGS="$CFLAGS -Wall -Werror"
 587 fi
 588
 589 # Files requiring some variable expansion
 590 AC_CONFIG_FILES([
 591         Makefile
 592         lxc.pc
 593         lxc.spec
 594
 595         config/Makefile
 596         config/apparmor/Makefile
 597         config/bash/Makefile
 598         config/bash/lxc
 599         config/init/Makefile
 600         config/init/sysvinit/Makefile
 601         config/init/sysvinit/lxc
 602         config/init/systemd/Makefile
 603         config/init/systemd/lxc.service
 604         config/init/upstart/Makefile
 605         config/etc/Makefile
 606         config/templates/Makefile
 607         config/templates/archlinux.common.conf
 608         config/templates/archlinux.userns.conf
 609         config/templates/centos.common.conf
 610         config/templates/centos.userns.conf
 611         config/templates/common.conf
 612         config/templates/debian.common.conf
 613         config/templates/debian.userns.conf
 614         config/templates/fedora.common.conf
 615         config/templates/fedora.userns.conf
 616         config/templates/gentoo.common.conf
 617         config/templates/gentoo.moresecure.conf
 618         config/templates/gentoo.userns.conf
 619         config/templates/opensuse.common.conf
 620         config/templates/opensuse.userns.conf
 621         config/templates/oracle.common.conf
 622         config/templates/oracle.userns.conf
 623         config/templates/plamo.common.conf
 624         config/templates/plamo.userns.conf
 625         config/templates/ubuntu-cloud.common.conf
 626         config/templates/ubuntu-cloud.lucid.conf
 627         config/templates/ubuntu-cloud.userns.conf
 628         config/templates/ubuntu.common.conf
 629         config/templates/ubuntu.lucid.conf
 630         config/templates/ubuntu.userns.conf
 631         config/templates/userns.conf
 632         config/yum/Makefile
 633
 634         doc/Makefile
 635         doc/api/Makefile
 636         doc/legacy/lxc-ls.sgml
 637         doc/lxc-attach.sgml
 638         doc/lxc-autostart.sgml
 639         doc/lxc-cgroup.sgml
 640         doc/lxc-checkconfig.sgml
 641         doc/lxc-clone.sgml
 642         doc/lxc-config.sgml
 643         doc/lxc-console.sgml
 644         doc/lxc-create.sgml
 645         doc/lxc-destroy.sgml
 646         doc/lxc-device.sgml
 647         doc/lxc-execute.sgml
 648         doc/lxc-freeze.sgml
 649         doc/lxc-info.sgml
 650         doc/lxc-ls.sgml
 651         doc/lxc-monitor.sgml
 652         doc/lxc-snapshot.sgml
 653         doc/lxc-start-ephemeral.sgml
 654         doc/lxc-start.sgml
 655         doc/lxc-stop.sgml
 656         doc/lxc-top.sgml
 657         doc/lxc-unfreeze.sgml
 658         doc/lxc-unshare.sgml
 659         doc/lxc-user-nic.sgml
 660         doc/lxc-usernsexec.sgml
 661         doc/lxc-wait.sgml
 662
 663         doc/lxc.conf.sgml
 664         doc/lxc.container.conf.sgml
 665         doc/lxc.system.conf.sgml
 666         doc/lxc-usernet.sgml
 667         doc/lxc.sgml
 668         doc/common_options.sgml
 669         doc/see_also.sgml
 670
 671         doc/rootfs/Makefile
 672
 673         doc/examples/Makefile
 674         doc/examples/lxc-macvlan.conf
 675         doc/examples/lxc-vlan.conf
 676         doc/examples/lxc-no-netns.conf
 677         doc/examples/lxc-empty-netns.conf
 678         doc/examples/lxc-phys.conf
 679         doc/examples/lxc-veth.conf
 680         doc/examples/lxc-complex.conf
 681
 682         doc/ja/Makefile
 683         doc/ja/legacy/lxc-ls.sgml
 684         doc/ja/lxc-attach.sgml
 685         doc/ja/lxc-autostart.sgml
 686         doc/ja/lxc-cgroup.sgml
 687         doc/ja/lxc-checkconfig.sgml
 688         doc/ja/lxc-clone.sgml
 689         doc/ja/lxc-config.sgml
 690         doc/ja/lxc-console.sgml
 691         doc/ja/lxc-create.sgml
 692         doc/ja/lxc-destroy.sgml
 693         doc/ja/lxc-device.sgml
 694         doc/ja/lxc-execute.sgml
 695         doc/ja/lxc-freeze.sgml
 696         doc/ja/lxc-info.sgml
 697         doc/ja/lxc-ls.sgml
 698         doc/ja/lxc-monitor.sgml
 699         doc/ja/lxc-snapshot.sgml
 700         doc/ja/lxc-start-ephemeral.sgml
 701         doc/ja/lxc-start.sgml
 702         doc/ja/lxc-stop.sgml
 703         doc/ja/lxc-top.sgml
 704         doc/ja/lxc-unfreeze.sgml
 705         doc/ja/lxc-unshare.sgml
 706         doc/ja/lxc-user-nic.sgml
 707         doc/ja/lxc-usernsexec.sgml
 708         doc/ja/lxc-wait.sgml
 709
 710         doc/ja/lxc.conf.sgml
 711         doc/ja/lxc.container.conf.sgml
 712         doc/ja/lxc.system.conf.sgml
 713         doc/ja/lxc-usernet.sgml
 714         doc/ja/lxc.sgml
 715         doc/ja/common_options.sgml
 716         doc/ja/see_also.sgml
 717
 718         hooks/Makefile
 719
 720         templates/Makefile
 721         templates/lxc-alpine
 722         templates/lxc-altlinux
 723         templates/lxc-archlinux
 724         templates/lxc-busybox
 725         templates/lxc-centos
 726         templates/lxc-cirros
 727         templates/lxc-debian
 728         templates/lxc-download
 729         templates/lxc-fedora
 730         templates/lxc-gentoo
 731         templates/lxc-openmandriva
 732         templates/lxc-opensuse
 733         templates/lxc-oracle
 734         templates/lxc-plamo
 735         templates/lxc-sshd
 736         templates/lxc-ubuntu
 737         templates/lxc-ubuntu-cloud
 738
 739         src/Makefile
 740         src/lxc/Makefile
 741         src/lxc/lxc-checkconfig
 742         src/lxc/lxc-ls
 743         src/lxc/lxc-start-ephemeral
 744         src/lxc/legacy/lxc-ls
 745         src/lxc/lxc.functions
 746         src/lxc/version.h
 747         src/python-lxc/Makefile
 748
 749         src/lua-lxc/Makefile
 750
 751         src/tests/Makefile
 752         src/tests/lxc-test-usernic
 753 ])
 754 AC_CONFIG_COMMANDS([default],[[]],[[]])
 755 AC_OUTPUT
 756
 757 # Configuration overview
 758 cat << EOF
 759
 760 ----------------------------
 761 Environment:
 762  - compiler: $CC
 763  - distribution: $with_distro
 764  - init script type(s): $init_script
 765  - rpath: $enable_rpath
 766  - GnuTLS: $enable_gnutls
 767  - Bash integration: $enable_bash
 768  - Openvswitch: $enable_ovs
 769
 770 Security features:
 771  - Apparmor: $enable_apparmor
 772  - Linux capabilities: $enable_capabilities
 773  - seccomp: $enable_seccomp
 774  - SELinux: $enable_selinux
 775  - cgmanager: $enable_cgmanager
 776
 777 Bindings:
 778  - lua: $enable_lua
 779  - python3: $enable_python
 780
 781 Documentation:
 782  - examples: $enable_examples
 783  - API documentation: $enable_api_docs
 784  - user documentation: $enable_doc
 785
 786 Debugging:
 787  - tests: $enable_tests
 788  - mutex debugging: $enable_mutex_debugging
 789
 790 Paths:
 791  - Logs in configpath: $enable_configpath_log
 792 EOF
 793
 794 if test "x$ac_cv_func_pthread_atfork" = "xno" ; then
 795 cat << EOF
 796
 797 WARNING: Threading not supported on your platform
 798
 799         You are compiling LXC for bionic target which lacks certain threading related functionality used by LXC API (like pthread_atfork).
 800         Please note that, because of the missing functionality, multithreaded usage of LXC API cause some problems.
 801 EOF
 802 fi