configure.ac

   1 ##
   2 ## Configure template file for FRRouting.
   3 ## autoconf will generate configure script.
   4 ##
   5 ##  Copyright (c) 1996, 97, 98, 99, 2000 Kunihiro Ishiguro <kunihiro@zebra.org>
   6 ##  Portions Copyright (c) 2003 Paul Jakma <paul@dishone.st>
   7 ##
   8 AC_PREREQ(2.60)
   9
  10 AC_INIT(frr, 5.1-dev, [https://github.com/frrouting/frr/issues])
  11 PACKAGE_URL="https://frrouting.org/"
  12 AC_SUBST(PACKAGE_URL)
  13 PACKAGE_FULLNAME="FRRouting"
  14 AC_SUBST(PACKAGE_FULLNAME)
  15
  16 CONFIG_ARGS="$ac_configure_args"
  17 AC_SUBST(CONFIG_ARGS)
  18
  19 AC_CONFIG_SRCDIR(lib/zebra.h)
  20 AC_CONFIG_MACRO_DIR([m4])
  21
  22 dnl -----------------------------------
  23 dnl Get hostname and other information.
  24 dnl -----------------------------------
  25 AC_CANONICAL_BUILD()
  26 AC_CANONICAL_HOST()
  27
  28 AS_IF([test "$host" != "$build"], [
  29   if test "$srcdir" = "."; then
  30     AC_MSG_ERROR([cross-compilation is only possible with builddir separate from srcdir.  create a separate directory and run as .../path-to-frr/configure.])
  31   fi
  32   test -d hosttools || mkdir hosttools
  33   abssrc="`cd \"${srcdir}\"; pwd`"
  34
  35   AC_MSG_NOTICE([...])
  36   AC_MSG_NOTICE([... cross-compilation: creating hosttools directory and self-configuring for build platform tools])
  37   AC_MSG_NOTICE([... use HOST_CPPFLAGS / HOST_CFLAGS / HOST_LDFLAGS if neccessary])
  38   AC_MSG_NOTICE([...])
  39
  40   ( CPPFLAGS="$HOST_CPPFLAGS"; \
  41     CFLAGS="$HOST_CFLAGS"; \
  42     LDFLAGS="$HOST_LDFLAGS"; \
  43     cd hosttools; "${abssrc}/configure" "--host=$build" "--build=$build" "--enable-clippy-only" "--disable-nhrpd" "--disable-vtysh"; )
  44
  45   AC_MSG_NOTICE([...])
  46   AC_MSG_NOTICE([... cross-compilation: finished self-configuring for build platform tools])
  47   AC_MSG_NOTICE([...])
  48
  49   build_clippy="false"
  50   HOSTTOOLS="hosttools/"
  51 ], [
  52   build_clippy="true"
  53   HOSTTOOLS=""
  54 ])
  55 AC_SUBST(HOSTTOOLS)
  56 AM_CONDITIONAL([BUILD_CLIPPY], [$build_clippy])
  57
  58 # Disable portability warnings -- our automake code (in particular
  59 # common.am) uses some constructs specific to gmake.
  60 AM_INIT_AUTOMAKE([1.12 -Wno-portability])
  61 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
  62 AM_SILENT_RULES([yes])
  63 AC_CONFIG_HEADERS(config.h)
  64
  65 AC_PATH_PROG(PERL, perl)
  66 PKG_PROG_PKG_CONFIG
  67
  68 dnl default is to match previous behavior
  69 exampledir=${sysconfdir}
  70 AC_ARG_ENABLE([exampledir],
  71           AS_HELP_STRING([--enable-exampledir],
  72                          [specify alternate directory for examples]),
  73                          exampledir="$enableval",)
  74 dnl XXX add --exampledir to autoconf standard directory list somehow
  75 AC_SUBST(exampledir)
  76
  77 dnl default is to match previous behavior
  78 pkgsrcrcdir=""
  79 AC_ARG_ENABLE([pkgsrcrcdir],
  80           AS_HELP_STRING([--enable-pkgsrcrcdir],
  81                          [specify directory for rc.d scripts]),
  82                          pkgsrcrcdir="$enableval",)
  83 dnl XXX add --pkgsrcrcdir to autoconf standard directory list somehow
  84 AC_SUBST(pkgsrcrcdir)
  85 AM_CONDITIONAL([PKGSRC], [test "x$pkgsrcrcdir" != "x"])
  86
  87 AC_ARG_WITH([moduledir], [AS_HELP_STRING([--with-moduledir=DIR], [module directory (${libdir}/frr/modules)])], [
  88         moduledir="$withval"
  89 ], [
  90         moduledir="\${libdir}/frr/modules"
  91 ])
  92 AC_SUBST([moduledir], [$moduledir])
  93
  94 AC_ARG_ENABLE(tcmalloc,
  95         AS_HELP_STRING([--enable-tcmalloc], [Turn on tcmalloc]),
  96 [case "${enableval}" in
  97   yes) tcmalloc_enabled=true
  98 LIBS="$LIBS -ltcmalloc_minimal"
  99  ;;
 100   no)  tcmalloc_enabled=false ;;
 101   *) AC_MSG_ERROR(bad value ${enableval} for --enable-tcmalloc) ;;
 102 esac],[tcmalloc_enabled=false])
 103
 104
 105 dnl Thanks autoconf, but we don't want a default -g -O2.  We have our own
 106 dnl flag determination logic.
 107 CFLAGS="${CFLAGS:-}"
 108
 109 dnl --------------------
 110 dnl Check CC and friends
 111 dnl --------------------
 112 dnl note orig_cflags is also used further down
 113 orig_cflags="$CFLAGS"
 114 AC_LANG([C])
 115 AC_PROG_CC
 116 AC_PROG_CPP
 117 AM_PROG_CC_C_O
 118 dnl remove autoconf default "-g -O2"
 119 CFLAGS="$orig_cflags"
 120 AC_PROG_CC_C99
 121 dnl NB: see C11 below
 122
 123 AC_PROG_EGREP
 124 PKG_PROG_PKG_CONFIG
 125
 126 dnl autoconf 2.59 appears not to support AC_PROG_SED
 127 dnl AC_PROG_SED
 128 AC_CHECK_PROG([SED],[sed],[sed],[/bin/false])
 129
 130 dnl try and enable CFLAGS that are useful for FRR
 131 dnl - specifically, options to control warnings
 132
 133 AC_USE_SYSTEM_EXTENSIONS
 134 AC_DEFUN([AC_C_FLAG], [{
 135         AC_LANG_PUSH(C)
 136         ac_c_flag_save="$CFLAGS"
 137         CFLAGS="$CFLAGS $1"
 138         AC_MSG_CHECKING([[whether $CC supports $1]])
 139         AC_COMPILE_IFELSE(
 140                 [AC_LANG_PROGRAM([[]])],
 141                 [
 142                         AC_MSG_RESULT([yes])
 143                         m4_if([$3], [], [], [
 144                                 CFLAGS="$ac_c_flag_save"
 145                                 $3
 146                         ])
 147                 ], [
 148                         CFLAGS="$ac_c_flag_save"
 149                         AC_MSG_RESULT([no])
 150                         $2
 151                 ])
 152         AC_LANG_POP(C)
 153         }])
 154
 155 AC_DEFUN([AC_LINK_IFELSE_FLAGS], [{
 156         AC_LANG_PUSH(C)
 157         ac_cflags_save="$CFLAGS"
 158         ac_libs_save="$LIBS"
 159         CFLAGS="$CFLAGS $1"
 160         LIBS="$LIBS $2"
 161         AC_LINK_IFELSE(
 162                 [$3],
 163                 [
 164                         AC_MSG_RESULT([yes])
 165                         CFLAGS="$ac_cflags_save"
 166                         LIBS="$ac_libs_save"
 167                         $5
 168                 ], [
 169                         AC_MSG_RESULT([no])
 170                         CFLAGS="$ac_cflags_save"
 171                         LIBS="$ac_libs_save"
 172                         $4
 173                 ])
 174         AC_LANG_POP(C)
 175         }])
 176
 177 dnl ICC won't bail on unknown options without -diag-error 10006
 178 dnl need to do this first so we get useful results for the other options
 179 AC_C_FLAG([-diag-error 10006])
 180
 181 dnl AC_PROG_CC_C99 may change CC to include -std=gnu99 or something
 182 ac_cc="$CC"
 183 CC="${CC% -std=gnu99}"
 184 CC="${CC% -std=c99}"
 185
 186 AC_C_FLAG([-std=gnu11], [CC="$ac_cc"], [CC="$CC -std=gnu11"])
 187
 188 dnl AddressSanitizer support
 189 AC_ARG_ENABLE([address-sanitizer], AS_HELP_STRING([--enable-address-sanitizer], \
 190               [enabled AddressSanitizer support for detecting a wide variety of \
 191                memory allocation and deallocation errors]), \
 192               [AC_DEFINE(HAVE_ADDRESS_SANITIZER, 1, [enable AddressSanitizer])
 193               ASAN_FLAGS="-fsanitize=address"
 194               SAN_CLIPPY_FLAGS="-fno-sanitize=all"
 195               AC_SUBST([ASAN_FLAGS])
 196               AC_SUBST([SAN_CLIPPY_FLAGS])
 197               LIBS="-ldl $LIBS"
 198               AC_TRY_COMPILE([],[const int i=0;],[AC_MSG_NOTICE([Address Sanitizer Enabled])],
 199                                                  [AC_MSG_ERROR([Address Sanitizer not available])])
 200               ])
 201
 202 dnl ThreadSanitizer support
 203 AC_ARG_ENABLE([thread-sanitizer], AS_HELP_STRING([--enable-thread-sanitizer], \
 204               [enabled ThreadSanitizer support for detecting data races]), \
 205               [AC_DEFINE(HAVE_THREAD_SANITIZER, 1, [enable ThreadSanitizer])
 206               TSAN_FLAGS="-fsanitize=thread"
 207               SAN_CLIPPY_FLAGS="-fno-sanitize=all"
 208               AC_SUBST([TSAN_FLAGS])
 209               AC_SUBST([SAN_CLIPPY_FLAGS])
 210               LIBS="-ldl $LIBS"
 211               AC_TRY_COMPILE([],[const int i=0;],[AC_MSG_NOTICE([Thread Sanitizer Enabled])],
 212                                                  [AC_MSG_ERROR([Thread Sanitizer not available])])
 213               ])
 214
 215 dnl MemorySanitizer support
 216 AC_ARG_ENABLE([memory-sanitizer], AS_HELP_STRING([--enable-memory-sanitizer], \
 217               [enabled MemorySanitizer support for detecting uninitialized memory reads]), \
 218               [AC_DEFINE(HAVE_THREAD_SANITIZER, 1, [enable MemorySanitizer])
 219               MSAN_FLAGS="-fsanitize=memory -fPIE -pie"
 220               SAN_CLIPPY_FLAGS="-fno-sanitize=all"
 221               AC_SUBST([MSAN_FLAGS])
 222               AC_SUBST([SAN_CLIPPY_FLAGS])
 223               LIBS="-ldl $LIBS"
 224               AC_TRY_COMPILE([],[const int i=0;],[AC_MSG_NOTICE([Memory Sanitizer Enabled])],
 225                                                  [AC_MSG_ERROR([Memory Sanitizer not available])])
 226               ])
 227
 228 dnl if the user has specified any CFLAGS, override our settings
 229 if test "x${enable_gcov}" = "xyes"; then
 230    if test "z$orig_cflags" = "z"; then
 231       AC_C_FLAG([-coverage])
 232       AC_C_FLAG([-O0])
 233    fi
 234
 235    LDFLAGS="${LDFLAGS} -lgcov"
 236 elif test "x${enable_dev_build}" = "xyes"; then
 237    AC_DEFINE(DEV_BUILD,,Build for development)
 238    if test "z$orig_cflags" = "z"; then
 239       AC_C_FLAG([-g3])
 240       AC_C_FLAG([-O0])
 241    fi
 242 else
 243    if test "z$orig_cflags" = "z"; then
 244       AC_C_FLAG([-g])
 245       AC_C_FLAG([-Os], [
 246         AC_C_FLAG([-O2])
 247       ])
 248    fi
 249 fi
 250 AM_CONDITIONAL([DEV_BUILD], [test "x$enable_dev_build" = "xyes"])
 251
 252 dnl always want these CFLAGS
 253 AC_C_FLAG([-fno-omit-frame-pointer])
 254 AC_C_FLAG([-funwind-tables])
 255 AC_C_FLAG([-Wall])
 256 AC_C_FLAG([-Wextra])
 257 AC_C_FLAG([-Wmissing-prototypes])
 258 AC_C_FLAG([-Wmissing-declarations])
 259 AC_C_FLAG([-Wpointer-arith])
 260 AC_C_FLAG([-Wbad-function-cast])
 261 AC_C_FLAG([-Wwrite-strings])
 262 if test x"${enable_gcc_ultra_verbose}" = x"yes" ; then
 263   AC_C_FLAG([-Wcast-qual])
 264   AC_C_FLAG([-Wstrict-prototypes])
 265   AC_C_FLAG([-Wmissing-noreturn])
 266   AC_C_FLAG([-Wmissing-format-attribute])
 267   AC_C_FLAG([-Wunreachable-code])
 268   AC_C_FLAG([-Wpacked])
 269   AC_C_FLAG([-Wpadded])
 270 else
 271   AC_C_FLAG([-Wno-unused-result])
 272 fi
 273 AC_C_FLAG([-Wno-unused-parameter])
 274 AC_C_FLAG([-Wno-missing-field-initializers])
 275
 276 dnl ICC emits a broken warning for const char *x = a ? "b" : "c";
 277 dnl for some reason the string consts get 'promoted' to char *,
 278 dnl triggering a const to non-const conversion warning.
 279 AC_C_FLAG([-diag-disable 3179])
 280
 281 if test x"${enable_werror}" = x"yes" ; then
 282   WERROR="-Werror"
 283 fi
 284 AC_SUBST(WERROR)
 285
 286 dnl need link on this one, not compile
 287 AC_LANG_PUSH(C)
 288 ac_ld_flag_save="$LDFLAGS"
 289 LDFLAGS="$LDFLAGS -rdynamic"
 290 AC_MSG_CHECKING([[whether linker supports -rdynamic]])
 291 AC_LINK_IFELSE(
 292         [AC_LANG_PROGRAM([[]])],
 293         [AC_MSG_RESULT([yes])],
 294         [
 295                 LDFLAGS="$ac_ld_flag_save"
 296                 AC_MSG_RESULT([no])
 297         ])
 298 AC_LANG_POP(C)
 299
 300 dnl ----------
 301 dnl Essentials
 302 dnl ----------
 303
 304 AX_PTHREAD([
 305   CC="$PTHREAD_CC"
 306   CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 307   LIBS="$PTHREAD_LIBS $LIBS"
 308 ], [
 309   AC_MSG_FAILURE([This FRR version needs pthreads])
 310 ])
 311
 312 dnl --------------
 313 dnl Check programs
 314 dnl --------------
 315 AC_PROG_INSTALL
 316 AC_PROG_LN_S
 317 AC_PROG_MAKE_SET
 318 AC_CHECK_TOOL(AR, ar)
 319
 320 dnl -----------------
 321 dnl System extensions
 322 dnl -----------------
 323 AC_GNU_SOURCE
 324
 325 dnl -------
 326 dnl libtool
 327 dnl -------
 328 LT_INIT
 329
 330 dnl ----------------------
 331 dnl Packages configuration
 332 dnl ----------------------
 333 AC_ARG_WITH(pkg-extra-version,
 334         AS_HELP_STRING([--with-pkg-extra-version=VER], [add extra version field, for packagers/distributions]),
 335         [EXTRAVERSION=$withval],)
 336 AC_ARG_WITH(pkg-git-version,
 337         AS_HELP_STRING([--with-pkg-git-version], [add git information to MOTD and build version string]),
 338         [ test "x$withval" != "xno" && with_pkg_git_version="yes" ])
 339 AC_ARG_WITH(vtysh_pager,
 340         AS_HELP_STRING([--with-vtysh-pager=PAGER], [control what pager is compiled in as default]),
 341         VTYSH_PAGER=$withval, VTYSH_PAGER="more")
 342 AC_ARG_ENABLE(vtysh,
 343   AS_HELP_STRING([--disable-vtysh], [do not build integrated vty shell for FRR]))
 344 AC_ARG_ENABLE(doc,
 345   AS_HELP_STRING([--disable-doc], [do not build docs]))
 346 AC_ARG_ENABLE(zebra,
 347   AS_HELP_STRING([--disable-zebra], [do not build zebra daemon]))
 348 AC_ARG_ENABLE(bgpd,
 349   AS_HELP_STRING([--disable-bgpd], [do not build bgpd]))
 350 AC_ARG_ENABLE(ripd,
 351   AS_HELP_STRING([--disable-ripd], [do not build ripd]))
 352 AC_ARG_ENABLE(ripngd,
 353   AS_HELP_STRING([--disable-ripngd], [do not build ripngd]))
 354 AC_ARG_ENABLE(ospfd,
 355   AS_HELP_STRING([--disable-ospfd], [do not build ospfd]))
 356 AC_ARG_ENABLE(ospf6d,
 357   AS_HELP_STRING([--disable-ospf6d], [do not build ospf6d]))
 358 AC_ARG_ENABLE(ldpd,
 359   AS_HELP_STRING([--disable-ldpd], [do not build ldpd]))
 360 AC_ARG_ENABLE(nhrpd,
 361   AS_HELP_STRING([--disable-nhrpd], [do not build nhrpd]))
 362 AC_ARG_ENABLE(eigrpd,
 363   AS_HELP_STRING([--disable-eigrpd], [do not build eigrpd]))
 364 AC_ARG_ENABLE(babeld,
 365   AS_HELP_STRING([--disable-babeld], [do not build babeld]))
 366 AC_ARG_ENABLE(watchfrr,
 367   AS_HELP_STRING([--disable-watchfrr], [do not build watchfrr]))
 368 AC_ARG_ENABLE(isisd,
 369   AS_HELP_STRING([--disable-isisd], [do not build isisd]))
 370 AC_ARG_ENABLE(pimd,
 371   AS_HELP_STRING([--disable-pimd], [do not build pimd]))
 372 AC_ARG_ENABLE(pbrd,
 373   AS_HELP_STRING([--disable-pbrd], [do not build pbrd]))
 374 AC_ARG_ENABLE(sharpd,
 375   AS_HELP_STRING([--enable-sharpd], [build sharpd]))
 376 AC_ARG_ENABLE(staticd,
 377   AS_HELP_STRING([--disable-staticd], [do not build staticd]))
 378 AC_ARG_ENABLE(bgp-announce,
 379   AS_HELP_STRING([--disable-bgp-announce,], [turn off BGP route announcement]))
 380 AC_ARG_ENABLE(bgp-vnc,
 381   AS_HELP_STRING([--disable-bgp-vnc],[turn off BGP VNC support]))
 382 AC_ARG_WITH(rfp-path,
 383   AS_HELP_STRING([--with-rfp-path[=DIR]],[path to replaced stub RFP used with BGP VNC]))
 384 AC_ARG_ENABLE(snmp,
 385   AS_HELP_STRING([--enable-snmp=ARG], [enable SNMP support (smux or agentx)]))
 386 AC_ARG_ENABLE(zeromq,
 387   AS_HELP_STRING([--enable-zeromq], [enable ZeroMQ handler (libfrrzmq)]))
 388 AC_ARG_WITH(libpam,
 389   AS_HELP_STRING([--with-libpam], [use libpam for PAM support in vtysh]))
 390 AC_ARG_ENABLE(ospfapi,
 391   AS_HELP_STRING([--disable-ospfapi], [do not build OSPFAPI to access the OSPF LSA Database]))
 392 AC_ARG_ENABLE(ospfclient,
 393   AS_HELP_STRING([--disable-ospfclient], [do not build OSPFAPI client for OSPFAPI,
 394                           (this is the default if --disable-ospfapi is set)]))
 395 AC_ARG_ENABLE(multipath,
 396   AS_HELP_STRING([--enable-multipath=ARG], [enable multipath function, ARG must be digit]))
 397 AC_ARG_ENABLE(user,
 398   AS_HELP_STRING([--enable-user=USER], [user to run FRR suite as (default frr)]))
 399 AC_ARG_ENABLE(group,
 400   AS_HELP_STRING([--enable-group=GROUP], [group to run FRR suite as (default frr)]))
 401 AC_ARG_ENABLE(vty_group,
 402   AS_HELP_STRING([--enable-vty-group=ARG], [set vty sockets to have specified group as owner]))
 403 AC_ARG_ENABLE(configfile_mask,
 404   AS_HELP_STRING([--enable-configfile-mask=ARG], [set mask for config files]))
 405 AC_ARG_ENABLE(logfile_mask,
 406   AS_HELP_STRING([--enable-logfile-mask=ARG], [set mask for log files]))
 407 AC_ARG_ENABLE(shell_access,
 408   AS_HELP_STRING([--enable-shell-access], [Allow users to access shell/telnet/ssh]))
 409 AC_ARG_ENABLE(realms,
 410   AS_HELP_STRING([--enable-realms], [enable REALMS support under Linux]))
 411 AC_ARG_ENABLE(rtadv,
 412   AS_HELP_STRING([--disable-rtadv], [disable IPV6 router advertisement feature]))
 413 AC_ARG_ENABLE(irdp,
 414   AS_HELP_STRING([--disable-irdp], [enable IRDP server support in zebra (default if supported)]))
 415 AC_ARG_ENABLE(capabilities,
 416   AS_HELP_STRING([--disable-capabilities], [disable using POSIX capabilities]))
 417 AC_ARG_ENABLE(rusage,
 418   AS_HELP_STRING([--disable-rusage], [disable using getrusage]))
 419 AC_ARG_ENABLE(gcc_ultra_verbose,
 420   AS_HELP_STRING([--enable-gcc-ultra-verbose], [enable ultra verbose GCC warnings]))
 421 AC_ARG_ENABLE(linux24_tcp_md5,
 422   AS_HELP_STRING([--enable-linux24-tcp-md5], [enable support for old, Linux-2.4 RFC2385 patch]))
 423 AC_ARG_ENABLE(backtrace,
 424   AS_HELP_STRING([--disable-backtrace,], [disable crash backtraces (default autodetect)]))
 425 AC_ARG_ENABLE(time-check,
 426   AS_HELP_STRING([--disable-time-check], [disable slow thread warning messages]))
 427 AC_ARG_ENABLE(pcreposix,
 428   AS_HELP_STRING([--enable-pcreposix], [enable using PCRE Posix libs for regex functions]))
 429 AC_ARG_ENABLE(fpm,
 430   AS_HELP_STRING([--enable-fpm], [enable Forwarding Plane Manager support]))
 431 AC_ARG_ENABLE(systemd,
 432   AS_HELP_STRING([--enable-systemd], [enable Systemd support]))
 433 AC_ARG_ENABLE(werror,
 434   AS_HELP_STRING([--enable-werror], [enable -Werror (recommended for developers only)]))
 435 AC_ARG_ENABLE(cumulus,
 436   AS_HELP_STRING([--enable-cumulus], [enable Cumulus Switch Special Extensions]))
 437 AC_ARG_ENABLE(datacenter,
 438   AS_HELP_STRING([--enable-datacenter], [enable Compilation for Data Center Extensions]))
 439 AC_ARG_ENABLE(fuzzing,
 440   AS_HELP_STRING([--enable-fuzzing], [enable ability to fuzz various parts of FRR]))
 441 AC_ARG_ENABLE(netlink_fuzzing,
 442   AS_HELP_STRING([--enable-netlink-fuzzing], [enable ability to fuzz netlink listening socket in zebra]))
 443 AC_ARG_ENABLE(rr-semantics,
 444   AS_HELP_STRING([--disable-rr-semantics], [disable the v6 Route Replace semantics]))
 445 AC_ARG_ENABLE([protobuf],
 446   AS_HELP_STRING([--enable-protobuf], [Enable experimental protobuf support]))
 447 AC_ARG_ENABLE([oldvpn_commands],
 448   AS_HELP_STRING([--enable-oldvpn-commands], [Keep old vpn commands]))
 449 AC_ARG_ENABLE(rpki,
 450   AS_HELP_STRING([--enable-rpki], [enable RPKI prefix validation support]))
 451 AC_ARG_ENABLE([clippy-only],
 452   AS_HELP_STRING([--enable-clippy-only], [Only build clippy]))
 453 AC_ARG_ENABLE([numeric_version],
 454   AS_HELP_STRING([--enable-numeric-version], [Only numeric digits allowed in version (for Alpine)]))
 455 AC_ARG_ENABLE([gcov],
 456   AS_HELP_STRING([--enable-gcov], [Add code coverage information]))
 457
 458 AS_IF([test "${enable_clippy_only}" != "yes"], [
 459 AC_CHECK_HEADERS(json-c/json.h)
 460 AC_CHECK_LIB(json-c, json_object_get, LIBS="$LIBS -ljson-c", [], [-lm])
 461 if test $ac_cv_lib_json_c_json_object_get = no; then
 462   AC_CHECK_LIB(json, json_object_get, LIBS="$LIBS -ljson")
 463   if test $ac_cv_lib_json_json_object_get = no; then
 464       AC_MSG_ERROR([lib json is needed to compile])
 465   fi
 466 fi
 467 ])
 468
 469 AC_ARG_ENABLE([dev_build],
 470     AS_HELP_STRING([--enable-dev-build], [build for development]))
 471
 472 if test x"${enable_time_check}" != x"no" ; then
 473   if test x"${enable_time_check}" = x"yes" -o x"${enable_time_check}" = x ; then
 474     AC_DEFINE(CONSUMED_TIME_CHECK,5000000,Consumed Time Check)
 475   else
 476     AC_DEFINE_UNQUOTED(CONSUMED_TIME_CHECK,$enable_time_check,Consumed Time Check)
 477   fi
 478 fi
 479
 480 case "${enable_systemd}" in
 481   "no") ;;
 482   "yes")
 483   AC_CHECK_LIB(systemd, sd_notify, LIBS="$LIBS -lsystemd")
 484   if test $ac_cv_lib_systemd_sd_notify = no; then
 485     AC_MSG_ERROR([enable systemd has been specified but systemd development env not found on your system])
 486   else
 487     AC_DEFINE(HAVE_SYSTEMD,,Compile systemd support in)
 488   fi
 489   ;;
 490   "*") ;;
 491 esac
 492
 493 if test "${enable_rr_semantics}" != "no" ; then
 494   AC_DEFINE(HAVE_V6_RR_SEMANTICS,, Compile in v6 Route Replacement Semantics)
 495 fi
 496
 497 if test "${enable_datacenter}" = "yes" ; then
 498   AC_DEFINE(HAVE_DATACENTER,,Compile extensions for a DataCenter)
 499   DFLT_NAME="datacenter"
 500 else
 501   DFLT_NAME="traditional"
 502 fi
 503
 504 if test "${enable_fuzzing}" = "yes" ; then
 505   AC_DEFINE(HANDLE_ZAPI_FUZZING,,Compile extensions to use with a fuzzer)
 506 fi
 507
 508 if test "${enable_netlink_fuzzing}" = "yes" ; then
 509   AC_DEFINE(HANDLE_NETLINK_FUZZING,,Compile extensions to use with a fuzzer for netlink)
 510 fi
 511
 512 if test "${enable_cumulus}" = "yes" ; then
 513   AC_DEFINE(HAVE_CUMULUS,,Compile Special Cumulus Code in)
 514 fi
 515
 516 AC_SUBST(DFLT_NAME)
 517 AC_DEFINE_UNQUOTED(DFLT_NAME,["$DFLT_NAME"], Name of the configuration default set)
 518
 519 if test "${enable_shell_access}" = "yes"; then
 520    AC_DEFINE(HAVE_SHELL_ACCESS,,Allow user to use ssh/telnet/bash)
 521 fi
 522
 523 AM_CONDITIONAL([FPM], [test "x$enable_fpm" = "xyes"])
 524
 525 #
 526 # Python for clippy
 527 #
 528 AS_IF([test "$host" = "$build"], [
 529   PYTHONCONFIG=""
 530
 531   # ordering:
 532   # 1.  try python3, but respect the user's preference on which minor ver
 533   # 2.  try python, which might be py3 or py2 again on the user's preference
 534   # 3.  try python2 (can really only be 2.7 but eh)
 535   # 4.  try 3.5 > 3.4 > 3.3 > 3.2 > 2.7 through pkg-config (no user pref)
 536   #
 537   # (AX_PYTHON_DEVEL has no clue about py3 vs py2)
 538   # (AX_PYTHON does not do what we need)
 539
 540   AC_CHECK_TOOLS([PYTHONCONFIG], [python3-config python-config python2-config])
 541   if test -n "$PYTHONCONFIG"; then
 542     PYTHON_CFLAGS="`\"${PYTHONCONFIG}\" --includes`"
 543     PYTHON_LIBS="`\"${PYTHONCONFIG}\" --libs`"
 544
 545     AC_MSG_CHECKING([whether we found a working Python version])
 546     AC_LINK_IFELSE_FLAGS([$PYTHON_CFLAGS], [$PYTHON_LIBS], [AC_LANG_PROGRAM([
 547 #include <Python.h>
 548 #if PY_VERSION_HEX < 0x02070000
 549 #error python too old
 550 #endif
 551 int main(void);
 552 ],
 553 [
 554 {
 555   Py_Initialize();
 556   return 0;
 557 }
 558 ])], [
 559       PYTHONCONFIG=""
 560       unset PYTHON_LIBS
 561       unset PYTHON_CFLAGS
 562     ])
 563   fi
 564
 565   if test -z "$PYTHONCONFIG"; then
 566     PKG_CHECK_MODULES([PYTHON], python-3.5, [], [
 567       PKG_CHECK_MODULES([PYTHON], python-3.4, [], [
 568         PKG_CHECK_MODULES([PYTHON], python-3.3, [], [
 569           PKG_CHECK_MODULES([PYTHON], python-3.2, [], [
 570             PKG_CHECK_MODULES([PYTHON], python-2.7, [], [
 571               AC_MSG_FAILURE([could not find python-config or pkg-config python, please install Python development files from libpython-dev or similar])
 572               ])])])])])
 573
 574
 575     AC_MSG_CHECKING([whether we found a working Python version])
 576     AC_LINK_IFELSE_FLAGS([$PYTHON_CFLAGS], [$PYTHON_LIBS], [AC_LANG_PROGRAM([
 577 #include <Python.h>
 578 #if PY_VERSION_HEX < 0x02070000
 579 #error python too old
 580 #endif
 581 int main(void);
 582 ],
 583 [
 584 {
 585   Py_Initialize();
 586   return 0;
 587 }
 588 ])], [
 589       AC_MSG_FAILURE([could not find python-config or pkg-config python, please install Python development files from libpython-dev or similar])
 590     ])
 591   fi
 592 ])
 593 AC_SUBST(PYTHON_CFLAGS)
 594 AC_SUBST(PYTHON_LIBS)
 595
 596 #
 597 # Logic for protobuf support.
 598 #
 599 if test "$enable_protobuf" = "yes"; then
 600    have_protobuf=yes
 601
 602    # Check for protoc-c
 603    AC_CHECK_PROG([PROTOC_C], [protoc-c], [protoc-c], [/bin/false])
 604    if test "x$PROTOC_C" = "x/bin/false"; then
 605       have_protobuf=no
 606    else
 607       found_protobuf_c=no
 608       PKG_CHECK_MODULES([PROTOBUF_C], libprotobuf-c >= 0.14,
 609                      [found_protobuf_c=yes],
 610                      [AC_MSG_RESULT([pkg-config did not find libprotobuf-c])])
 611
 612       if test "x$found_protobuf_c" = "xyes"; then
 613          LDFLAGS="$LDFLAGS $PROTOBUF_C_LIBS"
 614          CFLAGS="$CFLAGS $PROTOBUF_C_CFLAGS"
 615       else
 616         AC_CHECK_HEADER([google/protobuf-c/protobuf-c.h], [],
 617                         [have_protobuf=no; AC_MSG_RESULT([Couldn't find google/protobuf-c.h])])
 618       fi
 619    fi
 620 fi
 621
 622 #
 623 # Logic for old vpn commans support.
 624 #
 625 if test "$enable_oldvpn_commands" = "yes"; then
 626    AC_DEFINE(KEEP_OLD_VPN_COMMANDS,, [Define for compiling with old vpn commands])
 627 fi
 628
 629 # Fail if the user explicity enabled protobuf support and we couldn't
 630 # find the compiler or libraries.
 631 if test "x$have_protobuf" = "xno" && test "x$enable_protobuf" = "xyes"; then
 632    AC_MSG_ERROR([Protobuf enabled explicitly but can't find libraries/tools])
 633 fi
 634
 635 if test "x$have_protobuf" = "xyes"; then
 636    AC_DEFINE(HAVE_PROTOBUF,, protobuf)
 637 fi
 638
 639 AM_CONDITIONAL([HAVE_PROTOBUF], [test "x$have_protobuf" = "xyes"])
 640
 641 #
 642 # End of logic for protobuf support.
 643 #
 644
 645 if test "${enable_linux24_tcp_md5}" = "yes"; then
 646   AC_DEFINE(HAVE_TCP_MD5_LINUX24,,Old Linux 2.4 TCP MD5 Signature Patch)
 647 fi
 648
 649 AC_MSG_CHECKING(if zebra should be configurable to send Route Advertisements)
 650 if test "${enable_rtadv}" != "no"; then
 651   AC_MSG_RESULT(yes)
 652   AC_DEFINE(HAVE_RTADV,,Enable IPv6 Routing Advertisement support)
 653 else
 654   AC_MSG_RESULT(no)
 655 fi
 656
 657 if test x"${enable_user}" = x"no"; then
 658   enable_user=""
 659 else
 660   if test x"${enable_user}" = x"yes" || test x"${enable_user}" = x""; then
 661     enable_user="frr"
 662   fi
 663   AC_DEFINE_UNQUOTED(FRR_USER, "${enable_user}", frr User)
 664 fi
 665
 666 if test x"${enable_group}" = x"no"; then
 667   enable_group=""
 668 else
 669   if test x"${enable_group}" = x"yes" || test x"${enable_group}" = x""; then
 670     enable_group="frr"
 671   fi
 672   AC_DEFINE_UNQUOTED(FRR_GROUP, "${enable_group}", frr Group)
 673 fi
 674
 675 if test x"${enable_vty_group}" = x"yes" ; then
 676   AC_MSG_ERROR([--enable-vty-group requires a group as argument, not yes])
 677 elif test x"${enable_vty_group}" != x""; then
 678   if test x"${enable_vty_group}" != x"no"; then
 679     AC_DEFINE_UNQUOTED(VTY_GROUP, "${enable_vty_group}", VTY Sockets Group)
 680   fi
 681 fi
 682 AC_SUBST([enable_user])
 683 AC_SUBST([enable_group])
 684 AC_SUBST([enable_vty_group])
 685
 686 enable_configfile_mask=${enable_configfile_mask:-0600}
 687 AC_DEFINE_UNQUOTED(CONFIGFILE_MASK, ${enable_configfile_mask}, Mask for config files)
 688
 689 enable_logfile_mask=${enable_logfile_mask:-0600}
 690 AC_DEFINE_UNQUOTED(LOGFILE_MASK, ${enable_logfile_mask}, Mask for log files)
 691
 692 MPATH_NUM=1
 693
 694 case "${enable_multipath}" in
 695   0)
 696     MPATH_NUM=64
 697     ;;
 698   [[1-9]|[1-9][0-9]|[1-9][0-9][0-9]])
 699     MPATH_NUM="${enable_multipath}"
 700     ;;
 701   "")
 702     ;;
 703   *)
 704     AC_MSG_FAILURE([Please specify digit to enable multipath ARG])
 705     ;;
 706 esac
 707
 708 AC_DEFINE_UNQUOTED(MULTIPATH_NUM, $MPATH_NUM, Maximum number of paths for a route)
 709
 710 AC_DEFINE_UNQUOTED(VTYSH_PAGER, "$VTYSH_PAGER", [What pager to use])
 711
 712 dnl --------------------
 713 dnl Enable code coverage
 714 dnl --------------------
 715 AM_CONDITIONAL([HAVE_GCOV],[test '!' "$enable_gcov" = no])
 716
 717 dnl ------------------------------------
 718 dnl Alpine only accepts numeric versions
 719 dnl ------------------------------------
 720 if test "x${enable_numeric_version}" != "x" ; then
 721   VERSION="`echo ${VERSION} | tr -c -d '[[.0-9]]'`"
 722   PACKAGE_VERSION="`echo ${PACKAGE_VERSION} | tr -c -d '[[.0-9]]'`"
 723 fi
 724
 725 dnl -----------------------------------
 726 dnl Add extra version string to package
 727 dnl name, string and version fields.
 728 dnl -----------------------------------
 729 if test "x${EXTRAVERSION}" != "x" ; then
 730   VERSION="${VERSION}${EXTRAVERSION}"
 731   PACKAGE_VERSION="${PACKAGE_VERSION}${EXTRAVERSION}"
 732   AC_SUBST(PACKAGE_EXTRAVERSION, ["${EXTRAVERSION}"])
 733   PACKAGE_STRING="${PACKAGE_STRING}${EXTRAVERSION}"
 734 fi
 735
 736 if test "x$with_pkg_git_version" = "xyes"; then
 737         if test -d "${srcdir}/.git"; then
 738                 AC_DEFINE(GIT_VERSION, [1], [include git version info])
 739         else    with_pkg_git_version="no"
 740                 AC_MSG_WARN([--with-pkg-git-version given, but this is not a git checkout])
 741         fi
 742 fi
 743 AM_CONDITIONAL([GIT_VERSION], [test "x$with_pkg_git_version" = "xyes"])
 744
 745 dnl ------------------------------------
 746 dnl Check C keywords and standard  types
 747 dnl ------------------------------------
 748 AC_C_CONST
 749 AC_C_INLINE
 750 AC_C_VOLATILE
 751 AC_HEADER_STDC
 752 dnl AC_TYPE_PID_T
 753 AC_TYPE_UID_T
 754 AC_TYPE_MODE_T
 755 AC_TYPE_SIZE_T
 756 AC_STRUCT_TM
 757
 758 dnl -------------------------
 759 dnl Check other header files.
 760 dnl -------------------------
 761 AC_CHECK_HEADERS([stropts.h sys/ksym.h \
 762         linux/version.h asm/types.h \
 763         sys/cdefs.h])
 764
 765 ac_stdatomic_ok=false
 766 AC_DEFINE(FRR_AUTOCONF_ATOMIC, 1, [did autoconf checks for atomic funcs])
 767 AC_CHECK_HEADER([stdatomic.h],[
 768
 769   AC_MSG_CHECKING([whether _Atomic qualifier works])
 770   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 771 #include <stdatomic.h>
 772 int main(int argc, char **argv) {
 773   _Atomic int i = 0;
 774   return i;
 775 }
 776 ]])], [
 777     AC_DEFINE(HAVE_STDATOMIC_H, 1, [found stdatomic.h])
 778     AC_MSG_RESULT([yes])
 779     ac_stdatomic_ok=true
 780   ], [
 781     AC_MSG_RESULT([no])
 782   ])
 783 ])
 784
 785 AS_IF([$ac_stdatomic_ok], [true], [
 786   AC_MSG_CHECKING([for __atomic_* builtins])
 787   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 788 int main(int argc, char **argv) {
 789   volatile int i = 1;
 790   __atomic_store_n (&i, 0, __ATOMIC_RELEASE);
 791   return __atomic_load_n (&i, __ATOMIC_ACQUIRE);
 792 }
 793 ]])], [
 794     AC_DEFINE(HAVE___ATOMIC, 1, [found __atomic builtins])
 795     AC_MSG_RESULT([yes])
 796   ], [
 797     AC_MSG_RESULT([no])
 798
 799     dnl FreeBSD 9 has a broken stdatomic.h where _Atomic doesn't work
 800     AC_MSG_CHECKING([for __sync_* builtins])
 801     AC_LINK_IFELSE([AC_LANG_SOURCE([[
 802 int main(int argc, char **argv) {
 803   volatile int i = 1;
 804   __sync_fetch_and_sub (&i, 1);
 805   return __sync_val_compare_and_swap (&i, 0, 1);
 806 }
 807 ]])], [
 808       AC_DEFINE(HAVE___SYNC, 1, [found __sync builtins])
 809       AC_MSG_RESULT([yes])
 810
 811       AC_MSG_CHECKING([for __sync_swap builtin])
 812       AC_LINK_IFELSE([AC_LANG_SOURCE([[
 813 int main(int argc, char **argv) {
 814   volatile int i = 1;
 815   return __sync_swap (&i, 2);
 816 }
 817 ]])], [
 818         AC_DEFINE(HAVE___SYNC_SWAP, 1, [found __sync_swap builtin])
 819         AC_MSG_RESULT([yes])
 820       ], [
 821         AC_MSG_RESULT([no])
 822       ])
 823
 824     ], [
 825       AC_MSG_RESULT([no])
 826       AC_MSG_FAILURE([stdatomic.h unavailable and $CC has neither __atomic nor __sync builtins])
 827     ])
 828   ])
 829 ])
 830
 831 dnl Utility macro to avoid retyping includes all the time
 832 m4_define([FRR_INCLUDES],
 833 [#ifdef SUNOS_5
 834 #define _XPG4_2
 835 #define __EXTENSIONS__
 836 #endif
 837 #include <stdio.h>
 838 #include <stdlib.h>
 839 #include <stddef.h>
 840 #include <sys/types.h>
 841 /* sys/conf.h depends on param.h on FBSD at least */
 842 #include <sys/param.h>
 843 /* Required for MAXSIG */
 844 #include <signal.h>
 845 #include <sys/socket.h>
 846 #ifdef __APPLE__
 847 # define __APPLE_USE_RFC_3542
 848 #endif
 849 #include <netinet/in.h>
 850 #include <sys/time.h>
 851 #include <time.h>
 852 #include <net/if.h>
 853 ])dnl
 854
 855 dnl Same applies for HAVE_NET_IF_VAR_H, which HAVE_NETINET6_ND6_H and
 856 dnl HAVE_NETINET_IN_VAR_H depend upon. But if_var.h depends on if.h, hence
 857 dnl an additional round for it.
 858
 859 AC_CHECK_HEADERS([net/if_var.h], [], [], FRR_INCLUDES)
 860
 861 m4_define([FRR_INCLUDES],
 862 FRR_INCLUDES
 863 [#if HAVE_NET_IF_VAR_H
 864 # include <net/if_var.h>
 865 #endif
 866 ])dnl
 867
 868 AC_CHECK_HEADERS([netinet/in_var.h \
 869         net/if_dl.h net/netopt.h \
 870         inet/nd.h netinet/ip_icmp.h \
 871         sys/sysctl.h sys/sockio.h kvm.h sys/conf.h],
 872         [], [], FRR_INCLUDES)
 873
 874 AC_CHECK_HEADERS([ucontext.h], [], [],
 875 [#ifndef __USE_GNU
 876 #define __USE_GNU
 877 #endif /* __USE_GNU */
 878 FRR_INCLUDES
 879 ])
 880
 881 m4_define([UCONTEXT_INCLUDES],
 882 [#include <ucontext.h>])dnl
 883
 884 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.uc_regs],
 885   [], [], [UCONTEXT_INCLUDES])
 886 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs],
 887   [AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs.nip],
 888    [], [], [UCONTEXT_INCLUDES])],
 889   [], [UCONTEXT_INCLUDES])
 890 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.gregs],
 891   [], [], [UCONTEXT_INCLUDES])
 892
 893 m4_define([FRR_INCLUDES],
 894 FRR_INCLUDES
 895 [
 896 #include <sys/un.h>
 897 #include <netinet/in_systm.h>
 898 #if HAVE_NETINET_IN_VAR_H
 899 # include <netinet/in_var.h>
 900 #endif
 901 #if HAVE_NET_IF_DL_H
 902 # include <net/if_dl.h>
 903 #endif
 904 #if HAVE_NET_NETOPT_H
 905 # include <net/netopt.h>
 906 #endif
 907 #include <net/route.h>
 908 #if HAVE_INET_ND_H
 909 # include <inet/nd.h>
 910 #endif
 911 #include <arpa/inet.h>
 912 /* Required for IDRP */
 913 #if HAVE_NETINET_IP_ICMP_H
 914 # include <netinet/ip_icmp.h>
 915 #endif
 916 ])dnl
 917
 918 dnl V6 headers are checked below, after we check for v6
 919
 920 AC_MSG_CHECKING([which operating system interface to use])
 921 case "$host_os" in
 922   sunos* | solaris2*)
 923     AC_MSG_RESULT([Solaris])
 924
 925     AC_DEFINE(SUNOS_5, 1, [SunOS 5])
 926     AC_DEFINE(SOLARIS_IPV6, 1, Solaris IPv6)
 927
 928     AC_CHECK_LIB(socket, main)
 929     AC_CHECK_LIB(nsl, main)
 930     AC_CHECK_LIB(umem, main)
 931     AC_CHECK_FUNCS([printstack], [
 932       AC_DEFINE([HAVE_PRINTSTACK],1,[Solaris printstack])
 933       AC_DEFINE([HAVE_STACK_TRACE],1,[Stack symbols decode functionality])
 934     ])
 935     CURSES=-lcurses
 936     SOLARIS="solaris"
 937     ;;
 938   linux*)
 939     AC_MSG_RESULT([Linux])
 940
 941     AC_DEFINE(GNU_LINUX,,GNU Linux)
 942     AC_DEFINE(HAVE_NETLINK,,netlink)
 943     AC_DEFINE(LINUX_IPV6,1,Linux IPv6 stack)
 944
 945     dnl Linux has a compilation problem with mixing
 946     dnl netinet/in.h and linux/in6.h they are not
 947     dnl compatible.  There has been discussion on
 948     dnl how to fix it but no real progress on implementation
 949     dnl when they fix it, remove this
 950     AC_DEFINE(IPV6_MINHOPCOUNT, 73, Linux ipv6 Min Hop Count)
 951     ;;
 952   openbsd*)
 953     AC_MSG_RESULT([OpenBSD])
 954
 955     AC_DEFINE(OPEN_BSD,,OpenBSD)
 956     AC_DEFINE(KAME,1,KAME IPv6)
 957     AC_DEFINE(BSD_V6_SYSCTL,1,BSD v6 sysctl to turn on and off forwarding)
 958
 959     if test "x${enable_pimd}" != "xno"; then
 960       case "$host_os" in
 961       openbsd6.0)
 962         ;;
 963       openbsd[6-9]*)
 964         AC_MSG_FAILURE([pimd cannot be enabled as PIM support has been removed from OpenBSD 6.1])
 965         ;;
 966       esac
 967     fi
 968     ;;
 969   *)
 970     AC_MSG_RESULT([BSD])
 971
 972     AC_DEFINE(HAVE_NET_RT_IFLIST,,NET_RT_IFLIST)
 973     AC_DEFINE(KAME,1,KAME IPv6)
 974     AC_DEFINE(BSD_V6_SYSCTL,1,BSD v6 sysctl to turn on and off forwarding)
 975     ;;
 976 esac
 977 AM_CONDITIONAL(SOLARIS, test "${SOLARIS}" = "solaris")
 978
 979 AC_SYS_LARGEFILE
 980
 981 dnl ------------------------
 982 dnl Integrated REALMS option
 983 dnl ------------------------
 984 if test "${enable_realms}" = "yes"; then
 985     case "$host_os" in
 986       linux*)
 987        AC_DEFINE(SUPPORT_REALMS,, Realms support)
 988        ;;
 989       *)
 990        echo "Sorry, only Linux has REALMS support"
 991        exit 1
 992        ;;
 993     esac
 994 fi
 995 AM_CONDITIONAL([SUPPORT_REALMS], [test "${enable_realms}" = "yes"])
 996
 997 dnl ---------------------
 998 dnl Integrated VTY option
 999 dnl ---------------------
1000 case "${enable_vtysh}" in
1001   "no") VTYSH="";;
1002   *)    VTYSH="vtysh";
1003          AC_DEFINE(VTYSH,,VTY shell)
1004 dnl      Vtysh uses libreadline, which looks for termcap functions at
1005 dnl      configure time.  We follow readlines search order.
1006 dnl      The required procedures are in libtermcap on NetBSD, in
1007 dnl      [TODO] on Linux, and in [TODO] on Solaris.
1008          AC_CHECK_LIB(termcap, tputs, LIBREADLINE="$LIBREADLINE -ltermcap",
1009            [AC_CHECK_LIB(tinfo, tputs, LIBREADLINE="$LIBREADLINE -ltinfo",
1010              [AC_CHECK_LIB(curses, tputs, LIBREADLINE="$LIBREADLINE -lcurses",
1011                [AC_CHECK_LIB(ncurses, tputs,
1012                              LIBREADLINE="$LIBREADLINE -lncurses")]
1013               )]
1014             )]
1015           )
1016          AC_CHECK_LIB(readline, main, LIBREADLINE="-lreadline $LIBREADLINE",,
1017                       "$LIBREADLINE")
1018          if test $ac_cv_lib_readline_main = no; then
1019            AC_MSG_ERROR([vtysh needs libreadline but was not found and usable on your system.])
1020          fi
1021          AC_CHECK_HEADER(readline/history.h)
1022          if test $ac_cv_header_readline_history_h = no;then
1023            AC_MSG_ERROR([readline is too old to have readline/history.h, please update to the latest readline library.])
1024          fi
1025          AC_CHECK_LIB(readline, rl_completion_matches,
1026                       LIBREADLINE="$LIBREADLINE",, "$LIBREADLINE")
1027          if test $ac_cv_lib_readline_rl_completion_matches = no; then
1028            AC_DEFINE(rl_completion_matches,completion_matches,Old readline)
1029          fi
1030          ;;
1031 esac
1032 AC_SUBST(LIBREADLINE)
1033 AM_CONDITIONAL(VTYSH, test "x$VTYSH" = "xvtysh")
1034
1035 dnl ----------
1036 dnl PAM module
1037 dnl
1038 dnl FRR detects the PAM library it is built against by checking for a
1039 dnl functional pam_misc.h (Linux-PAM) or openpam.h (OpenPAM) header. pam_misc.h
1040 dnl is known to #include pam_appl.h, the standard header of a PAM library, and
1041 dnl openpam.h doesn't do that, although depends on the header too. Hence a
1042 dnl little assistance to AC_CHECK_HEADER is necessary for the proper detection
1043 dnl of OpenPAM.
1044 dnl ----------
1045 if test "$with_libpam" = "yes"; then
1046   AC_CHECK_HEADER([security/pam_misc.h],
1047     [AC_DEFINE(HAVE_PAM_MISC_H,,Have pam_misc.h)
1048      AC_DEFINE(PAM_CONV_FUNC,misc_conv,Have misc_conv)
1049      pam_conv_func="misc_conv"
1050     ],
1051     [], FRR_INCLUDES)
1052   AC_CHECK_HEADER([security/openpam.h],
1053     [AC_DEFINE(HAVE_OPENPAM_H,,Have openpam.h)
1054      AC_DEFINE(PAM_CONV_FUNC,openpam_ttyconv,Have openpam_ttyconv)
1055      pam_conv_func="openpam_ttyconv"
1056     ],
1057     [], FRR_INCLUDES[#include <security/pam_appl.h>])
1058   if test -z "$ac_cv_header_security_pam_misc_h$ac_cv_header_security_openpam_h" ; then
1059     AC_MSG_WARN([*** pam support will not be built ***])
1060     with_libpam="no"
1061   fi
1062 fi
1063
1064 if test "$with_libpam" = "yes"; then
1065 dnl took this test from proftpds configure.in and suited to our needs
1066 dnl -------------------------------------------------------------------------
1067 dnl
1068 dnl This next check looks funky due to a linker problem with some versions
1069 dnl of the PAM library.  Prior to 0.72 release, the Linux PAM shared library
1070 dnl omitted requiring libdl linking information. PAM-0.72 or better ships
1071 dnl with RedHat 6.2 and Debian 2.2 or better.
1072 AC_CHECK_LIB(pam, pam_start,
1073   [AC_CHECK_LIB(pam, $pam_conv_func,
1074     [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1075      LIBPAM="-lpam"],
1076     [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1077      LIBPAM="-lpam -lpam_misc"]
1078     )
1079   ],
1080
1081   [AC_CHECK_LIB(pam, pam_end,
1082     [AC_CHECK_LIB(pam, $pam_conv_func,
1083       [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1084        LIBPAM="-lpam -ldl"],
1085       [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1086        LIBPAM="-lpam -ldl -lpam_misc"]
1087      )
1088   ],AC_MSG_WARN([*** pam support will not be built ***]),
1089   [-ldl])
1090   ]
1091 )
1092 fi
1093 AC_SUBST(LIBPAM)
1094
1095 dnl -------------------------------
1096 dnl Endian-ness check
1097 dnl -------------------------------
1098 AC_WORDS_BIGENDIAN
1099
1100 dnl -------------------------------
1101 dnl check the size in byte of the C
1102 dnl -------------------------------
1103 dnl AC_CHECK_SIZEOF(char)
1104 dnl AC_CHECK_SIZEOF(int)
1105 dnl AC_CHECK_SIZEOF(short)
1106 dnl AC_CHECK_SIZEOF(long)
1107
1108 dnl ----------------------------
1109 dnl check existance of functions
1110 dnl ----------------------------
1111 AC_FUNC_FNMATCH
1112 AC_FUNC_FORK
1113 AC_FUNC_MKTIME
1114 AC_FUNC_STAT
1115
1116 dnl -------------------------------
1117 dnl bgpd needs pow() and hence libm
1118 dnl -------------------------------
1119 TMPLIBS="$LIBS"
1120 AC_CHECK_HEADER([math.h],
1121   [AC_CHECK_LIB([m], [pow],
1122     [LIBM="-lm"
1123      LIBS="$LIBS $LIBM"
1124      AC_CHECK_FUNCS(pow,[],[LIBM=""])
1125     ])
1126 ])
1127 if test x"$LIBM" = x ; then
1128   AC_MSG_WARN([Unable to find working pow function - bgpd may not link])
1129 fi
1130 LIBS="$TMPLIBS"
1131 AC_SUBST(LIBM)
1132
1133 AC_CHECK_FUNCS([ppoll], [
1134   AC_DEFINE([HAVE_PPOLL], 1, [have Linux/BSD ppoll()])
1135 ])
1136 AC_CHECK_FUNCS([pollts], [
1137   AC_DEFINE([HAVE_POLLTS], 1, [have NetBSD pollts()])
1138 ])
1139
1140 dnl ---------------
1141 dnl other functions
1142 dnl ---------------
1143 AC_CHECK_FUNCS([ \
1144         strlcat strlcpy \
1145         getgrouplist])
1146
1147 AC_CHECK_HEADER([asm-generic/unistd.h],
1148                 [AC_CHECK_DECL(__NR_setns,
1149                                AC_DEFINE(HAVE_NETNS,, Have netns),,
1150                                FRR_INCLUDES [#include <asm-generic/unistd.h>
1151                                ])
1152                  AC_CHECK_FUNCS(setns)]
1153                )
1154
1155 dnl --------------------------
1156 dnl Determine IS-IS I/O method
1157 dnl --------------------------
1158 AC_DEFINE(ISIS_METHOD_PFPACKET, 1, [ constant value for isis method pfpacket ])
1159 AC_DEFINE(ISIS_METHOD_DLPI,     2, [ constant value for isis method dlpi ])
1160 AC_DEFINE(ISIS_METHOD_BPF,      3, [ constant value for isis method bpf ])
1161 AC_CHECK_HEADER(net/bpf.h)
1162 AC_CHECK_HEADER(sys/dlpi.h)
1163 AC_MSG_CHECKING(zebra IS-IS I/O method)
1164
1165 case "$host_os" in
1166   linux*)
1167     AC_MSG_RESULT(pfpacket)
1168     ISIS_METHOD_MACRO="ISIS_METHOD_PFPACKET"
1169     ;;
1170   solaris* | sunos*)
1171     AC_MSG_RESULT(DLPI)
1172     ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1173     ;;
1174   *)
1175     if test $ac_cv_header_net_bpf_h = no; then
1176       if test $ac_cv_header_sys_dlpi_h = no; then
1177         AC_MSG_RESULT(none)
1178         if test "${enable_isisd}" = yes; then
1179           AC_MSG_FAILURE([IS-IS support requested but no packet backend found])
1180         fi
1181         AC_MSG_WARN([*** IS-IS support will not be built ***])
1182         enable_isisd="no"
1183       else
1184         AC_MSG_RESULT(DLPI)
1185       fi
1186       ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1187     else
1188       AC_MSG_RESULT(BPF)
1189       ISIS_METHOD_MACRO="ISIS_METHOD_BPF"
1190     fi
1191     ;;
1192 esac
1193 AC_DEFINE_UNQUOTED(ISIS_METHOD, $ISIS_METHOD_MACRO, [ selected method for isis, == one of the constants ])
1194
1195 dnl ------------------------------------
1196 dnl check for broken CMSG_FIRSTHDR macro
1197 dnl ------------------------------------
1198 AC_MSG_CHECKING(for broken CMSG_FIRSTHDR)
1199 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1200 #ifdef SUNOS_5
1201 #define _XPG4_2
1202 #define __EXTENSIONS__
1203 #endif
1204 #include <stdlib.h>
1205 #include <sys/types.h>
1206 #include <sys/socket.h>
1207
1208 main()
1209 {
1210   struct msghdr msg;
1211   char buf[4];
1212
1213   msg.msg_control = buf;
1214   msg.msg_controllen = 0;
1215
1216   if (CMSG_FIRSTHDR(&msg) != NULL)
1217     exit(0);
1218   exit (1);
1219 }]])],[AC_MSG_RESULT(yes - using workaround) AC_DEFINE(HAVE_BROKEN_CMSG_FIRSTHDR,,Broken CMSG_FIRSTHDR)],
1220 [AC_MSG_RESULT(no)],[AC_MSG_RESULT(no)])
1221
1222 dnl ---------------------------------------------------------------
1223 dnl figure out how to specify an interface in multicast sockets API
1224 dnl ---------------------------------------------------------------
1225 AC_CHECK_MEMBERS([struct ip_mreqn.imr_ifindex], [], [], FRR_INCLUDES)
1226
1227 AC_CHECK_HEADERS([linux/mroute.h], [], [],[
1228         #include <sys/socket.h>
1229         #include <netinet/in.h>
1230         #define _LINUX_IN_H             /* For Linux <= 2.6.25 */
1231         #include <linux/types.h>
1232 ])
1233
1234 m4_define([FRR_INCLUDES],
1235 FRR_INCLUDES
1236 [#if HAVE_LINUX_MROUTE_H
1237 # include <linux/mroute.h>
1238 #endif
1239 ])dnl
1240
1241 AC_CHECK_HEADERS([netinet/ip_mroute.h], [], [],[
1242         #include <sys/socket.h>
1243         #include <sys/types.h>
1244         #include <netinet/in.h>
1245         #include <net/route.h>
1246 ])
1247
1248 m4_define([FRR_INCLUDES],
1249 FRR_INCLUDES
1250 [#if HAVE_NETINET_IP_MROUTE_H
1251 # include <netinet/ip_mroute.h>
1252 #endif
1253 ])dnl
1254
1255 AC_MSG_CHECKING([for BSD struct ip_mreq hack])
1256 AC_TRY_COMPILE([#include <sys/param.h>],
1257 [#if (defined(__FreeBSD__) && ((__FreeBSD_version >= 500022 && __FreeBSD_version < 700000) || (__FreeBSD_version < 500000 && __FreeBSD_version >= 440000))) || (defined(__NetBSD__) && defined(__NetBSD_Version__) && __NetBSD_Version__ >= 106010000) || defined(__OpenBSD__) || defined(__APPLE__) || defined(__DragonFly__) || defined(__sun)
1258   return (0);
1259 #else
1260   #error No support for BSD struct ip_mreq hack detected
1261 #endif],[AC_MSG_RESULT(yes)
1262 AC_DEFINE(HAVE_BSD_STRUCT_IP_MREQ_HACK,,[Can pass ifindex in struct ip_mreq])],
1263 AC_MSG_RESULT(no))
1264
1265 AC_MSG_CHECKING([for RFC3678 protocol-independed API])
1266 AC_TRY_COMPILE([
1267 #include <sys/types.h>
1268 #include <netinet/in.h>
1269 ], [struct group_req gr; int sock; setsockopt(sock, IPPROTO_IP, MCAST_JOIN_GROUP, (void*)&gr, sizeof(gr));
1270 ], [AC_MSG_RESULT(yes)
1271 AC_DEFINE(HAVE_RFC3678,1,[Have RFC3678 protocol-independed API])],
1272 AC_MSG_RESULT(no))
1273
1274 dnl ---------------------------------------------------------------
1275 dnl figure out how to check link-state
1276 dnl ---------------------------------------------------------------
1277 AC_CHECK_HEADER( [net/if_media.h],
1278   [m4_define([LINK_DETECT_INCLUDES],
1279     FRR_INCLUDES
1280     [#include <net/if_media.h>
1281   ])
1282   AC_CHECK_MEMBERS( [struct ifmediareq.ifm_status],
1283     AC_DEFINE(HAVE_BSD_LINK_DETECT,,[BSD link-detect]),
1284     [], LINK_DETECT_INCLUDES)],
1285   [],
1286   FRR_INCLUDES)
1287
1288 dnl ---------------------------------------------------------------
1289 dnl Additional, newer way to check link-state using ifi_link_state.
1290 dnl Not available in all BSD's when ifmediareq available
1291 dnl ---------------------------------------------------------------
1292 AC_CHECK_MEMBERS([struct if_data.ifi_link_state],
1293   AC_DEFINE(HAVE_BSD_IFI_LINK_STATE,,[BSD ifi_link_state available]),
1294   [], FRR_INCLUDES)
1295
1296 dnl ------------------------
1297 dnl TCP_MD5SIG socket option
1298 dnl ------------------------
1299
1300 AC_CHECK_HEADER([netinet/tcp.h],
1301    [m4_define([MD5_INCLUDES],
1302       FRR_INCLUDES
1303       [#include <netinet/tcp.h>
1304     ])
1305     AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)],
1306    [],
1307    FRR_INCLUDES)
1308 if test $ac_cv_have_decl_TCP_MD5SIG = no; then
1309   AC_CHECK_HEADER([linux/tcp.h],
1310        [m4_define([MD5_INCLUDES],
1311           FRR_INCLUDES
1312           [#include <linux/tcp.h>
1313         ])
1314        AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)])
1315 fi
1316
1317 dnl ----------------------------------------------------------------------------
1318 dnl figure out if domainname is available in the utsname struct (GNU extension).
1319 dnl ----------------------------------------------------------------------------
1320 AC_CHECK_MEMBERS([struct utsname.domainname], [], [], [#include <sys/utsname.h>])
1321
1322 dnl ------------------
1323 dnl IPv6 header checks
1324 dnl ------------------
1325 AC_CHECK_HEADERS([netinet6/in6.h netinet/in6_var.h \
1326         netinet6/in6_var.h netinet6/nd6.h], [], [],
1327         FRR_INCLUDES)
1328
1329 m4_define([FRR_INCLUDES],dnl
1330 FRR_INCLUDES
1331 [#if HAVE_NETINET6_IN6_H
1332 #include <netinet6/in6.h>
1333 #endif
1334 #if HAVE_NETINET_IN6_VAR_H
1335 #include <netinet/in6_var.h>
1336 #endif
1337 #include <netinet/icmp6.h>
1338 #if HAVE_NETINET6_IN6_VAR_H
1339 # include <netinet6/in6_var.h>
1340 #endif
1341 #if HAVE_NETINET6_ND6_H
1342 # include <netinet6/nd6.h>
1343 #endif
1344 ])dnl
1345
1346 dnl disable doc check
1347 if test "${enable_doc}" = "no";then
1348   DOC=""
1349 else
1350   DOC="doc"
1351 fi
1352
1353 dnl --------------------
1354 dnl Daemon disable check
1355 dnl --------------------
1356 AM_CONDITIONAL(ZEBRA, test "${enable_zebra}" != "no")
1357
1358 if test "${enable_bgpd}" = "no";then
1359   BGPD=""
1360 else
1361   BGPD="bgpd"
1362 fi
1363 AM_CONDITIONAL(BGPD, test "x$BGPD" = "xbgpd")
1364
1365 AM_CONDITIONAL(RIPD, test "${enable_ripd}" != "no")
1366 AM_CONDITIONAL(OSPFD, test "${enable_ospfd}" != "no")
1367 AM_CONDITIONAL(LDPD, test "${enable_ldpd}" != "no")
1368
1369 AS_IF([test "${enable_ldpd}" != "no"], [
1370   AC_DEFINE(HAVE_LDPD, 1, ldpd)
1371 ])
1372
1373 NHRPD=""
1374 case "$host_os" in
1375   linux*)
1376     if test "${enable_nhrpd}" != "no"; then
1377       NHRPD="nhrpd"
1378     fi
1379     ;;
1380   *)
1381     if test "${enable_nhrpd}" = "yes"; then
1382       AC_MSG_ERROR([nhrpd requires kernel APIs that are only present on Linux.])
1383     fi
1384     ;;
1385 esac
1386 AM_CONDITIONAL(NHRPD, test "x$NHRPD" = "xnhrpd")
1387
1388 AM_CONDITIONAL(EIGRPD, test "${enable_eigrpd}" != "no")
1389
1390 if test "${enable_watchfrr}" = "no";then
1391   WATCHFRR=""
1392 else
1393   WATCHFRR="watchfrr"
1394 fi
1395 AM_CONDITIONAL(WATCHFRR, test "x$WATCHFRR" = "xwatchfrr")
1396
1397 OSPFCLIENT=""
1398 if test "${enable_ospfapi}" != "no";then
1399     AC_DEFINE(SUPPORT_OSPF_API,,OSPFAPI)
1400
1401   if test "${enable_ospfclient}" != "no";then
1402       OSPFCLIENT="ospfclient"
1403   fi
1404 fi
1405
1406 AM_CONDITIONAL(OSPFCLIENT, test "x$OSPFCLIENT" = "xospfclient")
1407 AM_CONDITIONAL(RIPNGD, test "${enable_ripngd}" != "no")
1408 AM_CONDITIONAL(BABELD, test "${enable_babeld}" != "no")
1409 AM_CONDITIONAL(OSPF6D, test "${enable_ospf6d}" != "no")
1410 AM_CONDITIONAL(ISISD, test "${enable_isisd}" != "no")
1411 AM_CONDITIONAL(PIMD, test "${enable_pimd}" != "no")
1412 AM_CONDITIONAL(PBRD, test "${enable_pbrd}" != "no")
1413 AM_CONDITIONAL(SHARPD, test "${enable_sharpd}" = "yes")
1414 AM_CONDITIONAL(STATICD, test "${enable_staticd}" != "no")
1415
1416 if test "${enable_bgp_announce}" = "no";then
1417   AC_DEFINE(DISABLE_BGP_ANNOUNCE,1,Disable BGP installation to zebra)
1418 else
1419   AC_DEFINE(DISABLE_BGP_ANNOUNCE,0,Disable BGP installation to zebra)
1420 fi
1421
1422 if test "${with_rfp_path}" = "yes" || test x"${with_rfp_path}" = x""; then
1423   with_rfp_path="bgpd/rfp-example"
1424 fi
1425 if test "${with_rfp_path}" != "no"; then
1426   VNC_RFP_PATH="${with_rfp_path}"
1427   AC_SUBST(VNC_RFP_PATH)
1428 fi
1429
1430 if test "${enable_bgp_vnc}" != "no";then
1431   AC_DEFINE(ENABLE_BGP_VNC,1,Enable BGP VNC support)
1432   RFPTEST="${with_rfp_path}/rfptest"
1433   LIBRFP="${with_rfp_path}/librfp"
1434   RFPINC="${with_rfp_path}/librfp"
1435 else
1436   RFPTEST=
1437   LIBRFP=
1438   RFPINC="bgpd/rfp-example/librfp"
1439 fi
1440 # set
1441 AM_CONDITIONAL([ENABLE_BGP_VNC], [test x${enable_bgp_vnc} != xno])
1442
1443 AC_SUBST(DOC)
1444 AC_SUBST(RFPTEST)
1445 AC_SUBST(LIBRFP)
1446 AC_SUBST(RFPINC)
1447 AC_SUBST(BGPD)
1448 AC_SUBST(SOLARIS)
1449 AC_SUBST(VTYSH)
1450 AC_SUBST(CURSES)
1451 AC_CHECK_LIB(crypt, crypt, [],
1452                     [AC_CHECK_LIB(crypto, DES_crypt)])
1453 AC_CHECK_LIB(resolv, res_init)
1454
1455 dnl ---------------------------
1456 dnl check system has PCRE regexp
1457 dnl ---------------------------
1458 if test "x$enable_pcreposix" = "xyes"; then
1459   AC_CHECK_LIB(pcreposix, regexec, [], [
1460     AC_MSG_ERROR([--enable-pcreposix given but unable to find libpcreposix])
1461   ])
1462 fi
1463 AC_SUBST(HAVE_LIBPCREPOSIX)
1464
1465 dnl ------------------
1466 dnl check C-Ares library
1467 dnl ------------------
1468 if test "${NHRPD}" != ""; then
1469   PKG_CHECK_MODULES([CARES], [libcares], , [
1470     AC_MSG_ERROR([trying to build nhrpd, but libcares not found. install c-ares and its -dev headers.])
1471   ])
1472 fi
1473
1474
1475 dnl ------------------
1476 dnl check Net-SNMP library
1477 dnl ------------------
1478 if test "${enable_snmp}" != "" -a "${enable_snmp}" != "no"; then
1479    AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], [no])
1480    if test x"$NETSNMP_CONFIG" = x"no"; then
1481       AC_MSG_ERROR([--enable-snmp given but unable to find net-snmp-config])
1482    fi
1483    SNMP_LIBS="`${NETSNMP_CONFIG} --agent-libs`"
1484    SNMP_CFLAGS="`${NETSNMP_CONFIG} --base-cflags`"
1485    AC_MSG_CHECKING([whether we can link to Net-SNMP])
1486    AC_LINK_IFELSE_FLAGS([$SNMP_CFLAGS], [$SNMP_LIBS], [AC_LANG_PROGRAM([
1487 int main(void);
1488 ],
1489 [
1490 {
1491   return 0;
1492 }
1493 ])], [
1494      AC_MSG_ERROR([--enable-snmp given but not usable])])
1495    case "${enable_snmp}" in
1496      yes)
1497       SNMP_METHOD=agentx
1498       ;;
1499      smux|agentx)
1500       SNMP_METHOD="${enable_snmp}"
1501       ;;
1502      *)
1503       AC_MSG_ERROR([--enable-snmp given with an unknown method (${enable_snmp}). Use smux or agentx])
1504       ;;
1505    esac
1506    AH_TEMPLATE([SNMP_SMUX], [Use SNMP SMUX to interface with snmpd])
1507    AH_TEMPLATE([SNMP_AGENTX], [Use SNMP AgentX to interface with snmpd])
1508    AC_DEFINE_UNQUOTED(AS_TR_CPP(SNMP_${SNMP_METHOD}),,SNMP method to interface with snmpd)
1509 fi
1510 AM_CONDITIONAL([SNMP], [test "x${SNMP_METHOD}" != "x"])
1511 AC_SUBST(SNMP_LIBS)
1512 AC_SUBST(SNMP_CFLAGS)
1513
1514 dnl ---------------
1515 dnl math
1516 dnl ---------------
1517 AC_SEARCH_LIBS([sqrt], [m])
1518
1519 dnl ---------------
1520 dnl dlopen & dlinfo
1521 dnl ---------------
1522 AC_SEARCH_LIBS(dlopen, [dl dld], [], [
1523   AC_MSG_ERROR([unable to find the dlopen()])
1524 ])
1525
1526 AC_CHECK_HEADERS([link.h])
1527
1528 AC_MSG_CHECKING([for dlinfo(RTLD_DI_ORIGIN)])
1529 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1530 #include <stdlib.h>
1531 #ifdef HAVE_LINK_H
1532 #include <link.h>
1533 #endif
1534 #include <dlfcn.h>
1535 ]], [[
1536   char origin[1];
1537   dlinfo (NULL, RTLD_DI_ORIGIN, &origin);
1538 ]])], [
1539   AC_MSG_RESULT(yes)
1540   AC_DEFINE(HAVE_DLINFO_ORIGIN, 1, [Have dlinfo RTLD_DI_ORIGIN])
1541 ], [
1542   AC_MSG_RESULT(no)
1543 ])
1544
1545 AC_MSG_CHECKING([for dlinfo(RTLD_DI_LINKMAP)])
1546 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1547 #include <stdlib.h>
1548 #ifdef HAVE_LINK_H
1549 #include <link.h>
1550 #endif
1551 #include <dlfcn.h>
1552 ]], [[
1553   struct link_map *lm = NULL;
1554   dlinfo (NULL, RTLD_DI_LINKMAP, &lm);
1555 ]])], [
1556   AC_MSG_RESULT(yes)
1557   AC_DEFINE(HAVE_DLINFO_LINKMAP, 1, [Have dlinfo RTLD_DI_LINKMAP])
1558 ], [
1559   AC_MSG_RESULT(no)
1560 ])
1561
1562
1563 AM_CONDITIONAL(SNMP, test "x$SNMP_METHOD" = "xagentx")
1564
1565 dnl ---------------------------
1566 dnl sockaddr and netinet checks
1567 dnl ---------------------------
1568 AC_CHECK_TYPES([
1569         struct sockaddr_dl,
1570         struct vifctl, struct mfcctl, struct sioc_sg_req,
1571         vifi_t, struct sioc_vif_req, struct igmpmsg,
1572         struct ifaliasreq, struct if6_aliasreq, struct in6_aliasreq,
1573         struct nd_opt_adv_interval, struct rt_addrinfo,
1574         struct nd_opt_homeagent_info, struct nd_opt_adv_interval],
1575         [], [], FRR_INCLUDES)
1576
1577 AC_CHECK_MEMBERS([struct sockaddr.sa_len,
1578         struct sockaddr_in.sin_len, struct sockaddr_un.sun_len,
1579         struct sockaddr_dl.sdl_len,
1580         struct if6_aliasreq.ifra_lifetime,
1581         struct nd_opt_adv_interval.nd_opt_ai_type],
1582         [], [], FRR_INCLUDES)
1583
1584 dnl ---------------------------
1585 dnl IRDP/pktinfo/icmphdr checks
1586 dnl ---------------------------
1587
1588 AC_CHECK_TYPES([struct in_pktinfo], [
1589   AC_CHECK_TYPES([struct icmphdr], [
1590     IRDP=true
1591   ], [
1592     IRDP=false
1593   ], [FRR_INCLUDES])
1594 ], [
1595   IRDP=false
1596 ], [FRR_INCLUDES])
1597
1598 case "${enable_irdp}" in
1599 yes)
1600   $IRDP || AC_MSG_ERROR(['IRDP requires in_pktinfo at the moment!'])
1601   ;;
1602 no)
1603   IRDP=false
1604   ;;
1605 esac
1606
1607 AM_CONDITIONAL(IRDP, $IRDP)
1608
1609 dnl -----------------------
1610 dnl checking for IP_PKTINFO
1611 dnl -----------------------
1612 AC_MSG_CHECKING(for IP_PKTINFO)
1613 AC_TRY_COMPILE([#include <netdb.h>], [
1614   int opt = IP_PKTINFO;
1615 ], [
1616   AC_MSG_RESULT(yes)
1617   AC_DEFINE(HAVE_IP_PKTINFO, 1, [Have IP_PKTINFO])
1618 ], [
1619   AC_MSG_RESULT(no)
1620 ])
1621
1622 dnl ---------------------------
1623 dnl checking for IP_RECVDSTADDR
1624 dnl ---------------------------
1625 AC_MSG_CHECKING(for IP_RECVDSTADDR)
1626 AC_TRY_COMPILE([#include <netinet/in.h>], [
1627   int opt = IP_RECVDSTADDR;
1628 ], [
1629   AC_MSG_RESULT(yes)
1630   AC_DEFINE(HAVE_IP_RECVDSTADDR, 1, [Have IP_RECVDSTADDR])
1631 ], [
1632   AC_MSG_RESULT(no)
1633 ])
1634
1635 dnl ----------------------
1636 dnl checking for IP_RECVIF
1637 dnl ----------------------
1638 AC_MSG_CHECKING(for IP_RECVIF)
1639 AC_TRY_COMPILE([#include <netinet/in.h>], [
1640   int opt = IP_RECVIF;
1641 ], [
1642   AC_MSG_RESULT(yes)
1643   AC_DEFINE(HAVE_IP_RECVIF, 1, [Have IP_RECVIF])
1644 ], [
1645   AC_MSG_RESULT(no)
1646 ])
1647
1648 dnl ----------------------
1649 dnl checking for SO_BINDANY
1650 dnl ----------------------
1651 AC_MSG_CHECKING(for SO_BINDANY)
1652 AC_TRY_COMPILE([#include <sys/socket.h>], [
1653   int opt = SO_BINDANY;
1654 ], [
1655   AC_MSG_RESULT(yes)
1656   AC_DEFINE(HAVE_SO_BINDANY, 1, [Have SO_BINDANY])
1657 ], [
1658   AC_MSG_RESULT(no)
1659 ])
1660
1661 dnl ----------------------
1662 dnl checking for IP_FREEBIND
1663 dnl ----------------------
1664 AC_MSG_CHECKING(for IP_FREEBIND)
1665 AC_TRY_COMPILE([#include <netinet/in.h>], [
1666   int opt = IP_FREEBIND;
1667 ], [
1668   AC_MSG_RESULT(yes)
1669   AC_DEFINE(HAVE_IP_FREEBIND, 1, [Have IP_FREEBIND])
1670 ], [
1671   AC_MSG_RESULT(no)
1672 ])
1673
1674 dnl --------------------------------------
1675 dnl checking for be32dec existence or not
1676 dnl --------------------------------------
1677 AC_CHECK_DECLS([be32enc, be32dec], [], [],
1678                [#include <sys/endian.h>])
1679
1680 dnl --------------------------------------
1681 dnl checking for clock_time monotonic struct and call
1682 dnl --------------------------------------
1683 AC_CHECK_DECL(CLOCK_MONOTONIC,
1684         [AC_CHECK_LIB(rt, clock_gettime, [LIBS="$LIBS -lrt"])
1685          AC_DEFINE(HAVE_CLOCK_MONOTONIC,, Have monotonic clock)
1686 ], [AC_MSG_RESULT(no)], [FRR_INCLUDES])
1687
1688 dnl --------------------------------------
1689 dnl checking for flex and bison
1690 dnl --------------------------------------
1691
1692 AM_PROG_LEX
1693 AC_MSG_CHECKING(version of flex)
1694 frr_ac_flex_version="$(eval $LEX -V | grep flex | head -n 1)"
1695 frr_ac_flex_version="${frr_ac_flex_version##* }"
1696 AC_MSG_RESULT([$frr_ac_flex_version])
1697 AX_COMPARE_VERSION([$frr_ac_flex_version], [lt], [2.5.20], [
1698   LEX="$SHELL $missing_dir/missing flex"
1699   if test -f "${srcdir}/lib/command_lex.c" -a -f "${srcdir}/lib/command_lex.h"; then
1700     AC_MSG_WARN([using pregenerated flex output files])
1701   else
1702     AC_MSG_ERROR([flex failure and pregenerated files not included (probably a git build)])
1703   fi
1704   AC_SUBST([LEX_OUTPUT_ROOT], [lex.yy])
1705   AC_SUBST([LEXLIB], [''])
1706 ])
1707
1708 AC_PROG_YACC
1709 dnl thanks GNU bison for this b*llshit...
1710 AC_MSG_CHECKING(version of bison)
1711 frr_ac_bison_version="$(eval $YACC -V | grep bison | head -n 1)"
1712 frr_ac_bison_version="${frr_ac_bison_version##* }"
1713 frr_ac_bison_missing="false"
1714 case "x${frr_ac_bison_version}" in
1715   x2.7*)
1716     BISON_OPENBRACE='"'
1717     BISON_CLOSEBRACE='"'
1718     BISON_VERBOSE=''
1719     AC_MSG_RESULT([$frr_ac_bison_version - 2.7 or older])
1720     ;;
1721   x2.*|x1.*)
1722     AC_MSG_RESULT([$frr_ac_bison_version])
1723     AC_MSG_WARN([installed bison is too old.  Please install GNU bison 2.7.x or newer.])
1724     frr_ac_bison_missing="true"
1725     ;;
1726   x)
1727     AC_MSG_RESULT([none])
1728     AC_MSG_WARN([could not determine bison version.  Please install GNU bison 2.7.x or newer.])
1729     frr_ac_bison_missing="true"
1730     ;;
1731   *)
1732     BISON_OPENBRACE='{'
1733     BISON_CLOSEBRACE='}'
1734     BISON_VERBOSE='-Dparse.error=verbose'
1735     AC_MSG_RESULT([$frr_ac_bison_version - 3.0 or newer])
1736     ;;
1737 esac
1738 AC_SUBST(BISON_OPENBRACE)
1739 AC_SUBST(BISON_CLOSEBRACE)
1740 AC_SUBST(BISON_VERBOSE)
1741
1742 if $frr_ac_bison_missing; then
1743   YACC="$SHELL $missing_dir/missing bison -y"
1744   if test -f "${srcdir}/lib/command_parse.c" -a -f "${srcdir}/lib/command_parse.h"; then
1745     AC_MSG_WARN([using pregenerated bison output files])
1746   else
1747     AC_MSG_ERROR([bison failure and pregenerated files not included (probably a git build)])
1748   fi
1749 fi
1750
1751 dnl -------------------
1752 dnl capabilities checks
1753 dnl -------------------
1754 if test "${enable_capabilities}" != "no"; then
1755   AC_MSG_CHECKING(whether prctl PR_SET_KEEPCAPS is available)
1756   AC_TRY_COMPILE([#include <sys/prctl.h>],[prctl(PR_SET_KEEPCAPS, 1, 0, 0, 0);],
1757     [AC_MSG_RESULT(yes)
1758      AC_DEFINE(HAVE_PR_SET_KEEPCAPS,,prctl)
1759      frr_ac_keepcaps="yes"],
1760      AC_MSG_RESULT(no)
1761   )
1762   if test x"${frr_ac_keepcaps}" = x"yes"; then
1763     AC_CHECK_HEADERS(sys/capability.h)
1764   fi
1765   if test x"${ac_cv_header_sys_capability_h}" = x"yes"; then
1766     AC_CHECK_LIB(cap, cap_init,
1767       [AC_DEFINE(HAVE_LCAPS,1,Capabilities)
1768        LIBCAP="-lcap"
1769        frr_ac_lcaps="yes"]
1770     )
1771   else
1772     AC_CHECK_HEADERS(priv.h,
1773      [AC_MSG_CHECKING(Solaris style privileges are available)
1774       AC_TRY_COMPILE([#include <priv.h>],[getpflags(PRIV_AWARE);],
1775           [AC_MSG_RESULT(yes)
1776            AC_DEFINE(HAVE_SOLARIS_CAPABILITIES,1,getpflags)
1777            frr_ac_scaps="yes"],
1778            AC_MSG_RESULT(no)
1779       )
1780      ]
1781    )
1782   fi
1783   if test x"${frr_ac_scaps}" = x"yes" \
1784        -o x"${frr_ac_lcaps}" = x"yes"; then
1785     AC_DEFINE(HAVE_CAPABILITIES,1,capabilities)
1786   fi
1787 fi
1788 AC_SUBST(LIBCAP)
1789
1790 dnl ---------------------------
1791 dnl check for glibc 'backtrace'
1792 dnl ---------------------------
1793 if test x"${enable_backtrace}" != x"no" ; then
1794   backtrace_ok=no
1795   AC_CHECK_HEADER([execinfo.h], [
1796     AC_SEARCH_LIBS([backtrace], [execinfo], [
1797       AC_DEFINE(HAVE_GLIBC_BACKTRACE,,[Glibc backtrace])
1798       AC_DEFINE(HAVE_STACK_TRACE,,[Stack symbol decoding])
1799       backtrace_ok=yes
1800     ],, [-lm])
1801   ])
1802
1803   if test x"${enable_backtrace}" = x"yes" -a x"${backtrace_ok}" = x"no"; then
1804     dnl user explicitly requested backtrace but we failed to find support
1805     AC_MSG_FAILURE([failed to find backtrace support])
1806   fi
1807 fi
1808
1809 dnl -----------------------------------------
1810 dnl check for malloc mallinfo struct and call
1811 dnl this must try and link using LIBS, in
1812 dnl order to check no alternative allocator
1813 dnl has been specified, which might not provide
1814 dnl mallinfo, e.g. such as Umem on Solaris.
1815 dnl -----------------------------------------
1816 AC_CHECK_HEADER([malloc.h],
1817  [AC_MSG_CHECKING(whether mallinfo is available)
1818   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <malloc.h>]],
1819                         [[struct mallinfo ac_x; ac_x = mallinfo ();]])],
1820       [AC_MSG_RESULT(yes)
1821        AC_DEFINE(HAVE_MALLINFO,,mallinfo)],
1822        AC_MSG_RESULT(no)
1823   )
1824  ], [], FRR_INCLUDES)
1825
1826 dnl ------
1827 dnl ZeroMQ
1828 dnl ------
1829 if test "x$enable_zeromq" != "xno"; then
1830   PKG_CHECK_MODULES(ZEROMQ, [libzmq >= 4.0.0], [
1831     AC_DEFINE(HAVE_ZEROMQ, 1, [Enable ZeroMQ support])
1832     ZEROMQ=true
1833   ], [
1834     if test "x$enable_zeromq" = "xyes"; then
1835       AC_MSG_ERROR([configuration specifies --enable-zeromq but libzmq was not found])
1836     fi
1837   ])
1838 fi
1839 AM_CONDITIONAL([ZEROMQ], test "x$ZEROMQ" = "xtrue")
1840
1841 dnl ----------
1842 dnl configure date
1843 dnl ----------
1844 dev_version=`echo $VERSION | grep dev`
1845 #don't expire deprecated code in non 'dev' branch
1846 if test "${dev_version}" = ""; then
1847    CONFDATE=0
1848 else
1849    CONFDATE=`date '+%Y%m%d'`
1850 fi
1851 AC_SUBST(CONFDATE)
1852
1853 dnl ------------------------------
1854 dnl set paths for state directory
1855 dnl ------------------------------
1856 AC_MSG_CHECKING(directory to use for state file)
1857 if test "${prefix}" = "NONE"; then
1858   frr_statedir_prefix="";
1859 else
1860   frr_statedir_prefix=${prefix}
1861 fi
1862 if test "${localstatedir}" = '${prefix}/var'; then
1863   for FRR_STATE_DIR in ${frr_statedir_prefix}/var/run dnl
1864                         ${frr_statedir_prefix}/var/adm dnl
1865                         ${frr_statedir_prefix}/etc dnl
1866                         /var/run        dnl
1867                         /var/adm        dnl
1868                         /etc            dnl
1869                         /dev/null;
1870   do
1871     test -d $FRR_STATE_DIR && break
1872   done
1873   frr_statedir=$FRR_STATE_DIR
1874 else
1875   frr_statedir=${localstatedir}
1876 fi
1877 if test $frr_statedir = "/dev/null"; then
1878     AC_MSG_ERROR('STATE DIRECTORY NOT FOUND! FIX OR SPECIFY --localstatedir!')
1879 fi
1880 AC_MSG_RESULT(${frr_statedir})
1881 AC_SUBST(frr_statedir)
1882
1883 AC_DEFINE_UNQUOTED(LDPD_SOCKET, "$frr_statedir/ldpd.sock",ldpd control socket)
1884 AC_DEFINE_UNQUOTED(ZEBRA_SERV_PATH, "$frr_statedir/zserv.api",zebra api socket)
1885 AC_DEFINE_UNQUOTED(DAEMON_VTY_DIR, "$frr_statedir",daemon vty directory)
1886
1887 dnl autoconf does this, but it does it too late...
1888 test "x$prefix" = xNONE && prefix=$ac_default_prefix
1889 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
1890
1891 dnl get the full path, recursing through variables...
1892 vtysh_bin="$bindir/vtysh"
1893 for I in 1 2 3 4 5 6 7 8 9 10; do
1894         eval vtysh_bin="\"$vtysh_bin\""
1895 done
1896 AC_DEFINE_UNQUOTED(VTYSH_BIN_PATH, "$vtysh_bin",path to vtysh binary)
1897
1898 CFG_SYSCONF="$sysconfdir"
1899 CFG_SBIN="$sbindir"
1900 CFG_STATE="$frr_statedir"
1901 CFG_MODULE="$moduledir"
1902 for I in 1 2 3 4 5 6 7 8 9 10; do
1903         eval CFG_SYSCONF="\"$CFG_SYSCONF\""
1904         eval CFG_SBIN="\"$CFG_SBIN\""
1905         eval CFG_STATE="\"$CFG_STATE\""
1906         eval CFG_MODULE="\"$CFG_MODULE\""
1907 done
1908 AC_SUBST(CFG_SYSCONF)
1909 AC_SUBST(CFG_SBIN)
1910 AC_SUBST(CFG_STATE)
1911 AC_SUBST(CFG_MODULE)
1912 AC_DEFINE_UNQUOTED(MODULE_PATH, "$CFG_MODULE", path to modules)
1913
1914 dnl ------------------------------------
1915 dnl Enable RPKI and add librtr to libs
1916 dnl ------------------------------------
1917 if test "${enable_rpki}" = "yes"; then
1918   PKG_CHECK_MODULES(RTRLIB,[rtrlib >= 0.5.0],
1919       [AC_DEFINE(HAVE_RPKI,1,Enable RPKI prefix validation for BGP)
1920       RPKI=true],
1921       [RPKI=false
1922       AC_MSG_ERROR([rtrlib was not found on your system or is too old.])]
1923   )
1924 fi
1925 AM_CONDITIONAL([RPKI], test "x$RPKI" = "xtrue")
1926
1927 dnl ------------------------------------------
1928 dnl Check whether rtrlib was build with ssh support
1929 dnl ------------------------------------------
1930 AC_MSG_CHECKING([whether the RTR Library is compiled with SSH])
1931 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "rtrlib/rtrlib.h"]],
1932                         [[struct tr_ssh_config config;]])],
1933         [AC_MSG_RESULT(yes)
1934         AC_DEFINE(FOUND_SSH,,found_ssh)],
1935         AC_MSG_RESULT(no)
1936 )
1937
1938 dnl ---------------------------
1939 dnl Check htonl works correctly
1940 dnl ---------------------------
1941 AC_MSG_CHECKING(for working htonl)
1942 AC_CACHE_VAL(ac_cv_htonl_works,
1943  [AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES],[htonl (0);])],
1944                 [ac_cv_htonl_works=yes], [ac_cv_htonl_works=no])
1945  ]
1946 )
1947 AC_MSG_RESULT($ac_cv_htonl_works)
1948
1949 AC_CONFIG_FILES([Makefile
1950           bgpd/Makefile
1951           vtysh/Makefile
1952           doc/Makefile
1953           doc/user/Makefile
1954           doc/manpages/Makefile
1955           doc/developer/Makefile
1956           tests/Makefile
1957           bgpd/rfp-example/rfptest/Makefile
1958           bgpd/rfp-example/librfp/Makefile
1959           redhat/frr.spec
1960           debianpkg/Makefile
1961           debianpkg/changelog
1962           alpine/APKBUILD
1963           snapcraft/snapcraft.yaml
1964           lib/version.h
1965           tests/lib/cli/test_cli.refout
1966           pkgsrc/bgpd.sh pkgsrc/ospf6d.sh pkgsrc/ospfd.sh
1967           pkgsrc/ripd.sh pkgsrc/ripngd.sh pkgsrc/zebra.sh
1968           pkgsrc/eigrpd.sh])
1969
1970 if test "${enable_bgp_vnc}" != "no"; then
1971    if test "${with_rfp_path}" != "bgpd/rfp-example" ; then
1972       AC_CONFIG_FILES([${with_rfp_path}/rfptest/Makefile ${with_rfp_path}/librfp/Makefile])
1973    fi
1974 fi
1975
1976 AC_CONFIG_FILES([solaris/Makefile])
1977
1978 AC_CONFIG_FILES([vtysh/extract.pl],[chmod +x vtysh/extract.pl])
1979
1980 AC_CONFIG_COMMANDS([lib/route_types.h], [
1981         dst="${ac_abs_top_builddir}/lib/route_types.h"
1982         ${PERL} "${ac_abs_top_srcdir}/lib/route_types.pl" \
1983                 < "${ac_abs_top_srcdir}/lib/route_types.txt" \
1984                 > "${dst}.tmp"
1985         test -f "${dst}" \
1986                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
1987                 && rm "${dst}.tmp" \
1988                 || mv "${dst}.tmp" "${dst}"
1989 ], [
1990         PERL="$PERL"
1991 ])
1992
1993 AS_IF([test "x$with_pkg_git_version" = "xyes"], [
1994     AC_CONFIG_COMMANDS([lib/gitversion.h], [
1995         dst="${ac_abs_top_builddir}/lib/gitversion.h"
1996         ${PERL} "${ac_abs_top_srcdir}/lib/gitversion.pl" \
1997                 "${ac_abs_top_srcdir}" \
1998                 > "${dst}.tmp"
1999         test -f "${dst}" \
2000                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
2001                 && rm "${dst}.tmp" \
2002                 || mv "${dst}.tmp" "${dst}"
2003     ], [
2004         PERL="$PERL"
2005     ])
2006 ])
2007
2008 ## Hack, but working solution to avoid rebuilding of frr.info.
2009 ## It's already in CVS until texinfo 4.7 is more common.
2010 AC_OUTPUT
2011
2012 echo "
2013 FRRouting configuration
2014 ------------------------------
2015 FRR version             : ${PACKAGE_VERSION}
2016 host operating system   : ${host_os}
2017 source code location    : ${srcdir}
2018 compiler                : ${CC}
2019 compiler flags          : ${CFLAGS}
2020 make                    : ${MAKE-make}
2021 linker flags            : ${LDFLAGS} ${LIBS} ${LIBCAP} ${LIBREADLINE} ${LIBM}
2022 state file directory    : ${frr_statedir}
2023 config file directory   : `eval echo \`echo ${sysconfdir}\``
2024 example directory       : `eval echo \`echo ${exampledir}\``
2025 module directory        : ${CFG_MODULE}
2026 user to run as          : ${enable_user}
2027 group to run as         : ${enable_group}
2028 group for vty sockets   : ${enable_vty_group}
2029 config file mask        : ${enable_configfile_mask}
2030 log file mask           : ${enable_logfile_mask}
2031 zebra protobuf enabled  : ${have_protobuf:-no}
2032
2033 The above user and group must have read/write access to the state file
2034 directory and to the config files in the config file directory."