configure.ac

   1 ##
   2 ## Configure template file for FRRouting.
   3 ## autoconf will generate a configure script.
   4 ##
   5 ##  Copyright (c) 1996, 97, 98, 99, 2000 Kunihiro Ishiguro <kunihiro@zebra.org>
   6 ##  Portions Copyright (c) 2003 Paul Jakma <paul@dishone.st>
   7 ##
   8 AC_PREREQ([2.60])
   9
  10 AC_INIT([frr], [7.2-dev], [https://github.com/frrouting/frr/issues])
  11 PACKAGE_URL="https://frrouting.org/"
  12 AC_SUBST([PACKAGE_URL])
  13 PACKAGE_FULLNAME="FRRouting"
  14 AC_SUBST([PACKAGE_FULLNAME])
  15
  16 CONFIG_ARGS="`echo $ac_configure_args | sed -e \"s% '[[A-Z]]*FLAGS=[[^']]\+'%%g\"`"
  17 AC_SUBST([CONFIG_ARGS])
  18
  19 AC_CONFIG_SRCDIR([lib/zebra.h])
  20 AC_CONFIG_MACRO_DIR([m4])
  21
  22 dnl -----------------------------------
  23 dnl Get hostname and other information.
  24 dnl -----------------------------------
  25 AC_CANONICAL_BUILD()
  26 AC_CANONICAL_HOST()
  27
  28 hosttools_clippy="false"
  29 build_clippy="true"
  30
  31 dnl case 1: external clippy
  32 if test -n "$with_clippy" -a "$with_clippy" != "no" -a "$with_clippy" != "yes"; then
  33   if test "$enable_clippy_only" == "yes"; then
  34     AC_MSG_ERROR([--enable-clippy-only does not make sense with --with-clippy])
  35   fi
  36
  37   CLIPPY="$with_clippy"
  38   build_clippy="false"
  39   if test ! -x "$with_clippy"; then
  40     AC_MSG_ERROR([clippy tool ($with_clippy) is not executable])
  41   fi
  42
  43 dnl case 2: cross-compiling internal clippy
  44 elif test "$host" != "$build"; then
  45   if test "$srcdir" = "."; then
  46     AC_MSG_ERROR([cross-compilation is only possible with builddir separate from srcdir or by building clippy separately and using the --with-clippy option.  create a separate directory and run as .../path-to-frr/configure.])
  47   fi
  48   test -d hosttools || mkdir hosttools
  49   abssrc="`cd \"${srcdir}\"; pwd`"
  50
  51   AC_MSG_NOTICE([...])
  52   AC_MSG_NOTICE([... cross-compilation: creating hosttools directory and self-configuring for build platform tools])
  53   AC_MSG_NOTICE([... use HOST_CPPFLAGS / HOST_CFLAGS / HOST_LDFLAGS if neccessary])
  54   AC_MSG_NOTICE([...])
  55
  56   (
  57     for var in $ac_precious_vars; do
  58       dnl special cases
  59       case "$var" in
  60       YACC|YFLAGS) continue;;
  61       PYTHON*)     retain=true;;
  62       *)           retain=false;
  63       esac
  64
  65       eval "hostvar=\"\${HOST_$var}\""
  66       eval "targetvar=\"\${$var}\""
  67       if test -n "$hostvar"; then
  68         eval "$var='$hostvar'"
  69         _AS_ECHO_LOG([host $var='$hostvar'])
  70       elif $retain; then
  71         _AS_ECHO_LOG([host retain $var='$targetvar'])
  72       else
  73         eval "unset $var"
  74         _AS_ECHO_LOG([host unset $var])
  75       fi
  76     done
  77     cd hosttools
  78     "${abssrc}/configure" "--host=$build" "--build=$build" "--enable-clippy-only" "--disable-nhrpd" "--disable-vtysh"
  79   ) || exit 1
  80
  81   AC_MSG_NOTICE([...])
  82   AC_MSG_NOTICE([... cross-compilation: finished self-configuring for build platform tools])
  83   AC_MSG_NOTICE([...])
  84
  85   build_clippy="false"
  86   hosttools_clippy="true"
  87   CLIPPY="hosttools/lib/clippy"
  88
  89 dnl case 3: normal build internal clippy
  90 else
  91   CLIPPY="lib/clippy\$(EXEEXT)"
  92 fi
  93 AC_SUBST([CLIPPY])
  94 AM_CONDITIONAL([BUILD_CLIPPY], [$build_clippy])
  95 AM_CONDITIONAL([HOSTTOOLS_CLIPPY], [$hosttools_clippy])
  96 AM_CONDITIONAL([ONLY_CLIPPY], [test "$enable_clippy_only" = "yes"])
  97
  98 # Disable portability warnings -- our automake code (in particular
  99 # common.am) uses some constructs specific to gmake.
 100 AM_INIT_AUTOMAKE([1.12 -Wno-portability foreign])
 101 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
 102 AM_SILENT_RULES([yes])
 103 AC_CONFIG_HEADERS([config.h])
 104
 105 AC_PATH_PROG([PERL], [perl])
 106 PKG_PROG_PKG_CONFIG
 107
 108 dnl default is to match previous behavior
 109 exampledir=${sysconfdir}
 110 AC_ARG_ENABLE([exampledir],
 111           AS_HELP_STRING([--enable-exampledir],
 112                          [specify alternate directory for examples]),
 113                          exampledir="$enableval",)
 114 dnl XXX add --exampledir to autoconf standard directory list somehow
 115 AC_SUBST([exampledir])
 116
 117 dnl default is to match previous behavior
 118 pkgsrcrcdir=""
 119 AC_ARG_ENABLE([pkgsrcrcdir],
 120           AS_HELP_STRING([--enable-pkgsrcrcdir],
 121                          [specify directory for rc.d scripts]),
 122                          pkgsrcrcdir="$enableval",)
 123 dnl XXX add --pkgsrcrcdir to autoconf standard directory list somehow
 124 AC_SUBST([pkgsrcrcdir])
 125 AM_CONDITIONAL([PKGSRC], [test "x$pkgsrcrcdir" != "x"])
 126
 127 AC_ARG_WITH([moduledir], [AS_HELP_STRING([--with-moduledir=DIR], [module directory (${libdir}/frr/modules)])], [
 128         moduledir="$withval"
 129 ], [
 130         moduledir="\${libdir}/frr/modules"
 131 ])
 132 AC_SUBST([moduledir], [$moduledir])
 133
 134
 135 AC_ARG_WITH([yangmodelsdir], [AS_HELP_STRING([--with-yangmodelsdir=DIR], [yang models directory (${datarootdir}/yang)])], [
 136         yangmodelsdir="$withval"
 137 ], [
 138         yangmodelsdir="\${datarootdir}/yang"
 139 ])
 140 AC_SUBST([yangmodelsdir])
 141
 142 AC_ARG_ENABLE(tcmalloc,
 143         AS_HELP_STRING([--enable-tcmalloc], [Turn on tcmalloc]),
 144 [case "${enableval}" in
 145   yes) tcmalloc_enabled=true
 146 LIBS="$LIBS -ltcmalloc_minimal"
 147  ;;
 148   no)  tcmalloc_enabled=false ;;
 149   *) AC_MSG_ERROR([bad value ${enableval} for --enable-tcmalloc]) ;;
 150 esac],[tcmalloc_enabled=false])
 151
 152
 153 dnl Thanks autoconf, but we don't want a default -g -O2.  We have our own
 154 dnl flag determination logic.
 155 CFLAGS="${CFLAGS:-}"
 156
 157 dnl --------------------
 158 dnl Check CC and friends
 159 dnl --------------------
 160 dnl note orig_cflags is also used further down
 161 orig_cflags="$CFLAGS"
 162 orig_cxxflags="$CXXFLAGS"
 163 AC_LANG([C])
 164 AC_PROG_CC
 165 AC_PROG_CPP
 166 AC_PROG_CXX
 167 AM_PROG_CC_C_O
 168 dnl remove autoconf default "-g -O2"
 169 CFLAGS="$orig_cflags"
 170 CXXFLAGS="$orig_cxxflags"
 171 AC_PROG_CC_C99
 172 dnl NB: see C11 below
 173
 174 PKG_PROG_PKG_CONFIG
 175
 176 dnl it's 2019, sed is sed.
 177 SED=sed
 178 AC_SUBST([SED])
 179
 180 dnl try and enable CFLAGS that are useful for FRR
 181 dnl - specifically, options to control warnings
 182
 183 AC_USE_SYSTEM_EXTENSIONS
 184 AC_DEFUN([AC_C_FLAG], [{
 185     m4_pushdef([cachename],[m4_translit([frr_cv_$1],[ =-+],[____])])
 186     AC_CACHE_CHECK([[whether $CC supports $1]], cachename, [
 187         AC_LANG_PUSH([C])
 188         ac_c_flag_save="$CFLAGS"
 189         CFLAGS="$CFLAGS $1"
 190         AC_COMPILE_IFELSE(
 191                 [AC_LANG_PROGRAM([[]])],
 192                 [
 193                         cachename=yes
 194                 ], [
 195                         cachename=no
 196                 ])
 197         CFLAGS="$ac_c_flag_save"
 198         AC_LANG_POP([C])
 199     ])
 200     if test "${cachename}" = yes; then
 201         m4_if([$3], [], [CFLAGS="$CFLAGS $1"], [$3])
 202     else
 203         :
 204         $2
 205     fi
 206     m4_popdef([cachename])
 207 }])
 208
 209 AC_DEFUN([AC_LINK_IFELSE_FLAGS], [{
 210         AC_LANG_PUSH([C])
 211         ac_cflags_save="$CFLAGS"
 212         ac_libs_save="$LIBS"
 213         CFLAGS="$CFLAGS $1"
 214         LIBS="$LIBS $2"
 215         AC_LINK_IFELSE(
 216                 [$3],
 217                 [
 218                         CFLAGS="$ac_cflags_save"
 219                         LIBS="$ac_libs_save"
 220                         m4_default([$5], [
 221                                 AC_MSG_RESULT([yes])
 222                         ])
 223                 ], [
 224                         CFLAGS="$ac_cflags_save"
 225                         LIBS="$ac_libs_save"
 226                         m4_default([$4], [
 227                                 AC_MSG_RESULT([no])
 228                         ])
 229                 ])
 230         AC_LANG_POP([C])
 231         }])
 232
 233 dnl ICC won't bail on unknown options without -diag-error 10006
 234 dnl need to do this first so we get useful results for the other options
 235 AC_C_FLAG([-diag-error 10006])
 236
 237 dnl AC_PROG_CC_C99 may change CC to include -std=gnu99 or something
 238 ac_cc="$CC"
 239 CC="${CC% -std=gnu99}"
 240 CC="${CC% -std=c99}"
 241
 242 AC_C_FLAG([-std=gnu11], [CC="$ac_cc"], [CC="$CC -std=gnu11"])
 243
 244 dnl if the user has specified any CFLAGS, override our settings
 245 if test "x${enable_gcov}" = "xyes"; then
 246    if test "z$orig_cflags" = "z"; then
 247       AC_C_FLAG([-coverage])
 248       AC_C_FLAG([-O0])
 249    fi
 250
 251    LDFLAGS="${LDFLAGS} -lgcov"
 252 elif test "x${enable_dev_build}" = "xyes"; then
 253    AC_DEFINE([DEV_BUILD], [1], [Build for development])
 254    if test "z$orig_cflags" = "z"; then
 255       AC_C_FLAG([-g3])
 256       AC_C_FLAG([-O0])
 257    fi
 258    if test "x${enable_lua}" = "xyes"; then
 259       AX_PROG_LUA([5.3])
 260       AX_LUA_HEADERS
 261       AX_LUA_LIBS([
 262          AC_DEFINE([HAVE_LUA], [1], [Have support for Lua interpreter])
 263          LIBS="$LIBS $LUA_LIB"
 264       ])
 265    fi
 266 else
 267    if test "x${enable_lua}" = "xyes"; then
 268       AC_MSG_ERROR([Lua is not meant to be built/used outside of development at this time])
 269    fi
 270    if test "z$orig_cflags" = "z"; then
 271       AC_C_FLAG([-g])
 272       AC_C_FLAG([-O2])
 273    fi
 274 fi
 275 AM_CONDITIONAL([DEV_BUILD], [test "x$enable_dev_build" = "xyes"])
 276
 277 dnl always want these CFLAGS
 278 AC_C_FLAG([-fno-omit-frame-pointer])
 279 AC_C_FLAG([-funwind-tables])
 280 AC_C_FLAG([-Wall])
 281 AC_C_FLAG([-Wextra])
 282 AC_C_FLAG([-Wmissing-prototypes])
 283 AC_C_FLAG([-Wmissing-declarations])
 284 AC_C_FLAG([-Wpointer-arith])
 285 AC_C_FLAG([-Wbad-function-cast])
 286 AC_C_FLAG([-Wwrite-strings])
 287 if test x"${enable_gcc_ultra_verbose}" = x"yes" ; then
 288   AC_C_FLAG([-Wcast-qual])
 289   AC_C_FLAG([-Wstrict-prototypes])
 290   AC_C_FLAG([-Wmissing-noreturn])
 291   AC_C_FLAG([-Wmissing-format-attribute])
 292   AC_C_FLAG([-Wunreachable-code])
 293   AC_C_FLAG([-Wpacked])
 294   AC_C_FLAG([-Wpadded])
 295   AC_C_FLAG([-Wshadow])
 296 else
 297   AC_C_FLAG([-Wno-unused-result])
 298 fi
 299 AC_C_FLAG([-Wno-unused-parameter])
 300 AC_C_FLAG([-Wno-missing-field-initializers])
 301
 302 AC_C_FLAG([-Wc++-compat], [], [CXX_COMPAT_CFLAGS="-Wc++-compat"])
 303 AC_SUBST([CXX_COMPAT_CFLAGS])
 304
 305 dnl ICC emits a broken warning for const char *x = a ? "b" : "c";
 306 dnl for some reason the string consts get 'promoted' to char *,
 307 dnl triggering a const to non-const conversion warning.
 308 AC_C_FLAG([-diag-disable 3179])
 309
 310 if test x"${enable_werror}" = x"yes" ; then
 311   WERROR="-Werror"
 312 fi
 313 AC_SUBST([WERROR])
 314
 315 SAN_FLAGS=""
 316 if test "$enable_address_sanitizer" = "yes"; then
 317   AC_C_FLAG([-fsanitize=address], [
 318     AC_MSG_ERROR([$CC does not support Address Sanitizer.])
 319   ], [
 320     SAN_FLAGS="$SAN_FLAGS -fsanitize=address"
 321   ])
 322 fi
 323 if test "$enable_thread_sanitizer" = "yes"; then
 324   AC_C_FLAG([-fsanitize=thread], [
 325     AC_MSG_ERROR([$CC does not support Thread Sanitizer.])
 326   ], [
 327     SAN_FLAGS="$SAN_FLAGS -fsanitize=thread"
 328   ])
 329 fi
 330 if test "$enable_memory_sanitizer" = "yes"; then
 331   AC_C_FLAG([-fsanitize=thread -fPIE -pie], [
 332     AC_MSG_ERROR([$CC does not support Thread Sanitizer.])
 333   ], [
 334     SAN_FLAGS="-fsanitize=memory -fPIE -pie"
 335   ])
 336 fi
 337 AC_SUBST([SAN_FLAGS])
 338
 339 dnl ----------
 340 dnl Essentials
 341 dnl ----------
 342
 343 AX_PTHREAD([
 344   CC="$PTHREAD_CC"
 345   CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 346   LIBS="$PTHREAD_LIBS $LIBS"
 347 ], [
 348   AC_MSG_FAILURE([This FRR version needs pthreads])
 349 ])
 350
 351 AC_SEARCH_LIBS([pthread_condattr_setclock], [],
 352                 [frr_cv_pthread_condattr_setclock=yes],
 353                 [frr_cv_pthread_condattr_setclock=no])
 354 if test "$frr_cv_pthread_condattr_setclock" = yes; then
 355   AC_DEFINE([HAVE_PTHREAD_CONDATTR_SETCLOCK], [1], [Have pthread.h pthread_condattr_setclock])
 356 fi
 357
 358 dnl --------------
 359 dnl Check programs
 360 dnl --------------
 361 AC_PROG_INSTALL
 362 AC_PROG_LN_S
 363 AC_CHECK_TOOL([AR], [ar])
 364
 365 dnl -------
 366 dnl libtool
 367 dnl -------
 368 AC_ARG_ENABLE([static-bin],
 369   AS_HELP_STRING([--enable-static-bin], [link binaries statically]))
 370 LT_INIT
 371 _LT_CONFIG_LIBTOOL([
 372   patch -N -i "${srcdir}/m4/libtool-whole-archive.patch" libtool >&AS_MESSAGE_LOG_FD || \
 373     AC_MSG_WARN([Could not patch libtool for static linking support.  Loading modules into a statically linked daemon will fail.])
 374 ])
 375 if test "$enable_static_bin" = "yes"; then
 376   AC_LDFLAGS="-static"
 377   if test "$enable_static" != "yes"; then
 378     AC_MSG_ERROR([The --enable-static-bin option must be combined with --enable-static.])
 379   fi
 380 fi
 381 if test "$enable_shared" != "yes"; then
 382   AC_MSG_ERROR([FRR cannot be built with --disable-shared.  If you want statically linked daemons, use --enable-shared --enable-static --enable-static-bin])
 383 fi
 384 AC_SUBST([AC_LDFLAGS])
 385 AM_CONDITIONAL([STATIC_BIN], [test "x$enable_static_bin" = "xyes"])
 386
 387 dnl $AR and $RANLIB are set by LT_INIT above
 388 AC_MSG_CHECKING([whether $AR supports D option])
 389 if $AR crD conftest.a >/dev/null 2>/dev/null; then
 390   AC_MSG_RESULT([yes])
 391   dnl ARFLAGS is for automake, AR_FLAGS for libtool m-(
 392   ARFLAGS="crD"
 393   AR_FLAGS="crD"
 394 else
 395   AC_MSG_RESULT([no])
 396   ARFLAGS="cru"
 397   AR_FLAGS="cru"
 398 fi
 399 AC_SUBST([ARFLAGS])
 400 AC_SUBST([AR_FLAGS])
 401
 402 AC_MSG_CHECKING([whether $RANLIB supports D option])
 403 if $RANLIB -D conftest.a >conftest.err 2>&1; then
 404   if grep -q -- '-D' conftest.err; then
 405     AC_MSG_RESULT([no])
 406   else
 407     AC_MSG_RESULT([yes])
 408     RANLIB="$RANLIB -D"
 409   fi
 410 else
 411   AC_MSG_RESULT([no])
 412 fi
 413 AC_SUBST([RANLIB])
 414
 415 test -f conftest.err && rm conftest.err
 416 test -f conftest.a && rm conftest.a
 417
 418 dnl ----------------------
 419 dnl Packages configuration
 420 dnl ----------------------
 421 if test -f config.version; then
 422   . ./config.version
 423 elif test -f "${srcdir}/config.version"; then
 424   . "${srcdir}/config.version"
 425 fi
 426 AC_ARG_WITH([pkg-extra-version],
 427   AS_HELP_STRING([--with-pkg-extra-version=VER], [add extra version field, for packagers/distributions]), [
 428   if test "$withval" = "no"; then
 429     EXTRAVERSION=
 430   else
 431     EXTRAVERSION=$withval
 432   fi
 433 ], [])
 434 AC_ARG_WITH([pkg-git-version],
 435         AS_HELP_STRING([--with-pkg-git-version], [add git information to MOTD and build version string]),
 436         [ test "x$withval" != "xno" && with_pkg_git_version="yes" ])
 437 AC_ARG_WITH([clippy],
 438   AS_HELP_STRING([--with-clippy=PATH], [use external clippy helper program]))
 439 AC_ARG_WITH([vtysh_pager],
 440         AS_HELP_STRING([--with-vtysh-pager=PAGER], [control what pager is compiled in as default]),
 441         VTYSH_PAGER=$withval, VTYSH_PAGER="more")
 442 AC_ARG_ENABLE([vtysh],
 443   AS_HELP_STRING([--disable-vtysh], [do not build integrated vty shell for FRR]))
 444 AC_ARG_ENABLE([doc],
 445   AS_HELP_STRING([--disable-doc], [do not build docs]))
 446 AC_ARG_ENABLE([doc-html],
 447   AS_HELP_STRING([--enable-doc-html], [build HTML docs]))
 448 AC_ARG_ENABLE([zebra],
 449   AS_HELP_STRING([--disable-zebra], [do not build zebra daemon]))
 450 AC_ARG_ENABLE([bgpd],
 451   AS_HELP_STRING([--disable-bgpd], [do not build bgpd]))
 452 AC_ARG_ENABLE([ripd],
 453   AS_HELP_STRING([--disable-ripd], [do not build ripd]))
 454 AC_ARG_ENABLE([ripngd],
 455   AS_HELP_STRING([--disable-ripngd], [do not build ripngd]))
 456 AC_ARG_ENABLE([ospfd],
 457   AS_HELP_STRING([--disable-ospfd], [do not build ospfd]))
 458 AC_ARG_ENABLE([ospf6d],
 459   AS_HELP_STRING([--disable-ospf6d], [do not build ospf6d]))
 460 AC_ARG_ENABLE([ldpd],
 461   AS_HELP_STRING([--disable-ldpd], [do not build ldpd]))
 462 AC_ARG_ENABLE([nhrpd],
 463   AS_HELP_STRING([--disable-nhrpd], [do not build nhrpd]))
 464 AC_ARG_ENABLE([eigrpd],
 465   AS_HELP_STRING([--disable-eigrpd], [do not build eigrpd]))
 466 AC_ARG_ENABLE([babeld],
 467   AS_HELP_STRING([--disable-babeld], [do not build babeld]))
 468 AC_ARG_ENABLE([watchfrr],
 469   AS_HELP_STRING([--disable-watchfrr], [do not build watchfrr]))
 470 AC_ARG_ENABLE([isisd],
 471   AS_HELP_STRING([--disable-isisd], [do not build isisd]))
 472 AC_ARG_ENABLE([pimd],
 473   AS_HELP_STRING([--disable-pimd], [do not build pimd]))
 474 AC_ARG_ENABLE([pbrd],
 475   AS_HELP_STRING([--disable-pbrd], [do not build pbrd]))
 476 AC_ARG_ENABLE([sharpd],
 477   AS_HELP_STRING([--enable-sharpd], [build sharpd]))
 478 AC_ARG_ENABLE([staticd],
 479   AS_HELP_STRING([--disable-staticd], [do not build staticd]))
 480 AC_ARG_ENABLE([fabricd],
 481   AS_HELP_STRING([--disable-fabricd], [do not build fabricd]))
 482 AC_ARG_ENABLE([vrrpd],
 483   AS_HELP_STRING([--disable-vrrpd], [do not build vrrpd]))
 484 AC_ARG_ENABLE([bgp-announce],
 485   AS_HELP_STRING([--disable-bgp-announce,], [turn off BGP route announcement]))
 486 AC_ARG_ENABLE([bgp-vnc],
 487   AS_HELP_STRING([--disable-bgp-vnc],[turn off BGP VNC support]))
 488 AC_ARG_ENABLE([bgp-bmp],
 489   AS_HELP_STRING([--disable-bgp-bmp],[turn off BGP BMP support]))
 490 AC_ARG_ENABLE([snmp],
 491   AS_HELP_STRING([--enable-snmp], [enable SNMP support for agentx]))
 492 AC_ARG_ENABLE([config_rollbacks],
 493   AS_HELP_STRING([--enable-config-rollbacks], [enable configuration rollbacks (requires sqlite3)]))
 494 AC_ARG_ENABLE([confd],
 495   AS_HELP_STRING([--enable-confd=ARG], [enable confd integration]))
 496 AC_ARG_ENABLE([sysrepo],
 497   AS_HELP_STRING([--enable-sysrepo], [enable sysrepo integration]))
 498 AC_ARG_ENABLE([grpc],
 499   AS_HELP_STRING([--enable-grpc], [enable the gRPC northbound plugin]))
 500 AC_ARG_ENABLE([zeromq],
 501   AS_HELP_STRING([--enable-zeromq], [enable ZeroMQ handler (libfrrzmq)]))
 502 AC_ARG_WITH([libpam],
 503   AS_HELP_STRING([--with-libpam], [use libpam for PAM support in vtysh]))
 504 AC_ARG_ENABLE([ospfapi],
 505   AS_HELP_STRING([--disable-ospfapi], [do not build OSPFAPI to access the OSPF LSA Database]))
 506 AC_ARG_ENABLE([ospfclient],
 507   AS_HELP_STRING([--disable-ospfclient], [do not build OSPFAPI client for OSPFAPI,
 508                           (this is the default if --disable-ospfapi is set)]))
 509 AC_ARG_ENABLE([multipath],
 510   AS_HELP_STRING([--enable-multipath=ARG], [enable multipath function, ARG must be digit]))
 511 AC_ARG_ENABLE([user],
 512   AS_HELP_STRING([--enable-user=USER], [user to run FRR suite as (default frr)]))
 513 AC_ARG_ENABLE([group],
 514   AS_HELP_STRING([--enable-group=GROUP], [group to run FRR suite as (default frr)]))
 515 AC_ARG_ENABLE([vty_group],
 516   AS_HELP_STRING([--enable-vty-group=ARG], [set vty sockets to have specified group as owner]))
 517 AC_ARG_ENABLE([configfile_mask],
 518   AS_HELP_STRING([--enable-configfile-mask=ARG], [set mask for config files]))
 519 AC_ARG_ENABLE([logfile_mask],
 520   AS_HELP_STRING([--enable-logfile-mask=ARG], [set mask for log files]))
 521 AC_ARG_ENABLE([shell_access],
 522   AS_HELP_STRING([--enable-shell-access], [Allow users to access shell/telnet/ssh]))
 523 AC_ARG_ENABLE([realms],
 524   AS_HELP_STRING([--enable-realms], [enable REALMS support under Linux]))
 525 AC_ARG_ENABLE([rtadv],
 526   AS_HELP_STRING([--disable-rtadv], [disable IPV6 router advertisement feature]))
 527 AC_ARG_ENABLE([irdp],
 528   AS_HELP_STRING([--disable-irdp], [enable IRDP server support in zebra (default if supported)]))
 529 AC_ARG_ENABLE([capabilities],
 530   AS_HELP_STRING([--disable-capabilities], [disable using POSIX capabilities]))
 531 AC_ARG_ENABLE([rusage],
 532   AS_HELP_STRING([--disable-rusage], [disable using getrusage]))
 533 AC_ARG_ENABLE([gcc_ultra_verbose],
 534   AS_HELP_STRING([--enable-gcc-ultra-verbose], [enable ultra verbose GCC warnings]))
 535 AC_ARG_ENABLE([backtrace],
 536   AS_HELP_STRING([--disable-backtrace,], [disable crash backtraces (default autodetect)]))
 537 AC_ARG_ENABLE([time-check],
 538   AS_HELP_STRING([--disable-time-check], [disable slow thread warning messages]))
 539 AC_ARG_ENABLE([pcreposix],
 540   AS_HELP_STRING([--enable-pcreposix], [enable using PCRE Posix libs for regex functions]))
 541 AC_ARG_ENABLE([fpm],
 542   AS_HELP_STRING([--enable-fpm], [enable Forwarding Plane Manager support]))
 543 AC_ARG_ENABLE([systemd],
 544   AS_HELP_STRING([--enable-systemd], [enable Systemd support]))
 545 AC_ARG_ENABLE([werror],
 546   AS_HELP_STRING([--enable-werror], [enable -Werror (recommended for developers only)]))
 547 AC_ARG_ENABLE([cumulus],
 548   AS_HELP_STRING([--enable-cumulus], [enable Cumulus Switch Special Extensions]))
 549 AC_ARG_ENABLE([datacenter],
 550   AS_HELP_STRING([--enable-datacenter], [enable Compilation for Data Center Extensions]))
 551 AC_ARG_ENABLE([fuzzing],
 552   AS_HELP_STRING([--enable-fuzzing], [enable ability to fuzz various parts of FRR]))
 553 AC_ARG_ENABLE([netlink_fuzzing],
 554   AS_HELP_STRING([--enable-netlink-fuzzing], [enable ability to fuzz netlink listening socket in zebra]))
 555 AC_ARG_ENABLE([rr-semantics],
 556   AS_HELP_STRING([--disable-rr-semantics], [disable the v6 Route Replace semantics]))
 557 AC_ARG_ENABLE([protobuf],
 558   AS_HELP_STRING([--enable-protobuf], [Enable experimental protobuf support]))
 559 AC_ARG_ENABLE([oldvpn_commands],
 560   AS_HELP_STRING([--enable-oldvpn-commands], [Keep old vpn commands]))
 561 AC_ARG_ENABLE([rpki],
 562   AS_HELP_STRING([--enable-rpki], [enable RPKI prefix validation support]))
 563 AC_ARG_ENABLE([clippy-only],
 564   AS_HELP_STRING([--enable-clippy-only], [Only build clippy]))
 565 AC_ARG_ENABLE([numeric_version],
 566   AS_HELP_STRING([--enable-numeric-version], [Only numeric digits allowed in version (for Alpine)]))
 567 AC_ARG_ENABLE([gcov],
 568   AS_HELP_STRING([--enable-gcov], [Add code coverage information]))
 569 AC_ARG_ENABLE([bfdd],
 570   AS_HELP_STRING([--disable-bfdd], [do not build bfdd]))
 571 AC_ARG_ENABLE([address-sanitizer],
 572   AS_HELP_STRING([--enable-address-sanitizer], [enable AddressSanitizer support for detecting a wide variety of memory allocation and deallocation errors]))
 573 AC_ARG_ENABLE([thread-sanitizer],
 574   AS_HELP_STRING([--enable-thread-sanitizer], [enable ThreadSanitizer support for detecting data races]))
 575 AC_ARG_ENABLE([memory-sanitizer],
 576   AS_HELP_STRING([--enable-memory-sanitizer], [enable MemorySanitizer support for detecting uninitialized memory reads]))
 577 AC_ARG_WITH([crypto],
 578   AS_HELP_STRING([--with-crypto=<internal|openssl>], [choose between different implementations of cryptographic functions(default value is --with-crypto=internal)]))
 579
 580 #if openssl, else use the internal
 581 AS_IF([test x"${with_crypto}" = x"openssl"], [
 582 AC_CHECK_LIB([crypto], [EVP_DigestInit], [LIBS="$LIBS -lcrypto"], [], [])
 583 if test $ac_cv_lib_crypto_EVP_DigestInit = no; then
 584   AC_MSG_ERROR([build with openssl has been specified but openssl library was not found on your system])
 585 else
 586   AC_DEFINE([CRYPTO_OPENSSL], [1], [Compile with openssl support])
 587 fi
 588 ], [test x"${with_crypto}" = x"internal" || test x"${with_crypto}" = x"" ], [AC_DEFINE([CRYPTO_INTERNAL], [1], [Compile with internal cryptographic implementation])
 589 ], [AC_MSG_ERROR([Unknown value for --with-crypto])]
 590 )
 591
 592 AS_IF([test "${enable_clippy_only}" != "yes"], [
 593 AC_CHECK_HEADERS([json-c/json.h])
 594 AC_CHECK_LIB([json-c], [json_object_get], [LIBS="$LIBS -ljson-c"], [], [-lm])
 595 if test "$ac_cv_lib_json_c_json_object_get" = no; then
 596   AC_CHECK_LIB([json], [json_object_get], [LIBS="$LIBS -ljson"])
 597   if test "$ac_cv_lib_json_json_object_get" = no; then
 598       AC_MSG_ERROR([libjson is needed to compile])
 599   fi
 600 fi
 601 ])
 602
 603 AC_ARG_ENABLE([dev_build],
 604     AS_HELP_STRING([--enable-dev-build], [build for development]))
 605
 606 AC_ARG_ENABLE([lua],
 607     AS_HELP_STRING([--enable-lua], [Build Lua scripting]))
 608
 609 if test x"${enable_time_check}" != x"no" ; then
 610   if test x"${enable_time_check}" = x"yes" -o x"${enable_time_check}" = x ; then
 611     AC_DEFINE([CONSUMED_TIME_CHECK], [5000000], [Consumed Time Check])
 612   else
 613     AC_DEFINE_UNQUOTED([CONSUMED_TIME_CHECK], [$enable_time_check], [Consumed Time Check])
 614   fi
 615 fi
 616
 617 case "${enable_systemd}" in
 618   "no") ;;
 619   "yes")
 620   AC_CHECK_LIB([systemd], [sd_notify], [LIBS="$LIBS -lsystemd"])
 621   if test $ac_cv_lib_systemd_sd_notify = no; then
 622     AC_MSG_ERROR([enable systemd has been specified but systemd development env not found on your system])
 623   else
 624     AC_DEFINE([HAVE_SYSTEMD], [1], [Compile systemd support in])
 625   fi
 626   ;;
 627   "*") ;;
 628 esac
 629
 630 if test "${enable_rr_semantics}" != "no" ; then
 631   AC_DEFINE([HAVE_V6_RR_SEMANTICS], [1], [Compile in v6 Route Replacement Semantics])
 632 fi
 633
 634 if test "${enable_datacenter}" = "yes" ; then
 635   AC_DEFINE([HAVE_DATACENTER], [1], [Compile extensions for a DataCenter])
 636   DFLT_NAME="datacenter"
 637 else
 638   DFLT_NAME="traditional"
 639 fi
 640
 641 if test "${enable_fuzzing}" = "yes" ; then
 642   AC_DEFINE([HANDLE_ZAPI_FUZZING], [1], [Compile extensions to use with a fuzzer])
 643 fi
 644
 645 if test "${enable_netlink_fuzzing}" = "yes" ; then
 646   AC_DEFINE([HANDLE_NETLINK_FUZZING], [1], [Compile extensions to use with a fuzzer for netlink])
 647 fi
 648
 649 if test "${enable_cumulus}" = "yes" ; then
 650   AC_DEFINE([HAVE_CUMULUS], [1], [Compile Special Cumulus Code in])
 651 fi
 652
 653 AC_SUBST([DFLT_NAME])
 654 AC_DEFINE_UNQUOTED([DFLT_NAME], ["$DFLT_NAME"], [Name of the configuration default set])
 655
 656 if test "${enable_shell_access}" = "yes"; then
 657    AC_DEFINE([HAVE_SHELL_ACCESS], [1], [Allow user to use ssh/telnet/bash, be aware this is considered insecure])
 658 fi
 659
 660 #
 661 # Python for clippy
 662 #
 663
 664 AS_IF([test "$host" = "$build"], [
 665   FRR_PYTHON_DEV
 666 ], [
 667   FRR_PYTHON
 668 ])
 669
 670 FRR_PYTHON_MODULES([pytest])
 671
 672 if test "${enable_doc}" != "no"; then
 673   FRR_PYTHON_MODULES([sphinx], , [
 674     if test "${enable_doc}" = "yes"; then
 675       AC_MSG_ERROR([Documentation was explicitly requested with --enable-doc but sphinx is not available for $PYTHON. Please disable docs or install sphinx.])
 676     fi
 677   ])
 678 fi
 679 AM_CONDITIONAL([DOC], [test "${enable_doc}" != "no" -a "$frr_py_mod_sphinx" != "false"])
 680 AM_CONDITIONAL([DOC_HTML], [test "${enable_doc_html}" = "yes"])
 681
 682 FRR_PYTHON_MOD_EXEC([sphinx], [--version], [
 683   PYSPHINX="-m sphinx"
 684 ], [
 685   PYSPHINX="-c 'import sys; from sphinx import main; sys.exit(main(sys.argv))'"
 686 ])
 687 AC_SUBST([PYSPHINX])
 688
 689 #
 690 # Logic for old vpn commands support.
 691 #
 692 if test "$enable_oldvpn_commands" = "yes"; then
 693    AC_DEFINE([KEEP_OLD_VPN_COMMANDS], [1], [Define for compiling with old vpn commands])
 694 fi
 695
 696 #
 697 # End of logic for protobuf support.
 698 #
 699
 700 AC_MSG_CHECKING([if zebra should be configurable to send Route Advertisements])
 701 if test "${enable_rtadv}" != "no"; then
 702   AC_MSG_RESULT([yes])
 703   AC_DEFINE([HAVE_RTADV], [1], [Enable IPv6 Routing Advertisement support])
 704 else
 705   AC_MSG_RESULT([no])
 706 fi
 707
 708 if test x"${enable_user}" = x"no"; then
 709   enable_user=""
 710 else
 711   if test x"${enable_user}" = x"yes" || test x"${enable_user}" = x""; then
 712     enable_user="frr"
 713   fi
 714   AC_DEFINE_UNQUOTED([FRR_USER], ["${enable_user}"], [frr User])
 715 fi
 716
 717 if test x"${enable_group}" = x"no"; then
 718   enable_group=""
 719 else
 720   if test x"${enable_group}" = x"yes" || test x"${enable_group}" = x""; then
 721     enable_group="frr"
 722   fi
 723   AC_DEFINE_UNQUOTED([FRR_GROUP], ["${enable_group}"], [frr Group])
 724 fi
 725
 726 if test x"${enable_vty_group}" = x"yes" ; then
 727   AC_MSG_ERROR([--enable-vty-group requires a group as argument, not yes])
 728 elif test x"${enable_vty_group}" != x""; then
 729   if test x"${enable_vty_group}" != x"no"; then
 730     AC_DEFINE_UNQUOTED([VTY_GROUP], ["${enable_vty_group}"], [VTY Sockets Group])
 731   fi
 732 fi
 733 AC_SUBST([enable_user])
 734 AC_SUBST([enable_group])
 735 AC_SUBST([enable_vty_group])
 736
 737 enable_configfile_mask=${enable_configfile_mask:-0600}
 738 AC_DEFINE_UNQUOTED([CONFIGFILE_MASK], [${enable_configfile_mask}], [Mask for config files])
 739
 740 enable_logfile_mask=${enable_logfile_mask:-0600}
 741 AC_DEFINE_UNQUOTED([LOGFILE_MASK], [${enable_logfile_mask}], [Mask for log files])
 742
 743 MPATH_NUM=16
 744
 745 case "${enable_multipath}" in
 746   0)
 747     MPATH_NUM=64
 748     ;;
 749   [[1-9]|[1-9][0-9]|[1-9][0-9][0-9]])
 750     MPATH_NUM="${enable_multipath}"
 751     ;;
 752   "")
 753     ;;
 754   *)
 755     AC_MSG_FAILURE([Please specify digit to enable multipath ARG])
 756     ;;
 757 esac
 758
 759 AC_DEFINE_UNQUOTED([MULTIPATH_NUM], [$MPATH_NUM], [Maximum number of paths for a route])
 760
 761 AC_DEFINE_UNQUOTED([VTYSH_PAGER], ["$VTYSH_PAGER"], [What pager to use])
 762
 763 dnl --------------------
 764 dnl Enable code coverage
 765 dnl --------------------
 766 AM_CONDITIONAL([HAVE_GCOV], [test '!' "$enable_gcov" = no])
 767
 768 dnl ------------------------------------
 769 dnl Alpine only accepts numeric versions
 770 dnl ------------------------------------
 771 if test "x${enable_numeric_version}" != "x" ; then
 772   VERSION="`echo ${VERSION} | tr -c -d '[[.0-9]]'`"
 773   PACKAGE_VERSION="`echo ${PACKAGE_VERSION} | tr -c -d '[[.0-9]]'`"
 774 fi
 775
 776 dnl -----------------------------------
 777 dnl Add extra version string to package
 778 dnl name, string and version fields.
 779 dnl -----------------------------------
 780 if test "x${EXTRAVERSION}" != "x" ; then
 781   VERSION="${VERSION}${EXTRAVERSION}"
 782   PACKAGE_VERSION="${PACKAGE_VERSION}${EXTRAVERSION}"
 783   AC_SUBST(PACKAGE_EXTRAVERSION, ["${EXTRAVERSION}"])
 784   PACKAGE_STRING="${PACKAGE_STRING}${EXTRAVERSION}"
 785 fi
 786 AC_SUBST([EXTRAVERSION])
 787
 788 if test "x$with_pkg_git_version" = "xyes"; then
 789         if test -d "${srcdir}/.git"; then
 790                 AC_DEFINE([GIT_VERSION], [1], [include git version info])
 791         else    with_pkg_git_version="no"
 792                 AC_MSG_WARN([--with-pkg-git-version given, but this is not a git checkout])
 793         fi
 794 fi
 795 AM_CONDITIONAL([GIT_VERSION], [test "x$with_pkg_git_version" = "xyes"])
 796
 797 AC_CHECK_TOOL([OBJCOPY], [objcopy], [:])
 798 if test "x${OBJCOPY}" != "x:"; then
 799   AC_CACHE_CHECK([for .interp value to use], [frr_cv_interp], [
 800     frr_cv_interp=""
 801     AC_LINK_IFELSE([AC_LANG_SOURCE([[int main() { return 0; }]])], [
 802       if $OBJCOPY -j.interp -Obinary conftest conftest.interp; then
 803         frr_cv_interp="`xargs -0 echo < conftest.interp`"
 804       fi
 805       test -f conftest.interp && rm conftest.interp
 806     ])
 807   ])
 808 fi
 809 if test -n "$frr_cv_interp"; then
 810   AC_DEFINE_UNQUOTED([INTERP], ["$frr_cv_interp"], [.interp value])
 811 fi
 812
 813 dnl -------------------------
 814 dnl Check other header files.
 815 dnl -------------------------
 816 AC_CHECK_HEADERS([stropts.h sys/ksym.h \
 817         linux/version.h asm/types.h])
 818
 819 ac_stdatomic_ok=false
 820 AC_DEFINE([FRR_AUTOCONF_ATOMIC], [1], [did autoconf checks for atomic funcs])
 821 AC_CHECK_HEADER([stdatomic.h],[
 822
 823   AC_MSG_CHECKING([whether _Atomic qualifier works])
 824   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 825 #include <stdatomic.h>
 826 int main(int argc, char **argv) {
 827   _Atomic int i = 0;
 828   return i;
 829 }
 830 ]])], [
 831     AC_DEFINE([HAVE_STDATOMIC_H], [1], [found stdatomic.h])
 832     AC_MSG_RESULT([yes])
 833     ac_stdatomic_ok=true
 834   ], [
 835     AC_MSG_RESULT([no])
 836   ])
 837 ])
 838
 839 AS_IF([$ac_stdatomic_ok], [true], [
 840   AC_MSG_CHECKING([for __atomic_* builtins])
 841   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 842 int main(int argc, char **argv) {
 843   volatile int i = 1;
 844   __atomic_store_n (&i, 0, __ATOMIC_RELEASE);
 845   return __atomic_load_n (&i, __ATOMIC_ACQUIRE);
 846 }
 847 ]])], [
 848     AC_DEFINE([HAVE___ATOMIC], [1], [found __atomic builtins])
 849     AC_MSG_RESULT([yes])
 850   ], [
 851     AC_MSG_RESULT([no])
 852
 853     dnl FreeBSD 9 has a broken stdatomic.h where _Atomic doesn't work
 854     AC_MSG_CHECKING([for __sync_* builtins])
 855     AC_LINK_IFELSE([AC_LANG_SOURCE([[
 856 int main(int argc, char **argv) {
 857   volatile int i = 1;
 858   __sync_fetch_and_sub (&i, 1);
 859   return __sync_val_compare_and_swap (&i, 0, 1);
 860 }
 861 ]])], [
 862       AC_DEFINE([HAVE___SYNC], [1], [found __sync builtins])
 863       AC_MSG_RESULT([yes])
 864
 865       AC_MSG_CHECKING([for __sync_swap builtin])
 866       AC_LINK_IFELSE([AC_LANG_SOURCE([[
 867 int main(int argc, char **argv) {
 868   volatile int i = 1;
 869   return __sync_swap (&i, 2);
 870 }
 871 ]])], [
 872         AC_DEFINE([HAVE___SYNC_SWAP], 1, [found __sync_swap builtin])
 873         AC_MSG_RESULT([yes])
 874       ], [
 875         AC_MSG_RESULT([no])
 876       ])
 877
 878     ], [
 879       AC_MSG_RESULT([no])
 880       AC_MSG_FAILURE([stdatomic.h unavailable and $CC has neither __atomic nor __sync builtins])
 881     ])
 882   ])
 883 ])
 884
 885 AC_CHECK_HEADERS([pthread_np.h],,, [
 886 #include <pthread.h>
 887 ])
 888 AC_CHECK_FUNCS([pthread_setname_np pthread_set_name_np])
 889
 890 needsync=true
 891
 892 AS_IF([$needsync], [
 893   dnl Linux
 894   AC_MSG_CHECKING([for Linux futex() support])
 895   AC_LINK_IFELSE([AC_LANG_PROGRAM([
 896 #ifndef _GNU_SOURCE
 897 #define _GNU_SOURCE
 898 #endif
 899 #include <unistd.h>
 900 #include <limits.h>
 901 #include <sys/time.h>
 902 #include <sys/syscall.h>
 903 #include <linux/futex.h>
 904
 905 int main(void);
 906 ],
 907 [
 908 {
 909   return syscall(SYS_futex, NULL, FUTEX_WAIT, 0, NULL, NULL, 0);
 910 }
 911 ])], [
 912     AC_MSG_RESULT([yes])
 913     AC_DEFINE(HAVE_SYNC_LINUX_FUTEX,,Have Linux futex support)
 914     needsync=false
 915   ], [
 916     AC_MSG_RESULT([no])
 917   ])
 918 ])
 919
 920 AS_IF([$needsync], [
 921   dnl FreeBSD
 922   AC_MSG_CHECKING([for FreeBSD _umtx_op() support])
 923   AC_LINK_IFELSE([AC_LANG_PROGRAM([
 924 #include <errno.h>
 925 #include <stdlib.h>
 926 #include <sys/types.h>
 927 #include <sys/umtx.h>
 928 int main(void);
 929 ],
 930 [
 931 {
 932   return _umtx_op(NULL, UMTX_OP_WAIT_UINT, 0, NULL, NULL);
 933 }
 934 ])], [
 935     AC_MSG_RESULT([yes])
 936     AC_DEFINE(HAVE_SYNC_UMTX_OP,,Have FreeBSD _umtx_op() support)
 937     needsync=false
 938   ], [
 939     AC_MSG_RESULT([no])
 940   ])
 941 ])
 942
 943 AS_IF([$needsync], [
 944   dnl OpenBSD patch (not upstream at the time of writing this)
 945   dnl https://marc.info/?l=openbsd-tech&m=147299508409549&w=2
 946   AC_MSG_CHECKING([for OpenBSD futex() support])
 947   AC_LINK_IFELSE([AC_LANG_PROGRAM([
 948 #include <sys/futex.h>
 949 int main(void);
 950 ],
 951 [
 952 {
 953   return futex(NULL, FUTEX_WAIT, 0, NULL, NULL, 0);
 954 }
 955 ])], [
 956     AC_MSG_RESULT([yes])
 957     AC_DEFINE(HAVE_SYNC_OPENBSD_FUTEX,,Have OpenBSD futex support)
 958     needsync=false
 959   ], [
 960     AC_MSG_RESULT([no])
 961   ])
 962 ])
 963
 964 dnl Utility macro to avoid retyping includes all the time
 965 m4_define([FRR_INCLUDES],
 966 [#ifdef SUNOS_5
 967 #define _POSIX_C_SOURCE 200809L
 968 #define __EXTENSIONS__
 969 #endif
 970 #include <stdio.h>
 971 #include <stdlib.h>
 972 #include <stddef.h>
 973 #include <sys/types.h>
 974 /* sys/conf.h depends on param.h on FBSD at least */
 975 #include <sys/param.h>
 976 /* Required for MAXSIG */
 977 #include <signal.h>
 978 #include <sys/socket.h>
 979 #ifdef __APPLE__
 980 # define __APPLE_USE_RFC_3542
 981 #endif
 982 #include <netinet/in.h>
 983 #include <sys/time.h>
 984 #include <time.h>
 985 #include <net/if.h>
 986 ])dnl
 987
 988 dnl Same applies for HAVE_NET_IF_VAR_H, which HAVE_NETINET6_ND6_H and
 989 dnl HAVE_NETINET_IN_VAR_H depend upon. But if_var.h depends on if.h, hence
 990 dnl an additional round for it.
 991
 992 AC_CHECK_HEADERS([net/if_var.h], [], [], [FRR_INCLUDES])
 993
 994 m4_define([FRR_INCLUDES],
 995 FRR_INCLUDES
 996 [#if HAVE_NET_IF_VAR_H
 997 # include <net/if_var.h>
 998 #endif
 999 ])dnl
1000
1001 AC_CHECK_HEADERS([netinet/in_var.h \
1002         net/if_dl.h net/netopt.h \
1003         inet/nd.h netinet/ip_icmp.h \
1004         sys/sysctl.h sys/sockio.h sys/conf.h],
1005         [], [], [FRR_INCLUDES])
1006
1007 AC_CHECK_HEADERS([ucontext.h], [], [],
1008 [#ifndef __USE_GNU
1009 #define __USE_GNU
1010 #endif /* __USE_GNU */
1011 FRR_INCLUDES
1012 ])
1013
1014 m4_define([UCONTEXT_INCLUDES],
1015 [#include <ucontext.h>])dnl
1016
1017 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.uc_regs],
1018   [], [], [UCONTEXT_INCLUDES])
1019 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs],
1020   [AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs.nip],
1021    [], [], [UCONTEXT_INCLUDES])],
1022   [], [UCONTEXT_INCLUDES])
1023 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.gregs],
1024   [], [], [UCONTEXT_INCLUDES])
1025
1026 m4_define([FRR_INCLUDES],
1027 FRR_INCLUDES
1028 [
1029 #include <sys/un.h>
1030 #include <netinet/in_systm.h>
1031 #if HAVE_NETINET_IN_VAR_H
1032 # include <netinet/in_var.h>
1033 #endif
1034 #if HAVE_NET_IF_DL_H
1035 # include <net/if_dl.h>
1036 #endif
1037 #if HAVE_NET_NETOPT_H
1038 # include <net/netopt.h>
1039 #endif
1040 #include <net/route.h>
1041 #if HAVE_INET_ND_H
1042 # include <inet/nd.h>
1043 #endif
1044 #include <arpa/inet.h>
1045 /* Required for IDRP */
1046 #if HAVE_NETINET_IP_ICMP_H
1047 # include <netinet/ip_icmp.h>
1048 #endif
1049 ])dnl
1050
1051 dnl V6 headers are checked below, after we check for v6
1052
1053 AC_MSG_CHECKING([which operating system interface to use])
1054 case "$host_os" in
1055   sunos* | solaris2*)
1056     AC_MSG_RESULT([Solaris])
1057
1058     AC_DEFINE([SUNOS_5], [1], [SunOS 5])
1059     AC_DEFINE([SOLARIS_IPV6], [1], Solaris IPv6)
1060     AC_DEFINE([_POSIX_C_SOURCE], [200809L], [enable POSIX.1-2008 and XPG7/SUSv4])
1061
1062     AC_CHECK_LIB([socket], [main])
1063     AC_CHECK_LIB([nsl], [main])
1064     AC_CHECK_LIB([umem], [main])
1065     SOLARIS="solaris"
1066     AC_MSG_WARN([--Solaris support is being considered for deprecation, please let us know if you are still using this--])
1067     ;;
1068   linux*)
1069     AC_MSG_RESULT([Linux])
1070
1071     AC_DEFINE([GNU_LINUX], [1], [GNU Linux])
1072     AC_DEFINE([HAVE_NETLINK], [1], [netlink])
1073     AC_DEFINE([LINUX_IPV6], [1], [Linux IPv6 stack])
1074
1075     dnl Linux has a compilation problem with mixing
1076     dnl netinet/in.h and linux/in6.h they are not
1077     dnl compatible.  There has been discussion on
1078     dnl how to fix it but no real progress on implementation
1079     dnl when they fix it, remove this
1080     AC_DEFINE([IPV6_MINHOPCOUNT], [73], [Linux ipv6 Min Hop Count])
1081     ;;
1082   openbsd*)
1083     AC_MSG_RESULT([OpenBSD])
1084
1085     AC_DEFINE([OPEN_BSD], [1], [OpenBSD])
1086     AC_DEFINE([KAME], [1], [KAME IPv6])
1087     AC_DEFINE([BSD_V6_SYSCTL], [1], [BSD v6 sysctl to turn on and off forwarding])
1088
1089     if test "x${enable_pimd}" != "xno"; then
1090       case "$host_os" in
1091       openbsd6.0)
1092         ;;
1093       openbsd[6-9]*)
1094         AC_MSG_FAILURE([pimd cannot be enabled as PIM support has been removed from OpenBSD 6.1])
1095         ;;
1096       esac
1097     fi
1098     ;;
1099   *)
1100     AC_MSG_RESULT([BSD])
1101
1102     AC_DEFINE([HAVE_NET_RT_IFLIST], [1], [NET_RT_IFLIST])
1103     AC_DEFINE([KAME], [1], [KAME IPv6])
1104     AC_DEFINE([BSD_V6_SYSCTL], [1], [BSD v6 sysctl to turn on and off forwarding])
1105     ;;
1106 esac
1107 AM_CONDITIONAL([SOLARIS], [test "${SOLARIS}" = "solaris"])
1108
1109 AC_SYS_LARGEFILE
1110
1111 dnl ------------------------
1112 dnl Integrated REALMS option
1113 dnl ------------------------
1114 if test "${enable_realms}" = "yes"; then
1115     case "$host_os" in
1116       linux*)
1117        AC_DEFINE([SUPPORT_REALMS], [1], [Realms support])
1118        ;;
1119       *)
1120        echo "Sorry, only Linux has REALMS support"
1121        exit 1
1122        ;;
1123     esac
1124 fi
1125
1126 dnl -------------------------------
1127 dnl Endian-ness check
1128 dnl -------------------------------
1129 AC_WORDS_BIGENDIAN
1130
1131 dnl ---------------
1132 dnl other functions
1133 dnl ---------------
1134 AC_CHECK_FUNCS([ \
1135         strlcat strlcpy \
1136         getgrouplist])
1137
1138 dnl ##########################################################################
1139 dnl LARGE if block spans a lot of "configure"!
1140 if test "${enable_clippy_only}" != "yes"; then
1141 dnl ##########################################################################
1142
1143 #
1144 # Logic for protobuf support.
1145 #
1146 if test "$enable_protobuf" = "yes"; then
1147   # Check for protoc & protoc-c
1148
1149   # protoc is not required, it's only for a "be nice" helper target
1150   AC_CHECK_PROGS([PROTOC], [protoc], [/bin/false])
1151
1152   AC_CHECK_PROGS([PROTOC_C], [protoc-c], [/bin/false])
1153   if test "$PROTOC_C" = "/bin/false"; then
1154     AC_MSG_FAILURE([protobuf requested but protoc-c not found.  Install protobuf-c.])
1155   fi
1156
1157   PKG_CHECK_MODULES([PROTOBUF_C], [libprotobuf-c >= 0.14],, [
1158     AC_MSG_FAILURE([protobuf requested but libprotobuf-c not found.  Install protobuf-c.])
1159   ])
1160   AC_CHECK_HEADER([google/protobuf-c/protobuf-c.h], [], [
1161     AC_MSG_FAILURE([protobuf requested but protobuf-c.h not found.  Install protobuf-c.])
1162   ])
1163
1164   AC_DEFINE([HAVE_PROTOBUF], [1], [protobuf])
1165 fi
1166
1167
1168 dnl ---------------------
1169 dnl Integrated VTY option
1170 dnl ---------------------
1171 case "${enable_vtysh}" in
1172 "no")
1173   VTYSH="";;
1174 *)
1175   VTYSH="vtysh";
1176   AC_DEFINE([VTYSH], [1], [VTY shell])
1177
1178   prev_libs="$LIBS"
1179   AC_CHECK_LIB([readline], [main], [
1180     LIBREADLINE="-lreadline"
1181   ], [
1182     dnl readline failed - it might be incorrectly linked and missing its
1183     dnl termcap/tinfo/curses dependency.  see if we can fix that...
1184     AC_SEARCH_LIBS([tputs], [termcap tinfo curses ncurses], [
1185       LIBREADLINE="$ac_cv_search_tputs"
1186     ], [
1187       AC_MSG_ERROR([libreadline (needed for vtysh) not found and/or missing dependencies])
1188     ])
1189
1190     dnl re-try with the lib we found above
1191     unset ac_cv_lib_readline_main
1192     AC_CHECK_LIB([readline], [main], [
1193       LIBREADLINE="-lreadline $LIBREADLINE"
1194     ], [
1195       AC_MSG_ERROR([libreadline (needed for vtysh) not found and/or missing dependencies])
1196     ], [$LIBREADLINE])
1197   ], [])
1198   LIBS="$prev_libs"
1199
1200   AC_CHECK_HEADER([readline/history.h])
1201   if test $ac_cv_header_readline_history_h = no;then
1202     AC_MSG_ERROR([readline is too old to have readline/history.h, please update to the latest readline library.])
1203   fi
1204   AC_CHECK_LIB([readline], [rl_completion_matches], [true], [], [$LIBREADLINE])
1205   if test $ac_cv_lib_readline_rl_completion_matches = no; then
1206     AC_DEFINE([rl_completion_matches], [completion_matches], [Old readline])
1207   fi
1208   AC_CHECK_LIB([readline], [append_history], [frr_cv_append_history=yes], [frr_cv_append_history=no], [$LIBREADLINE])
1209   if test "$frr_cv_append_history" = yes; then
1210     AC_DEFINE([HAVE_APPEND_HISTORY], [1], [Have history.h append_history])
1211   fi
1212   ;;
1213 esac
1214 AC_SUBST([LIBREADLINE])
1215
1216 dnl ----------
1217 dnl PAM module
1218 dnl
1219 dnl FRR detects the PAM library it is built against by checking for a
1220 dnl functional pam_misc.h (Linux-PAM) or openpam.h (OpenPAM) header. pam_misc.h
1221 dnl is known to #include pam_appl.h, the standard header of a PAM library, and
1222 dnl openpam.h doesn't do that, although depends on the header too. Hence a
1223 dnl little assistance to AC_CHECK_HEADER is necessary for the proper detection
1224 dnl of OpenPAM.
1225 dnl ----------
1226 if test "$with_libpam" = "yes"; then
1227   AC_CHECK_HEADER([security/pam_misc.h],
1228     [AC_DEFINE([HAVE_PAM_MISC_H], [1], [Have pam_misc.h])
1229      AC_DEFINE([PAM_CONV_FUNC], [misc_conv], [Have misc_conv])
1230      pam_conv_func="misc_conv"
1231     ],
1232     [], FRR_INCLUDES)
1233   AC_CHECK_HEADER([security/openpam.h],
1234     [AC_DEFINE([HAVE_OPENPAM_H], [1], [Have openpam.h])
1235      AC_DEFINE([PAM_CONV_FUNC], [openpam_ttyconv], [Have openpam_ttyconv])
1236      pam_conv_func="openpam_ttyconv"
1237     ],
1238     [], FRR_INCLUDES[#include <security/pam_appl.h>])
1239   if test -z "$ac_cv_header_security_pam_misc_h$ac_cv_header_security_openpam_h" ; then
1240     AC_MSG_WARN([*** pam support will not be built ***])
1241     with_libpam="no"
1242   fi
1243 fi
1244
1245 if test "$with_libpam" = "yes"; then
1246 dnl took this test from proftpds configure.in and suited to our needs
1247 dnl -------------------------------------------------------------------------
1248 dnl
1249 dnl This next check looks funky due to a linker problem with some versions
1250 dnl of the PAM library.  Prior to 0.72 release, the Linux PAM shared library
1251 dnl omitted requiring libdl linking information. PAM-0.72 or better ships
1252 dnl with RedHat 6.2 and Debian 2.2 or better.
1253 AC_CHECK_LIB([pam], [pam_start],
1254   [AC_CHECK_LIB([pam], [$pam_conv_func],
1255     [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1256      LIBPAM="-lpam"],
1257     [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1258      LIBPAM="-lpam -lpam_misc"]
1259     )
1260   ],
1261
1262   [AC_CHECK_LIB([pam], [pam_end],
1263     [AC_CHECK_LIB([pam], [$pam_conv_func],
1264       [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1265        LIBPAM="-lpam -ldl"],
1266       [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1267        LIBPAM="-lpam -ldl -lpam_misc"]
1268      )
1269   ],AC_MSG_WARN([*** pam support will not be built ***]),
1270   [-ldl])
1271   ]
1272 )
1273 fi
1274 AC_SUBST([LIBPAM])
1275
1276 dnl -------------------------------
1277 dnl bgpd needs pow() and hence libm
1278 dnl -------------------------------
1279 TMPLIBS="$LIBS"
1280 LIBS=""
1281 AC_SEARCH_LIBS([pow], [m], [
1282   LIBM="$LIBS"
1283 ], [
1284   AC_MSG_WARN([Unable to find working pow function - bgpd may not link])
1285 ])
1286 LIBS="$TMPLIBS"
1287 AC_SUBST([LIBM])
1288
1289 AC_CHECK_FUNCS([ppoll], [
1290   AC_DEFINE([HAVE_PPOLL], [1], [have Linux/BSD ppoll()])
1291 ])
1292 AC_CHECK_FUNCS([pollts], [
1293   AC_DEFINE([HAVE_POLLTS], [1], [have NetBSD pollts()])
1294 ])
1295
1296 AC_CHECK_HEADER([asm-generic/unistd.h],
1297                 [AC_CHECK_DECL(__NR_setns,
1298                                AC_DEFINE([HAVE_NETNS], [1], [Have netns]),,
1299                                FRR_INCLUDES [#include <asm-generic/unistd.h>
1300                                ])
1301                  AC_CHECK_FUNCS([setns])]
1302                )
1303
1304 dnl --------------------------
1305 dnl Determine IS-IS I/O method
1306 dnl --------------------------
1307 AC_DEFINE([ISIS_METHOD_PFPACKET], [1], [constant value for isis method pfpacket])
1308 AC_DEFINE([ISIS_METHOD_DLPI], [2], [constant value for isis method dlpi])
1309 AC_DEFINE([ISIS_METHOD_BPF], [3], [constant value for isis method bpf])
1310 AC_CHECK_HEADER([net/bpf.h])
1311 AC_CHECK_HEADER([sys/dlpi.h])
1312 AC_MSG_CHECKING([zebra IS-IS I/O method])
1313
1314 case "$host_os" in
1315   linux*)
1316     AC_MSG_RESULT([pfpacket])
1317     ISIS_METHOD_MACRO="ISIS_METHOD_PFPACKET"
1318     ;;
1319   solaris* | sunos*)
1320     AC_MSG_RESULT([DLPI])
1321     ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1322     ;;
1323   *)
1324     if test $ac_cv_header_net_bpf_h = no; then
1325       if test $ac_cv_header_sys_dlpi_h = no; then
1326         AC_MSG_RESULT([none])
1327         if test "${enable_isisd}" = yes -o "${enable_fabricd}" = yes; then
1328           AC_MSG_FAILURE([IS-IS support requested but no packet backend found])
1329         fi
1330         AC_MSG_WARN([*** IS-IS support will not be built ***])
1331         enable_isisd="no"
1332         enable_fabricd="no"
1333       else
1334         AC_MSG_RESULT([DLPI])
1335       fi
1336       ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1337     else
1338       AC_MSG_RESULT([BPF])
1339       ISIS_METHOD_MACRO="ISIS_METHOD_BPF"
1340     fi
1341     ;;
1342 esac
1343 AC_DEFINE_UNQUOTED([ISIS_METHOD], [$ISIS_METHOD_MACRO], [selected method for isis, == one of the constants])
1344
1345 dnl ---------------------------------------------------------------
1346 dnl figure out how to specify an interface in multicast sockets API
1347 dnl ---------------------------------------------------------------
1348 AC_CHECK_MEMBERS([struct ip_mreqn.imr_ifindex], [], [], FRR_INCLUDES)
1349
1350 AC_CHECK_HEADERS([linux/mroute.h], [], [],[
1351         #include <sys/socket.h>
1352         #include <netinet/in.h>
1353         #define _LINUX_IN_H             /* For Linux <= 2.6.25 */
1354         #include <linux/types.h>
1355 ])
1356
1357 m4_define([FRR_INCLUDES],
1358 FRR_INCLUDES
1359 [#if HAVE_LINUX_MROUTE_H
1360 # include <linux/mroute.h>
1361 #endif
1362 ])dnl
1363
1364 AC_CHECK_HEADERS([netinet/ip_mroute.h], [], [],[
1365         #include <sys/socket.h>
1366         #include <sys/types.h>
1367         #include <netinet/in.h>
1368         #include <net/route.h>
1369 ])
1370
1371 m4_define([FRR_INCLUDES],
1372 FRR_INCLUDES
1373 [#if HAVE_NETINET_IP_MROUTE_H
1374 # include <netinet/ip_mroute.h>
1375 #endif
1376 ])dnl
1377
1378 AC_MSG_CHECKING([for BSD struct ip_mreq hack])
1379 AC_TRY_COMPILE([#include <sys/param.h>],
1380 [#if (defined(__FreeBSD__) && ((__FreeBSD_version >= 500022 && __FreeBSD_version < 700000) || (__FreeBSD_version < 500000 && __FreeBSD_version >= 440000))) || (defined(__NetBSD__) && defined(__NetBSD_Version__) && __NetBSD_Version__ >= 106010000) || defined(__OpenBSD__) || defined(__APPLE__) || defined(__DragonFly__) || defined(__sun)
1381   return (0);
1382 #else
1383   #error No support for BSD struct ip_mreq hack detected
1384 #endif],[AC_MSG_RESULT([yes])
1385 AC_DEFINE([HAVE_BSD_STRUCT_IP_MREQ_HACK], [1], [Can pass ifindex in struct ip_mreq])],
1386 AC_MSG_RESULT([no]))
1387
1388 AC_MSG_CHECKING([for RFC3678 protocol-independed API])
1389 AC_TRY_COMPILE([
1390 #include <sys/types.h>
1391 #include <netinet/in.h>
1392 ], [struct group_req gr; int sock; setsockopt(sock, IPPROTO_IP, MCAST_JOIN_GROUP, (void*)&gr, sizeof(gr));
1393 ], [AC_MSG_RESULT([yes])
1394 AC_DEFINE([HAVE_RFC3678], [1], [Have RFC3678 protocol-independed API])],
1395 AC_MSG_RESULT([no]))
1396
1397 dnl ---------------------------------------------------------------
1398 dnl figure out how to check link-state
1399 dnl ---------------------------------------------------------------
1400 AC_CHECK_HEADER([net/if_media.h],
1401   [m4_define([LINK_DETECT_INCLUDES],
1402     FRR_INCLUDES
1403     [#include <net/if_media.h>
1404   ])
1405   AC_CHECK_MEMBERS([struct ifmediareq.ifm_status],
1406     AC_DEFINE([HAVE_BSD_LINK_DETECT], [1], [BSD link-detect]),
1407     [], LINK_DETECT_INCLUDES)],
1408   [],
1409   FRR_INCLUDES)
1410
1411 dnl ---------------------------------------------------------------
1412 dnl Additional, newer way to check link-state using ifi_link_state.
1413 dnl Not available in all BSD's when ifmediareq available
1414 dnl ---------------------------------------------------------------
1415 AC_CHECK_MEMBERS([struct if_data.ifi_link_state],
1416   AC_DEFINE([HAVE_BSD_IFI_LINK_STATE], [1], [BSD ifi_link_state available]),
1417   [], FRR_INCLUDES)
1418
1419 dnl ------------------------
1420 dnl TCP_MD5SIG socket option
1421 dnl ------------------------
1422
1423 AC_CHECK_HEADER([netinet/tcp.h],
1424    [m4_define([MD5_INCLUDES],
1425       FRR_INCLUDES
1426       [#include <netinet/tcp.h>
1427     ])
1428     AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)],
1429    [],
1430    FRR_INCLUDES)
1431 if test $ac_cv_have_decl_TCP_MD5SIG = no; then
1432   AC_CHECK_HEADER([linux/tcp.h],
1433        [m4_define([MD5_INCLUDES],
1434           FRR_INCLUDES
1435           [#include <linux/tcp.h>
1436         ])
1437        AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)])
1438 fi
1439
1440 AC_SUBST([SOLARIS])
1441 AC_CHECK_LIB([crypt], [crypt], [],
1442                     [AC_CHECK_LIB([crypto], [DES_crypt])])
1443 AC_CHECK_LIB([resolv], [res_init])
1444
1445 dnl ---------------------------
1446 dnl check system has PCRE regexp
1447 dnl ---------------------------
1448 if test "x$enable_pcreposix" = "xyes"; then
1449   AC_CHECK_LIB([pcreposix], [regexec], [], [
1450     AC_MSG_ERROR([--enable-pcreposix given but unable to find libpcreposix])
1451   ])
1452 fi
1453 AC_SUBST([HAVE_LIBPCREPOSIX])
1454
1455 dnl ##########################################################################
1456 dnl test "${enable_clippy_only}" != "yes"
1457 fi
1458 dnl END OF LARGE if block
1459 dnl ##########################################################################
1460
1461 dnl ------------------
1462 dnl check C-Ares library
1463 dnl ------------------
1464 PKG_CHECK_MODULES([CARES], [libcares], [
1465   c_ares_found=true
1466 ],[
1467   c_ares_found=false
1468 ])
1469 AM_CONDITIONAL([CARES], [$c_ares_found])
1470
1471
1472 dnl ----------------------------------------------------------------------------
1473 dnl figure out if domainname is available in the utsname struct (GNU extension).
1474 dnl ----------------------------------------------------------------------------
1475 AC_CHECK_MEMBERS([struct utsname.domainname], [], [], [#include <sys/utsname.h>])
1476
1477 dnl ------------------
1478 dnl IPv6 header checks
1479 dnl ------------------
1480 AC_CHECK_HEADERS([netinet6/in6.h netinet/in6_var.h \
1481         netinet6/in6_var.h netinet6/nd6.h], [], [],
1482         FRR_INCLUDES)
1483
1484 m4_define([FRR_INCLUDES],dnl
1485 FRR_INCLUDES
1486 [#if HAVE_NETINET6_IN6_H
1487 #include <netinet6/in6.h>
1488 #endif
1489 #if HAVE_NETINET_IN6_VAR_H
1490 #include <netinet/in6_var.h>
1491 #endif
1492 #include <netinet/icmp6.h>
1493 #if HAVE_NETINET6_IN6_VAR_H
1494 # include <netinet6/in6_var.h>
1495 #endif
1496 #if HAVE_NETINET6_ND6_H
1497 # include <netinet6/nd6.h>
1498 #endif
1499 ])dnl
1500
1501 dnl --------------------
1502 dnl Daemon disable check
1503 dnl --------------------
1504
1505 AS_IF([test "${enable_ldpd}" != "no"], [
1506   AC_DEFINE([HAVE_LDPD], [1], [ldpd])
1507 ])
1508
1509 if test "$enable_bfdd" = "no"; then
1510   AC_DEFINE([HAVE_BFDD], [0], [bfdd])
1511   BFDD=""
1512 else
1513   AC_DEFINE([HAVE_BFDD], [1], [bfdd])
1514   BFDD="bfdd"
1515
1516   case $host_os in
1517     linux*)
1518       AC_DEFINE([BFD_LINUX], [1], [bfdd])
1519       ;;
1520
1521     *)
1522       AC_DEFINE([BFD_BSD], [1], [bfdd])
1523       ;;
1524   esac
1525 fi
1526
1527 if test "$ac_cv_lib_json_c_json_object_get" = no -a "x$BFDD" = "xbfdd"; then
1528   AC_MSG_ERROR(["you must use json-c library to use bfdd"])
1529 fi
1530
1531 NHRPD=""
1532 case "$host_os" in
1533   linux*)
1534     case "${enable_nhrpd}" in
1535       no)
1536         ;;
1537       yes)
1538         if test "${enable_clippy_only}" != "yes"; then
1539         if test "$c_ares_found" != "true" ; then
1540           AC_MSG_ERROR([nhrpd requires libcares.  Please install c-ares and its -dev headers.])
1541         fi
1542         fi
1543         NHRPD="nhrpd"
1544         ;;
1545       *)
1546         if test "$c_ares_found" = "true" ; then
1547           NHRPD="nhrpd"
1548         fi
1549         ;;
1550     esac
1551     ;;
1552   *)
1553     if test "${enable_nhrpd}" = "yes"; then
1554       AC_MSG_ERROR([nhrpd requires kernel APIs that are only present on Linux.])
1555     fi
1556     ;;
1557 esac
1558
1559 if test "${enable_watchfrr}" = "no";then
1560   WATCHFRR=""
1561 else
1562   WATCHFRR="watchfrr"
1563 fi
1564
1565 OSPFCLIENT=""
1566 if test "${enable_ospfapi}" != "no";then
1567     AC_DEFINE([SUPPORT_OSPF_API], [1], [OSPFAPI])
1568
1569   if test "${enable_ospfclient}" != "no";then
1570       OSPFCLIENT="ospfclient"
1571   fi
1572 fi
1573
1574 if test "${enable_bgp_announce}" = "no";then
1575   AC_DEFINE([DISABLE_BGP_ANNOUNCE], [1], [Disable BGP installation to zebra])
1576 else
1577   AC_DEFINE([DISABLE_BGP_ANNOUNCE], [0], [Disable BGP installation to zebra])
1578 fi
1579
1580 if test "${enable_bgp_vnc}" != "no";then
1581   AC_DEFINE([ENABLE_BGP_VNC], [1], [Enable BGP VNC support])
1582 fi
1583
1584 bgpd_bmp=false
1585 case "${enable_bmp}" in
1586   no)
1587     ;;
1588   yes)
1589     if test "$c_ares_found" != "true" ; then
1590       AC_MSG_ERROR([BMP support requires libcares.  Please install c-ares and its -dev headers.])
1591     fi
1592     bgpd_bmp=true
1593     ;;
1594   *)
1595     if test "$c_ares_found" = "true" ; then
1596       bgpd_bmp=true
1597     fi
1598     ;;
1599 esac
1600
1601 dnl ##########################################################################
1602 dnl LARGE if block
1603 if test "${enable_clippy_only}" != "yes"; then
1604 dnl ##########################################################################
1605
1606 dnl ------------------
1607 dnl check Net-SNMP library
1608 dnl ------------------
1609 if test "${enable_snmp}" != "" -a "${enable_snmp}" != "no"; then
1610    AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], [no])
1611    if test x"$NETSNMP_CONFIG" = x"no"; then
1612       AC_MSG_ERROR([--enable-snmp given but unable to find net-snmp-config])
1613    fi
1614    SNMP_LIBS="`${NETSNMP_CONFIG} --agent-libs`"
1615    SNMP_CFLAGS="`${NETSNMP_CONFIG} --base-cflags`"
1616    # net-snmp lists all of its own dependencies.  we absolutely do not want that
1617    # among other things we avoid a GPL vs. OpenSSL license conflict here
1618    for removelib in crypto ssl sensors pci wrap; do
1619      SNMP_LIBS="`echo $SNMP_LIBS | sed -e 's/\(^\|\s\)-l'$removelib'\b/ /g' -e 's/\(^\|\s\)\([^\s]*\/\)\?lib'$removelib'\.[^\s]\+\b/ /g'`"
1620    done
1621    AC_MSG_CHECKING([whether we can link to Net-SNMP])
1622    AC_LINK_IFELSE_FLAGS([$SNMP_CFLAGS], [$SNMP_LIBS], [AC_LANG_PROGRAM([
1623 int main(void);
1624 ],
1625 [
1626 {
1627   return 0;
1628 }
1629 ])], [
1630      AC_MSG_RESULT([no])
1631      AC_MSG_ERROR([--enable-snmp given but not usable])])
1632    case "${enable_snmp}" in
1633      yes)
1634       SNMP_METHOD=agentx
1635       ;;
1636      agentx)
1637       SNMP_METHOD="${enable_snmp}"
1638       ;;
1639      *)
1640       AC_MSG_ERROR([--enable-snmp given with an unknown method (${enable_snmp}). Use yes or agentx])
1641       ;;
1642    esac
1643    AH_TEMPLATE([SNMP_AGENTX], [Use SNMP AgentX to interface with snmpd])
1644    AC_DEFINE_UNQUOTED(AS_TR_CPP(SNMP_${SNMP_METHOD}),,[SNMP method to interface with snmpd])
1645 fi
1646 AC_SUBST([SNMP_LIBS])
1647 AC_SUBST([SNMP_CFLAGS])
1648
1649 dnl ---------------
1650 dnl libyang
1651 dnl ---------------
1652 PKG_CHECK_MODULES([LIBYANG], [libyang >= 0.16.105], , [
1653   AC_MSG_ERROR([libyang (>= 0.16.105) was not found on your system.])
1654 ])
1655 ac_cflags_save="$CFLAGS"
1656 CFLAGS="$CFLAGS $LIBYANG_CFLAGS"
1657 AC_CHECK_MEMBER([struct lyd_node.priv], [], [
1658   AC_MSG_ERROR([m4_normalize([
1659     libyang needs to be compiled with ENABLE_LYD_PRIV=ON.
1660     Instructions for this are included in the build documentation for your platform at http://docs.frrouting.org/projects/dev-guide/en/latest/building.html])
1661   ])
1662 ], [[#include <libyang/libyang.h>]])
1663 CFLAGS="$ac_cflags_save"
1664
1665 dnl ---------------
1666 dnl configuration rollbacks
1667 dnl ---------------
1668 SQLITE3=false
1669 if test "$enable_config_rollbacks" = "yes"; then
1670   PKG_CHECK_MODULES([SQLITE3], [sqlite3], [
1671     AC_DEFINE([HAVE_CONFIG_ROLLBACKS], [1], [Enable configuration rollbacks])
1672     AC_DEFINE([HAVE_SQLITE3], [1], [Enable sqlite3 database])
1673     SQLITE3=true
1674   ], [
1675     AC_MSG_ERROR([--enable-config-rollbacks given but sqlite3 was not found on your system.])
1676   ])
1677 fi
1678
1679 dnl ---------------
1680 dnl confd
1681 dnl ---------------
1682 if test "$enable_confd" != "" -a "$enable_confd" != "no"; then
1683    AC_CHECK_PROG([CONFD], [confd], [confd], [/bin/false], "${enable_confd}/bin")
1684    if test "x$CONFD" = "x/bin/false"; then
1685       AC_MSG_ERROR([confd was not found on your system.])]
1686    fi
1687    CONFD_CFLAGS="-I${enable_confd}/include -L${enable_confd}/lib"
1688    AC_SUBST([CONFD_CFLAGS])
1689    CONFD_LIBS="-lconfd"
1690    AC_SUBST([CONFD_LIBS])
1691    AC_DEFINE([HAVE_CONFD], [1], [Enable confd integration])
1692 fi
1693
1694 dnl ---------------
1695 dnl sysrepo
1696 dnl ---------------
1697 if test "$enable_sysrepo" = "yes"; then
1698   PKG_CHECK_MODULES([SYSREPO], [libsysrepo],
1699       [AC_DEFINE([HAVE_SYSREPO], [1], [Enable sysrepo integration])
1700       SYSREPO=true],
1701       [SYSREPO=false
1702       AC_MSG_ERROR([sysrepo was not found on your system.])]
1703   )
1704 fi
1705
1706 dnl ---------------
1707 dnl gRPC
1708 dnl ---------------
1709 if test "$enable_grpc" = "yes"; then
1710   PKG_CHECK_MODULES([GRPC], [grpc grpc++ protobuf], [
1711     AC_CHECK_PROGS([PROTOC], [protoc], [/bin/false])
1712     if test "$PROTOC" = "/bin/false"; then
1713       AC_MSG_FAILURE([grpc requested but protoc not found.])
1714     fi
1715
1716     AC_DEFINE([HAVE_GRPC], [1], [Enable the gRPC northbound plugin])
1717     GRPC=true
1718   ], [
1719     GRPC=false
1720     AC_MSG_ERROR([grpc/grpc++ were not found on your system.])
1721   ])
1722 fi
1723
1724 dnl ------
1725 dnl ZeroMQ
1726 dnl ------
1727 if test "x$enable_zeromq" != "xno"; then
1728   PKG_CHECK_MODULES([ZEROMQ], [libzmq >= 4.0.0], [
1729     AC_DEFINE([HAVE_ZEROMQ], [1], [Enable ZeroMQ support])
1730     ZEROMQ=true
1731   ], [
1732     if test "x$enable_zeromq" = "xyes"; then
1733       AC_MSG_ERROR([configuration specifies --enable-zeromq but libzmq was not found])
1734     fi
1735   ])
1736 fi
1737
1738 dnl ------------------------------------
1739 dnl Enable RPKI and add librtr to libs
1740 dnl ------------------------------------
1741 if test "${enable_rpki}" = "yes"; then
1742   PKG_CHECK_MODULES([RTRLIB], [rtrlib >= 0.5.0],
1743       [RPKI=true],
1744       [RPKI=false
1745       AC_MSG_ERROR([rtrlib was not found on your system or is too old.])]
1746   )
1747 fi
1748
1749 dnl ------------------------------------------
1750 dnl Check whether rtrlib was build with ssh support
1751 dnl ------------------------------------------
1752 AC_MSG_CHECKING([whether the RTR Library is compiled with SSH])
1753 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "rtrlib/rtrlib.h"]],
1754                         [[struct tr_ssh_config config;]])],
1755         [AC_MSG_RESULT([yes])
1756         AC_DEFINE([FOUND_SSH], [1], [found_ssh])],
1757         AC_MSG_RESULT([no])
1758 )
1759
1760 dnl ---------------
1761 dnl dlopen & dlinfo
1762 dnl ---------------
1763 AC_SEARCH_LIBS([dlopen], [dl dld], [], [
1764   AC_MSG_ERROR([unable to find the dlopen()])
1765 ])
1766
1767 AC_CHECK_HEADERS([link.h])
1768
1769 AC_CACHE_CHECK([for dlinfo(RTLD_DI_ORIGIN)], [frr_cv_rtld_di_origin], [
1770   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1771 #include <stdlib.h>
1772 #ifdef HAVE_LINK_H
1773 #include <link.h>
1774 #endif
1775 #include <dlfcn.h>
1776 ]], [[
1777   char origin[1];
1778   dlinfo (NULL, RTLD_DI_ORIGIN, &origin);
1779 ]])], [
1780     frr_cv_rtld_di_origin=yes
1781   ], [
1782     frr_cv_rtld_di_origin=no
1783   ])
1784 ])
1785 if test "$frr_cv_rtld_di_origin" = yes; then
1786   AC_DEFINE([HAVE_DLINFO_ORIGIN], [1], [Have dlinfo RTLD_DI_ORIGIN])
1787 fi
1788
1789 AC_CACHE_CHECK([for dlinfo(RTLD_DI_LINKMAP)], [frr_cv_rtld_di_linkmap], [
1790   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1791 #include <stdlib.h>
1792 #ifdef HAVE_LINK_H
1793 #include <link.h>
1794 #endif
1795 #include <dlfcn.h>
1796 ]], [[
1797   struct link_map *lm = NULL;
1798   dlinfo (NULL, RTLD_DI_LINKMAP, &lm);
1799 ]])], [
1800     frr_cv_rtld_di_linkmap=yes
1801   ], [
1802     frr_cv_rtld_di_linkmap=no
1803   ])
1804 ])
1805 if test "$frr_cv_rtld_di_linkmap" = yes; then
1806   AC_DEFINE([HAVE_DLINFO_LINKMAP], [1], [Have dlinfo RTLD_DI_LINKMAP])
1807 fi
1808
1809 dnl ##########################################################################
1810 dnl test "${enable_clippy_only}" != "yes"
1811 fi
1812 dnl END OF LARGE if block
1813 dnl ##########################################################################
1814
1815 dnl ---------------------------
1816 dnl sockaddr and netinet checks
1817 dnl ---------------------------
1818 AC_CHECK_TYPES([
1819         struct sockaddr_dl,
1820         struct vifctl, struct mfcctl, struct sioc_sg_req,
1821         vifi_t, struct sioc_vif_req, struct igmpmsg,
1822         struct ifaliasreq, struct if6_aliasreq, struct in6_aliasreq,
1823         struct nd_opt_adv_interval,
1824         struct nd_opt_homeagent_info, struct nd_opt_adv_interval,
1825         struct nd_opt_rdnss, struct nd_opt_dnssl],
1826         [], [], FRR_INCLUDES)
1827
1828 AC_CHECK_MEMBERS([struct sockaddr.sa_len,
1829         struct sockaddr_in.sin_len, struct sockaddr_un.sun_len,
1830         struct sockaddr_dl.sdl_len,
1831         struct if6_aliasreq.ifra_lifetime,
1832         struct nd_opt_adv_interval.nd_opt_ai_type],
1833         [], [], FRR_INCLUDES)
1834
1835 dnl ---------------------------
1836 dnl IRDP/pktinfo/icmphdr checks
1837 dnl ---------------------------
1838
1839 AC_CHECK_TYPES([struct in_pktinfo], [
1840   AC_CHECK_TYPES([struct icmphdr], [
1841     IRDP=true
1842   ], [
1843     IRDP=false
1844   ], [FRR_INCLUDES])
1845 ], [
1846   IRDP=false
1847 ], [FRR_INCLUDES])
1848
1849 case "${enable_irdp}" in
1850 yes)
1851   $IRDP || AC_MSG_ERROR(['IRDP requires in_pktinfo at the moment!'])
1852   ;;
1853 no)
1854   IRDP=false
1855   ;;
1856 esac
1857
1858
1859 dnl -----------------------
1860 dnl checking for IP_PKTINFO
1861 dnl -----------------------
1862 AC_MSG_CHECKING([for IP_PKTINFO])
1863 AC_TRY_COMPILE([#include <netdb.h>], [
1864   int opt = IP_PKTINFO;
1865 ], [
1866   AC_MSG_RESULT([yes])
1867   AC_DEFINE([HAVE_IP_PKTINFO], [1], [Have IP_PKTINFO])
1868 ], [
1869   AC_MSG_RESULT([no])
1870 ])
1871
1872 dnl ---------------------------
1873 dnl checking for IP_RECVDSTADDR
1874 dnl ---------------------------
1875 AC_MSG_CHECKING([for IP_RECVDSTADDR])
1876 AC_TRY_COMPILE([#include <netinet/in.h>], [
1877   int opt = IP_RECVDSTADDR;
1878 ], [
1879   AC_MSG_RESULT([yes])
1880   AC_DEFINE([HAVE_IP_RECVDSTADDR], [1], [Have IP_RECVDSTADDR])
1881 ], [
1882   AC_MSG_RESULT([no])
1883 ])
1884
1885 dnl ----------------------
1886 dnl checking for IP_RECVIF
1887 dnl ----------------------
1888 AC_MSG_CHECKING([for IP_RECVIF])
1889 AC_TRY_COMPILE([#include <netinet/in.h>], [
1890   int opt = IP_RECVIF;
1891 ], [
1892   AC_MSG_RESULT([yes])
1893   AC_DEFINE([HAVE_IP_RECVIF], [1], [Have IP_RECVIF])
1894 ], [
1895   AC_MSG_RESULT([no])
1896 ])
1897
1898 dnl ----------------------
1899 dnl checking for SO_BINDANY
1900 dnl ----------------------
1901 AC_MSG_CHECKING([for SO_BINDANY])
1902 AC_TRY_COMPILE([#include <sys/socket.h>], [
1903   int opt = SO_BINDANY;
1904 ], [
1905   AC_MSG_RESULT([yes])
1906   AC_DEFINE([HAVE_SO_BINDANY], [1], [Have SO_BINDANY])
1907 ], [
1908   AC_MSG_RESULT([no])
1909 ])
1910
1911 dnl ----------------------
1912 dnl checking for IP_FREEBIND
1913 dnl ----------------------
1914 AC_MSG_CHECKING([for IP_FREEBIND])
1915 AC_TRY_COMPILE([#include <netinet/in.h>], [
1916   int opt = IP_FREEBIND;
1917 ], [
1918   AC_MSG_RESULT([yes])
1919   AC_DEFINE([HAVE_IP_FREEBIND], [1], [Have IP_FREEBIND])
1920 ], [
1921   AC_MSG_RESULT([no])
1922 ])
1923
1924 dnl --------------------------------------
1925 dnl checking for be32dec existence or not
1926 dnl --------------------------------------
1927 AC_CHECK_DECLS([be32enc, be32dec], [], [],
1928                [#include <sys/endian.h>])
1929
1930 dnl --------------------------------------
1931 dnl checking for clock_time monotonic struct and call
1932 dnl --------------------------------------
1933 AC_CHECK_DECL([CLOCK_MONOTONIC],
1934         [AC_CHECK_LIB([rt], [clock_gettime], [LIBS="$LIBS -lrt"])
1935          AC_DEFINE([HAVE_CLOCK_MONOTONIC], [1], [Have monotonic clock])
1936 ], [AC_MSG_RESULT([no])], [FRR_INCLUDES])
1937
1938 dnl --------------------------------------
1939 dnl checking for flex and bison
1940 dnl --------------------------------------
1941
1942 AM_PROG_LEX
1943 AC_MSG_CHECKING([version of flex])
1944 frr_ac_flex_version="$(eval $LEX -V | grep flex | head -n 1)"
1945 frr_ac_flex_version="${frr_ac_flex_version##* }"
1946 AC_MSG_RESULT([$frr_ac_flex_version])
1947 AX_COMPARE_VERSION([$frr_ac_flex_version], [lt], [2.5.20], [
1948   LEX="$SHELL $missing_dir/missing flex"
1949   if test -f "${srcdir}/lib/command_lex.c" -a -f "${srcdir}/lib/command_lex.h"; then
1950     AC_MSG_WARN([using pregenerated flex output files])
1951   else
1952     AC_MSG_ERROR([flex failure and pregenerated files not included (probably a git build)])
1953   fi
1954   AC_SUBST([LEX_OUTPUT_ROOT], [lex.yy])
1955   AC_SUBST([LEXLIB], [''])
1956 ])
1957
1958 AC_PROG_YACC
1959 dnl thanks GNU bison for this b*llshit...
1960 AC_MSG_CHECKING([version of bison])
1961 frr_ac_bison_version="$(eval $YACC -V | grep bison | head -n 1)"
1962 frr_ac_bison_version="${frr_ac_bison_version##* }"
1963 frr_ac_bison_missing="false"
1964 case "x${frr_ac_bison_version}x" in
1965   x2.7*)
1966     BISON_OPENBRACE='"'
1967     BISON_CLOSEBRACE='"'
1968     BISON_VERBOSE=''
1969     AC_MSG_RESULT([$frr_ac_bison_version - 2.7 or older])
1970     ;;
1971   x2.*|x1.*)
1972     AC_MSG_RESULT([$frr_ac_bison_version])
1973     AC_MSG_WARN([installed bison is too old.  Please install GNU bison 2.7.x or newer.])
1974     frr_ac_bison_missing="true"
1975     ;;
1976   x)
1977     AC_MSG_RESULT([none])
1978     AC_MSG_WARN([could not determine bison version.  Please install GNU bison 2.7.x or newer.])
1979     frr_ac_bison_missing="true"
1980     ;;
1981   x3.[012][^0-9]*)
1982     BISON_OPENBRACE='{'
1983     BISON_CLOSEBRACE='}'
1984     BISON_VERBOSE='-Dparse.error=verbose'
1985     AC_MSG_RESULT([$frr_ac_bison_version - 3.0 to 3.2])
1986     ;;
1987   *)
1988     BISON_OPENBRACE='{'
1989     BISON_CLOSEBRACE='}'
1990     BISON_VERBOSE='-Dparse.error=verbose -Wno-yacc'
1991     AC_MSG_RESULT([$frr_ac_bison_version - 3.3 or newer])
1992     ;;
1993 esac
1994 AC_SUBST([BISON_OPENBRACE])
1995 AC_SUBST([BISON_CLOSEBRACE])
1996 AC_SUBST([BISON_VERBOSE])
1997
1998 if $frr_ac_bison_missing; then
1999   YACC="$SHELL $missing_dir/missing bison -y"
2000   if test -f "${srcdir}/lib/command_parse.c" -a -f "${srcdir}/lib/command_parse.h"; then
2001     AC_MSG_WARN([using pregenerated bison output files])
2002   else
2003     AC_MSG_ERROR([bison failure and pregenerated files not included (probably a git build)])
2004   fi
2005 fi
2006
2007 dnl -------------------
2008 dnl capabilities checks
2009 dnl -------------------
2010 if test "${enable_capabilities}" != "no"; then
2011   AC_MSG_CHECKING([whether prctl PR_SET_KEEPCAPS is available])
2012   AC_TRY_COMPILE([#include <sys/prctl.h>], [prctl(PR_SET_KEEPCAPS, 1, 0, 0, 0);],
2013     [AC_MSG_RESULT([yes])
2014      AC_DEFINE([HAVE_PR_SET_KEEPCAPS], [1], [prctl])
2015      frr_ac_keepcaps="yes"],
2016      AC_MSG_RESULT([no])
2017   )
2018   if test x"${frr_ac_keepcaps}" = x"yes"; then
2019     AC_CHECK_HEADERS([sys/capability.h])
2020   fi
2021   if test x"${ac_cv_header_sys_capability_h}" = x"yes"; then
2022     AC_CHECK_LIB([cap], [cap_init],
2023       [AC_DEFINE([HAVE_LCAPS], [1], [Capabilities])
2024        LIBCAP="-lcap"
2025        frr_ac_lcaps="yes"]
2026     )
2027   else
2028     AC_CHECK_HEADERS([priv.h],
2029      [AC_MSG_CHECKING([Solaris style privileges are available])
2030       AC_TRY_COMPILE([#include <priv.h>], [getpflags(PRIV_AWARE);],
2031           [AC_MSG_RESULT([yes])
2032            AC_DEFINE([HAVE_SOLARIS_CAPABILITIES], [1], [getpflags])
2033            frr_ac_scaps="yes"],
2034            AC_MSG_RESULT(no)
2035       )
2036      ]
2037    )
2038   fi
2039   if test x"${frr_ac_scaps}" = x"yes" \
2040        -o x"${frr_ac_lcaps}" = x"yes"; then
2041     AC_DEFINE([HAVE_CAPABILITIES], [1], [capabilities])
2042   fi
2043
2044   case "$host_os" in
2045   linux*)
2046     if test "$frr_ac_lcaps" != "yes"; then
2047       AC_MSG_ERROR([libcap and/or its headers were not found.  Running FRR without libcap support built in causes a huge performance penalty.])
2048     fi
2049     ;;
2050   esac
2051 else
2052   case "$host_os" in
2053   linux*)
2054     AC_MSG_WARN([Running FRR without libcap support built in causes a huge performance penalty.])
2055     ;;
2056   esac
2057 fi
2058 AC_SUBST([LIBCAP])
2059
2060 dnl ---------------------------
2061 dnl check for glibc 'backtrace'
2062 dnl ---------------------------
2063 if test x"${enable_backtrace}" != x"no" ; then
2064   backtrace_ok=no
2065   PKG_CHECK_MODULES([UNWIND], [libunwind], [
2066     AC_DEFINE([HAVE_LIBUNWIND], [1], [libunwind])
2067     backtrace_ok=yes
2068   ], [
2069     case "$host_os" in
2070     sunos* | solaris2*)
2071       AC_CHECK_FUNCS([printstack], [
2072         AC_DEFINE([HAVE_PRINTSTACK], [1], [Solaris printstack])
2073         backtrace_ok=yes
2074       ])
2075       ;;
2076     esac
2077     if test "$backtrace_ok" = no; then
2078       AC_CHECK_HEADER([execinfo.h], [
2079         AC_SEARCH_LIBS([backtrace], [execinfo], [
2080           AC_DEFINE([HAVE_GLIBC_BACKTRACE], [1], [Glibc backtrace])
2081           backtrace_ok=yes
2082         ],, [-lm])
2083       ])
2084     fi
2085   ])
2086
2087   if test x"${enable_backtrace}" = x"yes" -a x"${backtrace_ok}" = x"no"; then
2088     dnl user explicitly requested backtrace but we failed to find support
2089     AC_MSG_FAILURE([failed to find backtrace or libunwind support])
2090   fi
2091 fi
2092
2093 dnl -----------------------------------------
2094 dnl check for malloc mallinfo struct and call
2095 dnl this must try and link using LIBS, in
2096 dnl order to check no alternative allocator
2097 dnl has been specified, which might not provide
2098 dnl mallinfo, e.g. such as Umem on Solaris.
2099 dnl -----------------------------------------
2100 AC_CHECK_HEADERS([malloc.h malloc_np.h malloc/malloc.h],,, [FRR_INCLUDES])
2101
2102 AC_CACHE_CHECK([whether mallinfo is available], [frr_cv_mallinfo], [
2103   AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2104 #ifdef HAVE_MALLOC_H
2105 #include <malloc.h>
2106 #endif
2107 #ifdef HAVE_MALLOC_NP_H
2108 #include <malloc_np.h>
2109 #endif
2110 #ifdef HAVE_MALLOC_MALLOC_H
2111 #include <malloc/malloc.h>
2112 #endif
2113 ]], [[
2114 struct mallinfo ac_x; ac_x = mallinfo ();
2115 ]])], [
2116     frr_cv_mallinfo=yes
2117   ], [
2118     frr_cv_mallinfo=no
2119   ])
2120 ])
2121 if test "$frr_cv_mallinfo" = yes; then
2122   AC_DEFINE([HAVE_MALLINFO], [1], [mallinfo])
2123 fi
2124
2125 AC_MSG_CHECKING([whether malloc_usable_size is available])
2126 AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2127 #ifdef HAVE_MALLOC_H
2128 #include <malloc.h>
2129 #endif
2130 #ifdef HAVE_MALLOC_MALLOC_H
2131 #include <malloc/malloc.h>
2132 #endif
2133 ]], [[
2134 size_t ac_x; ac_x = malloc_usable_size(NULL);
2135 ]])], [
2136   AC_MSG_RESULT([yes])
2137   AC_DEFINE([HAVE_MALLOC_USABLE_SIZE], [1], [malloc_usable_size])
2138 ], [
2139   AC_MSG_RESULT([no])
2140
2141   AC_MSG_CHECKING([whether malloc_size is available])
2142   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2143 #ifdef HAVE_MALLOC_H
2144 #include <malloc.h>
2145 #endif
2146 #ifdef HAVE_MALLOC_MALLOC_H
2147 #include <malloc/malloc.h>
2148 #endif
2149 ]], [[
2150 size_t ac_x; ac_x = malloc_size(NULL);
2151 ]])], [
2152     AC_MSG_RESULT([yes])
2153     AC_DEFINE([HAVE_MALLOC_SIZE], [1], [malloc_size])
2154   ], [
2155     AC_MSG_RESULT([no])
2156   ])
2157 ])
2158
2159 dnl ----------
2160 dnl configure date
2161 dnl ----------
2162 dev_version=`echo $VERSION | grep dev`
2163 #don't expire deprecated code in non 'dev' branch
2164 if test "${dev_version}" = ""; then
2165    CONFDATE=0
2166 else
2167    CONFDATE=`date '+%Y%m%d'`
2168 fi
2169 AC_SUBST([CONFDATE])
2170
2171 dnl ------------------------------
2172 dnl set paths for state directory
2173 dnl ------------------------------
2174 AC_MSG_CHECKING([directory to use for state file])
2175 if test "${prefix}" = "NONE"; then
2176   frr_statedir_prefix="";
2177 else
2178   frr_statedir_prefix=${prefix}
2179 fi
2180 if test "${localstatedir}" = '${prefix}/var'; then
2181   for FRR_STATE_DIR in ${frr_statedir_prefix}/var/run dnl
2182                         ${frr_statedir_prefix}/var/adm dnl
2183                         ${frr_statedir_prefix}/etc dnl
2184                         /var/run        dnl
2185                         /var/adm        dnl
2186                         /etc            dnl
2187                         /dev/null;
2188   do
2189     test -d $FRR_STATE_DIR && break
2190   done
2191   frr_statedir=$FRR_STATE_DIR
2192 else
2193   frr_statedir=${localstatedir}
2194 fi
2195 if test $frr_statedir = "/dev/null"; then
2196     AC_MSG_ERROR([STATE DIRECTORY NOT FOUND! FIX OR SPECIFY --localstatedir!])
2197 fi
2198 AC_MSG_RESULT([${frr_statedir}])
2199 AC_SUBST([frr_statedir])
2200
2201 AC_DEFINE_UNQUOTED([LDPD_SOCKET], ["$frr_statedir%s%s/ldpd.sock"], [ldpd control socket])
2202 AC_DEFINE_UNQUOTED([ZEBRA_SERV_PATH], ["$frr_statedir%s%s/zserv.api"], [zebra api socket])
2203 AC_DEFINE_UNQUOTED([BFDD_CONTROL_SOCKET], ["$frr_statedir%s%s/bfdd.sock"], [bfdd control socket])
2204 AC_DEFINE_UNQUOTED([DAEMON_VTY_DIR], ["$frr_statedir%s%s"], [daemon vty directory])
2205 AC_DEFINE_UNQUOTED([DAEMON_DB_DIR], ["$frr_statedir"], [daemon database directory])
2206
2207 dnl autoconf does this, but it does it too late...
2208 test "x$prefix" = xNONE && prefix=$ac_default_prefix
2209 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
2210
2211 dnl get the full path, recursing through variables...
2212 vtysh_bin="$bindir/vtysh"
2213 for I in 1 2 3 4 5 6 7 8 9 10; do
2214         eval vtysh_bin="\"$vtysh_bin\""
2215 done
2216 AC_DEFINE_UNQUOTED([VTYSH_BIN_PATH], ["$vtysh_bin"], [path to vtysh binary])
2217 AC_SUBST([vtysh_bin])
2218
2219 CFG_SYSCONF="$sysconfdir"
2220 CFG_SBIN="$sbindir"
2221 CFG_STATE="$frr_statedir"
2222 CFG_MODULE="$moduledir"
2223 CFG_YANGMODELS="$yangmodelsdir"
2224 for I in 1 2 3 4 5 6 7 8 9 10; do
2225         eval CFG_SYSCONF="\"$CFG_SYSCONF\""
2226         eval CFG_SBIN="\"$CFG_SBIN\""
2227         eval CFG_STATE="\"$CFG_STATE\""
2228         eval CFG_MODULE="\"$CFG_MODULE\""
2229         eval CFG_YANGMODELS="\"$CFG_YANGMODELS\""
2230 done
2231 AC_SUBST([CFG_SYSCONF])
2232 AC_SUBST([CFG_SBIN])
2233 AC_SUBST([CFG_STATE])
2234 AC_SUBST([CFG_MODULE])
2235 AC_SUBST([CFG_YANGMODELS])
2236 AC_DEFINE_UNQUOTED([MODULE_PATH], ["$CFG_MODULE"], [path to modules])
2237 AC_DEFINE_UNQUOTED([YANG_MODELS_PATH], ["$CFG_YANGMODELS"], [path to YANG data models])
2238 AC_DEFINE_UNQUOTED([WATCHFRR_SH_PATH], ["${CFG_SBIN%/}/watchfrr.sh"], [path to watchfrr.sh])
2239
2240 dnl various features
2241 AM_CONDITIONAL([SUPPORT_REALMS], [test "${enable_realms}" = "yes"])
2242 AM_CONDITIONAL([ENABLE_BGP_VNC], [test x${enable_bgp_vnc} != xno])
2243 AM_CONDITIONAL([BGP_BMP], [$bgpd_bmp])
2244 dnl northbound
2245 AM_CONDITIONAL([SQLITE3], [$SQLITE3])
2246 AM_CONDITIONAL([CONFD], [test "x$enable_confd" != "x"])
2247 AM_CONDITIONAL([SYSREPO], [test "x$enable_sysrepo" = "xyes"])
2248 AM_CONDITIONAL([GRPC], [test "x$enable_grpc" = "xyes"])
2249 AM_CONDITIONAL([ZEROMQ], [test "x$ZEROMQ" = "xtrue"])
2250 dnl plugins
2251 AM_CONDITIONAL([RPKI], [test "x$RPKI" = "xtrue"])
2252 AM_CONDITIONAL([SNMP], [test "x$SNMP_METHOD" = "xagentx"])
2253 AM_CONDITIONAL([IRDP], [$IRDP])
2254 AM_CONDITIONAL([FPM], [test "x$enable_fpm" = "xyes"])
2255 AM_CONDITIONAL([HAVE_PROTOBUF], [test "x$enable_protobuf" = "xyes"])
2256 dnl daemons
2257 AM_CONDITIONAL([VTYSH], [test "x$VTYSH" = "xvtysh"])
2258 AM_CONDITIONAL([ZEBRA], [test "${enable_zebra}" != "no"])
2259 AM_CONDITIONAL([BGPD], [test "x${enable_bgpd}" != "no"])
2260 AM_CONDITIONAL([RIPD], [test "${enable_ripd}" != "no"])
2261 AM_CONDITIONAL([OSPFD], [test "${enable_ospfd}" != "no"])
2262 AM_CONDITIONAL([LDPD], [test "${enable_ldpd}" != "no"])
2263 AM_CONDITIONAL([BFDD], [test "x$BFDD" = "xbfdd"])
2264 AM_CONDITIONAL([NHRPD], [test "x$NHRPD" = "xnhrpd"])
2265 AM_CONDITIONAL([EIGRPD], [test "${enable_eigrpd}" != "no"])
2266 AM_CONDITIONAL([WATCHFRR], [test "x$WATCHFRR" = "xwatchfrr"])
2267 AM_CONDITIONAL([OSPFCLIENT], [test "x$OSPFCLIENT" = "xospfclient"])
2268 AM_CONDITIONAL([RIPNGD], [test "${enable_ripngd}" != "no"])
2269 AM_CONDITIONAL([BABELD], [test "${enable_babeld}" != "no"])
2270 AM_CONDITIONAL([OSPF6D], [test "${enable_ospf6d}" != "no"])
2271 AM_CONDITIONAL([ISISD], [test "${enable_isisd}" != "no"])
2272 AM_CONDITIONAL([PIMD], [test "${enable_pimd}" != "no"])
2273 AM_CONDITIONAL([PBRD], [test "${enable_pbrd}" != "no"])
2274 AM_CONDITIONAL([SHARPD], [test "${enable_sharpd}" = "yes"])
2275 AM_CONDITIONAL([STATICD], [test "${enable_staticd}" != "no"])
2276 AM_CONDITIONAL([FABRICD], [test "${enable_fabricd}" != "no"])
2277 AM_CONDITIONAL([VRRPD], [test "${enable_vrrpd}" != "no"])
2278
2279 AC_CONFIG_FILES([Makefile],[sed -e 's/^#AUTODERP# //' -i Makefile])
2280
2281 AC_CONFIG_FILES([
2282           config.version
2283           changelog-auto
2284           redhat/frr.spec
2285           solaris/Makefile
2286           alpine/APKBUILD
2287           snapcraft/snapcraft.yaml
2288           lib/version.h
2289           tests/lib/cli/test_cli.refout
2290           pkgsrc/bgpd.sh pkgsrc/ospf6d.sh pkgsrc/ospfd.sh
2291           pkgsrc/ripd.sh pkgsrc/ripngd.sh pkgsrc/zebra.sh
2292           pkgsrc/eigrpd.sh])
2293
2294 AC_CONFIG_FILES([vtysh/extract.pl], [chmod +x vtysh/extract.pl])
2295 AC_CONFIG_FILES([tools/frr], [chmod +x tools/frr])
2296 AC_CONFIG_FILES([tools/watchfrr.sh], [chmod +x tools/watchfrr.sh])
2297 AC_CONFIG_FILES([tools/frrinit.sh], [chmod +x tools/frrinit.sh])
2298 AC_CONFIG_FILES([tools/frrcommon.sh])
2299
2300 AC_CONFIG_COMMANDS([lib/route_types.h], [
2301         dst="${ac_abs_top_builddir}/lib/route_types.h"
2302         ${PERL} "${ac_abs_top_srcdir}/lib/route_types.pl" \
2303                 < "${ac_abs_top_srcdir}/lib/route_types.txt" \
2304                 > "${dst}.tmp"
2305         test -f "${dst}" \
2306                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
2307                 && rm "${dst}.tmp" \
2308                 || mv "${dst}.tmp" "${dst}"
2309 ], [
2310         PERL="$PERL"
2311 ])
2312
2313 AS_IF([test "x$with_pkg_git_version" = "xyes"], [
2314     AC_CONFIG_COMMANDS([lib/gitversion.h], [
2315         dst="${ac_abs_top_builddir}/lib/gitversion.h"
2316         ${PERL} "${ac_abs_top_srcdir}/lib/gitversion.pl" \
2317                 "${ac_abs_top_srcdir}" \
2318                 > "${dst}.tmp"
2319         test -f "${dst}" \
2320                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
2321                 && rm "${dst}.tmp" \
2322                 || mv "${dst}.tmp" "${dst}"
2323     ], [
2324         PERL="$PERL"
2325     ])
2326 ])
2327
2328 ## Hack, but working solution to avoid rebuilding of frr.info.
2329 ## It's already in CVS until texinfo 4.7 is more common.
2330 AC_OUTPUT
2331
2332 echo "
2333 FRRouting configuration
2334 ------------------------------
2335 FRR version             : ${PACKAGE_VERSION}
2336 host operating system   : ${host_os}
2337 source code location    : ${srcdir}
2338 compiler                : ${CC}
2339 compiler flags          : ${CFLAGS} ${SAN_FLAGS}
2340 make                    : ${MAKE-make}
2341 linker flags            : ${LDFLAGS} ${SAN_FLAGS} ${LIBS} ${LIBCAP} ${LIBREADLINE} ${LIBM}
2342 state file directory    : ${frr_statedir}
2343 config file directory   : `eval echo \`echo ${sysconfdir}\``
2344 example directory       : `eval echo \`echo ${exampledir}\``
2345 module directory        : ${CFG_MODULE}
2346 user to run as          : ${enable_user}
2347 group to run as         : ${enable_group}
2348 group for vty sockets   : ${enable_vty_group}
2349 config file mask        : ${enable_configfile_mask}
2350 log file mask           : ${enable_logfile_mask}
2351 zebra protobuf enabled  : ${enable_protobuf:-no}
2352
2353 The above user and group must have read/write access to the state file
2354 directory and to the config files in the config file directory."
2355
2356 if test "${enable_doc}" != "no" -a "$frr_py_mod_sphinx" = false; then
2357   AC_MSG_WARN([sphinx is missing but required to build documentation])
2358 fi
2359 if test "$frr_py_mod_pytest" = false; then
2360   AC_MSG_WARN([pytest is missing, unit tests cannot be performed])
2361 fi