configure.ac

   1 ##
   2 ## Configure template file for FRRouting.
   3 ## autoconf will generate a configure script.
   4 ##
   5 ##  Copyright (c) 1996, 97, 98, 99, 2000 Kunihiro Ishiguro <kunihiro@zebra.org>
   6 ##  Portions Copyright (c) 2003 Paul Jakma <paul@dishone.st>
   7 ##
   8 AC_PREREQ([2.69])
   9
  10 AC_INIT([frr], [8.5-dev], [https://github.com/frrouting/frr/issues])
  11 PACKAGE_URL="https://frrouting.org/"
  12 AC_SUBST([PACKAGE_URL])
  13 PACKAGE_FULLNAME="FRRouting"
  14 AC_SUBST([PACKAGE_FULLNAME])
  15
  16 CONFIG_ARGS="`echo $ac_configure_args | sed -e \"s% '[[A-Z]]*FLAGS=[[^']]\+'%%g\"`"
  17 AC_SUBST([CONFIG_ARGS])
  18
  19 AC_CONFIG_SRCDIR([lib/zebra.h])
  20 AC_CONFIG_MACRO_DIR([m4])
  21 AC_CONFIG_AUX_DIR([m4/ac])
  22
  23 dnl -----------------------------------
  24 dnl Get hostname and other information.
  25 dnl -----------------------------------
  26 AC_CANONICAL_BUILD()
  27 AC_CANONICAL_HOST()
  28
  29 AC_ARG_VAR([AR],[archiver command])
  30 AC_ARG_VAR([LD],[linker command])
  31 AC_ARG_VAR([OBJCOPY],[objcopy command])
  32 AC_ARG_VAR([OBJDUMP],[objdump command])
  33 AC_ARG_VAR([RANLIB],[ranlib command])
  34 AC_ARG_VAR([STRIP],[strip command])
  35
  36 hosttools_clippy="false"
  37 build_clippy="true"
  38
  39 dnl case 1: external clippy
  40 if test -n "$with_clippy" -a "$with_clippy" != "no" -a "$with_clippy" != "yes"; then
  41   if test "$enable_clippy_only" = "yes"; then
  42     AC_MSG_ERROR([--enable-clippy-only does not make sense with --with-clippy])
  43   fi
  44
  45   CLIPPY="$with_clippy"
  46   build_clippy="false"
  47   if test ! -x "$with_clippy"; then
  48     AC_MSG_ERROR([clippy tool ($with_clippy) is not executable])
  49   fi
  50
  51 dnl case 2: cross-compiling internal clippy
  52 elif test "$host" != "$build"; then
  53   if test "$srcdir" = "."; then
  54     AC_MSG_ERROR([cross-compilation is only possible with builddir separate from srcdir or by building clippy separately and using the --with-clippy option.  create a separate directory and run as .../path-to-frr/configure.])
  55   fi
  56   test -d hosttools || mkdir hosttools
  57   abssrc="`cd \"${srcdir}\"; pwd`"
  58
  59   AC_MSG_NOTICE([...])
  60   AC_MSG_NOTICE([... cross-compilation: creating hosttools directory and self-configuring for build platform tools])
  61   AC_MSG_NOTICE([... use HOST_CPPFLAGS / HOST_CFLAGS / HOST_LDFLAGS if necessary])
  62   AC_MSG_NOTICE([...])
  63
  64   (
  65     for var in $ac_precious_vars; do
  66       dnl special cases
  67       case "$var" in
  68       YACC|YFLAGS) continue;;
  69       PYTHON*)     retain=true;;
  70       *)           retain=false;
  71       esac
  72
  73       eval "hostvar=\"\${HOST_$var}\""
  74       eval "targetvar=\"\${$var}\""
  75       if test -n "$hostvar"; then
  76         eval "$var='$hostvar'"
  77         _AS_ECHO_LOG([host $var='$hostvar'])
  78       elif $retain; then
  79         _AS_ECHO_LOG([host retain $var='$targetvar'])
  80       else
  81         eval "unset $var"
  82         _AS_ECHO_LOG([host unset $var])
  83       fi
  84     done
  85     cd hosttools
  86     "${abssrc}/configure" "--host=$build" "--build=$build" "--enable-clippy-only" "--disable-nhrpd" "--disable-vtysh"
  87   ) || exit 1
  88
  89   AC_MSG_NOTICE([...])
  90   AC_MSG_NOTICE([... cross-compilation: finished self-configuring for build platform tools])
  91   AC_MSG_NOTICE([...])
  92
  93   build_clippy="false"
  94   hosttools_clippy="true"
  95   CLIPPY="hosttools/lib/clippy"
  96
  97 dnl case 3: normal build internal clippy
  98 else
  99   CLIPPY="lib/clippy\$(EXEEXT)"
 100 fi
 101 AC_SUBST([CLIPPY])
 102 AM_CONDITIONAL([BUILD_CLIPPY], [$build_clippy])
 103 AM_CONDITIONAL([HOSTTOOLS_CLIPPY], [$hosttools_clippy])
 104 AM_CONDITIONAL([ONLY_CLIPPY], [test "$enable_clippy_only" = "yes"])
 105
 106 # Disable portability warnings -- our automake code (in particular
 107 # common.am) uses some constructs specific to gmake.
 108 AM_INIT_AUTOMAKE([1.12 -Wno-portability foreign])
 109 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
 110 AM_SILENT_RULES([yes])
 111 AC_CONFIG_HEADERS([config.h])
 112
 113 AC_PATH_PROG([PERL], [perl])
 114 PKG_PROG_PKG_CONFIG
 115
 116 dnl default is to match previous behavior
 117 pkgsrcrcdir=""
 118 AC_ARG_ENABLE([pkgsrcrcdir],
 119           AS_HELP_STRING([--enable-pkgsrcrcdir],
 120                          [specify directory for rc.d scripts]),
 121                          pkgsrcrcdir="$enableval",)
 122 dnl XXX add --pkgsrcrcdir to autoconf standard directory list somehow
 123 AC_SUBST([pkgsrcrcdir])
 124 AM_CONDITIONAL([PKGSRC], [test "$pkgsrcrcdir" != ""])
 125
 126 AC_ARG_WITH([moduledir], [AS_HELP_STRING([--with-moduledir=DIR], [module directory (${libdir}/frr/modules)])], [
 127         moduledir="$withval"
 128 ], [
 129         moduledir="\${libdir}/frr/modules"
 130 ])
 131 AC_SUBST([moduledir], [$moduledir])
 132
 133 AC_ARG_WITH([scriptdir], [AS_HELP_STRING([--with-scriptdir=DIR], [script directory (${sysconfdir}/scripts)])], [
 134         scriptdir="$withval"
 135 ], [
 136         scriptdir="\${sysconfdir}/scripts"
 137 ])
 138 AC_SUBST([scriptdir], [$scriptdir])
 139
 140 AC_ARG_WITH([yangmodelsdir], [AS_HELP_STRING([--with-yangmodelsdir=DIR], [yang models directory (${datarootdir}/yang)])], [
 141         yangmodelsdir="$withval"
 142 ], [
 143         yangmodelsdir="\${datarootdir}/yang"
 144 ])
 145 AC_SUBST([yangmodelsdir])
 146
 147 AC_ARG_WITH([vici-socket], [AS_HELP_STRING([--with-vici-socket=PATH], [vici-socket (/var/run/charon.vici)])], [
 148         vici_socket="$withval"
 149 ], [
 150         vici_socket="/var/run/charon.vici"
 151 ])
 152 AC_DEFINE_UNQUOTED([VICI_SOCKET], ["$vici_socket"], [StrongSWAN vici socket path])
 153
 154 AC_ARG_ENABLE(tcmalloc,
 155         AS_HELP_STRING([--enable-tcmalloc], [Turn on tcmalloc]),
 156 [case "${enableval}" in
 157   yes) tcmalloc_enabled=true
 158 LIBS="$LIBS -ltcmalloc_minimal"
 159  ;;
 160   no)  tcmalloc_enabled=false ;;
 161   *) AC_MSG_ERROR([bad value ${enableval} for --enable-tcmalloc]) ;;
 162 esac],[tcmalloc_enabled=false])
 163
 164
 165 dnl Thanks autoconf, but we don't want a default -g -O2.  We have our own
 166 dnl flag determination logic.
 167 CFLAGS="${CFLAGS:-}"
 168
 169 dnl --------------------
 170 dnl Check CC and friends
 171 dnl --------------------
 172 dnl note orig_cflags is also used further down
 173 orig_cflags="$CFLAGS"
 174 orig_cxxflags="$CXXFLAGS"
 175 AC_LANG([C])
 176 AC_PROG_CC
 177 AC_PROG_CPP
 178 AC_PROG_CXX
 179 AM_PROG_CC_C_O
 180 dnl remove autoconf default "-g -O2"
 181 CFLAGS="$orig_cflags"
 182 CXXFLAGS="$orig_cxxflags"
 183
 184 dnl Some special handling for ICC later on
 185 if test "$CC" = "icc"; then
 186     cc_is_icc="yes"
 187 fi
 188
 189 PKG_PROG_PKG_CONFIG
 190
 191 dnl it's 2019, sed is sed.
 192 SED=sed
 193 AC_SUBST([SED])
 194
 195 dnl try and enable CFLAGS that are useful for FRR
 196 dnl - specifically, options to control warnings
 197
 198 AC_SUBST([AC_CFLAGS])
 199 AC_USE_SYSTEM_EXTENSIONS
 200 AC_DEFUN([AC_C_FLAG], [{
 201     m4_pushdef([cachename],[m4_translit([frr_cv_$1],[ =-+/{}$],[________])])
 202     AC_CACHE_CHECK([[whether $CC supports $1]], cachename, [
 203         AC_LANG_PUSH([C])
 204         ac_c_flag_save="$CFLAGS"
 205         CFLAGS="$CFLAGS $1"
 206         AC_COMPILE_IFELSE(
 207                 [AC_LANG_PROGRAM([[$4]])],
 208                 [
 209                         cachename=yes
 210                 ], [
 211                         cachename=no
 212                 ])
 213         CFLAGS="$ac_c_flag_save"
 214         AC_LANG_POP([C])
 215     ])
 216     if test "$cachename" = "yes"; then
 217         m4_if([$3], [], [AC_CFLAGS="$AC_CFLAGS $1"], [$3])
 218     else
 219         :
 220         $2
 221     fi
 222     m4_popdef([cachename])
 223 }])
 224
 225 AC_DEFUN([AC_LINK_IFELSE_FLAGS], [{
 226         AC_LANG_PUSH([C])
 227         ac_cflags_save="$CFLAGS"
 228         ac_libs_save="$LIBS"
 229         CFLAGS="$CFLAGS $1"
 230         LIBS="$LIBS $2"
 231         AC_LINK_IFELSE(
 232                 [$3],
 233                 [
 234                         CFLAGS="$ac_cflags_save"
 235                         LIBS="$ac_libs_save"
 236                         m4_default([$5], [
 237                                 AC_MSG_RESULT([yes])
 238                         ])
 239                 ], [
 240                         CFLAGS="$ac_cflags_save"
 241                         LIBS="$ac_libs_save"
 242                         m4_default([$4], [
 243                                 AC_MSG_RESULT([no])
 244                         ])
 245                 ])
 246         AC_LANG_POP([C])
 247         }])
 248
 249 dnl ICC won't bail on unknown options without -diag-error 10006
 250 dnl need to do this first so we get useful results for the other options
 251 if test "$cc_is_icc" = "yes"; then
 252     AC_C_FLAG([-diag-error 10006])
 253 fi
 254
 255 dnl autoconf 2.69 AC_PROG_CC_C99 is "state of the art"
 256 dnl autoconf 2.70 AC_PROG_CC_C99 is deprecated and AC_PROC_CC tries to do C11
 257 m4_if(m4_version_compare(m4_defn([AC_AUTOCONF_VERSION]), [2.70]), [-1], [dnl
 258   dnl autoconf < 2.70
 259   AC_PROG_CC_C99
 260
 261   dnl AC_PROG_CC_C99 may change CC to include -std=gnu99 or something
 262   ac_cc="$CC"
 263   CC="${CC% -std=gnu99}"
 264   CC="${CC% -std=c99}"
 265
 266   AC_C_FLAG([-std=gnu11], [CC="$ac_cc"], [CC="$CC -std=gnu11"])
 267 ], [
 268   dnl autoconf >= 2.70
 269   if test "$ac_cv_prog_cc_c11" = "no"; then
 270     AC_MSG_ERROR([ISO C11 compiler support (with GNU extensions) is required.])
 271   fi
 272 ])
 273
 274 dnl if the user has specified any CFLAGS, override our settings
 275 if test "$enable_gcov" = "yes"; then
 276    if test "$orig_cflags" = ""; then
 277       AC_C_FLAG([--coverage])
 278       AC_C_FLAG([-O0])
 279    fi
 280
 281    AC_LDFLAGS="${AC_LDFLAGS} --coverage"
 282 fi
 283
 284 if test "$enable_clang_coverage" = "yes"; then
 285    AC_C_FLAG([-fprofile-instr-generate], [
 286      AC_MSG_ERROR([$CC does not support -fprofile-instr-generate.])
 287    ])
 288    AC_C_FLAG([-fcoverage-mapping], [
 289      AC_MSG_ERROR([$CC does not support -fcoverage-mapping.])
 290    ])
 291 fi
 292
 293 AM_CONDITIONAL([SCRIPTING], [test "$enable_scripting" = "yes"])
 294
 295 if test "$enable_scripting" = "yes"; then
 296    AX_PROG_LUA([5.3], [5.4], [], [
 297      AC_MSG_ERROR([Lua 5.3 is required to build with Lua support. No other version is supported.])
 298    ])
 299    AX_LUA_HEADERS([], [
 300      AC_MSG_ERROR([Lua 5.3 headers are required to build with Lua support. No other version is supported.])
 301    ])
 302    AX_LUA_LIBS([
 303      AC_DEFINE([HAVE_SCRIPTING], [1], [Have support for scripting])
 304      LIBS="$LIBS $LUA_LIB"
 305      SCRIPTING=true
 306    ], [
 307      SCRIPTING=false
 308      AC_MSG_ERROR([Lua 5.3 libraries are required to build with Lua support. No other version is supported.])
 309    ])
 310 fi
 311
 312 dnl the following flags go in CFLAGS rather than AC_CFLAGS since they make
 313 dnl sense to be overridden by the user
 314 if test "$enable_dev_build" = "yes"; then
 315    AC_DEFINE([DEV_BUILD], [1], [Build for development])
 316    if test "$orig_cflags" = ""; then
 317       AC_C_FLAG([-O0],,[CFLAGS="$CFLAGS -O0"])
 318       AC_C_FLAG([-g3],,[CFLAGS="$CFLAGS -g3"])
 319       AC_C_FLAG([-ggdb3],,[CFLAGS="$CFLAGS -ggdb3"])
 320    fi
 321 else
 322    if test "$orig_cflags" = ""; then
 323       AC_C_FLAG([-g],,[CFLAGS="$CFLAGS -g"])
 324       AC_C_FLAG([-O2],,[CFLAGS="$CFLAGS -O2"])
 325    fi
 326 fi
 327
 328 dnl just stick -g into LDFLAGS, if we don't have it in CFLAGS it won't do much
 329 LDFLAGS="$LDFLAGS -g"
 330
 331 AM_CONDITIONAL([DEV_BUILD], [test "$enable_dev_build" = "yes"])
 332
 333 dnl -fms-extensions causes clang to have a built-in __wchar_t on OpenBSD,
 334 dnl which just straight up breaks compiling any code.
 335 dnl (2022-04-04 / OpenBSD 7 / clang 11.1.0)
 336 AH_VERBATIM([OpenBSD], [
 337 #ifdef __OpenBSD__
 338 #define __wchar_t __wchar_t_ignore
 339 #include <stdint.h>
 340 #undef __wchar_t
 341 #endif
 342 ])
 343
 344 dnl always want these CFLAGS
 345 AC_C_FLAG([-fms-extensions], [
 346   AC_MSG_ERROR([$CC does not support unnamed struct fields (-fms-extensions)])
 347 ])
 348 AC_C_FLAG([-fno-omit-frame-pointer])
 349 AC_C_FLAG([-funwind-tables])
 350 AC_C_FLAG([-Wall])
 351 AC_C_FLAG([-Wextra])
 352 AC_C_FLAG([-Wstrict-prototypes])
 353 AC_C_FLAG([-Wmissing-prototypes])
 354 AC_C_FLAG([-Wmissing-declarations])
 355 AC_C_FLAG([-Wpointer-arith])
 356 AC_C_FLAG([-Wbad-function-cast])
 357 AC_C_FLAG([-Wwrite-strings])
 358 AC_C_FLAG([-Wundef])
 359 if test "$enable_gcc_ultra_verbose" = "yes" ; then
 360   AC_C_FLAG([-Wcast-qual])
 361   AC_C_FLAG([-Wmissing-noreturn])
 362   AC_C_FLAG([-Wmissing-format-attribute])
 363   AC_C_FLAG([-Wunreachable-code])
 364   AC_C_FLAG([-Wpacked])
 365   AC_C_FLAG([-Wpadded])
 366   AC_C_FLAG([-Wshadow])
 367 else
 368   AC_C_FLAG([-Wno-unused-result])
 369 fi
 370 AC_C_FLAG([-Wno-unused-parameter])
 371 AC_C_FLAG([-Wno-missing-field-initializers])
 372
 373 AC_C_FLAG([-Wc++-compat], [], [CXX_COMPAT_CFLAGS="-Wc++-compat"])
 374 AC_SUBST([CXX_COMPAT_CFLAGS])
 375
 376 dnl ICC emits a broken warning for const char *x = a ? "b" : "c";
 377 dnl for some reason the string consts get 'promoted' to char *,
 378 dnl triggering a const to non-const conversion warning.
 379 if test "$cc_is_icc" = "yes"; then
 380     AC_C_FLAG([-diag-disable 3179])
 381 fi
 382
 383 if test "$enable_werror" = "yes" ; then
 384   WERROR="-Werror"
 385 fi
 386 AC_SUBST([WERROR])
 387
 388 SAN_FLAGS=""
 389 if test "$enable_address_sanitizer" = "yes"; then
 390   AC_C_FLAG([-fsanitize=address], [
 391     AC_MSG_ERROR([$CC does not support Address Sanitizer.])
 392   ], [
 393     SAN_FLAGS="$SAN_FLAGS -fsanitize=address"
 394   ])
 395 fi
 396 if test "$enable_thread_sanitizer" = "yes"; then
 397   AC_C_FLAG([-fsanitize=thread], [
 398     AC_MSG_ERROR([$CC does not support Thread Sanitizer.])
 399   ], [
 400     SAN_FLAGS="$SAN_FLAGS -fsanitize=thread"
 401   ])
 402 fi
 403 if test "$enable_memory_sanitizer" = "yes"; then
 404   AC_C_FLAG([-fsanitize=memory -fPIE -pie], [
 405     AC_MSG_ERROR([$CC does not support Memory Sanitizer.])
 406   ], [
 407     SAN_FLAGS="$SAN_FLAGS -fsanitize=memory -fPIE -pie"
 408   ])
 409 fi
 410 if test "$enable_undefined_sanitizer" = "yes"; then
 411   AC_C_FLAG([-fsanitize=undefined], [
 412     AC_MSG_ERROR([$CC does not support UndefinedBehaviorSanitizer.])
 413   ], [
 414     SAN_FLAGS="$SAN_FLAGS -fsanitize=undefined"
 415   ])
 416 fi
 417 AC_SUBST([SAN_FLAGS])
 418
 419 dnl frr-format.so
 420 if test "$with_frr_format" != "no" -a "$with_frr_format" != "yes" -a -n "$with_frr_format"; then
 421   AC_C_FLAG([-fplugin=${with_frr_format}], [
 422     AC_MSG_ERROR([specified frr-format plugin ($with_frr_format) does not work])
 423   ],,[
 424 #ifndef _FRR_ATTRIBUTE_PRINTFRR
 425 #error plugin not loaded
 426 #endif
 427 #if _FRR_ATTRIBUTE_PRINTFRR < 0x10000
 428 #error plugin too old
 429 #endif
 430   ])
 431 elif test "$with_frr_format" = "no"; then
 432   : #nothing
 433 else
 434   AC_C_FLAG([-fplugin=tools/gcc-plugins/frr-format.so],[
 435     AC_C_FLAG([-fplugin=frr-format],[
 436       if test "$with_frr_format" = "yes"; then
 437         AC_MSG_ERROR([frr-format plugin requested but not found])
 438       fi
 439     ],,[
 440 #ifndef _FRR_ATTRIBUTE_PRINTFRR
 441 #error plugin not loaded
 442 #endif
 443 #if _FRR_ATTRIBUTE_PRINTFRR < 0x10000
 444 #error plugin too old
 445 #endif
 446     ])
 447   ],,[
 448 #ifndef _FRR_ATTRIBUTE_PRINTFRR
 449 #error plugin not loaded
 450 #endif
 451 #if _FRR_ATTRIBUTE_PRINTFRR < 0x10000
 452 #error plugin too old
 453 #endif
 454   ])
 455 fi
 456
 457 AC_MSG_CHECKING([whether linker supports __start/stop_section symbols])
 458 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 459 #include <stdio.h>
 460 int __attribute__((section("secttest"))) var = 1;
 461 extern int __start_secttest, __stop_secttest;
 462 ]], [[
 463   void *a = &var, *b = &__start_secttest, *c = &__stop_secttest;
 464   printf("%p %p %p\n", a, b, c);
 465 ]])], [
 466   AC_MSG_RESULT(yes)
 467   AC_DEFINE(HAVE_SECTION_SYMS, 1, [have __start/stop_section symbols])
 468 ], [
 469   AC_MSG_RESULT(no)
 470 ])
 471
 472 dnl ----------
 473 dnl Essentials
 474 dnl ----------
 475
 476 AX_PTHREAD([
 477   CC="$PTHREAD_CC"
 478   AC_CFLAGS="$AC_CFLAGS $PTHREAD_CFLAGS"
 479   LIBS="$PTHREAD_LIBS $LIBS"
 480 ], [
 481   AC_MSG_FAILURE([This FRR version needs pthreads])
 482 ])
 483
 484 orig_cflags="$CFLAGS"
 485 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 486
 487 AC_SEARCH_LIBS([pthread_condattr_setclock], [],
 488                 [frr_cv_pthread_condattr_setclock=yes],
 489                 [frr_cv_pthread_condattr_setclock=no])
 490 if test "$frr_cv_pthread_condattr_setclock" = "yes"; then
 491   AC_DEFINE([HAVE_PTHREAD_CONDATTR_SETCLOCK], [1], [Have pthread.h pthread_condattr_setclock])
 492 fi
 493
 494 AC_CHECK_HEADERS([pthread_np.h],,, [
 495 #include <pthread.h>
 496 ])
 497 AC_CHECK_FUNCS([pthread_setname_np pthread_set_name_np pthread_getthreadid_np])
 498
 499 CFLAGS="$orig_cflags"
 500
 501 dnl --------------
 502 dnl Check programs
 503 dnl --------------
 504 AC_PROG_INSTALL
 505 AC_PROG_LN_S
 506 AC_CHECK_TOOL([AR], [ar])
 507
 508 dnl -------
 509 dnl libtool
 510 dnl -------
 511 AC_ARG_ENABLE([static-bin],
 512   AS_HELP_STRING([--enable-static-bin], [link binaries statically]))
 513 LT_INIT
 514 _LT_CONFIG_LIBTOOL([
 515   patch -N -i "${srcdir}/m4/libtool-whole-archive.patch" libtool >&AS_MESSAGE_LOG_FD || \
 516     AC_MSG_WARN([Could not patch libtool for static linking support.  Loading modules into a statically linked daemon will fail.])
 517 dnl the -i option is not POSIX sed and the BSDs implement it differently
 518 dnl cat'ing the output back instead of mv/cp keeps permissions on libtool intact
 519   sed -e 's%func_warning "relinking%true #\0%'                   libtool > libtool.sed && cat libtool.sed > libtool
 520   sed -e 's%func_warning "remember to run%true #\0%'             libtool > libtool.sed && cat libtool.sed > libtool
 521   sed -e 's%func_warning ".*has not been installed in%true #\0%' libtool > libtool.sed && cat libtool.sed > libtool
 522   test -f libtool.sed && rm libtool.sed
 523 ])
 524 if test "$enable_static_bin" = "yes"; then
 525   AC_LDFLAGS_EXEC="-static"
 526   if test "$enable_static" != "yes"; then
 527     AC_MSG_ERROR([The --enable-static-bin option must be combined with --enable-static.])
 528   fi
 529 fi
 530 if test "$enable_shared" != "yes"; then
 531   AC_MSG_ERROR([FRR cannot be built with --disable-shared.  If you want statically linked daemons, use --enable-shared --enable-static --enable-static-bin])
 532 fi
 533 AC_SUBST([AC_LDFLAGS])
 534 AC_SUBST([AC_LDFLAGS_EXEC])
 535 AM_CONDITIONAL([STATIC_BIN], [test "$enable_static_bin" = "yes"])
 536
 537 dnl libtool, the repository of all knowledge related linkers, is too stupid to
 538 dnl correctly tell the linker how to build modules.
 539 if test -z "$module_cmds"; then
 540   module_cmds="`echo \"$archive_cmds\" | sed -e 's%$wl-soname $wl$soname%%'`"
 541 fi
 542 if test -z "$module_expsym_cmds"; then
 543   module_expsym_cmds="`echo \"$archive_expsym_cmds\" | sed -e 's%$wl-soname $wl$soname%%'`"
 544 fi
 545
 546 AC_ARG_ENABLE([rpath],
 547   [AS_HELP_STRING([--enable-rpath], [set hardcoded rpaths in the executable @<:@default=yes@:>@])],
 548   [],
 549   [enable_rpath=yes])
 550
 551 dnl $AR and $RANLIB are set by LT_INIT above
 552 AC_MSG_CHECKING([whether $AR supports D option])
 553 if $AR crD conftest.a >/dev/null 2>/dev/null; then
 554   AC_MSG_RESULT([yes])
 555   dnl ARFLAGS is for automake, AR_FLAGS for libtool m-(
 556   ARFLAGS="crD"
 557   AR_FLAGS="crD"
 558 else
 559   AC_MSG_RESULT([no])
 560   ARFLAGS="cru"
 561   AR_FLAGS="cru"
 562 fi
 563 AC_SUBST([ARFLAGS])
 564 AC_SUBST([AR_FLAGS])
 565
 566 AC_MSG_CHECKING([whether $RANLIB supports D option])
 567 if $RANLIB -D conftest.a >conftest.err 2>&1; then
 568   if grep -q -- '-D' conftest.err; then
 569     AC_MSG_RESULT([no])
 570   else
 571     AC_MSG_RESULT([yes])
 572     RANLIB="$RANLIB -D"
 573   fi
 574 else
 575   AC_MSG_RESULT([no])
 576 fi
 577 AC_SUBST([RANLIB])
 578
 579 test -f conftest.err && rm conftest.err
 580 test -f conftest.a && rm conftest.a
 581
 582 dnl ----------------------
 583 dnl Packages configuration
 584 dnl ----------------------
 585 if test -f config.version; then
 586   . ./config.version
 587 elif test -f "${srcdir}/config.version"; then
 588   . "${srcdir}/config.version"
 589 fi
 590 AC_ARG_WITH([pkg-extra-version],
 591   AS_HELP_STRING([--with-pkg-extra-version=VER], [add extra version field, for packagers/distributions]), [
 592   if test "$withval" = "no"; then
 593     EXTRAVERSION=
 594   else
 595     EXTRAVERSION=$withval
 596   fi
 597 ], [])
 598 AC_ARG_WITH([pkg-git-version],
 599         AS_HELP_STRING([--with-pkg-git-version], [add git information to MOTD and build version string]),
 600         [ test "$withval" != "no" && with_pkg_git_version="yes" ])
 601 AC_ARG_WITH([clippy],
 602   AS_HELP_STRING([--with-clippy=PATH], [use external clippy helper program]))
 603 AC_ARG_WITH([vtysh_pager],
 604         AS_HELP_STRING([--with-vtysh-pager=PAGER], [control what pager is compiled in as default]),
 605         VTYSH_PAGER=$withval, VTYSH_PAGER="more")
 606 AC_ARG_ENABLE([vtysh],
 607   AS_HELP_STRING([--disable-vtysh], [do not build integrated vty shell for FRR]))
 608 AC_ARG_ENABLE([doc],
 609   AS_HELP_STRING([--disable-doc], [do not build docs]))
 610 AC_ARG_ENABLE([doc-html],
 611   AS_HELP_STRING([--enable-doc-html], [build HTML docs]))
 612 AC_ARG_ENABLE([zebra],
 613   AS_HELP_STRING([--disable-zebra], [do not build zebra daemon]))
 614 AC_ARG_ENABLE([bgpd],
 615   AS_HELP_STRING([--disable-bgpd], [do not build bgpd]))
 616 AC_ARG_ENABLE([ripd],
 617   AS_HELP_STRING([--disable-ripd], [do not build ripd]))
 618 AC_ARG_ENABLE([ripngd],
 619   AS_HELP_STRING([--disable-ripngd], [do not build ripngd]))
 620 AC_ARG_ENABLE([ospfd],
 621   AS_HELP_STRING([--disable-ospfd], [do not build ospfd]))
 622 AC_ARG_ENABLE([ospf6d],
 623   AS_HELP_STRING([--disable-ospf6d], [do not build ospf6d]))
 624 AC_ARG_ENABLE([ldpd],
 625   AS_HELP_STRING([--disable-ldpd], [do not build ldpd]))
 626 AC_ARG_ENABLE([nhrpd],
 627   AS_HELP_STRING([--disable-nhrpd], [do not build nhrpd]))
 628 AC_ARG_ENABLE([eigrpd],
 629   AS_HELP_STRING([--disable-eigrpd], [do not build eigrpd]))
 630 AC_ARG_ENABLE([babeld],
 631   AS_HELP_STRING([--disable-babeld], [do not build babeld]))
 632 AC_ARG_ENABLE([watchfrr],
 633   AS_HELP_STRING([--disable-watchfrr], [do not build watchfrr]))
 634 AC_ARG_ENABLE([isisd],
 635   AS_HELP_STRING([--disable-isisd], [do not build isisd]))
 636 AC_ARG_ENABLE([pimd],
 637   AS_HELP_STRING([--disable-pimd], [do not build pimd]))
 638 AC_ARG_ENABLE([pim6d],
 639   AS_HELP_STRING([--enable-pim6d], [build pim6d]))
 640 AC_ARG_ENABLE([pbrd],
 641   AS_HELP_STRING([--disable-pbrd], [do not build pbrd]))
 642 AC_ARG_ENABLE([sharpd],
 643   AS_HELP_STRING([--enable-sharpd], [build sharpd]))
 644 AC_ARG_ENABLE([staticd],
 645   AS_HELP_STRING([--disable-staticd], [do not build staticd]))
 646 AC_ARG_ENABLE([fabricd],
 647   AS_HELP_STRING([--disable-fabricd], [do not build fabricd]))
 648 AC_ARG_ENABLE([vrrpd],
 649   AS_HELP_STRING([--disable-vrrpd], [do not build vrrpd]))
 650 AC_ARG_ENABLE([pathd],
 651   AS_HELP_STRING([--disable-pathd], [do not build pathd]))
 652 AC_ARG_ENABLE([bgp-announce],
 653   AS_HELP_STRING([--disable-bgp-announce], [turn off BGP route announcement]))
 654 AC_ARG_ENABLE([bgp-vnc],
 655   AS_HELP_STRING([--disable-bgp-vnc],[turn off BGP VNC support]))
 656 AC_ARG_ENABLE([bgp-bmp],
 657   AS_HELP_STRING([--disable-bgp-bmp],[turn off BGP BMP support]))
 658 AC_ARG_ENABLE([snmp],
 659   AS_HELP_STRING([--enable-snmp], [enable SNMP support for agentx]))
 660 AC_ARG_ENABLE([config_rollbacks],
 661   AS_HELP_STRING([--enable-config-rollbacks], [enable configuration rollbacks (requires sqlite3)]))
 662 AC_ARG_ENABLE([confd],
 663   AS_HELP_STRING([--enable-confd=ARG], [enable confd integration]))
 664 AC_ARG_ENABLE([sysrepo],
 665   AS_HELP_STRING([--enable-sysrepo], [enable sysrepo integration]))
 666 AC_ARG_ENABLE([grpc],
 667   AS_HELP_STRING([--enable-grpc], [enable the gRPC northbound plugin]))
 668 AC_ARG_ENABLE([zeromq],
 669   AS_HELP_STRING([--enable-zeromq], [enable ZeroMQ handler (libfrrzmq)]))
 670 AC_ARG_ENABLE([lttng],
 671   AS_HELP_STRING([--enable-lttng], [enable LTTng tracing]))
 672 AC_ARG_ENABLE([usdt],
 673   AS_HELP_STRING([--enable-usdt], [enable USDT probes]))
 674 AC_ARG_WITH([libpam],
 675   AS_HELP_STRING([--with-libpam], [use libpam for PAM support in vtysh]))
 676 AC_ARG_ENABLE([ospfapi],
 677   AS_HELP_STRING([--disable-ospfapi], [do not build OSPFAPI to access the OSPF LSA Database]))
 678 AC_ARG_ENABLE([ospfclient],
 679   AS_HELP_STRING([--disable-ospfclient], [do not build OSPFAPI client for OSPFAPI,
 680                           (this is the default if --disable-ospfapi is set)]))
 681 AC_ARG_ENABLE([multipath],
 682   AS_HELP_STRING([--enable-multipath=ARG], [enable multipath function, ARG must be digit]))
 683 AC_ARG_WITH([service_timeout],
 684   AS_HELP_STRING([--with-service-timeout=ARG], [set service timeout value (2 minutes by default), ARG must be digit]))
 685 AC_ARG_ENABLE([user],
 686   AS_HELP_STRING([--enable-user=USER], [user to run FRR suite as (default frr)]))
 687 AC_ARG_ENABLE([group],
 688   AS_HELP_STRING([--enable-group=GROUP], [group to run FRR suite as (default frr)]))
 689 AC_ARG_ENABLE([vty_group],
 690   AS_HELP_STRING([--enable-vty-group=ARG], [set vty sockets to have specified group as owner]))
 691 AC_ARG_ENABLE([configfile_mask],
 692   AS_HELP_STRING([--enable-configfile-mask=ARG], [set mask for config files]))
 693 AC_ARG_ENABLE([logfile_mask],
 694   AS_HELP_STRING([--enable-logfile-mask=ARG], [set mask for log files]))
 695 AC_ARG_ENABLE([shell_access],
 696   AS_HELP_STRING([--enable-shell-access], [Allow users to access shell/telnet/ssh]))
 697 AC_ARG_ENABLE([realms],
 698   AS_HELP_STRING([--enable-realms], [enable REALMS support under Linux]))
 699 AC_ARG_ENABLE([rtadv],
 700   AS_HELP_STRING([--disable-rtadv], [disable IPV6 router advertisement feature]))
 701 AC_ARG_ENABLE([irdp],
 702   AS_HELP_STRING([--disable-irdp], [disable IRDP server support in zebra (enabled by default if supported)]))
 703 AC_ARG_ENABLE([capabilities],
 704   AS_HELP_STRING([--disable-capabilities], [disable using POSIX capabilities]))
 705 AC_ARG_ENABLE([gcc_ultra_verbose],
 706   AS_HELP_STRING([--enable-gcc-ultra-verbose], [enable ultra verbose GCC warnings]))
 707 AC_ARG_ENABLE([backtrace],
 708   AS_HELP_STRING([--disable-backtrace], [disable crash backtraces (default autodetect)]))
 709 AC_ARG_ENABLE([time-check],
 710   AS_HELP_STRING([--disable-time-check], [disable slow thread warning messages]))
 711 AC_ARG_ENABLE([cpu-time],
 712   AS_HELP_STRING([--disable-cpu-time], [disable cpu usage data gathering]))
 713 AC_ARG_ENABLE([pcreposix],
 714   AS_HELP_STRING([--enable-pcreposix], [enable using PCRE Posix libs for regex functions]))
 715 AC_ARG_ENABLE([fpm],
 716   AS_HELP_STRING([--enable-fpm], [enable Forwarding Plane Manager support]))
 717 AC_ARG_ENABLE([werror],
 718   AS_HELP_STRING([--enable-werror], [enable -Werror (recommended for developers only)]))
 719 AC_ARG_ENABLE([cumulus],
 720   AS_HELP_STRING([--enable-cumulus], [enable Cumulus Switch Special Extensions]))
 721 AC_ARG_ENABLE([datacenter],
 722   AS_HELP_STRING([--enable-datacenter], [enable Compilation for Data Center Extensions]))
 723 AC_ARG_ENABLE([rr-semantics],
 724   AS_HELP_STRING([--disable-rr-semantics], [disable the v6 Route Replace semantics]))
 725 AC_ARG_ENABLE([protobuf],
 726   AS_HELP_STRING([--enable-protobuf], [Enable experimental protobuf support]))
 727 AC_ARG_ENABLE([oldvpn_commands],
 728   AS_HELP_STRING([--enable-oldvpn-commands], [Keep old vpn commands]))
 729 AC_ARG_ENABLE([rpki],
 730   AS_HELP_STRING([--enable-rpki], [enable RPKI prefix validation support]))
 731 AC_ARG_ENABLE([clippy-only],
 732   AS_HELP_STRING([--enable-clippy-only], [Only build clippy]))
 733 AC_ARG_ENABLE([numeric_version],
 734   AS_HELP_STRING([--enable-numeric-version], [Only numeric digits allowed in version (for Alpine)]))
 735 AC_ARG_ENABLE([gcov],
 736   AS_HELP_STRING([--enable-gcov], [Collect coverage information with gcov]))
 737 AC_ARG_ENABLE([clang_coverage],
 738   AS_HELP_STRING([--enable-clang-coverage], [Collect coverage information with Clang Coverage]))
 739 AC_ARG_ENABLE([bfdd],
 740   AS_HELP_STRING([--disable-bfdd], [do not build bfdd]))
 741 AC_ARG_ENABLE([address-sanitizer],
 742   AS_HELP_STRING([--enable-address-sanitizer], [enable AddressSanitizer support for detecting a wide variety of memory allocation and deallocation errors]))
 743 AC_ARG_ENABLE([thread-sanitizer],
 744   AS_HELP_STRING([--enable-thread-sanitizer], [enable ThreadSanitizer support for detecting data races]))
 745 AC_ARG_ENABLE([memory-sanitizer],
 746   AS_HELP_STRING([--enable-memory-sanitizer], [enable MemorySanitizer support for detecting uninitialized memory reads]))
 747 AC_ARG_ENABLE([undefined-sanitizer],
 748   AS_HELP_STRING([--enable-undefined-sanitizer], [enable UndefinedBehaviorSanitizer support for detecting undefined behavior]))
 749 AC_ARG_WITH([crypto],
 750   AS_HELP_STRING([--with-crypto=<internal|openssl>], [choose between different implementations of cryptographic functions(default value is --with-crypto=internal)]))
 751 AC_ARG_WITH([frr-format],
 752   AS_HELP_STRING([--with-frr-format[=<.../frr-format.so>]], [use frr-format GCC plugin]))
 753
 754 AC_ARG_ENABLE([version-build-config],
 755   AS_HELP_STRING([--disable-version-build-config], [do not include build configs in show version command]))
 756
 757 #if openssl, else use the internal
 758 AS_IF([test "$with_crypto" = "openssl"], [
 759 AC_CHECK_LIB([crypto], [EVP_DigestInit], [LIBS="$LIBS -lcrypto"], [], [])
 760 if test "$ac_cv_lib_crypto_EVP_DigestInit" = "no"; then
 761   AC_MSG_ERROR([build with openssl has been specified but openssl library was not found on your system])
 762 else
 763   AC_DEFINE([CRYPTO_OPENSSL], [1], [Compile with openssl support])
 764 fi
 765 ], [test "$with_crypto" = "internal" || test "$with_crypto" = "" ], [AC_DEFINE([CRYPTO_INTERNAL], [1], [Compile with internal cryptographic implementation])
 766 ], [AC_MSG_ERROR([Unknown value for --with-crypto])]
 767 )
 768
 769 AS_IF([test "$enable_clippy_only" != "yes"], [
 770 AC_CHECK_HEADERS([json-c/json.h])
 771 AC_CHECK_LIB([json-c], [json_object_get], [LIBS="$LIBS -ljson-c"], [], [-lm])
 772 if test "$ac_cv_lib_json_c_json_object_get" = "no"; then
 773   AC_CHECK_LIB([json], [json_object_get], [LIBS="$LIBS -ljson"])
 774   if test "$ac_cv_lib_json_json_object_get" = "no"; then
 775       AC_MSG_ERROR([libjson is needed to compile])
 776   fi
 777 fi
 778 ])
 779
 780 AC_ARG_ENABLE([dev_build],
 781     AS_HELP_STRING([--enable-dev-build], [build for development]))
 782
 783 AC_ARG_ENABLE([scripting],
 784     AS_HELP_STRING([--enable-scripting], [Build with scripting support]))
 785
 786 AC_ARG_ENABLE([netlink-debug],
 787   AS_HELP_STRING([--disable-netlink-debug], [don't pretty print netlink debug messages]))
 788
 789 if test "$enable_netlink_debug" != "no" ; then
 790   AC_DEFINE([NETLINK_DEBUG], [1], [Netlink extra debugging code])
 791 fi
 792
 793 AM_CONDITIONAL([NETLINK_DEBUG], [test "$enable_netlink_debug" != "no"])
 794
 795 if test "$enable_time_check" != "no" ; then
 796   if test "$enable_time_check" = "yes" -o "$enable_time_check" = "" ; then
 797     AC_DEFINE([CONSUMED_TIME_CHECK], [5000000], [Consumed Time Check])
 798   else
 799     AC_DEFINE_UNQUOTED([CONSUMED_TIME_CHECK], [$enable_time_check], [Consumed Time Check])
 800   fi
 801 fi
 802
 803 case "${enable_cpu_time}" in
 804   "no")
 805   AC_DEFINE([EXCLUDE_CPU_TIME], [1], [Exclude getrusage data gathering])
 806   ;;
 807   "*")
 808   ;;
 809 esac
 810
 811 if test "$enable_rr_semantics" != "no" ; then
 812   AC_DEFINE([HAVE_V6_RR_SEMANTICS], [1], [Compile in v6 Route Replacement Semantics])
 813 fi
 814
 815 if test "$enable_datacenter" = "yes" ; then
 816   AC_DEFINE([HAVE_DATACENTER], [1], [Compile extensions for a DataCenter])
 817   DFLT_NAME="datacenter"
 818 else
 819   DFLT_NAME="traditional"
 820 fi
 821
 822 if test "$enable_cumulus" = "yes" ; then
 823   AC_DEFINE([HAVE_CUMULUS], [1], [Compile Special Cumulus Code in])
 824 fi
 825
 826 AC_SUBST([DFLT_NAME])
 827 AC_DEFINE_UNQUOTED([DFLT_NAME], ["$DFLT_NAME"], [Name of the configuration default set])
 828
 829 if test "$enable_shell_access" = "yes"; then
 830    AC_DEFINE([HAVE_SHELL_ACCESS], [1], [Allow user to use ssh/telnet/bash, be aware this is considered insecure])
 831 fi
 832
 833 #
 834 # Python for clippy
 835 #
 836
 837 AS_IF([test "$host" = "$build"], [
 838   AM_PATH_PYTHON([3])
 839   AC_CHECK_HEADER([gelf.h], [], [
 840     AC_MSG_ERROR([libelf headers are required for building clippy.  (Host only when cross-compiling.)])
 841   ])
 842
 843   LIBS_save="$LIBS"
 844   AC_CHECK_LIB([elf], [elf_memory], [], [
 845     AC_MSG_ERROR([libelf is required for building clippy.  (Host only when cross-compiling.)])
 846   ])
 847
 848   AC_CHECK_LIB([elf], [elf_getdata_rawchunk], [
 849     AC_DEFINE([HAVE_ELF_GETDATA_RAWCHUNK], [1], [Have elf_getdata_rawchunk()])
 850   ])
 851   AC_CHECK_LIB([elf], [gelf_getnote], [
 852     AC_DEFINE([HAVE_GELF_GETNOTE], [1], [Have gelf_getnote()])
 853   ])
 854   LIBS="$LIBS_save"
 855   unset LIBS_save
 856
 857   FRR_PYTHON_DEV
 858 ], [
 859   FRR_PYTHON
 860 ])
 861
 862 FRR_PYTHON_MODULES([pytest])
 863
 864 if test "$enable_doc" != "no"; then
 865   FRR_PYTHON_MODULES([sphinx], , [
 866     if test "$enable_doc" = "yes"; then
 867       AC_MSG_ERROR([Documentation was explicitly requested with --enable-doc but sphinx is not available for $PYTHON. Please disable docs or install sphinx.])
 868     fi
 869   ])
 870 fi
 871 AM_CONDITIONAL([DOC], [test "$enable_doc" != "no" -a "$frr_py_mod_sphinx" != "false"])
 872 AM_CONDITIONAL([DOC_HTML], [test "$enable_doc_html" = "yes"])
 873
 874 FRR_PYTHON_MOD_EXEC([sphinx], [--version], [
 875   PYSPHINX="-m sphinx"
 876 ], [
 877   PYSPHINX="-c 'import sys; from sphinx import main; sys.exit(main(sys.argv))'"
 878 ])
 879 AC_SUBST([PYSPHINX])
 880
 881 #
 882 # Logic for old vpn commands support.
 883 #
 884 if test "$enable_oldvpn_commands" = "yes"; then
 885    AC_DEFINE([KEEP_OLD_VPN_COMMANDS], [1], [Define for compiling with old vpn commands])
 886 fi
 887
 888 #
 889 # End of logic for protobuf support.
 890 #
 891
 892 AC_MSG_CHECKING([if zebra should be configurable to send Route Advertisements])
 893 if test "$enable_rtadv" != "no"; then
 894   AC_MSG_RESULT([yes])
 895   AC_DEFINE([HAVE_RTADV], [1], [Enable IPv6 Routing Advertisement support])
 896 else
 897   AC_MSG_RESULT([no])
 898 fi
 899
 900 if test "$enable_user" = "no"; then
 901   enable_user=""
 902 else
 903   if test "$enable_user" = "yes" || test "$enable_user" = ""; then
 904     enable_user="frr"
 905   fi
 906   AC_DEFINE_UNQUOTED([FRR_USER], ["${enable_user}"], [frr User])
 907 fi
 908
 909 if test "$enable_group" = "no"; then
 910   enable_group=""
 911 else
 912   if test "$enable_group" = "yes" || test "$enable_group" = ""; then
 913     enable_group="frr"
 914   fi
 915   AC_DEFINE_UNQUOTED([FRR_GROUP], ["${enable_group}"], [frr Group])
 916 fi
 917
 918 if test "$enable_vty_group" = "yes" ; then
 919   AC_MSG_ERROR([--enable-vty-group requires a group as argument, not yes])
 920 elif test "$enable_vty_group" != ""; then
 921   if test "$enable_vty_group" != "no"; then
 922     AC_DEFINE_UNQUOTED([VTY_GROUP], ["${enable_vty_group}"], [VTY Sockets Group])
 923   fi
 924 fi
 925 AC_SUBST([enable_user])
 926 AC_SUBST([enable_group])
 927 AC_SUBST([enable_vty_group])
 928
 929 enable_configfile_mask=${enable_configfile_mask:-0600}
 930 AC_DEFINE_UNQUOTED([CONFIGFILE_MASK], [${enable_configfile_mask}], [Mask for config files])
 931 AC_SUBST([enable_configfile_mask])
 932
 933 enable_logfile_mask=${enable_logfile_mask:-0600}
 934 AC_DEFINE_UNQUOTED([LOGFILE_MASK], [${enable_logfile_mask}], [Mask for log files])
 935
 936 MPATH_NUM=16
 937
 938 case "${enable_multipath}" in
 939   0)
 940     MPATH_NUM=64
 941     ;;
 942   [[1-9]|[1-9][0-9]|[1-9][0-9][0-9]])
 943     MPATH_NUM="${enable_multipath}"
 944     ;;
 945   "")
 946     ;;
 947   *)
 948     AC_MSG_FAILURE([Please specify digit to enable multipath ARG])
 949     ;;
 950 esac
 951
 952 AC_DEFINE_UNQUOTED([MULTIPATH_NUM], [$MPATH_NUM], [Maximum number of paths for a route])
 953
 954 AC_DEFINE_UNQUOTED([VTYSH_PAGER], ["$VTYSH_PAGER"], [What pager to use])
 955
 956
 957 TIMEOUT_MIN=2
 958 case "${with_service_timeout}" in
 959   [[1-9]|[1-9][0-9]|[1-9][0-9][0-9]])
 960     TIMEOUT_MIN="${with_service_timeout}"
 961     ;;
 962   0|"")
 963     ;;
 964   *)
 965     AC_MSG_FAILURE([Please specify digit for timeout ARG])
 966     ;;
 967 esac
 968 AC_SUBST([TIMEOUT_MIN])
 969
 970 dnl --------------------
 971 dnl Enable code coverage
 972 dnl --------------------
 973 AM_CONDITIONAL([HAVE_GCOV], [test "$enable_gcov" != "no"])
 974
 975 dnl ------------------------------------
 976 dnl Alpine only accepts numeric versions
 977 dnl ------------------------------------
 978 if test "$enable_numeric_version" != "" ; then
 979   VERSION="`echo ${VERSION} | tr -c -d '[[.0-9]]'`"
 980   PACKAGE_VERSION="`echo ${PACKAGE_VERSION} | tr -c -d '[[.0-9]]'`"
 981 fi
 982
 983 dnl -----------------------------------
 984 dnl Add extra version string to package
 985 dnl name, string and version fields.
 986 dnl -----------------------------------
 987 if test "$EXTRAVERSION" != "" ; then
 988   VERSION="${VERSION}${EXTRAVERSION}"
 989   PACKAGE_VERSION="${PACKAGE_VERSION}${EXTRAVERSION}"
 990   AC_SUBST(PACKAGE_EXTRAVERSION, ["${EXTRAVERSION}"])
 991   PACKAGE_STRING="${PACKAGE_STRING}${EXTRAVERSION}"
 992 fi
 993 AC_SUBST([EXTRAVERSION])
 994
 995 if test "$with_pkg_git_version" = "yes"; then
 996         if test -e "${srcdir}/.git"; then
 997                 AC_DEFINE([GIT_VERSION], [1], [include git version info])
 998         else    with_pkg_git_version="no"
 999                 AC_MSG_WARN([--with-pkg-git-version given, but this is not a git checkout])
1000         fi
1001 fi
1002 AM_CONDITIONAL([GIT_VERSION], [test "$with_pkg_git_version" = "yes"])
1003
1004 AC_CHECK_TOOL([OBJCOPY], [objcopy], [:])
1005 if test "$OBJCOPY" != ":"; then
1006   AC_CACHE_CHECK([for .interp value to use], [frr_cv_interp], [
1007     frr_cv_interp=""
1008     AC_LINK_IFELSE([AC_LANG_SOURCE([[int main() { return 0; }]])], [
1009       if $OBJCOPY -j.interp -Obinary conftest conftest.interp; then
1010         frr_cv_interp="`xargs -0 echo < conftest.interp`"
1011       fi
1012       test -f conftest.interp && rm conftest.interp
1013     ])
1014   ])
1015 fi
1016 if test -n "$frr_cv_interp"; then
1017   AC_DEFINE_UNQUOTED([INTERP], ["$frr_cv_interp"], [.interp value])
1018 fi
1019
1020 dnl -------------------------
1021 dnl Check other header files.
1022 dnl -------------------------
1023 AC_CHECK_HEADERS([stropts.h sys/ksym.h \
1024         linux/version.h asm/types.h endian.h sys/endian.h])
1025
1026 ac_stdatomic_ok=false
1027 AC_DEFINE([FRR_AUTOCONF_ATOMIC], [1], [did autoconf checks for atomic funcs])
1028 AC_CHECK_HEADER([stdatomic.h],[
1029
1030   AC_MSG_CHECKING([whether _Atomic qualifier works])
1031   AC_LINK_IFELSE([AC_LANG_SOURCE([[
1032 #include <stdatomic.h>
1033 int main(int argc, char **argv) {
1034   _Atomic int i = 0;
1035   return i;
1036 }
1037 ]])], [
1038     AC_DEFINE([HAVE_STDATOMIC_H], [1], [found stdatomic.h])
1039     AC_MSG_RESULT([yes])
1040     ac_stdatomic_ok=true
1041   ], [
1042     AC_MSG_RESULT([no])
1043   ])
1044 ])
1045
1046 AS_IF([$ac_stdatomic_ok], [true], [
1047   AC_MSG_CHECKING([for __atomic_* builtins])
1048   AC_LINK_IFELSE([AC_LANG_SOURCE([[
1049 int main(int argc, char **argv) {
1050   volatile int i = 1;
1051   __atomic_store_n (&i, 0, __ATOMIC_RELEASE);
1052   return __atomic_load_n (&i, __ATOMIC_ACQUIRE);
1053 }
1054 ]])], [
1055     AC_DEFINE([HAVE___ATOMIC], [1], [found __atomic builtins])
1056     AC_MSG_RESULT([yes])
1057   ], [
1058     AC_MSG_RESULT([no])
1059
1060     dnl FreeBSD 9 has a broken stdatomic.h where _Atomic doesn't work
1061     AC_MSG_CHECKING([for __sync_* builtins])
1062     AC_LINK_IFELSE([AC_LANG_SOURCE([[
1063 int main(int argc, char **argv) {
1064   volatile int i = 1;
1065   __sync_fetch_and_sub (&i, 1);
1066   return __sync_val_compare_and_swap (&i, 0, 1);
1067 }
1068 ]])], [
1069       AC_DEFINE([HAVE___SYNC], [1], [found __sync builtins])
1070       AC_MSG_RESULT([yes])
1071
1072       AC_MSG_CHECKING([for __sync_swap builtin])
1073       AC_LINK_IFELSE([AC_LANG_SOURCE([[
1074 int main(int argc, char **argv) {
1075   volatile int i = 1;
1076   return __sync_swap (&i, 2);
1077 }
1078 ]])], [
1079         AC_DEFINE([HAVE___SYNC_SWAP], 1, [found __sync_swap builtin])
1080         AC_MSG_RESULT([yes])
1081       ], [
1082         AC_MSG_RESULT([no])
1083       ])
1084
1085     ], [
1086       AC_MSG_RESULT([no])
1087       AC_MSG_FAILURE([stdatomic.h unavailable and $CC has neither __atomic nor __sync builtins])
1088     ])
1089   ])
1090 ])
1091
1092 needsync=true
1093
1094 AS_IF([$needsync], [
1095   dnl Linux
1096   AC_MSG_CHECKING([for Linux futex() support])
1097   AC_LINK_IFELSE([AC_LANG_PROGRAM([
1098 #ifndef _GNU_SOURCE
1099 #define _GNU_SOURCE
1100 #endif
1101 #include <unistd.h>
1102 #include <limits.h>
1103 #include <sys/time.h>
1104 #include <sys/syscall.h>
1105 #include <linux/futex.h>
1106
1107 int main(void);
1108 ],
1109 [
1110 {
1111   return syscall(SYS_futex, NULL, FUTEX_WAIT, 0, NULL, NULL, 0);
1112 }
1113 ])], [
1114     AC_MSG_RESULT([yes])
1115     AC_DEFINE(HAVE_SYNC_LINUX_FUTEX,,Have Linux futex support)
1116     needsync=false
1117   ], [
1118     AC_MSG_RESULT([no])
1119   ])
1120 ])
1121
1122 AS_IF([$needsync], [
1123   dnl FreeBSD
1124   AC_MSG_CHECKING([for FreeBSD _umtx_op() support])
1125   AC_LINK_IFELSE([AC_LANG_PROGRAM([
1126 #include <errno.h>
1127 #include <stdlib.h>
1128 #include <sys/types.h>
1129 #include <sys/umtx.h>
1130 int main(void);
1131 ],
1132 [
1133 {
1134   return _umtx_op(NULL, UMTX_OP_WAIT_UINT, 0, NULL, NULL);
1135 }
1136 ])], [
1137     AC_MSG_RESULT([yes])
1138     AC_DEFINE(HAVE_SYNC_UMTX_OP,,Have FreeBSD _umtx_op() support)
1139     needsync=false
1140   ], [
1141     AC_MSG_RESULT([no])
1142   ])
1143 ])
1144
1145 AS_IF([$needsync], [
1146   dnl OpenBSD patch (not upstream at the time of writing this)
1147   dnl https://marc.info/?l=openbsd-tech&m=147299508409549&w=2
1148   AC_MSG_CHECKING([for OpenBSD futex() support])
1149   AC_LINK_IFELSE([AC_LANG_PROGRAM([
1150 #include <sys/futex.h>
1151 int main(void);
1152 ],
1153 [
1154 {
1155   return futex(NULL, FUTEX_WAIT, 0, NULL, NULL, 0);
1156 }
1157 ])], [
1158     AC_MSG_RESULT([yes])
1159     AC_DEFINE(HAVE_SYNC_OPENBSD_FUTEX,,Have OpenBSD futex support)
1160     needsync=false
1161   ], [
1162     AC_MSG_RESULT([no])
1163   ])
1164 ])
1165
1166 dnl Utility macro to avoid retyping includes all the time
1167 m4_define([FRR_INCLUDES],
1168 [#ifdef SUNOS_5
1169 #define _POSIX_C_SOURCE 200809L
1170 #define __EXTENSIONS__
1171 #endif
1172 #include <stdio.h>
1173 #include <stdlib.h>
1174 #include <stddef.h>
1175 #include <sys/types.h>
1176 /* sys/conf.h depends on param.h on FBSD at least */
1177 #include <sys/param.h>
1178 /* Required for MAXSIG */
1179 #include <signal.h>
1180 #include <sys/socket.h>
1181 #ifdef __APPLE__
1182 # define __APPLE_USE_RFC_3542
1183 #endif
1184 #include <netinet/in.h>
1185 #include <sys/time.h>
1186 #include <time.h>
1187 #include <net/if.h>
1188 ])dnl
1189
1190 dnl Same applies for HAVE_NET_IF_VAR_H, which HAVE_NETINET6_ND6_H and
1191 dnl HAVE_NETINET_IN_VAR_H depend upon. But if_var.h depends on if.h, hence
1192 dnl an additional round for it.
1193
1194 AC_CHECK_HEADERS([net/if_var.h], [], [], [FRR_INCLUDES])
1195
1196 m4_define([FRR_INCLUDES],
1197 FRR_INCLUDES
1198 [#ifdef HAVE_NET_IF_VAR_H
1199 # include <net/if_var.h>
1200 #endif
1201 ])dnl
1202
1203 AC_CHECK_HEADERS([netinet/in_var.h \
1204         net/if_dl.h net/netopt.h \
1205         inet/nd.h netinet/ip_icmp.h \
1206         sys/sysctl.h sys/sockio.h sys/conf.h],
1207         [], [], [FRR_INCLUDES])
1208
1209 AC_CHECK_HEADERS([ucontext.h], [], [],
1210 [#ifndef __USE_GNU
1211 #define __USE_GNU
1212 #endif /* __USE_GNU */
1213 FRR_INCLUDES
1214 ])
1215
1216 m4_define([UCONTEXT_INCLUDES],
1217 [#include <ucontext.h>])dnl
1218
1219 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.uc_regs],
1220   [], [], [UCONTEXT_INCLUDES])
1221 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs],
1222   [AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs.nip],
1223    [], [], [UCONTEXT_INCLUDES])],
1224   [], [UCONTEXT_INCLUDES])
1225 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.gregs],
1226   [], [], [UCONTEXT_INCLUDES])
1227
1228 m4_define([FRR_INCLUDES],
1229 FRR_INCLUDES
1230 [
1231 #include <sys/un.h>
1232 #include <netinet/in_systm.h>
1233 #ifdef HAVE_NETINET_IN_VAR_H
1234 # include <netinet/in_var.h>
1235 #endif
1236 #ifdef HAVE_NET_IF_DL_H
1237 # include <net/if_dl.h>
1238 #endif
1239 #ifdef HAVE_NET_NETOPT_H
1240 # include <net/netopt.h>
1241 #endif
1242 #include <net/route.h>
1243 #ifdef HAVE_INET_ND_H
1244 # include <inet/nd.h>
1245 #endif
1246 #include <arpa/inet.h>
1247 /* Required for IDRP */
1248 #ifdef HAVE_NETINET_IP_ICMP_H
1249 # include <netinet/ip_icmp.h>
1250 #endif
1251 ])dnl
1252
1253 dnl V6 headers are checked below, after we check for v6
1254
1255 is_linux=false
1256
1257 AC_MSG_CHECKING([which operating system interface to use])
1258 case "$host_os" in
1259   sunos* | solaris2*)
1260     AC_MSG_FAILURE([Solaris support has been removed please see versions prior or equal to 7.5])
1261     ;;
1262   linux*)
1263     AC_MSG_RESULT([Linux])
1264
1265     AC_DEFINE([GNU_LINUX], [1], [GNU Linux])
1266     AC_DEFINE([HAVE_NETLINK], [1], [netlink])
1267     AC_DEFINE([LINUX_IPV6], [1], [Linux IPv6 stack])
1268
1269     dnl Linux has a compilation problem with mixing
1270     dnl netinet/in.h and linux/in6.h they are not
1271     dnl compatible.  There has been discussion on
1272     dnl how to fix it but no real progress on implementation
1273     dnl when they fix it, remove this
1274     AC_DEFINE([IPV6_MINHOPCOUNT], [73], [Linux ipv6 Min Hop Count])
1275
1276     is_linux=true
1277     ;;
1278   openbsd*)
1279     AC_MSG_RESULT([OpenBSD])
1280
1281     AC_DEFINE([OPEN_BSD], [1], [OpenBSD])
1282     AC_DEFINE([KAME], [1], [KAME IPv6])
1283     AC_DEFINE([BSD_V6_SYSCTL], [1], [BSD v6 sysctl to turn on and off forwarding])
1284     ;;
1285   *)
1286     AC_MSG_RESULT([BSD])
1287
1288     AC_DEFINE([HAVE_NET_RT_IFLIST], [1], [NET_RT_IFLIST])
1289     AC_DEFINE([KAME], [1], [KAME IPv6])
1290     AC_DEFINE([BSD_V6_SYSCTL], [1], [BSD v6 sysctl to turn on and off forwarding])
1291     ;;
1292 esac
1293 AM_CONDITIONAL([LINUX], [${is_linux}])
1294
1295 AC_SYS_LARGEFILE
1296
1297 dnl ------------------------
1298 dnl Integrated REALMS option
1299 dnl ------------------------
1300 if test "$enable_realms" = "yes"; then
1301     case "$host_os" in
1302       linux*)
1303        AC_DEFINE([SUPPORT_REALMS], [1], [Realms support])
1304        ;;
1305       *)
1306        echo "Sorry, only Linux has REALMS support"
1307        exit 1
1308        ;;
1309     esac
1310 fi
1311
1312 dnl ---------------
1313 dnl other functions
1314 dnl ---------------
1315 AC_CHECK_FUNCS([ \
1316         strlcat strlcpy \
1317         getgrouplist \
1318         openat \
1319         unlinkat \
1320         posix_fallocate \
1321         sendmmsg \
1322         explicit_bzero \
1323         ])
1324
1325 AC_CHECK_MEMBERS([struct mmsghdr.msg_hdr], [], [], FRR_INCLUDES)
1326
1327 dnl ##########################################################################
1328 dnl LARGE if block spans a lot of "configure"!
1329 if test "$enable_clippy_only" != "yes"; then
1330 dnl ##########################################################################
1331
1332 #
1333 # Logic for protobuf support.
1334 #
1335 PROTO3=false
1336 if test "$enable_protobuf" = "yes"; then
1337   # Check for protoc & protoc-c
1338
1339   # protoc is not required, it's only for a "be nice" helper target
1340   AC_CHECK_PROGS([PROTOC], [protoc], [/bin/false])
1341
1342   AC_CHECK_PROGS([PROTOC_C], [protoc-c], [/bin/false])
1343   if test "$PROTOC_C" = "/bin/false"; then
1344     AC_MSG_FAILURE([protobuf requested but protoc-c not found.  Install protobuf-c.])
1345   fi
1346
1347   PKG_CHECK_MODULES([PROTOBUF_C], [libprotobuf-c >= 0.14],, [
1348     AC_MSG_FAILURE([protobuf requested but libprotobuf-c not found.  Install protobuf-c.])
1349   ])
1350
1351   PROTO3=true
1352   AC_CHECK_HEADER([google/protobuf-c/protobuf-c.h],
1353                   [AC_CHECK_DECLS(PROTOBUF_C_LABEL_NONE,
1354                                   AC_DEFINE([HAVE_PROTOBUF_VERSION_3],
1355                                             [1], [Have Protobuf version 3]),
1356                                   [PROTO3=false],
1357                                   [#include <google/protobuf-c/protobuf-c.h>])],
1358                   [PROTO3=false && AC_MSG_FAILURE([protobuf requested but protobuf-c.h not found.  Install protobuf-c.])])
1359
1360   AC_DEFINE([HAVE_PROTOBUF], [1], [protobuf])
1361 fi
1362
1363
1364 dnl ---------------------
1365 dnl Integrated VTY option
1366 dnl ---------------------
1367 case "${enable_vtysh}" in
1368 "no")
1369   VTYSH="";;
1370 *)
1371   VTYSH="vtysh";
1372   AC_DEFINE([VTYSH], [1], [VTY shell])
1373
1374   prev_libs="$LIBS"
1375   AC_CHECK_LIB([readline], [readline], [
1376     LIBREADLINE="-lreadline"
1377   ], [
1378     dnl readline failed - it might be incorrectly linked and missing its
1379     dnl termcap/tinfo/curses dependency.  see if we can fix that...
1380     AC_SEARCH_LIBS([tputs], [termcap tinfo curses ncurses], [
1381       LIBREADLINE="$ac_cv_search_tputs"
1382     ], [
1383       AC_MSG_ERROR([libreadline (needed for vtysh) not found and/or missing dependencies])
1384     ])
1385
1386     dnl re-try with the lib we found above
1387     unset ac_cv_lib_readline_main
1388     AC_CHECK_LIB([readline], [main], [
1389       LIBREADLINE="-lreadline $LIBREADLINE"
1390     ], [
1391       AC_MSG_ERROR([libreadline (needed for vtysh) not found and/or missing dependencies])
1392     ], [$LIBREADLINE])
1393   ], [])
1394   LIBS="$LIBS -lreadline"
1395   AC_CHECK_FUNCS([rl_clear_visible_line])
1396   LIBS="$prev_libs"
1397
1398   AC_CHECK_HEADER([readline/history.h])
1399   if test "$ac_cv_header_readline_history_h" = "no"; then
1400     AC_MSG_ERROR([readline is too old to have readline/history.h, please update to the latest readline library.])
1401   fi
1402   AC_CHECK_LIB([readline], [rl_completion_matches], [true], [], [$LIBREADLINE])
1403   if test "$ac_cv_lib_readline_rl_completion_matches" = "no"; then
1404     AC_DEFINE([rl_completion_matches], [completion_matches], [Old readline])
1405   fi
1406   AC_CHECK_LIB([readline], [append_history], [frr_cv_append_history=yes], [frr_cv_append_history=no], [$LIBREADLINE])
1407   if test "$frr_cv_append_history" = "yes"; then
1408     AC_DEFINE([HAVE_APPEND_HISTORY], [1], [Have history.h append_history])
1409   fi
1410   ;;
1411 esac
1412 AC_SUBST([LIBREADLINE])
1413
1414 dnl ----------
1415 dnl PAM module
1416 dnl
1417 dnl FRR detects the PAM library it is built against by checking for a
1418 dnl functional pam_misc.h (Linux-PAM) or openpam.h (OpenPAM) header. pam_misc.h
1419 dnl is known to #include pam_appl.h, the standard header of a PAM library, and
1420 dnl openpam.h doesn't do that, although depends on the header too. Hence a
1421 dnl little assistance to AC_CHECK_HEADER is necessary for the proper detection
1422 dnl of OpenPAM.
1423 dnl ----------
1424 if test "$with_libpam" = "yes"; then
1425   AC_CHECK_HEADER([security/pam_misc.h],
1426     [AC_DEFINE([HAVE_PAM_MISC_H], [1], [Have pam_misc.h])
1427      AC_DEFINE([PAM_CONV_FUNC], [misc_conv], [Have misc_conv])
1428      pam_conv_func="misc_conv"
1429     ],
1430     [], FRR_INCLUDES)
1431   AC_CHECK_HEADER([security/openpam.h],
1432     [AC_DEFINE([HAVE_OPENPAM_H], [1], [Have openpam.h])
1433      AC_DEFINE([PAM_CONV_FUNC], [openpam_ttyconv], [Have openpam_ttyconv])
1434      pam_conv_func="openpam_ttyconv"
1435     ],
1436     [], FRR_INCLUDES[#include <security/pam_appl.h>])
1437   if test -z "$ac_cv_header_security_pam_misc_h$ac_cv_header_security_openpam_h" ; then
1438     AC_MSG_WARN([*** pam support will not be built ***])
1439     with_libpam="no"
1440   fi
1441 fi
1442
1443 if test "$with_libpam" = "yes"; then
1444 dnl took this test from proftpds configure.in and suited to our needs
1445 dnl -------------------------------------------------------------------------
1446 dnl
1447 dnl This next check looks funky due to a linker problem with some versions
1448 dnl of the PAM library.  Prior to 0.72 release, the Linux PAM shared library
1449 dnl omitted requiring libdl linking information. PAM-0.72 or better ships
1450 dnl with RedHat 6.2 and Debian 2.2 or better.
1451 AC_CHECK_LIB([pam], [pam_start],
1452   [AC_CHECK_LIB([pam], [$pam_conv_func],
1453     [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1454      LIBPAM="-lpam"],
1455     [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1456      LIBPAM="-lpam -lpam_misc"]
1457     )
1458   ],
1459
1460   [AC_CHECK_LIB([pam], [pam_end],
1461     [AC_CHECK_LIB([pam], [$pam_conv_func],
1462       [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1463        LIBPAM="-lpam -ldl"],
1464       [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1465        LIBPAM="-lpam -ldl -lpam_misc"]
1466      )
1467   ],AC_MSG_WARN([*** pam support will not be built ***]),
1468   [-ldl])
1469   ]
1470 )
1471 fi
1472 AC_SUBST([LIBPAM])
1473
1474 dnl -------------------------------
1475 dnl bgpd needs pow() and hence libm
1476 dnl -------------------------------
1477 TMPLIBS="$LIBS"
1478 LIBS=""
1479 AC_SEARCH_LIBS([pow], [m], [
1480   LIBM="$LIBS"
1481 ], [
1482   AC_MSG_WARN([Unable to find working pow function - bgpd may not link])
1483 ])
1484 LIBS="$TMPLIBS"
1485 AC_SUBST([LIBM])
1486
1487 AC_CHECK_FUNCS([ppoll], [
1488   AC_DEFINE([HAVE_PPOLL], [1], [have Linux/BSD ppoll()])
1489 ])
1490 AC_CHECK_FUNCS([pollts], [
1491   AC_DEFINE([HAVE_POLLTS], [1], [have NetBSD pollts()])
1492 ])
1493
1494 AC_CHECK_HEADER([asm-generic/unistd.h],
1495                 [AC_CHECK_DECL(__NR_setns,
1496                                AC_DEFINE([HAVE_NETNS], [1], [Have netns]),,
1497                                FRR_INCLUDES [#include <asm-generic/unistd.h>
1498                                ])
1499                  AC_CHECK_FUNCS([setns])]
1500                )
1501
1502 dnl --------------------------
1503 dnl Determine IS-IS I/O method
1504 dnl --------------------------
1505 AC_DEFINE([ISIS_METHOD_PFPACKET], [1], [constant value for isis method pfpacket])
1506 AC_DEFINE([ISIS_METHOD_DLPI], [2], [constant value for isis method dlpi])
1507 AC_DEFINE([ISIS_METHOD_BPF], [3], [constant value for isis method bpf])
1508 AC_CHECK_HEADER([net/bpf.h])
1509 AC_CHECK_HEADER([sys/dlpi.h])
1510 AC_MSG_CHECKING([zebra IS-IS I/O method])
1511
1512 case "$host_os" in
1513   linux*)
1514     AC_MSG_RESULT([pfpacket])
1515     ISIS_METHOD_MACRO="ISIS_METHOD_PFPACKET"
1516     ;;
1517   *)
1518     if test "$ac_cv_header_net_bpf_h" = "no"; then
1519       if test "$ac_cv_header_sys_dlpi_h" = "no"; then
1520         AC_MSG_RESULT([none])
1521         if test "$enable_isisd" = "yes" -o "$enable_fabricd" = "yes"; then
1522           AC_MSG_FAILURE([IS-IS support requested but no packet backend found])
1523         fi
1524         AC_MSG_WARN([*** IS-IS support will not be built ***])
1525         enable_isisd="no"
1526         enable_fabricd="no"
1527       else
1528         AC_MSG_RESULT([DLPI])
1529       fi
1530       ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1531     else
1532       AC_MSG_RESULT([BPF])
1533       ISIS_METHOD_MACRO="ISIS_METHOD_BPF"
1534     fi
1535     ;;
1536 esac
1537 AC_DEFINE_UNQUOTED([ISIS_METHOD], [$ISIS_METHOD_MACRO], [selected method for isis, == one of the constants])
1538
1539 dnl ---------------------------------------------------------------
1540 dnl figure out how to specify an interface in multicast sockets API
1541 dnl ---------------------------------------------------------------
1542 AC_CHECK_MEMBERS([struct ip_mreqn.imr_ifindex], [], [], FRR_INCLUDES)
1543
1544 AC_CHECK_HEADERS([linux/mroute.h], [], [],[
1545         #include <sys/socket.h>
1546         #include <netinet/in.h>
1547         #define _LINUX_IN_H             /* For Linux <= 2.6.25 */
1548         #include <linux/types.h>
1549 ])
1550
1551 AC_CHECK_HEADERS([linux/mroute6.h], [], [],[
1552         #include <sys/socket.h>
1553         #include <netinet/in.h>
1554         #define _LINUX_IN_H             /* For Linux <= 2.6.25 */
1555         #include <linux/types.h>
1556 ])
1557
1558 m4_define([FRR_INCLUDES],
1559 FRR_INCLUDES
1560 [#ifdef HAVE_LINUX_MROUTE_H
1561 # include <linux/mroute.h>
1562 #endif
1563 ])dnl
1564
1565 AC_CHECK_HEADERS([netinet/ip_mroute.h], [], [],[
1566         #include <sys/socket.h>
1567         #include <sys/types.h>
1568         #include <netinet/in.h>
1569         #include <net/route.h>
1570 ])
1571
1572 m4_define([FRR_INCLUDES],
1573 FRR_INCLUDES
1574 [#ifdef HAVE_NETINET_IP_MROUTE_H
1575 # include <netinet/ip_mroute.h>
1576 #endif
1577 ])dnl
1578
1579 AC_MSG_CHECKING([for RFC3678 protocol-independed API])
1580 AC_COMPILE_IFELSE(
1581 [ AC_LANG_PROGRAM([[
1582       #include <sys/types.h>
1583       #include <netinet/in.h>
1584   ]], [[
1585       struct group_req gr;
1586       int sock;
1587       setsockopt(sock, IPPROTO_IP, MCAST_JOIN_GROUP, (void*)&gr, sizeof(gr));
1588   ]])
1589 ],[
1590   AC_MSG_RESULT([yes])
1591   AC_DEFINE([HAVE_RFC3678], [1], [Have RFC3678 protocol-independed API])
1592 ],[
1593   AC_MSG_RESULT(no)
1594 ])
1595
1596 dnl ---------------------------------------------------------------
1597 dnl figure out how to check link-state
1598 dnl ---------------------------------------------------------------
1599 AC_CHECK_HEADER([net/if_media.h],
1600   [m4_define([LINK_DETECT_INCLUDES],
1601     FRR_INCLUDES
1602     [#include <net/if_media.h>
1603   ])
1604   AC_CHECK_MEMBERS([struct ifmediareq.ifm_status],
1605     AC_DEFINE([HAVE_BSD_LINK_DETECT], [1], [BSD link-detect]),
1606     [], LINK_DETECT_INCLUDES)],
1607   [],
1608   FRR_INCLUDES)
1609
1610 dnl ---------------------------------------------------------------
1611 dnl Additional, newer way to check link-state using ifi_link_state.
1612 dnl Not available in all BSD's when ifmediareq available
1613 dnl ---------------------------------------------------------------
1614 AC_CHECK_MEMBERS([struct if_data.ifi_link_state],
1615   AC_DEFINE([HAVE_BSD_IFI_LINK_STATE], [1], [BSD ifi_link_state available]),
1616   [], FRR_INCLUDES)
1617
1618 dnl ------------------------
1619 dnl TCP_MD5SIG socket option
1620 dnl ------------------------
1621
1622 AC_CHECK_HEADER([netinet/tcp.h],
1623    [m4_define([MD5_INCLUDES],
1624       FRR_INCLUDES
1625       [#include <netinet/tcp.h>
1626     ])
1627     AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)],
1628    [],
1629    FRR_INCLUDES)
1630 if test "$ac_cv_have_decl_TCP_MD5SIG" = "no"; then
1631   AC_CHECK_HEADER([linux/tcp.h],
1632        [m4_define([MD5_INCLUDES],
1633           FRR_INCLUDES
1634           [#include <linux/tcp.h>
1635         ])
1636        AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)])
1637 fi
1638
1639 LIBS_save="$LIBS"
1640 AC_CHECK_LIB([crypt], [crypt], [], [
1641   AC_CHECK_LIB([crypto], [DES_crypt])
1642 ])
1643 LIBCRYPT="$LIBS"
1644 LIBCRYPT="${LIBCRYPT%$LIBS_save}"
1645 LIBCRYPT="${LIBCRYPT#$LIBS_save}"
1646 AC_SUBST([LIBCRYPT])
1647 LIBS="$LIBS_save"
1648 unset LIBS_save
1649
1650 AC_CHECK_LIB([resolv], [res_init])
1651
1652 dnl ---------------------------
1653 dnl check system has PCRE regexp
1654 dnl ---------------------------
1655 if test "$enable_pcreposix" = "yes"; then
1656   AC_CHECK_LIB([pcreposix], [regexec], [], [
1657     AC_MSG_ERROR([--enable-pcreposix given but unable to find libpcreposix])
1658   ])
1659 fi
1660 AC_SUBST([HAVE_LIBPCREPOSIX])
1661
1662 dnl ##########################################################################
1663 dnl test "$enable_clippy_only" != "yes"
1664 fi
1665 dnl END OF LARGE if block
1666 dnl ##########################################################################
1667
1668 dnl ------------------
1669 dnl check C-Ares library
1670 dnl ------------------
1671 PKG_CHECK_MODULES([CARES], [libcares], [
1672   c_ares_found=true
1673 ],[
1674   c_ares_found=false
1675 ])
1676 AM_CONDITIONAL([CARES], [$c_ares_found])
1677
1678
1679 dnl ----------------------------------------------------------------------------
1680 dnl figure out if domainname is available in the utsname struct (GNU extension).
1681 dnl ----------------------------------------------------------------------------
1682 AC_CHECK_MEMBERS([struct utsname.domainname], [], [], [#include <sys/utsname.h>])
1683
1684 dnl ------------------
1685 dnl IPv6 header checks
1686 dnl ------------------
1687 AC_CHECK_HEADERS([netinet6/in6.h netinet/in6_var.h \
1688         netinet6/in6_var.h netinet6/nd6.h], [], [],
1689         FRR_INCLUDES)
1690
1691 m4_define([FRR_INCLUDES],dnl
1692 FRR_INCLUDES
1693 [#ifdef HAVE_NETINET6_IN6_H
1694 #include <netinet6/in6.h>
1695 #endif
1696 #ifdef HAVE_NETINET_IN6_VAR_H
1697 #include <netinet/in6_var.h>
1698 #endif
1699 #include <netinet/icmp6.h>
1700 #ifdef HAVE_NETINET6_IN6_VAR_H
1701 # include <netinet6/in6_var.h>
1702 #endif
1703 #ifdef HAVE_NETINET6_ND6_H
1704 # include <netinet6/nd6.h>
1705 #endif
1706 ])dnl
1707
1708 dnl --------------------
1709 dnl Daemon disable check
1710 dnl --------------------
1711
1712 AS_IF([test "$enable_bgpd" != "no"], [
1713   AC_DEFINE([HAVE_BGPD], [1], [bgpd])
1714 ])
1715
1716 AS_IF([test "$enable_ripd" != "no"], [
1717   AC_DEFINE([HAVE_RIPD], [1], [ripd])
1718 ])
1719
1720 AS_IF([test "$enable_ripngd" != "no"], [
1721   AC_DEFINE([HAVE_RIPNGD], [1], [ripngd])
1722 ])
1723
1724 AS_IF([test "$enable_ospfd" != "no"], [
1725   AC_DEFINE([HAVE_OSPFD], [1], [ospfd])
1726 ])
1727
1728 AS_IF([test "$enable_ospf6d" != "no"], [
1729   AC_DEFINE([HAVE_OSPF6D], [1], [ospf6d])
1730 ])
1731
1732 AS_IF([test "$enable_ldpd" != "no"], [
1733   AC_DEFINE([HAVE_LDPD], [1], [ldpd])
1734 ])
1735
1736 AS_IF([test "$enable_nhrpd" != "no"], [
1737   AC_DEFINE([HAVE_NHRPD], [1], [nhrpd])
1738 ])
1739
1740 AS_IF([test "$enable_eigrpd" != "no"], [
1741   AC_DEFINE([HAVE_EIGRPD], [1], [eigrpd])
1742 ])
1743
1744 AS_IF([test "$enable_babeld" != "no"], [
1745   AC_DEFINE([HAVE_BABELD], [1], [babeld])
1746 ])
1747
1748 AS_IF([test "$enable_isisd" != "no"], [
1749   AC_DEFINE([HAVE_ISISD], [1], [isisd])
1750 ])
1751
1752 AS_IF([test "$enable_pimd" != "no"], [
1753   AC_DEFINE([HAVE_PIMD], [1], [pimd])
1754 ])
1755
1756 AS_IF([test "$enable_pim6d" = "yes"], [
1757   AC_DEFINE([HAVE_PIM6D], [1], [pim6d])
1758 ])
1759
1760 AS_IF([test "$enable_pbrd" != "no"], [
1761   AC_DEFINE([HAVE_PBRD], [1], [pbrd])
1762 ])
1763
1764 AS_IF([test "$enable_sharpd" = "yes"], [
1765   AC_DEFINE([HAVE_SHARPD], [1], [sharpd])
1766 ])
1767
1768 AS_IF([test "$enable_staticd" != "no"], [
1769   AC_DEFINE([HAVE_STATICD], [1], [staticd])
1770 ])
1771
1772 AS_IF([test "$enable_fabricd" != "no"], [
1773   AC_DEFINE([HAVE_FABRICD], [1], [fabricd])
1774 ])
1775
1776 AS_IF([test "$enable_vrrpd" != "no"], [
1777   AC_DEFINE([HAVE_VRRPD], [1], [vrrpd])
1778 ])
1779
1780 if test "$enable_bfdd" = "no"; then
1781   AC_DEFINE([HAVE_BFDD], [0], [bfdd])
1782   BFDD=""
1783 else
1784   AC_DEFINE([HAVE_BFDD], [1], [bfdd])
1785   BFDD="bfdd"
1786
1787   case $host_os in
1788     linux*)
1789       AC_DEFINE([BFD_LINUX], [1], [bfdd])
1790       ;;
1791
1792     *)
1793       AC_DEFINE([BFD_BSD], [1], [bfdd])
1794       ;;
1795   esac
1796 fi
1797
1798 AS_IF([test "$enable_pathd" != "no"], [
1799   AC_DEFINE([HAVE_PATHD], [1], [pathd])
1800 ])
1801
1802 if test "$ac_cv_lib_json_c_json_object_get" = "no" -a "$BFDD" = "bfdd"; then
1803   AC_MSG_ERROR(["you must use json-c library to use bfdd"])
1804 fi
1805
1806 NHRPD=""
1807 case "$host_os" in
1808   linux*)
1809     case "${enable_nhrpd}" in
1810       no)
1811         ;;
1812       yes)
1813         if test "$enable_clippy_only" != "yes"; then
1814         if test "$c_ares_found" != "true" ; then
1815           AC_MSG_ERROR([nhrpd requires libcares.  Please install c-ares and its -dev headers.])
1816         fi
1817         fi
1818         NHRPD="nhrpd"
1819         ;;
1820       *)
1821         if test "$c_ares_found" = "true" ; then
1822           NHRPD="nhrpd"
1823         fi
1824         ;;
1825     esac
1826     ;;
1827   *)
1828     if test "$enable_nhrpd" = "yes"; then
1829       AC_MSG_ERROR([nhrpd requires kernel APIs that are only present on Linux.])
1830     fi
1831     ;;
1832 esac
1833
1834 if test "$enable_watchfrr" = "no";then
1835   WATCHFRR=""
1836 else
1837   WATCHFRR="watchfrr"
1838 fi
1839
1840 OSPFCLIENT=""
1841 if test "$enable_ospfapi" != "no";then
1842     AC_DEFINE([SUPPORT_OSPF_API], [1], [OSPFAPI])
1843
1844   if test "$enable_ospfclient" != "no";then
1845       OSPFCLIENT="ospfclient"
1846   fi
1847 fi
1848
1849 if test "$enable_bgp_announce" = "no";then
1850   AC_DEFINE([DISABLE_BGP_ANNOUNCE], [1], [Disable BGP installation to zebra])
1851 else
1852   AC_DEFINE([DISABLE_BGP_ANNOUNCE], [0], [Disable BGP installation to zebra])
1853 fi
1854
1855 if test "$enable_bgp_vnc" != "no";then
1856   AC_DEFINE([ENABLE_BGP_VNC], [1], [Enable BGP VNC support])
1857 fi
1858
1859 bgpd_bmp=false
1860 case "${enable_bgp_bmp}" in
1861   no)
1862     ;;
1863   yes)
1864     if test "$c_ares_found" != "true" ; then
1865       AC_MSG_ERROR([BMP support requires libcares.  Please install c-ares and its -dev headers.])
1866     fi
1867     bgpd_bmp=true
1868     ;;
1869   *)
1870     if test "$c_ares_found" = "true" ; then
1871       bgpd_bmp=true
1872     fi
1873     ;;
1874 esac
1875
1876 if test "$enable_version_build_config" != "no";then
1877   AC_DEFINE([ENABLE_VERSION_BUILD_CONFIG], [1], [Report build configs in show version])
1878 fi
1879
1880 dnl ##########################################################################
1881 dnl LARGE if block
1882 if test "$enable_clippy_only" != "yes"; then
1883 dnl ##########################################################################
1884
1885 dnl ------------------
1886 dnl check Net-SNMP library
1887 dnl ------------------
1888 if test "$enable_snmp" != "" -a "$enable_snmp" != "no"; then
1889    AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], [no])
1890    if test "$NETSNMP_CONFIG" = "no"; then
1891       AC_MSG_ERROR([--enable-snmp given but unable to find net-snmp-config])
1892    fi
1893    SNMP_LIBS="`${NETSNMP_CONFIG} --agent-libs`"
1894    SNMP_CFLAGS="`${NETSNMP_CONFIG} --base-cflags`"
1895    # net-snmp lists all of its own dependencies.  we absolutely do not want that
1896    # among other things we avoid a GPL vs. OpenSSL license conflict here
1897    for removelib in crypto ssl sensors pci wrap; do
1898      SNMP_LIBS="`echo $SNMP_LIBS | sed -e 's/\(^\|\s\)-l'$removelib'\b/ /g' -e 's/\(^\|\s\)\([^\s]*\/\)\?lib'$removelib'\.[^\s]\+\b/ /g'`"
1899    done
1900    AC_MSG_CHECKING([whether we can link to Net-SNMP])
1901    AC_LINK_IFELSE_FLAGS([$SNMP_CFLAGS], [$SNMP_LIBS], [AC_LANG_PROGRAM([
1902 int main(void);
1903 ],
1904 [
1905 {
1906   return 0;
1907 }
1908 ])], [
1909      AC_MSG_RESULT([no])
1910      AC_MSG_ERROR([--enable-snmp given but not usable])])
1911    case "${enable_snmp}" in
1912      yes)
1913       SNMP_METHOD=agentx
1914       ;;
1915      agentx)
1916       SNMP_METHOD="${enable_snmp}"
1917       ;;
1918      *)
1919       AC_MSG_ERROR([--enable-snmp given with an unknown method (${enable_snmp}). Use yes or agentx])
1920       ;;
1921    esac
1922    AH_TEMPLATE([SNMP_AGENTX], [Use SNMP AgentX to interface with snmpd])
1923    AC_DEFINE_UNQUOTED(AS_TR_CPP(SNMP_${SNMP_METHOD}),,[SNMP method to interface with snmpd])
1924 fi
1925 AC_SUBST([SNMP_LIBS])
1926 AC_SUBST([SNMP_CFLAGS])
1927
1928 dnl ---------------
1929 dnl libyang
1930 dnl ---------------
1931 PKG_CHECK_MODULES([LIBYANG], [libyang >= 2.0.0], , [
1932   AC_MSG_ERROR([libyang (>= 2.0.0) was not found on your system.])
1933 ])
1934 ac_cflags_save="$CFLAGS"
1935 CFLAGS="$CFLAGS $LIBYANG_CFLAGS"
1936 AC_CHECK_MEMBER([struct lyd_node.priv], [], [
1937   AC_MSG_ERROR([m4_normalize([
1938     libyang needs to be compiled with ENABLE_LYD_PRIV=ON.
1939     Instructions for this are included in the build documentation for your platform at http://docs.frrouting.org/projects/dev-guide/en/latest/building.html])
1940   ])
1941 ], [[#include <libyang/libyang.h>]])
1942 CFLAGS="$ac_cflags_save"
1943
1944 dnl ---------------
1945 dnl configuration rollbacks
1946 dnl ---------------
1947 SQLITE3=false
1948 if test "$enable_config_rollbacks" = "yes"; then
1949   PKG_CHECK_MODULES([SQLITE3], [sqlite3], [
1950     AC_DEFINE([HAVE_CONFIG_ROLLBACKS], [1], [Enable configuration rollbacks])
1951     AC_DEFINE([HAVE_SQLITE3], [1], [Enable sqlite3 database])
1952     SQLITE3=true
1953   ], [
1954     AC_MSG_ERROR([--enable-config-rollbacks given but sqlite3 was not found on your system.])
1955   ])
1956 fi
1957
1958 dnl ---------------
1959 dnl confd
1960 dnl ---------------
1961 if test "$enable_confd" != "" -a "$enable_confd" != "no"; then
1962    AC_CHECK_PROG([CONFD], [confd], [confd], [/bin/false], "${enable_confd}/bin")
1963    if test "$CONFD" = "/bin/false"; then
1964       AC_MSG_ERROR([confd was not found on your system.])]
1965    fi
1966    AC_CHECK_PROG([CONFDC], [confdc], [confdc], [/bin/false], "${enable_confd}/bin")
1967    CONFD_CFLAGS="-I${enable_confd}/include -L${enable_confd}/lib"
1968    AC_SUBST([CONFD_CFLAGS])
1969    CONFD_LIBS="-lconfd"
1970    AC_SUBST([CONFD_LIBS])
1971    AC_DEFINE([HAVE_CONFD], [1], [Enable confd integration])
1972 fi
1973
1974 dnl ---------------
1975 dnl sysrepo
1976 dnl ---------------
1977 if test "$enable_sysrepo" = "yes"; then
1978   PKG_CHECK_MODULES([SYSREPO], [sysrepo >= 2.1.42],
1979       [AC_DEFINE([HAVE_SYSREPO], [1], [Enable sysrepo integration])
1980       SYSREPO=true],
1981       [SYSREPO=false
1982       AC_MSG_ERROR([sysrepo was not found on your system.])]
1983   )
1984 fi
1985
1986 dnl ---------------
1987 dnl gRPC
1988 dnl ---------------
1989 if test "$enable_grpc" = "yes"; then
1990   AC_LANG_PUSH([C++])
1991   AX_CXX_COMPILE_STDCXX([11], [ext])
1992   PKG_CHECK_MODULES([GRPC], [grpc >= 6.0.0 grpc++ >= 1.16.1 protobuf >= 3.6.1 ], [
1993     AC_CHECK_PROGS([PROTOC], [protoc], [/bin/false])
1994     if test "$PROTOC" = "/bin/false"; then
1995       AC_MSG_FAILURE([grpc requested but protoc not found.])
1996     fi
1997
1998     AC_DEFINE([HAVE_GRPC], [1], [Enable the gRPC northbound plugin])
1999     GRPC=true
2000   ], [
2001     GRPC=false
2002     AC_MSG_ERROR([grpc/grpc++ were not found on your system.])
2003   ])
2004   AC_LANG_POP([C++])
2005 fi
2006
2007 dnl ---------
2008 dnl DPDK
2009 dnl ---------
2010 if test "$enable_dp_dpdk" = "yes"; then
2011   PKG_CHECK_MODULES([DPDK], [libdpdk], [
2012     AC_DEFINE([HAVE_DPDK], [1], [Enable DPDK backend])
2013     DPDK=true
2014   ], [
2015     AC_MSG_ERROR([configuration specifies --enable-dp-dpdk but DPDK libs were not found])
2016   ])
2017 fi
2018
2019 dnl -----
2020 dnl LTTng
2021 dnl -----
2022 if test "$enable_lttng" = "yes"; then
2023   PKG_CHECK_MODULES([UST], [lttng-ust >= 2.9.0], [
2024     AC_DEFINE([HAVE_LTTNG], [1], [Enable LTTng support])
2025     LTTNG=true
2026   ], [
2027     AC_MSG_ERROR([configuration specifies --enable-lttng but lttng-ust was not found])
2028   ])
2029 fi
2030
2031 dnl ----
2032 dnl USDT
2033 dnl ----
2034 if test "$enable_usdt" = "yes"; then
2035   AC_CHECK_HEADERS([sys/sdt.h], [
2036     AC_DEFINE([HAVE_USDT], [1], [Enable USDT probes])
2037     USDT=true
2038   ], [
2039     AC_MSG_ERROR([configuration specifies --enable-usdt but no USDT kernel headers (sys/sdt.h) found])
2040   ])
2041 fi
2042
2043 dnl ------
2044 dnl ZeroMQ
2045 dnl ------
2046 if test "$enable_zeromq" != "no"; then
2047   PKG_CHECK_MODULES([ZEROMQ], [libzmq >= 4.0.0], [
2048     AC_DEFINE([HAVE_ZEROMQ], [1], [Enable ZeroMQ support])
2049     ZEROMQ=true
2050   ], [
2051     if test "$enable_zeromq" = "yes"; then
2052       AC_MSG_ERROR([configuration specifies --enable-zeromq but libzmq was not found])
2053     fi
2054   ])
2055 fi
2056
2057 dnl ------------------------------------
2058 dnl Enable RPKI and add librtr to libs
2059 dnl ------------------------------------
2060 if test "$enable_rpki" = "yes"; then
2061   PKG_CHECK_MODULES([RTRLIB], [rtrlib >= 0.8.0],
2062       [RPKI=true],
2063       [RPKI=false
2064       AC_MSG_ERROR([rtrlib was not found on your system or is too old.])]
2065   )
2066 fi
2067
2068 dnl ------------------------------------
2069 dnl pimd is not supported on OpenBSD and MacOS
2070 dnl ------------------------------------
2071 if test "$enable_pimd" != "no"; then
2072 AC_MSG_CHECKING([for pimd OS support])
2073 case "$host_os" in
2074   darwin*)
2075     AC_MSG_RESULT([no])
2076     enable_pimd="no"
2077     ;;
2078   openbsd*)
2079     AC_MSG_RESULT([no])
2080     enable_pimd="no"
2081     ;;
2082   *)
2083     AC_MSG_RESULT([yes])
2084     ;;
2085 esac
2086 fi
2087
2088 dnl -------------------------------------
2089 dnl VRRP is only supported on linux
2090 dnl -------------------------------------
2091 if test "$enable_vrrpd" != "no"; then
2092 AC_MSG_CHECKING([for VRRP OS support])
2093 case "$host_os" in
2094   linux*)
2095     AC_MSG_RESULT([yes])
2096     ;;
2097   *)
2098     AC_MSG_RESULT([no])
2099     enable_vrrpd="no"
2100     ;;
2101 esac
2102 fi
2103
2104 dnl ------------------------------------------
2105 dnl Check whether rtrlib was build with ssh support
2106 dnl ------------------------------------------
2107 AC_MSG_CHECKING([whether the RTR Library is compiled with SSH])
2108 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "rtrlib/rtrlib.h"]],
2109                         [[struct tr_ssh_config config;]])],
2110         [AC_MSG_RESULT([yes])
2111         AC_DEFINE([FOUND_SSH], [1], [found_ssh])],
2112         AC_MSG_RESULT([no])
2113 )
2114
2115 dnl ---------------
2116 dnl dlopen & dlinfo
2117 dnl ---------------
2118 LIBS_save="$LIBS"
2119 AC_SEARCH_LIBS([dlopen], [dl dld], [], [
2120   AC_MSG_ERROR([unable to find the dlopen()])
2121 ])
2122
2123 AC_CHECK_HEADERS([link.h])
2124
2125 AC_CACHE_CHECK([for dlinfo(RTLD_DI_ORIGIN)], [frr_cv_rtld_di_origin], [
2126   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2127 #include <stdlib.h>
2128 #ifdef HAVE_LINK_H
2129 #include <link.h>
2130 #endif
2131 #include <dlfcn.h>
2132 ]], [[
2133   char origin[1];
2134   dlinfo (NULL, RTLD_DI_ORIGIN, &origin);
2135 ]])], [
2136     frr_cv_rtld_di_origin=yes
2137   ], [
2138     frr_cv_rtld_di_origin=no
2139   ])
2140 ])
2141 if test "$frr_cv_rtld_di_origin" = "yes"; then
2142   AC_DEFINE([HAVE_DLINFO_ORIGIN], [1], [Have dlinfo RTLD_DI_ORIGIN])
2143 fi
2144
2145 AC_CACHE_CHECK([for dlinfo(RTLD_DI_LINKMAP)], [frr_cv_rtld_di_linkmap], [
2146   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2147 #include <stdlib.h>
2148 #ifdef HAVE_LINK_H
2149 #include <link.h>
2150 #endif
2151 #include <dlfcn.h>
2152 ]], [[
2153   struct link_map *lm = NULL;
2154   dlinfo (NULL, RTLD_DI_LINKMAP, &lm);
2155 ]])], [
2156     frr_cv_rtld_di_linkmap=yes
2157   ], [
2158     frr_cv_rtld_di_linkmap=no
2159   ])
2160 ])
2161 if test "$frr_cv_rtld_di_linkmap" = "yes"; then
2162   AC_DEFINE([HAVE_DLINFO_LINKMAP], [1], [Have dlinfo RTLD_DI_LINKMAP])
2163 fi
2164
2165 LIBDL="$LIBS"
2166 LIBDL="${LIBDL%$LIBS_save}"
2167 LIBDL="${LIBDL#$LIBS_save}"
2168 AC_SUBST([LIBDL])
2169 LIBS="$LIBS_save"
2170 unset LIBS_save
2171
2172 dnl ##########################################################################
2173 dnl test "$enable_clippy_only" != "yes"
2174 fi
2175 dnl END OF LARGE if block
2176 dnl ##########################################################################
2177
2178 dnl ---------------------------
2179 dnl sockaddr and netinet checks
2180 dnl ---------------------------
2181 AC_CHECK_TYPES([
2182         struct sockaddr_dl,
2183         struct vifctl, struct mfcctl, struct sioc_sg_req,
2184         vifi_t, struct sioc_vif_req, struct igmpmsg,
2185         struct ifaliasreq, struct if6_aliasreq, struct in6_aliasreq,
2186         struct nd_opt_adv_interval,
2187         struct nd_opt_homeagent_info, struct nd_opt_adv_interval,
2188         struct nd_opt_rdnss, struct nd_opt_dnssl],
2189         [], [], FRR_INCLUDES)
2190
2191 AC_CHECK_MEMBERS([struct sockaddr.sa_len,
2192         struct sockaddr_in.sin_len, struct sockaddr_un.sun_len,
2193         struct sockaddr_dl.sdl_len,
2194         struct if6_aliasreq.ifra_lifetime,
2195         struct nd_opt_adv_interval.nd_opt_ai_type],
2196         [], [], FRR_INCLUDES)
2197
2198 dnl ---------------------------
2199 dnl IRDP/pktinfo/icmphdr checks
2200 dnl ---------------------------
2201
2202 AC_CHECK_TYPES([struct in_pktinfo], [
2203   AC_CHECK_TYPES([struct icmphdr], [
2204     IRDP=true
2205   ], [
2206     IRDP=false
2207   ], [FRR_INCLUDES])
2208 ], [
2209   IRDP=false
2210 ], [FRR_INCLUDES])
2211
2212 case "${enable_irdp}" in
2213 yes)
2214   $IRDP || AC_MSG_ERROR(['IRDP requires in_pktinfo at the moment!'])
2215   ;;
2216 no)
2217   IRDP=false
2218   ;;
2219 esac
2220
2221
2222 dnl -----------------------
2223 dnl checking for IP_PKTINFO
2224 dnl -----------------------
2225 AC_MSG_CHECKING([for IP_PKTINFO])
2226 AC_COMPILE_IFELSE(
2227 [ AC_LANG_PROGRAM([[
2228         #include <netdb.h>
2229    ]], [[
2230         int opt = IP_PKTINFO;
2231    ]])
2232 ],[
2233   AC_MSG_RESULT([yes])
2234   AC_DEFINE([HAVE_IP_PKTINFO], [1], [Have IP_PKTINFO])
2235 ],[
2236   AC_MSG_RESULT([no])
2237 ])
2238
2239 dnl ---------------------------
2240 dnl checking for IP_RECVDSTADDR
2241 dnl ---------------------------
2242 AC_MSG_CHECKING([for IP_RECVDSTADDR])
2243 AC_COMPILE_IFELSE(
2244 [ AC_LANG_PROGRAM([[
2245         #include <netinet/in.h>
2246   ]], [[
2247         int opt = IP_RECVDSTADDR;
2248   ]])
2249 ],[
2250   AC_MSG_RESULT([yes])
2251   AC_DEFINE([HAVE_IP_RECVDSTADDR], [1], [Have IP_RECVDSTADDR])
2252 ],[
2253   AC_MSG_RESULT([no])
2254 ])
2255
2256 dnl ----------------------
2257 dnl checking for IP_RECVIF
2258 dnl ----------------------
2259 AC_MSG_CHECKING([for IP_RECVIF])
2260 AC_COMPILE_IFELSE(
2261 [ AC_LANG_PROGRAM([[
2262         #include <netinet/in.h>
2263   ]], [[
2264         int opt = IP_RECVIF;
2265   ]])
2266 ],[
2267   AC_MSG_RESULT([yes])
2268   AC_DEFINE([HAVE_IP_RECVIF], [1], [Have IP_RECVIF])
2269 ],[
2270   AC_MSG_RESULT([no])
2271 ])
2272
2273 dnl ----------------------
2274 dnl checking for SO_BINDANY
2275 dnl ----------------------
2276 AC_MSG_CHECKING([for SO_BINDANY])
2277 AC_COMPILE_IFELSE(
2278 [ AC_LANG_PROGRAM([[
2279         #include <sys/socket.h>
2280   ]], [[
2281         int opt = SO_BINDANY;
2282   ]])
2283 ],[
2284   AC_MSG_RESULT([yes])
2285   AC_DEFINE([HAVE_SO_BINDANY], [1], [Have SO_BINDANY])
2286 ],[
2287   AC_MSG_RESULT([no])
2288 ])
2289
2290 dnl ----------------------
2291 dnl checking for IP_FREEBIND
2292 dnl ----------------------
2293 AC_MSG_CHECKING([for IP_FREEBIND])
2294 AC_COMPILE_IFELSE(
2295 [ AC_LANG_PROGRAM([[
2296         #include <netinet/in.h>
2297   ]], [[
2298         int opt = IP_FREEBIND;
2299   ]])
2300 ],[
2301   AC_MSG_RESULT([yes])
2302   AC_DEFINE([HAVE_IP_FREEBIND], [1], [Have IP_FREEBIND])
2303 ],[
2304   AC_MSG_RESULT([no])
2305 ])
2306
2307 dnl --------------------------------------
2308 dnl checking for be32dec existence or not
2309 dnl --------------------------------------
2310 AC_CHECK_DECLS([be32enc, be32dec], [], [], [
2311         #ifdef HAVE_SYS_ENDIAN_H
2312         #include <sys/endian.h>
2313         #endif
2314         #ifdef HAVE_ENDIAN_H
2315         #include <endian.h>
2316         #endif
2317 ])
2318
2319 dnl --------------------------------------
2320 dnl checking for clock_time monotonic struct and call
2321 dnl --------------------------------------
2322 AC_CHECK_DECL([CLOCK_MONOTONIC],
2323         [AC_CHECK_LIB([rt], [clock_gettime], [LIBS="$LIBS -lrt"])
2324          AC_DEFINE([HAVE_CLOCK_MONOTONIC], [1], [Have monotonic clock])
2325 ], [AC_MSG_RESULT([no])], [FRR_INCLUDES])
2326
2327 AC_CHECK_DECL([CLOCK_THREAD_CPUTIME_ID], [
2328          AC_DEFINE([HAVE_CLOCK_THREAD_CPUTIME_ID], [1], [Have cpu-time clock])
2329 ], [AC_MSG_RESULT([no])], [FRR_INCLUDES])
2330
2331 AC_SEARCH_LIBS([clock_nanosleep], [rt], [
2332   AC_DEFINE([HAVE_CLOCK_NANOSLEEP], [1], [Have clock_nanosleep()])
2333 ])
2334
2335 dnl --------------------------------------
2336 dnl checking for flex and bison
2337 dnl --------------------------------------
2338
2339 dnl autoconf 2.69 AC_PROG_LEX has no parameters
2340 dnl autoconf 2.70 AC_PROG_LEX prints a deprecation warning without params
2341 m4_if(m4_version_compare(m4_defn([AC_AUTOCONF_VERSION]), [2.70]), [-1], [dnl
2342   dnl autoconf < 2.70
2343   AC_PROG_LEX
2344 ], [
2345   dnl autoconf >= 2.70
2346   AC_PROG_LEX([noyywrap])
2347 ])
2348
2349 AC_MSG_CHECKING([version of flex])
2350 frr_ac_flex_version="$(eval $LEX -V | grep flex | head -n 1)"
2351 frr_ac_flex_version="${frr_ac_flex_version##* }"
2352 AC_MSG_RESULT([$frr_ac_flex_version])
2353 AX_COMPARE_VERSION([$frr_ac_flex_version], [lt], [2.5.20], [
2354   LEX="$SHELL $missing_dir/missing flex"
2355   if test -f "${srcdir}/lib/command_lex.c" -a -f "${srcdir}/lib/command_lex.h"; then
2356     AC_MSG_WARN([using pregenerated flex output files])
2357   else
2358     AC_MSG_ERROR([flex failure and pregenerated files not included (probably a git build)])
2359   fi
2360   AC_SUBST([LEX_OUTPUT_ROOT], [lex.yy])
2361   AC_SUBST([LEXLIB], [''])
2362 ])
2363
2364 AC_PROG_YACC
2365 dnl thanks GNU bison for this b*llshit...
2366 AC_MSG_CHECKING([version of bison])
2367 frr_ac_bison_version="$(eval $YACC -V | grep bison | head -n 1)"
2368 frr_ac_bison_version="${frr_ac_bison_version##* }"
2369 frr_ac_bison_missing="false"
2370 case "x${frr_ac_bison_version}x" in
2371   x2.7*)
2372     BISON_OPENBRACE='"'
2373     BISON_CLOSEBRACE='"'
2374     BISON_VERBOSE=''
2375     AC_MSG_RESULT([$frr_ac_bison_version - 2.7 or older])
2376     ;;
2377   x2.*|x1.*)
2378     AC_MSG_RESULT([$frr_ac_bison_version])
2379     AC_MSG_WARN([installed bison is too old.  Please install GNU bison 2.7.x or newer.])
2380     frr_ac_bison_missing="true"
2381     ;;
2382   x)
2383     AC_MSG_RESULT([none])
2384     AC_MSG_WARN([could not determine bison version.  Please install GNU bison 2.7.x or newer.])
2385     frr_ac_bison_missing="true"
2386     ;;
2387   x3.[012][^0-9]*)
2388     BISON_OPENBRACE='{'
2389     BISON_CLOSEBRACE='}'
2390     BISON_VERBOSE='-Dparse.error=verbose'
2391     AC_MSG_RESULT([$frr_ac_bison_version - 3.0 to 3.2])
2392     ;;
2393   *)
2394     BISON_OPENBRACE='{'
2395     BISON_CLOSEBRACE='}'
2396     BISON_VERBOSE='-Dparse.error=verbose -Wno-yacc'
2397     AC_MSG_RESULT([$frr_ac_bison_version - 3.3 or newer])
2398     ;;
2399 esac
2400 AC_SUBST([BISON_OPENBRACE])
2401 AC_SUBST([BISON_CLOSEBRACE])
2402 AC_SUBST([BISON_VERBOSE])
2403
2404 if $frr_ac_bison_missing; then
2405   YACC="$SHELL $missing_dir/missing bison -y"
2406   if test -f "${srcdir}/lib/command_parse.c" -a -f "${srcdir}/lib/command_parse.h"; then
2407     AC_MSG_WARN([using pregenerated bison output files])
2408   else
2409     AC_MSG_ERROR([bison failure and pregenerated files not included (probably a git build)])
2410   fi
2411 fi
2412
2413 dnl -------------------
2414 dnl capabilities checks
2415 dnl -------------------
2416 if test "$enable_capabilities" != "no"; then
2417   AC_MSG_CHECKING([whether prctl PR_SET_KEEPCAPS is available])
2418   AC_COMPILE_IFELSE(
2419   [ AC_LANG_PROGRAM([[
2420         #include <sys/prctl.h>
2421     ]], [[
2422         prctl(PR_SET_KEEPCAPS, 1, 0, 0, 0);
2423     ]])
2424   ],[AC_MSG_RESULT([yes])
2425      AC_DEFINE([HAVE_PR_SET_KEEPCAPS], [1], [prctl])
2426      frr_ac_keepcaps="yes"
2427   ],[AC_MSG_RESULT(no)
2428   ])
2429   if test "$frr_ac_keepcaps" = "yes"; then
2430     AC_CHECK_HEADERS([sys/capability.h])
2431   fi
2432   if test "$ac_cv_header_sys_capability_h" = "yes"; then
2433     AC_CHECK_LIB([cap], [cap_init],
2434       [AC_DEFINE([HAVE_LCAPS], [1], [Capabilities])
2435        LIBCAP="-lcap"
2436        frr_ac_lcaps="yes"]
2437     )
2438   fi
2439   if test "$frr_ac_scaps" = "yes" \
2440        -o "$frr_ac_lcaps" = "yes"; then
2441     AC_DEFINE([HAVE_CAPABILITIES], [1], [capabilities])
2442   fi
2443
2444   case "$host_os" in
2445   linux*)
2446     if test "$enable_clippy_only" != "yes"; then
2447     if test "$frr_ac_lcaps" != "yes"; then
2448       AC_MSG_ERROR([libcap and/or its headers were not found.  Running FRR without libcap support built in causes a huge performance penalty.])
2449     fi
2450     fi
2451     ;;
2452   esac
2453 else
2454   case "$host_os" in
2455   linux*)
2456     AC_MSG_WARN([Running FRR without libcap support built in causes a huge performance penalty.])
2457     ;;
2458   esac
2459 fi
2460 AC_SUBST([LIBCAP])
2461
2462 dnl ---------------------------
2463 dnl check for glibc 'backtrace'
2464 dnl ---------------------------
2465 if test "$enable_backtrace" != "no" ; then
2466   backtrace_ok=no
2467   PKG_CHECK_MODULES([UNWIND], [libunwind], [
2468     AC_DEFINE([HAVE_LIBUNWIND], [1], [libunwind])
2469     backtrace_ok=yes
2470   ], [
2471     true
2472   ])
2473
2474   if test "$backtrace_ok" = "no"; then
2475     AC_CHECK_HEADER([unwind.h], [
2476       AC_SEARCH_LIBS([unw_getcontext], [unwind], [
2477         AC_DEFINE([HAVE_LIBUNWIND], [1], [libunwind])
2478         backtrace_ok=yes
2479       ])
2480     ])
2481   fi
2482
2483   if test "$backtrace_ok" = "no"; then
2484     AC_CHECK_HEADER([execinfo.h], [
2485       AC_SEARCH_LIBS([backtrace], [execinfo], [
2486         AC_DEFINE([HAVE_GLIBC_BACKTRACE], [1], [Glibc backtrace])
2487         backtrace_ok=yes
2488       ],, [-lm])
2489     ])
2490   fi
2491
2492   if test "$enable_backtrace" = "yes" -a "$backtrace_ok" = "no"; then
2493     dnl user explicitly requested backtrace but we failed to find support
2494     AC_MSG_FAILURE([failed to find backtrace or libunwind support])
2495   fi
2496 fi
2497
2498 dnl -----------------------------------------
2499 dnl check for malloc mallinfo struct and call
2500 dnl this must try and link using LIBS, in
2501 dnl order to check no alternative allocator
2502 dnl has been specified, which might not provide
2503 dnl mallinfo
2504 dnl -----------------------------------------
2505 AC_CHECK_HEADERS([malloc.h malloc_np.h malloc/malloc.h],,, [FRR_INCLUDES])
2506
2507 AC_CACHE_CHECK([whether mallinfo is available], [frr_cv_mallinfo], [
2508   AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2509 #ifdef HAVE_MALLOC_H
2510 #include <malloc.h>
2511 #endif
2512 #ifdef HAVE_MALLOC_NP_H
2513 #include <malloc_np.h>
2514 #endif
2515 #ifdef HAVE_MALLOC_MALLOC_H
2516 #include <malloc/malloc.h>
2517 #endif
2518 ]], [[
2519 struct mallinfo ac_x; ac_x = mallinfo ();
2520 ]])], [
2521     frr_cv_mallinfo=yes
2522   ], [
2523     frr_cv_mallinfo=no
2524   ])
2525 ])
2526 if test "$frr_cv_mallinfo" = "yes"; then
2527   AC_DEFINE([HAVE_MALLINFO], [1], [mallinfo])
2528 fi
2529
2530 AC_CACHE_CHECK([whether mallinfo2 is available], [frr_cv_mallinfo2], [
2531   AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2532 #ifdef HAVE_MALLOC_H
2533 #include <malloc.h>
2534 #endif
2535 #ifdef HAVE_MALLOC_NP_H
2536 #include <malloc_np.h>
2537 #endif
2538 #ifdef HAVE_MALLOC_MALLOC_H
2539 #include <malloc/malloc.h>
2540 #endif
2541 ]], [[
2542 struct mallinfo2 ac_x; ac_x = mallinfo2 ();
2543 ]])], [
2544     frr_cv_mallinfo2=yes
2545   ], [
2546     frr_cv_mallinfo2=no
2547   ])
2548 ])
2549 if test "$frr_cv_mallinfo2" = "yes"; then
2550   AC_DEFINE([HAVE_MALLINFO2], [1], [mallinfo2])
2551 fi
2552
2553 AC_MSG_CHECKING([whether malloc_usable_size is available])
2554 AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2555 #ifdef HAVE_MALLOC_H
2556 #include <malloc.h>
2557 #endif
2558 #ifdef HAVE_MALLOC_MALLOC_H
2559 #include <malloc/malloc.h>
2560 #endif
2561 ]], [[
2562 size_t ac_x; ac_x = malloc_usable_size(NULL);
2563 ]])], [
2564   AC_MSG_RESULT([yes])
2565   AC_DEFINE([HAVE_MALLOC_USABLE_SIZE], [1], [malloc_usable_size])
2566 ], [
2567   AC_MSG_RESULT([no])
2568
2569   AC_MSG_CHECKING([whether malloc_size is available])
2570   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2571 #ifdef HAVE_MALLOC_H
2572 #include <malloc.h>
2573 #endif
2574 #ifdef HAVE_MALLOC_MALLOC_H
2575 #include <malloc/malloc.h>
2576 #endif
2577 ]], [[
2578 size_t ac_x; ac_x = malloc_size(NULL);
2579 ]])], [
2580     AC_MSG_RESULT([yes])
2581     AC_DEFINE([HAVE_MALLOC_SIZE], [1], [malloc_size])
2582   ], [
2583     AC_MSG_RESULT([no])
2584   ])
2585 ])
2586
2587 dnl ----------
2588 dnl configure date
2589 dnl ----------
2590 dev_version=`echo $VERSION | grep dev`
2591 #don't expire deprecated code in non 'dev' branch
2592 if test "$dev_version" = ""; then
2593    CONFDATE=0
2594 else
2595    CONFDATE=`date '+%Y%m%d'`
2596 fi
2597 AC_SUBST([CONFDATE])
2598
2599 dnl ------------------------------
2600 dnl set paths for state directory
2601 dnl ------------------------------
2602 AC_MSG_CHECKING([directory to use for state file])
2603 if test "$prefix" = "NONE"; then
2604   frr_statedir_prefix="";
2605 else
2606   frr_statedir_prefix=${prefix}
2607 fi
2608 if test "$localstatedir" = '${prefix}/var'; then
2609   for FRR_STATE_DIR in ${frr_statedir_prefix}/var/run dnl
2610                         ${frr_statedir_prefix}/var/adm dnl
2611                         ${frr_statedir_prefix}/etc dnl
2612                         /var/run        dnl
2613                         /var/adm        dnl
2614                         /etc            dnl
2615                         /dev/null;
2616   do
2617     test -d $FRR_STATE_DIR && break
2618   done
2619   frr_statedir=$FRR_STATE_DIR
2620 else
2621   frr_statedir=${localstatedir}
2622 fi
2623 if test "$frr_statedir" = "/dev/null"; then
2624     AC_MSG_ERROR([STATE DIRECTORY NOT FOUND! FIX OR SPECIFY --localstatedir!])
2625 fi
2626 AC_MSG_RESULT([${frr_statedir}])
2627 AC_SUBST([frr_statedir])
2628
2629 AC_DEFINE_UNQUOTED([LDPD_SOCKET], ["$frr_statedir%s%s/ldpd.sock"], [ldpd control socket])
2630 AC_DEFINE_UNQUOTED([ZEBRA_SERV_PATH], ["$frr_statedir%s%s/zserv.api"], [zebra api socket])
2631 AC_DEFINE_UNQUOTED([BFDD_CONTROL_SOCKET], ["$frr_statedir%s%s/bfdd.sock"], [bfdd control socket])
2632 AC_DEFINE_UNQUOTED([OSPFD_GR_STATE], ["$frr_statedir%s/ospfd-gr.json"], [ospfd GR state information])
2633 AC_DEFINE_UNQUOTED([OSPF6D_GR_STATE], ["$frr_statedir/ospf6d-gr.json"], [ospf6d GR state information])
2634 AC_DEFINE_UNQUOTED([ISISD_RESTART], ["$frr_statedir%s/isid-restart.json"], [isisd restart information])
2635 AC_DEFINE_UNQUOTED([OSPF6_AUTH_SEQ_NUM_FILE], ["$frr_statedir/ospf6d-at-seq-no.dat"], [ospf6d AT Sequence number information])
2636 AC_DEFINE_UNQUOTED([DAEMON_VTY_DIR], ["$frr_statedir%s%s"], [daemon vty directory])
2637 AC_DEFINE_UNQUOTED([DAEMON_DB_DIR], ["$frr_statedir"], [daemon database directory])
2638
2639 dnl autoconf does this, but it does it too late...
2640 test "$prefix" = "NONE" && prefix=$ac_default_prefix
2641 test "$exec_prefix" = "NONE" && exec_prefix='${prefix}'
2642
2643 dnl get the full path, recursing through variables...
2644 vtysh_bin="$bindir/vtysh"
2645 for I in 1 2 3 4 5 6 7 8 9 10; do
2646         eval vtysh_bin="\"$vtysh_bin\""
2647 done
2648 AC_DEFINE_UNQUOTED([VTYSH_BIN_PATH], ["$vtysh_bin"], [path to vtysh binary])
2649 AC_SUBST([vtysh_bin])
2650
2651 CFG_SYSCONF="$sysconfdir"
2652 CFG_SBIN="$sbindir"
2653 CFG_STATE="$frr_statedir"
2654 CFG_MODULE="$moduledir"
2655 CFG_YANGMODELS="$yangmodelsdir"
2656 CFG_SCRIPT="$scriptdir"
2657 for I in 1 2 3 4 5 6 7 8 9 10; do
2658         eval CFG_SYSCONF="\"$CFG_SYSCONF\""
2659         eval CFG_SBIN="\"$CFG_SBIN\""
2660         eval CFG_STATE="\"$CFG_STATE\""
2661         eval CFG_MODULE="\"$CFG_MODULE\""
2662         eval CFG_YANGMODELS="\"$CFG_YANGMODELS\""
2663         eval CFG_SCRIPT="\"$CFG_SCRIPT\""
2664 done
2665 AC_SUBST([CFG_SYSCONF])
2666 AC_SUBST([CFG_SBIN])
2667 AC_SUBST([CFG_STATE])
2668 AC_SUBST([CFG_MODULE])
2669 AC_SUBST([CFG_SCRIPT])
2670 AC_SUBST([CFG_YANGMODELS])
2671 AC_DEFINE_UNQUOTED([MODULE_PATH], ["$CFG_MODULE"], [path to modules])
2672 AC_DEFINE_UNQUOTED([SCRIPT_PATH], ["$CFG_SCRIPT"], [path to scripts])
2673 AC_DEFINE_UNQUOTED([YANG_MODELS_PATH], ["$CFG_YANGMODELS"], [path to YANG data models])
2674 AC_DEFINE_UNQUOTED([WATCHFRR_SH_PATH], ["${CFG_SBIN%/}/watchfrr.sh"], [path to watchfrr.sh])
2675
2676 dnl various features
2677 AM_CONDITIONAL([SUPPORT_REALMS], [test "$enable_realms" = "yes"])
2678 AM_CONDITIONAL([ENABLE_BGP_VNC], [test "$enable_bgp_vnc" != "no"])
2679 AM_CONDITIONAL([BGP_BMP], [$bgpd_bmp])
2680 dnl northbound
2681 AM_CONDITIONAL([SQLITE3], [$SQLITE3])
2682 AM_CONDITIONAL([CONFD], [test "$enable_confd" != ""])
2683 AM_CONDITIONAL([SYSREPO], [test "$enable_sysrepo" = "yes"])
2684 AM_CONDITIONAL([GRPC], [test "$enable_grpc" = "yes"])
2685 AM_CONDITIONAL([ZEROMQ], [test "$ZEROMQ" = "true"])
2686 dnl plugins
2687 AM_CONDITIONAL([RPKI], [test "$RPKI" = "true"])
2688 AM_CONDITIONAL([SNMP], [test "$SNMP_METHOD" = "agentx"])
2689 AM_CONDITIONAL([IRDP], [$IRDP])
2690 AM_CONDITIONAL([FPM], [test "$enable_fpm" = "yes"])
2691 AM_CONDITIONAL([HAVE_PROTOBUF], [test "$enable_protobuf" = "yes"])
2692 AM_CONDITIONAL([HAVE_PROTOBUF3], [$PROTO3])
2693
2694 dnl PCEP plugin
2695 AS_IF([test "$enable_pathd" != "no"], [
2696        AC_SUBST([PATHD_PCEP_LIBS], ["pceplib/libpcep_pcc.la"])
2697        AC_SUBST([PATHD_PCEP_INCL], ["-I./pceplib "])
2698        ])
2699 AC_CHECK_LIB([cunit], [CU_initialize_registry], [pcep_cunit=yes],[pcep_cunit=no])
2700 AM_CONDITIONAL([PATHD_PCEP_TEST], [test "x${pcep_cunit}" = xyes])
2701 AC_CHECK_PROG(VALGRIND_CHECK, valgrind, yes)
2702 AM_CONDITIONAL([HAVE_VALGRIND_PCEP], [test "$VALGRIND_CHECK" = "yes"])
2703
2704 dnl daemons
2705 AM_CONDITIONAL([VTYSH], [test "$VTYSH" = "vtysh"])
2706 AM_CONDITIONAL([ZEBRA], [test "$enable_zebra" != "no"])
2707 AM_CONDITIONAL([BGPD], [test "$enable_bgpd" != "no"])
2708 AM_CONDITIONAL([RIPD], [test "$enable_ripd" != "no"])
2709 AM_CONDITIONAL([OSPFD], [test "$enable_ospfd" != "no"])
2710 AM_CONDITIONAL([LDPD], [test "$enable_ldpd" != "no"])
2711 AM_CONDITIONAL([BFDD], [test "$BFDD" = "bfdd"])
2712 AM_CONDITIONAL([NHRPD], [test "$NHRPD" = "nhrpd"])
2713 AM_CONDITIONAL([EIGRPD], [test "$enable_eigrpd" != "no"])
2714 AM_CONDITIONAL([WATCHFRR], [test "$WATCHFRR" = "watchfrr"])
2715 AM_CONDITIONAL([OSPFCLIENT], [test "$OSPFCLIENT" = "ospfclient"])
2716 AM_CONDITIONAL([RIPNGD], [test "$enable_ripngd" != "no"])
2717 AM_CONDITIONAL([BABELD], [test "$enable_babeld" != "no"])
2718 AM_CONDITIONAL([OSPF6D], [test "$enable_ospf6d" != "no"])
2719 AM_CONDITIONAL([ISISD], [test "$enable_isisd" != "no"])
2720 AM_CONDITIONAL([PIMD], [test "$enable_pimd" != "no"])
2721 AM_CONDITIONAL([PIM6D], [test "$enable_pim6d" = "yes"])
2722 AM_CONDITIONAL([PBRD], [test "$enable_pbrd" != "no"])
2723 AM_CONDITIONAL([SHARPD], [test "$enable_sharpd" = "yes"])
2724 AM_CONDITIONAL([STATICD], [test "$enable_staticd" != "no"])
2725 AM_CONDITIONAL([FABRICD], [test "$enable_fabricd" != "no"])
2726 AM_CONDITIONAL([VRRPD], [test "$enable_vrrpd" != "no"])
2727 AM_CONDITIONAL([PATHD], [test "$enable_pathd" != "no"])
2728 AM_CONDITIONAL([PATHD_PCEP], [test "$enable_pathd" != "no"])
2729 AM_CONDITIONAL([DP_DPDK], [test "$enable_dp_dpdk" = "yes"])
2730
2731 AC_CONFIG_FILES([Makefile],[
2732         test "$enable_dev_build" = "yes" && makefile_devbuild="--dev-build"
2733         ${PYTHON} "${ac_abs_top_srcdir}/python/makefile.py" ${makefile_devbuild} || exit 1
2734 ], [
2735         PYTHON="$PYTHON"
2736         enable_dev_build="$enable_dev_build"
2737 ])
2738
2739 AC_CONFIG_FILES([
2740           config.version
2741           redhat/frr.spec
2742           alpine/APKBUILD
2743           snapcraft/snapcraft.yaml
2744           lib/version.h
2745           tests/lib/cli/test_cli.refout
2746           pkgsrc/bgpd.sh pkgsrc/ospf6d.sh pkgsrc/ospfd.sh
2747           pkgsrc/ripd.sh pkgsrc/ripngd.sh pkgsrc/zebra.sh
2748           pkgsrc/eigrpd.sh])
2749
2750 AC_CONFIG_FILES([vtysh/extract.pl], [chmod +x vtysh/extract.pl])
2751 AC_CONFIG_FILES([tools/frr], [chmod +x tools/frr])
2752 AC_CONFIG_FILES([tools/watchfrr.sh], [chmod +x tools/watchfrr.sh])
2753 AC_CONFIG_FILES([tools/frrinit.sh], [chmod +x tools/frrinit.sh])
2754 AC_CONFIG_FILES([tools/frrcommon.sh])
2755 AC_CONFIG_FILES([tools/frr.service])
2756 AC_CONFIG_FILES([tools/frr@.service])
2757
2758 AS_IF([test "$with_pkg_git_version" = "yes"], [
2759     AC_CONFIG_COMMANDS([lib/gitversion.h], [
2760         dst="${ac_abs_top_builddir}/lib/gitversion.h"
2761         ${PERL} "${ac_abs_top_srcdir}/lib/gitversion.pl" \
2762                 "${ac_abs_top_srcdir}" \
2763                 > "${dst}.tmp"
2764         test -f "$dst" \
2765                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
2766                 && rm "${dst}.tmp" \
2767                 || mv "${dst}.tmp" "${dst}"
2768     ], [
2769         PERL="$PERL"
2770     ])
2771 ])
2772
2773 ## Hack, but working solution to avoid rebuilding of frr.info.
2774 ## It's already in CVS until texinfo 4.7 is more common.
2775 AC_OUTPUT
2776
2777 if test "$enable_rpath" = "yes" ; then
2778         true
2779 else
2780         # See https://old-en.opensuse.org/openSUSE:Packaging_Guidelines#Removing_Rpath
2781         sed -e 's|^hardcode_libdir_flag_spec=.*|hardcode_libdir_flag_spec=""|g' libtool > libtool.sed && cat libtool.sed > libtool
2782         sed -e 's|^runpath_var=LD_RUN_PATH|runpath_var=DIE_RPATH_DIE|g'         libtool > libtool.sed && cat libtool.sed > libtool
2783         test -f libtool.sed && rm libtool.sed
2784 fi
2785
2786 echo "
2787 FRRouting configuration
2788 ------------------------------
2789 FRR version             : ${PACKAGE_VERSION}
2790 host operating system   : ${host_os}
2791 source code location    : ${srcdir}
2792 compiler                : ${CC}
2793 compiler flags          : ${CFLAGS} ${WERROR} ${AC_CFLAGS} ${SAN_FLAGS}
2794 make                    : ${MAKE-make}
2795 linker flags            : ${LDFLAGS} ${SAN_FLAGS} ${LIBS} ${LIBCAP} ${LIBREADLINE} ${LIBM}
2796 state file directory    : ${frr_statedir}
2797 config file directory   : `eval echo \`echo ${sysconfdir}\``
2798 module directory        : ${CFG_MODULE}
2799 script directory        : ${CFG_SCRIPT}
2800 user to run as          : ${enable_user}
2801 group to run as         : ${enable_group}
2802 group for vty sockets   : ${enable_vty_group}
2803 config file mask        : ${enable_configfile_mask}
2804 log file mask           : ${enable_logfile_mask}
2805 zebra protobuf enabled  : ${enable_protobuf:-no}
2806 vici socket path        : ${vici_socket}
2807
2808 The above user and group must have read/write access to the state file
2809 directory and to the config files in the config file directory."
2810
2811 if test -n "$enable_datacenter"; then
2812   AC_MSG_WARN([The --enable-datacenter compile time option is deprecated.  Please modify the init script to pass -F datacenter to the daemons instead.])
2813 fi
2814 if test -n "$enable_time_check"; then
2815   AC_MSG_WARN([The --enable-time-check compile time option is deprecated.  Please use the service cputime-stats configuration option instead.])
2816 fi
2817 if test -n "$enable_cpu_time"; then
2818   AC_MSG_WARN([The --enable-cpu-time compile time option is deprecated.  Please use the service cputime-warning NNN configuration option instead.])
2819 fi
2820
2821 if test "$enable_doc" != "no" -a "$frr_py_mod_sphinx" = "false"; then
2822   AC_MSG_WARN([sphinx is missing but required to build documentation])
2823 fi
2824 if test "$frr_py_mod_pytest" = "false"; then
2825   AC_MSG_WARN([pytest is missing, unit tests cannot be performed])
2826 fi