configure.ac

   1 ##
   2 ## Configure template file for FRRouting.
   3 ## autoconf will generate configure script.
   4 ##
   5 ##  Copyright (c) 1996, 97, 98, 99, 2000 Kunihiro Ishiguro <kunihiro@zebra.org>
   6 ##  Portions Copyright (c) 2003 Paul Jakma <paul@dishone.st>
   7 ##
   8 AC_PREREQ(2.60)
   9
  10 AC_INIT(frr, 3.1-dev, [https://github.com/frrouting/frr/issues])
  11 PACKAGE_URL="https://frrouting.org/"
  12 AC_SUBST(PACKAGE_URL)
  13 PACKAGE_FULLNAME="FRRouting"
  14 AC_SUBST(PACKAGE_FULLNAME)
  15
  16 CONFIG_ARGS="$ac_configure_args"
  17 AC_SUBST(CONFIG_ARGS)
  18
  19 AC_CONFIG_SRCDIR(lib/zebra.h)
  20 AC_CONFIG_MACRO_DIR([m4])
  21
  22 dnl -----------------------------------
  23 dnl Get hostname and other information.
  24 dnl -----------------------------------
  25 AC_CANONICAL_BUILD()
  26 AC_CANONICAL_HOST()
  27
  28 AS_IF([test "$host" != "$build"], [
  29   if test "$srcdir" = "."; then
  30     AC_MSG_ERROR([cross-compilation is only possible with builddir separate from srcdir.  create a separate directory and run as .../path-to-frr/configure.])
  31   fi
  32   test -d hosttools || mkdir hosttools
  33   abssrc="`cd \"${srcdir}\"; pwd`"
  34
  35   AC_MSG_NOTICE([...])
  36   AC_MSG_NOTICE([... cross-compilation: creating hosttools directory and self-configuring for build platform tools])
  37   AC_MSG_NOTICE([... use HOST_CPPFLAGS / HOST_CFLAGS / HOST_LDFLAGS if neccessary])
  38   AC_MSG_NOTICE([...])
  39
  40   ( CPPFLAGS="$HOST_CPPFLAGS"; \
  41     CFLAGS="$HOST_CFLAGS"; \
  42     LDFLAGS="$HOST_LDFLAGS"; \
  43     cd hosttools; "${abssrc}/configure" "--host=$build" "--build=$build"; )
  44
  45   AC_MSG_NOTICE([...])
  46   AC_MSG_NOTICE([... cross-compilation: finished self-configuring for build platform tools])
  47   AC_MSG_NOTICE([...])
  48
  49   build_clippy="false"
  50   HOSTTOOLS="hosttools/"
  51 ], [
  52   build_clippy="true"
  53   HOSTTOOLS=""
  54 ])
  55 AC_SUBST(HOSTTOOLS)
  56 AM_CONDITIONAL([BUILD_CLIPPY], [$build_clippy])
  57
  58 # Disable portability warnings -- our automake code (in particular
  59 # common.am) uses some constructs specific to gmake.
  60 AM_INIT_AUTOMAKE([1.12 -Wno-portability])
  61 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
  62 AM_SILENT_RULES([yes])
  63 AC_CONFIG_HEADERS(config.h)
  64
  65 AC_PATH_PROG(PERL, perl)
  66 PKG_PROG_PKG_CONFIG
  67
  68 dnl default is to match previous behavior
  69 exampledir=${sysconfdir}
  70 AC_ARG_ENABLE([exampledir],
  71           AS_HELP_STRING([--enable-exampledir],
  72                          [specify alternate directory for examples]),
  73                          exampledir="$enableval",)
  74 dnl XXX add --exampledir to autoconf standard directory list somehow
  75 AC_SUBST(exampledir)
  76
  77 dnl default is to match previous behavior
  78 pkgsrcrcdir=""
  79 AC_ARG_ENABLE([pkgsrcrcdir],
  80           AS_HELP_STRING([--enable-pkgsrcrcdir],
  81                          [specify directory for rc.d scripts]),
  82                          pkgsrcrcdir="$enableval",)
  83 dnl XXX add --pkgsrcrcdir to autoconf standard directory list somehow
  84 AC_SUBST(pkgsrcrcdir)
  85 AM_CONDITIONAL([PKGSRC], [test "x$pkgsrcrcdir" != "x"])
  86
  87 AC_ARG_WITH([moduledir], [AS_HELP_STRING([--with-moduledir=DIR], [module directory (${libdir}/frr/modules)])], [
  88         moduledir="$withval"
  89 ], [
  90         moduledir="\${libdir}/frr/modules"
  91 ])
  92 AC_SUBST([moduledir], [$moduledir])
  93
  94 AC_ARG_ENABLE(tcmalloc,
  95         AS_HELP_STRING([--enable-tcmalloc], [Turn on tcmalloc]),
  96 [case "${enableval}" in
  97   yes) tcmalloc_enabled=true
  98 LIBS="$LIBS -ltcmalloc_minimal"
  99  ;;
 100   no)  tcmalloc_enabled=false ;;
 101   *) AC_MSG_ERROR(bad value ${enableval} for --enable-tcmalloc) ;;
 102 esac],[tcmalloc_enabled=false])
 103
 104
 105 dnl Thanks autoconf, but we don't want a default -g -O2.  We have our own
 106 dnl flag determination logic.
 107 CFLAGS="${CFLAGS:-}"
 108
 109 dnl --------------------
 110 dnl Check CC and friends
 111 dnl --------------------
 112 dnl note orig_cflags is also used further down
 113 orig_cflags="$CFLAGS"
 114 AC_LANG([C])
 115 AC_PROG_CC
 116 AC_PROG_CPP
 117 AM_PROG_CC_C_O
 118 dnl remove autoconf default "-g -O2"
 119 CFLAGS="$orig_cflags"
 120 AC_PROG_CC_C99
 121 dnl NB: see C11 below
 122
 123 AC_PROG_EGREP
 124 PKG_PROG_PKG_CONFIG
 125
 126 dnl autoconf 2.59 appears not to support AC_PROG_SED
 127 dnl AC_PROG_SED
 128 AC_CHECK_PROG([SED],[sed],[sed],[/bin/false])
 129
 130 dnl try and enable CFLAGS that are useful for FRR
 131 dnl - specifically, options to control warnings
 132
 133 AC_USE_SYSTEM_EXTENSIONS
 134 AC_DEFUN([AC_C_FLAG], [{
 135         AC_LANG_PUSH(C)
 136         ac_c_flag_save="$CFLAGS"
 137         CFLAGS="$CFLAGS $1"
 138         AC_MSG_CHECKING([[whether $CC supports $1]])
 139         AC_COMPILE_IFELSE(
 140                 [AC_LANG_PROGRAM([[]])],
 141                 [
 142                         AC_MSG_RESULT([yes])
 143                         m4_if([$3], [], [], [
 144                                 CFLAGS="$ac_c_flag_save"
 145                                 $3
 146                         ])
 147                 ], [
 148                         CFLAGS="$ac_c_flag_save"
 149                         AC_MSG_RESULT([no])
 150                         $2
 151                 ])
 152         AC_LANG_POP(C)
 153         }])
 154
 155 AC_DEFUN([AC_LINK_IFELSE_FLAGS], [{
 156         AC_LANG_PUSH(C)
 157         ac_cflags_save="$CFLAGS"
 158         ac_libs_save="$LIBS"
 159         CFLAGS="$CFLAGS $1"
 160         LIBS="$LIBS $2"
 161         AC_LINK_IFELSE(
 162                 [$3],
 163                 [
 164                         AC_MSG_RESULT([yes])
 165                         CFLAGS="$ac_cflags_save"
 166                         LIBS="$ac_libs_save"
 167                         $5
 168                 ], [
 169                         AC_MSG_RESULT([no])
 170                         CFLAGS="$ac_cflags_save"
 171                         LIBS="$ac_libs_save"
 172                         $4
 173                 ])
 174         AC_LANG_POP(C)
 175         }])
 176
 177 dnl ICC won't bail on unknown options without -diag-error 10006
 178 dnl need to do this first so we get useful results for the other options
 179 AC_C_FLAG([-diag-error 10006])
 180
 181 dnl AC_PROG_CC_C99 may change CC to include -std=gnu99 or something
 182 ac_cc="$CC"
 183 CC="${CC% -std=gnu99}"
 184 CC="${CC% -std=c99}"
 185
 186 AC_C_FLAG([-std=gnu11], [CC="$ac_cc"], [CC="$CC -std=gnu11"])
 187
 188 dnl if the user specified any CFLAGS, we don't add "-g -Os/-O2" here
 189 if test "z$orig_cflags" = "z"; then
 190   AC_C_FLAG([-g])
 191   AC_C_FLAG([-Os], [
 192     AC_C_FLAG([-O2])
 193   ])
 194 fi
 195
 196 dnl always want these CFLAGS
 197 AC_C_FLAG([-fno-omit-frame-pointer])
 198 AC_C_FLAG([-funwind-tables])
 199 AC_C_FLAG([-Wall])
 200 AC_C_FLAG([-Wextra])
 201 AC_C_FLAG([-Wmissing-prototypes])
 202 AC_C_FLAG([-Wmissing-declarations])
 203 AC_C_FLAG([-Wpointer-arith])
 204 AC_C_FLAG([-Wbad-function-cast])
 205 AC_C_FLAG([-Wwrite-strings])
 206 if test x"${enable_gcc_ultra_verbose}" = x"yes" ; then
 207   AC_C_FLAG([-Wcast-qual])
 208   AC_C_FLAG([-Wstrict-prototypes])
 209   AC_C_FLAG([-Wmissing-noreturn])
 210   AC_C_FLAG([-Wmissing-format-attribute])
 211   AC_C_FLAG([-Wunreachable-code])
 212   AC_C_FLAG([-Wpacked])
 213   AC_C_FLAG([-Wpadded])
 214 else
 215   AC_C_FLAG([-Wno-unused-result])
 216 fi
 217 AC_C_FLAG([-Wno-unused-parameter])
 218 AC_C_FLAG([-Wno-missing-field-initializers])
 219
 220 dnl ICC emits a broken warning for const char *x = a ? "b" : "c";
 221 dnl for some reason the string consts get 'promoted' to char *,
 222 dnl triggering a const to non-const conversion warning.
 223 AC_C_FLAG([-diag-disable 3179])
 224
 225 if test x"${enable_werror}" = x"yes" ; then
 226   WERROR="-Werror"
 227 fi
 228 AC_SUBST(WERROR)
 229
 230 dnl need link on this one, not compile
 231 AC_LANG_PUSH(C)
 232 ac_ld_flag_save="$LDFLAGS"
 233 LDFLAGS="$LDFLAGS -rdynamic"
 234 AC_MSG_CHECKING([[whether linker supports -rdynamic]])
 235 AC_LINK_IFELSE(
 236         [AC_LANG_PROGRAM([[]])],
 237         [AC_MSG_RESULT([yes])],
 238         [
 239                 LDFLAGS="$ac_ld_flag_save"
 240                 AC_MSG_RESULT([no])
 241         ])
 242 AC_LANG_POP(C)
 243
 244 dnl ----------
 245 dnl Essentials
 246 dnl ----------
 247
 248 AX_PTHREAD([
 249   CC="$PTHREAD_CC"
 250   CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 251   LIBS="$PTHREAD_LIBS $LIBS"
 252 ], [
 253   AC_MSG_FAILURE([This FRR version needs pthreads])
 254 ])
 255
 256 dnl --------------
 257 dnl Check programs
 258 dnl --------------
 259 AC_PROG_INSTALL
 260 AC_PROG_LN_S
 261 AC_PROG_MAKE_SET
 262 AC_CHECK_TOOL(AR, ar)
 263
 264 dnl -----------------
 265 dnl System extensions
 266 dnl -----------------
 267 AC_GNU_SOURCE
 268
 269 dnl -------
 270 dnl libtool
 271 dnl -------
 272 LT_INIT
 273
 274 dnl ----------------------
 275 dnl Packages configuration
 276 dnl ----------------------
 277 AC_ARG_WITH(pkg-extra-version,
 278         AS_HELP_STRING([--with-pkg-extra-version=VER], [add extra version field, for packagers/distributions]),
 279         [EXTRAVERSION=$withval],)
 280 AC_ARG_WITH(pkg-git-version,
 281         AS_HELP_STRING([--with-pkg-git-version], [add git information to MOTD and build version string]),
 282         [ test "x$withval" != "xno" && with_pkg_git_version="yes" ])
 283 AC_ARG_WITH(vtysh_pager,
 284         AS_HELP_STRING([--with-vtysh-pager=PAGER], [control what pager is compiled in as default]),
 285         VTYSH_PAGER=$withval, VTYSH_PAGER="more")
 286 AC_ARG_ENABLE(vtysh,
 287   AS_HELP_STRING([--disable-vtysh], [do not build integrated vty shell for FRR]))
 288 AC_ARG_ENABLE(doc,
 289   AS_HELP_STRING([--disable-doc], [do not build docs]))
 290 AC_ARG_ENABLE(zebra,
 291   AS_HELP_STRING([--disable-zebra], [do not build zebra daemon]))
 292 AC_ARG_ENABLE(bgpd,
 293   AS_HELP_STRING([--disable-bgpd], [do not build bgpd]))
 294 AC_ARG_ENABLE(ripd,
 295   AS_HELP_STRING([--disable-ripd], [do not build ripd]))
 296 AC_ARG_ENABLE(ripngd,
 297   AS_HELP_STRING([--disable-ripngd], [do not build ripngd]))
 298 AC_ARG_ENABLE(ospfd,
 299   AS_HELP_STRING([--disable-ospfd], [do not build ospfd]))
 300 AC_ARG_ENABLE(ospf6d,
 301   AS_HELP_STRING([--disable-ospf6d], [do not build ospf6d]))
 302 AC_ARG_ENABLE(ldpd,
 303   AS_HELP_STRING([--enable-ldpd], [build ldpd]))
 304 AC_ARG_ENABLE(nhrpd,
 305   AS_HELP_STRING([--disable-nhrpd], [do not build nhrpd]))
 306 AC_ARG_ENABLE(eigrpd,
 307   AS_HELP_STRING([--disable-eigrpd], [do not build eigrpd]))
 308 AC_ARG_ENABLE(babeld,
 309   AS_HELP_STRING([--disable-babeld], [do not build babeld]))
 310 AC_ARG_ENABLE(watchfrr,
 311   AS_HELP_STRING([--disable-watchfrr], [do not build watchfrr]))
 312 AC_ARG_ENABLE(isisd,
 313   AS_HELP_STRING([--disable-isisd], [do not build isisd]))
 314 AC_ARG_ENABLE(pimd,
 315   AS_HELP_STRING([--disable-pimd], [do not build pimd]))
 316 AC_ARG_ENABLE(bgp-announce,
 317   AS_HELP_STRING([--disable-bgp-announce,], [turn off BGP route announcement]))
 318 AC_ARG_ENABLE(bgp-vnc,
 319   AS_HELP_STRING([--disable-bgp-vnc],[turn off BGP VNC support]))
 320 AC_ARG_WITH(rfp-path,
 321   AS_HELP_STRING([--with-rfp-path[=DIR]],[path to replaced stub RFP used with BGP VNC]))
 322 AC_ARG_ENABLE(snmp,
 323   AS_HELP_STRING([--enable-snmp=ARG], [enable SNMP support (smux or agentx)]))
 324 AC_ARG_ENABLE(zeromq,
 325   AS_HELP_STRING([--enable-zeromq], [enable ZeroMQ handler (libfrrzmq)]))
 326 AC_ARG_WITH(libpam,
 327   AS_HELP_STRING([--with-libpam], [use libpam for PAM support in vtysh]))
 328 AC_ARG_ENABLE(ospfapi,
 329   AS_HELP_STRING([--disable-ospfapi], [do not build OSPFAPI to access the OSPF LSA Database]))
 330 AC_ARG_ENABLE(ospfclient,
 331   AS_HELP_STRING([--disable-ospfclient], [do not build OSPFAPI client for OSPFAPI,
 332                           (this is the default if --disable-ospfapi is set)]))
 333 AC_ARG_ENABLE(multipath,
 334   AS_HELP_STRING([--enable-multipath=ARG], [enable multipath function, ARG must be digit]))
 335 AC_ARG_ENABLE(user,
 336   AS_HELP_STRING([--enable-user=USER], [user to run FRR suite as (default frr)]))
 337 AC_ARG_ENABLE(group,
 338   AS_HELP_STRING([--enable-group=GROUP], [group to run FRR suite as (default frr)]))
 339 AC_ARG_ENABLE(vty_group,
 340   AS_HELP_STRING([--enable-vty-group=ARG], [set vty sockets to have specified group as owner]))
 341 AC_ARG_ENABLE(configfile_mask,
 342   AS_HELP_STRING([--enable-configfile-mask=ARG], [set mask for config files]))
 343 AC_ARG_ENABLE(logfile_mask,
 344   AS_HELP_STRING([--enable-logfile-mask=ARG], [set mask for log files]))
 345 AC_ARG_ENABLE(shell_access,
 346   AS_HELP_STRING([--enable-shell-access], [Allow users to access shell/telnet/ssh]))
 347 AC_ARG_ENABLE(rtadv,
 348   AS_HELP_STRING([--disable-rtadv], [disable IPV6 router advertisement feature]))
 349 AC_ARG_ENABLE(irdp,
 350   AS_HELP_STRING([--disable-irdp], [enable IRDP server support in zebra (default if supported)]))
 351 AC_ARG_ENABLE(capabilities,
 352   AS_HELP_STRING([--disable-capabilities], [disable using POSIX capabilities]))
 353 AC_ARG_ENABLE(rusage,
 354   AS_HELP_STRING([--disable-rusage], [disable using getrusage]))
 355 AC_ARG_ENABLE(gcc_ultra_verbose,
 356   AS_HELP_STRING([--enable-gcc-ultra-verbose], [enable ultra verbose GCC warnings]))
 357 AC_ARG_ENABLE(linux24_tcp_md5,
 358   AS_HELP_STRING([--enable-linux24-tcp-md5], [enable support for old, Linux-2.4 RFC2385 patch]))
 359 AC_ARG_ENABLE(backtrace,
 360   AS_HELP_STRING([--disable-backtrace,], [disable crash backtraces (default autodetect)]))
 361 AC_ARG_ENABLE(time-check,
 362   AS_HELP_STRING([--disable-time-check], [disable slow thread warning messages]))
 363 AC_ARG_ENABLE(pcreposix,
 364   AS_HELP_STRING([--enable-pcreposix], [enable using PCRE Posix libs for regex functions]))
 365 AC_ARG_ENABLE(fpm,
 366   AS_HELP_STRING([--enable-fpm], [enable Forwarding Plane Manager support]))
 367 AC_ARG_ENABLE(systemd,
 368   AS_HELP_STRING([--enable-systemd], [enable Systemd support]))
 369 AC_ARG_ENABLE(werror,
 370   AS_HELP_STRING([--enable-werror], [enable -Werror (recommended for developers only)]))
 371 AC_ARG_ENABLE(cumulus,
 372   AS_HELP_STRING([--enable-cumulus], [enable Cumulus Switch Special Extensions]))
 373 AC_ARG_ENABLE(datacenter,
 374   AS_HELP_STRING([--enable-datacenter], [enable Compilation for Data Center Extensions]))
 375 AC_ARG_ENABLE(rr-semantics,
 376   AS_HELP_STRING([--disable-rr-semantics], [disable the v6 Route Replace semantics]))
 377 AC_ARG_ENABLE([protobuf],
 378   AS_HELP_STRING([--enable-protobuf], [Enable experimental protobuf support]))
 379 AC_ARG_ENABLE([oldvpn_commands],
 380   AS_HELP_STRING([--enable-oldvpn-commands], [Keep old vpn commands]))
 381
 382 AC_CHECK_HEADERS(json-c/json.h)
 383 AC_CHECK_LIB(json-c, json_object_get, LIBS="$LIBS -ljson-c", [], [-lm])
 384 if test $ac_cv_lib_json_c_json_object_get = no; then
 385   AC_CHECK_LIB(json, json_object_get, LIBS="$LIBS -ljson")
 386   if test $ac_cv_lib_json_json_object_get = no; then
 387       AC_MSG_ERROR([lib json is needed to compile])
 388   fi
 389 fi
 390
 391 AC_ARG_ENABLE([dev_build],
 392     AS_HELP_STRING([--enable-dev-build], [build for development]))
 393
 394 if test x"${enable_time_check}" != x"no" ; then
 395   if test x"${enable_time_check}" = x"yes" -o x"${enable_time_check}" = x ; then
 396     AC_DEFINE(CONSUMED_TIME_CHECK,5000000,Consumed Time Check)
 397   else
 398     AC_DEFINE_UNQUOTED(CONSUMED_TIME_CHECK,$enable_time_check,Consumed Time Check)
 399   fi
 400 fi
 401
 402 case "${enable_systemd}" in
 403   "no") ;;
 404   "yes")
 405   AC_CHECK_LIB(systemd, sd_notify, LIBS="$LIBS -lsystemd")
 406   if test $ac_cv_lib_systemd_sd_notify = no; then
 407     AC_MSG_ERROR([enable systemd has been specified but systemd development env not found on your system])
 408   else
 409     AC_DEFINE(HAVE_SYSTEMD,,Compile systemd support in)
 410   fi
 411   ;;
 412   "*") ;;
 413 esac
 414
 415 if test "${enable_rr_semantics}" != "no" ; then
 416   AC_DEFINE(HAVE_V6_RR_SEMANTICS,, Compile in v6 Route Replacement Semantics)
 417 fi
 418
 419 if test "${enable_datacenter}" = "yes" ; then
 420   AC_DEFINE(HAVE_DATACENTER,,Compile extensions for a DataCenter)
 421   DFLT_NAME="datacenter"
 422 else
 423   DFLT_NAME="traditional"
 424 fi
 425
 426 if test "${enable_cumulus}" = "yes" ; then
 427   AC_DEFINE(HAVE_CUMULUS,,Compile Special Cumulus Code in)
 428 fi
 429
 430 AC_SUBST(DFLT_NAME)
 431 AC_DEFINE_UNQUOTED(DFLT_NAME,["$DFLT_NAME"], Name of the configuration default set)
 432
 433 if test "${enable_shell_access}" = "yes"; then
 434    AC_DEFINE(HAVE_SHELL_ACCESS,,Allow user to use ssh/telnet/bash)
 435 fi
 436
 437 AM_CONDITIONAL([FPM], [test "x$enable_fpm" = "xyes"])
 438
 439 if test "x${enable_dev_build}" = "xyes"; then
 440    AC_DEFINE(DEV_BUILD,,Build for development)
 441 fi
 442 AM_CONDITIONAL([DEV_BUILD], [test "x$enable_dev_build" = "xyes"])
 443
 444 #
 445 # Python for clippy
 446 #
 447 AS_IF([test "$host" = "$build"], [
 448   PYTHONCONFIG=""
 449
 450   # ordering:
 451   # 1.  try python3, but respect the user's preference on which minor ver
 452   # 2.  try python, which might be py3 or py2 again on the user's preference
 453   # 3.  try python2 (can really only be 2.7 but eh)
 454   # 4.  try 3.5 > 3.4 > 3.3 > 3.2 > 2.7 through pkg-config (no user pref)
 455   #
 456   # (AX_PYTHON_DEVEL has no clue about py3 vs py2)
 457   # (AX_PYTHON does not do what we need)
 458
 459   AC_CHECK_TOOLS([PYTHONCONFIG], [python3-config python-config python2-config])
 460   if test -n "$PYTHONCONFIG"; then
 461     PYTHON_CFLAGS="`\"${PYTHONCONFIG}\" --includes`"
 462     PYTHON_LIBS="`\"${PYTHONCONFIG}\" --libs`"
 463
 464     AC_MSG_CHECKING([whether we found a working Python version])
 465     AC_LINK_IFELSE_FLAGS([$PYTHON_CFLAGS], [$PYTHON_LIBS], [AC_LANG_PROGRAM([
 466 #include <Python.h>
 467 #if PY_VERSION_HEX < 0x02070000
 468 #error python too old
 469 #endif
 470 int main(void);
 471 ],
 472 [
 473 {
 474   Py_Initialize();
 475   return 0;
 476 }
 477 ])], [
 478       PYTHONCONFIG=""
 479       unset PYTHON_LIBS
 480       unset PYTHON_CFLAGS
 481     ])
 482   fi
 483
 484   if test -z "$PYTHONCONFIG"; then
 485     PKG_CHECK_MODULES([PYTHON], python-3.5, [], [
 486       PKG_CHECK_MODULES([PYTHON], python-3.4, [], [
 487         PKG_CHECK_MODULES([PYTHON], python-3.3, [], [
 488           PKG_CHECK_MODULES([PYTHON], python-3.2, [], [
 489             PKG_CHECK_MODULES([PYTHON], python-2.7, [], [
 490               AC_MSG_FAILURE([could not find python-config or pkg-config python, please install Python development files from libpython-dev or similar])
 491               ])])])])])
 492
 493
 494     AC_MSG_CHECKING([whether we found a working Python version])
 495     AC_LINK_IFELSE_FLAGS([$PYTHON_CFLAGS], [$PYTHON_LIBS], [AC_LANG_PROGRAM([
 496 #include <Python.h>
 497 #if PY_VERSION_HEX < 0x02070000
 498 #error python too old
 499 #endif
 500 int main(void);
 501 ],
 502 [
 503 {
 504   Py_Initialize();
 505   return 0;
 506 }
 507 ])], [
 508       AC_MSG_FAILURE([could not find python-config or pkg-config python, please install Python development files from libpython-dev or similar])
 509     ])
 510   fi
 511 ])
 512 AC_SUBST(PYTHON_CFLAGS)
 513 AC_SUBST(PYTHON_LIBS)
 514
 515 #
 516 # Logic for protobuf support.
 517 #
 518 if test "$enable_protobuf" = "yes"; then
 519    have_protobuf=yes
 520
 521    # Check for protoc-c
 522    AC_CHECK_PROG([PROTOC_C], [protoc-c], [protoc-c], [/bin/false])
 523    if test "x$PROTOC_C" = "x/bin/false"; then
 524       have_protobuf=no
 525    else
 526       found_protobuf_c=no
 527       PKG_CHECK_MODULES([PROTOBUF_C], libprotobuf-c >= 0.14,
 528                      [found_protobuf_c=yes],
 529                      [AC_MSG_RESULT([pkg-config did not find libprotobuf-c])])
 530
 531       if test "x$found_protobuf_c" = "xyes"; then
 532          LDFLAGS="$LDFLAGS $PROTOBUF_C_LIBS"
 533          CFLAGS="$CFLAGS $PROTOBUF_C_CFLAGS"
 534       else
 535         AC_CHECK_HEADER([google/protobuf-c/protobuf-c.h], [],
 536                         [have_protobuf=no; AC_MSG_RESULT([Couldn't find google/protobuf-c.h])])
 537       fi
 538    fi
 539 fi
 540
 541 #
 542 # Logic for old vpn commans support.
 543 #
 544 if test "$enable_oldvpn_commands" = "yes"; then
 545    AC_DEFINE(KEEP_OLD_VPN_COMMANDS,, [Define for compiling with old vpn commands])
 546 fi
 547
 548 # Fail if the user explicity enabled protobuf support and we couldn't
 549 # find the compiler or libraries.
 550 if test "x$have_protobuf" = "xno" && test "x$enable_protobuf" = "xyes"; then
 551    AC_MSG_ERROR([Protobuf enabled explicitly but can't find libraries/tools])
 552 fi
 553
 554 if test "x$have_protobuf" = "xyes"; then
 555    AC_DEFINE(HAVE_PROTOBUF,, protobuf)
 556 fi
 557
 558 AM_CONDITIONAL([HAVE_PROTOBUF], [test "x$have_protobuf" = "xyes"])
 559
 560 #
 561 # End of logic for protobuf support.
 562 #
 563
 564 if test "${enable_linux24_tcp_md5}" = "yes"; then
 565   AC_DEFINE(HAVE_TCP_MD5_LINUX24,,Old Linux 2.4 TCP MD5 Signature Patch)
 566 fi
 567
 568 AC_MSG_CHECKING(if zebra should be configurable to send Route Advertisements)
 569 if test "${enable_rtadv}" != "no"; then
 570   AC_MSG_RESULT(yes)
 571   AC_DEFINE(HAVE_RTADV,,Enable IPv6 Routing Advertisement support)
 572 else
 573   AC_MSG_RESULT(no)
 574 fi
 575
 576 if test x"${enable_user}" = x"no"; then
 577   enable_user=""
 578 else
 579   if test x"${enable_user}" = x"yes" || test x"${enable_user}" = x""; then
 580     enable_user="frr"
 581   fi
 582   AC_DEFINE_UNQUOTED(FRR_USER, "${enable_user}", frr User)
 583 fi
 584
 585 if test x"${enable_group}" = x"no"; then
 586   enable_group=""
 587 else
 588   if test x"${enable_group}" = x"yes" || test x"${enable_group}" = x""; then
 589     enable_group="frr"
 590   fi
 591   AC_DEFINE_UNQUOTED(FRR_GROUP, "${enable_group}", frr Group)
 592 fi
 593
 594 if test x"${enable_vty_group}" = x"yes" ; then
 595   AC_MSG_ERROR([--enable-vty-group requires a group as argument, not yes])
 596 elif test x"${enable_vty_group}" != x""; then
 597   if test x"${enable_vty_group}" != x"no"; then
 598     AC_DEFINE_UNQUOTED(VTY_GROUP, "${enable_vty_group}", VTY Sockets Group)
 599   fi
 600 fi
 601 AC_SUBST([enable_user])
 602 AC_SUBST([enable_group])
 603 AC_SUBST([enable_vty_group])
 604
 605 enable_configfile_mask=${enable_configfile_mask:-0600}
 606 AC_DEFINE_UNQUOTED(CONFIGFILE_MASK, ${enable_configfile_mask}, Mask for config files)
 607
 608 enable_logfile_mask=${enable_logfile_mask:-0600}
 609 AC_DEFINE_UNQUOTED(LOGFILE_MASK, ${enable_logfile_mask}, Mask for log files)
 610
 611 MPATH_NUM=1
 612
 613 case "${enable_multipath}" in
 614   0)
 615     MPATH_NUM=64
 616     ;;
 617   [[1-9]|[1-9][0-9]|[1-9][0-9][0-9]])
 618     MPATH_NUM="${enable_multipath}"
 619     ;;
 620   "")
 621     ;;
 622   *)
 623     AC_MSG_FAILURE([Please specify digit to enable multipath ARG])
 624     ;;
 625 esac
 626
 627 AC_DEFINE_UNQUOTED(MULTIPATH_NUM, $MPATH_NUM, Maximum number of paths for a route)
 628
 629 AC_DEFINE_UNQUOTED(VTYSH_PAGER, "$VTYSH_PAGER", [What pager to use])
 630
 631 dnl -----------------------------------
 632 dnl Add extra version string to package
 633 dnl name, string and version fields.
 634 dnl -----------------------------------
 635 if test "x${EXTRAVERSION}" != "x" ; then
 636   VERSION="${VERSION}${EXTRAVERSION}"
 637   PACKAGE_VERSION="${PACKAGE_VERSION}${EXTRAVERSION}"
 638   AC_SUBST(PACKAGE_EXTRAVERSION, ["${EXTRAVERSION}"])
 639   PACKAGE_STRING="${PACKAGE_STRING}${EXTRAVERSION}"
 640 fi
 641
 642 if test "x$with_pkg_git_version" = "xyes"; then
 643         if test -d "${srcdir}/.git"; then
 644                 AC_DEFINE(GIT_VERSION, [1], [include git version info])
 645         else    with_pkg_git_version="no"
 646                 AC_MSG_WARN([--with-pkg-git-version given, but this is not a git checkout])
 647         fi
 648 fi
 649 AM_CONDITIONAL([GIT_VERSION], [test "x$with_pkg_git_version" = "xyes"])
 650
 651 dnl ------------------------------------
 652 dnl Check C keywords and standard  types
 653 dnl ------------------------------------
 654 AC_C_CONST
 655 AC_C_INLINE
 656 AC_C_VOLATILE
 657 AC_HEADER_STDC
 658 dnl AC_TYPE_PID_T
 659 AC_TYPE_UID_T
 660 AC_TYPE_MODE_T
 661 AC_TYPE_SIZE_T
 662 AC_STRUCT_TM
 663
 664 dnl -------------------------
 665 dnl Check other header files.
 666 dnl -------------------------
 667 AC_CHECK_HEADERS([stropts.h sys/ksym.h \
 668         linux/version.h asm/types.h \
 669         sys/cdefs.h])
 670
 671 ac_stdatomic_ok=false
 672 AC_DEFINE(FRR_AUTOCONF_ATOMIC, 1, [did autoconf checks for atomic funcs])
 673 AC_CHECK_HEADER([stdatomic.h],[
 674
 675   AC_MSG_CHECKING([whether _Atomic qualifier works])
 676   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 677 #include <stdatomic.h>
 678 int main(int argc, char **argv) {
 679   _Atomic int i = 0;
 680   return i;
 681 }
 682 ]])], [
 683     AC_DEFINE(HAVE_STDATOMIC_H, 1, [found stdatomic.h])
 684     AC_MSG_RESULT([yes])
 685     ac_stdatomic_ok=true
 686   ], [
 687     AC_MSG_RESULT([no])
 688   ])
 689 ])
 690
 691 AS_IF([$ac_stdatomic_ok], [true], [
 692   AC_MSG_CHECKING([for __atomic_* builtins])
 693   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 694 int main(int argc, char **argv) {
 695   volatile int i = 1;
 696   __atomic_store_n (&i, 0, __ATOMIC_RELEASE);
 697   return __atomic_load_n (&i, __ATOMIC_ACQUIRE);
 698 }
 699 ]])], [
 700     AC_DEFINE(HAVE___ATOMIC, 1, [found __atomic builtins])
 701     AC_MSG_RESULT([yes])
 702   ], [
 703     AC_MSG_RESULT([no])
 704
 705     dnl FreeBSD 9 has a broken stdatomic.h where _Atomic doesn't work
 706     AC_MSG_CHECKING([for __sync_* builtins])
 707     AC_LINK_IFELSE([AC_LANG_SOURCE([[
 708 int main(int argc, char **argv) {
 709   volatile int i = 1;
 710   __sync_fetch_and_sub (&i, 1);
 711   return __sync_val_compare_and_swap (&i, 0, 1);
 712 }
 713 ]])], [
 714       AC_DEFINE(HAVE___SYNC, 1, [found __sync builtins])
 715       AC_MSG_RESULT([yes])
 716
 717       AC_MSG_CHECKING([for __sync_swap builtin])
 718       AC_LINK_IFELSE([AC_LANG_SOURCE([[
 719 int main(int argc, char **argv) {
 720   volatile int i = 1;
 721   return __sync_swap (&i, 2);
 722 }
 723 ]])], [
 724         AC_DEFINE(HAVE___SYNC_SWAP, 1, [found __sync_swap builtin])
 725         AC_MSG_RESULT([yes])
 726       ], [
 727         AC_MSG_RESULT([no])
 728       ])
 729
 730     ], [
 731       AC_MSG_RESULT([no])
 732       AC_MSG_FAILURE([stdatomic.h unavailable and $CC has neither __atomic nor __sync builtins])
 733     ])
 734   ])
 735 ])
 736
 737 dnl Utility macro to avoid retyping includes all the time
 738 m4_define([FRR_INCLUDES],
 739 [#ifdef SUNOS_5
 740 #define _XPG4_2
 741 #define __EXTENSIONS__
 742 #endif
 743 #include <stdio.h>
 744 #include <stdlib.h>
 745 #include <stddef.h>
 746 #include <sys/types.h>
 747 /* sys/conf.h depends on param.h on FBSD at least */
 748 #include <sys/param.h>
 749 /* Required for MAXSIG */
 750 #include <signal.h>
 751 #include <sys/socket.h>
 752 #ifdef __APPLE__
 753 # define __APPLE_USE_RFC_3542
 754 #endif
 755 #include <netinet/in.h>
 756 #include <sys/time.h>
 757 #include <time.h>
 758 #include <net/if.h>
 759 ])dnl
 760
 761 dnl Same applies for HAVE_NET_IF_VAR_H, which HAVE_NETINET6_ND6_H and
 762 dnl HAVE_NETINET_IN_VAR_H depend upon. But if_var.h depends on if.h, hence
 763 dnl an additional round for it.
 764
 765 AC_CHECK_HEADERS([net/if_var.h], [], [], FRR_INCLUDES)
 766
 767 m4_define([FRR_INCLUDES],
 768 FRR_INCLUDES
 769 [#if HAVE_NET_IF_VAR_H
 770 # include <net/if_var.h>
 771 #endif
 772 ])dnl
 773
 774 AC_CHECK_HEADERS([netinet/in_var.h \
 775         net/if_dl.h net/netopt.h \
 776         inet/nd.h netinet/ip_icmp.h \
 777         sys/sysctl.h sys/sockio.h kvm.h sys/conf.h],
 778         [], [], FRR_INCLUDES)
 779
 780 AC_CHECK_HEADERS([ucontext.h], [], [],
 781 [#ifndef __USE_GNU
 782 #define __USE_GNU
 783 #endif /* __USE_GNU */
 784 FRR_INCLUDES
 785 ])
 786
 787 m4_define([UCONTEXT_INCLUDES],
 788 [#include <ucontext.h>])dnl
 789
 790 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.uc_regs],
 791   [], [], [UCONTEXT_INCLUDES])
 792 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs],
 793   [AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs.nip],
 794    [], [], [UCONTEXT_INCLUDES])],
 795   [], [UCONTEXT_INCLUDES])
 796 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.gregs],
 797   [], [], [UCONTEXT_INCLUDES])
 798
 799 m4_define([FRR_INCLUDES],
 800 FRR_INCLUDES
 801 [
 802 #include <sys/un.h>
 803 #include <netinet/in_systm.h>
 804 #if HAVE_NETINET_IN_VAR_H
 805 # include <netinet/in_var.h>
 806 #endif
 807 #if HAVE_NET_IF_DL_H
 808 # include <net/if_dl.h>
 809 #endif
 810 #if HAVE_NET_NETOPT_H
 811 # include <net/netopt.h>
 812 #endif
 813 #include <net/route.h>
 814 #if HAVE_INET_ND_H
 815 # include <inet/nd.h>
 816 #endif
 817 #include <arpa/inet.h>
 818 /* Required for IDRP */
 819 #if HAVE_NETINET_IP_ICMP_H
 820 # include <netinet/ip_icmp.h>
 821 #endif
 822 ])dnl
 823
 824 dnl V6 headers are checked below, after we check for v6
 825
 826 AC_MSG_CHECKING([which operating system interface to use])
 827 case "$host_os" in
 828   sunos* | solaris2*)
 829     AC_MSG_RESULT([Solaris])
 830
 831     AC_DEFINE(SUNOS_5, 1, [SunOS 5])
 832     AC_DEFINE(SOLARIS_IPV6, 1, Solaris IPv6)
 833
 834     AC_CHECK_LIB(socket, main)
 835     AC_CHECK_LIB(nsl, main)
 836     AC_CHECK_LIB(umem, main)
 837     AC_CHECK_FUNCS([printstack], [
 838       AC_DEFINE([HAVE_PRINTSTACK],1,[Solaris printstack])
 839       AC_DEFINE([HAVE_STACK_TRACE],1,[Stack symbols decode functionality])
 840     ])
 841     CURSES=-lcurses
 842     SOLARIS="solaris"
 843     ;;
 844   linux*)
 845     AC_MSG_RESULT([Linux])
 846
 847     AC_DEFINE(GNU_LINUX,,GNU Linux)
 848     AC_DEFINE(HAVE_NETLINK,,netlink)
 849     AC_DEFINE(LINUX_IPV6,1,Linux IPv6 stack)
 850
 851     dnl Linux has a compilation problem with mixing
 852     dnl netinet/in.h and linux/in6.h they are not
 853     dnl compatible.  There has been discussion on
 854     dnl how to fix it but no real progress on implementation
 855     dnl when they fix it, remove this
 856     AC_DEFINE(IPV6_MINHOPCOUNT, 73, Linux ipv6 Min Hop Count)
 857
 858     AC_CHECK_DECLS([IFLA_INFO_SLAVE_KIND], [], [], [#include <linux/if_link.h>])
 859     ;;
 860   openbsd*)
 861     AC_MSG_RESULT([OpenBSD])
 862
 863     AC_DEFINE(OPEN_BSD,,OpenBSD)
 864     AC_DEFINE(KAME,1,KAME IPv6)
 865
 866     if test "x${enable_pimd}" != "xno"; then
 867       case "$host_os" in
 868       openbsd6.0)
 869         ;;
 870       openbsd[6-9]*)
 871         AC_MSG_FAILURE([pimd cannot be enabled as PIM support has been removed from OpenBSD 6.1])
 872         ;;
 873       esac
 874     fi
 875     ;;
 876   *)
 877     AC_MSG_RESULT([BSD])
 878
 879     AC_DEFINE(HAVE_NET_RT_IFLIST,,NET_RT_IFLIST)
 880     AC_DEFINE(KAME,1,KAME IPv6)
 881     ;;
 882 esac
 883 AM_CONDITIONAL(SOLARIS, test "${SOLARIS}" = "solaris")
 884
 885 AC_SYS_LARGEFILE
 886
 887 dnl ---------------------
 888 dnl Integrated VTY option
 889 dnl ---------------------
 890 case "${enable_vtysh}" in
 891   "no") VTYSH="";;
 892   *)    VTYSH="vtysh";
 893          AC_DEFINE(VTYSH,,VTY shell)
 894 dnl      Vtysh uses libreadline, which looks for termcap functions at
 895 dnl      configure time.  We follow readlines search order.
 896 dnl      The required procedures are in libtermcap on NetBSD, in
 897 dnl      [TODO] on Linux, and in [TODO] on Solaris.
 898          AC_CHECK_LIB(termcap, tputs, LIBREADLINE="$LIBREADLINE -ltermcap",
 899            [AC_CHECK_LIB(tinfo, tputs, LIBREADLINE="$LIBREADLINE -ltinfo",
 900              [AC_CHECK_LIB(curses, tputs, LIBREADLINE="$LIBREADLINE -lcurses",
 901                [AC_CHECK_LIB(ncurses, tputs,
 902                              LIBREADLINE="$LIBREADLINE -lncurses")]
 903               )]
 904             )]
 905           )
 906          AC_CHECK_LIB(readline, main, LIBREADLINE="-lreadline $LIBREADLINE",,
 907                       "$LIBREADLINE")
 908          if test $ac_cv_lib_readline_main = no; then
 909            AC_MSG_ERROR([vtysh needs libreadline but was not found and usable on your system.])
 910          fi
 911          AC_CHECK_HEADER(readline/history.h)
 912          if test $ac_cv_header_readline_history_h = no;then
 913            AC_MSG_ERROR([readline is too old to have readline/history.h, please update to the latest readline library.])
 914          fi
 915          AC_CHECK_LIB(readline, rl_completion_matches,
 916                       LIBREADLINE="$LIBREADLINE",, "$LIBREADLINE")
 917          if test $ac_cv_lib_readline_rl_completion_matches = no; then
 918            AC_DEFINE(rl_completion_matches,completion_matches,Old readline)
 919          fi
 920          ;;
 921 esac
 922 AC_SUBST(LIBREADLINE)
 923 AM_CONDITIONAL(VTYSH, test "x$VTYSH" = "xvtysh")
 924
 925 dnl ----------
 926 dnl PAM module
 927 dnl
 928 dnl FRR detects the PAM library it is built against by checking for a
 929 dnl functional pam_misc.h (Linux-PAM) or openpam.h (OpenPAM) header. pam_misc.h
 930 dnl is known to #include pam_appl.h, the standard header of a PAM library, and
 931 dnl openpam.h doesn't do that, although depends on the header too. Hence a
 932 dnl little assistance to AC_CHECK_HEADER is necessary for the proper detection
 933 dnl of OpenPAM.
 934 dnl ----------
 935 if test "$with_libpam" = "yes"; then
 936   AC_CHECK_HEADER([security/pam_misc.h],
 937     [AC_DEFINE(HAVE_PAM_MISC_H,,Have pam_misc.h)
 938      AC_DEFINE(PAM_CONV_FUNC,misc_conv,Have misc_conv)
 939      pam_conv_func="misc_conv"
 940     ],
 941     [], FRR_INCLUDES)
 942   AC_CHECK_HEADER([security/openpam.h],
 943     [AC_DEFINE(HAVE_OPENPAM_H,,Have openpam.h)
 944      AC_DEFINE(PAM_CONV_FUNC,openpam_ttyconv,Have openpam_ttyconv)
 945      pam_conv_func="openpam_ttyconv"
 946     ],
 947     [], FRR_INCLUDES[#include <security/pam_appl.h>])
 948   if test -z "$ac_cv_header_security_pam_misc_h$ac_cv_header_security_openpam_h" ; then
 949     AC_MSG_WARN([*** pam support will not be built ***])
 950     with_libpam="no"
 951   fi
 952 fi
 953
 954 if test "$with_libpam" = "yes"; then
 955 dnl took this test from proftpds configure.in and suited to our needs
 956 dnl -------------------------------------------------------------------------
 957 dnl
 958 dnl This next check looks funky due to a linker problem with some versions
 959 dnl of the PAM library.  Prior to 0.72 release, the Linux PAM shared library
 960 dnl omitted requiring libdl linking information. PAM-0.72 or better ships
 961 dnl with RedHat 6.2 and Debian 2.2 or better.
 962 AC_CHECK_LIB(pam, pam_start,
 963   [AC_CHECK_LIB(pam, $pam_conv_func,
 964     [AC_DEFINE(USE_PAM,,Use PAM for authentication)
 965      LIBPAM="-lpam"],
 966     [AC_DEFINE(USE_PAM,,Use PAM for authentication)
 967      LIBPAM="-lpam -lpam_misc"]
 968     )
 969   ],
 970
 971   [AC_CHECK_LIB(pam, pam_end,
 972     [AC_CHECK_LIB(pam, $pam_conv_func,
 973       [AC_DEFINE(USE_PAM,,Use PAM for authentication)
 974        LIBPAM="-lpam -ldl"],
 975       [AC_DEFINE(USE_PAM,,Use PAM for authentication)
 976        LIBPAM="-lpam -ldl -lpam_misc"]
 977      )
 978   ],AC_MSG_WARN([*** pam support will not be built ***]),
 979   [-ldl])
 980   ]
 981 )
 982 fi
 983 AC_SUBST(LIBPAM)
 984
 985 dnl -------------------------------
 986 dnl Endian-ness check
 987 dnl -------------------------------
 988 AC_WORDS_BIGENDIAN
 989
 990 dnl -------------------------------
 991 dnl check the size in byte of the C
 992 dnl -------------------------------
 993 dnl AC_CHECK_SIZEOF(char)
 994 dnl AC_CHECK_SIZEOF(int)
 995 dnl AC_CHECK_SIZEOF(short)
 996 dnl AC_CHECK_SIZEOF(long)
 997
 998 dnl ----------------------------
 999 dnl check existance of functions
1000 dnl ----------------------------
1001 AC_FUNC_FNMATCH
1002 AC_FUNC_FORK
1003 AC_FUNC_MKTIME
1004 AC_FUNC_STAT
1005
1006 dnl -------------------------------
1007 dnl bgpd needs pow() and hence libm
1008 dnl -------------------------------
1009 TMPLIBS="$LIBS"
1010 AC_CHECK_HEADER([math.h],
1011   [AC_CHECK_LIB([m], [pow],
1012     [LIBM="-lm"
1013      LIBS="$LIBS $LIBM"
1014      AC_CHECK_FUNCS(pow,[],[LIBM=""])
1015     ])
1016 ])
1017 if test x"$LIBM" = x ; then
1018   AC_MSG_WARN([Unable to find working pow function - bgpd may not link])
1019 fi
1020 LIBS="$TMPLIBS"
1021 AC_SUBST(LIBM)
1022
1023 AC_CHECK_FUNCS([ppoll], [
1024   AC_DEFINE([HAVE_PPOLL], 1, [have Linux/BSD ppoll()])
1025 ])
1026 AC_CHECK_FUNCS([pollts], [
1027   AC_DEFINE([HAVE_POLLTS], 1, [have NetBSD pollts()])
1028 ])
1029
1030 dnl ---------------
1031 dnl other functions
1032 dnl ---------------
1033 AC_CHECK_FUNCS([ \
1034         strlcat strlcpy \
1035         getgrouplist])
1036
1037 AC_CHECK_HEADER([asm-generic/unistd.h],
1038                 [AC_CHECK_DECL(__NR_setns,
1039                                AC_DEFINE(HAVE_NETNS,, Have netns),,
1040                                FRR_INCLUDES [#include <asm-generic/unistd.h>
1041                                ])
1042                  AC_CHECK_FUNCS(setns)]
1043                )
1044
1045 dnl --------------------------
1046 dnl Determine IS-IS I/O method
1047 dnl --------------------------
1048 AC_DEFINE(ISIS_METHOD_PFPACKET, 1, [ constant value for isis method pfpacket ])
1049 AC_DEFINE(ISIS_METHOD_DLPI,     2, [ constant value for isis method dlpi ])
1050 AC_DEFINE(ISIS_METHOD_BPF,      3, [ constant value for isis method bpf ])
1051 AC_CHECK_HEADER(net/bpf.h)
1052 AC_CHECK_HEADER(sys/dlpi.h)
1053 AC_MSG_CHECKING(zebra IS-IS I/O method)
1054
1055 case "$host_os" in
1056   linux*)
1057     AC_MSG_RESULT(pfpacket)
1058     ISIS_METHOD_MACRO="ISIS_METHOD_PFPACKET"
1059     ;;
1060   solaris* | sunos*)
1061     AC_MSG_RESULT(DLPI)
1062     ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1063     ;;
1064   *)
1065     if test $ac_cv_header_net_bpf_h = no; then
1066       if test $ac_cv_header_sys_dlpi_h = no; then
1067         AC_MSG_RESULT(none)
1068         if test "${enable_isisd}" = yes; then
1069           AC_MSG_FAILURE([IS-IS support requested but no packet backend found])
1070         fi
1071         AC_MSG_WARN([*** IS-IS support will not be built ***])
1072         enable_isisd="no"
1073       else
1074         AC_MSG_RESULT(DLPI)
1075       fi
1076       ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1077     else
1078       AC_MSG_RESULT(BPF)
1079       ISIS_METHOD_MACRO="ISIS_METHOD_BPF"
1080     fi
1081     ;;
1082 esac
1083 AC_DEFINE_UNQUOTED(ISIS_METHOD, $ISIS_METHOD_MACRO, [ selected method for isis, == one of the constants ])
1084
1085 dnl ------------------------------------
1086 dnl check for broken CMSG_FIRSTHDR macro
1087 dnl ------------------------------------
1088 AC_MSG_CHECKING(for broken CMSG_FIRSTHDR)
1089 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1090 #ifdef SUNOS_5
1091 #define _XPG4_2
1092 #define __EXTENSIONS__
1093 #endif
1094 #include <stdlib.h>
1095 #include <sys/types.h>
1096 #include <sys/socket.h>
1097
1098 main()
1099 {
1100   struct msghdr msg;
1101   char buf[4];
1102
1103   msg.msg_control = buf;
1104   msg.msg_controllen = 0;
1105
1106   if (CMSG_FIRSTHDR(&msg) != NULL)
1107     exit(0);
1108   exit (1);
1109 }]])],[AC_MSG_RESULT(yes - using workaround) AC_DEFINE(HAVE_BROKEN_CMSG_FIRSTHDR,,Broken CMSG_FIRSTHDR)],
1110 [AC_MSG_RESULT(no)],[AC_MSG_RESULT(no)])
1111
1112 dnl ---------------------------------------------------------------
1113 dnl figure out how to specify an interface in multicast sockets API
1114 dnl ---------------------------------------------------------------
1115 AC_CHECK_MEMBERS([struct ip_mreqn.imr_ifindex], [], [], FRR_INCLUDES)
1116
1117 AC_CHECK_HEADERS([linux/mroute.h], [], [],[
1118         #include <sys/socket.h>
1119         #include <netinet/in.h>
1120         #define _LINUX_IN_H             /* For Linux <= 2.6.25 */
1121         #include <linux/types.h>
1122 ])
1123
1124 m4_define([FRR_INCLUDES],
1125 FRR_INCLUDES
1126 [#if HAVE_LINUX_MROUTE_H
1127 # include <linux/mroute.h>
1128 #endif
1129 ])dnl
1130
1131 AC_CHECK_HEADERS([netinet/ip_mroute.h], [], [],[
1132         #include <sys/socket.h>
1133         #include <sys/types.h>
1134         #include <netinet/in.h>
1135         #include <net/route.h>
1136 ])
1137
1138 m4_define([FRR_INCLUDES],
1139 FRR_INCLUDES
1140 [#if HAVE_NETINET_IP_MROUTE_H
1141 # include <netinet/ip_mroute.h>
1142 #endif
1143 ])dnl
1144
1145 AC_MSG_CHECKING([for BSD struct ip_mreq hack])
1146 AC_TRY_COMPILE([#include <sys/param.h>],
1147 [#if (defined(__FreeBSD__) && ((__FreeBSD_version >= 500022 && __FreeBSD_version < 700000) || (__FreeBSD_version < 500000 && __FreeBSD_version >= 440000))) || (defined(__NetBSD__) && defined(__NetBSD_Version__) && __NetBSD_Version__ >= 106010000) || defined(__OpenBSD__) || defined(__APPLE__) || defined(__DragonFly__) || defined(__sun)
1148   return (0);
1149 #else
1150   #error No support for BSD struct ip_mreq hack detected
1151 #endif],[AC_MSG_RESULT(yes)
1152 AC_DEFINE(HAVE_BSD_STRUCT_IP_MREQ_HACK,,[Can pass ifindex in struct ip_mreq])],
1153 AC_MSG_RESULT(no))
1154
1155 AC_MSG_CHECKING([for RFC3678 protocol-independed API])
1156 AC_TRY_COMPILE([
1157 #include <sys/types.h>
1158 #include <netinet/in.h>
1159 ], [struct group_req gr; int sock; setsockopt(sock, IPPROTO_IP, MCAST_JOIN_GROUP, (void*)&gr, sizeof(gr));
1160 ], [AC_MSG_RESULT(yes)
1161 AC_DEFINE(HAVE_RFC3678,1,[Have RFC3678 protocol-independed API])],
1162 AC_MSG_RESULT(no))
1163
1164 dnl ---------------------------------------------------------------
1165 dnl figure out how to check link-state
1166 dnl ---------------------------------------------------------------
1167 AC_CHECK_HEADER( [net/if_media.h],
1168   [m4_define([LINK_DETECT_INCLUDES],
1169     FRR_INCLUDES
1170     [#include <net/if_media.h>
1171   ])
1172   AC_CHECK_MEMBERS( [struct ifmediareq.ifm_status],
1173     AC_DEFINE(HAVE_BSD_LINK_DETECT,,[BSD link-detect]),
1174     [], LINK_DETECT_INCLUDES)],
1175   [],
1176   FRR_INCLUDES)
1177
1178 dnl ---------------------------------------------------------------
1179 dnl Additional, newer way to check link-state using ifi_link_state.
1180 dnl Not available in all BSD's when ifmediareq available
1181 dnl ---------------------------------------------------------------
1182 AC_CHECK_MEMBERS([struct if_data.ifi_link_state],
1183   AC_DEFINE(HAVE_BSD_IFI_LINK_STATE,,[BSD ifi_link_state available]),
1184   [], FRR_INCLUDES)
1185
1186 dnl ------------------------
1187 dnl TCP_MD5SIG socket option
1188 dnl ------------------------
1189
1190 AC_CHECK_HEADER([netinet/tcp.h],
1191    [m4_define([MD5_INCLUDES],
1192       FRR_INCLUDES
1193       [#include <netinet/tcp.h>
1194     ])
1195     AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)],
1196    [],
1197    FRR_INCLUDES)
1198 if test $ac_cv_have_decl_TCP_MD5SIG = no; then
1199   AC_CHECK_HEADER([linux/tcp.h],
1200        [m4_define([MD5_INCLUDES],
1201           FRR_INCLUDES
1202           [#include <linux/tcp.h>
1203         ])
1204        AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)])
1205 fi
1206
1207 dnl ----------------------------------------------------------------------------
1208 dnl figure out if domainname is available in the utsname struct (GNU extension).
1209 dnl ----------------------------------------------------------------------------
1210 AC_CHECK_MEMBERS([struct utsname.domainname], [], [], [#include <sys/utsname.h>])
1211
1212 dnl ------------------
1213 dnl IPv6 header checks
1214 dnl ------------------
1215 AC_CHECK_HEADERS([netinet6/in6.h netinet/in6_var.h \
1216         netinet6/in6_var.h netinet6/nd6.h], [], [],
1217         FRR_INCLUDES)
1218
1219 m4_define([FRR_INCLUDES],dnl
1220 FRR_INCLUDES
1221 [#if HAVE_NETINET6_IN6_H
1222 #include <netinet6/in6.h>
1223 #endif
1224 #if HAVE_NETINET_IN6_VAR_H
1225 #include <netinet/in6_var.h>
1226 #endif
1227 #include <netinet/icmp6.h>
1228 #if HAVE_NETINET6_IN6_VAR_H
1229 # include <netinet6/in6_var.h>
1230 #endif
1231 #if HAVE_NETINET6_ND6_H
1232 # include <netinet6/nd6.h>
1233 #endif
1234 ])dnl
1235
1236 dnl disable doc check
1237 if test "${enable_doc}" = "no";then
1238   DOC=""
1239 else
1240   DOC="doc"
1241 fi
1242
1243 dnl --------------------
1244 dnl Daemon disable check
1245 dnl --------------------
1246 AM_CONDITIONAL(ZEBRA, test "${enable_zebra}" != "no")
1247
1248 if test "${enable_bgpd}" = "no";then
1249   BGPD=""
1250 else
1251   BGPD="bgpd"
1252 fi
1253 AM_CONDITIONAL(BGPD, test "x$BGPD" = "xbgpd")
1254
1255 AM_CONDITIONAL(RIPD, test "${enable_ripd}" != "no")
1256 AM_CONDITIONAL(OSPFD, test "${enable_ospfd}" != "no")
1257 AM_CONDITIONAL(LDPD, test "${enable_ldpd}" != "no")
1258
1259 AS_IF([test "${enable_ldpd}" != "no"], [
1260   AC_DEFINE(HAVE_LDPD, 1, ldpd)
1261 ])
1262
1263 NHRPD=""
1264 case "$host_os" in
1265   linux*)
1266     if test "${enable_nhrpd}" != "no"; then
1267       NHRPD="nhrpd"
1268     fi
1269     ;;
1270   *)
1271     if test "${enable_nhrpd}" = "yes"; then
1272       AC_MSG_ERROR([nhrpd requires kernel APIs that are only present on Linux.])
1273     fi
1274     ;;
1275 esac
1276 AM_CONDITIONAL(NHRPD, test "x$NHRPD" = "xnhrpd")
1277
1278 AM_CONDITIONAL(EIGRPD, test "${enable_eigrpd}" != "no")
1279
1280 if test "${enable_watchfrr}" = "no";then
1281   WATCHFRR=""
1282 else
1283   WATCHFRR="watchfrr"
1284 fi
1285 AM_CONDITIONAL(WATCHFRR, test "x$WATCHFRR" = "xwatchfrr")
1286
1287 OSPFCLIENT=""
1288 if test "${enable_ospfapi}" != "no";then
1289     AC_DEFINE(SUPPORT_OSPF_API,,OSPFAPI)
1290
1291   if test "${enable_ospfclient}" != "no";then
1292       OSPFCLIENT="ospfclient"
1293   fi
1294 fi
1295
1296 AM_CONDITIONAL(OSPFCLIENT, test "x$OSPFCLIENT" = "xospfclient")
1297 AM_CONDITIONAL(RIPNGD, test "${enable_ripngd}" != "no")
1298 AM_CONDITIONAL(BABELD, test "${enable_babeld}" != "no")
1299 AM_CONDITIONAL(OSPF6D, test "${enable_ospf6d}" != "no")
1300 AM_CONDITIONAL(ISISD, test "${enable_isisd}" != "no")
1301
1302 case "${enable_pimd}" in
1303   "no" ) PIMD="";;
1304   *    ) PIMD="pimd";;
1305 esac
1306 AM_CONDITIONAL(PIMD, test "x$PIMD" = "xpimd")
1307
1308 if test "${enable_bgp_announce}" = "no";then
1309   AC_DEFINE(DISABLE_BGP_ANNOUNCE,1,Disable BGP installation to zebra)
1310 else
1311   AC_DEFINE(DISABLE_BGP_ANNOUNCE,0,Disable BGP installation to zebra)
1312 fi
1313
1314 if test "${with_rfp_path}" = "yes" || test x"${with_rfp_path}" = x""; then
1315   with_rfp_path="bgpd/rfp-example"
1316 fi
1317 if test "${with_rfp_path}" != "no"; then
1318   VNC_RFP_PATH="${with_rfp_path}"
1319   AC_SUBST(VNC_RFP_PATH)
1320 fi
1321
1322 if test "${enable_bgp_vnc}" != "no";then
1323   AC_DEFINE(ENABLE_BGP_VNC,1,Enable BGP VNC support)
1324   RFPTEST="${with_rfp_path}/rfptest"
1325   LIBRFP="${with_rfp_path}/librfp"
1326   RFPINC="${with_rfp_path}/librfp"
1327 else
1328   RFPTEST=
1329   LIBRFP=
1330   RFPINC="bgpd/rfp-example/librfp"
1331 fi
1332 # set
1333 AM_CONDITIONAL([ENABLE_BGP_VNC], [test x${enable_bgp_vnc} != xno])
1334
1335 AC_SUBST(DOC)
1336 AC_SUBST(RFPTEST)
1337 AC_SUBST(LIBRFP)
1338 AC_SUBST(RFPINC)
1339 AC_SUBST(BGPD)
1340 AC_SUBST(WATCHFRR)
1341 AC_SUBST(ISISD)
1342 AC_SUBST(PIMD)
1343 AC_SUBST(SOLARIS)
1344 AC_SUBST(VTYSH)
1345 AC_SUBST(CURSES)
1346 AC_CHECK_LIB(crypt, crypt, [],
1347                     [AC_CHECK_LIB(crypto, DES_crypt)])
1348 AC_CHECK_LIB(resolv, res_init)
1349
1350 dnl ---------------------------
1351 dnl check system has PCRE regexp
1352 dnl ---------------------------
1353 if test "x$enable_pcreposix" = "xyes"; then
1354   AC_CHECK_LIB(pcreposix, regexec, [], [
1355     AC_MSG_ERROR([--enable-pcreposix given but unable to find libpcreposix])
1356   ])
1357 fi
1358 AC_SUBST(HAVE_LIBPCREPOSIX)
1359
1360 dnl ------------------
1361 dnl check C-Ares library
1362 dnl ------------------
1363 if test "${NHRPD}" != ""; then
1364   PKG_CHECK_MODULES([CARES], [libcares], , [
1365     AC_MSG_ERROR([trying to build nhrpd, but libcares not found. install c-ares and its -dev headers.])
1366   ])
1367 fi
1368
1369
1370 dnl ------------------
1371 dnl check Net-SNMP library
1372 dnl ------------------
1373 if test "${enable_snmp}" != "" -a "${enable_snmp}" != "no"; then
1374    AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], [no])
1375    if test x"$NETSNMP_CONFIG" = x"no"; then
1376       AC_MSG_ERROR([--enable-snmp given but unable to find net-snmp-config])
1377    fi
1378    SNMP_LIBS="`${NETSNMP_CONFIG} --agent-libs`"
1379    SNMP_CFLAGS="`${NETSNMP_CONFIG} --base-cflags`"
1380    AC_MSG_CHECKING([whether we can link to Net-SNMP])
1381    AC_LINK_IFELSE_FLAGS([$SNMP_CFLAGS], [$SNMP_LIBS], [AC_LANG_PROGRAM([
1382 int main(void);
1383 ],
1384 [
1385 {
1386   return 0;
1387 }
1388 ])], [
1389      AC_MSG_ERROR([--enable-snmp given but not usable])])
1390    case "${enable_snmp}" in
1391      yes)
1392       SNMP_METHOD=agentx
1393       ;;
1394      smux|agentx)
1395       SNMP_METHOD="${enable_snmp}"
1396       ;;
1397      *)
1398       AC_MSG_ERROR([--enable-snmp given with an unknown method (${enable_snmp}). Use smux or agentx])
1399       ;;
1400    esac
1401    AH_TEMPLATE([SNMP_SMUX], [Use SNMP SMUX to interface with snmpd])
1402    AH_TEMPLATE([SNMP_AGENTX], [Use SNMP AgentX to interface with snmpd])
1403    AC_DEFINE_UNQUOTED(AS_TR_CPP(SNMP_${SNMP_METHOD}),,SNMP method to interface with snmpd)
1404 fi
1405 AM_CONDITIONAL([SNMP], [test "x${SNMP_METHOD}" != "x"])
1406 AC_SUBST(SNMP_LIBS)
1407 AC_SUBST(SNMP_CFLAGS)
1408
1409 dnl ---------------
1410 dnl math
1411 dnl ---------------
1412 AC_SEARCH_LIBS([sqrt], [m])
1413
1414 dnl ---------------
1415 dnl dlopen & dlinfo
1416 dnl ---------------
1417 AC_SEARCH_LIBS(dlopen, [dl dld], [], [
1418   AC_MSG_ERROR([unable to find the dlopen()])
1419 ])
1420
1421 AC_CHECK_HEADERS([link.h])
1422
1423 AC_MSG_CHECKING([for dlinfo(RTLD_DI_ORIGIN)])
1424 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1425 #include <stdlib.h>
1426 #ifdef HAVE_LINK_H
1427 #include <link.h>
1428 #endif
1429 #include <dlfcn.h>
1430 ]], [[
1431   char origin[1];
1432   dlinfo (NULL, RTLD_DI_ORIGIN, &origin);
1433 ]])], [
1434   AC_MSG_RESULT(yes)
1435   AC_DEFINE(HAVE_DLINFO_ORIGIN, 1, [Have dlinfo RTLD_DI_ORIGIN])
1436 ], [
1437   AC_MSG_RESULT(no)
1438 ])
1439
1440 AC_MSG_CHECKING([for dlinfo(RTLD_DI_LINKMAP)])
1441 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1442 #include <stdlib.h>
1443 #ifdef HAVE_LINK_H
1444 #include <link.h>
1445 #endif
1446 #include <dlfcn.h>
1447 ]], [[
1448   struct link_map *lm = NULL;
1449   dlinfo (NULL, RTLD_DI_LINKMAP, &lm);
1450 ]])], [
1451   AC_MSG_RESULT(yes)
1452   AC_DEFINE(HAVE_DLINFO_LINKMAP, 1, [Have dlinfo RTLD_DI_LINKMAP])
1453 ], [
1454   AC_MSG_RESULT(no)
1455 ])
1456
1457
1458 AM_CONDITIONAL(SNMP, test "x$SNMP_METHOD" = "xagentx")
1459
1460 dnl ---------------------------
1461 dnl sockaddr and netinet checks
1462 dnl ---------------------------
1463 AC_CHECK_TYPES([
1464         struct sockaddr_dl,
1465         struct vifctl, struct mfcctl, struct sioc_sg_req,
1466         vifi_t, struct sioc_vif_req, struct igmpmsg,
1467         struct ifaliasreq, struct if6_aliasreq, struct in6_aliasreq,
1468         struct nd_opt_adv_interval, struct rt_addrinfo,
1469         struct nd_opt_homeagent_info, struct nd_opt_adv_interval],
1470         [], [], FRR_INCLUDES)
1471
1472 AC_CHECK_MEMBERS([struct sockaddr.sa_len,
1473         struct sockaddr_in.sin_len, struct sockaddr_un.sun_len,
1474         struct sockaddr_dl.sdl_len,
1475         struct if6_aliasreq.ifra_lifetime,
1476         struct nd_opt_adv_interval.nd_opt_ai_type],
1477         [], [], FRR_INCLUDES)
1478
1479 dnl ---------------------------
1480 dnl IRDP/pktinfo/icmphdr checks
1481 dnl ---------------------------
1482
1483 AC_CHECK_TYPES([struct in_pktinfo], [
1484   AC_CHECK_TYPES([struct icmphdr], [
1485     IRDP=true
1486   ], [
1487     IRDP=false
1488   ], [FRR_INCLUDES])
1489 ], [
1490   IRDP=false
1491 ], [FRR_INCLUDES])
1492
1493 case "${enable_irdp}" in
1494 yes)
1495   $IRDP || AC_MSG_ERROR(['IRDP requires in_pktinfo at the moment!'])
1496   ;;
1497 no)
1498   IRDP=false
1499   ;;
1500 esac
1501
1502 AM_CONDITIONAL(IRDP, $IRDP)
1503
1504 dnl -----------------------
1505 dnl checking for IP_PKTINFO
1506 dnl -----------------------
1507 AC_MSG_CHECKING(for IP_PKTINFO)
1508 AC_TRY_COMPILE([#include <netdb.h>], [
1509   int opt = IP_PKTINFO;
1510 ], [
1511   AC_MSG_RESULT(yes)
1512   AC_DEFINE(HAVE_IP_PKTINFO, 1, [Have IP_PKTINFO])
1513 ], [
1514   AC_MSG_RESULT(no)
1515 ])
1516
1517 dnl ---------------------------
1518 dnl checking for IP_RECVDSTADDR
1519 dnl ---------------------------
1520 AC_MSG_CHECKING(for IP_RECVDSTADDR)
1521 AC_TRY_COMPILE([#include <netinet/in.h>], [
1522   int opt = IP_RECVDSTADDR;
1523 ], [
1524   AC_MSG_RESULT(yes)
1525   AC_DEFINE(HAVE_IP_RECVDSTADDR, 1, [Have IP_RECVDSTADDR])
1526 ], [
1527   AC_MSG_RESULT(no)
1528 ])
1529
1530 dnl ----------------------
1531 dnl checking for IP_RECVIF
1532 dnl ----------------------
1533 AC_MSG_CHECKING(for IP_RECVIF)
1534 AC_TRY_COMPILE([#include <netinet/in.h>], [
1535   int opt = IP_RECVIF;
1536 ], [
1537   AC_MSG_RESULT(yes)
1538   AC_DEFINE(HAVE_IP_RECVIF, 1, [Have IP_RECVIF])
1539 ], [
1540   AC_MSG_RESULT(no)
1541 ])
1542
1543 dnl ----------------------
1544 dnl checking for SO_BINDANY
1545 dnl ----------------------
1546 AC_MSG_CHECKING(for SO_BINDANY)
1547 AC_TRY_COMPILE([#include <sys/socket.h>], [
1548   int opt = SO_BINDANY;
1549 ], [
1550   AC_MSG_RESULT(yes)
1551   AC_DEFINE(HAVE_SO_BINDANY, 1, [Have SO_BINDANY])
1552 ], [
1553   AC_MSG_RESULT(no)
1554 ])
1555
1556 dnl ----------------------
1557 dnl checking for IP_FREEBIND
1558 dnl ----------------------
1559 AC_MSG_CHECKING(for IP_FREEBIND)
1560 AC_TRY_COMPILE([#include <netinet/in.h>], [
1561   int opt = IP_FREEBIND;
1562 ], [
1563   AC_MSG_RESULT(yes)
1564   AC_DEFINE(HAVE_IP_FREEBIND, 1, [Have IP_FREEBIND])
1565 ], [
1566   AC_MSG_RESULT(no)
1567 ])
1568
1569 dnl --------------------------------------
1570 dnl checking for be32dec existence or not
1571 dnl --------------------------------------
1572 AC_CHECK_DECLS([be32enc, be32dec], [], [],
1573                [#include <sys/endian.h>])
1574
1575 dnl --------------------------------------
1576 dnl checking for clock_time monotonic struct and call
1577 dnl --------------------------------------
1578 AC_CHECK_DECL(CLOCK_MONOTONIC,
1579         [AC_CHECK_LIB(rt, clock_gettime, [LIBS="$LIBS -lrt"])
1580          AC_DEFINE(HAVE_CLOCK_MONOTONIC,, Have monotonic clock)
1581 ], [AC_MSG_RESULT(no)], [FRR_INCLUDES])
1582
1583 dnl --------------------------------------
1584 dnl checking for flex and bison
1585 dnl --------------------------------------
1586
1587 AM_PROG_LEX
1588 AC_MSG_CHECKING(version of flex)
1589 frr_ac_flex_version="$(eval $LEX -V | grep flex | head -n 1)"
1590 frr_ac_flex_version="${frr_ac_flex_version##* }"
1591 AC_MSG_RESULT([$frr_ac_flex_version])
1592 AX_COMPARE_VERSION([$frr_ac_flex_version], [lt], [2.5.20], [
1593   LEX="$SHELL $missing_dir/missing flex"
1594   if test -f "${srcdir}/lib/command_lex.c" -a -f "${srcdir}/lib/command_lex.h"; then
1595     AC_MSG_WARN([using pregenerated flex output files])
1596   else
1597     AC_MSG_ERROR([flex failure and pregenerated files not included (probably a git build)])
1598   fi
1599   AC_SUBST([LEX_OUTPUT_ROOT], [lex.yy])
1600   AC_SUBST([LEXLIB], [''])
1601 ])
1602
1603 AC_PROG_YACC
1604 dnl thanks GNU bison for this b*llshit...
1605 AC_MSG_CHECKING(version of bison)
1606 frr_ac_bison_version="$(eval $YACC -V | grep bison | head -n 1)"
1607 frr_ac_bison_version="${frr_ac_bison_version##* }"
1608 frr_ac_bison_missing="false"
1609 case "x${frr_ac_bison_version}" in
1610   x2.7*)
1611     BISON_OPENBRACE='"'
1612     BISON_CLOSEBRACE='"'
1613     BISON_VERBOSE=''
1614     AC_MSG_RESULT([$frr_ac_bison_version - 2.7 or older])
1615     ;;
1616   x2.*|x1.*)
1617     AC_MSG_RESULT([$frr_ac_bison_version])
1618     AC_MSG_WARN([installed bison is too old.  Please install GNU bison 2.7.x or newer.])
1619     frr_ac_bison_missing="true"
1620     ;;
1621   x)
1622     AC_MSG_RESULT([none])
1623     AC_MSG_WARN([could not determine bison version.  Please install GNU bison 2.7.x or newer.])
1624     frr_ac_bison_missing="true"
1625     ;;
1626   *)
1627     BISON_OPENBRACE='{'
1628     BISON_CLOSEBRACE='}'
1629     BISON_VERBOSE='-Dparse.error=verbose'
1630     AC_MSG_RESULT([$frr_ac_bison_version - 3.0 or newer])
1631     ;;
1632 esac
1633 AC_SUBST(BISON_OPENBRACE)
1634 AC_SUBST(BISON_CLOSEBRACE)
1635 AC_SUBST(BISON_VERBOSE)
1636
1637 if $frr_ac_bison_missing; then
1638   YACC="$SHELL $missing_dir/missing bison -y"
1639   if test -f "${srcdir}/lib/command_parse.c" -a -f "${srcdir}/lib/command_parse.h"; then
1640     AC_MSG_WARN([using pregenerated bison output files])
1641   else
1642     AC_MSG_ERROR([bison failure and pregenerated files not included (probably a git build)])
1643   fi
1644 fi
1645
1646 dnl -------------------
1647 dnl capabilities checks
1648 dnl -------------------
1649 if test "${enable_capabilities}" != "no"; then
1650   AC_MSG_CHECKING(whether prctl PR_SET_KEEPCAPS is available)
1651   AC_TRY_COMPILE([#include <sys/prctl.h>],[prctl(PR_SET_KEEPCAPS, 1, 0, 0, 0);],
1652     [AC_MSG_RESULT(yes)
1653      AC_DEFINE(HAVE_PR_SET_KEEPCAPS,,prctl)
1654      frr_ac_keepcaps="yes"],
1655      AC_MSG_RESULT(no)
1656   )
1657   if test x"${frr_ac_keepcaps}" = x"yes"; then
1658     AC_CHECK_HEADERS(sys/capability.h)
1659   fi
1660   if test x"${ac_cv_header_sys_capability_h}" = x"yes"; then
1661     AC_CHECK_LIB(cap, cap_init,
1662       [AC_DEFINE(HAVE_LCAPS,1,Capabilities)
1663        LIBCAP="-lcap"
1664        frr_ac_lcaps="yes"]
1665     )
1666   else
1667     AC_CHECK_HEADERS(priv.h,
1668      [AC_MSG_CHECKING(Solaris style privileges are available)
1669       AC_TRY_COMPILE([#include <priv.h>],[getpflags(PRIV_AWARE);],
1670           [AC_MSG_RESULT(yes)
1671            AC_DEFINE(HAVE_SOLARIS_CAPABILITIES,1,getpflags)
1672            frr_ac_scaps="yes"],
1673            AC_MSG_RESULT(no)
1674       )
1675      ]
1676    )
1677   fi
1678   if test x"${frr_ac_scaps}" = x"yes" \
1679        -o x"${frr_ac_lcaps}" = x"yes"; then
1680     AC_DEFINE(HAVE_CAPABILITIES,1,capabilities)
1681   fi
1682 fi
1683 AC_SUBST(LIBCAP)
1684
1685 dnl ---------------------------
1686 dnl check for glibc 'backtrace'
1687 dnl ---------------------------
1688 if test x"${enable_backtrace}" != x"no" ; then
1689   backtrace_ok=no
1690   AC_CHECK_HEADER([execinfo.h], [
1691     AC_SEARCH_LIBS([backtrace], [execinfo], [
1692       AC_DEFINE(HAVE_GLIBC_BACKTRACE,,[Glibc backtrace])
1693       AC_DEFINE(HAVE_STACK_TRACE,,[Stack symbol decoding])
1694       backtrace_ok=yes
1695     ],, [-lm])
1696   ])
1697
1698   if test x"${enable_backtrace}" = x"yes" -a x"${backtrace_ok}" = x"no"; then
1699     dnl user explicitly requested backtrace but we failed to find support
1700     AC_MSG_FAILURE([failed to find backtrace support])
1701   fi
1702 fi
1703
1704 dnl -----------------------------------------
1705 dnl check for malloc mallinfo struct and call
1706 dnl this must try and link using LIBS, in
1707 dnl order to check no alternative allocator
1708 dnl has been specified, which might not provide
1709 dnl mallinfo, e.g. such as Umem on Solaris.
1710 dnl -----------------------------------------
1711 AC_CHECK_HEADER([malloc.h],
1712  [AC_MSG_CHECKING(whether mallinfo is available)
1713   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <malloc.h>]],
1714                         [[struct mallinfo ac_x; ac_x = mallinfo ();]])],
1715       [AC_MSG_RESULT(yes)
1716        AC_DEFINE(HAVE_MALLINFO,,mallinfo)],
1717        AC_MSG_RESULT(no)
1718   )
1719  ], [], FRR_INCLUDES)
1720
1721 dnl ------
1722 dnl ZeroMQ
1723 dnl ------
1724 if test "x$enable_zeromq" != "xno"; then
1725   PKG_CHECK_MODULES(ZEROMQ, [libzmq >= 4.0.0], [
1726     AC_DEFINE(HAVE_ZEROMQ, 1, [Enable ZeroMQ support])
1727     ZEROMQ=true
1728   ], [
1729     if test "x$enable_zeromq" = "xyes"; then
1730       AC_MSG_ERROR([configuration specifies --enable-zeromq but libzmq was not found])
1731     fi
1732   ])
1733 fi
1734 AM_CONDITIONAL([ZEROMQ], test "x$ZEROMQ" = "xtrue")
1735
1736 dnl ----------
1737 dnl configure date
1738 dnl ----------
1739 CONFDATE=`date '+%Y%m%d'`
1740 AC_SUBST(CONFDATE)
1741
1742 dnl ------------------------------
1743 dnl set paths for state directory
1744 dnl ------------------------------
1745 AC_MSG_CHECKING(directory to use for state file)
1746 if test "${prefix}" = "NONE"; then
1747   frr_statedir_prefix="";
1748 else
1749   frr_statedir_prefix=${prefix}
1750 fi
1751 if test "${localstatedir}" = '${prefix}/var'; then
1752   for FRR_STATE_DIR in ${frr_statedir_prefix}/var/run dnl
1753                         ${frr_statedir_prefix}/var/adm dnl
1754                         ${frr_statedir_prefix}/etc dnl
1755                         /var/run        dnl
1756                         /var/adm        dnl
1757                         /etc            dnl
1758                         /dev/null;
1759   do
1760     test -d $FRR_STATE_DIR && break
1761   done
1762   frr_statedir=$FRR_STATE_DIR
1763 else
1764   frr_statedir=${localstatedir}
1765 fi
1766 if test $frr_statedir = "/dev/null"; then
1767     AC_MSG_ERROR('STATE DIRECTORY NOT FOUND! FIX OR SPECIFY --localstatedir!')
1768 fi
1769 AC_MSG_RESULT(${frr_statedir})
1770 AC_SUBST(frr_statedir)
1771
1772 AC_DEFINE_UNQUOTED(LDPD_SOCKET, "$frr_statedir/ldpd.sock",ldpd control socket)
1773 AC_DEFINE_UNQUOTED(ZEBRA_SERV_PATH, "$frr_statedir/zserv.api",zebra api socket)
1774 AC_DEFINE_UNQUOTED(DAEMON_VTY_DIR, "$frr_statedir",daemon vty directory)
1775
1776 dnl autoconf does this, but it does it too late...
1777 test "x$prefix" = xNONE && prefix=$ac_default_prefix
1778 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
1779
1780 dnl get the full path, recursing through variables...
1781 vtysh_bin="$bindir/vtysh"
1782 for I in 1 2 3 4 5 6 7 8 9 10; do
1783         eval vtysh_bin="\"$vtysh_bin\""
1784 done
1785 AC_DEFINE_UNQUOTED(VTYSH_BIN_PATH, "$vtysh_bin",path to vtysh binary)
1786
1787 CFG_SYSCONF="$sysconfdir"
1788 CFG_SBIN="$sbindir"
1789 CFG_STATE="$frr_statedir"
1790 CFG_MODULE="$moduledir"
1791 for I in 1 2 3 4 5 6 7 8 9 10; do
1792         eval CFG_SYSCONF="\"$CFG_SYSCONF\""
1793         eval CFG_SBIN="\"$CFG_SBIN\""
1794         eval CFG_STATE="\"$CFG_STATE\""
1795         eval CFG_MODULE="\"$CFG_MODULE\""
1796 done
1797 AC_SUBST(CFG_SYSCONF)
1798 AC_SUBST(CFG_SBIN)
1799 AC_SUBST(CFG_STATE)
1800 AC_SUBST(CFG_MODULE)
1801 AC_DEFINE_UNQUOTED(MODULE_PATH, "$CFG_MODULE", path to modules)
1802
1803 dnl ---------------------------
1804 dnl Check htonl works correctly
1805 dnl ---------------------------
1806 AC_MSG_CHECKING(for working htonl)
1807 AC_CACHE_VAL(ac_cv_htonl_works,
1808  [AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES],[htonl (0);])],
1809                 [ac_cv_htonl_works=yes], [ac_cv_htonl_works=no])
1810  ]
1811 )
1812 AC_MSG_RESULT($ac_cv_htonl_works)
1813
1814 AC_CONFIG_FILES([Makefile
1815           bgpd/Makefile watchfrr/Makefile
1816           vtysh/Makefile
1817           doc/Makefile tests/Makefile
1818           bgpd/rfp-example/rfptest/Makefile bgpd/rfp-example/librfp/Makefile
1819           pimd/Makefile
1820           tools/Makefile
1821           redhat/frr.spec
1822           snapcraft/snapcraft.yaml
1823           lib/version.h
1824           tests/lib/cli/test_cli.refout
1825           doc/defines.texi
1826           doc/bgpd.8
1827           doc/isisd.8
1828           doc/ospf6d.8
1829           doc/ospfclient.8
1830           doc/ospfd.8
1831           doc/ldpd.8
1832           doc/ripd.8
1833           doc/eigrpd.8
1834           doc/ripngd.8
1835           doc/pimd.8
1836           doc/nhrpd.8
1837           doc/vtysh.1
1838           doc/watchfrr.8
1839           doc/zebra.8
1840           doc/frr.1
1841           doc/frr-args.8
1842           pkgsrc/bgpd.sh pkgsrc/ospf6d.sh pkgsrc/ospfd.sh
1843           pkgsrc/ripd.sh pkgsrc/ripngd.sh pkgsrc/zebra.sh
1844           pkgsrc/eigrpd.sh])
1845
1846 if test "${enable_bgp_vnc}" != "no"; then
1847    if test "${with_rfp_path}" != "bgpd/rfp-example" ; then
1848       AC_CONFIG_FILES([${with_rfp_path}/rfptest/Makefile ${with_rfp_path}/librfp/Makefile])
1849    fi
1850 fi
1851
1852 AC_CONFIG_FILES([solaris/Makefile])
1853
1854 AC_CONFIG_FILES([vtysh/extract.pl],[chmod +x vtysh/extract.pl])
1855
1856 AC_CONFIG_COMMANDS([lib/route_types.h], [
1857         dst="${ac_abs_top_builddir}/lib/route_types.h"
1858         ${PERL} "${ac_abs_top_srcdir}/lib/route_types.pl" \
1859                 < "${ac_abs_top_srcdir}/lib/route_types.txt" \
1860                 > "${dst}.tmp"
1861         test -f "${dst}" \
1862                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
1863                 && rm "${dst}.tmp" \
1864                 || mv "${dst}.tmp" "${dst}"
1865 ], [
1866         PERL="$PERL"
1867 ])
1868
1869 AS_IF([test "x$with_pkg_git_version" = "xyes"], [
1870     AC_CONFIG_COMMANDS([lib/gitversion.h], [
1871         dst="${ac_abs_top_builddir}/lib/gitversion.h"
1872         ${PERL} "${ac_abs_top_srcdir}/lib/gitversion.pl" \
1873                 "${ac_abs_top_srcdir}" \
1874                 > "${dst}.tmp"
1875         test -f "${dst}" \
1876                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
1877                 && rm "${dst}.tmp" \
1878                 || mv "${dst}.tmp" "${dst}"
1879     ], [
1880         PERL="$PERL"
1881     ])
1882 ])
1883
1884 ## Hack, but working solution to avoid rebuilding of frr.info.
1885 ## It's already in CVS until texinfo 4.7 is more common.
1886 AC_OUTPUT
1887
1888 echo "
1889 FRRouting configuration
1890 ------------------------------
1891 FRR version             : ${PACKAGE_VERSION}
1892 host operating system   : ${host_os}
1893 source code location    : ${srcdir}
1894 compiler                : ${CC}
1895 compiler flags          : ${CFLAGS}
1896 make                    : ${MAKE-make}
1897 linker flags            : ${LDFLAGS} ${LIBS} ${LIBCAP} ${LIBREADLINE} ${LIBM}
1898 state file directory    : ${frr_statedir}
1899 config file directory   : `eval echo \`echo ${sysconfdir}\``
1900 example directory       : `eval echo \`echo ${exampledir}\``
1901 module directory        : ${CFG_MODULE}
1902 user to run as          : ${enable_user}
1903 group to run as         : ${enable_group}
1904 group for vty sockets   : ${enable_vty_group}
1905 config file mask        : ${enable_configfile_mask}
1906 log file mask           : ${enable_logfile_mask}
1907 zebra protobuf enabled  : ${have_protobuf:-no}
1908
1909 The above user and group must have read/write access to the state file
1910 directory and to the config files in the config file directory."