configure.ac

   1 ##
   2 ## Configure template file for FRRouting.
   3 ## autoconf will generate a configure script.
   4 ##
   5 ##  Copyright (c) 1996, 97, 98, 99, 2000 Kunihiro Ishiguro <kunihiro@zebra.org>
   6 ##  Portions Copyright (c) 2003 Paul Jakma <paul@dishone.st>
   7 ##
   8 AC_PREREQ([2.69])
   9
  10 AC_INIT([frr], [8.1-dev], [https://github.com/frrouting/frr/issues])
  11 PACKAGE_URL="https://frrouting.org/"
  12 AC_SUBST([PACKAGE_URL])
  13 PACKAGE_FULLNAME="FRRouting"
  14 AC_SUBST([PACKAGE_FULLNAME])
  15
  16 CONFIG_ARGS="`echo $ac_configure_args | sed -e \"s% '[[A-Z]]*FLAGS=[[^']]\+'%%g\"`"
  17 AC_SUBST([CONFIG_ARGS])
  18
  19 AC_CONFIG_SRCDIR([lib/zebra.h])
  20 AC_CONFIG_MACRO_DIR([m4])
  21 AC_CONFIG_AUX_DIR([m4/ac])
  22
  23 dnl -----------------------------------
  24 dnl Get hostname and other information.
  25 dnl -----------------------------------
  26 AC_CANONICAL_BUILD()
  27 AC_CANONICAL_HOST()
  28
  29 AC_ARG_VAR([AR],[archiver command])
  30 AC_ARG_VAR([LD],[linker command])
  31 AC_ARG_VAR([OBJCOPY],[objcopy command])
  32 AC_ARG_VAR([OBJDUMP],[objdump command])
  33 AC_ARG_VAR([RANLIB],[ranlib command])
  34 AC_ARG_VAR([STRIP],[strip command])
  35
  36 hosttools_clippy="false"
  37 build_clippy="true"
  38
  39 dnl case 1: external clippy
  40 if test -n "$with_clippy" -a "$with_clippy" != "no" -a "$with_clippy" != "yes"; then
  41   if test "$enable_clippy_only" = "yes"; then
  42     AC_MSG_ERROR([--enable-clippy-only does not make sense with --with-clippy])
  43   fi
  44
  45   CLIPPY="$with_clippy"
  46   build_clippy="false"
  47   if test ! -x "$with_clippy"; then
  48     AC_MSG_ERROR([clippy tool ($with_clippy) is not executable])
  49   fi
  50
  51 dnl case 2: cross-compiling internal clippy
  52 elif test "$host" != "$build"; then
  53   if test "$srcdir" = "."; then
  54     AC_MSG_ERROR([cross-compilation is only possible with builddir separate from srcdir or by building clippy separately and using the --with-clippy option.  create a separate directory and run as .../path-to-frr/configure.])
  55   fi
  56   test -d hosttools || mkdir hosttools
  57   abssrc="`cd \"${srcdir}\"; pwd`"
  58
  59   AC_MSG_NOTICE([...])
  60   AC_MSG_NOTICE([... cross-compilation: creating hosttools directory and self-configuring for build platform tools])
  61   AC_MSG_NOTICE([... use HOST_CPPFLAGS / HOST_CFLAGS / HOST_LDFLAGS if neccessary])
  62   AC_MSG_NOTICE([...])
  63
  64   (
  65     for var in $ac_precious_vars; do
  66       dnl special cases
  67       case "$var" in
  68       YACC|YFLAGS) continue;;
  69       PYTHON*)     retain=true;;
  70       *)           retain=false;
  71       esac
  72
  73       eval "hostvar=\"\${HOST_$var}\""
  74       eval "targetvar=\"\${$var}\""
  75       if test -n "$hostvar"; then
  76         eval "$var='$hostvar'"
  77         _AS_ECHO_LOG([host $var='$hostvar'])
  78       elif $retain; then
  79         _AS_ECHO_LOG([host retain $var='$targetvar'])
  80       else
  81         eval "unset $var"
  82         _AS_ECHO_LOG([host unset $var])
  83       fi
  84     done
  85     cd hosttools
  86     "${abssrc}/configure" "--host=$build" "--build=$build" "--enable-clippy-only" "--disable-nhrpd" "--disable-vtysh"
  87   ) || exit 1
  88
  89   AC_MSG_NOTICE([...])
  90   AC_MSG_NOTICE([... cross-compilation: finished self-configuring for build platform tools])
  91   AC_MSG_NOTICE([...])
  92
  93   build_clippy="false"
  94   hosttools_clippy="true"
  95   CLIPPY="hosttools/lib/clippy"
  96
  97 dnl case 3: normal build internal clippy
  98 else
  99   CLIPPY="lib/clippy\$(EXEEXT)"
 100 fi
 101 AC_SUBST([CLIPPY])
 102 AM_CONDITIONAL([BUILD_CLIPPY], [$build_clippy])
 103 AM_CONDITIONAL([HOSTTOOLS_CLIPPY], [$hosttools_clippy])
 104 AM_CONDITIONAL([ONLY_CLIPPY], [test "$enable_clippy_only" = "yes"])
 105
 106 # Disable portability warnings -- our automake code (in particular
 107 # common.am) uses some constructs specific to gmake.
 108 AM_INIT_AUTOMAKE([1.12 -Wno-portability foreign])
 109 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
 110 AM_SILENT_RULES([yes])
 111 AC_CONFIG_HEADERS([config.h])
 112
 113 AC_PATH_PROG([PERL], [perl])
 114 PKG_PROG_PKG_CONFIG
 115
 116 dnl default is to match previous behavior
 117 exampledir=${sysconfdir}
 118 AC_ARG_ENABLE([exampledir],
 119           AS_HELP_STRING([--enable-exampledir],
 120                          [specify alternate directory for examples]),
 121                          exampledir="$enableval",)
 122 dnl XXX add --exampledir to autoconf standard directory list somehow
 123 AC_SUBST([exampledir])
 124
 125 dnl default is to match previous behavior
 126 pkgsrcrcdir=""
 127 AC_ARG_ENABLE([pkgsrcrcdir],
 128           AS_HELP_STRING([--enable-pkgsrcrcdir],
 129                          [specify directory for rc.d scripts]),
 130                          pkgsrcrcdir="$enableval",)
 131 dnl XXX add --pkgsrcrcdir to autoconf standard directory list somehow
 132 AC_SUBST([pkgsrcrcdir])
 133 AM_CONDITIONAL([PKGSRC], [test "$pkgsrcrcdir" != ""])
 134
 135 AC_ARG_WITH([moduledir], [AS_HELP_STRING([--with-moduledir=DIR], [module directory (${libdir}/frr/modules)])], [
 136         moduledir="$withval"
 137 ], [
 138         moduledir="\${libdir}/frr/modules"
 139 ])
 140 AC_SUBST([moduledir], [$moduledir])
 141
 142 AC_ARG_WITH([scriptdir], [AS_HELP_STRING([--with-scriptdir=DIR], [script directory (${sysconfdir}/scripts)])], [
 143         scriptdir="$withval"
 144 ], [
 145         scriptdir="\${sysconfdir}/scripts"
 146 ])
 147 AC_SUBST([scriptdir], [$scriptdir])
 148
 149 AC_ARG_WITH([yangmodelsdir], [AS_HELP_STRING([--with-yangmodelsdir=DIR], [yang models directory (${datarootdir}/yang)])], [
 150         yangmodelsdir="$withval"
 151 ], [
 152         yangmodelsdir="\${datarootdir}/yang"
 153 ])
 154 AC_SUBST([yangmodelsdir])
 155
 156 AC_ARG_WITH([vici-socket], [AS_HELP_STRING([--with-vici-socket=PATH], [vici-socket (/var/run/charon.vici)])], [
 157         vici_socket="$withval"
 158 ], [
 159         vici_socket="/var/run/charon.vici"
 160 ])
 161 AC_DEFINE_UNQUOTED([VICI_SOCKET], ["$vici_socket"], [StrongSWAN vici socket path])
 162
 163 AC_ARG_ENABLE(tcmalloc,
 164         AS_HELP_STRING([--enable-tcmalloc], [Turn on tcmalloc]),
 165 [case "${enableval}" in
 166   yes) tcmalloc_enabled=true
 167 LIBS="$LIBS -ltcmalloc_minimal"
 168  ;;
 169   no)  tcmalloc_enabled=false ;;
 170   *) AC_MSG_ERROR([bad value ${enableval} for --enable-tcmalloc]) ;;
 171 esac],[tcmalloc_enabled=false])
 172
 173
 174 dnl Thanks autoconf, but we don't want a default -g -O2.  We have our own
 175 dnl flag determination logic.
 176 CFLAGS="${CFLAGS:-}"
 177
 178 dnl --------------------
 179 dnl Check CC and friends
 180 dnl --------------------
 181 dnl note orig_cflags is also used further down
 182 orig_cflags="$CFLAGS"
 183 orig_cxxflags="$CXXFLAGS"
 184 AC_LANG([C])
 185 AC_PROG_CC
 186 AC_PROG_CPP
 187 AC_PROG_CXX
 188 AM_PROG_CC_C_O
 189 dnl remove autoconf default "-g -O2"
 190 CFLAGS="$orig_cflags"
 191 CXXFLAGS="$orig_cxxflags"
 192 AC_PROG_CC_C99
 193 dnl NB: see C11 below
 194
 195 dnl Some special handling for ICC later on
 196 if test "$CC" = "icc"; then
 197     cc_is_icc="yes"
 198 fi
 199
 200 PKG_PROG_PKG_CONFIG
 201
 202 dnl it's 2019, sed is sed.
 203 SED=sed
 204 AC_SUBST([SED])
 205
 206 dnl try and enable CFLAGS that are useful for FRR
 207 dnl - specifically, options to control warnings
 208
 209 AC_SUBST([AC_CFLAGS])
 210 AC_USE_SYSTEM_EXTENSIONS
 211 AC_DEFUN([AC_C_FLAG], [{
 212     m4_pushdef([cachename],[m4_translit([frr_cv_$1],[ =-+/{}$],[________])])
 213     AC_CACHE_CHECK([[whether $CC supports $1]], cachename, [
 214         AC_LANG_PUSH([C])
 215         ac_c_flag_save="$CFLAGS"
 216         CFLAGS="$CFLAGS $1"
 217         AC_COMPILE_IFELSE(
 218                 [AC_LANG_PROGRAM([[$4]])],
 219                 [
 220                         cachename=yes
 221                 ], [
 222                         cachename=no
 223                 ])
 224         CFLAGS="$ac_c_flag_save"
 225         AC_LANG_POP([C])
 226     ])
 227     if test "$cachename" = "yes"; then
 228         m4_if([$3], [], [AC_CFLAGS="$AC_CFLAGS $1"], [$3])
 229     else
 230         :
 231         $2
 232     fi
 233     m4_popdef([cachename])
 234 }])
 235
 236 AC_DEFUN([AC_LINK_IFELSE_FLAGS], [{
 237         AC_LANG_PUSH([C])
 238         ac_cflags_save="$CFLAGS"
 239         ac_libs_save="$LIBS"
 240         CFLAGS="$CFLAGS $1"
 241         LIBS="$LIBS $2"
 242         AC_LINK_IFELSE(
 243                 [$3],
 244                 [
 245                         CFLAGS="$ac_cflags_save"
 246                         LIBS="$ac_libs_save"
 247                         m4_default([$5], [
 248                                 AC_MSG_RESULT([yes])
 249                         ])
 250                 ], [
 251                         CFLAGS="$ac_cflags_save"
 252                         LIBS="$ac_libs_save"
 253                         m4_default([$4], [
 254                                 AC_MSG_RESULT([no])
 255                         ])
 256                 ])
 257         AC_LANG_POP([C])
 258         }])
 259
 260 dnl ICC won't bail on unknown options without -diag-error 10006
 261 dnl need to do this first so we get useful results for the other options
 262 if test "$cc_is_icc" = "yes"; then
 263     AC_C_FLAG([-diag-error 10006])
 264 fi
 265
 266 dnl AC_PROG_CC_C99 may change CC to include -std=gnu99 or something
 267 ac_cc="$CC"
 268 CC="${CC% -std=gnu99}"
 269 CC="${CC% -std=c99}"
 270
 271 AC_C_FLAG([-std=gnu11], [CC="$ac_cc"], [CC="$CC -std=gnu11"])
 272
 273 dnl if the user has specified any CFLAGS, override our settings
 274 if test "$enable_gcov" = "yes"; then
 275    if test "$orig_cflags" = ""; then
 276       AC_C_FLAG([-coverage])
 277       AC_C_FLAG([-O0])
 278    fi
 279
 280    AC_LDFLAGS="${AC_LDFLAGS} -lgcov"
 281 fi
 282
 283 if test "$enable_clang_coverage" = "yes"; then
 284    AC_C_FLAG([-fprofile-instr-generate], [
 285      AC_MSG_ERROR([$CC does not support -fprofile-instr-generate.])
 286    ])
 287    AC_C_FLAG([-fcoverage-mapping], [
 288      AC_MSG_ERROR([$CC does not support -fcoverage-mapping.])
 289    ])
 290 fi
 291
 292 if test "$enable_scripting" = "yes"; then
 293    AX_PROG_LUA([5.3], [5.4], [], [
 294      AC_MSG_ERROR([Lua 5.3 is required to build with Lua support. No other version is supported.])
 295    ])
 296    AX_LUA_HEADERS([], [
 297      AC_MSG_ERROR([Lua 5.3 headers are required to build with Lua support. No other version is supported.])
 298    ])
 299    AX_LUA_LIBS([
 300      AC_DEFINE([HAVE_SCRIPTING], [1], [Have support for scripting])
 301      LIBS="$LIBS $LUA_LIB"
 302    ], [
 303      AC_MSG_ERROR([Lua 5.3 libraries are required to build with Lua support. No other version is supported.])
 304    ])
 305 fi
 306
 307 dnl the following flags go in CFLAGS rather than AC_CFLAGS since they make
 308 dnl sense to be overridden by the user
 309 if test "$enable_dev_build" = "yes"; then
 310    AC_DEFINE([DEV_BUILD], [1], [Build for development])
 311    if test "$orig_cflags" = ""; then
 312       AC_C_FLAG([-O0],,[CFLAGS="$CFLAGS -O0"])
 313       AC_C_FLAG([-g3],,[CFLAGS="$CFLAGS -g3"])
 314       AC_C_FLAG([-ggdb3],,[CFLAGS="$CFLAGS -ggdb3"])
 315    fi
 316 else
 317    if test "$orig_cflags" = ""; then
 318       AC_C_FLAG([-g],,[CFLAGS="$CFLAGS -g"])
 319       AC_C_FLAG([-O2],,[CFLAGS="$CFLAGS -O2"])
 320    fi
 321 fi
 322
 323 AM_CONDITIONAL([DEV_BUILD], [test "$enable_dev_build" = "yes"])
 324
 325 dnl always want these CFLAGS
 326 AC_C_FLAG([-fno-omit-frame-pointer])
 327 AC_C_FLAG([-funwind-tables])
 328 AC_C_FLAG([-Wall])
 329 AC_C_FLAG([-Wextra])
 330 AC_C_FLAG([-Wmissing-prototypes])
 331 AC_C_FLAG([-Wmissing-declarations])
 332 AC_C_FLAG([-Wpointer-arith])
 333 AC_C_FLAG([-Wbad-function-cast])
 334 AC_C_FLAG([-Wwrite-strings])
 335 AC_C_FLAG([-Wundef])
 336 if test "$enable_gcc_ultra_verbose" = "yes" ; then
 337   AC_C_FLAG([-Wcast-qual])
 338   AC_C_FLAG([-Wstrict-prototypes])
 339   AC_C_FLAG([-Wmissing-noreturn])
 340   AC_C_FLAG([-Wmissing-format-attribute])
 341   AC_C_FLAG([-Wunreachable-code])
 342   AC_C_FLAG([-Wpacked])
 343   AC_C_FLAG([-Wpadded])
 344   AC_C_FLAG([-Wshadow])
 345 else
 346   AC_C_FLAG([-Wno-unused-result])
 347 fi
 348 AC_C_FLAG([-Wno-unused-parameter])
 349 AC_C_FLAG([-Wno-missing-field-initializers])
 350
 351 AC_C_FLAG([-Wc++-compat], [], [CXX_COMPAT_CFLAGS="-Wc++-compat"])
 352 AC_SUBST([CXX_COMPAT_CFLAGS])
 353
 354 dnl ICC emits a broken warning for const char *x = a ? "b" : "c";
 355 dnl for some reason the string consts get 'promoted' to char *,
 356 dnl triggering a const to non-const conversion warning.
 357 if test "$cc_is_icc" = "yes"; then
 358     AC_C_FLAG([-diag-disable 3179])
 359 fi
 360
 361 if test "$enable_werror" = "yes" ; then
 362   WERROR="-Werror"
 363 fi
 364 AC_SUBST([WERROR])
 365
 366 SAN_FLAGS=""
 367 if test "$enable_address_sanitizer" = "yes"; then
 368   AC_C_FLAG([-fsanitize=address], [
 369     AC_MSG_ERROR([$CC does not support Address Sanitizer.])
 370   ], [
 371     SAN_FLAGS="$SAN_FLAGS -fsanitize=address"
 372   ])
 373 fi
 374 if test "$enable_thread_sanitizer" = "yes"; then
 375   AC_C_FLAG([-fsanitize=thread], [
 376     AC_MSG_ERROR([$CC does not support Thread Sanitizer.])
 377   ], [
 378     SAN_FLAGS="$SAN_FLAGS -fsanitize=thread"
 379   ])
 380 fi
 381 if test "$enable_memory_sanitizer" = "yes"; then
 382   AC_C_FLAG([-fsanitize=memory -fPIE -pie], [
 383     AC_MSG_ERROR([$CC does not support Memory Sanitizer.])
 384   ], [
 385     SAN_FLAGS="$SAN_FLAGS -fsanitize=memory -fPIE -pie"
 386   ])
 387 fi
 388 if test "$enable_undefined_sanitizer" = "yes"; then
 389   AC_C_FLAG([-fsanitize=undefined], [
 390     AC_MSG_ERROR([$CC does not support UndefinedBehaviorSanitizer.])
 391   ], [
 392     SAN_FLAGS="$SAN_FLAGS -fsanitize=undefined"
 393   ])
 394 fi
 395 AC_SUBST([SAN_FLAGS])
 396
 397 dnl frr-format.so
 398 if test "$with_frr_format" != "no" -a "$with_frr_format" != "yes" -a -n "$with_frr_format"; then
 399   AC_C_FLAG([-fplugin=${with_frr_format}], [
 400     AC_MSG_ERROR([specified frr-format plugin ($with_frr_format) does not work])
 401   ],,[
 402 #ifndef _FRR_ATTRIBUTE_PRINTFRR
 403 #error plugin not loaded
 404 #endif
 405 #if _FRR_ATTRIBUTE_PRINTFRR < 0x10000
 406 #error plugin too old
 407 #endif
 408   ])
 409 elif test "$with_frr_format" = "no"; then
 410   : #nothing
 411 else
 412   AC_C_FLAG([-fplugin=tools/gcc-plugins/frr-format.so],[
 413     AC_C_FLAG([-fplugin=frr-format],[
 414       if test "$with_frr_format" = "yes"; then
 415         AC_MSG_ERROR([frr-format plugin requested but not found])
 416       fi
 417     ],,[
 418 #ifndef _FRR_ATTRIBUTE_PRINTFRR
 419 #error plugin not loaded
 420 #endif
 421 #if _FRR_ATTRIBUTE_PRINTFRR < 0x10000
 422 #error plugin too old
 423 #endif
 424     ])
 425   ],,[
 426 #ifndef _FRR_ATTRIBUTE_PRINTFRR
 427 #error plugin not loaded
 428 #endif
 429 #if _FRR_ATTRIBUTE_PRINTFRR < 0x10000
 430 #error plugin too old
 431 #endif
 432   ])
 433 fi
 434
 435 AC_MSG_CHECKING([whether linker supports __start/stop_section symbols])
 436 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 437 #include <stdio.h>
 438 int __attribute__((section("secttest"))) var = 1;
 439 extern int __start_secttest, __stop_secttest;
 440 ]], [[
 441   void *a = &var, *b = &__start_secttest, *c = &__stop_secttest;
 442   printf("%p %p %p\n", a, b, c);
 443 ]])], [
 444   AC_MSG_RESULT(yes)
 445   AC_DEFINE(HAVE_SECTION_SYMS, 1, [have __start/stop_section symbols])
 446 ], [
 447   AC_MSG_RESULT(no)
 448 ])
 449
 450 dnl ----------
 451 dnl Essentials
 452 dnl ----------
 453
 454 AX_PTHREAD([
 455   CC="$PTHREAD_CC"
 456   AC_CFLAGS="$AC_CFLAGS $PTHREAD_CFLAGS"
 457   LIBS="$PTHREAD_LIBS $LIBS"
 458 ], [
 459   AC_MSG_FAILURE([This FRR version needs pthreads])
 460 ])
 461
 462 orig_cflags="$CFLAGS"
 463 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 464
 465 AC_SEARCH_LIBS([pthread_condattr_setclock], [],
 466                 [frr_cv_pthread_condattr_setclock=yes],
 467                 [frr_cv_pthread_condattr_setclock=no])
 468 if test "$frr_cv_pthread_condattr_setclock" = "yes"; then
 469   AC_DEFINE([HAVE_PTHREAD_CONDATTR_SETCLOCK], [1], [Have pthread.h pthread_condattr_setclock])
 470 fi
 471
 472 AC_CHECK_HEADERS([pthread_np.h],,, [
 473 #include <pthread.h>
 474 ])
 475 AC_CHECK_FUNCS([pthread_setname_np pthread_set_name_np pthread_getthreadid_np])
 476
 477 CFLAGS="$orig_cflags"
 478
 479 dnl --------------
 480 dnl Check programs
 481 dnl --------------
 482 AC_PROG_INSTALL
 483 AC_PROG_LN_S
 484 AC_CHECK_TOOL([AR], [ar])
 485
 486 dnl -------
 487 dnl libtool
 488 dnl -------
 489 AC_ARG_ENABLE([static-bin],
 490   AS_HELP_STRING([--enable-static-bin], [link binaries statically]))
 491 LT_INIT
 492 _LT_CONFIG_LIBTOOL([
 493   patch -N -i "${srcdir}/m4/libtool-whole-archive.patch" libtool >&AS_MESSAGE_LOG_FD || \
 494     AC_MSG_WARN([Could not patch libtool for static linking support.  Loading modules into a statically linked daemon will fail.])
 495   sed -e 's%func_warning "relinking%true #\0%' -i libtool || true
 496   sed -e 's%func_warning "remember to run%true #\0%' -i libtool || true
 497   sed -e 's%func_warning ".*has not been installed in%true #\0%' -i libtool || true
 498 ])
 499 if test "$enable_static_bin" = "yes"; then
 500   AC_LDFLAGS="-static"
 501   if test "$enable_static" != "yes"; then
 502     AC_MSG_ERROR([The --enable-static-bin option must be combined with --enable-static.])
 503   fi
 504 fi
 505 if test "$enable_shared" != "yes"; then
 506   AC_MSG_ERROR([FRR cannot be built with --disable-shared.  If you want statically linked daemons, use --enable-shared --enable-static --enable-static-bin])
 507 fi
 508 AC_SUBST([AC_LDFLAGS])
 509 AM_CONDITIONAL([STATIC_BIN], [test "$enable_static_bin" = "yes"])
 510
 511 AC_ARG_ENABLE([rpath],
 512   [AS_HELP_STRING([--enable-rpath], [set hardcoded rpaths in the executable @<:@default=yes@:>@])],
 513   [],
 514   [enable_rpath=yes])
 515
 516 dnl $AR and $RANLIB are set by LT_INIT above
 517 AC_MSG_CHECKING([whether $AR supports D option])
 518 if $AR crD conftest.a >/dev/null 2>/dev/null; then
 519   AC_MSG_RESULT([yes])
 520   dnl ARFLAGS is for automake, AR_FLAGS for libtool m-(
 521   ARFLAGS="crD"
 522   AR_FLAGS="crD"
 523 else
 524   AC_MSG_RESULT([no])
 525   ARFLAGS="cru"
 526   AR_FLAGS="cru"
 527 fi
 528 AC_SUBST([ARFLAGS])
 529 AC_SUBST([AR_FLAGS])
 530
 531 AC_MSG_CHECKING([whether $RANLIB supports D option])
 532 if $RANLIB -D conftest.a >conftest.err 2>&1; then
 533   if grep -q -- '-D' conftest.err; then
 534     AC_MSG_RESULT([no])
 535   else
 536     AC_MSG_RESULT([yes])
 537     RANLIB="$RANLIB -D"
 538   fi
 539 else
 540   AC_MSG_RESULT([no])
 541 fi
 542 AC_SUBST([RANLIB])
 543
 544 test -f conftest.err && rm conftest.err
 545 test -f conftest.a && rm conftest.a
 546
 547 dnl ----------------------
 548 dnl Packages configuration
 549 dnl ----------------------
 550 if test -f config.version; then
 551   . ./config.version
 552 elif test -f "${srcdir}/config.version"; then
 553   . "${srcdir}/config.version"
 554 fi
 555 AC_ARG_WITH([pkg-extra-version],
 556   AS_HELP_STRING([--with-pkg-extra-version=VER], [add extra version field, for packagers/distributions]), [
 557   if test "$withval" = "no"; then
 558     EXTRAVERSION=
 559   else
 560     EXTRAVERSION=$withval
 561   fi
 562 ], [])
 563 AC_ARG_WITH([pkg-git-version],
 564         AS_HELP_STRING([--with-pkg-git-version], [add git information to MOTD and build version string]),
 565         [ test "$withval" != "no" && with_pkg_git_version="yes" ])
 566 AC_ARG_WITH([clippy],
 567   AS_HELP_STRING([--with-clippy=PATH], [use external clippy helper program]))
 568 AC_ARG_WITH([vtysh_pager],
 569         AS_HELP_STRING([--with-vtysh-pager=PAGER], [control what pager is compiled in as default]),
 570         VTYSH_PAGER=$withval, VTYSH_PAGER="more")
 571 AC_ARG_ENABLE([vtysh],
 572   AS_HELP_STRING([--disable-vtysh], [do not build integrated vty shell for FRR]))
 573 AC_ARG_ENABLE([doc],
 574   AS_HELP_STRING([--disable-doc], [do not build docs]))
 575 AC_ARG_ENABLE([doc-html],
 576   AS_HELP_STRING([--enable-doc-html], [build HTML docs]))
 577 AC_ARG_ENABLE([zebra],
 578   AS_HELP_STRING([--disable-zebra], [do not build zebra daemon]))
 579 AC_ARG_ENABLE([bgpd],
 580   AS_HELP_STRING([--disable-bgpd], [do not build bgpd]))
 581 AC_ARG_ENABLE([ripd],
 582   AS_HELP_STRING([--disable-ripd], [do not build ripd]))
 583 AC_ARG_ENABLE([ripngd],
 584   AS_HELP_STRING([--disable-ripngd], [do not build ripngd]))
 585 AC_ARG_ENABLE([ospfd],
 586   AS_HELP_STRING([--disable-ospfd], [do not build ospfd]))
 587 AC_ARG_ENABLE([ospf6d],
 588   AS_HELP_STRING([--disable-ospf6d], [do not build ospf6d]))
 589 AC_ARG_ENABLE([ldpd],
 590   AS_HELP_STRING([--disable-ldpd], [do not build ldpd]))
 591 AC_ARG_ENABLE([nhrpd],
 592   AS_HELP_STRING([--disable-nhrpd], [do not build nhrpd]))
 593 AC_ARG_ENABLE([eigrpd],
 594   AS_HELP_STRING([--disable-eigrpd], [do not build eigrpd]))
 595 AC_ARG_ENABLE([babeld],
 596   AS_HELP_STRING([--disable-babeld], [do not build babeld]))
 597 AC_ARG_ENABLE([watchfrr],
 598   AS_HELP_STRING([--disable-watchfrr], [do not build watchfrr]))
 599 AC_ARG_ENABLE([isisd],
 600   AS_HELP_STRING([--disable-isisd], [do not build isisd]))
 601 AC_ARG_ENABLE([pimd],
 602   AS_HELP_STRING([--disable-pimd], [do not build pimd]))
 603 AC_ARG_ENABLE([pbrd],
 604   AS_HELP_STRING([--disable-pbrd], [do not build pbrd]))
 605 AC_ARG_ENABLE([sharpd],
 606   AS_HELP_STRING([--enable-sharpd], [build sharpd]))
 607 AC_ARG_ENABLE([staticd],
 608   AS_HELP_STRING([--disable-staticd], [do not build staticd]))
 609 AC_ARG_ENABLE([fabricd],
 610   AS_HELP_STRING([--disable-fabricd], [do not build fabricd]))
 611 AC_ARG_ENABLE([vrrpd],
 612   AS_HELP_STRING([--disable-vrrpd], [do not build vrrpd]))
 613 AC_ARG_ENABLE([pathd],
 614   AS_HELP_STRING([--disable-pathd], [do not build pathd]))
 615 AC_ARG_ENABLE([bgp-announce],
 616   AS_HELP_STRING([--disable-bgp-announce], [turn off BGP route announcement]))
 617 AC_ARG_ENABLE([bgp-vnc],
 618   AS_HELP_STRING([--disable-bgp-vnc],[turn off BGP VNC support]))
 619 AC_ARG_ENABLE([bgp-bmp],
 620   AS_HELP_STRING([--disable-bgp-bmp],[turn off BGP BMP support]))
 621 AC_ARG_ENABLE([snmp],
 622   AS_HELP_STRING([--enable-snmp], [enable SNMP support for agentx]))
 623 AC_ARG_ENABLE([config_rollbacks],
 624   AS_HELP_STRING([--enable-config-rollbacks], [enable configuration rollbacks (requires sqlite3)]))
 625 AC_ARG_ENABLE([confd],
 626   AS_HELP_STRING([--enable-confd=ARG], [enable confd integration]))
 627 AC_ARG_ENABLE([sysrepo],
 628   AS_HELP_STRING([--enable-sysrepo], [enable sysrepo integration]))
 629 AC_ARG_ENABLE([grpc],
 630   AS_HELP_STRING([--enable-grpc], [enable the gRPC northbound plugin]))
 631 AC_ARG_ENABLE([zeromq],
 632   AS_HELP_STRING([--enable-zeromq], [enable ZeroMQ handler (libfrrzmq)]))
 633 AC_ARG_ENABLE([lttng],
 634   AS_HELP_STRING([--enable-lttng], [enable LTTng tracing]))
 635 AC_ARG_ENABLE([usdt],
 636   AS_HELP_STRING([--enable-usdt], [enable USDT probes]))
 637 AC_ARG_WITH([libpam],
 638   AS_HELP_STRING([--with-libpam], [use libpam for PAM support in vtysh]))
 639 AC_ARG_ENABLE([ospfapi],
 640   AS_HELP_STRING([--disable-ospfapi], [do not build OSPFAPI to access the OSPF LSA Database]))
 641 AC_ARG_ENABLE([ospfclient],
 642   AS_HELP_STRING([--disable-ospfclient], [do not build OSPFAPI client for OSPFAPI,
 643                           (this is the default if --disable-ospfapi is set)]))
 644 AC_ARG_ENABLE([multipath],
 645   AS_HELP_STRING([--enable-multipath=ARG], [enable multipath function, ARG must be digit]))
 646 AC_ARG_ENABLE([user],
 647   AS_HELP_STRING([--enable-user=USER], [user to run FRR suite as (default frr)]))
 648 AC_ARG_ENABLE([group],
 649   AS_HELP_STRING([--enable-group=GROUP], [group to run FRR suite as (default frr)]))
 650 AC_ARG_ENABLE([vty_group],
 651   AS_HELP_STRING([--enable-vty-group=ARG], [set vty sockets to have specified group as owner]))
 652 AC_ARG_ENABLE([configfile_mask],
 653   AS_HELP_STRING([--enable-configfile-mask=ARG], [set mask for config files]))
 654 AC_ARG_ENABLE([logfile_mask],
 655   AS_HELP_STRING([--enable-logfile-mask=ARG], [set mask for log files]))
 656 AC_ARG_ENABLE([shell_access],
 657   AS_HELP_STRING([--enable-shell-access], [Allow users to access shell/telnet/ssh]))
 658 AC_ARG_ENABLE([realms],
 659   AS_HELP_STRING([--enable-realms], [enable REALMS support under Linux]))
 660 AC_ARG_ENABLE([rtadv],
 661   AS_HELP_STRING([--disable-rtadv], [disable IPV6 router advertisement feature]))
 662 AC_ARG_ENABLE([irdp],
 663   AS_HELP_STRING([--disable-irdp], [disable IRDP server support in zebra (enabled by default if supported)]))
 664 AC_ARG_ENABLE([capabilities],
 665   AS_HELP_STRING([--disable-capabilities], [disable using POSIX capabilities]))
 666 AC_ARG_ENABLE([rusage],
 667   AS_HELP_STRING([--disable-rusage], [disable using getrusage]))
 668 AC_ARG_ENABLE([gcc_ultra_verbose],
 669   AS_HELP_STRING([--enable-gcc-ultra-verbose], [enable ultra verbose GCC warnings]))
 670 AC_ARG_ENABLE([backtrace],
 671   AS_HELP_STRING([--disable-backtrace], [disable crash backtraces (default autodetect)]))
 672 AC_ARG_ENABLE([time-check],
 673   AS_HELP_STRING([--disable-time-check], [disable slow thread warning messages]))
 674 AC_ARG_ENABLE([cpu-time],
 675   AS_HELP_STRING([--disable-cpu-time], [disable cpu usage data gathering]))
 676 AC_ARG_ENABLE([pcreposix],
 677   AS_HELP_STRING([--enable-pcreposix], [enable using PCRE Posix libs for regex functions]))
 678 AC_ARG_ENABLE([fpm],
 679   AS_HELP_STRING([--enable-fpm], [enable Forwarding Plane Manager support]))
 680 AC_ARG_ENABLE([pcep],
 681   AS_HELP_STRING([--enable-pcep], [enable PCEP support for pathd]))
 682 AC_ARG_ENABLE([systemd],
 683   AS_HELP_STRING([--enable-systemd], [enable Systemd support]))
 684 AC_ARG_ENABLE([werror],
 685   AS_HELP_STRING([--enable-werror], [enable -Werror (recommended for developers only)]))
 686 AC_ARG_ENABLE([cumulus],
 687   AS_HELP_STRING([--enable-cumulus], [enable Cumulus Switch Special Extensions]))
 688 AC_ARG_ENABLE([datacenter],
 689   AS_HELP_STRING([--enable-datacenter], [enable Compilation for Data Center Extensions]))
 690 AC_ARG_ENABLE([rr-semantics],
 691   AS_HELP_STRING([--disable-rr-semantics], [disable the v6 Route Replace semantics]))
 692 AC_ARG_ENABLE([protobuf],
 693   AS_HELP_STRING([--enable-protobuf], [Enable experimental protobuf support]))
 694 AC_ARG_ENABLE([oldvpn_commands],
 695   AS_HELP_STRING([--enable-oldvpn-commands], [Keep old vpn commands]))
 696 AC_ARG_ENABLE([rpki],
 697   AS_HELP_STRING([--enable-rpki], [enable RPKI prefix validation support]))
 698 AC_ARG_ENABLE([clippy-only],
 699   AS_HELP_STRING([--enable-clippy-only], [Only build clippy]))
 700 AC_ARG_ENABLE([numeric_version],
 701   AS_HELP_STRING([--enable-numeric-version], [Only numeric digits allowed in version (for Alpine)]))
 702 AC_ARG_ENABLE([gcov],
 703   AS_HELP_STRING([--enable-gcov], [Collect coverage information with gcov]))
 704 AC_ARG_ENABLE([clang_coverage],
 705   AS_HELP_STRING([--enable-clang-coverage], [Collect coverage information with Clang Coverage]))
 706 AC_ARG_ENABLE([bfdd],
 707   AS_HELP_STRING([--disable-bfdd], [do not build bfdd]))
 708 AC_ARG_ENABLE([address-sanitizer],
 709   AS_HELP_STRING([--enable-address-sanitizer], [enable AddressSanitizer support for detecting a wide variety of memory allocation and deallocation errors]))
 710 AC_ARG_ENABLE([thread-sanitizer],
 711   AS_HELP_STRING([--enable-thread-sanitizer], [enable ThreadSanitizer support for detecting data races]))
 712 AC_ARG_ENABLE([memory-sanitizer],
 713   AS_HELP_STRING([--enable-memory-sanitizer], [enable MemorySanitizer support for detecting uninitialized memory reads]))
 714 AC_ARG_ENABLE([undefined-sanitizer],
 715   AS_HELP_STRING([--undefined-sanitizer], [enable UndefinedBehaviorSanitizer support for detecting undefined behavior]))
 716 AC_ARG_WITH([crypto],
 717   AS_HELP_STRING([--with-crypto=<internal|openssl>], [choose between different implementations of cryptographic functions(default value is --with-crypto=internal)]))
 718 AC_ARG_WITH([frr-format],
 719   AS_HELP_STRING([--with-frr-format[=<.../frr-format.so>]], [use frr-format GCC plugin]))
 720
 721 AC_ARG_ENABLE([version-build-config],
 722   AS_HELP_STRING([--disable-version-build-config], [do not include build configs in show version command]))
 723
 724 #if openssl, else use the internal
 725 AS_IF([test "$with_crypto" = "openssl"], [
 726 AC_CHECK_LIB([crypto], [EVP_DigestInit], [LIBS="$LIBS -lcrypto"], [], [])
 727 if test "$ac_cv_lib_crypto_EVP_DigestInit" = "no"; then
 728   AC_MSG_ERROR([build with openssl has been specified but openssl library was not found on your system])
 729 else
 730   AC_DEFINE([CRYPTO_OPENSSL], [1], [Compile with openssl support])
 731 fi
 732 ], [test "$with_crypto" = "internal" || test "$with_crypto" = "" ], [AC_DEFINE([CRYPTO_INTERNAL], [1], [Compile with internal cryptographic implementation])
 733 ], [AC_MSG_ERROR([Unknown value for --with-crypto])]
 734 )
 735
 736 AS_IF([test "$enable_clippy_only" != "yes"], [
 737 AC_CHECK_HEADERS([json-c/json.h])
 738 AC_CHECK_LIB([json-c], [json_object_get], [LIBS="$LIBS -ljson-c"], [], [-lm])
 739 if test "$ac_cv_lib_json_c_json_object_get" = "no"; then
 740   AC_CHECK_LIB([json], [json_object_get], [LIBS="$LIBS -ljson"])
 741   if test "$ac_cv_lib_json_json_object_get" = "no"; then
 742       AC_MSG_ERROR([libjson is needed to compile])
 743   fi
 744 fi
 745 ])
 746
 747 AC_ARG_ENABLE([dev_build],
 748     AS_HELP_STRING([--enable-dev-build], [build for development]))
 749
 750 AC_ARG_ENABLE([scripting],
 751     AS_HELP_STRING([--enable-scripting], [Build with scripting support]))
 752
 753 AC_ARG_ENABLE([netlink-debug],
 754   AS_HELP_STRING([--disable-netlink-debug], [pretty print netlink debug messages]))
 755
 756 if test "$enable_netlink_debug" != "no" ; then
 757   AC_DEFINE([NETLINK_DEBUG], [1], [Netlink extra debugging code])
 758 fi
 759
 760 AM_CONDITIONAL([NETLINK_DEBUG], [test "$enable_netlink_debug" != "no"])
 761
 762 if test "$enable_time_check" != "no" ; then
 763   if test "$enable_time_check" = "yes" -o "$enable_time_check" = "" ; then
 764     AC_DEFINE([CONSUMED_TIME_CHECK], [5000000], [Consumed Time Check])
 765   else
 766     AC_DEFINE_UNQUOTED([CONSUMED_TIME_CHECK], [$enable_time_check], [Consumed Time Check])
 767   fi
 768 fi
 769
 770 case "${enable_cpu_time}" in
 771   "no")
 772   AC_DEFINE([EXCLUDE_CPU_TIME], [1], [Exclude getrusage data gathering])
 773   ;;
 774   "*")
 775   ;;
 776 esac
 777
 778 case "${enable_systemd}" in
 779   "no") ;;
 780   "yes")
 781   AC_CHECK_LIB([systemd], [sd_notify], [LIBS="$LIBS -lsystemd"])
 782   if test "$ac_cv_lib_systemd_sd_notify" = "no"; then
 783     AC_MSG_ERROR([enable systemd has been specified but systemd development env not found on your system])
 784   else
 785     AC_DEFINE([HAVE_SYSTEMD], [1], [Compile systemd support in])
 786   fi
 787   ;;
 788   "*") ;;
 789 esac
 790
 791 if test "$enable_rr_semantics" != "no" ; then
 792   AC_DEFINE([HAVE_V6_RR_SEMANTICS], [1], [Compile in v6 Route Replacement Semantics])
 793 fi
 794
 795 if test "$enable_datacenter" = "yes" ; then
 796   AC_DEFINE([HAVE_DATACENTER], [1], [Compile extensions for a DataCenter])
 797   AC_MSG_WARN([The --enable-datacenter compile time option is deprecated.  Please modify the init script to pass -F datacenter to the daemons instead.])
 798   DFLT_NAME="datacenter"
 799 else
 800   DFLT_NAME="traditional"
 801 fi
 802
 803 if test "$enable_cumulus" = "yes" ; then
 804   AC_DEFINE([HAVE_CUMULUS], [1], [Compile Special Cumulus Code in])
 805 fi
 806
 807 AC_SUBST([DFLT_NAME])
 808 AC_DEFINE_UNQUOTED([DFLT_NAME], ["$DFLT_NAME"], [Name of the configuration default set])
 809
 810 if test "$enable_shell_access" = "yes"; then
 811    AC_DEFINE([HAVE_SHELL_ACCESS], [1], [Allow user to use ssh/telnet/bash, be aware this is considered insecure])
 812 fi
 813
 814 #
 815 # Python for clippy
 816 #
 817
 818 AS_IF([test "$host" = "$build"], [
 819   AC_CHECK_HEADER([gelf.h], [], [
 820     AC_MSG_ERROR([libelf headers are required for building clippy.  (Host only when cross-compiling.)])
 821   ])
 822   AC_CHECK_LIB([elf], [elf_memory], [], [
 823     AC_MSG_ERROR([libelf is required for building clippy.  (Host only when cross-compiling.)])
 824   ])
 825
 826   AC_CHECK_LIB([elf], [elf_getdata_rawchunk], [
 827     AC_DEFINE([HAVE_ELF_GETDATA_RAWCHUNK], [1], [Have elf_getdata_rawchunk()])
 828   ])
 829   AC_CHECK_LIB([elf], [gelf_getnote], [
 830     AC_DEFINE([HAVE_GELF_GETNOTE], [1], [Have gelf_getnote()])
 831   ])
 832
 833   FRR_PYTHON_DEV
 834 ], [
 835   FRR_PYTHON
 836 ])
 837
 838 FRR_PYTHON_MODULES([pytest])
 839
 840 if test "$enable_doc" != "no"; then
 841   FRR_PYTHON_MODULES([sphinx], , [
 842     if test "$enable_doc" = "yes"; then
 843       AC_MSG_ERROR([Documentation was explicitly requested with --enable-doc but sphinx is not available for $PYTHON. Please disable docs or install sphinx.])
 844     fi
 845   ])
 846 fi
 847 AM_CONDITIONAL([DOC], [test "$enable_doc" != "no" -a "$frr_py_mod_sphinx" != "false"])
 848 AM_CONDITIONAL([DOC_HTML], [test "$enable_doc_html" = "yes"])
 849
 850 FRR_PYTHON_MOD_EXEC([sphinx], [--version], [
 851   PYSPHINX="-m sphinx"
 852 ], [
 853   PYSPHINX="-c 'import sys; from sphinx import main; sys.exit(main(sys.argv))'"
 854 ])
 855 AC_SUBST([PYSPHINX])
 856
 857 #
 858 # Logic for old vpn commands support.
 859 #
 860 if test "$enable_oldvpn_commands" = "yes"; then
 861    AC_DEFINE([KEEP_OLD_VPN_COMMANDS], [1], [Define for compiling with old vpn commands])
 862 fi
 863
 864 #
 865 # End of logic for protobuf support.
 866 #
 867
 868 AC_MSG_CHECKING([if zebra should be configurable to send Route Advertisements])
 869 if test "$enable_rtadv" != "no"; then
 870   AC_MSG_RESULT([yes])
 871   AC_DEFINE([HAVE_RTADV], [1], [Enable IPv6 Routing Advertisement support])
 872 else
 873   AC_MSG_RESULT([no])
 874 fi
 875
 876 if test "$enable_user" = "no"; then
 877   enable_user=""
 878 else
 879   if test "$enable_user" = "yes" || test "$enable_user" = ""; then
 880     enable_user="frr"
 881   fi
 882   AC_DEFINE_UNQUOTED([FRR_USER], ["${enable_user}"], [frr User])
 883 fi
 884
 885 if test "$enable_group" = "no"; then
 886   enable_group=""
 887 else
 888   if test "$enable_group" = "yes" || test "$enable_group" = ""; then
 889     enable_group="frr"
 890   fi
 891   AC_DEFINE_UNQUOTED([FRR_GROUP], ["${enable_group}"], [frr Group])
 892 fi
 893
 894 if test "$enable_vty_group" = "yes" ; then
 895   AC_MSG_ERROR([--enable-vty-group requires a group as argument, not yes])
 896 elif test "$enable_vty_group" != ""; then
 897   if test "$enable_vty_group" != "no"; then
 898     AC_DEFINE_UNQUOTED([VTY_GROUP], ["${enable_vty_group}"], [VTY Sockets Group])
 899   fi
 900 fi
 901 AC_SUBST([enable_user])
 902 AC_SUBST([enable_group])
 903 AC_SUBST([enable_vty_group])
 904
 905 enable_configfile_mask=${enable_configfile_mask:-0600}
 906 AC_DEFINE_UNQUOTED([CONFIGFILE_MASK], [${enable_configfile_mask}], [Mask for config files])
 907 AC_SUBST([enable_configfile_mask])
 908
 909 enable_logfile_mask=${enable_logfile_mask:-0600}
 910 AC_DEFINE_UNQUOTED([LOGFILE_MASK], [${enable_logfile_mask}], [Mask for log files])
 911
 912 MPATH_NUM=16
 913
 914 case "${enable_multipath}" in
 915   0)
 916     MPATH_NUM=64
 917     ;;
 918   [[1-9]|[1-9][0-9]|[1-9][0-9][0-9]])
 919     MPATH_NUM="${enable_multipath}"
 920     ;;
 921   "")
 922     ;;
 923   *)
 924     AC_MSG_FAILURE([Please specify digit to enable multipath ARG])
 925     ;;
 926 esac
 927
 928 AC_DEFINE_UNQUOTED([MULTIPATH_NUM], [$MPATH_NUM], [Maximum number of paths for a route])
 929
 930 AC_DEFINE_UNQUOTED([VTYSH_PAGER], ["$VTYSH_PAGER"], [What pager to use])
 931
 932 dnl --------------------
 933 dnl Enable code coverage
 934 dnl --------------------
 935 AM_CONDITIONAL([HAVE_GCOV], [test "$enable_gcov" != "no"])
 936
 937 dnl ------------------------------------
 938 dnl Alpine only accepts numeric versions
 939 dnl ------------------------------------
 940 if test "$enable_numeric_version" != "" ; then
 941   VERSION="`echo ${VERSION} | tr -c -d '[[.0-9]]'`"
 942   PACKAGE_VERSION="`echo ${PACKAGE_VERSION} | tr -c -d '[[.0-9]]'`"
 943 fi
 944
 945 dnl -----------------------------------
 946 dnl Add extra version string to package
 947 dnl name, string and version fields.
 948 dnl -----------------------------------
 949 if test "$EXTRAVERSION" != "" ; then
 950   VERSION="${VERSION}${EXTRAVERSION}"
 951   PACKAGE_VERSION="${PACKAGE_VERSION}${EXTRAVERSION}"
 952   AC_SUBST(PACKAGE_EXTRAVERSION, ["${EXTRAVERSION}"])
 953   PACKAGE_STRING="${PACKAGE_STRING}${EXTRAVERSION}"
 954 fi
 955 AC_SUBST([EXTRAVERSION])
 956
 957 if test "$with_pkg_git_version" = "yes"; then
 958         if test -e "${srcdir}/.git"; then
 959                 AC_DEFINE([GIT_VERSION], [1], [include git version info])
 960         else    with_pkg_git_version="no"
 961                 AC_MSG_WARN([--with-pkg-git-version given, but this is not a git checkout])
 962         fi
 963 fi
 964 AM_CONDITIONAL([GIT_VERSION], [test "$with_pkg_git_version" = "yes"])
 965
 966 AC_CHECK_TOOL([OBJCOPY], [objcopy], [:])
 967 if test "$OBJCOPY" != ":"; then
 968   AC_CACHE_CHECK([for .interp value to use], [frr_cv_interp], [
 969     frr_cv_interp=""
 970     AC_LINK_IFELSE([AC_LANG_SOURCE([[int main() { return 0; }]])], [
 971       if $OBJCOPY -j.interp -Obinary conftest conftest.interp; then
 972         frr_cv_interp="`xargs -0 echo < conftest.interp`"
 973       fi
 974       test -f conftest.interp && rm conftest.interp
 975     ])
 976   ])
 977 fi
 978 if test -n "$frr_cv_interp"; then
 979   AC_DEFINE_UNQUOTED([INTERP], ["$frr_cv_interp"], [.interp value])
 980 fi
 981
 982 dnl -------------------------
 983 dnl Check other header files.
 984 dnl -------------------------
 985 AC_CHECK_HEADERS([stropts.h sys/ksym.h \
 986         linux/version.h asm/types.h endian.h sys/endian.h])
 987
 988 ac_stdatomic_ok=false
 989 AC_DEFINE([FRR_AUTOCONF_ATOMIC], [1], [did autoconf checks for atomic funcs])
 990 AC_CHECK_HEADER([stdatomic.h],[
 991
 992   AC_MSG_CHECKING([whether _Atomic qualifier works])
 993   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 994 #include <stdatomic.h>
 995 int main(int argc, char **argv) {
 996   _Atomic int i = 0;
 997   return i;
 998 }
 999 ]])], [
1000     AC_DEFINE([HAVE_STDATOMIC_H], [1], [found stdatomic.h])
1001     AC_MSG_RESULT([yes])
1002     ac_stdatomic_ok=true
1003   ], [
1004     AC_MSG_RESULT([no])
1005   ])
1006 ])
1007
1008 AS_IF([$ac_stdatomic_ok], [true], [
1009   AC_MSG_CHECKING([for __atomic_* builtins])
1010   AC_LINK_IFELSE([AC_LANG_SOURCE([[
1011 int main(int argc, char **argv) {
1012   volatile int i = 1;
1013   __atomic_store_n (&i, 0, __ATOMIC_RELEASE);
1014   return __atomic_load_n (&i, __ATOMIC_ACQUIRE);
1015 }
1016 ]])], [
1017     AC_DEFINE([HAVE___ATOMIC], [1], [found __atomic builtins])
1018     AC_MSG_RESULT([yes])
1019   ], [
1020     AC_MSG_RESULT([no])
1021
1022     dnl FreeBSD 9 has a broken stdatomic.h where _Atomic doesn't work
1023     AC_MSG_CHECKING([for __sync_* builtins])
1024     AC_LINK_IFELSE([AC_LANG_SOURCE([[
1025 int main(int argc, char **argv) {
1026   volatile int i = 1;
1027   __sync_fetch_and_sub (&i, 1);
1028   return __sync_val_compare_and_swap (&i, 0, 1);
1029 }
1030 ]])], [
1031       AC_DEFINE([HAVE___SYNC], [1], [found __sync builtins])
1032       AC_MSG_RESULT([yes])
1033
1034       AC_MSG_CHECKING([for __sync_swap builtin])
1035       AC_LINK_IFELSE([AC_LANG_SOURCE([[
1036 int main(int argc, char **argv) {
1037   volatile int i = 1;
1038   return __sync_swap (&i, 2);
1039 }
1040 ]])], [
1041         AC_DEFINE([HAVE___SYNC_SWAP], 1, [found __sync_swap builtin])
1042         AC_MSG_RESULT([yes])
1043       ], [
1044         AC_MSG_RESULT([no])
1045       ])
1046
1047     ], [
1048       AC_MSG_RESULT([no])
1049       AC_MSG_FAILURE([stdatomic.h unavailable and $CC has neither __atomic nor __sync builtins])
1050     ])
1051   ])
1052 ])
1053
1054 needsync=true
1055
1056 AS_IF([$needsync], [
1057   dnl Linux
1058   AC_MSG_CHECKING([for Linux futex() support])
1059   AC_LINK_IFELSE([AC_LANG_PROGRAM([
1060 #ifndef _GNU_SOURCE
1061 #define _GNU_SOURCE
1062 #endif
1063 #include <unistd.h>
1064 #include <limits.h>
1065 #include <sys/time.h>
1066 #include <sys/syscall.h>
1067 #include <linux/futex.h>
1068
1069 int main(void);
1070 ],
1071 [
1072 {
1073   return syscall(SYS_futex, NULL, FUTEX_WAIT, 0, NULL, NULL, 0);
1074 }
1075 ])], [
1076     AC_MSG_RESULT([yes])
1077     AC_DEFINE(HAVE_SYNC_LINUX_FUTEX,,Have Linux futex support)
1078     needsync=false
1079   ], [
1080     AC_MSG_RESULT([no])
1081   ])
1082 ])
1083
1084 AS_IF([$needsync], [
1085   dnl FreeBSD
1086   AC_MSG_CHECKING([for FreeBSD _umtx_op() support])
1087   AC_LINK_IFELSE([AC_LANG_PROGRAM([
1088 #include <errno.h>
1089 #include <stdlib.h>
1090 #include <sys/types.h>
1091 #include <sys/umtx.h>
1092 int main(void);
1093 ],
1094 [
1095 {
1096   return _umtx_op(NULL, UMTX_OP_WAIT_UINT, 0, NULL, NULL);
1097 }
1098 ])], [
1099     AC_MSG_RESULT([yes])
1100     AC_DEFINE(HAVE_SYNC_UMTX_OP,,Have FreeBSD _umtx_op() support)
1101     needsync=false
1102   ], [
1103     AC_MSG_RESULT([no])
1104   ])
1105 ])
1106
1107 AS_IF([$needsync], [
1108   dnl OpenBSD patch (not upstream at the time of writing this)
1109   dnl https://marc.info/?l=openbsd-tech&m=147299508409549&w=2
1110   AC_MSG_CHECKING([for OpenBSD futex() support])
1111   AC_LINK_IFELSE([AC_LANG_PROGRAM([
1112 #include <sys/futex.h>
1113 int main(void);
1114 ],
1115 [
1116 {
1117   return futex(NULL, FUTEX_WAIT, 0, NULL, NULL, 0);
1118 }
1119 ])], [
1120     AC_MSG_RESULT([yes])
1121     AC_DEFINE(HAVE_SYNC_OPENBSD_FUTEX,,Have OpenBSD futex support)
1122     needsync=false
1123   ], [
1124     AC_MSG_RESULT([no])
1125   ])
1126 ])
1127
1128 dnl Utility macro to avoid retyping includes all the time
1129 m4_define([FRR_INCLUDES],
1130 [#ifdef SUNOS_5
1131 #define _POSIX_C_SOURCE 200809L
1132 #define __EXTENSIONS__
1133 #endif
1134 #include <stdio.h>
1135 #include <stdlib.h>
1136 #include <stddef.h>
1137 #include <sys/types.h>
1138 /* sys/conf.h depends on param.h on FBSD at least */
1139 #include <sys/param.h>
1140 /* Required for MAXSIG */
1141 #include <signal.h>
1142 #include <sys/socket.h>
1143 #ifdef __APPLE__
1144 # define __APPLE_USE_RFC_3542
1145 #endif
1146 #include <netinet/in.h>
1147 #include <sys/time.h>
1148 #include <time.h>
1149 #include <net/if.h>
1150 ])dnl
1151
1152 dnl Same applies for HAVE_NET_IF_VAR_H, which HAVE_NETINET6_ND6_H and
1153 dnl HAVE_NETINET_IN_VAR_H depend upon. But if_var.h depends on if.h, hence
1154 dnl an additional round for it.
1155
1156 AC_CHECK_HEADERS([net/if_var.h], [], [], [FRR_INCLUDES])
1157
1158 m4_define([FRR_INCLUDES],
1159 FRR_INCLUDES
1160 [#ifdef HAVE_NET_IF_VAR_H
1161 # include <net/if_var.h>
1162 #endif
1163 ])dnl
1164
1165 AC_CHECK_HEADERS([netinet/in_var.h \
1166         net/if_dl.h net/netopt.h \
1167         inet/nd.h netinet/ip_icmp.h \
1168         sys/sysctl.h sys/sockio.h sys/conf.h],
1169         [], [], [FRR_INCLUDES])
1170
1171 AC_CHECK_HEADERS([ucontext.h], [], [],
1172 [#ifndef __USE_GNU
1173 #define __USE_GNU
1174 #endif /* __USE_GNU */
1175 FRR_INCLUDES
1176 ])
1177
1178 m4_define([UCONTEXT_INCLUDES],
1179 [#include <ucontext.h>])dnl
1180
1181 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.uc_regs],
1182   [], [], [UCONTEXT_INCLUDES])
1183 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs],
1184   [AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs.nip],
1185    [], [], [UCONTEXT_INCLUDES])],
1186   [], [UCONTEXT_INCLUDES])
1187 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.gregs],
1188   [], [], [UCONTEXT_INCLUDES])
1189
1190 m4_define([FRR_INCLUDES],
1191 FRR_INCLUDES
1192 [
1193 #include <sys/un.h>
1194 #include <netinet/in_systm.h>
1195 #ifdef HAVE_NETINET_IN_VAR_H
1196 # include <netinet/in_var.h>
1197 #endif
1198 #ifdef HAVE_NET_IF_DL_H
1199 # include <net/if_dl.h>
1200 #endif
1201 #ifdef HAVE_NET_NETOPT_H
1202 # include <net/netopt.h>
1203 #endif
1204 #include <net/route.h>
1205 #ifdef HAVE_INET_ND_H
1206 # include <inet/nd.h>
1207 #endif
1208 #include <arpa/inet.h>
1209 /* Required for IDRP */
1210 #ifdef HAVE_NETINET_IP_ICMP_H
1211 # include <netinet/ip_icmp.h>
1212 #endif
1213 ])dnl
1214
1215 dnl V6 headers are checked below, after we check for v6
1216
1217 is_linux=false
1218
1219 AC_MSG_CHECKING([which operating system interface to use])
1220 case "$host_os" in
1221   sunos* | solaris2*)
1222     AC_MSG_FAILURE([Solaris support has been removed please see versions prior or equal to 7.5])
1223     ;;
1224   linux*)
1225     AC_MSG_RESULT([Linux])
1226
1227     AC_DEFINE([GNU_LINUX], [1], [GNU Linux])
1228     AC_DEFINE([HAVE_NETLINK], [1], [netlink])
1229     AC_DEFINE([LINUX_IPV6], [1], [Linux IPv6 stack])
1230
1231     dnl Linux has a compilation problem with mixing
1232     dnl netinet/in.h and linux/in6.h they are not
1233     dnl compatible.  There has been discussion on
1234     dnl how to fix it but no real progress on implementation
1235     dnl when they fix it, remove this
1236     AC_DEFINE([IPV6_MINHOPCOUNT], [73], [Linux ipv6 Min Hop Count])
1237
1238     is_linux=true
1239     ;;
1240   openbsd*)
1241     AC_MSG_RESULT([OpenBSD])
1242
1243     AC_DEFINE([OPEN_BSD], [1], [OpenBSD])
1244     AC_DEFINE([KAME], [1], [KAME IPv6])
1245     AC_DEFINE([BSD_V6_SYSCTL], [1], [BSD v6 sysctl to turn on and off forwarding])
1246     ;;
1247   *)
1248     AC_MSG_RESULT([BSD])
1249
1250     AC_DEFINE([HAVE_NET_RT_IFLIST], [1], [NET_RT_IFLIST])
1251     AC_DEFINE([KAME], [1], [KAME IPv6])
1252     AC_DEFINE([BSD_V6_SYSCTL], [1], [BSD v6 sysctl to turn on and off forwarding])
1253     ;;
1254 esac
1255 AM_CONDITIONAL([LINUX], [${is_linux}])
1256
1257 AC_SYS_LARGEFILE
1258
1259 dnl ------------------------
1260 dnl Integrated REALMS option
1261 dnl ------------------------
1262 if test "$enable_realms" = "yes"; then
1263     case "$host_os" in
1264       linux*)
1265        AC_DEFINE([SUPPORT_REALMS], [1], [Realms support])
1266        ;;
1267       *)
1268        echo "Sorry, only Linux has REALMS support"
1269        exit 1
1270        ;;
1271     esac
1272 fi
1273
1274 dnl ---------------
1275 dnl other functions
1276 dnl ---------------
1277 AC_CHECK_FUNCS([ \
1278         strlcat strlcpy \
1279         getgrouplist \
1280         openat \
1281         unlinkat \
1282         posix_fallocate \
1283         ])
1284
1285 dnl ##########################################################################
1286 dnl LARGE if block spans a lot of "configure"!
1287 if test "$enable_clippy_only" != "yes"; then
1288 dnl ##########################################################################
1289
1290 #
1291 # Logic for protobuf support.
1292 #
1293 PROTO3=false
1294 if test "$enable_protobuf" = "yes"; then
1295   # Check for protoc & protoc-c
1296
1297   # protoc is not required, it's only for a "be nice" helper target
1298   AC_CHECK_PROGS([PROTOC], [protoc], [/bin/false])
1299
1300   AC_CHECK_PROGS([PROTOC_C], [protoc-c], [/bin/false])
1301   if test "$PROTOC_C" = "/bin/false"; then
1302     AC_MSG_FAILURE([protobuf requested but protoc-c not found.  Install protobuf-c.])
1303   fi
1304
1305   PKG_CHECK_MODULES([PROTOBUF_C], [libprotobuf-c >= 0.14],, [
1306     AC_MSG_FAILURE([protobuf requested but libprotobuf-c not found.  Install protobuf-c.])
1307   ])
1308
1309   PROTO3=true
1310   AC_CHECK_HEADER([google/protobuf-c/protobuf-c.h],
1311                   [AC_CHECK_DECLS(PROTOBUF_C_LABEL_NONE,
1312                                   AC_DEFINE([HAVE_PROTOBUF_VERSION_3],
1313                                             [1], [Have Protobuf version 3]),
1314                                   [PROTO3=false],
1315                                   [#include <google/protobuf-c/protobuf-c.h>])],
1316                   [PROTO3=false && AC_MSG_FAILURE([protobuf requested but protobuf-c.h not found.  Install protobuf-c.])])
1317
1318   AC_DEFINE([HAVE_PROTOBUF], [1], [protobuf])
1319 fi
1320
1321
1322 dnl ---------------------
1323 dnl Integrated VTY option
1324 dnl ---------------------
1325 case "${enable_vtysh}" in
1326 "no")
1327   VTYSH="";;
1328 *)
1329   VTYSH="vtysh";
1330   AC_DEFINE([VTYSH], [1], [VTY shell])
1331
1332   prev_libs="$LIBS"
1333   AC_CHECK_LIB([readline], [main], [
1334     LIBREADLINE="-lreadline"
1335   ], [
1336     dnl readline failed - it might be incorrectly linked and missing its
1337     dnl termcap/tinfo/curses dependency.  see if we can fix that...
1338     AC_SEARCH_LIBS([tputs], [termcap tinfo curses ncurses], [
1339       LIBREADLINE="$ac_cv_search_tputs"
1340     ], [
1341       AC_MSG_ERROR([libreadline (needed for vtysh) not found and/or missing dependencies])
1342     ])
1343
1344     dnl re-try with the lib we found above
1345     unset ac_cv_lib_readline_main
1346     AC_CHECK_LIB([readline], [main], [
1347       LIBREADLINE="-lreadline $LIBREADLINE"
1348     ], [
1349       AC_MSG_ERROR([libreadline (needed for vtysh) not found and/or missing dependencies])
1350     ], [$LIBREADLINE])
1351   ], [])
1352   LIBS="$prev_libs"
1353
1354   AC_CHECK_HEADER([readline/history.h])
1355   if test "$ac_cv_header_readline_history_h" = "no"; then
1356     AC_MSG_ERROR([readline is too old to have readline/history.h, please update to the latest readline library.])
1357   fi
1358   AC_CHECK_LIB([readline], [rl_completion_matches], [true], [], [$LIBREADLINE])
1359   if test "$ac_cv_lib_readline_rl_completion_matches" = "no"; then
1360     AC_DEFINE([rl_completion_matches], [completion_matches], [Old readline])
1361   fi
1362   AC_CHECK_LIB([readline], [append_history], [frr_cv_append_history=yes], [frr_cv_append_history=no], [$LIBREADLINE])
1363   if test "$frr_cv_append_history" = "yes"; then
1364     AC_DEFINE([HAVE_APPEND_HISTORY], [1], [Have history.h append_history])
1365   fi
1366   ;;
1367 esac
1368 AC_SUBST([LIBREADLINE])
1369
1370 dnl ----------
1371 dnl PAM module
1372 dnl
1373 dnl FRR detects the PAM library it is built against by checking for a
1374 dnl functional pam_misc.h (Linux-PAM) or openpam.h (OpenPAM) header. pam_misc.h
1375 dnl is known to #include pam_appl.h, the standard header of a PAM library, and
1376 dnl openpam.h doesn't do that, although depends on the header too. Hence a
1377 dnl little assistance to AC_CHECK_HEADER is necessary for the proper detection
1378 dnl of OpenPAM.
1379 dnl ----------
1380 if test "$with_libpam" = "yes"; then
1381   AC_CHECK_HEADER([security/pam_misc.h],
1382     [AC_DEFINE([HAVE_PAM_MISC_H], [1], [Have pam_misc.h])
1383      AC_DEFINE([PAM_CONV_FUNC], [misc_conv], [Have misc_conv])
1384      pam_conv_func="misc_conv"
1385     ],
1386     [], FRR_INCLUDES)
1387   AC_CHECK_HEADER([security/openpam.h],
1388     [AC_DEFINE([HAVE_OPENPAM_H], [1], [Have openpam.h])
1389      AC_DEFINE([PAM_CONV_FUNC], [openpam_ttyconv], [Have openpam_ttyconv])
1390      pam_conv_func="openpam_ttyconv"
1391     ],
1392     [], FRR_INCLUDES[#include <security/pam_appl.h>])
1393   if test -z "$ac_cv_header_security_pam_misc_h$ac_cv_header_security_openpam_h" ; then
1394     AC_MSG_WARN([*** pam support will not be built ***])
1395     with_libpam="no"
1396   fi
1397 fi
1398
1399 if test "$with_libpam" = "yes"; then
1400 dnl took this test from proftpds configure.in and suited to our needs
1401 dnl -------------------------------------------------------------------------
1402 dnl
1403 dnl This next check looks funky due to a linker problem with some versions
1404 dnl of the PAM library.  Prior to 0.72 release, the Linux PAM shared library
1405 dnl omitted requiring libdl linking information. PAM-0.72 or better ships
1406 dnl with RedHat 6.2 and Debian 2.2 or better.
1407 AC_CHECK_LIB([pam], [pam_start],
1408   [AC_CHECK_LIB([pam], [$pam_conv_func],
1409     [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1410      LIBPAM="-lpam"],
1411     [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1412      LIBPAM="-lpam -lpam_misc"]
1413     )
1414   ],
1415
1416   [AC_CHECK_LIB([pam], [pam_end],
1417     [AC_CHECK_LIB([pam], [$pam_conv_func],
1418       [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1419        LIBPAM="-lpam -ldl"],
1420       [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1421        LIBPAM="-lpam -ldl -lpam_misc"]
1422      )
1423   ],AC_MSG_WARN([*** pam support will not be built ***]),
1424   [-ldl])
1425   ]
1426 )
1427 fi
1428 AC_SUBST([LIBPAM])
1429
1430 dnl -------------------------------
1431 dnl bgpd needs pow() and hence libm
1432 dnl -------------------------------
1433 TMPLIBS="$LIBS"
1434 LIBS=""
1435 AC_SEARCH_LIBS([pow], [m], [
1436   LIBM="$LIBS"
1437 ], [
1438   AC_MSG_WARN([Unable to find working pow function - bgpd may not link])
1439 ])
1440 LIBS="$TMPLIBS"
1441 AC_SUBST([LIBM])
1442
1443 AC_CHECK_FUNCS([ppoll], [
1444   AC_DEFINE([HAVE_PPOLL], [1], [have Linux/BSD ppoll()])
1445 ])
1446 AC_CHECK_FUNCS([pollts], [
1447   AC_DEFINE([HAVE_POLLTS], [1], [have NetBSD pollts()])
1448 ])
1449
1450 AC_CHECK_HEADER([asm-generic/unistd.h],
1451                 [AC_CHECK_DECL(__NR_setns,
1452                                AC_DEFINE([HAVE_NETNS], [1], [Have netns]),,
1453                                FRR_INCLUDES [#include <asm-generic/unistd.h>
1454                                ])
1455                  AC_CHECK_FUNCS([setns])]
1456                )
1457
1458 dnl --------------------------
1459 dnl Determine IS-IS I/O method
1460 dnl --------------------------
1461 AC_DEFINE([ISIS_METHOD_PFPACKET], [1], [constant value for isis method pfpacket])
1462 AC_DEFINE([ISIS_METHOD_DLPI], [2], [constant value for isis method dlpi])
1463 AC_DEFINE([ISIS_METHOD_BPF], [3], [constant value for isis method bpf])
1464 AC_CHECK_HEADER([net/bpf.h])
1465 AC_CHECK_HEADER([sys/dlpi.h])
1466 AC_MSG_CHECKING([zebra IS-IS I/O method])
1467
1468 case "$host_os" in
1469   linux*)
1470     AC_MSG_RESULT([pfpacket])
1471     ISIS_METHOD_MACRO="ISIS_METHOD_PFPACKET"
1472     ;;
1473   *)
1474     if test "$ac_cv_header_net_bpf_h" = "no"; then
1475       if test "$ac_cv_header_sys_dlpi_h" = "no"; then
1476         AC_MSG_RESULT([none])
1477         if test "$enable_isisd" = "yes" -o "$enable_fabricd" = "yes"; then
1478           AC_MSG_FAILURE([IS-IS support requested but no packet backend found])
1479         fi
1480         AC_MSG_WARN([*** IS-IS support will not be built ***])
1481         enable_isisd="no"
1482         enable_fabricd="no"
1483       else
1484         AC_MSG_RESULT([DLPI])
1485       fi
1486       ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1487     else
1488       AC_MSG_RESULT([BPF])
1489       ISIS_METHOD_MACRO="ISIS_METHOD_BPF"
1490     fi
1491     ;;
1492 esac
1493 AC_DEFINE_UNQUOTED([ISIS_METHOD], [$ISIS_METHOD_MACRO], [selected method for isis, == one of the constants])
1494
1495 dnl ---------------------------------------------------------------
1496 dnl figure out how to specify an interface in multicast sockets API
1497 dnl ---------------------------------------------------------------
1498 AC_CHECK_MEMBERS([struct ip_mreqn.imr_ifindex], [], [], FRR_INCLUDES)
1499
1500 AC_CHECK_HEADERS([linux/mroute.h], [], [],[
1501         #include <sys/socket.h>
1502         #include <netinet/in.h>
1503         #define _LINUX_IN_H             /* For Linux <= 2.6.25 */
1504         #include <linux/types.h>
1505 ])
1506
1507 m4_define([FRR_INCLUDES],
1508 FRR_INCLUDES
1509 [#ifdef HAVE_LINUX_MROUTE_H
1510 # include <linux/mroute.h>
1511 #endif
1512 ])dnl
1513
1514 AC_CHECK_HEADERS([netinet/ip_mroute.h], [], [],[
1515         #include <sys/socket.h>
1516         #include <sys/types.h>
1517         #include <netinet/in.h>
1518         #include <net/route.h>
1519 ])
1520
1521 m4_define([FRR_INCLUDES],
1522 FRR_INCLUDES
1523 [#ifdef HAVE_NETINET_IP_MROUTE_H
1524 # include <netinet/ip_mroute.h>
1525 #endif
1526 ])dnl
1527
1528 AC_MSG_CHECKING([for RFC3678 protocol-independed API])
1529 AC_COMPILE_IFELSE(
1530 [ AC_LANG_PROGRAM([[
1531       #include <sys/types.h>
1532       #include <netinet/in.h>
1533   ]], [[
1534       struct group_req gr;
1535       int sock;
1536       setsockopt(sock, IPPROTO_IP, MCAST_JOIN_GROUP, (void*)&gr, sizeof(gr));
1537   ]])
1538 ],[
1539   AC_MSG_RESULT([yes])
1540   AC_DEFINE([HAVE_RFC3678], [1], [Have RFC3678 protocol-independed API])
1541 ],[
1542   AC_MSG_RESULT(no)
1543 ])
1544
1545 dnl ---------------------------------------------------------------
1546 dnl figure out how to check link-state
1547 dnl ---------------------------------------------------------------
1548 AC_CHECK_HEADER([net/if_media.h],
1549   [m4_define([LINK_DETECT_INCLUDES],
1550     FRR_INCLUDES
1551     [#include <net/if_media.h>
1552   ])
1553   AC_CHECK_MEMBERS([struct ifmediareq.ifm_status],
1554     AC_DEFINE([HAVE_BSD_LINK_DETECT], [1], [BSD link-detect]),
1555     [], LINK_DETECT_INCLUDES)],
1556   [],
1557   FRR_INCLUDES)
1558
1559 dnl ---------------------------------------------------------------
1560 dnl Additional, newer way to check link-state using ifi_link_state.
1561 dnl Not available in all BSD's when ifmediareq available
1562 dnl ---------------------------------------------------------------
1563 AC_CHECK_MEMBERS([struct if_data.ifi_link_state],
1564   AC_DEFINE([HAVE_BSD_IFI_LINK_STATE], [1], [BSD ifi_link_state available]),
1565   [], FRR_INCLUDES)
1566
1567 dnl ------------------------
1568 dnl TCP_MD5SIG socket option
1569 dnl ------------------------
1570
1571 AC_CHECK_HEADER([netinet/tcp.h],
1572    [m4_define([MD5_INCLUDES],
1573       FRR_INCLUDES
1574       [#include <netinet/tcp.h>
1575     ])
1576     AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)],
1577    [],
1578    FRR_INCLUDES)
1579 if test "$ac_cv_have_decl_TCP_MD5SIG" = "no"; then
1580   AC_CHECK_HEADER([linux/tcp.h],
1581        [m4_define([MD5_INCLUDES],
1582           FRR_INCLUDES
1583           [#include <linux/tcp.h>
1584         ])
1585        AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)])
1586 fi
1587
1588 AC_CHECK_LIB([crypt], [crypt], [],
1589                     [AC_CHECK_LIB([crypto], [DES_crypt])])
1590 AC_CHECK_LIB([resolv], [res_init])
1591
1592 dnl ---------------------------
1593 dnl check system has PCRE regexp
1594 dnl ---------------------------
1595 if test "$enable_pcreposix" = "yes"; then
1596   AC_CHECK_LIB([pcreposix], [regexec], [], [
1597     AC_MSG_ERROR([--enable-pcreposix given but unable to find libpcreposix])
1598   ])
1599 fi
1600 AC_SUBST([HAVE_LIBPCREPOSIX])
1601
1602 dnl ##########################################################################
1603 dnl test "$enable_clippy_only" != "yes"
1604 fi
1605 dnl END OF LARGE if block
1606 dnl ##########################################################################
1607
1608 dnl ------------------
1609 dnl check C-Ares library
1610 dnl ------------------
1611 PKG_CHECK_MODULES([CARES], [libcares], [
1612   c_ares_found=true
1613 ],[
1614   c_ares_found=false
1615 ])
1616 AM_CONDITIONAL([CARES], [$c_ares_found])
1617
1618
1619 dnl ----------------------------------------------------------------------------
1620 dnl figure out if domainname is available in the utsname struct (GNU extension).
1621 dnl ----------------------------------------------------------------------------
1622 AC_CHECK_MEMBERS([struct utsname.domainname], [], [], [#include <sys/utsname.h>])
1623
1624 dnl ------------------
1625 dnl IPv6 header checks
1626 dnl ------------------
1627 AC_CHECK_HEADERS([netinet6/in6.h netinet/in6_var.h \
1628         netinet6/in6_var.h netinet6/nd6.h], [], [],
1629         FRR_INCLUDES)
1630
1631 m4_define([FRR_INCLUDES],dnl
1632 FRR_INCLUDES
1633 [#ifdef HAVE_NETINET6_IN6_H
1634 #include <netinet6/in6.h>
1635 #endif
1636 #ifdef HAVE_NETINET_IN6_VAR_H
1637 #include <netinet/in6_var.h>
1638 #endif
1639 #include <netinet/icmp6.h>
1640 #ifdef HAVE_NETINET6_IN6_VAR_H
1641 # include <netinet6/in6_var.h>
1642 #endif
1643 #ifdef HAVE_NETINET6_ND6_H
1644 # include <netinet6/nd6.h>
1645 #endif
1646 ])dnl
1647
1648 dnl --------------------
1649 dnl Daemon disable check
1650 dnl --------------------
1651
1652 AS_IF([test "$enable_bgpd" != "no"], [
1653   AC_DEFINE([HAVE_BGPD], [1], [bgpd])
1654 ])
1655
1656 AS_IF([test "$enable_ripd" != "no"], [
1657   AC_DEFINE([HAVE_RIPD], [1], [ripd])
1658 ])
1659
1660 AS_IF([test "$enable_ripngd" != "no"], [
1661   AC_DEFINE([HAVE_RIPNGD], [1], [ripngd])
1662 ])
1663
1664 AS_IF([test "$enable_ospfd" != "no"], [
1665   AC_DEFINE([HAVE_OSPFD], [1], [ospfd])
1666 ])
1667
1668 AS_IF([test "$enable_ospf6d" != "no"], [
1669   AC_DEFINE([HAVE_OSPF6D], [1], [ospf6d])
1670 ])
1671
1672 AS_IF([test "$enable_ldpd" != "no"], [
1673   AC_DEFINE([HAVE_LDPD], [1], [ldpd])
1674 ])
1675
1676 AS_IF([test "$enable_nhrpd" != "no"], [
1677   AC_DEFINE([HAVE_NHRPD], [1], [nhrpd])
1678 ])
1679
1680 AS_IF([test "$enable_eigrpd" != "no"], [
1681   AC_DEFINE([HAVE_EIGRPD], [1], [eigrpd])
1682 ])
1683
1684 AS_IF([test "$enable_babeld" != "no"], [
1685   AC_DEFINE([HAVE_BABELD], [1], [babeld])
1686 ])
1687
1688 AS_IF([test "$enable_isisd" != "no"], [
1689   AC_DEFINE([HAVE_ISISD], [1], [isisd])
1690 ])
1691
1692 AS_IF([test "$enable_pimd" != "no"], [
1693   AC_DEFINE([HAVE_PIMD], [1], [pimd])
1694 ])
1695
1696 AS_IF([test "$enable_pbrd" != "no"], [
1697   AC_DEFINE([HAVE_PBRD], [1], [pbrd])
1698 ])
1699
1700 AS_IF([test "$enable_sharpd" = "yes"], [
1701   AC_DEFINE([HAVE_SHARPD], [1], [sharpd])
1702 ])
1703
1704 AS_IF([test "$enable_staticd" != "no"], [
1705   AC_DEFINE([HAVE_STATICD], [1], [staticd])
1706 ])
1707
1708 AS_IF([test "$enable_fabricd" != "no"], [
1709   AC_DEFINE([HAVE_FABRICD], [1], [fabricd])
1710 ])
1711
1712 AS_IF([test "$enable_vrrpd" != "no"], [
1713   AC_DEFINE([HAVE_VRRPD], [1], [vrrpd])
1714 ])
1715
1716 if test "$enable_bfdd" = "no"; then
1717   AC_DEFINE([HAVE_BFDD], [0], [bfdd])
1718   BFDD=""
1719 else
1720   AC_DEFINE([HAVE_BFDD], [1], [bfdd])
1721   BFDD="bfdd"
1722
1723   case $host_os in
1724     linux*)
1725       AC_DEFINE([BFD_LINUX], [1], [bfdd])
1726       ;;
1727
1728     *)
1729       AC_DEFINE([BFD_BSD], [1], [bfdd])
1730       ;;
1731   esac
1732 fi
1733
1734 AS_IF([test "$enable_pathd" != "no"], [
1735   AC_DEFINE([HAVE_PATHD], [1], [pathd])
1736   AC_DEFINE([HAVE_PATHD_PCEP], [1], [pathd-pcep])
1737 ])
1738
1739
1740 if test "$ac_cv_lib_json_c_json_object_get" = "no" -a "$BFDD" = "bfdd"; then
1741   AC_MSG_ERROR(["you must use json-c library to use bfdd"])
1742 fi
1743
1744 NHRPD=""
1745 case "$host_os" in
1746   linux*)
1747     case "${enable_nhrpd}" in
1748       no)
1749         ;;
1750       yes)
1751         if test "$enable_clippy_only" != "yes"; then
1752         if test "$c_ares_found" != "true" ; then
1753           AC_MSG_ERROR([nhrpd requires libcares.  Please install c-ares and its -dev headers.])
1754         fi
1755         fi
1756         NHRPD="nhrpd"
1757         ;;
1758       *)
1759         if test "$c_ares_found" = "true" ; then
1760           NHRPD="nhrpd"
1761         fi
1762         ;;
1763     esac
1764     ;;
1765   *)
1766     if test "$enable_nhrpd" = "yes"; then
1767       AC_MSG_ERROR([nhrpd requires kernel APIs that are only present on Linux.])
1768     fi
1769     ;;
1770 esac
1771
1772 if test "$enable_watchfrr" = "no";then
1773   WATCHFRR=""
1774 else
1775   WATCHFRR="watchfrr"
1776 fi
1777
1778 OSPFCLIENT=""
1779 if test "$enable_ospfapi" != "no";then
1780     AC_DEFINE([SUPPORT_OSPF_API], [1], [OSPFAPI])
1781
1782   if test "$enable_ospfclient" != "no";then
1783       OSPFCLIENT="ospfclient"
1784   fi
1785 fi
1786
1787 if test "$enable_bgp_announce" = "no";then
1788   AC_DEFINE([DISABLE_BGP_ANNOUNCE], [1], [Disable BGP installation to zebra])
1789 else
1790   AC_DEFINE([DISABLE_BGP_ANNOUNCE], [0], [Disable BGP installation to zebra])
1791 fi
1792
1793 if test "$enable_bgp_vnc" != "no";then
1794   AC_DEFINE([ENABLE_BGP_VNC], [1], [Enable BGP VNC support])
1795 fi
1796
1797 bgpd_bmp=false
1798 case "${enable_bmp}" in
1799   no)
1800     ;;
1801   yes)
1802     if test "$c_ares_found" != "true" ; then
1803       AC_MSG_ERROR([BMP support requires libcares.  Please install c-ares and its -dev headers.])
1804     fi
1805     bgpd_bmp=true
1806     ;;
1807   *)
1808     if test "$c_ares_found" = "true" ; then
1809       bgpd_bmp=true
1810     fi
1811     ;;
1812 esac
1813
1814 if test "$enable_version_build_config" != "no";then
1815   AC_DEFINE([ENABLE_VERSION_BUILD_CONFIG], [1], [Report build configs in show version])
1816 fi
1817
1818 dnl ##########################################################################
1819 dnl LARGE if block
1820 if test "$enable_clippy_only" != "yes"; then
1821 dnl ##########################################################################
1822
1823 dnl ------------------
1824 dnl check Net-SNMP library
1825 dnl ------------------
1826 if test "$enable_snmp" != "" -a "$enable_snmp" != "no"; then
1827    AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], [no])
1828    if test "$NETSNMP_CONFIG" = "no"; then
1829       AC_MSG_ERROR([--enable-snmp given but unable to find net-snmp-config])
1830    fi
1831    SNMP_LIBS="`${NETSNMP_CONFIG} --agent-libs`"
1832    SNMP_CFLAGS="`${NETSNMP_CONFIG} --base-cflags`"
1833    # net-snmp lists all of its own dependencies.  we absolutely do not want that
1834    # among other things we avoid a GPL vs. OpenSSL license conflict here
1835    for removelib in crypto ssl sensors pci wrap; do
1836      SNMP_LIBS="`echo $SNMP_LIBS | sed -e 's/\(^\|\s\)-l'$removelib'\b/ /g' -e 's/\(^\|\s\)\([^\s]*\/\)\?lib'$removelib'\.[^\s]\+\b/ /g'`"
1837    done
1838    AC_MSG_CHECKING([whether we can link to Net-SNMP])
1839    AC_LINK_IFELSE_FLAGS([$SNMP_CFLAGS], [$SNMP_LIBS], [AC_LANG_PROGRAM([
1840 int main(void);
1841 ],
1842 [
1843 {
1844   return 0;
1845 }
1846 ])], [
1847      AC_MSG_RESULT([no])
1848      AC_MSG_ERROR([--enable-snmp given but not usable])])
1849    case "${enable_snmp}" in
1850      yes)
1851       SNMP_METHOD=agentx
1852       ;;
1853      agentx)
1854       SNMP_METHOD="${enable_snmp}"
1855       ;;
1856      *)
1857       AC_MSG_ERROR([--enable-snmp given with an unknown method (${enable_snmp}). Use yes or agentx])
1858       ;;
1859    esac
1860    AH_TEMPLATE([SNMP_AGENTX], [Use SNMP AgentX to interface with snmpd])
1861    AC_DEFINE_UNQUOTED(AS_TR_CPP(SNMP_${SNMP_METHOD}),,[SNMP method to interface with snmpd])
1862 fi
1863 AC_SUBST([SNMP_LIBS])
1864 AC_SUBST([SNMP_CFLAGS])
1865
1866 dnl ---------------
1867 dnl libyang
1868 dnl ---------------
1869 PKG_CHECK_MODULES([LIBYANG], [libyang >= 2.0.0], , [
1870   AC_MSG_ERROR([libyang (>= 2.0.0) was not found on your system.])
1871 ])
1872 ac_cflags_save="$CFLAGS"
1873 CFLAGS="$CFLAGS $LIBYANG_CFLAGS"
1874 AC_CHECK_MEMBER([struct lyd_node.priv], [], [
1875   AC_MSG_ERROR([m4_normalize([
1876     libyang needs to be compiled with ENABLE_LYD_PRIV=ON.
1877     Instructions for this are included in the build documentation for your platform at http://docs.frrouting.org/projects/dev-guide/en/latest/building.html])
1878   ])
1879 ], [[#include <libyang/libyang.h>]])
1880 CFLAGS="$ac_cflags_save"
1881
1882 dnl ---------------
1883 dnl configuration rollbacks
1884 dnl ---------------
1885 SQLITE3=false
1886 if test "$enable_config_rollbacks" = "yes"; then
1887   PKG_CHECK_MODULES([SQLITE3], [sqlite3], [
1888     AC_DEFINE([HAVE_CONFIG_ROLLBACKS], [1], [Enable configuration rollbacks])
1889     AC_DEFINE([HAVE_SQLITE3], [1], [Enable sqlite3 database])
1890     SQLITE3=true
1891   ], [
1892     AC_MSG_ERROR([--enable-config-rollbacks given but sqlite3 was not found on your system.])
1893   ])
1894 fi
1895
1896 dnl ---------------
1897 dnl confd
1898 dnl ---------------
1899 if test "$enable_confd" != "" -a "$enable_confd" != "no"; then
1900    AC_CHECK_PROG([CONFD], [confd], [confd], [/bin/false], "${enable_confd}/bin")
1901    if test "$CONFD" = "/bin/false"; then
1902       AC_MSG_ERROR([confd was not found on your system.])]
1903    fi
1904    CONFD_CFLAGS="-I${enable_confd}/include -L${enable_confd}/lib"
1905    AC_SUBST([CONFD_CFLAGS])
1906    CONFD_LIBS="-lconfd"
1907    AC_SUBST([CONFD_LIBS])
1908    AC_DEFINE([HAVE_CONFD], [1], [Enable confd integration])
1909 fi
1910
1911 dnl ---------------
1912 dnl sysrepo
1913 dnl ---------------
1914 if test "$enable_sysrepo" = "yes"; then
1915   PKG_CHECK_MODULES([SYSREPO], [sysrepo],
1916       [AC_DEFINE([HAVE_SYSREPO], [1], [Enable sysrepo integration])
1917       SYSREPO=true],
1918       [SYSREPO=false
1919       AC_MSG_ERROR([sysrepo was not found on your system.])]
1920   )
1921 fi
1922
1923 dnl ---------------
1924 dnl gRPC
1925 dnl ---------------
1926 if test "$enable_grpc" = "yes"; then
1927   PKG_CHECK_MODULES([GRPC], [grpc grpc++ protobuf], [
1928     AC_CHECK_PROGS([PROTOC], [protoc], [/bin/false])
1929     if test "$PROTOC" = "/bin/false"; then
1930       AC_MSG_FAILURE([grpc requested but protoc not found.])
1931     fi
1932
1933     AC_DEFINE([HAVE_GRPC], [1], [Enable the gRPC northbound plugin])
1934     GRPC=true
1935   ], [
1936     GRPC=false
1937     AC_MSG_ERROR([grpc/grpc++ were not found on your system.])
1938   ])
1939 fi
1940
1941 dnl -----
1942 dnl LTTng
1943 dnl -----
1944 if test "$enable_lttng" = "yes"; then
1945   PKG_CHECK_MODULES([UST], [lttng-ust >= 2.12.0], [
1946     AC_DEFINE([HAVE_LTTNG], [1], [Enable LTTng support])
1947     LTTNG=true
1948   ], [
1949     AC_MSG_ERROR([configuration specifies --enable-lttng but lttng-ust was not found])
1950   ])
1951 fi
1952
1953 dnl ----
1954 dnl USDT
1955 dnl ----
1956 if test "$enable_usdt" = "yes"; then
1957   AC_CHECK_HEADERS([sys/sdt.h], [
1958     AC_DEFINE([HAVE_USDT], [1], [Enable USDT probes])
1959     USDT=true
1960   ], [
1961     AC_MSG_ERROR([configuration specifies --enable-usdt but no USDT kernel headers (sys/sdt.h) found])
1962   ])
1963 fi
1964
1965 dnl ------
1966 dnl ZeroMQ
1967 dnl ------
1968 if test "$enable_zeromq" != "no"; then
1969   PKG_CHECK_MODULES([ZEROMQ], [libzmq >= 4.0.0], [
1970     AC_DEFINE([HAVE_ZEROMQ], [1], [Enable ZeroMQ support])
1971     ZEROMQ=true
1972   ], [
1973     if test "$enable_zeromq" = "yes"; then
1974       AC_MSG_ERROR([configuration specifies --enable-zeromq but libzmq was not found])
1975     fi
1976   ])
1977 fi
1978
1979 dnl ------------------------------------
1980 dnl Enable RPKI and add librtr to libs
1981 dnl ------------------------------------
1982 if test "$enable_rpki" = "yes"; then
1983   PKG_CHECK_MODULES([RTRLIB], [rtrlib >= 0.5.0],
1984       [RPKI=true],
1985       [RPKI=false
1986       AC_MSG_ERROR([rtrlib was not found on your system or is too old.])]
1987   )
1988 fi
1989
1990 dnl ------------------------------------
1991 dnl pimd is not supported on OpenBSD and MacOS
1992 dnl ------------------------------------
1993 if test "$enable_pimd" != "no"; then
1994 AC_MSG_CHECKING([for pimd OS support])
1995 case "$host_os" in
1996   darwin*)
1997     AC_MSG_RESULT([no])
1998     enable_pimd="no"
1999     ;;
2000   openbsd*)
2001     AC_MSG_RESULT([no])
2002     enable_pimd="no"
2003     ;;
2004   *)
2005     AC_MSG_RESULT([yes])
2006     ;;
2007 esac
2008 fi
2009
2010 dnl -------------------------------------
2011 dnl VRRP is only supported on linux
2012 dnl -------------------------------------
2013 if test "$enable_vrrpd" != "no"; then
2014 AC_MSG_CHECKING([for VRRP OS support])
2015 case "$host_os" in
2016   linux*)
2017     AC_MSG_RESULT([yes])
2018     ;;
2019   *)
2020     AC_MSG_RESULT([no])
2021     enable_vrrpd="no"
2022     ;;
2023 esac
2024 fi
2025
2026 dnl ------------------------------------------
2027 dnl Check whether rtrlib was build with ssh support
2028 dnl ------------------------------------------
2029 AC_MSG_CHECKING([whether the RTR Library is compiled with SSH])
2030 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "rtrlib/rtrlib.h"]],
2031                         [[struct tr_ssh_config config;]])],
2032         [AC_MSG_RESULT([yes])
2033         AC_DEFINE([FOUND_SSH], [1], [found_ssh])],
2034         AC_MSG_RESULT([no])
2035 )
2036
2037 dnl ---------------
2038 dnl dlopen & dlinfo
2039 dnl ---------------
2040 AC_SEARCH_LIBS([dlopen], [dl dld], [], [
2041   AC_MSG_ERROR([unable to find the dlopen()])
2042 ])
2043
2044 AC_CHECK_HEADERS([link.h])
2045
2046 AC_CACHE_CHECK([for dlinfo(RTLD_DI_ORIGIN)], [frr_cv_rtld_di_origin], [
2047   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2048 #include <stdlib.h>
2049 #ifdef HAVE_LINK_H
2050 #include <link.h>
2051 #endif
2052 #include <dlfcn.h>
2053 ]], [[
2054   char origin[1];
2055   dlinfo (NULL, RTLD_DI_ORIGIN, &origin);
2056 ]])], [
2057     frr_cv_rtld_di_origin=yes
2058   ], [
2059     frr_cv_rtld_di_origin=no
2060   ])
2061 ])
2062 if test "$frr_cv_rtld_di_origin" = "yes"; then
2063   AC_DEFINE([HAVE_DLINFO_ORIGIN], [1], [Have dlinfo RTLD_DI_ORIGIN])
2064 fi
2065
2066 AC_CACHE_CHECK([for dlinfo(RTLD_DI_LINKMAP)], [frr_cv_rtld_di_linkmap], [
2067   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2068 #include <stdlib.h>
2069 #ifdef HAVE_LINK_H
2070 #include <link.h>
2071 #endif
2072 #include <dlfcn.h>
2073 ]], [[
2074   struct link_map *lm = NULL;
2075   dlinfo (NULL, RTLD_DI_LINKMAP, &lm);
2076 ]])], [
2077     frr_cv_rtld_di_linkmap=yes
2078   ], [
2079     frr_cv_rtld_di_linkmap=no
2080   ])
2081 ])
2082 if test "$frr_cv_rtld_di_linkmap" = "yes"; then
2083   AC_DEFINE([HAVE_DLINFO_LINKMAP], [1], [Have dlinfo RTLD_DI_LINKMAP])
2084 fi
2085
2086 dnl ##########################################################################
2087 dnl test "$enable_clippy_only" != "yes"
2088 fi
2089 dnl END OF LARGE if block
2090 dnl ##########################################################################
2091
2092 dnl ---------------------------
2093 dnl sockaddr and netinet checks
2094 dnl ---------------------------
2095 AC_CHECK_TYPES([
2096         struct sockaddr_dl,
2097         struct vifctl, struct mfcctl, struct sioc_sg_req,
2098         vifi_t, struct sioc_vif_req, struct igmpmsg,
2099         struct ifaliasreq, struct if6_aliasreq, struct in6_aliasreq,
2100         struct nd_opt_adv_interval,
2101         struct nd_opt_homeagent_info, struct nd_opt_adv_interval,
2102         struct nd_opt_rdnss, struct nd_opt_dnssl],
2103         [], [], FRR_INCLUDES)
2104
2105 AC_CHECK_MEMBERS([struct sockaddr.sa_len,
2106         struct sockaddr_in.sin_len, struct sockaddr_un.sun_len,
2107         struct sockaddr_dl.sdl_len,
2108         struct if6_aliasreq.ifra_lifetime,
2109         struct nd_opt_adv_interval.nd_opt_ai_type],
2110         [], [], FRR_INCLUDES)
2111
2112 dnl ---------------------------
2113 dnl IRDP/pktinfo/icmphdr checks
2114 dnl ---------------------------
2115
2116 AC_CHECK_TYPES([struct in_pktinfo], [
2117   AC_CHECK_TYPES([struct icmphdr], [
2118     IRDP=true
2119   ], [
2120     IRDP=false
2121   ], [FRR_INCLUDES])
2122 ], [
2123   IRDP=false
2124 ], [FRR_INCLUDES])
2125
2126 case "${enable_irdp}" in
2127 yes)
2128   $IRDP || AC_MSG_ERROR(['IRDP requires in_pktinfo at the moment!'])
2129   ;;
2130 no)
2131   IRDP=false
2132   ;;
2133 esac
2134
2135
2136 dnl -----------------------
2137 dnl checking for IP_PKTINFO
2138 dnl -----------------------
2139 AC_MSG_CHECKING([for IP_PKTINFO])
2140 AC_COMPILE_IFELSE(
2141 [ AC_LANG_PROGRAM([[
2142         #include <netdb.h>
2143    ]], [[
2144         int opt = IP_PKTINFO;
2145    ]])
2146 ],[
2147   AC_MSG_RESULT([yes])
2148   AC_DEFINE([HAVE_IP_PKTINFO], [1], [Have IP_PKTINFO])
2149 ],[
2150   AC_MSG_RESULT([no])
2151 ])
2152
2153 dnl ---------------------------
2154 dnl checking for IP_RECVDSTADDR
2155 dnl ---------------------------
2156 AC_MSG_CHECKING([for IP_RECVDSTADDR])
2157 AC_COMPILE_IFELSE(
2158 [ AC_LANG_PROGRAM([[
2159         #include <netinet/in.h>
2160   ]], [[
2161         int opt = IP_RECVDSTADDR;
2162   ]])
2163 ],[
2164   AC_MSG_RESULT([yes])
2165   AC_DEFINE([HAVE_IP_RECVDSTADDR], [1], [Have IP_RECVDSTADDR])
2166 ],[
2167   AC_MSG_RESULT([no])
2168 ])
2169
2170 dnl ----------------------
2171 dnl checking for IP_RECVIF
2172 dnl ----------------------
2173 AC_MSG_CHECKING([for IP_RECVIF])
2174 AC_COMPILE_IFELSE(
2175 [ AC_LANG_PROGRAM([[
2176         #include <netinet/in.h>
2177   ]], [[
2178         int opt = IP_RECVIF;
2179   ]])
2180 ],[
2181   AC_MSG_RESULT([yes])
2182   AC_DEFINE([HAVE_IP_RECVIF], [1], [Have IP_RECVIF])
2183 ],[
2184   AC_MSG_RESULT([no])
2185 ])
2186
2187 dnl ----------------------
2188 dnl checking for SO_BINDANY
2189 dnl ----------------------
2190 AC_MSG_CHECKING([for SO_BINDANY])
2191 AC_COMPILE_IFELSE(
2192 [ AC_LANG_PROGRAM([[
2193         #include <sys/socket.h>
2194   ]], [[
2195         int opt = SO_BINDANY;
2196   ]])
2197 ],[
2198   AC_MSG_RESULT([yes])
2199   AC_DEFINE([HAVE_SO_BINDANY], [1], [Have SO_BINDANY])
2200 ],[
2201   AC_MSG_RESULT([no])
2202 ])
2203
2204 dnl ----------------------
2205 dnl checking for IP_FREEBIND
2206 dnl ----------------------
2207 AC_MSG_CHECKING([for IP_FREEBIND])
2208 AC_COMPILE_IFELSE(
2209 [ AC_LANG_PROGRAM([[
2210         #include <netinet/in.h>
2211   ]], [[
2212         int opt = IP_FREEBIND;
2213   ]])
2214 ],[
2215   AC_MSG_RESULT([yes])
2216   AC_DEFINE([HAVE_IP_FREEBIND], [1], [Have IP_FREEBIND])
2217 ],[
2218   AC_MSG_RESULT([no])
2219 ])
2220
2221 dnl --------------------------------------
2222 dnl checking for be32dec existence or not
2223 dnl --------------------------------------
2224 AC_CHECK_DECLS([be32enc, be32dec], [], [], [
2225         #ifdef HAVE_SYS_ENDIAN_H
2226         #include <sys/endian.h>
2227         #endif
2228         #ifdef HAVE_ENDIAN_H
2229         #include <endian.h>
2230         #endif
2231 ])
2232
2233 dnl --------------------------------------
2234 dnl checking for clock_time monotonic struct and call
2235 dnl --------------------------------------
2236 AC_CHECK_DECL([CLOCK_MONOTONIC],
2237         [AC_CHECK_LIB([rt], [clock_gettime], [LIBS="$LIBS -lrt"])
2238          AC_DEFINE([HAVE_CLOCK_MONOTONIC], [1], [Have monotonic clock])
2239 ], [AC_MSG_RESULT([no])], [FRR_INCLUDES])
2240
2241 AC_SEARCH_LIBS([clock_nanosleep], [rt], [
2242   AC_DEFINE([HAVE_CLOCK_NANOSLEEP], [1], [Have clock_nanosleep()])
2243 ])
2244
2245 dnl --------------------------------------
2246 dnl checking for flex and bison
2247 dnl --------------------------------------
2248
2249 AM_PROG_LEX
2250 AC_MSG_CHECKING([version of flex])
2251 frr_ac_flex_version="$(eval $LEX -V | grep flex | head -n 1)"
2252 frr_ac_flex_version="${frr_ac_flex_version##* }"
2253 AC_MSG_RESULT([$frr_ac_flex_version])
2254 AX_COMPARE_VERSION([$frr_ac_flex_version], [lt], [2.5.20], [
2255   LEX="$SHELL $missing_dir/missing flex"
2256   if test -f "${srcdir}/lib/command_lex.c" -a -f "${srcdir}/lib/command_lex.h"; then
2257     AC_MSG_WARN([using pregenerated flex output files])
2258   else
2259     AC_MSG_ERROR([flex failure and pregenerated files not included (probably a git build)])
2260   fi
2261   AC_SUBST([LEX_OUTPUT_ROOT], [lex.yy])
2262   AC_SUBST([LEXLIB], [''])
2263 ])
2264
2265 AC_PROG_YACC
2266 dnl thanks GNU bison for this b*llshit...
2267 AC_MSG_CHECKING([version of bison])
2268 frr_ac_bison_version="$(eval $YACC -V | grep bison | head -n 1)"
2269 frr_ac_bison_version="${frr_ac_bison_version##* }"
2270 frr_ac_bison_missing="false"
2271 case "x${frr_ac_bison_version}x" in
2272   x2.7*)
2273     BISON_OPENBRACE='"'
2274     BISON_CLOSEBRACE='"'
2275     BISON_VERBOSE=''
2276     AC_MSG_RESULT([$frr_ac_bison_version - 2.7 or older])
2277     ;;
2278   x2.*|x1.*)
2279     AC_MSG_RESULT([$frr_ac_bison_version])
2280     AC_MSG_WARN([installed bison is too old.  Please install GNU bison 2.7.x or newer.])
2281     frr_ac_bison_missing="true"
2282     ;;
2283   x)
2284     AC_MSG_RESULT([none])
2285     AC_MSG_WARN([could not determine bison version.  Please install GNU bison 2.7.x or newer.])
2286     frr_ac_bison_missing="true"
2287     ;;
2288   x3.[012][^0-9]*)
2289     BISON_OPENBRACE='{'
2290     BISON_CLOSEBRACE='}'
2291     BISON_VERBOSE='-Dparse.error=verbose'
2292     AC_MSG_RESULT([$frr_ac_bison_version - 3.0 to 3.2])
2293     ;;
2294   *)
2295     BISON_OPENBRACE='{'
2296     BISON_CLOSEBRACE='}'
2297     BISON_VERBOSE='-Dparse.error=verbose -Wno-yacc'
2298     AC_MSG_RESULT([$frr_ac_bison_version - 3.3 or newer])
2299     ;;
2300 esac
2301 AC_SUBST([BISON_OPENBRACE])
2302 AC_SUBST([BISON_CLOSEBRACE])
2303 AC_SUBST([BISON_VERBOSE])
2304
2305 if $frr_ac_bison_missing; then
2306   YACC="$SHELL $missing_dir/missing bison -y"
2307   if test -f "${srcdir}/lib/command_parse.c" -a -f "${srcdir}/lib/command_parse.h"; then
2308     AC_MSG_WARN([using pregenerated bison output files])
2309   else
2310     AC_MSG_ERROR([bison failure and pregenerated files not included (probably a git build)])
2311   fi
2312 fi
2313
2314 dnl -------------------
2315 dnl capabilities checks
2316 dnl -------------------
2317 if test "$enable_capabilities" != "no"; then
2318   AC_MSG_CHECKING([whether prctl PR_SET_KEEPCAPS is available])
2319   AC_COMPILE_IFELSE(
2320   [ AC_LANG_PROGRAM([[
2321         #include <sys/prctl.h>
2322     ]], [[
2323         prctl(PR_SET_KEEPCAPS, 1, 0, 0, 0);
2324     ]])
2325   ],[AC_MSG_RESULT([yes])
2326      AC_DEFINE([HAVE_PR_SET_KEEPCAPS], [1], [prctl])
2327      frr_ac_keepcaps="yes"
2328   ],[AC_MSG_RESULT(no)
2329   ])
2330   if test "$frr_ac_keepcaps" = "yes"; then
2331     AC_CHECK_HEADERS([sys/capability.h])
2332   fi
2333   if test "$ac_cv_header_sys_capability_h" = "yes"; then
2334     AC_CHECK_LIB([cap], [cap_init],
2335       [AC_DEFINE([HAVE_LCAPS], [1], [Capabilities])
2336        LIBCAP="-lcap"
2337        frr_ac_lcaps="yes"]
2338     )
2339   fi
2340   if test "$frr_ac_scaps" = "yes" \
2341        -o "$frr_ac_lcaps" = "yes"; then
2342     AC_DEFINE([HAVE_CAPABILITIES], [1], [capabilities])
2343   fi
2344
2345   case "$host_os" in
2346   linux*)
2347     if test "$enable_clippy_only" != "yes"; then
2348     if test "$frr_ac_lcaps" != "yes"; then
2349       AC_MSG_ERROR([libcap and/or its headers were not found.  Running FRR without libcap support built in causes a huge performance penalty.])
2350     fi
2351     fi
2352     ;;
2353   esac
2354 else
2355   case "$host_os" in
2356   linux*)
2357     AC_MSG_WARN([Running FRR without libcap support built in causes a huge performance penalty.])
2358     ;;
2359   esac
2360 fi
2361 AC_SUBST([LIBCAP])
2362
2363 dnl ---------------------------
2364 dnl check for glibc 'backtrace'
2365 dnl ---------------------------
2366 if test "$enable_backtrace" != "no" ; then
2367   backtrace_ok=no
2368   PKG_CHECK_MODULES([UNWIND], [libunwind], [
2369     AC_DEFINE([HAVE_LIBUNWIND], [1], [libunwind])
2370     backtrace_ok=yes
2371   ], [
2372     true
2373   ])
2374
2375   if test "$backtrace_ok" = "no"; then
2376     AC_CHECK_HEADER([unwind.h], [
2377       AC_SEARCH_LIBS([unw_getcontext], [unwind], [
2378         AC_DEFINE([HAVE_LIBUNWIND], [1], [libunwind])
2379         backtrace_ok=yes
2380       ])
2381     ])
2382   fi
2383
2384   if test "$backtrace_ok" = "no"; then
2385     AC_CHECK_HEADER([execinfo.h], [
2386       AC_SEARCH_LIBS([backtrace], [execinfo], [
2387         AC_DEFINE([HAVE_GLIBC_BACKTRACE], [1], [Glibc backtrace])
2388         backtrace_ok=yes
2389       ],, [-lm])
2390     ])
2391   fi
2392
2393   if test "$enable_backtrace" = "yes" -a "$backtrace_ok" = "no"; then
2394     dnl user explicitly requested backtrace but we failed to find support
2395     AC_MSG_FAILURE([failed to find backtrace or libunwind support])
2396   fi
2397 fi
2398
2399 dnl -----------------------------------------
2400 dnl check for malloc mallinfo struct and call
2401 dnl this must try and link using LIBS, in
2402 dnl order to check no alternative allocator
2403 dnl has been specified, which might not provide
2404 dnl mallinfo
2405 dnl -----------------------------------------
2406 AC_CHECK_HEADERS([malloc.h malloc_np.h malloc/malloc.h],,, [FRR_INCLUDES])
2407
2408 AC_CACHE_CHECK([whether mallinfo is available], [frr_cv_mallinfo], [
2409   AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2410 #ifdef HAVE_MALLOC_H
2411 #include <malloc.h>
2412 #endif
2413 #ifdef HAVE_MALLOC_NP_H
2414 #include <malloc_np.h>
2415 #endif
2416 #ifdef HAVE_MALLOC_MALLOC_H
2417 #include <malloc/malloc.h>
2418 #endif
2419 ]], [[
2420 struct mallinfo ac_x; ac_x = mallinfo ();
2421 ]])], [
2422     frr_cv_mallinfo=yes
2423   ], [
2424     frr_cv_mallinfo=no
2425   ])
2426 ])
2427 if test "$frr_cv_mallinfo" = "yes"; then
2428   AC_DEFINE([HAVE_MALLINFO], [1], [mallinfo])
2429 fi
2430
2431 AC_CACHE_CHECK([whether mallinfo2 is available], [frr_cv_mallinfo2], [
2432   AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2433 #ifdef HAVE_MALLOC_H
2434 #include <malloc.h>
2435 #endif
2436 #ifdef HAVE_MALLOC_NP_H
2437 #include <malloc_np.h>
2438 #endif
2439 #ifdef HAVE_MALLOC_MALLOC_H
2440 #include <malloc/malloc.h>
2441 #endif
2442 ]], [[
2443 struct mallinfo2 ac_x; ac_x = mallinfo2 ();
2444 ]])], [
2445     frr_cv_mallinfo2=yes
2446   ], [
2447     frr_cv_mallinfo2=no
2448   ])
2449 ])
2450 if test "$frr_cv_mallinfo2" = "yes"; then
2451   AC_DEFINE([HAVE_MALLINFO2], [1], [mallinfo2])
2452 fi
2453
2454 AC_MSG_CHECKING([whether malloc_usable_size is available])
2455 AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2456 #ifdef HAVE_MALLOC_H
2457 #include <malloc.h>
2458 #endif
2459 #ifdef HAVE_MALLOC_MALLOC_H
2460 #include <malloc/malloc.h>
2461 #endif
2462 ]], [[
2463 size_t ac_x; ac_x = malloc_usable_size(NULL);
2464 ]])], [
2465   AC_MSG_RESULT([yes])
2466   AC_DEFINE([HAVE_MALLOC_USABLE_SIZE], [1], [malloc_usable_size])
2467 ], [
2468   AC_MSG_RESULT([no])
2469
2470   AC_MSG_CHECKING([whether malloc_size is available])
2471   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2472 #ifdef HAVE_MALLOC_H
2473 #include <malloc.h>
2474 #endif
2475 #ifdef HAVE_MALLOC_MALLOC_H
2476 #include <malloc/malloc.h>
2477 #endif
2478 ]], [[
2479 size_t ac_x; ac_x = malloc_size(NULL);
2480 ]])], [
2481     AC_MSG_RESULT([yes])
2482     AC_DEFINE([HAVE_MALLOC_SIZE], [1], [malloc_size])
2483   ], [
2484     AC_MSG_RESULT([no])
2485   ])
2486 ])
2487
2488 dnl ----------
2489 dnl configure date
2490 dnl ----------
2491 dev_version=`echo $VERSION | grep dev`
2492 #don't expire deprecated code in non 'dev' branch
2493 if test "$dev_version" = ""; then
2494    CONFDATE=0
2495 else
2496    CONFDATE=`date '+%Y%m%d'`
2497 fi
2498 AC_SUBST([CONFDATE])
2499
2500 dnl ------------------------------
2501 dnl set paths for state directory
2502 dnl ------------------------------
2503 AC_MSG_CHECKING([directory to use for state file])
2504 if test "$prefix" = "NONE"; then
2505   frr_statedir_prefix="";
2506 else
2507   frr_statedir_prefix=${prefix}
2508 fi
2509 if test "$localstatedir" = '${prefix}/var'; then
2510   for FRR_STATE_DIR in ${frr_statedir_prefix}/var/run dnl
2511                         ${frr_statedir_prefix}/var/adm dnl
2512                         ${frr_statedir_prefix}/etc dnl
2513                         /var/run        dnl
2514                         /var/adm        dnl
2515                         /etc            dnl
2516                         /dev/null;
2517   do
2518     test -d $FRR_STATE_DIR && break
2519   done
2520   frr_statedir=$FRR_STATE_DIR
2521 else
2522   frr_statedir=${localstatedir}
2523 fi
2524 if test "$frr_statedir" = "/dev/null"; then
2525     AC_MSG_ERROR([STATE DIRECTORY NOT FOUND! FIX OR SPECIFY --localstatedir!])
2526 fi
2527 AC_MSG_RESULT([${frr_statedir}])
2528 AC_SUBST([frr_statedir])
2529
2530 AC_DEFINE_UNQUOTED([LDPD_SOCKET], ["$frr_statedir%s%s/ldpd.sock"], [ldpd control socket])
2531 AC_DEFINE_UNQUOTED([ZEBRA_SERV_PATH], ["$frr_statedir%s%s/zserv.api"], [zebra api socket])
2532 AC_DEFINE_UNQUOTED([BFDD_CONTROL_SOCKET], ["$frr_statedir%s%s/bfdd.sock"], [bfdd control socket])
2533 AC_DEFINE_UNQUOTED([DAEMON_VTY_DIR], ["$frr_statedir%s%s"], [daemon vty directory])
2534 AC_DEFINE_UNQUOTED([DAEMON_DB_DIR], ["$frr_statedir"], [daemon database directory])
2535
2536 dnl autoconf does this, but it does it too late...
2537 test "$prefix" = "NONE" && prefix=$ac_default_prefix
2538 test "$exec_prefix" = "NONE" && exec_prefix='${prefix}'
2539
2540 dnl get the full path, recursing through variables...
2541 vtysh_bin="$bindir/vtysh"
2542 for I in 1 2 3 4 5 6 7 8 9 10; do
2543         eval vtysh_bin="\"$vtysh_bin\""
2544 done
2545 AC_DEFINE_UNQUOTED([VTYSH_BIN_PATH], ["$vtysh_bin"], [path to vtysh binary])
2546 AC_SUBST([vtysh_bin])
2547
2548 CFG_SYSCONF="$sysconfdir"
2549 CFG_SBIN="$sbindir"
2550 CFG_STATE="$frr_statedir"
2551 CFG_MODULE="$moduledir"
2552 CFG_YANGMODELS="$yangmodelsdir"
2553 CFG_SCRIPT="$scriptdir"
2554 for I in 1 2 3 4 5 6 7 8 9 10; do
2555         eval CFG_SYSCONF="\"$CFG_SYSCONF\""
2556         eval CFG_SBIN="\"$CFG_SBIN\""
2557         eval CFG_STATE="\"$CFG_STATE\""
2558         eval CFG_MODULE="\"$CFG_MODULE\""
2559         eval CFG_YANGMODELS="\"$CFG_YANGMODELS\""
2560         eval CFG_SCRIPT="\"$CFG_SCRIPT\""
2561 done
2562 AC_SUBST([CFG_SYSCONF])
2563 AC_SUBST([CFG_SBIN])
2564 AC_SUBST([CFG_STATE])
2565 AC_SUBST([CFG_MODULE])
2566 AC_SUBST([CFG_SCRIPT])
2567 AC_SUBST([CFG_YANGMODELS])
2568 AC_DEFINE_UNQUOTED([MODULE_PATH], ["$CFG_MODULE"], [path to modules])
2569 AC_DEFINE_UNQUOTED([SCRIPT_PATH], ["$CFG_SCRIPT"], [path to scripts])
2570 AC_DEFINE_UNQUOTED([YANG_MODELS_PATH], ["$CFG_YANGMODELS"], [path to YANG data models])
2571 AC_DEFINE_UNQUOTED([WATCHFRR_SH_PATH], ["${CFG_SBIN%/}/watchfrr.sh"], [path to watchfrr.sh])
2572
2573 dnl various features
2574 AM_CONDITIONAL([SUPPORT_REALMS], [test "$enable_realms" = "yes"])
2575 AM_CONDITIONAL([ENABLE_BGP_VNC], [test "$enable_bgp_vnc" != "no"])
2576 AM_CONDITIONAL([BGP_BMP], [$bgpd_bmp])
2577 dnl northbound
2578 AM_CONDITIONAL([SQLITE3], [$SQLITE3])
2579 AM_CONDITIONAL([CONFD], [test "$enable_confd" != ""])
2580 AM_CONDITIONAL([SYSREPO], [test "$enable_sysrepo" = "yes"])
2581 AM_CONDITIONAL([GRPC], [test "$enable_grpc" = "yes"])
2582 AM_CONDITIONAL([ZEROMQ], [test "$ZEROMQ" = "true"])
2583 dnl plugins
2584 AM_CONDITIONAL([RPKI], [test "$RPKI" = "true"])
2585 AM_CONDITIONAL([SNMP], [test "$SNMP_METHOD" = "agentx"])
2586 AM_CONDITIONAL([IRDP], [$IRDP])
2587 AM_CONDITIONAL([FPM], [test "$enable_fpm" = "yes"])
2588 AM_CONDITIONAL([HAVE_PROTOBUF], [test "$enable_protobuf" = "yes"])
2589 AM_CONDITIONAL([HAVE_PROTOBUF3], [$PROTO3])
2590
2591 dnl PCEP plugin
2592 AS_IF([test "$enable_pathd" != "no"], [
2593        AC_SUBST([PATHD_PCEP_LIBS], ["pceplib/libpcep_pcc.la"])
2594        AC_SUBST([PATHD_PCEP_INCL], ["-I./pceplib "])
2595        ])
2596 AC_CHECK_LIB([cunit], [CU_initialize_registry], [pcep_cunit=yes],[pcep_cunit=no])
2597 AM_CONDITIONAL([PATHD_PCEP_TEST], [test "x${pcep_cunit}" = xyes])
2598 AC_CHECK_PROG(VALGRIND_CHECK, valgrind, yes)
2599 AM_CONDITIONAL([HAVE_VALGRIND_PCEP], [test "$VALGRIND_CHECK" = "yes"])
2600
2601 dnl daemons
2602 AM_CONDITIONAL([VTYSH], [test "$VTYSH" = "vtysh"])
2603 AM_CONDITIONAL([ZEBRA], [test "$enable_zebra" != "no"])
2604 AM_CONDITIONAL([BGPD], [test "$enable_bgpd" != "no"])
2605 AM_CONDITIONAL([RIPD], [test "$enable_ripd" != "no"])
2606 AM_CONDITIONAL([OSPFD], [test "$enable_ospfd" != "no"])
2607 AM_CONDITIONAL([LDPD], [test "$enable_ldpd" != "no"])
2608 AM_CONDITIONAL([BFDD], [test "$BFDD" = "bfdd"])
2609 AM_CONDITIONAL([NHRPD], [test "$NHRPD" = "nhrpd"])
2610 AM_CONDITIONAL([EIGRPD], [test "$enable_eigrpd" != "no"])
2611 AM_CONDITIONAL([WATCHFRR], [test "$WATCHFRR" = "watchfrr"])
2612 AM_CONDITIONAL([OSPFCLIENT], [test "$OSPFCLIENT" = "ospfclient"])
2613 AM_CONDITIONAL([RIPNGD], [test "$enable_ripngd" != "no"])
2614 AM_CONDITIONAL([BABELD], [test "$enable_babeld" != "no"])
2615 AM_CONDITIONAL([OSPF6D], [test "$enable_ospf6d" != "no"])
2616 AM_CONDITIONAL([ISISD], [test "$enable_isisd" != "no"])
2617 AM_CONDITIONAL([PIMD], [test "$enable_pimd" != "no"])
2618 AM_CONDITIONAL([PBRD], [test "$enable_pbrd" != "no"])
2619 AM_CONDITIONAL([SHARPD], [test "$enable_sharpd" = "yes"])
2620 AM_CONDITIONAL([STATICD], [test "$enable_staticd" != "no"])
2621 AM_CONDITIONAL([FABRICD], [test "$enable_fabricd" != "no"])
2622 AM_CONDITIONAL([VRRPD], [test "$enable_vrrpd" != "no"])
2623 AM_CONDITIONAL([PATHD], [test "$enable_pathd" != "no"])
2624 AM_CONDITIONAL([PATHD_PCEP], [test "$enable_pathd" != "no"])
2625
2626 AC_CONFIG_FILES([Makefile],[
2627         test "$enable_dev_build" = "yes" && makefile_devbuild="--dev-build"
2628         ${PYTHON} "${ac_abs_top_srcdir}/python/makefile.py" ${makefile_devbuild} || exit 1
2629 ], [
2630         PYTHON="$PYTHON"
2631         enable_dev_build="$enable_dev_build"
2632 ])
2633
2634 AC_CONFIG_FILES([
2635           config.version
2636           changelog-auto
2637           redhat/frr.spec
2638           alpine/APKBUILD
2639           snapcraft/snapcraft.yaml
2640           lib/version.h
2641           tests/lib/cli/test_cli.refout
2642           pkgsrc/bgpd.sh pkgsrc/ospf6d.sh pkgsrc/ospfd.sh
2643           pkgsrc/ripd.sh pkgsrc/ripngd.sh pkgsrc/zebra.sh
2644           pkgsrc/eigrpd.sh])
2645
2646 AC_CONFIG_FILES([vtysh/extract.pl], [chmod +x vtysh/extract.pl])
2647 AC_CONFIG_FILES([tools/frr], [chmod +x tools/frr])
2648 AC_CONFIG_FILES([tools/watchfrr.sh], [chmod +x tools/watchfrr.sh])
2649 AC_CONFIG_FILES([tools/frrinit.sh], [chmod +x tools/frrinit.sh])
2650 AC_CONFIG_FILES([tools/frrcommon.sh])
2651 AC_CONFIG_FILES([tools/frr.service])
2652 AC_CONFIG_FILES([tools/frr@.service])
2653
2654 AS_IF([test "$with_pkg_git_version" = "yes"], [
2655     AC_CONFIG_COMMANDS([lib/gitversion.h], [
2656         dst="${ac_abs_top_builddir}/lib/gitversion.h"
2657         ${PERL} "${ac_abs_top_srcdir}/lib/gitversion.pl" \
2658                 "${ac_abs_top_srcdir}" \
2659                 > "${dst}.tmp"
2660         test -f "$dst" \
2661                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
2662                 && rm "${dst}.tmp" \
2663                 || mv "${dst}.tmp" "${dst}"
2664     ], [
2665         PERL="$PERL"
2666     ])
2667 ])
2668
2669 ## Hack, but working solution to avoid rebuilding of frr.info.
2670 ## It's already in CVS until texinfo 4.7 is more common.
2671 AC_OUTPUT
2672
2673 if test "$enable_rpath" = "yes" ; then
2674         true
2675 else
2676         # See https://old-en.opensuse.org/openSUSE:Packaging_Guidelines#Removing_Rpath
2677         sed -i 's|^hardcode_libdir_flag_spec=.*|hardcode_libdir_flag_spec=""|g' libtool
2678         sed -i 's|^runpath_var=LD_RUN_PATH|runpath_var=DIE_RPATH_DIE|g' libtool
2679 fi
2680
2681 echo "
2682 FRRouting configuration
2683 ------------------------------
2684 FRR version             : ${PACKAGE_VERSION}
2685 host operating system   : ${host_os}
2686 source code location    : ${srcdir}
2687 compiler                : ${CC}
2688 compiler flags          : ${CFLAGS} ${AC_CFLAGS} ${SAN_FLAGS}
2689 make                    : ${MAKE-make}
2690 linker flags            : ${LDFLAGS} ${SAN_FLAGS} ${LIBS} ${LIBCAP} ${LIBREADLINE} ${LIBM}
2691 state file directory    : ${frr_statedir}
2692 config file directory   : `eval echo \`echo ${sysconfdir}\``
2693 example directory       : `eval echo \`echo ${exampledir}\``
2694 module directory        : ${CFG_MODULE}
2695 script directory        : ${CFG_SCRIPT}
2696 user to run as          : ${enable_user}
2697 group to run as         : ${enable_group}
2698 group for vty sockets   : ${enable_vty_group}
2699 config file mask        : ${enable_configfile_mask}
2700 log file mask           : ${enable_logfile_mask}
2701 zebra protobuf enabled  : ${enable_protobuf:-no}
2702 vici socket path        : ${vici_socket}
2703
2704 The above user and group must have read/write access to the state file
2705 directory and to the config files in the config file directory."
2706
2707 if test "$enable_doc" != "no" -a "$frr_py_mod_sphinx" = "false"; then
2708   AC_MSG_WARN([sphinx is missing but required to build documentation])
2709 fi
2710 if test "$frr_py_mod_pytest" = "false"; then
2711   AC_MSG_WARN([pytest is missing, unit tests cannot be performed])
2712 fi