configure.ac

   1 ##
   2 ## Configure template file for FRRouting.
   3 ## autoconf will generate a configure script.
   4 ##
   5 ##  Copyright (c) 1996, 97, 98, 99, 2000 Kunihiro Ishiguro <kunihiro@zebra.org>
   6 ##  Portions Copyright (c) 2003 Paul Jakma <paul@dishone.st>
   7 ##
   8 AC_PREREQ([2.60])
   9
  10 AC_INIT([frr], [7.2-dev], [https://github.com/frrouting/frr/issues])
  11 PACKAGE_URL="https://frrouting.org/"
  12 AC_SUBST([PACKAGE_URL])
  13 PACKAGE_FULLNAME="FRRouting"
  14 AC_SUBST([PACKAGE_FULLNAME])
  15
  16 CONFIG_ARGS="`echo $ac_configure_args | sed -e \"s% '[[A-Z]]*FLAGS=[[^']]\+'%%g\"`"
  17 AC_SUBST([CONFIG_ARGS])
  18
  19 AC_CONFIG_SRCDIR([lib/zebra.h])
  20 AC_CONFIG_MACRO_DIR([m4])
  21
  22 dnl -----------------------------------
  23 dnl Get hostname and other information.
  24 dnl -----------------------------------
  25 AC_CANONICAL_BUILD()
  26 AC_CANONICAL_HOST()
  27
  28 hosttools_clippy="false"
  29 build_clippy="true"
  30
  31 dnl case 1: external clippy
  32 if test -n "$with_clippy" -a "$with_clippy" != "no" -a "$with_clippy" != "yes"; then
  33   if test "$enable_clippy_only" == "yes"; then
  34     AC_MSG_ERROR([--enable-clippy-only does not make sense with --with-clippy])
  35   fi
  36
  37   CLIPPY="$with_clippy"
  38   build_clippy="false"
  39   if test ! -x "$with_clippy"; then
  40     AC_MSG_ERROR([clippy tool ($with_clippy) is not executable])
  41   fi
  42
  43 dnl case 2: cross-compiling internal clippy
  44 elif test "$host" != "$build"; then
  45   if test "$srcdir" = "."; then
  46     AC_MSG_ERROR([cross-compilation is only possible with builddir separate from srcdir or by building clippy separately and using the --with-clippy option.  create a separate directory and run as .../path-to-frr/configure.])
  47   fi
  48   test -d hosttools || mkdir hosttools
  49   abssrc="`cd \"${srcdir}\"; pwd`"
  50
  51   AC_MSG_NOTICE([...])
  52   AC_MSG_NOTICE([... cross-compilation: creating hosttools directory and self-configuring for build platform tools])
  53   AC_MSG_NOTICE([... use HOST_CPPFLAGS / HOST_CFLAGS / HOST_LDFLAGS if neccessary])
  54   AC_MSG_NOTICE([...])
  55
  56   (
  57     for var in $ac_precious_vars; do
  58       dnl special cases
  59       case "$var" in
  60       YACC|YFLAGS) continue;;
  61       PYTHON*)     retain=true;;
  62       *)           retain=false;
  63       esac
  64
  65       eval "hostvar=\"\${HOST_$var}\""
  66       eval "targetvar=\"\${$var}\""
  67       if test -n "$hostvar"; then
  68         eval "$var='$hostvar'"
  69         _AS_ECHO_LOG([host $var='$hostvar'])
  70       elif $retain; then
  71         _AS_ECHO_LOG([host retain $var='$targetvar'])
  72       else
  73         eval "unset $var"
  74         _AS_ECHO_LOG([host unset $var])
  75       fi
  76     done
  77     cd hosttools
  78     "${abssrc}/configure" "--host=$build" "--build=$build" "--enable-clippy-only" "--disable-nhrpd" "--disable-vtysh"
  79   ) || exit 1
  80
  81   AC_MSG_NOTICE([...])
  82   AC_MSG_NOTICE([... cross-compilation: finished self-configuring for build platform tools])
  83   AC_MSG_NOTICE([...])
  84
  85   build_clippy="false"
  86   hosttools_clippy="true"
  87   CLIPPY="hosttools/lib/clippy"
  88
  89 dnl case 3: normal build internal clippy
  90 else
  91   CLIPPY="lib/clippy\$(EXEEXT)"
  92 fi
  93 AC_SUBST([CLIPPY])
  94 AM_CONDITIONAL([BUILD_CLIPPY], [$build_clippy])
  95 AM_CONDITIONAL([HOSTTOOLS_CLIPPY], [$hosttools_clippy])
  96 AM_CONDITIONAL([ONLY_CLIPPY], [test "$enable_clippy_only" = "yes"])
  97
  98 # Disable portability warnings -- our automake code (in particular
  99 # common.am) uses some constructs specific to gmake.
 100 AM_INIT_AUTOMAKE([1.12 -Wno-portability foreign])
 101 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
 102 AM_SILENT_RULES([yes])
 103 AC_CONFIG_HEADERS([config.h])
 104
 105 AC_PATH_PROG([PERL], [perl])
 106 PKG_PROG_PKG_CONFIG
 107
 108 dnl default is to match previous behavior
 109 exampledir=${sysconfdir}
 110 AC_ARG_ENABLE([exampledir],
 111           AS_HELP_STRING([--enable-exampledir],
 112                          [specify alternate directory for examples]),
 113                          exampledir="$enableval",)
 114 dnl XXX add --exampledir to autoconf standard directory list somehow
 115 AC_SUBST([exampledir])
 116
 117 dnl default is to match previous behavior
 118 pkgsrcrcdir=""
 119 AC_ARG_ENABLE([pkgsrcrcdir],
 120           AS_HELP_STRING([--enable-pkgsrcrcdir],
 121                          [specify directory for rc.d scripts]),
 122                          pkgsrcrcdir="$enableval",)
 123 dnl XXX add --pkgsrcrcdir to autoconf standard directory list somehow
 124 AC_SUBST([pkgsrcrcdir])
 125 AM_CONDITIONAL([PKGSRC], [test "x$pkgsrcrcdir" != "x"])
 126
 127 AC_ARG_WITH([moduledir], [AS_HELP_STRING([--with-moduledir=DIR], [module directory (${libdir}/frr/modules)])], [
 128         moduledir="$withval"
 129 ], [
 130         moduledir="\${libdir}/frr/modules"
 131 ])
 132 AC_SUBST([moduledir], [$moduledir])
 133
 134
 135 AC_ARG_WITH([yangmodelsdir], [AS_HELP_STRING([--with-yangmodelsdir=DIR], [yang models directory (${datarootdir}/yang)])], [
 136         yangmodelsdir="$withval"
 137 ], [
 138         yangmodelsdir="\${datarootdir}/yang"
 139 ])
 140 AC_SUBST([yangmodelsdir])
 141
 142 AC_ARG_WITH([libyang_pluginsdir], [AS_HELP_STRING([--with-libyang-pluginsdir=DIR], [yangmodule plugins directory (${libdir}/frr/libyang_plugins)])], [
 143         libyang_pluginsdir="$withval"
 144 ], [
 145    libyang_pluginsdir="\${libdir}/frr/libyang_plugins"
 146 ])
 147 AC_SUBST([libyang_pluginsdir])
 148
 149 AC_ARG_ENABLE(tcmalloc,
 150         AS_HELP_STRING([--enable-tcmalloc], [Turn on tcmalloc]),
 151 [case "${enableval}" in
 152   yes) tcmalloc_enabled=true
 153 LIBS="$LIBS -ltcmalloc_minimal"
 154  ;;
 155   no)  tcmalloc_enabled=false ;;
 156   *) AC_MSG_ERROR([bad value ${enableval} for --enable-tcmalloc]) ;;
 157 esac],[tcmalloc_enabled=false])
 158
 159
 160 dnl Thanks autoconf, but we don't want a default -g -O2.  We have our own
 161 dnl flag determination logic.
 162 CFLAGS="${CFLAGS:-}"
 163
 164 dnl --------------------
 165 dnl Check CC and friends
 166 dnl --------------------
 167 dnl note orig_cflags is also used further down
 168 orig_cflags="$CFLAGS"
 169 orig_cxxflags="$CXXFLAGS"
 170 AC_LANG([C])
 171 AC_PROG_CC
 172 AC_PROG_CPP
 173 AC_PROG_CXX
 174 AM_PROG_CC_C_O
 175 dnl remove autoconf default "-g -O2"
 176 CFLAGS="$orig_cflags"
 177 CXXFLAGS="$orig_cxxflags"
 178 AC_PROG_CC_C99
 179 dnl NB: see C11 below
 180
 181 PKG_PROG_PKG_CONFIG
 182
 183 dnl it's 2019, sed is sed.
 184 SED=sed
 185 AC_SUBST([SED])
 186
 187 dnl try and enable CFLAGS that are useful for FRR
 188 dnl - specifically, options to control warnings
 189
 190 AC_USE_SYSTEM_EXTENSIONS
 191 AC_DEFUN([AC_C_FLAG], [{
 192     m4_pushdef([cachename],[m4_translit([frr_cv_$1],[ =-+],[____])])
 193     AC_CACHE_CHECK([[whether $CC supports $1]], cachename, [
 194         AC_LANG_PUSH([C])
 195         ac_c_flag_save="$CFLAGS"
 196         CFLAGS="$CFLAGS $1"
 197         AC_COMPILE_IFELSE(
 198                 [AC_LANG_PROGRAM([[]])],
 199                 [
 200                         cachename=yes
 201                 ], [
 202                         cachename=no
 203                 ])
 204         CFLAGS="$ac_c_flag_save"
 205         AC_LANG_POP([C])
 206     ])
 207     if test "${cachename}" = yes; then
 208         m4_if([$3], [], [CFLAGS="$CFLAGS $1"], [$3])
 209     else
 210         :
 211         $2
 212     fi
 213     m4_popdef([cachename])
 214 }])
 215
 216 AC_DEFUN([AC_LINK_IFELSE_FLAGS], [{
 217         AC_LANG_PUSH([C])
 218         ac_cflags_save="$CFLAGS"
 219         ac_libs_save="$LIBS"
 220         CFLAGS="$CFLAGS $1"
 221         LIBS="$LIBS $2"
 222         AC_LINK_IFELSE(
 223                 [$3],
 224                 [
 225                         CFLAGS="$ac_cflags_save"
 226                         LIBS="$ac_libs_save"
 227                         m4_default([$5], [
 228                                 AC_MSG_RESULT([yes])
 229                         ])
 230                 ], [
 231                         CFLAGS="$ac_cflags_save"
 232                         LIBS="$ac_libs_save"
 233                         m4_default([$4], [
 234                                 AC_MSG_RESULT([no])
 235                         ])
 236                 ])
 237         AC_LANG_POP([C])
 238         }])
 239
 240 dnl ICC won't bail on unknown options without -diag-error 10006
 241 dnl need to do this first so we get useful results for the other options
 242 AC_C_FLAG([-diag-error 10006])
 243
 244 dnl AC_PROG_CC_C99 may change CC to include -std=gnu99 or something
 245 ac_cc="$CC"
 246 CC="${CC% -std=gnu99}"
 247 CC="${CC% -std=c99}"
 248
 249 AC_C_FLAG([-std=gnu11], [CC="$ac_cc"], [CC="$CC -std=gnu11"])
 250
 251 dnl if the user has specified any CFLAGS, override our settings
 252 if test "x${enable_gcov}" = "xyes"; then
 253    if test "z$orig_cflags" = "z"; then
 254       AC_C_FLAG([-coverage])
 255       AC_C_FLAG([-O0])
 256    fi
 257
 258    LDFLAGS="${LDFLAGS} -lgcov"
 259 elif test "x${enable_dev_build}" = "xyes"; then
 260    AC_DEFINE([DEV_BUILD], [1], [Build for development])
 261    if test "z$orig_cflags" = "z"; then
 262       AC_C_FLAG([-g3])
 263       AC_C_FLAG([-O0])
 264    fi
 265    if test "x${enable_lua}" = "xyes"; then
 266       AX_PROG_LUA([5.3])
 267       AX_LUA_HEADERS
 268       AX_LUA_LIBS([
 269          AC_DEFINE([HAVE_LUA], [1], [Have support for Lua interpreter])
 270          LIBS="$LIBS $LUA_LIB"
 271       ])
 272    fi
 273 else
 274    if test "x${enable_lua}" = "xyes"; then
 275       AC_MSG_ERROR([Lua is not meant to be built/used outside of development at this time])
 276    fi
 277    if test "z$orig_cflags" = "z"; then
 278       AC_C_FLAG([-g])
 279       AC_C_FLAG([-O2])
 280    fi
 281 fi
 282 AM_CONDITIONAL([DEV_BUILD], [test "x$enable_dev_build" = "xyes"])
 283
 284 dnl always want these CFLAGS
 285 AC_C_FLAG([-fno-omit-frame-pointer])
 286 AC_C_FLAG([-funwind-tables])
 287 AC_C_FLAG([-Wall])
 288 AC_C_FLAG([-Wextra])
 289 AC_C_FLAG([-Wmissing-prototypes])
 290 AC_C_FLAG([-Wmissing-declarations])
 291 AC_C_FLAG([-Wpointer-arith])
 292 AC_C_FLAG([-Wbad-function-cast])
 293 AC_C_FLAG([-Wwrite-strings])
 294 if test x"${enable_gcc_ultra_verbose}" = x"yes" ; then
 295   AC_C_FLAG([-Wcast-qual])
 296   AC_C_FLAG([-Wstrict-prototypes])
 297   AC_C_FLAG([-Wmissing-noreturn])
 298   AC_C_FLAG([-Wmissing-format-attribute])
 299   AC_C_FLAG([-Wunreachable-code])
 300   AC_C_FLAG([-Wpacked])
 301   AC_C_FLAG([-Wpadded])
 302   AC_C_FLAG([-Wshadow])
 303 else
 304   AC_C_FLAG([-Wno-unused-result])
 305 fi
 306 AC_C_FLAG([-Wno-unused-parameter])
 307 AC_C_FLAG([-Wno-missing-field-initializers])
 308
 309 AC_C_FLAG([-Wc++-compat], [], [CXX_COMPAT_CFLAGS="-Wc++-compat"])
 310 AC_SUBST([CXX_COMPAT_CFLAGS])
 311
 312 dnl ICC emits a broken warning for const char *x = a ? "b" : "c";
 313 dnl for some reason the string consts get 'promoted' to char *,
 314 dnl triggering a const to non-const conversion warning.
 315 AC_C_FLAG([-diag-disable 3179])
 316
 317 if test x"${enable_werror}" = x"yes" ; then
 318   WERROR="-Werror"
 319 fi
 320 AC_SUBST([WERROR])
 321
 322 SAN_FLAGS=""
 323 if test "$enable_address_sanitizer" = "yes"; then
 324   AC_C_FLAG([-fsanitize=address], [
 325     AC_MSG_ERROR([$CC does not support Address Sanitizer.])
 326   ], [
 327     SAN_FLAGS="$SAN_FLAGS -fsanitize=address"
 328   ])
 329 fi
 330 if test "$enable_thread_sanitizer" = "yes"; then
 331   AC_C_FLAG([-fsanitize=thread], [
 332     AC_MSG_ERROR([$CC does not support Thread Sanitizer.])
 333   ], [
 334     SAN_FLAGS="$SAN_FLAGS -fsanitize=thread"
 335   ])
 336 fi
 337 if test "$enable_memory_sanitizer" = "yes"; then
 338   AC_C_FLAG([-fsanitize=thread -fPIE -pie], [
 339     AC_MSG_ERROR([$CC does not support Thread Sanitizer.])
 340   ], [
 341     SAN_FLAGS="-fsanitize=memory -fPIE -pie"
 342   ])
 343 fi
 344 AC_SUBST([SAN_FLAGS])
 345
 346 dnl ----------
 347 dnl Essentials
 348 dnl ----------
 349
 350 AX_PTHREAD([
 351   CC="$PTHREAD_CC"
 352   CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 353   LIBS="$PTHREAD_LIBS $LIBS"
 354 ], [
 355   AC_MSG_FAILURE([This FRR version needs pthreads])
 356 ])
 357
 358 AC_SEARCH_LIBS([pthread_condattr_setclock], [],
 359                 [frr_cv_pthread_condattr_setclock=yes],
 360                 [frr_cv_pthread_condattr_setclock=no])
 361 if test "$frr_cv_pthread_condattr_setclock" = yes; then
 362   AC_DEFINE([HAVE_PTHREAD_CONDATTR_SETCLOCK], [1], [Have pthread.h pthread_condattr_setclock])
 363 fi
 364
 365 dnl --------------
 366 dnl Check programs
 367 dnl --------------
 368 AC_PROG_INSTALL
 369 AC_PROG_LN_S
 370 AC_CHECK_TOOL([AR], [ar])
 371
 372 dnl -------
 373 dnl libtool
 374 dnl -------
 375 AC_ARG_ENABLE([static-bin],
 376   AS_HELP_STRING([--enable-static-bin], [link binaries statically]))
 377 LT_INIT
 378 _LT_CONFIG_LIBTOOL([
 379   patch -N -i "${srcdir}/m4/libtool-whole-archive.patch" libtool >&AS_MESSAGE_LOG_FD || \
 380     AC_MSG_WARN([Could not patch libtool for static linking support.  Loading modules into a statically linked daemon will fail.])
 381 ])
 382 if test "$enable_static_bin" = "yes"; then
 383   AC_LDFLAGS="-static"
 384   if test "$enable_static" != "yes"; then
 385     AC_MSG_ERROR([The --enable-static-bin option must be combined with --enable-static.])
 386   fi
 387 fi
 388 if test "$enable_shared" != "yes"; then
 389   AC_MSG_ERROR([FRR cannot be built with --disable-shared.  If you want statically linked daemons, use --enable-shared --enable-static --enable-static-bin])
 390 fi
 391 AC_SUBST([AC_LDFLAGS])
 392 AM_CONDITIONAL([STATIC_BIN], [test "x$enable_static_bin" = "xyes"])
 393
 394 dnl $AR and $RANLIB are set by LT_INIT above
 395 AC_MSG_CHECKING([whether $AR supports D option])
 396 if $AR crD conftest.a >/dev/null 2>/dev/null; then
 397   AC_MSG_RESULT([yes])
 398   dnl ARFLAGS is for automake, AR_FLAGS for libtool m-(
 399   ARFLAGS="crD"
 400   AR_FLAGS="crD"
 401 else
 402   AC_MSG_RESULT([no])
 403   ARFLAGS="cru"
 404   AR_FLAGS="cru"
 405 fi
 406 AC_SUBST([ARFLAGS])
 407 AC_SUBST([AR_FLAGS])
 408
 409 AC_MSG_CHECKING([whether $RANLIB supports D option])
 410 if $RANLIB -D conftest.a >conftest.err 2>&1; then
 411   if grep -q -- '-D' conftest.err; then
 412     AC_MSG_RESULT([no])
 413   else
 414     AC_MSG_RESULT([yes])
 415     RANLIB="$RANLIB -D"
 416   fi
 417 else
 418   AC_MSG_RESULT([no])
 419 fi
 420 AC_SUBST([RANLIB])
 421
 422 test -f conftest.err && rm conftest.err
 423 test -f conftest.a && rm conftest.a
 424
 425 dnl ----------------------
 426 dnl Packages configuration
 427 dnl ----------------------
 428 if test -f config.version; then
 429   . ./config.version
 430 elif test -f "${srcdir}/config.version"; then
 431   . "${srcdir}/config.version"
 432 fi
 433 AC_ARG_WITH([pkg-extra-version],
 434   AS_HELP_STRING([--with-pkg-extra-version=VER], [add extra version field, for packagers/distributions]), [
 435   if test "$withval" = "no"; then
 436     EXTRAVERSION=
 437   else
 438     EXTRAVERSION=$withval
 439   fi
 440 ], [])
 441 AC_ARG_WITH([pkg-git-version],
 442         AS_HELP_STRING([--with-pkg-git-version], [add git information to MOTD and build version string]),
 443         [ test "x$withval" != "xno" && with_pkg_git_version="yes" ])
 444 AC_ARG_WITH([clippy],
 445   AS_HELP_STRING([--with-clippy=PATH], [use external clippy helper program]))
 446 AC_ARG_WITH([vtysh_pager],
 447         AS_HELP_STRING([--with-vtysh-pager=PAGER], [control what pager is compiled in as default]),
 448         VTYSH_PAGER=$withval, VTYSH_PAGER="more")
 449 AC_ARG_ENABLE([vtysh],
 450   AS_HELP_STRING([--disable-vtysh], [do not build integrated vty shell for FRR]))
 451 AC_ARG_ENABLE([doc],
 452   AS_HELP_STRING([--disable-doc], [do not build docs]))
 453 AC_ARG_ENABLE([doc-html],
 454   AS_HELP_STRING([--enable-doc-html], [build HTML docs]))
 455 AC_ARG_ENABLE([zebra],
 456   AS_HELP_STRING([--disable-zebra], [do not build zebra daemon]))
 457 AC_ARG_ENABLE([bgpd],
 458   AS_HELP_STRING([--disable-bgpd], [do not build bgpd]))
 459 AC_ARG_ENABLE([ripd],
 460   AS_HELP_STRING([--disable-ripd], [do not build ripd]))
 461 AC_ARG_ENABLE([ripngd],
 462   AS_HELP_STRING([--disable-ripngd], [do not build ripngd]))
 463 AC_ARG_ENABLE([ospfd],
 464   AS_HELP_STRING([--disable-ospfd], [do not build ospfd]))
 465 AC_ARG_ENABLE([ospf6d],
 466   AS_HELP_STRING([--disable-ospf6d], [do not build ospf6d]))
 467 AC_ARG_ENABLE([ldpd],
 468   AS_HELP_STRING([--disable-ldpd], [do not build ldpd]))
 469 AC_ARG_ENABLE([nhrpd],
 470   AS_HELP_STRING([--disable-nhrpd], [do not build nhrpd]))
 471 AC_ARG_ENABLE([eigrpd],
 472   AS_HELP_STRING([--disable-eigrpd], [do not build eigrpd]))
 473 AC_ARG_ENABLE([babeld],
 474   AS_HELP_STRING([--disable-babeld], [do not build babeld]))
 475 AC_ARG_ENABLE([watchfrr],
 476   AS_HELP_STRING([--disable-watchfrr], [do not build watchfrr]))
 477 AC_ARG_ENABLE([isisd],
 478   AS_HELP_STRING([--disable-isisd], [do not build isisd]))
 479 AC_ARG_ENABLE([pimd],
 480   AS_HELP_STRING([--disable-pimd], [do not build pimd]))
 481 AC_ARG_ENABLE([pbrd],
 482   AS_HELP_STRING([--disable-pbrd], [do not build pbrd]))
 483 AC_ARG_ENABLE([sharpd],
 484   AS_HELP_STRING([--enable-sharpd], [build sharpd]))
 485 AC_ARG_ENABLE([staticd],
 486   AS_HELP_STRING([--disable-staticd], [do not build staticd]))
 487 AC_ARG_ENABLE([fabricd],
 488   AS_HELP_STRING([--disable-fabricd], [do not build fabricd]))
 489 AC_ARG_ENABLE([bgp-announce],
 490   AS_HELP_STRING([--disable-bgp-announce,], [turn off BGP route announcement]))
 491 AC_ARG_ENABLE([vrrpd],
 492   AS_HELP_STRING([--disable-vrrpd], [do not build vrrpd]))
 493 AC_ARG_ENABLE([bgp-vnc],
 494   AS_HELP_STRING([--disable-bgp-vnc],[turn off BGP VNC support]))
 495 AC_ARG_ENABLE([snmp],
 496   AS_HELP_STRING([--enable-snmp], [enable SNMP support for agentx]))
 497 AC_ARG_ENABLE([config_rollbacks],
 498   AS_HELP_STRING([--enable-config-rollbacks], [enable configuration rollbacks (requires sqlite3)]))
 499 AC_ARG_ENABLE([confd],
 500   AS_HELP_STRING([--enable-confd=ARG], [enable confd integration]))
 501 AC_ARG_ENABLE([sysrepo],
 502   AS_HELP_STRING([--enable-sysrepo], [enable sysrepo integration]))
 503 AC_ARG_ENABLE([grpc],
 504   AS_HELP_STRING([--enable-grpc], [enable the gRPC northbound plugin]))
 505 AC_ARG_ENABLE([zeromq],
 506   AS_HELP_STRING([--enable-zeromq], [enable ZeroMQ handler (libfrrzmq)]))
 507 AC_ARG_WITH([libpam],
 508   AS_HELP_STRING([--with-libpam], [use libpam for PAM support in vtysh]))
 509 AC_ARG_ENABLE([ospfapi],
 510   AS_HELP_STRING([--disable-ospfapi], [do not build OSPFAPI to access the OSPF LSA Database]))
 511 AC_ARG_ENABLE([ospfclient],
 512   AS_HELP_STRING([--disable-ospfclient], [do not build OSPFAPI client for OSPFAPI,
 513                           (this is the default if --disable-ospfapi is set)]))
 514 AC_ARG_ENABLE([multipath],
 515   AS_HELP_STRING([--enable-multipath=ARG], [enable multipath function, ARG must be digit]))
 516 AC_ARG_ENABLE([user],
 517   AS_HELP_STRING([--enable-user=USER], [user to run FRR suite as (default frr)]))
 518 AC_ARG_ENABLE([group],
 519   AS_HELP_STRING([--enable-group=GROUP], [group to run FRR suite as (default frr)]))
 520 AC_ARG_ENABLE([vty_group],
 521   AS_HELP_STRING([--enable-vty-group=ARG], [set vty sockets to have specified group as owner]))
 522 AC_ARG_ENABLE([configfile_mask],
 523   AS_HELP_STRING([--enable-configfile-mask=ARG], [set mask for config files]))
 524 AC_ARG_ENABLE([logfile_mask],
 525   AS_HELP_STRING([--enable-logfile-mask=ARG], [set mask for log files]))
 526 AC_ARG_ENABLE([shell_access],
 527   AS_HELP_STRING([--enable-shell-access], [Allow users to access shell/telnet/ssh]))
 528 AC_ARG_ENABLE([realms],
 529   AS_HELP_STRING([--enable-realms], [enable REALMS support under Linux]))
 530 AC_ARG_ENABLE([rtadv],
 531   AS_HELP_STRING([--disable-rtadv], [disable IPV6 router advertisement feature]))
 532 AC_ARG_ENABLE([irdp],
 533   AS_HELP_STRING([--disable-irdp], [enable IRDP server support in zebra (default if supported)]))
 534 AC_ARG_ENABLE([capabilities],
 535   AS_HELP_STRING([--disable-capabilities], [disable using POSIX capabilities]))
 536 AC_ARG_ENABLE([rusage],
 537   AS_HELP_STRING([--disable-rusage], [disable using getrusage]))
 538 AC_ARG_ENABLE([gcc_ultra_verbose],
 539   AS_HELP_STRING([--enable-gcc-ultra-verbose], [enable ultra verbose GCC warnings]))
 540 AC_ARG_ENABLE([backtrace],
 541   AS_HELP_STRING([--disable-backtrace,], [disable crash backtraces (default autodetect)]))
 542 AC_ARG_ENABLE([time-check],
 543   AS_HELP_STRING([--disable-time-check], [disable slow thread warning messages]))
 544 AC_ARG_ENABLE([pcreposix],
 545   AS_HELP_STRING([--enable-pcreposix], [enable using PCRE Posix libs for regex functions]))
 546 AC_ARG_ENABLE([fpm],
 547   AS_HELP_STRING([--enable-fpm], [enable Forwarding Plane Manager support]))
 548 AC_ARG_ENABLE([systemd],
 549   AS_HELP_STRING([--enable-systemd], [enable Systemd support]))
 550 AC_ARG_ENABLE([werror],
 551   AS_HELP_STRING([--enable-werror], [enable -Werror (recommended for developers only)]))
 552 AC_ARG_ENABLE([cumulus],
 553   AS_HELP_STRING([--enable-cumulus], [enable Cumulus Switch Special Extensions]))
 554 AC_ARG_ENABLE([datacenter],
 555   AS_HELP_STRING([--enable-datacenter], [enable Compilation for Data Center Extensions]))
 556 AC_ARG_ENABLE([fuzzing],
 557   AS_HELP_STRING([--enable-fuzzing], [enable ability to fuzz various parts of FRR]))
 558 AC_ARG_ENABLE([netlink_fuzzing],
 559   AS_HELP_STRING([--enable-netlink-fuzzing], [enable ability to fuzz netlink listening socket in zebra]))
 560 AC_ARG_ENABLE([rr-semantics],
 561   AS_HELP_STRING([--disable-rr-semantics], [disable the v6 Route Replace semantics]))
 562 AC_ARG_ENABLE([protobuf],
 563   AS_HELP_STRING([--enable-protobuf], [Enable experimental protobuf support]))
 564 AC_ARG_ENABLE([oldvpn_commands],
 565   AS_HELP_STRING([--enable-oldvpn-commands], [Keep old vpn commands]))
 566 AC_ARG_ENABLE([rpki],
 567   AS_HELP_STRING([--enable-rpki], [enable RPKI prefix validation support]))
 568 AC_ARG_ENABLE([clippy-only],
 569   AS_HELP_STRING([--enable-clippy-only], [Only build clippy]))
 570 AC_ARG_ENABLE([numeric_version],
 571   AS_HELP_STRING([--enable-numeric-version], [Only numeric digits allowed in version (for Alpine)]))
 572 AC_ARG_ENABLE([gcov],
 573   AS_HELP_STRING([--enable-gcov], [Add code coverage information]))
 574 AC_ARG_ENABLE([bfdd],
 575   AS_HELP_STRING([--disable-bfdd], [do not build bfdd]))
 576 AC_ARG_ENABLE([address-sanitizer],
 577   AS_HELP_STRING([--enable-address-sanitizer], [enable AddressSanitizer support for detecting a wide variety of memory allocation and deallocation errors]))
 578 AC_ARG_ENABLE([thread-sanitizer],
 579   AS_HELP_STRING([--enable-thread-sanitizer], [enable ThreadSanitizer support for detecting data races]))
 580 AC_ARG_ENABLE([memory-sanitizer],
 581   AS_HELP_STRING([--enable-memory-sanitizer], [enable MemorySanitizer support for detecting uninitialized memory reads]))
 582
 583 AS_IF([test "${enable_clippy_only}" != "yes"], [
 584 AC_CHECK_HEADERS([json-c/json.h])
 585 AC_CHECK_LIB([json-c], [json_object_get], [LIBS="$LIBS -ljson-c"], [], [-lm])
 586 if test "$ac_cv_lib_json_c_json_object_get" = no; then
 587   AC_CHECK_LIB([json], [json_object_get], [LIBS="$LIBS -ljson"])
 588   if test "$ac_cv_lib_json_json_object_get" = no; then
 589       AC_MSG_ERROR([libjson is needed to compile])
 590   fi
 591 fi
 592 ])
 593
 594 AC_ARG_ENABLE([dev_build],
 595     AS_HELP_STRING([--enable-dev-build], [build for development]))
 596
 597 AC_ARG_ENABLE([lua],
 598     AS_HELP_STRING([--enable-lua], [Build Lua scripting]))
 599
 600 if test x"${enable_time_check}" != x"no" ; then
 601   if test x"${enable_time_check}" = x"yes" -o x"${enable_time_check}" = x ; then
 602     AC_DEFINE([CONSUMED_TIME_CHECK], [5000000], [Consumed Time Check])
 603   else
 604     AC_DEFINE_UNQUOTED([CONSUMED_TIME_CHECK], [$enable_time_check], [Consumed Time Check])
 605   fi
 606 fi
 607
 608 case "${enable_systemd}" in
 609   "no") ;;
 610   "yes")
 611   AC_CHECK_LIB([systemd], [sd_notify], [LIBS="$LIBS -lsystemd"])
 612   if test $ac_cv_lib_systemd_sd_notify = no; then
 613     AC_MSG_ERROR([enable systemd has been specified but systemd development env not found on your system])
 614   else
 615     AC_DEFINE([HAVE_SYSTEMD], [1], [Compile systemd support in])
 616   fi
 617   ;;
 618   "*") ;;
 619 esac
 620
 621 if test "${enable_rr_semantics}" != "no" ; then
 622   AC_DEFINE([HAVE_V6_RR_SEMANTICS], [1], [Compile in v6 Route Replacement Semantics])
 623 fi
 624
 625 if test "${enable_datacenter}" = "yes" ; then
 626   AC_DEFINE([HAVE_DATACENTER], [1], [Compile extensions for a DataCenter])
 627   DFLT_NAME="datacenter"
 628 else
 629   DFLT_NAME="traditional"
 630 fi
 631
 632 if test "${enable_fuzzing}" = "yes" ; then
 633   AC_DEFINE([HANDLE_ZAPI_FUZZING], [1], [Compile extensions to use with a fuzzer])
 634 fi
 635
 636 if test "${enable_netlink_fuzzing}" = "yes" ; then
 637   AC_DEFINE([HANDLE_NETLINK_FUZZING], [1], [Compile extensions to use with a fuzzer for netlink])
 638 fi
 639
 640 if test "${enable_cumulus}" = "yes" ; then
 641   AC_DEFINE([HAVE_CUMULUS], [1], [Compile Special Cumulus Code in])
 642 fi
 643
 644 AC_SUBST([DFLT_NAME])
 645 AC_DEFINE_UNQUOTED([DFLT_NAME], ["$DFLT_NAME"], [Name of the configuration default set])
 646
 647 if test "${enable_shell_access}" = "yes"; then
 648    AC_DEFINE([HAVE_SHELL_ACCESS], [1], [Allow user to use ssh/telnet/bash, be aware this is considered insecure])
 649 fi
 650
 651 #
 652 # Python for clippy
 653 #
 654
 655 AS_IF([test "$host" = "$build"], [
 656   FRR_PYTHON_DEV
 657 ], [
 658   FRR_PYTHON
 659 ])
 660
 661 FRR_PYTHON_MODULES([pytest])
 662
 663 if test "${enable_doc}" != "no"; then
 664   FRR_PYTHON_MODULES([sphinx], , [
 665     if test "${enable_doc}" = "yes"; then
 666       AC_MSG_ERROR([Documentation was explicitly requested with --enable-doc but sphinx is not available for $PYTHON. Please disable docs or install sphinx.])
 667     fi
 668   ])
 669 fi
 670 AM_CONDITIONAL([DOC], [test "${enable_doc}" != "no" -a "$frr_py_mod_sphinx" != "false"])
 671 AM_CONDITIONAL([DOC_HTML], [test "${enable_doc_html}" = "yes"])
 672
 673 FRR_PYTHON_MOD_EXEC([sphinx], [--version], [
 674   PYSPHINX="-m sphinx"
 675 ], [
 676   PYSPHINX="-c 'import sys; from sphinx import main; sys.exit(main(sys.argv))'"
 677 ])
 678 AC_SUBST([PYSPHINX])
 679
 680 #
 681 # Logic for old vpn commands support.
 682 #
 683 if test "$enable_oldvpn_commands" = "yes"; then
 684    AC_DEFINE([KEEP_OLD_VPN_COMMANDS], [1], [Define for compiling with old vpn commands])
 685 fi
 686
 687 #
 688 # End of logic for protobuf support.
 689 #
 690
 691 AC_MSG_CHECKING([if zebra should be configurable to send Route Advertisements])
 692 if test "${enable_rtadv}" != "no"; then
 693   AC_MSG_RESULT([yes])
 694   AC_DEFINE([HAVE_RTADV], [1], [Enable IPv6 Routing Advertisement support])
 695 else
 696   AC_MSG_RESULT([no])
 697 fi
 698
 699 if test x"${enable_user}" = x"no"; then
 700   enable_user=""
 701 else
 702   if test x"${enable_user}" = x"yes" || test x"${enable_user}" = x""; then
 703     enable_user="frr"
 704   fi
 705   AC_DEFINE_UNQUOTED([FRR_USER], ["${enable_user}"], [frr User])
 706 fi
 707
 708 if test x"${enable_group}" = x"no"; then
 709   enable_group=""
 710 else
 711   if test x"${enable_group}" = x"yes" || test x"${enable_group}" = x""; then
 712     enable_group="frr"
 713   fi
 714   AC_DEFINE_UNQUOTED([FRR_GROUP], ["${enable_group}"], [frr Group])
 715 fi
 716
 717 if test x"${enable_vty_group}" = x"yes" ; then
 718   AC_MSG_ERROR([--enable-vty-group requires a group as argument, not yes])
 719 elif test x"${enable_vty_group}" != x""; then
 720   if test x"${enable_vty_group}" != x"no"; then
 721     AC_DEFINE_UNQUOTED([VTY_GROUP], ["${enable_vty_group}"], [VTY Sockets Group])
 722   fi
 723 fi
 724 AC_SUBST([enable_user])
 725 AC_SUBST([enable_group])
 726 AC_SUBST([enable_vty_group])
 727
 728 enable_configfile_mask=${enable_configfile_mask:-0600}
 729 AC_DEFINE_UNQUOTED([CONFIGFILE_MASK], [${enable_configfile_mask}], [Mask for config files])
 730
 731 enable_logfile_mask=${enable_logfile_mask:-0600}
 732 AC_DEFINE_UNQUOTED([LOGFILE_MASK], [${enable_logfile_mask}], [Mask for log files])
 733
 734 MPATH_NUM=16
 735
 736 case "${enable_multipath}" in
 737   0)
 738     MPATH_NUM=64
 739     ;;
 740   [[1-9]|[1-9][0-9]|[1-9][0-9][0-9]])
 741     MPATH_NUM="${enable_multipath}"
 742     ;;
 743   "")
 744     ;;
 745   *)
 746     AC_MSG_FAILURE([Please specify digit to enable multipath ARG])
 747     ;;
 748 esac
 749
 750 AC_DEFINE_UNQUOTED([MULTIPATH_NUM], [$MPATH_NUM], [Maximum number of paths for a route])
 751
 752 AC_DEFINE_UNQUOTED([VTYSH_PAGER], ["$VTYSH_PAGER"], [What pager to use])
 753
 754 dnl --------------------
 755 dnl Enable code coverage
 756 dnl --------------------
 757 AM_CONDITIONAL([HAVE_GCOV], [test '!' "$enable_gcov" = no])
 758
 759 dnl ------------------------------------
 760 dnl Alpine only accepts numeric versions
 761 dnl ------------------------------------
 762 if test "x${enable_numeric_version}" != "x" ; then
 763   VERSION="`echo ${VERSION} | tr -c -d '[[.0-9]]'`"
 764   PACKAGE_VERSION="`echo ${PACKAGE_VERSION} | tr -c -d '[[.0-9]]'`"
 765 fi
 766
 767 dnl -----------------------------------
 768 dnl Add extra version string to package
 769 dnl name, string and version fields.
 770 dnl -----------------------------------
 771 if test "x${EXTRAVERSION}" != "x" ; then
 772   VERSION="${VERSION}${EXTRAVERSION}"
 773   PACKAGE_VERSION="${PACKAGE_VERSION}${EXTRAVERSION}"
 774   AC_SUBST(PACKAGE_EXTRAVERSION, ["${EXTRAVERSION}"])
 775   PACKAGE_STRING="${PACKAGE_STRING}${EXTRAVERSION}"
 776 fi
 777 AC_SUBST([EXTRAVERSION])
 778
 779 if test "x$with_pkg_git_version" = "xyes"; then
 780         if test -d "${srcdir}/.git"; then
 781                 AC_DEFINE([GIT_VERSION], [1], [include git version info])
 782         else    with_pkg_git_version="no"
 783                 AC_MSG_WARN([--with-pkg-git-version given, but this is not a git checkout])
 784         fi
 785 fi
 786 AM_CONDITIONAL([GIT_VERSION], [test "x$with_pkg_git_version" = "xyes"])
 787
 788 AC_CHECK_TOOL([OBJCOPY], [objcopy], [:])
 789 if test "x${OBJCOPY}" != "x:"; then
 790   AC_CACHE_CHECK([for .interp value to use], [frr_cv_interp], [
 791     frr_cv_interp=""
 792     AC_LINK_IFELSE([AC_LANG_SOURCE([[int main() { return 0; }]])], [
 793       if $OBJCOPY -j.interp -Obinary conftest conftest.interp; then
 794         frr_cv_interp="`xargs -0 echo < conftest.interp`"
 795       fi
 796       test -f conftest.interp && rm conftest.interp
 797     ])
 798   ])
 799 fi
 800 if test -n "$frr_cv_interp"; then
 801   AC_DEFINE_UNQUOTED([INTERP], ["$frr_cv_interp"], [.interp value])
 802 fi
 803
 804 dnl -------------------------
 805 dnl Check other header files.
 806 dnl -------------------------
 807 AC_CHECK_HEADERS([stropts.h sys/ksym.h \
 808         linux/version.h asm/types.h])
 809
 810 ac_stdatomic_ok=false
 811 AC_DEFINE([FRR_AUTOCONF_ATOMIC], [1], [did autoconf checks for atomic funcs])
 812 AC_CHECK_HEADER([stdatomic.h],[
 813
 814   AC_MSG_CHECKING([whether _Atomic qualifier works])
 815   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 816 #include <stdatomic.h>
 817 int main(int argc, char **argv) {
 818   _Atomic int i = 0;
 819   return i;
 820 }
 821 ]])], [
 822     AC_DEFINE([HAVE_STDATOMIC_H], [1], [found stdatomic.h])
 823     AC_MSG_RESULT([yes])
 824     ac_stdatomic_ok=true
 825   ], [
 826     AC_MSG_RESULT([no])
 827   ])
 828 ])
 829
 830 AS_IF([$ac_stdatomic_ok], [true], [
 831   AC_MSG_CHECKING([for __atomic_* builtins])
 832   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 833 int main(int argc, char **argv) {
 834   volatile int i = 1;
 835   __atomic_store_n (&i, 0, __ATOMIC_RELEASE);
 836   return __atomic_load_n (&i, __ATOMIC_ACQUIRE);
 837 }
 838 ]])], [
 839     AC_DEFINE([HAVE___ATOMIC], [1], [found __atomic builtins])
 840     AC_MSG_RESULT([yes])
 841   ], [
 842     AC_MSG_RESULT([no])
 843
 844     dnl FreeBSD 9 has a broken stdatomic.h where _Atomic doesn't work
 845     AC_MSG_CHECKING([for __sync_* builtins])
 846     AC_LINK_IFELSE([AC_LANG_SOURCE([[
 847 int main(int argc, char **argv) {
 848   volatile int i = 1;
 849   __sync_fetch_and_sub (&i, 1);
 850   return __sync_val_compare_and_swap (&i, 0, 1);
 851 }
 852 ]])], [
 853       AC_DEFINE([HAVE___SYNC], [1], [found __sync builtins])
 854       AC_MSG_RESULT([yes])
 855
 856       AC_MSG_CHECKING([for __sync_swap builtin])
 857       AC_LINK_IFELSE([AC_LANG_SOURCE([[
 858 int main(int argc, char **argv) {
 859   volatile int i = 1;
 860   return __sync_swap (&i, 2);
 861 }
 862 ]])], [
 863         AC_DEFINE([HAVE___SYNC_SWAP], 1, [found __sync_swap builtin])
 864         AC_MSG_RESULT([yes])
 865       ], [
 866         AC_MSG_RESULT([no])
 867       ])
 868
 869     ], [
 870       AC_MSG_RESULT([no])
 871       AC_MSG_FAILURE([stdatomic.h unavailable and $CC has neither __atomic nor __sync builtins])
 872     ])
 873   ])
 874 ])
 875
 876 AC_CHECK_HEADERS([pthread_np.h],,, [
 877 #include <pthread.h>
 878 ])
 879 AC_CHECK_FUNCS([pthread_setname_np pthread_set_name_np])
 880
 881 needsync=true
 882
 883 AS_IF([$needsync], [
 884   dnl Linux
 885   AC_MSG_CHECKING([for Linux futex() support])
 886   AC_LINK_IFELSE([AC_LANG_PROGRAM([
 887 #ifndef _GNU_SOURCE
 888 #define _GNU_SOURCE
 889 #endif
 890 #include <unistd.h>
 891 #include <limits.h>
 892 #include <sys/time.h>
 893 #include <sys/syscall.h>
 894 #include <linux/futex.h>
 895
 896 int main(void);
 897 ],
 898 [
 899 {
 900   return syscall(SYS_futex, NULL, FUTEX_WAIT, 0, NULL, NULL, 0);
 901 }
 902 ])], [
 903     AC_MSG_RESULT([yes])
 904     AC_DEFINE(HAVE_SYNC_LINUX_FUTEX,,Have Linux futex support)
 905     needsync=false
 906   ], [
 907     AC_MSG_RESULT([no])
 908   ])
 909 ])
 910
 911 AS_IF([$needsync], [
 912   dnl FreeBSD
 913   AC_MSG_CHECKING([for FreeBSD _umtx_op() support])
 914   AC_LINK_IFELSE([AC_LANG_PROGRAM([
 915 #include <errno.h>
 916 #include <stdlib.h>
 917 #include <sys/types.h>
 918 #include <sys/umtx.h>
 919 int main(void);
 920 ],
 921 [
 922 {
 923   return _umtx_op(NULL, UMTX_OP_WAIT_UINT, 0, NULL, NULL);
 924 }
 925 ])], [
 926     AC_MSG_RESULT([yes])
 927     AC_DEFINE(HAVE_SYNC_UMTX_OP,,Have FreeBSD _umtx_op() support)
 928     needsync=false
 929   ], [
 930     AC_MSG_RESULT([no])
 931   ])
 932 ])
 933
 934 AS_IF([$needsync], [
 935   dnl OpenBSD patch (not upstream at the time of writing this)
 936   dnl https://marc.info/?l=openbsd-tech&m=147299508409549&w=2
 937   AC_MSG_CHECKING([for OpenBSD futex() support])
 938   AC_LINK_IFELSE([AC_LANG_PROGRAM([
 939 #include <sys/futex.h>
 940 int main(void);
 941 ],
 942 [
 943 {
 944   return futex(NULL, FUTEX_WAIT, 0, NULL, NULL, 0);
 945 }
 946 ])], [
 947     AC_MSG_RESULT([yes])
 948     AC_DEFINE(HAVE_SYNC_OPENBSD_FUTEX,,Have OpenBSD futex support)
 949     needsync=false
 950   ], [
 951     AC_MSG_RESULT([no])
 952   ])
 953 ])
 954
 955 dnl Utility macro to avoid retyping includes all the time
 956 m4_define([FRR_INCLUDES],
 957 [#ifdef SUNOS_5
 958 #define _POSIX_C_SOURCE 200809L
 959 #define __EXTENSIONS__
 960 #endif
 961 #include <stdio.h>
 962 #include <stdlib.h>
 963 #include <stddef.h>
 964 #include <sys/types.h>
 965 /* sys/conf.h depends on param.h on FBSD at least */
 966 #include <sys/param.h>
 967 /* Required for MAXSIG */
 968 #include <signal.h>
 969 #include <sys/socket.h>
 970 #ifdef __APPLE__
 971 # define __APPLE_USE_RFC_3542
 972 #endif
 973 #include <netinet/in.h>
 974 #include <sys/time.h>
 975 #include <time.h>
 976 #include <net/if.h>
 977 ])dnl
 978
 979 dnl Same applies for HAVE_NET_IF_VAR_H, which HAVE_NETINET6_ND6_H and
 980 dnl HAVE_NETINET_IN_VAR_H depend upon. But if_var.h depends on if.h, hence
 981 dnl an additional round for it.
 982
 983 AC_CHECK_HEADERS([net/if_var.h], [], [], [FRR_INCLUDES])
 984
 985 m4_define([FRR_INCLUDES],
 986 FRR_INCLUDES
 987 [#if HAVE_NET_IF_VAR_H
 988 # include <net/if_var.h>
 989 #endif
 990 ])dnl
 991
 992 AC_CHECK_HEADERS([netinet/in_var.h \
 993         net/if_dl.h net/netopt.h \
 994         inet/nd.h netinet/ip_icmp.h \
 995         sys/sysctl.h sys/sockio.h sys/conf.h],
 996         [], [], [FRR_INCLUDES])
 997
 998 AC_CHECK_HEADERS([ucontext.h], [], [],
 999 [#ifndef __USE_GNU
1000 #define __USE_GNU
1001 #endif /* __USE_GNU */
1002 FRR_INCLUDES
1003 ])
1004
1005 m4_define([UCONTEXT_INCLUDES],
1006 [#include <ucontext.h>])dnl
1007
1008 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.uc_regs],
1009   [], [], [UCONTEXT_INCLUDES])
1010 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs],
1011   [AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs.nip],
1012    [], [], [UCONTEXT_INCLUDES])],
1013   [], [UCONTEXT_INCLUDES])
1014 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.gregs],
1015   [], [], [UCONTEXT_INCLUDES])
1016
1017 m4_define([FRR_INCLUDES],
1018 FRR_INCLUDES
1019 [
1020 #include <sys/un.h>
1021 #include <netinet/in_systm.h>
1022 #if HAVE_NETINET_IN_VAR_H
1023 # include <netinet/in_var.h>
1024 #endif
1025 #if HAVE_NET_IF_DL_H
1026 # include <net/if_dl.h>
1027 #endif
1028 #if HAVE_NET_NETOPT_H
1029 # include <net/netopt.h>
1030 #endif
1031 #include <net/route.h>
1032 #if HAVE_INET_ND_H
1033 # include <inet/nd.h>
1034 #endif
1035 #include <arpa/inet.h>
1036 /* Required for IDRP */
1037 #if HAVE_NETINET_IP_ICMP_H
1038 # include <netinet/ip_icmp.h>
1039 #endif
1040 ])dnl
1041
1042 dnl V6 headers are checked below, after we check for v6
1043
1044 AC_MSG_CHECKING([which operating system interface to use])
1045 case "$host_os" in
1046   sunos* | solaris2*)
1047     AC_MSG_RESULT([Solaris])
1048
1049     AC_DEFINE([SUNOS_5], [1], [SunOS 5])
1050     AC_DEFINE([SOLARIS_IPV6], [1], Solaris IPv6)
1051     AC_DEFINE([_POSIX_C_SOURCE], [200809L], [enable POSIX.1-2008 and XPG7/SUSv4])
1052
1053     AC_CHECK_LIB([socket], [main])
1054     AC_CHECK_LIB([nsl], [main])
1055     AC_CHECK_LIB([umem], [main])
1056     SOLARIS="solaris"
1057     ;;
1058   linux*)
1059     AC_MSG_RESULT([Linux])
1060
1061     AC_DEFINE([GNU_LINUX], [1], [GNU Linux])
1062     AC_DEFINE([HAVE_NETLINK], [1], [netlink])
1063     AC_DEFINE([LINUX_IPV6], [1], [Linux IPv6 stack])
1064
1065     dnl Linux has a compilation problem with mixing
1066     dnl netinet/in.h and linux/in6.h they are not
1067     dnl compatible.  There has been discussion on
1068     dnl how to fix it but no real progress on implementation
1069     dnl when they fix it, remove this
1070     AC_DEFINE([IPV6_MINHOPCOUNT], [73], [Linux ipv6 Min Hop Count])
1071     ;;
1072   openbsd*)
1073     AC_MSG_RESULT([OpenBSD])
1074
1075     AC_DEFINE([OPEN_BSD], [1], [OpenBSD])
1076     AC_DEFINE([KAME], [1], [KAME IPv6])
1077     AC_DEFINE([BSD_V6_SYSCTL], [1], [BSD v6 sysctl to turn on and off forwarding])
1078
1079     if test "x${enable_pimd}" != "xno"; then
1080       case "$host_os" in
1081       openbsd6.0)
1082         ;;
1083       openbsd[6-9]*)
1084         AC_MSG_FAILURE([pimd cannot be enabled as PIM support has been removed from OpenBSD 6.1])
1085         ;;
1086       esac
1087     fi
1088     ;;
1089   *)
1090     AC_MSG_RESULT([BSD])
1091
1092     AC_DEFINE([HAVE_NET_RT_IFLIST], [1], [NET_RT_IFLIST])
1093     AC_DEFINE([KAME], [1], [KAME IPv6])
1094     AC_DEFINE([BSD_V6_SYSCTL], [1], [BSD v6 sysctl to turn on and off forwarding])
1095     ;;
1096 esac
1097 AM_CONDITIONAL([SOLARIS], [test "${SOLARIS}" = "solaris"])
1098
1099 AC_SYS_LARGEFILE
1100
1101 dnl ------------------------
1102 dnl Integrated REALMS option
1103 dnl ------------------------
1104 if test "${enable_realms}" = "yes"; then
1105     case "$host_os" in
1106       linux*)
1107        AC_DEFINE([SUPPORT_REALMS], [1], [Realms support])
1108        ;;
1109       *)
1110        echo "Sorry, only Linux has REALMS support"
1111        exit 1
1112        ;;
1113     esac
1114 fi
1115
1116 dnl -------------------------------
1117 dnl Endian-ness check
1118 dnl -------------------------------
1119 AC_WORDS_BIGENDIAN
1120
1121 dnl ---------------
1122 dnl other functions
1123 dnl ---------------
1124 AC_CHECK_FUNCS([ \
1125         strlcat strlcpy \
1126         getgrouplist])
1127
1128 dnl ##########################################################################
1129 dnl LARGE if block spans a lot of "configure"!
1130 if test "${enable_clippy_only}" != "yes"; then
1131 dnl ##########################################################################
1132
1133 #
1134 # Logic for protobuf support.
1135 #
1136 if test "$enable_protobuf" = "yes"; then
1137   # Check for protoc & protoc-c
1138
1139   # protoc is not required, it's only for a "be nice" helper target
1140   AC_CHECK_PROGS([PROTOC], [protoc], [/bin/false])
1141
1142   AC_CHECK_PROGS([PROTOC_C], [protoc-c], [/bin/false])
1143   if test "$PROTOC_C" = "/bin/false"; then
1144     AC_MSG_FAILURE([protobuf requested but protoc-c not found.  Install protobuf-c.])
1145   fi
1146
1147   PKG_CHECK_MODULES([PROTOBUF_C], [libprotobuf-c >= 0.14],, [
1148     AC_MSG_FAILURE([protobuf requested but libprotobuf-c not found.  Install protobuf-c.])
1149   ])
1150   AC_CHECK_HEADER([google/protobuf-c/protobuf-c.h], [], [
1151     AC_MSG_FAILURE([protobuf requested but protobuf-c.h not found.  Install protobuf-c.])
1152   ])
1153
1154   AC_DEFINE([HAVE_PROTOBUF], [1], [protobuf])
1155 fi
1156
1157
1158 dnl ---------------------
1159 dnl Integrated VTY option
1160 dnl ---------------------
1161 case "${enable_vtysh}" in
1162 "no")
1163   VTYSH="";;
1164 *)
1165   VTYSH="vtysh";
1166   AC_DEFINE([VTYSH], [1], [VTY shell])
1167
1168   prev_libs="$LIBS"
1169   AC_CHECK_LIB([readline], [main], [
1170     LIBREADLINE="-lreadline"
1171   ], [
1172     dnl readline failed - it might be incorrectly linked and missing its
1173     dnl termcap/tinfo/curses dependency.  see if we can fix that...
1174     AC_SEARCH_LIBS([tputs], [termcap tinfo curses ncurses], [
1175       LIBREADLINE="$ac_cv_search_tputs"
1176     ], [
1177       AC_MSG_ERROR([libreadline (needed for vtysh) not found and/or missing dependencies])
1178     ])
1179
1180     dnl re-try with the lib we found above
1181     unset ac_cv_lib_readline_main
1182     AC_CHECK_LIB([readline], [main], [
1183       LIBREADLINE="-lreadline $LIBREADLINE"
1184     ], [
1185       AC_MSG_ERROR([libreadline (needed for vtysh) not found and/or missing dependencies])
1186     ], [$LIBREADLINE])
1187   ], [])
1188   LIBS="$prev_libs"
1189
1190   AC_CHECK_HEADER([readline/history.h])
1191   if test $ac_cv_header_readline_history_h = no;then
1192     AC_MSG_ERROR([readline is too old to have readline/history.h, please update to the latest readline library.])
1193   fi
1194   AC_CHECK_LIB([readline], [rl_completion_matches], [true], [], [$LIBREADLINE])
1195   if test $ac_cv_lib_readline_rl_completion_matches = no; then
1196     AC_DEFINE([rl_completion_matches], [completion_matches], [Old readline])
1197   fi
1198   AC_CHECK_LIB([readline], [append_history], [frr_cv_append_history=yes], [frr_cv_append_history=no], [$LIBREADLINE])
1199   if test "$frr_cv_append_history" = yes; then
1200     AC_DEFINE([HAVE_APPEND_HISTORY], [1], [Have history.h append_history])
1201   fi
1202   ;;
1203 esac
1204 AC_SUBST([LIBREADLINE])
1205
1206 dnl ----------
1207 dnl PAM module
1208 dnl
1209 dnl FRR detects the PAM library it is built against by checking for a
1210 dnl functional pam_misc.h (Linux-PAM) or openpam.h (OpenPAM) header. pam_misc.h
1211 dnl is known to #include pam_appl.h, the standard header of a PAM library, and
1212 dnl openpam.h doesn't do that, although depends on the header too. Hence a
1213 dnl little assistance to AC_CHECK_HEADER is necessary for the proper detection
1214 dnl of OpenPAM.
1215 dnl ----------
1216 if test "$with_libpam" = "yes"; then
1217   AC_CHECK_HEADER([security/pam_misc.h],
1218     [AC_DEFINE([HAVE_PAM_MISC_H], [1], [Have pam_misc.h])
1219      AC_DEFINE([PAM_CONV_FUNC], [misc_conv], [Have misc_conv])
1220      pam_conv_func="misc_conv"
1221     ],
1222     [], FRR_INCLUDES)
1223   AC_CHECK_HEADER([security/openpam.h],
1224     [AC_DEFINE([HAVE_OPENPAM_H], [1], [Have openpam.h])
1225      AC_DEFINE([PAM_CONV_FUNC], [openpam_ttyconv], [Have openpam_ttyconv])
1226      pam_conv_func="openpam_ttyconv"
1227     ],
1228     [], FRR_INCLUDES[#include <security/pam_appl.h>])
1229   if test -z "$ac_cv_header_security_pam_misc_h$ac_cv_header_security_openpam_h" ; then
1230     AC_MSG_WARN([*** pam support will not be built ***])
1231     with_libpam="no"
1232   fi
1233 fi
1234
1235 if test "$with_libpam" = "yes"; then
1236 dnl took this test from proftpds configure.in and suited to our needs
1237 dnl -------------------------------------------------------------------------
1238 dnl
1239 dnl This next check looks funky due to a linker problem with some versions
1240 dnl of the PAM library.  Prior to 0.72 release, the Linux PAM shared library
1241 dnl omitted requiring libdl linking information. PAM-0.72 or better ships
1242 dnl with RedHat 6.2 and Debian 2.2 or better.
1243 AC_CHECK_LIB([pam], [pam_start],
1244   [AC_CHECK_LIB([pam], [$pam_conv_func],
1245     [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1246      LIBPAM="-lpam"],
1247     [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1248      LIBPAM="-lpam -lpam_misc"]
1249     )
1250   ],
1251
1252   [AC_CHECK_LIB([pam], [pam_end],
1253     [AC_CHECK_LIB([pam], [$pam_conv_func],
1254       [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1255        LIBPAM="-lpam -ldl"],
1256       [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1257        LIBPAM="-lpam -ldl -lpam_misc"]
1258      )
1259   ],AC_MSG_WARN([*** pam support will not be built ***]),
1260   [-ldl])
1261   ]
1262 )
1263 fi
1264 AC_SUBST([LIBPAM])
1265
1266 dnl -------------------------------
1267 dnl bgpd needs pow() and hence libm
1268 dnl -------------------------------
1269 TMPLIBS="$LIBS"
1270 LIBS=""
1271 AC_SEARCH_LIBS([pow], [m], [
1272   LIBM="$LIBS"
1273 ], [
1274   AC_MSG_WARN([Unable to find working pow function - bgpd may not link])
1275 ])
1276 LIBS="$TMPLIBS"
1277 AC_SUBST([LIBM])
1278
1279 AC_CHECK_FUNCS([ppoll], [
1280   AC_DEFINE([HAVE_PPOLL], [1], [have Linux/BSD ppoll()])
1281 ])
1282 AC_CHECK_FUNCS([pollts], [
1283   AC_DEFINE([HAVE_POLLTS], [1], [have NetBSD pollts()])
1284 ])
1285
1286 AC_CHECK_HEADER([asm-generic/unistd.h],
1287                 [AC_CHECK_DECL(__NR_setns,
1288                                AC_DEFINE([HAVE_NETNS], [1], [Have netns]),,
1289                                FRR_INCLUDES [#include <asm-generic/unistd.h>
1290                                ])
1291                  AC_CHECK_FUNCS([setns])]
1292                )
1293
1294 dnl --------------------------
1295 dnl Determine IS-IS I/O method
1296 dnl --------------------------
1297 AC_DEFINE([ISIS_METHOD_PFPACKET], [1], [constant value for isis method pfpacket])
1298 AC_DEFINE([ISIS_METHOD_DLPI], [2], [constant value for isis method dlpi])
1299 AC_DEFINE([ISIS_METHOD_BPF], [3], [constant value for isis method bpf])
1300 AC_CHECK_HEADER([net/bpf.h])
1301 AC_CHECK_HEADER([sys/dlpi.h])
1302 AC_MSG_CHECKING([zebra IS-IS I/O method])
1303
1304 case "$host_os" in
1305   linux*)
1306     AC_MSG_RESULT([pfpacket])
1307     ISIS_METHOD_MACRO="ISIS_METHOD_PFPACKET"
1308     ;;
1309   solaris* | sunos*)
1310     AC_MSG_RESULT([DLPI])
1311     ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1312     ;;
1313   *)
1314     if test $ac_cv_header_net_bpf_h = no; then
1315       if test $ac_cv_header_sys_dlpi_h = no; then
1316         AC_MSG_RESULT([none])
1317         if test "${enable_isisd}" = yes -o "${enable_fabricd}" = yes; then
1318           AC_MSG_FAILURE([IS-IS support requested but no packet backend found])
1319         fi
1320         AC_MSG_WARN([*** IS-IS support will not be built ***])
1321         enable_isisd="no"
1322         enable_fabricd="no"
1323       else
1324         AC_MSG_RESULT([DLPI])
1325       fi
1326       ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1327     else
1328       AC_MSG_RESULT([BPF])
1329       ISIS_METHOD_MACRO="ISIS_METHOD_BPF"
1330     fi
1331     ;;
1332 esac
1333 AC_DEFINE_UNQUOTED([ISIS_METHOD], [$ISIS_METHOD_MACRO], [selected method for isis, == one of the constants])
1334
1335 dnl ---------------------------------------------------------------
1336 dnl figure out how to specify an interface in multicast sockets API
1337 dnl ---------------------------------------------------------------
1338 AC_CHECK_MEMBERS([struct ip_mreqn.imr_ifindex], [], [], FRR_INCLUDES)
1339
1340 AC_CHECK_HEADERS([linux/mroute.h], [], [],[
1341         #include <sys/socket.h>
1342         #include <netinet/in.h>
1343         #define _LINUX_IN_H             /* For Linux <= 2.6.25 */
1344         #include <linux/types.h>
1345 ])
1346
1347 m4_define([FRR_INCLUDES],
1348 FRR_INCLUDES
1349 [#if HAVE_LINUX_MROUTE_H
1350 # include <linux/mroute.h>
1351 #endif
1352 ])dnl
1353
1354 AC_CHECK_HEADERS([netinet/ip_mroute.h], [], [],[
1355         #include <sys/socket.h>
1356         #include <sys/types.h>
1357         #include <netinet/in.h>
1358         #include <net/route.h>
1359 ])
1360
1361 m4_define([FRR_INCLUDES],
1362 FRR_INCLUDES
1363 [#if HAVE_NETINET_IP_MROUTE_H
1364 # include <netinet/ip_mroute.h>
1365 #endif
1366 ])dnl
1367
1368 AC_MSG_CHECKING([for BSD struct ip_mreq hack])
1369 AC_TRY_COMPILE([#include <sys/param.h>],
1370 [#if (defined(__FreeBSD__) && ((__FreeBSD_version >= 500022 && __FreeBSD_version < 700000) || (__FreeBSD_version < 500000 && __FreeBSD_version >= 440000))) || (defined(__NetBSD__) && defined(__NetBSD_Version__) && __NetBSD_Version__ >= 106010000) || defined(__OpenBSD__) || defined(__APPLE__) || defined(__DragonFly__) || defined(__sun)
1371   return (0);
1372 #else
1373   #error No support for BSD struct ip_mreq hack detected
1374 #endif],[AC_MSG_RESULT([yes])
1375 AC_DEFINE([HAVE_BSD_STRUCT_IP_MREQ_HACK], [1], [Can pass ifindex in struct ip_mreq])],
1376 AC_MSG_RESULT([no]))
1377
1378 AC_MSG_CHECKING([for RFC3678 protocol-independed API])
1379 AC_TRY_COMPILE([
1380 #include <sys/types.h>
1381 #include <netinet/in.h>
1382 ], [struct group_req gr; int sock; setsockopt(sock, IPPROTO_IP, MCAST_JOIN_GROUP, (void*)&gr, sizeof(gr));
1383 ], [AC_MSG_RESULT([yes])
1384 AC_DEFINE([HAVE_RFC3678], [1], [Have RFC3678 protocol-independed API])],
1385 AC_MSG_RESULT([no]))
1386
1387 dnl ---------------------------------------------------------------
1388 dnl figure out how to check link-state
1389 dnl ---------------------------------------------------------------
1390 AC_CHECK_HEADER([net/if_media.h],
1391   [m4_define([LINK_DETECT_INCLUDES],
1392     FRR_INCLUDES
1393     [#include <net/if_media.h>
1394   ])
1395   AC_CHECK_MEMBERS([struct ifmediareq.ifm_status],
1396     AC_DEFINE([HAVE_BSD_LINK_DETECT], [1], [BSD link-detect]),
1397     [], LINK_DETECT_INCLUDES)],
1398   [],
1399   FRR_INCLUDES)
1400
1401 dnl ---------------------------------------------------------------
1402 dnl Additional, newer way to check link-state using ifi_link_state.
1403 dnl Not available in all BSD's when ifmediareq available
1404 dnl ---------------------------------------------------------------
1405 AC_CHECK_MEMBERS([struct if_data.ifi_link_state],
1406   AC_DEFINE([HAVE_BSD_IFI_LINK_STATE], [1], [BSD ifi_link_state available]),
1407   [], FRR_INCLUDES)
1408
1409 dnl ------------------------
1410 dnl TCP_MD5SIG socket option
1411 dnl ------------------------
1412
1413 AC_CHECK_HEADER([netinet/tcp.h],
1414    [m4_define([MD5_INCLUDES],
1415       FRR_INCLUDES
1416       [#include <netinet/tcp.h>
1417     ])
1418     AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)],
1419    [],
1420    FRR_INCLUDES)
1421 if test $ac_cv_have_decl_TCP_MD5SIG = no; then
1422   AC_CHECK_HEADER([linux/tcp.h],
1423        [m4_define([MD5_INCLUDES],
1424           FRR_INCLUDES
1425           [#include <linux/tcp.h>
1426         ])
1427        AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)])
1428 fi
1429
1430 AC_SUBST([SOLARIS])
1431 AC_CHECK_LIB([crypt], [crypt], [],
1432                     [AC_CHECK_LIB([crypto], [DES_crypt])])
1433 AC_CHECK_LIB([resolv], [res_init])
1434
1435 dnl ---------------------------
1436 dnl check system has PCRE regexp
1437 dnl ---------------------------
1438 if test "x$enable_pcreposix" = "xyes"; then
1439   AC_CHECK_LIB([pcreposix], [regexec], [], [
1440     AC_MSG_ERROR([--enable-pcreposix given but unable to find libpcreposix])
1441   ])
1442 fi
1443 AC_SUBST([HAVE_LIBPCREPOSIX])
1444
1445 dnl ##########################################################################
1446 dnl test "${enable_clippy_only}" != "yes"
1447 fi
1448 dnl END OF LARGE if block
1449 dnl ##########################################################################
1450
1451
1452 dnl ----------------------------------------------------------------------------
1453 dnl figure out if domainname is available in the utsname struct (GNU extension).
1454 dnl ----------------------------------------------------------------------------
1455 AC_CHECK_MEMBERS([struct utsname.domainname], [], [], [#include <sys/utsname.h>])
1456
1457 dnl ------------------
1458 dnl IPv6 header checks
1459 dnl ------------------
1460 AC_CHECK_HEADERS([netinet6/in6.h netinet/in6_var.h \
1461         netinet6/in6_var.h netinet6/nd6.h], [], [],
1462         FRR_INCLUDES)
1463
1464 m4_define([FRR_INCLUDES],dnl
1465 FRR_INCLUDES
1466 [#if HAVE_NETINET6_IN6_H
1467 #include <netinet6/in6.h>
1468 #endif
1469 #if HAVE_NETINET_IN6_VAR_H
1470 #include <netinet/in6_var.h>
1471 #endif
1472 #include <netinet/icmp6.h>
1473 #if HAVE_NETINET6_IN6_VAR_H
1474 # include <netinet6/in6_var.h>
1475 #endif
1476 #if HAVE_NETINET6_ND6_H
1477 # include <netinet6/nd6.h>
1478 #endif
1479 ])dnl
1480
1481 dnl --------------------
1482 dnl Daemon disable check
1483 dnl --------------------
1484
1485 AS_IF([test "${enable_ldpd}" != "no"], [
1486   AC_DEFINE([HAVE_LDPD], [1], [ldpd])
1487 ])
1488
1489 if test "$enable_bfdd" = "no"; then
1490   AC_DEFINE([HAVE_BFDD], [0], [bfdd])
1491   BFDD=""
1492 else
1493   AC_DEFINE([HAVE_BFDD], [1], [bfdd])
1494   BFDD="bfdd"
1495
1496   case $host_os in
1497     linux*)
1498       AC_DEFINE([BFD_LINUX], [1], [bfdd])
1499       ;;
1500
1501     *)
1502       AC_DEFINE([BFD_BSD], [1], [bfdd])
1503       ;;
1504   esac
1505 fi
1506
1507 if test "$ac_cv_lib_json_c_json_object_get" = no -a "x$BFDD" = "xbfdd"; then
1508   AC_MSG_ERROR(["you must use json-c library to use bfdd"])
1509 fi
1510
1511 NHRPD=""
1512 case "$host_os" in
1513   linux*)
1514     if test "${enable_nhrpd}" != "no"; then
1515       NHRPD="nhrpd"
1516     fi
1517     ;;
1518   *)
1519     if test "${enable_nhrpd}" = "yes"; then
1520       AC_MSG_ERROR([nhrpd requires kernel APIs that are only present on Linux.])
1521     fi
1522     ;;
1523 esac
1524
1525 if test "${enable_watchfrr}" = "no";then
1526   WATCHFRR=""
1527 else
1528   WATCHFRR="watchfrr"
1529 fi
1530
1531 OSPFCLIENT=""
1532 if test "${enable_ospfapi}" != "no";then
1533     AC_DEFINE([SUPPORT_OSPF_API], [1], [OSPFAPI])
1534
1535   if test "${enable_ospfclient}" != "no";then
1536       OSPFCLIENT="ospfclient"
1537   fi
1538 fi
1539
1540 if test "${enable_bgp_announce}" = "no";then
1541   AC_DEFINE([DISABLE_BGP_ANNOUNCE], [1], [Disable BGP installation to zebra])
1542 else
1543   AC_DEFINE([DISABLE_BGP_ANNOUNCE], [0], [Disable BGP installation to zebra])
1544 fi
1545
1546 if test "${enable_bgp_vnc}" != "no";then
1547   AC_DEFINE([ENABLE_BGP_VNC], [1], [Enable BGP VNC support])
1548 fi
1549
1550 dnl ##########################################################################
1551 dnl LARGE if block
1552 if test "${enable_clippy_only}" != "yes"; then
1553 dnl ##########################################################################
1554
1555 dnl ------------------
1556 dnl check C-Ares library
1557 dnl ------------------
1558 if test "${NHRPD}" != ""; then
1559   PKG_CHECK_MODULES([CARES], [libcares], ,[
1560     AC_MSG_ERROR([trying to build nhrpd, but libcares not found. install c-ares and its -dev headers.])
1561   ])
1562 fi
1563
1564
1565 dnl ------------------
1566 dnl check Net-SNMP library
1567 dnl ------------------
1568 if test "${enable_snmp}" != "" -a "${enable_snmp}" != "no"; then
1569    AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], [no])
1570    if test x"$NETSNMP_CONFIG" = x"no"; then
1571       AC_MSG_ERROR([--enable-snmp given but unable to find net-snmp-config])
1572    fi
1573    SNMP_LIBS="`${NETSNMP_CONFIG} --agent-libs`"
1574    SNMP_CFLAGS="`${NETSNMP_CONFIG} --base-cflags`"
1575    # net-snmp lists all of its own dependencies.  we absolutely do not want that
1576    # among other things we avoid a GPL vs. OpenSSL license conflict here
1577    for removelib in crypto ssl sensors pci wrap; do
1578      SNMP_LIBS="`echo $SNMP_LIBS | sed -e 's/\(^\|\s\)-l'$removelib'\b/ /g' -e 's/\(^\|\s\)\([^\s]*\/\)\?lib'$removelib'\.[^\s]\+\b/ /g'`"
1579    done
1580    AC_MSG_CHECKING([whether we can link to Net-SNMP])
1581    AC_LINK_IFELSE_FLAGS([$SNMP_CFLAGS], [$SNMP_LIBS], [AC_LANG_PROGRAM([
1582 int main(void);
1583 ],
1584 [
1585 {
1586   return 0;
1587 }
1588 ])], [
1589      AC_MSG_RESULT([no])
1590      AC_MSG_ERROR([--enable-snmp given but not usable])])
1591    case "${enable_snmp}" in
1592      yes)
1593       SNMP_METHOD=agentx
1594       ;;
1595      agentx)
1596       SNMP_METHOD="${enable_snmp}"
1597       ;;
1598      *)
1599       AC_MSG_ERROR([--enable-snmp given with an unknown method (${enable_snmp}). Use yes or agentx])
1600       ;;
1601    esac
1602    AH_TEMPLATE([SNMP_AGENTX], [Use SNMP AgentX to interface with snmpd])
1603    AC_DEFINE_UNQUOTED(AS_TR_CPP(SNMP_${SNMP_METHOD}),,[SNMP method to interface with snmpd])
1604 fi
1605 AC_SUBST([SNMP_LIBS])
1606 AC_SUBST([SNMP_CFLAGS])
1607
1608 dnl ---------------
1609 dnl libyang
1610 dnl ---------------
1611 PKG_CHECK_MODULES([LIBYANG], [libyang >= 0.16.7], , [
1612   AC_MSG_ERROR([libyang (>= 0.16.7) was not found on your system.])
1613 ])
1614 ac_cflags_save="$CFLAGS"
1615 CFLAGS="$CFLAGS $LIBYANG_CFLAGS"
1616 AC_CHECK_MEMBER([struct lyd_node.priv], [], [
1617   AC_MSG_ERROR([m4_normalize([
1618     libyang needs to be compiled with ENABLE_LYD_PRIV=ON.
1619     Instructions for this are included in the build documentation for your platform at http://docs.frrouting.org/projects/dev-guide/en/latest/building.html])
1620   ])
1621 ], [[#include <libyang/libyang.h>]])
1622 CFLAGS="$ac_cflags_save"
1623
1624 dnl ---------------
1625 dnl configuration rollbacks
1626 dnl ---------------
1627 SQLITE3=false
1628 if test "$enable_config_rollbacks" = "yes"; then
1629   PKG_CHECK_MODULES([SQLITE3], [sqlite3], [
1630     AC_DEFINE([HAVE_CONFIG_ROLLBACKS], [1], [Enable configuration rollbacks])
1631     AC_DEFINE([HAVE_SQLITE3], [1], [Enable sqlite3 database])
1632     SQLITE3=true
1633   ], [
1634     AC_MSG_ERROR([--enable-config-rollbacks given but sqlite3 was not found on your system.])
1635   ])
1636 fi
1637
1638 dnl ---------------
1639 dnl confd
1640 dnl ---------------
1641 if test "$enable_confd" != "" -a "$enable_confd" != "no"; then
1642    AC_CHECK_PROG([CONFD], [confd], [confd], [/bin/false], "${enable_confd}/bin")
1643    if test "x$CONFD" = "x/bin/false"; then
1644       AC_MSG_ERROR([confd was not found on your system.])]
1645    fi
1646    CONFD_CFLAGS="-I${enable_confd}/include -L${enable_confd}/lib"
1647    AC_SUBST([CONFD_CFLAGS])
1648    CONFD_LIBS="-lconfd"
1649    AC_SUBST([CONFD_LIBS])
1650    AC_DEFINE([HAVE_CONFD], [1], [Enable confd integration])
1651 fi
1652
1653 dnl ---------------
1654 dnl sysrepo
1655 dnl ---------------
1656 if test "$enable_sysrepo" = "yes"; then
1657   PKG_CHECK_MODULES([SYSREPO], [libsysrepo],
1658       [AC_DEFINE([HAVE_SYSREPO], [1], [Enable sysrepo integration])
1659       SYSREPO=true],
1660       [SYSREPO=false
1661       AC_MSG_ERROR([sysrepo was not found on your system.])]
1662   )
1663 fi
1664
1665 dnl ---------------
1666 dnl gRPC
1667 dnl ---------------
1668 if test "$enable_grpc" = "yes"; then
1669   PKG_CHECK_MODULES([GRPC], [grpc grpc++ protobuf], [
1670     AC_CHECK_PROGS([PROTOC], [protoc], [/bin/false])
1671     if test "$PROTOC" = "/bin/false"; then
1672       AC_MSG_FAILURE([grpc requested but protoc not found.])
1673     fi
1674
1675     AC_DEFINE([HAVE_GRPC], [1], [Enable the gRPC northbound plugin])
1676     GRPC=true
1677   ], [
1678     GRPC=false
1679     AC_MSG_ERROR([grpc/grpc++ were not found on your system.])
1680   ])
1681 fi
1682
1683 dnl ------
1684 dnl ZeroMQ
1685 dnl ------
1686 if test "x$enable_zeromq" != "xno"; then
1687   PKG_CHECK_MODULES([ZEROMQ], [libzmq >= 4.0.0], [
1688     AC_DEFINE([HAVE_ZEROMQ], [1], [Enable ZeroMQ support])
1689     ZEROMQ=true
1690   ], [
1691     if test "x$enable_zeromq" = "xyes"; then
1692       AC_MSG_ERROR([configuration specifies --enable-zeromq but libzmq was not found])
1693     fi
1694   ])
1695 fi
1696
1697 dnl ------------------------------------
1698 dnl Enable RPKI and add librtr to libs
1699 dnl ------------------------------------
1700 if test "${enable_rpki}" = "yes"; then
1701   PKG_CHECK_MODULES([RTRLIB], [rtrlib >= 0.5.0],
1702       [RPKI=true],
1703       [RPKI=false
1704       AC_MSG_ERROR([rtrlib was not found on your system or is too old.])]
1705   )
1706 fi
1707
1708 dnl ------------------------------------------
1709 dnl Check whether rtrlib was build with ssh support
1710 dnl ------------------------------------------
1711 AC_MSG_CHECKING([whether the RTR Library is compiled with SSH])
1712 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "rtrlib/rtrlib.h"]],
1713                         [[struct tr_ssh_config config;]])],
1714         [AC_MSG_RESULT([yes])
1715         AC_DEFINE([FOUND_SSH], [1], [found_ssh])],
1716         AC_MSG_RESULT([no])
1717 )
1718
1719 dnl ---------------
1720 dnl dlopen & dlinfo
1721 dnl ---------------
1722 AC_SEARCH_LIBS([dlopen], [dl dld], [], [
1723   AC_MSG_ERROR([unable to find the dlopen()])
1724 ])
1725
1726 AC_CHECK_HEADERS([link.h])
1727
1728 AC_CACHE_CHECK([for dlinfo(RTLD_DI_ORIGIN)], [frr_cv_rtld_di_origin], [
1729   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1730 #include <stdlib.h>
1731 #ifdef HAVE_LINK_H
1732 #include <link.h>
1733 #endif
1734 #include <dlfcn.h>
1735 ]], [[
1736   char origin[1];
1737   dlinfo (NULL, RTLD_DI_ORIGIN, &origin);
1738 ]])], [
1739     frr_cv_rtld_di_origin=yes
1740   ], [
1741     frr_cv_rtld_di_origin=no
1742   ])
1743 ])
1744 if test "$frr_cv_rtld_di_origin" = yes; then
1745   AC_DEFINE([HAVE_DLINFO_ORIGIN], [1], [Have dlinfo RTLD_DI_ORIGIN])
1746 fi
1747
1748 AC_CACHE_CHECK([for dlinfo(RTLD_DI_LINKMAP)], [frr_cv_rtld_di_linkmap], [
1749   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1750 #include <stdlib.h>
1751 #ifdef HAVE_LINK_H
1752 #include <link.h>
1753 #endif
1754 #include <dlfcn.h>
1755 ]], [[
1756   struct link_map *lm = NULL;
1757   dlinfo (NULL, RTLD_DI_LINKMAP, &lm);
1758 ]])], [
1759     frr_cv_rtld_di_linkmap=yes
1760   ], [
1761     frr_cv_rtld_di_linkmap=no
1762   ])
1763 ])
1764 if test "$frr_cv_rtld_di_linkmap" = yes; then
1765   AC_DEFINE([HAVE_DLINFO_LINKMAP], [1], [Have dlinfo RTLD_DI_LINKMAP])
1766 fi
1767
1768 dnl ##########################################################################
1769 dnl test "${enable_clippy_only}" != "yes"
1770 fi
1771 dnl END OF LARGE if block
1772 dnl ##########################################################################
1773
1774 dnl ---------------------------
1775 dnl sockaddr and netinet checks
1776 dnl ---------------------------
1777 AC_CHECK_TYPES([
1778         struct sockaddr_dl,
1779         struct vifctl, struct mfcctl, struct sioc_sg_req,
1780         vifi_t, struct sioc_vif_req, struct igmpmsg,
1781         struct ifaliasreq, struct if6_aliasreq, struct in6_aliasreq,
1782         struct nd_opt_adv_interval,
1783         struct nd_opt_homeagent_info, struct nd_opt_adv_interval,
1784         struct nd_opt_rdnss, struct nd_opt_dnssl],
1785         [], [], FRR_INCLUDES)
1786
1787 AC_CHECK_MEMBERS([struct sockaddr.sa_len,
1788         struct sockaddr_in.sin_len, struct sockaddr_un.sun_len,
1789         struct sockaddr_dl.sdl_len,
1790         struct if6_aliasreq.ifra_lifetime,
1791         struct nd_opt_adv_interval.nd_opt_ai_type],
1792         [], [], FRR_INCLUDES)
1793
1794 dnl ---------------------------
1795 dnl IRDP/pktinfo/icmphdr checks
1796 dnl ---------------------------
1797
1798 AC_CHECK_TYPES([struct in_pktinfo], [
1799   AC_CHECK_TYPES([struct icmphdr], [
1800     IRDP=true
1801   ], [
1802     IRDP=false
1803   ], [FRR_INCLUDES])
1804 ], [
1805   IRDP=false
1806 ], [FRR_INCLUDES])
1807
1808 case "${enable_irdp}" in
1809 yes)
1810   $IRDP || AC_MSG_ERROR(['IRDP requires in_pktinfo at the moment!'])
1811   ;;
1812 no)
1813   IRDP=false
1814   ;;
1815 esac
1816
1817
1818 dnl -----------------------
1819 dnl checking for IP_PKTINFO
1820 dnl -----------------------
1821 AC_MSG_CHECKING([for IP_PKTINFO])
1822 AC_TRY_COMPILE([#include <netdb.h>], [
1823   int opt = IP_PKTINFO;
1824 ], [
1825   AC_MSG_RESULT([yes])
1826   AC_DEFINE([HAVE_IP_PKTINFO], [1], [Have IP_PKTINFO])
1827 ], [
1828   AC_MSG_RESULT([no])
1829 ])
1830
1831 dnl ---------------------------
1832 dnl checking for IP_RECVDSTADDR
1833 dnl ---------------------------
1834 AC_MSG_CHECKING([for IP_RECVDSTADDR])
1835 AC_TRY_COMPILE([#include <netinet/in.h>], [
1836   int opt = IP_RECVDSTADDR;
1837 ], [
1838   AC_MSG_RESULT([yes])
1839   AC_DEFINE([HAVE_IP_RECVDSTADDR], [1], [Have IP_RECVDSTADDR])
1840 ], [
1841   AC_MSG_RESULT([no])
1842 ])
1843
1844 dnl ----------------------
1845 dnl checking for IP_RECVIF
1846 dnl ----------------------
1847 AC_MSG_CHECKING([for IP_RECVIF])
1848 AC_TRY_COMPILE([#include <netinet/in.h>], [
1849   int opt = IP_RECVIF;
1850 ], [
1851   AC_MSG_RESULT([yes])
1852   AC_DEFINE([HAVE_IP_RECVIF], [1], [Have IP_RECVIF])
1853 ], [
1854   AC_MSG_RESULT([no])
1855 ])
1856
1857 dnl ----------------------
1858 dnl checking for SO_BINDANY
1859 dnl ----------------------
1860 AC_MSG_CHECKING([for SO_BINDANY])
1861 AC_TRY_COMPILE([#include <sys/socket.h>], [
1862   int opt = SO_BINDANY;
1863 ], [
1864   AC_MSG_RESULT([yes])
1865   AC_DEFINE([HAVE_SO_BINDANY], [1], [Have SO_BINDANY])
1866 ], [
1867   AC_MSG_RESULT([no])
1868 ])
1869
1870 dnl ----------------------
1871 dnl checking for IP_FREEBIND
1872 dnl ----------------------
1873 AC_MSG_CHECKING([for IP_FREEBIND])
1874 AC_TRY_COMPILE([#include <netinet/in.h>], [
1875   int opt = IP_FREEBIND;
1876 ], [
1877   AC_MSG_RESULT([yes])
1878   AC_DEFINE([HAVE_IP_FREEBIND], [1], [Have IP_FREEBIND])
1879 ], [
1880   AC_MSG_RESULT([no])
1881 ])
1882
1883 dnl --------------------------------------
1884 dnl checking for be32dec existence or not
1885 dnl --------------------------------------
1886 AC_CHECK_DECLS([be32enc, be32dec], [], [],
1887                [#include <sys/endian.h>])
1888
1889 dnl --------------------------------------
1890 dnl checking for clock_time monotonic struct and call
1891 dnl --------------------------------------
1892 AC_CHECK_DECL([CLOCK_MONOTONIC],
1893         [AC_CHECK_LIB([rt], [clock_gettime], [LIBS="$LIBS -lrt"])
1894          AC_DEFINE([HAVE_CLOCK_MONOTONIC], [1], [Have monotonic clock])
1895 ], [AC_MSG_RESULT([no])], [FRR_INCLUDES])
1896
1897 dnl --------------------------------------
1898 dnl checking for flex and bison
1899 dnl --------------------------------------
1900
1901 AM_PROG_LEX
1902 AC_MSG_CHECKING([version of flex])
1903 frr_ac_flex_version="$(eval $LEX -V | grep flex | head -n 1)"
1904 frr_ac_flex_version="${frr_ac_flex_version##* }"
1905 AC_MSG_RESULT([$frr_ac_flex_version])
1906 AX_COMPARE_VERSION([$frr_ac_flex_version], [lt], [2.5.20], [
1907   LEX="$SHELL $missing_dir/missing flex"
1908   if test -f "${srcdir}/lib/command_lex.c" -a -f "${srcdir}/lib/command_lex.h"; then
1909     AC_MSG_WARN([using pregenerated flex output files])
1910   else
1911     AC_MSG_ERROR([flex failure and pregenerated files not included (probably a git build)])
1912   fi
1913   AC_SUBST([LEX_OUTPUT_ROOT], [lex.yy])
1914   AC_SUBST([LEXLIB], [''])
1915 ])
1916
1917 AC_PROG_YACC
1918 dnl thanks GNU bison for this b*llshit...
1919 AC_MSG_CHECKING([version of bison])
1920 frr_ac_bison_version="$(eval $YACC -V | grep bison | head -n 1)"
1921 frr_ac_bison_version="${frr_ac_bison_version##* }"
1922 frr_ac_bison_missing="false"
1923 case "x${frr_ac_bison_version}x" in
1924   x2.7*)
1925     BISON_OPENBRACE='"'
1926     BISON_CLOSEBRACE='"'
1927     BISON_VERBOSE=''
1928     AC_MSG_RESULT([$frr_ac_bison_version - 2.7 or older])
1929     ;;
1930   x2.*|x1.*)
1931     AC_MSG_RESULT([$frr_ac_bison_version])
1932     AC_MSG_WARN([installed bison is too old.  Please install GNU bison 2.7.x or newer.])
1933     frr_ac_bison_missing="true"
1934     ;;
1935   x)
1936     AC_MSG_RESULT([none])
1937     AC_MSG_WARN([could not determine bison version.  Please install GNU bison 2.7.x or newer.])
1938     frr_ac_bison_missing="true"
1939     ;;
1940   x3.[012][^0-9]*)
1941     BISON_OPENBRACE='{'
1942     BISON_CLOSEBRACE='}'
1943     BISON_VERBOSE='-Dparse.error=verbose'
1944     AC_MSG_RESULT([$frr_ac_bison_version - 3.0 to 3.2])
1945     ;;
1946   *)
1947     BISON_OPENBRACE='{'
1948     BISON_CLOSEBRACE='}'
1949     BISON_VERBOSE='-Dparse.error=verbose -Wno-yacc'
1950     AC_MSG_RESULT([$frr_ac_bison_version - 3.3 or newer])
1951     ;;
1952 esac
1953 AC_SUBST([BISON_OPENBRACE])
1954 AC_SUBST([BISON_CLOSEBRACE])
1955 AC_SUBST([BISON_VERBOSE])
1956
1957 if $frr_ac_bison_missing; then
1958   YACC="$SHELL $missing_dir/missing bison -y"
1959   if test -f "${srcdir}/lib/command_parse.c" -a -f "${srcdir}/lib/command_parse.h"; then
1960     AC_MSG_WARN([using pregenerated bison output files])
1961   else
1962     AC_MSG_ERROR([bison failure and pregenerated files not included (probably a git build)])
1963   fi
1964 fi
1965
1966 dnl -------------------
1967 dnl capabilities checks
1968 dnl -------------------
1969 if test "${enable_capabilities}" != "no"; then
1970   AC_MSG_CHECKING([whether prctl PR_SET_KEEPCAPS is available])
1971   AC_TRY_COMPILE([#include <sys/prctl.h>], [prctl(PR_SET_KEEPCAPS, 1, 0, 0, 0);],
1972     [AC_MSG_RESULT([yes])
1973      AC_DEFINE([HAVE_PR_SET_KEEPCAPS], [1], [prctl])
1974      frr_ac_keepcaps="yes"],
1975      AC_MSG_RESULT([no])
1976   )
1977   if test x"${frr_ac_keepcaps}" = x"yes"; then
1978     AC_CHECK_HEADERS([sys/capability.h])
1979   fi
1980   if test x"${ac_cv_header_sys_capability_h}" = x"yes"; then
1981     AC_CHECK_LIB([cap], [cap_init],
1982       [AC_DEFINE([HAVE_LCAPS], [1], [Capabilities])
1983        LIBCAP="-lcap"
1984        frr_ac_lcaps="yes"]
1985     )
1986   else
1987     AC_CHECK_HEADERS([priv.h],
1988      [AC_MSG_CHECKING([Solaris style privileges are available])
1989       AC_TRY_COMPILE([#include <priv.h>], [getpflags(PRIV_AWARE);],
1990           [AC_MSG_RESULT([yes])
1991            AC_DEFINE([HAVE_SOLARIS_CAPABILITIES], [1], [getpflags])
1992            frr_ac_scaps="yes"],
1993            AC_MSG_RESULT(no)
1994       )
1995      ]
1996    )
1997   fi
1998   if test x"${frr_ac_scaps}" = x"yes" \
1999        -o x"${frr_ac_lcaps}" = x"yes"; then
2000     AC_DEFINE([HAVE_CAPABILITIES], [1], [capabilities])
2001   fi
2002 fi
2003 AC_SUBST([LIBCAP])
2004
2005 dnl ---------------------------
2006 dnl check for glibc 'backtrace'
2007 dnl ---------------------------
2008 if test x"${enable_backtrace}" != x"no" ; then
2009   backtrace_ok=no
2010   PKG_CHECK_MODULES([UNWIND], [libunwind], [
2011     AC_DEFINE([HAVE_LIBUNWIND], [1], [libunwind])
2012     backtrace_ok=yes
2013   ], [
2014     case "$host_os" in
2015     sunos* | solaris2*)
2016       AC_CHECK_FUNCS([printstack], [
2017         AC_DEFINE([HAVE_PRINTSTACK], [1], [Solaris printstack])
2018         backtrace_ok=yes
2019       ])
2020       ;;
2021     esac
2022     if test "$backtrace_ok" = no; then
2023       AC_CHECK_HEADER([execinfo.h], [
2024         AC_SEARCH_LIBS([backtrace], [execinfo], [
2025           AC_DEFINE([HAVE_GLIBC_BACKTRACE], [1], [Glibc backtrace])
2026           backtrace_ok=yes
2027         ],, [-lm])
2028       ])
2029     fi
2030   ])
2031
2032   if test x"${enable_backtrace}" = x"yes" -a x"${backtrace_ok}" = x"no"; then
2033     dnl user explicitly requested backtrace but we failed to find support
2034     AC_MSG_FAILURE([failed to find backtrace or libunwind support])
2035   fi
2036 fi
2037
2038 dnl -----------------------------------------
2039 dnl check for malloc mallinfo struct and call
2040 dnl this must try and link using LIBS, in
2041 dnl order to check no alternative allocator
2042 dnl has been specified, which might not provide
2043 dnl mallinfo, e.g. such as Umem on Solaris.
2044 dnl -----------------------------------------
2045 AC_CHECK_HEADERS([malloc.h malloc_np.h malloc/malloc.h],,, [FRR_INCLUDES])
2046
2047 AC_CACHE_CHECK([whether mallinfo is available], [frr_cv_mallinfo], [
2048   AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2049 #ifdef HAVE_MALLOC_H
2050 #include <malloc.h>
2051 #endif
2052 #ifdef HAVE_MALLOC_NP_H
2053 #include <malloc_np.h>
2054 #endif
2055 #ifdef HAVE_MALLOC_MALLOC_H
2056 #include <malloc/malloc.h>
2057 #endif
2058 ]], [[
2059 struct mallinfo ac_x; ac_x = mallinfo ();
2060 ]])], [
2061     frr_cv_mallinfo=yes
2062   ], [
2063     frr_cv_mallinfo=no
2064   ])
2065 ])
2066 if test "$frr_cv_mallinfo" = yes; then
2067   AC_DEFINE([HAVE_MALLINFO], [1], [mallinfo])
2068 fi
2069
2070 AC_MSG_CHECKING([whether malloc_usable_size is available])
2071 AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2072 #ifdef HAVE_MALLOC_H
2073 #include <malloc.h>
2074 #endif
2075 #ifdef HAVE_MALLOC_MALLOC_H
2076 #include <malloc/malloc.h>
2077 #endif
2078 ]], [[
2079 size_t ac_x; ac_x = malloc_usable_size(NULL);
2080 ]])], [
2081   AC_MSG_RESULT([yes])
2082   AC_DEFINE([HAVE_MALLOC_USABLE_SIZE], [1], [malloc_usable_size])
2083 ], [
2084   AC_MSG_RESULT([no])
2085
2086   AC_MSG_CHECKING([whether malloc_size is available])
2087   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2088 #ifdef HAVE_MALLOC_H
2089 #include <malloc.h>
2090 #endif
2091 #ifdef HAVE_MALLOC_MALLOC_H
2092 #include <malloc/malloc.h>
2093 #endif
2094 ]], [[
2095 size_t ac_x; ac_x = malloc_size(NULL);
2096 ]])], [
2097     AC_MSG_RESULT([yes])
2098     AC_DEFINE([HAVE_MALLOC_SIZE], [1], [malloc_size])
2099   ], [
2100     AC_MSG_RESULT([no])
2101   ])
2102 ])
2103
2104 dnl ----------
2105 dnl configure date
2106 dnl ----------
2107 dev_version=`echo $VERSION | grep dev`
2108 #don't expire deprecated code in non 'dev' branch
2109 if test "${dev_version}" = ""; then
2110    CONFDATE=0
2111 else
2112    CONFDATE=`date '+%Y%m%d'`
2113 fi
2114 AC_SUBST([CONFDATE])
2115
2116 dnl ------------------------------
2117 dnl set paths for state directory
2118 dnl ------------------------------
2119 AC_MSG_CHECKING([directory to use for state file])
2120 if test "${prefix}" = "NONE"; then
2121   frr_statedir_prefix="";
2122 else
2123   frr_statedir_prefix=${prefix}
2124 fi
2125 if test "${localstatedir}" = '${prefix}/var'; then
2126   for FRR_STATE_DIR in ${frr_statedir_prefix}/var/run dnl
2127                         ${frr_statedir_prefix}/var/adm dnl
2128                         ${frr_statedir_prefix}/etc dnl
2129                         /var/run        dnl
2130                         /var/adm        dnl
2131                         /etc            dnl
2132                         /dev/null;
2133   do
2134     test -d $FRR_STATE_DIR && break
2135   done
2136   frr_statedir=$FRR_STATE_DIR
2137 else
2138   frr_statedir=${localstatedir}
2139 fi
2140 if test $frr_statedir = "/dev/null"; then
2141     AC_MSG_ERROR([STATE DIRECTORY NOT FOUND! FIX OR SPECIFY --localstatedir!])
2142 fi
2143 AC_MSG_RESULT([${frr_statedir}])
2144 AC_SUBST([frr_statedir])
2145
2146 AC_DEFINE_UNQUOTED([LDPD_SOCKET], ["$frr_statedir%s%s/ldpd.sock"], [ldpd control socket])
2147 AC_DEFINE_UNQUOTED([ZEBRA_SERV_PATH], ["$frr_statedir%s%s/zserv.api"], [zebra api socket])
2148 AC_DEFINE_UNQUOTED([BFDD_CONTROL_SOCKET], ["$frr_statedir%s%s/bfdd.sock"], [bfdd control socket])
2149 AC_DEFINE_UNQUOTED([DAEMON_VTY_DIR], ["$frr_statedir%s%s"], [daemon vty directory])
2150 AC_DEFINE_UNQUOTED([DAEMON_DB_DIR], ["$frr_statedir"], [daemon database directory])
2151
2152 dnl autoconf does this, but it does it too late...
2153 test "x$prefix" = xNONE && prefix=$ac_default_prefix
2154 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
2155
2156 dnl get the full path, recursing through variables...
2157 vtysh_bin="$bindir/vtysh"
2158 for I in 1 2 3 4 5 6 7 8 9 10; do
2159         eval vtysh_bin="\"$vtysh_bin\""
2160 done
2161 AC_DEFINE_UNQUOTED([VTYSH_BIN_PATH], ["$vtysh_bin"], [path to vtysh binary])
2162 AC_SUBST([vtysh_bin])
2163
2164 CFG_SYSCONF="$sysconfdir"
2165 CFG_SBIN="$sbindir"
2166 CFG_STATE="$frr_statedir"
2167 CFG_MODULE="$moduledir"
2168 CFG_YANGMODELS="$yangmodelsdir"
2169 CFG_LIBYANG_PLUGINS="$libyang_pluginsdir"
2170 for I in 1 2 3 4 5 6 7 8 9 10; do
2171         eval CFG_SYSCONF="\"$CFG_SYSCONF\""
2172         eval CFG_SBIN="\"$CFG_SBIN\""
2173         eval CFG_STATE="\"$CFG_STATE\""
2174         eval CFG_MODULE="\"$CFG_MODULE\""
2175         eval CFG_YANGMODELS="\"$CFG_YANGMODELS\""
2176         eval CFG_LIBYANG_PLUGINS="\"$CFG_LIBYANG_PLUGINS\""
2177 done
2178 AC_SUBST([CFG_SYSCONF])
2179 AC_SUBST([CFG_SBIN])
2180 AC_SUBST([CFG_STATE])
2181 AC_SUBST([CFG_MODULE])
2182 AC_SUBST([CFG_YANGMODELS])
2183 AC_SUBST([CFG_LIBYANG_PLUGINS])
2184 AC_DEFINE_UNQUOTED([MODULE_PATH], ["$CFG_MODULE"], [path to modules])
2185 AC_DEFINE_UNQUOTED([YANG_MODELS_PATH], ["$CFG_YANGMODELS"], [path to YANG data models])
2186 AC_DEFINE_UNQUOTED([LIBYANG_PLUGINS_PATH], ["$CFG_LIBYANG_PLUGINS"], [path to libyang plugins])
2187 AC_DEFINE_UNQUOTED([WATCHFRR_SH_PATH], ["${CFG_SBIN%/}/watchfrr.sh"], [path to watchfrr.sh])
2188
2189 dnl various features
2190 AM_CONDITIONAL([SUPPORT_REALMS], [test "${enable_realms}" = "yes"])
2191 AM_CONDITIONAL([ENABLE_BGP_VNC], [test x${enable_bgp_vnc} != xno])
2192 dnl northbound
2193 AM_CONDITIONAL([SQLITE3], [$SQLITE3])
2194 AM_CONDITIONAL([CONFD], [test "x$enable_confd" != "x"])
2195 AM_CONDITIONAL([SYSREPO], [test "x$enable_sysrepo" = "xyes"])
2196 AM_CONDITIONAL([GRPC], [test "x$enable_grpc" = "xyes"])
2197 AM_CONDITIONAL([ZEROMQ], [test "x$ZEROMQ" = "xtrue"])
2198 dnl plugins
2199 AM_CONDITIONAL([RPKI], [test "x$RPKI" = "xtrue"])
2200 AM_CONDITIONAL([SNMP], [test "x$SNMP_METHOD" = "xagentx"])
2201 AM_CONDITIONAL([IRDP], [$IRDP])
2202 AM_CONDITIONAL([FPM], [test "x$enable_fpm" = "xyes"])
2203 AM_CONDITIONAL([HAVE_PROTOBUF], [test "x$enable_protobuf" = "xyes"])
2204 dnl daemons
2205 AM_CONDITIONAL([VTYSH], [test "x$VTYSH" = "xvtysh"])
2206 AM_CONDITIONAL([ZEBRA], [test "${enable_zebra}" != "no"])
2207 AM_CONDITIONAL([BGPD], [test "x${enable_bgpd}" != "no"])
2208 AM_CONDITIONAL([RIPD], [test "${enable_ripd}" != "no"])
2209 AM_CONDITIONAL([OSPFD], [test "${enable_ospfd}" != "no"])
2210 AM_CONDITIONAL([LDPD], [test "${enable_ldpd}" != "no"])
2211 AM_CONDITIONAL([BFDD], [test "x$BFDD" = "xbfdd"])
2212 AM_CONDITIONAL([NHRPD], [test "x$NHRPD" = "xnhrpd"])
2213 AM_CONDITIONAL([EIGRPD], [test "${enable_eigrpd}" != "no"])
2214 AM_CONDITIONAL([WATCHFRR], [test "x$WATCHFRR" = "xwatchfrr"])
2215 AM_CONDITIONAL([OSPFCLIENT], [test "x$OSPFCLIENT" = "xospfclient"])
2216 AM_CONDITIONAL([RIPNGD], [test "${enable_ripngd}" != "no"])
2217 AM_CONDITIONAL([BABELD], [test "${enable_babeld}" != "no"])
2218 AM_CONDITIONAL([OSPF6D], [test "${enable_ospf6d}" != "no"])
2219 AM_CONDITIONAL([ISISD], [test "${enable_isisd}" != "no"])
2220 AM_CONDITIONAL([PIMD], [test "${enable_pimd}" != "no"])
2221 AM_CONDITIONAL([PBRD], [test "${enable_pbrd}" != "no"])
2222 AM_CONDITIONAL([SHARPD], [test "${enable_sharpd}" = "yes"])
2223 AM_CONDITIONAL([STATICD], [test "${enable_staticd}" != "no"])
2224 AM_CONDITIONAL([FABRICD], [test "${enable_fabricd}" != "no"])
2225 AM_CONDITIONAL([VRRPD], [test "${enable_vrrpd}" != "no"])
2226
2227 AC_CONFIG_FILES([Makefile],[sed -e 's/^#AUTODERP# //' -i Makefile])
2228
2229 AC_CONFIG_FILES([
2230           config.version
2231           changelog-auto
2232           redhat/frr.spec
2233           solaris/Makefile
2234           alpine/APKBUILD
2235           snapcraft/snapcraft.yaml
2236           lib/version.h
2237           tests/lib/cli/test_cli.refout
2238           pkgsrc/bgpd.sh pkgsrc/ospf6d.sh pkgsrc/ospfd.sh
2239           pkgsrc/ripd.sh pkgsrc/ripngd.sh pkgsrc/zebra.sh
2240           pkgsrc/eigrpd.sh])
2241
2242 AC_CONFIG_FILES([vtysh/extract.pl], [chmod +x vtysh/extract.pl])
2243 AC_CONFIG_FILES([tools/frr], [chmod +x tools/frr])
2244 AC_CONFIG_FILES([tools/watchfrr.sh], [chmod +x tools/watchfrr.sh])
2245 AC_CONFIG_FILES([tools/frrinit.sh], [chmod +x tools/frrinit.sh])
2246 AC_CONFIG_FILES([tools/frrcommon.sh])
2247
2248 AC_CONFIG_COMMANDS([lib/route_types.h], [
2249         dst="${ac_abs_top_builddir}/lib/route_types.h"
2250         ${PERL} "${ac_abs_top_srcdir}/lib/route_types.pl" \
2251                 < "${ac_abs_top_srcdir}/lib/route_types.txt" \
2252                 > "${dst}.tmp"
2253         test -f "${dst}" \
2254                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
2255                 && rm "${dst}.tmp" \
2256                 || mv "${dst}.tmp" "${dst}"
2257 ], [
2258         PERL="$PERL"
2259 ])
2260
2261 AS_IF([test "x$with_pkg_git_version" = "xyes"], [
2262     AC_CONFIG_COMMANDS([lib/gitversion.h], [
2263         dst="${ac_abs_top_builddir}/lib/gitversion.h"
2264         ${PERL} "${ac_abs_top_srcdir}/lib/gitversion.pl" \
2265                 "${ac_abs_top_srcdir}" \
2266                 > "${dst}.tmp"
2267         test -f "${dst}" \
2268                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
2269                 && rm "${dst}.tmp" \
2270                 || mv "${dst}.tmp" "${dst}"
2271     ], [
2272         PERL="$PERL"
2273     ])
2274 ])
2275
2276 ## Hack, but working solution to avoid rebuilding of frr.info.
2277 ## It's already in CVS until texinfo 4.7 is more common.
2278 AC_OUTPUT
2279
2280 echo "
2281 FRRouting configuration
2282 ------------------------------
2283 FRR version             : ${PACKAGE_VERSION}
2284 host operating system   : ${host_os}
2285 source code location    : ${srcdir}
2286 compiler                : ${CC}
2287 compiler flags          : ${CFLAGS} ${SAN_FLAGS}
2288 make                    : ${MAKE-make}
2289 linker flags            : ${LDFLAGS} ${SAN_FLAGS} ${LIBS} ${LIBCAP} ${LIBREADLINE} ${LIBM}
2290 state file directory    : ${frr_statedir}
2291 config file directory   : `eval echo \`echo ${sysconfdir}\``
2292 example directory       : `eval echo \`echo ${exampledir}\``
2293 module directory        : ${CFG_MODULE}
2294 user to run as          : ${enable_user}
2295 group to run as         : ${enable_group}
2296 group for vty sockets   : ${enable_vty_group}
2297 config file mask        : ${enable_configfile_mask}
2298 log file mask           : ${enable_logfile_mask}
2299 zebra protobuf enabled  : ${enable_protobuf:-no}
2300
2301 The above user and group must have read/write access to the state file
2302 directory and to the config files in the config file directory."
2303
2304 if test "${enable_doc}" != "no" -a "$frr_py_mod_sphinx" = false; then
2305   AC_MSG_WARN([sphinx is missing but required to build documentation])
2306 fi
2307 if test "$frr_py_mod_pytest" = false; then
2308   AC_MSG_WARN([pytest is missing, unit tests cannot be performed])
2309 fi