configure.ac

   1 ##
   2 ## Configure template file for FRRouting.
   3 ## autoconf will generate configure script.
   4 ##
   5 ##  Copyright (c) 1996, 97, 98, 99, 2000 Kunihiro Ishiguro <kunihiro@zebra.org>
   6 ##  Portions Copyright (c) 2003 Paul Jakma <paul@dishone.st>
   7 ##
   8 AC_PREREQ(2.60)
   9
  10 AC_INIT(frr, 6.1-dev, [https://github.com/frrouting/frr/issues])
  11 PACKAGE_URL="https://frrouting.org/"
  12 AC_SUBST(PACKAGE_URL)
  13 PACKAGE_FULLNAME="FRRouting"
  14 AC_SUBST(PACKAGE_FULLNAME)
  15
  16 CONFIG_ARGS="$ac_configure_args"
  17 AC_SUBST(CONFIG_ARGS)
  18
  19 AC_CONFIG_SRCDIR(lib/zebra.h)
  20 AC_CONFIG_MACRO_DIR([m4])
  21
  22 dnl -----------------------------------
  23 dnl Get hostname and other information.
  24 dnl -----------------------------------
  25 AC_CANONICAL_BUILD()
  26 AC_CANONICAL_HOST()
  27
  28 AS_IF([test "$host" != "$build"], [
  29   if test "$srcdir" = "."; then
  30     AC_MSG_ERROR([cross-compilation is only possible with builddir separate from srcdir.  create a separate directory and run as .../path-to-frr/configure.])
  31   fi
  32   test -d hosttools || mkdir hosttools
  33   abssrc="`cd \"${srcdir}\"; pwd`"
  34
  35   AC_MSG_NOTICE([...])
  36   AC_MSG_NOTICE([... cross-compilation: creating hosttools directory and self-configuring for build platform tools])
  37   AC_MSG_NOTICE([... use HOST_CPPFLAGS / HOST_CFLAGS / HOST_LDFLAGS if neccessary])
  38   AC_MSG_NOTICE([...])
  39
  40   ( CPPFLAGS="$HOST_CPPFLAGS"; \
  41     CFLAGS="$HOST_CFLAGS"; \
  42     LDFLAGS="$HOST_LDFLAGS"; \
  43     cd hosttools; "${abssrc}/configure" "--host=$build" "--build=$build" "--enable-clippy-only" "--disable-nhrpd" "--disable-vtysh"; )
  44
  45   AC_MSG_NOTICE([...])
  46   AC_MSG_NOTICE([... cross-compilation: finished self-configuring for build platform tools])
  47   AC_MSG_NOTICE([...])
  48
  49   build_clippy="false"
  50   HOSTTOOLS="hosttools/"
  51 ], [
  52   build_clippy="true"
  53   HOSTTOOLS=""
  54 ])
  55 AC_SUBST(HOSTTOOLS)
  56 AM_CONDITIONAL([BUILD_CLIPPY], [$build_clippy])
  57
  58 # Disable portability warnings -- our automake code (in particular
  59 # common.am) uses some constructs specific to gmake.
  60 AM_INIT_AUTOMAKE([1.12 -Wno-portability])
  61 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
  62 AM_SILENT_RULES([yes])
  63 AC_CONFIG_HEADERS(config.h)
  64
  65 AC_PATH_PROG(PERL, perl)
  66 PKG_PROG_PKG_CONFIG
  67
  68 dnl default is to match previous behavior
  69 exampledir=${sysconfdir}
  70 AC_ARG_ENABLE([exampledir],
  71           AS_HELP_STRING([--enable-exampledir],
  72                          [specify alternate directory for examples]),
  73                          exampledir="$enableval",)
  74 dnl XXX add --exampledir to autoconf standard directory list somehow
  75 AC_SUBST(exampledir)
  76
  77 dnl default is to match previous behavior
  78 pkgsrcrcdir=""
  79 AC_ARG_ENABLE([pkgsrcrcdir],
  80           AS_HELP_STRING([--enable-pkgsrcrcdir],
  81                          [specify directory for rc.d scripts]),
  82                          pkgsrcrcdir="$enableval",)
  83 dnl XXX add --pkgsrcrcdir to autoconf standard directory list somehow
  84 AC_SUBST(pkgsrcrcdir)
  85 AM_CONDITIONAL([PKGSRC], [test "x$pkgsrcrcdir" != "x"])
  86
  87 AC_ARG_WITH([moduledir], [AS_HELP_STRING([--with-moduledir=DIR], [module directory (${libdir}/frr/modules)])], [
  88         moduledir="$withval"
  89 ], [
  90         moduledir="\${libdir}/frr/modules"
  91 ])
  92 AC_SUBST([moduledir], [$moduledir])
  93
  94 AC_ARG_ENABLE(tcmalloc,
  95         AS_HELP_STRING([--enable-tcmalloc], [Turn on tcmalloc]),
  96 [case "${enableval}" in
  97   yes) tcmalloc_enabled=true
  98 LIBS="$LIBS -ltcmalloc_minimal"
  99  ;;
 100   no)  tcmalloc_enabled=false ;;
 101   *) AC_MSG_ERROR(bad value ${enableval} for --enable-tcmalloc) ;;
 102 esac],[tcmalloc_enabled=false])
 103
 104
 105 dnl Thanks autoconf, but we don't want a default -g -O2.  We have our own
 106 dnl flag determination logic.
 107 CFLAGS="${CFLAGS:-}"
 108
 109 dnl --------------------
 110 dnl Check CC and friends
 111 dnl --------------------
 112 dnl note orig_cflags is also used further down
 113 orig_cflags="$CFLAGS"
 114 AC_LANG([C])
 115 AC_PROG_CC
 116 AC_PROG_CPP
 117 AM_PROG_CC_C_O
 118 dnl remove autoconf default "-g -O2"
 119 CFLAGS="$orig_cflags"
 120 AC_PROG_CC_C99
 121 dnl NB: see C11 below
 122
 123 AC_PROG_EGREP
 124 PKG_PROG_PKG_CONFIG
 125
 126 dnl autoconf 2.59 appears not to support AC_PROG_SED
 127 dnl AC_PROG_SED
 128 AC_CHECK_PROG([SED],[sed],[sed],[/bin/false])
 129
 130 dnl try and enable CFLAGS that are useful for FRR
 131 dnl - specifically, options to control warnings
 132
 133 AC_USE_SYSTEM_EXTENSIONS
 134 AC_DEFUN([AC_C_FLAG], [{
 135     m4_pushdef([cachename],[m4_translit([frr_cv_$1],[ =-],[___])])
 136     AC_CACHE_CHECK([[whether $CC supports $1]], cachename, [
 137         AC_LANG_PUSH(C)
 138         ac_c_flag_save="$CFLAGS"
 139         CFLAGS="$CFLAGS $1"
 140         AC_COMPILE_IFELSE(
 141                 [AC_LANG_PROGRAM([[]])],
 142                 [
 143                         cachename=yes
 144                 ], [
 145                         cachename=no
 146                 ])
 147         CFLAGS="$ac_c_flag_save"
 148         AC_LANG_POP(C)
 149     ])
 150     if test "${cachename}" = yes; then
 151         m4_if([$3], [], [CFLAGS="$CFLAGS $1"], [$3])
 152     else
 153         :
 154         $2
 155     fi
 156     m4_popdef([cachename])
 157 }])
 158
 159 AC_DEFUN([AC_LINK_IFELSE_FLAGS], [{
 160         AC_LANG_PUSH(C)
 161         ac_cflags_save="$CFLAGS"
 162         ac_libs_save="$LIBS"
 163         CFLAGS="$CFLAGS $1"
 164         LIBS="$LIBS $2"
 165         AC_LINK_IFELSE(
 166                 [$3],
 167                 [
 168                         AC_MSG_RESULT([yes])
 169                         CFLAGS="$ac_cflags_save"
 170                         LIBS="$ac_libs_save"
 171                         $5
 172                 ], [
 173                         AC_MSG_RESULT([no])
 174                         CFLAGS="$ac_cflags_save"
 175                         LIBS="$ac_libs_save"
 176                         $4
 177                 ])
 178         AC_LANG_POP(C)
 179         }])
 180
 181 dnl ICC won't bail on unknown options without -diag-error 10006
 182 dnl need to do this first so we get useful results for the other options
 183 AC_C_FLAG([-diag-error 10006])
 184
 185 dnl AC_PROG_CC_C99 may change CC to include -std=gnu99 or something
 186 ac_cc="$CC"
 187 CC="${CC% -std=gnu99}"
 188 CC="${CC% -std=c99}"
 189
 190 AC_C_FLAG([-std=gnu11], [CC="$ac_cc"], [CC="$CC -std=gnu11"])
 191
 192 dnl AddressSanitizer support
 193 AC_ARG_ENABLE([address-sanitizer], AS_HELP_STRING([--enable-address-sanitizer], \
 194               [enabled AddressSanitizer support for detecting a wide variety of \
 195                memory allocation and deallocation errors]), \
 196               [AC_DEFINE(HAVE_ADDRESS_SANITIZER, 1, [enable AddressSanitizer])
 197               ASAN_FLAGS="-fsanitize=address"
 198               SAN_CLIPPY_FLAGS="-fno-sanitize=all"
 199               AC_SUBST([ASAN_FLAGS])
 200               AC_SUBST([SAN_CLIPPY_FLAGS])
 201               LIBS="-ldl $LIBS"
 202               AC_TRY_COMPILE([],[const int i=0;],[AC_MSG_NOTICE([Address Sanitizer Enabled])],
 203                                                  [AC_MSG_ERROR([Address Sanitizer not available])])
 204               ])
 205
 206 dnl ThreadSanitizer support
 207 AC_ARG_ENABLE([thread-sanitizer], AS_HELP_STRING([--enable-thread-sanitizer], \
 208               [enabled ThreadSanitizer support for detecting data races]), \
 209               [AC_DEFINE(HAVE_THREAD_SANITIZER, 1, [enable ThreadSanitizer])
 210               TSAN_FLAGS="-fsanitize=thread"
 211               SAN_CLIPPY_FLAGS="-fno-sanitize=all"
 212               AC_SUBST([TSAN_FLAGS])
 213               AC_SUBST([SAN_CLIPPY_FLAGS])
 214               LIBS="-ldl $LIBS"
 215               AC_TRY_COMPILE([],[const int i=0;],[AC_MSG_NOTICE([Thread Sanitizer Enabled])],
 216                                                  [AC_MSG_ERROR([Thread Sanitizer not available])])
 217               ])
 218
 219 dnl MemorySanitizer support
 220 AC_ARG_ENABLE([memory-sanitizer], AS_HELP_STRING([--enable-memory-sanitizer], \
 221               [enabled MemorySanitizer support for detecting uninitialized memory reads]), \
 222               [AC_DEFINE(HAVE_THREAD_SANITIZER, 1, [enable MemorySanitizer])
 223               MSAN_FLAGS="-fsanitize=memory -fPIE -pie"
 224               SAN_CLIPPY_FLAGS="-fno-sanitize=all"
 225               AC_SUBST([MSAN_FLAGS])
 226               AC_SUBST([SAN_CLIPPY_FLAGS])
 227               LIBS="-ldl $LIBS"
 228               AC_TRY_COMPILE([],[const int i=0;],[AC_MSG_NOTICE([Memory Sanitizer Enabled])],
 229                                                  [AC_MSG_ERROR([Memory Sanitizer not available])])
 230               ])
 231
 232 dnl if the user has specified any CFLAGS, override our settings
 233 if test "x${enable_gcov}" = "xyes"; then
 234    if test "z$orig_cflags" = "z"; then
 235       AC_C_FLAG([-coverage])
 236       AC_C_FLAG([-O0])
 237    fi
 238
 239    LDFLAGS="${LDFLAGS} -lgcov"
 240 elif test "x${enable_dev_build}" = "xyes"; then
 241    AC_DEFINE(DEV_BUILD,,Build for development)
 242    if test "z$orig_cflags" = "z"; then
 243       AC_C_FLAG([-g3])
 244       AC_C_FLAG([-O0])
 245    fi
 246 else
 247    if test "z$orig_cflags" = "z"; then
 248       AC_C_FLAG([-g])
 249       AC_C_FLAG([-Os], [
 250         AC_C_FLAG([-O2])
 251       ])
 252    fi
 253 fi
 254 AM_CONDITIONAL([DEV_BUILD], [test "x$enable_dev_build" = "xyes"])
 255
 256 dnl always want these CFLAGS
 257 AC_C_FLAG([-fno-omit-frame-pointer])
 258 AC_C_FLAG([-funwind-tables])
 259 AC_C_FLAG([-Wall])
 260 AC_C_FLAG([-Wextra])
 261 AC_C_FLAG([-Wmissing-prototypes])
 262 AC_C_FLAG([-Wmissing-declarations])
 263 AC_C_FLAG([-Wpointer-arith])
 264 AC_C_FLAG([-Wbad-function-cast])
 265 AC_C_FLAG([-Wwrite-strings])
 266 if test x"${enable_gcc_ultra_verbose}" = x"yes" ; then
 267   AC_C_FLAG([-Wcast-qual])
 268   AC_C_FLAG([-Wstrict-prototypes])
 269   AC_C_FLAG([-Wmissing-noreturn])
 270   AC_C_FLAG([-Wmissing-format-attribute])
 271   AC_C_FLAG([-Wunreachable-code])
 272   AC_C_FLAG([-Wpacked])
 273   AC_C_FLAG([-Wpadded])
 274 else
 275   AC_C_FLAG([-Wno-unused-result])
 276 fi
 277 AC_C_FLAG([-Wno-unused-parameter])
 278 AC_C_FLAG([-Wno-missing-field-initializers])
 279
 280 dnl ICC emits a broken warning for const char *x = a ? "b" : "c";
 281 dnl for some reason the string consts get 'promoted' to char *,
 282 dnl triggering a const to non-const conversion warning.
 283 AC_C_FLAG([-diag-disable 3179])
 284
 285 if test x"${enable_werror}" = x"yes" ; then
 286   WERROR="-Werror"
 287 fi
 288 AC_SUBST(WERROR)
 289
 290 dnl ----------
 291 dnl Essentials
 292 dnl ----------
 293
 294 AX_PTHREAD([
 295   CC="$PTHREAD_CC"
 296   CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 297   LIBS="$PTHREAD_LIBS $LIBS"
 298 ], [
 299   AC_MSG_FAILURE([This FRR version needs pthreads])
 300 ])
 301
 302 AC_SEARCH_LIBS([pthread_condattr_setclock], [],
 303                 [frr_cv_pthread_condattr_setclock=yes],
 304                 [frr_cv_pthread_condattr_setclock=no])
 305 if test "$frr_cv_pthread_condattr_setclock" = yes; then
 306   AC_DEFINE(HAVE_PTHREAD_CONDATTR_SETCLOCK, 1, [Have pthread.h pthread_condattr_setclock])
 307 fi
 308
 309 dnl --------------
 310 dnl Check programs
 311 dnl --------------
 312 AC_PROG_INSTALL
 313 AC_PROG_LN_S
 314 AC_PROG_MAKE_SET
 315 AC_CHECK_TOOL(AR, ar)
 316
 317 dnl -----------------
 318 dnl System extensions
 319 dnl -----------------
 320 AC_GNU_SOURCE
 321
 322 dnl -------
 323 dnl libtool
 324 dnl -------
 325 LT_INIT
 326
 327 dnl ----------------------
 328 dnl Packages configuration
 329 dnl ----------------------
 330 AC_ARG_WITH(pkg-extra-version,
 331         AS_HELP_STRING([--with-pkg-extra-version=VER], [add extra version field, for packagers/distributions]),
 332         [EXTRAVERSION=$withval],)
 333 AC_ARG_WITH(pkg-git-version,
 334         AS_HELP_STRING([--with-pkg-git-version], [add git information to MOTD and build version string]),
 335         [ test "x$withval" != "xno" && with_pkg_git_version="yes" ])
 336 AC_ARG_WITH(vtysh_pager,
 337         AS_HELP_STRING([--with-vtysh-pager=PAGER], [control what pager is compiled in as default]),
 338         VTYSH_PAGER=$withval, VTYSH_PAGER="more")
 339 AC_ARG_ENABLE(vtysh,
 340   AS_HELP_STRING([--disable-vtysh], [do not build integrated vty shell for FRR]))
 341 AC_ARG_ENABLE(doc,
 342   AS_HELP_STRING([--disable-doc], [do not build docs]))
 343 AC_ARG_ENABLE(doc-html,
 344   AS_HELP_STRING([--enable-doc-html], [build HTML docs]))
 345 AC_ARG_ENABLE(zebra,
 346   AS_HELP_STRING([--disable-zebra], [do not build zebra daemon]))
 347 AC_ARG_ENABLE(bgpd,
 348   AS_HELP_STRING([--disable-bgpd], [do not build bgpd]))
 349 AC_ARG_ENABLE(ripd,
 350   AS_HELP_STRING([--disable-ripd], [do not build ripd]))
 351 AC_ARG_ENABLE(ripngd,
 352   AS_HELP_STRING([--disable-ripngd], [do not build ripngd]))
 353 AC_ARG_ENABLE(ospfd,
 354   AS_HELP_STRING([--disable-ospfd], [do not build ospfd]))
 355 AC_ARG_ENABLE(ospf6d,
 356   AS_HELP_STRING([--disable-ospf6d], [do not build ospf6d]))
 357 AC_ARG_ENABLE(ldpd,
 358   AS_HELP_STRING([--disable-ldpd], [do not build ldpd]))
 359 AC_ARG_ENABLE(nhrpd,
 360   AS_HELP_STRING([--disable-nhrpd], [do not build nhrpd]))
 361 AC_ARG_ENABLE(eigrpd,
 362   AS_HELP_STRING([--disable-eigrpd], [do not build eigrpd]))
 363 AC_ARG_ENABLE(babeld,
 364   AS_HELP_STRING([--disable-babeld], [do not build babeld]))
 365 AC_ARG_ENABLE(watchfrr,
 366   AS_HELP_STRING([--disable-watchfrr], [do not build watchfrr]))
 367 AC_ARG_ENABLE(isisd,
 368   AS_HELP_STRING([--disable-isisd], [do not build isisd]))
 369 AC_ARG_ENABLE(pimd,
 370   AS_HELP_STRING([--disable-pimd], [do not build pimd]))
 371 AC_ARG_ENABLE(pbrd,
 372   AS_HELP_STRING([--disable-pbrd], [do not build pbrd]))
 373 AC_ARG_ENABLE(sharpd,
 374   AS_HELP_STRING([--enable-sharpd], [build sharpd]))
 375 AC_ARG_ENABLE(staticd,
 376   AS_HELP_STRING([--disable-staticd], [do not build staticd]))
 377 AC_ARG_ENABLE(fabricd,
 378   AS_HELP_STRING([--disable-fabricd], [do not build fabricd]))
 379 AC_ARG_ENABLE(bgp-announce,
 380   AS_HELP_STRING([--disable-bgp-announce,], [turn off BGP route announcement]))
 381 AC_ARG_ENABLE(bgp-vnc,
 382   AS_HELP_STRING([--disable-bgp-vnc],[turn off BGP VNC support]))
 383 AC_ARG_ENABLE(snmp,
 384   AS_HELP_STRING([--enable-snmp], [enable SNMP support for agentx]))
 385 AC_ARG_ENABLE(zeromq,
 386   AS_HELP_STRING([--enable-zeromq], [enable ZeroMQ handler (libfrrzmq)]))
 387 AC_ARG_WITH(libpam,
 388   AS_HELP_STRING([--with-libpam], [use libpam for PAM support in vtysh]))
 389 AC_ARG_ENABLE(ospfapi,
 390   AS_HELP_STRING([--disable-ospfapi], [do not build OSPFAPI to access the OSPF LSA Database]))
 391 AC_ARG_ENABLE(ospfclient,
 392   AS_HELP_STRING([--disable-ospfclient], [do not build OSPFAPI client for OSPFAPI,
 393                           (this is the default if --disable-ospfapi is set)]))
 394 AC_ARG_ENABLE(multipath,
 395   AS_HELP_STRING([--enable-multipath=ARG], [enable multipath function, ARG must be digit]))
 396 AC_ARG_ENABLE(user,
 397   AS_HELP_STRING([--enable-user=USER], [user to run FRR suite as (default frr)]))
 398 AC_ARG_ENABLE(group,
 399   AS_HELP_STRING([--enable-group=GROUP], [group to run FRR suite as (default frr)]))
 400 AC_ARG_ENABLE(vty_group,
 401   AS_HELP_STRING([--enable-vty-group=ARG], [set vty sockets to have specified group as owner]))
 402 AC_ARG_ENABLE(configfile_mask,
 403   AS_HELP_STRING([--enable-configfile-mask=ARG], [set mask for config files]))
 404 AC_ARG_ENABLE(logfile_mask,
 405   AS_HELP_STRING([--enable-logfile-mask=ARG], [set mask for log files]))
 406 AC_ARG_ENABLE(shell_access,
 407   AS_HELP_STRING([--enable-shell-access], [Allow users to access shell/telnet/ssh]))
 408 AC_ARG_ENABLE(realms,
 409   AS_HELP_STRING([--enable-realms], [enable REALMS support under Linux]))
 410 AC_ARG_ENABLE(rtadv,
 411   AS_HELP_STRING([--disable-rtadv], [disable IPV6 router advertisement feature]))
 412 AC_ARG_ENABLE(irdp,
 413   AS_HELP_STRING([--disable-irdp], [enable IRDP server support in zebra (default if supported)]))
 414 AC_ARG_ENABLE(capabilities,
 415   AS_HELP_STRING([--disable-capabilities], [disable using POSIX capabilities]))
 416 AC_ARG_ENABLE(rusage,
 417   AS_HELP_STRING([--disable-rusage], [disable using getrusage]))
 418 AC_ARG_ENABLE(gcc_ultra_verbose,
 419   AS_HELP_STRING([--enable-gcc-ultra-verbose], [enable ultra verbose GCC warnings]))
 420 AC_ARG_ENABLE(backtrace,
 421   AS_HELP_STRING([--disable-backtrace,], [disable crash backtraces (default autodetect)]))
 422 AC_ARG_ENABLE(time-check,
 423   AS_HELP_STRING([--disable-time-check], [disable slow thread warning messages]))
 424 AC_ARG_ENABLE(pcreposix,
 425   AS_HELP_STRING([--enable-pcreposix], [enable using PCRE Posix libs for regex functions]))
 426 AC_ARG_ENABLE(fpm,
 427   AS_HELP_STRING([--enable-fpm], [enable Forwarding Plane Manager support]))
 428 AC_ARG_ENABLE(systemd,
 429   AS_HELP_STRING([--enable-systemd], [enable Systemd support]))
 430 AC_ARG_ENABLE(werror,
 431   AS_HELP_STRING([--enable-werror], [enable -Werror (recommended for developers only)]))
 432 AC_ARG_ENABLE(cumulus,
 433   AS_HELP_STRING([--enable-cumulus], [enable Cumulus Switch Special Extensions]))
 434 AC_ARG_ENABLE(datacenter,
 435   AS_HELP_STRING([--enable-datacenter], [enable Compilation for Data Center Extensions]))
 436 AC_ARG_ENABLE(fuzzing,
 437   AS_HELP_STRING([--enable-fuzzing], [enable ability to fuzz various parts of FRR]))
 438 AC_ARG_ENABLE(netlink_fuzzing,
 439   AS_HELP_STRING([--enable-netlink-fuzzing], [enable ability to fuzz netlink listening socket in zebra]))
 440 AC_ARG_ENABLE(rr-semantics,
 441   AS_HELP_STRING([--disable-rr-semantics], [disable the v6 Route Replace semantics]))
 442 AC_ARG_ENABLE([protobuf],
 443   AS_HELP_STRING([--enable-protobuf], [Enable experimental protobuf support]))
 444 AC_ARG_ENABLE([oldvpn_commands],
 445   AS_HELP_STRING([--enable-oldvpn-commands], [Keep old vpn commands]))
 446 AC_ARG_ENABLE(rpki,
 447   AS_HELP_STRING([--enable-rpki], [enable RPKI prefix validation support]))
 448 AC_ARG_ENABLE([clippy-only],
 449   AS_HELP_STRING([--enable-clippy-only], [Only build clippy]))
 450 AC_ARG_ENABLE([numeric_version],
 451   AS_HELP_STRING([--enable-numeric-version], [Only numeric digits allowed in version (for Alpine)]))
 452 AC_ARG_ENABLE([gcov],
 453   AS_HELP_STRING([--enable-gcov], [Add code coverage information]))
 454 AC_ARG_ENABLE(bfdd,
 455   AS_HELP_STRING([--disable-bfdd], [do not build bfdd]))
 456
 457 AS_IF([test "${enable_clippy_only}" != "yes"], [
 458 AC_CHECK_HEADERS(json-c/json.h)
 459 AC_CHECK_LIB(json-c, json_object_get, LIBS="$LIBS -ljson-c", [], [-lm])
 460 if test $ac_cv_lib_json_c_json_object_get = no; then
 461   AC_CHECK_LIB(json, json_object_get, LIBS="$LIBS -ljson")
 462   if test $ac_cv_lib_json_json_object_get = no; then
 463       AC_MSG_ERROR([lib json is needed to compile])
 464   fi
 465 fi
 466 ])
 467
 468 AC_ARG_ENABLE([dev_build],
 469     AS_HELP_STRING([--enable-dev-build], [build for development]))
 470
 471 if test x"${enable_time_check}" != x"no" ; then
 472   if test x"${enable_time_check}" = x"yes" -o x"${enable_time_check}" = x ; then
 473     AC_DEFINE(CONSUMED_TIME_CHECK,5000000,Consumed Time Check)
 474   else
 475     AC_DEFINE_UNQUOTED(CONSUMED_TIME_CHECK,$enable_time_check,Consumed Time Check)
 476   fi
 477 fi
 478
 479 case "${enable_systemd}" in
 480   "no") ;;
 481   "yes")
 482   AC_CHECK_LIB(systemd, sd_notify, LIBS="$LIBS -lsystemd")
 483   if test $ac_cv_lib_systemd_sd_notify = no; then
 484     AC_MSG_ERROR([enable systemd has been specified but systemd development env not found on your system])
 485   else
 486     AC_DEFINE(HAVE_SYSTEMD,,Compile systemd support in)
 487   fi
 488   ;;
 489   "*") ;;
 490 esac
 491
 492 if test "${enable_rr_semantics}" != "no" ; then
 493   AC_DEFINE(HAVE_V6_RR_SEMANTICS,, Compile in v6 Route Replacement Semantics)
 494 fi
 495
 496 if test "${enable_datacenter}" = "yes" ; then
 497   AC_DEFINE(HAVE_DATACENTER,,Compile extensions for a DataCenter)
 498   DFLT_NAME="datacenter"
 499 else
 500   DFLT_NAME="traditional"
 501 fi
 502
 503 if test "${enable_fuzzing}" = "yes" ; then
 504   AC_DEFINE(HANDLE_ZAPI_FUZZING,,Compile extensions to use with a fuzzer)
 505 fi
 506
 507 if test "${enable_netlink_fuzzing}" = "yes" ; then
 508   AC_DEFINE(HANDLE_NETLINK_FUZZING,,Compile extensions to use with a fuzzer for netlink)
 509 fi
 510
 511 if test "${enable_cumulus}" = "yes" ; then
 512   AC_DEFINE(HAVE_CUMULUS,,Compile Special Cumulus Code in)
 513 fi
 514
 515 AC_SUBST(DFLT_NAME)
 516 AC_DEFINE_UNQUOTED(DFLT_NAME,["$DFLT_NAME"], Name of the configuration default set)
 517
 518 if test "${enable_shell_access}" = "yes"; then
 519    AC_DEFINE(HAVE_SHELL_ACCESS,,Allow user to use ssh/telnet/bash)
 520 fi
 521
 522 AM_CONDITIONAL([FPM], [test "x$enable_fpm" = "xyes"])
 523
 524 #
 525 # Python for clippy
 526 #
 527
 528 AC_DEFUN([FRR_PYTHON_CHECK_WORKING], [
 529   AC_MSG_CHECKING([whether we found a working Python version])
 530   AC_LINK_IFELSE_FLAGS([$PYTHON_CFLAGS], [$PYTHON_LIBS], [AC_LANG_PROGRAM([
 531 #include <Python.h>
 532 #if PY_VERSION_HEX < 0x02070000
 533 #error python too old
 534 #endif
 535 int main(void);
 536 ],
 537 [
 538 {
 539   Py_Initialize();
 540   return 0;
 541 }
 542 ])], [
 543     # some python installs are missing the zlib dependency...
 544     PYTHON_LIBS="${PYTHON_LIBS} -lz"
 545     AC_LINK_IFELSE_FLAGS([$PYTHON_CFLAGS], [$PYTHON_LIBS], [AC_LANG_PROGRAM([
 546 #include <Python.h>
 547 #if PY_VERSION_HEX < 0x02070000
 548 #error python too old
 549 #endif
 550 int main(void);
 551 ],
 552 [
 553 {
 554   Py_Initialize();
 555   return 0;
 556 }
 557 ])], [
 558       m4_if([$1], [], [
 559         PYTHONCONFIG=""
 560         unset PYTHON_LIBS
 561         unset PYTHON_CFLAGS
 562       ], [$1])
 563     ])
 564   ])
 565 ])
 566
 567 AS_IF([test "$host" = "$build"], [
 568   PYTHONCONFIG=""
 569
 570   # ordering:
 571   # 1.  try python3, but respect the user's preference on which minor ver
 572   # 2.  try python, which might be py3 or py2 again on the user's preference
 573   # 3.  try python2 (can really only be 2.7 but eh)
 574   # 4.  try 3.6 > 3.5 > 3.4 > 3.3 > 3.2 > 2.7 through pkg-config (no user pref)
 575   #
 576   # (AX_PYTHON_DEVEL has no clue about py3 vs py2)
 577   # (AX_PYTHON does not do what we need)
 578
 579   AC_CHECK_TOOLS([PYTHONCONFIG], [ \
 580         python3-config \
 581         python-config \
 582         python2-config \
 583         python3.6-config \
 584         python3.5-config \
 585         python3.4-config \
 586         python3.3-config \
 587         python3.2-config \
 588         python2.7-config ])
 589   if test -n "$PYTHONCONFIG"; then
 590     PYTHON_CFLAGS="`\"${PYTHONCONFIG}\" --includes`"
 591     PYTHON_LIBS="`\"${PYTHONCONFIG}\" --ldflags`"
 592
 593     FRR_PYTHON_CHECK_WORKING([])
 594   fi
 595
 596   if test -z "$PYTHONCONFIG"; then
 597     PKG_CHECK_MODULES([PYTHON], python-3.6, [], [
 598       PKG_CHECK_MODULES([PYTHON], python-3.5, [], [
 599         PKG_CHECK_MODULES([PYTHON], python-3.4, [], [
 600           PKG_CHECK_MODULES([PYTHON], python-3.3, [], [
 601             PKG_CHECK_MODULES([PYTHON], python-3.2, [], [
 602               PKG_CHECK_MODULES([PYTHON], python-2.7, [], [
 603                 AC_MSG_FAILURE([could not find python-config or pkg-config python, please install Python development files from libpython-dev or similar])
 604                 ])])])])])])
 605
 606
 607     FRR_PYTHON_CHECK_WORKING([
 608       AC_MSG_FAILURE([could not find python-config or pkg-config python, please install Python development files from libpython-dev or similar])
 609     ])
 610   fi
 611 ])
 612 AC_SUBST(PYTHON_CFLAGS)
 613 AC_SUBST(PYTHON_LIBS)
 614
 615 #
 616 # Logic for protobuf support.
 617 #
 618 if test "$enable_protobuf" = "yes"; then
 619    have_protobuf=yes
 620
 621    # Check for protoc-c
 622    AC_CHECK_PROG([PROTOC_C], [protoc-c], [protoc-c], [/bin/false])
 623    if test "x$PROTOC_C" = "x/bin/false"; then
 624       have_protobuf=no
 625    else
 626       found_protobuf_c=no
 627       PKG_CHECK_MODULES([PROTOBUF_C], libprotobuf-c >= 0.14,
 628                      [found_protobuf_c=yes],
 629                      [AC_MSG_RESULT([pkg-config did not find libprotobuf-c])])
 630
 631       if test "x$found_protobuf_c" = "xyes"; then
 632          LDFLAGS="$LDFLAGS $PROTOBUF_C_LIBS"
 633          CFLAGS="$CFLAGS $PROTOBUF_C_CFLAGS"
 634       else
 635         AC_CHECK_HEADER([google/protobuf-c/protobuf-c.h], [],
 636                         [have_protobuf=no; AC_MSG_RESULT([Couldn't find google/protobuf-c.h])])
 637       fi
 638    fi
 639 fi
 640
 641 #
 642 # Logic for old vpn commans support.
 643 #
 644 if test "$enable_oldvpn_commands" = "yes"; then
 645    AC_DEFINE(KEEP_OLD_VPN_COMMANDS,, [Define for compiling with old vpn commands])
 646 fi
 647
 648 # Fail if the user explicity enabled protobuf support and we couldn't
 649 # find the compiler or libraries.
 650 if test "x$have_protobuf" = "xno" && test "x$enable_protobuf" = "xyes"; then
 651    AC_MSG_ERROR([Protobuf enabled explicitly but can't find libraries/tools])
 652 fi
 653
 654 if test "x$have_protobuf" = "xyes"; then
 655    AC_DEFINE(HAVE_PROTOBUF,, protobuf)
 656 fi
 657
 658 AM_CONDITIONAL([HAVE_PROTOBUF], [test "x$have_protobuf" = "xyes"])
 659
 660 #
 661 # End of logic for protobuf support.
 662 #
 663
 664 AC_MSG_CHECKING(if zebra should be configurable to send Route Advertisements)
 665 if test "${enable_rtadv}" != "no"; then
 666   AC_MSG_RESULT(yes)
 667   AC_DEFINE(HAVE_RTADV,,Enable IPv6 Routing Advertisement support)
 668 else
 669   AC_MSG_RESULT(no)
 670 fi
 671
 672 if test x"${enable_user}" = x"no"; then
 673   enable_user=""
 674 else
 675   if test x"${enable_user}" = x"yes" || test x"${enable_user}" = x""; then
 676     enable_user="frr"
 677   fi
 678   AC_DEFINE_UNQUOTED(FRR_USER, "${enable_user}", frr User)
 679 fi
 680
 681 if test x"${enable_group}" = x"no"; then
 682   enable_group=""
 683 else
 684   if test x"${enable_group}" = x"yes" || test x"${enable_group}" = x""; then
 685     enable_group="frr"
 686   fi
 687   AC_DEFINE_UNQUOTED(FRR_GROUP, "${enable_group}", frr Group)
 688 fi
 689
 690 if test x"${enable_vty_group}" = x"yes" ; then
 691   AC_MSG_ERROR([--enable-vty-group requires a group as argument, not yes])
 692 elif test x"${enable_vty_group}" != x""; then
 693   if test x"${enable_vty_group}" != x"no"; then
 694     AC_DEFINE_UNQUOTED(VTY_GROUP, "${enable_vty_group}", VTY Sockets Group)
 695   fi
 696 fi
 697 AC_SUBST([enable_user])
 698 AC_SUBST([enable_group])
 699 AC_SUBST([enable_vty_group])
 700
 701 enable_configfile_mask=${enable_configfile_mask:-0600}
 702 AC_DEFINE_UNQUOTED(CONFIGFILE_MASK, ${enable_configfile_mask}, Mask for config files)
 703
 704 enable_logfile_mask=${enable_logfile_mask:-0600}
 705 AC_DEFINE_UNQUOTED(LOGFILE_MASK, ${enable_logfile_mask}, Mask for log files)
 706
 707 MPATH_NUM=1
 708
 709 case "${enable_multipath}" in
 710   0)
 711     MPATH_NUM=64
 712     ;;
 713   [[1-9]|[1-9][0-9]|[1-9][0-9][0-9]])
 714     MPATH_NUM="${enable_multipath}"
 715     ;;
 716   "")
 717     ;;
 718   *)
 719     AC_MSG_FAILURE([Please specify digit to enable multipath ARG])
 720     ;;
 721 esac
 722
 723 AC_DEFINE_UNQUOTED(MULTIPATH_NUM, $MPATH_NUM, Maximum number of paths for a route)
 724
 725 AC_DEFINE_UNQUOTED(VTYSH_PAGER, "$VTYSH_PAGER", [What pager to use])
 726
 727 dnl --------------------
 728 dnl Enable code coverage
 729 dnl --------------------
 730 AM_CONDITIONAL([HAVE_GCOV],[test '!' "$enable_gcov" = no])
 731
 732 dnl ------------------------------------
 733 dnl Alpine only accepts numeric versions
 734 dnl ------------------------------------
 735 if test "x${enable_numeric_version}" != "x" ; then
 736   VERSION="`echo ${VERSION} | tr -c -d '[[.0-9]]'`"
 737   PACKAGE_VERSION="`echo ${PACKAGE_VERSION} | tr -c -d '[[.0-9]]'`"
 738 fi
 739
 740 dnl -----------------------------------
 741 dnl Add extra version string to package
 742 dnl name, string and version fields.
 743 dnl -----------------------------------
 744 if test "x${EXTRAVERSION}" != "x" ; then
 745   VERSION="${VERSION}${EXTRAVERSION}"
 746   PACKAGE_VERSION="${PACKAGE_VERSION}${EXTRAVERSION}"
 747   AC_SUBST(PACKAGE_EXTRAVERSION, ["${EXTRAVERSION}"])
 748   PACKAGE_STRING="${PACKAGE_STRING}${EXTRAVERSION}"
 749 fi
 750
 751 if test "x$with_pkg_git_version" = "xyes"; then
 752         if test -d "${srcdir}/.git"; then
 753                 AC_DEFINE(GIT_VERSION, [1], [include git version info])
 754         else    with_pkg_git_version="no"
 755                 AC_MSG_WARN([--with-pkg-git-version given, but this is not a git checkout])
 756         fi
 757 fi
 758 AM_CONDITIONAL([GIT_VERSION], [test "x$with_pkg_git_version" = "xyes"])
 759
 760 dnl ------------------------------------
 761 dnl Check C keywords and standard  types
 762 dnl ------------------------------------
 763 AC_C_CONST
 764 AC_C_INLINE
 765 AC_C_VOLATILE
 766 AC_HEADER_STDC
 767 dnl AC_TYPE_PID_T
 768 AC_TYPE_UID_T
 769 AC_TYPE_MODE_T
 770 AC_TYPE_SIZE_T
 771 AC_STRUCT_TM
 772
 773 dnl -------------------------
 774 dnl Check other header files.
 775 dnl -------------------------
 776 AC_CHECK_HEADERS([stropts.h sys/ksym.h \
 777         linux/version.h asm/types.h \
 778         sys/cdefs.h])
 779
 780 ac_stdatomic_ok=false
 781 AC_DEFINE(FRR_AUTOCONF_ATOMIC, 1, [did autoconf checks for atomic funcs])
 782 AC_CHECK_HEADER([stdatomic.h],[
 783
 784   AC_MSG_CHECKING([whether _Atomic qualifier works])
 785   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 786 #include <stdatomic.h>
 787 int main(int argc, char **argv) {
 788   _Atomic int i = 0;
 789   return i;
 790 }
 791 ]])], [
 792     AC_DEFINE(HAVE_STDATOMIC_H, 1, [found stdatomic.h])
 793     AC_MSG_RESULT([yes])
 794     ac_stdatomic_ok=true
 795   ], [
 796     AC_MSG_RESULT([no])
 797   ])
 798 ])
 799
 800 AS_IF([$ac_stdatomic_ok], [true], [
 801   AC_MSG_CHECKING([for __atomic_* builtins])
 802   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 803 int main(int argc, char **argv) {
 804   volatile int i = 1;
 805   __atomic_store_n (&i, 0, __ATOMIC_RELEASE);
 806   return __atomic_load_n (&i, __ATOMIC_ACQUIRE);
 807 }
 808 ]])], [
 809     AC_DEFINE(HAVE___ATOMIC, 1, [found __atomic builtins])
 810     AC_MSG_RESULT([yes])
 811   ], [
 812     AC_MSG_RESULT([no])
 813
 814     dnl FreeBSD 9 has a broken stdatomic.h where _Atomic doesn't work
 815     AC_MSG_CHECKING([for __sync_* builtins])
 816     AC_LINK_IFELSE([AC_LANG_SOURCE([[
 817 int main(int argc, char **argv) {
 818   volatile int i = 1;
 819   __sync_fetch_and_sub (&i, 1);
 820   return __sync_val_compare_and_swap (&i, 0, 1);
 821 }
 822 ]])], [
 823       AC_DEFINE(HAVE___SYNC, 1, [found __sync builtins])
 824       AC_MSG_RESULT([yes])
 825
 826       AC_MSG_CHECKING([for __sync_swap builtin])
 827       AC_LINK_IFELSE([AC_LANG_SOURCE([[
 828 int main(int argc, char **argv) {
 829   volatile int i = 1;
 830   return __sync_swap (&i, 2);
 831 }
 832 ]])], [
 833         AC_DEFINE(HAVE___SYNC_SWAP, 1, [found __sync_swap builtin])
 834         AC_MSG_RESULT([yes])
 835       ], [
 836         AC_MSG_RESULT([no])
 837       ])
 838
 839     ], [
 840       AC_MSG_RESULT([no])
 841       AC_MSG_FAILURE([stdatomic.h unavailable and $CC has neither __atomic nor __sync builtins])
 842     ])
 843   ])
 844 ])
 845
 846 dnl Utility macro to avoid retyping includes all the time
 847 m4_define([FRR_INCLUDES],
 848 [#ifdef SUNOS_5
 849 #define _XPG4_2
 850 #define __EXTENSIONS__
 851 #endif
 852 #include <stdio.h>
 853 #include <stdlib.h>
 854 #include <stddef.h>
 855 #include <sys/types.h>
 856 /* sys/conf.h depends on param.h on FBSD at least */
 857 #include <sys/param.h>
 858 /* Required for MAXSIG */
 859 #include <signal.h>
 860 #include <sys/socket.h>
 861 #ifdef __APPLE__
 862 # define __APPLE_USE_RFC_3542
 863 #endif
 864 #include <netinet/in.h>
 865 #include <sys/time.h>
 866 #include <time.h>
 867 #include <net/if.h>
 868 ])dnl
 869
 870 dnl Same applies for HAVE_NET_IF_VAR_H, which HAVE_NETINET6_ND6_H and
 871 dnl HAVE_NETINET_IN_VAR_H depend upon. But if_var.h depends on if.h, hence
 872 dnl an additional round for it.
 873
 874 AC_CHECK_HEADERS([net/if_var.h], [], [], FRR_INCLUDES)
 875
 876 m4_define([FRR_INCLUDES],
 877 FRR_INCLUDES
 878 [#if HAVE_NET_IF_VAR_H
 879 # include <net/if_var.h>
 880 #endif
 881 ])dnl
 882
 883 AC_CHECK_HEADERS([netinet/in_var.h \
 884         net/if_dl.h net/netopt.h \
 885         inet/nd.h netinet/ip_icmp.h \
 886         sys/sysctl.h sys/sockio.h kvm.h sys/conf.h],
 887         [], [], FRR_INCLUDES)
 888
 889 AC_CHECK_HEADERS([ucontext.h], [], [],
 890 [#ifndef __USE_GNU
 891 #define __USE_GNU
 892 #endif /* __USE_GNU */
 893 FRR_INCLUDES
 894 ])
 895
 896 m4_define([UCONTEXT_INCLUDES],
 897 [#include <ucontext.h>])dnl
 898
 899 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.uc_regs],
 900   [], [], [UCONTEXT_INCLUDES])
 901 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs],
 902   [AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs.nip],
 903    [], [], [UCONTEXT_INCLUDES])],
 904   [], [UCONTEXT_INCLUDES])
 905 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.gregs],
 906   [], [], [UCONTEXT_INCLUDES])
 907
 908 m4_define([FRR_INCLUDES],
 909 FRR_INCLUDES
 910 [
 911 #include <sys/un.h>
 912 #include <netinet/in_systm.h>
 913 #if HAVE_NETINET_IN_VAR_H
 914 # include <netinet/in_var.h>
 915 #endif
 916 #if HAVE_NET_IF_DL_H
 917 # include <net/if_dl.h>
 918 #endif
 919 #if HAVE_NET_NETOPT_H
 920 # include <net/netopt.h>
 921 #endif
 922 #include <net/route.h>
 923 #if HAVE_INET_ND_H
 924 # include <inet/nd.h>
 925 #endif
 926 #include <arpa/inet.h>
 927 /* Required for IDRP */
 928 #if HAVE_NETINET_IP_ICMP_H
 929 # include <netinet/ip_icmp.h>
 930 #endif
 931 ])dnl
 932
 933 dnl V6 headers are checked below, after we check for v6
 934
 935 AC_MSG_CHECKING([which operating system interface to use])
 936 case "$host_os" in
 937   sunos* | solaris2*)
 938     AC_MSG_RESULT([Solaris])
 939
 940     AC_DEFINE(SUNOS_5, 1, [SunOS 5])
 941     AC_DEFINE(SOLARIS_IPV6, 1, Solaris IPv6)
 942
 943     AC_CHECK_LIB(socket, main)
 944     AC_CHECK_LIB(nsl, main)
 945     AC_CHECK_LIB(umem, main)
 946     AC_CHECK_FUNCS([printstack], [
 947       AC_DEFINE([HAVE_PRINTSTACK],1,[Solaris printstack])
 948       AC_DEFINE([HAVE_STACK_TRACE],1,[Stack symbols decode functionality])
 949     ])
 950     CURSES=-lcurses
 951     SOLARIS="solaris"
 952     ;;
 953   linux*)
 954     AC_MSG_RESULT([Linux])
 955
 956     AC_DEFINE(GNU_LINUX,,GNU Linux)
 957     AC_DEFINE(HAVE_NETLINK,,netlink)
 958     AC_DEFINE(LINUX_IPV6,1,Linux IPv6 stack)
 959
 960     dnl Linux has a compilation problem with mixing
 961     dnl netinet/in.h and linux/in6.h they are not
 962     dnl compatible.  There has been discussion on
 963     dnl how to fix it but no real progress on implementation
 964     dnl when they fix it, remove this
 965     AC_DEFINE(IPV6_MINHOPCOUNT, 73, Linux ipv6 Min Hop Count)
 966     ;;
 967   openbsd*)
 968     AC_MSG_RESULT([OpenBSD])
 969
 970     AC_DEFINE(OPEN_BSD,,OpenBSD)
 971     AC_DEFINE(KAME,1,KAME IPv6)
 972     AC_DEFINE(BSD_V6_SYSCTL,1,BSD v6 sysctl to turn on and off forwarding)
 973
 974     if test "x${enable_pimd}" != "xno"; then
 975       case "$host_os" in
 976       openbsd6.0)
 977         ;;
 978       openbsd[6-9]*)
 979         AC_MSG_FAILURE([pimd cannot be enabled as PIM support has been removed from OpenBSD 6.1])
 980         ;;
 981       esac
 982     fi
 983     ;;
 984   *)
 985     AC_MSG_RESULT([BSD])
 986
 987     AC_DEFINE(HAVE_NET_RT_IFLIST,,NET_RT_IFLIST)
 988     AC_DEFINE(KAME,1,KAME IPv6)
 989     AC_DEFINE(BSD_V6_SYSCTL,1,BSD v6 sysctl to turn on and off forwarding)
 990     ;;
 991 esac
 992 AM_CONDITIONAL(SOLARIS, test "${SOLARIS}" = "solaris")
 993
 994 AC_SYS_LARGEFILE
 995
 996 dnl ------------------------
 997 dnl Integrated REALMS option
 998 dnl ------------------------
 999 if test "${enable_realms}" = "yes"; then
1000     case "$host_os" in
1001       linux*)
1002        AC_DEFINE(SUPPORT_REALMS,, Realms support)
1003        ;;
1004       *)
1005        echo "Sorry, only Linux has REALMS support"
1006        exit 1
1007        ;;
1008     esac
1009 fi
1010 AM_CONDITIONAL([SUPPORT_REALMS], [test "${enable_realms}" = "yes"])
1011
1012 dnl ---------------------
1013 dnl Integrated VTY option
1014 dnl ---------------------
1015 case "${enable_vtysh}" in
1016   "no") VTYSH="";;
1017   *)    VTYSH="vtysh";
1018          AC_DEFINE(VTYSH,,VTY shell)
1019 dnl      Vtysh uses libreadline, which looks for termcap functions at
1020 dnl      configure time.  We follow readlines search order.
1021 dnl      The required procedures are in libtermcap on NetBSD, in
1022 dnl      [TODO] on Linux, and in [TODO] on Solaris.
1023          AC_CHECK_LIB(termcap, tputs, LIBREADLINE="$LIBREADLINE -ltermcap",
1024            [AC_CHECK_LIB(tinfo, tputs, LIBREADLINE="$LIBREADLINE -ltinfo",
1025              [AC_CHECK_LIB(curses, tputs, LIBREADLINE="$LIBREADLINE -lcurses",
1026                [AC_CHECK_LIB(ncurses, tputs,
1027                              LIBREADLINE="$LIBREADLINE -lncurses")]
1028               )]
1029             )]
1030           )
1031          AC_CHECK_LIB(readline, main, LIBREADLINE="-lreadline $LIBREADLINE",,
1032                       "$LIBREADLINE")
1033          if test $ac_cv_lib_readline_main = no; then
1034            AC_MSG_ERROR([vtysh needs libreadline but was not found and usable on your system.])
1035          fi
1036          AC_CHECK_HEADER(readline/history.h)
1037          if test $ac_cv_header_readline_history_h = no;then
1038            AC_MSG_ERROR([readline is too old to have readline/history.h, please update to the latest readline library.])
1039          fi
1040          AC_CHECK_LIB(readline, rl_completion_matches,
1041                       LIBREADLINE="$LIBREADLINE",, "$LIBREADLINE")
1042          if test $ac_cv_lib_readline_rl_completion_matches = no; then
1043            AC_DEFINE(rl_completion_matches,completion_matches,Old readline)
1044          fi
1045          AC_SEARCH_LIBS([append_history], [readline], [frr_cv_append_history=yes], [frr_cv_append_history=no])
1046          if test "$frr_cv_append_history" = yes; then
1047            AC_DEFINE(HAVE_APPEND_HISTORY, 1, [Have history.h append_history])
1048          fi
1049          ;;
1050 esac
1051 AC_SUBST(LIBREADLINE)
1052 AM_CONDITIONAL(VTYSH, test "x$VTYSH" = "xvtysh")
1053
1054 dnl ----------
1055 dnl PAM module
1056 dnl
1057 dnl FRR detects the PAM library it is built against by checking for a
1058 dnl functional pam_misc.h (Linux-PAM) or openpam.h (OpenPAM) header. pam_misc.h
1059 dnl is known to #include pam_appl.h, the standard header of a PAM library, and
1060 dnl openpam.h doesn't do that, although depends on the header too. Hence a
1061 dnl little assistance to AC_CHECK_HEADER is necessary for the proper detection
1062 dnl of OpenPAM.
1063 dnl ----------
1064 if test "$with_libpam" = "yes"; then
1065   AC_CHECK_HEADER([security/pam_misc.h],
1066     [AC_DEFINE(HAVE_PAM_MISC_H,,Have pam_misc.h)
1067      AC_DEFINE(PAM_CONV_FUNC,misc_conv,Have misc_conv)
1068      pam_conv_func="misc_conv"
1069     ],
1070     [], FRR_INCLUDES)
1071   AC_CHECK_HEADER([security/openpam.h],
1072     [AC_DEFINE(HAVE_OPENPAM_H,,Have openpam.h)
1073      AC_DEFINE(PAM_CONV_FUNC,openpam_ttyconv,Have openpam_ttyconv)
1074      pam_conv_func="openpam_ttyconv"
1075     ],
1076     [], FRR_INCLUDES[#include <security/pam_appl.h>])
1077   if test -z "$ac_cv_header_security_pam_misc_h$ac_cv_header_security_openpam_h" ; then
1078     AC_MSG_WARN([*** pam support will not be built ***])
1079     with_libpam="no"
1080   fi
1081 fi
1082
1083 if test "$with_libpam" = "yes"; then
1084 dnl took this test from proftpds configure.in and suited to our needs
1085 dnl -------------------------------------------------------------------------
1086 dnl
1087 dnl This next check looks funky due to a linker problem with some versions
1088 dnl of the PAM library.  Prior to 0.72 release, the Linux PAM shared library
1089 dnl omitted requiring libdl linking information. PAM-0.72 or better ships
1090 dnl with RedHat 6.2 and Debian 2.2 or better.
1091 AC_CHECK_LIB(pam, pam_start,
1092   [AC_CHECK_LIB(pam, $pam_conv_func,
1093     [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1094      LIBPAM="-lpam"],
1095     [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1096      LIBPAM="-lpam -lpam_misc"]
1097     )
1098   ],
1099
1100   [AC_CHECK_LIB(pam, pam_end,
1101     [AC_CHECK_LIB(pam, $pam_conv_func,
1102       [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1103        LIBPAM="-lpam -ldl"],
1104       [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1105        LIBPAM="-lpam -ldl -lpam_misc"]
1106      )
1107   ],AC_MSG_WARN([*** pam support will not be built ***]),
1108   [-ldl])
1109   ]
1110 )
1111 fi
1112 AC_SUBST(LIBPAM)
1113
1114 dnl -------------------------------
1115 dnl Endian-ness check
1116 dnl -------------------------------
1117 AC_WORDS_BIGENDIAN
1118
1119 dnl -------------------------------
1120 dnl check the size in byte of the C
1121 dnl -------------------------------
1122 dnl AC_CHECK_SIZEOF(char)
1123 dnl AC_CHECK_SIZEOF(int)
1124 dnl AC_CHECK_SIZEOF(short)
1125 dnl AC_CHECK_SIZEOF(long)
1126
1127 dnl ----------------------------
1128 dnl check existance of functions
1129 dnl ----------------------------
1130 AC_FUNC_FNMATCH
1131 AC_FUNC_FORK
1132 AC_FUNC_MKTIME
1133 AC_FUNC_STAT
1134
1135 dnl -------------------------------
1136 dnl bgpd needs pow() and hence libm
1137 dnl -------------------------------
1138 TMPLIBS="$LIBS"
1139 AC_CHECK_HEADER([math.h],
1140   [AC_CHECK_LIB([m], [pow],
1141     [LIBM="-lm"
1142      LIBS="$LIBS $LIBM"
1143      AC_CHECK_FUNCS(pow,[],[LIBM=""])
1144     ])
1145 ])
1146 if test x"$LIBM" = x ; then
1147   AC_MSG_WARN([Unable to find working pow function - bgpd may not link])
1148 fi
1149 LIBS="$TMPLIBS"
1150 AC_SUBST(LIBM)
1151
1152 AC_CHECK_FUNCS([ppoll], [
1153   AC_DEFINE([HAVE_PPOLL], 1, [have Linux/BSD ppoll()])
1154 ])
1155 AC_CHECK_FUNCS([pollts], [
1156   AC_DEFINE([HAVE_POLLTS], 1, [have NetBSD pollts()])
1157 ])
1158
1159 dnl ---------------
1160 dnl other functions
1161 dnl ---------------
1162 AC_CHECK_FUNCS([ \
1163         strlcat strlcpy \
1164         getgrouplist])
1165
1166 AC_CHECK_HEADER([asm-generic/unistd.h],
1167                 [AC_CHECK_DECL(__NR_setns,
1168                                AC_DEFINE(HAVE_NETNS,, Have netns),,
1169                                FRR_INCLUDES [#include <asm-generic/unistd.h>
1170                                ])
1171                  AC_CHECK_FUNCS(setns)]
1172                )
1173
1174 dnl --------------------------
1175 dnl Determine IS-IS I/O method
1176 dnl --------------------------
1177 AC_DEFINE(ISIS_METHOD_PFPACKET, 1, [ constant value for isis method pfpacket ])
1178 AC_DEFINE(ISIS_METHOD_DLPI,     2, [ constant value for isis method dlpi ])
1179 AC_DEFINE(ISIS_METHOD_BPF,      3, [ constant value for isis method bpf ])
1180 AC_CHECK_HEADER(net/bpf.h)
1181 AC_CHECK_HEADER(sys/dlpi.h)
1182 AC_MSG_CHECKING(zebra IS-IS I/O method)
1183
1184 case "$host_os" in
1185   linux*)
1186     AC_MSG_RESULT(pfpacket)
1187     ISIS_METHOD_MACRO="ISIS_METHOD_PFPACKET"
1188     ;;
1189   solaris* | sunos*)
1190     AC_MSG_RESULT(DLPI)
1191     ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1192     ;;
1193   *)
1194     if test $ac_cv_header_net_bpf_h = no; then
1195       if test $ac_cv_header_sys_dlpi_h = no; then
1196         AC_MSG_RESULT(none)
1197         if test "${enable_isisd}" = yes -o "${enable_fabricd}" = yes; then
1198           AC_MSG_FAILURE([IS-IS support requested but no packet backend found])
1199         fi
1200         AC_MSG_WARN([*** IS-IS support will not be built ***])
1201         enable_isisd="no"
1202         enable_fabricd="no"
1203       else
1204         AC_MSG_RESULT(DLPI)
1205       fi
1206       ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1207     else
1208       AC_MSG_RESULT(BPF)
1209       ISIS_METHOD_MACRO="ISIS_METHOD_BPF"
1210     fi
1211     ;;
1212 esac
1213 AC_DEFINE_UNQUOTED(ISIS_METHOD, $ISIS_METHOD_MACRO, [ selected method for isis, == one of the constants ])
1214
1215 dnl ---------------------------------------------------------------
1216 dnl figure out how to specify an interface in multicast sockets API
1217 dnl ---------------------------------------------------------------
1218 AC_CHECK_MEMBERS([struct ip_mreqn.imr_ifindex], [], [], FRR_INCLUDES)
1219
1220 AC_CHECK_HEADERS([linux/mroute.h], [], [],[
1221         #include <sys/socket.h>
1222         #include <netinet/in.h>
1223         #define _LINUX_IN_H             /* For Linux <= 2.6.25 */
1224         #include <linux/types.h>
1225 ])
1226
1227 m4_define([FRR_INCLUDES],
1228 FRR_INCLUDES
1229 [#if HAVE_LINUX_MROUTE_H
1230 # include <linux/mroute.h>
1231 #endif
1232 ])dnl
1233
1234 AC_CHECK_HEADERS([netinet/ip_mroute.h], [], [],[
1235         #include <sys/socket.h>
1236         #include <sys/types.h>
1237         #include <netinet/in.h>
1238         #include <net/route.h>
1239 ])
1240
1241 m4_define([FRR_INCLUDES],
1242 FRR_INCLUDES
1243 [#if HAVE_NETINET_IP_MROUTE_H
1244 # include <netinet/ip_mroute.h>
1245 #endif
1246 ])dnl
1247
1248 AC_MSG_CHECKING([for BSD struct ip_mreq hack])
1249 AC_TRY_COMPILE([#include <sys/param.h>],
1250 [#if (defined(__FreeBSD__) && ((__FreeBSD_version >= 500022 && __FreeBSD_version < 700000) || (__FreeBSD_version < 500000 && __FreeBSD_version >= 440000))) || (defined(__NetBSD__) && defined(__NetBSD_Version__) && __NetBSD_Version__ >= 106010000) || defined(__OpenBSD__) || defined(__APPLE__) || defined(__DragonFly__) || defined(__sun)
1251   return (0);
1252 #else
1253   #error No support for BSD struct ip_mreq hack detected
1254 #endif],[AC_MSG_RESULT(yes)
1255 AC_DEFINE(HAVE_BSD_STRUCT_IP_MREQ_HACK,,[Can pass ifindex in struct ip_mreq])],
1256 AC_MSG_RESULT(no))
1257
1258 AC_MSG_CHECKING([for RFC3678 protocol-independed API])
1259 AC_TRY_COMPILE([
1260 #include <sys/types.h>
1261 #include <netinet/in.h>
1262 ], [struct group_req gr; int sock; setsockopt(sock, IPPROTO_IP, MCAST_JOIN_GROUP, (void*)&gr, sizeof(gr));
1263 ], [AC_MSG_RESULT(yes)
1264 AC_DEFINE(HAVE_RFC3678,1,[Have RFC3678 protocol-independed API])],
1265 AC_MSG_RESULT(no))
1266
1267 dnl ---------------------------------------------------------------
1268 dnl figure out how to check link-state
1269 dnl ---------------------------------------------------------------
1270 AC_CHECK_HEADER( [net/if_media.h],
1271   [m4_define([LINK_DETECT_INCLUDES],
1272     FRR_INCLUDES
1273     [#include <net/if_media.h>
1274   ])
1275   AC_CHECK_MEMBERS( [struct ifmediareq.ifm_status],
1276     AC_DEFINE(HAVE_BSD_LINK_DETECT,,[BSD link-detect]),
1277     [], LINK_DETECT_INCLUDES)],
1278   [],
1279   FRR_INCLUDES)
1280
1281 dnl ---------------------------------------------------------------
1282 dnl Additional, newer way to check link-state using ifi_link_state.
1283 dnl Not available in all BSD's when ifmediareq available
1284 dnl ---------------------------------------------------------------
1285 AC_CHECK_MEMBERS([struct if_data.ifi_link_state],
1286   AC_DEFINE(HAVE_BSD_IFI_LINK_STATE,,[BSD ifi_link_state available]),
1287   [], FRR_INCLUDES)
1288
1289 dnl ------------------------
1290 dnl TCP_MD5SIG socket option
1291 dnl ------------------------
1292
1293 AC_CHECK_HEADER([netinet/tcp.h],
1294    [m4_define([MD5_INCLUDES],
1295       FRR_INCLUDES
1296       [#include <netinet/tcp.h>
1297     ])
1298     AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)],
1299    [],
1300    FRR_INCLUDES)
1301 if test $ac_cv_have_decl_TCP_MD5SIG = no; then
1302   AC_CHECK_HEADER([linux/tcp.h],
1303        [m4_define([MD5_INCLUDES],
1304           FRR_INCLUDES
1305           [#include <linux/tcp.h>
1306         ])
1307        AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)])
1308 fi
1309
1310 dnl ----------------------------------------------------------------------------
1311 dnl figure out if domainname is available in the utsname struct (GNU extension).
1312 dnl ----------------------------------------------------------------------------
1313 AC_CHECK_MEMBERS([struct utsname.domainname], [], [], [#include <sys/utsname.h>])
1314
1315 dnl ------------------
1316 dnl IPv6 header checks
1317 dnl ------------------
1318 AC_CHECK_HEADERS([netinet6/in6.h netinet/in6_var.h \
1319         netinet6/in6_var.h netinet6/nd6.h], [], [],
1320         FRR_INCLUDES)
1321
1322 m4_define([FRR_INCLUDES],dnl
1323 FRR_INCLUDES
1324 [#if HAVE_NETINET6_IN6_H
1325 #include <netinet6/in6.h>
1326 #endif
1327 #if HAVE_NETINET_IN6_VAR_H
1328 #include <netinet/in6_var.h>
1329 #endif
1330 #include <netinet/icmp6.h>
1331 #if HAVE_NETINET6_IN6_VAR_H
1332 # include <netinet6/in6_var.h>
1333 #endif
1334 #if HAVE_NETINET6_ND6_H
1335 # include <netinet6/nd6.h>
1336 #endif
1337 ])dnl
1338
1339 dnl disable doc check
1340 AC_CHECK_PROGS([SPHINXBUILD], [sphinx-build sphinx-build3 sphinx-build2], [no])
1341 AM_CONDITIONAL(DOC, test "${enable_doc}" != "no")
1342 AM_CONDITIONAL(DOC_HTML, test "${enable_doc_html}" = "yes")
1343
1344 dnl --------------------
1345 dnl Daemon disable check
1346 dnl --------------------
1347 AM_CONDITIONAL(ZEBRA, test "${enable_zebra}" != "no")
1348
1349 if test "${enable_bgpd}" = "no";then
1350   BGPD=""
1351 else
1352   BGPD="bgpd"
1353 fi
1354 AM_CONDITIONAL(BGPD, test "x$BGPD" = "xbgpd")
1355
1356 AM_CONDITIONAL(RIPD, test "${enable_ripd}" != "no")
1357 AM_CONDITIONAL(OSPFD, test "${enable_ospfd}" != "no")
1358 AM_CONDITIONAL(LDPD, test "${enable_ldpd}" != "no")
1359
1360 AS_IF([test "${enable_ldpd}" != "no"], [
1361   AC_DEFINE(HAVE_LDPD, 1, ldpd)
1362 ])
1363
1364 if test "$enable_bfdd" = "no"; then
1365   AC_DEFINE(HAVE_BFDD, 0, bfdd)
1366   BFDD=""
1367 else
1368   AC_DEFINE(HAVE_BFDD, 1, bfdd)
1369   BFDD="bfdd"
1370
1371   case $host_os in
1372     linux*)
1373       AC_DEFINE(BFD_LINUX, 1, bfdd)
1374       ;;
1375
1376     *)
1377       AC_DEFINE(BFD_BSD, 1, bfdd)
1378       ;;
1379   esac
1380 fi
1381
1382 AM_CONDITIONAL(BFDD, [test "x$BFDD" = "xbfdd"])
1383
1384 if test $ac_cv_lib_json_c_json_object_get = no -a "x$BFDD" = "xbfdd"; then
1385   AC_MSG_ERROR(["you must use json-c library to use bfdd"])
1386 fi
1387
1388 NHRPD=""
1389 case "$host_os" in
1390   linux*)
1391     if test "${enable_nhrpd}" != "no"; then
1392       NHRPD="nhrpd"
1393     fi
1394     ;;
1395   *)
1396     if test "${enable_nhrpd}" = "yes"; then
1397       AC_MSG_ERROR([nhrpd requires kernel APIs that are only present on Linux.])
1398     fi
1399     ;;
1400 esac
1401 AM_CONDITIONAL(NHRPD, test "x$NHRPD" = "xnhrpd")
1402
1403 AM_CONDITIONAL(EIGRPD, test "${enable_eigrpd}" != "no")
1404
1405 if test "${enable_watchfrr}" = "no";then
1406   WATCHFRR=""
1407 else
1408   WATCHFRR="watchfrr"
1409 fi
1410 AM_CONDITIONAL(WATCHFRR, test "x$WATCHFRR" = "xwatchfrr")
1411
1412 OSPFCLIENT=""
1413 if test "${enable_ospfapi}" != "no";then
1414     AC_DEFINE(SUPPORT_OSPF_API,,OSPFAPI)
1415
1416   if test "${enable_ospfclient}" != "no";then
1417       OSPFCLIENT="ospfclient"
1418   fi
1419 fi
1420
1421 AM_CONDITIONAL(OSPFCLIENT, test "x$OSPFCLIENT" = "xospfclient")
1422 AM_CONDITIONAL(RIPNGD, test "${enable_ripngd}" != "no")
1423 AM_CONDITIONAL(BABELD, test "${enable_babeld}" != "no")
1424 AM_CONDITIONAL(OSPF6D, test "${enable_ospf6d}" != "no")
1425 AM_CONDITIONAL(ISISD, test "${enable_isisd}" != "no")
1426 AM_CONDITIONAL(PIMD, test "${enable_pimd}" != "no")
1427 AM_CONDITIONAL(PBRD, test "${enable_pbrd}" != "no")
1428 AM_CONDITIONAL(SHARPD, test "${enable_sharpd}" = "yes")
1429 AM_CONDITIONAL(STATICD, test "${enable_staticd}" != "no")
1430 AM_CONDITIONAL(FABRICD, test "${enable_fabricd}" != "no")
1431
1432 if test "${enable_bgp_announce}" = "no";then
1433   AC_DEFINE(DISABLE_BGP_ANNOUNCE,1,Disable BGP installation to zebra)
1434 else
1435   AC_DEFINE(DISABLE_BGP_ANNOUNCE,0,Disable BGP installation to zebra)
1436 fi
1437
1438 if test "${enable_bgp_vnc}" != "no";then
1439   AC_DEFINE(ENABLE_BGP_VNC,1,Enable BGP VNC support)
1440 fi
1441 AM_CONDITIONAL([ENABLE_BGP_VNC], [test x${enable_bgp_vnc} != xno])
1442
1443 AC_SUBST(SOLARIS)
1444 AC_SUBST(CURSES)
1445 AC_CHECK_LIB(crypt, crypt, [],
1446                     [AC_CHECK_LIB(crypto, DES_crypt)])
1447 AC_CHECK_LIB(resolv, res_init)
1448
1449 dnl ---------------------------
1450 dnl check system has PCRE regexp
1451 dnl ---------------------------
1452 if test "x$enable_pcreposix" = "xyes"; then
1453   AC_CHECK_LIB(pcreposix, regexec, [], [
1454     AC_MSG_ERROR([--enable-pcreposix given but unable to find libpcreposix])
1455   ])
1456 fi
1457 AC_SUBST(HAVE_LIBPCREPOSIX)
1458
1459 dnl ------------------
1460 dnl check C-Ares library
1461 dnl ------------------
1462 if test "${NHRPD}" != ""; then
1463   PKG_CHECK_MODULES([CARES], [libcares], , [
1464     AC_MSG_ERROR([trying to build nhrpd, but libcares not found. install c-ares and its -dev headers.])
1465   ])
1466 fi
1467
1468
1469 dnl ------------------
1470 dnl check Net-SNMP library
1471 dnl ------------------
1472 if test "${enable_snmp}" != "" -a "${enable_snmp}" != "no"; then
1473    AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], [no])
1474    if test x"$NETSNMP_CONFIG" = x"no"; then
1475       AC_MSG_ERROR([--enable-snmp given but unable to find net-snmp-config])
1476    fi
1477    SNMP_LIBS="`${NETSNMP_CONFIG} --agent-libs`"
1478    SNMP_CFLAGS="`${NETSNMP_CONFIG} --base-cflags`"
1479    AC_MSG_CHECKING([whether we can link to Net-SNMP])
1480    AC_LINK_IFELSE_FLAGS([$SNMP_CFLAGS], [$SNMP_LIBS], [AC_LANG_PROGRAM([
1481 int main(void);
1482 ],
1483 [
1484 {
1485   return 0;
1486 }
1487 ])], [
1488      AC_MSG_ERROR([--enable-snmp given but not usable])])
1489    case "${enable_snmp}" in
1490      yes)
1491       SNMP_METHOD=agentx
1492       ;;
1493      agentx)
1494       SNMP_METHOD="${enable_snmp}"
1495       ;;
1496      *)
1497       AC_MSG_ERROR([--enable-snmp given with an unknown method (${enable_snmp}). Use yes or agentx])
1498       ;;
1499    esac
1500    AH_TEMPLATE([SNMP_AGENTX], [Use SNMP AgentX to interface with snmpd])
1501    AC_DEFINE_UNQUOTED(AS_TR_CPP(SNMP_${SNMP_METHOD}),,SNMP method to interface with snmpd)
1502 fi
1503 AM_CONDITIONAL([SNMP], [test "x${SNMP_METHOD}" != "x"])
1504 AC_SUBST(SNMP_LIBS)
1505 AC_SUBST(SNMP_CFLAGS)
1506
1507 dnl ---------------
1508 dnl math
1509 dnl ---------------
1510 AC_SEARCH_LIBS([sqrt], [m])
1511
1512 dnl ---------------
1513 dnl dlopen & dlinfo
1514 dnl ---------------
1515 AC_SEARCH_LIBS(dlopen, [dl dld], [], [
1516   AC_MSG_ERROR([unable to find the dlopen()])
1517 ])
1518
1519 AC_CHECK_HEADERS([link.h])
1520
1521 AC_CACHE_CHECK([for dlinfo(RTLD_DI_ORIGIN)], [frr_cv_rtld_di_origin], [
1522   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1523 #include <stdlib.h>
1524 #ifdef HAVE_LINK_H
1525 #include <link.h>
1526 #endif
1527 #include <dlfcn.h>
1528 ]], [[
1529   char origin[1];
1530   dlinfo (NULL, RTLD_DI_ORIGIN, &origin);
1531 ]])], [
1532     frr_cv_rtld_di_origin=yes
1533   ], [
1534     frr_cv_rtld_di_origin=no
1535   ])
1536 ])
1537 if test "$frr_cv_rtld_di_origin" = yes; then
1538   AC_DEFINE(HAVE_DLINFO_ORIGIN, 1, [Have dlinfo RTLD_DI_ORIGIN])
1539 fi
1540
1541 AC_CACHE_CHECK([for dlinfo(RTLD_DI_LINKMAP)], [frr_cv_rtld_di_linkmap], [
1542   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1543 #include <stdlib.h>
1544 #ifdef HAVE_LINK_H
1545 #include <link.h>
1546 #endif
1547 #include <dlfcn.h>
1548 ]], [[
1549   struct link_map *lm = NULL;
1550   dlinfo (NULL, RTLD_DI_LINKMAP, &lm);
1551 ]])], [
1552     frr_cv_rtld_di_linkmap=yes
1553   ], [
1554     frr_cv_rtld_di_linkmap=no
1555   ])
1556 ])
1557 if test "$frr_cv_rtld_di_linkmap" = yes; then
1558   AC_DEFINE(HAVE_DLINFO_LINKMAP, 1, [Have dlinfo RTLD_DI_LINKMAP])
1559 fi
1560
1561 AM_CONDITIONAL(SNMP, test "x$SNMP_METHOD" = "xagentx")
1562
1563 dnl ---------------------------
1564 dnl sockaddr and netinet checks
1565 dnl ---------------------------
1566 AC_CHECK_TYPES([
1567         struct sockaddr_dl,
1568         struct vifctl, struct mfcctl, struct sioc_sg_req,
1569         vifi_t, struct sioc_vif_req, struct igmpmsg,
1570         struct ifaliasreq, struct if6_aliasreq, struct in6_aliasreq,
1571         struct nd_opt_adv_interval, struct rt_addrinfo,
1572         struct nd_opt_homeagent_info, struct nd_opt_adv_interval],
1573         [], [], FRR_INCLUDES)
1574
1575 AC_CHECK_MEMBERS([struct sockaddr.sa_len,
1576         struct sockaddr_in.sin_len, struct sockaddr_un.sun_len,
1577         struct sockaddr_dl.sdl_len,
1578         struct if6_aliasreq.ifra_lifetime,
1579         struct nd_opt_adv_interval.nd_opt_ai_type],
1580         [], [], FRR_INCLUDES)
1581
1582 dnl ---------------------------
1583 dnl IRDP/pktinfo/icmphdr checks
1584 dnl ---------------------------
1585
1586 AC_CHECK_TYPES([struct in_pktinfo], [
1587   AC_CHECK_TYPES([struct icmphdr], [
1588     IRDP=true
1589   ], [
1590     IRDP=false
1591   ], [FRR_INCLUDES])
1592 ], [
1593   IRDP=false
1594 ], [FRR_INCLUDES])
1595
1596 case "${enable_irdp}" in
1597 yes)
1598   $IRDP || AC_MSG_ERROR(['IRDP requires in_pktinfo at the moment!'])
1599   ;;
1600 no)
1601   IRDP=false
1602   ;;
1603 esac
1604
1605 AM_CONDITIONAL(IRDP, $IRDP)
1606
1607 dnl -----------------------
1608 dnl checking for IP_PKTINFO
1609 dnl -----------------------
1610 AC_MSG_CHECKING(for IP_PKTINFO)
1611 AC_TRY_COMPILE([#include <netdb.h>], [
1612   int opt = IP_PKTINFO;
1613 ], [
1614   AC_MSG_RESULT(yes)
1615   AC_DEFINE(HAVE_IP_PKTINFO, 1, [Have IP_PKTINFO])
1616 ], [
1617   AC_MSG_RESULT(no)
1618 ])
1619
1620 dnl ---------------------------
1621 dnl checking for IP_RECVDSTADDR
1622 dnl ---------------------------
1623 AC_MSG_CHECKING(for IP_RECVDSTADDR)
1624 AC_TRY_COMPILE([#include <netinet/in.h>], [
1625   int opt = IP_RECVDSTADDR;
1626 ], [
1627   AC_MSG_RESULT(yes)
1628   AC_DEFINE(HAVE_IP_RECVDSTADDR, 1, [Have IP_RECVDSTADDR])
1629 ], [
1630   AC_MSG_RESULT(no)
1631 ])
1632
1633 dnl ----------------------
1634 dnl checking for IP_RECVIF
1635 dnl ----------------------
1636 AC_MSG_CHECKING(for IP_RECVIF)
1637 AC_TRY_COMPILE([#include <netinet/in.h>], [
1638   int opt = IP_RECVIF;
1639 ], [
1640   AC_MSG_RESULT(yes)
1641   AC_DEFINE(HAVE_IP_RECVIF, 1, [Have IP_RECVIF])
1642 ], [
1643   AC_MSG_RESULT(no)
1644 ])
1645
1646 dnl ----------------------
1647 dnl checking for SO_BINDANY
1648 dnl ----------------------
1649 AC_MSG_CHECKING(for SO_BINDANY)
1650 AC_TRY_COMPILE([#include <sys/socket.h>], [
1651   int opt = SO_BINDANY;
1652 ], [
1653   AC_MSG_RESULT(yes)
1654   AC_DEFINE(HAVE_SO_BINDANY, 1, [Have SO_BINDANY])
1655 ], [
1656   AC_MSG_RESULT(no)
1657 ])
1658
1659 dnl ----------------------
1660 dnl checking for IP_FREEBIND
1661 dnl ----------------------
1662 AC_MSG_CHECKING(for IP_FREEBIND)
1663 AC_TRY_COMPILE([#include <netinet/in.h>], [
1664   int opt = IP_FREEBIND;
1665 ], [
1666   AC_MSG_RESULT(yes)
1667   AC_DEFINE(HAVE_IP_FREEBIND, 1, [Have IP_FREEBIND])
1668 ], [
1669   AC_MSG_RESULT(no)
1670 ])
1671
1672 dnl --------------------------------------
1673 dnl checking for be32dec existence or not
1674 dnl --------------------------------------
1675 AC_CHECK_DECLS([be32enc, be32dec], [], [],
1676                [#include <sys/endian.h>])
1677
1678 dnl --------------------------------------
1679 dnl checking for clock_time monotonic struct and call
1680 dnl --------------------------------------
1681 AC_CHECK_DECL(CLOCK_MONOTONIC,
1682         [AC_CHECK_LIB(rt, clock_gettime, [LIBS="$LIBS -lrt"])
1683          AC_DEFINE(HAVE_CLOCK_MONOTONIC,, Have monotonic clock)
1684 ], [AC_MSG_RESULT(no)], [FRR_INCLUDES])
1685
1686 dnl --------------------------------------
1687 dnl checking for flex and bison
1688 dnl --------------------------------------
1689
1690 AM_PROG_LEX
1691 AC_MSG_CHECKING(version of flex)
1692 frr_ac_flex_version="$(eval $LEX -V | grep flex | head -n 1)"
1693 frr_ac_flex_version="${frr_ac_flex_version##* }"
1694 AC_MSG_RESULT([$frr_ac_flex_version])
1695 AX_COMPARE_VERSION([$frr_ac_flex_version], [lt], [2.5.20], [
1696   LEX="$SHELL $missing_dir/missing flex"
1697   if test -f "${srcdir}/lib/command_lex.c" -a -f "${srcdir}/lib/command_lex.h"; then
1698     AC_MSG_WARN([using pregenerated flex output files])
1699   else
1700     AC_MSG_ERROR([flex failure and pregenerated files not included (probably a git build)])
1701   fi
1702   AC_SUBST([LEX_OUTPUT_ROOT], [lex.yy])
1703   AC_SUBST([LEXLIB], [''])
1704 ])
1705
1706 AC_PROG_YACC
1707 dnl thanks GNU bison for this b*llshit...
1708 AC_MSG_CHECKING(version of bison)
1709 frr_ac_bison_version="$(eval $YACC -V | grep bison | head -n 1)"
1710 frr_ac_bison_version="${frr_ac_bison_version##* }"
1711 frr_ac_bison_missing="false"
1712 case "x${frr_ac_bison_version}" in
1713   x2.7*)
1714     BISON_OPENBRACE='"'
1715     BISON_CLOSEBRACE='"'
1716     BISON_VERBOSE=''
1717     AC_MSG_RESULT([$frr_ac_bison_version - 2.7 or older])
1718     ;;
1719   x2.*|x1.*)
1720     AC_MSG_RESULT([$frr_ac_bison_version])
1721     AC_MSG_WARN([installed bison is too old.  Please install GNU bison 2.7.x or newer.])
1722     frr_ac_bison_missing="true"
1723     ;;
1724   x)
1725     AC_MSG_RESULT([none])
1726     AC_MSG_WARN([could not determine bison version.  Please install GNU bison 2.7.x or newer.])
1727     frr_ac_bison_missing="true"
1728     ;;
1729   *)
1730     BISON_OPENBRACE='{'
1731     BISON_CLOSEBRACE='}'
1732     BISON_VERBOSE='-Dparse.error=verbose'
1733     AC_MSG_RESULT([$frr_ac_bison_version - 3.0 or newer])
1734     ;;
1735 esac
1736 AC_SUBST(BISON_OPENBRACE)
1737 AC_SUBST(BISON_CLOSEBRACE)
1738 AC_SUBST(BISON_VERBOSE)
1739
1740 if $frr_ac_bison_missing; then
1741   YACC="$SHELL $missing_dir/missing bison -y"
1742   if test -f "${srcdir}/lib/command_parse.c" -a -f "${srcdir}/lib/command_parse.h"; then
1743     AC_MSG_WARN([using pregenerated bison output files])
1744   else
1745     AC_MSG_ERROR([bison failure and pregenerated files not included (probably a git build)])
1746   fi
1747 fi
1748
1749 dnl -------------------
1750 dnl capabilities checks
1751 dnl -------------------
1752 if test "${enable_capabilities}" != "no"; then
1753   AC_MSG_CHECKING(whether prctl PR_SET_KEEPCAPS is available)
1754   AC_TRY_COMPILE([#include <sys/prctl.h>],[prctl(PR_SET_KEEPCAPS, 1, 0, 0, 0);],
1755     [AC_MSG_RESULT(yes)
1756      AC_DEFINE(HAVE_PR_SET_KEEPCAPS,,prctl)
1757      frr_ac_keepcaps="yes"],
1758      AC_MSG_RESULT(no)
1759   )
1760   if test x"${frr_ac_keepcaps}" = x"yes"; then
1761     AC_CHECK_HEADERS(sys/capability.h)
1762   fi
1763   if test x"${ac_cv_header_sys_capability_h}" = x"yes"; then
1764     AC_CHECK_LIB(cap, cap_init,
1765       [AC_DEFINE(HAVE_LCAPS,1,Capabilities)
1766        LIBCAP="-lcap"
1767        frr_ac_lcaps="yes"]
1768     )
1769   else
1770     AC_CHECK_HEADERS(priv.h,
1771      [AC_MSG_CHECKING(Solaris style privileges are available)
1772       AC_TRY_COMPILE([#include <priv.h>],[getpflags(PRIV_AWARE);],
1773           [AC_MSG_RESULT(yes)
1774            AC_DEFINE(HAVE_SOLARIS_CAPABILITIES,1,getpflags)
1775            frr_ac_scaps="yes"],
1776            AC_MSG_RESULT(no)
1777       )
1778      ]
1779    )
1780   fi
1781   if test x"${frr_ac_scaps}" = x"yes" \
1782        -o x"${frr_ac_lcaps}" = x"yes"; then
1783     AC_DEFINE(HAVE_CAPABILITIES,1,capabilities)
1784   fi
1785 fi
1786 AC_SUBST(LIBCAP)
1787
1788 dnl ---------------------------
1789 dnl check for glibc 'backtrace'
1790 dnl ---------------------------
1791 if test x"${enable_backtrace}" != x"no" ; then
1792   backtrace_ok=no
1793   AC_CHECK_HEADER([execinfo.h], [
1794     AC_SEARCH_LIBS([backtrace], [execinfo], [
1795       AC_DEFINE(HAVE_GLIBC_BACKTRACE,,[Glibc backtrace])
1796       AC_DEFINE(HAVE_STACK_TRACE,,[Stack symbol decoding])
1797       backtrace_ok=yes
1798     ],, [-lm])
1799   ])
1800
1801   if test x"${enable_backtrace}" = x"yes" -a x"${backtrace_ok}" = x"no"; then
1802     dnl user explicitly requested backtrace but we failed to find support
1803     AC_MSG_FAILURE([failed to find backtrace support])
1804   fi
1805 fi
1806
1807 dnl -----------------------------------------
1808 dnl check for malloc mallinfo struct and call
1809 dnl this must try and link using LIBS, in
1810 dnl order to check no alternative allocator
1811 dnl has been specified, which might not provide
1812 dnl mallinfo, e.g. such as Umem on Solaris.
1813 dnl -----------------------------------------
1814 AC_CHECK_HEADERS([malloc.h malloc/malloc.h],,, [FRR_INCLUDES])
1815
1816 AC_CACHE_CHECK([whether mallinfo is available], [frr_cv_mallinfo], [
1817   AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
1818 #ifdef HAVE_MALLOC_H
1819 #include <malloc.h>
1820 #endif
1821 #ifdef HAVE_MALLOC_MALLOC_H
1822 #include <malloc/malloc.h>
1823 #endif
1824 ]], [[
1825 struct mallinfo ac_x; ac_x = mallinfo ();
1826 ]])], [
1827     frr_cv_mallinfo=yes
1828   ], [
1829     frr_cv_mallinfo=no
1830   ])
1831 ])
1832 if test "$frr_cv_mallinfo" = yes; then
1833   AC_DEFINE(HAVE_MALLINFO,,mallinfo)
1834 fi
1835
1836 AC_MSG_CHECKING(whether malloc_usable_size is available)
1837 AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
1838 #ifdef HAVE_MALLOC_H
1839 #include <malloc.h>
1840 #endif
1841 #ifdef HAVE_MALLOC_MALLOC_H
1842 #include <malloc/malloc.h>
1843 #endif
1844 ]], [[
1845 size_t ac_x; ac_x = malloc_usable_size(NULL);
1846 ]])], [
1847   AC_MSG_RESULT(yes)
1848   AC_DEFINE(HAVE_MALLOC_USABLE_SIZE,,malloc_usable_size)
1849 ], [
1850   AC_MSG_RESULT(no)
1851
1852   AC_MSG_CHECKING(whether malloc_size is available)
1853   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1854 #ifdef HAVE_MALLOC_H
1855 #include <malloc.h>
1856 #endif
1857 #ifdef HAVE_MALLOC_MALLOC_H
1858 #include <malloc/malloc.h>
1859 #endif
1860 ]], [[
1861 size_t ac_x; ac_x = malloc_size(NULL);
1862 ]])], [
1863     AC_MSG_RESULT(yes)
1864     AC_DEFINE(HAVE_MALLOC_SIZE,,malloc_size)
1865   ], [
1866     AC_MSG_RESULT(no)
1867   ])
1868 ])
1869
1870 dnl ------
1871 dnl ZeroMQ
1872 dnl ------
1873 if test "x$enable_zeromq" != "xno"; then
1874   PKG_CHECK_MODULES(ZEROMQ, [libzmq >= 4.0.0], [
1875     AC_DEFINE(HAVE_ZEROMQ, 1, [Enable ZeroMQ support])
1876     ZEROMQ=true
1877   ], [
1878     if test "x$enable_zeromq" = "xyes"; then
1879       AC_MSG_ERROR([configuration specifies --enable-zeromq but libzmq was not found])
1880     fi
1881   ])
1882 fi
1883 AM_CONDITIONAL([ZEROMQ], test "x$ZEROMQ" = "xtrue")
1884
1885 dnl ----------
1886 dnl configure date
1887 dnl ----------
1888 dev_version=`echo $VERSION | grep dev`
1889 #don't expire deprecated code in non 'dev' branch
1890 if test "${dev_version}" = ""; then
1891    CONFDATE=0
1892 else
1893    CONFDATE=`date '+%Y%m%d'`
1894 fi
1895 AC_SUBST(CONFDATE)
1896
1897 dnl ------------------------------
1898 dnl set paths for state directory
1899 dnl ------------------------------
1900 AC_MSG_CHECKING(directory to use for state file)
1901 if test "${prefix}" = "NONE"; then
1902   frr_statedir_prefix="";
1903 else
1904   frr_statedir_prefix=${prefix}
1905 fi
1906 if test "${localstatedir}" = '${prefix}/var'; then
1907   for FRR_STATE_DIR in ${frr_statedir_prefix}/var/run dnl
1908                         ${frr_statedir_prefix}/var/adm dnl
1909                         ${frr_statedir_prefix}/etc dnl
1910                         /var/run        dnl
1911                         /var/adm        dnl
1912                         /etc            dnl
1913                         /dev/null;
1914   do
1915     test -d $FRR_STATE_DIR && break
1916   done
1917   frr_statedir=$FRR_STATE_DIR
1918 else
1919   frr_statedir=${localstatedir}
1920 fi
1921 if test $frr_statedir = "/dev/null"; then
1922     AC_MSG_ERROR('STATE DIRECTORY NOT FOUND! FIX OR SPECIFY --localstatedir!')
1923 fi
1924 AC_MSG_RESULT(${frr_statedir})
1925 AC_SUBST(frr_statedir)
1926
1927 AC_DEFINE_UNQUOTED(LDPD_SOCKET, "$frr_statedir/ldpd.sock",ldpd control socket)
1928 AC_DEFINE_UNQUOTED(ZEBRA_SERV_PATH, "$frr_statedir/zserv.api",zebra api socket)
1929 AC_DEFINE_UNQUOTED(BFDD_CONTROL_SOCKET, "$frr_statedir/bfdd.sock", bfdd control socket)
1930 AC_DEFINE_UNQUOTED(DAEMON_VTY_DIR, "$frr_statedir",daemon vty directory)
1931
1932 dnl autoconf does this, but it does it too late...
1933 test "x$prefix" = xNONE && prefix=$ac_default_prefix
1934 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
1935
1936 dnl get the full path, recursing through variables...
1937 vtysh_bin="$bindir/vtysh"
1938 for I in 1 2 3 4 5 6 7 8 9 10; do
1939         eval vtysh_bin="\"$vtysh_bin\""
1940 done
1941 AC_DEFINE_UNQUOTED(VTYSH_BIN_PATH, "$vtysh_bin",path to vtysh binary)
1942
1943 CFG_SYSCONF="$sysconfdir"
1944 CFG_SBIN="$sbindir"
1945 CFG_STATE="$frr_statedir"
1946 CFG_MODULE="$moduledir"
1947 for I in 1 2 3 4 5 6 7 8 9 10; do
1948         eval CFG_SYSCONF="\"$CFG_SYSCONF\""
1949         eval CFG_SBIN="\"$CFG_SBIN\""
1950         eval CFG_STATE="\"$CFG_STATE\""
1951         eval CFG_MODULE="\"$CFG_MODULE\""
1952 done
1953 AC_SUBST(CFG_SYSCONF)
1954 AC_SUBST(CFG_SBIN)
1955 AC_SUBST(CFG_STATE)
1956 AC_SUBST(CFG_MODULE)
1957 AC_DEFINE_UNQUOTED(MODULE_PATH, "$CFG_MODULE", path to modules)
1958
1959 dnl ------------------------------------
1960 dnl Enable RPKI and add librtr to libs
1961 dnl ------------------------------------
1962 if test "${enable_rpki}" = "yes"; then
1963   PKG_CHECK_MODULES(RTRLIB,[rtrlib >= 0.5.0],
1964       [RPKI=true],
1965       [RPKI=false
1966       AC_MSG_ERROR([rtrlib was not found on your system or is too old.])]
1967   )
1968 fi
1969 AM_CONDITIONAL([RPKI], test "x$RPKI" = "xtrue")
1970
1971 dnl ------------------------------------------
1972 dnl Check whether rtrlib was build with ssh support
1973 dnl ------------------------------------------
1974 AC_MSG_CHECKING([whether the RTR Library is compiled with SSH])
1975 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "rtrlib/rtrlib.h"]],
1976                         [[struct tr_ssh_config config;]])],
1977         [AC_MSG_RESULT(yes)
1978         AC_DEFINE(FOUND_SSH,,found_ssh)],
1979         AC_MSG_RESULT(no)
1980 )
1981
1982 dnl ---------------------------
1983 dnl Check htonl works correctly
1984 dnl ---------------------------
1985 AC_MSG_CHECKING(for working htonl)
1986 AC_CACHE_VAL(ac_cv_htonl_works,
1987  [AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES],[htonl (0);])],
1988                 [ac_cv_htonl_works=yes], [ac_cv_htonl_works=no])
1989  ]
1990 )
1991 AC_MSG_RESULT($ac_cv_htonl_works)
1992
1993 AC_CONFIG_FILES([Makefile],[sed -e 's/^#AUTODERP# //' -i Makefile])
1994
1995 AC_CONFIG_FILES([
1996           redhat/frr.spec
1997           solaris/Makefile
1998           debianpkg/changelog
1999           alpine/APKBUILD
2000           snapcraft/snapcraft.yaml
2001           lib/version.h
2002           tests/lib/cli/test_cli.refout
2003           pkgsrc/bgpd.sh pkgsrc/ospf6d.sh pkgsrc/ospfd.sh
2004           pkgsrc/ripd.sh pkgsrc/ripngd.sh pkgsrc/zebra.sh
2005           pkgsrc/eigrpd.sh])
2006
2007 AC_CONFIG_FILES([vtysh/extract.pl],[chmod +x vtysh/extract.pl])
2008
2009 AC_CONFIG_COMMANDS([lib/route_types.h], [
2010         dst="${ac_abs_top_builddir}/lib/route_types.h"
2011         ${PERL} "${ac_abs_top_srcdir}/lib/route_types.pl" \
2012                 < "${ac_abs_top_srcdir}/lib/route_types.txt" \
2013                 > "${dst}.tmp"
2014         test -f "${dst}" \
2015                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
2016                 && rm "${dst}.tmp" \
2017                 || mv "${dst}.tmp" "${dst}"
2018 ], [
2019         PERL="$PERL"
2020 ])
2021
2022 AS_IF([test "x$with_pkg_git_version" = "xyes"], [
2023     AC_CONFIG_COMMANDS([lib/gitversion.h], [
2024         dst="${ac_abs_top_builddir}/lib/gitversion.h"
2025         ${PERL} "${ac_abs_top_srcdir}/lib/gitversion.pl" \
2026                 "${ac_abs_top_srcdir}" \
2027                 > "${dst}.tmp"
2028         test -f "${dst}" \
2029                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
2030                 && rm "${dst}.tmp" \
2031                 || mv "${dst}.tmp" "${dst}"
2032     ], [
2033         PERL="$PERL"
2034     ])
2035 ])
2036
2037 ## Hack, but working solution to avoid rebuilding of frr.info.
2038 ## It's already in CVS until texinfo 4.7 is more common.
2039 AC_OUTPUT
2040
2041 echo "
2042 FRRouting configuration
2043 ------------------------------
2044 FRR version             : ${PACKAGE_VERSION}
2045 host operating system   : ${host_os}
2046 source code location    : ${srcdir}
2047 compiler                : ${CC}
2048 compiler flags          : ${CFLAGS}
2049 make                    : ${MAKE-make}
2050 linker flags            : ${LDFLAGS} ${LIBS} ${LIBCAP} ${LIBREADLINE} ${LIBM}
2051 state file directory    : ${frr_statedir}
2052 config file directory   : `eval echo \`echo ${sysconfdir}\``
2053 example directory       : `eval echo \`echo ${exampledir}\``
2054 module directory        : ${CFG_MODULE}
2055 user to run as          : ${enable_user}
2056 group to run as         : ${enable_group}
2057 group for vty sockets   : ${enable_vty_group}
2058 config file mask        : ${enable_configfile_mask}
2059 log file mask           : ${enable_logfile_mask}
2060 zebra protobuf enabled  : ${have_protobuf:-no}
2061
2062 The above user and group must have read/write access to the state file
2063 directory and to the config files in the config file directory."
2064
2065 if test "${enable_doc}" != "no";then
2066   AS_IF([test "x$SPHINXBUILD" = xno],
2067      AC_MSG_WARN(sphinx-build is missing but required to build documentation))
2068 fi