configure.ac

   1 ##
   2 ## Configure template file for FRRouting.
   3 ## autoconf will generate configure script.
   4 ##
   5 ##  Copyright (c) 1996, 97, 98, 99, 2000 Kunihiro Ishiguro <kunihiro@zebra.org>
   6 ##  Portions Copyright (c) 2003 Paul Jakma <paul@dishone.st>
   7 ##
   8 AC_PREREQ(2.60)
   9
  10 AC_INIT(frr, 3.1-dev, [https://github.com/frrouting/frr/issues])
  11 PACKAGE_URL="https://frrouting.org/"
  12 AC_SUBST(PACKAGE_URL)
  13 PACKAGE_FULLNAME="FRRouting"
  14 AC_SUBST(PACKAGE_FULLNAME)
  15
  16 CONFIG_ARGS="$ac_configure_args"
  17 AC_SUBST(CONFIG_ARGS)
  18
  19 AC_CONFIG_SRCDIR(lib/zebra.h)
  20 AC_CONFIG_MACRO_DIR([m4])
  21
  22 dnl -----------------------------------
  23 dnl Get hostname and other information.
  24 dnl -----------------------------------
  25 AC_CANONICAL_BUILD()
  26 AC_CANONICAL_HOST()
  27
  28 AS_IF([test "$host" != "$build"], [
  29   if test "$srcdir" = "."; then
  30     AC_MSG_ERROR([cross-compilation is only possible with builddir separate from srcdir.  create a separate directory and run as .../path-to-frr/configure.])
  31   fi
  32   test -d hosttools || mkdir hosttools
  33   abssrc="`cd \"${srcdir}\"; pwd`"
  34
  35   AC_MSG_NOTICE([...])
  36   AC_MSG_NOTICE([... cross-compilation: creating hosttools directory and self-configuring for build platform tools])
  37   AC_MSG_NOTICE([... use HOST_CPPFLAGS / HOST_CFLAGS / HOST_LDFLAGS if neccessary])
  38   AC_MSG_NOTICE([...])
  39
  40   ( CPPFLAGS="$HOST_CPPFLAGS"; \
  41     CFLAGS="$HOST_CFLAGS"; \
  42     LDFLAGS="$HOST_LDFLAGS"; \
  43     cd hosttools; "${abssrc}/configure" "--host=$build" "--build=$build"; )
  44
  45   AC_MSG_NOTICE([...])
  46   AC_MSG_NOTICE([... cross-compilation: finished self-configuring for build platform tools])
  47   AC_MSG_NOTICE([...])
  48
  49   build_clippy="false"
  50   HOSTTOOLS="hosttools/"
  51 ], [
  52   build_clippy="true"
  53   HOSTTOOLS=""
  54 ])
  55 AC_SUBST(HOSTTOOLS)
  56 AM_CONDITIONAL([BUILD_CLIPPY], [$build_clippy])
  57
  58 # Disable portability warnings -- our automake code (in particular
  59 # common.am) uses some constructs specific to gmake.
  60 AM_INIT_AUTOMAKE([1.12 -Wno-portability])
  61 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
  62 AM_SILENT_RULES([yes])
  63 AC_CONFIG_HEADERS(config.h)
  64
  65 AC_PATH_PROG(PERL, perl)
  66 PKG_PROG_PKG_CONFIG
  67
  68 dnl default is to match previous behavior
  69 exampledir=${sysconfdir}
  70 AC_ARG_ENABLE([exampledir],
  71           AS_HELP_STRING([--enable-exampledir],
  72                          [specify alternate directory for examples]),
  73                          exampledir="$enableval",)
  74 dnl XXX add --exampledir to autoconf standard directory list somehow
  75 AC_SUBST(exampledir)
  76
  77 dnl default is to match previous behavior
  78 pkgsrcrcdir=""
  79 AC_ARG_ENABLE([pkgsrcrcdir],
  80           AS_HELP_STRING([--enable-pkgsrcrcdir],
  81                          [specify directory for rc.d scripts]),
  82                          pkgsrcrcdir="$enableval",)
  83 dnl XXX add --pkgsrcrcdir to autoconf standard directory list somehow
  84 AC_SUBST(pkgsrcrcdir)
  85 AM_CONDITIONAL([PKGSRC], [test "x$pkgsrcrcdir" != "x"])
  86
  87 AC_ARG_WITH([moduledir], [AS_HELP_STRING([--with-moduledir=DIR], [module directory (${libdir}/frr/modules)])], [
  88         moduledir="$withval"
  89 ], [
  90         moduledir="\${libdir}/frr/modules"
  91 ])
  92 AC_SUBST([moduledir], [$moduledir])
  93
  94 AC_ARG_ENABLE(tcmalloc,
  95         AS_HELP_STRING([--enable-tcmalloc], [Turn on tcmalloc]),
  96 [case "${enableval}" in
  97   yes) tcmalloc_enabled=true
  98 LIBS="$LIBS -ltcmalloc_minimal"
  99  ;;
 100   no)  tcmalloc_enabled=false ;;
 101   *) AC_MSG_ERROR(bad value ${enableval} for --enable-tcmalloc) ;;
 102 esac],[tcmalloc_enabled=false])
 103
 104
 105 dnl Thanks autoconf, but we don't want a default -g -O2.  We have our own
 106 dnl flag determination logic.
 107 CFLAGS="${CFLAGS:-}"
 108
 109 dnl --------------------
 110 dnl Check CC and friends
 111 dnl --------------------
 112 dnl note orig_cflags is also used further down
 113 orig_cflags="$CFLAGS"
 114 AC_LANG([C])
 115 AC_PROG_CC
 116 AC_PROG_CPP
 117 AM_PROG_CC_C_O
 118 dnl remove autoconf default "-g -O2"
 119 CFLAGS="$orig_cflags"
 120 AC_PROG_CC_C99
 121 dnl NB: see C11 below
 122
 123 AC_PROG_EGREP
 124 PKG_PROG_PKG_CONFIG
 125
 126 dnl autoconf 2.59 appears not to support AC_PROG_SED
 127 dnl AC_PROG_SED
 128 AC_CHECK_PROG([SED],[sed],[sed],[/bin/false])
 129
 130 dnl try and enable CFLAGS that are useful for FRR
 131 dnl - specifically, options to control warnings
 132
 133 AC_USE_SYSTEM_EXTENSIONS
 134 AC_DEFUN([AC_C_FLAG], [{
 135         AC_LANG_PUSH(C)
 136         ac_c_flag_save="$CFLAGS"
 137         CFLAGS="$CFLAGS $1"
 138         AC_MSG_CHECKING([[whether $CC supports $1]])
 139         AC_COMPILE_IFELSE(
 140                 [AC_LANG_PROGRAM([[]])],
 141                 [
 142                         AC_MSG_RESULT([yes])
 143                         m4_if([$3], [], [], [
 144                                 CFLAGS="$ac_c_flag_save"
 145                                 $3
 146                         ])
 147                 ], [
 148                         CFLAGS="$ac_c_flag_save"
 149                         AC_MSG_RESULT([no])
 150                         $2
 151                 ])
 152         AC_LANG_POP(C)
 153         }])
 154
 155 AC_DEFUN([AC_LINK_IFELSE_FLAGS], [{
 156         AC_LANG_PUSH(C)
 157         ac_cflags_save="$CFLAGS"
 158         ac_libs_save="$LIBS"
 159         CFLAGS="$CFLAGS $1"
 160         LIBS="$LIBS $2"
 161         AC_LINK_IFELSE(
 162                 [$3],
 163                 [
 164                         AC_MSG_RESULT([yes])
 165                         CFLAGS="$ac_cflags_save"
 166                         LIBS="$ac_libs_save"
 167                         $5
 168                 ], [
 169                         AC_MSG_RESULT([no])
 170                         CFLAGS="$ac_cflags_save"
 171                         LIBS="$ac_libs_save"
 172                         $4
 173                 ])
 174         AC_LANG_POP(C)
 175         }])
 176
 177 dnl ICC won't bail on unknown options without -diag-error 10006
 178 dnl need to do this first so we get useful results for the other options
 179 AC_C_FLAG([-diag-error 10006])
 180
 181 dnl AC_PROG_CC_C99 may change CC to include -std=gnu99 or something
 182 ac_cc="$CC"
 183 CC="${CC% -std=gnu99}"
 184 CC="${CC% -std=c99}"
 185
 186 AC_C_FLAG([-std=gnu11], [CC="$ac_cc"], [CC="$CC -std=gnu11"])
 187
 188 dnl if the user specified any CFLAGS, we don't add "-g -Os/-O2" here
 189 if test "z$orig_cflags" = "z"; then
 190   AC_C_FLAG([-g])
 191   AC_C_FLAG([-Os], [
 192     AC_C_FLAG([-O2])
 193   ])
 194 fi
 195
 196 dnl always want these CFLAGS
 197 AC_C_FLAG([-fno-omit-frame-pointer])
 198 AC_C_FLAG([-Wall])
 199 AC_C_FLAG([-Wextra])
 200 AC_C_FLAG([-Wmissing-prototypes])
 201 AC_C_FLAG([-Wmissing-declarations])
 202 AC_C_FLAG([-Wpointer-arith])
 203 AC_C_FLAG([-Wbad-function-cast])
 204 AC_C_FLAG([-Wwrite-strings])
 205 if test x"${enable_gcc_ultra_verbose}" = x"yes" ; then
 206   AC_C_FLAG([-Wcast-qual])
 207   AC_C_FLAG([-Wstrict-prototypes])
 208   AC_C_FLAG([-Wmissing-noreturn])
 209   AC_C_FLAG([-Wmissing-format-attribute])
 210   AC_C_FLAG([-Wunreachable-code])
 211   AC_C_FLAG([-Wpacked])
 212   AC_C_FLAG([-Wpadded])
 213 else
 214   AC_C_FLAG([-Wno-unused-result])
 215 fi
 216 AC_C_FLAG([-Wno-unused-parameter])
 217 AC_C_FLAG([-Wno-missing-field-initializers])
 218
 219 dnl ICC emits a broken warning for const char *x = a ? "b" : "c";
 220 dnl for some reason the string consts get 'promoted' to char *,
 221 dnl triggering a const to non-const conversion warning.
 222 AC_C_FLAG([-diag-disable 3179])
 223
 224 if test x"${enable_werror}" = x"yes" ; then
 225   WERROR="-Werror"
 226 fi
 227 AC_SUBST(WERROR)
 228
 229 dnl need link on this one, not compile
 230 AC_LANG_PUSH(C)
 231 ac_ld_flag_save="$LDFLAGS"
 232 LDFLAGS="$LDFLAGS -rdynamic"
 233 AC_MSG_CHECKING([[whether linker supports -rdynamic]])
 234 AC_LINK_IFELSE(
 235         [AC_LANG_PROGRAM([[]])],
 236         [AC_MSG_RESULT([yes])],
 237         [
 238                 LDFLAGS="$ac_ld_flag_save"
 239                 AC_MSG_RESULT([no])
 240         ])
 241 AC_LANG_POP(C)
 242
 243 dnl ----------
 244 dnl Essentials
 245 dnl ----------
 246
 247 AX_PTHREAD([
 248   CC="$PTHREAD_CC"
 249   CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 250   LIBS="$PTHREAD_LIBS $LIBS"
 251 ], [
 252   AC_MSG_FAILURE([This FRR version needs pthreads])
 253 ])
 254
 255 dnl --------------
 256 dnl Check programs
 257 dnl --------------
 258 AC_PROG_INSTALL
 259 AC_PROG_LN_S
 260 AC_PROG_MAKE_SET
 261 AC_CHECK_TOOL(AR, ar)
 262
 263 dnl -----------------
 264 dnl System extensions
 265 dnl -----------------
 266 AC_GNU_SOURCE
 267
 268 dnl -------
 269 dnl libtool
 270 dnl -------
 271 LT_INIT
 272
 273 dnl ----------------------
 274 dnl Packages configuration
 275 dnl ----------------------
 276 AC_ARG_WITH(pkg-extra-version,
 277         AS_HELP_STRING([--with-pkg-extra-version=VER], [add extra version field, for packagers/distributions]),
 278         [EXTRAVERSION=$withval],)
 279 AC_ARG_WITH(pkg-git-version,
 280         AS_HELP_STRING([--with-pkg-git-version], [add git information to MOTD and build version string]),
 281         [ test "x$withval" != "xno" && with_pkg_git_version="yes" ])
 282 AC_ARG_WITH(vtysh_pager,
 283         AS_HELP_STRING([--with-vtysh-pager=PAGER], [control what pager is compiled in as default]),
 284         VTYSH_PAGER=$withval, VTYSH_PAGER="more")
 285 AC_ARG_ENABLE(vtysh,
 286   AS_HELP_STRING([--disable-vtysh], [do not build integrated vty shell for FRR]))
 287 AC_ARG_ENABLE(doc,
 288   AS_HELP_STRING([--disable-doc], [do not build docs]))
 289 AC_ARG_ENABLE(zebra,
 290   AS_HELP_STRING([--disable-zebra], [do not build zebra daemon]))
 291 AC_ARG_ENABLE(bgpd,
 292   AS_HELP_STRING([--disable-bgpd], [do not build bgpd]))
 293 AC_ARG_ENABLE(ripd,
 294   AS_HELP_STRING([--disable-ripd], [do not build ripd]))
 295 AC_ARG_ENABLE(ripngd,
 296   AS_HELP_STRING([--disable-ripngd], [do not build ripngd]))
 297 AC_ARG_ENABLE(ospfd,
 298   AS_HELP_STRING([--disable-ospfd], [do not build ospfd]))
 299 AC_ARG_ENABLE(ospf6d,
 300   AS_HELP_STRING([--disable-ospf6d], [do not build ospf6d]))
 301 AC_ARG_ENABLE(ldpd,
 302   AS_HELP_STRING([--enable-ldpd], [build ldpd]))
 303 AC_ARG_ENABLE(nhrpd,
 304   AS_HELP_STRING([--disable-nhrpd], [do not build nhrpd]))
 305 AC_ARG_ENABLE(eigrpd,
 306   AS_HELP_STRING([--disable-eigrpd], [do not build eigrpd]))
 307 AC_ARG_ENABLE(babeld,
 308   AS_HELP_STRING([--disable-babeld], [do not build babeld]))
 309 AC_ARG_ENABLE(watchfrr,
 310   AS_HELP_STRING([--disable-watchfrr], [do not build watchfrr]))
 311 AC_ARG_ENABLE(isisd,
 312   AS_HELP_STRING([--disable-isisd], [do not build isisd]))
 313 AC_ARG_ENABLE(pimd,
 314   AS_HELP_STRING([--disable-pimd], [do not build pimd]))
 315 AC_ARG_ENABLE(bgp-announce,
 316   AS_HELP_STRING([--disable-bgp-announce,], [turn off BGP route announcement]))
 317 AC_ARG_ENABLE(bgp-vnc,
 318   AS_HELP_STRING([--disable-bgp-vnc],[turn off BGP VNC support]))
 319 AC_ARG_WITH(rfp-path,
 320   AS_HELP_STRING([--with-rfp-path[=DIR]],[path to replaced stub RFP used with BGP VNC]))
 321 AC_ARG_ENABLE(snmp,
 322   AS_HELP_STRING([--enable-snmp=ARG], [enable SNMP support (smux or agentx)]))
 323 AC_ARG_WITH(libpam,
 324   AS_HELP_STRING([--with-libpam], [use libpam for PAM support in vtysh]))
 325 AC_ARG_ENABLE(tcp-zebra,
 326   AS_HELP_STRING([--enable-tcp-zebra], [enable TCP/IP socket connection between zebra and protocol daemon]))
 327 AC_ARG_ENABLE(ospfapi,
 328   AS_HELP_STRING([--disable-ospfapi], [do not build OSPFAPI to access the OSPF LSA Database]))
 329 AC_ARG_ENABLE(ospfclient,
 330   AS_HELP_STRING([--disable-ospfclient], [do not build OSPFAPI client for OSPFAPI,
 331                           (this is the default if --disable-ospfapi is set)]))
 332 AC_ARG_ENABLE(multipath,
 333   AS_HELP_STRING([--enable-multipath=ARG], [enable multipath function, ARG must be digit]))
 334 AC_ARG_ENABLE(user,
 335   AS_HELP_STRING([--enable-user=USER], [user to run FRR suite as (default frr)]))
 336 AC_ARG_ENABLE(group,
 337   AS_HELP_STRING([--enable-group=GROUP], [group to run FRR suite as (default frr)]))
 338 AC_ARG_ENABLE(vty_group,
 339   AS_HELP_STRING([--enable-vty-group=ARG], [set vty sockets to have specified group as owner]))
 340 AC_ARG_ENABLE(configfile_mask,
 341   AS_HELP_STRING([--enable-configfile-mask=ARG], [set mask for config files]))
 342 AC_ARG_ENABLE(logfile_mask,
 343   AS_HELP_STRING([--enable-logfile-mask=ARG], [set mask for log files]))
 344 AC_ARG_ENABLE(shell_access,
 345   AS_HELP_STRING([--enable-shell-access], [Allow users to access shell/telnet/ssh]))
 346 AC_ARG_ENABLE(rtadv,
 347   AS_HELP_STRING([--disable-rtadv], [disable IPV6 router advertisement feature]))
 348 AC_ARG_ENABLE(irdp,
 349   AS_HELP_STRING([--enable-irdp], [enable IRDP server support in zebra]))
 350 AC_ARG_ENABLE(capabilities,
 351   AS_HELP_STRING([--disable-capabilities], [disable using POSIX capabilities]))
 352 AC_ARG_ENABLE(rusage,
 353   AS_HELP_STRING([--disable-rusage], [disable using getrusage]))
 354 AC_ARG_ENABLE(gcc_ultra_verbose,
 355   AS_HELP_STRING([--enable-gcc-ultra-verbose], [enable ultra verbose GCC warnings]))
 356 AC_ARG_ENABLE(linux24_tcp_md5,
 357   AS_HELP_STRING([--enable-linux24-tcp-md5], [enable support for old, Linux-2.4 RFC2385 patch]))
 358 AC_ARG_ENABLE(backtrace,
 359   AS_HELP_STRING([--disable-backtrace,], [disable crash backtraces (default autodetect)]))
 360 AC_ARG_ENABLE(time-check,
 361   AS_HELP_STRING([--disable-time-check], [disable slow thread warning messages]))
 362 AC_ARG_ENABLE(pcreposix,
 363   AS_HELP_STRING([--enable-pcreposix], [enable using PCRE Posix libs for regex functions]))
 364 AC_ARG_ENABLE(fpm,
 365   AS_HELP_STRING([--enable-fpm], [enable Forwarding Plane Manager support]))
 366 AC_ARG_ENABLE(systemd,
 367   AS_HELP_STRING([--enable-systemd], [enable Systemd support]))
 368 AC_ARG_ENABLE(werror,
 369   AS_HELP_STRING([--enable-werror], [enable -Werror (recommended for developers only)]))
 370 AC_ARG_ENABLE(cumulus,
 371   AS_HELP_STRING([--enable-cumulus], [enable Cumulus Switch Special Extensions]))
 372 AC_ARG_ENABLE(datacenter,
 373   AS_HELP_STRING([--enable-datacenter], [enable Compilation for Data Center Extensions]))
 374 AC_ARG_ENABLE(rr-semantics,
 375   AS_HELP_STRING([--disable-rr-semantics], [disable the v6 Route Replace semantics]))
 376 AC_ARG_ENABLE([protobuf],
 377   AS_HELP_STRING([--enable-protobuf], [Enable experimental protobuf support]))
 378 AC_ARG_ENABLE([oldvpn_commands],
 379   AS_HELP_STRING([--enable-oldvpn-commands], [Keep old vpn commands]))
 380
 381 AC_CHECK_HEADERS(json-c/json.h)
 382 AC_CHECK_LIB(json-c, json_object_get, LIBS="$LIBS -ljson-c", [], [-lm])
 383 if test $ac_cv_lib_json_c_json_object_get = no; then
 384   AC_CHECK_LIB(json, json_object_get, LIBS="$LIBS -ljson")
 385   if test $ac_cv_lib_json_json_object_get = no; then
 386       AC_MSG_ERROR([lib json is needed to compile])
 387   fi
 388 fi
 389
 390 AC_ARG_ENABLE([dev_build],
 391     AS_HELP_STRING([--enable-dev-build], [build for development]))
 392
 393 if test x"${enable_time_check}" != x"no" ; then
 394   if test x"${enable_time_check}" = x"yes" -o x"${enable_time_check}" = x ; then
 395     AC_DEFINE(CONSUMED_TIME_CHECK,5000000,Consumed Time Check)
 396   else
 397     AC_DEFINE_UNQUOTED(CONSUMED_TIME_CHECK,$enable_time_check,Consumed Time Check)
 398   fi
 399 fi
 400
 401 case "${enable_systemd}" in
 402   "no") ;;
 403   "yes")
 404   AC_CHECK_LIB(systemd, sd_notify, LIBS="$LIBS -lsystemd")
 405   if test $ac_cv_lib_systemd_sd_notify = no; then
 406     AC_MSG_ERROR([enable systemd has been specified but systemd development env not found on your system])
 407   else
 408     AC_DEFINE(HAVE_SYSTEMD,,Compile systemd support in)
 409   fi
 410   ;;
 411   "*") ;;
 412 esac
 413
 414 if test "${enable_rr_semantics}" != "no" ; then
 415   AC_DEFINE(HAVE_V6_RR_SEMANTICS,, Compile in v6 Route Replacement Semantics)
 416 fi
 417
 418 if test "${enable_datacenter}" = "yes" ; then
 419   AC_DEFINE(HAVE_DATACENTER,,Compile extensions for a DataCenter)
 420   DFLT_NAME="datacenter"
 421 else
 422   DFLT_NAME="traditional"
 423 fi
 424
 425 if test "${enable_cumulus}" = "yes" ; then
 426   AC_DEFINE(HAVE_CUMULUS,,Compile Special Cumulus Code in)
 427 fi
 428
 429 AC_SUBST(DFLT_NAME)
 430 AC_DEFINE_UNQUOTED(DFLT_NAME,["$DFLT_NAME"], Name of the configuration default set)
 431
 432 if test "${enable_shell_access}" = "yes"; then
 433    AC_DEFINE(HAVE_SHELL_ACCESS,,Allow user to use ssh/telnet/bash)
 434 fi
 435
 436 AM_CONDITIONAL([FPM], [test "x$enable_fpm" = "xyes"])
 437
 438 if test "x${enable_dev_build}" = "xyes"; then
 439    AC_DEFINE(DEV_BUILD,,Build for development)
 440 fi
 441 AM_CONDITIONAL([DEV_BUILD], [test "x$enable_dev_build" = "xyes"])
 442
 443 #
 444 # Python for clippy
 445 #
 446 AS_IF([test "$host" = "$build"], [
 447   PYTHONCONFIG=""
 448
 449   # ordering:
 450   # 1.  try python3, but respect the user's preference on which minor ver
 451   # 2.  try python, which might be py3 or py2 again on the user's preference
 452   # 3.  try python2 (can really only be 2.7 but eh)
 453   # 4.  try 3.5 > 3.4 > 3.3 > 3.2 > 2.7 through pkg-config (no user pref)
 454   #
 455   # (AX_PYTHON_DEVEL has no clue about py3 vs py2)
 456   # (AX_PYTHON does not do what we need)
 457
 458   AC_CHECK_TOOLS([PYTHONCONFIG], [python3-config python-config python2-config])
 459   if test -n "$PYTHONCONFIG"; then
 460     PYTHON_CFLAGS="`\"${PYTHONCONFIG}\" --includes`"
 461     PYTHON_LIBS="`\"${PYTHONCONFIG}\" --libs`"
 462
 463     AC_MSG_CHECKING([whether we found a working Python version])
 464     AC_LINK_IFELSE_FLAGS([$PYTHON_CFLAGS], [$PYTHON_LIBS], [AC_LANG_PROGRAM([
 465 #include <Python.h>
 466 #if PY_VERSION_HEX < 0x02070000
 467 #error python too old
 468 #endif
 469 int main(void);
 470 ],
 471 [
 472 {
 473   Py_Initialize();
 474   return 0;
 475 }
 476 ])], [
 477       PYTHONCONFIG=""
 478       unset PYTHON_LIBS
 479       unset PYTHON_CFLAGS
 480     ])
 481   fi
 482
 483   if test -z "$PYTHONCONFIG"; then
 484     PKG_CHECK_MODULES([PYTHON], python-3.5, [], [
 485       PKG_CHECK_MODULES([PYTHON], python-3.4, [], [
 486         PKG_CHECK_MODULES([PYTHON], python-3.3, [], [
 487           PKG_CHECK_MODULES([PYTHON], python-3.2, [], [
 488             PKG_CHECK_MODULES([PYTHON], python-2.7, [], [
 489               AC_MSG_FAILURE([could not find python-config or pkg-config python, please install Python development files from libpython-dev or similar])
 490               ])])])])])
 491
 492
 493     AC_MSG_CHECKING([whether we found a working Python version])
 494     AC_LINK_IFELSE_FLAGS([$PYTHON_CFLAGS], [$PYTHON_LIBS], [AC_LANG_PROGRAM([
 495 #include <Python.h>
 496 #if PY_VERSION_HEX < 0x02070000
 497 #error python too old
 498 #endif
 499 int main(void);
 500 ],
 501 [
 502 {
 503   Py_Initialize();
 504   return 0;
 505 }
 506 ])], [
 507       AC_MSG_FAILURE([could not find python-config or pkg-config python, please install Python development files from libpython-dev or similar])
 508     ])
 509   fi
 510 ])
 511 AC_SUBST(PYTHON_CFLAGS)
 512 AC_SUBST(PYTHON_LIBS)
 513
 514 #
 515 # Logic for protobuf support.
 516 #
 517 if test "$enable_protobuf" = "yes"; then
 518    have_protobuf=yes
 519
 520    # Check for protoc-c
 521    AC_CHECK_PROG([PROTOC_C], [protoc-c], [protoc-c], [/bin/false])
 522    if test "x$PROTOC_C" = "x/bin/false"; then
 523       have_protobuf=no
 524    else
 525       found_protobuf_c=no
 526       PKG_CHECK_MODULES([PROTOBUF_C], libprotobuf-c >= 0.14,
 527                      [found_protobuf_c=yes],
 528                      [AC_MSG_RESULT([pkg-config did not find libprotobuf-c])])
 529
 530       if test "x$found_protobuf_c" = "xyes"; then
 531          LDFLAGS="$LDFLAGS $PROTOBUF_C_LIBS"
 532          CFLAGS="$CFLAGS $PROTOBUF_C_CFLAGS"
 533       else
 534         AC_CHECK_HEADER([google/protobuf-c/protobuf-c.h], [],
 535                         [have_protobuf=no; AC_MSG_RESULT([Couldn't find google/protobuf-c.h])])
 536       fi
 537    fi
 538 fi
 539
 540 #
 541 # Logic for old vpn commans support.
 542 #
 543 if test "$enable_oldvpn_commands" = "yes"; then
 544    AC_DEFINE(KEEP_OLD_VPN_COMMANDS,, [Define for compiling with old vpn commands])
 545 fi
 546
 547 # Fail if the user explicity enabled protobuf support and we couldn't
 548 # find the compiler or libraries.
 549 if test "x$have_protobuf" = "xno" && test "x$enable_protobuf" = "xyes"; then
 550    AC_MSG_ERROR([Protobuf enabled explicitly but can't find libraries/tools])
 551 fi
 552
 553 if test "x$have_protobuf" = "xyes"; then
 554    AC_DEFINE(HAVE_PROTOBUF,, protobuf)
 555 fi
 556
 557 AM_CONDITIONAL([HAVE_PROTOBUF], [test "x$have_protobuf" = "xyes"])
 558
 559 #
 560 # End of logic for protobuf support.
 561 #
 562
 563 if test "${enable_tcp_zebra}" = "yes"; then
 564   AC_DEFINE(HAVE_TCP_ZEBRA,,Use TCP for zebra communication)
 565 fi
 566
 567 if test "${enable_linux24_tcp_md5}" = "yes"; then
 568   AC_DEFINE(HAVE_TCP_MD5_LINUX24,,Old Linux 2.4 TCP MD5 Signature Patch)
 569 fi
 570
 571 AC_MSG_CHECKING(if zebra should be configurable to send Route Advertisements)
 572 if test "${enable_rtadv}" != "no"; then
 573   AC_MSG_RESULT(yes)
 574   AC_DEFINE(HAVE_RTADV,,Enable IPv6 Routing Advertisement support)
 575 else
 576   AC_MSG_RESULT(no)
 577 fi
 578
 579 if test "${enable_irdp}" = "yes"; then
 580   AC_DEFINE(HAVE_IRDP,, IRDP )
 581 fi
 582
 583 if test x"${enable_user}" = x"no"; then
 584   enable_user=""
 585 else
 586   if test x"${enable_user}" = x"yes" || test x"${enable_user}" = x""; then
 587     enable_user="frr"
 588   fi
 589   AC_DEFINE_UNQUOTED(FRR_USER, "${enable_user}", frr User)
 590 fi
 591
 592 if test x"${enable_group}" = x"no"; then
 593   enable_group=""
 594 else
 595   if test x"${enable_group}" = x"yes" || test x"${enable_group}" = x""; then
 596     enable_group="frr"
 597   fi
 598   AC_DEFINE_UNQUOTED(FRR_GROUP, "${enable_group}", frr Group)
 599 fi
 600
 601 if test x"${enable_vty_group}" = x"yes" ; then
 602   AC_MSG_ERROR([--enable-vty-group requires a group as argument, not yes])
 603 elif test x"${enable_vty_group}" != x""; then
 604   if test x"${enable_vty_group}" != x"no"; then
 605     AC_DEFINE_UNQUOTED(VTY_GROUP, "${enable_vty_group}", VTY Sockets Group)
 606   fi
 607 fi
 608 AC_SUBST([enable_user])
 609 AC_SUBST([enable_group])
 610 AC_SUBST([enable_vty_group])
 611
 612 enable_configfile_mask=${enable_configfile_mask:-0600}
 613 AC_DEFINE_UNQUOTED(CONFIGFILE_MASK, ${enable_configfile_mask}, Mask for config files)
 614
 615 enable_logfile_mask=${enable_logfile_mask:-0600}
 616 AC_DEFINE_UNQUOTED(LOGFILE_MASK, ${enable_logfile_mask}, Mask for log files)
 617
 618 MPATH_NUM=1
 619
 620 case "${enable_multipath}" in
 621   0)
 622     MPATH_NUM=64
 623     ;;
 624   [[1-9]|[1-9][0-9]|[1-9][0-9][0-9]])
 625     MPATH_NUM="${enable_multipath}"
 626     ;;
 627   "")
 628     ;;
 629   *)
 630     AC_MSG_FAILURE([Please specify digit to enable multipath ARG])
 631     ;;
 632 esac
 633
 634 AC_DEFINE_UNQUOTED(MULTIPATH_NUM, $MPATH_NUM, Maximum number of paths for a route)
 635
 636 AC_DEFINE_UNQUOTED(VTYSH_PAGER, "$VTYSH_PAGER", [What pager to use])
 637
 638 dnl -----------------------------------
 639 dnl Add extra version string to package
 640 dnl name, string and version fields.
 641 dnl -----------------------------------
 642 if test "x${EXTRAVERSION}" != "x" ; then
 643   VERSION="${VERSION}${EXTRAVERSION}"
 644   PACKAGE_VERSION="${PACKAGE_VERSION}${EXTRAVERSION}"
 645   AC_SUBST(PACKAGE_EXTRAVERSION, ["${EXTRAVERSION}"])
 646   PACKAGE_STRING="${PACKAGE_STRING}${EXTRAVERSION}"
 647 fi
 648
 649 if test "x$with_pkg_git_version" = "xyes"; then
 650         if test -d "${srcdir}/.git"; then
 651                 AC_DEFINE(GIT_VERSION, [1], [include git version info])
 652         else    with_pkg_git_version="no"
 653                 AC_MSG_WARN([--with-pkg-git-version given, but this is not a git checkout])
 654         fi
 655 fi
 656 AM_CONDITIONAL([GIT_VERSION], [test "x$with_pkg_git_version" = "xyes"])
 657
 658 dnl ------------------------------------
 659 dnl Check C keywords and standard  types
 660 dnl ------------------------------------
 661 AC_C_CONST
 662 AC_C_INLINE
 663 AC_C_VOLATILE
 664 AC_HEADER_STDC
 665 dnl AC_TYPE_PID_T
 666 AC_TYPE_UID_T
 667 AC_TYPE_MODE_T
 668 AC_TYPE_SIZE_T
 669 AC_STRUCT_TM
 670
 671 dnl -------------------------
 672 dnl Check other header files.
 673 dnl -------------------------
 674 AC_CHECK_HEADERS([stropts.h sys/ksym.h \
 675         linux/version.h asm/types.h \
 676         sys/cdefs.h])
 677
 678 ac_stdatomic_ok=false
 679 AC_DEFINE(FRR_AUTOCONF_ATOMIC, 1, [did autoconf checks for atomic funcs])
 680 AC_CHECK_HEADER([stdatomic.h],[
 681
 682   AC_MSG_CHECKING([whether _Atomic qualifier works])
 683   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 684 #include <stdatomic.h>
 685 int main(int argc, char **argv) {
 686   _Atomic int i = 0;
 687   return i;
 688 }
 689 ]])], [
 690     AC_DEFINE(HAVE_STDATOMIC_H, 1, [found stdatomic.h])
 691     AC_MSG_RESULT([yes])
 692     ac_stdatomic_ok=true
 693   ], [
 694     AC_MSG_RESULT([no])
 695   ])
 696 ])
 697
 698 AS_IF([$ac_stdatomic_ok], [true], [
 699   AC_MSG_CHECKING([for __atomic_* builtins])
 700   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 701 int main(int argc, char **argv) {
 702   volatile int i = 1;
 703   __atomic_store_n (&i, 0, __ATOMIC_RELEASE);
 704   return __atomic_load_n (&i, __ATOMIC_ACQUIRE);
 705 }
 706 ]])], [
 707     AC_DEFINE(HAVE___ATOMIC, 1, [found __atomic builtins])
 708     AC_MSG_RESULT([yes])
 709   ], [
 710     AC_MSG_RESULT([no])
 711
 712     dnl FreeBSD 9 has a broken stdatomic.h where _Atomic doesn't work
 713     AC_MSG_CHECKING([for __sync_* builtins])
 714     AC_LINK_IFELSE([AC_LANG_SOURCE([[
 715 int main(int argc, char **argv) {
 716   volatile int i = 1;
 717   __sync_fetch_and_sub (&i, 1);
 718   return __sync_val_compare_and_swap (&i, 0, 1);
 719 }
 720 ]])], [
 721       AC_DEFINE(HAVE___SYNC, 1, [found __sync builtins])
 722       AC_MSG_RESULT([yes])
 723
 724       AC_MSG_CHECKING([for __sync_swap builtin])
 725       AC_LINK_IFELSE([AC_LANG_SOURCE([[
 726 int main(int argc, char **argv) {
 727   volatile int i = 1;
 728   return __sync_swap (&i, 2);
 729 }
 730 ]])], [
 731         AC_DEFINE(HAVE___SYNC_SWAP, 1, [found __sync_swap builtin])
 732         AC_MSG_RESULT([yes])
 733       ], [
 734         AC_MSG_RESULT([no])
 735       ])
 736
 737     ], [
 738       AC_MSG_RESULT([no])
 739       AC_MSG_FAILURE([stdatomic.h unavailable and $CC has neither __atomic nor __sync builtins])
 740     ])
 741   ])
 742 ])
 743
 744 dnl Utility macro to avoid retyping includes all the time
 745 m4_define([FRR_INCLUDES],
 746 [#ifdef SUNOS_5
 747 #define _XPG4_2
 748 #define __EXTENSIONS__
 749 #endif
 750 #include <stdio.h>
 751 #include <stdlib.h>
 752 #include <stddef.h>
 753 #include <sys/types.h>
 754 /* sys/conf.h depends on param.h on FBSD at least */
 755 #include <sys/param.h>
 756 /* Required for MAXSIG */
 757 #include <signal.h>
 758 #include <sys/socket.h>
 759 #ifdef __APPLE__
 760 # define __APPLE_USE_RFC_3542
 761 #endif
 762 #include <netinet/in.h>
 763 #include <sys/time.h>
 764 #include <time.h>
 765 #include <net/if.h>
 766 ])dnl
 767
 768 dnl Same applies for HAVE_NET_IF_VAR_H, which HAVE_NETINET6_ND6_H and
 769 dnl HAVE_NETINET_IN_VAR_H depend upon. But if_var.h depends on if.h, hence
 770 dnl an additional round for it.
 771
 772 AC_CHECK_HEADERS([net/if_var.h], [], [], FRR_INCLUDES)
 773
 774 m4_define([FRR_INCLUDES],
 775 FRR_INCLUDES
 776 [#if HAVE_NET_IF_VAR_H
 777 # include <net/if_var.h>
 778 #endif
 779 ])dnl
 780
 781 AC_CHECK_HEADERS([netinet/in_var.h \
 782         net/if_dl.h net/netopt.h \
 783         inet/nd.h netinet/ip_icmp.h \
 784         sys/sysctl.h sys/sockio.h kvm.h sys/conf.h],
 785         [], [], FRR_INCLUDES)
 786
 787 AC_CHECK_HEADERS([ucontext.h], [], [],
 788 [#ifndef __USE_GNU
 789 #define __USE_GNU
 790 #endif /* __USE_GNU */
 791 FRR_INCLUDES
 792 ])
 793
 794 m4_define([UCONTEXT_INCLUDES],
 795 [#include <ucontext.h>])dnl
 796
 797 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.uc_regs],
 798   [], [], [UCONTEXT_INCLUDES])
 799 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs],
 800   [AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs.nip],
 801    [], [], [UCONTEXT_INCLUDES])],
 802   [], [UCONTEXT_INCLUDES])
 803 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.gregs],
 804   [], [], [UCONTEXT_INCLUDES])
 805
 806 m4_define([FRR_INCLUDES],
 807 FRR_INCLUDES
 808 [
 809 #include <sys/un.h>
 810 #include <netinet/in_systm.h>
 811 #if HAVE_NETINET_IN_VAR_H
 812 # include <netinet/in_var.h>
 813 #endif
 814 #if HAVE_NET_IF_DL_H
 815 # include <net/if_dl.h>
 816 #endif
 817 #if HAVE_NET_NETOPT_H
 818 # include <net/netopt.h>
 819 #endif
 820 #include <net/route.h>
 821 #if HAVE_INET_ND_H
 822 # include <inet/nd.h>
 823 #endif
 824 #include <arpa/inet.h>
 825 /* Required for IDRP */
 826 #if HAVE_NETINET_IP_ICMP_H
 827 # include <netinet/ip_icmp.h>
 828 #endif
 829 ])dnl
 830
 831 dnl V6 headers are checked below, after we check for v6
 832
 833 AC_MSG_CHECKING([which operating system interface to use])
 834 case "$host_os" in
 835   sunos* | solaris2*)
 836     AC_MSG_RESULT([Solaris])
 837
 838     AC_DEFINE(SUNOS_5, 1, [SunOS 5])
 839     AC_DEFINE(SOLARIS_IPV6, 1, Solaris IPv6)
 840
 841     AC_CHECK_LIB(socket, main)
 842     AC_CHECK_LIB(nsl, main)
 843     AC_CHECK_LIB(umem, main)
 844     AC_CHECK_FUNCS([printstack], [
 845       AC_DEFINE([HAVE_PRINTSTACK],1,[Solaris printstack])
 846       AC_DEFINE([HAVE_STACK_TRACE],1,[Stack symbols decode functionality])
 847     ])
 848     CURSES=-lcurses
 849     SOLARIS="solaris"
 850     ;;
 851   linux*)
 852     AC_MSG_RESULT([Linux])
 853
 854     AC_DEFINE(GNU_LINUX,,GNU Linux)
 855     AC_DEFINE(HAVE_NETLINK,,netlink)
 856     AC_DEFINE(LINUX_IPV6,1,Linux IPv6 stack)
 857
 858     dnl Linux has a compilation problem with mixing
 859     dnl netinet/in.h and linux/in6.h they are not
 860     dnl compatible.  There has been discussion on
 861     dnl how to fix it but no real progress on implementation
 862     dnl when they fix it, remove this
 863     AC_DEFINE(IPV6_MINHOPCOUNT, 73, Linux ipv6 Min Hop Count)
 864
 865     AC_CHECK_DECLS([IFLA_INFO_SLAVE_KIND], [], [], [#include <linux/if_link.h>])
 866     ;;
 867   openbsd*)
 868     AC_MSG_RESULT([OpenBSD])
 869
 870     AC_DEFINE(OPEN_BSD,,OpenBSD)
 871     AC_DEFINE(KAME,1,KAME IPv6)
 872
 873     if test "x${enable_pimd}" != "xno"; then
 874       case "$host_os" in
 875       openbsd6.0)
 876         ;;
 877       openbsd[6-9]*)
 878         AC_MSG_FAILURE([pimd cannot be enabled as PIM support has been removed from OpenBSD 6.1])
 879         ;;
 880       esac
 881     fi
 882     ;;
 883   *)
 884     AC_MSG_RESULT([BSD])
 885
 886     AC_DEFINE(HAVE_NET_RT_IFLIST,,NET_RT_IFLIST)
 887     AC_DEFINE(KAME,1,KAME IPv6)
 888     ;;
 889 esac
 890
 891 AC_SYS_LARGEFILE
 892
 893 dnl ---------------------
 894 dnl Integrated VTY option
 895 dnl ---------------------
 896 case "${enable_vtysh}" in
 897   "no") VTYSH="";;
 898   *)    VTYSH="vtysh";
 899          AC_DEFINE(VTYSH,,VTY shell)
 900 dnl      Vtysh uses libreadline, which looks for termcap functions at
 901 dnl      configure time.  We follow readlines search order.
 902 dnl      The required procedures are in libtermcap on NetBSD, in
 903 dnl      [TODO] on Linux, and in [TODO] on Solaris.
 904          AC_CHECK_LIB(termcap, tputs, LIBREADLINE="$LIBREADLINE -ltermcap",
 905            [AC_CHECK_LIB(tinfo, tputs, LIBREADLINE="$LIBREADLINE -ltinfo",
 906              [AC_CHECK_LIB(curses, tputs, LIBREADLINE="$LIBREADLINE -lcurses",
 907                [AC_CHECK_LIB(ncurses, tputs,
 908                              LIBREADLINE="$LIBREADLINE -lncurses")]
 909               )]
 910             )]
 911           )
 912          AC_CHECK_LIB(readline, main, LIBREADLINE="-lreadline $LIBREADLINE",,
 913                       "$LIBREADLINE")
 914          if test $ac_cv_lib_readline_main = no; then
 915            AC_MSG_ERROR([vtysh needs libreadline but was not found and usable on your system.])
 916          fi
 917          AC_CHECK_HEADER(readline/history.h)
 918          if test $ac_cv_header_readline_history_h = no;then
 919            AC_MSG_ERROR([readline is too old to have readline/history.h, please update to the latest readline library.])
 920          fi
 921          AC_CHECK_LIB(readline, rl_completion_matches,
 922                       LIBREADLINE="$LIBREADLINE",, "$LIBREADLINE")
 923          if test $ac_cv_lib_readline_rl_completion_matches = no; then
 924            AC_DEFINE(rl_completion_matches,completion_matches,Old readline)
 925          fi
 926          ;;
 927 esac
 928 AC_SUBST(LIBREADLINE)
 929 AM_CONDITIONAL(VTYSH, test "x$VTYSH" = "xvtysh")
 930
 931 dnl ----------
 932 dnl PAM module
 933 dnl
 934 dnl FRR detects the PAM library it is built against by checking for a
 935 dnl functional pam_misc.h (Linux-PAM) or openpam.h (OpenPAM) header. pam_misc.h
 936 dnl is known to #include pam_appl.h, the standard header of a PAM library, and
 937 dnl openpam.h doesn't do that, although depends on the header too. Hence a
 938 dnl little assistance to AC_CHECK_HEADER is necessary for the proper detection
 939 dnl of OpenPAM.
 940 dnl ----------
 941 if test "$with_libpam" = "yes"; then
 942   AC_CHECK_HEADER([security/pam_misc.h],
 943     [AC_DEFINE(HAVE_PAM_MISC_H,,Have pam_misc.h)
 944      AC_DEFINE(PAM_CONV_FUNC,misc_conv,Have misc_conv)
 945      pam_conv_func="misc_conv"
 946     ],
 947     [], FRR_INCLUDES)
 948   AC_CHECK_HEADER([security/openpam.h],
 949     [AC_DEFINE(HAVE_OPENPAM_H,,Have openpam.h)
 950      AC_DEFINE(PAM_CONV_FUNC,openpam_ttyconv,Have openpam_ttyconv)
 951      pam_conv_func="openpam_ttyconv"
 952     ],
 953     [], FRR_INCLUDES[#include <security/pam_appl.h>])
 954   if test -z "$ac_cv_header_security_pam_misc_h$ac_cv_header_security_openpam_h" ; then
 955     AC_MSG_WARN([*** pam support will not be built ***])
 956     with_libpam="no"
 957   fi
 958 fi
 959
 960 if test "$with_libpam" = "yes"; then
 961 dnl took this test from proftpds configure.in and suited to our needs
 962 dnl -------------------------------------------------------------------------
 963 dnl
 964 dnl This next check looks funky due to a linker problem with some versions
 965 dnl of the PAM library.  Prior to 0.72 release, the Linux PAM shared library
 966 dnl omitted requiring libdl linking information. PAM-0.72 or better ships
 967 dnl with RedHat 6.2 and Debian 2.2 or better.
 968 AC_CHECK_LIB(pam, pam_start,
 969   [AC_CHECK_LIB(pam, $pam_conv_func,
 970     [AC_DEFINE(USE_PAM,,Use PAM for authentication)
 971      LIBPAM="-lpam"],
 972     [AC_DEFINE(USE_PAM,,Use PAM for authentication)
 973      LIBPAM="-lpam -lpam_misc"]
 974     )
 975   ],
 976
 977   [AC_CHECK_LIB(pam, pam_end,
 978     [AC_CHECK_LIB(pam, $pam_conv_func,
 979       [AC_DEFINE(USE_PAM,,Use PAM for authentication)
 980        LIBPAM="-lpam -ldl"],
 981       [AC_DEFINE(USE_PAM,,Use PAM for authentication)
 982        LIBPAM="-lpam -ldl -lpam_misc"]
 983      )
 984   ],AC_MSG_WARN([*** pam support will not be built ***]),
 985   [-ldl])
 986   ]
 987 )
 988 fi
 989 AC_SUBST(LIBPAM)
 990
 991 dnl -------------------------------
 992 dnl Endian-ness check
 993 dnl -------------------------------
 994 AC_WORDS_BIGENDIAN
 995
 996 dnl -------------------------------
 997 dnl check the size in byte of the C
 998 dnl -------------------------------
 999 dnl AC_CHECK_SIZEOF(char)
1000 dnl AC_CHECK_SIZEOF(int)
1001 dnl AC_CHECK_SIZEOF(short)
1002 dnl AC_CHECK_SIZEOF(long)
1003
1004 dnl ----------------------------
1005 dnl check existance of functions
1006 dnl ----------------------------
1007 AC_FUNC_FNMATCH
1008 AC_FUNC_FORK
1009 AC_FUNC_MKTIME
1010 AC_FUNC_STAT
1011
1012 dnl -------------------------------
1013 dnl bgpd needs pow() and hence libm
1014 dnl -------------------------------
1015 TMPLIBS="$LIBS"
1016 AC_CHECK_HEADER([math.h],
1017   [AC_CHECK_LIB([m], [pow],
1018     [LIBM="-lm"
1019      LIBS="$LIBS $LIBM"
1020      AC_CHECK_FUNCS(pow,[],[LIBM=""])
1021     ])
1022 ])
1023 if test x"$LIBM" = x ; then
1024   AC_MSG_WARN([Unable to find working pow function - bgpd may not link])
1025 fi
1026 LIBS="$TMPLIBS"
1027 AC_SUBST(LIBM)
1028
1029 dnl ---------------
1030 dnl other functions
1031 dnl ---------------
1032 AC_CHECK_FUNCS([ \
1033         strlcat strlcpy \
1034         getgrouplist])
1035
1036 AC_CHECK_HEADER([asm-generic/unistd.h],
1037                 [AC_CHECK_DECL(__NR_setns,
1038                                AC_DEFINE(HAVE_NETNS,, Have netns),,
1039                                FRR_INCLUDES [#include <asm-generic/unistd.h>
1040                                ])
1041                  AC_CHECK_FUNCS(setns)]
1042                )
1043
1044 dnl --------------------------
1045 dnl Determine IS-IS I/O method
1046 dnl --------------------------
1047 AC_DEFINE(ISIS_METHOD_PFPACKET, 1, [ constant value for isis method pfpacket ])
1048 AC_DEFINE(ISIS_METHOD_DLPI,     2, [ constant value for isis method dlpi ])
1049 AC_DEFINE(ISIS_METHOD_BPF,      3, [ constant value for isis method bpf ])
1050 AC_CHECK_HEADER(net/bpf.h)
1051 AC_CHECK_HEADER(sys/dlpi.h)
1052 AC_MSG_CHECKING(zebra IS-IS I/O method)
1053
1054 case "$host_os" in
1055   linux*)
1056     AC_MSG_RESULT(pfpacket)
1057     ISIS_METHOD_MACRO="ISIS_METHOD_PFPACKET"
1058     ;;
1059   solaris* | sunos*)
1060     AC_MSG_RESULT(DLPI)
1061     ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1062     ;;
1063   *)
1064     if test $ac_cv_header_net_bpf_h = no; then
1065       if test $ac_cv_header_sys_dlpi_h = no; then
1066         AC_MSG_RESULT(none)
1067         if test "${enable_isisd}" = yes; then
1068           AC_MSG_FAILURE([IS-IS support requested but no packet backend found])
1069         fi
1070         AC_MSG_WARN([*** IS-IS support will not be built ***])
1071         enable_isisd="no"
1072       else
1073         AC_MSG_RESULT(DLPI)
1074       fi
1075       ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1076     else
1077       AC_MSG_RESULT(BPF)
1078       ISIS_METHOD_MACRO="ISIS_METHOD_BPF"
1079     fi
1080     ;;
1081 esac
1082 AC_DEFINE_UNQUOTED(ISIS_METHOD, $ISIS_METHOD_MACRO, [ selected method for isis, == one of the constants ])
1083
1084 dnl ------------------------------------
1085 dnl check for broken CMSG_FIRSTHDR macro
1086 dnl ------------------------------------
1087 AC_MSG_CHECKING(for broken CMSG_FIRSTHDR)
1088 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1089 #ifdef SUNOS_5
1090 #define _XPG4_2
1091 #define __EXTENSIONS__
1092 #endif
1093 #include <stdlib.h>
1094 #include <sys/types.h>
1095 #include <sys/socket.h>
1096
1097 main()
1098 {
1099   struct msghdr msg;
1100   char buf[4];
1101
1102   msg.msg_control = buf;
1103   msg.msg_controllen = 0;
1104
1105   if (CMSG_FIRSTHDR(&msg) != NULL)
1106     exit(0);
1107   exit (1);
1108 }]])],[AC_MSG_RESULT(yes - using workaround) AC_DEFINE(HAVE_BROKEN_CMSG_FIRSTHDR,,Broken CMSG_FIRSTHDR)],
1109 [AC_MSG_RESULT(no)],[AC_MSG_RESULT(no)])
1110
1111 dnl ---------------------------------------------------------------
1112 dnl figure out how to specify an interface in multicast sockets API
1113 dnl ---------------------------------------------------------------
1114 AC_CHECK_MEMBERS([struct ip_mreqn.imr_ifindex], [], [], FRR_INCLUDES)
1115
1116 AC_CHECK_HEADERS([linux/mroute.h], [], [],[
1117         #include <sys/socket.h>
1118         #include <netinet/in.h>
1119         #define _LINUX_IN_H             /* For Linux <= 2.6.25 */
1120         #include <linux/types.h>
1121 ])
1122
1123 m4_define([FRR_INCLUDES],
1124 FRR_INCLUDES
1125 [#if HAVE_LINUX_MROUTE_H
1126 # include <linux/mroute.h>
1127 #endif
1128 ])dnl
1129
1130 AC_CHECK_HEADERS([netinet/ip_mroute.h], [], [],[
1131         #include <sys/socket.h>
1132         #include <sys/types.h>
1133         #include <netinet/in.h>
1134         #include <net/route.h>
1135 ])
1136
1137 m4_define([FRR_INCLUDES],
1138 FRR_INCLUDES
1139 [#if HAVE_NETINET_IP_MROUTE_H
1140 # include <netinet/ip_mroute.h>
1141 #endif
1142 ])dnl
1143
1144 AC_MSG_CHECKING([for BSD struct ip_mreq hack])
1145 AC_TRY_COMPILE([#include <sys/param.h>],
1146 [#if (defined(__FreeBSD__) && ((__FreeBSD_version >= 500022 && __FreeBSD_version < 700000) || (__FreeBSD_version < 500000 && __FreeBSD_version >= 440000))) || (defined(__NetBSD__) && defined(__NetBSD_Version__) && __NetBSD_Version__ >= 106010000) || defined(__OpenBSD__) || defined(__APPLE__) || defined(__DragonFly__) || defined(__sun)
1147   return (0);
1148 #else
1149   #error No support for BSD struct ip_mreq hack detected
1150 #endif],[AC_MSG_RESULT(yes)
1151 AC_DEFINE(HAVE_BSD_STRUCT_IP_MREQ_HACK,,[Can pass ifindex in struct ip_mreq])],
1152 AC_MSG_RESULT(no))
1153
1154 AC_MSG_CHECKING([for RFC3678 protocol-independed API])
1155 AC_TRY_COMPILE([
1156 #include <sys/types.h>
1157 #include <netinet/in.h>
1158 ], [struct group_req gr; int sock; setsockopt(sock, IPPROTO_IP, MCAST_JOIN_GROUP, (void*)&gr, sizeof(gr));
1159 ], [AC_MSG_RESULT(yes)
1160 AC_DEFINE(HAVE_RFC3678,1,[Have RFC3678 protocol-independed API])],
1161 AC_MSG_RESULT(no))
1162
1163 dnl ---------------------------------------------------------------
1164 dnl figure out how to check link-state
1165 dnl ---------------------------------------------------------------
1166 AC_CHECK_HEADER( [net/if_media.h],
1167   [m4_define([LINK_DETECT_INCLUDES],
1168     FRR_INCLUDES
1169     [#include <net/if_media.h>
1170   ])
1171   AC_CHECK_MEMBERS( [struct ifmediareq.ifm_status],
1172     AC_DEFINE(HAVE_BSD_LINK_DETECT,,[BSD link-detect]),
1173     [], LINK_DETECT_INCLUDES)],
1174   [],
1175   FRR_INCLUDES)
1176
1177 dnl ---------------------------------------------------------------
1178 dnl Additional, newer way to check link-state using ifi_link_state.
1179 dnl Not available in all BSD's when ifmediareq available
1180 dnl ---------------------------------------------------------------
1181 AC_CHECK_MEMBERS([struct if_data.ifi_link_state],
1182   AC_DEFINE(HAVE_BSD_IFI_LINK_STATE,,[BSD ifi_link_state available]),
1183   [], FRR_INCLUDES)
1184
1185 dnl ------------------------
1186 dnl TCP_MD5SIG socket option
1187 dnl ------------------------
1188
1189 AC_CHECK_HEADER([netinet/tcp.h],
1190    [m4_define([MD5_INCLUDES],
1191       FRR_INCLUDES
1192       [#include <netinet/tcp.h>
1193     ])
1194     AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)],
1195    [],
1196    FRR_INCLUDES)
1197 if test $ac_cv_have_decl_TCP_MD5SIG = no; then
1198   AC_CHECK_HEADER([linux/tcp.h],
1199        [m4_define([MD5_INCLUDES],
1200           FRR_INCLUDES
1201           [#include <linux/tcp.h>
1202         ])
1203        AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)])
1204 fi
1205
1206 dnl ----------------------------------------------------------------------------
1207 dnl figure out if domainname is available in the utsname struct (GNU extension).
1208 dnl ----------------------------------------------------------------------------
1209 AC_CHECK_MEMBERS([struct utsname.domainname], [], [], [#include <sys/utsname.h>])
1210
1211 dnl ------------------
1212 dnl IPv6 header checks
1213 dnl ------------------
1214 AC_CHECK_HEADERS([netinet6/in6.h netinet/in6_var.h \
1215         netinet6/in6_var.h netinet6/nd6.h], [], [],
1216         FRR_INCLUDES)
1217
1218 m4_define([FRR_INCLUDES],dnl
1219 FRR_INCLUDES
1220 [#if HAVE_NETINET6_IN6_H
1221 #include <netinet6/in6.h>
1222 #endif
1223 #if HAVE_NETINET_IN6_VAR_H
1224 #include <netinet/in6_var.h>
1225 #endif
1226 #include <netinet/icmp6.h>
1227 #if HAVE_NETINET6_IN6_VAR_H
1228 # include <netinet6/in6_var.h>
1229 #endif
1230 #if HAVE_NETINET6_ND6_H
1231 # include <netinet6/nd6.h>
1232 #endif
1233 ])dnl
1234
1235 dnl disable doc check
1236 if test "${enable_doc}" = "no";then
1237   DOC=""
1238 else
1239   DOC="doc"
1240 fi
1241
1242 dnl --------------------
1243 dnl Daemon disable check
1244 dnl --------------------
1245 AM_CONDITIONAL(ZEBRA, test "${enable_zebra}" != "no")
1246
1247 if test "${enable_bgpd}" = "no";then
1248   BGPD=""
1249 else
1250   BGPD="bgpd"
1251 fi
1252 AM_CONDITIONAL(BGPD, test "x$BGPD" = "xbgpd")
1253
1254 AM_CONDITIONAL(RIPD, test "${enable_ripd}" != "no")
1255 AM_CONDITIONAL(OSPFD, test "${enable_ospfd}" != "no")
1256 AM_CONDITIONAL(LDPD, test "${enable_ldpd}" != "no")
1257
1258 AS_IF([test "${enable_ldpd}" != "no"], [
1259   AC_DEFINE(HAVE_LDPD, 1, ldpd)
1260 ])
1261
1262 NHRPD=""
1263 case "$host_os" in
1264   linux*)
1265     if test "${enable_nhrpd}" != "no"; then
1266       NHRPD="nhrpd"
1267     fi
1268     ;;
1269   *)
1270     if test "${enable_nhrpd}" = "yes"; then
1271       AC_MSG_ERROR([nhrpd requires kernel APIs that are only present on Linux.])
1272     fi
1273     ;;
1274 esac
1275 AM_CONDITIONAL(NHRPD, test "x$NHRPD" = "xnhrpd")
1276
1277 if test "${enable_eigrpd}" = "no";then
1278   EIGRPD=""
1279 else
1280   EIGRPD="eigrpd"
1281 fi
1282 AM_CONDITIONAL(EIGRPD, test "x$EIGRPD" = "xeigrpd")
1283
1284 if test "${enable_watchfrr}" = "no";then
1285   WATCHFRR=""
1286 else
1287   WATCHFRR="watchfrr"
1288 fi
1289 AM_CONDITIONAL(WATCHFRR, test "x$WATCHFRR" = "xwatchfrr")
1290
1291 OSPFCLIENT=""
1292 if test "${enable_ospfapi}" != "no";then
1293     AC_DEFINE(SUPPORT_OSPF_API,,OSPFAPI)
1294
1295   if test "${enable_ospfclient}" != "no";then
1296       OSPFCLIENT="ospfclient"
1297   fi
1298 fi
1299
1300 AM_CONDITIONAL(OSPFCLIENT, test "x$OSPFCLIENT" = "xospfclient")
1301
1302 AM_CONDITIONAL(RIPNGD, test "${enable_ripngd}" != "no")
1303
1304 case "${enable_babeld}" in
1305   "no" ) BABELD="";;
1306   *    ) BABELD="babeld";;
1307 esac
1308 AM_CONDITIONAL(BABELD, test "x$BABELD" = "xbabeld")
1309
1310 AM_CONDITIONAL(OSPF6D, test "${enable_ospf6d}" != "no")
1311 AM_CONDITIONAL(ISISD, test "${enable_isisd}" != "no")
1312
1313 case "${enable_pimd}" in
1314   "no" ) PIMD="";;
1315   *    ) PIMD="pimd";;
1316 esac
1317 AM_CONDITIONAL(PIMD, test "x$PIMD" = "xpimd")
1318
1319 if test "${enable_bgp_announce}" = "no";then
1320   AC_DEFINE(DISABLE_BGP_ANNOUNCE,1,Disable BGP installation to zebra)
1321 else
1322   AC_DEFINE(DISABLE_BGP_ANNOUNCE,0,Disable BGP installation to zebra)
1323 fi
1324
1325 if test "${with_rfp_path}" = "yes" || test x"${with_rfp_path}" = x""; then
1326   with_rfp_path="bgpd/rfp-example"
1327 fi
1328 if test "${with_rfp_path}" != "no"; then
1329   VNC_RFP_PATH="${with_rfp_path}"
1330   AC_SUBST(VNC_RFP_PATH)
1331 fi
1332
1333 if test "${enable_bgp_vnc}" != "no";then
1334   AC_DEFINE(ENABLE_BGP_VNC,1,Enable BGP VNC support)
1335   RFPTEST="${with_rfp_path}/rfptest"
1336   LIBRFP="${with_rfp_path}/librfp"
1337   RFPINC="${with_rfp_path}/librfp"
1338 else
1339   RFPTEST=
1340   LIBRFP=
1341   RFPINC="bgpd/rfp-example/librfp"
1342 fi
1343 # set
1344 AM_CONDITIONAL([ENABLE_BGP_VNC], [test x${enable_bgp_vnc} != xno])
1345
1346 AC_SUBST(DOC)
1347 AC_SUBST(RFPTEST)
1348 AC_SUBST(LIBRFP)
1349 AC_SUBST(RFPINC)
1350 AC_SUBST(BABELD)
1351 AC_SUBST(BGPD)
1352 AC_SUBST(EIGRPD)
1353 AC_SUBST(WATCHFRR)
1354 AC_SUBST(ISISD)
1355 AC_SUBST(PIMD)
1356 AC_SUBST(SOLARIS)
1357 AC_SUBST(VTYSH)
1358 AC_SUBST(CURSES)
1359 AC_CHECK_LIB(crypt, crypt, [],
1360                     [AC_CHECK_LIB(crypto, DES_crypt)])
1361 AC_CHECK_LIB(resolv, res_init)
1362
1363 dnl ---------------------------
1364 dnl check system has PCRE regexp
1365 dnl ---------------------------
1366 if test "x$enable_pcreposix" = "xyes"; then
1367   AC_CHECK_LIB(pcreposix, regexec, [], [
1368     AC_MSG_ERROR([--enable-pcreposix given but unable to find libpcreposix])
1369   ])
1370 fi
1371 AC_SUBST(HAVE_LIBPCREPOSIX)
1372
1373 dnl ------------------
1374 dnl check C-Ares library
1375 dnl ------------------
1376 if test "${NHRPD}" != ""; then
1377   PKG_CHECK_MODULES([CARES], [libcares], , [
1378     AC_MSG_ERROR([trying to build nhrpd, but libcares not found. install c-ares and its -dev headers.])
1379   ])
1380 fi
1381
1382
1383 dnl ------------------
1384 dnl check Net-SNMP library
1385 dnl ------------------
1386 if test "${enable_snmp}" != ""; then
1387    AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], [no])
1388    if test x"$NETSNMP_CONFIG" = x"no"; then
1389       AC_MSG_ERROR([--enable-snmp given but unable to find net-snmp-config])
1390    fi
1391    SNMP_LIBS="`${NETSNMP_CONFIG} --agent-libs`"
1392    SNMP_CFLAGS="`${NETSNMP_CONFIG} --base-cflags`"
1393    AC_MSG_CHECKING([whether we can link to Net-SNMP])
1394    AC_LINK_IFELSE_FLAGS([$SNMP_CFLAGS], [$SNMP_LIBS], [AC_LANG_PROGRAM([
1395 int main(void);
1396 ],
1397 [
1398 {
1399   return 0;
1400 }
1401 ])], [
1402      AC_MSG_ERROR([--enable-snmp given but not usable])])
1403    case "${enable_snmp}" in
1404      yes)
1405       SNMP_METHOD=agentx
1406       ;;
1407      smux|agentx)
1408       SNMP_METHOD="${enable_snmp}"
1409       ;;
1410      *)
1411       AC_MSG_ERROR([--enable-snmp given with an unknown method (${enable_snmp}). Use smux or agentx])
1412       ;;
1413    esac
1414    AH_TEMPLATE([SNMP_SMUX], [Use SNMP SMUX to interface with snmpd])
1415    AH_TEMPLATE([SNMP_AGENTX], [Use SNMP AgentX to interface with snmpd])
1416    AC_DEFINE_UNQUOTED(AS_TR_CPP(SNMP_${SNMP_METHOD}),,SNMP method to interface with snmpd)
1417 fi
1418 AM_CONDITIONAL([SNMP], [test "x${SNMP_METHOD}" != "x"])
1419 AC_SUBST(SNMP_LIBS)
1420 AC_SUBST(SNMP_CFLAGS)
1421
1422 dnl ---------------
1423 dnl math
1424 dnl ---------------
1425 AC_SEARCH_LIBS([sqrt], [m])
1426
1427 dnl ---------------
1428 dnl dlopen & dlinfo
1429 dnl ---------------
1430 AC_SEARCH_LIBS(dlopen, [dl dld], [], [
1431   AC_MSG_ERROR([unable to find the dlopen()])
1432 ])
1433
1434 AC_CHECK_HEADERS([link.h])
1435
1436 AC_MSG_CHECKING([for dlinfo(RTLD_DI_ORIGIN)])
1437 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1438 #include <stdlib.h>
1439 #ifdef HAVE_LINK_H
1440 #include <link.h>
1441 #endif
1442 #include <dlfcn.h>
1443 ]], [[
1444   char origin[1];
1445   dlinfo (NULL, RTLD_DI_ORIGIN, &origin);
1446 ]])], [
1447   AC_MSG_RESULT(yes)
1448   AC_DEFINE(HAVE_DLINFO_ORIGIN, 1, [Have dlinfo RTLD_DI_ORIGIN])
1449 ], [
1450   AC_MSG_RESULT(no)
1451 ])
1452
1453 AC_MSG_CHECKING([for dlinfo(RTLD_DI_LINKMAP)])
1454 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1455 #include <stdlib.h>
1456 #ifdef HAVE_LINK_H
1457 #include <link.h>
1458 #endif
1459 #include <dlfcn.h>
1460 ]], [[
1461   struct link_map *lm = NULL;
1462   dlinfo (NULL, RTLD_DI_LINKMAP, &lm);
1463 ]])], [
1464   AC_MSG_RESULT(yes)
1465   AC_DEFINE(HAVE_DLINFO_LINKMAP, 1, [Have dlinfo RTLD_DI_LINKMAP])
1466 ], [
1467   AC_MSG_RESULT(no)
1468 ])
1469
1470
1471 AM_CONDITIONAL(SNMP, test "x$SNMP_METHOD" = "xagentx")
1472
1473 dnl ---------------------------
1474 dnl sockaddr and netinet checks
1475 dnl ---------------------------
1476 AC_CHECK_TYPES([
1477         struct sockaddr_dl,
1478         struct vifctl, struct mfcctl, struct sioc_sg_req,
1479         vifi_t, struct sioc_vif_req, struct igmpmsg,
1480         struct ifaliasreq, struct if6_aliasreq, struct in6_aliasreq,
1481         struct nd_opt_adv_interval, struct rt_addrinfo,
1482         struct nd_opt_homeagent_info, struct nd_opt_adv_interval],
1483         [], [], FRR_INCLUDES)
1484
1485 AC_CHECK_MEMBERS([struct sockaddr.sa_len,
1486         struct sockaddr_in.sin_len, struct sockaddr_un.sun_len,
1487         struct sockaddr_dl.sdl_len,
1488         struct if6_aliasreq.ifra_lifetime,
1489         struct nd_opt_adv_interval.nd_opt_ai_type],
1490         [], [], FRR_INCLUDES)
1491
1492 dnl ---------------------------
1493 dnl IRDP/pktinfo/icmphdr checks
1494 dnl ---------------------------
1495 AC_CHECK_TYPES([struct in_pktinfo],
1496  [AC_CHECK_TYPES([struct icmphdr],
1497    [if test "${enable_irdp}" != "no"; then
1498       AC_DEFINE(HAVE_IRDP,, IRDP)
1499     fi],
1500    [if test "${enable_irdp}" = "yes"; then
1501       AC_MSG_ERROR(['IRDP requires in_pktinfo at the moment!'])
1502     fi], [FRR_INCLUDES])],
1503  [if test "${enable_irdp}" = "yes"; then
1504     AC_MSG_ERROR(['IRDP requires in_pktinfo at the moment!'])
1505   fi], [FRR_INCLUDES])
1506
1507 dnl -----------------------
1508 dnl checking for IP_PKTINFO
1509 dnl -----------------------
1510 AC_MSG_CHECKING(for IP_PKTINFO)
1511 AC_TRY_COMPILE([#include <netdb.h>], [
1512   int opt = IP_PKTINFO;
1513 ], [
1514   AC_MSG_RESULT(yes)
1515   AC_DEFINE(HAVE_IP_PKTINFO, 1, [Have IP_PKTINFO])
1516 ], [
1517   AC_MSG_RESULT(no)
1518 ])
1519
1520 dnl ---------------------------
1521 dnl checking for IP_RECVDSTADDR
1522 dnl ---------------------------
1523 AC_MSG_CHECKING(for IP_RECVDSTADDR)
1524 AC_TRY_COMPILE([#include <netinet/in.h>], [
1525   int opt = IP_RECVDSTADDR;
1526 ], [
1527   AC_MSG_RESULT(yes)
1528   AC_DEFINE(HAVE_IP_RECVDSTADDR, 1, [Have IP_RECVDSTADDR])
1529 ], [
1530   AC_MSG_RESULT(no)
1531 ])
1532
1533 dnl ----------------------
1534 dnl checking for IP_RECVIF
1535 dnl ----------------------
1536 AC_MSG_CHECKING(for IP_RECVIF)
1537 AC_TRY_COMPILE([#include <netinet/in.h>], [
1538   int opt = IP_RECVIF;
1539 ], [
1540   AC_MSG_RESULT(yes)
1541   AC_DEFINE(HAVE_IP_RECVIF, 1, [Have IP_RECVIF])
1542 ], [
1543   AC_MSG_RESULT(no)
1544 ])
1545
1546 dnl ----------------------
1547 dnl checking for SO_BINDANY
1548 dnl ----------------------
1549 AC_MSG_CHECKING(for SO_BINDANY)
1550 AC_TRY_COMPILE([#include <sys/socket.h>], [
1551   int opt = SO_BINDANY;
1552 ], [
1553   AC_MSG_RESULT(yes)
1554   AC_DEFINE(HAVE_SO_BINDANY, 1, [Have SO_BINDANY])
1555 ], [
1556   AC_MSG_RESULT(no)
1557 ])
1558
1559 dnl ----------------------
1560 dnl checking for IP_FREEBIND
1561 dnl ----------------------
1562 AC_MSG_CHECKING(for IP_FREEBIND)
1563 AC_TRY_COMPILE([#include <netinet/in.h>], [
1564   int opt = IP_FREEBIND;
1565 ], [
1566   AC_MSG_RESULT(yes)
1567   AC_DEFINE(HAVE_IP_FREEBIND, 1, [Have IP_FREEBIND])
1568 ], [
1569   AC_MSG_RESULT(no)
1570 ])
1571
1572 dnl --------------------------------------
1573 dnl checking for be32dec existence or not
1574 dnl --------------------------------------
1575 AC_CHECK_DECLS([be32enc, be32dec], [], [],
1576                [#include <sys/endian.h>])
1577
1578 dnl --------------------------------------
1579 dnl checking for clock_time monotonic struct and call
1580 dnl --------------------------------------
1581 AC_CHECK_DECL(CLOCK_MONOTONIC,
1582         [AC_CHECK_LIB(rt, clock_gettime, [LIBS="$LIBS -lrt"])
1583          AC_DEFINE(HAVE_CLOCK_MONOTONIC,, Have monotonic clock)
1584 ], [AC_MSG_RESULT(no)], [FRR_INCLUDES])
1585
1586 dnl --------------------------------------
1587 dnl checking for flex and bison
1588 dnl --------------------------------------
1589
1590 AM_PROG_LEX
1591 AC_MSG_CHECKING(version of flex)
1592 frr_ac_flex_version="$(eval $LEX -V | grep flex | head -n 1)"
1593 frr_ac_flex_version="${frr_ac_flex_version##* }"
1594 AC_MSG_RESULT([$frr_ac_flex_version])
1595 AX_COMPARE_VERSION([$frr_ac_flex_version], [lt], [2.5.20], [
1596   LEX="$SHELL $missing_dir/missing flex"
1597   if test -f "${srcdir}/lib/command_lex.c" -a -f "${srcdir}/lib/command_lex.h"; then
1598     AC_MSG_WARN([using pregenerated flex output files])
1599   else
1600     AC_MSG_ERROR([flex failure and pregenerated files not included (probably a git build)])
1601   fi
1602   AC_SUBST([LEX_OUTPUT_ROOT], [lex.yy])
1603   AC_SUBST([LEXLIB], [''])
1604 ])
1605
1606 AC_PROG_YACC
1607 dnl thanks GNU bison for this b*llshit...
1608 AC_MSG_CHECKING(version of bison)
1609 frr_ac_bison_version="$(eval $YACC -V | grep bison | head -n 1)"
1610 frr_ac_bison_version="${frr_ac_bison_version##* }"
1611 frr_ac_bison_missing="false"
1612 case "x${frr_ac_bison_version}" in
1613   x2.7*)
1614     BISON_OPENBRACE='"'
1615     BISON_CLOSEBRACE='"'
1616     BISON_VERBOSE=''
1617     AC_MSG_RESULT([$frr_ac_bison_version - 2.7 or older])
1618     ;;
1619   x2.*|x1.*)
1620     AC_MSG_RESULT([$frr_ac_bison_version])
1621     AC_MSG_WARN([installed bison is too old.  Please install GNU bison 2.7.x or newer.])
1622     frr_ac_bison_missing="true"
1623     ;;
1624   x)
1625     AC_MSG_RESULT([none])
1626     AC_MSG_WARN([could not determine bison version.  Please install GNU bison 2.7.x or newer.])
1627     frr_ac_bison_missing="true"
1628     ;;
1629   *)
1630     BISON_OPENBRACE='{'
1631     BISON_CLOSEBRACE='}'
1632     BISON_VERBOSE='-Dparse.error=verbose'
1633     AC_MSG_RESULT([$frr_ac_bison_version - 3.0 or newer])
1634     ;;
1635 esac
1636 AC_SUBST(BISON_OPENBRACE)
1637 AC_SUBST(BISON_CLOSEBRACE)
1638 AC_SUBST(BISON_VERBOSE)
1639
1640 if $frr_ac_bison_missing; then
1641   YACC="$SHELL $missing_dir/missing bison -y"
1642   if test -f "${srcdir}/lib/command_parse.c" -a -f "${srcdir}/lib/command_parse.h"; then
1643     AC_MSG_WARN([using pregenerated bison output files])
1644   else
1645     AC_MSG_ERROR([bison failure and pregenerated files not included (probably a git build)])
1646   fi
1647 fi
1648
1649 dnl -------------------
1650 dnl capabilities checks
1651 dnl -------------------
1652 if test "${enable_capabilities}" != "no"; then
1653   AC_MSG_CHECKING(whether prctl PR_SET_KEEPCAPS is available)
1654   AC_TRY_COMPILE([#include <sys/prctl.h>],[prctl(PR_SET_KEEPCAPS, 1, 0, 0, 0);],
1655     [AC_MSG_RESULT(yes)
1656      AC_DEFINE(HAVE_PR_SET_KEEPCAPS,,prctl)
1657      frr_ac_keepcaps="yes"],
1658      AC_MSG_RESULT(no)
1659   )
1660   if test x"${frr_ac_keepcaps}" = x"yes"; then
1661     AC_CHECK_HEADERS(sys/capability.h)
1662   fi
1663   if test x"${ac_cv_header_sys_capability_h}" = x"yes"; then
1664     AC_CHECK_LIB(cap, cap_init,
1665       [AC_DEFINE(HAVE_LCAPS,1,Capabilities)
1666        LIBCAP="-lcap"
1667        frr_ac_lcaps="yes"]
1668     )
1669   else
1670     AC_CHECK_HEADERS(priv.h,
1671      [AC_MSG_CHECKING(Solaris style privileges are available)
1672       AC_TRY_COMPILE([#include <priv.h>],[getpflags(PRIV_AWARE);],
1673           [AC_MSG_RESULT(yes)
1674            AC_DEFINE(HAVE_SOLARIS_CAPABILITIES,1,getpflags)
1675            frr_ac_scaps="yes"],
1676            AC_MSG_RESULT(no)
1677       )
1678      ]
1679    )
1680   fi
1681   if test x"${frr_ac_scaps}" = x"yes" \
1682        -o x"${frr_ac_lcaps}" = x"yes"; then
1683     AC_DEFINE(HAVE_CAPABILITIES,1,capabilities)
1684   fi
1685 fi
1686 AC_SUBST(LIBCAP)
1687
1688 dnl ---------------------------
1689 dnl check for glibc 'backtrace'
1690 dnl ---------------------------
1691 if test x"${enable_backtrace}" != x"no" ; then
1692   backtrace_ok=no
1693   AC_CHECK_HEADER([execinfo.h], [
1694     AC_SEARCH_LIBS([backtrace], [execinfo], [
1695       AC_DEFINE(HAVE_GLIBC_BACKTRACE,,[Glibc backtrace])
1696       AC_DEFINE(HAVE_STACK_TRACE,,[Stack symbol decoding])
1697       backtrace_ok=yes
1698     ],, [-lm])
1699   ])
1700
1701   if test x"${enable_backtrace}" = x"yes" -a x"${backtrace_ok}" = x"no"; then
1702     dnl user explicitly requested backtrace but we failed to find support
1703     AC_MSG_FAILURE([failed to find backtrace support])
1704   fi
1705 fi
1706
1707 dnl -----------------------------------------
1708 dnl check for malloc mallinfo struct and call
1709 dnl this must try and link using LIBS, in
1710 dnl order to check no alternative allocator
1711 dnl has been specified, which might not provide
1712 dnl mallinfo, e.g. such as Umem on Solaris.
1713 dnl -----------------------------------------
1714 AC_CHECK_HEADER([malloc.h],
1715  [AC_MSG_CHECKING(whether mallinfo is available)
1716   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <malloc.h>]],
1717                         [[struct mallinfo ac_x; ac_x = mallinfo ();]])],
1718       [AC_MSG_RESULT(yes)
1719        AC_DEFINE(HAVE_MALLINFO,,mallinfo)],
1720        AC_MSG_RESULT(no)
1721   )
1722  ], [], FRR_INCLUDES)
1723
1724 dnl ----------
1725 dnl configure date
1726 dnl ----------
1727 CONFDATE=`date '+%Y%m%d'`
1728 AC_SUBST(CONFDATE)
1729
1730 dnl ------------------------------
1731 dnl set paths for state directory
1732 dnl ------------------------------
1733 AC_MSG_CHECKING(directory to use for state file)
1734 if test "${prefix}" = "NONE"; then
1735   frr_statedir_prefix="";
1736 else
1737   frr_statedir_prefix=${prefix}
1738 fi
1739 if test "${localstatedir}" = '${prefix}/var'; then
1740   for FRR_STATE_DIR in ${frr_statedir_prefix}/var/run dnl
1741                         ${frr_statedir_prefix}/var/adm dnl
1742                         ${frr_statedir_prefix}/etc dnl
1743                         /var/run        dnl
1744                         /var/adm        dnl
1745                         /etc            dnl
1746                         /dev/null;
1747   do
1748     test -d $FRR_STATE_DIR && break
1749   done
1750   frr_statedir=$FRR_STATE_DIR
1751 else
1752   frr_statedir=${localstatedir}
1753 fi
1754 if test $frr_statedir = "/dev/null"; then
1755     AC_MSG_ERROR('STATE DIRECTORY NOT FOUND! FIX OR SPECIFY --localstatedir!')
1756 fi
1757 AC_MSG_RESULT(${frr_statedir})
1758 AC_SUBST(frr_statedir)
1759
1760 AC_DEFINE_UNQUOTED(LDPD_SOCKET, "$frr_statedir/ldpd.sock",ldpd control socket)
1761 AC_DEFINE_UNQUOTED(ZEBRA_SERV_PATH, "$frr_statedir/zserv.api",zebra api socket)
1762 AC_DEFINE_UNQUOTED(DAEMON_VTY_DIR, "$frr_statedir",daemon vty directory)
1763
1764 dnl autoconf does this, but it does it too late...
1765 test "x$prefix" = xNONE && prefix=$ac_default_prefix
1766 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
1767
1768 dnl get the full path, recursing through variables...
1769 vtysh_bin="$bindir/vtysh"
1770 for I in 1 2 3 4 5 6 7 8 9 10; do
1771         eval vtysh_bin="\"$vtysh_bin\""
1772 done
1773 AC_DEFINE_UNQUOTED(VTYSH_BIN_PATH, "$vtysh_bin",path to vtysh binary)
1774
1775 CFG_SYSCONF="$sysconfdir"
1776 CFG_SBIN="$sbindir"
1777 CFG_STATE="$frr_statedir"
1778 CFG_MODULE="$moduledir"
1779 for I in 1 2 3 4 5 6 7 8 9 10; do
1780         eval CFG_SYSCONF="\"$CFG_SYSCONF\""
1781         eval CFG_SBIN="\"$CFG_SBIN\""
1782         eval CFG_STATE="\"$CFG_STATE\""
1783         eval CFG_MODULE="\"$CFG_MODULE\""
1784 done
1785 AC_SUBST(CFG_SYSCONF)
1786 AC_SUBST(CFG_SBIN)
1787 AC_SUBST(CFG_STATE)
1788 AC_SUBST(CFG_MODULE)
1789 AC_DEFINE_UNQUOTED(MODULE_PATH, "$CFG_MODULE", path to modules)
1790
1791 dnl ---------------------------
1792 dnl Check htonl works correctly
1793 dnl ---------------------------
1794 AC_MSG_CHECKING(for working htonl)
1795 AC_CACHE_VAL(ac_cv_htonl_works,
1796  [AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES],[htonl (0);])],
1797                 [ac_cv_htonl_works=yes], [ac_cv_htonl_works=no])
1798  ]
1799 )
1800 AC_MSG_RESULT($ac_cv_htonl_works)
1801
1802 AC_CONFIG_FILES([Makefile
1803           bgpd/Makefile watchfrr/Makefile
1804           vtysh/Makefile
1805           doc/Makefile tests/Makefile
1806           bgpd/rfp-example/rfptest/Makefile bgpd/rfp-example/librfp/Makefile
1807           babeld/Makefile
1808           pimd/Makefile
1809           eigrpd/Makefile
1810           tools/Makefile
1811           redhat/frr.spec
1812           snapcraft/snapcraft.yaml
1813           lib/version.h
1814           tests/lib/cli/test_cli.refout
1815           doc/defines.texi
1816           doc/bgpd.8
1817           doc/isisd.8
1818           doc/ospf6d.8
1819           doc/ospfclient.8
1820           doc/ospfd.8
1821           doc/ldpd.8
1822           doc/ripd.8
1823           doc/eigrpd.8
1824           doc/ripngd.8
1825           doc/pimd.8
1826           doc/nhrpd.8
1827           doc/vtysh.1
1828           doc/watchfrr.8
1829           doc/zebra.8
1830           doc/frr.1
1831           pkgsrc/bgpd.sh pkgsrc/ospf6d.sh pkgsrc/ospfd.sh
1832           pkgsrc/ripd.sh pkgsrc/ripngd.sh pkgsrc/zebra.sh
1833           pkgsrc/eigrpd.sh])
1834
1835
1836 AC_CONFIG_FILES([solaris/Makefile])
1837
1838 AC_CONFIG_FILES([vtysh/extract.pl],[chmod +x vtysh/extract.pl])
1839
1840 AC_CONFIG_COMMANDS([lib/route_types.h], [
1841         dst="${ac_abs_top_builddir}/lib/route_types.h"
1842         ${PERL} "${ac_abs_top_srcdir}/lib/route_types.pl" \
1843                 < "${ac_abs_top_srcdir}/lib/route_types.txt" \
1844                 > "${dst}.tmp"
1845         test -f "${dst}" \
1846                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
1847                 && rm "${dst}.tmp" \
1848                 || mv "${dst}.tmp" "${dst}"
1849 ], [
1850         PERL="$PERL"
1851 ])
1852
1853 AS_IF([test "x$with_pkg_git_version" = "xyes"], [
1854     AC_CONFIG_COMMANDS([lib/gitversion.h], [
1855         dst="${ac_abs_top_builddir}/lib/gitversion.h"
1856         ${PERL} "${ac_abs_top_srcdir}/lib/gitversion.pl" \
1857                 "${ac_abs_top_srcdir}" \
1858                 > "${dst}.tmp"
1859         test -f "${dst}" \
1860                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
1861                 && rm "${dst}.tmp" \
1862                 || mv "${dst}.tmp" "${dst}"
1863     ], [
1864         PERL="$PERL"
1865     ])
1866 ])
1867
1868 ## Hack, but working solution to avoid rebuilding of frr.info.
1869 ## It's already in CVS until texinfo 4.7 is more common.
1870 AC_OUTPUT
1871
1872 echo "
1873 FRRouting configuration
1874 ------------------------------
1875 FRR version             : ${PACKAGE_VERSION}
1876 host operating system   : ${host_os}
1877 source code location    : ${srcdir}
1878 compiler                : ${CC}
1879 compiler flags          : ${CFLAGS}
1880 make                    : ${MAKE-make}
1881 linker flags            : ${LDFLAGS} ${LIBS} ${LIBCAP} ${LIBREADLINE} ${LIBM}
1882 state file directory    : ${frr_statedir}
1883 config file directory   : `eval echo \`echo ${sysconfdir}\``
1884 example directory       : `eval echo \`echo ${exampledir}\``
1885 module directory        : ${CFG_MODULE}
1886 user to run as          : ${enable_user}
1887 group to run as         : ${enable_group}
1888 group for vty sockets   : ${enable_vty_group}
1889 config file mask        : ${enable_configfile_mask}
1890 log file mask           : ${enable_logfile_mask}
1891 zebra protobuf enabled  : ${have_protobuf:-no}
1892
1893 The above user and group must have read/write access to the state file
1894 directory and to the config files in the config file directory."