configure.ac

   1 ##
   2 ## Configure template file for FRRouting.
   3 ## autoconf will generate configure script.
   4 ##
   5 ##  Copyright (c) 1996, 97, 98, 99, 2000 Kunihiro Ishiguro <kunihiro@zebra.org>
   6 ##  Portions Copyright (c) 2003 Paul Jakma <paul@dishone.st>
   7 ##
   8 AC_PREREQ(2.60)
   9
  10 AC_INIT(frr, 6.1-dev, [https://github.com/frrouting/frr/issues])
  11 PACKAGE_URL="https://frrouting.org/"
  12 AC_SUBST(PACKAGE_URL)
  13 PACKAGE_FULLNAME="FRRouting"
  14 AC_SUBST(PACKAGE_FULLNAME)
  15
  16 CONFIG_ARGS="$ac_configure_args"
  17 AC_SUBST(CONFIG_ARGS)
  18
  19 AC_CONFIG_SRCDIR(lib/zebra.h)
  20 AC_CONFIG_MACRO_DIR([m4])
  21
  22 dnl -----------------------------------
  23 dnl Get hostname and other information.
  24 dnl -----------------------------------
  25 AC_CANONICAL_BUILD()
  26 AC_CANONICAL_HOST()
  27
  28 AS_IF([test "$host" != "$build"], [
  29   if test "$srcdir" = "."; then
  30     AC_MSG_ERROR([cross-compilation is only possible with builddir separate from srcdir.  create a separate directory and run as .../path-to-frr/configure.])
  31   fi
  32   test -d hosttools || mkdir hosttools
  33   abssrc="`cd \"${srcdir}\"; pwd`"
  34
  35   AC_MSG_NOTICE([...])
  36   AC_MSG_NOTICE([... cross-compilation: creating hosttools directory and self-configuring for build platform tools])
  37   AC_MSG_NOTICE([... use HOST_CPPFLAGS / HOST_CFLAGS / HOST_LDFLAGS if neccessary])
  38   AC_MSG_NOTICE([...])
  39
  40   ( CPPFLAGS="$HOST_CPPFLAGS"; \
  41     CFLAGS="$HOST_CFLAGS"; \
  42     LDFLAGS="$HOST_LDFLAGS"; \
  43     cd hosttools; "${abssrc}/configure" "--host=$build" "--build=$build" "--enable-clippy-only" "--disable-nhrpd" "--disable-vtysh"; )
  44
  45   AC_MSG_NOTICE([...])
  46   AC_MSG_NOTICE([... cross-compilation: finished self-configuring for build platform tools])
  47   AC_MSG_NOTICE([...])
  48
  49   build_clippy="false"
  50   HOSTTOOLS="hosttools/"
  51 ], [
  52   build_clippy="true"
  53   HOSTTOOLS=""
  54 ])
  55 AC_SUBST(HOSTTOOLS)
  56 AM_CONDITIONAL([BUILD_CLIPPY], [$build_clippy])
  57
  58 # Disable portability warnings -- our automake code (in particular
  59 # common.am) uses some constructs specific to gmake.
  60 AM_INIT_AUTOMAKE([1.12 -Wno-portability foreign])
  61 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
  62 AM_SILENT_RULES([yes])
  63 AC_CONFIG_HEADERS(config.h)
  64
  65 AC_PATH_PROG(PERL, perl)
  66 PKG_PROG_PKG_CONFIG
  67
  68 dnl default is to match previous behavior
  69 exampledir=${sysconfdir}
  70 AC_ARG_ENABLE([exampledir],
  71           AS_HELP_STRING([--enable-exampledir],
  72                          [specify alternate directory for examples]),
  73                          exampledir="$enableval",)
  74 dnl XXX add --exampledir to autoconf standard directory list somehow
  75 AC_SUBST(exampledir)
  76
  77 dnl default is to match previous behavior
  78 pkgsrcrcdir=""
  79 AC_ARG_ENABLE([pkgsrcrcdir],
  80           AS_HELP_STRING([--enable-pkgsrcrcdir],
  81                          [specify directory for rc.d scripts]),
  82                          pkgsrcrcdir="$enableval",)
  83 dnl XXX add --pkgsrcrcdir to autoconf standard directory list somehow
  84 AC_SUBST(pkgsrcrcdir)
  85 AM_CONDITIONAL([PKGSRC], [test "x$pkgsrcrcdir" != "x"])
  86
  87 AC_ARG_WITH([moduledir], [AS_HELP_STRING([--with-moduledir=DIR], [module directory (${libdir}/frr/modules)])], [
  88         moduledir="$withval"
  89 ], [
  90         moduledir="\${libdir}/frr/modules"
  91 ])
  92 AC_SUBST([moduledir], [$moduledir])
  93
  94 AC_ARG_ENABLE(tcmalloc,
  95         AS_HELP_STRING([--enable-tcmalloc], [Turn on tcmalloc]),
  96 [case "${enableval}" in
  97   yes) tcmalloc_enabled=true
  98 LIBS="$LIBS -ltcmalloc_minimal"
  99  ;;
 100   no)  tcmalloc_enabled=false ;;
 101   *) AC_MSG_ERROR(bad value ${enableval} for --enable-tcmalloc) ;;
 102 esac],[tcmalloc_enabled=false])
 103
 104
 105 dnl Thanks autoconf, but we don't want a default -g -O2.  We have our own
 106 dnl flag determination logic.
 107 CFLAGS="${CFLAGS:-}"
 108
 109 dnl --------------------
 110 dnl Check CC and friends
 111 dnl --------------------
 112 dnl note orig_cflags is also used further down
 113 orig_cflags="$CFLAGS"
 114 AC_LANG([C])
 115 AC_PROG_CC
 116 AC_PROG_CPP
 117 AM_PROG_CC_C_O
 118 dnl remove autoconf default "-g -O2"
 119 CFLAGS="$orig_cflags"
 120 AC_PROG_CC_C99
 121 dnl NB: see C11 below
 122
 123 AC_PROG_EGREP
 124 PKG_PROG_PKG_CONFIG
 125
 126 dnl autoconf 2.59 appears not to support AC_PROG_SED
 127 dnl AC_PROG_SED
 128 AC_CHECK_PROG([SED],[sed],[sed],[/bin/false])
 129
 130 dnl try and enable CFLAGS that are useful for FRR
 131 dnl - specifically, options to control warnings
 132
 133 AC_USE_SYSTEM_EXTENSIONS
 134 AC_DEFUN([AC_C_FLAG], [{
 135     m4_pushdef([cachename],[m4_translit([frr_cv_$1],[ =-],[___])])
 136     AC_CACHE_CHECK([[whether $CC supports $1]], cachename, [
 137         AC_LANG_PUSH(C)
 138         ac_c_flag_save="$CFLAGS"
 139         CFLAGS="$CFLAGS $1"
 140         AC_COMPILE_IFELSE(
 141                 [AC_LANG_PROGRAM([[]])],
 142                 [
 143                         cachename=yes
 144                 ], [
 145                         cachename=no
 146                 ])
 147         CFLAGS="$ac_c_flag_save"
 148         AC_LANG_POP(C)
 149     ])
 150     if test "${cachename}" = yes; then
 151         m4_if([$3], [], [CFLAGS="$CFLAGS $1"], [$3])
 152     else
 153         :
 154         $2
 155     fi
 156     m4_popdef([cachename])
 157 }])
 158
 159 AC_DEFUN([AC_LINK_IFELSE_FLAGS], [{
 160         AC_LANG_PUSH(C)
 161         ac_cflags_save="$CFLAGS"
 162         ac_libs_save="$LIBS"
 163         CFLAGS="$CFLAGS $1"
 164         LIBS="$LIBS $2"
 165         AC_LINK_IFELSE(
 166                 [$3],
 167                 [
 168                         AC_MSG_RESULT([yes])
 169                         CFLAGS="$ac_cflags_save"
 170                         LIBS="$ac_libs_save"
 171                         $5
 172                 ], [
 173                         AC_MSG_RESULT([no])
 174                         CFLAGS="$ac_cflags_save"
 175                         LIBS="$ac_libs_save"
 176                         $4
 177                 ])
 178         AC_LANG_POP(C)
 179         }])
 180
 181 dnl ICC won't bail on unknown options without -diag-error 10006
 182 dnl need to do this first so we get useful results for the other options
 183 AC_C_FLAG([-diag-error 10006])
 184
 185 dnl AC_PROG_CC_C99 may change CC to include -std=gnu99 or something
 186 ac_cc="$CC"
 187 CC="${CC% -std=gnu99}"
 188 CC="${CC% -std=c99}"
 189
 190 AC_C_FLAG([-std=gnu11], [CC="$ac_cc"], [CC="$CC -std=gnu11"])
 191
 192 dnl if the user has specified any CFLAGS, override our settings
 193 if test "x${enable_gcov}" = "xyes"; then
 194    if test "z$orig_cflags" = "z"; then
 195       AC_C_FLAG([-coverage])
 196       AC_C_FLAG([-O0])
 197    fi
 198
 199    LDFLAGS="${LDFLAGS} -lgcov"
 200 elif test "x${enable_dev_build}" = "xyes"; then
 201    AC_DEFINE(DEV_BUILD,,Build for development)
 202    if test "z$orig_cflags" = "z"; then
 203       AC_C_FLAG([-g3])
 204       AC_C_FLAG([-O0])
 205    fi
 206    if test "x${enable_lua}" = "xyes"; then
 207       AC_CHECK_LIB([lua], [lua_newstate],
 208       [LIBS="$LIBS -llua"])
 209       AC_DEFINE(HAVE_LUA,,Lua enabled for development)
 210    fi
 211 else
 212    if test "x${enable_lua}" = "xyes"; then
 213       AC_MSG_ERROR([Lua is not meant to be built/used outside of development at this time])
 214    fi
 215    if test "z$orig_cflags" = "z"; then
 216       AC_C_FLAG([-g])
 217       AC_C_FLAG([-Os], [
 218         AC_C_FLAG([-O2])
 219       ])
 220    fi
 221 fi
 222 AM_CONDITIONAL([DEV_BUILD], [test "x$enable_dev_build" = "xyes"])
 223
 224 dnl always want these CFLAGS
 225 AC_C_FLAG([-fno-omit-frame-pointer])
 226 AC_C_FLAG([-funwind-tables])
 227 AC_C_FLAG([-Wall])
 228 AC_C_FLAG([-Wextra])
 229 AC_C_FLAG([-Wmissing-prototypes])
 230 AC_C_FLAG([-Wmissing-declarations])
 231 AC_C_FLAG([-Wpointer-arith])
 232 AC_C_FLAG([-Wbad-function-cast])
 233 AC_C_FLAG([-Wwrite-strings])
 234 if test x"${enable_gcc_ultra_verbose}" = x"yes" ; then
 235   AC_C_FLAG([-Wcast-qual])
 236   AC_C_FLAG([-Wstrict-prototypes])
 237   AC_C_FLAG([-Wmissing-noreturn])
 238   AC_C_FLAG([-Wmissing-format-attribute])
 239   AC_C_FLAG([-Wunreachable-code])
 240   AC_C_FLAG([-Wpacked])
 241   AC_C_FLAG([-Wpadded])
 242   AC_C_FLAG([-Wshadow])
 243 else
 244   AC_C_FLAG([-Wno-unused-result])
 245 fi
 246 AC_C_FLAG([-Wno-unused-parameter])
 247 AC_C_FLAG([-Wno-missing-field-initializers])
 248
 249 dnl ICC emits a broken warning for const char *x = a ? "b" : "c";
 250 dnl for some reason the string consts get 'promoted' to char *,
 251 dnl triggering a const to non-const conversion warning.
 252 AC_C_FLAG([-diag-disable 3179])
 253
 254 if test x"${enable_werror}" = x"yes" ; then
 255   WERROR="-Werror"
 256 fi
 257 AC_SUBST(WERROR)
 258
 259 SAN_FLAGS=""
 260 if test "$enable_address_sanitizer" = "yes"; then
 261   AC_C_FLAG([-fsanitize=address], [
 262     AC_MSG_ERROR([$CC does not support Address Sanitizer.])
 263   ], [
 264     SAN_FLAGS="$SAN_FLAGS -fsanitize=address"
 265   ])
 266 fi
 267 if test "$enable_thread_sanitizer" = "yes"; then
 268   AC_C_FLAG([-fsanitize=thread], [
 269     AC_MSG_ERROR([$CC does not support Thread Sanitizer.])
 270   ], [
 271     SAN_FLAGS="$SAN_FLAGS -fsanitize=thread"
 272   ])
 273 fi
 274 if test "$enable_memory_sanitizer" = "yes"; then
 275   AC_C_FLAG([-fsanitize=thread -fPIE -pie], [
 276     AC_MSG_ERROR([$CC does not support Thread Sanitizer.])
 277   ], [
 278     SAN_FLAGS="-fsanitize=memory -fPIE -pie"
 279   ])
 280 fi
 281 AC_SUBST([SAN_FLAGS])
 282
 283 dnl ----------
 284 dnl Essentials
 285 dnl ----------
 286
 287 AX_PTHREAD([
 288   CC="$PTHREAD_CC"
 289   CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 290   LIBS="$PTHREAD_LIBS $LIBS"
 291 ], [
 292   AC_MSG_FAILURE([This FRR version needs pthreads])
 293 ])
 294
 295 AC_SEARCH_LIBS([pthread_condattr_setclock], [],
 296                 [frr_cv_pthread_condattr_setclock=yes],
 297                 [frr_cv_pthread_condattr_setclock=no])
 298 if test "$frr_cv_pthread_condattr_setclock" = yes; then
 299   AC_DEFINE(HAVE_PTHREAD_CONDATTR_SETCLOCK, 1, [Have pthread.h pthread_condattr_setclock])
 300 fi
 301
 302 dnl --------------
 303 dnl Check programs
 304 dnl --------------
 305 AC_PROG_INSTALL
 306 AC_PROG_LN_S
 307 AC_PROG_MAKE_SET
 308 AC_CHECK_TOOL(AR, ar)
 309
 310 dnl -------
 311 dnl libtool
 312 dnl -------
 313 AC_ARG_ENABLE(static-bin,
 314   AS_HELP_STRING([--enable-static-bin], [link binaries statically]))
 315 LT_INIT
 316 _LT_CONFIG_LIBTOOL([
 317   patch -N -i "${srcdir}/m4/libtool-whole-archive.patch" libtool >&AS_MESSAGE_LOG_FD || \
 318     AC_MSG_WARN([Could not patch libtool for static linking support.  Loading modules into a statically linked daemon will fail.])
 319 ])
 320 if test "$enable_static_bin" = "yes"; then
 321   AC_LDFLAGS="-static"
 322 fi
 323 AC_SUBST(AC_LDFLAGS)
 324 AM_CONDITIONAL([STATIC_BIN], [test "x$enable_static_bin" = "xyes"])
 325
 326 dnl ----------------------
 327 dnl Packages configuration
 328 dnl ----------------------
 329 AC_ARG_WITH(pkg-extra-version,
 330         AS_HELP_STRING([--with-pkg-extra-version=VER], [add extra version field, for packagers/distributions]),
 331         [EXTRAVERSION=$withval],)
 332 AC_ARG_WITH(pkg-git-version,
 333         AS_HELP_STRING([--with-pkg-git-version], [add git information to MOTD and build version string]),
 334         [ test "x$withval" != "xno" && with_pkg_git_version="yes" ])
 335 AC_ARG_WITH(vtysh_pager,
 336         AS_HELP_STRING([--with-vtysh-pager=PAGER], [control what pager is compiled in as default]),
 337         VTYSH_PAGER=$withval, VTYSH_PAGER="more")
 338 AC_ARG_ENABLE(vtysh,
 339   AS_HELP_STRING([--disable-vtysh], [do not build integrated vty shell for FRR]))
 340 AC_ARG_ENABLE(doc,
 341   AS_HELP_STRING([--disable-doc], [do not build docs]))
 342 AC_ARG_ENABLE(doc-html,
 343   AS_HELP_STRING([--enable-doc-html], [build HTML docs]))
 344 AC_ARG_ENABLE(zebra,
 345   AS_HELP_STRING([--disable-zebra], [do not build zebra daemon]))
 346 AC_ARG_ENABLE(bgpd,
 347   AS_HELP_STRING([--disable-bgpd], [do not build bgpd]))
 348 AC_ARG_ENABLE(ripd,
 349   AS_HELP_STRING([--disable-ripd], [do not build ripd]))
 350 AC_ARG_ENABLE(ripngd,
 351   AS_HELP_STRING([--disable-ripngd], [do not build ripngd]))
 352 AC_ARG_ENABLE(ospfd,
 353   AS_HELP_STRING([--disable-ospfd], [do not build ospfd]))
 354 AC_ARG_ENABLE(ospf6d,
 355   AS_HELP_STRING([--disable-ospf6d], [do not build ospf6d]))
 356 AC_ARG_ENABLE(ldpd,
 357   AS_HELP_STRING([--disable-ldpd], [do not build ldpd]))
 358 AC_ARG_ENABLE(nhrpd,
 359   AS_HELP_STRING([--disable-nhrpd], [do not build nhrpd]))
 360 AC_ARG_ENABLE(eigrpd,
 361   AS_HELP_STRING([--disable-eigrpd], [do not build eigrpd]))
 362 AC_ARG_ENABLE(babeld,
 363   AS_HELP_STRING([--disable-babeld], [do not build babeld]))
 364 AC_ARG_ENABLE(watchfrr,
 365   AS_HELP_STRING([--disable-watchfrr], [do not build watchfrr]))
 366 AC_ARG_ENABLE(isisd,
 367   AS_HELP_STRING([--disable-isisd], [do not build isisd]))
 368 AC_ARG_ENABLE(pimd,
 369   AS_HELP_STRING([--disable-pimd], [do not build pimd]))
 370 AC_ARG_ENABLE(pbrd,
 371   AS_HELP_STRING([--disable-pbrd], [do not build pbrd]))
 372 AC_ARG_ENABLE(sharpd,
 373   AS_HELP_STRING([--enable-sharpd], [build sharpd]))
 374 AC_ARG_ENABLE(staticd,
 375   AS_HELP_STRING([--disable-staticd], [do not build staticd]))
 376 AC_ARG_ENABLE(fabricd,
 377   AS_HELP_STRING([--disable-fabricd], [do not build fabricd]))
 378 AC_ARG_ENABLE(bgp-announce,
 379   AS_HELP_STRING([--disable-bgp-announce,], [turn off BGP route announcement]))
 380 AC_ARG_ENABLE(bgp-vnc,
 381   AS_HELP_STRING([--disable-bgp-vnc],[turn off BGP VNC support]))
 382 AC_ARG_ENABLE(snmp,
 383   AS_HELP_STRING([--enable-snmp], [enable SNMP support for agentx]))
 384 AC_ARG_ENABLE(zeromq,
 385   AS_HELP_STRING([--enable-zeromq], [enable ZeroMQ handler (libfrrzmq)]))
 386 AC_ARG_WITH(libpam,
 387   AS_HELP_STRING([--with-libpam], [use libpam for PAM support in vtysh]))
 388 AC_ARG_ENABLE(ospfapi,
 389   AS_HELP_STRING([--disable-ospfapi], [do not build OSPFAPI to access the OSPF LSA Database]))
 390 AC_ARG_ENABLE(ospfclient,
 391   AS_HELP_STRING([--disable-ospfclient], [do not build OSPFAPI client for OSPFAPI,
 392                           (this is the default if --disable-ospfapi is set)]))
 393 AC_ARG_ENABLE(multipath,
 394   AS_HELP_STRING([--enable-multipath=ARG], [enable multipath function, ARG must be digit]))
 395 AC_ARG_ENABLE(user,
 396   AS_HELP_STRING([--enable-user=USER], [user to run FRR suite as (default frr)]))
 397 AC_ARG_ENABLE(group,
 398   AS_HELP_STRING([--enable-group=GROUP], [group to run FRR suite as (default frr)]))
 399 AC_ARG_ENABLE(vty_group,
 400   AS_HELP_STRING([--enable-vty-group=ARG], [set vty sockets to have specified group as owner]))
 401 AC_ARG_ENABLE(configfile_mask,
 402   AS_HELP_STRING([--enable-configfile-mask=ARG], [set mask for config files]))
 403 AC_ARG_ENABLE(logfile_mask,
 404   AS_HELP_STRING([--enable-logfile-mask=ARG], [set mask for log files]))
 405 AC_ARG_ENABLE(shell_access,
 406   AS_HELP_STRING([--enable-shell-access], [Allow users to access shell/telnet/ssh]))
 407 AC_ARG_ENABLE(realms,
 408   AS_HELP_STRING([--enable-realms], [enable REALMS support under Linux]))
 409 AC_ARG_ENABLE(rtadv,
 410   AS_HELP_STRING([--disable-rtadv], [disable IPV6 router advertisement feature]))
 411 AC_ARG_ENABLE(irdp,
 412   AS_HELP_STRING([--disable-irdp], [enable IRDP server support in zebra (default if supported)]))
 413 AC_ARG_ENABLE(capabilities,
 414   AS_HELP_STRING([--disable-capabilities], [disable using POSIX capabilities]))
 415 AC_ARG_ENABLE(rusage,
 416   AS_HELP_STRING([--disable-rusage], [disable using getrusage]))
 417 AC_ARG_ENABLE(gcc_ultra_verbose,
 418   AS_HELP_STRING([--enable-gcc-ultra-verbose], [enable ultra verbose GCC warnings]))
 419 AC_ARG_ENABLE(backtrace,
 420   AS_HELP_STRING([--disable-backtrace,], [disable crash backtraces (default autodetect)]))
 421 AC_ARG_ENABLE(time-check,
 422   AS_HELP_STRING([--disable-time-check], [disable slow thread warning messages]))
 423 AC_ARG_ENABLE(pcreposix,
 424   AS_HELP_STRING([--enable-pcreposix], [enable using PCRE Posix libs for regex functions]))
 425 AC_ARG_ENABLE(fpm,
 426   AS_HELP_STRING([--enable-fpm], [enable Forwarding Plane Manager support]))
 427 AC_ARG_ENABLE(systemd,
 428   AS_HELP_STRING([--enable-systemd], [enable Systemd support]))
 429 AC_ARG_ENABLE(werror,
 430   AS_HELP_STRING([--enable-werror], [enable -Werror (recommended for developers only)]))
 431 AC_ARG_ENABLE(cumulus,
 432   AS_HELP_STRING([--enable-cumulus], [enable Cumulus Switch Special Extensions]))
 433 AC_ARG_ENABLE(datacenter,
 434   AS_HELP_STRING([--enable-datacenter], [enable Compilation for Data Center Extensions]))
 435 AC_ARG_ENABLE(fuzzing,
 436   AS_HELP_STRING([--enable-fuzzing], [enable ability to fuzz various parts of FRR]))
 437 AC_ARG_ENABLE(netlink_fuzzing,
 438   AS_HELP_STRING([--enable-netlink-fuzzing], [enable ability to fuzz netlink listening socket in zebra]))
 439 AC_ARG_ENABLE(rr-semantics,
 440   AS_HELP_STRING([--disable-rr-semantics], [disable the v6 Route Replace semantics]))
 441 AC_ARG_ENABLE([protobuf],
 442   AS_HELP_STRING([--enable-protobuf], [Enable experimental protobuf support]))
 443 AC_ARG_ENABLE([oldvpn_commands],
 444   AS_HELP_STRING([--enable-oldvpn-commands], [Keep old vpn commands]))
 445 AC_ARG_ENABLE(rpki,
 446   AS_HELP_STRING([--enable-rpki], [enable RPKI prefix validation support]))
 447 AC_ARG_ENABLE([clippy-only],
 448   AS_HELP_STRING([--enable-clippy-only], [Only build clippy]))
 449 AC_ARG_ENABLE([numeric_version],
 450   AS_HELP_STRING([--enable-numeric-version], [Only numeric digits allowed in version (for Alpine)]))
 451 AC_ARG_ENABLE([gcov],
 452   AS_HELP_STRING([--enable-gcov], [Add code coverage information]))
 453 AC_ARG_ENABLE(bfdd,
 454   AS_HELP_STRING([--disable-bfdd], [do not build bfdd]))
 455 AC_ARG_ENABLE([address-sanitizer],
 456   AS_HELP_STRING([--enable-address-sanitizer], [enable AddressSanitizer support for detecting a wide variety of memory allocation and deallocation errors]))
 457 AC_ARG_ENABLE([thread-sanitizer],
 458   AS_HELP_STRING([--enable-thread-sanitizer], [enable ThreadSanitizer support for detecting data races]))
 459 AC_ARG_ENABLE([memory-sanitizer],
 460   AS_HELP_STRING([--enable-memory-sanitizer], [enable MemorySanitizer support for detecting uninitialized memory reads]))
 461
 462 AS_IF([test "${enable_clippy_only}" != "yes"], [
 463 AC_CHECK_HEADERS(json-c/json.h)
 464 AC_CHECK_LIB(json-c, json_object_get, LIBS="$LIBS -ljson-c", [], [-lm])
 465 if test $ac_cv_lib_json_c_json_object_get = no; then
 466   AC_CHECK_LIB(json, json_object_get, LIBS="$LIBS -ljson")
 467   if test $ac_cv_lib_json_json_object_get = no; then
 468       AC_MSG_ERROR([lib json is needed to compile])
 469   fi
 470 fi
 471 ])
 472
 473 AC_ARG_ENABLE([dev_build],
 474     AS_HELP_STRING([--enable-dev-build], [build for development]))
 475
 476 AC_ARG_ENABLE([lua],
 477     AS_HELP_STRING([--enable-lua], [Build Lua scripting]))
 478
 479 if test x"${enable_time_check}" != x"no" ; then
 480   if test x"${enable_time_check}" = x"yes" -o x"${enable_time_check}" = x ; then
 481     AC_DEFINE(CONSUMED_TIME_CHECK,5000000,Consumed Time Check)
 482   else
 483     AC_DEFINE_UNQUOTED(CONSUMED_TIME_CHECK,$enable_time_check,Consumed Time Check)
 484   fi
 485 fi
 486
 487 case "${enable_systemd}" in
 488   "no") ;;
 489   "yes")
 490   AC_CHECK_LIB(systemd, sd_notify, LIBS="$LIBS -lsystemd")
 491   if test $ac_cv_lib_systemd_sd_notify = no; then
 492     AC_MSG_ERROR([enable systemd has been specified but systemd development env not found on your system])
 493   else
 494     AC_DEFINE(HAVE_SYSTEMD,,Compile systemd support in)
 495   fi
 496   ;;
 497   "*") ;;
 498 esac
 499
 500 if test "${enable_rr_semantics}" != "no" ; then
 501   AC_DEFINE(HAVE_V6_RR_SEMANTICS,, Compile in v6 Route Replacement Semantics)
 502 fi
 503
 504 if test "${enable_datacenter}" = "yes" ; then
 505   AC_DEFINE(HAVE_DATACENTER,,Compile extensions for a DataCenter)
 506   DFLT_NAME="datacenter"
 507 else
 508   DFLT_NAME="traditional"
 509 fi
 510
 511 if test "${enable_fuzzing}" = "yes" ; then
 512   AC_DEFINE(HANDLE_ZAPI_FUZZING,,Compile extensions to use with a fuzzer)
 513 fi
 514
 515 if test "${enable_netlink_fuzzing}" = "yes" ; then
 516   AC_DEFINE(HANDLE_NETLINK_FUZZING,,Compile extensions to use with a fuzzer for netlink)
 517 fi
 518
 519 if test "${enable_cumulus}" = "yes" ; then
 520   AC_DEFINE(HAVE_CUMULUS,,Compile Special Cumulus Code in)
 521 fi
 522
 523 AC_SUBST(DFLT_NAME)
 524 AC_DEFINE_UNQUOTED(DFLT_NAME,["$DFLT_NAME"], Name of the configuration default set)
 525
 526 if test "${enable_shell_access}" = "yes"; then
 527    AC_DEFINE(HAVE_SHELL_ACCESS,,Allow user to use ssh/telnet/bash)
 528 fi
 529
 530 AM_CONDITIONAL([FPM], [test "x$enable_fpm" = "xyes"])
 531
 532 #
 533 # Python for clippy
 534 #
 535
 536 AC_DEFUN([FRR_PYTHON_CHECK_WORKING], [
 537   AC_MSG_CHECKING([whether we found a working Python version])
 538   AC_LINK_IFELSE_FLAGS([$PYTHON_CFLAGS], [$PYTHON_LIBS], [AC_LANG_PROGRAM([
 539 #include <Python.h>
 540 #if PY_VERSION_HEX < 0x02070000
 541 #error python too old
 542 #endif
 543 int main(void);
 544 ],
 545 [
 546 {
 547   Py_Initialize();
 548   return 0;
 549 }
 550 ])], [
 551     # some python installs are missing the zlib dependency...
 552     PYTHON_LIBS="${PYTHON_LIBS} -lz"
 553     AC_LINK_IFELSE_FLAGS([$PYTHON_CFLAGS], [$PYTHON_LIBS], [AC_LANG_PROGRAM([
 554 #include <Python.h>
 555 #if PY_VERSION_HEX < 0x02070000
 556 #error python too old
 557 #endif
 558 int main(void);
 559 ],
 560 [
 561 {
 562   Py_Initialize();
 563   return 0;
 564 }
 565 ])], [
 566       m4_if([$1], [], [
 567         PYTHONCONFIG=""
 568         unset PYTHON_LIBS
 569         unset PYTHON_CFLAGS
 570       ], [$1])
 571     ])
 572   ])
 573 ])
 574
 575 AS_IF([test "$host" = "$build"], [
 576   PYTHONCONFIG=""
 577
 578   # ordering:
 579   # 1.  try python3, but respect the user's preference on which minor ver
 580   # 2.  try python, which might be py3 or py2 again on the user's preference
 581   # 3.  try python2 (can really only be 2.7 but eh)
 582   # 4.  try 3.6 > 3.5 > 3.4 > 3.3 > 3.2 > 2.7 through pkg-config (no user pref)
 583   #
 584   # (AX_PYTHON_DEVEL has no clue about py3 vs py2)
 585   # (AX_PYTHON does not do what we need)
 586
 587   AC_CHECK_TOOLS([PYTHONCONFIG], [ \
 588         python3-config \
 589         python-config \
 590         python2-config \
 591         python3.6-config \
 592         python3.5-config \
 593         python3.4-config \
 594         python3.3-config \
 595         python3.2-config \
 596         python2.7-config ])
 597   if test -n "$PYTHONCONFIG"; then
 598     PYTHON_CFLAGS="`\"${PYTHONCONFIG}\" --includes`"
 599     PYTHON_LIBS="`\"${PYTHONCONFIG}\" --ldflags`"
 600
 601     FRR_PYTHON_CHECK_WORKING([])
 602   fi
 603
 604   if test -z "$PYTHONCONFIG"; then
 605     PKG_CHECK_MODULES([PYTHON], python-3.6, [], [
 606       PKG_CHECK_MODULES([PYTHON], python-3.5, [], [
 607         PKG_CHECK_MODULES([PYTHON], python-3.4, [], [
 608           PKG_CHECK_MODULES([PYTHON], python-3.3, [], [
 609             PKG_CHECK_MODULES([PYTHON], python-3.2, [], [
 610               PKG_CHECK_MODULES([PYTHON], python-2.7, [], [
 611                 AC_MSG_FAILURE([could not find python-config or pkg-config python, please install Python development files from libpython-dev or similar])
 612                 ])])])])])])
 613
 614
 615     FRR_PYTHON_CHECK_WORKING([
 616       AC_MSG_FAILURE([could not find python-config or pkg-config python, please install Python development files from libpython-dev or similar])
 617     ])
 618   fi
 619 ])
 620 AC_SUBST(PYTHON_CFLAGS)
 621 AC_SUBST(PYTHON_LIBS)
 622
 623 #
 624 # Logic for protobuf support.
 625 #
 626 if test "$enable_protobuf" = "yes"; then
 627   # Check for protoc & protoc-c
 628
 629   # protoc is not required, it's only for a "be nice" helper target
 630   AC_CHECK_PROGS([PROTOC], [protoc], [/bin/false])
 631
 632   AC_CHECK_PROGS([PROTOC_C], [protoc-c], [/bin/false])
 633   if test "$PROTOC_C" = "/bin/false"; then
 634     AC_MSG_FAILURE([protobuf requested but protoc-c not found.  Install protobuf-c.])
 635   fi
 636
 637   PKG_CHECK_MODULES([PROTOBUF_C], [libprotobuf-c >= 0.14],, [
 638     AC_MSG_FAILURE([protobuf requested but libprotobuf-c not found.  Install protobuf-c.])
 639   ])
 640   AC_CHECK_HEADER([google/protobuf-c/protobuf-c.h], [], [
 641     AC_MSG_FAILURE([protobuf requested but protobuf-c.h not found.  Install protobuf-c.])
 642   ])
 643
 644   AC_DEFINE(HAVE_PROTOBUF,, protobuf)
 645 fi
 646 AM_CONDITIONAL([HAVE_PROTOBUF], [test "x$enable_protobuf" = "xyes"])
 647
 648 #
 649 # Logic for old vpn commans support.
 650 #
 651 if test "$enable_oldvpn_commands" = "yes"; then
 652    AC_DEFINE(KEEP_OLD_VPN_COMMANDS,, [Define for compiling with old vpn commands])
 653 fi
 654
 655 #
 656 # End of logic for protobuf support.
 657 #
 658
 659 AC_MSG_CHECKING(if zebra should be configurable to send Route Advertisements)
 660 if test "${enable_rtadv}" != "no"; then
 661   AC_MSG_RESULT(yes)
 662   AC_DEFINE(HAVE_RTADV,,Enable IPv6 Routing Advertisement support)
 663 else
 664   AC_MSG_RESULT(no)
 665 fi
 666
 667 if test x"${enable_user}" = x"no"; then
 668   enable_user=""
 669 else
 670   if test x"${enable_user}" = x"yes" || test x"${enable_user}" = x""; then
 671     enable_user="frr"
 672   fi
 673   AC_DEFINE_UNQUOTED(FRR_USER, "${enable_user}", frr User)
 674 fi
 675
 676 if test x"${enable_group}" = x"no"; then
 677   enable_group=""
 678 else
 679   if test x"${enable_group}" = x"yes" || test x"${enable_group}" = x""; then
 680     enable_group="frr"
 681   fi
 682   AC_DEFINE_UNQUOTED(FRR_GROUP, "${enable_group}", frr Group)
 683 fi
 684
 685 if test x"${enable_vty_group}" = x"yes" ; then
 686   AC_MSG_ERROR([--enable-vty-group requires a group as argument, not yes])
 687 elif test x"${enable_vty_group}" != x""; then
 688   if test x"${enable_vty_group}" != x"no"; then
 689     AC_DEFINE_UNQUOTED(VTY_GROUP, "${enable_vty_group}", VTY Sockets Group)
 690   fi
 691 fi
 692 AC_SUBST([enable_user])
 693 AC_SUBST([enable_group])
 694 AC_SUBST([enable_vty_group])
 695
 696 enable_configfile_mask=${enable_configfile_mask:-0600}
 697 AC_DEFINE_UNQUOTED(CONFIGFILE_MASK, ${enable_configfile_mask}, Mask for config files)
 698
 699 enable_logfile_mask=${enable_logfile_mask:-0600}
 700 AC_DEFINE_UNQUOTED(LOGFILE_MASK, ${enable_logfile_mask}, Mask for log files)
 701
 702 MPATH_NUM=1
 703
 704 case "${enable_multipath}" in
 705   0)
 706     MPATH_NUM=64
 707     ;;
 708   [[1-9]|[1-9][0-9]|[1-9][0-9][0-9]])
 709     MPATH_NUM="${enable_multipath}"
 710     ;;
 711   "")
 712     ;;
 713   *)
 714     AC_MSG_FAILURE([Please specify digit to enable multipath ARG])
 715     ;;
 716 esac
 717
 718 AC_DEFINE_UNQUOTED(MULTIPATH_NUM, $MPATH_NUM, Maximum number of paths for a route)
 719
 720 AC_DEFINE_UNQUOTED(VTYSH_PAGER, "$VTYSH_PAGER", [What pager to use])
 721
 722 dnl --------------------
 723 dnl Enable code coverage
 724 dnl --------------------
 725 AM_CONDITIONAL([HAVE_GCOV],[test '!' "$enable_gcov" = no])
 726
 727 dnl ------------------------------------
 728 dnl Alpine only accepts numeric versions
 729 dnl ------------------------------------
 730 if test "x${enable_numeric_version}" != "x" ; then
 731   VERSION="`echo ${VERSION} | tr -c -d '[[.0-9]]'`"
 732   PACKAGE_VERSION="`echo ${PACKAGE_VERSION} | tr -c -d '[[.0-9]]'`"
 733 fi
 734
 735 dnl -----------------------------------
 736 dnl Add extra version string to package
 737 dnl name, string and version fields.
 738 dnl -----------------------------------
 739 if test "x${EXTRAVERSION}" != "x" ; then
 740   VERSION="${VERSION}${EXTRAVERSION}"
 741   PACKAGE_VERSION="${PACKAGE_VERSION}${EXTRAVERSION}"
 742   AC_SUBST(PACKAGE_EXTRAVERSION, ["${EXTRAVERSION}"])
 743   PACKAGE_STRING="${PACKAGE_STRING}${EXTRAVERSION}"
 744 fi
 745
 746 if test "x$with_pkg_git_version" = "xyes"; then
 747         if test -d "${srcdir}/.git"; then
 748                 AC_DEFINE(GIT_VERSION, [1], [include git version info])
 749         else    with_pkg_git_version="no"
 750                 AC_MSG_WARN([--with-pkg-git-version given, but this is not a git checkout])
 751         fi
 752 fi
 753 AM_CONDITIONAL([GIT_VERSION], [test "x$with_pkg_git_version" = "xyes"])
 754
 755 AC_CHECK_TOOL([OBJCOPY], [objcopy], [:])
 756 AC_CACHE_CHECK([for .interp value to use], [frr_cv_interp], [
 757   frr_cv_interp=""
 758   AC_LINK_IFELSE([AC_LANG_SOURCE([[int main() { return 0; }]])], [
 759     if $OBJCOPY -j.interp -Obinary conftest conftest.interp; then
 760       frr_cv_interp="`xargs -0 echo < conftest.interp`"
 761     fi
 762     test -f conftest.interp && rm conftest.interp
 763   ])
 764 ])
 765 if test -n "$frr_cv_interp"; then
 766   AC_DEFINE_UNQUOTED(INTERP, ["$frr_cv_interp"], [.interp value])
 767 fi
 768
 769 dnl ------------------------------------
 770 dnl Check C keywords and standard  types
 771 dnl ------------------------------------
 772 AC_C_CONST
 773 AC_C_INLINE
 774 AC_C_VOLATILE
 775 AC_HEADER_STDC
 776 dnl AC_TYPE_PID_T
 777 AC_TYPE_UID_T
 778 AC_TYPE_MODE_T
 779 AC_TYPE_SIZE_T
 780 AC_STRUCT_TM
 781
 782 dnl -------------------------
 783 dnl Check other header files.
 784 dnl -------------------------
 785 AC_CHECK_HEADERS([stropts.h sys/ksym.h \
 786         linux/version.h asm/types.h \
 787         sys/cdefs.h])
 788
 789 ac_stdatomic_ok=false
 790 AC_DEFINE(FRR_AUTOCONF_ATOMIC, 1, [did autoconf checks for atomic funcs])
 791 AC_CHECK_HEADER([stdatomic.h],[
 792
 793   AC_MSG_CHECKING([whether _Atomic qualifier works])
 794   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 795 #include <stdatomic.h>
 796 int main(int argc, char **argv) {
 797   _Atomic int i = 0;
 798   return i;
 799 }
 800 ]])], [
 801     AC_DEFINE(HAVE_STDATOMIC_H, 1, [found stdatomic.h])
 802     AC_MSG_RESULT([yes])
 803     ac_stdatomic_ok=true
 804   ], [
 805     AC_MSG_RESULT([no])
 806   ])
 807 ])
 808
 809 AS_IF([$ac_stdatomic_ok], [true], [
 810   AC_MSG_CHECKING([for __atomic_* builtins])
 811   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 812 int main(int argc, char **argv) {
 813   volatile int i = 1;
 814   __atomic_store_n (&i, 0, __ATOMIC_RELEASE);
 815   return __atomic_load_n (&i, __ATOMIC_ACQUIRE);
 816 }
 817 ]])], [
 818     AC_DEFINE(HAVE___ATOMIC, 1, [found __atomic builtins])
 819     AC_MSG_RESULT([yes])
 820   ], [
 821     AC_MSG_RESULT([no])
 822
 823     dnl FreeBSD 9 has a broken stdatomic.h where _Atomic doesn't work
 824     AC_MSG_CHECKING([for __sync_* builtins])
 825     AC_LINK_IFELSE([AC_LANG_SOURCE([[
 826 int main(int argc, char **argv) {
 827   volatile int i = 1;
 828   __sync_fetch_and_sub (&i, 1);
 829   return __sync_val_compare_and_swap (&i, 0, 1);
 830 }
 831 ]])], [
 832       AC_DEFINE(HAVE___SYNC, 1, [found __sync builtins])
 833       AC_MSG_RESULT([yes])
 834
 835       AC_MSG_CHECKING([for __sync_swap builtin])
 836       AC_LINK_IFELSE([AC_LANG_SOURCE([[
 837 int main(int argc, char **argv) {
 838   volatile int i = 1;
 839   return __sync_swap (&i, 2);
 840 }
 841 ]])], [
 842         AC_DEFINE(HAVE___SYNC_SWAP, 1, [found __sync_swap builtin])
 843         AC_MSG_RESULT([yes])
 844       ], [
 845         AC_MSG_RESULT([no])
 846       ])
 847
 848     ], [
 849       AC_MSG_RESULT([no])
 850       AC_MSG_FAILURE([stdatomic.h unavailable and $CC has neither __atomic nor __sync builtins])
 851     ])
 852   ])
 853 ])
 854
 855 AC_CHECK_HEADERS([pthread_np.h],,, [
 856 #include <pthread.h>
 857 ])
 858 AC_CHECK_FUNCS([pthread_setname_np pthread_set_name_np])
 859
 860 dnl Utility macro to avoid retyping includes all the time
 861 m4_define([FRR_INCLUDES],
 862 [#ifdef SUNOS_5
 863 #define _POSIX_C_SOURCE 200809L
 864 #define __EXTENSIONS__
 865 #endif
 866 #include <stdio.h>
 867 #include <stdlib.h>
 868 #include <stddef.h>
 869 #include <sys/types.h>
 870 /* sys/conf.h depends on param.h on FBSD at least */
 871 #include <sys/param.h>
 872 /* Required for MAXSIG */
 873 #include <signal.h>
 874 #include <sys/socket.h>
 875 #ifdef __APPLE__
 876 # define __APPLE_USE_RFC_3542
 877 #endif
 878 #include <netinet/in.h>
 879 #include <sys/time.h>
 880 #include <time.h>
 881 #include <net/if.h>
 882 ])dnl
 883
 884 dnl Same applies for HAVE_NET_IF_VAR_H, which HAVE_NETINET6_ND6_H and
 885 dnl HAVE_NETINET_IN_VAR_H depend upon. But if_var.h depends on if.h, hence
 886 dnl an additional round for it.
 887
 888 AC_CHECK_HEADERS([net/if_var.h], [], [], FRR_INCLUDES)
 889
 890 m4_define([FRR_INCLUDES],
 891 FRR_INCLUDES
 892 [#if HAVE_NET_IF_VAR_H
 893 # include <net/if_var.h>
 894 #endif
 895 ])dnl
 896
 897 AC_CHECK_HEADERS([netinet/in_var.h \
 898         net/if_dl.h net/netopt.h \
 899         inet/nd.h netinet/ip_icmp.h \
 900         sys/sysctl.h sys/sockio.h kvm.h sys/conf.h],
 901         [], [], FRR_INCLUDES)
 902
 903 AC_CHECK_HEADERS([ucontext.h], [], [],
 904 [#ifndef __USE_GNU
 905 #define __USE_GNU
 906 #endif /* __USE_GNU */
 907 FRR_INCLUDES
 908 ])
 909
 910 m4_define([UCONTEXT_INCLUDES],
 911 [#include <ucontext.h>])dnl
 912
 913 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.uc_regs],
 914   [], [], [UCONTEXT_INCLUDES])
 915 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs],
 916   [AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs.nip],
 917    [], [], [UCONTEXT_INCLUDES])],
 918   [], [UCONTEXT_INCLUDES])
 919 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.gregs],
 920   [], [], [UCONTEXT_INCLUDES])
 921
 922 m4_define([FRR_INCLUDES],
 923 FRR_INCLUDES
 924 [
 925 #include <sys/un.h>
 926 #include <netinet/in_systm.h>
 927 #if HAVE_NETINET_IN_VAR_H
 928 # include <netinet/in_var.h>
 929 #endif
 930 #if HAVE_NET_IF_DL_H
 931 # include <net/if_dl.h>
 932 #endif
 933 #if HAVE_NET_NETOPT_H
 934 # include <net/netopt.h>
 935 #endif
 936 #include <net/route.h>
 937 #if HAVE_INET_ND_H
 938 # include <inet/nd.h>
 939 #endif
 940 #include <arpa/inet.h>
 941 /* Required for IDRP */
 942 #if HAVE_NETINET_IP_ICMP_H
 943 # include <netinet/ip_icmp.h>
 944 #endif
 945 ])dnl
 946
 947 dnl V6 headers are checked below, after we check for v6
 948
 949 AC_MSG_CHECKING([which operating system interface to use])
 950 case "$host_os" in
 951   sunos* | solaris2*)
 952     AC_MSG_RESULT([Solaris])
 953
 954     AC_DEFINE(SUNOS_5, 1, [SunOS 5])
 955     AC_DEFINE(SOLARIS_IPV6, 1, Solaris IPv6)
 956     AC_DEFINE(_POSIX_C_SOURCE, 200809L, [enable POSIX.1-2008 and XPG7/SUSv4])
 957
 958     AC_CHECK_LIB(socket, main)
 959     AC_CHECK_LIB(nsl, main)
 960     AC_CHECK_LIB(umem, main)
 961     AC_CHECK_FUNCS([printstack], [
 962       AC_DEFINE([HAVE_PRINTSTACK],1,[Solaris printstack])
 963       AC_DEFINE([HAVE_STACK_TRACE],1,[Stack symbols decode functionality])
 964     ])
 965     CURSES=-lcurses
 966     SOLARIS="solaris"
 967     ;;
 968   linux*)
 969     AC_MSG_RESULT([Linux])
 970
 971     AC_DEFINE(GNU_LINUX,,GNU Linux)
 972     AC_DEFINE(HAVE_NETLINK,,netlink)
 973     AC_DEFINE(LINUX_IPV6,1,Linux IPv6 stack)
 974
 975     dnl Linux has a compilation problem with mixing
 976     dnl netinet/in.h and linux/in6.h they are not
 977     dnl compatible.  There has been discussion on
 978     dnl how to fix it but no real progress on implementation
 979     dnl when they fix it, remove this
 980     AC_DEFINE(IPV6_MINHOPCOUNT, 73, Linux ipv6 Min Hop Count)
 981     ;;
 982   openbsd*)
 983     AC_MSG_RESULT([OpenBSD])
 984
 985     AC_DEFINE(OPEN_BSD,,OpenBSD)
 986     AC_DEFINE(KAME,1,KAME IPv6)
 987     AC_DEFINE(BSD_V6_SYSCTL,1,BSD v6 sysctl to turn on and off forwarding)
 988
 989     if test "x${enable_pimd}" != "xno"; then
 990       case "$host_os" in
 991       openbsd6.0)
 992         ;;
 993       openbsd[6-9]*)
 994         AC_MSG_FAILURE([pimd cannot be enabled as PIM support has been removed from OpenBSD 6.1])
 995         ;;
 996       esac
 997     fi
 998     ;;
 999   *)
1000     AC_MSG_RESULT([BSD])
1001
1002     AC_DEFINE(HAVE_NET_RT_IFLIST,,NET_RT_IFLIST)
1003     AC_DEFINE(KAME,1,KAME IPv6)
1004     AC_DEFINE(BSD_V6_SYSCTL,1,BSD v6 sysctl to turn on and off forwarding)
1005     ;;
1006 esac
1007 AM_CONDITIONAL(SOLARIS, test "${SOLARIS}" = "solaris")
1008
1009 AC_SYS_LARGEFILE
1010
1011 dnl ------------------------
1012 dnl Integrated REALMS option
1013 dnl ------------------------
1014 if test "${enable_realms}" = "yes"; then
1015     case "$host_os" in
1016       linux*)
1017        AC_DEFINE(SUPPORT_REALMS,, Realms support)
1018        ;;
1019       *)
1020        echo "Sorry, only Linux has REALMS support"
1021        exit 1
1022        ;;
1023     esac
1024 fi
1025 AM_CONDITIONAL([SUPPORT_REALMS], [test "${enable_realms}" = "yes"])
1026
1027 dnl ---------------------
1028 dnl Integrated VTY option
1029 dnl ---------------------
1030 case "${enable_vtysh}" in
1031   "no") VTYSH="";;
1032   *)    VTYSH="vtysh";
1033          AC_DEFINE(VTYSH,,VTY shell)
1034 dnl      Vtysh uses libreadline, which looks for termcap functions at
1035 dnl      configure time.  We follow readlines search order.
1036 dnl      The required procedures are in libtermcap on NetBSD, in
1037 dnl      [TODO] on Linux, and in [TODO] on Solaris.
1038          AC_CHECK_LIB(termcap, tputs, LIBREADLINE="$LIBREADLINE -ltermcap",
1039            [AC_CHECK_LIB(tinfo, tputs, LIBREADLINE="$LIBREADLINE -ltinfo",
1040              [AC_CHECK_LIB(curses, tputs, LIBREADLINE="$LIBREADLINE -lcurses",
1041                [AC_CHECK_LIB(ncurses, tputs,
1042                              LIBREADLINE="$LIBREADLINE -lncurses")]
1043               )]
1044             )]
1045           )
1046          AC_CHECK_LIB(readline, main, LIBREADLINE="-lreadline $LIBREADLINE",,
1047                       "$LIBREADLINE")
1048          if test $ac_cv_lib_readline_main = no; then
1049            AC_MSG_ERROR([vtysh needs libreadline but was not found and usable on your system.])
1050          fi
1051          AC_CHECK_HEADER(readline/history.h)
1052          if test $ac_cv_header_readline_history_h = no;then
1053            AC_MSG_ERROR([readline is too old to have readline/history.h, please update to the latest readline library.])
1054          fi
1055          AC_CHECK_LIB(readline, rl_completion_matches,
1056                       LIBREADLINE="$LIBREADLINE",, "$LIBREADLINE")
1057          if test $ac_cv_lib_readline_rl_completion_matches = no; then
1058            AC_DEFINE(rl_completion_matches,completion_matches,Old readline)
1059          fi
1060          AC_SEARCH_LIBS([append_history], [readline], [frr_cv_append_history=yes], [frr_cv_append_history=no])
1061          if test "$frr_cv_append_history" = yes; then
1062            AC_DEFINE(HAVE_APPEND_HISTORY, 1, [Have history.h append_history])
1063          fi
1064          ;;
1065 esac
1066 AC_SUBST(LIBREADLINE)
1067 AM_CONDITIONAL(VTYSH, test "x$VTYSH" = "xvtysh")
1068
1069 dnl ----------
1070 dnl PAM module
1071 dnl
1072 dnl FRR detects the PAM library it is built against by checking for a
1073 dnl functional pam_misc.h (Linux-PAM) or openpam.h (OpenPAM) header. pam_misc.h
1074 dnl is known to #include pam_appl.h, the standard header of a PAM library, and
1075 dnl openpam.h doesn't do that, although depends on the header too. Hence a
1076 dnl little assistance to AC_CHECK_HEADER is necessary for the proper detection
1077 dnl of OpenPAM.
1078 dnl ----------
1079 if test "$with_libpam" = "yes"; then
1080   AC_CHECK_HEADER([security/pam_misc.h],
1081     [AC_DEFINE(HAVE_PAM_MISC_H,,Have pam_misc.h)
1082      AC_DEFINE(PAM_CONV_FUNC,misc_conv,Have misc_conv)
1083      pam_conv_func="misc_conv"
1084     ],
1085     [], FRR_INCLUDES)
1086   AC_CHECK_HEADER([security/openpam.h],
1087     [AC_DEFINE(HAVE_OPENPAM_H,,Have openpam.h)
1088      AC_DEFINE(PAM_CONV_FUNC,openpam_ttyconv,Have openpam_ttyconv)
1089      pam_conv_func="openpam_ttyconv"
1090     ],
1091     [], FRR_INCLUDES[#include <security/pam_appl.h>])
1092   if test -z "$ac_cv_header_security_pam_misc_h$ac_cv_header_security_openpam_h" ; then
1093     AC_MSG_WARN([*** pam support will not be built ***])
1094     with_libpam="no"
1095   fi
1096 fi
1097
1098 if test "$with_libpam" = "yes"; then
1099 dnl took this test from proftpds configure.in and suited to our needs
1100 dnl -------------------------------------------------------------------------
1101 dnl
1102 dnl This next check looks funky due to a linker problem with some versions
1103 dnl of the PAM library.  Prior to 0.72 release, the Linux PAM shared library
1104 dnl omitted requiring libdl linking information. PAM-0.72 or better ships
1105 dnl with RedHat 6.2 and Debian 2.2 or better.
1106 AC_CHECK_LIB(pam, pam_start,
1107   [AC_CHECK_LIB(pam, $pam_conv_func,
1108     [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1109      LIBPAM="-lpam"],
1110     [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1111      LIBPAM="-lpam -lpam_misc"]
1112     )
1113   ],
1114
1115   [AC_CHECK_LIB(pam, pam_end,
1116     [AC_CHECK_LIB(pam, $pam_conv_func,
1117       [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1118        LIBPAM="-lpam -ldl"],
1119       [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1120        LIBPAM="-lpam -ldl -lpam_misc"]
1121      )
1122   ],AC_MSG_WARN([*** pam support will not be built ***]),
1123   [-ldl])
1124   ]
1125 )
1126 fi
1127 AC_SUBST(LIBPAM)
1128
1129 dnl -------------------------------
1130 dnl Endian-ness check
1131 dnl -------------------------------
1132 AC_WORDS_BIGENDIAN
1133
1134 dnl -------------------------------
1135 dnl check the size in byte of the C
1136 dnl -------------------------------
1137 dnl AC_CHECK_SIZEOF(char)
1138 dnl AC_CHECK_SIZEOF(int)
1139 dnl AC_CHECK_SIZEOF(short)
1140 dnl AC_CHECK_SIZEOF(long)
1141
1142 dnl ----------------------------
1143 dnl check existance of functions
1144 dnl ----------------------------
1145 AC_FUNC_FNMATCH
1146 AC_FUNC_FORK
1147 AC_FUNC_MKTIME
1148 AC_FUNC_STAT
1149
1150 dnl -------------------------------
1151 dnl bgpd needs pow() and hence libm
1152 dnl -------------------------------
1153 TMPLIBS="$LIBS"
1154 AC_CHECK_HEADER([math.h],
1155   [AC_CHECK_LIB([m], [pow],
1156     [LIBM="-lm"
1157      LIBS="$LIBS $LIBM"
1158      AC_CHECK_FUNCS(pow,[],[LIBM=""])
1159     ])
1160 ])
1161 if test x"$LIBM" = x ; then
1162   AC_MSG_WARN([Unable to find working pow function - bgpd may not link])
1163 fi
1164 LIBS="$TMPLIBS"
1165
1166 AC_SUBST(LIBM)
1167
1168 AC_CHECK_FUNCS([ppoll], [
1169   AC_DEFINE([HAVE_PPOLL], 1, [have Linux/BSD ppoll()])
1170 ])
1171 AC_CHECK_FUNCS([pollts], [
1172   AC_DEFINE([HAVE_POLLTS], 1, [have NetBSD pollts()])
1173 ])
1174
1175 dnl ---------------
1176 dnl other functions
1177 dnl ---------------
1178 AC_CHECK_FUNCS([ \
1179         strlcat strlcpy \
1180         getgrouplist])
1181
1182 AC_CHECK_HEADER([asm-generic/unistd.h],
1183                 [AC_CHECK_DECL(__NR_setns,
1184                                AC_DEFINE(HAVE_NETNS,, Have netns),,
1185                                FRR_INCLUDES [#include <asm-generic/unistd.h>
1186                                ])
1187                  AC_CHECK_FUNCS(setns)]
1188                )
1189
1190 dnl --------------------------
1191 dnl Determine IS-IS I/O method
1192 dnl --------------------------
1193 AC_DEFINE(ISIS_METHOD_PFPACKET, 1, [ constant value for isis method pfpacket ])
1194 AC_DEFINE(ISIS_METHOD_DLPI,     2, [ constant value for isis method dlpi ])
1195 AC_DEFINE(ISIS_METHOD_BPF,      3, [ constant value for isis method bpf ])
1196 AC_CHECK_HEADER(net/bpf.h)
1197 AC_CHECK_HEADER(sys/dlpi.h)
1198 AC_MSG_CHECKING(zebra IS-IS I/O method)
1199
1200 case "$host_os" in
1201   linux*)
1202     AC_MSG_RESULT(pfpacket)
1203     ISIS_METHOD_MACRO="ISIS_METHOD_PFPACKET"
1204     ;;
1205   solaris* | sunos*)
1206     AC_MSG_RESULT(DLPI)
1207     ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1208     ;;
1209   *)
1210     if test $ac_cv_header_net_bpf_h = no; then
1211       if test $ac_cv_header_sys_dlpi_h = no; then
1212         AC_MSG_RESULT(none)
1213         if test "${enable_isisd}" = yes -o "${enable_fabricd}" = yes; then
1214           AC_MSG_FAILURE([IS-IS support requested but no packet backend found])
1215         fi
1216         AC_MSG_WARN([*** IS-IS support will not be built ***])
1217         enable_isisd="no"
1218         enable_fabricd="no"
1219       else
1220         AC_MSG_RESULT(DLPI)
1221       fi
1222       ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1223     else
1224       AC_MSG_RESULT(BPF)
1225       ISIS_METHOD_MACRO="ISIS_METHOD_BPF"
1226     fi
1227     ;;
1228 esac
1229 AC_DEFINE_UNQUOTED(ISIS_METHOD, $ISIS_METHOD_MACRO, [ selected method for isis, == one of the constants ])
1230
1231 dnl ---------------------------------------------------------------
1232 dnl figure out how to specify an interface in multicast sockets API
1233 dnl ---------------------------------------------------------------
1234 AC_CHECK_MEMBERS([struct ip_mreqn.imr_ifindex], [], [], FRR_INCLUDES)
1235
1236 AC_CHECK_HEADERS([linux/mroute.h], [], [],[
1237         #include <sys/socket.h>
1238         #include <netinet/in.h>
1239         #define _LINUX_IN_H             /* For Linux <= 2.6.25 */
1240         #include <linux/types.h>
1241 ])
1242
1243 m4_define([FRR_INCLUDES],
1244 FRR_INCLUDES
1245 [#if HAVE_LINUX_MROUTE_H
1246 # include <linux/mroute.h>
1247 #endif
1248 ])dnl
1249
1250 AC_CHECK_HEADERS([netinet/ip_mroute.h], [], [],[
1251         #include <sys/socket.h>
1252         #include <sys/types.h>
1253         #include <netinet/in.h>
1254         #include <net/route.h>
1255 ])
1256
1257 m4_define([FRR_INCLUDES],
1258 FRR_INCLUDES
1259 [#if HAVE_NETINET_IP_MROUTE_H
1260 # include <netinet/ip_mroute.h>
1261 #endif
1262 ])dnl
1263
1264 AC_MSG_CHECKING([for BSD struct ip_mreq hack])
1265 AC_TRY_COMPILE([#include <sys/param.h>],
1266 [#if (defined(__FreeBSD__) && ((__FreeBSD_version >= 500022 && __FreeBSD_version < 700000) || (__FreeBSD_version < 500000 && __FreeBSD_version >= 440000))) || (defined(__NetBSD__) && defined(__NetBSD_Version__) && __NetBSD_Version__ >= 106010000) || defined(__OpenBSD__) || defined(__APPLE__) || defined(__DragonFly__) || defined(__sun)
1267   return (0);
1268 #else
1269   #error No support for BSD struct ip_mreq hack detected
1270 #endif],[AC_MSG_RESULT(yes)
1271 AC_DEFINE(HAVE_BSD_STRUCT_IP_MREQ_HACK,,[Can pass ifindex in struct ip_mreq])],
1272 AC_MSG_RESULT(no))
1273
1274 AC_MSG_CHECKING([for RFC3678 protocol-independed API])
1275 AC_TRY_COMPILE([
1276 #include <sys/types.h>
1277 #include <netinet/in.h>
1278 ], [struct group_req gr; int sock; setsockopt(sock, IPPROTO_IP, MCAST_JOIN_GROUP, (void*)&gr, sizeof(gr));
1279 ], [AC_MSG_RESULT(yes)
1280 AC_DEFINE(HAVE_RFC3678,1,[Have RFC3678 protocol-independed API])],
1281 AC_MSG_RESULT(no))
1282
1283 dnl ---------------------------------------------------------------
1284 dnl figure out how to check link-state
1285 dnl ---------------------------------------------------------------
1286 AC_CHECK_HEADER( [net/if_media.h],
1287   [m4_define([LINK_DETECT_INCLUDES],
1288     FRR_INCLUDES
1289     [#include <net/if_media.h>
1290   ])
1291   AC_CHECK_MEMBERS( [struct ifmediareq.ifm_status],
1292     AC_DEFINE(HAVE_BSD_LINK_DETECT,,[BSD link-detect]),
1293     [], LINK_DETECT_INCLUDES)],
1294   [],
1295   FRR_INCLUDES)
1296
1297 dnl ---------------------------------------------------------------
1298 dnl Additional, newer way to check link-state using ifi_link_state.
1299 dnl Not available in all BSD's when ifmediareq available
1300 dnl ---------------------------------------------------------------
1301 AC_CHECK_MEMBERS([struct if_data.ifi_link_state],
1302   AC_DEFINE(HAVE_BSD_IFI_LINK_STATE,,[BSD ifi_link_state available]),
1303   [], FRR_INCLUDES)
1304
1305 dnl ------------------------
1306 dnl TCP_MD5SIG socket option
1307 dnl ------------------------
1308
1309 AC_CHECK_HEADER([netinet/tcp.h],
1310    [m4_define([MD5_INCLUDES],
1311       FRR_INCLUDES
1312       [#include <netinet/tcp.h>
1313     ])
1314     AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)],
1315    [],
1316    FRR_INCLUDES)
1317 if test $ac_cv_have_decl_TCP_MD5SIG = no; then
1318   AC_CHECK_HEADER([linux/tcp.h],
1319        [m4_define([MD5_INCLUDES],
1320           FRR_INCLUDES
1321           [#include <linux/tcp.h>
1322         ])
1323        AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)])
1324 fi
1325
1326 dnl ----------------------------------------------------------------------------
1327 dnl figure out if domainname is available in the utsname struct (GNU extension).
1328 dnl ----------------------------------------------------------------------------
1329 AC_CHECK_MEMBERS([struct utsname.domainname], [], [], [#include <sys/utsname.h>])
1330
1331 dnl ------------------
1332 dnl IPv6 header checks
1333 dnl ------------------
1334 AC_CHECK_HEADERS([netinet6/in6.h netinet/in6_var.h \
1335         netinet6/in6_var.h netinet6/nd6.h], [], [],
1336         FRR_INCLUDES)
1337
1338 m4_define([FRR_INCLUDES],dnl
1339 FRR_INCLUDES
1340 [#if HAVE_NETINET6_IN6_H
1341 #include <netinet6/in6.h>
1342 #endif
1343 #if HAVE_NETINET_IN6_VAR_H
1344 #include <netinet/in6_var.h>
1345 #endif
1346 #include <netinet/icmp6.h>
1347 #if HAVE_NETINET6_IN6_VAR_H
1348 # include <netinet6/in6_var.h>
1349 #endif
1350 #if HAVE_NETINET6_ND6_H
1351 # include <netinet6/nd6.h>
1352 #endif
1353 ])dnl
1354
1355 dnl disable doc check
1356 AC_CHECK_PROGS([SPHINXBUILD], [sphinx-build sphinx-build3 sphinx-build2], [/bin/false])
1357 if test "$SPHINXBUILD" = "/bin/false"; then
1358   if test "${enable_doc}" = "yes"; then
1359     AC_MSG_ERROR([Documentation was explicitly requested with --enable-doc but sphinx-build is not available. Please disable docs or install sphinx.])
1360   fi
1361 fi
1362 AM_CONDITIONAL(DOC, test "${enable_doc}" != "no" -a "$SPHINXBUILD" != "/bin/false")
1363 AM_CONDITIONAL(DOC_HTML, test "${enable_doc_html}" = "yes")
1364
1365 dnl --------------------
1366 dnl Daemon disable check
1367 dnl --------------------
1368 AM_CONDITIONAL(ZEBRA, test "${enable_zebra}" != "no")
1369
1370 if test "${enable_bgpd}" = "no";then
1371   BGPD=""
1372 else
1373   BGPD="bgpd"
1374 fi
1375 AM_CONDITIONAL(BGPD, test "x$BGPD" = "xbgpd")
1376
1377 AM_CONDITIONAL(RIPD, test "${enable_ripd}" != "no")
1378 AM_CONDITIONAL(OSPFD, test "${enable_ospfd}" != "no")
1379 AM_CONDITIONAL(LDPD, test "${enable_ldpd}" != "no")
1380
1381 AS_IF([test "${enable_ldpd}" != "no"], [
1382   AC_DEFINE(HAVE_LDPD, 1, ldpd)
1383 ])
1384
1385 if test "$enable_bfdd" = "no"; then
1386   AC_DEFINE(HAVE_BFDD, 0, bfdd)
1387   BFDD=""
1388 else
1389   AC_DEFINE(HAVE_BFDD, 1, bfdd)
1390   BFDD="bfdd"
1391
1392   case $host_os in
1393     linux*)
1394       AC_DEFINE(BFD_LINUX, 1, bfdd)
1395       ;;
1396
1397     *)
1398       AC_DEFINE(BFD_BSD, 1, bfdd)
1399       ;;
1400   esac
1401 fi
1402
1403 AM_CONDITIONAL(BFDD, [test "x$BFDD" = "xbfdd"])
1404
1405 if test $ac_cv_lib_json_c_json_object_get = no -a "x$BFDD" = "xbfdd"; then
1406   AC_MSG_ERROR(["you must use json-c library to use bfdd"])
1407 fi
1408
1409 NHRPD=""
1410 case "$host_os" in
1411   linux*)
1412     if test "${enable_nhrpd}" != "no"; then
1413       NHRPD="nhrpd"
1414     fi
1415     ;;
1416   *)
1417     if test "${enable_nhrpd}" = "yes"; then
1418       AC_MSG_ERROR([nhrpd requires kernel APIs that are only present on Linux.])
1419     fi
1420     ;;
1421 esac
1422 AM_CONDITIONAL(NHRPD, test "x$NHRPD" = "xnhrpd")
1423
1424 AM_CONDITIONAL(EIGRPD, test "${enable_eigrpd}" != "no")
1425
1426 if test "${enable_watchfrr}" = "no";then
1427   WATCHFRR=""
1428 else
1429   WATCHFRR="watchfrr"
1430 fi
1431 AM_CONDITIONAL(WATCHFRR, test "x$WATCHFRR" = "xwatchfrr")
1432
1433 OSPFCLIENT=""
1434 if test "${enable_ospfapi}" != "no";then
1435     AC_DEFINE(SUPPORT_OSPF_API,,OSPFAPI)
1436
1437   if test "${enable_ospfclient}" != "no";then
1438       OSPFCLIENT="ospfclient"
1439   fi
1440 fi
1441
1442 AM_CONDITIONAL(OSPFCLIENT, test "x$OSPFCLIENT" = "xospfclient")
1443 AM_CONDITIONAL(RIPNGD, test "${enable_ripngd}" != "no")
1444 AM_CONDITIONAL(BABELD, test "${enable_babeld}" != "no")
1445 AM_CONDITIONAL(OSPF6D, test "${enable_ospf6d}" != "no")
1446 AM_CONDITIONAL(ISISD, test "${enable_isisd}" != "no")
1447 AM_CONDITIONAL(PIMD, test "${enable_pimd}" != "no")
1448 AM_CONDITIONAL(PBRD, test "${enable_pbrd}" != "no")
1449 AM_CONDITIONAL(SHARPD, test "${enable_sharpd}" = "yes")
1450 AM_CONDITIONAL(STATICD, test "${enable_staticd}" != "no")
1451 AM_CONDITIONAL(FABRICD, test "${enable_fabricd}" != "no")
1452
1453 if test "${enable_bgp_announce}" = "no";then
1454   AC_DEFINE(DISABLE_BGP_ANNOUNCE,1,Disable BGP installation to zebra)
1455 else
1456   AC_DEFINE(DISABLE_BGP_ANNOUNCE,0,Disable BGP installation to zebra)
1457 fi
1458
1459 if test "${enable_bgp_vnc}" != "no";then
1460   AC_DEFINE(ENABLE_BGP_VNC,1,Enable BGP VNC support)
1461 fi
1462 AM_CONDITIONAL([ENABLE_BGP_VNC], [test x${enable_bgp_vnc} != xno])
1463
1464 AC_SUBST(SOLARIS)
1465 AC_SUBST(CURSES)
1466 AC_CHECK_LIB(crypt, crypt, [],
1467                     [AC_CHECK_LIB(crypto, DES_crypt)])
1468 AC_CHECK_LIB(resolv, res_init)
1469
1470 dnl ---------------------------
1471 dnl check system has PCRE regexp
1472 dnl ---------------------------
1473 if test "x$enable_pcreposix" = "xyes"; then
1474   AC_CHECK_LIB(pcreposix, regexec, [], [
1475     AC_MSG_ERROR([--enable-pcreposix given but unable to find libpcreposix])
1476   ])
1477 fi
1478 AC_SUBST(HAVE_LIBPCREPOSIX)
1479
1480 dnl ------------------
1481 dnl check C-Ares library
1482 dnl ------------------
1483 if test "${NHRPD}" != ""; then
1484   PKG_CHECK_MODULES([CARES], [libcares], , [
1485     AC_MSG_ERROR([trying to build nhrpd, but libcares not found. install c-ares and its -dev headers.])
1486   ])
1487 fi
1488
1489
1490 dnl ------------------
1491 dnl check Net-SNMP library
1492 dnl ------------------
1493 if test "${enable_snmp}" != "" -a "${enable_snmp}" != "no"; then
1494    AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], [no])
1495    if test x"$NETSNMP_CONFIG" = x"no"; then
1496       AC_MSG_ERROR([--enable-snmp given but unable to find net-snmp-config])
1497    fi
1498    SNMP_LIBS="`${NETSNMP_CONFIG} --agent-libs`"
1499    SNMP_CFLAGS="`${NETSNMP_CONFIG} --base-cflags`"
1500    AC_MSG_CHECKING([whether we can link to Net-SNMP])
1501    AC_LINK_IFELSE_FLAGS([$SNMP_CFLAGS], [$SNMP_LIBS], [AC_LANG_PROGRAM([
1502 int main(void);
1503 ],
1504 [
1505 {
1506   return 0;
1507 }
1508 ])], [
1509      AC_MSG_ERROR([--enable-snmp given but not usable])])
1510    case "${enable_snmp}" in
1511      yes)
1512       SNMP_METHOD=agentx
1513       ;;
1514      agentx)
1515       SNMP_METHOD="${enable_snmp}"
1516       ;;
1517      *)
1518       AC_MSG_ERROR([--enable-snmp given with an unknown method (${enable_snmp}). Use yes or agentx])
1519       ;;
1520    esac
1521    AH_TEMPLATE([SNMP_AGENTX], [Use SNMP AgentX to interface with snmpd])
1522    AC_DEFINE_UNQUOTED(AS_TR_CPP(SNMP_${SNMP_METHOD}),,SNMP method to interface with snmpd)
1523 fi
1524 AM_CONDITIONAL([SNMP], [test "x${SNMP_METHOD}" != "x"])
1525 AC_SUBST(SNMP_LIBS)
1526 AC_SUBST(SNMP_CFLAGS)
1527
1528 dnl ---------------
1529 dnl math
1530 dnl ---------------
1531 AC_SEARCH_LIBS([sqrt], [m])
1532
1533 dnl ---------------
1534 dnl dlopen & dlinfo
1535 dnl ---------------
1536 AC_SEARCH_LIBS(dlopen, [dl dld], [], [
1537   AC_MSG_ERROR([unable to find the dlopen()])
1538 ])
1539
1540 AC_CHECK_HEADERS([link.h])
1541
1542 AC_CACHE_CHECK([for dlinfo(RTLD_DI_ORIGIN)], [frr_cv_rtld_di_origin], [
1543   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1544 #include <stdlib.h>
1545 #ifdef HAVE_LINK_H
1546 #include <link.h>
1547 #endif
1548 #include <dlfcn.h>
1549 ]], [[
1550   char origin[1];
1551   dlinfo (NULL, RTLD_DI_ORIGIN, &origin);
1552 ]])], [
1553     frr_cv_rtld_di_origin=yes
1554   ], [
1555     frr_cv_rtld_di_origin=no
1556   ])
1557 ])
1558 if test "$frr_cv_rtld_di_origin" = yes; then
1559   AC_DEFINE(HAVE_DLINFO_ORIGIN, 1, [Have dlinfo RTLD_DI_ORIGIN])
1560 fi
1561
1562 AC_CACHE_CHECK([for dlinfo(RTLD_DI_LINKMAP)], [frr_cv_rtld_di_linkmap], [
1563   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1564 #include <stdlib.h>
1565 #ifdef HAVE_LINK_H
1566 #include <link.h>
1567 #endif
1568 #include <dlfcn.h>
1569 ]], [[
1570   struct link_map *lm = NULL;
1571   dlinfo (NULL, RTLD_DI_LINKMAP, &lm);
1572 ]])], [
1573     frr_cv_rtld_di_linkmap=yes
1574   ], [
1575     frr_cv_rtld_di_linkmap=no
1576   ])
1577 ])
1578 if test "$frr_cv_rtld_di_linkmap" = yes; then
1579   AC_DEFINE(HAVE_DLINFO_LINKMAP, 1, [Have dlinfo RTLD_DI_LINKMAP])
1580 fi
1581
1582 AM_CONDITIONAL(SNMP, test "x$SNMP_METHOD" = "xagentx")
1583
1584 dnl ---------------------------
1585 dnl sockaddr and netinet checks
1586 dnl ---------------------------
1587 AC_CHECK_TYPES([
1588         struct sockaddr_dl,
1589         struct vifctl, struct mfcctl, struct sioc_sg_req,
1590         vifi_t, struct sioc_vif_req, struct igmpmsg,
1591         struct ifaliasreq, struct if6_aliasreq, struct in6_aliasreq,
1592         struct nd_opt_adv_interval, struct rt_addrinfo,
1593         struct nd_opt_homeagent_info, struct nd_opt_adv_interval],
1594         [], [], FRR_INCLUDES)
1595
1596 AC_CHECK_MEMBERS([struct sockaddr.sa_len,
1597         struct sockaddr_in.sin_len, struct sockaddr_un.sun_len,
1598         struct sockaddr_dl.sdl_len,
1599         struct if6_aliasreq.ifra_lifetime,
1600         struct nd_opt_adv_interval.nd_opt_ai_type],
1601         [], [], FRR_INCLUDES)
1602
1603 dnl ---------------------------
1604 dnl IRDP/pktinfo/icmphdr checks
1605 dnl ---------------------------
1606
1607 AC_CHECK_TYPES([struct in_pktinfo], [
1608   AC_CHECK_TYPES([struct icmphdr], [
1609     IRDP=true
1610   ], [
1611     IRDP=false
1612   ], [FRR_INCLUDES])
1613 ], [
1614   IRDP=false
1615 ], [FRR_INCLUDES])
1616
1617 case "${enable_irdp}" in
1618 yes)
1619   $IRDP || AC_MSG_ERROR(['IRDP requires in_pktinfo at the moment!'])
1620   ;;
1621 no)
1622   IRDP=false
1623   ;;
1624 esac
1625
1626 AM_CONDITIONAL(IRDP, $IRDP)
1627
1628 dnl -----------------------
1629 dnl checking for IP_PKTINFO
1630 dnl -----------------------
1631 AC_MSG_CHECKING(for IP_PKTINFO)
1632 AC_TRY_COMPILE([#include <netdb.h>], [
1633   int opt = IP_PKTINFO;
1634 ], [
1635   AC_MSG_RESULT(yes)
1636   AC_DEFINE(HAVE_IP_PKTINFO, 1, [Have IP_PKTINFO])
1637 ], [
1638   AC_MSG_RESULT(no)
1639 ])
1640
1641 dnl ---------------------------
1642 dnl checking for IP_RECVDSTADDR
1643 dnl ---------------------------
1644 AC_MSG_CHECKING(for IP_RECVDSTADDR)
1645 AC_TRY_COMPILE([#include <netinet/in.h>], [
1646   int opt = IP_RECVDSTADDR;
1647 ], [
1648   AC_MSG_RESULT(yes)
1649   AC_DEFINE(HAVE_IP_RECVDSTADDR, 1, [Have IP_RECVDSTADDR])
1650 ], [
1651   AC_MSG_RESULT(no)
1652 ])
1653
1654 dnl ----------------------
1655 dnl checking for IP_RECVIF
1656 dnl ----------------------
1657 AC_MSG_CHECKING(for IP_RECVIF)
1658 AC_TRY_COMPILE([#include <netinet/in.h>], [
1659   int opt = IP_RECVIF;
1660 ], [
1661   AC_MSG_RESULT(yes)
1662   AC_DEFINE(HAVE_IP_RECVIF, 1, [Have IP_RECVIF])
1663 ], [
1664   AC_MSG_RESULT(no)
1665 ])
1666
1667 dnl ----------------------
1668 dnl checking for SO_BINDANY
1669 dnl ----------------------
1670 AC_MSG_CHECKING(for SO_BINDANY)
1671 AC_TRY_COMPILE([#include <sys/socket.h>], [
1672   int opt = SO_BINDANY;
1673 ], [
1674   AC_MSG_RESULT(yes)
1675   AC_DEFINE(HAVE_SO_BINDANY, 1, [Have SO_BINDANY])
1676 ], [
1677   AC_MSG_RESULT(no)
1678 ])
1679
1680 dnl ----------------------
1681 dnl checking for IP_FREEBIND
1682 dnl ----------------------
1683 AC_MSG_CHECKING(for IP_FREEBIND)
1684 AC_TRY_COMPILE([#include <netinet/in.h>], [
1685   int opt = IP_FREEBIND;
1686 ], [
1687   AC_MSG_RESULT(yes)
1688   AC_DEFINE(HAVE_IP_FREEBIND, 1, [Have IP_FREEBIND])
1689 ], [
1690   AC_MSG_RESULT(no)
1691 ])
1692
1693 dnl --------------------------------------
1694 dnl checking for be32dec existence or not
1695 dnl --------------------------------------
1696 AC_CHECK_DECLS([be32enc, be32dec], [], [],
1697                [#include <sys/endian.h>])
1698
1699 dnl --------------------------------------
1700 dnl checking for clock_time monotonic struct and call
1701 dnl --------------------------------------
1702 AC_CHECK_DECL(CLOCK_MONOTONIC,
1703         [AC_CHECK_LIB(rt, clock_gettime, [LIBS="$LIBS -lrt"])
1704          AC_DEFINE(HAVE_CLOCK_MONOTONIC,, Have monotonic clock)
1705 ], [AC_MSG_RESULT(no)], [FRR_INCLUDES])
1706
1707 dnl --------------------------------------
1708 dnl checking for flex and bison
1709 dnl --------------------------------------
1710
1711 AM_PROG_LEX
1712 AC_MSG_CHECKING(version of flex)
1713 frr_ac_flex_version="$(eval $LEX -V | grep flex | head -n 1)"
1714 frr_ac_flex_version="${frr_ac_flex_version##* }"
1715 AC_MSG_RESULT([$frr_ac_flex_version])
1716 AX_COMPARE_VERSION([$frr_ac_flex_version], [lt], [2.5.20], [
1717   LEX="$SHELL $missing_dir/missing flex"
1718   if test -f "${srcdir}/lib/command_lex.c" -a -f "${srcdir}/lib/command_lex.h"; then
1719     AC_MSG_WARN([using pregenerated flex output files])
1720   else
1721     AC_MSG_ERROR([flex failure and pregenerated files not included (probably a git build)])
1722   fi
1723   AC_SUBST([LEX_OUTPUT_ROOT], [lex.yy])
1724   AC_SUBST([LEXLIB], [''])
1725 ])
1726
1727 AC_PROG_YACC
1728 dnl thanks GNU bison for this b*llshit...
1729 AC_MSG_CHECKING(version of bison)
1730 frr_ac_bison_version="$(eval $YACC -V | grep bison | head -n 1)"
1731 frr_ac_bison_version="${frr_ac_bison_version##* }"
1732 frr_ac_bison_missing="false"
1733 case "x${frr_ac_bison_version}" in
1734   x2.7*)
1735     BISON_OPENBRACE='"'
1736     BISON_CLOSEBRACE='"'
1737     BISON_VERBOSE=''
1738     AC_MSG_RESULT([$frr_ac_bison_version - 2.7 or older])
1739     ;;
1740   x2.*|x1.*)
1741     AC_MSG_RESULT([$frr_ac_bison_version])
1742     AC_MSG_WARN([installed bison is too old.  Please install GNU bison 2.7.x or newer.])
1743     frr_ac_bison_missing="true"
1744     ;;
1745   x)
1746     AC_MSG_RESULT([none])
1747     AC_MSG_WARN([could not determine bison version.  Please install GNU bison 2.7.x or newer.])
1748     frr_ac_bison_missing="true"
1749     ;;
1750   *)
1751     BISON_OPENBRACE='{'
1752     BISON_CLOSEBRACE='}'
1753     BISON_VERBOSE='-Dparse.error=verbose'
1754     AC_MSG_RESULT([$frr_ac_bison_version - 3.0 or newer])
1755     ;;
1756 esac
1757 AC_SUBST(BISON_OPENBRACE)
1758 AC_SUBST(BISON_CLOSEBRACE)
1759 AC_SUBST(BISON_VERBOSE)
1760
1761 if $frr_ac_bison_missing; then
1762   YACC="$SHELL $missing_dir/missing bison -y"
1763   if test -f "${srcdir}/lib/command_parse.c" -a -f "${srcdir}/lib/command_parse.h"; then
1764     AC_MSG_WARN([using pregenerated bison output files])
1765   else
1766     AC_MSG_ERROR([bison failure and pregenerated files not included (probably a git build)])
1767   fi
1768 fi
1769
1770 dnl -------------------
1771 dnl capabilities checks
1772 dnl -------------------
1773 if test "${enable_capabilities}" != "no"; then
1774   AC_MSG_CHECKING(whether prctl PR_SET_KEEPCAPS is available)
1775   AC_TRY_COMPILE([#include <sys/prctl.h>],[prctl(PR_SET_KEEPCAPS, 1, 0, 0, 0);],
1776     [AC_MSG_RESULT(yes)
1777      AC_DEFINE(HAVE_PR_SET_KEEPCAPS,,prctl)
1778      frr_ac_keepcaps="yes"],
1779      AC_MSG_RESULT(no)
1780   )
1781   if test x"${frr_ac_keepcaps}" = x"yes"; then
1782     AC_CHECK_HEADERS(sys/capability.h)
1783   fi
1784   if test x"${ac_cv_header_sys_capability_h}" = x"yes"; then
1785     AC_CHECK_LIB(cap, cap_init,
1786       [AC_DEFINE(HAVE_LCAPS,1,Capabilities)
1787        LIBCAP="-lcap"
1788        frr_ac_lcaps="yes"]
1789     )
1790   else
1791     AC_CHECK_HEADERS(priv.h,
1792      [AC_MSG_CHECKING(Solaris style privileges are available)
1793       AC_TRY_COMPILE([#include <priv.h>],[getpflags(PRIV_AWARE);],
1794           [AC_MSG_RESULT(yes)
1795            AC_DEFINE(HAVE_SOLARIS_CAPABILITIES,1,getpflags)
1796            frr_ac_scaps="yes"],
1797            AC_MSG_RESULT(no)
1798       )
1799      ]
1800    )
1801   fi
1802   if test x"${frr_ac_scaps}" = x"yes" \
1803        -o x"${frr_ac_lcaps}" = x"yes"; then
1804     AC_DEFINE(HAVE_CAPABILITIES,1,capabilities)
1805   fi
1806 fi
1807 AC_SUBST(LIBCAP)
1808
1809 dnl ---------------------------
1810 dnl check for glibc 'backtrace'
1811 dnl ---------------------------
1812 if test x"${enable_backtrace}" != x"no" ; then
1813   backtrace_ok=no
1814   AC_CHECK_HEADER([execinfo.h], [
1815     AC_SEARCH_LIBS([backtrace], [execinfo], [
1816       AC_DEFINE(HAVE_GLIBC_BACKTRACE,,[Glibc backtrace])
1817       AC_DEFINE(HAVE_STACK_TRACE,,[Stack symbol decoding])
1818       backtrace_ok=yes
1819     ],, [-lm])
1820   ])
1821
1822   if test x"${enable_backtrace}" = x"yes" -a x"${backtrace_ok}" = x"no"; then
1823     dnl user explicitly requested backtrace but we failed to find support
1824     AC_MSG_FAILURE([failed to find backtrace support])
1825   fi
1826 fi
1827
1828 dnl -----------------------------------------
1829 dnl check for malloc mallinfo struct and call
1830 dnl this must try and link using LIBS, in
1831 dnl order to check no alternative allocator
1832 dnl has been specified, which might not provide
1833 dnl mallinfo, e.g. such as Umem on Solaris.
1834 dnl -----------------------------------------
1835 AC_CHECK_HEADERS([malloc.h malloc_np.h malloc/malloc.h],,, [FRR_INCLUDES])
1836
1837 AC_CACHE_CHECK([whether mallinfo is available], [frr_cv_mallinfo], [
1838   AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
1839 #ifdef HAVE_MALLOC_H
1840 #include <malloc.h>
1841 #endif
1842 #ifdef HAVE_MALLOC_NP_H
1843 #include <malloc_np.h>
1844 #endif
1845 #ifdef HAVE_MALLOC_MALLOC_H
1846 #include <malloc/malloc.h>
1847 #endif
1848 ]], [[
1849 struct mallinfo ac_x; ac_x = mallinfo ();
1850 ]])], [
1851     frr_cv_mallinfo=yes
1852   ], [
1853     frr_cv_mallinfo=no
1854   ])
1855 ])
1856 if test "$frr_cv_mallinfo" = yes; then
1857   AC_DEFINE(HAVE_MALLINFO,,mallinfo)
1858 fi
1859
1860 AC_MSG_CHECKING(whether malloc_usable_size is available)
1861 AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
1862 #ifdef HAVE_MALLOC_H
1863 #include <malloc.h>
1864 #endif
1865 #ifdef HAVE_MALLOC_MALLOC_H
1866 #include <malloc/malloc.h>
1867 #endif
1868 ]], [[
1869 size_t ac_x; ac_x = malloc_usable_size(NULL);
1870 ]])], [
1871   AC_MSG_RESULT(yes)
1872   AC_DEFINE(HAVE_MALLOC_USABLE_SIZE,,malloc_usable_size)
1873 ], [
1874   AC_MSG_RESULT(no)
1875
1876   AC_MSG_CHECKING(whether malloc_size is available)
1877   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1878 #ifdef HAVE_MALLOC_H
1879 #include <malloc.h>
1880 #endif
1881 #ifdef HAVE_MALLOC_MALLOC_H
1882 #include <malloc/malloc.h>
1883 #endif
1884 ]], [[
1885 size_t ac_x; ac_x = malloc_size(NULL);
1886 ]])], [
1887     AC_MSG_RESULT(yes)
1888     AC_DEFINE(HAVE_MALLOC_SIZE,,malloc_size)
1889   ], [
1890     AC_MSG_RESULT(no)
1891   ])
1892 ])
1893
1894 dnl ------
1895 dnl ZeroMQ
1896 dnl ------
1897 if test "x$enable_zeromq" != "xno"; then
1898   PKG_CHECK_MODULES(ZEROMQ, [libzmq >= 4.0.0], [
1899     AC_DEFINE(HAVE_ZEROMQ, 1, [Enable ZeroMQ support])
1900     ZEROMQ=true
1901   ], [
1902     if test "x$enable_zeromq" = "xyes"; then
1903       AC_MSG_ERROR([configuration specifies --enable-zeromq but libzmq was not found])
1904     fi
1905   ])
1906 fi
1907 AM_CONDITIONAL([ZEROMQ], test "x$ZEROMQ" = "xtrue")
1908
1909 dnl ----------
1910 dnl configure date
1911 dnl ----------
1912 dev_version=`echo $VERSION | grep dev`
1913 #don't expire deprecated code in non 'dev' branch
1914 if test "${dev_version}" = ""; then
1915    CONFDATE=0
1916 else
1917    CONFDATE=`date '+%Y%m%d'`
1918 fi
1919 AC_SUBST(CONFDATE)
1920
1921 dnl ------------------------------
1922 dnl set paths for state directory
1923 dnl ------------------------------
1924 AC_MSG_CHECKING(directory to use for state file)
1925 if test "${prefix}" = "NONE"; then
1926   frr_statedir_prefix="";
1927 else
1928   frr_statedir_prefix=${prefix}
1929 fi
1930 if test "${localstatedir}" = '${prefix}/var'; then
1931   for FRR_STATE_DIR in ${frr_statedir_prefix}/var/run dnl
1932                         ${frr_statedir_prefix}/var/adm dnl
1933                         ${frr_statedir_prefix}/etc dnl
1934                         /var/run        dnl
1935                         /var/adm        dnl
1936                         /etc            dnl
1937                         /dev/null;
1938   do
1939     test -d $FRR_STATE_DIR && break
1940   done
1941   frr_statedir=$FRR_STATE_DIR
1942 else
1943   frr_statedir=${localstatedir}
1944 fi
1945 if test $frr_statedir = "/dev/null"; then
1946     AC_MSG_ERROR('STATE DIRECTORY NOT FOUND! FIX OR SPECIFY --localstatedir!')
1947 fi
1948 AC_MSG_RESULT(${frr_statedir})
1949 AC_SUBST(frr_statedir)
1950
1951 AC_DEFINE_UNQUOTED(LDPD_SOCKET, "$frr_statedir/ldpd.sock",ldpd control socket)
1952 AC_DEFINE_UNQUOTED(ZEBRA_SERV_PATH, "$frr_statedir/zserv.api",zebra api socket)
1953 AC_DEFINE_UNQUOTED(BFDD_CONTROL_SOCKET, "$frr_statedir/bfdd.sock", bfdd control socket)
1954 AC_DEFINE_UNQUOTED(DAEMON_VTY_DIR, "$frr_statedir",daemon vty directory)
1955
1956 dnl autoconf does this, but it does it too late...
1957 test "x$prefix" = xNONE && prefix=$ac_default_prefix
1958 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
1959
1960 dnl get the full path, recursing through variables...
1961 vtysh_bin="$bindir/vtysh"
1962 for I in 1 2 3 4 5 6 7 8 9 10; do
1963         eval vtysh_bin="\"$vtysh_bin\""
1964 done
1965 AC_DEFINE_UNQUOTED(VTYSH_BIN_PATH, "$vtysh_bin",path to vtysh binary)
1966 AC_SUBST(vtysh_bin)
1967
1968 CFG_SYSCONF="$sysconfdir"
1969 CFG_SBIN="$sbindir"
1970 CFG_STATE="$frr_statedir"
1971 CFG_MODULE="$moduledir"
1972 for I in 1 2 3 4 5 6 7 8 9 10; do
1973         eval CFG_SYSCONF="\"$CFG_SYSCONF\""
1974         eval CFG_SBIN="\"$CFG_SBIN\""
1975         eval CFG_STATE="\"$CFG_STATE\""
1976         eval CFG_MODULE="\"$CFG_MODULE\""
1977 done
1978 AC_SUBST(CFG_SYSCONF)
1979 AC_SUBST(CFG_SBIN)
1980 AC_SUBST(CFG_STATE)
1981 AC_SUBST(CFG_MODULE)
1982 AC_DEFINE_UNQUOTED(MODULE_PATH, "$CFG_MODULE", path to modules)
1983
1984 dnl ------------------------------------
1985 dnl Enable RPKI and add librtr to libs
1986 dnl ------------------------------------
1987 if test "${enable_rpki}" = "yes"; then
1988   PKG_CHECK_MODULES(RTRLIB,[rtrlib >= 0.5.0],
1989       [RPKI=true],
1990       [RPKI=false
1991       AC_MSG_ERROR([rtrlib was not found on your system or is too old.])]
1992   )
1993 fi
1994 AM_CONDITIONAL([RPKI], test "x$RPKI" = "xtrue")
1995
1996 dnl ------------------------------------------
1997 dnl Check whether rtrlib was build with ssh support
1998 dnl ------------------------------------------
1999 AC_MSG_CHECKING([whether the RTR Library is compiled with SSH])
2000 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "rtrlib/rtrlib.h"]],
2001                         [[struct tr_ssh_config config;]])],
2002         [AC_MSG_RESULT(yes)
2003         AC_DEFINE(FOUND_SSH,,found_ssh)],
2004         AC_MSG_RESULT(no)
2005 )
2006
2007 dnl ---------------------------
2008 dnl Check htonl works correctly
2009 dnl ---------------------------
2010 AC_MSG_CHECKING(for working htonl)
2011 AC_CACHE_VAL(ac_cv_htonl_works,
2012  [AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES],[htonl (0);])],
2013                 [ac_cv_htonl_works=yes], [ac_cv_htonl_works=no])
2014  ]
2015 )
2016 AC_MSG_RESULT($ac_cv_htonl_works)
2017
2018 AC_CONFIG_FILES([Makefile],[sed -e 's/^#AUTODERP# //' -i Makefile])
2019
2020 AC_CONFIG_FILES([
2021           redhat/frr.spec
2022           solaris/Makefile
2023           debianpkg/changelog
2024           alpine/APKBUILD
2025           snapcraft/snapcraft.yaml
2026           lib/version.h
2027           tests/lib/cli/test_cli.refout
2028           pkgsrc/bgpd.sh pkgsrc/ospf6d.sh pkgsrc/ospfd.sh
2029           pkgsrc/ripd.sh pkgsrc/ripngd.sh pkgsrc/zebra.sh
2030           pkgsrc/eigrpd.sh])
2031
2032 AC_CONFIG_FILES([vtysh/extract.pl],[chmod +x vtysh/extract.pl])
2033 AC_CONFIG_FILES([tools/frr],[chmod +x tools/frr])
2034
2035 AC_CONFIG_COMMANDS([lib/route_types.h], [
2036         dst="${ac_abs_top_builddir}/lib/route_types.h"
2037         ${PERL} "${ac_abs_top_srcdir}/lib/route_types.pl" \
2038                 < "${ac_abs_top_srcdir}/lib/route_types.txt" \
2039                 > "${dst}.tmp"
2040         test -f "${dst}" \
2041                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
2042                 && rm "${dst}.tmp" \
2043                 || mv "${dst}.tmp" "${dst}"
2044 ], [
2045         PERL="$PERL"
2046 ])
2047
2048 AS_IF([test "x$with_pkg_git_version" = "xyes"], [
2049     AC_CONFIG_COMMANDS([lib/gitversion.h], [
2050         dst="${ac_abs_top_builddir}/lib/gitversion.h"
2051         ${PERL} "${ac_abs_top_srcdir}/lib/gitversion.pl" \
2052                 "${ac_abs_top_srcdir}" \
2053                 > "${dst}.tmp"
2054         test -f "${dst}" \
2055                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
2056                 && rm "${dst}.tmp" \
2057                 || mv "${dst}.tmp" "${dst}"
2058     ], [
2059         PERL="$PERL"
2060     ])
2061 ])
2062
2063 ## Hack, but working solution to avoid rebuilding of frr.info.
2064 ## It's already in CVS until texinfo 4.7 is more common.
2065 AC_OUTPUT
2066
2067 echo "
2068 FRRouting configuration
2069 ------------------------------
2070 FRR version             : ${PACKAGE_VERSION}
2071 host operating system   : ${host_os}
2072 source code location    : ${srcdir}
2073 compiler                : ${CC}
2074 compiler flags          : ${CFLAGS} ${SAN_FLAGS}
2075 make                    : ${MAKE-make}
2076 linker flags            : ${LDFLAGS} ${SAN_FLAGS} ${LIBS} ${LIBCAP} ${LIBREADLINE} ${LIBM}
2077 state file directory    : ${frr_statedir}
2078 config file directory   : `eval echo \`echo ${sysconfdir}\``
2079 example directory       : `eval echo \`echo ${exampledir}\``
2080 module directory        : ${CFG_MODULE}
2081 user to run as          : ${enable_user}
2082 group to run as         : ${enable_group}
2083 group for vty sockets   : ${enable_vty_group}
2084 config file mask        : ${enable_configfile_mask}
2085 log file mask           : ${enable_logfile_mask}
2086 zebra protobuf enabled  : ${enable_protobuf:-no}
2087
2088 The above user and group must have read/write access to the state file
2089 directory and to the config files in the config file directory."
2090
2091 if test "${enable_doc}" != "no";then
2092   AS_IF([test "$SPHINXBUILD" = /bin/false],
2093      AC_MSG_WARN(sphinx-build is missing but required to build documentation))
2094 fi