configure.ac

   1 ##
   2 ## Configure template file for FRRouting.
   3 ## autoconf will generate configure script.
   4 ##
   5 ##  Copyright (c) 1996, 97, 98, 99, 2000 Kunihiro Ishiguro <kunihiro@zebra.org>
   6 ##  Portions Copyright (c) 2003 Paul Jakma <paul@dishone.st>
   7 ##
   8 AC_PREREQ(2.60)
   9
  10 AC_INIT(frr, 6.1-dev, [https://github.com/frrouting/frr/issues])
  11 PACKAGE_URL="https://frrouting.org/"
  12 AC_SUBST(PACKAGE_URL)
  13 PACKAGE_FULLNAME="FRRouting"
  14 AC_SUBST(PACKAGE_FULLNAME)
  15
  16 CONFIG_ARGS="$ac_configure_args"
  17 AC_SUBST(CONFIG_ARGS)
  18
  19 AC_CONFIG_SRCDIR(lib/zebra.h)
  20 AC_CONFIG_MACRO_DIR([m4])
  21
  22 dnl -----------------------------------
  23 dnl Get hostname and other information.
  24 dnl -----------------------------------
  25 AC_CANONICAL_BUILD()
  26 AC_CANONICAL_HOST()
  27
  28 AS_IF([test "$host" != "$build"], [
  29   if test "$srcdir" = "."; then
  30     AC_MSG_ERROR([cross-compilation is only possible with builddir separate from srcdir.  create a separate directory and run as .../path-to-frr/configure.])
  31   fi
  32   test -d hosttools || mkdir hosttools
  33   abssrc="`cd \"${srcdir}\"; pwd`"
  34
  35   AC_MSG_NOTICE([...])
  36   AC_MSG_NOTICE([... cross-compilation: creating hosttools directory and self-configuring for build platform tools])
  37   AC_MSG_NOTICE([... use HOST_CPPFLAGS / HOST_CFLAGS / HOST_LDFLAGS if neccessary])
  38   AC_MSG_NOTICE([...])
  39
  40   ( CPPFLAGS="$HOST_CPPFLAGS"; \
  41     CFLAGS="$HOST_CFLAGS"; \
  42     LDFLAGS="$HOST_LDFLAGS"; \
  43     cd hosttools; "${abssrc}/configure" "--host=$build" "--build=$build" "--enable-clippy-only" "--disable-nhrpd" "--disable-vtysh"; )
  44
  45   AC_MSG_NOTICE([...])
  46   AC_MSG_NOTICE([... cross-compilation: finished self-configuring for build platform tools])
  47   AC_MSG_NOTICE([...])
  48
  49   build_clippy="false"
  50   HOSTTOOLS="hosttools/"
  51 ], [
  52   build_clippy="true"
  53   HOSTTOOLS=""
  54 ])
  55 AC_SUBST(HOSTTOOLS)
  56 AM_CONDITIONAL([BUILD_CLIPPY], [$build_clippy])
  57
  58 # Disable portability warnings -- our automake code (in particular
  59 # common.am) uses some constructs specific to gmake.
  60 AM_INIT_AUTOMAKE([1.12 -Wno-portability foreign])
  61 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
  62 AM_SILENT_RULES([yes])
  63 AC_CONFIG_HEADERS(config.h)
  64
  65 AC_PATH_PROG(PERL, perl)
  66 PKG_PROG_PKG_CONFIG
  67
  68 dnl default is to match previous behavior
  69 exampledir=${sysconfdir}
  70 AC_ARG_ENABLE([exampledir],
  71           AS_HELP_STRING([--enable-exampledir],
  72                          [specify alternate directory for examples]),
  73                          exampledir="$enableval",)
  74 dnl XXX add --exampledir to autoconf standard directory list somehow
  75 AC_SUBST(exampledir)
  76
  77 dnl default is to match previous behavior
  78 pkgsrcrcdir=""
  79 AC_ARG_ENABLE([pkgsrcrcdir],
  80           AS_HELP_STRING([--enable-pkgsrcrcdir],
  81                          [specify directory for rc.d scripts]),
  82                          pkgsrcrcdir="$enableval",)
  83 dnl XXX add --pkgsrcrcdir to autoconf standard directory list somehow
  84 AC_SUBST(pkgsrcrcdir)
  85 AM_CONDITIONAL([PKGSRC], [test "x$pkgsrcrcdir" != "x"])
  86
  87 AC_ARG_WITH([moduledir], [AS_HELP_STRING([--with-moduledir=DIR], [module directory (${libdir}/frr/modules)])], [
  88         moduledir="$withval"
  89 ], [
  90         moduledir="\${libdir}/frr/modules"
  91 ])
  92 AC_SUBST([moduledir], [$moduledir])
  93
  94 AC_ARG_ENABLE(tcmalloc,
  95         AS_HELP_STRING([--enable-tcmalloc], [Turn on tcmalloc]),
  96 [case "${enableval}" in
  97   yes) tcmalloc_enabled=true
  98 LIBS="$LIBS -ltcmalloc_minimal"
  99  ;;
 100   no)  tcmalloc_enabled=false ;;
 101   *) AC_MSG_ERROR(bad value ${enableval} for --enable-tcmalloc) ;;
 102 esac],[tcmalloc_enabled=false])
 103
 104
 105 dnl Thanks autoconf, but we don't want a default -g -O2.  We have our own
 106 dnl flag determination logic.
 107 CFLAGS="${CFLAGS:-}"
 108
 109 dnl --------------------
 110 dnl Check CC and friends
 111 dnl --------------------
 112 dnl note orig_cflags is also used further down
 113 orig_cflags="$CFLAGS"
 114 AC_LANG([C])
 115 AC_PROG_CC
 116 AC_PROG_CPP
 117 AM_PROG_CC_C_O
 118 dnl remove autoconf default "-g -O2"
 119 CFLAGS="$orig_cflags"
 120 AC_PROG_CC_C99
 121 dnl NB: see C11 below
 122
 123 AC_PROG_EGREP
 124 PKG_PROG_PKG_CONFIG
 125
 126 dnl autoconf 2.59 appears not to support AC_PROG_SED
 127 dnl AC_PROG_SED
 128 AC_CHECK_PROG([SED],[sed],[sed],[/bin/false])
 129
 130 dnl try and enable CFLAGS that are useful for FRR
 131 dnl - specifically, options to control warnings
 132
 133 AC_USE_SYSTEM_EXTENSIONS
 134 AC_DEFUN([AC_C_FLAG], [{
 135     m4_pushdef([cachename],[m4_translit([frr_cv_$1],[ =-],[___])])
 136     AC_CACHE_CHECK([[whether $CC supports $1]], cachename, [
 137         AC_LANG_PUSH(C)
 138         ac_c_flag_save="$CFLAGS"
 139         CFLAGS="$CFLAGS $1"
 140         AC_COMPILE_IFELSE(
 141                 [AC_LANG_PROGRAM([[]])],
 142                 [
 143                         cachename=yes
 144                 ], [
 145                         cachename=no
 146                 ])
 147         CFLAGS="$ac_c_flag_save"
 148         AC_LANG_POP(C)
 149     ])
 150     if test "${cachename}" = yes; then
 151         m4_if([$3], [], [CFLAGS="$CFLAGS $1"], [$3])
 152     else
 153         :
 154         $2
 155     fi
 156     m4_popdef([cachename])
 157 }])
 158
 159 AC_DEFUN([AC_LINK_IFELSE_FLAGS], [{
 160         AC_LANG_PUSH(C)
 161         ac_cflags_save="$CFLAGS"
 162         ac_libs_save="$LIBS"
 163         CFLAGS="$CFLAGS $1"
 164         LIBS="$LIBS $2"
 165         AC_LINK_IFELSE(
 166                 [$3],
 167                 [
 168                         AC_MSG_RESULT([yes])
 169                         CFLAGS="$ac_cflags_save"
 170                         LIBS="$ac_libs_save"
 171                         $5
 172                 ], [
 173                         AC_MSG_RESULT([no])
 174                         CFLAGS="$ac_cflags_save"
 175                         LIBS="$ac_libs_save"
 176                         $4
 177                 ])
 178         AC_LANG_POP(C)
 179         }])
 180
 181 dnl ICC won't bail on unknown options without -diag-error 10006
 182 dnl need to do this first so we get useful results for the other options
 183 AC_C_FLAG([-diag-error 10006])
 184
 185 dnl AC_PROG_CC_C99 may change CC to include -std=gnu99 or something
 186 ac_cc="$CC"
 187 CC="${CC% -std=gnu99}"
 188 CC="${CC% -std=c99}"
 189
 190 AC_C_FLAG([-std=gnu11], [CC="$ac_cc"], [CC="$CC -std=gnu11"])
 191
 192 dnl if the user has specified any CFLAGS, override our settings
 193 if test "x${enable_gcov}" = "xyes"; then
 194    if test "z$orig_cflags" = "z"; then
 195       AC_C_FLAG([-coverage])
 196       AC_C_FLAG([-O0])
 197    fi
 198
 199    LDFLAGS="${LDFLAGS} -lgcov"
 200 elif test "x${enable_dev_build}" = "xyes"; then
 201    AC_DEFINE(DEV_BUILD,,Build for development)
 202    if test "z$orig_cflags" = "z"; then
 203       AC_C_FLAG([-g3])
 204       AC_C_FLAG([-O0])
 205    fi
 206 else
 207    if test "z$orig_cflags" = "z"; then
 208       AC_C_FLAG([-g])
 209       AC_C_FLAG([-Os], [
 210         AC_C_FLAG([-O2])
 211       ])
 212    fi
 213 fi
 214 AM_CONDITIONAL([DEV_BUILD], [test "x$enable_dev_build" = "xyes"])
 215
 216 dnl always want these CFLAGS
 217 AC_C_FLAG([-fno-omit-frame-pointer])
 218 AC_C_FLAG([-funwind-tables])
 219 AC_C_FLAG([-Wall])
 220 AC_C_FLAG([-Wextra])
 221 AC_C_FLAG([-Wmissing-prototypes])
 222 AC_C_FLAG([-Wmissing-declarations])
 223 AC_C_FLAG([-Wpointer-arith])
 224 AC_C_FLAG([-Wbad-function-cast])
 225 AC_C_FLAG([-Wwrite-strings])
 226 if test x"${enable_gcc_ultra_verbose}" = x"yes" ; then
 227   AC_C_FLAG([-Wcast-qual])
 228   AC_C_FLAG([-Wstrict-prototypes])
 229   AC_C_FLAG([-Wmissing-noreturn])
 230   AC_C_FLAG([-Wmissing-format-attribute])
 231   AC_C_FLAG([-Wunreachable-code])
 232   AC_C_FLAG([-Wpacked])
 233   AC_C_FLAG([-Wpadded])
 234   AC_C_FLAG([-Wshadow])
 235 else
 236   AC_C_FLAG([-Wno-unused-result])
 237 fi
 238 AC_C_FLAG([-Wno-unused-parameter])
 239 AC_C_FLAG([-Wno-missing-field-initializers])
 240
 241 dnl ICC emits a broken warning for const char *x = a ? "b" : "c";
 242 dnl for some reason the string consts get 'promoted' to char *,
 243 dnl triggering a const to non-const conversion warning.
 244 AC_C_FLAG([-diag-disable 3179])
 245
 246 if test x"${enable_werror}" = x"yes" ; then
 247   WERROR="-Werror"
 248 fi
 249 AC_SUBST(WERROR)
 250
 251 SAN_FLAGS=""
 252 if test "$enable_address_sanitizer" = "yes"; then
 253   AC_C_FLAG([-fsanitize=address], [
 254     AC_MSG_ERROR([$CC does not support Address Sanitizer.])
 255   ], [
 256     SAN_FLAGS="$SAN_FLAGS -fsanitize=address"
 257   ])
 258 fi
 259 if test "$enable_thread_sanitizer" = "yes"; then
 260   AC_C_FLAG([-fsanitize=thread], [
 261     AC_MSG_ERROR([$CC does not support Thread Sanitizer.])
 262   ], [
 263     SAN_FLAGS="$SAN_FLAGS -fsanitize=thread"
 264   ])
 265 fi
 266 if test "$enable_memory_sanitizer" = "yes"; then
 267   AC_C_FLAG([-fsanitize=thread -fPIE -pie], [
 268     AC_MSG_ERROR([$CC does not support Thread Sanitizer.])
 269   ], [
 270     SAN_FLAGS="-fsanitize=memory -fPIE -pie"
 271   ])
 272 fi
 273 AC_SUBST([SAN_FLAGS])
 274
 275 dnl ----------
 276 dnl Essentials
 277 dnl ----------
 278
 279 AX_PTHREAD([
 280   CC="$PTHREAD_CC"
 281   CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 282   LIBS="$PTHREAD_LIBS $LIBS"
 283 ], [
 284   AC_MSG_FAILURE([This FRR version needs pthreads])
 285 ])
 286
 287 AC_SEARCH_LIBS([pthread_condattr_setclock], [],
 288                 [frr_cv_pthread_condattr_setclock=yes],
 289                 [frr_cv_pthread_condattr_setclock=no])
 290 if test "$frr_cv_pthread_condattr_setclock" = yes; then
 291   AC_DEFINE(HAVE_PTHREAD_CONDATTR_SETCLOCK, 1, [Have pthread.h pthread_condattr_setclock])
 292 fi
 293
 294 dnl --------------
 295 dnl Check programs
 296 dnl --------------
 297 AC_PROG_INSTALL
 298 AC_PROG_LN_S
 299 AC_PROG_MAKE_SET
 300 AC_CHECK_TOOL(AR, ar)
 301
 302 dnl -------
 303 dnl libtool
 304 dnl -------
 305 LT_INIT
 306
 307 dnl ----------------------
 308 dnl Packages configuration
 309 dnl ----------------------
 310 AC_ARG_WITH(pkg-extra-version,
 311         AS_HELP_STRING([--with-pkg-extra-version=VER], [add extra version field, for packagers/distributions]),
 312         [EXTRAVERSION=$withval],)
 313 AC_ARG_WITH(pkg-git-version,
 314         AS_HELP_STRING([--with-pkg-git-version], [add git information to MOTD and build version string]),
 315         [ test "x$withval" != "xno" && with_pkg_git_version="yes" ])
 316 AC_ARG_WITH(vtysh_pager,
 317         AS_HELP_STRING([--with-vtysh-pager=PAGER], [control what pager is compiled in as default]),
 318         VTYSH_PAGER=$withval, VTYSH_PAGER="more")
 319 AC_ARG_ENABLE(vtysh,
 320   AS_HELP_STRING([--disable-vtysh], [do not build integrated vty shell for FRR]))
 321 AC_ARG_ENABLE(doc,
 322   AS_HELP_STRING([--disable-doc], [do not build docs]))
 323 AC_ARG_ENABLE(doc-html,
 324   AS_HELP_STRING([--enable-doc-html], [build HTML docs]))
 325 AC_ARG_ENABLE(zebra,
 326   AS_HELP_STRING([--disable-zebra], [do not build zebra daemon]))
 327 AC_ARG_ENABLE(bgpd,
 328   AS_HELP_STRING([--disable-bgpd], [do not build bgpd]))
 329 AC_ARG_ENABLE(ripd,
 330   AS_HELP_STRING([--disable-ripd], [do not build ripd]))
 331 AC_ARG_ENABLE(ripngd,
 332   AS_HELP_STRING([--disable-ripngd], [do not build ripngd]))
 333 AC_ARG_ENABLE(ospfd,
 334   AS_HELP_STRING([--disable-ospfd], [do not build ospfd]))
 335 AC_ARG_ENABLE(ospf6d,
 336   AS_HELP_STRING([--disable-ospf6d], [do not build ospf6d]))
 337 AC_ARG_ENABLE(ldpd,
 338   AS_HELP_STRING([--disable-ldpd], [do not build ldpd]))
 339 AC_ARG_ENABLE(nhrpd,
 340   AS_HELP_STRING([--disable-nhrpd], [do not build nhrpd]))
 341 AC_ARG_ENABLE(eigrpd,
 342   AS_HELP_STRING([--disable-eigrpd], [do not build eigrpd]))
 343 AC_ARG_ENABLE(babeld,
 344   AS_HELP_STRING([--disable-babeld], [do not build babeld]))
 345 AC_ARG_ENABLE(watchfrr,
 346   AS_HELP_STRING([--disable-watchfrr], [do not build watchfrr]))
 347 AC_ARG_ENABLE(isisd,
 348   AS_HELP_STRING([--disable-isisd], [do not build isisd]))
 349 AC_ARG_ENABLE(pimd,
 350   AS_HELP_STRING([--disable-pimd], [do not build pimd]))
 351 AC_ARG_ENABLE(pbrd,
 352   AS_HELP_STRING([--disable-pbrd], [do not build pbrd]))
 353 AC_ARG_ENABLE(sharpd,
 354   AS_HELP_STRING([--enable-sharpd], [build sharpd]))
 355 AC_ARG_ENABLE(staticd,
 356   AS_HELP_STRING([--disable-staticd], [do not build staticd]))
 357 AC_ARG_ENABLE(fabricd,
 358   AS_HELP_STRING([--disable-fabricd], [do not build fabricd]))
 359 AC_ARG_ENABLE(bgp-announce,
 360   AS_HELP_STRING([--disable-bgp-announce,], [turn off BGP route announcement]))
 361 AC_ARG_ENABLE(bgp-vnc,
 362   AS_HELP_STRING([--disable-bgp-vnc],[turn off BGP VNC support]))
 363 AC_ARG_ENABLE(snmp,
 364   AS_HELP_STRING([--enable-snmp], [enable SNMP support for agentx]))
 365 AC_ARG_ENABLE(zeromq,
 366   AS_HELP_STRING([--enable-zeromq], [enable ZeroMQ handler (libfrrzmq)]))
 367 AC_ARG_WITH(libpam,
 368   AS_HELP_STRING([--with-libpam], [use libpam for PAM support in vtysh]))
 369 AC_ARG_ENABLE(ospfapi,
 370   AS_HELP_STRING([--disable-ospfapi], [do not build OSPFAPI to access the OSPF LSA Database]))
 371 AC_ARG_ENABLE(ospfclient,
 372   AS_HELP_STRING([--disable-ospfclient], [do not build OSPFAPI client for OSPFAPI,
 373                           (this is the default if --disable-ospfapi is set)]))
 374 AC_ARG_ENABLE(multipath,
 375   AS_HELP_STRING([--enable-multipath=ARG], [enable multipath function, ARG must be digit]))
 376 AC_ARG_ENABLE(user,
 377   AS_HELP_STRING([--enable-user=USER], [user to run FRR suite as (default frr)]))
 378 AC_ARG_ENABLE(group,
 379   AS_HELP_STRING([--enable-group=GROUP], [group to run FRR suite as (default frr)]))
 380 AC_ARG_ENABLE(vty_group,
 381   AS_HELP_STRING([--enable-vty-group=ARG], [set vty sockets to have specified group as owner]))
 382 AC_ARG_ENABLE(configfile_mask,
 383   AS_HELP_STRING([--enable-configfile-mask=ARG], [set mask for config files]))
 384 AC_ARG_ENABLE(logfile_mask,
 385   AS_HELP_STRING([--enable-logfile-mask=ARG], [set mask for log files]))
 386 AC_ARG_ENABLE(shell_access,
 387   AS_HELP_STRING([--enable-shell-access], [Allow users to access shell/telnet/ssh]))
 388 AC_ARG_ENABLE(realms,
 389   AS_HELP_STRING([--enable-realms], [enable REALMS support under Linux]))
 390 AC_ARG_ENABLE(rtadv,
 391   AS_HELP_STRING([--disable-rtadv], [disable IPV6 router advertisement feature]))
 392 AC_ARG_ENABLE(irdp,
 393   AS_HELP_STRING([--disable-irdp], [enable IRDP server support in zebra (default if supported)]))
 394 AC_ARG_ENABLE(capabilities,
 395   AS_HELP_STRING([--disable-capabilities], [disable using POSIX capabilities]))
 396 AC_ARG_ENABLE(rusage,
 397   AS_HELP_STRING([--disable-rusage], [disable using getrusage]))
 398 AC_ARG_ENABLE(gcc_ultra_verbose,
 399   AS_HELP_STRING([--enable-gcc-ultra-verbose], [enable ultra verbose GCC warnings]))
 400 AC_ARG_ENABLE(backtrace,
 401   AS_HELP_STRING([--disable-backtrace,], [disable crash backtraces (default autodetect)]))
 402 AC_ARG_ENABLE(time-check,
 403   AS_HELP_STRING([--disable-time-check], [disable slow thread warning messages]))
 404 AC_ARG_ENABLE(pcreposix,
 405   AS_HELP_STRING([--enable-pcreposix], [enable using PCRE Posix libs for regex functions]))
 406 AC_ARG_ENABLE(fpm,
 407   AS_HELP_STRING([--enable-fpm], [enable Forwarding Plane Manager support]))
 408 AC_ARG_ENABLE(systemd,
 409   AS_HELP_STRING([--enable-systemd], [enable Systemd support]))
 410 AC_ARG_ENABLE(werror,
 411   AS_HELP_STRING([--enable-werror], [enable -Werror (recommended for developers only)]))
 412 AC_ARG_ENABLE(cumulus,
 413   AS_HELP_STRING([--enable-cumulus], [enable Cumulus Switch Special Extensions]))
 414 AC_ARG_ENABLE(datacenter,
 415   AS_HELP_STRING([--enable-datacenter], [enable Compilation for Data Center Extensions]))
 416 AC_ARG_ENABLE(fuzzing,
 417   AS_HELP_STRING([--enable-fuzzing], [enable ability to fuzz various parts of FRR]))
 418 AC_ARG_ENABLE(netlink_fuzzing,
 419   AS_HELP_STRING([--enable-netlink-fuzzing], [enable ability to fuzz netlink listening socket in zebra]))
 420 AC_ARG_ENABLE(rr-semantics,
 421   AS_HELP_STRING([--disable-rr-semantics], [disable the v6 Route Replace semantics]))
 422 AC_ARG_ENABLE([protobuf],
 423   AS_HELP_STRING([--enable-protobuf], [Enable experimental protobuf support]))
 424 AC_ARG_ENABLE([oldvpn_commands],
 425   AS_HELP_STRING([--enable-oldvpn-commands], [Keep old vpn commands]))
 426 AC_ARG_ENABLE(rpki,
 427   AS_HELP_STRING([--enable-rpki], [enable RPKI prefix validation support]))
 428 AC_ARG_ENABLE([clippy-only],
 429   AS_HELP_STRING([--enable-clippy-only], [Only build clippy]))
 430 AC_ARG_ENABLE([numeric_version],
 431   AS_HELP_STRING([--enable-numeric-version], [Only numeric digits allowed in version (for Alpine)]))
 432 AC_ARG_ENABLE([gcov],
 433   AS_HELP_STRING([--enable-gcov], [Add code coverage information]))
 434 AC_ARG_ENABLE(bfdd,
 435   AS_HELP_STRING([--disable-bfdd], [do not build bfdd]))
 436 AC_ARG_ENABLE([address-sanitizer],
 437   AS_HELP_STRING([--enable-address-sanitizer], [enable AddressSanitizer support for detecting a wide variety of memory allocation and deallocation errors]))
 438 AC_ARG_ENABLE([thread-sanitizer],
 439   AS_HELP_STRING([--enable-thread-sanitizer], [enable ThreadSanitizer support for detecting data races]))
 440 AC_ARG_ENABLE([memory-sanitizer],
 441   AS_HELP_STRING([--enable-memory-sanitizer], [enable MemorySanitizer support for detecting uninitialized memory reads]))
 442
 443 AS_IF([test "${enable_clippy_only}" != "yes"], [
 444 AC_CHECK_HEADERS(json-c/json.h)
 445 AC_CHECK_LIB(json-c, json_object_get, LIBS="$LIBS -ljson-c", [], [-lm])
 446 if test $ac_cv_lib_json_c_json_object_get = no; then
 447   AC_CHECK_LIB(json, json_object_get, LIBS="$LIBS -ljson")
 448   if test $ac_cv_lib_json_json_object_get = no; then
 449       AC_MSG_ERROR([lib json is needed to compile])
 450   fi
 451 fi
 452 ])
 453
 454 AC_ARG_ENABLE([dev_build],
 455     AS_HELP_STRING([--enable-dev-build], [build for development]))
 456
 457 if test x"${enable_time_check}" != x"no" ; then
 458   if test x"${enable_time_check}" = x"yes" -o x"${enable_time_check}" = x ; then
 459     AC_DEFINE(CONSUMED_TIME_CHECK,5000000,Consumed Time Check)
 460   else
 461     AC_DEFINE_UNQUOTED(CONSUMED_TIME_CHECK,$enable_time_check,Consumed Time Check)
 462   fi
 463 fi
 464
 465 case "${enable_systemd}" in
 466   "no") ;;
 467   "yes")
 468   AC_CHECK_LIB(systemd, sd_notify, LIBS="$LIBS -lsystemd")
 469   if test $ac_cv_lib_systemd_sd_notify = no; then
 470     AC_MSG_ERROR([enable systemd has been specified but systemd development env not found on your system])
 471   else
 472     AC_DEFINE(HAVE_SYSTEMD,,Compile systemd support in)
 473   fi
 474   ;;
 475   "*") ;;
 476 esac
 477
 478 if test "${enable_rr_semantics}" != "no" ; then
 479   AC_DEFINE(HAVE_V6_RR_SEMANTICS,, Compile in v6 Route Replacement Semantics)
 480 fi
 481
 482 if test "${enable_datacenter}" = "yes" ; then
 483   AC_DEFINE(HAVE_DATACENTER,,Compile extensions for a DataCenter)
 484   DFLT_NAME="datacenter"
 485 else
 486   DFLT_NAME="traditional"
 487 fi
 488
 489 if test "${enable_fuzzing}" = "yes" ; then
 490   AC_DEFINE(HANDLE_ZAPI_FUZZING,,Compile extensions to use with a fuzzer)
 491 fi
 492
 493 if test "${enable_netlink_fuzzing}" = "yes" ; then
 494   AC_DEFINE(HANDLE_NETLINK_FUZZING,,Compile extensions to use with a fuzzer for netlink)
 495 fi
 496
 497 if test "${enable_cumulus}" = "yes" ; then
 498   AC_DEFINE(HAVE_CUMULUS,,Compile Special Cumulus Code in)
 499 fi
 500
 501 AC_SUBST(DFLT_NAME)
 502 AC_DEFINE_UNQUOTED(DFLT_NAME,["$DFLT_NAME"], Name of the configuration default set)
 503
 504 if test "${enable_shell_access}" = "yes"; then
 505    AC_DEFINE(HAVE_SHELL_ACCESS,,Allow user to use ssh/telnet/bash)
 506 fi
 507
 508 AM_CONDITIONAL([FPM], [test "x$enable_fpm" = "xyes"])
 509
 510 #
 511 # Python for clippy
 512 #
 513
 514 AC_DEFUN([FRR_PYTHON_CHECK_WORKING], [
 515   AC_MSG_CHECKING([whether we found a working Python version])
 516   AC_LINK_IFELSE_FLAGS([$PYTHON_CFLAGS], [$PYTHON_LIBS], [AC_LANG_PROGRAM([
 517 #include <Python.h>
 518 #if PY_VERSION_HEX < 0x02070000
 519 #error python too old
 520 #endif
 521 int main(void);
 522 ],
 523 [
 524 {
 525   Py_Initialize();
 526   return 0;
 527 }
 528 ])], [
 529     # some python installs are missing the zlib dependency...
 530     PYTHON_LIBS="${PYTHON_LIBS} -lz"
 531     AC_LINK_IFELSE_FLAGS([$PYTHON_CFLAGS], [$PYTHON_LIBS], [AC_LANG_PROGRAM([
 532 #include <Python.h>
 533 #if PY_VERSION_HEX < 0x02070000
 534 #error python too old
 535 #endif
 536 int main(void);
 537 ],
 538 [
 539 {
 540   Py_Initialize();
 541   return 0;
 542 }
 543 ])], [
 544       m4_if([$1], [], [
 545         PYTHONCONFIG=""
 546         unset PYTHON_LIBS
 547         unset PYTHON_CFLAGS
 548       ], [$1])
 549     ])
 550   ])
 551 ])
 552
 553 AS_IF([test "$host" = "$build"], [
 554   PYTHONCONFIG=""
 555
 556   # ordering:
 557   # 1.  try python3, but respect the user's preference on which minor ver
 558   # 2.  try python, which might be py3 or py2 again on the user's preference
 559   # 3.  try python2 (can really only be 2.7 but eh)
 560   # 4.  try 3.6 > 3.5 > 3.4 > 3.3 > 3.2 > 2.7 through pkg-config (no user pref)
 561   #
 562   # (AX_PYTHON_DEVEL has no clue about py3 vs py2)
 563   # (AX_PYTHON does not do what we need)
 564
 565   AC_CHECK_TOOLS([PYTHONCONFIG], [ \
 566         python3-config \
 567         python-config \
 568         python2-config \
 569         python3.6-config \
 570         python3.5-config \
 571         python3.4-config \
 572         python3.3-config \
 573         python3.2-config \
 574         python2.7-config ])
 575   if test -n "$PYTHONCONFIG"; then
 576     PYTHON_CFLAGS="`\"${PYTHONCONFIG}\" --includes`"
 577     PYTHON_LIBS="`\"${PYTHONCONFIG}\" --ldflags`"
 578
 579     FRR_PYTHON_CHECK_WORKING([])
 580   fi
 581
 582   if test -z "$PYTHONCONFIG"; then
 583     PKG_CHECK_MODULES([PYTHON], python-3.6, [], [
 584       PKG_CHECK_MODULES([PYTHON], python-3.5, [], [
 585         PKG_CHECK_MODULES([PYTHON], python-3.4, [], [
 586           PKG_CHECK_MODULES([PYTHON], python-3.3, [], [
 587             PKG_CHECK_MODULES([PYTHON], python-3.2, [], [
 588               PKG_CHECK_MODULES([PYTHON], python-2.7, [], [
 589                 AC_MSG_FAILURE([could not find python-config or pkg-config python, please install Python development files from libpython-dev or similar])
 590                 ])])])])])])
 591
 592
 593     FRR_PYTHON_CHECK_WORKING([
 594       AC_MSG_FAILURE([could not find python-config or pkg-config python, please install Python development files from libpython-dev or similar])
 595     ])
 596   fi
 597 ])
 598 AC_SUBST(PYTHON_CFLAGS)
 599 AC_SUBST(PYTHON_LIBS)
 600
 601 #
 602 # Logic for protobuf support.
 603 #
 604 if test "$enable_protobuf" = "yes"; then
 605   # Check for protoc & protoc-c
 606
 607   # protoc is not required, it's only for a "be nice" helper target
 608   AC_CHECK_PROGS([PROTOC], [protoc], [/bin/false])
 609
 610   AC_CHECK_PROGS([PROTOC_C], [protoc-c], [/bin/false])
 611   if test "$PROTOC_C" = "/bin/false"; then
 612     AC_MSG_FAILURE([protobuf requested but protoc-c not found.  Install protobuf-c.])
 613   fi
 614
 615   PKG_CHECK_MODULES([PROTOBUF_C], [libprotobuf-c >= 0.14],, [
 616     AC_MSG_FAILURE([protobuf requested but libprotobuf-c not found.  Install protobuf-c.])
 617   ])
 618   AC_CHECK_HEADER([google/protobuf-c/protobuf-c.h], [], [
 619     AC_MSG_FAILURE([protobuf requested but protobuf-c.h not found.  Install protobuf-c.])
 620   ])
 621
 622   AC_DEFINE(HAVE_PROTOBUF,, protobuf)
 623 fi
 624 AM_CONDITIONAL([HAVE_PROTOBUF], [test "x$enable_protobuf" = "xyes"])
 625
 626 #
 627 # Logic for old vpn commans support.
 628 #
 629 if test "$enable_oldvpn_commands" = "yes"; then
 630    AC_DEFINE(KEEP_OLD_VPN_COMMANDS,, [Define for compiling with old vpn commands])
 631 fi
 632
 633 #
 634 # End of logic for protobuf support.
 635 #
 636
 637 AC_MSG_CHECKING(if zebra should be configurable to send Route Advertisements)
 638 if test "${enable_rtadv}" != "no"; then
 639   AC_MSG_RESULT(yes)
 640   AC_DEFINE(HAVE_RTADV,,Enable IPv6 Routing Advertisement support)
 641 else
 642   AC_MSG_RESULT(no)
 643 fi
 644
 645 if test x"${enable_user}" = x"no"; then
 646   enable_user=""
 647 else
 648   if test x"${enable_user}" = x"yes" || test x"${enable_user}" = x""; then
 649     enable_user="frr"
 650   fi
 651   AC_DEFINE_UNQUOTED(FRR_USER, "${enable_user}", frr User)
 652 fi
 653
 654 if test x"${enable_group}" = x"no"; then
 655   enable_group=""
 656 else
 657   if test x"${enable_group}" = x"yes" || test x"${enable_group}" = x""; then
 658     enable_group="frr"
 659   fi
 660   AC_DEFINE_UNQUOTED(FRR_GROUP, "${enable_group}", frr Group)
 661 fi
 662
 663 if test x"${enable_vty_group}" = x"yes" ; then
 664   AC_MSG_ERROR([--enable-vty-group requires a group as argument, not yes])
 665 elif test x"${enable_vty_group}" != x""; then
 666   if test x"${enable_vty_group}" != x"no"; then
 667     AC_DEFINE_UNQUOTED(VTY_GROUP, "${enable_vty_group}", VTY Sockets Group)
 668   fi
 669 fi
 670 AC_SUBST([enable_user])
 671 AC_SUBST([enable_group])
 672 AC_SUBST([enable_vty_group])
 673
 674 enable_configfile_mask=${enable_configfile_mask:-0600}
 675 AC_DEFINE_UNQUOTED(CONFIGFILE_MASK, ${enable_configfile_mask}, Mask for config files)
 676
 677 enable_logfile_mask=${enable_logfile_mask:-0600}
 678 AC_DEFINE_UNQUOTED(LOGFILE_MASK, ${enable_logfile_mask}, Mask for log files)
 679
 680 MPATH_NUM=1
 681
 682 case "${enable_multipath}" in
 683   0)
 684     MPATH_NUM=64
 685     ;;
 686   [[1-9]|[1-9][0-9]|[1-9][0-9][0-9]])
 687     MPATH_NUM="${enable_multipath}"
 688     ;;
 689   "")
 690     ;;
 691   *)
 692     AC_MSG_FAILURE([Please specify digit to enable multipath ARG])
 693     ;;
 694 esac
 695
 696 AC_DEFINE_UNQUOTED(MULTIPATH_NUM, $MPATH_NUM, Maximum number of paths for a route)
 697
 698 AC_DEFINE_UNQUOTED(VTYSH_PAGER, "$VTYSH_PAGER", [What pager to use])
 699
 700 dnl --------------------
 701 dnl Enable code coverage
 702 dnl --------------------
 703 AM_CONDITIONAL([HAVE_GCOV],[test '!' "$enable_gcov" = no])
 704
 705 dnl ------------------------------------
 706 dnl Alpine only accepts numeric versions
 707 dnl ------------------------------------
 708 if test "x${enable_numeric_version}" != "x" ; then
 709   VERSION="`echo ${VERSION} | tr -c -d '[[.0-9]]'`"
 710   PACKAGE_VERSION="`echo ${PACKAGE_VERSION} | tr -c -d '[[.0-9]]'`"
 711 fi
 712
 713 dnl -----------------------------------
 714 dnl Add extra version string to package
 715 dnl name, string and version fields.
 716 dnl -----------------------------------
 717 if test "x${EXTRAVERSION}" != "x" ; then
 718   VERSION="${VERSION}${EXTRAVERSION}"
 719   PACKAGE_VERSION="${PACKAGE_VERSION}${EXTRAVERSION}"
 720   AC_SUBST(PACKAGE_EXTRAVERSION, ["${EXTRAVERSION}"])
 721   PACKAGE_STRING="${PACKAGE_STRING}${EXTRAVERSION}"
 722 fi
 723
 724 if test "x$with_pkg_git_version" = "xyes"; then
 725         if test -d "${srcdir}/.git"; then
 726                 AC_DEFINE(GIT_VERSION, [1], [include git version info])
 727         else    with_pkg_git_version="no"
 728                 AC_MSG_WARN([--with-pkg-git-version given, but this is not a git checkout])
 729         fi
 730 fi
 731 AM_CONDITIONAL([GIT_VERSION], [test "x$with_pkg_git_version" = "xyes"])
 732
 733 dnl ------------------------------------
 734 dnl Check C keywords and standard  types
 735 dnl ------------------------------------
 736 AC_C_CONST
 737 AC_C_INLINE
 738 AC_C_VOLATILE
 739 AC_HEADER_STDC
 740 dnl AC_TYPE_PID_T
 741 AC_TYPE_UID_T
 742 AC_TYPE_MODE_T
 743 AC_TYPE_SIZE_T
 744 AC_STRUCT_TM
 745
 746 dnl -------------------------
 747 dnl Check other header files.
 748 dnl -------------------------
 749 AC_CHECK_HEADERS([stropts.h sys/ksym.h \
 750         linux/version.h asm/types.h \
 751         sys/cdefs.h])
 752
 753 ac_stdatomic_ok=false
 754 AC_DEFINE(FRR_AUTOCONF_ATOMIC, 1, [did autoconf checks for atomic funcs])
 755 AC_CHECK_HEADER([stdatomic.h],[
 756
 757   AC_MSG_CHECKING([whether _Atomic qualifier works])
 758   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 759 #include <stdatomic.h>
 760 int main(int argc, char **argv) {
 761   _Atomic int i = 0;
 762   return i;
 763 }
 764 ]])], [
 765     AC_DEFINE(HAVE_STDATOMIC_H, 1, [found stdatomic.h])
 766     AC_MSG_RESULT([yes])
 767     ac_stdatomic_ok=true
 768   ], [
 769     AC_MSG_RESULT([no])
 770   ])
 771 ])
 772
 773 AS_IF([$ac_stdatomic_ok], [true], [
 774   AC_MSG_CHECKING([for __atomic_* builtins])
 775   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 776 int main(int argc, char **argv) {
 777   volatile int i = 1;
 778   __atomic_store_n (&i, 0, __ATOMIC_RELEASE);
 779   return __atomic_load_n (&i, __ATOMIC_ACQUIRE);
 780 }
 781 ]])], [
 782     AC_DEFINE(HAVE___ATOMIC, 1, [found __atomic builtins])
 783     AC_MSG_RESULT([yes])
 784   ], [
 785     AC_MSG_RESULT([no])
 786
 787     dnl FreeBSD 9 has a broken stdatomic.h where _Atomic doesn't work
 788     AC_MSG_CHECKING([for __sync_* builtins])
 789     AC_LINK_IFELSE([AC_LANG_SOURCE([[
 790 int main(int argc, char **argv) {
 791   volatile int i = 1;
 792   __sync_fetch_and_sub (&i, 1);
 793   return __sync_val_compare_and_swap (&i, 0, 1);
 794 }
 795 ]])], [
 796       AC_DEFINE(HAVE___SYNC, 1, [found __sync builtins])
 797       AC_MSG_RESULT([yes])
 798
 799       AC_MSG_CHECKING([for __sync_swap builtin])
 800       AC_LINK_IFELSE([AC_LANG_SOURCE([[
 801 int main(int argc, char **argv) {
 802   volatile int i = 1;
 803   return __sync_swap (&i, 2);
 804 }
 805 ]])], [
 806         AC_DEFINE(HAVE___SYNC_SWAP, 1, [found __sync_swap builtin])
 807         AC_MSG_RESULT([yes])
 808       ], [
 809         AC_MSG_RESULT([no])
 810       ])
 811
 812     ], [
 813       AC_MSG_RESULT([no])
 814       AC_MSG_FAILURE([stdatomic.h unavailable and $CC has neither __atomic nor __sync builtins])
 815     ])
 816   ])
 817 ])
 818
 819 AC_CHECK_HEADERS([pthread_np.h],,, [
 820 #include <pthread.h>
 821 ])
 822 AC_CHECK_FUNCS([pthread_setname_np pthread_set_name_np])
 823
 824 dnl Utility macro to avoid retyping includes all the time
 825 m4_define([FRR_INCLUDES],
 826 [#ifdef SUNOS_5
 827 #define _POSIX_C_SOURCE 200809L
 828 #define __EXTENSIONS__
 829 #endif
 830 #include <stdio.h>
 831 #include <stdlib.h>
 832 #include <stddef.h>
 833 #include <sys/types.h>
 834 /* sys/conf.h depends on param.h on FBSD at least */
 835 #include <sys/param.h>
 836 /* Required for MAXSIG */
 837 #include <signal.h>
 838 #include <sys/socket.h>
 839 #ifdef __APPLE__
 840 # define __APPLE_USE_RFC_3542
 841 #endif
 842 #include <netinet/in.h>
 843 #include <sys/time.h>
 844 #include <time.h>
 845 #include <net/if.h>
 846 ])dnl
 847
 848 dnl Same applies for HAVE_NET_IF_VAR_H, which HAVE_NETINET6_ND6_H and
 849 dnl HAVE_NETINET_IN_VAR_H depend upon. But if_var.h depends on if.h, hence
 850 dnl an additional round for it.
 851
 852 AC_CHECK_HEADERS([net/if_var.h], [], [], FRR_INCLUDES)
 853
 854 m4_define([FRR_INCLUDES],
 855 FRR_INCLUDES
 856 [#if HAVE_NET_IF_VAR_H
 857 # include <net/if_var.h>
 858 #endif
 859 ])dnl
 860
 861 AC_CHECK_HEADERS([netinet/in_var.h \
 862         net/if_dl.h net/netopt.h \
 863         inet/nd.h netinet/ip_icmp.h \
 864         sys/sysctl.h sys/sockio.h kvm.h sys/conf.h],
 865         [], [], FRR_INCLUDES)
 866
 867 AC_CHECK_HEADERS([ucontext.h], [], [],
 868 [#ifndef __USE_GNU
 869 #define __USE_GNU
 870 #endif /* __USE_GNU */
 871 FRR_INCLUDES
 872 ])
 873
 874 m4_define([UCONTEXT_INCLUDES],
 875 [#include <ucontext.h>])dnl
 876
 877 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.uc_regs],
 878   [], [], [UCONTEXT_INCLUDES])
 879 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs],
 880   [AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs.nip],
 881    [], [], [UCONTEXT_INCLUDES])],
 882   [], [UCONTEXT_INCLUDES])
 883 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.gregs],
 884   [], [], [UCONTEXT_INCLUDES])
 885
 886 m4_define([FRR_INCLUDES],
 887 FRR_INCLUDES
 888 [
 889 #include <sys/un.h>
 890 #include <netinet/in_systm.h>
 891 #if HAVE_NETINET_IN_VAR_H
 892 # include <netinet/in_var.h>
 893 #endif
 894 #if HAVE_NET_IF_DL_H
 895 # include <net/if_dl.h>
 896 #endif
 897 #if HAVE_NET_NETOPT_H
 898 # include <net/netopt.h>
 899 #endif
 900 #include <net/route.h>
 901 #if HAVE_INET_ND_H
 902 # include <inet/nd.h>
 903 #endif
 904 #include <arpa/inet.h>
 905 /* Required for IDRP */
 906 #if HAVE_NETINET_IP_ICMP_H
 907 # include <netinet/ip_icmp.h>
 908 #endif
 909 ])dnl
 910
 911 dnl V6 headers are checked below, after we check for v6
 912
 913 AC_MSG_CHECKING([which operating system interface to use])
 914 case "$host_os" in
 915   sunos* | solaris2*)
 916     AC_MSG_RESULT([Solaris])
 917
 918     AC_DEFINE(SUNOS_5, 1, [SunOS 5])
 919     AC_DEFINE(SOLARIS_IPV6, 1, Solaris IPv6)
 920     AC_DEFINE(_POSIX_C_SOURCE, 200809L, [enable POSIX.1-2008 and XPG7/SUSv4])
 921
 922     AC_CHECK_LIB(socket, main)
 923     AC_CHECK_LIB(nsl, main)
 924     AC_CHECK_LIB(umem, main)
 925     AC_CHECK_FUNCS([printstack], [
 926       AC_DEFINE([HAVE_PRINTSTACK],1,[Solaris printstack])
 927       AC_DEFINE([HAVE_STACK_TRACE],1,[Stack symbols decode functionality])
 928     ])
 929     CURSES=-lcurses
 930     SOLARIS="solaris"
 931     ;;
 932   linux*)
 933     AC_MSG_RESULT([Linux])
 934
 935     AC_DEFINE(GNU_LINUX,,GNU Linux)
 936     AC_DEFINE(HAVE_NETLINK,,netlink)
 937     AC_DEFINE(LINUX_IPV6,1,Linux IPv6 stack)
 938
 939     dnl Linux has a compilation problem with mixing
 940     dnl netinet/in.h and linux/in6.h they are not
 941     dnl compatible.  There has been discussion on
 942     dnl how to fix it but no real progress on implementation
 943     dnl when they fix it, remove this
 944     AC_DEFINE(IPV6_MINHOPCOUNT, 73, Linux ipv6 Min Hop Count)
 945     ;;
 946   openbsd*)
 947     AC_MSG_RESULT([OpenBSD])
 948
 949     AC_DEFINE(OPEN_BSD,,OpenBSD)
 950     AC_DEFINE(KAME,1,KAME IPv6)
 951     AC_DEFINE(BSD_V6_SYSCTL,1,BSD v6 sysctl to turn on and off forwarding)
 952
 953     if test "x${enable_pimd}" != "xno"; then
 954       case "$host_os" in
 955       openbsd6.0)
 956         ;;
 957       openbsd[6-9]*)
 958         AC_MSG_FAILURE([pimd cannot be enabled as PIM support has been removed from OpenBSD 6.1])
 959         ;;
 960       esac
 961     fi
 962     ;;
 963   *)
 964     AC_MSG_RESULT([BSD])
 965
 966     AC_DEFINE(HAVE_NET_RT_IFLIST,,NET_RT_IFLIST)
 967     AC_DEFINE(KAME,1,KAME IPv6)
 968     AC_DEFINE(BSD_V6_SYSCTL,1,BSD v6 sysctl to turn on and off forwarding)
 969     ;;
 970 esac
 971 AM_CONDITIONAL(SOLARIS, test "${SOLARIS}" = "solaris")
 972
 973 AC_SYS_LARGEFILE
 974
 975 dnl ------------------------
 976 dnl Integrated REALMS option
 977 dnl ------------------------
 978 if test "${enable_realms}" = "yes"; then
 979     case "$host_os" in
 980       linux*)
 981        AC_DEFINE(SUPPORT_REALMS,, Realms support)
 982        ;;
 983       *)
 984        echo "Sorry, only Linux has REALMS support"
 985        exit 1
 986        ;;
 987     esac
 988 fi
 989 AM_CONDITIONAL([SUPPORT_REALMS], [test "${enable_realms}" = "yes"])
 990
 991 dnl ---------------------
 992 dnl Integrated VTY option
 993 dnl ---------------------
 994 case "${enable_vtysh}" in
 995   "no") VTYSH="";;
 996   *)    VTYSH="vtysh";
 997          AC_DEFINE(VTYSH,,VTY shell)
 998 dnl      Vtysh uses libreadline, which looks for termcap functions at
 999 dnl      configure time.  We follow readlines search order.
1000 dnl      The required procedures are in libtermcap on NetBSD, in
1001 dnl      [TODO] on Linux, and in [TODO] on Solaris.
1002          AC_CHECK_LIB(termcap, tputs, LIBREADLINE="$LIBREADLINE -ltermcap",
1003            [AC_CHECK_LIB(tinfo, tputs, LIBREADLINE="$LIBREADLINE -ltinfo",
1004              [AC_CHECK_LIB(curses, tputs, LIBREADLINE="$LIBREADLINE -lcurses",
1005                [AC_CHECK_LIB(ncurses, tputs,
1006                              LIBREADLINE="$LIBREADLINE -lncurses")]
1007               )]
1008             )]
1009           )
1010          AC_CHECK_LIB(readline, main, LIBREADLINE="-lreadline $LIBREADLINE",,
1011                       "$LIBREADLINE")
1012          if test $ac_cv_lib_readline_main = no; then
1013            AC_MSG_ERROR([vtysh needs libreadline but was not found and usable on your system.])
1014          fi
1015          AC_CHECK_HEADER(readline/history.h)
1016          if test $ac_cv_header_readline_history_h = no;then
1017            AC_MSG_ERROR([readline is too old to have readline/history.h, please update to the latest readline library.])
1018          fi
1019          AC_CHECK_LIB(readline, rl_completion_matches,
1020                       LIBREADLINE="$LIBREADLINE",, "$LIBREADLINE")
1021          if test $ac_cv_lib_readline_rl_completion_matches = no; then
1022            AC_DEFINE(rl_completion_matches,completion_matches,Old readline)
1023          fi
1024          AC_SEARCH_LIBS([append_history], [readline], [frr_cv_append_history=yes], [frr_cv_append_history=no])
1025          if test "$frr_cv_append_history" = yes; then
1026            AC_DEFINE(HAVE_APPEND_HISTORY, 1, [Have history.h append_history])
1027          fi
1028          ;;
1029 esac
1030 AC_SUBST(LIBREADLINE)
1031 AM_CONDITIONAL(VTYSH, test "x$VTYSH" = "xvtysh")
1032
1033 dnl ----------
1034 dnl PAM module
1035 dnl
1036 dnl FRR detects the PAM library it is built against by checking for a
1037 dnl functional pam_misc.h (Linux-PAM) or openpam.h (OpenPAM) header. pam_misc.h
1038 dnl is known to #include pam_appl.h, the standard header of a PAM library, and
1039 dnl openpam.h doesn't do that, although depends on the header too. Hence a
1040 dnl little assistance to AC_CHECK_HEADER is necessary for the proper detection
1041 dnl of OpenPAM.
1042 dnl ----------
1043 if test "$with_libpam" = "yes"; then
1044   AC_CHECK_HEADER([security/pam_misc.h],
1045     [AC_DEFINE(HAVE_PAM_MISC_H,,Have pam_misc.h)
1046      AC_DEFINE(PAM_CONV_FUNC,misc_conv,Have misc_conv)
1047      pam_conv_func="misc_conv"
1048     ],
1049     [], FRR_INCLUDES)
1050   AC_CHECK_HEADER([security/openpam.h],
1051     [AC_DEFINE(HAVE_OPENPAM_H,,Have openpam.h)
1052      AC_DEFINE(PAM_CONV_FUNC,openpam_ttyconv,Have openpam_ttyconv)
1053      pam_conv_func="openpam_ttyconv"
1054     ],
1055     [], FRR_INCLUDES[#include <security/pam_appl.h>])
1056   if test -z "$ac_cv_header_security_pam_misc_h$ac_cv_header_security_openpam_h" ; then
1057     AC_MSG_WARN([*** pam support will not be built ***])
1058     with_libpam="no"
1059   fi
1060 fi
1061
1062 if test "$with_libpam" = "yes"; then
1063 dnl took this test from proftpds configure.in and suited to our needs
1064 dnl -------------------------------------------------------------------------
1065 dnl
1066 dnl This next check looks funky due to a linker problem with some versions
1067 dnl of the PAM library.  Prior to 0.72 release, the Linux PAM shared library
1068 dnl omitted requiring libdl linking information. PAM-0.72 or better ships
1069 dnl with RedHat 6.2 and Debian 2.2 or better.
1070 AC_CHECK_LIB(pam, pam_start,
1071   [AC_CHECK_LIB(pam, $pam_conv_func,
1072     [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1073      LIBPAM="-lpam"],
1074     [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1075      LIBPAM="-lpam -lpam_misc"]
1076     )
1077   ],
1078
1079   [AC_CHECK_LIB(pam, pam_end,
1080     [AC_CHECK_LIB(pam, $pam_conv_func,
1081       [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1082        LIBPAM="-lpam -ldl"],
1083       [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1084        LIBPAM="-lpam -ldl -lpam_misc"]
1085      )
1086   ],AC_MSG_WARN([*** pam support will not be built ***]),
1087   [-ldl])
1088   ]
1089 )
1090 fi
1091 AC_SUBST(LIBPAM)
1092
1093 dnl -------------------------------
1094 dnl Endian-ness check
1095 dnl -------------------------------
1096 AC_WORDS_BIGENDIAN
1097
1098 dnl -------------------------------
1099 dnl check the size in byte of the C
1100 dnl -------------------------------
1101 dnl AC_CHECK_SIZEOF(char)
1102 dnl AC_CHECK_SIZEOF(int)
1103 dnl AC_CHECK_SIZEOF(short)
1104 dnl AC_CHECK_SIZEOF(long)
1105
1106 dnl ----------------------------
1107 dnl check existance of functions
1108 dnl ----------------------------
1109 AC_FUNC_FNMATCH
1110 AC_FUNC_FORK
1111 AC_FUNC_MKTIME
1112 AC_FUNC_STAT
1113
1114 dnl -------------------------------
1115 dnl bgpd needs pow() and hence libm
1116 dnl -------------------------------
1117 TMPLIBS="$LIBS"
1118 AC_CHECK_HEADER([math.h],
1119   [AC_CHECK_LIB([m], [pow],
1120     [LIBM="-lm"
1121      LIBS="$LIBS $LIBM"
1122      AC_CHECK_FUNCS(pow,[],[LIBM=""])
1123     ])
1124 ])
1125 if test x"$LIBM" = x ; then
1126   AC_MSG_WARN([Unable to find working pow function - bgpd may not link])
1127 fi
1128 LIBS="$TMPLIBS"
1129 AC_SUBST(LIBM)
1130
1131 AC_CHECK_FUNCS([ppoll], [
1132   AC_DEFINE([HAVE_PPOLL], 1, [have Linux/BSD ppoll()])
1133 ])
1134 AC_CHECK_FUNCS([pollts], [
1135   AC_DEFINE([HAVE_POLLTS], 1, [have NetBSD pollts()])
1136 ])
1137
1138 dnl ---------------
1139 dnl other functions
1140 dnl ---------------
1141 AC_CHECK_FUNCS([ \
1142         strlcat strlcpy \
1143         getgrouplist])
1144
1145 AC_CHECK_HEADER([asm-generic/unistd.h],
1146                 [AC_CHECK_DECL(__NR_setns,
1147                                AC_DEFINE(HAVE_NETNS,, Have netns),,
1148                                FRR_INCLUDES [#include <asm-generic/unistd.h>
1149                                ])
1150                  AC_CHECK_FUNCS(setns)]
1151                )
1152
1153 dnl --------------------------
1154 dnl Determine IS-IS I/O method
1155 dnl --------------------------
1156 AC_DEFINE(ISIS_METHOD_PFPACKET, 1, [ constant value for isis method pfpacket ])
1157 AC_DEFINE(ISIS_METHOD_DLPI,     2, [ constant value for isis method dlpi ])
1158 AC_DEFINE(ISIS_METHOD_BPF,      3, [ constant value for isis method bpf ])
1159 AC_CHECK_HEADER(net/bpf.h)
1160 AC_CHECK_HEADER(sys/dlpi.h)
1161 AC_MSG_CHECKING(zebra IS-IS I/O method)
1162
1163 case "$host_os" in
1164   linux*)
1165     AC_MSG_RESULT(pfpacket)
1166     ISIS_METHOD_MACRO="ISIS_METHOD_PFPACKET"
1167     ;;
1168   solaris* | sunos*)
1169     AC_MSG_RESULT(DLPI)
1170     ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1171     ;;
1172   *)
1173     if test $ac_cv_header_net_bpf_h = no; then
1174       if test $ac_cv_header_sys_dlpi_h = no; then
1175         AC_MSG_RESULT(none)
1176         if test "${enable_isisd}" = yes -o "${enable_fabricd}" = yes; then
1177           AC_MSG_FAILURE([IS-IS support requested but no packet backend found])
1178         fi
1179         AC_MSG_WARN([*** IS-IS support will not be built ***])
1180         enable_isisd="no"
1181         enable_fabricd="no"
1182       else
1183         AC_MSG_RESULT(DLPI)
1184       fi
1185       ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1186     else
1187       AC_MSG_RESULT(BPF)
1188       ISIS_METHOD_MACRO="ISIS_METHOD_BPF"
1189     fi
1190     ;;
1191 esac
1192 AC_DEFINE_UNQUOTED(ISIS_METHOD, $ISIS_METHOD_MACRO, [ selected method for isis, == one of the constants ])
1193
1194 dnl ---------------------------------------------------------------
1195 dnl figure out how to specify an interface in multicast sockets API
1196 dnl ---------------------------------------------------------------
1197 AC_CHECK_MEMBERS([struct ip_mreqn.imr_ifindex], [], [], FRR_INCLUDES)
1198
1199 AC_CHECK_HEADERS([linux/mroute.h], [], [],[
1200         #include <sys/socket.h>
1201         #include <netinet/in.h>
1202         #define _LINUX_IN_H             /* For Linux <= 2.6.25 */
1203         #include <linux/types.h>
1204 ])
1205
1206 m4_define([FRR_INCLUDES],
1207 FRR_INCLUDES
1208 [#if HAVE_LINUX_MROUTE_H
1209 # include <linux/mroute.h>
1210 #endif
1211 ])dnl
1212
1213 AC_CHECK_HEADERS([netinet/ip_mroute.h], [], [],[
1214         #include <sys/socket.h>
1215         #include <sys/types.h>
1216         #include <netinet/in.h>
1217         #include <net/route.h>
1218 ])
1219
1220 m4_define([FRR_INCLUDES],
1221 FRR_INCLUDES
1222 [#if HAVE_NETINET_IP_MROUTE_H
1223 # include <netinet/ip_mroute.h>
1224 #endif
1225 ])dnl
1226
1227 AC_MSG_CHECKING([for BSD struct ip_mreq hack])
1228 AC_TRY_COMPILE([#include <sys/param.h>],
1229 [#if (defined(__FreeBSD__) && ((__FreeBSD_version >= 500022 && __FreeBSD_version < 700000) || (__FreeBSD_version < 500000 && __FreeBSD_version >= 440000))) || (defined(__NetBSD__) && defined(__NetBSD_Version__) && __NetBSD_Version__ >= 106010000) || defined(__OpenBSD__) || defined(__APPLE__) || defined(__DragonFly__) || defined(__sun)
1230   return (0);
1231 #else
1232   #error No support for BSD struct ip_mreq hack detected
1233 #endif],[AC_MSG_RESULT(yes)
1234 AC_DEFINE(HAVE_BSD_STRUCT_IP_MREQ_HACK,,[Can pass ifindex in struct ip_mreq])],
1235 AC_MSG_RESULT(no))
1236
1237 AC_MSG_CHECKING([for RFC3678 protocol-independed API])
1238 AC_TRY_COMPILE([
1239 #include <sys/types.h>
1240 #include <netinet/in.h>
1241 ], [struct group_req gr; int sock; setsockopt(sock, IPPROTO_IP, MCAST_JOIN_GROUP, (void*)&gr, sizeof(gr));
1242 ], [AC_MSG_RESULT(yes)
1243 AC_DEFINE(HAVE_RFC3678,1,[Have RFC3678 protocol-independed API])],
1244 AC_MSG_RESULT(no))
1245
1246 dnl ---------------------------------------------------------------
1247 dnl figure out how to check link-state
1248 dnl ---------------------------------------------------------------
1249 AC_CHECK_HEADER( [net/if_media.h],
1250   [m4_define([LINK_DETECT_INCLUDES],
1251     FRR_INCLUDES
1252     [#include <net/if_media.h>
1253   ])
1254   AC_CHECK_MEMBERS( [struct ifmediareq.ifm_status],
1255     AC_DEFINE(HAVE_BSD_LINK_DETECT,,[BSD link-detect]),
1256     [], LINK_DETECT_INCLUDES)],
1257   [],
1258   FRR_INCLUDES)
1259
1260 dnl ---------------------------------------------------------------
1261 dnl Additional, newer way to check link-state using ifi_link_state.
1262 dnl Not available in all BSD's when ifmediareq available
1263 dnl ---------------------------------------------------------------
1264 AC_CHECK_MEMBERS([struct if_data.ifi_link_state],
1265   AC_DEFINE(HAVE_BSD_IFI_LINK_STATE,,[BSD ifi_link_state available]),
1266   [], FRR_INCLUDES)
1267
1268 dnl ------------------------
1269 dnl TCP_MD5SIG socket option
1270 dnl ------------------------
1271
1272 AC_CHECK_HEADER([netinet/tcp.h],
1273    [m4_define([MD5_INCLUDES],
1274       FRR_INCLUDES
1275       [#include <netinet/tcp.h>
1276     ])
1277     AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)],
1278    [],
1279    FRR_INCLUDES)
1280 if test $ac_cv_have_decl_TCP_MD5SIG = no; then
1281   AC_CHECK_HEADER([linux/tcp.h],
1282        [m4_define([MD5_INCLUDES],
1283           FRR_INCLUDES
1284           [#include <linux/tcp.h>
1285         ])
1286        AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)])
1287 fi
1288
1289 dnl ----------------------------------------------------------------------------
1290 dnl figure out if domainname is available in the utsname struct (GNU extension).
1291 dnl ----------------------------------------------------------------------------
1292 AC_CHECK_MEMBERS([struct utsname.domainname], [], [], [#include <sys/utsname.h>])
1293
1294 dnl ------------------
1295 dnl IPv6 header checks
1296 dnl ------------------
1297 AC_CHECK_HEADERS([netinet6/in6.h netinet/in6_var.h \
1298         netinet6/in6_var.h netinet6/nd6.h], [], [],
1299         FRR_INCLUDES)
1300
1301 m4_define([FRR_INCLUDES],dnl
1302 FRR_INCLUDES
1303 [#if HAVE_NETINET6_IN6_H
1304 #include <netinet6/in6.h>
1305 #endif
1306 #if HAVE_NETINET_IN6_VAR_H
1307 #include <netinet/in6_var.h>
1308 #endif
1309 #include <netinet/icmp6.h>
1310 #if HAVE_NETINET6_IN6_VAR_H
1311 # include <netinet6/in6_var.h>
1312 #endif
1313 #if HAVE_NETINET6_ND6_H
1314 # include <netinet6/nd6.h>
1315 #endif
1316 ])dnl
1317
1318 dnl disable doc check
1319 AC_CHECK_PROGS([SPHINXBUILD], [sphinx-build sphinx-build3 sphinx-build2], [/bin/false])
1320 if test "$SPHINXBUILD" = "/bin/false"; then
1321   if test "${enable_doc}" = "yes"; then
1322     AC_MSG_ERROR([Documentation was explicitly requested with --enable-doc but sphinx-build is not available. Please disable docs or install sphinx.])
1323   fi
1324 fi
1325 AM_CONDITIONAL(DOC, test "${enable_doc}" != "no" -a "$SPHINXBUILD" != "/bin/false")
1326 AM_CONDITIONAL(DOC_HTML, test "${enable_doc_html}" = "yes")
1327
1328 dnl --------------------
1329 dnl Daemon disable check
1330 dnl --------------------
1331 AM_CONDITIONAL(ZEBRA, test "${enable_zebra}" != "no")
1332
1333 if test "${enable_bgpd}" = "no";then
1334   BGPD=""
1335 else
1336   BGPD="bgpd"
1337 fi
1338 AM_CONDITIONAL(BGPD, test "x$BGPD" = "xbgpd")
1339
1340 AM_CONDITIONAL(RIPD, test "${enable_ripd}" != "no")
1341 AM_CONDITIONAL(OSPFD, test "${enable_ospfd}" != "no")
1342 AM_CONDITIONAL(LDPD, test "${enable_ldpd}" != "no")
1343
1344 AS_IF([test "${enable_ldpd}" != "no"], [
1345   AC_DEFINE(HAVE_LDPD, 1, ldpd)
1346 ])
1347
1348 if test "$enable_bfdd" = "no"; then
1349   AC_DEFINE(HAVE_BFDD, 0, bfdd)
1350   BFDD=""
1351 else
1352   AC_DEFINE(HAVE_BFDD, 1, bfdd)
1353   BFDD="bfdd"
1354
1355   case $host_os in
1356     linux*)
1357       AC_DEFINE(BFD_LINUX, 1, bfdd)
1358       ;;
1359
1360     *)
1361       AC_DEFINE(BFD_BSD, 1, bfdd)
1362       ;;
1363   esac
1364 fi
1365
1366 AM_CONDITIONAL(BFDD, [test "x$BFDD" = "xbfdd"])
1367
1368 if test $ac_cv_lib_json_c_json_object_get = no -a "x$BFDD" = "xbfdd"; then
1369   AC_MSG_ERROR(["you must use json-c library to use bfdd"])
1370 fi
1371
1372 NHRPD=""
1373 case "$host_os" in
1374   linux*)
1375     if test "${enable_nhrpd}" != "no"; then
1376       NHRPD="nhrpd"
1377     fi
1378     ;;
1379   *)
1380     if test "${enable_nhrpd}" = "yes"; then
1381       AC_MSG_ERROR([nhrpd requires kernel APIs that are only present on Linux.])
1382     fi
1383     ;;
1384 esac
1385 AM_CONDITIONAL(NHRPD, test "x$NHRPD" = "xnhrpd")
1386
1387 AM_CONDITIONAL(EIGRPD, test "${enable_eigrpd}" != "no")
1388
1389 if test "${enable_watchfrr}" = "no";then
1390   WATCHFRR=""
1391 else
1392   WATCHFRR="watchfrr"
1393 fi
1394 AM_CONDITIONAL(WATCHFRR, test "x$WATCHFRR" = "xwatchfrr")
1395
1396 OSPFCLIENT=""
1397 if test "${enable_ospfapi}" != "no";then
1398     AC_DEFINE(SUPPORT_OSPF_API,,OSPFAPI)
1399
1400   if test "${enable_ospfclient}" != "no";then
1401       OSPFCLIENT="ospfclient"
1402   fi
1403 fi
1404
1405 AM_CONDITIONAL(OSPFCLIENT, test "x$OSPFCLIENT" = "xospfclient")
1406 AM_CONDITIONAL(RIPNGD, test "${enable_ripngd}" != "no")
1407 AM_CONDITIONAL(BABELD, test "${enable_babeld}" != "no")
1408 AM_CONDITIONAL(OSPF6D, test "${enable_ospf6d}" != "no")
1409 AM_CONDITIONAL(ISISD, test "${enable_isisd}" != "no")
1410 AM_CONDITIONAL(PIMD, test "${enable_pimd}" != "no")
1411 AM_CONDITIONAL(PBRD, test "${enable_pbrd}" != "no")
1412 AM_CONDITIONAL(SHARPD, test "${enable_sharpd}" = "yes")
1413 AM_CONDITIONAL(STATICD, test "${enable_staticd}" != "no")
1414 AM_CONDITIONAL(FABRICD, test "${enable_fabricd}" != "no")
1415
1416 if test "${enable_bgp_announce}" = "no";then
1417   AC_DEFINE(DISABLE_BGP_ANNOUNCE,1,Disable BGP installation to zebra)
1418 else
1419   AC_DEFINE(DISABLE_BGP_ANNOUNCE,0,Disable BGP installation to zebra)
1420 fi
1421
1422 if test "${enable_bgp_vnc}" != "no";then
1423   AC_DEFINE(ENABLE_BGP_VNC,1,Enable BGP VNC support)
1424 fi
1425 AM_CONDITIONAL([ENABLE_BGP_VNC], [test x${enable_bgp_vnc} != xno])
1426
1427 AC_SUBST(SOLARIS)
1428 AC_SUBST(CURSES)
1429 AC_CHECK_LIB(crypt, crypt, [],
1430                     [AC_CHECK_LIB(crypto, DES_crypt)])
1431 AC_CHECK_LIB(resolv, res_init)
1432
1433 dnl ---------------------------
1434 dnl check system has PCRE regexp
1435 dnl ---------------------------
1436 if test "x$enable_pcreposix" = "xyes"; then
1437   AC_CHECK_LIB(pcreposix, regexec, [], [
1438     AC_MSG_ERROR([--enable-pcreposix given but unable to find libpcreposix])
1439   ])
1440 fi
1441 AC_SUBST(HAVE_LIBPCREPOSIX)
1442
1443 dnl ------------------
1444 dnl check C-Ares library
1445 dnl ------------------
1446 if test "${NHRPD}" != ""; then
1447   PKG_CHECK_MODULES([CARES], [libcares], , [
1448     AC_MSG_ERROR([trying to build nhrpd, but libcares not found. install c-ares and its -dev headers.])
1449   ])
1450 fi
1451
1452
1453 dnl ------------------
1454 dnl check Net-SNMP library
1455 dnl ------------------
1456 if test "${enable_snmp}" != "" -a "${enable_snmp}" != "no"; then
1457    AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], [no])
1458    if test x"$NETSNMP_CONFIG" = x"no"; then
1459       AC_MSG_ERROR([--enable-snmp given but unable to find net-snmp-config])
1460    fi
1461    SNMP_LIBS="`${NETSNMP_CONFIG} --agent-libs`"
1462    SNMP_CFLAGS="`${NETSNMP_CONFIG} --base-cflags`"
1463    AC_MSG_CHECKING([whether we can link to Net-SNMP])
1464    AC_LINK_IFELSE_FLAGS([$SNMP_CFLAGS], [$SNMP_LIBS], [AC_LANG_PROGRAM([
1465 int main(void);
1466 ],
1467 [
1468 {
1469   return 0;
1470 }
1471 ])], [
1472      AC_MSG_ERROR([--enable-snmp given but not usable])])
1473    case "${enable_snmp}" in
1474      yes)
1475       SNMP_METHOD=agentx
1476       ;;
1477      agentx)
1478       SNMP_METHOD="${enable_snmp}"
1479       ;;
1480      *)
1481       AC_MSG_ERROR([--enable-snmp given with an unknown method (${enable_snmp}). Use yes or agentx])
1482       ;;
1483    esac
1484    AH_TEMPLATE([SNMP_AGENTX], [Use SNMP AgentX to interface with snmpd])
1485    AC_DEFINE_UNQUOTED(AS_TR_CPP(SNMP_${SNMP_METHOD}),,SNMP method to interface with snmpd)
1486 fi
1487 AM_CONDITIONAL([SNMP], [test "x${SNMP_METHOD}" != "x"])
1488 AC_SUBST(SNMP_LIBS)
1489 AC_SUBST(SNMP_CFLAGS)
1490
1491 dnl ---------------
1492 dnl math
1493 dnl ---------------
1494 AC_SEARCH_LIBS([sqrt], [m])
1495
1496 dnl ---------------
1497 dnl dlopen & dlinfo
1498 dnl ---------------
1499 AC_SEARCH_LIBS(dlopen, [dl dld], [], [
1500   AC_MSG_ERROR([unable to find the dlopen()])
1501 ])
1502
1503 AC_CHECK_HEADERS([link.h])
1504
1505 AC_CACHE_CHECK([for dlinfo(RTLD_DI_ORIGIN)], [frr_cv_rtld_di_origin], [
1506   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1507 #include <stdlib.h>
1508 #ifdef HAVE_LINK_H
1509 #include <link.h>
1510 #endif
1511 #include <dlfcn.h>
1512 ]], [[
1513   char origin[1];
1514   dlinfo (NULL, RTLD_DI_ORIGIN, &origin);
1515 ]])], [
1516     frr_cv_rtld_di_origin=yes
1517   ], [
1518     frr_cv_rtld_di_origin=no
1519   ])
1520 ])
1521 if test "$frr_cv_rtld_di_origin" = yes; then
1522   AC_DEFINE(HAVE_DLINFO_ORIGIN, 1, [Have dlinfo RTLD_DI_ORIGIN])
1523 fi
1524
1525 AC_CACHE_CHECK([for dlinfo(RTLD_DI_LINKMAP)], [frr_cv_rtld_di_linkmap], [
1526   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1527 #include <stdlib.h>
1528 #ifdef HAVE_LINK_H
1529 #include <link.h>
1530 #endif
1531 #include <dlfcn.h>
1532 ]], [[
1533   struct link_map *lm = NULL;
1534   dlinfo (NULL, RTLD_DI_LINKMAP, &lm);
1535 ]])], [
1536     frr_cv_rtld_di_linkmap=yes
1537   ], [
1538     frr_cv_rtld_di_linkmap=no
1539   ])
1540 ])
1541 if test "$frr_cv_rtld_di_linkmap" = yes; then
1542   AC_DEFINE(HAVE_DLINFO_LINKMAP, 1, [Have dlinfo RTLD_DI_LINKMAP])
1543 fi
1544
1545 AM_CONDITIONAL(SNMP, test "x$SNMP_METHOD" = "xagentx")
1546
1547 dnl ---------------------------
1548 dnl sockaddr and netinet checks
1549 dnl ---------------------------
1550 AC_CHECK_TYPES([
1551         struct sockaddr_dl,
1552         struct vifctl, struct mfcctl, struct sioc_sg_req,
1553         vifi_t, struct sioc_vif_req, struct igmpmsg,
1554         struct ifaliasreq, struct if6_aliasreq, struct in6_aliasreq,
1555         struct nd_opt_adv_interval, struct rt_addrinfo,
1556         struct nd_opt_homeagent_info, struct nd_opt_adv_interval],
1557         [], [], FRR_INCLUDES)
1558
1559 AC_CHECK_MEMBERS([struct sockaddr.sa_len,
1560         struct sockaddr_in.sin_len, struct sockaddr_un.sun_len,
1561         struct sockaddr_dl.sdl_len,
1562         struct if6_aliasreq.ifra_lifetime,
1563         struct nd_opt_adv_interval.nd_opt_ai_type],
1564         [], [], FRR_INCLUDES)
1565
1566 dnl ---------------------------
1567 dnl IRDP/pktinfo/icmphdr checks
1568 dnl ---------------------------
1569
1570 AC_CHECK_TYPES([struct in_pktinfo], [
1571   AC_CHECK_TYPES([struct icmphdr], [
1572     IRDP=true
1573   ], [
1574     IRDP=false
1575   ], [FRR_INCLUDES])
1576 ], [
1577   IRDP=false
1578 ], [FRR_INCLUDES])
1579
1580 case "${enable_irdp}" in
1581 yes)
1582   $IRDP || AC_MSG_ERROR(['IRDP requires in_pktinfo at the moment!'])
1583   ;;
1584 no)
1585   IRDP=false
1586   ;;
1587 esac
1588
1589 AM_CONDITIONAL(IRDP, $IRDP)
1590
1591 dnl -----------------------
1592 dnl checking for IP_PKTINFO
1593 dnl -----------------------
1594 AC_MSG_CHECKING(for IP_PKTINFO)
1595 AC_TRY_COMPILE([#include <netdb.h>], [
1596   int opt = IP_PKTINFO;
1597 ], [
1598   AC_MSG_RESULT(yes)
1599   AC_DEFINE(HAVE_IP_PKTINFO, 1, [Have IP_PKTINFO])
1600 ], [
1601   AC_MSG_RESULT(no)
1602 ])
1603
1604 dnl ---------------------------
1605 dnl checking for IP_RECVDSTADDR
1606 dnl ---------------------------
1607 AC_MSG_CHECKING(for IP_RECVDSTADDR)
1608 AC_TRY_COMPILE([#include <netinet/in.h>], [
1609   int opt = IP_RECVDSTADDR;
1610 ], [
1611   AC_MSG_RESULT(yes)
1612   AC_DEFINE(HAVE_IP_RECVDSTADDR, 1, [Have IP_RECVDSTADDR])
1613 ], [
1614   AC_MSG_RESULT(no)
1615 ])
1616
1617 dnl ----------------------
1618 dnl checking for IP_RECVIF
1619 dnl ----------------------
1620 AC_MSG_CHECKING(for IP_RECVIF)
1621 AC_TRY_COMPILE([#include <netinet/in.h>], [
1622   int opt = IP_RECVIF;
1623 ], [
1624   AC_MSG_RESULT(yes)
1625   AC_DEFINE(HAVE_IP_RECVIF, 1, [Have IP_RECVIF])
1626 ], [
1627   AC_MSG_RESULT(no)
1628 ])
1629
1630 dnl ----------------------
1631 dnl checking for SO_BINDANY
1632 dnl ----------------------
1633 AC_MSG_CHECKING(for SO_BINDANY)
1634 AC_TRY_COMPILE([#include <sys/socket.h>], [
1635   int opt = SO_BINDANY;
1636 ], [
1637   AC_MSG_RESULT(yes)
1638   AC_DEFINE(HAVE_SO_BINDANY, 1, [Have SO_BINDANY])
1639 ], [
1640   AC_MSG_RESULT(no)
1641 ])
1642
1643 dnl ----------------------
1644 dnl checking for IP_FREEBIND
1645 dnl ----------------------
1646 AC_MSG_CHECKING(for IP_FREEBIND)
1647 AC_TRY_COMPILE([#include <netinet/in.h>], [
1648   int opt = IP_FREEBIND;
1649 ], [
1650   AC_MSG_RESULT(yes)
1651   AC_DEFINE(HAVE_IP_FREEBIND, 1, [Have IP_FREEBIND])
1652 ], [
1653   AC_MSG_RESULT(no)
1654 ])
1655
1656 dnl --------------------------------------
1657 dnl checking for be32dec existence or not
1658 dnl --------------------------------------
1659 AC_CHECK_DECLS([be32enc, be32dec], [], [],
1660                [#include <sys/endian.h>])
1661
1662 dnl --------------------------------------
1663 dnl checking for clock_time monotonic struct and call
1664 dnl --------------------------------------
1665 AC_CHECK_DECL(CLOCK_MONOTONIC,
1666         [AC_CHECK_LIB(rt, clock_gettime, [LIBS="$LIBS -lrt"])
1667          AC_DEFINE(HAVE_CLOCK_MONOTONIC,, Have monotonic clock)
1668 ], [AC_MSG_RESULT(no)], [FRR_INCLUDES])
1669
1670 dnl --------------------------------------
1671 dnl checking for flex and bison
1672 dnl --------------------------------------
1673
1674 AM_PROG_LEX
1675 AC_MSG_CHECKING(version of flex)
1676 frr_ac_flex_version="$(eval $LEX -V | grep flex | head -n 1)"
1677 frr_ac_flex_version="${frr_ac_flex_version##* }"
1678 AC_MSG_RESULT([$frr_ac_flex_version])
1679 AX_COMPARE_VERSION([$frr_ac_flex_version], [lt], [2.5.20], [
1680   LEX="$SHELL $missing_dir/missing flex"
1681   if test -f "${srcdir}/lib/command_lex.c" -a -f "${srcdir}/lib/command_lex.h"; then
1682     AC_MSG_WARN([using pregenerated flex output files])
1683   else
1684     AC_MSG_ERROR([flex failure and pregenerated files not included (probably a git build)])
1685   fi
1686   AC_SUBST([LEX_OUTPUT_ROOT], [lex.yy])
1687   AC_SUBST([LEXLIB], [''])
1688 ])
1689
1690 AC_PROG_YACC
1691 dnl thanks GNU bison for this b*llshit...
1692 AC_MSG_CHECKING(version of bison)
1693 frr_ac_bison_version="$(eval $YACC -V | grep bison | head -n 1)"
1694 frr_ac_bison_version="${frr_ac_bison_version##* }"
1695 frr_ac_bison_missing="false"
1696 case "x${frr_ac_bison_version}" in
1697   x2.7*)
1698     BISON_OPENBRACE='"'
1699     BISON_CLOSEBRACE='"'
1700     BISON_VERBOSE=''
1701     AC_MSG_RESULT([$frr_ac_bison_version - 2.7 or older])
1702     ;;
1703   x2.*|x1.*)
1704     AC_MSG_RESULT([$frr_ac_bison_version])
1705     AC_MSG_WARN([installed bison is too old.  Please install GNU bison 2.7.x or newer.])
1706     frr_ac_bison_missing="true"
1707     ;;
1708   x)
1709     AC_MSG_RESULT([none])
1710     AC_MSG_WARN([could not determine bison version.  Please install GNU bison 2.7.x or newer.])
1711     frr_ac_bison_missing="true"
1712     ;;
1713   *)
1714     BISON_OPENBRACE='{'
1715     BISON_CLOSEBRACE='}'
1716     BISON_VERBOSE='-Dparse.error=verbose'
1717     AC_MSG_RESULT([$frr_ac_bison_version - 3.0 or newer])
1718     ;;
1719 esac
1720 AC_SUBST(BISON_OPENBRACE)
1721 AC_SUBST(BISON_CLOSEBRACE)
1722 AC_SUBST(BISON_VERBOSE)
1723
1724 if $frr_ac_bison_missing; then
1725   YACC="$SHELL $missing_dir/missing bison -y"
1726   if test -f "${srcdir}/lib/command_parse.c" -a -f "${srcdir}/lib/command_parse.h"; then
1727     AC_MSG_WARN([using pregenerated bison output files])
1728   else
1729     AC_MSG_ERROR([bison failure and pregenerated files not included (probably a git build)])
1730   fi
1731 fi
1732
1733 dnl -------------------
1734 dnl capabilities checks
1735 dnl -------------------
1736 if test "${enable_capabilities}" != "no"; then
1737   AC_MSG_CHECKING(whether prctl PR_SET_KEEPCAPS is available)
1738   AC_TRY_COMPILE([#include <sys/prctl.h>],[prctl(PR_SET_KEEPCAPS, 1, 0, 0, 0);],
1739     [AC_MSG_RESULT(yes)
1740      AC_DEFINE(HAVE_PR_SET_KEEPCAPS,,prctl)
1741      frr_ac_keepcaps="yes"],
1742      AC_MSG_RESULT(no)
1743   )
1744   if test x"${frr_ac_keepcaps}" = x"yes"; then
1745     AC_CHECK_HEADERS(sys/capability.h)
1746   fi
1747   if test x"${ac_cv_header_sys_capability_h}" = x"yes"; then
1748     AC_CHECK_LIB(cap, cap_init,
1749       [AC_DEFINE(HAVE_LCAPS,1,Capabilities)
1750        LIBCAP="-lcap"
1751        frr_ac_lcaps="yes"]
1752     )
1753   else
1754     AC_CHECK_HEADERS(priv.h,
1755      [AC_MSG_CHECKING(Solaris style privileges are available)
1756       AC_TRY_COMPILE([#include <priv.h>],[getpflags(PRIV_AWARE);],
1757           [AC_MSG_RESULT(yes)
1758            AC_DEFINE(HAVE_SOLARIS_CAPABILITIES,1,getpflags)
1759            frr_ac_scaps="yes"],
1760            AC_MSG_RESULT(no)
1761       )
1762      ]
1763    )
1764   fi
1765   if test x"${frr_ac_scaps}" = x"yes" \
1766        -o x"${frr_ac_lcaps}" = x"yes"; then
1767     AC_DEFINE(HAVE_CAPABILITIES,1,capabilities)
1768   fi
1769 fi
1770 AC_SUBST(LIBCAP)
1771
1772 dnl ---------------------------
1773 dnl check for glibc 'backtrace'
1774 dnl ---------------------------
1775 if test x"${enable_backtrace}" != x"no" ; then
1776   backtrace_ok=no
1777   AC_CHECK_HEADER([execinfo.h], [
1778     AC_SEARCH_LIBS([backtrace], [execinfo], [
1779       AC_DEFINE(HAVE_GLIBC_BACKTRACE,,[Glibc backtrace])
1780       AC_DEFINE(HAVE_STACK_TRACE,,[Stack symbol decoding])
1781       backtrace_ok=yes
1782     ],, [-lm])
1783   ])
1784
1785   if test x"${enable_backtrace}" = x"yes" -a x"${backtrace_ok}" = x"no"; then
1786     dnl user explicitly requested backtrace but we failed to find support
1787     AC_MSG_FAILURE([failed to find backtrace support])
1788   fi
1789 fi
1790
1791 dnl -----------------------------------------
1792 dnl check for malloc mallinfo struct and call
1793 dnl this must try and link using LIBS, in
1794 dnl order to check no alternative allocator
1795 dnl has been specified, which might not provide
1796 dnl mallinfo, e.g. such as Umem on Solaris.
1797 dnl -----------------------------------------
1798 AC_CHECK_HEADERS([malloc.h malloc_np.h malloc/malloc.h],,, [FRR_INCLUDES])
1799
1800 AC_CACHE_CHECK([whether mallinfo is available], [frr_cv_mallinfo], [
1801   AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
1802 #ifdef HAVE_MALLOC_H
1803 #include <malloc.h>
1804 #endif
1805 #ifdef HAVE_MALLOC_NP_H
1806 #include <malloc_np.h>
1807 #endif
1808 #ifdef HAVE_MALLOC_MALLOC_H
1809 #include <malloc/malloc.h>
1810 #endif
1811 ]], [[
1812 struct mallinfo ac_x; ac_x = mallinfo ();
1813 ]])], [
1814     frr_cv_mallinfo=yes
1815   ], [
1816     frr_cv_mallinfo=no
1817   ])
1818 ])
1819 if test "$frr_cv_mallinfo" = yes; then
1820   AC_DEFINE(HAVE_MALLINFO,,mallinfo)
1821 fi
1822
1823 AC_MSG_CHECKING(whether malloc_usable_size is available)
1824 AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
1825 #ifdef HAVE_MALLOC_H
1826 #include <malloc.h>
1827 #endif
1828 #ifdef HAVE_MALLOC_MALLOC_H
1829 #include <malloc/malloc.h>
1830 #endif
1831 ]], [[
1832 size_t ac_x; ac_x = malloc_usable_size(NULL);
1833 ]])], [
1834   AC_MSG_RESULT(yes)
1835   AC_DEFINE(HAVE_MALLOC_USABLE_SIZE,,malloc_usable_size)
1836 ], [
1837   AC_MSG_RESULT(no)
1838
1839   AC_MSG_CHECKING(whether malloc_size is available)
1840   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1841 #ifdef HAVE_MALLOC_H
1842 #include <malloc.h>
1843 #endif
1844 #ifdef HAVE_MALLOC_MALLOC_H
1845 #include <malloc/malloc.h>
1846 #endif
1847 ]], [[
1848 size_t ac_x; ac_x = malloc_size(NULL);
1849 ]])], [
1850     AC_MSG_RESULT(yes)
1851     AC_DEFINE(HAVE_MALLOC_SIZE,,malloc_size)
1852   ], [
1853     AC_MSG_RESULT(no)
1854   ])
1855 ])
1856
1857 dnl ------
1858 dnl ZeroMQ
1859 dnl ------
1860 if test "x$enable_zeromq" != "xno"; then
1861   PKG_CHECK_MODULES(ZEROMQ, [libzmq >= 4.0.0], [
1862     AC_DEFINE(HAVE_ZEROMQ, 1, [Enable ZeroMQ support])
1863     ZEROMQ=true
1864   ], [
1865     if test "x$enable_zeromq" = "xyes"; then
1866       AC_MSG_ERROR([configuration specifies --enable-zeromq but libzmq was not found])
1867     fi
1868   ])
1869 fi
1870 AM_CONDITIONAL([ZEROMQ], test "x$ZEROMQ" = "xtrue")
1871
1872 dnl ----------
1873 dnl configure date
1874 dnl ----------
1875 dev_version=`echo $VERSION | grep dev`
1876 #don't expire deprecated code in non 'dev' branch
1877 if test "${dev_version}" = ""; then
1878    CONFDATE=0
1879 else
1880    CONFDATE=`date '+%Y%m%d'`
1881 fi
1882 AC_SUBST(CONFDATE)
1883
1884 dnl ------------------------------
1885 dnl set paths for state directory
1886 dnl ------------------------------
1887 AC_MSG_CHECKING(directory to use for state file)
1888 if test "${prefix}" = "NONE"; then
1889   frr_statedir_prefix="";
1890 else
1891   frr_statedir_prefix=${prefix}
1892 fi
1893 if test "${localstatedir}" = '${prefix}/var'; then
1894   for FRR_STATE_DIR in ${frr_statedir_prefix}/var/run dnl
1895                         ${frr_statedir_prefix}/var/adm dnl
1896                         ${frr_statedir_prefix}/etc dnl
1897                         /var/run        dnl
1898                         /var/adm        dnl
1899                         /etc            dnl
1900                         /dev/null;
1901   do
1902     test -d $FRR_STATE_DIR && break
1903   done
1904   frr_statedir=$FRR_STATE_DIR
1905 else
1906   frr_statedir=${localstatedir}
1907 fi
1908 if test $frr_statedir = "/dev/null"; then
1909     AC_MSG_ERROR('STATE DIRECTORY NOT FOUND! FIX OR SPECIFY --localstatedir!')
1910 fi
1911 AC_MSG_RESULT(${frr_statedir})
1912 AC_SUBST(frr_statedir)
1913
1914 AC_DEFINE_UNQUOTED(LDPD_SOCKET, "$frr_statedir/ldpd.sock",ldpd control socket)
1915 AC_DEFINE_UNQUOTED(ZEBRA_SERV_PATH, "$frr_statedir/zserv.api",zebra api socket)
1916 AC_DEFINE_UNQUOTED(BFDD_CONTROL_SOCKET, "$frr_statedir/bfdd.sock", bfdd control socket)
1917 AC_DEFINE_UNQUOTED(DAEMON_VTY_DIR, "$frr_statedir",daemon vty directory)
1918
1919 dnl autoconf does this, but it does it too late...
1920 test "x$prefix" = xNONE && prefix=$ac_default_prefix
1921 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
1922
1923 dnl get the full path, recursing through variables...
1924 vtysh_bin="$bindir/vtysh"
1925 for I in 1 2 3 4 5 6 7 8 9 10; do
1926         eval vtysh_bin="\"$vtysh_bin\""
1927 done
1928 AC_DEFINE_UNQUOTED(VTYSH_BIN_PATH, "$vtysh_bin",path to vtysh binary)
1929
1930 CFG_SYSCONF="$sysconfdir"
1931 CFG_SBIN="$sbindir"
1932 CFG_STATE="$frr_statedir"
1933 CFG_MODULE="$moduledir"
1934 for I in 1 2 3 4 5 6 7 8 9 10; do
1935         eval CFG_SYSCONF="\"$CFG_SYSCONF\""
1936         eval CFG_SBIN="\"$CFG_SBIN\""
1937         eval CFG_STATE="\"$CFG_STATE\""
1938         eval CFG_MODULE="\"$CFG_MODULE\""
1939 done
1940 AC_SUBST(CFG_SYSCONF)
1941 AC_SUBST(CFG_SBIN)
1942 AC_SUBST(CFG_STATE)
1943 AC_SUBST(CFG_MODULE)
1944 AC_DEFINE_UNQUOTED(MODULE_PATH, "$CFG_MODULE", path to modules)
1945
1946 dnl ------------------------------------
1947 dnl Enable RPKI and add librtr to libs
1948 dnl ------------------------------------
1949 if test "${enable_rpki}" = "yes"; then
1950   PKG_CHECK_MODULES(RTRLIB,[rtrlib >= 0.5.0],
1951       [RPKI=true],
1952       [RPKI=false
1953       AC_MSG_ERROR([rtrlib was not found on your system or is too old.])]
1954   )
1955 fi
1956 AM_CONDITIONAL([RPKI], test "x$RPKI" = "xtrue")
1957
1958 dnl ------------------------------------------
1959 dnl Check whether rtrlib was build with ssh support
1960 dnl ------------------------------------------
1961 AC_MSG_CHECKING([whether the RTR Library is compiled with SSH])
1962 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "rtrlib/rtrlib.h"]],
1963                         [[struct tr_ssh_config config;]])],
1964         [AC_MSG_RESULT(yes)
1965         AC_DEFINE(FOUND_SSH,,found_ssh)],
1966         AC_MSG_RESULT(no)
1967 )
1968
1969 dnl ---------------------------
1970 dnl Check htonl works correctly
1971 dnl ---------------------------
1972 AC_MSG_CHECKING(for working htonl)
1973 AC_CACHE_VAL(ac_cv_htonl_works,
1974  [AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES],[htonl (0);])],
1975                 [ac_cv_htonl_works=yes], [ac_cv_htonl_works=no])
1976  ]
1977 )
1978 AC_MSG_RESULT($ac_cv_htonl_works)
1979
1980 AC_CONFIG_FILES([Makefile],[sed -e 's/^#AUTODERP# //' -i Makefile])
1981
1982 AC_CONFIG_FILES([
1983           redhat/frr.spec
1984           solaris/Makefile
1985           debianpkg/changelog
1986           alpine/APKBUILD
1987           snapcraft/snapcraft.yaml
1988           lib/version.h
1989           tests/lib/cli/test_cli.refout
1990           pkgsrc/bgpd.sh pkgsrc/ospf6d.sh pkgsrc/ospfd.sh
1991           pkgsrc/ripd.sh pkgsrc/ripngd.sh pkgsrc/zebra.sh
1992           pkgsrc/eigrpd.sh])
1993
1994 AC_CONFIG_FILES([vtysh/extract.pl],[chmod +x vtysh/extract.pl])
1995
1996 AC_CONFIG_COMMANDS([lib/route_types.h], [
1997         dst="${ac_abs_top_builddir}/lib/route_types.h"
1998         ${PERL} "${ac_abs_top_srcdir}/lib/route_types.pl" \
1999                 < "${ac_abs_top_srcdir}/lib/route_types.txt" \
2000                 > "${dst}.tmp"
2001         test -f "${dst}" \
2002                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
2003                 && rm "${dst}.tmp" \
2004                 || mv "${dst}.tmp" "${dst}"
2005 ], [
2006         PERL="$PERL"
2007 ])
2008
2009 AS_IF([test "x$with_pkg_git_version" = "xyes"], [
2010     AC_CONFIG_COMMANDS([lib/gitversion.h], [
2011         dst="${ac_abs_top_builddir}/lib/gitversion.h"
2012         ${PERL} "${ac_abs_top_srcdir}/lib/gitversion.pl" \
2013                 "${ac_abs_top_srcdir}" \
2014                 > "${dst}.tmp"
2015         test -f "${dst}" \
2016                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
2017                 && rm "${dst}.tmp" \
2018                 || mv "${dst}.tmp" "${dst}"
2019     ], [
2020         PERL="$PERL"
2021     ])
2022 ])
2023
2024 ## Hack, but working solution to avoid rebuilding of frr.info.
2025 ## It's already in CVS until texinfo 4.7 is more common.
2026 AC_OUTPUT
2027
2028 echo "
2029 FRRouting configuration
2030 ------------------------------
2031 FRR version             : ${PACKAGE_VERSION}
2032 host operating system   : ${host_os}
2033 source code location    : ${srcdir}
2034 compiler                : ${CC}
2035 compiler flags          : ${CFLAGS} ${SAN_FLAGS}
2036 make                    : ${MAKE-make}
2037 linker flags            : ${LDFLAGS} ${SAN_FLAGS} ${LIBS} ${LIBCAP} ${LIBREADLINE} ${LIBM}
2038 state file directory    : ${frr_statedir}
2039 config file directory   : `eval echo \`echo ${sysconfdir}\``
2040 example directory       : `eval echo \`echo ${exampledir}\``
2041 module directory        : ${CFG_MODULE}
2042 user to run as          : ${enable_user}
2043 group to run as         : ${enable_group}
2044 group for vty sockets   : ${enable_vty_group}
2045 config file mask        : ${enable_configfile_mask}
2046 log file mask           : ${enable_logfile_mask}
2047 zebra protobuf enabled  : ${enable_protobuf:-no}
2048
2049 The above user and group must have read/write access to the state file
2050 directory and to the config files in the config file directory."
2051
2052 if test "${enable_doc}" != "no";then
2053   AS_IF([test "$SPHINXBUILD" = /bin/false],
2054      AC_MSG_WARN(sphinx-build is missing but required to build documentation))
2055 fi