configure.ac

   1 ##
   2 ## Configure template file for FRRouting.
   3 ## autoconf will generate a configure script.
   4 ##
   5 ##  Copyright (c) 1996, 97, 98, 99, 2000 Kunihiro Ishiguro <kunihiro@zebra.org>
   6 ##  Portions Copyright (c) 2003 Paul Jakma <paul@dishone.st>
   7 ##
   8 AC_PREREQ([2.69])
   9
  10 AC_INIT([frr], [8.5-dev], [https://github.com/frrouting/frr/issues])
  11 PACKAGE_URL="https://frrouting.org/"
  12 AC_SUBST([PACKAGE_URL])
  13 PACKAGE_FULLNAME="FRRouting"
  14 AC_SUBST([PACKAGE_FULLNAME])
  15
  16 CONFIG_ARGS="`echo $ac_configure_args | sed -e \"s% '[[A-Z]]*FLAGS=[[^']]\+'%%g\"`"
  17 AC_SUBST([CONFIG_ARGS])
  18
  19 AC_CONFIG_SRCDIR([lib/zebra.h])
  20 AC_CONFIG_MACRO_DIR([m4])
  21 AC_CONFIG_AUX_DIR([m4/ac])
  22
  23 dnl -----------------------------------
  24 dnl Get hostname and other information.
  25 dnl -----------------------------------
  26 AC_CANONICAL_BUILD()
  27 AC_CANONICAL_HOST()
  28
  29 AC_ARG_VAR([AR],[archiver command])
  30 AC_ARG_VAR([LD],[linker command])
  31 AC_ARG_VAR([OBJCOPY],[objcopy command])
  32 AC_ARG_VAR([OBJDUMP],[objdump command])
  33 AC_ARG_VAR([RANLIB],[ranlib command])
  34 AC_ARG_VAR([STRIP],[strip command])
  35
  36 hosttools_clippy="false"
  37 build_clippy="true"
  38
  39 dnl case 1: external clippy
  40 if test -n "$with_clippy" -a "$with_clippy" != "no" -a "$with_clippy" != "yes"; then
  41   if test "$enable_clippy_only" = "yes"; then
  42     AC_MSG_ERROR([--enable-clippy-only does not make sense with --with-clippy])
  43   fi
  44
  45   CLIPPY="$with_clippy"
  46   build_clippy="false"
  47   if test ! -x "$with_clippy"; then
  48     AC_MSG_ERROR([clippy tool ($with_clippy) is not executable])
  49   fi
  50
  51 dnl case 2: cross-compiling internal clippy
  52 elif test "$host" != "$build"; then
  53   if test "$srcdir" = "."; then
  54     AC_MSG_ERROR([cross-compilation is only possible with builddir separate from srcdir or by building clippy separately and using the --with-clippy option.  create a separate directory and run as .../path-to-frr/configure.])
  55   fi
  56   test -d hosttools || mkdir hosttools
  57   abssrc="`cd \"${srcdir}\"; pwd`"
  58
  59   AC_MSG_NOTICE([...])
  60   AC_MSG_NOTICE([... cross-compilation: creating hosttools directory and self-configuring for build platform tools])
  61   AC_MSG_NOTICE([... use HOST_CPPFLAGS / HOST_CFLAGS / HOST_LDFLAGS if necessary])
  62   AC_MSG_NOTICE([...])
  63
  64   (
  65     for var in $ac_precious_vars; do
  66       dnl special cases
  67       case "$var" in
  68       YACC|YFLAGS) continue;;
  69       PYTHON*)     retain=true;;
  70       *)           retain=false;
  71       esac
  72
  73       eval "hostvar=\"\${HOST_$var}\""
  74       eval "targetvar=\"\${$var}\""
  75       if test -n "$hostvar"; then
  76         eval "$var='$hostvar'"
  77         _AS_ECHO_LOG([host $var='$hostvar'])
  78       elif $retain; then
  79         _AS_ECHO_LOG([host retain $var='$targetvar'])
  80       else
  81         eval "unset $var"
  82         _AS_ECHO_LOG([host unset $var])
  83       fi
  84     done
  85     cd hosttools
  86     "${abssrc}/configure" "--host=$build" "--build=$build" "--enable-clippy-only" "--disable-nhrpd" "--disable-vtysh"
  87   ) || exit 1
  88
  89   AC_MSG_NOTICE([...])
  90   AC_MSG_NOTICE([... cross-compilation: finished self-configuring for build platform tools])
  91   AC_MSG_NOTICE([...])
  92
  93   build_clippy="false"
  94   hosttools_clippy="true"
  95   CLIPPY="hosttools/lib/clippy"
  96
  97 dnl case 3: normal build internal clippy
  98 else
  99   CLIPPY="lib/clippy\$(EXEEXT)"
 100 fi
 101 AC_SUBST([CLIPPY])
 102 AM_CONDITIONAL([BUILD_CLIPPY], [$build_clippy])
 103 AM_CONDITIONAL([HOSTTOOLS_CLIPPY], [$hosttools_clippy])
 104 AM_CONDITIONAL([ONLY_CLIPPY], [test "$enable_clippy_only" = "yes"])
 105
 106 # Disable portability warnings -- our automake code (in particular
 107 # common.am) uses some constructs specific to gmake.
 108 AM_INIT_AUTOMAKE([1.12 -Wno-portability foreign])
 109 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
 110 AM_SILENT_RULES([yes])
 111 AC_CONFIG_HEADERS([config.h])
 112
 113 AC_PATH_PROG([PERL], [perl])
 114 PKG_PROG_PKG_CONFIG
 115
 116 dnl default is to match previous behavior
 117 pkgsrcrcdir=""
 118 AC_ARG_ENABLE([pkgsrcrcdir],
 119           AS_HELP_STRING([--enable-pkgsrcrcdir],
 120                          [specify directory for rc.d scripts]),
 121                          pkgsrcrcdir="$enableval",)
 122 dnl XXX add --pkgsrcrcdir to autoconf standard directory list somehow
 123 AC_SUBST([pkgsrcrcdir])
 124 AM_CONDITIONAL([PKGSRC], [test "$pkgsrcrcdir" != ""])
 125
 126 AC_ARG_WITH([moduledir], [AS_HELP_STRING([--with-moduledir=DIR], [module directory (${libdir}/frr/modules)])], [
 127         moduledir="$withval"
 128 ], [
 129         moduledir="\${libdir}/frr/modules"
 130 ])
 131 AC_SUBST([moduledir], [$moduledir])
 132
 133 AC_ARG_WITH([scriptdir], [AS_HELP_STRING([--with-scriptdir=DIR], [script directory (${sysconfdir}/scripts)])], [
 134         scriptdir="$withval"
 135 ], [
 136         scriptdir="\${sysconfdir}/scripts"
 137 ])
 138 AC_SUBST([scriptdir], [$scriptdir])
 139
 140 AC_ARG_WITH([yangmodelsdir], [AS_HELP_STRING([--with-yangmodelsdir=DIR], [yang models directory (${datarootdir}/yang)])], [
 141         yangmodelsdir="$withval"
 142 ], [
 143         yangmodelsdir="\${datarootdir}/yang"
 144 ])
 145 AC_SUBST([yangmodelsdir])
 146
 147 AC_ARG_WITH([vici-socket], [AS_HELP_STRING([--with-vici-socket=PATH], [vici-socket (/var/run/charon.vici)])], [
 148         vici_socket="$withval"
 149 ], [
 150         vici_socket="/var/run/charon.vici"
 151 ])
 152 AC_DEFINE_UNQUOTED([VICI_SOCKET], ["$vici_socket"], [StrongSWAN vici socket path])
 153
 154 AC_ARG_ENABLE(tcmalloc,
 155         AS_HELP_STRING([--enable-tcmalloc], [Turn on tcmalloc]),
 156 [case "${enableval}" in
 157   yes) tcmalloc_enabled=true
 158 LIBS="$LIBS -ltcmalloc_minimal"
 159  ;;
 160   no)  tcmalloc_enabled=false ;;
 161   *) AC_MSG_ERROR([bad value ${enableval} for --enable-tcmalloc]) ;;
 162 esac],[tcmalloc_enabled=false])
 163
 164
 165 dnl Thanks autoconf, but we don't want a default -g -O2.  We have our own
 166 dnl flag determination logic.
 167 CFLAGS="${CFLAGS:-}"
 168
 169 dnl --------------------
 170 dnl Check CC and friends
 171 dnl --------------------
 172 dnl note orig_cflags is also used further down
 173 orig_cflags="$CFLAGS"
 174 orig_cxxflags="$CXXFLAGS"
 175 AC_LANG([C])
 176 AC_PROG_CC
 177 AC_PROG_CPP
 178 AC_PROG_CXX
 179 AM_PROG_CC_C_O
 180 dnl remove autoconf default "-g -O2"
 181 CFLAGS="$orig_cflags"
 182 CXXFLAGS="$orig_cxxflags"
 183
 184 dnl Some special handling for ICC later on
 185 if test "$CC" = "icc"; then
 186     cc_is_icc="yes"
 187 fi
 188
 189 PKG_PROG_PKG_CONFIG
 190
 191 dnl it's 2019, sed is sed.
 192 SED=sed
 193 AC_SUBST([SED])
 194
 195 dnl try and enable CFLAGS that are useful for FRR
 196 dnl - specifically, options to control warnings
 197
 198 AC_SUBST([AC_CFLAGS])
 199 AC_USE_SYSTEM_EXTENSIONS
 200 AC_DEFUN([AC_C_FLAG], [{
 201     m4_pushdef([cachename],[m4_translit([frr_cv_$1],[ =-+/{}$],[________])])
 202     AC_CACHE_CHECK([[whether $CC supports $1]], cachename, [
 203         AC_LANG_PUSH([C])
 204         ac_c_flag_save="$CFLAGS"
 205         CFLAGS="$CFLAGS $1"
 206         AC_COMPILE_IFELSE(
 207                 [AC_LANG_PROGRAM([[$4]])],
 208                 [
 209                         cachename=yes
 210                 ], [
 211                         cachename=no
 212                 ])
 213         CFLAGS="$ac_c_flag_save"
 214         AC_LANG_POP([C])
 215     ])
 216     if test "$cachename" = "yes"; then
 217         m4_if([$3], [], [AC_CFLAGS="$AC_CFLAGS $1"], [$3])
 218     else
 219         :
 220         $2
 221     fi
 222     m4_popdef([cachename])
 223 }])
 224
 225 AC_DEFUN([AC_LINK_IFELSE_FLAGS], [{
 226         AC_LANG_PUSH([C])
 227         ac_cflags_save="$CFLAGS"
 228         ac_libs_save="$LIBS"
 229         CFLAGS="$CFLAGS $1"
 230         LIBS="$LIBS $2"
 231         AC_LINK_IFELSE(
 232                 [$3],
 233                 [
 234                         CFLAGS="$ac_cflags_save"
 235                         LIBS="$ac_libs_save"
 236                         m4_default([$5], [
 237                                 AC_MSG_RESULT([yes])
 238                         ])
 239                 ], [
 240                         CFLAGS="$ac_cflags_save"
 241                         LIBS="$ac_libs_save"
 242                         m4_default([$4], [
 243                                 AC_MSG_RESULT([no])
 244                         ])
 245                 ])
 246         AC_LANG_POP([C])
 247         }])
 248
 249 dnl ICC won't bail on unknown options without -diag-error 10006
 250 dnl need to do this first so we get useful results for the other options
 251 if test "$cc_is_icc" = "yes"; then
 252     AC_C_FLAG([-diag-error 10006])
 253 fi
 254
 255 dnl autoconf 2.69 AC_PROG_CC_C99 is "state of the art"
 256 dnl autoconf 2.70 AC_PROG_CC_C99 is deprecated and AC_PROC_CC tries to do C11
 257 m4_if(m4_version_compare(m4_defn([AC_AUTOCONF_VERSION]), [2.70]), [-1], [dnl
 258   dnl autoconf < 2.70
 259   AC_PROG_CC_C99
 260
 261   dnl AC_PROG_CC_C99 may change CC to include -std=gnu99 or something
 262   ac_cc="$CC"
 263   CC="${CC% -std=gnu99}"
 264   CC="${CC% -std=c99}"
 265
 266   AC_C_FLAG([-std=gnu11], [CC="$ac_cc"], [CC="$CC -std=gnu11"])
 267 ], [
 268   dnl autoconf >= 2.70
 269   if test "$ac_cv_prog_cc_c11" = "no"; then
 270     AC_MSG_ERROR([ISO C11 compiler support (with GNU extensions) is required.])
 271   fi
 272 ])
 273
 274 dnl if the user has specified any CFLAGS, override our settings
 275 if test "$enable_gcov" = "yes"; then
 276    if test "$orig_cflags" = ""; then
 277       AC_C_FLAG([--coverage])
 278       AC_C_FLAG([-O0])
 279    fi
 280
 281    AC_LDFLAGS="${AC_LDFLAGS} --coverage"
 282 fi
 283
 284 if test "$enable_clang_coverage" = "yes"; then
 285    AC_C_FLAG([-fprofile-instr-generate], [
 286      AC_MSG_ERROR([$CC does not support -fprofile-instr-generate.])
 287    ])
 288    AC_C_FLAG([-fcoverage-mapping], [
 289      AC_MSG_ERROR([$CC does not support -fcoverage-mapping.])
 290    ])
 291 fi
 292
 293 AM_CONDITIONAL([SCRIPTING], [test "$enable_scripting" = "yes"])
 294
 295 if test "$enable_scripting" = "yes"; then
 296    AX_PROG_LUA([5.3], [5.4], [], [
 297      AC_MSG_ERROR([Lua 5.3 is required to build with Lua support. No other version is supported.])
 298    ])
 299    AX_LUA_HEADERS([], [
 300      AC_MSG_ERROR([Lua 5.3 headers are required to build with Lua support. No other version is supported.])
 301    ])
 302    AX_LUA_LIBS([
 303      AC_DEFINE([HAVE_SCRIPTING], [1], [Have support for scripting])
 304      LIBS="$LIBS $LUA_LIB"
 305      SCRIPTING=true
 306    ], [
 307      SCRIPTING=false
 308      AC_MSG_ERROR([Lua 5.3 libraries are required to build with Lua support. No other version is supported.])
 309    ])
 310 fi
 311
 312 dnl the following flags go in CFLAGS rather than AC_CFLAGS since they make
 313 dnl sense to be overridden by the user
 314 if test "$enable_dev_build" = "yes"; then
 315    AC_DEFINE([DEV_BUILD], [1], [Build for development])
 316    if test "$orig_cflags" = ""; then
 317       AC_C_FLAG([-O0],,[CFLAGS="$CFLAGS -O0"])
 318       AC_C_FLAG([-g3],,[CFLAGS="$CFLAGS -g3"])
 319       AC_C_FLAG([-ggdb3],,[CFLAGS="$CFLAGS -ggdb3"])
 320    fi
 321 else
 322    if test "$orig_cflags" = ""; then
 323       AC_C_FLAG([-g],,[CFLAGS="$CFLAGS -g"])
 324       AC_C_FLAG([-O2],,[CFLAGS="$CFLAGS -O2"])
 325    fi
 326 fi
 327
 328 dnl just stick -g into LDFLAGS, if we don't have it in CFLAGS it won't do much
 329 LDFLAGS="$LDFLAGS -g"
 330
 331 AM_CONDITIONAL([DEV_BUILD], [test "$enable_dev_build" = "yes"])
 332
 333 dnl -fms-extensions causes clang to have a built-in __wchar_t on OpenBSD,
 334 dnl which just straight up breaks compiling any code.
 335 dnl (2022-04-04 / OpenBSD 7 / clang 11.1.0)
 336 AH_VERBATIM([OpenBSD], [
 337 #ifdef __OpenBSD__
 338 #define __wchar_t __wchar_t_ignore
 339 #include <stdint.h>
 340 #undef __wchar_t
 341 #endif
 342 ])
 343
 344 dnl always want these CFLAGS
 345 AC_C_FLAG([-fms-extensions], [
 346   AC_MSG_ERROR([$CC does not support unnamed struct fields (-fms-extensions)])
 347 ])
 348 AC_C_FLAG([-fno-omit-frame-pointer])
 349 AC_C_FLAG([-funwind-tables])
 350 AC_C_FLAG([-Wall])
 351 AC_C_FLAG([-Wextra])
 352 AC_C_FLAG([-Wformat-nonliteral])
 353 AC_C_FLAG([-Wformat-security])
 354 AC_C_FLAG([-Wstrict-prototypes])
 355 AC_C_FLAG([-Wmissing-prototypes])
 356 AC_C_FLAG([-Wmissing-declarations])
 357 AC_C_FLAG([-Wpointer-arith])
 358 AC_C_FLAG([-Wbad-function-cast])
 359 AC_C_FLAG([-Wwrite-strings])
 360 AC_C_FLAG([-Wundef])
 361 if test "$enable_gcc_ultra_verbose" = "yes" ; then
 362   AC_C_FLAG([-Wcast-qual])
 363   AC_C_FLAG([-Wmissing-noreturn])
 364   AC_C_FLAG([-Wmissing-format-attribute])
 365   AC_C_FLAG([-Wunreachable-code])
 366   AC_C_FLAG([-Wpacked])
 367   AC_C_FLAG([-Wpadded])
 368   AC_C_FLAG([-Wshadow])
 369 else
 370   AC_C_FLAG([-Wno-unused-result])
 371 fi
 372 AC_C_FLAG([-Wno-unused-parameter])
 373 AC_C_FLAG([-Wno-missing-field-initializers])
 374
 375 AC_C_FLAG([-Wc++-compat], [], [CXX_COMPAT_CFLAGS="-Wc++-compat"])
 376 AC_SUBST([CXX_COMPAT_CFLAGS])
 377
 378 dnl ICC emits a broken warning for const char *x = a ? "b" : "c";
 379 dnl for some reason the string consts get 'promoted' to char *,
 380 dnl triggering a const to non-const conversion warning.
 381 if test "$cc_is_icc" = "yes"; then
 382     AC_C_FLAG([-diag-disable 3179])
 383 fi
 384
 385 if test "$enable_werror" = "yes" ; then
 386   WERROR="-Werror"
 387 fi
 388 AC_SUBST([WERROR])
 389
 390 SAN_FLAGS=""
 391 if test "$enable_address_sanitizer" = "yes"; then
 392   AC_C_FLAG([-fsanitize=address], [
 393     AC_MSG_ERROR([$CC does not support Address Sanitizer.])
 394   ], [
 395     SAN_FLAGS="$SAN_FLAGS -fsanitize=address"
 396   ])
 397 fi
 398 if test "$enable_thread_sanitizer" = "yes"; then
 399   AC_C_FLAG([-fsanitize=thread], [
 400     AC_MSG_ERROR([$CC does not support Thread Sanitizer.])
 401   ], [
 402     SAN_FLAGS="$SAN_FLAGS -fsanitize=thread"
 403   ])
 404 fi
 405 if test "$enable_memory_sanitizer" = "yes"; then
 406   AC_C_FLAG([-fsanitize=memory -fPIE -pie], [
 407     AC_MSG_ERROR([$CC does not support Memory Sanitizer.])
 408   ], [
 409     SAN_FLAGS="$SAN_FLAGS -fsanitize=memory -fPIE -pie"
 410   ])
 411 fi
 412 if test "$enable_undefined_sanitizer" = "yes"; then
 413   AC_C_FLAG([-fsanitize=undefined], [
 414     AC_MSG_ERROR([$CC does not support UndefinedBehaviorSanitizer.])
 415   ], [
 416     SAN_FLAGS="$SAN_FLAGS -fsanitize=undefined"
 417   ])
 418 fi
 419 AC_SUBST([SAN_FLAGS])
 420
 421 dnl frr-format.so
 422 if test "$with_frr_format" != "no" -a "$with_frr_format" != "yes" -a -n "$with_frr_format"; then
 423   AC_C_FLAG([-fplugin=${with_frr_format}], [
 424     AC_MSG_ERROR([specified frr-format plugin ($with_frr_format) does not work])
 425   ],,[
 426 #ifndef _FRR_ATTRIBUTE_PRINTFRR
 427 #error plugin not loaded
 428 #endif
 429 #if _FRR_ATTRIBUTE_PRINTFRR < 0x10000
 430 #error plugin too old
 431 #endif
 432   ])
 433 elif test "$with_frr_format" = "no"; then
 434   : #nothing
 435 else
 436   AC_C_FLAG([-fplugin=tools/gcc-plugins/frr-format.so],[
 437     AC_C_FLAG([-fplugin=frr-format],[
 438       if test "$with_frr_format" = "yes"; then
 439         AC_MSG_ERROR([frr-format plugin requested but not found])
 440       fi
 441     ],,[
 442 #ifndef _FRR_ATTRIBUTE_PRINTFRR
 443 #error plugin not loaded
 444 #endif
 445 #if _FRR_ATTRIBUTE_PRINTFRR < 0x10000
 446 #error plugin too old
 447 #endif
 448     ])
 449   ],,[
 450 #ifndef _FRR_ATTRIBUTE_PRINTFRR
 451 #error plugin not loaded
 452 #endif
 453 #if _FRR_ATTRIBUTE_PRINTFRR < 0x10000
 454 #error plugin too old
 455 #endif
 456   ])
 457 fi
 458
 459 AC_MSG_CHECKING([whether linker supports __start/stop_section symbols])
 460 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 461 #include <stdio.h>
 462 int __attribute__((section("secttest"))) var = 1;
 463 extern int __start_secttest, __stop_secttest;
 464 ]], [[
 465   void *a = &var, *b = &__start_secttest, *c = &__stop_secttest;
 466   printf("%p %p %p\n", a, b, c);
 467 ]])], [
 468   AC_MSG_RESULT(yes)
 469   AC_DEFINE(HAVE_SECTION_SYMS, 1, [have __start/stop_section symbols])
 470 ], [
 471   AC_MSG_RESULT(no)
 472 ])
 473
 474 dnl ----------
 475 dnl Essentials
 476 dnl ----------
 477
 478 AX_PTHREAD([
 479   CC="$PTHREAD_CC"
 480   AC_CFLAGS="$AC_CFLAGS $PTHREAD_CFLAGS"
 481   LIBS="$PTHREAD_LIBS $LIBS"
 482 ], [
 483   AC_MSG_FAILURE([This FRR version needs pthreads])
 484 ])
 485
 486 orig_cflags="$CFLAGS"
 487 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 488
 489 AC_SEARCH_LIBS([pthread_condattr_setclock], [],
 490                 [frr_cv_pthread_condattr_setclock=yes],
 491                 [frr_cv_pthread_condattr_setclock=no])
 492 if test "$frr_cv_pthread_condattr_setclock" = "yes"; then
 493   AC_DEFINE([HAVE_PTHREAD_CONDATTR_SETCLOCK], [1], [Have pthread.h pthread_condattr_setclock])
 494 fi
 495
 496 AC_CHECK_HEADERS([pthread_np.h],,, [
 497 #include <pthread.h>
 498 ])
 499 AC_CHECK_FUNCS([pthread_setname_np pthread_set_name_np pthread_getthreadid_np])
 500
 501 CFLAGS="$orig_cflags"
 502
 503 dnl --------------
 504 dnl Check programs
 505 dnl --------------
 506 AC_PROG_INSTALL
 507 AC_PROG_LN_S
 508 AC_CHECK_TOOL([AR], [ar])
 509
 510 dnl -------
 511 dnl libtool
 512 dnl -------
 513 AC_ARG_ENABLE([static-bin],
 514   AS_HELP_STRING([--enable-static-bin], [link binaries statically]))
 515 LT_INIT
 516 _LT_CONFIG_LIBTOOL([
 517   patch -N -i "${srcdir}/m4/libtool-whole-archive.patch" libtool >&AS_MESSAGE_LOG_FD || \
 518     AC_MSG_WARN([Could not patch libtool for static linking support.  Loading modules into a statically linked daemon will fail.])
 519 dnl the -i option is not POSIX sed and the BSDs implement it differently
 520 dnl cat'ing the output back instead of mv/cp keeps permissions on libtool intact
 521   sed -e 's%func_warning "relinking%true #\0%'                   libtool > libtool.sed && cat libtool.sed > libtool
 522   sed -e 's%func_warning "remember to run%true #\0%'             libtool > libtool.sed && cat libtool.sed > libtool
 523   sed -e 's%func_warning ".*has not been installed in%true #\0%' libtool > libtool.sed && cat libtool.sed > libtool
 524   test -f libtool.sed && rm libtool.sed
 525 ])
 526 if test "$enable_static_bin" = "yes"; then
 527   AC_LDFLAGS_EXEC="-static"
 528   if test "$enable_static" != "yes"; then
 529     AC_MSG_ERROR([The --enable-static-bin option must be combined with --enable-static.])
 530   fi
 531 fi
 532 if test "$enable_shared" != "yes"; then
 533   AC_MSG_ERROR([FRR cannot be built with --disable-shared.  If you want statically linked daemons, use --enable-shared --enable-static --enable-static-bin])
 534 fi
 535 AC_SUBST([AC_LDFLAGS])
 536 AC_SUBST([AC_LDFLAGS_EXEC])
 537 AM_CONDITIONAL([STATIC_BIN], [test "$enable_static_bin" = "yes"])
 538
 539 dnl libtool, the repository of all knowledge related linkers, is too stupid to
 540 dnl correctly tell the linker how to build modules.
 541 if test -z "$module_cmds"; then
 542   module_cmds="`echo \"$archive_cmds\" | sed -e 's%$wl-soname $wl$soname%%'`"
 543 fi
 544 if test -z "$module_expsym_cmds"; then
 545   module_expsym_cmds="`echo \"$archive_expsym_cmds\" | sed -e 's%$wl-soname $wl$soname%%'`"
 546 fi
 547
 548 AC_ARG_ENABLE([rpath],
 549   [AS_HELP_STRING([--enable-rpath], [set hardcoded rpaths in the executable @<:@default=yes@:>@])],
 550   [],
 551   [enable_rpath=yes])
 552
 553 dnl $AR and $RANLIB are set by LT_INIT above
 554 AC_MSG_CHECKING([whether $AR supports D option])
 555 if $AR crD conftest.a >/dev/null 2>/dev/null; then
 556   AC_MSG_RESULT([yes])
 557   dnl ARFLAGS is for automake, AR_FLAGS for libtool m-(
 558   ARFLAGS="crD"
 559   AR_FLAGS="crD"
 560 else
 561   AC_MSG_RESULT([no])
 562   ARFLAGS="cru"
 563   AR_FLAGS="cru"
 564 fi
 565 AC_SUBST([ARFLAGS])
 566 AC_SUBST([AR_FLAGS])
 567
 568 AC_MSG_CHECKING([whether $RANLIB supports D option])
 569 if $RANLIB -D conftest.a >conftest.err 2>&1; then
 570   if grep -q -- '-D' conftest.err; then
 571     AC_MSG_RESULT([no])
 572   else
 573     AC_MSG_RESULT([yes])
 574     RANLIB="$RANLIB -D"
 575   fi
 576 else
 577   AC_MSG_RESULT([no])
 578 fi
 579 AC_SUBST([RANLIB])
 580
 581 test -f conftest.err && rm conftest.err
 582 test -f conftest.a && rm conftest.a
 583
 584 dnl ----------------------
 585 dnl Packages configuration
 586 dnl ----------------------
 587 if test -f config.version; then
 588   . ./config.version
 589 elif test -f "${srcdir}/config.version"; then
 590   . "${srcdir}/config.version"
 591 fi
 592 AC_ARG_WITH([pkg-extra-version],
 593   AS_HELP_STRING([--with-pkg-extra-version=VER], [add extra version field, for packagers/distributions]), [
 594   if test "$withval" = "no"; then
 595     EXTRAVERSION=
 596   else
 597     EXTRAVERSION=$withval
 598   fi
 599 ], [])
 600 AC_ARG_WITH([pkg-git-version],
 601         AS_HELP_STRING([--with-pkg-git-version], [add git information to MOTD and build version string]),
 602         [ test "$withval" != "no" && with_pkg_git_version="yes" ])
 603 AC_ARG_WITH([clippy],
 604   AS_HELP_STRING([--with-clippy=PATH], [use external clippy helper program]))
 605 AC_ARG_WITH([vtysh_pager],
 606         AS_HELP_STRING([--with-vtysh-pager=PAGER], [control what pager is compiled in as default]),
 607         VTYSH_PAGER=$withval, VTYSH_PAGER="more")
 608 AC_ARG_ENABLE([vtysh],
 609   AS_HELP_STRING([--disable-vtysh], [do not build integrated vty shell for FRR]))
 610 AC_ARG_ENABLE([doc],
 611   AS_HELP_STRING([--disable-doc], [do not build docs]))
 612 AC_ARG_ENABLE([doc-html],
 613   AS_HELP_STRING([--enable-doc-html], [build HTML docs]))
 614 AC_ARG_ENABLE([zebra],
 615   AS_HELP_STRING([--disable-zebra], [do not build zebra daemon]))
 616 AC_ARG_ENABLE([bgpd],
 617   AS_HELP_STRING([--disable-bgpd], [do not build bgpd]))
 618 AC_ARG_ENABLE([ripd],
 619   AS_HELP_STRING([--disable-ripd], [do not build ripd]))
 620 AC_ARG_ENABLE([ripngd],
 621   AS_HELP_STRING([--disable-ripngd], [do not build ripngd]))
 622 AC_ARG_ENABLE([ospfd],
 623   AS_HELP_STRING([--disable-ospfd], [do not build ospfd]))
 624 AC_ARG_ENABLE([ospf6d],
 625   AS_HELP_STRING([--disable-ospf6d], [do not build ospf6d]))
 626 AC_ARG_ENABLE([ldpd],
 627   AS_HELP_STRING([--disable-ldpd], [do not build ldpd]))
 628 AC_ARG_ENABLE([nhrpd],
 629   AS_HELP_STRING([--disable-nhrpd], [do not build nhrpd]))
 630 AC_ARG_ENABLE([eigrpd],
 631   AS_HELP_STRING([--disable-eigrpd], [do not build eigrpd]))
 632 AC_ARG_ENABLE([babeld],
 633   AS_HELP_STRING([--disable-babeld], [do not build babeld]))
 634 AC_ARG_ENABLE([watchfrr],
 635   AS_HELP_STRING([--disable-watchfrr], [do not build watchfrr]))
 636 AC_ARG_ENABLE([isisd],
 637   AS_HELP_STRING([--disable-isisd], [do not build isisd]))
 638 AC_ARG_ENABLE([pimd],
 639   AS_HELP_STRING([--disable-pimd], [do not build pimd]))
 640 AC_ARG_ENABLE([pim6d],
 641   AS_HELP_STRING([--disable-pim6d], [do not build pim6d]))
 642 AC_ARG_ENABLE([pbrd],
 643   AS_HELP_STRING([--disable-pbrd], [do not build pbrd]))
 644 AC_ARG_ENABLE([sharpd],
 645   AS_HELP_STRING([--enable-sharpd], [build sharpd]))
 646 AC_ARG_ENABLE([staticd],
 647   AS_HELP_STRING([--disable-staticd], [do not build staticd]))
 648 AC_ARG_ENABLE([fabricd],
 649   AS_HELP_STRING([--disable-fabricd], [do not build fabricd]))
 650 AC_ARG_ENABLE([vrrpd],
 651   AS_HELP_STRING([--disable-vrrpd], [do not build vrrpd]))
 652 AC_ARG_ENABLE([pathd],
 653   AS_HELP_STRING([--disable-pathd], [do not build pathd]))
 654 AC_ARG_ENABLE([bgp-announce],
 655   AS_HELP_STRING([--disable-bgp-announce], [turn off BGP route announcement]))
 656 AC_ARG_ENABLE([bgp-vnc],
 657   AS_HELP_STRING([--disable-bgp-vnc],[turn off BGP VNC support]))
 658 AC_ARG_ENABLE([bgp-bmp],
 659   AS_HELP_STRING([--disable-bgp-bmp],[turn off BGP BMP support]))
 660 AC_ARG_ENABLE([snmp],
 661   AS_HELP_STRING([--enable-snmp], [enable SNMP support for agentx]))
 662 AC_ARG_ENABLE([config_rollbacks],
 663   AS_HELP_STRING([--enable-config-rollbacks], [enable configuration rollbacks (requires sqlite3)]))
 664 AC_ARG_ENABLE([confd],
 665   AS_HELP_STRING([--enable-confd=ARG], [enable confd integration]))
 666 AC_ARG_ENABLE([sysrepo],
 667   AS_HELP_STRING([--enable-sysrepo], [enable sysrepo integration]))
 668 AC_ARG_ENABLE([grpc],
 669   AS_HELP_STRING([--enable-grpc], [enable the gRPC northbound plugin]))
 670 AC_ARG_ENABLE([zeromq],
 671   AS_HELP_STRING([--enable-zeromq], [enable ZeroMQ handler (libfrrzmq)]))
 672 AC_ARG_ENABLE([lttng],
 673   AS_HELP_STRING([--enable-lttng], [enable LTTng tracing]))
 674 AC_ARG_ENABLE([usdt],
 675   AS_HELP_STRING([--enable-usdt], [enable USDT probes]))
 676 AC_ARG_WITH([libpam],
 677   AS_HELP_STRING([--with-libpam], [use libpam for PAM support in vtysh]))
 678 AC_ARG_ENABLE([ospfapi],
 679   AS_HELP_STRING([--disable-ospfapi], [do not build OSPFAPI to access the OSPF LSA Database]))
 680 AC_ARG_ENABLE([ospfclient],
 681   AS_HELP_STRING([--disable-ospfclient], [do not build OSPFAPI client for OSPFAPI,
 682                           (this is the default if --disable-ospfapi is set)]))
 683 AC_ARG_ENABLE([multipath],
 684   AS_HELP_STRING([--enable-multipath=ARG], [enable multipath function, ARG must be digit]))
 685 AC_ARG_WITH([service_timeout],
 686   AS_HELP_STRING([--with-service-timeout=ARG], [set service timeout value (2 minutes by default), ARG must be digit]))
 687 AC_ARG_ENABLE([user],
 688   AS_HELP_STRING([--enable-user=USER], [user to run FRR suite as (default frr)]))
 689 AC_ARG_ENABLE([group],
 690   AS_HELP_STRING([--enable-group=GROUP], [group to run FRR suite as (default frr)]))
 691 AC_ARG_ENABLE([vty_group],
 692   AS_HELP_STRING([--enable-vty-group=ARG], [set vty sockets to have specified group as owner]))
 693 AC_ARG_ENABLE([configfile_mask],
 694   AS_HELP_STRING([--enable-configfile-mask=ARG], [set mask for config files]))
 695 AC_ARG_ENABLE([logfile_mask],
 696   AS_HELP_STRING([--enable-logfile-mask=ARG], [set mask for log files]))
 697 AC_ARG_ENABLE([shell_access],
 698   AS_HELP_STRING([--enable-shell-access], [Allow users to access shell/telnet/ssh]))
 699 AC_ARG_ENABLE([realms],
 700   AS_HELP_STRING([--enable-realms], [enable REALMS support under Linux]))
 701 AC_ARG_ENABLE([rtadv],
 702   AS_HELP_STRING([--disable-rtadv], [disable IPV6 router advertisement feature]))
 703 AC_ARG_ENABLE([irdp],
 704   AS_HELP_STRING([--disable-irdp], [disable IRDP server support in zebra (enabled by default if supported)]))
 705 AC_ARG_ENABLE([capabilities],
 706   AS_HELP_STRING([--disable-capabilities], [disable using POSIX capabilities]))
 707 AC_ARG_ENABLE([gcc_ultra_verbose],
 708   AS_HELP_STRING([--enable-gcc-ultra-verbose], [enable ultra verbose GCC warnings]))
 709 AC_ARG_ENABLE([backtrace],
 710   AS_HELP_STRING([--disable-backtrace], [disable crash backtraces (default autodetect)]))
 711 AC_ARG_ENABLE([time-check],
 712   AS_HELP_STRING([--disable-time-check], [disable slow thread warning messages]))
 713 AC_ARG_ENABLE([cpu-time],
 714   AS_HELP_STRING([--disable-cpu-time], [disable cpu usage data gathering]))
 715 AC_ARG_ENABLE([pcreposix],
 716   AS_HELP_STRING([--enable-pcreposix], [enable using PCRE Posix libs for regex functions]))
 717 AC_ARG_ENABLE([pcre2posix],
 718   AS_HELP_STRING([--enable-pcre2posix], [enable using PCRE2 Posix libs for regex functions]))
 719 AC_ARG_ENABLE([fpm],
 720   AS_HELP_STRING([--enable-fpm], [enable Forwarding Plane Manager support]))
 721 AC_ARG_ENABLE([werror],
 722   AS_HELP_STRING([--enable-werror], [enable -Werror (recommended for developers only)]))
 723 AC_ARG_ENABLE([cumulus],
 724   AS_HELP_STRING([--enable-cumulus], [enable Cumulus Switch Special Extensions]))
 725 AC_ARG_ENABLE([datacenter],
 726   AS_HELP_STRING([--enable-datacenter], [enable Compilation for Data Center Extensions]))
 727 AC_ARG_ENABLE([rr-semantics],
 728   AS_HELP_STRING([--disable-rr-semantics], [disable the v6 Route Replace semantics]))
 729 AC_ARG_ENABLE([protobuf],
 730   AS_HELP_STRING([--enable-protobuf], [Enable experimental protobuf support]))
 731 AC_ARG_ENABLE([oldvpn_commands],
 732   AS_HELP_STRING([--enable-oldvpn-commands], [Keep old vpn commands]))
 733 AC_ARG_ENABLE([rpki],
 734   AS_HELP_STRING([--enable-rpki], [enable RPKI prefix validation support]))
 735 AC_ARG_ENABLE([clippy-only],
 736   AS_HELP_STRING([--enable-clippy-only], [Only build clippy]))
 737 AC_ARG_ENABLE([numeric_version],
 738   AS_HELP_STRING([--enable-numeric-version], [Only numeric digits allowed in version (for Alpine)]))
 739 AC_ARG_ENABLE([gcov],
 740   AS_HELP_STRING([--enable-gcov], [Collect coverage information with gcov]))
 741 AC_ARG_ENABLE([clang_coverage],
 742   AS_HELP_STRING([--enable-clang-coverage], [Collect coverage information with Clang Coverage]))
 743 AC_ARG_ENABLE([bfdd],
 744   AS_HELP_STRING([--disable-bfdd], [do not build bfdd]))
 745 AC_ARG_ENABLE([address-sanitizer],
 746   AS_HELP_STRING([--enable-address-sanitizer], [enable AddressSanitizer support for detecting a wide variety of memory allocation and deallocation errors]))
 747 AC_ARG_ENABLE([thread-sanitizer],
 748   AS_HELP_STRING([--enable-thread-sanitizer], [enable ThreadSanitizer support for detecting data races]))
 749 AC_ARG_ENABLE([memory-sanitizer],
 750   AS_HELP_STRING([--enable-memory-sanitizer], [enable MemorySanitizer support for detecting uninitialized memory reads]))
 751 AC_ARG_ENABLE([undefined-sanitizer],
 752   AS_HELP_STRING([--enable-undefined-sanitizer], [enable UndefinedBehaviorSanitizer support for detecting undefined behavior]))
 753 AC_ARG_WITH([crypto],
 754   AS_HELP_STRING([--with-crypto=<internal|openssl>], [choose between different implementations of cryptographic functions(default value is --with-crypto=internal)]))
 755 AC_ARG_WITH([frr-format],
 756   AS_HELP_STRING([--with-frr-format[=<.../frr-format.so>]], [use frr-format GCC plugin]))
 757
 758 AC_ARG_ENABLE([version-build-config],
 759   AS_HELP_STRING([--disable-version-build-config], [do not include build configs in show version command]))
 760
 761 #if openssl, else use the internal
 762 AS_IF([test "$with_crypto" = "openssl"], [
 763 AC_CHECK_LIB([crypto], [EVP_DigestInit], [LIBS="$LIBS -lcrypto"], [], [])
 764 if test "$ac_cv_lib_crypto_EVP_DigestInit" = "no"; then
 765   AC_MSG_ERROR([build with openssl has been specified but openssl library was not found on your system])
 766 else
 767   AC_DEFINE([CRYPTO_OPENSSL], [1], [Compile with openssl support])
 768 fi
 769 ], [test "$with_crypto" = "internal" || test "$with_crypto" = "" ], [AC_DEFINE([CRYPTO_INTERNAL], [1], [Compile with internal cryptographic implementation])
 770 ], [AC_MSG_ERROR([Unknown value for --with-crypto])]
 771 )
 772
 773 AS_IF([test "$enable_clippy_only" != "yes"], [
 774 AC_CHECK_HEADERS([json-c/json.h])
 775 AC_CHECK_LIB([json-c], [json_object_get], [LIBS="$LIBS -ljson-c"], [], [-lm])
 776 if test "$ac_cv_lib_json_c_json_object_get" = "no"; then
 777   AC_CHECK_LIB([json], [json_object_get], [LIBS="$LIBS -ljson"])
 778   if test "$ac_cv_lib_json_json_object_get" = "no"; then
 779       AC_MSG_ERROR([libjson is needed to compile])
 780   fi
 781 fi
 782 ])
 783
 784 AC_ARG_ENABLE([dev_build],
 785     AS_HELP_STRING([--enable-dev-build], [build for development]))
 786
 787 AC_ARG_ENABLE([scripting],
 788     AS_HELP_STRING([--enable-scripting], [Build with scripting support]))
 789
 790 AC_ARG_ENABLE([netlink-debug],
 791   AS_HELP_STRING([--disable-netlink-debug], [don't pretty print netlink debug messages]))
 792
 793 if test "$enable_netlink_debug" != "no" ; then
 794   AC_DEFINE([NETLINK_DEBUG], [1], [Netlink extra debugging code])
 795 fi
 796
 797 AM_CONDITIONAL([NETLINK_DEBUG], [test "$enable_netlink_debug" != "no"])
 798
 799 if test "$enable_time_check" != "no" ; then
 800   if test "$enable_time_check" = "yes" -o "$enable_time_check" = "" ; then
 801     AC_DEFINE([CONSUMED_TIME_CHECK], [5000000], [Consumed Time Check])
 802   else
 803     AC_DEFINE_UNQUOTED([CONSUMED_TIME_CHECK], [$enable_time_check], [Consumed Time Check])
 804   fi
 805 fi
 806
 807 case "${enable_cpu_time}" in
 808   "no")
 809   AC_DEFINE([EXCLUDE_CPU_TIME], [1], [Exclude getrusage data gathering])
 810   ;;
 811   "*")
 812   ;;
 813 esac
 814
 815 if test "$enable_rr_semantics" != "no" ; then
 816   AC_DEFINE([HAVE_V6_RR_SEMANTICS], [1], [Compile in v6 Route Replacement Semantics])
 817 fi
 818
 819 if test "$enable_datacenter" = "yes" ; then
 820   AC_DEFINE([HAVE_DATACENTER], [1], [Compile extensions for a DataCenter])
 821   DFLT_NAME="datacenter"
 822 else
 823   DFLT_NAME="traditional"
 824 fi
 825
 826 if test "$enable_cumulus" = "yes" ; then
 827   AC_DEFINE([HAVE_CUMULUS], [1], [Compile Special Cumulus Code in])
 828 fi
 829
 830 AC_SUBST([DFLT_NAME])
 831 AC_DEFINE_UNQUOTED([DFLT_NAME], ["$DFLT_NAME"], [Name of the configuration default set])
 832
 833 if test "$enable_shell_access" = "yes"; then
 834    AC_DEFINE([HAVE_SHELL_ACCESS], [1], [Allow user to use ssh/telnet/bash, be aware this is considered insecure])
 835 fi
 836
 837 #
 838 # Python for clippy
 839 #
 840
 841 AS_IF([test "$host" = "$build"], [
 842   AM_PATH_PYTHON([3])
 843   AC_CHECK_HEADER([gelf.h], [], [
 844     AC_MSG_ERROR([libelf headers are required for building clippy.  (Host only when cross-compiling.)])
 845   ])
 846
 847   LIBS_save="$LIBS"
 848   AC_CHECK_LIB([elf], [elf_memory], [], [
 849     AC_MSG_ERROR([libelf is required for building clippy.  (Host only when cross-compiling.)])
 850   ])
 851
 852   AC_CHECK_LIB([elf], [elf_getdata_rawchunk], [
 853     AC_DEFINE([HAVE_ELF_GETDATA_RAWCHUNK], [1], [Have elf_getdata_rawchunk()])
 854   ])
 855   AC_CHECK_LIB([elf], [gelf_getnote], [
 856     AC_DEFINE([HAVE_GELF_GETNOTE], [1], [Have gelf_getnote()])
 857   ])
 858   LIBS="$LIBS_save"
 859   unset LIBS_save
 860
 861   FRR_PYTHON_DEV
 862 ], [
 863   FRR_PYTHON
 864 ])
 865
 866 FRR_PYTHON_MODULES([pytest])
 867
 868 if test "$enable_doc" != "no"; then
 869   FRR_PYTHON_MODULES([sphinx], , [
 870     if test "$enable_doc" = "yes"; then
 871       AC_MSG_ERROR([Documentation was explicitly requested with --enable-doc but sphinx is not available for $PYTHON. Please disable docs or install sphinx.])
 872     fi
 873   ])
 874 fi
 875 AM_CONDITIONAL([DOC], [test "$enable_doc" != "no" -a "$frr_py_mod_sphinx" != "false"])
 876 AM_CONDITIONAL([DOC_HTML], [test "$enable_doc_html" = "yes"])
 877
 878 FRR_PYTHON_MOD_EXEC([sphinx], [--version], [
 879   PYSPHINX="-m sphinx"
 880 ], [
 881   PYSPHINX="-c 'import sys; from sphinx import main; sys.exit(main(sys.argv))'"
 882 ])
 883 AC_SUBST([PYSPHINX])
 884
 885 #
 886 # Logic for old vpn commands support.
 887 #
 888 if test "$enable_oldvpn_commands" = "yes"; then
 889    AC_DEFINE([KEEP_OLD_VPN_COMMANDS], [1], [Define for compiling with old vpn commands])
 890 fi
 891
 892 #
 893 # End of logic for protobuf support.
 894 #
 895
 896 AC_MSG_CHECKING([if zebra should be configurable to send Route Advertisements])
 897 if test "$enable_rtadv" != "no"; then
 898   AC_MSG_RESULT([yes])
 899   AC_DEFINE([HAVE_RTADV], [1], [Enable IPv6 Routing Advertisement support])
 900 else
 901   AC_MSG_RESULT([no])
 902 fi
 903
 904 if test "$enable_user" = "no"; then
 905   enable_user=""
 906 else
 907   if test "$enable_user" = "yes" || test "$enable_user" = ""; then
 908     enable_user="frr"
 909   fi
 910   AC_DEFINE_UNQUOTED([FRR_USER], ["${enable_user}"], [frr User])
 911 fi
 912
 913 if test "$enable_group" = "no"; then
 914   enable_group=""
 915 else
 916   if test "$enable_group" = "yes" || test "$enable_group" = ""; then
 917     enable_group="frr"
 918   fi
 919   AC_DEFINE_UNQUOTED([FRR_GROUP], ["${enable_group}"], [frr Group])
 920 fi
 921
 922 if test "$enable_vty_group" = "yes" ; then
 923   AC_MSG_ERROR([--enable-vty-group requires a group as argument, not yes])
 924 elif test "$enable_vty_group" != ""; then
 925   if test "$enable_vty_group" != "no"; then
 926     AC_DEFINE_UNQUOTED([VTY_GROUP], ["${enable_vty_group}"], [VTY Sockets Group])
 927   fi
 928 fi
 929 AC_SUBST([enable_user])
 930 AC_SUBST([enable_group])
 931 AC_SUBST([enable_vty_group])
 932
 933 enable_configfile_mask=${enable_configfile_mask:-0600}
 934 AC_DEFINE_UNQUOTED([CONFIGFILE_MASK], [${enable_configfile_mask}], [Mask for config files])
 935 AC_SUBST([enable_configfile_mask])
 936
 937 enable_logfile_mask=${enable_logfile_mask:-0600}
 938 AC_DEFINE_UNQUOTED([LOGFILE_MASK], [${enable_logfile_mask}], [Mask for log files])
 939
 940 MPATH_NUM=16
 941
 942 case "${enable_multipath}" in
 943   0)
 944     MPATH_NUM=64
 945     ;;
 946   [[1-9]|[1-9][0-9]|[1-9][0-9][0-9]])
 947     MPATH_NUM="${enable_multipath}"
 948     ;;
 949   "")
 950     ;;
 951   *)
 952     AC_MSG_FAILURE([Please specify digit to enable multipath ARG])
 953     ;;
 954 esac
 955
 956 AC_DEFINE_UNQUOTED([MULTIPATH_NUM], [$MPATH_NUM], [Maximum number of paths for a route])
 957
 958 AC_DEFINE_UNQUOTED([VTYSH_PAGER], ["$VTYSH_PAGER"], [What pager to use])
 959
 960
 961 TIMEOUT_MIN=2
 962 case "${with_service_timeout}" in
 963   [[1-9]|[1-9][0-9]|[1-9][0-9][0-9]])
 964     TIMEOUT_MIN="${with_service_timeout}"
 965     ;;
 966   0|"")
 967     ;;
 968   *)
 969     AC_MSG_FAILURE([Please specify digit for timeout ARG])
 970     ;;
 971 esac
 972 AC_SUBST([TIMEOUT_MIN])
 973
 974 dnl --------------------
 975 dnl Enable code coverage
 976 dnl --------------------
 977 AM_CONDITIONAL([HAVE_GCOV], [test "$enable_gcov" != "no"])
 978
 979 dnl ------------------------------------
 980 dnl Alpine only accepts numeric versions
 981 dnl ------------------------------------
 982 if test "$enable_numeric_version" != "" ; then
 983   VERSION="`echo ${VERSION} | tr -c -d '[[.0-9]]'`"
 984   PACKAGE_VERSION="`echo ${PACKAGE_VERSION} | tr -c -d '[[.0-9]]'`"
 985 fi
 986
 987 dnl -----------------------------------
 988 dnl Add extra version string to package
 989 dnl name, string and version fields.
 990 dnl -----------------------------------
 991 if test "$EXTRAVERSION" != "" ; then
 992   VERSION="${VERSION}${EXTRAVERSION}"
 993   PACKAGE_VERSION="${PACKAGE_VERSION}${EXTRAVERSION}"
 994   AC_SUBST(PACKAGE_EXTRAVERSION, ["${EXTRAVERSION}"])
 995   PACKAGE_STRING="${PACKAGE_STRING}${EXTRAVERSION}"
 996 fi
 997 AC_SUBST([EXTRAVERSION])
 998
 999 if test "$with_pkg_git_version" = "yes"; then
1000         if test -e "${srcdir}/.git"; then
1001                 AC_DEFINE([GIT_VERSION], [1], [include git version info])
1002         else    with_pkg_git_version="no"
1003                 AC_MSG_WARN([--with-pkg-git-version given, but this is not a git checkout])
1004         fi
1005 fi
1006 AM_CONDITIONAL([GIT_VERSION], [test "$with_pkg_git_version" = "yes"])
1007
1008 AC_CHECK_TOOL([OBJCOPY], [objcopy], [:])
1009 if test "$OBJCOPY" != ":"; then
1010   AC_CACHE_CHECK([for .interp value to use], [frr_cv_interp], [
1011     frr_cv_interp=""
1012     AC_LINK_IFELSE([AC_LANG_SOURCE([[int main() { return 0; }]])], [
1013       if $OBJCOPY -j.interp -Obinary conftest conftest.interp; then
1014         frr_cv_interp="`xargs -0 echo < conftest.interp`"
1015       fi
1016       test -f conftest.interp && rm conftest.interp
1017     ])
1018   ])
1019 fi
1020 if test -n "$frr_cv_interp"; then
1021   AC_DEFINE_UNQUOTED([INTERP], ["$frr_cv_interp"], [.interp value])
1022 fi
1023
1024 dnl -------------------------
1025 dnl Check other header files.
1026 dnl -------------------------
1027 AC_CHECK_HEADERS([stropts.h sys/ksym.h \
1028         linux/version.h asm/types.h endian.h sys/endian.h])
1029
1030 ac_stdatomic_ok=false
1031 AC_DEFINE([FRR_AUTOCONF_ATOMIC], [1], [did autoconf checks for atomic funcs])
1032 AC_CHECK_HEADER([stdatomic.h],[
1033
1034   AC_MSG_CHECKING([whether _Atomic qualifier works])
1035   AC_LINK_IFELSE([AC_LANG_SOURCE([[
1036 #include <stdatomic.h>
1037 int main(int argc, char **argv) {
1038   _Atomic int i = 0;
1039   return i;
1040 }
1041 ]])], [
1042     AC_DEFINE([HAVE_STDATOMIC_H], [1], [found stdatomic.h])
1043     AC_MSG_RESULT([yes])
1044     ac_stdatomic_ok=true
1045   ], [
1046     AC_MSG_RESULT([no])
1047   ])
1048 ])
1049
1050 AS_IF([$ac_stdatomic_ok], [true], [
1051   AC_MSG_CHECKING([for __atomic_* builtins])
1052   AC_LINK_IFELSE([AC_LANG_SOURCE([[
1053 int main(int argc, char **argv) {
1054   volatile int i = 1;
1055   __atomic_store_n (&i, 0, __ATOMIC_RELEASE);
1056   return __atomic_load_n (&i, __ATOMIC_ACQUIRE);
1057 }
1058 ]])], [
1059     AC_DEFINE([HAVE___ATOMIC], [1], [found __atomic builtins])
1060     AC_MSG_RESULT([yes])
1061   ], [
1062     AC_MSG_RESULT([no])
1063
1064     dnl FreeBSD 9 has a broken stdatomic.h where _Atomic doesn't work
1065     AC_MSG_CHECKING([for __sync_* builtins])
1066     AC_LINK_IFELSE([AC_LANG_SOURCE([[
1067 int main(int argc, char **argv) {
1068   volatile int i = 1;
1069   __sync_fetch_and_sub (&i, 1);
1070   return __sync_val_compare_and_swap (&i, 0, 1);
1071 }
1072 ]])], [
1073       AC_DEFINE([HAVE___SYNC], [1], [found __sync builtins])
1074       AC_MSG_RESULT([yes])
1075
1076       AC_MSG_CHECKING([for __sync_swap builtin])
1077       AC_LINK_IFELSE([AC_LANG_SOURCE([[
1078 int main(int argc, char **argv) {
1079   volatile int i = 1;
1080   return __sync_swap (&i, 2);
1081 }
1082 ]])], [
1083         AC_DEFINE([HAVE___SYNC_SWAP], 1, [found __sync_swap builtin])
1084         AC_MSG_RESULT([yes])
1085       ], [
1086         AC_MSG_RESULT([no])
1087       ])
1088
1089     ], [
1090       AC_MSG_RESULT([no])
1091       AC_MSG_FAILURE([stdatomic.h unavailable and $CC has neither __atomic nor __sync builtins])
1092     ])
1093   ])
1094 ])
1095
1096 needsync=true
1097
1098 AS_IF([$needsync], [
1099   dnl Linux
1100   AC_MSG_CHECKING([for Linux futex() support])
1101   AC_LINK_IFELSE([AC_LANG_PROGRAM([
1102 #ifndef _GNU_SOURCE
1103 #define _GNU_SOURCE
1104 #endif
1105 #include <unistd.h>
1106 #include <limits.h>
1107 #include <sys/time.h>
1108 #include <sys/syscall.h>
1109 #include <linux/futex.h>
1110
1111 int main(void);
1112 ],
1113 [
1114 {
1115   return syscall(SYS_futex, NULL, FUTEX_WAIT, 0, NULL, NULL, 0);
1116 }
1117 ])], [
1118     AC_MSG_RESULT([yes])
1119     AC_DEFINE(HAVE_SYNC_LINUX_FUTEX,,Have Linux futex support)
1120     needsync=false
1121   ], [
1122     AC_MSG_RESULT([no])
1123   ])
1124 ])
1125
1126 AS_IF([$needsync], [
1127   dnl FreeBSD
1128   AC_MSG_CHECKING([for FreeBSD _umtx_op() support])
1129   AC_LINK_IFELSE([AC_LANG_PROGRAM([
1130 #include <errno.h>
1131 #include <stdlib.h>
1132 #include <sys/types.h>
1133 #include <sys/umtx.h>
1134 int main(void);
1135 ],
1136 [
1137 {
1138   return _umtx_op(NULL, UMTX_OP_WAIT_UINT, 0, NULL, NULL);
1139 }
1140 ])], [
1141     AC_MSG_RESULT([yes])
1142     AC_DEFINE(HAVE_SYNC_UMTX_OP,,Have FreeBSD _umtx_op() support)
1143     needsync=false
1144   ], [
1145     AC_MSG_RESULT([no])
1146   ])
1147 ])
1148
1149 AS_IF([$needsync], [
1150   dnl OpenBSD patch (not upstream at the time of writing this)
1151   dnl https://marc.info/?l=openbsd-tech&m=147299508409549&w=2
1152   AC_MSG_CHECKING([for OpenBSD futex() support])
1153   AC_LINK_IFELSE([AC_LANG_PROGRAM([
1154 #include <sys/futex.h>
1155 int main(void);
1156 ],
1157 [
1158 {
1159   return futex(NULL, FUTEX_WAIT, 0, NULL, NULL, 0);
1160 }
1161 ])], [
1162     AC_MSG_RESULT([yes])
1163     AC_DEFINE(HAVE_SYNC_OPENBSD_FUTEX,,Have OpenBSD futex support)
1164     needsync=false
1165   ], [
1166     AC_MSG_RESULT([no])
1167   ])
1168 ])
1169
1170 dnl Utility macro to avoid retyping includes all the time
1171 m4_define([FRR_INCLUDES],
1172 [#ifdef SUNOS_5
1173 #define _POSIX_C_SOURCE 200809L
1174 #define __EXTENSIONS__
1175 #endif
1176 #include <stdio.h>
1177 #include <stdlib.h>
1178 #include <stddef.h>
1179 #include <sys/types.h>
1180 /* sys/conf.h depends on param.h on FBSD at least */
1181 #include <sys/param.h>
1182 /* Required for MAXSIG */
1183 #include <signal.h>
1184 #include <sys/socket.h>
1185 #ifdef __APPLE__
1186 # define __APPLE_USE_RFC_3542
1187 #endif
1188 #include <netinet/in.h>
1189 #include <sys/time.h>
1190 #include <time.h>
1191 #include <net/if.h>
1192 ])dnl
1193
1194 dnl Same applies for HAVE_NET_IF_VAR_H, which HAVE_NETINET6_ND6_H and
1195 dnl HAVE_NETINET_IN_VAR_H depend upon. But if_var.h depends on if.h, hence
1196 dnl an additional round for it.
1197
1198 AC_CHECK_HEADERS([net/if_var.h], [], [], [FRR_INCLUDES])
1199
1200 m4_define([FRR_INCLUDES],
1201 FRR_INCLUDES
1202 [#ifdef HAVE_NET_IF_VAR_H
1203 # include <net/if_var.h>
1204 #endif
1205 ])dnl
1206
1207 AC_CHECK_HEADERS([netinet/in_var.h \
1208         net/if_dl.h net/netopt.h \
1209         inet/nd.h netinet/ip_icmp.h \
1210         sys/sysctl.h sys/sockio.h sys/conf.h],
1211         [], [], [FRR_INCLUDES])
1212
1213 AC_CHECK_HEADERS([ucontext.h], [], [],
1214 [#ifndef __USE_GNU
1215 #define __USE_GNU
1216 #endif /* __USE_GNU */
1217 FRR_INCLUDES
1218 ])
1219
1220 m4_define([UCONTEXT_INCLUDES],
1221 [#include <ucontext.h>])dnl
1222
1223 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.uc_regs],
1224   [], [], [UCONTEXT_INCLUDES])
1225 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs],
1226   [AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs.nip],
1227    [], [], [UCONTEXT_INCLUDES])],
1228   [], [UCONTEXT_INCLUDES])
1229 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.gregs],
1230   [], [], [UCONTEXT_INCLUDES])
1231
1232 m4_define([FRR_INCLUDES],
1233 FRR_INCLUDES
1234 [
1235 #include <sys/un.h>
1236 #include <netinet/in_systm.h>
1237 #ifdef HAVE_NETINET_IN_VAR_H
1238 # include <netinet/in_var.h>
1239 #endif
1240 #ifdef HAVE_NET_IF_DL_H
1241 # include <net/if_dl.h>
1242 #endif
1243 #ifdef HAVE_NET_NETOPT_H
1244 # include <net/netopt.h>
1245 #endif
1246 #include <net/route.h>
1247 #ifdef HAVE_INET_ND_H
1248 # include <inet/nd.h>
1249 #endif
1250 #include <arpa/inet.h>
1251 /* Required for IDRP */
1252 #ifdef HAVE_NETINET_IP_ICMP_H
1253 # include <netinet/ip_icmp.h>
1254 #endif
1255 ])dnl
1256
1257 dnl V6 headers are checked below, after we check for v6
1258
1259 is_linux=false
1260
1261 AC_MSG_CHECKING([which operating system interface to use])
1262 case "$host_os" in
1263   sunos* | solaris2*)
1264     AC_MSG_FAILURE([Solaris support has been removed please see versions prior or equal to 7.5])
1265     ;;
1266   linux*)
1267     AC_MSG_RESULT([Linux])
1268
1269     AC_DEFINE([GNU_LINUX], [1], [GNU Linux])
1270     AC_DEFINE([HAVE_NETLINK], [1], [netlink])
1271     AC_DEFINE([LINUX_IPV6], [1], [Linux IPv6 stack])
1272
1273     dnl Linux has a compilation problem with mixing
1274     dnl netinet/in.h and linux/in6.h they are not
1275     dnl compatible.  There has been discussion on
1276     dnl how to fix it but no real progress on implementation
1277     dnl when they fix it, remove this
1278     AC_DEFINE([IPV6_MINHOPCOUNT], [73], [Linux ipv6 Min Hop Count])
1279
1280     is_linux=true
1281     ;;
1282   openbsd*)
1283     AC_MSG_RESULT([OpenBSD])
1284
1285     AC_DEFINE([OPEN_BSD], [1], [OpenBSD])
1286     AC_DEFINE([KAME], [1], [KAME IPv6])
1287     AC_DEFINE([BSD_V6_SYSCTL], [1], [BSD v6 sysctl to turn on and off forwarding])
1288     ;;
1289   *)
1290     AC_MSG_RESULT([BSD])
1291
1292     AC_DEFINE([HAVE_NET_RT_IFLIST], [1], [NET_RT_IFLIST])
1293     AC_DEFINE([KAME], [1], [KAME IPv6])
1294     AC_DEFINE([BSD_V6_SYSCTL], [1], [BSD v6 sysctl to turn on and off forwarding])
1295     ;;
1296 esac
1297 AM_CONDITIONAL([LINUX], [${is_linux}])
1298
1299 AC_SYS_LARGEFILE
1300
1301 dnl ------------------------
1302 dnl Integrated REALMS option
1303 dnl ------------------------
1304 if test "$enable_realms" = "yes"; then
1305     case "$host_os" in
1306       linux*)
1307        AC_DEFINE([SUPPORT_REALMS], [1], [Realms support])
1308        ;;
1309       *)
1310        echo "Sorry, only Linux has REALMS support"
1311        exit 1
1312        ;;
1313     esac
1314 fi
1315
1316 dnl ---------------
1317 dnl other functions
1318 dnl ---------------
1319 AC_CHECK_FUNCS([ \
1320         strlcat strlcpy \
1321         getgrouplist \
1322         openat \
1323         unlinkat \
1324         posix_fallocate \
1325         sendmmsg \
1326         explicit_bzero \
1327         ])
1328
1329 AC_CHECK_MEMBERS([struct mmsghdr.msg_hdr], [], [], FRR_INCLUDES)
1330
1331 dnl ##########################################################################
1332 dnl LARGE if block spans a lot of "configure"!
1333 if test "$enable_clippy_only" != "yes"; then
1334 dnl ##########################################################################
1335
1336 #
1337 # Logic for protobuf support.
1338 #
1339 PROTO3=false
1340 if test "$enable_protobuf" = "yes"; then
1341   # Check for protoc & protoc-c
1342
1343   # protoc is not required, it's only for a "be nice" helper target
1344   AC_CHECK_PROGS([PROTOC], [protoc], [/bin/false])
1345
1346   AC_CHECK_PROGS([PROTOC_C], [protoc-c], [/bin/false])
1347   if test "$PROTOC_C" = "/bin/false"; then
1348     AC_MSG_FAILURE([protobuf requested but protoc-c not found.  Install protobuf-c.])
1349   fi
1350
1351   PKG_CHECK_MODULES([PROTOBUF_C], [libprotobuf-c >= 0.14],, [
1352     AC_MSG_FAILURE([protobuf requested but libprotobuf-c not found.  Install protobuf-c.])
1353   ])
1354
1355   PROTO3=true
1356   AC_CHECK_HEADER([google/protobuf-c/protobuf-c.h],
1357                   [AC_CHECK_DECLS(PROTOBUF_C_LABEL_NONE,
1358                                   AC_DEFINE([HAVE_PROTOBUF_VERSION_3],
1359                                             [1], [Have Protobuf version 3]),
1360                                   [PROTO3=false],
1361                                   [#include <google/protobuf-c/protobuf-c.h>])],
1362                   [PROTO3=false && AC_MSG_FAILURE([protobuf requested but protobuf-c.h not found.  Install protobuf-c.])])
1363
1364   AC_DEFINE([HAVE_PROTOBUF], [1], [protobuf])
1365 fi
1366
1367
1368 dnl ---------------------
1369 dnl Integrated VTY option
1370 dnl ---------------------
1371 case "${enable_vtysh}" in
1372 "no")
1373   VTYSH="";;
1374 *)
1375   VTYSH="vtysh";
1376   AC_DEFINE([VTYSH], [1], [VTY shell])
1377
1378   prev_libs="$LIBS"
1379   AC_CHECK_LIB([readline], [readline], [
1380     LIBREADLINE="-lreadline"
1381   ], [
1382     dnl readline failed - it might be incorrectly linked and missing its
1383     dnl termcap/tinfo/curses dependency.  see if we can fix that...
1384     AC_SEARCH_LIBS([tputs], [termcap tinfo curses ncurses], [
1385       LIBREADLINE="$ac_cv_search_tputs"
1386     ], [
1387       AC_MSG_ERROR([libreadline (needed for vtysh) not found and/or missing dependencies])
1388     ])
1389
1390     dnl re-try with the lib we found above
1391     unset ac_cv_lib_readline_main
1392     AC_CHECK_LIB([readline], [main], [
1393       LIBREADLINE="-lreadline $LIBREADLINE"
1394     ], [
1395       AC_MSG_ERROR([libreadline (needed for vtysh) not found and/or missing dependencies])
1396     ], [$LIBREADLINE])
1397   ], [])
1398   LIBS="$LIBS -lreadline"
1399   AC_CHECK_FUNCS([rl_clear_visible_line])
1400   LIBS="$prev_libs"
1401
1402   AC_CHECK_HEADER([readline/history.h])
1403   if test "$ac_cv_header_readline_history_h" = "no"; then
1404     AC_MSG_ERROR([readline is too old to have readline/history.h, please update to the latest readline library.])
1405   fi
1406   AC_CHECK_LIB([readline], [rl_completion_matches], [true], [], [$LIBREADLINE])
1407   if test "$ac_cv_lib_readline_rl_completion_matches" = "no"; then
1408     AC_DEFINE([rl_completion_matches], [completion_matches], [Old readline])
1409   fi
1410   AC_CHECK_LIB([readline], [append_history], [frr_cv_append_history=yes], [frr_cv_append_history=no], [$LIBREADLINE])
1411   if test "$frr_cv_append_history" = "yes"; then
1412     AC_DEFINE([HAVE_APPEND_HISTORY], [1], [Have history.h append_history])
1413   fi
1414   ;;
1415 esac
1416 AC_SUBST([LIBREADLINE])
1417
1418 dnl ----------
1419 dnl PAM module
1420 dnl
1421 dnl FRR detects the PAM library it is built against by checking for a
1422 dnl functional pam_misc.h (Linux-PAM) or openpam.h (OpenPAM) header. pam_misc.h
1423 dnl is known to #include pam_appl.h, the standard header of a PAM library, and
1424 dnl openpam.h doesn't do that, although depends on the header too. Hence a
1425 dnl little assistance to AC_CHECK_HEADER is necessary for the proper detection
1426 dnl of OpenPAM.
1427 dnl ----------
1428 if test "$with_libpam" = "yes"; then
1429   AC_CHECK_HEADER([security/pam_misc.h],
1430     [AC_DEFINE([HAVE_PAM_MISC_H], [1], [Have pam_misc.h])
1431      AC_DEFINE([PAM_CONV_FUNC], [misc_conv], [Have misc_conv])
1432      pam_conv_func="misc_conv"
1433     ],
1434     [], FRR_INCLUDES)
1435   AC_CHECK_HEADER([security/openpam.h],
1436     [AC_DEFINE([HAVE_OPENPAM_H], [1], [Have openpam.h])
1437      AC_DEFINE([PAM_CONV_FUNC], [openpam_ttyconv], [Have openpam_ttyconv])
1438      pam_conv_func="openpam_ttyconv"
1439     ],
1440     [], FRR_INCLUDES[#include <security/pam_appl.h>])
1441   if test -z "$ac_cv_header_security_pam_misc_h$ac_cv_header_security_openpam_h" ; then
1442     AC_MSG_WARN([*** pam support will not be built ***])
1443     with_libpam="no"
1444   fi
1445 fi
1446
1447 if test "$with_libpam" = "yes"; then
1448 dnl took this test from proftpds configure.in and suited to our needs
1449 dnl -------------------------------------------------------------------------
1450 dnl
1451 dnl This next check looks funky due to a linker problem with some versions
1452 dnl of the PAM library.  Prior to 0.72 release, the Linux PAM shared library
1453 dnl omitted requiring libdl linking information. PAM-0.72 or better ships
1454 dnl with RedHat 6.2 and Debian 2.2 or better.
1455 AC_CHECK_LIB([pam], [pam_start],
1456   [AC_CHECK_LIB([pam], [$pam_conv_func],
1457     [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1458      LIBPAM="-lpam"],
1459     [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1460      LIBPAM="-lpam -lpam_misc"]
1461     )
1462   ],
1463
1464   [AC_CHECK_LIB([pam], [pam_end],
1465     [AC_CHECK_LIB([pam], [$pam_conv_func],
1466       [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1467        LIBPAM="-lpam -ldl"],
1468       [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1469        LIBPAM="-lpam -ldl -lpam_misc"]
1470      )
1471   ],AC_MSG_WARN([*** pam support will not be built ***]),
1472   [-ldl])
1473   ]
1474 )
1475 fi
1476 AC_SUBST([LIBPAM])
1477
1478 dnl -------------------------------
1479 dnl bgpd needs pow() and hence libm
1480 dnl -------------------------------
1481 TMPLIBS="$LIBS"
1482 LIBS=""
1483 AC_SEARCH_LIBS([pow], [m], [
1484   LIBM="$LIBS"
1485 ], [
1486   AC_MSG_WARN([Unable to find working pow function - bgpd may not link])
1487 ])
1488 LIBS="$TMPLIBS"
1489 AC_SUBST([LIBM])
1490
1491 AC_CHECK_FUNCS([ppoll], [
1492   AC_DEFINE([HAVE_PPOLL], [1], [have Linux/BSD ppoll()])
1493 ])
1494 AC_CHECK_FUNCS([pollts], [
1495   AC_DEFINE([HAVE_POLLTS], [1], [have NetBSD pollts()])
1496 ])
1497
1498 AC_CHECK_HEADER([asm-generic/unistd.h],
1499                 [AC_CHECK_DECL(__NR_setns,
1500                                AC_DEFINE([HAVE_NETNS], [1], [Have netns]),,
1501                                FRR_INCLUDES [#include <asm-generic/unistd.h>
1502                                ])
1503                  AC_CHECK_FUNCS([setns])]
1504                )
1505
1506 dnl --------------------------
1507 dnl Determine IS-IS I/O method
1508 dnl --------------------------
1509 AC_DEFINE([ISIS_METHOD_PFPACKET], [1], [constant value for isis method pfpacket])
1510 AC_DEFINE([ISIS_METHOD_DLPI], [2], [constant value for isis method dlpi])
1511 AC_DEFINE([ISIS_METHOD_BPF], [3], [constant value for isis method bpf])
1512 AC_CHECK_HEADER([net/bpf.h])
1513 AC_CHECK_HEADER([sys/dlpi.h])
1514 AC_MSG_CHECKING([zebra IS-IS I/O method])
1515
1516 case "$host_os" in
1517   linux*)
1518     AC_MSG_RESULT([pfpacket])
1519     ISIS_METHOD_MACRO="ISIS_METHOD_PFPACKET"
1520     ;;
1521   *)
1522     if test "$ac_cv_header_net_bpf_h" = "no"; then
1523       if test "$ac_cv_header_sys_dlpi_h" = "no"; then
1524         AC_MSG_RESULT([none])
1525         if test "$enable_isisd" = "yes" -o "$enable_fabricd" = "yes"; then
1526           AC_MSG_FAILURE([IS-IS support requested but no packet backend found])
1527         fi
1528         AC_MSG_WARN([*** IS-IS support will not be built ***])
1529         enable_isisd="no"
1530         enable_fabricd="no"
1531       else
1532         AC_MSG_RESULT([DLPI])
1533       fi
1534       ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1535     else
1536       AC_MSG_RESULT([BPF])
1537       ISIS_METHOD_MACRO="ISIS_METHOD_BPF"
1538     fi
1539     ;;
1540 esac
1541 AC_DEFINE_UNQUOTED([ISIS_METHOD], [$ISIS_METHOD_MACRO], [selected method for isis, == one of the constants])
1542
1543 dnl ---------------------------------------------------------------
1544 dnl figure out how to specify an interface in multicast sockets API
1545 dnl ---------------------------------------------------------------
1546 AC_CHECK_MEMBERS([struct ip_mreqn.imr_ifindex], [], [], FRR_INCLUDES)
1547
1548 AC_CHECK_HEADERS([linux/mroute.h], [], [],[
1549         #include <sys/socket.h>
1550         #include <netinet/in.h>
1551         #define _LINUX_IN_H             /* For Linux <= 2.6.25 */
1552         #include <linux/types.h>
1553 ])
1554
1555 AC_CHECK_HEADERS([linux/mroute6.h], [], [],[
1556         #include <sys/socket.h>
1557         #include <netinet/in.h>
1558         #define _LINUX_IN_H             /* For Linux <= 2.6.25 */
1559         #include <linux/types.h>
1560 ])
1561
1562 m4_define([FRR_INCLUDES],
1563 FRR_INCLUDES
1564 [#ifdef HAVE_LINUX_MROUTE_H
1565 # include <linux/mroute.h>
1566 #endif
1567 ])dnl
1568
1569 AC_CHECK_HEADERS([netinet/ip_mroute.h], [], [],[
1570         #include <sys/socket.h>
1571         #include <sys/types.h>
1572         #include <netinet/in.h>
1573         #include <net/route.h>
1574 ])
1575
1576 m4_define([FRR_INCLUDES],
1577 FRR_INCLUDES
1578 [#ifdef HAVE_NETINET_IP_MROUTE_H
1579 # include <netinet/ip_mroute.h>
1580 #endif
1581 ])dnl
1582
1583 AC_MSG_CHECKING([for RFC3678 protocol-independed API])
1584 AC_COMPILE_IFELSE(
1585 [ AC_LANG_PROGRAM([[
1586       #include <sys/types.h>
1587       #include <netinet/in.h>
1588   ]], [[
1589       struct group_req gr;
1590       int sock;
1591       setsockopt(sock, IPPROTO_IP, MCAST_JOIN_GROUP, (void*)&gr, sizeof(gr));
1592   ]])
1593 ],[
1594   AC_MSG_RESULT([yes])
1595   AC_DEFINE([HAVE_RFC3678], [1], [Have RFC3678 protocol-independed API])
1596 ],[
1597   AC_MSG_RESULT(no)
1598 ])
1599
1600 dnl ---------------------------------------------------------------
1601 dnl figure out how to check link-state
1602 dnl ---------------------------------------------------------------
1603 AC_CHECK_HEADER([net/if_media.h],
1604   [m4_define([LINK_DETECT_INCLUDES],
1605     FRR_INCLUDES
1606     [#include <net/if_media.h>
1607   ])
1608   AC_CHECK_MEMBERS([struct ifmediareq.ifm_status],
1609     AC_DEFINE([HAVE_BSD_LINK_DETECT], [1], [BSD link-detect]),
1610     [], LINK_DETECT_INCLUDES)],
1611   [],
1612   FRR_INCLUDES)
1613
1614 dnl ---------------------------------------------------------------
1615 dnl Additional, newer way to check link-state using ifi_link_state.
1616 dnl Not available in all BSD's when ifmediareq available
1617 dnl ---------------------------------------------------------------
1618 AC_CHECK_MEMBERS([struct if_data.ifi_link_state],
1619   AC_DEFINE([HAVE_BSD_IFI_LINK_STATE], [1], [BSD ifi_link_state available]),
1620   [], FRR_INCLUDES)
1621
1622 dnl ------------------------
1623 dnl TCP_MD5SIG socket option
1624 dnl ------------------------
1625
1626 AC_CHECK_HEADER([netinet/tcp.h],
1627    [m4_define([MD5_INCLUDES],
1628       FRR_INCLUDES
1629       [#include <netinet/tcp.h>
1630     ])
1631     AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)],
1632    [],
1633    FRR_INCLUDES)
1634 if test "$ac_cv_have_decl_TCP_MD5SIG" = "no"; then
1635   AC_CHECK_HEADER([linux/tcp.h],
1636        [m4_define([MD5_INCLUDES],
1637           FRR_INCLUDES
1638           [#include <linux/tcp.h>
1639         ])
1640        AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)])
1641 fi
1642
1643 LIBS_save="$LIBS"
1644 AC_CHECK_LIB([crypt], [crypt], [], [
1645   AC_CHECK_LIB([crypto], [DES_crypt])
1646 ])
1647 LIBCRYPT="$LIBS"
1648 LIBCRYPT="${LIBCRYPT%$LIBS_save}"
1649 LIBCRYPT="${LIBCRYPT#$LIBS_save}"
1650 AC_SUBST([LIBCRYPT])
1651 LIBS="$LIBS_save"
1652 unset LIBS_save
1653
1654 AC_CHECK_LIB([resolv], [res_init])
1655
1656 dnl ---------------------------
1657 dnl check system has PCRE regexp
1658 dnl ---------------------------
1659 if test "$enable_pcreposix" = "yes"; then
1660   AC_CHECK_LIB([pcreposix], [regexec], [], [
1661     AC_MSG_ERROR([--enable-pcreposix given but unable to find libpcreposix])
1662   ])
1663 fi
1664 AC_SUBST([HAVE_LIBPCREPOSIX])
1665
1666 dnl ---------------------------
1667 dnl check system has PCRE2 regexp
1668 dnl ---------------------------
1669 if test "$enable_pcre2posix" = "yes"; then
1670   AC_CHECK_LIB([pcre2-posix], [regexec], [], [
1671     AC_MSG_ERROR([--enable-pcre2posix given but unable to find libpcre2-posix])
1672   ])
1673 fi
1674 AC_SUBST([HAVE_LIBPCRE2_POSIX])
1675
1676 dnl ##########################################################################
1677 dnl test "$enable_clippy_only" != "yes"
1678 fi
1679 dnl END OF LARGE if block
1680 dnl ##########################################################################
1681
1682 dnl ------------------
1683 dnl check C-Ares library
1684 dnl ------------------
1685 PKG_CHECK_MODULES([CARES], [libcares], [
1686   c_ares_found=true
1687 ],[
1688   c_ares_found=false
1689 ])
1690 AM_CONDITIONAL([CARES], [$c_ares_found])
1691
1692
1693 dnl ----------------------------------------------------------------------------
1694 dnl figure out if domainname is available in the utsname struct (GNU extension).
1695 dnl ----------------------------------------------------------------------------
1696 AC_CHECK_MEMBERS([struct utsname.domainname], [], [], [#include <sys/utsname.h>])
1697
1698 dnl ------------------
1699 dnl IPv6 header checks
1700 dnl ------------------
1701 AC_CHECK_HEADERS([netinet6/in6.h netinet/in6_var.h \
1702         netinet6/in6_var.h netinet6/nd6.h], [], [],
1703         FRR_INCLUDES)
1704
1705 m4_define([FRR_INCLUDES],dnl
1706 FRR_INCLUDES
1707 [#ifdef HAVE_NETINET6_IN6_H
1708 #include <netinet6/in6.h>
1709 #endif
1710 #ifdef HAVE_NETINET_IN6_VAR_H
1711 #include <netinet/in6_var.h>
1712 #endif
1713 #include <netinet/icmp6.h>
1714 #ifdef HAVE_NETINET6_IN6_VAR_H
1715 # include <netinet6/in6_var.h>
1716 #endif
1717 #ifdef HAVE_NETINET6_ND6_H
1718 # include <netinet6/nd6.h>
1719 #endif
1720 ])dnl
1721
1722 dnl --------------------
1723 dnl Daemon disable check
1724 dnl --------------------
1725
1726 AS_IF([test "$enable_bgpd" != "no"], [
1727   AC_DEFINE([HAVE_BGPD], [1], [bgpd])
1728 ])
1729
1730 AS_IF([test "$enable_ripd" != "no"], [
1731   AC_DEFINE([HAVE_RIPD], [1], [ripd])
1732 ])
1733
1734 AS_IF([test "$enable_ripngd" != "no"], [
1735   AC_DEFINE([HAVE_RIPNGD], [1], [ripngd])
1736 ])
1737
1738 AS_IF([test "$enable_ospfd" != "no"], [
1739   AC_DEFINE([HAVE_OSPFD], [1], [ospfd])
1740 ])
1741
1742 AS_IF([test "$enable_ospf6d" != "no"], [
1743   AC_DEFINE([HAVE_OSPF6D], [1], [ospf6d])
1744 ])
1745
1746 AS_IF([test "$enable_ldpd" != "no"], [
1747   AC_DEFINE([HAVE_LDPD], [1], [ldpd])
1748 ])
1749
1750 AS_IF([test "$enable_nhrpd" != "no"], [
1751   AC_DEFINE([HAVE_NHRPD], [1], [nhrpd])
1752 ])
1753
1754 AS_IF([test "$enable_eigrpd" != "no"], [
1755   AC_DEFINE([HAVE_EIGRPD], [1], [eigrpd])
1756 ])
1757
1758 AS_IF([test "$enable_babeld" != "no"], [
1759   AC_DEFINE([HAVE_BABELD], [1], [babeld])
1760 ])
1761
1762 AS_IF([test "$enable_isisd" != "no"], [
1763   AC_DEFINE([HAVE_ISISD], [1], [isisd])
1764 ])
1765
1766 AS_IF([test "$enable_pimd" != "no"], [
1767   AC_DEFINE([HAVE_PIMD], [1], [pimd])
1768 ])
1769
1770 AS_IF([test "$enable_pim6d" != "no"], [
1771   AC_DEFINE([HAVE_PIM6D], [1], [pim6d])
1772 ])
1773
1774 AS_IF([test "$enable_pbrd" != "no"], [
1775   AC_DEFINE([HAVE_PBRD], [1], [pbrd])
1776 ])
1777
1778 AS_IF([test "$enable_sharpd" = "yes"], [
1779   AC_DEFINE([HAVE_SHARPD], [1], [sharpd])
1780 ])
1781
1782 AS_IF([test "$enable_staticd" != "no"], [
1783   AC_DEFINE([HAVE_STATICD], [1], [staticd])
1784 ])
1785
1786 AS_IF([test "$enable_fabricd" != "no"], [
1787   AC_DEFINE([HAVE_FABRICD], [1], [fabricd])
1788 ])
1789
1790 AS_IF([test "$enable_vrrpd" != "no"], [
1791   AC_DEFINE([HAVE_VRRPD], [1], [vrrpd])
1792 ])
1793
1794 if test "$enable_bfdd" = "no"; then
1795   AC_DEFINE([HAVE_BFDD], [0], [bfdd])
1796   BFDD=""
1797 else
1798   AC_DEFINE([HAVE_BFDD], [1], [bfdd])
1799   BFDD="bfdd"
1800
1801   case $host_os in
1802     linux*)
1803       AC_DEFINE([BFD_LINUX], [1], [bfdd])
1804       ;;
1805
1806     *)
1807       AC_DEFINE([BFD_BSD], [1], [bfdd])
1808       ;;
1809   esac
1810 fi
1811
1812 AS_IF([test "$enable_pathd" != "no"], [
1813   AC_DEFINE([HAVE_PATHD], [1], [pathd])
1814 ])
1815
1816 if test "$ac_cv_lib_json_c_json_object_get" = "no" -a "$BFDD" = "bfdd"; then
1817   AC_MSG_ERROR(["you must use json-c library to use bfdd"])
1818 fi
1819
1820 NHRPD=""
1821 case "$host_os" in
1822   linux*)
1823     case "${enable_nhrpd}" in
1824       no)
1825         ;;
1826       yes)
1827         if test "$enable_clippy_only" != "yes"; then
1828         if test "$c_ares_found" != "true" ; then
1829           AC_MSG_ERROR([nhrpd requires libcares.  Please install c-ares and its -dev headers.])
1830         fi
1831         fi
1832         NHRPD="nhrpd"
1833         ;;
1834       *)
1835         if test "$c_ares_found" = "true" ; then
1836           NHRPD="nhrpd"
1837         fi
1838         ;;
1839     esac
1840     ;;
1841   *)
1842     if test "$enable_nhrpd" = "yes"; then
1843       AC_MSG_ERROR([nhrpd requires kernel APIs that are only present on Linux.])
1844     fi
1845     ;;
1846 esac
1847
1848 if test "$enable_watchfrr" = "no";then
1849   WATCHFRR=""
1850 else
1851   WATCHFRR="watchfrr"
1852 fi
1853
1854 OSPFCLIENT=""
1855 if test "$enable_ospfapi" != "no";then
1856     AC_DEFINE([SUPPORT_OSPF_API], [1], [OSPFAPI])
1857
1858   if test "$enable_ospfclient" != "no";then
1859       OSPFCLIENT="ospfclient"
1860   fi
1861 fi
1862
1863 if test "$enable_bgp_announce" = "no";then
1864   AC_DEFINE([DISABLE_BGP_ANNOUNCE], [1], [Disable BGP installation to zebra])
1865 else
1866   AC_DEFINE([DISABLE_BGP_ANNOUNCE], [0], [Disable BGP installation to zebra])
1867 fi
1868
1869 if test "$enable_bgp_vnc" != "no";then
1870   AC_DEFINE([ENABLE_BGP_VNC], [1], [Enable BGP VNC support])
1871 fi
1872
1873 bgpd_bmp=false
1874 case "${enable_bgp_bmp}" in
1875   no)
1876     ;;
1877   yes)
1878     if test "$c_ares_found" != "true" ; then
1879       AC_MSG_ERROR([BMP support requires libcares.  Please install c-ares and its -dev headers.])
1880     fi
1881     bgpd_bmp=true
1882     ;;
1883   *)
1884     if test "$c_ares_found" = "true" ; then
1885       bgpd_bmp=true
1886     fi
1887     ;;
1888 esac
1889
1890 if test "$enable_version_build_config" != "no";then
1891   AC_DEFINE([ENABLE_VERSION_BUILD_CONFIG], [1], [Report build configs in show version])
1892 fi
1893
1894 dnl ##########################################################################
1895 dnl LARGE if block
1896 if test "$enable_clippy_only" != "yes"; then
1897 dnl ##########################################################################
1898
1899 dnl ------------------
1900 dnl check Net-SNMP library
1901 dnl ------------------
1902 if test "$enable_snmp" != "" -a "$enable_snmp" != "no"; then
1903    AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], [no])
1904    if test "$NETSNMP_CONFIG" = "no"; then
1905       AC_MSG_ERROR([--enable-snmp given but unable to find net-snmp-config])
1906    fi
1907    SNMP_LIBS="`${NETSNMP_CONFIG} --agent-libs`"
1908    SNMP_CFLAGS="`${NETSNMP_CONFIG} --base-cflags`"
1909    # net-snmp lists all of its own dependencies.  we absolutely do not want that
1910    # among other things we avoid a GPL vs. OpenSSL license conflict here
1911    for removelib in crypto ssl sensors pci wrap; do
1912      SNMP_LIBS="`echo $SNMP_LIBS | sed -e 's/\(^\|\s\)-l'$removelib'\b/ /g' -e 's/\(^\|\s\)\([^\s]*\/\)\?lib'$removelib'\.[^\s]\+\b/ /g'`"
1913    done
1914    AC_MSG_CHECKING([whether we can link to Net-SNMP])
1915    AC_LINK_IFELSE_FLAGS([$SNMP_CFLAGS], [$SNMP_LIBS], [AC_LANG_PROGRAM([
1916 int main(void);
1917 ],
1918 [
1919 {
1920   return 0;
1921 }
1922 ])], [
1923      AC_MSG_RESULT([no])
1924      AC_MSG_ERROR([--enable-snmp given but not usable])])
1925    case "${enable_snmp}" in
1926      yes)
1927       SNMP_METHOD=agentx
1928       ;;
1929      agentx)
1930       SNMP_METHOD="${enable_snmp}"
1931       ;;
1932      *)
1933       AC_MSG_ERROR([--enable-snmp given with an unknown method (${enable_snmp}). Use yes or agentx])
1934       ;;
1935    esac
1936    AH_TEMPLATE([SNMP_AGENTX], [Use SNMP AgentX to interface with snmpd])
1937    AC_DEFINE_UNQUOTED(AS_TR_CPP(SNMP_${SNMP_METHOD}),,[SNMP method to interface with snmpd])
1938 fi
1939 AC_SUBST([SNMP_LIBS])
1940 AC_SUBST([SNMP_CFLAGS])
1941
1942 dnl ---------------
1943 dnl libyang
1944 dnl ---------------
1945 PKG_CHECK_MODULES([LIBYANG], [libyang >= 2.0.0], , [
1946   AC_MSG_ERROR([libyang (>= 2.0.0) was not found on your system.])
1947 ])
1948 ac_cflags_save="$CFLAGS"
1949 CFLAGS="$CFLAGS $LIBYANG_CFLAGS"
1950 AC_CHECK_MEMBER([struct lyd_node.priv], [], [
1951   AC_MSG_ERROR([m4_normalize([
1952     libyang needs to be compiled with ENABLE_LYD_PRIV=ON.
1953     Instructions for this are included in the build documentation for your platform at http://docs.frrouting.org/projects/dev-guide/en/latest/building.html])
1954   ])
1955 ], [[#include <libyang/libyang.h>]])
1956 CFLAGS="$ac_cflags_save"
1957
1958 dnl ---------------
1959 dnl configuration rollbacks
1960 dnl ---------------
1961 SQLITE3=false
1962 if test "$enable_config_rollbacks" = "yes"; then
1963   PKG_CHECK_MODULES([SQLITE3], [sqlite3], [
1964     AC_DEFINE([HAVE_CONFIG_ROLLBACKS], [1], [Enable configuration rollbacks])
1965     AC_DEFINE([HAVE_SQLITE3], [1], [Enable sqlite3 database])
1966     SQLITE3=true
1967   ], [
1968     AC_MSG_ERROR([--enable-config-rollbacks given but sqlite3 was not found on your system.])
1969   ])
1970 fi
1971
1972 dnl ---------------
1973 dnl confd
1974 dnl ---------------
1975 if test "$enable_confd" != "" -a "$enable_confd" != "no"; then
1976    AC_CHECK_PROG([CONFD], [confd], [confd], [/bin/false], "${enable_confd}/bin")
1977    if test "$CONFD" = "/bin/false"; then
1978       AC_MSG_ERROR([confd was not found on your system.])]
1979    fi
1980    AC_CHECK_PROG([CONFDC], [confdc], [confdc], [/bin/false], "${enable_confd}/bin")
1981    CONFD_CFLAGS="-I${enable_confd}/include -L${enable_confd}/lib"
1982    AC_SUBST([CONFD_CFLAGS])
1983    CONFD_LIBS="-lconfd"
1984    AC_SUBST([CONFD_LIBS])
1985    AC_DEFINE([HAVE_CONFD], [1], [Enable confd integration])
1986 fi
1987
1988 dnl ---------------
1989 dnl sysrepo
1990 dnl ---------------
1991 if test "$enable_sysrepo" = "yes"; then
1992   PKG_CHECK_MODULES([SYSREPO], [sysrepo >= 2.1.42],
1993       [AC_DEFINE([HAVE_SYSREPO], [1], [Enable sysrepo integration])
1994       SYSREPO=true],
1995       [SYSREPO=false
1996       AC_MSG_ERROR([sysrepo was not found on your system.])]
1997   )
1998 fi
1999
2000 dnl ---------------
2001 dnl gRPC
2002 dnl ---------------
2003 if test "$enable_grpc" = "yes"; then
2004   AC_LANG_PUSH([C++])
2005   AX_CXX_COMPILE_STDCXX([11], [ext])
2006   PKG_CHECK_MODULES([GRPC], [grpc >= 6.0.0 grpc++ >= 1.16.1 protobuf >= 3.6.1 ], [
2007     AC_CHECK_PROGS([PROTOC], [protoc], [/bin/false])
2008     if test "$PROTOC" = "/bin/false"; then
2009       AC_MSG_FAILURE([grpc requested but protoc not found.])
2010     fi
2011
2012     AC_DEFINE([HAVE_GRPC], [1], [Enable the gRPC northbound plugin])
2013     GRPC=true
2014   ], [
2015     GRPC=false
2016     AC_MSG_ERROR([grpc/grpc++ were not found on your system.])
2017   ])
2018   AC_LANG_POP([C++])
2019 fi
2020
2021 dnl ---------
2022 dnl DPDK
2023 dnl ---------
2024 if test "$enable_dp_dpdk" = "yes"; then
2025   PKG_CHECK_MODULES([DPDK], [libdpdk], [
2026     AC_DEFINE([HAVE_DPDK], [1], [Enable DPDK backend])
2027     DPDK=true
2028   ], [
2029     AC_MSG_ERROR([configuration specifies --enable-dp-dpdk but DPDK libs were not found])
2030   ])
2031 fi
2032
2033 dnl -----
2034 dnl LTTng
2035 dnl -----
2036 if test "$enable_lttng" = "yes"; then
2037   PKG_CHECK_MODULES([UST], [lttng-ust >= 2.9.0], [
2038     AC_DEFINE([HAVE_LTTNG], [1], [Enable LTTng support])
2039     LTTNG=true
2040   ], [
2041     AC_MSG_ERROR([configuration specifies --enable-lttng but lttng-ust was not found])
2042   ])
2043 fi
2044
2045 dnl ----
2046 dnl USDT
2047 dnl ----
2048 if test "$enable_usdt" = "yes"; then
2049   AC_CHECK_HEADERS([sys/sdt.h], [
2050     AC_DEFINE([HAVE_USDT], [1], [Enable USDT probes])
2051     USDT=true
2052   ], [
2053     AC_MSG_ERROR([configuration specifies --enable-usdt but no USDT kernel headers (sys/sdt.h) found])
2054   ])
2055 fi
2056
2057 dnl ------
2058 dnl ZeroMQ
2059 dnl ------
2060 if test "$enable_zeromq" != "no"; then
2061   PKG_CHECK_MODULES([ZEROMQ], [libzmq >= 4.0.0], [
2062     AC_DEFINE([HAVE_ZEROMQ], [1], [Enable ZeroMQ support])
2063     ZEROMQ=true
2064   ], [
2065     if test "$enable_zeromq" = "yes"; then
2066       AC_MSG_ERROR([configuration specifies --enable-zeromq but libzmq was not found])
2067     fi
2068   ])
2069 fi
2070
2071 dnl ------------------------------------
2072 dnl Enable RPKI and add librtr to libs
2073 dnl ------------------------------------
2074 if test "$enable_rpki" = "yes"; then
2075   PKG_CHECK_MODULES([RTRLIB], [rtrlib >= 0.8.0],
2076       [RPKI=true],
2077       [RPKI=false
2078       AC_MSG_ERROR([rtrlib was not found on your system or is too old.])]
2079   )
2080 fi
2081
2082 dnl ------------------------------------
2083 dnl pimd and pim6d not supported on OpenBSD and MacOS
2084 dnl ------------------------------------
2085 if test "$enable_pimd" != "no"; then
2086 AC_MSG_CHECKING([for pimd OS support])
2087 case "$host_os" in
2088   darwin*)
2089     AC_MSG_RESULT([no])
2090     enable_pimd="no"
2091     ;;
2092   openbsd*)
2093     AC_MSG_RESULT([no])
2094     enable_pimd="no"
2095     ;;
2096   *)
2097     AC_MSG_RESULT([yes])
2098     ;;
2099 esac
2100 fi
2101
2102 if test "$enable_pim6d" != "no"; then
2103 AC_MSG_CHECKING([for pim6d OS support])
2104 case "$host_os" in
2105   linux*)
2106     AC_MSG_RESULT([yes])
2107     ;;
2108   *)
2109     AC_MSG_RESULT([no])
2110     enable_pim6d="no"
2111     ;;
2112 esac
2113 fi
2114
2115 dnl -------------------------------------
2116 dnl VRRP is only supported on linux
2117 dnl -------------------------------------
2118 if test "$enable_vrrpd" != "no"; then
2119 AC_MSG_CHECKING([for VRRP OS support])
2120 case "$host_os" in
2121   linux*)
2122     AC_MSG_RESULT([yes])
2123     ;;
2124   *)
2125     AC_MSG_RESULT([no])
2126     enable_vrrpd="no"
2127     ;;
2128 esac
2129 fi
2130
2131 dnl ------------------------------------------
2132 dnl Check whether rtrlib was build with ssh support
2133 dnl ------------------------------------------
2134 AC_MSG_CHECKING([whether the RTR Library is compiled with SSH])
2135 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "rtrlib/rtrlib.h"]],
2136                         [[struct tr_ssh_config config;]])],
2137         [AC_MSG_RESULT([yes])
2138         AC_DEFINE([FOUND_SSH], [1], [found_ssh])],
2139         AC_MSG_RESULT([no])
2140 )
2141
2142 dnl ---------------
2143 dnl dlopen & dlinfo
2144 dnl ---------------
2145 LIBS_save="$LIBS"
2146 AC_SEARCH_LIBS([dlopen], [dl dld], [], [
2147   AC_MSG_ERROR([unable to find the dlopen()])
2148 ])
2149
2150 AC_CHECK_HEADERS([link.h])
2151
2152 AC_CACHE_CHECK([for dlinfo(RTLD_DI_ORIGIN)], [frr_cv_rtld_di_origin], [
2153   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2154 #include <stdlib.h>
2155 #ifdef HAVE_LINK_H
2156 #include <link.h>
2157 #endif
2158 #include <dlfcn.h>
2159 ]], [[
2160   char origin[1];
2161   dlinfo (NULL, RTLD_DI_ORIGIN, &origin);
2162 ]])], [
2163     frr_cv_rtld_di_origin=yes
2164   ], [
2165     frr_cv_rtld_di_origin=no
2166   ])
2167 ])
2168 if test "$frr_cv_rtld_di_origin" = "yes"; then
2169   AC_DEFINE([HAVE_DLINFO_ORIGIN], [1], [Have dlinfo RTLD_DI_ORIGIN])
2170 fi
2171
2172 AC_CACHE_CHECK([for dlinfo(RTLD_DI_LINKMAP)], [frr_cv_rtld_di_linkmap], [
2173   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2174 #include <stdlib.h>
2175 #ifdef HAVE_LINK_H
2176 #include <link.h>
2177 #endif
2178 #include <dlfcn.h>
2179 ]], [[
2180   struct link_map *lm = NULL;
2181   dlinfo (NULL, RTLD_DI_LINKMAP, &lm);
2182 ]])], [
2183     frr_cv_rtld_di_linkmap=yes
2184   ], [
2185     frr_cv_rtld_di_linkmap=no
2186   ])
2187 ])
2188 if test "$frr_cv_rtld_di_linkmap" = "yes"; then
2189   AC_DEFINE([HAVE_DLINFO_LINKMAP], [1], [Have dlinfo RTLD_DI_LINKMAP])
2190 fi
2191
2192 LIBDL="$LIBS"
2193 LIBDL="${LIBDL%$LIBS_save}"
2194 LIBDL="${LIBDL#$LIBS_save}"
2195 AC_SUBST([LIBDL])
2196 LIBS="$LIBS_save"
2197 unset LIBS_save
2198
2199 dnl ##########################################################################
2200 dnl test "$enable_clippy_only" != "yes"
2201 fi
2202 dnl END OF LARGE if block
2203 dnl ##########################################################################
2204
2205 dnl ---------------------------
2206 dnl sockaddr and netinet checks
2207 dnl ---------------------------
2208 AC_CHECK_TYPES([
2209         struct sockaddr_dl,
2210         struct vifctl, struct mfcctl, struct sioc_sg_req,
2211         vifi_t, struct sioc_vif_req, struct igmpmsg,
2212         struct ifaliasreq, struct if6_aliasreq, struct in6_aliasreq,
2213         struct nd_opt_adv_interval,
2214         struct nd_opt_homeagent_info, struct nd_opt_adv_interval,
2215         struct nd_opt_rdnss, struct nd_opt_dnssl],
2216         [], [], FRR_INCLUDES)
2217
2218 AC_CHECK_MEMBERS([struct sockaddr.sa_len,
2219         struct sockaddr_in.sin_len, struct sockaddr_un.sun_len,
2220         struct sockaddr_dl.sdl_len,
2221         struct if6_aliasreq.ifra_lifetime,
2222         struct nd_opt_adv_interval.nd_opt_ai_type],
2223         [], [], FRR_INCLUDES)
2224
2225 dnl ---------------------------
2226 dnl IRDP/pktinfo/icmphdr checks
2227 dnl ---------------------------
2228
2229 AC_CHECK_TYPES([struct in_pktinfo], [
2230   AC_CHECK_TYPES([struct icmphdr], [
2231     IRDP=true
2232   ], [
2233     IRDP=false
2234   ], [FRR_INCLUDES])
2235 ], [
2236   IRDP=false
2237 ], [FRR_INCLUDES])
2238
2239 case "${enable_irdp}" in
2240 yes)
2241   $IRDP || AC_MSG_ERROR(['IRDP requires in_pktinfo at the moment!'])
2242   ;;
2243 no)
2244   IRDP=false
2245   ;;
2246 esac
2247
2248
2249 dnl -----------------------
2250 dnl checking for IP_PKTINFO
2251 dnl -----------------------
2252 AC_MSG_CHECKING([for IP_PKTINFO])
2253 AC_COMPILE_IFELSE(
2254 [ AC_LANG_PROGRAM([[
2255         #include <netdb.h>
2256    ]], [[
2257         int opt = IP_PKTINFO;
2258    ]])
2259 ],[
2260   AC_MSG_RESULT([yes])
2261   AC_DEFINE([HAVE_IP_PKTINFO], [1], [Have IP_PKTINFO])
2262 ],[
2263   AC_MSG_RESULT([no])
2264 ])
2265
2266 dnl ---------------------------
2267 dnl checking for IP_RECVDSTADDR
2268 dnl ---------------------------
2269 AC_MSG_CHECKING([for IP_RECVDSTADDR])
2270 AC_COMPILE_IFELSE(
2271 [ AC_LANG_PROGRAM([[
2272         #include <netinet/in.h>
2273   ]], [[
2274         int opt = IP_RECVDSTADDR;
2275   ]])
2276 ],[
2277   AC_MSG_RESULT([yes])
2278   AC_DEFINE([HAVE_IP_RECVDSTADDR], [1], [Have IP_RECVDSTADDR])
2279 ],[
2280   AC_MSG_RESULT([no])
2281 ])
2282
2283 dnl ----------------------
2284 dnl checking for IP_RECVIF
2285 dnl ----------------------
2286 AC_MSG_CHECKING([for IP_RECVIF])
2287 AC_COMPILE_IFELSE(
2288 [ AC_LANG_PROGRAM([[
2289         #include <netinet/in.h>
2290   ]], [[
2291         int opt = IP_RECVIF;
2292   ]])
2293 ],[
2294   AC_MSG_RESULT([yes])
2295   AC_DEFINE([HAVE_IP_RECVIF], [1], [Have IP_RECVIF])
2296 ],[
2297   AC_MSG_RESULT([no])
2298 ])
2299
2300 dnl ----------------------
2301 dnl checking for SO_BINDANY
2302 dnl ----------------------
2303 AC_MSG_CHECKING([for SO_BINDANY])
2304 AC_COMPILE_IFELSE(
2305 [ AC_LANG_PROGRAM([[
2306         #include <sys/socket.h>
2307   ]], [[
2308         int opt = SO_BINDANY;
2309   ]])
2310 ],[
2311   AC_MSG_RESULT([yes])
2312   AC_DEFINE([HAVE_SO_BINDANY], [1], [Have SO_BINDANY])
2313 ],[
2314   AC_MSG_RESULT([no])
2315 ])
2316
2317 dnl ----------------------
2318 dnl checking for IP_FREEBIND
2319 dnl ----------------------
2320 AC_MSG_CHECKING([for IP_FREEBIND])
2321 AC_COMPILE_IFELSE(
2322 [ AC_LANG_PROGRAM([[
2323         #include <netinet/in.h>
2324   ]], [[
2325         int opt = IP_FREEBIND;
2326   ]])
2327 ],[
2328   AC_MSG_RESULT([yes])
2329   AC_DEFINE([HAVE_IP_FREEBIND], [1], [Have IP_FREEBIND])
2330 ],[
2331   AC_MSG_RESULT([no])
2332 ])
2333
2334 dnl --------------------------------------
2335 dnl checking for be32dec existence or not
2336 dnl --------------------------------------
2337 AC_CHECK_DECLS([be32enc, be32dec], [], [], [
2338         #ifdef HAVE_SYS_ENDIAN_H
2339         #include <sys/endian.h>
2340         #endif
2341         #ifdef HAVE_ENDIAN_H
2342         #include <endian.h>
2343         #endif
2344 ])
2345
2346 dnl --------------------------------------
2347 dnl checking for clock_time monotonic struct and call
2348 dnl --------------------------------------
2349 AC_CHECK_DECL([CLOCK_MONOTONIC],
2350         [AC_CHECK_LIB([rt], [clock_gettime], [LIBS="$LIBS -lrt"])
2351          AC_DEFINE([HAVE_CLOCK_MONOTONIC], [1], [Have monotonic clock])
2352 ], [AC_MSG_RESULT([no])], [FRR_INCLUDES])
2353
2354 AC_CHECK_DECL([CLOCK_THREAD_CPUTIME_ID], [
2355          AC_DEFINE([HAVE_CLOCK_THREAD_CPUTIME_ID], [1], [Have cpu-time clock])
2356 ], [AC_MSG_RESULT([no])], [FRR_INCLUDES])
2357
2358 AC_SEARCH_LIBS([clock_nanosleep], [rt], [
2359   AC_DEFINE([HAVE_CLOCK_NANOSLEEP], [1], [Have clock_nanosleep()])
2360 ])
2361
2362 dnl --------------------------------------
2363 dnl checking for flex and bison
2364 dnl --------------------------------------
2365
2366 dnl autoconf 2.69 AC_PROG_LEX has no parameters
2367 dnl autoconf 2.70 AC_PROG_LEX prints a deprecation warning without params
2368 m4_if(m4_version_compare(m4_defn([AC_AUTOCONF_VERSION]), [2.70]), [-1], [dnl
2369   dnl autoconf < 2.70
2370   AC_PROG_LEX
2371 ], [
2372   dnl autoconf >= 2.70
2373   AC_PROG_LEX([noyywrap])
2374 ])
2375
2376 AC_MSG_CHECKING([version of flex])
2377 frr_ac_flex_version="$(eval $LEX -V | grep flex | head -n 1)"
2378 frr_ac_flex_version="${frr_ac_flex_version##* }"
2379 AC_MSG_RESULT([$frr_ac_flex_version])
2380 AX_COMPARE_VERSION([$frr_ac_flex_version], [lt], [2.5.20], [
2381   LEX="$SHELL $missing_dir/missing flex"
2382   if test -f "${srcdir}/lib/command_lex.c" -a -f "${srcdir}/lib/command_lex.h"; then
2383     AC_MSG_WARN([using pregenerated flex output files])
2384   else
2385     AC_MSG_ERROR([flex failure and pregenerated files not included (probably a git build)])
2386   fi
2387   AC_SUBST([LEX_OUTPUT_ROOT], [lex.yy])
2388   AC_SUBST([LEXLIB], [''])
2389 ])
2390
2391 AC_PROG_YACC
2392 dnl thanks GNU bison for this b*llshit...
2393 AC_MSG_CHECKING([version of bison])
2394 frr_ac_bison_version="$(eval $YACC -V | grep bison | head -n 1)"
2395 frr_ac_bison_version="${frr_ac_bison_version##* }"
2396 frr_ac_bison_missing="false"
2397 case "x${frr_ac_bison_version}x" in
2398   x2.7*)
2399     BISON_OPENBRACE='"'
2400     BISON_CLOSEBRACE='"'
2401     BISON_VERBOSE=''
2402     AC_MSG_RESULT([$frr_ac_bison_version - 2.7 or older])
2403     ;;
2404   x2.*|x1.*)
2405     AC_MSG_RESULT([$frr_ac_bison_version])
2406     AC_MSG_WARN([installed bison is too old.  Please install GNU bison 2.7.x or newer.])
2407     frr_ac_bison_missing="true"
2408     ;;
2409   x)
2410     AC_MSG_RESULT([none])
2411     AC_MSG_WARN([could not determine bison version.  Please install GNU bison 2.7.x or newer.])
2412     frr_ac_bison_missing="true"
2413     ;;
2414   x3.[012][^0-9]*)
2415     BISON_OPENBRACE='{'
2416     BISON_CLOSEBRACE='}'
2417     BISON_VERBOSE='-Dparse.error=verbose'
2418     AC_MSG_RESULT([$frr_ac_bison_version - 3.0 to 3.2])
2419     ;;
2420   *)
2421     BISON_OPENBRACE='{'
2422     BISON_CLOSEBRACE='}'
2423     BISON_VERBOSE='-Dparse.error=verbose -Wno-yacc'
2424     AC_MSG_RESULT([$frr_ac_bison_version - 3.3 or newer])
2425     ;;
2426 esac
2427 AC_SUBST([BISON_OPENBRACE])
2428 AC_SUBST([BISON_CLOSEBRACE])
2429 AC_SUBST([BISON_VERBOSE])
2430
2431 if $frr_ac_bison_missing; then
2432   YACC="$SHELL $missing_dir/missing bison -y"
2433   if test -f "${srcdir}/lib/command_parse.c" -a -f "${srcdir}/lib/command_parse.h"; then
2434     AC_MSG_WARN([using pregenerated bison output files])
2435   else
2436     AC_MSG_ERROR([bison failure and pregenerated files not included (probably a git build)])
2437   fi
2438 fi
2439
2440 dnl -------------------
2441 dnl capabilities checks
2442 dnl -------------------
2443 if test "$enable_capabilities" != "no"; then
2444   AC_MSG_CHECKING([whether prctl PR_SET_KEEPCAPS is available])
2445   AC_COMPILE_IFELSE(
2446   [ AC_LANG_PROGRAM([[
2447         #include <sys/prctl.h>
2448     ]], [[
2449         prctl(PR_SET_KEEPCAPS, 1, 0, 0, 0);
2450     ]])
2451   ],[AC_MSG_RESULT([yes])
2452      AC_DEFINE([HAVE_PR_SET_KEEPCAPS], [1], [prctl])
2453      frr_ac_keepcaps="yes"
2454   ],[AC_MSG_RESULT(no)
2455   ])
2456   if test "$frr_ac_keepcaps" = "yes"; then
2457     AC_CHECK_HEADERS([sys/capability.h])
2458   fi
2459   if test "$ac_cv_header_sys_capability_h" = "yes"; then
2460     AC_CHECK_LIB([cap], [cap_init],
2461       [AC_DEFINE([HAVE_LCAPS], [1], [Capabilities])
2462        LIBCAP="-lcap"
2463        frr_ac_lcaps="yes"]
2464     )
2465   fi
2466   if test "$frr_ac_scaps" = "yes" \
2467        -o "$frr_ac_lcaps" = "yes"; then
2468     AC_DEFINE([HAVE_CAPABILITIES], [1], [capabilities])
2469   fi
2470
2471   case "$host_os" in
2472   linux*)
2473     if test "$enable_clippy_only" != "yes"; then
2474     if test "$frr_ac_lcaps" != "yes"; then
2475       AC_MSG_ERROR([libcap and/or its headers were not found.  Running FRR without libcap support built in causes a huge performance penalty.])
2476     fi
2477     fi
2478     ;;
2479   esac
2480 else
2481   case "$host_os" in
2482   linux*)
2483     AC_MSG_WARN([Running FRR without libcap support built in causes a huge performance penalty.])
2484     ;;
2485   esac
2486 fi
2487 AC_SUBST([LIBCAP])
2488
2489 dnl ---------------------------
2490 dnl check for glibc 'backtrace'
2491 dnl ---------------------------
2492 if test "$enable_backtrace" != "no" ; then
2493   backtrace_ok=no
2494   PKG_CHECK_MODULES([UNWIND], [libunwind], [
2495     AC_DEFINE([HAVE_LIBUNWIND], [1], [libunwind])
2496     backtrace_ok=yes
2497   ], [
2498     true
2499   ])
2500
2501   if test "$backtrace_ok" = "no"; then
2502     AC_CHECK_HEADER([unwind.h], [
2503       AC_SEARCH_LIBS([unw_getcontext], [unwind], [
2504         AC_DEFINE([HAVE_LIBUNWIND], [1], [libunwind])
2505         backtrace_ok=yes
2506       ])
2507     ])
2508   fi
2509
2510   if test "$backtrace_ok" = "no"; then
2511     AC_CHECK_HEADER([execinfo.h], [
2512       AC_SEARCH_LIBS([backtrace], [execinfo], [
2513         AC_DEFINE([HAVE_GLIBC_BACKTRACE], [1], [Glibc backtrace])
2514         backtrace_ok=yes
2515       ],, [-lm])
2516     ])
2517   fi
2518
2519   if test "$enable_backtrace" = "yes" -a "$backtrace_ok" = "no"; then
2520     dnl user explicitly requested backtrace but we failed to find support
2521     AC_MSG_FAILURE([failed to find backtrace or libunwind support])
2522   fi
2523 fi
2524
2525 dnl -----------------------------------------
2526 dnl check for malloc mallinfo struct and call
2527 dnl this must try and link using LIBS, in
2528 dnl order to check no alternative allocator
2529 dnl has been specified, which might not provide
2530 dnl mallinfo
2531 dnl -----------------------------------------
2532 AC_CHECK_HEADERS([malloc.h malloc_np.h malloc/malloc.h],,, [FRR_INCLUDES])
2533
2534 AC_CACHE_CHECK([whether mallinfo is available], [frr_cv_mallinfo], [
2535   AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2536 #ifdef HAVE_MALLOC_H
2537 #include <malloc.h>
2538 #endif
2539 #ifdef HAVE_MALLOC_NP_H
2540 #include <malloc_np.h>
2541 #endif
2542 #ifdef HAVE_MALLOC_MALLOC_H
2543 #include <malloc/malloc.h>
2544 #endif
2545 ]], [[
2546 struct mallinfo ac_x; ac_x = mallinfo ();
2547 ]])], [
2548     frr_cv_mallinfo=yes
2549   ], [
2550     frr_cv_mallinfo=no
2551   ])
2552 ])
2553 if test "$frr_cv_mallinfo" = "yes"; then
2554   AC_DEFINE([HAVE_MALLINFO], [1], [mallinfo])
2555 fi
2556
2557 AC_CACHE_CHECK([whether mallinfo2 is available], [frr_cv_mallinfo2], [
2558   AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2559 #ifdef HAVE_MALLOC_H
2560 #include <malloc.h>
2561 #endif
2562 #ifdef HAVE_MALLOC_NP_H
2563 #include <malloc_np.h>
2564 #endif
2565 #ifdef HAVE_MALLOC_MALLOC_H
2566 #include <malloc/malloc.h>
2567 #endif
2568 ]], [[
2569 struct mallinfo2 ac_x; ac_x = mallinfo2 ();
2570 ]])], [
2571     frr_cv_mallinfo2=yes
2572   ], [
2573     frr_cv_mallinfo2=no
2574   ])
2575 ])
2576 if test "$frr_cv_mallinfo2" = "yes"; then
2577   AC_DEFINE([HAVE_MALLINFO2], [1], [mallinfo2])
2578 fi
2579
2580 AC_MSG_CHECKING([whether malloc_usable_size is available])
2581 AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2582 #ifdef HAVE_MALLOC_H
2583 #include <malloc.h>
2584 #endif
2585 #ifdef HAVE_MALLOC_MALLOC_H
2586 #include <malloc/malloc.h>
2587 #endif
2588 ]], [[
2589 size_t ac_x; ac_x = malloc_usable_size(NULL);
2590 ]])], [
2591   AC_MSG_RESULT([yes])
2592   AC_DEFINE([HAVE_MALLOC_USABLE_SIZE], [1], [malloc_usable_size])
2593 ], [
2594   AC_MSG_RESULT([no])
2595
2596   AC_MSG_CHECKING([whether malloc_size is available])
2597   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2598 #ifdef HAVE_MALLOC_H
2599 #include <malloc.h>
2600 #endif
2601 #ifdef HAVE_MALLOC_MALLOC_H
2602 #include <malloc/malloc.h>
2603 #endif
2604 ]], [[
2605 size_t ac_x; ac_x = malloc_size(NULL);
2606 ]])], [
2607     AC_MSG_RESULT([yes])
2608     AC_DEFINE([HAVE_MALLOC_SIZE], [1], [malloc_size])
2609   ], [
2610     AC_MSG_RESULT([no])
2611   ])
2612 ])
2613
2614 dnl ----------
2615 dnl configure date
2616 dnl ----------
2617 dev_version=`echo $VERSION | grep dev`
2618 #don't expire deprecated code in non 'dev' branch
2619 if test "$dev_version" = ""; then
2620    CONFDATE=0
2621 else
2622    CONFDATE=`date '+%Y%m%d'`
2623 fi
2624 AC_SUBST([CONFDATE])
2625
2626 dnl ------------------------------
2627 dnl set paths for state directory
2628 dnl ------------------------------
2629 AC_MSG_CHECKING([directory to use for state file])
2630 if test "$prefix" = "NONE"; then
2631   frr_statedir_prefix="";
2632 else
2633   frr_statedir_prefix=${prefix}
2634 fi
2635 if test "$localstatedir" = '${prefix}/var'; then
2636   for FRR_STATE_DIR in ${frr_statedir_prefix}/var/run dnl
2637                         ${frr_statedir_prefix}/var/adm dnl
2638                         ${frr_statedir_prefix}/etc dnl
2639                         /var/run        dnl
2640                         /var/adm        dnl
2641                         /etc            dnl
2642                         /dev/null;
2643   do
2644     test -d $FRR_STATE_DIR && break
2645   done
2646   frr_statedir=$FRR_STATE_DIR
2647 else
2648   frr_statedir=${localstatedir}
2649 fi
2650 if test "$frr_statedir" = "/dev/null"; then
2651     AC_MSG_ERROR([STATE DIRECTORY NOT FOUND! FIX OR SPECIFY --localstatedir!])
2652 fi
2653 AC_MSG_RESULT([${frr_statedir}])
2654 AC_SUBST([frr_statedir])
2655
2656 AC_DEFINE_UNQUOTED([LDPD_SOCKET], ["$frr_statedir%s%s/ldpd.sock"], [ldpd control socket])
2657 AC_DEFINE_UNQUOTED([ZEBRA_SERV_PATH], ["$frr_statedir%s%s/zserv.api"], [zebra api socket])
2658 AC_DEFINE_UNQUOTED([BFDD_CONTROL_SOCKET], ["$frr_statedir%s%s/bfdd.sock"], [bfdd control socket])
2659 AC_DEFINE_UNQUOTED([OSPFD_GR_STATE], ["$frr_statedir%s/ospfd-gr.json"], [ospfd GR state information])
2660 AC_DEFINE_UNQUOTED([OSPF6D_GR_STATE], ["$frr_statedir/ospf6d-gr.json"], [ospf6d GR state information])
2661 AC_DEFINE_UNQUOTED([ISISD_RESTART], ["$frr_statedir%s/isid-restart.json"], [isisd restart information])
2662 AC_DEFINE_UNQUOTED([OSPF6_AUTH_SEQ_NUM_FILE], ["$frr_statedir/ospf6d-at-seq-no.dat"], [ospf6d AT Sequence number information])
2663 AC_DEFINE_UNQUOTED([DAEMON_VTY_DIR], ["$frr_statedir%s%s"], [daemon vty directory])
2664 AC_DEFINE_UNQUOTED([DAEMON_DB_DIR], ["$frr_statedir"], [daemon database directory])
2665
2666 dnl autoconf does this, but it does it too late...
2667 test "$prefix" = "NONE" && prefix=$ac_default_prefix
2668 test "$exec_prefix" = "NONE" && exec_prefix='${prefix}'
2669
2670 dnl get the full path, recursing through variables...
2671 vtysh_bin="$bindir/vtysh"
2672 for I in 1 2 3 4 5 6 7 8 9 10; do
2673         eval vtysh_bin="\"$vtysh_bin\""
2674 done
2675 AC_DEFINE_UNQUOTED([VTYSH_BIN_PATH], ["$vtysh_bin"], [path to vtysh binary])
2676 AC_SUBST([vtysh_bin])
2677
2678 CFG_SYSCONF="$sysconfdir"
2679 CFG_SBIN="$sbindir"
2680 CFG_STATE="$frr_statedir"
2681 CFG_MODULE="$moduledir"
2682 CFG_YANGMODELS="$yangmodelsdir"
2683 CFG_SCRIPT="$scriptdir"
2684 for I in 1 2 3 4 5 6 7 8 9 10; do
2685         eval CFG_SYSCONF="\"$CFG_SYSCONF\""
2686         eval CFG_SBIN="\"$CFG_SBIN\""
2687         eval CFG_STATE="\"$CFG_STATE\""
2688         eval CFG_MODULE="\"$CFG_MODULE\""
2689         eval CFG_YANGMODELS="\"$CFG_YANGMODELS\""
2690         eval CFG_SCRIPT="\"$CFG_SCRIPT\""
2691 done
2692 AC_SUBST([CFG_SYSCONF])
2693 AC_SUBST([CFG_SBIN])
2694 AC_SUBST([CFG_STATE])
2695 AC_SUBST([CFG_MODULE])
2696 AC_SUBST([CFG_SCRIPT])
2697 AC_SUBST([CFG_YANGMODELS])
2698 AC_DEFINE_UNQUOTED([MODULE_PATH], ["$CFG_MODULE"], [path to modules])
2699 AC_DEFINE_UNQUOTED([SCRIPT_PATH], ["$CFG_SCRIPT"], [path to scripts])
2700 AC_DEFINE_UNQUOTED([YANG_MODELS_PATH], ["$CFG_YANGMODELS"], [path to YANG data models])
2701 AC_DEFINE_UNQUOTED([WATCHFRR_SH_PATH], ["${CFG_SBIN%/}/watchfrr.sh"], [path to watchfrr.sh])
2702
2703 dnl various features
2704 AM_CONDITIONAL([SUPPORT_REALMS], [test "$enable_realms" = "yes"])
2705 AM_CONDITIONAL([ENABLE_BGP_VNC], [test "$enable_bgp_vnc" != "no"])
2706 AM_CONDITIONAL([BGP_BMP], [$bgpd_bmp])
2707 dnl northbound
2708 AM_CONDITIONAL([SQLITE3], [$SQLITE3])
2709 AM_CONDITIONAL([CONFD], [test "$enable_confd" != ""])
2710 AM_CONDITIONAL([SYSREPO], [test "$enable_sysrepo" = "yes"])
2711 AM_CONDITIONAL([GRPC], [test "$enable_grpc" = "yes"])
2712 AM_CONDITIONAL([ZEROMQ], [test "$ZEROMQ" = "true"])
2713 dnl plugins
2714 AM_CONDITIONAL([RPKI], [test "$RPKI" = "true"])
2715 AM_CONDITIONAL([SNMP], [test "$SNMP_METHOD" = "agentx"])
2716 AM_CONDITIONAL([IRDP], [$IRDP])
2717 AM_CONDITIONAL([FPM], [test "$enable_fpm" = "yes"])
2718 AM_CONDITIONAL([HAVE_PROTOBUF], [test "$enable_protobuf" = "yes"])
2719 AM_CONDITIONAL([HAVE_PROTOBUF3], [$PROTO3])
2720
2721 dnl PCEP plugin
2722 AS_IF([test "$enable_pathd" != "no"], [
2723        AC_SUBST([PATHD_PCEP_LIBS], ["pceplib/libpcep_pcc.la"])
2724        AC_SUBST([PATHD_PCEP_INCL], ["-I./pceplib "])
2725        ])
2726 AC_CHECK_LIB([cunit], [CU_initialize_registry], [pcep_cunit=yes],[pcep_cunit=no])
2727 AM_CONDITIONAL([PATHD_PCEP_TEST], [test "x${pcep_cunit}" = xyes])
2728 AC_CHECK_PROG(VALGRIND_CHECK, valgrind, yes)
2729 AM_CONDITIONAL([HAVE_VALGRIND_PCEP], [test "$VALGRIND_CHECK" = "yes"])
2730
2731 dnl daemons
2732 AM_CONDITIONAL([VTYSH], [test "$VTYSH" = "vtysh"])
2733 AM_CONDITIONAL([ZEBRA], [test "$enable_zebra" != "no"])
2734 AM_CONDITIONAL([BGPD], [test "$enable_bgpd" != "no"])
2735 AM_CONDITIONAL([RIPD], [test "$enable_ripd" != "no"])
2736 AM_CONDITIONAL([OSPFD], [test "$enable_ospfd" != "no"])
2737 AM_CONDITIONAL([LDPD], [test "$enable_ldpd" != "no"])
2738 AM_CONDITIONAL([BFDD], [test "$BFDD" = "bfdd"])
2739 AM_CONDITIONAL([NHRPD], [test "$NHRPD" = "nhrpd"])
2740 AM_CONDITIONAL([EIGRPD], [test "$enable_eigrpd" != "no"])
2741 AM_CONDITIONAL([WATCHFRR], [test "$WATCHFRR" = "watchfrr"])
2742 AM_CONDITIONAL([OSPFCLIENT], [test "$OSPFCLIENT" = "ospfclient"])
2743 AM_CONDITIONAL([RIPNGD], [test "$enable_ripngd" != "no"])
2744 AM_CONDITIONAL([BABELD], [test "$enable_babeld" != "no"])
2745 AM_CONDITIONAL([OSPF6D], [test "$enable_ospf6d" != "no"])
2746 AM_CONDITIONAL([ISISD], [test "$enable_isisd" != "no"])
2747 AM_CONDITIONAL([PIMD], [test "$enable_pimd" != "no"])
2748 AM_CONDITIONAL([PIM6D], [test "$enable_pim6d" != "no"])
2749 AM_CONDITIONAL([PBRD], [test "$enable_pbrd" != "no"])
2750 AM_CONDITIONAL([SHARPD], [test "$enable_sharpd" = "yes"])
2751 AM_CONDITIONAL([STATICD], [test "$enable_staticd" != "no"])
2752 AM_CONDITIONAL([FABRICD], [test "$enable_fabricd" != "no"])
2753 AM_CONDITIONAL([VRRPD], [test "$enable_vrrpd" != "no"])
2754 AM_CONDITIONAL([PATHD], [test "$enable_pathd" != "no"])
2755 AM_CONDITIONAL([PATHD_PCEP], [test "$enable_pathd" != "no"])
2756 AM_CONDITIONAL([DP_DPDK], [test "$enable_dp_dpdk" = "yes"])
2757
2758 AC_CONFIG_FILES([Makefile],[
2759         test "$enable_dev_build" = "yes" && makefile_devbuild="--dev-build"
2760         ${PYTHON} "${ac_abs_top_srcdir}/python/makefile.py" ${makefile_devbuild} || exit 1
2761 ], [
2762         PYTHON="$PYTHON"
2763         enable_dev_build="$enable_dev_build"
2764 ])
2765
2766 AC_CONFIG_FILES([
2767           config.version
2768           redhat/frr.spec
2769           alpine/APKBUILD
2770           snapcraft/snapcraft.yaml
2771           lib/version.h
2772           tests/lib/cli/test_cli.refout
2773           pkgsrc/bgpd.sh pkgsrc/ospf6d.sh pkgsrc/ospfd.sh
2774           pkgsrc/ripd.sh pkgsrc/ripngd.sh pkgsrc/zebra.sh
2775           pkgsrc/eigrpd.sh])
2776
2777 AC_CONFIG_FILES([tools/frr], [chmod +x tools/frr])
2778 AC_CONFIG_FILES([tools/watchfrr.sh], [chmod +x tools/watchfrr.sh])
2779 AC_CONFIG_FILES([tools/frrinit.sh], [chmod +x tools/frrinit.sh])
2780 AC_CONFIG_FILES([tools/frrcommon.sh])
2781 AC_CONFIG_FILES([tools/frr.service])
2782 AC_CONFIG_FILES([tools/frr@.service])
2783
2784 AS_IF([test "$with_pkg_git_version" = "yes"], [
2785     AC_CONFIG_COMMANDS([lib/gitversion.h], [
2786         dst="${ac_abs_top_builddir}/lib/gitversion.h"
2787         ${PERL} "${ac_abs_top_srcdir}/lib/gitversion.pl" \
2788                 "${ac_abs_top_srcdir}" \
2789                 > "${dst}.tmp"
2790         test -f "$dst" \
2791                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
2792                 && rm "${dst}.tmp" \
2793                 || mv "${dst}.tmp" "${dst}"
2794     ], [
2795         PERL="$PERL"
2796     ])
2797 ])
2798
2799 ## Hack, but working solution to avoid rebuilding of frr.info.
2800 ## It's already in CVS until texinfo 4.7 is more common.
2801 AC_OUTPUT
2802
2803 if test "$enable_rpath" = "yes" ; then
2804         true
2805 else
2806         # See https://old-en.opensuse.org/openSUSE:Packaging_Guidelines#Removing_Rpath
2807         sed -e 's|^hardcode_libdir_flag_spec=.*|hardcode_libdir_flag_spec=""|g' libtool > libtool.sed && cat libtool.sed > libtool
2808         sed -e 's|^runpath_var=LD_RUN_PATH|runpath_var=DIE_RPATH_DIE|g'         libtool > libtool.sed && cat libtool.sed > libtool
2809         test -f libtool.sed && rm libtool.sed
2810 fi
2811
2812 echo "
2813 FRRouting configuration
2814 ------------------------------
2815 FRR version             : ${PACKAGE_VERSION}
2816 host operating system   : ${host_os}
2817 source code location    : ${srcdir}
2818 compiler                : ${CC}
2819 compiler flags          : ${CFLAGS} ${WERROR} ${AC_CFLAGS} ${SAN_FLAGS}
2820 make                    : ${MAKE-make}
2821 linker flags            : ${LDFLAGS} ${SAN_FLAGS} ${LIBS} ${LIBCAP} ${LIBREADLINE} ${LIBM}
2822 state file directory    : ${frr_statedir}
2823 config file directory   : `eval echo \`echo ${sysconfdir}\``
2824 module directory        : ${CFG_MODULE}
2825 script directory        : ${CFG_SCRIPT}
2826 user to run as          : ${enable_user}
2827 group to run as         : ${enable_group}
2828 group for vty sockets   : ${enable_vty_group}
2829 config file mask        : ${enable_configfile_mask}
2830 log file mask           : ${enable_logfile_mask}
2831 zebra protobuf enabled  : ${enable_protobuf:-no}
2832 vici socket path        : ${vici_socket}
2833
2834 The above user and group must have read/write access to the state file
2835 directory and to the config files in the config file directory."
2836
2837 if test -n "$enable_datacenter"; then
2838   AC_MSG_WARN([The --enable-datacenter compile time option is deprecated.  Please modify the init script to pass -F datacenter to the daemons instead.])
2839 fi
2840 if test -n "$enable_time_check"; then
2841   AC_MSG_WARN([The --enable-time-check compile time option is deprecated.  Please use the service cputime-stats configuration option instead.])
2842 fi
2843 if test -n "$enable_cpu_time"; then
2844   AC_MSG_WARN([The --enable-cpu-time compile time option is deprecated.  Please use the service cputime-warning NNN configuration option instead.])
2845 fi
2846
2847 if test "$enable_doc" != "no" -a "$frr_py_mod_sphinx" = "false"; then
2848   AC_MSG_WARN([sphinx is missing but required to build documentation])
2849 fi
2850 if test "$frr_py_mod_pytest" = "false"; then
2851   AC_MSG_WARN([pytest is missing, unit tests cannot be performed])
2852 fi