configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 m4_define([lxc_version_major], 1)
   5 m4_define([lxc_version_minor], 0)
   6 m4_define([lxc_version_micro], 0)
   7 m4_define([lxc_version_beta], [beta2])
   8
   9 m4_define([lxc_version_base], [lxc_version_major.lxc_version_minor.lxc_version_micro])
  10 m4_define([lxc_version],
  11           [ifelse(lxc_version_beta, [], [lxc_version_base], [lxc_version_base.lxc_version_beta])])
  12
  13 AC_INIT([lxc], [lxc_version])
  14
  15 # We need pkg-config
  16 PKG_PROG_PKG_CONFIG
  17
  18 AC_SUBST(LXC_VERSION_BASE, lxc_version_base)
  19 AC_SUBST(LXC_VERSION_BETA, lxc_version_beta)
  20
  21 AC_SUBST([LXC_VERSION_MAJOR], [lxc_version_major])
  22 AC_SUBST([LXC_VERSION_MINOR], [lxc_version_minor])
  23 AC_SUBST([LXC_VERSION_MICRO], [lxc_version_micro])
  24 AC_SUBST([LXC_VERSION], [lxc_version])
  25
  26 AC_CONFIG_SRCDIR([configure.ac])
  27 AC_CONFIG_AUX_DIR([config])
  28 AC_CONFIG_HEADERS([src/config.h])
  29 AM_INIT_AUTOMAKE([-Wall -Werror -Wno-portability subdir-objects])
  30 AC_CANONICAL_HOST
  31 AM_PROG_CC_C_O
  32 AC_GNU_SOURCE
  33
  34 # Detect the distribution. This is used for the default configuration and
  35 # for some distro-specific build options.
  36 AC_MSG_CHECKING([host distribution])
  37 AC_ARG_WITH(distro, AS_HELP_STRING([--with-distro=DISTRO], [Specify the Linux distribution to target: One of redhat, oracle, centos, fedora, suse, gentoo, debian, arch, slackware, paldo, openmandriva or pardus.]))
  38 if test "z$with_distro" = "z"; then
  39         with_distro=`lsb_release -is`
  40 fi
  41 if test "z$with_distro" = "z"; then
  42         AC_CHECK_FILE(/etc/redhat-release,with_distro="redhat")
  43         AC_CHECK_FILE(/etc/oracle-release,with_distro="oracle")
  44         AC_CHECK_FILE(/etc/centos-release,with_distro="centos")
  45         AC_CHECK_FILE(/etc/fedora-release,with_distro="fedora")
  46         AC_CHECK_FILE(/etc/SuSE-release,with_distro="suse")
  47         AC_CHECK_FILE(/etc/gentoo-release,with_distro="gentoo")
  48         AC_CHECK_FILE(/etc/debian_version,with_distro="debian")
  49         AC_CHECK_FILE(/etc/arch-release,with_distro="arch")
  50         AC_CHECK_FILE(/etc/slackware-version,with_distro="slackware")
  51         AC_CHECK_FILE(/etc/frugalware-release,with_distro="frugalware")
  52         AC_CHECK_FILE(/etc/mandrakelinux-release, with_distro="openmandriva")
  53         AC_CHECK_FILE(/etc/mandriva-release,with_distro="openmandriva")
  54         AC_CHECK_FILE(/etc/pardus-release,with_distro="pardus")
  55 fi
  56 with_distro=`echo ${with_distro} | tr '[[:upper:]]' '[[:lower:]]'`
  57
  58 if test "z$with_distro" = "z"; then
  59         with_distro="unknown"
  60 fi
  61 case $with_distro in
  62         ubuntu)
  63                 distroconf=default.conf.ubuntu
  64                 ;;
  65         redhat|centos|fedora|oracle|oracleserver)
  66                 distroconf=default.conf.libvirt
  67                 ;;
  68         *)
  69                 echo -n "Linux distribution network config unknown, defaulting to lxc.network.type = empty"
  70                 distroconf=default.conf.unknown
  71                 ;;
  72 esac
  73 AC_MSG_RESULT([$with_distro])
  74 AM_CONDITIONAL([HAVE_DEBIAN], [test x"$with_distro" = "xdebian" -o x"$with_distro" = "xubuntu"])
  75 AM_CONDITIONAL([DISTRO_UBUNTU], [test "x$with_distro" = "xubuntu"])
  76
  77 # Check for init system type
  78 AC_MSG_CHECKING([for init system type])
  79 AC_ARG_WITH([init-script],
  80             [AC_HELP_STRING([--with-init-script@<:@=TYPE@<:@,TYPE,...@:>@@:>@],
  81                             [Type(s) of init script to install: sysvinit, systemd, upstart,
  82                              distro @<:@default=distro@:>@])],[],[with_init_script=distro])
  83 case "$with_init_script" in
  84         distro)
  85                 case $with_distro in
  86                         fedora)
  87                                 init_script=systemd
  88                                 ;;
  89                         redhat|centos|oracle|oracleserver)
  90                                 init_script=sysvinit
  91                                 ;;
  92                         debian)
  93                                 init_script=upstart,systemd
  94                                 ;;
  95                         ubuntu)
  96                                 init_script=upstart
  97                                 ;;
  98                         *)
  99                                 echo -n "Linux distribution init system unknown."
 100                                 init_script=
 101                                 ;;
 102                 esac
 103                 ;;
 104         *)
 105                 init_script=$with_init_script
 106                 ;;
 107 esac
 108
 109 # Check valid init systems were given, run in subshell so we don't mess up IFS
 110 (IFS="," ; for init_sys in $init_script;
 111 do
 112         case "$init_sys" in
 113                 none|sysvinit|systemd|upstart)
 114                         ;;
 115                 *)
 116                         exit 1
 117                         ;;
 118         esac
 119 done) || AC_MSG_ERROR([Unknown init system type in $init_script])
 120
 121 AM_CONDITIONAL([INIT_SCRIPT_SYSV], [echo "$init_script" |grep -q "sysvinit"])
 122 AM_CONDITIONAL([INIT_SCRIPT_SYSTEMD], [echo "$init_script" |grep -q "systemd"])
 123 AM_CONDITIONAL([INIT_SCRIPT_UPSTART], [echo "$init_script" |grep -q "upstart"])
 124 AC_MSG_RESULT($init_script)
 125
 126 # Allow disabling rpath
 127 AC_ARG_ENABLE([rpath],
 128         [AC_HELP_STRING([--enable-rpath], [set rpath in executables [default=no]])],
 129         [], [enable_rpath=no])
 130 AM_CONDITIONAL([ENABLE_RPATH], [test "x$enable_rpath" = "xyes"])
 131
 132 # Documentation (manpages)
 133 AC_ARG_ENABLE([doc],
 134         [AC_HELP_STRING([--enable-doc], [make man pages [default=auto]])],
 135         [], [enable_doc=auto])
 136
 137 if test "x$enable_doc" = "xyes" -o "x$enable_doc" = "xauto"; then
 138         db2xman=""
 139         dbparsers="docbook2x-man db2x_docbook2man docbook2man docbook-to-man"
 140
 141         AC_MSG_CHECKING(for docbook2x-man)
 142         for name in ${dbparsers}; do
 143                 if "$name" --help >/dev/null 2>&1; then
 144                         db2xman="$name"
 145                         break;
 146                 fi
 147         done
 148
 149         if test -n "${db2xman}"; then
 150                 AC_MSG_RESULT([${db2xman}])
 151                 enable_doc="yes"
 152         else
 153                 AC_MSG_RESULT([no])
 154                 if test "x$enable_doc" = "xyes"; then
 155                         AC_MSG_ERROR([docbook2x-man is required, but could not be found])
 156                 fi
 157                 enable_doc="no"
 158         fi
 159
 160         AC_SUBST(db2xman)
 161 fi
 162 AM_CONDITIONAL([ENABLE_DOCBOOK], [test "x$db2xman" != "x"])
 163 AM_CONDITIONAL([USE_DOCBOOK2X], [test "x$db2xman" != "xdocbook2man"])
 164
 165 if test "x$db2xman" = "xdocbook2man"; then
 166         docdtd="\"-//Davenport//DTD DocBook V3.0//EN\""
 167 else
 168         docdtd="\"-//OASIS//DTD DocBook XML\" \"http://www.oasis-open.org/docbook/xml/4.5/docbookx.dtd\""
 169 fi
 170 AC_SUBST(docdtd)
 171
 172 # Documentation (API)
 173 AC_ARG_ENABLE([api-docs],
 174         [AC_HELP_STRING([--enable-api-docs],
 175         [make API documentation [default=auto]])],
 176         [], [enable_api_docs=auto])
 177
 178 if test "x$enable_api_docs" = "xyes" -o "x$enable_api_docs" = "xauto"; then
 179         AC_CHECK_PROGS([HAVE_DOXYGEN],[doxygen])
 180         AC_SUBST([HAVE_DOXYGEN])
 181
 182         if test "x$HAVE_DOXYGEN" != "x"; then
 183                 enable_api_docs="yes"
 184         else
 185                 if test "x$enable_api_docs" = "xyes"; then
 186                         AC_MSG_ERROR([doxygen is required, but could not be found])
 187                 fi
 188                 enable_api_docs="no"
 189         fi
 190 fi
 191
 192 AM_CONDITIONAL([ENABLE_API_DOCS], [test "x$HAVE_DOXYGEN" != "x"])
 193
 194 # Apparmor
 195 AC_ARG_ENABLE([apparmor],
 196         [AC_HELP_STRING([--enable-apparmor], [enable apparmor support [default=auto]])],
 197         [], [enable_apparmor=auto])
 198
 199 if test "$enable_apparmor" = "auto" ; then
 200         AC_CHECK_LIB([apparmor],[aa_change_profile],[enable_apparmor=yes], [enable_apparmor=no])
 201 fi
 202 AM_CONDITIONAL([ENABLE_APPARMOR], [test "x$enable_apparmor" = "xyes"])
 203
 204 AC_CHECK_LIB([gnutls], [gnutls_hash_fast], [enable_gnutls=yes], [enable_gnutls=no])
 205
 206 AM_COND_IF([ENABLE_APPARMOR],
 207         [AC_CHECK_HEADER([sys/apparmor.h],[],[AC_MSG_ERROR([You must install the AppArmor development package in order to compile lxc])])
 208         AC_CHECK_LIB([apparmor], [aa_change_profile],[],[AC_MSG_ERROR([You must install the AppArmor development package in order to compile lxc])])
 209         AC_SUBST([APPARMOR_LIBS], [-lapparmor])])
 210
 211 # SELinux
 212 AC_ARG_ENABLE([selinux],
 213         [AC_HELP_STRING([--enable-selinux], [enable SELinux support [default=auto]])],
 214         [], [enable_selinux=auto])
 215
 216 if test "x$enable_selinux" = xauto; then
 217         AC_CHECK_LIB([selinux],[setexeccon_raw],[enable_selinux=yes],[enable_selinux=no])
 218 fi
 219 AM_CONDITIONAL([ENABLE_SELINUX], [test "x$enable_selinux" = "xyes"])
 220 AM_COND_IF([ENABLE_SELINUX],
 221         [AC_CHECK_HEADER([selinux/selinux.h],[],[AC_MSG_ERROR([You must install the SELinux development package in order to compile lxc])])
 222         AC_CHECK_LIB([selinux], [setexeccon_raw],[],[AC_MSG_ERROR([You must install the SELinux development package in order to compile lxc])])
 223         AC_SUBST([SELINUX_LIBS])])
 224
 225 # Seccomp syscall filter
 226 AC_ARG_ENABLE([seccomp],
 227         [AC_HELP_STRING([--enable-seccomp], [enable seccomp support [default=auto]])],
 228         [], [enable_seccomp=auto])
 229
 230 if test "x$enable_seccomp" = "xauto" ; then
 231         AC_CHECK_LIB([seccomp],[seccomp_init],[enable_seccomp=yes],[enable_seccomp=no])
 232 fi
 233 AM_CONDITIONAL([ENABLE_SECCOMP], [test "x$enable_seccomp" = "xyes"])
 234
 235 AM_COND_IF([ENABLE_SECCOMP],
 236         [PKG_CHECK_MODULES([SECCOMP],[libseccomp],[],[
 237                 AC_CHECK_HEADER([seccomp.h],[],[AC_MSG_ERROR([You must install the seccomp development package in order to compile lxc])])
 238                 AC_CHECK_LIB([seccomp], [seccomp_init],[],[AC_MSG_ERROR([You must install the seccomp development package in order to compile lxc])])
 239                 AC_SUBST([SECCOMP_LIBS], [-lseccomp])
 240                 ])
 241         ])
 242
 243 # cgmanager
 244 AC_ARG_ENABLE([cgmanager],
 245         [AC_HELP_STRING([--enable-cgmanager], [enable cgmanager support [default=auto]])],
 246         [], [enable_cgmanager=auto])
 247
 248 if test "x$enable_cgmanager" = "xauto" ; then
 249         AC_CHECK_LIB([cgmanager],[cgmanager_create],[enable_cgmanager=yes],[enable_cgmanager=no])
 250 fi
 251 AM_CONDITIONAL([ENABLE_CGMANAGER], [test "x$enable_cgmanager" = "xyes"])
 252
 253 AM_COND_IF([ENABLE_CGMANAGER],
 254         [PKG_CHECK_MODULES([CGMANAGER], [libcgmanager])
 255         PKG_CHECK_MODULES([NIH], [libnih >= 1.0.2])
 256         PKG_CHECK_MODULES([NIH_DBUS], [libnih-dbus >= 1.0.0])
 257         PKG_CHECK_MODULES([DBUS], [dbus-1 >= 1.2.16])
 258         ])
 259
 260 # Linux capabilities
 261 AC_ARG_ENABLE([capabilities],
 262         [AC_HELP_STRING([--enable-capabilities], [enable kernel capabilities support [default=auto]])],
 263         [], [enable_capabilities=auto])
 264
 265 if test "x$enable_capabilities" = "xauto"; then
 266         AC_CHECK_LIB([cap],[cap_set_proc],[enable_capabilities=yes],[enable_capabilities=no])
 267 fi
 268 AM_CONDITIONAL([ENABLE_CAP], [test "x$enable_capabilities" = "xyes"])
 269
 270 AM_COND_IF([ENABLE_CAP],
 271         [AC_CHECK_LIB(cap,cap_set_proc,[],[AC_MSG_ERROR([You are missing libcap support.])])
 272         AC_SUBST([CAP_LIBS], [-lcap])])
 273
 274 # HAVE_SCMP_FILTER_CTX=1 will tell us we have libseccomp api >= 1.0.0
 275 OLD_CFLAGS="$CFLAGS"
 276 CFLAGS="$CFLAGS $SECCOMP_CFLAGS"
 277 AC_CHECK_TYPES([scmp_filter_ctx], [], [], [[#include <seccomp.h>]])
 278 CFLAGS="$OLD_CFLAGS"
 279
 280 # Configuration examples
 281 AC_ARG_ENABLE([examples],
 282         [AC_HELP_STRING([--enable-examples], [install examples [default=yes]])],
 283         [], [enable_examples=yes])
 284 AM_CONDITIONAL([ENABLE_EXAMPLES], [test "x$enable_examples" = "xyes"])
 285
 286 # Python3 module and scripts
 287 AC_ARG_ENABLE([python],
 288         [AC_HELP_STRING([--enable-python], [enable python binding [default=auto]])],
 289         [], [enable_python=auto])
 290
 291 if test "x$enable_python" = "xauto"; then
 292         PKG_CHECK_MODULES([PYTHONDEV], [python3 >= 3.2],[enable_python=yes],[enable_python=no])
 293         if test "$CC" = "clang"; then
 294                 enable_python=no
 295         fi
 296 fi
 297
 298 if test "x$enable_python" = "xyes" && test "$CC" = "clang"; then
 299         AC_MSG_ERROR([Python3 is incompatible with the clang compiler])
 300 fi
 301
 302 AM_CONDITIONAL([ENABLE_PYTHON], [test "x$enable_python" = "xyes"])
 303
 304 AM_COND_IF([ENABLE_PYTHON],
 305         [AM_PATH_PYTHON([3.2], [], [AC_MSG_ERROR([You must install python3])])
 306         PKG_CHECK_MODULES([PYTHONDEV], [python3 >= 3.2],[],[AC_MSG_ERROR([You must install python3-dev])])
 307         AC_DEFINE_UNQUOTED([ENABLE_PYTHON], 1, [Python3 is available])])
 308
 309 # Enable dumping stack traces
 310 AC_ARG_ENABLE([mutex-debugging],
 311         [AC_HELP_STRING([--enable-mutex-debugging], [Makes mutexes to report error and provide stack trace [default=no]])],
 312         [], [enable_mutex_debugging=no])
 313 AM_CONDITIONAL([MUTEX_DEBUGGING], [test "x$enable_mutex_debugging" = "xyes"])
 314
 315 AM_COND_IF([MUTEX_DEBUGGING],
 316         AC_DEFINE_UNQUOTED([MUTEX_DEBUGGING], 1, [Enabling mutex debugging]))
 317
 318 # Not in older autoconf versions
 319 # AS_VAR_COPY(DEST, SOURCE)
 320 # -------------------------
 321 # Set the polymorphic shell variable DEST to the contents of the polymorphic
 322 # shell variable SOURCE.
 323 m4_ifdef([AS_VAR_COPY], [],
 324 [AC_DEFUN([AS_VAR_COPY],
 325     [AS_LITERAL_IF([$1[]$2], [$1=$$2], [eval $1=\$$2])])
 326 ])
 327
 328 dnl PKG_CHECK_VAR was introduced with pkg-config 0.28
 329 m4_ifdef([PKG_CHECK_VAR], [],
 330 [AC_DEFUN([PKG_CHECK_VAR],
 331     [AC_REQUIRE([PKG_PROG_PKG_CONFIG])dnl
 332      AC_ARG_VAR([$1], [value of $3 for $2, overriding pkg-config])dnl
 333      _PKG_CONFIG([$1], [variable="][$3]["], [$2])
 334      AS_VAR_COPY([$1], [pkg_cv_][$1])
 335      AS_VAR_IF([$1], [""], [$5], [$4])dnl
 336     ])# PKG_CHECK_VAR
 337 ])
 338
 339 # Lua module and scripts
 340 AC_ARG_ENABLE([lua],
 341         [AC_HELP_STRING([--enable-lua], [enable lua binding [default=auto]])],
 342         [], [enable_lua=auto])
 343
 344 AC_ARG_WITH([lua-pc],
 345         [AS_HELP_STRING(
 346                 [--with-lua-pc=PKG],
 347                 [Specify pkg-config package name for lua]
 348         )], [], [with_lua_pc=no])
 349
 350 if test "x$enable_lua" = "xyes" -a "x$with_lua_pc" != "xno"; then
 351         # exit with error if not found
 352         PKG_CHECK_MODULES([LUA], [$with_lua_pc], [LUAPKGCONFIG=$with_lua_pc])
 353 fi
 354
 355 if test "x$enable_lua" = "xauto" -a "x$with_lua_pc" != "xno"; then
 356         PKG_CHECK_MODULES([LUA], [$with_lua_pc],
 357                 [LUAPKGCONFIG=$with_lua_pc
 358                 enable_lua=yes],
 359                 [enable_lua=no])
 360 fi
 361
 362 if test "x$enable_lua" != "xno"; then
 363         PKG_CHECK_MODULES([LUA], [lua], [LUAPKGCONFIG=lua],
 364                 [PKG_CHECK_MODULES([LUA], [lua5.2], [LUAPKGCONFIG=lua5.2],
 365                         [PKG_CHECK_MODULES([LUA], [lua5.1], [LUAPKGCONFIG=lua5.1],
 366                                 [AS_IF([test "x$enable_lua" = "xyes"],
 367                                         [AC_MSG_ERROR([Lua not found. Please use --with-lua-pc=PKG])],
 368                                         [enable_lua=no])]
 369                         )]
 370                 )])
 371         AS_IF([test "x$LUAPKGCONFIG" != "x"], [enable_lua=yes])
 372 fi
 373
 374 AM_CONDITIONAL([ENABLE_LUA],
 375         [test "x$enable_lua" = "xyes"])
 376
 377 AM_COND_IF([ENABLE_LUA],
 378         [AC_MSG_CHECKING([Lua version])
 379         PKG_CHECK_VAR([LUA_VERSION], [$LUAPKGCONFIG], [V],,
 380                 [PKG_CHECK_VAR([LUA_VERSION], [$LUAPKGCONFIG], [major_version])])
 381         AC_MSG_RESULT([$LUA_VERSION])
 382         PKG_CHECK_VAR([LUA_INSTALL_CMOD], [$LUAPKGCONFIG], [INSTALL_CMOD],,
 383                 [LUA_INSTALL_CMOD=$libdir/lua/$LUA_VERSION])
 384         PKG_CHECK_VAR([LUA_INSTALL_LMOD], [$LUAPKGCONFIG], [INSTALL_LMOD],,
 385                 [LUA_INSTALL_LMOD=$datadir/lua/$LUA_VERSION])
 386         ])
 387
 388 # Optional test binaries
 389 AC_ARG_ENABLE([tests],
 390         [AC_HELP_STRING([--enable-tests], [build test/example binaries [default=no]])],
 391         [], [enable_tests=no])
 392 AM_CONDITIONAL([ENABLE_TESTS], [test "x$enable_tests" = "xyes"])
 393
 394 # LXC container path, where the containers are actually stored
 395 # This is overridden by an entry in the file called LXCCONF
 396 # (i.e. /etc/lxc/lxc.conf)
 397 AC_ARG_WITH([config-path],
 398         [AC_HELP_STRING(
 399                 [--with-config-path=dir],
 400                 [lxc configuration repository path]
 401         )], [], [with_config_path=['${localstatedir}/lib/lxc']])
 402
 403 # The path of the global lxc configuration file.
 404 AC_ARG_WITH([global-conf],
 405         [AC_HELP_STRING(
 406                 [--with-global-conf=dir],
 407                 [global lxc configuration file]
 408         )], [], [with_global_conf=['${sysconfdir}/lxc/lxc.conf']])
 409
 410 # The path of the userns network configuration file
 411 AC_ARG_WITH([usernic-conf],
 412         [AC_HELP_STRING(
 413                 [--with-usernic-conf],
 414                 [user network interface configuration file]
 415         )], [], [with_usernic_conf=['${sysconfdir}/lxc/lxc-usernet']])
 416
 417 # The path of the runtime usernic database
 418 AC_ARG_WITH([usernic-db],
 419         [AC_HELP_STRING(
 420                 [--with-usernic-db],
 421                 [lxc user nic database]
 422         )], [], [with_usernic_db=['/run/lxc/nics']])
 423
 424 # Rootfs path, where the container mount structure is assembled
 425 AC_ARG_WITH([rootfs-path],
 426         [AC_HELP_STRING(
 427                 [--with-rootfs-path=dir],
 428                 [lxc rootfs mount point]
 429         )], [], [with_rootfs_path=['${libdir}/lxc/rootfs']])
 430
 431 # cgroup pattern specification
 432 AC_ARG_WITH([cgroup-pattern],
 433         [AC_HELP_STRING(
 434                 [--with-cgroup-pattern=pattern],
 435                 [pattern for container cgroups]
 436         )], [], [with_cgroup_pattern=['/lxc/%n']])
 437
 438 # Container log path.  By default, use $lxcpath.
 439 AC_MSG_CHECKING([Whether to place logfiles in container config path])
 440 AC_ARG_ENABLE([configpath-log],
 441         [AC_HELP_STRING([--enable-configpath-log], [use logfiles in config path [default=no]])],
 442         [], [enable_configpath_log=no])
 443 AC_MSG_RESULT([$enable_configpath_log])
 444 AM_CONDITIONAL([USE_CONFIGPATH_LOGS], [test "$enable_configpath_log" = "yes"])
 445
 446 if test "$enable_configpath_log" = "yes"; then
 447         default_log_path="${with_config_path}"
 448 else
 449         default_log_path="${localstatedir}/log/lxc"
 450 fi
 451
 452 AC_ARG_WITH([log-path],
 453         [AC_HELP_STRING(
 454                 [--with-log-path=dir],
 455                 [per container log path]
 456         )], [], [with_log_path=['${default_log_path}']])
 457
 458 # Expand some useful variables
 459 AS_AC_EXPAND(PREFIX, "$prefix")
 460 AS_AC_EXPAND(LIBDIR, "$libdir")
 461 AS_AC_EXPAND(BINDIR, "$bindir")
 462 AS_AC_EXPAND(LIBEXECDIR, "$libexecdir")
 463 AS_AC_EXPAND(INCLUDEDIR, "$includedir")
 464 AS_AC_EXPAND(SYSCONFDIR, "$sysconfdir")
 465 AS_AC_EXPAND(LXC_DEFAULT_CONFIG, "$sysconfdir/lxc/default.conf")
 466 AS_AC_EXPAND(DATADIR, "$datadir")
 467 AS_AC_EXPAND(LOCALSTATEDIR, "$localstatedir")
 468 AS_AC_EXPAND(DOCDIR, "$docdir")
 469 AS_AC_EXPAND(LXC_DISTRO_CONF, "$distroconf")
 470 AS_AC_EXPAND(LXC_GENERATE_DATE, "$(date)")
 471 AS_AC_EXPAND(LXCPATH, "$with_config_path")
 472 AS_AC_EXPAND(LXC_GLOBAL_CONF, "$with_global_conf")
 473 AS_AC_EXPAND(LXC_USERNIC_CONF, "$with_usernic_conf")
 474 AS_AC_EXPAND(LXC_USERNIC_DB, "$with_usernic_db")
 475 AS_AC_EXPAND(LXCROOTFSMOUNT, "$with_rootfs_path")
 476 AS_AC_EXPAND(LXCTEMPLATEDIR, "$datadir/lxc/templates")
 477 AS_AC_EXPAND(LXCTEMPLATECONFIG, "$datadir/lxc/config")
 478 AS_AC_EXPAND(LXCHOOKDIR, "$datadir/lxc/hooks")
 479 AS_AC_EXPAND(LXCINITDIR, "$libexecdir")
 480 AS_AC_EXPAND(LOGPATH, "$with_log_path")
 481 AC_SUBST(DEFAULT_CGROUP_PATTERN, ["$with_cgroup_pattern"])
 482
 483 # Check for some standard kernel headers
 484 AC_CHECK_HEADERS([linux/unistd.h linux/netlink.h linux/genetlink.h],
 485                                 [],
 486                                 AC_MSG_ERROR([Please install the Linux kernel headers.]),
 487                                 [#include <sys/socket.h>])
 488
 489 # Check for alternate C libraries
 490 AC_MSG_CHECKING(for bionic libc)
 491 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 492         [[#ifndef __ANDROID__
 493 error: Not bionic!
 494 #endif]])],
 495         [is_bionic=yes],
 496         [is_bionic=no])
 497 if test "x$is_bionic" = "xyes"; then
 498         AC_DEFINE([IS_BIONIC], 1, [bionic libc])
 499         AC_MSG_RESULT([yes])
 500 else
 501         AC_MSG_RESULT([no])
 502 fi
 503 AM_CONDITIONAL([IS_BIONIC], [test "x$is_bionic" = "xyes"])
 504
 505 # Some systems lack PR_CAPBSET_DROP definition => HAVE_DECL_PR_CAPBSET_DROP
 506 AC_CHECK_DECLS([PR_CAPBSET_DROP], [], [], [#include <sys/prctl.h>])
 507
 508 # Check for some headers
 509 AC_CHECK_HEADERS([sys/signalfd.h pty.h ifaddrs.h sys/capability.h sys/personality.h utmpx.h sys/timerfd.h])
 510
 511 # Check for some syscalls functions
 512 AC_CHECK_FUNCS([setns pivot_root sethostname unshare rand_r confstr])
 513
 514 # Check for some functions
 515 AC_CHECK_LIB(pthread, main)
 516 AC_CHECK_FUNCS(pthread_atfork)
 517 AC_CHECK_LIB(util, openpty)
 518 AC_CHECK_FUNCS([openpty hasmntopt setmntent endmntent])
 519 AC_CHECK_FUNCS([getline],
 520         AM_CONDITIONAL(HAVE_GETLINE, true)
 521         AC_DEFINE(HAVE_GETLINE,1,[Have getline]),
 522         AM_CONDITIONAL(HAVE_GETLINE, false))
 523 AC_CHECK_FUNCS([fgetln],
 524         AM_CONDITIONAL(HAVE_FGETLN, true)
 525         AC_DEFINE(HAVE_FGETLN,1,[Have fgetln]),
 526         AM_CONDITIONAL(HAVE_FGETLN, false))
 527
 528 # Check for some libraries
 529 AC_SEARCH_LIBS(sem_open, [rt pthread])
 530 AC_SEARCH_LIBS(clock_gettime, [rt])
 531
 532 # Check for some standard binaries
 533 AC_PROG_GCC_TRADITIONAL
 534 AC_PROG_SED
 535
 536 # See if we support thread-local storage.
 537 LXC_CHECK_TLS
 538
 539 if test "x$GCC" = "xyes"; then
 540         CFLAGS="$CFLAGS -Wall -Werror"
 541 fi
 542
 543 # Files requiring some variable expansion
 544 AC_CONFIG_FILES([
 545         Makefile
 546         lxc.pc
 547         lxc.spec
 548
 549         config/Makefile
 550         config/apparmor/Makefile
 551         config/init/Makefile
 552         config/init/sysvinit/Makefile
 553         config/init/systemd/Makefile
 554         config/init/upstart/Makefile
 555         config/etc/Makefile
 556         config/templates/Makefile
 557         config/templates/centos.common.conf
 558         config/templates/centos.userns.conf
 559         config/templates/debian.common.conf
 560         config/templates/debian.userns.conf
 561         config/templates/fedora.common.conf
 562         config/templates/fedora.userns.conf
 563         config/templates/oracle.common.conf
 564         config/templates/oracle.userns.conf
 565         config/templates/plamo.common.conf
 566         config/templates/plamo.userns.conf
 567         config/templates/ubuntu-cloud.common.conf
 568         config/templates/ubuntu-cloud.lucid.conf
 569         config/templates/ubuntu-cloud.userns.conf
 570         config/templates/ubuntu.common.conf
 571         config/templates/ubuntu.lucid.conf
 572         config/templates/ubuntu.userns.conf
 573
 574         doc/Makefile
 575         doc/api/Makefile
 576         doc/legacy/lxc-ls.sgml
 577         doc/lxc-attach.sgml
 578         doc/lxc-autostart.sgml
 579         doc/lxc-cgroup.sgml
 580         doc/lxc-checkconfig.sgml
 581         doc/lxc-clone.sgml
 582         doc/lxc-console.sgml
 583         doc/lxc-create.sgml
 584         doc/lxc-destroy.sgml
 585         doc/lxc-device.sgml
 586         doc/lxc-execute.sgml
 587         doc/lxc-freeze.sgml
 588         doc/lxc-info.sgml
 589         doc/lxc-ls.sgml
 590         doc/lxc-monitor.sgml
 591         doc/lxc-netstat.sgml
 592         doc/lxc-ps.sgml
 593         doc/lxc-snapshot.sgml
 594         doc/lxc-start-ephemeral.sgml
 595         doc/lxc-start.sgml
 596         doc/lxc-stop.sgml
 597         doc/lxc-top.sgml
 598         doc/lxc-unfreeze.sgml
 599         doc/lxc-unshare.sgml
 600         doc/lxc-user-nic.sgml
 601         doc/lxc-usernsexec.sgml
 602         doc/lxc-version.sgml
 603         doc/lxc-wait.sgml
 604
 605         doc/lxc.conf.sgml
 606         doc/lxc-usernet.sgml
 607         doc/lxc.sgml
 608         doc/common_options.sgml
 609         doc/see_also.sgml
 610
 611         doc/rootfs/Makefile
 612
 613         doc/examples/Makefile
 614         doc/examples/lxc-macvlan.conf
 615         doc/examples/lxc-vlan.conf
 616         doc/examples/lxc-no-netns.conf
 617         doc/examples/lxc-empty-netns.conf
 618         doc/examples/lxc-phys.conf
 619         doc/examples/lxc-veth.conf
 620         doc/examples/lxc-complex.conf
 621
 622         doc/ja/Makefile
 623         doc/ja/legacy/lxc-ls.sgml
 624         doc/ja/lxc-attach.sgml
 625         doc/ja/lxc-autostart.sgml
 626         doc/ja/lxc-cgroup.sgml
 627         doc/ja/lxc-checkconfig.sgml
 628         doc/ja/lxc-clone.sgml
 629         doc/ja/lxc-console.sgml
 630         doc/ja/lxc-create.sgml
 631         doc/ja/lxc-destroy.sgml
 632         doc/ja/lxc-device.sgml
 633         doc/ja/lxc-execute.sgml
 634         doc/ja/lxc-freeze.sgml
 635         doc/ja/lxc-info.sgml
 636         doc/ja/lxc-ls.sgml
 637         doc/ja/lxc-monitor.sgml
 638         doc/ja/lxc-netstat.sgml
 639         doc/ja/lxc-ps.sgml
 640         doc/ja/lxc-snapshot.sgml
 641         doc/ja/lxc-start-ephemeral.sgml
 642         doc/ja/lxc-start.sgml
 643         doc/ja/lxc-stop.sgml
 644         doc/ja/lxc-top.sgml
 645         doc/ja/lxc-unfreeze.sgml
 646         doc/ja/lxc-unshare.sgml
 647         doc/ja/lxc-user-nic.sgml
 648         doc/ja/lxc-usernsexec.sgml
 649         doc/ja/lxc-version.sgml
 650         doc/ja/lxc-wait.sgml
 651
 652         doc/ja/lxc.conf.sgml
 653         doc/ja/lxc-usernet.sgml
 654         doc/ja/lxc.sgml
 655         doc/ja/common_options.sgml
 656         doc/ja/see_also.sgml
 657
 658         hooks/Makefile
 659
 660         templates/Makefile
 661         templates/lxc-alpine
 662         templates/lxc-altlinux
 663         templates/lxc-archlinux
 664         templates/lxc-busybox
 665         templates/lxc-centos
 666         templates/lxc-cirros
 667         templates/lxc-debian
 668         templates/lxc-download
 669         templates/lxc-fedora
 670         templates/lxc-gentoo
 671         templates/lxc-openmandriva
 672         templates/lxc-opensuse
 673         templates/lxc-oracle
 674         templates/lxc-plamo
 675         templates/lxc-sshd
 676         templates/lxc-ubuntu
 677         templates/lxc-ubuntu-cloud
 678
 679         src/Makefile
 680         src/lxc/Makefile
 681         src/lxc/lxc-ps
 682         src/lxc/lxc-netstat
 683         src/lxc/lxc-checkconfig
 684         src/lxc/lxc-version
 685         src/lxc/lxc-start-ephemeral
 686         src/lxc/legacy/lxc-ls
 687         src/lxc/lxc.functions
 688         src/lxc/version.h
 689         src/python-lxc/Makefile
 690
 691         src/lua-lxc/Makefile
 692
 693         src/tests/Makefile
 694 ])
 695 AC_CONFIG_COMMANDS([default],[[]],[[]])
 696 AC_OUTPUT
 697
 698 # Configuration overview
 699 cat << EOF
 700
 701 ----------------------------
 702 Environment:
 703  - compiler: $CC
 704  - distribution: $with_distro
 705  - init script type(s): $init_script
 706  - rpath: $enable_rpath
 707  - GnuTLS: $enable_gnutls
 708
 709 Security features:
 710  - Apparmor: $enable_apparmor
 711  - Linux capabilities: $enable_capabilities
 712  - seccomp: $enable_seccomp
 713  - SELinux: $enable_selinux
 714  - cgmanager: $enable_cgmanager
 715
 716 Bindings:
 717  - lua: $enable_lua
 718  - python3: $enable_python
 719
 720 Documentation:
 721  - examples: $enable_examples
 722  - API documentation: $enable_api_docs
 723  - user documentation: $enable_doc
 724
 725 Debugging:
 726  - tests: $enable_tests
 727  - mutex debugging: $enable_mutex_debugging
 728
 729 Paths:
 730  - Logs in configpath: $enable_configpath_log
 731 EOF
 732
 733 if test "x$ac_cv_func_pthread_atfork" = "xno" ; then
 734 cat << EOF
 735
 736 WARNING: Threading not supported on your platform
 737
 738         You are compiling LXC for bionic target which lacks certain threading related functionality used by LXC API (like pthread_atfork).
 739         Please note that, because of the missing functionality, multithreaded usage of LXC API cause some problems.
 740 EOF
 741 fi