configure.ac

   1 ##
   2 ## Configure template file for FRRouting.
   3 ## autoconf will generate configure script.
   4 ##
   5 ##  Copyright (c) 1996, 97, 98, 99, 2000 Kunihiro Ishiguro <kunihiro@zebra.org>
   6 ##  Portions Copyright (c) 2003 Paul Jakma <paul@dishone.st>
   7 ##
   8 AC_PREREQ(2.60)
   9
  10 AC_INIT(frr, 6.1-dev, [https://github.com/frrouting/frr/issues])
  11 PACKAGE_URL="https://frrouting.org/"
  12 AC_SUBST(PACKAGE_URL)
  13 PACKAGE_FULLNAME="FRRouting"
  14 AC_SUBST(PACKAGE_FULLNAME)
  15
  16 CONFIG_ARGS="$ac_configure_args"
  17 AC_SUBST(CONFIG_ARGS)
  18
  19 AC_CONFIG_SRCDIR(lib/zebra.h)
  20 AC_CONFIG_MACRO_DIR([m4])
  21
  22 dnl -----------------------------------
  23 dnl Get hostname and other information.
  24 dnl -----------------------------------
  25 AC_CANONICAL_BUILD()
  26 AC_CANONICAL_HOST()
  27
  28 AS_IF([test "$host" != "$build"], [
  29   if test "$srcdir" = "."; then
  30     AC_MSG_ERROR([cross-compilation is only possible with builddir separate from srcdir.  create a separate directory and run as .../path-to-frr/configure.])
  31   fi
  32   test -d hosttools || mkdir hosttools
  33   abssrc="`cd \"${srcdir}\"; pwd`"
  34
  35   AC_MSG_NOTICE([...])
  36   AC_MSG_NOTICE([... cross-compilation: creating hosttools directory and self-configuring for build platform tools])
  37   AC_MSG_NOTICE([... use HOST_CPPFLAGS / HOST_CFLAGS / HOST_LDFLAGS if neccessary])
  38   AC_MSG_NOTICE([...])
  39
  40   ( CPPFLAGS="$HOST_CPPFLAGS"; \
  41     CFLAGS="$HOST_CFLAGS"; \
  42     LDFLAGS="$HOST_LDFLAGS"; \
  43     cd hosttools; "${abssrc}/configure" "--host=$build" "--build=$build" "--enable-clippy-only" "--disable-nhrpd" "--disable-vtysh"; )
  44
  45   AC_MSG_NOTICE([...])
  46   AC_MSG_NOTICE([... cross-compilation: finished self-configuring for build platform tools])
  47   AC_MSG_NOTICE([...])
  48
  49   build_clippy="false"
  50   HOSTTOOLS="hosttools/"
  51 ], [
  52   build_clippy="true"
  53   HOSTTOOLS=""
  54 ])
  55 AC_SUBST(HOSTTOOLS)
  56 AM_CONDITIONAL([BUILD_CLIPPY], [$build_clippy])
  57
  58 # Disable portability warnings -- our automake code (in particular
  59 # common.am) uses some constructs specific to gmake.
  60 AM_INIT_AUTOMAKE([1.12 -Wno-portability])
  61 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
  62 AM_SILENT_RULES([yes])
  63 AC_CONFIG_HEADERS(config.h)
  64
  65 AC_PATH_PROG(PERL, perl)
  66 PKG_PROG_PKG_CONFIG
  67
  68 dnl default is to match previous behavior
  69 exampledir=${sysconfdir}
  70 AC_ARG_ENABLE([exampledir],
  71           AS_HELP_STRING([--enable-exampledir],
  72                          [specify alternate directory for examples]),
  73                          exampledir="$enableval",)
  74 dnl XXX add --exampledir to autoconf standard directory list somehow
  75 AC_SUBST(exampledir)
  76
  77 dnl default is to match previous behavior
  78 pkgsrcrcdir=""
  79 AC_ARG_ENABLE([pkgsrcrcdir],
  80           AS_HELP_STRING([--enable-pkgsrcrcdir],
  81                          [specify directory for rc.d scripts]),
  82                          pkgsrcrcdir="$enableval",)
  83 dnl XXX add --pkgsrcrcdir to autoconf standard directory list somehow
  84 AC_SUBST(pkgsrcrcdir)
  85 AM_CONDITIONAL([PKGSRC], [test "x$pkgsrcrcdir" != "x"])
  86
  87 AC_ARG_WITH([moduledir], [AS_HELP_STRING([--with-moduledir=DIR], [module directory (${libdir}/frr/modules)])], [
  88         moduledir="$withval"
  89 ], [
  90         moduledir="\${libdir}/frr/modules"
  91 ])
  92 AC_SUBST([moduledir], [$moduledir])
  93
  94 AC_ARG_ENABLE(tcmalloc,
  95         AS_HELP_STRING([--enable-tcmalloc], [Turn on tcmalloc]),
  96 [case "${enableval}" in
  97   yes) tcmalloc_enabled=true
  98 LIBS="$LIBS -ltcmalloc_minimal"
  99  ;;
 100   no)  tcmalloc_enabled=false ;;
 101   *) AC_MSG_ERROR(bad value ${enableval} for --enable-tcmalloc) ;;
 102 esac],[tcmalloc_enabled=false])
 103
 104
 105 dnl Thanks autoconf, but we don't want a default -g -O2.  We have our own
 106 dnl flag determination logic.
 107 CFLAGS="${CFLAGS:-}"
 108
 109 dnl --------------------
 110 dnl Check CC and friends
 111 dnl --------------------
 112 dnl note orig_cflags is also used further down
 113 orig_cflags="$CFLAGS"
 114 AC_LANG([C])
 115 AC_PROG_CC
 116 AC_PROG_CPP
 117 AM_PROG_CC_C_O
 118 dnl remove autoconf default "-g -O2"
 119 CFLAGS="$orig_cflags"
 120 AC_PROG_CC_C99
 121 dnl NB: see C11 below
 122
 123 AC_PROG_EGREP
 124 PKG_PROG_PKG_CONFIG
 125
 126 dnl autoconf 2.59 appears not to support AC_PROG_SED
 127 dnl AC_PROG_SED
 128 AC_CHECK_PROG([SED],[sed],[sed],[/bin/false])
 129
 130 dnl try and enable CFLAGS that are useful for FRR
 131 dnl - specifically, options to control warnings
 132
 133 AC_USE_SYSTEM_EXTENSIONS
 134 AC_DEFUN([AC_C_FLAG], [{
 135     m4_pushdef([cachename],[m4_translit([frr_cv_$1],[ =-],[___])])
 136     AC_CACHE_CHECK([[whether $CC supports $1]], cachename, [
 137         AC_LANG_PUSH(C)
 138         ac_c_flag_save="$CFLAGS"
 139         CFLAGS="$CFLAGS $1"
 140         AC_COMPILE_IFELSE(
 141                 [AC_LANG_PROGRAM([[]])],
 142                 [
 143                         cachename=yes
 144                 ], [
 145                         cachename=no
 146                 ])
 147         CFLAGS="$ac_c_flag_save"
 148         AC_LANG_POP(C)
 149     ])
 150     if test "${cachename}" = yes; then
 151         m4_if([$3], [], [CFLAGS="$CFLAGS $1"], [$3])
 152     else
 153         :
 154         $2
 155     fi
 156     m4_popdef([cachename])
 157 }])
 158
 159 AC_DEFUN([AC_LINK_IFELSE_FLAGS], [{
 160         AC_LANG_PUSH(C)
 161         ac_cflags_save="$CFLAGS"
 162         ac_libs_save="$LIBS"
 163         CFLAGS="$CFLAGS $1"
 164         LIBS="$LIBS $2"
 165         AC_LINK_IFELSE(
 166                 [$3],
 167                 [
 168                         AC_MSG_RESULT([yes])
 169                         CFLAGS="$ac_cflags_save"
 170                         LIBS="$ac_libs_save"
 171                         $5
 172                 ], [
 173                         AC_MSG_RESULT([no])
 174                         CFLAGS="$ac_cflags_save"
 175                         LIBS="$ac_libs_save"
 176                         $4
 177                 ])
 178         AC_LANG_POP(C)
 179         }])
 180
 181 dnl ICC won't bail on unknown options without -diag-error 10006
 182 dnl need to do this first so we get useful results for the other options
 183 AC_C_FLAG([-diag-error 10006])
 184
 185 dnl AC_PROG_CC_C99 may change CC to include -std=gnu99 or something
 186 ac_cc="$CC"
 187 CC="${CC% -std=gnu99}"
 188 CC="${CC% -std=c99}"
 189
 190 AC_C_FLAG([-std=gnu11], [CC="$ac_cc"], [CC="$CC -std=gnu11"])
 191
 192 dnl AddressSanitizer support
 193 AC_ARG_ENABLE([address-sanitizer], AS_HELP_STRING([--enable-address-sanitizer], \
 194               [enabled AddressSanitizer support for detecting a wide variety of \
 195                memory allocation and deallocation errors]), \
 196               [AC_DEFINE(HAVE_ADDRESS_SANITIZER, 1, [enable AddressSanitizer])
 197               ASAN_FLAGS="-fsanitize=address"
 198               SAN_CLIPPY_FLAGS="-fno-sanitize=all"
 199               AC_SUBST([ASAN_FLAGS])
 200               AC_SUBST([SAN_CLIPPY_FLAGS])
 201               LIBS="-ldl $LIBS"
 202               AC_TRY_COMPILE([],[const int i=0;],[AC_MSG_NOTICE([Address Sanitizer Enabled])],
 203                                                  [AC_MSG_ERROR([Address Sanitizer not available])])
 204               ])
 205
 206 dnl ThreadSanitizer support
 207 AC_ARG_ENABLE([thread-sanitizer], AS_HELP_STRING([--enable-thread-sanitizer], \
 208               [enabled ThreadSanitizer support for detecting data races]), \
 209               [AC_DEFINE(HAVE_THREAD_SANITIZER, 1, [enable ThreadSanitizer])
 210               TSAN_FLAGS="-fsanitize=thread"
 211               SAN_CLIPPY_FLAGS="-fno-sanitize=all"
 212               AC_SUBST([TSAN_FLAGS])
 213               AC_SUBST([SAN_CLIPPY_FLAGS])
 214               LIBS="-ldl $LIBS"
 215               AC_TRY_COMPILE([],[const int i=0;],[AC_MSG_NOTICE([Thread Sanitizer Enabled])],
 216                                                  [AC_MSG_ERROR([Thread Sanitizer not available])])
 217               ])
 218
 219 dnl MemorySanitizer support
 220 AC_ARG_ENABLE([memory-sanitizer], AS_HELP_STRING([--enable-memory-sanitizer], \
 221               [enabled MemorySanitizer support for detecting uninitialized memory reads]), \
 222               [AC_DEFINE(HAVE_THREAD_SANITIZER, 1, [enable MemorySanitizer])
 223               MSAN_FLAGS="-fsanitize=memory -fPIE -pie"
 224               SAN_CLIPPY_FLAGS="-fno-sanitize=all"
 225               AC_SUBST([MSAN_FLAGS])
 226               AC_SUBST([SAN_CLIPPY_FLAGS])
 227               LIBS="-ldl $LIBS"
 228               AC_TRY_COMPILE([],[const int i=0;],[AC_MSG_NOTICE([Memory Sanitizer Enabled])],
 229                                                  [AC_MSG_ERROR([Memory Sanitizer not available])])
 230               ])
 231
 232 dnl if the user has specified any CFLAGS, override our settings
 233 if test "x${enable_gcov}" = "xyes"; then
 234    if test "z$orig_cflags" = "z"; then
 235       AC_C_FLAG([-coverage])
 236       AC_C_FLAG([-O0])
 237    fi
 238
 239    LDFLAGS="${LDFLAGS} -lgcov"
 240 elif test "x${enable_dev_build}" = "xyes"; then
 241    AC_DEFINE(DEV_BUILD,,Build for development)
 242    if test "z$orig_cflags" = "z"; then
 243       AC_C_FLAG([-g3])
 244       AC_C_FLAG([-O0])
 245    fi
 246 else
 247    if test "z$orig_cflags" = "z"; then
 248       AC_C_FLAG([-g])
 249       AC_C_FLAG([-Os], [
 250         AC_C_FLAG([-O2])
 251       ])
 252    fi
 253 fi
 254 AM_CONDITIONAL([DEV_BUILD], [test "x$enable_dev_build" = "xyes"])
 255
 256 dnl always want these CFLAGS
 257 AC_C_FLAG([-fno-omit-frame-pointer])
 258 AC_C_FLAG([-funwind-tables])
 259 AC_C_FLAG([-Wall])
 260 AC_C_FLAG([-Wextra])
 261 AC_C_FLAG([-Wmissing-prototypes])
 262 AC_C_FLAG([-Wmissing-declarations])
 263 AC_C_FLAG([-Wpointer-arith])
 264 AC_C_FLAG([-Wbad-function-cast])
 265 AC_C_FLAG([-Wwrite-strings])
 266 if test x"${enable_gcc_ultra_verbose}" = x"yes" ; then
 267   AC_C_FLAG([-Wcast-qual])
 268   AC_C_FLAG([-Wstrict-prototypes])
 269   AC_C_FLAG([-Wmissing-noreturn])
 270   AC_C_FLAG([-Wmissing-format-attribute])
 271   AC_C_FLAG([-Wunreachable-code])
 272   AC_C_FLAG([-Wpacked])
 273   AC_C_FLAG([-Wpadded])
 274 else
 275   AC_C_FLAG([-Wno-unused-result])
 276 fi
 277 AC_C_FLAG([-Wno-unused-parameter])
 278 AC_C_FLAG([-Wno-missing-field-initializers])
 279
 280 dnl ICC emits a broken warning for const char *x = a ? "b" : "c";
 281 dnl for some reason the string consts get 'promoted' to char *,
 282 dnl triggering a const to non-const conversion warning.
 283 AC_C_FLAG([-diag-disable 3179])
 284
 285 if test x"${enable_werror}" = x"yes" ; then
 286   WERROR="-Werror"
 287 fi
 288 AC_SUBST(WERROR)
 289
 290 dnl ----------
 291 dnl Essentials
 292 dnl ----------
 293
 294 AX_PTHREAD([
 295   CC="$PTHREAD_CC"
 296   CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 297   LIBS="$PTHREAD_LIBS $LIBS"
 298 ], [
 299   AC_MSG_FAILURE([This FRR version needs pthreads])
 300 ])
 301
 302 AC_SEARCH_LIBS([pthread_condattr_setclock], [],
 303                 [frr_cv_pthread_condattr_setclock=yes],
 304                 [frr_cv_pthread_condattr_setclock=no])
 305 if test "$frr_cv_pthread_condattr_setclock" = yes; then
 306   AC_DEFINE(HAVE_PTHREAD_CONDATTR_SETCLOCK, 1, [Have pthread.h pthread_condattr_setclock])
 307 fi
 308
 309 dnl --------------
 310 dnl Check programs
 311 dnl --------------
 312 AC_PROG_INSTALL
 313 AC_PROG_LN_S
 314 AC_PROG_MAKE_SET
 315 AC_CHECK_TOOL(AR, ar)
 316
 317 dnl -----------------
 318 dnl System extensions
 319 dnl -----------------
 320 AC_GNU_SOURCE
 321
 322 dnl -------
 323 dnl libtool
 324 dnl -------
 325 LT_INIT
 326
 327 dnl ----------------------
 328 dnl Packages configuration
 329 dnl ----------------------
 330 AC_ARG_WITH(pkg-extra-version,
 331         AS_HELP_STRING([--with-pkg-extra-version=VER], [add extra version field, for packagers/distributions]),
 332         [EXTRAVERSION=$withval],)
 333 AC_ARG_WITH(pkg-git-version,
 334         AS_HELP_STRING([--with-pkg-git-version], [add git information to MOTD and build version string]),
 335         [ test "x$withval" != "xno" && with_pkg_git_version="yes" ])
 336 AC_ARG_WITH(vtysh_pager,
 337         AS_HELP_STRING([--with-vtysh-pager=PAGER], [control what pager is compiled in as default]),
 338         VTYSH_PAGER=$withval, VTYSH_PAGER="more")
 339 AC_ARG_ENABLE(vtysh,
 340   AS_HELP_STRING([--disable-vtysh], [do not build integrated vty shell for FRR]))
 341 AC_ARG_ENABLE(doc,
 342   AS_HELP_STRING([--disable-doc], [do not build docs]))
 343 AC_ARG_ENABLE(doc-html,
 344   AS_HELP_STRING([--enable-doc-html], [build HTML docs]))
 345 AC_ARG_ENABLE(zebra,
 346   AS_HELP_STRING([--disable-zebra], [do not build zebra daemon]))
 347 AC_ARG_ENABLE(bgpd,
 348   AS_HELP_STRING([--disable-bgpd], [do not build bgpd]))
 349 AC_ARG_ENABLE(ripd,
 350   AS_HELP_STRING([--disable-ripd], [do not build ripd]))
 351 AC_ARG_ENABLE(ripngd,
 352   AS_HELP_STRING([--disable-ripngd], [do not build ripngd]))
 353 AC_ARG_ENABLE(ospfd,
 354   AS_HELP_STRING([--disable-ospfd], [do not build ospfd]))
 355 AC_ARG_ENABLE(ospf6d,
 356   AS_HELP_STRING([--disable-ospf6d], [do not build ospf6d]))
 357 AC_ARG_ENABLE(ldpd,
 358   AS_HELP_STRING([--disable-ldpd], [do not build ldpd]))
 359 AC_ARG_ENABLE(nhrpd,
 360   AS_HELP_STRING([--disable-nhrpd], [do not build nhrpd]))
 361 AC_ARG_ENABLE(eigrpd,
 362   AS_HELP_STRING([--disable-eigrpd], [do not build eigrpd]))
 363 AC_ARG_ENABLE(babeld,
 364   AS_HELP_STRING([--disable-babeld], [do not build babeld]))
 365 AC_ARG_ENABLE(watchfrr,
 366   AS_HELP_STRING([--disable-watchfrr], [do not build watchfrr]))
 367 AC_ARG_ENABLE(isisd,
 368   AS_HELP_STRING([--disable-isisd], [do not build isisd]))
 369 AC_ARG_ENABLE(pimd,
 370   AS_HELP_STRING([--disable-pimd], [do not build pimd]))
 371 AC_ARG_ENABLE(pbrd,
 372   AS_HELP_STRING([--disable-pbrd], [do not build pbrd]))
 373 AC_ARG_ENABLE(sharpd,
 374   AS_HELP_STRING([--enable-sharpd], [build sharpd]))
 375 AC_ARG_ENABLE(staticd,
 376   AS_HELP_STRING([--disable-staticd], [do not build staticd]))
 377 AC_ARG_ENABLE(fabricd,
 378   AS_HELP_STRING([--disable-fabricd], [do not build fabricd]))
 379 AC_ARG_ENABLE(bgp-announce,
 380   AS_HELP_STRING([--disable-bgp-announce,], [turn off BGP route announcement]))
 381 AC_ARG_ENABLE(bgp-vnc,
 382   AS_HELP_STRING([--disable-bgp-vnc],[turn off BGP VNC support]))
 383 AC_ARG_ENABLE(snmp,
 384   AS_HELP_STRING([--enable-snmp], [enable SNMP support for agentx]))
 385 AC_ARG_ENABLE(zeromq,
 386   AS_HELP_STRING([--enable-zeromq], [enable ZeroMQ handler (libfrrzmq)]))
 387 AC_ARG_WITH(libpam,
 388   AS_HELP_STRING([--with-libpam], [use libpam for PAM support in vtysh]))
 389 AC_ARG_ENABLE(ospfapi,
 390   AS_HELP_STRING([--disable-ospfapi], [do not build OSPFAPI to access the OSPF LSA Database]))
 391 AC_ARG_ENABLE(ospfclient,
 392   AS_HELP_STRING([--disable-ospfclient], [do not build OSPFAPI client for OSPFAPI,
 393                           (this is the default if --disable-ospfapi is set)]))
 394 AC_ARG_ENABLE(multipath,
 395   AS_HELP_STRING([--enable-multipath=ARG], [enable multipath function, ARG must be digit]))
 396 AC_ARG_ENABLE(user,
 397   AS_HELP_STRING([--enable-user=USER], [user to run FRR suite as (default frr)]))
 398 AC_ARG_ENABLE(group,
 399   AS_HELP_STRING([--enable-group=GROUP], [group to run FRR suite as (default frr)]))
 400 AC_ARG_ENABLE(vty_group,
 401   AS_HELP_STRING([--enable-vty-group=ARG], [set vty sockets to have specified group as owner]))
 402 AC_ARG_ENABLE(configfile_mask,
 403   AS_HELP_STRING([--enable-configfile-mask=ARG], [set mask for config files]))
 404 AC_ARG_ENABLE(logfile_mask,
 405   AS_HELP_STRING([--enable-logfile-mask=ARG], [set mask for log files]))
 406 AC_ARG_ENABLE(shell_access,
 407   AS_HELP_STRING([--enable-shell-access], [Allow users to access shell/telnet/ssh]))
 408 AC_ARG_ENABLE(realms,
 409   AS_HELP_STRING([--enable-realms], [enable REALMS support under Linux]))
 410 AC_ARG_ENABLE(rtadv,
 411   AS_HELP_STRING([--disable-rtadv], [disable IPV6 router advertisement feature]))
 412 AC_ARG_ENABLE(irdp,
 413   AS_HELP_STRING([--disable-irdp], [enable IRDP server support in zebra (default if supported)]))
 414 AC_ARG_ENABLE(capabilities,
 415   AS_HELP_STRING([--disable-capabilities], [disable using POSIX capabilities]))
 416 AC_ARG_ENABLE(rusage,
 417   AS_HELP_STRING([--disable-rusage], [disable using getrusage]))
 418 AC_ARG_ENABLE(gcc_ultra_verbose,
 419   AS_HELP_STRING([--enable-gcc-ultra-verbose], [enable ultra verbose GCC warnings]))
 420 AC_ARG_ENABLE(backtrace,
 421   AS_HELP_STRING([--disable-backtrace,], [disable crash backtraces (default autodetect)]))
 422 AC_ARG_ENABLE(time-check,
 423   AS_HELP_STRING([--disable-time-check], [disable slow thread warning messages]))
 424 AC_ARG_ENABLE(pcreposix,
 425   AS_HELP_STRING([--enable-pcreposix], [enable using PCRE Posix libs for regex functions]))
 426 AC_ARG_ENABLE(fpm,
 427   AS_HELP_STRING([--enable-fpm], [enable Forwarding Plane Manager support]))
 428 AC_ARG_ENABLE(systemd,
 429   AS_HELP_STRING([--enable-systemd], [enable Systemd support]))
 430 AC_ARG_ENABLE(werror,
 431   AS_HELP_STRING([--enable-werror], [enable -Werror (recommended for developers only)]))
 432 AC_ARG_ENABLE(cumulus,
 433   AS_HELP_STRING([--enable-cumulus], [enable Cumulus Switch Special Extensions]))
 434 AC_ARG_ENABLE(datacenter,
 435   AS_HELP_STRING([--enable-datacenter], [enable Compilation for Data Center Extensions]))
 436 AC_ARG_ENABLE(fuzzing,
 437   AS_HELP_STRING([--enable-fuzzing], [enable ability to fuzz various parts of FRR]))
 438 AC_ARG_ENABLE(netlink_fuzzing,
 439   AS_HELP_STRING([--enable-netlink-fuzzing], [enable ability to fuzz netlink listening socket in zebra]))
 440 AC_ARG_ENABLE(rr-semantics,
 441   AS_HELP_STRING([--disable-rr-semantics], [disable the v6 Route Replace semantics]))
 442 AC_ARG_ENABLE([protobuf],
 443   AS_HELP_STRING([--enable-protobuf], [Enable experimental protobuf support]))
 444 AC_ARG_ENABLE([oldvpn_commands],
 445   AS_HELP_STRING([--enable-oldvpn-commands], [Keep old vpn commands]))
 446 AC_ARG_ENABLE(rpki,
 447   AS_HELP_STRING([--enable-rpki], [enable RPKI prefix validation support]))
 448 AC_ARG_ENABLE([clippy-only],
 449   AS_HELP_STRING([--enable-clippy-only], [Only build clippy]))
 450 AC_ARG_ENABLE([numeric_version],
 451   AS_HELP_STRING([--enable-numeric-version], [Only numeric digits allowed in version (for Alpine)]))
 452 AC_ARG_ENABLE([gcov],
 453   AS_HELP_STRING([--enable-gcov], [Add code coverage information]))
 454 AC_ARG_ENABLE(bfdd,
 455   AS_HELP_STRING([--disable-bfdd], [do not build bfdd]))
 456
 457 AS_IF([test "${enable_clippy_only}" != "yes"], [
 458 AC_CHECK_HEADERS(json-c/json.h)
 459 AC_CHECK_LIB(json-c, json_object_get, LIBS="$LIBS -ljson-c", [], [-lm])
 460 if test $ac_cv_lib_json_c_json_object_get = no; then
 461   AC_CHECK_LIB(json, json_object_get, LIBS="$LIBS -ljson")
 462   if test $ac_cv_lib_json_json_object_get = no; then
 463       AC_MSG_ERROR([lib json is needed to compile])
 464   fi
 465 fi
 466 ])
 467
 468 AC_ARG_ENABLE([dev_build],
 469     AS_HELP_STRING([--enable-dev-build], [build for development]))
 470
 471 if test x"${enable_time_check}" != x"no" ; then
 472   if test x"${enable_time_check}" = x"yes" -o x"${enable_time_check}" = x ; then
 473     AC_DEFINE(CONSUMED_TIME_CHECK,5000000,Consumed Time Check)
 474   else
 475     AC_DEFINE_UNQUOTED(CONSUMED_TIME_CHECK,$enable_time_check,Consumed Time Check)
 476   fi
 477 fi
 478
 479 case "${enable_systemd}" in
 480   "no") ;;
 481   "yes")
 482   AC_CHECK_LIB(systemd, sd_notify, LIBS="$LIBS -lsystemd")
 483   if test $ac_cv_lib_systemd_sd_notify = no; then
 484     AC_MSG_ERROR([enable systemd has been specified but systemd development env not found on your system])
 485   else
 486     AC_DEFINE(HAVE_SYSTEMD,,Compile systemd support in)
 487   fi
 488   ;;
 489   "*") ;;
 490 esac
 491
 492 if test "${enable_rr_semantics}" != "no" ; then
 493   AC_DEFINE(HAVE_V6_RR_SEMANTICS,, Compile in v6 Route Replacement Semantics)
 494 fi
 495
 496 if test "${enable_datacenter}" = "yes" ; then
 497   AC_DEFINE(HAVE_DATACENTER,,Compile extensions for a DataCenter)
 498   DFLT_NAME="datacenter"
 499 else
 500   DFLT_NAME="traditional"
 501 fi
 502
 503 if test "${enable_fuzzing}" = "yes" ; then
 504   AC_DEFINE(HANDLE_ZAPI_FUZZING,,Compile extensions to use with a fuzzer)
 505 fi
 506
 507 if test "${enable_netlink_fuzzing}" = "yes" ; then
 508   AC_DEFINE(HANDLE_NETLINK_FUZZING,,Compile extensions to use with a fuzzer for netlink)
 509 fi
 510
 511 if test "${enable_cumulus}" = "yes" ; then
 512   AC_DEFINE(HAVE_CUMULUS,,Compile Special Cumulus Code in)
 513 fi
 514
 515 AC_SUBST(DFLT_NAME)
 516 AC_DEFINE_UNQUOTED(DFLT_NAME,["$DFLT_NAME"], Name of the configuration default set)
 517
 518 if test "${enable_shell_access}" = "yes"; then
 519    AC_DEFINE(HAVE_SHELL_ACCESS,,Allow user to use ssh/telnet/bash)
 520 fi
 521
 522 AM_CONDITIONAL([FPM], [test "x$enable_fpm" = "xyes"])
 523
 524 #
 525 # Python for clippy
 526 #
 527
 528 AC_DEFUN([FRR_PYTHON_CHECK_WORKING], [
 529   AC_MSG_CHECKING([whether we found a working Python version])
 530   AC_LINK_IFELSE_FLAGS([$PYTHON_CFLAGS], [$PYTHON_LIBS], [AC_LANG_PROGRAM([
 531 #include <Python.h>
 532 #if PY_VERSION_HEX < 0x02070000
 533 #error python too old
 534 #endif
 535 int main(void);
 536 ],
 537 [
 538 {
 539   Py_Initialize();
 540   return 0;
 541 }
 542 ])], [
 543     # some python installs are missing the zlib dependency...
 544     PYTHON_LIBS="${PYTHON_LIBS} -lz"
 545     AC_LINK_IFELSE_FLAGS([$PYTHON_CFLAGS], [$PYTHON_LIBS], [AC_LANG_PROGRAM([
 546 #include <Python.h>
 547 #if PY_VERSION_HEX < 0x02070000
 548 #error python too old
 549 #endif
 550 int main(void);
 551 ],
 552 [
 553 {
 554   Py_Initialize();
 555   return 0;
 556 }
 557 ])], [
 558       m4_if([$1], [], [
 559         PYTHONCONFIG=""
 560         unset PYTHON_LIBS
 561         unset PYTHON_CFLAGS
 562       ], [$1])
 563     ])
 564   ])
 565 ])
 566
 567 AS_IF([test "$host" = "$build"], [
 568   PYTHONCONFIG=""
 569
 570   # ordering:
 571   # 1.  try python3, but respect the user's preference on which minor ver
 572   # 2.  try python, which might be py3 or py2 again on the user's preference
 573   # 3.  try python2 (can really only be 2.7 but eh)
 574   # 4.  try 3.6 > 3.5 > 3.4 > 3.3 > 3.2 > 2.7 through pkg-config (no user pref)
 575   #
 576   # (AX_PYTHON_DEVEL has no clue about py3 vs py2)
 577   # (AX_PYTHON does not do what we need)
 578
 579   AC_CHECK_TOOLS([PYTHONCONFIG], [ \
 580         python3-config \
 581         python-config \
 582         python2-config \
 583         python3.6-config \
 584         python3.5-config \
 585         python3.4-config \
 586         python3.3-config \
 587         python3.2-config \
 588         python2.7-config ])
 589   if test -n "$PYTHONCONFIG"; then
 590     PYTHON_CFLAGS="`\"${PYTHONCONFIG}\" --includes`"
 591     PYTHON_LIBS="`\"${PYTHONCONFIG}\" --ldflags`"
 592
 593     FRR_PYTHON_CHECK_WORKING([])
 594   fi
 595
 596   if test -z "$PYTHONCONFIG"; then
 597     PKG_CHECK_MODULES([PYTHON], python-3.6, [], [
 598       PKG_CHECK_MODULES([PYTHON], python-3.5, [], [
 599         PKG_CHECK_MODULES([PYTHON], python-3.4, [], [
 600           PKG_CHECK_MODULES([PYTHON], python-3.3, [], [
 601             PKG_CHECK_MODULES([PYTHON], python-3.2, [], [
 602               PKG_CHECK_MODULES([PYTHON], python-2.7, [], [
 603                 AC_MSG_FAILURE([could not find python-config or pkg-config python, please install Python development files from libpython-dev or similar])
 604                 ])])])])])])
 605
 606
 607     FRR_PYTHON_CHECK_WORKING([
 608       AC_MSG_FAILURE([could not find python-config or pkg-config python, please install Python development files from libpython-dev or similar])
 609     ])
 610   fi
 611 ])
 612 AC_SUBST(PYTHON_CFLAGS)
 613 AC_SUBST(PYTHON_LIBS)
 614
 615 #
 616 # Logic for protobuf support.
 617 #
 618 if test "$enable_protobuf" = "yes"; then
 619   # Check for protoc & protoc-c
 620
 621   # protoc is not required, it's only for a "be nice" helper target
 622   AC_CHECK_PROGS([PROTOC], [protoc], [/bin/false])
 623
 624   AC_CHECK_PROGS([PROTOC_C], [protoc-c], [/bin/false])
 625   if test "$PROTOC_C" = "/bin/false"; then
 626     AC_MSG_FAILURE([protobuf requested but protoc-c not found.  Install protobuf-c.])
 627   fi
 628
 629   PKG_CHECK_MODULES([PROTOBUF_C], [libprotobuf-c >= 0.14],, [
 630     AC_MSG_FAILURE([protobuf requested but libprotobuf-c not found.  Install protobuf-c.])
 631   ])
 632   AC_CHECK_HEADER([google/protobuf-c/protobuf-c.h], [], [
 633     AC_MSG_FAILURE([protobuf requested but protobuf-c.h not found.  Install protobuf-c.])
 634   ])
 635
 636   AC_DEFINE(HAVE_PROTOBUF,, protobuf)
 637 fi
 638 AM_CONDITIONAL([HAVE_PROTOBUF], [test "x$enable_protobuf" = "xyes"])
 639
 640 #
 641 # Logic for old vpn commans support.
 642 #
 643 if test "$enable_oldvpn_commands" = "yes"; then
 644    AC_DEFINE(KEEP_OLD_VPN_COMMANDS,, [Define for compiling with old vpn commands])
 645 fi
 646
 647 #
 648 # End of logic for protobuf support.
 649 #
 650
 651 AC_MSG_CHECKING(if zebra should be configurable to send Route Advertisements)
 652 if test "${enable_rtadv}" != "no"; then
 653   AC_MSG_RESULT(yes)
 654   AC_DEFINE(HAVE_RTADV,,Enable IPv6 Routing Advertisement support)
 655 else
 656   AC_MSG_RESULT(no)
 657 fi
 658
 659 if test x"${enable_user}" = x"no"; then
 660   enable_user=""
 661 else
 662   if test x"${enable_user}" = x"yes" || test x"${enable_user}" = x""; then
 663     enable_user="frr"
 664   fi
 665   AC_DEFINE_UNQUOTED(FRR_USER, "${enable_user}", frr User)
 666 fi
 667
 668 if test x"${enable_group}" = x"no"; then
 669   enable_group=""
 670 else
 671   if test x"${enable_group}" = x"yes" || test x"${enable_group}" = x""; then
 672     enable_group="frr"
 673   fi
 674   AC_DEFINE_UNQUOTED(FRR_GROUP, "${enable_group}", frr Group)
 675 fi
 676
 677 if test x"${enable_vty_group}" = x"yes" ; then
 678   AC_MSG_ERROR([--enable-vty-group requires a group as argument, not yes])
 679 elif test x"${enable_vty_group}" != x""; then
 680   if test x"${enable_vty_group}" != x"no"; then
 681     AC_DEFINE_UNQUOTED(VTY_GROUP, "${enable_vty_group}", VTY Sockets Group)
 682   fi
 683 fi
 684 AC_SUBST([enable_user])
 685 AC_SUBST([enable_group])
 686 AC_SUBST([enable_vty_group])
 687
 688 enable_configfile_mask=${enable_configfile_mask:-0600}
 689 AC_DEFINE_UNQUOTED(CONFIGFILE_MASK, ${enable_configfile_mask}, Mask for config files)
 690
 691 enable_logfile_mask=${enable_logfile_mask:-0600}
 692 AC_DEFINE_UNQUOTED(LOGFILE_MASK, ${enable_logfile_mask}, Mask for log files)
 693
 694 MPATH_NUM=1
 695
 696 case "${enable_multipath}" in
 697   0)
 698     MPATH_NUM=64
 699     ;;
 700   [[1-9]|[1-9][0-9]|[1-9][0-9][0-9]])
 701     MPATH_NUM="${enable_multipath}"
 702     ;;
 703   "")
 704     ;;
 705   *)
 706     AC_MSG_FAILURE([Please specify digit to enable multipath ARG])
 707     ;;
 708 esac
 709
 710 AC_DEFINE_UNQUOTED(MULTIPATH_NUM, $MPATH_NUM, Maximum number of paths for a route)
 711
 712 AC_DEFINE_UNQUOTED(VTYSH_PAGER, "$VTYSH_PAGER", [What pager to use])
 713
 714 dnl --------------------
 715 dnl Enable code coverage
 716 dnl --------------------
 717 AM_CONDITIONAL([HAVE_GCOV],[test '!' "$enable_gcov" = no])
 718
 719 dnl ------------------------------------
 720 dnl Alpine only accepts numeric versions
 721 dnl ------------------------------------
 722 if test "x${enable_numeric_version}" != "x" ; then
 723   VERSION="`echo ${VERSION} | tr -c -d '[[.0-9]]'`"
 724   PACKAGE_VERSION="`echo ${PACKAGE_VERSION} | tr -c -d '[[.0-9]]'`"
 725 fi
 726
 727 dnl -----------------------------------
 728 dnl Add extra version string to package
 729 dnl name, string and version fields.
 730 dnl -----------------------------------
 731 if test "x${EXTRAVERSION}" != "x" ; then
 732   VERSION="${VERSION}${EXTRAVERSION}"
 733   PACKAGE_VERSION="${PACKAGE_VERSION}${EXTRAVERSION}"
 734   AC_SUBST(PACKAGE_EXTRAVERSION, ["${EXTRAVERSION}"])
 735   PACKAGE_STRING="${PACKAGE_STRING}${EXTRAVERSION}"
 736 fi
 737
 738 if test "x$with_pkg_git_version" = "xyes"; then
 739         if test -d "${srcdir}/.git"; then
 740                 AC_DEFINE(GIT_VERSION, [1], [include git version info])
 741         else    with_pkg_git_version="no"
 742                 AC_MSG_WARN([--with-pkg-git-version given, but this is not a git checkout])
 743         fi
 744 fi
 745 AM_CONDITIONAL([GIT_VERSION], [test "x$with_pkg_git_version" = "xyes"])
 746
 747 dnl ------------------------------------
 748 dnl Check C keywords and standard  types
 749 dnl ------------------------------------
 750 AC_C_CONST
 751 AC_C_INLINE
 752 AC_C_VOLATILE
 753 AC_HEADER_STDC
 754 dnl AC_TYPE_PID_T
 755 AC_TYPE_UID_T
 756 AC_TYPE_MODE_T
 757 AC_TYPE_SIZE_T
 758 AC_STRUCT_TM
 759
 760 dnl -------------------------
 761 dnl Check other header files.
 762 dnl -------------------------
 763 AC_CHECK_HEADERS([stropts.h sys/ksym.h \
 764         linux/version.h asm/types.h \
 765         sys/cdefs.h])
 766
 767 ac_stdatomic_ok=false
 768 AC_DEFINE(FRR_AUTOCONF_ATOMIC, 1, [did autoconf checks for atomic funcs])
 769 AC_CHECK_HEADER([stdatomic.h],[
 770
 771   AC_MSG_CHECKING([whether _Atomic qualifier works])
 772   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 773 #include <stdatomic.h>
 774 int main(int argc, char **argv) {
 775   _Atomic int i = 0;
 776   return i;
 777 }
 778 ]])], [
 779     AC_DEFINE(HAVE_STDATOMIC_H, 1, [found stdatomic.h])
 780     AC_MSG_RESULT([yes])
 781     ac_stdatomic_ok=true
 782   ], [
 783     AC_MSG_RESULT([no])
 784   ])
 785 ])
 786
 787 AS_IF([$ac_stdatomic_ok], [true], [
 788   AC_MSG_CHECKING([for __atomic_* builtins])
 789   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 790 int main(int argc, char **argv) {
 791   volatile int i = 1;
 792   __atomic_store_n (&i, 0, __ATOMIC_RELEASE);
 793   return __atomic_load_n (&i, __ATOMIC_ACQUIRE);
 794 }
 795 ]])], [
 796     AC_DEFINE(HAVE___ATOMIC, 1, [found __atomic builtins])
 797     AC_MSG_RESULT([yes])
 798   ], [
 799     AC_MSG_RESULT([no])
 800
 801     dnl FreeBSD 9 has a broken stdatomic.h where _Atomic doesn't work
 802     AC_MSG_CHECKING([for __sync_* builtins])
 803     AC_LINK_IFELSE([AC_LANG_SOURCE([[
 804 int main(int argc, char **argv) {
 805   volatile int i = 1;
 806   __sync_fetch_and_sub (&i, 1);
 807   return __sync_val_compare_and_swap (&i, 0, 1);
 808 }
 809 ]])], [
 810       AC_DEFINE(HAVE___SYNC, 1, [found __sync builtins])
 811       AC_MSG_RESULT([yes])
 812
 813       AC_MSG_CHECKING([for __sync_swap builtin])
 814       AC_LINK_IFELSE([AC_LANG_SOURCE([[
 815 int main(int argc, char **argv) {
 816   volatile int i = 1;
 817   return __sync_swap (&i, 2);
 818 }
 819 ]])], [
 820         AC_DEFINE(HAVE___SYNC_SWAP, 1, [found __sync_swap builtin])
 821         AC_MSG_RESULT([yes])
 822       ], [
 823         AC_MSG_RESULT([no])
 824       ])
 825
 826     ], [
 827       AC_MSG_RESULT([no])
 828       AC_MSG_FAILURE([stdatomic.h unavailable and $CC has neither __atomic nor __sync builtins])
 829     ])
 830   ])
 831 ])
 832
 833 dnl Utility macro to avoid retyping includes all the time
 834 m4_define([FRR_INCLUDES],
 835 [#ifdef SUNOS_5
 836 #define _XPG4_2
 837 #define __EXTENSIONS__
 838 #endif
 839 #include <stdio.h>
 840 #include <stdlib.h>
 841 #include <stddef.h>
 842 #include <sys/types.h>
 843 /* sys/conf.h depends on param.h on FBSD at least */
 844 #include <sys/param.h>
 845 /* Required for MAXSIG */
 846 #include <signal.h>
 847 #include <sys/socket.h>
 848 #ifdef __APPLE__
 849 # define __APPLE_USE_RFC_3542
 850 #endif
 851 #include <netinet/in.h>
 852 #include <sys/time.h>
 853 #include <time.h>
 854 #include <net/if.h>
 855 ])dnl
 856
 857 dnl Same applies for HAVE_NET_IF_VAR_H, which HAVE_NETINET6_ND6_H and
 858 dnl HAVE_NETINET_IN_VAR_H depend upon. But if_var.h depends on if.h, hence
 859 dnl an additional round for it.
 860
 861 AC_CHECK_HEADERS([net/if_var.h], [], [], FRR_INCLUDES)
 862
 863 m4_define([FRR_INCLUDES],
 864 FRR_INCLUDES
 865 [#if HAVE_NET_IF_VAR_H
 866 # include <net/if_var.h>
 867 #endif
 868 ])dnl
 869
 870 AC_CHECK_HEADERS([netinet/in_var.h \
 871         net/if_dl.h net/netopt.h \
 872         inet/nd.h netinet/ip_icmp.h \
 873         sys/sysctl.h sys/sockio.h kvm.h sys/conf.h],
 874         [], [], FRR_INCLUDES)
 875
 876 AC_CHECK_HEADERS([ucontext.h], [], [],
 877 [#ifndef __USE_GNU
 878 #define __USE_GNU
 879 #endif /* __USE_GNU */
 880 FRR_INCLUDES
 881 ])
 882
 883 m4_define([UCONTEXT_INCLUDES],
 884 [#include <ucontext.h>])dnl
 885
 886 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.uc_regs],
 887   [], [], [UCONTEXT_INCLUDES])
 888 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs],
 889   [AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs.nip],
 890    [], [], [UCONTEXT_INCLUDES])],
 891   [], [UCONTEXT_INCLUDES])
 892 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.gregs],
 893   [], [], [UCONTEXT_INCLUDES])
 894
 895 m4_define([FRR_INCLUDES],
 896 FRR_INCLUDES
 897 [
 898 #include <sys/un.h>
 899 #include <netinet/in_systm.h>
 900 #if HAVE_NETINET_IN_VAR_H
 901 # include <netinet/in_var.h>
 902 #endif
 903 #if HAVE_NET_IF_DL_H
 904 # include <net/if_dl.h>
 905 #endif
 906 #if HAVE_NET_NETOPT_H
 907 # include <net/netopt.h>
 908 #endif
 909 #include <net/route.h>
 910 #if HAVE_INET_ND_H
 911 # include <inet/nd.h>
 912 #endif
 913 #include <arpa/inet.h>
 914 /* Required for IDRP */
 915 #if HAVE_NETINET_IP_ICMP_H
 916 # include <netinet/ip_icmp.h>
 917 #endif
 918 ])dnl
 919
 920 dnl V6 headers are checked below, after we check for v6
 921
 922 AC_MSG_CHECKING([which operating system interface to use])
 923 case "$host_os" in
 924   sunos* | solaris2*)
 925     AC_MSG_RESULT([Solaris])
 926
 927     AC_DEFINE(SUNOS_5, 1, [SunOS 5])
 928     AC_DEFINE(SOLARIS_IPV6, 1, Solaris IPv6)
 929
 930     AC_CHECK_LIB(socket, main)
 931     AC_CHECK_LIB(nsl, main)
 932     AC_CHECK_LIB(umem, main)
 933     AC_CHECK_FUNCS([printstack], [
 934       AC_DEFINE([HAVE_PRINTSTACK],1,[Solaris printstack])
 935       AC_DEFINE([HAVE_STACK_TRACE],1,[Stack symbols decode functionality])
 936     ])
 937     CURSES=-lcurses
 938     SOLARIS="solaris"
 939     ;;
 940   linux*)
 941     AC_MSG_RESULT([Linux])
 942
 943     AC_DEFINE(GNU_LINUX,,GNU Linux)
 944     AC_DEFINE(HAVE_NETLINK,,netlink)
 945     AC_DEFINE(LINUX_IPV6,1,Linux IPv6 stack)
 946
 947     dnl Linux has a compilation problem with mixing
 948     dnl netinet/in.h and linux/in6.h they are not
 949     dnl compatible.  There has been discussion on
 950     dnl how to fix it but no real progress on implementation
 951     dnl when they fix it, remove this
 952     AC_DEFINE(IPV6_MINHOPCOUNT, 73, Linux ipv6 Min Hop Count)
 953     ;;
 954   openbsd*)
 955     AC_MSG_RESULT([OpenBSD])
 956
 957     AC_DEFINE(OPEN_BSD,,OpenBSD)
 958     AC_DEFINE(KAME,1,KAME IPv6)
 959     AC_DEFINE(BSD_V6_SYSCTL,1,BSD v6 sysctl to turn on and off forwarding)
 960
 961     if test "x${enable_pimd}" != "xno"; then
 962       case "$host_os" in
 963       openbsd6.0)
 964         ;;
 965       openbsd[6-9]*)
 966         AC_MSG_FAILURE([pimd cannot be enabled as PIM support has been removed from OpenBSD 6.1])
 967         ;;
 968       esac
 969     fi
 970     ;;
 971   *)
 972     AC_MSG_RESULT([BSD])
 973
 974     AC_DEFINE(HAVE_NET_RT_IFLIST,,NET_RT_IFLIST)
 975     AC_DEFINE(KAME,1,KAME IPv6)
 976     AC_DEFINE(BSD_V6_SYSCTL,1,BSD v6 sysctl to turn on and off forwarding)
 977     ;;
 978 esac
 979 AM_CONDITIONAL(SOLARIS, test "${SOLARIS}" = "solaris")
 980
 981 AC_SYS_LARGEFILE
 982
 983 dnl ------------------------
 984 dnl Integrated REALMS option
 985 dnl ------------------------
 986 if test "${enable_realms}" = "yes"; then
 987     case "$host_os" in
 988       linux*)
 989        AC_DEFINE(SUPPORT_REALMS,, Realms support)
 990        ;;
 991       *)
 992        echo "Sorry, only Linux has REALMS support"
 993        exit 1
 994        ;;
 995     esac
 996 fi
 997 AM_CONDITIONAL([SUPPORT_REALMS], [test "${enable_realms}" = "yes"])
 998
 999 dnl ---------------------
1000 dnl Integrated VTY option
1001 dnl ---------------------
1002 case "${enable_vtysh}" in
1003   "no") VTYSH="";;
1004   *)    VTYSH="vtysh";
1005          AC_DEFINE(VTYSH,,VTY shell)
1006 dnl      Vtysh uses libreadline, which looks for termcap functions at
1007 dnl      configure time.  We follow readlines search order.
1008 dnl      The required procedures are in libtermcap on NetBSD, in
1009 dnl      [TODO] on Linux, and in [TODO] on Solaris.
1010          AC_CHECK_LIB(termcap, tputs, LIBREADLINE="$LIBREADLINE -ltermcap",
1011            [AC_CHECK_LIB(tinfo, tputs, LIBREADLINE="$LIBREADLINE -ltinfo",
1012              [AC_CHECK_LIB(curses, tputs, LIBREADLINE="$LIBREADLINE -lcurses",
1013                [AC_CHECK_LIB(ncurses, tputs,
1014                              LIBREADLINE="$LIBREADLINE -lncurses")]
1015               )]
1016             )]
1017           )
1018          AC_CHECK_LIB(readline, main, LIBREADLINE="-lreadline $LIBREADLINE",,
1019                       "$LIBREADLINE")
1020          if test $ac_cv_lib_readline_main = no; then
1021            AC_MSG_ERROR([vtysh needs libreadline but was not found and usable on your system.])
1022          fi
1023          AC_CHECK_HEADER(readline/history.h)
1024          if test $ac_cv_header_readline_history_h = no;then
1025            AC_MSG_ERROR([readline is too old to have readline/history.h, please update to the latest readline library.])
1026          fi
1027          AC_CHECK_LIB(readline, rl_completion_matches,
1028                       LIBREADLINE="$LIBREADLINE",, "$LIBREADLINE")
1029          if test $ac_cv_lib_readline_rl_completion_matches = no; then
1030            AC_DEFINE(rl_completion_matches,completion_matches,Old readline)
1031          fi
1032          AC_SEARCH_LIBS([append_history], [readline], [frr_cv_append_history=yes], [frr_cv_append_history=no])
1033          if test "$frr_cv_append_history" = yes; then
1034            AC_DEFINE(HAVE_APPEND_HISTORY, 1, [Have history.h append_history])
1035          fi
1036          ;;
1037 esac
1038 AC_SUBST(LIBREADLINE)
1039 AM_CONDITIONAL(VTYSH, test "x$VTYSH" = "xvtysh")
1040
1041 dnl ----------
1042 dnl PAM module
1043 dnl
1044 dnl FRR detects the PAM library it is built against by checking for a
1045 dnl functional pam_misc.h (Linux-PAM) or openpam.h (OpenPAM) header. pam_misc.h
1046 dnl is known to #include pam_appl.h, the standard header of a PAM library, and
1047 dnl openpam.h doesn't do that, although depends on the header too. Hence a
1048 dnl little assistance to AC_CHECK_HEADER is necessary for the proper detection
1049 dnl of OpenPAM.
1050 dnl ----------
1051 if test "$with_libpam" = "yes"; then
1052   AC_CHECK_HEADER([security/pam_misc.h],
1053     [AC_DEFINE(HAVE_PAM_MISC_H,,Have pam_misc.h)
1054      AC_DEFINE(PAM_CONV_FUNC,misc_conv,Have misc_conv)
1055      pam_conv_func="misc_conv"
1056     ],
1057     [], FRR_INCLUDES)
1058   AC_CHECK_HEADER([security/openpam.h],
1059     [AC_DEFINE(HAVE_OPENPAM_H,,Have openpam.h)
1060      AC_DEFINE(PAM_CONV_FUNC,openpam_ttyconv,Have openpam_ttyconv)
1061      pam_conv_func="openpam_ttyconv"
1062     ],
1063     [], FRR_INCLUDES[#include <security/pam_appl.h>])
1064   if test -z "$ac_cv_header_security_pam_misc_h$ac_cv_header_security_openpam_h" ; then
1065     AC_MSG_WARN([*** pam support will not be built ***])
1066     with_libpam="no"
1067   fi
1068 fi
1069
1070 if test "$with_libpam" = "yes"; then
1071 dnl took this test from proftpds configure.in and suited to our needs
1072 dnl -------------------------------------------------------------------------
1073 dnl
1074 dnl This next check looks funky due to a linker problem with some versions
1075 dnl of the PAM library.  Prior to 0.72 release, the Linux PAM shared library
1076 dnl omitted requiring libdl linking information. PAM-0.72 or better ships
1077 dnl with RedHat 6.2 and Debian 2.2 or better.
1078 AC_CHECK_LIB(pam, pam_start,
1079   [AC_CHECK_LIB(pam, $pam_conv_func,
1080     [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1081      LIBPAM="-lpam"],
1082     [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1083      LIBPAM="-lpam -lpam_misc"]
1084     )
1085   ],
1086
1087   [AC_CHECK_LIB(pam, pam_end,
1088     [AC_CHECK_LIB(pam, $pam_conv_func,
1089       [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1090        LIBPAM="-lpam -ldl"],
1091       [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1092        LIBPAM="-lpam -ldl -lpam_misc"]
1093      )
1094   ],AC_MSG_WARN([*** pam support will not be built ***]),
1095   [-ldl])
1096   ]
1097 )
1098 fi
1099 AC_SUBST(LIBPAM)
1100
1101 dnl -------------------------------
1102 dnl Endian-ness check
1103 dnl -------------------------------
1104 AC_WORDS_BIGENDIAN
1105
1106 dnl -------------------------------
1107 dnl check the size in byte of the C
1108 dnl -------------------------------
1109 dnl AC_CHECK_SIZEOF(char)
1110 dnl AC_CHECK_SIZEOF(int)
1111 dnl AC_CHECK_SIZEOF(short)
1112 dnl AC_CHECK_SIZEOF(long)
1113
1114 dnl ----------------------------
1115 dnl check existance of functions
1116 dnl ----------------------------
1117 AC_FUNC_FNMATCH
1118 AC_FUNC_FORK
1119 AC_FUNC_MKTIME
1120 AC_FUNC_STAT
1121
1122 dnl -------------------------------
1123 dnl bgpd needs pow() and hence libm
1124 dnl -------------------------------
1125 TMPLIBS="$LIBS"
1126 AC_CHECK_HEADER([math.h],
1127   [AC_CHECK_LIB([m], [pow],
1128     [LIBM="-lm"
1129      LIBS="$LIBS $LIBM"
1130      AC_CHECK_FUNCS(pow,[],[LIBM=""])
1131     ])
1132 ])
1133 if test x"$LIBM" = x ; then
1134   AC_MSG_WARN([Unable to find working pow function - bgpd may not link])
1135 fi
1136 LIBS="$TMPLIBS"
1137 AC_SUBST(LIBM)
1138
1139 AC_CHECK_FUNCS([ppoll], [
1140   AC_DEFINE([HAVE_PPOLL], 1, [have Linux/BSD ppoll()])
1141 ])
1142 AC_CHECK_FUNCS([pollts], [
1143   AC_DEFINE([HAVE_POLLTS], 1, [have NetBSD pollts()])
1144 ])
1145
1146 dnl ---------------
1147 dnl other functions
1148 dnl ---------------
1149 AC_CHECK_FUNCS([ \
1150         strlcat strlcpy \
1151         getgrouplist])
1152
1153 AC_CHECK_HEADER([asm-generic/unistd.h],
1154                 [AC_CHECK_DECL(__NR_setns,
1155                                AC_DEFINE(HAVE_NETNS,, Have netns),,
1156                                FRR_INCLUDES [#include <asm-generic/unistd.h>
1157                                ])
1158                  AC_CHECK_FUNCS(setns)]
1159                )
1160
1161 dnl --------------------------
1162 dnl Determine IS-IS I/O method
1163 dnl --------------------------
1164 AC_DEFINE(ISIS_METHOD_PFPACKET, 1, [ constant value for isis method pfpacket ])
1165 AC_DEFINE(ISIS_METHOD_DLPI,     2, [ constant value for isis method dlpi ])
1166 AC_DEFINE(ISIS_METHOD_BPF,      3, [ constant value for isis method bpf ])
1167 AC_CHECK_HEADER(net/bpf.h)
1168 AC_CHECK_HEADER(sys/dlpi.h)
1169 AC_MSG_CHECKING(zebra IS-IS I/O method)
1170
1171 case "$host_os" in
1172   linux*)
1173     AC_MSG_RESULT(pfpacket)
1174     ISIS_METHOD_MACRO="ISIS_METHOD_PFPACKET"
1175     ;;
1176   solaris* | sunos*)
1177     AC_MSG_RESULT(DLPI)
1178     ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1179     ;;
1180   *)
1181     if test $ac_cv_header_net_bpf_h = no; then
1182       if test $ac_cv_header_sys_dlpi_h = no; then
1183         AC_MSG_RESULT(none)
1184         if test "${enable_isisd}" = yes -o "${enable_fabricd}" = yes; then
1185           AC_MSG_FAILURE([IS-IS support requested but no packet backend found])
1186         fi
1187         AC_MSG_WARN([*** IS-IS support will not be built ***])
1188         enable_isisd="no"
1189         enable_fabricd="no"
1190       else
1191         AC_MSG_RESULT(DLPI)
1192       fi
1193       ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1194     else
1195       AC_MSG_RESULT(BPF)
1196       ISIS_METHOD_MACRO="ISIS_METHOD_BPF"
1197     fi
1198     ;;
1199 esac
1200 AC_DEFINE_UNQUOTED(ISIS_METHOD, $ISIS_METHOD_MACRO, [ selected method for isis, == one of the constants ])
1201
1202 dnl ---------------------------------------------------------------
1203 dnl figure out how to specify an interface in multicast sockets API
1204 dnl ---------------------------------------------------------------
1205 AC_CHECK_MEMBERS([struct ip_mreqn.imr_ifindex], [], [], FRR_INCLUDES)
1206
1207 AC_CHECK_HEADERS([linux/mroute.h], [], [],[
1208         #include <sys/socket.h>
1209         #include <netinet/in.h>
1210         #define _LINUX_IN_H             /* For Linux <= 2.6.25 */
1211         #include <linux/types.h>
1212 ])
1213
1214 m4_define([FRR_INCLUDES],
1215 FRR_INCLUDES
1216 [#if HAVE_LINUX_MROUTE_H
1217 # include <linux/mroute.h>
1218 #endif
1219 ])dnl
1220
1221 AC_CHECK_HEADERS([netinet/ip_mroute.h], [], [],[
1222         #include <sys/socket.h>
1223         #include <sys/types.h>
1224         #include <netinet/in.h>
1225         #include <net/route.h>
1226 ])
1227
1228 m4_define([FRR_INCLUDES],
1229 FRR_INCLUDES
1230 [#if HAVE_NETINET_IP_MROUTE_H
1231 # include <netinet/ip_mroute.h>
1232 #endif
1233 ])dnl
1234
1235 AC_MSG_CHECKING([for BSD struct ip_mreq hack])
1236 AC_TRY_COMPILE([#include <sys/param.h>],
1237 [#if (defined(__FreeBSD__) && ((__FreeBSD_version >= 500022 && __FreeBSD_version < 700000) || (__FreeBSD_version < 500000 && __FreeBSD_version >= 440000))) || (defined(__NetBSD__) && defined(__NetBSD_Version__) && __NetBSD_Version__ >= 106010000) || defined(__OpenBSD__) || defined(__APPLE__) || defined(__DragonFly__) || defined(__sun)
1238   return (0);
1239 #else
1240   #error No support for BSD struct ip_mreq hack detected
1241 #endif],[AC_MSG_RESULT(yes)
1242 AC_DEFINE(HAVE_BSD_STRUCT_IP_MREQ_HACK,,[Can pass ifindex in struct ip_mreq])],
1243 AC_MSG_RESULT(no))
1244
1245 AC_MSG_CHECKING([for RFC3678 protocol-independed API])
1246 AC_TRY_COMPILE([
1247 #include <sys/types.h>
1248 #include <netinet/in.h>
1249 ], [struct group_req gr; int sock; setsockopt(sock, IPPROTO_IP, MCAST_JOIN_GROUP, (void*)&gr, sizeof(gr));
1250 ], [AC_MSG_RESULT(yes)
1251 AC_DEFINE(HAVE_RFC3678,1,[Have RFC3678 protocol-independed API])],
1252 AC_MSG_RESULT(no))
1253
1254 dnl ---------------------------------------------------------------
1255 dnl figure out how to check link-state
1256 dnl ---------------------------------------------------------------
1257 AC_CHECK_HEADER( [net/if_media.h],
1258   [m4_define([LINK_DETECT_INCLUDES],
1259     FRR_INCLUDES
1260     [#include <net/if_media.h>
1261   ])
1262   AC_CHECK_MEMBERS( [struct ifmediareq.ifm_status],
1263     AC_DEFINE(HAVE_BSD_LINK_DETECT,,[BSD link-detect]),
1264     [], LINK_DETECT_INCLUDES)],
1265   [],
1266   FRR_INCLUDES)
1267
1268 dnl ---------------------------------------------------------------
1269 dnl Additional, newer way to check link-state using ifi_link_state.
1270 dnl Not available in all BSD's when ifmediareq available
1271 dnl ---------------------------------------------------------------
1272 AC_CHECK_MEMBERS([struct if_data.ifi_link_state],
1273   AC_DEFINE(HAVE_BSD_IFI_LINK_STATE,,[BSD ifi_link_state available]),
1274   [], FRR_INCLUDES)
1275
1276 dnl ------------------------
1277 dnl TCP_MD5SIG socket option
1278 dnl ------------------------
1279
1280 AC_CHECK_HEADER([netinet/tcp.h],
1281    [m4_define([MD5_INCLUDES],
1282       FRR_INCLUDES
1283       [#include <netinet/tcp.h>
1284     ])
1285     AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)],
1286    [],
1287    FRR_INCLUDES)
1288 if test $ac_cv_have_decl_TCP_MD5SIG = no; then
1289   AC_CHECK_HEADER([linux/tcp.h],
1290        [m4_define([MD5_INCLUDES],
1291           FRR_INCLUDES
1292           [#include <linux/tcp.h>
1293         ])
1294        AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)])
1295 fi
1296
1297 dnl ----------------------------------------------------------------------------
1298 dnl figure out if domainname is available in the utsname struct (GNU extension).
1299 dnl ----------------------------------------------------------------------------
1300 AC_CHECK_MEMBERS([struct utsname.domainname], [], [], [#include <sys/utsname.h>])
1301
1302 dnl ------------------
1303 dnl IPv6 header checks
1304 dnl ------------------
1305 AC_CHECK_HEADERS([netinet6/in6.h netinet/in6_var.h \
1306         netinet6/in6_var.h netinet6/nd6.h], [], [],
1307         FRR_INCLUDES)
1308
1309 m4_define([FRR_INCLUDES],dnl
1310 FRR_INCLUDES
1311 [#if HAVE_NETINET6_IN6_H
1312 #include <netinet6/in6.h>
1313 #endif
1314 #if HAVE_NETINET_IN6_VAR_H
1315 #include <netinet/in6_var.h>
1316 #endif
1317 #include <netinet/icmp6.h>
1318 #if HAVE_NETINET6_IN6_VAR_H
1319 # include <netinet6/in6_var.h>
1320 #endif
1321 #if HAVE_NETINET6_ND6_H
1322 # include <netinet6/nd6.h>
1323 #endif
1324 ])dnl
1325
1326 dnl disable doc check
1327 AC_CHECK_PROGS([SPHINXBUILD], [sphinx-build sphinx-build3 sphinx-build2], [no])
1328 AM_CONDITIONAL(DOC, test "${enable_doc}" != "no")
1329 AM_CONDITIONAL(DOC_HTML, test "${enable_doc_html}" = "yes")
1330
1331 dnl --------------------
1332 dnl Daemon disable check
1333 dnl --------------------
1334 AM_CONDITIONAL(ZEBRA, test "${enable_zebra}" != "no")
1335
1336 if test "${enable_bgpd}" = "no";then
1337   BGPD=""
1338 else
1339   BGPD="bgpd"
1340 fi
1341 AM_CONDITIONAL(BGPD, test "x$BGPD" = "xbgpd")
1342
1343 AM_CONDITIONAL(RIPD, test "${enable_ripd}" != "no")
1344 AM_CONDITIONAL(OSPFD, test "${enable_ospfd}" != "no")
1345 AM_CONDITIONAL(LDPD, test "${enable_ldpd}" != "no")
1346
1347 AS_IF([test "${enable_ldpd}" != "no"], [
1348   AC_DEFINE(HAVE_LDPD, 1, ldpd)
1349 ])
1350
1351 if test "$enable_bfdd" = "no"; then
1352   AC_DEFINE(HAVE_BFDD, 0, bfdd)
1353   BFDD=""
1354 else
1355   AC_DEFINE(HAVE_BFDD, 1, bfdd)
1356   BFDD="bfdd"
1357
1358   case $host_os in
1359     linux*)
1360       AC_DEFINE(BFD_LINUX, 1, bfdd)
1361       ;;
1362
1363     *)
1364       AC_DEFINE(BFD_BSD, 1, bfdd)
1365       ;;
1366   esac
1367 fi
1368
1369 AM_CONDITIONAL(BFDD, [test "x$BFDD" = "xbfdd"])
1370
1371 if test $ac_cv_lib_json_c_json_object_get = no -a "x$BFDD" = "xbfdd"; then
1372   AC_MSG_ERROR(["you must use json-c library to use bfdd"])
1373 fi
1374
1375 NHRPD=""
1376 case "$host_os" in
1377   linux*)
1378     if test "${enable_nhrpd}" != "no"; then
1379       NHRPD="nhrpd"
1380     fi
1381     ;;
1382   *)
1383     if test "${enable_nhrpd}" = "yes"; then
1384       AC_MSG_ERROR([nhrpd requires kernel APIs that are only present on Linux.])
1385     fi
1386     ;;
1387 esac
1388 AM_CONDITIONAL(NHRPD, test "x$NHRPD" = "xnhrpd")
1389
1390 AM_CONDITIONAL(EIGRPD, test "${enable_eigrpd}" != "no")
1391
1392 if test "${enable_watchfrr}" = "no";then
1393   WATCHFRR=""
1394 else
1395   WATCHFRR="watchfrr"
1396 fi
1397 AM_CONDITIONAL(WATCHFRR, test "x$WATCHFRR" = "xwatchfrr")
1398
1399 OSPFCLIENT=""
1400 if test "${enable_ospfapi}" != "no";then
1401     AC_DEFINE(SUPPORT_OSPF_API,,OSPFAPI)
1402
1403   if test "${enable_ospfclient}" != "no";then
1404       OSPFCLIENT="ospfclient"
1405   fi
1406 fi
1407
1408 AM_CONDITIONAL(OSPFCLIENT, test "x$OSPFCLIENT" = "xospfclient")
1409 AM_CONDITIONAL(RIPNGD, test "${enable_ripngd}" != "no")
1410 AM_CONDITIONAL(BABELD, test "${enable_babeld}" != "no")
1411 AM_CONDITIONAL(OSPF6D, test "${enable_ospf6d}" != "no")
1412 AM_CONDITIONAL(ISISD, test "${enable_isisd}" != "no")
1413 AM_CONDITIONAL(PIMD, test "${enable_pimd}" != "no")
1414 AM_CONDITIONAL(PBRD, test "${enable_pbrd}" != "no")
1415 AM_CONDITIONAL(SHARPD, test "${enable_sharpd}" = "yes")
1416 AM_CONDITIONAL(STATICD, test "${enable_staticd}" != "no")
1417 AM_CONDITIONAL(FABRICD, test "${enable_fabricd}" != "no")
1418
1419 if test "${enable_bgp_announce}" = "no";then
1420   AC_DEFINE(DISABLE_BGP_ANNOUNCE,1,Disable BGP installation to zebra)
1421 else
1422   AC_DEFINE(DISABLE_BGP_ANNOUNCE,0,Disable BGP installation to zebra)
1423 fi
1424
1425 if test "${enable_bgp_vnc}" != "no";then
1426   AC_DEFINE(ENABLE_BGP_VNC,1,Enable BGP VNC support)
1427 fi
1428 AM_CONDITIONAL([ENABLE_BGP_VNC], [test x${enable_bgp_vnc} != xno])
1429
1430 AC_SUBST(SOLARIS)
1431 AC_SUBST(CURSES)
1432 AC_CHECK_LIB(crypt, crypt, [],
1433                     [AC_CHECK_LIB(crypto, DES_crypt)])
1434 AC_CHECK_LIB(resolv, res_init)
1435
1436 dnl ---------------------------
1437 dnl check system has PCRE regexp
1438 dnl ---------------------------
1439 if test "x$enable_pcreposix" = "xyes"; then
1440   AC_CHECK_LIB(pcreposix, regexec, [], [
1441     AC_MSG_ERROR([--enable-pcreposix given but unable to find libpcreposix])
1442   ])
1443 fi
1444 AC_SUBST(HAVE_LIBPCREPOSIX)
1445
1446 dnl ------------------
1447 dnl check C-Ares library
1448 dnl ------------------
1449 if test "${NHRPD}" != ""; then
1450   PKG_CHECK_MODULES([CARES], [libcares], , [
1451     AC_MSG_ERROR([trying to build nhrpd, but libcares not found. install c-ares and its -dev headers.])
1452   ])
1453 fi
1454
1455
1456 dnl ------------------
1457 dnl check Net-SNMP library
1458 dnl ------------------
1459 if test "${enable_snmp}" != "" -a "${enable_snmp}" != "no"; then
1460    AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], [no])
1461    if test x"$NETSNMP_CONFIG" = x"no"; then
1462       AC_MSG_ERROR([--enable-snmp given but unable to find net-snmp-config])
1463    fi
1464    SNMP_LIBS="`${NETSNMP_CONFIG} --agent-libs`"
1465    SNMP_CFLAGS="`${NETSNMP_CONFIG} --base-cflags`"
1466    AC_MSG_CHECKING([whether we can link to Net-SNMP])
1467    AC_LINK_IFELSE_FLAGS([$SNMP_CFLAGS], [$SNMP_LIBS], [AC_LANG_PROGRAM([
1468 int main(void);
1469 ],
1470 [
1471 {
1472   return 0;
1473 }
1474 ])], [
1475      AC_MSG_ERROR([--enable-snmp given but not usable])])
1476    case "${enable_snmp}" in
1477      yes)
1478       SNMP_METHOD=agentx
1479       ;;
1480      agentx)
1481       SNMP_METHOD="${enable_snmp}"
1482       ;;
1483      *)
1484       AC_MSG_ERROR([--enable-snmp given with an unknown method (${enable_snmp}). Use yes or agentx])
1485       ;;
1486    esac
1487    AH_TEMPLATE([SNMP_AGENTX], [Use SNMP AgentX to interface with snmpd])
1488    AC_DEFINE_UNQUOTED(AS_TR_CPP(SNMP_${SNMP_METHOD}),,SNMP method to interface with snmpd)
1489 fi
1490 AM_CONDITIONAL([SNMP], [test "x${SNMP_METHOD}" != "x"])
1491 AC_SUBST(SNMP_LIBS)
1492 AC_SUBST(SNMP_CFLAGS)
1493
1494 dnl ---------------
1495 dnl math
1496 dnl ---------------
1497 AC_SEARCH_LIBS([sqrt], [m])
1498
1499 dnl ---------------
1500 dnl dlopen & dlinfo
1501 dnl ---------------
1502 AC_SEARCH_LIBS(dlopen, [dl dld], [], [
1503   AC_MSG_ERROR([unable to find the dlopen()])
1504 ])
1505
1506 AC_CHECK_HEADERS([link.h])
1507
1508 AC_CACHE_CHECK([for dlinfo(RTLD_DI_ORIGIN)], [frr_cv_rtld_di_origin], [
1509   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1510 #include <stdlib.h>
1511 #ifdef HAVE_LINK_H
1512 #include <link.h>
1513 #endif
1514 #include <dlfcn.h>
1515 ]], [[
1516   char origin[1];
1517   dlinfo (NULL, RTLD_DI_ORIGIN, &origin);
1518 ]])], [
1519     frr_cv_rtld_di_origin=yes
1520   ], [
1521     frr_cv_rtld_di_origin=no
1522   ])
1523 ])
1524 if test "$frr_cv_rtld_di_origin" = yes; then
1525   AC_DEFINE(HAVE_DLINFO_ORIGIN, 1, [Have dlinfo RTLD_DI_ORIGIN])
1526 fi
1527
1528 AC_CACHE_CHECK([for dlinfo(RTLD_DI_LINKMAP)], [frr_cv_rtld_di_linkmap], [
1529   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1530 #include <stdlib.h>
1531 #ifdef HAVE_LINK_H
1532 #include <link.h>
1533 #endif
1534 #include <dlfcn.h>
1535 ]], [[
1536   struct link_map *lm = NULL;
1537   dlinfo (NULL, RTLD_DI_LINKMAP, &lm);
1538 ]])], [
1539     frr_cv_rtld_di_linkmap=yes
1540   ], [
1541     frr_cv_rtld_di_linkmap=no
1542   ])
1543 ])
1544 if test "$frr_cv_rtld_di_linkmap" = yes; then
1545   AC_DEFINE(HAVE_DLINFO_LINKMAP, 1, [Have dlinfo RTLD_DI_LINKMAP])
1546 fi
1547
1548 AM_CONDITIONAL(SNMP, test "x$SNMP_METHOD" = "xagentx")
1549
1550 dnl ---------------------------
1551 dnl sockaddr and netinet checks
1552 dnl ---------------------------
1553 AC_CHECK_TYPES([
1554         struct sockaddr_dl,
1555         struct vifctl, struct mfcctl, struct sioc_sg_req,
1556         vifi_t, struct sioc_vif_req, struct igmpmsg,
1557         struct ifaliasreq, struct if6_aliasreq, struct in6_aliasreq,
1558         struct nd_opt_adv_interval, struct rt_addrinfo,
1559         struct nd_opt_homeagent_info, struct nd_opt_adv_interval],
1560         [], [], FRR_INCLUDES)
1561
1562 AC_CHECK_MEMBERS([struct sockaddr.sa_len,
1563         struct sockaddr_in.sin_len, struct sockaddr_un.sun_len,
1564         struct sockaddr_dl.sdl_len,
1565         struct if6_aliasreq.ifra_lifetime,
1566         struct nd_opt_adv_interval.nd_opt_ai_type],
1567         [], [], FRR_INCLUDES)
1568
1569 dnl ---------------------------
1570 dnl IRDP/pktinfo/icmphdr checks
1571 dnl ---------------------------
1572
1573 AC_CHECK_TYPES([struct in_pktinfo], [
1574   AC_CHECK_TYPES([struct icmphdr], [
1575     IRDP=true
1576   ], [
1577     IRDP=false
1578   ], [FRR_INCLUDES])
1579 ], [
1580   IRDP=false
1581 ], [FRR_INCLUDES])
1582
1583 case "${enable_irdp}" in
1584 yes)
1585   $IRDP || AC_MSG_ERROR(['IRDP requires in_pktinfo at the moment!'])
1586   ;;
1587 no)
1588   IRDP=false
1589   ;;
1590 esac
1591
1592 AM_CONDITIONAL(IRDP, $IRDP)
1593
1594 dnl -----------------------
1595 dnl checking for IP_PKTINFO
1596 dnl -----------------------
1597 AC_MSG_CHECKING(for IP_PKTINFO)
1598 AC_TRY_COMPILE([#include <netdb.h>], [
1599   int opt = IP_PKTINFO;
1600 ], [
1601   AC_MSG_RESULT(yes)
1602   AC_DEFINE(HAVE_IP_PKTINFO, 1, [Have IP_PKTINFO])
1603 ], [
1604   AC_MSG_RESULT(no)
1605 ])
1606
1607 dnl ---------------------------
1608 dnl checking for IP_RECVDSTADDR
1609 dnl ---------------------------
1610 AC_MSG_CHECKING(for IP_RECVDSTADDR)
1611 AC_TRY_COMPILE([#include <netinet/in.h>], [
1612   int opt = IP_RECVDSTADDR;
1613 ], [
1614   AC_MSG_RESULT(yes)
1615   AC_DEFINE(HAVE_IP_RECVDSTADDR, 1, [Have IP_RECVDSTADDR])
1616 ], [
1617   AC_MSG_RESULT(no)
1618 ])
1619
1620 dnl ----------------------
1621 dnl checking for IP_RECVIF
1622 dnl ----------------------
1623 AC_MSG_CHECKING(for IP_RECVIF)
1624 AC_TRY_COMPILE([#include <netinet/in.h>], [
1625   int opt = IP_RECVIF;
1626 ], [
1627   AC_MSG_RESULT(yes)
1628   AC_DEFINE(HAVE_IP_RECVIF, 1, [Have IP_RECVIF])
1629 ], [
1630   AC_MSG_RESULT(no)
1631 ])
1632
1633 dnl ----------------------
1634 dnl checking for SO_BINDANY
1635 dnl ----------------------
1636 AC_MSG_CHECKING(for SO_BINDANY)
1637 AC_TRY_COMPILE([#include <sys/socket.h>], [
1638   int opt = SO_BINDANY;
1639 ], [
1640   AC_MSG_RESULT(yes)
1641   AC_DEFINE(HAVE_SO_BINDANY, 1, [Have SO_BINDANY])
1642 ], [
1643   AC_MSG_RESULT(no)
1644 ])
1645
1646 dnl ----------------------
1647 dnl checking for IP_FREEBIND
1648 dnl ----------------------
1649 AC_MSG_CHECKING(for IP_FREEBIND)
1650 AC_TRY_COMPILE([#include <netinet/in.h>], [
1651   int opt = IP_FREEBIND;
1652 ], [
1653   AC_MSG_RESULT(yes)
1654   AC_DEFINE(HAVE_IP_FREEBIND, 1, [Have IP_FREEBIND])
1655 ], [
1656   AC_MSG_RESULT(no)
1657 ])
1658
1659 dnl --------------------------------------
1660 dnl checking for be32dec existence or not
1661 dnl --------------------------------------
1662 AC_CHECK_DECLS([be32enc, be32dec], [], [],
1663                [#include <sys/endian.h>])
1664
1665 dnl --------------------------------------
1666 dnl checking for clock_time monotonic struct and call
1667 dnl --------------------------------------
1668 AC_CHECK_DECL(CLOCK_MONOTONIC,
1669         [AC_CHECK_LIB(rt, clock_gettime, [LIBS="$LIBS -lrt"])
1670          AC_DEFINE(HAVE_CLOCK_MONOTONIC,, Have monotonic clock)
1671 ], [AC_MSG_RESULT(no)], [FRR_INCLUDES])
1672
1673 dnl --------------------------------------
1674 dnl checking for flex and bison
1675 dnl --------------------------------------
1676
1677 AM_PROG_LEX
1678 AC_MSG_CHECKING(version of flex)
1679 frr_ac_flex_version="$(eval $LEX -V | grep flex | head -n 1)"
1680 frr_ac_flex_version="${frr_ac_flex_version##* }"
1681 AC_MSG_RESULT([$frr_ac_flex_version])
1682 AX_COMPARE_VERSION([$frr_ac_flex_version], [lt], [2.5.20], [
1683   LEX="$SHELL $missing_dir/missing flex"
1684   if test -f "${srcdir}/lib/command_lex.c" -a -f "${srcdir}/lib/command_lex.h"; then
1685     AC_MSG_WARN([using pregenerated flex output files])
1686   else
1687     AC_MSG_ERROR([flex failure and pregenerated files not included (probably a git build)])
1688   fi
1689   AC_SUBST([LEX_OUTPUT_ROOT], [lex.yy])
1690   AC_SUBST([LEXLIB], [''])
1691 ])
1692
1693 AC_PROG_YACC
1694 dnl thanks GNU bison for this b*llshit...
1695 AC_MSG_CHECKING(version of bison)
1696 frr_ac_bison_version="$(eval $YACC -V | grep bison | head -n 1)"
1697 frr_ac_bison_version="${frr_ac_bison_version##* }"
1698 frr_ac_bison_missing="false"
1699 case "x${frr_ac_bison_version}" in
1700   x2.7*)
1701     BISON_OPENBRACE='"'
1702     BISON_CLOSEBRACE='"'
1703     BISON_VERBOSE=''
1704     AC_MSG_RESULT([$frr_ac_bison_version - 2.7 or older])
1705     ;;
1706   x2.*|x1.*)
1707     AC_MSG_RESULT([$frr_ac_bison_version])
1708     AC_MSG_WARN([installed bison is too old.  Please install GNU bison 2.7.x or newer.])
1709     frr_ac_bison_missing="true"
1710     ;;
1711   x)
1712     AC_MSG_RESULT([none])
1713     AC_MSG_WARN([could not determine bison version.  Please install GNU bison 2.7.x or newer.])
1714     frr_ac_bison_missing="true"
1715     ;;
1716   *)
1717     BISON_OPENBRACE='{'
1718     BISON_CLOSEBRACE='}'
1719     BISON_VERBOSE='-Dparse.error=verbose'
1720     AC_MSG_RESULT([$frr_ac_bison_version - 3.0 or newer])
1721     ;;
1722 esac
1723 AC_SUBST(BISON_OPENBRACE)
1724 AC_SUBST(BISON_CLOSEBRACE)
1725 AC_SUBST(BISON_VERBOSE)
1726
1727 if $frr_ac_bison_missing; then
1728   YACC="$SHELL $missing_dir/missing bison -y"
1729   if test -f "${srcdir}/lib/command_parse.c" -a -f "${srcdir}/lib/command_parse.h"; then
1730     AC_MSG_WARN([using pregenerated bison output files])
1731   else
1732     AC_MSG_ERROR([bison failure and pregenerated files not included (probably a git build)])
1733   fi
1734 fi
1735
1736 dnl -------------------
1737 dnl capabilities checks
1738 dnl -------------------
1739 if test "${enable_capabilities}" != "no"; then
1740   AC_MSG_CHECKING(whether prctl PR_SET_KEEPCAPS is available)
1741   AC_TRY_COMPILE([#include <sys/prctl.h>],[prctl(PR_SET_KEEPCAPS, 1, 0, 0, 0);],
1742     [AC_MSG_RESULT(yes)
1743      AC_DEFINE(HAVE_PR_SET_KEEPCAPS,,prctl)
1744      frr_ac_keepcaps="yes"],
1745      AC_MSG_RESULT(no)
1746   )
1747   if test x"${frr_ac_keepcaps}" = x"yes"; then
1748     AC_CHECK_HEADERS(sys/capability.h)
1749   fi
1750   if test x"${ac_cv_header_sys_capability_h}" = x"yes"; then
1751     AC_CHECK_LIB(cap, cap_init,
1752       [AC_DEFINE(HAVE_LCAPS,1,Capabilities)
1753        LIBCAP="-lcap"
1754        frr_ac_lcaps="yes"]
1755     )
1756   else
1757     AC_CHECK_HEADERS(priv.h,
1758      [AC_MSG_CHECKING(Solaris style privileges are available)
1759       AC_TRY_COMPILE([#include <priv.h>],[getpflags(PRIV_AWARE);],
1760           [AC_MSG_RESULT(yes)
1761            AC_DEFINE(HAVE_SOLARIS_CAPABILITIES,1,getpflags)
1762            frr_ac_scaps="yes"],
1763            AC_MSG_RESULT(no)
1764       )
1765      ]
1766    )
1767   fi
1768   if test x"${frr_ac_scaps}" = x"yes" \
1769        -o x"${frr_ac_lcaps}" = x"yes"; then
1770     AC_DEFINE(HAVE_CAPABILITIES,1,capabilities)
1771   fi
1772 fi
1773 AC_SUBST(LIBCAP)
1774
1775 dnl ---------------------------
1776 dnl check for glibc 'backtrace'
1777 dnl ---------------------------
1778 if test x"${enable_backtrace}" != x"no" ; then
1779   backtrace_ok=no
1780   AC_CHECK_HEADER([execinfo.h], [
1781     AC_SEARCH_LIBS([backtrace], [execinfo], [
1782       AC_DEFINE(HAVE_GLIBC_BACKTRACE,,[Glibc backtrace])
1783       AC_DEFINE(HAVE_STACK_TRACE,,[Stack symbol decoding])
1784       backtrace_ok=yes
1785     ],, [-lm])
1786   ])
1787
1788   if test x"${enable_backtrace}" = x"yes" -a x"${backtrace_ok}" = x"no"; then
1789     dnl user explicitly requested backtrace but we failed to find support
1790     AC_MSG_FAILURE([failed to find backtrace support])
1791   fi
1792 fi
1793
1794 dnl -----------------------------------------
1795 dnl check for malloc mallinfo struct and call
1796 dnl this must try and link using LIBS, in
1797 dnl order to check no alternative allocator
1798 dnl has been specified, which might not provide
1799 dnl mallinfo, e.g. such as Umem on Solaris.
1800 dnl -----------------------------------------
1801 AC_CHECK_HEADERS([malloc.h malloc/malloc.h],,, [FRR_INCLUDES])
1802
1803 AC_CACHE_CHECK([whether mallinfo is available], [frr_cv_mallinfo], [
1804   AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
1805 #ifdef HAVE_MALLOC_H
1806 #include <malloc.h>
1807 #endif
1808 #ifdef HAVE_MALLOC_MALLOC_H
1809 #include <malloc/malloc.h>
1810 #endif
1811 ]], [[
1812 struct mallinfo ac_x; ac_x = mallinfo ();
1813 ]])], [
1814     frr_cv_mallinfo=yes
1815   ], [
1816     frr_cv_mallinfo=no
1817   ])
1818 ])
1819 if test "$frr_cv_mallinfo" = yes; then
1820   AC_DEFINE(HAVE_MALLINFO,,mallinfo)
1821 fi
1822
1823 AC_MSG_CHECKING(whether malloc_usable_size is available)
1824 AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
1825 #ifdef HAVE_MALLOC_H
1826 #include <malloc.h>
1827 #endif
1828 #ifdef HAVE_MALLOC_MALLOC_H
1829 #include <malloc/malloc.h>
1830 #endif
1831 ]], [[
1832 size_t ac_x; ac_x = malloc_usable_size(NULL);
1833 ]])], [
1834   AC_MSG_RESULT(yes)
1835   AC_DEFINE(HAVE_MALLOC_USABLE_SIZE,,malloc_usable_size)
1836 ], [
1837   AC_MSG_RESULT(no)
1838
1839   AC_MSG_CHECKING(whether malloc_size is available)
1840   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1841 #ifdef HAVE_MALLOC_H
1842 #include <malloc.h>
1843 #endif
1844 #ifdef HAVE_MALLOC_MALLOC_H
1845 #include <malloc/malloc.h>
1846 #endif
1847 ]], [[
1848 size_t ac_x; ac_x = malloc_size(NULL);
1849 ]])], [
1850     AC_MSG_RESULT(yes)
1851     AC_DEFINE(HAVE_MALLOC_SIZE,,malloc_size)
1852   ], [
1853     AC_MSG_RESULT(no)
1854   ])
1855 ])
1856
1857 dnl ------
1858 dnl ZeroMQ
1859 dnl ------
1860 if test "x$enable_zeromq" != "xno"; then
1861   PKG_CHECK_MODULES(ZEROMQ, [libzmq >= 4.0.0], [
1862     AC_DEFINE(HAVE_ZEROMQ, 1, [Enable ZeroMQ support])
1863     ZEROMQ=true
1864   ], [
1865     if test "x$enable_zeromq" = "xyes"; then
1866       AC_MSG_ERROR([configuration specifies --enable-zeromq but libzmq was not found])
1867     fi
1868   ])
1869 fi
1870 AM_CONDITIONAL([ZEROMQ], test "x$ZEROMQ" = "xtrue")
1871
1872 dnl ----------
1873 dnl configure date
1874 dnl ----------
1875 dev_version=`echo $VERSION | grep dev`
1876 #don't expire deprecated code in non 'dev' branch
1877 if test "${dev_version}" = ""; then
1878    CONFDATE=0
1879 else
1880    CONFDATE=`date '+%Y%m%d'`
1881 fi
1882 AC_SUBST(CONFDATE)
1883
1884 dnl ------------------------------
1885 dnl set paths for state directory
1886 dnl ------------------------------
1887 AC_MSG_CHECKING(directory to use for state file)
1888 if test "${prefix}" = "NONE"; then
1889   frr_statedir_prefix="";
1890 else
1891   frr_statedir_prefix=${prefix}
1892 fi
1893 if test "${localstatedir}" = '${prefix}/var'; then
1894   for FRR_STATE_DIR in ${frr_statedir_prefix}/var/run dnl
1895                         ${frr_statedir_prefix}/var/adm dnl
1896                         ${frr_statedir_prefix}/etc dnl
1897                         /var/run        dnl
1898                         /var/adm        dnl
1899                         /etc            dnl
1900                         /dev/null;
1901   do
1902     test -d $FRR_STATE_DIR && break
1903   done
1904   frr_statedir=$FRR_STATE_DIR
1905 else
1906   frr_statedir=${localstatedir}
1907 fi
1908 if test $frr_statedir = "/dev/null"; then
1909     AC_MSG_ERROR('STATE DIRECTORY NOT FOUND! FIX OR SPECIFY --localstatedir!')
1910 fi
1911 AC_MSG_RESULT(${frr_statedir})
1912 AC_SUBST(frr_statedir)
1913
1914 AC_DEFINE_UNQUOTED(LDPD_SOCKET, "$frr_statedir/ldpd.sock",ldpd control socket)
1915 AC_DEFINE_UNQUOTED(ZEBRA_SERV_PATH, "$frr_statedir/zserv.api",zebra api socket)
1916 AC_DEFINE_UNQUOTED(BFDD_CONTROL_SOCKET, "$frr_statedir/bfdd.sock", bfdd control socket)
1917 AC_DEFINE_UNQUOTED(DAEMON_VTY_DIR, "$frr_statedir",daemon vty directory)
1918
1919 dnl autoconf does this, but it does it too late...
1920 test "x$prefix" = xNONE && prefix=$ac_default_prefix
1921 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
1922
1923 dnl get the full path, recursing through variables...
1924 vtysh_bin="$bindir/vtysh"
1925 for I in 1 2 3 4 5 6 7 8 9 10; do
1926         eval vtysh_bin="\"$vtysh_bin\""
1927 done
1928 AC_DEFINE_UNQUOTED(VTYSH_BIN_PATH, "$vtysh_bin",path to vtysh binary)
1929
1930 CFG_SYSCONF="$sysconfdir"
1931 CFG_SBIN="$sbindir"
1932 CFG_STATE="$frr_statedir"
1933 CFG_MODULE="$moduledir"
1934 for I in 1 2 3 4 5 6 7 8 9 10; do
1935         eval CFG_SYSCONF="\"$CFG_SYSCONF\""
1936         eval CFG_SBIN="\"$CFG_SBIN\""
1937         eval CFG_STATE="\"$CFG_STATE\""
1938         eval CFG_MODULE="\"$CFG_MODULE\""
1939 done
1940 AC_SUBST(CFG_SYSCONF)
1941 AC_SUBST(CFG_SBIN)
1942 AC_SUBST(CFG_STATE)
1943 AC_SUBST(CFG_MODULE)
1944 AC_DEFINE_UNQUOTED(MODULE_PATH, "$CFG_MODULE", path to modules)
1945
1946 dnl ------------------------------------
1947 dnl Enable RPKI and add librtr to libs
1948 dnl ------------------------------------
1949 if test "${enable_rpki}" = "yes"; then
1950   PKG_CHECK_MODULES(RTRLIB,[rtrlib >= 0.5.0],
1951       [RPKI=true],
1952       [RPKI=false
1953       AC_MSG_ERROR([rtrlib was not found on your system or is too old.])]
1954   )
1955 fi
1956 AM_CONDITIONAL([RPKI], test "x$RPKI" = "xtrue")
1957
1958 dnl ------------------------------------------
1959 dnl Check whether rtrlib was build with ssh support
1960 dnl ------------------------------------------
1961 AC_MSG_CHECKING([whether the RTR Library is compiled with SSH])
1962 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "rtrlib/rtrlib.h"]],
1963                         [[struct tr_ssh_config config;]])],
1964         [AC_MSG_RESULT(yes)
1965         AC_DEFINE(FOUND_SSH,,found_ssh)],
1966         AC_MSG_RESULT(no)
1967 )
1968
1969 dnl ---------------------------
1970 dnl Check htonl works correctly
1971 dnl ---------------------------
1972 AC_MSG_CHECKING(for working htonl)
1973 AC_CACHE_VAL(ac_cv_htonl_works,
1974  [AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES],[htonl (0);])],
1975                 [ac_cv_htonl_works=yes], [ac_cv_htonl_works=no])
1976  ]
1977 )
1978 AC_MSG_RESULT($ac_cv_htonl_works)
1979
1980 AC_CONFIG_FILES([Makefile],[sed -e 's/^#AUTODERP# //' -i Makefile])
1981
1982 AC_CONFIG_FILES([
1983           redhat/frr.spec
1984           solaris/Makefile
1985           debianpkg/changelog
1986           alpine/APKBUILD
1987           snapcraft/snapcraft.yaml
1988           lib/version.h
1989           tests/lib/cli/test_cli.refout
1990           pkgsrc/bgpd.sh pkgsrc/ospf6d.sh pkgsrc/ospfd.sh
1991           pkgsrc/ripd.sh pkgsrc/ripngd.sh pkgsrc/zebra.sh
1992           pkgsrc/eigrpd.sh])
1993
1994 AC_CONFIG_FILES([vtysh/extract.pl],[chmod +x vtysh/extract.pl])
1995
1996 AC_CONFIG_COMMANDS([lib/route_types.h], [
1997         dst="${ac_abs_top_builddir}/lib/route_types.h"
1998         ${PERL} "${ac_abs_top_srcdir}/lib/route_types.pl" \
1999                 < "${ac_abs_top_srcdir}/lib/route_types.txt" \
2000                 > "${dst}.tmp"
2001         test -f "${dst}" \
2002                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
2003                 && rm "${dst}.tmp" \
2004                 || mv "${dst}.tmp" "${dst}"
2005 ], [
2006         PERL="$PERL"
2007 ])
2008
2009 AS_IF([test "x$with_pkg_git_version" = "xyes"], [
2010     AC_CONFIG_COMMANDS([lib/gitversion.h], [
2011         dst="${ac_abs_top_builddir}/lib/gitversion.h"
2012         ${PERL} "${ac_abs_top_srcdir}/lib/gitversion.pl" \
2013                 "${ac_abs_top_srcdir}" \
2014                 > "${dst}.tmp"
2015         test -f "${dst}" \
2016                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
2017                 && rm "${dst}.tmp" \
2018                 || mv "${dst}.tmp" "${dst}"
2019     ], [
2020         PERL="$PERL"
2021     ])
2022 ])
2023
2024 ## Hack, but working solution to avoid rebuilding of frr.info.
2025 ## It's already in CVS until texinfo 4.7 is more common.
2026 AC_OUTPUT
2027
2028 echo "
2029 FRRouting configuration
2030 ------------------------------
2031 FRR version             : ${PACKAGE_VERSION}
2032 host operating system   : ${host_os}
2033 source code location    : ${srcdir}
2034 compiler                : ${CC}
2035 compiler flags          : ${CFLAGS}
2036 make                    : ${MAKE-make}
2037 linker flags            : ${LDFLAGS} ${LIBS} ${LIBCAP} ${LIBREADLINE} ${LIBM}
2038 state file directory    : ${frr_statedir}
2039 config file directory   : `eval echo \`echo ${sysconfdir}\``
2040 example directory       : `eval echo \`echo ${exampledir}\``
2041 module directory        : ${CFG_MODULE}
2042 user to run as          : ${enable_user}
2043 group to run as         : ${enable_group}
2044 group for vty sockets   : ${enable_vty_group}
2045 config file mask        : ${enable_configfile_mask}
2046 log file mask           : ${enable_logfile_mask}
2047 zebra protobuf enabled  : ${enable_protobuf:-no}
2048
2049 The above user and group must have read/write access to the state file
2050 directory and to the config files in the config file directory."
2051
2052 if test "${enable_doc}" != "no";then
2053   AS_IF([test "x$SPHINXBUILD" = xno],
2054      AC_MSG_WARN(sphinx-build is missing but required to build documentation))
2055 fi