configure.ac

   1 ##
   2 ## Configure template file for FRRouting.
   3 ## autoconf will generate a configure script.
   4 ##
   5 ##  Copyright (c) 1996, 97, 98, 99, 2000 Kunihiro Ishiguro <kunihiro@zebra.org>
   6 ##  Portions Copyright (c) 2003 Paul Jakma <paul@dishone.st>
   7 ##
   8 AC_PREREQ([2.69])
   9
  10 AC_INIT([frr], [8.1-dev], [https://github.com/frrouting/frr/issues])
  11 PACKAGE_URL="https://frrouting.org/"
  12 AC_SUBST([PACKAGE_URL])
  13 PACKAGE_FULLNAME="FRRouting"
  14 AC_SUBST([PACKAGE_FULLNAME])
  15
  16 CONFIG_ARGS="`echo $ac_configure_args | sed -e \"s% '[[A-Z]]*FLAGS=[[^']]\+'%%g\"`"
  17 AC_SUBST([CONFIG_ARGS])
  18
  19 AC_CONFIG_SRCDIR([lib/zebra.h])
  20 AC_CONFIG_MACRO_DIR([m4])
  21 AC_CONFIG_AUX_DIR([m4/ac])
  22
  23 dnl -----------------------------------
  24 dnl Get hostname and other information.
  25 dnl -----------------------------------
  26 AC_CANONICAL_BUILD()
  27 AC_CANONICAL_HOST()
  28
  29 AC_ARG_VAR([AR],[archiver command])
  30 AC_ARG_VAR([LD],[linker command])
  31 AC_ARG_VAR([OBJCOPY],[objcopy command])
  32 AC_ARG_VAR([OBJDUMP],[objdump command])
  33 AC_ARG_VAR([RANLIB],[ranlib command])
  34 AC_ARG_VAR([STRIP],[strip command])
  35
  36 hosttools_clippy="false"
  37 build_clippy="true"
  38
  39 dnl case 1: external clippy
  40 if test -n "$with_clippy" -a "$with_clippy" != "no" -a "$with_clippy" != "yes"; then
  41   if test "$enable_clippy_only" = "yes"; then
  42     AC_MSG_ERROR([--enable-clippy-only does not make sense with --with-clippy])
  43   fi
  44
  45   CLIPPY="$with_clippy"
  46   build_clippy="false"
  47   if test ! -x "$with_clippy"; then
  48     AC_MSG_ERROR([clippy tool ($with_clippy) is not executable])
  49   fi
  50
  51 dnl case 2: cross-compiling internal clippy
  52 elif test "$host" != "$build"; then
  53   if test "$srcdir" = "."; then
  54     AC_MSG_ERROR([cross-compilation is only possible with builddir separate from srcdir or by building clippy separately and using the --with-clippy option.  create a separate directory and run as .../path-to-frr/configure.])
  55   fi
  56   test -d hosttools || mkdir hosttools
  57   abssrc="`cd \"${srcdir}\"; pwd`"
  58
  59   AC_MSG_NOTICE([...])
  60   AC_MSG_NOTICE([... cross-compilation: creating hosttools directory and self-configuring for build platform tools])
  61   AC_MSG_NOTICE([... use HOST_CPPFLAGS / HOST_CFLAGS / HOST_LDFLAGS if neccessary])
  62   AC_MSG_NOTICE([...])
  63
  64   (
  65     for var in $ac_precious_vars; do
  66       dnl special cases
  67       case "$var" in
  68       YACC|YFLAGS) continue;;
  69       PYTHON*)     retain=true;;
  70       *)           retain=false;
  71       esac
  72
  73       eval "hostvar=\"\${HOST_$var}\""
  74       eval "targetvar=\"\${$var}\""
  75       if test -n "$hostvar"; then
  76         eval "$var='$hostvar'"
  77         _AS_ECHO_LOG([host $var='$hostvar'])
  78       elif $retain; then
  79         _AS_ECHO_LOG([host retain $var='$targetvar'])
  80       else
  81         eval "unset $var"
  82         _AS_ECHO_LOG([host unset $var])
  83       fi
  84     done
  85     cd hosttools
  86     "${abssrc}/configure" "--host=$build" "--build=$build" "--enable-clippy-only" "--disable-nhrpd" "--disable-vtysh"
  87   ) || exit 1
  88
  89   AC_MSG_NOTICE([...])
  90   AC_MSG_NOTICE([... cross-compilation: finished self-configuring for build platform tools])
  91   AC_MSG_NOTICE([...])
  92
  93   build_clippy="false"
  94   hosttools_clippy="true"
  95   CLIPPY="hosttools/lib/clippy"
  96
  97 dnl case 3: normal build internal clippy
  98 else
  99   CLIPPY="lib/clippy\$(EXEEXT)"
 100 fi
 101 AC_SUBST([CLIPPY])
 102 AM_CONDITIONAL([BUILD_CLIPPY], [$build_clippy])
 103 AM_CONDITIONAL([HOSTTOOLS_CLIPPY], [$hosttools_clippy])
 104 AM_CONDITIONAL([ONLY_CLIPPY], [test "$enable_clippy_only" = "yes"])
 105
 106 # Disable portability warnings -- our automake code (in particular
 107 # common.am) uses some constructs specific to gmake.
 108 AM_INIT_AUTOMAKE([1.12 -Wno-portability foreign])
 109 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
 110 AM_SILENT_RULES([yes])
 111 AC_CONFIG_HEADERS([config.h])
 112
 113 AC_PATH_PROG([PERL], [perl])
 114 PKG_PROG_PKG_CONFIG
 115
 116 dnl default is to match previous behavior
 117 pkgsrcrcdir=""
 118 AC_ARG_ENABLE([pkgsrcrcdir],
 119           AS_HELP_STRING([--enable-pkgsrcrcdir],
 120                          [specify directory for rc.d scripts]),
 121                          pkgsrcrcdir="$enableval",)
 122 dnl XXX add --pkgsrcrcdir to autoconf standard directory list somehow
 123 AC_SUBST([pkgsrcrcdir])
 124 AM_CONDITIONAL([PKGSRC], [test "$pkgsrcrcdir" != ""])
 125
 126 AC_ARG_WITH([moduledir], [AS_HELP_STRING([--with-moduledir=DIR], [module directory (${libdir}/frr/modules)])], [
 127         moduledir="$withval"
 128 ], [
 129         moduledir="\${libdir}/frr/modules"
 130 ])
 131 AC_SUBST([moduledir], [$moduledir])
 132
 133 AC_ARG_WITH([scriptdir], [AS_HELP_STRING([--with-scriptdir=DIR], [script directory (${sysconfdir}/scripts)])], [
 134         scriptdir="$withval"
 135 ], [
 136         scriptdir="\${sysconfdir}/scripts"
 137 ])
 138 AC_SUBST([scriptdir], [$scriptdir])
 139
 140 AC_ARG_WITH([yangmodelsdir], [AS_HELP_STRING([--with-yangmodelsdir=DIR], [yang models directory (${datarootdir}/yang)])], [
 141         yangmodelsdir="$withval"
 142 ], [
 143         yangmodelsdir="\${datarootdir}/yang"
 144 ])
 145 AC_SUBST([yangmodelsdir])
 146
 147 AC_ARG_WITH([vici-socket], [AS_HELP_STRING([--with-vici-socket=PATH], [vici-socket (/var/run/charon.vici)])], [
 148         vici_socket="$withval"
 149 ], [
 150         vici_socket="/var/run/charon.vici"
 151 ])
 152 AC_DEFINE_UNQUOTED([VICI_SOCKET], ["$vici_socket"], [StrongSWAN vici socket path])
 153
 154 AC_ARG_ENABLE(tcmalloc,
 155         AS_HELP_STRING([--enable-tcmalloc], [Turn on tcmalloc]),
 156 [case "${enableval}" in
 157   yes) tcmalloc_enabled=true
 158 LIBS="$LIBS -ltcmalloc_minimal"
 159  ;;
 160   no)  tcmalloc_enabled=false ;;
 161   *) AC_MSG_ERROR([bad value ${enableval} for --enable-tcmalloc]) ;;
 162 esac],[tcmalloc_enabled=false])
 163
 164
 165 dnl Thanks autoconf, but we don't want a default -g -O2.  We have our own
 166 dnl flag determination logic.
 167 CFLAGS="${CFLAGS:-}"
 168
 169 dnl --------------------
 170 dnl Check CC and friends
 171 dnl --------------------
 172 dnl note orig_cflags is also used further down
 173 orig_cflags="$CFLAGS"
 174 orig_cxxflags="$CXXFLAGS"
 175 AC_LANG([C])
 176 AC_PROG_CC
 177 AC_PROG_CPP
 178 AC_PROG_CXX
 179 AM_PROG_CC_C_O
 180 dnl remove autoconf default "-g -O2"
 181 CFLAGS="$orig_cflags"
 182 CXXFLAGS="$orig_cxxflags"
 183 AC_PROG_CC_C99
 184 dnl NB: see C11 below
 185
 186 dnl Some special handling for ICC later on
 187 if test "$CC" = "icc"; then
 188     cc_is_icc="yes"
 189 fi
 190
 191 PKG_PROG_PKG_CONFIG
 192
 193 dnl it's 2019, sed is sed.
 194 SED=sed
 195 AC_SUBST([SED])
 196
 197 dnl try and enable CFLAGS that are useful for FRR
 198 dnl - specifically, options to control warnings
 199
 200 AC_SUBST([AC_CFLAGS])
 201 AC_USE_SYSTEM_EXTENSIONS
 202 AC_DEFUN([AC_C_FLAG], [{
 203     m4_pushdef([cachename],[m4_translit([frr_cv_$1],[ =-+/{}$],[________])])
 204     AC_CACHE_CHECK([[whether $CC supports $1]], cachename, [
 205         AC_LANG_PUSH([C])
 206         ac_c_flag_save="$CFLAGS"
 207         CFLAGS="$CFLAGS $1"
 208         AC_COMPILE_IFELSE(
 209                 [AC_LANG_PROGRAM([[$4]])],
 210                 [
 211                         cachename=yes
 212                 ], [
 213                         cachename=no
 214                 ])
 215         CFLAGS="$ac_c_flag_save"
 216         AC_LANG_POP([C])
 217     ])
 218     if test "$cachename" = "yes"; then
 219         m4_if([$3], [], [AC_CFLAGS="$AC_CFLAGS $1"], [$3])
 220     else
 221         :
 222         $2
 223     fi
 224     m4_popdef([cachename])
 225 }])
 226
 227 AC_DEFUN([AC_LINK_IFELSE_FLAGS], [{
 228         AC_LANG_PUSH([C])
 229         ac_cflags_save="$CFLAGS"
 230         ac_libs_save="$LIBS"
 231         CFLAGS="$CFLAGS $1"
 232         LIBS="$LIBS $2"
 233         AC_LINK_IFELSE(
 234                 [$3],
 235                 [
 236                         CFLAGS="$ac_cflags_save"
 237                         LIBS="$ac_libs_save"
 238                         m4_default([$5], [
 239                                 AC_MSG_RESULT([yes])
 240                         ])
 241                 ], [
 242                         CFLAGS="$ac_cflags_save"
 243                         LIBS="$ac_libs_save"
 244                         m4_default([$4], [
 245                                 AC_MSG_RESULT([no])
 246                         ])
 247                 ])
 248         AC_LANG_POP([C])
 249         }])
 250
 251 dnl ICC won't bail on unknown options without -diag-error 10006
 252 dnl need to do this first so we get useful results for the other options
 253 if test "$cc_is_icc" = "yes"; then
 254     AC_C_FLAG([-diag-error 10006])
 255 fi
 256
 257 dnl AC_PROG_CC_C99 may change CC to include -std=gnu99 or something
 258 ac_cc="$CC"
 259 CC="${CC% -std=gnu99}"
 260 CC="${CC% -std=c99}"
 261
 262 AC_C_FLAG([-std=gnu11], [CC="$ac_cc"], [CC="$CC -std=gnu11"])
 263
 264 dnl if the user has specified any CFLAGS, override our settings
 265 if test "$enable_gcov" = "yes"; then
 266    if test "$orig_cflags" = ""; then
 267       AC_C_FLAG([-coverage])
 268       AC_C_FLAG([-O0])
 269    fi
 270
 271    AC_LDFLAGS="${AC_LDFLAGS} -lgcov"
 272 fi
 273
 274 if test "$enable_clang_coverage" = "yes"; then
 275    AC_C_FLAG([-fprofile-instr-generate], [
 276      AC_MSG_ERROR([$CC does not support -fprofile-instr-generate.])
 277    ])
 278    AC_C_FLAG([-fcoverage-mapping], [
 279      AC_MSG_ERROR([$CC does not support -fcoverage-mapping.])
 280    ])
 281 fi
 282
 283 if test "$enable_scripting" = "yes"; then
 284    AX_PROG_LUA([5.3], [5.4], [], [
 285      AC_MSG_ERROR([Lua 5.3 is required to build with Lua support. No other version is supported.])
 286    ])
 287    AX_LUA_HEADERS([], [
 288      AC_MSG_ERROR([Lua 5.3 headers are required to build with Lua support. No other version is supported.])
 289    ])
 290    AX_LUA_LIBS([
 291      AC_DEFINE([HAVE_SCRIPTING], [1], [Have support for scripting])
 292      LIBS="$LIBS $LUA_LIB"
 293    ], [
 294      AC_MSG_ERROR([Lua 5.3 libraries are required to build with Lua support. No other version is supported.])
 295    ])
 296 fi
 297
 298 dnl the following flags go in CFLAGS rather than AC_CFLAGS since they make
 299 dnl sense to be overridden by the user
 300 if test "$enable_dev_build" = "yes"; then
 301    AC_DEFINE([DEV_BUILD], [1], [Build for development])
 302    if test "$orig_cflags" = ""; then
 303       AC_C_FLAG([-O0],,[CFLAGS="$CFLAGS -O0"])
 304       AC_C_FLAG([-g3],,[CFLAGS="$CFLAGS -g3"])
 305       AC_C_FLAG([-ggdb3],,[CFLAGS="$CFLAGS -ggdb3"])
 306    fi
 307 else
 308    if test "$orig_cflags" = ""; then
 309       AC_C_FLAG([-g],,[CFLAGS="$CFLAGS -g"])
 310       AC_C_FLAG([-O2],,[CFLAGS="$CFLAGS -O2"])
 311    fi
 312 fi
 313
 314 AM_CONDITIONAL([DEV_BUILD], [test "$enable_dev_build" = "yes"])
 315
 316 dnl always want these CFLAGS
 317 AC_C_FLAG([-fno-omit-frame-pointer])
 318 AC_C_FLAG([-funwind-tables])
 319 AC_C_FLAG([-Wall])
 320 AC_C_FLAG([-Wextra])
 321 AC_C_FLAG([-Wmissing-prototypes])
 322 AC_C_FLAG([-Wmissing-declarations])
 323 AC_C_FLAG([-Wpointer-arith])
 324 AC_C_FLAG([-Wbad-function-cast])
 325 AC_C_FLAG([-Wwrite-strings])
 326 AC_C_FLAG([-Wundef])
 327 if test "$enable_gcc_ultra_verbose" = "yes" ; then
 328   AC_C_FLAG([-Wcast-qual])
 329   AC_C_FLAG([-Wstrict-prototypes])
 330   AC_C_FLAG([-Wmissing-noreturn])
 331   AC_C_FLAG([-Wmissing-format-attribute])
 332   AC_C_FLAG([-Wunreachable-code])
 333   AC_C_FLAG([-Wpacked])
 334   AC_C_FLAG([-Wpadded])
 335   AC_C_FLAG([-Wshadow])
 336 else
 337   AC_C_FLAG([-Wno-unused-result])
 338 fi
 339 AC_C_FLAG([-Wno-unused-parameter])
 340 AC_C_FLAG([-Wno-missing-field-initializers])
 341
 342 AC_C_FLAG([-Wc++-compat], [], [CXX_COMPAT_CFLAGS="-Wc++-compat"])
 343 AC_SUBST([CXX_COMPAT_CFLAGS])
 344
 345 dnl ICC emits a broken warning for const char *x = a ? "b" : "c";
 346 dnl for some reason the string consts get 'promoted' to char *,
 347 dnl triggering a const to non-const conversion warning.
 348 if test "$cc_is_icc" = "yes"; then
 349     AC_C_FLAG([-diag-disable 3179])
 350 fi
 351
 352 if test "$enable_werror" = "yes" ; then
 353   WERROR="-Werror"
 354 fi
 355 AC_SUBST([WERROR])
 356
 357 SAN_FLAGS=""
 358 if test "$enable_address_sanitizer" = "yes"; then
 359   AC_C_FLAG([-fsanitize=address], [
 360     AC_MSG_ERROR([$CC does not support Address Sanitizer.])
 361   ], [
 362     SAN_FLAGS="$SAN_FLAGS -fsanitize=address"
 363   ])
 364 fi
 365 if test "$enable_thread_sanitizer" = "yes"; then
 366   AC_C_FLAG([-fsanitize=thread], [
 367     AC_MSG_ERROR([$CC does not support Thread Sanitizer.])
 368   ], [
 369     SAN_FLAGS="$SAN_FLAGS -fsanitize=thread"
 370   ])
 371 fi
 372 if test "$enable_memory_sanitizer" = "yes"; then
 373   AC_C_FLAG([-fsanitize=memory -fPIE -pie], [
 374     AC_MSG_ERROR([$CC does not support Memory Sanitizer.])
 375   ], [
 376     SAN_FLAGS="$SAN_FLAGS -fsanitize=memory -fPIE -pie"
 377   ])
 378 fi
 379 if test "$enable_undefined_sanitizer" = "yes"; then
 380   AC_C_FLAG([-fsanitize=undefined], [
 381     AC_MSG_ERROR([$CC does not support UndefinedBehaviorSanitizer.])
 382   ], [
 383     SAN_FLAGS="$SAN_FLAGS -fsanitize=undefined"
 384   ])
 385 fi
 386 AC_SUBST([SAN_FLAGS])
 387
 388 dnl frr-format.so
 389 if test "$with_frr_format" != "no" -a "$with_frr_format" != "yes" -a -n "$with_frr_format"; then
 390   AC_C_FLAG([-fplugin=${with_frr_format}], [
 391     AC_MSG_ERROR([specified frr-format plugin ($with_frr_format) does not work])
 392   ],,[
 393 #ifndef _FRR_ATTRIBUTE_PRINTFRR
 394 #error plugin not loaded
 395 #endif
 396 #if _FRR_ATTRIBUTE_PRINTFRR < 0x10000
 397 #error plugin too old
 398 #endif
 399   ])
 400 elif test "$with_frr_format" = "no"; then
 401   : #nothing
 402 else
 403   AC_C_FLAG([-fplugin=tools/gcc-plugins/frr-format.so],[
 404     AC_C_FLAG([-fplugin=frr-format],[
 405       if test "$with_frr_format" = "yes"; then
 406         AC_MSG_ERROR([frr-format plugin requested but not found])
 407       fi
 408     ],,[
 409 #ifndef _FRR_ATTRIBUTE_PRINTFRR
 410 #error plugin not loaded
 411 #endif
 412 #if _FRR_ATTRIBUTE_PRINTFRR < 0x10000
 413 #error plugin too old
 414 #endif
 415     ])
 416   ],,[
 417 #ifndef _FRR_ATTRIBUTE_PRINTFRR
 418 #error plugin not loaded
 419 #endif
 420 #if _FRR_ATTRIBUTE_PRINTFRR < 0x10000
 421 #error plugin too old
 422 #endif
 423   ])
 424 fi
 425
 426 AC_MSG_CHECKING([whether linker supports __start/stop_section symbols])
 427 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 428 #include <stdio.h>
 429 int __attribute__((section("secttest"))) var = 1;
 430 extern int __start_secttest, __stop_secttest;
 431 ]], [[
 432   void *a = &var, *b = &__start_secttest, *c = &__stop_secttest;
 433   printf("%p %p %p\n", a, b, c);
 434 ]])], [
 435   AC_MSG_RESULT(yes)
 436   AC_DEFINE(HAVE_SECTION_SYMS, 1, [have __start/stop_section symbols])
 437 ], [
 438   AC_MSG_RESULT(no)
 439 ])
 440
 441 dnl ----------
 442 dnl Essentials
 443 dnl ----------
 444
 445 AX_PTHREAD([
 446   CC="$PTHREAD_CC"
 447   AC_CFLAGS="$AC_CFLAGS $PTHREAD_CFLAGS"
 448   LIBS="$PTHREAD_LIBS $LIBS"
 449 ], [
 450   AC_MSG_FAILURE([This FRR version needs pthreads])
 451 ])
 452
 453 orig_cflags="$CFLAGS"
 454 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 455
 456 AC_SEARCH_LIBS([pthread_condattr_setclock], [],
 457                 [frr_cv_pthread_condattr_setclock=yes],
 458                 [frr_cv_pthread_condattr_setclock=no])
 459 if test "$frr_cv_pthread_condattr_setclock" = "yes"; then
 460   AC_DEFINE([HAVE_PTHREAD_CONDATTR_SETCLOCK], [1], [Have pthread.h pthread_condattr_setclock])
 461 fi
 462
 463 AC_CHECK_HEADERS([pthread_np.h],,, [
 464 #include <pthread.h>
 465 ])
 466 AC_CHECK_FUNCS([pthread_setname_np pthread_set_name_np pthread_getthreadid_np])
 467
 468 CFLAGS="$orig_cflags"
 469
 470 dnl --------------
 471 dnl Check programs
 472 dnl --------------
 473 AC_PROG_INSTALL
 474 AC_PROG_LN_S
 475 AC_CHECK_TOOL([AR], [ar])
 476
 477 dnl -------
 478 dnl libtool
 479 dnl -------
 480 AC_ARG_ENABLE([static-bin],
 481   AS_HELP_STRING([--enable-static-bin], [link binaries statically]))
 482 LT_INIT
 483 _LT_CONFIG_LIBTOOL([
 484   patch -N -i "${srcdir}/m4/libtool-whole-archive.patch" libtool >&AS_MESSAGE_LOG_FD || \
 485     AC_MSG_WARN([Could not patch libtool for static linking support.  Loading modules into a statically linked daemon will fail.])
 486   sed -e 's%func_warning "relinking%true #\0%' -i libtool || true
 487   sed -e 's%func_warning "remember to run%true #\0%' -i libtool || true
 488   sed -e 's%func_warning ".*has not been installed in%true #\0%' -i libtool || true
 489 ])
 490 if test "$enable_static_bin" = "yes"; then
 491   AC_LDFLAGS="-static"
 492   if test "$enable_static" != "yes"; then
 493     AC_MSG_ERROR([The --enable-static-bin option must be combined with --enable-static.])
 494   fi
 495 fi
 496 if test "$enable_shared" != "yes"; then
 497   AC_MSG_ERROR([FRR cannot be built with --disable-shared.  If you want statically linked daemons, use --enable-shared --enable-static --enable-static-bin])
 498 fi
 499 AC_SUBST([AC_LDFLAGS])
 500 AM_CONDITIONAL([STATIC_BIN], [test "$enable_static_bin" = "yes"])
 501
 502 AC_ARG_ENABLE([rpath],
 503   [AS_HELP_STRING([--enable-rpath], [set hardcoded rpaths in the executable @<:@default=yes@:>@])],
 504   [],
 505   [enable_rpath=yes])
 506
 507 dnl $AR and $RANLIB are set by LT_INIT above
 508 AC_MSG_CHECKING([whether $AR supports D option])
 509 if $AR crD conftest.a >/dev/null 2>/dev/null; then
 510   AC_MSG_RESULT([yes])
 511   dnl ARFLAGS is for automake, AR_FLAGS for libtool m-(
 512   ARFLAGS="crD"
 513   AR_FLAGS="crD"
 514 else
 515   AC_MSG_RESULT([no])
 516   ARFLAGS="cru"
 517   AR_FLAGS="cru"
 518 fi
 519 AC_SUBST([ARFLAGS])
 520 AC_SUBST([AR_FLAGS])
 521
 522 AC_MSG_CHECKING([whether $RANLIB supports D option])
 523 if $RANLIB -D conftest.a >conftest.err 2>&1; then
 524   if grep -q -- '-D' conftest.err; then
 525     AC_MSG_RESULT([no])
 526   else
 527     AC_MSG_RESULT([yes])
 528     RANLIB="$RANLIB -D"
 529   fi
 530 else
 531   AC_MSG_RESULT([no])
 532 fi
 533 AC_SUBST([RANLIB])
 534
 535 test -f conftest.err && rm conftest.err
 536 test -f conftest.a && rm conftest.a
 537
 538 dnl ----------------------
 539 dnl Packages configuration
 540 dnl ----------------------
 541 if test -f config.version; then
 542   . ./config.version
 543 elif test -f "${srcdir}/config.version"; then
 544   . "${srcdir}/config.version"
 545 fi
 546 AC_ARG_WITH([pkg-extra-version],
 547   AS_HELP_STRING([--with-pkg-extra-version=VER], [add extra version field, for packagers/distributions]), [
 548   if test "$withval" = "no"; then
 549     EXTRAVERSION=
 550   else
 551     EXTRAVERSION=$withval
 552   fi
 553 ], [])
 554 AC_ARG_WITH([pkg-git-version],
 555         AS_HELP_STRING([--with-pkg-git-version], [add git information to MOTD and build version string]),
 556         [ test "$withval" != "no" && with_pkg_git_version="yes" ])
 557 AC_ARG_WITH([clippy],
 558   AS_HELP_STRING([--with-clippy=PATH], [use external clippy helper program]))
 559 AC_ARG_WITH([vtysh_pager],
 560         AS_HELP_STRING([--with-vtysh-pager=PAGER], [control what pager is compiled in as default]),
 561         VTYSH_PAGER=$withval, VTYSH_PAGER="more")
 562 AC_ARG_ENABLE([vtysh],
 563   AS_HELP_STRING([--disable-vtysh], [do not build integrated vty shell for FRR]))
 564 AC_ARG_ENABLE([doc],
 565   AS_HELP_STRING([--disable-doc], [do not build docs]))
 566 AC_ARG_ENABLE([doc-html],
 567   AS_HELP_STRING([--enable-doc-html], [build HTML docs]))
 568 AC_ARG_ENABLE([zebra],
 569   AS_HELP_STRING([--disable-zebra], [do not build zebra daemon]))
 570 AC_ARG_ENABLE([bgpd],
 571   AS_HELP_STRING([--disable-bgpd], [do not build bgpd]))
 572 AC_ARG_ENABLE([ripd],
 573   AS_HELP_STRING([--disable-ripd], [do not build ripd]))
 574 AC_ARG_ENABLE([ripngd],
 575   AS_HELP_STRING([--disable-ripngd], [do not build ripngd]))
 576 AC_ARG_ENABLE([ospfd],
 577   AS_HELP_STRING([--disable-ospfd], [do not build ospfd]))
 578 AC_ARG_ENABLE([ospf6d],
 579   AS_HELP_STRING([--disable-ospf6d], [do not build ospf6d]))
 580 AC_ARG_ENABLE([ldpd],
 581   AS_HELP_STRING([--disable-ldpd], [do not build ldpd]))
 582 AC_ARG_ENABLE([nhrpd],
 583   AS_HELP_STRING([--disable-nhrpd], [do not build nhrpd]))
 584 AC_ARG_ENABLE([eigrpd],
 585   AS_HELP_STRING([--disable-eigrpd], [do not build eigrpd]))
 586 AC_ARG_ENABLE([babeld],
 587   AS_HELP_STRING([--disable-babeld], [do not build babeld]))
 588 AC_ARG_ENABLE([watchfrr],
 589   AS_HELP_STRING([--disable-watchfrr], [do not build watchfrr]))
 590 AC_ARG_ENABLE([isisd],
 591   AS_HELP_STRING([--disable-isisd], [do not build isisd]))
 592 AC_ARG_ENABLE([pimd],
 593   AS_HELP_STRING([--disable-pimd], [do not build pimd]))
 594 AC_ARG_ENABLE([pbrd],
 595   AS_HELP_STRING([--disable-pbrd], [do not build pbrd]))
 596 AC_ARG_ENABLE([sharpd],
 597   AS_HELP_STRING([--enable-sharpd], [build sharpd]))
 598 AC_ARG_ENABLE([staticd],
 599   AS_HELP_STRING([--disable-staticd], [do not build staticd]))
 600 AC_ARG_ENABLE([fabricd],
 601   AS_HELP_STRING([--disable-fabricd], [do not build fabricd]))
 602 AC_ARG_ENABLE([vrrpd],
 603   AS_HELP_STRING([--disable-vrrpd], [do not build vrrpd]))
 604 AC_ARG_ENABLE([pathd],
 605   AS_HELP_STRING([--disable-pathd], [do not build pathd]))
 606 AC_ARG_ENABLE([bgp-announce],
 607   AS_HELP_STRING([--disable-bgp-announce], [turn off BGP route announcement]))
 608 AC_ARG_ENABLE([bgp-vnc],
 609   AS_HELP_STRING([--disable-bgp-vnc],[turn off BGP VNC support]))
 610 AC_ARG_ENABLE([bgp-bmp],
 611   AS_HELP_STRING([--disable-bgp-bmp],[turn off BGP BMP support]))
 612 AC_ARG_ENABLE([snmp],
 613   AS_HELP_STRING([--enable-snmp], [enable SNMP support for agentx]))
 614 AC_ARG_ENABLE([config_rollbacks],
 615   AS_HELP_STRING([--enable-config-rollbacks], [enable configuration rollbacks (requires sqlite3)]))
 616 AC_ARG_ENABLE([confd],
 617   AS_HELP_STRING([--enable-confd=ARG], [enable confd integration]))
 618 AC_ARG_ENABLE([sysrepo],
 619   AS_HELP_STRING([--enable-sysrepo], [enable sysrepo integration]))
 620 AC_ARG_ENABLE([grpc],
 621   AS_HELP_STRING([--enable-grpc], [enable the gRPC northbound plugin]))
 622 AC_ARG_ENABLE([zeromq],
 623   AS_HELP_STRING([--enable-zeromq], [enable ZeroMQ handler (libfrrzmq)]))
 624 AC_ARG_ENABLE([lttng],
 625   AS_HELP_STRING([--enable-lttng], [enable LTTng tracing]))
 626 AC_ARG_ENABLE([usdt],
 627   AS_HELP_STRING([--enable-usdt], [enable USDT probes]))
 628 AC_ARG_WITH([libpam],
 629   AS_HELP_STRING([--with-libpam], [use libpam for PAM support in vtysh]))
 630 AC_ARG_ENABLE([ospfapi],
 631   AS_HELP_STRING([--disable-ospfapi], [do not build OSPFAPI to access the OSPF LSA Database]))
 632 AC_ARG_ENABLE([ospfclient],
 633   AS_HELP_STRING([--disable-ospfclient], [do not build OSPFAPI client for OSPFAPI,
 634                           (this is the default if --disable-ospfapi is set)]))
 635 AC_ARG_ENABLE([multipath],
 636   AS_HELP_STRING([--enable-multipath=ARG], [enable multipath function, ARG must be digit]))
 637 AC_ARG_ENABLE([user],
 638   AS_HELP_STRING([--enable-user=USER], [user to run FRR suite as (default frr)]))
 639 AC_ARG_ENABLE([group],
 640   AS_HELP_STRING([--enable-group=GROUP], [group to run FRR suite as (default frr)]))
 641 AC_ARG_ENABLE([vty_group],
 642   AS_HELP_STRING([--enable-vty-group=ARG], [set vty sockets to have specified group as owner]))
 643 AC_ARG_ENABLE([configfile_mask],
 644   AS_HELP_STRING([--enable-configfile-mask=ARG], [set mask for config files]))
 645 AC_ARG_ENABLE([logfile_mask],
 646   AS_HELP_STRING([--enable-logfile-mask=ARG], [set mask for log files]))
 647 AC_ARG_ENABLE([shell_access],
 648   AS_HELP_STRING([--enable-shell-access], [Allow users to access shell/telnet/ssh]))
 649 AC_ARG_ENABLE([realms],
 650   AS_HELP_STRING([--enable-realms], [enable REALMS support under Linux]))
 651 AC_ARG_ENABLE([rtadv],
 652   AS_HELP_STRING([--disable-rtadv], [disable IPV6 router advertisement feature]))
 653 AC_ARG_ENABLE([irdp],
 654   AS_HELP_STRING([--disable-irdp], [disable IRDP server support in zebra (enabled by default if supported)]))
 655 AC_ARG_ENABLE([capabilities],
 656   AS_HELP_STRING([--disable-capabilities], [disable using POSIX capabilities]))
 657 AC_ARG_ENABLE([rusage],
 658   AS_HELP_STRING([--disable-rusage], [disable using getrusage]))
 659 AC_ARG_ENABLE([gcc_ultra_verbose],
 660   AS_HELP_STRING([--enable-gcc-ultra-verbose], [enable ultra verbose GCC warnings]))
 661 AC_ARG_ENABLE([backtrace],
 662   AS_HELP_STRING([--disable-backtrace], [disable crash backtraces (default autodetect)]))
 663 AC_ARG_ENABLE([time-check],
 664   AS_HELP_STRING([--disable-time-check], [disable slow thread warning messages]))
 665 AC_ARG_ENABLE([cpu-time],
 666   AS_HELP_STRING([--disable-cpu-time], [disable cpu usage data gathering]))
 667 AC_ARG_ENABLE([pcreposix],
 668   AS_HELP_STRING([--enable-pcreposix], [enable using PCRE Posix libs for regex functions]))
 669 AC_ARG_ENABLE([fpm],
 670   AS_HELP_STRING([--enable-fpm], [enable Forwarding Plane Manager support]))
 671 AC_ARG_ENABLE([pcep],
 672   AS_HELP_STRING([--enable-pcep], [enable PCEP support for pathd]))
 673 AC_ARG_ENABLE([systemd],
 674   AS_HELP_STRING([--enable-systemd], [enable Systemd support]))
 675 AC_ARG_ENABLE([werror],
 676   AS_HELP_STRING([--enable-werror], [enable -Werror (recommended for developers only)]))
 677 AC_ARG_ENABLE([cumulus],
 678   AS_HELP_STRING([--enable-cumulus], [enable Cumulus Switch Special Extensions]))
 679 AC_ARG_ENABLE([datacenter],
 680   AS_HELP_STRING([--enable-datacenter], [enable Compilation for Data Center Extensions]))
 681 AC_ARG_ENABLE([rr-semantics],
 682   AS_HELP_STRING([--disable-rr-semantics], [disable the v6 Route Replace semantics]))
 683 AC_ARG_ENABLE([protobuf],
 684   AS_HELP_STRING([--enable-protobuf], [Enable experimental protobuf support]))
 685 AC_ARG_ENABLE([oldvpn_commands],
 686   AS_HELP_STRING([--enable-oldvpn-commands], [Keep old vpn commands]))
 687 AC_ARG_ENABLE([rpki],
 688   AS_HELP_STRING([--enable-rpki], [enable RPKI prefix validation support]))
 689 AC_ARG_ENABLE([clippy-only],
 690   AS_HELP_STRING([--enable-clippy-only], [Only build clippy]))
 691 AC_ARG_ENABLE([numeric_version],
 692   AS_HELP_STRING([--enable-numeric-version], [Only numeric digits allowed in version (for Alpine)]))
 693 AC_ARG_ENABLE([gcov],
 694   AS_HELP_STRING([--enable-gcov], [Collect coverage information with gcov]))
 695 AC_ARG_ENABLE([clang_coverage],
 696   AS_HELP_STRING([--enable-clang-coverage], [Collect coverage information with Clang Coverage]))
 697 AC_ARG_ENABLE([bfdd],
 698   AS_HELP_STRING([--disable-bfdd], [do not build bfdd]))
 699 AC_ARG_ENABLE([address-sanitizer],
 700   AS_HELP_STRING([--enable-address-sanitizer], [enable AddressSanitizer support for detecting a wide variety of memory allocation and deallocation errors]))
 701 AC_ARG_ENABLE([thread-sanitizer],
 702   AS_HELP_STRING([--enable-thread-sanitizer], [enable ThreadSanitizer support for detecting data races]))
 703 AC_ARG_ENABLE([memory-sanitizer],
 704   AS_HELP_STRING([--enable-memory-sanitizer], [enable MemorySanitizer support for detecting uninitialized memory reads]))
 705 AC_ARG_ENABLE([undefined-sanitizer],
 706   AS_HELP_STRING([--undefined-sanitizer], [enable UndefinedBehaviorSanitizer support for detecting undefined behavior]))
 707 AC_ARG_WITH([crypto],
 708   AS_HELP_STRING([--with-crypto=<internal|openssl>], [choose between different implementations of cryptographic functions(default value is --with-crypto=internal)]))
 709 AC_ARG_WITH([frr-format],
 710   AS_HELP_STRING([--with-frr-format[=<.../frr-format.so>]], [use frr-format GCC plugin]))
 711
 712 AC_ARG_ENABLE([version-build-config],
 713   AS_HELP_STRING([--disable-version-build-config], [do not include build configs in show version command]))
 714
 715 #if openssl, else use the internal
 716 AS_IF([test "$with_crypto" = "openssl"], [
 717 AC_CHECK_LIB([crypto], [EVP_DigestInit], [LIBS="$LIBS -lcrypto"], [], [])
 718 if test "$ac_cv_lib_crypto_EVP_DigestInit" = "no"; then
 719   AC_MSG_ERROR([build with openssl has been specified but openssl library was not found on your system])
 720 else
 721   AC_DEFINE([CRYPTO_OPENSSL], [1], [Compile with openssl support])
 722 fi
 723 ], [test "$with_crypto" = "internal" || test "$with_crypto" = "" ], [AC_DEFINE([CRYPTO_INTERNAL], [1], [Compile with internal cryptographic implementation])
 724 ], [AC_MSG_ERROR([Unknown value for --with-crypto])]
 725 )
 726
 727 AS_IF([test "$enable_clippy_only" != "yes"], [
 728 AC_CHECK_HEADERS([json-c/json.h])
 729 AC_CHECK_LIB([json-c], [json_object_get], [LIBS="$LIBS -ljson-c"], [], [-lm])
 730 if test "$ac_cv_lib_json_c_json_object_get" = "no"; then
 731   AC_CHECK_LIB([json], [json_object_get], [LIBS="$LIBS -ljson"])
 732   if test "$ac_cv_lib_json_json_object_get" = "no"; then
 733       AC_MSG_ERROR([libjson is needed to compile])
 734   fi
 735 fi
 736 ])
 737
 738 AC_ARG_ENABLE([dev_build],
 739     AS_HELP_STRING([--enable-dev-build], [build for development]))
 740
 741 AC_ARG_ENABLE([scripting],
 742     AS_HELP_STRING([--enable-scripting], [Build with scripting support]))
 743
 744 AC_ARG_ENABLE([netlink-debug],
 745   AS_HELP_STRING([--disable-netlink-debug], [pretty print netlink debug messages]))
 746
 747 if test "$enable_netlink_debug" != "no" ; then
 748   AC_DEFINE([NETLINK_DEBUG], [1], [Netlink extra debugging code])
 749 fi
 750
 751 AM_CONDITIONAL([NETLINK_DEBUG], [test "$enable_netlink_debug" != "no"])
 752
 753 if test "$enable_time_check" != "no" ; then
 754   if test "$enable_time_check" = "yes" -o "$enable_time_check" = "" ; then
 755     AC_DEFINE([CONSUMED_TIME_CHECK], [5000000], [Consumed Time Check])
 756   else
 757     AC_DEFINE_UNQUOTED([CONSUMED_TIME_CHECK], [$enable_time_check], [Consumed Time Check])
 758   fi
 759 fi
 760
 761 case "${enable_cpu_time}" in
 762   "no")
 763   AC_DEFINE([EXCLUDE_CPU_TIME], [1], [Exclude getrusage data gathering])
 764   ;;
 765   "*")
 766   ;;
 767 esac
 768
 769 case "${enable_systemd}" in
 770   "no") ;;
 771   "yes")
 772   AC_CHECK_LIB([systemd], [sd_notify], [LIBS="$LIBS -lsystemd"])
 773   if test "$ac_cv_lib_systemd_sd_notify" = "no"; then
 774     AC_MSG_ERROR([enable systemd has been specified but systemd development env not found on your system])
 775   else
 776     AC_DEFINE([HAVE_SYSTEMD], [1], [Compile systemd support in])
 777   fi
 778   ;;
 779   "*") ;;
 780 esac
 781
 782 if test "$enable_rr_semantics" != "no" ; then
 783   AC_DEFINE([HAVE_V6_RR_SEMANTICS], [1], [Compile in v6 Route Replacement Semantics])
 784 fi
 785
 786 if test "$enable_datacenter" = "yes" ; then
 787   AC_DEFINE([HAVE_DATACENTER], [1], [Compile extensions for a DataCenter])
 788   AC_MSG_WARN([The --enable-datacenter compile time option is deprecated.  Please modify the init script to pass -F datacenter to the daemons instead.])
 789   DFLT_NAME="datacenter"
 790 else
 791   DFLT_NAME="traditional"
 792 fi
 793
 794 if test "$enable_cumulus" = "yes" ; then
 795   AC_DEFINE([HAVE_CUMULUS], [1], [Compile Special Cumulus Code in])
 796 fi
 797
 798 AC_SUBST([DFLT_NAME])
 799 AC_DEFINE_UNQUOTED([DFLT_NAME], ["$DFLT_NAME"], [Name of the configuration default set])
 800
 801 if test "$enable_shell_access" = "yes"; then
 802    AC_DEFINE([HAVE_SHELL_ACCESS], [1], [Allow user to use ssh/telnet/bash, be aware this is considered insecure])
 803 fi
 804
 805 #
 806 # Python for clippy
 807 #
 808
 809 AS_IF([test "$host" = "$build"], [
 810   AC_CHECK_HEADER([gelf.h], [], [
 811     AC_MSG_ERROR([libelf headers are required for building clippy.  (Host only when cross-compiling.)])
 812   ])
 813   AC_CHECK_LIB([elf], [elf_memory], [], [
 814     AC_MSG_ERROR([libelf is required for building clippy.  (Host only when cross-compiling.)])
 815   ])
 816
 817   AC_CHECK_LIB([elf], [elf_getdata_rawchunk], [
 818     AC_DEFINE([HAVE_ELF_GETDATA_RAWCHUNK], [1], [Have elf_getdata_rawchunk()])
 819   ])
 820   AC_CHECK_LIB([elf], [gelf_getnote], [
 821     AC_DEFINE([HAVE_GELF_GETNOTE], [1], [Have gelf_getnote()])
 822   ])
 823
 824   FRR_PYTHON_DEV
 825 ], [
 826   FRR_PYTHON
 827 ])
 828
 829 FRR_PYTHON_MODULES([pytest])
 830
 831 if test "$enable_doc" != "no"; then
 832   FRR_PYTHON_MODULES([sphinx], , [
 833     if test "$enable_doc" = "yes"; then
 834       AC_MSG_ERROR([Documentation was explicitly requested with --enable-doc but sphinx is not available for $PYTHON. Please disable docs or install sphinx.])
 835     fi
 836   ])
 837 fi
 838 AM_CONDITIONAL([DOC], [test "$enable_doc" != "no" -a "$frr_py_mod_sphinx" != "false"])
 839 AM_CONDITIONAL([DOC_HTML], [test "$enable_doc_html" = "yes"])
 840
 841 FRR_PYTHON_MOD_EXEC([sphinx], [--version], [
 842   PYSPHINX="-m sphinx"
 843 ], [
 844   PYSPHINX="-c 'import sys; from sphinx import main; sys.exit(main(sys.argv))'"
 845 ])
 846 AC_SUBST([PYSPHINX])
 847
 848 #
 849 # Logic for old vpn commands support.
 850 #
 851 if test "$enable_oldvpn_commands" = "yes"; then
 852    AC_DEFINE([KEEP_OLD_VPN_COMMANDS], [1], [Define for compiling with old vpn commands])
 853 fi
 854
 855 #
 856 # End of logic for protobuf support.
 857 #
 858
 859 AC_MSG_CHECKING([if zebra should be configurable to send Route Advertisements])
 860 if test "$enable_rtadv" != "no"; then
 861   AC_MSG_RESULT([yes])
 862   AC_DEFINE([HAVE_RTADV], [1], [Enable IPv6 Routing Advertisement support])
 863 else
 864   AC_MSG_RESULT([no])
 865 fi
 866
 867 if test "$enable_user" = "no"; then
 868   enable_user=""
 869 else
 870   if test "$enable_user" = "yes" || test "$enable_user" = ""; then
 871     enable_user="frr"
 872   fi
 873   AC_DEFINE_UNQUOTED([FRR_USER], ["${enable_user}"], [frr User])
 874 fi
 875
 876 if test "$enable_group" = "no"; then
 877   enable_group=""
 878 else
 879   if test "$enable_group" = "yes" || test "$enable_group" = ""; then
 880     enable_group="frr"
 881   fi
 882   AC_DEFINE_UNQUOTED([FRR_GROUP], ["${enable_group}"], [frr Group])
 883 fi
 884
 885 if test "$enable_vty_group" = "yes" ; then
 886   AC_MSG_ERROR([--enable-vty-group requires a group as argument, not yes])
 887 elif test "$enable_vty_group" != ""; then
 888   if test "$enable_vty_group" != "no"; then
 889     AC_DEFINE_UNQUOTED([VTY_GROUP], ["${enable_vty_group}"], [VTY Sockets Group])
 890   fi
 891 fi
 892 AC_SUBST([enable_user])
 893 AC_SUBST([enable_group])
 894 AC_SUBST([enable_vty_group])
 895
 896 enable_configfile_mask=${enable_configfile_mask:-0600}
 897 AC_DEFINE_UNQUOTED([CONFIGFILE_MASK], [${enable_configfile_mask}], [Mask for config files])
 898 AC_SUBST([enable_configfile_mask])
 899
 900 enable_logfile_mask=${enable_logfile_mask:-0600}
 901 AC_DEFINE_UNQUOTED([LOGFILE_MASK], [${enable_logfile_mask}], [Mask for log files])
 902
 903 MPATH_NUM=16
 904
 905 case "${enable_multipath}" in
 906   0)
 907     MPATH_NUM=64
 908     ;;
 909   [[1-9]|[1-9][0-9]|[1-9][0-9][0-9]])
 910     MPATH_NUM="${enable_multipath}"
 911     ;;
 912   "")
 913     ;;
 914   *)
 915     AC_MSG_FAILURE([Please specify digit to enable multipath ARG])
 916     ;;
 917 esac
 918
 919 AC_DEFINE_UNQUOTED([MULTIPATH_NUM], [$MPATH_NUM], [Maximum number of paths for a route])
 920
 921 AC_DEFINE_UNQUOTED([VTYSH_PAGER], ["$VTYSH_PAGER"], [What pager to use])
 922
 923 dnl --------------------
 924 dnl Enable code coverage
 925 dnl --------------------
 926 AM_CONDITIONAL([HAVE_GCOV], [test "$enable_gcov" != "no"])
 927
 928 dnl ------------------------------------
 929 dnl Alpine only accepts numeric versions
 930 dnl ------------------------------------
 931 if test "$enable_numeric_version" != "" ; then
 932   VERSION="`echo ${VERSION} | tr -c -d '[[.0-9]]'`"
 933   PACKAGE_VERSION="`echo ${PACKAGE_VERSION} | tr -c -d '[[.0-9]]'`"
 934 fi
 935
 936 dnl -----------------------------------
 937 dnl Add extra version string to package
 938 dnl name, string and version fields.
 939 dnl -----------------------------------
 940 if test "$EXTRAVERSION" != "" ; then
 941   VERSION="${VERSION}${EXTRAVERSION}"
 942   PACKAGE_VERSION="${PACKAGE_VERSION}${EXTRAVERSION}"
 943   AC_SUBST(PACKAGE_EXTRAVERSION, ["${EXTRAVERSION}"])
 944   PACKAGE_STRING="${PACKAGE_STRING}${EXTRAVERSION}"
 945 fi
 946 AC_SUBST([EXTRAVERSION])
 947
 948 if test "$with_pkg_git_version" = "yes"; then
 949         if test -e "${srcdir}/.git"; then
 950                 AC_DEFINE([GIT_VERSION], [1], [include git version info])
 951         else    with_pkg_git_version="no"
 952                 AC_MSG_WARN([--with-pkg-git-version given, but this is not a git checkout])
 953         fi
 954 fi
 955 AM_CONDITIONAL([GIT_VERSION], [test "$with_pkg_git_version" = "yes"])
 956
 957 AC_CHECK_TOOL([OBJCOPY], [objcopy], [:])
 958 if test "$OBJCOPY" != ":"; then
 959   AC_CACHE_CHECK([for .interp value to use], [frr_cv_interp], [
 960     frr_cv_interp=""
 961     AC_LINK_IFELSE([AC_LANG_SOURCE([[int main() { return 0; }]])], [
 962       if $OBJCOPY -j.interp -Obinary conftest conftest.interp; then
 963         frr_cv_interp="`xargs -0 echo < conftest.interp`"
 964       fi
 965       test -f conftest.interp && rm conftest.interp
 966     ])
 967   ])
 968 fi
 969 if test -n "$frr_cv_interp"; then
 970   AC_DEFINE_UNQUOTED([INTERP], ["$frr_cv_interp"], [.interp value])
 971 fi
 972
 973 dnl -------------------------
 974 dnl Check other header files.
 975 dnl -------------------------
 976 AC_CHECK_HEADERS([stropts.h sys/ksym.h \
 977         linux/version.h asm/types.h endian.h sys/endian.h])
 978
 979 ac_stdatomic_ok=false
 980 AC_DEFINE([FRR_AUTOCONF_ATOMIC], [1], [did autoconf checks for atomic funcs])
 981 AC_CHECK_HEADER([stdatomic.h],[
 982
 983   AC_MSG_CHECKING([whether _Atomic qualifier works])
 984   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 985 #include <stdatomic.h>
 986 int main(int argc, char **argv) {
 987   _Atomic int i = 0;
 988   return i;
 989 }
 990 ]])], [
 991     AC_DEFINE([HAVE_STDATOMIC_H], [1], [found stdatomic.h])
 992     AC_MSG_RESULT([yes])
 993     ac_stdatomic_ok=true
 994   ], [
 995     AC_MSG_RESULT([no])
 996   ])
 997 ])
 998
 999 AS_IF([$ac_stdatomic_ok], [true], [
1000   AC_MSG_CHECKING([for __atomic_* builtins])
1001   AC_LINK_IFELSE([AC_LANG_SOURCE([[
1002 int main(int argc, char **argv) {
1003   volatile int i = 1;
1004   __atomic_store_n (&i, 0, __ATOMIC_RELEASE);
1005   return __atomic_load_n (&i, __ATOMIC_ACQUIRE);
1006 }
1007 ]])], [
1008     AC_DEFINE([HAVE___ATOMIC], [1], [found __atomic builtins])
1009     AC_MSG_RESULT([yes])
1010   ], [
1011     AC_MSG_RESULT([no])
1012
1013     dnl FreeBSD 9 has a broken stdatomic.h where _Atomic doesn't work
1014     AC_MSG_CHECKING([for __sync_* builtins])
1015     AC_LINK_IFELSE([AC_LANG_SOURCE([[
1016 int main(int argc, char **argv) {
1017   volatile int i = 1;
1018   __sync_fetch_and_sub (&i, 1);
1019   return __sync_val_compare_and_swap (&i, 0, 1);
1020 }
1021 ]])], [
1022       AC_DEFINE([HAVE___SYNC], [1], [found __sync builtins])
1023       AC_MSG_RESULT([yes])
1024
1025       AC_MSG_CHECKING([for __sync_swap builtin])
1026       AC_LINK_IFELSE([AC_LANG_SOURCE([[
1027 int main(int argc, char **argv) {
1028   volatile int i = 1;
1029   return __sync_swap (&i, 2);
1030 }
1031 ]])], [
1032         AC_DEFINE([HAVE___SYNC_SWAP], 1, [found __sync_swap builtin])
1033         AC_MSG_RESULT([yes])
1034       ], [
1035         AC_MSG_RESULT([no])
1036       ])
1037
1038     ], [
1039       AC_MSG_RESULT([no])
1040       AC_MSG_FAILURE([stdatomic.h unavailable and $CC has neither __atomic nor __sync builtins])
1041     ])
1042   ])
1043 ])
1044
1045 needsync=true
1046
1047 AS_IF([$needsync], [
1048   dnl Linux
1049   AC_MSG_CHECKING([for Linux futex() support])
1050   AC_LINK_IFELSE([AC_LANG_PROGRAM([
1051 #ifndef _GNU_SOURCE
1052 #define _GNU_SOURCE
1053 #endif
1054 #include <unistd.h>
1055 #include <limits.h>
1056 #include <sys/time.h>
1057 #include <sys/syscall.h>
1058 #include <linux/futex.h>
1059
1060 int main(void);
1061 ],
1062 [
1063 {
1064   return syscall(SYS_futex, NULL, FUTEX_WAIT, 0, NULL, NULL, 0);
1065 }
1066 ])], [
1067     AC_MSG_RESULT([yes])
1068     AC_DEFINE(HAVE_SYNC_LINUX_FUTEX,,Have Linux futex support)
1069     needsync=false
1070   ], [
1071     AC_MSG_RESULT([no])
1072   ])
1073 ])
1074
1075 AS_IF([$needsync], [
1076   dnl FreeBSD
1077   AC_MSG_CHECKING([for FreeBSD _umtx_op() support])
1078   AC_LINK_IFELSE([AC_LANG_PROGRAM([
1079 #include <errno.h>
1080 #include <stdlib.h>
1081 #include <sys/types.h>
1082 #include <sys/umtx.h>
1083 int main(void);
1084 ],
1085 [
1086 {
1087   return _umtx_op(NULL, UMTX_OP_WAIT_UINT, 0, NULL, NULL);
1088 }
1089 ])], [
1090     AC_MSG_RESULT([yes])
1091     AC_DEFINE(HAVE_SYNC_UMTX_OP,,Have FreeBSD _umtx_op() support)
1092     needsync=false
1093   ], [
1094     AC_MSG_RESULT([no])
1095   ])
1096 ])
1097
1098 AS_IF([$needsync], [
1099   dnl OpenBSD patch (not upstream at the time of writing this)
1100   dnl https://marc.info/?l=openbsd-tech&m=147299508409549&w=2
1101   AC_MSG_CHECKING([for OpenBSD futex() support])
1102   AC_LINK_IFELSE([AC_LANG_PROGRAM([
1103 #include <sys/futex.h>
1104 int main(void);
1105 ],
1106 [
1107 {
1108   return futex(NULL, FUTEX_WAIT, 0, NULL, NULL, 0);
1109 }
1110 ])], [
1111     AC_MSG_RESULT([yes])
1112     AC_DEFINE(HAVE_SYNC_OPENBSD_FUTEX,,Have OpenBSD futex support)
1113     needsync=false
1114   ], [
1115     AC_MSG_RESULT([no])
1116   ])
1117 ])
1118
1119 dnl Utility macro to avoid retyping includes all the time
1120 m4_define([FRR_INCLUDES],
1121 [#ifdef SUNOS_5
1122 #define _POSIX_C_SOURCE 200809L
1123 #define __EXTENSIONS__
1124 #endif
1125 #include <stdio.h>
1126 #include <stdlib.h>
1127 #include <stddef.h>
1128 #include <sys/types.h>
1129 /* sys/conf.h depends on param.h on FBSD at least */
1130 #include <sys/param.h>
1131 /* Required for MAXSIG */
1132 #include <signal.h>
1133 #include <sys/socket.h>
1134 #ifdef __APPLE__
1135 # define __APPLE_USE_RFC_3542
1136 #endif
1137 #include <netinet/in.h>
1138 #include <sys/time.h>
1139 #include <time.h>
1140 #include <net/if.h>
1141 ])dnl
1142
1143 dnl Same applies for HAVE_NET_IF_VAR_H, which HAVE_NETINET6_ND6_H and
1144 dnl HAVE_NETINET_IN_VAR_H depend upon. But if_var.h depends on if.h, hence
1145 dnl an additional round for it.
1146
1147 AC_CHECK_HEADERS([net/if_var.h], [], [], [FRR_INCLUDES])
1148
1149 m4_define([FRR_INCLUDES],
1150 FRR_INCLUDES
1151 [#ifdef HAVE_NET_IF_VAR_H
1152 # include <net/if_var.h>
1153 #endif
1154 ])dnl
1155
1156 AC_CHECK_HEADERS([netinet/in_var.h \
1157         net/if_dl.h net/netopt.h \
1158         inet/nd.h netinet/ip_icmp.h \
1159         sys/sysctl.h sys/sockio.h sys/conf.h],
1160         [], [], [FRR_INCLUDES])
1161
1162 AC_CHECK_HEADERS([ucontext.h], [], [],
1163 [#ifndef __USE_GNU
1164 #define __USE_GNU
1165 #endif /* __USE_GNU */
1166 FRR_INCLUDES
1167 ])
1168
1169 m4_define([UCONTEXT_INCLUDES],
1170 [#include <ucontext.h>])dnl
1171
1172 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.uc_regs],
1173   [], [], [UCONTEXT_INCLUDES])
1174 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs],
1175   [AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs.nip],
1176    [], [], [UCONTEXT_INCLUDES])],
1177   [], [UCONTEXT_INCLUDES])
1178 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.gregs],
1179   [], [], [UCONTEXT_INCLUDES])
1180
1181 m4_define([FRR_INCLUDES],
1182 FRR_INCLUDES
1183 [
1184 #include <sys/un.h>
1185 #include <netinet/in_systm.h>
1186 #ifdef HAVE_NETINET_IN_VAR_H
1187 # include <netinet/in_var.h>
1188 #endif
1189 #ifdef HAVE_NET_IF_DL_H
1190 # include <net/if_dl.h>
1191 #endif
1192 #ifdef HAVE_NET_NETOPT_H
1193 # include <net/netopt.h>
1194 #endif
1195 #include <net/route.h>
1196 #ifdef HAVE_INET_ND_H
1197 # include <inet/nd.h>
1198 #endif
1199 #include <arpa/inet.h>
1200 /* Required for IDRP */
1201 #ifdef HAVE_NETINET_IP_ICMP_H
1202 # include <netinet/ip_icmp.h>
1203 #endif
1204 ])dnl
1205
1206 dnl V6 headers are checked below, after we check for v6
1207
1208 is_linux=false
1209
1210 AC_MSG_CHECKING([which operating system interface to use])
1211 case "$host_os" in
1212   sunos* | solaris2*)
1213     AC_MSG_FAILURE([Solaris support has been removed please see versions prior or equal to 7.5])
1214     ;;
1215   linux*)
1216     AC_MSG_RESULT([Linux])
1217
1218     AC_DEFINE([GNU_LINUX], [1], [GNU Linux])
1219     AC_DEFINE([HAVE_NETLINK], [1], [netlink])
1220     AC_DEFINE([LINUX_IPV6], [1], [Linux IPv6 stack])
1221
1222     dnl Linux has a compilation problem with mixing
1223     dnl netinet/in.h and linux/in6.h they are not
1224     dnl compatible.  There has been discussion on
1225     dnl how to fix it but no real progress on implementation
1226     dnl when they fix it, remove this
1227     AC_DEFINE([IPV6_MINHOPCOUNT], [73], [Linux ipv6 Min Hop Count])
1228
1229     is_linux=true
1230     ;;
1231   openbsd*)
1232     AC_MSG_RESULT([OpenBSD])
1233
1234     AC_DEFINE([OPEN_BSD], [1], [OpenBSD])
1235     AC_DEFINE([KAME], [1], [KAME IPv6])
1236     AC_DEFINE([BSD_V6_SYSCTL], [1], [BSD v6 sysctl to turn on and off forwarding])
1237     ;;
1238   *)
1239     AC_MSG_RESULT([BSD])
1240
1241     AC_DEFINE([HAVE_NET_RT_IFLIST], [1], [NET_RT_IFLIST])
1242     AC_DEFINE([KAME], [1], [KAME IPv6])
1243     AC_DEFINE([BSD_V6_SYSCTL], [1], [BSD v6 sysctl to turn on and off forwarding])
1244     ;;
1245 esac
1246 AM_CONDITIONAL([LINUX], [${is_linux}])
1247
1248 AC_SYS_LARGEFILE
1249
1250 dnl ------------------------
1251 dnl Integrated REALMS option
1252 dnl ------------------------
1253 if test "$enable_realms" = "yes"; then
1254     case "$host_os" in
1255       linux*)
1256        AC_DEFINE([SUPPORT_REALMS], [1], [Realms support])
1257        ;;
1258       *)
1259        echo "Sorry, only Linux has REALMS support"
1260        exit 1
1261        ;;
1262     esac
1263 fi
1264
1265 dnl ---------------
1266 dnl other functions
1267 dnl ---------------
1268 AC_CHECK_FUNCS([ \
1269         strlcat strlcpy \
1270         getgrouplist \
1271         openat \
1272         unlinkat \
1273         posix_fallocate \
1274         ])
1275
1276 dnl ##########################################################################
1277 dnl LARGE if block spans a lot of "configure"!
1278 if test "$enable_clippy_only" != "yes"; then
1279 dnl ##########################################################################
1280
1281 #
1282 # Logic for protobuf support.
1283 #
1284 PROTO3=false
1285 if test "$enable_protobuf" = "yes"; then
1286   # Check for protoc & protoc-c
1287
1288   # protoc is not required, it's only for a "be nice" helper target
1289   AC_CHECK_PROGS([PROTOC], [protoc], [/bin/false])
1290
1291   AC_CHECK_PROGS([PROTOC_C], [protoc-c], [/bin/false])
1292   if test "$PROTOC_C" = "/bin/false"; then
1293     AC_MSG_FAILURE([protobuf requested but protoc-c not found.  Install protobuf-c.])
1294   fi
1295
1296   PKG_CHECK_MODULES([PROTOBUF_C], [libprotobuf-c >= 0.14],, [
1297     AC_MSG_FAILURE([protobuf requested but libprotobuf-c not found.  Install protobuf-c.])
1298   ])
1299
1300   PROTO3=true
1301   AC_CHECK_HEADER([google/protobuf-c/protobuf-c.h],
1302                   [AC_CHECK_DECLS(PROTOBUF_C_LABEL_NONE,
1303                                   AC_DEFINE([HAVE_PROTOBUF_VERSION_3],
1304                                             [1], [Have Protobuf version 3]),
1305                                   [PROTO3=false],
1306                                   [#include <google/protobuf-c/protobuf-c.h>])],
1307                   [PROTO3=false && AC_MSG_FAILURE([protobuf requested but protobuf-c.h not found.  Install protobuf-c.])])
1308
1309   AC_DEFINE([HAVE_PROTOBUF], [1], [protobuf])
1310 fi
1311
1312
1313 dnl ---------------------
1314 dnl Integrated VTY option
1315 dnl ---------------------
1316 case "${enable_vtysh}" in
1317 "no")
1318   VTYSH="";;
1319 *)
1320   VTYSH="vtysh";
1321   AC_DEFINE([VTYSH], [1], [VTY shell])
1322
1323   prev_libs="$LIBS"
1324   AC_CHECK_LIB([readline], [main], [
1325     LIBREADLINE="-lreadline"
1326   ], [
1327     dnl readline failed - it might be incorrectly linked and missing its
1328     dnl termcap/tinfo/curses dependency.  see if we can fix that...
1329     AC_SEARCH_LIBS([tputs], [termcap tinfo curses ncurses], [
1330       LIBREADLINE="$ac_cv_search_tputs"
1331     ], [
1332       AC_MSG_ERROR([libreadline (needed for vtysh) not found and/or missing dependencies])
1333     ])
1334
1335     dnl re-try with the lib we found above
1336     unset ac_cv_lib_readline_main
1337     AC_CHECK_LIB([readline], [main], [
1338       LIBREADLINE="-lreadline $LIBREADLINE"
1339     ], [
1340       AC_MSG_ERROR([libreadline (needed for vtysh) not found and/or missing dependencies])
1341     ], [$LIBREADLINE])
1342   ], [])
1343   LIBS="$prev_libs"
1344
1345   AC_CHECK_HEADER([readline/history.h])
1346   if test "$ac_cv_header_readline_history_h" = "no"; then
1347     AC_MSG_ERROR([readline is too old to have readline/history.h, please update to the latest readline library.])
1348   fi
1349   AC_CHECK_LIB([readline], [rl_completion_matches], [true], [], [$LIBREADLINE])
1350   if test "$ac_cv_lib_readline_rl_completion_matches" = "no"; then
1351     AC_DEFINE([rl_completion_matches], [completion_matches], [Old readline])
1352   fi
1353   AC_CHECK_LIB([readline], [append_history], [frr_cv_append_history=yes], [frr_cv_append_history=no], [$LIBREADLINE])
1354   if test "$frr_cv_append_history" = "yes"; then
1355     AC_DEFINE([HAVE_APPEND_HISTORY], [1], [Have history.h append_history])
1356   fi
1357   ;;
1358 esac
1359 AC_SUBST([LIBREADLINE])
1360
1361 dnl ----------
1362 dnl PAM module
1363 dnl
1364 dnl FRR detects the PAM library it is built against by checking for a
1365 dnl functional pam_misc.h (Linux-PAM) or openpam.h (OpenPAM) header. pam_misc.h
1366 dnl is known to #include pam_appl.h, the standard header of a PAM library, and
1367 dnl openpam.h doesn't do that, although depends on the header too. Hence a
1368 dnl little assistance to AC_CHECK_HEADER is necessary for the proper detection
1369 dnl of OpenPAM.
1370 dnl ----------
1371 if test "$with_libpam" = "yes"; then
1372   AC_CHECK_HEADER([security/pam_misc.h],
1373     [AC_DEFINE([HAVE_PAM_MISC_H], [1], [Have pam_misc.h])
1374      AC_DEFINE([PAM_CONV_FUNC], [misc_conv], [Have misc_conv])
1375      pam_conv_func="misc_conv"
1376     ],
1377     [], FRR_INCLUDES)
1378   AC_CHECK_HEADER([security/openpam.h],
1379     [AC_DEFINE([HAVE_OPENPAM_H], [1], [Have openpam.h])
1380      AC_DEFINE([PAM_CONV_FUNC], [openpam_ttyconv], [Have openpam_ttyconv])
1381      pam_conv_func="openpam_ttyconv"
1382     ],
1383     [], FRR_INCLUDES[#include <security/pam_appl.h>])
1384   if test -z "$ac_cv_header_security_pam_misc_h$ac_cv_header_security_openpam_h" ; then
1385     AC_MSG_WARN([*** pam support will not be built ***])
1386     with_libpam="no"
1387   fi
1388 fi
1389
1390 if test "$with_libpam" = "yes"; then
1391 dnl took this test from proftpds configure.in and suited to our needs
1392 dnl -------------------------------------------------------------------------
1393 dnl
1394 dnl This next check looks funky due to a linker problem with some versions
1395 dnl of the PAM library.  Prior to 0.72 release, the Linux PAM shared library
1396 dnl omitted requiring libdl linking information. PAM-0.72 or better ships
1397 dnl with RedHat 6.2 and Debian 2.2 or better.
1398 AC_CHECK_LIB([pam], [pam_start],
1399   [AC_CHECK_LIB([pam], [$pam_conv_func],
1400     [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1401      LIBPAM="-lpam"],
1402     [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1403      LIBPAM="-lpam -lpam_misc"]
1404     )
1405   ],
1406
1407   [AC_CHECK_LIB([pam], [pam_end],
1408     [AC_CHECK_LIB([pam], [$pam_conv_func],
1409       [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1410        LIBPAM="-lpam -ldl"],
1411       [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1412        LIBPAM="-lpam -ldl -lpam_misc"]
1413      )
1414   ],AC_MSG_WARN([*** pam support will not be built ***]),
1415   [-ldl])
1416   ]
1417 )
1418 fi
1419 AC_SUBST([LIBPAM])
1420
1421 dnl -------------------------------
1422 dnl bgpd needs pow() and hence libm
1423 dnl -------------------------------
1424 TMPLIBS="$LIBS"
1425 LIBS=""
1426 AC_SEARCH_LIBS([pow], [m], [
1427   LIBM="$LIBS"
1428 ], [
1429   AC_MSG_WARN([Unable to find working pow function - bgpd may not link])
1430 ])
1431 LIBS="$TMPLIBS"
1432 AC_SUBST([LIBM])
1433
1434 AC_CHECK_FUNCS([ppoll], [
1435   AC_DEFINE([HAVE_PPOLL], [1], [have Linux/BSD ppoll()])
1436 ])
1437 AC_CHECK_FUNCS([pollts], [
1438   AC_DEFINE([HAVE_POLLTS], [1], [have NetBSD pollts()])
1439 ])
1440
1441 AC_CHECK_HEADER([asm-generic/unistd.h],
1442                 [AC_CHECK_DECL(__NR_setns,
1443                                AC_DEFINE([HAVE_NETNS], [1], [Have netns]),,
1444                                FRR_INCLUDES [#include <asm-generic/unistd.h>
1445                                ])
1446                  AC_CHECK_FUNCS([setns])]
1447                )
1448
1449 dnl --------------------------
1450 dnl Determine IS-IS I/O method
1451 dnl --------------------------
1452 AC_DEFINE([ISIS_METHOD_PFPACKET], [1], [constant value for isis method pfpacket])
1453 AC_DEFINE([ISIS_METHOD_DLPI], [2], [constant value for isis method dlpi])
1454 AC_DEFINE([ISIS_METHOD_BPF], [3], [constant value for isis method bpf])
1455 AC_CHECK_HEADER([net/bpf.h])
1456 AC_CHECK_HEADER([sys/dlpi.h])
1457 AC_MSG_CHECKING([zebra IS-IS I/O method])
1458
1459 case "$host_os" in
1460   linux*)
1461     AC_MSG_RESULT([pfpacket])
1462     ISIS_METHOD_MACRO="ISIS_METHOD_PFPACKET"
1463     ;;
1464   *)
1465     if test "$ac_cv_header_net_bpf_h" = "no"; then
1466       if test "$ac_cv_header_sys_dlpi_h" = "no"; then
1467         AC_MSG_RESULT([none])
1468         if test "$enable_isisd" = "yes" -o "$enable_fabricd" = "yes"; then
1469           AC_MSG_FAILURE([IS-IS support requested but no packet backend found])
1470         fi
1471         AC_MSG_WARN([*** IS-IS support will not be built ***])
1472         enable_isisd="no"
1473         enable_fabricd="no"
1474       else
1475         AC_MSG_RESULT([DLPI])
1476       fi
1477       ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1478     else
1479       AC_MSG_RESULT([BPF])
1480       ISIS_METHOD_MACRO="ISIS_METHOD_BPF"
1481     fi
1482     ;;
1483 esac
1484 AC_DEFINE_UNQUOTED([ISIS_METHOD], [$ISIS_METHOD_MACRO], [selected method for isis, == one of the constants])
1485
1486 dnl ---------------------------------------------------------------
1487 dnl figure out how to specify an interface in multicast sockets API
1488 dnl ---------------------------------------------------------------
1489 AC_CHECK_MEMBERS([struct ip_mreqn.imr_ifindex], [], [], FRR_INCLUDES)
1490
1491 AC_CHECK_HEADERS([linux/mroute.h], [], [],[
1492         #include <sys/socket.h>
1493         #include <netinet/in.h>
1494         #define _LINUX_IN_H             /* For Linux <= 2.6.25 */
1495         #include <linux/types.h>
1496 ])
1497
1498 m4_define([FRR_INCLUDES],
1499 FRR_INCLUDES
1500 [#ifdef HAVE_LINUX_MROUTE_H
1501 # include <linux/mroute.h>
1502 #endif
1503 ])dnl
1504
1505 AC_CHECK_HEADERS([netinet/ip_mroute.h], [], [],[
1506         #include <sys/socket.h>
1507         #include <sys/types.h>
1508         #include <netinet/in.h>
1509         #include <net/route.h>
1510 ])
1511
1512 m4_define([FRR_INCLUDES],
1513 FRR_INCLUDES
1514 [#ifdef HAVE_NETINET_IP_MROUTE_H
1515 # include <netinet/ip_mroute.h>
1516 #endif
1517 ])dnl
1518
1519 AC_MSG_CHECKING([for RFC3678 protocol-independed API])
1520 AC_COMPILE_IFELSE(
1521 [ AC_LANG_PROGRAM([[
1522       #include <sys/types.h>
1523       #include <netinet/in.h>
1524   ]], [[
1525       struct group_req gr;
1526       int sock;
1527       setsockopt(sock, IPPROTO_IP, MCAST_JOIN_GROUP, (void*)&gr, sizeof(gr));
1528   ]])
1529 ],[
1530   AC_MSG_RESULT([yes])
1531   AC_DEFINE([HAVE_RFC3678], [1], [Have RFC3678 protocol-independed API])
1532 ],[
1533   AC_MSG_RESULT(no)
1534 ])
1535
1536 dnl ---------------------------------------------------------------
1537 dnl figure out how to check link-state
1538 dnl ---------------------------------------------------------------
1539 AC_CHECK_HEADER([net/if_media.h],
1540   [m4_define([LINK_DETECT_INCLUDES],
1541     FRR_INCLUDES
1542     [#include <net/if_media.h>
1543   ])
1544   AC_CHECK_MEMBERS([struct ifmediareq.ifm_status],
1545     AC_DEFINE([HAVE_BSD_LINK_DETECT], [1], [BSD link-detect]),
1546     [], LINK_DETECT_INCLUDES)],
1547   [],
1548   FRR_INCLUDES)
1549
1550 dnl ---------------------------------------------------------------
1551 dnl Additional, newer way to check link-state using ifi_link_state.
1552 dnl Not available in all BSD's when ifmediareq available
1553 dnl ---------------------------------------------------------------
1554 AC_CHECK_MEMBERS([struct if_data.ifi_link_state],
1555   AC_DEFINE([HAVE_BSD_IFI_LINK_STATE], [1], [BSD ifi_link_state available]),
1556   [], FRR_INCLUDES)
1557
1558 dnl ------------------------
1559 dnl TCP_MD5SIG socket option
1560 dnl ------------------------
1561
1562 AC_CHECK_HEADER([netinet/tcp.h],
1563    [m4_define([MD5_INCLUDES],
1564       FRR_INCLUDES
1565       [#include <netinet/tcp.h>
1566     ])
1567     AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)],
1568    [],
1569    FRR_INCLUDES)
1570 if test "$ac_cv_have_decl_TCP_MD5SIG" = "no"; then
1571   AC_CHECK_HEADER([linux/tcp.h],
1572        [m4_define([MD5_INCLUDES],
1573           FRR_INCLUDES
1574           [#include <linux/tcp.h>
1575         ])
1576        AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)])
1577 fi
1578
1579 AC_CHECK_LIB([crypt], [crypt], [],
1580                     [AC_CHECK_LIB([crypto], [DES_crypt])])
1581 AC_CHECK_LIB([resolv], [res_init])
1582
1583 dnl ---------------------------
1584 dnl check system has PCRE regexp
1585 dnl ---------------------------
1586 if test "$enable_pcreposix" = "yes"; then
1587   AC_CHECK_LIB([pcreposix], [regexec], [], [
1588     AC_MSG_ERROR([--enable-pcreposix given but unable to find libpcreposix])
1589   ])
1590 fi
1591 AC_SUBST([HAVE_LIBPCREPOSIX])
1592
1593 dnl ##########################################################################
1594 dnl test "$enable_clippy_only" != "yes"
1595 fi
1596 dnl END OF LARGE if block
1597 dnl ##########################################################################
1598
1599 dnl ------------------
1600 dnl check C-Ares library
1601 dnl ------------------
1602 PKG_CHECK_MODULES([CARES], [libcares], [
1603   c_ares_found=true
1604 ],[
1605   c_ares_found=false
1606 ])
1607 AM_CONDITIONAL([CARES], [$c_ares_found])
1608
1609
1610 dnl ----------------------------------------------------------------------------
1611 dnl figure out if domainname is available in the utsname struct (GNU extension).
1612 dnl ----------------------------------------------------------------------------
1613 AC_CHECK_MEMBERS([struct utsname.domainname], [], [], [#include <sys/utsname.h>])
1614
1615 dnl ------------------
1616 dnl IPv6 header checks
1617 dnl ------------------
1618 AC_CHECK_HEADERS([netinet6/in6.h netinet/in6_var.h \
1619         netinet6/in6_var.h netinet6/nd6.h], [], [],
1620         FRR_INCLUDES)
1621
1622 m4_define([FRR_INCLUDES],dnl
1623 FRR_INCLUDES
1624 [#ifdef HAVE_NETINET6_IN6_H
1625 #include <netinet6/in6.h>
1626 #endif
1627 #ifdef HAVE_NETINET_IN6_VAR_H
1628 #include <netinet/in6_var.h>
1629 #endif
1630 #include <netinet/icmp6.h>
1631 #ifdef HAVE_NETINET6_IN6_VAR_H
1632 # include <netinet6/in6_var.h>
1633 #endif
1634 #ifdef HAVE_NETINET6_ND6_H
1635 # include <netinet6/nd6.h>
1636 #endif
1637 ])dnl
1638
1639 dnl --------------------
1640 dnl Daemon disable check
1641 dnl --------------------
1642
1643 AS_IF([test "$enable_bgpd" != "no"], [
1644   AC_DEFINE([HAVE_BGPD], [1], [bgpd])
1645 ])
1646
1647 AS_IF([test "$enable_ripd" != "no"], [
1648   AC_DEFINE([HAVE_RIPD], [1], [ripd])
1649 ])
1650
1651 AS_IF([test "$enable_ripngd" != "no"], [
1652   AC_DEFINE([HAVE_RIPNGD], [1], [ripngd])
1653 ])
1654
1655 AS_IF([test "$enable_ospfd" != "no"], [
1656   AC_DEFINE([HAVE_OSPFD], [1], [ospfd])
1657 ])
1658
1659 AS_IF([test "$enable_ospf6d" != "no"], [
1660   AC_DEFINE([HAVE_OSPF6D], [1], [ospf6d])
1661 ])
1662
1663 AS_IF([test "$enable_ldpd" != "no"], [
1664   AC_DEFINE([HAVE_LDPD], [1], [ldpd])
1665 ])
1666
1667 AS_IF([test "$enable_nhrpd" != "no"], [
1668   AC_DEFINE([HAVE_NHRPD], [1], [nhrpd])
1669 ])
1670
1671 AS_IF([test "$enable_eigrpd" != "no"], [
1672   AC_DEFINE([HAVE_EIGRPD], [1], [eigrpd])
1673 ])
1674
1675 AS_IF([test "$enable_babeld" != "no"], [
1676   AC_DEFINE([HAVE_BABELD], [1], [babeld])
1677 ])
1678
1679 AS_IF([test "$enable_isisd" != "no"], [
1680   AC_DEFINE([HAVE_ISISD], [1], [isisd])
1681 ])
1682
1683 AS_IF([test "$enable_pimd" != "no"], [
1684   AC_DEFINE([HAVE_PIMD], [1], [pimd])
1685 ])
1686
1687 AS_IF([test "$enable_pbrd" != "no"], [
1688   AC_DEFINE([HAVE_PBRD], [1], [pbrd])
1689 ])
1690
1691 AS_IF([test "$enable_sharpd" = "yes"], [
1692   AC_DEFINE([HAVE_SHARPD], [1], [sharpd])
1693 ])
1694
1695 AS_IF([test "$enable_staticd" != "no"], [
1696   AC_DEFINE([HAVE_STATICD], [1], [staticd])
1697 ])
1698
1699 AS_IF([test "$enable_fabricd" != "no"], [
1700   AC_DEFINE([HAVE_FABRICD], [1], [fabricd])
1701 ])
1702
1703 AS_IF([test "$enable_vrrpd" != "no"], [
1704   AC_DEFINE([HAVE_VRRPD], [1], [vrrpd])
1705 ])
1706
1707 if test "$enable_bfdd" = "no"; then
1708   AC_DEFINE([HAVE_BFDD], [0], [bfdd])
1709   BFDD=""
1710 else
1711   AC_DEFINE([HAVE_BFDD], [1], [bfdd])
1712   BFDD="bfdd"
1713
1714   case $host_os in
1715     linux*)
1716       AC_DEFINE([BFD_LINUX], [1], [bfdd])
1717       ;;
1718
1719     *)
1720       AC_DEFINE([BFD_BSD], [1], [bfdd])
1721       ;;
1722   esac
1723 fi
1724
1725 AS_IF([test "$enable_pathd" != "no"], [
1726   AC_DEFINE([HAVE_PATHD], [1], [pathd])
1727   AC_DEFINE([HAVE_PATHD_PCEP], [1], [pathd-pcep])
1728 ])
1729
1730
1731 if test "$ac_cv_lib_json_c_json_object_get" = "no" -a "$BFDD" = "bfdd"; then
1732   AC_MSG_ERROR(["you must use json-c library to use bfdd"])
1733 fi
1734
1735 NHRPD=""
1736 case "$host_os" in
1737   linux*)
1738     case "${enable_nhrpd}" in
1739       no)
1740         ;;
1741       yes)
1742         if test "$enable_clippy_only" != "yes"; then
1743         if test "$c_ares_found" != "true" ; then
1744           AC_MSG_ERROR([nhrpd requires libcares.  Please install c-ares and its -dev headers.])
1745         fi
1746         fi
1747         NHRPD="nhrpd"
1748         ;;
1749       *)
1750         if test "$c_ares_found" = "true" ; then
1751           NHRPD="nhrpd"
1752         fi
1753         ;;
1754     esac
1755     ;;
1756   *)
1757     if test "$enable_nhrpd" = "yes"; then
1758       AC_MSG_ERROR([nhrpd requires kernel APIs that are only present on Linux.])
1759     fi
1760     ;;
1761 esac
1762
1763 if test "$enable_watchfrr" = "no";then
1764   WATCHFRR=""
1765 else
1766   WATCHFRR="watchfrr"
1767 fi
1768
1769 OSPFCLIENT=""
1770 if test "$enable_ospfapi" != "no";then
1771     AC_DEFINE([SUPPORT_OSPF_API], [1], [OSPFAPI])
1772
1773   if test "$enable_ospfclient" != "no";then
1774       OSPFCLIENT="ospfclient"
1775   fi
1776 fi
1777
1778 if test "$enable_bgp_announce" = "no";then
1779   AC_DEFINE([DISABLE_BGP_ANNOUNCE], [1], [Disable BGP installation to zebra])
1780 else
1781   AC_DEFINE([DISABLE_BGP_ANNOUNCE], [0], [Disable BGP installation to zebra])
1782 fi
1783
1784 if test "$enable_bgp_vnc" != "no";then
1785   AC_DEFINE([ENABLE_BGP_VNC], [1], [Enable BGP VNC support])
1786 fi
1787
1788 bgpd_bmp=false
1789 case "${enable_bmp}" in
1790   no)
1791     ;;
1792   yes)
1793     if test "$c_ares_found" != "true" ; then
1794       AC_MSG_ERROR([BMP support requires libcares.  Please install c-ares and its -dev headers.])
1795     fi
1796     bgpd_bmp=true
1797     ;;
1798   *)
1799     if test "$c_ares_found" = "true" ; then
1800       bgpd_bmp=true
1801     fi
1802     ;;
1803 esac
1804
1805 if test "$enable_version_build_config" != "no";then
1806   AC_DEFINE([ENABLE_VERSION_BUILD_CONFIG], [1], [Report build configs in show version])
1807 fi
1808
1809 dnl ##########################################################################
1810 dnl LARGE if block
1811 if test "$enable_clippy_only" != "yes"; then
1812 dnl ##########################################################################
1813
1814 dnl ------------------
1815 dnl check Net-SNMP library
1816 dnl ------------------
1817 if test "$enable_snmp" != "" -a "$enable_snmp" != "no"; then
1818    AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], [no])
1819    if test "$NETSNMP_CONFIG" = "no"; then
1820       AC_MSG_ERROR([--enable-snmp given but unable to find net-snmp-config])
1821    fi
1822    SNMP_LIBS="`${NETSNMP_CONFIG} --agent-libs`"
1823    SNMP_CFLAGS="`${NETSNMP_CONFIG} --base-cflags`"
1824    # net-snmp lists all of its own dependencies.  we absolutely do not want that
1825    # among other things we avoid a GPL vs. OpenSSL license conflict here
1826    for removelib in crypto ssl sensors pci wrap; do
1827      SNMP_LIBS="`echo $SNMP_LIBS | sed -e 's/\(^\|\s\)-l'$removelib'\b/ /g' -e 's/\(^\|\s\)\([^\s]*\/\)\?lib'$removelib'\.[^\s]\+\b/ /g'`"
1828    done
1829    AC_MSG_CHECKING([whether we can link to Net-SNMP])
1830    AC_LINK_IFELSE_FLAGS([$SNMP_CFLAGS], [$SNMP_LIBS], [AC_LANG_PROGRAM([
1831 int main(void);
1832 ],
1833 [
1834 {
1835   return 0;
1836 }
1837 ])], [
1838      AC_MSG_RESULT([no])
1839      AC_MSG_ERROR([--enable-snmp given but not usable])])
1840    case "${enable_snmp}" in
1841      yes)
1842       SNMP_METHOD=agentx
1843       ;;
1844      agentx)
1845       SNMP_METHOD="${enable_snmp}"
1846       ;;
1847      *)
1848       AC_MSG_ERROR([--enable-snmp given with an unknown method (${enable_snmp}). Use yes or agentx])
1849       ;;
1850    esac
1851    AH_TEMPLATE([SNMP_AGENTX], [Use SNMP AgentX to interface with snmpd])
1852    AC_DEFINE_UNQUOTED(AS_TR_CPP(SNMP_${SNMP_METHOD}),,[SNMP method to interface with snmpd])
1853 fi
1854 AC_SUBST([SNMP_LIBS])
1855 AC_SUBST([SNMP_CFLAGS])
1856
1857 dnl ---------------
1858 dnl libyang
1859 dnl ---------------
1860 PKG_CHECK_MODULES([LIBYANG], [libyang >= 2.0.0], , [
1861   AC_MSG_ERROR([libyang (>= 2.0.0) was not found on your system.])
1862 ])
1863 ac_cflags_save="$CFLAGS"
1864 CFLAGS="$CFLAGS $LIBYANG_CFLAGS"
1865 AC_CHECK_MEMBER([struct lyd_node.priv], [], [
1866   AC_MSG_ERROR([m4_normalize([
1867     libyang needs to be compiled with ENABLE_LYD_PRIV=ON.
1868     Instructions for this are included in the build documentation for your platform at http://docs.frrouting.org/projects/dev-guide/en/latest/building.html])
1869   ])
1870 ], [[#include <libyang/libyang.h>]])
1871 CFLAGS="$ac_cflags_save"
1872
1873 dnl ---------------
1874 dnl configuration rollbacks
1875 dnl ---------------
1876 SQLITE3=false
1877 if test "$enable_config_rollbacks" = "yes"; then
1878   PKG_CHECK_MODULES([SQLITE3], [sqlite3], [
1879     AC_DEFINE([HAVE_CONFIG_ROLLBACKS], [1], [Enable configuration rollbacks])
1880     AC_DEFINE([HAVE_SQLITE3], [1], [Enable sqlite3 database])
1881     SQLITE3=true
1882   ], [
1883     AC_MSG_ERROR([--enable-config-rollbacks given but sqlite3 was not found on your system.])
1884   ])
1885 fi
1886
1887 dnl ---------------
1888 dnl confd
1889 dnl ---------------
1890 if test "$enable_confd" != "" -a "$enable_confd" != "no"; then
1891    AC_CHECK_PROG([CONFD], [confd], [confd], [/bin/false], "${enable_confd}/bin")
1892    if test "$CONFD" = "/bin/false"; then
1893       AC_MSG_ERROR([confd was not found on your system.])]
1894    fi
1895    CONFD_CFLAGS="-I${enable_confd}/include -L${enable_confd}/lib"
1896    AC_SUBST([CONFD_CFLAGS])
1897    CONFD_LIBS="-lconfd"
1898    AC_SUBST([CONFD_LIBS])
1899    AC_DEFINE([HAVE_CONFD], [1], [Enable confd integration])
1900 fi
1901
1902 dnl ---------------
1903 dnl sysrepo
1904 dnl ---------------
1905 if test "$enable_sysrepo" = "yes"; then
1906   PKG_CHECK_MODULES([SYSREPO], [sysrepo],
1907       [AC_DEFINE([HAVE_SYSREPO], [1], [Enable sysrepo integration])
1908       SYSREPO=true],
1909       [SYSREPO=false
1910       AC_MSG_ERROR([sysrepo was not found on your system.])]
1911   )
1912 fi
1913
1914 dnl ---------------
1915 dnl gRPC
1916 dnl ---------------
1917 if test "$enable_grpc" = "yes"; then
1918   AC_LANG_PUSH([C++])
1919   AX_CXX_COMPILE_STDCXX([11], [ext])
1920   PKG_CHECK_MODULES([GRPC], [grpc >= 6.0.0 grpc++ >= 1.16.1 protobuf >= 3.6.1 ], [
1921     AC_CHECK_PROGS([PROTOC], [protoc], [/bin/false])
1922     if test "$PROTOC" = "/bin/false"; then
1923       AC_MSG_FAILURE([grpc requested but protoc not found.])
1924     fi
1925
1926     AC_DEFINE([HAVE_GRPC], [1], [Enable the gRPC northbound plugin])
1927     GRPC=true
1928   ], [
1929     GRPC=false
1930     AC_MSG_ERROR([grpc/grpc++ were not found on your system.])
1931   ])
1932   AC_LANG_POP([C++])
1933 fi
1934
1935 dnl -----
1936 dnl LTTng
1937 dnl -----
1938 if test "$enable_lttng" = "yes"; then
1939   PKG_CHECK_MODULES([UST], [lttng-ust >= 2.12.0], [
1940     AC_DEFINE([HAVE_LTTNG], [1], [Enable LTTng support])
1941     LTTNG=true
1942   ], [
1943     AC_MSG_ERROR([configuration specifies --enable-lttng but lttng-ust was not found])
1944   ])
1945 fi
1946
1947 dnl ----
1948 dnl USDT
1949 dnl ----
1950 if test "$enable_usdt" = "yes"; then
1951   AC_CHECK_HEADERS([sys/sdt.h], [
1952     AC_DEFINE([HAVE_USDT], [1], [Enable USDT probes])
1953     USDT=true
1954   ], [
1955     AC_MSG_ERROR([configuration specifies --enable-usdt but no USDT kernel headers (sys/sdt.h) found])
1956   ])
1957 fi
1958
1959 dnl ------
1960 dnl ZeroMQ
1961 dnl ------
1962 if test "$enable_zeromq" != "no"; then
1963   PKG_CHECK_MODULES([ZEROMQ], [libzmq >= 4.0.0], [
1964     AC_DEFINE([HAVE_ZEROMQ], [1], [Enable ZeroMQ support])
1965     ZEROMQ=true
1966   ], [
1967     if test "$enable_zeromq" = "yes"; then
1968       AC_MSG_ERROR([configuration specifies --enable-zeromq but libzmq was not found])
1969     fi
1970   ])
1971 fi
1972
1973 dnl ------------------------------------
1974 dnl Enable RPKI and add librtr to libs
1975 dnl ------------------------------------
1976 if test "$enable_rpki" = "yes"; then
1977   PKG_CHECK_MODULES([RTRLIB], [rtrlib >= 0.5.0],
1978       [RPKI=true],
1979       [RPKI=false
1980       AC_MSG_ERROR([rtrlib was not found on your system or is too old.])]
1981   )
1982 fi
1983
1984 dnl ------------------------------------
1985 dnl pimd is not supported on OpenBSD and MacOS
1986 dnl ------------------------------------
1987 if test "$enable_pimd" != "no"; then
1988 AC_MSG_CHECKING([for pimd OS support])
1989 case "$host_os" in
1990   darwin*)
1991     AC_MSG_RESULT([no])
1992     enable_pimd="no"
1993     ;;
1994   openbsd*)
1995     AC_MSG_RESULT([no])
1996     enable_pimd="no"
1997     ;;
1998   *)
1999     AC_MSG_RESULT([yes])
2000     ;;
2001 esac
2002 fi
2003
2004 dnl -------------------------------------
2005 dnl VRRP is only supported on linux
2006 dnl -------------------------------------
2007 if test "$enable_vrrpd" != "no"; then
2008 AC_MSG_CHECKING([for VRRP OS support])
2009 case "$host_os" in
2010   linux*)
2011     AC_MSG_RESULT([yes])
2012     ;;
2013   *)
2014     AC_MSG_RESULT([no])
2015     enable_vrrpd="no"
2016     ;;
2017 esac
2018 fi
2019
2020 dnl ------------------------------------------
2021 dnl Check whether rtrlib was build with ssh support
2022 dnl ------------------------------------------
2023 AC_MSG_CHECKING([whether the RTR Library is compiled with SSH])
2024 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "rtrlib/rtrlib.h"]],
2025                         [[struct tr_ssh_config config;]])],
2026         [AC_MSG_RESULT([yes])
2027         AC_DEFINE([FOUND_SSH], [1], [found_ssh])],
2028         AC_MSG_RESULT([no])
2029 )
2030
2031 dnl ---------------
2032 dnl dlopen & dlinfo
2033 dnl ---------------
2034 AC_SEARCH_LIBS([dlopen], [dl dld], [], [
2035   AC_MSG_ERROR([unable to find the dlopen()])
2036 ])
2037
2038 AC_CHECK_HEADERS([link.h])
2039
2040 AC_CACHE_CHECK([for dlinfo(RTLD_DI_ORIGIN)], [frr_cv_rtld_di_origin], [
2041   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2042 #include <stdlib.h>
2043 #ifdef HAVE_LINK_H
2044 #include <link.h>
2045 #endif
2046 #include <dlfcn.h>
2047 ]], [[
2048   char origin[1];
2049   dlinfo (NULL, RTLD_DI_ORIGIN, &origin);
2050 ]])], [
2051     frr_cv_rtld_di_origin=yes
2052   ], [
2053     frr_cv_rtld_di_origin=no
2054   ])
2055 ])
2056 if test "$frr_cv_rtld_di_origin" = "yes"; then
2057   AC_DEFINE([HAVE_DLINFO_ORIGIN], [1], [Have dlinfo RTLD_DI_ORIGIN])
2058 fi
2059
2060 AC_CACHE_CHECK([for dlinfo(RTLD_DI_LINKMAP)], [frr_cv_rtld_di_linkmap], [
2061   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2062 #include <stdlib.h>
2063 #ifdef HAVE_LINK_H
2064 #include <link.h>
2065 #endif
2066 #include <dlfcn.h>
2067 ]], [[
2068   struct link_map *lm = NULL;
2069   dlinfo (NULL, RTLD_DI_LINKMAP, &lm);
2070 ]])], [
2071     frr_cv_rtld_di_linkmap=yes
2072   ], [
2073     frr_cv_rtld_di_linkmap=no
2074   ])
2075 ])
2076 if test "$frr_cv_rtld_di_linkmap" = "yes"; then
2077   AC_DEFINE([HAVE_DLINFO_LINKMAP], [1], [Have dlinfo RTLD_DI_LINKMAP])
2078 fi
2079
2080 dnl ##########################################################################
2081 dnl test "$enable_clippy_only" != "yes"
2082 fi
2083 dnl END OF LARGE if block
2084 dnl ##########################################################################
2085
2086 dnl ---------------------------
2087 dnl sockaddr and netinet checks
2088 dnl ---------------------------
2089 AC_CHECK_TYPES([
2090         struct sockaddr_dl,
2091         struct vifctl, struct mfcctl, struct sioc_sg_req,
2092         vifi_t, struct sioc_vif_req, struct igmpmsg,
2093         struct ifaliasreq, struct if6_aliasreq, struct in6_aliasreq,
2094         struct nd_opt_adv_interval,
2095         struct nd_opt_homeagent_info, struct nd_opt_adv_interval,
2096         struct nd_opt_rdnss, struct nd_opt_dnssl],
2097         [], [], FRR_INCLUDES)
2098
2099 AC_CHECK_MEMBERS([struct sockaddr.sa_len,
2100         struct sockaddr_in.sin_len, struct sockaddr_un.sun_len,
2101         struct sockaddr_dl.sdl_len,
2102         struct if6_aliasreq.ifra_lifetime,
2103         struct nd_opt_adv_interval.nd_opt_ai_type],
2104         [], [], FRR_INCLUDES)
2105
2106 dnl ---------------------------
2107 dnl IRDP/pktinfo/icmphdr checks
2108 dnl ---------------------------
2109
2110 AC_CHECK_TYPES([struct in_pktinfo], [
2111   AC_CHECK_TYPES([struct icmphdr], [
2112     IRDP=true
2113   ], [
2114     IRDP=false
2115   ], [FRR_INCLUDES])
2116 ], [
2117   IRDP=false
2118 ], [FRR_INCLUDES])
2119
2120 case "${enable_irdp}" in
2121 yes)
2122   $IRDP || AC_MSG_ERROR(['IRDP requires in_pktinfo at the moment!'])
2123   ;;
2124 no)
2125   IRDP=false
2126   ;;
2127 esac
2128
2129
2130 dnl -----------------------
2131 dnl checking for IP_PKTINFO
2132 dnl -----------------------
2133 AC_MSG_CHECKING([for IP_PKTINFO])
2134 AC_COMPILE_IFELSE(
2135 [ AC_LANG_PROGRAM([[
2136         #include <netdb.h>
2137    ]], [[
2138         int opt = IP_PKTINFO;
2139    ]])
2140 ],[
2141   AC_MSG_RESULT([yes])
2142   AC_DEFINE([HAVE_IP_PKTINFO], [1], [Have IP_PKTINFO])
2143 ],[
2144   AC_MSG_RESULT([no])
2145 ])
2146
2147 dnl ---------------------------
2148 dnl checking for IP_RECVDSTADDR
2149 dnl ---------------------------
2150 AC_MSG_CHECKING([for IP_RECVDSTADDR])
2151 AC_COMPILE_IFELSE(
2152 [ AC_LANG_PROGRAM([[
2153         #include <netinet/in.h>
2154   ]], [[
2155         int opt = IP_RECVDSTADDR;
2156   ]])
2157 ],[
2158   AC_MSG_RESULT([yes])
2159   AC_DEFINE([HAVE_IP_RECVDSTADDR], [1], [Have IP_RECVDSTADDR])
2160 ],[
2161   AC_MSG_RESULT([no])
2162 ])
2163
2164 dnl ----------------------
2165 dnl checking for IP_RECVIF
2166 dnl ----------------------
2167 AC_MSG_CHECKING([for IP_RECVIF])
2168 AC_COMPILE_IFELSE(
2169 [ AC_LANG_PROGRAM([[
2170         #include <netinet/in.h>
2171   ]], [[
2172         int opt = IP_RECVIF;
2173   ]])
2174 ],[
2175   AC_MSG_RESULT([yes])
2176   AC_DEFINE([HAVE_IP_RECVIF], [1], [Have IP_RECVIF])
2177 ],[
2178   AC_MSG_RESULT([no])
2179 ])
2180
2181 dnl ----------------------
2182 dnl checking for SO_BINDANY
2183 dnl ----------------------
2184 AC_MSG_CHECKING([for SO_BINDANY])
2185 AC_COMPILE_IFELSE(
2186 [ AC_LANG_PROGRAM([[
2187         #include <sys/socket.h>
2188   ]], [[
2189         int opt = SO_BINDANY;
2190   ]])
2191 ],[
2192   AC_MSG_RESULT([yes])
2193   AC_DEFINE([HAVE_SO_BINDANY], [1], [Have SO_BINDANY])
2194 ],[
2195   AC_MSG_RESULT([no])
2196 ])
2197
2198 dnl ----------------------
2199 dnl checking for IP_FREEBIND
2200 dnl ----------------------
2201 AC_MSG_CHECKING([for IP_FREEBIND])
2202 AC_COMPILE_IFELSE(
2203 [ AC_LANG_PROGRAM([[
2204         #include <netinet/in.h>
2205   ]], [[
2206         int opt = IP_FREEBIND;
2207   ]])
2208 ],[
2209   AC_MSG_RESULT([yes])
2210   AC_DEFINE([HAVE_IP_FREEBIND], [1], [Have IP_FREEBIND])
2211 ],[
2212   AC_MSG_RESULT([no])
2213 ])
2214
2215 dnl --------------------------------------
2216 dnl checking for be32dec existence or not
2217 dnl --------------------------------------
2218 AC_CHECK_DECLS([be32enc, be32dec], [], [], [
2219         #ifdef HAVE_SYS_ENDIAN_H
2220         #include <sys/endian.h>
2221         #endif
2222         #ifdef HAVE_ENDIAN_H
2223         #include <endian.h>
2224         #endif
2225 ])
2226
2227 dnl --------------------------------------
2228 dnl checking for clock_time monotonic struct and call
2229 dnl --------------------------------------
2230 AC_CHECK_DECL([CLOCK_MONOTONIC],
2231         [AC_CHECK_LIB([rt], [clock_gettime], [LIBS="$LIBS -lrt"])
2232          AC_DEFINE([HAVE_CLOCK_MONOTONIC], [1], [Have monotonic clock])
2233 ], [AC_MSG_RESULT([no])], [FRR_INCLUDES])
2234
2235 AC_SEARCH_LIBS([clock_nanosleep], [rt], [
2236   AC_DEFINE([HAVE_CLOCK_NANOSLEEP], [1], [Have clock_nanosleep()])
2237 ])
2238
2239 dnl --------------------------------------
2240 dnl checking for flex and bison
2241 dnl --------------------------------------
2242
2243 AM_PROG_LEX
2244 AC_MSG_CHECKING([version of flex])
2245 frr_ac_flex_version="$(eval $LEX -V | grep flex | head -n 1)"
2246 frr_ac_flex_version="${frr_ac_flex_version##* }"
2247 AC_MSG_RESULT([$frr_ac_flex_version])
2248 AX_COMPARE_VERSION([$frr_ac_flex_version], [lt], [2.5.20], [
2249   LEX="$SHELL $missing_dir/missing flex"
2250   if test -f "${srcdir}/lib/command_lex.c" -a -f "${srcdir}/lib/command_lex.h"; then
2251     AC_MSG_WARN([using pregenerated flex output files])
2252   else
2253     AC_MSG_ERROR([flex failure and pregenerated files not included (probably a git build)])
2254   fi
2255   AC_SUBST([LEX_OUTPUT_ROOT], [lex.yy])
2256   AC_SUBST([LEXLIB], [''])
2257 ])
2258
2259 AC_PROG_YACC
2260 dnl thanks GNU bison for this b*llshit...
2261 AC_MSG_CHECKING([version of bison])
2262 frr_ac_bison_version="$(eval $YACC -V | grep bison | head -n 1)"
2263 frr_ac_bison_version="${frr_ac_bison_version##* }"
2264 frr_ac_bison_missing="false"
2265 case "x${frr_ac_bison_version}x" in
2266   x2.7*)
2267     BISON_OPENBRACE='"'
2268     BISON_CLOSEBRACE='"'
2269     BISON_VERBOSE=''
2270     AC_MSG_RESULT([$frr_ac_bison_version - 2.7 or older])
2271     ;;
2272   x2.*|x1.*)
2273     AC_MSG_RESULT([$frr_ac_bison_version])
2274     AC_MSG_WARN([installed bison is too old.  Please install GNU bison 2.7.x or newer.])
2275     frr_ac_bison_missing="true"
2276     ;;
2277   x)
2278     AC_MSG_RESULT([none])
2279     AC_MSG_WARN([could not determine bison version.  Please install GNU bison 2.7.x or newer.])
2280     frr_ac_bison_missing="true"
2281     ;;
2282   x3.[012][^0-9]*)
2283     BISON_OPENBRACE='{'
2284     BISON_CLOSEBRACE='}'
2285     BISON_VERBOSE='-Dparse.error=verbose'
2286     AC_MSG_RESULT([$frr_ac_bison_version - 3.0 to 3.2])
2287     ;;
2288   *)
2289     BISON_OPENBRACE='{'
2290     BISON_CLOSEBRACE='}'
2291     BISON_VERBOSE='-Dparse.error=verbose -Wno-yacc'
2292     AC_MSG_RESULT([$frr_ac_bison_version - 3.3 or newer])
2293     ;;
2294 esac
2295 AC_SUBST([BISON_OPENBRACE])
2296 AC_SUBST([BISON_CLOSEBRACE])
2297 AC_SUBST([BISON_VERBOSE])
2298
2299 if $frr_ac_bison_missing; then
2300   YACC="$SHELL $missing_dir/missing bison -y"
2301   if test -f "${srcdir}/lib/command_parse.c" -a -f "${srcdir}/lib/command_parse.h"; then
2302     AC_MSG_WARN([using pregenerated bison output files])
2303   else
2304     AC_MSG_ERROR([bison failure and pregenerated files not included (probably a git build)])
2305   fi
2306 fi
2307
2308 dnl -------------------
2309 dnl capabilities checks
2310 dnl -------------------
2311 if test "$enable_capabilities" != "no"; then
2312   AC_MSG_CHECKING([whether prctl PR_SET_KEEPCAPS is available])
2313   AC_COMPILE_IFELSE(
2314   [ AC_LANG_PROGRAM([[
2315         #include <sys/prctl.h>
2316     ]], [[
2317         prctl(PR_SET_KEEPCAPS, 1, 0, 0, 0);
2318     ]])
2319   ],[AC_MSG_RESULT([yes])
2320      AC_DEFINE([HAVE_PR_SET_KEEPCAPS], [1], [prctl])
2321      frr_ac_keepcaps="yes"
2322   ],[AC_MSG_RESULT(no)
2323   ])
2324   if test "$frr_ac_keepcaps" = "yes"; then
2325     AC_CHECK_HEADERS([sys/capability.h])
2326   fi
2327   if test "$ac_cv_header_sys_capability_h" = "yes"; then
2328     AC_CHECK_LIB([cap], [cap_init],
2329       [AC_DEFINE([HAVE_LCAPS], [1], [Capabilities])
2330        LIBCAP="-lcap"
2331        frr_ac_lcaps="yes"]
2332     )
2333   fi
2334   if test "$frr_ac_scaps" = "yes" \
2335        -o "$frr_ac_lcaps" = "yes"; then
2336     AC_DEFINE([HAVE_CAPABILITIES], [1], [capabilities])
2337   fi
2338
2339   case "$host_os" in
2340   linux*)
2341     if test "$enable_clippy_only" != "yes"; then
2342     if test "$frr_ac_lcaps" != "yes"; then
2343       AC_MSG_ERROR([libcap and/or its headers were not found.  Running FRR without libcap support built in causes a huge performance penalty.])
2344     fi
2345     fi
2346     ;;
2347   esac
2348 else
2349   case "$host_os" in
2350   linux*)
2351     AC_MSG_WARN([Running FRR without libcap support built in causes a huge performance penalty.])
2352     ;;
2353   esac
2354 fi
2355 AC_SUBST([LIBCAP])
2356
2357 dnl ---------------------------
2358 dnl check for glibc 'backtrace'
2359 dnl ---------------------------
2360 if test "$enable_backtrace" != "no" ; then
2361   backtrace_ok=no
2362   PKG_CHECK_MODULES([UNWIND], [libunwind], [
2363     AC_DEFINE([HAVE_LIBUNWIND], [1], [libunwind])
2364     backtrace_ok=yes
2365   ], [
2366     true
2367   ])
2368
2369   if test "$backtrace_ok" = "no"; then
2370     AC_CHECK_HEADER([unwind.h], [
2371       AC_SEARCH_LIBS([unw_getcontext], [unwind], [
2372         AC_DEFINE([HAVE_LIBUNWIND], [1], [libunwind])
2373         backtrace_ok=yes
2374       ])
2375     ])
2376   fi
2377
2378   if test "$backtrace_ok" = "no"; then
2379     AC_CHECK_HEADER([execinfo.h], [
2380       AC_SEARCH_LIBS([backtrace], [execinfo], [
2381         AC_DEFINE([HAVE_GLIBC_BACKTRACE], [1], [Glibc backtrace])
2382         backtrace_ok=yes
2383       ],, [-lm])
2384     ])
2385   fi
2386
2387   if test "$enable_backtrace" = "yes" -a "$backtrace_ok" = "no"; then
2388     dnl user explicitly requested backtrace but we failed to find support
2389     AC_MSG_FAILURE([failed to find backtrace or libunwind support])
2390   fi
2391 fi
2392
2393 dnl -----------------------------------------
2394 dnl check for malloc mallinfo struct and call
2395 dnl this must try and link using LIBS, in
2396 dnl order to check no alternative allocator
2397 dnl has been specified, which might not provide
2398 dnl mallinfo
2399 dnl -----------------------------------------
2400 AC_CHECK_HEADERS([malloc.h malloc_np.h malloc/malloc.h],,, [FRR_INCLUDES])
2401
2402 AC_CACHE_CHECK([whether mallinfo is available], [frr_cv_mallinfo], [
2403   AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2404 #ifdef HAVE_MALLOC_H
2405 #include <malloc.h>
2406 #endif
2407 #ifdef HAVE_MALLOC_NP_H
2408 #include <malloc_np.h>
2409 #endif
2410 #ifdef HAVE_MALLOC_MALLOC_H
2411 #include <malloc/malloc.h>
2412 #endif
2413 ]], [[
2414 struct mallinfo ac_x; ac_x = mallinfo ();
2415 ]])], [
2416     frr_cv_mallinfo=yes
2417   ], [
2418     frr_cv_mallinfo=no
2419   ])
2420 ])
2421 if test "$frr_cv_mallinfo" = "yes"; then
2422   AC_DEFINE([HAVE_MALLINFO], [1], [mallinfo])
2423 fi
2424
2425 AC_CACHE_CHECK([whether mallinfo2 is available], [frr_cv_mallinfo2], [
2426   AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2427 #ifdef HAVE_MALLOC_H
2428 #include <malloc.h>
2429 #endif
2430 #ifdef HAVE_MALLOC_NP_H
2431 #include <malloc_np.h>
2432 #endif
2433 #ifdef HAVE_MALLOC_MALLOC_H
2434 #include <malloc/malloc.h>
2435 #endif
2436 ]], [[
2437 struct mallinfo2 ac_x; ac_x = mallinfo2 ();
2438 ]])], [
2439     frr_cv_mallinfo2=yes
2440   ], [
2441     frr_cv_mallinfo2=no
2442   ])
2443 ])
2444 if test "$frr_cv_mallinfo2" = "yes"; then
2445   AC_DEFINE([HAVE_MALLINFO2], [1], [mallinfo2])
2446 fi
2447
2448 AC_MSG_CHECKING([whether malloc_usable_size is available])
2449 AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2450 #ifdef HAVE_MALLOC_H
2451 #include <malloc.h>
2452 #endif
2453 #ifdef HAVE_MALLOC_MALLOC_H
2454 #include <malloc/malloc.h>
2455 #endif
2456 ]], [[
2457 size_t ac_x; ac_x = malloc_usable_size(NULL);
2458 ]])], [
2459   AC_MSG_RESULT([yes])
2460   AC_DEFINE([HAVE_MALLOC_USABLE_SIZE], [1], [malloc_usable_size])
2461 ], [
2462   AC_MSG_RESULT([no])
2463
2464   AC_MSG_CHECKING([whether malloc_size is available])
2465   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2466 #ifdef HAVE_MALLOC_H
2467 #include <malloc.h>
2468 #endif
2469 #ifdef HAVE_MALLOC_MALLOC_H
2470 #include <malloc/malloc.h>
2471 #endif
2472 ]], [[
2473 size_t ac_x; ac_x = malloc_size(NULL);
2474 ]])], [
2475     AC_MSG_RESULT([yes])
2476     AC_DEFINE([HAVE_MALLOC_SIZE], [1], [malloc_size])
2477   ], [
2478     AC_MSG_RESULT([no])
2479   ])
2480 ])
2481
2482 dnl ----------
2483 dnl configure date
2484 dnl ----------
2485 dev_version=`echo $VERSION | grep dev`
2486 #don't expire deprecated code in non 'dev' branch
2487 if test "$dev_version" = ""; then
2488    CONFDATE=0
2489 else
2490    CONFDATE=`date '+%Y%m%d'`
2491 fi
2492 AC_SUBST([CONFDATE])
2493
2494 dnl ------------------------------
2495 dnl set paths for state directory
2496 dnl ------------------------------
2497 AC_MSG_CHECKING([directory to use for state file])
2498 if test "$prefix" = "NONE"; then
2499   frr_statedir_prefix="";
2500 else
2501   frr_statedir_prefix=${prefix}
2502 fi
2503 if test "$localstatedir" = '${prefix}/var'; then
2504   for FRR_STATE_DIR in ${frr_statedir_prefix}/var/run dnl
2505                         ${frr_statedir_prefix}/var/adm dnl
2506                         ${frr_statedir_prefix}/etc dnl
2507                         /var/run        dnl
2508                         /var/adm        dnl
2509                         /etc            dnl
2510                         /dev/null;
2511   do
2512     test -d $FRR_STATE_DIR && break
2513   done
2514   frr_statedir=$FRR_STATE_DIR
2515 else
2516   frr_statedir=${localstatedir}
2517 fi
2518 if test "$frr_statedir" = "/dev/null"; then
2519     AC_MSG_ERROR([STATE DIRECTORY NOT FOUND! FIX OR SPECIFY --localstatedir!])
2520 fi
2521 AC_MSG_RESULT([${frr_statedir}])
2522 AC_SUBST([frr_statedir])
2523
2524 AC_DEFINE_UNQUOTED([LDPD_SOCKET], ["$frr_statedir%s%s/ldpd.sock"], [ldpd control socket])
2525 AC_DEFINE_UNQUOTED([ZEBRA_SERV_PATH], ["$frr_statedir%s%s/zserv.api"], [zebra api socket])
2526 AC_DEFINE_UNQUOTED([BFDD_CONTROL_SOCKET], ["$frr_statedir%s%s/bfdd.sock"], [bfdd control socket])
2527 AC_DEFINE_UNQUOTED([DAEMON_VTY_DIR], ["$frr_statedir%s%s"], [daemon vty directory])
2528 AC_DEFINE_UNQUOTED([DAEMON_DB_DIR], ["$frr_statedir"], [daemon database directory])
2529
2530 dnl autoconf does this, but it does it too late...
2531 test "$prefix" = "NONE" && prefix=$ac_default_prefix
2532 test "$exec_prefix" = "NONE" && exec_prefix='${prefix}'
2533
2534 dnl get the full path, recursing through variables...
2535 vtysh_bin="$bindir/vtysh"
2536 for I in 1 2 3 4 5 6 7 8 9 10; do
2537         eval vtysh_bin="\"$vtysh_bin\""
2538 done
2539 AC_DEFINE_UNQUOTED([VTYSH_BIN_PATH], ["$vtysh_bin"], [path to vtysh binary])
2540 AC_SUBST([vtysh_bin])
2541
2542 CFG_SYSCONF="$sysconfdir"
2543 CFG_SBIN="$sbindir"
2544 CFG_STATE="$frr_statedir"
2545 CFG_MODULE="$moduledir"
2546 CFG_YANGMODELS="$yangmodelsdir"
2547 CFG_SCRIPT="$scriptdir"
2548 for I in 1 2 3 4 5 6 7 8 9 10; do
2549         eval CFG_SYSCONF="\"$CFG_SYSCONF\""
2550         eval CFG_SBIN="\"$CFG_SBIN\""
2551         eval CFG_STATE="\"$CFG_STATE\""
2552         eval CFG_MODULE="\"$CFG_MODULE\""
2553         eval CFG_YANGMODELS="\"$CFG_YANGMODELS\""
2554         eval CFG_SCRIPT="\"$CFG_SCRIPT\""
2555 done
2556 AC_SUBST([CFG_SYSCONF])
2557 AC_SUBST([CFG_SBIN])
2558 AC_SUBST([CFG_STATE])
2559 AC_SUBST([CFG_MODULE])
2560 AC_SUBST([CFG_SCRIPT])
2561 AC_SUBST([CFG_YANGMODELS])
2562 AC_DEFINE_UNQUOTED([MODULE_PATH], ["$CFG_MODULE"], [path to modules])
2563 AC_DEFINE_UNQUOTED([SCRIPT_PATH], ["$CFG_SCRIPT"], [path to scripts])
2564 AC_DEFINE_UNQUOTED([YANG_MODELS_PATH], ["$CFG_YANGMODELS"], [path to YANG data models])
2565 AC_DEFINE_UNQUOTED([WATCHFRR_SH_PATH], ["${CFG_SBIN%/}/watchfrr.sh"], [path to watchfrr.sh])
2566
2567 dnl various features
2568 AM_CONDITIONAL([SUPPORT_REALMS], [test "$enable_realms" = "yes"])
2569 AM_CONDITIONAL([ENABLE_BGP_VNC], [test "$enable_bgp_vnc" != "no"])
2570 AM_CONDITIONAL([BGP_BMP], [$bgpd_bmp])
2571 dnl northbound
2572 AM_CONDITIONAL([SQLITE3], [$SQLITE3])
2573 AM_CONDITIONAL([CONFD], [test "$enable_confd" != ""])
2574 AM_CONDITIONAL([SYSREPO], [test "$enable_sysrepo" = "yes"])
2575 AM_CONDITIONAL([GRPC], [test "$enable_grpc" = "yes"])
2576 AM_CONDITIONAL([ZEROMQ], [test "$ZEROMQ" = "true"])
2577 dnl plugins
2578 AM_CONDITIONAL([RPKI], [test "$RPKI" = "true"])
2579 AM_CONDITIONAL([SNMP], [test "$SNMP_METHOD" = "agentx"])
2580 AM_CONDITIONAL([IRDP], [$IRDP])
2581 AM_CONDITIONAL([FPM], [test "$enable_fpm" = "yes"])
2582 AM_CONDITIONAL([HAVE_PROTOBUF], [test "$enable_protobuf" = "yes"])
2583 AM_CONDITIONAL([HAVE_PROTOBUF3], [$PROTO3])
2584
2585 dnl PCEP plugin
2586 AS_IF([test "$enable_pathd" != "no"], [
2587        AC_SUBST([PATHD_PCEP_LIBS], ["pceplib/libpcep_pcc.la"])
2588        AC_SUBST([PATHD_PCEP_INCL], ["-I./pceplib "])
2589        ])
2590 AC_CHECK_LIB([cunit], [CU_initialize_registry], [pcep_cunit=yes],[pcep_cunit=no])
2591 AM_CONDITIONAL([PATHD_PCEP_TEST], [test "x${pcep_cunit}" = xyes])
2592 AC_CHECK_PROG(VALGRIND_CHECK, valgrind, yes)
2593 AM_CONDITIONAL([HAVE_VALGRIND_PCEP], [test "$VALGRIND_CHECK" = "yes"])
2594
2595 dnl daemons
2596 AM_CONDITIONAL([VTYSH], [test "$VTYSH" = "vtysh"])
2597 AM_CONDITIONAL([ZEBRA], [test "$enable_zebra" != "no"])
2598 AM_CONDITIONAL([BGPD], [test "$enable_bgpd" != "no"])
2599 AM_CONDITIONAL([RIPD], [test "$enable_ripd" != "no"])
2600 AM_CONDITIONAL([OSPFD], [test "$enable_ospfd" != "no"])
2601 AM_CONDITIONAL([LDPD], [test "$enable_ldpd" != "no"])
2602 AM_CONDITIONAL([BFDD], [test "$BFDD" = "bfdd"])
2603 AM_CONDITIONAL([NHRPD], [test "$NHRPD" = "nhrpd"])
2604 AM_CONDITIONAL([EIGRPD], [test "$enable_eigrpd" != "no"])
2605 AM_CONDITIONAL([WATCHFRR], [test "$WATCHFRR" = "watchfrr"])
2606 AM_CONDITIONAL([OSPFCLIENT], [test "$OSPFCLIENT" = "ospfclient"])
2607 AM_CONDITIONAL([RIPNGD], [test "$enable_ripngd" != "no"])
2608 AM_CONDITIONAL([BABELD], [test "$enable_babeld" != "no"])
2609 AM_CONDITIONAL([OSPF6D], [test "$enable_ospf6d" != "no"])
2610 AM_CONDITIONAL([ISISD], [test "$enable_isisd" != "no"])
2611 AM_CONDITIONAL([PIMD], [test "$enable_pimd" != "no"])
2612 AM_CONDITIONAL([PBRD], [test "$enable_pbrd" != "no"])
2613 AM_CONDITIONAL([SHARPD], [test "$enable_sharpd" = "yes"])
2614 AM_CONDITIONAL([STATICD], [test "$enable_staticd" != "no"])
2615 AM_CONDITIONAL([FABRICD], [test "$enable_fabricd" != "no"])
2616 AM_CONDITIONAL([VRRPD], [test "$enable_vrrpd" != "no"])
2617 AM_CONDITIONAL([PATHD], [test "$enable_pathd" != "no"])
2618 AM_CONDITIONAL([PATHD_PCEP], [test "$enable_pathd" != "no"])
2619
2620 AC_CONFIG_FILES([Makefile],[
2621         test "$enable_dev_build" = "yes" && makefile_devbuild="--dev-build"
2622         ${PYTHON} "${ac_abs_top_srcdir}/python/makefile.py" ${makefile_devbuild} || exit 1
2623 ], [
2624         PYTHON="$PYTHON"
2625         enable_dev_build="$enable_dev_build"
2626 ])
2627
2628 AC_CONFIG_FILES([
2629           config.version
2630           changelog-auto
2631           redhat/frr.spec
2632           alpine/APKBUILD
2633           snapcraft/snapcraft.yaml
2634           lib/version.h
2635           tests/lib/cli/test_cli.refout
2636           pkgsrc/bgpd.sh pkgsrc/ospf6d.sh pkgsrc/ospfd.sh
2637           pkgsrc/ripd.sh pkgsrc/ripngd.sh pkgsrc/zebra.sh
2638           pkgsrc/eigrpd.sh])
2639
2640 AC_CONFIG_FILES([vtysh/extract.pl], [chmod +x vtysh/extract.pl])
2641 AC_CONFIG_FILES([tools/frr], [chmod +x tools/frr])
2642 AC_CONFIG_FILES([tools/watchfrr.sh], [chmod +x tools/watchfrr.sh])
2643 AC_CONFIG_FILES([tools/frrinit.sh], [chmod +x tools/frrinit.sh])
2644 AC_CONFIG_FILES([tools/frrcommon.sh])
2645 AC_CONFIG_FILES([tools/frr.service])
2646 AC_CONFIG_FILES([tools/frr@.service])
2647
2648 AS_IF([test "$with_pkg_git_version" = "yes"], [
2649     AC_CONFIG_COMMANDS([lib/gitversion.h], [
2650         dst="${ac_abs_top_builddir}/lib/gitversion.h"
2651         ${PERL} "${ac_abs_top_srcdir}/lib/gitversion.pl" \
2652                 "${ac_abs_top_srcdir}" \
2653                 > "${dst}.tmp"
2654         test -f "$dst" \
2655                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
2656                 && rm "${dst}.tmp" \
2657                 || mv "${dst}.tmp" "${dst}"
2658     ], [
2659         PERL="$PERL"
2660     ])
2661 ])
2662
2663 ## Hack, but working solution to avoid rebuilding of frr.info.
2664 ## It's already in CVS until texinfo 4.7 is more common.
2665 AC_OUTPUT
2666
2667 if test "$enable_rpath" = "yes" ; then
2668         true
2669 else
2670         # See https://old-en.opensuse.org/openSUSE:Packaging_Guidelines#Removing_Rpath
2671         sed -i 's|^hardcode_libdir_flag_spec=.*|hardcode_libdir_flag_spec=""|g' libtool
2672         sed -i 's|^runpath_var=LD_RUN_PATH|runpath_var=DIE_RPATH_DIE|g' libtool
2673 fi
2674
2675 echo "
2676 FRRouting configuration
2677 ------------------------------
2678 FRR version             : ${PACKAGE_VERSION}
2679 host operating system   : ${host_os}
2680 source code location    : ${srcdir}
2681 compiler                : ${CC}
2682 compiler flags          : ${CFLAGS} ${WERROR} ${AC_CFLAGS} ${SAN_FLAGS}
2683 make                    : ${MAKE-make}
2684 linker flags            : ${LDFLAGS} ${SAN_FLAGS} ${LIBS} ${LIBCAP} ${LIBREADLINE} ${LIBM}
2685 state file directory    : ${frr_statedir}
2686 config file directory   : `eval echo \`echo ${sysconfdir}\``
2687 module directory        : ${CFG_MODULE}
2688 script directory        : ${CFG_SCRIPT}
2689 user to run as          : ${enable_user}
2690 group to run as         : ${enable_group}
2691 group for vty sockets   : ${enable_vty_group}
2692 config file mask        : ${enable_configfile_mask}
2693 log file mask           : ${enable_logfile_mask}
2694 zebra protobuf enabled  : ${enable_protobuf:-no}
2695 vici socket path        : ${vici_socket}
2696
2697 The above user and group must have read/write access to the state file
2698 directory and to the config files in the config file directory."
2699
2700 if test "$enable_doc" != "no" -a "$frr_py_mod_sphinx" = "false"; then
2701   AC_MSG_WARN([sphinx is missing but required to build documentation])
2702 fi
2703 if test "$frr_py_mod_pytest" = "false"; then
2704   AC_MSG_WARN([pytest is missing, unit tests cannot be performed])
2705 fi