configure.ac

   1 ##
   2 ## Configure template file for FRRouting.
   3 ## autoconf will generate configure script.
   4 ##
   5 ##  Copyright (c) 1996, 97, 98, 99, 2000 Kunihiro Ishiguro <kunihiro@zebra.org>
   6 ##  Portions Copyright (c) 2003 Paul Jakma <paul@dishone.st>
   7 ##
   8 AC_PREREQ(2.60)
   9
  10 AC_INIT(frr, 3.1-dev, [https://github.com/frrouting/frr/issues])
  11 PACKAGE_URL="https://frrouting.org/"
  12 PACKAGE_FULLNAME="FRRouting"
  13 AC_SUBST(PACKAGE_FULLNAME)
  14
  15 CONFIG_ARGS="$ac_configure_args"
  16 AC_SUBST(CONFIG_ARGS)
  17
  18 AC_CONFIG_SRCDIR(lib/zebra.h)
  19 AC_CONFIG_MACRO_DIR([m4])
  20
  21 dnl -----------------------------------
  22 dnl Get hostname and other information.
  23 dnl -----------------------------------
  24 AC_CANONICAL_BUILD()
  25 AC_CANONICAL_HOST()
  26
  27 AS_IF([test "$host" != "$build"], [
  28   if test "$srcdir" = "."; then
  29     AC_MSG_ERROR([cross-compilation is only possible with builddir separate from srcdir.  create a separate directory and run as .../path-to-frr/configure.])
  30   fi
  31   test -d hosttools || mkdir hosttools
  32   abssrc="`cd \"${srcdir}\"; pwd`"
  33
  34   AC_MSG_NOTICE([...])
  35   AC_MSG_NOTICE([... cross-compilation: creating hosttools directory and self-configuring for build platform tools])
  36   AC_MSG_NOTICE([... use HOST_CPPFLAGS / HOST_CFLAGS / HOST_LDFLAGS if neccessary])
  37   AC_MSG_NOTICE([...])
  38
  39   ( CPPFLAGS="$HOST_CPPFLAGS"; \
  40     CFLAGS="$HOST_CFLAGS"; \
  41     LDFLAGS="$HOST_LDFLAGS"; \
  42     cd hosttools; "${abssrc}/configure" "--host=$build" "--build=$build"; )
  43
  44   AC_MSG_NOTICE([...])
  45   AC_MSG_NOTICE([... cross-compilation: finished self-configuring for build platform tools])
  46   AC_MSG_NOTICE([...])
  47
  48   build_clippy="false"
  49   CLIPPYDIR="hosttools/lib"
  50 ], [
  51   build_clippy="true"
  52   CLIPPYDIR="lib"
  53 ])
  54 AC_SUBST(CLIPPYDIR)
  55 AM_CONDITIONAL([BUILD_CLIPPY], [$build_clippy])
  56
  57 # Disable portability warnings -- our automake code (in particular
  58 # common.am) uses some constructs specific to gmake.
  59 AM_INIT_AUTOMAKE([1.12 -Wno-portability])
  60 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
  61 AM_SILENT_RULES([yes])
  62 AC_CONFIG_HEADERS(config.h)
  63
  64 AC_PATH_PROG(PERL, perl)
  65 PKG_PROG_PKG_CONFIG
  66
  67 dnl default is to match previous behavior
  68 exampledir=${sysconfdir}
  69 AC_ARG_ENABLE([exampledir],
  70           AS_HELP_STRING([--enable-exampledir],
  71                          [specify alternate directory for examples]),
  72                          exampledir="$enableval",)
  73 dnl XXX add --exampledir to autoconf standard directory list somehow
  74 AC_SUBST(exampledir)
  75
  76 dnl default is to match previous behavior
  77 pkgsrcrcdir=""
  78 pkgsrcdir=""
  79 AC_ARG_ENABLE([pkgsrcrcdir],
  80           AS_HELP_STRING([--enable-pkgsrcrcdir],
  81                          [specify directory for rc.d scripts]),
  82                          pkgsrcrcdir="$enableval"; pkgsrcdir="pkgsrc",)
  83 dnl XXX add --pkgsrcrcdir to autoconf standard directory list somehow
  84 AC_SUBST(pkgsrcdir)
  85 AC_SUBST(pkgsrcrcdir)
  86
  87 AC_ARG_WITH([moduledir], [AS_HELP_STRING([--with-moduledir=DIR], [module directory (${libdir}/frr/modules)])], [
  88         moduledir="$withval"
  89 ], [
  90         moduledir="\${libdir}/frr/modules"
  91 ])
  92 AC_SUBST([moduledir], [$moduledir])
  93
  94 AC_ARG_ENABLE(tcmalloc,
  95         AS_HELP_STRING([--enable-tcmalloc], [Turn on tcmalloc]),
  96 [case "${enableval}" in
  97   yes) tcmalloc_enabled=true
  98 LIBS="$LIBS -ltcmalloc_minimal"
  99  ;;
 100   no)  tcmalloc_enabled=false ;;
 101   *) AC_MSG_ERROR(bad value ${enableval} for --enable-tcmalloc) ;;
 102 esac],[tcmalloc_enabled=false])
 103
 104
 105 dnl Thanks autoconf, but we don't want a default -g -O2.  We have our own
 106 dnl flag determination logic.
 107 CFLAGS="${CFLAGS:-}"
 108
 109 dnl --------------------
 110 dnl Check CC and friends
 111 dnl --------------------
 112 dnl note orig_cflags is also used further down
 113 orig_cflags="$CFLAGS"
 114 AC_LANG([C])
 115 AC_PROG_CC
 116 AC_PROG_CPP
 117 AM_PROG_CC_C_O
 118 dnl remove autoconf default "-g -O2"
 119 CFLAGS="$orig_cflags"
 120 AC_PROG_CC_C99
 121 dnl NB: see C11 below
 122
 123 AC_PROG_EGREP
 124 PKG_PROG_PKG_CONFIG
 125
 126 dnl autoconf 2.59 appears not to support AC_PROG_SED
 127 dnl AC_PROG_SED
 128 AC_CHECK_PROG([SED],[sed],[sed],[/bin/false])
 129
 130 dnl try and enable CFLAGS that are useful for FRR
 131 dnl - specifically, options to control warnings
 132
 133 AC_USE_SYSTEM_EXTENSIONS
 134 AC_DEFUN([AC_C_FLAG], [{
 135         AC_LANG_PUSH(C)
 136         ac_c_flag_save="$CFLAGS"
 137         CFLAGS="$CFLAGS $1"
 138         AC_MSG_CHECKING([[whether $CC supports $1]])
 139         AC_COMPILE_IFELSE(
 140                 [AC_LANG_PROGRAM([[]])],
 141                 [
 142                         AC_MSG_RESULT([yes])
 143                         m4_if([$3], [], [], [
 144                                 CFLAGS="$ac_c_flag_save"
 145                                 $3
 146                         ])
 147                 ], [
 148                         CFLAGS="$ac_c_flag_save"
 149                         AC_MSG_RESULT([no])
 150                         $2
 151                 ])
 152         AC_LANG_POP(C)
 153         }])
 154
 155 AC_DEFUN([AC_LINK_IFELSE_FLAGS], [{
 156         AC_LANG_PUSH(C)
 157         ac_cflags_save="$CFLAGS"
 158         ac_libs_save="$LIBS"
 159         CFLAGS="$CFLAGS $1"
 160         LIBS="$LIBS $2"
 161         AC_LINK_IFELSE(
 162                 [$3],
 163                 [
 164                         AC_MSG_RESULT([yes])
 165                         CFLAGS="$ac_cflags_save"
 166                         LIBS="$ac_libs_save"
 167                         $5
 168                 ], [
 169                         AC_MSG_RESULT([no])
 170                         CFLAGS="$ac_cflags_save"
 171                         LIBS="$ac_libs_save"
 172                         $4
 173                 ])
 174         AC_LANG_POP(C)
 175         }])
 176
 177 dnl ICC won't bail on unknown options without -diag-error 10006
 178 dnl need to do this first so we get useful results for the other options
 179 AC_C_FLAG([-diag-error 10006])
 180
 181 dnl AC_PROG_CC_C99 may change CC to include -std=gnu99 or something
 182 ac_cc="$CC"
 183 CC="${CC% -std=gnu99}"
 184 CC="${CC% -std=c99}"
 185
 186 AC_C_FLAG([-std=gnu11], [CC="$ac_cc"], [CC="$CC -std=gnu11"])
 187
 188 dnl if the user specified any CFLAGS, we don't add "-g -Os/-O2" here
 189 if test "z$orig_cflags" = "z"; then
 190   AC_C_FLAG([-g])
 191   AC_C_FLAG([-Os], [
 192     AC_C_FLAG([-O2])
 193   ])
 194 fi
 195
 196 dnl always want these CFLAGS
 197 AC_C_FLAG([-fno-omit-frame-pointer])
 198 AC_C_FLAG([-Wall])
 199 AC_C_FLAG([-Wextra])
 200 AC_C_FLAG([-Wmissing-prototypes])
 201 AC_C_FLAG([-Wmissing-declarations])
 202 AC_C_FLAG([-Wpointer-arith])
 203 AC_C_FLAG([-Wbad-function-cast])
 204 AC_C_FLAG([-Wwrite-strings])
 205 if test x"${enable_gcc_ultra_verbose}" = x"yes" ; then
 206   AC_C_FLAG([-Wcast-qual])
 207   AC_C_FLAG([-Wstrict-prototypes])
 208   AC_C_FLAG([-Wmissing-noreturn])
 209   AC_C_FLAG([-Wmissing-format-attribute])
 210   AC_C_FLAG([-Wunreachable-code])
 211   AC_C_FLAG([-Wpacked])
 212   AC_C_FLAG([-Wpadded])
 213 else
 214   AC_C_FLAG([-Wno-unused-result])
 215 fi
 216 AC_C_FLAG([-Wno-unused-parameter])
 217 AC_C_FLAG([-Wno-missing-field-initializers])
 218
 219 dnl ICC emits a broken warning for const char *x = a ? "b" : "c";
 220 dnl for some reason the string consts get 'promoted' to char *,
 221 dnl triggering a const to non-const conversion warning.
 222 AC_C_FLAG([-diag-disable 3179])
 223
 224 if test x"${enable_werror}" = x"yes" ; then
 225   WERROR="-Werror"
 226 fi
 227 AC_SUBST(WERROR)
 228
 229 dnl need link on this one, not compile
 230 AC_LANG_PUSH(C)
 231 ac_ld_flag_save="$LDFLAGS"
 232 LDFLAGS="$LDFLAGS -rdynamic"
 233 AC_MSG_CHECKING([[whether linker supports -rdynamic]])
 234 AC_LINK_IFELSE(
 235         [AC_LANG_PROGRAM([[]])],
 236         [AC_MSG_RESULT([yes])],
 237         [
 238                 LDFLAGS="$ac_ld_flag_save"
 239                 AC_MSG_RESULT([no])
 240         ])
 241 AC_LANG_POP(C)
 242
 243 dnl ----------
 244 dnl Essentials
 245 dnl ----------
 246
 247 AX_PTHREAD([
 248   CC="$PTHREAD_CC"
 249   CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 250   LIBS="$PTHREAD_LIBS $LIBS"
 251 ], [
 252   AC_MSG_FAILURE([This FRR version needs pthreads])
 253 ])
 254
 255 dnl --------------
 256 dnl Check programs
 257 dnl --------------
 258 AC_PROG_INSTALL
 259 AC_PROG_LN_S
 260 AC_PROG_MAKE_SET
 261 AC_CHECK_TOOL(AR, ar)
 262
 263 dnl -----------------
 264 dnl System extensions
 265 dnl -----------------
 266 AC_GNU_SOURCE
 267
 268 dnl -------
 269 dnl libtool
 270 dnl -------
 271 LT_INIT
 272
 273 dnl ----------------------
 274 dnl Packages configuration
 275 dnl ----------------------
 276 AC_ARG_WITH(pkg-extra-version,
 277         AS_HELP_STRING([--with-pkg-extra-version=VER], [add extra version field, for packagers/distributions]),
 278         [EXTRAVERSION=$withval],)
 279 AC_ARG_WITH(pkg-git-version,
 280         AS_HELP_STRING([--with-pkg-git-version], [add git information to MOTD and build version string]),
 281         [ test "x$withval" != "xno" && with_pkg_git_version="yes" ])
 282 AC_ARG_WITH(vtysh_pager,
 283         AS_HELP_STRING([--with-vtysh-pager=PAGER], [control what pager is compiled in as default]),
 284         VTYSH_PAGER=$withval, VTYSH_PAGER="more")
 285 AC_ARG_ENABLE(vtysh,
 286   AS_HELP_STRING([--disable-vtysh], [do not build integrated vty shell for FRR]))
 287 AC_ARG_ENABLE(doc,
 288   AS_HELP_STRING([--disable-doc], [do not build docs]))
 289 AC_ARG_ENABLE(zebra,
 290   AS_HELP_STRING([--disable-zebra], [do not build zebra daemon]))
 291 AC_ARG_ENABLE(bgpd,
 292   AS_HELP_STRING([--disable-bgpd], [do not build bgpd]))
 293 AC_ARG_ENABLE(ripd,
 294   AS_HELP_STRING([--disable-ripd], [do not build ripd]))
 295 AC_ARG_ENABLE(ripngd,
 296   AS_HELP_STRING([--disable-ripngd], [do not build ripngd]))
 297 AC_ARG_ENABLE(ospfd,
 298   AS_HELP_STRING([--disable-ospfd], [do not build ospfd]))
 299 AC_ARG_ENABLE(ospf6d,
 300   AS_HELP_STRING([--disable-ospf6d], [do not build ospf6d]))
 301 AC_ARG_ENABLE(ldpd,
 302   AS_HELP_STRING([--enable-ldpd], [build ldpd]))
 303 AC_ARG_ENABLE(nhrpd,
 304   AS_HELP_STRING([--disable-nhrpd], [do not build nhrpd]))
 305 AC_ARG_ENABLE(eigrpd,
 306   AS_HELP_STRING([--disable-eigrpd], [do not build eigrpd]))
 307 AC_ARG_ENABLE(babeld,
 308   AS_HELP_STRING([--disable-babeld], [do not build babeld]))
 309 AC_ARG_ENABLE(watchfrr,
 310   AS_HELP_STRING([--disable-watchfrr], [do not build watchfrr]))
 311 AC_ARG_ENABLE(isisd,
 312   AS_HELP_STRING([--disable-isisd], [do not build isisd]))
 313 AC_ARG_ENABLE(pimd,
 314   AS_HELP_STRING([--disable-pimd], [do not build pimd]))
 315 AC_ARG_ENABLE(bgp-announce,
 316   AS_HELP_STRING([--disable-bgp-announce,], [turn off BGP route announcement]))
 317 AC_ARG_ENABLE(bgp-vnc,
 318   AS_HELP_STRING([--disable-bgp-vnc],[turn off BGP VNC support]))
 319 AC_ARG_WITH(rfp-path,
 320   AS_HELP_STRING([--with-rfp-path[=DIR]],[path to replaced stub RFP used with BGP VNC]))
 321 AC_ARG_ENABLE(snmp,
 322   AS_HELP_STRING([--enable-snmp=ARG], [enable SNMP support (smux or agentx)]))
 323 AC_ARG_WITH(libpam,
 324   AS_HELP_STRING([--with-libpam], [use libpam for PAM support in vtysh]))
 325 AC_ARG_ENABLE(tcp-zebra,
 326   AS_HELP_STRING([--enable-tcp-zebra], [enable TCP/IP socket connection between zebra and protocol daemon]))
 327 AC_ARG_ENABLE(ospfapi,
 328   AS_HELP_STRING([--disable-ospfapi], [do not build OSPFAPI to access the OSPF LSA Database]))
 329 AC_ARG_ENABLE(ospfclient,
 330   AS_HELP_STRING([--disable-ospfclient], [do not build OSPFAPI client for OSPFAPI,
 331                           (this is the default if --disable-ospfapi is set)]))
 332 AC_ARG_ENABLE(multipath,
 333   AS_HELP_STRING([--enable-multipath=ARG], [enable multipath function, ARG must be digit]))
 334 AC_ARG_ENABLE(user,
 335   AS_HELP_STRING([--enable-user=USER], [user to run FRR suite as (default frr)]))
 336 AC_ARG_ENABLE(group,
 337   AS_HELP_STRING([--enable-group=GROUP], [group to run FRR suite as (default frr)]))
 338 AC_ARG_ENABLE(vty_group,
 339   AS_HELP_STRING([--enable-vty-group=ARG], [set vty sockets to have specified group as owner]))
 340 AC_ARG_ENABLE(configfile_mask,
 341   AS_HELP_STRING([--enable-configfile-mask=ARG], [set mask for config files]))
 342 AC_ARG_ENABLE(logfile_mask,
 343   AS_HELP_STRING([--enable-logfile-mask=ARG], [set mask for log files]))
 344 AC_ARG_ENABLE(shell_access,
 345   AS_HELP_STRING([--enable-shell-access], [Allow users to access shell/telnet/ssh]))
 346 AC_ARG_ENABLE(rtadv,
 347   AS_HELP_STRING([--disable-rtadv], [disable IPV6 router advertisement feature]))
 348 AC_ARG_ENABLE(irdp,
 349   AS_HELP_STRING([--enable-irdp], [enable IRDP server support in zebra]))
 350 AC_ARG_ENABLE(capabilities,
 351   AS_HELP_STRING([--disable-capabilities], [disable using POSIX capabilities]))
 352 AC_ARG_ENABLE(rusage,
 353   AS_HELP_STRING([--disable-rusage], [disable using getrusage]))
 354 AC_ARG_ENABLE(gcc_ultra_verbose,
 355   AS_HELP_STRING([--enable-gcc-ultra-verbose], [enable ultra verbose GCC warnings]))
 356 AC_ARG_ENABLE(linux24_tcp_md5,
 357   AS_HELP_STRING([--enable-linux24-tcp-md5], [enable support for old, Linux-2.4 RFC2385 patch]))
 358 AC_ARG_ENABLE(backtrace,
 359   AS_HELP_STRING([--disable-backtrace,], [disable crash backtraces (default autodetect)]))
 360 AC_ARG_ENABLE(time-check,
 361   AS_HELP_STRING([--disable-time-check], [disable slow thread warning messages]))
 362 AC_ARG_ENABLE(pcreposix,
 363   AS_HELP_STRING([--enable-pcreposix], [enable using PCRE Posix libs for regex functions]))
 364 AC_ARG_ENABLE(fpm,
 365   AS_HELP_STRING([--enable-fpm], [enable Forwarding Plane Manager support]))
 366 AC_ARG_ENABLE(systemd,
 367   AS_HELP_STRING([--enable-systemd], [enable Systemd support]))
 368 AC_ARG_ENABLE(werror,
 369   AS_HELP_STRING([--enable-werror], [enable -Werror (recommended for developers only)]))
 370 AC_ARG_ENABLE(cumulus,
 371   AS_HELP_STRING([--enable-cumulus], [enable Cumulus Switch Special Extensions]))
 372 AC_ARG_ENABLE(datacenter,
 373   AS_HELP_STRING([--enable-datacenter], [enable Compilation for Data Center Extensions]))
 374 AC_ARG_ENABLE(rr-semantics,
 375   AS_HELP_STRING([--disable-rr-semantics], [disable the v6 Route Replace semantics]))
 376 AC_ARG_ENABLE([protobuf],
 377   AS_HELP_STRING([--enable-protobuf], [Enable experimental protobuf support]))
 378 AC_ARG_ENABLE([oldvpn_commands],
 379   AS_HELP_STRING([--enable-oldvpn-commands], [Keep old vpn commands]))
 380
 381 AC_CHECK_HEADERS(json-c/json.h)
 382 AC_CHECK_LIB(json-c, json_object_get, LIBS="$LIBS -ljson-c")
 383 if test $ac_cv_lib_json_c_json_object_get = no; then
 384   AC_CHECK_LIB(json, json_object_get, LIBS="$LIBS -ljson")
 385   if test $ac_cv_lib_json_json_object_get = no; then
 386       AC_MSG_ERROR([lib json is needed to compile])
 387   fi
 388 fi
 389
 390 AC_ARG_ENABLE([dev_build],
 391     AS_HELP_STRING([--enable-dev-build], [build for development]))
 392
 393 if test x"${enable_time_check}" != x"no" ; then
 394   if test x"${enable_time_check}" = x"yes" -o x"${enable_time_check}" = x ; then
 395     AC_DEFINE(CONSUMED_TIME_CHECK,5000000,Consumed Time Check)
 396   else
 397     AC_DEFINE_UNQUOTED(CONSUMED_TIME_CHECK,$enable_time_check,Consumed Time Check)
 398   fi
 399 fi
 400
 401 case "${enable_systemd}" in
 402   "no") ;;
 403   "yes")
 404   AC_CHECK_LIB(systemd, sd_notify, LIBS="$LIBS -lsystemd")
 405   if test $ac_cv_lib_systemd_sd_notify = no; then
 406     AC_MSG_ERROR([enable systemd has been specified but systemd development env not found on your system])
 407   else
 408     AC_DEFINE(HAVE_SYSTEMD,,Compile systemd support in)
 409   fi
 410   ;;
 411   "*") ;;
 412 esac
 413
 414 if test "${enable_rr_semantics}" != "no" ; then
 415   AC_DEFINE(HAVE_V6_RR_SEMANTICS,, Compile in v6 Route Replacement Semantics)
 416 fi
 417
 418 dnl ----------
 419 dnl MPLS check
 420 dnl ----------
 421 AC_MSG_CHECKING(whether this OS has MPLS stack)
 422 case "$host" in
 423   *-linux*)
 424       MPLS_METHOD="zebra_mpls_netlink.o"
 425       AC_MSG_RESULT(Linux MPLS)
 426   ;;
 427   *-openbsd*)
 428       MPLS_METHOD="zebra_mpls_openbsd.o"
 429       AC_MSG_RESULT(OpenBSD MPLS)
 430   ;;
 431   *)
 432       MPLS_METHOD="zebra_mpls_null.o"
 433       AC_MSG_RESULT(Unsupported kernel)
 434   ;;
 435 esac
 436 AC_SUBST(MPLS_METHOD)
 437
 438 if test "${enable_datacenter}" = "yes" ; then
 439   AC_DEFINE(HAVE_DATACENTER,,Compile extensions for a DataCenter)
 440   DFLT_NAME="datacenter"
 441 else
 442   DFLT_NAME="traditional"
 443 fi
 444
 445 if test "${enable_cumulus}" = "yes" ; then
 446   AC_DEFINE(HAVE_CUMULUS,,Compile Special Cumulus Code in)
 447 fi
 448
 449 AC_SUBST(DFLT_NAME)
 450 AC_DEFINE_UNQUOTED(DFLT_NAME,["$DFLT_NAME"], Name of the configuration default set)
 451
 452 if test "${enable_shell_access}" = "yes"; then
 453    AC_DEFINE(HAVE_SHELL_ACCESS,,Allow user to use ssh/telnet/bash)
 454 fi
 455
 456 AM_CONDITIONAL([FPM], [test "x$enable_fpm" = "xyes"])
 457
 458 if test "x${enable_dev_build}" = "xyes"; then
 459    AC_DEFINE(DEV_BUILD,,Build for development)
 460 fi
 461 AM_CONDITIONAL([DEV_BUILD], [test "x$enable_dev_build" = "xyes"])
 462
 463 #
 464 # Python for clippy
 465 #
 466 AS_IF([test "$host" = "$build"], [
 467   PYTHONCONFIG=""
 468
 469   # ordering:
 470   # 1.  try python3, but respect the user's preference on which minor ver
 471   # 2.  try python, which might be py3 or py2 again on the user's preference
 472   # 3.  try python2 (can really only be 2.7 but eh)
 473   # 4.  try 3.5 > 3.4 > 3.3 > 3.2 > 2.7 through pkg-config (no user pref)
 474   #
 475   # (AX_PYTHON_DEVEL has no clue about py3 vs py2)
 476   # (AX_PYTHON does not do what we need)
 477
 478   AC_CHECK_TOOLS([PYTHONCONFIG], [python3-config python-config python2-config])
 479   if test -n "$PYTHONCONFIG"; then
 480     PYTHON_CFLAGS="`\"${PYTHONCONFIG}\" --includes`"
 481     PYTHON_LIBS="`\"${PYTHONCONFIG}\" --libs`"
 482
 483     AC_MSG_CHECKING([whether we found a working Python version])
 484     AC_LINK_IFELSE_FLAGS([$PYTHON_CFLAGS], [$PYTHON_LIBS], [AC_LANG_PROGRAM([
 485 #include <Python.h>
 486 #if PY_VERSION_HEX < 0x02070000
 487 #error python too old
 488 #endif
 489 int main(void);
 490 ],
 491 [
 492 {
 493   Py_Initialize();
 494   return 0;
 495 }
 496 ])], [
 497       PYTHONCONFIG=""
 498       unset PYTHON_LIBS
 499       unset PYTHON_CFLAGS
 500     ])
 501   fi
 502
 503   if test -z "$PYTHONCONFIG"; then
 504     PKG_CHECK_MODULES([PYTHON], python-3.5, [], [
 505       PKG_CHECK_MODULES([PYTHON], python-3.4, [], [
 506         PKG_CHECK_MODULES([PYTHON], python-3.3, [], [
 507           PKG_CHECK_MODULES([PYTHON], python-3.2, [], [
 508             PKG_CHECK_MODULES([PYTHON], python-2.7, [], [
 509               AC_MSG_FAILURE([could not find python-config or pkg-config python, please install Python development files from libpython-dev or similar])
 510               ])])])])])
 511
 512
 513     AC_MSG_CHECKING([whether we found a working Python version])
 514     AC_LINK_IFELSE_FLAGS([$PYTHON_CFLAGS], [$PYTHON_LIBS], [AC_LANG_PROGRAM([
 515 #include <Python.h>
 516 #if PY_VERSION_HEX < 0x02070000
 517 #error python too old
 518 #endif
 519 int main(void);
 520 ],
 521 [
 522 {
 523   Py_Initialize();
 524   return 0;
 525 }
 526 ])], [
 527       AC_MSG_FAILURE([could not find python-config or pkg-config python, please install Python development files from libpython-dev or similar])
 528     ])
 529   fi
 530 ])
 531 AC_SUBST(PYTHON_CFLAGS)
 532 AC_SUBST(PYTHON_LIBS)
 533
 534 #
 535 # Logic for protobuf support.
 536 #
 537 if test "$enable_protobuf" = "yes"; then
 538    have_protobuf=yes
 539
 540    # Check for protoc-c
 541    AC_CHECK_PROG([PROTOC_C], [protoc-c], [protoc-c], [/bin/false])
 542    if test "x$PROTOC_C" = "x/bin/false"; then
 543       have_protobuf=no
 544    else
 545       found_protobuf_c=no
 546       PKG_CHECK_MODULES([PROTOBUF_C], libprotobuf-c >= 0.14,
 547                      [found_protobuf_c=yes],
 548                      [AC_MSG_RESULT([pkg-config did not find libprotobuf-c])])
 549
 550       if test "x$found_protobuf_c" = "xyes"; then
 551          LDFLAGS="$LDFLAGS $PROTOBUF_C_LIBS"
 552          CFLAGS="$CFLAGS $PROTOBUF_C_CFLAGS"
 553       else
 554         AC_CHECK_HEADER([google/protobuf-c/protobuf-c.h], [],
 555                         [have_protobuf=no; AC_MSG_RESULT([Couldn't find google/protobuf-c.h])])
 556       fi
 557    fi
 558 fi
 559
 560 #
 561 # Logic for old vpn commans support.
 562 #
 563 if test "$enable_oldvpn_commands" = "yes"; then
 564    AC_DEFINE(KEEP_OLD_VPN_COMMANDS,, [Define for compiling with old vpn commands])
 565 fi
 566
 567 # Fail if the user explicity enabled protobuf support and we couldn't
 568 # find the compiler or libraries.
 569 if test "x$have_protobuf" = "xno" && test "x$enable_protobuf" = "xyes"; then
 570    AC_MSG_ERROR([Protobuf enabled explicitly but can't find libraries/tools])
 571 fi
 572
 573 if test "x$have_protobuf" = "xyes"; then
 574    AC_DEFINE(HAVE_PROTOBUF,, protobuf)
 575 fi
 576
 577 AM_CONDITIONAL([HAVE_PROTOBUF], [test "x$have_protobuf" = "xyes"])
 578
 579 #
 580 # End of logic for protobuf support.
 581 #
 582
 583 if test "${enable_tcp_zebra}" = "yes"; then
 584   AC_DEFINE(HAVE_TCP_ZEBRA,,Use TCP for zebra communication)
 585 fi
 586
 587 if test "${enable_linux24_tcp_md5}" = "yes"; then
 588   AC_DEFINE(HAVE_TCP_MD5_LINUX24,,Old Linux 2.4 TCP MD5 Signature Patch)
 589 fi
 590
 591 AC_MSG_CHECKING(if zebra should be configurable to send Route Advertisements)
 592 if test "${enable_rtadv}" != "no"; then
 593   AC_MSG_RESULT(yes)
 594   AC_DEFINE(HAVE_RTADV,,Enable IPv6 Routing Advertisement support)
 595 else
 596   AC_MSG_RESULT(no)
 597 fi
 598
 599 if test "${enable_irdp}" = "yes"; then
 600   AC_DEFINE(HAVE_IRDP,, IRDP )
 601 fi
 602
 603 if test x"${enable_user}" = x"no"; then
 604   enable_user=""
 605 else
 606   if test x"${enable_user}" = x"yes" || test x"${enable_user}" = x""; then
 607     enable_user="frr"
 608   fi
 609   AC_DEFINE_UNQUOTED(FRR_USER, "${enable_user}", frr User)
 610 fi
 611
 612 if test x"${enable_group}" = x"no"; then
 613   enable_group=""
 614 else
 615   if test x"${enable_group}" = x"yes" || test x"${enable_group}" = x""; then
 616     enable_group="frr"
 617   fi
 618   AC_DEFINE_UNQUOTED(FRR_GROUP, "${enable_group}", frr Group)
 619 fi
 620
 621 if test x"${enable_vty_group}" = x"yes" ; then
 622   AC_MSG_ERROR([--enable-vty-group requires a group as argument, not yes])
 623 elif test x"${enable_vty_group}" != x""; then
 624   if test x"${enable_vty_group}" != x"no"; then
 625     AC_DEFINE_UNQUOTED(VTY_GROUP, "${enable_vty_group}", VTY Sockets Group)
 626   fi
 627 fi
 628 AC_SUBST([enable_user])
 629 AC_SUBST([enable_group])
 630 AC_SUBST([enable_vty_group])
 631
 632 enable_configfile_mask=${enable_configfile_mask:-0600}
 633 AC_DEFINE_UNQUOTED(CONFIGFILE_MASK, ${enable_configfile_mask}, Mask for config files)
 634
 635 enable_logfile_mask=${enable_logfile_mask:-0600}
 636 AC_DEFINE_UNQUOTED(LOGFILE_MASK, ${enable_logfile_mask}, Mask for log files)
 637
 638 MPATH_NUM=1
 639
 640 case "${enable_multipath}" in
 641   0)
 642     MPATH_NUM=64
 643     ;;
 644   [[1-9]|[1-9][0-9]|[1-9][0-9][0-9]])
 645     MPATH_NUM="${enable_multipath}"
 646     ;;
 647   "")
 648     ;;
 649   *)
 650     AC_MSG_FAILURE([Please specify digit to enable multipath ARG])
 651     ;;
 652 esac
 653
 654 AC_DEFINE_UNQUOTED(MULTIPATH_NUM, $MPATH_NUM, Maximum number of paths for a route)
 655
 656 AC_DEFINE_UNQUOTED(VTYSH_PAGER, "$VTYSH_PAGER", [What pager to use])
 657
 658 dnl -----------------------------------
 659 dnl Add extra version string to package
 660 dnl name, string and version fields.
 661 dnl -----------------------------------
 662 if test "x${EXTRAVERSION}" != "x" ; then
 663   VERSION="${VERSION}${EXTRAVERSION}"
 664   PACKAGE_VERSION="${PACKAGE_VERSION}${EXTRAVERSION}"
 665   AC_SUBST(PACKAGE_EXTRAVERSION, ["${EXTRAVERSION}"])
 666   PACKAGE_STRING="${PACKAGE_STRING}${EXTRAVERSION}"
 667 fi
 668
 669 if test "x$with_pkg_git_version" = "xyes"; then
 670         if test -d "${srcdir}/.git"; then
 671                 AC_DEFINE(GIT_VERSION, [1], [include git version info])
 672         else    with_pkg_git_version="no"
 673                 AC_MSG_WARN([--with-pkg-git-version given, but this is not a git checkout])
 674         fi
 675 fi
 676 AM_CONDITIONAL([GIT_VERSION], [test "x$with_pkg_git_version" = "xyes"])
 677
 678 dnl ------------------------------------
 679 dnl Check C keywords and standard  types
 680 dnl ------------------------------------
 681 AC_C_CONST
 682 AC_C_INLINE
 683 AC_C_VOLATILE
 684 AC_HEADER_STDC
 685 dnl AC_TYPE_PID_T
 686 AC_TYPE_UID_T
 687 AC_TYPE_MODE_T
 688 AC_TYPE_SIZE_T
 689 AC_STRUCT_TM
 690
 691 dnl -------------------------
 692 dnl Check other header files.
 693 dnl -------------------------
 694 AC_CHECK_HEADERS([stropts.h sys/ksym.h \
 695         linux/version.h asm/types.h \
 696         sys/cdefs.h])
 697
 698 ac_stdatomic_ok=false
 699 AC_DEFINE(FRR_AUTOCONF_ATOMIC, 1, [did autoconf checks for atomic funcs])
 700 AC_CHECK_HEADER([stdatomic.h],[
 701
 702   AC_MSG_CHECKING([whether _Atomic qualifier works])
 703   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 704 #include <stdatomic.h>
 705 int main(int argc, char **argv) {
 706   _Atomic int i = 0;
 707   return i;
 708 }
 709 ]])], [
 710     AC_DEFINE(HAVE_STDATOMIC_H, 1, [found stdatomic.h])
 711     AC_MSG_RESULT([yes])
 712     ac_stdatomic_ok=true
 713   ], [
 714     AC_MSG_RESULT([no])
 715   ])
 716 ])
 717
 718 AS_IF([$ac_stdatomic_ok], [true], [
 719   AC_MSG_CHECKING([for __atomic_* builtins])
 720   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 721 int main(int argc, char **argv) {
 722   volatile int i = 1;
 723   __atomic_store_n (&i, 0, __ATOMIC_RELEASE);
 724   return __atomic_load_n (&i, __ATOMIC_ACQUIRE);
 725 }
 726 ]])], [
 727     AC_DEFINE(HAVE___ATOMIC, 1, [found __atomic builtins])
 728     AC_MSG_RESULT([yes])
 729   ], [
 730     AC_MSG_RESULT([no])
 731
 732     dnl FreeBSD 9 has a broken stdatomic.h where _Atomic doesn't work
 733     AC_MSG_CHECKING([for __sync_* builtins])
 734     AC_LINK_IFELSE([AC_LANG_SOURCE([[
 735 int main(int argc, char **argv) {
 736   volatile int i = 1;
 737   __sync_fetch_and_sub (&i, 1);
 738   return __sync_val_compare_and_swap (&i, 0, 1);
 739 }
 740 ]])], [
 741       AC_DEFINE(HAVE___SYNC, 1, [found __sync builtins])
 742       AC_MSG_RESULT([yes])
 743
 744       AC_MSG_CHECKING([for __sync_swap builtin])
 745       AC_LINK_IFELSE([AC_LANG_SOURCE([[
 746 int main(int argc, char **argv) {
 747   volatile int i = 1;
 748   return __sync_swap (&i, 2);
 749 }
 750 ]])], [
 751         AC_DEFINE(HAVE___SYNC_SWAP, 1, [found __sync_swap builtin])
 752         AC_MSG_RESULT([yes])
 753       ], [
 754         AC_MSG_RESULT([no])
 755       ])
 756
 757     ], [
 758       AC_MSG_RESULT([no])
 759       AC_MSG_FAILURE([stdatomic.h unavailable and $CC has neither __atomic nor __sync builtins])
 760     ])
 761   ])
 762 ])
 763
 764 dnl Utility macro to avoid retyping includes all the time
 765 m4_define([FRR_INCLUDES],
 766 [#ifdef SUNOS_5
 767 #define _XPG4_2
 768 #define __EXTENSIONS__
 769 #endif
 770 #include <stdio.h>
 771 #include <stdlib.h>
 772 #include <stddef.h>
 773 #include <sys/types.h>
 774 /* sys/conf.h depends on param.h on FBSD at least */
 775 #include <sys/param.h>
 776 /* Required for MAXSIG */
 777 #include <signal.h>
 778 #include <sys/socket.h>
 779 #ifdef __APPLE__
 780 # define __APPLE_USE_RFC_3542
 781 #endif
 782 #include <netinet/in.h>
 783 #include <sys/time.h>
 784 #include <time.h>
 785 #include <net/if.h>
 786 ])dnl
 787
 788 dnl Same applies for HAVE_NET_IF_VAR_H, which HAVE_NETINET6_ND6_H and
 789 dnl HAVE_NETINET_IN_VAR_H depend upon. But if_var.h depends on if.h, hence
 790 dnl an additional round for it.
 791
 792 AC_CHECK_HEADERS([net/if_var.h], [], [], FRR_INCLUDES)
 793
 794 m4_define([FRR_INCLUDES],
 795 FRR_INCLUDES
 796 [#if HAVE_NET_IF_VAR_H
 797 # include <net/if_var.h>
 798 #endif
 799 ])dnl
 800
 801 AC_CHECK_HEADERS([netinet/in_var.h \
 802         net/if_dl.h net/netopt.h \
 803         inet/nd.h netinet/ip_icmp.h \
 804         sys/sysctl.h sys/sockio.h kvm.h sys/conf.h],
 805         [], [], FRR_INCLUDES)
 806
 807 AC_CHECK_HEADERS([ucontext.h], [], [],
 808 [#ifndef __USE_GNU
 809 #define __USE_GNU
 810 #endif /* __USE_GNU */
 811 FRR_INCLUDES
 812 ])
 813
 814 m4_define([UCONTEXT_INCLUDES],
 815 [#include <ucontext.h>])dnl
 816
 817 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.uc_regs],
 818   [], [], [UCONTEXT_INCLUDES])
 819 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs],
 820   [AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs.nip],
 821    [], [], [UCONTEXT_INCLUDES])],
 822   [], [UCONTEXT_INCLUDES])
 823 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.gregs],
 824   [], [], [UCONTEXT_INCLUDES])
 825
 826 m4_define([FRR_INCLUDES],
 827 FRR_INCLUDES
 828 [
 829 #include <sys/un.h>
 830 #include <netinet/in_systm.h>
 831 #if HAVE_NETINET_IN_VAR_H
 832 # include <netinet/in_var.h>
 833 #endif
 834 #if HAVE_NET_IF_DL_H
 835 # include <net/if_dl.h>
 836 #endif
 837 #if HAVE_NET_NETOPT_H
 838 # include <net/netopt.h>
 839 #endif
 840 #include <net/route.h>
 841 #if HAVE_INET_ND_H
 842 # include <inet/nd.h>
 843 #endif
 844 #include <arpa/inet.h>
 845 /* Required for IDRP */
 846 #if HAVE_NETINET_IP_ICMP_H
 847 # include <netinet/ip_icmp.h>
 848 #endif
 849 ])dnl
 850
 851 dnl V6 headers are checked below, after we check for v6
 852
 853 dnl Some systems (Solaris 2.x) require libnsl (Network Services Library)
 854 case "$host" in
 855   [*-sunos5.[6-7]*] | [*-solaris2.[6-7]*])
 856       opsys=sol2-6
 857       AC_DEFINE(SUNOS_56, 1, SunOS 5.6 to 5.7)
 858       AC_DEFINE(SUNOS_5, 1, SunOS 5)
 859       AC_CHECK_LIB(xnet, main)
 860       CURSES=-lcurses
 861       SOLARIS="solaris"
 862   ;;
 863   [*-sunos5.[8-9]] \
 864   | [*-sunos5.1[0-9]] \
 865   | [*-sunos5.1[0-9].[0-9]] \
 866   | [*-solaris2.[8-9]] \
 867   | [*-solaris2.1[0-9]] \
 868   | [*-solaris2.1[0-9].[0-9]])
 869       opsys=sol8
 870       AC_DEFINE(SUNOS_59, 1, [SunOS 5.8 up])
 871       AC_DEFINE(SUNOS_5, 1, [SunOS 5])
 872       AC_CHECK_LIB(socket, main)
 873       AC_CHECK_LIB(nsl, main)
 874       AC_CHECK_LIB(umem, main)
 875       AC_CHECK_FUNCS([printstack],
 876         [AC_DEFINE([HAVE_PRINTSTACK],1,[Solaris printstack])
 877          AC_DEFINE([HAVE_STACK_TRACE],1,[Stack symbols decode functionality])
 878         ])
 879       CURSES=-lcurses
 880       SOLARIS="solaris"
 881   ;;
 882   *-sunos5* | *-solaris2*)
 883       AC_DEFINE(SUNOS_5,,SunOS 5, Unknown SunOS)
 884       AC_CHECK_LIB(socket, main)
 885       AC_CHECK_LIB(nsl, main)
 886       CURSES=-lcurses
 887       SOLARIS="solaris"
 888   ;;
 889   *-linux*)
 890       opsys=gnu-linux
 891       AC_DEFINE(GNU_LINUX,,GNU Linux)
 892   ;;
 893   *-openbsd*)
 894       opsys=openbsd
 895       AC_DEFINE(OPEN_BSD,,OpenBSD)
 896   ;;
 897 esac
 898
 899 AC_SYS_LARGEFILE
 900
 901 dnl ---------------------
 902 dnl Integrated VTY option
 903 dnl ---------------------
 904 case "${enable_vtysh}" in
 905   "no") VTYSH="";;
 906   *)    VTYSH="vtysh";
 907          AC_DEFINE(VTYSH,,VTY shell)
 908 dnl      Vtysh uses libreadline, which looks for termcap functions at
 909 dnl      configure time.  We follow readlines search order.
 910 dnl      The required procedures are in libtermcap on NetBSD, in
 911 dnl      [TODO] on Linux, and in [TODO] on Solaris.
 912          AC_CHECK_LIB(termcap, tputs, LIBREADLINE="$LIBREADLINE -ltermcap",
 913            [AC_CHECK_LIB(tinfo, tputs, LIBREADLINE="$LIBREADLINE -ltinfo",
 914              [AC_CHECK_LIB(curses, tputs, LIBREADLINE="$LIBREADLINE -lcurses",
 915                [AC_CHECK_LIB(ncurses, tputs,
 916                              LIBREADLINE="$LIBREADLINE -lncurses")]
 917               )]
 918             )]
 919           )
 920          AC_CHECK_LIB(readline, main, LIBREADLINE="-lreadline $LIBREADLINE",,
 921                       "$LIBREADLINE")
 922          if test $ac_cv_lib_readline_main = no; then
 923            AC_MSG_ERROR([vtysh needs libreadline but was not found and usable on your system.])
 924          fi
 925          AC_CHECK_HEADER(readline/history.h)
 926          if test $ac_cv_header_readline_history_h = no;then
 927            AC_MSG_ERROR([readline is too old to have readline/history.h, please update to the latest readline library.])
 928          fi
 929          AC_CHECK_LIB(readline, rl_completion_matches,
 930                       LIBREADLINE="$LIBREADLINE",, "$LIBREADLINE")
 931          if test $ac_cv_lib_readline_rl_completion_matches = no; then
 932            AC_DEFINE(rl_completion_matches,completion_matches,Old readline)
 933          fi
 934          ;;
 935 esac
 936 AC_SUBST(LIBREADLINE)
 937 AM_CONDITIONAL(VTYSH, test "x$VTYSH" = "xvtysh")
 938
 939 dnl ----------
 940 dnl PAM module
 941 dnl
 942 dnl FRR detects the PAM library it is built against by checking for a
 943 dnl functional pam_misc.h (Linux-PAM) or openpam.h (OpenPAM) header. pam_misc.h
 944 dnl is known to #include pam_appl.h, the standard header of a PAM library, and
 945 dnl openpam.h doesn't do that, although depends on the header too. Hence a
 946 dnl little assistance to AC_CHECK_HEADER is necessary for the proper detection
 947 dnl of OpenPAM.
 948 dnl ----------
 949 if test "$with_libpam" = "yes"; then
 950   AC_CHECK_HEADER([security/pam_misc.h],
 951     [AC_DEFINE(HAVE_PAM_MISC_H,,Have pam_misc.h)
 952      AC_DEFINE(PAM_CONV_FUNC,misc_conv,Have misc_conv)
 953      pam_conv_func="misc_conv"
 954     ],
 955     [], FRR_INCLUDES)
 956   AC_CHECK_HEADER([security/openpam.h],
 957     [AC_DEFINE(HAVE_OPENPAM_H,,Have openpam.h)
 958      AC_DEFINE(PAM_CONV_FUNC,openpam_ttyconv,Have openpam_ttyconv)
 959      pam_conv_func="openpam_ttyconv"
 960     ],
 961     [], FRR_INCLUDES[#include <security/pam_appl.h>])
 962   if test -z "$ac_cv_header_security_pam_misc_h$ac_cv_header_security_openpam_h" ; then
 963     AC_MSG_WARN([*** pam support will not be built ***])
 964     with_libpam="no"
 965   fi
 966 fi
 967
 968 if test "$with_libpam" = "yes"; then
 969 dnl took this test from proftpds configure.in and suited to our needs
 970 dnl -------------------------------------------------------------------------
 971 dnl
 972 dnl This next check looks funky due to a linker problem with some versions
 973 dnl of the PAM library.  Prior to 0.72 release, the Linux PAM shared library
 974 dnl omitted requiring libdl linking information. PAM-0.72 or better ships
 975 dnl with RedHat 6.2 and Debian 2.2 or better.
 976 AC_CHECK_LIB(pam, pam_start,
 977   [AC_CHECK_LIB(pam, $pam_conv_func,
 978     [AC_DEFINE(USE_PAM,,Use PAM for authentication)
 979      LIBPAM="-lpam"],
 980     [AC_DEFINE(USE_PAM,,Use PAM for authentication)
 981      LIBPAM="-lpam -lpam_misc"]
 982     )
 983   ],
 984
 985   [AC_CHECK_LIB(pam, pam_end,
 986     [AC_CHECK_LIB(pam, $pam_conv_func,
 987       [AC_DEFINE(USE_PAM,,Use PAM for authentication)
 988        LIBPAM="-lpam -ldl"],
 989       [AC_DEFINE(USE_PAM,,Use PAM for authentication)
 990        LIBPAM="-lpam -ldl -lpam_misc"]
 991      )
 992   ],AC_MSG_WARN([*** pam support will not be built ***]),
 993   [-ldl])
 994   ]
 995 )
 996 fi
 997 AC_SUBST(LIBPAM)
 998
 999 dnl -------------------------------
1000 dnl Endian-ness check
1001 dnl -------------------------------
1002 AC_WORDS_BIGENDIAN
1003
1004 dnl -------------------------------
1005 dnl check the size in byte of the C
1006 dnl -------------------------------
1007 dnl AC_CHECK_SIZEOF(char)
1008 dnl AC_CHECK_SIZEOF(int)
1009 dnl AC_CHECK_SIZEOF(short)
1010 dnl AC_CHECK_SIZEOF(long)
1011
1012 dnl ----------------------------
1013 dnl check existance of functions
1014 dnl ----------------------------
1015 AC_FUNC_FNMATCH
1016 AC_FUNC_FORK
1017 AC_FUNC_MKTIME
1018 AC_FUNC_STAT
1019
1020 dnl -------------------------------
1021 dnl bgpd needs pow() and hence libm
1022 dnl -------------------------------
1023 TMPLIBS="$LIBS"
1024 AC_CHECK_HEADER([math.h],
1025   [AC_CHECK_LIB([m], [pow],
1026     [LIBM="-lm"
1027      LIBS="$LIBS $LIBM"
1028      AC_CHECK_FUNCS(pow,[],[LIBM=""])
1029     ])
1030 ])
1031 if test x"$LIBM" = x ; then
1032   AC_MSG_WARN([Unable to find working pow function - bgpd may not link])
1033 fi
1034 LIBS="$TMPLIBS"
1035 AC_SUBST(LIBM)
1036
1037 dnl ---------------
1038 dnl other functions
1039 dnl ---------------
1040 AC_CHECK_FUNCS([ \
1041         strlcat strlcpy \
1042         getgrouplist])
1043
1044 AC_CHECK_HEADER([asm-generic/unistd.h],
1045                 [AC_CHECK_DECL(__NR_setns,
1046                                AC_DEFINE(HAVE_NETNS,, Have netns),,
1047                                FRR_INCLUDES [#include <asm-generic/unistd.h>
1048                                ])
1049                  AC_CHECK_FUNCS(setns)]
1050                )
1051
1052 dnl ------------------------------------
1053 dnl Determine routing get and set method
1054 dnl ------------------------------------
1055 AC_MSG_CHECKING(zebra between kernel interface method)
1056 if test x"$opsys" = x"gnu-linux"; then
1057   AC_MSG_RESULT(netlink)
1058   RT_METHOD=rt_netlink.o
1059   KERNEL_METHOD=kernel_netlink.o
1060   AC_DEFINE(HAVE_NETLINK,,netlink)
1061   netlink=yes
1062   AC_CHECK_DECLS([IFLA_INFO_SLAVE_KIND], [], [], [#include <linux/if_link.h>])
1063 else
1064   AC_MSG_RESULT(Route socket)
1065   KERNEL_METHOD="kernel_socket.o"
1066   RT_METHOD="rt_socket.o"
1067 fi
1068 AC_SUBST(RT_METHOD)
1069 AC_SUBST(KERNEL_METHOD)
1070 AM_CONDITIONAL([HAVE_NETLINK], [test "x$netlink" = "xyes"])
1071
1072 dnl --------------------------
1073 dnl Determine IS-IS I/O method
1074 dnl --------------------------
1075 AC_DEFINE(ISIS_METHOD_PFPACKET, 1, [ constant value for isis method pfpacket ])
1076 AC_DEFINE(ISIS_METHOD_DLPI,     2, [ constant value for isis method dlpi ])
1077 AC_DEFINE(ISIS_METHOD_BPF,      3, [ constant value for isis method bpf ])
1078 AC_CHECK_HEADER(net/bpf.h)
1079 AC_CHECK_HEADER(sys/dlpi.h)
1080 AC_MSG_CHECKING(zebra IS-IS I/O method)
1081 if test x"$opsys" = x"gnu-linux"; then
1082   AC_MSG_RESULT(pfpacket)
1083   ISIS_METHOD_MACRO="ISIS_METHOD_PFPACKET"
1084 elif test x"$opsys" = x"sol2-6" -o x"$opsys" = x"sol8"; then
1085   AC_MSG_RESULT(DLPI)
1086   ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1087 else
1088   if test $ac_cv_header_net_bpf_h = no; then
1089     if test $ac_cv_header_sys_dlpi_h = no; then
1090       AC_MSG_RESULT(none)
1091       AC_MSG_WARN([*** IS-IS support will not be built ***])
1092       ISISD=""
1093     else
1094       AC_MSG_RESULT(DLPI)
1095     fi
1096     ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1097   else
1098     AC_MSG_RESULT(BPF)
1099     ISIS_METHOD_MACRO="ISIS_METHOD_BPF"
1100   fi
1101 fi
1102 AC_DEFINE_UNQUOTED(ISIS_METHOD, $ISIS_METHOD_MACRO, [ selected method for isis, == one of the constants ])
1103
1104 dnl ------------------------------------
1105 dnl check for broken CMSG_FIRSTHDR macro
1106 dnl ------------------------------------
1107 AC_MSG_CHECKING(for broken CMSG_FIRSTHDR)
1108 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1109 #ifdef SUNOS_5
1110 #define _XPG4_2
1111 #define __EXTENSIONS__
1112 #endif
1113 #include <stdlib.h>
1114 #include <sys/types.h>
1115 #include <sys/socket.h>
1116
1117 main()
1118 {
1119   struct msghdr msg;
1120   char buf[4];
1121
1122   msg.msg_control = buf;
1123   msg.msg_controllen = 0;
1124
1125   if (CMSG_FIRSTHDR(&msg) != NULL)
1126     exit(0);
1127   exit (1);
1128 }]])],[AC_MSG_RESULT(yes - using workaround) AC_DEFINE(HAVE_BROKEN_CMSG_FIRSTHDR,,Broken CMSG_FIRSTHDR)],
1129 [AC_MSG_RESULT(no)],[AC_MSG_RESULT(no)])
1130
1131 dnl ------------------------------
1132 dnl check kernel route read method
1133 dnl ------------------------------
1134 AC_CACHE_CHECK([route read method], [frr_cv_rtread_method],
1135 [if test "x$netlink" = xyes; then
1136   frr_cv_rtread_method="netlink"
1137 else
1138 for frr_cv_rtread_method in /dev/ip /dev/null;
1139 do
1140   test x`ls $frr_cv_rtread_method 2>/dev/null` = x"$frr_cv_rtread_method" && break
1141 done
1142 case $frr_cv_rtread_method in
1143   "/dev/ip")
1144                      case "$host" in
1145                        *-freebsd*)    frr_cv_rtread_method="sysctl";;
1146                        *)             frr_cv_rtread_method="getmsg";;
1147                      esac;;
1148         *)
1149                      frr_cv_rtread_method="sysctl";;
1150 esac
1151 fi])
1152 RTREAD_METHOD=rtread_${frr_cv_rtread_method}.o
1153 AC_SUBST(RTREAD_METHOD)
1154
1155 dnl -----------------------------
1156 dnl check interface lookup method
1157 dnl -----------------------------
1158 IOCTL_METHOD=ioctl.o
1159 AC_MSG_CHECKING(interface looking up method)
1160 if test "$netlink" = yes; then
1161   AC_MSG_RESULT(netlink)
1162   IF_METHOD=if_netlink.o
1163 elif test "$opsys" = "sol2-6";then
1164   AC_MSG_RESULT(Solaris GIF)
1165   IF_METHOD=if_ioctl.o
1166 elif test "$opsys" = "sol8";then
1167   AC_MSG_RESULT(Solaris GLIF)
1168   IF_METHOD=if_ioctl_solaris.o
1169   IOCTL_METHOD=ioctl_solaris.o
1170 elif test "$opsys" = "openbsd";then
1171   AC_MSG_RESULT(openbsd)
1172   IF_METHOD=if_ioctl.o
1173 elif grep NET_RT_IFLIST /usr/include/sys/socket.h >/dev/null 2>&1; then
1174   AC_MSG_RESULT(sysctl)
1175     IF_METHOD=if_sysctl.o
1176     AC_DEFINE(HAVE_NET_RT_IFLIST,,NET_RT_IFLIST)
1177 else
1178     AC_MSG_RESULT(ioctl)
1179     IF_METHOD=if_ioctl.o
1180 fi
1181 AC_SUBST(IF_METHOD)
1182 AC_SUBST(IOCTL_METHOD)
1183
1184 dnl ---------------------------------------------------------------
1185 dnl figure out how to specify an interface in multicast sockets API
1186 dnl ---------------------------------------------------------------
1187 AC_CHECK_MEMBERS([struct ip_mreqn.imr_ifindex], [], [], FRR_INCLUDES)
1188
1189 AC_CHECK_HEADERS([linux/mroute.h], [], [],[
1190         #include <sys/socket.h>
1191         #include <netinet/in.h>
1192         #define _LINUX_IN_H             /* For Linux <= 2.6.25 */
1193         #include <linux/types.h>
1194 ])
1195
1196 m4_define([FRR_INCLUDES],
1197 FRR_INCLUDES
1198 [#if HAVE_LINUX_MROUTE_H
1199 # include <linux/mroute.h>
1200 #endif
1201 ])dnl
1202
1203 AC_CHECK_HEADERS([netinet/ip_mroute.h], [], [],[
1204         #include <sys/socket.h>
1205         #include <sys/types.h>
1206         #include <netinet/in.h>
1207         #include <net/route.h>
1208 ])
1209
1210 m4_define([FRR_INCLUDES],
1211 FRR_INCLUDES
1212 [#if HAVE_NETINET_IP_MROUTE_H
1213 # include <netinet/ip_mroute.h>
1214 #endif
1215 ])dnl
1216
1217 AC_MSG_CHECKING([for BSD struct ip_mreq hack])
1218 AC_TRY_COMPILE([#include <sys/param.h>],
1219 [#if (defined(__FreeBSD__) && ((__FreeBSD_version >= 500022 && __FreeBSD_version < 700000) || (__FreeBSD_version < 500000 && __FreeBSD_version >= 440000))) || (defined(__NetBSD__) && defined(__NetBSD_Version__) && __NetBSD_Version__ >= 106010000) || defined(__OpenBSD__) || defined(__APPLE__) || defined(__DragonFly__) || defined(__sun)
1220   return (0);
1221 #else
1222   #error No support for BSD struct ip_mreq hack detected
1223 #endif],[AC_MSG_RESULT(yes)
1224 AC_DEFINE(HAVE_BSD_STRUCT_IP_MREQ_HACK,,[Can pass ifindex in struct ip_mreq])],
1225 AC_MSG_RESULT(no))
1226
1227 AC_MSG_CHECKING([for RFC3678 protocol-independed API])
1228 AC_TRY_COMPILE([
1229 #include <sys/types.h>
1230 #include <netinet/in.h>
1231 ], [struct group_req gr; int sock; setsockopt(sock, IPPROTO_IP, MCAST_JOIN_GROUP, (void*)&gr, sizeof(gr));
1232 ], [AC_MSG_RESULT(yes)
1233 AC_DEFINE(HAVE_RFC3678,1,[Have RFC3678 protocol-independed API])],
1234 AC_MSG_RESULT(no))
1235
1236 dnl ---------------------------------------------------------------
1237 dnl figure out how to check link-state
1238 dnl ---------------------------------------------------------------
1239 AC_CHECK_HEADER( [net/if_media.h],
1240   [m4_define([LINK_DETECT_INCLUDES],
1241     FRR_INCLUDES
1242     [#include <net/if_media.h>
1243   ])
1244   AC_CHECK_MEMBERS( [struct ifmediareq.ifm_status],
1245     AC_DEFINE(HAVE_BSD_LINK_DETECT,,[BSD link-detect]),
1246     [], LINK_DETECT_INCLUDES)],
1247   [],
1248   FRR_INCLUDES)
1249
1250 dnl ---------------------------------------------------------------
1251 dnl Additional, newer way to check link-state using ifi_link_state.
1252 dnl Not available in all BSD's when ifmediareq available
1253 dnl ---------------------------------------------------------------
1254 AC_CHECK_MEMBERS([struct if_data.ifi_link_state],
1255   AC_DEFINE(HAVE_BSD_IFI_LINK_STATE,,[BSD ifi_link_state available]),
1256   [], FRR_INCLUDES)
1257
1258 dnl ------------------------
1259 dnl TCP_MD5SIG socket option
1260 dnl ------------------------
1261
1262 AC_CHECK_HEADER([netinet/tcp.h],
1263    [m4_define([MD5_INCLUDES],
1264       FRR_INCLUDES
1265       [#include <netinet/tcp.h>
1266     ])
1267     AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)],
1268    [],
1269    FRR_INCLUDES)
1270 if test $ac_cv_have_decl_TCP_MD5SIG = no; then
1271   AC_CHECK_HEADER([linux/tcp.h],
1272        [m4_define([MD5_INCLUDES],
1273           FRR_INCLUDES
1274           [#include <linux/tcp.h>
1275         ])
1276        AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)])
1277 fi
1278
1279 dnl -----------------------------
1280 dnl check ipforward detect method
1281 dnl -----------------------------
1282 AC_CACHE_CHECK([ipforward method], [frr_cv_ipforward_method],
1283 [if test x$cross_compiling = xyes; then
1284   if test x"$opsys" = x"gnu-linux"; then
1285     frr_cv_ipforward_method=/proc/net/snmp
1286   else
1287     frr_cv_ipforward_method=/dev/ip
1288   fi
1289 else
1290   for frr_cv_ipforward_method in /proc/net/snmp /dev/ip /dev/null;
1291   do
1292     test x`ls $frr_cv_ipforward_method 2>/dev/null` = x"$frr_cv_ipforward_method" && break
1293   done
1294 fi
1295 case $frr_cv_ipforward_method in
1296   "/proc/net/snmp")  frr_cv_ipforward_method="proc";;
1297   "/dev/ip")
1298                      case "$host" in
1299                        *-freebsd*)    frr_cv_ipforward_method="sysctl";;
1300                        *)             frr_cv_ipforward_method="solaris";;
1301                      esac;;
1302   *)                 frr_cv_ipforward_method="sysctl";;
1303 esac])
1304 IPFORWARD=ipforward_${frr_cv_ipforward_method}.o
1305 AC_SUBST(IPFORWARD)
1306
1307 dnl ----------------------------------------------------------------------------
1308 dnl figure out if domainname is available in the utsname struct (GNU extension).
1309 dnl ----------------------------------------------------------------------------
1310 AC_CHECK_MEMBERS([struct utsname.domainname], [], [], [#include <sys/utsname.h>])
1311
1312 dnl ----------
1313 dnl IPv6 check
1314 dnl ----------
1315 AC_MSG_CHECKING(whether does this OS have IPv6 stack)
1316 dnl ---------
1317 dnl KAME IPv6
1318 dnl ---------
1319   if grep WIDE /usr/include/netinet6/in6.h >/dev/null 2>&1; then
1320     AC_DEFINE(KAME,1,KAME IPv6)
1321     AC_MSG_RESULT(KAME)
1322 dnl ------------------------------------
1323 dnl Solaris 9, 10 and potentially higher
1324 dnl ------------------------------------
1325   elif test x"$opsys" = x"sol8"; then
1326     AC_DEFINE(SOLARIS_IPV6, 1, Solaris IPv6)
1327     AC_MSG_RESULT(Solaris IPv6)
1328 dnl ----------
1329 dnl Linux IPv6
1330 dnl ----------
1331   elif test x"$opsys" = x"gnu-linux"; then
1332     AC_DEFINE(LINUX_IPV6,1,Linux IPv6 stack)
1333     dnl Linux has a compilation problem with mixing
1334     dnl netinet/in.h and linux/in6.h they are not
1335     dnl compatible.  There has been discussion on
1336     dnl how to fix it but no real progress on implementation
1337     dnl when they fix it, remove this
1338     AC_DEFINE(IPV6_MINHOPCOUNT, 73, Linux ipv6 Min Hop Count)
1339     AC_MSG_RESULT(Linux IPv6)
1340   else
1341     AC_MSG_ERROR([Failed to detect IPv6 stack])
1342   fi
1343
1344 dnl ------------------
1345 dnl IPv6 header checks
1346 dnl ------------------
1347 AC_CHECK_HEADERS([netinet6/in6.h netinet/in6_var.h \
1348         netinet6/in6_var.h netinet6/nd6.h], [], [],
1349         FRR_INCLUDES)
1350
1351 m4_define([FRR_INCLUDES],dnl
1352 FRR_INCLUDES
1353 [#if HAVE_NETINET6_IN6_H
1354 #include <netinet6/in6.h>
1355 #endif
1356 #if HAVE_NETINET_IN6_VAR_H
1357 #include <netinet/in6_var.h>
1358 #endif
1359 #include <netinet/icmp6.h>
1360 #if HAVE_NETINET6_IN6_VAR_H
1361 # include <netinet6/in6_var.h>
1362 #endif
1363 #if HAVE_NETINET6_ND6_H
1364 # include <netinet6/nd6.h>
1365 #endif
1366 ])dnl
1367
1368 dnl disable doc check
1369 if test "${enable_doc}" = "no";then
1370   DOC=""
1371 else
1372   DOC="doc"
1373 fi
1374
1375 dnl --------------------
1376 dnl Daemon disable check
1377 dnl --------------------
1378 if test "${enable_zebra}" = "no";then
1379   ZEBRA=""
1380 else
1381   ZEBRA="zebra"
1382 fi
1383 AM_CONDITIONAL(ZEBRA, test "x$ZEBRA" = "xzebra")
1384
1385 if test "${enable_bgpd}" = "no";then
1386   BGPD=""
1387 else
1388   BGPD="bgpd"
1389 fi
1390 AM_CONDITIONAL(BGPD, test "x$BGPD" = "xbgpd")
1391
1392 if test "${enable_ripd}" = "no";then
1393   RIPD=""
1394 else
1395   RIPD="ripd"
1396 fi
1397 AM_CONDITIONAL(RIPD, test "x$RIPD" = "xripd")
1398
1399 if test "${enable_ospfd}" = "no";then
1400   OSPFD=""
1401 else
1402   OSPFD="ospfd"
1403 fi
1404 AM_CONDITIONAL(OSPFD, test "x$OSPFD" = "xospfd")
1405
1406 if test "${enable_ldpd}" = "no";then
1407   LDPD=""
1408 else
1409   LDPD="ldpd"
1410   AC_DEFINE(HAVE_LDPD, 1, ldpd)
1411 fi
1412 AM_CONDITIONAL(LDPD, test "x$LDPD" = "xldpd")
1413
1414 NHRPD=""
1415 if test "$opsys" = "gnu-linux"; then
1416   if test "${enable_nhrpd}" != "no"; then
1417     NHRPD="nhrpd"
1418   fi
1419 else
1420   if test "${enable_nhrpd}" = "yes"; then
1421     AC_MSG_ERROR([nhrpd requires kernel APIs that are only present on Linux.])
1422   fi
1423 fi
1424 AM_CONDITIONAL(NHRPD, test "x$NHRPD" = "xnhrpd")
1425
1426 if test "${enable_eigrpd}" = "no";then
1427   EIGRPD=""
1428 else
1429   EIGRPD="eigrpd"
1430 fi
1431 AM_CONDITIONAL(EIGRPD, test "x$EIGRPD" = "xeigrpd")
1432
1433 if test "${enable_watchfrr}" = "no";then
1434   WATCHFRR=""
1435 else
1436   WATCHFRR="watchfrr"
1437 fi
1438 AM_CONDITIONAL(WATCHFRR, test "x$WATCHFRR" = "xwatchfrr")
1439
1440 OSPFCLIENT=""
1441 if test "${enable_ospfapi}" != "no";then
1442     AC_DEFINE(SUPPORT_OSPF_API,,OSPFAPI)
1443
1444   if test "${enable_ospfclient}" != "no";then
1445       OSPFCLIENT="ospfclient"
1446   fi
1447 fi
1448
1449 AM_CONDITIONAL(OSPFCLIENT, test "x$OSPFCLIENT" = "xospfclient")
1450
1451 case "${enable_ripngd}" in
1452   "no" ) RIPNGD="";;
1453   *    ) RIPNGD="ripngd";;
1454 esac
1455 AM_CONDITIONAL(RIPNGD, test "x$RIPNGD" = "xripngd")
1456
1457 case "${enable_babeld}" in
1458   "no" ) BABELD="";;
1459   *    ) BABELD="babeld";;
1460 esac
1461 AM_CONDITIONAL(BABELD, test "x$BABELD" = "xbabeld")
1462
1463 case "${enable_ospf6d}" in
1464   "no" ) OSPF6D="";;
1465   *    ) OSPF6D="ospf6d";;
1466 esac
1467 AM_CONDITIONAL(OSPF6D, test "x$OSPF6D" = "xospf6d")
1468
1469 case "${enable_isisd}" in
1470   "no" ) ISISD="";;
1471   *    ) ISISD="isisd";;
1472 esac
1473 AM_CONDITIONAL(ISISD, test "x$ISISD" = "xisisd")
1474
1475 case "${enable_pimd}" in
1476   "no" ) PIMD="";;
1477   *    ) PIMD="pimd";;
1478 esac
1479 AM_CONDITIONAL(PIMD, test "x$PIMD" = "xpimd")
1480
1481 if test "${enable_bgp_announce}" = "no";then
1482   AC_DEFINE(DISABLE_BGP_ANNOUNCE,1,Disable BGP installation to zebra)
1483 else
1484   AC_DEFINE(DISABLE_BGP_ANNOUNCE,0,Disable BGP installation to zebra)
1485 fi
1486
1487 if test "${with_rfp_path}" = "yes" || test x"${with_rfp_path}" = x""; then
1488   with_rfp_path="bgpd/rfp-example"
1489 fi
1490 if test "${with_rfp_path}" != "no"; then
1491   VNC_RFP_PATH="${with_rfp_path}"
1492   AC_SUBST(VNC_RFP_PATH)
1493 fi
1494
1495 if test "${enable_bgp_vnc}" != "no";then
1496   AC_DEFINE(ENABLE_BGP_VNC,1,Enable BGP VNC support)
1497   RFPTEST="${with_rfp_path}/rfptest"
1498   LIBRFP="${with_rfp_path}/librfp"
1499   RFPINC="${with_rfp_path}/librfp"
1500 else
1501   RFPTEST=
1502   LIBRFP=
1503   RFPINC="bgpd/rfp-example/librfp"
1504 fi
1505 # set
1506 AM_CONDITIONAL([ENABLE_BGP_VNC], [test x${enable_bgp_vnc} != xno])
1507
1508 AC_SUBST(DOC)
1509 AC_SUBST(ZEBRA)
1510 AC_SUBST(RFPTEST)
1511 AC_SUBST(LIBRFP)
1512 AC_SUBST(RFPINC)
1513 AC_SUBST(BABELD)
1514 AC_SUBST(BGPD)
1515 AC_SUBST(RIPD)
1516 AC_SUBST(RIPNGD)
1517 AC_SUBST(OSPFD)
1518 AC_SUBST(OSPF6D)
1519 AC_SUBST(LDPD)
1520 AC_SUBST(NHRPD)
1521 AC_SUBST(EIGRPD)
1522 AC_SUBST(WATCHFRR)
1523 AC_SUBST(ISISD)
1524 AC_SUBST(PIMD)
1525 AC_SUBST(SOLARIS)
1526 AC_SUBST(VTYSH)
1527 AC_SUBST(CURSES)
1528 AC_SUBST(OSPFCLIENT)
1529 AC_SUBST(OSPFAPI)
1530 AC_CHECK_LIB(crypt, crypt)
1531 AC_CHECK_LIB(resolv, res_init)
1532
1533 dnl ---------------------------
1534 dnl check system has PCRE regexp
1535 dnl ---------------------------
1536 if test "x$enable_pcreposix" = "xyes"; then
1537   AC_CHECK_LIB(pcreposix, regexec, [], [
1538     AC_MSG_ERROR([--enable-pcreposix given but unable to find libpcreposix])
1539   ])
1540 fi
1541 AC_SUBST(HAVE_LIBPCREPOSIX)
1542
1543 dnl ------------------
1544 dnl check C-Ares library
1545 dnl ------------------
1546 if test "${NHRPD}" != ""; then
1547   PKG_CHECK_MODULES([CARES], [libcares], , [
1548     AC_MSG_ERROR([trying to build nhrpd, but libcares not found. install c-ares and its -dev headers.])
1549   ])
1550 fi
1551
1552
1553 dnl ------------------
1554 dnl check Net-SNMP library
1555 dnl ------------------
1556 if test "${enable_snmp}" != ""; then
1557    AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], [no])
1558    if test x"$NETSNMP_CONFIG" = x"no"; then
1559       AC_MSG_ERROR([--enable-snmp given but unable to find net-snmp-config])
1560    fi
1561    SNMP_LIBS="`${NETSNMP_CONFIG} --agent-libs`"
1562    SNMP_CFLAGS="`${NETSNMP_CONFIG} --base-cflags`"
1563    AC_MSG_CHECKING([whether we can link to Net-SNMP])
1564    AC_LINK_IFELSE_FLAGS([$SNMP_CFLAGS], [$SNMP_LIBS], [AC_LANG_PROGRAM([
1565 int main(void);
1566 ],
1567 [
1568 {
1569   return 0;
1570 }
1571 ])], [
1572      AC_MSG_ERROR([--enable-snmp given but not usable])])
1573    case "${enable_snmp}" in
1574      yes)
1575       SNMP_METHOD=agentx
1576       ;;
1577      smux|agentx)
1578       SNMP_METHOD="${enable_snmp}"
1579       ;;
1580      *)
1581       AC_MSG_ERROR([--enable-snmp given with an unknown method (${enable_snmp}). Use smux or agentx])
1582       ;;
1583    esac
1584    AH_TEMPLATE([SNMP_SMUX], [Use SNMP SMUX to interface with snmpd])
1585    AH_TEMPLATE([SNMP_AGENTX], [Use SNMP AgentX to interface with snmpd])
1586    AC_DEFINE_UNQUOTED(AS_TR_CPP(SNMP_${SNMP_METHOD}),,SNMP method to interface with snmpd)
1587 fi
1588 AM_CONDITIONAL([SNMP], [test "x${SNMP_METHOD}" != "x"])
1589 AC_SUBST(SNMP_LIBS)
1590 AC_SUBST(SNMP_CFLAGS)
1591
1592 dnl ---------------
1593 dnl math
1594 dnl ---------------
1595 AC_SEARCH_LIBS([sqrt], [m])
1596
1597 dnl ---------------
1598 dnl dlopen & dlinfo
1599 dnl ---------------
1600 AC_SEARCH_LIBS(dlopen, [dl dld], [], [
1601   AC_MSG_ERROR([unable to find the dlopen()])
1602 ])
1603
1604 AC_CHECK_HEADERS([link.h])
1605
1606 AC_MSG_CHECKING([for dlinfo(RTLD_DI_ORIGIN)])
1607 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1608 #include <stdlib.h>
1609 #ifdef HAVE_LINK_H
1610 #include <link.h>
1611 #endif
1612 #include <dlfcn.h>
1613 ]], [[
1614   char origin[1];
1615   dlinfo (NULL, RTLD_DI_ORIGIN, &origin);
1616 ]])], [
1617   AC_MSG_RESULT(yes)
1618   AC_DEFINE(HAVE_DLINFO_ORIGIN, 1, [Have dlinfo RTLD_DI_ORIGIN])
1619 ], [
1620   AC_MSG_RESULT(no)
1621 ])
1622
1623 AC_MSG_CHECKING([for dlinfo(RTLD_DI_LINKMAP)])
1624 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1625 #include <stdlib.h>
1626 #ifdef HAVE_LINK_H
1627 #include <link.h>
1628 #endif
1629 #include <dlfcn.h>
1630 ]], [[
1631   struct link_map *lm = NULL;
1632   dlinfo (NULL, RTLD_DI_LINKMAP, &lm);
1633 ]])], [
1634   AC_MSG_RESULT(yes)
1635   AC_DEFINE(HAVE_DLINFO_LINKMAP, 1, [Have dlinfo RTLD_DI_LINKMAP])
1636 ], [
1637   AC_MSG_RESULT(no)
1638 ])
1639
1640
1641 AM_CONDITIONAL(SNMP, test "x$SNMP_METHOD" = "xagentx")
1642
1643 dnl ---------------------------
1644 dnl sockaddr and netinet checks
1645 dnl ---------------------------
1646 AC_CHECK_TYPES([
1647         struct sockaddr_dl,
1648         struct vifctl, struct mfcctl, struct sioc_sg_req,
1649         vifi_t, struct sioc_vif_req, struct igmpmsg,
1650         struct ifaliasreq, struct if6_aliasreq, struct in6_aliasreq,
1651         struct nd_opt_adv_interval, struct rt_addrinfo,
1652         struct nd_opt_homeagent_info, struct nd_opt_adv_interval],
1653         [], [], FRR_INCLUDES)
1654
1655 AC_CHECK_MEMBERS([struct sockaddr.sa_len,
1656         struct sockaddr_in.sin_len, struct sockaddr_un.sun_len,
1657         struct sockaddr_dl.sdl_len,
1658         struct if6_aliasreq.ifra_lifetime,
1659         struct nd_opt_adv_interval.nd_opt_ai_type],
1660         [], [], FRR_INCLUDES)
1661
1662 dnl ---------------------------
1663 dnl IRDP/pktinfo/icmphdr checks
1664 dnl ---------------------------
1665 AC_CHECK_TYPES([struct in_pktinfo],
1666  [AC_CHECK_TYPES([struct icmphdr],
1667    [if test "${enable_irdp}" != "no"; then
1668       AC_DEFINE(HAVE_IRDP,, IRDP)
1669     fi],
1670    [if test "${enable_irdp}" = "yes"; then
1671       AC_MSG_ERROR(['IRDP requires in_pktinfo at the moment!'])
1672     fi], [FRR_INCLUDES])],
1673  [if test "${enable_irdp}" = "yes"; then
1674     AC_MSG_ERROR(['IRDP requires in_pktinfo at the moment!'])
1675   fi], [FRR_INCLUDES])
1676
1677 dnl -----------------------
1678 dnl checking for IP_PKTINFO
1679 dnl -----------------------
1680 AC_MSG_CHECKING(for IP_PKTINFO)
1681 AC_TRY_COMPILE([#include <netdb.h>], [
1682   int opt = IP_PKTINFO;
1683 ], [
1684   AC_MSG_RESULT(yes)
1685   AC_DEFINE(HAVE_IP_PKTINFO, 1, [Have IP_PKTINFO])
1686 ], [
1687   AC_MSG_RESULT(no)
1688 ])
1689
1690 dnl ---------------------------
1691 dnl checking for IP_RECVDSTADDR
1692 dnl ---------------------------
1693 AC_MSG_CHECKING(for IP_RECVDSTADDR)
1694 AC_TRY_COMPILE([#include <netinet/in.h>], [
1695   int opt = IP_RECVDSTADDR;
1696 ], [
1697   AC_MSG_RESULT(yes)
1698   AC_DEFINE(HAVE_IP_RECVDSTADDR, 1, [Have IP_RECVDSTADDR])
1699 ], [
1700   AC_MSG_RESULT(no)
1701 ])
1702
1703 dnl ----------------------
1704 dnl checking for IP_RECVIF
1705 dnl ----------------------
1706 AC_MSG_CHECKING(for IP_RECVIF)
1707 AC_TRY_COMPILE([#include <netinet/in.h>], [
1708   int opt = IP_RECVIF;
1709 ], [
1710   AC_MSG_RESULT(yes)
1711   AC_DEFINE(HAVE_IP_RECVIF, 1, [Have IP_RECVIF])
1712 ], [
1713   AC_MSG_RESULT(no)
1714 ])
1715
1716 dnl ----------------------
1717 dnl checking for SO_BINDANY
1718 dnl ----------------------
1719 AC_MSG_CHECKING(for SO_BINDANY)
1720 AC_TRY_COMPILE([#include <sys/socket.h>], [
1721   int opt = SO_BINDANY;
1722 ], [
1723   AC_MSG_RESULT(yes)
1724   AC_DEFINE(HAVE_SO_BINDANY, 1, [Have SO_BINDANY])
1725 ], [
1726   AC_MSG_RESULT(no)
1727 ])
1728
1729 dnl ----------------------
1730 dnl checking for IP_FREEBIND
1731 dnl ----------------------
1732 AC_MSG_CHECKING(for IP_FREEBIND)
1733 AC_TRY_COMPILE([#include <netinet/in.h>], [
1734   int opt = IP_FREEBIND;
1735 ], [
1736   AC_MSG_RESULT(yes)
1737   AC_DEFINE(HAVE_IP_FREEBIND, 1, [Have IP_FREEBIND])
1738 ], [
1739   AC_MSG_RESULT(no)
1740 ])
1741
1742 dnl --------------------------------------
1743 dnl checking for be32dec existence or not
1744 dnl --------------------------------------
1745 AC_CHECK_DECLS([be32enc, be32dec], [], [],
1746                [#include <sys/endian.h>])
1747
1748 dnl --------------------------------------
1749 dnl checking for clock_time monotonic struct and call
1750 dnl --------------------------------------
1751 AC_CHECK_DECL(CLOCK_MONOTONIC,
1752         [AC_CHECK_LIB(rt, clock_gettime, [LIBS="$LIBS -lrt"])
1753          AC_DEFINE(HAVE_CLOCK_MONOTONIC,, Have monotonic clock)
1754 ], [AC_MSG_RESULT(no)], [FRR_INCLUDES])
1755
1756 dnl --------------------------------------
1757 dnl checking for flex and bison
1758 dnl --------------------------------------
1759
1760 AM_PROG_LEX
1761 AC_MSG_CHECKING(version of flex)
1762 frr_ac_flex_version="$(eval $LEX -V | grep flex | head -n 1)"
1763 frr_ac_flex_version="${frr_ac_flex_version##* }"
1764 AC_MSG_RESULT([$frr_ac_flex_version])
1765 AX_COMPARE_VERSION([$frr_ac_flex_version], [lt], [2.5.20], [
1766   LEX="$SHELL $missing_dir/missing flex"
1767   if test -f "${srcdir}/lib/command_lex.c" -a -f "${srcdir}/lib/command_lex.h"; then
1768     AC_MSG_WARN([using pregenerated flex output files])
1769   else
1770     AC_MSG_ERROR([flex failure and pregenerated files not included (probably a git build)])
1771   fi
1772   AC_SUBST([LEX_OUTPUT_ROOT], [lex.yy])
1773   AC_SUBST([LEXLIB], [''])
1774 ])
1775
1776 AC_PROG_YACC
1777 dnl thanks GNU bison for this b*llshit...
1778 AC_MSG_CHECKING(version of bison)
1779 frr_ac_bison_version="$(eval $YACC -V | grep bison | head -n 1)"
1780 frr_ac_bison_version="${frr_ac_bison_version##* }"
1781 frr_ac_bison_missing="false"
1782 case "x${frr_ac_bison_version}" in
1783   x2.7*)
1784     BISON_OPENBRACE='"'
1785     BISON_CLOSEBRACE='"'
1786     BISON_VERBOSE=''
1787     AC_MSG_RESULT([$frr_ac_bison_version - 2.7 or older])
1788     ;;
1789   x2.*|x1.*)
1790     AC_MSG_RESULT([$frr_ac_bison_version])
1791     AC_MSG_WARN([installed bison is too old.  Please install GNU bison 2.7.x or newer.])
1792     frr_ac_bison_missing="true"
1793     ;;
1794   x)
1795     AC_MSG_RESULT([none])
1796     AC_MSG_WARN([could not determine bison version.  Please install GNU bison 2.7.x or newer.])
1797     frr_ac_bison_missing="true"
1798     ;;
1799   *)
1800     BISON_OPENBRACE='{'
1801     BISON_CLOSEBRACE='}'
1802     BISON_VERBOSE='-Dparse.error=verbose'
1803     AC_MSG_RESULT([$frr_ac_bison_version - 3.0 or newer])
1804     ;;
1805 esac
1806 AC_SUBST(BISON_OPENBRACE)
1807 AC_SUBST(BISON_CLOSEBRACE)
1808 AC_SUBST(BISON_VERBOSE)
1809
1810 if $frr_ac_bison_missing; then
1811   YACC="$SHELL $missing_dir/missing bison -y"
1812   if test -f "${srcdir}/lib/command_parse.c" -a -f "${srcdir}/lib/command_parse.h"; then
1813     AC_MSG_WARN([using pregenerated bison output files])
1814   else
1815     AC_MSG_ERROR([bison failure and pregenerated files not included (probably a git build)])
1816   fi
1817 fi
1818
1819 dnl -------------------
1820 dnl capabilities checks
1821 dnl -------------------
1822 if test "${enable_capabilities}" != "no"; then
1823   AC_MSG_CHECKING(whether prctl PR_SET_KEEPCAPS is available)
1824   AC_TRY_COMPILE([#include <sys/prctl.h>],[prctl(PR_SET_KEEPCAPS, 1, 0, 0, 0);],
1825     [AC_MSG_RESULT(yes)
1826      AC_DEFINE(HAVE_PR_SET_KEEPCAPS,,prctl)
1827      frr_ac_keepcaps="yes"],
1828      AC_MSG_RESULT(no)
1829   )
1830   if test x"${frr_ac_keepcaps}" = x"yes"; then
1831     AC_CHECK_HEADERS(sys/capability.h)
1832   fi
1833   if test x"${ac_cv_header_sys_capability_h}" = x"yes"; then
1834     AC_CHECK_LIB(cap, cap_init,
1835       [AC_DEFINE(HAVE_LCAPS,1,Capabilities)
1836        LIBCAP="-lcap"
1837        frr_ac_lcaps="yes"]
1838     )
1839   else
1840     AC_CHECK_HEADERS(priv.h,
1841      [AC_MSG_CHECKING(Solaris style privileges are available)
1842       AC_TRY_COMPILE([#include <priv.h>],[getpflags(PRIV_AWARE);],
1843           [AC_MSG_RESULT(yes)
1844            AC_DEFINE(HAVE_SOLARIS_CAPABILITIES,1,getpflags)
1845            frr_ac_scaps="yes"],
1846            AC_MSG_RESULT(no)
1847       )
1848      ]
1849    )
1850   fi
1851   if test x"${frr_ac_scaps}" = x"yes" \
1852        -o x"${frr_ac_lcaps}" = x"yes"; then
1853     AC_DEFINE(HAVE_CAPABILITIES,1,capabilities)
1854   fi
1855 fi
1856 AC_SUBST(LIBCAP)
1857
1858 dnl ---------------------------
1859 dnl check for glibc 'backtrace'
1860 dnl ---------------------------
1861 if test x"${enable_backtrace}" != x"no" ; then
1862   backtrace_ok=no
1863   AC_CHECK_HEADER([execinfo.h], [
1864     AC_SEARCH_LIBS([backtrace], [execinfo], [
1865       AC_DEFINE(HAVE_GLIBC_BACKTRACE,,[Glibc backtrace])
1866       AC_DEFINE(HAVE_STACK_TRACE,,[Stack symbol decoding])
1867       backtrace_ok=yes
1868     ],, [-lm])
1869   ])
1870
1871   if test x"${enable_backtrace}" = x"yes" -a x"${backtrace_ok}" = x"no"; then
1872     dnl user explicitly requested backtrace but we failed to find support
1873     AC_MSG_FAILURE([failed to find backtrace support])
1874   fi
1875 fi
1876
1877 dnl -----------------------------------------
1878 dnl check for malloc mallinfo struct and call
1879 dnl this must try and link using LIBS, in
1880 dnl order to check no alternative allocator
1881 dnl has been specified, which might not provide
1882 dnl mallinfo, e.g. such as Umem on Solaris.
1883 dnl -----------------------------------------
1884 AC_CHECK_HEADER([malloc.h],
1885  [AC_MSG_CHECKING(whether mallinfo is available)
1886   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <malloc.h>]],
1887                         [[struct mallinfo ac_x; ac_x = mallinfo ();]])],
1888       [AC_MSG_RESULT(yes)
1889        AC_DEFINE(HAVE_MALLINFO,,mallinfo)],
1890        AC_MSG_RESULT(no)
1891   )
1892  ], [], FRR_INCLUDES)
1893
1894 dnl ----------
1895 dnl configure date
1896 dnl ----------
1897 CONFDATE=`date '+%Y%m%d'`
1898 AC_SUBST(CONFDATE)
1899
1900 dnl ------------------------------
1901 dnl set paths for state directory
1902 dnl ------------------------------
1903 AC_MSG_CHECKING(directory to use for state file)
1904 if test "${prefix}" = "NONE"; then
1905   frr_statedir_prefix="";
1906 else
1907   frr_statedir_prefix=${prefix}
1908 fi
1909 if test "${localstatedir}" = '${prefix}/var'; then
1910   for FRR_STATE_DIR in ${frr_statedir_prefix}/var/run dnl
1911                         ${frr_statedir_prefix}/var/adm dnl
1912                         ${frr_statedir_prefix}/etc dnl
1913                         /var/run        dnl
1914                         /var/adm        dnl
1915                         /etc            dnl
1916                         /dev/null;
1917   do
1918     test -d $FRR_STATE_DIR && break
1919   done
1920   frr_statedir=$FRR_STATE_DIR
1921 else
1922   frr_statedir=${localstatedir}
1923 fi
1924 if test $frr_statedir = "/dev/null"; then
1925     AC_MSG_ERROR('STATE DIRECTORY NOT FOUND! FIX OR SPECIFY --localstatedir!')
1926 fi
1927 AC_MSG_RESULT(${frr_statedir})
1928 AC_SUBST(frr_statedir)
1929
1930 AC_DEFINE_UNQUOTED(LDPD_SOCKET, "$frr_statedir/ldpd.sock",ldpd control socket)
1931 AC_DEFINE_UNQUOTED(ZEBRA_SERV_PATH, "$frr_statedir/zserv.api",zebra api socket)
1932 AC_DEFINE_UNQUOTED(DAEMON_VTY_DIR, "$frr_statedir",daemon vty directory)
1933
1934 dnl autoconf does this, but it does it too late...
1935 test "x$prefix" = xNONE && prefix=$ac_default_prefix
1936 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
1937
1938 dnl get the full path, recursing through variables...
1939 vtysh_bin="$bindir/vtysh"
1940 for I in 1 2 3 4 5 6 7 8 9 10; do
1941         eval vtysh_bin="\"$vtysh_bin\""
1942 done
1943 AC_DEFINE_UNQUOTED(VTYSH_BIN_PATH, "$vtysh_bin",path to vtysh binary)
1944
1945 CFG_SYSCONF="$sysconfdir"
1946 CFG_SBIN="$sbindir"
1947 CFG_STATE="$frr_statedir"
1948 CFG_MODULE="$moduledir"
1949 for I in 1 2 3 4 5 6 7 8 9 10; do
1950         eval CFG_SYSCONF="\"$CFG_SYSCONF\""
1951         eval CFG_SBIN="\"$CFG_SBIN\""
1952         eval CFG_STATE="\"$CFG_STATE\""
1953         eval CFG_MODULE="\"$CFG_MODULE\""
1954 done
1955 AC_SUBST(CFG_SYSCONF)
1956 AC_SUBST(CFG_SBIN)
1957 AC_SUBST(CFG_STATE)
1958 AC_SUBST(CFG_MODULE)
1959 AC_DEFINE_UNQUOTED(MODULE_PATH, "$CFG_MODULE", path to modules)
1960
1961 dnl ---------------------------
1962 dnl Check htonl works correctly
1963 dnl ---------------------------
1964 AC_MSG_CHECKING(for working htonl)
1965 AC_CACHE_VAL(ac_cv_htonl_works,
1966  [AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES],[htonl (0);])],
1967                 [ac_cv_htonl_works=yes], [ac_cv_htonl_works=no])
1968  ]
1969 )
1970 AC_MSG_RESULT($ac_cv_htonl_works)
1971
1972 AC_CONFIG_FILES([Makefile lib/Makefile qpb/Makefile zebra/Makefile ripd/Makefile
1973           ripngd/Makefile bgpd/Makefile ospfd/Makefile watchfrr/Makefile
1974           ospf6d/Makefile ldpd/Makefile isisd/Makefile vtysh/Makefile
1975           doc/Makefile ospfclient/Makefile tests/Makefile m4/Makefile
1976           bgpd/rfp-example/rfptest/Makefile bgpd/rfp-example/librfp/Makefile
1977           babeld/Makefile
1978           pimd/Makefile
1979           eigrpd/Makefile
1980           nhrpd/Makefile
1981           redhat/Makefile
1982           tools/Makefile
1983           pkgsrc/Makefile
1984           python/Makefile
1985           fpm/Makefile
1986           redhat/frr.spec
1987           snapcraft/Makefile
1988           snapcraft/snapcraft.yaml
1989           lib/version.h
1990           tests/lib/cli/test_cli.refout
1991           doc/defines.texi
1992           doc/bgpd.8
1993           doc/isisd.8
1994           doc/ospf6d.8
1995           doc/ospfclient.8
1996           doc/ospfd.8
1997           doc/ldpd.8
1998           doc/ripd.8
1999           doc/eigrpd.8
2000           doc/ripngd.8
2001           doc/pimd.8
2002           doc/nhrpd.8
2003           doc/vtysh.1
2004           doc/watchfrr.8
2005           doc/zebra.8
2006           doc/frr.1
2007           pkgsrc/bgpd.sh pkgsrc/ospf6d.sh pkgsrc/ospfd.sh
2008           pkgsrc/ripd.sh pkgsrc/ripngd.sh pkgsrc/zebra.sh
2009           pkgsrc/eigrpd.sh])
2010
2011
2012 AC_CONFIG_FILES([solaris/Makefile])
2013
2014 AC_CONFIG_FILES([vtysh/extract.pl],[chmod +x vtysh/extract.pl])
2015
2016 ## Hack, but working solution to avoid rebuilding of frr.info.
2017 ## It's already in CVS until texinfo 4.7 is more common.
2018 AC_OUTPUT
2019
2020 echo "
2021 FRRouting configuration
2022 ------------------------------
2023 FRR version             : ${PACKAGE_VERSION}
2024 host operating system   : ${host_os}
2025 source code location    : ${srcdir}
2026 compiler                : ${CC}
2027 compiler flags          : ${CFLAGS}
2028 make                    : ${MAKE-make}
2029 linker flags            : ${LDFLAGS} ${LIBS} ${LIBCAP} ${LIBREADLINE} ${LIBM}
2030 state file directory    : ${frr_statedir}
2031 config file directory   : `eval echo \`echo ${sysconfdir}\``
2032 example directory       : `eval echo \`echo ${exampledir}\``
2033 module directory        : ${CFG_MODULE}
2034 user to run as          : ${enable_user}
2035 group to run as         : ${enable_group}
2036 group for vty sockets   : ${enable_vty_group}
2037 config file mask        : ${enable_configfile_mask}
2038 log file mask           : ${enable_logfile_mask}
2039 zebra protobuf enabled  : ${have_protobuf:-no}
2040
2041 The above user and group must have read/write access to the state file
2042 directory and to the config files in the config file directory."