configure.ac

   1 ##
   2 ## Configure template file for FRRouting.
   3 ## autoconf will generate configure script.
   4 ##
   5 ##  Copyright (c) 1996, 97, 98, 99, 2000 Kunihiro Ishiguro <kunihiro@zebra.org>
   6 ##  Portions Copyright (c) 2003 Paul Jakma <paul@dishone.st>
   7 ##
   8 AC_PREREQ(2.60)
   9
  10 AC_INIT(frr, 6.1-dev, [https://github.com/frrouting/frr/issues])
  11 PACKAGE_URL="https://frrouting.org/"
  12 AC_SUBST(PACKAGE_URL)
  13 PACKAGE_FULLNAME="FRRouting"
  14 AC_SUBST(PACKAGE_FULLNAME)
  15
  16 CONFIG_ARGS="$ac_configure_args"
  17 AC_SUBST(CONFIG_ARGS)
  18
  19 AC_CONFIG_SRCDIR(lib/zebra.h)
  20 AC_CONFIG_MACRO_DIR([m4])
  21
  22 dnl -----------------------------------
  23 dnl Get hostname and other information.
  24 dnl -----------------------------------
  25 AC_CANONICAL_BUILD()
  26 AC_CANONICAL_HOST()
  27
  28 AS_IF([test "$host" != "$build"], [
  29   if test "$srcdir" = "."; then
  30     AC_MSG_ERROR([cross-compilation is only possible with builddir separate from srcdir.  create a separate directory and run as .../path-to-frr/configure.])
  31   fi
  32   test -d hosttools || mkdir hosttools
  33   abssrc="`cd \"${srcdir}\"; pwd`"
  34
  35   AC_MSG_NOTICE([...])
  36   AC_MSG_NOTICE([... cross-compilation: creating hosttools directory and self-configuring for build platform tools])
  37   AC_MSG_NOTICE([... use HOST_CPPFLAGS / HOST_CFLAGS / HOST_LDFLAGS if neccessary])
  38   AC_MSG_NOTICE([...])
  39
  40   ( CPPFLAGS="$HOST_CPPFLAGS"; \
  41     CFLAGS="$HOST_CFLAGS"; \
  42     LDFLAGS="$HOST_LDFLAGS"; \
  43     cd hosttools; "${abssrc}/configure" "--host=$build" "--build=$build" "--enable-clippy-only" "--disable-nhrpd" "--disable-vtysh"; )
  44
  45   AC_MSG_NOTICE([...])
  46   AC_MSG_NOTICE([... cross-compilation: finished self-configuring for build platform tools])
  47   AC_MSG_NOTICE([...])
  48
  49   build_clippy="false"
  50   HOSTTOOLS="hosttools/"
  51 ], [
  52   build_clippy="true"
  53   HOSTTOOLS=""
  54 ])
  55 AC_SUBST(HOSTTOOLS)
  56 AM_CONDITIONAL([BUILD_CLIPPY], [$build_clippy])
  57
  58 # Disable portability warnings -- our automake code (in particular
  59 # common.am) uses some constructs specific to gmake.
  60 AM_INIT_AUTOMAKE([1.12 -Wno-portability])
  61 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
  62 AM_SILENT_RULES([yes])
  63 AC_CONFIG_HEADERS(config.h)
  64
  65 AC_PATH_PROG(PERL, perl)
  66 PKG_PROG_PKG_CONFIG
  67
  68 dnl default is to match previous behavior
  69 exampledir=${sysconfdir}
  70 AC_ARG_ENABLE([exampledir],
  71           AS_HELP_STRING([--enable-exampledir],
  72                          [specify alternate directory for examples]),
  73                          exampledir="$enableval",)
  74 dnl XXX add --exampledir to autoconf standard directory list somehow
  75 AC_SUBST(exampledir)
  76
  77 dnl default is to match previous behavior
  78 pkgsrcrcdir=""
  79 AC_ARG_ENABLE([pkgsrcrcdir],
  80           AS_HELP_STRING([--enable-pkgsrcrcdir],
  81                          [specify directory for rc.d scripts]),
  82                          pkgsrcrcdir="$enableval",)
  83 dnl XXX add --pkgsrcrcdir to autoconf standard directory list somehow
  84 AC_SUBST(pkgsrcrcdir)
  85 AM_CONDITIONAL([PKGSRC], [test "x$pkgsrcrcdir" != "x"])
  86
  87 AC_ARG_WITH([moduledir], [AS_HELP_STRING([--with-moduledir=DIR], [module directory (${libdir}/frr/modules)])], [
  88         moduledir="$withval"
  89 ], [
  90         moduledir="\${libdir}/frr/modules"
  91 ])
  92 AC_SUBST([moduledir], [$moduledir])
  93
  94 AC_ARG_ENABLE(tcmalloc,
  95         AS_HELP_STRING([--enable-tcmalloc], [Turn on tcmalloc]),
  96 [case "${enableval}" in
  97   yes) tcmalloc_enabled=true
  98 LIBS="$LIBS -ltcmalloc_minimal"
  99  ;;
 100   no)  tcmalloc_enabled=false ;;
 101   *) AC_MSG_ERROR(bad value ${enableval} for --enable-tcmalloc) ;;
 102 esac],[tcmalloc_enabled=false])
 103
 104
 105 dnl Thanks autoconf, but we don't want a default -g -O2.  We have our own
 106 dnl flag determination logic.
 107 CFLAGS="${CFLAGS:-}"
 108
 109 dnl --------------------
 110 dnl Check CC and friends
 111 dnl --------------------
 112 dnl note orig_cflags is also used further down
 113 orig_cflags="$CFLAGS"
 114 AC_LANG([C])
 115 AC_PROG_CC
 116 AC_PROG_CPP
 117 AM_PROG_CC_C_O
 118 dnl remove autoconf default "-g -O2"
 119 CFLAGS="$orig_cflags"
 120 AC_PROG_CC_C99
 121 dnl NB: see C11 below
 122
 123 AC_PROG_EGREP
 124 PKG_PROG_PKG_CONFIG
 125
 126 dnl autoconf 2.59 appears not to support AC_PROG_SED
 127 dnl AC_PROG_SED
 128 AC_CHECK_PROG([SED],[sed],[sed],[/bin/false])
 129
 130 dnl try and enable CFLAGS that are useful for FRR
 131 dnl - specifically, options to control warnings
 132
 133 AC_USE_SYSTEM_EXTENSIONS
 134 AC_DEFUN([AC_C_FLAG], [{
 135     m4_pushdef([cachename],[m4_translit([frr_cv_$1],[ =-],[___])])
 136     AC_CACHE_CHECK([[whether $CC supports $1]], cachename, [
 137         AC_LANG_PUSH(C)
 138         ac_c_flag_save="$CFLAGS"
 139         CFLAGS="$CFLAGS $1"
 140         AC_COMPILE_IFELSE(
 141                 [AC_LANG_PROGRAM([[]])],
 142                 [
 143                         cachename=yes
 144                 ], [
 145                         cachename=no
 146                 ])
 147         CFLAGS="$ac_c_flag_save"
 148         AC_LANG_POP(C)
 149     ])
 150     if test "${cachename}" = yes; then
 151         m4_if([$3], [], [CFLAGS="$CFLAGS $1"], [$3])
 152     else
 153         :
 154         $2
 155     fi
 156     m4_popdef([cachename])
 157 }])
 158
 159 AC_DEFUN([AC_LINK_IFELSE_FLAGS], [{
 160         AC_LANG_PUSH(C)
 161         ac_cflags_save="$CFLAGS"
 162         ac_libs_save="$LIBS"
 163         CFLAGS="$CFLAGS $1"
 164         LIBS="$LIBS $2"
 165         AC_LINK_IFELSE(
 166                 [$3],
 167                 [
 168                         AC_MSG_RESULT([yes])
 169                         CFLAGS="$ac_cflags_save"
 170                         LIBS="$ac_libs_save"
 171                         $5
 172                 ], [
 173                         AC_MSG_RESULT([no])
 174                         CFLAGS="$ac_cflags_save"
 175                         LIBS="$ac_libs_save"
 176                         $4
 177                 ])
 178         AC_LANG_POP(C)
 179         }])
 180
 181 dnl ICC won't bail on unknown options without -diag-error 10006
 182 dnl need to do this first so we get useful results for the other options
 183 AC_C_FLAG([-diag-error 10006])
 184
 185 dnl AC_PROG_CC_C99 may change CC to include -std=gnu99 or something
 186 ac_cc="$CC"
 187 CC="${CC% -std=gnu99}"
 188 CC="${CC% -std=c99}"
 189
 190 AC_C_FLAG([-std=gnu11], [CC="$ac_cc"], [CC="$CC -std=gnu11"])
 191
 192 dnl if the user has specified any CFLAGS, override our settings
 193 if test "x${enable_gcov}" = "xyes"; then
 194    if test "z$orig_cflags" = "z"; then
 195       AC_C_FLAG([-coverage])
 196       AC_C_FLAG([-O0])
 197    fi
 198
 199    LDFLAGS="${LDFLAGS} -lgcov"
 200 elif test "x${enable_dev_build}" = "xyes"; then
 201    AC_DEFINE(DEV_BUILD,,Build for development)
 202    if test "z$orig_cflags" = "z"; then
 203       AC_C_FLAG([-g3])
 204       AC_C_FLAG([-O0])
 205    fi
 206 else
 207    if test "z$orig_cflags" = "z"; then
 208       AC_C_FLAG([-g])
 209       AC_C_FLAG([-Os], [
 210         AC_C_FLAG([-O2])
 211       ])
 212    fi
 213 fi
 214 AM_CONDITIONAL([DEV_BUILD], [test "x$enable_dev_build" = "xyes"])
 215
 216 dnl always want these CFLAGS
 217 AC_C_FLAG([-fno-omit-frame-pointer])
 218 AC_C_FLAG([-funwind-tables])
 219 AC_C_FLAG([-Wall])
 220 AC_C_FLAG([-Wextra])
 221 AC_C_FLAG([-Wmissing-prototypes])
 222 AC_C_FLAG([-Wmissing-declarations])
 223 AC_C_FLAG([-Wpointer-arith])
 224 AC_C_FLAG([-Wbad-function-cast])
 225 AC_C_FLAG([-Wwrite-strings])
 226 if test x"${enable_gcc_ultra_verbose}" = x"yes" ; then
 227   AC_C_FLAG([-Wcast-qual])
 228   AC_C_FLAG([-Wstrict-prototypes])
 229   AC_C_FLAG([-Wmissing-noreturn])
 230   AC_C_FLAG([-Wmissing-format-attribute])
 231   AC_C_FLAG([-Wunreachable-code])
 232   AC_C_FLAG([-Wpacked])
 233   AC_C_FLAG([-Wpadded])
 234 else
 235   AC_C_FLAG([-Wno-unused-result])
 236 fi
 237 AC_C_FLAG([-Wno-unused-parameter])
 238 AC_C_FLAG([-Wno-missing-field-initializers])
 239
 240 dnl ICC emits a broken warning for const char *x = a ? "b" : "c";
 241 dnl for some reason the string consts get 'promoted' to char *,
 242 dnl triggering a const to non-const conversion warning.
 243 AC_C_FLAG([-diag-disable 3179])
 244
 245 if test x"${enable_werror}" = x"yes" ; then
 246   WERROR="-Werror"
 247 fi
 248 AC_SUBST(WERROR)
 249
 250 SAN_FLAGS=""
 251 if test "$enable_address_sanitizer" = "yes"; then
 252   AC_C_FLAG([-fsanitize=address], [
 253     AC_MSG_ERROR([$CC does not support Address Sanitizer.])
 254   ], [
 255     SAN_FLAGS="$SAN_FLAGS -fsanitize=address"
 256   ])
 257 fi
 258 if test "$enable_thread_sanitizer" = "yes"; then
 259   AC_C_FLAG([-fsanitize=thread], [
 260     AC_MSG_ERROR([$CC does not support Thread Sanitizer.])
 261   ], [
 262     SAN_FLAGS="$SAN_FLAGS -fsanitize=thread"
 263   ])
 264 fi
 265 if test "$enable_memory_sanitizer" = "yes"; then
 266   AC_C_FLAG([-fsanitize=thread -fPIE -pie], [
 267     AC_MSG_ERROR([$CC does not support Thread Sanitizer.])
 268   ], [
 269     SAN_FLAGS="-fsanitize=memory -fPIE -pie"
 270   ])
 271 fi
 272 AC_SUBST([SAN_FLAGS])
 273
 274 dnl ----------
 275 dnl Essentials
 276 dnl ----------
 277
 278 AX_PTHREAD([
 279   CC="$PTHREAD_CC"
 280   CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 281   LIBS="$PTHREAD_LIBS $LIBS"
 282 ], [
 283   AC_MSG_FAILURE([This FRR version needs pthreads])
 284 ])
 285
 286 AC_SEARCH_LIBS([pthread_condattr_setclock], [],
 287                 [frr_cv_pthread_condattr_setclock=yes],
 288                 [frr_cv_pthread_condattr_setclock=no])
 289 if test "$frr_cv_pthread_condattr_setclock" = yes; then
 290   AC_DEFINE(HAVE_PTHREAD_CONDATTR_SETCLOCK, 1, [Have pthread.h pthread_condattr_setclock])
 291 fi
 292
 293 dnl --------------
 294 dnl Check programs
 295 dnl --------------
 296 AC_PROG_INSTALL
 297 AC_PROG_LN_S
 298 AC_PROG_MAKE_SET
 299 AC_CHECK_TOOL(AR, ar)
 300
 301 dnl -------
 302 dnl libtool
 303 dnl -------
 304 LT_INIT
 305
 306 dnl ----------------------
 307 dnl Packages configuration
 308 dnl ----------------------
 309 AC_ARG_WITH(pkg-extra-version,
 310         AS_HELP_STRING([--with-pkg-extra-version=VER], [add extra version field, for packagers/distributions]),
 311         [EXTRAVERSION=$withval],)
 312 AC_ARG_WITH(pkg-git-version,
 313         AS_HELP_STRING([--with-pkg-git-version], [add git information to MOTD and build version string]),
 314         [ test "x$withval" != "xno" && with_pkg_git_version="yes" ])
 315 AC_ARG_WITH(vtysh_pager,
 316         AS_HELP_STRING([--with-vtysh-pager=PAGER], [control what pager is compiled in as default]),
 317         VTYSH_PAGER=$withval, VTYSH_PAGER="more")
 318 AC_ARG_ENABLE(vtysh,
 319   AS_HELP_STRING([--disable-vtysh], [do not build integrated vty shell for FRR]))
 320 AC_ARG_ENABLE(doc,
 321   AS_HELP_STRING([--disable-doc], [do not build docs]))
 322 AC_ARG_ENABLE(doc-html,
 323   AS_HELP_STRING([--enable-doc-html], [build HTML docs]))
 324 AC_ARG_ENABLE(zebra,
 325   AS_HELP_STRING([--disable-zebra], [do not build zebra daemon]))
 326 AC_ARG_ENABLE(bgpd,
 327   AS_HELP_STRING([--disable-bgpd], [do not build bgpd]))
 328 AC_ARG_ENABLE(ripd,
 329   AS_HELP_STRING([--disable-ripd], [do not build ripd]))
 330 AC_ARG_ENABLE(ripngd,
 331   AS_HELP_STRING([--disable-ripngd], [do not build ripngd]))
 332 AC_ARG_ENABLE(ospfd,
 333   AS_HELP_STRING([--disable-ospfd], [do not build ospfd]))
 334 AC_ARG_ENABLE(ospf6d,
 335   AS_HELP_STRING([--disable-ospf6d], [do not build ospf6d]))
 336 AC_ARG_ENABLE(ldpd,
 337   AS_HELP_STRING([--disable-ldpd], [do not build ldpd]))
 338 AC_ARG_ENABLE(nhrpd,
 339   AS_HELP_STRING([--disable-nhrpd], [do not build nhrpd]))
 340 AC_ARG_ENABLE(eigrpd,
 341   AS_HELP_STRING([--disable-eigrpd], [do not build eigrpd]))
 342 AC_ARG_ENABLE(babeld,
 343   AS_HELP_STRING([--disable-babeld], [do not build babeld]))
 344 AC_ARG_ENABLE(watchfrr,
 345   AS_HELP_STRING([--disable-watchfrr], [do not build watchfrr]))
 346 AC_ARG_ENABLE(isisd,
 347   AS_HELP_STRING([--disable-isisd], [do not build isisd]))
 348 AC_ARG_ENABLE(pimd,
 349   AS_HELP_STRING([--disable-pimd], [do not build pimd]))
 350 AC_ARG_ENABLE(pbrd,
 351   AS_HELP_STRING([--disable-pbrd], [do not build pbrd]))
 352 AC_ARG_ENABLE(sharpd,
 353   AS_HELP_STRING([--enable-sharpd], [build sharpd]))
 354 AC_ARG_ENABLE(staticd,
 355   AS_HELP_STRING([--disable-staticd], [do not build staticd]))
 356 AC_ARG_ENABLE(fabricd,
 357   AS_HELP_STRING([--disable-fabricd], [do not build fabricd]))
 358 AC_ARG_ENABLE(bgp-announce,
 359   AS_HELP_STRING([--disable-bgp-announce,], [turn off BGP route announcement]))
 360 AC_ARG_ENABLE(bgp-vnc,
 361   AS_HELP_STRING([--disable-bgp-vnc],[turn off BGP VNC support]))
 362 AC_ARG_ENABLE(snmp,
 363   AS_HELP_STRING([--enable-snmp], [enable SNMP support for agentx]))
 364 AC_ARG_ENABLE(zeromq,
 365   AS_HELP_STRING([--enable-zeromq], [enable ZeroMQ handler (libfrrzmq)]))
 366 AC_ARG_WITH(libpam,
 367   AS_HELP_STRING([--with-libpam], [use libpam for PAM support in vtysh]))
 368 AC_ARG_ENABLE(ospfapi,
 369   AS_HELP_STRING([--disable-ospfapi], [do not build OSPFAPI to access the OSPF LSA Database]))
 370 AC_ARG_ENABLE(ospfclient,
 371   AS_HELP_STRING([--disable-ospfclient], [do not build OSPFAPI client for OSPFAPI,
 372                           (this is the default if --disable-ospfapi is set)]))
 373 AC_ARG_ENABLE(multipath,
 374   AS_HELP_STRING([--enable-multipath=ARG], [enable multipath function, ARG must be digit]))
 375 AC_ARG_ENABLE(user,
 376   AS_HELP_STRING([--enable-user=USER], [user to run FRR suite as (default frr)]))
 377 AC_ARG_ENABLE(group,
 378   AS_HELP_STRING([--enable-group=GROUP], [group to run FRR suite as (default frr)]))
 379 AC_ARG_ENABLE(vty_group,
 380   AS_HELP_STRING([--enable-vty-group=ARG], [set vty sockets to have specified group as owner]))
 381 AC_ARG_ENABLE(configfile_mask,
 382   AS_HELP_STRING([--enable-configfile-mask=ARG], [set mask for config files]))
 383 AC_ARG_ENABLE(logfile_mask,
 384   AS_HELP_STRING([--enable-logfile-mask=ARG], [set mask for log files]))
 385 AC_ARG_ENABLE(shell_access,
 386   AS_HELP_STRING([--enable-shell-access], [Allow users to access shell/telnet/ssh]))
 387 AC_ARG_ENABLE(realms,
 388   AS_HELP_STRING([--enable-realms], [enable REALMS support under Linux]))
 389 AC_ARG_ENABLE(rtadv,
 390   AS_HELP_STRING([--disable-rtadv], [disable IPV6 router advertisement feature]))
 391 AC_ARG_ENABLE(irdp,
 392   AS_HELP_STRING([--disable-irdp], [enable IRDP server support in zebra (default if supported)]))
 393 AC_ARG_ENABLE(capabilities,
 394   AS_HELP_STRING([--disable-capabilities], [disable using POSIX capabilities]))
 395 AC_ARG_ENABLE(rusage,
 396   AS_HELP_STRING([--disable-rusage], [disable using getrusage]))
 397 AC_ARG_ENABLE(gcc_ultra_verbose,
 398   AS_HELP_STRING([--enable-gcc-ultra-verbose], [enable ultra verbose GCC warnings]))
 399 AC_ARG_ENABLE(backtrace,
 400   AS_HELP_STRING([--disable-backtrace,], [disable crash backtraces (default autodetect)]))
 401 AC_ARG_ENABLE(time-check,
 402   AS_HELP_STRING([--disable-time-check], [disable slow thread warning messages]))
 403 AC_ARG_ENABLE(pcreposix,
 404   AS_HELP_STRING([--enable-pcreposix], [enable using PCRE Posix libs for regex functions]))
 405 AC_ARG_ENABLE(fpm,
 406   AS_HELP_STRING([--enable-fpm], [enable Forwarding Plane Manager support]))
 407 AC_ARG_ENABLE(systemd,
 408   AS_HELP_STRING([--enable-systemd], [enable Systemd support]))
 409 AC_ARG_ENABLE(werror,
 410   AS_HELP_STRING([--enable-werror], [enable -Werror (recommended for developers only)]))
 411 AC_ARG_ENABLE(cumulus,
 412   AS_HELP_STRING([--enable-cumulus], [enable Cumulus Switch Special Extensions]))
 413 AC_ARG_ENABLE(datacenter,
 414   AS_HELP_STRING([--enable-datacenter], [enable Compilation for Data Center Extensions]))
 415 AC_ARG_ENABLE(fuzzing,
 416   AS_HELP_STRING([--enable-fuzzing], [enable ability to fuzz various parts of FRR]))
 417 AC_ARG_ENABLE(netlink_fuzzing,
 418   AS_HELP_STRING([--enable-netlink-fuzzing], [enable ability to fuzz netlink listening socket in zebra]))
 419 AC_ARG_ENABLE(rr-semantics,
 420   AS_HELP_STRING([--disable-rr-semantics], [disable the v6 Route Replace semantics]))
 421 AC_ARG_ENABLE([protobuf],
 422   AS_HELP_STRING([--enable-protobuf], [Enable experimental protobuf support]))
 423 AC_ARG_ENABLE([oldvpn_commands],
 424   AS_HELP_STRING([--enable-oldvpn-commands], [Keep old vpn commands]))
 425 AC_ARG_ENABLE(rpki,
 426   AS_HELP_STRING([--enable-rpki], [enable RPKI prefix validation support]))
 427 AC_ARG_ENABLE([clippy-only],
 428   AS_HELP_STRING([--enable-clippy-only], [Only build clippy]))
 429 AC_ARG_ENABLE([numeric_version],
 430   AS_HELP_STRING([--enable-numeric-version], [Only numeric digits allowed in version (for Alpine)]))
 431 AC_ARG_ENABLE([gcov],
 432   AS_HELP_STRING([--enable-gcov], [Add code coverage information]))
 433 AC_ARG_ENABLE(bfdd,
 434   AS_HELP_STRING([--disable-bfdd], [do not build bfdd]))
 435 AC_ARG_ENABLE([address-sanitizer],
 436   AS_HELP_STRING([--enable-address-sanitizer], [enable AddressSanitizer support for detecting a wide variety of memory allocation and deallocation errors]))
 437 AC_ARG_ENABLE([thread-sanitizer],
 438   AS_HELP_STRING([--enable-thread-sanitizer], [enable ThreadSanitizer support for detecting data races]))
 439 AC_ARG_ENABLE([memory-sanitizer],
 440   AS_HELP_STRING([--enable-memory-sanitizer], [enable MemorySanitizer support for detecting uninitialized memory reads]))
 441
 442 AS_IF([test "${enable_clippy_only}" != "yes"], [
 443 AC_CHECK_HEADERS(json-c/json.h)
 444 AC_CHECK_LIB(json-c, json_object_get, LIBS="$LIBS -ljson-c", [], [-lm])
 445 if test $ac_cv_lib_json_c_json_object_get = no; then
 446   AC_CHECK_LIB(json, json_object_get, LIBS="$LIBS -ljson")
 447   if test $ac_cv_lib_json_json_object_get = no; then
 448       AC_MSG_ERROR([lib json is needed to compile])
 449   fi
 450 fi
 451 ])
 452
 453 AC_ARG_ENABLE([dev_build],
 454     AS_HELP_STRING([--enable-dev-build], [build for development]))
 455
 456 if test x"${enable_time_check}" != x"no" ; then
 457   if test x"${enable_time_check}" = x"yes" -o x"${enable_time_check}" = x ; then
 458     AC_DEFINE(CONSUMED_TIME_CHECK,5000000,Consumed Time Check)
 459   else
 460     AC_DEFINE_UNQUOTED(CONSUMED_TIME_CHECK,$enable_time_check,Consumed Time Check)
 461   fi
 462 fi
 463
 464 case "${enable_systemd}" in
 465   "no") ;;
 466   "yes")
 467   AC_CHECK_LIB(systemd, sd_notify, LIBS="$LIBS -lsystemd")
 468   if test $ac_cv_lib_systemd_sd_notify = no; then
 469     AC_MSG_ERROR([enable systemd has been specified but systemd development env not found on your system])
 470   else
 471     AC_DEFINE(HAVE_SYSTEMD,,Compile systemd support in)
 472   fi
 473   ;;
 474   "*") ;;
 475 esac
 476
 477 if test "${enable_rr_semantics}" != "no" ; then
 478   AC_DEFINE(HAVE_V6_RR_SEMANTICS,, Compile in v6 Route Replacement Semantics)
 479 fi
 480
 481 if test "${enable_datacenter}" = "yes" ; then
 482   AC_DEFINE(HAVE_DATACENTER,,Compile extensions for a DataCenter)
 483   DFLT_NAME="datacenter"
 484 else
 485   DFLT_NAME="traditional"
 486 fi
 487
 488 if test "${enable_fuzzing}" = "yes" ; then
 489   AC_DEFINE(HANDLE_ZAPI_FUZZING,,Compile extensions to use with a fuzzer)
 490 fi
 491
 492 if test "${enable_netlink_fuzzing}" = "yes" ; then
 493   AC_DEFINE(HANDLE_NETLINK_FUZZING,,Compile extensions to use with a fuzzer for netlink)
 494 fi
 495
 496 if test "${enable_cumulus}" = "yes" ; then
 497   AC_DEFINE(HAVE_CUMULUS,,Compile Special Cumulus Code in)
 498 fi
 499
 500 AC_SUBST(DFLT_NAME)
 501 AC_DEFINE_UNQUOTED(DFLT_NAME,["$DFLT_NAME"], Name of the configuration default set)
 502
 503 if test "${enable_shell_access}" = "yes"; then
 504    AC_DEFINE(HAVE_SHELL_ACCESS,,Allow user to use ssh/telnet/bash)
 505 fi
 506
 507 AM_CONDITIONAL([FPM], [test "x$enable_fpm" = "xyes"])
 508
 509 #
 510 # Python for clippy
 511 #
 512
 513 AC_DEFUN([FRR_PYTHON_CHECK_WORKING], [
 514   AC_MSG_CHECKING([whether we found a working Python version])
 515   AC_LINK_IFELSE_FLAGS([$PYTHON_CFLAGS], [$PYTHON_LIBS], [AC_LANG_PROGRAM([
 516 #include <Python.h>
 517 #if PY_VERSION_HEX < 0x02070000
 518 #error python too old
 519 #endif
 520 int main(void);
 521 ],
 522 [
 523 {
 524   Py_Initialize();
 525   return 0;
 526 }
 527 ])], [
 528     # some python installs are missing the zlib dependency...
 529     PYTHON_LIBS="${PYTHON_LIBS} -lz"
 530     AC_LINK_IFELSE_FLAGS([$PYTHON_CFLAGS], [$PYTHON_LIBS], [AC_LANG_PROGRAM([
 531 #include <Python.h>
 532 #if PY_VERSION_HEX < 0x02070000
 533 #error python too old
 534 #endif
 535 int main(void);
 536 ],
 537 [
 538 {
 539   Py_Initialize();
 540   return 0;
 541 }
 542 ])], [
 543       m4_if([$1], [], [
 544         PYTHONCONFIG=""
 545         unset PYTHON_LIBS
 546         unset PYTHON_CFLAGS
 547       ], [$1])
 548     ])
 549   ])
 550 ])
 551
 552 AS_IF([test "$host" = "$build"], [
 553   PYTHONCONFIG=""
 554
 555   # ordering:
 556   # 1.  try python3, but respect the user's preference on which minor ver
 557   # 2.  try python, which might be py3 or py2 again on the user's preference
 558   # 3.  try python2 (can really only be 2.7 but eh)
 559   # 4.  try 3.6 > 3.5 > 3.4 > 3.3 > 3.2 > 2.7 through pkg-config (no user pref)
 560   #
 561   # (AX_PYTHON_DEVEL has no clue about py3 vs py2)
 562   # (AX_PYTHON does not do what we need)
 563
 564   AC_CHECK_TOOLS([PYTHONCONFIG], [ \
 565         python3-config \
 566         python-config \
 567         python2-config \
 568         python3.6-config \
 569         python3.5-config \
 570         python3.4-config \
 571         python3.3-config \
 572         python3.2-config \
 573         python2.7-config ])
 574   if test -n "$PYTHONCONFIG"; then
 575     PYTHON_CFLAGS="`\"${PYTHONCONFIG}\" --includes`"
 576     PYTHON_LIBS="`\"${PYTHONCONFIG}\" --ldflags`"
 577
 578     FRR_PYTHON_CHECK_WORKING([])
 579   fi
 580
 581   if test -z "$PYTHONCONFIG"; then
 582     PKG_CHECK_MODULES([PYTHON], python-3.6, [], [
 583       PKG_CHECK_MODULES([PYTHON], python-3.5, [], [
 584         PKG_CHECK_MODULES([PYTHON], python-3.4, [], [
 585           PKG_CHECK_MODULES([PYTHON], python-3.3, [], [
 586             PKG_CHECK_MODULES([PYTHON], python-3.2, [], [
 587               PKG_CHECK_MODULES([PYTHON], python-2.7, [], [
 588                 AC_MSG_FAILURE([could not find python-config or pkg-config python, please install Python development files from libpython-dev or similar])
 589                 ])])])])])])
 590
 591
 592     FRR_PYTHON_CHECK_WORKING([
 593       AC_MSG_FAILURE([could not find python-config or pkg-config python, please install Python development files from libpython-dev or similar])
 594     ])
 595   fi
 596 ])
 597 AC_SUBST(PYTHON_CFLAGS)
 598 AC_SUBST(PYTHON_LIBS)
 599
 600 #
 601 # Logic for protobuf support.
 602 #
 603 if test "$enable_protobuf" = "yes"; then
 604   # Check for protoc & protoc-c
 605
 606   # protoc is not required, it's only for a "be nice" helper target
 607   AC_CHECK_PROGS([PROTOC], [protoc], [/bin/false])
 608
 609   AC_CHECK_PROGS([PROTOC_C], [protoc-c], [/bin/false])
 610   if test "$PROTOC_C" = "/bin/false"; then
 611     AC_MSG_FAILURE([protobuf requested but protoc-c not found.  Install protobuf-c.])
 612   fi
 613
 614   PKG_CHECK_MODULES([PROTOBUF_C], [libprotobuf-c >= 0.14],, [
 615     AC_MSG_FAILURE([protobuf requested but libprotobuf-c not found.  Install protobuf-c.])
 616   ])
 617   AC_CHECK_HEADER([google/protobuf-c/protobuf-c.h], [], [
 618     AC_MSG_FAILURE([protobuf requested but protobuf-c.h not found.  Install protobuf-c.])
 619   ])
 620
 621   AC_DEFINE(HAVE_PROTOBUF,, protobuf)
 622 fi
 623 AM_CONDITIONAL([HAVE_PROTOBUF], [test "x$enable_protobuf" = "xyes"])
 624
 625 #
 626 # Logic for old vpn commans support.
 627 #
 628 if test "$enable_oldvpn_commands" = "yes"; then
 629    AC_DEFINE(KEEP_OLD_VPN_COMMANDS,, [Define for compiling with old vpn commands])
 630 fi
 631
 632 #
 633 # End of logic for protobuf support.
 634 #
 635
 636 AC_MSG_CHECKING(if zebra should be configurable to send Route Advertisements)
 637 if test "${enable_rtadv}" != "no"; then
 638   AC_MSG_RESULT(yes)
 639   AC_DEFINE(HAVE_RTADV,,Enable IPv6 Routing Advertisement support)
 640 else
 641   AC_MSG_RESULT(no)
 642 fi
 643
 644 if test x"${enable_user}" = x"no"; then
 645   enable_user=""
 646 else
 647   if test x"${enable_user}" = x"yes" || test x"${enable_user}" = x""; then
 648     enable_user="frr"
 649   fi
 650   AC_DEFINE_UNQUOTED(FRR_USER, "${enable_user}", frr User)
 651 fi
 652
 653 if test x"${enable_group}" = x"no"; then
 654   enable_group=""
 655 else
 656   if test x"${enable_group}" = x"yes" || test x"${enable_group}" = x""; then
 657     enable_group="frr"
 658   fi
 659   AC_DEFINE_UNQUOTED(FRR_GROUP, "${enable_group}", frr Group)
 660 fi
 661
 662 if test x"${enable_vty_group}" = x"yes" ; then
 663   AC_MSG_ERROR([--enable-vty-group requires a group as argument, not yes])
 664 elif test x"${enable_vty_group}" != x""; then
 665   if test x"${enable_vty_group}" != x"no"; then
 666     AC_DEFINE_UNQUOTED(VTY_GROUP, "${enable_vty_group}", VTY Sockets Group)
 667   fi
 668 fi
 669 AC_SUBST([enable_user])
 670 AC_SUBST([enable_group])
 671 AC_SUBST([enable_vty_group])
 672
 673 enable_configfile_mask=${enable_configfile_mask:-0600}
 674 AC_DEFINE_UNQUOTED(CONFIGFILE_MASK, ${enable_configfile_mask}, Mask for config files)
 675
 676 enable_logfile_mask=${enable_logfile_mask:-0600}
 677 AC_DEFINE_UNQUOTED(LOGFILE_MASK, ${enable_logfile_mask}, Mask for log files)
 678
 679 MPATH_NUM=1
 680
 681 case "${enable_multipath}" in
 682   0)
 683     MPATH_NUM=64
 684     ;;
 685   [[1-9]|[1-9][0-9]|[1-9][0-9][0-9]])
 686     MPATH_NUM="${enable_multipath}"
 687     ;;
 688   "")
 689     ;;
 690   *)
 691     AC_MSG_FAILURE([Please specify digit to enable multipath ARG])
 692     ;;
 693 esac
 694
 695 AC_DEFINE_UNQUOTED(MULTIPATH_NUM, $MPATH_NUM, Maximum number of paths for a route)
 696
 697 AC_DEFINE_UNQUOTED(VTYSH_PAGER, "$VTYSH_PAGER", [What pager to use])
 698
 699 dnl --------------------
 700 dnl Enable code coverage
 701 dnl --------------------
 702 AM_CONDITIONAL([HAVE_GCOV],[test '!' "$enable_gcov" = no])
 703
 704 dnl ------------------------------------
 705 dnl Alpine only accepts numeric versions
 706 dnl ------------------------------------
 707 if test "x${enable_numeric_version}" != "x" ; then
 708   VERSION="`echo ${VERSION} | tr -c -d '[[.0-9]]'`"
 709   PACKAGE_VERSION="`echo ${PACKAGE_VERSION} | tr -c -d '[[.0-9]]'`"
 710 fi
 711
 712 dnl -----------------------------------
 713 dnl Add extra version string to package
 714 dnl name, string and version fields.
 715 dnl -----------------------------------
 716 if test "x${EXTRAVERSION}" != "x" ; then
 717   VERSION="${VERSION}${EXTRAVERSION}"
 718   PACKAGE_VERSION="${PACKAGE_VERSION}${EXTRAVERSION}"
 719   AC_SUBST(PACKAGE_EXTRAVERSION, ["${EXTRAVERSION}"])
 720   PACKAGE_STRING="${PACKAGE_STRING}${EXTRAVERSION}"
 721 fi
 722
 723 if test "x$with_pkg_git_version" = "xyes"; then
 724         if test -d "${srcdir}/.git"; then
 725                 AC_DEFINE(GIT_VERSION, [1], [include git version info])
 726         else    with_pkg_git_version="no"
 727                 AC_MSG_WARN([--with-pkg-git-version given, but this is not a git checkout])
 728         fi
 729 fi
 730 AM_CONDITIONAL([GIT_VERSION], [test "x$with_pkg_git_version" = "xyes"])
 731
 732 dnl ------------------------------------
 733 dnl Check C keywords and standard  types
 734 dnl ------------------------------------
 735 AC_C_CONST
 736 AC_C_INLINE
 737 AC_C_VOLATILE
 738 AC_HEADER_STDC
 739 dnl AC_TYPE_PID_T
 740 AC_TYPE_UID_T
 741 AC_TYPE_MODE_T
 742 AC_TYPE_SIZE_T
 743 AC_STRUCT_TM
 744
 745 dnl -------------------------
 746 dnl Check other header files.
 747 dnl -------------------------
 748 AC_CHECK_HEADERS([stropts.h sys/ksym.h \
 749         linux/version.h asm/types.h \
 750         sys/cdefs.h])
 751
 752 ac_stdatomic_ok=false
 753 AC_DEFINE(FRR_AUTOCONF_ATOMIC, 1, [did autoconf checks for atomic funcs])
 754 AC_CHECK_HEADER([stdatomic.h],[
 755
 756   AC_MSG_CHECKING([whether _Atomic qualifier works])
 757   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 758 #include <stdatomic.h>
 759 int main(int argc, char **argv) {
 760   _Atomic int i = 0;
 761   return i;
 762 }
 763 ]])], [
 764     AC_DEFINE(HAVE_STDATOMIC_H, 1, [found stdatomic.h])
 765     AC_MSG_RESULT([yes])
 766     ac_stdatomic_ok=true
 767   ], [
 768     AC_MSG_RESULT([no])
 769   ])
 770 ])
 771
 772 AS_IF([$ac_stdatomic_ok], [true], [
 773   AC_MSG_CHECKING([for __atomic_* builtins])
 774   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 775 int main(int argc, char **argv) {
 776   volatile int i = 1;
 777   __atomic_store_n (&i, 0, __ATOMIC_RELEASE);
 778   return __atomic_load_n (&i, __ATOMIC_ACQUIRE);
 779 }
 780 ]])], [
 781     AC_DEFINE(HAVE___ATOMIC, 1, [found __atomic builtins])
 782     AC_MSG_RESULT([yes])
 783   ], [
 784     AC_MSG_RESULT([no])
 785
 786     dnl FreeBSD 9 has a broken stdatomic.h where _Atomic doesn't work
 787     AC_MSG_CHECKING([for __sync_* builtins])
 788     AC_LINK_IFELSE([AC_LANG_SOURCE([[
 789 int main(int argc, char **argv) {
 790   volatile int i = 1;
 791   __sync_fetch_and_sub (&i, 1);
 792   return __sync_val_compare_and_swap (&i, 0, 1);
 793 }
 794 ]])], [
 795       AC_DEFINE(HAVE___SYNC, 1, [found __sync builtins])
 796       AC_MSG_RESULT([yes])
 797
 798       AC_MSG_CHECKING([for __sync_swap builtin])
 799       AC_LINK_IFELSE([AC_LANG_SOURCE([[
 800 int main(int argc, char **argv) {
 801   volatile int i = 1;
 802   return __sync_swap (&i, 2);
 803 }
 804 ]])], [
 805         AC_DEFINE(HAVE___SYNC_SWAP, 1, [found __sync_swap builtin])
 806         AC_MSG_RESULT([yes])
 807       ], [
 808         AC_MSG_RESULT([no])
 809       ])
 810
 811     ], [
 812       AC_MSG_RESULT([no])
 813       AC_MSG_FAILURE([stdatomic.h unavailable and $CC has neither __atomic nor __sync builtins])
 814     ])
 815   ])
 816 ])
 817
 818 AC_CHECK_HEADERS([pthread_np.h],,, [
 819 #include <pthread.h>
 820 ])
 821
 822 dnl Utility macro to avoid retyping includes all the time
 823 m4_define([FRR_INCLUDES],
 824 [#ifdef SUNOS_5
 825 #define _POSIX_C_SOURCE 200809L
 826 #define __EXTENSIONS__
 827 #endif
 828 #include <stdio.h>
 829 #include <stdlib.h>
 830 #include <stddef.h>
 831 #include <sys/types.h>
 832 /* sys/conf.h depends on param.h on FBSD at least */
 833 #include <sys/param.h>
 834 /* Required for MAXSIG */
 835 #include <signal.h>
 836 #include <sys/socket.h>
 837 #ifdef __APPLE__
 838 # define __APPLE_USE_RFC_3542
 839 #endif
 840 #include <netinet/in.h>
 841 #include <sys/time.h>
 842 #include <time.h>
 843 #include <net/if.h>
 844 ])dnl
 845
 846 dnl Same applies for HAVE_NET_IF_VAR_H, which HAVE_NETINET6_ND6_H and
 847 dnl HAVE_NETINET_IN_VAR_H depend upon. But if_var.h depends on if.h, hence
 848 dnl an additional round for it.
 849
 850 AC_CHECK_HEADERS([net/if_var.h], [], [], FRR_INCLUDES)
 851
 852 m4_define([FRR_INCLUDES],
 853 FRR_INCLUDES
 854 [#if HAVE_NET_IF_VAR_H
 855 # include <net/if_var.h>
 856 #endif
 857 ])dnl
 858
 859 AC_CHECK_HEADERS([netinet/in_var.h \
 860         net/if_dl.h net/netopt.h \
 861         inet/nd.h netinet/ip_icmp.h \
 862         sys/sysctl.h sys/sockio.h kvm.h sys/conf.h],
 863         [], [], FRR_INCLUDES)
 864
 865 AC_CHECK_HEADERS([ucontext.h], [], [],
 866 [#ifndef __USE_GNU
 867 #define __USE_GNU
 868 #endif /* __USE_GNU */
 869 FRR_INCLUDES
 870 ])
 871
 872 m4_define([UCONTEXT_INCLUDES],
 873 [#include <ucontext.h>])dnl
 874
 875 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.uc_regs],
 876   [], [], [UCONTEXT_INCLUDES])
 877 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs],
 878   [AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs.nip],
 879    [], [], [UCONTEXT_INCLUDES])],
 880   [], [UCONTEXT_INCLUDES])
 881 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.gregs],
 882   [], [], [UCONTEXT_INCLUDES])
 883
 884 m4_define([FRR_INCLUDES],
 885 FRR_INCLUDES
 886 [
 887 #include <sys/un.h>
 888 #include <netinet/in_systm.h>
 889 #if HAVE_NETINET_IN_VAR_H
 890 # include <netinet/in_var.h>
 891 #endif
 892 #if HAVE_NET_IF_DL_H
 893 # include <net/if_dl.h>
 894 #endif
 895 #if HAVE_NET_NETOPT_H
 896 # include <net/netopt.h>
 897 #endif
 898 #include <net/route.h>
 899 #if HAVE_INET_ND_H
 900 # include <inet/nd.h>
 901 #endif
 902 #include <arpa/inet.h>
 903 /* Required for IDRP */
 904 #if HAVE_NETINET_IP_ICMP_H
 905 # include <netinet/ip_icmp.h>
 906 #endif
 907 ])dnl
 908
 909 dnl V6 headers are checked below, after we check for v6
 910
 911 AC_MSG_CHECKING([which operating system interface to use])
 912 case "$host_os" in
 913   sunos* | solaris2*)
 914     AC_MSG_RESULT([Solaris])
 915
 916     AC_DEFINE(SUNOS_5, 1, [SunOS 5])
 917     AC_DEFINE(SOLARIS_IPV6, 1, Solaris IPv6)
 918     AC_DEFINE(_POSIX_C_SOURCE, 200809L, [enable POSIX.1-2008 and XPG7/SUSv4])
 919
 920     AC_CHECK_LIB(socket, main)
 921     AC_CHECK_LIB(nsl, main)
 922     AC_CHECK_LIB(umem, main)
 923     AC_CHECK_FUNCS([printstack], [
 924       AC_DEFINE([HAVE_PRINTSTACK],1,[Solaris printstack])
 925       AC_DEFINE([HAVE_STACK_TRACE],1,[Stack symbols decode functionality])
 926     ])
 927     CURSES=-lcurses
 928     SOLARIS="solaris"
 929     ;;
 930   linux*)
 931     AC_MSG_RESULT([Linux])
 932
 933     AC_DEFINE(GNU_LINUX,,GNU Linux)
 934     AC_DEFINE(HAVE_NETLINK,,netlink)
 935     AC_DEFINE(LINUX_IPV6,1,Linux IPv6 stack)
 936
 937     dnl Linux has a compilation problem with mixing
 938     dnl netinet/in.h and linux/in6.h they are not
 939     dnl compatible.  There has been discussion on
 940     dnl how to fix it but no real progress on implementation
 941     dnl when they fix it, remove this
 942     AC_DEFINE(IPV6_MINHOPCOUNT, 73, Linux ipv6 Min Hop Count)
 943     ;;
 944   openbsd*)
 945     AC_MSG_RESULT([OpenBSD])
 946
 947     AC_DEFINE(OPEN_BSD,,OpenBSD)
 948     AC_DEFINE(KAME,1,KAME IPv6)
 949     AC_DEFINE(BSD_V6_SYSCTL,1,BSD v6 sysctl to turn on and off forwarding)
 950
 951     if test "x${enable_pimd}" != "xno"; then
 952       case "$host_os" in
 953       openbsd6.0)
 954         ;;
 955       openbsd[6-9]*)
 956         AC_MSG_FAILURE([pimd cannot be enabled as PIM support has been removed from OpenBSD 6.1])
 957         ;;
 958       esac
 959     fi
 960     ;;
 961   *)
 962     AC_MSG_RESULT([BSD])
 963
 964     AC_DEFINE(HAVE_NET_RT_IFLIST,,NET_RT_IFLIST)
 965     AC_DEFINE(KAME,1,KAME IPv6)
 966     AC_DEFINE(BSD_V6_SYSCTL,1,BSD v6 sysctl to turn on and off forwarding)
 967     ;;
 968 esac
 969 AM_CONDITIONAL(SOLARIS, test "${SOLARIS}" = "solaris")
 970
 971 AC_SYS_LARGEFILE
 972
 973 dnl ------------------------
 974 dnl Integrated REALMS option
 975 dnl ------------------------
 976 if test "${enable_realms}" = "yes"; then
 977     case "$host_os" in
 978       linux*)
 979        AC_DEFINE(SUPPORT_REALMS,, Realms support)
 980        ;;
 981       *)
 982        echo "Sorry, only Linux has REALMS support"
 983        exit 1
 984        ;;
 985     esac
 986 fi
 987 AM_CONDITIONAL([SUPPORT_REALMS], [test "${enable_realms}" = "yes"])
 988
 989 dnl ---------------------
 990 dnl Integrated VTY option
 991 dnl ---------------------
 992 case "${enable_vtysh}" in
 993   "no") VTYSH="";;
 994   *)    VTYSH="vtysh";
 995          AC_DEFINE(VTYSH,,VTY shell)
 996 dnl      Vtysh uses libreadline, which looks for termcap functions at
 997 dnl      configure time.  We follow readlines search order.
 998 dnl      The required procedures are in libtermcap on NetBSD, in
 999 dnl      [TODO] on Linux, and in [TODO] on Solaris.
1000          AC_CHECK_LIB(termcap, tputs, LIBREADLINE="$LIBREADLINE -ltermcap",
1001            [AC_CHECK_LIB(tinfo, tputs, LIBREADLINE="$LIBREADLINE -ltinfo",
1002              [AC_CHECK_LIB(curses, tputs, LIBREADLINE="$LIBREADLINE -lcurses",
1003                [AC_CHECK_LIB(ncurses, tputs,
1004                              LIBREADLINE="$LIBREADLINE -lncurses")]
1005               )]
1006             )]
1007           )
1008          AC_CHECK_LIB(readline, main, LIBREADLINE="-lreadline $LIBREADLINE",,
1009                       "$LIBREADLINE")
1010          if test $ac_cv_lib_readline_main = no; then
1011            AC_MSG_ERROR([vtysh needs libreadline but was not found and usable on your system.])
1012          fi
1013          AC_CHECK_HEADER(readline/history.h)
1014          if test $ac_cv_header_readline_history_h = no;then
1015            AC_MSG_ERROR([readline is too old to have readline/history.h, please update to the latest readline library.])
1016          fi
1017          AC_CHECK_LIB(readline, rl_completion_matches,
1018                       LIBREADLINE="$LIBREADLINE",, "$LIBREADLINE")
1019          if test $ac_cv_lib_readline_rl_completion_matches = no; then
1020            AC_DEFINE(rl_completion_matches,completion_matches,Old readline)
1021          fi
1022          AC_SEARCH_LIBS([append_history], [readline], [frr_cv_append_history=yes], [frr_cv_append_history=no])
1023          if test "$frr_cv_append_history" = yes; then
1024            AC_DEFINE(HAVE_APPEND_HISTORY, 1, [Have history.h append_history])
1025          fi
1026          ;;
1027 esac
1028 AC_SUBST(LIBREADLINE)
1029 AM_CONDITIONAL(VTYSH, test "x$VTYSH" = "xvtysh")
1030
1031 dnl ----------
1032 dnl PAM module
1033 dnl
1034 dnl FRR detects the PAM library it is built against by checking for a
1035 dnl functional pam_misc.h (Linux-PAM) or openpam.h (OpenPAM) header. pam_misc.h
1036 dnl is known to #include pam_appl.h, the standard header of a PAM library, and
1037 dnl openpam.h doesn't do that, although depends on the header too. Hence a
1038 dnl little assistance to AC_CHECK_HEADER is necessary for the proper detection
1039 dnl of OpenPAM.
1040 dnl ----------
1041 if test "$with_libpam" = "yes"; then
1042   AC_CHECK_HEADER([security/pam_misc.h],
1043     [AC_DEFINE(HAVE_PAM_MISC_H,,Have pam_misc.h)
1044      AC_DEFINE(PAM_CONV_FUNC,misc_conv,Have misc_conv)
1045      pam_conv_func="misc_conv"
1046     ],
1047     [], FRR_INCLUDES)
1048   AC_CHECK_HEADER([security/openpam.h],
1049     [AC_DEFINE(HAVE_OPENPAM_H,,Have openpam.h)
1050      AC_DEFINE(PAM_CONV_FUNC,openpam_ttyconv,Have openpam_ttyconv)
1051      pam_conv_func="openpam_ttyconv"
1052     ],
1053     [], FRR_INCLUDES[#include <security/pam_appl.h>])
1054   if test -z "$ac_cv_header_security_pam_misc_h$ac_cv_header_security_openpam_h" ; then
1055     AC_MSG_WARN([*** pam support will not be built ***])
1056     with_libpam="no"
1057   fi
1058 fi
1059
1060 if test "$with_libpam" = "yes"; then
1061 dnl took this test from proftpds configure.in and suited to our needs
1062 dnl -------------------------------------------------------------------------
1063 dnl
1064 dnl This next check looks funky due to a linker problem with some versions
1065 dnl of the PAM library.  Prior to 0.72 release, the Linux PAM shared library
1066 dnl omitted requiring libdl linking information. PAM-0.72 or better ships
1067 dnl with RedHat 6.2 and Debian 2.2 or better.
1068 AC_CHECK_LIB(pam, pam_start,
1069   [AC_CHECK_LIB(pam, $pam_conv_func,
1070     [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1071      LIBPAM="-lpam"],
1072     [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1073      LIBPAM="-lpam -lpam_misc"]
1074     )
1075   ],
1076
1077   [AC_CHECK_LIB(pam, pam_end,
1078     [AC_CHECK_LIB(pam, $pam_conv_func,
1079       [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1080        LIBPAM="-lpam -ldl"],
1081       [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1082        LIBPAM="-lpam -ldl -lpam_misc"]
1083      )
1084   ],AC_MSG_WARN([*** pam support will not be built ***]),
1085   [-ldl])
1086   ]
1087 )
1088 fi
1089 AC_SUBST(LIBPAM)
1090
1091 dnl -------------------------------
1092 dnl Endian-ness check
1093 dnl -------------------------------
1094 AC_WORDS_BIGENDIAN
1095
1096 dnl -------------------------------
1097 dnl check the size in byte of the C
1098 dnl -------------------------------
1099 dnl AC_CHECK_SIZEOF(char)
1100 dnl AC_CHECK_SIZEOF(int)
1101 dnl AC_CHECK_SIZEOF(short)
1102 dnl AC_CHECK_SIZEOF(long)
1103
1104 dnl ----------------------------
1105 dnl check existance of functions
1106 dnl ----------------------------
1107 AC_FUNC_FNMATCH
1108 AC_FUNC_FORK
1109 AC_FUNC_MKTIME
1110 AC_FUNC_STAT
1111
1112 dnl -------------------------------
1113 dnl bgpd needs pow() and hence libm
1114 dnl -------------------------------
1115 TMPLIBS="$LIBS"
1116 AC_CHECK_HEADER([math.h],
1117   [AC_CHECK_LIB([m], [pow],
1118     [LIBM="-lm"
1119      LIBS="$LIBS $LIBM"
1120      AC_CHECK_FUNCS(pow,[],[LIBM=""])
1121     ])
1122 ])
1123 if test x"$LIBM" = x ; then
1124   AC_MSG_WARN([Unable to find working pow function - bgpd may not link])
1125 fi
1126 LIBS="$TMPLIBS"
1127 AC_SUBST(LIBM)
1128
1129 AC_CHECK_FUNCS([ppoll], [
1130   AC_DEFINE([HAVE_PPOLL], 1, [have Linux/BSD ppoll()])
1131 ])
1132 AC_CHECK_FUNCS([pollts], [
1133   AC_DEFINE([HAVE_POLLTS], 1, [have NetBSD pollts()])
1134 ])
1135
1136 dnl ---------------
1137 dnl other functions
1138 dnl ---------------
1139 AC_CHECK_FUNCS([ \
1140         strlcat strlcpy \
1141         getgrouplist])
1142
1143 AC_CHECK_HEADER([asm-generic/unistd.h],
1144                 [AC_CHECK_DECL(__NR_setns,
1145                                AC_DEFINE(HAVE_NETNS,, Have netns),,
1146                                FRR_INCLUDES [#include <asm-generic/unistd.h>
1147                                ])
1148                  AC_CHECK_FUNCS(setns)]
1149                )
1150
1151 dnl --------------------------
1152 dnl Determine IS-IS I/O method
1153 dnl --------------------------
1154 AC_DEFINE(ISIS_METHOD_PFPACKET, 1, [ constant value for isis method pfpacket ])
1155 AC_DEFINE(ISIS_METHOD_DLPI,     2, [ constant value for isis method dlpi ])
1156 AC_DEFINE(ISIS_METHOD_BPF,      3, [ constant value for isis method bpf ])
1157 AC_CHECK_HEADER(net/bpf.h)
1158 AC_CHECK_HEADER(sys/dlpi.h)
1159 AC_MSG_CHECKING(zebra IS-IS I/O method)
1160
1161 case "$host_os" in
1162   linux*)
1163     AC_MSG_RESULT(pfpacket)
1164     ISIS_METHOD_MACRO="ISIS_METHOD_PFPACKET"
1165     ;;
1166   solaris* | sunos*)
1167     AC_MSG_RESULT(DLPI)
1168     ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1169     ;;
1170   *)
1171     if test $ac_cv_header_net_bpf_h = no; then
1172       if test $ac_cv_header_sys_dlpi_h = no; then
1173         AC_MSG_RESULT(none)
1174         if test "${enable_isisd}" = yes -o "${enable_fabricd}" = yes; then
1175           AC_MSG_FAILURE([IS-IS support requested but no packet backend found])
1176         fi
1177         AC_MSG_WARN([*** IS-IS support will not be built ***])
1178         enable_isisd="no"
1179         enable_fabricd="no"
1180       else
1181         AC_MSG_RESULT(DLPI)
1182       fi
1183       ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1184     else
1185       AC_MSG_RESULT(BPF)
1186       ISIS_METHOD_MACRO="ISIS_METHOD_BPF"
1187     fi
1188     ;;
1189 esac
1190 AC_DEFINE_UNQUOTED(ISIS_METHOD, $ISIS_METHOD_MACRO, [ selected method for isis, == one of the constants ])
1191
1192 dnl ---------------------------------------------------------------
1193 dnl figure out how to specify an interface in multicast sockets API
1194 dnl ---------------------------------------------------------------
1195 AC_CHECK_MEMBERS([struct ip_mreqn.imr_ifindex], [], [], FRR_INCLUDES)
1196
1197 AC_CHECK_HEADERS([linux/mroute.h], [], [],[
1198         #include <sys/socket.h>
1199         #include <netinet/in.h>
1200         #define _LINUX_IN_H             /* For Linux <= 2.6.25 */
1201         #include <linux/types.h>
1202 ])
1203
1204 m4_define([FRR_INCLUDES],
1205 FRR_INCLUDES
1206 [#if HAVE_LINUX_MROUTE_H
1207 # include <linux/mroute.h>
1208 #endif
1209 ])dnl
1210
1211 AC_CHECK_HEADERS([netinet/ip_mroute.h], [], [],[
1212         #include <sys/socket.h>
1213         #include <sys/types.h>
1214         #include <netinet/in.h>
1215         #include <net/route.h>
1216 ])
1217
1218 m4_define([FRR_INCLUDES],
1219 FRR_INCLUDES
1220 [#if HAVE_NETINET_IP_MROUTE_H
1221 # include <netinet/ip_mroute.h>
1222 #endif
1223 ])dnl
1224
1225 AC_MSG_CHECKING([for BSD struct ip_mreq hack])
1226 AC_TRY_COMPILE([#include <sys/param.h>],
1227 [#if (defined(__FreeBSD__) && ((__FreeBSD_version >= 500022 && __FreeBSD_version < 700000) || (__FreeBSD_version < 500000 && __FreeBSD_version >= 440000))) || (defined(__NetBSD__) && defined(__NetBSD_Version__) && __NetBSD_Version__ >= 106010000) || defined(__OpenBSD__) || defined(__APPLE__) || defined(__DragonFly__) || defined(__sun)
1228   return (0);
1229 #else
1230   #error No support for BSD struct ip_mreq hack detected
1231 #endif],[AC_MSG_RESULT(yes)
1232 AC_DEFINE(HAVE_BSD_STRUCT_IP_MREQ_HACK,,[Can pass ifindex in struct ip_mreq])],
1233 AC_MSG_RESULT(no))
1234
1235 AC_MSG_CHECKING([for RFC3678 protocol-independed API])
1236 AC_TRY_COMPILE([
1237 #include <sys/types.h>
1238 #include <netinet/in.h>
1239 ], [struct group_req gr; int sock; setsockopt(sock, IPPROTO_IP, MCAST_JOIN_GROUP, (void*)&gr, sizeof(gr));
1240 ], [AC_MSG_RESULT(yes)
1241 AC_DEFINE(HAVE_RFC3678,1,[Have RFC3678 protocol-independed API])],
1242 AC_MSG_RESULT(no))
1243
1244 dnl ---------------------------------------------------------------
1245 dnl figure out how to check link-state
1246 dnl ---------------------------------------------------------------
1247 AC_CHECK_HEADER( [net/if_media.h],
1248   [m4_define([LINK_DETECT_INCLUDES],
1249     FRR_INCLUDES
1250     [#include <net/if_media.h>
1251   ])
1252   AC_CHECK_MEMBERS( [struct ifmediareq.ifm_status],
1253     AC_DEFINE(HAVE_BSD_LINK_DETECT,,[BSD link-detect]),
1254     [], LINK_DETECT_INCLUDES)],
1255   [],
1256   FRR_INCLUDES)
1257
1258 dnl ---------------------------------------------------------------
1259 dnl Additional, newer way to check link-state using ifi_link_state.
1260 dnl Not available in all BSD's when ifmediareq available
1261 dnl ---------------------------------------------------------------
1262 AC_CHECK_MEMBERS([struct if_data.ifi_link_state],
1263   AC_DEFINE(HAVE_BSD_IFI_LINK_STATE,,[BSD ifi_link_state available]),
1264   [], FRR_INCLUDES)
1265
1266 dnl ------------------------
1267 dnl TCP_MD5SIG socket option
1268 dnl ------------------------
1269
1270 AC_CHECK_HEADER([netinet/tcp.h],
1271    [m4_define([MD5_INCLUDES],
1272       FRR_INCLUDES
1273       [#include <netinet/tcp.h>
1274     ])
1275     AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)],
1276    [],
1277    FRR_INCLUDES)
1278 if test $ac_cv_have_decl_TCP_MD5SIG = no; then
1279   AC_CHECK_HEADER([linux/tcp.h],
1280        [m4_define([MD5_INCLUDES],
1281           FRR_INCLUDES
1282           [#include <linux/tcp.h>
1283         ])
1284        AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)])
1285 fi
1286
1287 dnl ----------------------------------------------------------------------------
1288 dnl figure out if domainname is available in the utsname struct (GNU extension).
1289 dnl ----------------------------------------------------------------------------
1290 AC_CHECK_MEMBERS([struct utsname.domainname], [], [], [#include <sys/utsname.h>])
1291
1292 dnl ------------------
1293 dnl IPv6 header checks
1294 dnl ------------------
1295 AC_CHECK_HEADERS([netinet6/in6.h netinet/in6_var.h \
1296         netinet6/in6_var.h netinet6/nd6.h], [], [],
1297         FRR_INCLUDES)
1298
1299 m4_define([FRR_INCLUDES],dnl
1300 FRR_INCLUDES
1301 [#if HAVE_NETINET6_IN6_H
1302 #include <netinet6/in6.h>
1303 #endif
1304 #if HAVE_NETINET_IN6_VAR_H
1305 #include <netinet/in6_var.h>
1306 #endif
1307 #include <netinet/icmp6.h>
1308 #if HAVE_NETINET6_IN6_VAR_H
1309 # include <netinet6/in6_var.h>
1310 #endif
1311 #if HAVE_NETINET6_ND6_H
1312 # include <netinet6/nd6.h>
1313 #endif
1314 ])dnl
1315
1316 dnl disable doc check
1317 AC_CHECK_PROGS([SPHINXBUILD], [sphinx-build sphinx-build3 sphinx-build2], [no])
1318 AM_CONDITIONAL(DOC, test "${enable_doc}" != "no")
1319 AM_CONDITIONAL(DOC_HTML, test "${enable_doc_html}" = "yes")
1320
1321 dnl --------------------
1322 dnl Daemon disable check
1323 dnl --------------------
1324 AM_CONDITIONAL(ZEBRA, test "${enable_zebra}" != "no")
1325
1326 if test "${enable_bgpd}" = "no";then
1327   BGPD=""
1328 else
1329   BGPD="bgpd"
1330 fi
1331 AM_CONDITIONAL(BGPD, test "x$BGPD" = "xbgpd")
1332
1333 AM_CONDITIONAL(RIPD, test "${enable_ripd}" != "no")
1334 AM_CONDITIONAL(OSPFD, test "${enable_ospfd}" != "no")
1335 AM_CONDITIONAL(LDPD, test "${enable_ldpd}" != "no")
1336
1337 AS_IF([test "${enable_ldpd}" != "no"], [
1338   AC_DEFINE(HAVE_LDPD, 1, ldpd)
1339 ])
1340
1341 if test "$enable_bfdd" = "no"; then
1342   AC_DEFINE(HAVE_BFDD, 0, bfdd)
1343   BFDD=""
1344 else
1345   AC_DEFINE(HAVE_BFDD, 1, bfdd)
1346   BFDD="bfdd"
1347
1348   case $host_os in
1349     linux*)
1350       AC_DEFINE(BFD_LINUX, 1, bfdd)
1351       ;;
1352
1353     *)
1354       AC_DEFINE(BFD_BSD, 1, bfdd)
1355       ;;
1356   esac
1357 fi
1358
1359 AM_CONDITIONAL(BFDD, [test "x$BFDD" = "xbfdd"])
1360
1361 if test $ac_cv_lib_json_c_json_object_get = no -a "x$BFDD" = "xbfdd"; then
1362   AC_MSG_ERROR(["you must use json-c library to use bfdd"])
1363 fi
1364
1365 NHRPD=""
1366 case "$host_os" in
1367   linux*)
1368     if test "${enable_nhrpd}" != "no"; then
1369       NHRPD="nhrpd"
1370     fi
1371     ;;
1372   *)
1373     if test "${enable_nhrpd}" = "yes"; then
1374       AC_MSG_ERROR([nhrpd requires kernel APIs that are only present on Linux.])
1375     fi
1376     ;;
1377 esac
1378 AM_CONDITIONAL(NHRPD, test "x$NHRPD" = "xnhrpd")
1379
1380 AM_CONDITIONAL(EIGRPD, test "${enable_eigrpd}" != "no")
1381
1382 if test "${enable_watchfrr}" = "no";then
1383   WATCHFRR=""
1384 else
1385   WATCHFRR="watchfrr"
1386 fi
1387 AM_CONDITIONAL(WATCHFRR, test "x$WATCHFRR" = "xwatchfrr")
1388
1389 OSPFCLIENT=""
1390 if test "${enable_ospfapi}" != "no";then
1391     AC_DEFINE(SUPPORT_OSPF_API,,OSPFAPI)
1392
1393   if test "${enable_ospfclient}" != "no";then
1394       OSPFCLIENT="ospfclient"
1395   fi
1396 fi
1397
1398 AM_CONDITIONAL(OSPFCLIENT, test "x$OSPFCLIENT" = "xospfclient")
1399 AM_CONDITIONAL(RIPNGD, test "${enable_ripngd}" != "no")
1400 AM_CONDITIONAL(BABELD, test "${enable_babeld}" != "no")
1401 AM_CONDITIONAL(OSPF6D, test "${enable_ospf6d}" != "no")
1402 AM_CONDITIONAL(ISISD, test "${enable_isisd}" != "no")
1403 AM_CONDITIONAL(PIMD, test "${enable_pimd}" != "no")
1404 AM_CONDITIONAL(PBRD, test "${enable_pbrd}" != "no")
1405 AM_CONDITIONAL(SHARPD, test "${enable_sharpd}" = "yes")
1406 AM_CONDITIONAL(STATICD, test "${enable_staticd}" != "no")
1407 AM_CONDITIONAL(FABRICD, test "${enable_fabricd}" != "no")
1408
1409 if test "${enable_bgp_announce}" = "no";then
1410   AC_DEFINE(DISABLE_BGP_ANNOUNCE,1,Disable BGP installation to zebra)
1411 else
1412   AC_DEFINE(DISABLE_BGP_ANNOUNCE,0,Disable BGP installation to zebra)
1413 fi
1414
1415 if test "${enable_bgp_vnc}" != "no";then
1416   AC_DEFINE(ENABLE_BGP_VNC,1,Enable BGP VNC support)
1417 fi
1418 AM_CONDITIONAL([ENABLE_BGP_VNC], [test x${enable_bgp_vnc} != xno])
1419
1420 AC_SUBST(SOLARIS)
1421 AC_SUBST(CURSES)
1422 AC_CHECK_LIB(crypt, crypt, [],
1423                     [AC_CHECK_LIB(crypto, DES_crypt)])
1424 AC_CHECK_LIB(resolv, res_init)
1425
1426 dnl ---------------------------
1427 dnl check system has PCRE regexp
1428 dnl ---------------------------
1429 if test "x$enable_pcreposix" = "xyes"; then
1430   AC_CHECK_LIB(pcreposix, regexec, [], [
1431     AC_MSG_ERROR([--enable-pcreposix given but unable to find libpcreposix])
1432   ])
1433 fi
1434 AC_SUBST(HAVE_LIBPCREPOSIX)
1435
1436 dnl ------------------
1437 dnl check C-Ares library
1438 dnl ------------------
1439 if test "${NHRPD}" != ""; then
1440   PKG_CHECK_MODULES([CARES], [libcares], , [
1441     AC_MSG_ERROR([trying to build nhrpd, but libcares not found. install c-ares and its -dev headers.])
1442   ])
1443 fi
1444
1445
1446 dnl ------------------
1447 dnl check Net-SNMP library
1448 dnl ------------------
1449 if test "${enable_snmp}" != "" -a "${enable_snmp}" != "no"; then
1450    AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], [no])
1451    if test x"$NETSNMP_CONFIG" = x"no"; then
1452       AC_MSG_ERROR([--enable-snmp given but unable to find net-snmp-config])
1453    fi
1454    SNMP_LIBS="`${NETSNMP_CONFIG} --agent-libs`"
1455    SNMP_CFLAGS="`${NETSNMP_CONFIG} --base-cflags`"
1456    AC_MSG_CHECKING([whether we can link to Net-SNMP])
1457    AC_LINK_IFELSE_FLAGS([$SNMP_CFLAGS], [$SNMP_LIBS], [AC_LANG_PROGRAM([
1458 int main(void);
1459 ],
1460 [
1461 {
1462   return 0;
1463 }
1464 ])], [
1465      AC_MSG_ERROR([--enable-snmp given but not usable])])
1466    case "${enable_snmp}" in
1467      yes)
1468       SNMP_METHOD=agentx
1469       ;;
1470      agentx)
1471       SNMP_METHOD="${enable_snmp}"
1472       ;;
1473      *)
1474       AC_MSG_ERROR([--enable-snmp given with an unknown method (${enable_snmp}). Use yes or agentx])
1475       ;;
1476    esac
1477    AH_TEMPLATE([SNMP_AGENTX], [Use SNMP AgentX to interface with snmpd])
1478    AC_DEFINE_UNQUOTED(AS_TR_CPP(SNMP_${SNMP_METHOD}),,SNMP method to interface with snmpd)
1479 fi
1480 AM_CONDITIONAL([SNMP], [test "x${SNMP_METHOD}" != "x"])
1481 AC_SUBST(SNMP_LIBS)
1482 AC_SUBST(SNMP_CFLAGS)
1483
1484 dnl ---------------
1485 dnl math
1486 dnl ---------------
1487 AC_SEARCH_LIBS([sqrt], [m])
1488
1489 dnl ---------------
1490 dnl dlopen & dlinfo
1491 dnl ---------------
1492 AC_SEARCH_LIBS(dlopen, [dl dld], [], [
1493   AC_MSG_ERROR([unable to find the dlopen()])
1494 ])
1495
1496 AC_CHECK_HEADERS([link.h])
1497
1498 AC_CACHE_CHECK([for dlinfo(RTLD_DI_ORIGIN)], [frr_cv_rtld_di_origin], [
1499   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1500 #include <stdlib.h>
1501 #ifdef HAVE_LINK_H
1502 #include <link.h>
1503 #endif
1504 #include <dlfcn.h>
1505 ]], [[
1506   char origin[1];
1507   dlinfo (NULL, RTLD_DI_ORIGIN, &origin);
1508 ]])], [
1509     frr_cv_rtld_di_origin=yes
1510   ], [
1511     frr_cv_rtld_di_origin=no
1512   ])
1513 ])
1514 if test "$frr_cv_rtld_di_origin" = yes; then
1515   AC_DEFINE(HAVE_DLINFO_ORIGIN, 1, [Have dlinfo RTLD_DI_ORIGIN])
1516 fi
1517
1518 AC_CACHE_CHECK([for dlinfo(RTLD_DI_LINKMAP)], [frr_cv_rtld_di_linkmap], [
1519   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1520 #include <stdlib.h>
1521 #ifdef HAVE_LINK_H
1522 #include <link.h>
1523 #endif
1524 #include <dlfcn.h>
1525 ]], [[
1526   struct link_map *lm = NULL;
1527   dlinfo (NULL, RTLD_DI_LINKMAP, &lm);
1528 ]])], [
1529     frr_cv_rtld_di_linkmap=yes
1530   ], [
1531     frr_cv_rtld_di_linkmap=no
1532   ])
1533 ])
1534 if test "$frr_cv_rtld_di_linkmap" = yes; then
1535   AC_DEFINE(HAVE_DLINFO_LINKMAP, 1, [Have dlinfo RTLD_DI_LINKMAP])
1536 fi
1537
1538 AM_CONDITIONAL(SNMP, test "x$SNMP_METHOD" = "xagentx")
1539
1540 dnl ---------------------------
1541 dnl sockaddr and netinet checks
1542 dnl ---------------------------
1543 AC_CHECK_TYPES([
1544         struct sockaddr_dl,
1545         struct vifctl, struct mfcctl, struct sioc_sg_req,
1546         vifi_t, struct sioc_vif_req, struct igmpmsg,
1547         struct ifaliasreq, struct if6_aliasreq, struct in6_aliasreq,
1548         struct nd_opt_adv_interval, struct rt_addrinfo,
1549         struct nd_opt_homeagent_info, struct nd_opt_adv_interval],
1550         [], [], FRR_INCLUDES)
1551
1552 AC_CHECK_MEMBERS([struct sockaddr.sa_len,
1553         struct sockaddr_in.sin_len, struct sockaddr_un.sun_len,
1554         struct sockaddr_dl.sdl_len,
1555         struct if6_aliasreq.ifra_lifetime,
1556         struct nd_opt_adv_interval.nd_opt_ai_type],
1557         [], [], FRR_INCLUDES)
1558
1559 dnl ---------------------------
1560 dnl IRDP/pktinfo/icmphdr checks
1561 dnl ---------------------------
1562
1563 AC_CHECK_TYPES([struct in_pktinfo], [
1564   AC_CHECK_TYPES([struct icmphdr], [
1565     IRDP=true
1566   ], [
1567     IRDP=false
1568   ], [FRR_INCLUDES])
1569 ], [
1570   IRDP=false
1571 ], [FRR_INCLUDES])
1572
1573 case "${enable_irdp}" in
1574 yes)
1575   $IRDP || AC_MSG_ERROR(['IRDP requires in_pktinfo at the moment!'])
1576   ;;
1577 no)
1578   IRDP=false
1579   ;;
1580 esac
1581
1582 AM_CONDITIONAL(IRDP, $IRDP)
1583
1584 dnl -----------------------
1585 dnl checking for IP_PKTINFO
1586 dnl -----------------------
1587 AC_MSG_CHECKING(for IP_PKTINFO)
1588 AC_TRY_COMPILE([#include <netdb.h>], [
1589   int opt = IP_PKTINFO;
1590 ], [
1591   AC_MSG_RESULT(yes)
1592   AC_DEFINE(HAVE_IP_PKTINFO, 1, [Have IP_PKTINFO])
1593 ], [
1594   AC_MSG_RESULT(no)
1595 ])
1596
1597 dnl ---------------------------
1598 dnl checking for IP_RECVDSTADDR
1599 dnl ---------------------------
1600 AC_MSG_CHECKING(for IP_RECVDSTADDR)
1601 AC_TRY_COMPILE([#include <netinet/in.h>], [
1602   int opt = IP_RECVDSTADDR;
1603 ], [
1604   AC_MSG_RESULT(yes)
1605   AC_DEFINE(HAVE_IP_RECVDSTADDR, 1, [Have IP_RECVDSTADDR])
1606 ], [
1607   AC_MSG_RESULT(no)
1608 ])
1609
1610 dnl ----------------------
1611 dnl checking for IP_RECVIF
1612 dnl ----------------------
1613 AC_MSG_CHECKING(for IP_RECVIF)
1614 AC_TRY_COMPILE([#include <netinet/in.h>], [
1615   int opt = IP_RECVIF;
1616 ], [
1617   AC_MSG_RESULT(yes)
1618   AC_DEFINE(HAVE_IP_RECVIF, 1, [Have IP_RECVIF])
1619 ], [
1620   AC_MSG_RESULT(no)
1621 ])
1622
1623 dnl ----------------------
1624 dnl checking for SO_BINDANY
1625 dnl ----------------------
1626 AC_MSG_CHECKING(for SO_BINDANY)
1627 AC_TRY_COMPILE([#include <sys/socket.h>], [
1628   int opt = SO_BINDANY;
1629 ], [
1630   AC_MSG_RESULT(yes)
1631   AC_DEFINE(HAVE_SO_BINDANY, 1, [Have SO_BINDANY])
1632 ], [
1633   AC_MSG_RESULT(no)
1634 ])
1635
1636 dnl ----------------------
1637 dnl checking for IP_FREEBIND
1638 dnl ----------------------
1639 AC_MSG_CHECKING(for IP_FREEBIND)
1640 AC_TRY_COMPILE([#include <netinet/in.h>], [
1641   int opt = IP_FREEBIND;
1642 ], [
1643   AC_MSG_RESULT(yes)
1644   AC_DEFINE(HAVE_IP_FREEBIND, 1, [Have IP_FREEBIND])
1645 ], [
1646   AC_MSG_RESULT(no)
1647 ])
1648
1649 dnl --------------------------------------
1650 dnl checking for be32dec existence or not
1651 dnl --------------------------------------
1652 AC_CHECK_DECLS([be32enc, be32dec], [], [],
1653                [#include <sys/endian.h>])
1654
1655 dnl --------------------------------------
1656 dnl checking for clock_time monotonic struct and call
1657 dnl --------------------------------------
1658 AC_CHECK_DECL(CLOCK_MONOTONIC,
1659         [AC_CHECK_LIB(rt, clock_gettime, [LIBS="$LIBS -lrt"])
1660          AC_DEFINE(HAVE_CLOCK_MONOTONIC,, Have monotonic clock)
1661 ], [AC_MSG_RESULT(no)], [FRR_INCLUDES])
1662
1663 dnl --------------------------------------
1664 dnl checking for flex and bison
1665 dnl --------------------------------------
1666
1667 AM_PROG_LEX
1668 AC_MSG_CHECKING(version of flex)
1669 frr_ac_flex_version="$(eval $LEX -V | grep flex | head -n 1)"
1670 frr_ac_flex_version="${frr_ac_flex_version##* }"
1671 AC_MSG_RESULT([$frr_ac_flex_version])
1672 AX_COMPARE_VERSION([$frr_ac_flex_version], [lt], [2.5.20], [
1673   LEX="$SHELL $missing_dir/missing flex"
1674   if test -f "${srcdir}/lib/command_lex.c" -a -f "${srcdir}/lib/command_lex.h"; then
1675     AC_MSG_WARN([using pregenerated flex output files])
1676   else
1677     AC_MSG_ERROR([flex failure and pregenerated files not included (probably a git build)])
1678   fi
1679   AC_SUBST([LEX_OUTPUT_ROOT], [lex.yy])
1680   AC_SUBST([LEXLIB], [''])
1681 ])
1682
1683 AC_PROG_YACC
1684 dnl thanks GNU bison for this b*llshit...
1685 AC_MSG_CHECKING(version of bison)
1686 frr_ac_bison_version="$(eval $YACC -V | grep bison | head -n 1)"
1687 frr_ac_bison_version="${frr_ac_bison_version##* }"
1688 frr_ac_bison_missing="false"
1689 case "x${frr_ac_bison_version}" in
1690   x2.7*)
1691     BISON_OPENBRACE='"'
1692     BISON_CLOSEBRACE='"'
1693     BISON_VERBOSE=''
1694     AC_MSG_RESULT([$frr_ac_bison_version - 2.7 or older])
1695     ;;
1696   x2.*|x1.*)
1697     AC_MSG_RESULT([$frr_ac_bison_version])
1698     AC_MSG_WARN([installed bison is too old.  Please install GNU bison 2.7.x or newer.])
1699     frr_ac_bison_missing="true"
1700     ;;
1701   x)
1702     AC_MSG_RESULT([none])
1703     AC_MSG_WARN([could not determine bison version.  Please install GNU bison 2.7.x or newer.])
1704     frr_ac_bison_missing="true"
1705     ;;
1706   *)
1707     BISON_OPENBRACE='{'
1708     BISON_CLOSEBRACE='}'
1709     BISON_VERBOSE='-Dparse.error=verbose'
1710     AC_MSG_RESULT([$frr_ac_bison_version - 3.0 or newer])
1711     ;;
1712 esac
1713 AC_SUBST(BISON_OPENBRACE)
1714 AC_SUBST(BISON_CLOSEBRACE)
1715 AC_SUBST(BISON_VERBOSE)
1716
1717 if $frr_ac_bison_missing; then
1718   YACC="$SHELL $missing_dir/missing bison -y"
1719   if test -f "${srcdir}/lib/command_parse.c" -a -f "${srcdir}/lib/command_parse.h"; then
1720     AC_MSG_WARN([using pregenerated bison output files])
1721   else
1722     AC_MSG_ERROR([bison failure and pregenerated files not included (probably a git build)])
1723   fi
1724 fi
1725
1726 dnl -------------------
1727 dnl capabilities checks
1728 dnl -------------------
1729 if test "${enable_capabilities}" != "no"; then
1730   AC_MSG_CHECKING(whether prctl PR_SET_KEEPCAPS is available)
1731   AC_TRY_COMPILE([#include <sys/prctl.h>],[prctl(PR_SET_KEEPCAPS, 1, 0, 0, 0);],
1732     [AC_MSG_RESULT(yes)
1733      AC_DEFINE(HAVE_PR_SET_KEEPCAPS,,prctl)
1734      frr_ac_keepcaps="yes"],
1735      AC_MSG_RESULT(no)
1736   )
1737   if test x"${frr_ac_keepcaps}" = x"yes"; then
1738     AC_CHECK_HEADERS(sys/capability.h)
1739   fi
1740   if test x"${ac_cv_header_sys_capability_h}" = x"yes"; then
1741     AC_CHECK_LIB(cap, cap_init,
1742       [AC_DEFINE(HAVE_LCAPS,1,Capabilities)
1743        LIBCAP="-lcap"
1744        frr_ac_lcaps="yes"]
1745     )
1746   else
1747     AC_CHECK_HEADERS(priv.h,
1748      [AC_MSG_CHECKING(Solaris style privileges are available)
1749       AC_TRY_COMPILE([#include <priv.h>],[getpflags(PRIV_AWARE);],
1750           [AC_MSG_RESULT(yes)
1751            AC_DEFINE(HAVE_SOLARIS_CAPABILITIES,1,getpflags)
1752            frr_ac_scaps="yes"],
1753            AC_MSG_RESULT(no)
1754       )
1755      ]
1756    )
1757   fi
1758   if test x"${frr_ac_scaps}" = x"yes" \
1759        -o x"${frr_ac_lcaps}" = x"yes"; then
1760     AC_DEFINE(HAVE_CAPABILITIES,1,capabilities)
1761   fi
1762 fi
1763 AC_SUBST(LIBCAP)
1764
1765 dnl ---------------------------
1766 dnl check for glibc 'backtrace'
1767 dnl ---------------------------
1768 if test x"${enable_backtrace}" != x"no" ; then
1769   backtrace_ok=no
1770   AC_CHECK_HEADER([execinfo.h], [
1771     AC_SEARCH_LIBS([backtrace], [execinfo], [
1772       AC_DEFINE(HAVE_GLIBC_BACKTRACE,,[Glibc backtrace])
1773       AC_DEFINE(HAVE_STACK_TRACE,,[Stack symbol decoding])
1774       backtrace_ok=yes
1775     ],, [-lm])
1776   ])
1777
1778   if test x"${enable_backtrace}" = x"yes" -a x"${backtrace_ok}" = x"no"; then
1779     dnl user explicitly requested backtrace but we failed to find support
1780     AC_MSG_FAILURE([failed to find backtrace support])
1781   fi
1782 fi
1783
1784 dnl -----------------------------------------
1785 dnl check for malloc mallinfo struct and call
1786 dnl this must try and link using LIBS, in
1787 dnl order to check no alternative allocator
1788 dnl has been specified, which might not provide
1789 dnl mallinfo, e.g. such as Umem on Solaris.
1790 dnl -----------------------------------------
1791 AC_CHECK_HEADERS([malloc.h malloc_np.h malloc/malloc.h],,, [FRR_INCLUDES])
1792
1793 AC_CACHE_CHECK([whether mallinfo is available], [frr_cv_mallinfo], [
1794   AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
1795 #ifdef HAVE_MALLOC_H
1796 #include <malloc.h>
1797 #endif
1798 #ifdef HAVE_MALLOC_NP_H
1799 #include <malloc_np.h>
1800 #endif
1801 #ifdef HAVE_MALLOC_MALLOC_H
1802 #include <malloc/malloc.h>
1803 #endif
1804 ]], [[
1805 struct mallinfo ac_x; ac_x = mallinfo ();
1806 ]])], [
1807     frr_cv_mallinfo=yes
1808   ], [
1809     frr_cv_mallinfo=no
1810   ])
1811 ])
1812 if test "$frr_cv_mallinfo" = yes; then
1813   AC_DEFINE(HAVE_MALLINFO,,mallinfo)
1814 fi
1815
1816 AC_MSG_CHECKING(whether malloc_usable_size is available)
1817 AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
1818 #ifdef HAVE_MALLOC_H
1819 #include <malloc.h>
1820 #endif
1821 #ifdef HAVE_MALLOC_MALLOC_H
1822 #include <malloc/malloc.h>
1823 #endif
1824 ]], [[
1825 size_t ac_x; ac_x = malloc_usable_size(NULL);
1826 ]])], [
1827   AC_MSG_RESULT(yes)
1828   AC_DEFINE(HAVE_MALLOC_USABLE_SIZE,,malloc_usable_size)
1829 ], [
1830   AC_MSG_RESULT(no)
1831
1832   AC_MSG_CHECKING(whether malloc_size is available)
1833   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1834 #ifdef HAVE_MALLOC_H
1835 #include <malloc.h>
1836 #endif
1837 #ifdef HAVE_MALLOC_MALLOC_H
1838 #include <malloc/malloc.h>
1839 #endif
1840 ]], [[
1841 size_t ac_x; ac_x = malloc_size(NULL);
1842 ]])], [
1843     AC_MSG_RESULT(yes)
1844     AC_DEFINE(HAVE_MALLOC_SIZE,,malloc_size)
1845   ], [
1846     AC_MSG_RESULT(no)
1847   ])
1848 ])
1849
1850 dnl ------
1851 dnl ZeroMQ
1852 dnl ------
1853 if test "x$enable_zeromq" != "xno"; then
1854   PKG_CHECK_MODULES(ZEROMQ, [libzmq >= 4.0.0], [
1855     AC_DEFINE(HAVE_ZEROMQ, 1, [Enable ZeroMQ support])
1856     ZEROMQ=true
1857   ], [
1858     if test "x$enable_zeromq" = "xyes"; then
1859       AC_MSG_ERROR([configuration specifies --enable-zeromq but libzmq was not found])
1860     fi
1861   ])
1862 fi
1863 AM_CONDITIONAL([ZEROMQ], test "x$ZEROMQ" = "xtrue")
1864
1865 dnl ----------
1866 dnl configure date
1867 dnl ----------
1868 dev_version=`echo $VERSION | grep dev`
1869 #don't expire deprecated code in non 'dev' branch
1870 if test "${dev_version}" = ""; then
1871    CONFDATE=0
1872 else
1873    CONFDATE=`date '+%Y%m%d'`
1874 fi
1875 AC_SUBST(CONFDATE)
1876
1877 dnl ------------------------------
1878 dnl set paths for state directory
1879 dnl ------------------------------
1880 AC_MSG_CHECKING(directory to use for state file)
1881 if test "${prefix}" = "NONE"; then
1882   frr_statedir_prefix="";
1883 else
1884   frr_statedir_prefix=${prefix}
1885 fi
1886 if test "${localstatedir}" = '${prefix}/var'; then
1887   for FRR_STATE_DIR in ${frr_statedir_prefix}/var/run dnl
1888                         ${frr_statedir_prefix}/var/adm dnl
1889                         ${frr_statedir_prefix}/etc dnl
1890                         /var/run        dnl
1891                         /var/adm        dnl
1892                         /etc            dnl
1893                         /dev/null;
1894   do
1895     test -d $FRR_STATE_DIR && break
1896   done
1897   frr_statedir=$FRR_STATE_DIR
1898 else
1899   frr_statedir=${localstatedir}
1900 fi
1901 if test $frr_statedir = "/dev/null"; then
1902     AC_MSG_ERROR('STATE DIRECTORY NOT FOUND! FIX OR SPECIFY --localstatedir!')
1903 fi
1904 AC_MSG_RESULT(${frr_statedir})
1905 AC_SUBST(frr_statedir)
1906
1907 AC_DEFINE_UNQUOTED(LDPD_SOCKET, "$frr_statedir/ldpd.sock",ldpd control socket)
1908 AC_DEFINE_UNQUOTED(ZEBRA_SERV_PATH, "$frr_statedir/zserv.api",zebra api socket)
1909 AC_DEFINE_UNQUOTED(BFDD_CONTROL_SOCKET, "$frr_statedir/bfdd.sock", bfdd control socket)
1910 AC_DEFINE_UNQUOTED(DAEMON_VTY_DIR, "$frr_statedir",daemon vty directory)
1911
1912 dnl autoconf does this, but it does it too late...
1913 test "x$prefix" = xNONE && prefix=$ac_default_prefix
1914 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
1915
1916 dnl get the full path, recursing through variables...
1917 vtysh_bin="$bindir/vtysh"
1918 for I in 1 2 3 4 5 6 7 8 9 10; do
1919         eval vtysh_bin="\"$vtysh_bin\""
1920 done
1921 AC_DEFINE_UNQUOTED(VTYSH_BIN_PATH, "$vtysh_bin",path to vtysh binary)
1922
1923 CFG_SYSCONF="$sysconfdir"
1924 CFG_SBIN="$sbindir"
1925 CFG_STATE="$frr_statedir"
1926 CFG_MODULE="$moduledir"
1927 for I in 1 2 3 4 5 6 7 8 9 10; do
1928         eval CFG_SYSCONF="\"$CFG_SYSCONF\""
1929         eval CFG_SBIN="\"$CFG_SBIN\""
1930         eval CFG_STATE="\"$CFG_STATE\""
1931         eval CFG_MODULE="\"$CFG_MODULE\""
1932 done
1933 AC_SUBST(CFG_SYSCONF)
1934 AC_SUBST(CFG_SBIN)
1935 AC_SUBST(CFG_STATE)
1936 AC_SUBST(CFG_MODULE)
1937 AC_DEFINE_UNQUOTED(MODULE_PATH, "$CFG_MODULE", path to modules)
1938
1939 dnl ------------------------------------
1940 dnl Enable RPKI and add librtr to libs
1941 dnl ------------------------------------
1942 if test "${enable_rpki}" = "yes"; then
1943   PKG_CHECK_MODULES(RTRLIB,[rtrlib >= 0.5.0],
1944       [RPKI=true],
1945       [RPKI=false
1946       AC_MSG_ERROR([rtrlib was not found on your system or is too old.])]
1947   )
1948 fi
1949 AM_CONDITIONAL([RPKI], test "x$RPKI" = "xtrue")
1950
1951 dnl ------------------------------------------
1952 dnl Check whether rtrlib was build with ssh support
1953 dnl ------------------------------------------
1954 AC_MSG_CHECKING([whether the RTR Library is compiled with SSH])
1955 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "rtrlib/rtrlib.h"]],
1956                         [[struct tr_ssh_config config;]])],
1957         [AC_MSG_RESULT(yes)
1958         AC_DEFINE(FOUND_SSH,,found_ssh)],
1959         AC_MSG_RESULT(no)
1960 )
1961
1962 dnl ---------------------------
1963 dnl Check htonl works correctly
1964 dnl ---------------------------
1965 AC_MSG_CHECKING(for working htonl)
1966 AC_CACHE_VAL(ac_cv_htonl_works,
1967  [AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES],[htonl (0);])],
1968                 [ac_cv_htonl_works=yes], [ac_cv_htonl_works=no])
1969  ]
1970 )
1971 AC_MSG_RESULT($ac_cv_htonl_works)
1972
1973 AC_CONFIG_FILES([Makefile],[sed -e 's/^#AUTODERP# //' -i Makefile])
1974
1975 AC_CONFIG_FILES([
1976           redhat/frr.spec
1977           solaris/Makefile
1978           debianpkg/changelog
1979           alpine/APKBUILD
1980           snapcraft/snapcraft.yaml
1981           lib/version.h
1982           tests/lib/cli/test_cli.refout
1983           pkgsrc/bgpd.sh pkgsrc/ospf6d.sh pkgsrc/ospfd.sh
1984           pkgsrc/ripd.sh pkgsrc/ripngd.sh pkgsrc/zebra.sh
1985           pkgsrc/eigrpd.sh])
1986
1987 AC_CONFIG_FILES([vtysh/extract.pl],[chmod +x vtysh/extract.pl])
1988
1989 AC_CONFIG_COMMANDS([lib/route_types.h], [
1990         dst="${ac_abs_top_builddir}/lib/route_types.h"
1991         ${PERL} "${ac_abs_top_srcdir}/lib/route_types.pl" \
1992                 < "${ac_abs_top_srcdir}/lib/route_types.txt" \
1993                 > "${dst}.tmp"
1994         test -f "${dst}" \
1995                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
1996                 && rm "${dst}.tmp" \
1997                 || mv "${dst}.tmp" "${dst}"
1998 ], [
1999         PERL="$PERL"
2000 ])
2001
2002 AS_IF([test "x$with_pkg_git_version" = "xyes"], [
2003     AC_CONFIG_COMMANDS([lib/gitversion.h], [
2004         dst="${ac_abs_top_builddir}/lib/gitversion.h"
2005         ${PERL} "${ac_abs_top_srcdir}/lib/gitversion.pl" \
2006                 "${ac_abs_top_srcdir}" \
2007                 > "${dst}.tmp"
2008         test -f "${dst}" \
2009                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
2010                 && rm "${dst}.tmp" \
2011                 || mv "${dst}.tmp" "${dst}"
2012     ], [
2013         PERL="$PERL"
2014     ])
2015 ])
2016
2017 ## Hack, but working solution to avoid rebuilding of frr.info.
2018 ## It's already in CVS until texinfo 4.7 is more common.
2019 AC_OUTPUT
2020
2021 echo "
2022 FRRouting configuration
2023 ------------------------------
2024 FRR version             : ${PACKAGE_VERSION}
2025 host operating system   : ${host_os}
2026 source code location    : ${srcdir}
2027 compiler                : ${CC}
2028 compiler flags          : ${CFLAGS} ${SAN_FLAGS}
2029 make                    : ${MAKE-make}
2030 linker flags            : ${LDFLAGS} ${SAN_FLAGS} ${LIBS} ${LIBCAP} ${LIBREADLINE} ${LIBM}
2031 state file directory    : ${frr_statedir}
2032 config file directory   : `eval echo \`echo ${sysconfdir}\``
2033 example directory       : `eval echo \`echo ${exampledir}\``
2034 module directory        : ${CFG_MODULE}
2035 user to run as          : ${enable_user}
2036 group to run as         : ${enable_group}
2037 group for vty sockets   : ${enable_vty_group}
2038 config file mask        : ${enable_configfile_mask}
2039 log file mask           : ${enable_logfile_mask}
2040 zebra protobuf enabled  : ${enable_protobuf:-no}
2041
2042 The above user and group must have read/write access to the state file
2043 directory and to the config files in the config file directory."
2044
2045 if test "${enable_doc}" != "no";then
2046   AS_IF([test "x$SPHINXBUILD" = xno],
2047      AC_MSG_WARN(sphinx-build is missing but required to build documentation))
2048 fi