configure.ac

   1 ##
   2 ## Configure template file for FRRouting.
   3 ## autoconf will generate configure script.
   4 ##
   5 ##  Copyright (c) 1996, 97, 98, 99, 2000 Kunihiro Ishiguro <kunihiro@zebra.org>
   6 ##  Portions Copyright (c) 2003 Paul Jakma <paul@dishone.st>
   7 ##
   8 AC_PREREQ(2.60)
   9
  10 AC_INIT(frr, 6.0, [https://github.com/frrouting/frr/issues])
  11 PACKAGE_URL="https://frrouting.org/"
  12 AC_SUBST(PACKAGE_URL)
  13 PACKAGE_FULLNAME="FRRouting"
  14 AC_SUBST(PACKAGE_FULLNAME)
  15
  16 CONFIG_ARGS="$ac_configure_args"
  17 AC_SUBST(CONFIG_ARGS)
  18
  19 AC_CONFIG_SRCDIR(lib/zebra.h)
  20 AC_CONFIG_MACRO_DIR([m4])
  21
  22 dnl -----------------------------------
  23 dnl Get hostname and other information.
  24 dnl -----------------------------------
  25 AC_CANONICAL_BUILD()
  26 AC_CANONICAL_HOST()
  27
  28 AS_IF([test "$host" != "$build"], [
  29   if test "$srcdir" = "."; then
  30     AC_MSG_ERROR([cross-compilation is only possible with builddir separate from srcdir.  create a separate directory and run as .../path-to-frr/configure.])
  31   fi
  32   test -d hosttools || mkdir hosttools
  33   abssrc="`cd \"${srcdir}\"; pwd`"
  34
  35   AC_MSG_NOTICE([...])
  36   AC_MSG_NOTICE([... cross-compilation: creating hosttools directory and self-configuring for build platform tools])
  37   AC_MSG_NOTICE([... use HOST_CPPFLAGS / HOST_CFLAGS / HOST_LDFLAGS if neccessary])
  38   AC_MSG_NOTICE([...])
  39
  40   ( CPPFLAGS="$HOST_CPPFLAGS"; \
  41     CFLAGS="$HOST_CFLAGS"; \
  42     LDFLAGS="$HOST_LDFLAGS"; \
  43     cd hosttools; "${abssrc}/configure" "--host=$build" "--build=$build" "--enable-clippy-only" "--disable-nhrpd" "--disable-vtysh"; )
  44
  45   AC_MSG_NOTICE([...])
  46   AC_MSG_NOTICE([... cross-compilation: finished self-configuring for build platform tools])
  47   AC_MSG_NOTICE([...])
  48
  49   build_clippy="false"
  50   HOSTTOOLS="hosttools/"
  51 ], [
  52   build_clippy="true"
  53   HOSTTOOLS=""
  54 ])
  55 AC_SUBST(HOSTTOOLS)
  56 AM_CONDITIONAL([BUILD_CLIPPY], [$build_clippy])
  57
  58 # Disable portability warnings -- our automake code (in particular
  59 # common.am) uses some constructs specific to gmake.
  60 AM_INIT_AUTOMAKE([1.12 -Wno-portability foreign])
  61 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
  62 AM_SILENT_RULES([yes])
  63 AC_CONFIG_HEADERS(config.h)
  64
  65 AC_PATH_PROG(PERL, perl)
  66 PKG_PROG_PKG_CONFIG
  67
  68 dnl default is to match previous behavior
  69 exampledir=${sysconfdir}
  70 AC_ARG_ENABLE([exampledir],
  71           AS_HELP_STRING([--enable-exampledir],
  72                          [specify alternate directory for examples]),
  73                          exampledir="$enableval",)
  74 dnl XXX add --exampledir to autoconf standard directory list somehow
  75 AC_SUBST(exampledir)
  76
  77 dnl default is to match previous behavior
  78 pkgsrcrcdir=""
  79 AC_ARG_ENABLE([pkgsrcrcdir],
  80           AS_HELP_STRING([--enable-pkgsrcrcdir],
  81                          [specify directory for rc.d scripts]),
  82                          pkgsrcrcdir="$enableval",)
  83 dnl XXX add --pkgsrcrcdir to autoconf standard directory list somehow
  84 AC_SUBST(pkgsrcrcdir)
  85 AM_CONDITIONAL([PKGSRC], [test "x$pkgsrcrcdir" != "x"])
  86
  87 AC_ARG_WITH([moduledir], [AS_HELP_STRING([--with-moduledir=DIR], [module directory (${libdir}/frr/modules)])], [
  88         moduledir="$withval"
  89 ], [
  90         moduledir="\${libdir}/frr/modules"
  91 ])
  92 AC_SUBST([moduledir], [$moduledir])
  93
  94 AC_ARG_ENABLE(tcmalloc,
  95         AS_HELP_STRING([--enable-tcmalloc], [Turn on tcmalloc]),
  96 [case "${enableval}" in
  97   yes) tcmalloc_enabled=true
  98 LIBS="$LIBS -ltcmalloc_minimal"
  99  ;;
 100   no)  tcmalloc_enabled=false ;;
 101   *) AC_MSG_ERROR(bad value ${enableval} for --enable-tcmalloc) ;;
 102 esac],[tcmalloc_enabled=false])
 103
 104
 105 dnl Thanks autoconf, but we don't want a default -g -O2.  We have our own
 106 dnl flag determination logic.
 107 CFLAGS="${CFLAGS:-}"
 108
 109 dnl --------------------
 110 dnl Check CC and friends
 111 dnl --------------------
 112 dnl note orig_cflags is also used further down
 113 orig_cflags="$CFLAGS"
 114 AC_LANG([C])
 115 AC_PROG_CC
 116 AC_PROG_CPP
 117 AM_PROG_CC_C_O
 118 dnl remove autoconf default "-g -O2"
 119 CFLAGS="$orig_cflags"
 120 AC_PROG_CC_C99
 121 dnl NB: see C11 below
 122
 123 AC_PROG_EGREP
 124 PKG_PROG_PKG_CONFIG
 125
 126 dnl autoconf 2.59 appears not to support AC_PROG_SED
 127 dnl AC_PROG_SED
 128 AC_CHECK_PROG([SED],[sed],[sed],[/bin/false])
 129
 130 dnl try and enable CFLAGS that are useful for FRR
 131 dnl - specifically, options to control warnings
 132
 133 AC_USE_SYSTEM_EXTENSIONS
 134 AC_DEFUN([AC_C_FLAG], [{
 135     m4_pushdef([cachename],[m4_translit([frr_cv_$1],[ =-],[___])])
 136     AC_CACHE_CHECK([[whether $CC supports $1]], cachename, [
 137         AC_LANG_PUSH(C)
 138         ac_c_flag_save="$CFLAGS"
 139         CFLAGS="$CFLAGS $1"
 140         AC_COMPILE_IFELSE(
 141                 [AC_LANG_PROGRAM([[]])],
 142                 [
 143                         cachename=yes
 144                 ], [
 145                         cachename=no
 146                 ])
 147         CFLAGS="$ac_c_flag_save"
 148         AC_LANG_POP(C)
 149     ])
 150     if test "${cachename}" = yes; then
 151         m4_if([$3], [], [CFLAGS="$CFLAGS $1"], [$3])
 152     else
 153         :
 154         $2
 155     fi
 156     m4_popdef([cachename])
 157 }])
 158
 159 AC_DEFUN([AC_LINK_IFELSE_FLAGS], [{
 160         AC_LANG_PUSH(C)
 161         ac_cflags_save="$CFLAGS"
 162         ac_libs_save="$LIBS"
 163         CFLAGS="$CFLAGS $1"
 164         LIBS="$LIBS $2"
 165         AC_LINK_IFELSE(
 166                 [$3],
 167                 [
 168                         AC_MSG_RESULT([yes])
 169                         CFLAGS="$ac_cflags_save"
 170                         LIBS="$ac_libs_save"
 171                         $5
 172                 ], [
 173                         AC_MSG_RESULT([no])
 174                         CFLAGS="$ac_cflags_save"
 175                         LIBS="$ac_libs_save"
 176                         $4
 177                 ])
 178         AC_LANG_POP(C)
 179         }])
 180
 181 dnl ICC won't bail on unknown options without -diag-error 10006
 182 dnl need to do this first so we get useful results for the other options
 183 AC_C_FLAG([-diag-error 10006])
 184
 185 dnl AC_PROG_CC_C99 may change CC to include -std=gnu99 or something
 186 ac_cc="$CC"
 187 CC="${CC% -std=gnu99}"
 188 CC="${CC% -std=c99}"
 189
 190 AC_C_FLAG([-std=gnu11], [CC="$ac_cc"], [CC="$CC -std=gnu11"])
 191
 192 dnl if the user has specified any CFLAGS, override our settings
 193 if test "x${enable_gcov}" = "xyes"; then
 194    if test "z$orig_cflags" = "z"; then
 195       AC_C_FLAG([-coverage])
 196       AC_C_FLAG([-O0])
 197    fi
 198
 199    LDFLAGS="${LDFLAGS} -lgcov"
 200 elif test "x${enable_dev_build}" = "xyes"; then
 201    AC_DEFINE(DEV_BUILD,,Build for development)
 202    if test "z$orig_cflags" = "z"; then
 203       AC_C_FLAG([-g3])
 204       AC_C_FLAG([-O0])
 205    fi
 206 else
 207    if test "z$orig_cflags" = "z"; then
 208       AC_C_FLAG([-g])
 209       AC_C_FLAG([-Os], [
 210         AC_C_FLAG([-O2])
 211       ])
 212    fi
 213 fi
 214 AM_CONDITIONAL([DEV_BUILD], [test "x$enable_dev_build" = "xyes"])
 215
 216 dnl always want these CFLAGS
 217 AC_C_FLAG([-fno-omit-frame-pointer])
 218 AC_C_FLAG([-funwind-tables])
 219 AC_C_FLAG([-Wall])
 220 AC_C_FLAG([-Wextra])
 221 AC_C_FLAG([-Wmissing-prototypes])
 222 AC_C_FLAG([-Wmissing-declarations])
 223 AC_C_FLAG([-Wpointer-arith])
 224 AC_C_FLAG([-Wbad-function-cast])
 225 AC_C_FLAG([-Wwrite-strings])
 226 if test x"${enable_gcc_ultra_verbose}" = x"yes" ; then
 227   AC_C_FLAG([-Wcast-qual])
 228   AC_C_FLAG([-Wstrict-prototypes])
 229   AC_C_FLAG([-Wmissing-noreturn])
 230   AC_C_FLAG([-Wmissing-format-attribute])
 231   AC_C_FLAG([-Wunreachable-code])
 232   AC_C_FLAG([-Wpacked])
 233   AC_C_FLAG([-Wpadded])
 234 else
 235   AC_C_FLAG([-Wno-unused-result])
 236 fi
 237 AC_C_FLAG([-Wno-unused-parameter])
 238 AC_C_FLAG([-Wno-missing-field-initializers])
 239
 240 dnl ICC emits a broken warning for const char *x = a ? "b" : "c";
 241 dnl for some reason the string consts get 'promoted' to char *,
 242 dnl triggering a const to non-const conversion warning.
 243 AC_C_FLAG([-diag-disable 3179])
 244
 245 if test x"${enable_werror}" = x"yes" ; then
 246   WERROR="-Werror"
 247 fi
 248 AC_SUBST(WERROR)
 249
 250 SAN_FLAGS=""
 251 if test "$enable_address_sanitizer" = "yes"; then
 252   AC_C_FLAG([-fsanitize=address], [
 253     AC_MSG_ERROR([$CC does not support Address Sanitizer.])
 254   ], [
 255     SAN_FLAGS="$SAN_FLAGS -fsanitize=address"
 256   ])
 257 fi
 258 if test "$enable_thread_sanitizer" = "yes"; then
 259   AC_C_FLAG([-fsanitize=thread], [
 260     AC_MSG_ERROR([$CC does not support Thread Sanitizer.])
 261   ], [
 262     SAN_FLAGS="$SAN_FLAGS -fsanitize=thread"
 263   ])
 264 fi
 265 if test "$enable_memory_sanitizer" = "yes"; then
 266   AC_C_FLAG([-fsanitize=thread -fPIE -pie], [
 267     AC_MSG_ERROR([$CC does not support Thread Sanitizer.])
 268   ], [
 269     SAN_FLAGS="-fsanitize=memory -fPIE -pie"
 270   ])
 271 fi
 272 AC_SUBST([SAN_FLAGS])
 273
 274 dnl ----------
 275 dnl Essentials
 276 dnl ----------
 277
 278 AX_PTHREAD([
 279   CC="$PTHREAD_CC"
 280   CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 281   LIBS="$PTHREAD_LIBS $LIBS"
 282 ], [
 283   AC_MSG_FAILURE([This FRR version needs pthreads])
 284 ])
 285
 286 dnl --------------
 287 dnl Check programs
 288 dnl --------------
 289 AC_PROG_INSTALL
 290 AC_PROG_LN_S
 291 AC_PROG_MAKE_SET
 292 AC_CHECK_TOOL(AR, ar)
 293
 294 dnl -----------------
 295 dnl System extensions
 296 dnl -----------------
 297 AC_GNU_SOURCE
 298
 299 dnl -------
 300 dnl libtool
 301 dnl -------
 302 LT_INIT
 303
 304 dnl $AR and $RANLIB are set by LT_INIT above
 305 AC_MSG_CHECKING([whether $AR supports D option])
 306 if $AR crD conftest.a; then
 307   AC_MSG_RESULT([yes])
 308   dnl ARFLAGS is for automake, AR_FLAGS for libtool m-(
 309   ARFLAGS="crD"
 310   AR_FLAGS="crD"
 311 else
 312   AC_MSG_RESULT([no])
 313   ARFLAGS="cru"
 314   AR_FLAGS="cru"
 315 fi
 316 AC_SUBST(ARFLAGS)
 317 AC_SUBST(AR_FLAGS)
 318
 319 AC_MSG_CHECKING([whether $RANLIB supports D option])
 320 if $RANLIB -D conftest.a; then
 321   AC_MSG_RESULT([yes])
 322   RANLIB="$RANLIB -D"
 323 else
 324   AC_MSG_RESULT([no])
 325 fi
 326 AC_SUBST(RANLIB)
 327
 328 test -f conftest.a && rm conftest.a
 329
 330 dnl ----------------------
 331 dnl Packages configuration
 332 dnl ----------------------
 333 if test -f config.version; then
 334   . ./config.version
 335 elif test -f "${srcdir}/config.version"; then
 336   . "${srcdir}/config.version"
 337 fi
 338 AC_ARG_WITH(pkg-extra-version,
 339   AS_HELP_STRING([--with-pkg-extra-version=VER], [add extra version field, for packagers/distributions]), [
 340   if test "$withval" = "no"; then
 341     EXTRAVERSION=
 342   else
 343     EXTRAVERSION=$withval
 344   fi
 345 ], [])
 346 AC_ARG_WITH(pkg-git-version,
 347         AS_HELP_STRING([--with-pkg-git-version], [add git information to MOTD and build version string]),
 348         [ test "x$withval" != "xno" && with_pkg_git_version="yes" ])
 349 AC_ARG_WITH(vtysh_pager,
 350         AS_HELP_STRING([--with-vtysh-pager=PAGER], [control what pager is compiled in as default]),
 351         VTYSH_PAGER=$withval, VTYSH_PAGER="more")
 352 AC_ARG_ENABLE(vtysh,
 353   AS_HELP_STRING([--disable-vtysh], [do not build integrated vty shell for FRR]))
 354 AC_ARG_ENABLE(doc,
 355   AS_HELP_STRING([--disable-doc], [do not build docs]))
 356 AC_ARG_ENABLE(doc-html,
 357   AS_HELP_STRING([--enable-doc-html], [build HTML docs]))
 358 AC_ARG_ENABLE(zebra,
 359   AS_HELP_STRING([--disable-zebra], [do not build zebra daemon]))
 360 AC_ARG_ENABLE(bgpd,
 361   AS_HELP_STRING([--disable-bgpd], [do not build bgpd]))
 362 AC_ARG_ENABLE(ripd,
 363   AS_HELP_STRING([--disable-ripd], [do not build ripd]))
 364 AC_ARG_ENABLE(ripngd,
 365   AS_HELP_STRING([--disable-ripngd], [do not build ripngd]))
 366 AC_ARG_ENABLE(ospfd,
 367   AS_HELP_STRING([--disable-ospfd], [do not build ospfd]))
 368 AC_ARG_ENABLE(ospf6d,
 369   AS_HELP_STRING([--disable-ospf6d], [do not build ospf6d]))
 370 AC_ARG_ENABLE(ldpd,
 371   AS_HELP_STRING([--disable-ldpd], [do not build ldpd]))
 372 AC_ARG_ENABLE(nhrpd,
 373   AS_HELP_STRING([--disable-nhrpd], [do not build nhrpd]))
 374 AC_ARG_ENABLE(eigrpd,
 375   AS_HELP_STRING([--disable-eigrpd], [do not build eigrpd]))
 376 AC_ARG_ENABLE(babeld,
 377   AS_HELP_STRING([--disable-babeld], [do not build babeld]))
 378 AC_ARG_ENABLE(watchfrr,
 379   AS_HELP_STRING([--disable-watchfrr], [do not build watchfrr]))
 380 AC_ARG_ENABLE(isisd,
 381   AS_HELP_STRING([--disable-isisd], [do not build isisd]))
 382 AC_ARG_ENABLE(pimd,
 383   AS_HELP_STRING([--disable-pimd], [do not build pimd]))
 384 AC_ARG_ENABLE(pbrd,
 385   AS_HELP_STRING([--disable-pbrd], [do not build pbrd]))
 386 AC_ARG_ENABLE(sharpd,
 387   AS_HELP_STRING([--enable-sharpd], [build sharpd]))
 388 AC_ARG_ENABLE(staticd,
 389   AS_HELP_STRING([--disable-staticd], [do not build staticd]))
 390 AC_ARG_ENABLE(bgp-announce,
 391   AS_HELP_STRING([--disable-bgp-announce,], [turn off BGP route announcement]))
 392 AC_ARG_ENABLE(bgp-vnc,
 393   AS_HELP_STRING([--disable-bgp-vnc],[turn off BGP VNC support]))
 394 AC_ARG_ENABLE(snmp,
 395   AS_HELP_STRING([--enable-snmp], [enable SNMP support for agentx]))
 396 AC_ARG_ENABLE(zeromq,
 397   AS_HELP_STRING([--enable-zeromq], [enable ZeroMQ handler (libfrrzmq)]))
 398 AC_ARG_WITH(libpam,
 399   AS_HELP_STRING([--with-libpam], [use libpam for PAM support in vtysh]))
 400 AC_ARG_ENABLE(ospfapi,
 401   AS_HELP_STRING([--disable-ospfapi], [do not build OSPFAPI to access the OSPF LSA Database]))
 402 AC_ARG_ENABLE(ospfclient,
 403   AS_HELP_STRING([--disable-ospfclient], [do not build OSPFAPI client for OSPFAPI,
 404                           (this is the default if --disable-ospfapi is set)]))
 405 AC_ARG_ENABLE(multipath,
 406   AS_HELP_STRING([--enable-multipath=ARG], [enable multipath function, ARG must be digit]))
 407 AC_ARG_ENABLE(user,
 408   AS_HELP_STRING([--enable-user=USER], [user to run FRR suite as (default frr)]))
 409 AC_ARG_ENABLE(group,
 410   AS_HELP_STRING([--enable-group=GROUP], [group to run FRR suite as (default frr)]))
 411 AC_ARG_ENABLE(vty_group,
 412   AS_HELP_STRING([--enable-vty-group=ARG], [set vty sockets to have specified group as owner]))
 413 AC_ARG_ENABLE(configfile_mask,
 414   AS_HELP_STRING([--enable-configfile-mask=ARG], [set mask for config files]))
 415 AC_ARG_ENABLE(logfile_mask,
 416   AS_HELP_STRING([--enable-logfile-mask=ARG], [set mask for log files]))
 417 AC_ARG_ENABLE(shell_access,
 418   AS_HELP_STRING([--enable-shell-access], [Allow users to access shell/telnet/ssh]))
 419 AC_ARG_ENABLE(realms,
 420   AS_HELP_STRING([--enable-realms], [enable REALMS support under Linux]))
 421 AC_ARG_ENABLE(rtadv,
 422   AS_HELP_STRING([--disable-rtadv], [disable IPV6 router advertisement feature]))
 423 AC_ARG_ENABLE(irdp,
 424   AS_HELP_STRING([--disable-irdp], [enable IRDP server support in zebra (default if supported)]))
 425 AC_ARG_ENABLE(capabilities,
 426   AS_HELP_STRING([--disable-capabilities], [disable using POSIX capabilities]))
 427 AC_ARG_ENABLE(rusage,
 428   AS_HELP_STRING([--disable-rusage], [disable using getrusage]))
 429 AC_ARG_ENABLE(gcc_ultra_verbose,
 430   AS_HELP_STRING([--enable-gcc-ultra-verbose], [enable ultra verbose GCC warnings]))
 431 AC_ARG_ENABLE(backtrace,
 432   AS_HELP_STRING([--disable-backtrace,], [disable crash backtraces (default autodetect)]))
 433 AC_ARG_ENABLE(time-check,
 434   AS_HELP_STRING([--disable-time-check], [disable slow thread warning messages]))
 435 AC_ARG_ENABLE(pcreposix,
 436   AS_HELP_STRING([--enable-pcreposix], [enable using PCRE Posix libs for regex functions]))
 437 AC_ARG_ENABLE(fpm,
 438   AS_HELP_STRING([--enable-fpm], [enable Forwarding Plane Manager support]))
 439 AC_ARG_ENABLE(systemd,
 440   AS_HELP_STRING([--enable-systemd], [enable Systemd support]))
 441 AC_ARG_ENABLE(werror,
 442   AS_HELP_STRING([--enable-werror], [enable -Werror (recommended for developers only)]))
 443 AC_ARG_ENABLE(cumulus,
 444   AS_HELP_STRING([--enable-cumulus], [enable Cumulus Switch Special Extensions]))
 445 AC_ARG_ENABLE(datacenter,
 446   AS_HELP_STRING([--enable-datacenter], [enable Compilation for Data Center Extensions]))
 447 AC_ARG_ENABLE(fuzzing,
 448   AS_HELP_STRING([--enable-fuzzing], [enable ability to fuzz various parts of FRR]))
 449 AC_ARG_ENABLE(netlink_fuzzing,
 450   AS_HELP_STRING([--enable-netlink-fuzzing], [enable ability to fuzz netlink listening socket in zebra]))
 451 AC_ARG_ENABLE(rr-semantics,
 452   AS_HELP_STRING([--disable-rr-semantics], [disable the v6 Route Replace semantics]))
 453 AC_ARG_ENABLE([protobuf],
 454   AS_HELP_STRING([--enable-protobuf], [Enable experimental protobuf support]))
 455 AC_ARG_ENABLE([oldvpn_commands],
 456   AS_HELP_STRING([--enable-oldvpn-commands], [Keep old vpn commands]))
 457 AC_ARG_ENABLE(rpki,
 458   AS_HELP_STRING([--enable-rpki], [enable RPKI prefix validation support]))
 459 AC_ARG_ENABLE([clippy-only],
 460   AS_HELP_STRING([--enable-clippy-only], [Only build clippy]))
 461 AC_ARG_ENABLE([numeric_version],
 462   AS_HELP_STRING([--enable-numeric-version], [Only numeric digits allowed in version (for Alpine)]))
 463 AC_ARG_ENABLE([gcov],
 464   AS_HELP_STRING([--enable-gcov], [Add code coverage information]))
 465 AC_ARG_ENABLE(bfdd,
 466   AS_HELP_STRING([--disable-bfdd], [do not build bfdd]))
 467 AC_ARG_ENABLE([address-sanitizer],
 468   AS_HELP_STRING([--enable-address-sanitizer], [enable AddressSanitizer support for detecting a wide variety of memory allocation and deallocation errors]))
 469 AC_ARG_ENABLE([thread-sanitizer],
 470   AS_HELP_STRING([--enable-thread-sanitizer], [enable ThreadSanitizer support for detecting data races]))
 471 AC_ARG_ENABLE([memory-sanitizer],
 472   AS_HELP_STRING([--enable-memory-sanitizer], [enable MemorySanitizer support for detecting uninitialized memory reads]))
 473
 474 AS_IF([test "${enable_clippy_only}" != "yes"], [
 475 AC_CHECK_HEADERS(json-c/json.h)
 476 AC_CHECK_LIB(json-c, json_object_get, LIBS="$LIBS -ljson-c", [], [-lm])
 477 if test "$ac_cv_lib_json_c_json_object_get" = no; then
 478   AC_CHECK_LIB(json, json_object_get, LIBS="$LIBS -ljson")
 479   if test "$ac_cv_lib_json_json_object_get" = no; then
 480       AC_MSG_ERROR([lib json is needed to compile])
 481   fi
 482 fi
 483 ])
 484
 485 AC_ARG_ENABLE([dev_build],
 486     AS_HELP_STRING([--enable-dev-build], [build for development]))
 487
 488 if test x"${enable_time_check}" != x"no" ; then
 489   if test x"${enable_time_check}" = x"yes" -o x"${enable_time_check}" = x ; then
 490     AC_DEFINE(CONSUMED_TIME_CHECK,5000000,Consumed Time Check)
 491   else
 492     AC_DEFINE_UNQUOTED(CONSUMED_TIME_CHECK,$enable_time_check,Consumed Time Check)
 493   fi
 494 fi
 495
 496 case "${enable_systemd}" in
 497   "no") ;;
 498   "yes")
 499   AC_CHECK_LIB(systemd, sd_notify, LIBS="$LIBS -lsystemd")
 500   if test $ac_cv_lib_systemd_sd_notify = no; then
 501     AC_MSG_ERROR([enable systemd has been specified but systemd development env not found on your system])
 502   else
 503     AC_DEFINE(HAVE_SYSTEMD,,Compile systemd support in)
 504   fi
 505   ;;
 506   "*") ;;
 507 esac
 508
 509 if test "${enable_rr_semantics}" != "no" ; then
 510   AC_DEFINE(HAVE_V6_RR_SEMANTICS,, Compile in v6 Route Replacement Semantics)
 511 fi
 512
 513 if test "${enable_datacenter}" = "yes" ; then
 514   AC_DEFINE(HAVE_DATACENTER,,Compile extensions for a DataCenter)
 515   DFLT_NAME="datacenter"
 516 else
 517   DFLT_NAME="traditional"
 518 fi
 519
 520 if test "${enable_fuzzing}" = "yes" ; then
 521   AC_DEFINE(HANDLE_ZAPI_FUZZING,,Compile extensions to use with a fuzzer)
 522 fi
 523
 524 if test "${enable_netlink_fuzzing}" = "yes" ; then
 525   AC_DEFINE(HANDLE_NETLINK_FUZZING,,Compile extensions to use with a fuzzer for netlink)
 526 fi
 527
 528 if test "${enable_cumulus}" = "yes" ; then
 529   AC_DEFINE(HAVE_CUMULUS,,Compile Special Cumulus Code in)
 530 fi
 531
 532 AC_SUBST(DFLT_NAME)
 533 AC_DEFINE_UNQUOTED(DFLT_NAME,["$DFLT_NAME"], Name of the configuration default set)
 534
 535 if test "${enable_shell_access}" = "yes"; then
 536    AC_DEFINE(HAVE_SHELL_ACCESS,,Allow user to use ssh/telnet/bash)
 537 fi
 538
 539 AM_CONDITIONAL([FPM], [test "x$enable_fpm" = "xyes"])
 540
 541 #
 542 # Python for clippy
 543 #
 544
 545 AC_DEFUN([FRR_PYTHON_CHECK_WORKING], [
 546   AC_MSG_CHECKING([whether we found a working Python version])
 547   AC_LINK_IFELSE_FLAGS([$PYTHON_CFLAGS], [$PYTHON_LIBS], [AC_LANG_PROGRAM([
 548 #include <Python.h>
 549 #if PY_VERSION_HEX < 0x02070000
 550 #error python too old
 551 #endif
 552 int main(void);
 553 ],
 554 [
 555 {
 556   Py_Initialize();
 557   return 0;
 558 }
 559 ])], [
 560     # some python installs are missing the zlib dependency...
 561     PYTHON_LIBS="${PYTHON_LIBS} -lz"
 562     AC_LINK_IFELSE_FLAGS([$PYTHON_CFLAGS], [$PYTHON_LIBS], [AC_LANG_PROGRAM([
 563 #include <Python.h>
 564 #if PY_VERSION_HEX < 0x02070000
 565 #error python too old
 566 #endif
 567 int main(void);
 568 ],
 569 [
 570 {
 571   Py_Initialize();
 572   return 0;
 573 }
 574 ])], [
 575       m4_if([$1], [], [
 576         PYTHONCONFIG=""
 577         unset PYTHON_LIBS
 578         unset PYTHON_CFLAGS
 579       ], [$1])
 580     ])
 581   ])
 582 ])
 583
 584 AS_IF([test "$host" = "$build"], [
 585   PYTHONCONFIG=""
 586
 587   # ordering:
 588   # 1.  try python3, but respect the user's preference on which minor ver
 589   # 2.  try python, which might be py3 or py2 again on the user's preference
 590   # 3.  try python2 (can really only be 2.7 but eh)
 591   # 4.  try 3.6 > 3.5 > 3.4 > 3.3 > 3.2 > 2.7 through pkg-config (no user pref)
 592   #
 593   # (AX_PYTHON_DEVEL has no clue about py3 vs py2)
 594   # (AX_PYTHON does not do what we need)
 595
 596   AC_CHECK_TOOLS([PYTHONCONFIG], [ \
 597         python3-config \
 598         python-config \
 599         python2-config \
 600         python3.6-config \
 601         python3.5-config \
 602         python3.4-config \
 603         python3.3-config \
 604         python3.2-config \
 605         python2.7-config ])
 606   if test -n "$PYTHONCONFIG"; then
 607     PYTHON_CFLAGS="`\"${PYTHONCONFIG}\" --includes`"
 608     PYTHON_LIBS="`\"${PYTHONCONFIG}\" --ldflags`"
 609
 610     FRR_PYTHON_CHECK_WORKING([])
 611   fi
 612
 613   if test -z "$PYTHONCONFIG"; then
 614     PKG_CHECK_MODULES([PYTHON], python-3.6, [], [
 615       PKG_CHECK_MODULES([PYTHON], python-3.5, [], [
 616         PKG_CHECK_MODULES([PYTHON], python-3.4, [], [
 617           PKG_CHECK_MODULES([PYTHON], python-3.3, [], [
 618             PKG_CHECK_MODULES([PYTHON], python-3.2, [], [
 619               PKG_CHECK_MODULES([PYTHON], python-2.7, [], [
 620                 AC_MSG_FAILURE([could not find python-config or pkg-config python, please install Python development files from libpython-dev or similar])
 621                 ])])])])])])
 622
 623
 624     FRR_PYTHON_CHECK_WORKING([
 625       AC_MSG_FAILURE([could not find python-config or pkg-config python, please install Python development files from libpython-dev or similar])
 626     ])
 627   fi
 628 ])
 629 AC_SUBST(PYTHON_CFLAGS)
 630 AC_SUBST(PYTHON_LIBS)
 631
 632 #
 633 # Logic for protobuf support.
 634 #
 635 if test "$enable_protobuf" = "yes"; then
 636   # Check for protoc & protoc-c
 637
 638   # protoc is not required, it's only for a "be nice" helper target
 639   AC_CHECK_PROGS([PROTOC], [protoc], [/bin/false])
 640
 641   AC_CHECK_PROGS([PROTOC_C], [protoc-c], [/bin/false])
 642   if test "$PROTOC_C" = "/bin/false"; then
 643     AC_MSG_FAILURE([protobuf requested but protoc-c not found.  Install protobuf-c.])
 644   fi
 645
 646   PKG_CHECK_MODULES([PROTOBUF_C], [libprotobuf-c >= 0.14],, [
 647     AC_MSG_FAILURE([protobuf requested but libprotobuf-c not found.  Install protobuf-c.])
 648   ])
 649   AC_CHECK_HEADER([google/protobuf-c/protobuf-c.h], [], [
 650     AC_MSG_FAILURE([protobuf requested but protobuf-c.h not found.  Install protobuf-c.])
 651   ])
 652
 653   AC_DEFINE(HAVE_PROTOBUF,, protobuf)
 654 fi
 655 AM_CONDITIONAL([HAVE_PROTOBUF], [test "x$enable_protobuf" = "xyes"])
 656
 657 #
 658 # Logic for old vpn commans support.
 659 #
 660 if test "$enable_oldvpn_commands" = "yes"; then
 661    AC_DEFINE(KEEP_OLD_VPN_COMMANDS,, [Define for compiling with old vpn commands])
 662 fi
 663
 664 #
 665 # End of logic for protobuf support.
 666 #
 667
 668 AC_MSG_CHECKING(if zebra should be configurable to send Route Advertisements)
 669 if test "${enable_rtadv}" != "no"; then
 670   AC_MSG_RESULT(yes)
 671   AC_DEFINE(HAVE_RTADV,,Enable IPv6 Routing Advertisement support)
 672 else
 673   AC_MSG_RESULT(no)
 674 fi
 675
 676 if test x"${enable_user}" = x"no"; then
 677   enable_user=""
 678 else
 679   if test x"${enable_user}" = x"yes" || test x"${enable_user}" = x""; then
 680     enable_user="frr"
 681   fi
 682   AC_DEFINE_UNQUOTED(FRR_USER, "${enable_user}", frr User)
 683 fi
 684
 685 if test x"${enable_group}" = x"no"; then
 686   enable_group=""
 687 else
 688   if test x"${enable_group}" = x"yes" || test x"${enable_group}" = x""; then
 689     enable_group="frr"
 690   fi
 691   AC_DEFINE_UNQUOTED(FRR_GROUP, "${enable_group}", frr Group)
 692 fi
 693
 694 if test x"${enable_vty_group}" = x"yes" ; then
 695   AC_MSG_ERROR([--enable-vty-group requires a group as argument, not yes])
 696 elif test x"${enable_vty_group}" != x""; then
 697   if test x"${enable_vty_group}" != x"no"; then
 698     AC_DEFINE_UNQUOTED(VTY_GROUP, "${enable_vty_group}", VTY Sockets Group)
 699   fi
 700 fi
 701 AC_SUBST([enable_user])
 702 AC_SUBST([enable_group])
 703 AC_SUBST([enable_vty_group])
 704
 705 enable_configfile_mask=${enable_configfile_mask:-0600}
 706 AC_DEFINE_UNQUOTED(CONFIGFILE_MASK, ${enable_configfile_mask}, Mask for config files)
 707
 708 enable_logfile_mask=${enable_logfile_mask:-0600}
 709 AC_DEFINE_UNQUOTED(LOGFILE_MASK, ${enable_logfile_mask}, Mask for log files)
 710
 711 MPATH_NUM=1
 712
 713 case "${enable_multipath}" in
 714   0)
 715     MPATH_NUM=64
 716     ;;
 717   [[1-9]|[1-9][0-9]|[1-9][0-9][0-9]])
 718     MPATH_NUM="${enable_multipath}"
 719     ;;
 720   "")
 721     ;;
 722   *)
 723     AC_MSG_FAILURE([Please specify digit to enable multipath ARG])
 724     ;;
 725 esac
 726
 727 AC_DEFINE_UNQUOTED(MULTIPATH_NUM, $MPATH_NUM, Maximum number of paths for a route)
 728
 729 AC_DEFINE_UNQUOTED(VTYSH_PAGER, "$VTYSH_PAGER", [What pager to use])
 730
 731 dnl --------------------
 732 dnl Enable code coverage
 733 dnl --------------------
 734 AM_CONDITIONAL([HAVE_GCOV],[test '!' "$enable_gcov" = no])
 735
 736 dnl ------------------------------------
 737 dnl Alpine only accepts numeric versions
 738 dnl ------------------------------------
 739 if test "x${enable_numeric_version}" != "x" ; then
 740   VERSION="`echo ${VERSION} | tr -c -d '[[.0-9]]'`"
 741   PACKAGE_VERSION="`echo ${PACKAGE_VERSION} | tr -c -d '[[.0-9]]'`"
 742 fi
 743
 744 dnl -----------------------------------
 745 dnl Add extra version string to package
 746 dnl name, string and version fields.
 747 dnl -----------------------------------
 748 if test "x${EXTRAVERSION}" != "x" ; then
 749   VERSION="${VERSION}${EXTRAVERSION}"
 750   PACKAGE_VERSION="${PACKAGE_VERSION}${EXTRAVERSION}"
 751   AC_SUBST(PACKAGE_EXTRAVERSION, ["${EXTRAVERSION}"])
 752   PACKAGE_STRING="${PACKAGE_STRING}${EXTRAVERSION}"
 753 fi
 754 AC_SUBST(EXTRAVERSION)
 755
 756 if test "x$with_pkg_git_version" = "xyes"; then
 757         if test -d "${srcdir}/.git"; then
 758                 AC_DEFINE(GIT_VERSION, [1], [include git version info])
 759         else    with_pkg_git_version="no"
 760                 AC_MSG_WARN([--with-pkg-git-version given, but this is not a git checkout])
 761         fi
 762 fi
 763 AM_CONDITIONAL([GIT_VERSION], [test "x$with_pkg_git_version" = "xyes"])
 764
 765 dnl ------------------------------------
 766 dnl Check C keywords and standard  types
 767 dnl ------------------------------------
 768 AC_C_CONST
 769 AC_C_INLINE
 770 AC_C_VOLATILE
 771 AC_HEADER_STDC
 772 dnl AC_TYPE_PID_T
 773 AC_TYPE_UID_T
 774 AC_TYPE_MODE_T
 775 AC_TYPE_SIZE_T
 776 AC_STRUCT_TM
 777
 778 dnl -------------------------
 779 dnl Check other header files.
 780 dnl -------------------------
 781 AC_CHECK_HEADERS([stropts.h sys/ksym.h \
 782         linux/version.h asm/types.h \
 783         sys/cdefs.h])
 784
 785 ac_stdatomic_ok=false
 786 AC_DEFINE(FRR_AUTOCONF_ATOMIC, 1, [did autoconf checks for atomic funcs])
 787 AC_CHECK_HEADER([stdatomic.h],[
 788
 789   AC_MSG_CHECKING([whether _Atomic qualifier works])
 790   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 791 #include <stdatomic.h>
 792 int main(int argc, char **argv) {
 793   _Atomic int i = 0;
 794   return i;
 795 }
 796 ]])], [
 797     AC_DEFINE(HAVE_STDATOMIC_H, 1, [found stdatomic.h])
 798     AC_MSG_RESULT([yes])
 799     ac_stdatomic_ok=true
 800   ], [
 801     AC_MSG_RESULT([no])
 802   ])
 803 ])
 804
 805 AS_IF([$ac_stdatomic_ok], [true], [
 806   AC_MSG_CHECKING([for __atomic_* builtins])
 807   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 808 int main(int argc, char **argv) {
 809   volatile int i = 1;
 810   __atomic_store_n (&i, 0, __ATOMIC_RELEASE);
 811   return __atomic_load_n (&i, __ATOMIC_ACQUIRE);
 812 }
 813 ]])], [
 814     AC_DEFINE(HAVE___ATOMIC, 1, [found __atomic builtins])
 815     AC_MSG_RESULT([yes])
 816   ], [
 817     AC_MSG_RESULT([no])
 818
 819     dnl FreeBSD 9 has a broken stdatomic.h where _Atomic doesn't work
 820     AC_MSG_CHECKING([for __sync_* builtins])
 821     AC_LINK_IFELSE([AC_LANG_SOURCE([[
 822 int main(int argc, char **argv) {
 823   volatile int i = 1;
 824   __sync_fetch_and_sub (&i, 1);
 825   return __sync_val_compare_and_swap (&i, 0, 1);
 826 }
 827 ]])], [
 828       AC_DEFINE(HAVE___SYNC, 1, [found __sync builtins])
 829       AC_MSG_RESULT([yes])
 830
 831       AC_MSG_CHECKING([for __sync_swap builtin])
 832       AC_LINK_IFELSE([AC_LANG_SOURCE([[
 833 int main(int argc, char **argv) {
 834   volatile int i = 1;
 835   return __sync_swap (&i, 2);
 836 }
 837 ]])], [
 838         AC_DEFINE(HAVE___SYNC_SWAP, 1, [found __sync_swap builtin])
 839         AC_MSG_RESULT([yes])
 840       ], [
 841         AC_MSG_RESULT([no])
 842       ])
 843
 844     ], [
 845       AC_MSG_RESULT([no])
 846       AC_MSG_FAILURE([stdatomic.h unavailable and $CC has neither __atomic nor __sync builtins])
 847     ])
 848   ])
 849 ])
 850
 851 dnl Utility macro to avoid retyping includes all the time
 852 m4_define([FRR_INCLUDES],
 853 [#ifdef SUNOS_5
 854 #define _XPG4_2
 855 #define __EXTENSIONS__
 856 #endif
 857 #include <stdio.h>
 858 #include <stdlib.h>
 859 #include <stddef.h>
 860 #include <sys/types.h>
 861 /* sys/conf.h depends on param.h on FBSD at least */
 862 #include <sys/param.h>
 863 /* Required for MAXSIG */
 864 #include <signal.h>
 865 #include <sys/socket.h>
 866 #ifdef __APPLE__
 867 # define __APPLE_USE_RFC_3542
 868 #endif
 869 #include <netinet/in.h>
 870 #include <sys/time.h>
 871 #include <time.h>
 872 #include <net/if.h>
 873 ])dnl
 874
 875 dnl Same applies for HAVE_NET_IF_VAR_H, which HAVE_NETINET6_ND6_H and
 876 dnl HAVE_NETINET_IN_VAR_H depend upon. But if_var.h depends on if.h, hence
 877 dnl an additional round for it.
 878
 879 AC_CHECK_HEADERS([net/if_var.h], [], [], FRR_INCLUDES)
 880
 881 m4_define([FRR_INCLUDES],
 882 FRR_INCLUDES
 883 [#if HAVE_NET_IF_VAR_H
 884 # include <net/if_var.h>
 885 #endif
 886 ])dnl
 887
 888 AC_CHECK_HEADERS([netinet/in_var.h \
 889         net/if_dl.h net/netopt.h \
 890         inet/nd.h netinet/ip_icmp.h \
 891         sys/sysctl.h sys/sockio.h kvm.h sys/conf.h],
 892         [], [], FRR_INCLUDES)
 893
 894 AC_CHECK_HEADERS([ucontext.h], [], [],
 895 [#ifndef __USE_GNU
 896 #define __USE_GNU
 897 #endif /* __USE_GNU */
 898 FRR_INCLUDES
 899 ])
 900
 901 m4_define([UCONTEXT_INCLUDES],
 902 [#include <ucontext.h>])dnl
 903
 904 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.uc_regs],
 905   [], [], [UCONTEXT_INCLUDES])
 906 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs],
 907   [AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs.nip],
 908    [], [], [UCONTEXT_INCLUDES])],
 909   [], [UCONTEXT_INCLUDES])
 910 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.gregs],
 911   [], [], [UCONTEXT_INCLUDES])
 912
 913 m4_define([FRR_INCLUDES],
 914 FRR_INCLUDES
 915 [
 916 #include <sys/un.h>
 917 #include <netinet/in_systm.h>
 918 #if HAVE_NETINET_IN_VAR_H
 919 # include <netinet/in_var.h>
 920 #endif
 921 #if HAVE_NET_IF_DL_H
 922 # include <net/if_dl.h>
 923 #endif
 924 #if HAVE_NET_NETOPT_H
 925 # include <net/netopt.h>
 926 #endif
 927 #include <net/route.h>
 928 #if HAVE_INET_ND_H
 929 # include <inet/nd.h>
 930 #endif
 931 #include <arpa/inet.h>
 932 /* Required for IDRP */
 933 #if HAVE_NETINET_IP_ICMP_H
 934 # include <netinet/ip_icmp.h>
 935 #endif
 936 ])dnl
 937
 938 dnl V6 headers are checked below, after we check for v6
 939
 940 AC_MSG_CHECKING([which operating system interface to use])
 941 case "$host_os" in
 942   sunos* | solaris2*)
 943     AC_MSG_RESULT([Solaris])
 944
 945     AC_DEFINE(SUNOS_5, 1, [SunOS 5])
 946     AC_DEFINE(SOLARIS_IPV6, 1, Solaris IPv6)
 947
 948     AC_CHECK_LIB(socket, main)
 949     AC_CHECK_LIB(nsl, main)
 950     AC_CHECK_LIB(umem, main)
 951     AC_CHECK_FUNCS([printstack], [
 952       AC_DEFINE([HAVE_PRINTSTACK],1,[Solaris printstack])
 953       AC_DEFINE([HAVE_STACK_TRACE],1,[Stack symbols decode functionality])
 954     ])
 955     SOLARIS="solaris"
 956     ;;
 957   linux*)
 958     AC_MSG_RESULT([Linux])
 959
 960     AC_DEFINE(GNU_LINUX,,GNU Linux)
 961     AC_DEFINE(HAVE_NETLINK,,netlink)
 962     AC_DEFINE(LINUX_IPV6,1,Linux IPv6 stack)
 963
 964     dnl Linux has a compilation problem with mixing
 965     dnl netinet/in.h and linux/in6.h they are not
 966     dnl compatible.  There has been discussion on
 967     dnl how to fix it but no real progress on implementation
 968     dnl when they fix it, remove this
 969     AC_DEFINE(IPV6_MINHOPCOUNT, 73, Linux ipv6 Min Hop Count)
 970     ;;
 971   openbsd*)
 972     AC_MSG_RESULT([OpenBSD])
 973
 974     AC_DEFINE(OPEN_BSD,,OpenBSD)
 975     AC_DEFINE(KAME,1,KAME IPv6)
 976     AC_DEFINE(BSD_V6_SYSCTL,1,BSD v6 sysctl to turn on and off forwarding)
 977
 978     if test "x${enable_pimd}" != "xno"; then
 979       case "$host_os" in
 980       openbsd6.0)
 981         ;;
 982       openbsd[6-9]*)
 983         AC_MSG_FAILURE([pimd cannot be enabled as PIM support has been removed from OpenBSD 6.1])
 984         ;;
 985       esac
 986     fi
 987     ;;
 988   *)
 989     AC_MSG_RESULT([BSD])
 990
 991     AC_DEFINE(HAVE_NET_RT_IFLIST,,NET_RT_IFLIST)
 992     AC_DEFINE(KAME,1,KAME IPv6)
 993     AC_DEFINE(BSD_V6_SYSCTL,1,BSD v6 sysctl to turn on and off forwarding)
 994     ;;
 995 esac
 996 AM_CONDITIONAL(SOLARIS, test "${SOLARIS}" = "solaris")
 997
 998 AC_SYS_LARGEFILE
 999
1000 dnl ------------------------
1001 dnl Integrated REALMS option
1002 dnl ------------------------
1003 if test "${enable_realms}" = "yes"; then
1004     case "$host_os" in
1005       linux*)
1006        AC_DEFINE(SUPPORT_REALMS,, Realms support)
1007        ;;
1008       *)
1009        echo "Sorry, only Linux has REALMS support"
1010        exit 1
1011        ;;
1012     esac
1013 fi
1014 AM_CONDITIONAL([SUPPORT_REALMS], [test "${enable_realms}" = "yes"])
1015
1016 dnl ---------------------
1017 dnl Integrated VTY option
1018 dnl ---------------------
1019 case "${enable_vtysh}" in
1020 "no")
1021   VTYSH="";;
1022 *)
1023   VTYSH="vtysh";
1024   AC_DEFINE(VTYSH,,VTY shell)
1025
1026   prev_libs="$LIBS"
1027   AC_CHECK_LIB(readline, main, [
1028     LIBREADLINE="-lreadline"
1029   ], [
1030     dnl readline failed - it might be incorrectly linked and missing its
1031     dnl termcap/tinfo/curses dependency.  see if we can fix that...
1032     AC_SEARCH_LIBS(tputs, [termcap tinfo curses ncurses], [
1033       LIBREADLINE="$ac_cv_search_tputs"
1034     ], [
1035       AC_MSG_ERROR([libreadline (needed for vtysh) not found and/or missing dependencies])
1036     ])
1037
1038     dnl re-try with the lib we found above
1039     unset ac_cv_lib_readline_main
1040     AC_CHECK_LIB(readline, main, [
1041       LIBREADLINE="-lreadline $LIBREADLINE"
1042     ], [
1043       AC_MSG_ERROR([libreadline (needed for vtysh) not found and/or missing dependencies])
1044     ], [$LIBREADLINE])
1045   ], [])
1046   LIBS="$prev_libs"
1047
1048   AC_CHECK_HEADER(readline/history.h)
1049   if test $ac_cv_header_readline_history_h = no;then
1050     AC_MSG_ERROR([readline is too old to have readline/history.h, please update to the latest readline library.])
1051   fi
1052   AC_CHECK_LIB(readline, rl_completion_matches, [true], [], [$LIBREADLINE])
1053   if test $ac_cv_lib_readline_rl_completion_matches = no; then
1054     AC_DEFINE(rl_completion_matches,completion_matches,Old readline)
1055   fi
1056   AC_CHECK_LIB(readline, [append_history], [frr_cv_append_history=yes], [frr_cv_append_history=no], [$LIBREADLINE])
1057   if test "$frr_cv_append_history" = yes; then
1058     AC_DEFINE(HAVE_APPEND_HISTORY, 1, [Have history.h append_history])
1059   fi
1060   ;;
1061 esac
1062 AC_SUBST(LIBREADLINE)
1063 AM_CONDITIONAL(VTYSH, test "x$VTYSH" = "xvtysh")
1064
1065 dnl ----------
1066 dnl PAM module
1067 dnl
1068 dnl FRR detects the PAM library it is built against by checking for a
1069 dnl functional pam_misc.h (Linux-PAM) or openpam.h (OpenPAM) header. pam_misc.h
1070 dnl is known to #include pam_appl.h, the standard header of a PAM library, and
1071 dnl openpam.h doesn't do that, although depends on the header too. Hence a
1072 dnl little assistance to AC_CHECK_HEADER is necessary for the proper detection
1073 dnl of OpenPAM.
1074 dnl ----------
1075 if test "$with_libpam" = "yes"; then
1076   AC_CHECK_HEADER([security/pam_misc.h],
1077     [AC_DEFINE(HAVE_PAM_MISC_H,,Have pam_misc.h)
1078      AC_DEFINE(PAM_CONV_FUNC,misc_conv,Have misc_conv)
1079      pam_conv_func="misc_conv"
1080     ],
1081     [], FRR_INCLUDES)
1082   AC_CHECK_HEADER([security/openpam.h],
1083     [AC_DEFINE(HAVE_OPENPAM_H,,Have openpam.h)
1084      AC_DEFINE(PAM_CONV_FUNC,openpam_ttyconv,Have openpam_ttyconv)
1085      pam_conv_func="openpam_ttyconv"
1086     ],
1087     [], FRR_INCLUDES[#include <security/pam_appl.h>])
1088   if test -z "$ac_cv_header_security_pam_misc_h$ac_cv_header_security_openpam_h" ; then
1089     AC_MSG_WARN([*** pam support will not be built ***])
1090     with_libpam="no"
1091   fi
1092 fi
1093
1094 if test "$with_libpam" = "yes"; then
1095 dnl took this test from proftpds configure.in and suited to our needs
1096 dnl -------------------------------------------------------------------------
1097 dnl
1098 dnl This next check looks funky due to a linker problem with some versions
1099 dnl of the PAM library.  Prior to 0.72 release, the Linux PAM shared library
1100 dnl omitted requiring libdl linking information. PAM-0.72 or better ships
1101 dnl with RedHat 6.2 and Debian 2.2 or better.
1102 AC_CHECK_LIB(pam, pam_start,
1103   [AC_CHECK_LIB(pam, $pam_conv_func,
1104     [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1105      LIBPAM="-lpam"],
1106     [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1107      LIBPAM="-lpam -lpam_misc"]
1108     )
1109   ],
1110
1111   [AC_CHECK_LIB(pam, pam_end,
1112     [AC_CHECK_LIB(pam, $pam_conv_func,
1113       [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1114        LIBPAM="-lpam -ldl"],
1115       [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1116        LIBPAM="-lpam -ldl -lpam_misc"]
1117      )
1118   ],AC_MSG_WARN([*** pam support will not be built ***]),
1119   [-ldl])
1120   ]
1121 )
1122 fi
1123 AC_SUBST(LIBPAM)
1124
1125 dnl -------------------------------
1126 dnl Endian-ness check
1127 dnl -------------------------------
1128 AC_WORDS_BIGENDIAN
1129
1130 dnl -------------------------------
1131 dnl check the size in byte of the C
1132 dnl -------------------------------
1133 dnl AC_CHECK_SIZEOF(char)
1134 dnl AC_CHECK_SIZEOF(int)
1135 dnl AC_CHECK_SIZEOF(short)
1136 dnl AC_CHECK_SIZEOF(long)
1137
1138 dnl ----------------------------
1139 dnl check existance of functions
1140 dnl ----------------------------
1141 AC_FUNC_FNMATCH
1142 AC_FUNC_FORK
1143 AC_FUNC_MKTIME
1144 AC_FUNC_STAT
1145
1146 dnl -------------------------------
1147 dnl bgpd needs pow() and hence libm
1148 dnl -------------------------------
1149 TMPLIBS="$LIBS"
1150 AC_CHECK_HEADER([math.h],
1151   [AC_CHECK_LIB([m], [pow],
1152     [LIBM="-lm"
1153      LIBS="$LIBS $LIBM"
1154      AC_CHECK_FUNCS(pow,[],[LIBM=""])
1155     ])
1156 ])
1157 if test x"$LIBM" = x ; then
1158   AC_MSG_WARN([Unable to find working pow function - bgpd may not link])
1159 fi
1160 LIBS="$TMPLIBS"
1161 AC_SUBST(LIBM)
1162
1163 AC_CHECK_FUNCS([ppoll], [
1164   AC_DEFINE([HAVE_PPOLL], 1, [have Linux/BSD ppoll()])
1165 ])
1166 AC_CHECK_FUNCS([pollts], [
1167   AC_DEFINE([HAVE_POLLTS], 1, [have NetBSD pollts()])
1168 ])
1169
1170 dnl ---------------
1171 dnl other functions
1172 dnl ---------------
1173 AC_CHECK_FUNCS([ \
1174         strlcat strlcpy \
1175         getgrouplist])
1176
1177 AC_CHECK_HEADER([asm-generic/unistd.h],
1178                 [AC_CHECK_DECL(__NR_setns,
1179                                AC_DEFINE(HAVE_NETNS,, Have netns),,
1180                                FRR_INCLUDES [#include <asm-generic/unistd.h>
1181                                ])
1182                  AC_CHECK_FUNCS(setns)]
1183                )
1184
1185 dnl --------------------------
1186 dnl Determine IS-IS I/O method
1187 dnl --------------------------
1188 AC_DEFINE(ISIS_METHOD_PFPACKET, 1, [ constant value for isis method pfpacket ])
1189 AC_DEFINE(ISIS_METHOD_DLPI,     2, [ constant value for isis method dlpi ])
1190 AC_DEFINE(ISIS_METHOD_BPF,      3, [ constant value for isis method bpf ])
1191 AC_CHECK_HEADER(net/bpf.h)
1192 AC_CHECK_HEADER(sys/dlpi.h)
1193 AC_MSG_CHECKING(zebra IS-IS I/O method)
1194
1195 case "$host_os" in
1196   linux*)
1197     AC_MSG_RESULT(pfpacket)
1198     ISIS_METHOD_MACRO="ISIS_METHOD_PFPACKET"
1199     ;;
1200   solaris* | sunos*)
1201     AC_MSG_RESULT(DLPI)
1202     ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1203     ;;
1204   *)
1205     if test $ac_cv_header_net_bpf_h = no; then
1206       if test $ac_cv_header_sys_dlpi_h = no; then
1207         AC_MSG_RESULT(none)
1208         if test "${enable_isisd}" = yes; then
1209           AC_MSG_FAILURE([IS-IS support requested but no packet backend found])
1210         fi
1211         AC_MSG_WARN([*** IS-IS support will not be built ***])
1212         enable_isisd="no"
1213       else
1214         AC_MSG_RESULT(DLPI)
1215       fi
1216       ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1217     else
1218       AC_MSG_RESULT(BPF)
1219       ISIS_METHOD_MACRO="ISIS_METHOD_BPF"
1220     fi
1221     ;;
1222 esac
1223 AC_DEFINE_UNQUOTED(ISIS_METHOD, $ISIS_METHOD_MACRO, [ selected method for isis, == one of the constants ])
1224
1225 dnl ---------------------------------------------------------------
1226 dnl figure out how to specify an interface in multicast sockets API
1227 dnl ---------------------------------------------------------------
1228 AC_CHECK_MEMBERS([struct ip_mreqn.imr_ifindex], [], [], FRR_INCLUDES)
1229
1230 AC_CHECK_HEADERS([linux/mroute.h], [], [],[
1231         #include <sys/socket.h>
1232         #include <netinet/in.h>
1233         #define _LINUX_IN_H             /* For Linux <= 2.6.25 */
1234         #include <linux/types.h>
1235 ])
1236
1237 m4_define([FRR_INCLUDES],
1238 FRR_INCLUDES
1239 [#if HAVE_LINUX_MROUTE_H
1240 # include <linux/mroute.h>
1241 #endif
1242 ])dnl
1243
1244 AC_CHECK_HEADERS([netinet/ip_mroute.h], [], [],[
1245         #include <sys/socket.h>
1246         #include <sys/types.h>
1247         #include <netinet/in.h>
1248         #include <net/route.h>
1249 ])
1250
1251 m4_define([FRR_INCLUDES],
1252 FRR_INCLUDES
1253 [#if HAVE_NETINET_IP_MROUTE_H
1254 # include <netinet/ip_mroute.h>
1255 #endif
1256 ])dnl
1257
1258 AC_MSG_CHECKING([for BSD struct ip_mreq hack])
1259 AC_TRY_COMPILE([#include <sys/param.h>],
1260 [#if (defined(__FreeBSD__) && ((__FreeBSD_version >= 500022 && __FreeBSD_version < 700000) || (__FreeBSD_version < 500000 && __FreeBSD_version >= 440000))) || (defined(__NetBSD__) && defined(__NetBSD_Version__) && __NetBSD_Version__ >= 106010000) || defined(__OpenBSD__) || defined(__APPLE__) || defined(__DragonFly__) || defined(__sun)
1261   return (0);
1262 #else
1263   #error No support for BSD struct ip_mreq hack detected
1264 #endif],[AC_MSG_RESULT(yes)
1265 AC_DEFINE(HAVE_BSD_STRUCT_IP_MREQ_HACK,,[Can pass ifindex in struct ip_mreq])],
1266 AC_MSG_RESULT(no))
1267
1268 AC_MSG_CHECKING([for RFC3678 protocol-independed API])
1269 AC_TRY_COMPILE([
1270 #include <sys/types.h>
1271 #include <netinet/in.h>
1272 ], [struct group_req gr; int sock; setsockopt(sock, IPPROTO_IP, MCAST_JOIN_GROUP, (void*)&gr, sizeof(gr));
1273 ], [AC_MSG_RESULT(yes)
1274 AC_DEFINE(HAVE_RFC3678,1,[Have RFC3678 protocol-independed API])],
1275 AC_MSG_RESULT(no))
1276
1277 dnl ---------------------------------------------------------------
1278 dnl figure out how to check link-state
1279 dnl ---------------------------------------------------------------
1280 AC_CHECK_HEADER( [net/if_media.h],
1281   [m4_define([LINK_DETECT_INCLUDES],
1282     FRR_INCLUDES
1283     [#include <net/if_media.h>
1284   ])
1285   AC_CHECK_MEMBERS( [struct ifmediareq.ifm_status],
1286     AC_DEFINE(HAVE_BSD_LINK_DETECT,,[BSD link-detect]),
1287     [], LINK_DETECT_INCLUDES)],
1288   [],
1289   FRR_INCLUDES)
1290
1291 dnl ---------------------------------------------------------------
1292 dnl Additional, newer way to check link-state using ifi_link_state.
1293 dnl Not available in all BSD's when ifmediareq available
1294 dnl ---------------------------------------------------------------
1295 AC_CHECK_MEMBERS([struct if_data.ifi_link_state],
1296   AC_DEFINE(HAVE_BSD_IFI_LINK_STATE,,[BSD ifi_link_state available]),
1297   [], FRR_INCLUDES)
1298
1299 dnl ------------------------
1300 dnl TCP_MD5SIG socket option
1301 dnl ------------------------
1302
1303 AC_CHECK_HEADER([netinet/tcp.h],
1304    [m4_define([MD5_INCLUDES],
1305       FRR_INCLUDES
1306       [#include <netinet/tcp.h>
1307     ])
1308     AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)],
1309    [],
1310    FRR_INCLUDES)
1311 if test $ac_cv_have_decl_TCP_MD5SIG = no; then
1312   AC_CHECK_HEADER([linux/tcp.h],
1313        [m4_define([MD5_INCLUDES],
1314           FRR_INCLUDES
1315           [#include <linux/tcp.h>
1316         ])
1317        AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)])
1318 fi
1319
1320 dnl ----------------------------------------------------------------------------
1321 dnl figure out if domainname is available in the utsname struct (GNU extension).
1322 dnl ----------------------------------------------------------------------------
1323 AC_CHECK_MEMBERS([struct utsname.domainname], [], [], [#include <sys/utsname.h>])
1324
1325 dnl ------------------
1326 dnl IPv6 header checks
1327 dnl ------------------
1328 AC_CHECK_HEADERS([netinet6/in6.h netinet/in6_var.h \
1329         netinet6/in6_var.h netinet6/nd6.h], [], [],
1330         FRR_INCLUDES)
1331
1332 m4_define([FRR_INCLUDES],dnl
1333 FRR_INCLUDES
1334 [#if HAVE_NETINET6_IN6_H
1335 #include <netinet6/in6.h>
1336 #endif
1337 #if HAVE_NETINET_IN6_VAR_H
1338 #include <netinet/in6_var.h>
1339 #endif
1340 #include <netinet/icmp6.h>
1341 #if HAVE_NETINET6_IN6_VAR_H
1342 # include <netinet6/in6_var.h>
1343 #endif
1344 #if HAVE_NETINET6_ND6_H
1345 # include <netinet6/nd6.h>
1346 #endif
1347 ])dnl
1348
1349 dnl disable doc check
1350 AC_CHECK_PROGS([SPHINXBUILD], [sphinx-build sphinx-build3 sphinx-build2], [/bin/false])
1351 if test "$SPHINXBUILD" = "/bin/false"; then
1352   if test "${enable_doc}" = "yes"; then
1353     AC_MSG_ERROR([Documentation was explicitly requested with --enable-doc but sphinx-build is not available. Please disable docs or install sphinx.])
1354   fi
1355 fi
1356 AM_CONDITIONAL(DOC, test "${enable_doc}" != "no" -a "$SPHINXBUILD" != "/bin/false")
1357 AM_CONDITIONAL(DOC_HTML, test "${enable_doc_html}" = "yes")
1358
1359 dnl --------------------
1360 dnl Daemon disable check
1361 dnl --------------------
1362 AM_CONDITIONAL(ZEBRA, test "${enable_zebra}" != "no")
1363
1364 if test "${enable_bgpd}" = "no";then
1365   BGPD=""
1366 else
1367   BGPD="bgpd"
1368 fi
1369 AM_CONDITIONAL(BGPD, test "x$BGPD" = "xbgpd")
1370
1371 AM_CONDITIONAL(RIPD, test "${enable_ripd}" != "no")
1372 AM_CONDITIONAL(OSPFD, test "${enable_ospfd}" != "no")
1373 AM_CONDITIONAL(LDPD, test "${enable_ldpd}" != "no")
1374
1375 AS_IF([test "${enable_ldpd}" != "no"], [
1376   AC_DEFINE(HAVE_LDPD, 1, ldpd)
1377 ])
1378
1379 if test "$enable_bfdd" = "no"; then
1380   AC_DEFINE(HAVE_BFDD, 0, bfdd)
1381   BFDD=""
1382 else
1383   AC_DEFINE(HAVE_BFDD, 1, bfdd)
1384   BFDD="bfdd"
1385
1386   case $host_os in
1387     linux*)
1388       AC_DEFINE(BFD_LINUX, 1, bfdd)
1389       ;;
1390
1391     *)
1392       AC_DEFINE(BFD_BSD, 1, bfdd)
1393       ;;
1394   esac
1395 fi
1396
1397 AM_CONDITIONAL(BFDD, [test "x$BFDD" = "xbfdd"])
1398
1399 if test "$ac_cv_lib_json_c_json_object_get" = no -a "x$BFDD" = "xbfdd"; then
1400   AC_MSG_ERROR(["you must use json-c library to use bfdd"])
1401 fi
1402
1403 NHRPD=""
1404 case "$host_os" in
1405   linux*)
1406     if test "${enable_nhrpd}" != "no"; then
1407       NHRPD="nhrpd"
1408     fi
1409     ;;
1410   *)
1411     if test "${enable_nhrpd}" = "yes"; then
1412       AC_MSG_ERROR([nhrpd requires kernel APIs that are only present on Linux.])
1413     fi
1414     ;;
1415 esac
1416 AM_CONDITIONAL(NHRPD, test "x$NHRPD" = "xnhrpd")
1417
1418 AM_CONDITIONAL(EIGRPD, test "${enable_eigrpd}" != "no")
1419
1420 if test "${enable_watchfrr}" = "no";then
1421   WATCHFRR=""
1422 else
1423   WATCHFRR="watchfrr"
1424 fi
1425 AM_CONDITIONAL(WATCHFRR, test "x$WATCHFRR" = "xwatchfrr")
1426
1427 OSPFCLIENT=""
1428 if test "${enable_ospfapi}" != "no";then
1429     AC_DEFINE(SUPPORT_OSPF_API,,OSPFAPI)
1430
1431   if test "${enable_ospfclient}" != "no";then
1432       OSPFCLIENT="ospfclient"
1433   fi
1434 fi
1435
1436 AM_CONDITIONAL(OSPFCLIENT, test "x$OSPFCLIENT" = "xospfclient")
1437 AM_CONDITIONAL(RIPNGD, test "${enable_ripngd}" != "no")
1438 AM_CONDITIONAL(BABELD, test "${enable_babeld}" != "no")
1439 AM_CONDITIONAL(OSPF6D, test "${enable_ospf6d}" != "no")
1440 AM_CONDITIONAL(ISISD, test "${enable_isisd}" != "no")
1441 AM_CONDITIONAL(PIMD, test "${enable_pimd}" != "no")
1442 AM_CONDITIONAL(PBRD, test "${enable_pbrd}" != "no")
1443 AM_CONDITIONAL(SHARPD, test "${enable_sharpd}" = "yes")
1444 AM_CONDITIONAL(STATICD, test "${enable_staticd}" != "no")
1445
1446 if test "${enable_bgp_announce}" = "no";then
1447   AC_DEFINE(DISABLE_BGP_ANNOUNCE,1,Disable BGP installation to zebra)
1448 else
1449   AC_DEFINE(DISABLE_BGP_ANNOUNCE,0,Disable BGP installation to zebra)
1450 fi
1451
1452 if test "${enable_bgp_vnc}" != "no";then
1453   AC_DEFINE(ENABLE_BGP_VNC,1,Enable BGP VNC support)
1454 fi
1455 AM_CONDITIONAL([ENABLE_BGP_VNC], [test x${enable_bgp_vnc} != xno])
1456
1457 AC_SUBST(SOLARIS)
1458 AC_CHECK_LIB(crypt, crypt, [],
1459                     [AC_CHECK_LIB(crypto, DES_crypt)])
1460 AC_CHECK_LIB(resolv, res_init)
1461
1462 dnl ---------------------------
1463 dnl check system has PCRE regexp
1464 dnl ---------------------------
1465 if test "x$enable_pcreposix" = "xyes"; then
1466   AC_CHECK_LIB(pcreposix, regexec, [], [
1467     AC_MSG_ERROR([--enable-pcreposix given but unable to find libpcreposix])
1468   ])
1469 fi
1470 AC_SUBST(HAVE_LIBPCREPOSIX)
1471
1472 dnl ------------------
1473 dnl check C-Ares library
1474 dnl ------------------
1475 if test "${NHRPD}" != ""; then
1476   PKG_CHECK_MODULES([CARES], [libcares], , [
1477     AC_MSG_ERROR([trying to build nhrpd, but libcares not found. install c-ares and its -dev headers.])
1478   ])
1479 fi
1480
1481
1482 dnl ------------------
1483 dnl check Net-SNMP library
1484 dnl ------------------
1485 if test "${enable_snmp}" != "" -a "${enable_snmp}" != "no"; then
1486    AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], [no])
1487    if test x"$NETSNMP_CONFIG" = x"no"; then
1488       AC_MSG_ERROR([--enable-snmp given but unable to find net-snmp-config])
1489    fi
1490    SNMP_LIBS="`${NETSNMP_CONFIG} --agent-libs`"
1491    SNMP_CFLAGS="`${NETSNMP_CONFIG} --base-cflags`"
1492    AC_MSG_CHECKING([whether we can link to Net-SNMP])
1493    AC_LINK_IFELSE_FLAGS([$SNMP_CFLAGS], [$SNMP_LIBS], [AC_LANG_PROGRAM([
1494 int main(void);
1495 ],
1496 [
1497 {
1498   return 0;
1499 }
1500 ])], [
1501      AC_MSG_ERROR([--enable-snmp given but not usable])])
1502    case "${enable_snmp}" in
1503      yes)
1504       SNMP_METHOD=agentx
1505       ;;
1506      agentx)
1507       SNMP_METHOD="${enable_snmp}"
1508       ;;
1509      *)
1510       AC_MSG_ERROR([--enable-snmp given with an unknown method (${enable_snmp}). Use yes or agentx])
1511       ;;
1512    esac
1513    AH_TEMPLATE([SNMP_AGENTX], [Use SNMP AgentX to interface with snmpd])
1514    AC_DEFINE_UNQUOTED(AS_TR_CPP(SNMP_${SNMP_METHOD}),,SNMP method to interface with snmpd)
1515 fi
1516 AM_CONDITIONAL([SNMP], [test "x${SNMP_METHOD}" != "x"])
1517 AC_SUBST(SNMP_LIBS)
1518 AC_SUBST(SNMP_CFLAGS)
1519
1520 dnl ---------------
1521 dnl math
1522 dnl ---------------
1523 AC_SEARCH_LIBS([sqrt], [m])
1524
1525 dnl ---------------
1526 dnl dlopen & dlinfo
1527 dnl ---------------
1528 AC_SEARCH_LIBS(dlopen, [dl dld], [], [
1529   AC_MSG_ERROR([unable to find the dlopen()])
1530 ])
1531
1532 AC_CHECK_HEADERS([link.h])
1533
1534 AC_CACHE_CHECK([for dlinfo(RTLD_DI_ORIGIN)], [frr_cv_rtld_di_origin], [
1535   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1536 #include <stdlib.h>
1537 #ifdef HAVE_LINK_H
1538 #include <link.h>
1539 #endif
1540 #include <dlfcn.h>
1541 ]], [[
1542   char origin[1];
1543   dlinfo (NULL, RTLD_DI_ORIGIN, &origin);
1544 ]])], [
1545     frr_cv_rtld_di_origin=yes
1546   ], [
1547     frr_cv_rtld_di_origin=no
1548   ])
1549 ])
1550 if test "$frr_cv_rtld_di_origin" = yes; then
1551   AC_DEFINE(HAVE_DLINFO_ORIGIN, 1, [Have dlinfo RTLD_DI_ORIGIN])
1552 fi
1553
1554 AC_CACHE_CHECK([for dlinfo(RTLD_DI_LINKMAP)], [frr_cv_rtld_di_linkmap], [
1555   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1556 #include <stdlib.h>
1557 #ifdef HAVE_LINK_H
1558 #include <link.h>
1559 #endif
1560 #include <dlfcn.h>
1561 ]], [[
1562   struct link_map *lm = NULL;
1563   dlinfo (NULL, RTLD_DI_LINKMAP, &lm);
1564 ]])], [
1565     frr_cv_rtld_di_linkmap=yes
1566   ], [
1567     frr_cv_rtld_di_linkmap=no
1568   ])
1569 ])
1570 if test "$frr_cv_rtld_di_linkmap" = yes; then
1571   AC_DEFINE(HAVE_DLINFO_LINKMAP, 1, [Have dlinfo RTLD_DI_LINKMAP])
1572 fi
1573
1574 AM_CONDITIONAL(SNMP, test "x$SNMP_METHOD" = "xagentx")
1575
1576 dnl ---------------------------
1577 dnl sockaddr and netinet checks
1578 dnl ---------------------------
1579 AC_CHECK_TYPES([
1580         struct sockaddr_dl,
1581         struct vifctl, struct mfcctl, struct sioc_sg_req,
1582         vifi_t, struct sioc_vif_req, struct igmpmsg,
1583         struct ifaliasreq, struct if6_aliasreq, struct in6_aliasreq,
1584         struct nd_opt_adv_interval, struct rt_addrinfo,
1585         struct nd_opt_homeagent_info, struct nd_opt_adv_interval],
1586         [], [], FRR_INCLUDES)
1587
1588 AC_CHECK_MEMBERS([struct sockaddr.sa_len,
1589         struct sockaddr_in.sin_len, struct sockaddr_un.sun_len,
1590         struct sockaddr_dl.sdl_len,
1591         struct if6_aliasreq.ifra_lifetime,
1592         struct nd_opt_adv_interval.nd_opt_ai_type],
1593         [], [], FRR_INCLUDES)
1594
1595 dnl ---------------------------
1596 dnl IRDP/pktinfo/icmphdr checks
1597 dnl ---------------------------
1598
1599 AC_CHECK_TYPES([struct in_pktinfo], [
1600   AC_CHECK_TYPES([struct icmphdr], [
1601     IRDP=true
1602   ], [
1603     IRDP=false
1604   ], [FRR_INCLUDES])
1605 ], [
1606   IRDP=false
1607 ], [FRR_INCLUDES])
1608
1609 case "${enable_irdp}" in
1610 yes)
1611   $IRDP || AC_MSG_ERROR(['IRDP requires in_pktinfo at the moment!'])
1612   ;;
1613 no)
1614   IRDP=false
1615   ;;
1616 esac
1617
1618 AM_CONDITIONAL(IRDP, $IRDP)
1619
1620 dnl -----------------------
1621 dnl checking for IP_PKTINFO
1622 dnl -----------------------
1623 AC_MSG_CHECKING(for IP_PKTINFO)
1624 AC_TRY_COMPILE([#include <netdb.h>], [
1625   int opt = IP_PKTINFO;
1626 ], [
1627   AC_MSG_RESULT(yes)
1628   AC_DEFINE(HAVE_IP_PKTINFO, 1, [Have IP_PKTINFO])
1629 ], [
1630   AC_MSG_RESULT(no)
1631 ])
1632
1633 dnl ---------------------------
1634 dnl checking for IP_RECVDSTADDR
1635 dnl ---------------------------
1636 AC_MSG_CHECKING(for IP_RECVDSTADDR)
1637 AC_TRY_COMPILE([#include <netinet/in.h>], [
1638   int opt = IP_RECVDSTADDR;
1639 ], [
1640   AC_MSG_RESULT(yes)
1641   AC_DEFINE(HAVE_IP_RECVDSTADDR, 1, [Have IP_RECVDSTADDR])
1642 ], [
1643   AC_MSG_RESULT(no)
1644 ])
1645
1646 dnl ----------------------
1647 dnl checking for IP_RECVIF
1648 dnl ----------------------
1649 AC_MSG_CHECKING(for IP_RECVIF)
1650 AC_TRY_COMPILE([#include <netinet/in.h>], [
1651   int opt = IP_RECVIF;
1652 ], [
1653   AC_MSG_RESULT(yes)
1654   AC_DEFINE(HAVE_IP_RECVIF, 1, [Have IP_RECVIF])
1655 ], [
1656   AC_MSG_RESULT(no)
1657 ])
1658
1659 dnl ----------------------
1660 dnl checking for SO_BINDANY
1661 dnl ----------------------
1662 AC_MSG_CHECKING(for SO_BINDANY)
1663 AC_TRY_COMPILE([#include <sys/socket.h>], [
1664   int opt = SO_BINDANY;
1665 ], [
1666   AC_MSG_RESULT(yes)
1667   AC_DEFINE(HAVE_SO_BINDANY, 1, [Have SO_BINDANY])
1668 ], [
1669   AC_MSG_RESULT(no)
1670 ])
1671
1672 dnl ----------------------
1673 dnl checking for IP_FREEBIND
1674 dnl ----------------------
1675 AC_MSG_CHECKING(for IP_FREEBIND)
1676 AC_TRY_COMPILE([#include <netinet/in.h>], [
1677   int opt = IP_FREEBIND;
1678 ], [
1679   AC_MSG_RESULT(yes)
1680   AC_DEFINE(HAVE_IP_FREEBIND, 1, [Have IP_FREEBIND])
1681 ], [
1682   AC_MSG_RESULT(no)
1683 ])
1684
1685 dnl --------------------------------------
1686 dnl checking for be32dec existence or not
1687 dnl --------------------------------------
1688 AC_CHECK_DECLS([be32enc, be32dec], [], [],
1689                [#include <sys/endian.h>])
1690
1691 dnl --------------------------------------
1692 dnl checking for clock_time monotonic struct and call
1693 dnl --------------------------------------
1694 AC_CHECK_DECL(CLOCK_MONOTONIC,
1695         [AC_CHECK_LIB(rt, clock_gettime, [LIBS="$LIBS -lrt"])
1696          AC_DEFINE(HAVE_CLOCK_MONOTONIC,, Have monotonic clock)
1697 ], [AC_MSG_RESULT(no)], [FRR_INCLUDES])
1698
1699 dnl --------------------------------------
1700 dnl checking for flex and bison
1701 dnl --------------------------------------
1702
1703 AM_PROG_LEX
1704 AC_MSG_CHECKING(version of flex)
1705 frr_ac_flex_version="$(eval $LEX -V | grep flex | head -n 1)"
1706 frr_ac_flex_version="${frr_ac_flex_version##* }"
1707 AC_MSG_RESULT([$frr_ac_flex_version])
1708 AX_COMPARE_VERSION([$frr_ac_flex_version], [lt], [2.5.20], [
1709   LEX="$SHELL $missing_dir/missing flex"
1710   if test -f "${srcdir}/lib/command_lex.c" -a -f "${srcdir}/lib/command_lex.h"; then
1711     AC_MSG_WARN([using pregenerated flex output files])
1712   else
1713     AC_MSG_ERROR([flex failure and pregenerated files not included (probably a git build)])
1714   fi
1715   AC_SUBST([LEX_OUTPUT_ROOT], [lex.yy])
1716   AC_SUBST([LEXLIB], [''])
1717 ])
1718
1719 AC_PROG_YACC
1720 dnl thanks GNU bison for this b*llshit...
1721 AC_MSG_CHECKING(version of bison)
1722 frr_ac_bison_version="$(eval $YACC -V | grep bison | head -n 1)"
1723 frr_ac_bison_version="${frr_ac_bison_version##* }"
1724 frr_ac_bison_missing="false"
1725 case "x${frr_ac_bison_version}" in
1726   x2.7*)
1727     BISON_OPENBRACE='"'
1728     BISON_CLOSEBRACE='"'
1729     BISON_VERBOSE=''
1730     AC_MSG_RESULT([$frr_ac_bison_version - 2.7 or older])
1731     ;;
1732   x2.*|x1.*)
1733     AC_MSG_RESULT([$frr_ac_bison_version])
1734     AC_MSG_WARN([installed bison is too old.  Please install GNU bison 2.7.x or newer.])
1735     frr_ac_bison_missing="true"
1736     ;;
1737   x)
1738     AC_MSG_RESULT([none])
1739     AC_MSG_WARN([could not determine bison version.  Please install GNU bison 2.7.x or newer.])
1740     frr_ac_bison_missing="true"
1741     ;;
1742   *)
1743     BISON_OPENBRACE='{'
1744     BISON_CLOSEBRACE='}'
1745     BISON_VERBOSE='-Dparse.error=verbose'
1746     AC_MSG_RESULT([$frr_ac_bison_version - 3.0 or newer])
1747     ;;
1748 esac
1749 AC_SUBST(BISON_OPENBRACE)
1750 AC_SUBST(BISON_CLOSEBRACE)
1751 AC_SUBST(BISON_VERBOSE)
1752
1753 if $frr_ac_bison_missing; then
1754   YACC="$SHELL $missing_dir/missing bison -y"
1755   if test -f "${srcdir}/lib/command_parse.c" -a -f "${srcdir}/lib/command_parse.h"; then
1756     AC_MSG_WARN([using pregenerated bison output files])
1757   else
1758     AC_MSG_ERROR([bison failure and pregenerated files not included (probably a git build)])
1759   fi
1760 fi
1761
1762 dnl -------------------
1763 dnl capabilities checks
1764 dnl -------------------
1765 if test "${enable_capabilities}" != "no"; then
1766   AC_MSG_CHECKING(whether prctl PR_SET_KEEPCAPS is available)
1767   AC_TRY_COMPILE([#include <sys/prctl.h>],[prctl(PR_SET_KEEPCAPS, 1, 0, 0, 0);],
1768     [AC_MSG_RESULT(yes)
1769      AC_DEFINE(HAVE_PR_SET_KEEPCAPS,,prctl)
1770      frr_ac_keepcaps="yes"],
1771      AC_MSG_RESULT(no)
1772   )
1773   if test x"${frr_ac_keepcaps}" = x"yes"; then
1774     AC_CHECK_HEADERS(sys/capability.h)
1775   fi
1776   if test x"${ac_cv_header_sys_capability_h}" = x"yes"; then
1777     AC_CHECK_LIB(cap, cap_init,
1778       [AC_DEFINE(HAVE_LCAPS,1,Capabilities)
1779        LIBCAP="-lcap"
1780        frr_ac_lcaps="yes"]
1781     )
1782   else
1783     AC_CHECK_HEADERS(priv.h,
1784      [AC_MSG_CHECKING(Solaris style privileges are available)
1785       AC_TRY_COMPILE([#include <priv.h>],[getpflags(PRIV_AWARE);],
1786           [AC_MSG_RESULT(yes)
1787            AC_DEFINE(HAVE_SOLARIS_CAPABILITIES,1,getpflags)
1788            frr_ac_scaps="yes"],
1789            AC_MSG_RESULT(no)
1790       )
1791      ]
1792    )
1793   fi
1794   if test x"${frr_ac_scaps}" = x"yes" \
1795        -o x"${frr_ac_lcaps}" = x"yes"; then
1796     AC_DEFINE(HAVE_CAPABILITIES,1,capabilities)
1797   fi
1798 fi
1799 AC_SUBST(LIBCAP)
1800
1801 dnl ---------------------------
1802 dnl check for glibc 'backtrace'
1803 dnl ---------------------------
1804 if test x"${enable_backtrace}" != x"no" ; then
1805   backtrace_ok=no
1806   AC_CHECK_HEADER([execinfo.h], [
1807     AC_SEARCH_LIBS([backtrace], [execinfo], [
1808       AC_DEFINE(HAVE_GLIBC_BACKTRACE,,[Glibc backtrace])
1809       AC_DEFINE(HAVE_STACK_TRACE,,[Stack symbol decoding])
1810       backtrace_ok=yes
1811     ],, [-lm])
1812   ])
1813
1814   if test x"${enable_backtrace}" = x"yes" -a x"${backtrace_ok}" = x"no"; then
1815     dnl user explicitly requested backtrace but we failed to find support
1816     AC_MSG_FAILURE([failed to find backtrace support])
1817   fi
1818 fi
1819
1820 dnl -----------------------------------------
1821 dnl check for malloc mallinfo struct and call
1822 dnl this must try and link using LIBS, in
1823 dnl order to check no alternative allocator
1824 dnl has been specified, which might not provide
1825 dnl mallinfo, e.g. such as Umem on Solaris.
1826 dnl -----------------------------------------
1827 AC_CHECK_HEADERS([malloc.h malloc/malloc.h],,, [FRR_INCLUDES])
1828
1829 AC_CACHE_CHECK([whether mallinfo is available], [frr_cv_mallinfo], [
1830   AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
1831 #ifdef HAVE_MALLOC_H
1832 #include <malloc.h>
1833 #endif
1834 #ifdef HAVE_MALLOC_MALLOC_H
1835 #include <malloc/malloc.h>
1836 #endif
1837 ]], [[
1838 struct mallinfo ac_x; ac_x = mallinfo ();
1839 ]])], [
1840     frr_cv_mallinfo=yes
1841   ], [
1842     frr_cv_mallinfo=no
1843   ])
1844 ])
1845 if test "$frr_cv_mallinfo" = yes; then
1846   AC_DEFINE(HAVE_MALLINFO,,mallinfo)
1847 fi
1848
1849 AC_MSG_CHECKING(whether malloc_usable_size is available)
1850 AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
1851 #ifdef HAVE_MALLOC_H
1852 #include <malloc.h>
1853 #endif
1854 #ifdef HAVE_MALLOC_MALLOC_H
1855 #include <malloc/malloc.h>
1856 #endif
1857 ]], [[
1858 size_t ac_x; ac_x = malloc_usable_size(NULL);
1859 ]])], [
1860   AC_MSG_RESULT(yes)
1861   AC_DEFINE(HAVE_MALLOC_USABLE_SIZE,,malloc_usable_size)
1862 ], [
1863   AC_MSG_RESULT(no)
1864
1865   AC_MSG_CHECKING(whether malloc_size is available)
1866   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1867 #ifdef HAVE_MALLOC_H
1868 #include <malloc.h>
1869 #endif
1870 #ifdef HAVE_MALLOC_MALLOC_H
1871 #include <malloc/malloc.h>
1872 #endif
1873 ]], [[
1874 size_t ac_x; ac_x = malloc_size(NULL);
1875 ]])], [
1876     AC_MSG_RESULT(yes)
1877     AC_DEFINE(HAVE_MALLOC_SIZE,,malloc_size)
1878   ], [
1879     AC_MSG_RESULT(no)
1880   ])
1881 ])
1882
1883 dnl ------
1884 dnl ZeroMQ
1885 dnl ------
1886 if test "x$enable_zeromq" != "xno"; then
1887   PKG_CHECK_MODULES(ZEROMQ, [libzmq >= 4.0.0], [
1888     AC_DEFINE(HAVE_ZEROMQ, 1, [Enable ZeroMQ support])
1889     ZEROMQ=true
1890   ], [
1891     if test "x$enable_zeromq" = "xyes"; then
1892       AC_MSG_ERROR([configuration specifies --enable-zeromq but libzmq was not found])
1893     fi
1894   ])
1895 fi
1896 AM_CONDITIONAL([ZEROMQ], test "x$ZEROMQ" = "xtrue")
1897
1898 dnl ----------
1899 dnl configure date
1900 dnl ----------
1901 dev_version=`echo $VERSION | grep dev`
1902 #don't expire deprecated code in non 'dev' branch
1903 if test "${dev_version}" = ""; then
1904    CONFDATE=0
1905 else
1906    CONFDATE=`date '+%Y%m%d'`
1907 fi
1908 AC_SUBST(CONFDATE)
1909
1910 dnl ------------------------------
1911 dnl set paths for state directory
1912 dnl ------------------------------
1913 AC_MSG_CHECKING(directory to use for state file)
1914 if test "${prefix}" = "NONE"; then
1915   frr_statedir_prefix="";
1916 else
1917   frr_statedir_prefix=${prefix}
1918 fi
1919 if test "${localstatedir}" = '${prefix}/var'; then
1920   for FRR_STATE_DIR in ${frr_statedir_prefix}/var/run dnl
1921                         ${frr_statedir_prefix}/var/adm dnl
1922                         ${frr_statedir_prefix}/etc dnl
1923                         /var/run        dnl
1924                         /var/adm        dnl
1925                         /etc            dnl
1926                         /dev/null;
1927   do
1928     test -d $FRR_STATE_DIR && break
1929   done
1930   frr_statedir=$FRR_STATE_DIR
1931 else
1932   frr_statedir=${localstatedir}
1933 fi
1934 if test $frr_statedir = "/dev/null"; then
1935     AC_MSG_ERROR('STATE DIRECTORY NOT FOUND! FIX OR SPECIFY --localstatedir!')
1936 fi
1937 AC_MSG_RESULT(${frr_statedir})
1938 AC_SUBST(frr_statedir)
1939
1940 AC_DEFINE_UNQUOTED(LDPD_SOCKET, "$frr_statedir/ldpd.sock",ldpd control socket)
1941 AC_DEFINE_UNQUOTED(ZEBRA_SERV_PATH, "$frr_statedir/zserv.api",zebra api socket)
1942 AC_DEFINE_UNQUOTED(BFDD_CONTROL_SOCKET, "$frr_statedir/bfdd.sock", bfdd control socket)
1943 AC_DEFINE_UNQUOTED(DAEMON_VTY_DIR, "$frr_statedir",daemon vty directory)
1944
1945 dnl autoconf does this, but it does it too late...
1946 test "x$prefix" = xNONE && prefix=$ac_default_prefix
1947 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
1948
1949 dnl get the full path, recursing through variables...
1950 vtysh_bin="$bindir/vtysh"
1951 for I in 1 2 3 4 5 6 7 8 9 10; do
1952         eval vtysh_bin="\"$vtysh_bin\""
1953 done
1954 AC_DEFINE_UNQUOTED(VTYSH_BIN_PATH, "$vtysh_bin",path to vtysh binary)
1955 AC_SUBST(vtysh_bin)
1956
1957 CFG_SYSCONF="$sysconfdir"
1958 CFG_SBIN="$sbindir"
1959 CFG_STATE="$frr_statedir"
1960 CFG_MODULE="$moduledir"
1961 for I in 1 2 3 4 5 6 7 8 9 10; do
1962         eval CFG_SYSCONF="\"$CFG_SYSCONF\""
1963         eval CFG_SBIN="\"$CFG_SBIN\""
1964         eval CFG_STATE="\"$CFG_STATE\""
1965         eval CFG_MODULE="\"$CFG_MODULE\""
1966 done
1967 AC_SUBST(CFG_SYSCONF)
1968 AC_SUBST(CFG_SBIN)
1969 AC_SUBST(CFG_STATE)
1970 AC_SUBST(CFG_MODULE)
1971 AC_DEFINE_UNQUOTED(MODULE_PATH, "$CFG_MODULE", path to modules)
1972
1973 dnl ------------------------------------
1974 dnl Enable RPKI and add librtr to libs
1975 dnl ------------------------------------
1976 if test "${enable_rpki}" = "yes"; then
1977   PKG_CHECK_MODULES(RTRLIB,[rtrlib >= 0.5.0],
1978       [RPKI=true],
1979       [RPKI=false
1980       AC_MSG_ERROR([rtrlib was not found on your system or is too old.])]
1981   )
1982 fi
1983 AM_CONDITIONAL([RPKI], test "x$RPKI" = "xtrue")
1984
1985 dnl ------------------------------------------
1986 dnl Check whether rtrlib was build with ssh support
1987 dnl ------------------------------------------
1988 AC_MSG_CHECKING([whether the RTR Library is compiled with SSH])
1989 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "rtrlib/rtrlib.h"]],
1990                         [[struct tr_ssh_config config;]])],
1991         [AC_MSG_RESULT(yes)
1992         AC_DEFINE(FOUND_SSH,,found_ssh)],
1993         AC_MSG_RESULT(no)
1994 )
1995
1996 dnl ---------------------------
1997 dnl Check htonl works correctly
1998 dnl ---------------------------
1999 AC_MSG_CHECKING(for working htonl)
2000 AC_CACHE_VAL(ac_cv_htonl_works,
2001  [AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES],[htonl (0);])],
2002                 [ac_cv_htonl_works=yes], [ac_cv_htonl_works=no])
2003  ]
2004 )
2005 AC_MSG_RESULT($ac_cv_htonl_works)
2006
2007 AC_CONFIG_FILES([Makefile],[sed -e 's/^#AUTODERP# //' -i Makefile])
2008
2009 AC_CONFIG_FILES([
2010           config.version
2011           redhat/frr.spec
2012           solaris/Makefile
2013           debianpkg/changelog
2014           alpine/APKBUILD
2015           snapcraft/snapcraft.yaml
2016           lib/version.h
2017           tests/lib/cli/test_cli.refout
2018           pkgsrc/bgpd.sh pkgsrc/ospf6d.sh pkgsrc/ospfd.sh
2019           pkgsrc/ripd.sh pkgsrc/ripngd.sh pkgsrc/zebra.sh
2020           pkgsrc/eigrpd.sh])
2021
2022 AC_CONFIG_FILES([vtysh/extract.pl],[chmod +x vtysh/extract.pl])
2023 AC_CONFIG_FILES([tools/frr],[chmod +x tools/frr])
2024
2025 AC_CONFIG_COMMANDS([lib/route_types.h], [
2026         dst="${ac_abs_top_builddir}/lib/route_types.h"
2027         ${PERL} "${ac_abs_top_srcdir}/lib/route_types.pl" \
2028                 < "${ac_abs_top_srcdir}/lib/route_types.txt" \
2029                 > "${dst}.tmp"
2030         test -f "${dst}" \
2031                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
2032                 && rm "${dst}.tmp" \
2033                 || mv "${dst}.tmp" "${dst}"
2034 ], [
2035         PERL="$PERL"
2036 ])
2037
2038 AS_IF([test "x$with_pkg_git_version" = "xyes"], [
2039     AC_CONFIG_COMMANDS([lib/gitversion.h], [
2040         dst="${ac_abs_top_builddir}/lib/gitversion.h"
2041         ${PERL} "${ac_abs_top_srcdir}/lib/gitversion.pl" \
2042                 "${ac_abs_top_srcdir}" \
2043                 > "${dst}.tmp"
2044         test -f "${dst}" \
2045                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
2046                 && rm "${dst}.tmp" \
2047                 || mv "${dst}.tmp" "${dst}"
2048     ], [
2049         PERL="$PERL"
2050     ])
2051 ])
2052
2053 ## Hack, but working solution to avoid rebuilding of frr.info.
2054 ## It's already in CVS until texinfo 4.7 is more common.
2055 AC_OUTPUT
2056
2057 echo "
2058 FRRouting configuration
2059 ------------------------------
2060 FRR version             : ${PACKAGE_VERSION}
2061 host operating system   : ${host_os}
2062 source code location    : ${srcdir}
2063 compiler                : ${CC}
2064 compiler flags          : ${CFLAGS} ${SAN_FLAGS}
2065 make                    : ${MAKE-make}
2066 linker flags            : ${LDFLAGS} ${SAN_FLAGS} ${LIBS} ${LIBCAP} ${LIBREADLINE} ${LIBM}
2067 state file directory    : ${frr_statedir}
2068 config file directory   : `eval echo \`echo ${sysconfdir}\``
2069 example directory       : `eval echo \`echo ${exampledir}\``
2070 module directory        : ${CFG_MODULE}
2071 user to run as          : ${enable_user}
2072 group to run as         : ${enable_group}
2073 group for vty sockets   : ${enable_vty_group}
2074 config file mask        : ${enable_configfile_mask}
2075 log file mask           : ${enable_logfile_mask}
2076 zebra protobuf enabled  : ${enable_protobuf:-no}
2077
2078 The above user and group must have read/write access to the state file
2079 directory and to the config files in the config file directory."
2080
2081 if test "${enable_doc}" != "no";then
2082   AS_IF([test "$SPHINXBUILD" = /bin/false],
2083      AC_MSG_WARN(sphinx-build is missing but required to build documentation))
2084 fi