configure.ac

   1 ##
   2 ## Configure template file for FreeRangeRouting.
   3 ## autoconf will generate configure script.
   4 ##
   5 ##  Copyright (c) 1996, 97, 98, 99, 2000 Kunihiro Ishiguro <kunihiro@zebra.org>
   6 ##  Portions Copyright (c) 2003 Paul Jakma <paul@dishone.st>
   7 ##
   8 AC_PREREQ(2.60)
   9
  10 AC_INIT(frr, 2.1-dev, [https://github.com/freerangerouting/frr/issues])
  11 PACKAGE_URL="https://freerangerouting.org/"
  12 PACKAGE_FULLNAME="FreeRangeRouting"
  13 AC_SUBST(PACKAGE_FULLNAME)
  14
  15 CONFIG_ARGS="$ac_configure_args"
  16 AC_SUBST(CONFIG_ARGS)
  17
  18 AC_CONFIG_SRCDIR(lib/zebra.h)
  19 AC_CONFIG_MACRO_DIR([m4])
  20
  21 dnl -----------------------------------
  22 dnl Get hostname and other information.
  23 dnl -----------------------------------
  24 AC_CANONICAL_BUILD()
  25 AC_CANONICAL_HOST()
  26 AC_CANONICAL_TARGET()
  27
  28 # Disable portability warnings -- our automake code (in particular
  29 # common.am) uses some constructs specific to gmake.
  30 AM_INIT_AUTOMAKE([1.12 -Wno-portability])
  31 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
  32 AM_SILENT_RULES([yes])
  33 AC_CONFIG_HEADERS(config.h)
  34
  35 AC_PATH_PROG(PERL, perl)
  36 PKG_PROG_PKG_CONFIG
  37
  38 dnl default is to match previous behavior
  39 exampledir=${sysconfdir}
  40 AC_ARG_ENABLE([exampledir],
  41           AS_HELP_STRING([--enable-exampledir],
  42                          [specify alternate directory for examples]),
  43                          exampledir="$enableval",)
  44 dnl XXX add --exampledir to autoconf standard directory list somehow
  45 AC_SUBST(exampledir)
  46
  47 dnl default is to match previous behavior
  48 pkgsrcrcdir=""
  49 pkgsrcdir=""
  50 AC_ARG_ENABLE([pkgsrcrcdir],
  51           AS_HELP_STRING([--enable-pkgsrcrcdir],
  52                          [specify directory for rc.d scripts]),
  53                          pkgsrcrcdir="$enableval"; pkgsrcdir="pkgsrc",)
  54 dnl XXX add --pkgsrcrcdir to autoconf standard directory list somehow
  55 AC_SUBST(pkgsrcdir)
  56 AC_SUBST(pkgsrcrcdir)
  57
  58 AC_ARG_ENABLE(tcmalloc,
  59         AS_HELP_STRING([--enable-tcmalloc], [Turn on tcmalloc]),
  60 [case "${enableval}" in
  61   yes) tcmalloc_enabled=true
  62 LIBS="$LIBS -ltcmalloc_minimal"
  63  ;;
  64   no)  tcmalloc_enabled=false ;;
  65   *) AC_MSG_ERROR(bad value ${enableval} for --enable-tcmalloc) ;;
  66 esac],[tcmalloc_enabled=false])
  67
  68
  69 dnl --------------------
  70 dnl Check CC and friends
  71 dnl --------------------
  72 dnl note orig_cflags is also used further down
  73 orig_cflags="$CFLAGS"
  74 AC_LANG([C])
  75 AC_PROG_CC
  76 AC_PROG_CPP
  77 AM_PROG_CC_C_O
  78 dnl remove autoconf default "-g -O2"
  79 CFLAGS="$orig_cflags"
  80 AC_PROG_CC_C99
  81
  82 AC_PROG_EGREP
  83
  84 dnl autoconf 2.59 appears not to support AC_PROG_SED
  85 dnl AC_PROG_SED
  86 AC_CHECK_PROG([SED],[sed],[sed],[/bin/false])
  87
  88 dnl try and enable CFLAGS that are useful for Quagga
  89 dnl - specifically, options to control warnings
  90
  91 AC_USE_SYSTEM_EXTENSIONS()
  92 AC_DEFUN([AC_C_FLAG], [{
  93         AC_LANG_PUSH(C)
  94         ac_c_flag_save="$CFLAGS"
  95         CFLAGS="$CFLAGS $1"
  96         AC_MSG_CHECKING([[whether $CC supports $1]])
  97         AC_COMPILE_IFELSE(
  98                 [AC_LANG_PROGRAM([[]])],
  99                 [
 100                         AC_MSG_RESULT([yes])
 101                         m4_if([$3], [], [], [
 102                                 CFLAGS="$ac_c_flag_save"
 103                                 $3
 104                         ])
 105                 ], [
 106                         CFLAGS="$ac_c_flag_save"
 107                         AC_MSG_RESULT([no])
 108                         $2
 109                 ])
 110         AC_LANG_POP(C)
 111         }])
 112
 113 dnl ICC won't bail on unknown options without -diag-error 10006
 114 dnl need to do this first so we get useful results for the other options
 115 AC_C_FLAG([-diag-error 10006])
 116
 117 dnl if the user specified any CFLAGS, we don't add "-g -Os/-O2" here
 118 if test "z$orig_cflags" = "z"; then
 119   AC_C_FLAG([-g])
 120   AC_C_FLAG([-Os], [
 121     AC_C_FLAG([-O2])
 122   ])
 123 fi
 124
 125 dnl always want these CFLAGS
 126 AC_C_FLAG([-fno-omit-frame-pointer])
 127 AC_C_FLAG([-Wall])
 128 AC_C_FLAG([-Wextra])
 129 AC_C_FLAG([-Wmissing-prototypes])
 130 AC_C_FLAG([-Wmissing-declarations])
 131 AC_C_FLAG([-Wpointer-arith])
 132 AC_C_FLAG([-Wbad-function-cast])
 133 AC_C_FLAG([-Wwrite-strings])
 134 if test x"${enable_gcc_ultra_verbose}" = x"yes" ; then
 135   AC_C_FLAG([-Wcast-qual])
 136   AC_C_FLAG([-Wstrict-prototypes])
 137   AC_C_FLAG([-Wmissing-noreturn])
 138   AC_C_FLAG([-Wmissing-format-attribute])
 139   AC_C_FLAG([-Wunreachable-code])
 140   AC_C_FLAG([-Wpacked])
 141   AC_C_FLAG([-Wpadded])
 142 else
 143   AC_C_FLAG([-Wno-unused-result])
 144 fi
 145 AC_C_FLAG([-Wno-unused-parameter])
 146 AC_C_FLAG([-Wno-missing-field-initializers])
 147
 148 dnl ICC emits a broken warning for const char *x = a ? "b" : "c";
 149 dnl for some reason the string consts get 'promoted' to char *,
 150 dnl triggering a const to non-const conversion warning.
 151 AC_C_FLAG([-diag-disable 3179])
 152
 153 if test x"${enable_werror}" = x"yes" ; then
 154   WERROR="-Werror"
 155 fi
 156 AC_SUBST(WERROR)
 157
 158 dnl need link on this one, not compile
 159 AC_LANG_PUSH(C)
 160 ac_ld_flag_save="$LDFLAGS"
 161 LDFLAGS="$LDFLAGS -rdynamic"
 162 AC_MSG_CHECKING([[whether linker supports -rdynamic]])
 163 AC_LINK_IFELSE(
 164         [AC_LANG_PROGRAM([[]])],
 165         [AC_MSG_RESULT([yes])],
 166         [
 167                 LDFLAGS="$ac_ld_flag_save"
 168                 AC_MSG_RESULT([no])
 169         ])
 170 AC_LANG_POP(C)
 171
 172 dnl --------------
 173 dnl Check programs
 174 dnl --------------
 175 AC_PROG_INSTALL
 176 AC_PROG_LN_S
 177 AC_PROG_MAKE_SET
 178 AC_CHECK_TOOL(AR, ar)
 179
 180 dnl -----------------
 181 dnl System extensions
 182 dnl -----------------
 183 AC_GNU_SOURCE
 184
 185 dnl -------
 186 dnl libtool
 187 dnl -------
 188 LT_INIT
 189
 190 dnl ----------------------
 191 dnl Packages configuration
 192 dnl ----------------------
 193 AC_ARG_WITH(pkg-extra-version,
 194         AS_HELP_STRING([--with-pkg-extra-version=VER], [add extra version field, for packagers/distributions]),
 195         [EXTRAVERSION=$withval],)
 196 AC_ARG_WITH(pkg-git-version,
 197         AS_HELP_STRING([--with-pkg-git-version], [add git information to MOTD and build version string]),
 198         [ test "x$withval" != "xno" && with_pkg_git_version="yes" ])
 199 AC_ARG_ENABLE(vtysh,
 200   AS_HELP_STRING([--disable-vtysh], [do not build integrated vty shell for Quagga]))
 201 AC_ARG_ENABLE(doc,
 202   AS_HELP_STRING([--disable-doc], [do not build docs]))
 203 AC_ARG_ENABLE(zebra,
 204   AS_HELP_STRING([--disable-zebra], [do not build zebra daemon]))
 205 AC_ARG_ENABLE(bgpd,
 206   AS_HELP_STRING([--disable-bgpd], [do not build bgpd]))
 207 AC_ARG_ENABLE(ripd,
 208   AS_HELP_STRING([--disable-ripd], [do not build ripd]))
 209 AC_ARG_ENABLE(ripngd,
 210   AS_HELP_STRING([--disable-ripngd], [do not build ripngd]))
 211 AC_ARG_ENABLE(ospfd,
 212   AS_HELP_STRING([--disable-ospfd], [do not build ospfd]))
 213 AC_ARG_ENABLE(ospf6d,
 214   AS_HELP_STRING([--disable-ospf6d], [do not build ospf6d]))
 215 AC_ARG_ENABLE(ldpd,
 216   AS_HELP_STRING([--enable-ldpd], [build ldpd]))
 217 AC_ARG_ENABLE(watchfrr,
 218   AS_HELP_STRING([--disable-watchfrr], [do not build watchfrr]))
 219 AC_ARG_ENABLE(isisd,
 220   AS_HELP_STRING([--disable-isisd], [do not build isisd]))
 221 AC_ARG_ENABLE(pimd,
 222   AS_HELP_STRING([--disable-pimd], [do not build pimd]))
 223 AC_ARG_ENABLE(bgp-announce,
 224   AS_HELP_STRING([--disable-bgp-announce,], [turn off BGP route announcement]))
 225 AC_ARG_ENABLE(bgp-vnc,
 226   AS_HELP_STRING([--disable-bgp-vnc],[turn off BGP VNC support]))
 227 AC_ARG_WITH(rfp-path,
 228   AS_HELP_STRING([--with-rfp-path[=DIR]],[path to replaced stub RFP used with BGP VNC]))
 229 AC_ARG_ENABLE(snmp,
 230   AS_HELP_STRING([--enable-snmp=ARG], [enable SNMP support (smux or agentx)]))
 231 AC_ARG_WITH(libpam,
 232   AS_HELP_STRING([--with-libpam], [use libpam for PAM support in vtysh]))
 233 AC_ARG_ENABLE(tcp-zebra,
 234   AS_HELP_STRING([--enable-tcp-zebra], [enable TCP/IP socket connection between zebra and protocol daemon]))
 235 AC_ARG_ENABLE(ospfapi,
 236   AS_HELP_STRING([--disable-ospfapi], [do not build OSPFAPI to access the OSPF LSA Database]))
 237 AC_ARG_ENABLE(ospfclient,
 238   AS_HELP_STRING([--disable-ospfclient], [do not build OSPFAPI client for OSPFAPI,
 239                           (this is the default if --disable-ospfapi is set)]))
 240 AC_ARG_ENABLE(multipath,
 241   AS_HELP_STRING([--enable-multipath=ARG], [enable multipath function, ARG must be digit]))
 242 AC_ARG_ENABLE(user,
 243   AS_HELP_STRING([--enable-user=USER], [user to run FRR suite as (default frr)]))
 244 AC_ARG_ENABLE(group,
 245   AS_HELP_STRING([--enable-group=GROUP], [group to run FRR suite as (default frr)]))
 246 AC_ARG_ENABLE(vty_group,
 247   AS_HELP_STRING([--enable-vty-group=ARG], [set vty sockets to have specified group as owner]))
 248 AC_ARG_ENABLE(configfile_mask,
 249   AS_HELP_STRING([--enable-configfile-mask=ARG], [set mask for config files]))
 250 AC_ARG_ENABLE(logfile_mask,
 251   AS_HELP_STRING([--enable-logfile-mask=ARG], [set mask for log files]))
 252 AC_ARG_ENABLE(shell_access,
 253   AS_HELP_STRING([--enable-shell-access], [Allow users to access shell/telnet/ssh]))
 254 AC_ARG_ENABLE(rtadv,
 255   AS_HELP_STRING([--disable-rtadv], [disable IPV6 router advertisement feature]))
 256 AC_ARG_ENABLE(irdp,
 257   AS_HELP_STRING([--enable-irdp], [enable IRDP server support in zebra]))
 258 AC_ARG_ENABLE(capabilities,
 259   AS_HELP_STRING([--disable-capabilities], [disable using POSIX capabilities]))
 260 AC_ARG_ENABLE(rusage,
 261   AS_HELP_STRING([--disable-rusage], [disable using getrusage]))
 262 AC_ARG_ENABLE(gcc_ultra_verbose,
 263   AS_HELP_STRING([--enable-gcc-ultra-verbose], [enable ultra verbose GCC warnings]))
 264 AC_ARG_ENABLE(linux24_tcp_md5,
 265   AS_HELP_STRING([--enable-linux24-tcp-md5], [enable support for old, Linux-2.4 RFC2385 patch]))
 266 AC_ARG_ENABLE(backtrace,
 267   AS_HELP_STRING([--disable-backtrace,], [disable crash backtraces (default autodetect)]))
 268 AC_ARG_ENABLE(time-check,
 269   AS_HELP_STRING([--disable-time-check], [disable slow thread warning messages]))
 270 AC_ARG_ENABLE(pcreposix,
 271   AS_HELP_STRING([--enable-pcreposix], [enable using PCRE Posix libs for regex functions]))
 272 AC_ARG_ENABLE(fpm,
 273   AS_HELP_STRING([--enable-fpm], [enable Forwarding Plane Manager support]))
 274 AC_ARG_ENABLE(systemd,
 275   AS_HELP_STRING([--enable-systemd], [enable Systemd support]))
 276 AC_ARG_ENABLE(poll,
 277   AS_HELP_STRING([--enable-poll], [enable usage of Poll instead of select]))
 278 AC_ARG_ENABLE(werror,
 279   AS_HELP_STRING([--enable-werror], [enable -Werror (recommended for developers only)]))
 280 AC_ARG_ENABLE(cumulus,
 281   AS_HELP_STRING([--enable-cumulus], [enable Cumulus Switch Special Extensions]))
 282 AC_ARG_ENABLE(rr-semantics,
 283   AS_HELP_STRING([--disable-rr-semantics], [disable the v6 Route Replace semantics]))
 284 AC_ARG_ENABLE([protobuf],
 285   AS_HELP_STRING([--enable-protobuf], [Enable experimental protobuf support]))
 286 AC_ARG_ENABLE([oldvpn_commands],
 287   AS_HELP_STRING([--enable-old-vpn-commands], [Keep old vpn commands]))
 288
 289 AC_CHECK_HEADERS(json-c/json.h)
 290 AC_CHECK_LIB(json-c, json_object_get, LIBS="$LIBS -ljson-c")
 291 if test $ac_cv_lib_json_c_json_object_get = no; then
 292   AC_CHECK_LIB(json, json_object_get, LIBS="$LIBS -ljson")
 293   if test $ac_cv_lib_json_json_object_get = no; then
 294       AC_MSG_ERROR([lib json is needed to compile])
 295   fi
 296 fi
 297
 298 AC_ARG_ENABLE([dev_build],
 299     AS_HELP_STRING([--enable-dev-build], [build for development]))
 300
 301 if test x"${enable_time_check}" != x"no" ; then
 302   if test x"${enable_time_check}" = x"yes" -o x"${enable_time_check}" = x ; then
 303     AC_DEFINE(CONSUMED_TIME_CHECK,5000000,Consumed Time Check)
 304   else
 305     AC_DEFINE_UNQUOTED(CONSUMED_TIME_CHECK,$enable_time_check,Consumed Time Check)
 306   fi
 307 fi
 308
 309 case "${enable_systemd}" in
 310   "no") ;;
 311   "yes")
 312   AC_CHECK_LIB(systemd, sd_notify, LIBS="$LIBS -lsystemd")
 313   if test $ac_cv_lib_systemd_sd_notify = no; then
 314     AC_MSG_ERROR([enable systemd has been specified but systemd development env not found on your system])
 315   else
 316     AC_DEFINE(HAVE_SYSTEMD,,Compile systemd support in)
 317   fi
 318   ;;
 319   "*") ;;
 320 esac
 321
 322 if test "${enable_rr_semantics}" != "no" ; then
 323   AC_DEFINE(HAVE_V6_RR_SEMANTICS,, Compile in v6 Route Replacement Semantics)
 324 fi
 325
 326 if test "${enable_poll}" = "yes" ; then
 327   AC_DEFINE(HAVE_POLL,,Compile systemd support in)
 328 fi
 329
 330 dnl ----------
 331 dnl MPLS check
 332 dnl ----------
 333 AC_MSG_CHECKING(whether this OS has MPLS stack)
 334 case "$host" in
 335   *-linux*)
 336       MPLS_METHOD="zebra_mpls_netlink.o"
 337       AC_MSG_RESULT(Linux MPLS)
 338   ;;
 339   *-openbsd*)
 340       MPLS_METHOD="zebra_mpls_openbsd.o"
 341       AC_MSG_RESULT(OpenBSD MPLS)
 342   ;;
 343   *)
 344       MPLS_METHOD="zebra_mpls_null.o"
 345       AC_MSG_RESULT(Unsupported kernel)
 346   ;;
 347 esac
 348 AC_SUBST(MPLS_METHOD)
 349
 350 if test "${enable_cumulus}" = "yes" ; then
 351   AC_DEFINE(HAVE_CUMULUS,,Compile Special Cumulus Code in)
 352 fi
 353
 354 if test "${enable_shell_access}" = "yes"; then
 355    AC_DEFINE(HAVE_SHELL_ACCESS,,Allow user to use ssh/telnet/bash)
 356 fi
 357
 358 if test "${enable_fpm}" = "yes"; then
 359    AC_DEFINE(HAVE_FPM,,Forwarding Plane Manager support)
 360 fi
 361
 362 if test "x${enable_dev_build}" = "xyes"; then
 363    AC_DEFINE(DEV_BUILD,,Build for development)
 364 fi
 365 AM_CONDITIONAL([DEV_BUILD], [test "x$enable_dev_build" = "xyes"])
 366
 367 #
 368 # Logic for protobuf support.
 369 #
 370 if test "$enable_protobuf" = "yes"; then
 371    have_protobuf=yes
 372
 373    # Check for protoc-c
 374    AC_CHECK_PROG([PROTOC_C], [protoc-c], [protoc-c], [/bin/false])
 375    if test "x$PROTOC_C" = "x/bin/false"; then
 376       have_protobuf=no
 377    else
 378       found_protobuf_c=no
 379       PKG_CHECK_MODULES([PROTOBUF_C], libprotobuf-c >= 0.14,
 380                      [found_protobuf_c=yes],
 381                      [AC_MSG_RESULT([pkg-config did not find libprotobuf-c])])
 382
 383       if test "x$found_protobuf_c" = "xyes"; then
 384          LDFLAGS="$LDFLAGS $PROTOBUF_C_LIBS"
 385          CFLAGS="$CFLAGS $PROTOBUF_C_CFLAGS"
 386       else
 387         AC_CHECK_HEADER([google/protobuf-c/protobuf-c.h], [],
 388                         [have_protobuf=no; AC_MSG_RESULT([Couldn't find google/protobuf-c.h])])
 389       fi
 390    fi
 391 fi
 392
 393 #
 394 # Logic for old vpn commans support.
 395 #
 396 if test "$enable_old_vpn_commands" = "yes"; then
 397    AC_DEFINE(KEEP_OLD_VPN_COMMANDS,, [Define for compiling with old vpn commands])
 398 fi
 399
 400 # Fail if the user explicity enabled protobuf support and we couldn't
 401 # find the compiler or libraries.
 402 if test "x$have_protobuf" = "xno" && test "x$enable_protobuf" = "xyes"; then
 403    AC_MSG_ERROR([Protobuf enabled explicitly but can't find libraries/tools])
 404 fi
 405
 406 if test "x$have_protobuf" = "xyes"; then
 407    AC_DEFINE(HAVE_PROTOBUF,, protobuf)
 408 fi
 409
 410 AM_CONDITIONAL([HAVE_PROTOBUF], [test "x$have_protobuf" = "xyes"])
 411
 412 #
 413 # End of logic for protobuf support.
 414 #
 415
 416 if test "${enable_tcp_zebra}" = "yes"; then
 417   AC_DEFINE(HAVE_TCP_ZEBRA,,Use TCP for zebra communication)
 418 fi
 419
 420 if test "${enable_linux24_tcp_md5}" = "yes"; then
 421   AC_DEFINE(HAVE_TCP_MD5_LINUX24,,Old Linux 2.4 TCP MD5 Signature Patch)
 422 fi
 423
 424 AC_MSG_CHECKING(if zebra should be configurable to send Route Advertisements)
 425 if test "${enable_rtadv}" != "no"; then
 426   AC_MSG_RESULT(yes)
 427   AC_DEFINE(HAVE_RTADV,,Enable IPv6 Routing Advertisement support)
 428 else
 429   AC_MSG_RESULT(no)
 430 fi
 431
 432 if test "${enable_irdp}" = "yes"; then
 433   AC_DEFINE(HAVE_IRDP,, IRDP )
 434 fi
 435
 436 if test x"${enable_user}" = x"no"; then
 437   enable_user=""
 438 else
 439   if test x"${enable_user}" = x"yes" || test x"${enable_user}" = x""; then
 440     enable_user="frr"
 441   fi
 442   AC_DEFINE_UNQUOTED(FRR_USER, "${enable_user}", frr User)
 443 fi
 444
 445 if test x"${enable_group}" = x"no"; then
 446   enable_group=""
 447 else
 448   if test x"${enable_group}" = x"yes" || test x"${enable_group}" = x""; then
 449     enable_group="frr"
 450   fi
 451   AC_DEFINE_UNQUOTED(FRR_GROUP, "${enable_group}", frr Group)
 452 fi
 453
 454 if test x"${enable_vty_group}" = x"yes" ; then
 455   AC_MSG_ERROR([--enable-vty-group requires a group as argument, not yes])
 456 elif test x"${enable_vty_group}" != x""; then
 457   if test x"${enable_vty_group}" != x"no"; then
 458     AC_DEFINE_UNQUOTED(VTY_GROUP, "${enable_vty_group}", VTY Sockets Group)
 459   fi
 460 fi
 461 AC_SUBST([enable_user])
 462 AC_SUBST([enable_group])
 463 AC_SUBST([enable_vty_group])
 464
 465 enable_configfile_mask=${enable_configfile_mask:-0600}
 466 AC_DEFINE_UNQUOTED(CONFIGFILE_MASK, ${enable_configfile_mask}, Mask for config files)
 467
 468 enable_logfile_mask=${enable_logfile_mask:-0600}
 469 AC_DEFINE_UNQUOTED(LOGFILE_MASK, ${enable_logfile_mask}, Mask for log files)
 470
 471 MPATH_NUM=1
 472
 473 case "${enable_multipath}" in
 474   0)
 475     MPATH_NUM=64
 476     ;;
 477   [[1-9]|[1-9][0-9]|[1-9][0-9][0-9]])
 478     MPATH_NUM="${enable_multipath}"
 479     ;;
 480   "")
 481     ;;
 482   *)
 483     AC_MSG_FAILURE([Please specify digit to enable multipath ARG])
 484     ;;
 485 esac
 486
 487 AC_DEFINE_UNQUOTED(MULTIPATH_NUM, $MPATH_NUM, Maximum number of paths for a route)
 488
 489 dnl -----------------------------------
 490 dnl Add extra version string to package
 491 dnl name, string and version fields.
 492 dnl -----------------------------------
 493 if test "x${EXTRAVERSION}" != "x" ; then
 494   VERSION="${VERSION}${EXTRAVERSION}"
 495   PACKAGE_VERSION="${PACKAGE_VERSION}${EXTRAVERSION}"
 496   AC_SUBST(PACKAGE_EXTRAVERSION, ["${EXTRAVERSION}"])
 497   PACKAGE_STRING="${PACKAGE_STRING}${EXTRAVERSION}"
 498 fi
 499
 500 if test "x$with_pkg_git_version" = "xyes"; then
 501         if test -d "${srcdir}/.git"; then
 502                 AC_DEFINE(GIT_VERSION, [1], [include git version info])
 503         else    with_pkg_git_version="no"
 504                 AC_MSG_WARN([--with-pkg-git-version given, but this is not a git checkout])
 505         fi
 506 fi
 507 AM_CONDITIONAL([GIT_VERSION], [test "x$with_pkg_git_version" = "xyes"])
 508
 509 dnl ------------------------------------
 510 dnl Check C keywords and standard  types
 511 dnl ------------------------------------
 512 AC_C_CONST
 513 AC_C_INLINE
 514 AC_C_VOLATILE
 515 AC_HEADER_STDC
 516 dnl AC_TYPE_PID_T
 517 AC_TYPE_UID_T
 518 AC_TYPE_MODE_T
 519 AC_TYPE_SIZE_T
 520 AC_STRUCT_TM
 521
 522 dnl -------------------------
 523 dnl Check other header files.
 524 dnl -------------------------
 525 AC_CHECK_HEADERS([stropts.h sys/ksym.h \
 526         linux/version.h asm/types.h \
 527         sys/cdefs.h])
 528
 529 dnl Utility macro to avoid retyping includes all the time
 530 m4_define([FRR_INCLUDES],
 531 [#ifdef SUNOS_5
 532 #define _XPG4_2
 533 #define __EXTENSIONS__
 534 #endif
 535 #include <stdio.h>
 536 #include <stdlib.h>
 537 #include <stddef.h>
 538 #include <sys/types.h>
 539 /* sys/conf.h depends on param.h on FBSD at least */
 540 #include <sys/param.h>
 541 /* Required for MAXSIG */
 542 #include <signal.h>
 543 #include <sys/socket.h>
 544 #ifdef __APPLE__
 545 # define __APPLE_USE_RFC_3542
 546 #endif
 547 #include <netinet/in.h>
 548 #include <sys/time.h>
 549 #include <time.h>
 550 #include <net/if.h>
 551 ])dnl
 552
 553 dnl Same applies for HAVE_NET_IF_VAR_H, which HAVE_NETINET6_ND6_H and
 554 dnl HAVE_NETINET_IN_VAR_H depend upon. But if_var.h depends on if.h, hence
 555 dnl an additional round for it.
 556
 557 AC_CHECK_HEADERS([net/if_var.h], [], [], FRR_INCLUDES)
 558
 559 m4_define([FRR_INCLUDES],
 560 FRR_INCLUDES
 561 [#if HAVE_NET_IF_VAR_H
 562 # include <net/if_var.h>
 563 #endif
 564 ])dnl
 565
 566 AC_CHECK_HEADERS([netinet/in_var.h \
 567         net/if_dl.h net/netopt.h \
 568         inet/nd.h netinet/ip_icmp.h \
 569         sys/sysctl.h sys/sockio.h kvm.h sys/conf.h],
 570         [], [], FRR_INCLUDES)
 571
 572 AC_CHECK_HEADERS([ucontext.h], [], [],
 573 [#ifndef __USE_GNU
 574 #define __USE_GNU
 575 #endif /* __USE_GNU */
 576 FRR_INCLUDES
 577 ])
 578
 579 m4_define([UCONTEXT_INCLUDES],
 580 [#include <ucontext.h>])dnl
 581
 582 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.uc_regs],
 583   [], [], [UCONTEXT_INCLUDES])
 584 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs],
 585   [AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs.nip],
 586    [], [], [UCONTEXT_INCLUDES])],
 587   [], [UCONTEXT_INCLUDES])
 588 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.gregs],
 589   [], [], [UCONTEXT_INCLUDES])
 590
 591 m4_define([FRR_INCLUDES],
 592 FRR_INCLUDES
 593 [
 594 #include <sys/un.h>
 595 #include <netinet/in_systm.h>
 596 #if HAVE_NETINET_IN_VAR_H
 597 # include <netinet/in_var.h>
 598 #endif
 599 #if HAVE_NET_IF_DL_H
 600 # include <net/if_dl.h>
 601 #endif
 602 #if HAVE_NET_NETOPT_H
 603 # include <net/netopt.h>
 604 #endif
 605 #include <net/route.h>
 606 #if HAVE_INET_ND_H
 607 # include <inet/nd.h>
 608 #endif
 609 #include <arpa/inet.h>
 610 /* Required for IDRP */
 611 #if HAVE_NETINET_IP_ICMP_H
 612 # include <netinet/ip_icmp.h>
 613 #endif
 614 ])dnl
 615
 616 dnl V6 headers are checked below, after we check for v6
 617
 618 dnl Some systems (Solaris 2.x) require libnsl (Network Services Library)
 619 case "$host" in
 620   [*-sunos5.[6-7]*] | [*-solaris2.[6-7]*])
 621       opsys=sol2-6
 622       AC_DEFINE(SUNOS_56, 1, SunOS 5.6 to 5.7)
 623       AC_DEFINE(SUNOS_5, 1, SunOS 5)
 624       AC_CHECK_LIB(xnet, main)
 625       CURSES=-lcurses
 626       SOLARIS="solaris"
 627   ;;
 628   [*-sunos5.[8-9]] \
 629   | [*-sunos5.1[0-9]] \
 630   | [*-sunos5.1[0-9].[0-9]] \
 631   | [*-solaris2.[8-9]] \
 632   | [*-solaris2.1[0-9]] \
 633   | [*-solaris2.1[0-9].[0-9]])
 634       opsys=sol8
 635       AC_DEFINE(SUNOS_59, 1, [SunOS 5.8 up])
 636       AC_DEFINE(SUNOS_5, 1, [SunOS 5])
 637       AC_CHECK_LIB(socket, main)
 638       AC_CHECK_LIB(nsl, main)
 639       AC_CHECK_LIB(umem, main)
 640       AC_CHECK_FUNCS([printstack],
 641         [AC_DEFINE([HAVE_PRINTSTACK],1,[Solaris printstack])
 642          AC_DEFINE([HAVE_STACK_TRACE],1,[Stack symbols decode functionality])
 643         ])
 644       CURSES=-lcurses
 645       SOLARIS="solaris"
 646   ;;
 647   *-sunos5* | *-solaris2*)
 648       AC_DEFINE(SUNOS_5,,SunOS 5, Unknown SunOS)
 649       AC_CHECK_LIB(socket, main)
 650       AC_CHECK_LIB(nsl, main)
 651       CURSES=-lcurses
 652       SOLARIS="solaris"
 653   ;;
 654   *-linux*)
 655       opsys=gnu-linux
 656       AC_DEFINE(GNU_LINUX,,GNU Linux)
 657   ;;
 658   *-openbsd*)
 659       opsys=openbsd
 660       AC_DEFINE(OPEN_BSD,,OpenBSD)
 661   ;;
 662 esac
 663
 664 AC_SYS_LARGEFILE
 665
 666 dnl ---------------------
 667 dnl Integrated VTY option
 668 dnl ---------------------
 669 case "${enable_vtysh}" in
 670   "no") VTYSH="";;
 671   *)    VTYSH="vtysh";
 672          AC_DEFINE(VTYSH,,VTY shell)
 673 dnl      Vtysh uses libreadline, which looks for termcap functions at
 674 dnl      configure time.  We follow readlines search order.
 675 dnl      The required procedures are in libtermcap on NetBSD, in
 676 dnl      [TODO] on Linux, and in [TODO] on Solaris.
 677          AC_CHECK_LIB(termcap, tputs, LIBREADLINE="$LIBREADLINE -ltermcap",
 678            [AC_CHECK_LIB(tinfo, tputs, LIBREADLINE="$LIBREADLINE -ltinfo",
 679              [AC_CHECK_LIB(curses, tputs, LIBREADLINE="$LIBREADLINE -lcurses",
 680                [AC_CHECK_LIB(ncurses, tputs,
 681                              LIBREADLINE="$LIBREADLINE -lncurses")]
 682               )]
 683             )]
 684           )
 685          AC_CHECK_LIB(readline, main, LIBREADLINE="-lreadline $LIBREADLINE",,
 686                       "$LIBREADLINE")
 687          if test $ac_cv_lib_readline_main = no; then
 688            AC_MSG_ERROR([vtysh needs libreadline but was not found and usable on your system.])
 689          fi
 690          AC_CHECK_HEADER(readline/history.h)
 691          if test $ac_cv_header_readline_history_h = no;then
 692            AC_MSG_ERROR([readline is too old to have readline/history.h, please update to the latest readline library.])
 693          fi
 694          AC_CHECK_LIB(readline, rl_completion_matches,
 695                       LIBREADLINE="$LIBREADLINE",, "$LIBREADLINE")
 696          if test $ac_cv_lib_readline_rl_completion_matches = no; then
 697            AC_DEFINE(rl_completion_matches,completion_matches,Old readline)
 698          fi
 699          ;;
 700 esac
 701 AC_SUBST(LIBREADLINE)
 702 AM_CONDITIONAL(VTYSH, test "x$VTYSH" = "xvtysh")
 703
 704 dnl ----------
 705 dnl PAM module
 706 dnl
 707 dnl Quagga detects the PAM library it is built against by checking for a
 708 dnl functional pam_misc.h (Linux-PAM) or openpam.h (OpenPAM) header. pam_misc.h
 709 dnl is known to #include pam_appl.h, the standard header of a PAM library, and
 710 dnl openpam.h doesn't do that, although depends on the header too. Hence a
 711 dnl little assistance to AC_CHECK_HEADER is necessary for the proper detection
 712 dnl of OpenPAM.
 713 dnl ----------
 714 if test "$with_libpam" = "yes"; then
 715   AC_CHECK_HEADER([security/pam_misc.h],
 716     [AC_DEFINE(HAVE_PAM_MISC_H,,Have pam_misc.h)
 717      AC_DEFINE(PAM_CONV_FUNC,misc_conv,Have misc_conv)
 718      pam_conv_func="misc_conv"
 719     ],
 720     [], FRR_INCLUDES)
 721   AC_CHECK_HEADER([security/openpam.h],
 722     [AC_DEFINE(HAVE_OPENPAM_H,,Have openpam.h)
 723      AC_DEFINE(PAM_CONV_FUNC,openpam_ttyconv,Have openpam_ttyconv)
 724      pam_conv_func="openpam_ttyconv"
 725     ],
 726     [], FRR_INCLUDES[#include <security/pam_appl.h>])
 727   if test -z "$ac_cv_header_security_pam_misc_h$ac_cv_header_security_openpam_h" ; then
 728     AC_MSG_WARN([*** pam support will not be built ***])
 729     with_libpam="no"
 730   fi
 731 fi
 732
 733 if test "$with_libpam" = "yes"; then
 734 dnl took this test from proftpds configure.in and suited to our needs
 735 dnl -------------------------------------------------------------------------
 736 dnl
 737 dnl This next check looks funky due to a linker problem with some versions
 738 dnl of the PAM library.  Prior to 0.72 release, the Linux PAM shared library
 739 dnl omitted requiring libdl linking information. PAM-0.72 or better ships
 740 dnl with RedHat 6.2 and Debian 2.2 or better.
 741 AC_CHECK_LIB(pam, pam_start,
 742   [AC_CHECK_LIB(pam, $pam_conv_func,
 743     [AC_DEFINE(USE_PAM,,Use PAM for authentication)
 744      LIBPAM="-lpam"],
 745     [AC_DEFINE(USE_PAM,,Use PAM for authentication)
 746      LIBPAM="-lpam -lpam_misc"]
 747     )
 748   ],
 749
 750   [AC_CHECK_LIB(pam, pam_end,
 751     [AC_CHECK_LIB(pam, $pam_conv_func,
 752       [AC_DEFINE(USE_PAM,,Use PAM for authentication)
 753        LIBPAM="-lpam -ldl"],
 754       [AC_DEFINE(USE_PAM,,Use PAM for authentication)
 755        LIBPAM="-lpam -ldl -lpam_misc"]
 756      )
 757   ],AC_MSG_WARN([*** pam support will not be built ***]),
 758   [-ldl])
 759   ]
 760 )
 761 fi
 762 AC_SUBST(LIBPAM)
 763
 764 dnl -------------------------------
 765 dnl Endian-ness check
 766 dnl -------------------------------
 767 AC_WORDS_BIGENDIAN
 768
 769 dnl -------------------------------
 770 dnl check the size in byte of the C
 771 dnl -------------------------------
 772 dnl AC_CHECK_SIZEOF(char)
 773 dnl AC_CHECK_SIZEOF(int)
 774 dnl AC_CHECK_SIZEOF(short)
 775 dnl AC_CHECK_SIZEOF(long)
 776
 777 dnl ----------------------------
 778 dnl check existance of functions
 779 dnl ----------------------------
 780 AC_FUNC_FNMATCH
 781 AC_FUNC_FORK
 782 AC_FUNC_MKTIME
 783 AC_FUNC_STAT
 784
 785 dnl -------------------------------
 786 dnl bgpd needs pow() and hence libm
 787 dnl -------------------------------
 788 TMPLIBS="$LIBS"
 789 AC_CHECK_HEADER([math.h],
 790   [AC_CHECK_LIB([m], [pow],
 791     [LIBM="-lm"
 792      LIBS="$LIBS $LIBM"
 793      AC_CHECK_FUNCS(pow,[],[LIBM=""])
 794     ])
 795 ])
 796 if test x"$LIBM" = x ; then
 797   AC_MSG_WARN([Unable to find working pow function - bgpd may not link])
 798 fi
 799 LIBS="$TMPLIBS"
 800 AC_SUBST(LIBM)
 801
 802 dnl ---------------
 803 dnl other functions
 804 dnl ---------------
 805 AC_CHECK_FUNCS([ \
 806         strlcat strlcpy \
 807         getgrouplist \
 808         pledge])
 809
 810 AC_CHECK_HEADER([asm-generic/unistd.h],
 811                 [AC_CHECK_DECL(__NR_setns,
 812                                AC_DEFINE(HAVE_NETNS,, Have netns),,
 813                                FRR_INCLUDES [#include <asm-generic/unistd.h>
 814                                ])
 815                  AC_CHECK_FUNCS(setns)]
 816                )
 817
 818 dnl ------------------------------------
 819 dnl Determine routing get and set method
 820 dnl ------------------------------------
 821 AC_MSG_CHECKING(zebra between kernel interface method)
 822 if test x"$opsys" = x"gnu-linux"; then
 823   AC_MSG_RESULT(netlink)
 824   RT_METHOD=rt_netlink.o
 825   KERNEL_METHOD=kernel_netlink.o
 826   AC_DEFINE(HAVE_NETLINK,,netlink)
 827   netlink=yes
 828   AC_CHECK_DECLS([IFLA_INFO_SLAVE_KIND], [], [], [#include <linux/if_link.h>])
 829 else
 830   AC_MSG_RESULT(Route socket)
 831   KERNEL_METHOD="kernel_socket.o"
 832   RT_METHOD="rt_socket.o"
 833 fi
 834 AC_SUBST(RT_METHOD)
 835 AC_SUBST(KERNEL_METHOD)
 836 AM_CONDITIONAL([HAVE_NETLINK], [test "x$netlink" = "xyes"])
 837
 838 dnl --------------------------
 839 dnl Determine IS-IS I/O method
 840 dnl --------------------------
 841 AC_DEFINE(ISIS_METHOD_PFPACKET, 1, [ constant value for isis method pfpacket ])
 842 AC_DEFINE(ISIS_METHOD_DLPI,     2, [ constant value for isis method dlpi ])
 843 AC_DEFINE(ISIS_METHOD_BPF,      3, [ constant value for isis method bpf ])
 844 AC_CHECK_HEADER(net/bpf.h)
 845 AC_CHECK_HEADER(sys/dlpi.h)
 846 AC_MSG_CHECKING(zebra IS-IS I/O method)
 847 if test x"$opsys" = x"gnu-linux"; then
 848   AC_MSG_RESULT(pfpacket)
 849   ISIS_METHOD_MACRO="ISIS_METHOD_PFPACKET"
 850 elif test x"$opsys" = x"sol2-6" -o x"$opsys" = x"sol8"; then
 851   AC_MSG_RESULT(DLPI)
 852   ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
 853 else
 854   if test $ac_cv_header_net_bpf_h = no; then
 855     if test $ac_cv_header_sys_dlpi_h = no; then
 856       AC_MSG_RESULT(none)
 857       AC_MSG_WARN([*** IS-IS support will not be built ***])
 858       ISISD=""
 859     else
 860       AC_MSG_RESULT(DLPI)
 861     fi
 862     ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
 863   else
 864     AC_MSG_RESULT(BPF)
 865     ISIS_METHOD_MACRO="ISIS_METHOD_BPF"
 866   fi
 867 fi
 868 AC_DEFINE_UNQUOTED(ISIS_METHOD, $ISIS_METHOD_MACRO, [ selected method for isis, == one of the constants ])
 869
 870 dnl ------------------------------------
 871 dnl check for broken CMSG_FIRSTHDR macro
 872 dnl ------------------------------------
 873 AC_MSG_CHECKING(for broken CMSG_FIRSTHDR)
 874 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 875 #ifdef SUNOS_5
 876 #define _XPG4_2
 877 #define __EXTENSIONS__
 878 #endif
 879 #include <stdlib.h>
 880 #include <sys/types.h>
 881 #include <sys/socket.h>
 882
 883 main()
 884 {
 885   struct msghdr msg;
 886   char buf[4];
 887
 888   msg.msg_control = buf;
 889   msg.msg_controllen = 0;
 890
 891   if (CMSG_FIRSTHDR(&msg) != NULL)
 892     exit(0);
 893   exit (1);
 894 }]])],[AC_MSG_RESULT(yes - using workaround) AC_DEFINE(HAVE_BROKEN_CMSG_FIRSTHDR,,Broken CMSG_FIRSTHDR)],
 895 [AC_MSG_RESULT(no)],[AC_MSG_RESULT(no)])
 896
 897 dnl ------------------------------
 898 dnl check kernel route read method
 899 dnl ------------------------------
 900 AC_CACHE_CHECK([route read method], [frr_cv_rtread_method],
 901 [if test "x$netlink" = xyes; then
 902   frr_cv_rtread_method="netlink"
 903 else
 904 for frr_cv_rtread_method in /dev/ip /dev/null;
 905 do
 906   test x`ls $frr_cv_rtread_method 2>/dev/null` = x"$frr_cv_rtread_method" && break
 907 done
 908 case $frr_cv_rtread_method in
 909   "/dev/ip")
 910                      case "$host" in
 911                        *-freebsd*)    frr_cv_rtread_method="sysctl";;
 912                        *)             frr_cv_rtread_method="getmsg";;
 913                      esac;;
 914         *)
 915                      frr_cv_rtread_method="sysctl";;
 916 esac
 917 fi])
 918 RTREAD_METHOD=rtread_${frr_cv_rtread_method}.o
 919 AC_SUBST(RTREAD_METHOD)
 920
 921 dnl -----------------------------
 922 dnl check interface lookup method
 923 dnl -----------------------------
 924 IOCTL_METHOD=ioctl.o
 925 AC_MSG_CHECKING(interface looking up method)
 926 if test "$netlink" = yes; then
 927   AC_MSG_RESULT(netlink)
 928   IF_METHOD=if_netlink.o
 929 elif test "$opsys" = "sol2-6";then
 930   AC_MSG_RESULT(Solaris GIF)
 931   IF_METHOD=if_ioctl.o
 932 elif test "$opsys" = "sol8";then
 933   AC_MSG_RESULT(Solaris GLIF)
 934   IF_METHOD=if_ioctl_solaris.o
 935   IOCTL_METHOD=ioctl_solaris.o
 936 elif test "$opsys" = "openbsd";then
 937   AC_MSG_RESULT(openbsd)
 938   IF_METHOD=if_ioctl.o
 939 elif grep NET_RT_IFLIST /usr/include/sys/socket.h >/dev/null 2>&1; then
 940   AC_MSG_RESULT(sysctl)
 941     IF_METHOD=if_sysctl.o
 942     AC_DEFINE(HAVE_NET_RT_IFLIST,,NET_RT_IFLIST)
 943 else
 944     AC_MSG_RESULT(ioctl)
 945     IF_METHOD=if_ioctl.o
 946 fi
 947 AC_SUBST(IF_METHOD)
 948 AC_SUBST(IOCTL_METHOD)
 949
 950 dnl ---------------------------------------------------------------
 951 dnl figure out how to specify an interface in multicast sockets API
 952 dnl ---------------------------------------------------------------
 953 AC_CHECK_MEMBERS([struct ip_mreqn.imr_ifindex], [], [], FRR_INCLUDES)
 954
 955 AC_CHECK_HEADERS([linux/mroute.h], [], [],[
 956         #include <sys/socket.h>
 957         #include <netinet/in.h>
 958         #define _LINUX_IN_H             /* For Linux <= 2.6.25 */
 959         #include <linux/types.h>
 960 ])
 961
 962 m4_define([FRR_INCLUDES],
 963 FRR_INCLUDES
 964 [#if HAVE_LINUX_MROUTE_H
 965 # include <linux/mroute.h>
 966 #endif
 967 ])dnl
 968
 969 AC_CHECK_HEADERS([netinet/ip_mroute.h], [], [],[
 970         #include <sys/socket.h>
 971         #include <sys/types.h>
 972         #include <netinet/in.h>
 973         #include <net/route.h>
 974 ])
 975
 976 m4_define([FRR_INCLUDES],
 977 FRR_INCLUDES
 978 [#if HAVE_NETINET_IP_MROUTE_H
 979 # include <netinet/ip_mroute.h>
 980 #endif
 981 ])dnl
 982
 983 AC_MSG_CHECKING([for BSD struct ip_mreq hack])
 984 AC_TRY_COMPILE([#include <sys/param.h>],
 985 [#if (defined(__FreeBSD__) && ((__FreeBSD_version >= 500022 && __FreeBSD_version < 700000) || (__FreeBSD_version < 500000 && __FreeBSD_version >= 440000))) || (defined(__NetBSD__) && defined(__NetBSD_Version__) && __NetBSD_Version__ >= 106010000) || defined(__OpenBSD__) || defined(__APPLE__) || defined(__DragonFly__) || defined(__sun)
 986   return (0);
 987 #else
 988   #error No support for BSD struct ip_mreq hack detected
 989 #endif],[AC_MSG_RESULT(yes)
 990 AC_DEFINE(HAVE_BSD_STRUCT_IP_MREQ_HACK,,[Can pass ifindex in struct ip_mreq])],
 991 AC_MSG_RESULT(no))
 992
 993 AC_MSG_CHECKING([for RFC3678 protocol-independed API])
 994 AC_TRY_COMPILE([
 995 #include <sys/types.h>
 996 #include <netinet/in.h>
 997 ], [struct group_req gr; int sock; setsockopt(sock, IPPROTO_IP, MCAST_JOIN_GROUP, (void*)&gr, sizeof(gr));
 998 ], [AC_MSG_RESULT(yes)
 999 AC_DEFINE(HAVE_RFC3678,1,[Have RFC3678 protocol-independed API])],
1000 AC_MSG_RESULT(no))
1001
1002 dnl ---------------------------------------------------------------
1003 dnl figure out how to check link-state
1004 dnl ---------------------------------------------------------------
1005 AC_CHECK_HEADER( [net/if_media.h],
1006   [m4_define([LINK_DETECT_INCLUDES],
1007     FRR_INCLUDES
1008     [#include <net/if_media.h>
1009   ])
1010   AC_CHECK_MEMBERS( [struct ifmediareq.ifm_status],
1011     AC_DEFINE(HAVE_BSD_LINK_DETECT,,[BSD link-detect]),
1012     [], LINK_DETECT_INCLUDES)],
1013   [],
1014   FRR_INCLUDES)
1015
1016 dnl ---------------------------------------------------------------
1017 dnl Additional, newer way to check link-state using ifi_link_state.
1018 dnl Not available in all BSD's when ifmediareq available
1019 dnl ---------------------------------------------------------------
1020 AC_CHECK_MEMBERS([struct if_data.ifi_link_state],
1021   AC_DEFINE(HAVE_BSD_IFI_LINK_STATE,,[BSD ifi_link_state available]),
1022   [], FRR_INCLUDES)
1023
1024 dnl ------------------------
1025 dnl TCP_MD5SIG socket option
1026 dnl ------------------------
1027
1028 AC_CHECK_HEADER([netinet/tcp.h],
1029    [m4_define([MD5_INCLUDES],
1030       FRR_INCLUDES
1031       [#include <netinet/tcp.h>
1032     ])
1033     AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)],
1034    [],
1035    FRR_INCLUDES)
1036 if test $ac_cv_have_decl_TCP_MD5SIG = no; then
1037   AC_CHECK_HEADER([linux/tcp.h],
1038        [m4_define([MD5_INCLUDES],
1039           FRR_INCLUDES
1040           [#include <linux/tcp.h>
1041         ])
1042        AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)])
1043 fi
1044
1045 dnl -----------------------------
1046 dnl check ipforward detect method
1047 dnl -----------------------------
1048 AC_CACHE_CHECK([ipforward method], [frr_cv_ipforward_method],
1049 [if test x$cross_compiling = xyes; then
1050   if test x"$opsys" = x"gnu-linux"; then
1051     frr_cv_ipforward_method=/proc/net/snmp
1052   else
1053     frr_cv_ipforward_method=/dev/ip
1054   fi
1055 else
1056   for frr_cv_ipforward_method in /proc/net/snmp /dev/ip /dev/null;
1057   do
1058     test x`ls $frr_cv_ipforward_method 2>/dev/null` = x"$frr_cv_ipforward_method" && break
1059   done
1060 fi
1061 case $frr_cv_ipforward_method in
1062   "/proc/net/snmp")  frr_cv_ipforward_method="proc";;
1063   "/dev/ip")
1064                      case "$host" in
1065                        *-freebsd*)    frr_cv_ipforward_method="sysctl";;
1066                        *)             frr_cv_ipforward_method="solaris";;
1067                      esac;;
1068   *)                 frr_cv_ipforward_method="sysctl";;
1069 esac])
1070 IPFORWARD=ipforward_${frr_cv_ipforward_method}.o
1071 AC_SUBST(IPFORWARD)
1072
1073 dnl ----------------------------------------------------------------------------
1074 dnl figure out if domainname is available in the utsname struct (GNU extension).
1075 dnl ----------------------------------------------------------------------------
1076 AC_CHECK_MEMBERS([struct utsname.domainname], [], [], [#include <sys/utsname.h>])
1077
1078 dnl ----------
1079 dnl IPv6 check
1080 dnl ----------
1081 AC_MSG_CHECKING(whether does this OS have IPv6 stack)
1082 dnl ---------
1083 dnl KAME IPv6
1084 dnl ---------
1085   if grep WIDE /usr/include/netinet6/in6.h >/dev/null 2>&1; then
1086     AC_DEFINE(KAME,1,KAME IPv6)
1087     AC_MSG_RESULT(KAME)
1088 dnl ------------------------------------
1089 dnl Solaris 9, 10 and potentially higher
1090 dnl ------------------------------------
1091   elif test x"$opsys" = x"sol8"; then
1092     AC_DEFINE(SOLARIS_IPV6, 1, Solaris IPv6)
1093     AC_MSG_RESULT(Solaris IPv6)
1094 dnl ----------
1095 dnl Linux IPv6
1096 dnl ----------
1097   elif test x"$opsys" = x"gnu-linux"; then
1098     AC_DEFINE(LINUX_IPV6,1,Linux IPv6 stack)
1099     dnl Linux has a compilation problem with mixing
1100     dnl netinet/in.h and linux/in6.h they are not
1101     dnl compatible.  There has been discussion on
1102     dnl how to fix it but no real progress on implementation
1103     dnl when they fix it, remove this
1104     AC_DEFINE(IPV6_MINHOPCOUNT, 73, Linux ipv6 Min Hop Count)
1105     AC_MSG_RESULT(Linux IPv6)
1106   else
1107     AC_MSG_ERROR([Failed to detect IPv6 stack])
1108   fi
1109
1110 dnl ------------------
1111 dnl IPv6 header checks
1112 dnl ------------------
1113 AC_CHECK_HEADERS([netinet6/in6.h netinet/in6_var.h \
1114         netinet6/in6_var.h netinet6/nd6.h], [], [],
1115         FRR_INCLUDES)
1116
1117 m4_define([FRR_INCLUDES],dnl
1118 FRR_INCLUDES
1119 [#if HAVE_NETINET6_IN6_H
1120 #include <netinet6/in6.h>
1121 #endif
1122 #if HAVE_NETINET_IN6_VAR_H
1123 #include <netinet/in6_var.h>
1124 #endif
1125 #include <netinet/icmp6.h>
1126 #if HAVE_NETINET6_IN6_VAR_H
1127 # include <netinet6/in6_var.h>
1128 #endif
1129 #if HAVE_NETINET6_ND6_H
1130 # include <netinet6/nd6.h>
1131 #endif
1132 ])dnl
1133
1134 dnl disable doc check
1135 if test "${enable_doc}" = "no";then
1136   DOC=""
1137 else
1138   DOC="doc"
1139 fi
1140
1141 dnl --------------------
1142 dnl Daemon disable check
1143 dnl --------------------
1144 if test "${enable_zebra}" = "no";then
1145   ZEBRA=""
1146 else
1147   ZEBRA="zebra"
1148 fi
1149 AM_CONDITIONAL(ZEBRA, test "x$ZEBRA" = "xzebra")
1150
1151 if test "${enable_bgpd}" = "no";then
1152   BGPD=""
1153 else
1154   BGPD="bgpd"
1155 fi
1156 AM_CONDITIONAL(BGPD, test "x$BGPD" = "xbgpd")
1157
1158 if test "${enable_ripd}" = "no";then
1159   RIPD=""
1160 else
1161   RIPD="ripd"
1162 fi
1163 AM_CONDITIONAL(RIPD, test "x$RIPD" = "xripd")
1164
1165 if test "${enable_ospfd}" = "no";then
1166   OSPFD=""
1167 else
1168   OSPFD="ospfd"
1169 fi
1170 AM_CONDITIONAL(OSPFD, test "x$OSPFD" = "xospfd")
1171
1172 if test "${enable_ldpd}" = "no";then
1173   LDPD=""
1174 else
1175   AX_PROG_PERL_MODULES(XML::LibXML, , [
1176     if test -f "${srcdir}/ldpd/ldp_vty_cmds.c"; then
1177       AC_MSG_WARN([XML::LibXML perl module not found, using pregenerated ldp_vty_cmds.c])
1178     else
1179       AC_MSG_ERROR([XML::LibXML perl module not found and pregenerated ldp_vty_cmds.c missing])
1180     fi
1181   ])
1182
1183   LDPD="ldpd"
1184   AC_DEFINE(HAVE_LDPD, 1, ldpd)
1185 fi
1186 AM_CONDITIONAL(LDPD, test "x$LDPD" = "xldpd")
1187
1188 if test "${enable_watchfrr}" = "no";then
1189   WATCHFRR=""
1190 else
1191   WATCHFRR="watchfrr"
1192 fi
1193 AM_CONDITIONAL(WATCHFRR, test "x$WATCHFRR" = "xwatchfrr")
1194
1195 OSPFCLIENT=""
1196 if test "${enable_ospfapi}" != "no";then
1197     AC_DEFINE(SUPPORT_OSPF_API,,OSPFAPI)
1198
1199   if test "${enable_ospfclient}" != "no";then
1200       OSPFCLIENT="ospfclient"
1201   fi
1202 fi
1203
1204 AM_CONDITIONAL(OSPFCLIENT, test "x$OSPFCLIENT" = "xospfclient")
1205
1206 case "${enable_ripngd}" in
1207   "no" ) RIPNGD="";;
1208   *    ) RIPNGD="ripngd";;
1209 esac
1210 AM_CONDITIONAL(RIPNGD, test "x$RIPNGD" = "xripngd")
1211
1212 case "${enable_ospf6d}" in
1213   "no" ) OSPF6D="";;
1214   *    ) OSPF6D="ospf6d";;
1215 esac
1216 AM_CONDITIONAL(OSPF6D, test "x$OSPF6D" = "xospf6d")
1217
1218 case "${enable_isisd}" in
1219   "no" ) ISISD="";;
1220   *    ) ISISD="isisd";;
1221 esac
1222 AM_CONDITIONAL(ISISD, test "x$ISISD" = "xisisd")
1223
1224 case "${enable_pimd}" in
1225   "no" ) PIMD="";;
1226   *    ) PIMD="pimd";;
1227 esac
1228 AM_CONDITIONAL(PIMD, test "x$PIMD" = "xpimd")
1229
1230 if test "${enable_bgp_announce}" = "no";then
1231   AC_DEFINE(DISABLE_BGP_ANNOUNCE,1,Disable BGP installation to zebra)
1232 else
1233   AC_DEFINE(DISABLE_BGP_ANNOUNCE,0,Disable BGP installation to zebra)
1234 fi
1235
1236 if test "${with_rfp_path}" = "yes" || test x"${with_rfp_path}" = x""; then
1237   with_rfp_path="bgpd/rfp-example"
1238 fi
1239 if test "${with_rfp_path}" != "no"; then
1240   VNC_RFP_PATH="${with_rfp_path}"
1241   AC_SUBST(VNC_RFP_PATH)
1242 fi
1243
1244 if test "${enable_bgp_vnc}" != "no";then
1245   AC_DEFINE(ENABLE_BGP_VNC,1,Enable BGP VNC support)
1246   RFPTEST="${with_rfp_path}/rfptest"
1247   LIBRFP="${with_rfp_path}/librfp"
1248   RFPINC="${with_rfp_path}/librfp"
1249 else
1250   RFPTEST=
1251   LIBRFP=
1252   RFPINC="bgpd/rfp-example/librfp"
1253 fi
1254 # set
1255 AM_CONDITIONAL([ENABLE_BGP_VNC], [test x${enable_bgp_vnc} != xno])
1256
1257 AC_SUBST(DOC)
1258 AC_SUBST(ZEBRA)
1259 AC_SUBST(RFPTEST)
1260 AC_SUBST(LIBRFP)
1261 AC_SUBST(RFPINC)
1262 AC_SUBST(BGPD)
1263 AC_SUBST(RIPD)
1264 AC_SUBST(RIPNGD)
1265 AC_SUBST(OSPFD)
1266 AC_SUBST(OSPF6D)
1267 AC_SUBST(LDPD)
1268 AC_SUBST(WATCHFRR)
1269 AC_SUBST(ISISD)
1270 AC_SUBST(PIMD)
1271 AC_SUBST(SOLARIS)
1272 AC_SUBST(VTYSH)
1273 AC_SUBST(CURSES)
1274 AC_SUBST(OSPFCLIENT)
1275 AC_SUBST(OSPFAPI)
1276 AC_CHECK_LIB(crypt, crypt)
1277 AC_CHECK_LIB(resolv, res_init)
1278
1279 dnl ---------------------------
1280 dnl check system has PCRE regexp
1281 dnl ---------------------------
1282 if test "x$enable_pcreposix" = "xyes"; then
1283   AC_CHECK_LIB(pcreposix, pcreposix_regexec, ,[enable_pcreposix=no
1284   AC_MSG_WARN([*** falling back to other regex library ***]) ])
1285 fi
1286 AC_SUBST(HAVE_LIBPCREPOSIX)
1287
1288 dnl ------------------
1289 dnl check Net-SNMP library
1290 dnl ------------------
1291 if test "${enable_snmp}" != ""; then
1292    AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], [no])
1293    if test x"$NETSNMP_CONFIG" = x"no"; then
1294       AC_MSG_ERROR([--enable-snmp given but unable to find net-snmp-config])
1295    fi
1296    LIBS="$LIBS `${NETSNMP_CONFIG} --agent-libs`"
1297    CFLAGS="`${NETSNMP_CONFIG} --base-cflags` $CFLAGS"
1298    AC_MSG_CHECKING([whether we can link to Net-SNMP])
1299    AC_LINK_IFELSE([AC_LANG_PROGRAM([
1300 int main(void);
1301 ],
1302 [
1303 {
1304   return 0;
1305 }
1306 ])],[AC_MSG_RESULT(yes)],[
1307      AC_MSG_RESULT(no)
1308      AC_MSG_ERROR([--enable-snmp given but not usable])])
1309    AC_DEFINE(HAVE_SNMP,,SNMP)
1310    case "${enable_snmp}" in
1311      yes)
1312       SNMP_METHOD=agentx
1313       ;;
1314      smux|agentx)
1315       SNMP_METHOD="${enable_snmp}"
1316       ;;
1317      *)
1318       AC_MSG_ERROR([--enable-snmp given with an unknown method (${enable_snmp}). Use smux or agentx])
1319       ;;
1320    esac
1321    AH_TEMPLATE([SNMP_SMUX], [Use SNMP SMUX to interface with snmpd])
1322    AH_TEMPLATE([SNMP_AGENTX], [Use SNMP AgentX to interface with snmpd])
1323    AC_DEFINE_UNQUOTED(AS_TR_CPP(SNMP_${SNMP_METHOD}),,SNMP method to interface with snmpd)
1324 fi
1325
1326 dnl ---------------------------
1327 dnl sockaddr and netinet checks
1328 dnl ---------------------------
1329 AC_CHECK_TYPES([
1330         struct sockaddr_dl,
1331         struct vifctl, struct mfcctl, struct sioc_sg_req,
1332         vifi_t, struct sioc_vif_req, struct igmpmsg,
1333         struct ifaliasreq, struct if6_aliasreq, struct in6_aliasreq,
1334         struct nd_opt_adv_interval, struct rt_addrinfo,
1335         struct nd_opt_homeagent_info, struct nd_opt_adv_interval],
1336         [], [], FRR_INCLUDES)
1337
1338 AC_CHECK_MEMBERS([struct sockaddr.sa_len,
1339         struct sockaddr_in.sin_len, struct sockaddr_un.sun_len,
1340         struct sockaddr_dl.sdl_len,
1341         struct if6_aliasreq.ifra_lifetime,
1342         struct nd_opt_adv_interval.nd_opt_ai_type],
1343         [], [], FRR_INCLUDES)
1344
1345 dnl ---------------------------
1346 dnl IRDP/pktinfo/icmphdr checks
1347 dnl ---------------------------
1348 AC_CHECK_TYPES([struct in_pktinfo],
1349  [AC_CHECK_TYPES([struct icmphdr],
1350    [if test "${enable_irdp}" != "no"; then
1351       AC_DEFINE(HAVE_IRDP,, IRDP)
1352     fi],
1353    [if test "${enable_irdp}" = "yes"; then
1354       AC_MSG_ERROR(['IRDP requires in_pktinfo at the moment!'])
1355     fi], [FRR_INCLUDES])],
1356  [if test "${enable_irdp}" = "yes"; then
1357     AC_MSG_ERROR(['IRDP requires in_pktinfo at the moment!'])
1358   fi], [FRR_INCLUDES])
1359
1360 dnl -----------------------
1361 dnl checking for IP_PKTINFO
1362 dnl -----------------------
1363 AC_MSG_CHECKING(for IP_PKTINFO)
1364 AC_TRY_COMPILE([#include <netdb.h>], [
1365   int opt = IP_PKTINFO;
1366 ], [
1367   AC_MSG_RESULT(yes)
1368   AC_DEFINE(HAVE_IP_PKTINFO, 1, [Have IP_PKTINFO])
1369 ], [
1370   AC_MSG_RESULT(no)
1371 ])
1372
1373 dnl ---------------------------
1374 dnl checking for IP_RECVDSTADDR
1375 dnl ---------------------------
1376 AC_MSG_CHECKING(for IP_RECVDSTADDR)
1377 AC_TRY_COMPILE([#include <netinet/in.h>], [
1378   int opt = IP_RECVDSTADDR;
1379 ], [
1380   AC_MSG_RESULT(yes)
1381   AC_DEFINE(HAVE_IP_RECVDSTADDR, 1, [Have IP_RECVDSTADDR])
1382 ], [
1383   AC_MSG_RESULT(no)
1384 ])
1385
1386 dnl ----------------------
1387 dnl checking for IP_RECVIF
1388 dnl ----------------------
1389 AC_MSG_CHECKING(for IP_RECVIF)
1390 AC_TRY_COMPILE([#include <netinet/in.h>], [
1391   int opt = IP_RECVIF;
1392 ], [
1393   AC_MSG_RESULT(yes)
1394   AC_DEFINE(HAVE_IP_RECVIF, 1, [Have IP_RECVIF])
1395 ], [
1396   AC_MSG_RESULT(no)
1397 ])
1398
1399 dnl ----------------------
1400 dnl checking for SO_BINDANY
1401 dnl ----------------------
1402 AC_MSG_CHECKING(for SO_BINDANY)
1403 AC_TRY_COMPILE([#include <sys/socket.h>], [
1404   int opt = SO_BINDANY;
1405 ], [
1406   AC_MSG_RESULT(yes)
1407   AC_DEFINE(HAVE_SO_BINDANY, 1, [Have SO_BINDANY])
1408 ], [
1409   AC_MSG_RESULT(no)
1410 ])
1411
1412 dnl ----------------------
1413 dnl checking for IP_FREEBIND
1414 dnl ----------------------
1415 AC_MSG_CHECKING(for IP_FREEBIND)
1416 AC_TRY_COMPILE([#include <netinet/in.h>], [
1417   int opt = IP_FREEBIND;
1418 ], [
1419   AC_MSG_RESULT(yes)
1420   AC_DEFINE(HAVE_IP_FREEBIND, 1, [Have IP_FREEBIND])
1421 ], [
1422   AC_MSG_RESULT(no)
1423 ])
1424
1425 dnl --------------------------------------
1426 dnl checking for clock_time monotonic struct and call
1427 dnl --------------------------------------
1428 AC_CHECK_DECL(CLOCK_MONOTONIC,
1429         [AC_CHECK_LIB(rt, clock_gettime, [LIBS="$LIBS -lrt"])
1430          AC_DEFINE(HAVE_CLOCK_MONOTONIC,, Have monotonic clock)
1431 ], [AC_MSG_RESULT(no)], [FRR_INCLUDES])
1432
1433 dnl --------------------------------------
1434 dnl checking for flex and bison
1435 dnl --------------------------------------
1436
1437 AM_PROG_LEX
1438 AC_MSG_CHECKING(version of flex)
1439 quagga_ac_flex_version="$(eval $LEX -V | grep flex | head -n 1)"
1440 quagga_ac_flex_version="${quagga_ac_flex_version##* }"
1441 AC_MSG_RESULT([$quagga_ac_flex_version])
1442 AX_COMPARE_VERSION([$quagga_ac_flex_version], [lt], [2.5.20], [
1443   LEX="$SHELL $missing_dir/missing flex"
1444   if test -f "${srcdir}/lib/command_lex.c" -a -f "${srcdir}/lib/command_lex.h"; then
1445     AC_MSG_WARN([using pregenerated flex output files])
1446   else
1447     AC_MSG_ERROR([flex failure and pregenerated files not included (probably a git build)])
1448   fi
1449   AC_SUBST([LEX_OUTPUT_ROOT], [lex.yy])
1450   AC_SUBST([LEXLIB], [''])
1451 ])
1452
1453 AC_PROG_YACC
1454 dnl thanks GNU bison for this b*llshit...
1455 AC_MSG_CHECKING(version of bison)
1456 quagga_ac_bison_version="$(eval $YACC -V | grep bison | head -n 1)"
1457 quagga_ac_bison_version="${quagga_ac_bison_version##* }"
1458 quagga_ac_bison_missing="false"
1459 case "x${quagga_ac_bison_version}" in
1460   x2.7*)
1461     BISON_OPENBRACE='"'
1462     BISON_CLOSEBRACE='"'
1463     BISON_VERBOSE=''
1464     AC_MSG_RESULT([$quagga_ac_bison_version - 2.7 or older])
1465     ;;
1466   x2.*|x1.*)
1467     AC_MSG_RESULT([$quagga_ac_bison_version])
1468     AC_MSG_WARN([installed bison is too old.  Please install GNU bison 2.7.x or newer.])
1469     quagga_ac_bison_missing="true"
1470     ;;
1471   x)
1472     AC_MSG_RESULT([none])
1473     AC_MSG_WARN([could not determine bison version.  Please install GNU bison 2.7.x or newer.])
1474     quagga_ac_bison_missing="true"
1475     ;;
1476   *)
1477     BISON_OPENBRACE='{'
1478     BISON_CLOSEBRACE='}'
1479     BISON_VERBOSE='-Dparse.error=verbose'
1480     AC_MSG_RESULT([$quagga_ac_bison_version - 3.0 or newer])
1481     ;;
1482 esac
1483 AC_SUBST(BISON_OPENBRACE)
1484 AC_SUBST(BISON_CLOSEBRACE)
1485 AC_SUBST(BISON_VERBOSE)
1486
1487 if $quagga_ac_bison_missing; then
1488   YACC="$SHELL $missing_dir/missing bison -y"
1489   if test -f "${srcdir}/lib/command_parse.c" -a -f "${srcdir}/lib/command_parse.h"; then
1490     AC_MSG_WARN([using pregenerated bison output files])
1491   else
1492     AC_MSG_ERROR([bison failure and pregenerated files not included (probably a git build)])
1493   fi
1494 fi
1495
1496 dnl -------------------
1497 dnl capabilities checks
1498 dnl -------------------
1499 if test "${enable_capabilities}" != "no"; then
1500   AC_MSG_CHECKING(whether prctl PR_SET_KEEPCAPS is available)
1501   AC_TRY_COMPILE([#include <sys/prctl.h>],[prctl(PR_SET_KEEPCAPS, 1, 0, 0, 0);],
1502     [AC_MSG_RESULT(yes)
1503      AC_DEFINE(HAVE_PR_SET_KEEPCAPS,,prctl)
1504      frr_ac_keepcaps="yes"],
1505      AC_MSG_RESULT(no)
1506   )
1507   if test x"${frr_ac_keepcaps}" = x"yes"; then
1508     AC_CHECK_HEADERS(sys/capability.h)
1509   fi
1510   if test x"${ac_cv_header_sys_capability_h}" = x"yes"; then
1511     AC_CHECK_LIB(cap, cap_init,
1512       [AC_DEFINE(HAVE_LCAPS,1,Capabilities)
1513        LIBCAP="-lcap"
1514        frr_ac_lcaps="yes"]
1515     )
1516   else
1517     AC_CHECK_HEADERS(priv.h,
1518      [AC_MSG_CHECKING(Solaris style privileges are available)
1519       AC_TRY_COMPILE([#include <priv.h>],[getpflags(PRIV_AWARE);],
1520           [AC_MSG_RESULT(yes)
1521            AC_DEFINE(HAVE_SOLARIS_CAPABILITIES,1,getpflags)
1522            frr_ac_scaps="yes"],
1523            AC_MSG_RESULT(no)
1524       )
1525      ]
1526    )
1527   fi
1528   if test x"${frr_ac_scaps}" = x"yes" \
1529        -o x"${frr_ac_lcaps}" = x"yes"; then
1530     AC_DEFINE(HAVE_CAPABILITIES,1,capabilities)
1531   fi
1532 fi
1533 AC_SUBST(LIBCAP)
1534
1535 dnl ---------------------------
1536 dnl check for glibc 'backtrace'
1537 dnl ---------------------------
1538 if test x"${enable_backtrace}" != x"no" ; then
1539   backtrace_ok=no
1540   AC_CHECK_HEADER([execinfo.h], [
1541     AC_SEARCH_LIBS([backtrace], [execinfo], [
1542       AC_DEFINE(HAVE_GLIBC_BACKTRACE,,[Glibc backtrace])
1543       AC_DEFINE(HAVE_STACK_TRACE,,[Stack symbol decoding])
1544       backtrace_ok=yes
1545     ],, [-lm])
1546   ])
1547
1548   if test x"${enable_backtrace}" = x"yes" -a x"${backtrace_ok}" = x"no"; then
1549     dnl user explicitly requested backtrace but we failed to find support
1550     AC_MSG_FAILURE([failed to find backtrace support])
1551   fi
1552 fi
1553
1554 dnl -----------------------------------------
1555 dnl check for malloc mallinfo struct and call
1556 dnl this must try and link using LIBS, in
1557 dnl order to check no alternative allocator
1558 dnl has been specified, which might not provide
1559 dnl mallinfo, e.g. such as Umem on Solaris.
1560 dnl -----------------------------------------
1561 AC_CHECK_HEADER([malloc.h],
1562  [AC_MSG_CHECKING(whether mallinfo is available)
1563   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <malloc.h>]],
1564                         [[struct mallinfo ac_x; ac_x = mallinfo ();]])],
1565       [AC_MSG_RESULT(yes)
1566        AC_DEFINE(HAVE_MALLINFO,,mallinfo)],
1567        AC_MSG_RESULT(no)
1568   )
1569  ], [], FRR_INCLUDES)
1570
1571 dnl ----------
1572 dnl configure date
1573 dnl ----------
1574 CONFDATE=`date '+%Y%m%d'`
1575 AC_SUBST(CONFDATE)
1576
1577 dnl -------
1578 dnl DejaGNU
1579 dnl -------
1580 if test x"$DEJAGNU" = x
1581 then
1582   DEJAGNU="\$(top_srcdir)/tests/global-conf.exp"
1583 fi
1584 RUNTESTDEFAULTFLAGS="-x --tool \$\$tool"
1585
1586 AC_SUBST(DEJAGNU)
1587 AC_SUBST(RUNTESTDEFAULTFLAGS)
1588
1589 dnl ------------------------------
1590 dnl set paths for state directory
1591 dnl ------------------------------
1592 AC_MSG_CHECKING(directory to use for state file)
1593 if test "${prefix}" = "NONE"; then
1594   frr_statedir_prefix="";
1595 else
1596   frr_statedir_prefix=${prefix}
1597 fi
1598 if test "${localstatedir}" = '${prefix}/var'; then
1599   for FRR_STATE_DIR in ${frr_statedir_prefix}/var/run dnl
1600                         ${frr_statedir_prefix}/var/adm dnl
1601                         ${frr_statedir_prefix}/etc dnl
1602                         /var/run        dnl
1603                         /var/adm        dnl
1604                         /etc            dnl
1605                         /dev/null;
1606   do
1607     test -d $FRR_STATE_DIR && break
1608   done
1609   frr_statedir=$FRR_STATE_DIR
1610 else
1611   frr_statedir=${localstatedir}
1612 fi
1613 if test $frr_statedir = "/dev/null"; then
1614     AC_MSG_ERROR('STATE DIRECTORY NOT FOUND! FIX OR SPECIFY --localstatedir!')
1615 fi
1616 AC_MSG_RESULT(${frr_statedir})
1617 AC_SUBST(frr_statedir)
1618
1619 AC_DEFINE_UNQUOTED(PATH_ZEBRA_PID, "$frr_statedir/zebra.pid",zebra PID)
1620 AC_DEFINE_UNQUOTED(PATH_RIPD_PID, "$frr_statedir/ripd.pid",ripd PID)
1621 AC_DEFINE_UNQUOTED(PATH_RIPNGD_PID, "$frr_statedir/ripngd.pid",ripngd PID)
1622 AC_DEFINE_UNQUOTED(PATH_BGPD_PID, "$frr_statedir/bgpd.pid",bgpd PID)
1623 AC_DEFINE_UNQUOTED(PATH_OSPFD_PID, "$frr_statedir/ospfd.pid",ospfd PID)
1624 AC_DEFINE_UNQUOTED(PATH_OSPF6D_PID, "$frr_statedir/ospf6d.pid",ospf6d PID)
1625 AC_DEFINE_UNQUOTED(PATH_LDPD_PID, "$frr_statedir/ldpd.pid",ldpd PID)
1626 AC_DEFINE_UNQUOTED(LDPD_SOCKET, "$frr_statedir/ldpd.sock",ldpd control socket)
1627 AC_DEFINE_UNQUOTED(PATH_ISISD_PID, "$frr_statedir/isisd.pid",isisd PID)
1628 AC_DEFINE_UNQUOTED(PATH_PIMD_PID, "$frr_statedir/pimd.pid",pimd PID)
1629 AC_DEFINE_UNQUOTED(PATH_WATCHFRR_PID, "$frr_statedir/watchfrr.pid",watchfrr PID)
1630 AC_DEFINE_UNQUOTED(ZEBRA_SERV_PATH, "$frr_statedir/zserv.api",zebra api socket)
1631 AC_DEFINE_UNQUOTED(ZEBRA_VTYSH_PATH, "$frr_statedir/zebra.vty",zebra vty socket)
1632 AC_DEFINE_UNQUOTED(RIP_VTYSH_PATH, "$frr_statedir/ripd.vty",rip vty socket)
1633 AC_DEFINE_UNQUOTED(RIPNG_VTYSH_PATH, "$frr_statedir/ripngd.vty",ripng vty socket)
1634 AC_DEFINE_UNQUOTED(BGP_VTYSH_PATH, "$frr_statedir/bgpd.vty",bgpd vty socket)
1635 AC_DEFINE_UNQUOTED(OSPF_VTYSH_PATH, "$frr_statedir/ospfd.vty",ospfd vty socket)
1636 AC_DEFINE_UNQUOTED(OSPF6_VTYSH_PATH, "$frr_statedir/ospf6d.vty",ospf6d vty socket)
1637 AC_DEFINE_UNQUOTED(LDP_VTYSH_PATH, "$frr_statedir/ldpd.vty",ldpd vty socket)
1638 AC_DEFINE_UNQUOTED(ISIS_VTYSH_PATH, "$frr_statedir/isisd.vty",isisd vty socket)
1639 AC_DEFINE_UNQUOTED(PIM_VTYSH_PATH, "$frr_statedir/pimd.vty",pimd vty socket)
1640 AC_DEFINE_UNQUOTED(WATCHFRR_VTYSH_PATH, "$frr_statedir/watchfrr.vty",watchfrr vty socket)
1641 AC_DEFINE_UNQUOTED(DAEMON_VTY_DIR, "$frr_statedir",daemon vty directory)
1642
1643 dnl autoconf does this, but it does it too late...
1644 test "x$prefix" = xNONE && prefix=$ac_default_prefix
1645 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
1646
1647 dnl get the full path, recursing through variables...
1648 vtysh_bin="$bindir/vtysh"
1649 for I in 1 2 3 4 5 6 7 8 9 10; do
1650         eval vtysh_bin="\"$vtysh_bin\""
1651 done
1652 AC_DEFINE_UNQUOTED(VTYSH_BIN_PATH, "$vtysh_bin",path to vtysh binary)
1653
1654 CFG_SYSCONF="$sysconfdir"
1655 CFG_SBIN="$sbindir"
1656 CFG_STATE="$frr_statedir"
1657 for I in 1 2 3 4 5 6 7 8 9 10; do
1658         eval CFG_SYSCONF="\"$CFG_SYSCONF\""
1659         eval CFG_SBIN="\"$CFG_SBIN\""
1660         eval CFG_STATE="\"$CFG_STATE\""
1661 done
1662 AC_SUBST(CFG_SYSCONF)
1663 AC_SUBST(CFG_SBIN)
1664 AC_SUBST(CFG_STATE)
1665
1666 dnl -------------------------------
1667 dnl Quagga sources should always be
1668 dnl current wrt interfaces. Dont
1669 dnl allow deprecated interfaces to
1670 dnl be exposed.
1671 dnl -------------------------------
1672 AC_DEFINE(QUAGGA_NO_DEPRECATED_INTERFACES, 1, Hide deprecated interfaces)
1673
1674 dnl ---------------------------
1675 dnl Check htonl works correctly
1676 dnl ---------------------------
1677 AC_MSG_CHECKING(for working htonl)
1678 AC_CACHE_VAL(ac_cv_htonl_works,
1679  [AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES],[htonl (0);])],
1680                 [ac_cv_htonl_works=yes], [ac_cv_htonl_works=no])
1681  ]
1682 )
1683 AC_MSG_RESULT($ac_cv_htonl_works)
1684
1685 AC_CONFIG_FILES([Makefile lib/Makefile qpb/Makefile zebra/Makefile ripd/Makefile
1686           ripngd/Makefile bgpd/Makefile ospfd/Makefile watchfrr/Makefile
1687           ospf6d/Makefile ldpd/Makefile isisd/Makefile vtysh/Makefile
1688           doc/Makefile ospfclient/Makefile tests/Makefile m4/Makefile
1689           pimd/Makefile
1690           tests/bgpd.tests/Makefile
1691           tests/libzebra.tests/Makefile
1692           redhat/Makefile
1693           tools/Makefile
1694           cumulus/Makefile
1695           pkgsrc/Makefile
1696           fpm/Makefile
1697           redhat/frr.spec
1698           snapcraft/Makefile
1699           snapcraft/snapcraft.yaml
1700           lib/version.h
1701           doc/defines.texi
1702           doc/bgpd.8
1703           doc/isisd.8
1704           doc/ospf6d.8
1705           doc/ospfclient.8
1706           doc/ospfd.8
1707           doc/ldpd.8
1708           doc/ripd.8
1709           doc/ripngd.8
1710           doc/pimd.8
1711           doc/vtysh.1
1712           doc/watchfrr.8
1713           doc/zebra.8
1714           doc/frr.1
1715           pkgsrc/bgpd.sh pkgsrc/ospf6d.sh pkgsrc/ospfd.sh
1716           pkgsrc/ripd.sh pkgsrc/ripngd.sh pkgsrc/zebra.sh])
1717
1718 if test "${enable_bgp_vnc}" != "no"; then
1719    if test "${with_rfp_path}" = "bgpd/rfp-example" ; then
1720      AC_CONFIG_FILES([bgpd/rfp-example/rfptest/Makefile bgpd/rfp-example/librfp/Makefile])
1721    else
1722      AC_CONFIG_FILES([${with_rfp_path}/rfptest/Makefile ${with_rfp_path}/librfp/Makefile])
1723    fi
1724 fi
1725
1726 AC_CONFIG_FILES([solaris/Makefile])
1727
1728 AC_CONFIG_FILES([vtysh/extract.pl],[chmod +x vtysh/extract.pl])
1729
1730 ## Hack, but working solution to avoid rebuilding of quagga.info.
1731 ## It's already in CVS until texinfo 4.7 is more common.
1732 AC_OUTPUT
1733
1734 echo "
1735 FreeRangeRouting configuration
1736 ------------------------------
1737 FRR version             : ${PACKAGE_VERSION}
1738 host operating system   : ${host_os}
1739 source code location    : ${srcdir}
1740 compiler                : ${CC}
1741 compiler flags          : ${CFLAGS}
1742 make                    : ${MAKE-make}
1743 linker flags            : ${LDFLAGS} ${LIBS} ${LIBCAP} ${LIBREADLINE} ${LIBM}
1744 state file directory    : ${frr_statedir}
1745 config file directory   : `eval echo \`echo ${sysconfdir}\``
1746 example directory       : `eval echo \`echo ${exampledir}\``
1747 user to run as          : ${enable_user}
1748 group to run as         : ${enable_group}
1749 group for vty sockets   : ${enable_vty_group}
1750 config file mask        : ${enable_configfile_mask}
1751 log file mask           : ${enable_logfile_mask}
1752 zebra protobuf enabled  : ${have_protobuf:-no}
1753
1754 The above user and group must have read/write access to the state file
1755 directory and to the config files in the config file directory."