configure.ac

   1 ##
   2 ## Configure template file for FRRouting.
   3 ## autoconf will generate configure script.
   4 ##
   5 ##  Copyright (c) 1996, 97, 98, 99, 2000 Kunihiro Ishiguro <kunihiro@zebra.org>
   6 ##  Portions Copyright (c) 2003 Paul Jakma <paul@dishone.st>
   7 ##
   8 AC_PREREQ(2.60)
   9
  10 AC_INIT(frr, 6.1-dev, [https://github.com/frrouting/frr/issues])
  11 PACKAGE_URL="https://frrouting.org/"
  12 AC_SUBST(PACKAGE_URL)
  13 PACKAGE_FULLNAME="FRRouting"
  14 AC_SUBST(PACKAGE_FULLNAME)
  15
  16 CONFIG_ARGS="$ac_configure_args"
  17 AC_SUBST(CONFIG_ARGS)
  18
  19 AC_CONFIG_SRCDIR(lib/zebra.h)
  20 AC_CONFIG_MACRO_DIR([m4])
  21
  22 dnl -----------------------------------
  23 dnl Get hostname and other information.
  24 dnl -----------------------------------
  25 AC_CANONICAL_BUILD()
  26 AC_CANONICAL_HOST()
  27
  28 AS_IF([test "$host" != "$build"], [
  29   if test "$srcdir" = "."; then
  30     AC_MSG_ERROR([cross-compilation is only possible with builddir separate from srcdir.  create a separate directory and run as .../path-to-frr/configure.])
  31   fi
  32   test -d hosttools || mkdir hosttools
  33   abssrc="`cd \"${srcdir}\"; pwd`"
  34
  35   AC_MSG_NOTICE([...])
  36   AC_MSG_NOTICE([... cross-compilation: creating hosttools directory and self-configuring for build platform tools])
  37   AC_MSG_NOTICE([... use HOST_CPPFLAGS / HOST_CFLAGS / HOST_LDFLAGS if neccessary])
  38   AC_MSG_NOTICE([...])
  39
  40   ( CPPFLAGS="$HOST_CPPFLAGS"; \
  41     CFLAGS="$HOST_CFLAGS"; \
  42     LDFLAGS="$HOST_LDFLAGS"; \
  43     cd hosttools; "${abssrc}/configure" "--host=$build" "--build=$build" "--enable-clippy-only" "--disable-nhrpd" "--disable-vtysh"; )
  44
  45   AC_MSG_NOTICE([...])
  46   AC_MSG_NOTICE([... cross-compilation: finished self-configuring for build platform tools])
  47   AC_MSG_NOTICE([...])
  48
  49   build_clippy="false"
  50   HOSTTOOLS="hosttools/"
  51 ], [
  52   build_clippy="true"
  53   HOSTTOOLS=""
  54 ])
  55 AC_SUBST(HOSTTOOLS)
  56 AM_CONDITIONAL([BUILD_CLIPPY], [$build_clippy])
  57
  58 # Disable portability warnings -- our automake code (in particular
  59 # common.am) uses some constructs specific to gmake.
  60 AM_INIT_AUTOMAKE([1.12 -Wno-portability foreign])
  61 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
  62 AM_SILENT_RULES([yes])
  63 AC_CONFIG_HEADERS(config.h)
  64
  65 AC_PATH_PROG(PERL, perl)
  66 PKG_PROG_PKG_CONFIG
  67
  68 dnl default is to match previous behavior
  69 exampledir=${sysconfdir}
  70 AC_ARG_ENABLE([exampledir],
  71           AS_HELP_STRING([--enable-exampledir],
  72                          [specify alternate directory for examples]),
  73                          exampledir="$enableval",)
  74 dnl XXX add --exampledir to autoconf standard directory list somehow
  75 AC_SUBST(exampledir)
  76
  77 dnl default is to match previous behavior
  78 pkgsrcrcdir=""
  79 AC_ARG_ENABLE([pkgsrcrcdir],
  80           AS_HELP_STRING([--enable-pkgsrcrcdir],
  81                          [specify directory for rc.d scripts]),
  82                          pkgsrcrcdir="$enableval",)
  83 dnl XXX add --pkgsrcrcdir to autoconf standard directory list somehow
  84 AC_SUBST(pkgsrcrcdir)
  85 AM_CONDITIONAL([PKGSRC], [test "x$pkgsrcrcdir" != "x"])
  86
  87 AC_ARG_WITH([moduledir], [AS_HELP_STRING([--with-moduledir=DIR], [module directory (${libdir}/frr/modules)])], [
  88         moduledir="$withval"
  89 ], [
  90         moduledir="\${libdir}/frr/modules"
  91 ])
  92 AC_SUBST([moduledir], [$moduledir])
  93
  94 AC_ARG_ENABLE(tcmalloc,
  95         AS_HELP_STRING([--enable-tcmalloc], [Turn on tcmalloc]),
  96 [case "${enableval}" in
  97   yes) tcmalloc_enabled=true
  98 LIBS="$LIBS -ltcmalloc_minimal"
  99  ;;
 100   no)  tcmalloc_enabled=false ;;
 101   *) AC_MSG_ERROR(bad value ${enableval} for --enable-tcmalloc) ;;
 102 esac],[tcmalloc_enabled=false])
 103
 104
 105 dnl Thanks autoconf, but we don't want a default -g -O2.  We have our own
 106 dnl flag determination logic.
 107 CFLAGS="${CFLAGS:-}"
 108
 109 dnl --------------------
 110 dnl Check CC and friends
 111 dnl --------------------
 112 dnl note orig_cflags is also used further down
 113 orig_cflags="$CFLAGS"
 114 AC_LANG([C])
 115 AC_PROG_CC
 116 AC_PROG_CPP
 117 AM_PROG_CC_C_O
 118 dnl remove autoconf default "-g -O2"
 119 CFLAGS="$orig_cflags"
 120 AC_PROG_CC_C99
 121 dnl NB: see C11 below
 122
 123 AC_PROG_EGREP
 124 PKG_PROG_PKG_CONFIG
 125
 126 dnl autoconf 2.59 appears not to support AC_PROG_SED
 127 dnl AC_PROG_SED
 128 AC_CHECK_PROG([SED],[sed],[sed],[/bin/false])
 129
 130 dnl try and enable CFLAGS that are useful for FRR
 131 dnl - specifically, options to control warnings
 132
 133 AC_USE_SYSTEM_EXTENSIONS
 134 AC_DEFUN([AC_C_FLAG], [{
 135     m4_pushdef([cachename],[m4_translit([frr_cv_$1],[ =-],[___])])
 136     AC_CACHE_CHECK([[whether $CC supports $1]], cachename, [
 137         AC_LANG_PUSH(C)
 138         ac_c_flag_save="$CFLAGS"
 139         CFLAGS="$CFLAGS $1"
 140         AC_COMPILE_IFELSE(
 141                 [AC_LANG_PROGRAM([[]])],
 142                 [
 143                         cachename=yes
 144                 ], [
 145                         cachename=no
 146                 ])
 147         CFLAGS="$ac_c_flag_save"
 148         AC_LANG_POP(C)
 149     ])
 150     if test "${cachename}" = yes; then
 151         m4_if([$3], [], [CFLAGS="$CFLAGS $1"], [$3])
 152     else
 153         :
 154         $2
 155     fi
 156     m4_popdef([cachename])
 157 }])
 158
 159 AC_DEFUN([AC_LINK_IFELSE_FLAGS], [{
 160         AC_LANG_PUSH(C)
 161         ac_cflags_save="$CFLAGS"
 162         ac_libs_save="$LIBS"
 163         CFLAGS="$CFLAGS $1"
 164         LIBS="$LIBS $2"
 165         AC_LINK_IFELSE(
 166                 [$3],
 167                 [
 168                         AC_MSG_RESULT([yes])
 169                         CFLAGS="$ac_cflags_save"
 170                         LIBS="$ac_libs_save"
 171                         $5
 172                 ], [
 173                         AC_MSG_RESULT([no])
 174                         CFLAGS="$ac_cflags_save"
 175                         LIBS="$ac_libs_save"
 176                         $4
 177                 ])
 178         AC_LANG_POP(C)
 179         }])
 180
 181 dnl ICC won't bail on unknown options without -diag-error 10006
 182 dnl need to do this first so we get useful results for the other options
 183 AC_C_FLAG([-diag-error 10006])
 184
 185 dnl AC_PROG_CC_C99 may change CC to include -std=gnu99 or something
 186 ac_cc="$CC"
 187 CC="${CC% -std=gnu99}"
 188 CC="${CC% -std=c99}"
 189
 190 AC_C_FLAG([-std=gnu11], [CC="$ac_cc"], [CC="$CC -std=gnu11"])
 191
 192 dnl if the user has specified any CFLAGS, override our settings
 193 if test "x${enable_gcov}" = "xyes"; then
 194    if test "z$orig_cflags" = "z"; then
 195       AC_C_FLAG([-coverage])
 196       AC_C_FLAG([-O0])
 197    fi
 198
 199    LDFLAGS="${LDFLAGS} -lgcov"
 200 elif test "x${enable_dev_build}" = "xyes"; then
 201    AC_DEFINE(DEV_BUILD,,Build for development)
 202    if test "z$orig_cflags" = "z"; then
 203       AC_C_FLAG([-g3])
 204       AC_C_FLAG([-O0])
 205    fi
 206    if test "x${enable_lua}" = "xyes"; then
 207       AC_CHECK_LIB([lua], [lua_newstate],
 208       [LIBS="$LIBS -llua"])
 209       AC_DEFINE(HAVE_LUA,,Lua enabled for development)
 210    fi
 211 else
 212    if test "x${enable_lua}" = "xyes"; then
 213       AC_MSG_ERROR([Lua is not meant to be built/used outside of development at this time])
 214    fi
 215    if test "z$orig_cflags" = "z"; then
 216       AC_C_FLAG([-g])
 217       AC_C_FLAG([-Os], [
 218         AC_C_FLAG([-O2])
 219       ])
 220    fi
 221 fi
 222 AM_CONDITIONAL([DEV_BUILD], [test "x$enable_dev_build" = "xyes"])
 223
 224 dnl always want these CFLAGS
 225 AC_C_FLAG([-fno-omit-frame-pointer])
 226 AC_C_FLAG([-funwind-tables])
 227 AC_C_FLAG([-Wall])
 228 AC_C_FLAG([-Wextra])
 229 AC_C_FLAG([-Wmissing-prototypes])
 230 AC_C_FLAG([-Wmissing-declarations])
 231 AC_C_FLAG([-Wpointer-arith])
 232 AC_C_FLAG([-Wbad-function-cast])
 233 AC_C_FLAG([-Wwrite-strings])
 234 if test x"${enable_gcc_ultra_verbose}" = x"yes" ; then
 235   AC_C_FLAG([-Wcast-qual])
 236   AC_C_FLAG([-Wstrict-prototypes])
 237   AC_C_FLAG([-Wmissing-noreturn])
 238   AC_C_FLAG([-Wmissing-format-attribute])
 239   AC_C_FLAG([-Wunreachable-code])
 240   AC_C_FLAG([-Wpacked])
 241   AC_C_FLAG([-Wpadded])
 242   AC_C_FLAG([-Wshadow])
 243 else
 244   AC_C_FLAG([-Wno-unused-result])
 245 fi
 246 AC_C_FLAG([-Wno-unused-parameter])
 247 AC_C_FLAG([-Wno-missing-field-initializers])
 248
 249 dnl ICC emits a broken warning for const char *x = a ? "b" : "c";
 250 dnl for some reason the string consts get 'promoted' to char *,
 251 dnl triggering a const to non-const conversion warning.
 252 AC_C_FLAG([-diag-disable 3179])
 253
 254 if test x"${enable_werror}" = x"yes" ; then
 255   WERROR="-Werror"
 256 fi
 257 AC_SUBST(WERROR)
 258
 259 SAN_FLAGS=""
 260 if test "$enable_address_sanitizer" = "yes"; then
 261   AC_C_FLAG([-fsanitize=address], [
 262     AC_MSG_ERROR([$CC does not support Address Sanitizer.])
 263   ], [
 264     SAN_FLAGS="$SAN_FLAGS -fsanitize=address"
 265   ])
 266 fi
 267 if test "$enable_thread_sanitizer" = "yes"; then
 268   AC_C_FLAG([-fsanitize=thread], [
 269     AC_MSG_ERROR([$CC does not support Thread Sanitizer.])
 270   ], [
 271     SAN_FLAGS="$SAN_FLAGS -fsanitize=thread"
 272   ])
 273 fi
 274 if test "$enable_memory_sanitizer" = "yes"; then
 275   AC_C_FLAG([-fsanitize=thread -fPIE -pie], [
 276     AC_MSG_ERROR([$CC does not support Thread Sanitizer.])
 277   ], [
 278     SAN_FLAGS="-fsanitize=memory -fPIE -pie"
 279   ])
 280 fi
 281 AC_SUBST([SAN_FLAGS])
 282
 283 dnl ----------
 284 dnl Essentials
 285 dnl ----------
 286
 287 AX_PTHREAD([
 288   CC="$PTHREAD_CC"
 289   CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 290   LIBS="$PTHREAD_LIBS $LIBS"
 291 ], [
 292   AC_MSG_FAILURE([This FRR version needs pthreads])
 293 ])
 294
 295 AC_SEARCH_LIBS([pthread_condattr_setclock], [],
 296                 [frr_cv_pthread_condattr_setclock=yes],
 297                 [frr_cv_pthread_condattr_setclock=no])
 298 if test "$frr_cv_pthread_condattr_setclock" = yes; then
 299   AC_DEFINE(HAVE_PTHREAD_CONDATTR_SETCLOCK, 1, [Have pthread.h pthread_condattr_setclock])
 300 fi
 301
 302 dnl --------------
 303 dnl Check programs
 304 dnl --------------
 305 AC_PROG_INSTALL
 306 AC_PROG_LN_S
 307 AC_PROG_MAKE_SET
 308 AC_CHECK_TOOL(AR, ar)
 309
 310 dnl -------
 311 dnl libtool
 312 dnl -------
 313 LT_INIT
 314
 315 dnl ----------------------
 316 dnl Packages configuration
 317 dnl ----------------------
 318 AC_ARG_WITH(pkg-extra-version,
 319         AS_HELP_STRING([--with-pkg-extra-version=VER], [add extra version field, for packagers/distributions]),
 320         [EXTRAVERSION=$withval],)
 321 AC_ARG_WITH(pkg-git-version,
 322         AS_HELP_STRING([--with-pkg-git-version], [add git information to MOTD and build version string]),
 323         [ test "x$withval" != "xno" && with_pkg_git_version="yes" ])
 324 AC_ARG_WITH(vtysh_pager,
 325         AS_HELP_STRING([--with-vtysh-pager=PAGER], [control what pager is compiled in as default]),
 326         VTYSH_PAGER=$withval, VTYSH_PAGER="more")
 327 AC_ARG_ENABLE(vtysh,
 328   AS_HELP_STRING([--disable-vtysh], [do not build integrated vty shell for FRR]))
 329 AC_ARG_ENABLE(doc,
 330   AS_HELP_STRING([--disable-doc], [do not build docs]))
 331 AC_ARG_ENABLE(doc-html,
 332   AS_HELP_STRING([--enable-doc-html], [build HTML docs]))
 333 AC_ARG_ENABLE(zebra,
 334   AS_HELP_STRING([--disable-zebra], [do not build zebra daemon]))
 335 AC_ARG_ENABLE(bgpd,
 336   AS_HELP_STRING([--disable-bgpd], [do not build bgpd]))
 337 AC_ARG_ENABLE(ripd,
 338   AS_HELP_STRING([--disable-ripd], [do not build ripd]))
 339 AC_ARG_ENABLE(ripngd,
 340   AS_HELP_STRING([--disable-ripngd], [do not build ripngd]))
 341 AC_ARG_ENABLE(ospfd,
 342   AS_HELP_STRING([--disable-ospfd], [do not build ospfd]))
 343 AC_ARG_ENABLE(ospf6d,
 344   AS_HELP_STRING([--disable-ospf6d], [do not build ospf6d]))
 345 AC_ARG_ENABLE(ldpd,
 346   AS_HELP_STRING([--disable-ldpd], [do not build ldpd]))
 347 AC_ARG_ENABLE(nhrpd,
 348   AS_HELP_STRING([--disable-nhrpd], [do not build nhrpd]))
 349 AC_ARG_ENABLE(eigrpd,
 350   AS_HELP_STRING([--disable-eigrpd], [do not build eigrpd]))
 351 AC_ARG_ENABLE(babeld,
 352   AS_HELP_STRING([--disable-babeld], [do not build babeld]))
 353 AC_ARG_ENABLE(watchfrr,
 354   AS_HELP_STRING([--disable-watchfrr], [do not build watchfrr]))
 355 AC_ARG_ENABLE(isisd,
 356   AS_HELP_STRING([--disable-isisd], [do not build isisd]))
 357 AC_ARG_ENABLE(pimd,
 358   AS_HELP_STRING([--disable-pimd], [do not build pimd]))
 359 AC_ARG_ENABLE(pbrd,
 360   AS_HELP_STRING([--disable-pbrd], [do not build pbrd]))
 361 AC_ARG_ENABLE(sharpd,
 362   AS_HELP_STRING([--enable-sharpd], [build sharpd]))
 363 AC_ARG_ENABLE(staticd,
 364   AS_HELP_STRING([--disable-staticd], [do not build staticd]))
 365 AC_ARG_ENABLE(fabricd,
 366   AS_HELP_STRING([--disable-fabricd], [do not build fabricd]))
 367 AC_ARG_ENABLE(bgp-announce,
 368   AS_HELP_STRING([--disable-bgp-announce,], [turn off BGP route announcement]))
 369 AC_ARG_ENABLE(bgp-vnc,
 370   AS_HELP_STRING([--disable-bgp-vnc],[turn off BGP VNC support]))
 371 AC_ARG_ENABLE(snmp,
 372   AS_HELP_STRING([--enable-snmp], [enable SNMP support for agentx]))
 373 AC_ARG_ENABLE(zeromq,
 374   AS_HELP_STRING([--enable-zeromq], [enable ZeroMQ handler (libfrrzmq)]))
 375 AC_ARG_WITH(libpam,
 376   AS_HELP_STRING([--with-libpam], [use libpam for PAM support in vtysh]))
 377 AC_ARG_ENABLE(ospfapi,
 378   AS_HELP_STRING([--disable-ospfapi], [do not build OSPFAPI to access the OSPF LSA Database]))
 379 AC_ARG_ENABLE(ospfclient,
 380   AS_HELP_STRING([--disable-ospfclient], [do not build OSPFAPI client for OSPFAPI,
 381                           (this is the default if --disable-ospfapi is set)]))
 382 AC_ARG_ENABLE(multipath,
 383   AS_HELP_STRING([--enable-multipath=ARG], [enable multipath function, ARG must be digit]))
 384 AC_ARG_ENABLE(user,
 385   AS_HELP_STRING([--enable-user=USER], [user to run FRR suite as (default frr)]))
 386 AC_ARG_ENABLE(group,
 387   AS_HELP_STRING([--enable-group=GROUP], [group to run FRR suite as (default frr)]))
 388 AC_ARG_ENABLE(vty_group,
 389   AS_HELP_STRING([--enable-vty-group=ARG], [set vty sockets to have specified group as owner]))
 390 AC_ARG_ENABLE(configfile_mask,
 391   AS_HELP_STRING([--enable-configfile-mask=ARG], [set mask for config files]))
 392 AC_ARG_ENABLE(logfile_mask,
 393   AS_HELP_STRING([--enable-logfile-mask=ARG], [set mask for log files]))
 394 AC_ARG_ENABLE(shell_access,
 395   AS_HELP_STRING([--enable-shell-access], [Allow users to access shell/telnet/ssh]))
 396 AC_ARG_ENABLE(realms,
 397   AS_HELP_STRING([--enable-realms], [enable REALMS support under Linux]))
 398 AC_ARG_ENABLE(rtadv,
 399   AS_HELP_STRING([--disable-rtadv], [disable IPV6 router advertisement feature]))
 400 AC_ARG_ENABLE(irdp,
 401   AS_HELP_STRING([--disable-irdp], [enable IRDP server support in zebra (default if supported)]))
 402 AC_ARG_ENABLE(capabilities,
 403   AS_HELP_STRING([--disable-capabilities], [disable using POSIX capabilities]))
 404 AC_ARG_ENABLE(rusage,
 405   AS_HELP_STRING([--disable-rusage], [disable using getrusage]))
 406 AC_ARG_ENABLE(gcc_ultra_verbose,
 407   AS_HELP_STRING([--enable-gcc-ultra-verbose], [enable ultra verbose GCC warnings]))
 408 AC_ARG_ENABLE(backtrace,
 409   AS_HELP_STRING([--disable-backtrace,], [disable crash backtraces (default autodetect)]))
 410 AC_ARG_ENABLE(time-check,
 411   AS_HELP_STRING([--disable-time-check], [disable slow thread warning messages]))
 412 AC_ARG_ENABLE(pcreposix,
 413   AS_HELP_STRING([--enable-pcreposix], [enable using PCRE Posix libs for regex functions]))
 414 AC_ARG_ENABLE(fpm,
 415   AS_HELP_STRING([--enable-fpm], [enable Forwarding Plane Manager support]))
 416 AC_ARG_ENABLE(systemd,
 417   AS_HELP_STRING([--enable-systemd], [enable Systemd support]))
 418 AC_ARG_ENABLE(werror,
 419   AS_HELP_STRING([--enable-werror], [enable -Werror (recommended for developers only)]))
 420 AC_ARG_ENABLE(cumulus,
 421   AS_HELP_STRING([--enable-cumulus], [enable Cumulus Switch Special Extensions]))
 422 AC_ARG_ENABLE(datacenter,
 423   AS_HELP_STRING([--enable-datacenter], [enable Compilation for Data Center Extensions]))
 424 AC_ARG_ENABLE(fuzzing,
 425   AS_HELP_STRING([--enable-fuzzing], [enable ability to fuzz various parts of FRR]))
 426 AC_ARG_ENABLE(netlink_fuzzing,
 427   AS_HELP_STRING([--enable-netlink-fuzzing], [enable ability to fuzz netlink listening socket in zebra]))
 428 AC_ARG_ENABLE(rr-semantics,
 429   AS_HELP_STRING([--disable-rr-semantics], [disable the v6 Route Replace semantics]))
 430 AC_ARG_ENABLE([protobuf],
 431   AS_HELP_STRING([--enable-protobuf], [Enable experimental protobuf support]))
 432 AC_ARG_ENABLE([oldvpn_commands],
 433   AS_HELP_STRING([--enable-oldvpn-commands], [Keep old vpn commands]))
 434 AC_ARG_ENABLE(rpki,
 435   AS_HELP_STRING([--enable-rpki], [enable RPKI prefix validation support]))
 436 AC_ARG_ENABLE([clippy-only],
 437   AS_HELP_STRING([--enable-clippy-only], [Only build clippy]))
 438 AC_ARG_ENABLE([numeric_version],
 439   AS_HELP_STRING([--enable-numeric-version], [Only numeric digits allowed in version (for Alpine)]))
 440 AC_ARG_ENABLE([gcov],
 441   AS_HELP_STRING([--enable-gcov], [Add code coverage information]))
 442 AC_ARG_ENABLE(bfdd,
 443   AS_HELP_STRING([--disable-bfdd], [do not build bfdd]))
 444 AC_ARG_ENABLE([address-sanitizer],
 445   AS_HELP_STRING([--enable-address-sanitizer], [enable AddressSanitizer support for detecting a wide variety of memory allocation and deallocation errors]))
 446 AC_ARG_ENABLE([thread-sanitizer],
 447   AS_HELP_STRING([--enable-thread-sanitizer], [enable ThreadSanitizer support for detecting data races]))
 448 AC_ARG_ENABLE([memory-sanitizer],
 449   AS_HELP_STRING([--enable-memory-sanitizer], [enable MemorySanitizer support for detecting uninitialized memory reads]))
 450
 451 AS_IF([test "${enable_clippy_only}" != "yes"], [
 452 AC_CHECK_HEADERS(json-c/json.h)
 453 AC_CHECK_LIB(json-c, json_object_get, LIBS="$LIBS -ljson-c", [], [-lm])
 454 if test $ac_cv_lib_json_c_json_object_get = no; then
 455   AC_CHECK_LIB(json, json_object_get, LIBS="$LIBS -ljson")
 456   if test $ac_cv_lib_json_json_object_get = no; then
 457       AC_MSG_ERROR([lib json is needed to compile])
 458   fi
 459 fi
 460 ])
 461
 462 AC_ARG_ENABLE([dev_build],
 463     AS_HELP_STRING([--enable-dev-build], [build for development]))
 464
 465 AC_ARG_ENABLE([lua],
 466     AS_HELP_STRING([--enable-lua], [Build Lua scripting]))
 467
 468 if test x"${enable_time_check}" != x"no" ; then
 469   if test x"${enable_time_check}" = x"yes" -o x"${enable_time_check}" = x ; then
 470     AC_DEFINE(CONSUMED_TIME_CHECK,5000000,Consumed Time Check)
 471   else
 472     AC_DEFINE_UNQUOTED(CONSUMED_TIME_CHECK,$enable_time_check,Consumed Time Check)
 473   fi
 474 fi
 475
 476 case "${enable_systemd}" in
 477   "no") ;;
 478   "yes")
 479   AC_CHECK_LIB(systemd, sd_notify, LIBS="$LIBS -lsystemd")
 480   if test $ac_cv_lib_systemd_sd_notify = no; then
 481     AC_MSG_ERROR([enable systemd has been specified but systemd development env not found on your system])
 482   else
 483     AC_DEFINE(HAVE_SYSTEMD,,Compile systemd support in)
 484   fi
 485   ;;
 486   "*") ;;
 487 esac
 488
 489 if test "${enable_rr_semantics}" != "no" ; then
 490   AC_DEFINE(HAVE_V6_RR_SEMANTICS,, Compile in v6 Route Replacement Semantics)
 491 fi
 492
 493 if test "${enable_datacenter}" = "yes" ; then
 494   AC_DEFINE(HAVE_DATACENTER,,Compile extensions for a DataCenter)
 495   DFLT_NAME="datacenter"
 496 else
 497   DFLT_NAME="traditional"
 498 fi
 499
 500 if test "${enable_fuzzing}" = "yes" ; then
 501   AC_DEFINE(HANDLE_ZAPI_FUZZING,,Compile extensions to use with a fuzzer)
 502 fi
 503
 504 if test "${enable_netlink_fuzzing}" = "yes" ; then
 505   AC_DEFINE(HANDLE_NETLINK_FUZZING,,Compile extensions to use with a fuzzer for netlink)
 506 fi
 507
 508 if test "${enable_cumulus}" = "yes" ; then
 509   AC_DEFINE(HAVE_CUMULUS,,Compile Special Cumulus Code in)
 510 fi
 511
 512 AC_SUBST(DFLT_NAME)
 513 AC_DEFINE_UNQUOTED(DFLT_NAME,["$DFLT_NAME"], Name of the configuration default set)
 514
 515 if test "${enable_shell_access}" = "yes"; then
 516    AC_DEFINE(HAVE_SHELL_ACCESS,,Allow user to use ssh/telnet/bash)
 517 fi
 518
 519 AM_CONDITIONAL([FPM], [test "x$enable_fpm" = "xyes"])
 520
 521 #
 522 # Python for clippy
 523 #
 524
 525 AC_DEFUN([FRR_PYTHON_CHECK_WORKING], [
 526   AC_MSG_CHECKING([whether we found a working Python version])
 527   AC_LINK_IFELSE_FLAGS([$PYTHON_CFLAGS], [$PYTHON_LIBS], [AC_LANG_PROGRAM([
 528 #include <Python.h>
 529 #if PY_VERSION_HEX < 0x02070000
 530 #error python too old
 531 #endif
 532 int main(void);
 533 ],
 534 [
 535 {
 536   Py_Initialize();
 537   return 0;
 538 }
 539 ])], [
 540     # some python installs are missing the zlib dependency...
 541     PYTHON_LIBS="${PYTHON_LIBS} -lz"
 542     AC_LINK_IFELSE_FLAGS([$PYTHON_CFLAGS], [$PYTHON_LIBS], [AC_LANG_PROGRAM([
 543 #include <Python.h>
 544 #if PY_VERSION_HEX < 0x02070000
 545 #error python too old
 546 #endif
 547 int main(void);
 548 ],
 549 [
 550 {
 551   Py_Initialize();
 552   return 0;
 553 }
 554 ])], [
 555       m4_if([$1], [], [
 556         PYTHONCONFIG=""
 557         unset PYTHON_LIBS
 558         unset PYTHON_CFLAGS
 559       ], [$1])
 560     ])
 561   ])
 562 ])
 563
 564 AS_IF([test "$host" = "$build"], [
 565   PYTHONCONFIG=""
 566
 567   # ordering:
 568   # 1.  try python3, but respect the user's preference on which minor ver
 569   # 2.  try python, which might be py3 or py2 again on the user's preference
 570   # 3.  try python2 (can really only be 2.7 but eh)
 571   # 4.  try 3.6 > 3.5 > 3.4 > 3.3 > 3.2 > 2.7 through pkg-config (no user pref)
 572   #
 573   # (AX_PYTHON_DEVEL has no clue about py3 vs py2)
 574   # (AX_PYTHON does not do what we need)
 575
 576   AC_CHECK_TOOLS([PYTHONCONFIG], [ \
 577         python3-config \
 578         python-config \
 579         python2-config \
 580         python3.6-config \
 581         python3.5-config \
 582         python3.4-config \
 583         python3.3-config \
 584         python3.2-config \
 585         python2.7-config ])
 586   if test -n "$PYTHONCONFIG"; then
 587     PYTHON_CFLAGS="`\"${PYTHONCONFIG}\" --includes`"
 588     PYTHON_LIBS="`\"${PYTHONCONFIG}\" --ldflags`"
 589
 590     FRR_PYTHON_CHECK_WORKING([])
 591   fi
 592
 593   if test -z "$PYTHONCONFIG"; then
 594     PKG_CHECK_MODULES([PYTHON], python-3.6, [], [
 595       PKG_CHECK_MODULES([PYTHON], python-3.5, [], [
 596         PKG_CHECK_MODULES([PYTHON], python-3.4, [], [
 597           PKG_CHECK_MODULES([PYTHON], python-3.3, [], [
 598             PKG_CHECK_MODULES([PYTHON], python-3.2, [], [
 599               PKG_CHECK_MODULES([PYTHON], python-2.7, [], [
 600                 AC_MSG_FAILURE([could not find python-config or pkg-config python, please install Python development files from libpython-dev or similar])
 601                 ])])])])])])
 602
 603
 604     FRR_PYTHON_CHECK_WORKING([
 605       AC_MSG_FAILURE([could not find python-config or pkg-config python, please install Python development files from libpython-dev or similar])
 606     ])
 607   fi
 608 ])
 609 AC_SUBST(PYTHON_CFLAGS)
 610 AC_SUBST(PYTHON_LIBS)
 611
 612 #
 613 # Logic for protobuf support.
 614 #
 615 if test "$enable_protobuf" = "yes"; then
 616   # Check for protoc & protoc-c
 617
 618   # protoc is not required, it's only for a "be nice" helper target
 619   AC_CHECK_PROGS([PROTOC], [protoc], [/bin/false])
 620
 621   AC_CHECK_PROGS([PROTOC_C], [protoc-c], [/bin/false])
 622   if test "$PROTOC_C" = "/bin/false"; then
 623     AC_MSG_FAILURE([protobuf requested but protoc-c not found.  Install protobuf-c.])
 624   fi
 625
 626   PKG_CHECK_MODULES([PROTOBUF_C], [libprotobuf-c >= 0.14],, [
 627     AC_MSG_FAILURE([protobuf requested but libprotobuf-c not found.  Install protobuf-c.])
 628   ])
 629   AC_CHECK_HEADER([google/protobuf-c/protobuf-c.h], [], [
 630     AC_MSG_FAILURE([protobuf requested but protobuf-c.h not found.  Install protobuf-c.])
 631   ])
 632
 633   AC_DEFINE(HAVE_PROTOBUF,, protobuf)
 634 fi
 635 AM_CONDITIONAL([HAVE_PROTOBUF], [test "x$enable_protobuf" = "xyes"])
 636
 637 #
 638 # Logic for old vpn commans support.
 639 #
 640 if test "$enable_oldvpn_commands" = "yes"; then
 641    AC_DEFINE(KEEP_OLD_VPN_COMMANDS,, [Define for compiling with old vpn commands])
 642 fi
 643
 644 #
 645 # End of logic for protobuf support.
 646 #
 647
 648 AC_MSG_CHECKING(if zebra should be configurable to send Route Advertisements)
 649 if test "${enable_rtadv}" != "no"; then
 650   AC_MSG_RESULT(yes)
 651   AC_DEFINE(HAVE_RTADV,,Enable IPv6 Routing Advertisement support)
 652 else
 653   AC_MSG_RESULT(no)
 654 fi
 655
 656 if test x"${enable_user}" = x"no"; then
 657   enable_user=""
 658 else
 659   if test x"${enable_user}" = x"yes" || test x"${enable_user}" = x""; then
 660     enable_user="frr"
 661   fi
 662   AC_DEFINE_UNQUOTED(FRR_USER, "${enable_user}", frr User)
 663 fi
 664
 665 if test x"${enable_group}" = x"no"; then
 666   enable_group=""
 667 else
 668   if test x"${enable_group}" = x"yes" || test x"${enable_group}" = x""; then
 669     enable_group="frr"
 670   fi
 671   AC_DEFINE_UNQUOTED(FRR_GROUP, "${enable_group}", frr Group)
 672 fi
 673
 674 if test x"${enable_vty_group}" = x"yes" ; then
 675   AC_MSG_ERROR([--enable-vty-group requires a group as argument, not yes])
 676 elif test x"${enable_vty_group}" != x""; then
 677   if test x"${enable_vty_group}" != x"no"; then
 678     AC_DEFINE_UNQUOTED(VTY_GROUP, "${enable_vty_group}", VTY Sockets Group)
 679   fi
 680 fi
 681 AC_SUBST([enable_user])
 682 AC_SUBST([enable_group])
 683 AC_SUBST([enable_vty_group])
 684
 685 enable_configfile_mask=${enable_configfile_mask:-0600}
 686 AC_DEFINE_UNQUOTED(CONFIGFILE_MASK, ${enable_configfile_mask}, Mask for config files)
 687
 688 enable_logfile_mask=${enable_logfile_mask:-0600}
 689 AC_DEFINE_UNQUOTED(LOGFILE_MASK, ${enable_logfile_mask}, Mask for log files)
 690
 691 MPATH_NUM=1
 692
 693 case "${enable_multipath}" in
 694   0)
 695     MPATH_NUM=64
 696     ;;
 697   [[1-9]|[1-9][0-9]|[1-9][0-9][0-9]])
 698     MPATH_NUM="${enable_multipath}"
 699     ;;
 700   "")
 701     ;;
 702   *)
 703     AC_MSG_FAILURE([Please specify digit to enable multipath ARG])
 704     ;;
 705 esac
 706
 707 AC_DEFINE_UNQUOTED(MULTIPATH_NUM, $MPATH_NUM, Maximum number of paths for a route)
 708
 709 AC_DEFINE_UNQUOTED(VTYSH_PAGER, "$VTYSH_PAGER", [What pager to use])
 710
 711 dnl --------------------
 712 dnl Enable code coverage
 713 dnl --------------------
 714 AM_CONDITIONAL([HAVE_GCOV],[test '!' "$enable_gcov" = no])
 715
 716 dnl ------------------------------------
 717 dnl Alpine only accepts numeric versions
 718 dnl ------------------------------------
 719 if test "x${enable_numeric_version}" != "x" ; then
 720   VERSION="`echo ${VERSION} | tr -c -d '[[.0-9]]'`"
 721   PACKAGE_VERSION="`echo ${PACKAGE_VERSION} | tr -c -d '[[.0-9]]'`"
 722 fi
 723
 724 dnl -----------------------------------
 725 dnl Add extra version string to package
 726 dnl name, string and version fields.
 727 dnl -----------------------------------
 728 if test "x${EXTRAVERSION}" != "x" ; then
 729   VERSION="${VERSION}${EXTRAVERSION}"
 730   PACKAGE_VERSION="${PACKAGE_VERSION}${EXTRAVERSION}"
 731   AC_SUBST(PACKAGE_EXTRAVERSION, ["${EXTRAVERSION}"])
 732   PACKAGE_STRING="${PACKAGE_STRING}${EXTRAVERSION}"
 733 fi
 734
 735 if test "x$with_pkg_git_version" = "xyes"; then
 736         if test -d "${srcdir}/.git"; then
 737                 AC_DEFINE(GIT_VERSION, [1], [include git version info])
 738         else    with_pkg_git_version="no"
 739                 AC_MSG_WARN([--with-pkg-git-version given, but this is not a git checkout])
 740         fi
 741 fi
 742 AM_CONDITIONAL([GIT_VERSION], [test "x$with_pkg_git_version" = "xyes"])
 743
 744 AC_CHECK_TOOL([OBJCOPY], [objcopy], [:])
 745 AC_CACHE_CHECK([for .interp value to use], [frr_cv_interp], [
 746   frr_cv_interp=""
 747   AC_LINK_IFELSE([AC_LANG_SOURCE([[int main() { return 0; }]])], [
 748     if $OBJCOPY -j.interp -Obinary conftest conftest.interp; then
 749       frr_cv_interp="`xargs -0 echo < conftest.interp`"
 750     fi
 751     test -f conftest.interp && rm conftest.interp
 752   ])
 753 ])
 754 if test -n "$frr_cv_interp"; then
 755   AC_DEFINE_UNQUOTED(INTERP, ["$frr_cv_interp"], [.interp value])
 756 fi
 757
 758 dnl ------------------------------------
 759 dnl Check C keywords and standard  types
 760 dnl ------------------------------------
 761 AC_C_CONST
 762 AC_C_INLINE
 763 AC_C_VOLATILE
 764 AC_HEADER_STDC
 765 dnl AC_TYPE_PID_T
 766 AC_TYPE_UID_T
 767 AC_TYPE_MODE_T
 768 AC_TYPE_SIZE_T
 769 AC_STRUCT_TM
 770
 771 dnl -------------------------
 772 dnl Check other header files.
 773 dnl -------------------------
 774 AC_CHECK_HEADERS([stropts.h sys/ksym.h \
 775         linux/version.h asm/types.h \
 776         sys/cdefs.h])
 777
 778 ac_stdatomic_ok=false
 779 AC_DEFINE(FRR_AUTOCONF_ATOMIC, 1, [did autoconf checks for atomic funcs])
 780 AC_CHECK_HEADER([stdatomic.h],[
 781
 782   AC_MSG_CHECKING([whether _Atomic qualifier works])
 783   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 784 #include <stdatomic.h>
 785 int main(int argc, char **argv) {
 786   _Atomic int i = 0;
 787   return i;
 788 }
 789 ]])], [
 790     AC_DEFINE(HAVE_STDATOMIC_H, 1, [found stdatomic.h])
 791     AC_MSG_RESULT([yes])
 792     ac_stdatomic_ok=true
 793   ], [
 794     AC_MSG_RESULT([no])
 795   ])
 796 ])
 797
 798 AS_IF([$ac_stdatomic_ok], [true], [
 799   AC_MSG_CHECKING([for __atomic_* builtins])
 800   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 801 int main(int argc, char **argv) {
 802   volatile int i = 1;
 803   __atomic_store_n (&i, 0, __ATOMIC_RELEASE);
 804   return __atomic_load_n (&i, __ATOMIC_ACQUIRE);
 805 }
 806 ]])], [
 807     AC_DEFINE(HAVE___ATOMIC, 1, [found __atomic builtins])
 808     AC_MSG_RESULT([yes])
 809   ], [
 810     AC_MSG_RESULT([no])
 811
 812     dnl FreeBSD 9 has a broken stdatomic.h where _Atomic doesn't work
 813     AC_MSG_CHECKING([for __sync_* builtins])
 814     AC_LINK_IFELSE([AC_LANG_SOURCE([[
 815 int main(int argc, char **argv) {
 816   volatile int i = 1;
 817   __sync_fetch_and_sub (&i, 1);
 818   return __sync_val_compare_and_swap (&i, 0, 1);
 819 }
 820 ]])], [
 821       AC_DEFINE(HAVE___SYNC, 1, [found __sync builtins])
 822       AC_MSG_RESULT([yes])
 823
 824       AC_MSG_CHECKING([for __sync_swap builtin])
 825       AC_LINK_IFELSE([AC_LANG_SOURCE([[
 826 int main(int argc, char **argv) {
 827   volatile int i = 1;
 828   return __sync_swap (&i, 2);
 829 }
 830 ]])], [
 831         AC_DEFINE(HAVE___SYNC_SWAP, 1, [found __sync_swap builtin])
 832         AC_MSG_RESULT([yes])
 833       ], [
 834         AC_MSG_RESULT([no])
 835       ])
 836
 837     ], [
 838       AC_MSG_RESULT([no])
 839       AC_MSG_FAILURE([stdatomic.h unavailable and $CC has neither __atomic nor __sync builtins])
 840     ])
 841   ])
 842 ])
 843
 844 AC_CHECK_HEADERS([pthread_np.h],,, [
 845 #include <pthread.h>
 846 ])
 847 AC_CHECK_FUNCS([pthread_setname_np pthread_set_name_np])
 848
 849 dnl Utility macro to avoid retyping includes all the time
 850 m4_define([FRR_INCLUDES],
 851 [#ifdef SUNOS_5
 852 #define _POSIX_C_SOURCE 200809L
 853 #define __EXTENSIONS__
 854 #endif
 855 #include <stdio.h>
 856 #include <stdlib.h>
 857 #include <stddef.h>
 858 #include <sys/types.h>
 859 /* sys/conf.h depends on param.h on FBSD at least */
 860 #include <sys/param.h>
 861 /* Required for MAXSIG */
 862 #include <signal.h>
 863 #include <sys/socket.h>
 864 #ifdef __APPLE__
 865 # define __APPLE_USE_RFC_3542
 866 #endif
 867 #include <netinet/in.h>
 868 #include <sys/time.h>
 869 #include <time.h>
 870 #include <net/if.h>
 871 ])dnl
 872
 873 dnl Same applies for HAVE_NET_IF_VAR_H, which HAVE_NETINET6_ND6_H and
 874 dnl HAVE_NETINET_IN_VAR_H depend upon. But if_var.h depends on if.h, hence
 875 dnl an additional round for it.
 876
 877 AC_CHECK_HEADERS([net/if_var.h], [], [], FRR_INCLUDES)
 878
 879 m4_define([FRR_INCLUDES],
 880 FRR_INCLUDES
 881 [#if HAVE_NET_IF_VAR_H
 882 # include <net/if_var.h>
 883 #endif
 884 ])dnl
 885
 886 AC_CHECK_HEADERS([netinet/in_var.h \
 887         net/if_dl.h net/netopt.h \
 888         inet/nd.h netinet/ip_icmp.h \
 889         sys/sysctl.h sys/sockio.h kvm.h sys/conf.h],
 890         [], [], FRR_INCLUDES)
 891
 892 AC_CHECK_HEADERS([ucontext.h], [], [],
 893 [#ifndef __USE_GNU
 894 #define __USE_GNU
 895 #endif /* __USE_GNU */
 896 FRR_INCLUDES
 897 ])
 898
 899 m4_define([UCONTEXT_INCLUDES],
 900 [#include <ucontext.h>])dnl
 901
 902 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.uc_regs],
 903   [], [], [UCONTEXT_INCLUDES])
 904 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs],
 905   [AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs.nip],
 906    [], [], [UCONTEXT_INCLUDES])],
 907   [], [UCONTEXT_INCLUDES])
 908 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.gregs],
 909   [], [], [UCONTEXT_INCLUDES])
 910
 911 m4_define([FRR_INCLUDES],
 912 FRR_INCLUDES
 913 [
 914 #include <sys/un.h>
 915 #include <netinet/in_systm.h>
 916 #if HAVE_NETINET_IN_VAR_H
 917 # include <netinet/in_var.h>
 918 #endif
 919 #if HAVE_NET_IF_DL_H
 920 # include <net/if_dl.h>
 921 #endif
 922 #if HAVE_NET_NETOPT_H
 923 # include <net/netopt.h>
 924 #endif
 925 #include <net/route.h>
 926 #if HAVE_INET_ND_H
 927 # include <inet/nd.h>
 928 #endif
 929 #include <arpa/inet.h>
 930 /* Required for IDRP */
 931 #if HAVE_NETINET_IP_ICMP_H
 932 # include <netinet/ip_icmp.h>
 933 #endif
 934 ])dnl
 935
 936 dnl V6 headers are checked below, after we check for v6
 937
 938 AC_MSG_CHECKING([which operating system interface to use])
 939 case "$host_os" in
 940   sunos* | solaris2*)
 941     AC_MSG_RESULT([Solaris])
 942
 943     AC_DEFINE(SUNOS_5, 1, [SunOS 5])
 944     AC_DEFINE(SOLARIS_IPV6, 1, Solaris IPv6)
 945     AC_DEFINE(_POSIX_C_SOURCE, 200809L, [enable POSIX.1-2008 and XPG7/SUSv4])
 946
 947     AC_CHECK_LIB(socket, main)
 948     AC_CHECK_LIB(nsl, main)
 949     AC_CHECK_LIB(umem, main)
 950     AC_CHECK_FUNCS([printstack], [
 951       AC_DEFINE([HAVE_PRINTSTACK],1,[Solaris printstack])
 952       AC_DEFINE([HAVE_STACK_TRACE],1,[Stack symbols decode functionality])
 953     ])
 954     CURSES=-lcurses
 955     SOLARIS="solaris"
 956     ;;
 957   linux*)
 958     AC_MSG_RESULT([Linux])
 959
 960     AC_DEFINE(GNU_LINUX,,GNU Linux)
 961     AC_DEFINE(HAVE_NETLINK,,netlink)
 962     AC_DEFINE(LINUX_IPV6,1,Linux IPv6 stack)
 963
 964     dnl Linux has a compilation problem with mixing
 965     dnl netinet/in.h and linux/in6.h they are not
 966     dnl compatible.  There has been discussion on
 967     dnl how to fix it but no real progress on implementation
 968     dnl when they fix it, remove this
 969     AC_DEFINE(IPV6_MINHOPCOUNT, 73, Linux ipv6 Min Hop Count)
 970     ;;
 971   openbsd*)
 972     AC_MSG_RESULT([OpenBSD])
 973
 974     AC_DEFINE(OPEN_BSD,,OpenBSD)
 975     AC_DEFINE(KAME,1,KAME IPv6)
 976     AC_DEFINE(BSD_V6_SYSCTL,1,BSD v6 sysctl to turn on and off forwarding)
 977
 978     if test "x${enable_pimd}" != "xno"; then
 979       case "$host_os" in
 980       openbsd6.0)
 981         ;;
 982       openbsd[6-9]*)
 983         AC_MSG_FAILURE([pimd cannot be enabled as PIM support has been removed from OpenBSD 6.1])
 984         ;;
 985       esac
 986     fi
 987     ;;
 988   *)
 989     AC_MSG_RESULT([BSD])
 990
 991     AC_DEFINE(HAVE_NET_RT_IFLIST,,NET_RT_IFLIST)
 992     AC_DEFINE(KAME,1,KAME IPv6)
 993     AC_DEFINE(BSD_V6_SYSCTL,1,BSD v6 sysctl to turn on and off forwarding)
 994     ;;
 995 esac
 996 AM_CONDITIONAL(SOLARIS, test "${SOLARIS}" = "solaris")
 997
 998 AC_SYS_LARGEFILE
 999
1000 dnl ------------------------
1001 dnl Integrated REALMS option
1002 dnl ------------------------
1003 if test "${enable_realms}" = "yes"; then
1004     case "$host_os" in
1005       linux*)
1006        AC_DEFINE(SUPPORT_REALMS,, Realms support)
1007        ;;
1008       *)
1009        echo "Sorry, only Linux has REALMS support"
1010        exit 1
1011        ;;
1012     esac
1013 fi
1014 AM_CONDITIONAL([SUPPORT_REALMS], [test "${enable_realms}" = "yes"])
1015
1016 dnl ---------------------
1017 dnl Integrated VTY option
1018 dnl ---------------------
1019 case "${enable_vtysh}" in
1020   "no") VTYSH="";;
1021   *)    VTYSH="vtysh";
1022          AC_DEFINE(VTYSH,,VTY shell)
1023 dnl      Vtysh uses libreadline, which looks for termcap functions at
1024 dnl      configure time.  We follow readlines search order.
1025 dnl      The required procedures are in libtermcap on NetBSD, in
1026 dnl      [TODO] on Linux, and in [TODO] on Solaris.
1027          AC_CHECK_LIB(termcap, tputs, LIBREADLINE="$LIBREADLINE -ltermcap",
1028            [AC_CHECK_LIB(tinfo, tputs, LIBREADLINE="$LIBREADLINE -ltinfo",
1029              [AC_CHECK_LIB(curses, tputs, LIBREADLINE="$LIBREADLINE -lcurses",
1030                [AC_CHECK_LIB(ncurses, tputs,
1031                              LIBREADLINE="$LIBREADLINE -lncurses")]
1032               )]
1033             )]
1034           )
1035          AC_CHECK_LIB(readline, main, LIBREADLINE="-lreadline $LIBREADLINE",,
1036                       "$LIBREADLINE")
1037          if test $ac_cv_lib_readline_main = no; then
1038            AC_MSG_ERROR([vtysh needs libreadline but was not found and usable on your system.])
1039          fi
1040          AC_CHECK_HEADER(readline/history.h)
1041          if test $ac_cv_header_readline_history_h = no;then
1042            AC_MSG_ERROR([readline is too old to have readline/history.h, please update to the latest readline library.])
1043          fi
1044          AC_CHECK_LIB(readline, rl_completion_matches,
1045                       LIBREADLINE="$LIBREADLINE",, "$LIBREADLINE")
1046          if test $ac_cv_lib_readline_rl_completion_matches = no; then
1047            AC_DEFINE(rl_completion_matches,completion_matches,Old readline)
1048          fi
1049          AC_SEARCH_LIBS([append_history], [readline], [frr_cv_append_history=yes], [frr_cv_append_history=no])
1050          if test "$frr_cv_append_history" = yes; then
1051            AC_DEFINE(HAVE_APPEND_HISTORY, 1, [Have history.h append_history])
1052          fi
1053          ;;
1054 esac
1055 AC_SUBST(LIBREADLINE)
1056 AM_CONDITIONAL(VTYSH, test "x$VTYSH" = "xvtysh")
1057
1058 dnl ----------
1059 dnl PAM module
1060 dnl
1061 dnl FRR detects the PAM library it is built against by checking for a
1062 dnl functional pam_misc.h (Linux-PAM) or openpam.h (OpenPAM) header. pam_misc.h
1063 dnl is known to #include pam_appl.h, the standard header of a PAM library, and
1064 dnl openpam.h doesn't do that, although depends on the header too. Hence a
1065 dnl little assistance to AC_CHECK_HEADER is necessary for the proper detection
1066 dnl of OpenPAM.
1067 dnl ----------
1068 if test "$with_libpam" = "yes"; then
1069   AC_CHECK_HEADER([security/pam_misc.h],
1070     [AC_DEFINE(HAVE_PAM_MISC_H,,Have pam_misc.h)
1071      AC_DEFINE(PAM_CONV_FUNC,misc_conv,Have misc_conv)
1072      pam_conv_func="misc_conv"
1073     ],
1074     [], FRR_INCLUDES)
1075   AC_CHECK_HEADER([security/openpam.h],
1076     [AC_DEFINE(HAVE_OPENPAM_H,,Have openpam.h)
1077      AC_DEFINE(PAM_CONV_FUNC,openpam_ttyconv,Have openpam_ttyconv)
1078      pam_conv_func="openpam_ttyconv"
1079     ],
1080     [], FRR_INCLUDES[#include <security/pam_appl.h>])
1081   if test -z "$ac_cv_header_security_pam_misc_h$ac_cv_header_security_openpam_h" ; then
1082     AC_MSG_WARN([*** pam support will not be built ***])
1083     with_libpam="no"
1084   fi
1085 fi
1086
1087 if test "$with_libpam" = "yes"; then
1088 dnl took this test from proftpds configure.in and suited to our needs
1089 dnl -------------------------------------------------------------------------
1090 dnl
1091 dnl This next check looks funky due to a linker problem with some versions
1092 dnl of the PAM library.  Prior to 0.72 release, the Linux PAM shared library
1093 dnl omitted requiring libdl linking information. PAM-0.72 or better ships
1094 dnl with RedHat 6.2 and Debian 2.2 or better.
1095 AC_CHECK_LIB(pam, pam_start,
1096   [AC_CHECK_LIB(pam, $pam_conv_func,
1097     [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1098      LIBPAM="-lpam"],
1099     [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1100      LIBPAM="-lpam -lpam_misc"]
1101     )
1102   ],
1103
1104   [AC_CHECK_LIB(pam, pam_end,
1105     [AC_CHECK_LIB(pam, $pam_conv_func,
1106       [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1107        LIBPAM="-lpam -ldl"],
1108       [AC_DEFINE(USE_PAM,,Use PAM for authentication)
1109        LIBPAM="-lpam -ldl -lpam_misc"]
1110      )
1111   ],AC_MSG_WARN([*** pam support will not be built ***]),
1112   [-ldl])
1113   ]
1114 )
1115 fi
1116 AC_SUBST(LIBPAM)
1117
1118 dnl -------------------------------
1119 dnl Endian-ness check
1120 dnl -------------------------------
1121 AC_WORDS_BIGENDIAN
1122
1123 dnl -------------------------------
1124 dnl check the size in byte of the C
1125 dnl -------------------------------
1126 dnl AC_CHECK_SIZEOF(char)
1127 dnl AC_CHECK_SIZEOF(int)
1128 dnl AC_CHECK_SIZEOF(short)
1129 dnl AC_CHECK_SIZEOF(long)
1130
1131 dnl ----------------------------
1132 dnl check existance of functions
1133 dnl ----------------------------
1134 AC_FUNC_FNMATCH
1135 AC_FUNC_FORK
1136 AC_FUNC_MKTIME
1137 AC_FUNC_STAT
1138
1139 dnl -------------------------------
1140 dnl bgpd needs pow() and hence libm
1141 dnl -------------------------------
1142 TMPLIBS="$LIBS"
1143 AC_CHECK_HEADER([math.h],
1144   [AC_CHECK_LIB([m], [pow],
1145     [LIBM="-lm"
1146      LIBS="$LIBS $LIBM"
1147      AC_CHECK_FUNCS(pow,[],[LIBM=""])
1148     ])
1149 ])
1150 if test x"$LIBM" = x ; then
1151   AC_MSG_WARN([Unable to find working pow function - bgpd may not link])
1152 fi
1153 LIBS="$TMPLIBS"
1154
1155 AC_SUBST(LIBM)
1156
1157 AC_CHECK_FUNCS([ppoll], [
1158   AC_DEFINE([HAVE_PPOLL], 1, [have Linux/BSD ppoll()])
1159 ])
1160 AC_CHECK_FUNCS([pollts], [
1161   AC_DEFINE([HAVE_POLLTS], 1, [have NetBSD pollts()])
1162 ])
1163
1164 dnl ---------------
1165 dnl other functions
1166 dnl ---------------
1167 AC_CHECK_FUNCS([ \
1168         strlcat strlcpy \
1169         getgrouplist])
1170
1171 AC_CHECK_HEADER([asm-generic/unistd.h],
1172                 [AC_CHECK_DECL(__NR_setns,
1173                                AC_DEFINE(HAVE_NETNS,, Have netns),,
1174                                FRR_INCLUDES [#include <asm-generic/unistd.h>
1175                                ])
1176                  AC_CHECK_FUNCS(setns)]
1177                )
1178
1179 dnl --------------------------
1180 dnl Determine IS-IS I/O method
1181 dnl --------------------------
1182 AC_DEFINE(ISIS_METHOD_PFPACKET, 1, [ constant value for isis method pfpacket ])
1183 AC_DEFINE(ISIS_METHOD_DLPI,     2, [ constant value for isis method dlpi ])
1184 AC_DEFINE(ISIS_METHOD_BPF,      3, [ constant value for isis method bpf ])
1185 AC_CHECK_HEADER(net/bpf.h)
1186 AC_CHECK_HEADER(sys/dlpi.h)
1187 AC_MSG_CHECKING(zebra IS-IS I/O method)
1188
1189 case "$host_os" in
1190   linux*)
1191     AC_MSG_RESULT(pfpacket)
1192     ISIS_METHOD_MACRO="ISIS_METHOD_PFPACKET"
1193     ;;
1194   solaris* | sunos*)
1195     AC_MSG_RESULT(DLPI)
1196     ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1197     ;;
1198   *)
1199     if test $ac_cv_header_net_bpf_h = no; then
1200       if test $ac_cv_header_sys_dlpi_h = no; then
1201         AC_MSG_RESULT(none)
1202         if test "${enable_isisd}" = yes -o "${enable_fabricd}" = yes; then
1203           AC_MSG_FAILURE([IS-IS support requested but no packet backend found])
1204         fi
1205         AC_MSG_WARN([*** IS-IS support will not be built ***])
1206         enable_isisd="no"
1207         enable_fabricd="no"
1208       else
1209         AC_MSG_RESULT(DLPI)
1210       fi
1211       ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1212     else
1213       AC_MSG_RESULT(BPF)
1214       ISIS_METHOD_MACRO="ISIS_METHOD_BPF"
1215     fi
1216     ;;
1217 esac
1218 AC_DEFINE_UNQUOTED(ISIS_METHOD, $ISIS_METHOD_MACRO, [ selected method for isis, == one of the constants ])
1219
1220 dnl ---------------------------------------------------------------
1221 dnl figure out how to specify an interface in multicast sockets API
1222 dnl ---------------------------------------------------------------
1223 AC_CHECK_MEMBERS([struct ip_mreqn.imr_ifindex], [], [], FRR_INCLUDES)
1224
1225 AC_CHECK_HEADERS([linux/mroute.h], [], [],[
1226         #include <sys/socket.h>
1227         #include <netinet/in.h>
1228         #define _LINUX_IN_H             /* For Linux <= 2.6.25 */
1229         #include <linux/types.h>
1230 ])
1231
1232 m4_define([FRR_INCLUDES],
1233 FRR_INCLUDES
1234 [#if HAVE_LINUX_MROUTE_H
1235 # include <linux/mroute.h>
1236 #endif
1237 ])dnl
1238
1239 AC_CHECK_HEADERS([netinet/ip_mroute.h], [], [],[
1240         #include <sys/socket.h>
1241         #include <sys/types.h>
1242         #include <netinet/in.h>
1243         #include <net/route.h>
1244 ])
1245
1246 m4_define([FRR_INCLUDES],
1247 FRR_INCLUDES
1248 [#if HAVE_NETINET_IP_MROUTE_H
1249 # include <netinet/ip_mroute.h>
1250 #endif
1251 ])dnl
1252
1253 AC_MSG_CHECKING([for BSD struct ip_mreq hack])
1254 AC_TRY_COMPILE([#include <sys/param.h>],
1255 [#if (defined(__FreeBSD__) && ((__FreeBSD_version >= 500022 && __FreeBSD_version < 700000) || (__FreeBSD_version < 500000 && __FreeBSD_version >= 440000))) || (defined(__NetBSD__) && defined(__NetBSD_Version__) && __NetBSD_Version__ >= 106010000) || defined(__OpenBSD__) || defined(__APPLE__) || defined(__DragonFly__) || defined(__sun)
1256   return (0);
1257 #else
1258   #error No support for BSD struct ip_mreq hack detected
1259 #endif],[AC_MSG_RESULT(yes)
1260 AC_DEFINE(HAVE_BSD_STRUCT_IP_MREQ_HACK,,[Can pass ifindex in struct ip_mreq])],
1261 AC_MSG_RESULT(no))
1262
1263 AC_MSG_CHECKING([for RFC3678 protocol-independed API])
1264 AC_TRY_COMPILE([
1265 #include <sys/types.h>
1266 #include <netinet/in.h>
1267 ], [struct group_req gr; int sock; setsockopt(sock, IPPROTO_IP, MCAST_JOIN_GROUP, (void*)&gr, sizeof(gr));
1268 ], [AC_MSG_RESULT(yes)
1269 AC_DEFINE(HAVE_RFC3678,1,[Have RFC3678 protocol-independed API])],
1270 AC_MSG_RESULT(no))
1271
1272 dnl ---------------------------------------------------------------
1273 dnl figure out how to check link-state
1274 dnl ---------------------------------------------------------------
1275 AC_CHECK_HEADER( [net/if_media.h],
1276   [m4_define([LINK_DETECT_INCLUDES],
1277     FRR_INCLUDES
1278     [#include <net/if_media.h>
1279   ])
1280   AC_CHECK_MEMBERS( [struct ifmediareq.ifm_status],
1281     AC_DEFINE(HAVE_BSD_LINK_DETECT,,[BSD link-detect]),
1282     [], LINK_DETECT_INCLUDES)],
1283   [],
1284   FRR_INCLUDES)
1285
1286 dnl ---------------------------------------------------------------
1287 dnl Additional, newer way to check link-state using ifi_link_state.
1288 dnl Not available in all BSD's when ifmediareq available
1289 dnl ---------------------------------------------------------------
1290 AC_CHECK_MEMBERS([struct if_data.ifi_link_state],
1291   AC_DEFINE(HAVE_BSD_IFI_LINK_STATE,,[BSD ifi_link_state available]),
1292   [], FRR_INCLUDES)
1293
1294 dnl ------------------------
1295 dnl TCP_MD5SIG socket option
1296 dnl ------------------------
1297
1298 AC_CHECK_HEADER([netinet/tcp.h],
1299    [m4_define([MD5_INCLUDES],
1300       FRR_INCLUDES
1301       [#include <netinet/tcp.h>
1302     ])
1303     AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)],
1304    [],
1305    FRR_INCLUDES)
1306 if test $ac_cv_have_decl_TCP_MD5SIG = no; then
1307   AC_CHECK_HEADER([linux/tcp.h],
1308        [m4_define([MD5_INCLUDES],
1309           FRR_INCLUDES
1310           [#include <linux/tcp.h>
1311         ])
1312        AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)])
1313 fi
1314
1315 dnl ----------------------------------------------------------------------------
1316 dnl figure out if domainname is available in the utsname struct (GNU extension).
1317 dnl ----------------------------------------------------------------------------
1318 AC_CHECK_MEMBERS([struct utsname.domainname], [], [], [#include <sys/utsname.h>])
1319
1320 dnl ------------------
1321 dnl IPv6 header checks
1322 dnl ------------------
1323 AC_CHECK_HEADERS([netinet6/in6.h netinet/in6_var.h \
1324         netinet6/in6_var.h netinet6/nd6.h], [], [],
1325         FRR_INCLUDES)
1326
1327 m4_define([FRR_INCLUDES],dnl
1328 FRR_INCLUDES
1329 [#if HAVE_NETINET6_IN6_H
1330 #include <netinet6/in6.h>
1331 #endif
1332 #if HAVE_NETINET_IN6_VAR_H
1333 #include <netinet/in6_var.h>
1334 #endif
1335 #include <netinet/icmp6.h>
1336 #if HAVE_NETINET6_IN6_VAR_H
1337 # include <netinet6/in6_var.h>
1338 #endif
1339 #if HAVE_NETINET6_ND6_H
1340 # include <netinet6/nd6.h>
1341 #endif
1342 ])dnl
1343
1344 dnl disable doc check
1345 AC_CHECK_PROGS([SPHINXBUILD], [sphinx-build sphinx-build3 sphinx-build2], [/bin/false])
1346 if test "$SPHINXBUILD" = "/bin/false"; then
1347   if test "${enable_doc}" = "yes"; then
1348     AC_MSG_ERROR([Documentation was explicitly requested with --enable-doc but sphinx-build is not available. Please disable docs or install sphinx.])
1349   fi
1350 fi
1351 AM_CONDITIONAL(DOC, test "${enable_doc}" != "no" -a "$SPHINXBUILD" != "/bin/false")
1352 AM_CONDITIONAL(DOC_HTML, test "${enable_doc_html}" = "yes")
1353
1354 dnl --------------------
1355 dnl Daemon disable check
1356 dnl --------------------
1357 AM_CONDITIONAL(ZEBRA, test "${enable_zebra}" != "no")
1358
1359 if test "${enable_bgpd}" = "no";then
1360   BGPD=""
1361 else
1362   BGPD="bgpd"
1363 fi
1364 AM_CONDITIONAL(BGPD, test "x$BGPD" = "xbgpd")
1365
1366 AM_CONDITIONAL(RIPD, test "${enable_ripd}" != "no")
1367 AM_CONDITIONAL(OSPFD, test "${enable_ospfd}" != "no")
1368 AM_CONDITIONAL(LDPD, test "${enable_ldpd}" != "no")
1369
1370 AS_IF([test "${enable_ldpd}" != "no"], [
1371   AC_DEFINE(HAVE_LDPD, 1, ldpd)
1372 ])
1373
1374 if test "$enable_bfdd" = "no"; then
1375   AC_DEFINE(HAVE_BFDD, 0, bfdd)
1376   BFDD=""
1377 else
1378   AC_DEFINE(HAVE_BFDD, 1, bfdd)
1379   BFDD="bfdd"
1380
1381   case $host_os in
1382     linux*)
1383       AC_DEFINE(BFD_LINUX, 1, bfdd)
1384       ;;
1385
1386     *)
1387       AC_DEFINE(BFD_BSD, 1, bfdd)
1388       ;;
1389   esac
1390 fi
1391
1392 AM_CONDITIONAL(BFDD, [test "x$BFDD" = "xbfdd"])
1393
1394 if test $ac_cv_lib_json_c_json_object_get = no -a "x$BFDD" = "xbfdd"; then
1395   AC_MSG_ERROR(["you must use json-c library to use bfdd"])
1396 fi
1397
1398 NHRPD=""
1399 case "$host_os" in
1400   linux*)
1401     if test "${enable_nhrpd}" != "no"; then
1402       NHRPD="nhrpd"
1403     fi
1404     ;;
1405   *)
1406     if test "${enable_nhrpd}" = "yes"; then
1407       AC_MSG_ERROR([nhrpd requires kernel APIs that are only present on Linux.])
1408     fi
1409     ;;
1410 esac
1411 AM_CONDITIONAL(NHRPD, test "x$NHRPD" = "xnhrpd")
1412
1413 AM_CONDITIONAL(EIGRPD, test "${enable_eigrpd}" != "no")
1414
1415 if test "${enable_watchfrr}" = "no";then
1416   WATCHFRR=""
1417 else
1418   WATCHFRR="watchfrr"
1419 fi
1420 AM_CONDITIONAL(WATCHFRR, test "x$WATCHFRR" = "xwatchfrr")
1421
1422 OSPFCLIENT=""
1423 if test "${enable_ospfapi}" != "no";then
1424     AC_DEFINE(SUPPORT_OSPF_API,,OSPFAPI)
1425
1426   if test "${enable_ospfclient}" != "no";then
1427       OSPFCLIENT="ospfclient"
1428   fi
1429 fi
1430
1431 AM_CONDITIONAL(OSPFCLIENT, test "x$OSPFCLIENT" = "xospfclient")
1432 AM_CONDITIONAL(RIPNGD, test "${enable_ripngd}" != "no")
1433 AM_CONDITIONAL(BABELD, test "${enable_babeld}" != "no")
1434 AM_CONDITIONAL(OSPF6D, test "${enable_ospf6d}" != "no")
1435 AM_CONDITIONAL(ISISD, test "${enable_isisd}" != "no")
1436 AM_CONDITIONAL(PIMD, test "${enable_pimd}" != "no")
1437 AM_CONDITIONAL(PBRD, test "${enable_pbrd}" != "no")
1438 AM_CONDITIONAL(SHARPD, test "${enable_sharpd}" = "yes")
1439 AM_CONDITIONAL(STATICD, test "${enable_staticd}" != "no")
1440 AM_CONDITIONAL(FABRICD, test "${enable_fabricd}" != "no")
1441
1442 if test "${enable_bgp_announce}" = "no";then
1443   AC_DEFINE(DISABLE_BGP_ANNOUNCE,1,Disable BGP installation to zebra)
1444 else
1445   AC_DEFINE(DISABLE_BGP_ANNOUNCE,0,Disable BGP installation to zebra)
1446 fi
1447
1448 if test "${enable_bgp_vnc}" != "no";then
1449   AC_DEFINE(ENABLE_BGP_VNC,1,Enable BGP VNC support)
1450 fi
1451 AM_CONDITIONAL([ENABLE_BGP_VNC], [test x${enable_bgp_vnc} != xno])
1452
1453 AC_SUBST(SOLARIS)
1454 AC_SUBST(CURSES)
1455 AC_CHECK_LIB(crypt, crypt, [],
1456                     [AC_CHECK_LIB(crypto, DES_crypt)])
1457 AC_CHECK_LIB(resolv, res_init)
1458
1459 dnl ---------------------------
1460 dnl check system has PCRE regexp
1461 dnl ---------------------------
1462 if test "x$enable_pcreposix" = "xyes"; then
1463   AC_CHECK_LIB(pcreposix, regexec, [], [
1464     AC_MSG_ERROR([--enable-pcreposix given but unable to find libpcreposix])
1465   ])
1466 fi
1467 AC_SUBST(HAVE_LIBPCREPOSIX)
1468
1469 dnl ------------------
1470 dnl check C-Ares library
1471 dnl ------------------
1472 if test "${NHRPD}" != ""; then
1473   PKG_CHECK_MODULES([CARES], [libcares], , [
1474     AC_MSG_ERROR([trying to build nhrpd, but libcares not found. install c-ares and its -dev headers.])
1475   ])
1476 fi
1477
1478
1479 dnl ------------------
1480 dnl check Net-SNMP library
1481 dnl ------------------
1482 if test "${enable_snmp}" != "" -a "${enable_snmp}" != "no"; then
1483    AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], [no])
1484    if test x"$NETSNMP_CONFIG" = x"no"; then
1485       AC_MSG_ERROR([--enable-snmp given but unable to find net-snmp-config])
1486    fi
1487    SNMP_LIBS="`${NETSNMP_CONFIG} --agent-libs`"
1488    SNMP_CFLAGS="`${NETSNMP_CONFIG} --base-cflags`"
1489    AC_MSG_CHECKING([whether we can link to Net-SNMP])
1490    AC_LINK_IFELSE_FLAGS([$SNMP_CFLAGS], [$SNMP_LIBS], [AC_LANG_PROGRAM([
1491 int main(void);
1492 ],
1493 [
1494 {
1495   return 0;
1496 }
1497 ])], [
1498      AC_MSG_ERROR([--enable-snmp given but not usable])])
1499    case "${enable_snmp}" in
1500      yes)
1501       SNMP_METHOD=agentx
1502       ;;
1503      agentx)
1504       SNMP_METHOD="${enable_snmp}"
1505       ;;
1506      *)
1507       AC_MSG_ERROR([--enable-snmp given with an unknown method (${enable_snmp}). Use yes or agentx])
1508       ;;
1509    esac
1510    AH_TEMPLATE([SNMP_AGENTX], [Use SNMP AgentX to interface with snmpd])
1511    AC_DEFINE_UNQUOTED(AS_TR_CPP(SNMP_${SNMP_METHOD}),,SNMP method to interface with snmpd)
1512 fi
1513 AM_CONDITIONAL([SNMP], [test "x${SNMP_METHOD}" != "x"])
1514 AC_SUBST(SNMP_LIBS)
1515 AC_SUBST(SNMP_CFLAGS)
1516
1517 dnl ---------------
1518 dnl math
1519 dnl ---------------
1520 AC_SEARCH_LIBS([sqrt], [m])
1521
1522 dnl ---------------
1523 dnl dlopen & dlinfo
1524 dnl ---------------
1525 AC_SEARCH_LIBS(dlopen, [dl dld], [], [
1526   AC_MSG_ERROR([unable to find the dlopen()])
1527 ])
1528
1529 AC_CHECK_HEADERS([link.h])
1530
1531 AC_CACHE_CHECK([for dlinfo(RTLD_DI_ORIGIN)], [frr_cv_rtld_di_origin], [
1532   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1533 #include <stdlib.h>
1534 #ifdef HAVE_LINK_H
1535 #include <link.h>
1536 #endif
1537 #include <dlfcn.h>
1538 ]], [[
1539   char origin[1];
1540   dlinfo (NULL, RTLD_DI_ORIGIN, &origin);
1541 ]])], [
1542     frr_cv_rtld_di_origin=yes
1543   ], [
1544     frr_cv_rtld_di_origin=no
1545   ])
1546 ])
1547 if test "$frr_cv_rtld_di_origin" = yes; then
1548   AC_DEFINE(HAVE_DLINFO_ORIGIN, 1, [Have dlinfo RTLD_DI_ORIGIN])
1549 fi
1550
1551 AC_CACHE_CHECK([for dlinfo(RTLD_DI_LINKMAP)], [frr_cv_rtld_di_linkmap], [
1552   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1553 #include <stdlib.h>
1554 #ifdef HAVE_LINK_H
1555 #include <link.h>
1556 #endif
1557 #include <dlfcn.h>
1558 ]], [[
1559   struct link_map *lm = NULL;
1560   dlinfo (NULL, RTLD_DI_LINKMAP, &lm);
1561 ]])], [
1562     frr_cv_rtld_di_linkmap=yes
1563   ], [
1564     frr_cv_rtld_di_linkmap=no
1565   ])
1566 ])
1567 if test "$frr_cv_rtld_di_linkmap" = yes; then
1568   AC_DEFINE(HAVE_DLINFO_LINKMAP, 1, [Have dlinfo RTLD_DI_LINKMAP])
1569 fi
1570
1571 AM_CONDITIONAL(SNMP, test "x$SNMP_METHOD" = "xagentx")
1572
1573 dnl ---------------------------
1574 dnl sockaddr and netinet checks
1575 dnl ---------------------------
1576 AC_CHECK_TYPES([
1577         struct sockaddr_dl,
1578         struct vifctl, struct mfcctl, struct sioc_sg_req,
1579         vifi_t, struct sioc_vif_req, struct igmpmsg,
1580         struct ifaliasreq, struct if6_aliasreq, struct in6_aliasreq,
1581         struct nd_opt_adv_interval, struct rt_addrinfo,
1582         struct nd_opt_homeagent_info, struct nd_opt_adv_interval],
1583         [], [], FRR_INCLUDES)
1584
1585 AC_CHECK_MEMBERS([struct sockaddr.sa_len,
1586         struct sockaddr_in.sin_len, struct sockaddr_un.sun_len,
1587         struct sockaddr_dl.sdl_len,
1588         struct if6_aliasreq.ifra_lifetime,
1589         struct nd_opt_adv_interval.nd_opt_ai_type],
1590         [], [], FRR_INCLUDES)
1591
1592 dnl ---------------------------
1593 dnl IRDP/pktinfo/icmphdr checks
1594 dnl ---------------------------
1595
1596 AC_CHECK_TYPES([struct in_pktinfo], [
1597   AC_CHECK_TYPES([struct icmphdr], [
1598     IRDP=true
1599   ], [
1600     IRDP=false
1601   ], [FRR_INCLUDES])
1602 ], [
1603   IRDP=false
1604 ], [FRR_INCLUDES])
1605
1606 case "${enable_irdp}" in
1607 yes)
1608   $IRDP || AC_MSG_ERROR(['IRDP requires in_pktinfo at the moment!'])
1609   ;;
1610 no)
1611   IRDP=false
1612   ;;
1613 esac
1614
1615 AM_CONDITIONAL(IRDP, $IRDP)
1616
1617 dnl -----------------------
1618 dnl checking for IP_PKTINFO
1619 dnl -----------------------
1620 AC_MSG_CHECKING(for IP_PKTINFO)
1621 AC_TRY_COMPILE([#include <netdb.h>], [
1622   int opt = IP_PKTINFO;
1623 ], [
1624   AC_MSG_RESULT(yes)
1625   AC_DEFINE(HAVE_IP_PKTINFO, 1, [Have IP_PKTINFO])
1626 ], [
1627   AC_MSG_RESULT(no)
1628 ])
1629
1630 dnl ---------------------------
1631 dnl checking for IP_RECVDSTADDR
1632 dnl ---------------------------
1633 AC_MSG_CHECKING(for IP_RECVDSTADDR)
1634 AC_TRY_COMPILE([#include <netinet/in.h>], [
1635   int opt = IP_RECVDSTADDR;
1636 ], [
1637   AC_MSG_RESULT(yes)
1638   AC_DEFINE(HAVE_IP_RECVDSTADDR, 1, [Have IP_RECVDSTADDR])
1639 ], [
1640   AC_MSG_RESULT(no)
1641 ])
1642
1643 dnl ----------------------
1644 dnl checking for IP_RECVIF
1645 dnl ----------------------
1646 AC_MSG_CHECKING(for IP_RECVIF)
1647 AC_TRY_COMPILE([#include <netinet/in.h>], [
1648   int opt = IP_RECVIF;
1649 ], [
1650   AC_MSG_RESULT(yes)
1651   AC_DEFINE(HAVE_IP_RECVIF, 1, [Have IP_RECVIF])
1652 ], [
1653   AC_MSG_RESULT(no)
1654 ])
1655
1656 dnl ----------------------
1657 dnl checking for SO_BINDANY
1658 dnl ----------------------
1659 AC_MSG_CHECKING(for SO_BINDANY)
1660 AC_TRY_COMPILE([#include <sys/socket.h>], [
1661   int opt = SO_BINDANY;
1662 ], [
1663   AC_MSG_RESULT(yes)
1664   AC_DEFINE(HAVE_SO_BINDANY, 1, [Have SO_BINDANY])
1665 ], [
1666   AC_MSG_RESULT(no)
1667 ])
1668
1669 dnl ----------------------
1670 dnl checking for IP_FREEBIND
1671 dnl ----------------------
1672 AC_MSG_CHECKING(for IP_FREEBIND)
1673 AC_TRY_COMPILE([#include <netinet/in.h>], [
1674   int opt = IP_FREEBIND;
1675 ], [
1676   AC_MSG_RESULT(yes)
1677   AC_DEFINE(HAVE_IP_FREEBIND, 1, [Have IP_FREEBIND])
1678 ], [
1679   AC_MSG_RESULT(no)
1680 ])
1681
1682 dnl --------------------------------------
1683 dnl checking for be32dec existence or not
1684 dnl --------------------------------------
1685 AC_CHECK_DECLS([be32enc, be32dec], [], [],
1686                [#include <sys/endian.h>])
1687
1688 dnl --------------------------------------
1689 dnl checking for clock_time monotonic struct and call
1690 dnl --------------------------------------
1691 AC_CHECK_DECL(CLOCK_MONOTONIC,
1692         [AC_CHECK_LIB(rt, clock_gettime, [LIBS="$LIBS -lrt"])
1693          AC_DEFINE(HAVE_CLOCK_MONOTONIC,, Have monotonic clock)
1694 ], [AC_MSG_RESULT(no)], [FRR_INCLUDES])
1695
1696 dnl --------------------------------------
1697 dnl checking for flex and bison
1698 dnl --------------------------------------
1699
1700 AM_PROG_LEX
1701 AC_MSG_CHECKING(version of flex)
1702 frr_ac_flex_version="$(eval $LEX -V | grep flex | head -n 1)"
1703 frr_ac_flex_version="${frr_ac_flex_version##* }"
1704 AC_MSG_RESULT([$frr_ac_flex_version])
1705 AX_COMPARE_VERSION([$frr_ac_flex_version], [lt], [2.5.20], [
1706   LEX="$SHELL $missing_dir/missing flex"
1707   if test -f "${srcdir}/lib/command_lex.c" -a -f "${srcdir}/lib/command_lex.h"; then
1708     AC_MSG_WARN([using pregenerated flex output files])
1709   else
1710     AC_MSG_ERROR([flex failure and pregenerated files not included (probably a git build)])
1711   fi
1712   AC_SUBST([LEX_OUTPUT_ROOT], [lex.yy])
1713   AC_SUBST([LEXLIB], [''])
1714 ])
1715
1716 AC_PROG_YACC
1717 dnl thanks GNU bison for this b*llshit...
1718 AC_MSG_CHECKING(version of bison)
1719 frr_ac_bison_version="$(eval $YACC -V | grep bison | head -n 1)"
1720 frr_ac_bison_version="${frr_ac_bison_version##* }"
1721 frr_ac_bison_missing="false"
1722 case "x${frr_ac_bison_version}" in
1723   x2.7*)
1724     BISON_OPENBRACE='"'
1725     BISON_CLOSEBRACE='"'
1726     BISON_VERBOSE=''
1727     AC_MSG_RESULT([$frr_ac_bison_version - 2.7 or older])
1728     ;;
1729   x2.*|x1.*)
1730     AC_MSG_RESULT([$frr_ac_bison_version])
1731     AC_MSG_WARN([installed bison is too old.  Please install GNU bison 2.7.x or newer.])
1732     frr_ac_bison_missing="true"
1733     ;;
1734   x)
1735     AC_MSG_RESULT([none])
1736     AC_MSG_WARN([could not determine bison version.  Please install GNU bison 2.7.x or newer.])
1737     frr_ac_bison_missing="true"
1738     ;;
1739   *)
1740     BISON_OPENBRACE='{'
1741     BISON_CLOSEBRACE='}'
1742     BISON_VERBOSE='-Dparse.error=verbose'
1743     AC_MSG_RESULT([$frr_ac_bison_version - 3.0 or newer])
1744     ;;
1745 esac
1746 AC_SUBST(BISON_OPENBRACE)
1747 AC_SUBST(BISON_CLOSEBRACE)
1748 AC_SUBST(BISON_VERBOSE)
1749
1750 if $frr_ac_bison_missing; then
1751   YACC="$SHELL $missing_dir/missing bison -y"
1752   if test -f "${srcdir}/lib/command_parse.c" -a -f "${srcdir}/lib/command_parse.h"; then
1753     AC_MSG_WARN([using pregenerated bison output files])
1754   else
1755     AC_MSG_ERROR([bison failure and pregenerated files not included (probably a git build)])
1756   fi
1757 fi
1758
1759 dnl -------------------
1760 dnl capabilities checks
1761 dnl -------------------
1762 if test "${enable_capabilities}" != "no"; then
1763   AC_MSG_CHECKING(whether prctl PR_SET_KEEPCAPS is available)
1764   AC_TRY_COMPILE([#include <sys/prctl.h>],[prctl(PR_SET_KEEPCAPS, 1, 0, 0, 0);],
1765     [AC_MSG_RESULT(yes)
1766      AC_DEFINE(HAVE_PR_SET_KEEPCAPS,,prctl)
1767      frr_ac_keepcaps="yes"],
1768      AC_MSG_RESULT(no)
1769   )
1770   if test x"${frr_ac_keepcaps}" = x"yes"; then
1771     AC_CHECK_HEADERS(sys/capability.h)
1772   fi
1773   if test x"${ac_cv_header_sys_capability_h}" = x"yes"; then
1774     AC_CHECK_LIB(cap, cap_init,
1775       [AC_DEFINE(HAVE_LCAPS,1,Capabilities)
1776        LIBCAP="-lcap"
1777        frr_ac_lcaps="yes"]
1778     )
1779   else
1780     AC_CHECK_HEADERS(priv.h,
1781      [AC_MSG_CHECKING(Solaris style privileges are available)
1782       AC_TRY_COMPILE([#include <priv.h>],[getpflags(PRIV_AWARE);],
1783           [AC_MSG_RESULT(yes)
1784            AC_DEFINE(HAVE_SOLARIS_CAPABILITIES,1,getpflags)
1785            frr_ac_scaps="yes"],
1786            AC_MSG_RESULT(no)
1787       )
1788      ]
1789    )
1790   fi
1791   if test x"${frr_ac_scaps}" = x"yes" \
1792        -o x"${frr_ac_lcaps}" = x"yes"; then
1793     AC_DEFINE(HAVE_CAPABILITIES,1,capabilities)
1794   fi
1795 fi
1796 AC_SUBST(LIBCAP)
1797
1798 dnl ---------------------------
1799 dnl check for glibc 'backtrace'
1800 dnl ---------------------------
1801 if test x"${enable_backtrace}" != x"no" ; then
1802   backtrace_ok=no
1803   AC_CHECK_HEADER([execinfo.h], [
1804     AC_SEARCH_LIBS([backtrace], [execinfo], [
1805       AC_DEFINE(HAVE_GLIBC_BACKTRACE,,[Glibc backtrace])
1806       AC_DEFINE(HAVE_STACK_TRACE,,[Stack symbol decoding])
1807       backtrace_ok=yes
1808     ],, [-lm])
1809   ])
1810
1811   if test x"${enable_backtrace}" = x"yes" -a x"${backtrace_ok}" = x"no"; then
1812     dnl user explicitly requested backtrace but we failed to find support
1813     AC_MSG_FAILURE([failed to find backtrace support])
1814   fi
1815 fi
1816
1817 dnl -----------------------------------------
1818 dnl check for malloc mallinfo struct and call
1819 dnl this must try and link using LIBS, in
1820 dnl order to check no alternative allocator
1821 dnl has been specified, which might not provide
1822 dnl mallinfo, e.g. such as Umem on Solaris.
1823 dnl -----------------------------------------
1824 AC_CHECK_HEADERS([malloc.h malloc_np.h malloc/malloc.h],,, [FRR_INCLUDES])
1825
1826 AC_CACHE_CHECK([whether mallinfo is available], [frr_cv_mallinfo], [
1827   AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
1828 #ifdef HAVE_MALLOC_H
1829 #include <malloc.h>
1830 #endif
1831 #ifdef HAVE_MALLOC_NP_H
1832 #include <malloc_np.h>
1833 #endif
1834 #ifdef HAVE_MALLOC_MALLOC_H
1835 #include <malloc/malloc.h>
1836 #endif
1837 ]], [[
1838 struct mallinfo ac_x; ac_x = mallinfo ();
1839 ]])], [
1840     frr_cv_mallinfo=yes
1841   ], [
1842     frr_cv_mallinfo=no
1843   ])
1844 ])
1845 if test "$frr_cv_mallinfo" = yes; then
1846   AC_DEFINE(HAVE_MALLINFO,,mallinfo)
1847 fi
1848
1849 AC_MSG_CHECKING(whether malloc_usable_size is available)
1850 AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
1851 #ifdef HAVE_MALLOC_H
1852 #include <malloc.h>
1853 #endif
1854 #ifdef HAVE_MALLOC_MALLOC_H
1855 #include <malloc/malloc.h>
1856 #endif
1857 ]], [[
1858 size_t ac_x; ac_x = malloc_usable_size(NULL);
1859 ]])], [
1860   AC_MSG_RESULT(yes)
1861   AC_DEFINE(HAVE_MALLOC_USABLE_SIZE,,malloc_usable_size)
1862 ], [
1863   AC_MSG_RESULT(no)
1864
1865   AC_MSG_CHECKING(whether malloc_size is available)
1866   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1867 #ifdef HAVE_MALLOC_H
1868 #include <malloc.h>
1869 #endif
1870 #ifdef HAVE_MALLOC_MALLOC_H
1871 #include <malloc/malloc.h>
1872 #endif
1873 ]], [[
1874 size_t ac_x; ac_x = malloc_size(NULL);
1875 ]])], [
1876     AC_MSG_RESULT(yes)
1877     AC_DEFINE(HAVE_MALLOC_SIZE,,malloc_size)
1878   ], [
1879     AC_MSG_RESULT(no)
1880   ])
1881 ])
1882
1883 dnl ------
1884 dnl ZeroMQ
1885 dnl ------
1886 if test "x$enable_zeromq" != "xno"; then
1887   PKG_CHECK_MODULES(ZEROMQ, [libzmq >= 4.0.0], [
1888     AC_DEFINE(HAVE_ZEROMQ, 1, [Enable ZeroMQ support])
1889     ZEROMQ=true
1890   ], [
1891     if test "x$enable_zeromq" = "xyes"; then
1892       AC_MSG_ERROR([configuration specifies --enable-zeromq but libzmq was not found])
1893     fi
1894   ])
1895 fi
1896 AM_CONDITIONAL([ZEROMQ], test "x$ZEROMQ" = "xtrue")
1897
1898 dnl ----------
1899 dnl configure date
1900 dnl ----------
1901 dev_version=`echo $VERSION | grep dev`
1902 #don't expire deprecated code in non 'dev' branch
1903 if test "${dev_version}" = ""; then
1904    CONFDATE=0
1905 else
1906    CONFDATE=`date '+%Y%m%d'`
1907 fi
1908 AC_SUBST(CONFDATE)
1909
1910 dnl ------------------------------
1911 dnl set paths for state directory
1912 dnl ------------------------------
1913 AC_MSG_CHECKING(directory to use for state file)
1914 if test "${prefix}" = "NONE"; then
1915   frr_statedir_prefix="";
1916 else
1917   frr_statedir_prefix=${prefix}
1918 fi
1919 if test "${localstatedir}" = '${prefix}/var'; then
1920   for FRR_STATE_DIR in ${frr_statedir_prefix}/var/run dnl
1921                         ${frr_statedir_prefix}/var/adm dnl
1922                         ${frr_statedir_prefix}/etc dnl
1923                         /var/run        dnl
1924                         /var/adm        dnl
1925                         /etc            dnl
1926                         /dev/null;
1927   do
1928     test -d $FRR_STATE_DIR && break
1929   done
1930   frr_statedir=$FRR_STATE_DIR
1931 else
1932   frr_statedir=${localstatedir}
1933 fi
1934 if test $frr_statedir = "/dev/null"; then
1935     AC_MSG_ERROR('STATE DIRECTORY NOT FOUND! FIX OR SPECIFY --localstatedir!')
1936 fi
1937 AC_MSG_RESULT(${frr_statedir})
1938 AC_SUBST(frr_statedir)
1939
1940 AC_DEFINE_UNQUOTED(LDPD_SOCKET, "$frr_statedir/ldpd.sock",ldpd control socket)
1941 AC_DEFINE_UNQUOTED(ZEBRA_SERV_PATH, "$frr_statedir/zserv.api",zebra api socket)
1942 AC_DEFINE_UNQUOTED(BFDD_CONTROL_SOCKET, "$frr_statedir/bfdd.sock", bfdd control socket)
1943 AC_DEFINE_UNQUOTED(DAEMON_VTY_DIR, "$frr_statedir",daemon vty directory)
1944
1945 dnl autoconf does this, but it does it too late...
1946 test "x$prefix" = xNONE && prefix=$ac_default_prefix
1947 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
1948
1949 dnl get the full path, recursing through variables...
1950 vtysh_bin="$bindir/vtysh"
1951 for I in 1 2 3 4 5 6 7 8 9 10; do
1952         eval vtysh_bin="\"$vtysh_bin\""
1953 done
1954 AC_DEFINE_UNQUOTED(VTYSH_BIN_PATH, "$vtysh_bin",path to vtysh binary)
1955 AC_SUBST(vtysh_bin)
1956
1957 CFG_SYSCONF="$sysconfdir"
1958 CFG_SBIN="$sbindir"
1959 CFG_STATE="$frr_statedir"
1960 CFG_MODULE="$moduledir"
1961 for I in 1 2 3 4 5 6 7 8 9 10; do
1962         eval CFG_SYSCONF="\"$CFG_SYSCONF\""
1963         eval CFG_SBIN="\"$CFG_SBIN\""
1964         eval CFG_STATE="\"$CFG_STATE\""
1965         eval CFG_MODULE="\"$CFG_MODULE\""
1966 done
1967 AC_SUBST(CFG_SYSCONF)
1968 AC_SUBST(CFG_SBIN)
1969 AC_SUBST(CFG_STATE)
1970 AC_SUBST(CFG_MODULE)
1971 AC_DEFINE_UNQUOTED(MODULE_PATH, "$CFG_MODULE", path to modules)
1972
1973 dnl ------------------------------------
1974 dnl Enable RPKI and add librtr to libs
1975 dnl ------------------------------------
1976 if test "${enable_rpki}" = "yes"; then
1977   PKG_CHECK_MODULES(RTRLIB,[rtrlib >= 0.5.0],
1978       [RPKI=true],
1979       [RPKI=false
1980       AC_MSG_ERROR([rtrlib was not found on your system or is too old.])]
1981   )
1982 fi
1983 AM_CONDITIONAL([RPKI], test "x$RPKI" = "xtrue")
1984
1985 dnl ------------------------------------------
1986 dnl Check whether rtrlib was build with ssh support
1987 dnl ------------------------------------------
1988 AC_MSG_CHECKING([whether the RTR Library is compiled with SSH])
1989 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "rtrlib/rtrlib.h"]],
1990                         [[struct tr_ssh_config config;]])],
1991         [AC_MSG_RESULT(yes)
1992         AC_DEFINE(FOUND_SSH,,found_ssh)],
1993         AC_MSG_RESULT(no)
1994 )
1995
1996 dnl ---------------------------
1997 dnl Check htonl works correctly
1998 dnl ---------------------------
1999 AC_MSG_CHECKING(for working htonl)
2000 AC_CACHE_VAL(ac_cv_htonl_works,
2001  [AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES],[htonl (0);])],
2002                 [ac_cv_htonl_works=yes], [ac_cv_htonl_works=no])
2003  ]
2004 )
2005 AC_MSG_RESULT($ac_cv_htonl_works)
2006
2007 AC_CONFIG_FILES([Makefile],[sed -e 's/^#AUTODERP# //' -i Makefile])
2008
2009 AC_CONFIG_FILES([
2010           redhat/frr.spec
2011           solaris/Makefile
2012           debianpkg/changelog
2013           alpine/APKBUILD
2014           snapcraft/snapcraft.yaml
2015           lib/version.h
2016           tests/lib/cli/test_cli.refout
2017           pkgsrc/bgpd.sh pkgsrc/ospf6d.sh pkgsrc/ospfd.sh
2018           pkgsrc/ripd.sh pkgsrc/ripngd.sh pkgsrc/zebra.sh
2019           pkgsrc/eigrpd.sh])
2020
2021 AC_CONFIG_FILES([vtysh/extract.pl],[chmod +x vtysh/extract.pl])
2022 AC_CONFIG_FILES([tools/frr],[chmod +x tools/frr])
2023
2024 AC_CONFIG_COMMANDS([lib/route_types.h], [
2025         dst="${ac_abs_top_builddir}/lib/route_types.h"
2026         ${PERL} "${ac_abs_top_srcdir}/lib/route_types.pl" \
2027                 < "${ac_abs_top_srcdir}/lib/route_types.txt" \
2028                 > "${dst}.tmp"
2029         test -f "${dst}" \
2030                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
2031                 && rm "${dst}.tmp" \
2032                 || mv "${dst}.tmp" "${dst}"
2033 ], [
2034         PERL="$PERL"
2035 ])
2036
2037 AS_IF([test "x$with_pkg_git_version" = "xyes"], [
2038     AC_CONFIG_COMMANDS([lib/gitversion.h], [
2039         dst="${ac_abs_top_builddir}/lib/gitversion.h"
2040         ${PERL} "${ac_abs_top_srcdir}/lib/gitversion.pl" \
2041                 "${ac_abs_top_srcdir}" \
2042                 > "${dst}.tmp"
2043         test -f "${dst}" \
2044                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
2045                 && rm "${dst}.tmp" \
2046                 || mv "${dst}.tmp" "${dst}"
2047     ], [
2048         PERL="$PERL"
2049     ])
2050 ])
2051
2052 ## Hack, but working solution to avoid rebuilding of frr.info.
2053 ## It's already in CVS until texinfo 4.7 is more common.
2054 AC_OUTPUT
2055
2056 echo "
2057 FRRouting configuration
2058 ------------------------------
2059 FRR version             : ${PACKAGE_VERSION}
2060 host operating system   : ${host_os}
2061 source code location    : ${srcdir}
2062 compiler                : ${CC}
2063 compiler flags          : ${CFLAGS} ${SAN_FLAGS}
2064 make                    : ${MAKE-make}
2065 linker flags            : ${LDFLAGS} ${SAN_FLAGS} ${LIBS} ${LIBCAP} ${LIBREADLINE} ${LIBM}
2066 state file directory    : ${frr_statedir}
2067 config file directory   : `eval echo \`echo ${sysconfdir}\``
2068 example directory       : `eval echo \`echo ${exampledir}\``
2069 module directory        : ${CFG_MODULE}
2070 user to run as          : ${enable_user}
2071 group to run as         : ${enable_group}
2072 group for vty sockets   : ${enable_vty_group}
2073 config file mask        : ${enable_configfile_mask}
2074 log file mask           : ${enable_logfile_mask}
2075 zebra protobuf enabled  : ${enable_protobuf:-no}
2076
2077 The above user and group must have read/write access to the state file
2078 directory and to the config files in the config file directory."
2079
2080 if test "${enable_doc}" != "no";then
2081   AS_IF([test "$SPHINXBUILD" = /bin/false],
2082      AC_MSG_WARN(sphinx-build is missing but required to build documentation))
2083 fi